Porting/corelist.pl

   1 #!perl
   2 # Generates info for Module::CoreList from this perl tree
   3 # run this from the root of a perl tree
   4 #
   5 # Data is on STDOUT.
   6 #
   7 # With an optional arg specifying the root of a CPAN mirror, outputs the
   8 # %upstream and %bug_tracker hashes too.
   9
  10 use autodie;
  11 use strict;
  12 use warnings;
  13 no  warnings 'experimental::aggref';
  14 use File::Find;
  15 use ExtUtils::MM_Unix;
  16 use version;
  17 use lib "Porting";
  18 use Maintainers qw(%Modules files_to_modules);
  19 use File::Spec;
  20 use Parse::CPAN::Meta;
  21 use IPC::Cmd 'can_run';
  22 use HTTP::Tiny;
  23 use IO::Uncompress::Gunzip;
  24
  25 my $corelist_file = 'dist/Module-CoreList/lib/Module/CoreList.pm';
  26 my $utils_file = 'dist/Module-CoreList/lib/Module/CoreList/Utils.pm';
  27 my $pod_file = 'dist/Module-CoreList/lib/Module/CoreList.pod';
  28
  29 my %lines;
  30 my %module_to_file;
  31 my %modlist;
  32
  33 die "usage: $0 [ cpan-mirror/ ] [ 5.x.y] \n" unless @ARGV <= 2;
  34 my $cpan         = shift;
  35 my $raw_version  = shift || $];
  36 my $perl_version = version->parse("$raw_version");
  37 my $perl_vnum    = $perl_version->numify;
  38 my $perl_vstring = $perl_version->normal; # how do we get version.pm to not give us leading v?
  39 $perl_vstring =~ s/^v//;
  40
  41 if ( !-f 'MANIFEST' ) {
  42     die "Must be run from the root of a clean perl tree\n";
  43 }
  44
  45 open( my $corelist_fh, '<', $corelist_file );
  46 my $corelist = join( '', <$corelist_fh> );
  47 close $corelist_fh;
  48
  49 unless (
  50     $corelist =~ /^%released \s* = \s* \(
  51         .*?
  52         $perl_vnum \s* => \s* .*?
  53         \);/ismx
  54     )
  55 {
  56     warn "Adding $perl_vnum to the list of released perl versions. Please consider adding a release date.\n";
  57     $corelist =~ s/^(%released \s* = \s* .*?) ( \) )
  58                 /$1  $perl_vnum => '????-??-??',\n  $2/ismx;
  59 }
  60
  61 if ($cpan) {
  62     my $modlistfile = File::Spec->catfile( $cpan, 'modules', '02packages.details.txt' );
  63     my $content;
  64
  65     my $fh;
  66     if ( -e $modlistfile ) {
  67         warn "Reading the module list from $modlistfile";
  68         open $fh, '<', $modlistfile;
  69     } elsif ( -e $modlistfile . ".gz" ) {
  70         my $zcat = can_run('gzcat') || can_run('zcat') or die "Can't find gzcat or zcat";
  71         warn "Reading the module list from $modlistfile.gz";
  72         open $fh, '-|', "$zcat $modlistfile.gz";
  73     } else {
  74         warn "About to fetch 02packages from ftp.funet.fi. This may take a few minutes\n";
  75         my $gzipped_content = fetch_url('http://ftp.funet.fi/pub/CPAN/modules/02packages.details.txt.gz');
  76         unless ($gzipped_content) {
  77             die "Unable to read 02packages.details.txt from either your CPAN mirror or ftp.funet.fi";
  78         }
  79         IO::Uncompress::Gunzip::gunzip(\$gzipped_content, \$content, Transparent => 0)
  80             or die "Can't gunzip content: $IO::Uncompress::Gunzip::GunzipError";
  81     }
  82
  83     if ( $fh and !$content ) {
  84         local $/ = "\n";
  85         $content = join( '', <$fh> );
  86     }
  87
  88     die "Incompatible modlist format"
  89         unless $content =~ /^Columns: +package name, version, path/m;
  90
  91     # Converting the file to a hash is about 5 times faster than a regexp flat
  92     # lookup.
  93     for ( split( qr/\n/, $content ) ) {
  94         next unless /^([A-Za-z_:0-9]+) +[-0-9.undefHASHVERSIONvsetwhenloadingbogus]+ +(\S+)/;
  95         $modlist{$1} = $2;
  96     }
  97 }
  98
  99 find(
 100     sub {
 101         /(\.pm|_pm\.PL)$/ or return;
 102         /PPPort\.pm$/ and return;
 103         my $module = $File::Find::name;
 104         $module =~ /\b(demo|t|private)\b/ and return;    # demo or test modules
 105         my $version = MM->parse_version($_);
 106         defined $version or $version = 'undef';
 107         $version =~ /\d/ and $version = "'$version'";
 108
 109         # some heuristics to figure out the module name from the file name
 110         $module =~ s{^(lib|cpan|dist|(?:symbian/)?ext)/}{}
 111                         and $1 ne 'lib'
 112             and (
 113             $module =~ s{\b(\w+)/\1\b}{$1},
 114             $module =~ s{^B/O}{O},
 115             $module =~ s{^Devel-PPPort}{Devel},
 116             $module =~ s{^libnet/}{},
 117             $module =~ s{^Encode/encoding}{encoding},
 118             $module =~ s{^IPC-SysV/}{IPC/},
 119             $module =~ s{^MIME-Base64/QuotedPrint}{MIME/QuotedPrint},
 120             $module =~ s{^(?:DynaLoader|Errno|Opcode|XSLoader)/}{},
 121             $module =~ s{^Sys-Syslog/win32}{Sys-Syslog},
 122             $module =~ s{^Time-Piece/Seconds}{Time/Seconds},
 123             );
 124                 $module =~ s{^lib/}{}g;
 125         $module =~ s{/}{::}g;
 126         $module =~ s{-}{::}g;
 127                 $module =~ s{^.*::lib::}{}; # turns Foo/lib/Foo.pm into Foo.pm
 128         $module =~ s/(\.pm|_pm\.PL)$//;
 129         $lines{$module}          = $version;
 130         $module_to_file{$module} = $File::Find::name;
 131     },
 132     'symbian/ext',
 133     'lib',
 134     'ext',
 135         'cpan',
 136         'dist'
 137 );
 138
 139 -e 'configpm' and $lines{Config} = "$]";
 140
 141 if ( open my $ucdv, "<", "lib/unicore/version" ) {
 142     chomp( my $ucd = <$ucdv> );
 143     $lines{Unicode} = "'$ucd'";
 144     close $ucdv;
 145 }
 146
 147 my $delta_data = make_corelist_delta(
 148   $perl_vnum,
 149   \%lines,
 150   \%Module::CoreList::version
 151 );
 152
 153 my $versions_in_release = "    " . $perl_vnum . " => {\n";
 154 $versions_in_release .= "        delta_from => $delta_data->{delta_from},\n";
 155 $versions_in_release .= "        changed => {\n";
 156 foreach my $key (sort keys $delta_data->{changed}) {
 157   $versions_in_release .= sprintf "            %-24s=> %s,\n", "'$key'",
 158       defined $delta_data->{changed}{$key} ? "'"
 159         . $delta_data->{changed}{$key} . "'" : "undef";
 160 }
 161 $versions_in_release .= "        },\n";
 162 $versions_in_release .= "        removed => {\n";
 163 for my $key (sort keys($delta_data->{removed} || {})) {
 164   $versions_in_release .= sprintf "            %-24s=> %s,\n", "'$key'", 1;
 165 }
 166 $versions_in_release .= "        }\n";
 167 $versions_in_release .= "    },\n";
 168
 169 $corelist =~ s/^(%delta\s*=\s*.*?)^\s*$perl_vnum\s*=>\s*{.*?},\s*(^\);)$/$1$2/ism;
 170 $corelist =~ s/^(%delta\s*=\s*.*?)(^\);)$/$1$versions_in_release$2/ism;
 171
 172 exit unless %modlist;
 173
 174 # We have to go through this two stage lookup, given how Maintainers.pl keys its
 175 # data by "Module", which is really a dist.
 176 my $file_to_M = files_to_modules( values %module_to_file );
 177
 178 sub slurp_utf8($) {
 179     open my $fh, "<:utf8", "$_[0]"
 180         or die "can't open $_[0] for reading: $!";
 181     return do { local $/; <$fh> };
 182 }
 183
 184 sub parse_cpan_meta($) {
 185     return Parse::CPAN::Meta->${
 186         $_[0] =~ /\A\x7b/ ? \"load_json_string" : \"load_yaml_string"
 187     }($_[0]);
 188 }
 189
 190 my %module_to_upstream;
 191 my %module_to_dist;
 192 my %dist_to_meta_YAML;
 193 my %module_to_deprecated;
 194 while ( my ( $module, $file ) = each %module_to_file ) {
 195     my $M = $file_to_M->{$file};
 196     next unless $M;
 197     next if $Modules{$M}{MAINTAINER} && $Modules{$M}{MAINTAINER} eq 'P5P';
 198     $module_to_upstream{$module} = $Modules{$M}{UPSTREAM};
 199     $module_to_deprecated{$module} = 1 if $Modules{$M}{DEPRECATED};
 200     next
 201         if defined $module_to_upstream{$module}
 202             && $module_to_upstream{$module} eq 'blead';
 203     my $dist = $modlist{$module};
 204     unless ($dist) {
 205         warn "Can't find a distribution for $module\n";
 206         next;
 207     }
 208     $module_to_dist{$module} = $dist;
 209
 210     next if exists $dist_to_meta_YAML{$dist};
 211
 212     $dist_to_meta_YAML{$dist} = undef;
 213
 214     # Like it or lump it, this has to be Unix format.
 215     my $meta_YAML_path = "authors/id/$dist";
 216     $meta_YAML_path =~ s/(?:tar\.gz|tar\.bz2|zip|tgz)$/meta/
 217         or die "ERROR: bad meta YAML path: '$meta_YAML_path'";
 218     my $meta_YAML_url = 'http://ftp.funet.fi/pub/CPAN/' . $meta_YAML_path;
 219
 220     if ( -e "$cpan/$meta_YAML_path" ) {
 221         $dist_to_meta_YAML{$dist} = parse_cpan_meta(slurp_utf8( $cpan . "/" . $meta_YAML_path ));
 222     } elsif ( my $content = fetch_url($meta_YAML_url) ) {
 223         unless ($content) {
 224             warn "Failed to fetch $meta_YAML_url\n";
 225             next;
 226         }
 227         eval { $dist_to_meta_YAML{$dist} = parse_cpan_meta($content); };
 228         if ( my $err = $@ ) {
 229             warn "$meta_YAML_path: ".$err;
 230             next;
 231         }
 232     } else {
 233         warn "$meta_YAML_path does not exist for $module\n";
 234
 235         # I tried code to open the tarballs with Archive::Tar to find and
 236         # extract META.yml, but only Text-Tabs+Wrap-2006.1117.tar.gz had one,
 237         # so it's not worth including.
 238         next;
 239     }
 240 }
 241
 242 my $upstream_stanza = "%upstream = (\n";
 243 foreach my $module ( sort keys %module_to_upstream ) {
 244     my $upstream = defined $module_to_upstream{$module} ? "'$module_to_upstream{$module}'" : 'undef';
 245     $upstream_stanza .= sprintf "    %-24s=> %s,\n", "'$module'", $upstream;
 246 }
 247 $upstream_stanza .= ");";
 248
 249 $corelist =~ s/^%upstream .*? ;$/$upstream_stanza/ismx;
 250
 251 # Deprecation generation
 252 {
 253   my $delta_data = make_corelist_delta(
 254     $perl_vnum,
 255     \%module_to_deprecated,
 256     do { no warnings 'once'; \%Module::CoreList::deprecated },
 257   );
 258
 259   my $deprecated_stanza = "    " . $perl_vnum . " => {\n";
 260   $deprecated_stanza .= "        delta_from => $delta_data->{delta_from},\n";
 261   $deprecated_stanza .= "        changed => {\n";
 262   foreach my $key (sort keys $delta_data->{changed}) {
 263     $deprecated_stanza .= sprintf "            %-24s=> %s,\n", "'$key'",
 264         defined $delta_data->{changed}{$key} ? "'"
 265           . $delta_data->{changed}{$key} . "'" : "undef";
 266   }
 267   $deprecated_stanza .= "        },\n";
 268   $deprecated_stanza .= "        removed => {\n";
 269   for my $key (sort keys($delta_data->{removed} || {})) {
 270     $deprecated_stanza .= sprintf "           %-24s=> %s,\n", "'$key'", 1;
 271   }
 272   $deprecated_stanza .= "        }\n";
 273   $deprecated_stanza .= "    },\n";
 274
 275   $corelist =~ s/^(%deprecated\s*=\s*.*?)^\s*$perl_vnum\s*=>\s*{.*?},\s*(^\);)$/$1$2/ism;
 276   $corelist =~ s/^(%deprecated\s*=\s*.*?)(^\);)$/$1$deprecated_stanza$2/xism;
 277 }
 278
 279 my $tracker = "%bug_tracker = (\n";
 280 foreach my $module ( sort keys %module_to_upstream ) {
 281     my $upstream = defined $module_to_upstream{$module};
 282     next
 283         if defined $upstream and $upstream eq 'blead';
 284
 285     my $bug_tracker;
 286
 287     my $dist = $module_to_dist{$module};
 288     $bug_tracker = $dist_to_meta_YAML{$dist}->{resources}{bugtracker}
 289         if $dist;
 290     $bug_tracker = $bug_tracker->{web} if ref($bug_tracker) eq "HASH";
 291
 292     $bug_tracker = defined $bug_tracker ? quote($bug_tracker) : 'undef';
 293         next if $bug_tracker eq "'http://rt.perl.org/perlbug/'";
 294     $tracker .= sprintf "    %-24s=> %s,\n", "'$module'", $bug_tracker;
 295 }
 296 $tracker .= ");";
 297
 298 $corelist =~ s/^%bug_tracker .*? ;/$tracker/eismx;
 299
 300 write_corelist($corelist,$corelist_file);
 301
 302 open( my $pod_fh, '<', $pod_file );
 303 my $pod = join( '', <$pod_fh> );
 304
 305 unless ( $pod =~ /and $perl_vstring releases of perl/ ) {
 306     warn "Adding $perl_vstring to the list of perl versions covered by Module::CoreList\n";
 307     $pod =~ s/(currently\s+covers\s+(?:.*?))\s*and\s+(.*?)\s+releases\s+of\s+perl/$1, $2 and $perl_vstring releases of perl/ism;
 308 }
 309
 310 write_corelist($pod,$pod_file);
 311
 312 open( my $utils_fh, '<', $utils_file );
 313 my $utils = join( '', <$utils_fh> );
 314 close $utils_fh;
 315
 316 my %utils = map { ( $_ => 1 ) } parse_utils_lst();
 317
 318 my $delta_utils = make_coreutils_delta($perl_vnum, \%utils);
 319
 320 my $utilities_in_release = "    " . $perl_vnum . " => {\n";
 321 $utilities_in_release .= "        delta_from => $delta_utils->{delta_from},\n";
 322 $utilities_in_release .= "        changed => {\n";
 323 foreach my $key (sort keys $delta_utils->{changed}) {
 324   $utilities_in_release .= sprintf "            %-24s=> %s,\n", "'$key'",
 325       defined $delta_utils->{changed}{$key} ? "'"
 326         . $delta_utils->{changed}{$key} . "'" : "undef";
 327 }
 328 $utilities_in_release .= "        },\n";
 329 $utilities_in_release .= "        removed => {\n";
 330 for my $key (sort keys($delta_utils->{removed} || {})) {
 331   $utilities_in_release .= sprintf "            %-24s=> %s,\n", "'$key'", 1;
 332 }
 333 $utilities_in_release .= "        }\n";
 334 $utilities_in_release .= "    },\n";
 335
 336 $utils =~ s/^(my %delta\s*=\s*.*?)^\s*$perl_vnum\s*=>\s*{.*?},\s*(^\);)$/$1$2/ism;
 337 $utils =~ s/^(my %delta\s*=\s*.*?)(^\);)$/$1$utilities_in_release$2/ism;
 338
 339 write_corelist($utils,$utils_file);
 340
 341 warn "All done. Please check over the following files carefully before committing.\nThanks!\n";
 342 warn "$corelist_file\n$pod_file\n$utils_file\n";
 343
 344 sub write_corelist {
 345     my $content = shift;
 346     my $filename = shift;
 347     open (my $clfh, ">", $filename);
 348     binmode $clfh;
 349     print $clfh $content;
 350     close($clfh);
 351 }
 352
 353 sub fetch_url {
 354     my $url = shift;
 355     my $http = HTTP::Tiny->new;
 356     my $response = $http->get($url);
 357     if ($response->{success}) {
 358         return $response->{content};
 359     } else {
 360         warn "Error fetching $url: $response->{status} $response->{reason}\n";
 361         return;
 362     }
 363 }
 364
 365 sub make_corelist_delta {
 366   my($version, $lines, $existing) = @_;
 367   # Trust core perl, if someone does use a weird version number the worst that
 368   # can happen is an extra delta entry for a module.
 369   my %versions = map { $_ => eval $lines->{$_} } keys %$lines;
 370
 371   # Ensure we have the corelist data loaded from this perl checkout, not the system one.
 372   require $corelist_file;
 373
 374   my %deltas;
 375   # Search for the release with the least amount of changes (this avoids having
 376   # to ask for where this perl was branched from).
 377   for my $previous (reverse sort keys %$existing) {
 378     # Shouldn't happen, but ensure we don't load weird data...
 379     next if $previous > $version || $previous == $version && $previous eq $version;
 380
 381     my $delta = $deltas{$previous} = {};
 382     ($delta->{changed}, $delta->{removed}) = calculate_delta(
 383       $existing->{$previous}, \%versions);
 384   }
 385
 386   my $smallest = (sort {
 387       ((keys($deltas{$a}->{changed}) + keys($deltas{$a}->{removed})) <=>
 388        (keys($deltas{$b}->{changed}) + keys($deltas{$b}->{removed}))) ||
 389       $b <=> $a
 390     } keys %deltas)[0];
 391
 392   return {
 393     delta_from => $smallest,
 394     changed => $deltas{$smallest}{changed},
 395     removed => $deltas{$smallest}{removed},
 396   }
 397 }
 398
 399 sub make_coreutils_delta {
 400   my($version, $lines) = @_;
 401   # Trust core perl, if someone does use a weird version number the worst that
 402   # can happen is an extra delta entry for a module.
 403   my %utilities = map { $_ => eval $lines->{$_} } keys %$lines;
 404
 405   # Ensure we have the corelist data loaded from this perl checkout, not the system one.
 406   require $utils_file;
 407
 408   my %deltas;
 409   # Search for the release with the least amount of changes (this avoids having
 410   # to ask for where this perl was branched from).
 411   for my $previous (reverse sort keys %Module::CoreList::Utils::utilities) {
 412     # Shouldn't happen, but ensure we don't load weird data...
 413     next if $previous > $version || $previous == $version && $previous eq $version;
 414
 415     my $delta = $deltas{$previous} = {};
 416     ($delta->{changed}, $delta->{removed}) = calculate_delta(
 417       $Module::CoreList::Utils::utilities{$previous}, \%utilities);
 418   }
 419
 420   my $smallest = (sort {
 421       ((keys($deltas{$a}->{changed}) + keys($deltas{$a}->{removed})) <=>
 422        (keys($deltas{$b}->{changed}) + keys($deltas{$b}->{removed}))) ||
 423       $b <=> $a
 424     } keys %deltas)[0];
 425
 426   return {
 427     delta_from => $smallest,
 428     changed => $deltas{$smallest}{changed},
 429     removed => $deltas{$smallest}{removed},
 430   }
 431 }
 432
 433 # Calculate (changed, removed) modules between two versions.
 434 sub calculate_delta {
 435   my($from, $to) = @_;
 436   my(%changed, %removed);
 437
 438   for my $package(keys $from) {
 439     if(not exists $to->{$package}) {
 440       $removed{$package} = 1;
 441     }
 442   }
 443
 444   for my $package(keys $to) {
 445     if(!exists $from->{$package}
 446         || (defined $from->{$package} && !defined $to->{$package})
 447         || (!defined $from->{$package} && defined $to->{$package})
 448         || (defined $from->{$package} && defined $to->{$package}
 449             && $from->{$package} ne $to->{$package})) {
 450       $changed{$package} = $to->{$package};
 451     }
 452   }
 453
 454   return \%changed, \%removed;
 455 }
 456
 457 sub quote {
 458     my ($str) = @_;
 459     # There's gotta be something already doing this properly that we could just
 460     # reuse, but I can't quite thing of where to look for it, so I'm gonna do
 461     # the simplest possible thing that'll allow me to release 5.17.7.  --rafl
 462     $str =~ s/'/\\'/g;
 463     "'${str}'";
 464 }
 465
 466 sub parse_utils_lst {
 467   require File::Spec::Unix;
 468   my @scripts;
 469   open my $fh, '<', 'utils.lst' or die "$!\n";
 470   while (<$fh>) {
 471     chomp;
 472     my ($file,$extra) = split m!#!;
 473     $file =~ s!\s+!!g;
 474     push @scripts, $file;
 475     $extra =~ s!\s+!!g if $extra;
 476     if ( $extra and my ($link) = $extra =~ m!^link=(.+?)$! ) {
 477       push @scripts, $link;
 478     }
 479   }
 480   return map { +( File::Spec::Unix->splitpath( $_ ) )[-1] } @scripts;
 481 }