This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Converge ext/[GNOS]DBM_File/t/[gnos]dbm.t by using the same filename.
[perl5.git] / ext / ODBM_File / t / odbm.t
1 #!./perl
2
3 # $RCSfile: dbm.t,v $$Revision: 4.1 $$Date: 92/08/07 18:27:43 $
4
5 BEGIN {
6     require Config; import Config;
7     if ($Config{'extensions'} !~ /\bODBM_File\b/ or $Config{'d_cplusplus'}) {
8         print "1..0 # Skip: ODBM_File was not built\n";
9         exit 0;
10     }
11 }
12
13 use strict;
14 use warnings;
15
16 use Test::More tests => 79;
17
18 require ODBM_File;
19 #If Fcntl is not available, try 0x202 or 0x102 for O_RDWR|O_CREAT
20 use Fcntl;
21
22 unlink <Op_dbmx.*>;
23
24 umask(0);
25 my %h;
26 isa_ok(tie(%h, 'ODBM_File', 'Op_dbmx', O_RDWR|O_CREAT, 0640), 'ODBM_File');
27
28 my $Dfile = "Op_dbmx.pag";
29 if (! -e $Dfile) {
30         ($Dfile) = <Op_dbmx*>;
31 }
32 SKIP: {
33     skip "different file permission semantics on $^O", 1
34         if $^O eq 'amigaos' || $^O eq 'os2' || $^O eq 'MSWin32' || $^O eq 'NetWare';
35     my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,$atime,$mtime,$ctime,
36      $blksize,$blocks) = stat($Dfile);
37     is($mode & 0777, 0640);
38 }
39 my $i = 0;
40 while (my ($key,$value) = each(%h)) {
41     $i++;
42 }
43 is($i, 0);
44
45 $h{'goner1'} = 'snork';
46
47 $h{'abc'} = 'ABC';
48 $h{'def'} = 'DEF';
49 $h{'jkl','mno'} = "JKL\034MNO";
50 $h{'a',2,3,4,5} = join("\034",'A',2,3,4,5);
51 $h{'a'} = 'A';
52 $h{'b'} = 'B';
53 $h{'c'} = 'C';
54 $h{'d'} = 'D';
55 $h{'e'} = 'E';
56 $h{'f'} = 'F';
57 $h{'g'} = 'G';
58 $h{'h'} = 'H';
59 $h{'i'} = 'I';
60
61 $h{'goner2'} = 'snork';
62 delete $h{'goner2'};
63
64 untie(%h);
65 isa_ok(tie(%h, 'ODBM_File', 'Op_dbmx', O_RDWR, 0640), 'ODBM_File');
66
67 $h{'j'} = 'J';
68 $h{'k'} = 'K';
69 $h{'l'} = 'L';
70 $h{'m'} = 'M';
71 $h{'n'} = 'N';
72 $h{'o'} = 'O';
73 $h{'p'} = 'P';
74 $h{'q'} = 'Q';
75 $h{'r'} = 'R';
76 $h{'s'} = 'S';
77 $h{'t'} = 'T';
78 $h{'u'} = 'U';
79 $h{'v'} = 'V';
80 $h{'w'} = 'W';
81 $h{'x'} = 'X';
82 $h{'y'} = 'Y';
83 $h{'z'} = 'Z';
84
85 $h{'goner3'} = 'snork';
86
87 delete $h{'goner1'};
88 delete $h{'goner3'};
89
90 my @keys = keys(%h);
91 my @values = values(%h);
92
93 is($#keys, 29);
94 is($#values, 29);
95
96 while (my ($key,$value) = each(%h)) {
97     if ($key eq $keys[$i] && $value eq $values[$i] && $key eq lc($value)) {
98         $key =~ y/a-z/A-Z/;
99         $i++ if $key eq $value;
100     }
101 }
102
103 is($i, 30);
104
105 @keys = ('blurfl', keys(%h), 'dyick');
106 is($#keys, 31);
107
108 $h{'foo'} = '';
109 $h{''} = 'bar';
110
111 my $ok = 1;
112 for ($i = 1; $i < 200; $i++) { $h{$i + 0} = $i + 0; }
113 for ($i = 1; $i < 200; $i++) { $ok = 0 unless $h{$i} == $i; }
114 is($ok, 1, 'check cache overflow and numeric keys and contents');
115
116 my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,$atime,$mtime,$ctime,
117    $blksize,$blocks) = stat($Dfile);
118 cmp_ok($size, '>', 0);
119
120 @h{0..200} = 200..400;
121 my @foo = @h{0..200};
122 is(join(':',200..400), join(':',@foo));
123
124 is($h{'foo'}, '');
125 is($h{''}, 'bar');
126
127 untie %h;
128 unlink <Op_dbmx*>, $Dfile;
129
130 {
131    # sub-class test
132
133    package Another ;
134
135    open(FILE, ">SubDB.pm") or die "Cannot open SubDB.pm: $!\n" ;
136    print FILE <<'EOM' ;
137
138    package SubDB ;
139
140    use strict ;
141    use warnings ;
142    use vars qw(@ISA @EXPORT) ;
143
144    require Exporter ;
145    use ODBM_File;
146    @ISA=qw(ODBM_File);
147    @EXPORT = @ODBM_File::EXPORT ;
148
149    sub STORE { 
150         my $self = shift ;
151         my $key = shift ;
152         my $value = shift ;
153         $self->SUPER::STORE($key, $value * 2) ;
154    }
155
156    sub FETCH { 
157         my $self = shift ;
158         my $key = shift ;
159         $self->SUPER::FETCH($key) - 1 ;
160    }
161
162    sub A_new_method
163    {
164         my $self = shift ;
165         my $key = shift ;
166         my $value = $self->FETCH($key) ;
167         return "[[$value]]" ;
168    }
169
170    1 ;
171 EOM
172
173     close FILE ;
174
175     BEGIN { push @INC, '.'; }
176     unlink <dbhash_tmp*> ;
177
178     eval 'use SubDB ; use Fcntl ;';
179     main::is($@, "");
180     my %h ;
181     my $X ;
182     eval '
183         $X = tie(%h, "SubDB","dbhash_tmp", O_RDWR|O_CREAT, 0640 );
184         ' ;
185
186     main::is($@, "");
187
188     my $ret = eval '$h{"fred"} = 3 ; return $h{"fred"} ' ;
189     main::is($@, "");
190     main::is($ret, 5);
191
192     $ret = eval '$X->A_new_method("fred") ' ;
193     main::is($@, "");
194     main::is($ret, "[[5]]");
195
196     undef $X;
197     untie(%h);
198     unlink "SubDB.pm", <dbhash_tmp.*> ;
199
200 }
201
202 untie %h;
203 unlink <Op_dbmx*>, $Dfile;
204
205 {
206    # DBM Filter tests
207    my (%h, $db) ;
208    my ($fetch_key, $store_key, $fetch_value, $store_value) = ("") x 4 ;
209
210    sub checkOutput
211    {
212        my($fk, $sk, $fv, $sv) = @_ ;
213        print "# ", join('|', $fetch_key, $fk, $store_key, $sk,
214                         $fetch_value, $fv, $store_value, $sv, $_), "\n";
215        return
216            $fetch_key eq $fk && $store_key eq $sk && 
217            $fetch_value eq $fv && $store_value eq $sv &&
218            $_ eq 'original' ;
219    }
220    
221    unlink <Op_dbmx*>;
222    $db = tie %h, 'ODBM_File', 'Op_dbmx', O_RDWR|O_CREAT, 0640;
223    isa_ok($db, 'ODBM_File');
224
225    $db->filter_fetch_key   (sub { $fetch_key = $_ }) ;
226    $db->filter_store_key   (sub { $store_key = $_ }) ;
227    $db->filter_fetch_value (sub { $fetch_value = $_}) ;
228    $db->filter_store_value (sub { $store_value = $_ }) ;
229
230    $_ = "original" ;
231
232    $h{"fred"} = "joe" ;
233    #                   fk   sk     fv   sv
234    ok(checkOutput("", "fred", "", "joe"));
235
236    ($fetch_key, $store_key, $fetch_value, $store_value) = ("") x 4 ;
237    is($h{"fred"}, "joe");
238    #                   fk    sk     fv    sv
239    ok(checkOutput("", "fred", "joe", ""));
240
241    ($fetch_key, $store_key, $fetch_value, $store_value) = ("") x 4 ;
242    is($db->FIRSTKEY(), "fred");
243    #                    fk     sk  fv  sv
244    ok(checkOutput("fred", "", "", ""));
245
246    # replace the filters, but remember the previous set
247    my ($old_fk) = $db->filter_fetch_key   
248                         (sub { $_ = uc $_ ; $fetch_key = $_ }) ;
249    my ($old_sk) = $db->filter_store_key   
250                         (sub { $_ = lc $_ ; $store_key = $_ }) ;
251    my ($old_fv) = $db->filter_fetch_value 
252                         (sub { $_ = "[$_]"; $fetch_value = $_ }) ;
253    my ($old_sv) = $db->filter_store_value 
254                         (sub { s/o/x/g; $store_value = $_ }) ;
255    
256    ($fetch_key, $store_key, $fetch_value, $store_value) = ("") x 4 ;
257    $h{"Fred"} = "Joe" ;
258    #                   fk   sk     fv    sv
259    ok(checkOutput("", "fred", "", "Jxe"));
260
261    ($fetch_key, $store_key, $fetch_value, $store_value) = ("") x 4 ;
262    is($h{"Fred"}, "[Jxe]");
263    #                   fk   sk     fv    sv
264    ok(checkOutput("", "fred", "[Jxe]", ""));
265
266    ($fetch_key, $store_key, $fetch_value, $store_value) = ("") x 4 ;
267    is($db->FIRSTKEY(), "FRED");
268    #                   fk   sk     fv    sv
269    ok(checkOutput("FRED", "", "", ""));
270
271    # put the original filters back
272    $db->filter_fetch_key   ($old_fk);
273    $db->filter_store_key   ($old_sk);
274    $db->filter_fetch_value ($old_fv);
275    $db->filter_store_value ($old_sv);
276
277    ($fetch_key, $store_key, $fetch_value, $store_value) = ("") x 4 ;
278    $h{"fred"} = "joe" ;
279    ok(checkOutput("", "fred", "", "joe"));
280
281    ($fetch_key, $store_key, $fetch_value, $store_value) = ("") x 4 ;
282    is($h{"fred"}, "joe");
283    ok(checkOutput("", "fred", "joe", ""));
284
285    ($fetch_key, $store_key, $fetch_value, $store_value) = ("") x 4 ;
286    is($db->FIRSTKEY(), "fred");
287    ok(checkOutput("fred", "", "", ""));
288
289    # delete the filters
290    $db->filter_fetch_key   (undef);
291    $db->filter_store_key   (undef);
292    $db->filter_fetch_value (undef);
293    $db->filter_store_value (undef);
294
295    ($fetch_key, $store_key, $fetch_value, $store_value) = ("") x 4 ;
296    $h{"fred"} = "joe" ;
297    ok(checkOutput("", "", "", ""));
298
299    ($fetch_key, $store_key, $fetch_value, $store_value) = ("") x 4 ;
300    is($h{"fred"}, "joe");
301    ok(checkOutput("", "", "", ""));
302
303    ($fetch_key, $store_key, $fetch_value, $store_value) = ("") x 4 ;
304    is($db->FIRSTKEY(), "fred");
305    ok(checkOutput("", "", "", ""));
306
307    undef $db ;
308    untie %h;
309    unlink <Op_dbmx*>;
310 }
311
312 {    
313     # DBM Filter with a closure
314
315     my (%h, $db) ;
316
317     unlink <Op_dbmx*>;
318     $db = tie %h, 'ODBM_File', 'Op_dbmx', O_RDWR|O_CREAT, 0640;
319     isa_ok($db, 'ODBM_File');
320
321     my %result = () ;
322
323     sub Closure
324     {
325         my ($name) = @_ ;
326         my $count = 0 ;
327         my @kept = () ;
328
329         return sub { ++$count ; 
330                      push @kept, $_ ; 
331                      $result{$name} = "$name - $count: [@kept]" ;
332                    }
333     }
334
335     $db->filter_store_key(Closure("store key")) ;
336     $db->filter_store_value(Closure("store value")) ;
337     $db->filter_fetch_key(Closure("fetch key")) ;
338     $db->filter_fetch_value(Closure("fetch value")) ;
339
340     $_ = "original" ;
341
342     $h{"fred"} = "joe" ;
343     is($result{"store key"}, "store key - 1: [fred]");
344     is($result{"store value"}, "store value - 1: [joe]");
345     is($result{"fetch key"}, undef);
346     is($result{"fetch value"}, undef);
347     is($_, "original");
348
349     is($db->FIRSTKEY(), "fred");
350     is($result{"store key"}, "store key - 1: [fred]");
351     is($result{"store value"}, "store value - 1: [joe]");
352     is($result{"fetch key"}, "fetch key - 1: [fred]");
353     is($result{"fetch value"}, undef);
354     is($_, "original");
355
356     $h{"jim"}  = "john" ;
357     is($result{"store key"}, "store key - 2: [fred jim]");
358     is($result{"store value"}, "store value - 2: [joe john]");
359     is($result{"fetch key"}, "fetch key - 1: [fred]");
360     is($result{"fetch value"}, undef);
361     is($_, "original");
362
363     is($h{"fred"}, "joe");
364     is($result{"store key"}, "store key - 3: [fred jim fred]");
365     is($result{"store value"}, "store value - 2: [joe john]");
366     is($result{"fetch key"}, "fetch key - 1: [fred]");
367     is($result{"fetch value"}, "fetch value - 1: [joe]");
368     is($_, "original");
369
370     undef $db ;
371     untie %h;
372     unlink <Op_dbmx*>;
373 }               
374
375 {
376    # DBM Filter recursion detection
377    my (%h, $db) ;
378    unlink <Op_dbmx*>;
379
380    $db = tie %h, 'ODBM_File', 'Op_dbmx', O_RDWR|O_CREAT, 0640;
381    isa_ok($db, 'ODBM_File');
382
383    $db->filter_store_key (sub { $_ = $h{$_} }) ;
384
385    eval '$h{1} = 1234' ;
386    like($@, qr/^recursion detected in filter_store_key at/);
387    
388    undef $db ;
389    untie %h;
390    unlink <Op_dbmx*>;
391 }
392
393 {
394     # Bug ID 20001013.009
395     #
396     # test that $hash{KEY} = undef doesn't produce the warning
397     #     Use of uninitialized value in null operation 
398
399     unlink <Op_dbmx*>;
400     my %h ;
401     my $a = "";
402     local $SIG{__WARN__} = sub {$a = $_[0]} ;
403
404     isa_ok(tie(%h, 'ODBM_File', 'Op_dbmx', O_RDWR|O_CREAT, 0640), 'ODBM_File');
405     $h{ABC} = undef;
406     is($a, "");
407     untie %h;
408     unlink <Op_dbmx*>;
409 }
410
411 {
412     # When iterating over a tied hash using "each", the key passed to FETCH
413     # will be recycled and passed to NEXTKEY. If a Source Filter modifies the
414     # key in FETCH via a filter_fetch_key method we need to check that the
415     # modified key doesn't get passed to NEXTKEY.
416     # Also Test "keys" & "values" while we are at it.
417
418     unlink <Op_dbmx*>;
419     my $bad_key = 0 ;
420     my %h = () ;
421     my $db = tie %h, 'ODBM_File','Op_dbmx', O_RDWR|O_CREAT, 0640;
422     isa_ok($db, 'ODBM_File');
423     $db->filter_fetch_key (sub { $_ =~ s/^Beta_/Alpha_/ if defined $_}) ;
424     $db->filter_store_key (sub { $bad_key = 1 if /^Beta_/ ; $_ =~ s/^Alpha_/Beta_/}) ;
425
426     $h{'Alpha_ABC'} = 2 ;
427     $h{'Alpha_DEF'} = 5 ;
428
429     is($h{'Alpha_ABC'}, 2);
430     is($h{'Alpha_DEF'}, 5);
431
432     my ($k, $v) = ("","");
433     while (($k, $v) = each %h) {}
434     is($bad_key, 0);
435
436     $bad_key = 0 ;
437     foreach $k (keys %h) {}
438     is($bad_key, 0);
439
440     $bad_key = 0 ;
441     foreach $v (values %h) {}
442     is($bad_key, 0);
443
444     undef $db ;
445     untie %h ;
446     unlink <Op_dbmx*>;
447 }
448
449
450 {
451    # Check that DBM Filter can cope with read-only $_
452
453    my %h ;
454    unlink <Op1_dbmx*>;
455
456    my $db = tie %h, 'ODBM_File','Op1_dbmx', O_RDWR|O_CREAT, 0640;
457    isa_ok($db, 'ODBM_File');
458
459    $db->filter_fetch_key   (sub { }) ;
460    $db->filter_store_key   (sub { }) ;
461    $db->filter_fetch_value (sub { }) ;
462    $db->filter_store_value (sub { }) ;
463
464    $_ = "original" ;
465
466    $h{"fred"} = "joe" ;
467    is($h{"fred"}, "joe");
468
469    eval { grep { $h{$_} } (1, 2, 3) };
470    is($@, '');
471
472
473    # delete the filters
474    $db->filter_fetch_key   (undef);
475    $db->filter_store_key   (undef);
476    $db->filter_fetch_value (undef);
477    $db->filter_store_value (undef);
478
479    $h{"fred"} = "joe" ;
480
481    is($h{"fred"}, "joe");
482
483    is($db->FIRSTKEY(), "fred");
484    
485    eval { grep { $h{$_} } (1, 2, 3) };
486    is($@, '');
487
488    undef $db ;
489    untie %h;
490    unlink <Op1_dbmx*>;
491 }
492
493 if ($^O eq 'hpux') {
494     print <<EOM;
495 #
496 # If you experience failures with the odbm test in HP-UX,
497 # this is a well-known bug that's unfortunately very hard to fix.
498 # The suggested course of action is to avoid using the ODBM_File,
499 # but to use instead the NDBM_File extension.
500 #
501 EOM
502 }