This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
8efe7cc1821333c600e85cff3650b92d716869a0
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
140 C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<sockatmark>, C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<sockatmark>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item I<-X> FILEHANDLE
250
251 =item I<-X> EXPR
252
253 =item I<-X>
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Age of file in days when script started.
298     -A  Same for access time.
299     -C  Same for inode change time.
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  Example:
354
355     print "Can do.\n" if -r $a || -w _ || -x _;
356
357     stat($filename);
358     print "Readable\n" if -r _;
359     print "Writable\n" if -w _;
360     print "Executable\n" if -x _;
361     print "Setuid\n" if -u _;
362     print "Setgid\n" if -g _;
363     print "Sticky\n" if -k _;
364     print "Text\n" if -T _;
365     print "Binary\n" if -B _;
366
367 =item abs VALUE
368
369 =item abs
370
371 Returns the absolute value of its argument.
372 If VALUE is omitted, uses C<$_>.
373
374 =item accept NEWSOCKET,GENERICSOCKET
375
376 Accepts an incoming socket connect, just as the accept(2) system call
377 does.  Returns the packed address if it succeeded, false otherwise.
378 See the example in L<perlipc/"Sockets: Client/Server Communication">.
379
380 On systems that support a close-on-exec flag on files, the flag will
381 be set for the newly opened file descriptor, as determined by the
382 value of $^F.  See L<perlvar/$^F>.
383
384 =item alarm SECONDS
385
386 =item alarm
387
388 Arranges to have a SIGALRM delivered to this process after the
389 specified number of wallclock seconds have elapsed.  If SECONDS is not
390 specified, the value stored in C<$_> is used. (On some machines,
391 unfortunately, the elapsed time may be up to one second less or more
392 than you specified because of how seconds are counted, and process
393 scheduling may delay the delivery of the signal even further.)
394
395 Only one timer may be counting at once.  Each call disables the
396 previous timer, and an argument of C<0> may be supplied to cancel the
397 previous timer without starting a new one.  The returned value is the
398 amount of time remaining on the previous timer.
399
400 For delays of finer granularity than one second, you may use Perl's
401 four-argument version of select() leaving the first three arguments
402 undefined, or you might be able to use the C<syscall> interface to
403 access setitimer(2) if your system supports it.  The Time::HiRes
404 module (from CPAN, and starting from Perl 5.8 part of the standard
405 distribution) may also prove useful.
406
407 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
408 (C<sleep> may be internally implemented in your system with C<alarm>)
409
410 If you want to use C<alarm> to time out a system call you need to use an
411 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
412 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
413 restart system calls on some systems.  Using C<eval>/C<die> always works,
414 modulo the caveats given in L<perlipc/"Signals">.
415
416     eval {
417         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
418         alarm $timeout;
419         $nread = sysread SOCKET, $buffer, $size;
420         alarm 0;
421     };
422     if ($@) {
423         die unless $@ eq "alarm\n";   # propagate unexpected errors
424         # timed out
425     }
426     else {
427         # didn't
428     }
429
430 =item atan2 Y,X
431
432 Returns the arctangent of Y/X in the range -PI to PI.
433
434 For the tangent operation, you may use the C<Math::Trig::tan>
435 function, or use the familiar relation:
436
437     sub tan { sin($_[0]) / cos($_[0])  }
438
439 =item bind SOCKET,NAME
440
441 Binds a network address to a socket, just as the bind system call
442 does.  Returns true if it succeeded, false otherwise.  NAME should be a
443 packed address of the appropriate type for the socket.  See the examples in
444 L<perlipc/"Sockets: Client/Server Communication">.
445
446 =item binmode FILEHANDLE, DISCIPLINE
447
448 =item binmode FILEHANDLE
449
450 Arranges for FILEHANDLE to be read or written in "binary" or "text" mode
451 on systems where the run-time libraries distinguish between binary and
452 text files.  If FILEHANDLE is an expression, the value is taken as the
453 name of the filehandle.  DISCIPLINE can be either of C<:raw> for
454 binary mode or C<:crlf> for "text" mode.  If the DISCIPLINE is
455 omitted, it defaults to C<:raw>.  Returns true on success, C<undef> on
456 failure.  The C<:raw> are C<:clrf>, and any other directives of the
457 form C<:...>, are called I/O I<disciplines>.
458
459 The C<open> pragma can be used to establish default I/O disciplines.
460 See L<open>.
461
462 In general, binmode() should be called after open() but before any I/O
463 is done on the filehandle.  Calling binmode() will flush any possibly
464 pending buffered input or output data on the handle.  The only
465 exception to this is the C<:encoding> discipline that changes
466 the default character encoding of the handle, see L<open>.
467 The C<:encoding> discipline sometimes needs to be called in
468 mid-stream, and it doesn't flush the stream.
469
470 On some systems binmode() is necessary when you're not working with a
471 text file.  For the sake of portability it is a good idea to always use
472 it when appropriate, and to never use it when it isn't appropriate.
473
474 In other words:  Regardless of platform, use binmode() on binary
475 files, and do not use binmode() on text files.
476
477 The operating system, device drivers, C libraries, and Perl run-time
478 system all work together to let the programmer treat a single
479 character (C<\n>) as the line terminator, irrespective of the external
480 representation.  On many operating systems, the native text file
481 representation matches the internal representation, but on some
482 platforms the external representation of C<\n> is made up of more than
483 one character.
484
485 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
486 character to end each line in the external representation of text (even
487 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
488 on Unix and most VMS files).  Consequently binmode() has no effect on
489 these operating systems.  In other systems like OS/2, DOS and the various
490 flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>, but
491 what's stored in text files are the two characters C<\cM\cJ>.  That means
492 that, if you don't use binmode() on these systems, C<\cM\cJ> sequences on
493 disk will be converted to C<\n> on input, and any C<\n> in your program
494 will be converted back to C<\cM\cJ> on output.  This is what you want for
495 text files, but it can be disastrous for binary files.
496
497 Another consequence of using binmode() (on some systems) is that
498 special end-of-file markers will be seen as part of the data stream.
499 For systems from the Microsoft family this means that if your binary
500 data contains C<\cZ>, the I/O subsystem will regard it as the end of
501 the file, unless you use binmode().
502
503 binmode() is not only important for readline() and print() operations,
504 but also when using read(), seek(), sysread(), syswrite() and tell()
505 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
506 in L<perlvar> for how to manually set your input and output
507 line-termination sequences.
508
509 =item bless REF,CLASSNAME
510
511 =item bless REF
512
513 This function tells the thingy referenced by REF that it is now an object
514 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
515 is used.  Because a C<bless> is often the last thing in a constructor,
516 it returns the reference for convenience.  Always use the two-argument
517 version if the function doing the blessing might be inherited by a
518 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
519 (and blessings) of objects.
520
521 Consider always blessing objects in CLASSNAMEs that are mixed case.
522 Namespaces with all lowercase names are considered reserved for
523 Perl pragmata.  Builtin types have all uppercase names, so to prevent
524 confusion, you may wish to avoid such package names as well.  Make sure
525 that CLASSNAME is a true value.
526
527 See L<perlmod/"Perl Modules">.
528
529 =item caller EXPR
530
531 =item caller
532
533 Returns the context of the current subroutine call.  In scalar context,
534 returns the caller's package name if there is a caller, that is, if
535 we're in a subroutine or C<eval> or C<require>, and the undefined value
536 otherwise.  In list context, returns
537
538     ($package, $filename, $line) = caller;
539
540 With EXPR, it returns some extra information that the debugger uses to
541 print a stack trace.  The value of EXPR indicates how many call frames
542 to go back before the current one.
543
544     ($package, $filename, $line, $subroutine, $hasargs,
545     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
546
547 Here $subroutine may be C<(eval)> if the frame is not a subroutine
548 call, but an C<eval>.  In such a case additional elements $evaltext and
549 C<$is_require> are set: C<$is_require> is true if the frame is created by a
550 C<require> or C<use> statement, $evaltext contains the text of the
551 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
552 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
553 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
554 frame.  C<$hasargs> is true if a new instance of C<@_> was set up for the
555 frame.  C<$hints> and C<$bitmask> contain pragmatic hints that the caller
556 was compiled with.  The C<$hints> and C<$bitmask> values are subject to
557 change between versions of Perl, and are not meant for external use.
558
559 Furthermore, when called from within the DB package, caller returns more
560 detailed information: it sets the list variable C<@DB::args> to be the
561 arguments with which the subroutine was invoked.
562
563 Be aware that the optimizer might have optimized call frames away before
564 C<caller> had a chance to get the information.  That means that C<caller(N)>
565 might not return information about the call frame you expect it do, for
566 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
567 previous time C<caller> was called.
568
569 =item chdir EXPR
570
571 Changes the working directory to EXPR, if possible. If EXPR is omitted,
572 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
573 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
574 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
575 neither is set, C<chdir> does nothing. It returns true upon success,
576 false otherwise. See the example under C<die>.
577
578 =item chmod LIST
579
580 Changes the permissions of a list of files.  The first element of the
581 list must be the numerical mode, which should probably be an octal
582 number, and which definitely should I<not> a string of octal digits:
583 C<0644> is okay, C<'0644'> is not.  Returns the number of files
584 successfully changed.  See also L</oct>, if all you have is a string.
585
586     $cnt = chmod 0755, 'foo', 'bar';
587     chmod 0755, @executables;
588     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
589                                              # --w----r-T
590     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
591     $mode = 0644;   chmod $mode, 'foo';      # this is best
592
593 You can also import the symbolic C<S_I*> constants from the Fcntl
594 module:
595
596     use Fcntl ':mode';
597
598     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
599     # This is identical to the chmod 0755 of the above example.
600
601 =item chomp VARIABLE
602
603 =item chomp( LIST )
604
605 =item chomp
606
607 This safer version of L</chop> removes any trailing string
608 that corresponds to the current value of C<$/> (also known as
609 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
610 number of characters removed from all its arguments.  It's often used to
611 remove the newline from the end of an input record when you're worried
612 that the final record may be missing its newline.  When in paragraph
613 mode (C<$/ = "">), it removes all trailing newlines from the string.
614 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
615 a reference to an integer or the like, see L<perlvar>) chomp() won't
616 remove anything.
617 If VARIABLE is omitted, it chomps C<$_>.  Example:
618
619     while (<>) {
620         chomp;  # avoid \n on last field
621         @array = split(/:/);
622         # ...
623     }
624
625 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
626
627 You can actually chomp anything that's an lvalue, including an assignment:
628
629     chomp($cwd = `pwd`);
630     chomp($answer = <STDIN>);
631
632 If you chomp a list, each element is chomped, and the total number of
633 characters removed is returned.
634
635 =item chop VARIABLE
636
637 =item chop( LIST )
638
639 =item chop
640
641 Chops off the last character of a string and returns the character
642 chopped.  It is much more efficient than C<s/.$//s> because it neither
643 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
644 If VARIABLE is a hash, it chops the hash's values, but not its keys.
645
646 You can actually chop anything that's an lvalue, including an assignment.
647
648 If you chop a list, each element is chopped.  Only the value of the
649 last C<chop> is returned.
650
651 Note that C<chop> returns the last character.  To return all but the last
652 character, use C<substr($string, 0, -1)>.
653
654 =item chown LIST
655
656 Changes the owner (and group) of a list of files.  The first two
657 elements of the list must be the I<numeric> uid and gid, in that
658 order.  A value of -1 in either position is interpreted by most
659 systems to leave that value unchanged.  Returns the number of files
660 successfully changed.
661
662     $cnt = chown $uid, $gid, 'foo', 'bar';
663     chown $uid, $gid, @filenames;
664
665 Here's an example that looks up nonnumeric uids in the passwd file:
666
667     print "User: ";
668     chomp($user = <STDIN>);
669     print "Files: ";
670     chomp($pattern = <STDIN>);
671
672     ($login,$pass,$uid,$gid) = getpwnam($user)
673         or die "$user not in passwd file";
674
675     @ary = glob($pattern);      # expand filenames
676     chown $uid, $gid, @ary;
677
678 On most systems, you are not allowed to change the ownership of the
679 file unless you're the superuser, although you should be able to change
680 the group to any of your secondary groups.  On insecure systems, these
681 restrictions may be relaxed, but this is not a portable assumption.
682 On POSIX systems, you can detect this condition this way:
683
684     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
685     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
686
687 =item chr NUMBER
688
689 =item chr
690
691 Returns the character represented by that NUMBER in the character set.
692 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
693 chr(0x263a) is a Unicode smiley face.  Note that characters from 127
694 to 255 (inclusive) are by default not encoded in Unicode for backward
695 compatibility reasons (but see L<encoding>).
696
697 For the reverse, use L</ord>.
698 See L<perlunicode> and L<encoding> for more about Unicode.
699
700 If NUMBER is omitted, uses C<$_>.
701
702 =item chroot FILENAME
703
704 =item chroot
705
706 This function works like the system call by the same name: it makes the
707 named directory the new root directory for all further pathnames that
708 begin with a C</> by your process and all its children.  (It doesn't
709 change your current working directory, which is unaffected.)  For security
710 reasons, this call is restricted to the superuser.  If FILENAME is
711 omitted, does a C<chroot> to C<$_>.
712
713 =item close FILEHANDLE
714
715 =item close
716
717 Closes the file or pipe associated with the file handle, returning
718 true only if IO buffers are successfully flushed and closes the system
719 file descriptor.  Closes the currently selected filehandle if the
720 argument is omitted.
721
722 You don't have to close FILEHANDLE if you are immediately going to do
723 another C<open> on it, because C<open> will close it for you.  (See
724 C<open>.)  However, an explicit C<close> on an input file resets the line
725 counter (C<$.>), while the implicit close done by C<open> does not.
726
727 If the file handle came from a piped open C<close> will additionally
728 return false if one of the other system calls involved fails or if the
729 program exits with non-zero status.  (If the only problem was that the
730 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe
731 also waits for the process executing on the pipe to complete, in case you
732 want to look at the output of the pipe afterwards, and
733 implicitly puts the exit status value of that command into C<$?>.
734
735 Prematurely closing the read end of a pipe (i.e. before the process
736 writing to it at the other end has closed it) will result in a
737 SIGPIPE being delivered to the writer.  If the other end can't
738 handle that, be sure to read all the data before closing the pipe.
739
740 Example:
741
742     open(OUTPUT, '|sort >foo')  # pipe to sort
743         or die "Can't start sort: $!";
744     #...                        # print stuff to output
745     close OUTPUT                # wait for sort to finish
746         or warn $! ? "Error closing sort pipe: $!"
747                    : "Exit status $? from sort";
748     open(INPUT, 'foo')          # get sort's results
749         or die "Can't open 'foo' for input: $!";
750
751 FILEHANDLE may be an expression whose value can be used as an indirect
752 filehandle, usually the real filehandle name.
753
754 =item closedir DIRHANDLE
755
756 Closes a directory opened by C<opendir> and returns the success of that
757 system call.
758
759 DIRHANDLE may be an expression whose value can be used as an indirect
760 dirhandle, usually the real dirhandle name.
761
762 =item connect SOCKET,NAME
763
764 Attempts to connect to a remote socket, just as the connect system call
765 does.  Returns true if it succeeded, false otherwise.  NAME should be a
766 packed address of the appropriate type for the socket.  See the examples in
767 L<perlipc/"Sockets: Client/Server Communication">.
768
769 =item continue BLOCK
770
771 Actually a flow control statement rather than a function.  If there is a
772 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
773 C<foreach>), it is always executed just before the conditional is about to
774 be evaluated again, just like the third part of a C<for> loop in C.  Thus
775 it can be used to increment a loop variable, even when the loop has been
776 continued via the C<next> statement (which is similar to the C C<continue>
777 statement).
778
779 C<last>, C<next>, or C<redo> may appear within a C<continue>
780 block.  C<last> and C<redo> will behave as if they had been executed within
781 the main block.  So will C<next>, but since it will execute a C<continue>
782 block, it may be more entertaining.
783
784     while (EXPR) {
785         ### redo always comes here
786         do_something;
787     } continue {
788         ### next always comes here
789         do_something_else;
790         # then back the top to re-check EXPR
791     }
792     ### last always comes here
793
794 Omitting the C<continue> section is semantically equivalent to using an
795 empty one, logically enough.  In that case, C<next> goes directly back
796 to check the condition at the top of the loop.
797
798 =item cos EXPR
799
800 =item cos
801
802 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
803 takes cosine of C<$_>.
804
805 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
806 function, or use this relation:
807
808     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
809
810 =item crypt PLAINTEXT,SALT
811
812 Encrypts a string exactly like the crypt(3) function in the C library
813 (assuming that you actually have a version there that has not been
814 extirpated as a potential munition).  This can prove useful for checking
815 the password file for lousy passwords, amongst other things.  Only the
816 guys wearing white hats should do this.
817
818 Note that C<crypt> is intended to be a one-way function, much like
819 breaking eggs to make an omelette.  There is no (known) corresponding
820 decrypt function (in other words, the crypt() is a one-way hash
821 function).  As a result, this function isn't all that useful for
822 cryptography.  (For that, see your nearby CPAN mirror.)
823
824 When verifying an existing encrypted string you should use the
825 encrypted text as the salt (like C<crypt($plain, $crypted) eq
826 $crypted>).  This allows your code to work with the standard C<crypt>
827 and with more exotic implementations.  In other words, do not assume
828 anything about the returned string itself, or how many bytes in
829 the encrypted string matter.
830
831 Traditionally the result is a string of 13 bytes: two first bytes of
832 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
833 the first eight bytes of the encrypted string mattered, but
834 alternative hashing schemes (like MD5), higher level security schemes
835 (like C2), and implementations on non-UNIX platforms may produce
836 different strings.
837
838 When choosing a new salt create a random two character string whose
839 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
840 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
841
842 Here's an example that makes sure that whoever runs this program knows
843 their own password:
844
845     $pwd = (getpwuid($<))[1];
846
847     system "stty -echo";
848     print "Password: ";
849     chomp($word = <STDIN>);
850     print "\n";
851     system "stty echo";
852
853     if (crypt($word, $pwd) ne $pwd) {
854         die "Sorry...\n";
855     } else {
856         print "ok\n";
857     }
858
859 Of course, typing in your own password to whoever asks you
860 for it is unwise.
861
862 The L<crypt> function is unsuitable for encrypting large quantities
863 of data, not least of all because you can't get the information
864 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
865 on your favorite CPAN mirror for a slew of potentially useful
866 modules.
867
868 If using crypt() on a Unicode string (which I<potentially> has
869 characters with codepoints above 255), Perl tries to make sense
870 of the situation by trying to downgrade (a copy of the string)
871 the string back to an eight-bit byte string before calling crypt()
872 (on that copy).  If that works, good.  If not, crypt() dies with
873 C<Wide character in crypt>.
874
875 =item dbmclose HASH
876
877 [This function has been largely superseded by the C<untie> function.]
878
879 Breaks the binding between a DBM file and a hash.
880
881 =item dbmopen HASH,DBNAME,MASK
882
883 [This function has been largely superseded by the C<tie> function.]
884
885 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
886 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
887 argument is I<not> a filehandle, even though it looks like one).  DBNAME
888 is the name of the database (without the F<.dir> or F<.pag> extension if
889 any).  If the database does not exist, it is created with protection
890 specified by MASK (as modified by the C<umask>).  If your system supports
891 only the older DBM functions, you may perform only one C<dbmopen> in your
892 program.  In older versions of Perl, if your system had neither DBM nor
893 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
894 sdbm(3).
895
896 If you don't have write access to the DBM file, you can only read hash
897 variables, not set them.  If you want to test whether you can write,
898 either use file tests or try setting a dummy hash entry inside an C<eval>,
899 which will trap the error.
900
901 Note that functions such as C<keys> and C<values> may return huge lists
902 when used on large DBM files.  You may prefer to use the C<each>
903 function to iterate over large DBM files.  Example:
904
905     # print out history file offsets
906     dbmopen(%HIST,'/usr/lib/news/history',0666);
907     while (($key,$val) = each %HIST) {
908         print $key, ' = ', unpack('L',$val), "\n";
909     }
910     dbmclose(%HIST);
911
912 See also L<AnyDBM_File> for a more general description of the pros and
913 cons of the various dbm approaches, as well as L<DB_File> for a particularly
914 rich implementation.
915
916 You can control which DBM library you use by loading that library
917 before you call dbmopen():
918
919     use DB_File;
920     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
921         or die "Can't open netscape history file: $!";
922
923 =item defined EXPR
924
925 =item defined
926
927 Returns a Boolean value telling whether EXPR has a value other than
928 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
929 checked.
930
931 Many operations return C<undef> to indicate failure, end of file,
932 system error, uninitialized variable, and other exceptional
933 conditions.  This function allows you to distinguish C<undef> from
934 other values.  (A simple Boolean test will not distinguish among
935 C<undef>, zero, the empty string, and C<"0">, which are all equally
936 false.)  Note that since C<undef> is a valid scalar, its presence
937 doesn't I<necessarily> indicate an exceptional condition: C<pop>
938 returns C<undef> when its argument is an empty array, I<or> when the
939 element to return happens to be C<undef>.
940
941 You may also use C<defined(&func)> to check whether subroutine C<&func>
942 has ever been defined.  The return value is unaffected by any forward
943 declarations of C<&foo>.  Note that a subroutine which is not defined
944 may still be callable: its package may have an C<AUTOLOAD> method that
945 makes it spring into existence the first time that it is called -- see
946 L<perlsub>.
947
948 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
949 used to report whether memory for that aggregate has ever been
950 allocated.  This behavior may disappear in future versions of Perl.
951 You should instead use a simple test for size:
952
953     if (@an_array) { print "has array elements\n" }
954     if (%a_hash)   { print "has hash members\n"   }
955
956 When used on a hash element, it tells you whether the value is defined,
957 not whether the key exists in the hash.  Use L</exists> for the latter
958 purpose.
959
960 Examples:
961
962     print if defined $switch{'D'};
963     print "$val\n" while defined($val = pop(@ary));
964     die "Can't readlink $sym: $!"
965         unless defined($value = readlink $sym);
966     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
967     $debugging = 0 unless defined $debugging;
968
969 Note:  Many folks tend to overuse C<defined>, and then are surprised to
970 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
971 defined values.  For example, if you say
972
973     "ab" =~ /a(.*)b/;
974
975 The pattern match succeeds, and C<$1> is defined, despite the fact that it
976 matched "nothing".  But it didn't really match nothing--rather, it
977 matched something that happened to be zero characters long.  This is all
978 very above-board and honest.  When a function returns an undefined value,
979 it's an admission that it couldn't give you an honest answer.  So you
980 should use C<defined> only when you're questioning the integrity of what
981 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
982 what you want.
983
984 See also L</undef>, L</exists>, L</ref>.
985
986 =item delete EXPR
987
988 Given an expression that specifies a hash element, array element, hash slice,
989 or array slice, deletes the specified element(s) from the hash or array.
990 In the case of an array, if the array elements happen to be at the end,
991 the size of the array will shrink to the highest element that tests
992 true for exists() (or 0 if no such element exists).
993
994 Returns each element so deleted or the undefined value if there was no such
995 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
996 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
997 from a C<tie>d hash or array may not necessarily return anything.
998
999 Deleting an array element effectively returns that position of the array
1000 to its initial, uninitialized state.  Subsequently testing for the same
1001 element with exists() will return false.  Note that deleting array
1002 elements in the middle of an array will not shift the index of the ones
1003 after them down--use splice() for that.  See L</exists>.
1004
1005 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1006
1007     foreach $key (keys %HASH) {
1008         delete $HASH{$key};
1009     }
1010
1011     foreach $index (0 .. $#ARRAY) {
1012         delete $ARRAY[$index];
1013     }
1014
1015 And so do these:
1016
1017     delete @HASH{keys %HASH};
1018
1019     delete @ARRAY[0 .. $#ARRAY];
1020
1021 But both of these are slower than just assigning the empty list
1022 or undefining %HASH or @ARRAY:
1023
1024     %HASH = ();         # completely empty %HASH
1025     undef %HASH;        # forget %HASH ever existed
1026
1027     @ARRAY = ();        # completely empty @ARRAY
1028     undef @ARRAY;       # forget @ARRAY ever existed
1029
1030 Note that the EXPR can be arbitrarily complicated as long as the final
1031 operation is a hash element, array element,  hash slice, or array slice
1032 lookup:
1033
1034     delete $ref->[$x][$y]{$key};
1035     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1036
1037     delete $ref->[$x][$y][$index];
1038     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1039
1040 =item die LIST
1041
1042 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1043 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1044 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1045 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1046 an C<eval(),> the error message is stuffed into C<$@> and the
1047 C<eval> is terminated with the undefined value.  This makes
1048 C<die> the way to raise an exception.
1049
1050 Equivalent examples:
1051
1052     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1053     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1054
1055 If the value of EXPR does not end in a newline, the current script line
1056 number and input line number (if any) are also printed, and a newline
1057 is supplied.  Note that the "input line number" (also known as "chunk")
1058 is subject to whatever notion of "line" happens to be currently in
1059 effect, and is also available as the special variable C<$.>.
1060 See L<perlvar/"$/"> and L<perlvar/"$.">.
1061
1062 Hint: sometimes appending C<", stopped"> to your message
1063 will cause it to make better sense when the string C<"at foo line 123"> is
1064 appended.  Suppose you are running script "canasta".
1065
1066     die "/etc/games is no good";
1067     die "/etc/games is no good, stopped";
1068
1069 produce, respectively
1070
1071     /etc/games is no good at canasta line 123.
1072     /etc/games is no good, stopped at canasta line 123.
1073
1074 See also exit(), warn(), and the Carp module.
1075
1076 If LIST is empty and C<$@> already contains a value (typically from a
1077 previous eval) that value is reused after appending C<"\t...propagated">.
1078 This is useful for propagating exceptions:
1079
1080     eval { ... };
1081     die unless $@ =~ /Expected exception/;
1082
1083 If LIST is empty and C<$@> contains an object reference that has a
1084 C<PROPAGATE> method, that method will be called with additional file
1085 and line number parameters.  The return value replaces the value in
1086 C<$@>.  ie. as if C<<$@ = eval { $@->PROPAGATE(__FILE__, __LINE__) };>> 
1087 were called.
1088
1089 If C<$@> is empty then the string C<"Died"> is used.
1090
1091 die() can also be called with a reference argument.  If this happens to be
1092 trapped within an eval(), $@ contains the reference.  This behavior permits
1093 a more elaborate exception handling implementation using objects that
1094 maintain arbitrary state about the nature of the exception.  Such a scheme
1095 is sometimes preferable to matching particular string values of $@ using
1096 regular expressions.  Here's an example:
1097
1098     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1099     if ($@) {
1100         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1101             # handle Some::Module::Exception
1102         }
1103         else {
1104             # handle all other possible exceptions
1105         }
1106     }
1107
1108 Because perl will stringify uncaught exception messages before displaying
1109 them, you may want to overload stringification operations on such custom
1110 exception objects.  See L<overload> for details about that.
1111
1112 You can arrange for a callback to be run just before the C<die>
1113 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1114 handler will be called with the error text and can change the error
1115 message, if it sees fit, by calling C<die> again.  See
1116 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1117 L<"eval BLOCK"> for some examples.  Although this feature was meant
1118 to be run only right before your program was to exit, this is not
1119 currently the case--the C<$SIG{__DIE__}> hook is currently called
1120 even inside eval()ed blocks/strings!  If one wants the hook to do
1121 nothing in such situations, put
1122
1123         die @_ if $^S;
1124
1125 as the first line of the handler (see L<perlvar/$^S>).  Because
1126 this promotes strange action at a distance, this counterintuitive
1127 behavior may be fixed in a future release.
1128
1129 =item do BLOCK
1130
1131 Not really a function.  Returns the value of the last command in the
1132 sequence of commands indicated by BLOCK.  When modified by a loop
1133 modifier, executes the BLOCK once before testing the loop condition.
1134 (On other statements the loop modifiers test the conditional first.)
1135
1136 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1137 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1138 See L<perlsyn> for alternative strategies.
1139
1140 =item do SUBROUTINE(LIST)
1141
1142 A deprecated form of subroutine call.  See L<perlsub>.
1143
1144 =item do EXPR
1145
1146 Uses the value of EXPR as a filename and executes the contents of the
1147 file as a Perl script.  Its primary use is to include subroutines
1148 from a Perl subroutine library.
1149
1150     do 'stat.pl';
1151
1152 is just like
1153
1154     eval `cat stat.pl`;
1155
1156 except that it's more efficient and concise, keeps track of the current
1157 filename for error messages, searches the @INC libraries, and updates
1158 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1159 variables.  It also differs in that code evaluated with C<do FILENAME>
1160 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1161 same, however, in that it does reparse the file every time you call it,
1162 so you probably don't want to do this inside a loop.
1163
1164 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1165 error.  If C<do> can read the file but cannot compile it, it
1166 returns undef and sets an error message in C<$@>.   If the file is
1167 successfully compiled, C<do> returns the value of the last expression
1168 evaluated.
1169
1170 Note that inclusion of library modules is better done with the
1171 C<use> and C<require> operators, which also do automatic error checking
1172 and raise an exception if there's a problem.
1173
1174 You might like to use C<do> to read in a program configuration
1175 file.  Manual error checking can be done this way:
1176
1177     # read in config files: system first, then user
1178     for $file ("/share/prog/defaults.rc",
1179                "$ENV{HOME}/.someprogrc")
1180    {
1181         unless ($return = do $file) {
1182             warn "couldn't parse $file: $@" if $@;
1183             warn "couldn't do $file: $!"    unless defined $return;
1184             warn "couldn't run $file"       unless $return;
1185         }
1186     }
1187
1188 =item dump LABEL
1189
1190 =item dump
1191
1192 This function causes an immediate core dump.  See also the B<-u>
1193 command-line switch in L<perlrun>, which does the same thing.
1194 Primarily this is so that you can use the B<undump> program (not
1195 supplied) to turn your core dump into an executable binary after
1196 having initialized all your variables at the beginning of the
1197 program.  When the new binary is executed it will begin by executing
1198 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1199 Think of it as a goto with an intervening core dump and reincarnation.
1200 If C<LABEL> is omitted, restarts the program from the top.
1201
1202 B<WARNING>: Any files opened at the time of the dump will I<not>
1203 be open any more when the program is reincarnated, with possible
1204 resulting confusion on the part of Perl.
1205
1206 This function is now largely obsolete, partly because it's very
1207 hard to convert a core file into an executable, and because the
1208 real compiler backends for generating portable bytecode and compilable
1209 C code have superseded it.  That's why you should now invoke it as
1210 C<CORE::dump()>, if you don't want to be warned against a possible
1211 typo.
1212
1213 If you're looking to use L<dump> to speed up your program, consider
1214 generating bytecode or native C code as described in L<perlcc>.  If
1215 you're just trying to accelerate a CGI script, consider using the
1216 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1217 You might also consider autoloading or selfloading, which at least
1218 make your program I<appear> to run faster.
1219
1220 =item each HASH
1221
1222 When called in list context, returns a 2-element list consisting of the
1223 key and value for the next element of a hash, so that you can iterate over
1224 it.  When called in scalar context, returns only the key for the next
1225 element in the hash.
1226
1227 Entries are returned in an apparently random order.  The actual random
1228 order is subject to change in future versions of perl, but it is guaranteed
1229 to be in the same order as either the C<keys> or C<values> function
1230 would produce on the same (unmodified) hash.
1231
1232 When the hash is entirely read, a null array is returned in list context
1233 (which when assigned produces a false (C<0>) value), and C<undef> in
1234 scalar context.  The next call to C<each> after that will start iterating
1235 again.  There is a single iterator for each hash, shared by all C<each>,
1236 C<keys>, and C<values> function calls in the program; it can be reset by
1237 reading all the elements from the hash, or by evaluating C<keys HASH> or
1238 C<values HASH>.  If you add or delete elements of a hash while you're
1239 iterating over it, you may get entries skipped or duplicated, so
1240 don't.  Exception: It is always safe to delete the item most recently
1241 returned by C<each()>, which means that the following code will work:
1242
1243         while (($key, $value) = each %hash) {
1244           print $key, "\n";
1245           delete $hash{$key};   # This is safe
1246         }
1247
1248 The following prints out your environment like the printenv(1) program,
1249 only in a different order:
1250
1251     while (($key,$value) = each %ENV) {
1252         print "$key=$value\n";
1253     }
1254
1255 See also C<keys>, C<values> and C<sort>.
1256
1257 =item eof FILEHANDLE
1258
1259 =item eof ()
1260
1261 =item eof
1262
1263 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1264 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1265 gives the real filehandle.  (Note that this function actually
1266 reads a character and then C<ungetc>s it, so isn't very useful in an
1267 interactive context.)  Do not read from a terminal file (or call
1268 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1269 as terminals may lose the end-of-file condition if you do.
1270
1271 An C<eof> without an argument uses the last file read.  Using C<eof()>
1272 with empty parentheses is very different.  It refers to the pseudo file
1273 formed from the files listed on the command line and accessed via the
1274 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1275 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1276 used will cause C<@ARGV> to be examined to determine if input is
1277 available.
1278
1279 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1280 detect the end of each file, C<eof()> will only detect the end of the
1281 last file.  Examples:
1282
1283     # reset line numbering on each input file
1284     while (<>) {
1285         next if /^\s*#/;        # skip comments
1286         print "$.\t$_";
1287     } continue {
1288         close ARGV  if eof;     # Not eof()!
1289     }
1290
1291     # insert dashes just before last line of last file
1292     while (<>) {
1293         if (eof()) {            # check for end of current file
1294             print "--------------\n";
1295             close(ARGV);        # close or last; is needed if we
1296                                 # are reading from the terminal
1297         }
1298         print;
1299     }
1300
1301 Practical hint: you almost never need to use C<eof> in Perl, because the
1302 input operators typically return C<undef> when they run out of data, or if
1303 there was an error.
1304
1305 =item eval EXPR
1306
1307 =item eval BLOCK
1308
1309 In the first form, the return value of EXPR is parsed and executed as if it
1310 were a little Perl program.  The value of the expression (which is itself
1311 determined within scalar context) is first parsed, and if there weren't any
1312 errors, executed in the lexical context of the current Perl program, so
1313 that any variable settings or subroutine and format definitions remain
1314 afterwards.  Note that the value is parsed every time the eval executes.
1315 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1316 delay parsing and subsequent execution of the text of EXPR until run time.
1317
1318 In the second form, the code within the BLOCK is parsed only once--at the
1319 same time the code surrounding the eval itself was parsed--and executed
1320 within the context of the current Perl program.  This form is typically
1321 used to trap exceptions more efficiently than the first (see below), while
1322 also providing the benefit of checking the code within BLOCK at compile
1323 time.
1324
1325 The final semicolon, if any, may be omitted from the value of EXPR or within
1326 the BLOCK.
1327
1328 In both forms, the value returned is the value of the last expression
1329 evaluated inside the mini-program; a return statement may be also used, just
1330 as with subroutines.  The expression providing the return value is evaluated
1331 in void, scalar, or list context, depending on the context of the eval itself.
1332 See L</wantarray> for more on how the evaluation context can be determined.
1333
1334 If there is a syntax error or runtime error, or a C<die> statement is
1335 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1336 error message.  If there was no error, C<$@> is guaranteed to be a null
1337 string.  Beware that using C<eval> neither silences perl from printing
1338 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1339 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1340 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1341 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1342
1343 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1344 determining whether a particular feature (such as C<socket> or C<symlink>)
1345 is implemented.  It is also Perl's exception trapping mechanism, where
1346 the die operator is used to raise exceptions.
1347
1348 If the code to be executed doesn't vary, you may use the eval-BLOCK
1349 form to trap run-time errors without incurring the penalty of
1350 recompiling each time.  The error, if any, is still returned in C<$@>.
1351 Examples:
1352
1353     # make divide-by-zero nonfatal
1354     eval { $answer = $a / $b; }; warn $@ if $@;
1355
1356     # same thing, but less efficient
1357     eval '$answer = $a / $b'; warn $@ if $@;
1358
1359     # a compile-time error
1360     eval { $answer = };                 # WRONG
1361
1362     # a run-time error
1363     eval '$answer =';   # sets $@
1364
1365 Due to the current arguably broken state of C<__DIE__> hooks, when using
1366 the C<eval{}> form as an exception trap in libraries, you may wish not
1367 to trigger any C<__DIE__> hooks that user code may have installed.
1368 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1369 as shown in this example:
1370
1371     # a very private exception trap for divide-by-zero
1372     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1373     warn $@ if $@;
1374
1375 This is especially significant, given that C<__DIE__> hooks can call
1376 C<die> again, which has the effect of changing their error messages:
1377
1378     # __DIE__ hooks may modify error messages
1379     {
1380        local $SIG{'__DIE__'} =
1381               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1382        eval { die "foo lives here" };
1383        print $@ if $@;                # prints "bar lives here"
1384     }
1385
1386 Because this promotes action at a distance, this counterintuitive behavior
1387 may be fixed in a future release.
1388
1389 With an C<eval>, you should be especially careful to remember what's
1390 being looked at when:
1391
1392     eval $x;            # CASE 1
1393     eval "$x";          # CASE 2
1394
1395     eval '$x';          # CASE 3
1396     eval { $x };        # CASE 4
1397
1398     eval "\$$x++";      # CASE 5
1399     $$x++;              # CASE 6
1400
1401 Cases 1 and 2 above behave identically: they run the code contained in
1402 the variable $x.  (Although case 2 has misleading double quotes making
1403 the reader wonder what else might be happening (nothing is).)  Cases 3
1404 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1405 does nothing but return the value of $x.  (Case 4 is preferred for
1406 purely visual reasons, but it also has the advantage of compiling at
1407 compile-time instead of at run-time.)  Case 5 is a place where
1408 normally you I<would> like to use double quotes, except that in this
1409 particular situation, you can just use symbolic references instead, as
1410 in case 6.
1411
1412 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1413 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1414
1415 =item exec LIST
1416
1417 =item exec PROGRAM LIST
1418
1419 The C<exec> function executes a system command I<and never returns>--
1420 use C<system> instead of C<exec> if you want it to return.  It fails and
1421 returns false only if the command does not exist I<and> it is executed
1422 directly instead of via your system's command shell (see below).
1423
1424 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1425 warns you if there is a following statement which isn't C<die>, C<warn>,
1426 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1427 I<really> want to follow an C<exec> with some other statement, you
1428 can use one of these styles to avoid the warning:
1429
1430     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1431     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1432
1433 If there is more than one argument in LIST, or if LIST is an array
1434 with more than one value, calls execvp(3) with the arguments in LIST.
1435 If there is only one scalar argument or an array with one element in it,
1436 the argument is checked for shell metacharacters, and if there are any,
1437 the entire argument is passed to the system's command shell for parsing
1438 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1439 If there are no shell metacharacters in the argument, it is split into
1440 words and passed directly to C<execvp>, which is more efficient.
1441 Examples:
1442
1443     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1444     exec "sort $outfile | uniq";
1445
1446 If you don't really want to execute the first argument, but want to lie
1447 to the program you are executing about its own name, you can specify
1448 the program you actually want to run as an "indirect object" (without a
1449 comma) in front of the LIST.  (This always forces interpretation of the
1450 LIST as a multivalued list, even if there is only a single scalar in
1451 the list.)  Example:
1452
1453     $shell = '/bin/csh';
1454     exec $shell '-sh';          # pretend it's a login shell
1455
1456 or, more directly,
1457
1458     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1459
1460 When the arguments get executed via the system shell, results will
1461 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1462 for details.
1463
1464 Using an indirect object with C<exec> or C<system> is also more
1465 secure.  This usage (which also works fine with system()) forces
1466 interpretation of the arguments as a multivalued list, even if the
1467 list had just one argument.  That way you're safe from the shell
1468 expanding wildcards or splitting up words with whitespace in them.
1469
1470     @args = ( "echo surprise" );
1471
1472     exec @args;               # subject to shell escapes
1473                                 # if @args == 1
1474     exec { $args[0] } @args;  # safe even with one-arg list
1475
1476 The first version, the one without the indirect object, ran the I<echo>
1477 program, passing it C<"surprise"> an argument.  The second version
1478 didn't--it tried to run a program literally called I<"echo surprise">,
1479 didn't find it, and set C<$?> to a non-zero value indicating failure.
1480
1481 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1482 output before the exec, but this may not be supported on some platforms
1483 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1484 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1485 open handles in order to avoid lost output.
1486
1487 Note that C<exec> will not call your C<END> blocks, nor will it call
1488 any C<DESTROY> methods in your objects.
1489
1490 =item exists EXPR
1491
1492 Given an expression that specifies a hash element or array element,
1493 returns true if the specified element in the hash or array has ever
1494 been initialized, even if the corresponding value is undefined.  The
1495 element is not autovivified if it doesn't exist.
1496
1497     print "Exists\n"    if exists $hash{$key};
1498     print "Defined\n"   if defined $hash{$key};
1499     print "True\n"      if $hash{$key};
1500
1501     print "Exists\n"    if exists $array[$index];
1502     print "Defined\n"   if defined $array[$index];
1503     print "True\n"      if $array[$index];
1504
1505 A hash or array element can be true only if it's defined, and defined if
1506 it exists, but the reverse doesn't necessarily hold true.
1507
1508 Given an expression that specifies the name of a subroutine,
1509 returns true if the specified subroutine has ever been declared, even
1510 if it is undefined.  Mentioning a subroutine name for exists or defined
1511 does not count as declaring it.  Note that a subroutine which does not
1512 exist may still be callable: its package may have an C<AUTOLOAD>
1513 method that makes it spring into existence the first time that it is
1514 called -- see L<perlsub>.
1515
1516     print "Exists\n"    if exists &subroutine;
1517     print "Defined\n"   if defined &subroutine;
1518
1519 Note that the EXPR can be arbitrarily complicated as long as the final
1520 operation is a hash or array key lookup or subroutine name:
1521
1522     if (exists $ref->{A}->{B}->{$key})  { }
1523     if (exists $hash{A}{B}{$key})       { }
1524
1525     if (exists $ref->{A}->{B}->[$ix])   { }
1526     if (exists $hash{A}{B}[$ix])        { }
1527
1528     if (exists &{$ref->{A}{B}{$key}})   { }
1529
1530 Although the deepest nested array or hash will not spring into existence
1531 just because its existence was tested, any intervening ones will.
1532 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1533 into existence due to the existence test for the $key element above.
1534 This happens anywhere the arrow operator is used, including even:
1535
1536     undef $ref;
1537     if (exists $ref->{"Some key"})      { }
1538     print $ref;             # prints HASH(0x80d3d5c)
1539
1540 This surprising autovivification in what does not at first--or even
1541 second--glance appear to be an lvalue context may be fixed in a future
1542 release.
1543
1544 See L<perlref/"Pseudo-hashes: Using an array as a hash"> for specifics
1545 on how exists() acts when used on a pseudo-hash.
1546
1547 Use of a subroutine call, rather than a subroutine name, as an argument
1548 to exists() is an error.
1549
1550     exists &sub;        # OK
1551     exists &sub();      # Error
1552
1553 =item exit EXPR
1554
1555 Evaluates EXPR and exits immediately with that value.    Example:
1556
1557     $ans = <STDIN>;
1558     exit 0 if $ans =~ /^[Xx]/;
1559
1560 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1561 universally recognized values for EXPR are C<0> for success and C<1>
1562 for error; other values are subject to interpretation depending on the
1563 environment in which the Perl program is running.  For example, exiting
1564 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1565 the mailer to return the item undelivered, but that's not true everywhere.
1566
1567 Don't use C<exit> to abort a subroutine if there's any chance that
1568 someone might want to trap whatever error happened.  Use C<die> instead,
1569 which can be trapped by an C<eval>.
1570
1571 The exit() function does not always exit immediately.  It calls any
1572 defined C<END> routines first, but these C<END> routines may not
1573 themselves abort the exit.  Likewise any object destructors that need to
1574 be called are called before the real exit.  If this is a problem, you
1575 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1576 See L<perlmod> for details.
1577
1578 =item exp EXPR
1579
1580 =item exp
1581
1582 Returns I<e> (the natural logarithm base) to the power of EXPR.
1583 If EXPR is omitted, gives C<exp($_)>.
1584
1585 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1586
1587 Implements the fcntl(2) function.  You'll probably have to say
1588
1589     use Fcntl;
1590
1591 first to get the correct constant definitions.  Argument processing and
1592 value return works just like C<ioctl> below.
1593 For example:
1594
1595     use Fcntl;
1596     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1597         or die "can't fcntl F_GETFL: $!";
1598
1599 You don't have to check for C<defined> on the return from C<fnctl>.
1600 Like C<ioctl>, it maps a C<0> return from the system call into
1601 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1602 in numeric context.  It is also exempt from the normal B<-w> warnings
1603 on improper numeric conversions.
1604
1605 Note that C<fcntl> will produce a fatal error if used on a machine that
1606 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1607 manpage to learn what functions are available on your system.
1608
1609 =item fileno FILEHANDLE
1610
1611 Returns the file descriptor for a filehandle, or undefined if the
1612 filehandle is not open.  This is mainly useful for constructing
1613 bitmaps for C<select> and low-level POSIX tty-handling operations.
1614 If FILEHANDLE is an expression, the value is taken as an indirect
1615 filehandle, generally its name.
1616
1617 You can use this to find out whether two handles refer to the
1618 same underlying descriptor:
1619
1620     if (fileno(THIS) == fileno(THAT)) {
1621         print "THIS and THAT are dups\n";
1622     }
1623
1624 (Filehandles connected to memory objects via new features of C<open> may
1625 return undefined even though they are open.)
1626
1627
1628 =item flock FILEHANDLE,OPERATION
1629
1630 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1631 for success, false on failure.  Produces a fatal error if used on a
1632 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1633 C<flock> is Perl's portable file locking interface, although it locks
1634 only entire files, not records.
1635
1636 Two potentially non-obvious but traditional C<flock> semantics are
1637 that it waits indefinitely until the lock is granted, and that its locks
1638 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1639 fewer guarantees.  This means that files locked with C<flock> may be
1640 modified by programs that do not also use C<flock>.  See L<perlport>,
1641 your port's specific documentation, or your system-specific local manpages
1642 for details.  It's best to assume traditional behavior if you're writing
1643 portable programs.  (But if you're not, you should as always feel perfectly
1644 free to write for your own system's idiosyncrasies (sometimes called
1645 "features").  Slavish adherence to portability concerns shouldn't get
1646 in the way of your getting your job done.)
1647
1648 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1649 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1650 you can use the symbolic names if you import them from the Fcntl module,
1651 either individually, or as a group using the ':flock' tag.  LOCK_SH
1652 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1653 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1654 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1655 waiting for the lock (check the return status to see if you got it).
1656
1657 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1658 before locking or unlocking it.
1659
1660 Note that the emulation built with lockf(3) doesn't provide shared
1661 locks, and it requires that FILEHANDLE be open with write intent.  These
1662 are the semantics that lockf(3) implements.  Most if not all systems
1663 implement lockf(3) in terms of fcntl(2) locking, though, so the
1664 differing semantics shouldn't bite too many people.
1665
1666 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1667 be open with read intent to use LOCK_SH and requires that it be open
1668 with write intent to use LOCK_EX.
1669
1670 Note also that some versions of C<flock> cannot lock things over the
1671 network; you would need to use the more system-specific C<fcntl> for
1672 that.  If you like you can force Perl to ignore your system's flock(2)
1673 function, and so provide its own fcntl(2)-based emulation, by passing
1674 the switch C<-Ud_flock> to the F<Configure> program when you configure
1675 perl.
1676
1677 Here's a mailbox appender for BSD systems.
1678
1679     use Fcntl ':flock'; # import LOCK_* constants
1680
1681     sub lock {
1682         flock(MBOX,LOCK_EX);
1683         # and, in case someone appended
1684         # while we were waiting...
1685         seek(MBOX, 0, 2);
1686     }
1687
1688     sub unlock {
1689         flock(MBOX,LOCK_UN);
1690     }
1691
1692     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1693             or die "Can't open mailbox: $!";
1694
1695     lock();
1696     print MBOX $msg,"\n\n";
1697     unlock();
1698
1699 On systems that support a real flock(), locks are inherited across fork()
1700 calls, whereas those that must resort to the more capricious fcntl()
1701 function lose the locks, making it harder to write servers.
1702
1703 See also L<DB_File> for other flock() examples.
1704
1705 =item fork
1706
1707 Does a fork(2) system call to create a new process running the
1708 same program at the same point.  It returns the child pid to the
1709 parent process, C<0> to the child process, or C<undef> if the fork is
1710 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1711 are shared, while everything else is copied.  On most systems supporting
1712 fork(), great care has gone into making it extremely efficient (for
1713 example, using copy-on-write technology on data pages), making it the
1714 dominant paradigm for multitasking over the last few decades.
1715
1716 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1717 output before forking the child process, but this may not be supported
1718 on some platforms (see L<perlport>).  To be safe, you may need to set
1719 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1720 C<IO::Handle> on any open handles in order to avoid duplicate output.
1721
1722 If you C<fork> without ever waiting on your children, you will
1723 accumulate zombies.  On some systems, you can avoid this by setting
1724 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1725 forking and reaping moribund children.
1726
1727 Note that if your forked child inherits system file descriptors like
1728 STDIN and STDOUT that are actually connected by a pipe or socket, even
1729 if you exit, then the remote server (such as, say, a CGI script or a
1730 backgrounded job launched from a remote shell) won't think you're done.
1731 You should reopen those to F</dev/null> if it's any issue.
1732
1733 =item format
1734
1735 Declare a picture format for use by the C<write> function.  For
1736 example:
1737
1738     format Something =
1739         Test: @<<<<<<<< @||||| @>>>>>
1740               $str,     $%,    '$' . int($num)
1741     .
1742
1743     $str = "widget";
1744     $num = $cost/$quantity;
1745     $~ = 'Something';
1746     write;
1747
1748 See L<perlform> for many details and examples.
1749
1750 =item formline PICTURE,LIST
1751
1752 This is an internal function used by C<format>s, though you may call it,
1753 too.  It formats (see L<perlform>) a list of values according to the
1754 contents of PICTURE, placing the output into the format output
1755 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1756 Eventually, when a C<write> is done, the contents of
1757 C<$^A> are written to some filehandle, but you could also read C<$^A>
1758 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1759 does one C<formline> per line of form, but the C<formline> function itself
1760 doesn't care how many newlines are embedded in the PICTURE.  This means
1761 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1762 You may therefore need to use multiple formlines to implement a single
1763 record format, just like the format compiler.
1764
1765 Be careful if you put double quotes around the picture, because an C<@>
1766 character may be taken to mean the beginning of an array name.
1767 C<formline> always returns true.  See L<perlform> for other examples.
1768
1769 =item getc FILEHANDLE
1770
1771 =item getc
1772
1773 Returns the next character from the input file attached to FILEHANDLE,
1774 or the undefined value at end of file, or if there was an error.
1775 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1776 efficient.  However, it cannot be used by itself to fetch single
1777 characters without waiting for the user to hit enter.  For that, try
1778 something more like:
1779
1780     if ($BSD_STYLE) {
1781         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1782     }
1783     else {
1784         system "stty", '-icanon', 'eol', "\001";
1785     }
1786
1787     $key = getc(STDIN);
1788
1789     if ($BSD_STYLE) {
1790         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1791     }
1792     else {
1793         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1794     }
1795     print "\n";
1796
1797 Determination of whether $BSD_STYLE should be set
1798 is left as an exercise to the reader.
1799
1800 The C<POSIX::getattr> function can do this more portably on
1801 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1802 module from your nearest CPAN site; details on CPAN can be found on
1803 L<perlmodlib/CPAN>.
1804
1805 =item getlogin
1806
1807 Implements the C library function of the same name, which on most
1808 systems returns the current login from F</etc/utmp>, if any.  If null,
1809 use C<getpwuid>.
1810
1811     $login = getlogin || getpwuid($<) || "Kilroy";
1812
1813 Do not consider C<getlogin> for authentication: it is not as
1814 secure as C<getpwuid>.
1815
1816 =item getpeername SOCKET
1817
1818 Returns the packed sockaddr address of other end of the SOCKET connection.
1819
1820     use Socket;
1821     $hersockaddr    = getpeername(SOCK);
1822     ($port, $iaddr) = sockaddr_in($hersockaddr);
1823     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1824     $herstraddr     = inet_ntoa($iaddr);
1825
1826 =item getpgrp PID
1827
1828 Returns the current process group for the specified PID.  Use
1829 a PID of C<0> to get the current process group for the
1830 current process.  Will raise an exception if used on a machine that
1831 doesn't implement getpgrp(2).  If PID is omitted, returns process
1832 group of current process.  Note that the POSIX version of C<getpgrp>
1833 does not accept a PID argument, so only C<PID==0> is truly portable.
1834
1835 =item getppid
1836
1837 Returns the process id of the parent process.
1838
1839 =item getpriority WHICH,WHO
1840
1841 Returns the current priority for a process, a process group, or a user.
1842 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1843 machine that doesn't implement getpriority(2).
1844
1845 =item getpwnam NAME
1846
1847 =item getgrnam NAME
1848
1849 =item gethostbyname NAME
1850
1851 =item getnetbyname NAME
1852
1853 =item getprotobyname NAME
1854
1855 =item getpwuid UID
1856
1857 =item getgrgid GID
1858
1859 =item getservbyname NAME,PROTO
1860
1861 =item gethostbyaddr ADDR,ADDRTYPE
1862
1863 =item getnetbyaddr ADDR,ADDRTYPE
1864
1865 =item getprotobynumber NUMBER
1866
1867 =item getservbyport PORT,PROTO
1868
1869 =item getpwent
1870
1871 =item getgrent
1872
1873 =item gethostent
1874
1875 =item getnetent
1876
1877 =item getprotoent
1878
1879 =item getservent
1880
1881 =item setpwent
1882
1883 =item setgrent
1884
1885 =item sethostent STAYOPEN
1886
1887 =item setnetent STAYOPEN
1888
1889 =item setprotoent STAYOPEN
1890
1891 =item setservent STAYOPEN
1892
1893 =item endpwent
1894
1895 =item endgrent
1896
1897 =item endhostent
1898
1899 =item endnetent
1900
1901 =item endprotoent
1902
1903 =item endservent
1904
1905 These routines perform the same functions as their counterparts in the
1906 system library.  In list context, the return values from the
1907 various get routines are as follows:
1908
1909     ($name,$passwd,$uid,$gid,
1910        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1911     ($name,$passwd,$gid,$members) = getgr*
1912     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1913     ($name,$aliases,$addrtype,$net) = getnet*
1914     ($name,$aliases,$proto) = getproto*
1915     ($name,$aliases,$port,$proto) = getserv*
1916
1917 (If the entry doesn't exist you get a null list.)
1918
1919 The exact meaning of the $gcos field varies but it usually contains
1920 the real name of the user (as opposed to the login name) and other
1921 information pertaining to the user.  Beware, however, that in many
1922 system users are able to change this information and therefore it
1923 cannot be trusted and therefore the $gcos is tainted (see
1924 L<perlsec>).  The $passwd and $shell, user's encrypted password and
1925 login shell, are also tainted, because of the same reason.
1926
1927 In scalar context, you get the name, unless the function was a
1928 lookup by name, in which case you get the other thing, whatever it is.
1929 (If the entry doesn't exist you get the undefined value.)  For example:
1930
1931     $uid   = getpwnam($name);
1932     $name  = getpwuid($num);
1933     $name  = getpwent();
1934     $gid   = getgrnam($name);
1935     $name  = getgrgid($num;
1936     $name  = getgrent();
1937     #etc.
1938
1939 In I<getpw*()> the fields $quota, $comment, and $expire are special
1940 cases in the sense that in many systems they are unsupported.  If the
1941 $quota is unsupported, it is an empty scalar.  If it is supported, it
1942 usually encodes the disk quota.  If the $comment field is unsupported,
1943 it is an empty scalar.  If it is supported it usually encodes some
1944 administrative comment about the user.  In some systems the $quota
1945 field may be $change or $age, fields that have to do with password
1946 aging.  In some systems the $comment field may be $class.  The $expire
1947 field, if present, encodes the expiration period of the account or the
1948 password.  For the availability and the exact meaning of these fields
1949 in your system, please consult your getpwnam(3) documentation and your
1950 F<pwd.h> file.  You can also find out from within Perl what your
1951 $quota and $comment fields mean and whether you have the $expire field
1952 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1953 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
1954 files are only supported if your vendor has implemented them in the
1955 intuitive fashion that calling the regular C library routines gets the
1956 shadow versions if you're running under privilege or if there exists
1957 the shadow(3) functions as found in System V ( this includes Solaris
1958 and Linux.)  Those systems which implement a proprietary shadow password
1959 facility are unlikely to be supported.
1960
1961 The $members value returned by I<getgr*()> is a space separated list of
1962 the login names of the members of the group.
1963
1964 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1965 C, it will be returned to you via C<$?> if the function call fails.  The
1966 C<@addrs> value returned by a successful call is a list of the raw
1967 addresses returned by the corresponding system library call.  In the
1968 Internet domain, each address is four bytes long and you can unpack it
1969 by saying something like:
1970
1971     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1972
1973 The Socket library makes this slightly easier:
1974
1975     use Socket;
1976     $iaddr = inet_aton("127.1"); # or whatever address
1977     $name  = gethostbyaddr($iaddr, AF_INET);
1978
1979     # or going the other way
1980     $straddr = inet_ntoa($iaddr);
1981
1982 If you get tired of remembering which element of the return list
1983 contains which return value, by-name interfaces are provided
1984 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1985 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1986 and C<User::grent>.  These override the normal built-ins, supplying
1987 versions that return objects with the appropriate names
1988 for each field.  For example:
1989
1990    use File::stat;
1991    use User::pwent;
1992    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1993
1994 Even though it looks like they're the same method calls (uid),
1995 they aren't, because a C<File::stat> object is different from
1996 a C<User::pwent> object.
1997
1998 =item getsockname SOCKET
1999
2000 Returns the packed sockaddr address of this end of the SOCKET connection,
2001 in case you don't know the address because you have several different
2002 IPs that the connection might have come in on.
2003
2004     use Socket;
2005     $mysockaddr = getsockname(SOCK);
2006     ($port, $myaddr) = sockaddr_in($mysockaddr);
2007     printf "Connect to %s [%s]\n",
2008        scalar gethostbyaddr($myaddr, AF_INET),
2009        inet_ntoa($myaddr);
2010
2011 =item getsockopt SOCKET,LEVEL,OPTNAME
2012
2013 Returns the socket option requested, or undef if there is an error.
2014
2015 =item glob EXPR
2016
2017 =item glob
2018
2019 Returns the value of EXPR with filename expansions such as the
2020 standard Unix shell F</bin/csh> would do.  This is the internal function
2021 implementing the C<< <*.c> >> operator, but you can use it directly.
2022 If EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is
2023 discussed in more detail in L<perlop/"I/O Operators">.
2024
2025 Beginning with v5.6.0, this operator is implemented using the standard
2026 C<File::Glob> extension.  See L<File::Glob> for details.
2027
2028 =item gmtime EXPR
2029
2030 Converts a time as returned by the time function to an 8-element list
2031 with the time localized for the standard Greenwich time zone.
2032 Typically used as follows:
2033
2034     #  0    1    2     3     4    5     6     7
2035     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2036                                             gmtime(time);
2037
2038 All list elements are numeric, and come straight out of the C `struct
2039 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2040 specified time.  $mday is the day of the month, and $mon is the month
2041 itself, in the range C<0..11> with 0 indicating January and 11
2042 indicating December.  $year is the number of years since 1900.  That
2043 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2044 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2045 the year, in the range C<0..364> (or C<0..365> in leap years.)
2046
2047 Note that the $year element is I<not> simply the last two digits of
2048 the year.  If you assume it is, then you create non-Y2K-compliant
2049 programs--and you wouldn't want to do that, would you?
2050
2051 The proper way to get a complete 4-digit year is simply:
2052
2053         $year += 1900;
2054
2055 And to get the last two digits of the year (e.g., '01' in 2001) do:
2056
2057         $year = sprintf("%02d", $year % 100);
2058
2059 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2060
2061 In scalar context, C<gmtime()> returns the ctime(3) value:
2062
2063     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2064
2065 Also see the C<timegm> function provided by the C<Time::Local> module,
2066 and the strftime(3) function available via the POSIX module.
2067
2068 This scalar value is B<not> locale dependent (see L<perllocale>), but
2069 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2070 strftime(3) and mktime(3) functions available via the POSIX module.  To
2071 get somewhat similar but locale dependent date strings, set up your
2072 locale environment variables appropriately (please see L<perllocale>)
2073 and try for example:
2074
2075     use POSIX qw(strftime);
2076     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2077
2078 Note that the C<%a> and C<%b> escapes, which represent the short forms
2079 of the day of the week and the month of the year, may not necessarily
2080 be three characters wide in all locales.
2081
2082 =item goto LABEL
2083
2084 =item goto EXPR
2085
2086 =item goto &NAME
2087
2088 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2089 execution there.  It may not be used to go into any construct that
2090 requires initialization, such as a subroutine or a C<foreach> loop.  It
2091 also can't be used to go into a construct that is optimized away,
2092 or to get out of a block or subroutine given to C<sort>.
2093 It can be used to go almost anywhere else within the dynamic scope,
2094 including out of subroutines, but it's usually better to use some other
2095 construct such as C<last> or C<die>.  The author of Perl has never felt the
2096 need to use this form of C<goto> (in Perl, that is--C is another matter).
2097 (The difference being that C does not offer named loops combined with
2098 loop control.  Perl does, and this replaces most structured uses of C<goto>
2099 in other languages.)
2100
2101 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2102 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2103 necessarily recommended if you're optimizing for maintainability:
2104
2105     goto ("FOO", "BAR", "GLARCH")[$i];
2106
2107 The C<goto-&NAME> form is quite different from the other forms of
2108 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2109 doesn't have the stigma associated with other gotos.  Instead, it
2110 exits the current subroutine (losing any changes set by local()) and
2111 immediately calls in its place the named subroutine using the current
2112 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2113 load another subroutine and then pretend that the other subroutine had
2114 been called in the first place (except that any modifications to C<@_>
2115 in the current subroutine are propagated to the other subroutine.)
2116 After the C<goto>, not even C<caller> will be able to tell that this
2117 routine was called first.
2118
2119 NAME needn't be the name of a subroutine; it can be a scalar variable
2120 containing a code reference, or a block which evaluates to a code
2121 reference.
2122
2123 =item grep BLOCK LIST
2124
2125 =item grep EXPR,LIST
2126
2127 This is similar in spirit to, but not the same as, grep(1) and its
2128 relatives.  In particular, it is not limited to using regular expressions.
2129
2130 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2131 C<$_> to each element) and returns the list value consisting of those
2132 elements for which the expression evaluated to true.  In scalar
2133 context, returns the number of times the expression was true.
2134
2135     @foo = grep(!/^#/, @bar);    # weed out comments
2136
2137 or equivalently,
2138
2139     @foo = grep {!/^#/} @bar;    # weed out comments
2140
2141 Note that C<$_> is an alias to the list value, so it can be used to
2142 modify the elements of the LIST.  While this is useful and supported,
2143 it can cause bizarre results if the elements of LIST are not variables.
2144 Similarly, grep returns aliases into the original list, much as a for
2145 loop's index variable aliases the list elements.  That is, modifying an
2146 element of a list returned by grep (for example, in a C<foreach>, C<map>
2147 or another C<grep>) actually modifies the element in the original list.
2148 This is usually something to be avoided when writing clear code.
2149
2150 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2151
2152 =item hex EXPR
2153
2154 =item hex
2155
2156 Interprets EXPR as a hex string and returns the corresponding value.
2157 (To convert strings that might start with either 0, 0x, or 0b, see
2158 L</oct>.)  If EXPR is omitted, uses C<$_>.
2159
2160     print hex '0xAf'; # prints '175'
2161     print hex 'aF';   # same
2162
2163 Hex strings may only represent integers.  Strings that would cause
2164 integer overflow trigger a warning.  Leading whitespace is not stripped,
2165 unlike oct().
2166
2167 =item import
2168
2169 There is no builtin C<import> function.  It is just an ordinary
2170 method (subroutine) defined (or inherited) by modules that wish to export
2171 names to another module.  The C<use> function calls the C<import> method
2172 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2173
2174 =item index STR,SUBSTR,POSITION
2175
2176 =item index STR,SUBSTR
2177
2178 The index function searches for one string within another, but without
2179 the wildcard-like behavior of a full regular-expression pattern match.
2180 It returns the position of the first occurrence of SUBSTR in STR at
2181 or after POSITION.  If POSITION is omitted, starts searching from the
2182 beginning of the string.  The return value is based at C<0> (or whatever
2183 you've set the C<$[> variable to--but don't do that).  If the substring
2184 is not found, returns one less than the base, ordinarily C<-1>.
2185
2186 =item int EXPR
2187
2188 =item int
2189
2190 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2191 You should not use this function for rounding: one because it truncates
2192 towards C<0>, and two because machine representations of floating point
2193 numbers can sometimes produce counterintuitive results.  For example,
2194 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2195 because it's really more like -268.99999999999994315658 instead.  Usually,
2196 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2197 functions will serve you better than will int().
2198
2199 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2200
2201 Implements the ioctl(2) function.  You'll probably first have to say
2202
2203     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2204
2205 to get the correct function definitions.  If F<ioctl.ph> doesn't
2206 exist or doesn't have the correct definitions you'll have to roll your
2207 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2208 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2209 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2210 written depending on the FUNCTION--a pointer to the string value of SCALAR
2211 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2212 has no string value but does have a numeric value, that value will be
2213 passed rather than a pointer to the string value.  To guarantee this to be
2214 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2215 functions may be needed to manipulate the values of structures used by
2216 C<ioctl>.
2217
2218 The return value of C<ioctl> (and C<fcntl>) is as follows:
2219
2220         if OS returns:          then Perl returns:
2221             -1                    undefined value
2222              0                  string "0 but true"
2223         anything else               that number
2224
2225 Thus Perl returns true on success and false on failure, yet you can
2226 still easily determine the actual value returned by the operating
2227 system:
2228
2229     $retval = ioctl(...) || -1;
2230     printf "System returned %d\n", $retval;
2231
2232 The special string "C<0> but true" is exempt from B<-w> complaints
2233 about improper numeric conversions.
2234
2235 Here's an example of setting a filehandle named C<REMOTE> to be
2236 non-blocking at the system level.  You'll have to negotiate C<$|>
2237 on your own, though.
2238
2239     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2240
2241     $flags = fcntl(REMOTE, F_GETFL, 0)
2242                 or die "Can't get flags for the socket: $!\n";
2243
2244     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2245                 or die "Can't set flags for the socket: $!\n";
2246
2247 =item join EXPR,LIST
2248
2249 Joins the separate strings of LIST into a single string with fields
2250 separated by the value of EXPR, and returns that new string.  Example:
2251
2252     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2253
2254 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2255 first argument.  Compare L</split>.
2256
2257 =item keys HASH
2258
2259 Returns a list consisting of all the keys of the named hash.  (In
2260 scalar context, returns the number of keys.)  The keys are returned in
2261 an apparently random order.  The actual random order is subject to
2262 change in future versions of perl, but it is guaranteed to be the same
2263 order as either the C<values> or C<each> function produces (given
2264 that the hash has not been modified).  As a side effect, it resets
2265 HASH's iterator.
2266
2267 Here is yet another way to print your environment:
2268
2269     @keys = keys %ENV;
2270     @values = values %ENV;
2271     while (@keys) {
2272         print pop(@keys), '=', pop(@values), "\n";
2273     }
2274
2275 or how about sorted by key:
2276
2277     foreach $key (sort(keys %ENV)) {
2278         print $key, '=', $ENV{$key}, "\n";
2279     }
2280
2281 The returned values are copies of the original keys in the hash, so
2282 modifying them will not affect the original hash.  Compare L</values>.
2283
2284 To sort a hash by value, you'll need to use a C<sort> function.
2285 Here's a descending numeric sort of a hash by its values:
2286
2287     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2288         printf "%4d %s\n", $hash{$key}, $key;
2289     }
2290
2291 As an lvalue C<keys> allows you to increase the number of hash buckets
2292 allocated for the given hash.  This can gain you a measure of efficiency if
2293 you know the hash is going to get big.  (This is similar to pre-extending
2294 an array by assigning a larger number to $#array.)  If you say
2295
2296     keys %hash = 200;
2297
2298 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2299 in fact, since it rounds up to the next power of two.  These
2300 buckets will be retained even if you do C<%hash = ()>, use C<undef
2301 %hash> if you want to free the storage while C<%hash> is still in scope.
2302 You can't shrink the number of buckets allocated for the hash using
2303 C<keys> in this way (but you needn't worry about doing this by accident,
2304 as trying has no effect).
2305
2306 See also C<each>, C<values> and C<sort>.
2307
2308 =item kill SIGNAL, LIST
2309
2310 Sends a signal to a list of processes.  Returns the number of
2311 processes successfully signaled (which is not necessarily the
2312 same as the number actually killed).
2313
2314     $cnt = kill 1, $child1, $child2;
2315     kill 9, @goners;
2316
2317 If SIGNAL is zero, no signal is sent to the process.  This is a
2318 useful way to check that the process is alive and hasn't changed
2319 its UID.  See L<perlport> for notes on the portability of this
2320 construct.
2321
2322 Unlike in the shell, if SIGNAL is negative, it kills
2323 process groups instead of processes.  (On System V, a negative I<PROCESS>
2324 number will also kill process groups, but that's not portable.)  That
2325 means you usually want to use positive not negative signals.  You may also
2326 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2327
2328 =item last LABEL
2329
2330 =item last
2331
2332 The C<last> command is like the C<break> statement in C (as used in
2333 loops); it immediately exits the loop in question.  If the LABEL is
2334 omitted, the command refers to the innermost enclosing loop.  The
2335 C<continue> block, if any, is not executed:
2336
2337     LINE: while (<STDIN>) {
2338         last LINE if /^$/;      # exit when done with header
2339         #...
2340     }
2341
2342 C<last> cannot be used to exit a block which returns a value such as
2343 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2344 a grep() or map() operation.
2345
2346 Note that a block by itself is semantically identical to a loop
2347 that executes once.  Thus C<last> can be used to effect an early
2348 exit out of such a block.
2349
2350 See also L</continue> for an illustration of how C<last>, C<next>, and
2351 C<redo> work.
2352
2353 =item lc EXPR
2354
2355 =item lc
2356
2357 Returns a lowercased version of EXPR.  This is the internal function
2358 implementing the C<\L> escape in double-quoted strings.  Respects
2359 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2360 and L<perlunicode> for more details about locale and Unicode support.
2361
2362 If EXPR is omitted, uses C<$_>.
2363
2364 =item lcfirst EXPR
2365
2366 =item lcfirst
2367
2368 Returns the value of EXPR with the first character lowercased.  This
2369 is the internal function implementing the C<\l> escape in
2370 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2371 locale> in force.  See L<perllocale> and L<perlunicode> for more
2372 details about locale and Unicode support.
2373
2374 If EXPR is omitted, uses C<$_>.
2375
2376 =item length EXPR
2377
2378 =item length
2379
2380 Returns the length in characters of the value of EXPR.  If EXPR is
2381 omitted, returns length of C<$_>.  Note that this cannot be used on
2382 an entire array or hash to find out how many elements these have.
2383 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2384
2385 =item link OLDFILE,NEWFILE
2386
2387 Creates a new filename linked to the old filename.  Returns true for
2388 success, false otherwise.
2389
2390 =item listen SOCKET,QUEUESIZE
2391
2392 Does the same thing that the listen system call does.  Returns true if
2393 it succeeded, false otherwise.  See the example in
2394 L<perlipc/"Sockets: Client/Server Communication">.
2395
2396 =item local EXPR
2397
2398 You really probably want to be using C<my> instead, because C<local> isn't
2399 what most people think of as "local".  See
2400 L<perlsub/"Private Variables via my()"> for details.
2401
2402 A local modifies the listed variables to be local to the enclosing
2403 block, file, or eval.  If more than one value is listed, the list must
2404 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2405 for details, including issues with tied arrays and hashes.
2406
2407 =item localtime EXPR
2408
2409 Converts a time as returned by the time function to a 9-element list
2410 with the time analyzed for the local time zone.  Typically used as
2411 follows:
2412
2413     #  0    1    2     3     4    5     6     7     8
2414     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2415                                                 localtime(time);
2416
2417 All list elements are numeric, and come straight out of the C `struct
2418 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2419 specified time.  $mday is the day of the month, and $mon is the month
2420 itself, in the range C<0..11> with 0 indicating January and 11
2421 indicating December.  $year is the number of years since 1900.  That
2422 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2423 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2424 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2425 is true if the specified time occurs during daylight savings time,
2426 false otherwise.
2427
2428 Note that the $year element is I<not> simply the last two digits of
2429 the year.  If you assume it is, then you create non-Y2K-compliant
2430 programs--and you wouldn't want to do that, would you?
2431
2432 The proper way to get a complete 4-digit year is simply:
2433
2434         $year += 1900;
2435
2436 And to get the last two digits of the year (e.g., '01' in 2001) do:
2437
2438         $year = sprintf("%02d", $year % 100);
2439
2440 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2441
2442 In scalar context, C<localtime()> returns the ctime(3) value:
2443
2444     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2445
2446 This scalar value is B<not> locale dependent, see L<perllocale>, but
2447 instead a Perl builtin.  Also see the C<Time::Local> module
2448 (to convert the second, minutes, hours, ... back to seconds since the
2449 stroke of midnight the 1st of January 1970, the value returned by
2450 time()), and the strftime(3) and mktime(3) functions available via the
2451 POSIX module.  To get somewhat similar but locale dependent date
2452 strings, set up your locale environment variables appropriately
2453 (please see L<perllocale>) and try for example:
2454
2455     use POSIX qw(strftime);
2456     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2457
2458 Note that the C<%a> and C<%b>, the short forms of the day of the week
2459 and the month of the year, may not necessarily be three characters wide.
2460
2461 =item lock THING
2462
2463 This function places an advisory lock on a variable, subroutine,
2464 or referenced object contained in I<THING> until the lock goes out
2465 of scope.  This is a built-in function only if your version of Perl
2466 was built with threading enabled, and if you've said C<use Thread>.
2467 Otherwise a user-defined function by this name will be called.
2468 See L<Thread>.
2469
2470 =item log EXPR
2471
2472 =item log
2473
2474 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2475 returns log of C<$_>.  To get the log of another base, use basic algebra:
2476 The base-N log of a number is equal to the natural log of that number
2477 divided by the natural log of N.  For example:
2478
2479     sub log10 {
2480         my $n = shift;
2481         return log($n)/log(10);
2482     }
2483
2484 See also L</exp> for the inverse operation.
2485
2486 =item lstat EXPR
2487
2488 =item lstat
2489
2490 Does the same thing as the C<stat> function (including setting the
2491 special C<_> filehandle) but stats a symbolic link instead of the file
2492 the symbolic link points to.  If symbolic links are unimplemented on
2493 your system, a normal C<stat> is done.
2494
2495 If EXPR is omitted, stats C<$_>.
2496
2497 =item m//
2498
2499 The match operator.  See L<perlop>.
2500
2501 =item map BLOCK LIST
2502
2503 =item map EXPR,LIST
2504
2505 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2506 C<$_> to each element) and returns the list value composed of the
2507 results of each such evaluation.  In scalar context, returns the
2508 total number of elements so generated.  Evaluates BLOCK or EXPR in
2509 list context, so each element of LIST may produce zero, one, or
2510 more elements in the returned value.
2511
2512     @chars = map(chr, @nums);
2513
2514 translates a list of numbers to the corresponding characters.  And
2515
2516     %hash = map { getkey($_) => $_ } @array;
2517
2518 is just a funny way to write
2519
2520     %hash = ();
2521     foreach $_ (@array) {
2522         $hash{getkey($_)} = $_;
2523     }
2524
2525 Note that C<$_> is an alias to the list value, so it can be used to
2526 modify the elements of the LIST.  While this is useful and supported,
2527 it can cause bizarre results if the elements of LIST are not variables.
2528 Using a regular C<foreach> loop for this purpose would be clearer in
2529 most cases.  See also L</grep> for an array composed of those items of
2530 the original list for which the BLOCK or EXPR evaluates to true.
2531
2532 C<{> starts both hash references and blocks, so C<map { ...> could be either
2533 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2534 ahead for the closing C<}> it has to take a guess at which its dealing with
2535 based what it finds just after the C<{>. Usually it gets it right, but if it
2536 doesn't it won't realize something is wrong until it gets to the C<}> and
2537 encounters the missing (or unexpected) comma. The syntax error will be
2538 reported close to the C<}> but you'll need to change something near the C<{>
2539 such as using a unary C<+> to give perl some help:
2540
2541     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2542     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2543     %hash = map { ("\L$_", 1) } @array  # this also works
2544     %hash = map {  lc($_), 1  } @array  # as does this.
2545     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2546
2547     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2548
2549 or to force an anon hash constructor use C<+{>
2550
2551    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2552
2553 and you get list of anonymous hashes each with only 1 entry.
2554
2555 =item mkdir FILENAME,MASK
2556
2557 =item mkdir FILENAME
2558
2559 Creates the directory specified by FILENAME, with permissions
2560 specified by MASK (as modified by C<umask>).  If it succeeds it
2561 returns true, otherwise it returns false and sets C<$!> (errno).
2562 If omitted, MASK defaults to 0777.
2563
2564 In general, it is better to create directories with permissive MASK,
2565 and let the user modify that with their C<umask>, than it is to supply
2566 a restrictive MASK and give the user no way to be more permissive.
2567 The exceptions to this rule are when the file or directory should be
2568 kept private (mail files, for instance).  The perlfunc(1) entry on
2569 C<umask> discusses the choice of MASK in more detail.
2570
2571 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2572 number of trailing slashes.  Some operating and filesystems do not get
2573 this right, so Perl automatically removes all trailing slashes to keep
2574 everyone happy.
2575
2576 =item msgctl ID,CMD,ARG
2577
2578 Calls the System V IPC function msgctl(2).  You'll probably have to say
2579
2580     use IPC::SysV;
2581
2582 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2583 then ARG must be a variable which will hold the returned C<msqid_ds>
2584 structure.  Returns like C<ioctl>: the undefined value for error,
2585 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2586 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2587
2588 =item msgget KEY,FLAGS
2589
2590 Calls the System V IPC function msgget(2).  Returns the message queue
2591 id, or the undefined value if there is an error.  See also
2592 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2593
2594 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2595
2596 Calls the System V IPC function msgrcv to receive a message from
2597 message queue ID into variable VAR with a maximum message size of
2598 SIZE.  Note that when a message is received, the message type as a
2599 native long integer will be the first thing in VAR, followed by the
2600 actual message.  This packing may be opened with C<unpack("l! a*")>.
2601 Taints the variable.  Returns true if successful, or false if there is
2602 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2603 C<IPC::SysV::Msg> documentation.
2604
2605 =item msgsnd ID,MSG,FLAGS
2606
2607 Calls the System V IPC function msgsnd to send the message MSG to the
2608 message queue ID.  MSG must begin with the native long integer message
2609 type, and be followed by the length of the actual message, and finally
2610 the message itself.  This kind of packing can be achieved with
2611 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2612 or false if there is an error.  See also C<IPC::SysV>
2613 and C<IPC::SysV::Msg> documentation.
2614
2615 =item my EXPR
2616
2617 =item my EXPR : ATTRIBUTES
2618
2619 A C<my> declares the listed variables to be local (lexically) to the
2620 enclosing block, file, or C<eval>.  If
2621 more than one value is listed, the list must be placed in parentheses.  See
2622 L<perlsub/"Private Variables via my()"> for details.
2623
2624 =item next LABEL
2625
2626 =item next
2627
2628 The C<next> command is like the C<continue> statement in C; it starts
2629 the next iteration of the loop:
2630
2631     LINE: while (<STDIN>) {
2632         next LINE if /^#/;      # discard comments
2633         #...
2634     }
2635
2636 Note that if there were a C<continue> block on the above, it would get
2637 executed even on discarded lines.  If the LABEL is omitted, the command
2638 refers to the innermost enclosing loop.
2639
2640 C<next> cannot be used to exit a block which returns a value such as
2641 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2642 a grep() or map() operation.
2643
2644 Note that a block by itself is semantically identical to a loop
2645 that executes once.  Thus C<next> will exit such a block early.
2646
2647 See also L</continue> for an illustration of how C<last>, C<next>, and
2648 C<redo> work.
2649
2650 =item no Module LIST
2651
2652 See the L</use> function, which C<no> is the opposite of.
2653
2654 =item oct EXPR
2655
2656 =item oct
2657
2658 Interprets EXPR as an octal string and returns the corresponding
2659 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2660 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2661 binary string.  Leading whitespace is ignored in all three cases.)
2662 The following will handle decimal, binary, octal, and hex in the standard
2663 Perl or C notation:
2664
2665     $val = oct($val) if $val =~ /^0/;
2666
2667 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2668 in octal), use sprintf() or printf():
2669
2670     $perms = (stat("filename"))[2] & 07777;
2671     $oct_perms = sprintf "%lo", $perms;
2672
2673 The oct() function is commonly used when a string such as C<644> needs
2674 to be converted into a file mode, for example. (Although perl will
2675 automatically convert strings into numbers as needed, this automatic
2676 conversion assumes base 10.)
2677
2678 =item open FILEHANDLE,EXPR
2679
2680 =item open FILEHANDLE,MODE,EXPR
2681
2682 =item open FILEHANDLE,MODE,EXPR,LIST
2683
2684 =item open FILEHANDLE,MODE,REFERENCE
2685
2686 =item open FILEHANDLE
2687
2688 Opens the file whose filename is given by EXPR, and associates it with
2689 FILEHANDLE.
2690
2691 (The following is a comprehensive reference to open(): for a gentler
2692 introduction you may consider L<perlopentut>.)
2693
2694 If FILEHANDLE is an undefined lexical (C<my>) variable the variable is
2695 assigned a reference to a new anonymous filehandle, otherwise if
2696 FILEHANDLE is an expression, its value is used as the name of the real
2697 filehandle wanted.  (This is considered a symbolic reference, so C<use
2698 strict 'refs'> should I<not> be in effect.)
2699
2700 If EXPR is omitted, the scalar variable of the same name as the
2701 FILEHANDLE contains the filename.  (Note that lexical variables--those
2702 declared with C<my>--will not work for this purpose; so if you're
2703 using C<my>, specify EXPR in your call to open.) 
2704
2705 If three or more arguments are specified then the mode of opening and
2706 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2707 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2708 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2709 the file is opened for appending, again being created if necessary.
2710
2711 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2712 indicate that you want both read and write access to the file; thus
2713 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2714 '+>' >> mode would clobber the file first.  You can't usually use
2715 either read-write mode for updating textfiles, since they have
2716 variable length records.  See the B<-i> switch in L<perlrun> for a
2717 better approach.  The file is created with permissions of C<0666>
2718 modified by the process' C<umask> value.
2719
2720 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2721 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2722
2723 In the 2-arguments (and 1-argument) form of the call the mode and
2724 filename should be concatenated (in this order), possibly separated by
2725 spaces.  It is possible to omit the mode in these forms if the mode is
2726 C<< '<' >>.
2727
2728 If the filename begins with C<'|'>, the filename is interpreted as a
2729 command to which output is to be piped, and if the filename ends with a
2730 C<'|'>, the filename is interpreted as a command which pipes output to
2731 us.  See L<perlipc/"Using open() for IPC">
2732 for more examples of this.  (You are not allowed to C<open> to a command
2733 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2734 and L<perlipc/"Bidirectional Communication with Another Process">
2735 for alternatives.)
2736
2737 For three or more arguments if MODE is C<'|-'>, the filename is
2738 interpreted as a command to which output is to be piped, and if MODE
2739 is C<'-|'>, the filename is interpreted as a command which pipes
2740 output to us.  In the 2-arguments (and 1-argument) form one should
2741 replace dash (C<'-'>) with the command.
2742 See L<perlipc/"Using open() for IPC"> for more examples of this.
2743 (You are not allowed to C<open> to a command that pipes both in I<and>
2744 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2745 L<perlipc/"Bidirectional Communication"> for alternatives.)
2746
2747 In the three-or-more argument form of pipe opens, if LIST is specified
2748 (extra arguments after the command name) then LIST becomes arguments
2749 to the command invoked if the platform supports it.  The meaning of
2750 C<open> with more than three arguments for non-pipe modes is not yet
2751 specified. Experimental "layers" may give extra LIST arguments
2752 meaning.
2753
2754 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2755 and opening C<< '>-' >> opens STDOUT.
2756
2757 You may use the three-argument form of open to specify
2758 I<I/O disciplines> that affect how the input and output
2759 are processed: see L</binmode> and L<open>.  For example
2760
2761   open(FH, "<:utf8", "file")
2762
2763 will open the UTF-8 encoded file containing Unicode characters,
2764 see L<perluniintro>.
2765
2766 Open returns nonzero upon success, the undefined value otherwise.  If
2767 the C<open> involved a pipe, the return value happens to be the pid of
2768 the subprocess.
2769
2770 If you're running Perl on a system that distinguishes between text
2771 files and binary files, then you should check out L</binmode> for tips
2772 for dealing with this.  The key distinction between systems that need
2773 C<binmode> and those that don't is their text file formats.  Systems
2774 like Unix, MacOS, and Plan9, which delimit lines with a single
2775 character, and which encode that character in C as C<"\n">, do not
2776 need C<binmode>.  The rest need it.
2777
2778 In the three argument form MODE may also contain a list of IO "layers"
2779 (see L<open> and L<PerlIO> for more details) to be applied to the
2780 handle. This can be used to achieve the effect of C<binmode> as well
2781 as more complex behaviours.
2782
2783 When opening a file, it's usually a bad idea to continue normal execution
2784 if the request failed, so C<open> is frequently used in connection with
2785 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2786 where you want to make a nicely formatted error message (but there are
2787 modules that can help with that problem)) you should always check
2788 the return value from opening a file.  The infrequent exception is when
2789 working with an unopened filehandle is actually what you want to do.
2790
2791 As a special case the 3 arg form with a read/write mode and the third
2792 argument being C<undef>:
2793
2794     open(TMP, "+>", undef) or die ...
2795
2796 opens a filehandle to an anonymous temporary file.
2797
2798 File handles can be opened to "in memory" files held in Perl scalars via:
2799
2800     open($fh,'>', \$variable) || ..
2801
2802 Examples:
2803
2804     $ARTICLE = 100;
2805     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2806     while (<ARTICLE>) {...
2807
2808     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2809     # if the open fails, output is discarded
2810
2811     open(DBASE, '+<', 'dbase.mine')             # open for update
2812         or die "Can't open 'dbase.mine' for update: $!";
2813
2814     open(DBASE, '+<dbase.mine')                 # ditto
2815         or die "Can't open 'dbase.mine' for update: $!";
2816
2817     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2818         or die "Can't start caesar: $!";
2819
2820     open(ARTICLE, "caesar <$article |")         # ditto
2821         or die "Can't start caesar: $!";
2822
2823     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2824         or die "Can't start sort: $!";
2825
2826     # in memory files
2827     open(MEMORY,'>', \$var)
2828         or die "Can't open memory file: $!";
2829     print MEMORY "foo!\n";                      # output will end up in $var
2830
2831     # process argument list of files along with any includes
2832
2833     foreach $file (@ARGV) {
2834         process($file, 'fh00');
2835     }
2836
2837     sub process {
2838         my($filename, $input) = @_;
2839         $input++;               # this is a string increment
2840         unless (open($input, $filename)) {
2841             print STDERR "Can't open $filename: $!\n";
2842             return;
2843         }
2844
2845         local $_;
2846         while (<$input>) {              # note use of indirection
2847             if (/^#include "(.*)"/) {
2848                 process($1, $input);
2849                 next;
2850             }
2851             #...                # whatever
2852         }
2853     }
2854
2855 You may also, in the Bourne shell tradition, specify an EXPR beginning
2856 with C<< '>&' >>, in which case the rest of the string is interpreted as the
2857 name of a filehandle (or file descriptor, if numeric) to be
2858 duped and opened.  You may use C<&> after C<< > >>, C<<< >> >>>,
2859 C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.  The
2860 mode you specify should match the mode of the original filehandle.
2861 (Duping a filehandle does not take into account any existing contents of
2862 IO buffers.) If you use the 3 arg form then you can pass either a number,
2863 the name of a filehandle or the normal "reference to a glob".
2864
2865 Here is a script that saves, redirects, and restores STDOUT and
2866 STDERR:
2867
2868     #!/usr/bin/perl
2869     open(my $oldout, ">&", \*STDOUT);
2870     open(OLDERR, ">&STDERR");
2871
2872     open(STDOUT, '>', "foo.out") || die "Can't redirect stdout";
2873     open(STDERR, ">&STDOUT")     || die "Can't dup stdout";
2874
2875     select(STDERR); $| = 1;     # make unbuffered
2876     select(STDOUT); $| = 1;     # make unbuffered
2877
2878     print STDOUT "stdout 1\n";  # this works for
2879     print STDERR "stderr 1\n";  # subprocesses too
2880
2881     close(STDOUT);
2882     close(STDERR);
2883
2884     open(STDOUT, ">&OLDOUT");
2885     open(STDERR, ">&OLDERR");
2886
2887     print STDOUT "stdout 2\n";
2888     print STDERR "stderr 2\n";
2889
2890 If you specify C<< '<&=N' >>, where C<N> is a number, then Perl will
2891 do an equivalent of C's C<fdopen> of that file descriptor; this is
2892 more parsimonious of file descriptors.  For example:
2893
2894     open(FILEHANDLE, "<&=$fd")
2895
2896 or
2897
2898     open(FILEHANDLE, "<&=", $fd)
2899
2900 Note that if Perl is using the standard C libraries' fdopen() then on
2901 many UNIX systems, fdopen() is known to fail when file descriptors
2902 exceed a certain value, typically 255. If you need more file
2903 descriptors than that, consider rebuilding Perl to use the C<PerlIO>.
2904
2905 You can see whether Perl has been compiled with PerlIO or not by
2906 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
2907 is C<define>, you have PerlIO, otherwise you don't.
2908
2909 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2910 with 2-arguments (or 1-argument) form of open(), then
2911 there is an implicit fork done, and the return value of open is the pid
2912 of the child within the parent process, and C<0> within the child
2913 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2914 The filehandle behaves normally for the parent, but i/o to that
2915 filehandle is piped from/to the STDOUT/STDIN of the child process.
2916 In the child process the filehandle isn't opened--i/o happens from/to
2917 the new STDOUT or STDIN.  Typically this is used like the normal
2918 piped open when you want to exercise more control over just how the
2919 pipe command gets executed, such as when you are running setuid, and
2920 don't want to have to scan shell commands for metacharacters.
2921 The following triples are more or less equivalent:
2922
2923     open(FOO, "|tr '[a-z]' '[A-Z]'");
2924     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2925     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2926     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
2927
2928     open(FOO, "cat -n '$file'|");
2929     open(FOO, '-|', "cat -n '$file'");
2930     open(FOO, '-|') || exec 'cat', '-n', $file;
2931     open(FOO, '-|', "cat", '-n', $file);
2932
2933 The last example in each block shows the pipe as "list form", which is
2934 not yet supported on all platforms.
2935
2936 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2937
2938 Beginning with v5.6.0, Perl will attempt to flush all files opened for
2939 output before any operation that may do a fork, but this may not be
2940 supported on some platforms (see L<perlport>).  To be safe, you may need
2941 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
2942 of C<IO::Handle> on any open handles.
2943
2944 On systems that support a close-on-exec flag on files, the flag will
2945 be set for the newly opened file descriptor as determined by the value
2946 of $^F.  See L<perlvar/$^F>.
2947
2948 Closing any piped filehandle causes the parent process to wait for the
2949 child to finish, and returns the status value in C<$?>.
2950
2951 The filename passed to 2-argument (or 1-argument) form of open() will
2952 have leading and trailing whitespace deleted, and the normal
2953 redirection characters honored.  This property, known as "magic open",
2954 can often be used to good effect.  A user could specify a filename of
2955 F<"rsh cat file |">, or you could change certain filenames as needed:
2956
2957     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2958     open(FH, $filename) or die "Can't open $filename: $!";
2959
2960 Use 3-argument form to open a file with arbitrary weird characters in it,
2961
2962     open(FOO, '<', $file);
2963
2964 otherwise it's necessary to protect any leading and trailing whitespace:
2965
2966     $file =~ s#^(\s)#./$1#;
2967     open(FOO, "< $file\0");
2968
2969 (this may not work on some bizarre filesystems).  One should
2970 conscientiously choose between the I<magic> and 3-arguments form
2971 of open():
2972
2973     open IN, $ARGV[0];
2974
2975 will allow the user to specify an argument of the form C<"rsh cat file |">,
2976 but will not work on a filename which happens to have a trailing space, while
2977
2978     open IN, '<', $ARGV[0];
2979
2980 will have exactly the opposite restrictions.
2981
2982 If you want a "real" C C<open> (see L<open(2)> on your system), then you
2983 should use the C<sysopen> function, which involves no such magic (but
2984 may use subtly different filemodes than Perl open(), which is mapped
2985 to C fopen()).  This is
2986 another way to protect your filenames from interpretation.  For example:
2987
2988     use IO::Handle;
2989     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2990         or die "sysopen $path: $!";
2991     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2992     print HANDLE "stuff $$\n";
2993     seek(HANDLE, 0, 0);
2994     print "File contains: ", <HANDLE>;
2995
2996 Using the constructor from the C<IO::Handle> package (or one of its
2997 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2998 filehandles that have the scope of whatever variables hold references to
2999 them, and automatically close whenever and however you leave that scope:
3000
3001     use IO::File;
3002     #...
3003     sub read_myfile_munged {
3004         my $ALL = shift;
3005         my $handle = new IO::File;
3006         open($handle, "myfile") or die "myfile: $!";
3007         $first = <$handle>
3008             or return ();     # Automatically closed here.
3009         mung $first or die "mung failed";       # Or here.
3010         return $first, <$handle> if $ALL;       # Or here.
3011         $first;                                 # Or here.
3012     }
3013
3014 See L</seek> for some details about mixing reading and writing.
3015
3016 =item opendir DIRHANDLE,EXPR
3017
3018 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3019 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3020 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3021
3022 =item ord EXPR
3023
3024 =item ord
3025
3026 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3027 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3028 uses C<$_>.
3029
3030 For the reverse, see L</chr>.
3031 See L<perlunicode> and L<encoding> for more about Unicode.
3032
3033 =item our EXPR
3034
3035 =item our EXPR : ATTRIBUTES
3036
3037 An C<our> declares the listed variables to be valid globals within
3038 the enclosing block, file, or C<eval>.  That is, it has the same
3039 scoping rules as a "my" declaration, but does not create a local
3040 variable.  If more than one value is listed, the list must be placed
3041 in parentheses.  The C<our> declaration has no semantic effect unless
3042 "use strict vars" is in effect, in which case it lets you use the
3043 declared global variable without qualifying it with a package name.
3044 (But only within the lexical scope of the C<our> declaration.  In this
3045 it differs from "use vars", which is package scoped.)
3046
3047 An C<our> declaration declares a global variable that will be visible
3048 across its entire lexical scope, even across package boundaries.  The
3049 package in which the variable is entered is determined at the point
3050 of the declaration, not at the point of use.  This means the following
3051 behavior holds:
3052
3053     package Foo;
3054     our $bar;           # declares $Foo::bar for rest of lexical scope
3055     $bar = 20;
3056
3057     package Bar;
3058     print $bar;         # prints 20
3059
3060 Multiple C<our> declarations in the same lexical scope are allowed
3061 if they are in different packages.  If they happened to be in the same
3062 package, Perl will emit warnings if you have asked for them.
3063
3064     use warnings;
3065     package Foo;
3066     our $bar;           # declares $Foo::bar for rest of lexical scope
3067     $bar = 20;
3068
3069     package Bar;
3070     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3071     print $bar;         # prints 30
3072
3073     our $bar;           # emits warning
3074
3075 An C<our> declaration may also have a list of attributes associated
3076 with it.  B<WARNING>: This is an experimental feature that may be
3077 changed or removed in future releases of Perl.  It should not be
3078 relied upon.
3079
3080 The only currently recognized attribute is C<unique> which indicates
3081 that a single copy of the global is to be used by all interpreters
3082 should the program happen to be running in a multi-interpreter
3083 environment. (The default behaviour would be for each interpreter to
3084 have its own copy of the global.)  In such an environment, this
3085 attribute also has the effect of making the global readonly.
3086 Examples:
3087
3088     our @EXPORT : unique = qw(foo);
3089     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3090     our $VERSION : unique = "1.00";
3091
3092 Multi-interpreter environments can come to being either through the
3093 fork() emulation on Windows platforms, or by embedding perl in a
3094 multi-threaded application.  The C<unique> attribute does nothing in
3095 all other environments.
3096
3097 =item pack TEMPLATE,LIST
3098
3099 Takes a LIST of values and converts it into a string using the rules
3100 given by the TEMPLATE.  The resulting string is the concatenation of
3101 the converted values.  Typically, each converted value looks
3102 like its machine-level representation.  For example, on 32-bit machines
3103 a converted integer may be represented by a sequence of 4 bytes.
3104
3105 The TEMPLATE is a
3106 sequence of characters that give the order and type of values, as
3107 follows:
3108
3109     a   A string with arbitrary binary data, will be null padded.
3110     A   A text (ASCII) string, will be space padded.
3111     Z   A null terminated (ASCIZ) string, will be null padded.
3112
3113     b   A bit string (ascending bit order inside each byte, like vec()).
3114     B   A bit string (descending bit order inside each byte).
3115     h   A hex string (low nybble first).
3116     H   A hex string (high nybble first).
3117
3118     c   A signed char value.
3119     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3120
3121     s   A signed short value.
3122     S   An unsigned short value.
3123           (This 'short' is _exactly_ 16 bits, which may differ from
3124            what a local C compiler calls 'short'.  If you want
3125            native-length shorts, use the '!' suffix.)
3126
3127     i   A signed integer value.
3128     I   An unsigned integer value.
3129           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3130            size depends on what a local C compiler calls 'int',
3131            and may even be larger than the 'long' described in
3132            the next item.)
3133
3134     l   A signed long value.
3135     L   An unsigned long value.
3136           (This 'long' is _exactly_ 32 bits, which may differ from
3137            what a local C compiler calls 'long'.  If you want
3138            native-length longs, use the '!' suffix.)
3139
3140     n   An unsigned short in "network" (big-endian) order.
3141     N   An unsigned long in "network" (big-endian) order.
3142     v   An unsigned short in "VAX" (little-endian) order.
3143     V   An unsigned long in "VAX" (little-endian) order.
3144           (These 'shorts' and 'longs' are _exactly_ 16 bits and
3145            _exactly_ 32 bits, respectively.)
3146
3147     q   A signed quad (64-bit) value.
3148     Q   An unsigned quad value.
3149           (Quads are available only if your system supports 64-bit
3150            integer values _and_ if Perl has been compiled to support those.
3151            Causes a fatal error otherwise.)
3152
3153     f   A single-precision float in the native format.
3154     d   A double-precision float in the native format.
3155
3156     p   A pointer to a null-terminated string.
3157     P   A pointer to a structure (fixed-length string).
3158
3159     u   A uuencoded string.
3160     U   A Unicode character number.  Encodes to UTF-8 internally
3161         (or UTF-EBCDIC in EBCDIC platforms).
3162
3163     w   A BER compressed integer.  Its bytes represent an unsigned
3164         integer in base 128, most significant digit first, with as
3165         few digits as possible.  Bit eight (the high bit) is set
3166         on each byte except the last.
3167
3168     x   A null byte.
3169     X   Back up a byte.
3170     @   Null fill to absolute position.
3171
3172 The following rules apply:
3173
3174 =over 8
3175
3176 =item *
3177
3178 Each letter may optionally be followed by a number giving a repeat
3179 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3180 C<H>, and C<P> the pack function will gobble up that many values from
3181 the LIST.  A C<*> for the repeat count means to use however many items are
3182 left, except for C<@>, C<x>, C<X>, where it is equivalent
3183 to C<0>, and C<u>, where it is equivalent to 1 (or 45, what is the
3184 same).
3185
3186 When used with C<Z>, C<*> results in the addition of a trailing null
3187 byte (so the packed result will be one longer than the byte C<length>
3188 of the item).
3189
3190 The repeat count for C<u> is interpreted as the maximal number of bytes
3191 to encode per line of output, with 0 and 1 replaced by 45.
3192
3193 =item *
3194
3195 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3196 string of length count, padding with nulls or spaces as necessary.  When
3197 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3198 after the first null, and C<a> returns data verbatim.  When packing,
3199 C<a>, and C<Z> are equivalent.
3200
3201 If the value-to-pack is too long, it is truncated.  If too long and an
3202 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3203 by a null byte.  Thus C<Z> always packs a trailing null byte under
3204 all circumstances.
3205
3206 =item *
3207
3208 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3209 Each byte of the input field of pack() generates 1 bit of the result.
3210 Each result bit is based on the least-significant bit of the corresponding
3211 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3212 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3213
3214 Starting from the beginning of the input string of pack(), each 8-tuple
3215 of bytes is converted to 1 byte of output.  With format C<b>
3216 the first byte of the 8-tuple determines the least-significant bit of a
3217 byte, and with format C<B> it determines the most-significant bit of
3218 a byte.
3219
3220 If the length of the input string is not exactly divisible by 8, the
3221 remainder is packed as if the input string were padded by null bytes
3222 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3223
3224 If the input string of pack() is longer than needed, extra bytes are ignored.
3225 A C<*> for the repeat count of pack() means to use all the bytes of
3226 the input field.  On unpack()ing the bits are converted to a string
3227 of C<"0">s and C<"1">s.
3228
3229 =item *
3230
3231 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3232 representable as hexadecimal digits, 0-9a-f) long.
3233
3234 Each byte of the input field of pack() generates 4 bits of the result.
3235 For non-alphabetical bytes the result is based on the 4 least-significant
3236 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3237 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3238 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3239 is compatible with the usual hexadecimal digits, so that C<"a"> and
3240 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3241 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3242
3243 Starting from the beginning of the input string of pack(), each pair
3244 of bytes is converted to 1 byte of output.  With format C<h> the
3245 first byte of the pair determines the least-significant nybble of the
3246 output byte, and with format C<H> it determines the most-significant
3247 nybble.
3248
3249 If the length of the input string is not even, it behaves as if padded
3250 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3251 nybbles are ignored.
3252
3253 If the input string of pack() is longer than needed, extra bytes are ignored.
3254 A C<*> for the repeat count of pack() means to use all the bytes of
3255 the input field.  On unpack()ing the bits are converted to a string
3256 of hexadecimal digits.
3257
3258 =item *
3259
3260 The C<p> type packs a pointer to a null-terminated string.  You are
3261 responsible for ensuring the string is not a temporary value (which can
3262 potentially get deallocated before you get around to using the packed result).
3263 The C<P> type packs a pointer to a structure of the size indicated by the
3264 length.  A NULL pointer is created if the corresponding value for C<p> or
3265 C<P> is C<undef>, similarly for unpack().
3266
3267 =item *
3268
3269 The C</> template character allows packing and unpacking of strings where
3270 the packed structure contains a byte count followed by the string itself.
3271 You write I<length-item>C</>I<string-item>.
3272
3273 The I<length-item> can be any C<pack> template letter,
3274 and describes how the length value is packed.
3275 The ones likely to be of most use are integer-packing ones like
3276 C<n> (for Java strings), C<w> (for ASN.1 or SNMP)
3277 and C<N> (for Sun XDR).
3278
3279 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
3280 For C<unpack> the length of the string is obtained from the I<length-item>,
3281 but if you put in the '*' it will be ignored.
3282
3283     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3284     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3285     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3286
3287 The I<length-item> is not returned explicitly from C<unpack>.
3288
3289 Adding a count to the I<length-item> letter is unlikely to do anything
3290 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3291 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3292 which Perl does not regard as legal in numeric strings.
3293
3294 =item *
3295
3296 The integer types C<s>, C<S>, C<l>, and C<L> may be
3297 immediately followed by a C<!> suffix to signify native shorts or
3298 longs--as you can see from above for example a bare C<l> does mean
3299 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3300 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3301 see whether using C<!> makes any difference by
3302
3303         print length(pack("s")), " ", length(pack("s!")), "\n";
3304         print length(pack("l")), " ", length(pack("l!")), "\n";
3305
3306 C<i!> and C<I!> also work but only because of completeness;
3307 they are identical to C<i> and C<I>.
3308
3309 The actual sizes (in bytes) of native shorts, ints, longs, and long
3310 longs on the platform where Perl was built are also available via
3311 L<Config>:
3312
3313        use Config;
3314        print $Config{shortsize},    "\n";
3315        print $Config{intsize},      "\n";
3316        print $Config{longsize},     "\n";
3317        print $Config{longlongsize}, "\n";
3318
3319 (The C<$Config{longlongsize}> will be undefine if your system does
3320 not support long longs.)
3321
3322 =item *
3323
3324 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, and C<L>
3325 are inherently non-portable between processors and operating systems
3326 because they obey the native byteorder and endianness.  For example a
3327 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3328 (arranged in and handled by the CPU registers) into bytes as
3329
3330         0x12 0x34 0x56 0x78     # big-endian
3331         0x78 0x56 0x34 0x12     # little-endian
3332
3333 Basically, the Intel and VAX CPUs are little-endian, while everybody
3334 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3335 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3336 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3337 mode.
3338
3339 The names `big-endian' and `little-endian' are comic references to
3340 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3341 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3342 the egg-eating habits of the Lilliputians.
3343
3344 Some systems may have even weirder byte orders such as
3345
3346         0x56 0x78 0x12 0x34
3347         0x34 0x12 0x78 0x56
3348
3349 You can see your system's preference with
3350
3351         print join(" ", map { sprintf "%#02x", $_ }
3352                             unpack("C*",pack("L",0x12345678))), "\n";
3353
3354 The byteorder on the platform where Perl was built is also available
3355 via L<Config>:
3356
3357         use Config;
3358         print $Config{byteorder}, "\n";
3359
3360 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3361 and C<'87654321'> are big-endian.
3362
3363 If you want portable packed integers use the formats C<n>, C<N>,
3364 C<v>, and C<V>, their byte endianness and size are known.
3365 See also L<perlport>.
3366
3367 =item *
3368
3369 Real numbers (floats and doubles) are in the native machine format only;
3370 due to the multiplicity of floating formats around, and the lack of a
3371 standard "network" representation, no facility for interchange has been
3372 made.  This means that packed floating point data written on one machine
3373 may not be readable on another - even if both use IEEE floating point
3374 arithmetic (as the endian-ness of the memory representation is not part
3375 of the IEEE spec).  See also L<perlport>.
3376
3377 Note that Perl uses doubles internally for all numeric calculation, and
3378 converting from double into float and thence back to double again will
3379 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3380 equal $foo).
3381
3382 =item *
3383
3384 If the pattern begins with a C<U>, the resulting string will be treated
3385 as Unicode-encoded. You can force UTF8 encoding on in a string with an
3386 initial C<U0>, and the bytes that follow will be interpreted as Unicode
3387 characters. If you don't want this to happen, you can begin your pattern
3388 with C<C0> (or anything else) to force Perl not to UTF8 encode your
3389 string, and then follow this with a C<U*> somewhere in your pattern.
3390
3391 =item *
3392
3393 You must yourself do any alignment or padding by inserting for example
3394 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3395 could know where the bytes are going to or coming from.  Therefore
3396 C<pack> (and C<unpack>) handle their output and input as flat
3397 sequences of bytes.
3398
3399 =item *
3400
3401 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3402
3403 =item *
3404
3405 If TEMPLATE requires more arguments to pack() than actually given, pack()
3406 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3407 to pack() than actually given, extra arguments are ignored.
3408
3409 =back
3410
3411 Examples:
3412
3413     $foo = pack("CCCC",65,66,67,68);
3414     # foo eq "ABCD"
3415     $foo = pack("C4",65,66,67,68);
3416     # same thing
3417     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3418     # same thing with Unicode circled letters
3419
3420     $foo = pack("ccxxcc",65,66,67,68);
3421     # foo eq "AB\0\0CD"
3422
3423     # note: the above examples featuring "C" and "c" are true
3424     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3425     # and UTF-8.  In EBCDIC the first example would be
3426     # $foo = pack("CCCC",193,194,195,196);
3427
3428     $foo = pack("s2",1,2);
3429     # "\1\0\2\0" on little-endian
3430     # "\0\1\0\2" on big-endian
3431
3432     $foo = pack("a4","abcd","x","y","z");
3433     # "abcd"
3434
3435     $foo = pack("aaaa","abcd","x","y","z");
3436     # "axyz"
3437
3438     $foo = pack("a14","abcdefg");
3439     # "abcdefg\0\0\0\0\0\0\0"
3440
3441     $foo = pack("i9pl", gmtime);
3442     # a real struct tm (on my system anyway)
3443
3444     $utmp_template = "Z8 Z8 Z16 L";
3445     $utmp = pack($utmp_template, @utmp1);
3446     # a struct utmp (BSDish)
3447
3448     @utmp2 = unpack($utmp_template, $utmp);
3449     # "@utmp1" eq "@utmp2"
3450
3451     sub bintodec {
3452         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3453     }
3454
3455     $foo = pack('sx2l', 12, 34);
3456     # short 12, two zero bytes padding, long 34
3457     $bar = pack('s@4l', 12, 34);
3458     # short 12, zero fill to position 4, long 34
3459     # $foo eq $bar
3460
3461 The same template may generally also be used in unpack().
3462
3463 =item package NAMESPACE
3464
3465 =item package
3466
3467 Declares the compilation unit as being in the given namespace.  The scope
3468 of the package declaration is from the declaration itself through the end
3469 of the enclosing block, file, or eval (the same as the C<my> operator).
3470 All further unqualified dynamic identifiers will be in this namespace.
3471 A package statement affects only dynamic variables--including those
3472 you've used C<local> on--but I<not> lexical variables, which are created
3473 with C<my>.  Typically it would be the first declaration in a file to
3474 be included by the C<require> or C<use> operator.  You can switch into a
3475 package in more than one place; it merely influences which symbol table
3476 is used by the compiler for the rest of that block.  You can refer to
3477 variables and filehandles in other packages by prefixing the identifier
3478 with the package name and a double colon:  C<$Package::Variable>.
3479 If the package name is null, the C<main> package as assumed.  That is,
3480 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3481 still seen in older code).
3482
3483 If NAMESPACE is omitted, then there is no current package, and all
3484 identifiers must be fully qualified or lexicals.  However, you are
3485 strongly advised not to make use of this feature. Its use can cause
3486 unexpected behaviour, even crashing some versions of Perl. It is
3487 deprecated, and will be removed from a future release.
3488
3489 See L<perlmod/"Packages"> for more information about packages, modules,
3490 and classes.  See L<perlsub> for other scoping issues.
3491
3492 =item pipe READHANDLE,WRITEHANDLE
3493
3494 Opens a pair of connected pipes like the corresponding system call.
3495 Note that if you set up a loop of piped processes, deadlock can occur
3496 unless you are very careful.  In addition, note that Perl's pipes use
3497 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3498 after each command, depending on the application.
3499
3500 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3501 for examples of such things.
3502
3503 On systems that support a close-on-exec flag on files, the flag will be set
3504 for the newly opened file descriptors as determined by the value of $^F.
3505 See L<perlvar/$^F>.
3506
3507 =item pop ARRAY
3508
3509 =item pop
3510
3511 Pops and returns the last value of the array, shortening the array by
3512 one element.  Has an effect similar to
3513
3514     $ARRAY[$#ARRAY--]
3515
3516 If there are no elements in the array, returns the undefined value
3517 (although this may happen at other times as well).  If ARRAY is
3518 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3519 array in subroutines, just like C<shift>.
3520
3521 =item pos SCALAR
3522
3523 =item pos
3524
3525 Returns the offset of where the last C<m//g> search left off for the variable
3526 in question (C<$_> is used when the variable is not specified).  May be
3527 modified to change that offset.  Such modification will also influence
3528 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3529 L<perlop>.
3530
3531 =item print FILEHANDLE LIST
3532
3533 =item print LIST
3534
3535 =item print
3536
3537 Prints a string or a list of strings.  Returns true if successful.
3538 FILEHANDLE may be a scalar variable name, in which case the variable
3539 contains the name of or a reference to the filehandle, thus introducing
3540 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3541 the next token is a term, it may be misinterpreted as an operator
3542 unless you interpose a C<+> or put parentheses around the arguments.)
3543 If FILEHANDLE is omitted, prints by default to standard output (or
3544 to the last selected output channel--see L</select>).  If LIST is
3545 also omitted, prints C<$_> to the currently selected output channel.
3546 To set the default output channel to something other than STDOUT
3547 use the select operation.  The current value of C<$,> (if any) is
3548 printed between each LIST item.  The current value of C<$\> (if
3549 any) is printed after the entire LIST has been printed.  Because
3550 print takes a LIST, anything in the LIST is evaluated in list
3551 context, and any subroutine that you call will have one or more of
3552 its expressions evaluated in list context.  Also be careful not to
3553 follow the print keyword with a left parenthesis unless you want
3554 the corresponding right parenthesis to terminate the arguments to
3555 the print--interpose a C<+> or put parentheses around all the
3556 arguments.
3557
3558 Note that if you're storing FILEHANDLES in an array or other expression,
3559 you will have to use a block returning its value instead:
3560
3561     print { $files[$i] } "stuff\n";
3562     print { $OK ? STDOUT : STDERR } "stuff\n";
3563
3564 =item printf FILEHANDLE FORMAT, LIST
3565
3566 =item printf FORMAT, LIST
3567
3568 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3569 (the output record separator) is not appended.  The first argument
3570 of the list will be interpreted as the C<printf> format. See C<sprintf>
3571 for an explanation of the format argument. If C<use locale> is in effect,
3572 the character used for the decimal point in formatted real numbers is
3573 affected by the LC_NUMERIC locale.  See L<perllocale>.
3574
3575 Don't fall into the trap of using a C<printf> when a simple
3576 C<print> would do.  The C<print> is more efficient and less
3577 error prone.
3578
3579 =item prototype FUNCTION
3580
3581 Returns the prototype of a function as a string (or C<undef> if the
3582 function has no prototype).  FUNCTION is a reference to, or the name of,
3583 the function whose prototype you want to retrieve.
3584
3585 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3586 name for Perl builtin.  If the builtin is not I<overridable> (such as
3587 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3588 C<system>) returns C<undef> because the builtin does not really behave
3589 like a Perl function.  Otherwise, the string describing the equivalent
3590 prototype is returned.
3591
3592 =item push ARRAY,LIST
3593
3594 Treats ARRAY as a stack, and pushes the values of LIST
3595 onto the end of ARRAY.  The length of ARRAY increases by the length of
3596 LIST.  Has the same effect as
3597
3598     for $value (LIST) {
3599         $ARRAY[++$#ARRAY] = $value;
3600     }
3601
3602 but is more efficient.  Returns the new number of elements in the array.
3603
3604 =item q/STRING/
3605
3606 =item qq/STRING/
3607
3608 =item qr/STRING/
3609
3610 =item qx/STRING/
3611
3612 =item qw/STRING/
3613
3614 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3615
3616 =item quotemeta EXPR
3617
3618 =item quotemeta
3619
3620 Returns the value of EXPR with all non-"word"
3621 characters backslashed.  (That is, all characters not matching
3622 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3623 returned string, regardless of any locale settings.)
3624 This is the internal function implementing
3625 the C<\Q> escape in double-quoted strings.
3626
3627 If EXPR is omitted, uses C<$_>.
3628
3629 =item rand EXPR
3630
3631 =item rand
3632
3633 Returns a random fractional number greater than or equal to C<0> and less
3634 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3635 omitted, or a C<0>, the value C<1> is used.  Automatically calls C<srand>
3636 unless C<srand> has already been called.  See also C<srand>.
3637
3638 Apply C<int()> to the value returned by C<rand()> if you want random
3639 integers instead of random fractional numbers.  For example,
3640
3641     int(rand(10))
3642
3643 returns a random integer between C<0> and C<9>, inclusive.
3644
3645 (Note: If your rand function consistently returns numbers that are too
3646 large or too small, then your version of Perl was probably compiled
3647 with the wrong number of RANDBITS.)
3648
3649 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3650
3651 =item read FILEHANDLE,SCALAR,LENGTH
3652
3653 Attempts to read LENGTH I<characters> of data into variable SCALAR
3654 from the specified FILEHANDLE.  Returns the number of characters
3655 actually read, C<0> at end of file, or undef if there was an error.
3656 SCALAR will be grown or shrunk to the length actually read.  If SCALAR
3657 needs growing, the new bytes will be zero bytes.  An OFFSET may be
3658 specified to place the read data into some other place in SCALAR than
3659 the beginning.  The call is actually implemented in terms of either
3660 Perl's or system's fread() call.  To get a true read(2) system call,
3661 see C<sysread>.
3662
3663 Note the I<characters>: depending on the status of the filehandle,
3664 either (8-bit) bytes or characters are read.  By default all
3665 filehandles operate on bytes, but for example if the filehandle has
3666 been opened with the C<:utf8> discipline (see L</open>, and the C<open>
3667 pragma, L<open>), the I/O will operate on characters, not bytes.
3668
3669 =item readdir DIRHANDLE
3670
3671 Returns the next directory entry for a directory opened by C<opendir>.
3672 If used in list context, returns all the rest of the entries in the
3673 directory.  If there are no more entries, returns an undefined value in
3674 scalar context or a null list in list context.
3675
3676 If you're planning to filetest the return values out of a C<readdir>, you'd
3677 better prepend the directory in question.  Otherwise, because we didn't
3678 C<chdir> there, it would have been testing the wrong file.
3679
3680     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3681     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3682     closedir DIR;
3683
3684 =item readline EXPR
3685
3686 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3687 context, each call reads and returns the next line, until end-of-file is
3688 reached, whereupon the subsequent call returns undef.  In list context,
3689 reads until end-of-file is reached and returns a list of lines.  Note that
3690 the notion of "line" used here is however you may have defined it
3691 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3692
3693 When C<$/> is set to C<undef>, when readline() is in scalar
3694 context (i.e. file slurp mode), and when an empty file is read, it
3695 returns C<''> the first time, followed by C<undef> subsequently.
3696
3697 This is the internal function implementing the C<< <EXPR> >>
3698 operator, but you can use it directly.  The C<< <EXPR> >>
3699 operator is discussed in more detail in L<perlop/"I/O Operators">.
3700
3701     $line = <STDIN>;
3702     $line = readline(*STDIN);           # same thing
3703
3704 =item readlink EXPR
3705
3706 =item readlink
3707
3708 Returns the value of a symbolic link, if symbolic links are
3709 implemented.  If not, gives a fatal error.  If there is some system
3710 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3711 omitted, uses C<$_>.
3712
3713 =item readpipe EXPR
3714
3715 EXPR is executed as a system command.
3716 The collected standard output of the command is returned.
3717 In scalar context, it comes back as a single (potentially
3718 multi-line) string.  In list context, returns a list of lines
3719 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3720 This is the internal function implementing the C<qx/EXPR/>
3721 operator, but you can use it directly.  The C<qx/EXPR/>
3722 operator is discussed in more detail in L<perlop/"I/O Operators">.
3723
3724 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3725
3726 Receives a message on a socket.  Attempts to receive LENGTH characters
3727 of data into variable SCALAR from the specified SOCKET filehandle.
3728 SCALAR will be grown or shrunk to the length actually read.  Takes the
3729 same flags as the system call of the same name.  Returns the address
3730 of the sender if SOCKET's protocol supports this; returns an empty
3731 string otherwise.  If there's an error, returns the undefined value.
3732 This call is actually implemented in terms of recvfrom(2) system call.
3733 See L<perlipc/"UDP: Message Passing"> for examples.
3734
3735 Note the I<characters>: depending on the status of the socket, either
3736 (8-bit) bytes or characters are received.  By default all sockets
3737 operate on bytes, but for example if the socket has been changed using
3738 binmode() to operate with the C<:utf8> discipline (see the C<open>
3739 pragma, L<open>), the I/O will operate on characters, not bytes.
3740
3741 =item redo LABEL
3742
3743 =item redo
3744
3745 The C<redo> command restarts the loop block without evaluating the
3746 conditional again.  The C<continue> block, if any, is not executed.  If
3747 the LABEL is omitted, the command refers to the innermost enclosing
3748 loop.  This command is normally used by programs that want to lie to
3749 themselves about what was just input:
3750
3751     # a simpleminded Pascal comment stripper
3752     # (warning: assumes no { or } in strings)
3753     LINE: while (<STDIN>) {
3754         while (s|({.*}.*){.*}|$1 |) {}
3755         s|{.*}| |;
3756         if (s|{.*| |) {
3757             $front = $_;
3758             while (<STDIN>) {
3759                 if (/}/) {      # end of comment?
3760                     s|^|$front\{|;
3761                     redo LINE;
3762                 }
3763             }
3764         }
3765         print;
3766     }
3767
3768 C<redo> cannot be used to retry a block which returns a value such as
3769 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3770 a grep() or map() operation.
3771
3772 Note that a block by itself is semantically identical to a loop
3773 that executes once.  Thus C<redo> inside such a block will effectively
3774 turn it into a looping construct.
3775
3776 See also L</continue> for an illustration of how C<last>, C<next>, and
3777 C<redo> work.
3778
3779 =item ref EXPR
3780
3781 =item ref
3782
3783 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3784 is not specified, C<$_> will be used.  The value returned depends on the
3785 type of thing the reference is a reference to.
3786 Builtin types include:
3787
3788     SCALAR
3789     ARRAY
3790     HASH
3791     CODE
3792     REF
3793     GLOB
3794     LVALUE
3795
3796 If the referenced object has been blessed into a package, then that package
3797 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3798
3799     if (ref($r) eq "HASH") {
3800         print "r is a reference to a hash.\n";
3801     }
3802     unless (ref($r)) {
3803         print "r is not a reference at all.\n";
3804     }
3805     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3806         print "r is a reference to something that isa hash.\n";
3807     }
3808
3809 See also L<perlref>.
3810
3811 =item rename OLDNAME,NEWNAME
3812
3813 Changes the name of a file; an existing file NEWNAME will be
3814 clobbered.  Returns true for success, false otherwise.
3815
3816 Behavior of this function varies wildly depending on your system
3817 implementation.  For example, it will usually not work across file system
3818 boundaries, even though the system I<mv> command sometimes compensates
3819 for this.  Other restrictions include whether it works on directories,
3820 open files, or pre-existing files.  Check L<perlport> and either the
3821 rename(2) manpage or equivalent system documentation for details.
3822
3823 =item require VERSION
3824
3825 =item require EXPR
3826
3827 =item require
3828
3829 Demands a version of Perl specified by VERSION, or demands some semantics
3830 specified by EXPR or by C<$_> if EXPR is not supplied.
3831
3832 VERSION may be either a numeric argument such as 5.006, which will be
3833 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
3834 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
3835 VERSION is greater than the version of the current Perl interpreter.
3836 Compare with L</use>, which can do a similar check at compile time.
3837
3838 Specifying VERSION as a literal of the form v5.6.1 should generally be
3839 avoided, because it leads to misleading error messages under earlier
3840 versions of Perl which do not support this syntax.  The equivalent numeric
3841 version should be used instead.
3842
3843     require v5.6.1;     # run time version check
3844     require 5.6.1;      # ditto
3845     require 5.006_001;  # ditto; preferred for backwards compatibility
3846
3847 Otherwise, demands that a library file be included if it hasn't already
3848 been included.  The file is included via the do-FILE mechanism, which is
3849 essentially just a variety of C<eval>.  Has semantics similar to the following
3850 subroutine:
3851
3852     sub require {
3853         my($filename) = @_;
3854         return 1 if $INC{$filename};
3855         my($realfilename,$result);
3856         ITER: {
3857             foreach $prefix (@INC) {
3858                 $realfilename = "$prefix/$filename";
3859                 if (-f $realfilename) {
3860                     $INC{$filename} = $realfilename;
3861                     $result = do $realfilename;
3862                     last ITER;
3863                 }
3864             }
3865             die "Can't find $filename in \@INC";
3866         }
3867         delete $INC{$filename} if $@ || !$result;
3868         die $@ if $@;
3869         die "$filename did not return true value" unless $result;
3870         return $result;
3871     }
3872
3873 Note that the file will not be included twice under the same specified
3874 name.  The file must return true as the last statement to indicate
3875 successful execution of any initialization code, so it's customary to
3876 end such a file with C<1;> unless you're sure it'll return true
3877 otherwise.  But it's better just to put the C<1;>, in case you add more
3878 statements.
3879
3880 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3881 replaces "F<::>" with "F</>" in the filename for you,
3882 to make it easy to load standard modules.  This form of loading of
3883 modules does not risk altering your namespace.
3884
3885 In other words, if you try this:
3886
3887         require Foo::Bar;    # a splendid bareword
3888
3889 The require function will actually look for the "F<Foo/Bar.pm>" file in the
3890 directories specified in the C<@INC> array.
3891
3892 But if you try this:
3893
3894         $class = 'Foo::Bar';
3895         require $class;      # $class is not a bareword
3896     #or
3897         require "Foo::Bar";  # not a bareword because of the ""
3898
3899 The require function will look for the "F<Foo::Bar>" file in the @INC array and
3900 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3901
3902         eval "require $class";
3903
3904 You can also insert hooks into the import facility, by putting directly
3905 Perl code into the @INC array.  There are three forms of hooks: subroutine
3906 references, array references and blessed objects.
3907
3908 Subroutine references are the simplest case.  When the inclusion system
3909 walks through @INC and encounters a subroutine, this subroutine gets
3910 called with two parameters, the first being a reference to itself, and the
3911 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
3912 subroutine should return C<undef> or a filehandle, from which the file to
3913 include will be read.  If C<undef> is returned, C<require> will look at
3914 the remaining elements of @INC.
3915
3916 If the hook is an array reference, its first element must be a subroutine
3917 reference.  This subroutine is called as above, but the first parameter is
3918 the array reference.  This enables to pass indirectly some arguments to
3919 the subroutine.
3920
3921 In other words, you can write:
3922
3923     push @INC, \&my_sub;
3924     sub my_sub {
3925         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
3926         ...
3927     }
3928
3929 or:
3930
3931     push @INC, [ \&my_sub, $x, $y, ... ];
3932     sub my_sub {
3933         my ($arrayref, $filename) = @_;
3934         # Retrieve $x, $y, ...
3935         my @parameters = @$arrayref[1..$#$arrayref];
3936         ...
3937     }
3938
3939 If the hook is an object, it must provide an INC method, that will be
3940 called as above, the first parameter being the object itself.  (Note that
3941 you must fully qualify the sub's name, as it is always forced into package
3942 C<main>.)  Here is a typical code layout:
3943
3944     # In Foo.pm
3945     package Foo;
3946     sub new { ... }
3947     sub Foo::INC {
3948         my ($self, $filename) = @_;
3949         ...
3950     }
3951
3952     # In the main program
3953     push @INC, new Foo(...);
3954
3955 Note that these hooks are also permitted to set the %INC entry
3956 corresponding to the files they have loaded. See L<perlvar/%INC>.
3957
3958 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3959
3960 =item reset EXPR
3961
3962 =item reset
3963
3964 Generally used in a C<continue> block at the end of a loop to clear
3965 variables and reset C<??> searches so that they work again.  The
3966 expression is interpreted as a list of single characters (hyphens
3967 allowed for ranges).  All variables and arrays beginning with one of
3968 those letters are reset to their pristine state.  If the expression is
3969 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3970 only variables or searches in the current package.  Always returns
3971 1.  Examples:
3972
3973     reset 'X';          # reset all X variables
3974     reset 'a-z';        # reset lower case variables
3975     reset;              # just reset ?one-time? searches
3976
3977 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3978 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
3979 variables--lexical variables are unaffected, but they clean themselves
3980 up on scope exit anyway, so you'll probably want to use them instead.
3981 See L</my>.
3982
3983 =item return EXPR
3984
3985 =item return
3986
3987 Returns from a subroutine, C<eval>, or C<do FILE> with the value
3988 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3989 context, depending on how the return value will be used, and the context
3990 may vary from one execution to the next (see C<wantarray>).  If no EXPR
3991 is given, returns an empty list in list context, the undefined value in
3992 scalar context, and (of course) nothing at all in a void context.
3993
3994 (Note that in the absence of an explicit C<return>, a subroutine, eval,
3995 or do FILE will automatically return the value of the last expression
3996 evaluated.)
3997
3998 =item reverse LIST
3999
4000 In list context, returns a list value consisting of the elements
4001 of LIST in the opposite order.  In scalar context, concatenates the
4002 elements of LIST and returns a string value with all characters
4003 in the opposite order.
4004
4005     print reverse <>;           # line tac, last line first
4006
4007     undef $/;                   # for efficiency of <>
4008     print scalar reverse <>;    # character tac, last line tsrif
4009
4010 This operator is also handy for inverting a hash, although there are some
4011 caveats.  If a value is duplicated in the original hash, only one of those
4012 can be represented as a key in the inverted hash.  Also, this has to
4013 unwind one hash and build a whole new one, which may take some time
4014 on a large hash, such as from a DBM file.
4015
4016     %by_name = reverse %by_address;     # Invert the hash
4017
4018 =item rewinddir DIRHANDLE
4019
4020 Sets the current position to the beginning of the directory for the
4021 C<readdir> routine on DIRHANDLE.
4022
4023 =item rindex STR,SUBSTR,POSITION
4024
4025 =item rindex STR,SUBSTR
4026
4027 Works just like index() except that it returns the position of the LAST
4028 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4029 last occurrence at or before that position.
4030
4031 =item rmdir FILENAME
4032
4033 =item rmdir
4034
4035 Deletes the directory specified by FILENAME if that directory is empty.  If it
4036 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
4037 FILENAME is omitted, uses C<$_>.
4038
4039 =item s///
4040
4041 The substitution operator.  See L<perlop>.
4042
4043 =item scalar EXPR
4044
4045 Forces EXPR to be interpreted in scalar context and returns the value
4046 of EXPR.
4047
4048     @counts = ( scalar @a, scalar @b, scalar @c );
4049
4050 There is no equivalent operator to force an expression to
4051 be interpolated in list context because in practice, this is never
4052 needed.  If you really wanted to do so, however, you could use
4053 the construction C<@{[ (some expression) ]}>, but usually a simple
4054 C<(some expression)> suffices.
4055
4056 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4057 parenthesized list, this behaves as a scalar comma expression, evaluating
4058 all but the last element in void context and returning the final element
4059 evaluated in scalar context.  This is seldom what you want.
4060
4061 The following single statement:
4062
4063         print uc(scalar(&foo,$bar)),$baz;
4064
4065 is the moral equivalent of these two:
4066
4067         &foo;
4068         print(uc($bar),$baz);
4069
4070 See L<perlop> for more details on unary operators and the comma operator.
4071
4072 =item seek FILEHANDLE,POSITION,WHENCE
4073
4074 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4075 FILEHANDLE may be an expression whose value gives the name of the
4076 filehandle.  The values for WHENCE are C<0> to set the new position
4077 I<in bytes> to POSITION, C<1> to set it to the current position plus
4078 POSITION, and C<2> to set it to EOF plus POSITION (typically
4079 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4080 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4081 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4082 otherwise.
4083
4084 Note the I<in bytes>: even if the filehandle has been set to
4085 operate on characters (for example by using the C<:utf8> open
4086 discipline), tell() will return byte offsets, not character offsets
4087 (because implementing that would render seek() and tell() rather slow).
4088
4089 If you want to position file for C<sysread> or C<syswrite>, don't use
4090 C<seek>--buffering makes its effect on the file's system position
4091 unpredictable and non-portable.  Use C<sysseek> instead.
4092
4093 Due to the rules and rigors of ANSI C, on some systems you have to do a
4094 seek whenever you switch between reading and writing.  Amongst other
4095 things, this may have the effect of calling stdio's clearerr(3).
4096 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4097
4098     seek(TEST,0,1);
4099
4100 This is also useful for applications emulating C<tail -f>.  Once you hit
4101 EOF on your read, and then sleep for a while, you might have to stick in a
4102 seek() to reset things.  The C<seek> doesn't change the current position,
4103 but it I<does> clear the end-of-file condition on the handle, so that the
4104 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4105
4106 If that doesn't work (some IO implementations are particularly
4107 cantankerous), then you may need something more like this:
4108
4109     for (;;) {
4110         for ($curpos = tell(FILE); $_ = <FILE>;
4111              $curpos = tell(FILE)) {
4112             # search for some stuff and put it into files
4113         }
4114         sleep($for_a_while);
4115         seek(FILE, $curpos, 0);
4116     }
4117
4118 =item seekdir DIRHANDLE,POS
4119
4120 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4121 must be a value returned by C<telldir>.  Has the same caveats about
4122 possible directory compaction as the corresponding system library
4123 routine.
4124
4125 =item select FILEHANDLE
4126
4127 =item select
4128
4129 Returns the currently selected filehandle.  Sets the current default
4130 filehandle for output, if FILEHANDLE is supplied.  This has two
4131 effects: first, a C<write> or a C<print> without a filehandle will
4132 default to this FILEHANDLE.  Second, references to variables related to
4133 output will refer to this output channel.  For example, if you have to
4134 set the top of form format for more than one output channel, you might
4135 do the following:
4136
4137     select(REPORT1);
4138     $^ = 'report1_top';
4139     select(REPORT2);
4140     $^ = 'report2_top';
4141
4142 FILEHANDLE may be an expression whose value gives the name of the
4143 actual filehandle.  Thus:
4144
4145     $oldfh = select(STDERR); $| = 1; select($oldfh);
4146
4147 Some programmers may prefer to think of filehandles as objects with
4148 methods, preferring to write the last example as:
4149
4150     use IO::Handle;
4151     STDERR->autoflush(1);
4152
4153 =item select RBITS,WBITS,EBITS,TIMEOUT
4154
4155 This calls the select(2) system call with the bit masks specified, which
4156 can be constructed using C<fileno> and C<vec>, along these lines:
4157
4158     $rin = $win = $ein = '';
4159     vec($rin,fileno(STDIN),1) = 1;
4160     vec($win,fileno(STDOUT),1) = 1;
4161     $ein = $rin | $win;
4162
4163 If you want to select on many filehandles you might wish to write a
4164 subroutine:
4165
4166     sub fhbits {
4167         my(@fhlist) = split(' ',$_[0]);
4168         my($bits);
4169         for (@fhlist) {
4170             vec($bits,fileno($_),1) = 1;
4171         }
4172         $bits;
4173     }
4174     $rin = fhbits('STDIN TTY SOCK');
4175
4176 The usual idiom is:
4177
4178     ($nfound,$timeleft) =
4179       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4180
4181 or to block until something becomes ready just do this
4182
4183     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4184
4185 Most systems do not bother to return anything useful in $timeleft, so
4186 calling select() in scalar context just returns $nfound.
4187
4188 Any of the bit masks can also be undef.  The timeout, if specified, is
4189 in seconds, which may be fractional.  Note: not all implementations are
4190 capable of returning the $timeleft.  If not, they always return
4191 $timeleft equal to the supplied $timeout.
4192
4193 You can effect a sleep of 250 milliseconds this way:
4194
4195     select(undef, undef, undef, 0.25);
4196
4197 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4198 or <FH>) with C<select>, except as permitted by POSIX, and even
4199 then only on POSIX systems.  You have to use C<sysread> instead.
4200
4201 =item semctl ID,SEMNUM,CMD,ARG
4202
4203 Calls the System V IPC function C<semctl>.  You'll probably have to say
4204
4205     use IPC::SysV;
4206
4207 first to get the correct constant definitions.  If CMD is IPC_STAT or
4208 GETALL, then ARG must be a variable which will hold the returned
4209 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4210 the undefined value for error, "C<0 but true>" for zero, or the actual
4211 return value otherwise.  The ARG must consist of a vector of native
4212 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4213 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4214 documentation.
4215
4216 =item semget KEY,NSEMS,FLAGS
4217
4218 Calls the System V IPC function semget.  Returns the semaphore id, or
4219 the undefined value if there is an error.  See also
4220 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4221 documentation.
4222
4223 =item semop KEY,OPSTRING
4224
4225 Calls the System V IPC function semop to perform semaphore operations
4226 such as signalling and waiting.  OPSTRING must be a packed array of
4227 semop structures.  Each semop structure can be generated with
4228 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4229 operations is implied by the length of OPSTRING.  Returns true if
4230 successful, or false if there is an error.  As an example, the
4231 following code waits on semaphore $semnum of semaphore id $semid:
4232
4233     $semop = pack("s!3", $semnum, -1, 0);
4234     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4235
4236 To signal the semaphore, replace C<-1> with C<1>.  See also
4237 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4238 documentation.
4239
4240 =item send SOCKET,MSG,FLAGS,TO
4241
4242 =item send SOCKET,MSG,FLAGS
4243
4244 Sends a message on a socket.  Attempts to send the scalar MSG to the
4245 SOCKET filehandle.  Takes the same flags as the system call of the
4246 same name.  On unconnected sockets you must specify a destination to
4247 send TO, in which case it does a C C<sendto>.  Returns the number of
4248 characters sent, or the undefined value if there is an error.  The C
4249 system call sendmsg(2) is currently unimplemented.  See
4250 L<perlipc/"UDP: Message Passing"> for examples.
4251
4252 Note the I<characters>: depending on the status of the socket, either
4253 (8-bit) bytes or characters are sent.  By default all sockets operate
4254 on bytes, but for example if the socket has been changed using
4255 binmode() to operate with the C<:utf8> discipline (see L</open>, or
4256 the C<open> pragma, L<open>), the I/O will operate on characters, not
4257 bytes.
4258
4259 =item setpgrp PID,PGRP
4260
4261 Sets the current process group for the specified PID, C<0> for the current
4262 process.  Will produce a fatal error if used on a machine that doesn't
4263 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4264 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4265 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4266 C<POSIX::setsid()>.
4267
4268 =item setpriority WHICH,WHO,PRIORITY
4269
4270 Sets the current priority for a process, a process group, or a user.
4271 (See setpriority(2).)  Will produce a fatal error if used on a machine
4272 that doesn't implement setpriority(2).
4273
4274 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4275
4276 Sets the socket option requested.  Returns undefined if there is an
4277 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4278 argument.
4279
4280 =item shift ARRAY
4281
4282 =item shift
4283
4284 Shifts the first value of the array off and returns it, shortening the
4285 array by 1 and moving everything down.  If there are no elements in the
4286 array, returns the undefined value.  If ARRAY is omitted, shifts the
4287 C<@_> array within the lexical scope of subroutines and formats, and the
4288 C<@ARGV> array at file scopes or within the lexical scopes established by
4289 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4290 constructs.
4291
4292 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4293 same thing to the left end of an array that C<pop> and C<push> do to the
4294 right end.
4295
4296 =item shmctl ID,CMD,ARG
4297
4298 Calls the System V IPC function shmctl.  You'll probably have to say
4299
4300     use IPC::SysV;
4301
4302 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4303 then ARG must be a variable which will hold the returned C<shmid_ds>
4304 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4305 true" for zero, or the actual return value otherwise.
4306 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4307
4308 =item shmget KEY,SIZE,FLAGS
4309
4310 Calls the System V IPC function shmget.  Returns the shared memory
4311 segment id, or the undefined value if there is an error.
4312 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4313
4314 =item shmread ID,VAR,POS,SIZE
4315
4316 =item shmwrite ID,STRING,POS,SIZE
4317
4318 Reads or writes the System V shared memory segment ID starting at
4319 position POS for size SIZE by attaching to it, copying in/out, and
4320 detaching from it.  When reading, VAR must be a variable that will
4321 hold the data read.  When writing, if STRING is too long, only SIZE
4322 bytes are used; if STRING is too short, nulls are written to fill out
4323 SIZE bytes.  Return true if successful, or false if there is an error.
4324 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4325 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4326
4327 =item shutdown SOCKET,HOW
4328
4329 Shuts down a socket connection in the manner indicated by HOW, which
4330 has the same interpretation as in the system call of the same name.
4331
4332     shutdown(SOCKET, 0);    # I/we have stopped reading data
4333     shutdown(SOCKET, 1);    # I/we have stopped writing data
4334     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4335
4336 This is useful with sockets when you want to tell the other
4337 side you're done writing but not done reading, or vice versa.
4338 It's also a more insistent form of close because it also
4339 disables the file descriptor in any forked copies in other
4340 processes.
4341
4342 =item sin EXPR
4343
4344 =item sin
4345
4346 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4347 returns sine of C<$_>.
4348
4349 For the inverse sine operation, you may use the C<Math::Trig::asin>
4350 function, or use this relation:
4351
4352     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4353
4354 =item sleep EXPR
4355
4356 =item sleep
4357
4358 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4359 May be interrupted if the process receives a signal such as C<SIGALRM>.
4360 Returns the number of seconds actually slept.  You probably cannot
4361 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4362 using C<alarm>.
4363
4364 On some older systems, it may sleep up to a full second less than what
4365 you requested, depending on how it counts seconds.  Most modern systems
4366 always sleep the full amount.  They may appear to sleep longer than that,
4367 however, because your process might not be scheduled right away in a
4368 busy multitasking system.
4369
4370 For delays of finer granularity than one second, you may use Perl's
4371 C<syscall> interface to access setitimer(2) if your system supports
4372 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
4373 and starting from Perl 5.8 part of the standard distribution) may also
4374 help.
4375
4376 See also the POSIX module's C<pause> function.
4377
4378 =item sockatmark SOCKET
4379
4380 Returns true if the socket is positioned at the out-of-band mark
4381 (also known as the urgent data mark), false otherwise.  Use right
4382 after reading from the socket.
4383
4384 Not available directly, one has to import the function from
4385 the IO::Socket extension
4386
4387     use IO::Socket 'sockatmark';
4388
4389 Even this doesn't guarantee that sockatmark() really is available,
4390 though, because sockatmark() is a relatively recent addition to
4391 the family of socket functions.  If it is unavailable, attempt to
4392 use it will fail
4393
4394         IO::Socket::atmark not implemented on this architecture ...
4395
4396 See also L<IO::Socket>.
4397
4398 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4399
4400 Opens a socket of the specified kind and attaches it to filehandle
4401 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4402 the system call of the same name.  You should C<use Socket> first
4403 to get the proper definitions imported.  See the examples in
4404 L<perlipc/"Sockets: Client/Server Communication">.
4405
4406 On systems that support a close-on-exec flag on files, the flag will
4407 be set for the newly opened file descriptor, as determined by the
4408 value of $^F.  See L<perlvar/$^F>.
4409
4410 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4411
4412 Creates an unnamed pair of sockets in the specified domain, of the
4413 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4414 for the system call of the same name.  If unimplemented, yields a fatal
4415 error.  Returns true if successful.
4416
4417 On systems that support a close-on-exec flag on files, the flag will
4418 be set for the newly opened file descriptors, as determined by the value
4419 of $^F.  See L<perlvar/$^F>.
4420
4421 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4422 to C<pipe(Rdr, Wtr)> is essentially:
4423
4424     use Socket;
4425     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4426     shutdown(Rdr, 1);        # no more writing for reader
4427     shutdown(Wtr, 0);        # no more reading for writer
4428
4429 See L<perlipc> for an example of socketpair use.  Perl 5.8 and later will
4430 emulate socketpair using IP sockets to localhost if your system implements
4431 sockets but not socketpair.
4432
4433 =item sort SUBNAME LIST
4434
4435 =item sort BLOCK LIST
4436
4437 =item sort LIST
4438
4439 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
4440 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
4441 specified, it gives the name of a subroutine that returns an integer
4442 less than, equal to, or greater than C<0>, depending on how the elements
4443 of the list are to be ordered.  (The C<< <=> >> and C<cmp>
4444 operators are extremely useful in such routines.)  SUBNAME may be a
4445 scalar variable name (unsubscripted), in which case the value provides
4446 the name of (or a reference to) the actual subroutine to use.  In place
4447 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
4448 subroutine.
4449
4450 If the subroutine's prototype is C<($$)>, the elements to be compared
4451 are passed by reference in C<@_>, as for a normal subroutine.  This is
4452 slower than unprototyped subroutines, where the elements to be
4453 compared are passed into the subroutine
4454 as the package global variables $a and $b (see example below).  Note that
4455 in the latter case, it is usually counter-productive to declare $a and
4456 $b as lexicals.
4457
4458 In either case, the subroutine may not be recursive.  The values to be
4459 compared are always passed by reference, so don't modify them.
4460
4461 You also cannot exit out of the sort block or subroutine using any of the
4462 loop control operators described in L<perlsyn> or with C<goto>.
4463
4464 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4465 current collation locale.  See L<perllocale>.
4466
4467 Perl 5.6 and earlier used a quicksort algorithm to implement sort.
4468 That algorithm was not stable, and I<could> go quadratic.  (A I<stable> sort
4469 preserves the input order of elements that compare equal.  Although
4470 quicksort's run time is O(NlogN) when averaged over all arrays of
4471 length N, the time can be O(N**2), I<quadratic> behavior, for some
4472 inputs.)  In 5.7, the quicksort implementation was replaced with
4473 a stable mergesort algorithm whose worst case behavior is O(NlogN).
4474 But benchmarks indicated that for some inputs, on some platforms,
4475 the original quicksort was faster.  5.8 has a sort pragma for
4476 limited control of the sort.  Its rather blunt control of the
4477 underlying algorithm may not persist into future perls, but the
4478 ability to characterize the input or output in implementation
4479 independent ways quite probably will.  See L</use>.
4480
4481 Examples:
4482
4483     # sort lexically
4484     @articles = sort @files;
4485
4486     # same thing, but with explicit sort routine
4487     @articles = sort {$a cmp $b} @files;
4488
4489     # now case-insensitively
4490     @articles = sort {uc($a) cmp uc($b)} @files;
4491
4492     # same thing in reversed order
4493     @articles = sort {$b cmp $a} @files;
4494
4495     # sort numerically ascending
4496     @articles = sort {$a <=> $b} @files;
4497
4498     # sort numerically descending
4499     @articles = sort {$b <=> $a} @files;
4500
4501     # this sorts the %age hash by value instead of key
4502     # using an in-line function
4503     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4504
4505     # sort using explicit subroutine name
4506     sub byage {
4507         $age{$a} <=> $age{$b};  # presuming numeric
4508     }
4509     @sortedclass = sort byage @class;
4510
4511     sub backwards { $b cmp $a }
4512     @harry  = qw(dog cat x Cain Abel);
4513     @george = qw(gone chased yz Punished Axed);
4514     print sort @harry;
4515             # prints AbelCaincatdogx
4516     print sort backwards @harry;
4517             # prints xdogcatCainAbel
4518     print sort @george, 'to', @harry;
4519             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4520
4521     # inefficiently sort by descending numeric compare using
4522     # the first integer after the first = sign, or the
4523     # whole record case-insensitively otherwise
4524
4525     @new = sort {
4526         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4527                             ||
4528                     uc($a)  cmp  uc($b)
4529     } @old;
4530
4531     # same thing, but much more efficiently;
4532     # we'll build auxiliary indices instead
4533     # for speed
4534     @nums = @caps = ();
4535     for (@old) {
4536         push @nums, /=(\d+)/;
4537         push @caps, uc($_);
4538     }
4539
4540     @new = @old[ sort {
4541                         $nums[$b] <=> $nums[$a]
4542                                  ||
4543                         $caps[$a] cmp $caps[$b]
4544                        } 0..$#old
4545                ];
4546
4547     # same thing, but without any temps
4548     @new = map { $_->[0] }
4549            sort { $b->[1] <=> $a->[1]
4550                            ||
4551                   $a->[2] cmp $b->[2]
4552            } map { [$_, /=(\d+)/, uc($_)] } @old;
4553
4554     # using a prototype allows you to use any comparison subroutine
4555     # as a sort subroutine (including other package's subroutines)
4556     package other;
4557     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4558
4559     package main;
4560     @new = sort other::backwards @old;
4561
4562     # guarantee stability, regardless of algorithm
4563     use sort 'stable';
4564     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4565
4566     # force use of quicksort (not portable outside Perl 5.8)
4567     use sort '_quicksort';  # note discouraging _
4568     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4569
4570     # similar to the previous example, but demand stability as well
4571     use sort qw( _mergesort stable );
4572     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4573
4574 If you're using strict, you I<must not> declare $a
4575 and $b as lexicals.  They are package globals.  That means
4576 if you're in the C<main> package and type
4577
4578     @articles = sort {$b <=> $a} @files;
4579
4580 then C<$a> and C<$b> are C<$main::a> and C<$main::b> (or C<$::a> and C<$::b>),
4581 but if you're in the C<FooPack> package, it's the same as typing
4582
4583     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
4584
4585 The comparison function is required to behave.  If it returns
4586 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4587 sometimes saying the opposite, for example) the results are not
4588 well-defined.
4589
4590 =item splice ARRAY,OFFSET,LENGTH,LIST
4591
4592 =item splice ARRAY,OFFSET,LENGTH
4593
4594 =item splice ARRAY,OFFSET
4595
4596 =item splice ARRAY
4597
4598 Removes the elements designated by OFFSET and LENGTH from an array, and
4599 replaces them with the elements of LIST, if any.  In list context,
4600 returns the elements removed from the array.  In scalar context,
4601 returns the last element removed, or C<undef> if no elements are
4602 removed.  The array grows or shrinks as necessary.
4603 If OFFSET is negative then it starts that far from the end of the array.
4604 If LENGTH is omitted, removes everything from OFFSET onward.
4605 If LENGTH is negative, leaves that many elements off the end of the array.
4606 If both OFFSET and LENGTH are omitted, removes everything.
4607
4608 The following equivalences hold (assuming C<$[ == 0>):
4609
4610     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
4611     pop(@a)             splice(@a,-1)
4612     shift(@a)           splice(@a,0,1)
4613     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
4614     $a[$x] = $y         splice(@a,$x,1,$y)
4615
4616 Example, assuming array lengths are passed before arrays:
4617
4618     sub aeq {   # compare two list values
4619         my(@a) = splice(@_,0,shift);
4620         my(@b) = splice(@_,0,shift);
4621         return 0 unless @a == @b;       # same len?
4622         while (@a) {
4623             return 0 if pop(@a) ne pop(@b);
4624         }
4625         return 1;
4626     }
4627     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
4628
4629 =item split /PATTERN/,EXPR,LIMIT
4630
4631 =item split /PATTERN/,EXPR
4632
4633 =item split /PA