This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Document lock’s retval
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
111 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 =item Regular expressions and pattern matching
115 X<regular expression> X<regex> X<regexp>
116
117 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
118
119 =item Numeric functions
120 X<numeric> X<number> X<trigonometric> X<trigonometry>
121
122 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
123 C<sin>, C<sqrt>, C<srand>
124
125 =item Functions for real @ARRAYs
126 X<array>
127
128 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
129
130 =item Functions for list data
131 X<list>
132
133 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
134
135 =item Functions for real %HASHes
136 X<hash>
137
138 C<delete>, C<each>, C<exists>, C<keys>, C<values>
139
140 =item Input and output functions
141 X<I/O> X<input> X<output> X<dbm>
142
143 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
144 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
145 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
146 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
147 C<warn>, C<write>
148
149 =item Functions for fixed-length data or records
150
151 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
152
153 =item Functions for filehandles, files, or directories
154 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
155
156 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
157 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
158 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
159 C<umask>, C<unlink>, C<utime>
160
161 =item Keywords related to the control flow of your Perl program
162 X<control flow>
163
164 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
165 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
166
167 =item Keywords related to the switch feature
168
169 C<break>, C<continue>, C<default>, C<given>, C<when>
170
171 Except for C<continue>, these are available only if you enable the
172 C<"switch"> feature or use the C<CORE::> prefix.
173 See L<feature> and L<perlsyn/"Switch statements">.  
174 Alternately, include a C<use v5.10> or later to the current scope.  In Perl
175 5.14 and earlier, C<continue> required the C<"switch"> feature, like the
176 other keywords.
177
178 =item Keywords related to scoping
179
180 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
181
182 C<state> is available only if the C<"state"> feature
183 is enabled or if it is prefixed with C<CORE::>. See
184 L<feature>.  Alternately, include a C<use v5.10> or later to the current scope.
185
186 =item Miscellaneous functions
187
188 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
189 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
190
191 =item Functions for processes and process groups
192 X<process> X<pid> X<process id>
193
194 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
195 C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
196 C<times>, C<wait>, C<waitpid>
197
198 =item Keywords related to Perl modules
199 X<module>
200
201 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
202
203 =item Keywords related to classes and object-orientation
204 X<object> X<class> X<package>
205
206 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
207 C<untie>, C<use>
208
209 =item Low-level socket functions
210 X<socket> X<sock>
211
212 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
213 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
214 C<socket>, C<socketpair>
215
216 =item System V interprocess communication functions
217 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
218
219 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
220 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
221
222 =item Fetching user and group info
223 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
224
225 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
226 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
227 C<getpwuid>, C<setgrent>, C<setpwent>
228
229 =item Fetching network info
230 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
231
232 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
233 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
234 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
235 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
236 C<setnetent>, C<setprotoent>, C<setservent>
237
238 =item Time-related functions
239 X<time> X<date>
240
241 C<gmtime>, C<localtime>, C<time>, C<times>
242
243 =item Functions new in perl5
244 X<perl5>
245
246 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
247 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
248 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
249 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
250 C<ucfirst>, C<untie>, C<use>, C<when>
251
252 * C<sub> was a keyword in Perl 4, but in Perl 5 it is an
253 operator, which can be used in expressions.
254
255 =item Functions obsoleted in perl5
256
257 C<dbmclose>, C<dbmopen>
258
259 =back
260
261 =head2 Portability
262 X<portability> X<Unix> X<portable>
263
264 Perl was born in Unix and can therefore access all common Unix
265 system calls.  In non-Unix environments, the functionality of some
266 Unix system calls may not be available or details of the available
267 functionality may differ slightly.  The Perl functions affected
268 by this are:
269
270 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
271 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
272 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
273 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
274 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
275 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
276 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
277 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
278 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
279 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
280 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
281 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
282 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
283 C<shmwrite>, C<socket>, C<socketpair>,
284 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
285 C<times>, C<truncate>, C<umask>, C<unlink>,
286 C<utime>, C<wait>, C<waitpid>
287
288 For more information about the portability of these functions, see
289 L<perlport> and other available platform-specific documentation.
290
291 =head2 Alphabetical Listing of Perl Functions
292
293 =over 
294
295 =item -X FILEHANDLE
296 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
297 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
298
299 =item -X EXPR
300
301 =item -X DIRHANDLE
302
303 =item -X
304
305 A file test, where X is one of the letters listed below.  This unary
306 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
307 and tests the associated file to see if something is true about it.  If the
308 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
309 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
310 the undefined value if the file doesn't exist.  Despite the funny
311 names, precedence is the same as any other named unary operator.  The
312 operator may be any of:
313
314     -r  File is readable by effective uid/gid.
315     -w  File is writable by effective uid/gid.
316     -x  File is executable by effective uid/gid.
317     -o  File is owned by effective uid.
318
319     -R  File is readable by real uid/gid.
320     -W  File is writable by real uid/gid.
321     -X  File is executable by real uid/gid.
322     -O  File is owned by real uid.
323
324     -e  File exists.
325     -z  File has zero size (is empty).
326     -s  File has nonzero size (returns size in bytes).
327
328     -f  File is a plain file.
329     -d  File is a directory.
330     -l  File is a symbolic link.
331     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
332     -S  File is a socket.
333     -b  File is a block special file.
334     -c  File is a character special file.
335     -t  Filehandle is opened to a tty.
336
337     -u  File has setuid bit set.
338     -g  File has setgid bit set.
339     -k  File has sticky bit set.
340
341     -T  File is an ASCII text file (heuristic guess).
342     -B  File is a "binary" file (opposite of -T).
343
344     -M  Script start time minus file modification time, in days.
345     -A  Same for access time.
346     -C  Same for inode change time (Unix, may differ for other platforms)
347
348 Example:
349
350     while (<>) {
351         chomp;
352         next unless -f $_;  # ignore specials
353         #...
354     }
355
356 Note that C<-s/a/b/> does not do a negated substitution.  Saying
357 C<-exp($foo)> still works as expected, however: only single letters
358 following a minus are interpreted as file tests.
359
360 These operators are exempt from the "looks like a function rule" described
361 above. That is, an opening parenthesis after the operator does not affect
362 how much of the following code constitutes the argument. Put the opening
363 parentheses before the operator to separate it from code that follows (this
364 applies only to operators with higher precedence than unary operators, of
365 course):
366
367     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
368     (-s $file) + 1024  # correct
369
370 The interpretation of the file permission operators C<-r>, C<-R>,
371 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
372 of the file and the uids and gids of the user.  There may be other
373 reasons you can't actually read, write, or execute the file: for
374 example network filesystem access controls, ACLs (access control lists),
375 read-only filesystems, and unrecognized executable formats.  Note
376 that the use of these six specific operators to verify if some operation
377 is possible is usually a mistake, because it may be open to race
378 conditions.
379
380 Also note that, for the superuser on the local filesystems, the C<-r>,
381 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
382 if any execute bit is set in the mode.  Scripts run by the superuser
383 may thus need to do a stat() to determine the actual mode of the file,
384 or temporarily set their effective uid to something else.
385
386 If you are using ACLs, there is a pragma called C<filetest> that may
387 produce more accurate results than the bare stat() mode bits.
388 When under C<use filetest 'access'> the above-mentioned filetests
389 test whether the permission can(not) be granted using the
390 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
391 under this pragma return true even if there are no execute permission
392 bits set (nor any extra execute permission ACLs).  This strangeness is
393 due to the underlying system calls' definitions. Note also that, due to
394 the implementation of C<use filetest 'access'>, the C<_> special
395 filehandle won't cache the results of the file tests when this pragma is
396 in effect.  Read the documentation for the C<filetest> pragma for more
397 information.
398
399 The C<-T> and C<-B> switches work as follows.  The first block or so of the
400 file is examined for odd characters such as strange control codes or
401 characters with the high bit set.  If too many strange characters (>30%)
402 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
403 containing a zero byte in the first block is considered a binary file.  If C<-T>
404 or C<-B> is used on a filehandle, the current IO buffer is examined
405 rather than the first block.  Both C<-T> and C<-B> return true on an empty
406 file, or a file at EOF when testing a filehandle.  Because you have to
407 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
408 against the file first, as in C<next unless -f $file && -T $file>.
409
410 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
411 the special filehandle consisting of a solitary underline, then the stat
412 structure of the previous file test (or stat operator) is used, saving
413 a system call.  (This doesn't work with C<-t>, and you need to remember
414 that lstat() and C<-l> leave values in the stat structure for the
415 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
416 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
417 Example:
418
419     print "Can do.\n" if -r $a || -w _ || -x _;
420
421     stat($filename);
422     print "Readable\n" if -r _;
423     print "Writable\n" if -w _;
424     print "Executable\n" if -x _;
425     print "Setuid\n" if -u _;
426     print "Setgid\n" if -g _;
427     print "Sticky\n" if -k _;
428     print "Text\n" if -T _;
429     print "Binary\n" if -B _;
430
431 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
432 test operators, in a way that C<-f -w -x $file> is equivalent to
433 C<-x $file && -w _ && -f _>. (This is only fancy fancy: if you use
434 the return value of C<-f $file> as an argument to another filetest
435 operator, no special magic will happen.)
436
437 Portability issues: L<perlport/-X>.
438
439 =item abs VALUE
440 X<abs> X<absolute>
441
442 =item abs
443
444 Returns the absolute value of its argument.
445 If VALUE is omitted, uses C<$_>.
446
447 =item accept NEWSOCKET,GENERICSOCKET
448 X<accept>
449
450 Accepts an incoming socket connect, just as accept(2) 
451 does.  Returns the packed address if it succeeded, false otherwise.
452 See the example in L<perlipc/"Sockets: Client/Server Communication">.
453
454 On systems that support a close-on-exec flag on files, the flag will
455 be set for the newly opened file descriptor, as determined by the
456 value of $^F.  See L<perlvar/$^F>.
457
458 =item alarm SECONDS
459 X<alarm>
460 X<SIGALRM>
461 X<timer>
462
463 =item alarm
464
465 Arranges to have a SIGALRM delivered to this process after the
466 specified number of wallclock seconds has elapsed.  If SECONDS is not
467 specified, the value stored in C<$_> is used. (On some machines,
468 unfortunately, the elapsed time may be up to one second less or more
469 than you specified because of how seconds are counted, and process
470 scheduling may delay the delivery of the signal even further.)
471
472 Only one timer may be counting at once.  Each call disables the
473 previous timer, and an argument of C<0> may be supplied to cancel the
474 previous timer without starting a new one.  The returned value is the
475 amount of time remaining on the previous timer.
476
477 For delays of finer granularity than one second, the Time::HiRes module
478 (from CPAN, and starting from Perl 5.8 part of the standard
479 distribution) provides ualarm().  You may also use Perl's four-argument
480 version of select() leaving the first three arguments undefined, or you
481 might be able to use the C<syscall> interface to access setitimer(2) if
482 your system supports it. See L<perlfaq8> for details.
483
484 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
485 C<sleep> may be internally implemented on your system with C<alarm>.
486
487 If you want to use C<alarm> to time out a system call you need to use an
488 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
489 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
490 restart system calls on some systems.  Using C<eval>/C<die> always works,
491 modulo the caveats given in L<perlipc/"Signals">.
492
493     eval {
494         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
495         alarm $timeout;
496         $nread = sysread SOCKET, $buffer, $size;
497         alarm 0;
498     };
499     if ($@) {
500         die unless $@ eq "alarm\n";   # propagate unexpected errors
501         # timed out
502     }
503     else {
504         # didn't
505     }
506
507 For more information see L<perlipc>.
508
509 Portability issues: L<perlport/alarm>.
510
511 =item atan2 Y,X
512 X<atan2> X<arctangent> X<tan> X<tangent>
513
514 Returns the arctangent of Y/X in the range -PI to PI.
515
516 For the tangent operation, you may use the C<Math::Trig::tan>
517 function, or use the familiar relation:
518
519     sub tan { sin($_[0]) / cos($_[0])  }
520
521 The return value for C<atan2(0,0)> is implementation-defined; consult
522 your atan2(3) manpage for more information.
523
524 Portability issues: L<perlport/atan2>.
525
526 =item bind SOCKET,NAME
527 X<bind>
528
529 Binds a network address to a socket, just as bind(2)
530 does.  Returns true if it succeeded, false otherwise.  NAME should be a
531 packed address of the appropriate type for the socket.  See the examples in
532 L<perlipc/"Sockets: Client/Server Communication">.
533
534 =item binmode FILEHANDLE, LAYER
535 X<binmode> X<binary> X<text> X<DOS> X<Windows>
536
537 =item binmode FILEHANDLE
538
539 Arranges for FILEHANDLE to be read or written in "binary" or "text"
540 mode on systems where the run-time libraries distinguish between
541 binary and text files.  If FILEHANDLE is an expression, the value is
542 taken as the name of the filehandle.  Returns true on success,
543 otherwise it returns C<undef> and sets C<$!> (errno).
544
545 On some systems (in general, DOS- and Windows-based systems) binmode()
546 is necessary when you're not working with a text file.  For the sake
547 of portability it is a good idea always to use it when appropriate,
548 and never to use it when it isn't appropriate.  Also, people can
549 set their I/O to be by default UTF8-encoded Unicode, not bytes.
550
551 In other words: regardless of platform, use binmode() on binary data,
552 like images, for example.
553
554 If LAYER is present it is a single string, but may contain multiple
555 directives. The directives alter the behaviour of the filehandle.
556 When LAYER is present, using binmode on a text file makes sense.
557
558 If LAYER is omitted or specified as C<:raw> the filehandle is made
559 suitable for passing binary data. This includes turning off possible CRLF
560 translation and marking it as bytes (as opposed to Unicode characters).
561 Note that, despite what may be implied in I<"Programming Perl"> (the
562 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
563 Other layers that would affect the binary nature of the stream are
564 I<also> disabled. See L<PerlIO>, L<perlrun>, and the discussion about the
565 PERLIO environment variable.
566
567 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
568 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
569 establish default I/O layers.  See L<open>.
570
571 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
572 in "Programming Perl, 3rd Edition".  However, since the publishing of this
573 book, by many known as "Camel III", the consensus of the naming of this
574 functionality has moved from "discipline" to "layer".  All documentation
575 of this version of Perl therefore refers to "layers" rather than to
576 "disciplines".  Now back to the regularly scheduled documentation...>
577
578 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
579 C<:utf8> just marks the data as UTF-8 without further checking,
580 while C<:encoding(UTF-8)> checks the data for actually being valid
581 UTF-8. More details can be found in L<PerlIO::encoding>.
582
583 In general, binmode() should be called after open() but before any I/O
584 is done on the filehandle.  Calling binmode() normally flushes any
585 pending buffered output data (and perhaps pending input data) on the
586 handle.  An exception to this is the C<:encoding> layer that
587 changes the default character encoding of the handle; see L</open>.
588 The C<:encoding> layer sometimes needs to be called in
589 mid-stream, and it doesn't flush the stream.  The C<:encoding>
590 also implicitly pushes on top of itself the C<:utf8> layer because
591 internally Perl operates on UTF8-encoded Unicode characters.
592
593 The operating system, device drivers, C libraries, and Perl run-time
594 system all conspire to let the programmer treat a single
595 character (C<\n>) as the line terminator, irrespective of external
596 representation.  On many operating systems, the native text file
597 representation matches the internal representation, but on some
598 platforms the external representation of C<\n> is made up of more than
599 one character.
600
601 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
602 a single character to end each line in the external representation of text
603 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
604 flavors of Mac OS, and is LINE FEED on Unix and most VMS files). In other
605 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
606 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
607 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
608 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
609 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
610 output.  This is what you want for text files, but it can be disastrous for
611 binary files.
612
613 Another consequence of using binmode() (on some systems) is that
614 special end-of-file markers will be seen as part of the data stream.
615 For systems from the Microsoft family this means that, if your binary
616 data contain C<\cZ>, the I/O subsystem will regard it as the end of
617 the file, unless you use binmode().
618
619 binmode() is important not only for readline() and print() operations,
620 but also when using read(), seek(), sysread(), syswrite() and tell()
621 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
622 in L<perlvar> for how to manually set your input and output
623 line-termination sequences.
624
625 Portability issues: L<perlport/binmode>.
626
627 =item bless REF,CLASSNAME
628 X<bless>
629
630 =item bless REF
631
632 This function tells the thingy referenced by REF that it is now an object
633 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
634 is used.  Because a C<bless> is often the last thing in a constructor,
635 it returns the reference for convenience.  Always use the two-argument
636 version if a derived class might inherit the function doing the blessing.
637 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
638 of objects.
639
640 Consider always blessing objects in CLASSNAMEs that are mixed case.
641 Namespaces with all lowercase names are considered reserved for
642 Perl pragmata.  Builtin types have all uppercase names. To prevent
643 confusion, you may wish to avoid such package names as well.  Make sure
644 that CLASSNAME is a true value.
645
646 See L<perlmod/"Perl Modules">.
647
648 =item break
649
650 Break out of a C<given()> block.
651
652 This keyword is enabled by the C<"switch"> feature: see
653 L<feature> for more information.  You can also access it by
654 prefixing it with C<CORE::>.  Alternately, include a C<use
655 v5.10> or later to the current scope.
656
657 =item caller EXPR
658 X<caller> X<call stack> X<stack> X<stack trace>
659
660 =item caller
661
662 Returns the context of the current subroutine call.  In scalar context,
663 returns the caller's package name if there I<is> a caller (that is, if
664 we're in a subroutine or C<eval> or C<require>) and the undefined value
665 otherwise.  In list context, returns
666
667     # 0         1          2
668     ($package, $filename, $line) = caller;
669
670 With EXPR, it returns some extra information that the debugger uses to
671 print a stack trace.  The value of EXPR indicates how many call frames
672 to go back before the current one.
673
674     #  0         1          2      3            4
675     ($package, $filename, $line, $subroutine, $hasargs,
676
677     #  5          6          7            8       9         10
678     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
679      = caller($i);
680
681 Here $subroutine may be C<(eval)> if the frame is not a subroutine
682 call, but an C<eval>.  In such a case additional elements $evaltext and
683 C<$is_require> are set: C<$is_require> is true if the frame is created by a
684 C<require> or C<use> statement, $evaltext contains the text of the
685 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
686 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
687 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
688 frame.)  $subroutine may also be C<(unknown)> if this particular
689 subroutine happens to have been deleted from the symbol table.
690 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
691 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
692 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
693 between versions of Perl, and are not meant for external use.
694
695 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
696 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
697 of this hash, as they are the actual values stored in the optree.
698
699 Furthermore, when called from within the DB package, caller returns more
700 detailed information: it sets the list variable C<@DB::args> to be the
701 arguments with which the subroutine was invoked.
702
703 Be aware that the optimizer might have optimized call frames away before
704 C<caller> had a chance to get the information.  That means that C<caller(N)>
705 might not return information about the call frame you expect it to, for
706 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
707 previous time C<caller> was called.
708
709 Be aware that setting C<@DB::args> is I<best effort>, intended for
710 debugging or generating backtraces, and should not be relied upon. In
711 particular, as C<@_> contains aliases to the caller's arguments, Perl does
712 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
713 subroutine makes to C<@_> or its contents, not the original values at call
714 time. C<@DB::args>, like C<@_>, does not hold explicit references to its
715 elements, so under certain cases its elements may have become freed and
716 reallocated for other variables or temporary values. Finally, a side effect
717 of the current implementation is that the effects of C<shift @_> can
718 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
719 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
720 elements), so C<@DB::args> is actually a hybrid of the current state and
721 initial state of C<@_>. Buyer beware.
722
723 =item chdir EXPR
724 X<chdir>
725 X<cd>
726 X<directory, change>
727
728 =item chdir FILEHANDLE
729
730 =item chdir DIRHANDLE
731
732 =item chdir
733
734 Changes the working directory to EXPR, if possible. If EXPR is omitted,
735 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
736 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
737 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
738 neither is set, C<chdir> does nothing. It returns true on success,
739 false otherwise. See the example under C<die>.
740
741 On systems that support fchdir(2), you may pass a filehandle or
742 directory handle as the argument.  On systems that don't support fchdir(2),
743 passing handles raises an exception.
744
745 =item chmod LIST
746 X<chmod> X<permission> X<mode>
747
748 Changes the permissions of a list of files.  The first element of the
749 list must be the numeric mode, which should probably be an octal
750 number, and which definitely should I<not> be a string of octal digits:
751 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
752 successfully changed.  See also L</oct> if all you have is a string.
753
754     $cnt = chmod 0755, "foo", "bar";
755     chmod 0755, @executables;
756     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
757                                              # --w----r-T
758     $mode = "0644"; chmod oct($mode), "foo"; # this is better
759     $mode = 0644;   chmod $mode, "foo";      # this is best
760
761 On systems that support fchmod(2), you may pass filehandles among the
762 files.  On systems that don't support fchmod(2), passing filehandles raises
763 an exception.  Filehandles must be passed as globs or glob references to be
764 recognized; barewords are considered filenames.
765
766     open(my $fh, "<", "foo");
767     my $perm = (stat $fh)[2] & 07777;
768     chmod($perm | 0600, $fh);
769
770 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
771 module:
772
773     use Fcntl qw( :mode );
774     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
775     # Identical to the chmod 0755 of the example above.
776
777 Portability issues: L<perlport/chmod>.
778
779 =item chomp VARIABLE
780 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
781
782 =item chomp( LIST )
783
784 =item chomp
785
786 This safer version of L</chop> removes any trailing string
787 that corresponds to the current value of C<$/> (also known as
788 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
789 number of characters removed from all its arguments.  It's often used to
790 remove the newline from the end of an input record when you're worried
791 that the final record may be missing its newline.  When in paragraph
792 mode (C<$/ = "">), it removes all trailing newlines from the string.
793 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
794 a reference to an integer or the like; see L<perlvar>) chomp() won't
795 remove anything.
796 If VARIABLE is omitted, it chomps C<$_>.  Example:
797
798     while (<>) {
799         chomp;  # avoid \n on last field
800         @array = split(/:/);
801         # ...
802     }
803
804 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
805
806 You can actually chomp anything that's an lvalue, including an assignment:
807
808     chomp($cwd = `pwd`);
809     chomp($answer = <STDIN>);
810
811 If you chomp a list, each element is chomped, and the total number of
812 characters removed is returned.
813
814 Note that parentheses are necessary when you're chomping anything
815 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
816 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
817 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
818 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
819 as C<chomp($a, $b)>.
820
821 =item chop VARIABLE
822 X<chop>
823
824 =item chop( LIST )
825
826 =item chop
827
828 Chops off the last character of a string and returns the character
829 chopped.  It is much more efficient than C<s/.$//s> because it neither
830 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
831 If VARIABLE is a hash, it chops the hash's values, but not its keys.
832
833 You can actually chop anything that's an lvalue, including an assignment.
834
835 If you chop a list, each element is chopped.  Only the value of the
836 last C<chop> is returned.
837
838 Note that C<chop> returns the last character.  To return all but the last
839 character, use C<substr($string, 0, -1)>.
840
841 See also L</chomp>.
842
843 =item chown LIST
844 X<chown> X<owner> X<user> X<group>
845
846 Changes the owner (and group) of a list of files.  The first two
847 elements of the list must be the I<numeric> uid and gid, in that
848 order.  A value of -1 in either position is interpreted by most
849 systems to leave that value unchanged.  Returns the number of files
850 successfully changed.
851
852     $cnt = chown $uid, $gid, 'foo', 'bar';
853     chown $uid, $gid, @filenames;
854
855 On systems that support fchown(2), you may pass filehandles among the
856 files.  On systems that don't support fchown(2), passing filehandles raises
857 an exception.  Filehandles must be passed as globs or glob references to be
858 recognized; barewords are considered filenames.
859
860 Here's an example that looks up nonnumeric uids in the passwd file:
861
862     print "User: ";
863     chomp($user = <STDIN>);
864     print "Files: ";
865     chomp($pattern = <STDIN>);
866
867     ($login,$pass,$uid,$gid) = getpwnam($user)
868         or die "$user not in passwd file";
869
870     @ary = glob($pattern);  # expand filenames
871     chown $uid, $gid, @ary;
872
873 On most systems, you are not allowed to change the ownership of the
874 file unless you're the superuser, although you should be able to change
875 the group to any of your secondary groups.  On insecure systems, these
876 restrictions may be relaxed, but this is not a portable assumption.
877 On POSIX systems, you can detect this condition this way:
878
879     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
880     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
881
882 Portability issues: L<perlport/chmod>.
883
884 =item chr NUMBER
885 X<chr> X<character> X<ASCII> X<Unicode>
886
887 =item chr
888
889 Returns the character represented by that NUMBER in the character set.
890 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
891 chr(0x263a) is a Unicode smiley face.  
892
893 Negative values give the Unicode replacement character (chr(0xfffd)),
894 except under the L<bytes> pragma, where the low eight bits of the value
895 (truncated to an integer) are used.
896
897 If NUMBER is omitted, uses C<$_>.
898
899 For the reverse, use L</ord>.
900
901 Note that characters from 128 to 255 (inclusive) are by default
902 internally not encoded as UTF-8 for backward compatibility reasons.
903
904 See L<perlunicode> for more about Unicode.
905
906 =item chroot FILENAME
907 X<chroot> X<root>
908
909 =item chroot
910
911 This function works like the system call by the same name: it makes the
912 named directory the new root directory for all further pathnames that
913 begin with a C</> by your process and all its children.  (It doesn't
914 change your current working directory, which is unaffected.)  For security
915 reasons, this call is restricted to the superuser.  If FILENAME is
916 omitted, does a C<chroot> to C<$_>.
917
918 Portability issues: L<perlport/chroot>.
919
920 =item close FILEHANDLE
921 X<close>
922
923 =item close
924
925 Closes the file or pipe associated with the filehandle, flushes the IO
926 buffers, and closes the system file descriptor.  Returns true if those
927 operations succeed and if no error was reported by any PerlIO
928 layer.  Closes the currently selected filehandle if the argument is
929 omitted.
930
931 You don't have to close FILEHANDLE if you are immediately going to do
932 another C<open> on it, because C<open> closes it for you.  (See
933 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
934 counter (C<$.>), while the implicit close done by C<open> does not.
935
936 If the filehandle came from a piped open, C<close> returns false if one of
937 the other syscalls involved fails or if its program exits with non-zero
938 status.  If the only problem was that the program exited non-zero, C<$!>
939 will be set to C<0>.  Closing a pipe also waits for the process executing
940 on the pipe to exit--in case you wish to look at the output of the pipe
941 afterwards--and implicitly puts the exit status value of that command into
942 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
943
944 If there are multiple threads running, C<close> on a filehandle from a
945 piped open returns true without waiting for the child process to terminate,
946 if the filehandle is still open in another thread.
947
948 Closing the read end of a pipe before the process writing to it at the
949 other end is done writing results in the writer receiving a SIGPIPE.  If
950 the other end can't handle that, be sure to read all the data before
951 closing the pipe.
952
953 Example:
954
955     open(OUTPUT, '|sort >foo')  # pipe to sort
956         or die "Can't start sort: $!";
957     #...                        # print stuff to output
958     close OUTPUT                # wait for sort to finish
959         or warn $! ? "Error closing sort pipe: $!"
960                    : "Exit status $? from sort";
961     open(INPUT, 'foo')          # get sort's results
962         or die "Can't open 'foo' for input: $!";
963
964 FILEHANDLE may be an expression whose value can be used as an indirect
965 filehandle, usually the real filehandle name or an autovivified handle.
966
967 =item closedir DIRHANDLE
968 X<closedir>
969
970 Closes a directory opened by C<opendir> and returns the success of that
971 system call.
972
973 =item connect SOCKET,NAME
974 X<connect>
975
976 Attempts to connect to a remote socket, just like connect(2).
977 Returns true if it succeeded, false otherwise.  NAME should be a
978 packed address of the appropriate type for the socket.  See the examples in
979 L<perlipc/"Sockets: Client/Server Communication">.
980
981 =item continue BLOCK
982 X<continue>
983
984 =item continue
985
986 When followed by a BLOCK, C<continue> is actually a
987 flow control statement rather than a function.  If
988 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
989 C<foreach>), it is always executed just before the conditional is about to
990 be evaluated again, just like the third part of a C<for> loop in C.  Thus
991 it can be used to increment a loop variable, even when the loop has been
992 continued via the C<next> statement (which is similar to the C C<continue>
993 statement).
994
995 C<last>, C<next>, or C<redo> may appear within a C<continue>
996 block; C<last> and C<redo> behave as if they had been executed within
997 the main block.  So will C<next>, but since it will execute a C<continue>
998 block, it may be more entertaining.
999
1000     while (EXPR) {
1001         ### redo always comes here
1002         do_something;
1003     } continue {
1004         ### next always comes here
1005         do_something_else;
1006         # then back the top to re-check EXPR
1007     }
1008     ### last always comes here
1009
1010 Omitting the C<continue> section is equivalent to using an
1011 empty one, logically enough, so C<next> goes directly back
1012 to check the condition at the top of the loop.
1013
1014 When there is no BLOCK, C<continue> is a function that
1015 falls through the current C<when> or C<default> block instead of iterating
1016 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1017 In Perl 5.14 and earlier, this form of C<continue> was
1018 only available when the C<"switch"> feature was enabled.
1019 See L<feature> and L<perlsyn/"Switch statements"> for more
1020 information.
1021
1022 =item cos EXPR
1023 X<cos> X<cosine> X<acos> X<arccosine>
1024
1025 =item cos
1026
1027 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1028 takes the cosine of C<$_>.
1029
1030 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1031 function, or use this relation:
1032
1033     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1034
1035 =item crypt PLAINTEXT,SALT
1036 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1037 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1038
1039 Creates a digest string exactly like the crypt(3) function in the C
1040 library (assuming that you actually have a version there that has not
1041 been extirpated as a potential munition).
1042
1043 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1044 into a short string, called a digest, which is returned.  The same
1045 PLAINTEXT and SALT will always return the same string, but there is no
1046 (known) way to get the original PLAINTEXT from the hash.  Small
1047 changes in the PLAINTEXT or SALT will result in large changes in the
1048 digest.
1049
1050 There is no decrypt function.  This function isn't all that useful for
1051 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1052 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1053 primarily used to check if two pieces of text are the same without
1054 having to transmit or store the text itself.  An example is checking
1055 if a correct password is given.  The digest of the password is stored,
1056 not the password itself.  The user types in a password that is
1057 crypt()'d with the same salt as the stored digest.  If the two digests
1058 match, the password is correct.
1059
1060 When verifying an existing digest string you should use the digest as
1061 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1062 to create the digest is visible as part of the digest.  This ensures
1063 crypt() will hash the new string with the same salt as the digest.
1064 This allows your code to work with the standard L<crypt|/crypt> and
1065 with more exotic implementations.  In other words, assume
1066 nothing about the returned string itself nor about how many bytes 
1067 of SALT may matter.
1068
1069 Traditionally the result is a string of 13 bytes: two first bytes of
1070 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1071 the first eight bytes of PLAINTEXT mattered. But alternative
1072 hashing schemes (like MD5), higher level security schemes (like C2),
1073 and implementations on non-Unix platforms may produce different
1074 strings.
1075
1076 When choosing a new salt create a random two character string whose
1077 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1078 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1079 characters is just a recommendation; the characters allowed in
1080 the salt depend solely on your system's crypt library, and Perl can't
1081 restrict what salts C<crypt()> accepts.
1082
1083 Here's an example that makes sure that whoever runs this program knows
1084 their password:
1085
1086     $pwd = (getpwuid($<))[1];
1087
1088     system "stty -echo";
1089     print "Password: ";
1090     chomp($word = <STDIN>);
1091     print "\n";
1092     system "stty echo";
1093
1094     if (crypt($word, $pwd) ne $pwd) {
1095         die "Sorry...\n";
1096     } else {
1097         print "ok\n";
1098     }
1099
1100 Of course, typing in your own password to whoever asks you
1101 for it is unwise.
1102
1103 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1104 of data, not least of all because you can't get the information
1105 back.  Look at the L<Digest> module for more robust algorithms.
1106
1107 If using crypt() on a Unicode string (which I<potentially> has
1108 characters with codepoints above 255), Perl tries to make sense
1109 of the situation by trying to downgrade (a copy of)
1110 the string back to an eight-bit byte string before calling crypt()
1111 (on that copy).  If that works, good.  If not, crypt() dies with
1112 C<Wide character in crypt>.
1113
1114 Portability issues: L<perlport/crypt>.
1115
1116 =item dbmclose HASH
1117 X<dbmclose>
1118
1119 [This function has been largely superseded by the C<untie> function.]
1120
1121 Breaks the binding between a DBM file and a hash.
1122
1123 Portability issues: L<perlport/dbmclose>.
1124
1125 =item dbmopen HASH,DBNAME,MASK
1126 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1127
1128 [This function has been largely superseded by the
1129 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1130
1131 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1132 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1133 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1134 is the name of the database (without the F<.dir> or F<.pag> extension if
1135 any).  If the database does not exist, it is created with protection
1136 specified by MASK (as modified by the C<umask>).  If your system supports
1137 only the older DBM functions, you may make only one C<dbmopen> call in your
1138 program.  In older versions of Perl, if your system had neither DBM nor
1139 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1140 sdbm(3).
1141
1142 If you don't have write access to the DBM file, you can only read hash
1143 variables, not set them.  If you want to test whether you can write,
1144 either use file tests or try setting a dummy hash entry inside an C<eval> 
1145 to trap the error.
1146
1147 Note that functions such as C<keys> and C<values> may return huge lists
1148 when used on large DBM files.  You may prefer to use the C<each>
1149 function to iterate over large DBM files.  Example:
1150
1151     # print out history file offsets
1152     dbmopen(%HIST,'/usr/lib/news/history',0666);
1153     while (($key,$val) = each %HIST) {
1154         print $key, ' = ', unpack('L',$val), "\n";
1155     }
1156     dbmclose(%HIST);
1157
1158 See also L<AnyDBM_File> for a more general description of the pros and
1159 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1160 rich implementation.
1161
1162 You can control which DBM library you use by loading that library
1163 before you call dbmopen():
1164
1165     use DB_File;
1166     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1167         or die "Can't open netscape history file: $!";
1168
1169 Portability issues: L<perlport/dbmopen>.
1170
1171 =item default BLOCK
1172
1173 Within a C<foreach> or a C<given>, a C<default> BLOCK acts like a C<when>
1174 that's always true.  Only available after Perl 5.10, and only if the
1175 C<switch> feature has been requested or if the keyword is prefixed with
1176 C<CORE::>.  See L</when>.
1177
1178 =item defined EXPR
1179 X<defined> X<undef> X<undefined>
1180
1181 =item defined
1182
1183 Returns a Boolean value telling whether EXPR has a value other than
1184 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1185 checked.
1186
1187 Many operations return C<undef> to indicate failure, end of file,
1188 system error, uninitialized variable, and other exceptional
1189 conditions.  This function allows you to distinguish C<undef> from
1190 other values.  (A simple Boolean test will not distinguish among
1191 C<undef>, zero, the empty string, and C<"0">, which are all equally
1192 false.)  Note that since C<undef> is a valid scalar, its presence
1193 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1194 returns C<undef> when its argument is an empty array, I<or> when the
1195 element to return happens to be C<undef>.
1196
1197 You may also use C<defined(&func)> to check whether subroutine C<&func>
1198 has ever been defined.  The return value is unaffected by any forward
1199 declarations of C<&func>.  A subroutine that is not defined
1200 may still be callable: its package may have an C<AUTOLOAD> method that
1201 makes it spring into existence the first time that it is called; see
1202 L<perlsub>.
1203
1204 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1205 used to report whether memory for that aggregate had ever been
1206 allocated.  This behavior may disappear in future versions of Perl.
1207 You should instead use a simple test for size:
1208
1209     if (@an_array) { print "has array elements\n" }
1210     if (%a_hash)   { print "has hash members\n"   }
1211
1212 When used on a hash element, it tells you whether the value is defined,
1213 not whether the key exists in the hash.  Use L</exists> for the latter
1214 purpose.
1215
1216 Examples:
1217
1218     print if defined $switch{D};
1219     print "$val\n" while defined($val = pop(@ary));
1220     die "Can't readlink $sym: $!"
1221         unless defined($value = readlink $sym);
1222     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1223     $debugging = 0 unless defined $debugging;
1224
1225 Note:  Many folks tend to overuse C<defined> and are then surprised to
1226 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1227 defined values.  For example, if you say
1228
1229     "ab" =~ /a(.*)b/;
1230
1231 The pattern match succeeds and C<$1> is defined, although it
1232 matched "nothing".  It didn't really fail to match anything.  Rather, it
1233 matched something that happened to be zero characters long.  This is all
1234 very above-board and honest.  When a function returns an undefined value,
1235 it's an admission that it couldn't give you an honest answer.  So you
1236 should use C<defined> only when questioning the integrity of what
1237 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1238 what you want.
1239
1240 See also L</undef>, L</exists>, L</ref>.
1241
1242 =item delete EXPR
1243 X<delete>
1244
1245 Given an expression that specifies an element or slice of a hash, C<delete>
1246 deletes the specified elements from that hash so that exists() on that element
1247 no longer returns true.  Setting a hash element to the undefined value does
1248 not remove its key, but deleting it does; see L</exists>.
1249
1250 In list context, returns the value or values deleted, or the last such
1251 element in scalar context.  The return list's length always matches that of
1252 the argument list: deleting non-existent elements returns the undefined value
1253 in their corresponding positions.
1254
1255 delete() may also be used on arrays and array slices, but its behavior is less
1256 straightforward.  Although exists() will return false for deleted entries,
1257 deleting array elements never changes indices of existing values; use shift()
1258 or splice() for that.  However, if all deleted elements fall at the end of an
1259 array, the array's size shrinks to the position of the highest element that
1260 still tests true for exists(), or to 0 if none do.
1261
1262 B<WARNING:> Calling delete on array values is deprecated and likely to
1263 be removed in a future version of Perl.
1264
1265 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1266 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1267 or array may not necessarily return anything; it depends on the implementation
1268 of the C<tied> package's DELETE method, which may do whatever it pleases.
1269
1270 The C<delete local EXPR> construct localizes the deletion to the current
1271 block at run time.  Until the block exits, elements locally deleted
1272 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1273 of composite types">.
1274
1275     %hash = (foo => 11, bar => 22, baz => 33);
1276     $scalar = delete $hash{foo};             # $scalar is 11
1277     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1278     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1279
1280 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1281
1282     foreach $key (keys %HASH) {
1283         delete $HASH{$key};
1284     }
1285
1286     foreach $index (0 .. $#ARRAY) {
1287         delete $ARRAY[$index];
1288     }
1289
1290 And so do these:
1291
1292     delete @HASH{keys %HASH};
1293
1294     delete @ARRAY[0 .. $#ARRAY];
1295
1296 But both are slower than assigning the empty list
1297 or undefining %HASH or @ARRAY, which is the customary 
1298 way to empty out an aggregate:
1299
1300     %HASH = ();     # completely empty %HASH
1301     undef %HASH;    # forget %HASH ever existed
1302
1303     @ARRAY = ();    # completely empty @ARRAY
1304     undef @ARRAY;   # forget @ARRAY ever existed
1305
1306 The EXPR can be arbitrarily complicated provided its
1307 final operation is an element or slice of an aggregate:
1308
1309     delete $ref->[$x][$y]{$key};
1310     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1311
1312     delete $ref->[$x][$y][$index];
1313     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1314
1315 =item die LIST
1316 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1317
1318 C<die> raises an exception. Inside an C<eval> the error message is stuffed
1319 into C<$@> and the C<eval> is terminated with the undefined value.
1320 If the exception is outside of all enclosing C<eval>s, then the uncaught
1321 exception prints LIST to C<STDERR> and exits with a non-zero value. If you
1322 need to exit the process with a specific exit code, see L</exit>.
1323
1324 Equivalent examples:
1325
1326     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1327     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1328
1329 If the last element of LIST does not end in a newline, the current
1330 script line number and input line number (if any) are also printed,
1331 and a newline is supplied.  Note that the "input line number" (also
1332 known as "chunk") is subject to whatever notion of "line" happens to
1333 be currently in effect, and is also available as the special variable
1334 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1335
1336 Hint: sometimes appending C<", stopped"> to your message will cause it
1337 to make better sense when the string C<"at foo line 123"> is appended.
1338 Suppose you are running script "canasta".
1339
1340     die "/etc/games is no good";
1341     die "/etc/games is no good, stopped";
1342
1343 produce, respectively
1344
1345     /etc/games is no good at canasta line 123.
1346     /etc/games is no good, stopped at canasta line 123.
1347
1348 If the output is empty and C<$@> already contains a value (typically from a
1349 previous eval) that value is reused after appending C<"\t...propagated">.
1350 This is useful for propagating exceptions:
1351
1352     eval { ... };
1353     die unless $@ =~ /Expected exception/;
1354
1355 If the output is empty and C<$@> contains an object reference that has a
1356 C<PROPAGATE> method, that method will be called with additional file
1357 and line number parameters.  The return value replaces the value in
1358 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1359 were called.
1360
1361 If C<$@> is empty then the string C<"Died"> is used.
1362
1363 If an uncaught exception results in interpreter exit, the exit code is
1364 determined from the values of C<$!> and C<$?> with this pseudocode:
1365
1366     exit $! if $!;              # errno
1367     exit $? >> 8 if $? >> 8;    # child exit status
1368     exit 255;                   # last resort
1369
1370 The intent is to squeeze as much possible information about the likely cause
1371 into the limited space of the system exit code. However, as C<$!> is the value
1372 of C's C<errno>, which can be set by any system call, this means that the value
1373 of the exit code used by C<die> can be non-predictable, so should not be relied
1374 upon, other than to be non-zero.
1375
1376 You can also call C<die> with a reference argument, and if this is trapped
1377 within an C<eval>, C<$@> contains that reference.  This permits more
1378 elaborate exception handling using objects that maintain arbitrary state
1379 about the exception.  Such a scheme is sometimes preferable to matching
1380 particular string values of C<$@> with regular expressions.  Because C<$@> 
1381 is a global variable and C<eval> may be used within object implementations,
1382 be careful that analyzing the error object doesn't replace the reference in
1383 the global variable.  It's easiest to make a local copy of the reference
1384 before any manipulations.  Here's an example:
1385
1386     use Scalar::Util "blessed";
1387
1388     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1389     if (my $ev_err = $@) {
1390         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1391             # handle Some::Module::Exception
1392         }
1393         else {
1394             # handle all other possible exceptions
1395         }
1396     }
1397
1398 Because Perl stringifies uncaught exception messages before display,
1399 you'll probably want to overload stringification operations on
1400 exception objects.  See L<overload> for details about that.
1401
1402 You can arrange for a callback to be run just before the C<die>
1403 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1404 handler is called with the error text and can change the error
1405 message, if it sees fit, by calling C<die> again.  See
1406 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1407 L<"eval BLOCK"> for some examples.  Although this feature was 
1408 to be run only right before your program was to exit, this is not
1409 currently so: the C<$SIG{__DIE__}> hook is currently called
1410 even inside eval()ed blocks/strings!  If one wants the hook to do
1411 nothing in such situations, put
1412
1413     die @_ if $^S;
1414
1415 as the first line of the handler (see L<perlvar/$^S>).  Because
1416 this promotes strange action at a distance, this counterintuitive
1417 behavior may be fixed in a future release.
1418
1419 See also exit(), warn(), and the Carp module.
1420
1421 =item do BLOCK
1422 X<do> X<block>
1423
1424 Not really a function.  Returns the value of the last command in the
1425 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1426 C<until> loop modifier, executes the BLOCK once before testing the loop
1427 condition. (On other statements the loop modifiers test the conditional
1428 first.)
1429
1430 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1431 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1432 See L<perlsyn> for alternative strategies.
1433
1434 =item do SUBROUTINE(LIST)
1435 X<do>
1436
1437 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword,
1438 a scalar variable or a subroutine beginning with C<&>.
1439
1440 =item do EXPR
1441 X<do>
1442
1443 Uses the value of EXPR as a filename and executes the contents of the
1444 file as a Perl script.
1445
1446     do 'stat.pl';
1447
1448 is just like
1449
1450     eval `cat stat.pl`;
1451
1452 except that it's more efficient and concise, keeps track of the current
1453 filename for error messages, searches the C<@INC> directories, and updates
1454 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1455 these variables.  It also differs in that code evaluated with C<do FILENAME>
1456 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1457 same, however, in that it does reparse the file every time you call it,
1458 so you probably don't want to do this inside a loop.
1459
1460 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1461 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1462 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1463 could fail in a way that also sets C<$!>.  If the file is successfully
1464 compiled, C<do> returns the value of the last expression evaluated.
1465
1466 Inclusion of library modules is better done with the
1467 C<use> and C<require> operators, which also do automatic error checking
1468 and raise an exception if there's a problem.
1469
1470 You might like to use C<do> to read in a program configuration
1471 file.  Manual error checking can be done this way:
1472
1473     # read in config files: system first, then user
1474     for $file ("/share/prog/defaults.rc",
1475                "$ENV{HOME}/.someprogrc")
1476     {
1477         unless ($return = do $file) {
1478             warn "couldn't parse $file: $@" if $@;
1479             warn "couldn't do $file: $!"    unless defined $return;
1480             warn "couldn't run $file"       unless $return;
1481         }
1482     }
1483
1484 =item dump LABEL
1485 X<dump> X<core> X<undump>
1486
1487 =item dump
1488
1489 This function causes an immediate core dump.  See also the B<-u>
1490 command-line switch in L<perlrun>, which does the same thing.
1491 Primarily this is so that you can use the B<undump> program (not
1492 supplied) to turn your core dump into an executable binary after
1493 having initialized all your variables at the beginning of the
1494 program.  When the new binary is executed it will begin by executing
1495 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1496 Think of it as a goto with an intervening core dump and reincarnation.
1497 If C<LABEL> is omitted, restarts the program from the top.
1498
1499 B<WARNING>: Any files opened at the time of the dump will I<not>
1500 be open any more when the program is reincarnated, with possible
1501 resulting confusion by Perl.
1502
1503 This function is now largely obsolete, mostly because it's very hard to
1504 convert a core file into an executable. That's why you should now invoke
1505 it as C<CORE::dump()>, if you don't want to be warned against a possible
1506 typo.
1507
1508 Portability issues: L<perlport/dump>.
1509
1510 =item each HASH
1511 X<each> X<hash, iterator>
1512
1513 =item each ARRAY
1514 X<array, iterator>
1515
1516 =item each EXPR
1517
1518 When called in list context, returns a 2-element list consisting of the key
1519 and value for the next element of a hash, or the index and value for the
1520 next element of an array, so that you can iterate over it.  When called in
1521 scalar context, returns only the key (not the value) in a hash, or the index
1522 in an array.
1523
1524 Hash entries are returned in an apparently random order.  The actual random
1525 order is subject to change in future versions of Perl, but it is
1526 guaranteed to be in the same order as either the C<keys> or C<values>
1527 function would produce on the same (unmodified) hash.  Since Perl
1528 5.8.2 the ordering can be different even between different runs of Perl
1529 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1530
1531 After C<each> has returned all entries from the hash or array, the next
1532 call to C<each> returns the empty list in list context and C<undef> in
1533 scalar context.  The next call following that one restarts iteration.  Each
1534 hash or array has its own internal iterator, accessed by C<each>, C<keys>,
1535 and C<values>.  The iterator is implicitly reset when C<each> has reached
1536 the end as just described; it can be explicitly reset by calling C<keys> or
1537 C<values> on the hash or array.  If you add or delete a hash's elements
1538 while iterating over it, entries may be skipped or duplicated--so don't do
1539 that.  Exception: It is always safe to delete the item most recently
1540 returned by C<each()>, so the following code works properly:
1541
1542         while (($key, $value) = each %hash) {
1543           print $key, "\n";
1544           delete $hash{$key};   # This is safe
1545         }
1546
1547 This prints out your environment like the printenv(1) program,
1548 but in a different order:
1549
1550     while (($key,$value) = each %ENV) {
1551         print "$key=$value\n";
1552     }
1553
1554 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1555 reference to an unblessed hash or array.  The argument will be dereferenced
1556 automatically.  This aspect of C<each> is considered highly experimental.
1557 The exact behaviour may change in a future version of Perl.
1558
1559     while (($key,$value) = each $hashref) { ... }
1560
1561 See also C<keys>, C<values>, and C<sort>.
1562
1563 =item eof FILEHANDLE
1564 X<eof>
1565 X<end of file>
1566 X<end-of-file>
1567
1568 =item eof ()
1569
1570 =item eof
1571
1572 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1573 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1574 gives the real filehandle.  (Note that this function actually
1575 reads a character and then C<ungetc>s it, so isn't useful in an
1576 interactive context.)  Do not read from a terminal file (or call
1577 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1578 as terminals may lose the end-of-file condition if you do.
1579
1580 An C<eof> without an argument uses the last file read.  Using C<eof()>
1581 with empty parentheses is different.  It refers to the pseudo file
1582 formed from the files listed on the command line and accessed via the
1583 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1584 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1585 used will cause C<@ARGV> to be examined to determine if input is
1586 available.   Similarly, an C<eof()> after C<< <> >> has returned
1587 end-of-file will assume you are processing another C<@ARGV> list,
1588 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1589 see L<perlop/"I/O Operators">.
1590
1591 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1592 detect the end of each file, whereas C<eof()> will detect the end 
1593 of the very last file only.  Examples:
1594
1595     # reset line numbering on each input file
1596     while (<>) {
1597         next if /^\s*#/;  # skip comments
1598         print "$.\t$_";
1599     } continue {
1600         close ARGV if eof;  # Not eof()!
1601     }
1602
1603     # insert dashes just before last line of last file
1604     while (<>) {
1605         if (eof()) {  # check for end of last file
1606             print "--------------\n";
1607         }
1608         print;
1609         last if eof();          # needed if we're reading from a terminal
1610     }
1611
1612 Practical hint: you almost never need to use C<eof> in Perl, because the
1613 input operators typically return C<undef> when they run out of data or 
1614 encounter an error.
1615
1616 =item eval EXPR
1617 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1618 X<error, handling> X<exception, handling>
1619
1620 =item eval BLOCK
1621
1622 =item eval
1623
1624 In the first form, the return value of EXPR is parsed and executed as if it
1625 were a little Perl program.  The value of the expression (which is itself
1626 determined within scalar context) is first parsed, and if there were no
1627 errors, executed as a block within the lexical context of the current Perl
1628 program. This means, that in particular, any outer lexical variables are
1629 visible to it, and any package variable settings or subroutine and format
1630 definitions remain afterwards.
1631
1632 Note that the value is parsed every time the C<eval> executes.
1633 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1634 delay parsing and subsequent execution of the text of EXPR until run time.
1635
1636 In the second form, the code within the BLOCK is parsed only once--at the
1637 same time the code surrounding the C<eval> itself was parsed--and executed
1638 within the context of the current Perl program.  This form is typically
1639 used to trap exceptions more efficiently than the first (see below), while
1640 also providing the benefit of checking the code within BLOCK at compile
1641 time.
1642
1643 The final semicolon, if any, may be omitted from the value of EXPR or within
1644 the BLOCK.
1645
1646 In both forms, the value returned is the value of the last expression
1647 evaluated inside the mini-program; a return statement may be also used, just
1648 as with subroutines.  The expression providing the return value is evaluated
1649 in void, scalar, or list context, depending on the context of the C<eval> 
1650 itself.  See L</wantarray> for more on how the evaluation context can be 
1651 determined.
1652
1653 If there is a syntax error or runtime error, or a C<die> statement is
1654 executed, C<eval> returns C<undef> in scalar context
1655 or an empty list--or, for syntax errors, a list containing a single
1656 undefined value--in list context, and C<$@> is set to the error
1657 message.  The discrepancy in the return values in list context is
1658 considered a bug by some, and will probably be fixed in a future
1659 release.  If there was no error, C<$@> is guaranteed to be the empty
1660 string.  Beware that using C<eval> neither silences Perl from printing
1661 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1662 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1663 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1664 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1665
1666 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1667 determining whether a particular feature (such as C<socket> or C<symlink>)
1668 is implemented.  It is also Perl's exception-trapping mechanism, where
1669 the die operator is used to raise exceptions.
1670
1671 If you want to trap errors when loading an XS module, some problems with
1672 the binary interface (such as Perl version skew) may be fatal even with
1673 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set. See L<perlrun>.
1674
1675 If the code to be executed doesn't vary, you may use the eval-BLOCK
1676 form to trap run-time errors without incurring the penalty of
1677 recompiling each time.  The error, if any, is still returned in C<$@>.
1678 Examples:
1679
1680     # make divide-by-zero nonfatal
1681     eval { $answer = $a / $b; }; warn $@ if $@;
1682
1683     # same thing, but less efficient
1684     eval '$answer = $a / $b'; warn $@ if $@;
1685
1686     # a compile-time error
1687     eval { $answer = }; # WRONG
1688
1689     # a run-time error
1690     eval '$answer =';   # sets $@
1691
1692 Using the C<eval{}> form as an exception trap in libraries does have some
1693 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1694 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1695 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1696 as this example shows:
1697
1698     # a private exception trap for divide-by-zero
1699     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1700     warn $@ if $@;
1701
1702 This is especially significant, given that C<__DIE__> hooks can call
1703 C<die> again, which has the effect of changing their error messages:
1704
1705     # __DIE__ hooks may modify error messages
1706     {
1707        local $SIG{'__DIE__'} =
1708               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1709        eval { die "foo lives here" };
1710        print $@ if $@;                # prints "bar lives here"
1711     }
1712
1713 Because this promotes action at a distance, this counterintuitive behavior
1714 may be fixed in a future release.
1715
1716 With an C<eval>, you should be especially careful to remember what's
1717 being looked at when:
1718
1719     eval $x;        # CASE 1
1720     eval "$x";      # CASE 2
1721
1722     eval '$x';      # CASE 3
1723     eval { $x };    # CASE 4
1724
1725     eval "\$$x++";  # CASE 5
1726     $$x++;          # CASE 6
1727
1728 Cases 1 and 2 above behave identically: they run the code contained in
1729 the variable $x.  (Although case 2 has misleading double quotes making
1730 the reader wonder what else might be happening (nothing is).)  Cases 3
1731 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1732 does nothing but return the value of $x.  (Case 4 is preferred for
1733 purely visual reasons, but it also has the advantage of compiling at
1734 compile-time instead of at run-time.)  Case 5 is a place where
1735 normally you I<would> like to use double quotes, except that in this
1736 particular situation, you can just use symbolic references instead, as
1737 in case 6.
1738
1739 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1740 of localised variables, which means that for your code to run on older
1741 versions, a temporary is required if you want to mask some but not all
1742 errors:
1743
1744     # alter $@ on nefarious repugnancy only
1745     {
1746        my $e;
1747        {
1748           local $@; # protect existing $@
1749           eval { test_repugnancy() };
1750           # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1751           $@ =~ /nefarious/ and $e = $@;
1752        }
1753        die $e if defined $e
1754     }
1755
1756 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1757 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1758
1759 An C<eval ''> executed within the C<DB> package doesn't see the usual
1760 surrounding lexical scope, but rather the scope of the first non-DB piece
1761 of code that called it. You don't normally need to worry about this unless
1762 you are writing a Perl debugger.
1763
1764 =item exec LIST
1765 X<exec> X<execute>
1766
1767 =item exec PROGRAM LIST
1768
1769 The C<exec> function executes a system command I<and never returns>;
1770 use C<system> instead of C<exec> if you want it to return.  It fails and
1771 returns false only if the command does not exist I<and> it is executed
1772 directly instead of via your system's command shell (see below).
1773
1774 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1775 warns you if there is a following statement that isn't C<die>, C<warn>,
1776 or C<exit> (if C<-w> is set--but you always do that, right?).   If you
1777 I<really> want to follow an C<exec> with some other statement, you
1778 can use one of these styles to avoid the warning:
1779
1780     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1781     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1782
1783 If there is more than one argument in LIST, or if LIST is an array
1784 with more than one value, calls execvp(3) with the arguments in LIST.
1785 If there is only one scalar argument or an array with one element in it,
1786 the argument is checked for shell metacharacters, and if there are any,
1787 the entire argument is passed to the system's command shell for parsing
1788 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1789 If there are no shell metacharacters in the argument, it is split into
1790 words and passed directly to C<execvp>, which is more efficient.
1791 Examples:
1792
1793     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1794     exec "sort $outfile | uniq";
1795
1796 If you don't really want to execute the first argument, but want to lie
1797 to the program you are executing about its own name, you can specify
1798 the program you actually want to run as an "indirect object" (without a
1799 comma) in front of the LIST.  (This always forces interpretation of the
1800 LIST as a multivalued list, even if there is only a single scalar in
1801 the list.)  Example:
1802
1803     $shell = '/bin/csh';
1804     exec $shell '-sh';    # pretend it's a login shell
1805
1806 or, more directly,
1807
1808     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1809
1810 When the arguments get executed via the system shell, results are
1811 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1812 for details.
1813
1814 Using an indirect object with C<exec> or C<system> is also more
1815 secure.  This usage (which also works fine with system()) forces
1816 interpretation of the arguments as a multivalued list, even if the
1817 list had just one argument.  That way you're safe from the shell
1818 expanding wildcards or splitting up words with whitespace in them.
1819
1820     @args = ( "echo surprise" );
1821
1822     exec @args;               # subject to shell escapes
1823                                 # if @args == 1
1824     exec { $args[0] } @args;  # safe even with one-arg list
1825
1826 The first version, the one without the indirect object, ran the I<echo>
1827 program, passing it C<"surprise"> an argument.  The second version didn't;
1828 it tried to run a program named I<"echo surprise">, didn't find it, and set
1829 C<$?> to a non-zero value indicating failure.
1830
1831 Beginning with v5.6.0, Perl attempts to flush all files opened for
1832 output before the exec, but this may not be supported on some platforms
1833 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1834 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1835 open handles to avoid lost output.
1836
1837 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1838 C<DESTROY> methods on your objects.
1839
1840 Portability issues: L<perlport/exec>.
1841
1842 =item exists EXPR
1843 X<exists> X<autovivification>
1844
1845 Given an expression that specifies an element of a hash, returns true if the
1846 specified element in the hash has ever been initialized, even if the
1847 corresponding value is undefined.
1848
1849     print "Exists\n"    if exists $hash{$key};
1850     print "Defined\n"   if defined $hash{$key};
1851     print "True\n"      if $hash{$key};
1852
1853 exists may also be called on array elements, but its behavior is much less
1854 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
1855 that calling exists on array values is deprecated and likely to be removed in
1856 a future version of Perl.
1857
1858     print "Exists\n"    if exists $array[$index];
1859     print "Defined\n"   if defined $array[$index];
1860     print "True\n"      if $array[$index];
1861
1862 A hash or array element can be true only if it's defined and defined only if
1863 it exists, but the reverse doesn't necessarily hold true.
1864
1865 Given an expression that specifies the name of a subroutine,
1866 returns true if the specified subroutine has ever been declared, even
1867 if it is undefined.  Mentioning a subroutine name for exists or defined
1868 does not count as declaring it.  Note that a subroutine that does not
1869 exist may still be callable: its package may have an C<AUTOLOAD>
1870 method that makes it spring into existence the first time that it is
1871 called; see L<perlsub>.
1872
1873     print "Exists\n"  if exists &subroutine;
1874     print "Defined\n" if defined &subroutine;
1875
1876 Note that the EXPR can be arbitrarily complicated as long as the final
1877 operation is a hash or array key lookup or subroutine name:
1878
1879     if (exists $ref->{A}->{B}->{$key})  { }
1880     if (exists $hash{A}{B}{$key})       { }
1881
1882     if (exists $ref->{A}->{B}->[$ix])   { }
1883     if (exists $hash{A}{B}[$ix])        { }
1884
1885     if (exists &{$ref->{A}{B}{$key}})   { }
1886
1887 Although the mostly deeply nested array or hash will not spring into
1888 existence just because its existence was tested, any intervening ones will.
1889 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1890 into existence due to the existence test for the $key element above.
1891 This happens anywhere the arrow operator is used, including even here:
1892
1893     undef $ref;
1894     if (exists $ref->{"Some key"})    { }
1895     print $ref;  # prints HASH(0x80d3d5c)
1896
1897 This surprising autovivification in what does not at first--or even
1898 second--glance appear to be an lvalue context may be fixed in a future
1899 release.
1900
1901 Use of a subroutine call, rather than a subroutine name, as an argument
1902 to exists() is an error.
1903
1904     exists &sub;    # OK
1905     exists &sub();  # Error
1906
1907 =item exit EXPR
1908 X<exit> X<terminate> X<abort>
1909
1910 =item exit
1911
1912 Evaluates EXPR and exits immediately with that value.    Example:
1913
1914     $ans = <STDIN>;
1915     exit 0 if $ans =~ /^[Xx]/;
1916
1917 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1918 universally recognized values for EXPR are C<0> for success and C<1>
1919 for error; other values are subject to interpretation depending on the
1920 environment in which the Perl program is running.  For example, exiting
1921 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1922 the mailer to return the item undelivered, but that's not true everywhere.
1923
1924 Don't use C<exit> to abort a subroutine if there's any chance that
1925 someone might want to trap whatever error happened.  Use C<die> instead,
1926 which can be trapped by an C<eval>.
1927
1928 The exit() function does not always exit immediately.  It calls any
1929 defined C<END> routines first, but these C<END> routines may not
1930 themselves abort the exit.  Likewise any object destructors that need to
1931 be called are called before the real exit.  C<END> routines and destructors
1932 can change the exit status by modifying C<$?>. If this is a problem, you
1933 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1934 See L<perlmod> for details.
1935
1936 Portability issues: L<perlport/exit>.
1937
1938 =item exp EXPR
1939 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1940
1941 =item exp
1942
1943 Returns I<e> (the natural logarithm base) to the power of EXPR.
1944 If EXPR is omitted, gives C<exp($_)>.
1945
1946 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1947 X<fcntl>
1948
1949 Implements the fcntl(2) function.  You'll probably have to say
1950
1951     use Fcntl;
1952
1953 first to get the correct constant definitions.  Argument processing and
1954 value returned work just like C<ioctl> below.
1955 For example:
1956
1957     use Fcntl;
1958     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1959         or die "can't fcntl F_GETFL: $!";
1960
1961 You don't have to check for C<defined> on the return from C<fcntl>.
1962 Like C<ioctl>, it maps a C<0> return from the system call into
1963 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1964 in numeric context.  It is also exempt from the normal B<-w> warnings
1965 on improper numeric conversions.
1966
1967 Note that C<fcntl> raises an exception if used on a machine that
1968 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1969 manpage to learn what functions are available on your system.
1970
1971 Here's an example of setting a filehandle named C<REMOTE> to be
1972 non-blocking at the system level.  You'll have to negotiate C<$|>
1973 on your own, though.
1974
1975     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1976
1977     $flags = fcntl(REMOTE, F_GETFL, 0)
1978                 or die "Can't get flags for the socket: $!\n";
1979
1980     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1981                 or die "Can't set flags for the socket: $!\n";
1982
1983 Portability issues: L<perlport/fcntl>.
1984
1985 =item fileno FILEHANDLE
1986 X<fileno>
1987
1988 Returns the file descriptor for a filehandle, or undefined if the
1989 filehandle is not open.  If there is no real file descriptor at the OS
1990 level, as can happen with filehandles connected to memory objects via
1991 C<open> with a reference for the third argument, -1 is returned.
1992
1993 This is mainly useful for constructing
1994 bitmaps for C<select> and low-level POSIX tty-handling operations.
1995 If FILEHANDLE is an expression, the value is taken as an indirect
1996 filehandle, generally its name.
1997
1998 You can use this to find out whether two handles refer to the
1999 same underlying descriptor:
2000
2001     if (fileno(THIS) == fileno(THAT)) {
2002         print "THIS and THAT are dups\n";
2003     }
2004
2005 =item flock FILEHANDLE,OPERATION
2006 X<flock> X<lock> X<locking>
2007
2008 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2009 for success, false on failure.  Produces a fatal error if used on a
2010 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2011 C<flock> is Perl's portable file-locking interface, although it locks
2012 entire files only, not records.
2013
2014 Two potentially non-obvious but traditional C<flock> semantics are
2015 that it waits indefinitely until the lock is granted, and that its locks
2016 are B<merely advisory>.  Such discretionary locks are more flexible, but
2017 offer fewer guarantees.  This means that programs that do not also use
2018 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2019 your port's specific documentation, and your system-specific local manpages
2020 for details.  It's best to assume traditional behavior if you're writing
2021 portable programs.  (But if you're not, you should as always feel perfectly
2022 free to write for your own system's idiosyncrasies (sometimes called
2023 "features").  Slavish adherence to portability concerns shouldn't get
2024 in the way of your getting your job done.)
2025
2026 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2027 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2028 you can use the symbolic names if you import them from the L<Fcntl> module,
2029 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2030 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2031 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2032 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2033 waiting for the lock; check the return status to see if you got it.
2034
2035 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2036 before locking or unlocking it.
2037
2038 Note that the emulation built with lockf(3) doesn't provide shared
2039 locks, and it requires that FILEHANDLE be open with write intent.  These
2040 are the semantics that lockf(3) implements.  Most if not all systems
2041 implement lockf(3) in terms of fcntl(2) locking, though, so the
2042 differing semantics shouldn't bite too many people.
2043
2044 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2045 be open with read intent to use LOCK_SH and requires that it be open
2046 with write intent to use LOCK_EX.
2047
2048 Note also that some versions of C<flock> cannot lock things over the
2049 network; you would need to use the more system-specific C<fcntl> for
2050 that.  If you like you can force Perl to ignore your system's flock(2)
2051 function, and so provide its own fcntl(2)-based emulation, by passing
2052 the switch C<-Ud_flock> to the F<Configure> program when you configure
2053 and build a new Perl.
2054
2055 Here's a mailbox appender for BSD systems.
2056
2057     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
2058
2059     sub lock {
2060         my ($fh) = @_;
2061         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2062
2063         # and, in case someone appended while we were waiting...
2064         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2065     }
2066
2067     sub unlock {
2068         my ($fh) = @_;
2069         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2070     }
2071
2072     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2073         or die "Can't open mailbox: $!";
2074
2075     lock($mbox);
2076     print $mbox $msg,"\n\n";
2077     unlock($mbox);
2078
2079 On systems that support a real flock(2), locks are inherited across fork()
2080 calls, whereas those that must resort to the more capricious fcntl(2)
2081 function lose their locks, making it seriously harder to write servers.
2082
2083 See also L<DB_File> for other flock() examples.
2084
2085 Portability issues: L<perlport/flock>.
2086
2087 =item fork
2088 X<fork> X<child> X<parent>
2089
2090 Does a fork(2) system call to create a new process running the
2091 same program at the same point.  It returns the child pid to the
2092 parent process, C<0> to the child process, or C<undef> if the fork is
2093 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2094 are shared, while everything else is copied.  On most systems supporting
2095 fork(), great care has gone into making it extremely efficient (for
2096 example, using copy-on-write technology on data pages), making it the
2097 dominant paradigm for multitasking over the last few decades.
2098
2099 Beginning with v5.6.0, Perl attempts to flush all files opened for
2100 output before forking the child process, but this may not be supported
2101 on some platforms (see L<perlport>).  To be safe, you may need to set
2102 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2103 C<IO::Handle> on any open handles to avoid duplicate output.
2104
2105 If you C<fork> without ever waiting on your children, you will
2106 accumulate zombies.  On some systems, you can avoid this by setting
2107 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2108 forking and reaping moribund children.
2109
2110 Note that if your forked child inherits system file descriptors like
2111 STDIN and STDOUT that are actually connected by a pipe or socket, even
2112 if you exit, then the remote server (such as, say, a CGI script or a
2113 backgrounded job launched from a remote shell) won't think you're done.
2114 You should reopen those to F</dev/null> if it's any issue.
2115
2116 On some platforms such as Windows, where the fork() system call is not available,
2117 Perl can be built to emulate fork() in the Perl interpreter. The emulation is designed to,
2118 at the level of the Perl program, be as compatible as possible with the "Unix" fork().
2119 However it has limitations that have to be considered in code intended to be portable.
2120 See L<perlfork> for more details.
2121
2122 Portability issues: L<perlport/fork>.
2123
2124 =item format
2125 X<format>
2126
2127 Declare a picture format for use by the C<write> function.  For
2128 example:
2129
2130     format Something =
2131         Test: @<<<<<<<< @||||| @>>>>>
2132               $str,     $%,    '$' . int($num)
2133     .
2134
2135     $str = "widget";
2136     $num = $cost/$quantity;
2137     $~ = 'Something';
2138     write;
2139
2140 See L<perlform> for many details and examples.
2141
2142 =item formline PICTURE,LIST
2143 X<formline>
2144
2145 This is an internal function used by C<format>s, though you may call it,
2146 too.  It formats (see L<perlform>) a list of values according to the
2147 contents of PICTURE, placing the output into the format output
2148 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2149 Eventually, when a C<write> is done, the contents of
2150 C<$^A> are written to some filehandle.  You could also read C<$^A>
2151 and then set C<$^A> back to C<"">.  Note that a format typically
2152 does one C<formline> per line of form, but the C<formline> function itself
2153 doesn't care how many newlines are embedded in the PICTURE.  This means
2154 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2155 You may therefore need to use multiple formlines to implement a single
2156 record format, just like the C<format> compiler.
2157
2158 Be careful if you put double quotes around the picture, because an C<@>
2159 character may be taken to mean the beginning of an array name.
2160 C<formline> always returns true.  See L<perlform> for other examples.
2161
2162 If you are trying to use this instead of C<write> to capture the output,
2163 you may find it easier to open a filehandle to a scalar
2164 (C<< open $fh, ">", \$output >>) and write to that instead.
2165
2166 =item getc FILEHANDLE
2167 X<getc> X<getchar> X<character> X<file, read>
2168
2169 =item getc
2170
2171 Returns the next character from the input file attached to FILEHANDLE,
2172 or the undefined value at end of file or if there was an error (in
2173 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2174 STDIN.  This is not particularly efficient.  However, it cannot be
2175 used by itself to fetch single characters without waiting for the user
2176 to hit enter.  For that, try something more like:
2177
2178     if ($BSD_STYLE) {
2179         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2180     }
2181     else {
2182         system "stty", '-icanon', 'eol', "\001";
2183     }
2184
2185     $key = getc(STDIN);
2186
2187     if ($BSD_STYLE) {
2188         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2189     }
2190     else {
2191         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2192     }
2193     print "\n";
2194
2195 Determination of whether $BSD_STYLE should be set
2196 is left as an exercise to the reader.
2197
2198 The C<POSIX::getattr> function can do this more portably on
2199 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2200 module from your nearest CPAN site; details on CPAN can be found under
2201 L<perlmodlib/CPAN>.
2202
2203 =item getlogin
2204 X<getlogin> X<login>
2205
2206 This implements the C library function of the same name, which on most
2207 systems returns the current login from F</etc/utmp>, if any.  If it
2208 returns the empty string, use C<getpwuid>.
2209
2210     $login = getlogin || getpwuid($<) || "Kilroy";
2211
2212 Do not consider C<getlogin> for authentication: it is not as
2213 secure as C<getpwuid>.
2214
2215 Portability issues: L<perlport/getlogin>.
2216
2217 =item getpeername SOCKET
2218 X<getpeername> X<peer>
2219
2220 Returns the packed sockaddr address of the other end of the SOCKET
2221 connection.
2222
2223     use Socket;
2224     $hersockaddr    = getpeername(SOCK);
2225     ($port, $iaddr) = sockaddr_in($hersockaddr);
2226     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2227     $herstraddr     = inet_ntoa($iaddr);
2228
2229 =item getpgrp PID
2230 X<getpgrp> X<group>
2231
2232 Returns the current process group for the specified PID.  Use
2233 a PID of C<0> to get the current process group for the
2234 current process.  Will raise an exception if used on a machine that
2235 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2236 group of the current process.  Note that the POSIX version of C<getpgrp>
2237 does not accept a PID argument, so only C<PID==0> is truly portable.
2238
2239 Portability issues: L<perlport/getpgrp>.
2240
2241 =item getppid
2242 X<getppid> X<parent> X<pid>
2243
2244 Returns the process id of the parent process.
2245
2246 Note for Linux users: on Linux, the C functions C<getpid()> and
2247 C<getppid()> return different values from different threads. In order to
2248 be portable, this behavior is not reflected by the Perl-level function
2249 C<getppid()>, that returns a consistent value across threads. If you want
2250 to call the underlying C<getppid()>, you may use the CPAN module
2251 C<Linux::Pid>.
2252
2253 Portability issues: L<perlport/getppid>.
2254
2255 =item getpriority WHICH,WHO
2256 X<getpriority> X<priority> X<nice>
2257
2258 Returns the current priority for a process, a process group, or a user.
2259 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2260 machine that doesn't implement getpriority(2).
2261
2262 Portability issues: L<perlport/getpriority>.
2263
2264 =item getpwnam NAME
2265 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2266 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2267 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2268 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2269 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2270 X<endnetent> X<endprotoent> X<endservent> 
2271
2272 =item getgrnam NAME
2273
2274 =item gethostbyname NAME
2275
2276 =item getnetbyname NAME
2277
2278 =item getprotobyname NAME
2279
2280 =item getpwuid UID
2281
2282 =item getgrgid GID
2283
2284 =item getservbyname NAME,PROTO
2285
2286 =item gethostbyaddr ADDR,ADDRTYPE
2287
2288 =item getnetbyaddr ADDR,ADDRTYPE
2289
2290 =item getprotobynumber NUMBER
2291
2292 =item getservbyport PORT,PROTO
2293
2294 =item getpwent
2295
2296 =item getgrent
2297
2298 =item gethostent
2299
2300 =item getnetent
2301
2302 =item getprotoent
2303
2304 =item getservent
2305
2306 =item setpwent
2307
2308 =item setgrent
2309
2310 =item sethostent STAYOPEN
2311
2312 =item setnetent STAYOPEN
2313
2314 =item setprotoent STAYOPEN
2315
2316 =item setservent STAYOPEN
2317
2318 =item endpwent
2319
2320 =item endgrent
2321
2322 =item endhostent
2323
2324 =item endnetent
2325
2326 =item endprotoent
2327
2328 =item endservent
2329
2330 These routines are the same as their counterparts in the
2331 system C library.  In list context, the return values from the
2332 various get routines are as follows:
2333
2334     ($name,$passwd,$uid,$gid,
2335        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2336     ($name,$passwd,$gid,$members) = getgr*
2337     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2338     ($name,$aliases,$addrtype,$net) = getnet*
2339     ($name,$aliases,$proto) = getproto*
2340     ($name,$aliases,$port,$proto) = getserv*
2341
2342 (If the entry doesn't exist you get an empty list.)
2343
2344 The exact meaning of the $gcos field varies but it usually contains
2345 the real name of the user (as opposed to the login name) and other
2346 information pertaining to the user.  Beware, however, that in many
2347 system users are able to change this information and therefore it
2348 cannot be trusted and therefore the $gcos is tainted (see
2349 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2350 login shell, are also tainted, for the same reason.
2351
2352 In scalar context, you get the name, unless the function was a
2353 lookup by name, in which case you get the other thing, whatever it is.
2354 (If the entry doesn't exist you get the undefined value.)  For example:
2355
2356     $uid   = getpwnam($name);
2357     $name  = getpwuid($num);
2358     $name  = getpwent();
2359     $gid   = getgrnam($name);
2360     $name  = getgrgid($num);
2361     $name  = getgrent();
2362     #etc.
2363
2364 In I<getpw*()> the fields $quota, $comment, and $expire are special
2365 in that they are unsupported on many systems.  If the
2366 $quota is unsupported, it is an empty scalar.  If it is supported, it
2367 usually encodes the disk quota.  If the $comment field is unsupported,
2368 it is an empty scalar.  If it is supported it usually encodes some
2369 administrative comment about the user.  In some systems the $quota
2370 field may be $change or $age, fields that have to do with password
2371 aging.  In some systems the $comment field may be $class.  The $expire
2372 field, if present, encodes the expiration period of the account or the
2373 password.  For the availability and the exact meaning of these fields
2374 in your system, please consult getpwnam(3) and your system's 
2375 F<pwd.h> file.  You can also find out from within Perl what your
2376 $quota and $comment fields mean and whether you have the $expire field
2377 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2378 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2379 files are supported only if your vendor has implemented them in the
2380 intuitive fashion that calling the regular C library routines gets the
2381 shadow versions if you're running under privilege or if there exists
2382 the shadow(3) functions as found in System V (this includes Solaris
2383 and Linux).  Those systems that implement a proprietary shadow password
2384 facility are unlikely to be supported.
2385
2386 The $members value returned by I<getgr*()> is a space-separated list of
2387 the login names of the members of the group.
2388
2389 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2390 C, it will be returned to you via C<$?> if the function call fails.  The
2391 C<@addrs> value returned by a successful call is a list of raw
2392 addresses returned by the corresponding library call.  In the
2393 Internet domain, each address is four bytes long; you can unpack it
2394 by saying something like:
2395
2396     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2397
2398 The Socket library makes this slightly easier:
2399
2400     use Socket;
2401     $iaddr = inet_aton("127.1"); # or whatever address
2402     $name  = gethostbyaddr($iaddr, AF_INET);
2403
2404     # or going the other way
2405     $straddr = inet_ntoa($iaddr);
2406
2407 In the opposite way, to resolve a hostname to the IP address
2408 you can write this:
2409
2410     use Socket;
2411     $packed_ip = gethostbyname("www.perl.org");
2412     if (defined $packed_ip) {
2413         $ip_address = inet_ntoa($packed_ip);
2414     }
2415
2416 Make sure <gethostbyname()> is called in SCALAR context and that
2417 its return value is checked for definedness.
2418
2419 If you get tired of remembering which element of the return list
2420 contains which return value, by-name interfaces are provided
2421 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2422 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2423 and C<User::grent>.  These override the normal built-ins, supplying
2424 versions that return objects with the appropriate names
2425 for each field.  For example:
2426
2427    use File::stat;
2428    use User::pwent;
2429    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2430
2431 Even though it looks as though they're the same method calls (uid),
2432 they aren't, because a C<File::stat> object is different from
2433 a C<User::pwent> object.
2434
2435 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2436
2437 =item getsockname SOCKET
2438 X<getsockname>
2439
2440 Returns the packed sockaddr address of this end of the SOCKET connection,
2441 in case you don't know the address because you have several different
2442 IPs that the connection might have come in on.
2443
2444     use Socket;
2445     $mysockaddr = getsockname(SOCK);
2446     ($port, $myaddr) = sockaddr_in($mysockaddr);
2447     printf "Connect to %s [%s]\n",
2448        scalar gethostbyaddr($myaddr, AF_INET),
2449        inet_ntoa($myaddr);
2450
2451 =item getsockopt SOCKET,LEVEL,OPTNAME
2452 X<getsockopt>
2453
2454 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2455 Options may exist at multiple protocol levels depending on the socket
2456 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2457 C<Socket> module) will exist. To query options at another level the
2458 protocol number of the appropriate protocol controlling the option
2459 should be supplied. For example, to indicate that an option is to be
2460 interpreted by the TCP protocol, LEVEL should be set to the protocol
2461 number of TCP, which you can get using C<getprotobyname>.
2462
2463 The function returns a packed string representing the requested socket
2464 option, or C<undef> on error, with the reason for the error placed in
2465 C<$!>. Just what is in the packed string depends on LEVEL and OPTNAME;
2466 consult getsockopt(2) for details.  A common case is that the option is an
2467 integer, in which case the result is a packed integer, which you can decode
2468 using C<unpack> with the C<i> (or C<I>) format.
2469
2470 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2471
2472     use Socket qw(:all);
2473
2474     defined(my $tcp = getprotobyname("tcp"))
2475         or die "Could not determine the protocol number for tcp";
2476     # my $tcp = IPPROTO_TCP; # Alternative
2477     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2478         or die "getsockopt TCP_NODELAY: $!";
2479     my $nodelay = unpack("I", $packed);
2480     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2481
2482 Portability issues: L<perlport/getsockopt>.
2483
2484 =item given EXPR BLOCK
2485 X<given>
2486
2487 =item given BLOCK
2488
2489 C<given> is analogous to the C<switch> keyword in other languages. C<given>
2490 and C<when> are used in Perl to implement C<switch>/C<case> like statements.
2491 Only available after Perl 5.10.  For example:
2492
2493     use v5.10;
2494     given ($fruit) {
2495         when (/apples?/) {
2496             print "I like apples."
2497         }
2498         when (/oranges?/) {
2499             print "I don't like oranges."
2500         }
2501         default {
2502             print "I don't like anything"
2503         }
2504     }
2505
2506 See L<perlsyn/"Switch statements"> for detailed information.
2507
2508 =item glob EXPR
2509 X<glob> X<wildcard> X<filename, expansion> X<expand>
2510
2511 =item glob
2512
2513 In list context, returns a (possibly empty) list of filename expansions on
2514 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2515 scalar context, glob iterates through such filename expansions, returning
2516 undef when the list is exhausted. This is the internal function
2517 implementing the C<< <*.c> >> operator, but you can use it directly. If
2518 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2519 more detail in L<perlop/"I/O Operators">.
2520
2521 Note that C<glob> splits its arguments on whitespace and treats
2522 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2523 matches all files with a F<.c> or F<.h> extension.  The expression
2524 C<glob(".* *")> matches all files in the current working directory.
2525
2526 If non-empty braces are the only wildcard characters used in the
2527 C<glob>, no filenames are matched, but potentially many strings
2528 are returned.  For example, this produces nine strings, one for
2529 each pairing of fruits and colors:
2530
2531     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2532
2533 Beginning with v5.6.0, this operator is implemented using the standard
2534 C<File::Glob> extension.  See L<File::Glob> for details, including
2535 C<bsd_glob> which does not treat whitespace as a pattern separator.
2536
2537 Portability issues: L<perlport/glob>.
2538
2539 =item gmtime EXPR
2540 X<gmtime> X<UTC> X<Greenwich>
2541
2542 =item gmtime
2543
2544 Works just like L</localtime> but the returned values are
2545 localized for the standard Greenwich time zone.
2546
2547 Note: When called in list context, $isdst, the last value
2548 returned by gmtime, is always C<0>.  There is no
2549 Daylight Saving Time in GMT.
2550
2551 Portability issues: L<perlport/gmtime>.
2552
2553 =item goto LABEL
2554 X<goto> X<jump> X<jmp>
2555
2556 =item goto EXPR
2557
2558 =item goto &NAME
2559
2560 The C<goto-LABEL> form finds the statement labeled with LABEL and
2561 resumes execution there. It can't be used to get out of a block or
2562 subroutine given to C<sort>.  It can be used to go almost anywhere
2563 else within the dynamic scope, including out of subroutines, but it's
2564 usually better to use some other construct such as C<last> or C<die>.
2565 The author of Perl has never felt the need to use this form of C<goto>
2566 (in Perl, that is; C is another matter).  (The difference is that C
2567 does not offer named loops combined with loop control.  Perl does, and
2568 this replaces most structured uses of C<goto> in other languages.)
2569
2570 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2571 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2572 necessarily recommended if you're optimizing for maintainability:
2573
2574     goto ("FOO", "BAR", "GLARCH")[$i];
2575
2576 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2577 function" rule. A pair of parentheses following it does not (necessarily)
2578 delimit its argument. C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2579
2580 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2581 deprecated and will issue a warning.  Even then, it may not be used to
2582 go into any construct that requires initialization, such as a
2583 subroutine or a C<foreach> loop.  It also can't be used to go into a
2584 construct that is optimized away.
2585
2586 The C<goto-&NAME> form is quite different from the other forms of
2587 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2588 doesn't have the stigma associated with other gotos.  Instead, it
2589 exits the current subroutine (losing any changes set by local()) and
2590 immediately calls in its place the named subroutine using the current
2591 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2592 load another subroutine and then pretend that the other subroutine had
2593 been called in the first place (except that any modifications to C<@_>
2594 in the current subroutine are propagated to the other subroutine.)
2595 After the C<goto>, not even C<caller> will be able to tell that this
2596 routine was called first.
2597
2598 NAME needn't be the name of a subroutine; it can be a scalar variable
2599 containing a code reference or a block that evaluates to a code
2600 reference.
2601
2602 =item grep BLOCK LIST
2603 X<grep>
2604
2605 =item grep EXPR,LIST
2606
2607 This is similar in spirit to, but not the same as, grep(1) and its
2608 relatives.  In particular, it is not limited to using regular expressions.
2609
2610 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2611 C<$_> to each element) and returns the list value consisting of those
2612 elements for which the expression evaluated to true.  In scalar
2613 context, returns the number of times the expression was true.
2614
2615     @foo = grep(!/^#/, @bar);    # weed out comments
2616
2617 or equivalently,
2618
2619     @foo = grep {!/^#/} @bar;    # weed out comments
2620
2621 Note that C<$_> is an alias to the list value, so it can be used to
2622 modify the elements of the LIST.  While this is useful and supported,
2623 it can cause bizarre results if the elements of LIST are not variables.
2624 Similarly, grep returns aliases into the original list, much as a for
2625 loop's index variable aliases the list elements.  That is, modifying an
2626 element of a list returned by grep (for example, in a C<foreach>, C<map>
2627 or another C<grep>) actually modifies the element in the original list.
2628 This is usually something to be avoided when writing clear code.
2629
2630 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2631 been declared with C<my $_>) then, in addition to being locally aliased to
2632 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2633 can't be seen from the outside, avoiding any potential side-effects.
2634
2635 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2636
2637 =item hex EXPR
2638 X<hex> X<hexadecimal>
2639
2640 =item hex
2641
2642 Interprets EXPR as a hex string and returns the corresponding value.
2643 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2644 L</oct>.)  If EXPR is omitted, uses C<$_>.
2645
2646     print hex '0xAf'; # prints '175'
2647     print hex 'aF';   # same
2648
2649 Hex strings may only represent integers.  Strings that would cause
2650 integer overflow trigger a warning.  Leading whitespace is not stripped,
2651 unlike oct(). To present something as hex, look into L</printf>,
2652 L</sprintf>, and L</unpack>.
2653
2654 =item import LIST
2655 X<import>
2656
2657 There is no builtin C<import> function.  It is just an ordinary
2658 method (subroutine) defined (or inherited) by modules that wish to export
2659 names to another module.  The C<use> function calls the C<import> method
2660 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2661
2662 =item index STR,SUBSTR,POSITION
2663 X<index> X<indexOf> X<InStr>
2664
2665 =item index STR,SUBSTR
2666
2667 The index function searches for one string within another, but without
2668 the wildcard-like behavior of a full regular-expression pattern match.
2669 It returns the position of the first occurrence of SUBSTR in STR at
2670 or after POSITION.  If POSITION is omitted, starts searching from the
2671 beginning of the string.  POSITION before the beginning of the string
2672 or after its end is treated as if it were the beginning or the end,
2673 respectively.  POSITION and the return value are based at C<0> (or whatever
2674 you've set the C<$[> variable to--but don't do that).  If the substring
2675 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2676
2677 =item int EXPR
2678 X<int> X<integer> X<truncate> X<trunc> X<floor>
2679
2680 =item int
2681
2682 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2683 You should not use this function for rounding: one because it truncates
2684 towards C<0>, and two because machine representations of floating-point
2685 numbers can sometimes produce counterintuitive results.  For example,
2686 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2687 because it's really more like -268.99999999999994315658 instead.  Usually,
2688 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2689 functions will serve you better than will int().
2690
2691 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2692 X<ioctl>
2693
2694 Implements the ioctl(2) function.  You'll probably first have to say
2695
2696     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2697
2698 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2699 exist or doesn't have the correct definitions you'll have to roll your
2700 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2701 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2702 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2703 written depending on the FUNCTION; a C pointer to the string value of SCALAR
2704 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2705 has no string value but does have a numeric value, that value will be
2706 passed rather than a pointer to the string value.  To guarantee this to be
2707 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2708 functions may be needed to manipulate the values of structures used by
2709 C<ioctl>.
2710
2711 The return value of C<ioctl> (and C<fcntl>) is as follows:
2712
2713     if OS returns:      then Perl returns:
2714         -1               undefined value
2715          0              string "0 but true"
2716     anything else           that number
2717
2718 Thus Perl returns true on success and false on failure, yet you can
2719 still easily determine the actual value returned by the operating
2720 system:
2721
2722     $retval = ioctl(...) || -1;
2723     printf "System returned %d\n", $retval;
2724
2725 The special string C<"0 but true"> is exempt from B<-w> complaints
2726 about improper numeric conversions.
2727
2728 Portability issues: L<perlport/ioctl>.
2729
2730 =item join EXPR,LIST
2731 X<join>
2732
2733 Joins the separate strings of LIST into a single string with fields
2734 separated by the value of EXPR, and returns that new string.  Example:
2735
2736     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2737
2738 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2739 first argument.  Compare L</split>.
2740
2741 =item keys HASH
2742 X<keys> X<key>
2743
2744 =item keys ARRAY
2745
2746 =item keys EXPR
2747
2748 Returns a list consisting of all the keys of the named hash, or the indices
2749 of an array. (In scalar context, returns the number of keys or indices.)
2750
2751 The keys of a hash are returned in an apparently random order.  The actual
2752 random order is subject to change in future versions of Perl, but it
2753 is guaranteed to be the same order as either the C<values> or C<each>
2754 function produces (given that the hash has not been modified).  Since
2755 Perl 5.8.1 the ordering can be different even between different runs of
2756 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2757 Attacks">).
2758
2759 As a side effect, calling keys() resets the internal interator of the HASH or ARRAY
2760 (see L</each>).  In particular, calling keys() in void context resets
2761 the iterator with no other overhead.
2762
2763 Here is yet another way to print your environment:
2764
2765     @keys = keys %ENV;
2766     @values = values %ENV;
2767     while (@keys) {
2768         print pop(@keys), '=', pop(@values), "\n";
2769     }
2770
2771 or how about sorted by key:
2772
2773     foreach $key (sort(keys %ENV)) {
2774         print $key, '=', $ENV{$key}, "\n";
2775     }
2776
2777 The returned values are copies of the original keys in the hash, so
2778 modifying them will not affect the original hash.  Compare L</values>.
2779
2780 To sort a hash by value, you'll need to use a C<sort> function.
2781 Here's a descending numeric sort of a hash by its values:
2782
2783     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2784         printf "%4d %s\n", $hash{$key}, $key;
2785     }
2786
2787 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
2788 allocated for the given hash.  This can gain you a measure of efficiency if
2789 you know the hash is going to get big.  (This is similar to pre-extending
2790 an array by assigning a larger number to $#array.)  If you say
2791
2792     keys %hash = 200;
2793
2794 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2795 in fact, since it rounds up to the next power of two.  These
2796 buckets will be retained even if you do C<%hash = ()>, use C<undef
2797 %hash> if you want to free the storage while C<%hash> is still in scope.
2798 You can't shrink the number of buckets allocated for the hash using
2799 C<keys> in this way (but you needn't worry about doing this by accident,
2800 as trying has no effect). C<keys @array> in an lvalue context is a syntax
2801 error.
2802
2803 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
2804 a reference to an unblessed hash or array.  The argument will be
2805 dereferenced automatically.  This aspect of C<keys> is considered highly
2806 experimental.  The exact behaviour may change in a future version of Perl.
2807
2808     for (keys $hashref) { ... }
2809     for (keys $obj->get_arrayref) { ... }
2810
2811 See also C<each>, C<values>, and C<sort>.
2812
2813 =item kill SIGNAL, LIST
2814 X<kill> X<signal>
2815
2816 Sends a signal to a list of processes.  Returns the number of
2817 processes successfully signaled (which is not necessarily the
2818 same as the number actually killed).
2819
2820     $cnt = kill 1, $child1, $child2;
2821     kill 9, @goners;
2822
2823 If SIGNAL is zero, no signal is sent to the process, but C<kill>
2824 checks whether it's I<possible> to send a signal to it (that
2825 means, to be brief, that the process is owned by the same user, or we are
2826 the super-user).  This is useful to check that a child process is still
2827 alive (even if only as a zombie) and hasn't changed its UID.  See
2828 L<perlport> for notes on the portability of this construct.
2829
2830 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2831 of processes. That means you usually want to use positive not negative signals.
2832 You may also use a signal name in quotes.
2833
2834 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2835 the operating system.  For example, on POSIX-conforming systems, zero will
2836 signal the current process group and -1 will signal all processes.
2837
2838 See L<perlipc/"Signals"> for more details.
2839
2840 On some platforms such as Windows where the fork() system call is not available.
2841 Perl can be built to emulate fork() at the interpreter level.
2842 This emulation has limitations related to kill that have to be considered,
2843 for code running on Windows and in code intended to be portable.
2844
2845 See L<perlfork> for more details.
2846
2847 Portability issues: L<perlport/kill>.
2848
2849 =item last LABEL
2850 X<last> X<break>
2851
2852 =item last
2853
2854 The C<last> command is like the C<break> statement in C (as used in
2855 loops); it immediately exits the loop in question.  If the LABEL is
2856 omitted, the command refers to the innermost enclosing loop.  The
2857 C<continue> block, if any, is not executed:
2858
2859     LINE: while (<STDIN>) {
2860         last LINE if /^$/;  # exit when done with header
2861         #...
2862     }
2863
2864 C<last> cannot be used to exit a block that returns a value such as
2865 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
2866 a grep() or map() operation.
2867
2868 Note that a block by itself is semantically identical to a loop
2869 that executes once.  Thus C<last> can be used to effect an early
2870 exit out of such a block.
2871
2872 See also L</continue> for an illustration of how C<last>, C<next>, and
2873 C<redo> work.
2874
2875 =item lc EXPR
2876 X<lc> X<lowercase>
2877
2878 =item lc
2879
2880 Returns a lowercased version of EXPR.  This is the internal function
2881 implementing the C<\L> escape in double-quoted strings.
2882
2883 If EXPR is omitted, uses C<$_>.
2884
2885 What gets returned depends on several factors:
2886
2887 =over
2888
2889 =item If C<use bytes> is in effect:
2890
2891 =over
2892
2893 =item On EBCDIC platforms
2894
2895 The results are what the C language system call C<tolower()> returns.
2896
2897 =item On ASCII platforms
2898
2899 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
2900 respectively.
2901
2902 =back
2903
2904 =item Otherwise, If EXPR has the UTF8 flag set
2905
2906 If the current package has a subroutine named C<ToLower>, it will be used to
2907 change the case
2908 (See L<perlunicode/"User-Defined Case Mappings (for serious hackers only)">.)
2909 Otherwise Unicode semantics are used for the case change.
2910
2911 =item Otherwise, if C<use locale> is in effect
2912
2913 Respects current LC_CTYPE locale.  See L<perllocale>.
2914
2915 =item Otherwise, if C<use feature 'unicode_strings'> is in effect:
2916
2917 Unicode semantics are used for the case change.  Any subroutine named
2918 C<ToLower> will be ignored.
2919
2920 =item Otherwise:
2921
2922 =over
2923
2924 =item On EBCDIC platforms
2925
2926 The results are what the C language system call C<tolower()> returns.
2927
2928 =item On ASCII platforms
2929
2930 ASCII semantics are used for the case change.  The lowercase of any character
2931 outside the ASCII range is the character itself.
2932
2933 =back
2934
2935 =back
2936
2937 =item lcfirst EXPR
2938 X<lcfirst> X<lowercase>
2939
2940 =item lcfirst
2941
2942 Returns the value of EXPR with the first character lowercased.  This
2943 is the internal function implementing the C<\l> escape in
2944 double-quoted strings.
2945
2946 If EXPR is omitted, uses C<$_>.
2947
2948 This function behaves the same way under various pragmata, such as in a locale,
2949 as L</lc> does.
2950
2951 =item length EXPR
2952 X<length> X<size>
2953
2954 =item length
2955
2956 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2957 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
2958 C<undef>.
2959
2960 This function cannot be used on an entire array or hash to find out how
2961 many elements these have.  For that, use C<scalar @array> and C<scalar keys
2962 %hash>, respectively.
2963
2964 Like all Perl character operations, length() normally deals in logical
2965 characters, not physical bytes.  For how many bytes a string encoded as
2966 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
2967 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
2968
2969 =item link OLDFILE,NEWFILE
2970 X<link>
2971
2972 Creates a new filename linked to the old filename.  Returns true for
2973 success, false otherwise.
2974
2975 Portability issues: L<perlport/link>.
2976
2977 =item listen SOCKET,QUEUESIZE
2978 X<listen>
2979
2980 Does the same thing that the listen(2) system call does.  Returns true if
2981 it succeeded, false otherwise.  See the example in
2982 L<perlipc/"Sockets: Client/Server Communication">.
2983
2984 =item local EXPR
2985 X<local>
2986
2987 You really probably want to be using C<my> instead, because C<local> isn't
2988 what most people think of as "local".  See
2989 L<perlsub/"Private Variables via my()"> for details.
2990
2991 A local modifies the listed variables to be local to the enclosing
2992 block, file, or eval.  If more than one value is listed, the list must
2993 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2994 for details, including issues with tied arrays and hashes.
2995
2996 The C<delete local EXPR> construct can also be used to localize the deletion
2997 of array/hash elements to the current block.
2998 See L<perlsub/"Localized deletion of elements of composite types">.
2999
3000 =item localtime EXPR
3001 X<localtime> X<ctime>
3002
3003 =item localtime
3004
3005 Converts a time as returned by the time function to a 9-element list
3006 with the time analyzed for the local time zone.  Typically used as
3007 follows:
3008
3009     #  0    1    2     3     4    5     6     7     8
3010     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3011                                                 localtime(time);
3012
3013 All list elements are numeric and come straight out of the C `struct
3014 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3015 of the specified time.
3016
3017 C<$mday> is the day of the month and C<$mon> the month in
3018 the range C<0..11>, with 0 indicating January and 11 indicating December.
3019 This makes it easy to get a month name from a list:
3020
3021     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
3022     print "$abbr[$mon] $mday";
3023     # $mon=9, $mday=18 gives "Oct 18"
3024
3025 C<$year> is the number of years since 1900, B<not> just the last two digits
3026 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
3027 to get a 4-digit year is simply:
3028
3029     $year += 1900;
3030
3031 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
3032 to do that, would you?
3033
3034 To get the last two digits of the year (e.g., "01" in 2001) do:
3035
3036     $year = sprintf("%02d", $year % 100);
3037
3038 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3039 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3040 (or C<0..365> in leap years.)
3041
3042 C<$isdst> is true if the specified time occurs during Daylight Saving
3043 Time, false otherwise.
3044
3045 If EXPR is omitted, C<localtime()> uses the current time (as returned
3046 by time(3)).
3047
3048 In scalar context, C<localtime()> returns the ctime(3) value:
3049
3050     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3051
3052 This scalar value is B<not> locale-dependent but is a Perl builtin. For GMT
3053 instead of local time use the L</gmtime> builtin. See also the
3054 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3055 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3056 and mktime(3) functions.
3057
3058 To get somewhat similar but locale-dependent date strings, set up your
3059 locale environment variables appropriately (please see L<perllocale>) and
3060 try for example:
3061
3062     use POSIX qw(strftime);
3063     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3064     # or for GMT formatted appropriately for your locale:
3065     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3066
3067 Note that the C<%a> and C<%b>, the short forms of the day of the week
3068 and the month of the year, may not necessarily be three characters wide.
3069
3070 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3071 by-name access mechanism to the gmtime() and localtime() functions,
3072 respectively.
3073
3074 For a comprehensive date and time representation look at the
3075 L<DateTime> module on CPAN.
3076
3077 Portability issues: L<perlport/localtime>.
3078
3079 =item lock THING
3080 X<lock>
3081
3082 This function places an advisory lock on a shared variable or referenced
3083 object contained in I<THING> until the lock goes out of scope.
3084
3085 The value returned is the scalar itself, if the argument is a scalar, or a
3086 reference, if the argument is a hash or array.
3087
3088 lock() is a "weak keyword" : this means that if you've defined a function
3089 by this name (before any calls to it), that function will be called
3090 instead.  If you are not under C<use threads::shared> this does nothing.
3091 See L<threads::shared>.
3092
3093 =item log EXPR
3094 X<log> X<logarithm> X<e> X<ln> X<base>
3095
3096 =item log
3097
3098 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3099 returns the log of C<$_>.  To get the
3100 log of another base, use basic algebra:
3101 The base-N log of a number is equal to the natural log of that number
3102 divided by the natural log of N.  For example:
3103
3104     sub log10 {
3105         my $n = shift;
3106         return log($n)/log(10);
3107     }
3108
3109 See also L</exp> for the inverse operation.
3110
3111 =item lstat EXPR
3112 X<lstat>
3113
3114 =item lstat
3115
3116 Does the same thing as the C<stat> function (including setting the
3117 special C<_> filehandle) but stats a symbolic link instead of the file
3118 the symbolic link points to.  If symbolic links are unimplemented on
3119 your system, a normal C<stat> is done.  For much more detailed
3120 information, please see the documentation for C<stat>.
3121
3122 If EXPR is omitted, stats C<$_>.
3123
3124 Portability issues: L<perlport/lstat>.
3125
3126 =item m//
3127
3128 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3129
3130 =item map BLOCK LIST
3131 X<map>
3132
3133 =item map EXPR,LIST
3134
3135 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3136 C<$_> to each element) and returns the list value composed of the
3137 results of each such evaluation.  In scalar context, returns the
3138 total number of elements so generated.  Evaluates BLOCK or EXPR in
3139 list context, so each element of LIST may produce zero, one, or
3140 more elements in the returned value.
3141
3142     @chars = map(chr, @numbers);
3143
3144 translates a list of numbers to the corresponding characters.
3145
3146     my @squares = map { $_ * $_ } @numbers;
3147
3148 translates a list of numbers to their squared values.
3149
3150     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3151
3152 shows that number of returned elements can differ from the number of
3153 input elements. To omit an element, return an empty list ().
3154 This could also be achieved by writing
3155
3156     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3157
3158 which makes the intention more clear.
3159
3160 Map always returns a list, which can be
3161 assigned to a hash such that the elements
3162 become key/value pairs. See L<perldata> for more details.
3163
3164     %hash = map { get_a_key_for($_) => $_ } @array;
3165
3166 is just a funny way to write
3167
3168     %hash = ();
3169     foreach (@array) {
3170         $hash{get_a_key_for($_)} = $_;
3171     }
3172
3173 Note that C<$_> is an alias to the list value, so it can be used to
3174 modify the elements of the LIST.  While this is useful and supported,
3175 it can cause bizarre results if the elements of LIST are not variables.
3176 Using a regular C<foreach> loop for this purpose would be clearer in
3177 most cases.  See also L</grep> for an array composed of those items of
3178 the original list for which the BLOCK or EXPR evaluates to true.
3179
3180 If C<$_> is lexical in the scope where the C<map> appears (because it has
3181 been declared with C<my $_>), then, in addition to being locally aliased to
3182 the list elements, C<$_> keeps being lexical inside the block; that is, it
3183 can't be seen from the outside, avoiding any potential side-effects.
3184
3185 C<{> starts both hash references and blocks, so C<map { ...> could be either
3186 the start of map BLOCK LIST or map EXPR, LIST. Because Perl doesn't look
3187 ahead for the closing C<}> it has to take a guess at which it's dealing with
3188 based on what it finds just after the C<{>. Usually it gets it right, but if it
3189 doesn't it won't realize something is wrong until it gets to the C<}> and
3190 encounters the missing (or unexpected) comma. The syntax error will be
3191 reported close to the C<}>, but you'll need to change something near the C<{>
3192 such as using a unary C<+> to give Perl some help:
3193
3194     %hash = map {  "\L$_" => 1  } @array  # perl guesses EXPR.  wrong
3195     %hash = map { +"\L$_" => 1  } @array  # perl guesses BLOCK. right
3196     %hash = map { ("\L$_" => 1) } @array  # this also works
3197     %hash = map {  lc($_) => 1  } @array  # as does this.
3198     %hash = map +( lc($_) => 1 ), @array  # this is EXPR and works!
3199
3200     %hash = map  ( lc($_), 1 ),   @array  # evaluates to (1, @array)
3201
3202 or to force an anon hash constructor use C<+{>:
3203
3204    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end
3205
3206 to get a list of anonymous hashes each with only one entry apiece.
3207
3208 =item mkdir FILENAME,MASK
3209 X<mkdir> X<md> X<directory, create>
3210
3211 =item mkdir FILENAME
3212
3213 =item mkdir
3214
3215 Creates the directory specified by FILENAME, with permissions
3216 specified by MASK (as modified by C<umask>).  If it succeeds it
3217 returns true; otherwise it returns false and sets C<$!> (errno).
3218 MASK defaults to 0777 if omitted, and FILENAME defaults
3219 to C<$_> if omitted.
3220
3221 In general, it is better to create directories with a permissive MASK
3222 and let the user modify that with their C<umask> than it is to supply
3223 a restrictive MASK and give the user no way to be more permissive.
3224 The exceptions to this rule are when the file or directory should be
3225 kept private (mail files, for instance).  The perlfunc(1) entry on
3226 C<umask> discusses the choice of MASK in more detail.
3227
3228 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3229 number of trailing slashes.  Some operating and filesystems do not get
3230 this right, so Perl automatically removes all trailing slashes to keep
3231 everyone happy.
3232
3233 To recursively create a directory structure, look at
3234 the C<mkpath> function of the L<File::Path> module.
3235
3236 =item msgctl ID,CMD,ARG
3237 X<msgctl>
3238
3239 Calls the System V IPC function msgctl(2).  You'll probably have to say
3240
3241     use IPC::SysV;
3242
3243 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3244 then ARG must be a variable that will hold the returned C<msqid_ds>
3245 structure.  Returns like C<ioctl>: the undefined value for error,
3246 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3247 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3248 C<IPC::Semaphore>.
3249
3250 Portability issues: L<perlport/msgctl>.
3251
3252 =item msgget KEY,FLAGS
3253 X<msgget>
3254
3255 Calls the System V IPC function msgget(2).  Returns the message queue
3256 id, or C<undef> on error.  See also
3257 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3258 C<IPC::Msg>.
3259
3260 Portability issues: L<perlport/msgget>.
3261
3262 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3263 X<msgrcv>
3264
3265 Calls the System V IPC function msgrcv to receive a message from
3266 message queue ID into variable VAR with a maximum message size of
3267 SIZE.  Note that when a message is received, the message type as a
3268 native long integer will be the first thing in VAR, followed by the
3269 actual message.  This packing may be opened with C<unpack("l! a*")>.
3270 Taints the variable.  Returns true if successful, false 
3271 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3272 C<IPC::SysV> and C<IPC::SysV::Msg>.
3273
3274 Portability issues: L<perlport/msgrcv>.
3275
3276 =item msgsnd ID,MSG,FLAGS
3277 X<msgsnd>
3278
3279 Calls the System V IPC function msgsnd to send the message MSG to the
3280 message queue ID.  MSG must begin with the native long integer message
3281 type, be followed by the length of the actual message, and then finally
3282 the message itself.  This kind of packing can be achieved with
3283 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3284 false on error.  See also the C<IPC::SysV>
3285 and C<IPC::SysV::Msg> documentation.
3286
3287 Portability issues: L<perlport/msgsnd>.
3288
3289 =item my EXPR
3290 X<my>
3291
3292 =item my TYPE EXPR
3293
3294 =item my EXPR : ATTRS
3295
3296 =item my TYPE EXPR : ATTRS
3297
3298 A C<my> declares the listed variables to be local (lexically) to the
3299 enclosing block, file, or C<eval>.  If more than one value is listed,
3300 the list must be placed in parentheses.
3301
3302 The exact semantics and interface of TYPE and ATTRS are still
3303 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3304 and attributes are handled using the C<attributes> pragma, or starting
3305 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3306 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3307 L<attributes>, and L<Attribute::Handlers>.
3308
3309 =item next LABEL
3310 X<next> X<continue>
3311
3312 =item next
3313
3314 The C<next> command is like the C<continue> statement in C; it starts
3315 the next iteration of the loop:
3316
3317     LINE: while (<STDIN>) {
3318         next LINE if /^#/;  # discard comments
3319         #...
3320     }
3321
3322 Note that if there were a C<continue> block on the above, it would get
3323 executed even on discarded lines.  If LABEL is omitted, the command
3324 refers to the innermost enclosing loop.
3325
3326 C<next> cannot be used to exit a block which returns a value such as
3327 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3328 a grep() or map() operation.
3329
3330 Note that a block by itself is semantically identical to a loop
3331 that executes once.  Thus C<next> will exit such a block early.
3332
3333 See also L</continue> for an illustration of how C<last>, C<next>, and
3334 C<redo> work.
3335
3336 =item no MODULE VERSION LIST
3337 X<no declarations>
3338 X<unimporting>
3339
3340 =item no MODULE VERSION
3341
3342 =item no MODULE LIST
3343
3344 =item no MODULE
3345
3346 =item no VERSION
3347
3348 See the C<use> function, of which C<no> is the opposite.
3349
3350 =item oct EXPR
3351 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3352
3353 =item oct
3354
3355 Interprets EXPR as an octal string and returns the corresponding
3356 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3357 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3358 binary string.  Leading whitespace is ignored in all three cases.)
3359 The following will handle decimal, binary, octal, and hex in standard
3360 Perl notation:
3361
3362     $val = oct($val) if $val =~ /^0/;
3363
3364 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3365 in octal), use sprintf() or printf():
3366
3367     $dec_perms = (stat("filename"))[2] & 07777;
3368     $oct_perm_str = sprintf "%o", $perms;
3369
3370 The oct() function is commonly used when a string such as C<644> needs
3371 to be converted into a file mode, for example.  Although Perl 
3372 automatically converts strings into numbers as needed, this automatic
3373 conversion assumes base 10.
3374
3375 Leading white space is ignored without warning, as too are any trailing 
3376 non-digits, such as a decimal point (C<oct> only handles non-negative
3377 integers, not negative integers or floating point).
3378
3379 =item open FILEHANDLE,EXPR
3380 X<open> X<pipe> X<file, open> X<fopen>
3381
3382 =item open FILEHANDLE,MODE,EXPR
3383
3384 =item open FILEHANDLE,MODE,EXPR,LIST
3385
3386 =item open FILEHANDLE,MODE,REFERENCE
3387
3388 =item open FILEHANDLE
3389
3390 Opens the file whose filename is given by EXPR, and associates it with
3391 FILEHANDLE.
3392
3393 Simple examples to open a file for reading:
3394
3395     open(my $fh, "<", "input.txt") 
3396         or die "cannot open < input.txt: $!";
3397
3398 and for writing:
3399
3400     open(my $fh, ">", "output.txt") 
3401         or die "cannot open > output.txt: $!";
3402
3403 (The following is a comprehensive reference to open(): for a gentler
3404 introduction you may consider L<perlopentut>.)
3405
3406 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3407 new filehandle is autovivified, meaning that the variable is assigned a
3408 reference to a newly allocated anonymous filehandle.  Otherwise if
3409 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3410 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3411 in effect.)
3412
3413 If EXPR is omitted, the global (package) scalar variable of the same
3414 name as the FILEHANDLE contains the filename.  (Note that lexical 
3415 variables--those declared with C<my> or C<state>--will not work for this
3416 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3417 call to open.)
3418
3419 If three (or more) arguments are specified, the open mode (including
3420 optional encoding) in the second argument are distinct from the filename in
3421 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3422 If MODE is C<< > >>, the file is opened for output, with existing files
3423 first being truncated ("clobbered") and nonexisting files newly created.
3424 If MODE is C<<< >> >>>, the file is opened for appending, again being
3425 created if necessary.
3426
3427 You can put a C<+> in front of the C<< > >> or C<< < >> to
3428 indicate that you want both read and write access to the file; thus
3429 C<< +< >> is almost always preferred for read/write updates--the 
3430 C<< +> >> mode would clobber the file first.  You cant usually use
3431 either read-write mode for updating textfiles, since they have
3432 variable-length records.  See the B<-i> switch in L<perlrun> for a
3433 better approach.  The file is created with permissions of C<0666>
3434 modified by the process's C<umask> value.
3435
3436 These various prefixes correspond to the fopen(3) modes of C<r>,
3437 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3438
3439 In the one- and two-argument forms of the call, the mode and filename
3440 should be concatenated (in that order), preferably separated by white
3441 space.  You can--but shouldn't--omit the mode in these forms when that mode
3442 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3443 the filename argument is a known literal.
3444
3445 For three or more arguments if MODE is C<|->, the filename is
3446 interpreted as a command to which output is to be piped, and if MODE
3447 is C<-|>, the filename is interpreted as a command that pipes
3448 output to us.  In the two-argument (and one-argument) form, one should
3449 replace dash (C<->) with the command.
3450 See L<perlipc/"Using open() for IPC"> for more examples of this.
3451 (You are not allowed to C<open> to a command that pipes both in I<and>
3452 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3453 L<perlipc/"Bidirectional Communication with Another Process"> for
3454 alternatives.)
3455
3456 In the form of pipe opens taking three or more arguments, if LIST is specified
3457 (extra arguments after the command name) then LIST becomes arguments
3458 to the command invoked if the platform supports it.  The meaning of
3459 C<open> with more than three arguments for non-pipe modes is not yet
3460 defined, but experimental "layers" may give extra LIST arguments
3461 meaning.
3462
3463 In the two-argument (and one-argument) form, opening C<< <- >> 
3464 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3465
3466 You may (and usually should) use the three-argument form of open to specify
3467 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3468 that affect how the input and output are processed (see L<open> and
3469 L<PerlIO> for more details). For example:
3470
3471   open(my $fh, "<:encoding(UTF-8)", "filename")
3472     || die "can't open UTF-8 encoded filename: $!";
3473
3474 opens the UTF8-encoded file containing Unicode characters;
3475 see L<perluniintro>. Note that if layers are specified in the
3476 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3477 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3478
3479 Open returns nonzero on success, the undefined value otherwise.  If
3480 the C<open> involved a pipe, the return value happens to be the pid of
3481 the subprocess.
3482
3483 If you're running Perl on a system that distinguishes between text
3484 files and binary files, then you should check out L</binmode> for tips
3485 for dealing with this.  The key distinction between systems that need
3486 C<binmode> and those that don't is their text file formats.  Systems
3487 like Unix, Mac OS, and Plan 9, that end lines with a single
3488 character and encode that character in C as C<"\n"> do not
3489 need C<binmode>.  The rest need it.
3490
3491 When opening a file, it's seldom a good idea to continue 
3492 if the request failed, so C<open> is frequently used with
3493 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3494 where you want to format a suitable error message (but there are
3495 modules that can help with that problem)) always check
3496 the return value from opening a file.  
3497
3498 As a special case the three-argument form with a read/write mode and the third
3499 argument being C<undef>:
3500
3501     open(my $tmp, "+>", undef) or die ...
3502
3503 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3504 works for symmetry, but you really should consider writing something
3505 to the temporary file first.  You will need to seek() to do the
3506 reading.
3507
3508 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3509 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3510 open filehandles directly to Perl scalars via:
3511
3512     open($fh, ">", \$variable) || ..
3513
3514 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3515
3516     close STDOUT;
3517     open(STDOUT, ">", \$variable)
3518         or die "Can't open STDOUT: $!";
3519
3520 General examples:
3521
3522     $ARTICLE = 100;
3523     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3524     while (<ARTICLE>) {...
3525
3526     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3527     # if the open fails, output is discarded
3528
3529     open(my $dbase, "+<", "dbase.mine")      # open for update
3530         or die "Can't open 'dbase.mine' for update: $!";
3531
3532     open(my $dbase, "+<dbase.mine")          # ditto
3533         or die "Can't open 'dbase.mine' for update: $!";
3534
3535     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
3536         or die "Can't start caesar: $!";
3537
3538     open(ARTICLE, "caesar <$article |")      # ditto
3539         or die "Can't start caesar: $!";
3540
3541     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3542         or die "Can't start sort: $!";
3543
3544     # in-memory files
3545     open(MEMORY, ">", \$var)
3546         or die "Can't open memory file: $!";
3547     print MEMORY "foo!\n";                   # output will appear in $var
3548
3549     # process argument list of files along with any includes
3550
3551     foreach $file (@ARGV) {
3552         process($file, "fh00");
3553     }
3554
3555     sub process {
3556         my($filename, $input) = @_;
3557         $input++;    # this is a string increment
3558         unless (open($input, "<", $filename)) {
3559             print STDERR "Can't open $filename: $!\n";
3560             return;
3561         }
3562
3563         local $_;
3564         while (<$input>) {    # note use of indirection
3565             if (/^#include "(.*)"/) {
3566                 process($1, $input);
3567                 next;
3568             }
3569             #...          # whatever
3570         }
3571     }
3572
3573 See L<perliol> for detailed info on PerlIO.
3574
3575 You may also, in the Bourne shell tradition, specify an EXPR beginning
3576 with C<< >& >>, in which case the rest of the string is interpreted
3577 as the name of a filehandle (or file descriptor, if numeric) to be
3578 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3579 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3580 The mode you specify should match the mode of the original filehandle.
3581 (Duping a filehandle does not take into account any existing contents
3582 of IO buffers.) If you use the three-argument form, then you can pass either a
3583 number, the name of a filehandle, or the normal "reference to a glob".
3584
3585 Here is a script that saves, redirects, and restores C<STDOUT> and
3586 C<STDERR> using various methods:
3587
3588     #!/usr/bin/perl
3589     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3590     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
3591
3592     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
3593     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3594
3595     select STDERR; $| = 1;  # make unbuffered
3596     select STDOUT; $| = 1;  # make unbuffered
3597
3598     print STDOUT "stdout 1\n";  # this works for
3599     print STDERR "stderr 1\n";  # subprocesses too
3600
3601     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
3602     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
3603
3604     print STDOUT "stdout 2\n";
3605     print STDERR "stderr 2\n";
3606
3607 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3608 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3609 that file descriptor (and not call C<dup(2)>); this is more
3610 parsimonious of file descriptors.  For example:
3611
3612     # open for input, reusing the fileno of $fd
3613     open(FILEHANDLE, "<&=$fd")
3614
3615 or
3616
3617     open(FILEHANDLE, "<&=", $fd)
3618
3619 or
3620
3621     # open for append, using the fileno of OLDFH
3622     open(FH, ">>&=", OLDFH)
3623
3624 or
3625
3626     open(FH, ">>&=OLDFH")
3627
3628 Being parsimonious on filehandles is also useful (besides being
3629 parsimonious) for example when something is dependent on file
3630 descriptors, like for example locking using flock().  If you do just
3631 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
3632 descriptor as B, and therefore flock(A) will not flock(B) nor vice
3633 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
3634 the same underlying system file descriptor.
3635
3636 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
3637 fdopen() to implement the C<=> functionality.  On many Unix systems,
3638 fdopen() fails when file descriptors exceed a certain value, typically 255.
3639 For Perls 5.8.0 and later, PerlIO is (most often) the default.
3640
3641 You can see whether your Perl was built with PerlIO by running C<perl -V>
3642 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
3643 have PerlIO; otherwise you don't.
3644
3645 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
3646 with the one- or two-argument forms of C<open>), 
3647 an implicit C<fork> is done, so C<open> returns twice: in the parent
3648 process it returns the pid
3649 of the child process, and in the child process it returns (a defined) C<0>.
3650 Use C<defined($pid)> or C<//> to determine whether the open was successful.
3651
3652 For example, use either
3653
3654     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
3655
3656 or
3657     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
3658
3659 followed by 
3660
3661     if ($child_pid) {
3662         # am the parent:
3663         # either write TO_KID or else read FROM_KID
3664         ...
3665         wait $child_pid;
3666     } else {
3667         # am the child; use STDIN/STDOUT normally
3668         ...
3669         exit;
3670     } 
3671
3672 The filehandle behaves normally for the parent, but I/O to that
3673 filehandle is piped from/to the STDOUT/STDIN of the child process.
3674 In the child process, the filehandle isn't opened--I/O happens from/to
3675 the new STDOUT/STDIN.  Typically this is used like the normal
3676 piped open when you want to exercise more control over just how the
3677 pipe command gets executed, such as when running setuid and
3678 you don't want to have to scan shell commands for metacharacters.
3679
3680 The following blocks are more or less equivalent:
3681
3682     open(FOO, "|tr '[a-z]' '[A-Z]'");
3683     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
3684     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
3685     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
3686
3687     open(FOO, "cat -n '$file'|");
3688     open(FOO, "-|", "cat -n '$file'");
3689     open(FOO, "-|") || exec "cat", "-n", $file;
3690     open(FOO, "-|", "cat", "-n", $file);
3691
3692 The last two examples in each block show the pipe as "list form", which is
3693 not yet supported on all platforms.  A good rule of thumb is that if
3694 your platform has a real C<fork()> (in other words, if your platform is
3695 Unix, including Linux and MacOS X), you can use the list form.  You would 
3696 want to use the list form of the pipe so you can pass literal arguments
3697 to the command without risk of the shell interpreting any shell metacharacters
3698 in them.  However, this also bars you from opening pipes to commands
3699 that intentionally contain shell metacharacters, such as:
3700
3701     open(FOO, "|cat -n | expand -4 | lpr")
3702         // die "Can't open pipeline to lpr: $!";
3703
3704 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3705
3706 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3707 output before any operation that may do a fork, but this may not be
3708 supported on some platforms (see L<perlport>).  To be safe, you may need
3709 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3710 of C<IO::Handle> on any open handles.
3711
3712 On systems that support a close-on-exec flag on files, the flag will
3713 be set for the newly opened file descriptor as determined by the value
3714 of C<$^F>.  See L<perlvar/$^F>.
3715
3716 Closing any piped filehandle causes the parent process to wait for the
3717 child to finish, then returns the status value in C<$?> and
3718 C<${^CHILD_ERROR_NATIVE}>.
3719
3720 The filename passed to the one- and two-argument forms of open() will
3721 have leading and trailing whitespace deleted and normal
3722 redirection characters honored.  This property, known as "magic open",
3723 can often be used to good effect.  A user could specify a filename of
3724 F<"rsh cat file |">, or you could change certain filenames as needed:
3725
3726     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3727     open(FH, $filename) or die "Can't open $filename: $!";
3728
3729 Use the three-argument form to open a file with arbitrary weird characters in it,
3730
3731     open(FOO, "<", $file)
3732         || die "can't open < $file: $!";
3733
3734 otherwise it's necessary to protect any leading and trailing whitespace:
3735
3736     $file =~ s#^(\s)#./$1#;
3737     open(FOO, "< $file\0")
3738         || die "open failed: $!";
3739
3740 (this may not work on some bizarre filesystems).  One should
3741 conscientiously choose between the I<magic> and I<three-argument> form
3742 of open():
3743
3744     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
3745
3746 will allow the user to specify an argument of the form C<"rsh cat file |">,
3747 but will not work on a filename that happens to have a trailing space, while
3748
3749     open(IN, "<", $ARGV[0])
3750         || die "can't open < $ARGV[0]: $!";
3751
3752 will have exactly the opposite restrictions.
3753
3754 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3755 should use the C<sysopen> function, which involves no such magic (but may
3756 use subtly different filemodes than Perl open(), which is mapped to C
3757 fopen()).  This is another way to protect your filenames from
3758 interpretation.  For example:
3759
3760     use IO::Handle;
3761     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3762         or die "sysopen $path: $!";
3763     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3764     print HANDLE "stuff $$\n";
3765     seek(HANDLE, 0, 0);
3766     print "File contains: ", <HANDLE>;
3767
3768 Using the constructor from the C<IO::Handle> package (or one of its
3769 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3770 filehandles that have the scope of the variables used to hold them, then
3771 automatically (but silently) close once their reference counts become
3772 zero, typically at scope exit:
3773
3774     use IO::File;
3775     #...
3776     sub read_myfile_munged {
3777         my $ALL = shift;
3778         # or just leave it undef to autoviv
3779         my $handle = IO::File->new;
3780         open($handle, "<", "myfile") or die "myfile: $!";
3781         $first = <$handle>
3782             or return ();     # Automatically closed here.
3783         mung($first) or die "mung failed";  # Or here.
3784         return (first, <$handle>) if $ALL;  # Or here.
3785         return $first;                      # Or here.
3786     }
3787
3788 B<WARNING:> The previous example has a bug because the automatic
3789 close that happens when the refcount on C<handle> does not
3790 properly detect and report failures.  I<Always> close the handle
3791 yourself and inspect the return value.
3792
3793     close($handle) 
3794         || warn "close failed: $!";
3795
3796 See L</seek> for some details about mixing reading and writing.
3797
3798 Portability issues: L<perlport/open>.
3799
3800 =item opendir DIRHANDLE,EXPR
3801 X<opendir>
3802
3803 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3804 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3805 DIRHANDLE may be an expression whose value can be used as an indirect
3806 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3807 scalar variable (or array or hash element), the variable is assigned a
3808 reference to a new anonymous dirhandle; that is, it's autovivified.
3809 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3810
3811 See the example at C<readdir>.
3812
3813 =item ord EXPR
3814 X<ord> X<encoding>
3815
3816 =item ord
3817
3818 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3819 or Unicode) value of the first character of EXPR.  
3820 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
3821 (Note I<character>, not byte.)
3822
3823 For the reverse, see L</chr>.
3824 See L<perlunicode> for more about Unicode.
3825
3826 =item our EXPR
3827 X<our> X<global>
3828
3829 =item our TYPE EXPR
3830
3831 =item our EXPR : ATTRS
3832
3833 =item our TYPE EXPR : ATTRS
3834
3835 C<our> associates a simple name with a package variable in the current
3836 package for use within the current scope.  When C<use strict 'vars'> is in
3837 effect, C<our> lets you use declared global variables without qualifying
3838 them with package names, within the lexical scope of the C<our> declaration.
3839 In this way C<our> differs from C<use vars>, which is package-scoped.
3840
3841 Unlike C<my> or C<state>, which allocates storage for a variable and
3842 associates a simple name with that storage for use within the current
3843 scope, C<our> associates a simple name with a package (read: global)
3844 variable in the current package, for use within the current lexical scope.
3845 In other words, C<our> has the same scoping rules as C<my> or C<state>, but
3846 does not necessarily create a variable.
3847
3848 If more than one value is listed, the list must be placed
3849 in parentheses.
3850
3851     our $foo;
3852     our($bar, $baz);
3853
3854 An C<our> declaration declares a global variable that will be visible
3855 across its entire lexical scope, even across package boundaries.  The
3856 package in which the variable is entered is determined at the point
3857 of the declaration, not at the point of use.  This means the following
3858 behavior holds:
3859
3860     package Foo;
3861     our $bar;      # declares $Foo::bar for rest of lexical scope
3862     $bar = 20;
3863
3864     package Bar;
3865     print $bar;    # prints 20, as it refers to $Foo::bar
3866
3867 Multiple C<our> declarations with the same name in the same lexical
3868 scope are allowed if they are in different packages.  If they happen
3869 to be in the same package, Perl will emit warnings if you have asked
3870 for them, just like multiple C<my> declarations.  Unlike a second
3871 C<my> declaration, which will bind the name to a fresh variable, a
3872 second C<our> declaration in the same package, in the same scope, is
3873 merely redundant.
3874
3875     use warnings;
3876     package Foo;
3877     our $bar;      # declares $Foo::bar for rest of lexical scope
3878     $bar = 20;
3879
3880     package Bar;
3881     our $bar = 30; # declares $Bar::bar for rest of lexical scope
3882     print $bar;    # prints 30
3883
3884     our $bar;      # emits warning but has no other effect
3885     print $bar;    # still prints 30
3886
3887 An C<our> declaration may also have a list of attributes associated
3888 with it.
3889
3890 The exact semantics and interface of TYPE and ATTRS are still
3891 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3892 and attributes are handled using the C<attributes> pragma, or starting
3893 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3894 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3895 L<attributes>, and L<Attribute::Handlers>.
3896
3897 =item pack TEMPLATE,LIST
3898 X<pack>
3899
3900 Takes a LIST of values and converts it into a string using the rules
3901 given by the TEMPLATE.  The resulting string is the concatenation of
3902 the converted values.  Typically, each converted value looks
3903 like its machine-level representation.  For example, on 32-bit machines
3904 an integer may be represented by a sequence of 4 bytes, which  will in
3905 Perl be presented as a string that's 4 characters long. 
3906
3907 See L<perlpacktut> for an introduction to this function.
3908
3909 The TEMPLATE is a sequence of characters that give the order and type
3910 of values, as follows:
3911
3912     a  A string with arbitrary binary data, will be null padded.
3913     A  A text (ASCII) string, will be space padded.
3914     Z  A null-terminated (ASCIZ) string, will be null padded.
3915
3916     b  A bit string (ascending bit order inside each byte, like vec()).
3917     B  A bit string (descending bit order inside each byte).
3918     h  A hex string (low nybble first).
3919     H  A hex string (high nybble first).
3920
3921     c  A signed char (8-bit) value.
3922     C  An unsigned char (octet) value.
3923     W  An unsigned char value (can be greater than 255).
3924
3925     s  A signed short (16-bit) value.
3926     S  An unsigned short value.
3927
3928     l  A signed long (32-bit) value.
3929     L  An unsigned long value.
3930
3931     q  A signed quad (64-bit) value.
3932     Q  An unsigned quad value.
3933       (Quads are available only if your system supports 64-bit
3934        integer values _and_ if Perl has been compiled to support those.
3935            Raises an exception otherwise.)
3936
3937     i  A signed integer value.
3938     I  A unsigned integer value.
3939       (This 'integer' is _at_least_ 32 bits wide.  Its exact
3940            size depends on what a local C compiler calls 'int'.)
3941
3942     n  An unsigned short (16-bit) in "network" (big-endian) order.
3943     N  An unsigned long (32-bit) in "network" (big-endian) order.
3944     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
3945     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
3946
3947     j   A Perl internal signed integer value (IV).
3948     J   A Perl internal unsigned integer value (UV).
3949
3950     f  A single-precision float in native format.
3951     d  A double-precision float in native format.
3952
3953     F  A Perl internal floating-point value (NV) in native format
3954     D  A float of long-double precision in native format.
3955       (Long doubles are available only if your system supports long
3956        double values _and_ if Perl has been compiled to support those.
3957            Raises an exception otherwise.)
3958
3959     p  A pointer to a null-terminated string.
3960     P  A pointer to a structure (fixed-length string).
3961
3962     u  A uuencoded string.
3963     U  A Unicode character number.  Encodes to a character in character mode
3964         and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in byte mode.
3965
3966     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3967        details).  Its bytes represent an unsigned integer in base 128,
3968        most significant digit first, with as few digits as possible.  Bit
3969        eight (the high bit) is set on each byte except the last.
3970
3971     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
3972     X  Back up a byte.
3973     @  Null-fill or truncate to absolute position, counted from the
3974        start of the innermost ()-group.
3975     .  Null-fill or truncate to absolute position specified by the value.
3976     (  Start of a ()-group.
3977
3978 One or more modifiers below may optionally follow certain letters in the
3979 TEMPLATE (the second column lists letters for which the modifier is valid):
3980
3981     !   sSlLiI     Forces native (short, long, int) sizes instead
3982                    of fixed (16-/32-bit) sizes.
3983
3984         xX         Make x and X act as alignment commands.
3985
3986         nNvV       Treat integers as signed instead of unsigned.
3987
3988         @.         Specify position as byte offset in the internal
3989                    representation of the packed string. Efficient but
3990                    dangerous.
3991
3992     >   sSiIlLqQ   Force big-endian byte-order on the type.
3993         jJfFdDpP   (The "big end" touches the construct.)
3994
3995     <   sSiIlLqQ   Force little-endian byte-order on the type.
3996         jJfFdDpP   (The "little end" touches the construct.)
3997
3998 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
3999 to force a particular byte-order on all components in that group, 
4000 including all its subgroups.
4001
4002 The following rules apply:
4003
4004 =over 
4005
4006 =item *
4007
4008 Each letter may optionally be followed by a number indicating the repeat
4009 count.  A numeric repeat count may optionally be enclosed in brackets, as
4010 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4011 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4012 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4013 something else, dscribed below.  Supplying a C<*> for the repeat count
4014 instead of a number means to use however many items are left, except for:
4015
4016 =over 
4017
4018 =item * 
4019
4020 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4021
4022 =item * 
4023
4024 <.>, where it means relative to the start of the string.
4025
4026 =item * 
4027
4028 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4029
4030 =back 
4031
4032 One can replace a numeric repeat count with a template letter enclosed in
4033 brackets to use the packed byte length of the bracketed template for the
4034 repeat count.
4035
4036 For example, the template C<x[L]> skips as many bytes as in a packed long,
4037 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4038 variable-expanded) unpacks.  If the template in brackets contains alignment
4039 commands (such as C<x![d]>), its packed length is calculated as if the
4040 start of the template had the maximal possible alignment.
4041
4042 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4043 trailing null byte, so the resulting string is always one byte longer than
4044 the byte length of the item itself.
4045
4046 When used with C<@>, the repeat count represents an offset from the start
4047 of the innermost C<()> group.
4048
4049 When used with C<.>, the repeat count determines the starting position to
4050 calculate the value offset as follows:
4051
4052 =over 
4053
4054 =item *
4055
4056 If the repeat count is C<0>, it's relative to the current position.
4057
4058 =item *
4059
4060 If the repeat count is C<*>, the offset is relative to the start of the
4061 packed string.
4062
4063 =item *
4064
4065 And if it's an integer I<n>, the offset is relative to the start of the
4066 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4067 bigger then the group level.
4068
4069 =back
4070
4071 The repeat count for C<u> is interpreted as the maximal number of bytes
4072 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
4073 count should not be more than 65.
4074
4075 =item *
4076
4077 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4078 string of length count, padding with nulls or spaces as needed.  When
4079 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4080 after the first null, and C<a> returns data with no stripping at all.
4081
4082 If the value to pack is too long, the result is truncated.  If it's too
4083 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4084 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4085 when the count is 0.
4086
4087 =item *
4088
4089 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4090 Each such format generates 1 bit of the result.  These are typically followed
4091 by a repeat count like C<B8> or C<B64>.
4092
4093 Each result bit is based on the least-significant bit of the corresponding
4094 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4095 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4096
4097 Starting from the beginning of the input string, each 8-tuple
4098 of characters is converted to 1 character of output.  With format C<b>,
4099 the first character of the 8-tuple determines the least-significant bit of a
4100 character; with format C<B>, it determines the most-significant bit of
4101 a character.
4102
4103 If the length of the input string is not evenly divisible by 8, the
4104 remainder is packed as if the input string were padded by null characters
4105 at the end.  Similarly during unpacking, "extra" bits are ignored.
4106
4107 If the input string is longer than needed, remaining characters are ignored.
4108
4109 A C<*> for the repeat count uses all characters of the input field.  
4110 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4111
4112 =item *
4113
4114 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4115 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4116
4117 For each such format, pack() generates 4 bits of result.
4118 With non-alphabetical characters, the result is based on the 4 least-significant
4119 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4120 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4121 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4122 is compatible with the usual hexadecimal digits, so that C<"a"> and
4123 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4124 characters with this format.
4125
4126 Starting from the beginning of the template to pack(), each pair
4127 of characters is converted to 1 character of output.  With format C<h>, the
4128 first character of the pair determines the least-significant nybble of the
4129 output character; with format C<H>, it determines the most-significant
4130 nybble.
4131
4132 If the length of the input string is not even, it behaves as if padded by
4133 a null character at the end.  Similarly, "extra" nybbles are ignored during
4134 unpacking.
4135
4136 If the input string is longer than needed, extra characters are ignored.
4137
4138 A C<*> for the repeat count uses all characters of the input field.  For
4139 unpack(), nybbles are converted to a string of hexadecimal digits.
4140
4141 =item *
4142
4143 The C<p> format packs a pointer to a null-terminated string.  You are
4144 responsible for ensuring that the string is not a temporary value, as that
4145 could potentially get deallocated before you got around to using the packed
4146 result.  The C<P> format packs a pointer to a structure of the size indicated
4147 by the length.  A null pointer is created if the corresponding value for
4148 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4149 unpacks into C<undef>.
4150
4151 If your system has a strange pointer size--meaning a pointer is neither as
4152 big as an int nor as big as a long--it may not be possible to pack or
4153 unpack pointers in big- or little-endian byte order.  Attempting to do
4154 so raises an exception.
4155
4156 =item *
4157
4158 The C</> template character allows packing and unpacking of a sequence of
4159 items where the packed structure contains a packed item count followed by
4160 the packed items themselves.  This is useful when the structure you're
4161 unpacking has encoded the sizes or repeat counts for some of its fields
4162 within the structure itself as separate fields.
4163
4164 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4165 I<length-item> describes how the length value is packed. Formats likely
4166 to be of most use are integer-packing ones like C<n> for Java strings,
4167 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4168
4169 For C<pack>, I<sequence-item> may have a repeat count, in which case
4170 the minimum of that and the number of available items is used as the argument
4171 for I<length-item>. If it has no repeat count or uses a '*', the number
4172 of available items is used.
4173
4174 For C<unpack>, an internal stack of integer arguments unpacked so far is
4175 used. You write C</>I<sequence-item> and the repeat count is obtained by
4176 popping off the last element from the stack. The I<sequence-item> must not
4177 have a repeat count.
4178
4179 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4180 the I<length-item> is the string length, not the number of strings.  With
4181 an explicit repeat count for pack, the packed string is adjusted to that
4182 length.  For example:
4183
4184     unpack("W/a", "\004Gurusamy")           gives ("Guru")
4185     unpack("a3/A A*", "007 Bond  J ")       gives (" Bond", "J")
4186     unpack("a3 x2 /A A*", "007: Bond, J.")  gives ("Bond, J", ".")
4187
4188     pack("n/a* w/a","hello,","world")       gives "\000\006hello,\005world"
4189     pack("a/W2", ord("a") .. ord("z"))      gives "2ab"
4190
4191 The I<length-item> is not returned explicitly from C<unpack>.
4192
4193 Supplying a count to the I<length-item> format letter is only useful with
4194 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
4195 introduce C<"\000"> characters, which Perl does not regard as legal in
4196 numeric strings.
4197
4198 =item *
4199
4200 The integer types C<s>, C<S>, C<l>, and C<L> may be
4201 followed by a C<!> modifier to specify native shorts or
4202 longs.  As shown in the example above, a bare C<l> means
4203 exactly 32 bits, although the native C<long> as seen by the local C compiler
4204 may be larger.  This is mainly an issue on 64-bit platforms.  You can
4205 see whether using C<!> makes any difference this way:
4206
4207     printf "format s is %d, s! is %d\n", 
4208         length pack("s"), length pack("s!");
4209
4210     printf "format l is %d, l! is %d\n", 
4211         length pack("l"), length pack("l!");
4212
4213
4214 C<i!> and C<I!> are also allowed, but only for completeness' sake:
4215 they are identical to C<i> and C<I>.
4216
4217 The actual sizes (in bytes) of native shorts, ints, longs, and long
4218 longs on the platform where Perl was built are also available from
4219 the command line:
4220
4221     $ perl -V:{short,int,long{,long}}size
4222     shortsize='2';
4223     intsize='4';
4224     longsize='4';
4225     longlongsize='8';
4226
4227 or programmatically via the C<Config> module:
4228
4229        use Config;
4230        print $Config{shortsize},    "\n";
4231        print $Config{intsize},      "\n";
4232        print $Config{longsize},     "\n";
4233        print $Config{longlongsize}, "\n";
4234
4235 C<$Config{longlongsize}> is undefined on systems without 
4236 long long support.
4237
4238 =item *
4239
4240 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
4241 inherently non-portable between processors and operating systems because
4242 they obey native byteorder and endianness.  For example, a 4-byte integer
4243 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
4244 handled by the CPU registers) into bytes as
4245
4246     0x12 0x34 0x56 0x78  # big-endian
4247     0x78 0x56 0x34 0x12  # little-endian
4248
4249 Basically, Intel and VAX CPUs are little-endian, while everybody else,
4250 including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are
4251 big-endian.  Alpha and MIPS can be either: Digital/Compaq uses (well, used) 
4252 them in little-endian mode, but SGI/Cray uses them in big-endian mode.
4253
4254 The names I<big-endian> and I<little-endian> are comic references to the
4255 egg-eating habits of the little-endian Lilliputians and the big-endian
4256 Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>.
4257 This entered computer lingo via the paper "On Holy Wars and a Plea for
4258 Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980.
4259
4260 Some systems may have even weirder byte orders such as
4261
4262    0x56 0x78 0x12 0x34
4263    0x34 0x12 0x78 0x56
4264
4265 You can determine your system endianness with this incantation:
4266
4267    printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); 
4268
4269 The byteorder on the platform where Perl was built is also available
4270 via L<Config>:
4271
4272     use Config;
4273     print "$Config{byteorder}\n";
4274
4275 or from the command line:
4276
4277     $ perl -V:byteorder
4278
4279 Byteorders C<"1234"> and C<"12345678"> are little-endian; C<"4321">
4280 and C<"87654321"> are big-endian.
4281
4282 For portably packed integers, either use the formats C<n>, C<N>, C<v>, 
4283 and C<V> or else use the C<< > >> and C<< < >> modifiers described
4284 immediately below.  See also L<perlport>.
4285
4286 =item *
4287
4288 Starting with Perl 5.9.2, integer and floating-point formats, along with
4289 the C<p> and C<P> formats and C<()> groups, may all be followed by the 
4290 C<< > >> or C<< < >> endianness modifiers to respectively enforce big-
4291 or little-endian byte-order.  These modifiers are especially useful 
4292 given how C<n>, C<N>, C<v>, and C<V> don't cover signed integers, 
4293 64-bit integers, or floating-point values.
4294
4295 Here are some concerns to keep in mind when using an endianness modifier:
4296
4297 =over
4298
4299 =item * 
4300
4301 Exchanging signed integers between different platforms works only 
4302 when all platforms store them in the same format.  Most platforms store
4303 signed integers in two's-complement notation, so usually this is not an issue.
4304
4305 =item * 
4306
4307 The C<< > >> or C<< < >> modifiers can only be used on floating-point
4308 formats on big- or little-endian machines.  Otherwise, attempting to
4309 use them raises an exception.
4310
4311 =item * 
4312
4313 Forcing big- or little-endian byte-order on floating-point values for
4314 data exchange can work only if all platforms use the same
4315 binary representation such as IEEE floating-point.  Even if all
4316 platforms are using IEEE, there may still be subtle differences.  Being able
4317 to use C<< > >> or C<< < >> on floating-point values can be useful,
4318 but also dangerous if you don't know exactly what you're doing.
4319 It is not a general way to portably store floating-point values.
4320
4321 =item * 
4322
4323 When using C<< > >> or C<< < >> on a C<()> group, this affects
4324 all types inside the group that accept byte-order modifiers,
4325 including all subgroups.  It is silently ignored for all other
4326 types.  You are not allowed to override the byte-order within a group
4327 that already has a byte-order modifier suffix.
4328
4329 =back
4330
4331 =item *
4332
4333 Real numbers (floats and doubles) are in native machine format only.
4334 Due to the multiplicity of floating-point formats and the lack of a
4335 standard "network" representation for them, no facility for interchange has been
4336 made.  This means that packed floating-point data written on one machine
4337 may not be readable on another, even if both use IEEE floating-point
4338 arithmetic (because the endianness of the memory representation is not part
4339 of the IEEE spec).  See also L<perlport>.
4340
4341 If you know I<exactly> what you're doing, you can use the C<< > >> or C<< < >>
4342 modifiers to force big- or little-endian byte-order on floating-point values.
4343
4344 Because Perl uses doubles (or long doubles, if configured) internally for
4345 all numeric calculation, converting from double into float and thence 
4346 to double again loses precision, so C<unpack("f", pack("f", $foo)>)
4347 will not in general equal $foo.
4348
4349 =item *
4350
4351 Pack and unpack can operate in two modes: character mode (C<C0> mode) where
4352 the packed string is processed per character, and UTF-8 mode (C<U0> mode)
4353 where the packed string is processed in its UTF-8-encoded Unicode form on
4354 a byte-by-byte basis. Character mode is the default unless the format string 
4355 starts with C<U>. You can always switch mode mid-format with an explicit 
4356 C<C0> or C<U0> in the format.  This mode remains in effect until the next 
4357 mode change, or until the end of the C<()> group it (directly) applies to.
4358
4359 Using C<C0> to get Unicode characters while using C<U0> to get I<non>-Unicode 
4360 bytes is not necessarily obvious.   Probably only the first of these
4361 is what you want:
4362
4363     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4364       perl -CS -ne 'printf "%v04X\n", $_ for unpack("C0A*", $_)'
4365     03B1.03C9
4366     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4367       perl -CS -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4368     CE.B1.CF.89
4369     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4370       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("C0A*", $_)'
4371     CE.B1.CF.89
4372     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4373       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4374     C3.8E.C2.B1.C3.8F.C2.89
4375
4376 Those examples also illustrate that you should not try to use
4377 C<pack>/C<unpack> as a substitute for the L<Encode> module.
4378
4379 =item *
4380
4381 You must yourself do any alignment or padding by inserting, for example,
4382 enough C<"x">es while packing.  There is no way for pack() and unpack()
4383 to know where characters are going to or coming from, so they 
4384 handle their output and input as flat sequences of characters.
4385
4386 =item *
4387
4388 A C<()> group is a sub-TEMPLATE enclosed in parentheses.  A group may
4389 take a repeat count either as postfix, or for unpack(), also via the C</>
4390 template character.  Within each repetition of a group, positioning with
4391 C<@> starts over at 0. Therefore, the result of
4392
4393     pack("@1A((@2A)@3A)", qw[X Y Z])
4394
4395 is the string C<"\0X\0\0YZ">.
4396
4397 =item *
4398
4399 C<x> and C<X> accept the C<!> modifier to act as alignment commands: they
4400 jump forward or back to the closest position aligned at a multiple of C<count>
4401 characters. For example, to pack() or unpack() a C structure like
4402
4403     struct {
4404         char   c;    /* one signed, 8-bit character */
4405         double d; 
4406         char   cc[2];
4407     }
4408
4409 one may need to use the template C<c x![d] d c[2]>.  This assumes that
4410 doubles must be aligned to the size of double.
4411
4412 For alignment commands, a C<count> of 0 is equivalent to a C<count> of 1;
4413 both are no-ops.
4414
4415 =item *
4416
4417 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier to
4418 represent signed 16-/32-bit integers in big-/little-endian order.
4419 This is portable only when all platforms sharing packed data use the
4420 same binary representation for signed integers; for example, when all
4421 platforms use two's-complement representation.
4422
4423 =item *
4424
4425 Comments can be embedded in a TEMPLATE using C<#> through the end of line.
4426 White space can separate pack codes from each other, but modifiers and
4427 repeat counts must follow immediately.  Breaking complex templates into
4428 individual line-by-line components, suitably annotated, can do as much to
4429 improve legibility and maintainability of pack/unpack formats as C</x> can
4430 for complicated pattern matches.
4431
4432 =item *
4433
4434 If TEMPLATE requires more arguments than pack() is given, pack()
4435 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4436 than given, extra arguments are ignored.
4437
4438 =back
4439
4440 Examples:
4441
4442     $foo = pack("WWWW",65,66,67,68);
4443     # foo eq "ABCD"
4444     $foo = pack("W4",65,66,67,68);
4445     # same thing
4446     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4447     # same thing with Unicode circled letters.
4448     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4449     # same thing with Unicode circled letters. You don't get the UTF-8
4450     # bytes because the U at the start of the format caused a switch to
4451     # U0-mode, so the UTF-8 bytes get joined into characters
4452     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4453     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4454     # This is the UTF-8 encoding of the string in the previous example
4455
4456     $foo = pack("ccxxcc",65,66,67,68);
4457     # foo eq "AB\0\0CD"
4458
4459     # NOTE: The examples above featuring "W" and "c" are true
4460     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4461     # and UTF-8.  On EBCDIC systems, the first example would be
4462     #      $foo = pack("WWWW",193,194,195,196);
4463
4464     $foo = pack("s2",1,2);
4465     # "\001\000\002\000" on little-endian
4466     # "\000\001\000\002" on big-endian
4467
4468     $foo = pack("a4","abcd","x","y","z");
4469     # "abcd"
4470
4471     $foo = pack("aaaa","abcd","x","y","z");
4472     # "axyz"
4473
4474     $foo = pack("a14","abcdefg");
4475     # "abcdefg\0\0\0\0\0\0\0"
4476
4477     $foo = pack("i9pl", gmtime);
4478     # a real struct tm (on my system anyway)
4479
4480     $utmp_template = "Z8 Z8 Z16 L";
4481     $utmp = pack($utmp_template, @utmp1);
4482     # a struct utmp (BSDish)
4483
4484     @utmp2 = unpack($utmp_template, $utmp);
4485     # "@utmp1" eq "@utmp2"
4486
4487     sub bintodec {
4488         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4489     }
4490
4491     $foo = pack('sx2l', 12, 34);
4492     # short 12, two zero bytes padding, long 34
4493     $bar = pack('s@4l', 12, 34);
4494     # short 12, zero fill to position 4, long 34
4495     # $foo eq $bar
4496     $baz = pack('s.l', 12, 4, 34);
4497     # short 12, zero fill to position 4, long 34
4498
4499     $foo = pack('nN', 42, 4711);
4500     # pack big-endian 16- and 32-bit unsigned integers
4501     $foo = pack('S>L>', 42, 4711);
4502     # exactly the same
4503     $foo = pack('s<l<', -42, 4711);
4504     # pack little-endian 16- and 32-bit signed integers
4505     $foo = pack('(sl)<', -42, 4711);
4506     # exactly the same
4507
4508 The same template may generally also be used in unpack().
4509
4510 =item package NAMESPACE
4511
4512 =item package NAMESPACE VERSION
4513 X<package> X<module> X<namespace> X<version>
4514
4515 =item package NAMESPACE BLOCK
4516
4517 =item package NAMESPACE VERSION BLOCK
4518 X<package> X<module> X<namespace> X<version>
4519
4520 Declares the BLOCK or the rest of the compilation unit as being in the
4521 given namespace.  The scope of the package declaration is either the
4522 supplied code BLOCK or, in the absence of a BLOCK, from the declaration
4523 itself through the end of current scope (the enclosing block, file, or
4524 C<eval>).  That is, the forms without a BLOCK are operative through the end
4525 of the current scope, just like the C<my>, C<state>, and C<our> operators.
4526 All unqualified dynamic identifiers in this scope will be in the given
4527 namespace, except where overridden by another C<package> declaration or
4528 when they're one of the special identifiers that qualify into C<main::>,
4529 like C<STDOUT>, C<ARGV>, C<ENV>, and the punctuation variables.
4530
4531 A package statement affects dynamic variables only, including those
4532 you've used C<local> on, but I<not> lexical variables, which are created
4533 with C<my>, C<state>, or C<our>.  Typically it would be the first 
4534 declaration in a file included by C<require> or C<use>.  You can switch into a
4535 package in more than one place, since this only determines which default 
4536 symbol table the compiler uses for the rest of that block.  You can refer to
4537 identifiers in other packages than the current one by prefixing the identifier
4538 with the package name and a double colon, as in C<$SomePack::var>
4539 or C<ThatPack::INPUT_HANDLE>.  If package name is omitted, the C<main>
4540 package as assumed.  That is, C<$::sail> is equivalent to
4541 C<$main::sail> (as well as to C<$main'sail>, still seen in ancient
4542 code, mostly from Perl 4).
4543
4544 If VERSION is provided, C<package> sets the C<$VERSION> variable in the given
4545 namespace to a L<version> object with the VERSION provided.  VERSION must be a
4546 "strict" style version number as defined by the L<version> module: a positive
4547 decimal number (integer or decimal-fraction) without exponentiation or else a
4548 dotted-decimal v-string with a leading 'v' character and at least three
4549 components.  You should set C<$VERSION> only once per package.
4550
4551 See L<perlmod/"Packages"> for more information about packages, modules,
4552 and classes.  See L<perlsub> for other scoping issues.
4553
4554 =item pipe READHANDLE,WRITEHANDLE
4555 X<pipe>
4556
4557 Opens a pair of connected pipes like the corresponding system call.
4558 Note that if you set up a loop of piped processes, deadlock can occur
4559 unless you are very careful.  In addition, note that Perl's pipes use
4560 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4561 after each command, depending on the application.
4562
4563 See L<IPC::Open2>, L<IPC::Open3>, and
4564 L<perlipc/"Bidirectional Communication with Another Process">
4565 for examples of such things.
4566
4567 On systems that support a close-on-exec flag on files, that flag is set
4568 on all newly opened file descriptors whose C<fileno>s are I<higher> than 
4569 the current value of $^F (by default 2 for C<STDERR>).  See L<perlvar/$^F>.
4570
4571 =item pop ARRAY
4572 X<pop> X<stack>
4573
4574 =item pop EXPR
4575
4576 =item pop
4577
4578 Pops and returns the last value of the array, shortening the array by
4579 one element.
4580
4581 Returns the undefined value if the array is empty, although this may also
4582 happen at other times.  If ARRAY is omitted, pops the C<@ARGV> array in the
4583 main program, but the C<@_> array in subroutines, just like C<shift>.
4584
4585 Starting with Perl 5.14, C<pop> can take a scalar EXPR, which must hold a
4586 reference to an unblessed array.  The argument will be dereferenced
4587 automatically.  This aspect of C<pop> is considered highly experimental.
4588 The exact behaviour may change in a future version of Perl.
4589
4590 =item pos SCALAR
4591 X<pos> X<match, position>
4592
4593 =item pos
4594
4595 Returns the offset of where the last C<m//g> search left off for the
4596 variable in question (C<$_> is used when the variable is not
4597 specified). Note that 0 is a valid match offset. C<undef> indicates
4598 that the search position is reset (usually due to match failure, but
4599 can also be because no match has yet been run on the scalar).
4600
4601 C<pos> directly accesses the location used by the regexp engine to
4602 store the offset, so assigning to C<pos> will change that offset, and
4603 so will also influence the C<\G> zero-width assertion in regular
4604 expressions. Both of these effects take place for the next match, so
4605 you can't affect the position with C<pos> during the current match,
4606 such as in C<(?{pos() = 5})> or C<s//pos() = 5/e>.
4607
4608 Setting C<pos> also resets the I<matched with zero-length> flag, described
4609 under L<perlre/"Repeated Patterns Matching a Zero-length Substring">.
4610
4611 Because a failed C<m//gc> match doesn't reset the offset, the return
4612 from C<pos> won't change either in this case.  See L<perlre> and
4613 L<perlop>.
4614
4615 =item print FILEHANDLE LIST
4616 X<print>
4617
4618 =item print FILEHANDLE
4619
4620 =item print LIST
4621
4622 =item print
4623
4624 Prints a string or a list of strings.  Returns true if successful.
4625 FILEHANDLE may be a scalar variable containing the name of or a reference
4626 to the filehandle, thus introducing one level of indirection.  (NOTE: If
4627 FILEHANDLE is a variable and the next token is a term, it may be
4628 misinterpreted as an operator unless you interpose a C<+> or put
4629 parentheses around the arguments.) If FILEHANDLE is omitted, prints to the
4630 last selected (see L</select>) output handle.  If LIST is omitted, prints
4631 C<$_> to the currently selected output handle.  To use FILEHANDLE alone to
4632 print the content of C<$_> to it, you must use a real filehandle like
4633 C<FH>, not an indirect one like C<$fh>.  To set the default output handle
4634 to something other than STDOUT, use the select operation.
4635
4636 The current value of C<$,> (if any) is printed between each LIST item.  The
4637 current value of C<$\> (if any) is printed after the entire LIST has been
4638 printed.  Because print takes a LIST, anything in the LIST is evaluated in
4639 list context, including any subroutines whose return lists you pass to
4640 C<print>.  Be careful not to follow the print keyword with a left
4641 parenthesis unless you want the corresponding right parenthesis to
4642 terminate the arguments to the print; put parentheses around all arguments
4643 (or interpose a C<+>, but that doesn't look as good).
4644
4645 If you're storing handles in an array or hash, or in general whenever
4646 you're using any expression more complex than a bareword handle or a plain,
4647 unsubscripted scalar variable to retrieve it, you will have to use a block
4648 returning the filehandle value instead, in which case the LIST may not be
4649 omitted:
4650
4651     print { $files[$i] } "stuff\n";
4652     print { $OK ? STDOUT : STDERR } "stuff\n";
4653
4654 Printing to a closed pipe or socket will generate a SIGPIPE signal.  See
4655 L<perlipc> for more on signal handling.
4656
4657 =item printf FILEHANDLE FORMAT, LIST
4658 X<printf>
4659
4660 =item printf FILEHANDLE
4661
4662 =item printf FORMAT, LIST
4663
4664 =item printf
4665
4666 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4667 (the output record separator) is not appended.  The first argument of the
4668 list will be interpreted as the C<printf> format. See