This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
8a07efec6974a1d237abc7f820d3cc3b7d1b5758
[perl5.git] / lib / overload.pm
1 package overload;
2
3 our $VERSION = '1.03';
4
5 $overload::hint_bits = 0x20000; # HINT_LOCALIZE_HH
6
7 sub nil {}
8
9 sub OVERLOAD {
10   $package = shift;
11   my %arg = @_;
12   my ($sub, $fb);
13   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
14   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
15   for (keys %arg) {
16     if ($_ eq 'fallback') {
17       $fb = $arg{$_};
18     } else {
19       $sub = $arg{$_};
20       if (not ref $sub and $sub !~ /::/) {
21         $ {$package . "::(" . $_} = $sub;
22         $sub = \&nil;
23       }
24       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
25       *{$package . "::(" . $_} = \&{ $sub };
26     }
27   }
28   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
29 }
30
31 sub import {
32   $package = (caller())[0];
33   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
34   shift;
35   $package->overload::OVERLOAD(@_);
36 }
37
38 sub unimport {
39   $package = (caller())[0];
40   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
41   shift;
42   for (@_) {
43     if ($_ eq 'fallback') {
44       undef $ {$package . "::()"};
45     } else {
46       delete $ {$package . "::"}{"(" . $_};
47     }
48   }
49 }
50
51 sub Overloaded {
52   my $package = shift;
53   $package = ref $package if ref $package;
54   $package->can('()');
55 }
56
57 sub ov_method {
58   my $globref = shift;
59   return undef unless $globref;
60   my $sub = \&{*$globref};
61   return $sub if $sub ne \&nil;
62   return shift->can($ {*$globref});
63 }
64
65 sub OverloadedStringify {
66   my $package = shift;
67   $package = ref $package if ref $package;
68   #$package->can('(""')
69   ov_method mycan($package, '(""'), $package
70     or ov_method mycan($package, '(0+'), $package
71     or ov_method mycan($package, '(bool'), $package
72     or ov_method mycan($package, '(nomethod'), $package;
73 }
74
75 sub Method {
76   my $package = shift;
77   $package = ref $package if ref $package;
78   #my $meth = $package->can('(' . shift);
79   ov_method mycan($package, '(' . shift), $package;
80   #return $meth if $meth ne \&nil;
81   #return $ {*{$meth}};
82 }
83
84 sub AddrRef {
85   my $package = ref $_[0];
86   return "$_[0]" unless $package;
87
88         require Scalar::Util;
89         my $class = Scalar::Util::blessed($_[0]);
90         my $class_prefix = defined($class) ? "$class=" : "";
91         my $type = Scalar::Util::reftype($_[0]);
92         my $addr = Scalar::Util::refaddr($_[0]);
93         return sprintf("$class_prefix$type(0x%x)", $addr);
94 }
95
96 *StrVal = *AddrRef;
97
98 sub mycan {                             # Real can would leave stubs.
99   my ($package, $meth) = @_;
100   return \*{$package . "::$meth"} if defined &{$package . "::$meth"};
101   my $p;
102   foreach $p (@{$package . "::ISA"}) {
103     my $out = mycan($p, $meth);
104     return $out if $out;
105   }
106   return undef;
107 }
108
109 %constants = (
110               'integer'   =>  0x1000, # HINT_NEW_INTEGER
111               'float'     =>  0x2000, # HINT_NEW_FLOAT
112               'binary'    =>  0x4000, # HINT_NEW_BINARY
113               'q'         =>  0x8000, # HINT_NEW_STRING
114               'qr'        => 0x10000, # HINT_NEW_RE
115              );
116
117 %ops = ( with_assign      => "+ - * / % ** << >> x .",
118          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
119          num_comparison   => "< <= >  >= == !=",
120          '3way_comparison'=> "<=> cmp",
121          str_comparison   => "lt le gt ge eq ne",
122          binary           => "& | ^",
123          unary            => "neg ! ~",
124          mutators         => '++ --',
125          func             => "atan2 cos sin exp abs log sqrt int",
126          conversion       => 'bool "" 0+',
127          iterators        => '<>',
128          dereferencing    => '${} @{} %{} &{} *{}',
129          special          => 'nomethod fallback =');
130
131 use warnings::register;
132 sub constant {
133   # Arguments: what, sub
134   while (@_) {
135     if (@_ == 1) {
136         warnings::warnif ("Odd number of arguments for overload::constant");
137         last;
138     }
139     elsif (!exists $constants {$_ [0]}) {
140         warnings::warnif ("`$_[0]' is not an overloadable type");
141     }
142     elsif (!ref $_ [1] || "$_[1]" !~ /CODE\(0x[\da-f]+\)$/) {
143         # Can't use C<ref $_[1] eq "CODE"> above as code references can be
144         # blessed, and C<ref> would return the package the ref is blessed into.
145         if (warnings::enabled) {
146             $_ [1] = "undef" unless defined $_ [1];
147             warnings::warn ("`$_[1]' is not a code reference");
148         }
149     }
150     else {
151         $^H{$_[0]} = $_[1];
152         $^H |= $constants{$_[0]} | $overload::hint_bits;
153     }
154     shift, shift;
155   }
156 }
157
158 sub remove_constant {
159   # Arguments: what, sub
160   while (@_) {
161     delete $^H{$_[0]};
162     $^H &= ~ $constants{$_[0]};
163     shift, shift;
164   }
165 }
166
167 1;
168
169 __END__
170
171 =head1 NAME
172
173 overload - Package for overloading Perl operations
174
175 =head1 SYNOPSIS
176
177     package SomeThing;
178
179     use overload
180         '+' => \&myadd,
181         '-' => \&mysub;
182         # etc
183     ...
184
185     package main;
186     $a = new SomeThing 57;
187     $b=5+$a;
188     ...
189     if (overload::Overloaded $b) {...}
190     ...
191     $strval = overload::StrVal $b;
192
193 =head1 DESCRIPTION
194
195 =head2 Declaration of overloaded functions
196
197 The compilation directive
198
199     package Number;
200     use overload
201         "+" => \&add,
202         "*=" => "muas";
203
204 declares function Number::add() for addition, and method muas() in
205 the "class" C<Number> (or one of its base classes)
206 for the assignment form C<*=> of multiplication.
207
208 Arguments of this directive come in (key, value) pairs.  Legal values
209 are values legal inside a C<&{ ... }> call, so the name of a
210 subroutine, a reference to a subroutine, or an anonymous subroutine
211 will all work.  Note that values specified as strings are
212 interpreted as methods, not subroutines.  Legal keys are listed below.
213
214 The subroutine C<add> will be called to execute C<$a+$b> if $a
215 is a reference to an object blessed into the package C<Number>, or if $a is
216 not an object from a package with defined mathemagic addition, but $b is a
217 reference to a C<Number>.  It can also be called in other situations, like
218 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
219 methods refer to methods triggered by an overloaded mathematical
220 operator.)
221
222 Since overloading respects inheritance via the @ISA hierarchy, the
223 above declaration would also trigger overloading of C<+> and C<*=> in
224 all the packages which inherit from C<Number>.
225
226 =head2 Calling Conventions for Binary Operations
227
228 The functions specified in the C<use overload ...> directive are called
229 with three (in one particular case with four, see L<Last Resort>)
230 arguments.  If the corresponding operation is binary, then the first
231 two arguments are the two arguments of the operation.  However, due to
232 general object calling conventions, the first argument should always be
233 an object in the package, so in the situation of C<7+$a>, the
234 order of the arguments is interchanged.  It probably does not matter
235 when implementing the addition method, but whether the arguments
236 are reversed is vital to the subtraction method.  The method can
237 query this information by examining the third argument, which can take
238 three different values:
239
240 =over 7
241
242 =item FALSE
243
244 the order of arguments is as in the current operation.
245
246 =item TRUE
247
248 the arguments are reversed.
249
250 =item C<undef>
251
252 the current operation is an assignment variant (as in
253 C<$a+=7>), but the usual function is called instead.  This additional
254 information can be used to generate some optimizations.  Compare
255 L<Calling Conventions for Mutators>.
256
257 =back
258
259 =head2 Calling Conventions for Unary Operations
260
261 Unary operation are considered binary operations with the second
262 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
263 is called with arguments C<($a,undef,'')> when $a++ is executed.
264
265 =head2 Calling Conventions for Mutators
266
267 Two types of mutators have different calling conventions:
268
269 =over
270
271 =item C<++> and C<-->
272
273 The routines which implement these operators are expected to actually
274 I<mutate> their arguments.  So, assuming that $obj is a reference to a
275 number,
276
277   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
278
279 is an appropriate implementation of overloaded C<++>.  Note that
280
281   sub incr { ++$ {$_[0]} ; shift }
282
283 is OK if used with preincrement and with postincrement. (In the case
284 of postincrement a copying will be performed, see L<Copy Constructor>.)
285
286 =item C<x=> and other assignment versions
287
288 There is nothing special about these methods.  They may change the
289 value of their arguments, and may leave it as is.  The result is going
290 to be assigned to the value in the left-hand-side if different from
291 this value.
292
293 This allows for the same method to be used as overloaded C<+=> and
294 C<+>.  Note that this is I<allowed>, but not recommended, since by the
295 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
296 if C<+=> is not overloaded.
297
298 =back
299
300 B<Warning.>  Due to the presence of assignment versions of operations,
301 routines which may be called in assignment context may create
302 self-referential structures.  Currently Perl will not free self-referential
303 structures until cycles are C<explicitly> broken.  You may get problems
304 when traversing your structures too.
305
306 Say,
307
308   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
309
310 is asking for trouble, since for code C<$obj += $foo> the subroutine
311 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj,
312 \$foo]>.  If using such a subroutine is an important optimization, one
313 can overload C<+=> explicitly by a non-"optimized" version, or switch
314 to non-optimized version if C<not defined $_[2]> (see
315 L<Calling Conventions for Binary Operations>).
316
317 Even if no I<explicit> assignment-variants of operators are present in
318 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
319 C<',' . $obj . ','> may be both optimized to
320
321   my $tmp = ',' . $obj;    $tmp .= ',';
322
323 =head2 Overloadable Operations
324
325 The following symbols can be specified in C<use overload> directive:
326
327 =over 5
328
329 =item * I<Arithmetic operations>
330
331     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
332     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
333
334 For these operations a substituted non-assignment variant can be called if
335 the assignment variant is not available.  Methods for operations C<+>,
336 C<->, C<+=>, and C<-=> can be called to automatically generate
337 increment and decrement methods.  The operation C<-> can be used to
338 autogenerate missing methods for unary minus or C<abs>.
339
340 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
341 L<"Calling Conventions for Binary Operations">) for details of these
342 substitutions.
343
344 =item * I<Comparison operations>
345
346     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
347     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
348
349 If the corresponding "spaceship" variant is available, it can be
350 used to substitute for the missing operation.  During C<sort>ing
351 arrays, C<cmp> is used to compare values subject to C<use overload>.
352
353 =item * I<Bit operations>
354
355     "&", "^", "|", "neg", "!", "~",
356
357 C<neg> stands for unary minus.  If the method for C<neg> is not
358 specified, it can be autogenerated using the method for
359 subtraction. If the method for C<!> is not specified, it can be
360 autogenerated using the methods for C<bool>, or C<"">, or C<0+>.
361
362 =item * I<Increment and decrement>
363
364     "++", "--",
365
366 If undefined, addition and subtraction methods can be
367 used instead.  These operations are called both in prefix and
368 postfix form.
369
370 =item * I<Transcendental functions>
371
372     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt", "int"
373
374 If C<abs> is unavailable, it can be autogenerated using methods
375 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
376
377 Note that traditionally the Perl function L<int> rounds to 0, thus for
378 floating-point-like types one should follow the same semantic.  If
379 C<int> is unavailable, it can be autogenerated using the overloading of
380 C<0+>.
381
382 =item * I<Boolean, string and numeric conversion>
383
384     'bool', '""', '0+',
385
386 If one or two of these operations are not overloaded, the remaining ones can
387 be used instead.  C<bool> is used in the flow control operators
388 (like C<while>) and for the ternary C<?:> operation.  These functions can
389 return any arbitrary Perl value.  If the corresponding operation for this value
390 is overloaded too, that operation will be called again with this value.
391
392 As a special case if the overload returns the object itself then it will
393 be used directly. An overloaded conversion returning the object is
394 probably a bug, because you're likely to get something that looks like
395 C<YourPackage=HASH(0x8172b34)>.
396
397 =item * I<Iteration>
398
399     "<>"
400
401 If not overloaded, the argument will be converted to a filehandle or
402 glob (which may require a stringification).  The same overloading
403 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
404 I<globbing> syntax C<E<lt>${var}E<gt>>.
405
406 B<BUGS> Even in list context, the iterator is currently called only
407 once and with scalar context.
408
409 =item * I<Dereferencing>
410
411     '${}', '@{}', '%{}', '&{}', '*{}'.
412
413 If not overloaded, the argument will be dereferenced I<as is>, thus
414 should be of correct type.  These functions should return a reference
415 of correct type, or another object with overloaded dereferencing.
416
417 As a special case if the overload returns the object itself then it
418 will be used directly (provided it is the correct type).
419
420 The dereference operators must be specified explicitly they will not be passed to
421 "nomethod".
422
423 =item * I<Special>
424
425     "nomethod", "fallback", "=", "~~",
426
427 see L<SPECIAL SYMBOLS FOR C<use overload>>.
428
429 =back
430
431 See L<"Fallback"> for an explanation of when a missing method can be
432 autogenerated.
433
434 A computer-readable form of the above table is available in the hash
435 %overload::ops, with values being space-separated lists of names:
436
437  with_assign      => '+ - * / % ** << >> x .',
438  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
439  num_comparison   => '< <= > >= == !=',
440  '3way_comparison'=> '<=> cmp',
441  str_comparison   => 'lt le gt ge eq ne',
442  binary           => '& | ^',
443  unary            => 'neg ! ~',
444  mutators         => '++ --',
445  func             => 'atan2 cos sin exp abs log sqrt',
446  conversion       => 'bool "" 0+',
447  iterators        => '<>',
448  dereferencing    => '${} @{} %{} &{} *{}',
449  special          => 'nomethod fallback ='
450
451 =head2 Inheritance and overloading
452
453 Inheritance interacts with overloading in two ways.
454
455 =over
456
457 =item Strings as values of C<use overload> directive
458
459 If C<value> in
460
461   use overload key => value;
462
463 is a string, it is interpreted as a method name.
464
465 =item Overloading of an operation is inherited by derived classes
466
467 Any class derived from an overloaded class is also overloaded.  The
468 set of overloaded methods is the union of overloaded methods of all
469 the ancestors. If some method is overloaded in several ancestor, then
470 which description will be used is decided by the usual inheritance
471 rules:
472
473 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
474 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
475 then the subroutine C<D::plus_sub> will be called to implement
476 operation C<+> for an object in package C<A>.
477
478 =back
479
480 Note that since the value of the C<fallback> key is not a subroutine,
481 its inheritance is not governed by the above rules.  In the current
482 implementation, the value of C<fallback> in the first overloaded
483 ancestor is used, but this is accidental and subject to change.
484
485 =head1 SPECIAL SYMBOLS FOR C<use overload>
486
487 Three keys are recognized by Perl that are not covered by the above
488 description.
489
490 =head2 Last Resort
491
492 C<"nomethod"> should be followed by a reference to a function of four
493 parameters.  If defined, it is called when the overloading mechanism
494 cannot find a method for some operation.  The first three arguments of
495 this function coincide with the arguments for the corresponding method if
496 it were found, the fourth argument is the symbol
497 corresponding to the missing method.  If several methods are tried,
498 the last one is used.  Say, C<1-$a> can be equivalent to
499
500         &nomethodMethod($a,1,1,"-")
501
502 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
503 C<use overload> directive.
504
505 The C<"nomethod"> mechanism is I<not> used for the dereference operators
506 ( ${} @{} %{} &{} *{} ).
507
508
509 If some operation cannot be resolved, and there is no function
510 assigned to C<"nomethod">, then an exception will be raised via die()--
511 unless C<"fallback"> was specified as a key in C<use overload> directive.
512
513
514 =head2 Fallback
515
516 The key C<"fallback"> governs what to do if a method for a particular
517 operation is not found.  Three different cases are possible depending on
518 the value of C<"fallback">:
519
520 =head2 Smart Match
521
522 The key C<"~~"> allows you to override the smart matching used by
523 the switch construct. See L<feature>.
524
525 =over 16
526
527 =item * C<undef>
528
529 Perl tries to use a
530 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
531 then tries to calls C<"nomethod"> value; if missing, an exception
532 will be raised.
533
534 =item * TRUE
535
536 The same as for the C<undef> value, but no exception is raised.  Instead,
537 it silently reverts to what it would have done were there no C<use overload>
538 present.
539
540 =item * defined, but FALSE
541
542 No autogeneration is tried.  Perl tries to call
543 C<"nomethod"> value, and if this is missing, raises an exception.
544
545 =back
546
547 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
548 yet, see L<"Inheritance and overloading">.
549
550 =head2 Copy Constructor
551
552 The value for C<"="> is a reference to a function with three
553 arguments, i.e., it looks like the other values in C<use
554 overload>. However, it does not overload the Perl assignment
555 operator. This would go against Camel hair.
556
557 This operation is called in the situations when a mutator is applied
558 to a reference that shares its object with some other reference, such
559 as
560
561         $a=$b;
562         ++$a;
563
564 To make this change $a and not change $b, a copy of C<$$a> is made,
565 and $a is assigned a reference to this new object.  This operation is
566 done during execution of the C<++$a>, and not during the assignment,
567 (so before the increment C<$$a> coincides with C<$$b>).  This is only
568 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
569 C<nomethod>).  Note that if this operation is expressed via C<'+'>
570 a nonmutator, i.e., as in
571
572         $a=$b;
573         $a=$a+1;
574
575 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
576 appear as lvalue when the above code is executed.
577
578 If the copy constructor is required during the execution of some mutator,
579 but a method for C<'='> was not specified, it can be autogenerated as a
580 string copy if the object is a plain scalar.
581
582 =over 5
583
584 =item B<Example>
585
586 The actually executed code for
587
588         $a=$b;
589         Something else which does not modify $a or $b....
590         ++$a;
591
592 may be
593
594         $a=$b;
595         Something else which does not modify $a or $b....
596         $a = $a->clone(undef,"");
597         $a->incr(undef,"");
598
599 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
600 C<'='> was overloaded with C<\&clone>.
601
602 =back
603
604 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
605 C<$b = $a; ++$a>.
606
607 =head1 MAGIC AUTOGENERATION
608
609 If a method for an operation is not found, and the value for  C<"fallback"> is
610 TRUE or undefined, Perl tries to autogenerate a substitute method for
611 the missing operation based on the defined operations.  Autogenerated method
612 substitutions are possible for the following operations:
613
614 =over 16
615
616 =item I<Assignment forms of arithmetic operations>
617
618 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
619 is not defined.
620
621 =item I<Conversion operations>
622
623 String, numeric, and boolean conversion are calculated in terms of one
624 another if not all of them are defined.
625
626 =item I<Increment and decrement>
627
628 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
629 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
630
631 =item C<abs($a)>
632
633 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
634
635 =item I<Unary minus>
636
637 can be expressed in terms of subtraction.
638
639 =item I<Negation>
640
641 C<!> and C<not> can be expressed in terms of boolean conversion, or
642 string or numerical conversion.
643
644 =item I<Concatenation>
645
646 can be expressed in terms of string conversion.
647
648 =item I<Comparison operations>
649
650 can be expressed in terms of its "spaceship" counterpart: either
651 C<E<lt>=E<gt>> or C<cmp>:
652
653     <, >, <=, >=, ==, !=        in terms of <=>
654     lt, gt, le, ge, eq, ne      in terms of cmp
655
656 =item I<Iterator>
657
658     <>                          in terms of builtin operations
659
660 =item I<Dereferencing>
661
662     ${} @{} %{} &{} *{}         in terms of builtin operations
663
664 =item I<Copy operator>
665
666 can be expressed in terms of an assignment to the dereferenced value, if this
667 value is a scalar and not a reference.
668
669 =back
670
671 =head1 Losing overloading
672
673 The restriction for the comparison operation is that even if, for example,
674 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
675 function will produce only a standard logical value based on the
676 numerical value of the result of `C<cmp>'.  In particular, a working
677 numeric conversion is needed in this case (possibly expressed in terms of
678 other conversions).
679
680 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
681 if the string conversion substitution is applied.
682
683 When you chop() a mathemagical object it is promoted to a string and its
684 mathemagical properties are lost.  The same can happen with other
685 operations as well.
686
687 =head1 Run-time Overloading
688
689 Since all C<use> directives are executed at compile-time, the only way to
690 change overloading during run-time is to
691
692     eval 'use overload "+" => \&addmethod';
693
694 You can also use
695
696     eval 'no overload "+", "--", "<="';
697
698 though the use of these constructs during run-time is questionable.
699
700 =head1 Public functions
701
702 Package C<overload.pm> provides the following public functions:
703
704 =over 5
705
706 =item overload::StrVal(arg)
707
708 Gives string value of C<arg> as in absence of stringify overloading. If you
709 are using this to get the address of a reference (useful for checking if two
710 references point to the same thing) then you may be better off using
711 C<Scalar::Util::refaddr()>, which is faster.
712
713 =item overload::Overloaded(arg)
714
715 Returns true if C<arg> is subject to overloading of some operations.
716
717 =item overload::Method(obj,op)
718
719 Returns C<undef> or a reference to the method that implements C<op>.
720
721 =back
722
723 =head1 Overloading constants
724
725 For some applications, the Perl parser mangles constants too much.
726 It is possible to hook into this process via C<overload::constant()>
727 and C<overload::remove_constant()> functions.
728
729 These functions take a hash as an argument.  The recognized keys of this hash
730 are:
731
732 =over 8
733
734 =item integer
735
736 to overload integer constants,
737
738 =item float
739
740 to overload floating point constants,
741
742 =item binary
743
744 to overload octal and hexadecimal constants,
745
746 =item q
747
748 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
749 strings and here-documents,
750
751 =item qr
752
753 to overload constant pieces of regular expressions.
754
755 =back
756
757 The corresponding values are references to functions which take three arguments:
758 the first one is the I<initial> string form of the constant, the second one
759 is how Perl interprets this constant, the third one is how the constant is used.
760 Note that the initial string form does not
761 contain string delimiters, and has backslashes in backslash-delimiter
762 combinations stripped (thus the value of delimiter is not relevant for
763 processing of this string).  The return value of this function is how this
764 constant is going to be interpreted by Perl.  The third argument is undefined
765 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
766 context (comes from strings, regular expressions, and single-quote HERE
767 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
768 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
769
770 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
771 it is expected that overloaded constant strings are equipped with reasonable
772 overloaded catenation operator, otherwise absurd results will result.
773 Similarly, negative numbers are considered as negations of positive constants.
774
775 Note that it is probably meaningless to call the functions overload::constant()
776 and overload::remove_constant() from anywhere but import() and unimport() methods.
777 From these methods they may be called as
778
779         sub import {
780           shift;
781           return unless @_;
782           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
783           overload::constant integer => sub {Math::BigInt->new(shift)};
784         }
785
786 B<BUGS> Currently overloaded-ness of constants does not propagate
787 into C<eval '...'>.
788
789 =head1 IMPLEMENTATION
790
791 What follows is subject to change RSN.
792
793 The table of methods for all operations is cached in magic for the
794 symbol table hash for the package.  The cache is invalidated during
795 processing of C<use overload>, C<no overload>, new function
796 definitions, and changes in @ISA. However, this invalidation remains
797 unprocessed until the next C<bless>ing into the package. Hence if you
798 want to change overloading structure dynamically, you'll need an
799 additional (fake) C<bless>ing to update the table.
800
801 (Every SVish thing has a magic queue, and magic is an entry in that
802 queue.  This is how a single variable may participate in multiple
803 forms of magic simultaneously.  For instance, environment variables
804 regularly have two forms at once: their %ENV magic and their taint
805 magic. However, the magic which implements overloading is applied to
806 the stashes, which are rarely used directly, thus should not slow down
807 Perl.)
808
809 If an object belongs to a package using overload, it carries a special
810 flag.  Thus the only speed penalty during arithmetic operations without
811 overloading is the checking of this flag.
812
813 In fact, if C<use overload> is not present, there is almost no overhead
814 for overloadable operations, so most programs should not suffer
815 measurable performance penalties.  A considerable effort was made to
816 minimize the overhead when overload is used in some package, but the
817 arguments in question do not belong to packages using overload.  When
818 in doubt, test your speed with C<use overload> and without it.  So far
819 there have been no reports of substantial speed degradation if Perl is
820 compiled with optimization turned on.
821
822 There is no size penalty for data if overload is not used. The only
823 size penalty if overload is used in some package is that I<all> the
824 packages acquire a magic during the next C<bless>ing into the
825 package. This magic is three-words-long for packages without
826 overloading, and carries the cache table if the package is overloaded.
827
828 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is
829 carried out before any operation that can imply an assignment to the
830 object $a (or $b) refers to, like C<$a++>.  You can override this
831 behavior by defining your own copy constructor (see L<"Copy Constructor">).
832
833 It is expected that arguments to methods that are not explicitly supposed
834 to be changed are constant (but this is not enforced).
835
836 =head1 Metaphor clash
837
838 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
839 If it I<looks> counter intuitive to you, you are subject to a metaphor
840 clash.
841
842 Here is a Perl object metaphor:
843
844 I<  object is a reference to blessed data>
845
846 and an arithmetic metaphor:
847
848 I<  object is a thing by itself>.
849
850 The I<main> problem of overloading C<=> is the fact that these metaphors
851 imply different actions on the assignment C<$a = $b> if $a and $b are
852 objects.  Perl-think implies that $a becomes a reference to whatever
853 $b was referencing.  Arithmetic-think implies that the value of "object"
854 $a is changed to become the value of the object $b, preserving the fact
855 that $a and $b are separate entities.
856
857 The difference is not relevant in the absence of mutators.  After
858 a Perl-way assignment an operation which mutates the data referenced by $a
859 would change the data referenced by $b too.  Effectively, after
860 C<$a = $b> values of $a and $b become I<indistinguishable>.
861
862 On the other hand, anyone who has used algebraic notation knows the
863 expressive power of the arithmetic metaphor.  Overloading works hard
864 to enable this metaphor while preserving the Perlian way as far as
865 possible.  Since it is not possible to freely mix two contradicting
866 metaphors, overloading allows the arithmetic way to write things I<as
867 far as all the mutators are called via overloaded access only>.  The
868 way it is done is described in L<Copy Constructor>.
869
870 If some mutator methods are directly applied to the overloaded values,
871 one may need to I<explicitly unlink> other values which references the
872 same value:
873
874     $a = new Data 23;
875     ...
876     $b = $a;            # $b is "linked" to $a
877     ...
878     $a = $a->clone;     # Unlink $b from $a
879     $a->increment_by(4);
880
881 Note that overloaded access makes this transparent:
882
883     $a = new Data 23;
884     $b = $a;            # $b is "linked" to $a
885     $a += 4;            # would unlink $b automagically
886
887 However, it would not make
888
889     $a = new Data 23;
890     $a = 4;             # Now $a is a plain 4, not 'Data'
891
892 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
893 to an object do whatever you want.  It is just not the overload, but
894 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
895 which returns the object itself, and STORE() method which changes the
896 value of the object, one can reproduce the arithmetic metaphor in its
897 completeness, at least for variables which were tie()d from the start.
898
899 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
900
901 =head1 Cookbook
902
903 Please add examples to what follows!
904
905 =head2 Two-face scalars
906
907 Put this in F<two_face.pm> in your Perl library directory:
908
909   package two_face;             # Scalars with separate string and
910                                 # numeric values.
911   sub new { my $p = shift; bless [@_], $p }
912   use overload '""' => \&str, '0+' => \&num, fallback => 1;
913   sub num {shift->[1]}
914   sub str {shift->[0]}
915
916 Use it as follows:
917
918   require two_face;
919   my $seven = new two_face ("vii", 7);
920   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
921   print "seven contains `i'\n" if $seven =~ /i/;
922
923 (The second line creates a scalar which has both a string value, and a
924 numeric value.)  This prints:
925
926   seven=vii, seven=7, eight=8
927   seven contains `i'
928
929 =head2 Two-face references
930
931 Suppose you want to create an object which is accessible as both an
932 array reference and a hash reference.
933
934   package two_refs;
935   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
936   sub new {
937     my $p = shift;
938     bless \ [@_], $p;
939   }
940   sub gethash {
941     my %h;
942     my $self = shift;
943     tie %h, ref $self, $self;
944     \%h;
945   }
946
947   sub TIEHASH { my $p = shift; bless \ shift, $p }
948   my %fields;
949   my $i = 0;
950   $fields{$_} = $i++ foreach qw{zero one two three};
951   sub STORE {
952     my $self = ${shift()};
953     my $key = $fields{shift()};
954     defined $key or die "Out of band access";
955     $$self->[$key] = shift;
956   }
957   sub FETCH {
958     my $self = ${shift()};
959     my $key = $fields{shift()};
960     defined $key or die "Out of band access";
961     $$self->[$key];
962   }
963
964 Now one can access an object using both the array and hash syntax:
965
966   my $bar = new two_refs 3,4,5,6;
967   $bar->[2] = 11;
968   $bar->{two} == 11 or die 'bad hash fetch';
969
970 Note several important features of this example.  First of all, the
971 I<actual> type of $bar is a scalar reference, and we do not overload
972 the scalar dereference.  Thus we can get the I<actual> non-overloaded
973 contents of $bar by just using C<$$bar> (what we do in functions which
974 overload dereference).  Similarly, the object returned by the
975 TIEHASH() method is a scalar reference.
976
977 Second, we create a new tied hash each time the hash syntax is used.
978 This allows us not to worry about a possibility of a reference loop,
979 which would lead to a memory leak.
980
981 Both these problems can be cured.  Say, if we want to overload hash
982 dereference on a reference to an object which is I<implemented> as a
983 hash itself, the only problem one has to circumvent is how to access
984 this I<actual> hash (as opposed to the I<virtual> hash exhibited by the
985 overloaded dereference operator).  Here is one possible fetching routine:
986
987   sub access_hash {
988     my ($self, $key) = (shift, shift);
989     my $class = ref $self;
990     bless $self, 'overload::dummy'; # Disable overloading of %{}
991     my $out = $self->{$key};
992     bless $self, $class;        # Restore overloading
993     $out;
994   }
995
996 To remove creation of the tied hash on each access, one may an extra
997 level of indirection which allows a non-circular structure of references:
998
999   package two_refs1;
1000   use overload '%{}' => sub { ${shift()}->[1] },
1001                '@{}' => sub { ${shift()}->[0] };
1002   sub new {
1003     my $p = shift;
1004     my $a = [@_];
1005     my %h;
1006     tie %h, $p, $a;
1007     bless \ [$a, \%h], $p;
1008   }
1009   sub gethash {
1010     my %h;
1011     my $self = shift;
1012     tie %h, ref $self, $self;
1013     \%h;
1014   }
1015
1016   sub TIEHASH { my $p = shift; bless \ shift, $p }
1017   my %fields;
1018   my $i = 0;
1019   $fields{$_} = $i++ foreach qw{zero one two three};
1020   sub STORE {
1021     my $a = ${shift()};
1022     my $key = $fields{shift()};
1023     defined $key or die "Out of band access";
1024     $a->[$key] = shift;
1025   }
1026   sub FETCH {
1027     my $a = ${shift()};
1028     my $key = $fields{shift()};
1029     defined $key or die "Out of band access";
1030     $a->[$key];
1031   }
1032
1033 Now if $baz is overloaded like this, then C<$baz> is a reference to a
1034 reference to the intermediate array, which keeps a reference to an
1035 actual array, and the access hash.  The tie()ing object for the access
1036 hash is a reference to a reference to the actual array, so
1037
1038 =over
1039
1040 =item *
1041
1042 There are no loops of references.
1043
1044 =item *
1045
1046 Both "objects" which are blessed into the class C<two_refs1> are
1047 references to a reference to an array, thus references to a I<scalar>.
1048 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1049 overloaded operations.
1050
1051 =back
1052
1053 =head2 Symbolic calculator
1054
1055 Put this in F<symbolic.pm> in your Perl library directory:
1056
1057   package symbolic;             # Primitive symbolic calculator
1058   use overload nomethod => \&wrap;
1059
1060   sub new { shift; bless ['n', @_] }
1061   sub wrap {
1062     my ($obj, $other, $inv, $meth) = @_;
1063     ($obj, $other) = ($other, $obj) if $inv;
1064     bless [$meth, $obj, $other];
1065   }
1066
1067 This module is very unusual as overloaded modules go: it does not
1068 provide any usual overloaded operators, instead it provides the L<Last
1069 Resort> operator C<nomethod>.  In this example the corresponding
1070 subroutine returns an object which encapsulates operations done over
1071 the objects: C<new symbolic 3> contains C<['n', 3]>, C<2 + new
1072 symbolic 3> contains C<['+', 2, ['n', 3]]>.
1073
1074 Here is an example of the script which "calculates" the side of
1075 circumscribed octagon using the above package:
1076
1077   require symbolic;
1078   my $iter = 1;                 # 2**($iter+2) = 8
1079   my $side = new symbolic 1;
1080   my $cnt = $iter;
1081
1082   while ($cnt--) {
1083     $side = (sqrt(1 + $side**2) - 1)/$side;
1084   }
1085   print "OK\n";
1086
1087 The value of $side is
1088
1089   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1090                        undef], 1], ['n', 1]]
1091
1092 Note that while we obtained this value using a nice little script,
1093 there is no simple way to I<use> this value.  In fact this value may
1094 be inspected in debugger (see L<perldebug>), but ony if
1095 C<bareStringify> B<O>ption is set, and not via C<p> command.
1096
1097 If one attempts to print this value, then the overloaded operator
1098 C<""> will be called, which will call C<nomethod> operator.  The
1099 result of this operator will be stringified again, but this result is
1100 again of type C<symbolic>, which will lead to an infinite loop.
1101
1102 Add a pretty-printer method to the module F<symbolic.pm>:
1103
1104   sub pretty {
1105     my ($meth, $a, $b) = @{+shift};
1106     $a = 'u' unless defined $a;
1107     $b = 'u' unless defined $b;
1108     $a = $a->pretty if ref $a;
1109     $b = $b->pretty if ref $b;
1110     "[$meth $a $b]";
1111   }
1112
1113 Now one can finish the script by
1114
1115   print "side = ", $side->pretty, "\n";
1116
1117 The method C<pretty> is doing object-to-string conversion, so it
1118 is natural to overload the operator C<""> using this method.  However,
1119 inside such a method it is not necessary to pretty-print the
1120 I<components> $a and $b of an object.  In the above subroutine
1121 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1122 and $b.  If these components use overloading, the catenation operator
1123 will look for an overloaded operator C<.>; if not present, it will
1124 look for an overloaded operator C<"">.  Thus it is enough to use
1125
1126   use overload nomethod => \&wrap, '""' => \&str;
1127   sub str {
1128     my ($meth, $a, $b) = @{+shift};
1129     $a = 'u' unless defined $a;
1130     $b = 'u' unless defined $b;
1131     "[$meth $a $b]";
1132   }
1133
1134 Now one can change the last line of the script to
1135
1136   print "side = $side\n";
1137
1138 which outputs
1139
1140   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1141
1142 and one can inspect the value in debugger using all the possible
1143 methods.
1144
1145 Something is still amiss: consider the loop variable $cnt of the
1146 script.  It was a number, not an object.  We cannot make this value of
1147 type C<symbolic>, since then the loop will not terminate.
1148
1149 Indeed, to terminate the cycle, the $cnt should become false.
1150 However, the operator C<bool> for checking falsity is overloaded (this
1151 time via overloaded C<"">), and returns a long string, thus any object
1152 of type C<symbolic> is true.  To overcome this, we need a way to
1153 compare an object to 0.  In fact, it is easier to write a numeric
1154 conversion routine.
1155
1156 Here is the text of F<symbolic.pm> with such a routine added (and
1157 slightly modified str()):
1158
1159   package symbolic;             # Primitive symbolic calculator
1160   use overload
1161     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1162
1163   sub new { shift; bless ['n', @_] }
1164   sub wrap {
1165     my ($obj, $other, $inv, $meth) = @_;
1166     ($obj, $other) = ($other, $obj) if $inv;
1167     bless [$meth, $obj, $other];
1168   }
1169   sub str {
1170     my ($meth, $a, $b) = @{+shift};
1171     $a = 'u' unless defined $a;
1172     if (defined $b) {
1173       "[$meth $a $b]";
1174     } else {
1175       "[$meth $a]";
1176     }
1177   }
1178   my %subr = ( n => sub {$_[0]},
1179                sqrt => sub {sqrt $_[0]},
1180                '-' => sub {shift() - shift()},
1181                '+' => sub {shift() + shift()},
1182                '/' => sub {shift() / shift()},
1183                '*' => sub {shift() * shift()},
1184                '**' => sub {shift() ** shift()},
1185              );
1186   sub num {
1187     my ($meth, $a, $b) = @{+shift};
1188     my $subr = $subr{$meth}
1189       or die "Do not know how to ($meth) in symbolic";
1190     $a = $a->num if ref $a eq __PACKAGE__;
1191     $b = $b->num if ref $b eq __PACKAGE__;
1192     $subr->($a,$b);
1193   }
1194
1195 All the work of numeric conversion is done in %subr and num().  Of
1196 course, %subr is not complete, it contains only operators used in the
1197 example below.  Here is the extra-credit question: why do we need an
1198 explicit recursion in num()?  (Answer is at the end of this section.)
1199
1200 Use this module like this:
1201
1202   require symbolic;
1203   my $iter = new symbolic 2;    # 16-gon
1204   my $side = new symbolic 1;
1205   my $cnt = $iter;
1206
1207   while ($cnt) {
1208     $cnt = $cnt - 1;            # Mutator `--' not implemented
1209     $side = (sqrt(1 + $side**2) - 1)/$side;
1210   }
1211   printf "%s=%f\n", $side, $side;
1212   printf "pi=%f\n", $side*(2**($iter+2));
1213
1214 It prints (without so many line breaks)
1215
1216   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1217                           [n 1]] 2]]] 1]
1218      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1219   pi=3.182598
1220
1221 The above module is very primitive.  It does not implement
1222 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1223 (not required without mutators!), and implements only those arithmetic
1224 operations which are used in the example.
1225
1226 To implement most arithmetic operations is easy; one should just use
1227 the tables of operations, and change the code which fills %subr to
1228
1229   my %subr = ( 'n' => sub {$_[0]} );
1230   foreach my $op (split " ", $overload::ops{with_assign}) {
1231     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1232   }
1233   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1234   foreach my $op (split " ", "@overload::ops{ @bins }") {
1235     $subr{$op} = eval "sub {shift() $op shift()}";
1236   }
1237   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1238     print "defining `$op'\n";
1239     $subr{$op} = eval "sub {$op shift()}";
1240   }
1241
1242 Due to L<Calling Conventions for Mutators>, we do not need anything
1243 special to make C<+=> and friends work, except filling C<+=> entry of
1244 %subr, and defining a copy constructor (needed since Perl has no
1245 way to know that the implementation of C<'+='> does not mutate
1246 the argument, compare L<Copy Constructor>).
1247
1248 To implement a copy constructor, add C<< '=' => \&cpy >> to C<use overload>
1249 line, and code (this code assumes that mutators change things one level
1250 deep only, so recursive copying is not needed):
1251
1252   sub cpy {
1253     my $self = shift;
1254     bless [@$self], ref $self;
1255   }
1256
1257 To make C<++> and C<--> work, we need to implement actual mutators,
1258 either directly, or in C<nomethod>.  We continue to do things inside
1259 C<nomethod>, thus add
1260
1261     if ($meth eq '++' or $meth eq '--') {
1262       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1263       return $obj;
1264     }
1265
1266 after the first line of wrap().  This is not a most effective
1267 implementation, one may consider
1268
1269   sub inc { $_[0] = bless ['++', shift, 1]; }
1270
1271 instead.
1272
1273 As a final remark, note that one can fill %subr by
1274
1275   my %subr = ( 'n' => sub {$_[0]} );
1276   foreach my $op (split " ", $overload::ops{with_assign}) {
1277     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1278   }
1279   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1280   foreach my $op (split " ", "@overload::ops{ @bins }") {
1281     $subr{$op} = eval "sub {shift() $op shift()}";
1282   }
1283   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1284     $subr{$op} = eval "sub {$op shift()}";
1285   }
1286   $subr{'++'} = $subr{'+'};
1287   $subr{'--'} = $subr{'-'};
1288
1289 This finishes implementation of a primitive symbolic calculator in
1290 50 lines of Perl code.  Since the numeric values of subexpressions
1291 are not cached, the calculator is very slow.
1292
1293 Here is the answer for the exercise: In the case of str(), we need no
1294 explicit recursion since the overloaded C<.>-operator will fall back
1295 to an existing overloaded operator C<"">.  Overloaded arithmetic
1296 operators I<do not> fall back to numeric conversion if C<fallback> is
1297 not explicitly requested.  Thus without an explicit recursion num()
1298 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1299 the argument of num().
1300
1301 If you wonder why defaults for conversion are different for str() and
1302 num(), note how easy it was to write the symbolic calculator.  This
1303 simplicity is due to an appropriate choice of defaults.  One extra
1304 note: due to the explicit recursion num() is more fragile than sym():
1305 we need to explicitly check for the type of $a and $b.  If components
1306 $a and $b happen to be of some related type, this may lead to problems.
1307
1308 =head2 I<Really> symbolic calculator
1309
1310 One may wonder why we call the above calculator symbolic.  The reason
1311 is that the actual calculation of the value of expression is postponed
1312 until the value is I<used>.
1313
1314 To see it in action, add a method
1315
1316   sub STORE {
1317     my $obj = shift;
1318     $#$obj = 1;
1319     @$obj->[0,1] = ('=', shift);
1320   }
1321
1322 to the package C<symbolic>.  After this change one can do
1323
1324   my $a = new symbolic 3;
1325   my $b = new symbolic 4;
1326   my $c = sqrt($a**2 + $b**2);
1327
1328 and the numeric value of $c becomes 5.  However, after calling
1329
1330   $a->STORE(12);  $b->STORE(5);
1331
1332 the numeric value of $c becomes 13.  There is no doubt now that the module
1333 symbolic provides a I<symbolic> calculator indeed.
1334
1335 To hide the rough edges under the hood, provide a tie()d interface to the
1336 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1337
1338   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1339   sub FETCH { shift }
1340   sub nop {  }          # Around a bug
1341
1342 (the bug is described in L<"BUGS">).  One can use this new interface as
1343
1344   tie $a, 'symbolic', 3;
1345   tie $b, 'symbolic', 4;
1346   $a->nop;  $b->nop;    # Around a bug
1347
1348   my $c = sqrt($a**2 + $b**2);
1349
1350 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1351 of $c becomes 13.  To insulate the user of the module add a method
1352
1353   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1354
1355 Now
1356
1357   my ($a, $b);
1358   symbolic->vars($a, $b);
1359   my $c = sqrt($a**2 + $b**2);
1360
1361   $a = 3; $b = 4;
1362   printf "c5  %s=%f\n", $c, $c;
1363
1364   $a = 12; $b = 5;
1365   printf "c13  %s=%f\n", $c, $c;
1366
1367 shows that the numeric value of $c follows changes to the values of $a
1368 and $b.
1369
1370 =head1 AUTHOR
1371
1372 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1373
1374 =head1 DIAGNOSTICS
1375
1376 When Perl is run with the B<-Do> switch or its equivalent, overloading
1377 induces diagnostic messages.
1378
1379 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1380 deduce which operations are overloaded (and which ancestor triggers
1381 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1382 is shown by debugger. The method C<()> corresponds to the C<fallback>
1383 key (in fact a presence of this method shows that this package has
1384 overloading enabled, and it is what is used by the C<Overloaded>
1385 function of module C<overload>).
1386
1387 The module might issue the following warnings:
1388
1389 =over 4
1390
1391 =item Odd number of arguments for overload::constant
1392
1393 (W) The call to overload::constant contained an odd number of arguments.
1394 The arguments should come in pairs.
1395
1396 =item `%s' is not an overloadable type
1397
1398 (W) You tried to overload a constant type the overload package is unaware of.
1399
1400 =item `%s' is not a code reference
1401
1402 (W) The second (fourth, sixth, ...) argument of overload::constant needs
1403 to be a code reference. Either an anonymous subroutine, or a reference
1404 to a subroutine.
1405
1406 =back
1407
1408 =head1 BUGS
1409
1410 Because it is used for overloading, the per-package hash %OVERLOAD now
1411 has a special meaning in Perl. The symbol table is filled with names
1412 looking like line-noise.
1413
1414 For the purpose of inheritance every overloaded package behaves as if
1415 C<fallback> is present (possibly undefined). This may create
1416 interesting effects if some package is not overloaded, but inherits
1417 from two overloaded packages.
1418
1419 Relation between overloading and tie()ing is broken.  Overloading is
1420 triggered or not basing on the I<previous> class of tie()d value.
1421
1422 This happens because the presence of overloading is checked too early,
1423 before any tie()d access is attempted.  If the FETCH()ed class of the
1424 tie()d value does not change, a simple workaround is to access the value
1425 immediately after tie()ing, so that after this call the I<previous> class
1426 coincides with the current one.
1427
1428 B<Needed:> a way to fix this without a speed penalty.
1429
1430 Barewords are not covered by overloaded string constants.
1431
1432 This document is confusing.  There are grammos and misleading language
1433 used in places.  It would seem a total rewrite is needed.
1434
1435 =cut
1436