This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Storable: fixup huge
[perl5.git] / dist / Storable / t / huge.t
1 #!./perl
2
3 use strict;
4 use warnings;
5
6 use Config;
7 use Storable qw(dclone);
8 use Test::More;
9
10 BEGIN {
11     plan skip_all => 'Storable was not built'
12         if $ENV{PERL_CORE} && $Config{'extensions'} !~ /\b Storable \b/x;
13     plan skip_all => 'Need 64-bit pointers for this test'
14         if $Config{ptrsize} < 8;
15     plan skip_all => 'Need ~4 GiB memory for this test, set PERL_TEST_MEMORY > 4'
16         if !$ENV{PERL_TEST_MEMORY} || $ENV{PERL_TEST_MEMORY} < 4;
17 }
18
19 # Just too big to fit in an I32.
20 my $huge = int(2 ** 31);
21 #my $veryhuge = int(0x90000000); # go all the way
22
23 # These overlarge sizes are enabled only since Storable 3.00 and some
24 # cases need cperl support. Perl5 (as of 5.24) has some internal
25 # problems with >I32 sizes, which only cperl has fixed.
26 # hash key size: U32
27
28 my @cases = (
29     ['huge string',
30      sub { my $s = 'x' x $huge; \$s }],
31
32     ['array with huge element',
33      sub { my $s = 'x' x $huge; [$s] }],
34
35     # A hash with a huge number of keys would require tens of gigabytes of
36     # memory, which doesn't seem like a good idea even for this test file.
37
38     ['hash with huge value',
39      sub { my $s = 'x' x $huge; +{ foo => $s } }],
40
41     # Can't test hash with a huge key, because Perl internals currently
42     # limit hash keys to <2**31 length.
43   );
44
45 # v5.24.1c/v5.25.1c switched to die earlier with "Too many elements",
46 # which is much safer.
47 if (!($Config{usecperl} and
48       (($] >= 5.024001 and $] < 5.025000)
49        or $] >= 5.025001))) {
50   push @cases,
51     ['huge array',
52      sub { my @x; $x[$huge] = undef; \@x }],
53     # number of keys
54     ['huge hash',
55      sub { my %x = (0..$huge); \%x } ];
56 }
57
58
59 plan tests => 2 * scalar @cases;
60
61 for (@cases) {
62     my ($desc, $build) = @$_;
63     note "building test input: $desc";
64     my ($input, $exn, $clone);
65     if ($build) {
66       $input = $build->();
67       note "running test: $desc";
68       $exn = $@ if !eval { $clone = dclone($input); 1 };
69     }
70     if ($build && $Config{usecperl}) { # perl5 is not yet 2GB safe.
71         is($exn, undef, "$desc no exception");
72         is_deeply($clone, $input, "$desc cloned");
73     } else {
74         like($exn, qr/^Storable cannot yet handle data that needs a 64-bit machine\b/,
75              "$desc: throw an exception, not a segfault or panic");
76         ok(1, "$desc skip comparison");
77     }
78
79     # Ensure the huge objects are freed right now:
80     undef $input;
81     undef $clone;
82 }