This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
8da64cad6135179b56f1aabd989afc9255468827
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25 require 5.010_001;
26 use strict;
27 use warnings;
28 use Carp;
29 use Config;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34
35 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
36 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
37
38 ##########################################################################
39 #
40 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
41 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
42 # a pod file and a .t file
43 #
44 # The structure of this file is:
45 #   First these introductory comments; then
46 #   code needed for everywhere, such as debugging stuff; then
47 #   code to handle input parameters; then
48 #   data structures likely to be of external interest (some of which depend on
49 #       the input parameters, so follows them; then
50 #   more data structures and subroutine and package (class) definitions; then
51 #   the small actual loop to process the input files and finish up; then
52 #   a __DATA__ section, for the .t tests
53 #
54 # This program works on all releases of Unicode through at least 6.0.  The
55 # outputs have been scrutinized most intently for release 5.1.  The others
56 # have been checked for somewhat more than just sanity.  It can handle all
57 # existing Unicode character properties in those releases.
58 #
59 # This program is mostly about Unicode character (or code point) properties.
60 # A property describes some attribute or quality of a code point, like if it
61 # is lowercase or not, its name, what version of Unicode it was first defined
62 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
63 # possibilities by making all properties into mappings from each code point
64 # into some corresponding value.  In the case of it being lowercase or not,
65 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
66 # property maps each Unicode code point to a single value, called a "property
67 # value".  (Hence each Unicode property is a true mathematical function with
68 # exactly one value per code point.)
69 #
70 # When using a property in a regular expression, what is desired isn't the
71 # mapping of the code point to its property's value, but the reverse (or the
72 # mathematical "inverse relation"): starting with the property value, "Does a
73 # code point map to it?"  These are written in a "compound" form:
74 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
75 # files containing the lists of code points that map to each such regular
76 # expression property value, one file per list
77 #
78 # There is also a single form shortcut that Perl adds for many of the commonly
79 # used properties.  This happens for all binary properties, plus script,
80 # general_category, and block properties.
81 #
82 # Thus the outputs of this program are files.  There are map files, mostly in
83 # the 'To' directory; and there are list files for use in regular expression
84 # matching, all in subdirectories of the 'lib' directory, with each
85 # subdirectory being named for the property that the lists in it are for.
86 # Bookkeeping, test, and documentation files are also generated.
87
88 my $matches_directory = 'lib';   # Where match (\p{}) files go.
89 my $map_directory = 'To';        # Where map files go.
90
91 # DATA STRUCTURES
92 #
93 # The major data structures of this program are Property, of course, but also
94 # Table.  There are two kinds of tables, very similar to each other.
95 # "Match_Table" is the data structure giving the list of code points that have
96 # a particular property value, mentioned above.  There is also a "Map_Table"
97 # data structure which gives the property's mapping from code point to value.
98 # There are two structures because the match tables need to be combined in
99 # various ways, such as constructing unions, intersections, complements, etc.,
100 # and the map ones don't.  And there would be problems, perhaps subtle, if
101 # a map table were inadvertently operated on in some of those ways.
102 # The use of separate classes with operations defined on one but not the other
103 # prevents accidentally confusing the two.
104 #
105 # At the heart of each table's data structure is a "Range_List", which is just
106 # an ordered list of "Ranges", plus ancillary information, and methods to
107 # operate on them.  A Range is a compact way to store property information.
108 # Each range has a starting code point, an ending code point, and a value that
109 # is meant to apply to all the code points between the two end points,
110 # inclusive.  For a map table, this value is the property value for those
111 # code points.  Two such ranges could be written like this:
112 #   0x41 .. 0x5A, 'Upper',
113 #   0x61 .. 0x7A, 'Lower'
114 #
115 # Each range also has a type used as a convenience to classify the values.
116 # Most ranges in this program will be Type 0, or normal, but there are some
117 # ranges that have a non-zero type.  These are used only in map tables, and
118 # are for mappings that don't fit into the normal scheme of things.  Mappings
119 # that require a hash entry to communicate with utf8.c are one example;
120 # another example is mappings for charnames.pm to use which indicate a name
121 # that is algorithmically determinable from its code point (and vice-versa).
122 # These are used to significantly compact these tables, instead of listing
123 # each one of the tens of thousands individually.
124 #
125 # In a match table, the value of a range is irrelevant (and hence the type as
126 # well, which will always be 0), and arbitrarily set to the null string.
127 # Using the example above, there would be two match tables for those two
128 # entries, one named Upper would contain the 0x41..0x5A range, and the other
129 # named Lower would contain 0x61..0x7A.
130 #
131 # Actually, there are two types of range lists, "Range_Map" is the one
132 # associated with map tables, and "Range_List" with match tables.
133 # Again, this is so that methods can be defined on one and not the other so as
134 # to prevent operating on them in incorrect ways.
135 #
136 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
137 # in the perl core.  All tables could in theory be written, but some are
138 # suppressed because there is no current practical use for them.  It is easy
139 # to change which get written by changing various lists that are near the top
140 # of the actual code in this file.  The table data structures contain enough
141 # ancillary information to allow them to be treated as separate entities for
142 # writing, such as the path to each one's file.  There is a heading in each
143 # map table that gives the format of its entries, and what the map is for all
144 # the code points missing from it.  (This allows tables to be more compact.)
145 #
146 # The Property data structure contains one or more tables.  All properties
147 # contain a map table (except the $perl property which is a
148 # pseudo-property containing only match tables), and any properties that
149 # are usable in regular expression matches also contain various matching
150 # tables, one for each value the property can have.  A binary property can
151 # have two values, True and False (or Y and N, which are preferred by Unicode
152 # terminology).  Thus each of these properties will have a map table that
153 # takes every code point and maps it to Y or N (but having ranges cuts the
154 # number of entries in that table way down), and two match tables, one
155 # which has a list of all the code points that map to Y, and one for all the
156 # code points that map to N.  (For each of these, a third table is also
157 # generated for the pseudo Perl property.  It contains the identical code
158 # points as the Y table, but can be written, not in the compound form, but in
159 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
160 # properties have several possible values, some have many, and properties like
161 # Name have a different value for every named code point.  Those will not,
162 # unless the controlling lists are changed, have their match tables written
163 # out.  But all the ones which can be used in regular expression \p{} and \P{}
164 # constructs will.  Prior to 5.14, generally a property would have either its
165 # map table or its match tables written but not both.  Again, what gets
166 # written is controlled by lists which can easily be changed.  Starting in
167 # 5.14, advantage was taken of this, and all the map tables needed to
168 # reconstruct the Unicode db are now written out, while suppressing the
169 # Unicode .txt files that contain the data.  Our tables are much more compact
170 # than the .txt files, so a significant space savings was achieved.
171
172 # Properties have a 'Type', like binary, or string, or enum depending on how
173 # many match tables there are and the content of the maps.  This 'Type' is
174 # different than a range 'Type', so don't get confused by the two concepts
175 # having the same name.
176 #
177 # For information about the Unicode properties, see Unicode's UAX44 document:
178
179 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
180
181 # As stated earlier, this program will work on any release of Unicode so far.
182 # Most obvious problems in earlier data have NOT been corrected except when
183 # necessary to make Perl or this program work reasonably.  For example, no
184 # folding information was given in early releases, so this program substitutes
185 # lower case instead, just so that a regular expression with the /i option
186 # will do something that actually gives the right results in many cases.
187 # There are also a couple other corrections for version 1.1.5, commented at
188 # the point they are made.  As an example of corrections that weren't made
189 # (but could be) is this statement from DerivedAge.txt: "The supplementary
190 # private use code points and the non-character code points were assigned in
191 # version 2.0, but not specifically listed in the UCD until versions 3.0 and
192 # 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0) More information
193 # on Unicode version glitches is further down in these introductory comments.
194 #
195 # This program works on all non-provisional properties as of 6.0, though the
196 # files for some are suppressed from apparent lack of demand for them.  You
197 # can change which are output by changing lists in this program.
198 #
199 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
200 # loose matchings rules (from Unicode TR18):
201 #
202 #    The recommended names for UCD properties and property values are in
203 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
204 #    [PropValue]. There are both abbreviated names and longer, more
205 #    descriptive names. It is strongly recommended that both names be
206 #    recognized, and that loose matching of property names be used,
207 #    whereby the case distinctions, whitespace, hyphens, and underbar
208 #    are ignored.
209 # The program still allows Fuzzy to override its determination of if loose
210 # matching should be used, but it isn't currently used, as it is no longer
211 # needed; the calculations it makes are good enough.
212 #
213 # SUMMARY OF HOW IT WORKS:
214 #
215 #   Process arguments
216 #
217 #   A list is constructed containing each input file that is to be processed
218 #
219 #   Each file on the list is processed in a loop, using the associated handler
220 #   code for each:
221 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
222 #            first.  These files name the properties and property values.
223 #            Objects are created of all the property and property value names
224 #            that the rest of the input should expect, including all synonyms.
225 #        The other input files give mappings from properties to property
226 #           values.  That is, they list code points and say what the mapping
227 #           is under the given property.  Some files give the mappings for
228 #           just one property; and some for many.  This program goes through
229 #           each file and populates the properties from them.  Some properties
230 #           are listed in more than one file, and Unicode has set up a
231 #           precedence as to which has priority if there is a conflict.  Thus
232 #           the order of processing matters, and this program handles the
233 #           conflict possibility by processing the overriding input files
234 #           last, so that if necessary they replace earlier values.
235 #        After this is all done, the program creates the property mappings not
236 #            furnished by Unicode, but derivable from what it does give.
237 #        The tables of code points that match each property value in each
238 #            property that is accessible by regular expressions are created.
239 #        The Perl-defined properties are created and populated.  Many of these
240 #            require data determined from the earlier steps
241 #        Any Perl-defined synonyms are created, and name clashes between Perl
242 #            and Unicode are reconciled and warned about.
243 #        All the properties are written to files
244 #        Any other files are written, and final warnings issued.
245 #
246 # For clarity, a number of operators have been overloaded to work on tables:
247 #   ~ means invert (take all characters not in the set).  The more
248 #       conventional '!' is not used because of the possibility of confusing
249 #       it with the actual boolean operation.
250 #   + means union
251 #   - means subtraction
252 #   & means intersection
253 # The precedence of these is the order listed.  Parentheses should be
254 # copiously used.  These are not a general scheme.  The operations aren't
255 # defined for a number of things, deliberately, to avoid getting into trouble.
256 # Operations are done on references and affect the underlying structures, so
257 # that the copy constructors for them have been overloaded to not return a new
258 # clone, but the input object itself.
259 #
260 # The bool operator is deliberately not overloaded to avoid confusion with
261 # "should it mean if the object merely exists, or also is non-empty?".
262 #
263 # WHY CERTAIN DESIGN DECISIONS WERE MADE
264 #
265 # This program needs to be able to run under miniperl.  Therefore, it uses a
266 # minimum of other modules, and hence implements some things itself that could
267 # be gotten from CPAN
268 #
269 # This program uses inputs published by the Unicode Consortium.  These can
270 # change incompatibly between releases without the Perl maintainers realizing
271 # it.  Therefore this program is now designed to try to flag these.  It looks
272 # at the directories where the inputs are, and flags any unrecognized files.
273 # It keeps track of all the properties in the files it handles, and flags any
274 # that it doesn't know how to handle.  It also flags any input lines that
275 # don't match the expected syntax, among other checks.
276 #
277 # It is also designed so if a new input file matches one of the known
278 # templates, one hopefully just needs to add it to a list to have it
279 # processed.
280 #
281 # As mentioned earlier, some properties are given in more than one file.  In
282 # particular, the files in the extracted directory are supposedly just
283 # reformattings of the others.  But they contain information not easily
284 # derivable from the other files, including results for Unihan, which this
285 # program doesn't ordinarily look at, and for unassigned code points.  They
286 # also have historically had errors or been incomplete.  In an attempt to
287 # create the best possible data, this program thus processes them first to
288 # glean information missing from the other files; then processes those other
289 # files to override any errors in the extracted ones.  Much of the design was
290 # driven by this need to store things and then possibly override them.
291 #
292 # It tries to keep fatal errors to a minimum, to generate something usable for
293 # testing purposes.  It always looks for files that could be inputs, and will
294 # warn about any that it doesn't know how to handle (the -q option suppresses
295 # the warning).
296 #
297 # Why is there more than one type of range?
298 #   This simplified things.  There are some very specialized code points that
299 #   have to be handled specially for output, such as Hangul syllable names.
300 #   By creating a range type (done late in the development process), it
301 #   allowed this to be stored with the range, and overridden by other input.
302 #   Originally these were stored in another data structure, and it became a
303 #   mess trying to decide if a second file that was for the same property was
304 #   overriding the earlier one or not.
305 #
306 # Why are there two kinds of tables, match and map?
307 #   (And there is a base class shared by the two as well.)  As stated above,
308 #   they actually are for different things.  Development proceeded much more
309 #   smoothly when I (khw) realized the distinction.  Map tables are used to
310 #   give the property value for every code point (actually every code point
311 #   that doesn't map to a default value).  Match tables are used for regular
312 #   expression matches, and are essentially the inverse mapping.  Separating
313 #   the two allows more specialized methods, and error checks so that one
314 #   can't just take the intersection of two map tables, for example, as that
315 #   is nonsensical.
316 #
317 # DEBUGGING
318 #
319 # This program is written so it will run under miniperl.  Occasionally changes
320 # will cause an error where the backtrace doesn't work well under miniperl.
321 # To diagnose the problem, you can instead run it under regular perl, if you
322 # have one compiled.
323 #
324 # There is a good trace facility.  To enable it, first sub DEBUG must be set
325 # to return true.  Then a line like
326 #
327 # local $to_trace = 1 if main::DEBUG;
328 #
329 # can be added to enable tracing in its lexical scope or until you insert
330 # another line:
331 #
332 # local $to_trace = 0 if main::DEBUG;
333 #
334 # then use a line like "trace $a, @b, %c, ...;
335 #
336 # Some of the more complex subroutines already have trace statements in them.
337 # Permanent trace statements should be like:
338 #
339 # trace ... if main::DEBUG && $to_trace;
340 #
341 # If there is just one or a few files that you're debugging, you can easily
342 # cause most everything else to be skipped.  Change the line
343 #
344 # my $debug_skip = 0;
345 #
346 # to 1, and every file whose object is in @input_file_objects and doesn't have
347 # a, 'non_skip => 1,' in its constructor will be skipped.
348 #
349 # To compare the output tables, it may be useful to specify the -annotate
350 # flag.  This causes the tables to expand so there is one entry for each
351 # non-algorithmically named code point giving, currently its name, and its
352 # graphic representation if printable (and you have a font that knows about
353 # it).  This makes it easier to see what the particular code points are in
354 # each output table.  The tables are usable, but because they don't have
355 # ranges (for the most part), a Perl using them will run slower.  Non-named
356 # code points are annotated with a description of their status, and contiguous
357 # ones with the same description will be output as a range rather than
358 # individually.  Algorithmically named characters are also output as ranges,
359 # except when there are just a few contiguous ones.
360 #
361 # FUTURE ISSUES
362 #
363 # The program would break if Unicode were to change its names so that
364 # interior white space, underscores, or dashes differences were significant
365 # within property and property value names.
366 #
367 # It might be easier to use the xml versions of the UCD if this program ever
368 # would need heavy revision, and the ability to handle old versions was not
369 # required.
370 #
371 # There is the potential for name collisions, in that Perl has chosen names
372 # that Unicode could decide it also likes.  There have been such collisions in
373 # the past, with mostly Perl deciding to adopt the Unicode definition of the
374 # name.  However in the 5.2 Unicode beta testing, there were a number of such
375 # collisions, which were withdrawn before the final release, because of Perl's
376 # and other's protests.  These all involved new properties which began with
377 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
378 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
379 # Unicode document, so they are unlikely to be used by Unicode for another
380 # purpose.  However, they might try something beginning with 'In', or use any
381 # of the other Perl-defined properties.  This program will warn you of name
382 # collisions, and refuse to generate tables with them, but manual intervention
383 # will be required in this event.  One scheme that could be implemented, if
384 # necessary, would be to have this program generate another file, or add a
385 # field to mktables.lst that gives the date of first definition of a property.
386 # Each new release of Unicode would use that file as a basis for the next
387 # iteration.  And the Perl synonym addition code could sort based on the age
388 # of the property, so older properties get priority, and newer ones that clash
389 # would be refused; hence existing code would not be impacted, and some other
390 # synonym would have to be used for the new property.  This is ugly, and
391 # manual intervention would certainly be easier to do in the short run; lets
392 # hope it never comes to this.
393 #
394 # A NOTE ON UNIHAN
395 #
396 # This program can generate tables from the Unihan database.  But it doesn't
397 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
398 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
399 # database was split into 8 different files, all beginning with the letters
400 # 'Unihan'.  This program will read those file(s) if present, but it needs to
401 # know which of the many properties in the file(s) should have tables created
402 # for them.  It will create tables for any properties listed in
403 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
404 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
405 # property you want is not in those files of the release you are building
406 # against, you must add it to those two arrays.  Starting in 4.0, the
407 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
408 # is present in the directory, a table will be generated for that property.
409 # In 5.2, several more properties were added.  For your convenience, the two
410 # arrays are initialized with all the 6.0 listed properties that are also in
411 # earlier releases.  But these are commented out.  You can just uncomment the
412 # ones you want, or use them as a template for adding entries for other
413 # properties.
414 #
415 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
416 # and filter_unihan_line() are the functions where this is done.  This program
417 # already does some adjusting to make the lines look more like the rest of the
418 # Unicode DB;  You can see what that is in filter_unihan_line()
419 #
420 # There is a bug in the 3.2 data file in which some values for the
421 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
422 # could be added for these; or for a particular installation, the Unihan.txt
423 # file could be edited to fix them.
424 #
425 # HOW TO ADD A FILE TO BE PROCESSED
426 #
427 # A new file from Unicode needs to have an object constructed for it in
428 # @input_file_objects, probably at the end or at the end of the extracted
429 # ones.  The program should warn you if its name will clash with others on
430 # restrictive file systems, like DOS.  If so, figure out a better name, and
431 # add lines to the README.perl file giving that.  If the file is a character
432 # property, it should be in the format that Unicode has by default
433 # standardized for such files for the more recently introduced ones.
434 # If so, the Input_file constructor for @input_file_objects can just be the
435 # file name and release it first appeared in.  If not, then it should be
436 # possible to construct an each_line_handler() to massage the line into the
437 # standardized form.
438 #
439 # For non-character properties, more code will be needed.  You can look at
440 # the existing entries for clues.
441 #
442 # UNICODE VERSIONS NOTES
443 #
444 # The Unicode UCD has had a number of errors in it over the versions.  And
445 # these remain, by policy, in the standard for that version.  Therefore it is
446 # risky to correct them, because code may be expecting the error.  So this
447 # program doesn't generally make changes, unless the error breaks the Perl
448 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
449 # for U+1105, which causes real problems for the algorithms for Jamo
450 # calculations, so it is changed here.
451 #
452 # But it isn't so clear cut as to what to do about concepts that are
453 # introduced in a later release; should they extend back to earlier releases
454 # where the concept just didn't exist?  It was easier to do this than to not,
455 # so that's what was done.  For example, the default value for code points not
456 # in the files for various properties was probably undefined until changed by
457 # some version.  No_Block for blocks is such an example.  This program will
458 # assign No_Block even in Unicode versions that didn't have it.  This has the
459 # benefit that code being written doesn't have to special case earlier
460 # versions; and the detriment that it doesn't match the Standard precisely for
461 # the affected versions.
462 #
463 # Here are some observations about some of the issues in early versions:
464 #
465 # The number of code points in \p{alpha} halved in 2.1.9.  It turns out that
466 # the reason is that the CJK block starting at 4E00 was removed from PropList,
467 # and was not put back in until 3.1.0
468 #
469 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
470 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
471 # reason is that 3.2 introduced U+205F=medium math space, which was not
472 # classed as white space, but Perl figured out that it should have been. 4.0
473 # reclassified it correctly.
474 #
475 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
476 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
477 # was left with no code points, as all the ones that mapped to 202 stayed
478 # mapped to 202.  Thus if your program used the numeric name for the class,
479 # it would not have been affected, but if it used the mnemonic, it would have
480 # been.
481 #
482 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
483 # points which eventually came to have this script property value, instead
484 # mapped to "Unknown".  But in the next release all these code points were
485 # moved to \p{sc=common} instead.
486 #
487 # The default for missing code points for BidiClass is complicated.  Starting
488 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
489 # tries to do the best it can for earlier releases.  It is done in
490 # process_PropertyAliases()
491 #
492 ##############################################################################
493
494 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
495                         # and errors
496 my $MAX_LINE_WIDTH = 78;
497
498 # Debugging aid to skip most files so as to not be distracted by them when
499 # concentrating on the ones being debugged.  Add
500 # non_skip => 1,
501 # to the constructor for those files you want processed when you set this.
502 # Files with a first version number of 0 are special: they are always
503 # processed regardless of the state of this flag.  Generally, Jamo.txt and
504 # UnicodeData.txt must not be skipped if you want this program to not die
505 # before normal completion.
506 my $debug_skip = 0;
507
508 # Set to 1 to enable tracing.
509 our $to_trace = 0;
510
511 { # Closure for trace: debugging aid
512     my $print_caller = 1;        # ? Include calling subroutine name
513     my $main_with_colon = 'main::';
514     my $main_colon_length = length($main_with_colon);
515
516     sub trace {
517         return unless $to_trace;        # Do nothing if global flag not set
518
519         my @input = @_;
520
521         local $DB::trace = 0;
522         $DB::trace = 0;          # Quiet 'used only once' message
523
524         my $line_number;
525
526         # Loop looking up the stack to get the first non-trace caller
527         my $caller_line;
528         my $caller_name;
529         my $i = 0;
530         do {
531             $line_number = $caller_line;
532             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
533             $caller = $main_with_colon unless defined $caller;
534
535             $caller_name = $caller;
536
537             # get rid of pkg
538             $caller_name =~ s/.*:://;
539             if (substr($caller_name, 0, $main_colon_length)
540                 eq $main_with_colon)
541             {
542                 $caller_name = substr($caller_name, $main_colon_length);
543             }
544
545         } until ($caller_name ne 'trace');
546
547         # If the stack was empty, we were called from the top level
548         $caller_name = 'main' if ($caller_name eq ""
549                                     || $caller_name eq 'trace');
550
551         my $output = "";
552         foreach my $string (@input) {
553             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
554             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
555                 $output .= simple_dumper($string);
556             }
557             else {
558                 $string = "$string" if ref $string;
559                 $string = $UNDEF unless defined $string;
560                 chomp $string;
561                 $string = '""' if $string eq "";
562                 $output .= " " if $output ne ""
563                                 && $string ne ""
564                                 && substr($output, -1, 1) ne " "
565                                 && substr($string, 0, 1) ne " ";
566                 $output .= $string;
567             }
568         }
569
570         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
571         print STDERR "$caller_name: " if $print_caller;
572         print STDERR $output, "\n";
573         return;
574     }
575 }
576
577 # This is for a rarely used development feature that allows you to compare two
578 # versions of the Unicode standard without having to deal with changes caused
579 # by the code points introduced in the later version.  Change the 0 to a
580 # string containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only
581 # code points introduced in that release and earlier will be used; later ones
582 # are thrown away.  You use the version number of the earliest one you want to
583 # compare; then run this program on directory structures containing each
584 # release, and compare the outputs.  These outputs will therefore include only
585 # the code points common to both releases, and you can see the changes caused
586 # just by the underlying release semantic changes.  For versions earlier than
587 # 3.2, you must copy a version of DAge.txt into the directory.
588 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
589 my $compare_versions = DEBUG
590                        && $string_compare_versions
591                        && pack "C*", split /\./, $string_compare_versions;
592
593 sub uniques {
594     # Returns non-duplicated input values.  From "Perl Best Practices:
595     # Encapsulated Cleverness".  p. 455 in first edition.
596
597     my %seen;
598     # Arguably this breaks encapsulation, if the goal is to permit multiple
599     # distinct objects to stringify to the same value, and be interchangeable.
600     # However, for this program, no two objects stringify identically, and all
601     # lists passed to this function are either objects or strings. So this
602     # doesn't affect correctness, but it does give a couple of percent speedup.
603     no overloading;
604     return grep { ! $seen{$_}++ } @_;
605 }
606
607 $0 = File::Spec->canonpath($0);
608
609 my $make_test_script = 0;      # ? Should we output a test script
610 my $write_unchanged_files = 0; # ? Should we update the output files even if
611                                #    we don't think they have changed
612 my $use_directory = "";        # ? Should we chdir somewhere.
613 my $pod_directory;             # input directory to store the pod file.
614 my $pod_file = 'perluniprops';
615 my $t_path;                     # Path to the .t test file
616 my $file_list = 'mktables.lst'; # File to store input and output file names.
617                                # This is used to speed up the build, by not
618                                # executing the main body of the program if
619                                # nothing on the list has changed since the
620                                # previous build
621 my $make_list = 1;             # ? Should we write $file_list.  Set to always
622                                # make a list so that when the pumpking is
623                                # preparing a release, s/he won't have to do
624                                # special things
625 my $glob_list = 0;             # ? Should we try to include unknown .txt files
626                                # in the input.
627 my $output_range_counts = $debugging_build;   # ? Should we include the number
628                                               # of code points in ranges in
629                                               # the output
630 my $annotate = 0;              # ? Should character names be in the output
631
632 # Verbosity levels; 0 is quiet
633 my $NORMAL_VERBOSITY = 1;
634 my $PROGRESS = 2;
635 my $VERBOSE = 3;
636
637 my $verbosity = $NORMAL_VERBOSITY;
638
639 # Process arguments
640 while (@ARGV) {
641     my $arg = shift @ARGV;
642     if ($arg eq '-v') {
643         $verbosity = $VERBOSE;
644     }
645     elsif ($arg eq '-p') {
646         $verbosity = $PROGRESS;
647         $| = 1;     # Flush buffers as we go.
648     }
649     elsif ($arg eq '-q') {
650         $verbosity = 0;
651     }
652     elsif ($arg eq '-w') {
653         $write_unchanged_files = 1; # update the files even if havent changed
654     }
655     elsif ($arg eq '-check') {
656         my $this = shift @ARGV;
657         my $ok = shift @ARGV;
658         if ($this ne $ok) {
659             print "Skipping as check params are not the same.\n";
660             exit(0);
661         }
662     }
663     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
664         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
665     }
666     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
667     {
668         $make_test_script = 1;
669     }
670     elsif ($arg eq '-makelist') {
671         $make_list = 1;
672     }
673     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
674         -d $use_directory or croak "Unknown directory '$use_directory'";
675     }
676     elsif ($arg eq '-L') {
677
678         # Existence not tested until have chdir'd
679         $file_list = shift;
680     }
681     elsif ($arg eq '-globlist') {
682         $glob_list = 1;
683     }
684     elsif ($arg eq '-c') {
685         $output_range_counts = ! $output_range_counts
686     }
687     elsif ($arg eq '-annotate') {
688         $annotate = 1;
689         $debugging_build = 1;
690         $output_range_counts = 1;
691     }
692     else {
693         my $with_c = 'with';
694         $with_c .= 'out' if $output_range_counts;   # Complements the state
695         croak <<END;
696 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
697           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
698           [-check A B ]
699   -c          : Output comments $with_c number of code points in ranges
700   -q          : Quiet Mode: Only output serious warnings.
701   -p          : Set verbosity level to normal plus show progress.
702   -v          : Set Verbosity level high:  Show progress and non-serious
703                 warnings
704   -w          : Write files regardless
705   -C dir      : Change to this directory before proceeding. All relative paths
706                 except those specified by the -P and -T options will be done
707                 with respect to this directory.
708   -P dir      : Output $pod_file file to directory 'dir'.
709   -T path     : Create a test script as 'path'; overrides -maketest
710   -L filelist : Use alternate 'filelist' instead of standard one
711   -globlist   : Take as input all non-Test *.txt files in current and sub
712                 directories
713   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
714                 overrides -T
715   -makelist   : Rewrite the file list $file_list based on current setup
716   -annotate   : Output an annotation for each character in the table files;
717                 useful for debugging mktables, looking at diffs; but is slow,
718                 memory intensive; resulting tables are usable but slow and
719                 very large.
720   -check A B  : Executes $0 only if A and B are the same
721 END
722     }
723 }
724
725 # Stores the most-recently changed file.  If none have changed, can skip the
726 # build
727 my $most_recent = (stat $0)[9];   # Do this before the chdir!
728
729 # Change directories now, because need to read 'version' early.
730 if ($use_directory) {
731     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
732         $pod_directory = File::Spec->rel2abs($pod_directory);
733     }
734     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
735         $t_path = File::Spec->rel2abs($t_path);
736     }
737     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
738     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
739         $pod_directory = File::Spec->abs2rel($pod_directory);
740     }
741     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
742         $t_path = File::Spec->abs2rel($t_path);
743     }
744 }
745
746 # Get Unicode version into regular and v-string.  This is done now because
747 # various tables below get populated based on it.  These tables are populated
748 # here to be near the top of the file, and so easily seeable by those needing
749 # to modify things.
750 open my $VERSION, "<", "version"
751                     or croak "$0: can't open required file 'version': $!\n";
752 my $string_version = <$VERSION>;
753 close $VERSION;
754 chomp $string_version;
755 my $v_version = pack "C*", split /\./, $string_version;        # v string
756
757 # The following are the complete names of properties with property values that
758 # are known to not match any code points in some versions of Unicode, but that
759 # may change in the future so they should be matchable, hence an empty file is
760 # generated for them.
761 my @tables_that_may_be_empty = (
762                                 'Joining_Type=Left_Joining',
763                                 );
764 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
765 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
766 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
767                                                     if $v_version ge v4.1.0;
768 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
769                                                     if $v_version ge v6.0.0;
770
771 # The lists below are hashes, so the key is the item in the list, and the
772 # value is the reason why it is in the list.  This makes generation of
773 # documentation easier.
774
775 my %why_suppressed;  # No file generated for these.
776
777 # Files aren't generated for empty extraneous properties.  This is arguable.
778 # Extraneous properties generally come about because a property is no longer
779 # used in a newer version of Unicode.  If we generated a file without code
780 # points, programs that used to work on that property will still execute
781 # without errors.  It just won't ever match (or will always match, with \P{}).
782 # This means that the logic is now likely wrong.  I (khw) think its better to
783 # find this out by getting an error message.  Just move them to the table
784 # above to change this behavior
785 my %why_suppress_if_empty_warn_if_not = (
786
787    # It is the only property that has ever officially been removed from the
788    # Standard.  The database never contained any code points for it.
789    'Special_Case_Condition' => 'Obsolete',
790
791    # Apparently never official, but there were code points in some versions of
792    # old-style PropList.txt
793    'Non_Break' => 'Obsolete',
794 );
795
796 # These would normally go in the warn table just above, but they were changed
797 # a long time before this program was written, so warnings about them are
798 # moot.
799 if ($v_version gt v3.2.0) {
800     push @tables_that_may_be_empty,
801                                 'Canonical_Combining_Class=Attached_Below_Left'
802 }
803
804 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
805 # unless explicitly added.
806 if ($v_version ge v5.2.0) {
807     my $unihan = 'Unihan; remove from list if using Unihan';
808     foreach my $table (qw (
809                            kAccountingNumeric
810                            kOtherNumeric
811                            kPrimaryNumeric
812                            kCompatibilityVariant
813                            kIICore
814                            kIRG_GSource
815                            kIRG_HSource
816                            kIRG_JSource
817                            kIRG_KPSource
818                            kIRG_MSource
819                            kIRG_KSource
820                            kIRG_TSource
821                            kIRG_USource
822                            kIRG_VSource
823                            kRSUnicode
824                         ))
825     {
826         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
827     }
828 }
829
830 # Enum values for to_output_map() method in the Map_Table package.
831 my $EXTERNAL_MAP = 1;
832 my $INTERNAL_MAP = 2;
833
834 # To override computed values for writing the map tables for these properties.
835 # The default for enum map tables is to write them out, so that the Unicode
836 # .txt files can be removed, but all the data to compute any property value
837 # for any code point is available in a more compact form.
838 my %global_to_output_map = (
839     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
840     # get stuck supporting it if things change.  Since it is a STRING
841     # property, it normally would be listed in the pod, but INTERNAL_MAP
842     # suppresses that.
843     Unicode_1_Name => $INTERNAL_MAP,
844
845     Present_In => 0,                # Suppress, as easily computed from Age
846     Block => 0,                     # Suppress, as Blocks.txt is retained.
847
848     # Suppress, as mapping can be found instead from the
849     # Perl_Decomposition_Mapping file
850     Decomposition_Type => 0,
851 );
852
853 # Properties that this program ignores.
854 my @unimplemented_properties;
855
856 # With this release, it is automatically handled if the Unihan db is
857 # downloaded
858 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version le v5.2.0;
859
860 # There are several types of obsolete properties defined by Unicode.  These
861 # must be hand-edited for every new Unicode release.
862 my %why_deprecated;  # Generates a deprecated warning message if used.
863 my %why_stabilized;  # Documentation only
864 my %why_obsolete;    # Documentation only
865
866 {   # Closure
867     my $simple = 'Perl uses the more complete version of this property';
868     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
869
870     my $other_properties = 'other properties';
871     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
872     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
873
874     %why_deprecated = (
875         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
876         'Jamo_Short_Name' => $contributory,
877         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
878         'Other_Alphabetic' => $contributory,
879         'Other_Default_Ignorable_Code_Point' => $contributory,
880         'Other_Grapheme_Extend' => $contributory,
881         'Other_ID_Continue' => $contributory,
882         'Other_ID_Start' => $contributory,
883         'Other_Lowercase' => $contributory,
884         'Other_Math' => $contributory,
885         'Other_Uppercase' => $contributory,
886         'Expands_On_NFC' => $why_no_expand,
887         'Expands_On_NFD' => $why_no_expand,
888         'Expands_On_NFKC' => $why_no_expand,
889         'Expands_On_NFKD' => $why_no_expand,
890     );
891
892     %why_suppressed = (
893         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
894         # contains the same information, but without the algorithmically
895         # determinable Hangul syllables'.  This file is not published, so it's
896         # existence is not noted in the comment.
897         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize',
898
899         'ISO_Comment' => 'Apparently no demand for it, but can access it through Unicode::UCD::charinfo.  Obsoleted, and code points for it removed in Unicode 5.2',
900
901         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold",
902         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
903         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
904         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
905
906         'Name' => "Accessible via 'use charnames;'",
907         'Name_Alias' => "Accessible via 'use charnames;'",
908
909         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
910     );
911
912     # The following are suppressed because they were made contributory or
913     # deprecated by Unicode before Perl ever thought about supporting them.
914     foreach my $property ('Jamo_Short_Name',
915                           'Grapheme_Link',
916                           'Expands_On_NFC',
917                           'Expands_On_NFD',
918                           'Expands_On_NFKC',
919                           'Expands_On_NFKD'
920     ) {
921         $why_suppressed{$property} = $why_deprecated{$property};
922     }
923
924     # Customize the message for all the 'Other_' properties
925     foreach my $property (keys %why_deprecated) {
926         next if (my $main_property = $property) !~ s/^Other_//;
927         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
928     }
929 }
930
931 if ($v_version ge 4.0.0) {
932     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
933     if ($v_version ge 6.0.0) {
934         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
935     }
936 }
937 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
938     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
939     if ($v_version ge 6.0.0) {
940         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
941     }
942 }
943
944 # Probably obsolete forever
945 if ($v_version ge v4.1.0) {
946     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
947 }
948 if ($v_version ge v6.0.0) {
949     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana (or both)"';
950     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
951 }
952
953 # This program can create files for enumerated-like properties, such as
954 # 'Numeric_Type'.  This file would be the same format as for a string
955 # property, with a mapping from code point to its value, so you could look up,
956 # for example, the script a code point is in.  But no one so far wants this
957 # mapping, or they have found another way to get it since this is a new
958 # feature.  So no file is generated except if it is in this list.
959 my @output_mapped_properties = split "\n", <<END;
960 END
961
962 # If you are using the Unihan database in a Unicode version before 5.2, you
963 # need to add the properties that you want to extract from it to this table.
964 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
965 # listed, commented out
966 my @cjk_properties = split "\n", <<'END';
967 #cjkAccountingNumeric; kAccountingNumeric
968 #cjkOtherNumeric; kOtherNumeric
969 #cjkPrimaryNumeric; kPrimaryNumeric
970 #cjkCompatibilityVariant; kCompatibilityVariant
971 #cjkIICore ; kIICore
972 #cjkIRG_GSource; kIRG_GSource
973 #cjkIRG_HSource; kIRG_HSource
974 #cjkIRG_JSource; kIRG_JSource
975 #cjkIRG_KPSource; kIRG_KPSource
976 #cjkIRG_KSource; kIRG_KSource
977 #cjkIRG_TSource; kIRG_TSource
978 #cjkIRG_USource; kIRG_USource
979 #cjkIRG_VSource; kIRG_VSource
980 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
981 END
982
983 # Similarly for the property values.  For your convenience, the lines in the
984 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
985 # '#' marks (for Unicode versions before 5.2)
986 my @cjk_property_values = split "\n", <<'END';
987 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
988 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
989 ## @missing: 0000..10FFFF; cjkIICore; <none>
990 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
991 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
992 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
993 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
994 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
995 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
996 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
997 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
998 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
999 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1000 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1001 END
1002
1003 # The input files don't list every code point.  Those not listed are to be
1004 # defaulted to some value.  Below are hard-coded what those values are for
1005 # non-binary properties as of 5.1.  Starting in 5.0, there are
1006 # machine-parsable comment lines in the files the give the defaults; so this
1007 # list shouldn't have to be extended.  The claim is that all missing entries
1008 # for binary properties will default to 'N'.  Unicode tried to change that in
1009 # 5.2, but the beta period produced enough protest that they backed off.
1010 #
1011 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1012 # be in the form that it expects.  The others may be synonyms.
1013 my $CODE_POINT = '<code point>';
1014 my %default_mapping = (
1015     Age => "Unassigned",
1016     # Bidi_Class => Complicated; set in code
1017     Bidi_Mirroring_Glyph => "",
1018     Block => 'No_Block',
1019     Canonical_Combining_Class => 0,
1020     Case_Folding => $CODE_POINT,
1021     Decomposition_Mapping => $CODE_POINT,
1022     Decomposition_Type => 'None',
1023     East_Asian_Width => "Neutral",
1024     FC_NFKC_Closure => $CODE_POINT,
1025     General_Category => 'Cn',
1026     Grapheme_Cluster_Break => 'Other',
1027     Hangul_Syllable_Type => 'NA',
1028     ISO_Comment => "",
1029     Jamo_Short_Name => "",
1030     Joining_Group => "No_Joining_Group",
1031     # Joining_Type => Complicated; set in code
1032     kIICore => 'N',   #                       Is converted to binary
1033     #Line_Break => Complicated; set in code
1034     Lowercase_Mapping => $CODE_POINT,
1035     Name => "",
1036     Name_Alias => "",
1037     NFC_QC => 'Yes',
1038     NFD_QC => 'Yes',
1039     NFKC_QC => 'Yes',
1040     NFKD_QC => 'Yes',
1041     Numeric_Type => 'None',
1042     Numeric_Value => 'NaN',
1043     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1044     Sentence_Break => 'Other',
1045     Simple_Case_Folding => $CODE_POINT,
1046     Simple_Lowercase_Mapping => $CODE_POINT,
1047     Simple_Titlecase_Mapping => $CODE_POINT,
1048     Simple_Uppercase_Mapping => $CODE_POINT,
1049     Titlecase_Mapping => $CODE_POINT,
1050     Unicode_1_Name => "",
1051     Unicode_Radical_Stroke => "",
1052     Uppercase_Mapping => $CODE_POINT,
1053     Word_Break => 'Other',
1054 );
1055
1056 # Below are files that Unicode furnishes, but this program ignores, and why
1057 my %ignored_files = (
1058     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1059     'Index.txt' => 'Alphabetical index of Unicode characters',
1060     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1061     'NamesList.txt' => 'Annotated list of characters',
1062     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1063     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1064     'ReadMe.txt' => 'Documentation',
1065     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1066     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1067     'IndicMatraCategory.txt' => 'Provisional; for the analysis and processing of Indic scripts',
1068     'IndicSyllabicCategory.txt' => 'Provisional; for the analysis and processing of Indic scripts',
1069     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1070     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1071     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1072     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1073 );
1074
1075 ### End of externally interesting definitions, except for @input_file_objects
1076
1077 my $HEADER=<<"EOF";
1078 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1079 # This file is machine-generated by $0 from the Unicode
1080 # database, Version $string_version.  Any changes made here will be lost!
1081 EOF
1082
1083 my $INTERNAL_ONLY_HEADER = <<"EOF";
1084
1085 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1086 # This file is for internal use by core Perl only.  The format and even the
1087 # name or existence of this file are subject to change without notice.  Don't
1088 # use it directly.
1089 EOF
1090
1091 my $DEVELOPMENT_ONLY=<<"EOF";
1092 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1093 # This file contains information artificially constrained to code points
1094 # present in Unicode release $string_compare_versions.
1095 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1096 # not be used for production.
1097
1098 EOF
1099
1100 my $MAX_UNICODE_CODEPOINT_STRING = "10FFFF";
1101 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1102 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1103
1104 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1105 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1106 # to decrease backtracking.  The first regex allows the code point to be at
1107 # the end of a word, but to work properly, the word shouldn't end with a valid
1108 # hex character.  The second one won't match a code point at the end of a
1109 # word, and doesn't have the run-on issue
1110 my $run_on_code_point_re =
1111             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1112 my $code_point_re = qr/\b$run_on_code_point_re/;
1113
1114 # This matches the beginning of the line in the Unicode db files that give the
1115 # defaults for code points not listed (i.e., missing) in the file.  The code
1116 # depends on this ending with a semi-colon, so it can assume it is a valid
1117 # field when the line is split() by semi-colons
1118 my $missing_defaults_prefix =
1119             qr/^#\s+\@missing:\s+0000\.\.$MAX_UNICODE_CODEPOINT_STRING\s*;/;
1120
1121 # Property types.  Unicode has more types, but these are sufficient for our
1122 # purposes.
1123 my $UNKNOWN = -1;   # initialized to illegal value
1124 my $NON_STRING = 1; # Either binary or enum
1125 my $BINARY = 2;
1126 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1127                        # tables, additional true and false tables are
1128                        # generated so that false is anything matching the
1129                        # default value, and true is everything else.
1130 my $ENUM = 4;       # Include catalog
1131 my $STRING = 5;     # Anything else: string or misc
1132
1133 # Some input files have lines that give default values for code points not
1134 # contained in the file.  Sometimes these should be ignored.
1135 my $NO_DEFAULTS = 0;        # Must evaluate to false
1136 my $NOT_IGNORED = 1;
1137 my $IGNORED = 2;
1138
1139 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1140 # and will appear in the main body of the tables in the output files, but
1141 # there are other types of ranges as well, listed below, that are specially
1142 # handled.   There are pseudo-types as well that will never be stored as a
1143 # type, but will affect the calculation of the type.
1144
1145 # 0 is for normal, non-specials
1146 my $MULTI_CP = 1;           # Sequence of more than code point
1147 my $HANGUL_SYLLABLE = 2;
1148 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1149 my $NULL = 4;               # The map is to the null string; utf8.c can't
1150                             # handle these, nor is there an accepted syntax
1151                             # for them in \p{} constructs
1152 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1153                              # otherwise be $MULTI_CP type are instead type 0
1154
1155 # process_generic_property_file() can accept certain overrides in its input.
1156 # Each of these must begin AND end with $CMD_DELIM.
1157 my $CMD_DELIM = "\a";
1158 my $REPLACE_CMD = 'replace';    # Override the Replace
1159 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1160
1161 my $NO = 0;
1162 my $YES = 1;
1163
1164 # Values for the Replace argument to add_range.
1165 # $NO                      # Don't replace; add only the code points not
1166                            # already present.
1167 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1168                            # the comments at the subroutine definition.
1169 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1170 my $MULTIPLE = 4;          # Don't replace, but add a duplicate record if
1171                            # already there
1172 my $CROAK = 5;             # Die with an error if is already there
1173
1174 # Flags to give property statuses.  The phrases are to remind maintainers that
1175 # if the flag is changed, the indefinite article referring to it in the
1176 # documentation may need to be as well.
1177 my $NORMAL = "";
1178 my $SUPPRESSED = 'z';   # The character should never actually be seen, since
1179                         # it is suppressed
1180 my $PLACEHOLDER = 'P';  # A property that is defined as a placeholder in a
1181                         # Unicode version that doesn't have it, but we need it
1182                         # to be defined, if empty, to have things work.
1183                         # Implies no pod entry generated
1184 my $DEPRECATED = 'D';
1185 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1186 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1187 my $DISCOURAGED = 'X';
1188 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1189 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1190 my $STRICTER = 'T';
1191 my $a_bold_stricter = "a 'B<$STRICTER>'";
1192 my $A_bold_stricter = "A 'B<$STRICTER>'";
1193 my $STABILIZED = 'S';
1194 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1195 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1196 my $OBSOLETE = 'O';
1197 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1198 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1199
1200 my %status_past_participles = (
1201     $DISCOURAGED => 'discouraged',
1202     $SUPPRESSED => 'should never be generated',
1203     $STABILIZED => 'stabilized',
1204     $OBSOLETE => 'obsolete',
1205     $DEPRECATED => 'deprecated',
1206 );
1207
1208 # The format of the values of the tables:
1209 my $EMPTY_FORMAT = "";
1210 my $BINARY_FORMAT = 'b';
1211 my $DECIMAL_FORMAT = 'd';
1212 my $FLOAT_FORMAT = 'f';
1213 my $INTEGER_FORMAT = 'i';
1214 my $HEX_FORMAT = 'x';
1215 my $RATIONAL_FORMAT = 'r';
1216 my $STRING_FORMAT = 's';
1217 my $DECOMP_STRING_FORMAT = 'c';
1218 my $STRING_WHITE_SPACE_LIST = 'sw';
1219
1220 my %map_table_formats = (
1221     $BINARY_FORMAT => 'binary',
1222     $DECIMAL_FORMAT => 'single decimal digit',
1223     $FLOAT_FORMAT => 'floating point number',
1224     $INTEGER_FORMAT => 'integer',
1225     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1226     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1227     $STRING_FORMAT => 'string',
1228     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1229     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1230 );
1231
1232 # Unicode didn't put such derived files in a separate directory at first.
1233 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1234 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1235 my $AUXILIARY = 'auxiliary';
1236
1237 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1238 my %loose_to_file_of;       # loosely maps table names to their respective
1239                             # files
1240 my %stricter_to_file_of;    # same; but for stricter mapping.
1241 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1242                              # their rational equivalent
1243 my %loose_property_name_of; # Loosely maps (non_string) property names to
1244                             # standard form
1245
1246 # Most properties are immune to caseless matching, otherwise you would get
1247 # nonsensical results, as properties are a function of a code point, not
1248 # everything that is caselessly equivalent to that code point.  For example,
1249 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1250 # be true because 's' and 'S' are equivalent caselessly.  However,
1251 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1252 # extend that concept to those very few properties that are like this.  Each
1253 # such property will match the full range caselessly.  They are hard-coded in
1254 # the program; it's not worth trying to make it general as it's extremely
1255 # unlikely that they will ever change.
1256 my %caseless_equivalent_to;
1257
1258 # These constants names and values were taken from the Unicode standard,
1259 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1260 # syllables.  The '_string' versions are so generated tables can retain the
1261 # hex format, which is the more familiar value
1262 my $SBase_string = "0xAC00";
1263 my $SBase = CORE::hex $SBase_string;
1264 my $LBase_string = "0x1100";
1265 my $LBase = CORE::hex $LBase_string;
1266 my $VBase_string = "0x1161";
1267 my $VBase = CORE::hex $VBase_string;
1268 my $TBase_string = "0x11A7";
1269 my $TBase = CORE::hex $TBase_string;
1270 my $SCount = 11172;
1271 my $LCount = 19;
1272 my $VCount = 21;
1273 my $TCount = 28;
1274 my $NCount = $VCount * $TCount;
1275
1276 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1277 # with the above published constants.
1278 my %Jamo;
1279 my %Jamo_L;     # Leading consonants
1280 my %Jamo_V;     # Vowels
1281 my %Jamo_T;     # Trailing consonants
1282
1283 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1284 # The key is the base name of the code point, and the value is an
1285 # array giving all the ranges that use this base name.  Each range
1286 # is actually a hash giving the 'low' and 'high' values of it.
1287 my %names_ending_in_code_point;
1288 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1289                                         # removed from the names
1290 # Inverse mapping.  The list of ranges that have these kinds of
1291 # names.  Each element contains the low, high, and base names in an
1292 # anonymous hash.
1293 my @code_points_ending_in_code_point;
1294
1295 # Boolean: does this Unicode version have the hangul syllables, and are we
1296 # writing out a table for them?
1297 my $has_hangul_syllables = 0;
1298
1299 # Does this Unicode version have code points whose names end in their
1300 # respective code points, and are we writing out a table for them?  0 for no;
1301 # otherwise points to first property that a table is needed for them, so that
1302 # if multiple tables are needed, we don't create duplicates
1303 my $needing_code_points_ending_in_code_point = 0;
1304
1305 my @backslash_X_tests;     # List of tests read in for testing \X
1306 my @unhandled_properties;  # Will contain a list of properties found in
1307                            # the input that we didn't process.
1308 my @match_properties;      # Properties that have match tables, to be
1309                            # listed in the pod
1310 my @map_properties;        # Properties that get map files written
1311 my @named_sequences;       # NamedSequences.txt contents.
1312 my %potential_files;       # Generated list of all .txt files in the directory
1313                            # structure so we can warn if something is being
1314                            # ignored.
1315 my @files_actually_output; # List of files we generated.
1316 my @more_Names;            # Some code point names are compound; this is used
1317                            # to store the extra components of them.
1318 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1319                            # the minimum before we consider it equivalent to a
1320                            # candidate rational
1321 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1322
1323 # These store references to certain commonly used property objects
1324 my $gc;
1325 my $perl;
1326 my $block;
1327 my $perl_charname;
1328 my $print;
1329 my $Any;
1330 my $script;
1331
1332 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1333 my $has_In_conflicts = 0;
1334 my $has_Is_conflicts = 0;
1335
1336 sub internal_file_to_platform ($) {
1337     # Convert our file paths which have '/' separators to those of the
1338     # platform.
1339
1340     my $file = shift;
1341     return undef unless defined $file;
1342
1343     return File::Spec->join(split '/', $file);
1344 }
1345
1346 sub file_exists ($) {   # platform independent '-e'.  This program internally
1347                         # uses slash as a path separator.
1348     my $file = shift;
1349     return 0 if ! defined $file;
1350     return -e internal_file_to_platform($file);
1351 }
1352
1353 sub objaddr($) {
1354     # Returns the address of the blessed input object.
1355     # It doesn't check for blessedness because that would do a string eval
1356     # every call, and the program is structured so that this is never called
1357     # for a non-blessed object.
1358
1359     no overloading; # If overloaded, numifying below won't work.
1360
1361     # Numifying a ref gives its address.
1362     return pack 'J', $_[0];
1363 }
1364
1365 # These are used only if $annotate is true.
1366 # The entire range of Unicode characters is examined to populate these
1367 # after all the input has been processed.  But most can be skipped, as they
1368 # have the same descriptive phrases, such as being unassigned
1369 my @viacode;            # Contains the 1 million character names
1370 my @printable;          # boolean: And are those characters printable?
1371 my @annotate_char_type; # Contains a type of those characters, specifically
1372                         # for the purposes of annotation.
1373 my $annotate_ranges;    # A map of ranges of code points that have the same
1374                         # name for the purposes of annotation.  They map to the
1375                         # upper edge of the range, so that the end point can
1376                         # be immediately found.  This is used to skip ahead to
1377                         # the end of a range, and avoid processing each
1378                         # individual code point in it.
1379 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1380                                    # characters, but excluding those which are
1381                                    # also noncharacter code points
1382
1383 # The annotation types are an extension of the regular range types, though
1384 # some of the latter are folded into one.  Make the new types negative to
1385 # avoid conflicting with the regular types
1386 my $SURROGATE_TYPE = -1;
1387 my $UNASSIGNED_TYPE = -2;
1388 my $PRIVATE_USE_TYPE = -3;
1389 my $NONCHARACTER_TYPE = -4;
1390 my $CONTROL_TYPE = -5;
1391 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1392
1393 sub populate_char_info ($) {
1394     # Used only with the $annotate option.  Populates the arrays with the
1395     # input code point's info that are needed for outputting more detailed
1396     # comments.  If calling context wants a return, it is the end point of
1397     # any contiguous range of characters that share essentially the same info
1398
1399     my $i = shift;
1400     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1401
1402     $viacode[$i] = $perl_charname->value_of($i) || "";
1403
1404     # A character is generally printable if Unicode says it is,
1405     # but below we make sure that most Unicode general category 'C' types
1406     # aren't.
1407     $printable[$i] = $print->contains($i);
1408
1409     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1410
1411     # Only these two regular types are treated specially for annotations
1412     # purposes
1413     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1414                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1415
1416     # Give a generic name to all code points that don't have a real name.
1417     # We output ranges, if applicable, for these.  Also calculate the end
1418     # point of the range.
1419     my $end;
1420     if (! $viacode[$i]) {
1421         if ($gc-> table('Surrogate')->contains($i)) {
1422             $viacode[$i] = 'Surrogate';
1423             $annotate_char_type[$i] = $SURROGATE_TYPE;
1424             $printable[$i] = 0;
1425             $end = $gc->table('Surrogate')->containing_range($i)->end;
1426         }
1427         elsif ($gc-> table('Private_use')->contains($i)) {
1428             $viacode[$i] = 'Private Use';
1429             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1430             $printable[$i] = 0;
1431             $end = $gc->table('Private_Use')->containing_range($i)->end;
1432         }
1433         elsif (Property::property_ref('Noncharacter_Code_Point')-> table('Y')->
1434                                                                 contains($i))
1435         {
1436             $viacode[$i] = 'Noncharacter';
1437             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1438             $printable[$i] = 0;
1439             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1440                                                     containing_range($i)->end;
1441         }
1442         elsif ($gc-> table('Control')->contains($i)) {
1443             $viacode[$i] = 'Control';
1444             $annotate_char_type[$i] = $CONTROL_TYPE;
1445             $printable[$i] = 0;
1446             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1447         }
1448         elsif ($gc-> table('Unassigned')->contains($i)) {
1449             $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1450             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1451             $printable[$i] = 0;
1452
1453             # Because we name the unassigned by the blocks they are in, it
1454             # can't go past the end of that block, and it also can't go past
1455             # the unassigned range it is in.  The special table makes sure
1456             # that the non-characters, which are unassigned, are separated
1457             # out.
1458             $end = min($block->containing_range($i)->end,
1459                        $unassigned_sans_noncharacters-> containing_range($i)->
1460                                                                          end);
1461         }
1462         else {
1463             Carp::my_carp_bug("Can't figure out how to annotate "
1464                               . sprintf("U+%04X", $i)
1465                               . ".  Proceeding anyway.");
1466             $viacode[$i] = 'UNKNOWN';
1467             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1468             $printable[$i] = 0;
1469         }
1470     }
1471
1472     # Here, has a name, but if it's one in which the code point number is
1473     # appended to the name, do that.
1474     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1475         $viacode[$i] .= sprintf("-%04X", $i);
1476         $end = $perl_charname->containing_range($i)->end;
1477     }
1478
1479     # And here, has a name, but if it's a hangul syllable one, replace it with
1480     # the correct name from the Unicode algorithm
1481     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1482         use integer;
1483         my $SIndex = $i - $SBase;
1484         my $L = $LBase + $SIndex / $NCount;
1485         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1486         my $T = $TBase + $SIndex % $TCount;
1487         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1488         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1489         $end = $perl_charname->containing_range($i)->end;
1490     }
1491
1492     return if ! defined wantarray;
1493     return $i if ! defined $end;    # If not a range, return the input
1494
1495     # Save this whole range so can find the end point quickly
1496     $annotate_ranges->add_map($i, $end, $end);
1497
1498     return $end;
1499 }
1500
1501 # Commented code below should work on Perl 5.8.
1502 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1503 ## the native perl version of it (which is what would operate under miniperl)
1504 ## is extremely slow, as it does a string eval every call.
1505 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1506 #                            && defined eval "require Scalar::Util";
1507 #
1508 #sub objaddr($) {
1509 #    # Returns the address of the blessed input object.  Uses the XS version if
1510 #    # available.  It doesn't check for blessedness because that would do a
1511 #    # string eval every call, and the program is structured so that this is
1512 #    # never called for a non-blessed object.
1513 #
1514 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1515 #
1516 #    # Check at least that is a ref.
1517 #    my $pkg = ref($_[0]) or return undef;
1518 #
1519 #    # Change to a fake package to defeat any overloaded stringify
1520 #    bless $_[0], 'main::Fake';
1521 #
1522 #    # Numifying a ref gives its address.
1523 #    my $addr = pack 'J', $_[0];
1524 #
1525 #    # Return to original class
1526 #    bless $_[0], $pkg;
1527 #    return $addr;
1528 #}
1529
1530 sub max ($$) {
1531     my $a = shift;
1532     my $b = shift;
1533     return $a if $a >= $b;
1534     return $b;
1535 }
1536
1537 sub min ($$) {
1538     my $a = shift;
1539     my $b = shift;
1540     return $a if $a <= $b;
1541     return $b;
1542 }
1543
1544 sub clarify_number ($) {
1545     # This returns the input number with underscores inserted every 3 digits
1546     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1547     # checked.
1548
1549     my $number = shift;
1550     my $pos = length($number) - 3;
1551     return $number if $pos <= 1;
1552     while ($pos > 0) {
1553         substr($number, $pos, 0) = '_';
1554         $pos -= 3;
1555     }
1556     return $number;
1557 }
1558
1559
1560 package Carp;
1561
1562 # These routines give a uniform treatment of messages in this program.  They
1563 # are placed in the Carp package to cause the stack trace to not include them,
1564 # although an alternative would be to use another package and set @CARP_NOT
1565 # for it.
1566
1567 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1568
1569 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1570 # and overload trying to load Scalar:Util under miniperl.  See
1571 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1572 undef $overload::VERSION;
1573
1574 sub my_carp {
1575     my $message = shift || "";
1576     my $nofold = shift || 0;
1577
1578     if ($message) {
1579         $message = main::join_lines($message);
1580         $message =~ s/^$0: *//;     # Remove initial program name
1581         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1582         $message = "\n$0: $message;";
1583
1584         # Fold the message with program name, semi-colon end punctuation
1585         # (which looks good with the message that carp appends to it), and a
1586         # hanging indent for continuation lines.
1587         $message = main::simple_fold($message, "", 4) unless $nofold;
1588         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1589                                     # appends is to the same line
1590     }
1591
1592     return $message if defined wantarray;   # If a caller just wants the msg
1593
1594     carp $message;
1595     return;
1596 }
1597
1598 sub my_carp_bug {
1599     # This is called when it is clear that the problem is caused by a bug in
1600     # this program.
1601
1602     my $message = shift;
1603     $message =~ s/^$0: *//;
1604     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1605     carp $message;
1606     return;
1607 }
1608
1609 sub carp_too_few_args {
1610     if (@_ != 2) {
1611         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1612         return;
1613     }
1614
1615     my $args_ref = shift;
1616     my $count = shift;
1617
1618     my_carp_bug("Need at least $count arguments to "
1619         . (caller 1)[3]
1620         . ".  Instead got: '"
1621         . join ', ', @$args_ref
1622         . "'.  No action taken.");
1623     return;
1624 }
1625
1626 sub carp_extra_args {
1627     my $args_ref = shift;
1628     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1629
1630     unless (ref $args_ref) {
1631         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1632         return;
1633     }
1634     my ($package, $file, $line) = caller;
1635     my $subroutine = (caller 1)[3];
1636
1637     my $list;
1638     if (ref $args_ref eq 'HASH') {
1639         foreach my $key (keys %$args_ref) {
1640             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1641         }
1642         $list = join ', ', each %{$args_ref};
1643     }
1644     elsif (ref $args_ref eq 'ARRAY') {
1645         foreach my $arg (@$args_ref) {
1646             $arg = $UNDEF unless defined $arg;
1647         }
1648         $list = join ', ', @$args_ref;
1649     }
1650     else {
1651         my_carp_bug("Can't cope with ref "
1652                 . ref($args_ref)
1653                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1654         return;
1655     }
1656
1657     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1658     return;
1659 }
1660
1661 package main;
1662
1663 { # Closure
1664
1665     # This program uses the inside-out method for objects, as recommended in
1666     # "Perl Best Practices".  This closure aids in generating those.  There
1667     # are two routines.  setup_package() is called once per package to set
1668     # things up, and then set_access() is called for each hash representing a
1669     # field in the object.  These routines arrange for the object to be
1670     # properly destroyed when no longer used, and for standard accessor
1671     # functions to be generated.  If you need more complex accessors, just
1672     # write your own and leave those accesses out of the call to set_access().
1673     # More details below.
1674
1675     my %constructor_fields; # fields that are to be used in constructors; see
1676                             # below
1677
1678     # The values of this hash will be the package names as keys to other
1679     # hashes containing the name of each field in the package as keys, and
1680     # references to their respective hashes as values.
1681     my %package_fields;
1682
1683     sub setup_package {
1684         # Sets up the package, creating standard DESTROY and dump methods
1685         # (unless already defined).  The dump method is used in debugging by
1686         # simple_dumper().
1687         # The optional parameters are:
1688         #   a)  a reference to a hash, that gets populated by later
1689         #       set_access() calls with one of the accesses being
1690         #       'constructor'.  The caller can then refer to this, but it is
1691         #       not otherwise used by these two routines.
1692         #   b)  a reference to a callback routine to call during destruction
1693         #       of the object, before any fields are actually destroyed
1694
1695         my %args = @_;
1696         my $constructor_ref = delete $args{'Constructor_Fields'};
1697         my $destroy_callback = delete $args{'Destroy_Callback'};
1698         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1699
1700         my %fields;
1701         my $package = (caller)[0];
1702
1703         $package_fields{$package} = \%fields;
1704         $constructor_fields{$package} = $constructor_ref;
1705
1706         unless ($package->can('DESTROY')) {
1707             my $destroy_name = "${package}::DESTROY";
1708             no strict "refs";
1709
1710             # Use typeglob to give the anonymous subroutine the name we want
1711             *$destroy_name = sub {
1712                 my $self = shift;
1713                 my $addr = do { no overloading; pack 'J', $self; };
1714
1715                 $self->$destroy_callback if $destroy_callback;
1716                 foreach my $field (keys %{$package_fields{$package}}) {
1717                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1718                     delete $package_fields{$package}{$field}{$addr};
1719                 }
1720                 return;
1721             }
1722         }
1723
1724         unless ($package->can('dump')) {
1725             my $dump_name = "${package}::dump";
1726             no strict "refs";
1727             *$dump_name = sub {
1728                 my $self = shift;
1729                 return dump_inside_out($self, $package_fields{$package}, @_);
1730             }
1731         }
1732         return;
1733     }
1734
1735     sub set_access {
1736         # Arrange for the input field to be garbage collected when no longer
1737         # needed.  Also, creates standard accessor functions for the field
1738         # based on the optional parameters-- none if none of these parameters:
1739         #   'addable'    creates an 'add_NAME()' accessor function.
1740         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1741         #                function.
1742         #   'settable'   creates a 'set_NAME()' accessor function.
1743         #   'constructor' doesn't create an accessor function, but adds the
1744         #                field to the hash that was previously passed to
1745         #                setup_package();
1746         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1747         # 'add' etc. all mean 'addable'.
1748         # The read accessor function will work on both array and scalar
1749         # values.  If another accessor in the parameter list is 'a', the read
1750         # access assumes an array.  You can also force it to be array access
1751         # by specifying 'readable_array' instead of 'readable'
1752         #
1753         # A sort-of 'protected' access can be set-up by preceding the addable,
1754         # readable or settable with some initial portion of 'protected_' (but,
1755         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1756         # "protection" is only by convention.  All that happens is that the
1757         # accessor functions' names begin with an underscore.  So instead of
1758         # calling set_foo, the call is _set_foo.  (Real protection could be
1759         # accomplished by having a new subroutine, end_package, called at the
1760         # end of each package, and then storing the __LINE__ ranges and
1761         # checking them on every accessor.  But that is way overkill.)
1762
1763         # We create anonymous subroutines as the accessors and then use
1764         # typeglobs to assign them to the proper package and name
1765
1766         my $name = shift;   # Name of the field
1767         my $field = shift;  # Reference to the inside-out hash containing the
1768                             # field
1769
1770         my $package = (caller)[0];
1771
1772         if (! exists $package_fields{$package}) {
1773             croak "$0: Must call 'setup_package' before 'set_access'";
1774         }
1775
1776         # Stash the field so DESTROY can get it.
1777         $package_fields{$package}{$name} = $field;
1778
1779         # Remaining arguments are the accessors.  For each...
1780         foreach my $access (@_) {
1781             my $access = lc $access;
1782
1783             my $protected = "";
1784
1785             # Match the input as far as it goes.
1786             if ($access =~ /^(p[^_]*)_/) {
1787                 $protected = $1;
1788                 if (substr('protected_', 0, length $protected)
1789                     eq $protected)
1790                 {
1791
1792                     # Add 1 for the underscore not included in $protected
1793                     $access = substr($access, length($protected) + 1);
1794                     $protected = '_';
1795                 }
1796                 else {
1797                     $protected = "";
1798                 }
1799             }
1800
1801             if (substr('addable', 0, length $access) eq $access) {
1802                 my $subname = "${package}::${protected}add_$name";
1803                 no strict "refs";
1804
1805                 # add_ accessor.  Don't add if already there, which we
1806                 # determine using 'eq' for scalars and '==' otherwise.
1807                 *$subname = sub {
1808                     use strict "refs";
1809                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1810                     my $self = shift;
1811                     my $value = shift;
1812                     my $addr = do { no overloading; pack 'J', $self; };
1813                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1814                     if (ref $value) {
1815                         return if grep { $value == $_ } @{$field->{$addr}};
1816                     }
1817                     else {
1818                         return if grep { $value eq $_ } @{$field->{$addr}};
1819                     }
1820                     push @{$field->{$addr}}, $value;
1821                     return;
1822                 }
1823             }
1824             elsif (substr('constructor', 0, length $access) eq $access) {
1825                 if ($protected) {
1826                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1827                 }
1828                 else {
1829                     $constructor_fields{$package}{$name} = $field;
1830                 }
1831             }
1832             elsif (substr('readable_array', 0, length $access) eq $access) {
1833
1834                 # Here has read access.  If one of the other parameters for
1835                 # access is array, or this one specifies array (by being more
1836                 # than just 'readable_'), then create a subroutine that
1837                 # assumes the data is an array.  Otherwise just a scalar
1838                 my $subname = "${package}::${protected}$name";
1839                 if (grep { /^a/i } @_
1840                     or length($access) > length('readable_'))
1841                 {
1842                     no strict "refs";
1843                     *$subname = sub {
1844                         use strict "refs";
1845                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1846                         my $addr = do { no overloading; pack 'J', $_[0]; };
1847                         if (ref $field->{$addr} ne 'ARRAY') {
1848                             my $type = ref $field->{$addr};
1849                             $type = 'scalar' unless $type;
1850                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1851                             return;
1852                         }
1853                         return scalar @{$field->{$addr}} unless wantarray;
1854
1855                         # Make a copy; had problems with caller modifying the
1856                         # original otherwise
1857                         my @return = @{$field->{$addr}};
1858                         return @return;
1859                     }
1860                 }
1861                 else {
1862
1863                     # Here not an array value, a simpler function.
1864                     no strict "refs";
1865                     *$subname = sub {
1866                         use strict "refs";
1867                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1868                         no overloading;
1869                         return $field->{pack 'J', $_[0]};
1870                     }
1871                 }
1872             }
1873             elsif (substr('settable', 0, length $access) eq $access) {
1874                 my $subname = "${package}::${protected}set_$name";
1875                 no strict "refs";
1876                 *$subname = sub {
1877                     use strict "refs";
1878                     if (main::DEBUG) {
1879                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1880                         Carp::carp_extra_args(\@_) if @_ > 2;
1881                     }
1882                     # $self is $_[0]; $value is $_[1]
1883                     no overloading;
1884                     $field->{pack 'J', $_[0]} = $_[1];
1885                     return;
1886                 }
1887             }
1888             else {
1889                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1890             }
1891         }
1892         return;
1893     }
1894 }
1895
1896 package Input_file;
1897
1898 # All input files use this object, which stores various attributes about them,
1899 # and provides for convenient, uniform handling.  The run method wraps the
1900 # processing.  It handles all the bookkeeping of opening, reading, and closing
1901 # the file, returning only significant input lines.
1902 #
1903 # Each object gets a handler which processes the body of the file, and is
1904 # called by run().  Most should use the generic, default handler, which has
1905 # code scrubbed to handle things you might not expect.  A handler should
1906 # basically be a while(next_line()) {...} loop.
1907 #
1908 # You can also set up handlers to
1909 #   1) call before the first line is read for pre processing
1910 #   2) call to adjust each line of the input before the main handler gets them
1911 #   3) call upon EOF before the main handler exits its loop
1912 #   4) call at the end for post processing
1913 #
1914 # $_ is used to store the input line, and is to be filtered by the
1915 # each_line_handler()s.  So, if the format of the line is not in the desired
1916 # format for the main handler, these are used to do that adjusting.  They can
1917 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1918 # so the $_ output of one is used as the input to the next.  None of the other
1919 # handlers are stackable, but could easily be changed to be so.
1920 #
1921 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1922 # which insert the parameters as lines to be processed before the next input
1923 # file line is read.  This allows the EOF handler to flush buffers, for
1924 # example.  The difference between the two routines is that the lines inserted
1925 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1926 # called it from such a handler, you would get infinite recursion.)  Lines
1927 # inserted by insert_adjusted_lines() go directly to the main handler without
1928 # any adjustments.  If the  post-processing handler calls any of these, there
1929 # will be no effect.  Some error checking for these conditions could be added,
1930 # but it hasn't been done.
1931 #
1932 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1933 # to prevent further processing of the line.  This routine will output the
1934 # message as a warning once, and then keep a count of the lines that have the
1935 # same message, and output that count at the end of the file's processing.
1936 # This keeps the number of messages down to a manageable amount.
1937 #
1938 # get_missings() should be called to retrieve any @missing input lines.
1939 # Messages will be raised if this isn't done if the options aren't to ignore
1940 # missings.
1941
1942 sub trace { return main::trace(@_); }
1943
1944 { # Closure
1945     # Keep track of fields that are to be put into the constructor.
1946     my %constructor_fields;
1947
1948     main::setup_package(Constructor_Fields => \%constructor_fields);
1949
1950     my %file; # Input file name, required
1951     main::set_access('file', \%file, qw{ c r });
1952
1953     my %first_released; # Unicode version file was first released in, required
1954     main::set_access('first_released', \%first_released, qw{ c r });
1955
1956     my %handler;    # Subroutine to process the input file, defaults to
1957                     # 'process_generic_property_file'
1958     main::set_access('handler', \%handler, qw{ c });
1959
1960     my %property;
1961     # name of property this file is for.  defaults to none, meaning not
1962     # applicable, or is otherwise determinable, for example, from each line.
1963     main::set_access('property', \%property, qw{ c });
1964
1965     my %optional;
1966     # If this is true, the file is optional.  If not present, no warning is
1967     # output.  If it is present, the string given by this parameter is
1968     # evaluated, and if false the file is not processed.
1969     main::set_access('optional', \%optional, 'c', 'r');
1970
1971     my %non_skip;
1972     # This is used for debugging, to skip processing of all but a few input
1973     # files.  Add 'non_skip => 1' to the constructor for those files you want
1974     # processed when you set the $debug_skip global.
1975     main::set_access('non_skip', \%non_skip, 'c');
1976
1977     my %skip;
1978     # This is used to skip processing of this input file semi-permanently,
1979     # when it evaluates to true.  The value should be the reason the file is
1980     # being skipped.  It is used for files that we aren't planning to process
1981     # anytime soon, but want to allow to be in the directory and not raise a
1982     # message that we are not handling.  Mostly for test files.  This is in
1983     # contrast to the non_skip element, which is supposed to be used very
1984     # temporarily for debugging.  Sets 'optional' to 1.  Also, files that we
1985     # pretty much will never look at can be placed in the global
1986     # %ignored_files instead.  Ones used here will be added to that list.
1987     main::set_access('skip', \%skip, 'c');
1988
1989     my %each_line_handler;
1990     # list of subroutines to look at and filter each non-comment line in the
1991     # file.  defaults to none.  The subroutines are called in order, each is
1992     # to adjust $_ for the next one, and the final one adjusts it for
1993     # 'handler'
1994     main::set_access('each_line_handler', \%each_line_handler, 'c');
1995
1996     my %has_missings_defaults;
1997     # ? Are there lines in the file giving default values for code points
1998     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
1999     # the norm, but IGNORED means it has such lines, but the handler doesn't
2000     # use them.  Having these three states allows us to catch changes to the
2001     # UCD that this program should track
2002     main::set_access('has_missings_defaults',
2003                                         \%has_missings_defaults, qw{ c r });
2004
2005     my %pre_handler;
2006     # Subroutine to call before doing anything else in the file.  If undef, no
2007     # such handler is called.
2008     main::set_access('pre_handler', \%pre_handler, qw{ c });
2009
2010     my %eof_handler;
2011     # Subroutine to call upon getting an EOF on the input file, but before
2012     # that is returned to the main handler.  This is to allow buffers to be
2013     # flushed.  The handler is expected to call insert_lines() or
2014     # insert_adjusted() with the buffered material
2015     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2016
2017     my %post_handler;
2018     # Subroutine to call after all the lines of the file are read in and
2019     # processed.  If undef, no such handler is called.
2020     main::set_access('post_handler', \%post_handler, qw{ c });
2021
2022     my %progress_message;
2023     # Message to print to display progress in lieu of the standard one
2024     main::set_access('progress_message', \%progress_message, qw{ c });
2025
2026     my %handle;
2027     # cache open file handle, internal.  Is undef if file hasn't been
2028     # processed at all, empty if has;
2029     main::set_access('handle', \%handle);
2030
2031     my %added_lines;
2032     # cache of lines added virtually to the file, internal
2033     main::set_access('added_lines', \%added_lines);
2034
2035     my %errors;
2036     # cache of errors found, internal
2037     main::set_access('errors', \%errors);
2038
2039     my %missings;
2040     # storage of '@missing' defaults lines
2041     main::set_access('missings', \%missings);
2042
2043     sub new {
2044         my $class = shift;
2045
2046         my $self = bless \do{ my $anonymous_scalar }, $class;
2047         my $addr = do { no overloading; pack 'J', $self; };
2048
2049         # Set defaults
2050         $handler{$addr} = \&main::process_generic_property_file;
2051         $non_skip{$addr} = 0;
2052         $skip{$addr} = 0;
2053         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2054         $handle{$addr} = undef;
2055         $added_lines{$addr} = [ ];
2056         $each_line_handler{$addr} = [ ];
2057         $errors{$addr} = { };
2058         $missings{$addr} = [ ];
2059
2060         # Two positional parameters.
2061         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2062         $file{$addr} = main::internal_file_to_platform(shift);
2063         $first_released{$addr} = shift;
2064
2065         # The rest of the arguments are key => value pairs
2066         # %constructor_fields has been set up earlier to list all possible
2067         # ones.  Either set or push, depending on how the default has been set
2068         # up just above.
2069         my %args = @_;
2070         foreach my $key (keys %args) {
2071             my $argument = $args{$key};
2072
2073             # Note that the fields are the lower case of the constructor keys
2074             my $hash = $constructor_fields{lc $key};
2075             if (! defined $hash) {
2076                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2077                 next;
2078             }
2079             if (ref $hash->{$addr} eq 'ARRAY') {
2080                 if (ref $argument eq 'ARRAY') {
2081                     foreach my $argument (@{$argument}) {
2082                         next if ! defined $argument;
2083                         push @{$hash->{$addr}}, $argument;
2084                     }
2085                 }
2086                 else {
2087                     push @{$hash->{$addr}}, $argument if defined $argument;
2088                 }
2089             }
2090             else {
2091                 $hash->{$addr} = $argument;
2092             }
2093             delete $args{$key};
2094         };
2095
2096         # If the file has a property for it, it means that the property is not
2097         # listed in the file's entries.  So add a handler to the list of line
2098         # handlers to insert the property name into the lines, to provide a
2099         # uniform interface to the final processing subroutine.
2100         # the final code doesn't have to worry about that.
2101         if ($property{$addr}) {
2102             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2103         }
2104
2105         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2106             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2107         }
2108
2109         # If skipping, set to optional, and add to list of ignored files,
2110         # including its reason
2111         if ($skip{$addr}) {
2112             $optional{$addr} = 1;
2113             $ignored_files{$file{$addr}} = $skip{$addr}
2114         }
2115
2116         return $self;
2117     }
2118
2119
2120     use overload
2121         fallback => 0,
2122         qw("") => "_operator_stringify",
2123         "." => \&main::_operator_dot,
2124     ;
2125
2126     sub _operator_stringify {
2127         my $self = shift;
2128
2129         return __PACKAGE__ . " object for " . $self->file;
2130     }
2131
2132     # flag to make sure extracted files are processed early
2133     my $seen_non_extracted_non_age = 0;
2134
2135     sub run {
2136         # Process the input object $self.  This opens and closes the file and
2137         # calls all the handlers for it.  Currently,  this can only be called
2138         # once per file, as it destroy's the EOF handler
2139
2140         my $self = shift;
2141         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2142
2143         my $addr = do { no overloading; pack 'J', $self; };
2144
2145         my $file = $file{$addr};
2146
2147         # Don't process if not expecting this file (because released later
2148         # than this Unicode version), and isn't there.  This means if someone
2149         # copies it into an earlier version's directory, we will go ahead and
2150         # process it.
2151         return if $first_released{$addr} gt $v_version && ! -e $file;
2152
2153         # If in debugging mode and this file doesn't have the non-skip
2154         # flag set, and isn't one of the critical files, skip it.
2155         if ($debug_skip
2156             && $first_released{$addr} ne v0
2157             && ! $non_skip{$addr})
2158         {
2159             print "Skipping $file in debugging\n" if $verbosity;
2160             return;
2161         }
2162
2163         # File could be optional
2164         if ($optional{$addr}) {
2165             return unless -e $file;
2166             my $result = eval $optional{$addr};
2167             if (! defined $result) {
2168                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2169                 return;
2170             }
2171             if (! $result) {
2172                 if ($verbosity) {
2173                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2174                 }
2175                 return;
2176             }
2177         }
2178
2179         if (! defined $file || ! -e $file) {
2180
2181             # If the file doesn't exist, see if have internal data for it
2182             # (based on first_released being 0).
2183             if ($first_released{$addr} eq v0) {
2184                 $handle{$addr} = 'pretend_is_open';
2185             }
2186             else {
2187                 if (! $optional{$addr}  # File could be optional
2188                     && $v_version ge $first_released{$addr})
2189                 {
2190                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2191                 }
2192                 return;
2193             }
2194         }
2195         else {
2196
2197             # Here, the file exists.  Some platforms may change the case of
2198             # its name
2199             if ($seen_non_extracted_non_age) {
2200                 if ($file =~ /$EXTRACTED/i) {
2201                     Carp::my_carp_bug(join_lines(<<END
2202 $file should be processed just after the 'Prop...Alias' files, and before
2203 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2204 have subtle problems
2205 END
2206                     ));
2207                 }
2208             }
2209             elsif ($EXTRACTED_DIR
2210                     && $first_released{$addr} ne v0
2211                     && $file !~ /$EXTRACTED/i
2212                     && lc($file) ne 'dage.txt')
2213             {
2214                 # We don't set this (by the 'if' above) if we have no
2215                 # extracted directory, so if running on an early version,
2216                 # this test won't work.  Not worth worrying about.
2217                 $seen_non_extracted_non_age = 1;
2218             }
2219
2220             # And mark the file as having being processed, and warn if it
2221             # isn't a file we are expecting.  As we process the files,
2222             # they are deleted from the hash, so any that remain at the
2223             # end of the program are files that we didn't process.
2224             my $fkey = File::Spec->rel2abs($file);
2225             my $expecting = delete $potential_files{$fkey};
2226             $expecting = delete $potential_files{lc($fkey)} unless defined $expecting;
2227             Carp::my_carp("Was not expecting '$file'.") if
2228                     ! $expecting
2229                     && ! defined $handle{$addr};
2230
2231             # Having deleted from expected files, we can quit if not to do
2232             # anything.  Don't print progress unless really want verbosity
2233             if ($skip{$addr}) {
2234                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2235                 return;
2236             }
2237
2238             # Open the file, converting the slashes used in this program
2239             # into the proper form for the OS
2240             my $file_handle;
2241             if (not open $file_handle, "<", $file) {
2242                 Carp::my_carp("Can't open $file.  Skipping: $!");
2243                 return 0;
2244             }
2245             $handle{$addr} = $file_handle; # Cache the open file handle
2246         }
2247
2248         if ($verbosity >= $PROGRESS) {
2249             if ($progress_message{$addr}) {
2250                 print "$progress_message{$addr}\n";
2251             }
2252             else {
2253                 # If using a virtual file, say so.
2254                 print "Processing ", (-e $file)
2255                                        ? $file
2256                                        : "substitute $file",
2257                                      "\n";
2258             }
2259         }
2260
2261
2262         # Call any special handler for before the file.
2263         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2264
2265         # Then the main handler
2266         &{$handler{$addr}}($self);
2267
2268         # Then any special post-file handler.
2269         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2270
2271         # If any errors have been accumulated, output the counts (as the first
2272         # error message in each class was output when it was encountered).
2273         if ($errors{$addr}) {
2274             my $total = 0;
2275             my $types = 0;
2276             foreach my $error (keys %{$errors{$addr}}) {
2277                 $total += $errors{$addr}->{$error};
2278                 delete $errors{$addr}->{$error};
2279                 $types++;
2280             }
2281             if ($total > 1) {
2282                 my $message
2283                         = "A total of $total lines had errors in $file.  ";
2284
2285                 $message .= ($types == 1)
2286                             ? '(Only the first one was displayed.)'
2287                             : '(Only the first of each type was displayed.)';
2288                 Carp::my_carp($message);
2289             }
2290         }
2291
2292         if (@{$missings{$addr}}) {
2293             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2294         }
2295
2296         # If a real file handle, close it.
2297         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2298                                                         ref $handle{$addr};
2299         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2300                                # the file, as opposed to undef
2301         return;
2302     }
2303
2304     sub next_line {
2305         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2306         # if such a line exists.  'logical' means that any lines that have
2307         # been added via insert_lines() will be returned in $_ before the file
2308         # is read again.
2309
2310         my $self = shift;
2311         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2312
2313         my $addr = do { no overloading; pack 'J', $self; };
2314
2315         # Here the file is open (or if the handle is not a ref, is an open
2316         # 'virtual' file).  Get the next line; any inserted lines get priority
2317         # over the file itself.
2318         my $adjusted;
2319
2320         LINE:
2321         while (1) { # Loop until find non-comment, non-empty line
2322             #local $to_trace = 1 if main::DEBUG;
2323             my $inserted_ref = shift @{$added_lines{$addr}};
2324             if (defined $inserted_ref) {
2325                 ($adjusted, $_) = @{$inserted_ref};
2326                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2327                 return 1 if $adjusted;
2328             }
2329             else {
2330                 last if ! ref $handle{$addr}; # Don't read unless is real file
2331                 last if ! defined ($_ = readline $handle{$addr});
2332             }
2333             chomp;
2334             trace $_ if main::DEBUG && $to_trace;
2335
2336             # See if this line is the comment line that defines what property
2337             # value that code points that are not listed in the file should
2338             # have.  The format or existence of these lines is not guaranteed
2339             # by Unicode since they are comments, but the documentation says
2340             # that this was added for machine-readability, so probably won't
2341             # change.  This works starting in Unicode Version 5.0.  They look
2342             # like:
2343             #
2344             # @missing: 0000..10FFFF; Not_Reordered
2345             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2346             # @missing: 0000..10FFFF; ; NaN
2347             #
2348             # Save the line for a later get_missings() call.
2349             if (/$missing_defaults_prefix/) {
2350                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2351                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2352                 }
2353                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2354                     my @defaults = split /\s* ; \s*/x, $_;
2355
2356                     # The first field is the @missing, which ends in a
2357                     # semi-colon, so can safely shift.
2358                     shift @defaults;
2359
2360                     # Some of these lines may have empty field placeholders
2361                     # which get in the way.  An example is:
2362                     # @missing: 0000..10FFFF; ; NaN
2363                     # Remove them.  Process starting from the top so the
2364                     # splice doesn't affect things still to be looked at.
2365                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2366                         next if $defaults[$i] ne "";
2367                         splice @defaults, $i, 1;
2368                     }
2369
2370                     # What's left should be just the property (maybe) and the
2371                     # default.  Having only one element means it doesn't have
2372                     # the property.
2373                     my $default;
2374                     my $property;
2375                     if (@defaults >= 1) {
2376                         if (@defaults == 1) {
2377                             $default = $defaults[0];
2378                         }
2379                         else {
2380                             $property = $defaults[0];
2381                             $default = $defaults[1];
2382                         }
2383                     }
2384
2385                     if (@defaults < 1
2386                         || @defaults > 2
2387                         || ($default =~ /^</
2388                             && $default !~ /^<code *point>$/i
2389                             && $default !~ /^<none>$/i))
2390                     {
2391                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2392                     }
2393                     else {
2394
2395                         # If the property is missing from the line, it should
2396                         # be the one for the whole file
2397                         $property = $property{$addr} if ! defined $property;
2398
2399                         # Change <none> to the null string, which is what it
2400                         # really means.  If the default is the code point
2401                         # itself, set it to <code point>, which is what
2402                         # Unicode uses (but sometimes they've forgotten the
2403                         # space)
2404                         if ($default =~ /^<none>$/i) {
2405                             $default = "";
2406                         }
2407                         elsif ($default =~ /^<code *point>$/i) {
2408                             $default = $CODE_POINT;
2409                         }
2410
2411                         # Store them as a sub-arrays with both components.
2412                         push @{$missings{$addr}}, [ $default, $property ];
2413                     }
2414                 }
2415
2416                 # There is nothing for the caller to process on this comment
2417                 # line.
2418                 next;
2419             }
2420
2421             # Remove comments and trailing space, and skip this line if the
2422             # result is empty
2423             s/#.*//;
2424             s/\s+$//;
2425             next if /^$/;
2426
2427             # Call any handlers for this line, and skip further processing of
2428             # the line if the handler sets the line to null.
2429             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2430                 &{$sub_ref}($self);
2431                 next LINE if /^$/;
2432             }
2433
2434             # Here the line is ok.  return success.
2435             return 1;
2436         } # End of looping through lines.
2437
2438         # If there is an EOF handler, call it (only once) and if it generates
2439         # more lines to process go back in the loop to handle them.
2440         if ($eof_handler{$addr}) {
2441             &{$eof_handler{$addr}}($self);
2442             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2443             goto LINE if $added_lines{$addr};
2444         }
2445
2446         # Return failure -- no more lines.
2447         return 0;
2448
2449     }
2450
2451 #   Not currently used, not fully tested.
2452 #    sub peek {
2453 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2454 #        # record.  Not callable from an each_line_handler(), nor does it call
2455 #        # an each_line_handler() on the line.
2456 #
2457 #        my $self = shift;
2458 #        my $addr = do { no overloading; pack 'J', $self; };
2459 #
2460 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2461 #            my ($adjusted, $line) = @{$inserted_ref};
2462 #            next if $adjusted;
2463 #
2464 #            # Remove comments and trailing space, and return a non-empty
2465 #            # resulting line
2466 #            $line =~ s/#.*//;
2467 #            $line =~ s/\s+$//;
2468 #            return $line if $line ne "";
2469 #        }
2470 #
2471 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2472 #        while (1) { # Loop until find non-comment, non-empty line
2473 #            local $to_trace = 1 if main::DEBUG;
2474 #            trace $_ if main::DEBUG && $to_trace;
2475 #            return if ! defined (my $line = readline $handle{$addr});
2476 #            chomp $line;
2477 #            push @{$added_lines{$addr}}, [ 0, $line ];
2478 #
2479 #            $line =~ s/#.*//;
2480 #            $line =~ s/\s+$//;
2481 #            return $line if $line ne "";
2482 #        }
2483 #
2484 #        return;
2485 #    }
2486
2487
2488     sub insert_lines {
2489         # Lines can be inserted so that it looks like they were in the input
2490         # file at the place it was when this routine is called.  See also
2491         # insert_adjusted_lines().  Lines inserted via this routine go through
2492         # any each_line_handler()
2493
2494         my $self = shift;
2495
2496         # Each inserted line is an array, with the first element being 0 to
2497         # indicate that this line hasn't been adjusted, and needs to be
2498         # processed.
2499         no overloading;
2500         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2501         return;
2502     }
2503
2504     sub insert_adjusted_lines {
2505         # Lines can be inserted so that it looks like they were in the input
2506         # file at the place it was when this routine is called.  See also
2507         # insert_lines().  Lines inserted via this routine are already fully
2508         # adjusted, ready to be processed; each_line_handler()s handlers will
2509         # not be called.  This means this is not a completely general
2510         # facility, as only the last each_line_handler on the stack should
2511         # call this.  It could be made more general, by passing to each of the
2512         # line_handlers their position on the stack, which they would pass on
2513         # to this routine, and that would replace the boolean first element in
2514         # the anonymous array pushed here, so that the next_line routine could
2515         # use that to call only those handlers whose index is after it on the
2516         # stack.  But this is overkill for what is needed now.
2517
2518         my $self = shift;
2519         trace $_[0] if main::DEBUG && $to_trace;
2520
2521         # Each inserted line is an array, with the first element being 1 to
2522         # indicate that this line has been adjusted
2523         no overloading;
2524         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2525         return;
2526     }
2527
2528     sub get_missings {
2529         # Returns the stored up @missings lines' values, and clears the list.
2530         # The values are in an array, consisting of the default in the first
2531         # element, and the property in the 2nd.  However, since these lines
2532         # can be stacked up, the return is an array of all these arrays.
2533
2534         my $self = shift;
2535         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2536
2537         my $addr = do { no overloading; pack 'J', $self; };
2538
2539         # If not accepting a list return, just return the first one.
2540         return shift @{$missings{$addr}} unless wantarray;
2541
2542         my @return = @{$missings{$addr}};
2543         undef @{$missings{$addr}};
2544         return @return;
2545     }
2546
2547     sub _insert_property_into_line {
2548         # Add a property field to $_, if this file requires it.
2549
2550         my $self = shift;
2551         my $addr = do { no overloading; pack 'J', $self; };
2552         my $property = $property{$addr};
2553         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2554
2555         $_ =~ s/(;|$)/; $property$1/;
2556         return;
2557     }
2558
2559     sub carp_bad_line {
2560         # Output consistent error messages, using either a generic one, or the
2561         # one given by the optional parameter.  To avoid gazillions of the
2562         # same message in case the syntax of a  file is way off, this routine
2563         # only outputs the first instance of each message, incrementing a
2564         # count so the totals can be output at the end of the file.
2565
2566         my $self = shift;
2567         my $message = shift;
2568         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2569
2570         my $addr = do { no overloading; pack 'J', $self; };
2571
2572         $message = 'Unexpected line' unless $message;
2573
2574         # No trailing punctuation so as to fit with our addenda.
2575         $message =~ s/[.:;,]$//;
2576
2577         # If haven't seen this exact message before, output it now.  Otherwise
2578         # increment the count of how many times it has occurred
2579         unless ($errors{$addr}->{$message}) {
2580             Carp::my_carp("$message in '$_' in "
2581                             . $file{$addr}
2582                             . " at line $..  Skipping this line;");
2583             $errors{$addr}->{$message} = 1;
2584         }
2585         else {
2586             $errors{$addr}->{$message}++;
2587         }
2588
2589         # Clear the line to prevent any further (meaningful) processing of it.
2590         $_ = "";
2591
2592         return;
2593     }
2594 } # End closure
2595
2596 package Multi_Default;
2597
2598 # Certain properties in early versions of Unicode had more than one possible
2599 # default for code points missing from the files.  In these cases, one
2600 # default applies to everything left over after all the others are applied,
2601 # and for each of the others, there is a description of which class of code
2602 # points applies to it.  This object helps implement this by storing the
2603 # defaults, and for all but that final default, an eval string that generates
2604 # the class that it applies to.
2605
2606
2607 {   # Closure
2608
2609     main::setup_package();
2610
2611     my %class_defaults;
2612     # The defaults structure for the classes
2613     main::set_access('class_defaults', \%class_defaults);
2614
2615     my %other_default;
2616     # The default that applies to everything left over.
2617     main::set_access('other_default', \%other_default, 'r');
2618
2619
2620     sub new {
2621         # The constructor is called with default => eval pairs, terminated by
2622         # the left-over default. e.g.
2623         # Multi_Default->new(
2624         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2625         #               -  0x200D',
2626         #        'R' => 'some other expression that evaluates to code points',
2627         #        .
2628         #        .
2629         #        .
2630         #        'U'));
2631
2632         my $class = shift;
2633
2634         my $self = bless \do{my $anonymous_scalar}, $class;
2635         my $addr = do { no overloading; pack 'J', $self; };
2636
2637         while (@_ > 1) {
2638             my $default = shift;
2639             my $eval = shift;
2640             $class_defaults{$addr}->{$default} = $eval;
2641         }
2642
2643         $other_default{$addr} = shift;
2644
2645         return $self;
2646     }
2647
2648     sub get_next_defaults {
2649         # Iterates and returns the next class of defaults.
2650         my $self = shift;
2651         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2652
2653         my $addr = do { no overloading; pack 'J', $self; };
2654
2655         return each %{$class_defaults{$addr}};
2656     }
2657 }
2658
2659 package Alias;
2660
2661 # An alias is one of the names that a table goes by.  This class defines them
2662 # including some attributes.  Everything is currently setup in the
2663 # constructor.
2664
2665
2666 {   # Closure
2667
2668     main::setup_package();
2669
2670     my %name;
2671     main::set_access('name', \%name, 'r');
2672
2673     my %loose_match;
2674     # Should this name match loosely or not.
2675     main::set_access('loose_match', \%loose_match, 'r');
2676
2677     my %make_re_pod_entry;
2678     # Some aliases should not get their own entries in the re section of the
2679     # pod, because they are covered by a wild-card, and some we want to
2680     # discourage use of.  Binary
2681     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r');
2682
2683     my %status;
2684     # Aliases have a status, like deprecated, or even suppressed (which means
2685     # they don't appear in documentation).  Enum
2686     main::set_access('status', \%status, 'r');
2687
2688     my %externally_ok;
2689     # Similarly, some aliases should not be considered as usable ones for
2690     # external use, such as file names, or we don't want documentation to
2691     # recommend them.  Boolean
2692     main::set_access('externally_ok', \%externally_ok, 'r');
2693
2694     sub new {
2695         my $class = shift;
2696
2697         my $self = bless \do { my $anonymous_scalar }, $class;
2698         my $addr = do { no overloading; pack 'J', $self; };
2699
2700         $name{$addr} = shift;
2701         $loose_match{$addr} = shift;
2702         $make_re_pod_entry{$addr} = shift;
2703         $externally_ok{$addr} = shift;
2704         $status{$addr} = shift;
2705
2706         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2707
2708         # Null names are never ok externally
2709         $externally_ok{$addr} = 0 if $name{$addr} eq "";
2710
2711         return $self;
2712     }
2713 }
2714
2715 package Range;
2716
2717 # A range is the basic unit for storing code points, and is described in the
2718 # comments at the beginning of the program.  Each range has a starting code
2719 # point; an ending code point (not less than the starting one); a value
2720 # that applies to every code point in between the two end-points, inclusive;
2721 # and an enum type that applies to the value.  The type is for the user's
2722 # convenience, and has no meaning here, except that a non-zero type is
2723 # considered to not obey the normal Unicode rules for having standard forms.
2724 #
2725 # The same structure is used for both map and match tables, even though in the
2726 # latter, the value (and hence type) is irrelevant and could be used as a
2727 # comment.  In map tables, the value is what all the code points in the range
2728 # map to.  Type 0 values have the standardized version of the value stored as
2729 # well, so as to not have to recalculate it a lot.
2730
2731 sub trace { return main::trace(@_); }
2732
2733 {   # Closure
2734
2735     main::setup_package();
2736
2737     my %start;
2738     main::set_access('start', \%start, 'r', 's');
2739
2740     my %end;
2741     main::set_access('end', \%end, 'r', 's');
2742
2743     my %value;
2744     main::set_access('value', \%value, 'r');
2745
2746     my %type;
2747     main::set_access('type', \%type, 'r');
2748
2749     my %standard_form;
2750     # The value in internal standard form.  Defined only if the type is 0.
2751     main::set_access('standard_form', \%standard_form);
2752
2753     # Note that if these fields change, the dump() method should as well
2754
2755     sub new {
2756         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2757         my $class = shift;
2758
2759         my $self = bless \do { my $anonymous_scalar }, $class;
2760         my $addr = do { no overloading; pack 'J', $self; };
2761
2762         $start{$addr} = shift;
2763         $end{$addr} = shift;
2764
2765         my %args = @_;
2766
2767         my $value = delete $args{'Value'};  # Can be 0
2768         $value = "" unless defined $value;
2769         $value{$addr} = $value;
2770
2771         $type{$addr} = delete $args{'Type'} || 0;
2772
2773         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2774
2775         if (! $type{$addr}) {
2776             $standard_form{$addr} = main::standardize($value);
2777         }
2778
2779         return $self;
2780     }
2781
2782     use overload
2783         fallback => 0,
2784         qw("") => "_operator_stringify",
2785         "." => \&main::_operator_dot,
2786     ;
2787
2788     sub _operator_stringify {
2789         my $self = shift;
2790         my $addr = do { no overloading; pack 'J', $self; };
2791
2792         # Output it like '0041..0065 (value)'
2793         my $return = sprintf("%04X", $start{$addr})
2794                         .  '..'
2795                         . sprintf("%04X", $end{$addr});
2796         my $value = $value{$addr};
2797         my $type = $type{$addr};
2798         $return .= ' (';
2799         $return .= "$value";
2800         $return .= ", Type=$type" if $type != 0;
2801         $return .= ')';
2802
2803         return $return;
2804     }
2805
2806     sub standard_form {
2807         # The standard form is the value itself if the standard form is
2808         # undefined (that is if the value is special)
2809
2810         my $self = shift;
2811         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2812
2813         my $addr = do { no overloading; pack 'J', $self; };
2814
2815         return $standard_form{$addr} if defined $standard_form{$addr};
2816         return $value{$addr};
2817     }
2818
2819     sub dump {
2820         # Human, not machine readable.  For machine readable, comment out this
2821         # entire routine and let the standard one take effect.
2822         my $self = shift;
2823         my $indent = shift;
2824         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2825
2826         my $addr = do { no overloading; pack 'J', $self; };
2827
2828         my $return = $indent
2829                     . sprintf("%04X", $start{$addr})
2830                     . '..'
2831                     . sprintf("%04X", $end{$addr})
2832                     . " '$value{$addr}';";
2833         if (! defined $standard_form{$addr}) {
2834             $return .= "(type=$type{$addr})";
2835         }
2836         elsif ($standard_form{$addr} ne $value{$addr}) {
2837             $return .= "(standard '$standard_form{$addr}')";
2838         }
2839         return $return;
2840     }
2841 } # End closure
2842
2843 package _Range_List_Base;
2844
2845 # Base class for range lists.  A range list is simply an ordered list of
2846 # ranges, so that the ranges with the lowest starting numbers are first in it.
2847 #
2848 # When a new range is added that is adjacent to an existing range that has the
2849 # same value and type, it merges with it to form a larger range.
2850 #
2851 # Ranges generally do not overlap, except that there can be multiple entries
2852 # of single code point ranges.  This is because of NameAliases.txt.
2853 #
2854 # In this program, there is a standard value such that if two different
2855 # values, have the same standard value, they are considered equivalent.  This
2856 # value was chosen so that it gives correct results on Unicode data
2857
2858 # There are a number of methods to manipulate range lists, and some operators
2859 # are overloaded to handle them.
2860
2861 sub trace { return main::trace(@_); }
2862
2863 { # Closure
2864
2865     our $addr;
2866
2867     main::setup_package();
2868
2869     my %ranges;
2870     # The list of ranges
2871     main::set_access('ranges', \%ranges, 'readable_array');
2872
2873     my %max;
2874     # The highest code point in the list.  This was originally a method, but
2875     # actual measurements said it was used a lot.
2876     main::set_access('max', \%max, 'r');
2877
2878     my %each_range_iterator;
2879     # Iterator position for each_range()
2880     main::set_access('each_range_iterator', \%each_range_iterator);
2881
2882     my %owner_name_of;
2883     # Name of parent this is attached to, if any.  Solely for better error
2884     # messages.
2885     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2886
2887     my %_search_ranges_cache;
2888     # A cache of the previous result from _search_ranges(), for better
2889     # performance
2890     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2891
2892     sub new {
2893         my $class = shift;
2894         my %args = @_;
2895
2896         # Optional initialization data for the range list.
2897         my $initialize = delete $args{'Initialize'};
2898
2899         my $self;
2900
2901         # Use _union() to initialize.  _union() returns an object of this
2902         # class, which means that it will call this constructor recursively.
2903         # But it won't have this $initialize parameter so that it won't
2904         # infinitely loop on this.
2905         return _union($class, $initialize, %args) if defined $initialize;
2906
2907         $self = bless \do { my $anonymous_scalar }, $class;
2908         my $addr = do { no overloading; pack 'J', $self; };
2909
2910         # Optional parent object, only for debug info.
2911         $owner_name_of{$addr} = delete $args{'Owner'};
2912         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2913
2914         # Stringify, in case it is an object.
2915         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2916
2917         # This is used only for error messages, and so a colon is added
2918         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2919
2920         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2921
2922         # Max is initialized to a negative value that isn't adjacent to 0,
2923         # for simpler tests
2924         $max{$addr} = -2;
2925
2926         $_search_ranges_cache{$addr} = 0;
2927         $ranges{$addr} = [];
2928
2929         return $self;
2930     }
2931
2932     use overload
2933         fallback => 0,
2934         qw("") => "_operator_stringify",
2935         "." => \&main::_operator_dot,
2936     ;
2937
2938     sub _operator_stringify {
2939         my $self = shift;
2940         my $addr = do { no overloading; pack 'J', $self; };
2941
2942         return "Range_List attached to '$owner_name_of{$addr}'"
2943                                                 if $owner_name_of{$addr};
2944         return "anonymous Range_List " . \$self;
2945     }
2946
2947     sub _union {
2948         # Returns the union of the input code points.  It can be called as
2949         # either a constructor or a method.  If called as a method, the result
2950         # will be a new() instance of the calling object, containing the union
2951         # of that object with the other parameter's code points;  if called as
2952         # a constructor, the first parameter gives the class the new object
2953         # should be, and the second parameter gives the code points to go into
2954         # it.
2955         # In either case, there are two parameters looked at by this routine;
2956         # any additional parameters are passed to the new() constructor.
2957         #
2958         # The code points can come in the form of some object that contains
2959         # ranges, and has a conventionally named method to access them; or
2960         # they can be an array of individual code points (as integers); or
2961         # just a single code point.
2962         #
2963         # If they are ranges, this routine doesn't make any effort to preserve
2964         # the range values of one input over the other.  Therefore this base
2965         # class should not allow _union to be called from other than
2966         # initialization code, so as to prevent two tables from being added
2967         # together where the range values matter.  The general form of this
2968         # routine therefore belongs in a derived class, but it was moved here
2969         # to avoid duplication of code.  The failure to overload this in this
2970         # class keeps it safe.
2971         #
2972
2973         my $self;
2974         my @args;   # Arguments to pass to the constructor
2975
2976         my $class = shift;
2977
2978         # If a method call, will start the union with the object itself, and
2979         # the class of the new object will be the same as self.
2980         if (ref $class) {
2981             $self = $class;
2982             $class = ref $self;
2983             push @args, $self;
2984         }
2985
2986         # Add the other required parameter.
2987         push @args, shift;
2988         # Rest of parameters are passed on to the constructor
2989
2990         # Accumulate all records from both lists.
2991         my @records;
2992         for my $arg (@args) {
2993             #local $to_trace = 0 if main::DEBUG;
2994             trace "argument = $arg" if main::DEBUG && $to_trace;
2995             if (! defined $arg) {
2996                 my $message = "";
2997                 if (defined $self) {
2998                     no overloading;
2999                     $message .= $owner_name_of{pack 'J', $self};
3000                 }
3001                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
3002                 return;
3003             }
3004             $arg = [ $arg ] if ! ref $arg;
3005             my $type = ref $arg;
3006             if ($type eq 'ARRAY') {
3007                 foreach my $element (@$arg) {
3008                     push @records, Range->new($element, $element);
3009                 }
3010             }
3011             elsif ($arg->isa('Range')) {
3012                 push @records, $arg;
3013             }
3014             elsif ($arg->can('ranges')) {
3015                 push @records, $arg->ranges;
3016             }
3017             else {
3018                 my $message = "";
3019                 if (defined $self) {
3020                     no overloading;
3021                     $message .= $owner_name_of{pack 'J', $self};
3022                 }
3023                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3024                 return;
3025             }
3026         }
3027
3028         # Sort with the range containing the lowest ordinal first, but if
3029         # two ranges start at the same code point, sort with the bigger range
3030         # of the two first, because it takes fewer cycles.
3031         @records = sort { ($a->start <=> $b->start)
3032                                       or
3033                                     # if b is shorter than a, b->end will be
3034                                     # less than a->end, and we want to select
3035                                     # a, so want to return -1
3036                                     ($b->end <=> $a->end)
3037                                    } @records;
3038
3039         my $new = $class->new(@_);
3040
3041         # Fold in records so long as they add new information.
3042         for my $set (@records) {
3043             my $start = $set->start;
3044             my $end   = $set->end;
3045             my $value   = $set->value;
3046             if ($start > $new->max) {
3047                 $new->_add_delete('+', $start, $end, $value);
3048             }
3049             elsif ($end > $new->max) {
3050                 $new->_add_delete('+', $new->max +1, $end, $value);
3051             }
3052         }
3053
3054         return $new;
3055     }
3056
3057     sub range_count {        # Return the number of ranges in the range list
3058         my $self = shift;
3059         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3060
3061         no overloading;
3062         return scalar @{$ranges{pack 'J', $self}};
3063     }
3064
3065     sub min {
3066         # Returns the minimum code point currently in the range list, or if
3067         # the range list is empty, 2 beyond the max possible.  This is a
3068         # method because used so rarely, that not worth saving between calls,
3069         # and having to worry about changing it as ranges are added and
3070         # deleted.
3071
3072         my $self = shift;
3073         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3074
3075         my $addr = do { no overloading; pack 'J', $self; };
3076
3077         # If the range list is empty, return a large value that isn't adjacent
3078         # to any that could be in the range list, for simpler tests
3079         return $MAX_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3080         return $ranges{$addr}->[0]->start;
3081     }
3082
3083     sub contains {
3084         # Boolean: Is argument in the range list?  If so returns $i such that:
3085         #   range[$i]->end < $codepoint <= range[$i+1]->end
3086         # which is one beyond what you want; this is so that the 0th range
3087         # doesn't return false
3088         my $self = shift;
3089         my $codepoint = shift;
3090         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3091
3092         my $i = $self->_search_ranges($codepoint);
3093         return 0 unless defined $i;
3094
3095         # The search returns $i, such that
3096         #   range[$i-1]->end < $codepoint <= range[$i]->end
3097         # So is in the table if and only iff it is at least the start position
3098         # of range $i.
3099         no overloading;
3100         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3101         return $i + 1;
3102     }
3103
3104     sub containing_range {
3105         # Returns the range object that contains the code point, undef if none
3106
3107         my $self = shift;
3108         my $codepoint = shift;
3109         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3110
3111         my $i = $self->contains($codepoint);
3112         return unless $i;
3113
3114         # contains() returns 1 beyond where we should look
3115         no overloading;
3116         return $ranges{pack 'J', $self}->[$i-1];
3117     }
3118
3119     sub value_of {
3120         # Returns the value associated with the code point, undef if none
3121
3122         my $self = shift;
3123         my $codepoint = shift;
3124         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3125
3126         my $range = $self->containing_range($codepoint);
3127         return unless defined $range;
3128
3129         return $range->value;
3130     }
3131
3132     sub type_of {
3133         # Returns the type of the range containing the code point, undef if
3134         # the code point is not in the table
3135
3136         my $self = shift;
3137         my $codepoint = shift;
3138         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3139
3140         my $range = $self->containing_range($codepoint);
3141         return unless defined $range;
3142
3143         return $range->type;
3144     }
3145
3146     sub _search_ranges {
3147         # Find the range in the list which contains a code point, or where it
3148         # should go if were to add it.  That is, it returns $i, such that:
3149         #   range[$i-1]->end < $codepoint <= range[$i]->end
3150         # Returns undef if no such $i is possible (e.g. at end of table), or
3151         # if there is an error.
3152
3153         my $self = shift;
3154         my $code_point = shift;
3155         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3156
3157         my $addr = do { no overloading; pack 'J', $self; };
3158
3159         return if $code_point > $max{$addr};
3160         my $r = $ranges{$addr};                # The current list of ranges
3161         my $range_list_size = scalar @$r;
3162         my $i;
3163
3164         use integer;        # want integer division
3165
3166         # Use the cached result as the starting guess for this one, because,
3167         # an experiment on 5.1 showed that 90% of the time the cache was the
3168         # same as the result on the next call (and 7% it was one less).
3169         $i = $_search_ranges_cache{$addr};
3170         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3171                                             # from an intervening deletion
3172         #local $to_trace = 1 if main::DEBUG;
3173         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3174         return $i if $code_point <= $r->[$i]->end
3175                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3176
3177         # Here the cache doesn't yield the correct $i.  Try adding 1.
3178         if ($i < $range_list_size - 1
3179             && $r->[$i]->end < $code_point &&
3180             $code_point <= $r->[$i+1]->end)
3181         {
3182             $i++;
3183             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3184             $_search_ranges_cache{$addr} = $i;
3185             return $i;
3186         }
3187
3188         # Here, adding 1 also didn't work.  We do a binary search to
3189         # find the correct position, starting with current $i
3190         my $lower = 0;
3191         my $upper = $range_list_size - 1;
3192         while (1) {
3193             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3194
3195             if ($code_point <= $r->[$i]->end) {
3196
3197                 # Here we have met the upper constraint.  We can quit if we
3198                 # also meet the lower one.
3199                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3200
3201                 $upper = $i;        # Still too high.
3202
3203             }
3204             else {
3205
3206                 # Here, $r[$i]->end < $code_point, so look higher up.
3207                 $lower = $i;
3208             }
3209
3210             # Split search domain in half to try again.
3211             my $temp = ($upper + $lower) / 2;
3212
3213             # No point in continuing unless $i changes for next time
3214             # in the loop.
3215             if ($temp == $i) {
3216
3217                 # We can't reach the highest element because of the averaging.
3218                 # So if one below the upper edge, force it there and try one
3219                 # more time.
3220                 if ($i == $range_list_size - 2) {
3221
3222                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3223                     $i = $range_list_size - 1;
3224
3225                     # Change $lower as well so if fails next time through,
3226                     # taking the average will yield the same $i, and we will
3227                     # quit with the error message just below.
3228                     $lower = $i;
3229                     next;
3230                 }
3231                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3232                 return;
3233             }
3234             $i = $temp;
3235         } # End of while loop
3236
3237         if (main::DEBUG && $to_trace) {
3238             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3239             trace "i=  [ $i ]", $r->[$i];
3240             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3241         }
3242
3243         # Here we have found the offset.  Cache it as a starting point for the
3244         # next call.
3245         $_search_ranges_cache{$addr} = $i;
3246         return $i;
3247     }
3248
3249     sub _add_delete {
3250         # Add, replace or delete ranges to or from a list.  The $type
3251         # parameter gives which:
3252         #   '+' => insert or replace a range, returning a list of any changed
3253         #          ranges.
3254         #   '-' => delete a range, returning a list of any deleted ranges.
3255         #
3256         # The next three parameters give respectively the start, end, and
3257         # value associated with the range.  'value' should be null unless the
3258         # operation is '+';
3259         #
3260         # The range list is kept sorted so that the range with the lowest
3261         # starting position is first in the list, and generally, adjacent
3262         # ranges with the same values are merged into a single larger one (see
3263         # exceptions below).
3264         #
3265         # There are more parameters; all are key => value pairs:
3266         #   Type    gives the type of the value.  It is only valid for '+'.
3267         #           All ranges have types; if this parameter is omitted, 0 is
3268         #           assumed.  Ranges with type 0 are assumed to obey the
3269         #           Unicode rules for casing, etc; ranges with other types are
3270         #           not.  Otherwise, the type is arbitrary, for the caller's
3271         #           convenience, and looked at only by this routine to keep
3272         #           adjacent ranges of different types from being merged into
3273         #           a single larger range, and when Replace =>
3274         #           $IF_NOT_EQUIVALENT is specified (see just below).
3275         #   Replace  determines what to do if the range list already contains
3276         #            ranges which coincide with all or portions of the input
3277         #            range.  It is only valid for '+':
3278         #       => $NO            means that the new value is not to replace
3279         #                         any existing ones, but any empty gaps of the
3280         #                         range list coinciding with the input range
3281         #                         will be filled in with the new value.
3282         #       => $UNCONDITIONALLY  means to replace the existing values with
3283         #                         this one unconditionally.  However, if the
3284         #                         new and old values are identical, the
3285         #                         replacement is skipped to save cycles
3286         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3287         #                         with this one if they are not equivalent.
3288         #                         Ranges are equivalent if their types are the
3289         #                         same, and they are the same string; or if
3290         #                         both are type 0 ranges, if their Unicode
3291         #                         standard forms are identical.  In this last
3292         #                         case, the routine chooses the more "modern"
3293         #                         one to use.  This is because some of the
3294         #                         older files are formatted with values that
3295         #                         are, for example, ALL CAPs, whereas the
3296         #                         derived files have a more modern style,
3297         #                         which looks better.  By looking for this
3298         #                         style when the pre-existing and replacement
3299         #                         standard forms are the same, we can move to
3300         #                         the modern style
3301         #       => $MULTIPLE      means that if this range duplicates an
3302         #                         existing one, but has a different value,
3303         #                         don't replace the existing one, but insert
3304         #                         this, one so that the same range can occur
3305         #                         multiple times.  They are stored LIFO, so
3306         #                         that the final one inserted is the first one
3307         #                         returned in an ordered search of the table.
3308         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3309         #
3310         # "same value" means identical for non-type-0 ranges, and it means
3311         # having the same standard forms for type-0 ranges.
3312
3313         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3314
3315         my $self = shift;
3316         my $operation = shift;   # '+' for add/replace; '-' for delete;
3317         my $start = shift;
3318         my $end   = shift;
3319         my $value = shift;
3320
3321         my %args = @_;
3322
3323         $value = "" if not defined $value;        # warning: $value can be "0"
3324
3325         my $replace = delete $args{'Replace'};
3326         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3327
3328         my $type = delete $args{'Type'};
3329         $type = 0 unless defined $type;
3330
3331         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3332
3333         my $addr = do { no overloading; pack 'J', $self; };
3334
3335         if ($operation ne '+' && $operation ne '-') {
3336             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3337             return;
3338         }
3339         unless (defined $start && defined $end) {
3340             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3341             return;
3342         }
3343         unless ($end >= $start) {
3344             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3345             return;
3346         }
3347         #local $to_trace = 1 if main::DEBUG;
3348
3349         if ($operation eq '-') {
3350             if ($replace != $IF_NOT_EQUIVALENT) {
3351                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3352                 $replace = $IF_NOT_EQUIVALENT;
3353             }
3354             if ($type) {
3355                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3356                 $type = 0;
3357             }
3358             if ($value ne "") {
3359                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3360                 $value = "";
3361             }
3362         }
3363
3364         my $r = $ranges{$addr};               # The current list of ranges
3365         my $range_list_size = scalar @$r;     # And its size
3366         my $max = $max{$addr};                # The current high code point in
3367                                               # the list of ranges
3368
3369         # Do a special case requiring fewer machine cycles when the new range
3370         # starts after the current highest point.  The Unicode input data is
3371         # structured so this is common.
3372         if ($start > $max) {
3373
3374             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3375             return if $operation eq '-'; # Deleting a non-existing range is a
3376                                          # no-op
3377
3378             # If the new range doesn't logically extend the current final one
3379             # in the range list, create a new range at the end of the range
3380             # list.  (max cleverly is initialized to a negative number not
3381             # adjacent to 0 if the range list is empty, so even adding a range
3382             # to an empty range list starting at 0 will have this 'if'
3383             # succeed.)
3384             if ($start > $max + 1        # non-adjacent means can't extend.
3385                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3386                 || @{$r}[-1]->type != $type # types differ, can't extend.
3387             ) {
3388                 push @$r, Range->new($start, $end,
3389                                      Value => $value,
3390                                      Type => $type);
3391             }
3392             else {
3393
3394                 # Here, the new range starts just after the current highest in
3395                 # the range list, and they have the same type and value.
3396                 # Extend the current range to incorporate the new one.
3397                 @{$r}[-1]->set_end($end);
3398             }
3399
3400             # This becomes the new maximum.
3401             $max{$addr} = $end;
3402
3403             return;
3404         }
3405         #local $to_trace = 0 if main::DEBUG;
3406
3407         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3408
3409         # Here, the input range isn't after the whole rest of the range list.
3410         # Most likely 'splice' will be needed.  The rest of the routine finds
3411         # the needed splice parameters, and if necessary, does the splice.
3412         # First, find the offset parameter needed by the splice function for
3413         # the input range.  Note that the input range may span multiple
3414         # existing ones, but we'll worry about that later.  For now, just find
3415         # the beginning.  If the input range is to be inserted starting in a
3416         # position not currently in the range list, it must (obviously) come
3417         # just after the range below it, and just before the range above it.
3418         # Slightly less obviously, it will occupy the position currently
3419         # occupied by the range that is to come after it.  More formally, we
3420         # are looking for the position, $i, in the array of ranges, such that:
3421         #
3422         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3423         #
3424         # (The ordered relationships within existing ranges are also shown in
3425         # the equation above).  However, if the start of the input range is
3426         # within an existing range, the splice offset should point to that
3427         # existing range's position in the list; that is $i satisfies a
3428         # somewhat different equation, namely:
3429         #
3430         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3431         #
3432         # More briefly, $start can come before or after r[$i]->start, and at
3433         # this point, we don't know which it will be.  However, these
3434         # two equations share these constraints:
3435         #
3436         #   r[$i-1]->end < $start <= r[$i]->end
3437         #
3438         # And that is good enough to find $i.
3439
3440         my $i = $self->_search_ranges($start);
3441         if (! defined $i) {
3442             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3443             return;
3444         }
3445
3446         # The search function returns $i such that:
3447         #
3448         # r[$i-1]->end < $start <= r[$i]->end
3449         #
3450         # That means that $i points to the first range in the range list
3451         # that could possibly be affected by this operation.  We still don't
3452         # know if the start of the input range is within r[$i], or if it
3453         # points to empty space between r[$i-1] and r[$i].
3454         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3455
3456         # Special case the insertion of data that is not to replace any
3457         # existing data.
3458         if ($replace == $NO) {  # If $NO, has to be operation '+'
3459             #local $to_trace = 1 if main::DEBUG;
3460             trace "Doesn't replace" if main::DEBUG && $to_trace;
3461
3462             # Here, the new range is to take effect only on those code points
3463             # that aren't already in an existing range.  This can be done by
3464             # looking through the existing range list and finding the gaps in
3465             # the ranges that this new range affects, and then calling this
3466             # function recursively on each of those gaps, leaving untouched
3467             # anything already in the list.  Gather up a list of the changed
3468             # gaps first so that changes to the internal state as new ranges
3469             # are added won't be a problem.
3470             my @gap_list;
3471
3472             # First, if the starting point of the input range is outside an
3473             # existing one, there is a gap from there to the beginning of the
3474             # existing range -- add a span to fill the part that this new
3475             # range occupies
3476             if ($start < $r->[$i]->start) {
3477                 push @gap_list, Range->new($start,
3478                                            main::min($end,
3479                                                      $r->[$i]->start - 1),
3480                                            Type => $type);
3481                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3482             }
3483
3484             # Then look through the range list for other gaps until we reach
3485             # the highest range affected by the input one.
3486             my $j;
3487             for ($j = $i+1; $j < $range_list_size; $j++) {
3488                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3489                 last if $end < $r->[$j]->start;
3490
3491                 # If there is a gap between when this range starts and the
3492                 # previous one ends, add a span to fill it.  Note that just
3493                 # because there are two ranges doesn't mean there is a
3494                 # non-zero gap between them.  It could be that they have
3495                 # different values or types
3496                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3497                     push @gap_list,
3498                         Range->new($r->[$j-1]->end + 1,
3499                                    $r->[$j]->start - 1,
3500                                    Type => $type);
3501                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3502                 }
3503             }
3504
3505             # Here, we have either found an existing range in the range list,
3506             # beyond the area affected by the input one, or we fell off the
3507             # end of the loop because the input range affects the whole rest
3508             # of the range list.  In either case, $j is 1 higher than the
3509             # highest affected range.  If $j == $i, it means that there are no
3510             # affected ranges, that the entire insertion is in the gap between
3511             # r[$i-1], and r[$i], which we already have taken care of before
3512             # the loop.
3513             # On the other hand, if there are affected ranges, it might be
3514             # that there is a gap that needs filling after the final such
3515             # range to the end of the input range
3516             if ($r->[$j-1]->end < $end) {
3517                     push @gap_list, Range->new(main::max($start,
3518                                                          $r->[$j-1]->end + 1),
3519                                                $end,
3520                                                Type => $type);
3521                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3522             }
3523
3524             # Call recursively to fill in all the gaps.
3525             foreach my $gap (@gap_list) {
3526                 $self->_add_delete($operation,
3527                                    $gap->start,
3528                                    $gap->end,
3529                                    $value,
3530                                    Type => $type);
3531             }
3532
3533             return;
3534         }
3535
3536         # Here, we have taken care of the case where $replace is $NO.
3537         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3538         # If inserting a multiple record, this is where it goes, before the
3539         # first (if any) existing one.  This implies an insertion, and no
3540         # change to any existing ranges.  Note that $i can be -1 if this new
3541         # range doesn't actually duplicate any existing, and comes at the
3542         # beginning of the list.
3543         if ($replace == $MULTIPLE) {
3544
3545             if ($start != $end) {
3546                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3547                 return;
3548             }
3549
3550             # Don't add an exact duplicate, as it isn't really a multiple
3551             if ($end >= $r->[$i]->start) {
3552                 my $existing_value = $r->[$i]->value;
3553                 my $existing_type = $r->[$i]->type;
3554                 return if $value eq $existing_value && $type eq $existing_type;
3555
3556                 # If the multiple value is part of an existing range, we want
3557                 # to split up that range, so that only the single code point
3558                 # is affected.  To do this, we first call ourselves
3559                 # recursively to delete that code point from the table, having
3560                 # preserved its current data above.  Then we call ourselves
3561                 # recursively again to add the new multiple, which we know by
3562                 # the test just above is different than the current code
3563                 # point's value, so it will become a range containing a single
3564                 # code point: just itself.  Finally, we add back in the
3565                 # pre-existing code point, which will again be a single code
3566                 # point range.  Because 'i' likely will have changed as a
3567                 # result of these operations, we can't just continue on, but
3568                 # do this operation recursively as well.
3569                 if ($r->[$i]->start != $r->[$i]->end) {
3570                     $self->_add_delete('-', $start, $end, "");
3571                     $self->_add_delete('+', $start, $end, $value, Type => $type);
3572                     return $self->_add_delete('+', $start, $end, $existing_value, Type => $existing_type, Replace => $MULTIPLE);
3573                 }
3574             }
3575
3576             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3577             my @return = splice @$r,
3578                                 $i,
3579                                 0,
3580                                 Range->new($start,
3581                                            $end,
3582                                            Value => $value,
3583                                            Type => $type);
3584             if (main::DEBUG && $to_trace) {
3585                 trace "After splice:";
3586                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3587                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3588                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3589                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3590                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3591                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3592             }
3593             return @return;
3594         }
3595
3596         # Here, we have taken care of $NO and $MULTIPLE replaces.  This leaves
3597         # delete, insert, and replace either unconditionally or if not
3598         # equivalent.  $i still points to the first potential affected range.
3599         # Now find the highest range affected, which will determine the length
3600         # parameter to splice.  (The input range can span multiple existing
3601         # ones.)  If this isn't a deletion, while we are looking through the
3602         # range list, see also if this is a replacement rather than a clean
3603         # insertion; that is if it will change the values of at least one
3604         # existing range.  Start off assuming it is an insert, until find it
3605         # isn't.
3606         my $clean_insert = $operation eq '+';
3607         my $j;        # This will point to the highest affected range
3608
3609         # For non-zero types, the standard form is the value itself;
3610         my $standard_form = ($type) ? $value : main::standardize($value);
3611
3612         for ($j = $i; $j < $range_list_size; $j++) {
3613             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3614
3615             # If find a range that it doesn't overlap into, we can stop
3616             # searching
3617             last if $end < $r->[$j]->start;
3618
3619             # Here, overlaps the range at $j.  If the values don't match,
3620             # and so far we think this is a clean insertion, it becomes a
3621             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3622             if ($clean_insert) {
3623                 if ($r->[$j]->standard_form ne $standard_form) {
3624                     $clean_insert = 0;
3625                     if ($replace == $CROAK) {
3626                         main::croak("The range to add "
3627                         . sprintf("%04X", $start)
3628                         . '-'
3629                         . sprintf("%04X", $end)
3630                         . " with value '$value' overlaps an existing range $r->[$j]");
3631                     }
3632                 }
3633                 else {
3634
3635                     # Here, the two values are essentially the same.  If the
3636                     # two are actually identical, replacing wouldn't change
3637                     # anything so skip it.
3638                     my $pre_existing = $r->[$j]->value;
3639                     if ($pre_existing ne $value) {
3640
3641                         # Here the new and old standardized values are the
3642                         # same, but the non-standardized values aren't.  If
3643                         # replacing unconditionally, then replace
3644                         if( $replace == $UNCONDITIONALLY) {
3645                             $clean_insert = 0;
3646                         }
3647                         else {
3648
3649                             # Here, are replacing conditionally.  Decide to
3650                             # replace or not based on which appears to look
3651                             # the "nicest".  If one is mixed case and the
3652                             # other isn't, choose the mixed case one.
3653                             my $new_mixed = $value =~ /[A-Z]/
3654                                             && $value =~ /[a-z]/;
3655                             my $old_mixed = $pre_existing =~ /[A-Z]/
3656                                             && $pre_existing =~ /[a-z]/;
3657
3658                             if ($old_mixed != $new_mixed) {
3659                                 $clean_insert = 0 if $new_mixed;
3660                                 if (main::DEBUG && $to_trace) {
3661                                     if ($clean_insert) {
3662                                         trace "Retaining $pre_existing over $value";
3663                                     }
3664                                     else {
3665                                         trace "Replacing $pre_existing with $value";
3666                                     }
3667                                 }
3668                             }
3669                             else {
3670
3671                                 # Here casing wasn't different between the two.
3672                                 # If one has hyphens or underscores and the
3673                                 # other doesn't, choose the one with the
3674                                 # punctuation.
3675                                 my $new_punct = $value =~ /[-_]/;
3676                                 my $old_punct = $pre_existing =~ /[-_]/;
3677
3678                                 if ($old_punct != $new_punct) {
3679                                     $clean_insert = 0 if $new_punct;
3680                                     if (main::DEBUG && $to_trace) {
3681                                         if ($clean_insert) {
3682                                             trace "Retaining $pre_existing over $value";
3683                                         }
3684                                         else {
3685                                             trace "Replacing $pre_existing with $value";
3686                                         }
3687                                     }
3688                                 }   # else existing one is just as "good";
3689                                     # retain it to save cycles.
3690                             }
3691                         }
3692                     }
3693                 }
3694             }
3695         } # End of loop looking for highest affected range.
3696
3697         # Here, $j points to one beyond the highest range that this insertion
3698         # affects (hence to beyond the range list if that range is the final
3699         # one in the range list).
3700
3701         # The splice length is all the affected ranges.  Get it before
3702         # subtracting, for efficiency, so we don't have to later add 1.
3703         my $length = $j - $i;
3704
3705         $j--;        # $j now points to the highest affected range.
3706         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3707
3708         # Here, have taken care of $NO and $MULTIPLE replaces.
3709         # $j points to the highest affected range.  But it can be < $i or even
3710         # -1.  These happen only if the insertion is entirely in the gap
3711         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3712         # above exited first time through with $end < $r->[$i]->start.  (And
3713         # then we subtracted one from j)  This implies also that $start <
3714         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3715         # $start, so the entire input range is in the gap.
3716         if ($j < $i) {
3717
3718             # Here the entire input range is in the gap before $i.
3719
3720             if (main::DEBUG && $to_trace) {
3721                 if ($i) {
3722                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3723                 }
3724                 else {
3725                     trace "Entire range is before $r->[$i]";
3726                 }
3727             }
3728             return if $operation ne '+'; # Deletion of a non-existent range is
3729                                          # a no-op
3730         }
3731         else {
3732
3733             # Here part of the input range is not in the gap before $i.  Thus,
3734             # there is at least one affected one, and $j points to the highest
3735             # such one.
3736
3737             # At this point, here is the situation:
3738             # This is not an insertion of a multiple, nor of tentative ($NO)
3739             # data.
3740             #   $i  points to the first element in the current range list that
3741             #            may be affected by this operation.  In fact, we know
3742             #            that the range at $i is affected because we are in
3743             #            the else branch of this 'if'
3744             #   $j  points to the highest affected range.
3745             # In other words,
3746             #   r[$i-1]->end < $start <= r[$i]->end
3747             # And:
3748             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3749             #
3750             # Also:
3751             #   $clean_insert is a boolean which is set true if and only if
3752             #        this is a "clean insertion", i.e., not a change nor a
3753             #        deletion (multiple was handled above).
3754
3755             # We now have enough information to decide if this call is a no-op
3756             # or not.  It is a no-op if this is an insertion of already
3757             # existing data.
3758
3759             if (main::DEBUG && $to_trace && $clean_insert
3760                                          && $i == $j
3761                                          && $start >= $r->[$i]->start)
3762             {
3763                     trace "no-op";
3764             }
3765             return if $clean_insert
3766                       && $i == $j # more than one affected range => not no-op
3767
3768                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3769                       # Further, $start and/or $end is >= r[$i]->start
3770                       # The test below hence guarantees that
3771                       #     r[$i]->start < $start <= $end <= r[$i]->end
3772                       # This means the input range is contained entirely in
3773                       # the one at $i, so is a no-op
3774                       && $start >= $r->[$i]->start;
3775         }
3776
3777         # Here, we know that some action will have to be taken.  We have
3778         # calculated the offset and length (though adjustments may be needed)
3779         # for the splice.  Now start constructing the replacement list.
3780         my @replacement;
3781         my $splice_start = $i;
3782
3783         my $extends_below;
3784         my $extends_above;
3785
3786         # See if should extend any adjacent ranges.
3787         if ($operation eq '-') { # Don't extend deletions
3788             $extends_below = $extends_above = 0;
3789         }
3790         else {  # Here, should extend any adjacent ranges.  See if there are
3791                 # any.
3792             $extends_below = ($i > 0
3793                             # can't extend unless adjacent
3794                             && $r->[$i-1]->end == $start -1
3795                             # can't extend unless are same standard value
3796                             && $r->[$i-1]->standard_form eq $standard_form
3797                             # can't extend unless share type
3798                             && $r->[$i-1]->type == $type);
3799             $extends_above = ($j+1 < $range_list_size
3800                             && $r->[$j+1]->start == $end +1
3801                             && $r->[$j+1]->standard_form eq $standard_form
3802                             && $r->[$j+1]->type == $type);
3803         }
3804         if ($extends_below && $extends_above) { # Adds to both
3805             $splice_start--;     # start replace at element below
3806             $length += 2;        # will replace on both sides
3807             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3808
3809             # The result will fill in any gap, replacing both sides, and
3810             # create one large range.
3811             @replacement = Range->new($r->[$i-1]->start,
3812                                       $r->[$j+1]->end,
3813                                       Value => $value,
3814                                       Type => $type);
3815         }
3816         else {
3817
3818             # Here we know that the result won't just be the conglomeration of
3819             # a new range with both its adjacent neighbors.  But it could
3820             # extend one of them.
3821
3822             if ($extends_below) {
3823
3824                 # Here the new element adds to the one below, but not to the
3825                 # one above.  If inserting, and only to that one range,  can
3826                 # just change its ending to include the new one.
3827                 if ($length == 0 && $clean_insert) {
3828                     $r->[$i-1]->set_end($end);
3829                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3830                     return;
3831                 }
3832                 else {
3833                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3834                     $splice_start--;        # start replace at element below
3835                     $length++;              # will replace the element below
3836                     $start = $r->[$i-1]->start;
3837                 }
3838             }
3839             elsif ($extends_above) {
3840
3841                 # Here the new element adds to the one above, but not below.
3842                 # Mirror the code above
3843                 if ($length == 0 && $clean_insert) {
3844                     $r->[$j+1]->set_start($start);
3845                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3846                     return;
3847                 }
3848                 else {
3849                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3850                     $length++;        # will replace the element above
3851                     $end = $r->[$j+1]->end;
3852                 }
3853             }
3854
3855             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3856
3857             # Finally, here we know there will have to be a splice.
3858             # If the change or delete affects only the highest portion of the
3859             # first affected range, the range will have to be split.  The
3860             # splice will remove the whole range, but will replace it by a new
3861             # range containing just the unaffected part.  So, in this case,
3862             # add to the replacement list just this unaffected portion.
3863             if (! $extends_below
3864                 && $start > $r->[$i]->start && $start <= $r->[$i]->end)
3865             {
3866                 push @replacement,
3867                     Range->new($r->[$i]->start,
3868                                $start - 1,
3869                                Value => $r->[$i]->value,
3870                                Type => $r->[$i]->type);
3871             }
3872
3873             # In the case of an insert or change, but not a delete, we have to
3874             # put in the new stuff;  this comes next.
3875             if ($operation eq '+') {
3876                 push @replacement, Range->new($start,
3877                                               $end,
3878                                               Value => $value,
3879                                               Type => $type);
3880             }
3881
3882             trace "Range at $j is $r->[$j]" if main::DEBUG && $to_trace && $j != $i;
3883             #trace "$end >=", $r->[$j]->start, " && $end <", $r->[$j]->end if main::DEBUG && $to_trace;
3884
3885             # And finally, if we're changing or deleting only a portion of the
3886             # highest affected range, it must be split, as the lowest one was.
3887             if (! $extends_above
3888                 && $j >= 0  # Remember that j can be -1 if before first
3889                             # current element
3890                 && $end >= $r->[$j]->start
3891                 && $end < $r->[$j]->end)
3892             {
3893                 push @replacement,
3894                     Range->new($end + 1,
3895                                $r->[$j]->end,
3896                                Value => $r->[$j]->value,
3897                                Type => $r->[$j]->type);
3898             }
3899         }
3900
3901         # And do the splice, as calculated above
3902         if (main::DEBUG && $to_trace) {
3903             trace "replacing $length element(s) at $i with ";
3904             foreach my $replacement (@replacement) {
3905                 trace "    $replacement";
3906             }
3907             trace "Before splice:";
3908             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3909             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3910             trace "i  =[", $i, "]", $r->[$i];
3911             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3912             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3913         }
3914
3915         my @return = splice @$r, $splice_start, $length, @replacement;
3916
3917         if (main::DEBUG && $to_trace) {
3918             trace "After splice:";
3919             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3920             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3921             trace "i  =[", $i, "]", $r->[$i];
3922             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3923             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3924             trace "removed ", @return if @return;
3925         }
3926
3927         # An actual deletion could have changed the maximum in the list.
3928         # There was no deletion if the splice didn't return something, but
3929         # otherwise recalculate it.  This is done too rarely to worry about
3930         # performance.
3931         if ($operation eq '-' && @return) {
3932             $max{$addr} = $r->[-1]->end;
3933         }
3934         return @return;
3935     }
3936
3937     sub reset_each_range {  # reset the iterator for each_range();
3938         my $self = shift;
3939         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3940
3941         no overloading;
3942         undef $each_range_iterator{pack 'J', $self};
3943         return;
3944     }
3945
3946     sub each_range {
3947         # Iterate over each range in a range list.  Results are undefined if
3948         # the range list is changed during the iteration.
3949
3950         my $self = shift;
3951         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3952
3953         my $addr = do { no overloading; pack 'J', $self; };
3954
3955         return if $self->is_empty;
3956
3957         $each_range_iterator{$addr} = -1
3958                                 if ! defined $each_range_iterator{$addr};
3959         $each_range_iterator{$addr}++;
3960         return $ranges{$addr}->[$each_range_iterator{$addr}]
3961                         if $each_range_iterator{$addr} < @{$ranges{$addr}};
3962         undef $each_range_iterator{$addr};