This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
like and unlike weren't reporting failure where correctly in test.pl
[perl5.git] / t / test.pl
1 #
2 # t/test.pl - most of Test::More functionality without the fuss
3 #
4
5 $Level = 1;
6 my $test = 1;
7 my $planned;
8 my $noplan;
9
10 $TODO = 0;
11 $NO_ENDING = 0;
12
13 sub plan {
14     my $n;
15     if (@_ == 1) {
16         $n = shift;
17         if ($n eq 'no_plan') {
18           undef $n;
19           $noplan = 1;
20         }
21     } else {
22         my %plan = @_;
23         $n = $plan{tests}; 
24     }
25     print STDOUT "1..$n\n" unless $noplan;
26     $planned = $n;
27 }
28
29 END {
30     my $ran = $test - 1;
31     if (!$NO_ENDING) {
32         if (defined $planned && $planned != $ran) {
33             print STDERR
34                 "# Looks like you planned $planned tests but ran $ran.\n";
35         } elsif ($noplan) {
36             print "1..$ran\n";
37         }
38     }
39 }
40
41 # Use this instead of "print STDERR" when outputing failure diagnostic 
42 # messages
43 sub _diag {
44     return unless @_;
45     my @mess = map { /^#/ ? "$_\n" : "# $_\n" } 
46                map { split /\n/ } @_;
47     my $fh = $TODO ? *STDOUT : *STDERR;
48     print $fh @mess;
49
50 }
51
52 sub skip_all {
53     if (@_) {
54         print STDOUT "1..0 # Skipped: @_\n";
55     } else {
56         print STDOUT "1..0\n";
57     }
58     exit(0);
59 }
60
61 sub _ok {
62     my ($pass, $where, $name, @mess) = @_;
63     # Do not try to microoptimize by factoring out the "not ".
64     # VMS will avenge.
65     my $out;
66     if ($name) {
67         # escape out '#' or it will interfere with '# skip' and such
68         $name =~ s/#/\\#/g;
69         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
70     } else {
71         $out = $pass ? "ok $test" : "not ok $test";
72     }
73
74     $out .= " # TODO $TODO" if $TODO;
75     print STDOUT "$out\n";
76
77     unless ($pass) {
78         _diag "# Failed $where\n";
79     }
80
81     # Ensure that the message is properly escaped.
82     _diag @mess;
83
84     $test++;
85
86     return $pass;
87 }
88
89 sub _where {
90     my @caller = caller($Level);
91     return "at $caller[1] line $caller[2]";
92 }
93
94 # DON'T use this for matches. Use like() instead.
95 sub ok ($@) {
96     my ($pass, $name, @mess) = @_;
97     _ok($pass, _where(), $name, @mess);
98 }
99
100 sub _q {
101     my $x = shift;
102     return 'undef' unless defined $x;
103     my $q = $x;
104     $q =~ s/\\/\\\\/g;
105     $q =~ s/'/\\'/g;
106     return "'$q'";
107 }
108
109 sub _qq {
110     my $x = shift;
111     return defined $x ? '"' . display ($x) . '"' : 'undef';
112 };
113
114 # keys are the codes \n etc map to, values are 2 char strings such as \n
115 my %backslash_escape;
116 foreach my $x (split //, 'nrtfa\\\'"') {
117     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
118 }
119 # A way to display scalars containing control characters and Unicode.
120 # Trying to avoid setting $_, or relying on local $_ to work.
121 sub display {
122     my @result;
123     foreach my $x (@_) {
124         if (defined $x and not ref $x) {
125             my $y = '';
126             foreach my $c (unpack("U*", $x)) {
127                 if ($c > 255) {
128                     $y .= sprintf "\\x{%x}", $c;
129                 } elsif ($backslash_escape{$c}) {
130                     $y .= $backslash_escape{$c};
131                 } else {
132                     my $z = chr $c; # Maybe we can get away with a literal...
133                     $z = sprintf "\\%03o", $c if $z =~ /[[:^print:]]/;
134                     $y .= $z;
135                 }
136             }
137             $x = $y;
138         }
139         return $x unless wantarray;
140         push @result, $x;
141     }
142     return @result;
143 }
144
145 sub is ($$@) {
146     my ($got, $expected, $name, @mess) = @_;
147
148     my $pass;
149     if( !defined $got || !defined $expected ) {
150         # undef only matches undef
151         $pass = !defined $got && !defined $expected;
152     }
153     else {
154         $pass = $got eq $expected;
155     }
156
157     unless ($pass) {
158         unshift(@mess, "#      got "._q($got)."\n",
159                        "# expected "._q($expected)."\n");
160     }
161     _ok($pass, _where(), $name, @mess);
162 }
163
164 sub isnt ($$@) {
165     my ($got, $isnt, $name, @mess) = @_;
166
167     my $pass;
168     if( !defined $got || !defined $isnt ) {
169         # undef only matches undef
170         $pass = defined $got || defined $isnt;
171     }
172     else {
173         $pass = $got ne $isnt;
174     }
175
176     unless( $pass ) {
177         unshift(@mess, "# it should not be "._q($got)."\n",
178                        "# but it is.\n");
179     }
180     _ok($pass, _where(), $name, @mess);
181 }
182
183 sub cmp_ok ($$$@) {
184     my($got, $type, $expected, $name, @mess) = @_;
185
186     my $pass;
187     {
188         local $^W = 0;
189         local($@,$!);   # don't interfere with $@
190                         # eval() sometimes resets $!
191         $pass = eval "\$got $type \$expected";
192     }
193     unless ($pass) {
194         # It seems Irix long doubles can have 2147483648 and 2147483648
195         # that stringify to the same thing but are acutally numerically
196         # different. Display the numbers if $type isn't a string operator,
197         # and the numbers are stringwise the same.
198         # (all string operators have alphabetic names, so tr/a-z// is true)
199         # This will also show numbers for some uneeded cases, but will
200         # definately be helpful for things such as == and <= that fail
201         if ($got eq $expected and $type !~ tr/a-z//) {
202             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
203         }
204         unshift(@mess, "#      got "._q($got)."\n",
205                        "# expected $type "._q($expected)."\n");
206     }
207     _ok($pass, _where(), $name, @mess);
208 }
209
210 # Check that $got is within $range of $expected
211 # if $range is 0, then check it's exact
212 # else if $expected is 0, then $range is an absolute value
213 # otherwise $range is a fractional error.
214 # Here $range must be numeric, >= 0
215 # Non numeric ranges might be a useful future extension. (eg %)
216 sub within ($$$@) {
217     my ($got, $expected, $range, $name, @mess) = @_;
218     my $pass;
219     if (!defined $got or !defined $expected or !defined $range) {
220         # This is a fail, but doesn't need extra diagnostics
221     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
222         # This is a fail
223         unshift @mess, "# got, expected and range must be numeric\n";
224     } elsif ($range < 0) {
225         # This is also a fail
226         unshift @mess, "# range must not be negative\n";
227     } elsif ($range == 0) {
228         # Within 0 is ==
229         $pass = $got == $expected;
230     } elsif ($expected == 0) {
231         # If expected is 0, treat range as absolute
232         $pass = ($got <= $range) && ($got >= - $range);
233     } else {
234         my $diff = $got - $expected;
235         $pass = abs ($diff / $expected) < $range;
236     }
237     unless ($pass) {
238         if ($got eq $expected) {
239             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
240         }
241         unshift@mess, "#      got "._q($got)."\n",
242                       "# expected "._q($expected)." (within "._q($range).")\n";
243     }
244     _ok($pass, _where(), $name, @mess);
245 }
246
247 # Note: this isn't quite as fancy as Test::More::like().
248
249 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
250 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
251
252 sub like_yn ($$$@) {
253     my ($flip, $got, $expected, $name, @mess) = @_;
254     my $pass;
255     $pass = $got =~ /$expected/ if !$flip;
256     $pass = $got !~ /$expected/ if $flip;
257     unless ($pass) {
258         unshift(@mess, "#      got '$got'\n",
259                 "# expected /$expected/\n");
260     }
261     local $Level = 2;
262     _ok($pass, _where(), $name, @mess);
263 }
264
265 sub pass {
266     _ok(1, '', @_);
267 }
268
269 sub fail {
270     _ok(0, _where(), @_);
271 }
272
273 sub curr_test {
274     $test = shift if @_;
275     return $test;
276 }
277
278 sub next_test {
279   $test++;
280 }
281
282 # Note: can't pass multipart messages since we try to
283 # be compatible with Test::More::skip().
284 sub skip {
285     my $why = shift;
286     my $n    = @_ ? shift : 1;
287     for (1..$n) {
288         print STDOUT "ok $test # skip: $why\n";
289         $test++;
290     }
291     local $^W = 0;
292     last SKIP;
293 }
294
295 sub todo_skip {
296     my $why = shift;
297     my $n   = @_ ? shift : 1;
298
299     for (1..$n) {
300         print STDOUT "not ok $test # TODO & SKIP: $why\n";
301         $test++;
302     }
303     local $^W = 0;
304     last TODO;
305 }
306
307 sub eq_array {
308     my ($ra, $rb) = @_;
309     return 0 unless $#$ra == $#$rb;
310     for my $i (0..$#$ra) {
311         next     if !defined $ra->[$i] && !defined $rb->[$i]; 
312         return 0 if !defined $ra->[$i];
313         return 0 if !defined $rb->[$i];
314         return 0 unless $ra->[$i] eq $rb->[$i];
315     }
316     return 1;
317 }
318
319 sub eq_hash {
320   my ($orig, $suspect) = @_;
321   my $fail;
322   while (my ($key, $value) = each %$suspect) {
323     # Force a hash recompute if this perl's internals can cache the hash key.
324     $key = "" . $key;
325     if (exists $orig->{$key}) {
326       if ($orig->{$key} ne $value) {
327         print STDOUT "# key ", _qq($key), " was ", _qq($orig->{$key}),
328                      " now ", _qq($value), "\n";
329         $fail = 1;
330       }
331     } else {
332       print STDOUT "# key ", _qq($key), " is ", _qq($value), 
333                    ", not in original.\n";
334       $fail = 1;
335     }
336   }
337   foreach (keys %$orig) {
338     # Force a hash recompute if this perl's internals can cache the hash key.
339     $_ = "" . $_;
340     next if (exists $suspect->{$_});
341     print STDOUT "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
342     $fail = 1;
343   }
344   !$fail;
345 }
346
347 sub require_ok ($) {
348     my ($require) = @_;
349     eval <<REQUIRE_OK;
350 require $require;
351 REQUIRE_OK
352     _ok(!$@, _where(), "require $require");
353 }
354
355 sub use_ok ($) {
356     my ($use) = @_;
357     eval <<USE_OK;
358 use $use;
359 USE_OK
360     _ok(!$@, _where(), "use $use");
361 }
362
363 # runperl - Runs a separate perl interpreter.
364 # Arguments :
365 #   switches => [ command-line switches ]
366 #   nolib    => 1 # don't use -I../lib (included by default)
367 #   prog     => one-liner (avoid quotes)
368 #   progs    => [ multi-liner (avoid quotes) ]
369 #   progfile => perl script
370 #   stdin    => string to feed the stdin
371 #   stderr   => redirect stderr to stdout
372 #   args     => [ command-line arguments to the perl program ]
373 #   verbose  => print the command line
374
375 my $is_mswin    = $^O eq 'MSWin32';
376 my $is_netware  = $^O eq 'NetWare';
377 my $is_macos    = $^O eq 'MacOS';
378 my $is_vms      = $^O eq 'VMS';
379
380 sub _quote_args {
381     my ($runperl, $args) = @_;
382
383     foreach (@$args) {
384         # In VMS protect with doublequotes because otherwise
385         # DCL will lowercase -- unless already doublequoted.
386        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
387         $$runperl .= ' ' . $_;
388     }
389 }
390
391 sub _create_runperl { # Create the string to qx in runperl().
392     my %args = @_;
393     my $runperl = $^X =~ m/\s/ ? qq{"$^X"} : $^X;
394     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
395     if ($ENV{PERL_RUNPERL_DEBUG}) {
396         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
397     }
398     unless ($args{nolib}) {
399         if ($is_macos) {
400             $runperl .= ' -I::lib';
401             # Use UNIX style error messages instead of MPW style.
402             $runperl .= ' -MMac::err=unix' if $args{stderr};
403         }
404         else {
405             $runperl .= ' "-I../lib"'; # doublequotes because of VMS
406         }
407     }
408     if ($args{switches}) {
409         local $Level = 2;
410         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
411             unless ref $args{switches} eq "ARRAY";
412         _quote_args(\$runperl, $args{switches});
413     }
414     if (defined $args{prog}) {
415         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
416             if defined $args{progs};
417         $args{progs} = [$args{prog}]
418     }
419     if (defined $args{progs}) {
420         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
421             unless ref $args{progs} eq "ARRAY";
422         foreach my $prog (@{$args{progs}}) {
423             if ($is_mswin || $is_netware || $is_vms) {
424                 $runperl .= qq ( -e "$prog" );
425             }
426             else {
427                 $runperl .= qq ( -e '$prog' );
428             }
429         }
430     } elsif (defined $args{progfile}) {
431         $runperl .= qq( "$args{progfile}");
432     } else {
433         # You probaby didn't want to be sucking in from the upstream stdin
434         die "test.pl:runperl(): none of prog, progs, progfile, args, "
435             . " switches or stdin specified"
436             unless defined $args{args} or defined $args{switches}
437                 or defined $args{stdin};
438     }
439     if (defined $args{stdin}) {
440         # so we don't try to put literal newlines and crs onto the
441         # command line.
442         $args{stdin} =~ s/\n/\\n/g;
443         $args{stdin} =~ s/\r/\\r/g;
444
445         if ($is_mswin || $is_netware || $is_vms) {
446             $runperl = qq{$^X -e "print qq(} .
447                 $args{stdin} . q{)" | } . $runperl;
448         }
449         elsif ($is_macos) {
450             # MacOS can only do two processes under MPW at once;
451             # the test itself is one; we can't do two more, so
452             # write to temp file
453             my $stdin = qq{$^X -e 'print qq(} . $args{stdin} . qq{)' > teststdin; };
454             if ($args{verbose}) {
455                 my $stdindisplay = $stdin;
456                 $stdindisplay =~ s/\n/\n\#/g;
457                 print STDERR "# $stdindisplay\n";
458             }
459             `$stdin`;
460             $runperl .= q{ < teststdin };
461         }
462         else {
463             $runperl = qq{$^X -e 'print qq(} .
464                 $args{stdin} . q{)' | } . $runperl;
465         }
466     }
467     if (defined $args{args}) {
468         _quote_args(\$runperl, $args{args});
469     }
470     $runperl .= ' 2>&1'          if  $args{stderr} && !$is_macos;
471     $runperl .= " \xB3 Dev:Null" if !$args{stderr} &&  $is_macos;
472     if ($args{verbose}) {
473         my $runperldisplay = $runperl;
474         $runperldisplay =~ s/\n/\n\#/g;
475         print STDERR "# $runperldisplay\n";
476     }
477     return $runperl;
478 }
479
480 sub runperl {
481     die "test.pl:runperl() does not take a hashref"
482         if ref $_[0] and ref $_[0] eq 'HASH';
483     my $runperl = &_create_runperl;
484     my $result = `$runperl`;
485     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
486     return $result;
487 }
488
489 *run_perl = \&runperl; # Nice alias.
490
491 sub DIE {
492     print STDERR "# @_\n";
493     exit 1;
494 }
495
496 # A somewhat safer version of the sometimes wrong $^X.
497 my $Perl;
498 sub which_perl {
499     unless (defined $Perl) {
500         $Perl = $^X;
501         
502         # VMS should have 'perl' aliased properly
503         return $Perl if $^O eq 'VMS';
504
505         my $exe;
506         eval "require Config; Config->import";
507         if ($@) {
508             warn "test.pl had problems loading Config: $@";
509             $exe = '';
510         } else {
511             $exe = $Config{_exe};
512         }
513        $exe = '' unless defined $exe;
514         
515         # This doesn't absolutize the path: beware of future chdirs().
516         # We could do File::Spec->abs2rel() but that does getcwd()s,
517         # which is a bit heavyweight to do here.
518         
519         if ($Perl =~ /^perl\Q$exe\E$/i) {
520             my $perl = "perl$exe";
521             eval "require File::Spec";
522             if ($@) {
523                 warn "test.pl had problems loading File::Spec: $@";
524                 $Perl = "./$perl";
525             } else {
526                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
527             }
528         }
529
530         # Build up the name of the executable file from the name of
531         # the command.
532
533         if ($Perl !~ /\Q$exe\E$/i) {
534             $Perl .= $exe;
535         }
536
537         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
538         
539         # For subcommands to use.
540         $ENV{PERLEXE} = $Perl;
541     }
542     return $Perl;
543 }
544
545 sub unlink_all {
546     foreach my $file (@_) {
547         1 while unlink $file;
548         print STDERR "# Couldn't unlink '$file': $!\n" if -f $file;
549     }
550 }
551
552
553 my $tmpfile = "misctmp000";
554 1 while -f ++$tmpfile;
555 END { unlink_all $tmpfile }
556
557 #
558 # _fresh_perl
559 #
560 # The $resolve must be a subref that tests the first argument
561 # for success, or returns the definition of success (e.g. the
562 # expected scalar) if given no arguments.
563 #
564
565 sub _fresh_perl {
566     my($prog, $resolve, $runperl_args, $name) = @_;
567
568     $runperl_args ||= {};
569     $runperl_args->{progfile} = $tmpfile;
570     $runperl_args->{stderr} = 1;
571
572     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
573
574     # VMS adjustments
575     if( $^O eq 'VMS' ) {
576         $prog =~ s#/dev/null#NL:#;
577
578         # VMS file locking 
579         $prog =~ s{if \(-e _ and -f _ and -r _\)}
580                   {if (-e _ and -f _)}
581     }
582
583     print TEST $prog;
584     close TEST or die "Cannot close $tmpfile: $!";
585
586     my $results = runperl(%$runperl_args);
587     my $status = $?;
588
589     # Clean up the results into something a bit more predictable.
590     $results =~ s/\n+$//;
591     $results =~ s/at\s+misctmp\d+\s+line/at - line/g;
592     $results =~ s/of\s+misctmp\d+\s+aborted/of - aborted/g;
593
594     # bison says 'parse error' instead of 'syntax error',
595     # various yaccs may or may not capitalize 'syntax'.
596     $results =~ s/^(syntax|parse) error/syntax error/mig;
597
598     if ($^O eq 'VMS') {
599         # some tests will trigger VMS messages that won't be expected
600         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
601
602         # pipes double these sometimes
603         $results =~ s/\n\n/\n/g;
604     }
605
606     my $pass = $resolve->($results);
607     unless ($pass) {
608         _diag "# PROG: \n$prog\n";
609         _diag "# EXPECTED:\n", $resolve->(), "\n";
610         _diag "# GOT:\n$results\n";
611         _diag "# STATUS: $status\n";
612     }
613
614     # Use the first line of the program as a name if none was given
615     unless( $name ) {
616         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
617         $name .= '...' if length $first_line > length $name;
618     }
619
620     _ok($pass, _where(), "fresh_perl - $name");
621 }
622
623 #
624 # fresh_perl_is
625 #
626 # Combination of run_perl() and is().
627 #
628
629 sub fresh_perl_is {
630     my($prog, $expected, $runperl_args, $name) = @_;
631     local $Level = 2;
632     _fresh_perl($prog,
633                 sub { @_ ? $_[0] eq $expected : $expected },
634                 $runperl_args, $name);
635 }
636
637 #
638 # fresh_perl_like
639 #
640 # Combination of run_perl() and like().
641 #
642
643 sub fresh_perl_like {
644     my($prog, $expected, $runperl_args, $name) = @_;
645     local $Level = 2;
646     _fresh_perl($prog,
647                 sub { @_ ?
648                           $_[0] =~ (ref $expected ? $expected : /$expected/) :
649                           $expected },
650                 $runperl_args, $name);
651 }
652
653 sub can_ok ($@) {
654     my($proto, @methods) = @_;
655     my $class = ref $proto || $proto;
656
657     unless( @methods ) {
658         return _ok( 0, _where(), "$class->can(...)" );
659     }
660
661     my @nok = ();
662     foreach my $method (@methods) {
663         local($!, $@);  # don't interfere with caller's $@
664                         # eval sometimes resets $!
665         eval { $proto->can($method) } || push @nok, $method;
666     }
667
668     my $name;
669     $name = @methods == 1 ? "$class->can('$methods[0]')" 
670                           : "$class->can(...)";
671     
672     _ok( !@nok, _where(), $name );
673 }
674
675 sub isa_ok ($$;$) {
676     my($object, $class, $obj_name) = @_;
677
678     my $diag;
679     $obj_name = 'The object' unless defined $obj_name;
680     my $name = "$obj_name isa $class";
681     if( !defined $object ) {
682         $diag = "$obj_name isn't defined";
683     }
684     elsif( !ref $object ) {
685         $diag = "$obj_name isn't a reference";
686     }
687     else {
688         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
689         local($@, $!);  # eval sometimes resets $!
690         my $rslt = eval { $object->isa($class) };
691         if( $@ ) {
692             if( $@ =~ /^Can't call method "isa" on unblessed reference/ ) {
693                 if( !UNIVERSAL::isa($object, $class) ) {
694                     my $ref = ref $object;
695                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
696                 }
697             } else {
698                 die <<WHOA;
699 WHOA! I tried to call ->isa on your object and got some weird error.
700 This should never happen.  Please contact the author immediately.
701 Here's the error.
702 $@
703 WHOA
704             }
705         }
706         elsif( !$rslt ) {
707             my $ref = ref $object;
708             $diag = "$obj_name isn't a '$class' it's a '$ref'";
709         }
710     }
711
712     _ok( !$diag, _where(), $name );
713 }
714
715 1;