This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
regexp_unicode_prop.t: Add tests.
[perl5.git] / t / re / regexp_unicode_prop.t
1 #!./perl
2 #
3 # Tests that have to do with checking whether characters have (or not have)
4 # certain Unicode properties; belong (or not belong) to blocks, scripts, etc.
5 #
6
7 use strict;
8 use warnings;
9 use 5.010;
10
11 BEGIN {
12     require './test.pl';
13     skip_all_if_miniperl("no dynamic loading on miniperl, no File::Spec (used by charnames)");
14 }
15
16 sub run_tests;
17
18 #
19 # This is the data to test.
20 #
21 # This is a hash; keys are the property to test.
22 # Values are arrays containing characters to test. The characters can
23 # have the following formats:
24 #   '\N{CHARACTER NAME}'  -  Use character with that name
25 #   '\x{1234}'            -  Use character with that hex escape
26 #   '0x1234'              -  Use chr() to get that character
27 #   "a"                   -  Character to use
28 #
29 # If a character entry starts with ! the character does not belong to the class
30 #
31 # If the class is just single letter, we use both \pL and \p{L}
32 #
33
34 use charnames ':full';
35
36 my @CLASSES = (
37     L                         => ["a", "A"],
38     Ll                        => ["b", "!B"],
39     Lu                        => ["!c", "C"],
40     IsLl                      => ["d", "!D"],
41     IsLu                      => ["!e", "E"],
42     LC                        => ["f", "!1"],
43    'L&'                       => ["g", "!2"],
44    'Lowercase Letter'         => ["h", "!H"],
45
46     Common                    => ["!i", "3"],
47     Inherited                 => ["!j", '\x{300}'],
48
49     InBasicLatin              => ['\N{LATIN CAPITAL LETTER A}'],
50     InLatin1Supplement        => ['\N{LATIN CAPITAL LETTER A WITH GRAVE}'],
51     InLatinExtendedA          => ['\N{LATIN CAPITAL LETTER A WITH MACRON}'],
52     InLatinExtendedB          => ['\N{LATIN SMALL LETTER B WITH STROKE}'],
53     InKatakana                => ['\N{KATAKANA LETTER SMALL A}'],
54     IsLatin                   => ["0x100", "0x212b"],
55     IsHebrew                  => ["0x5d0", "0xfb4f"],
56     IsGreek                   => ["0x37a", "0x386", "!0x387", "0x388",
57                                   "0x38a", "!0x38b", "0x38c"],
58     HangulSyllables           => ['\x{AC00}'],
59    'Script=Latin'             => ['\x{0100}'],
60    'Block=LatinExtendedA'     => ['\x{0100}'],
61    'Category=UppercaseLetter' => ['\x{0100}'],
62
63     #
64     # It's ok to repeat class names.
65     #
66     InLatin1Supplement        =>
67                $::IS_EBCDIC ? ['!\x{7f}',  '\x{80}',            '!\x{100}']
68                             : ['!\x{7f}',  '\x{80}',  '\x{ff}', '!\x{100}'],
69     InLatinExtendedA          =>
70                             ['!\x{7f}', '!\x{80}', '!\x{ff}',  '\x{100}'],
71
72     #
73     # Properties are case-insensitive, and may have whitespace,
74     # dashes and underscores.
75     #
76    'in-latin1_SUPPLEMENT'     => ['\x{80}', 
77                                   '\N{LATIN SMALL LETTER Y WITH DIAERESIS}'],
78    '  ^  In Latin 1 Supplement  '
79                               => ['!\x{80}', '\N{COFFIN}'],
80    'latin-1   supplement'     => ['\x{80}', "0xDF"],
81
82 );
83
84 my @USER_DEFINED_PROPERTIES = (
85    #
86    # User defined properties
87    #
88    InKana1                   => ['\x{3040}', '!\x{303F}'],
89    InKana2                   => ['\x{3040}', '!\x{303F}'],
90    InKana3                   => ['\x{3041}', '!\x{3040}'],
91    InNotKana                 => ['\x{3040}', '!\x{3041}'],
92    InConsonant               => ['d',        '!e'],
93    IsSyriac1                 => ['\x{0712}', '!\x{072F}'],
94    IsSyriac1KanaMark         => ['\x{309A}', '!\x{3090}'],
95    IsSyriac1KanaMark         => ['\x{0730}', '!\x{0712}'],
96    '# User-defined character properties may lack \n at the end',
97    InGreekSmall              => ['\N{GREEK SMALL LETTER PI}',
98                                  '\N{GREEK SMALL LETTER FINAL SIGMA}'],
99    InGreekCapital            => ['\N{GREEK CAPITAL LETTER PI}', '!\x{03A2}'],
100    Dash                      => ['-'],
101    ASCII_Hex_Digit           => ['!-', 'A'],
102    IsAsciiHexAndDash         => ['-', 'A'],
103 );
104
105 my @USER_CASELESS_PROPERTIES = (
106    #
107    # User defined properties which differ depending on /i.  Second entry is
108    # false regularly, true under /i
109    #
110    'IsMyUpper'                => ["M", "!m" ],
111 );
112
113
114 #
115 # From the short properties we populate POSIX-like classes.
116 #
117 my %SHORT_PROPERTIES = (
118     'Ll'  => ['m', '\N{CYRILLIC SMALL LETTER A}'],
119     'Lu'  => ['M', '\N{GREEK CAPITAL LETTER ALPHA}'],
120     'Lo'  => ['\N{HIRAGANA LETTER SMALL A}'],
121     # is also in other alphabetic
122     'Mn'  => ['\N{HEBREW POINT RAFE}'],
123     'Nd'  => ["0", '\N{ARABIC-INDIC DIGIT ZERO}'],
124     'Pc'  => ["_"],
125     'Po'  => ["!"],
126     'Zs'  => [" "],
127     'Cc'  => ['\x{00}'],
128 );
129
130 #
131 # Illegal properties
132 #
133 my @ILLEGAL_PROPERTIES =
134     qw[q qrst f foo isfoo infoo ISfoo INfoo Is::foo In::foo];
135
136 my %d;
137
138 while (my ($class, $chars) = each %SHORT_PROPERTIES) {
139     push @{$d {IsAlpha}} => map {$class =~ /^[LM]/   ? $_ : "!$_"} @$chars;
140     push @{$d {IsAlnum}} => map {$class =~ /^[LMN]./ ? $_ : "!$_"} @$chars;
141     push @{$d {IsASCII}} => map {length ($_) == 1 || $_ eq '\x{00}'
142                                                      ? $_ : "!$_"} @$chars;
143     push @{$d {IsCntrl}} => map {$class =~ /^C/      ? $_ : "!$_"} @$chars;
144     push @{$d {IsBlank}} => map {$class =~ /^Z[lps]/ ? $_ : "!$_"} @$chars;
145     push @{$d {IsDigit}} => map {$class =~ /^Nd$/    ? $_ : "!$_"} @$chars;
146     push @{$d {IsGraph}} => map {$class =~ /^([LMNPS]|Co)/
147                                                      ? $_ : "!$_"} @$chars;
148     push @{$d {IsPrint}} => map {$class =~ /^([LMNPS]|Co|Zs)/
149                                                      ? $_ : "!$_"} @$chars;
150     push @{$d {IsLower}} => map {$class =~ /^Ll$/    ? $_ : "!$_"} @$chars;
151     push @{$d {IsUpper}} => map {$class =~ /^L[ut]/  ? $_ : "!$_"} @$chars;
152     push @{$d {IsPunct}} => map {$class =~ /^P/      ? $_ : "!$_"} @$chars;
153     push @{$d {IsWord}}  => map {$class =~ /^[LMN]/ || $_ eq "_"
154                                                      ? $_ : "!$_"} @$chars;
155     push @{$d {IsSpace}} => map {$class =~ /^Z/ ||
156                                  length ($_) == 1 && ord ($_) >= 0x09
157                                                   && ord ($_) <= 0x0D
158                                                      ? $_ : "!$_"} @$chars;
159 }
160
161 delete $d {IsASCII} if $::IS_EBCDIC;
162
163 push @CLASSES => "# Short properties"        => %SHORT_PROPERTIES,
164                  "# POSIX like properties"   => %d,
165                  "# User defined properties" => @USER_DEFINED_PROPERTIES;
166
167
168 #
169 # Calculate the number of tests.
170 #
171 my $count = 0;
172 for (my $i = 0; $i < @CLASSES; $i += 2) {
173     $i ++, redo if $CLASSES [$i] =~ /^\h*#\h*(.*)/;
174     $count += 2 * (length $CLASSES [$i] == 1 ? 4 : 2) * @{$CLASSES [$i + 1]};
175 }
176 $count += 4 * @ILLEGAL_PROPERTIES;
177 $count += 4 * grep {length $_ == 1} @ILLEGAL_PROPERTIES;
178 $count += 8 * @USER_CASELESS_PROPERTIES;
179
180 plan(tests => $count);
181
182 run_tests unless caller ();
183
184 sub match {
185     my ($char, $match, $nomatch, $caseless) = @_;
186     $caseless = "" unless defined $caseless;
187     $caseless = 'i' if $caseless;
188
189     my ($str, $name);
190
191     given ($char) {
192         when (/^\\/) {
193             $str  = eval qq ["$char"];
194             $name =      qq ["$char"];
195         }
196         when (/^0x([0-9A-Fa-f]+)$/) {
197             $str  =  chr hex $1;
198             $name = "chr ($char)";
199         }
200         default {
201             $str  =      $char;
202             $name = qq ["$char"];
203         }
204     }
205
206     undef $@;
207     my $pat = "qr/$match/$caseless";
208     my $match_pat = eval $pat;
209     is($@, '', "$pat compiled correctly to a regexp: $@");
210     like($str, $match_pat, "$name correctly matched");
211
212     undef $@;
213     $pat = "qr/$nomatch/$caseless";
214     my $nomatch_pat = eval $pat;
215     is($@, '', "$pat compiled correctly to a regexp: $@");
216     unlike($str, $nomatch_pat, "$name correctly did not match");
217 }
218
219 sub run_tests {
220
221     while (@CLASSES) {
222         my $class = shift @CLASSES;
223         if ($class =~ /^\h*#\h*(.*)/) {
224             print "# $1\n";
225             next;
226         }
227         last unless @CLASSES;
228         my $chars   = shift @CLASSES;
229         my @in      =                       grep {!/^!./} @$chars;
230         my @out     = map {s/^!(?=.)//; $_} grep { /^!./} @$chars;
231         my $in_pat  = eval qq ['\\p{$class}'];
232         my $out_pat = eval qq ['\\P{$class}'];
233
234         match $_, $in_pat,  $out_pat for @in;
235         match $_, $out_pat, $in_pat  for @out;
236
237         if (1 == length $class) {   # Repeat without braces if name length 1
238             my $in_pat  = eval qq ['\\p$class'];
239             my $out_pat = eval qq ['\\P$class'];
240
241             match $_, $in_pat,  $out_pat for @in;
242             match $_, $out_pat, $in_pat  for @out;
243         }
244     }
245
246
247     my $pat = qr /^Can't find Unicode property definition/;
248     print "# Illegal properties\n";
249     foreach my $p (@ILLEGAL_PROPERTIES) {
250         undef $@;
251         my $r = eval "'a' =~ /\\p{$p}/; 1";
252         is($r, undef, "Unknown Unicode property \\p{$p}");
253         like($@, $pat, "Unknown Unicode property \\p{$p}");
254         undef $@;
255         my $s = eval "'a' =~ /\\P{$p}/; 1";
256         is($s, undef, "Unknown Unicode property \\p{$p}");
257         like($@, $pat, "Unknown Unicode property \\p{$p}");
258         if (length $p == 1) {
259             undef $@;
260             my $r = eval "'a' =~ /\\p$p/; 1";
261             is($r, undef, "Unknown Unicode property \\p$p");
262             like($@, $pat, "Unknown Unicode property \\p$p");
263             undef $@;
264             my $s = eval "'a' =~ /\\P$p/; 1";
265             is($r, undef, "Unknown Unicode property \\P$p");
266             like($@, $pat, "Unknown Unicode property \\P$p");
267         }
268     }
269
270     print "# User-defined properties with /i differences\n";
271     foreach my $class (shift @USER_CASELESS_PROPERTIES) {
272         my $chars_ref = shift @USER_CASELESS_PROPERTIES;
273         my @in      =                       grep {!/^!./} @$chars_ref;
274         my @out     = map {s/^!(?=.)//; $_} grep { /^!./} @$chars_ref;
275         my $in_pat  = eval qq ['\\p{$class}'];
276         my $out_pat = eval qq ['\\P{$class}'];
277
278         # Verify works as regularly for not /i
279         match $_, $in_pat,  $out_pat for @in;
280         match $_, $out_pat, $in_pat  for @out;
281
282         # Verify that adding /i doesn't change the in set.
283         match $_, $in_pat,  $out_pat, 'i' for @in;
284
285         # Verify that adding /i does change the out set to match.
286         match $_, $in_pat,  $out_pat, 'i' for @out;
287     }
288 }
289
290
291 #
292 # User defined properties
293 #
294
295 sub InKana1 {<<'--'}
296 3040    309F
297 30A0    30FF
298 --
299
300 sub InKana2 {<<'--'}
301 +utf8::InHiragana
302 +utf8::InKatakana
303 --
304
305 sub InKana3 {<<'--'}
306 +utf8::InHiragana
307 +utf8::InKatakana
308 -utf8::IsCn
309 --
310
311 sub InNotKana {<<'--'}
312 !utf8::InHiragana
313 -utf8::InKatakana
314 +utf8::IsCn
315 --
316
317 sub InConsonant {<<'--'}   # Not EBCDIC-aware.
318 0061 007f
319 -0061
320 -0065
321 -0069
322 -006f
323 -0075
324 --
325
326 sub IsSyriac1 {<<'--'}
327 0712    072C
328 0730    074A
329 --
330
331 sub InGreekSmall   {return "03B1\t03C9"}
332 sub InGreekCapital {return "0391\t03A9\n-03A2"}
333
334 sub IsAsciiHexAndDash {<<'--'}
335 +utf8::ASCII_Hex_Digit
336 +utf8::Dash
337 --
338
339 sub IsMyUpper {
340     my $caseless = shift;
341     if ($caseless) {
342         return "0041\t005A\n0061\t007A"
343     }
344     else {
345         return "0041\t005A"
346     }
347 }
348
349 # Verify that can use user-defined properties inside another one
350 sub IsSyriac1KanaMark {<<'--'}
351 +main::IsSyriac1
352 +main::InKana3
353 &utf8::IsMark
354 --
355
356 # fake user-defined properties; these subs shouldn't be called, because
357 # their names don't start with In or Is
358
359 sub f       { die }
360 sub foo     { die }
361 sub isfoo   { die }
362 sub infoo   { die }
363 sub ISfoo   { die }
364 sub INfoo   { die }
365 sub Is::foo { die }
366 sub In::foo { die }
367 __END__