installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '../lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 BEGIN {
  11     use Config;
  12     if ($Config{userelocatableinc}) {
  13         # This might be a considered a hack. Need to get information about the
  14         # configuration from Config.pm *before* Config.pm expands any .../
  15         # prefixes.
  16         #
  17         # So we set $^X to pretend that we're the already installed perl, so
  18         # Config.pm doesits ... expansion off that location.
  19
  20         my $location = $Config{initialinstalllocation};
  21         die <<'OS' unless defined $location;
  22 $Config{initialinstalllocation} is not defined - can't install a relocatable
  23 perl without this.
  24 OS
  25         $^X = "$location/perl";
  26         # And then remove all trace of ever having loaded Config.pm, so that
  27         # it will reload with the revised $^X
  28         undef %Config::;
  29         delete $INC{"Config.pm"};
  30         delete $INC{"Config_heavy.pl"};
  31         # You never saw us. We weren't here.
  32     }
  33 }
  34
  35 use strict;
  36 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  37     $nonono, $dostrip, $versiononly, $silent, $verbose, $force,
  38     $otherperls, $archname, $Is_NetWare, $nwinstall, $nopods);
  39 use vars qw /$depth/;
  40
  41 BEGIN {
  42     $Is_VMS = $^O eq 'VMS';
  43     $Is_W32 = $^O eq 'MSWin32';
  44     $Is_OS2 = $^O eq 'os2';
  45     $Is_Cygwin = $^O eq 'cygwin';
  46     $Is_Darwin = $^O eq 'darwin';
  47     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  48 }
  49
  50 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  51
  52 use File::Find;
  53 use File::Compare;
  54 use File::Copy ();
  55 use File::Path ();
  56 use ExtUtils::Packlist;
  57 use Config;
  58 use subs qw(unlink link chmod);
  59
  60 if ($Config{d_umask}) {
  61     umask(022); # umasks like 077 aren't that useful for installations
  62 }
  63
  64 $Is_NetWare = $Config{osname} eq 'NetWare';
  65 if ($Is_NetWare) {
  66     $Is_W32 = 0;
  67     $scr_ext = '.pl';
  68 }
  69
  70 # override the ones in the rest of the script
  71 sub mkpath {
  72     File::Path::mkpath(@_) unless $nonono;
  73 }
  74
  75 my $mainperldir = "/usr/bin";
  76 my $exe_ext = $Config{exe_ext};
  77
  78 # Allow ``make install PERLNAME=something_besides_perl'':
  79 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  80
  81 # This is the base used for versioned names, like "perl5.6.0".
  82 # It's separate because a common use of $PERLNAME is to install
  83 # perl as "perl5", if that's used as base for versioned files you
  84 # get "perl55.6.0".
  85 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  86                     ? $ENV{PERLNAME_VERBASE}
  87                     : $perl;
  88 my $dbg = '';
  89 my $ndbg = '';
  90 if ( $Is_VMS ) {
  91     if ( defined $Config{usevmsdebug} ) {
  92         if ( $Config{usevmsdebug} eq 'define' ) {
  93             $dbg = 'dbg';
  94             $ndbg = 'ndbg';
  95         }
  96     }
  97 }
  98
  99 $otherperls = 1;
 100 my $destdir = '';
 101 while (@ARGV) {
 102     $nonono = 1 if $ARGV[0] eq '-n';
 103     $dostrip = 1 if $ARGV[0] eq '-s';
 104     $versiononly = 1 if $ARGV[0] eq '-v';
 105     $versiononly = 0 if $ARGV[0] eq '+v';
 106     $silent = 1 if $ARGV[0] eq '-S';
 107     $otherperls = 0 if $ARGV[0] eq '-o';
 108     $force = 1 if $ARGV[0] eq '-f';
 109     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
 110     $archname = 1 if $ARGV[0] eq '-A';
 111     $nwinstall = 1 if $ARGV[0] eq '-netware';
 112     $nopods = 1 if $ARGV[0] eq '-p';
 113     $destdir = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
 114     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
 115         print <<"EOT";
 116 Usage $0: [switches]
 117   -n        Don't actually run any commands; just print them.
 118   -s        Run strip on installed binaries.
 119   -v        Only install perl as a binary with the version number in the name.
 120             (Override whatever config.sh says)
 121   +v        Install perl as "perl" and as a binary with the version number in
 122             the name.  (Override whatever config.sh says)
 123   -S        Silent mode.
 124   -f        Force installation (don't check if same version is there)
 125   -o        Skip checking for other copies of perl in your PATH.
 126   -V        Verbose mode.
 127   -A        Also install perl with the architecture's name in the perl binary's
 128             name.
 129   -p        Don't install the pod files. [This will break use diagnostics;]
 130   -netware  Install correctly on a Netware server.
 131   -destdir  Prefix installation directories by this string.
 132 EOT
 133         exit;
 134     }
 135     shift;
 136 }
 137
 138 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 139 my (@scripts, @tolink);
 140 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 141 while (<SCRIPTS>) {
 142     next if /^#/;
 143     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
 144     next if /a2p/; # a2p is binary, to be installed separately
 145     chomp;
 146     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 147         push @scripts, $1;
 148         push @tolink, [$1, $2];
 149     } else {
 150         push @scripts, $_;
 151     }
 152 }
 153 close SCRIPTS;
 154
 155 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 156
 157 my @pods = $nopods ? () : (<pod/*.pod>, 'x2p/a2p.pod');
 158
 159 # Specify here any .pm files that are actually architecture-dependent.
 160 # (Those included with XS extensions under ext/ are automatically
 161 # added later.)
 162 # Now that the default privlib has the full perl version number included,
 163 # we no longer have to play the trick of sticking version-specific .pm
 164 # files under the archlib directory.
 165 my %archpms = (
 166     Config => 1,
 167     lib => 1,
 168     Cwd => 1,
 169 );
 170
 171 if ($^O eq 'dos') {
 172     push(@scripts,'djgpp/fixpmain');
 173     $archpms{config} = $archpms{filehand} = 1;
 174 }
 175
 176 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 177     push(@scripts, map("$_.exe", @scripts));
 178 }
 179
 180 find(sub {
 181     if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 182         my($path, $modname) = ($1,$2);
 183
 184         # strip to optional "/lib", or remove trailing component
 185         $path =~ s{.*/lib\b}{} or $path =~ s{/[^/]*$}{};
 186
 187         # strip any leading /
 188         $path =~ s{^/}{};
 189
 190         # reconstitute canonical module name
 191         $modname = "$path/$modname" if length $path;
 192
 193         # remember it
 194         $archpms{$modname} = 1;
 195     }
 196 }, 'ext');
 197
 198 # print "[$_]\n" for sort keys %archpms;
 199
 200 my $ver = $Config{version};
 201 my $release = substr($],0,3);   # Not used currently.
 202 my $patchlevel = substr($],3,2);
 203 die "Patchlevel of perl ($patchlevel)",
 204     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 205         if $patchlevel != $Config{'PERL_VERSION'};
 206
 207 # Fetch some frequently-used items from %Config
 208 my $installbin = "$destdir$Config{installbin}";
 209 my $installscript = "$destdir$Config{installscript}";
 210 my $installprivlib = "$destdir$Config{installprivlib}";
 211 my $installarchlib = "$destdir$Config{installarchlib}";
 212 my $installsitelib = "$destdir$Config{installsitelib}";
 213 my $installsitearch = "$destdir$Config{installsitearch}";
 214 my $installman1dir = "$destdir$Config{installman1dir}";
 215 my $man1ext = $Config{man1ext};
 216 my $libperl = $Config{libperl};
 217 # Shared library and dynamic loading suffixes.
 218 my $so = $Config{so};
 219 my $dlext = $Config{dlext};
 220 my $dlsrc = $Config{dlsrc};
 221 if ($^O eq 'os390') {
 222     my $pwd;
 223     chomp($pwd=`pwd`);
 224     my $archlibexp = $Config{archlibexp};
 225     my $usedl = $Config{usedl};
 226     if ($usedl eq 'define') {
 227         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 228     }
 229 }
 230
 231 if ($nwinstall) {
 232     # This is required only if we are installing on a NetWare server
 233     $installscript = $Config{installnwscripts};
 234     $installprivlib = $Config{installnwlib};
 235     $installarchlib = $Config{installnwlib};
 236     $installsitelib = $Config{installnwlib};
 237 }
 238
 239 my $d_dosuid = $Config{d_dosuid};
 240 my $binexp = $Config{binexp};
 241
 242 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 243     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 244               \$installarchlib, \$installsitelib, \$installsitearch,
 245               \$installman1dir ) {
 246         $$_ = unixify($$_);  $$_ =~ s:/$::;
 247     }
 248 }
 249
 250 # Do some quick sanity checks.
 251
 252 if (!$nonono && $d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 253
 254    $installbin          || die "No installbin directory in config.sh\n";
 255 -d $installbin          || mkpath($installbin, $verbose, 0777);
 256 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 257 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 258         unless $installbin =~ m#^/afs/# || $nonono;
 259
 260 if (!$Is_NetWare) {
 261 if (!$Is_VMS) {
 262 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 263 }
 264 else {
 265 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
 266     if ($dbg) {
 267         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
 268     }
 269 }
 270 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 271
 272 -f 't/rantests'         || $Is_W32
 273                         || warn "WARNING: You've never run 'make test' or",
 274                                 " some tests failed! (Installing anyway.)\n";
 275 } #if (!$Is_NetWare)
 276
 277 # This will be used to store the packlist
 278 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 279
 280 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 281     my $perldll;
 282
 283     if ($Is_Cygwin) {
 284         $perldll = $libperl;
 285         my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 286         $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 287         $perldll =~ s/^lib/cyg/;
 288     } else {
 289         $perldll = 'perl511.' . $dlext;
 290     }
 291
 292     if ($dlsrc ne "dl_none.xs") {
 293         -f $perldll || die "No perl DLL built\n";
 294     }
 295
 296     # Install the DLL
 297     safe_unlink("$installbin/$perldll");
 298     copy("$perldll", "$installbin/$perldll");
 299     chmod(0755, "$installbin/$perldll");
 300     $packlist->{"$installbin/$perldll"} = { type => 'file' };
 301 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 302
 303 # First we install the version-numbered executables.
 304
 305 if ($Is_VMS) {
 306     safe_unlink("$installbin/perl_setup.com");
 307     copy("perl_setup.com", "$installbin/perl_setup.com");
 308     chmod(0755, "$installbin/perl_setup.com");
 309     safe_unlink("$installbin/$dbg$perl$exe_ext");
 310     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
 311     chmod(0755, "$installbin/$dbg$perl$exe_ext");
 312     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
 313     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
 314     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
 315     if ($ndbg) {
 316         safe_unlink("$installbin/$ndbg$perl$exe_ext");
 317         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
 318         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
 319         safe_unlink("$installbin/${dbg}a2p$exe_ext");
 320         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
 321         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
 322     }
 323 }
 324 elsif ($^O eq 'mpeix') {
 325     # MPE lacks hard links and requires that executables with special
 326     # capabilities reside in the MPE namespace.
 327     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 328     # Install the primary executable into the MPE namespace as perlpath.
 329     copy("perl$exe_ext", $Config{perlpath});
 330     chmod(0755, $Config{perlpath});
 331     # Create a backup copy with the version number.
 332     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 333 }
 334 elsif ($^O ne 'dos') {
 335     if (!$Is_NetWare) {
 336         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 337         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 338         strip("$installbin/$perl_verbase$ver$exe_ext");
 339         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 340     }
 341     else {
 342         # If installing onto a NetWare server
 343         if ($nwinstall) {
 344             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 345             mkpath($Config{installnwsystem}, 1, 0777);
 346             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 347             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 348             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 349             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 350             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 351             mkpath($Config{installnwlcgi}, 1, 0777);
 352             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 353         }
 354     } #if (!$Is_NetWare)
 355 }
 356 else {
 357     safe_unlink("$installbin/$perl.exe");
 358     copy("perl.exe", "$installbin/$perl.exe");
 359 }
 360
 361 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 362 if ($d_dosuid) {
 363     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 364     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 365 }
 366
 367 # Install library files.
 368
 369 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 370
 371 mkpath($installprivlib, $verbose, 0777);
 372 mkpath($installarchlib, $verbose, 0777);
 373 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 374 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 375
 376 if (chdir "lib") {
 377     $do_installarchlib = ! samepath($installarchlib, '.');
 378     $do_installprivlib = ! samepath($installprivlib, '.');
 379     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 380
 381     if ($do_installarchlib || $do_installprivlib) {
 382         find(\&installlib, '.');
 383     }
 384     chdir ".." || die "Can't cd back to source directory: $!\n";
 385 }
 386 else {
 387     warn "Can't cd to lib to install lib files: $!\n";
 388 }
 389
 390 # Install header files and libraries.
 391 mkpath("$installarchlib/CORE", $verbose, 0777);
 392 my @corefiles;
 393 if ($Is_VMS) {  # We did core file selection during build
 394     my $coredir = "lib/$Config{archname}/$ver/CORE";
 395     $coredir =~ tr/./_/;
 396     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 397 }
 398 else {
 399     # [als] hard-coded 'libperl' name... not good!
 400     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 401
 402     # AIX needs perl.exp installed as well.
 403     push(@corefiles,'perl.exp') if $^O eq 'aix';
 404     if ($^O eq 'mpeix') {
 405         # MPE needs mpeixish.h installed as well.
 406         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 407         push(@corefiles,'mpeix/mpeixish.h');
 408     }
 409     # If they have built sperl.o...
 410     push(@corefiles,'sperl.o') if -f 'sperl.o';
 411 }
 412 foreach my $file (@corefiles) {
 413     # HP-UX (at least) needs to maintain execute permissions
 414     # on dynamically-loadable libraries. So we do it for all.
 415     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 416         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 417             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 418             chmod(0555, "$installarchlib/CORE/$file");
 419         } else {
 420             chmod(0444, "$installarchlib/CORE/$file");
 421         }
 422     }
 423 }
 424
 425 # Install main perl executables
 426 # Make links to ordinary names if installbin directory isn't current directory.
 427
 428 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 429     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 430     if ($^O eq 'mpeix') {
 431         # MPE doesn't support hard links, so use a symlink.
 432         # We don't want another cloned copy.
 433         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 434     } elsif ($^O eq 'vos') {
 435         # VOS doesn't support hard links, so use a symlink.
 436         symlink("$installbin/$perl_verbase$ver$exe_ext",
 437                 "$installbin/$perl$exe_ext");
 438     } else {
 439         link("$installbin/$perl_verbase$ver$exe_ext",
 440                 "$installbin/$perl$exe_ext");
 441     }
 442     link("$installbin/$perl_verbase$ver$exe_ext",
 443             "$installbin/suid$perl$exe_ext")
 444       if $d_dosuid;
 445 }
 446
 447 # For development purposes it can be very useful to have multiple perls
 448 # build for different "architectures" (eg threading or not) simultaneously.
 449 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 450     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 451     safe_unlink("$installbin/$archperl");
 452     if ($^O eq 'mpeix') {
 453         # MPE doesn't support hard links, so use a symlink.
 454         # We don't want another cloned copy.
 455         symlink($Config{perlpath}, "$installbin/$archperl");
 456     } elsif ($^O eq 'vos') {
 457         # VOS doesn't support hard links, so use a symlink.
 458         symlink("$installbin/$perl_verbase$ver$exe_ext",
 459                 "$installbin/$archperl");
 460     } else {
 461         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 462     }
 463 }
 464
 465 # Offer to install perl in a "standard" location
 466
 467 my $mainperl_is_instperl = 0;
 468
 469 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 470     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 471         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 472     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 473     my($instperl)       = "$installbin/$perl$exe_ext";
 474     my($expinstperl)    = "$binexp/$perl$exe_ext";
 475
 476     # First make sure $usrbinperl is not already the same as the perl we
 477     # just installed.
 478     if (-x $usrbinperl) {
 479         # Try to be clever about mainperl being a symbolic link
 480         # to binexp/perl if binexp and installbin are different.
 481         $mainperl_is_instperl =
 482             samepath($usrbinperl, $instperl) ||
 483             samepath($usrbinperl, $expinstperl) ||
 484              (($binexp ne $installbin) &&
 485               (-l $usrbinperl) &&
 486               ((readlink $usrbinperl) eq $expinstperl));
 487     }
 488     if (! $mainperl_is_instperl) {
 489         unlink($usrbinperl);
 490         ( $Config{'d_link'} eq 'define' &&
 491           eval { CORE::link $instperl, $usrbinperl } )  ||
 492         eval { symlink $expinstperl, $usrbinperl }      ||
 493         copy($instperl, $usrbinperl);
 494
 495         $mainperl_is_instperl = 1;
 496     }
 497 }
 498
 499 # Make links to ordinary names if installbin directory isn't current directory.
 500 if (!$Is_NetWare && $dbg eq '') {
 501     if (! samepath($installbin, 'x2p')) {
 502         my $base = 'a2p';
 503         $base .= $ver if $versiononly;
 504         safe_unlink("$installbin/$base$exe_ext");
 505         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 506         strip("$installbin/$base$exe_ext");
 507         chmod(0755, "$installbin/$base$exe_ext");
 508     }
 509 }
 510
 511 # cppstdin is just a script, but it is architecture-dependent, so
 512 # it can't safely be shared.  Place it in $installbin.
 513 # Note that Configure doesn't build cppstin if it isn't needed, so
 514 # we skip this if cppstdin doesn't exist.
 515 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 516     safe_unlink("$installbin/cppstdin");
 517     copy("cppstdin", "$installbin/cppstdin");
 518     chmod(0755, "$installbin/cppstdin");
 519 }
 520
 521 sub script_alias {
 522     my ($installscript, $orig, $alias, $scr_ext) = @_;
 523
 524     safe_unlink("$installscript/$alias$scr_ext");
 525     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 526         copy("$installscript/$orig$scr_ext",
 527              "$installscript/$alias$scr_ext");
 528     } elsif ($^O eq 'vos') {
 529         symlink("$installscript/$orig$scr_ext",
 530                 "$installscript/$alias$scr_ext");
 531     } else {
 532         link("$installscript/$orig$scr_ext",
 533              "$installscript/$alias$scr_ext");
 534     }
 535 }
 536
 537 # Install scripts.
 538 mkpath($installscript, $verbose, 0777);
 539 if ($versiononly) {
 540     for (@scripts) {
 541         (my $base = $_) =~ s#.*/##;
 542         $base .= $ver;
 543         copy($_,    "$installscript/$base");
 544         chmod(0755, "$installscript/$base");
 545     }
 546
 547     for (@tolink) {
 548         my ($from, $to) = map { "$_$ver" } @$_;
 549         (my $frbase = $from) =~ s#.*/##;
 550         (my $tobase = $to) =~ s#.*/##;
 551         script_alias($installscript, $frbase, $tobase, $scr_ext);
 552     }
 553 } else {
 554     for (@scripts) {
 555         (my $base = $_) =~ s#.*/##;
 556         copy($_, "$installscript/$base");
 557         chmod(0755, "$installscript/$base");
 558     }
 559
 560     for (@tolink) {
 561         my ($from, $to) = @$_;
 562         (my $frbase = $from) =~ s#.*/##;
 563         (my $tobase = $to) =~ s#.*/##;
 564         script_alias($installscript, $frbase, $tobase, $scr_ext);
 565     }
 566 }
 567
 568 # Install pod pages.  Where? I guess in $installprivlib/pod
 569 # ($installprivlib/pods for cygwin).
 570
 571 my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
 572 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 573     mkpath("${installprivlib}/$pod", $verbose, 0777);
 574
 575     # If Perl 5.003's perldiag.pod is there, rename it.
 576     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 577         read POD, $_, 4000;
 578         close POD;
 579         # Some of Perl 5.003's diagnostic messages ended with periods.
 580         if (/^=.*\.$/m) {
 581             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 582                                "${installprivlib}/$pod/perldiag-5.003.pod");
 583             print "  rename $from $to";
 584             rename($from, $to)
 585                 or warn "Couldn't rename $from to $to: $!\n"
 586                 unless $nonono;
 587         }
 588     }
 589
 590     for (@pods) {
 591         # $_ is a name like  pod/perl.pod
 592         (my $base = $_) =~ s#.*/##;
 593         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 594     }
 595
 596 }
 597
 598 # Check to make sure there aren't other perls around in installer's
 599 # path.  This is probably UNIX-specific.  Check all absolute directories
 600 # in the path except for where public executables are supposed to live.
 601 # Also skip $mainperl if the user opted to have it be a link to the
 602 # installed perl.
 603
 604 if (!$versiononly && $otherperls) {
 605     my ($path, @path);
 606     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 607     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 608     @path = split(/$dirsep/, $path);
 609     if ($Is_VMS) {
 610         my $i = 0;
 611         while (exists $ENV{'DCL$PATH' . $i}) {
 612             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 613             push(@path,$dir);
 614         }
 615     }
 616     my @otherperls;
 617     my %otherperls;
 618     for (@path) {
 619         next unless m,^/,;
 620         # Use &samepath here because some systems have other dirs linked
 621         # to $mainperldir (like SunOS)
 622         next if samepath($_, $binexp);
 623         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 624         my $otherperl = "$_/$perl$exe_ext";
 625         next if $otherperls{$otherperl}++;
 626         push(@otherperls, $otherperl)
 627             if (-x $otherperl && ! -d $otherperl);
 628     }
 629     if (@otherperls) {
 630         warn "\nWarning: $perl appears in your path in the following " .
 631             "locations beyond where\nwe just installed it:\n";
 632         for (@otherperls) {
 633             warn "    ", $_, "\n";
 634         }
 635         warn "\n";
 636     }
 637
 638 }
 639
 640 $packlist->write() unless $nonono;
 641 print "  Installation complete\n" if $verbose;
 642
 643 exit 0;
 644
 645 ###############################################################################
 646
 647 sub yn {
 648     my($prompt) = @_;
 649     my($answer);
 650     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 651     print STDERR $prompt;
 652     chop($answer = <STDIN>);
 653     $answer = $default if $answer =~ m/^\s*$/;
 654     ($answer =~ m/^[yY]/);
 655 }
 656
 657 sub unlink {
 658     my(@names) = @_;
 659     my($cnt) = 0;
 660
 661     return scalar(@names) if $Is_VMS;
 662
 663     foreach my $name (@names) {
 664         next unless -e $name;
 665         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 666         print "  unlink $name\n" if $verbose;
 667         ( CORE::unlink($name) and ++$cnt
 668           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 669     }
 670     return $cnt;
 671 }
 672
 673 sub safe_unlink {
 674     return if $nonono or $Is_VMS;
 675     my @names = @_;
 676     foreach my $name (@names) {
 677         next unless -e $name;
 678         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 679         print "  unlink $name\n" if $verbose;
 680         next if CORE::unlink($name);
 681         warn "Couldn't unlink $name: $!\n";
 682         if ($! =~ /busy/i) {
 683             print "  mv $name $name.old\n" if $verbose;
 684             safe_rename($name, "$name.old")
 685                 or warn "Couldn't rename $name: $!\n";
 686         }
 687     }
 688 }
 689
 690 sub safe_rename {
 691     my($from,$to) = @_;
 692     if (-f $to and not unlink($to)) {
 693         my($i);
 694         for ($i = 1; $i < 50; $i++) {
 695             last if rename($to, "$to.$i");
 696         }
 697         warn("Cannot rename to `$to.$i': $!"), return 0
 698            if $i >= 50; # Give up!
 699     }
 700     link($from,$to) || return 0;
 701     unlink($from);
 702 }
 703
 704 sub link {
 705     my($from,$to) = @_;
 706     my($success) = 0;
 707
 708     my $xfrom = $from;
 709     $xfrom =~ s/^\Q$destdir\E// if $destdir;
 710     my $xto = $to;
 711     $xto =~ s/^\Q$destdir\E// if $destdir;
 712     print $verbose ? "  ln $xfrom $xto\n" : "  $xto\n" unless $silent;
 713     eval {
 714         CORE::link($from, $to)
 715             ? $success++
 716             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 717               ? die "AFS"  # okay inside eval {}
 718               : die "Couldn't link $from to $to: $!\n"
 719           unless $nonono;
 720         $packlist->{$xto} = { from => $xfrom, type => 'link' };
 721     };
 722     if ($@) {
 723         warn "Replacing link() with File::Copy::copy(): $@";
 724         print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 725         print "  creating new version of $xto\n"
 726                  if $Is_VMS and -e $to and !$silent;
 727         unless ($nonono or File::Copy::copy($from, $to) and ++$success) {
 728             # Might have been that F::C::c can't overwrite the target
 729             warn "Couldn't copy $from to $to: $!\n"
 730                 unless -f $to and (chmod(0666, $to), unlink $to)
 731                         and File::Copy::copy($from, $to) and ++$success;
 732         }
 733         $packlist->{$xto} = { type => 'file' };
 734     }
 735     $success;
 736 }
 737
 738 sub chmod {
 739     my($mode,$name) = @_;
 740
 741     return if ($^O eq 'dos');
 742     printf "  chmod %o %s\n", $mode, $name if $verbose;
 743     CORE::chmod($mode,$name)
 744         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 745       unless $nonono;
 746 }
 747
 748 sub copy {
 749     my($from,$to) = @_;
 750
 751     my $xto = $to;
 752     $xto =~ s/^\Q$destdir\E// if $destdir;
 753     print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 754     print "  creating new version of $xto\n" if $Is_VMS and -e $to and !$silent;
 755     unless ($nonono or File::Copy::copy($from, $to)) {
 756         # Might have been that F::C::c can't overwrite the target
 757         warn "Couldn't copy $from to $to: $!\n"
 758             unless -f $to and (chmod(0666, $to), unlink $to)
 759                    and File::Copy::copy($from, $to);
 760     }
 761     $packlist->{$xto} = { type => 'file' };
 762 }
 763
 764 sub samepath {
 765     my($p1, $p2) = @_;
 766
 767     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 768
 769     if ($p1 ne $p2) {
 770         my($dev1, $ino1, $dev2, $ino2);
 771         ($dev1, $ino1) = stat($p1);
 772         ($dev2, $ino2) = stat($p2);
 773         ($dev1 == $dev2 && $ino1 == $ino2);
 774     }
 775     else {
 776         1;
 777     }
 778 }
 779
 780 sub installlib {
 781     my $dir = $File::Find::dir;
 782     $dir =~ s#^\.(?![^/])/?##;
 783     local($depth) = $dir ? "lib/$dir" : "lib";
 784
 785     my $name = $_;
 786
 787     # Ignore version control directories.
 788     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
 789         $File::Find::prune = 1;
 790         return;
 791     }
 792
 793     # ignore patch backups, RCS files, emacs backup & temp files and the
 794     # .exists files, .PL files, and test files.
 795     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$|^dbm_filter_util.pl$} ||
 796               $dir  =~ m{/t(?:/|$)};
 797     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
 798     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
 799     # the corelist script from lib/Module/CoreList/bin and ptar* in
 800     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
 801     # (they're installed later with other utils)
 802     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|cpan2dist|cpanp|cpanp-run-perl|ptardiff|config_data)\z/;
 803     # ignore the Makefiles
 804     return if $name =~ /^makefile$/i;
 805     # ignore the test extensions
 806     return if $dir =~ m{\bXS/(?:APItest|Typemap)\b};
 807     return if $name =~ m{\b(?:APItest|Typemap)\.pm$};
 808     # ignore the demo files
 809     return if $dir =~ /\b(?:demos?|eg)\b/;
 810
 811     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
 812     # Changes.e2x and README.e2x are needed by enc2xs.
 813     return if $name =~ m{^(?:README(?:\.\w+)?)$} && $name ne 'README.e2x';
 814     return if $name =~ m{^(?:MANIFEST|META\.yml)$};
 815     return if $name =~ m{^(?:INSTALL|TODO|BUGS|CREDITS)$}i;
 816     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
 817     return if $name =~ m{^(?:SIGNATURE|PAUSE200\d\.pub)$}; # CPAN files
 818     return if $name =~ m{^(?:NOTES|PATCHING)$}; # ExtUtils files
 819
 820     # if using a shared perl library then ignore:
 821     # - static library files [of statically linked extensions];
 822     # - import library files and export library files (only present on Win32
 823     #   anyway?) and empty bootstrap files [of dynamically linked extensions].
 824     return if $Config{useshrplib} eq 'true' and
 825              ($name =~ /$Config{_a}$/ or $name =~ /\.exp$/ or ($name =~ /\.bs$/ and -z $name));
 826
 827     $name = "$dir/$name" if $dir ne '';
 828
 829     my $installlib = $installprivlib;
 830     if ($dir =~ /^auto/ ||
 831           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 832           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
 833           $name eq 'Config_heavy.pl'
 834        ) {
 835         $installlib = $installarchlib;
 836         return unless $do_installarchlib;
 837     } else {
 838         return unless $do_installprivlib;
 839     }
 840
 841     if (-f $_) {
 842         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$])) {
 843             $installlib = $installprivlib;
 844             #We're installing *.al and *.ix files into $installprivlib,
 845             #but we have to delete old *.al and *.ix files from the 5.000
 846             #distribution:
 847             #This might not work because $archname might have changed.
 848             unlink("$installarchlib/$name");
 849         }
 850         my $xname = "$installlib/$name";
 851         $xname =~ s/^\Q$destdir\E// if $destdir;
 852         $packlist->{$xname} = { type => 'file' };
 853         if ($force || compare($_, "$installlib/$name") || $nonono) {
 854             unlink("$installlib/$name");
 855             mkpath("$installlib/$dir", $verbose, 0777);
 856             # HP-UX (at least) needs to maintain execute permissions
 857             # on dynamically-loaded libraries.
 858             if ($Is_NetWare && !$nwinstall) {
 859                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 860                 # if copied will give problems when building new extensions.
 861                 # Has to be copied if we are installing on a NetWare server and hence
 862                 # the check !$nwinstall
 863                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 864                     copy_if_diff($_, "$installlib/$name")
 865                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 866                                   "$installlib/$name");
 867                 }
 868            } else {
 869                 if (copy_if_diff($_, "$installlib/$name")) {
 870                     if ($name =~ /\.(so|$dlext)$/o) {
 871                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 872                         chmod(0555, "$installlib/$name");
 873                     } else {
 874                         strip("-S", "$installlib/$name")
 875                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 876                         chmod(0444, "$installlib/$name");
 877                     }
 878                 }
 879             } #if ($Is_NetWare)
 880         }
 881     }
 882 }
 883
 884 # Copy $from to $to, only if $from is different than $to.
 885 # Also preserve modification times for .a libraries.
 886 # On some systems, if you do
 887 #   ranlib libperl.a
 888 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 889 # and then try to link against the installed libperl.a, you might
 890 # get an error message to the effect that the symbol table is older
 891 # than the library.
 892 # Return true if copying occurred.
 893
 894 sub copy_if_diff {
 895     my($from,$to)=@_;
 896     return 1 if (($^O eq 'VMS') && (-d $from));
 897     my $xto = $to;
 898     $xto =~ s/^\Q$destdir\E// if $destdir;
 899     my $perlpodbadsymlink;
 900     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 901         -l $from &&
 902         ! -e $from) {
 903         # Some Linux implementations have problems traversing over
 904         # multiple symlinks (when going over NFS?) and fail to read
 905         # the symlink target.  Combine this with the fact that some
 906         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 907         # and you end up with those pods not getting installed.
 908         $perlpodbadsymlink = 1;
 909     }
 910     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 911     $packlist->{$xto} = { type => 'file' };
 912     if ($force || compare($from, $to) || $nonono) {
 913         safe_unlink($to);   # In case we don't have write permissions.
 914         if ($nonono) {
 915             $from = $depth . "/" . $from if $depth;
 916         }
 917         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 918             $from = "README.$1";
 919         }
 920         copy($from, $to);
 921         # Restore timestamps if it's a .a library or for OS/2.
 922         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 923             my ($atime, $mtime) = (stat $from)[8,9];
 924             utime $atime, $mtime, $to;
 925         }
 926         1;
 927     }
 928 }
 929
 930 sub strip
 931 {
 932     my(@args) = @_;
 933
 934     return unless $dostrip;
 935
 936     my @opts;
 937     while (@args && $args[0] =~ /^(-\w+)$/) {
 938         push @opts, shift @args;
 939     }
 940
 941     foreach my $file (@args) {
 942         if (-f $file) {
 943             if ($verbose) {
 944                 print "  strip " . join(' ', @opts);
 945                 print " " if (@opts);
 946                 print "$file\n";
 947             }
 948             system("strip", @opts, $file);
 949         } else {
 950             print "# file '$file' skipped\n" if $verbose;
 951         }
 952     }
 953 }