This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
8f3a6774aeb18fd76fcee8e0cb1da2856f28b52b
[perl5.git] / pod / perltie.pod
1 =head1 NAME
2
3 perltie - how to hide an object class in a simple variable
4
5 =head1 SYNOPSIS
6
7  tie VARIABLE, CLASSNAME, LIST
8
9  $object = tied VARIABLE
10
11  untie VARIABLE
12
13 =head1 DESCRIPTION
14
15 Prior to release 5.0 of Perl, a programmer could use dbmopen()
16 to connect an on-disk database in the standard Unix dbm(3x)
17 format magically to a %HASH in their program.  However, their Perl was either
18 built with one particular dbm library or another, but not both, and
19 you couldn't extend this mechanism to other packages or types of variables.
20
21 Now you can.
22
23 The tie() function binds a variable to a class (package) that will provide
24 the implementation for access methods for that variable.  Once this magic
25 has been performed, accessing a tied variable automatically triggers
26 method calls in the proper class.  The complexity of the class is
27 hidden behind magic methods calls.  The method names are in ALL CAPS,
28 which is a convention that Perl uses to indicate that they're called
29 implicitly rather than explicitly--just like the BEGIN() and END()
30 functions.
31
32 In the tie() call, C<VARIABLE> is the name of the variable to be
33 enchanted.  C<CLASSNAME> is the name of a class implementing objects of
34 the correct type.  Any additional arguments in the C<LIST> are passed to
35 the appropriate constructor method for that class--meaning TIESCALAR(),
36 TIEARRAY(), TIEHASH(), or TIEHANDLE().  (Typically these are arguments
37 such as might be passed to the dbminit() function of C.) The object
38 returned by the "new" method is also returned by the tie() function,
39 which would be useful if you wanted to access other methods in
40 C<CLASSNAME>. (You don't actually have to return a reference to a right
41 "type" (e.g., HASH or C<CLASSNAME>) so long as it's a properly blessed
42 object.)  You can also retrieve a reference to the underlying object
43 using the tied() function.
44
45 Unlike dbmopen(), the tie() function will not C<use> or C<require> a module
46 for you--you need to do that explicitly yourself.
47
48 =head2 Tying Scalars
49
50 A class implementing a tied scalar should define the following methods:
51 TIESCALAR, FETCH, STORE, and possibly UNTIE and/or DESTROY.
52
53 Let's look at each in turn, using as an example a tie class for
54 scalars that allows the user to do something like:
55
56     tie $his_speed, 'Nice', getppid();
57     tie $my_speed,  'Nice', $$;
58
59 And now whenever either of those variables is accessed, its current
60 system priority is retrieved and returned.  If those variables are set,
61 then the process's priority is changed!
62
63 We'll use Jarkko Hietaniemi <F<jhi@iki.fi>>'s BSD::Resource class (not
64 included) to access the PRIO_PROCESS, PRIO_MIN, and PRIO_MAX constants
65 from your system, as well as the getpriority() and setpriority() system
66 calls.  Here's the preamble of the class.
67
68     package Nice;
69     use Carp;
70     use BSD::Resource;
71     use strict;
72     $Nice::DEBUG = 0 unless defined $Nice::DEBUG;
73
74 =over 4
75
76 =item TIESCALAR classname, LIST
77
78 This is the constructor for the class.  That means it is
79 expected to return a blessed reference to a new scalar
80 (probably anonymous) that it's creating.  For example:
81
82     sub TIESCALAR {
83         my $class = shift;
84         my $pid = shift || $$; # 0 means me
85
86         if ($pid !~ /^\d+$/) {
87             carp "Nice::Tie::Scalar got non-numeric pid $pid" if $^W;
88             return undef;
89         }
90
91         unless (kill 0, $pid) { # EPERM or ERSCH, no doubt
92             carp "Nice::Tie::Scalar got bad pid $pid: $!" if $^W;
93             return undef;
94         }
95
96         return bless \$pid, $class;
97     }
98
99 This tie class has chosen to return an error rather than raising an
100 exception if its constructor should fail.  While this is how dbmopen() works,
101 other classes may well not wish to be so forgiving.  It checks the global
102 variable C<$^W> to see whether to emit a bit of noise anyway.
103
104 =item FETCH this
105
106 This method will be triggered every time the tied variable is accessed
107 (read).  It takes no arguments beyond its self reference, which is the
108 object representing the scalar we're dealing with.  Because in this case
109 we're using just a SCALAR ref for the tied scalar object, a simple $$self
110 allows the method to get at the real value stored there.  In our example
111 below, that real value is the process ID to which we've tied our variable.
112
113     sub FETCH {
114         my $self = shift;
115         confess "wrong type" unless ref $self;
116         croak "usage error" if @_;
117         my $nicety;
118         local($!) = 0;
119         $nicety = getpriority(PRIO_PROCESS, $$self);
120         if ($!) { croak "getpriority failed: $!" }
121         return $nicety;
122     }
123
124 This time we've decided to blow up (raise an exception) if the renice
125 fails--there's no place for us to return an error otherwise, and it's
126 probably the right thing to do.
127
128 =item STORE this, value
129
130 This method will be triggered every time the tied variable is set
131 (assigned).  Beyond its self reference, it also expects one (and only one)
132 argument--the new value the user is trying to assign.
133
134     sub STORE {
135         my $self = shift;
136         confess "wrong type" unless ref $self;
137         my $new_nicety = shift;
138         croak "usage error" if @_;
139
140         if ($new_nicety < PRIO_MIN) {
141             carp sprintf
142               "WARNING: priority %d less than minimum system priority %d",
143                   $new_nicety, PRIO_MIN if $^W;
144             $new_nicety = PRIO_MIN;
145         }
146
147         if ($new_nicety > PRIO_MAX) {
148             carp sprintf
149               "WARNING: priority %d greater than maximum system priority %d",
150                   $new_nicety, PRIO_MAX if $^W;
151             $new_nicety = PRIO_MAX;
152         }
153
154         unless (defined setpriority(PRIO_PROCESS, $$self, $new_nicety)) {
155             confess "setpriority failed: $!";
156         }
157         return $new_nicety;
158     }
159
160 =item UNTIE this
161
162 This method will be triggered when the C<untie> occurs. This can be useful
163 if the class needs to know when no further calls will be made. (Except DESTROY
164 of course.) See L<The C<untie> Gotcha> below for more details.
165
166 =item DESTROY this
167
168 This method will be triggered when the tied variable needs to be destructed.
169 As with other object classes, such a method is seldom necessary, because Perl
170 deallocates its moribund object's memory for you automatically--this isn't
171 C++, you know.  We'll use a DESTROY method here for debugging purposes only.
172
173     sub DESTROY {
174         my $self = shift;
175         confess "wrong type" unless ref $self;
176         carp "[ Nice::DESTROY pid $$self ]" if $Nice::DEBUG;
177     }
178
179 =back
180
181 That's about all there is to it.  Actually, it's more than all there
182 is to it, because we've done a few nice things here for the sake
183 of completeness, robustness, and general aesthetics.  Simpler
184 TIESCALAR classes are certainly possible.
185
186 =head2 Tying Arrays
187
188 A class implementing a tied ordinary array should define the following
189 methods: TIEARRAY, FETCH, STORE, FETCHSIZE, STORESIZE and perhaps UNTIE and/or DESTROY.
190
191 FETCHSIZE and STORESIZE are used to provide C<$#array> and
192 equivalent C<scalar(@array)> access.
193
194 The methods POP, PUSH, SHIFT, UNSHIFT, SPLICE, DELETE, and EXISTS are
195 required if the perl operator with the corresponding (but lowercase) name
196 is to operate on the tied array. The B<Tie::Array> class can be used as a
197 base class to implement the first five of these in terms of the basic
198 methods above.  The default implementations of DELETE and EXISTS in
199 B<Tie::Array> simply C<croak>.
200
201 In addition EXTEND will be called when perl would have pre-extended
202 allocation in a real array.
203
204 For this discussion, we'll implement an array whose elements are a fixed
205 size at creation.  If you try to create an element larger than the fixed
206 size, you'll take an exception.  For example:
207
208     use FixedElem_Array;
209     tie @array, 'FixedElem_Array', 3;
210     $array[0] = 'cat';  # ok.
211     $array[1] = 'dogs'; # exception, length('dogs') > 3.
212
213 The preamble code for the class is as follows:
214
215     package FixedElem_Array;
216     use Carp;
217     use strict;
218
219 =over 4
220
221 =item TIEARRAY classname, LIST
222
223 This is the constructor for the class.  That means it is expected to
224 return a blessed reference through which the new array (probably an
225 anonymous ARRAY ref) will be accessed.
226
227 In our example, just to show you that you don't I<really> have to return an
228 ARRAY reference, we'll choose a HASH reference to represent our object.
229 A HASH works out well as a generic record type: the C<{ELEMSIZE}> field will
230 store the maximum element size allowed, and the C<{ARRAY}> field will hold the
231 true ARRAY ref.  If someone outside the class tries to dereference the
232 object returned (doubtless thinking it an ARRAY ref), they'll blow up.
233 This just goes to show you that you should respect an object's privacy.
234
235     sub TIEARRAY {
236       my $class    = shift;
237       my $elemsize = shift;
238       if ( @_ || $elemsize =~ /\D/ ) {
239         croak "usage: tie ARRAY, '" . __PACKAGE__ . "', elem_size";
240       }
241       return bless {
242         ELEMSIZE => $elemsize,
243         ARRAY    => [],
244       }, $class;
245     }
246
247 =item FETCH this, index
248
249 This method will be triggered every time an individual element the tied array
250 is accessed (read).  It takes one argument beyond its self reference: the
251 index whose value we're trying to fetch.
252
253     sub FETCH {
254       my $self  = shift;
255       my $index = shift;
256       return $self->{ARRAY}->[$index];
257     }
258
259 If a negative array index is used to read from an array, the index
260 will be translated to a positive one internally by calling FETCHSIZE
261 before being passed to FETCH.  You may disable this feature by
262 assigning a true value to the variable C<$NEGATIVE_INDICES> in the
263 tied array class.
264
265 As you may have noticed, the name of the FETCH method (et al.) is the same
266 for all accesses, even though the constructors differ in names (TIESCALAR
267 vs TIEARRAY).  While in theory you could have the same class servicing
268 several tied types, in practice this becomes cumbersome, and it's easiest
269 to keep them at simply one tie type per class.
270
271 =item STORE this, index, value
272
273 This method will be triggered every time an element in the tied array is set
274 (written).  It takes two arguments beyond its self reference: the index at
275 which we're trying to store something and the value we're trying to put
276 there.
277
278 In our example, C<undef> is really C<$self-E<gt>{ELEMSIZE}> number of
279 spaces so we have a little more work to do here:
280
281     sub STORE {
282       my $self = shift;
283       my( $index, $value ) = @_;
284       if ( length $value > $self->{ELEMSIZE} ) {
285         croak "length of $value is greater than $self->{ELEMSIZE}";
286       }
287       # fill in the blanks
288       $self->EXTEND( $index ) if $index > $self->FETCHSIZE();
289       # right justify to keep element size for smaller elements
290       $self->{ARRAY}->[$index] = sprintf "%$self->{ELEMSIZE}s", $value;
291     }
292
293 Negative indexes are treated the same as with FETCH.
294
295 =item FETCHSIZE this
296
297 Returns the total number of items in the tied array associated with
298 object I<this>. (Equivalent to C<scalar(@array)>).  For example:
299
300     sub FETCHSIZE {
301       my $self = shift;
302       return scalar @{$self->{ARRAY}};
303     }
304
305 =item STORESIZE this, count
306
307 Sets the total number of items in the tied array associated with
308 object I<this> to be I<count>. If this makes the array larger then
309 class's mapping of C<undef> should be returned for new positions.
310 If the array becomes smaller then entries beyond count should be
311 deleted. 
312
313 In our example, 'undef' is really an element containing
314 C<$self-E<gt>{ELEMSIZE}> number of spaces.  Observe:
315
316     sub STORESIZE {
317       my $self  = shift;
318       my $count = shift;
319       if ( $count > $self->FETCHSIZE() ) {
320         foreach ( $count - $self->FETCHSIZE() .. $count ) {
321           $self->STORE( $_, '' );
322         }
323       } elsif ( $count < $self->FETCHSIZE() ) {
324         foreach ( 0 .. $self->FETCHSIZE() - $count - 2 ) {
325           $self->POP();
326         }
327       }
328     }
329
330 =item EXTEND this, count
331
332 Informative call that array is likely to grow to have I<count> entries.
333 Can be used to optimize allocation. This method need do nothing.
334
335 In our example, we want to make sure there are no blank (C<undef>)
336 entries, so C<EXTEND> will make use of C<STORESIZE> to fill elements
337 as needed:
338
339     sub EXTEND {   
340       my $self  = shift;
341       my $count = shift;
342       $self->STORESIZE( $count );
343     }
344
345 =item EXISTS this, key
346
347 Verify that the element at index I<key> exists in the tied array I<this>.
348
349 In our example, we will determine that if an element consists of
350 C<$self-E<gt>{ELEMSIZE}> spaces only, it does not exist:
351
352     sub EXISTS {
353       my $self  = shift;
354       my $index = shift;
355       return 0 if ! defined $self->{ARRAY}->[$index] ||
356                   $self->{ARRAY}->[$index] eq ' ' x $self->{ELEMSIZE};
357       return 1;
358     }
359
360 =item DELETE this, key
361
362 Delete the element at index I<key> from the tied array I<this>.
363
364 In our example, a deleted item is C<$self-E<gt>{ELEMSIZE}> spaces:
365
366     sub DELETE {
367       my $self  = shift;
368       my $index = shift;
369       return $self->STORE( $index, '' );
370     }
371
372 =item CLEAR this
373
374 Clear (remove, delete, ...) all values from the tied array associated with
375 object I<this>.  For example:
376
377     sub CLEAR {
378       my $self = shift;
379       return $self->{ARRAY} = [];
380     }
381
382 =item PUSH this, LIST 
383
384 Append elements of I<LIST> to the array.  For example:
385
386     sub PUSH {  
387       my $self = shift;
388       my @list = @_;
389       my $last = $self->FETCHSIZE();
390       $self->STORE( $last + $_, $list[$_] ) foreach 0 .. $#list;
391       return $self->FETCHSIZE();
392     }   
393
394 =item POP this
395
396 Remove last element of the array and return it.  For example:
397
398     sub POP {
399       my $self = shift;
400       return pop @{$self->{ARRAY}};
401     }
402
403 =item SHIFT this
404
405 Remove the first element of the array (shifting other elements down)
406 and return it.  For example:
407
408     sub SHIFT {
409       my $self = shift;
410       return shift @{$self->{ARRAY}};
411     }
412
413 =item UNSHIFT this, LIST 
414
415 Insert LIST elements at the beginning of the array, moving existing elements
416 up to make room.  For example:
417
418     sub UNSHIFT {
419       my $self = shift;
420       my @list = @_;
421       my $size = scalar( @list );
422       # make room for our list
423       @{$self->{ARRAY}}[ $size .. $#{$self->{ARRAY}} + $size ]
424        = @{$self->{ARRAY}};
425       $self->STORE( $_, $list[$_] ) foreach 0 .. $#list;
426     }
427
428 =item SPLICE this, offset, length, LIST
429
430 Perform the equivalent of C<splice> on the array. 
431
432 I<offset> is optional and defaults to zero, negative values count back 
433 from the end of the array. 
434
435 I<length> is optional and defaults to rest of the array.
436
437 I<LIST> may be empty.
438
439 Returns a list of the original I<length> elements at I<offset>.
440
441 In our example, we'll use a little shortcut if there is a I<LIST>:
442
443     sub SPLICE {
444       my $self   = shift;
445       my $offset = shift || 0;
446       my $length = shift || $self->FETCHSIZE() - $offset;
447       my @list   = (); 
448       if ( @_ ) {
449         tie @list, __PACKAGE__, $self->{ELEMSIZE};
450         @list   = @_;
451       }
452       return splice @{$self->{ARRAY}}, $offset, $length, @list;
453     }
454
455 =item UNTIE this
456
457 Will be called when C<untie> happens. (See L<The C<untie> Gotcha> below.)
458
459 =item DESTROY this
460
461 This method will be triggered when the tied variable needs to be destructed.
462 As with the scalar tie class, this is almost never needed in a
463 language that does its own garbage collection, so this time we'll
464 just leave it out.
465
466 =back
467
468 =head2 Tying Hashes
469
470 Hashes were the first Perl data type to be tied (see dbmopen()).  A class
471 implementing a tied hash should define the following methods: TIEHASH is
472 the constructor.  FETCH and STORE access the key and value pairs.  EXISTS
473 reports whether a key is present in the hash, and DELETE deletes one.
474 CLEAR empties the hash by deleting all the key and value pairs.  FIRSTKEY
475 and NEXTKEY implement the keys() and each() functions to iterate over all
476 the keys.  UNTIE is called when C<untie> happens, and DESTROY is called when
477 the tied variable is garbage collected.
478
479 If this seems like a lot, then feel free to inherit from merely the
480 standard Tie::StdHash module for most of your methods, redefining only the
481 interesting ones.  See L<Tie::Hash> for details.
482
483 Remember that Perl distinguishes between a key not existing in the hash,
484 and the key existing in the hash but having a corresponding value of
485 C<undef>.  The two possibilities can be tested with the C<exists()> and
486 C<defined()> functions.
487
488 Here's an example of a somewhat interesting tied hash class:  it gives you
489 a hash representing a particular user's dot files.  You index into the hash
490 with the name of the file (minus the dot) and you get back that dot file's
491 contents.  For example:
492
493     use DotFiles;
494     tie %dot, 'DotFiles';
495     if ( $dot{profile} =~ /MANPATH/ ||
496          $dot{login}   =~ /MANPATH/ ||
497          $dot{cshrc}   =~ /MANPATH/    )
498     {
499         print "you seem to set your MANPATH\n";
500     }
501
502 Or here's another sample of using our tied class:
503
504     tie %him, 'DotFiles', 'daemon';
505     foreach $f ( keys %him ) {
506         printf "daemon dot file %s is size %d\n",
507             $f, length $him{$f};
508     }
509
510 In our tied hash DotFiles example, we use a regular
511 hash for the object containing several important
512 fields, of which only the C<{LIST}> field will be what the
513 user thinks of as the real hash.
514
515 =over 5
516
517 =item USER
518
519 whose dot files this object represents
520
521 =item HOME
522
523 where those dot files live
524
525 =item CLOBBER
526
527 whether we should try to change or remove those dot files
528
529 =item LIST
530
531 the hash of dot file names and content mappings
532
533 =back
534
535 Here's the start of F<Dotfiles.pm>:
536
537     package DotFiles;
538     use Carp;
539     sub whowasi { (caller(1))[3] . '()' }
540     my $DEBUG = 0;
541     sub debug { $DEBUG = @_ ? shift : 1 }
542
543 For our example, we want to be able to emit debugging info to help in tracing
544 during development.  We keep also one convenience function around
545 internally to help print out warnings; whowasi() returns the function name
546 that calls it.
547
548 Here are the methods for the DotFiles tied hash.
549
550 =over 4
551
552 =item TIEHASH classname, LIST
553
554 This is the constructor for the class.  That means it is expected to
555 return a blessed reference through which the new object (probably but not
556 necessarily an anonymous hash) will be accessed.
557
558 Here's the constructor:
559
560     sub TIEHASH {
561         my $self = shift;
562         my $user = shift || $>;
563         my $dotdir = shift || '';
564         croak "usage: @{[&whowasi]} [USER [DOTDIR]]" if @_;
565         $user = getpwuid($user) if $user =~ /^\d+$/;
566         my $dir = (getpwnam($user))[7]
567                 || croak "@{[&whowasi]}: no user $user";
568         $dir .= "/$dotdir" if $dotdir;
569
570         my $node = {
571             USER    => $user,
572             HOME    => $dir,
573             LIST    => {},
574             CLOBBER => 0,
575         };
576
577         opendir(DIR, $dir)
578                 || croak "@{[&whowasi]}: can't opendir $dir: $!";
579         foreach $dot ( grep /^\./ && -f "$dir/$_", readdir(DIR)) {
580             $dot =~ s/^\.//;
581             $node->{LIST}{$dot} = undef;
582         }
583         closedir DIR;
584         return bless $node, $self;
585     }
586
587 It's probably worth mentioning that if you're going to filetest the
588 return values out of a readdir, you'd better prepend the directory
589 in question.  Otherwise, because we didn't chdir() there, it would
590 have been testing the wrong file.
591
592 =item FETCH this, key
593
594 This method will be triggered every time an element in the tied hash is
595 accessed (read).  It takes one argument beyond its self reference: the key
596 whose value we're trying to fetch.
597
598 Here's the fetch for our DotFiles example.
599
600     sub FETCH {
601         carp &whowasi if $DEBUG;
602         my $self = shift;
603         my $dot = shift;
604         my $dir = $self->{HOME};
605         my $file = "$dir/.$dot";
606
607         unless (exists $self->{LIST}->{$dot} || -f $file) {
608             carp "@{[&whowasi]}: no $dot file" if $DEBUG;
609             return undef;
610         }
611
612         if (defined $self->{LIST}->{$dot}) {
613             return $self->{LIST}->{$dot};
614         } else {
615             return $self->{LIST}->{$dot} = `cat $dir/.$dot`;
616         }
617     }
618
619 It was easy to write by having it call the Unix cat(1) command, but it
620 would probably be more portable to open the file manually (and somewhat
621 more efficient).  Of course, because dot files are a Unixy concept, we're
622 not that concerned.
623
624 =item STORE this, key, value
625
626 This method will be triggered every time an element in the tied hash is set
627 (written).  It takes two arguments beyond its self reference: the index at
628 which we're trying to store something, and the value we're trying to put
629 there.
630
631 Here in our DotFiles example, we'll be careful not to let
632 them try to overwrite the file unless they've called the clobber()
633 method on the original object reference returned by tie().
634
635     sub STORE {
636         carp &whowasi if $DEBUG;
637         my $self = shift;
638         my $dot = shift;
639         my $value = shift;
640         my $file = $self->{HOME} . "/.$dot";
641         my $user = $self->{USER};
642
643         croak "@{[&whowasi]}: $file not clobberable"
644             unless $self->{CLOBBER};
645
646         open(F, "> $file") || croak "can't open $file: $!";
647         print F $value;
648         close(F);
649     }
650
651 If they wanted to clobber something, they might say:
652
653     $ob = tie %daemon_dots, 'daemon';
654     $ob->clobber(1);
655     $daemon_dots{signature} = "A true daemon\n";
656
657 Another way to lay hands on a reference to the underlying object is to
658 use the tied() function, so they might alternately have set clobber
659 using:
660
661     tie %daemon_dots, 'daemon';
662     tied(%daemon_dots)->clobber(1);
663
664 The clobber method is simply:
665
666     sub clobber {
667         my $self = shift;
668         $self->{CLOBBER} = @_ ? shift : 1;
669     }
670
671 =item DELETE this, key
672
673 This method is triggered when we remove an element from the hash,
674 typically by using the delete() function.  Again, we'll
675 be careful to check whether they really want to clobber files.
676
677     sub DELETE   {
678         carp &whowasi if $DEBUG;
679
680         my $self = shift;
681         my $dot = shift;
682         my $file = $self->{HOME} . "/.$dot";
683         croak "@{[&whowasi]}: won't remove file $file"
684             unless $self->{CLOBBER};
685         delete $self->{LIST}->{$dot};
686         my $success = unlink($file);
687         carp "@{[&whowasi]}: can't unlink $file: $!" unless $success;
688         $success;
689     }
690
691 The value returned by DELETE becomes the return value of the call
692 to delete().  If you want to emulate the normal behavior of delete(),
693 you should return whatever FETCH would have returned for this key.
694 In this example, we have chosen instead to return a value which tells
695 the caller whether the file was successfully deleted.
696
697 =item CLEAR this
698
699 This method is triggered when the whole hash is to be cleared, usually by
700 assigning the empty list to it.
701
702 In our example, that would remove all the user's dot files!  It's such a
703 dangerous thing that they'll have to set CLOBBER to something higher than
704 1 to make it happen.
705
706     sub CLEAR    {
707         carp &whowasi if $DEBUG;
708         my $self = shift;
709         croak "@{[&whowasi]}: won't remove all dot files for $self->{USER}"
710             unless $self->{CLOBBER} > 1;
711         my $dot;
712         foreach $dot ( keys %{$self->{LIST}}) {
713             $self->DELETE($dot);
714         }
715     }
716
717 =item EXISTS this, key
718
719 This method is triggered when the user uses the exists() function
720 on a particular hash.  In our example, we'll look at the C<{LIST}>
721 hash element for this:
722
723     sub EXISTS   {
724         carp &whowasi if $DEBUG;
725         my $self = shift;
726         my $dot = shift;
727         return exists $self->{LIST}->{$dot};
728     }
729
730 =item FIRSTKEY this
731
732 This method will be triggered when the user is going
733 to iterate through the hash, such as via a keys() or each()
734 call.
735
736     sub FIRSTKEY {
737         carp &whowasi if $DEBUG;
738         my $self = shift;
739         my $a = keys %{$self->{LIST}};          # reset each() iterator
740         each %{$self->{LIST}}
741     }
742
743 =item NEXTKEY this, lastkey
744
745 This method gets triggered during a keys() or each() iteration.  It has a
746 second argument which is the last key that had been accessed.  This is
747 useful if you're carrying about ordering or calling the iterator from more
748 than one sequence, or not really storing things in a hash anywhere.
749
750 For our example, we're using a real hash so we'll do just the simple
751 thing, but we'll have to go through the LIST field indirectly.
752
753     sub NEXTKEY  {
754         carp &whowasi if $DEBUG;
755         my $self = shift;
756         return each %{ $self->{LIST} }
757     }
758
759 =item UNTIE this
760
761 This is called when C<untie> occurs.  See L<The C<untie> Gotcha> below.
762
763 =item DESTROY this
764
765 This method is triggered when a tied hash is about to go out of
766 scope.  You don't really need it unless you're trying to add debugging
767 or have auxiliary state to clean up.  Here's a very simple function:
768
769     sub DESTROY  {
770         carp &whowasi if $DEBUG;
771     }
772
773 =back
774
775 Note that functions such as keys() and values() may return huge lists
776 when used on large objects, like DBM files.  You may prefer to use the
777 each() function to iterate over such.  Example:
778
779     # print out history file offsets
780     use NDBM_File;
781     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
782     while (($key,$val) = each %HIST) {
783         print $key, ' = ', unpack('L',$val), "\n";
784     }
785     untie(%HIST);
786
787 =head2 Tying FileHandles
788
789 This is partially implemented now.
790
791 A class implementing a tied filehandle should define the following
792 methods: TIEHANDLE, at least one of PRINT, PRINTF, WRITE, READLINE, GETC,
793 READ, and possibly CLOSE, UNTIE and DESTROY.  The class can also provide: BINMODE,
794 OPEN, EOF, FILENO, SEEK, TELL - if the corresponding perl operators are
795 used on the handle.
796
797 When STDERR is tied, its PRINT method will be called to issue warnings
798 and error messages.  This feature is temporarily disabled during the call, 
799 which means you can use C<warn()> inside PRINT without starting a recursive
800 loop.  And just like C<__WARN__> and C<__DIE__> handlers, STDERR's PRINT
801 method may be called to report parser errors, so the caveats mentioned under 
802 L<perlvar/%SIG> apply.
803
804 All of this is especially useful when perl is embedded in some other 
805 program, where output to STDOUT and STDERR may have to be redirected 
806 in some special way.  See nvi and the Apache module for examples.
807
808 In our example we're going to create a shouting handle.
809
810     package Shout;
811
812 =over 4
813
814 =item TIEHANDLE classname, LIST
815
816 This is the constructor for the class.  That means it is expected to
817 return a blessed reference of some sort. The reference can be used to
818 hold some internal information.
819
820     sub TIEHANDLE { print "<shout>\n"; my $i; bless \$i, shift }
821
822 =item WRITE this, LIST
823
824 This method will be called when the handle is written to via the
825 C<syswrite> function.
826
827     sub WRITE {
828         $r = shift;
829         my($buf,$len,$offset) = @_;
830         print "WRITE called, \$buf=$buf, \$len=$len, \$offset=$offset";
831     }
832
833 =item PRINT this, LIST
834
835 This method will be triggered every time the tied handle is printed to
836 with the C<print()> function.
837 Beyond its self reference it also expects the list that was passed to
838 the print function.
839
840     sub PRINT { $r = shift; $$r++; print join($,,map(uc($_),@_)),$\ }
841
842 =item PRINTF this, LIST
843
844 This method will be triggered every time the tied handle is printed to
845 with the C<printf()> function.
846 Beyond its self reference it also expects the format and list that was
847 passed to the printf function.
848
849     sub PRINTF {
850         shift;
851         my $fmt = shift;
852         print sprintf($fmt, @_)."\n";
853     }
854
855 =item READ this, LIST
856
857 This method will be called when the handle is read from via the C<read>
858 or C<sysread> functions.
859
860     sub READ {
861         my $self = shift;
862         my $bufref = \$_[0];
863         my(undef,$len,$offset) = @_;
864         print "READ called, \$buf=$bufref, \$len=$len, \$offset=$offset";
865         # add to $$bufref, set $len to number of characters read
866         $len;
867     }
868
869 =item READLINE this
870
871 This method will be called when the handle is read from via <HANDLE>.
872 The method should return undef when there is no more data.
873
874     sub READLINE { $r = shift; "READLINE called $$r times\n"; }
875
876 =item GETC this
877
878 This method will be called when the C<getc> function is called.
879
880     sub GETC { print "Don't GETC, Get Perl"; return "a"; }
881
882 =item CLOSE this
883
884 This method will be called when the handle is closed via the C<close>
885 function.
886
887     sub CLOSE { print "CLOSE called.\n" }
888
889 =item UNTIE this
890
891 As with the other types of ties, this method will be called when C<untie> happens.
892 It may be appropriate to "auto CLOSE" when this occurs.  See
893 L<The C<untie> Gotcha> below.
894
895 =item DESTROY this
896
897 As with the other types of ties, this method will be called when the
898 tied handle is about to be destroyed. This is useful for debugging and
899 possibly cleaning up.
900
901     sub DESTROY { print "</shout>\n" }
902
903 =back
904
905 Here's how to use our little example:
906
907     tie(*FOO,'Shout');
908     print FOO "hello\n";
909     $a = 4; $b = 6;
910     print FOO $a, " plus ", $b, " equals ", $a + $b, "\n";
911     print <FOO>;
912
913 =head2 UNTIE this
914
915 You can define for all tie types an UNTIE method that will be called
916 at untie().  See L<The C<untie> Gotcha> below.
917
918 =head2 The C<untie> Gotcha
919
920 If you intend making use of the object returned from either tie() or
921 tied(), and if the tie's target class defines a destructor, there is a
922 subtle gotcha you I<must> guard against.
923
924 As setup, consider this (admittedly rather contrived) example of a
925 tie; all it does is use a file to keep a log of the values assigned to
926 a scalar.
927
928     package Remember;
929
930     use strict;
931     use warnings;
932     use IO::File;
933
934     sub TIESCALAR {
935         my $class = shift;
936         my $filename = shift;
937         my $handle = new IO::File "> $filename"
938                          or die "Cannot open $filename: $!\n";
939
940         print $handle "The Start\n";
941         bless {FH => $handle, Value => 0}, $class;
942     }
943
944     sub FETCH {
945         my $self = shift;
946         return $self->{Value};
947     }
948
949     sub STORE {
950         my $self = shift;
951         my $value = shift;
952         my $handle = $self->{FH};
953         print $handle "$value\n";
954         $self->{Value} = $value;
955     }
956
957     sub DESTROY {
958         my $self = shift;
959         my $handle = $self->{FH};
960         print $handle "The End\n";
961         close $handle;
962     }
963
964     1;
965
966 Here is an example that makes use of this tie:
967
968     use strict;
969     use Remember;
970
971     my $fred;
972     tie $fred, 'Remember', 'myfile.txt';
973     $fred = 1;
974     $fred = 4;
975     $fred = 5;
976     untie $fred;
977     system "cat myfile.txt";
978
979 This is the output when it is executed:
980
981     The Start
982     1
983     4
984     5
985     The End
986
987 So far so good.  Those of you who have been paying attention will have
988 spotted that the tied object hasn't been used so far.  So lets add an
989 extra method to the Remember class to allow comments to be included in
990 the file -- say, something like this:
991
992     sub comment {
993         my $self = shift;
994         my $text = shift;
995         my $handle = $self->{FH};
996         print $handle $text, "\n";
997     }
998
999 And here is the previous example modified to use the C<comment> method
1000 (which requires the tied object):
1001
1002     use strict;
1003     use Remember;
1004
1005     my ($fred, $x);
1006     $x = tie $fred, 'Remember', 'myfile.txt';
1007     $fred = 1;
1008     $fred = 4;
1009     comment $x "changing...";
1010     $fred = 5;
1011     untie $fred;
1012     system "cat myfile.txt";
1013
1014 When this code is executed there is no output.  Here's why:
1015
1016 When a variable is tied, it is associated with the object which is the
1017 return value of the TIESCALAR, TIEARRAY, or TIEHASH function.  This
1018 object normally has only one reference, namely, the implicit reference
1019 from the tied variable.  When untie() is called, that reference is
1020 destroyed.  Then, as in the first example above, the object's
1021 destructor (DESTROY) is called, which is normal for objects that have
1022 no more valid references; and thus the file is closed.
1023
1024 In the second example, however, we have stored another reference to
1025 the tied object in $x.  That means that when untie() gets called
1026 there will still be a valid reference to the object in existence, so
1027 the destructor is not called at that time, and thus the file is not
1028 closed.  The reason there is no output is because the file buffers
1029 have not been flushed to disk.
1030
1031 Now that you know what the problem is, what can you do to avoid it?
1032 Prior to the introduction of the optional UNTIE method the only way
1033 was the good old C<-w> flag. Which will spot any instances where you call
1034 untie() and there are still valid references to the tied object.  If
1035 the second script above this near the top C<use warnings 'untie'>
1036 or was run with the C<-w> flag, Perl prints this
1037 warning message:
1038
1039     untie attempted while 1 inner references still exist
1040
1041 To get the script to work properly and silence the warning make sure
1042 there are no valid references to the tied object I<before> untie() is
1043 called:
1044
1045     undef $x;
1046     untie $fred;
1047
1048 Now that UNTIE exists the class designer can decide which parts of the
1049 class functionality are really associated with C<untie> and which with
1050 the object being destroyed. What makes sense for a given class depends
1051 on whether the inner references are being kept so that non-tie-related
1052 methods can be called on the object. But in most cases it probably makes
1053 sense to move the functionality that would have been in DESTROY to the UNTIE
1054 method.
1055
1056 If the UNTIE method exists then the warning above does not occur. Instead the
1057 UNTIE method is passed the count of "extra" references and can issue its own
1058 warning if appropriate. e.g. to replicate the no UNTIE case this method can
1059 be used:
1060
1061     sub UNTIE
1062     {
1063      my ($obj,$count) = @_;
1064      carp "untie attempted while $count inner references still exist" if $count;
1065     }
1066
1067 =head1 SEE ALSO
1068
1069 See L<DB_File> or L<Config> for some interesting tie() implementations.
1070 A good starting point for many tie() implementations is with one of the
1071 modules L<Tie::Scalar>, L<Tie::Array>, L<Tie::Hash>, or L<Tie::Handle>.
1072
1073 =head1 BUGS
1074
1075 You cannot easily tie a multilevel data structure (such as a hash of
1076 hashes) to a dbm file.  The first problem is that all but GDBM and
1077 Berkeley DB have size limitations, but beyond that, you also have problems
1078 with how references are to be represented on disk.  One experimental
1079 module that does attempt to address this need partially is the MLDBM
1080 module.  Check your nearest CPAN site as described in L<perlmodlib> for
1081 source code to MLDBM.
1082
1083 Tied filehandles are still incomplete.  sysopen(), truncate(),
1084 flock(), fcntl(), stat() and -X can't currently be trapped.
1085
1086 The bucket usage information provided by C<scalar(%hash)> is not
1087 available.  If C<%hash> is tied, this will currently result in a
1088 fatal error.
1089
1090 Counting the number of entries in a hash via C<scalar(keys(%hash))> or
1091 C<scalar(values(%hash)>) is inefficient since it needs to iterate
1092 through all the entries with FIRSTKEY/NEXTKEY.
1093
1094 =head1 AUTHOR
1095
1096 Tom Christiansen
1097
1098 TIEHANDLE by Sven Verdoolaege <F<skimo@dns.ufsia.ac.be>> and Doug MacEachern <F<dougm@osf.org>>
1099
1100 UNTIE by Nick Ing-Simmons <F<nick@ing-simmons.net>>
1101
1102 Tying Arrays by Casey West <F<casey@geeknest.com>>