This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlre: Clarify /x eol can't be escaped
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start of the string's first line and the end of its last line to
35 matching the start and end of each line within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If locale matching rules are in effect, the case map is taken from the
55 current
56 locale for code points less than 255, and from Unicode rules for larger
57 code points.  However, matches that would cross the Unicode
58 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
59 L<perllocale>.
60
61 There are a number of Unicode characters that match multiple characters
62 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
63 should match the sequence C<fi>.  Perl is not
64 currently able to do this when the multiple characters are in the pattern and
65 are split between groupings, or when one or more are quantified.  Thus
66
67  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
68  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
69  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
70
71  # The below doesn't match, and it isn't clear what $1 and $2 would
72  # be even if it did!!
73  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
74
75 Perl doesn't match multiple characters in a bracketed
76 character class unless the character that maps to them is explicitly
77 mentioned, and it doesn't match them at all if the character class is
78 inverted, which otherwise could be highly confusing.  See
79 L<perlrecharclass/Bracketed Character Classes>, and
80 L<perlrecharclass/Negation>.
81
82 =item x
83 X</x>
84
85 Extend your pattern's legibility by permitting whitespace and comments.
86 Details in L</"/x">
87
88 =item p
89 X</p> X<regex, preserve> X<regexp, preserve>
90
91 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
92 ${^POSTMATCH} are available for use after matching.
93
94 In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
95 mechanism, ${^PREMATCH}, ${^MATCH}, and ${^POSTMATCH} will be available
96 after the match regardless of the modifier.
97
98 =item a, d, l and u
99 X</a> X</d> X</l> X</u>
100
101 These modifiers, all new in 5.14, affect which character-set rules
102 (Unicode, etc.) are used, as described below in
103 L</Character set modifiers>.
104
105 =item Other Modifiers
106
107 There are a number of flags that can be found at the end of regular
108 expression constructs that are I<not> generic regular expression flags, but
109 apply to the operation being performed, like matching or substitution (C<m//>
110 or C<s///> respectively).
111
112 Flags described further in
113 L<perlretut/"Using regular expressions in Perl"> are:
114
115   c  - keep the current position during repeated matching
116   g  - globally match the pattern repeatedly in the string
117
118 Substitution-specific modifiers described in
119
120 L<perlop/"s/PATTERN/REPLACEMENT/msixpodualgcer"> are:
121
122   e  - evaluate the right-hand side as an expression
123   ee - evaluate the right side as a string then eval the result
124   o  - pretend to optimize your code, but actually introduce bugs
125   r  - perform non-destructive substitution and return the new value
126
127 =back
128
129 Regular expression modifiers are usually written in documentation
130 as e.g., "the C</x> modifier", even though the delimiter
131 in question might not really be a slash.  The modifiers C</imsxadlup>
132 may also be embedded within the regular expression itself using
133 the C<(?...)> construct, see L</Extended Patterns> below.
134
135 =head3 /x
136
137 C</x> tells
138 the regular expression parser to ignore most whitespace that is neither
139 backslashed nor within a bracketed character class.  You can use this to
140 break up your regular expression into (slightly) more readable parts.
141 Also, the C<#> character is treated as a metacharacter introducing a
142 comment that runs up to the pattern's closing delimiter, or to the end
143 of the current line if the pattern extends onto the next line.  Hence,
144 this is very much like an ordinary Perl code comment.  (You can include
145 the closing delimiter within the comment only if you precede it with a
146 backslash, so be careful!)
147
148 Use of C</x> means that if you want real
149 whitespace or C<#> characters in the pattern (outside a bracketed character
150 class, which is unaffected by C</x>), then you'll either have to
151 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
152 hex, or C<\N{}> escapes.
153 It is ineffective to try to continue a comment onto the next line by
154 escaping the C<\n> with a backslash or C<\Q>.
155
156 You can use L</(?#text)> to create a comment that ends earlier than the
157 end of the current line, but C<text> also can't contain the closing
158 delimiter unless escaped with a backslash.
159
160 Taken together, these features go a long way towards
161 making Perl's regular expressions more readable.  Here's an example:
162
163     # Delete (most) C comments.
164     $program =~ s {
165         /\*     # Match the opening delimiter.
166         .*?     # Match a minimal number of characters.
167         \*/     # Match the closing delimiter.
168     } []gsx;
169
170 Note that anything inside
171 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
172 space interpretation within a single multi-character construct.  For
173 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
174 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
175 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<(>,
176 C<?>, and C<:>.  Within any delimiters for such a
177 construct, allowed spaces are not affected by C</x>, and depend on the
178 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
179 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
180 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
181 L<perluniprops/Properties accessible through \p{} and \P{}>.
182 X</x>
183
184 =head3 Character set modifiers
185
186 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
187 the character set modifiers; they affect the character set rules
188 used for the regular expression.
189
190 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
191 to you, and so you need not worry about them very much.  They exist for
192 Perl's internal use, so that complex regular expression data structures
193 can be automatically serialized and later exactly reconstituted,
194 including all their nuances.  But, since Perl can't keep a secret, and
195 there may be rare instances where they are useful, they are documented
196 here.
197
198 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
199 allow code that is to work mostly on ASCII data to not have to concern
200 itself with Unicode.
201
202 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
203 effect at the time of the execution of the pattern match.
204
205 C</u> sets the character set to B<U>nicode.
206
207 C</a> also sets the character set to Unicode, BUT adds several
208 restrictions for B<A>SCII-safe matching.
209
210 C</d> is the old, problematic, pre-5.14 B<D>efault character set
211 behavior.  Its only use is to force that old behavior.
212
213 At any given time, exactly one of these modifiers is in effect.  Their
214 existence allows Perl to keep the originally compiled behavior of a
215 regular expression, regardless of what rules are in effect when it is
216 actually executed.  And if it is interpolated into a larger regex, the
217 original's rules continue to apply to it, and only it.
218
219 The C</l> and C</u> modifiers are automatically selected for
220 regular expressions compiled within the scope of various pragmas,
221 and we recommend that in general, you use those pragmas instead of
222 specifying these modifiers explicitly.  For one thing, the modifiers
223 affect only pattern matching, and do not extend to even any replacement
224 done, whereas using the pragmas give consistent results for all
225 appropriate operations within their scopes.  For example,
226
227  s/foo/\Ubar/il
228
229 will match "foo" using the locale's rules for case-insensitive matching,
230 but the C</l> does not affect how the C<\U> operates.  Most likely you
231 want both of them to use locale rules.  To do this, instead compile the
232 regular expression within the scope of C<use locale>.  This both
233 implicitly adds the C</l> and applies locale rules to the C<\U>.   The
234 lesson is to C<use locale> and not C</l> explicitly.
235
236 Similarly, it would be better to use C<use feature 'unicode_strings'>
237 instead of,
238
239  s/foo/\Lbar/iu
240
241 to get Unicode rules, as the C<\L> in the former (but not necessarily
242 the latter) would also use Unicode rules.
243
244 More detail on each of the modifiers follows.  Most likely you don't
245 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
246 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
247
248 =head4 /l
249
250 means to use the current locale's rules (see L<perllocale>) when pattern
251 matching.  For example, C<\w> will match the "word" characters of that
252 locale, and C<"/i"> case-insensitive matching will match according to
253 the locale's case folding rules.  The locale used will be the one in
254 effect at the time of execution of the pattern match.  This may not be
255 the same as the compilation-time locale, and can differ from one match
256 to another if there is an intervening call of the
257 L<setlocale() function|perllocale/The setlocale function>.
258
259 The only non-single-byte locale Perl supports is (starting in v5.20)
260 UTF-8.  This means that code points above 255 are treated as Unicode no
261 matter what locale is in effect (since UTF-8 implies Unicode).
262
263 Under Unicode rules, there are a few case-insensitive matches that cross
264 the 255/256 boundary.  Except for UTF-8 locales in Perls v5.20 and
265 later, these are disallowed under C</l>.  For example, 0xFF (on ASCII
266 platforms) does not caselessly match the character at 0x178, C<LATIN
267 CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be C<LATIN SMALL
268 LETTER Y WITH DIAERESIS> in the current locale, and Perl has no way of
269 knowing if that character even exists in the locale, much less what code
270 point it is.
271
272 In a UTF-8 locale in v5.20 and later, the only visible difference
273 between locale and non-locale in regular expressions should be tainting
274 (see L<perlsec>).
275
276 This modifier may be specified to be the default by C<use locale>, but
277 see L</Which character set modifier is in effect?>.
278 X</l>
279
280 =head4 /u
281
282 means to use Unicode rules when pattern matching.  On ASCII platforms,
283 this means that the code points between 128 and 255 take on their
284 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
285 (Otherwise Perl considers their meanings to be undefined.)  Thus,
286 under this modifier, the ASCII platform effectively becomes a Unicode
287 platform; and hence, for example, C<\w> will match any of the more than
288 100_000 word characters in Unicode.
289
290 Unlike most locales, which are specific to a language and country pair,
291 Unicode classifies all the characters that are letters I<somewhere> in
292 the world as
293 C<\w>.  For example, your locale might not think that C<LATIN SMALL
294 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
295 Unicode does.  Similarly, all the characters that are decimal digits
296 somewhere in the world will match C<\d>; this is hundreds, not 10,
297 possible matches.  And some of those digits look like some of the 10
298 ASCII digits, but mean a different number, so a human could easily think
299 a number is a different quantity than it really is.  For example,
300 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
301 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
302 that are a mixture from different writing systems, creating a security
303 issue.  L<Unicode::UCD/num()> can be used to sort
304 this out.  Or the C</a> modifier can be used to force C<\d> to match
305 just the ASCII 0 through 9.
306
307 Also, under this modifier, case-insensitive matching works on the full
308 set of Unicode
309 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
310 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
311 if you're not prepared, might make it look like a hexadecimal constant,
312 presenting another potential security issue.  See
313 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
314 security issues.
315
316 This modifier may be specified to be the default by C<use feature
317 'unicode_strings>, C<use locale ':not_characters'>, or
318 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
319 but see L</Which character set modifier is in effect?>.
320 X</u>
321
322 =head4 /d
323
324 This modifier means to use the "Default" native rules of the platform
325 except when there is cause to use Unicode rules instead, as follows:
326
327 =over 4
328
329 =item 1
330
331 the target string is encoded in UTF-8; or
332
333 =item 2
334
335 the pattern is encoded in UTF-8; or
336
337 =item 3
338
339 the pattern explicitly mentions a code point that is above 255 (say by
340 C<\x{100}>); or
341
342 =item 4
343
344 the pattern uses a Unicode name (C<\N{...}>);  or
345
346 =item 5
347
348 the pattern uses a Unicode property (C<\p{...}>); or
349
350 =item 6
351
352 the pattern uses L</C<(?[ ])>>
353
354 =back
355
356 Another mnemonic for this modifier is "Depends", as the rules actually
357 used depend on various things, and as a result you can get unexpected
358 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
359 become rather infamous, leading to yet another (printable) name for this
360 modifier, "Dodgy".
361
362 Unless the pattern or string are encoded in UTF-8, only ASCII characters
363 can match positively.
364
365 Here are some examples of how that works on an ASCII platform:
366
367  $str =  "\xDF";      # $str is not in UTF-8 format.
368  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
369  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
370  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
371  chop $str;
372  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
373
374 This modifier is automatically selected by default when none of the
375 others are, so yet another name for it is "Default".
376
377 Because of the unexpected behaviors associated with this modifier, you
378 probably should only use it to maintain weird backward compatibilities.
379
380 =head4 /a (and /aa)
381
382 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
383 unlike the others, may be doubled-up to increase its effect.
384
385 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
386 the Posix character classes to match only in the ASCII range.  They thus
387 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
388 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
389 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, experimentally,
390 the vertical tab; C<\w> means the 63 characters
391 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
392 C<[[:print:]]> match only the appropriate ASCII-range characters.
393
394 This modifier is useful for people who only incidentally use Unicode,
395 and who do not wish to be burdened with its complexities and security
396 concerns.
397
398 With C</a>, one can write C<\d> with confidence that it will only match
399 ASCII characters, and should the need arise to match beyond ASCII, you
400 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
401 similar C<\p{...}> constructs that can match beyond ASCII both white
402 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
403 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
404 doesn't mean you can't use Unicode, it means that to get Unicode
405 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
406 signals Unicode.
407
408 As you would expect, this modifier causes, for example, C<\D> to mean
409 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
410 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
411 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
412 for C<\B>).
413
414 Otherwise, C</a> behaves like the C</u> modifier, in that
415 case-insensitive matching uses Unicode rules; for example, "k" will
416 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
417 points in the Latin1 range, above ASCII will have Unicode rules when it
418 comes to case-insensitive matching.
419
420 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
421 specify the "a" twice, for example C</aai> or C</aia>.  (The first
422 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
423 adds the C</i> restrictions.)  But, note that code points outside the
424 ASCII range will use Unicode rules for C</i> matching, so the modifier
425 doesn't really restrict things to just ASCII; it just forbids the
426 intermixing of ASCII and non-ASCII.
427
428 To summarize, this modifier provides protection for applications that
429 don't wish to be exposed to all of Unicode.  Specifying it twice
430 gives added protection.
431
432 This modifier may be specified to be the default by C<use re '/a'>
433 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
434 the C</u> modifier explicitly if there are a few regular expressions
435 where you do want full Unicode rules (but even here, it's best if
436 everything were under feature C<"unicode_strings">, along with the
437 C<use re '/aa'>).  Also see L</Which character set modifier is in
438 effect?>.
439 X</a>
440 X</aa>
441
442 =head4 Which character set modifier is in effect?
443
444 Which of these modifiers is in effect at any given point in a regular
445 expression depends on a fairly complex set of interactions.  These have
446 been designed so that in general you don't have to worry about it, but
447 this section gives the gory details.  As
448 explained below in L</Extended Patterns> it is possible to explicitly
449 specify modifiers that apply only to portions of a regular expression.
450 The innermost always has priority over any outer ones, and one applying
451 to the whole expression has priority over any of the default settings that are
452 described in the remainder of this section.
453
454 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
455 default modifiers (including these) for regular expressions compiled
456 within its scope.  This pragma has precedence over the other pragmas
457 listed below that also change the defaults.
458
459 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
460 and C<L<use feature 'unicode_strings|feature>>, or
461 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
462 C</u> when not in the same scope as either C<L<use locale|perllocale>>
463 or C<L<use bytes|bytes>>.
464 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
465 sets the default to C</u>, overriding any plain C<use locale>.)
466 Unlike the mechanisms mentioned above, these
467 affect operations besides regular expressions pattern matching, and so
468 give more consistent results with other operators, including using
469 C<\U>, C<\l>, etc. in substitution replacements.
470
471 If none of the above apply, for backwards compatibility reasons, the
472 C</d> modifier is the one in effect by default.  As this can lead to
473 unexpected results, it is best to specify which other rule set should be
474 used.
475
476 =head4 Character set modifier behavior prior to Perl 5.14
477
478 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
479 for regexes compiled within the scope of C<use locale>, and C</d> was
480 implied otherwise.  However, interpolating a regex into a larger regex
481 would ignore the original compilation in favor of whatever was in effect
482 at the time of the second compilation.  There were a number of
483 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
484 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
485 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
486
487 =head2 Regular Expressions
488
489 =head3 Metacharacters
490
491 The patterns used in Perl pattern matching evolved from those supplied in
492 the Version 8 regex routines.  (The routines are derived
493 (distantly) from Henry Spencer's freely redistributable reimplementation
494 of the V8 routines.)  See L<Version 8 Regular Expressions> for
495 details.
496
497 In particular the following metacharacters have their standard I<egrep>-ish
498 meanings:
499 X<metacharacter>
500 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
501
502
503     \        Quote the next metacharacter
504     ^        Match the beginning of the line
505     .        Match any character (except newline)
506     $        Match the end of the string (or before newline at the end
507              of the string)
508     |        Alternation
509     ()       Grouping
510     []       Bracketed Character class
511
512 By default, the "^" character is guaranteed to match only the
513 beginning of the string, the "$" character only the end (or before the
514 newline at the end), and Perl does certain optimizations with the
515 assumption that the string contains only one line.  Embedded newlines
516 will not be matched by "^" or "$".  You may, however, wish to treat a
517 string as a multi-line buffer, such that the "^" will match after any
518 newline within the string (except if the newline is the last character in
519 the string), and "$" will match before any newline.  At the
520 cost of a little more overhead, you can do this by using the /m modifier
521 on the pattern match operator.  (Older programs did this by setting C<$*>,
522 but this option was removed in perl 5.10.)
523 X<^> X<$> X</m>
524
525 To simplify multi-line substitutions, the "." character never matches a
526 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
527 the string is a single line--even if it isn't.
528 X<.> X</s>
529
530 =head3 Quantifiers
531
532 The following standard quantifiers are recognized:
533 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
534
535     *           Match 0 or more times
536     +           Match 1 or more times
537     ?           Match 1 or 0 times
538     {n}         Match exactly n times
539     {n,}        Match at least n times
540     {n,m}       Match at least n but not more than m times
541
542 (If a curly bracket occurs in any other context and does not form part of
543 a backslashed sequence like C<\x{...}>, it is treated as a regular
544 character.  In particular, the lower quantifier bound is not optional,
545 and a typo in a quantifier silently causes it to be treated as the
546 literal characters.  For example,
547
548     /o{4,a}/
549
550 compiles to match the sequence of six characters
551 S<C<"o { 4 , a }">>.  It is planned to eventually require literal uses
552 of curly brackets to be escaped, say by preceding them with a backslash
553 or enclosing them within square brackets, (C<"\{"> or C<"[{]">).  This
554 change will allow for future syntax extensions (like making the lower
555 bound of a quantifier optional), and better error checking.  In the
556 meantime, you should get in the habit of escaping all instances where
557 you mean a literal "{".)
558
559 The "*" quantifier is equivalent to C<{0,}>, the "+"
560 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
561 to non-negative integral values less than a preset limit defined when perl is built.
562 This is usually 32766 on the most common platforms.  The actual limit can
563 be seen in the error message generated by code such as this:
564
565     $_ **= $_ , / {$_} / for 2 .. 42;
566
567 By default, a quantified subpattern is "greedy", that is, it will match as
568 many times as possible (given a particular starting location) while still
569 allowing the rest of the pattern to match.  If you want it to match the
570 minimum number of times possible, follow the quantifier with a "?".  Note
571 that the meanings don't change, just the "greediness":
572 X<metacharacter> X<greedy> X<greediness>
573 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
574
575     *?        Match 0 or more times, not greedily
576     +?        Match 1 or more times, not greedily
577     ??        Match 0 or 1 time, not greedily
578     {n}?      Match exactly n times, not greedily (redundant)
579     {n,}?     Match at least n times, not greedily
580     {n,m}?    Match at least n but not more than m times, not greedily
581
582 Normally when a quantified subpattern does not allow the rest of the
583 overall pattern to match, Perl will backtrack. However, this behaviour is
584 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
585 as well.
586
587  *+     Match 0 or more times and give nothing back
588  ++     Match 1 or more times and give nothing back
589  ?+     Match 0 or 1 time and give nothing back
590  {n}+   Match exactly n times and give nothing back (redundant)
591  {n,}+  Match at least n times and give nothing back
592  {n,m}+ Match at least n but not more than m times and give nothing back
593
594 For instance,
595
596    'aaaa' =~ /a++a/
597
598 will never match, as the C<a++> will gobble up all the C<a>'s in the
599 string and won't leave any for the remaining part of the pattern. This
600 feature can be extremely useful to give perl hints about where it
601 shouldn't backtrack. For instance, the typical "match a double-quoted
602 string" problem can be most efficiently performed when written as:
603
604    /"(?:[^"\\]++|\\.)*+"/
605
606 as we know that if the final quote does not match, backtracking will not
607 help. See the independent subexpression
608 L</C<< (?>pattern) >>> for more details;
609 possessive quantifiers are just syntactic sugar for that construct. For
610 instance the above example could also be written as follows:
611
612    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
613
614 Note that the possessive quantifier modifier can not be be combined
615 with the non-greedy modifier. This is because it would make no sense.
616 Consider the follow equivalency table:
617
618     Illegal         Legal
619     ------------    ------
620     X??+            X{0}
621     X+?+            X{1}
622     X{min,max}?+    X{min}
623
624 =head3 Escape sequences
625
626 Because patterns are processed as double-quoted strings, the following
627 also work:
628
629  \t          tab                   (HT, TAB)
630  \n          newline               (LF, NL)
631  \r          return                (CR)
632  \f          form feed             (FF)
633  \a          alarm (bell)          (BEL)
634  \e          escape (think troff)  (ESC)
635  \cK         control char          (example: VT)
636  \x{}, \x00  character whose ordinal is the given hexadecimal number
637  \N{name}    named Unicode character or character sequence
638  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
639  \o{}, \000  character whose ordinal is the given octal number
640  \l          lowercase next char (think vi)
641  \u          uppercase next char (think vi)
642  \L          lowercase till \E (think vi)
643  \U          uppercase till \E (think vi)
644  \Q          quote (disable) pattern metacharacters till \E
645  \E          end either case modification or quoted section, think vi
646
647 Details are in L<perlop/Quote and Quote-like Operators>.
648
649 =head3 Character Classes and other Special Escapes
650
651 In addition, Perl defines the following:
652 X<\g> X<\k> X<\K> X<backreference>
653
654  Sequence   Note    Description
655   [...]     [1]  Match a character according to the rules of the
656                    bracketed character class defined by the "...".
657                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
658   [[:...:]] [2]  Match a character according to the rules of the POSIX
659                    character class "..." within the outer bracketed
660                    character class.  Example: [[:upper:]] matches any
661                    uppercase character.
662   (?[...])  [8]  Extended bracketed character class
663   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
664                    other connector punctuation chars plus Unicode
665                    marks)
666   \W        [3]  Match a non-"word" character
667   \s        [3]  Match a whitespace character
668   \S        [3]  Match a non-whitespace character
669   \d        [3]  Match a decimal digit character
670   \D        [3]  Match a non-digit character
671   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
672   \PP       [3]  Match non-P
673   \X        [4]  Match Unicode "eXtended grapheme cluster"
674   \C             Match a single C-language char (octet) even if that is
675                    part of a larger UTF-8 character.  Thus it breaks up
676                    characters into their UTF-8 bytes, so you may end up
677                    with malformed pieces of UTF-8.  Unsupported in
678                    lookbehind. (Deprecated.)
679   \1        [5]  Backreference to a specific capture group or buffer.
680                    '1' may actually be any positive integer.
681   \g1       [5]  Backreference to a specific or previous group,
682   \g{-1}    [5]  The number may be negative indicating a relative
683                    previous group and may optionally be wrapped in
684                    curly brackets for safer parsing.
685   \g{name}  [5]  Named backreference
686   \k<name>  [5]  Named backreference
687   \K        [6]  Keep the stuff left of the \K, don't include it in $&
688   \N        [7]  Any character but \n.  Not affected by /s modifier
689   \v        [3]  Vertical whitespace
690   \V        [3]  Not vertical whitespace
691   \h        [3]  Horizontal whitespace
692   \H        [3]  Not horizontal whitespace
693   \R        [4]  Linebreak
694
695 =over 4
696
697 =item [1]
698
699 See L<perlrecharclass/Bracketed Character Classes> for details.
700
701 =item [2]
702
703 See L<perlrecharclass/POSIX Character Classes> for details.
704
705 =item [3]
706
707 See L<perlrecharclass/Backslash sequences> for details.
708
709 =item [4]
710
711 See L<perlrebackslash/Misc> for details.
712
713 =item [5]
714
715 See L</Capture groups> below for details.
716
717 =item [6]
718
719 See L</Extended Patterns> below for details.
720
721 =item [7]
722
723 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
724 character or character sequence whose name is C<NAME>; and similarly
725 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
726 code point is I<hex>.  Otherwise it matches any character but C<\n>.
727
728 =item [8]
729
730 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
731
732 =back
733
734 =head3 Assertions
735
736 Perl defines the following zero-width assertions:
737 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
738 X<regexp, zero-width assertion>
739 X<regular expression, zero-width assertion>
740 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
741
742     \b  Match a word boundary
743     \B  Match except at a word boundary
744     \A  Match only at beginning of string
745     \Z  Match only at end of string, or before newline at the end
746     \z  Match only at end of string
747     \G  Match only at pos() (e.g. at the end-of-match position
748         of prior m//g)
749
750 A word boundary (C<\b>) is a spot between two characters
751 that has a C<\w> on one side of it and a C<\W> on the other side
752 of it (in either order), counting the imaginary characters off the
753 beginning and end of the string as matching a C<\W>.  (Within
754 character classes C<\b> represents backspace rather than a word
755 boundary, just as it normally does in any double-quoted string.)
756 The C<\A> and C<\Z> are just like "^" and "$", except that they
757 won't match multiple times when the C</m> modifier is used, while
758 "^" and "$" will match at every internal line boundary.  To match
759 the actual end of the string and not ignore an optional trailing
760 newline, use C<\z>.
761 X<\b> X<\A> X<\Z> X<\z> X</m>
762
763 The C<\G> assertion can be used to chain global matches (using
764 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
765 It is also useful when writing C<lex>-like scanners, when you have
766 several patterns that you want to match against consequent substrings
767 of your string; see the previous reference.  The actual location
768 where C<\G> will match can also be influenced by using C<pos()> as
769 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
770 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
771 is modified somewhat, in that contents to the left of C<\G> are
772 not counted when determining the length of the match. Thus the following
773 will not match forever:
774 X<\G>
775
776      my $string = 'ABC';
777      pos($string) = 1;
778      while ($string =~ /(.\G)/g) {
779          print $1;
780      }
781
782 It will print 'A' and then terminate, as it considers the match to
783 be zero-width, and thus will not match at the same position twice in a
784 row.
785
786 It is worth noting that C<\G> improperly used can result in an infinite
787 loop. Take care when using patterns that include C<\G> in an alternation.
788
789 Note also that C<s///> will refuse to overwrite part of a substitution
790 that has already been replaced; so for example this will stop after the
791 first iteration, rather than iterating its way backwards through the
792 string:
793
794     $_ = "123456789";
795     pos = 6;
796     s/.(?=.\G)/X/g;
797     print;      # prints 1234X6789, not XXXXX6789
798
799
800 =head3 Capture groups
801
802 The bracketing construct C<( ... )> creates capture groups (also referred to as
803 capture buffers). To refer to the current contents of a group later on, within
804 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
805 for the second, and so on.
806 This is called a I<backreference>.
807 X<regex, capture buffer> X<regexp, capture buffer>
808 X<regex, capture group> X<regexp, capture group>
809 X<regular expression, capture buffer> X<backreference>
810 X<regular expression, capture group> X<backreference>
811 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
812 X<named capture buffer> X<regular expression, named capture buffer>
813 X<named capture group> X<regular expression, named capture group>
814 X<%+> X<$+{name}> X<< \k<name> >>
815 There is no limit to the number of captured substrings that you may use.
816 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
817 a group did not match, the associated backreference won't match either. (This
818 can happen if the group is optional, or in a different branch of an
819 alternation.)
820 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
821 this form, described below.
822
823 You can also refer to capture groups relatively, by using a negative number, so
824 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
825 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
826 example:
827
828         /
829          (Y)            # group 1
830          (              # group 2
831             (X)         # group 3
832             \g{-1}      # backref to group 3
833             \g{-3}      # backref to group 1
834          )
835         /x
836
837 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
838 interpolate regexes into larger regexes and not have to worry about the
839 capture groups being renumbered.
840
841 You can dispense with numbers altogether and create named capture groups.
842 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
843 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
844 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
845 I<name> must not begin with a number, nor contain hyphens.
846 When different groups within the same pattern have the same name, any reference
847 to that name assumes the leftmost defined group.  Named groups count in
848 absolute and relative numbering, and so can also be referred to by those
849 numbers.
850 (It's possible to do things with named capture groups that would otherwise
851 require C<(??{})>.)
852
853 Capture group contents are dynamically scoped and available to you outside the
854 pattern until the end of the enclosing block or until the next successful
855 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
856 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
857 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
858
859 Braces are required in referring to named capture groups, but are optional for
860 absolute or relative numbered ones.  Braces are safer when creating a regex by
861 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
862 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
863 is probably not what you intended.
864
865 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
866 there were no named nor relative numbered capture groups.  Absolute numbered
867 groups were referred to using C<\1>,
868 C<\2>, etc., and this notation is still
869 accepted (and likely always will be).  But it leads to some ambiguities if
870 there are more than 9 capture groups, as C<\10> could mean either the tenth
871 capture group, or the character whose ordinal in octal is 010 (a backspace in
872 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
873 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
874 a backreference only if at least 11 left parentheses have opened before it.
875 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
876 There are several examples below that illustrate these perils.  You can avoid
877 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
878 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
879 digits padded with leading zeros, since a leading zero implies an octal
880 constant.
881
882 The C<\I<digit>> notation also works in certain circumstances outside
883 the pattern.  See L</Warning on \1 Instead of $1> below for details.
884
885 Examples:
886
887     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
888
889     /(.)\g1/                        # find first doubled char
890          and print "'$1' is the first doubled character\n";
891
892     /(?<char>.)\k<char>/            # ... a different way
893          and print "'$+{char}' is the first doubled character\n";
894
895     /(?'char'.)\g1/                 # ... mix and match
896          and print "'$1' is the first doubled character\n";
897
898     if (/Time: (..):(..):(..)/) {   # parse out values
899         $hours = $1;
900         $minutes = $2;
901         $seconds = $3;
902     }
903
904     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
905     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
906     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
907     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
908
909     $a = '(.)\1';        # Creates problems when concatenated.
910     $b = '(.)\g{1}';     # Avoids the problems.
911     "aa" =~ /${a}/;      # True
912     "aa" =~ /${b}/;      # True
913     "aa0" =~ /${a}0/;    # False!
914     "aa0" =~ /${b}0/;    # True
915     "aa\x08" =~ /${a}0/;  # True!
916     "aa\x08" =~ /${b}0/;  # False
917
918 Several special variables also refer back to portions of the previous
919 match.  C<$+> returns whatever the last bracket match matched.
920 C<$&> returns the entire matched string.  (At one point C<$0> did
921 also, but now it returns the name of the program.)  C<$`> returns
922 everything before the matched string.  C<$'> returns everything
923 after the matched string. And C<$^N> contains whatever was matched by
924 the most-recently closed group (submatch). C<$^N> can be used in
925 extended patterns (see below), for example to assign a submatch to a
926 variable.
927 X<$+> X<$^N> X<$&> X<$`> X<$'>
928
929 These special variables, like the C<%+> hash and the numbered match variables
930 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
931 until the end of the enclosing block or until the next successful
932 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
933 X<$+> X<$^N> X<$&> X<$`> X<$'>
934 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
935
936 B<NOTE>: Failed matches in Perl do not reset the match variables,
937 which makes it easier to write code that tests for a series of more
938 specific cases and remembers the best match.
939
940 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
941 beware that once Perl sees that you need one of C<$&>, C<$`>, or
942 C<$'> anywhere in the program, it has to provide them for every
943 pattern match.  This may substantially slow your program.
944
945 Perl uses the same mechanism to produce C<$1>, C<$2>, etc, so you also
946 pay a price for each pattern that contains capturing parentheses.
947 (To avoid this cost while retaining the grouping behaviour, use the
948 extended regular expression C<(?: ... )> instead.)  But if you never
949 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
950 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
951 if you can, but if you can't (and some algorithms really appreciate
952 them), once you've used them once, use them at will, because you've
953 already paid the price.
954 X<$&> X<$`> X<$'>
955
956 Perl 5.16 introduced a slightly more efficient mechanism that notes
957 separately whether each of C<$`>, C<$&>, and C<$'> have been seen, and
958 thus may only need to copy part of the string.  Perl 5.20 introduced a
959 much more efficient copy-on-write mechanism which eliminates any slowdown.
960
961 As another workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
962 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
963 and C<$'>, B<except> that they are only guaranteed to be defined after a
964 successful match that was executed with the C</p> (preserve) modifier.
965 The use of these variables incurs no global performance penalty, unlike
966 their punctuation char equivalents, however at the trade-off that you
967 have to tell perl when you want to use them.  As of Perl 5.20, these three
968 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
969 X</p> X<p modifier>
970
971 =head2 Quoting metacharacters
972
973 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
974 C<\w>, C<\n>.  Unlike some other regular expression languages, there
975 are no backslashed symbols that aren't alphanumeric.  So anything
976 that looks like \\, \(, \), \[, \], \{, or \} is always
977 interpreted as a literal character, not a metacharacter.  This was
978 once used in a common idiom to disable or quote the special meanings
979 of regular expression metacharacters in a string that you want to
980 use for a pattern. Simply quote all non-"word" characters:
981
982     $pattern =~ s/(\W)/\\$1/g;
983
984 (If C<use locale> is set, then this depends on the current locale.)
985 Today it is more common to use the quotemeta() function or the C<\Q>
986 metaquoting escape sequence to disable all metacharacters' special
987 meanings like this:
988
989     /$unquoted\Q$quoted\E$unquoted/
990
991 Beware that if you put literal backslashes (those not inside
992 interpolated variables) between C<\Q> and C<\E>, double-quotish
993 backslash interpolation may lead to confusing results.  If you
994 I<need> to use literal backslashes within C<\Q...\E>,
995 consult L<perlop/"Gory details of parsing quoted constructs">.
996
997 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
998
999 =head2 Extended Patterns
1000
1001 Perl also defines a consistent extension syntax for features not
1002 found in standard tools like B<awk> and
1003 B<lex>.  The syntax for most of these is a
1004 pair of parentheses with a question mark as the first thing within
1005 the parentheses.  The character after the question mark indicates
1006 the extension.
1007
1008 The stability of these extensions varies widely.  Some have been
1009 part of the core language for many years.  Others are experimental
1010 and may change without warning or be completely removed.  Check
1011 the documentation on an individual feature to verify its current
1012 status.
1013
1014 A question mark was chosen for this and for the minimal-matching
1015 construct because 1) question marks are rare in older regular
1016 expressions, and 2) whenever you see one, you should stop and
1017 "question" exactly what is going on.  That's psychology....
1018
1019 =over 4
1020
1021 =item C<(?#text)>
1022 X<(?#)>
1023
1024 A comment.  The text is ignored.
1025 Note that Perl closes
1026 the comment as soon as it sees a C<)>, so there is no way to put a literal
1027 C<)> in the comment.  The pattern's closing delimiter must be escaped by
1028 a backslash if it appears in the comment.
1029
1030 See L</E<sol>x> for another way to have comments in patterns.
1031
1032 =item C<(?adlupimsx-imsx)>
1033
1034 =item C<(?^alupimsx)>
1035 X<(?)> X<(?^)>
1036
1037 One or more embedded pattern-match modifiers, to be turned on (or
1038 turned off, if preceded by C<->) for the remainder of the pattern or
1039 the remainder of the enclosing pattern group (if any).
1040
1041 This is particularly useful for dynamic patterns, such as those read in from a
1042 configuration file, taken from an argument, or specified in a table
1043 somewhere.  Consider the case where some patterns want to be
1044 case-sensitive and some do not:  The case-insensitive ones merely need to
1045 include C<(?i)> at the front of the pattern.  For example:
1046
1047     $pattern = "foobar";
1048     if ( /$pattern/i ) { }
1049
1050     # more flexible:
1051
1052     $pattern = "(?i)foobar";
1053     if ( /$pattern/ ) { }
1054
1055 These modifiers are restored at the end of the enclosing group. For example,
1056
1057     ( (?i) blah ) \s+ \g1
1058
1059 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
1060 repetition of the previous word, assuming the C</x> modifier, and no C</i>
1061 modifier outside this group.
1062
1063 These modifiers do not carry over into named subpatterns called in the
1064 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1065 change the case-sensitivity of the "NAME" pattern.
1066
1067 Any of these modifiers can be set to apply globally to all regular
1068 expressions compiled within the scope of a C<use re>.  See
1069 L<re/"'/flags' mode">.
1070
1071 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1072 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
1073 C<"d">) may follow the caret to override it.
1074 But a minus sign is not legal with it.
1075
1076 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
1077 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
1078 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1079 others, and a maximum of one (or two C<a>'s) may appear in the
1080 construct.  Thus, for
1081 example, C<(?-p)> will warn when compiled under C<use warnings>;
1082 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1083
1084 Note also that the C<p> modifier is special in that its presence
1085 anywhere in a pattern has a global effect.
1086
1087 =item C<(?:pattern)>
1088 X<(?:)>
1089
1090 =item C<(?adluimsx-imsx:pattern)>
1091
1092 =item C<(?^aluimsx:pattern)>
1093 X<(?^:)>
1094
1095 This is for clustering, not capturing; it groups subexpressions like
1096 "()", but doesn't make backreferences as "()" does.  So
1097
1098     @fields = split(/\b(?:a|b|c)\b/)
1099
1100 is like
1101
1102     @fields = split(/\b(a|b|c)\b/)
1103
1104 but doesn't spit out extra fields.  It's also cheaper not to capture
1105 characters if you don't need to.
1106
1107 Any letters between C<?> and C<:> act as flags modifiers as with
1108 C<(?adluimsx-imsx)>.  For example,
1109
1110     /(?s-i:more.*than).*million/i
1111
1112 is equivalent to the more verbose
1113
1114     /(?:(?s-i)more.*than).*million/i
1115
1116 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1117 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1118 flags (except C<"d">) may follow the caret, so
1119
1120     (?^x:foo)
1121
1122 is equivalent to
1123
1124     (?x-ims:foo)
1125
1126 The caret tells Perl that this cluster doesn't inherit the flags of any
1127 surrounding pattern, but uses the system defaults (C<d-imsx>),
1128 modified by any flags specified.
1129
1130 The caret allows for simpler stringification of compiled regular
1131 expressions.  These look like
1132
1133     (?^:pattern)
1134
1135 with any non-default flags appearing between the caret and the colon.
1136 A test that looks at such stringification thus doesn't need to have the
1137 system default flags hard-coded in it, just the caret.  If new flags are
1138 added to Perl, the meaning of the caret's expansion will change to include
1139 the default for those flags, so the test will still work, unchanged.
1140
1141 Specifying a negative flag after the caret is an error, as the flag is
1142 redundant.
1143
1144 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1145 to match at the beginning.
1146
1147 =item C<(?|pattern)>
1148 X<(?|)> X<Branch reset>
1149
1150 This is the "branch reset" pattern, which has the special property
1151 that the capture groups are numbered from the same starting point
1152 in each alternation branch. It is available starting from perl 5.10.0.
1153
1154 Capture groups are numbered from left to right, but inside this
1155 construct the numbering is restarted for each branch.
1156
1157 The numbering within each branch will be as normal, and any groups
1158 following this construct will be numbered as though the construct
1159 contained only one branch, that being the one with the most capture
1160 groups in it.
1161
1162 This construct is useful when you want to capture one of a
1163 number of alternative matches.
1164
1165 Consider the following pattern.  The numbers underneath show in
1166 which group the captured content will be stored.
1167
1168
1169     # before  ---------------branch-reset----------- after        
1170     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1171     # 1            2         2  3        2     3     4  
1172
1173 Be careful when using the branch reset pattern in combination with 
1174 named captures. Named captures are implemented as being aliases to 
1175 numbered groups holding the captures, and that interferes with the
1176 implementation of the branch reset pattern. If you are using named
1177 captures in a branch reset pattern, it's best to use the same names,
1178 in the same order, in each of the alternations:
1179
1180    /(?|  (?<a> x ) (?<b> y )
1181       |  (?<a> z ) (?<b> w )) /x
1182
1183 Not doing so may lead to surprises:
1184
1185   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1186   say $+ {a};   # Prints '12'
1187   say $+ {b};   # *Also* prints '12'.
1188
1189 The problem here is that both the group named C<< a >> and the group
1190 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1191
1192 =item Look-Around Assertions
1193 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1194
1195 Look-around assertions are zero-width patterns which match a specific
1196 pattern without including it in C<$&>. Positive assertions match when
1197 their subpattern matches, negative assertions match when their subpattern
1198 fails. Look-behind matches text up to the current match position,
1199 look-ahead matches text following the current match position.
1200
1201 =over 4
1202
1203 =item C<(?=pattern)>
1204 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1205
1206 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1207 matches a word followed by a tab, without including the tab in C<$&>.
1208
1209 =item C<(?!pattern)>
1210 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1211
1212 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1213 matches any occurrence of "foo" that isn't followed by "bar".  Note
1214 however that look-ahead and look-behind are NOT the same thing.  You cannot
1215 use this for look-behind.
1216
1217 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1218 will not do what you want.  That's because the C<(?!foo)> is just saying that
1219 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1220 match.  Use look-behind instead (see below).
1221
1222 =item C<(?<=pattern)> C<\K>
1223 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1224
1225 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1226 matches a word that follows a tab, without including the tab in C<$&>.
1227 Works only for fixed-width look-behind.
1228
1229 There is a special form of this construct, called C<\K>, which causes the
1230 regex engine to "keep" everything it had matched prior to the C<\K> and
1231 not include it in C<$&>. This effectively provides variable-length
1232 look-behind. The use of C<\K> inside of another look-around assertion
1233 is allowed, but the behaviour is currently not well defined.
1234
1235 For various reasons C<\K> may be significantly more efficient than the
1236 equivalent C<< (?<=...) >> construct, and it is especially useful in
1237 situations where you want to efficiently remove something following
1238 something else in a string. For instance
1239
1240   s/(foo)bar/$1/g;
1241
1242 can be rewritten as the much more efficient
1243
1244   s/foo\Kbar//g;
1245
1246 =item C<(?<!pattern)>
1247 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1248
1249 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1250 matches any occurrence of "foo" that does not follow "bar".  Works
1251 only for fixed-width look-behind.
1252
1253 =back
1254
1255 =item C<(?'NAME'pattern)>
1256
1257 =item C<< (?<NAME>pattern) >>
1258 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1259
1260 A named capture group. Identical in every respect to normal capturing
1261 parentheses C<()> but for the additional fact that the group
1262 can be referred to by name in various regular expression
1263 constructs (like C<\g{NAME}>) and can be accessed by name
1264 after a successful match via C<%+> or C<%->. See L<perlvar>
1265 for more details on the C<%+> and C<%-> hashes.
1266
1267 If multiple distinct capture groups have the same name then the
1268 $+{NAME} will refer to the leftmost defined group in the match.
1269
1270 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1271
1272 B<NOTE:> While the notation of this construct is the same as the similar
1273 function in .NET regexes, the behavior is not. In Perl the groups are
1274 numbered sequentially regardless of being named or not. Thus in the
1275 pattern
1276
1277   /(x)(?<foo>y)(z)/
1278
1279 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1280 the opposite which is what a .NET regex hacker might expect.
1281
1282 Currently NAME is restricted to simple identifiers only.
1283 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1284 its Unicode extension (see L<utf8>),
1285 though it isn't extended by the locale (see L<perllocale>).
1286
1287 B<NOTE:> In order to make things easier for programmers with experience
1288 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1289 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1290 support the use of single quotes as a delimiter for the name.
1291
1292 =item C<< \k<NAME> >>
1293
1294 =item C<< \k'NAME' >>
1295
1296 Named backreference. Similar to numeric backreferences, except that
1297 the group is designated by name and not number. If multiple groups
1298 have the same name then it refers to the leftmost defined group in
1299 the current match.
1300
1301 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1302 earlier in the pattern.
1303
1304 Both forms are equivalent.
1305
1306 B<NOTE:> In order to make things easier for programmers with experience
1307 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1308 may be used instead of C<< \k<NAME> >>.
1309
1310 =item C<(?{ code })>
1311 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1312
1313 B<WARNING>: Using this feature safely requires that you understand its
1314 limitations.  Code executed that has side effects may not perform identically
1315 from version to version due to the effect of future optimisations in the regex
1316 engine.  For more information on this, see L</Embedded Code Execution
1317 Frequency>.
1318
1319 This zero-width assertion executes any embedded Perl code.  It always
1320 succeeds, and its return value is set as C<$^R>.
1321
1322 In literal patterns, the code is parsed at the same time as the
1323 surrounding code. While within the pattern, control is passed temporarily
1324 back to the perl parser, until the logically-balancing closing brace is
1325 encountered. This is similar to the way that an array index expression in
1326 a literal string is handled, for example
1327
1328     "abc$array[ 1 + f('[') + g()]def"
1329
1330 In particular, braces do not need to be balanced:
1331
1332     s/abc(?{ f('{'); })/def/
1333
1334 Even in a pattern that is interpolated and compiled at run-time, literal
1335 code blocks will be compiled once, at perl compile time; the following
1336 prints "ABCD":
1337
1338     print "D";
1339     my $qr = qr/(?{ BEGIN { print "A" } })/;
1340     my $foo = "foo";
1341     /$foo$qr(?{ BEGIN { print "B" } })/;
1342     BEGIN { print "C" }
1343
1344 In patterns where the text of the code is derived from run-time
1345 information rather than appearing literally in a source code /pattern/,
1346 the code is compiled at the same time that the pattern is compiled, and
1347 for reasons of security, C<use re 'eval'> must be in scope. This is to
1348 stop user-supplied patterns containing code snippets from being
1349 executable.
1350
1351 In situations where you need to enable this with C<use re 'eval'>, you should
1352 also have taint checking enabled.  Better yet, use the carefully
1353 constrained evaluation within a Safe compartment.  See L<perlsec> for
1354 details about both these mechanisms.
1355
1356 From the viewpoint of parsing, lexical variable scope and closures,
1357
1358     /AAA(?{ BBB })CCC/
1359
1360 behaves approximately like
1361
1362     /AAA/ && do { BBB } && /CCC/
1363
1364 Similarly,
1365
1366     qr/AAA(?{ BBB })CCC/
1367
1368 behaves approximately like
1369
1370     sub { /AAA/ && do { BBB } && /CCC/ }
1371
1372 In particular:
1373
1374     { my $i = 1; $r = qr/(?{ print $i })/ }
1375     my $i = 2;
1376     /$r/; # prints "1"
1377
1378 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1379 expression is matching against. You can also use C<pos()> to know what is
1380 the current position of matching within this string.
1381
1382 The code block introduces a new scope from the perspective of lexical
1383 variable declarations, but B<not> from the perspective of C<local> and
1384 similar localizing behaviours. So later code blocks within the same
1385 pattern will still see the values which were localized in earlier blocks.
1386 These accumulated localizations are undone either at the end of a
1387 successful match, or if the assertion is backtracked (compare
1388 L<"Backtracking">). For example,
1389
1390   $_ = 'a' x 8;
1391   m<
1392      (?{ $cnt = 0 })               # Initialize $cnt.
1393      (
1394        a
1395        (?{
1396            local $cnt = $cnt + 1;  # Update $cnt,
1397                                    # backtracking-safe.
1398        })
1399      )*
1400      aaaa
1401      (?{ $res = $cnt })            # On success copy to
1402                                    # non-localized location.
1403    >x;
1404
1405 will initially increment C<$cnt> up to 8; then during backtracking, its
1406 value will be unwound back to 4, which is the value assigned to C<$res>.
1407 At the end of the regex execution, $cnt will be wound back to its initial
1408 value of 0.
1409
1410 This assertion may be used as the condition in a
1411
1412     (?(condition)yes-pattern|no-pattern)
1413
1414 switch.  If I<not> used in this way, the result of evaluation of C<code>
1415 is put into the special variable C<$^R>.  This happens immediately, so
1416 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1417 regular expression.
1418
1419 The assignment to C<$^R> above is properly localized, so the old
1420 value of C<$^R> is restored if the assertion is backtracked; compare
1421 L<"Backtracking">.
1422
1423 Note that the special variable C<$^N>  is particularly useful with code
1424 blocks to capture the results of submatches in variables without having to
1425 keep track of the number of nested parentheses. For example:
1426
1427   $_ = "The brown fox jumps over the lazy dog";
1428   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1429   print "color = $color, animal = $animal\n";
1430
1431
1432 =item C<(??{ code })>
1433 X<(??{})>
1434 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1435
1436 B<WARNING>: Using this feature safely requires that you understand its
1437 limitations.  Code executed that has side effects may not perform
1438 identically from version to version due to the effect of future
1439 optimisations in the regex engine.  For more information on this, see
1440 L</Embedded Code Execution Frequency>.
1441
1442 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1443 same way as a C<(?{ code })> code block as described above, except that
1444 its return value, rather than being assigned to C<$^R>, is treated as a
1445 pattern, compiled if it's a string (or used as-is if its a qr// object),
1446 then matched as if it were inserted instead of this construct.
1447
1448 During the matching of this sub-pattern, it has its own set of
1449 captures which are valid during the sub-match, but are discarded once
1450 control returns to the main pattern. For example, the following matches,
1451 with the inner pattern capturing "B" and matching "BB", while the outer
1452 pattern captures "A";
1453
1454     my $inner = '(.)\1';
1455     "ABBA" =~ /^(.)(??{ $inner })\1/;
1456     print $1; # prints "A";
1457
1458 Note that this means that  there is no way for the inner pattern to refer
1459 to a capture group defined outside.  (The code block itself can use C<$1>,
1460 etc., to refer to the enclosing pattern's capture groups.)  Thus, although
1461
1462     ('a' x 100)=~/(??{'(.)' x 100})/
1463
1464 I<will> match, it will I<not> set $1 on exit.
1465
1466 The following pattern matches a parenthesized group:
1467
1468  $re = qr{
1469             \(
1470             (?:
1471                (?> [^()]+ )  # Non-parens without backtracking
1472              |
1473                (??{ $re })   # Group with matching parens
1474             )*
1475             \)
1476          }x;
1477
1478 See also
1479 L<C<(?I<PARNO>)>|/(?PARNO) (?-PARNO) (?+PARNO) (?R) (?0)>
1480 for a different, more efficient way to accomplish
1481 the same task.
1482
1483 Executing a postponed regular expression 50 times without consuming any
1484 input string will result in a fatal error.  The maximum depth is compiled
1485 into perl, so changing it requires a custom build.
1486
1487 =item C<(?I<PARNO>)> C<(?-I<PARNO>)> C<(?+I<PARNO>)> C<(?R)> C<(?0)>
1488 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1489 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1490 X<regex, relative recursion> X<GOSUB> X<GOSTART>
1491
1492 Recursive subpattern. Treat the contents of a given capture buffer in the
1493 current pattern as an independent subpattern and attempt to match it at
1494 the current position in the string. Information about capture state from
1495 the caller for things like backreferences is available to the subpattern,
1496 but capture buffers set by the subpattern are not visible to the caller.
1497
1498 Similar to C<(??{ code })> except that it does not involve executing any
1499 code or potentially compiling a returned pattern string; instead it treats
1500 the part of the current pattern contained within a specified capture group
1501 as an independent pattern that must match at the current position. Also
1502 different is the treatment of capture buffers, unlike C<(??{ code })>
1503 recursive patterns have access to their callers match state, so one can
1504 use backreferences safely.
1505
1506 I<PARNO> is a sequence of digits (not starting with 0) whose value reflects
1507 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1508 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1509 C<(?R)>. If I<PARNO> is preceded by a plus or minus sign then it is assumed
1510 to be relative, with negative numbers indicating preceding capture groups
1511 and positive ones following. Thus C<(?-1)> refers to the most recently
1512 declared group, and C<(?+1)> indicates the next group to be declared.
1513 Note that the counting for relative recursion differs from that of
1514 relative backreferences, in that with recursion unclosed groups B<are>
1515 included.
1516
1517 The following pattern matches a function foo() which may contain
1518 balanced parentheses as the argument.
1519
1520   $re = qr{ (                   # paren group 1 (full function)
1521               foo
1522               (                 # paren group 2 (parens)
1523                 \(
1524                   (             # paren group 3 (contents of parens)
1525                   (?:
1526                    (?> [^()]+ ) # Non-parens without backtracking
1527                   |
1528                    (?2)         # Recurse to start of paren group 2
1529                   )*
1530                   )
1531                 \)
1532               )
1533             )
1534           }x;
1535
1536 If the pattern was used as follows
1537
1538     'foo(bar(baz)+baz(bop))'=~/$re/
1539         and print "\$1 = $1\n",
1540                   "\$2 = $2\n",
1541                   "\$3 = $3\n";
1542
1543 the output produced should be the following:
1544
1545     $1 = foo(bar(baz)+baz(bop))
1546     $2 = (bar(baz)+baz(bop))
1547     $3 = bar(baz)+baz(bop)
1548
1549 If there is no corresponding capture group defined, then it is a
1550 fatal error.  Recursing deeper than 50 times without consuming any input
1551 string will also result in a fatal error.  The maximum depth is compiled
1552 into perl, so changing it requires a custom build.
1553
1554 The following shows how using negative indexing can make it
1555 easier to embed recursive patterns inside of a C<qr//> construct
1556 for later use:
1557
1558     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1559     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1560        # do something here...
1561     }
1562
1563 B<Note> that this pattern does not behave the same way as the equivalent
1564 PCRE or Python construct of the same form. In Perl you can backtrack into
1565 a recursed group, in PCRE and Python the recursed into group is treated
1566 as atomic. Also, modifiers are resolved at compile time, so constructs
1567 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1568 be processed.
1569
1570 =item C<(?&NAME)>
1571 X<(?&NAME)>
1572
1573 Recurse to a named subpattern. Identical to C<(?I<PARNO>)> except that the
1574 parenthesis to recurse to is determined by name. If multiple parentheses have
1575 the same name, then it recurses to the leftmost.
1576
1577 It is an error to refer to a name that is not declared somewhere in the
1578 pattern.
1579
1580 B<NOTE:> In order to make things easier for programmers with experience
1581 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1582 may be used instead of C<< (?&NAME) >>.
1583
1584 =item C<(?(condition)yes-pattern|no-pattern)>
1585 X<(?()>
1586
1587 =item C<(?(condition)yes-pattern)>
1588
1589 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1590 a true value, matches C<no-pattern> otherwise. A missing pattern always
1591 matches.
1592
1593 C<(condition)> should be one of: 1) an integer in
1594 parentheses (which is valid if the corresponding pair of parentheses
1595 matched); 2) a look-ahead/look-behind/evaluate zero-width assertion; 3) a
1596 name in angle brackets or single quotes (which is valid if a group
1597 with the given name matched); or 4) the special symbol (R) (true when
1598 evaluated inside of recursion or eval). Additionally the R may be
1599 followed by a number, (which will be true when evaluated when recursing
1600 inside of the appropriate group), or by C<&NAME>, in which case it will
1601 be true only when evaluated during recursion in the named group.
1602
1603 Here's a summary of the possible predicates:
1604
1605 =over 4
1606
1607 =item (1) (2) ...
1608
1609 Checks if the numbered capturing group has matched something.
1610
1611 =item (<NAME>) ('NAME')
1612
1613 Checks if a group with the given name has matched something.
1614
1615 =item (?=...) (?!...) (?<=...) (?<!...)
1616
1617 Checks whether the pattern matches (or does not match, for the '!'
1618 variants).
1619
1620 =item (?{ CODE })
1621
1622 Treats the return value of the code block as the condition.
1623
1624 =item (R)
1625
1626 Checks if the expression has been evaluated inside of recursion.
1627
1628 =item (R1) (R2) ...
1629
1630 Checks if the expression has been evaluated while executing directly
1631 inside of the n-th capture group. This check is the regex equivalent of
1632
1633   if ((caller(0))[3] eq 'subname') { ... }
1634
1635 In other words, it does not check the full recursion stack.
1636
1637 =item (R&NAME)
1638
1639 Similar to C<(R1)>, this predicate checks to see if we're executing
1640 directly inside of the leftmost group with a given name (this is the same
1641 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1642 stack, but only the name of the innermost active recursion.
1643
1644 =item (DEFINE)
1645
1646 In this case, the yes-pattern is never directly executed, and no
1647 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1648 See below for details.
1649
1650 =back
1651
1652 For example:
1653
1654     m{ ( \( )?
1655        [^()]+
1656        (?(1) \) )
1657      }x
1658
1659 matches a chunk of non-parentheses, possibly included in parentheses
1660 themselves.
1661
1662 A special form is the C<(DEFINE)> predicate, which never executes its
1663 yes-pattern directly, and does not allow a no-pattern. This allows one to
1664 define subpatterns which will be executed only by the recursion mechanism.
1665 This way, you can define a set of regular expression rules that can be
1666 bundled into any pattern you choose.
1667
1668 It is recommended that for this usage you put the DEFINE block at the
1669 end of the pattern, and that you name any subpatterns defined within it.
1670
1671 Also, it's worth noting that patterns defined this way probably will
1672 not be as efficient, as the optimizer is not very clever about
1673 handling them.
1674
1675 An example of how this might be used is as follows:
1676
1677   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1678    (?(DEFINE)
1679      (?<NAME_PAT>....)
1680      (?<ADRESS_PAT>....)
1681    )/x
1682
1683 Note that capture groups matched inside of recursion are not accessible
1684 after the recursion returns, so the extra layer of capturing groups is
1685 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1686 C<$+{NAME}> would be.
1687
1688 Finally, keep in mind that subpatterns created inside a DEFINE block
1689 count towards the absolute and relative number of captures, so this:
1690
1691     my @captures = "a" =~ /(.)                  # First capture
1692                            (?(DEFINE)
1693                                (?<EXAMPLE> 1 )  # Second capture
1694                            )/x;
1695     say scalar @captures;
1696
1697 Will output 2, not 1. This is particularly important if you intend to
1698 compile the definitions with the C<qr//> operator, and later
1699 interpolate them in another pattern.
1700
1701 =item C<< (?>pattern) >>
1702 X<backtrack> X<backtracking> X<atomic> X<possessive>
1703
1704 An "independent" subexpression, one which matches the substring
1705 that a I<standalone> C<pattern> would match if anchored at the given
1706 position, and it matches I<nothing other than this substring>.  This
1707 construct is useful for optimizations of what would otherwise be
1708 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1709 It may also be useful in places where the "grab all you can, and do not
1710 give anything back" semantic is desirable.
1711
1712 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1713 (anchored at the beginning of string, as above) will match I<all>
1714 characters C<a> at the beginning of string, leaving no C<a> for
1715 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1716 since the match of the subgroup C<a*> is influenced by the following
1717 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1718 C<a*ab> will match fewer characters than a standalone C<a*>, since
1719 this makes the tail match.
1720
1721 C<< (?>pattern) >> does not disable backtracking altogether once it has
1722 matched. It is still possible to backtrack past the construct, but not
1723 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1724
1725 An effect similar to C<< (?>pattern) >> may be achieved by writing
1726 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1727 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1728 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1729 (The difference between these two constructs is that the second one
1730 uses a capturing group, thus shifting ordinals of backreferences
1731 in the rest of a regular expression.)
1732
1733 Consider this pattern:
1734
1735     m{ \(
1736           (
1737             [^()]+           # x+
1738           |
1739             \( [^()]* \)
1740           )+
1741        \)
1742      }x
1743
1744 That will efficiently match a nonempty group with matching parentheses
1745 two levels deep or less.  However, if there is no such group, it
1746 will take virtually forever on a long string.  That's because there
1747 are so many different ways to split a long string into several
1748 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1749 to a subpattern of the above pattern.  Consider how the pattern
1750 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1751 seconds, but that each extra letter doubles this time.  This
1752 exponential performance will make it appear that your program has
1753 hung.  However, a tiny change to this pattern
1754
1755     m{ \(
1756           (
1757             (?> [^()]+ )        # change x+ above to (?> x+ )
1758           |
1759             \( [^()]* \)
1760           )+
1761        \)
1762      }x
1763
1764 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1765 this yourself would be a productive exercise), but finishes in a fourth
1766 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1767 however, that, when this construct is followed by a
1768 quantifier, it currently triggers a warning message under
1769 the C<use warnings> pragma or B<-w> switch saying it
1770 C<"matches null string many times in regex">.
1771
1772 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1773 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1774 This was only 4 times slower on a string with 1000000 C<a>s.
1775
1776 The "grab all you can, and do not give anything back" semantic is desirable
1777 in many situations where on the first sight a simple C<()*> looks like
1778 the correct solution.  Suppose we parse text with comments being delimited
1779 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1780 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1781 the comment delimiter, because it may "give up" some whitespace if
1782 the remainder of the pattern can be made to match that way.  The correct
1783 answer is either one of these:
1784
1785     (?>#[ \t]*)
1786     #[ \t]*(?![ \t])
1787
1788 For example, to grab non-empty comments into $1, one should use either
1789 one of these:
1790
1791     / (?> \# [ \t]* ) (        .+ ) /x;
1792     /     \# [ \t]*   ( [^ \t] .* ) /x;
1793
1794 Which one you pick depends on which of these expressions better reflects
1795 the above specification of comments.
1796
1797 In some literature this construct is called "atomic matching" or
1798 "possessive matching".
1799
1800 Possessive quantifiers are equivalent to putting the item they are applied
1801 to inside of one of these constructs. The following equivalences apply:
1802
1803     Quantifier Form     Bracketing Form
1804     ---------------     ---------------
1805     PAT*+               (?>PAT*)
1806     PAT++               (?>PAT+)
1807     PAT?+               (?>PAT?)
1808     PAT{min,max}+       (?>PAT{min,max})
1809
1810 =item C<(?[ ])>
1811
1812 See L<perlrecharclass/Extended Bracketed Character Classes>.
1813
1814 =back
1815
1816 =head2 Special Backtracking Control Verbs
1817
1818 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1819 otherwise stated the ARG argument is optional; in some cases, it is
1820 forbidden.
1821
1822 Any pattern containing a special backtracking verb that allows an argument
1823 has the special behaviour that when executed it sets the current package's
1824 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1825 rules apply:
1826
1827 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1828 verb pattern, if the verb was involved in the failure of the match. If the
1829 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1830 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1831 none. Also, the C<$REGMARK> variable will be set to FALSE.
1832
1833 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1834 the C<$REGMARK> variable will be set to the name of the last
1835 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1836 C<(*MARK:NAME)> verb below for more details.
1837
1838 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1839 and most other regex-related variables. They are not local to a scope, nor
1840 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1841 Use C<local> to localize changes to them to a specific scope if necessary.
1842
1843 If a pattern does not contain a special backtracking verb that allows an
1844 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1845
1846 =over 3
1847
1848 =item Verbs that take an argument
1849
1850 =over 4
1851
1852 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1853 X<(*PRUNE)> X<(*PRUNE:NAME)>
1854
1855 This zero-width pattern prunes the backtracking tree at the current point
1856 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1857 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1858 A may backtrack as necessary to match. Once it is reached, matching
1859 continues in B, which may also backtrack as necessary; however, should B
1860 not match, then no further backtracking will take place, and the pattern
1861 will fail outright at the current starting position.
1862
1863 The following example counts all the possible matching strings in a
1864 pattern (without actually matching any of them).
1865
1866     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1867     print "Count=$count\n";
1868
1869 which produces:
1870
1871     aaab
1872     aaa
1873     aa
1874     a
1875     aab
1876     aa
1877     a
1878     ab
1879     a
1880     Count=9
1881
1882 If we add a C<(*PRUNE)> before the count like the following
1883
1884     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1885     print "Count=$count\n";
1886
1887 we prevent backtracking and find the count of the longest matching string
1888 at each matching starting point like so:
1889
1890     aaab
1891     aab
1892     ab
1893     Count=3
1894
1895 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1896
1897 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1898 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1899 replaced with a C<< (?>pattern) >> with no functional difference; however,
1900 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1901 C<< (?>pattern) >> alone.
1902
1903 =item C<(*SKIP)> C<(*SKIP:NAME)>
1904 X<(*SKIP)>
1905
1906 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1907 failure it also signifies that whatever text that was matched leading up
1908 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1909 of this pattern. This effectively means that the regex engine "skips" forward
1910 to this position on failure and tries to match again, (assuming that
1911 there is sufficient room to match).
1912
1913 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1914 C<(*MARK:NAME)> was encountered while matching, then it is that position
1915 which is used as the "skip point". If no C<(*MARK)> of that name was
1916 encountered, then the C<(*SKIP)> operator has no effect. When used
1917 without a name the "skip point" is where the match point was when
1918 executing the (*SKIP) pattern.
1919
1920 Compare the following to the examples in C<(*PRUNE)>; note the string
1921 is twice as long:
1922
1923  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1924  print "Count=$count\n";
1925
1926 outputs
1927
1928     aaab
1929     aaab
1930     Count=2
1931
1932 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1933 executed, the next starting point will be where the cursor was when the
1934 C<(*SKIP)> was executed.
1935
1936 =item C<(*MARK:NAME)> C<(*:NAME)>
1937 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1938
1939 This zero-width pattern can be used to mark the point reached in a string
1940 when a certain part of the pattern has been successfully matched. This
1941 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1942 forward to that point if backtracked into on failure. Any number of
1943 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1944
1945 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1946 can be used to "label" a pattern branch, so that after matching, the
1947 program can determine which branches of the pattern were involved in the
1948 match.
1949
1950 When a match is successful, the C<$REGMARK> variable will be set to the
1951 name of the most recently executed C<(*MARK:NAME)> that was involved
1952 in the match.
1953
1954 This can be used to determine which branch of a pattern was matched
1955 without using a separate capture group for each branch, which in turn
1956 can result in a performance improvement, as perl cannot optimize
1957 C</(?:(x)|(y)|(z))/> as efficiently as something like
1958 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1959
1960 When a match has failed, and unless another verb has been involved in
1961 failing the match and has provided its own name to use, the C<$REGERROR>
1962 variable will be set to the name of the most recently executed
1963 C<(*MARK:NAME)>.
1964
1965 See L</(*SKIP)> for more details.
1966
1967 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1968
1969 =item C<(*THEN)> C<(*THEN:NAME)>
1970
1971 This is similar to the "cut group" operator C<::> from Perl 6.  Like
1972 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1973 failure, it causes the regex engine to try the next alternation in the
1974 innermost enclosing group (capturing or otherwise) that has alternations.
1975 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
1976 count as an alternation, as far as C<(*THEN)> is concerned.
1977
1978 Its name comes from the observation that this operation combined with the
1979 alternation operator (C<|>) can be used to create what is essentially a
1980 pattern-based if/then/else block:
1981
1982   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1983
1984 Note that if this operator is used and NOT inside of an alternation then
1985 it acts exactly like the C<(*PRUNE)> operator.
1986
1987   / A (*PRUNE) B /
1988
1989 is the same as
1990
1991   / A (*THEN) B /
1992
1993 but
1994
1995   / ( A (*THEN) B | C ) /
1996
1997 is not the same as
1998
1999   / ( A (*PRUNE) B | C ) /
2000
2001 as after matching the A but failing on the B the C<(*THEN)> verb will
2002 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
2003
2004 =back
2005
2006 =item Verbs without an argument
2007
2008 =over 4
2009
2010 =item C<(*COMMIT)>
2011 X<(*COMMIT)>
2012
2013 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
2014 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
2015 into on failure it causes the match to fail outright. No further attempts
2016 to find a valid match by advancing the start pointer will occur again.
2017 For example,
2018
2019  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
2020  print "Count=$count\n";
2021
2022 outputs
2023
2024     aaab
2025     Count=1
2026
2027 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
2028 does not match, the regex engine will not try any further matching on the
2029 rest of the string.
2030
2031 =item C<(*FAIL)> C<(*F)>
2032 X<(*FAIL)> X<(*F)>
2033
2034 This pattern matches nothing and always fails. It can be used to force the
2035 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
2036 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
2037
2038 It is probably useful only when combined with C<(?{})> or C<(??{})>.
2039
2040 =item C<(*ACCEPT)>
2041 X<(*ACCEPT)>
2042
2043 This pattern matches nothing and causes the end of successful matching at
2044 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
2045 whether there is actually more to match in the string. When inside of a
2046 nested pattern, such as recursion, or in a subpattern dynamically generated
2047 via C<(??{})>, only the innermost pattern is ended immediately.
2048
2049 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
2050 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
2051 For instance:
2052
2053   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
2054
2055 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
2056 be set. If another branch in the inner parentheses was matched, such as in the
2057 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
2058
2059 =back
2060
2061 =back
2062
2063 =head2 Backtracking
2064 X<backtrack> X<backtracking>
2065
2066 NOTE: This section presents an abstract approximation of regular
2067 expression behavior.  For a more rigorous (and complicated) view of
2068 the rules involved in selecting a match among possible alternatives,
2069 see L<Combining RE Pieces>.
2070
2071 A fundamental feature of regular expression matching involves the
2072 notion called I<backtracking>, which is currently used (when needed)
2073 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
2074 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2075 internally, but the general principle outlined here is valid.
2076
2077 For a regular expression to match, the I<entire> regular expression must
2078 match, not just part of it.  So if the beginning of a pattern containing a
2079 quantifier succeeds in a way that causes later parts in the pattern to
2080 fail, the matching engine backs up and recalculates the beginning
2081 part--that's why it's called backtracking.
2082
2083 Here is an example of backtracking:  Let's say you want to find the
2084 word following "foo" in the string "Food is on the foo table.":
2085
2086     $_ = "Food is on the foo table.";
2087     if ( /\b(foo)\s+(\w+)/i ) {
2088         print "$2 follows $1.\n";
2089     }
2090
2091 When the match runs, the first part of the regular expression (C<\b(foo)>)
2092 finds a possible match right at the beginning of the string, and loads up
2093 $1 with "Foo".  However, as soon as the matching engine sees that there's
2094 no whitespace following the "Foo" that it had saved in $1, it realizes its
2095 mistake and starts over again one character after where it had the
2096 tentative match.  This time it goes all the way until the next occurrence
2097 of "foo". The complete regular expression matches this time, and you get
2098 the expected output of "table follows foo."
2099
2100 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2101 everything between "foo" and "bar".  Initially, you write something
2102 like this:
2103
2104     $_ =  "The food is under the bar in the barn.";
2105     if ( /foo(.*)bar/ ) {
2106         print "got <$1>\n";
2107     }
2108
2109 Which perhaps unexpectedly yields:
2110
2111   got <d is under the bar in the >
2112
2113 That's because C<.*> was greedy, so you get everything between the
2114 I<first> "foo" and the I<last> "bar".  Here it's more effective
2115 to use minimal matching to make sure you get the text between a "foo"
2116 and the first "bar" thereafter.
2117
2118     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2119   got <d is under the >
2120
2121 Here's another example. Let's say you'd like to match a number at the end
2122 of a string, and you also want to keep the preceding part of the match.
2123 So you write this:
2124
2125     $_ = "I have 2 numbers: 53147";
2126     if ( /(.*)(\d*)/ ) {                                # Wrong!
2127         print "Beginning is <$1>, number is <$2>.\n";
2128     }
2129
2130 That won't work at all, because C<.*> was greedy and gobbled up the
2131 whole string. As C<\d*> can match on an empty string the complete
2132 regular expression matched successfully.
2133
2134     Beginning is <I have 2 numbers: 53147>, number is <>.
2135
2136 Here are some variants, most of which don't work:
2137
2138     $_ = "I have 2 numbers: 53147";
2139     @pats = qw{
2140         (.*)(\d*)
2141         (.*)(\d+)
2142         (.*?)(\d*)
2143         (.*?)(\d+)
2144         (.*)(\d+)$
2145         (.*?)(\d+)$
2146         (.*)\b(\d+)$
2147         (.*\D)(\d+)$
2148     };
2149
2150     for $pat (@pats) {
2151         printf "%-12s ", $pat;
2152         if ( /$pat/ ) {
2153             print "<$1> <$2>\n";
2154         } else {
2155             print "FAIL\n";
2156         }
2157     }
2158
2159 That will print out:
2160
2161     (.*)(\d*)    <I have 2 numbers: 53147> <>
2162     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2163     (.*?)(\d*)   <> <>
2164     (.*?)(\d+)   <I have > <2>
2165     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2166     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2167     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2168     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2169
2170 As you see, this can be a bit tricky.  It's important to realize that a
2171 regular expression is merely a set of assertions that gives a definition
2172 of success.  There may be 0, 1, or several different ways that the
2173 definition might succeed against a particular string.  And if there are
2174 multiple ways it might succeed, you need to understand backtracking to
2175 know which variety of success you will achieve.
2176
2177 When using look-ahead assertions and negations, this can all get even
2178 trickier.  Imagine you'd like to find a sequence of non-digits not
2179 followed by "123".  You might try to write that as
2180
2181     $_ = "ABC123";
2182     if ( /^\D*(?!123)/ ) {                # Wrong!
2183         print "Yup, no 123 in $_\n";
2184     }
2185
2186 But that isn't going to match; at least, not the way you're hoping.  It
2187 claims that there is no 123 in the string.  Here's a clearer picture of
2188 why that pattern matches, contrary to popular expectations:
2189
2190     $x = 'ABC123';
2191     $y = 'ABC445';
2192
2193     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2194     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2195
2196     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2197     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2198
2199 This prints
2200
2201     2: got ABC
2202     3: got AB
2203     4: got ABC
2204
2205 You might have expected test 3 to fail because it seems to a more
2206 general purpose version of test 1.  The important difference between
2207 them is that test 3 contains a quantifier (C<\D*>) and so can use
2208 backtracking, whereas test 1 will not.  What's happening is
2209 that you've asked "Is it true that at the start of $x, following 0 or more
2210 non-digits, you have something that's not 123?"  If the pattern matcher had
2211 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2212 fail.
2213
2214 The search engine will initially match C<\D*> with "ABC".  Then it will
2215 try to match C<(?!123)> with "123", which fails.  But because
2216 a quantifier (C<\D*>) has been used in the regular expression, the
2217 search engine can backtrack and retry the match differently
2218 in the hope of matching the complete regular expression.
2219
2220 The pattern really, I<really> wants to succeed, so it uses the
2221 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2222 time.  Now there's indeed something following "AB" that is not
2223 "123".  It's "C123", which suffices.
2224
2225 We can deal with this by using both an assertion and a negation.
2226 We'll say that the first part in $1 must be followed both by a digit
2227 and by something that's not "123".  Remember that the look-aheads
2228 are zero-width expressions--they only look, but don't consume any
2229 of the string in their match.  So rewriting this way produces what
2230 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2231
2232     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2233     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2234
2235     6: got ABC
2236
2237 In other words, the two zero-width assertions next to each other work as though
2238 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2239 matches only if you're at the beginning of the line AND the end of the
2240 line simultaneously.  The deeper underlying truth is that juxtaposition in
2241 regular expressions always means AND, except when you write an explicit OR
2242 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2243 although the attempted matches are made at different positions because "a"
2244 is not a zero-width assertion, but a one-width assertion.
2245
2246 B<WARNING>: Particularly complicated regular expressions can take
2247 exponential time to solve because of the immense number of possible
2248 ways they can use backtracking to try for a match.  For example, without
2249 internal optimizations done by the regular expression engine, this will
2250 take a painfully long time to run:
2251
2252     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2253
2254 And if you used C<*>'s in the internal groups instead of limiting them
2255 to 0 through 5 matches, then it would take forever--or until you ran
2256 out of stack space.  Moreover, these internal optimizations are not
2257 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2258 on the external group, no current optimization is applicable, and the
2259 match takes a long time to finish.
2260
2261 A powerful tool for optimizing such beasts is what is known as an
2262 "independent group",
2263 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2264 zero-length look-ahead/look-behind assertions will not backtrack to make
2265 the tail match, since they are in "logical" context: only
2266 whether they match is considered relevant.  For an example
2267 where side-effects of look-ahead I<might> have influenced the
2268 following match, see L</C<< (?>pattern) >>>.
2269
2270 =head2 Version 8 Regular Expressions
2271 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2272
2273 In case you're not familiar with the "regular" Version 8 regex
2274 routines, here are the pattern-matching rules not described above.
2275
2276 Any single character matches itself, unless it is a I<metacharacter>
2277 with a special meaning described here or above.  You can cause
2278 characters that normally function as metacharacters to be interpreted
2279 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2280 character; "\\" matches a "\"). This escape mechanism is also required
2281 for the character used as the pattern delimiter.
2282
2283 A series of characters matches that series of characters in the target
2284 string, so the pattern C<blurfl> would match "blurfl" in the target
2285 string.
2286
2287 You can specify a character class, by enclosing a list of characters
2288 in C<[]>, which will match any character from the list.  If the
2289 first character after the "[" is "^", the class matches any character not
2290 in the list.  Within a list, the "-" character specifies a
2291 range, so that C<a-z> represents all characters between "a" and "z",
2292 inclusive.  If you want either "-" or "]" itself to be a member of a
2293 class, put it at the start of the list (possibly after a "^"), or
2294 escape it with a backslash.  "-" is also taken literally when it is
2295 at the end of the list, just before the closing "]".  (The
2296 following all specify the same class of three characters: C<[-az]>,
2297 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2298 specifies a class containing twenty-six characters, even on EBCDIC-based
2299 character sets.)  Also, if you try to use the character
2300 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2301 a range, the "-" is understood literally.
2302
2303 Note also that the whole range idea is rather unportable between
2304 character sets--and even within character sets they may cause results
2305 you probably didn't expect.  A sound principle is to use only ranges
2306 that begin from and end at either alphabetics of equal case ([a-e],
2307 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
2308 spell out the character sets in full.
2309
2310 Characters may be specified using a metacharacter syntax much like that
2311 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2312 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2313 of three octal digits, matches the character whose coded character set value
2314 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2315 matches the character whose ordinal is I<nn>. The expression \cI<x>
2316 matches the character control-I<x>.  Finally, the "." metacharacter
2317 matches any character except "\n" (unless you use C</s>).
2318
2319 You can specify a series of alternatives for a pattern using "|" to
2320 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2321 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2322 first alternative includes everything from the last pattern delimiter
2323 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2324 the last alternative contains everything from the last "|" to the next
2325 closing pattern delimiter.  That's why it's common practice to include
2326 alternatives in parentheses: to minimize confusion about where they
2327 start and end.
2328
2329 Alternatives are tried from left to right, so the first
2330 alternative found for which the entire expression matches, is the one that
2331 is chosen. This means that alternatives are not necessarily greedy. For
2332 example: when matching C<foo|foot> against "barefoot", only the "foo"
2333 part will match, as that is the first alternative tried, and it successfully
2334 matches the target string. (This might not seem important, but it is
2335 important when you are capturing matched text using parentheses.)
2336
2337 Also remember that "|" is interpreted as a literal within square brackets,
2338 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2339
2340 Within a pattern, you may designate subpatterns for later reference
2341 by enclosing them in parentheses, and you may refer back to the
2342 I<n>th subpattern later in the pattern using the metacharacter
2343 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2344 of their opening parenthesis.  A backreference matches whatever
2345 actually matched the subpattern in the string being examined, not
2346 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2347 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2348 1 matched "0x", even though the rule C<0|0x> could potentially match
2349 the leading 0 in the second number.
2350
2351 =head2 Warning on \1 Instead of $1
2352
2353 Some people get too used to writing things like:
2354
2355     $pattern =~ s/(\W)/\\\1/g;
2356
2357 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2358 shocking the
2359 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2360 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2361 the usual double-quoted string means a control-A.  The customary Unix
2362 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2363 of doing that, you get yourself into trouble if you then add an C</e>
2364 modifier.
2365
2366     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2367
2368 Or if you try to do
2369
2370     s/(\d+)/\1000/;
2371
2372 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2373 C<${1}000>.  The operation of interpolation should not be confused
2374 with the operation of matching a backreference.  Certainly they mean two
2375 different things on the I<left> side of the C<s///>.
2376
2377 =head2 Repeated Patterns Matching a Zero-length Substring
2378
2379 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2380
2381 Regular expressions provide a terse and powerful programming language.  As
2382 with most other power tools, power comes together with the ability
2383 to wreak havoc.
2384
2385 A common abuse of this power stems from the ability to make infinite
2386 loops using regular expressions, with something as innocuous as:
2387
2388     'foo' =~ m{ ( o? )* }x;
2389
2390 The C<o?> matches at the beginning of C<'foo'>, and since the position
2391 in the string is not moved by the match, C<o?> would match again and again
2392 because of the C<*> quantifier.  Another common way to create a similar cycle
2393 is with the looping modifier C<//g>:
2394
2395     @matches = ( 'foo' =~ m{ o? }xg );
2396
2397 or
2398
2399     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2400
2401 or the loop implied by split().
2402
2403 However, long experience has shown that many programming tasks may
2404 be significantly simplified by using repeated subexpressions that
2405 may match zero-length substrings.  Here's a simple example being:
2406
2407     @chars = split //, $string;           # // is not magic in split
2408     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2409
2410 Thus Perl allows such constructs, by I<forcefully breaking
2411 the infinite loop>.  The rules for this are different for lower-level
2412 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2413 ones like the C</g> modifier or split() operator.
2414
2415 The lower-level loops are I<interrupted> (that is, the loop is
2416 broken) when Perl detects that a repeated expression matched a
2417 zero-length substring.   Thus
2418
2419    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2420
2421 is made equivalent to
2422
2423    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2424
2425 For example, this program
2426
2427    #!perl -l
2428    "aaaaab" =~ /
2429      (?:
2430         a                 # non-zero
2431         |                 # or
2432        (?{print "hello"}) # print hello whenever this
2433                           #    branch is tried
2434        (?=(b))            # zero-width assertion
2435      )*  # any number of times
2436     /x;
2437    print $&;
2438    print $1;
2439
2440 prints
2441
2442    hello
2443    aaaaa
2444    b
2445
2446 Notice that "hello" is only printed once, as when Perl sees that the sixth
2447 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2448 the C<*>.
2449
2450 The higher-level loops preserve an additional state between iterations:
2451 whether the last match was zero-length.  To break the loop, the following
2452 match after a zero-length match is prohibited to have a length of zero.
2453 This prohibition interacts with backtracking (see L<"Backtracking">),
2454 and so the I<second best> match is chosen if the I<best> match is of
2455 zero length.
2456
2457 For example:
2458
2459     $_ = 'bar';
2460     s/\w??/<$&>/g;
2461
2462 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2463 match given by non-greedy C<??> is the zero-length match, and the I<second
2464 best> match is what is matched by C<\w>.  Thus zero-length matches
2465 alternate with one-character-long matches.
2466
2467 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2468 position one notch further in the string.
2469
2470 The additional state of being I<matched with zero-length> is associated with
2471 the matched string, and is reset by each assignment to pos().
2472 Zero-length matches at the end of the previous match are ignored
2473 during C<split>.
2474
2475 =head2 Combining RE Pieces
2476
2477 Each of the elementary pieces of regular expressions which were described
2478 before (such as C<ab> or C<\Z>) could match at most one substring
2479 at the given position of the input string.  However, in a typical regular
2480 expression these elementary pieces are combined into more complicated
2481 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2482 (in these examples C<S> and C<T> are regular subexpressions).
2483
2484 Such combinations can include alternatives, leading to a problem of choice:
2485 if we match a regular expression C<a|ab> against C<"abc">, will it match
2486 substring C<"a"> or C<"ab">?  One way to describe which substring is
2487 actually matched is the concept of backtracking (see L<"Backtracking">).
2488 However, this description is too low-level and makes you think
2489 in terms of a particular implementation.
2490
2491 Another description starts with notions of "better"/"worse".  All the
2492 substrings which may be matched by the given regular expression can be
2493 sorted from the "best" match to the "worst" match, and it is the "best"
2494 match which is chosen.  This substitutes the question of "what is chosen?"
2495 by the question of "which matches are better, and which are worse?".
2496
2497 Again, for elementary pieces there is no such question, since at most
2498 one match at a given position is possible.  This section describes the
2499 notion of better/worse for combining operators.  In the description
2500 below C<S> and C<T> are regular subexpressions.
2501
2502 =over 4
2503
2504 =item C<ST>
2505
2506 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2507 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2508 which can be matched by C<T>.
2509
2510 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2511 match than C<A'B'>.
2512
2513 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2514 C<B> is a better match for C<T> than C<B'>.
2515
2516 =item C<S|T>
2517
2518 When C<S> can match, it is a better match than when only C<T> can match.
2519
2520 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2521 two matches for C<T>.
2522
2523 =item C<S{REPEAT_COUNT}>
2524
2525 Matches as C<SSS...S> (repeated as many times as necessary).
2526
2527 =item C<S{min,max}>
2528
2529 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2530
2531 =item C<S{min,max}?>
2532
2533 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2534
2535 =item C<S?>, C<S*>, C<S+>
2536
2537 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2538
2539 =item C<S??>, C<S*?>, C<S+?>
2540
2541 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2542
2543 =item C<< (?>S) >>
2544
2545 Matches the best match for C<S> and only that.
2546
2547 =item C<(?=S)>, C<(?<=S)>
2548
2549 Only the best match for C<S> is considered.  (This is important only if
2550 C<S> has capturing parentheses, and backreferences are used somewhere
2551 else in the whole regular expression.)
2552
2553 =item C<(?!S)>, C<(?<!S)>
2554
2555 For this grouping operator there is no need to describe the ordering, since
2556 only whether or not C<S> can match is important.
2557
2558 =item C<(??{ EXPR })>, C<(?I<PARNO>)>
2559
2560 The ordering is the same as for the regular expression which is
2561 the result of EXPR, or the pattern contained by capture group I<PARNO>.
2562
2563 =item C<(?(condition)yes-pattern|no-pattern)>
2564
2565 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2566 already determined.  The ordering of the matches is the same as for the
2567 chosen subexpression.
2568
2569 =back
2570
2571 The above recipes describe the ordering of matches I<at a given position>.
2572 One more rule is needed to understand how a match is determined for the
2573 whole regular expression: a match at an earlier position is always better
2574 than a match at a later position.
2575
2576 =head2 Creating Custom RE Engines
2577
2578 As of Perl 5.10.0, one can create custom regular expression engines.  This
2579 is not for the faint of heart, as they have to plug in at the C level.  See
2580 L<perlreapi> for more details.
2581
2582 As an alternative, overloaded constants (see L<overload>) provide a simple
2583 way to extend the functionality of the RE engine, by substituting one
2584 pattern for another.
2585
2586 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2587 matches at a boundary between whitespace characters and non-whitespace
2588 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2589 at these positions, so we want to have each C<\Y|> in the place of the
2590 more complicated version.  We can create a module C<customre> to do
2591 this:
2592
2593     package customre;
2594     use overload;
2595
2596     sub import {
2597       shift;
2598       die "No argument to customre::import allowed" if @_;
2599       overload::constant 'qr' => \&convert;
2600     }
2601
2602     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2603
2604     # We must also take care of not escaping the legitimate \\Y|
2605     # sequence, hence the presence of '\\' in the conversion rules.
2606     my %rules = ( '\\' => '\\\\',
2607                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2608     sub convert {
2609       my $re = shift;
2610       $re =~ s{
2611                 \\ ( \\ | Y . )
2612               }
2613               { $rules{$1} or invalid($re,$1) }sgex;
2614       return $re;
2615     }
2616
2617 Now C<use customre> enables the new escape in constant regular
2618 expressions, i.e., those without any runtime variable interpolations.
2619 As documented in L<overload>, this conversion will work only over
2620 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2621 part of this regular expression needs to be converted explicitly
2622 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2623
2624     use customre;
2625     $re = <>;
2626     chomp $re;
2627     $re = customre::convert $re;
2628     /\Y|$re\Y|/;
2629
2630 =head2 Embedded Code Execution Frequency
2631
2632 The exact rules for how often (??{}) and (?{}) are executed in a pattern
2633 are unspecified.  In the case of a successful match you can assume that
2634 they DWIM and will be executed in left to right order the appropriate
2635 number of times in the accepting path of the pattern as would any other
2636 meta-pattern.  How non-accepting pathways and match failures affect the
2637 number of times a pattern is executed is specifically unspecified and
2638 may vary depending on what optimizations can be applied to the pattern
2639 and is likely to change from version to version.
2640
2641 For instance in
2642
2643   "aaabcdeeeee"=~/a(?{print "a"})b(?{print "b"})cde/;
2644
2645 the exact number of times "a" or "b" are printed out is unspecified for
2646 failure, but you may assume they will be printed at least once during
2647 a successful match, additionally you may assume that if "b" is printed,
2648 it will be preceded by at least one "a".
2649
2650 In the case of branching constructs like the following:
2651
2652   /a(b|(?{ print "a" }))c(?{ print "c" })/;
2653
2654 you can assume that the input "ac" will output "ac", and that "abc"
2655 will output only "c".
2656
2657 When embedded code is quantified, successful matches will call the
2658 code once for each matched iteration of the quantifier.  For
2659 example:
2660
2661   "good" =~ /g(?:o(?{print "o"}))*d/;
2662
2663 will output "o" twice.
2664
2665 =head2 PCRE/Python Support
2666
2667 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2668 to the regex syntax. While Perl programmers are encouraged to use the
2669 Perl-specific syntax, the following are also accepted:
2670
2671 =over 4
2672
2673 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2674
2675 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2676
2677 =item C<< (?P=NAME) >>
2678
2679 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2680
2681 =item C<< (?P>NAME) >>
2682
2683 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2684
2685 =back
2686
2687 =head1 BUGS
2688
2689 Many regular expression constructs don't work on EBCDIC platforms.
2690
2691 There are a number of issues with regard to case-insensitive matching
2692 in Unicode rules.  See C<i> under L</Modifiers> above.
2693
2694 This document varies from difficult to understand to completely
2695 and utterly opaque.  The wandering prose riddled with jargon is
2696 hard to fathom in several places.
2697
2698 This document needs a rewrite that separates the tutorial content
2699 from the reference content.
2700
2701 =head1 SEE ALSO
2702
2703 L<perlrequick>.
2704
2705 L<perlretut>.
2706
2707 L<perlop/"Regexp Quote-Like Operators">.
2708
2709 L<perlop/"Gory details of parsing quoted constructs">.
2710
2711 L<perlfaq6>.
2712
2713 L<perlfunc/pos>.
2714
2715 L<perllocale>.
2716
2717 L<perlebcdic>.
2718
2719 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2720 by O'Reilly and Associates.