This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
note about values()
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 An named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
140 C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>, 
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>, C<stat>, C<symlink>, C<syscall>,
238 C<sysopen>, C<system>, C<times>, C<truncate>, C<umask>, C<unlink>,
239 C<utime>, C<wait>, C<waitpid>
240
241 For more information about the portability of these functions, see
242 L<perlport> and other available platform-specific documentation.
243
244 =head2 Alphabetical Listing of Perl Functions
245
246 =over 8
247
248 =item I<-X> FILEHANDLE
249
250 =item I<-X> EXPR
251
252 =item I<-X>
253
254 A file test, where X is one of the letters listed below.  This unary
255 operator takes one argument, either a filename or a filehandle, and
256 tests the associated file to see if something is true about it.  If the
257 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
258 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
259 the undefined value if the file doesn't exist.  Despite the funny
260 names, precedence is the same as any other named unary operator, and
261 the argument may be parenthesized like any other unary operator.  The
262 operator may be any of:
263 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
264 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
265
266     -r  File is readable by effective uid/gid.
267     -w  File is writable by effective uid/gid.
268     -x  File is executable by effective uid/gid.
269     -o  File is owned by effective uid.
270
271     -R  File is readable by real uid/gid.
272     -W  File is writable by real uid/gid.
273     -X  File is executable by real uid/gid.
274     -O  File is owned by real uid.
275
276     -e  File exists.
277     -z  File has zero size.
278     -s  File has nonzero size (returns size).
279
280     -f  File is a plain file.
281     -d  File is a directory.
282     -l  File is a symbolic link.
283     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
284     -S  File is a socket.
285     -b  File is a block special file.
286     -c  File is a character special file.
287     -t  Filehandle is opened to a tty.
288
289     -u  File has setuid bit set.
290     -g  File has setgid bit set.
291     -k  File has sticky bit set.
292
293     -T  File is an ASCII text file.
294     -B  File is a "binary" file (opposite of -T).
295
296     -M  Age of file in days when script started.
297     -A  Same for access time.
298     -C  Same for inode change time.
299
300 Example:
301
302     while (<>) {
303         chop;
304         next unless -f $_;      # ignore specials
305         #...
306     }
307
308 The interpretation of the file permission operators C<-r>, C<-R>,
309 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
310 of the file and the uids and gids of the user.  There may be other
311 reasons you can't actually read, write, or execute the file.  Such
312 reasons may be for example network filesystem access controls, ACLs
313 (access control lists), read-only filesystems, and unrecognized
314 executable formats.
315
316 Also note that, for the superuser on the local filesystems, the C<-r>,
317 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
318 if any execute bit is set in the mode.  Scripts run by the superuser
319 may thus need to do a stat() to determine the actual mode of the file,
320 or temporarily set their effective uid to something else.
321
322 If you are using ACLs, there is a pragma called C<filetest> that may
323 produce more accurate results than the bare stat() mode bits.
324 When under the C<use filetest 'access'> the above-mentioned filetests
325 will test whether the permission can (not) be granted using the
326 access() family of system calls.  Also note that the C<-x> and C<-X> may
327 under this pragma return true even if there are no execute permission
328 bits set (nor any extra execute permission ACLs).  This strangeness is
329 due to the underlying system calls' definitions.  Read the
330 documentation for the C<filetest> pragma for more information.
331
332 Note that C<-s/a/b/> does not do a negated substitution.  Saying
333 C<-exp($foo)> still works as expected, however--only single letters
334 following a minus are interpreted as file tests.
335
336 The C<-T> and C<-B> switches work as follows.  The first block or so of the
337 file is examined for odd characters such as strange control codes or
338 characters with the high bit set.  If too many strange characters (>30%)
339 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
340 containing null in the first block is considered a binary file.  If C<-T>
341 or C<-B> is used on a filehandle, the current stdio buffer is examined
342 rather than the first block.  Both C<-T> and C<-B> return true on a null
343 file, or a file at EOF when testing a filehandle.  Because you have to
344 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
345 against the file first, as in C<next unless -f $file && -T $file>.
346
347 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
348 the special filehandle consisting of a solitary underline, then the stat
349 structure of the previous file test (or stat operator) is used, saving
350 a system call.  (This doesn't work with C<-t>, and you need to remember
351 that lstat() and C<-l> will leave values in the stat structure for the
352 symbolic link, not the real file.)  Example:
353
354     print "Can do.\n" if -r $a || -w _ || -x _;
355
356     stat($filename);
357     print "Readable\n" if -r _;
358     print "Writable\n" if -w _;
359     print "Executable\n" if -x _;
360     print "Setuid\n" if -u _;
361     print "Setgid\n" if -g _;
362     print "Sticky\n" if -k _;
363     print "Text\n" if -T _;
364     print "Binary\n" if -B _;
365
366 =item abs VALUE
367
368 =item abs
369
370 Returns the absolute value of its argument.
371 If VALUE is omitted, uses C<$_>.
372
373 =item accept NEWSOCKET,GENERICSOCKET
374
375 Accepts an incoming socket connect, just as the accept(2) system call
376 does.  Returns the packed address if it succeeded, false otherwise.
377 See the example in L<perlipc/"Sockets: Client/Server Communication">.
378
379 On systems that support a close-on-exec flag on files, the flag will
380 be set for the newly opened file descriptor, as determined by the
381 value of $^F.  See L<perlvar/$^F>.
382
383 =item alarm SECONDS
384
385 =item alarm
386
387 Arranges to have a SIGALRM delivered to this process after the
388 specified number of seconds have elapsed.  If SECONDS is not specified,
389 the value stored in C<$_> is used. (On some machines,
390 unfortunately, the elapsed time may be up to one second less than you
391 specified because of how seconds are counted.)  Only one timer may be
392 counting at once.  Each call disables the previous timer, and an
393 argument of C<0> may be supplied to cancel the previous timer without
394 starting a new one.  The returned value is the amount of time remaining
395 on the previous timer.
396
397 For delays of finer granularity than one second, you may use Perl's
398 four-argument version of select() leaving the first three arguments
399 undefined, or you might be able to use the C<syscall> interface to
400 access setitimer(2) if your system supports it.  The Time::HiRes module
401 from CPAN may also prove useful.
402
403 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
404 (C<sleep> may be internally implemented in your system with C<alarm>)
405
406 If you want to use C<alarm> to time out a system call you need to use an
407 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
408 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
409 restart system calls on some systems.  Using C<eval>/C<die> always works,
410 modulo the caveats given in L<perlipc/"Signals">.
411
412     eval {
413         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
414         alarm $timeout;
415         $nread = sysread SOCKET, $buffer, $size;
416         alarm 0;
417     };
418     if ($@) {
419         die unless $@ eq "alarm\n";   # propagate unexpected errors
420         # timed out
421     }
422     else {
423         # didn't
424     }
425
426 =item atan2 Y,X
427
428 Returns the arctangent of Y/X in the range -PI to PI.
429
430 For the tangent operation, you may use the C<Math::Trig::tan>
431 function, or use the familiar relation:
432
433     sub tan { sin($_[0]) / cos($_[0])  }
434
435 =item bind SOCKET,NAME
436
437 Binds a network address to a socket, just as the bind system call
438 does.  Returns true if it succeeded, false otherwise.  NAME should be a
439 packed address of the appropriate type for the socket.  See the examples in
440 L<perlipc/"Sockets: Client/Server Communication">.
441
442 =item binmode FILEHANDLE, DISCIPLINE
443
444 =item binmode FILEHANDLE
445
446 Arranges for FILEHANDLE to be read or written in "binary" or "text" mode
447 on systems where the run-time libraries distinguish between binary and
448 text files.  If FILEHANDLE is an expression, the value is taken as the
449 name of the filehandle.  DISCIPLINE can be either of C<":raw"> for
450 binary mode or C<":crlf"> for "text" mode.  If the DISCIPLINE is
451 omitted, it defaults to C<":raw">.
452
453 binmode() should be called after open() but before any I/O is done on
454 the filehandle.
455
456 On many systems binmode() currently has no effect, but in future, it
457 will be extended to support user-defined input and output disciplines.
458 On some systems binmode() is necessary when you're not working with a
459 text file.  For the sake of portability it is a good idea to always use
460 it when appropriate, and to never use it when it isn't appropriate.
461
462 In other words:  Regardless of platform, use binmode() on binary
463 files, and do not use binmode() on text files.
464
465 The C<open> pragma can be used to establish default disciplines.
466 See L<open>.
467
468 The operating system, device drivers, C libraries, and Perl run-time
469 system all work together to let the programmer treat a single
470 character (C<\n>) as the line terminator, irrespective of the external
471 representation.  On many operating systems, the native text file
472 representation matches the internal representation, but on some
473 platforms the external representation of C<\n> is made up of more than
474 one character.
475
476 Mac OS and all variants of Unix use a single character to end each line
477 in the external representation of text (even though that single
478 character is not necessarily the same across these platforms).
479 Consequently binmode() has no effect on these operating systems.  In
480 other systems like VMS, MS-DOS and the various flavors of MS-Windows
481 your program sees a C<\n> as a simple C<\cJ>, but what's stored in text
482 files are the two characters C<\cM\cJ>.  That means that, if you don't
483 use binmode() on these systems, C<\cM\cJ> sequences on disk will be
484 converted to C<\n> on input, and any C<\n> in your program will be
485 converted back to C<\cM\cJ> on output.  This is what you want for text
486 files, but it can be disastrous for binary files.
487
488 Another consequence of using binmode() (on some systems) is that
489 special end-of-file markers will be seen as part of the data stream.
490 For systems from the Microsoft family this means that if your binary
491 data contains C<\cZ>, the I/O subsystem will regard it as the end of
492 the file, unless you use binmode().
493
494 binmode() is not only important for readline() and print() operations,
495 but also when using read(), seek(), sysread(), syswrite() and tell()
496 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
497 in L<perlvar> for how to manually set your input and output
498 line-termination sequences.
499
500 =item bless REF,CLASSNAME
501
502 =item bless REF
503
504 This function tells the thingy referenced by REF that it is now an object
505 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
506 is used.  Because a C<bless> is often the last thing in a constructor,
507 it returns the reference for convenience.  Always use the two-argument
508 version if the function doing the blessing might be inherited by a
509 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
510 (and blessings) of objects.
511
512 Consider always blessing objects in CLASSNAMEs that are mixed case.
513 Namespaces with all lowercase names are considered reserved for
514 Perl pragmata.  Builtin types have all uppercase names, so to prevent
515 confusion, you may wish to avoid such package names as well.  Make sure
516 that CLASSNAME is a true value.
517
518 See L<perlmod/"Perl Modules">.
519
520 =item caller EXPR
521
522 =item caller
523
524 Returns the context of the current subroutine call.  In scalar context,
525 returns the caller's package name if there is a caller, that is, if
526 we're in a subroutine or C<eval> or C<require>, and the undefined value
527 otherwise.  In list context, returns
528
529     ($package, $filename, $line) = caller;
530
531 With EXPR, it returns some extra information that the debugger uses to
532 print a stack trace.  The value of EXPR indicates how many call frames
533 to go back before the current one.
534
535     ($package, $filename, $line, $subroutine, $hasargs,
536     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
537
538 Here $subroutine may be C<(eval)> if the frame is not a subroutine
539 call, but an C<eval>.  In such a case additional elements $evaltext and
540 C<$is_require> are set: C<$is_require> is true if the frame is created by a
541 C<require> or C<use> statement, $evaltext contains the text of the
542 C<eval EXPR> statement.  In particular, for a C<eval BLOCK> statement,
543 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
544 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
545 frame.  C<$hints> and C<$bitmask> contain pragmatic hints that the caller
546 was compiled with.  The C<$hints> and C<$bitmask> values are subject to
547 change between versions of Perl, and are not meant for external use.
548
549 Furthermore, when called from within the DB package, caller returns more
550 detailed information: it sets the list variable C<@DB::args> to be the
551 arguments with which the subroutine was invoked.
552
553 Be aware that the optimizer might have optimized call frames away before
554 C<caller> had a chance to get the information.  That means that C<caller(N)>
555 might not return information about the call frame you expect it do, for
556 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the 
557 previous time C<caller> was called.
558
559 =item chdir EXPR
560
561 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
562 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
563 changes to the directory specified by C<$ENV{LOGDIR}>.  If neither is
564 set, C<chdir> does nothing.  It returns true upon success, false
565 otherwise.  See the example under C<die>.
566
567 =item chmod LIST
568
569 Changes the permissions of a list of files.  The first element of the
570 list must be the numerical mode, which should probably be an octal
571 number, and which definitely should I<not> a string of octal digits:
572 C<0644> is okay, C<'0644'> is not.  Returns the number of files
573 successfully changed.  See also L</oct>, if all you have is a string.
574
575     $cnt = chmod 0755, 'foo', 'bar';
576     chmod 0755, @executables;
577     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
578                                              # --w----r-T
579     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
580     $mode = 0644;   chmod $mode, 'foo';      # this is best
581
582 You can also import the symbolic C<S_I*> constants from the Fcntl
583 module:
584
585     use Fcntl ':mode';
586
587     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
588     # This is identical to the chmod 0755 of the above example.
589
590 =item chomp VARIABLE
591
592 =item chomp LIST
593
594 =item chomp
595
596 This safer version of L</chop> removes any trailing string
597 that corresponds to the current value of C<$/> (also known as
598 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
599 number of characters removed from all its arguments.  It's often used to
600 remove the newline from the end of an input record when you're worried
601 that the final record may be missing its newline.  When in paragraph
602 mode (C<$/ = "">), it removes all trailing newlines from the string.
603 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
604 a reference to an integer or the like, see L<perlvar>) chomp() won't
605 remove anything.  
606 If VARIABLE is omitted, it chomps C<$_>.  Example:
607
608     while (<>) {
609         chomp;  # avoid \n on last field
610         @array = split(/:/);
611         # ...
612     }
613
614 You can actually chomp anything that's an lvalue, including an assignment:
615
616     chomp($cwd = `pwd`);
617     chomp($answer = <STDIN>);
618
619 If you chomp a list, each element is chomped, and the total number of
620 characters removed is returned.
621
622 =item chop VARIABLE
623
624 =item chop LIST
625
626 =item chop
627
628 Chops off the last character of a string and returns the character
629 chopped.  It's used primarily to remove the newline from the end of an
630 input record, but is much more efficient than C<s/\n//> because it neither
631 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
632 Example:
633
634     while (<>) {
635         chop;   # avoid \n on last field
636         @array = split(/:/);
637         #...
638     }
639
640 You can actually chop anything that's an lvalue, including an assignment:
641
642     chop($cwd = `pwd`);
643     chop($answer = <STDIN>);
644
645 If you chop a list, each element is chopped.  Only the value of the
646 last C<chop> is returned.
647
648 Note that C<chop> returns the last character.  To return all but the last
649 character, use C<substr($string, 0, -1)>.
650
651 =item chown LIST
652
653 Changes the owner (and group) of a list of files.  The first two
654 elements of the list must be the I<numeric> uid and gid, in that
655 order.  A value of -1 in either position is interpreted by most
656 systems to leave that value unchanged.  Returns the number of files
657 successfully changed.
658
659     $cnt = chown $uid, $gid, 'foo', 'bar';
660     chown $uid, $gid, @filenames;
661
662 Here's an example that looks up nonnumeric uids in the passwd file:
663
664     print "User: ";
665     chomp($user = <STDIN>);
666     print "Files: ";
667     chomp($pattern = <STDIN>);
668
669     ($login,$pass,$uid,$gid) = getpwnam($user)
670         or die "$user not in passwd file";
671
672     @ary = glob($pattern);      # expand filenames
673     chown $uid, $gid, @ary;
674
675 On most systems, you are not allowed to change the ownership of the
676 file unless you're the superuser, although you should be able to change
677 the group to any of your secondary groups.  On insecure systems, these
678 restrictions may be relaxed, but this is not a portable assumption.
679 On POSIX systems, you can detect this condition this way:
680
681     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
682     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
683
684 =item chr NUMBER
685
686 =item chr
687
688 Returns the character represented by that NUMBER in the character set.
689 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
690 chr(0x263a) is a Unicode smiley face (but only within the scope of
691 a C<use utf8>).  For the reverse, use L</ord>.  
692 See L<utf8> for more about Unicode.
693
694 If NUMBER is omitted, uses C<$_>.
695
696 =item chroot FILENAME
697
698 =item chroot
699
700 This function works like the system call by the same name: it makes the
701 named directory the new root directory for all further pathnames that
702 begin with a C</> by your process and all its children.  (It doesn't
703 change your current working directory, which is unaffected.)  For security
704 reasons, this call is restricted to the superuser.  If FILENAME is
705 omitted, does a C<chroot> to C<$_>.
706
707 =item close FILEHANDLE
708
709 =item close
710
711 Closes the file or pipe associated with the file handle, returning true
712 only if stdio successfully flushes buffers and closes the system file
713 descriptor.  Closes the currently selected filehandle if the argument
714 is omitted.
715
716 You don't have to close FILEHANDLE if you are immediately going to do
717 another C<open> on it, because C<open> will close it for you.  (See
718 C<open>.)  However, an explicit C<close> on an input file resets the line
719 counter (C<$.>), while the implicit close done by C<open> does not.
720
721 If the file handle came from a piped open C<close> will additionally
722 return false if one of the other system calls involved fails or if the
723 program exits with non-zero status.  (If the only problem was that the
724 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe 
725 also waits for the process executing on the pipe to complete, in case you
726 want to look at the output of the pipe afterwards, and 
727 implicitly puts the exit status value of that command into C<$?>.
728
729 Prematurely closing the read end of a pipe (i.e. before the process
730 writing to it at the other end has closed it) will result in a
731 SIGPIPE being delivered to the writer.  If the other end can't
732 handle that, be sure to read all the data before closing the pipe.
733
734 Example:
735
736     open(OUTPUT, '|sort >foo')  # pipe to sort
737         or die "Can't start sort: $!";
738     #...                        # print stuff to output
739     close OUTPUT                # wait for sort to finish
740         or warn $! ? "Error closing sort pipe: $!"
741                    : "Exit status $? from sort";
742     open(INPUT, 'foo')          # get sort's results
743         or die "Can't open 'foo' for input: $!";
744
745 FILEHANDLE may be an expression whose value can be used as an indirect
746 filehandle, usually the real filehandle name.
747
748 =item closedir DIRHANDLE
749
750 Closes a directory opened by C<opendir> and returns the success of that
751 system call.
752
753 DIRHANDLE may be an expression whose value can be used as an indirect
754 dirhandle, usually the real dirhandle name.
755
756 =item connect SOCKET,NAME
757
758 Attempts to connect to a remote socket, just as the connect system call
759 does.  Returns true if it succeeded, false otherwise.  NAME should be a
760 packed address of the appropriate type for the socket.  See the examples in
761 L<perlipc/"Sockets: Client/Server Communication">.
762
763 =item continue BLOCK
764
765 Actually a flow control statement rather than a function.  If there is a
766 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
767 C<foreach>), it is always executed just before the conditional is about to
768 be evaluated again, just like the third part of a C<for> loop in C.  Thus
769 it can be used to increment a loop variable, even when the loop has been
770 continued via the C<next> statement (which is similar to the C C<continue>
771 statement).
772
773 C<last>, C<next>, or C<redo> may appear within a C<continue>
774 block.  C<last> and C<redo> will behave as if they had been executed within
775 the main block.  So will C<next>, but since it will execute a C<continue>
776 block, it may be more entertaining.
777
778     while (EXPR) {
779         ### redo always comes here
780         do_something;
781     } continue {
782         ### next always comes here
783         do_something_else;
784         # then back the top to re-check EXPR
785     }
786     ### last always comes here
787
788 Omitting the C<continue> section is semantically equivalent to using an
789 empty one, logically enough.  In that case, C<next> goes directly back
790 to check the condition at the top of the loop.
791
792 =item cos EXPR
793
794 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
795 takes cosine of C<$_>.
796
797 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
798 function, or use this relation:
799
800     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
801
802 =item crypt PLAINTEXT,SALT
803
804 Encrypts a string exactly like the crypt(3) function in the C library
805 (assuming that you actually have a version there that has not been
806 extirpated as a potential munition).  This can prove useful for checking
807 the password file for lousy passwords, amongst other things.  Only the
808 guys wearing white hats should do this.
809
810 Note that C<crypt> is intended to be a one-way function, much like breaking
811 eggs to make an omelette.  There is no (known) corresponding decrypt
812 function.  As a result, this function isn't all that useful for
813 cryptography.  (For that, see your nearby CPAN mirror.)
814
815 When verifying an existing encrypted string you should use the encrypted
816 text as the salt (like C<crypt($plain, $crypted) eq $crypted>).  This
817 allows your code to work with the standard C<crypt> and with more
818 exotic implementations.  When choosing a new salt create a random two
819 character string whose characters come from the set C<[./0-9A-Za-z]>
820 (like C<join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
821
822 Here's an example that makes sure that whoever runs this program knows
823 their own password:
824
825     $pwd = (getpwuid($<))[1];
826
827     system "stty -echo";
828     print "Password: ";
829     chomp($word = <STDIN>);
830     print "\n";
831     system "stty echo";
832
833     if (crypt($word, $pwd) ne $pwd) {
834         die "Sorry...\n";
835     } else {
836         print "ok\n";
837     }
838
839 Of course, typing in your own password to whoever asks you
840 for it is unwise.
841
842 The L<crypt> function is unsuitable for encrypting large quantities
843 of data, not least of all because you can't get the information
844 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
845 on your favorite CPAN mirror for a slew of potentially useful
846 modules.
847
848 =item dbmclose HASH
849
850 [This function has been largely superseded by the C<untie> function.]
851
852 Breaks the binding between a DBM file and a hash.
853
854 =item dbmopen HASH,DBNAME,MASK
855
856 [This function has been largely superseded by the C<tie> function.]
857
858 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
859 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
860 argument is I<not> a filehandle, even though it looks like one).  DBNAME
861 is the name of the database (without the F<.dir> or F<.pag> extension if
862 any).  If the database does not exist, it is created with protection
863 specified by MASK (as modified by the C<umask>).  If your system supports
864 only the older DBM functions, you may perform only one C<dbmopen> in your
865 program.  In older versions of Perl, if your system had neither DBM nor
866 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
867 sdbm(3).
868
869 If you don't have write access to the DBM file, you can only read hash
870 variables, not set them.  If you want to test whether you can write,
871 either use file tests or try setting a dummy hash entry inside an C<eval>,
872 which will trap the error.
873
874 Note that functions such as C<keys> and C<values> may return huge lists
875 when used on large DBM files.  You may prefer to use the C<each>
876 function to iterate over large DBM files.  Example:
877
878     # print out history file offsets
879     dbmopen(%HIST,'/usr/lib/news/history',0666);
880     while (($key,$val) = each %HIST) {
881         print $key, ' = ', unpack('L',$val), "\n";
882     }
883     dbmclose(%HIST);
884
885 See also L<AnyDBM_File> for a more general description of the pros and
886 cons of the various dbm approaches, as well as L<DB_File> for a particularly
887 rich implementation.
888
889 You can control which DBM library you use by loading that library
890 before you call dbmopen():
891
892     use DB_File;
893     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
894         or die "Can't open netscape history file: $!";
895
896 =item defined EXPR
897
898 =item defined
899
900 Returns a Boolean value telling whether EXPR has a value other than
901 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
902 checked.
903
904 Many operations return C<undef> to indicate failure, end of file,
905 system error, uninitialized variable, and other exceptional
906 conditions.  This function allows you to distinguish C<undef> from
907 other values.  (A simple Boolean test will not distinguish among
908 C<undef>, zero, the empty string, and C<"0">, which are all equally
909 false.)  Note that since C<undef> is a valid scalar, its presence
910 doesn't I<necessarily> indicate an exceptional condition: C<pop>
911 returns C<undef> when its argument is an empty array, I<or> when the
912 element to return happens to be C<undef>.
913
914 You may also use C<defined(&func)> to check whether subroutine C<&func>
915 has ever been defined.  The return value is unaffected by any forward
916 declarations of C<&foo>.
917
918 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
919 used to report whether memory for that aggregate has ever been
920 allocated.  This behavior may disappear in future versions of Perl.
921 You should instead use a simple test for size:
922
923     if (@an_array) { print "has array elements\n" }
924     if (%a_hash)   { print "has hash members\n"   }
925
926 When used on a hash element, it tells you whether the value is defined,
927 not whether the key exists in the hash.  Use L</exists> for the latter
928 purpose.
929
930 Examples:
931
932     print if defined $switch{'D'};
933     print "$val\n" while defined($val = pop(@ary));
934     die "Can't readlink $sym: $!"
935         unless defined($value = readlink $sym);
936     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
937     $debugging = 0 unless defined $debugging;
938
939 Note:  Many folks tend to overuse C<defined>, and then are surprised to
940 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
941 defined values.  For example, if you say
942
943     "ab" =~ /a(.*)b/;
944
945 The pattern match succeeds, and C<$1> is defined, despite the fact that it
946 matched "nothing".  But it didn't really match nothing--rather, it
947 matched something that happened to be zero characters long.  This is all
948 very above-board and honest.  When a function returns an undefined value,
949 it's an admission that it couldn't give you an honest answer.  So you
950 should use C<defined> only when you're questioning the integrity of what
951 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
952 what you want.
953
954 See also L</undef>, L</exists>, L</ref>.
955
956 =item delete EXPR
957
958 Given an expression that specifies a hash element, array element, hash slice,
959 or array slice, deletes the specified element(s) from the hash or array.
960 In the case of an array, if the array elements happen to be at the end,
961 the size of the array will shrink to the highest element that tests 
962 true for exists() (or 0 if no such element exists).
963
964 Returns each element so deleted or the undefined value if there was no such
965 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
966 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
967 from a C<tie>d hash or array may not necessarily return anything.
968
969 Deleting an array element effectively returns that position of the array
970 to its initial, uninitialized state.  Subsequently testing for the same
971 element with exists() will return false.  Note that deleting array
972 elements in the middle of an array will not shift the index of the ones
973 after them down--use splice() for that.  See L</exists>.
974
975 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
976
977     foreach $key (keys %HASH) {
978         delete $HASH{$key};
979     }
980
981     foreach $index (0 .. $#ARRAY) {
982         delete $ARRAY[$index];
983     }
984
985 And so do these:
986
987     delete @HASH{keys %HASH};
988
989     delete @ARRAY[0 .. $#ARRAY];
990
991 But both of these are slower than just assigning the empty list
992 or undefining %HASH or @ARRAY:
993
994     %HASH = ();         # completely empty %HASH
995     undef %HASH;        # forget %HASH ever existed
996
997     @ARRAY = ();        # completely empty @ARRAY
998     undef @ARRAY;       # forget @ARRAY ever existed
999
1000 Note that the EXPR can be arbitrarily complicated as long as the final
1001 operation is a hash element, array element,  hash slice, or array slice
1002 lookup:
1003
1004     delete $ref->[$x][$y]{$key};
1005     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1006
1007     delete $ref->[$x][$y][$index];
1008     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1009
1010 =item die LIST
1011
1012 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1013 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1014 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1015 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1016 an C<eval(),> the error message is stuffed into C<$@> and the
1017 C<eval> is terminated with the undefined value.  This makes
1018 C<die> the way to raise an exception.
1019
1020 Equivalent examples:
1021
1022     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1023     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1024
1025 If the value of EXPR does not end in a newline, the current script line
1026 number and input line number (if any) are also printed, and a newline
1027 is supplied.  Note that the "input line number" (also known as "chunk")
1028 is subject to whatever notion of "line" happens to be currently in
1029 effect, and is also available as the special variable C<$.>.
1030 See L<perlvar/"$/"> and L<perlvar/"$.">.
1031
1032 Hint: sometimes appending C<", stopped"> to your message
1033 will cause it to make better sense when the string C<"at foo line 123"> is
1034 appended.  Suppose you are running script "canasta".
1035
1036     die "/etc/games is no good";
1037     die "/etc/games is no good, stopped";
1038
1039 produce, respectively
1040
1041     /etc/games is no good at canasta line 123.
1042     /etc/games is no good, stopped at canasta line 123.
1043
1044 See also exit(), warn(), and the Carp module.
1045
1046 If LIST is empty and C<$@> already contains a value (typically from a
1047 previous eval) that value is reused after appending C<"\t...propagated">.
1048 This is useful for propagating exceptions:
1049
1050     eval { ... };
1051     die unless $@ =~ /Expected exception/;
1052
1053 If C<$@> is empty then the string C<"Died"> is used.
1054
1055 die() can also be called with a reference argument.  If this happens to be
1056 trapped within an eval(), $@ contains the reference.  This behavior permits
1057 a more elaborate exception handling implementation using objects that
1058 maintain arbitrary state about the nature of the exception.  Such a scheme
1059 is sometimes preferable to matching particular string values of $@ using
1060 regular expressions.  Here's an example:
1061
1062     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1063     if ($@) {
1064         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1065             # handle Some::Module::Exception
1066         }
1067         else {
1068             # handle all other possible exceptions
1069         }
1070     }
1071
1072 Because perl will stringify uncaught exception messages before displaying
1073 them, you may want to overload stringification operations on such custom
1074 exception objects.  See L<overload> for details about that.
1075
1076 You can arrange for a callback to be run just before the C<die>
1077 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1078 handler will be called with the error text and can change the error
1079 message, if it sees fit, by calling C<die> again.  See
1080 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1081 L<"eval BLOCK"> for some examples.  Although this feature was meant
1082 to be run only right before your program was to exit, this is not
1083 currently the case--the C<$SIG{__DIE__}> hook is currently called
1084 even inside eval()ed blocks/strings!  If one wants the hook to do
1085 nothing in such situations, put
1086
1087         die @_ if $^S;
1088
1089 as the first line of the handler (see L<perlvar/$^S>).  Because
1090 this promotes strange action at a distance, this counterintuitive
1091 behavior may be fixed in a future release.  
1092
1093 =item do BLOCK
1094
1095 Not really a function.  Returns the value of the last command in the
1096 sequence of commands indicated by BLOCK.  When modified by a loop
1097 modifier, executes the BLOCK once before testing the loop condition.
1098 (On other statements the loop modifiers test the conditional first.)
1099
1100 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1101 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1102 See L<perlsyn> for alternative strategies.
1103
1104 =item do SUBROUTINE(LIST)
1105
1106 A deprecated form of subroutine call.  See L<perlsub>.
1107
1108 =item do EXPR
1109
1110 Uses the value of EXPR as a filename and executes the contents of the
1111 file as a Perl script.  Its primary use is to include subroutines
1112 from a Perl subroutine library.
1113
1114     do 'stat.pl';
1115
1116 is just like
1117
1118     scalar eval `cat stat.pl`;
1119
1120 except that it's more efficient and concise, keeps track of the current
1121 filename for error messages, searches the @INC libraries, and updates
1122 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1123 variables.  It also differs in that code evaluated with C<do FILENAME>
1124 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1125 same, however, in that it does reparse the file every time you call it,
1126 so you probably don't want to do this inside a loop.
1127
1128 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1129 error.  If C<do> can read the file but cannot compile it, it
1130 returns undef and sets an error message in C<$@>.   If the file is
1131 successfully compiled, C<do> returns the value of the last expression
1132 evaluated.
1133
1134 Note that inclusion of library modules is better done with the
1135 C<use> and C<require> operators, which also do automatic error checking
1136 and raise an exception if there's a problem.
1137
1138 You might like to use C<do> to read in a program configuration
1139 file.  Manual error checking can be done this way:
1140
1141     # read in config files: system first, then user 
1142     for $file ("/share/prog/defaults.rc",
1143                "$ENV{HOME}/.someprogrc") 
1144    {
1145         unless ($return = do $file) {
1146             warn "couldn't parse $file: $@" if $@;
1147             warn "couldn't do $file: $!"    unless defined $return;
1148             warn "couldn't run $file"       unless $return;
1149         }
1150     }
1151
1152 =item dump LABEL
1153
1154 =item dump
1155
1156 This function causes an immediate core dump.  See also the B<-u>
1157 command-line switch in L<perlrun>, which does the same thing.
1158 Primarily this is so that you can use the B<undump> program (not
1159 supplied) to turn your core dump into an executable binary after
1160 having initialized all your variables at the beginning of the
1161 program.  When the new binary is executed it will begin by executing
1162 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1163 Think of it as a goto with an intervening core dump and reincarnation.
1164 If C<LABEL> is omitted, restarts the program from the top.
1165
1166 B<WARNING>: Any files opened at the time of the dump will I<not>
1167 be open any more when the program is reincarnated, with possible
1168 resulting confusion on the part of Perl.  
1169
1170 This function is now largely obsolete, partly because it's very
1171 hard to convert a core file into an executable, and because the
1172 real compiler backends for generating portable bytecode and compilable
1173 C code have superseded it.
1174
1175 If you're looking to use L<dump> to speed up your program, consider
1176 generating bytecode or native C code as described in L<perlcc>.  If
1177 you're just trying to accelerate a CGI script, consider using the
1178 C<mod_perl> extension to B<Apache>, or the CPAN module, Fast::CGI.
1179 You might also consider autoloading or selfloading, which at least
1180 make your program I<appear> to run faster.  
1181
1182 =item each HASH
1183
1184 When called in list context, returns a 2-element list consisting of the
1185 key and value for the next element of a hash, so that you can iterate over
1186 it.  When called in scalar context, returns the key for only the "next"
1187 element in the hash.
1188
1189 Entries are returned in an apparently random order.  The actual random
1190 order is subject to change in future versions of perl, but it is guaranteed
1191 to be in the same order as either the C<keys> or C<values> function
1192 would produce on the same (unmodified) hash.
1193
1194 When the hash is entirely read, a null array is returned in list context
1195 (which when assigned produces a false (C<0>) value), and C<undef> in
1196 scalar context.  The next call to C<each> after that will start iterating
1197 again.  There is a single iterator for each hash, shared by all C<each>,
1198 C<keys>, and C<values> function calls in the program; it can be reset by
1199 reading all the elements from the hash, or by evaluating C<keys HASH> or
1200 C<values HASH>.  If you add or delete elements of a hash while you're
1201 iterating over it, you may get entries skipped or duplicated, so don't.
1202
1203 The following prints out your environment like the printenv(1) program,
1204 only in a different order:
1205
1206     while (($key,$value) = each %ENV) {
1207         print "$key=$value\n";
1208     }
1209
1210 See also C<keys>, C<values> and C<sort>.
1211
1212 =item eof FILEHANDLE
1213
1214 =item eof ()
1215
1216 =item eof
1217
1218 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1219 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1220 gives the real filehandle.  (Note that this function actually
1221 reads a character and then C<ungetc>s it, so isn't very useful in an
1222 interactive context.)  Do not read from a terminal file (or call
1223 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1224 as terminals may lose the end-of-file condition if you do.
1225
1226 An C<eof> without an argument uses the last file read.  Using C<eof()>
1227 with empty parentheses is very different.  It refers to the pseudo file
1228 formed from the files listed on the command line and accessed via the
1229 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1230 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1231 used will cause C<@ARGV> to be examined to determine if input is
1232 available.
1233
1234 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1235 detect the end of each file, C<eof()> will only detect the end of the
1236 last file.  Examples:
1237
1238     # reset line numbering on each input file
1239     while (<>) {
1240         next if /^\s*#/;        # skip comments 
1241         print "$.\t$_";
1242     } continue {
1243         close ARGV  if eof;     # Not eof()!
1244     }
1245
1246     # insert dashes just before last line of last file
1247     while (<>) {
1248         if (eof()) {            # check for end of current file
1249             print "--------------\n";
1250             close(ARGV);        # close or last; is needed if we
1251                                 # are reading from the terminal
1252         }
1253         print;
1254     }
1255
1256 Practical hint: you almost never need to use C<eof> in Perl, because the
1257 input operators typically return C<undef> when they run out of data, or if
1258 there was an error.
1259
1260 =item eval EXPR
1261
1262 =item eval BLOCK
1263
1264 In the first form, the return value of EXPR is parsed and executed as if it
1265 were a little Perl program.  The value of the expression (which is itself
1266 determined within scalar context) is first parsed, and if there weren't any
1267 errors, executed in the context of the current Perl program, so that any
1268 variable settings or subroutine and format definitions remain afterwards.
1269 Note that the value is parsed every time the eval executes.  If EXPR is
1270 omitted, evaluates C<$_>.  This form is typically used to delay parsing
1271 and subsequent execution of the text of EXPR until run time.
1272
1273 In the second form, the code within the BLOCK is parsed only once--at the
1274 same time the code surrounding the eval itself was parsed--and executed
1275 within the context of the current Perl program.  This form is typically
1276 used to trap exceptions more efficiently than the first (see below), while
1277 also providing the benefit of checking the code within BLOCK at compile
1278 time.
1279
1280 The final semicolon, if any, may be omitted from the value of EXPR or within
1281 the BLOCK.
1282
1283 In both forms, the value returned is the value of the last expression
1284 evaluated inside the mini-program; a return statement may be also used, just
1285 as with subroutines.  The expression providing the return value is evaluated
1286 in void, scalar, or list context, depending on the context of the eval itself.
1287 See L</wantarray> for more on how the evaluation context can be determined.
1288
1289 If there is a syntax error or runtime error, or a C<die> statement is
1290 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1291 error message.  If there was no error, C<$@> is guaranteed to be a null
1292 string.  Beware that using C<eval> neither silences perl from printing
1293 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1294 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1295 L</warn> and L<perlvar>.
1296
1297 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1298 determining whether a particular feature (such as C<socket> or C<symlink>)
1299 is implemented.  It is also Perl's exception trapping mechanism, where
1300 the die operator is used to raise exceptions.
1301
1302 If the code to be executed doesn't vary, you may use the eval-BLOCK
1303 form to trap run-time errors without incurring the penalty of
1304 recompiling each time.  The error, if any, is still returned in C<$@>.
1305 Examples:
1306
1307     # make divide-by-zero nonfatal
1308     eval { $answer = $a / $b; }; warn $@ if $@;
1309
1310     # same thing, but less efficient
1311     eval '$answer = $a / $b'; warn $@ if $@;
1312
1313     # a compile-time error
1314     eval { $answer = };                 # WRONG
1315
1316     # a run-time error
1317     eval '$answer =';   # sets $@
1318
1319 Due to the current arguably broken state of C<__DIE__> hooks, when using
1320 the C<eval{}> form as an exception trap in libraries, you may wish not
1321 to trigger any C<__DIE__> hooks that user code may have installed.
1322 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1323 as shown in this example:
1324
1325     # a very private exception trap for divide-by-zero
1326     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1327     warn $@ if $@;
1328
1329 This is especially significant, given that C<__DIE__> hooks can call
1330 C<die> again, which has the effect of changing their error messages:
1331
1332     # __DIE__ hooks may modify error messages
1333     {
1334        local $SIG{'__DIE__'} =
1335               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1336        eval { die "foo lives here" };
1337        print $@ if $@;                # prints "bar lives here"
1338     }
1339
1340 Because this promotes action at a distance, this counterintuitive behavior
1341 may be fixed in a future release.
1342
1343 With an C<eval>, you should be especially careful to remember what's
1344 being looked at when:
1345
1346     eval $x;            # CASE 1
1347     eval "$x";          # CASE 2
1348
1349     eval '$x';          # CASE 3
1350     eval { $x };        # CASE 4
1351
1352     eval "\$$x++";      # CASE 5
1353     $$x++;              # CASE 6
1354
1355 Cases 1 and 2 above behave identically: they run the code contained in
1356 the variable $x.  (Although case 2 has misleading double quotes making
1357 the reader wonder what else might be happening (nothing is).)  Cases 3
1358 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1359 does nothing but return the value of $x.  (Case 4 is preferred for
1360 purely visual reasons, but it also has the advantage of compiling at
1361 compile-time instead of at run-time.)  Case 5 is a place where
1362 normally you I<would> like to use double quotes, except that in this
1363 particular situation, you can just use symbolic references instead, as
1364 in case 6.
1365
1366 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1367 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1368
1369 =item exec LIST
1370
1371 =item exec PROGRAM LIST
1372
1373 The C<exec> function executes a system command I<and never returns>--
1374 use C<system> instead of C<exec> if you want it to return.  It fails and
1375 returns false only if the command does not exist I<and> it is executed
1376 directly instead of via your system's command shell (see below).
1377
1378 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1379 warns you if there is a following statement which isn't C<die>, C<warn>,
1380 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1381 I<really> want to follow an C<exec> with some other statement, you
1382 can use one of these styles to avoid the warning:
1383
1384     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1385     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1386
1387 If there is more than one argument in LIST, or if LIST is an array
1388 with more than one value, calls execvp(3) with the arguments in LIST.
1389 If there is only one scalar argument or an array with one element in it,
1390 the argument is checked for shell metacharacters, and if there are any,
1391 the entire argument is passed to the system's command shell for parsing
1392 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1393 If there are no shell metacharacters in the argument, it is split into
1394 words and passed directly to C<execvp>, which is more efficient.  
1395 Examples:
1396
1397     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1398     exec "sort $outfile | uniq";
1399
1400 If you don't really want to execute the first argument, but want to lie
1401 to the program you are executing about its own name, you can specify
1402 the program you actually want to run as an "indirect object" (without a
1403 comma) in front of the LIST.  (This always forces interpretation of the
1404 LIST as a multivalued list, even if there is only a single scalar in
1405 the list.)  Example:
1406
1407     $shell = '/bin/csh';
1408     exec $shell '-sh';          # pretend it's a login shell
1409
1410 or, more directly,
1411
1412     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1413
1414 When the arguments get executed via the system shell, results will
1415 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1416 for details.
1417
1418 Using an indirect object with C<exec> or C<system> is also more
1419 secure.  This usage (which also works fine with system()) forces
1420 interpretation of the arguments as a multivalued list, even if the
1421 list had just one argument.  That way you're safe from the shell
1422 expanding wildcards or splitting up words with whitespace in them.
1423
1424     @args = ( "echo surprise" );
1425
1426     exec @args;               # subject to shell escapes
1427                                 # if @args == 1
1428     exec { $args[0] } @args;  # safe even with one-arg list
1429
1430 The first version, the one without the indirect object, ran the I<echo>
1431 program, passing it C<"surprise"> an argument.  The second version
1432 didn't--it tried to run a program literally called I<"echo surprise">,
1433 didn't find it, and set C<$?> to a non-zero value indicating failure.
1434
1435 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1436 output before the exec, but this may not be supported on some platforms
1437 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1438 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1439 open handles in order to avoid lost output.
1440
1441 Note that C<exec> will not call your C<END> blocks, nor will it call
1442 any C<DESTROY> methods in your objects.
1443
1444 =item exists EXPR
1445
1446 Given an expression that specifies a hash element or array element,
1447 returns true if the specified element in the hash or array has ever
1448 been initialized, even if the corresponding value is undefined.  The
1449 element is not autovivified if it doesn't exist.
1450
1451     print "Exists\n"    if exists $hash{$key};
1452     print "Defined\n"   if defined $hash{$key};
1453     print "True\n"      if $hash{$key};
1454
1455     print "Exists\n"    if exists $array[$index];
1456     print "Defined\n"   if defined $array[$index];
1457     print "True\n"      if $array[$index];
1458
1459 A hash or array element can be true only if it's defined, and defined if
1460 it exists, but the reverse doesn't necessarily hold true.
1461
1462 Given an expression that specifies the name of a subroutine,
1463 returns true if the specified subroutine has ever been declared, even
1464 if it is undefined.  Mentioning a subroutine name for exists or defined
1465 does not count as declaring it.
1466
1467     print "Exists\n"    if exists &subroutine;
1468     print "Defined\n"   if defined &subroutine;
1469
1470 Note that the EXPR can be arbitrarily complicated as long as the final
1471 operation is a hash or array key lookup or subroutine name:
1472
1473     if (exists $ref->{A}->{B}->{$key})  { }
1474     if (exists $hash{A}{B}{$key})       { }
1475
1476     if (exists $ref->{A}->{B}->[$ix])   { }
1477     if (exists $hash{A}{B}[$ix])        { }
1478
1479     if (exists &{$ref->{A}{B}{$key}})   { }
1480
1481 Although the deepest nested array or hash will not spring into existence
1482 just because its existence was tested, any intervening ones will.
1483 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1484 into existence due to the existence test for the $key element above.
1485 This happens anywhere the arrow operator is used, including even:
1486
1487     undef $ref;
1488     if (exists $ref->{"Some key"})      { }
1489     print $ref;             # prints HASH(0x80d3d5c)
1490
1491 This surprising autovivification in what does not at first--or even
1492 second--glance appear to be an lvalue context may be fixed in a future
1493 release.
1494
1495 See L<perlref/"Pseudo-hashes: Using an array as a hash"> for specifics
1496 on how exists() acts when used on a pseudo-hash.
1497
1498 Use of a subroutine call, rather than a subroutine name, as an argument
1499 to exists() is an error.
1500
1501     exists &sub;        # OK
1502     exists &sub();      # Error
1503
1504 =item exit EXPR
1505
1506 Evaluates EXPR and exits immediately with that value.    Example:
1507
1508     $ans = <STDIN>;
1509     exit 0 if $ans =~ /^[Xx]/;
1510
1511 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1512 universally recognized values for EXPR are C<0> for success and C<1>
1513 for error; other values are subject to interpretation depending on the
1514 environment in which the Perl program is running.  For example, exiting
1515 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1516 the mailer to return the item undelivered, but that's not true everywhere.
1517
1518 Don't use C<exit> to abort a subroutine if there's any chance that
1519 someone might want to trap whatever error happened.  Use C<die> instead,
1520 which can be trapped by an C<eval>.
1521
1522 The exit() function does not always exit immediately.  It calls any
1523 defined C<END> routines first, but these C<END> routines may not
1524 themselves abort the exit.  Likewise any object destructors that need to
1525 be called are called before the real exit.  If this is a problem, you
1526 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1527 See L<perlmod> for details.
1528
1529 =item exp EXPR
1530
1531 =item exp
1532
1533 Returns I<e> (the natural logarithm base) to the power of EXPR.  
1534 If EXPR is omitted, gives C<exp($_)>.
1535
1536 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1537
1538 Implements the fcntl(2) function.  You'll probably have to say
1539
1540     use Fcntl;
1541
1542 first to get the correct constant definitions.  Argument processing and
1543 value return works just like C<ioctl> below.  
1544 For example:
1545
1546     use Fcntl;
1547     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1548         or die "can't fcntl F_GETFL: $!";
1549
1550 You don't have to check for C<defined> on the return from C<fnctl>.
1551 Like C<ioctl>, it maps a C<0> return from the system call into
1552 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1553 in numeric context.  It is also exempt from the normal B<-w> warnings
1554 on improper numeric conversions.
1555
1556 Note that C<fcntl> will produce a fatal error if used on a machine that
1557 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1558 manpage to learn what functions are available on your system.
1559
1560 =item fileno FILEHANDLE
1561
1562 Returns the file descriptor for a filehandle, or undefined if the
1563 filehandle is not open.  This is mainly useful for constructing
1564 bitmaps for C<select> and low-level POSIX tty-handling operations.
1565 If FILEHANDLE is an expression, the value is taken as an indirect
1566 filehandle, generally its name.
1567
1568 You can use this to find out whether two handles refer to the 
1569 same underlying descriptor:
1570
1571     if (fileno(THIS) == fileno(THAT)) {
1572         print "THIS and THAT are dups\n";
1573     } 
1574
1575 =item flock FILEHANDLE,OPERATION
1576
1577 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1578 for success, false on failure.  Produces a fatal error if used on a
1579 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1580 C<flock> is Perl's portable file locking interface, although it locks
1581 only entire files, not records.
1582
1583 Two potentially non-obvious but traditional C<flock> semantics are
1584 that it waits indefinitely until the lock is granted, and that its locks
1585 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1586 fewer guarantees.  This means that files locked with C<flock> may be
1587 modified by programs that do not also use C<flock>.  See L<perlport>,
1588 your port's specific documentation, or your system-specific local manpages
1589 for details.  It's best to assume traditional behavior if you're writing
1590 portable programs.  (But if you're not, you should as always feel perfectly
1591 free to write for your own system's idiosyncrasies (sometimes called
1592 "features").  Slavish adherence to portability concerns shouldn't get
1593 in the way of your getting your job done.)
1594
1595 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1596 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1597 you can use the symbolic names if you import them from the Fcntl module,
1598 either individually, or as a group using the ':flock' tag.  LOCK_SH
1599 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1600 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1601 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1602 waiting for the lock (check the return status to see if you got it).
1603
1604 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1605 before locking or unlocking it.
1606
1607 Note that the emulation built with lockf(3) doesn't provide shared
1608 locks, and it requires that FILEHANDLE be open with write intent.  These
1609 are the semantics that lockf(3) implements.  Most if not all systems
1610 implement lockf(3) in terms of fcntl(2) locking, though, so the
1611 differing semantics shouldn't bite too many people.
1612
1613 Note also that some versions of C<flock> cannot lock things over the
1614 network; you would need to use the more system-specific C<fcntl> for
1615 that.  If you like you can force Perl to ignore your system's flock(2)
1616 function, and so provide its own fcntl(2)-based emulation, by passing
1617 the switch C<-Ud_flock> to the F<Configure> program when you configure
1618 perl.
1619
1620 Here's a mailbox appender for BSD systems.
1621
1622     use Fcntl ':flock'; # import LOCK_* constants
1623
1624     sub lock {
1625         flock(MBOX,LOCK_EX);
1626         # and, in case someone appended
1627         # while we were waiting...
1628         seek(MBOX, 0, 2);
1629     }
1630
1631     sub unlock {
1632         flock(MBOX,LOCK_UN);
1633     }
1634
1635     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1636             or die "Can't open mailbox: $!";
1637
1638     lock();
1639     print MBOX $msg,"\n\n";
1640     unlock();
1641
1642 On systems that support a real flock(), locks are inherited across fork()
1643 calls, whereas those that must resort to the more capricious fcntl()
1644 function lose the locks, making it harder to write servers.
1645
1646 See also L<DB_File> for other flock() examples.
1647
1648 =item fork
1649
1650 Does a fork(2) system call to create a new process running the
1651 same program at the same point.  It returns the child pid to the
1652 parent process, C<0> to the child process, or C<undef> if the fork is
1653 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1654 are shared, while everything else is copied.  On most systems supporting
1655 fork(), great care has gone into making it extremely efficient (for
1656 example, using copy-on-write technology on data pages), making it the
1657 dominant paradigm for multitasking over the last few decades.
1658
1659 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1660 output before forking the child process, but this may not be supported
1661 on some platforms (see L<perlport>).  To be safe, you may need to set
1662 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1663 C<IO::Handle> on any open handles in order to avoid duplicate output.
1664
1665 If you C<fork> without ever waiting on your children, you will
1666 accumulate zombies.  On some systems, you can avoid this by setting
1667 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1668 forking and reaping moribund children.
1669
1670 Note that if your forked child inherits system file descriptors like
1671 STDIN and STDOUT that are actually connected by a pipe or socket, even
1672 if you exit, then the remote server (such as, say, a CGI script or a
1673 backgrounded job launched from a remote shell) won't think you're done.
1674 You should reopen those to F</dev/null> if it's any issue.
1675
1676 =item format
1677
1678 Declare a picture format for use by the C<write> function.  For
1679 example:
1680
1681     format Something =
1682         Test: @<<<<<<<< @||||| @>>>>>
1683               $str,     $%,    '$' . int($num)
1684     .
1685
1686     $str = "widget";
1687     $num = $cost/$quantity;
1688     $~ = 'Something';
1689     write;
1690
1691 See L<perlform> for many details and examples.
1692
1693 =item formline PICTURE,LIST
1694
1695 This is an internal function used by C<format>s, though you may call it,
1696 too.  It formats (see L<perlform>) a list of values according to the
1697 contents of PICTURE, placing the output into the format output
1698 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1699 Eventually, when a C<write> is done, the contents of
1700 C<$^A> are written to some filehandle, but you could also read C<$^A>
1701 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1702 does one C<formline> per line of form, but the C<formline> function itself
1703 doesn't care how many newlines are embedded in the PICTURE.  This means
1704 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1705 You may therefore need to use multiple formlines to implement a single
1706 record format, just like the format compiler.
1707
1708 Be careful if you put double quotes around the picture, because an C<@>
1709 character may be taken to mean the beginning of an array name.
1710 C<formline> always returns true.  See L<perlform> for other examples.
1711
1712 =item getc FILEHANDLE
1713
1714 =item getc
1715
1716 Returns the next character from the input file attached to FILEHANDLE,
1717 or the undefined value at end of file, or if there was an error.
1718 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1719 efficient.  However, it cannot be used by itself to fetch single
1720 characters without waiting for the user to hit enter.  For that, try
1721 something more like:
1722
1723     if ($BSD_STYLE) {
1724         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1725     }
1726     else {
1727         system "stty", '-icanon', 'eol', "\001";
1728     }
1729
1730     $key = getc(STDIN);
1731
1732     if ($BSD_STYLE) {
1733         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1734     }
1735     else {
1736         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1737     }
1738     print "\n";
1739
1740 Determination of whether $BSD_STYLE should be set
1741 is left as an exercise to the reader.
1742
1743 The C<POSIX::getattr> function can do this more portably on
1744 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1745 module from your nearest CPAN site; details on CPAN can be found on
1746 L<perlmodlib/CPAN>.
1747
1748 =item getlogin
1749
1750 Implements the C library function of the same name, which on most
1751 systems returns the current login from F</etc/utmp>, if any.  If null,
1752 use C<getpwuid>.
1753
1754     $login = getlogin || getpwuid($<) || "Kilroy";
1755
1756 Do not consider C<getlogin> for authentication: it is not as
1757 secure as C<getpwuid>.
1758
1759 =item getpeername SOCKET
1760
1761 Returns the packed sockaddr address of other end of the SOCKET connection.
1762
1763     use Socket;
1764     $hersockaddr    = getpeername(SOCK);
1765     ($port, $iaddr) = sockaddr_in($hersockaddr);
1766     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1767     $herstraddr     = inet_ntoa($iaddr);
1768
1769 =item getpgrp PID
1770
1771 Returns the current process group for the specified PID.  Use
1772 a PID of C<0> to get the current process group for the
1773 current process.  Will raise an exception if used on a machine that
1774 doesn't implement getpgrp(2).  If PID is omitted, returns process
1775 group of current process.  Note that the POSIX version of C<getpgrp>
1776 does not accept a PID argument, so only C<PID==0> is truly portable.
1777
1778 =item getppid
1779
1780 Returns the process id of the parent process.
1781
1782 =item getpriority WHICH,WHO
1783
1784 Returns the current priority for a process, a process group, or a user.
1785 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1786 machine that doesn't implement getpriority(2).
1787
1788 =item getpwnam NAME
1789
1790 =item getgrnam NAME
1791
1792 =item gethostbyname NAME
1793
1794 =item getnetbyname NAME
1795
1796 =item getprotobyname NAME
1797
1798 =item getpwuid UID
1799
1800 =item getgrgid GID
1801
1802 =item getservbyname NAME,PROTO
1803
1804 =item gethostbyaddr ADDR,ADDRTYPE
1805
1806 =item getnetbyaddr ADDR,ADDRTYPE
1807
1808 =item getprotobynumber NUMBER
1809
1810 =item getservbyport PORT,PROTO
1811
1812 =item getpwent
1813
1814 =item getgrent
1815
1816 =item gethostent
1817
1818 =item getnetent
1819
1820 =item getprotoent
1821
1822 =item getservent
1823
1824 =item setpwent
1825
1826 =item setgrent
1827
1828 =item sethostent STAYOPEN
1829
1830 =item setnetent STAYOPEN
1831
1832 =item setprotoent STAYOPEN
1833
1834 =item setservent STAYOPEN
1835
1836 =item endpwent
1837
1838 =item endgrent
1839
1840 =item endhostent
1841
1842 =item endnetent
1843
1844 =item endprotoent
1845
1846 =item endservent
1847
1848 These routines perform the same functions as their counterparts in the
1849 system library.  In list context, the return values from the
1850 various get routines are as follows:
1851
1852     ($name,$passwd,$uid,$gid,
1853        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1854     ($name,$passwd,$gid,$members) = getgr*
1855     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1856     ($name,$aliases,$addrtype,$net) = getnet*
1857     ($name,$aliases,$proto) = getproto*
1858     ($name,$aliases,$port,$proto) = getserv*
1859
1860 (If the entry doesn't exist you get a null list.)
1861
1862 The exact meaning of the $gcos field varies but it usually contains
1863 the real name of the user (as opposed to the login name) and other
1864 information pertaining to the user.  Beware, however, that in many
1865 system users are able to change this information and therefore it
1866 cannot be trusted and therefore the $gcos is tainted (see
1867 L<perlsec>).  The $passwd and $shell, user's encrypted password and
1868 login shell, are also tainted, because of the same reason.
1869
1870 In scalar context, you get the name, unless the function was a
1871 lookup by name, in which case you get the other thing, whatever it is.
1872 (If the entry doesn't exist you get the undefined value.)  For example:
1873
1874     $uid   = getpwnam($name);
1875     $name  = getpwuid($num);
1876     $name  = getpwent();
1877     $gid   = getgrnam($name);
1878     $name  = getgrgid($num;
1879     $name  = getgrent();
1880     #etc.
1881
1882 In I<getpw*()> the fields $quota, $comment, and $expire are special
1883 cases in the sense that in many systems they are unsupported.  If the
1884 $quota is unsupported, it is an empty scalar.  If it is supported, it
1885 usually encodes the disk quota.  If the $comment field is unsupported,
1886 it is an empty scalar.  If it is supported it usually encodes some
1887 administrative comment about the user.  In some systems the $quota
1888 field may be $change or $age, fields that have to do with password
1889 aging.  In some systems the $comment field may be $class.  The $expire
1890 field, if present, encodes the expiration period of the account or the
1891 password.  For the availability and the exact meaning of these fields
1892 in your system, please consult your getpwnam(3) documentation and your
1893 F<pwd.h> file.  You can also find out from within Perl what your
1894 $quota and $comment fields mean and whether you have the $expire field
1895 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1896 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
1897 files are only supported if your vendor has implemented them in the
1898 intuitive fashion that calling the regular C library routines gets the
1899 shadow versions if you're running under privilege or if there exists
1900 the shadow(3) functions as found in System V ( this includes Solaris
1901 and Linux.)  Those systems which implement a proprietary shadow password
1902 facility are unlikely to be supported.
1903
1904 The $members value returned by I<getgr*()> is a space separated list of
1905 the login names of the members of the group.
1906
1907 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1908 C, it will be returned to you via C<$?> if the function call fails.  The
1909 C<@addrs> value returned by a successful call is a list of the raw
1910 addresses returned by the corresponding system library call.  In the
1911 Internet domain, each address is four bytes long and you can unpack it
1912 by saying something like:
1913
1914     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1915
1916 The Socket library makes this slightly easier:
1917
1918     use Socket;
1919     $iaddr = inet_aton("127.1"); # or whatever address
1920     $name  = gethostbyaddr($iaddr, AF_INET);
1921
1922     # or going the other way
1923     $straddr = inet_ntoa($iaddr);
1924
1925 If you get tired of remembering which element of the return list
1926 contains which return value, by-name interfaces are provided
1927 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1928 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1929 and C<User::grent>.  These override the normal built-ins, supplying
1930 versions that return objects with the appropriate names
1931 for each field.  For example:
1932
1933    use File::stat;
1934    use User::pwent;
1935    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1936
1937 Even though it looks like they're the same method calls (uid), 
1938 they aren't, because a C<File::stat> object is different from 
1939 a C<User::pwent> object.
1940
1941 =item getsockname SOCKET
1942
1943 Returns the packed sockaddr address of this end of the SOCKET connection,
1944 in case you don't know the address because you have several different
1945 IPs that the connection might have come in on.
1946
1947     use Socket;
1948     $mysockaddr = getsockname(SOCK);
1949     ($port, $myaddr) = sockaddr_in($mysockaddr);
1950     printf "Connect to %s [%s]\n", 
1951        scalar gethostbyaddr($myaddr, AF_INET),
1952        inet_ntoa($myaddr);
1953
1954 =item getsockopt SOCKET,LEVEL,OPTNAME
1955
1956 Returns the socket option requested, or undef if there is an error.
1957
1958 =item glob EXPR
1959
1960 =item glob
1961
1962 Returns the value of EXPR with filename expansions such as the
1963 standard Unix shell F</bin/csh> would do.  This is the internal function
1964 implementing the C<< <*.c> >> operator, but you can use it directly.
1965 If EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is
1966 discussed in more detail in L<perlop/"I/O Operators">.
1967
1968 Beginning with v5.6.0, this operator is implemented using the standard
1969 C<File::Glob> extension.  See L<File::Glob> for details.
1970
1971 =item gmtime EXPR
1972
1973 Converts a time as returned by the time function to a 8-element list
1974 with the time localized for the standard Greenwich time zone.
1975 Typically used as follows:
1976
1977     #  0    1    2     3     4    5     6     7  
1978     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
1979                                             gmtime(time);
1980
1981 All list elements are numeric, and come straight out of the C `struct
1982 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
1983 specified time.  $mday is the day of the month, and $mon is the month
1984 itself, in the range C<0..11> with 0 indicating January and 11
1985 indicating December.  $year is the number of years since 1900.  That
1986 is, $year is C<123> in year 2023.  $wday is the day of the week, with
1987 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
1988 the year, in the range C<0..364> (or C<0..365> in leap years.)  
1989
1990 Note that the $year element is I<not> simply the last two digits of
1991 the year.  If you assume it is, then you create non-Y2K-compliant
1992 programs--and you wouldn't want to do that, would you?
1993
1994 The proper way to get a complete 4-digit year is simply:
1995
1996         $year += 1900;
1997
1998 And to get the last two digits of the year (e.g., '01' in 2001) do:
1999
2000         $year = sprintf("%02d", $year % 100);
2001
2002 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2003
2004 In scalar context, C<gmtime()> returns the ctime(3) value:
2005
2006     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2007
2008 Also see the C<timegm> function provided by the C<Time::Local> module,
2009 and the strftime(3) function available via the POSIX module.
2010
2011 This scalar value is B<not> locale dependent (see L<perllocale>), but
2012 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2013 strftime(3) and mktime(3) functions available via the POSIX module.  To
2014 get somewhat similar but locale dependent date strings, set up your
2015 locale environment variables appropriately (please see L<perllocale>)
2016 and try for example:
2017
2018     use POSIX qw(strftime);
2019     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2020
2021 Note that the C<%a> and C<%b> escapes, which represent the short forms
2022 of the day of the week and the month of the year, may not necessarily
2023 be three characters wide in all locales.
2024
2025 =item goto LABEL
2026
2027 =item goto EXPR
2028
2029 =item goto &NAME
2030
2031 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2032 execution there.  It may not be used to go into any construct that
2033 requires initialization, such as a subroutine or a C<foreach> loop.  It
2034 also can't be used to go into a construct that is optimized away,
2035 or to get out of a block or subroutine given to C<sort>.
2036 It can be used to go almost anywhere else within the dynamic scope,
2037 including out of subroutines, but it's usually better to use some other
2038 construct such as C<last> or C<die>.  The author of Perl has never felt the
2039 need to use this form of C<goto> (in Perl, that is--C is another matter).
2040
2041 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2042 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2043 necessarily recommended if you're optimizing for maintainability:
2044
2045     goto ("FOO", "BAR", "GLARCH")[$i];
2046
2047 The C<goto-&NAME> form is quite different from the other forms of C<goto>.
2048 In fact, it isn't a goto in the normal sense at all, and doesn't have
2049 the stigma associated with other gotos.  Instead, it
2050 substitutes a call to the named subroutine for the currently running
2051 subroutine.  This is used by C<AUTOLOAD> subroutines that wish to load
2052 another subroutine and then pretend that the other subroutine had been
2053 called in the first place (except that any modifications to C<@_>
2054 in the current subroutine are propagated to the other subroutine.)
2055 After the C<goto>, not even C<caller> will be able to tell that this
2056 routine was called first.
2057
2058 NAME needn't be the name of a subroutine; it can be a scalar variable
2059 containing a code reference, or a block which evaluates to a code
2060 reference.
2061
2062 =item grep BLOCK LIST
2063
2064 =item grep EXPR,LIST
2065
2066 This is similar in spirit to, but not the same as, grep(1) and its
2067 relatives.  In particular, it is not limited to using regular expressions.
2068
2069 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2070 C<$_> to each element) and returns the list value consisting of those
2071 elements for which the expression evaluated to true.  In scalar
2072 context, returns the number of times the expression was true.
2073
2074     @foo = grep(!/^#/, @bar);    # weed out comments
2075
2076 or equivalently,
2077
2078     @foo = grep {!/^#/} @bar;    # weed out comments
2079
2080 Note that, because C<$_> is a reference into the list value, it can
2081 be used to modify the elements of the array.  While this is useful and
2082 supported, it can cause bizarre results if the LIST is not a named array.
2083 Similarly, grep returns aliases into the original list, much as a for
2084 loop's index variable aliases the list elements.  That is, modifying an
2085 element of a list returned by grep (for example, in a C<foreach>, C<map>
2086 or another C<grep>) actually modifies the element in the original list.
2087 This is usually something to be avoided when writing clear code.
2088
2089 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2090
2091 =item hex EXPR
2092
2093 =item hex
2094
2095 Interprets EXPR as a hex string and returns the corresponding value.
2096 (To convert strings that might start with either 0, 0x, or 0b, see
2097 L</oct>.)  If EXPR is omitted, uses C<$_>.
2098
2099     print hex '0xAf'; # prints '175'
2100     print hex 'aF';   # same
2101
2102 Hex strings may only represent integers.  Strings that would cause
2103 integer overflow trigger a warning.
2104
2105 =item import
2106
2107 There is no builtin C<import> function.  It is just an ordinary
2108 method (subroutine) defined (or inherited) by modules that wish to export
2109 names to another module.  The C<use> function calls the C<import> method
2110 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
2111
2112 =item index STR,SUBSTR,POSITION
2113
2114 =item index STR,SUBSTR
2115
2116 The index function searches for one string within another, but without
2117 the wildcard-like behavior of a full regular-expression pattern match.
2118 It returns the position of the first occurrence of SUBSTR in STR at
2119 or after POSITION.  If POSITION is omitted, starts searching from the
2120 beginning of the string.  The return value is based at C<0> (or whatever
2121 you've set the C<$[> variable to--but don't do that).  If the substring
2122 is not found, returns one less than the base, ordinarily C<-1>.
2123
2124 =item int EXPR
2125
2126 =item int
2127
2128 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2129 You should not use this function for rounding: one because it truncates
2130 towards C<0>, and two because machine representations of floating point
2131 numbers can sometimes produce counterintuitive results.  For example,
2132 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2133 because it's really more like -268.99999999999994315658 instead.  Usually,
2134 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2135 functions will serve you better than will int().
2136
2137 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2138
2139 Implements the ioctl(2) function.  You'll probably first have to say
2140
2141     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2142
2143 to get the correct function definitions.  If F<ioctl.ph> doesn't
2144 exist or doesn't have the correct definitions you'll have to roll your
2145 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2146 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2147 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2148 written depending on the FUNCTION--a pointer to the string value of SCALAR
2149 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2150 has no string value but does have a numeric value, that value will be
2151 passed rather than a pointer to the string value.  To guarantee this to be
2152 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2153 functions may be needed to manipulate the values of structures used by
2154 C<ioctl>.  
2155
2156 The return value of C<ioctl> (and C<fcntl>) is as follows:
2157
2158         if OS returns:          then Perl returns:
2159             -1                    undefined value
2160              0                  string "0 but true"
2161         anything else               that number
2162
2163 Thus Perl returns true on success and false on failure, yet you can
2164 still easily determine the actual value returned by the operating
2165 system:
2166
2167     $retval = ioctl(...) || -1;
2168     printf "System returned %d\n", $retval;
2169
2170 The special string "C<0> but true" is exempt from B<-w> complaints
2171 about improper numeric conversions.
2172
2173 Here's an example of setting a filehandle named C<REMOTE> to be
2174 non-blocking at the system level.  You'll have to negotiate C<$|>
2175 on your own, though.
2176
2177     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2178
2179     $flags = fcntl(REMOTE, F_GETFL, 0)
2180                 or die "Can't get flags for the socket: $!\n";
2181
2182     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2183                 or die "Can't set flags for the socket: $!\n";
2184
2185 =item join EXPR,LIST
2186
2187 Joins the separate strings of LIST into a single string with fields
2188 separated by the value of EXPR, and returns that new string.  Example:
2189
2190     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2191
2192 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2193 first argument.  Compare L</split>.
2194
2195 =item keys HASH
2196
2197 Returns a list consisting of all the keys of the named hash.  (In
2198 scalar context, returns the number of keys.)  The keys are returned in
2199 an apparently random order.  The actual random order is subject to
2200 change in future versions of perl, but it is guaranteed to be the same
2201 order as either the C<values> or C<each> function produces (given
2202 that the hash has not been modified).  As a side effect, it resets
2203 HASH's iterator.
2204
2205 Here is yet another way to print your environment:
2206
2207     @keys = keys %ENV;
2208     @values = values %ENV;
2209     while (@keys) { 
2210         print pop(@keys), '=', pop(@values), "\n";
2211     }
2212
2213 or how about sorted by key:
2214
2215     foreach $key (sort(keys %ENV)) {
2216         print $key, '=', $ENV{$key}, "\n";
2217     }
2218
2219 The returned values are copies of the original keys in the hash, so
2220 modifying them will not affect the original hash.  Compare L</values>.
2221
2222 To sort a hash by value, you'll need to use a C<sort> function.
2223 Here's a descending numeric sort of a hash by its values:
2224
2225     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2226         printf "%4d %s\n", $hash{$key}, $key;
2227     }
2228
2229 As an lvalue C<keys> allows you to increase the number of hash buckets
2230 allocated for the given hash.  This can gain you a measure of efficiency if
2231 you know the hash is going to get big.  (This is similar to pre-extending
2232 an array by assigning a larger number to $#array.)  If you say
2233
2234     keys %hash = 200;
2235
2236 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2237 in fact, since it rounds up to the next power of two.  These
2238 buckets will be retained even if you do C<%hash = ()>, use C<undef
2239 %hash> if you want to free the storage while C<%hash> is still in scope.
2240 You can't shrink the number of buckets allocated for the hash using
2241 C<keys> in this way (but you needn't worry about doing this by accident,
2242 as trying has no effect).
2243
2244 See also C<each>, C<values> and C<sort>.
2245
2246 =item kill SIGNAL, LIST
2247
2248 Sends a signal to a list of processes.  Returns the number of
2249 processes successfully signaled (which is not necessarily the
2250 same as the number actually killed).
2251
2252     $cnt = kill 1, $child1, $child2;
2253     kill 9, @goners;
2254
2255 If SIGNAL is zero, no signal is sent to the process.  This is a
2256 useful way to check that the process is alive and hasn't changed
2257 its UID.  See L<perlport> for notes on the portability of this
2258 construct.
2259
2260 Unlike in the shell, if SIGNAL is negative, it kills
2261 process groups instead of processes.  (On System V, a negative I<PROCESS>
2262 number will also kill process groups, but that's not portable.)  That
2263 means you usually want to use positive not negative signals.  You may also
2264 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2265
2266 =item last LABEL
2267
2268 =item last
2269
2270 The C<last> command is like the C<break> statement in C (as used in
2271 loops); it immediately exits the loop in question.  If the LABEL is
2272 omitted, the command refers to the innermost enclosing loop.  The
2273 C<continue> block, if any, is not executed:
2274
2275     LINE: while (<STDIN>) {
2276         last LINE if /^$/;      # exit when done with header
2277         #...
2278     }
2279
2280 C<last> cannot be used to exit a block which returns a value such as
2281 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2282 a grep() or map() operation.
2283
2284 Note that a block by itself is semantically identical to a loop
2285 that executes once.  Thus C<last> can be used to effect an early
2286 exit out of such a block.
2287
2288 See also L</continue> for an illustration of how C<last>, C<next>, and
2289 C<redo> work.
2290
2291 =item lc EXPR
2292
2293 =item lc
2294
2295 Returns an lowercased version of EXPR.  This is the internal function
2296 implementing the C<\L> escape in double-quoted strings.
2297 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2298 and L<utf8>.
2299
2300 If EXPR is omitted, uses C<$_>.
2301
2302 =item lcfirst EXPR
2303
2304 =item lcfirst
2305
2306 Returns the value of EXPR with the first character lowercased.  This is
2307 the internal function implementing the C<\l> escape in double-quoted strings.
2308 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
2309
2310 If EXPR is omitted, uses C<$_>.
2311
2312 =item length EXPR
2313
2314 =item length
2315
2316 Returns the length in characters of the value of EXPR.  If EXPR is
2317 omitted, returns length of C<$_>.  Note that this cannot be used on 
2318 an entire array or hash to find out how many elements these have.
2319 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2320
2321 =item link OLDFILE,NEWFILE
2322
2323 Creates a new filename linked to the old filename.  Returns true for
2324 success, false otherwise. 
2325
2326 =item listen SOCKET,QUEUESIZE
2327
2328 Does the same thing that the listen system call does.  Returns true if
2329 it succeeded, false otherwise.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
2330
2331 =item local EXPR
2332
2333 You really probably want to be using C<my> instead, because C<local> isn't
2334 what most people think of as "local".  See L<perlsub/"Private Variables
2335 via my()"> for details.
2336
2337 A local modifies the listed variables to be local to the enclosing
2338 block, file, or eval.  If more than one value is listed, the list must
2339 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2340 for details, including issues with tied arrays and hashes.
2341
2342 =item localtime EXPR
2343
2344 Converts a time as returned by the time function to a 9-element list
2345 with the time analyzed for the local time zone.  Typically used as
2346 follows:
2347
2348     #  0    1    2     3     4    5     6     7     8
2349     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2350                                                 localtime(time);
2351
2352 All list elements are numeric, and come straight out of the C `struct
2353 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2354 specified time.  $mday is the day of the month, and $mon is the month
2355 itself, in the range C<0..11> with 0 indicating January and 11
2356 indicating December.  $year is the number of years since 1900.  That
2357 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2358 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2359 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2360 is true if the specified time occurs during daylight savings time,
2361 false otherwise.
2362
2363 Note that the $year element is I<not> simply the last two digits of
2364 the year.  If you assume it is, then you create non-Y2K-compliant
2365 programs--and you wouldn't want to do that, would you?
2366
2367 The proper way to get a complete 4-digit year is simply:
2368
2369         $year += 1900;
2370
2371 And to get the last two digits of the year (e.g., '01' in 2001) do:
2372
2373         $year = sprintf("%02d", $year % 100);
2374
2375 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2376
2377 In scalar context, C<localtime()> returns the ctime(3) value:
2378
2379     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2380
2381 This scalar value is B<not> locale dependent, see L<perllocale>, but
2382 instead a Perl builtin.  Also see the C<Time::Local> module
2383 (to convert the second, minutes, hours, ... back to seconds since the
2384 stroke of midnight the 1st of January 1970, the value returned by
2385 time()), and the strftime(3) and mktime(3) functions available via the
2386 POSIX module.  To get somewhat similar but locale dependent date
2387 strings, set up your locale environment variables appropriately
2388 (please see L<perllocale>) and try for example:
2389
2390     use POSIX qw(strftime);
2391     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2392
2393 Note that the C<%a> and C<%b>, the short forms of the day of the week
2394 and the month of the year, may not necessarily be three characters wide.
2395
2396 =item lock
2397
2398     lock I<THING>
2399
2400 This function places an advisory lock on a variable, subroutine,
2401 or referenced object contained in I<THING> until the lock goes out
2402 of scope.  This is a built-in function only if your version of Perl
2403 was built with threading enabled, and if you've said C<use Threads>.
2404 Otherwise a user-defined function by this name will be called.  See
2405 L<Thread>.
2406
2407 =item log EXPR
2408
2409 =item log
2410
2411 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2412 returns log of C<$_>.  To get the log of another base, use basic algebra:
2413 The base-N log of a number is equal to the natural log of that number
2414 divided by the natural log of N.  For example:
2415
2416     sub log10 {
2417         my $n = shift;
2418         return log($n)/log(10);
2419     } 
2420
2421 See also L</exp> for the inverse operation.
2422
2423 =item lstat FILEHANDLE
2424
2425 =item lstat EXPR
2426
2427 =item lstat
2428
2429 Does the same thing as the C<stat> function (including setting the
2430 special C<_> filehandle) but stats a symbolic link instead of the file
2431 the symbolic link points to.  If symbolic links are unimplemented on
2432 your system, a normal C<stat> is done.
2433
2434 If EXPR is omitted, stats C<$_>.
2435
2436 =item m//
2437
2438 The match operator.  See L<perlop>.
2439
2440 =item map BLOCK LIST
2441
2442 =item map EXPR,LIST
2443
2444 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2445 C<$_> to each element) and returns the list value composed of the
2446 results of each such evaluation.  In scalar context, returns the
2447 total number of elements so generated.  Evaluates BLOCK or EXPR in
2448 list context, so each element of LIST may produce zero, one, or
2449 more elements in the returned value.
2450
2451     @chars = map(chr, @nums);
2452
2453 translates a list of numbers to the corresponding characters.  And
2454
2455     %hash = map { getkey($_) => $_ } @array;
2456
2457 is just a funny way to write
2458
2459     %hash = ();
2460     foreach $_ (@array) {
2461         $hash{getkey($_)} = $_;
2462     }
2463
2464 Note that, because C<$_> is a reference into the list value, it can
2465 be used to modify the elements of the array.  While this is useful and
2466 supported, it can cause bizarre results if the LIST is not a named array.
2467 Using a regular C<foreach> loop for this purpose would be clearer in
2468 most cases.  See also L</grep> for an array composed of those items of
2469 the original list for which the BLOCK or EXPR evaluates to true.
2470
2471 =item mkdir FILENAME,MASK
2472
2473 =item mkdir FILENAME
2474
2475 Creates the directory specified by FILENAME, with permissions
2476 specified by MASK (as modified by C<umask>).  If it succeeds it
2477 returns true, otherwise it returns false and sets C<$!> (errno).
2478 If omitted, MASK defaults to 0777.
2479
2480 In general, it is better to create directories with permissive MASK,
2481 and let the user modify that with their C<umask>, than it is to supply
2482 a restrictive MASK and give the user no way to be more permissive.
2483 The exceptions to this rule are when the file or directory should be
2484 kept private (mail files, for instance).  The perlfunc(1) entry on
2485 C<umask> discusses the choice of MASK in more detail.
2486
2487 =item msgctl ID,CMD,ARG
2488
2489 Calls the System V IPC function msgctl(2).  You'll probably have to say
2490
2491     use IPC::SysV;
2492
2493 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2494 then ARG must be a variable which will hold the returned C<msqid_ds>
2495 structure.  Returns like C<ioctl>: the undefined value for error,
2496 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2497 C<IPC::SysV> and C<IPC::Semaphore> documentation.
2498
2499 =item msgget KEY,FLAGS
2500
2501 Calls the System V IPC function msgget(2).  Returns the message queue
2502 id, or the undefined value if there is an error.  See also C<IPC::SysV>
2503 and C<IPC::Msg> documentation.
2504
2505 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2506
2507 Calls the System V IPC function msgrcv to receive a message from
2508 message queue ID into variable VAR with a maximum message size of
2509 SIZE.  Note that when a message is received, the message type as a
2510 native long integer will be the first thing in VAR, followed by the
2511 actual message.  This packing may be opened with C<unpack("l! a*")>.
2512 Taints the variable.  Returns true if successful, or false if there is
2513 an error.  See also C<IPC::SysV> and C<IPC::SysV::Msg> documentation.
2514
2515 =item msgsnd ID,MSG,FLAGS
2516
2517 Calls the System V IPC function msgsnd to send the message MSG to the
2518 message queue ID.  MSG must begin with the native long integer message
2519 type, and be followed by the length of the actual message, and finally
2520 the message itself.  This kind of packing can be achieved with
2521 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2522 or false if there is an error.  See also C<IPC::SysV>
2523 and C<IPC::SysV::Msg> documentation.
2524
2525 =item my EXPR
2526
2527 =item my EXPR : ATTRIBUTES
2528
2529 A C<my> declares the listed variables to be local (lexically) to the
2530 enclosing block, file, or C<eval>.  If
2531 more than one value is listed, the list must be placed in parentheses.  See
2532 L<perlsub/"Private Variables via my()"> for details.
2533
2534 =item next LABEL
2535
2536 =item next
2537
2538 The C<next> command is like the C<continue> statement in C; it starts
2539 the next iteration of the loop:
2540
2541     LINE: while (<STDIN>) {
2542         next LINE if /^#/;      # discard comments
2543         #...
2544     }
2545
2546 Note that if there were a C<continue> block on the above, it would get
2547 executed even on discarded lines.  If the LABEL is omitted, the command
2548 refers to the innermost enclosing loop.
2549
2550 C<next> cannot be used to exit a block which returns a value such as
2551 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2552 a grep() or map() operation.
2553
2554 Note that a block by itself is semantically identical to a loop
2555 that executes once.  Thus C<next> will exit such a block early.
2556
2557 See also L</continue> for an illustration of how C<last>, C<next>, and
2558 C<redo> work.
2559
2560 =item no Module LIST
2561
2562 See the L</use> function, which C<no> is the opposite of.
2563
2564 =item oct EXPR
2565
2566 =item oct
2567
2568 Interprets EXPR as an octal string and returns the corresponding
2569 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2570 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2571 binary string.)  The following will handle decimal, binary, octal, and
2572 hex in the standard Perl or C notation:
2573
2574     $val = oct($val) if $val =~ /^0/;
2575
2576 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2577 in octal), use sprintf() or printf():
2578
2579     $perms = (stat("filename"))[2] & 07777;
2580     $oct_perms = sprintf "%lo", $perms;
2581
2582 The oct() function is commonly used when a string such as C<644> needs
2583 to be converted into a file mode, for example. (Although perl will
2584 automatically convert strings into numbers as needed, this automatic
2585 conversion assumes base 10.)
2586
2587 =item open FILEHANDLE,MODE,LIST
2588
2589 =item open FILEHANDLE,EXPR
2590
2591 =item open FILEHANDLE
2592
2593 Opens the file whose filename is given by EXPR, and associates it with
2594 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
2595 name of the real filehandle wanted.  (This is considered a symbolic
2596 reference, so C<use strict 'refs'> should I<not> be in effect.)
2597
2598 If EXPR is omitted, the scalar
2599 variable of the same name as the FILEHANDLE contains the filename.
2600 (Note that lexical variables--those declared with C<my>--will not work
2601 for this purpose; so if you're using C<my>, specify EXPR in your call
2602 to open.)  See L<perlopentut> for a kinder, gentler explanation of opening
2603 files.
2604
2605 If MODE is C<< '<' >> or nothing, the file is opened for input.
2606 If MODE is C<< '>' >>, the file is truncated and opened for
2607 output, being created if necessary.  If MODE is C<<< '>>' >>>,
2608 the file is opened for appending, again being created if necessary. 
2609 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to indicate that
2610 you want both read and write access to the file; thus C<< '+<' >> is almost
2611 always preferred for read/write updates--the C<< '+>' >> mode would clobber the
2612 file first.  You can't usually use either read-write mode for updating
2613 textfiles, since they have variable length records.  See the B<-i>
2614 switch in L<perlrun> for a better approach.  The file is created with
2615 permissions of C<0666> modified by the process' C<umask> value.
2616
2617 These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>,
2618 C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2619
2620 In the 2-arguments (and 1-argument) form of the call the mode and
2621 filename should be concatenated (in this order), possibly separated by
2622 spaces.  It is possible to omit the mode if the mode is C<< '<' >>.
2623
2624 If the filename begins with C<'|'>, the filename is interpreted as a
2625 command to which output is to be piped, and if the filename ends with a
2626 C<'|'>, the filename is interpreted as a command which pipes output to
2627 us.  See L<perlipc/"Using open() for IPC">
2628 for more examples of this.  (You are not allowed to C<open> to a command
2629 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2630 and L<perlipc/"Bidirectional Communication with Another Process">
2631 for alternatives.)
2632
2633 If MODE is C<'|-'>, the filename is interpreted as a
2634 command to which output is to be piped, and if MODE is
2635 C<'-|'>, the filename is interpreted as a command which pipes output to
2636 us.  In the 2-arguments (and 1-argument) form one should replace dash
2637 (C<'-'>) with the command.  See L<perlipc/"Using open() for IPC">
2638 for more examples of this.  (You are not allowed to C<open> to a command
2639 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2640 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2641
2642 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2643 and opening C<< '>-' >> opens STDOUT.  
2644
2645 Open returns
2646 nonzero upon success, the undefined value otherwise.  If the C<open>
2647 involved a pipe, the return value happens to be the pid of the
2648 subprocess.
2649
2650 If you're unfortunate enough to be running Perl on a system that
2651 distinguishes between text files and binary files (modern operating
2652 systems don't care), then you should check out L</binmode> for tips for
2653 dealing with this.  The key distinction between systems that need C<binmode>
2654 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2655 Plan9, which delimit lines with a single character, and which encode that
2656 character in C as C<"\n">, do not need C<binmode>.  The rest need it.
2657
2658 When opening a file, it's usually a bad idea to continue normal execution
2659 if the request failed, so C<open> is frequently used in connection with
2660 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2661 where you want to make a nicely formatted error message (but there are
2662 modules that can help with that problem)) you should always check
2663 the return value from opening a file.  The infrequent exception is when
2664 working with an unopened filehandle is actually what you want to do.
2665
2666 Examples:
2667
2668     $ARTICLE = 100;
2669     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2670     while (<ARTICLE>) {...
2671
2672     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2673     # if the open fails, output is discarded
2674
2675     open(DBASE, '+<', 'dbase.mine')             # open for update
2676         or die "Can't open 'dbase.mine' for update: $!";
2677
2678     open(DBASE, '+<dbase.mine')                 # ditto
2679         or die "Can't open 'dbase.mine' for update: $!";
2680
2681     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2682         or die "Can't start caesar: $!";
2683
2684     open(ARTICLE, "caesar <$article |")         # ditto
2685         or die "Can't start caesar: $!";
2686
2687     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2688         or die "Can't start sort: $!";
2689
2690     # process argument list of files along with any includes
2691
2692     foreach $file (@ARGV) {
2693         process($file, 'fh00');
2694     }
2695
2696     sub process {
2697         my($filename, $input) = @_;
2698         $input++;               # this is a string increment
2699         unless (open($input, $filename)) {
2700             print STDERR "Can't open $filename: $!\n";
2701             return;
2702         }
2703
2704         local $_;
2705         while (<$input>) {              # note use of indirection
2706             if (/^#include "(.*)"/) {
2707                 process($1, $input);
2708                 next;
2709             }
2710             #...                # whatever
2711         }
2712     }
2713
2714 You may also, in the Bourne shell tradition, specify an EXPR beginning
2715 with C<< '>&' >>, in which case the rest of the string is interpreted as the
2716 name of a filehandle (or file descriptor, if numeric) to be
2717 duped and opened.  You may use C<&> after C<< > >>, C<<< >> >>>,
2718 C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.  The
2719 mode you specify should match the mode of the original filehandle.
2720 (Duping a filehandle does not take into account any existing contents of
2721 stdio buffers.)  Duping file handles is not yet supported for 3-argument
2722 open().
2723
2724 Here is a script that saves, redirects, and restores STDOUT and
2725 STDERR:
2726
2727     #!/usr/bin/perl
2728     open(OLDOUT, ">&STDOUT");
2729     open(OLDERR, ">&STDERR");
2730
2731     open(STDOUT, '>', "foo.out") || die "Can't redirect stdout";
2732     open(STDERR, ">&STDOUT")     || die "Can't dup stdout";
2733
2734     select(STDERR); $| = 1;     # make unbuffered
2735     select(STDOUT); $| = 1;     # make unbuffered
2736
2737     print STDOUT "stdout 1\n";  # this works for
2738     print STDERR "stderr 1\n";  # subprocesses too
2739
2740     close(STDOUT);
2741     close(STDERR);
2742
2743     open(STDOUT, ">&OLDOUT");
2744     open(STDERR, ">&OLDERR");
2745
2746     print STDOUT "stdout 2\n";
2747     print STDERR "stderr 2\n";
2748
2749 If you specify C<< '<&=N' >>, where C<N> is a number, then Perl will do an
2750 equivalent of C's C<fdopen> of that file descriptor; this is more
2751 parsimonious of file descriptors.  For example:
2752
2753     open(FILEHANDLE, "<&=$fd")
2754
2755 Note that this feature depends on the fdopen() C library function.
2756 On many UNIX systems, fdopen() is known to fail when file descriptors
2757 exceed a certain value, typically 255. If you need more file
2758 descriptors than that, consider rebuilding Perl to use the C<sfio>
2759 library.
2760
2761 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2762 with 2-arguments (or 1-argument) form of open(), then
2763 there is an implicit fork done, and the return value of open is the pid
2764 of the child within the parent process, and C<0> within the child
2765 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2766 The filehandle behaves normally for the parent, but i/o to that
2767 filehandle is piped from/to the STDOUT/STDIN of the child process.
2768 In the child process the filehandle isn't opened--i/o happens from/to
2769 the new STDOUT or STDIN.  Typically this is used like the normal
2770 piped open when you want to exercise more control over just how the
2771 pipe command gets executed, such as when you are running setuid, and
2772 don't want to have to scan shell commands for metacharacters.
2773 The following triples are more or less equivalent:
2774
2775     open(FOO, "|tr '[a-z]' '[A-Z]'");
2776     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2777     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2778
2779     open(FOO, "cat -n '$file'|");
2780     open(FOO, '-|', "cat -n '$file'");
2781     open(FOO, '-|') || exec 'cat', '-n', $file;
2782
2783 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2784
2785 Beginning with v5.6.0, Perl will attempt to flush all files opened for
2786 output before any operation that may do a fork, but this may not be
2787 supported on some platforms (see L<perlport>).  To be safe, you may need
2788 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
2789 of C<IO::Handle> on any open handles.
2790
2791 On systems that support a
2792 close-on-exec flag on files, the flag will be set for the newly opened
2793 file descriptor as determined by the value of $^F.  See L<perlvar/$^F>.
2794
2795 Closing any piped filehandle causes the parent process to wait for the
2796 child to finish, and returns the status value in C<$?>.
2797
2798 The filename passed to 2-argument (or 1-argument) form of open()
2799 will have leading and trailing
2800 whitespace deleted, and the normal redirection characters
2801 honored.  This property, known as "magic open", 
2802 can often be used to good effect.  A user could specify a filename of
2803 F<"rsh cat file |">, or you could change certain filenames as needed:
2804
2805     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2806     open(FH, $filename) or die "Can't open $filename: $!";
2807
2808 Use 3-argument form to open a file with arbitrary weird characters in it,
2809
2810     open(FOO, '<', $file);
2811
2812 otherwise it's necessary to protect any leading and trailing whitespace:
2813
2814     $file =~ s#^(\s)#./$1#;
2815     open(FOO, "< $file\0");
2816
2817 (this may not work on some bizzare filesystems).  One should
2818 conscientiously choose between the I<magic> and 3-arguments form
2819 of open():
2820
2821     open IN, $ARGV[0];
2822
2823 will allow the user to specify an argument of the form C<"rsh cat file |">,
2824 but will not work on a filename which happens to have a trailing space, while
2825
2826     open IN, '<', $ARGV[0];
2827
2828 will have exactly the opposite restrictions.
2829
2830 If you want a "real" C C<open> (see L<open(2)> on your system), then you
2831 should use the C<sysopen> function, which involves no such magic (but
2832 may use subtly different filemodes than Perl open(), which is mapped
2833 to C fopen()).  This is
2834 another way to protect your filenames from interpretation.  For example:
2835
2836     use IO::Handle;
2837     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2838         or die "sysopen $path: $!";
2839     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2840     print HANDLE "stuff $$\n");
2841     seek(HANDLE, 0, 0);
2842     print "File contains: ", <HANDLE>;
2843
2844 Using the constructor from the C<IO::Handle> package (or one of its
2845 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2846 filehandles that have the scope of whatever variables hold references to
2847 them, and automatically close whenever and however you leave that scope:
2848
2849     use IO::File;
2850     #...
2851     sub read_myfile_munged {
2852         my $ALL = shift;
2853         my $handle = new IO::File;
2854         open($handle, "myfile") or die "myfile: $!";
2855         $first = <$handle>
2856             or return ();     # Automatically closed here.
2857         mung $first or die "mung failed";       # Or here.
2858         return $first, <$handle> if $ALL;       # Or here.
2859         $first;                                 # Or here.
2860     }
2861
2862 See L</seek> for some details about mixing reading and writing.
2863
2864 =item opendir DIRHANDLE,EXPR
2865
2866 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
2867 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
2868 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2869
2870 =item ord EXPR
2871
2872 =item ord
2873
2874 Returns the numeric (ASCII or Unicode) value of the first character of EXPR.  If
2875 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2876 See L<utf8> for more about Unicode.
2877
2878 =item our EXPR
2879
2880 An C<our> declares the listed variables to be valid globals within
2881 the enclosing block, file, or C<eval>.  That is, it has the same
2882 scoping rules as a "my" declaration, but does not create a local
2883 variable.  If more than one value is listed, the list must be placed
2884 in parentheses.  The C<our> declaration has no semantic effect unless
2885 "use strict vars" is in effect, in which case it lets you use the
2886 declared global variable without qualifying it with a package name.
2887 (But only within the lexical scope of the C<our> declaration.  In this
2888 it differs from "use vars", which is package scoped.)
2889
2890 An C<our> declaration declares a global variable that will be visible
2891 across its entire lexical scope, even across package boundaries.  The
2892 package in which the variable is entered is determined at the point
2893 of the declaration, not at the point of use.  This means the following
2894 behavior holds:
2895
2896     package Foo;
2897     our $bar;           # declares $Foo::bar for rest of lexical scope
2898     $bar = 20;
2899
2900     package Bar;
2901     print $bar;         # prints 20
2902
2903 Multiple C<our> declarations in the same lexical scope are allowed
2904 if they are in different packages.  If they happened to be in the same
2905 package, Perl will emit warnings if you have asked for them.
2906
2907     use warnings;
2908     package Foo;
2909     our $bar;           # declares $Foo::bar for rest of lexical scope
2910     $bar = 20;
2911
2912     package Bar;
2913     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
2914     print $bar;         # prints 30
2915
2916     our $bar;           # emits warning
2917
2918 =item pack TEMPLATE,LIST
2919
2920 Takes a LIST of values and converts it into a string using the rules
2921 given by the TEMPLATE.  The resulting string is the concatenation of
2922 the converted values.  Typically, each converted value looks
2923 like its machine-level representation.  For example, on 32-bit machines
2924 a converted integer may be represented by a sequence of 4 bytes.
2925
2926 The TEMPLATE is a
2927 sequence of characters that give the order and type of values, as
2928 follows:
2929
2930     a   A string with arbitrary binary data, will be null padded.
2931     A   An ASCII string, will be space padded.
2932     Z   A null terminated (asciz) string, will be null padded.
2933
2934     b   A bit string (ascending bit order inside each byte, like vec()).
2935     B   A bit string (descending bit order inside each byte).
2936     h   A hex string (low nybble first).
2937     H   A hex string (high nybble first).
2938
2939     c   A signed char value.
2940     C   An unsigned char value.  Only does bytes.  See U for Unicode.
2941
2942     s   A signed short value.
2943     S   An unsigned short value.
2944           (This 'short' is _exactly_ 16 bits, which may differ from
2945            what a local C compiler calls 'short'.  If you want
2946            native-length shorts, use the '!' suffix.)
2947
2948     i   A signed integer value.
2949     I   An unsigned integer value.
2950           (This 'integer' is _at_least_ 32 bits wide.  Its exact
2951            size depends on what a local C compiler calls 'int',
2952            and may even be larger than the 'long' described in
2953            the next item.)
2954
2955     l   A signed long value.
2956     L   An unsigned long value.
2957           (This 'long' is _exactly_ 32 bits, which may differ from
2958            what a local C compiler calls 'long'.  If you want
2959            native-length longs, use the '!' suffix.)
2960
2961     n   An unsigned short in "network" (big-endian) order.
2962     N   An unsigned long in "network" (big-endian) order.
2963     v   An unsigned short in "VAX" (little-endian) order.
2964     V   An unsigned long in "VAX" (little-endian) order.
2965           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2966            _exactly_ 32 bits, respectively.)
2967
2968     q   A signed quad (64-bit) value.
2969     Q   An unsigned quad value.
2970           (Quads are available only if your system supports 64-bit
2971            integer values _and_ if Perl has been compiled to support those.
2972            Causes a fatal error otherwise.)
2973
2974     f   A single-precision float in the native format.
2975     d   A double-precision float in the native format.
2976
2977     p   A pointer to a null-terminated string.
2978     P   A pointer to a structure (fixed-length string).
2979
2980     u   A uuencoded string.
2981     U   A Unicode character number.  Encodes to UTF-8 internally.
2982         Works even if C<use utf8> is not in effect.
2983
2984     w   A BER compressed integer.  Its bytes represent an unsigned
2985         integer in base 128, most significant digit first, with as
2986         few digits as possible.  Bit eight (the high bit) is set
2987         on each byte except the last.
2988
2989     x   A null byte.
2990     X   Back up a byte.
2991     @   Null fill to absolute position.
2992
2993 The following rules apply:
2994
2995 =over 8
2996
2997 =item *
2998
2999 Each letter may optionally be followed by a number giving a repeat
3000 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3001 C<H>, and C<P> the pack function will gobble up that many values from
3002 the LIST.  A C<*> for the repeat count means to use however many items are
3003 left, except for C<@>, C<x>, C<X>, where it is equivalent
3004 to C<0>, and C<u>, where it is equivalent to 1 (or 45, what is the
3005 same).
3006
3007 When used with C<Z>, C<*> results in the addition of a trailing null
3008 byte (so the packed result will be one longer than the byte C<length>
3009 of the item).
3010
3011 The repeat count for C<u> is interpreted as the maximal number of bytes
3012 to encode per line of output, with 0 and 1 replaced by 45.
3013
3014 =item *
3015
3016 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3017 string of length count, padding with nulls or spaces as necessary.  When
3018 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3019 after the first null, and C<a> returns data verbatim.  When packing,
3020 C<a>, and C<Z> are equivalent.
3021
3022 If the value-to-pack is too long, it is truncated.  If too long and an
3023 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3024 by a null byte.  Thus C<Z> always packs a trailing null byte under
3025 all circumstances.
3026
3027 =item *
3028
3029 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3030 Each byte of the input field of pack() generates 1 bit of the result.
3031 Each result bit is based on the least-significant bit of the corresponding
3032 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3033 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3034
3035 Starting from the beginning of the input string of pack(), each 8-tuple
3036 of bytes is converted to 1 byte of output.  With format C<b>
3037 the first byte of the 8-tuple determines the least-significant bit of a
3038 byte, and with format C<B> it determines the most-significant bit of
3039 a byte.
3040
3041 If the length of the input string is not exactly divisible by 8, the
3042 remainder is packed as if the input string were padded by null bytes
3043 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3044
3045 If the input string of pack() is longer than needed, extra bytes are ignored.
3046 A C<*> for the repeat count of pack() means to use all the bytes of
3047 the input field.  On unpack()ing the bits are converted to a string
3048 of C<"0">s and C<"1">s.
3049
3050 =item *
3051
3052 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3053 representable as hexadecimal digits, 0-9a-f) long.
3054
3055 Each byte of the input field of pack() generates 4 bits of the result.
3056 For non-alphabetical bytes the result is based on the 4 least-significant
3057 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3058 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3059 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3060 is compatible with the usual hexadecimal digits, so that C<"a"> and
3061 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3062 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3063
3064 Starting from the beginning of the input string of pack(), each pair
3065 of bytes is converted to 1 byte of output.  With format C<h> the
3066 first byte of the pair determines the least-significant nybble of the
3067 output byte, and with format C<H> it determines the most-significant
3068 nybble.
3069
3070 If the length of the input string is not even, it behaves as if padded
3071 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3072 nybbles are ignored.
3073
3074 If the input string of pack() is longer than needed, extra bytes are ignored.
3075 A C<*> for the repeat count of pack() means to use all the bytes of
3076 the input field.  On unpack()ing the bits are converted to a string
3077 of hexadecimal digits.
3078
3079 =item *
3080
3081 The C<p> type packs a pointer to a null-terminated string.  You are
3082 responsible for ensuring the string is not a temporary value (which can
3083 potentially get deallocated before you get around to using the packed result).
3084 The C<P> type packs a pointer to a structure of the size indicated by the
3085 length.  A NULL pointer is created if the corresponding value for C<p> or
3086 C<P> is C<undef>, similarly for unpack().
3087
3088 =item *
3089
3090 The C</> template character allows packing and unpacking of strings where
3091 the packed structure contains a byte count followed by the string itself.
3092 You write I<length-item>C</>I<string-item>.
3093
3094 The I<length-item> can be any C<pack> template letter,
3095 and describes how the length value is packed.
3096 The ones likely to be of most use are integer-packing ones like
3097 C<n> (for Java strings), C<w> (for ASN.1 or SNMP)
3098 and C<N> (for Sun XDR).
3099
3100 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
3101 For C<unpack> the length of the string is obtained from the I<length-item>,
3102 but if you put in the '*' it will be ignored.
3103
3104     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3105     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3106     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3107
3108 The I<length-item> is not returned explicitly from C<unpack>.
3109
3110 Adding a count to the I<length-item> letter is unlikely to do anything
3111 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3112 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3113 which Perl does not regard as legal in numeric strings.
3114
3115 =item *
3116
3117 The integer types C<s>, C<S>, C<l>, and C<L> may be
3118 immediately followed by a C<!> suffix to signify native shorts or
3119 longs--as you can see from above for example a bare C<l> does mean
3120 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3121 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3122 see whether using C<!> makes any difference by
3123
3124         print length(pack("s")), " ", length(pack("s!")), "\n";
3125         print length(pack("l")), " ", length(pack("l!")), "\n";
3126
3127 C<i!> and C<I!> also work but only because of completeness;
3128 they are identical to C<i> and C<I>.
3129
3130 The actual sizes (in bytes) of native shorts, ints, longs, and long
3131 longs on the platform where Perl was built are also available via
3132 L<Config>:
3133
3134        use Config;
3135        print $Config{shortsize},    "\n";
3136        print $Config{intsize},      "\n";
3137        print $Config{longsize},     "\n";
3138        print $Config{longlongsize}, "\n";
3139
3140 (The C<$Config{longlongsize}> will be undefine if your system does
3141 not support long longs.) 
3142
3143 =item *
3144
3145 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, and C<L>
3146 are inherently non-portable between processors and operating systems
3147 because they obey the native byteorder and endianness.  For example a
3148 4-byte integer 0x12345678 (305419896 decimal) be ordered natively
3149 (arranged in and handled by the CPU registers) into bytes as
3150
3151         0x12 0x34 0x56 0x78     # little-endian
3152         0x78 0x56 0x34 0x12     # big-endian
3153
3154 Basically, the Intel, Alpha, and VAX CPUs are little-endian, while
3155 everybody else, for example Motorola m68k/88k, PPC, Sparc, HP PA,
3156 Power, and Cray are big-endian.  MIPS can be either: Digital used it
3157 in little-endian mode; SGI uses it in big-endian mode.
3158
3159 The names `big-endian' and `little-endian' are comic references to
3160 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3161 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3162 the egg-eating habits of the Lilliputians.
3163
3164 Some systems may have even weirder byte orders such as
3165
3166         0x56 0x78 0x12 0x34
3167         0x34 0x12 0x78 0x56
3168
3169 You can see your system's preference with
3170
3171         print join(" ", map { sprintf "%#02x", $_ }
3172                             unpack("C*",pack("L",0x12345678))), "\n";
3173
3174 The byteorder on the platform where Perl was built is also available
3175 via L<Config>:
3176
3177         use Config;
3178         print $Config{byteorder}, "\n";
3179
3180 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3181 and C<'87654321'> are big-endian.
3182
3183 If you want portable packed integers use the formats C<n>, C<N>,
3184 C<v>, and C<V>, their byte endianness and size is known.
3185 See also L<perlport>.
3186
3187 =item *
3188
3189 Real numbers (floats and doubles) are in the native machine format only;
3190 due to the multiplicity of floating formats around, and the lack of a
3191 standard "network" representation, no facility for interchange has been
3192 made.  This means that packed floating point data written on one machine
3193 may not be readable on another - even if both use IEEE floating point
3194 arithmetic (as the endian-ness of the memory representation is not part
3195 of the IEEE spec).  See also L<perlport>.
3196
3197 Note that Perl uses doubles internally for all numeric calculation, and
3198 converting from double into float and thence back to double again will
3199 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3200 equal $foo).
3201
3202 =item *
3203
3204 You must yourself do any alignment or padding by inserting for example
3205 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3206 could know where the bytes are going to or coming from.  Therefore
3207 C<pack> (and C<unpack>) handle their output and input as flat
3208 sequences of bytes.
3209
3210 =item *
3211
3212 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3213
3214 =item *
3215
3216 If TEMPLATE requires more arguments to pack() than actually given, pack()
3217 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3218 to pack() than actually given, extra arguments are ignored.
3219
3220 =back
3221
3222 Examples:
3223
3224     $foo = pack("CCCC",65,66,67,68);
3225     # foo eq "ABCD"
3226     $foo = pack("C4",65,66,67,68);
3227     # same thing
3228     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3229     # same thing with Unicode circled letters
3230
3231     $foo = pack("ccxxcc",65,66,67,68);
3232     # foo eq "AB\0\0CD"
3233
3234     # note: the above examples featuring "C" and "c" are true
3235     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3236     # and UTF-8.  In EBCDIC the first example would be
3237     # $foo = pack("CCCC",193,194,195,196);
3238
3239     $foo = pack("s2",1,2);
3240     # "\1\0\2\0" on little-endian
3241     # "\0\1\0\2" on big-endian
3242
3243     $foo = pack("a4","abcd","x","y","z");
3244     # "abcd"
3245
3246     $foo = pack("aaaa","abcd","x","y","z");
3247     # "axyz"
3248
3249     $foo = pack("a14","abcdefg");
3250     # "abcdefg\0\0\0\0\0\0\0"
3251
3252     $foo = pack("i9pl", gmtime);
3253     # a real struct tm (on my system anyway)
3254
3255     $utmp_template = "Z8 Z8 Z16 L";
3256     $utmp = pack($utmp_template, @utmp1);
3257     # a struct utmp (BSDish)
3258
3259     @utmp2 = unpack($utmp_template, $utmp);
3260     # "@utmp1" eq "@utmp2"
3261
3262     sub bintodec {
3263         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3264     }
3265
3266     $foo = pack('sx2l', 12, 34);
3267     # short 12, two zero bytes padding, long 34
3268     $bar = pack('s@4l', 12, 34);
3269     # short 12, zero fill to position 4, long 34
3270     # $foo eq $bar
3271
3272 The same template may generally also be used in unpack().
3273
3274 =item package 
3275
3276 =item package NAMESPACE
3277
3278 Declares the compilation unit as being in the given namespace.  The scope
3279 of the package declaration is from the declaration itself through the end
3280 of the enclosing block, file, or eval (the same as the C<my> operator).
3281 All further unqualified dynamic identifiers will be in this namespace.
3282 A package statement affects only dynamic variables--including those
3283 you've used C<local> on--but I<not> lexical variables, which are created
3284 with C<my>.  Typically it would be the first declaration in a file to
3285 be included by the C<require> or C<use> operator.  You can switch into a
3286 package in more than one place; it merely influences which symbol table
3287 is used by the compiler for the rest of that block.  You can refer to
3288 variables and filehandles in other packages by prefixing the identifier
3289 with the package name and a double colon:  C<$Package::Variable>.
3290 If the package name is null, the C<main> package as assumed.  That is,
3291 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3292 still seen in older code).
3293
3294 If NAMESPACE is omitted, then there is no current package, and all
3295 identifiers must be fully qualified or lexicals.  This is stricter
3296 than C<use strict>, since it also extends to function names.
3297
3298 See L<perlmod/"Packages"> for more information about packages, modules,
3299 and classes.  See L<perlsub> for other scoping issues.
3300
3301 =item pipe READHANDLE,WRITEHANDLE
3302
3303 Opens a pair of connected pipes like the corresponding system call.
3304 Note that if you set up a loop of piped processes, deadlock can occur
3305 unless you are very careful.  In addition, note that Perl's pipes use
3306 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3307 after each command, depending on the application.
3308
3309 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3310 for examples of such things.
3311
3312 On systems that support a close-on-exec flag on files, the flag will be set
3313 for the newly opened file descriptors as determined by the value of $^F.
3314 See L<perlvar/$^F>.
3315
3316 =item pop ARRAY
3317
3318 =item pop
3319
3320 Pops and returns the last value of the array, shortening the array by
3321 one element.  Has an effect similar to
3322
3323     $ARRAY[$#ARRAY--]
3324
3325 If there are no elements in the array, returns the undefined value
3326 (although this may happen at other times as well).  If ARRAY is
3327 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3328 array in subroutines, just like C<shift>.
3329
3330 =item pos SCALAR
3331
3332 =item pos
3333
3334 Returns the offset of where the last C<m//g> search left off for the variable
3335 is in question (C<$_> is used when the variable is not specified).  May be
3336 modified to change that offset.  Such modification will also influence
3337 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3338 L<perlop>.
3339
3340 =item print FILEHANDLE LIST
3341
3342 =item print LIST
3343
3344 =item print
3345
3346 Prints a string or a list of strings.  Returns true if successful.
3347 FILEHANDLE may be a scalar variable name, in which case the variable
3348 contains the name of or a reference to the filehandle, thus introducing
3349 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3350 the next token is a term, it may be misinterpreted as an operator
3351 unless you interpose a C<+> or put parentheses around the arguments.)
3352 If FILEHANDLE is omitted, prints by default to standard output (or
3353 to the last selected output channel--see L</select>).  If LIST is
3354 also omitted, prints C<$_> to the currently selected output channel.
3355 To set the default output channel to something other than STDOUT
3356 use the select operation.  The current value of C<$,> (if any) is
3357 printed between each LIST item.  The current value of C<$\> (if
3358 any) is printed after the entire LIST has been printed.  Because
3359 print takes a LIST, anything in the LIST is evaluated in list
3360 context, and any subroutine that you call will have one or more of
3361 its expressions evaluated in list context.  Also be careful not to
3362 follow the print keyword with a left parenthesis unless you want
3363 the corresponding right parenthesis to terminate the arguments to
3364 the print--interpose a C<+> or put parentheses around all the
3365 arguments.
3366
3367 Note that if you're storing FILEHANDLES in an array or other expression,
3368 you will have to use a block returning its value instead:
3369
3370     print { $files[$i] } "stuff\n";
3371     print { $OK ? STDOUT : STDERR } "stuff\n";
3372
3373 =item printf FILEHANDLE FORMAT, LIST
3374
3375 =item printf FORMAT, LIST
3376
3377 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3378 (the output record separator) is not appended.  The first argument
3379 of the list will be interpreted as the C<printf> format.  If C<use locale> is
3380 in effect, the character used for the decimal point in formatted real numbers
3381 is affected by the LC_NUMERIC locale.  See L<perllocale>.
3382
3383 Don't fall into the trap of using a C<printf> when a simple
3384 C<print> would do.  The C<print> is more efficient and less
3385 error prone.
3386
3387 =item prototype FUNCTION
3388
3389 Returns the prototype of a function as a string (or C<undef> if the
3390 function has no prototype).  FUNCTION is a reference to, or the name of,
3391 the function whose prototype you want to retrieve.
3392
3393 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3394 name for Perl builtin.  If the builtin is not I<overridable> (such as
3395 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3396 C<system>) returns C<undef> because the builtin does not really behave
3397 like a Perl function.  Otherwise, the string describing the equivalent
3398 prototype is returned.
3399
3400 =item push ARRAY,LIST
3401
3402 Treats ARRAY as a stack, and pushes the values of LIST
3403 onto the end of ARRAY.  The length of ARRAY increases by the length of
3404 LIST.  Has the same effect as
3405
3406     for $value (LIST) {
3407         $ARRAY[++$#ARRAY] = $value;
3408     }
3409
3410 but is more efficient.  Returns the new number of elements in the array.
3411
3412 =item q/STRING/
3413
3414 =item qq/STRING/
3415
3416 =item qr/STRING/
3417
3418 =item qx/STRING/
3419
3420 =item qw/STRING/
3421
3422 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3423
3424 =item quotemeta EXPR
3425
3426 =item quotemeta
3427
3428 Returns the value of EXPR with all non-alphanumeric
3429 characters backslashed.  (That is, all characters not matching
3430 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3431 returned string, regardless of any locale settings.)
3432 This is the internal function implementing
3433 the C<\Q> escape in double-quoted strings.
3434
3435 If EXPR is omitted, uses C<$_>.
3436
3437 =item rand EXPR
3438
3439 =item rand
3440
3441 Returns a random fractional number greater than or equal to C<0> and less
3442 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3443 omitted, the value C<1> is used.  Automatically calls C<srand> unless
3444 C<srand> has already been called.  See also C<srand>.
3445
3446 (Note: If your rand function consistently returns numbers that are too
3447 large or too small, then your version of Perl was probably compiled
3448 with the wrong number of RANDBITS.)
3449
3450 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3451
3452 =item read FILEHANDLE,SCALAR,LENGTH
3453
3454 Attempts to read LENGTH bytes of data into variable SCALAR from the
3455 specified FILEHANDLE.  Returns the number of bytes actually read,
3456 C<0> at end of file, or undef if there was an error.  SCALAR will be grown
3457 or shrunk to the length actually read.  An OFFSET may be specified to
3458 place the read data at some other place than the beginning of the
3459 string.  This call is actually implemented in terms of stdio's fread(3)
3460 call.  To get a true read(2) system call, see C<sysread>.
3461
3462 =item readdir DIRHANDLE
3463
3464 Returns the next directory entry for a directory opened by C<opendir>.
3465 If used in list context, returns all the rest of the entries in the
3466 directory.  If there are no more entries, returns an undefined value in
3467 scalar context or a null list in list context.
3468
3469 If you're planning to filetest the return values out of a C<readdir>, you'd
3470 better prepend the directory in question.  Otherwise, because we didn't
3471 C<chdir> there, it would have been testing the wrong file.
3472
3473     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3474     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3475     closedir DIR;
3476
3477 =item readline EXPR
3478
3479 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3480 context, each call reads and returns the next line, until end-of-file is
3481 reached, whereupon the subsequent call returns undef.  In list context,
3482 reads until end-of-file is reached and returns a list of lines.  Note that
3483 the notion of "line" used here is however you may have defined it
3484 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3485
3486 When C<$/> is set to C<undef>, when readline() is in scalar
3487 context (i.e. file slurp mode), and when an empty file is read, it
3488 returns C<''> the first time, followed by C<undef> subsequently.
3489
3490 This is the internal function implementing the C<< <EXPR> >>
3491 operator, but you can use it directly.  The C<< <EXPR> >>
3492 operator is discussed in more detail in L<perlop/"I/O Operators">.
3493
3494     $line = <STDIN>;
3495     $line = readline(*STDIN);           # same thing
3496
3497 =item readlink EXPR
3498
3499 =item readlink
3500
3501 Returns the value of a symbolic link, if symbolic links are
3502 implemented.  If not, gives a fatal error.  If there is some system
3503 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3504 omitted, uses C<$_>.
3505
3506 =item readpipe EXPR
3507
3508 EXPR is executed as a system command.
3509 The collected standard output of the command is returned.
3510 In scalar context, it comes back as a single (potentially
3511 multi-line) string.  In list context, returns a list of lines
3512 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3513 This is the internal function implementing the C<qx/EXPR/>
3514 operator, but you can use it directly.  The C<qx/EXPR/>
3515 operator is discussed in more detail in L<perlop/"I/O Operators">.
3516
3517 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3518
3519 Receives a message on a socket.  Attempts to receive LENGTH bytes of
3520 data into variable SCALAR from the specified SOCKET filehandle.  SCALAR
3521 will be grown or shrunk to the length actually read.  Takes the same
3522 flags as the system call of the same name.  Returns the address of the
3523 sender if SOCKET's protocol supports this; returns an empty string
3524 otherwise.  If there's an error, returns the undefined value.  This call
3525 is actually implemented in terms of recvfrom(2) system call.  See
3526 L<perlipc/"UDP: Message Passing"> for examples.
3527
3528 =item redo LABEL
3529
3530 =item redo
3531
3532 The C<redo> command restarts the loop block without evaluating the
3533 conditional again.  The C<continue> block, if any, is not executed.  If
3534 the LABEL is omitted, the command refers to the innermost enclosing
3535 loop.  This command is normally used by programs that want to lie to
3536 themselves about what was just input:
3537
3538     # a simpleminded Pascal comment stripper
3539     # (warning: assumes no { or } in strings)
3540     LINE: while (<STDIN>) {
3541         while (s|({.*}.*){.*}|$1 |) {}
3542         s|{.*}| |;
3543         if (s|{.*| |) {
3544             $front = $_;
3545             while (<STDIN>) {
3546                 if (/}/) {      # end of comment?
3547                     s|^|$front\{|;
3548                     redo LINE;
3549                 }
3550             }
3551         }
3552         print;
3553     }
3554
3555 C<redo> cannot be used to retry a block which returns a value such as
3556 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3557 a grep() or map() operation.
3558
3559 Note that a block by itself is semantically identical to a loop
3560 that executes once.  Thus C<redo> inside such a block will effectively
3561 turn it into a looping construct.
3562
3563 See also L</continue> for an illustration of how C<last>, C<next>, and
3564 C<redo> work.
3565
3566 =item ref EXPR
3567
3568 =item ref
3569
3570 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3571 is not specified, C<$_> will be used.  The value returned depends on the
3572 type of thing the reference is a reference to.
3573 Builtin types include:
3574
3575     SCALAR
3576     ARRAY
3577     HASH
3578     CODE
3579     REF
3580     GLOB
3581     LVALUE
3582
3583 If the referenced object has been blessed into a package, then that package
3584 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3585
3586     if (ref($r) eq "HASH") {
3587         print "r is a reference to a hash.\n";
3588     }
3589     unless (ref($r)) {
3590         print "r is not a reference at all.\n";
3591     }
3592     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3593         print "r is a reference to something that isa hash.\n";
3594     } 
3595
3596 See also L<perlref>.
3597
3598 =item rename OLDNAME,NEWNAME
3599
3600 Changes the name of a file; an existing file NEWNAME will be
3601 clobbered.  Returns true for success, false otherwise.
3602
3603 Behavior of this function varies wildly depending on your system
3604 implementation.  For example, it will usually not work across file system
3605 boundaries, even though the system I<mv> command sometimes compensates
3606 for this.  Other restrictions include whether it works on directories,
3607 open files, or pre-existing files.  Check L<perlport> and either the
3608 rename(2) manpage or equivalent system documentation for details.
3609
3610 =item require VERSION
3611
3612 =item require EXPR
3613
3614 =item require
3615
3616 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
3617 supplied.
3618
3619 If a VERSION is specified as a literal of the form v5.6.1,
3620 demands that the current version of Perl (C<$^V> or $PERL_VERSION) be
3621 at least as recent as that version, at run time.  (For compatibility
3622 with older versions of Perl, a numeric argument will also be interpreted
3623 as VERSION.)  Compare with L</use>, which can do a similar check at
3624 compile time.
3625
3626     require v5.6.1;     # run time version check
3627     require 5.6.1;      # ditto
3628     require 5.005_03;   # float version allowed for compatibility
3629
3630 Otherwise, demands that a library file be included if it hasn't already
3631 been included.  The file is included via the do-FILE mechanism, which is
3632 essentially just a variety of C<eval>.  Has semantics similar to the following
3633 subroutine:
3634
3635     sub require {
3636         my($filename) = @_;
3637         return 1 if $INC{$filename};
3638         my($realfilename,$result);
3639         ITER: {
3640             foreach $prefix (@INC) {
3641                 $realfilename = "$prefix/$filename";
3642                 if (-f $realfilename) {
3643                     $INC{$filename} = $realfilename;
3644                     $result = do $realfilename;
3645                     last ITER;
3646                 }
3647             }
3648             die "Can't find $filename in \@INC";
3649         }
3650         delete $INC{$filename} if $@ || !$result;
3651         die $@ if $@;
3652         die "$filename did not return true value" unless $result;
3653         return $result;
3654     }
3655
3656 Note that the file will not be included twice under the same specified
3657 name.  The file must return true as the last statement to indicate
3658 successful execution of any initialization code, so it's customary to
3659 end such a file with C<1;> unless you're sure it'll return true
3660 otherwise.  But it's better just to put the C<1;>, in case you add more
3661 statements.
3662
3663 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3664 replaces "F<::>" with "F</>" in the filename for you,
3665 to make it easy to load standard modules.  This form of loading of
3666 modules does not risk altering your namespace.
3667
3668 In other words, if you try this:
3669
3670         require Foo::Bar;    # a splendid bareword 
3671
3672 The require function will actually look for the "F<Foo/Bar.pm>" file in the 
3673 directories specified in the C<@INC> array.
3674
3675 But if you try this:
3676
3677         $class = 'Foo::Bar';
3678         require $class;      # $class is not a bareword
3679     #or
3680         require "Foo::Bar";  # not a bareword because of the ""
3681
3682 The require function will look for the "F<Foo::Bar>" file in the @INC array and 
3683 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3684
3685         eval "require $class";
3686
3687 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3688
3689 =item reset EXPR
3690
3691 =item reset
3692
3693 Generally used in a C<continue> block at the end of a loop to clear
3694 variables and reset C<??> searches so that they work again.  The
3695 expression is interpreted as a list of single characters (hyphens
3696 allowed for ranges).  All variables and arrays beginning with one of
3697 those letters are reset to their pristine state.  If the expression is
3698 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3699 only variables or searches in the current package.  Always returns
3700 1.  Examples:
3701
3702     reset 'X';          # reset all X variables
3703     reset 'a-z';        # reset lower case variables
3704     reset;              # just reset ?one-time? searches
3705
3706 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3707 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
3708 variables--lexical variables are unaffected, but they clean themselves
3709 up on scope exit anyway, so you'll probably want to use them instead.
3710 See L</my>.
3711
3712 =item return EXPR
3713
3714 =item return
3715
3716 Returns from a subroutine, C<eval>, or C<do FILE> with the value 
3717 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3718 context, depending on how the return value will be used, and the context
3719 may vary from one execution to the next (see C<wantarray>).  If no EXPR
3720 is given, returns an empty list in list context, the undefined value in
3721 scalar context, and (of course) nothing at all in a void context.
3722
3723 (Note that in the absence of a explicit C<return>, a subroutine, eval,
3724 or do FILE will automatically return the value of the last expression
3725 evaluated.)
3726
3727 =item reverse LIST
3728
3729 In list context, returns a list value consisting of the elements
3730 of LIST in the opposite order.  In scalar context, concatenates the
3731 elements of LIST and returns a string value with all characters
3732 in the opposite order.
3733
3734     print reverse <>;           # line tac, last line first
3735
3736     undef $/;                   # for efficiency of <>
3737     print scalar reverse <>;    # character tac, last line tsrif
3738
3739 This operator is also handy for inverting a hash, although there are some
3740 caveats.  If a value is duplicated in the original hash, only one of those
3741 can be represented as a key in the inverted hash.  Also, this has to
3742 unwind one hash and build a whole new one, which may take some time
3743 on a large hash, such as from a DBM file.
3744
3745     %by_name = reverse %by_address;     # Invert the hash
3746
3747 =item rewinddir DIRHANDLE
3748
3749 Sets the current position to the beginning of the directory for the
3750 C<readdir> routine on DIRHANDLE.
3751
3752 =item rindex STR,SUBSTR,POSITION
3753
3754 =item rindex STR,SUBSTR
3755
3756 Works just like index() except that it returns the position of the LAST
3757 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
3758 last occurrence at or before that position.
3759
3760 =item rmdir FILENAME
3761
3762 =item rmdir
3763
3764 Deletes the directory specified by FILENAME if that directory is empty.  If it
3765 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
3766 FILENAME is omitted, uses C<$_>.
3767
3768 =item s///
3769
3770 The substitution operator.  See L<perlop>.
3771
3772 =item scalar EXPR
3773
3774 Forces EXPR to be interpreted in scalar context and returns the value
3775 of EXPR.
3776
3777     @counts = ( scalar @a, scalar @b, scalar @c );
3778
3779 There is no equivalent operator to force an expression to
3780 be interpolated in list context because in practice, this is never
3781 needed.  If you really wanted to do so, however, you could use
3782 the construction C<@{[ (some expression) ]}>, but usually a simple
3783 C<(some expression)> suffices.
3784
3785 Because C<scalar> is unary operator, if you accidentally use for EXPR a
3786 parenthesized list, this behaves as a scalar comma expression, evaluating
3787 all but the last element in void context and returning the final element
3788 evaluated in scalar context.  This is seldom what you want.
3789
3790 The following single statement:
3791
3792         print uc(scalar(&foo,$bar)),$baz;
3793
3794 is the moral equivalent of these two:
3795
3796         &foo;
3797         print(uc($bar),$baz);
3798
3799 See L<perlop> for more details on unary operators and the comma operator.
3800
3801 =item seek FILEHANDLE,POSITION,WHENCE
3802
3803 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
3804 FILEHANDLE may be an expression whose value gives the name of the
3805 filehandle.  The values for WHENCE are C<0> to set the new position to
3806 POSITION, C<1> to set it to the current position plus POSITION, and
3807 C<2> to set it to EOF plus POSITION (typically negative).  For WHENCE
3808 you may use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END>
3809 (start of the file, current position, end of the file) from the Fcntl
3810 module.  Returns C<1> upon success, C<0> otherwise.
3811
3812 If you want to position file for C<sysread> or C<syswrite>, don't use
3813 C<seek>--buffering makes its effect on the file's system position
3814 unpredictable and non-portable.  Use C<sysseek> instead.
3815
3816 Due to the rules and rigors of ANSI C, on some systems you have to do a
3817 seek whenever you switch between reading and writing.  Amongst other
3818 things, this may have the effect of calling stdio's clearerr(3).
3819 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
3820
3821     seek(TEST,0,1);
3822
3823 This is also useful for applications emulating C<tail -f>.  Once you hit
3824 EOF on your read, and then sleep for a while, you might have to stick in a
3825 seek() to reset things.  The C<seek> doesn't change the current position,
3826 but it I<does> clear the end-of-file condition on the handle, so that the
3827 next C<< <FILE> >> makes Perl try again to read something.  We hope.
3828
3829 If that doesn't work (some stdios are particularly cantankerous), then
3830 you may need something more like this:
3831
3832     for (;;) {
3833         for ($curpos = tell(FILE); $_ = <FILE>;
3834              $curpos = tell(FILE)) {
3835             # search for some stuff and put it into files
3836         }
3837         sleep($for_a_while);
3838         seek(FILE, $curpos, 0);
3839     }
3840
3841 =item seekdir DIRHANDLE,POS
3842
3843 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
3844 must be a value returned by C<telldir>.  Has the same caveats about
3845 possible directory compaction as the corresponding system library
3846 routine.
3847
3848 =item select FILEHANDLE
3849
3850 =item select
3851
3852 Returns the currently selected filehandle.  Sets the current default
3853 filehandle for output, if FILEHANDLE is supplied.  This has two
3854 effects: first, a C<write> or a C<print> without a filehandle will
3855 default to this FILEHANDLE.  Second, references to variables related to
3856 output will refer to this output channel.  For example, if you have to
3857 set the top of form format for more than one output channel, you might
3858 do the following:
3859
3860     select(REPORT1);
3861     $^ = 'report1_top';
3862     select(REPORT2);
3863     $^ = 'report2_top';
3864
3865 FILEHANDLE may be an expression whose value gives the name of the
3866 actual filehandle.  Thus:
3867
3868     $oldfh = select(STDERR); $| = 1; select($oldfh);
3869
3870 Some programmers may prefer to think of filehandles as objects with
3871 methods, preferring to write the last example as:
3872
3873     use IO::Handle;
3874     STDERR->autoflush(1);
3875
3876 =item select RBITS,WBITS,EBITS,TIMEOUT
3877
3878 This calls the select(2) system call with the bit masks specified, which
3879 can be constructed using C<fileno> and C<vec>, along these lines:
3880
3881     $rin = $win = $ein = '';
3882     vec($rin,fileno(STDIN),1) = 1;
3883     vec($win,fileno(STDOUT),1) = 1;
3884     $ein = $rin | $win;
3885
3886 If you want to select on many filehandles you might wish to write a
3887 subroutine:
3888
3889     sub fhbits {
3890         my(@fhlist) = split(' ',$_[0]);
3891         my($bits);
3892         for (@fhlist) {
3893             vec($bits,fileno($_),1) = 1;
3894         }
3895         $bits;
3896     }
3897     $rin = fhbits('STDIN TTY SOCK');
3898
3899 The usual idiom is:
3900
3901     ($nfound,$timeleft) =
3902       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
3903
3904 or to block until something becomes ready just do this
3905
3906     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
3907
3908 Most systems do not bother to return anything useful in $timeleft, so
3909 calling select() in scalar context just returns $nfound.
3910
3911 Any of the bit masks can also be undef.  The timeout, if specified, is
3912 in seconds, which may be fractional.  Note: not all implementations are
3913 capable of returning the$timeleft.  If not, they always return
3914 $timeleft equal to the supplied $timeout.
3915
3916 You can effect a sleep of 250 milliseconds this way:
3917
3918     select(undef, undef, undef, 0.25);
3919
3920 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
3921 or <FH>) with C<select>, except as permitted by POSIX, and even
3922 then only on POSIX systems.  You have to use C<sysread> instead.
3923
3924 =item semctl ID,SEMNUM,CMD,ARG
3925
3926 Calls the System V IPC function C<semctl>.  You'll probably have to say
3927
3928     use IPC::SysV;
3929
3930 first to get the correct constant definitions.  If CMD is IPC_STAT or
3931 GETALL, then ARG must be a variable which will hold the returned
3932 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
3933 the undefined value for error, "C<0 but true>" for zero, or the actual
3934 return value otherwise.  The ARG must consist of a vector of native
3935 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
3936 See also C<IPC::SysV> and C<IPC::Semaphore> documentation.
3937
3938 =item semget KEY,NSEMS,FLAGS
3939
3940 Calls the System V IPC function semget.  Returns the semaphore id, or
3941 the undefined value if there is an error.  See also C<IPC::SysV> and
3942 C<IPC::SysV::Semaphore> documentation.
3943
3944 =item semop KEY,OPSTRING
3945
3946 Calls the System V IPC function semop to perform semaphore operations
3947 such as signaling and waiting.  OPSTRING must be a packed array of
3948 semop structures.  Each semop structure can be generated with
3949 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
3950 operations is implied by the length of OPSTRING.  Returns true if
3951 successful, or false if there is an error.  As an example, the
3952 following code waits on semaphore $semnum of semaphore id $semid:
3953
3954     $semop = pack("sss", $semnum, -1, 0);
3955     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
3956
3957 To signal the semaphore, replace C<-1> with C<1>.  See also C<IPC::SysV>
3958 and C<IPC::SysV::Semaphore> documentation.
3959
3960 =item send SOCKET,MSG,FLAGS,TO
3961
3962 =item send SOCKET,MSG,FLAGS
3963
3964 Sends a message on a socket.  Takes the same flags as the system call
3965 of the same name.  On unconnected sockets you must specify a
3966 destination to send TO, in which case it does a C C<sendto>.  Returns
3967 the number of characters sent, or the undefined value if there is an
3968 error.  The C system call sendmsg(2) is currently unimplemented.
3969 See L<perlipc/"UDP: Message Passing"> for examples.
3970
3971 =item setpgrp PID,PGRP
3972
3973 Sets the current process group for the specified PID, C<0> for the current
3974 process.  Will produce a fatal error if used on a machine that doesn't
3975 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
3976 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
3977 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
3978 C<POSIX::setsid()>.
3979
3980 =item setpriority WHICH,WHO,PRIORITY
3981
3982 Sets the current priority for a process, a process group, or a user.
3983 (See setpriority(2).)  Will produce a fatal error if used on a machine
3984 that doesn't implement setpriority(2).
3985
3986 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
3987
3988 Sets the socket option requested.  Returns undefined if there is an
3989 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
3990 argument.
3991
3992 =item shift ARRAY
3993
3994 =item shift
3995
3996 Shifts the first value of the array off and returns it, shortening the
3997 array by 1 and moving everything down.  If there are no elements in the
3998 array, returns the undefined value.  If ARRAY is omitted, shifts the
3999 C<@_> array within the lexical scope of subroutines and formats, and the
4000 C<@ARGV> array at file scopes or within the lexical scopes established by
4001 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4002 constructs.
4003
4004 See also C<unshift>, C<push>, and C<pop>.  C<shift()> and C<unshift> do the
4005 same thing to the left end of an array that C<pop> and C<push> do to the
4006 right end.
4007
4008 =item shmctl ID,CMD,ARG
4009
4010 Calls the System V IPC function shmctl.  You'll probably have to say
4011
4012     use IPC::SysV;
4013
4014 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4015 then ARG must be a variable which will hold the returned C<shmid_ds>
4016 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4017 true" for zero, or the actual return value otherwise.
4018 See also C<IPC::SysV> documentation.
4019
4020 =item shmget KEY,SIZE,FLAGS
4021
4022 Calls the System V IPC function shmget.  Returns the shared memory
4023 segment id, or the undefined value if there is an error.
4024 See also C<IPC::SysV> documentation.
4025
4026 =item shmread ID,VAR,POS,SIZE
4027
4028 =item shmwrite ID,STRING,POS,SIZE
4029
4030 Reads or writes the System V shared memory segment ID starting at
4031 position POS for size SIZE by attaching to it, copying in/out, and
4032 detaching from it.  When reading, VAR must be a variable that will
4033 hold the data read.  When writing, if STRING is too long, only SIZE
4034 bytes are used; if STRING is too short, nulls are written to fill out
4035 SIZE bytes.  Return true if successful, or false if there is an error.
4036 shmread() taints the variable. See also C<IPC::SysV> documentation and
4037 the C<IPC::Shareable> module from CPAN.
4038
4039 =item shutdown SOCKET,HOW
4040
4041 Shuts down a socket connection in the manner indicated by HOW, which
4042 has the same interpretation as in the system call of the same name.
4043
4044     shutdown(SOCKET, 0);    # I/we have stopped reading data
4045     shutdown(SOCKET, 1);    # I/we have stopped writing data
4046     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4047
4048 This is useful with sockets when you want to tell the other
4049 side you're done writing but not done reading, or vice versa.
4050 It's also a more insistent form of close because it also 
4051 disables the file descriptor in any forked copies in other
4052 processes.
4053
4054 =item sin EXPR
4055
4056 =item sin
4057
4058 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4059 returns sine of C<$_>.
4060
4061 For the inverse sine operation, you may use the C<Math::Trig::asin>
4062 function, or use this relation:
4063
4064     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4065
4066 =item sleep EXPR
4067
4068 =item sleep
4069
4070 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4071 May be interrupted if the process receives a signal such as C<SIGALRM>.
4072 Returns the number of seconds actually slept.  You probably cannot
4073 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4074 using C<alarm>.
4075
4076 On some older systems, it may sleep up to a full second less than what
4077 you requested, depending on how it counts seconds.  Most modern systems
4078 always sleep the full amount.  They may appear to sleep longer than that,
4079 however, because your process might not be scheduled right away in a
4080 busy multitasking system.
4081
4082 For delays of finer granularity than one second, you may use Perl's
4083 C<syscall> interface to access setitimer(2) if your system supports
4084 it, or else see L</select> above.  The Time::HiRes module from CPAN
4085 may also help.
4086
4087 See also the POSIX module's C<sigpause> function.
4088
4089 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4090
4091 Opens a socket of the specified kind and attaches it to filehandle
4092 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4093 the system call of the same name.  You should C<use Socket> first
4094 to get the proper definitions imported.  See the examples in
4095 L<perlipc/"Sockets: Client/Server Communication">.
4096
4097 On systems that support a close-on-exec flag on files, the flag will
4098 be set for the newly opened file descriptor, as determined by the
4099 value of $^F.  See L<perlvar/$^F>.
4100
4101 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4102
4103 Creates an unnamed pair of sockets in the specified domain, of the
4104 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4105 for the system call of the same name.  If unimplemented, yields a fatal
4106 error.  Returns true if successful.
4107
4108 On systems that support a close-on-exec flag on files, the flag will
4109 be set for the newly opened file descriptors, as determined by the value
4110 of $^F.  See L<perlvar/$^F>.
4111
4112 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4113 to C<pipe(Rdr, Wtr)> is essentially:
4114
4115     use Socket;
4116     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4117     shutdown(Rdr, 1);        # no more writing for reader
4118     shutdown(Wtr, 0);        # no more reading for writer
4119
4120 See L<perlipc> for an example of socketpair use.
4121
4122 =item sort SUBNAME LIST
4123
4124 =item sort BLOCK LIST
4125
4126 =item sort LIST
4127
4128 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
4129 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
4130 specified, it gives the name of a subroutine that returns an integer
4131 less than, equal to, or greater than C<0>, depending on how the elements
4132 of the list are to be ordered.  (The C<< <=> >> and C<cmp>
4133 operators are extremely useful in such routines.)  SUBNAME may be a
4134 scalar variable name (unsubscripted), in which case the value provides
4135 the name of (or a reference to) the actual subroutine to use.  In place
4136 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
4137 subroutine.
4138
4139 If the subroutine's prototype is C<($$)>, the elements to be compared
4140 are passed by reference in C<@_>, as for a normal subroutine.  This is
4141 slower than unprototyped subroutines, where the elements to be
4142 compared are passed into the subroutine
4143 as the package global variables $a and $b (see example below).  Note that
4144 in the latter case, it is usually counter-productive to declare $a and
4145 $b as lexicals.
4146
4147 In either case, the subroutine may not be recursive.  The values to be
4148 compared are always passed by reference, so don't modify them.
4149
4150 You also cannot exit out of the sort block or subroutine using any of the
4151 loop control operators described in L<perlsyn> or with C<goto>.
4152
4153 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4154 current collation locale.  See L<perllocale>.
4155
4156 Examples:
4157
4158     # sort lexically
4159     @articles = sort @files;
4160
4161     # same thing, but with explicit sort routine
4162     @articles = sort {$a cmp $b} @files;
4163
4164     # now case-insensitively
4165     @articles = sort {uc($a) cmp uc($b)} @files;
4166
4167     # same thing in reversed order
4168     @articles = sort {$b cmp $a} @files;
4169
4170     # sort numerically ascending
4171     @articles = sort {$a <=> $b} @files;
4172
4173     # sort numerically descending
4174     @articles = sort {$b <=> $a} @files;
4175
4176     # this sorts the %age hash by value instead of key
4177     # using an in-line function
4178     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4179
4180     # sort using explicit subroutine name
4181     sub byage {
4182         $age{$a} <=> $age{$b};  # presuming numeric
4183     }
4184     @sortedclass = sort byage @class;
4185
4186     sub backwards { $b cmp $a }
4187     @harry  = qw(dog cat x Cain Abel);
4188     @george = qw(gone chased yz Punished Axed);
4189     print sort @harry;
4190             # prints AbelCaincatdogx
4191     print sort backwards @harry;
4192             # prints xdogcatCainAbel
4193     print sort @george, 'to', @harry;
4194             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4195
4196     # inefficiently sort by descending numeric compare using
4197     # the first integer after the first = sign, or the
4198     # whole record case-insensitively otherwise
4199
4200     @new = sort {
4201         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4202                             ||
4203                     uc($a)  cmp  uc($b)
4204     } @old;
4205
4206     # same thing, but much more efficiently;
4207     # we'll build auxiliary indices instead
4208     # for speed
4209     @nums = @caps = ();
4210     for (@old) {
4211         push @nums, /=(\d+)/;
4212         push @caps, uc($_);
4213     }
4214
4215     @new = @old[ sort {
4216                         $nums[$b] <=> $nums[$a]
4217                                  ||
4218                         $caps[$a] cmp $caps[$b]
4219                        } 0..$#old
4220                ];
4221
4222     # same thing, but without any temps
4223     @new = map { $_->[0] }
4224            sort { $b->[1] <=> $a->[1]
4225                            ||
4226                   $a->[2] cmp $b->[2]
4227            } map { [$_, /=(\d+)/, uc($_)] } @old;
4228
4229     # using a prototype allows you to use any comparison subroutine
4230     # as a sort subroutine (including other package's subroutines)
4231     package other;
4232     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4233
4234     package main;
4235     @new = sort other::backwards @old;
4236
4237 If you're using strict, you I<must not> declare $a
4238 and $b as lexicals.  They are package globals.  That means
4239 if you're in the C<main> package, it's
4240
4241     @articles = sort {$main::b <=> $main::a} @files;
4242
4243 or just
4244
4245     @articles = sort {$::b <=> $::a} @files;
4246
4247 but if you're in the C<FooPack> package, it's
4248
4249     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
4250
4251 The comparison function is required to behave.  If it returns
4252 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4253 sometimes saying the opposite, for example) the results are not
4254 well-defined.
4255
4256 =item splice ARRAY,OFFSET,LENGTH,LIST
4257
4258 =item splice ARRAY,OFFSET,LENGTH
4259
4260 =item splice ARRAY,OFFSET
4261
4262 =item splice ARRAY
4263
4264 Removes the elements designated by OFFSET and LENGTH from an array, and
4265 replaces them with the elements of LIST, if any.  In list context,
4266 returns the elements removed from the array.  In scalar context,
4267 returns the last element removed, or C<undef> if no elements are
4268 removed.  The array grows or shrinks as necessary.
4269 If OFFSET is negative then it starts that far from the end of the array.
4270 If LENGTH is omitted, removes everything from OFFSET onward.
4271 If LENGTH is negative, leaves that many elements off the end of the array.
4272 If both OFFSET and LENGTH are omitted, removes everything.
4273
4274 The following equivalences hold (assuming C<$[ == 0>):
4275
4276     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
4277     pop(@a)             splice(@a,-1)
4278     shift(@a)           splice(@a,0,1)
4279     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
4280     $a[$x] = $y         splice(@a,$x,1,$y)
4281
4282 Example, assuming array lengths are passed before arrays:
4283
4284     sub aeq {   # compare two list values
4285         my(@a) = splice(@_,0,shift);
4286         my(@b) = splice(@_,0,shift);
4287         return 0 unless @a == @b;       # same len?
4288         while (@a) {
4289             return 0 if pop(@a) ne pop(@b);
4290         }
4291         return 1;
4292     }
4293     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
4294
4295 =item split /PATTERN/,EXPR,LIMIT
4296
4297 =item split /PATTERN/,EXPR
4298
4299 =item split /PATTERN/
4300
4301 =item split
4302
4303 Splits a string into a list of strings and returns that list.  By default,
4304 empty leading fields are preserved, and empty trailing ones are deleted.
4305
4306 If not in list context, returns the number of fields found and splits into
4307 the C<@_> array.  (In list context, you can force the split into C<@_> by
4308 using C<??> as the pattern delimiters, but it still returns the list
4309 value.)  The use of implicit split to C<@_> is deprecated, however, because
4310 it clobbers your subroutine arguments.
4311
4312 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
4313 splits on whitespace (after skipping any leading whitespace).  Anything
4314 matching PATTERN is taken to be a delimiter separating the fields.  (Note
4315 that the delimiter may be longer than one character.)
4316
4317 If LIMIT is specified and positive, splits into no more than that
4318 many fields (though it may split into fewer).  If LIMIT is unspecified
4319 or zero, trailing null fields are stripped (which potential users
4320 of C<pop> would do well to remember).  If LIMIT is negative, it is
4321 treated as if an arbitrarily large LIMIT had been specified.
4322
4323 A pattern matching the null string (not to be confused with
4324 a null pattern C<//>, which is just one member of the set of patterns
4325 matching a null string) will split the value of EXPR into separate
4326 characters at each point it matches that way.  For example:
4327
4328     print join(':', split(/ */, 'hi there'));
4329
4330 produces the output 'h:i:t:h:e:r:e'.
4331
4332 The LIMIT parameter can be used to split a line partially
4333
4334     ($login, $passwd, $remainder) = split(/:/, $_, 3);
4335
4336 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
4337 one larger than the number of variables in the list, to avoid
4338 unnecessary work.  For the list above LIMIT would have been 4 by
4339 default.  In time critical applications it behooves you not to split
4340 into more fields than you really need.
4341
4342 If the PATTERN contains parentheses, additional list elements are
4343 created from each matching substring in the delimiter.
4344
4345     split(/([,-])/, "1-10,20", 3);
4346
4347 produces the list value
4348
4349     (1, '-', 10, ',', 20)
4350
4351 If you had the entire header of a normal Unix email message in $header,
4352 you could split it up into fields and their values this way:
4353
4354     $header =~ s/\n\s+/ /g;  # fix continuation lines
4355     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
4356
4357 The pattern C</PATTERN/> may be replaced with an expression to specify
4358 patterns that vary at runtime.  (To do runtime compilation only once,
4359 use C</$variable/o>.)
4360
4361 As a special case, specifying a PATTERN of space (C<' '>) will split on
4362 white space just as C<split> with no arguments does.  Thus, C<split(' ')> can
4363 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
4364 will give you as many null initial fields as there are leading spaces.
4365 A C<split> on C</\s+/> is like a C<split(' ')> except that any leading
4366 whitespace produces a null first field.  A C<split> with no arguments
4367 really does a C<split(' ', $_)> internally.
4368
4369 Example:
4370
4371     open(PASSWD, '/etc/passwd');
4372     while (<PASSWD>) {
4373         ($login, $passwd, $uid, $gid,
4374          $gcos, $home, $shell) = split(/:/);
4375         #...
4376     }
4377
4378 (Note that $shell above will still have a newline on it.  See L</chop>,
4379 L</chomp>, and L</join>.)
4380
4381 =item sprintf FORMAT, LIST
4382
4383 Returns a string formatted by the usual C<printf> conventions of the
4384 C library function C<sprintf>.  See L<sprintf(3)> or L<printf(3)>
4385 on your system for an explanation of the general principles.
4386
4387 Perl does its own C<sprintf> formatting--it emulates the C
4388 function C<sprintf>, but it doesn't use it (except for floating-point
4389 numbers, and even then only the standard modifiers are allowed).  As a
4390 result, any non-standard extensions in your local C<sprintf> are not
4391 available from Perl.
4392
4393 Perl's C<sprintf> permits the following universally-known conversions:
4394
4395    %%   a percent sign
4396    %c   a character with the given number
4397    %s   a string
4398    %d   a signed integer, in decimal
4399    %u   an unsigned integer, in decimal
4400    %o   an unsigned integer, in octal
4401    %x   an unsigned integer, in hexadecimal
4402    %e   a floating-point number, in scientific notation
4403    %f   a floating-point number, in fixed decimal notation
4404    %g   a floating-point number, in %e or %f notation
4405
4406 In addition, Perl permits the following widely-supported conversions:
4407
4408    %X   like %x, but using upper-case letters
4409    %E   like %e, but using an upper-case "E"
4410    %G   like %g, but with an upper-case "E" (if applicable)
4411    %b   an unsigned integer, in binary
4412    %p   a pointer (outputs the Perl value's address in hexadecimal)
4413    %n   special: *stores* the number of characters output so far
4414         into the next variable in the parameter list 
4415
4416 Finally, for backward (and we do mean "backward") compatibility, Perl
4417 permits these unnecessary but widely-supported conversions:
4418
4419    %i   a synonym for %d
4420    %D   a synonym for %ld
4421    %U   a synonym for %lu
4422    %O   a synonym for %lo
4423    %F   a synonym for %f
4424
4425 Perl permits the following universally-known flags between the C<%>
4426 and the conversion letter:
4427
4428    space   prefix positive number with a space
4429    +       prefix positive number with a plus sign
4430    -       left-justify within the field
4431    0       use zeros, not spaces, to right-justify
4432    #       prefix non-zero octal with "0", non-zero hex with "0x"
4433    number  minimum field width
4434    .number "precision": digits after decimal point for
4435            floating-point, max length for string, minimum length
4436            for integer
4437    l       interpret integer as C type "long" or "unsigned long"
4438    h       interpret integer as C type "short" or "unsigned short"
4439            If no flags, interpret integer as C type "int" or "unsigned"
4440
4441 There are also two Perl-specific flags:
4442
4443    V       interpret integer as Perl's standard integer type
4444    v       interpret string as a vector of integers, output as
4445            numbers separated either by dots, or by an arbitrary
4446            string received from the argument list when the flag
4447            is preceded by C<*>
4448
4449 Where a number would appear in the flags, an asterisk (C<*>) may be
4450 used instead, in which case Perl uses the next item in the parameter
4451 list as the given number (that is, as the field width or precision).
4452 If a field width obtained through C<*> is negative, it has the same
4453 effect as the C<-> flag: left-justification.
4454
4455 The C<v> flag is useful for displaying ordinal values of characters
4456 in arbitrary strings:
4457
4458     printf "version is v%vd\n", $^V;            # Perl's version
4459     printf "address is %*vX\n", ":", $addr;     # IPv6 address
4460     printf "bits are %*vb\n", " ", $bits;       # random bitstring
4461
4462 If C<use locale> is in effect, the character used for the decimal
4463 point in formatted real numbers is affected by the LC_NUMERIC locale.
4464 See L<perllocale>.
4465
4466 If Perl understands "quads" (64-bit integers) (this requires
4467 either that the platform natively support quads or that Perl
4468 be specifically compiled to support quads), the characters
4469
4470         d u o x X b i D U O
4471
4472 print quads, and they may optionally be preceded by
4473
4474         ll L q
4475
4476 For example
4477
4478         %lld %16LX %qo
4479
4480 You can find out whether your Perl supports quads via L<Config>:
4481
4482         use Config;
4483         ($Config{use64bitint} eq 'define' || $Config{longsize} == 8) &&
4484                 print "quads\n";
4485
4486 If Perl understands "long doubles" (this requires that the platform
4487 support long doubles), the flags
4488
4489         e f g E F G
4490
4491 may optionally be preceded by
4492
4493         ll L
4494
4495 For example
4496
4497         %llf %Lg
4498
4499 You can find out whether your Perl supports long doubles via L<Config>:
4500
4501         use Config;
4502         $Config{d_longdbl} eq 'define' && print "long doubles\n";
4503
4504 =item sqrt EXPR
4505
4506 =item sqrt
4507
4508 Return the square root of EXPR.  If EXPR is omitted, returns square
4509 root of C<$_>.  Only works on non-negative operands, unless you've
4510 loaded the standard Math::Complex module.
4511
4512     use Math::Complex;
4513     print sqrt(-2);    # prints 1.4142135623731i
4514
4515 =item srand EXPR
4516
4517 =item srand
4518
4519 Sets the random number seed for the C<rand> operator.  If EXPR is
4520 omitted, uses a semi-random value supplied by the kernel (if it supports
4521 the F</dev/urandom> device) or based on the current time and process
4522 ID, among other things.  In versions of Perl prior to 5.004 the default
4523 seed was just the current C<time>.  This isn't a particularly good seed,
4524 so many old programs supply their own seed value (often C<time ^ $$> or
4525 C<time ^ ($$ + ($$ << 15))>), but that isn't necessary any more.
4526
4527 In fact, it's usually not necessary to call C<srand> at all, because if
4528 it is not called explicitly, it is called implicitly at the first use of
4529 the C<rand> operator.  However, this was not the case in version of Perl
4530 before 5.004, so if your script will run under older Perl versions, it
4531 should call C<srand>.
4532
4533 Note that you need something much more random than the default seed for
4534 cryptographic purposes.  Checksumming the compressed output of one or more
4535 rapidly changing operating system status programs is the usual method.  For
4536 example:
4537
4538     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
4539
4540 If you're particularly concerned with this, see the C<Math::TrulyRandom>
4541 module in CPAN.
4542
4543 Do I<not> call C<srand> multiple times in your program unless you know
4544 exactly what you're doing and why you're doing it.  The point of the
4545 function is to "seed" the C<rand> function so that C<rand> can produce
4546 a different sequence each time you run your program.  Just do it once at the
4547 top of your program, or you I<won't> get random numbers out of C<rand>!
4548
4549 Frequently called programs (like CGI scripts) that simply use
4550
4551     time ^ $$
4552
4553 for a seed can fall prey to the mathematical property that
4554
4555     a^b == (a+1)^(b+1)
4556
4557 one-third of the time.  So don't do that.
4558
4559 =item stat FILEHANDLE
4560
4561 =item stat EXPR
4562
4563 =item stat
4564
4565 Returns a 13-element list giving the status info for a file, either
4566 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
4567 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
4568 as follows:
4569
4570     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
4571        $atime,$mtime,$ctime,$blksize,$blocks)
4572            = stat($filename);
4573
4574 Not all fields are supported on all filesystem types.  Here are the
4575 meaning of the fields:
4576
4577   0 dev      device number of filesystem
4578   1 ino      inode number
4579   2 mode     file mode  (type and permissions)
4580   3 nlink    number of (hard) links to the file
4581   4 uid      numeric user ID of file's owner
4582   5 gid      numeric group ID of file's owner
4583   6 rdev     the device identifier (special files only)
4584   7 size     total size of file, in bytes
4585   8 atime    last access time in seconds since the epoch
4586   9 mtime    last modify time in seconds since the epoch
4587  10 ctime    inode change time (NOT creation time!) in seconds since the epoch
4588  11 blksize  preferred block size for file system I/O
4589  12 blocks   actual number of blocks allocated
4590
4591 (The epoch was at 00:00 January 1, 1970 GMT.)
4592
4593 If stat is passed the special filehandle consisting of an underline, no
4594 stat is done, but the current contents of the stat structure from the
4595 last stat or filetest are returned.  Example:
4596
4597     if (-x $file && (($d) = stat(_)) && $d < 0) {
4598         print "$file is executable NFS file\n";
4599     }
4600
4601 (This works on machines only for which the device number is negative
4602 under NFS.)
4603
4604 Because the mode contains both the file type and its permissions, you
4605 should mask off the file type portion and (s)printf using a C<"%o"> 
4606 if you want to see the real permissions.
4607
4608     $mode = (stat($filename))[2];
4609     printf "Permissions are %04o\n", $mode & 07777;
4610
4611 In scalar context, C<stat> returns a boolean value indicating success
4612 or failure, and, if successful, sets the information associated with
4613 the special filehandle C<_>.
4614
4615 The File::stat module provides a convenient, by-name access mechanism:
4616
4617     use File::stat;
4618     $sb = stat($filename);
4619     printf "File is %s, size is %s, perm %04o, mtime %s\n", 
4620         $filename, $sb->size, $sb->mode & 07777,
4621         scalar localtime $sb->mtime;
4622
4623 You can import symbolic mode constants (C<S_IF*>) and functions
4624 (C<S_IS*>) from the Fcntl module:
4625
4626     use Fcntl ':mode';
4627
4628     $mode = (stat($filename))[2];
4629
4630     $user_rwx      = ($mode & S_IRWXU) >> 6;
4631     $group_read    = ($mode & S_IRGRP) >> 3;
4632     $other_execute =  $mode & S_IXOTH;
4633
4634     printf "Permissions are %04o\n", S_ISMODE($mode), "\n";
4635
4636     $is_setuid     =  $mode & S_ISUID;
4637     $is_setgid     =  S_ISDIR($mode);
4638
4639 You could write the last two using the C<-u> and C<-d> operators.
4640 The commonly available S_IF* constants are
4641
4642     # Permissions: read, write, execute, for user, group, others.
4643
4644     S_IRWXU S_IRUSR S_IWUSR S_IXUSR
4645     S_IRWXG S_IRGRP S_IWGRP S_IXGRP
4646     S_IRWXO S_IROTH S_IWOTH S_IXOTH
4647
4648     # Setuid/Setgid/Stickiness.
4649
4650     S_ISUID S_ISGID S_ISVTX S_ISTXT
4651
4652     # File types.  Not necessarily all are available on your system.
4653
4654     S_IFREG S_IFDIR S_IFLNK S_IFBLK S_ISCHR S_IFIFO S_IFSOCK S_IFWHT S_ENFMT
4655
4656     # The following are compatibility aliases for S_IRUSR, S_IWUSR, S_IXUSR.
4657
4658     S_IREAD S_IWRITE S_IEXEC
4659
4660 and the S_IF* functions are
4661
4662     S_IFMODE($mode)     the part of $mode containing the permission bits
4663                         and the setuid/setgid/sticky bits
4664
4665     S_IFMT($mode)       the part of $mode containing the file type
4666                &n