This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlxs: Add text about dealing with locales, etc
[perl5.git] / pod / perllocale.pod
1 =encoding utf8
2
3 =head1 NAME
4
5 perllocale - Perl locale handling (internationalization and localization)
6
7 =head1 DESCRIPTION
8
9 In the beginning there was ASCII, the "American Standard Code for
10 Information Interchange", which works quite well for Americans with
11 their English alphabet and dollar-denominated currency.  But it doesn't
12 work so well even for other English speakers, who may use different
13 currencies, such as the pound sterling (as the symbol for that currency
14 is not in ASCII); and it's hopelessly inadequate for many of the
15 thousands of the world's other languages.
16
17 To address these deficiencies, the concept of locales was invented
18 (formally the ISO C, XPG4, POSIX 1.c "locale system").  And applications
19 were and are being written that use the locale mechanism.  The process of
20 making such an application take account of its users' preferences in
21 these kinds of matters is called B<internationalization> (often
22 abbreviated as B<i18n>); telling such an application about a particular
23 set of preferences is known as B<localization> (B<l10n>).
24
25 Perl has been extended to support the locale system.  This
26 is controlled per application by using one pragma, one function call,
27 and several environment variables.
28
29 Unfortunately, there are quite a few deficiencies with the design (and
30 often, the implementations) of locales.  Unicode was invented (see
31 L<perlunitut> for an introduction to that) in part to address these
32 design deficiencies, and nowadays, there is a series of "UTF-8
33 locales", based on Unicode.  These are locales whose character set is
34 Unicode, encoded in UTF-8.  Starting in v5.20, Perl fully supports
35 UTF-8 locales, except for sorting and string comparisions.  (Use
36 L<Unicode::Collate> for these.)  Perl continues to support the old
37 non UTF-8 locales as well.
38
39 (Unicode is also creating C<CLDR>, the "Common Locale Data Repository",
40 L<http://cldr.unicode.org/> which includes more types of information than
41 are available in the POSIX locale system.  At the time of this writing,
42 there was no CPAN module that provides access to this XML-encoded data.
43 However, many of its locales have the POSIX-only data extracted, and are
44 available as UTF-8 locales at
45 L<http://unicode.org/Public/cldr/latest/>.)
46
47 =head1 WHAT IS A LOCALE
48
49 A locale is a set of data that describes various aspects of how various
50 communities in the world categorize their world.  These categories are
51 broken down into the following types (some of which include a brief
52 note here):
53
54 =over
55
56 =item Category C<LC_NUMERIC>: Numeric formatting
57
58 This indicates how numbers should be formatted for human readability,
59 for example the character used as the decimal point.
60
61 =item Category C<LC_MONETARY>: Formatting of monetary amounts
62
63 =for comment
64 The nbsp below makes this look better (though not great)
65
66 E<160>
67
68 =item Category C<LC_TIME>: Date/Time formatting
69
70 =for comment
71 The nbsp below makes this look better (though not great)
72
73 E<160>
74
75 =item Category C<LC_MESSAGES>: Error and other messages
76
77 This is used by Perl itself only for accessing operating system error
78 messages via L<$!|perlvar/$ERRNO> and L<$^E|perlvar/$EXTENDED_OS_ERROR>.
79
80 =item Category C<LC_COLLATE>: Collation
81
82 This indicates the ordering of letters for comparison and sorting.
83 In Latin alphabets, for example, "b", generally follows "a".
84
85 =item Category C<LC_CTYPE>: Character Types
86
87 This indicates, for example if a character is an uppercase letter.
88
89 =item Other categories
90
91 Some platforms have other categories, dealing with such things as
92 measurement units and paper sizes.  None of these are used directly by
93 Perl, but outside operations that Perl interacts with may use
94 these.  See L</Not within the scope of "use locale"> below.
95
96 =back
97
98 More details on the categories used by Perl are given below in L</LOCALE
99 CATEGORIES>.
100
101 Together, these categories go a long way towards being able to customize
102 a single program to run in many different locations.  But there are
103 deficiencies, so keep reading.
104
105 =head1 PREPARING TO USE LOCALES
106
107 Perl itself will not use locales unless specifically requested to (but
108 again note that Perl may interact with code that does use them).  Even
109 if there is such a request, B<all> of the following must be true
110 for it to work properly:
111
112 =over 4
113
114 =item *
115
116 B<Your operating system must support the locale system>.  If it does,
117 you should find that the C<setlocale()> function is a documented part of
118 its C library.
119
120 =item *
121
122 B<Definitions for locales that you use must be installed>.  You, or
123 your system administrator, must make sure that this is the case. The
124 available locales, the location in which they are kept, and the manner
125 in which they are installed all vary from system to system.  Some systems
126 provide only a few, hard-wired locales and do not allow more to be
127 added.  Others allow you to add "canned" locales provided by the system
128 supplier.  Still others allow you or the system administrator to define
129 and add arbitrary locales.  (You may have to ask your supplier to
130 provide canned locales that are not delivered with your operating
131 system.)  Read your system documentation for further illumination.
132
133 =item *
134
135 B<Perl must believe that the locale system is supported>.  If it does,
136 C<perl -V:d_setlocale> will say that the value for C<d_setlocale> is
137 C<define>.
138
139 =back
140
141 If you want a Perl application to process and present your data
142 according to a particular locale, the application code should include
143 the S<C<use locale>> pragma (see L<The "use locale" pragma>) where
144 appropriate, and B<at least one> of the following must be true:
145
146 =over 4
147
148 =item 1
149
150 B<The locale-determining environment variables (see L</"ENVIRONMENT">)
151 must be correctly set up> at the time the application is started, either
152 by yourself or by whomever set up your system account; or
153
154 =item 2
155
156 B<The application must set its own locale> using the method described in
157 L<The setlocale function>.
158
159 =back
160
161 =head1 USING LOCALES
162
163 =head2 The C<"use locale"> pragma
164
165 By default, Perl itself ignores the current locale.  The S<C<use locale>>
166 pragma tells Perl to use the current locale for some operations.
167 Starting in v5.16, there are optional parameters to this pragma,
168 described below, which restrict which operations are affected by it.
169
170 The current locale is set at execution time by
171 L<setlocale()|/The setlocale function> described below.  If that function
172 hasn't yet been called in the course of the program's execution, the
173 current locale is that which was determined by the L</"ENVIRONMENT"> in
174 effect at the start of the program.
175 If there is no valid environment, the current locale is whatever the
176 system default has been set to.   On POSIX systems, it is likely, but
177 not necessarily, the "C" locale.  On Windows, the default is set via the
178 computer's S<C<Control Panel-E<gt>Regional and Language Options>> (or its
179 current equivalent).
180
181 The operations that are affected by locale are:
182
183 =over 4
184
185 =item B<Not within the scope of C<"use locale">>
186
187 Only certain operations originating outside Perl should be affected, as
188 follows:
189
190 =over 4
191
192 =item *
193
194 The current locale is also used when going outside of Perl with
195 operations like L<system()|perlfunc/system LIST> or
196 L<qxE<sol>E<sol>|perlop/qxE<sol>STRINGE<sol>>, if those operations are
197 locale-sensitive.
198
199 =item *
200
201 Also Perl gives access to various C library functions through the
202 L<POSIX> module.  Some of those functions are always affected by the
203 current locale.  For example, C<POSIX::strftime()> uses C<LC_TIME>;
204 C<POSIX::strtod()> uses C<LC_NUMERIC>; C<POSIX::strcoll()> and
205 C<POSIX::strxfrm()> use C<LC_COLLATE>; and character classification
206 functions like C<POSIX::isalnum()> use C<LC_CTYPE>.  All such functions
207 will behave according to the current underlying locale, even if that
208 locale isn't exposed to Perl space.
209
210 =item *
211
212 XS modules for all categories but C<LC_NUMERIC> get the underlying
213 locale, and hence any C library functions they call will use that
214 underlying locale.  For more discussion, see L<perlxs/CAVEATS>.
215
216 =back
217
218 =for comment
219 The nbsp below makes this look better (though not great)
220
221 E<160>
222
223 =item B<Lingering effects of C<S<use locale>>>
224
225 Certain Perl operations that are set-up within the scope of a
226 C<use locale> retain that effect even outside the scope.
227 These include:
228
229 =over 4
230
231 =item *
232
233 The output format of a L<write()|perlfunc/write> is determined by an
234 earlier format declaration (L<perlfunc/format>), so whether or not the
235 output is affected by locale is determined by if the C<format()> is
236 within the scope of a C<use locale>, not whether the C<write()>
237 is.
238
239 =item *
240
241 Regular expression patterns can be compiled using
242 L<qrE<sol>E<sol>|perlop/qrE<sol>STRINGE<sol>msixpodual> with actual
243 matching deferred to later.  Again, it is whether or not the compilation
244 was done within the scope of C<use locale> that determines the match
245 behavior, not if the matches are done within such a scope or not.
246
247 =back
248
249 =for comment
250 The nbsp below makes this look better (though not great)
251
252
253 E<160>
254
255 =item B<Under C<"use locale";>>
256
257 =over 4
258
259 =item *
260
261 All the above operations
262
263 =item *
264
265 B<Format declarations> (L<perlfunc/format>) and hence any subsequent
266 C<write()>s use C<LC_NUMERIC>.
267
268 =item *
269
270 B<stringification and output> use C<LC_NUMERIC>.
271 These include the results of
272 C<print()>,
273 C<printf()>,
274 C<say()>,
275 and
276 C<sprintf()>.
277
278 =item *
279
280 B<The comparison operators> (C<lt>, C<le>, C<cmp>, C<ge>, and C<gt>) use
281 C<LC_COLLATE>.  C<sort()> is also affected if used without an
282 explicit comparison function, because it uses C<cmp> by default.
283
284 B<Note:> C<eq> and C<ne> are unaffected by locale: they always
285 perform a char-by-char comparison of their scalar operands.  What's
286 more, if C<cmp> finds that its operands are equal according to the
287 collation sequence specified by the current locale, it goes on to
288 perform a char-by-char comparison, and only returns I<0> (equal) if the
289 operands are char-for-char identical.  If you really want to know whether
290 two strings--which C<eq> and C<cmp> may consider different--are equal
291 as far as collation in the locale is concerned, see the discussion in
292 L<Category C<LC_COLLATE>: Collation>.
293
294 =item *
295
296 B<Regular expressions and case-modification functions> (C<uc()>, C<lc()>,
297 C<ucfirst()>, and C<lcfirst()>) use C<LC_CTYPE>
298
299 =item *
300
301 The variables L<$!|perlvar/$ERRNO> (and its synonyms C<$ERRNO> and
302 C<$OS_ERROR>) and L<$^E|perlvar/$EXTENDED_OS_ERROR> (and its synonym
303 C<$EXTENDED_OS_ERROR>) when used as strings use C<LC_MESSAGES>.
304
305 =back
306
307 =back
308
309 The default behavior is restored with the S<C<no locale>> pragma, or
310 upon reaching the end of the block enclosing C<use locale>.
311 Note that C<use locale> and C<use locale ':not_characters'> may be
312 nested, and that what is in effect within an inner scope will revert to
313 the outer scope's rules at the end of the inner scope.
314
315 The string result of any operation that uses locale
316 information is tainted, as it is possible for a locale to be
317 untrustworthy.  See L<"SECURITY">.
318
319 Starting in Perl v5.16 in a very limited way, and more generally in
320 v5.22, you can restrict which category or categories are enabled by this
321 particular instance of the pragma by adding parameters to it.  For
322 example,
323
324  use locale qw(:ctype :numeric);
325
326 enables locale awareness within its scope of only those operations
327 (listed above) that are affected by C<LC_CTYPE> and C<LC_NUMERIC>.
328
329 The possible categories are: C<:collate>, C<:ctype>, C<:messages>,
330 C<:monetary>, C<:numeric>, C<:time>, and the pseudo category
331 C<:characters> (described below).
332
333 Thus you can say
334
335  use locale ':messages';
336
337 and only L<$!|perlvar/$ERRNO> and L<$^E|perlvar/$EXTENDED_OS_ERROR>
338 will be locale aware.  Everything else is unaffected.
339
340 Since Perl doesn't currently do anything with the C<LC_MONETARY>
341 category, specifying C<:monetary> does effectively nothing.  Some
342 systems have other categories, such as C<LC_PAPER_SIZE>, but Perl
343 also doesn't know anything about them, and there is no way to specify
344 them in this pragma's arguments.
345
346 You can also easily say to use all categories but one, by either, for
347 example,
348
349  use locale ':!ctype';
350  use locale ':not_ctype';
351
352 both of which mean to enable locale awarness of all categories but
353 C<LC_CTYPE>.  Only one category argument may be specified in a
354 S<C<use locale>> if it is of the negated form.
355
356 Prior to v5.22 only one form of the pragma with arguments is available:
357
358  use locale ':not_characters';
359
360 (and you have to say C<not_>; you can't use the bang C<!> form).  This
361 pseudo category is a shorthand for specifying both C<:collate> and
362 C<:ctype>.  Hence, in the negated form, it is nearly the same thing as
363 saying
364
365  use locale qw(:messages :monetary :numeric :time);
366
367 We use the term "nearly", because C<:not_characters> also turns on
368 S<C<use feature 'unicode_strings'>> within its scope.  This form is
369 less useful in v5.20 and later, and is described fully in
370 L</Unicode and UTF-8>, but briefly, it tells Perl to not use the
371 character portions of the locale definition, that is the C<LC_CTYPE> and
372 C<LC_COLLATE> categories.  Instead it will use the native character set
373 (extended by Unicode).  When using this parameter, you are responsible
374 for getting the external character set translated into the
375 native/Unicode one (which it already will be if it is one of the
376 increasingly popular UTF-8 locales).  There are convenient ways of doing
377 this, as described in L</Unicode and UTF-8>.
378
379 =head2 The setlocale function
380
381 You can switch locales as often as you wish at run time with the
382 C<POSIX::setlocale()> function:
383
384         # Import locale-handling tool set from POSIX module.
385         # This example uses: setlocale -- the function call
386         #                    LC_CTYPE -- explained below
387         # (Showing the testing for success/failure of operations is
388         # omitted in these examples to avoid distracting from the main
389         # point)
390
391         use POSIX qw(locale_h);
392         use locale;
393         my $old_locale;
394
395         # query and save the old locale
396         $old_locale = setlocale(LC_CTYPE);
397
398         setlocale(LC_CTYPE, "fr_CA.ISO8859-1");
399         # LC_CTYPE now in locale "French, Canada, codeset ISO 8859-1"
400
401         setlocale(LC_CTYPE, "");
402         # LC_CTYPE now reset to the default defined by the
403         # LC_ALL/LC_CTYPE/LANG environment variables, or to the system
404         # default.  See below for documentation.
405
406         # restore the old locale
407         setlocale(LC_CTYPE, $old_locale);
408
409 The first argument of C<setlocale()> gives the B<category>, the second the
410 B<locale>.  The category tells in what aspect of data processing you
411 want to apply locale-specific rules.  Category names are discussed in
412 L</LOCALE CATEGORIES> and L</"ENVIRONMENT">.  The locale is the name of a
413 collection of customization information corresponding to a particular
414 combination of language, country or territory, and codeset.  Read on for
415 hints on the naming of locales: not all systems name locales as in the
416 example.
417
418 If no second argument is provided and the category is something other
419 than C<LC_ALL>, the function returns a string naming the current locale
420 for the category.  You can use this value as the second argument in a
421 subsequent call to C<setlocale()>, B<but> on some platforms the string
422 is opaque, not something that most people would be able to decipher as
423 to what locale it means.
424
425 If no second argument is provided and the category is C<LC_ALL>, the
426 result is implementation-dependent.  It may be a string of
427 concatenated locale names (separator also implementation-dependent)
428 or a single locale name.  Please consult your L<setlocale(3)> man page for
429 details.
430
431 If a second argument is given and it corresponds to a valid locale,
432 the locale for the category is set to that value, and the function
433 returns the now-current locale value.  You can then use this in yet
434 another call to C<setlocale()>.  (In some implementations, the return
435 value may sometimes differ from the value you gave as the second
436 argument--think of it as an alias for the value you gave.)
437
438 As the example shows, if the second argument is an empty string, the
439 category's locale is returned to the default specified by the
440 corresponding environment variables.  Generally, this results in a
441 return to the default that was in force when Perl started up: changes
442 to the environment made by the application after startup may or may not
443 be noticed, depending on your system's C library.
444
445 Note that when a form of C<use locale> that doesn't include all
446 categories is specified, Perl ignores the excluded categories.
447
448 If C<set_locale()> fails for some reason (for example, an attempt to set
449 to a locale unknown to the system), the locale for the category is not
450 changed, and the function returns C<undef>.
451
452
453 For further information about the categories, consult L<setlocale(3)>.
454
455 =head2 Finding locales
456
457 For locales available in your system, consult also L<setlocale(3)> to
458 see whether it leads to the list of available locales (search for the
459 I<SEE ALSO> section).  If that fails, try the following command lines:
460
461         locale -a
462
463         nlsinfo
464
465         ls /usr/lib/nls/loc
466
467         ls /usr/lib/locale
468
469         ls /usr/lib/nls
470
471         ls /usr/share/locale
472
473 and see whether they list something resembling these
474
475         en_US.ISO8859-1     de_DE.ISO8859-1     ru_RU.ISO8859-5
476         en_US.iso88591      de_DE.iso88591      ru_RU.iso88595
477         en_US               de_DE               ru_RU
478         en                  de                  ru
479         english             german              russian
480         english.iso88591    german.iso88591     russian.iso88595
481         english.roman8                          russian.koi8r
482
483 Sadly, even though the calling interface for C<setlocale()> has been
484 standardized, names of locales and the directories where the
485 configuration resides have not been.  The basic form of the name is
486 I<language_territory>B<.>I<codeset>, but the latter parts after
487 I<language> are not always present.  The I<language> and I<country>
488 are usually from the standards B<ISO 3166> and B<ISO 639>, the
489 two-letter abbreviations for the countries and the languages of the
490 world, respectively.  The I<codeset> part often mentions some B<ISO
491 8859> character set, the Latin codesets.  For example, C<ISO 8859-1>
492 is the so-called "Western European codeset" that can be used to encode
493 most Western European languages adequately.  Again, there are several
494 ways to write even the name of that one standard.  Lamentably.
495
496 Two special locales are worth particular mention: "C" and "POSIX".
497 Currently these are effectively the same locale: the difference is
498 mainly that the first one is defined by the C standard, the second by
499 the POSIX standard.  They define the B<default locale> in which
500 every program starts in the absence of locale information in its
501 environment.  (The I<default> default locale, if you will.)  Its language
502 is (American) English and its character codeset ASCII or, rarely, a
503 superset thereof (such as the "DEC Multinational Character Set
504 (DEC-MCS)").  B<Warning>. The C locale delivered by some vendors
505 may not actually exactly match what the C standard calls for.  So
506 beware.
507
508 B<NOTE>: Not all systems have the "POSIX" locale (not all systems are
509 POSIX-conformant), so use "C" when you need explicitly to specify this
510 default locale.
511
512 =head2 LOCALE PROBLEMS
513
514 You may encounter the following warning message at Perl startup:
515
516         perl: warning: Setting locale failed.
517         perl: warning: Please check that your locale settings:
518                 LC_ALL = "En_US",
519                 LANG = (unset)
520             are supported and installed on your system.
521         perl: warning: Falling back to the standard locale ("C").
522
523 This means that your locale settings had C<LC_ALL> set to "En_US" and
524 LANG exists but has no value.  Perl tried to believe you but could not.
525 Instead, Perl gave up and fell back to the "C" locale, the default locale
526 that is supposed to work no matter what.  (On Windows, it first tries
527 falling back to the system default locale.)  This usually means your
528 locale settings were wrong, they mention locales your system has never
529 heard of, or the locale installation in your system has problems (for
530 example, some system files are broken or missing).  There are quick and
531 temporary fixes to these problems, as well as more thorough and lasting
532 fixes.
533
534 =head2 Testing for broken locales
535
536 If you are building Perl from source, the Perl test suite file
537 F<lib/locale.t> can be used to test the locales on your system.
538 Setting the environment variable C<PERL_DEBUG_FULL_TEST> to 1
539 will cause it to output detailed results.  For example, on Linux, you
540 could say
541
542  PERL_DEBUG_FULL_TEST=1 ./perl -T -Ilib lib/locale.t > locale.log 2>&1
543
544 Besides many other tests, it will test every locale it finds on your
545 system to see if they conform to the POSIX standard.  If any have
546 errors, it will include a summary near the end of the output of which
547 locales passed all its tests, and which failed, and why.
548
549 =head2 Temporarily fixing locale problems
550
551 The two quickest fixes are either to render Perl silent about any
552 locale inconsistencies or to run Perl under the default locale "C".
553
554 Perl's moaning about locale problems can be silenced by setting the
555 environment variable C<PERL_BADLANG> to a zero value, for example "0".
556 This method really just sweeps the problem under the carpet: you tell
557 Perl to shut up even when Perl sees that something is wrong.  Do not
558 be surprised if later something locale-dependent misbehaves.
559
560 Perl can be run under the "C" locale by setting the environment
561 variable C<LC_ALL> to "C".  This method is perhaps a bit more civilized
562 than the C<PERL_BADLANG> approach, but setting C<LC_ALL> (or
563 other locale variables) may affect other programs as well, not just
564 Perl.  In particular, external programs run from within Perl will see
565 these changes.  If you make the new settings permanent (read on), all
566 programs you run see the changes.  See L<"ENVIRONMENT"> for
567 the full list of relevant environment variables and L<USING LOCALES>
568 for their effects in Perl.  Effects in other programs are
569 easily deducible.  For example, the variable C<LC_COLLATE> may well affect
570 your B<sort> program (or whatever the program that arranges "records"
571 alphabetically in your system is called).
572
573 You can test out changing these variables temporarily, and if the
574 new settings seem to help, put those settings into your shell startup
575 files.  Consult your local documentation for the exact details.  For in
576 Bourne-like shells (B<sh>, B<ksh>, B<bash>, B<zsh>):
577
578         LC_ALL=en_US.ISO8859-1
579         export LC_ALL
580
581 This assumes that we saw the locale "en_US.ISO8859-1" using the commands
582 discussed above.  We decided to try that instead of the above faulty
583 locale "En_US"--and in Cshish shells (B<csh>, B<tcsh>)
584
585         setenv LC_ALL en_US.ISO8859-1
586
587 or if you have the "env" application you can do in any shell
588
589         env LC_ALL=en_US.ISO8859-1 perl ...
590
591 If you do not know what shell you have, consult your local
592 helpdesk or the equivalent.
593
594 =head2 Permanently fixing locale problems
595
596 The slower but superior fixes are when you may be able to yourself
597 fix the misconfiguration of your own environment variables.  The
598 mis(sing)configuration of the whole system's locales usually requires
599 the help of your friendly system administrator.
600
601 First, see earlier in this document about L<Finding locales>.  That tells
602 how to find which locales are really supported--and more importantly,
603 installed--on your system.  In our example error message, environment
604 variables affecting the locale are listed in the order of decreasing
605 importance (and unset variables do not matter).  Therefore, having
606 LC_ALL set to "En_US" must have been the bad choice, as shown by the
607 error message.  First try fixing locale settings listed first.
608
609 Second, if using the listed commands you see something B<exactly>
610 (prefix matches do not count and case usually counts) like "En_US"
611 without the quotes, then you should be okay because you are using a
612 locale name that should be installed and available in your system.
613 In this case, see L<Permanently fixing your system's locale configuration>.
614
615 =head2 Permanently fixing your system's locale configuration
616
617 This is when you see something like:
618
619         perl: warning: Please check that your locale settings:
620                 LC_ALL = "En_US",
621                 LANG = (unset)
622             are supported and installed on your system.
623
624 but then cannot see that "En_US" listed by the above-mentioned
625 commands.  You may see things like "en_US.ISO8859-1", but that isn't
626 the same.  In this case, try running under a locale
627 that you can list and which somehow matches what you tried.  The
628 rules for matching locale names are a bit vague because
629 standardization is weak in this area.  See again the
630 L<Finding locales> about general rules.
631
632 =head2 Fixing system locale configuration
633
634 Contact a system administrator (preferably your own) and report the exact
635 error message you get, and ask them to read this same documentation you
636 are now reading.  They should be able to check whether there is something
637 wrong with the locale configuration of the system.  The L<Finding locales>
638 section is unfortunately a bit vague about the exact commands and places
639 because these things are not that standardized.
640
641 =head2 The localeconv function
642
643 The C<POSIX::localeconv()> function allows you to get particulars of the
644 locale-dependent numeric formatting information specified by the current
645 underlying C<LC_NUMERIC> and C<LC_MONETARY> locales (regardless of
646 whether called from within the scope of C<S<use locale>> or not).  (If
647 you just want the name of
648 the current locale for a particular category, use C<POSIX::setlocale()>
649 with a single parameter--see L<The setlocale function>.)
650
651         use POSIX qw(locale_h);
652
653         # Get a reference to a hash of locale-dependent info
654         $locale_values = localeconv();
655
656         # Output sorted list of the values
657         for (sort keys %$locale_values) {
658             printf "%-20s = %s\n", $_, $locale_values->{$_}
659         }
660
661 C<localeconv()> takes no arguments, and returns B<a reference to> a hash.
662 The keys of this hash are variable names for formatting, such as
663 C<decimal_point> and C<thousands_sep>.  The values are the
664 corresponding, er, values.  See L<POSIX/localeconv> for a longer
665 example listing the categories an implementation might be expected to
666 provide; some provide more and others fewer.  You don't need an
667 explicit C<use locale>, because C<localeconv()> always observes the
668 current locale.
669
670 Here's a simple-minded example program that rewrites its command-line
671 parameters as integers correctly formatted in the current locale:
672
673     use POSIX qw(locale_h);
674
675     # Get some of locale's numeric formatting parameters
676     my ($thousands_sep, $grouping) =
677             @{localeconv()}{'thousands_sep', 'grouping'};
678
679     # Apply defaults if values are missing
680     $thousands_sep = ',' unless $thousands_sep;
681
682     # grouping and mon_grouping are packed lists
683     # of small integers (characters) telling the
684     # grouping (thousand_seps and mon_thousand_seps
685     # being the group dividers) of numbers and
686     # monetary quantities.  The integers' meanings:
687     # 255 means no more grouping, 0 means repeat
688     # the previous grouping, 1-254 means use that
689     # as the current grouping.  Grouping goes from
690     # right to left (low to high digits).  In the
691     # below we cheat slightly by never using anything
692     # else than the first grouping (whatever that is).
693     if ($grouping) {
694         @grouping = unpack("C*", $grouping);
695     } else {
696         @grouping = (3);
697     }
698
699     # Format command line params for current locale
700     for (@ARGV) {
701         $_ = int;    # Chop non-integer part
702         1 while
703         s/(\d)(\d{$grouping[0]}($|$thousands_sep))/$1$thousands_sep$2/;
704         print "$_";
705     }
706     print "\n";
707
708 Note that if the platform doesn't have C<LC_NUMERIC> and/or
709 C<LC_MONETARY> available or enabled, the corresponding elements of the
710 hash will be missing.
711
712 =head2 I18N::Langinfo
713
714 Another interface for querying locale-dependent information is the
715 C<I18N::Langinfo::langinfo()> function, available at least in Unix-like
716 systems and VMS.
717
718 The following example will import the C<langinfo()> function itself and
719 three constants to be used as arguments to C<langinfo()>: a constant for
720 the abbreviated first day of the week (the numbering starts from
721 Sunday = 1) and two more constants for the affirmative and negative
722 answers for a yes/no question in the current locale.
723
724     use I18N::Langinfo qw(langinfo ABDAY_1 YESSTR NOSTR);
725
726     my ($abday_1, $yesstr, $nostr)
727                 = map { langinfo } qw(ABDAY_1 YESSTR NOSTR);
728
729     print "$abday_1? [$yesstr/$nostr] ";
730
731 In other words, in the "C" (or English) locale the above will probably
732 print something like:
733
734     Sun? [yes/no]
735
736 See L<I18N::Langinfo> for more information.
737
738 =head1 LOCALE CATEGORIES
739
740 The following subsections describe basic locale categories.  Beyond these,
741 some combination categories allow manipulation of more than one
742 basic category at a time.  See L<"ENVIRONMENT"> for a discussion of these.
743
744 =head2 Category C<LC_COLLATE>: Collation
745
746 In the scope of a S<C<use locale>> form that includes collation, Perl
747 looks to the C<LC_COLLATE>
748 environment variable to determine the application's notions on collation
749 (ordering) of characters.  For example, "b" follows "a" in Latin
750 alphabets, but where do "E<aacute>" and "E<aring>" belong?  And while
751 "color" follows "chocolate" in English, what about in traditional Spanish?
752
753 The following collations all make sense and you may meet any of them
754 if you "use locale".
755
756         A B C D E a b c d e
757         A a B b C c D d E e
758         a A b B c C d D e E
759         a b c d e A B C D E
760
761 Here is a code snippet to tell what "word"
762 characters are in the current locale, in that locale's order:
763
764         use locale;
765         print +(sort grep /\w/, map { chr } 0..255), "\n";
766
767 Compare this with the characters that you see and their order if you
768 state explicitly that the locale should be ignored:
769
770         no locale;
771         print +(sort grep /\w/, map { chr } 0..255), "\n";
772
773 This machine-native collation (which is what you get unless S<C<use
774 locale>> has appeared earlier in the same block) must be used for
775 sorting raw binary data, whereas the locale-dependent collation of the
776 first example is useful for natural text.
777
778 As noted in L<USING LOCALES>, C<cmp> compares according to the current
779 collation locale when C<use locale> is in effect, but falls back to a
780 char-by-char comparison for strings that the locale says are equal. You
781 can use C<POSIX::strcoll()> if you don't want this fall-back:
782
783         use POSIX qw(strcoll);
784         $equal_in_locale =
785             !strcoll("space and case ignored", "SpaceAndCaseIgnored");
786
787 C<$equal_in_locale> will be true if the collation locale specifies a
788 dictionary-like ordering that ignores space characters completely and
789 which folds case.
790
791 Perl only supports single-byte locales for C<LC_COLLATE>.  This means
792 that a UTF-8 locale likely will just give you machine-native ordering.
793 Use L<Unicode::Collate> for the full implementation of the Unicode
794 Collation Algorithm.
795
796 If you have a single string that you want to check for "equality in
797 locale" against several others, you might think you could gain a little
798 efficiency by using C<POSIX::strxfrm()> in conjunction with C<eq>:
799
800         use POSIX qw(strxfrm);
801         $xfrm_string = strxfrm("Mixed-case string");
802         print "locale collation ignores spaces\n"
803             if $xfrm_string eq strxfrm("Mixed-casestring");
804         print "locale collation ignores hyphens\n"
805             if $xfrm_string eq strxfrm("Mixedcase string");
806         print "locale collation ignores case\n"
807             if $xfrm_string eq strxfrm("mixed-case string");
808
809 C<strxfrm()> takes a string and maps it into a transformed string for use
810 in char-by-char comparisons against other transformed strings during
811 collation.  "Under the hood", locale-affected Perl comparison operators
812 call C<strxfrm()> for both operands, then do a char-by-char
813 comparison of the transformed strings.  By calling C<strxfrm()> explicitly
814 and using a non locale-affected comparison, the example attempts to save
815 a couple of transformations.  But in fact, it doesn't save anything: Perl
816 magic (see L<perlguts/Magic Variables>) creates the transformed version of a
817 string the first time it's needed in a comparison, then keeps this version around
818 in case it's needed again.  An example rewritten the easy way with
819 C<cmp> runs just about as fast.  It also copes with null characters
820 embedded in strings; if you call C<strxfrm()> directly, it treats the first
821 null it finds as a terminator.  don't expect the transformed strings
822 it produces to be portable across systems--or even from one revision
823 of your operating system to the next.  In short, don't call C<strxfrm()>
824 directly: let Perl do it for you.
825
826 Note: C<use locale> isn't shown in some of these examples because it isn't
827 needed: C<strcoll()> and C<strxfrm()> are POSIX functions
828 which use the standard system-supplied C<libc> functions that
829 always obey the current C<LC_COLLATE> locale.
830
831 =head2 Category C<LC_CTYPE>: Character Types
832
833 In the scope of a S<C<use locale>> form that includes C<LC_CTYPE>, Perl
834 obeys the C<LC_CTYPE> locale
835 setting.  This controls the application's notion of which characters are
836 alphabetic, numeric, punctuation, I<etc>.  This affects Perl's C<\w>
837 regular expression metanotation,
838 which stands for alphanumeric characters--that is, alphabetic,
839 numeric, and the platform's native underscore.
840 (Consult L<perlre> for more information about
841 regular expressions.)  Thanks to C<LC_CTYPE>, depending on your locale
842 setting, characters like "E<aelig>", "E<eth>", "E<szlig>", and
843 "E<oslash>" may be understood as C<\w> characters.
844 It also affects things like C<\s>, C<\D>, and the POSIX character
845 classes, like C<[[:graph:]]>.  (See L<perlrecharclass> for more
846 information on all these.)
847
848 The C<LC_CTYPE> locale also provides the map used in transliterating
849 characters between lower and uppercase.  This affects the case-mapping
850 functions--C<fc()>, C<lc()>, C<lcfirst()>, C<uc()>, and C<ucfirst()>; case-mapping
851 interpolation with C<\F>, C<\l>, C<\L>, C<\u>, or C<\U> in double-quoted
852 strings and C<s///> substitutions; and case-independent regular expression
853 pattern matching using the C<i> modifier.
854
855 Finally, C<LC_CTYPE> affects the (deprecated) POSIX character-class test
856 functions--C<POSIX::isalpha()>, C<POSIX::islower()>, and so on.  For
857 example, if you move from the "C" locale to a 7-bit Scandinavian one,
858 you may find--possibly to your surprise--that "|" moves from the
859 C<POSIX::ispunct()> class to C<POSIX::isalpha()>.
860 Unfortunately, this creates big problems for regular expressions. "|" still
861 means alternation even though it matches C<\w>.
862
863 Starting in v5.20, Perl supports UTF-8 locales for C<LC_CTYPE>, but
864 otherwise Perl only supports single-byte locales, such as the ISO 8859
865 series.  This means that wide character locales, for example for Asian
866 languages, are not supported.  The UTF-8 locale support is actually a
867 superset of POSIX locales, because it is really full Unicode behavior
868 as if no locale were in effect at all (except for tainting; see
869 L</SECURITY>).  POSIX locales, even UTF-8 ones,
870 are lacking certain concepts in Unicode, such as the idea that changing
871 the case of a character could expand to be more than one character.
872 Perl in a UTF-8 locale, will give you that expansion.  Prior to v5.20,
873 Perl treated a UTF-8 locale on some platforms like an ISO 8859-1 one,
874 with some restrictions, and on other platforms more like the "C" locale.
875 For releases v5.16 and v5.18, C<S<use locale 'not_characters>> could be
876 used as a workaround for this (see L</Unicode and UTF-8>).
877
878 Note that there are quite a few things that are unaffected by the
879 current locale.  All the escape sequences for particular characters,
880 C<\n> for example, always mean the platform's native one.  This means,
881 for example, that C<\N> in regular expressions (every character
882 but new-line) works on the platform character set.
883
884 B<Note:> A broken or malicious C<LC_CTYPE> locale definition may result
885 in clearly ineligible characters being considered to be alphanumeric by
886 your application.  For strict matching of (mundane) ASCII letters and
887 digits--for example, in command strings--locale-aware applications
888 should use C<\w> with the C</a> regular expression modifier.  See L<"SECURITY">.
889
890 =head2 Category C<LC_NUMERIC>: Numeric Formatting
891
892 After a proper C<POSIX::setlocale()> call, and within the scope of
893 of a C<use locale> form that includes numerics, Perl obeys the
894 C<LC_NUMERIC> locale information, which controls an application's idea
895 of how numbers should be formatted for human readability.
896 In most implementations the only effect is to
897 change the character used for the decimal point--perhaps from "."  to ",".
898 The functions aren't aware of such niceties as thousands separation and
899 so on. (See L<The localeconv function> if you care about these things.)
900
901  use POSIX qw(strtod setlocale LC_NUMERIC);
902  use locale;
903
904  setlocale LC_NUMERIC, "";
905
906  $n = 5/2;   # Assign numeric 2.5 to $n
907
908  $a = " $n"; # Locale-dependent conversion to string
909
910  print "half five is $n\n";       # Locale-dependent output
911
912  printf "half five is %g\n", $n;  # Locale-dependent output
913
914  print "DECIMAL POINT IS COMMA\n"
915           if $n == (strtod("2,5"))[0]; # Locale-dependent conversion
916
917 See also L<I18N::Langinfo> and C<RADIXCHAR>.
918
919 =head2 Category C<LC_MONETARY>: Formatting of monetary amounts
920
921 The C standard defines the C<LC_MONETARY> category, but not a function
922 that is affected by its contents.  (Those with experience of standards
923 committees will recognize that the working group decided to punt on the
924 issue.)  Consequently, Perl essentially takes no notice of it.  If you
925 really want to use C<LC_MONETARY>, you can query its contents--see
926 L<The localeconv function>--and use the information that it returns in your
927 application's own formatting of currency amounts.  However, you may well
928 find that the information, voluminous and complex though it may be, still
929 does not quite meet your requirements: currency formatting is a hard nut
930 to crack.
931
932 See also L<I18N::Langinfo> and C<CRNCYSTR>.
933
934 =head2 C<LC_TIME>
935
936 Output produced by C<POSIX::strftime()>, which builds a formatted
937 human-readable date/time string, is affected by the current C<LC_TIME>
938 locale.  Thus, in a French locale, the output produced by the C<%B>
939 format element (full month name) for the first month of the year would
940 be "janvier".  Here's how to get a list of long month names in the
941 current locale:
942
943         use POSIX qw(strftime);
944         for (0..11) {
945             $long_month_name[$_] =
946                 strftime("%B", 0, 0, 0, 1, $_, 96);
947         }
948
949 Note: C<use locale> isn't needed in this example: C<strftime()> is a POSIX
950 function which uses the standard system-supplied C<libc> function that
951 always obeys the current C<LC_TIME> locale.
952
953 See also L<I18N::Langinfo> and C<ABDAY_1>..C<ABDAY_7>, C<DAY_1>..C<DAY_7>,
954 C<ABMON_1>..C<ABMON_12>, and C<ABMON_1>..C<ABMON_12>.
955
956 =head2 Other categories
957
958 The remaining locale categories are not currently used by Perl itself.
959 But again note that things Perl interacts with may use these, including
960 extensions outside the standard Perl distribution, and by the
961 operating system and its utilities.  Note especially that the string
962 value of C<$!> and the error messages given by external utilities may
963 be changed by C<LC_MESSAGES>.  If you want to have portable error
964 codes, use C<%!>.  See L<Errno>.
965
966 =head1 SECURITY
967
968 Although the main discussion of Perl security issues can be found in
969 L<perlsec>, a discussion of Perl's locale handling would be incomplete
970 if it did not draw your attention to locale-dependent security issues.
971 Locales--particularly on systems that allow unprivileged users to
972 build their own locales--are untrustworthy.  A malicious (or just plain
973 broken) locale can make a locale-aware application give unexpected
974 results.  Here are a few possibilities:
975
976 =over 4
977
978 =item *
979
980 Regular expression checks for safe file names or mail addresses using
981 C<\w> may be spoofed by an C<LC_CTYPE> locale that claims that
982 characters such as "E<gt>" and "|" are alphanumeric.
983
984 =item *
985
986 String interpolation with case-mapping, as in, say, C<$dest =
987 "C:\U$name.$ext">, may produce dangerous results if a bogus C<LC_CTYPE>
988 case-mapping table is in effect.
989
990 =item *
991
992 A sneaky C<LC_COLLATE> locale could result in the names of students with
993 "D" grades appearing ahead of those with "A"s.
994
995 =item *
996
997 An application that takes the trouble to use information in
998 C<LC_MONETARY> may format debits as if they were credits and vice versa
999 if that locale has been subverted.  Or it might make payments in US
1000 dollars instead of Hong Kong dollars.
1001
1002 =item *
1003
1004 The date and day names in dates formatted by C<strftime()> could be
1005 manipulated to advantage by a malicious user able to subvert the
1006 C<LC_DATE> locale.  ("Look--it says I wasn't in the building on
1007 Sunday.")
1008
1009 =back
1010
1011 Such dangers are not peculiar to the locale system: any aspect of an
1012 application's environment which may be modified maliciously presents
1013 similar challenges.  Similarly, they are not specific to Perl: any
1014 programming language that allows you to write programs that take
1015 account of their environment exposes you to these issues.
1016
1017 Perl cannot protect you from all possibilities shown in the
1018 examples--there is no substitute for your own vigilance--but, when
1019 C<use locale> is in effect, Perl uses the tainting mechanism (see
1020 L<perlsec>) to mark string results that become locale-dependent, and
1021 which may be untrustworthy in consequence.  Here is a summary of the
1022 tainting behavior of operators and functions that may be affected by
1023 the locale:
1024
1025 =over 4
1026
1027 =item  *
1028
1029 B<Comparison operators> (C<lt>, C<le>, C<ge>, C<gt> and C<cmp>):
1030
1031 Scalar true/false (or less/equal/greater) result is never tainted.
1032
1033 =item  *
1034
1035 B<Case-mapping interpolation> (with C<\l>, C<\L>, C<\u>, C<\U>, or C<\F>)
1036
1037 The result string containing interpolated material is tainted if
1038 a C<use locale> form that includes C<LC_CTYPE> is in effect.
1039
1040 =item  *
1041
1042 B<Matching operator> (C<m//>):
1043
1044 Scalar true/false result never tainted.
1045
1046 All subpatterns, either delivered as a list-context result or as C<$1>
1047 I<etc>., are tainted if a C<use locale> form that includes
1048 C<LC_CTYPE> is in effect, and the subpattern
1049 regular expression contains a locale-dependent construct.  These
1050 constructs include C<\w> (to match an alphanumeric character), C<\W>
1051 (non-alphanumeric character), C<\b> and C<\B> (word-boundary and
1052 non-boundardy, which depend on what C<\w> and C<\W> match), C<\s>
1053 (whitespace character), C<\S> (non whitespace character), C<\d> and
1054 C<\D> (digits and non-digits), and the POSIX character classes, such as
1055 C<[:alpha:]> (see L<perlrecharclass/POSIX Character Classes>).
1056
1057 Tainting is also likely if the pattern is to be matched
1058 case-insensitively (via C</i>).  The exception is if all the code points
1059 to be matched this way are above 255 and do not have folds under Unicode
1060 rules to below 256.  Tainting is not done for these because Perl
1061 only uses Unicode rules for such code points, and those rules are the
1062 same no matter what the current locale.
1063
1064 The matched-pattern variables, C<$&>, C<$`> (pre-match), C<$'>
1065 (post-match), and C<$+> (last match) also are tainted.
1066
1067 =item  *
1068
1069 B<Substitution operator> (C<s///>):
1070
1071 Has the same behavior as the match operator.  Also, the left
1072 operand of C<=~> becomes tainted when a C<use locale>
1073 form that includes C<LC_CTYPE> is in effect, if modified as
1074 a result of a substitution based on a regular
1075 expression match involving any of the things mentioned in the previous
1076 item, or of case-mapping, such as C<\l>, C<\L>,C<\u>, C<\U>, or C<\F>.
1077
1078 =item *
1079
1080 B<Output formatting functions> (C<printf()> and C<write()>):
1081
1082 Results are never tainted because otherwise even output from print,
1083 for example C<print(1/7)>, should be tainted if C<use locale> is in
1084 effect.
1085
1086 =item *
1087
1088 B<Case-mapping functions> (C<lc()>, C<lcfirst()>, C<uc()>, C<ucfirst()>):
1089
1090 Results are tainted if a C<use locale> form that includes C<LC_CTYPE> is
1091 in effect.
1092
1093 =item *
1094
1095 B<POSIX locale-dependent functions> (C<localeconv()>, C<strcoll()>,
1096 C<strftime()>, C<strxfrm()>):
1097
1098 Results are never tainted.
1099
1100 =item *
1101
1102 B<POSIX character class tests> (C<POSIX::isalnum()>,
1103 C<POSIX::isalpha()>, C<POSIX::isdigit()>, C<POSIX::isgraph()>,
1104 C<POSIX::islower()>, C<POSIX::isprint()>, C<POSIX::ispunct()>,
1105 C<POSIX::isspace()>, C<POSIX::isupper()>, C<POSIX::isxdigit()>):
1106
1107 True/false results are never tainted.
1108
1109 =back
1110
1111 Three examples illustrate locale-dependent tainting.
1112 The first program, which ignores its locale, won't run: a value taken
1113 directly from the command line may not be used to name an output file
1114 when taint checks are enabled.
1115
1116         #/usr/local/bin/perl -T
1117         # Run with taint checking
1118
1119         # Command line sanity check omitted...
1120         $tainted_output_file = shift;
1121
1122         open(F, ">$tainted_output_file")
1123             or warn "Open of $tainted_output_file failed: $!\n";
1124
1125 The program can be made to run by "laundering" the tainted value through
1126 a regular expression: the second example--which still ignores locale
1127 information--runs, creating the file named on its command line
1128 if it can.
1129
1130         #/usr/local/bin/perl -T
1131
1132         $tainted_output_file = shift;
1133         $tainted_output_file =~ m%[\w/]+%;
1134         $untainted_output_file = $&;
1135
1136         open(F, ">$untainted_output_file")
1137             or warn "Open of $untainted_output_file failed: $!\n";
1138
1139 Compare this with a similar but locale-aware program:
1140
1141         #/usr/local/bin/perl -T
1142
1143         $tainted_output_file = shift;
1144         use locale;
1145         $tainted_output_file =~ m%[\w/]+%;
1146         $localized_output_file = $&;
1147
1148         open(F, ">$localized_output_file")
1149             or warn "Open of $localized_output_file failed: $!\n";
1150
1151 This third program fails to run because C<$&> is tainted: it is the result
1152 of a match involving C<\w> while C<use locale> is in effect.
1153
1154 =head1 ENVIRONMENT
1155
1156 =over 12
1157
1158 =item PERL_SKIP_LOCALE_INIT
1159
1160 This environment variable, available starting in Perl v5.20, and if it
1161 evaluates to a TRUE value, tells Perl to not use the rest of the
1162 environment variables to initialize with.  Instead, Perl uses whatever
1163 the current locale settings are.  This is particularly useful in
1164 embedded environments, see
1165 L<perlembed/Using embedded Perl with POSIX locales>.
1166
1167 =item PERL_BADLANG
1168
1169 A string that can suppress Perl's warning about failed locale settings
1170 at startup.  Failure can occur if the locale support in the operating
1171 system is lacking (broken) in some way--or if you mistyped the name of
1172 a locale when you set up your environment.  If this environment
1173 variable is absent, or has a value that does not evaluate to integer
1174 zero--that is, "0" or ""-- Perl will complain about locale setting
1175 failures.
1176
1177 B<NOTE>: C<PERL_BADLANG> only gives you a way to hide the warning message.
1178 The message tells about some problem in your system's locale support,
1179 and you should investigate what the problem is.
1180
1181 =back
1182
1183 The following environment variables are not specific to Perl: They are
1184 part of the standardized (ISO C, XPG4, POSIX 1.c) C<setlocale()> method
1185 for controlling an application's opinion on data.  Windows is non-POSIX,
1186 but Perl arranges for the following to work as described anyway.
1187 If the locale given by an environment variable is not valid, Perl tries
1188 the next lower one in priority.  If none are valid, on Windows, the
1189 system default locale is then tried.  If all else fails, the C<"C">
1190 locale is used.  If even that doesn't work, something is badly broken,
1191 but Perl tries to forge ahead with whatever the locale settings might
1192 be.
1193
1194 =over 12
1195
1196 =item C<LC_ALL>
1197
1198 C<LC_ALL> is the "override-all" locale environment variable. If
1199 set, it overrides all the rest of the locale environment variables.
1200
1201 =item C<LANGUAGE>
1202
1203 B<NOTE>: C<LANGUAGE> is a GNU extension, it affects you only if you
1204 are using the GNU libc.  This is the case if you are using e.g. Linux.
1205 If you are using "commercial" Unixes you are most probably I<not>
1206 using GNU libc and you can ignore C<LANGUAGE>.
1207
1208 However, in the case you are using C<LANGUAGE>: it affects the
1209 language of informational, warning, and error messages output by
1210 commands (in other words, it's like C<LC_MESSAGES>) but it has higher
1211 priority than C<LC_ALL>.  Moreover, it's not a single value but
1212 instead a "path" (":"-separated list) of I<languages> (not locales).
1213 See the GNU C<gettext> library documentation for more information.
1214
1215 =item C<LC_CTYPE>.
1216
1217 In the absence of C<LC_ALL>, C<LC_CTYPE> chooses the character type
1218 locale.  In the absence of both C<LC_ALL> and C<LC_CTYPE>, C<LANG>
1219 chooses the character type locale.
1220
1221 =item C<LC_COLLATE>
1222
1223 In the absence of C<LC_ALL>, C<LC_COLLATE> chooses the collation
1224 (sorting) locale.  In the absence of both C<LC_ALL> and C<LC_COLLATE>,
1225 C<LANG> chooses the collation locale.
1226
1227 =item C<LC_MONETARY>
1228
1229 In the absence of C<LC_ALL>, C<LC_MONETARY> chooses the monetary
1230 formatting locale.  In the absence of both C<LC_ALL> and C<LC_MONETARY>,
1231 C<LANG> chooses the monetary formatting locale.
1232
1233 =item C<LC_NUMERIC>
1234
1235 In the absence of C<LC_ALL>, C<LC_NUMERIC> chooses the numeric format
1236 locale.  In the absence of both C<LC_ALL> and C<LC_NUMERIC>, C<LANG>
1237 chooses the numeric format.
1238
1239 =item C<LC_TIME>
1240
1241 In the absence of C<LC_ALL>, C<LC_TIME> chooses the date and time
1242 formatting locale.  In the absence of both C<LC_ALL> and C<LC_TIME>,
1243 C<LANG> chooses the date and time formatting locale.
1244
1245 =item C<LANG>
1246
1247 C<LANG> is the "catch-all" locale environment variable. If it is set, it
1248 is used as the last resort after the overall C<LC_ALL> and the
1249 category-specific C<LC_I<foo>>
1250
1251 =back
1252
1253 =head2 Examples
1254
1255 The C<LC_NUMERIC> controls the numeric output:
1256
1257    use locale;
1258    use POSIX qw(locale_h); # Imports setlocale() and the LC_ constants.
1259    setlocale(LC_NUMERIC, "fr_FR") or die "Pardon";
1260    printf "%g\n", 1.23; # If the "fr_FR" succeeded, probably shows 1,23.
1261
1262 and also how strings are parsed by C<POSIX::strtod()> as numbers:
1263
1264    use locale;
1265    use POSIX qw(locale_h strtod);
1266    setlocale(LC_NUMERIC, "de_DE") or die "Entschuldigung";
1267    my $x = strtod("2,34") + 5;
1268    print $x, "\n"; # Probably shows 7,34.
1269
1270 =head1 NOTES
1271
1272 =head2 String C<eval> and C<LC_NUMERIC>
1273
1274 A string L<eval|perlfunc/eval EXPR> parses its expression as standard
1275 Perl.  It is therefore expecting the decimal point to be a dot.  If
1276 C<LC_NUMERIC> is set to have this be a comma instead, the parsing will
1277 be confused, perhaps silently.
1278
1279  use locale;
1280  use POSIX qw(locale_h);
1281  setlocale(LC_NUMERIC, "fr_FR") or die "Pardon";
1282  my $a = 1.2;
1283  print eval "$a + 1.5";
1284  print "\n";
1285
1286 prints C<13,5>.  This is because in that locale, the comma is the
1287 decimal point character.  The C<eval> thus expands to:
1288
1289  eval "1,2 + 1.5"
1290
1291 and the result is not what you likely expected.  No warnings are
1292 generated.  If you do string C<eval>'s within the scope of
1293 S<C<use locale>>, you should instead change the C<eval> line to do
1294 something like:
1295
1296  print eval "no locale; $a + 1.5";
1297
1298 This prints C<2.7>.
1299
1300 You could also exclude C<LC_NUMERIC>, if you don't need it, by
1301
1302  use locale ':!numeric';
1303
1304 =head2 Backward compatibility
1305
1306 Versions of Perl prior to 5.004 B<mostly> ignored locale information,
1307 generally behaving as if something similar to the C<"C"> locale were
1308 always in force, even if the program environment suggested otherwise
1309 (see L<The setlocale function>).  By default, Perl still behaves this
1310 way for backward compatibility.  If you want a Perl application to pay
1311 attention to locale information, you B<must> use the S<C<use locale>>
1312 pragma (see L<The "use locale" pragma>) or, in the unlikely event
1313 that you want to do so for just pattern matching, the
1314 C</l> regular expression modifier (see L<perlre/Character set
1315 modifiers>) to instruct it to do so.
1316
1317 Versions of Perl from 5.002 to 5.003 did use the C<LC_CTYPE>
1318 information if available; that is, C<\w> did understand what
1319 were the letters according to the locale environment variables.
1320 The problem was that the user had no control over the feature:
1321 if the C library supported locales, Perl used them.
1322
1323 =head2 I18N:Collate obsolete
1324
1325 In versions of Perl prior to 5.004, per-locale collation was possible
1326 using the C<I18N::Collate> library module.  This module is now mildly
1327 obsolete and should be avoided in new applications.  The C<LC_COLLATE>
1328 functionality is now integrated into the Perl core language: One can
1329 use locale-specific scalar data completely normally with C<use locale>,
1330 so there is no longer any need to juggle with the scalar references of
1331 C<I18N::Collate>.
1332
1333 =head2 Sort speed and memory use impacts
1334
1335 Comparing and sorting by locale is usually slower than the default
1336 sorting; slow-downs of two to four times have been observed.  It will
1337 also consume more memory: once a Perl scalar variable has participated
1338 in any string comparison or sorting operation obeying the locale
1339 collation rules, it will take 3-15 times more memory than before.  (The
1340 exact multiplier depends on the string's contents, the operating system
1341 and the locale.) These downsides are dictated more by the operating
1342 system's implementation of the locale system than by Perl.
1343
1344 =head2 Freely available locale definitions
1345
1346 The Unicode CLDR project extracts the POSIX portion of many of its
1347 locales, available at
1348
1349   http://unicode.org/Public/cldr/latest/
1350
1351 There is a large collection of locale definitions at:
1352
1353   http://std.dkuug.dk/i18n/WG15-collection/locales/
1354
1355 You should be aware that it is
1356 unsupported, and is not claimed to be fit for any purpose.  If your
1357 system allows installation of arbitrary locales, you may find the
1358 definitions useful as they are, or as a basis for the development of
1359 your own locales.
1360
1361 =head2 I18n and l10n
1362
1363 "Internationalization" is often abbreviated as B<i18n> because its first
1364 and last letters are separated by eighteen others.  (You may guess why
1365 the internalin ... internaliti ... i18n tends to get abbreviated.)  In
1366 the same way, "localization" is often abbreviated to B<l10n>.
1367
1368 =head2 An imperfect standard
1369
1370 Internationalization, as defined in the C and POSIX standards, can be
1371 criticized as incomplete, ungainly, and having too large a granularity.
1372 (Locales apply to a whole process, when it would arguably be more useful
1373 to have them apply to a single thread, window group, or whatever.)  They
1374 also have a tendency, like standards groups, to divide the world into
1375 nations, when we all know that the world can equally well be divided
1376 into bankers, bikers, gamers, and so on.
1377
1378 =head1 Unicode and UTF-8
1379
1380 The support of Unicode is new starting from Perl version v5.6, and more fully
1381 implemented in versions v5.8 and later.  See L<perluniintro>.
1382
1383 Starting in Perl v5.20, UTF-8 locales are supported in Perl, except for
1384 C<LC_COLLATE> (use L<Unicode::Collate> instead).  If you have Perl v5.16
1385 or v5.18 and can't upgrade, you can use
1386
1387     use locale ':not_characters';
1388
1389 When this form of the pragma is used, only the non-character portions of
1390 locales are used by Perl, for example C<LC_NUMERIC>.  Perl assumes that
1391 you have translated all the characters it is to operate on into Unicode
1392 (actually the platform's native character set (ASCII or EBCDIC) plus
1393 Unicode).  For data in files, this can conveniently be done by also
1394 specifying
1395
1396     use open ':locale';
1397
1398 This pragma arranges for all inputs from files to be translated into
1399 Unicode from the current locale as specified in the environment (see
1400 L</ENVIRONMENT>), and all outputs to files to be translated back
1401 into the locale.  (See L<open>).  On a per-filehandle basis, you can
1402 instead use the L<PerlIO::locale> module, or the L<Encode::Locale>
1403 module, both available from CPAN.  The latter module also has methods to
1404 ease the handling of C<ARGV> and environment variables, and can be used
1405 on individual strings.  If you know that all your locales will be
1406 UTF-8, as many are these days, you can use the L<B<-C>|perlrun/-C>
1407 command line switch.
1408
1409 This form of the pragma allows essentially seamless handling of locales
1410 with Unicode.  The collation order will be by Unicode code point order.
1411 It is strongly
1412 recommended that when you need to order and sort strings that you use
1413 the standard module L<Unicode::Collate> which gives much better results
1414 in many instances than you can get with the old-style locale handling.
1415
1416 All the modules and switches just described can be used in v5.20 with
1417 just plain C<use locale>, and, should the input locales not be UTF-8,
1418 you'll get the less than ideal behavior, described below, that you get
1419 with pre-v5.16 Perls, or when you use the locale pragma without the
1420 C<:not_characters> parameter in v5.16 and v5.18.  If you are using
1421 exclusively UTF-8 locales in v5.20 and higher, the rest of this section
1422 does not apply to you.
1423
1424 There are two cases, multi-byte and single-byte locales.  First
1425 multi-byte:
1426
1427 The only multi-byte (or wide character) locale that Perl is ever likely
1428 to support is UTF-8.  This is due to the difficulty of implementation,
1429 the fact that high quality UTF-8 locales are now published for every
1430 area of the world (L<http://unicode.org/Public/cldr/latest/>), and that
1431 failing all that you can use the L<Encode> module to translate to/from
1432 your locale.  So, you'll have to do one of those things if you're using
1433 one of these locales, such as Big5 or Shift JIS.  For UTF-8 locales, in
1434 Perls (pre v5.20) that don't have full UTF-8 locale support, they may
1435 work reasonably well (depending on your C library implementation)
1436 simply because both
1437 they and Perl store characters that take up multiple bytes the same way.
1438 However, some, if not most, C library implementations may not process
1439 the characters in the upper half of the Latin-1 range (128 - 255)
1440 properly under C<LC_CTYPE>.  To see if a character is a particular type
1441 under a locale, Perl uses the functions like C<isalnum()>.  Your C
1442 library may not work for UTF-8 locales with those functions, instead
1443 only working under the newer wide library functions like C<iswalnum()>.
1444 However, they are treated like single-byte locales, and will have the
1445 restrictions described below.
1446
1447 For single-byte locales,
1448 Perl generally takes the tack to use locale rules on code points that can fit
1449 in a single byte, and Unicode rules for those that can't (though this
1450 isn't uniformly applied, see the note at the end of this section).  This
1451 prevents many problems in locales that aren't UTF-8.  Suppose the locale
1452 is ISO8859-7, Greek.  The character at 0xD7 there is a capital Chi. But
1453 in the ISO8859-1 locale, Latin1, it is a multiplication sign.  The POSIX
1454 regular expression character class C<[[:alpha:]]> will magically match
1455 0xD7 in the Greek locale but not in the Latin one.
1456
1457 However, there are places where this breaks down.  Certain Perl constructs are
1458 for Unicode only, such as C<\p{Alpha}>.  They assume that 0xD7 always has its
1459 Unicode meaning (or the equivalent on EBCDIC platforms).  Since Latin1 is a
1460 subset of Unicode and 0xD7 is the multiplication sign in both Latin1 and
1461 Unicode, C<\p{Alpha}> will never match it, regardless of locale.  A similar
1462 issue occurs with C<\N{...}>.  Prior to v5.20, It is therefore a bad
1463 idea to use C<\p{}> or
1464 C<\N{}> under plain C<use locale>--I<unless> you can guarantee that the
1465 locale will be a ISO8859-1.  Use POSIX character classes instead.
1466
1467 Another problem with this approach is that operations that cross the
1468 single byte/multiple byte boundary are not well-defined, and so are
1469 disallowed.  (This boundary is between the codepoints at 255/256.)
1470 For example, lower casing LATIN CAPITAL LETTER Y WITH DIAERESIS (U+0178)
1471 should return LATIN SMALL LETTER Y WITH DIAERESIS (U+00FF).  But in the
1472 Greek locale, for example, there is no character at 0xFF, and Perl
1473 has no way of knowing what the character at 0xFF is really supposed to
1474 represent.  Thus it disallows the operation.  In this mode, the
1475 lowercase of U+0178 is itself.
1476
1477 The same problems ensue if you enable automatic UTF-8-ification of your
1478 standard file handles, default C<open()> layer, and C<@ARGV> on non-ISO8859-1,
1479 non-UTF-8 locales (by using either the B<-C> command line switch or the
1480 C<PERL_UNICODE> environment variable; see L<perlrun>).
1481 Things are read in as UTF-8, which would normally imply a Unicode
1482 interpretation, but the presence of a locale causes them to be interpreted
1483 in that locale instead.  For example, a 0xD7 code point in the Unicode
1484 input, which should mean the multiplication sign, won't be interpreted by
1485 Perl that way under the Greek locale.  This is not a problem
1486 I<provided> you make certain that all locales will always and only be either
1487 an ISO8859-1, or, if you don't have a deficient C library, a UTF-8 locale.
1488
1489 Still another problem is that this approach can lead to two code
1490 points meaning the same character.  Thus in a Greek locale, both U+03A7
1491 and U+00D7 are GREEK CAPITAL LETTER CHI.
1492
1493 Vendor locales are notoriously buggy, and it is difficult for Perl to test
1494 its locale-handling code because this interacts with code that Perl has no
1495 control over; therefore the locale-handling code in Perl may be buggy as
1496 well.  (However, the Unicode-supplied locales should be better, and
1497 there is a feed back mechanism to correct any problems.  See
1498 L</Freely available locale definitions>.)
1499
1500 If you have Perl v5.16, the problems mentioned above go away if you use
1501 the C<:not_characters> parameter to the locale pragma (except for vendor
1502 bugs in the non-character portions).  If you don't have v5.16, and you
1503 I<do> have locales that work, using them may be worthwhile for certain
1504 specific purposes, as long as you keep in mind the gotchas already
1505 mentioned.  For example, if the collation for your locales works, it
1506 runs faster under locales than under L<Unicode::Collate>; and you gain
1507 access to such things as the local currency symbol and the names of the
1508 months and days of the week.  (But to hammer home the point, in v5.16,
1509 you get this access without the downsides of locales by using the
1510 C<:not_characters> form of the pragma.)
1511
1512 Note: The policy of using locale rules for code points that can fit in a
1513 byte, and Unicode rules for those that can't is not uniformly applied.
1514 Pre-v5.12, it was somewhat haphazard; in v5.12 it was applied fairly
1515 consistently to regular expression matching except for bracketed
1516 character classes; in v5.14 it was extended to all regex matches; and in
1517 v5.16 to the casing operations such as C<"\L"> and C<uc()>.  For
1518 collation, in all releases, the system's C<strxfrm()> function is called,
1519 and whatever it does is what you get.
1520
1521 =head1 BUGS
1522
1523 =head2 Broken systems
1524
1525 In certain systems, the operating system's locale support
1526 is broken and cannot be fixed or used by Perl.  Such deficiencies can
1527 and will result in mysterious hangs and/or Perl core dumps when
1528 C<use locale> is in effect.  When confronted with such a system,
1529 please report in excruciating detail to <F<perlbug@perl.org>>, and
1530 also contact your vendor: bug fixes may exist for these problems
1531 in your operating system.  Sometimes such bug fixes are called an
1532 operating system upgrade.  If you have the source for Perl, include in
1533 the perlbug email the output of the test described above in L</Testing
1534 for broken locales>.
1535
1536 =head1 SEE ALSO
1537
1538 L<I18N::Langinfo>, L<perluniintro>, L<perlunicode>, L<open>,
1539 L<POSIX/isalnum>, L<POSIX/isalpha>,
1540 L<POSIX/isdigit>, L<POSIX/isgraph>, L<POSIX/islower>,
1541 L<POSIX/isprint>, L<POSIX/ispunct>, L<POSIX/isspace>,
1542 L<POSIX/isupper>, L<POSIX/isxdigit>, L<POSIX/localeconv>,
1543 L<POSIX/setlocale>, L<POSIX/strcoll>, L<POSIX/strftime>,
1544 L<POSIX/strtod>, L<POSIX/strxfrm>.
1545
1546 For special considerations when Perl is embedded in a C program,
1547 see L<perlembed/Using embedded Perl with POSIX locales>.
1548
1549 =head1 HISTORY
1550
1551 Jarkko Hietaniemi's original F<perli18n.pod> heavily hacked by Dominic
1552 Dunlop, assisted by the perl5-porters.  Prose worked over a bit by
1553 Tom Christiansen, and updated by Perl 5 porters.