lib/Config.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require "./test.pl";
   7 }
   8
   9 plan 'no_plan';
  10
  11 use_ok('Config');
  12
  13 # Some (safe?) bets.
  14
  15 ok(keys %Config > 500, "Config has more than 500 entries");
  16
  17 ok(each %Config);
  18
  19 is($Config{PERL_REVISION}, 5, "PERL_REVISION is 5");
  20
  21 # Check that old config variable names are aliased to their new ones.
  22 my %grandfathers = ( PERL_VERSION       => 'PATCHLEVEL',
  23                      PERL_SUBVERSION    => 'SUBVERSION',
  24                      PERL_CONFIG_SH     => 'CONFIG'
  25                    );
  26 while( my($new, $old) = each %grandfathers ) {
  27     isnt($Config{$new}, undef,       "$new is defined");
  28     is($Config{$new}, $Config{$old}, "$new is aliased to $old");
  29 }
  30
  31 ok( exists $Config{cc},      "has cc");
  32
  33 ok( exists $Config{ccflags}, "has ccflags");
  34
  35 ok(!exists $Config{python},  "has no python");
  36
  37 ok( exists $Config{d_fork},  "has d_fork");
  38
  39 ok(!exists $Config{d_bork},  "has no d_bork");
  40
  41 like($Config{ivsize},     qr/^(4|8)$/, "ivsize is 4 or 8 (it is $Config{ivsize})");
  42
  43 # byteorder is virtual, but it has rules.
  44
  45 like($Config{byteorder}, qr/^(1234|4321|12345678|87654321)$/, "byteorder is 1234 or 4321 or 12345678 or 87654321 (it is $Config{byteorder})");
  46
  47 is(length $Config{byteorder}, $Config{ivsize}, "byteorder is as long as ivsize (which is $Config{ivsize})");
  48
  49 # ccflags_nolargefiles is virtual, too.
  50
  51 ok(exists $Config{ccflags_nolargefiles}, "has ccflags_nolargefiles");
  52
  53 # Utility functions.
  54
  55 {
  56     # make sure we can export what we say we can export.
  57     package Foo;
  58     my @exports = qw(myconfig config_sh config_vars config_re);
  59     Config->import(@exports);
  60     foreach my $func (@exports) {
  61         ::ok( __PACKAGE__->can($func), "$func exported" );
  62     }
  63 }
  64
  65 like(Config::myconfig(),       qr/osname=\Q$Config{osname}\E/,   "myconfig");
  66 like(Config::config_sh(),      qr/osname='\Q$Config{osname}\E'/, "config_sh");
  67 foreach my $line (Config::config_re('c.*')) {
  68   like($line,                  qr/^c.*?=.*$/,                   'config_re' );
  69 }
  70
  71 my $out = tie *STDOUT, 'FakeOut';
  72
  73 Config::config_vars('cc');
  74 my $out1 = $$out;
  75 $out->clear;
  76
  77 Config::config_vars('d_bork');
  78 my $out2 = $$out;
  79 $out->clear;
  80
  81 Config::config_vars('PERL_API_.*');
  82 my $out3 = $$out;
  83 $out->clear;
  84
  85 Config::config_vars(':PERL_API_.*:');
  86 my $out4 = $$out;
  87 $out->clear;
  88
  89 Config::config_vars(':PERL_API_REVISION:');
  90 my $out5 = $$out;
  91 $out->clear;
  92
  93 Config::config_vars('?flags');
  94 my $out6 = $$out;
  95 $out->clear;
  96
  97 untie *STDOUT;
  98 like($out1, qr/^cc='\Q$Config{cc}\E';/, "config_vars cc");
  99 like($out2, qr/^d_bork='UNKNOWN';/, "config_vars d_bork is UNKNOWN");
 100
 101 is(3, scalar split(/\n/, $out3), "3 PERL_API vars found");
 102 my @api = $out3 =~ /^PERL_API_(\w+)=(.*);/mg;
 103 is("'5'", $api[1], "1st is 5");
 104 is("'9'", $api[5], "2nd is 9");
 105 is("'1'", $api[3], "3rd is 1");
 106 @api = split(/ /, $out4);
 107 is(3, @api, "trailing colon puts 3 terms on same line");
 108 unlike($out4, qr/=/, "leading colon suppresses param names");
 109 is("'5'", $api[0], "revision is 5");
 110 is("'9'", $api[2], "version is 9");
 111 is("'1'", $api[1], "subversion is 1");
 112
 113 is("'5' ", $out5, "leading and trailing colons return just the value");
 114
 115 like($out6, qr/\bnot\s+found\b/, "config_vars with invalid regexp");
 116
 117 # Read-only.
 118
 119 undef $@;
 120 eval { $Config{d_bork} = 'borkbork' };
 121 like($@, qr/Config is read-only/, "no STORE");
 122
 123 ok(!exists $Config{d_bork}, "still no d_bork");
 124
 125 undef $@;
 126 eval { delete $Config{d_fork} };
 127 like($@, qr/Config is read-only/, "no DELETE");
 128
 129 ok( exists $Config{d_fork}, "still d_fork");
 130
 131 undef $@;
 132 eval { %Config = () };
 133 like($@, qr/Config is read-only/, "no CLEAR");
 134
 135 ok( exists $Config{d_fork}, "still d_fork");
 136
 137 {
 138     package FakeOut;
 139
 140     sub TIEHANDLE {
 141         bless(\(my $text), $_[0]);
 142     }
 143
 144     sub clear {
 145         ${ $_[0] } = '';
 146     }
 147
 148     sub PRINT {
 149         my $self = shift;
 150         $$self .= join('', @_);
 151     }
 152 }
 153
 154 # Signal-related variables
 155 # (this is actually a regression test for Configure.)
 156
 157 is($Config{sig_num_init}  =~ tr/,/,/, $Config{sig_size}, "sig_num_init size");
 158 is($Config{sig_name_init} =~ tr/,/,/, $Config{sig_size}, "sig_name_init size");