This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
doc fixes
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
140 C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<sockatmark>, C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<sockatmark>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item I<-X> FILEHANDLE
250
251 =item I<-X> EXPR
252
253 =item I<-X>
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Age of file in days when script started.
298     -A  Same for access time.
299     -C  Same for inode change time.
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  Example:
354
355     print "Can do.\n" if -r $a || -w _ || -x _;
356
357     stat($filename);
358     print "Readable\n" if -r _;
359     print "Writable\n" if -w _;
360     print "Executable\n" if -x _;
361     print "Setuid\n" if -u _;
362     print "Setgid\n" if -g _;
363     print "Sticky\n" if -k _;
364     print "Text\n" if -T _;
365     print "Binary\n" if -B _;
366
367 =item abs VALUE
368
369 =item abs
370
371 Returns the absolute value of its argument.
372 If VALUE is omitted, uses C<$_>.
373
374 =item accept NEWSOCKET,GENERICSOCKET
375
376 Accepts an incoming socket connect, just as the accept(2) system call
377 does.  Returns the packed address if it succeeded, false otherwise.
378 See the example in L<perlipc/"Sockets: Client/Server Communication">.
379
380 On systems that support a close-on-exec flag on files, the flag will
381 be set for the newly opened file descriptor, as determined by the
382 value of $^F.  See L<perlvar/$^F>.
383
384 =item alarm SECONDS
385
386 =item alarm
387
388 Arranges to have a SIGALRM delivered to this process after the
389 specified number of wallclock seconds have elapsed.  If SECONDS is not
390 specified, the value stored in C<$_> is used. (On some machines,
391 unfortunately, the elapsed time may be up to one second less or more
392 than you specified because of how seconds are counted, and process
393 scheduling may delay the delivery of the signal even further.)
394
395 Only one timer may be counting at once.  Each call disables the
396 previous timer, and an argument of C<0> may be supplied to cancel the
397 previous timer without starting a new one.  The returned value is the
398 amount of time remaining on the previous timer.
399
400 For delays of finer granularity than one second, you may use Perl's
401 four-argument version of select() leaving the first three arguments
402 undefined, or you might be able to use the C<syscall> interface to
403 access setitimer(2) if your system supports it.  The Time::HiRes
404 module (from CPAN, and starting from Perl 5.8 part of the standard
405 distribution) may also prove useful.
406
407 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
408 (C<sleep> may be internally implemented in your system with C<alarm>)
409
410 If you want to use C<alarm> to time out a system call you need to use an
411 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
412 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
413 restart system calls on some systems.  Using C<eval>/C<die> always works,
414 modulo the caveats given in L<perlipc/"Signals">.
415
416     eval {
417         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
418         alarm $timeout;
419         $nread = sysread SOCKET, $buffer, $size;
420         alarm 0;
421     };
422     if ($@) {
423         die unless $@ eq "alarm\n";   # propagate unexpected errors
424         # timed out
425     }
426     else {
427         # didn't
428     }
429
430 =item atan2 Y,X
431
432 Returns the arctangent of Y/X in the range -PI to PI.
433
434 For the tangent operation, you may use the C<Math::Trig::tan>
435 function, or use the familiar relation:
436
437     sub tan { sin($_[0]) / cos($_[0])  }
438
439 =item bind SOCKET,NAME
440
441 Binds a network address to a socket, just as the bind system call
442 does.  Returns true if it succeeded, false otherwise.  NAME should be a
443 packed address of the appropriate type for the socket.  See the examples in
444 L<perlipc/"Sockets: Client/Server Communication">.
445
446 =item binmode FILEHANDLE, DISCIPLINE
447
448 =item binmode FILEHANDLE
449
450 Arranges for FILEHANDLE to be read or written in "binary" or "text" mode
451 on systems where the run-time libraries distinguish between binary and
452 text files.  If FILEHANDLE is an expression, the value is taken as the
453 name of the filehandle.  DISCIPLINE can be either of C<:raw> for
454 binary mode or C<:crlf> for "text" mode.  If the DISCIPLINE is
455 omitted, it defaults to C<:raw>.  Returns true on success, C<undef> on
456 failure.  The C<:raw> are C<:clrf>, and any other directives of the
457 form C<:...>, are called I/O I<disciplines>.
458
459 The C<open> pragma can be used to establish default I/O disciplines.
460 See L<open>.
461
462 In general, binmode() should be called after open() but before any I/O
463 is done on the filehandle.  Calling binmode() will flush any possibly
464 pending buffered input or output data on the handle.  The only
465 exception to this is the C<:encoding> discipline that changes
466 the default character encoding of the handle, see L<open>.
467 The C<:encoding> discipline sometimes needs to be called in
468 mid-stream, and it doesn't flush the stream.
469
470 On some systems binmode() is necessary when you're not working with a
471 text file.  For the sake of portability it is a good idea to always use
472 it when appropriate, and to never use it when it isn't appropriate.
473
474 In other words:  Regardless of platform, use binmode() on binary
475 files, and do not use binmode() on text files.
476
477 The operating system, device drivers, C libraries, and Perl run-time
478 system all work together to let the programmer treat a single
479 character (C<\n>) as the line terminator, irrespective of the external
480 representation.  On many operating systems, the native text file
481 representation matches the internal representation, but on some
482 platforms the external representation of C<\n> is made up of more than
483 one character.
484
485 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
486 character to end each line in the external representation of text (even
487 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
488 on Unix and most VMS files).  Consequently binmode() has no effect on
489 these operating systems.  In other systems like OS/2, DOS and the various
490 flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>, but
491 what's stored in text files are the two characters C<\cM\cJ>.  That means
492 that, if you don't use binmode() on these systems, C<\cM\cJ> sequences on
493 disk will be converted to C<\n> on input, and any C<\n> in your program
494 will be converted back to C<\cM\cJ> on output.  This is what you want for
495 text files, but it can be disastrous for binary files.
496
497 Another consequence of using binmode() (on some systems) is that
498 special end-of-file markers will be seen as part of the data stream.
499 For systems from the Microsoft family this means that if your binary
500 data contains C<\cZ>, the I/O subsystem will regard it as the end of
501 the file, unless you use binmode().
502
503 binmode() is not only important for readline() and print() operations,
504 but also when using read(), seek(), sysread(), syswrite() and tell()
505 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
506 in L<perlvar> for how to manually set your input and output
507 line-termination sequences.
508
509 =item bless REF,CLASSNAME
510
511 =item bless REF
512
513 This function tells the thingy referenced by REF that it is now an object
514 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
515 is used.  Because a C<bless> is often the last thing in a constructor,
516 it returns the reference for convenience.  Always use the two-argument
517 version if the function doing the blessing might be inherited by a
518 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
519 (and blessings) of objects.
520
521 Consider always blessing objects in CLASSNAMEs that are mixed case.
522 Namespaces with all lowercase names are considered reserved for
523 Perl pragmata.  Builtin types have all uppercase names, so to prevent
524 confusion, you may wish to avoid such package names as well.  Make sure
525 that CLASSNAME is a true value.
526
527 See L<perlmod/"Perl Modules">.
528
529 =item caller EXPR
530
531 =item caller
532
533 Returns the context of the current subroutine call.  In scalar context,
534 returns the caller's package name if there is a caller, that is, if
535 we're in a subroutine or C<eval> or C<require>, and the undefined value
536 otherwise.  In list context, returns
537
538     ($package, $filename, $line) = caller;
539
540 With EXPR, it returns some extra information that the debugger uses to
541 print a stack trace.  The value of EXPR indicates how many call frames
542 to go back before the current one.
543
544     ($package, $filename, $line, $subroutine, $hasargs,
545     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
546
547 Here $subroutine may be C<(eval)> if the frame is not a subroutine
548 call, but an C<eval>.  In such a case additional elements $evaltext and
549 C<$is_require> are set: C<$is_require> is true if the frame is created by a
550 C<require> or C<use> statement, $evaltext contains the text of the
551 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
552 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
553 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
554 frame.  C<$hasargs> is true if a new instance of C<@_> was set up for the
555 frame.  C<$hints> and C<$bitmask> contain pragmatic hints that the caller
556 was compiled with.  The C<$hints> and C<$bitmask> values are subject to
557 change between versions of Perl, and are not meant for external use.
558
559 Furthermore, when called from within the DB package, caller returns more
560 detailed information: it sets the list variable C<@DB::args> to be the
561 arguments with which the subroutine was invoked.
562
563 Be aware that the optimizer might have optimized call frames away before
564 C<caller> had a chance to get the information.  That means that C<caller(N)>
565 might not return information about the call frame you expect it do, for
566 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
567 previous time C<caller> was called.
568
569 =item chdir EXPR
570
571 Changes the working directory to EXPR, if possible. If EXPR is omitted,
572 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
573 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
574 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
575 neither is set, C<chdir> does nothing. It returns true upon success,
576 false otherwise. See the example under C<die>.
577
578 =item chmod LIST
579
580 Changes the permissions of a list of files.  The first element of the
581 list must be the numerical mode, which should probably be an octal
582 number, and which definitely should I<not> a string of octal digits:
583 C<0644> is okay, C<'0644'> is not.  Returns the number of files
584 successfully changed.  See also L</oct>, if all you have is a string.
585
586     $cnt = chmod 0755, 'foo', 'bar';
587     chmod 0755, @executables;
588     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
589                                              # --w----r-T
590     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
591     $mode = 0644;   chmod $mode, 'foo';      # this is best
592
593 You can also import the symbolic C<S_I*> constants from the Fcntl
594 module:
595
596     use Fcntl ':mode';
597
598     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
599     # This is identical to the chmod 0755 of the above example.
600
601 =item chomp VARIABLE
602
603 =item chomp( LIST )
604
605 =item chomp
606
607 This safer version of L</chop> removes any trailing string
608 that corresponds to the current value of C<$/> (also known as
609 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
610 number of characters removed from all its arguments.  It's often used to
611 remove the newline from the end of an input record when you're worried
612 that the final record may be missing its newline.  When in paragraph
613 mode (C<$/ = "">), it removes all trailing newlines from the string.
614 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
615 a reference to an integer or the like, see L<perlvar>) chomp() won't
616 remove anything.
617 If VARIABLE is omitted, it chomps C<$_>.  Example:
618
619     while (<>) {
620         chomp;  # avoid \n on last field
621         @array = split(/:/);
622         # ...
623     }
624
625 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
626
627 You can actually chomp anything that's an lvalue, including an assignment:
628
629     chomp($cwd = `pwd`);
630     chomp($answer = <STDIN>);
631
632 If you chomp a list, each element is chomped, and the total number of
633 characters removed is returned.
634
635 =item chop VARIABLE
636
637 =item chop( LIST )
638
639 =item chop
640
641 Chops off the last character of a string and returns the character
642 chopped.  It is much more efficient than C<s/.$//s> because it neither
643 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
644 If VARIABLE is a hash, it chops the hash's values, but not its keys.
645
646 You can actually chop anything that's an lvalue, including an assignment.
647
648 If you chop a list, each element is chopped.  Only the value of the
649 last C<chop> is returned.
650
651 Note that C<chop> returns the last character.  To return all but the last
652 character, use C<substr($string, 0, -1)>.
653
654 =item chown LIST
655
656 Changes the owner (and group) of a list of files.  The first two
657 elements of the list must be the I<numeric> uid and gid, in that
658 order.  A value of -1 in either position is interpreted by most
659 systems to leave that value unchanged.  Returns the number of files
660 successfully changed.
661
662     $cnt = chown $uid, $gid, 'foo', 'bar';
663     chown $uid, $gid, @filenames;
664
665 Here's an example that looks up nonnumeric uids in the passwd file:
666
667     print "User: ";
668     chomp($user = <STDIN>);
669     print "Files: ";
670     chomp($pattern = <STDIN>);
671
672     ($login,$pass,$uid,$gid) = getpwnam($user)
673         or die "$user not in passwd file";
674
675     @ary = glob($pattern);      # expand filenames
676     chown $uid, $gid, @ary;
677
678 On most systems, you are not allowed to change the ownership of the
679 file unless you're the superuser, although you should be able to change
680 the group to any of your secondary groups.  On insecure systems, these
681 restrictions may be relaxed, but this is not a portable assumption.
682 On POSIX systems, you can detect this condition this way:
683
684     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
685     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
686
687 =item chr NUMBER
688
689 =item chr
690
691 Returns the character represented by that NUMBER in the character set.
692 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
693 chr(0x263a) is a Unicode smiley face.  Note that characters from 127
694 to 255 (inclusive) are by default not encoded in Unicode for backward
695 compatibility reasons (but see L<encoding>).
696
697 For the reverse, use L</ord>.
698 See L<perlunicode> and L<encoding> for more about Unicode.
699
700 If NUMBER is omitted, uses C<$_>.
701
702 =item chroot FILENAME
703
704 =item chroot
705
706 This function works like the system call by the same name: it makes the
707 named directory the new root directory for all further pathnames that
708 begin with a C</> by your process and all its children.  (It doesn't
709 change your current working directory, which is unaffected.)  For security
710 reasons, this call is restricted to the superuser.  If FILENAME is
711 omitted, does a C<chroot> to C<$_>.
712
713 =item close FILEHANDLE
714
715 =item close
716
717 Closes the file or pipe associated with the file handle, returning
718 true only if IO buffers are successfully flushed and closes the system
719 file descriptor.  Closes the currently selected filehandle if the
720 argument is omitted.
721
722 You don't have to close FILEHANDLE if you are immediately going to do
723 another C<open> on it, because C<open> will close it for you.  (See
724 C<open>.)  However, an explicit C<close> on an input file resets the line
725 counter (C<$.>), while the implicit close done by C<open> does not.
726
727 If the file handle came from a piped open C<close> will additionally
728 return false if one of the other system calls involved fails or if the
729 program exits with non-zero status.  (If the only problem was that the
730 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe
731 also waits for the process executing on the pipe to complete, in case you
732 want to look at the output of the pipe afterwards, and
733 implicitly puts the exit status value of that command into C<$?>.
734
735 Prematurely closing the read end of a pipe (i.e. before the process
736 writing to it at the other end has closed it) will result in a
737 SIGPIPE being delivered to the writer.  If the other end can't
738 handle that, be sure to read all the data before closing the pipe.
739
740 Example:
741
742     open(OUTPUT, '|sort >foo')  # pipe to sort
743         or die "Can't start sort: $!";
744     #...                        # print stuff to output
745     close OUTPUT                # wait for sort to finish
746         or warn $! ? "Error closing sort pipe: $!"
747                    : "Exit status $? from sort";
748     open(INPUT, 'foo')          # get sort's results
749         or die "Can't open 'foo' for input: $!";
750
751 FILEHANDLE may be an expression whose value can be used as an indirect
752 filehandle, usually the real filehandle name.
753
754 =item closedir DIRHANDLE
755
756 Closes a directory opened by C<opendir> and returns the success of that
757 system call.
758
759 DIRHANDLE may be an expression whose value can be used as an indirect
760 dirhandle, usually the real dirhandle name.
761
762 =item connect SOCKET,NAME
763
764 Attempts to connect to a remote socket, just as the connect system call
765 does.  Returns true if it succeeded, false otherwise.  NAME should be a
766 packed address of the appropriate type for the socket.  See the examples in
767 L<perlipc/"Sockets: Client/Server Communication">.
768
769 =item continue BLOCK
770
771 Actually a flow control statement rather than a function.  If there is a
772 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
773 C<foreach>), it is always executed just before the conditional is about to
774 be evaluated again, just like the third part of a C<for> loop in C.  Thus
775 it can be used to increment a loop variable, even when the loop has been
776 continued via the C<next> statement (which is similar to the C C<continue>
777 statement).
778
779 C<last>, C<next>, or C<redo> may appear within a C<continue>
780 block.  C<last> and C<redo> will behave as if they had been executed within
781 the main block.  So will C<next>, but since it will execute a C<continue>
782 block, it may be more entertaining.
783
784     while (EXPR) {
785         ### redo always comes here
786         do_something;
787     } continue {
788         ### next always comes here
789         do_something_else;
790         # then back the top to re-check EXPR
791     }
792     ### last always comes here
793
794 Omitting the C<continue> section is semantically equivalent to using an
795 empty one, logically enough.  In that case, C<next> goes directly back
796 to check the condition at the top of the loop.
797
798 =item cos EXPR
799
800 =item cos
801
802 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
803 takes cosine of C<$_>.
804
805 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
806 function, or use this relation:
807
808     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
809
810 =item crypt PLAINTEXT,SALT
811
812 Encrypts a string exactly like the crypt(3) function in the C library
813 (assuming that you actually have a version there that has not been
814 extirpated as a potential munition).  This can prove useful for checking
815 the password file for lousy passwords, amongst other things.  Only the
816 guys wearing white hats should do this.
817
818 Note that C<crypt> is intended to be a one-way function, much like
819 breaking eggs to make an omelette.  There is no (known) corresponding
820 decrypt function (in other words, the crypt() is a one-way hash
821 function).  As a result, this function isn't all that useful for
822 cryptography.  (For that, see your nearby CPAN mirror.)
823
824 When verifying an existing encrypted string you should use the
825 encrypted text as the salt (like C<crypt($plain, $crypted) eq
826 $crypted>).  This allows your code to work with the standard C<crypt>
827 and with more exotic implementations.  In other words, do not assume
828 anything about the returned string itself, or how many bytes in
829 the encrypted string matter.
830
831 Traditionally the result is a string of 13 bytes: two first bytes of
832 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
833 the first eight bytes of the encrypted string mattered, but
834 alternative hashing schemes (like MD5), higher level security schemes
835 (like C2), and implementations on non-UNIX platforms may produce
836 different strings.
837
838 When choosing a new salt create a random two character string whose
839 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
840 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
841
842 Here's an example that makes sure that whoever runs this program knows
843 their own password:
844
845     $pwd = (getpwuid($<))[1];
846
847     system "stty -echo";
848     print "Password: ";
849     chomp($word = <STDIN>);
850     print "\n";
851     system "stty echo";
852
853     if (crypt($word, $pwd) ne $pwd) {
854         die "Sorry...\n";
855     } else {
856         print "ok\n";
857     }
858
859 Of course, typing in your own password to whoever asks you
860 for it is unwise.
861
862 The L<crypt> function is unsuitable for encrypting large quantities
863 of data, not least of all because you can't get the information
864 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
865 on your favorite CPAN mirror for a slew of potentially useful
866 modules.
867
868 If using crypt() on a Unicode string (which potentially has
869 characters with codepoints above 255), Perl tries to make sense of
870 the situation by using only the low eight bits of the characters when
871 calling crypt().
872
873 =item dbmclose HASH
874
875 [This function has been largely superseded by the C<untie> function.]
876
877 Breaks the binding between a DBM file and a hash.
878
879 =item dbmopen HASH,DBNAME,MASK
880
881 [This function has been largely superseded by the C<tie> function.]
882
883 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
884 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
885 argument is I<not> a filehandle, even though it looks like one).  DBNAME
886 is the name of the database (without the F<.dir> or F<.pag> extension if
887 any).  If the database does not exist, it is created with protection
888 specified by MASK (as modified by the C<umask>).  If your system supports
889 only the older DBM functions, you may perform only one C<dbmopen> in your
890 program.  In older versions of Perl, if your system had neither DBM nor
891 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
892 sdbm(3).
893
894 If you don't have write access to the DBM file, you can only read hash
895 variables, not set them.  If you want to test whether you can write,
896 either use file tests or try setting a dummy hash entry inside an C<eval>,
897 which will trap the error.
898
899 Note that functions such as C<keys> and C<values> may return huge lists
900 when used on large DBM files.  You may prefer to use the C<each>
901 function to iterate over large DBM files.  Example:
902
903     # print out history file offsets
904     dbmopen(%HIST,'/usr/lib/news/history',0666);
905     while (($key,$val) = each %HIST) {
906         print $key, ' = ', unpack('L',$val), "\n";
907     }
908     dbmclose(%HIST);
909
910 See also L<AnyDBM_File> for a more general description of the pros and
911 cons of the various dbm approaches, as well as L<DB_File> for a particularly
912 rich implementation.
913
914 You can control which DBM library you use by loading that library
915 before you call dbmopen():
916
917     use DB_File;
918     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
919         or die "Can't open netscape history file: $!";
920
921 =item defined EXPR
922
923 =item defined
924
925 Returns a Boolean value telling whether EXPR has a value other than
926 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
927 checked.
928
929 Many operations return C<undef> to indicate failure, end of file,
930 system error, uninitialized variable, and other exceptional
931 conditions.  This function allows you to distinguish C<undef> from
932 other values.  (A simple Boolean test will not distinguish among
933 C<undef>, zero, the empty string, and C<"0">, which are all equally
934 false.)  Note that since C<undef> is a valid scalar, its presence
935 doesn't I<necessarily> indicate an exceptional condition: C<pop>
936 returns C<undef> when its argument is an empty array, I<or> when the
937 element to return happens to be C<undef>.
938
939 You may also use C<defined(&func)> to check whether subroutine C<&func>
940 has ever been defined.  The return value is unaffected by any forward
941 declarations of C<&foo>.  Note that a subroutine which is not defined
942 may still be callable: its package may have an C<AUTOLOAD> method that
943 makes it spring into existence the first time that it is called -- see
944 L<perlsub>.
945
946 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
947 used to report whether memory for that aggregate has ever been
948 allocated.  This behavior may disappear in future versions of Perl.
949 You should instead use a simple test for size:
950
951     if (@an_array) { print "has array elements\n" }
952     if (%a_hash)   { print "has hash members\n"   }
953
954 When used on a hash element, it tells you whether the value is defined,
955 not whether the key exists in the hash.  Use L</exists> for the latter
956 purpose.
957
958 Examples:
959
960     print if defined $switch{'D'};
961     print "$val\n" while defined($val = pop(@ary));
962     die "Can't readlink $sym: $!"
963         unless defined($value = readlink $sym);
964     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
965     $debugging = 0 unless defined $debugging;
966
967 Note:  Many folks tend to overuse C<defined>, and then are surprised to
968 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
969 defined values.  For example, if you say
970
971     "ab" =~ /a(.*)b/;
972
973 The pattern match succeeds, and C<$1> is defined, despite the fact that it
974 matched "nothing".  But it didn't really match nothing--rather, it
975 matched something that happened to be zero characters long.  This is all
976 very above-board and honest.  When a function returns an undefined value,
977 it's an admission that it couldn't give you an honest answer.  So you
978 should use C<defined> only when you're questioning the integrity of what
979 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
980 what you want.
981
982 See also L</undef>, L</exists>, L</ref>.
983
984 =item delete EXPR
985
986 Given an expression that specifies a hash element, array element, hash slice,
987 or array slice, deletes the specified element(s) from the hash or array.
988 In the case of an array, if the array elements happen to be at the end,
989 the size of the array will shrink to the highest element that tests
990 true for exists() (or 0 if no such element exists).
991
992 Returns each element so deleted or the undefined value if there was no such
993 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
994 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
995 from a C<tie>d hash or array may not necessarily return anything.
996
997 Deleting an array element effectively returns that position of the array
998 to its initial, uninitialized state.  Subsequently testing for the same
999 element with exists() will return false.  Note that deleting array
1000 elements in the middle of an array will not shift the index of the ones
1001 after them down--use splice() for that.  See L</exists>.
1002
1003 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1004
1005     foreach $key (keys %HASH) {
1006         delete $HASH{$key};
1007     }
1008
1009     foreach $index (0 .. $#ARRAY) {
1010         delete $ARRAY[$index];
1011     }
1012
1013 And so do these:
1014
1015     delete @HASH{keys %HASH};
1016
1017     delete @ARRAY[0 .. $#ARRAY];
1018
1019 But both of these are slower than just assigning the empty list
1020 or undefining %HASH or @ARRAY:
1021
1022     %HASH = ();         # completely empty %HASH
1023     undef %HASH;        # forget %HASH ever existed
1024
1025     @ARRAY = ();        # completely empty @ARRAY
1026     undef @ARRAY;       # forget @ARRAY ever existed
1027
1028 Note that the EXPR can be arbitrarily complicated as long as the final
1029 operation is a hash element, array element,  hash slice, or array slice
1030 lookup:
1031
1032     delete $ref->[$x][$y]{$key};
1033     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1034
1035     delete $ref->[$x][$y][$index];
1036     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1037
1038 =item die LIST
1039
1040 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1041 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1042 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1043 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1044 an C<eval(),> the error message is stuffed into C<$@> and the
1045 C<eval> is terminated with the undefined value.  This makes
1046 C<die> the way to raise an exception.
1047
1048 Equivalent examples:
1049
1050     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1051     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1052
1053 If the value of EXPR does not end in a newline, the current script line
1054 number and input line number (if any) are also printed, and a newline
1055 is supplied.  Note that the "input line number" (also known as "chunk")
1056 is subject to whatever notion of "line" happens to be currently in
1057 effect, and is also available as the special variable C<$.>.
1058 See L<perlvar/"$/"> and L<perlvar/"$.">.
1059
1060 Hint: sometimes appending C<", stopped"> to your message
1061 will cause it to make better sense when the string C<"at foo line 123"> is
1062 appended.  Suppose you are running script "canasta".
1063
1064     die "/etc/games is no good";
1065     die "/etc/games is no good, stopped";
1066
1067 produce, respectively
1068
1069     /etc/games is no good at canasta line 123.
1070     /etc/games is no good, stopped at canasta line 123.
1071
1072 See also exit(), warn(), and the Carp module.
1073
1074 If LIST is empty and C<$@> already contains a value (typically from a
1075 previous eval) that value is reused after appending C<"\t...propagated">.
1076 This is useful for propagating exceptions:
1077
1078     eval { ... };
1079     die unless $@ =~ /Expected exception/;
1080
1081 If LIST is empty and C<$@> contains an object reference that has a
1082 C<PROPAGATE> method, that method will be called with additional file
1083 and line number parameters.  The return value replaces the value in
1084 C<$@>.  ie. as if C<<$@ = eval { $@->PROPAGATE(__FILE__, __LINE__) };>> 
1085 were called.
1086
1087 If C<$@> is empty then the string C<"Died"> is used.
1088
1089 die() can also be called with a reference argument.  If this happens to be
1090 trapped within an eval(), $@ contains the reference.  This behavior permits
1091 a more elaborate exception handling implementation using objects that
1092 maintain arbitrary state about the nature of the exception.  Such a scheme
1093 is sometimes preferable to matching particular string values of $@ using
1094 regular expressions.  Here's an example:
1095
1096     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1097     if ($@) {
1098         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1099             # handle Some::Module::Exception
1100         }
1101         else {
1102             # handle all other possible exceptions
1103         }
1104     }
1105
1106 Because perl will stringify uncaught exception messages before displaying
1107 them, you may want to overload stringification operations on such custom
1108 exception objects.  See L<overload> for details about that.
1109
1110 You can arrange for a callback to be run just before the C<die>
1111 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1112 handler will be called with the error text and can change the error
1113 message, if it sees fit, by calling C<die> again.  See
1114 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1115 L<"eval BLOCK"> for some examples.  Although this feature was meant
1116 to be run only right before your program was to exit, this is not
1117 currently the case--the C<$SIG{__DIE__}> hook is currently called
1118 even inside eval()ed blocks/strings!  If one wants the hook to do
1119 nothing in such situations, put
1120
1121         die @_ if $^S;
1122
1123 as the first line of the handler (see L<perlvar/$^S>).  Because
1124 this promotes strange action at a distance, this counterintuitive
1125 behavior may be fixed in a future release.
1126
1127 =item do BLOCK
1128
1129 Not really a function.  Returns the value of the last command in the
1130 sequence of commands indicated by BLOCK.  When modified by a loop
1131 modifier, executes the BLOCK once before testing the loop condition.
1132 (On other statements the loop modifiers test the conditional first.)
1133
1134 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1135 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1136 See L<perlsyn> for alternative strategies.
1137
1138 =item do SUBROUTINE(LIST)
1139
1140 A deprecated form of subroutine call.  See L<perlsub>.
1141
1142 =item do EXPR
1143
1144 Uses the value of EXPR as a filename and executes the contents of the
1145 file as a Perl script.  Its primary use is to include subroutines
1146 from a Perl subroutine library.
1147
1148     do 'stat.pl';
1149
1150 is just like
1151
1152     eval `cat stat.pl`;
1153
1154 except that it's more efficient and concise, keeps track of the current
1155 filename for error messages, searches the @INC libraries, and updates
1156 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1157 variables.  It also differs in that code evaluated with C<do FILENAME>
1158 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1159 same, however, in that it does reparse the file every time you call it,
1160 so you probably don't want to do this inside a loop.
1161
1162 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1163 error.  If C<do> can read the file but cannot compile it, it
1164 returns undef and sets an error message in C<$@>.   If the file is
1165 successfully compiled, C<do> returns the value of the last expression
1166 evaluated.
1167
1168 Note that inclusion of library modules is better done with the
1169 C<use> and C<require> operators, which also do automatic error checking
1170 and raise an exception if there's a problem.
1171
1172 You might like to use C<do> to read in a program configuration
1173 file.  Manual error checking can be done this way:
1174
1175     # read in config files: system first, then user
1176     for $file ("/share/prog/defaults.rc",
1177                "$ENV{HOME}/.someprogrc")
1178    {
1179         unless ($return = do $file) {
1180             warn "couldn't parse $file: $@" if $@;
1181             warn "couldn't do $file: $!"    unless defined $return;
1182             warn "couldn't run $file"       unless $return;
1183         }
1184     }
1185
1186 =item dump LABEL
1187
1188 =item dump
1189
1190 This function causes an immediate core dump.  See also the B<-u>
1191 command-line switch in L<perlrun>, which does the same thing.
1192 Primarily this is so that you can use the B<undump> program (not
1193 supplied) to turn your core dump into an executable binary after
1194 having initialized all your variables at the beginning of the
1195 program.  When the new binary is executed it will begin by executing
1196 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1197 Think of it as a goto with an intervening core dump and reincarnation.
1198 If C<LABEL> is omitted, restarts the program from the top.
1199
1200 B<WARNING>: Any files opened at the time of the dump will I<not>
1201 be open any more when the program is reincarnated, with possible
1202 resulting confusion on the part of Perl.
1203
1204 This function is now largely obsolete, partly because it's very
1205 hard to convert a core file into an executable, and because the
1206 real compiler backends for generating portable bytecode and compilable
1207 C code have superseded it.  That's why you should now invoke it as
1208 C<CORE::dump()>, if you don't want to be warned against a possible
1209 typo.
1210
1211 If you're looking to use L<dump> to speed up your program, consider
1212 generating bytecode or native C code as described in L<perlcc>.  If
1213 you're just trying to accelerate a CGI script, consider using the
1214 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1215 You might also consider autoloading or selfloading, which at least
1216 make your program I<appear> to run faster.
1217
1218 =item each HASH
1219
1220 When called in list context, returns a 2-element list consisting of the
1221 key and value for the next element of a hash, so that you can iterate over
1222 it.  When called in scalar context, returns only the key for the next
1223 element in the hash.
1224
1225 Entries are returned in an apparently random order.  The actual random
1226 order is subject to change in future versions of perl, but it is guaranteed
1227 to be in the same order as either the C<keys> or C<values> function
1228 would produce on the same (unmodified) hash.
1229
1230 When the hash is entirely read, a null array is returned in list context
1231 (which when assigned produces a false (C<0>) value), and C<undef> in
1232 scalar context.  The next call to C<each> after that will start iterating
1233 again.  There is a single iterator for each hash, shared by all C<each>,
1234 C<keys>, and C<values> function calls in the program; it can be reset by
1235 reading all the elements from the hash, or by evaluating C<keys HASH> or
1236 C<values HASH>.  If you add or delete elements of a hash while you're
1237 iterating over it, you may get entries skipped or duplicated, so
1238 don't.  Exception: It is always safe to delete the item most recently
1239 returned by C<each()>, which means that the following code will work:
1240
1241         while (($key, $value) = each %hash) {
1242           print $key, "\n";
1243           delete $hash{$key};   # This is safe
1244         }
1245
1246 The following prints out your environment like the printenv(1) program,
1247 only in a different order:
1248
1249     while (($key,$value) = each %ENV) {
1250         print "$key=$value\n";
1251     }
1252
1253 See also C<keys>, C<values> and C<sort>.
1254
1255 =item eof FILEHANDLE
1256
1257 =item eof ()
1258
1259 =item eof
1260
1261 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1262 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1263 gives the real filehandle.  (Note that this function actually
1264 reads a character and then C<ungetc>s it, so isn't very useful in an
1265 interactive context.)  Do not read from a terminal file (or call
1266 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1267 as terminals may lose the end-of-file condition if you do.
1268
1269 An C<eof> without an argument uses the last file read.  Using C<eof()>
1270 with empty parentheses is very different.  It refers to the pseudo file
1271 formed from the files listed on the command line and accessed via the
1272 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1273 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1274 used will cause C<@ARGV> to be examined to determine if input is
1275 available.
1276
1277 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1278 detect the end of each file, C<eof()> will only detect the end of the
1279 last file.  Examples:
1280
1281     # reset line numbering on each input file
1282     while (<>) {
1283         next if /^\s*#/;        # skip comments
1284         print "$.\t$_";
1285     } continue {
1286         close ARGV  if eof;     # Not eof()!
1287     }
1288
1289     # insert dashes just before last line of last file
1290     while (<>) {
1291         if (eof()) {            # check for end of current file
1292             print "--------------\n";
1293             close(ARGV);        # close or last; is needed if we
1294                                 # are reading from the terminal
1295         }
1296         print;
1297     }
1298
1299 Practical hint: you almost never need to use C<eof> in Perl, because the
1300 input operators typically return C<undef> when they run out of data, or if
1301 there was an error.
1302
1303 =item eval EXPR
1304
1305 =item eval BLOCK
1306
1307 In the first form, the return value of EXPR is parsed and executed as if it
1308 were a little Perl program.  The value of the expression (which is itself
1309 determined within scalar context) is first parsed, and if there weren't any
1310 errors, executed in the lexical context of the current Perl program, so
1311 that any variable settings or subroutine and format definitions remain
1312 afterwards.  Note that the value is parsed every time the eval executes.
1313 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1314 delay parsing and subsequent execution of the text of EXPR until run time.
1315
1316 In the second form, the code within the BLOCK is parsed only once--at the
1317 same time the code surrounding the eval itself was parsed--and executed
1318 within the context of the current Perl program.  This form is typically
1319 used to trap exceptions more efficiently than the first (see below), while
1320 also providing the benefit of checking the code within BLOCK at compile
1321 time.
1322
1323 The final semicolon, if any, may be omitted from the value of EXPR or within
1324 the BLOCK.
1325
1326 In both forms, the value returned is the value of the last expression
1327 evaluated inside the mini-program; a return statement may be also used, just
1328 as with subroutines.  The expression providing the return value is evaluated
1329 in void, scalar, or list context, depending on the context of the eval itself.
1330 See L</wantarray> for more on how the evaluation context can be determined.
1331
1332 If there is a syntax error or runtime error, or a C<die> statement is
1333 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1334 error message.  If there was no error, C<$@> is guaranteed to be a null
1335 string.  Beware that using C<eval> neither silences perl from printing
1336 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1337 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1338 L</warn> and L<perlvar>.
1339
1340 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1341 determining whether a particular feature (such as C<socket> or C<symlink>)
1342 is implemented.  It is also Perl's exception trapping mechanism, where
1343 the die operator is used to raise exceptions.
1344
1345 If the code to be executed doesn't vary, you may use the eval-BLOCK
1346 form to trap run-time errors without incurring the penalty of
1347 recompiling each time.  The error, if any, is still returned in C<$@>.
1348 Examples:
1349
1350     # make divide-by-zero nonfatal
1351     eval { $answer = $a / $b; }; warn $@ if $@;
1352
1353     # same thing, but less efficient
1354     eval '$answer = $a / $b'; warn $@ if $@;
1355
1356     # a compile-time error
1357     eval { $answer = };                 # WRONG
1358
1359     # a run-time error
1360     eval '$answer =';   # sets $@
1361
1362 Due to the current arguably broken state of C<__DIE__> hooks, when using
1363 the C<eval{}> form as an exception trap in libraries, you may wish not
1364 to trigger any C<__DIE__> hooks that user code may have installed.
1365 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1366 as shown in this example:
1367
1368     # a very private exception trap for divide-by-zero
1369     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1370     warn $@ if $@;
1371
1372 This is especially significant, given that C<__DIE__> hooks can call
1373 C<die> again, which has the effect of changing their error messages:
1374
1375     # __DIE__ hooks may modify error messages
1376     {
1377        local $SIG{'__DIE__'} =
1378               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1379        eval { die "foo lives here" };
1380        print $@ if $@;                # prints "bar lives here"
1381     }
1382
1383 Because this promotes action at a distance, this counterintuitive behavior
1384 may be fixed in a future release.
1385
1386 With an C<eval>, you should be especially careful to remember what's
1387 being looked at when:
1388
1389     eval $x;            # CASE 1
1390     eval "$x";          # CASE 2
1391
1392     eval '$x';          # CASE 3
1393     eval { $x };        # CASE 4
1394
1395     eval "\$$x++";      # CASE 5
1396     $$x++;              # CASE 6
1397
1398 Cases 1 and 2 above behave identically: they run the code contained in
1399 the variable $x.  (Although case 2 has misleading double quotes making
1400 the reader wonder what else might be happening (nothing is).)  Cases 3
1401 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1402 does nothing but return the value of $x.  (Case 4 is preferred for
1403 purely visual reasons, but it also has the advantage of compiling at
1404 compile-time instead of at run-time.)  Case 5 is a place where
1405 normally you I<would> like to use double quotes, except that in this
1406 particular situation, you can just use symbolic references instead, as
1407 in case 6.
1408
1409 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1410 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1411
1412 =item exec LIST
1413
1414 =item exec PROGRAM LIST
1415
1416 The C<exec> function executes a system command I<and never returns>--
1417 use C<system> instead of C<exec> if you want it to return.  It fails and
1418 returns false only if the command does not exist I<and> it is executed
1419 directly instead of via your system's command shell (see below).
1420
1421 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1422 warns you if there is a following statement which isn't C<die>, C<warn>,
1423 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1424 I<really> want to follow an C<exec> with some other statement, you
1425 can use one of these styles to avoid the warning:
1426
1427     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1428     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1429
1430 If there is more than one argument in LIST, or if LIST is an array
1431 with more than one value, calls execvp(3) with the arguments in LIST.
1432 If there is only one scalar argument or an array with one element in it,
1433 the argument is checked for shell metacharacters, and if there are any,
1434 the entire argument is passed to the system's command shell for parsing
1435 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1436 If there are no shell metacharacters in the argument, it is split into
1437 words and passed directly to C<execvp>, which is more efficient.
1438 Examples:
1439
1440     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1441     exec "sort $outfile | uniq";
1442
1443 If you don't really want to execute the first argument, but want to lie
1444 to the program you are executing about its own name, you can specify
1445 the program you actually want to run as an "indirect object" (without a
1446 comma) in front of the LIST.  (This always forces interpretation of the
1447 LIST as a multivalued list, even if there is only a single scalar in
1448 the list.)  Example:
1449
1450     $shell = '/bin/csh';
1451     exec $shell '-sh';          # pretend it's a login shell
1452
1453 or, more directly,
1454
1455     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1456
1457 When the arguments get executed via the system shell, results will
1458 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1459 for details.
1460
1461 Using an indirect object with C<exec> or C<system> is also more
1462 secure.  This usage (which also works fine with system()) forces
1463 interpretation of the arguments as a multivalued list, even if the
1464 list had just one argument.  That way you're safe from the shell
1465 expanding wildcards or splitting up words with whitespace in them.
1466
1467     @args = ( "echo surprise" );
1468
1469     exec @args;               # subject to shell escapes
1470                                 # if @args == 1
1471     exec { $args[0] } @args;  # safe even with one-arg list
1472
1473 The first version, the one without the indirect object, ran the I<echo>
1474 program, passing it C<"surprise"> an argument.  The second version
1475 didn't--it tried to run a program literally called I<"echo surprise">,
1476 didn't find it, and set C<$?> to a non-zero value indicating failure.
1477
1478 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1479 output before the exec, but this may not be supported on some platforms
1480 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1481 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1482 open handles in order to avoid lost output.
1483
1484 Note that C<exec> will not call your C<END> blocks, nor will it call
1485 any C<DESTROY> methods in your objects.
1486
1487 =item exists EXPR
1488
1489 Given an expression that specifies a hash element or array element,
1490 returns true if the specified element in the hash or array has ever
1491 been initialized, even if the corresponding value is undefined.  The
1492 element is not autovivified if it doesn't exist.
1493
1494     print "Exists\n"    if exists $hash{$key};
1495     print "Defined\n"   if defined $hash{$key};
1496     print "True\n"      if $hash{$key};
1497
1498     print "Exists\n"    if exists $array[$index];
1499     print "Defined\n"   if defined $array[$index];
1500     print "True\n"      if $array[$index];
1501
1502 A hash or array element can be true only if it's defined, and defined if
1503 it exists, but the reverse doesn't necessarily hold true.
1504
1505 Given an expression that specifies the name of a subroutine,
1506 returns true if the specified subroutine has ever been declared, even
1507 if it is undefined.  Mentioning a subroutine name for exists or defined
1508 does not count as declaring it.  Note that a subroutine which does not
1509 exist may still be callable: its package may have an C<AUTOLOAD>
1510 method that makes it spring into existence the first time that it is
1511 called -- see L<perlsub>.
1512
1513     print "Exists\n"    if exists &subroutine;
1514     print "Defined\n"   if defined &subroutine;
1515
1516 Note that the EXPR can be arbitrarily complicated as long as the final
1517 operation is a hash or array key lookup or subroutine name:
1518
1519     if (exists $ref->{A}->{B}->{$key})  { }
1520     if (exists $hash{A}{B}{$key})       { }
1521
1522     if (exists $ref->{A}->{B}->[$ix])   { }
1523     if (exists $hash{A}{B}[$ix])        { }
1524
1525     if (exists &{$ref->{A}{B}{$key}})   { }
1526
1527 Although the deepest nested array or hash will not spring into existence
1528 just because its existence was tested, any intervening ones will.
1529 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1530 into existence due to the existence test for the $key element above.
1531 This happens anywhere the arrow operator is used, including even:
1532
1533     undef $ref;
1534     if (exists $ref->{"Some key"})      { }
1535     print $ref;             # prints HASH(0x80d3d5c)
1536
1537 This surprising autovivification in what does not at first--or even
1538 second--glance appear to be an lvalue context may be fixed in a future
1539 release.
1540
1541 See L<perlref/"Pseudo-hashes: Using an array as a hash"> for specifics
1542 on how exists() acts when used on a pseudo-hash.
1543
1544 Use of a subroutine call, rather than a subroutine name, as an argument
1545 to exists() is an error.
1546
1547     exists &sub;        # OK
1548     exists &sub();      # Error
1549
1550 =item exit EXPR
1551
1552 Evaluates EXPR and exits immediately with that value.    Example:
1553
1554     $ans = <STDIN>;
1555     exit 0 if $ans =~ /^[Xx]/;
1556
1557 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1558 universally recognized values for EXPR are C<0> for success and C<1>
1559 for error; other values are subject to interpretation depending on the
1560 environment in which the Perl program is running.  For example, exiting
1561 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1562 the mailer to return the item undelivered, but that's not true everywhere.
1563
1564 Don't use C<exit> to abort a subroutine if there's any chance that
1565 someone might want to trap whatever error happened.  Use C<die> instead,
1566 which can be trapped by an C<eval>.
1567
1568 The exit() function does not always exit immediately.  It calls any
1569 defined C<END> routines first, but these C<END> routines may not
1570 themselves abort the exit.  Likewise any object destructors that need to
1571 be called are called before the real exit.  If this is a problem, you
1572 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1573 See L<perlmod> for details.
1574
1575 =item exp EXPR
1576
1577 =item exp
1578
1579 Returns I<e> (the natural logarithm base) to the power of EXPR.
1580 If EXPR is omitted, gives C<exp($_)>.
1581
1582 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1583
1584 Implements the fcntl(2) function.  You'll probably have to say
1585
1586     use Fcntl;
1587
1588 first to get the correct constant definitions.  Argument processing and
1589 value return works just like C<ioctl> below.
1590 For example:
1591
1592     use Fcntl;
1593     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1594         or die "can't fcntl F_GETFL: $!";
1595
1596 You don't have to check for C<defined> on the return from C<fnctl>.
1597 Like C<ioctl>, it maps a C<0> return from the system call into
1598 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1599 in numeric context.  It is also exempt from the normal B<-w> warnings
1600 on improper numeric conversions.
1601
1602 Note that C<fcntl> will produce a fatal error if used on a machine that
1603 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1604 manpage to learn what functions are available on your system.
1605
1606 =item fileno FILEHANDLE
1607
1608 Returns the file descriptor for a filehandle, or undefined if the
1609 filehandle is not open.  This is mainly useful for constructing
1610 bitmaps for C<select> and low-level POSIX tty-handling operations.
1611 If FILEHANDLE is an expression, the value is taken as an indirect
1612 filehandle, generally its name.
1613
1614 You can use this to find out whether two handles refer to the
1615 same underlying descriptor:
1616
1617     if (fileno(THIS) == fileno(THAT)) {
1618         print "THIS and THAT are dups\n";
1619     }
1620
1621 (Filehandles connected to memory objects via new features of C<open> may
1622 return undefined even though they are open.)
1623
1624
1625 =item flock FILEHANDLE,OPERATION
1626
1627 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1628 for success, false on failure.  Produces a fatal error if used on a
1629 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1630 C<flock> is Perl's portable file locking interface, although it locks
1631 only entire files, not records.
1632
1633 Two potentially non-obvious but traditional C<flock> semantics are
1634 that it waits indefinitely until the lock is granted, and that its locks
1635 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1636 fewer guarantees.  This means that files locked with C<flock> may be
1637 modified by programs that do not also use C<flock>.  See L<perlport>,
1638 your port's specific documentation, or your system-specific local manpages
1639 for details.  It's best to assume traditional behavior if you're writing
1640 portable programs.  (But if you're not, you should as always feel perfectly
1641 free to write for your own system's idiosyncrasies (sometimes called
1642 "features").  Slavish adherence to portability concerns shouldn't get
1643 in the way of your getting your job done.)
1644
1645 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1646 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1647 you can use the symbolic names if you import them from the Fcntl module,
1648 either individually, or as a group using the ':flock' tag.  LOCK_SH
1649 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1650 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1651 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1652 waiting for the lock (check the return status to see if you got it).
1653
1654 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1655 before locking or unlocking it.
1656
1657 Note that the emulation built with lockf(3) doesn't provide shared
1658 locks, and it requires that FILEHANDLE be open with write intent.  These
1659 are the semantics that lockf(3) implements.  Most if not all systems
1660 implement lockf(3) in terms of fcntl(2) locking, though, so the
1661 differing semantics shouldn't bite too many people.
1662
1663 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1664 be open with read intent to use LOCK_SH and requires that it be open
1665 with write intent to use LOCK_EX.
1666
1667 Note also that some versions of C<flock> cannot lock things over the
1668 network; you would need to use the more system-specific C<fcntl> for
1669 that.  If you like you can force Perl to ignore your system's flock(2)
1670 function, and so provide its own fcntl(2)-based emulation, by passing
1671 the switch C<-Ud_flock> to the F<Configure> program when you configure
1672 perl.
1673
1674 Here's a mailbox appender for BSD systems.
1675
1676     use Fcntl ':flock'; # import LOCK_* constants
1677
1678     sub lock {
1679         flock(MBOX,LOCK_EX);
1680         # and, in case someone appended
1681         # while we were waiting...
1682         seek(MBOX, 0, 2);
1683     }
1684
1685     sub unlock {
1686         flock(MBOX,LOCK_UN);
1687     }
1688
1689     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1690             or die "Can't open mailbox: $!";
1691
1692     lock();
1693     print MBOX $msg,"\n\n";
1694     unlock();
1695
1696 On systems that support a real flock(), locks are inherited across fork()
1697 calls, whereas those that must resort to the more capricious fcntl()
1698 function lose the locks, making it harder to write servers.
1699
1700 See also L<DB_File> for other flock() examples.
1701
1702 =item fork
1703
1704 Does a fork(2) system call to create a new process running the
1705 same program at the same point.  It returns the child pid to the
1706 parent process, C<0> to the child process, or C<undef> if the fork is
1707 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1708 are shared, while everything else is copied.  On most systems supporting
1709 fork(), great care has gone into making it extremely efficient (for
1710 example, using copy-on-write technology on data pages), making it the
1711 dominant paradigm for multitasking over the last few decades.
1712
1713 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1714 output before forking the child process, but this may not be supported
1715 on some platforms (see L<perlport>).  To be safe, you may need to set
1716 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1717 C<IO::Handle> on any open handles in order to avoid duplicate output.
1718
1719 If you C<fork> without ever waiting on your children, you will
1720 accumulate zombies.  On some systems, you can avoid this by setting
1721 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1722 forking and reaping moribund children.
1723
1724 Note that if your forked child inherits system file descriptors like
1725 STDIN and STDOUT that are actually connected by a pipe or socket, even
1726 if you exit, then the remote server (such as, say, a CGI script or a
1727 backgrounded job launched from a remote shell) won't think you're done.
1728 You should reopen those to F</dev/null> if it's any issue.
1729
1730 =item format
1731
1732 Declare a picture format for use by the C<write> function.  For
1733 example:
1734
1735     format Something =
1736         Test: @<<<<<<<< @||||| @>>>>>
1737               $str,     $%,    '$' . int($num)
1738     .
1739
1740     $str = "widget";
1741     $num = $cost/$quantity;
1742     $~ = 'Something';
1743     write;
1744
1745 See L<perlform> for many details and examples.
1746
1747 =item formline PICTURE,LIST
1748
1749 This is an internal function used by C<format>s, though you may call it,
1750 too.  It formats (see L<perlform>) a list of values according to the
1751 contents of PICTURE, placing the output into the format output
1752 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1753 Eventually, when a C<write> is done, the contents of
1754 C<$^A> are written to some filehandle, but you could also read C<$^A>
1755 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1756 does one C<formline> per line of form, but the C<formline> function itself
1757 doesn't care how many newlines are embedded in the PICTURE.  This means
1758 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1759 You may therefore need to use multiple formlines to implement a single
1760 record format, just like the format compiler.
1761
1762 Be careful if you put double quotes around the picture, because an C<@>
1763 character may be taken to mean the beginning of an array name.
1764 C<formline> always returns true.  See L<perlform> for other examples.
1765
1766 =item getc FILEHANDLE
1767
1768 =item getc
1769
1770 Returns the next character from the input file attached to FILEHANDLE,
1771 or the undefined value at end of file, or if there was an error.
1772 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1773 efficient.  However, it cannot be used by itself to fetch single
1774 characters without waiting for the user to hit enter.  For that, try
1775 something more like:
1776
1777     if ($BSD_STYLE) {
1778         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1779     }
1780     else {
1781         system "stty", '-icanon', 'eol', "\001";
1782     }
1783
1784     $key = getc(STDIN);
1785
1786     if ($BSD_STYLE) {
1787         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1788     }
1789     else {
1790         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1791     }
1792     print "\n";
1793
1794 Determination of whether $BSD_STYLE should be set
1795 is left as an exercise to the reader.
1796
1797 The C<POSIX::getattr> function can do this more portably on
1798 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1799 module from your nearest CPAN site; details on CPAN can be found on
1800 L<perlmodlib/CPAN>.
1801
1802 =item getlogin
1803
1804 Implements the C library function of the same name, which on most
1805 systems returns the current login from F</etc/utmp>, if any.  If null,
1806 use C<getpwuid>.
1807
1808     $login = getlogin || getpwuid($<) || "Kilroy";
1809
1810 Do not consider C<getlogin> for authentication: it is not as
1811 secure as C<getpwuid>.
1812
1813 =item getpeername SOCKET
1814
1815 Returns the packed sockaddr address of other end of the SOCKET connection.
1816
1817     use Socket;
1818     $hersockaddr    = getpeername(SOCK);
1819     ($port, $iaddr) = sockaddr_in($hersockaddr);
1820     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1821     $herstraddr     = inet_ntoa($iaddr);
1822
1823 =item getpgrp PID
1824
1825 Returns the current process group for the specified PID.  Use
1826 a PID of C<0> to get the current process group for the
1827 current process.  Will raise an exception if used on a machine that
1828 doesn't implement getpgrp(2).  If PID is omitted, returns process
1829 group of current process.  Note that the POSIX version of C<getpgrp>
1830 does not accept a PID argument, so only C<PID==0> is truly portable.
1831
1832 =item getppid
1833
1834 Returns the process id of the parent process.
1835
1836 =item getpriority WHICH,WHO
1837
1838 Returns the current priority for a process, a process group, or a user.
1839 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1840 machine that doesn't implement getpriority(2).
1841
1842 =item getpwnam NAME
1843
1844 =item getgrnam NAME
1845
1846 =item gethostbyname NAME
1847
1848 =item getnetbyname NAME
1849
1850 =item getprotobyname NAME
1851
1852 =item getpwuid UID
1853
1854 =item getgrgid GID
1855
1856 =item getservbyname NAME,PROTO
1857
1858 =item gethostbyaddr ADDR,ADDRTYPE
1859
1860 =item getnetbyaddr ADDR,ADDRTYPE
1861
1862 =item getprotobynumber NUMBER
1863
1864 =item getservbyport PORT,PROTO
1865
1866 =item getpwent
1867
1868 =item getgrent
1869
1870 =item gethostent
1871
1872 =item getnetent
1873
1874 =item getprotoent
1875
1876 =item getservent
1877
1878 =item setpwent
1879
1880 =item setgrent
1881
1882 =item sethostent STAYOPEN
1883
1884 =item setnetent STAYOPEN
1885
1886 =item setprotoent STAYOPEN
1887
1888 =item setservent STAYOPEN
1889
1890 =item endpwent
1891
1892 =item endgrent
1893
1894 =item endhostent
1895
1896 =item endnetent
1897
1898 =item endprotoent
1899
1900 =item endservent
1901
1902 These routines perform the same functions as their counterparts in the
1903 system library.  In list context, the return values from the
1904 various get routines are as follows:
1905
1906     ($name,$passwd,$uid,$gid,
1907        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1908     ($name,$passwd,$gid,$members) = getgr*
1909     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1910     ($name,$aliases,$addrtype,$net) = getnet*
1911     ($name,$aliases,$proto) = getproto*
1912     ($name,$aliases,$port,$proto) = getserv*
1913
1914 (If the entry doesn't exist you get a null list.)
1915
1916 The exact meaning of the $gcos field varies but it usually contains
1917 the real name of the user (as opposed to the login name) and other
1918 information pertaining to the user.  Beware, however, that in many
1919 system users are able to change this information and therefore it
1920 cannot be trusted and therefore the $gcos is tainted (see
1921 L<perlsec>).  The $passwd and $shell, user's encrypted password and
1922 login shell, are also tainted, because of the same reason.
1923
1924 In scalar context, you get the name, unless the function was a
1925 lookup by name, in which case you get the other thing, whatever it is.
1926 (If the entry doesn't exist you get the undefined value.)  For example:
1927
1928     $uid   = getpwnam($name);
1929     $name  = getpwuid($num);
1930     $name  = getpwent();
1931     $gid   = getgrnam($name);
1932     $name  = getgrgid($num;
1933     $name  = getgrent();
1934     #etc.
1935
1936 In I<getpw*()> the fields $quota, $comment, and $expire are special
1937 cases in the sense that in many systems they are unsupported.  If the
1938 $quota is unsupported, it is an empty scalar.  If it is supported, it
1939 usually encodes the disk quota.  If the $comment field is unsupported,
1940 it is an empty scalar.  If it is supported it usually encodes some
1941 administrative comment about the user.  In some systems the $quota
1942 field may be $change or $age, fields that have to do with password
1943 aging.  In some systems the $comment field may be $class.  The $expire
1944 field, if present, encodes the expiration period of the account or the
1945 password.  For the availability and the exact meaning of these fields
1946 in your system, please consult your getpwnam(3) documentation and your
1947 F<pwd.h> file.  You can also find out from within Perl what your
1948 $quota and $comment fields mean and whether you have the $expire field
1949 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1950 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
1951 files are only supported if your vendor has implemented them in the
1952 intuitive fashion that calling the regular C library routines gets the
1953 shadow versions if you're running under privilege or if there exists
1954 the shadow(3) functions as found in System V ( this includes Solaris
1955 and Linux.)  Those systems which implement a proprietary shadow password
1956 facility are unlikely to be supported.
1957
1958 The $members value returned by I<getgr*()> is a space separated list of
1959 the login names of the members of the group.
1960
1961 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1962 C, it will be returned to you via C<$?> if the function call fails.  The
1963 C<@addrs> value returned by a successful call is a list of the raw
1964 addresses returned by the corresponding system library call.  In the
1965 Internet domain, each address is four bytes long and you can unpack it
1966 by saying something like:
1967
1968     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1969
1970 The Socket library makes this slightly easier:
1971
1972     use Socket;
1973     $iaddr = inet_aton("127.1"); # or whatever address
1974     $name  = gethostbyaddr($iaddr, AF_INET);
1975
1976     # or going the other way
1977     $straddr = inet_ntoa($iaddr);
1978
1979 If you get tired of remembering which element of the return list
1980 contains which return value, by-name interfaces are provided
1981 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1982 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1983 and C<User::grent>.  These override the normal built-ins, supplying
1984 versions that return objects with the appropriate names
1985 for each field.  For example:
1986
1987    use File::stat;
1988    use User::pwent;
1989    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1990
1991 Even though it looks like they're the same method calls (uid),
1992 they aren't, because a C<File::stat> object is different from
1993 a C<User::pwent> object.
1994
1995 =item getsockname SOCKET
1996
1997 Returns the packed sockaddr address of this end of the SOCKET connection,
1998 in case you don't know the address because you have several different
1999 IPs that the connection might have come in on.
2000
2001     use Socket;
2002     $mysockaddr = getsockname(SOCK);
2003     ($port, $myaddr) = sockaddr_in($mysockaddr);
2004     printf "Connect to %s [%s]\n",
2005        scalar gethostbyaddr($myaddr, AF_INET),
2006        inet_ntoa($myaddr);
2007
2008 =item getsockopt SOCKET,LEVEL,OPTNAME
2009
2010 Returns the socket option requested, or undef if there is an error.
2011
2012 =item glob EXPR
2013
2014 =item glob
2015
2016 Returns the value of EXPR with filename expansions such as the
2017 standard Unix shell F</bin/csh> would do.  This is the internal function
2018 implementing the C<< <*.c> >> operator, but you can use it directly.
2019 If EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is
2020 discussed in more detail in L<perlop/"I/O Operators">.
2021
2022 Beginning with v5.6.0, this operator is implemented using the standard
2023 C<File::Glob> extension.  See L<File::Glob> for details.
2024
2025 =item gmtime EXPR
2026
2027 Converts a time as returned by the time function to an 8-element list
2028 with the time localized for the standard Greenwich time zone.
2029 Typically used as follows:
2030
2031     #  0    1    2     3     4    5     6     7
2032     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2033                                             gmtime(time);
2034
2035 All list elements are numeric, and come straight out of the C `struct
2036 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2037 specified time.  $mday is the day of the month, and $mon is the month
2038 itself, in the range C<0..11> with 0 indicating January and 11
2039 indicating December.  $year is the number of years since 1900.  That
2040 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2041 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2042 the year, in the range C<0..364> (or C<0..365> in leap years.)
2043
2044 Note that the $year element is I<not> simply the last two digits of
2045 the year.  If you assume it is, then you create non-Y2K-compliant
2046 programs--and you wouldn't want to do that, would you?
2047
2048 The proper way to get a complete 4-digit year is simply:
2049
2050         $year += 1900;
2051
2052 And to get the last two digits of the year (e.g., '01' in 2001) do:
2053
2054         $year = sprintf("%02d", $year % 100);
2055
2056 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2057
2058 In scalar context, C<gmtime()> returns the ctime(3) value:
2059
2060     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2061
2062 Also see the C<timegm> function provided by the C<Time::Local> module,
2063 and the strftime(3) function available via the POSIX module.
2064
2065 This scalar value is B<not> locale dependent (see L<perllocale>), but
2066 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2067 strftime(3) and mktime(3) functions available via the POSIX module.  To
2068 get somewhat similar but locale dependent date strings, set up your
2069 locale environment variables appropriately (please see L<perllocale>)
2070 and try for example:
2071
2072     use POSIX qw(strftime);
2073     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2074
2075 Note that the C<%a> and C<%b> escapes, which represent the short forms
2076 of the day of the week and the month of the year, may not necessarily
2077 be three characters wide in all locales.
2078
2079 =item goto LABEL
2080
2081 =item goto EXPR
2082
2083 =item goto &NAME
2084
2085 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2086 execution there.  It may not be used to go into any construct that
2087 requires initialization, such as a subroutine or a C<foreach> loop.  It
2088 also can't be used to go into a construct that is optimized away,
2089 or to get out of a block or subroutine given to C<sort>.
2090 It can be used to go almost anywhere else within the dynamic scope,
2091 including out of subroutines, but it's usually better to use some other
2092 construct such as C<last> or C<die>.  The author of Perl has never felt the
2093 need to use this form of C<goto> (in Perl, that is--C is another matter).
2094 (The difference being that C does not offer named loops combined with
2095 loop control.  Perl does, and this replaces most structured uses of C<goto>
2096 in other languages.)
2097
2098 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2099 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2100 necessarily recommended if you're optimizing for maintainability:
2101
2102     goto ("FOO", "BAR", "GLARCH")[$i];
2103
2104 The C<goto-&NAME> form is quite different from the other forms of
2105 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2106 doesn't have the stigma associated with other gotos.  Instead, it
2107 exits the current subroutine (losing any changes set by local()) and
2108 immediately calls in its place the named subroutine using the current
2109 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2110 load another subroutine and then pretend that the other subroutine had
2111 been called in the first place (except that any modifications to C<@_>
2112 in the current subroutine are propagated to the other subroutine.)
2113 After the C<goto>, not even C<caller> will be able to tell that this
2114 routine was called first.
2115
2116 NAME needn't be the name of a subroutine; it can be a scalar variable
2117 containing a code reference, or a block which evaluates to a code
2118 reference.
2119
2120 =item grep BLOCK LIST
2121
2122 =item grep EXPR,LIST
2123
2124 This is similar in spirit to, but not the same as, grep(1) and its
2125 relatives.  In particular, it is not limited to using regular expressions.
2126
2127 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2128 C<$_> to each element) and returns the list value consisting of those
2129 elements for which the expression evaluated to true.  In scalar
2130 context, returns the number of times the expression was true.
2131
2132     @foo = grep(!/^#/, @bar);    # weed out comments
2133
2134 or equivalently,
2135
2136     @foo = grep {!/^#/} @bar;    # weed out comments
2137
2138 Note that C<$_> is an alias to the list value, so it can be used to
2139 modify the elements of the LIST.  While this is useful and supported,
2140 it can cause bizarre results if the elements of LIST are not variables.
2141 Similarly, grep returns aliases into the original list, much as a for
2142 loop's index variable aliases the list elements.  That is, modifying an
2143 element of a list returned by grep (for example, in a C<foreach>, C<map>
2144 or another C<grep>) actually modifies the element in the original list.
2145 This is usually something to be avoided when writing clear code.
2146
2147 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2148
2149 =item hex EXPR
2150
2151 =item hex
2152
2153 Interprets EXPR as a hex string and returns the corresponding value.
2154 (To convert strings that might start with either 0, 0x, or 0b, see
2155 L</oct>.)  If EXPR is omitted, uses C<$_>.
2156
2157     print hex '0xAf'; # prints '175'
2158     print hex 'aF';   # same
2159
2160 Hex strings may only represent integers.  Strings that would cause
2161 integer overflow trigger a warning.  Leading whitespace is not stripped,
2162 unlike oct().
2163
2164 =item import
2165
2166 There is no builtin C<import> function.  It is just an ordinary
2167 method (subroutine) defined (or inherited) by modules that wish to export
2168 names to another module.  The C<use> function calls the C<import> method
2169 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2170
2171 =item index STR,SUBSTR,POSITION
2172
2173 =item index STR,SUBSTR
2174
2175 The index function searches for one string within another, but without
2176 the wildcard-like behavior of a full regular-expression pattern match.
2177 It returns the position of the first occurrence of SUBSTR in STR at
2178 or after POSITION.  If POSITION is omitted, starts searching from the
2179 beginning of the string.  The return value is based at C<0> (or whatever
2180 you've set the C<$[> variable to--but don't do that).  If the substring
2181 is not found, returns one less than the base, ordinarily C<-1>.
2182
2183 =item int EXPR
2184
2185 =item int
2186
2187 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2188 You should not use this function for rounding: one because it truncates
2189 towards C<0>, and two because machine representations of floating point
2190 numbers can sometimes produce counterintuitive results.  For example,
2191 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2192 because it's really more like -268.99999999999994315658 instead.  Usually,
2193 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2194 functions will serve you better than will int().
2195
2196 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2197
2198 Implements the ioctl(2) function.  You'll probably first have to say
2199
2200     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2201
2202 to get the correct function definitions.  If F<ioctl.ph> doesn't
2203 exist or doesn't have the correct definitions you'll have to roll your
2204 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2205 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2206 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2207 written depending on the FUNCTION--a pointer to the string value of SCALAR
2208 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2209 has no string value but does have a numeric value, that value will be
2210 passed rather than a pointer to the string value.  To guarantee this to be
2211 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2212 functions may be needed to manipulate the values of structures used by
2213 C<ioctl>.
2214
2215 The return value of C<ioctl> (and C<fcntl>) is as follows:
2216
2217         if OS returns:          then Perl returns:
2218             -1                    undefined value
2219              0                  string "0 but true"
2220         anything else               that number
2221
2222 Thus Perl returns true on success and false on failure, yet you can
2223 still easily determine the actual value returned by the operating
2224 system:
2225
2226     $retval = ioctl(...) || -1;
2227     printf "System returned %d\n", $retval;
2228
2229 The special string "C<0> but true" is exempt from B<-w> complaints
2230 about improper numeric conversions.
2231
2232 Here's an example of setting a filehandle named C<REMOTE> to be
2233 non-blocking at the system level.  You'll have to negotiate C<$|>
2234 on your own, though.
2235
2236     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2237
2238     $flags = fcntl(REMOTE, F_GETFL, 0)
2239                 or die "Can't get flags for the socket: $!\n";
2240
2241     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2242                 or die "Can't set flags for the socket: $!\n";
2243
2244 =item join EXPR,LIST
2245
2246 Joins the separate strings of LIST into a single string with fields
2247 separated by the value of EXPR, and returns that new string.  Example:
2248
2249     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2250
2251 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2252 first argument.  Compare L</split>.
2253
2254 =item keys HASH
2255
2256 Returns a list consisting of all the keys of the named hash.  (In
2257 scalar context, returns the number of keys.)  The keys are returned in
2258 an apparently random order.  The actual random order is subject to
2259 change in future versions of perl, but it is guaranteed to be the same
2260 order as either the C<values> or C<each> function produces (given
2261 that the hash has not been modified).  As a side effect, it resets
2262 HASH's iterator.
2263
2264 Here is yet another way to print your environment:
2265
2266     @keys = keys %ENV;
2267     @values = values %ENV;
2268     while (@keys) {
2269         print pop(@keys), '=', pop(@values), "\n";
2270     }
2271
2272 or how about sorted by key:
2273
2274     foreach $key (sort(keys %ENV)) {
2275         print $key, '=', $ENV{$key}, "\n";
2276     }
2277
2278 The returned values are copies of the original keys in the hash, so
2279 modifying them will not affect the original hash.  Compare L</values>.
2280
2281 To sort a hash by value, you'll need to use a C<sort> function.
2282 Here's a descending numeric sort of a hash by its values:
2283
2284     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2285         printf "%4d %s\n", $hash{$key}, $key;
2286     }
2287
2288 As an lvalue C<keys> allows you to increase the number of hash buckets
2289 allocated for the given hash.  This can gain you a measure of efficiency if
2290 you know the hash is going to get big.  (This is similar to pre-extending
2291 an array by assigning a larger number to $#array.)  If you say
2292
2293     keys %hash = 200;
2294
2295 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2296 in fact, since it rounds up to the next power of two.  These
2297 buckets will be retained even if you do C<%hash = ()>, use C<undef
2298 %hash> if you want to free the storage while C<%hash> is still in scope.
2299 You can't shrink the number of buckets allocated for the hash using
2300 C<keys> in this way (but you needn't worry about doing this by accident,
2301 as trying has no effect).
2302
2303 See also C<each>, C<values> and C<sort>.
2304
2305 =item kill SIGNAL, LIST
2306
2307 Sends a signal to a list of processes.  Returns the number of
2308 processes successfully signaled (which is not necessarily the
2309 same as the number actually killed).
2310
2311     $cnt = kill 1, $child1, $child2;
2312     kill 9, @goners;
2313
2314 If SIGNAL is zero, no signal is sent to the process.  This is a
2315 useful way to check that the process is alive and hasn't changed
2316 its UID.  See L<perlport> for notes on the portability of this
2317 construct.
2318
2319 Unlike in the shell, if SIGNAL is negative, it kills
2320 process groups instead of processes.  (On System V, a negative I<PROCESS>
2321 number will also kill process groups, but that's not portable.)  That
2322 means you usually want to use positive not negative signals.  You may also
2323 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2324
2325 =item last LABEL
2326
2327 =item last
2328
2329 The C<last> command is like the C<break> statement in C (as used in
2330 loops); it immediately exits the loop in question.  If the LABEL is
2331 omitted, the command refers to the innermost enclosing loop.  The
2332 C<continue> block, if any, is not executed:
2333
2334     LINE: while (<STDIN>) {
2335         last LINE if /^$/;      # exit when done with header
2336         #...
2337     }
2338
2339 C<last> cannot be used to exit a block which returns a value such as
2340 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2341 a grep() or map() operation.
2342
2343 Note that a block by itself is semantically identical to a loop
2344 that executes once.  Thus C<last> can be used to effect an early
2345 exit out of such a block.
2346
2347 See also L</continue> for an illustration of how C<last>, C<next>, and
2348 C<redo> work.
2349
2350 =item lc EXPR
2351
2352 =item lc
2353
2354 Returns a lowercased version of EXPR.  This is the internal function
2355 implementing the C<\L> escape in double-quoted strings.  Respects
2356 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2357 and L<perlunicode> for more details about locale and Unicode support.
2358
2359 If EXPR is omitted, uses C<$_>.
2360
2361 =item lcfirst EXPR
2362
2363 =item lcfirst
2364
2365 Returns the value of EXPR with the first character lowercased.  This
2366 is the internal function implementing the C<\l> escape in
2367 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2368 locale> in force.  See L<perllocale> and L<perlunicode> for more
2369 details about locale and Unicode support.
2370
2371 If EXPR is omitted, uses C<$_>.
2372
2373 =item length EXPR
2374
2375 =item length
2376
2377 Returns the length in characters of the value of EXPR.  If EXPR is
2378 omitted, returns length of C<$_>.  Note that this cannot be used on
2379 an entire array or hash to find out how many elements these have.
2380 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2381
2382 =item link OLDFILE,NEWFILE
2383
2384 Creates a new filename linked to the old filename.  Returns true for
2385 success, false otherwise.
2386
2387 =item listen SOCKET,QUEUESIZE
2388
2389 Does the same thing that the listen system call does.  Returns true if
2390 it succeeded, false otherwise.  See the example in
2391 L<perlipc/"Sockets: Client/Server Communication">.
2392
2393 =item local EXPR
2394
2395 You really probably want to be using C<my> instead, because C<local> isn't
2396 what most people think of as "local".  See
2397 L<perlsub/"Private Variables via my()"> for details.
2398
2399 A local modifies the listed variables to be local to the enclosing
2400 block, file, or eval.  If more than one value is listed, the list must
2401 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2402 for details, including issues with tied arrays and hashes.
2403
2404 =item localtime EXPR
2405
2406 Converts a time as returned by the time function to a 9-element list
2407 with the time analyzed for the local time zone.  Typically used as
2408 follows:
2409
2410     #  0    1    2     3     4    5     6     7     8
2411     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2412                                                 localtime(time);
2413
2414 All list elements are numeric, and come straight out of the C `struct
2415 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2416 specified time.  $mday is the day of the month, and $mon is the month
2417 itself, in the range C<0..11> with 0 indicating January and 11
2418 indicating December.  $year is the number of years since 1900.  That
2419 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2420 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2421 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2422 is true if the specified time occurs during daylight savings time,
2423 false otherwise.
2424
2425 Note that the $year element is I<not> simply the last two digits of
2426 the year.  If you assume it is, then you create non-Y2K-compliant
2427 programs--and you wouldn't want to do that, would you?
2428
2429 The proper way to get a complete 4-digit year is simply:
2430
2431         $year += 1900;
2432
2433 And to get the last two digits of the year (e.g., '01' in 2001) do:
2434
2435         $year = sprintf("%02d", $year % 100);
2436
2437 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2438
2439 In scalar context, C<localtime()> returns the ctime(3) value:
2440
2441     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2442
2443 This scalar value is B<not> locale dependent, see L<perllocale>, but
2444 instead a Perl builtin.  Also see the C<Time::Local> module
2445 (to convert the second, minutes, hours, ... back to seconds since the
2446 stroke of midnight the 1st of January 1970, the value returned by
2447 time()), and the strftime(3) and mktime(3) functions available via the
2448 POSIX module.  To get somewhat similar but locale dependent date
2449 strings, set up your locale environment variables appropriately
2450 (please see L<perllocale>) and try for example:
2451
2452     use POSIX qw(strftime);
2453     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2454
2455 Note that the C<%a> and C<%b>, the short forms of the day of the week
2456 and the month of the year, may not necessarily be three characters wide.
2457
2458 =item lock THING
2459
2460 This function places an advisory lock on a variable, subroutine,
2461 or referenced object contained in I<THING> until the lock goes out
2462 of scope.  This is a built-in function only if your version of Perl
2463 was built with threading enabled, and if you've said C<use Thread>.
2464 Otherwise a user-defined function by this name will be called.
2465 See L<Thread>.
2466
2467 =item log EXPR
2468
2469 =item log
2470
2471 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2472 returns log of C<$_>.  To get the log of another base, use basic algebra:
2473 The base-N log of a number is equal to the natural log of that number
2474 divided by the natural log of N.  For example:
2475
2476     sub log10 {
2477         my $n = shift;
2478         return log($n)/log(10);
2479     }
2480
2481 See also L</exp> for the inverse operation.
2482
2483 =item lstat EXPR
2484
2485 =item lstat
2486
2487 Does the same thing as the C<stat> function (including setting the
2488 special C<_> filehandle) but stats a symbolic link instead of the file
2489 the symbolic link points to.  If symbolic links are unimplemented on
2490 your system, a normal C<stat> is done.
2491
2492 If EXPR is omitted, stats C<$_>.
2493
2494 =item m//
2495
2496 The match operator.  See L<perlop>.
2497
2498 =item map BLOCK LIST
2499
2500 =item map EXPR,LIST
2501
2502 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2503 C<$_> to each element) and returns the list value composed of the
2504 results of each such evaluation.  In scalar context, returns the
2505 total number of elements so generated.  Evaluates BLOCK or EXPR in
2506 list context, so each element of LIST may produce zero, one, or
2507 more elements in the returned value.
2508
2509     @chars = map(chr, @nums);
2510
2511 translates a list of numbers to the corresponding characters.  And
2512
2513     %hash = map { getkey($_) => $_ } @array;
2514
2515 is just a funny way to write
2516
2517     %hash = ();
2518     foreach $_ (@array) {
2519         $hash{getkey($_)} = $_;
2520     }
2521
2522 Note that C<$_> is an alias to the list value, so it can be used to
2523 modify the elements of the LIST.  While this is useful and supported,
2524 it can cause bizarre results if the elements of LIST are not variables.
2525 Using a regular C<foreach> loop for this purpose would be clearer in
2526 most cases.  See also L</grep> for an array composed of those items of
2527 the original list for which the BLOCK or EXPR evaluates to true.
2528
2529 C<{> starts both hash references and blocks, so C<map { ...> could be either
2530 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2531 ahead for the closing C<}> it has to take a guess at which its dealing with
2532 based what it finds just after the C<{>. Usually it gets it right, but if it
2533 doesn't it won't realize something is wrong until it gets to the C<}> and
2534 encounters the missing (or unexpected) comma. The syntax error will be
2535 reported close to the C<}> but you'll need to change something near the C<{>
2536 such as using a unary C<+> to give perl some help:
2537
2538     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2539     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2540     %hash = map { ("\L$_", 1) } @array  # this also works
2541     %hash = map {  lc($_), 1  } @array  # as does this.
2542     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2543
2544     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2545
2546 or to force an anon hash constructor use C<+{>
2547
2548    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2549
2550 and you get list of anonymous hashes each with only 1 entry.
2551
2552 =item mkdir FILENAME,MASK
2553
2554 =item mkdir FILENAME
2555
2556 Creates the directory specified by FILENAME, with permissions
2557 specified by MASK (as modified by C<umask>).  If it succeeds it
2558 returns true, otherwise it returns false and sets C<$!> (errno).
2559 If omitted, MASK defaults to 0777.
2560
2561 In general, it is better to create directories with permissive MASK,
2562 and let the user modify that with their C<umask>, than it is to supply
2563 a restrictive MASK and give the user no way to be more permissive.
2564 The exceptions to this rule are when the file or directory should be
2565 kept private (mail files, for instance).  The perlfunc(1) entry on
2566 C<umask> discusses the choice of MASK in more detail.
2567
2568 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2569 number of trailing slashes.  Some operating and filesystems do not get
2570 this right, so Perl automatically removes all trailing slashes to keep
2571 everyone happy.
2572
2573 =item msgctl ID,CMD,ARG
2574
2575 Calls the System V IPC function msgctl(2).  You'll probably have to say
2576
2577     use IPC::SysV;
2578
2579 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2580 then ARG must be a variable which will hold the returned C<msqid_ds>
2581 structure.  Returns like C<ioctl>: the undefined value for error,
2582 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2583 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2584
2585 =item msgget KEY,FLAGS
2586
2587 Calls the System V IPC function msgget(2).  Returns the message queue
2588 id, or the undefined value if there is an error.  See also
2589 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2590
2591 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2592
2593 Calls the System V IPC function msgrcv to receive a message from
2594 message queue ID into variable VAR with a maximum message size of
2595 SIZE.  Note that when a message is received, the message type as a
2596 native long integer will be the first thing in VAR, followed by the
2597 actual message.  This packing may be opened with C<unpack("l! a*")>.
2598 Taints the variable.  Returns true if successful, or false if there is
2599 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2600 C<IPC::SysV::Msg> documentation.
2601
2602 =item msgsnd ID,MSG,FLAGS
2603
2604 Calls the System V IPC function msgsnd to send the message MSG to the
2605 message queue ID.  MSG must begin with the native long integer message
2606 type, and be followed by the length of the actual message, and finally
2607 the message itself.  This kind of packing can be achieved with
2608 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2609 or false if there is an error.  See also C<IPC::SysV>
2610 and C<IPC::SysV::Msg> documentation.
2611
2612 =item my EXPR
2613
2614 =item my EXPR : ATTRIBUTES
2615
2616 A C<my> declares the listed variables to be local (lexically) to the
2617 enclosing block, file, or C<eval>.  If
2618 more than one value is listed, the list must be placed in parentheses.  See
2619 L<perlsub/"Private Variables via my()"> for details.
2620
2621 =item next LABEL
2622
2623 =item next
2624
2625 The C<next> command is like the C<continue> statement in C; it starts
2626 the next iteration of the loop:
2627
2628     LINE: while (<STDIN>) {
2629         next LINE if /^#/;      # discard comments
2630         #...
2631     }
2632
2633 Note that if there were a C<continue> block on the above, it would get
2634 executed even on discarded lines.  If the LABEL is omitted, the command
2635 refers to the innermost enclosing loop.
2636
2637 C<next> cannot be used to exit a block which returns a value such as
2638 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2639 a grep() or map() operation.
2640
2641 Note that a block by itself is semantically identical to a loop
2642 that executes once.  Thus C<next> will exit such a block early.
2643
2644 See also L</continue> for an illustration of how C<last>, C<next>, and
2645 C<redo> work.
2646
2647 =item no Module LIST
2648
2649 See the L</use> function, which C<no> is the opposite of.
2650
2651 =item oct EXPR
2652
2653 =item oct
2654
2655 Interprets EXPR as an octal string and returns the corresponding
2656 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2657 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2658 binary string.  Leading whitespace is ignored in all three cases.)
2659 The following will handle decimal, binary, octal, and hex in the standard
2660 Perl or C notation:
2661
2662     $val = oct($val) if $val =~ /^0/;
2663
2664 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2665 in octal), use sprintf() or printf():
2666
2667     $perms = (stat("filename"))[2] & 07777;
2668     $oct_perms = sprintf "%lo", $perms;
2669
2670 The oct() function is commonly used when a string such as C<644> needs
2671 to be converted into a file mode, for example. (Although perl will
2672 automatically convert strings into numbers as needed, this automatic
2673 conversion assumes base 10.)
2674
2675 =item open FILEHANDLE,EXPR
2676
2677 =item open FILEHANDLE,MODE,EXPR
2678
2679 =item open FILEHANDLE,MODE,EXPR,LIST
2680
2681 =item open FILEHANDLE,MODE,REFERENCE
2682
2683 =item open FILEHANDLE
2684
2685 Opens the file whose filename is given by EXPR, and associates it with
2686 FILEHANDLE.
2687
2688 (The following is a comprehensive reference to open(): for a gentler
2689 introduction you may consider L<perlopentut>.)
2690
2691 If FILEHANDLE is an undefined lexical (C<my>) variable the variable is
2692 assigned a reference to a new anonymous filehandle, otherwise if
2693 FILEHANDLE is an expression, its value is used as the name of the real
2694 filehandle wanted.  (This is considered a symbolic reference, so C<use
2695 strict 'refs'> should I<not> be in effect.)
2696
2697 If EXPR is omitted, the scalar variable of the same name as the
2698 FILEHANDLE contains the filename.  (Note that lexical variables--those
2699 declared with C<my>--will not work for this purpose; so if you're
2700 using C<my>, specify EXPR in your call to open.) 
2701
2702 If three or more arguments are specified then the mode of opening and
2703 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2704 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2705 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2706 the file is opened for appending, again being created if necessary.
2707
2708 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2709 indicate that you want both read and write access to the file; thus
2710 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2711 '+>' >> mode would clobber the file first.  You can't usually use
2712 either read-write mode for updating textfiles, since they have
2713 variable length records.  See the B<-i> switch in L<perlrun> for a
2714 better approach.  The file is created with permissions of C<0666>
2715 modified by the process' C<umask> value.
2716
2717 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2718 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2719
2720 In the 2-arguments (and 1-argument) form of the call the mode and
2721 filename should be concatenated (in this order), possibly separated by
2722 spaces.  It is possible to omit the mode in these forms if the mode is
2723 C<< '<' >>.
2724
2725 If the filename begins with C<'|'>, the filename is interpreted as a
2726 command to which output is to be piped, and if the filename ends with a
2727 C<'|'>, the filename is interpreted as a command which pipes output to
2728 us.  See L<perlipc/"Using open() for IPC">
2729 for more examples of this.  (You are not allowed to C<open> to a command
2730 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2731 and L<perlipc/"Bidirectional Communication with Another Process">
2732 for alternatives.)
2733
2734 For three or more arguments if MODE is C<'|-'>, the filename is
2735 interpreted as a command to which output is to be piped, and if MODE
2736 is C<'-|'>, the filename is interpreted as a command which pipes
2737 output to us.  In the 2-arguments (and 1-argument) form one should
2738 replace dash (C<'-'>) with the command.
2739 See L<perlipc/"Using open() for IPC"> for more examples of this.
2740 (You are not allowed to C<open> to a command that pipes both in I<and>
2741 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2742 L<perlipc/"Bidirectional Communication"> for alternatives.)
2743
2744 In the three-or-more argument form of pipe opens, if LIST is specified
2745 (extra arguments after the command name) then LIST becomes arguments
2746 to the command invoked if the platform supports it.  The meaning of
2747 C<open> with more than three arguments for non-pipe modes is not yet
2748 specified. Experimental "layers" may give extra LIST arguments
2749 meaning.
2750
2751 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2752 and opening C<< '>-' >> opens STDOUT.
2753
2754 You may use the three-argument form of open to specify
2755 I<I/O disciplines> that affect how the input and output
2756 are processed: see L</binmode> and L<open>.  For example
2757
2758   open(FH, "<:utf8", "file")
2759
2760 will open the UTF-8 encoded file containing Unicode characters,
2761 see L<perluniintro>.
2762
2763 Open returns nonzero upon success, the undefined value otherwise.  If
2764 the C<open> involved a pipe, the return value happens to be the pid of
2765 the subprocess.
2766
2767 If you're running Perl on a system that distinguishes between text
2768 files and binary files, then you should check out L</binmode> for tips
2769 for dealing with this.  The key distinction between systems that need
2770 C<binmode> and those that don't is their text file formats.  Systems
2771 like Unix, MacOS, and Plan9, which delimit lines with a single
2772 character, and which encode that character in C as C<"\n">, do not
2773 need C<binmode>.  The rest need it.
2774
2775 In the three argument form MODE may also contain a list of IO "layers"
2776 (see L<open> and L<PerlIO> for more details) to be applied to the
2777 handle. This can be used to achieve the effect of C<binmode> as well
2778 as more complex behaviours.
2779
2780 When opening a file, it's usually a bad idea to continue normal execution
2781 if the request failed, so C<open> is frequently used in connection with
2782 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2783 where you want to make a nicely formatted error message (but there are
2784 modules that can help with that problem)) you should always check
2785 the return value from opening a file.  The infrequent exception is when
2786 working with an unopened filehandle is actually what you want to do.
2787
2788 As a special case the 3 arg form with a read/write mode and the third
2789 argument being C<undef>:
2790
2791     open(TMP, "+>", undef) or die ...
2792
2793 opens a filehandle to an anonymous temporary file.
2794
2795 File handles can be opened to "in memory" files held in Perl scalars via:
2796
2797     open($fh,'>', \$variable) || ..
2798
2799 Examples:
2800
2801     $ARTICLE = 100;
2802     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2803     while (<ARTICLE>) {...
2804
2805     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2806     # if the open fails, output is discarded
2807
2808     open(DBASE, '+<', 'dbase.mine')             # open for update
2809         or die "Can't open 'dbase.mine' for update: $!";
2810
2811     open(DBASE, '+<dbase.mine')                 # ditto
2812         or die "Can't open 'dbase.mine' for update: $!";
2813
2814     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2815         or die "Can't start caesar: $!";
2816
2817     open(ARTICLE, "caesar <$article |")         # ditto
2818         or die "Can't start caesar: $!";
2819
2820     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2821         or die "Can't start sort: $!";
2822
2823     # in memory files
2824     open(MEMORY,'>', \$var)
2825         or die "Can't open memory file: $!";
2826     print MEMORY "foo!\n";                      # output will end up in $var
2827
2828     # process argument list of files along with any includes
2829
2830     foreach $file (@ARGV) {
2831         process($file, 'fh00');
2832     }
2833
2834     sub process {
2835         my($filename, $input) = @_;
2836         $input++;               # this is a string increment
2837         unless (open($input, $filename)) {
2838             print STDERR "Can't open $filename: $!\n";
2839             return;
2840         }
2841
2842         local $_;
2843         while (<$input>) {              # note use of indirection
2844             if (/^#include "(.*)"/) {
2845                 process($1, $input);
2846                 next;
2847             }
2848             #...                # whatever
2849         }
2850     }
2851
2852 You may also, in the Bourne shell tradition, specify an EXPR beginning
2853 with C<< '>&' >>, in which case the rest of the string is interpreted as the
2854 name of a filehandle (or file descriptor, if numeric) to be
2855 duped and opened.  You may use C<&> after C<< > >>, C<<< >> >>>,
2856 C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.  The
2857 mode you specify should match the mode of the original filehandle.
2858 (Duping a filehandle does not take into account any existing contents of
2859 IO buffers.) If you use the 3 arg form then you can pass either a number,
2860 the name of a filehandle or the normal "reference to a glob".
2861
2862 Here is a script that saves, redirects, and restores STDOUT and
2863 STDERR:
2864
2865     #!/usr/bin/perl
2866     open(my $oldout, ">&", \*STDOUT);
2867     open(OLDERR, ">&STDERR");
2868
2869     open(STDOUT, '>', "foo.out") || die "Can't redirect stdout";
2870     open(STDERR, ">&STDOUT")     || die "Can't dup stdout";
2871
2872     select(STDERR); $| = 1;     # make unbuffered
2873     select(STDOUT); $| = 1;     # make unbuffered
2874
2875     print STDOUT "stdout 1\n";  # this works for
2876     print STDERR "stderr 1\n";  # subprocesses too
2877
2878     close(STDOUT);
2879     close(STDERR);
2880
2881     open(STDOUT, ">&OLDOUT");
2882     open(STDERR, ">&OLDERR");
2883
2884     print STDOUT "stdout 2\n";
2885     print STDERR "stderr 2\n";
2886
2887 If you specify C<< '<&=N' >>, where C<N> is a number, then Perl will
2888 do an equivalent of C's C<fdopen> of that file descriptor; this is
2889 more parsimonious of file descriptors.  For example:
2890
2891     open(FILEHANDLE, "<&=$fd")
2892
2893 or
2894
2895     open(FILEHANDLE, "<&=", $fd)
2896
2897 Note that if Perl is using the standard C libraries' fdopen() then on
2898 many UNIX systems, fdopen() is known to fail when file descriptors
2899 exceed a certain value, typically 255. If you need more file
2900 descriptors than that, consider rebuilding Perl to use the C<PerlIO>.
2901
2902 You can see whether Perl has been compiled with PerlIO or not by
2903 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
2904 is C<define>, you have PerlIO, otherwise you don't.
2905
2906 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2907 with 2-arguments (or 1-argument) form of open(), then
2908 there is an implicit fork done, and the return value of open is the pid
2909 of the child within the parent process, and C<0> within the child
2910 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2911 The filehandle behaves normally for the parent, but i/o to that
2912 filehandle is piped from/to the STDOUT/STDIN of the child process.
2913 In the child process the filehandle isn't opened--i/o happens from/to
2914 the new STDOUT or STDIN.  Typically this is used like the normal
2915 piped open when you want to exercise more control over just how the
2916 pipe command gets executed, such as when you are running setuid, and
2917 don't want to have to scan shell commands for metacharacters.
2918 The following triples are more or less equivalent:
2919
2920     open(FOO, "|tr '[a-z]' '[A-Z]'");
2921     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2922     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2923     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
2924
2925     open(FOO, "cat -n '$file'|");
2926     open(FOO, '-|', "cat -n '$file'");
2927     open(FOO, '-|') || exec 'cat', '-n', $file;
2928     open(FOO, '-|', "cat", '-n', $file);
2929
2930 The last example in each block shows the pipe as "list form", which is
2931 not yet supported on all platforms.
2932
2933 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2934
2935 Beginning with v5.6.0, Perl will attempt to flush all files opened for
2936 output before any operation that may do a fork, but this may not be
2937 supported on some platforms (see L<perlport>).  To be safe, you may need
2938 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
2939 of C<IO::Handle> on any open handles.
2940
2941 On systems that support a close-on-exec flag on files, the flag will
2942 be set for the newly opened file descriptor as determined by the value
2943 of $^F.  See L<perlvar/$^F>.
2944
2945 Closing any piped filehandle causes the parent process to wait for the
2946 child to finish, and returns the status value in C<$?>.
2947
2948 The filename passed to 2-argument (or 1-argument) form of open() will
2949 have leading and trailing whitespace deleted, and the normal
2950 redirection characters honored.  This property, known as "magic open",
2951 can often be used to good effect.  A user could specify a filename of
2952 F<"rsh cat file |">, or you could change certain filenames as needed:
2953
2954     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2955     open(FH, $filename) or die "Can't open $filename: $!";
2956
2957 Use 3-argument form to open a file with arbitrary weird characters in it,
2958
2959     open(FOO, '<', $file);
2960
2961 otherwise it's necessary to protect any leading and trailing whitespace:
2962
2963     $file =~ s#^(\s)#./$1#;
2964     open(FOO, "< $file\0");
2965
2966 (this may not work on some bizarre filesystems).  One should
2967 conscientiously choose between the I<magic> and 3-arguments form
2968 of open():
2969
2970     open IN, $ARGV[0];
2971
2972 will allow the user to specify an argument of the form C<"rsh cat file |">,
2973 but will not work on a filename which happens to have a trailing space, while
2974
2975     open IN, '<', $ARGV[0];
2976
2977 will have exactly the opposite restrictions.
2978
2979 If you want a "real" C C<open> (see L<open(2)> on your system), then you
2980 should use the C<sysopen> function, which involves no such magic (but
2981 may use subtly different filemodes than Perl open(), which is mapped
2982 to C fopen()).  This is
2983 another way to protect your filenames from interpretation.  For example:
2984
2985     use IO::Handle;
2986     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2987         or die "sysopen $path: $!";
2988     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2989     print HANDLE "stuff $$\n";
2990     seek(HANDLE, 0, 0);
2991     print "File contains: ", <HANDLE>;
2992
2993 Using the constructor from the C<IO::Handle> package (or one of its
2994 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2995 filehandles that have the scope of whatever variables hold references to
2996 them, and automatically close whenever and however you leave that scope:
2997
2998     use IO::File;
2999     #...
3000     sub read_myfile_munged {
3001         my $ALL = shift;
3002         my $handle = new IO::File;
3003         open($handle, "myfile") or die "myfile: $!";
3004         $first = <$handle>
3005             or return ();     # Automatically closed here.
3006         mung $first or die "mung failed";       # Or here.
3007         return $first, <$handle> if $ALL;       # Or here.
3008         $first;                                 # Or here.
3009     }
3010
3011 See L</seek> for some details about mixing reading and writing.
3012
3013 =item opendir DIRHANDLE,EXPR
3014
3015 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3016 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3017 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3018
3019 =item ord EXPR
3020
3021 =item ord
3022
3023 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3024 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3025 uses C<$_>.
3026
3027 For the reverse, see L</chr>.
3028 See L<perlunicode> and L<encoding> for more about Unicode.
3029
3030 =item our EXPR
3031
3032 =item our EXPR : ATTRIBUTES
3033
3034 An C<our> declares the listed variables to be valid globals within
3035 the enclosing block, file, or C<eval>.  That is, it has the same
3036 scoping rules as a "my" declaration, but does not create a local
3037 variable.  If more than one value is listed, the list must be placed
3038 in parentheses.  The C<our> declaration has no semantic effect unless
3039 "use strict vars" is in effect, in which case it lets you use the
3040 declared global variable without qualifying it with a package name.
3041 (But only within the lexical scope of the C<our> declaration.  In this
3042 it differs from "use vars", which is package scoped.)
3043
3044 An C<our> declaration declares a global variable that will be visible
3045 across its entire lexical scope, even across package boundaries.  The
3046 package in which the variable is entered is determined at the point
3047 of the declaration, not at the point of use.  This means the following
3048 behavior holds:
3049
3050     package Foo;
3051     our $bar;           # declares $Foo::bar for rest of lexical scope
3052     $bar = 20;
3053
3054     package Bar;
3055     print $bar;         # prints 20
3056
3057 Multiple C<our> declarations in the same lexical scope are allowed
3058 if they are in different packages.  If they happened to be in the same
3059 package, Perl will emit warnings if you have asked for them.
3060
3061     use warnings;
3062     package Foo;
3063     our $bar;           # declares $Foo::bar for rest of lexical scope
3064     $bar = 20;
3065
3066     package Bar;
3067     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3068     print $bar;         # prints 30
3069
3070     our $bar;           # emits warning
3071
3072 An C<our> declaration may also have a list of attributes associated
3073 with it.  B<WARNING>: This is an experimental feature that may be
3074 changed or removed in future releases of Perl.  It should not be
3075 relied upon.
3076
3077 The only currently recognized attribute is C<unique> which indicates
3078 that a single copy of the global is to be used by all interpreters
3079 should the program happen to be running in a multi-interpreter
3080 environment. (The default behaviour would be for each interpreter to
3081 have its own copy of the global.)  In such an environment, this
3082 attribute also has the effect of making the global readonly.
3083 Examples:
3084
3085     our @EXPORT : unique = qw(foo);
3086     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3087     our $VERSION : unique = "1.00";
3088
3089 Multi-interpreter environments can come to being either through the
3090 fork() emulation on Windows platforms, or by embedding perl in a
3091 multi-threaded application.  The C<unique> attribute does nothing in
3092 all other environments.
3093
3094 =item pack TEMPLATE,LIST
3095
3096 Takes a LIST of values and converts it into a string using the rules
3097 given by the TEMPLATE.  The resulting string is the concatenation of
3098 the converted values.  Typically, each converted value looks
3099 like its machine-level representation.  For example, on 32-bit machines
3100 a converted integer may be represented by a sequence of 4 bytes.
3101
3102 The TEMPLATE is a
3103 sequence of characters that give the order and type of values, as
3104 follows:
3105
3106     a   A string with arbitrary binary data, will be null padded.
3107     A   A text (ASCII) string, will be space padded.
3108     Z   A null terminated (ASCIZ) string, will be null padded.
3109
3110     b   A bit string (ascending bit order inside each byte, like vec()).
3111     B   A bit string (descending bit order inside each byte).
3112     h   A hex string (low nybble first).
3113     H   A hex string (high nybble first).
3114
3115     c   A signed char value.
3116     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3117
3118     s   A signed short value.
3119     S   An unsigned short value.
3120           (This 'short' is _exactly_ 16 bits, which may differ from
3121            what a local C compiler calls 'short'.  If you want
3122            native-length shorts, use the '!' suffix.)
3123
3124     i   A signed integer value.
3125     I   An unsigned integer value.
3126           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3127            size depends on what a local C compiler calls 'int',
3128            and may even be larger than the 'long' described in
3129            the next item.)
3130
3131     l   A signed long value.
3132     L   An unsigned long value.
3133           (This 'long' is _exactly_ 32 bits, which may differ from
3134            what a local C compiler calls 'long'.  If you want
3135            native-length longs, use the '!' suffix.)
3136
3137     n   An unsigned short in "network" (big-endian) order.
3138     N   An unsigned long in "network" (big-endian) order.
3139     v   An unsigned short in "VAX" (little-endian) order.
3140     V   An unsigned long in "VAX" (little-endian) order.
3141           (These 'shorts' and 'longs' are _exactly_ 16 bits and
3142            _exactly_ 32 bits, respectively.)
3143
3144     q   A signed quad (64-bit) value.
3145     Q   An unsigned quad value.
3146           (Quads are available only if your system supports 64-bit
3147            integer values _and_ if Perl has been compiled to support those.
3148            Causes a fatal error otherwise.)
3149
3150     f   A single-precision float in the native format.
3151     d   A double-precision float in the native format.
3152
3153     p   A pointer to a null-terminated string.
3154     P   A pointer to a structure (fixed-length string).
3155
3156     u   A uuencoded string.
3157     U   A Unicode character number.  Encodes to UTF-8 internally
3158         (or UTF-EBCDIC in EBCDIC platforms).
3159
3160     w   A BER compressed integer.  Its bytes represent an unsigned
3161         integer in base 128, most significant digit first, with as
3162         few digits as possible.  Bit eight (the high bit) is set
3163         on each byte except the last.
3164
3165     x   A null byte.
3166     X   Back up a byte.
3167     @   Null fill to absolute position.
3168
3169 The following rules apply:
3170
3171 =over 8
3172
3173 =item *
3174
3175 Each letter may optionally be followed by a number giving a repeat
3176 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3177 C<H>, and C<P> the pack function will gobble up that many values from
3178 the LIST.  A C<*> for the repeat count means to use however many items are
3179 left, except for C<@>, C<x>, C<X>, where it is equivalent
3180 to C<0>, and C<u>, where it is equivalent to 1 (or 45, what is the
3181 same).
3182
3183 When used with C<Z>, C<*> results in the addition of a trailing null
3184 byte (so the packed result will be one longer than the byte C<length>
3185 of the item).
3186
3187 The repeat count for C<u> is interpreted as the maximal number of bytes
3188 to encode per line of output, with 0 and 1 replaced by 45.
3189
3190 =item *
3191
3192 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3193 string of length count, padding with nulls or spaces as necessary.  When
3194 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3195 after the first null, and C<a> returns data verbatim.  When packing,
3196 C<a>, and C<Z> are equivalent.
3197
3198 If the value-to-pack is too long, it is truncated.  If too long and an
3199 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3200 by a null byte.  Thus C<Z> always packs a trailing null byte under
3201 all circumstances.
3202
3203 =item *
3204
3205 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3206 Each byte of the input field of pack() generates 1 bit of the result.
3207 Each result bit is based on the least-significant bit of the corresponding
3208 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3209 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3210
3211 Starting from the beginning of the input string of pack(), each 8-tuple
3212 of bytes is converted to 1 byte of output.  With format C<b>
3213 the first byte of the 8-tuple determines the least-significant bit of a
3214 byte, and with format C<B> it determines the most-significant bit of
3215 a byte.
3216
3217 If the length of the input string is not exactly divisible by 8, the
3218 remainder is packed as if the input string were padded by null bytes
3219 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3220
3221 If the input string of pack() is longer than needed, extra bytes are ignored.
3222 A C<*> for the repeat count of pack() means to use all the bytes of
3223 the input field.  On unpack()ing the bits are converted to a string
3224 of C<"0">s and C<"1">s.
3225
3226 =item *
3227
3228 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3229 representable as hexadecimal digits, 0-9a-f) long.
3230
3231 Each byte of the input field of pack() generates 4 bits of the result.
3232 For non-alphabetical bytes the result is based on the 4 least-significant
3233 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3234 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3235 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3236 is compatible with the usual hexadecimal digits, so that C<"a"> and
3237 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3238 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3239
3240 Starting from the beginning of the input string of pack(), each pair
3241 of bytes is converted to 1 byte of output.  With format C<h> the
3242 first byte of the pair determines the least-significant nybble of the
3243 output byte, and with format C<H> it determines the most-significant
3244 nybble.
3245
3246 If the length of the input string is not even, it behaves as if padded
3247 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3248 nybbles are ignored.
3249
3250 If the input string of pack() is longer than needed, extra bytes are ignored.
3251 A C<*> for the repeat count of pack() means to use all the bytes of
3252 the input field.  On unpack()ing the bits are converted to a string
3253 of hexadecimal digits.
3254
3255 =item *
3256
3257 The C<p> type packs a pointer to a null-terminated string.  You are
3258 responsible for ensuring the string is not a temporary value (which can
3259 potentially get deallocated before you get around to using the packed result).
3260 The C<P> type packs a pointer to a structure of the size indicated by the
3261 length.  A NULL pointer is created if the corresponding value for C<p> or
3262 C<P> is C<undef>, similarly for unpack().
3263
3264 =item *
3265
3266 The C</> template character allows packing and unpacking of strings where
3267 the packed structure contains a byte count followed by the string itself.
3268 You write I<length-item>C</>I<string-item>.
3269
3270 The I<length-item> can be any C<pack> template letter,
3271 and describes how the length value is packed.
3272 The ones likely to be of most use are integer-packing ones like
3273 C<n> (for Java strings), C<w> (for ASN.1 or SNMP)
3274 and C<N> (for Sun XDR).
3275
3276 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
3277 For C<unpack> the length of the string is obtained from the I<length-item>,
3278 but if you put in the '*' it will be ignored.
3279
3280     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3281     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3282     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3283
3284 The I<length-item> is not returned explicitly from C<unpack>.
3285
3286 Adding a count to the I<length-item> letter is unlikely to do anything
3287 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3288 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3289 which Perl does not regard as legal in numeric strings.
3290
3291 =item *
3292
3293 The integer types C<s>, C<S>, C<l>, and C<L> may be
3294 immediately followed by a C<!> suffix to signify native shorts or
3295 longs--as you can see from above for example a bare C<l> does mean
3296 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3297 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3298 see whether using C<!> makes any difference by
3299
3300         print length(pack("s")), " ", length(pack("s!")), "\n";
3301         print length(pack("l")), " ", length(pack("l!")), "\n";
3302
3303 C<i!> and C<I!> also work but only because of completeness;
3304 they are identical to C<i> and C<I>.
3305
3306 The actual sizes (in bytes) of native shorts, ints, longs, and long
3307 longs on the platform where Perl was built are also available via
3308 L<Config>:
3309
3310        use Config;
3311        print $Config{shortsize},    "\n";
3312        print $Config{intsize},      "\n";
3313        print $Config{longsize},     "\n";
3314        print $Config{longlongsize}, "\n";
3315
3316 (The C<$Config{longlongsize}> will be undefine if your system does
3317 not support long longs.)
3318
3319 =item *
3320
3321 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, and C<L>
3322 are inherently non-portable between processors and operating systems
3323 because they obey the native byteorder and endianness.  For example a
3324 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3325 (arranged in and handled by the CPU registers) into bytes as
3326
3327         0x12 0x34 0x56 0x78     # big-endian
3328         0x78 0x56 0x34 0x12     # little-endian
3329
3330 Basically, the Intel and VAX CPUs are little-endian, while everybody
3331 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3332 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3333 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3334 mode.
3335
3336 The names `big-endian' and `little-endian' are comic references to
3337 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3338 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3339 the egg-eating habits of the Lilliputians.
3340
3341 Some systems may have even weirder byte orders such as
3342
3343         0x56 0x78 0x12 0x34
3344         0x34 0x12 0x78 0x56
3345
3346 You can see your system's preference with
3347
3348         print join(" ", map { sprintf "%#02x", $_ }
3349                             unpack("C*",pack("L",0x12345678))), "\n";
3350
3351 The byteorder on the platform where Perl was built is also available
3352 via L<Config>:
3353
3354         use Config;
3355         print $Config{byteorder}, "\n";
3356
3357 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3358 and C<'87654321'> are big-endian.
3359
3360 If you want portable packed integers use the formats C<n>, C<N>,
3361 C<v>, and C<V>, their byte endianness and size are known.
3362 See also L<perlport>.
3363
3364 =item *
3365
3366 Real numbers (floats and doubles) are in the native machine format only;
3367 due to the multiplicity of floating formats around, and the lack of a
3368 standard "network" representation, no facility for interchange has been
3369 made.  This means that packed floating point data written on one machine
3370 may not be readable on another - even if both use IEEE floating point
3371 arithmetic (as the endian-ness of the memory representation is not part
3372 of the IEEE spec).  See also L<perlport>.
3373
3374 Note that Perl uses doubles internally for all numeric calculation, and
3375 converting from double into float and thence back to double again will
3376 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3377 equal $foo).
3378
3379 =item *
3380
3381 If the pattern begins with a C<U>, the resulting string will be treated
3382 as Unicode-encoded. You can force UTF8 encoding on in a string with an
3383 initial C<U0>, and the bytes that follow will be interpreted as Unicode
3384 characters. If you don't want this to happen, you can begin your pattern
3385 with C<C0> (or anything else) to force Perl not to UTF8 encode your
3386 string, and then follow this with a C<U*> somewhere in your pattern.
3387
3388 =item *
3389
3390 You must yourself do any alignment or padding by inserting for example
3391 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3392 could know where the bytes are going to or coming from.  Therefore
3393 C<pack> (and C<unpack>) handle their output and input as flat
3394 sequences of bytes.
3395
3396 =item *
3397
3398 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3399
3400 =item *
3401
3402 If TEMPLATE requires more arguments to pack() than actually given, pack()
3403 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3404 to pack() than actually given, extra arguments are ignored.
3405
3406 =back
3407
3408 Examples:
3409
3410     $foo = pack("CCCC",65,66,67,68);
3411     # foo eq "ABCD"
3412     $foo = pack("C4",65,66,67,68);
3413     # same thing
3414     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3415     # same thing with Unicode circled letters
3416
3417     $foo = pack("ccxxcc",65,66,67,68);
3418     # foo eq "AB\0\0CD"
3419
3420     # note: the above examples featuring "C" and "c" are true
3421     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3422     # and UTF-8.  In EBCDIC the first example would be
3423     # $foo = pack("CCCC",193,194,195,196);
3424
3425     $foo = pack("s2",1,2);
3426     # "\1\0\2\0" on little-endian
3427     # "\0\1\0\2" on big-endian
3428
3429     $foo = pack("a4","abcd","x","y","z");
3430     # "abcd"
3431
3432     $foo = pack("aaaa","abcd","x","y","z");
3433     # "axyz"
3434
3435     $foo = pack("a14","abcdefg");
3436     # "abcdefg\0\0\0\0\0\0\0"
3437
3438     $foo = pack("i9pl", gmtime);
3439     # a real struct tm (on my system anyway)
3440
3441     $utmp_template = "Z8 Z8 Z16 L";
3442     $utmp = pack($utmp_template, @utmp1);
3443     # a struct utmp (BSDish)
3444
3445     @utmp2 = unpack($utmp_template, $utmp);
3446     # "@utmp1" eq "@utmp2"
3447
3448     sub bintodec {
3449         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3450     }
3451
3452     $foo = pack('sx2l', 12, 34);
3453     # short 12, two zero bytes padding, long 34
3454     $bar = pack('s@4l', 12, 34);
3455     # short 12, zero fill to position 4, long 34
3456     # $foo eq $bar
3457
3458 The same template may generally also be used in unpack().
3459
3460 =item package NAMESPACE
3461
3462 =item package
3463
3464 Declares the compilation unit as being in the given namespace.  The scope
3465 of the package declaration is from the declaration itself through the end
3466 of the enclosing block, file, or eval (the same as the C<my> operator).
3467 All further unqualified dynamic identifiers will be in this namespace.
3468 A package statement affects only dynamic variables--including those
3469 you've used C<local> on--but I<not> lexical variables, which are created
3470 with C<my>.  Typically it would be the first declaration in a file to
3471 be included by the C<require> or C<use> operator.  You can switch into a
3472 package in more than one place; it merely influences which symbol table
3473 is used by the compiler for the rest of that block.  You can refer to
3474 variables and filehandles in other packages by prefixing the identifier
3475 with the package name and a double colon:  C<$Package::Variable>.
3476 If the package name is null, the C<main> package as assumed.  That is,
3477 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3478 still seen in older code).
3479
3480 If NAMESPACE is omitted, then there is no current package, and all
3481 identifiers must be fully qualified or lexicals.  However, you are
3482 strongly advised not to make use of this feature. Its use can cause
3483 unexpected behaviour, even crashing some versions of Perl. It is
3484 deprecated, and will be removed from a future release.
3485
3486 See L<perlmod/"Packages"> for more information about packages, modules,
3487 and classes.  See L<perlsub> for other scoping issues.
3488
3489 =item pipe READHANDLE,WRITEHANDLE
3490
3491 Opens a pair of connected pipes like the corresponding system call.
3492 Note that if you set up a loop of piped processes, deadlock can occur
3493 unless you are very careful.  In addition, note that Perl's pipes use
3494 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3495 after each command, depending on the application.
3496
3497 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3498 for examples of such things.
3499
3500 On systems that support a close-on-exec flag on files, the flag will be set
3501 for the newly opened file descriptors as determined by the value of $^F.
3502 See L<perlvar/$^F>.
3503
3504 =item pop ARRAY
3505
3506 =item pop
3507
3508 Pops and returns the last value of the array, shortening the array by
3509 one element.  Has an effect similar to
3510
3511     $ARRAY[$#ARRAY--]
3512
3513 If there are no elements in the array, returns the undefined value
3514 (although this may happen at other times as well).  If ARRAY is
3515 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3516 array in subroutines, just like C<shift>.
3517
3518 =item pos SCALAR
3519
3520 =item pos
3521
3522 Returns the offset of where the last C<m//g> search left off for the variable
3523 in question (C<$_> is used when the variable is not specified).  May be
3524 modified to change that offset.  Such modification will also influence
3525 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3526 L<perlop>.
3527
3528 =item print FILEHANDLE LIST
3529
3530 =item print LIST
3531
3532 =item print
3533
3534 Prints a string or a list of strings.  Returns true if successful.
3535 FILEHANDLE may be a scalar variable name, in which case the variable
3536 contains the name of or a reference to the filehandle, thus introducing
3537 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3538 the next token is a term, it may be misinterpreted as an operator
3539 unless you interpose a C<+> or put parentheses around the arguments.)
3540 If FILEHANDLE is omitted, prints by default to standard output (or
3541 to the last selected output channel--see L</select>).  If LIST is
3542 also omitted, prints C<$_> to the currently selected output channel.
3543 To set the default output channel to something other than STDOUT
3544 use the select operation.  The current value of C<$,> (if any) is
3545 printed between each LIST item.  The current value of C<$\> (if
3546 any) is printed after the entire LIST has been printed.  Because
3547 print takes a LIST, anything in the LIST is evaluated in list
3548 context, and any subroutine that you call will have one or more of
3549 its expressions evaluated in list context.  Also be careful not to
3550 follow the print keyword with a left parenthesis unless you want
3551 the corresponding right parenthesis to terminate the arguments to
3552 the print--interpose a C<+> or put parentheses around all the
3553 arguments.
3554
3555 Note that if you're storing FILEHANDLES in an array or other expression,
3556 you will have to use a block returning its value instead:
3557
3558     print { $files[$i] } "stuff\n";
3559     print { $OK ? STDOUT : STDERR } "stuff\n";
3560
3561 =item printf FILEHANDLE FORMAT, LIST
3562
3563 =item printf FORMAT, LIST
3564
3565 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3566 (the output record separator) is not appended.  The first argument
3567 of the list will be interpreted as the C<printf> format. See C<sprintf>
3568 for an explanation of the format argument. If C<use locale> is in effect,
3569 the character used for the decimal point in formatted real numbers is
3570 affected by the LC_NUMERIC locale.  See L<perllocale>.
3571
3572 Don't fall into the trap of using a C<printf> when a simple
3573 C<print> would do.  The C<print> is more efficient and less
3574 error prone.
3575
3576 =item prototype FUNCTION
3577
3578 Returns the prototype of a function as a string (or C<undef> if the
3579 function has no prototype).  FUNCTION is a reference to, or the name of,
3580 the function whose prototype you want to retrieve.
3581
3582 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3583 name for Perl builtin.  If the builtin is not I<overridable> (such as
3584 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3585 C<system>) returns C<undef> because the builtin does not really behave
3586 like a Perl function.  Otherwise, the string describing the equivalent
3587 prototype is returned.
3588
3589 =item push ARRAY,LIST
3590
3591 Treats ARRAY as a stack, and pushes the values of LIST
3592 onto the end of ARRAY.  The length of ARRAY increases by the length of
3593 LIST.  Has the same effect as
3594
3595     for $value (LIST) {
3596         $ARRAY[++$#ARRAY] = $value;
3597     }
3598
3599 but is more efficient.  Returns the new number of elements in the array.
3600
3601 =item q/STRING/
3602
3603 =item qq/STRING/
3604
3605 =item qr/STRING/
3606
3607 =item qx/STRING/
3608
3609 =item qw/STRING/
3610
3611 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3612
3613 =item quotemeta EXPR
3614
3615 =item quotemeta
3616
3617 Returns the value of EXPR with all non-"word"
3618 characters backslashed.  (That is, all characters not matching
3619 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3620 returned string, regardless of any locale settings.)
3621 This is the internal function implementing
3622 the C<\Q> escape in double-quoted strings.
3623
3624 If EXPR is omitted, uses C<$_>.
3625
3626 =item rand EXPR
3627
3628 =item rand
3629
3630 Returns a random fractional number greater than or equal to C<0> and less
3631 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3632 omitted, or a C<0>, the value C<1> is used.  Automatically calls C<srand>
3633 unless C<srand> has already been called.  See also C<srand>.
3634
3635 Apply C<int()> to the value returned by C<rand()> if you want random
3636 integers instead of random fractional numbers.  For example,
3637
3638     int(rand(10))
3639
3640 returns a random integer between C<0> and C<9>, inclusive.
3641
3642 (Note: If your rand function consistently returns numbers that are too
3643 large or too small, then your version of Perl was probably compiled
3644 with the wrong number of RANDBITS.)
3645
3646 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3647
3648 =item read FILEHANDLE,SCALAR,LENGTH
3649
3650 Attempts to read LENGTH I<characters> of data into variable SCALAR
3651 from the specified FILEHANDLE.  Returns the number of characters
3652 actually read, C<0> at end of file, or undef if there was an error.
3653 SCALAR will be grown or shrunk to the length actually read.  If SCALAR
3654 needs growing, the new bytes will be zero bytes.  An OFFSET may be
3655 specified to place the read data into some other place in SCALAR than
3656 the beginning.  The call is actually implemented in terms of either
3657 Perl's or system's fread() call.  To get a true read(2) system call,
3658 see C<sysread>.
3659
3660 Note the I<characters>: depending on the status of the filehandle,
3661 either (8-bit) bytes or characters are read.  By default all
3662 filehandles operate on bytes, but for example if the filehandle has
3663 been opened with the C<:utf8> discipline (see L</open>, and the C<open>
3664 pragma, L<open>), the I/O will operate on characters, not bytes.
3665
3666 =item readdir DIRHANDLE
3667
3668 Returns the next directory entry for a directory opened by C<opendir>.
3669 If used in list context, returns all the rest of the entries in the
3670 directory.  If there are no more entries, returns an undefined value in
3671 scalar context or a null list in list context.
3672
3673 If you're planning to filetest the return values out of a C<readdir>, you'd
3674 better prepend the directory in question.  Otherwise, because we didn't
3675 C<chdir> there, it would have been testing the wrong file.
3676
3677     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3678     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3679     closedir DIR;
3680
3681 =item readline EXPR
3682
3683 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3684 context, each call reads and returns the next line, until end-of-file is
3685 reached, whereupon the subsequent call returns undef.  In list context,
3686 reads until end-of-file is reached and returns a list of lines.  Note that
3687 the notion of "line" used here is however you may have defined it
3688 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3689
3690 When C<$/> is set to C<undef>, when readline() is in scalar
3691 context (i.e. file slurp mode), and when an empty file is read, it
3692 returns C<''> the first time, followed by C<undef> subsequently.
3693
3694 This is the internal function implementing the C<< <EXPR> >>
3695 operator, but you can use it directly.  The C<< <EXPR> >>
3696 operator is discussed in more detail in L<perlop/"I/O Operators">.
3697
3698     $line = <STDIN>;
3699     $line = readline(*STDIN);           # same thing
3700
3701 =item readlink EXPR
3702
3703 =item readlink
3704
3705 Returns the value of a symbolic link, if symbolic links are
3706 implemented.  If not, gives a fatal error.  If there is some system
3707 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3708 omitted, uses C<$_>.
3709
3710 =item readpipe EXPR
3711
3712 EXPR is executed as a system command.
3713 The collected standard output of the command is returned.
3714 In scalar context, it comes back as a single (potentially
3715 multi-line) string.  In list context, returns a list of lines
3716 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3717 This is the internal function implementing the C<qx/EXPR/>
3718 operator, but you can use it directly.  The C<qx/EXPR/>
3719 operator is discussed in more detail in L<perlop/"I/O Operators">.
3720
3721 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3722
3723 Receives a message on a socket.  Attempts to receive LENGTH characters
3724 of data into variable SCALAR from the specified SOCKET filehandle.
3725 SCALAR will be grown or shrunk to the length actually read.  Takes the
3726 same flags as the system call of the same name.  Returns the address
3727 of the sender if SOCKET's protocol supports this; returns an empty
3728 string otherwise.  If there's an error, returns the undefined value.
3729 This call is actually implemented in terms of recvfrom(2) system call.
3730 See L<perlipc/"UDP: Message Passing"> for examples.
3731
3732 Note the I<characters>: depending on the status of the socket, either
3733 (8-bit) bytes or characters are received.  By default all sockets
3734 operate on bytes, but for example if the socket has been changed using
3735 binmode() to operate with the C<:utf8> discipline (see the C<open>
3736 pragma, L<open>), the I/O will operate on characters, not bytes.
3737
3738 =item redo LABEL
3739
3740 =item redo
3741
3742 The C<redo> command restarts the loop block without evaluating the
3743 conditional again.  The C<continue> block, if any, is not executed.  If
3744 the LABEL is omitted, the command refers to the innermost enclosing
3745 loop.  This command is normally used by programs that want to lie to
3746 themselves about what was just input:
3747
3748     # a simpleminded Pascal comment stripper
3749     # (warning: assumes no { or } in strings)
3750     LINE: while (<STDIN>) {
3751         while (s|({.*}.*){.*}|$1 |) {}
3752         s|{.*}| |;
3753         if (s|{.*| |) {
3754             $front = $_;
3755             while (<STDIN>) {
3756                 if (/}/) {      # end of comment?
3757                     s|^|$front\{|;
3758                     redo LINE;
3759                 }
3760             }
3761         }
3762         print;
3763     }
3764
3765 C<redo> cannot be used to retry a block which returns a value such as
3766 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3767 a grep() or map() operation.
3768
3769 Note that a block by itself is semantically identical to a loop
3770 that executes once.  Thus C<redo> inside such a block will effectively
3771 turn it into a looping construct.
3772
3773 See also L</continue> for an illustration of how C<last>, C<next>, and
3774 C<redo> work.
3775
3776 =item ref EXPR
3777
3778 =item ref
3779
3780 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3781 is not specified, C<$_> will be used.  The value returned depends on the
3782 type of thing the reference is a reference to.
3783 Builtin types include:
3784
3785     SCALAR
3786     ARRAY
3787     HASH
3788     CODE
3789     REF
3790     GLOB
3791     LVALUE
3792
3793 If the referenced object has been blessed into a package, then that package
3794 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3795
3796     if (ref($r) eq "HASH") {
3797         print "r is a reference to a hash.\n";
3798     }
3799     unless (ref($r)) {
3800         print "r is not a reference at all.\n";
3801     }
3802     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3803         print "r is a reference to something that isa hash.\n";
3804     }
3805
3806 See also L<perlref>.
3807
3808 =item rename OLDNAME,NEWNAME
3809
3810 Changes the name of a file; an existing file NEWNAME will be
3811 clobbered.  Returns true for success, false otherwise.
3812
3813 Behavior of this function varies wildly depending on your system
3814 implementation.  For example, it will usually not work across file system
3815 boundaries, even though the system I<mv> command sometimes compensates
3816 for this.  Other restrictions include whether it works on directories,
3817 open files, or pre-existing files.  Check L<perlport> and either the
3818 rename(2) manpage or equivalent system documentation for details.
3819
3820 =item require VERSION
3821
3822 =item require EXPR
3823
3824 =item require
3825
3826 Demands a version of Perl specified by VERSION, or demands some semantics
3827 specified by EXPR or by C<$_> if EXPR is not supplied.
3828
3829 VERSION may be either a numeric argument such as 5.006, which will be
3830 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
3831 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
3832 VERSION is greater than the version of the current Perl interpreter.
3833 Compare with L</use>, which can do a similar check at compile time.
3834
3835 Specifying VERSION as a literal of the form v5.6.1 should generally be
3836 avoided, because it leads to misleading error messages under earlier
3837 versions of Perl which do not support this syntax.  The equivalent numeric
3838 version should be used instead.
3839
3840     require v5.6.1;     # run time version check
3841     require 5.6.1;      # ditto
3842     require 5.006_001;  # ditto; preferred for backwards compatibility
3843
3844 Otherwise, demands that a library file be included if it hasn't already
3845 been included.  The file is included via the do-FILE mechanism, which is
3846 essentially just a variety of C<eval>.  Has semantics similar to the following
3847 subroutine:
3848
3849     sub require {
3850         my($filename) = @_;
3851         return 1 if $INC{$filename};
3852         my($realfilename,$result);
3853         ITER: {
3854             foreach $prefix (@INC) {
3855                 $realfilename = "$prefix/$filename";
3856                 if (-f $realfilename) {
3857                     $INC{$filename} = $realfilename;
3858                     $result = do $realfilename;
3859                     last ITER;
3860                 }
3861             }
3862             die "Can't find $filename in \@INC";
3863         }
3864         delete $INC{$filename} if $@ || !$result;
3865         die $@ if $@;
3866         die "$filename did not return true value" unless $result;
3867         return $result;
3868     }
3869
3870 Note that the file will not be included twice under the same specified
3871 name.  The file must return true as the last statement to indicate
3872 successful execution of any initialization code, so it's customary to
3873 end such a file with C<1;> unless you're sure it'll return true
3874 otherwise.  But it's better just to put the C<1;>, in case you add more
3875 statements.
3876
3877 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3878 replaces "F<::>" with "F</>" in the filename for you,
3879 to make it easy to load standard modules.  This form of loading of
3880 modules does not risk altering your namespace.
3881
3882 In other words, if you try this:
3883
3884         require Foo::Bar;    # a splendid bareword
3885
3886 The require function will actually look for the "F<Foo/Bar.pm>" file in the
3887 directories specified in the C<@INC> array.
3888
3889 But if you try this:
3890
3891         $class = 'Foo::Bar';
3892         require $class;      # $class is not a bareword
3893     #or
3894         require "Foo::Bar";  # not a bareword because of the ""
3895
3896 The require function will look for the "F<Foo::Bar>" file in the @INC array and
3897 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3898
3899         eval "require $class";
3900
3901 You can also insert hooks into the import facility, by putting directly
3902 Perl code into the @INC array.  There are three forms of hooks: subroutine
3903 references, array references and blessed objects.
3904
3905 Subroutine references are the simplest case.  When the inclusion system
3906 walks through @INC and encounters a subroutine, this subroutine gets
3907 called with two parameters, the first being a reference to itself, and the
3908 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
3909 subroutine should return C<undef> or a filehandle, from which the file to
3910 include will be read.  If C<undef> is returned, C<require> will look at
3911 the remaining elements of @INC.
3912
3913 If the hook is an array reference, its first element must be a subroutine
3914 reference.  This subroutine is called as above, but the first parameter is
3915 the array reference.  This enables to pass indirectly some arguments to
3916 the subroutine.
3917
3918 In other words, you can write:
3919
3920     push @INC, \&my_sub;
3921     sub my_sub {
3922         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
3923         ...
3924     }
3925
3926 or:
3927
3928     push @INC, [ \&my_sub, $x, $y, ... ];
3929     sub my_sub {
3930         my ($arrayref, $filename) = @_;
3931         # Retrieve $x, $y, ...
3932         my @parameters = @$arrayref[1..$#$arrayref];
3933         ...
3934     }
3935
3936 If the hook is an object, it must provide an INC method, that will be
3937 called as above, the first parameter being the object itself.  (Note that
3938 you must fully qualify the sub's name, as it is always forced into package
3939 C<main>.)  Here is a typical code layout:
3940
3941     # In Foo.pm
3942     package Foo;
3943     sub new { ... }
3944     sub Foo::INC {
3945         my ($self, $filename) = @_;
3946         ...
3947     }
3948
3949     # In the main program
3950     push @INC, new Foo(...);
3951
3952 Note that these hooks are also permitted to set the %INC entry
3953 corresponding to the files they have loaded. See L<perlvar/%INC>.
3954
3955 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3956
3957 =item reset EXPR
3958
3959 =item reset
3960
3961 Generally used in a C<continue> block at the end of a loop to clear
3962 variables and reset C<??> searches so that they work again.  The
3963 expression is interpreted as a list of single characters (hyphens
3964 allowed for ranges).  All variables and arrays beginning with one of
3965 those letters are reset to their pristine state.  If the expression is
3966 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3967 only variables or searches in the current package.  Always returns
3968 1.  Examples:
3969
3970     reset 'X';          # reset all X variables
3971     reset 'a-z';        # reset lower case variables
3972     reset;              # just reset ?one-time? searches
3973
3974 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3975 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
3976 variables--lexical variables are unaffected, but they clean themselves
3977 up on scope exit anyway, so you'll probably want to use them instead.
3978 See L</my>.
3979
3980 =item return EXPR
3981
3982 =item return
3983
3984 Returns from a subroutine, C<eval>, or C<do FILE> with the value
3985 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3986 context, depending on how the return value will be used, and the context
3987 may vary from one execution to the next (see C<wantarray>).  If no EXPR
3988 is given, returns an empty list in list context, the undefined value in
3989 scalar context, and (of course) nothing at all in a void context.
3990
3991 (Note that in the absence of an explicit C<return>, a subroutine, eval,
3992 or do FILE will automatically return the value of the last expression
3993 evaluated.)
3994
3995 =item reverse LIST
3996
3997 In list context, returns a list value consisting of the elements
3998 of LIST in the opposite order.  In scalar context, concatenates the
3999 elements of LIST and returns a string value with all characters
4000 in the opposite order.
4001
4002     print reverse <>;           # line tac, last line first
4003
4004     undef $/;                   # for efficiency of <>
4005     print scalar reverse <>;    # character tac, last line tsrif
4006
4007 This operator is also handy for inverting a hash, although there are some
4008 caveats.  If a value is duplicated in the original hash, only one of those
4009 can be represented as a key in the inverted hash.  Also, this has to
4010 unwind one hash and build a whole new one, which may take some time
4011 on a large hash, such as from a DBM file.
4012
4013     %by_name = reverse %by_address;     # Invert the hash
4014
4015 =item rewinddir DIRHANDLE
4016
4017 Sets the current position to the beginning of the directory for the
4018 C<readdir> routine on DIRHANDLE.
4019
4020 =item rindex STR,SUBSTR,POSITION
4021
4022 =item rindex STR,SUBSTR
4023
4024 Works just like index() except that it returns the position of the LAST
4025 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4026 last occurrence at or before that position.
4027
4028 =item rmdir FILENAME
4029
4030 =item rmdir
4031
4032 Deletes the directory specified by FILENAME if that directory is empty.  If it
4033 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
4034 FILENAME is omitted, uses C<$_>.
4035
4036 =item s///
4037
4038 The substitution operator.  See L<perlop>.
4039
4040 =item scalar EXPR
4041
4042 Forces EXPR to be interpreted in scalar context and returns the value
4043 of EXPR.
4044
4045     @counts = ( scalar @a, scalar @b, scalar @c );
4046
4047 There is no equivalent operator to force an expression to
4048 be interpolated in list context because in practice, this is never
4049 needed.  If you really wanted to do so, however, you could use
4050 the construction C<@{[ (some expression) ]}>, but usually a simple
4051 C<(some expression)> suffices.
4052
4053 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4054 parenthesized list, this behaves as a scalar comma expression, evaluating
4055 all but the last element in void context and returning the final element
4056 evaluated in scalar context.  This is seldom what you want.
4057
4058 The following single statement:
4059
4060         print uc(scalar(&foo,$bar)),$baz;
4061
4062 is the moral equivalent of these two:
4063
4064         &foo;
4065         print(uc($bar),$baz);
4066
4067 See L<perlop> for more details on unary operators and the comma operator.
4068
4069 =item seek FILEHANDLE,POSITION,WHENCE
4070
4071 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4072 FILEHANDLE may be an expression whose value gives the name of the
4073 filehandle.  The values for WHENCE are C<0> to set the new position
4074 I<in bytes> to POSITION, C<1> to set it to the current position plus
4075 POSITION, and C<2> to set it to EOF plus POSITION (typically
4076 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4077 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4078 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4079 otherwise.
4080
4081 Note the I<in bytes>: even if the filehandle has been set to
4082 operate on characters (for example by using the C<:utf8> open
4083 discipline), tell() will return byte offsets, not character offsets
4084 (because implementing that would render seek() and tell() rather slow).
4085
4086 If you want to position file for C<sysread> or C<syswrite>, don't use
4087 C<seek>--buffering makes its effect on the file's system position
4088 unpredictable and non-portable.  Use C<sysseek> instead.
4089
4090 Due to the rules and rigors of ANSI C, on some systems you have to do a
4091 seek whenever you switch between reading and writing.  Amongst other
4092 things, this may have the effect of calling stdio's clearerr(3).
4093 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4094
4095     seek(TEST,0,1);
4096
4097 This is also useful for applications emulating C<tail -f>.  Once you hit
4098 EOF on your read, and then sleep for a while, you might have to stick in a
4099 seek() to reset things.  The C<seek> doesn't change the current position,
4100 but it I<does> clear the end-of-file condition on the handle, so that the
4101 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4102
4103 If that doesn't work (some IO implementations are particularly
4104 cantankerous), then you may need something more like this:
4105
4106     for (;;) {
4107         for ($curpos = tell(FILE); $_ = <FILE>;
4108              $curpos = tell(FILE)) {
4109             # search for some stuff and put it into files
4110         }
4111         sleep($for_a_while);
4112         seek(FILE, $curpos, 0);
4113     }
4114
4115 =item seekdir DIRHANDLE,POS
4116
4117 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4118 must be a value returned by C<telldir>.  Has the same caveats about
4119 possible directory compaction as the corresponding system library
4120 routine.
4121
4122 =item select FILEHANDLE
4123
4124 =item select
4125
4126 Returns the currently selected filehandle.  Sets the current default
4127 filehandle for output, if FILEHANDLE is supplied.  This has two
4128 effects: first, a C<write> or a C<print> without a filehandle will
4129 default to this FILEHANDLE.  Second, references to variables related to
4130 output will refer to this output channel.  For example, if you have to
4131 set the top of form format for more than one output channel, you might
4132 do the following:
4133
4134     select(REPORT1);
4135     $^ = 'report1_top';
4136     select(REPORT2);
4137     $^ = 'report2_top';
4138
4139 FILEHANDLE may be an expression whose value gives the name of the
4140 actual filehandle.  Thus:
4141
4142     $oldfh = select(STDERR); $| = 1; select($oldfh);
4143
4144 Some programmers may prefer to think of filehandles as objects with
4145 methods, preferring to write the last example as:
4146
4147     use IO::Handle;
4148     STDERR->autoflush(1);
4149
4150 =item select RBITS,WBITS,EBITS,TIMEOUT
4151
4152 This calls the select(2) system call with the bit masks specified, which
4153 can be constructed using C<fileno> and C<vec>, along these lines:
4154
4155     $rin = $win = $ein = '';
4156     vec($rin,fileno(STDIN),1) = 1;
4157     vec($win,fileno(STDOUT),1) = 1;
4158     $ein = $rin | $win;
4159
4160 If you want to select on many filehandles you might wish to write a
4161 subroutine:
4162
4163     sub fhbits {
4164         my(@fhlist) = split(' ',$_[0]);
4165         my($bits);
4166         for (@fhlist) {
4167             vec($bits,fileno($_),1) = 1;
4168         }
4169         $bits;
4170     }
4171     $rin = fhbits('STDIN TTY SOCK');
4172
4173 The usual idiom is:
4174
4175     ($nfound,$timeleft) =
4176       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4177
4178 or to block until something becomes ready just do this
4179
4180     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4181
4182 Most systems do not bother to return anything useful in $timeleft, so
4183 calling select() in scalar context just returns $nfound.
4184
4185 Any of the bit masks can also be undef.  The timeout, if specified, is
4186 in seconds, which may be fractional.  Note: not all implementations are
4187 capable of returning the $timeleft.  If not, they always return
4188 $timeleft equal to the supplied $timeout.
4189
4190 You can effect a sleep of 250 milliseconds this way:
4191
4192     select(undef, undef, undef, 0.25);
4193
4194 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4195 or <FH>) with C<select>, except as permitted by POSIX, and even
4196 then only on POSIX systems.  You have to use C<sysread> instead.
4197
4198 =item semctl ID,SEMNUM,CMD,ARG
4199
4200 Calls the System V IPC function C<semctl>.  You'll probably have to say
4201
4202     use IPC::SysV;
4203
4204 first to get the correct constant definitions.  If CMD is IPC_STAT or
4205 GETALL, then ARG must be a variable which will hold the returned
4206 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4207 the undefined value for error, "C<0 but true>" for zero, or the actual
4208 return value otherwise.  The ARG must consist of a vector of native
4209 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4210 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4211 documentation.
4212
4213 =item semget KEY,NSEMS,FLAGS
4214
4215 Calls the System V IPC function semget.  Returns the semaphore id, or
4216 the undefined value if there is an error.  See also
4217 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4218 documentation.
4219
4220 =item semop KEY,OPSTRING
4221
4222 Calls the System V IPC function semop to perform semaphore operations
4223 such as signalling and waiting.  OPSTRING must be a packed array of
4224 semop structures.  Each semop structure can be generated with
4225 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4226 operations is implied by the length of OPSTRING.  Returns true if
4227 successful, or false if there is an error.  As an example, the
4228 following code waits on semaphore $semnum of semaphore id $semid:
4229
4230     $semop = pack("s!3", $semnum, -1, 0);
4231     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4232
4233 To signal the semaphore, replace C<-1> with C<1>.  See also
4234 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4235 documentation.
4236
4237 =item send SOCKET,MSG,FLAGS,TO
4238
4239 =item send SOCKET,MSG,FLAGS
4240
4241 Sends a message on a socket.  Attempts to send the scalar MSG to the
4242 SOCKET filehandle.  Takes the same flags as the system call of the
4243 same name.  On unconnected sockets you must specify a destination to
4244 send TO, in which case it does a C C<sendto>.  Returns the number of
4245 characters sent, or the undefined value if there is an error.  The C
4246 system call sendmsg(2) is currently unimplemented.  See
4247 L<perlipc/"UDP: Message Passing"> for examples.
4248
4249 Note the I<characters>: depending on the status of the socket, either
4250 (8-bit) bytes or characters are sent.  By default all sockets operate
4251 on bytes, but for example if the socket has been changed using
4252 binmode() to operate with the C<:utf8> discipline (see L</open>, or
4253 the C<open> pragma, L<open>), the I/O will operate on characters, not
4254 bytes.
4255
4256 =item setpgrp PID,PGRP
4257
4258 Sets the current process group for the specified PID, C<0> for the current
4259 process.  Will produce a fatal error if used on a machine that doesn't
4260 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4261 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4262 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4263 C<POSIX::setsid()>.
4264
4265 =item setpriority WHICH,WHO,PRIORITY
4266
4267 Sets the current priority for a process, a process group, or a user.
4268 (See setpriority(2).)  Will produce a fatal error if used on a machine
4269 that doesn't implement setpriority(2).
4270
4271 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4272
4273 Sets the socket option requested.  Returns undefined if there is an
4274 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4275 argument.
4276
4277 =item shift ARRAY
4278
4279 =item shift
4280
4281 Shifts the first value of the array off and returns it, shortening the
4282 array by 1 and moving everything down.  If there are no elements in the
4283 array, returns the undefined value.  If ARRAY is omitted, shifts the
4284 C<@_> array within the lexical scope of subroutines and formats, and the
4285 C<@ARGV> array at file scopes or within the lexical scopes established by
4286 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4287 constructs.
4288
4289 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4290 same thing to the left end of an array that C<pop> and C<push> do to the
4291 right end.
4292
4293 =item shmctl ID,CMD,ARG
4294
4295 Calls the System V IPC function shmctl.  You'll probably have to say
4296
4297     use IPC::SysV;
4298
4299 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4300 then ARG must be a variable which will hold the returned C<shmid_ds>
4301 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4302 true" for zero, or the actual return value otherwise.
4303 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4304
4305 =item shmget KEY,SIZE,FLAGS
4306
4307 Calls the System V IPC function shmget.  Returns the shared memory
4308 segment id, or the undefined value if there is an error.
4309 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4310
4311 =item shmread ID,VAR,POS,SIZE
4312
4313 =item shmwrite ID,STRING,POS,SIZE
4314
4315 Reads or writes the System V shared memory segment ID starting at
4316 position POS for size SIZE by attaching to it, copying in/out, and
4317 detaching from it.  When reading, VAR must be a variable that will
4318 hold the data read.  When writing, if STRING is too long, only SIZE
4319 bytes are used; if STRING is too short, nulls are written to fill out
4320 SIZE bytes.  Return true if successful, or false if there is an error.
4321 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4322 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4323
4324 =item shutdown SOCKET,HOW
4325
4326 Shuts down a socket connection in the manner indicated by HOW, which
4327 has the same interpretation as in the system call of the same name.
4328
4329     shutdown(SOCKET, 0);    # I/we have stopped reading data
4330     shutdown(SOCKET, 1);    # I/we have stopped writing data
4331     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4332
4333 This is useful with sockets when you want to tell the other
4334 side you're done writing but not done reading, or vice versa.
4335 It's also a more insistent form of close because it also
4336 disables the file descriptor in any forked copies in other
4337 processes.
4338
4339 =item sin EXPR
4340
4341 =item sin
4342
4343 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4344 returns sine of C<$_>.
4345
4346 For the inverse sine operation, you may use the C<Math::Trig::asin>
4347 function, or use this relation:
4348
4349     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4350
4351 =item sleep EXPR
4352
4353 =item sleep
4354
4355 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4356 May be interrupted if the process receives a signal such as C<SIGALRM>.
4357 Returns the number of seconds actually slept.  You probably cannot
4358 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4359 using C<alarm>.
4360
4361 On some older systems, it may sleep up to a full second less than what
4362 you requested, depending on how it counts seconds.  Most modern systems
4363 always sleep the full amount.  They may appear to sleep longer than that,
4364 however, because your process might not be scheduled right away in a
4365 busy multitasking system.
4366
4367 For delays of finer granularity than one second, you may use Perl's
4368 C<syscall> interface to access setitimer(2) if your system supports
4369 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
4370 and starting from Perl 5.8 part of the standard distribution) may also
4371 help.
4372
4373 See also the POSIX module's C<pause> function.
4374
4375 =item sockatmark SOCKET
4376
4377 Returns true if the socket is positioned at the out-of-band mark
4378 (also known as the urgent data mark), false otherwise.  Use right
4379 after reading from the socket.
4380
4381 Not available directly, one has to import the function from
4382 the IO::Socket extension
4383
4384     use IO::Socket 'sockatmark';
4385
4386 Even this doesn't guarantee that sockatmark() really is available,
4387 though, because sockatmark() is a relatively recent addition to
4388 the family of socket functions.  If it is unavailable, attempt to
4389 use it will fail
4390
4391         IO::Socket::atmark not implemented on this architecture ...
4392
4393 See also L<IO::Socket>.
4394
4395 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4396
4397 Opens a socket of the specified kind and attaches it to filehandle
4398 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4399 the system call of the same name.  You should C<use Socket> first
4400 to get the proper definitions imported.  See the examples in
4401 L<perlipc/"Sockets: Client/Server Communication">.
4402
4403 On systems that support a close-on-exec flag on files, the flag will
4404 be set for the newly opened file descriptor, as determined by the
4405 value of $^F.  See L<perlvar/$^F>.
4406
4407 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4408
4409 Creates an unnamed pair of sockets in the specified domain, of the
4410 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4411 for the system call of the same name.  If unimplemented, yields a fatal
4412 error.  Returns true if successful.
4413
4414 On systems that support a close-on-exec flag on files, the flag will
4415 be set for the newly opened file descriptors, as determined by the value
4416 of $^F.  See L<perlvar/$^F>.
4417
4418 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4419 to C<pipe(Rdr, Wtr)> is essentially:
4420
4421     use Socket;
4422     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4423     shutdown(Rdr, 1);        # no more writing for reader
4424     shutdown(Wtr, 0);        # no more reading for writer
4425
4426 See L<perlipc> for an example of socketpair use.  Perl 5.8 and later will
4427 emulate socketpair using IP sockets to localhost if your system implements
4428 sockets but not socketpair.
4429
4430 =item sort SUBNAME LIST
4431
4432 =item sort BLOCK LIST
4433
4434 =item sort LIST
4435
4436 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
4437 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
4438 specified, it gives the name of a subroutine that returns an integer
4439 less than, equal to, or greater than C<0>, depending on how the elements
4440 of the list are to be ordered.  (The C<< <=> >> and C<cmp>
4441 operators are extremely useful in such routines.)  SUBNAME may be a
4442 scalar variable name (unsubscripted), in which case the value provides
4443 the name of (or a reference to) the actual subroutine to use.  In place
4444 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
4445 subroutine.
4446
4447 If the subroutine's prototype is C<($$)>, the elements to be compared
4448 are passed by reference in C<@_>, as for a normal subroutine.  This is
4449 slower than unprototyped subroutines, where the elements to be
4450 compared are passed into the subroutine
4451 as the package global variables $a and $b (see example below).  Note that
4452 in the latter case, it is usually counter-productive to declare $a and
4453 $b as lexicals.
4454
4455 In either case, the subroutine may not be recursive.  The values to be
4456 compared are always passed by reference, so don't modify them.
4457
4458 You also cannot exit out of the sort block or subroutine using any of the
4459 loop control operators described in L<perlsyn> or with C<goto>.
4460
4461 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4462 current collation locale.  See L<perllocale>.
4463
4464 Perl 5.6 and earlier used a quicksort algorithm to implement sort.
4465 That algorithm was not stable, and I<could> go quadratic.  (A I<stable> sort
4466 preserves the input order of elements that compare equal.  Although
4467 quicksort's run time is O(NlogN) when averaged over all arrays of
4468 length N, the time can be O(N**2), I<quadratic> behavior, for some
4469 inputs.)  In 5.7, the quicksort implementation was replaced with
4470 a stable mergesort algorithm whose worst case behavior is O(NlogN).
4471 But benchmarks indicated that for some inputs, on some platforms,
4472 the original quicksort was faster.  5.8 has a sort pragma for
4473 limited control of the sort.  Its rather blunt control of the
4474 underlying algorithm may not persist into future perls, but the
4475 ability to characterize the input or output in implementation
4476 independent ways quite probably will.  See L</use>.
4477
4478 Examples:
4479
4480     # sort lexically
4481     @articles = sort @files;
4482
4483     # same thing, but with explicit sort routine
4484     @articles = sort {$a cmp $b} @files;
4485
4486     # now case-insensitively
4487     @articles = sort {uc($a) cmp uc($b)} @files;
4488
4489     # same thing in reversed order
4490     @articles = sort {$b cmp $a} @files;
4491
4492     # sort numerically ascending
4493     @articles = sort {$a <=> $b} @files;
4494
4495     # sort numerically descending
4496     @articles = sort {$b <=> $a} @files;
4497
4498     # this sorts the %age hash by value instead of key
4499     # using an in-line function
4500     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4501
4502     # sort using explicit subroutine name
4503     sub byage {
4504         $age{$a} <=> $age{$b};  # presuming numeric
4505     }
4506     @sortedclass = sort byage @class;
4507
4508     sub backwards { $b cmp $a }
4509     @harry  = qw(dog cat x Cain Abel);
4510     @george = qw(gone chased yz Punished Axed);
4511     print sort @harry;
4512             # prints AbelCaincatdogx
4513     print sort backwards @harry;
4514             # prints xdogcatCainAbel
4515     print sort @george, 'to', @harry;
4516             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4517
4518     # inefficiently sort by descending numeric compare using
4519     # the first integer after the first = sign, or the
4520     # whole record case-insensitively otherwise
4521
4522     @new = sort {
4523         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4524                             ||
4525                     uc($a)  cmp  uc($b)
4526     } @old;
4527
4528     # same thing, but much more efficiently;
4529     # we'll build auxiliary indices instead
4530     # for speed
4531     @nums = @caps = ();
4532     for (@old) {
4533         push @nums, /=(\d+)/;
4534         push @caps, uc($_);
4535     }
4536
4537     @new = @old[ sort {
4538                         $nums[$b] <=> $nums[$a]
4539                                  ||
4540                         $caps[$a] cmp $caps[$b]
4541                        } 0..$#old
4542                ];
4543
4544     # same thing, but without any temps
4545     @new = map { $_->[0] }
4546            sort { $b->[1] <=> $a->[1]
4547                            ||
4548                   $a->[2] cmp $b->[2]
4549            } map { [$_, /=(\d+)/, uc($_)] } @old;
4550
4551     # using a prototype allows you to use any comparison subroutine
4552     # as a sort subroutine (including other package's subroutines)
4553     package other;
4554     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4555
4556     package main;
4557     @new = sort other::backwards @old;
4558
4559     # guarantee stability, regardless of algorithm
4560     use sort 'stable';
4561     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4562
4563     # force use of quicksort (not portable outside Perl 5.8)
4564     use sort '_quicksort';  # note discouraging _
4565     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4566
4567     # similar to the previous example, but demand stability as well
4568     use sort qw( _mergesort stable );
4569     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4570
4571 If you're using strict, you I<must not> declare $a
4572 and $b as lexicals.  They are package globals.  That means
4573 if you're in the C<main> package and type
4574
4575     @articles = sort {$b <=> $a} @files;
4576
4577 then C<$a> and C<$b> are C<$main::a> and C<$main::b> (or C<$::a> and C<$::b>),
4578 but if you're in the C<FooPack> package, it's the same as typing
4579
4580     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
4581
4582 The comparison function is required to behave.  If it returns
4583 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4584 sometimes saying the opposite, for example) the results are not
4585 well-defined.
4586
4587 =item splice ARRAY,OFFSET,LENGTH,LIST
4588
4589 =item splice ARRAY,OFFSET,LENGTH
4590
4591 =item splice ARRAY,OFFSET
4592
4593 =item splice ARRAY
4594
4595 Removes the elements designated by OFFSET and LENGTH from an array, and
4596 replaces them with the elements of LIST, if any.  In list context,
4597 returns the elements removed from the array.  In scalar context,
4598 returns the last element removed, or C<undef> if no elements are
4599 removed.  The array grows or shrinks as necessary.
4600 If OFFSET is negative then it starts that far from the end of the array.
4601 If LENGTH is omitted, removes everything from OFFSET onward.
4602 If LENGTH is negative, leaves that many elements off the end of the array.
4603 If both OFFSET and LENGTH are omitted, removes everything.
4604
4605 The following equivalences hold (assuming C<$[ == 0>):
4606
4607     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
4608     pop(@a)             splice(@a,-1)
4609     shift(@a)           splice(@a,0,1)
4610     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
4611     $a[$x] = $y         splice(@a,$x,1,$y)
4612
4613 Example, assuming array lengths are passed before arrays:
4614
4615     sub aeq {   # compare two list values
4616         my(@a) = splice(@_,0,shift);
4617         my(@b) = splice(@_,0,shift);
4618         return 0 unless @a == @b;       # same len?
4619         while (@a) {
4620             return 0 if pop(@a) ne pop(@b);
4621         }
4622         return 1;
4623     }
4624     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
4625
4626 =item split /PATTERN/,EXPR,LIMIT
4627
4628 =item split /PATTERN/,EXPR
4629
4630 =item split /PATTERN/
4631
4632 =item split
4633
4634 Splits a string into a list of strings and returns that list.  By default,
4635 empty leading fields are preserved, and empty trailing ones are deleted.
4636
4637 In scalar context, returns the number of fields found and splits into
4638 the C<@_> array.  Use of split in scalar context is deprecated, however,
4639 because it clobbers your subroutine arguments.
4640
4641 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
4642 splits on whitespace (after skipping any leading whitespace).  Anything
4643 matching PATTERN is taken to be a delimiter separating the fields.  (Note
4644 that the delimiter may be longer than one character.)
4645
4646 If LIMIT is specified and positive, it represents the maximum number
4647 of fields the EXPR will be split into, though the actual number of
4648 fields returned depends on the number of times PATTERN matches within
4649 EXPR.  If LIMIT is unspecified or zero, trailing null fields are
4650 stripped (which potential users