This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Clarification on what Perl does to floating points in the modulus
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 =head2 Operator Precedence and Associativity 
9 X<operator, precedence> X<precedence> X<associativity>
10
11 Operator precedence and associativity work in Perl more or less like
12 they do in mathematics.
13
14 I<Operator precedence> means some operators are evaluated before
15 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
16 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
17 22> and not C<6 * 5 == 30>.
18
19 I<Operator associativity> defines what happens if a sequence of the
20 same operators is used one after another: whether the evaluator will
21 evaluate the left operations first or the right.  For example, in C<8
22 - 4 - 2>, subtraction is left associative so Perl evaluates the
23 expression left to right.  C<8 - 4> is evaluated first making the
24 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
25
26 Perl operators have the following associativity and precedence,
27 listed from highest precedence to lowest.  Operators borrowed from
28 C keep the same precedence relationship with each other, even where
29 C's precedence is slightly screwy.  (This makes learning Perl easier
30 for C folks.)  With very few exceptions, these all operate on scalar
31 values only, not array values.
32
33     left        terms and list operators (leftward)
34     left        ->
35     nonassoc    ++ --
36     right       **
37     right       ! ~ \ and unary + and -
38     left        =~ !~
39     left        * / % x
40     left        + - .
41     left        << >>
42     nonassoc    named unary operators
43     nonassoc    < > <= >= lt gt le ge
44     nonassoc    == != <=> eq ne cmp ~~
45     left        &
46     left        | ^
47     left        &&
48     left        || //
49     nonassoc    ..  ...
50     right       ?:
51     right       = += -= *= etc.
52     left        , =>
53     nonassoc    list operators (rightward)
54     right       not
55     left        and
56     left        or xor err
57
58 In the following sections, these operators are covered in precedence order.
59
60 Many operators can be overloaded for objects.  See L<overload>.
61
62 =head2 Terms and List Operators (Leftward)
63 X<list operator> X<operator, list> X<term>
64
65 A TERM has the highest precedence in Perl.  They include variables,
66 quote and quote-like operators, any expression in parentheses,
67 and any function whose arguments are parenthesized.  Actually, there
68 aren't really functions in this sense, just list operators and unary
69 operators behaving as functions because you put parentheses around
70 the arguments.  These are all documented in L<perlfunc>.
71
72 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
73 is followed by a left parenthesis as the next token, the operator and
74 arguments within parentheses are taken to be of highest precedence,
75 just like a normal function call.
76
77 In the absence of parentheses, the precedence of list operators such as
78 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
79 whether you are looking at the left side or the right side of the operator.
80 For example, in
81
82     @ary = (1, 3, sort 4, 2);
83     print @ary;         # prints 1324
84
85 the commas on the right of the sort are evaluated before the sort,
86 but the commas on the left are evaluated after.  In other words,
87 list operators tend to gobble up all arguments that follow, and
88 then act like a simple TERM with regard to the preceding expression.
89 Be careful with parentheses:
90
91     # These evaluate exit before doing the print:
92     print($foo, exit);  # Obviously not what you want.
93     print $foo, exit;   # Nor is this.
94
95     # These do the print before evaluating exit:
96     (print $foo), exit; # This is what you want.
97     print($foo), exit;  # Or this.
98     print ($foo), exit; # Or even this.
99
100 Also note that
101
102     print ($foo & 255) + 1, "\n";
103
104 probably doesn't do what you expect at first glance.  The parentheses
105 enclose the argument list for C<print> which is evaluated (printing
106 the result of C<$foo & 255>).  Then one is added to the return value
107 of C<print> (usually 1).  The result is something like this:
108
109     1 + 1, "\n";    # Obviously not what you meant.
110
111 To do what you meant properly, you must write:
112
113     print(($foo & 255) + 1, "\n");
114
115 See L<Named Unary Operators> for more discussion of this.
116
117 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
118 well as subroutine and method calls, and the anonymous
119 constructors C<[]> and C<{}>.
120
121 See also L<Quote and Quote-like Operators> toward the end of this section,
122 as well as L</"I/O Operators">.
123
124 =head2 The Arrow Operator
125 X<arrow> X<dereference> X<< -> >>
126
127 "C<< -> >>" is an infix dereference operator, just as it is in C
128 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
129 C<(...)> subscript, then the left side must be either a hard or
130 symbolic reference to an array, a hash, or a subroutine respectively.
131 (Or technically speaking, a location capable of holding a hard
132 reference, if it's an array or hash reference being used for
133 assignment.)  See L<perlreftut> and L<perlref>.
134
135 Otherwise, the right side is a method name or a simple scalar
136 variable containing either the method name or a subroutine reference,
137 and the left side must be either an object (a blessed reference)
138 or a class name (that is, a package name).  See L<perlobj>.
139
140 =head2 Auto-increment and Auto-decrement
141 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
142
143 "++" and "--" work as in C.  That is, if placed before a variable,
144 they increment or decrement the variable by one before returning the
145 value, and if placed after, increment or decrement after returning the
146 value.
147
148     $i = 0;  $j = 0;
149     print $i++;  # prints 0
150     print ++$j;  # prints 1
151
152 Note that just as in C, Perl doesn't define B<when> the variable is
153 incremented or decremented. You just know it will be done sometime 
154 before or after the value is returned. This also means that modifying
155 a variable twice in the same statement will lead to undefined behaviour.
156 Avoid statements like:
157
158     $i = $i ++;
159     print ++ $i + $i ++;
160
161 Perl will not guarantee what the result of the above statements is.
162
163 The auto-increment operator has a little extra builtin magic to it.  If
164 you increment a variable that is numeric, or that has ever been used in
165 a numeric context, you get a normal increment.  If, however, the
166 variable has been used in only string contexts since it was set, and
167 has a value that is not the empty string and matches the pattern
168 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
169 character within its range, with carry:
170
171     print ++($foo = '99');      # prints '100'
172     print ++($foo = 'a0');      # prints 'a1'
173     print ++($foo = 'Az');      # prints 'Ba'
174     print ++($foo = 'zz');      # prints 'aaa'
175
176 C<undef> is always treated as numeric, and in particular is changed
177 to C<0> before incrementing (so that a post-increment of an undef value
178 will return C<0> rather than C<undef>).
179
180 The auto-decrement operator is not magical.
181
182 =head2 Exponentiation
183 X<**> X<exponentiation> X<power>
184
185 Binary "**" is the exponentiation operator.  It binds even more
186 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
187 implemented using C's pow(3) function, which actually works on doubles
188 internally.)
189
190 =head2 Symbolic Unary Operators
191 X<unary operator> X<operator, unary>
192
193 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
194 precedence version of this.
195 X<!>
196
197 Unary "-" performs arithmetic negation if the operand is numeric.  If
198 the operand is an identifier, a string consisting of a minus sign
199 concatenated with the identifier is returned.  Otherwise, if the string
200 starts with a plus or minus, a string starting with the opposite sign
201 is returned.  One effect of these rules is that -bareword is equivalent
202 to the string "-bareword".  If, however, the string begins with a
203 non-alphabetic character (exluding "+" or "-"), Perl will attempt to convert
204 the string to a numeric and the arithmetic negation is performed. If the
205 string cannot be cleanly converted to a numeric, Perl will give the warning
206 B<Argument "the string" isn't numeric in negation (-) at ...>.
207 X<-> X<negation, arithmetic>
208
209 Unary "~" performs bitwise negation, i.e., 1's complement.  For
210 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
211 L<Bitwise String Operators>.)  Note that the width of the result is
212 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
213 bits wide on a 64-bit platform, so if you are expecting a certain bit
214 width, remember to use the & operator to mask off the excess bits.
215 X<~> X<negation, binary>
216
217 Unary "+" has no effect whatsoever, even on strings.  It is useful
218 syntactically for separating a function name from a parenthesized expression
219 that would otherwise be interpreted as the complete list of function
220 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
221 X<+>
222
223 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
224 and L<perlref>.  Do not confuse this behavior with the behavior of
225 backslash within a string, although both forms do convey the notion
226 of protecting the next thing from interpolation.
227 X<\> X<reference> X<backslash>
228
229 =head2 Binding Operators
230 X<binding> X<operator, binding> X<=~> X<!~>
231
232 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
233 search or modify the string $_ by default.  This operator makes that kind
234 of operation work on some other string.  The right argument is a search
235 pattern, substitution, or transliteration.  The left argument is what is
236 supposed to be searched, substituted, or transliterated instead of the default
237 $_.  When used in scalar context, the return value generally indicates the
238 success of the operation.  Behavior in list context depends on the particular
239 operator.  See L</"Regexp Quote-Like Operators"> for details and 
240 L<perlretut> for examples using these operators.
241
242 If the right argument is an expression rather than a search pattern,
243 substitution, or transliteration, it is interpreted as a search pattern at run
244 time.
245
246 Binary "!~" is just like "=~" except the return value is negated in
247 the logical sense.
248
249 =head2 Multiplicative Operators
250 X<operator, multiplicative>
251
252 Binary "*" multiplies two numbers.
253 X<*>
254
255 Binary "/" divides two numbers.
256 X</> X<slash>
257
258 Binary "%" computes the modulus of two numbers.  Given integer
259 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
260 C<$a> minus the largest multiple of C<$b> that is not greater than
261 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
262 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
263 result will be less than or equal to zero).  If the operands
264 C<$a> and C<$b> are floting point values, only the integer portion 
265 of C<$a> and C<$b> will be used in the operation.
266 Note that when C<use integer> is in scope, "%" gives you direct access
267 to the modulus operator as implemented by your C compiler.  This
268 operator is not as well defined for negative operands, but it will
269 execute faster.
270 X<%> X<remainder> X<modulus> X<mod>
271
272 Binary "x" is the repetition operator.  In scalar context or if the left
273 operand is not enclosed in parentheses, it returns a string consisting
274 of the left operand repeated the number of times specified by the right
275 operand.  In list context, if the left operand is enclosed in
276 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
277 If the right operand is zero or negative, it returns an empty string
278 or an empty list, depending on the context.
279 X<x>
280
281     print '-' x 80;             # print row of dashes
282
283     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
284
285     @ones = (1) x 80;           # a list of 80 1's
286     @ones = (5) x @ones;        # set all elements to 5
287
288
289 =head2 Additive Operators
290 X<operator, additive>
291
292 Binary "+" returns the sum of two numbers.
293 X<+>
294
295 Binary "-" returns the difference of two numbers.
296 X<->
297
298 Binary "." concatenates two strings.
299 X<string, concatenation> X<concatenation>
300 X<cat> X<concat> X<concatenate> X<.>
301
302 =head2 Shift Operators
303 X<shift operator> X<operator, shift> X<<< << >>>
304 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
305 X<shl> X<shr> X<shift, right> X<shift, left>
306
307 Binary "<<" returns the value of its left argument shifted left by the
308 number of bits specified by the right argument.  Arguments should be
309 integers.  (See also L<Integer Arithmetic>.)
310
311 Binary ">>" returns the value of its left argument shifted right by
312 the number of bits specified by the right argument.  Arguments should
313 be integers.  (See also L<Integer Arithmetic>.)
314
315 Note that both "<<" and ">>" in Perl are implemented directly using
316 "<<" and ">>" in C.  If C<use integer> (see L<Integer Arithmetic>) is
317 in force then signed C integers are used, else unsigned C integers are
318 used.  Either way, the implementation isn't going to generate results
319 larger than the size of the integer type Perl was built with (32 bits
320 or 64 bits).
321
322 The result of overflowing the range of the integers is undefined
323 because it is undefined also in C.  In other words, using 32-bit
324 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
325 of bits is also undefined.
326
327 =head2 Named Unary Operators
328 X<operator, named unary>
329
330 The various named unary operators are treated as functions with one
331 argument, with optional parentheses.
332
333 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
334 is followed by a left parenthesis as the next token, the operator and
335 arguments within parentheses are taken to be of highest precedence,
336 just like a normal function call.  For example,
337 because named unary operators are higher precedence than ||:
338
339     chdir $foo    || die;       # (chdir $foo) || die
340     chdir($foo)   || die;       # (chdir $foo) || die
341     chdir ($foo)  || die;       # (chdir $foo) || die
342     chdir +($foo) || die;       # (chdir $foo) || die
343
344 but, because * is higher precedence than named operators:
345
346     chdir $foo * 20;    # chdir ($foo * 20)
347     chdir($foo) * 20;   # (chdir $foo) * 20
348     chdir ($foo) * 20;  # (chdir $foo) * 20
349     chdir +($foo) * 20; # chdir ($foo * 20)
350
351     rand 10 * 20;       # rand (10 * 20)
352     rand(10) * 20;      # (rand 10) * 20
353     rand (10) * 20;     # (rand 10) * 20
354     rand +(10) * 20;    # rand (10 * 20)
355
356 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
357 treated like named unary operators, but they don't follow this functional
358 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
359 equivalent to C<-f "$file.bak">.
360 X<-X> X<filetest> X<operator, filetest>
361
362 See also L<"Terms and List Operators (Leftward)">.
363
364 =head2 Relational Operators
365 X<relational operator> X<operator, relational>
366
367 Binary "<" returns true if the left argument is numerically less than
368 the right argument.
369 X<< < >>
370
371 Binary ">" returns true if the left argument is numerically greater
372 than the right argument.
373 X<< > >>
374
375 Binary "<=" returns true if the left argument is numerically less than
376 or equal to the right argument.
377 X<< <= >>
378
379 Binary ">=" returns true if the left argument is numerically greater
380 than or equal to the right argument.
381 X<< >= >>
382
383 Binary "lt" returns true if the left argument is stringwise less than
384 the right argument.
385 X<< lt >>
386
387 Binary "gt" returns true if the left argument is stringwise greater
388 than the right argument.
389 X<< gt >>
390
391 Binary "le" returns true if the left argument is stringwise less than
392 or equal to the right argument.
393 X<< le >>
394
395 Binary "ge" returns true if the left argument is stringwise greater
396 than or equal to the right argument.
397 X<< ge >>
398
399 =head2 Equality Operators
400 X<equality> X<equal> X<equals> X<operator, equality>
401
402 Binary "==" returns true if the left argument is numerically equal to
403 the right argument.
404 X<==>
405
406 Binary "!=" returns true if the left argument is numerically not equal
407 to the right argument.
408 X<!=>
409
410 Binary "<=>" returns -1, 0, or 1 depending on whether the left
411 argument is numerically less than, equal to, or greater than the right
412 argument.  If your platform supports NaNs (not-a-numbers) as numeric
413 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
414 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
415 returns true, as does NaN != anything else. If your platform doesn't
416 support NaNs then NaN is just a string with numeric value 0.
417 X<< <=> >> X<spaceship>
418
419     perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
420     perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
421
422 Binary "eq" returns true if the left argument is stringwise equal to
423 the right argument.
424 X<eq>
425
426 Binary "ne" returns true if the left argument is stringwise not equal
427 to the right argument.
428 X<ne>
429
430 Binary "cmp" returns -1, 0, or 1 depending on whether the left
431 argument is stringwise less than, equal to, or greater than the right
432 argument.
433 X<cmp>
434
435 Binary "~~" does a smart match between its arguments. Smart matching
436 is described in L<perlsyn/"Smart Matching in Detail">.
437 This operator is only available if you enable the "~~" feature:
438 see L<feature> for more information.
439 X<~~>
440
441 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
442 by the current locale if C<use locale> is in effect.  See L<perllocale>.
443
444 =head2 Bitwise And
445 X<operator, bitwise, and> X<bitwise and> X<&>
446
447 Binary "&" returns its operands ANDed together bit by bit.
448 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
449
450 Note that "&" has lower priority than relational operators, so for example
451 the brackets are essential in a test like
452
453         print "Even\n" if ($x & 1) == 0;
454
455 =head2 Bitwise Or and Exclusive Or
456 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
457 X<bitwise xor> X<^>
458
459 Binary "|" returns its operands ORed together bit by bit.
460 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
461
462 Binary "^" returns its operands XORed together bit by bit.
463 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
464
465 Note that "|" and "^" have lower priority than relational operators, so
466 for example the brackets are essential in a test like
467
468         print "false\n" if (8 | 2) != 10;
469
470 =head2 C-style Logical And
471 X<&&> X<logical and> X<operator, logical, and>
472
473 Binary "&&" performs a short-circuit logical AND operation.  That is,
474 if the left operand is false, the right operand is not even evaluated.
475 Scalar or list context propagates down to the right operand if it
476 is evaluated.
477
478 =head2 C-style Logical Or
479 X<||> X<operator, logical, or>
480
481 Binary "||" performs a short-circuit logical OR operation.  That is,
482 if the left operand is true, the right operand is not even evaluated.
483 Scalar or list context propagates down to the right operand if it
484 is evaluated.
485
486 =head2 C-style Logical Defined-Or
487 X<//> X<operator, logical, defined-or>
488
489 Although it has no direct equivalent in C, Perl's C<//> operator is related
490 to its C-style or.  In fact, it's exactly the same as C<||>, except that it 
491 tests the left hand side's definedness instead of its truth.  Thus, C<$a // $b>
492 is similar to C<defined($a) || $b> (except that it returns the value of C<$a> 
493 rather than the value of C<defined($a)>) and is exactly equivalent to 
494 C<defined($a) ? $a : $b>.  This is very useful for providing default values
495 for variables.  If you actually want to test if at least one of C<$a> and 
496 C<$b> is defined, use C<defined($a // $b)>.
497
498 The C<||>, C<//> and C<&&> operators return the last value evaluated
499 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
500 portable way to find out the home directory might be:
501
502     $home = $ENV{'HOME'} // $ENV{'LOGDIR'} //
503         (getpwuid($<))[7] // die "You're homeless!\n";
504
505 In particular, this means that you shouldn't use this
506 for selecting between two aggregates for assignment:
507
508     @a = @b || @c;              # this is wrong
509     @a = scalar(@b) || @c;      # really meant this
510     @a = @b ? @b : @c;          # this works fine, though
511
512 As more readable alternatives to C<&&>, C<//> and C<||> when used for
513 control flow, Perl provides C<and>, C<err> and C<or> operators (see below).
514 The short-circuit behavior is identical.  The precedence of "and", "err" 
515 and "or" is much lower, however, so that you can safely use them after a
516 list operator without the need for parentheses:
517
518     unlink "alpha", "beta", "gamma"
519             or gripe(), next LINE;
520
521 With the C-style operators that would have been written like this:
522
523     unlink("alpha", "beta", "gamma")
524             || (gripe(), next LINE);
525
526 Using "or" for assignment is unlikely to do what you want; see below.
527
528 =head2 Range Operators
529 X<operator, range> X<range> X<..> X<...>
530
531 Binary ".." is the range operator, which is really two different
532 operators depending on the context.  In list context, it returns a
533 list of values counting (up by ones) from the left value to the right
534 value.  If the left value is greater than the right value then it
535 returns the empty list.  The range operator is useful for writing
536 C<foreach (1..10)> loops and for doing slice operations on arrays. In
537 the current implementation, no temporary array is created when the
538 range operator is used as the expression in C<foreach> loops, but older
539 versions of Perl might burn a lot of memory when you write something
540 like this:
541
542     for (1 .. 1_000_000) {
543         # code
544     }
545
546 The range operator also works on strings, using the magical auto-increment,
547 see below.
548
549 In scalar context, ".." returns a boolean value.  The operator is
550 bistable, like a flip-flop, and emulates the line-range (comma) operator
551 of B<sed>, B<awk>, and various editors.  Each ".." operator maintains its
552 own boolean state.  It is false as long as its left operand is false.
553 Once the left operand is true, the range operator stays true until the
554 right operand is true, I<AFTER> which the range operator becomes false
555 again.  It doesn't become false till the next time the range operator is
556 evaluated.  It can test the right operand and become false on the same
557 evaluation it became true (as in B<awk>), but it still returns true once.
558 If you don't want it to test the right operand till the next
559 evaluation, as in B<sed>, just use three dots ("...") instead of
560 two.  In all other regards, "..." behaves just like ".." does.
561
562 The right operand is not evaluated while the operator is in the
563 "false" state, and the left operand is not evaluated while the
564 operator is in the "true" state.  The precedence is a little lower
565 than || and &&.  The value returned is either the empty string for
566 false, or a sequence number (beginning with 1) for true.  The
567 sequence number is reset for each range encountered.  The final
568 sequence number in a range has the string "E0" appended to it, which
569 doesn't affect its numeric value, but gives you something to search
570 for if you want to exclude the endpoint.  You can exclude the
571 beginning point by waiting for the sequence number to be greater
572 than 1.
573
574 If either operand of scalar ".." is a constant expression,
575 that operand is considered true if it is equal (C<==>) to the current
576 input line number (the C<$.> variable).
577
578 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
579 but that is only an issue if you use a floating point expression; when
580 implicitly using C<$.> as described in the previous paragraph, the
581 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
582 is set to a floating point value and you are not reading from a file.
583 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
584 you want in scalar context because each of the operands are evaluated
585 using their integer representation.
586
587 Examples:
588
589 As a scalar operator:
590
591     if (101 .. 200) { print; } # print 2nd hundred lines, short for
592                                #   if ($. == 101 .. $. == 200) ...
593
594     next LINE if (1 .. /^$/);  # skip header lines, short for
595                                #   ... if ($. == 1 .. /^$/);
596                                # (typically in a loop labeled LINE)
597
598     s/^/> / if (/^$/ .. eof());  # quote body
599
600     # parse mail messages
601     while (<>) {
602         $in_header =   1  .. /^$/;
603         $in_body   = /^$/ .. eof;
604         if ($in_header) {
605             # ...
606         } else { # in body
607             # ...
608         }
609     } continue {
610         close ARGV if eof;             # reset $. each file
611     }
612
613 Here's a simple example to illustrate the difference between
614 the two range operators:
615
616     @lines = ("   - Foo",
617               "01 - Bar",
618               "1  - Baz",
619               "   - Quux");
620
621     foreach (@lines) {
622         if (/0/ .. /1/) {
623             print "$_\n";
624         }
625     }
626
627 This program will print only the line containing "Bar". If
628 the range operator is changed to C<...>, it will also print the
629 "Baz" line.
630
631 And now some examples as a list operator:
632
633     for (101 .. 200) { print; } # print $_ 100 times
634     @foo = @foo[0 .. $#foo];    # an expensive no-op
635     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
636
637 The range operator (in list context) makes use of the magical
638 auto-increment algorithm if the operands are strings.  You
639 can say
640
641     @alphabet = ('A' .. 'Z');
642
643 to get all normal letters of the English alphabet, or
644
645     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
646
647 to get a hexadecimal digit, or
648
649     @z2 = ('01' .. '31');  print $z2[$mday];
650
651 to get dates with leading zeros.  If the final value specified is not
652 in the sequence that the magical increment would produce, the sequence
653 goes until the next value would be longer than the final value
654 specified.
655
656 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
657 return two elements in list context.
658
659     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
660
661 =head2 Conditional Operator
662 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
663
664 Ternary "?:" is the conditional operator, just as in C.  It works much
665 like an if-then-else.  If the argument before the ? is true, the
666 argument before the : is returned, otherwise the argument after the :
667 is returned.  For example:
668
669     printf "I have %d dog%s.\n", $n,
670             ($n == 1) ? '' : "s";
671
672 Scalar or list context propagates downward into the 2nd
673 or 3rd argument, whichever is selected.
674
675     $a = $ok ? $b : $c;  # get a scalar
676     @a = $ok ? @b : @c;  # get an array
677     $a = $ok ? @b : @c;  # oops, that's just a count!
678
679 The operator may be assigned to if both the 2nd and 3rd arguments are
680 legal lvalues (meaning that you can assign to them):
681
682     ($a_or_b ? $a : $b) = $c;
683
684 Because this operator produces an assignable result, using assignments
685 without parentheses will get you in trouble.  For example, this:
686
687     $a % 2 ? $a += 10 : $a += 2
688
689 Really means this:
690
691     (($a % 2) ? ($a += 10) : $a) += 2
692
693 Rather than this:
694
695     ($a % 2) ? ($a += 10) : ($a += 2)
696
697 That should probably be written more simply as:
698
699     $a += ($a % 2) ? 10 : 2;
700
701 =head2 Assignment Operators
702 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
703 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
704 X<%=> X<^=> X<x=>
705
706 "=" is the ordinary assignment operator.
707
708 Assignment operators work as in C.  That is,
709
710     $a += 2;
711
712 is equivalent to
713
714     $a = $a + 2;
715
716 although without duplicating any side effects that dereferencing the lvalue
717 might trigger, such as from tie().  Other assignment operators work similarly.
718 The following are recognized:
719
720     **=    +=    *=    &=    <<=    &&=
721            -=    /=    |=    >>=    ||=
722            .=    %=    ^=           //=
723                  x=
724
725 Although these are grouped by family, they all have the precedence
726 of assignment.
727
728 Unlike in C, the scalar assignment operator produces a valid lvalue.
729 Modifying an assignment is equivalent to doing the assignment and
730 then modifying the variable that was assigned to.  This is useful
731 for modifying a copy of something, like this:
732
733     ($tmp = $global) =~ tr [A-Z] [a-z];
734
735 Likewise,
736
737     ($a += 2) *= 3;
738
739 is equivalent to
740
741     $a += 2;
742     $a *= 3;
743
744 Similarly, a list assignment in list context produces the list of
745 lvalues assigned to, and a list assignment in scalar context returns
746 the number of elements produced by the expression on the right hand
747 side of the assignment.
748
749 =head2 Comma Operator
750 X<comma> X<operator, comma> X<,>
751
752 Binary "," is the comma operator.  In scalar context it evaluates
753 its left argument, throws that value away, then evaluates its right
754 argument and returns that value.  This is just like C's comma operator.
755
756 In list context, it's just the list argument separator, and inserts
757 both its arguments into the list.  These arguments are also evaluated
758 from left to right.
759
760 The C<< => >> operator is a synonym for the comma, but forces any word
761 (consisting entirely of word characters) to its left to be interpreted
762 as a string (as of 5.001).  This includes words that might otherwise be
763 considered a constant or function call.
764
765     use constant FOO => "something";
766
767     my %h = ( FOO => 23 );
768
769 is equivalent to:
770
771     my %h = ("FOO", 23);
772
773 It is I<NOT>:
774
775     my %h = ("something", 23);
776
777 If the argument on the left is not a word, it is first interpreted as
778 an expression, and then the string value of that is used.
779
780 The C<< => >> operator is helpful in documenting the correspondence
781 between keys and values in hashes, and other paired elements in lists.
782
783         %hash = ( $key => $value );
784         login( $username => $password );
785
786 =head2 List Operators (Rightward)
787 X<operator, list, rightward> X<list operator>
788
789 On the right side of a list operator, it has very low precedence,
790 such that it controls all comma-separated expressions found there.
791 The only operators with lower precedence are the logical operators
792 "and", "or", and "not", which may be used to evaluate calls to list
793 operators without the need for extra parentheses:
794
795     open HANDLE, "filename"
796         or die "Can't open: $!\n";
797
798 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
799
800 =head2 Logical Not
801 X<operator, logical, not> X<not>
802
803 Unary "not" returns the logical negation of the expression to its right.
804 It's the equivalent of "!" except for the very low precedence.
805
806 =head2 Logical And
807 X<operator, logical, and> X<and>
808
809 Binary "and" returns the logical conjunction of the two surrounding
810 expressions.  It's equivalent to && except for the very low
811 precedence.  This means that it short-circuits: i.e., the right
812 expression is evaluated only if the left expression is true.
813
814 =head2 Logical or, Defined or, and Exclusive Or
815 X<operator, logical, or> X<operator, logical, xor> X<operator, logical, err>
816 X<operator, logical, defined or> X<operator, logical, exclusive or>
817 X<or> X<xor> X<err>
818
819 Binary "or" returns the logical disjunction of the two surrounding
820 expressions.  It's equivalent to || except for the very low precedence.
821 This makes it useful for control flow
822
823     print FH $data              or die "Can't write to FH: $!";
824
825 This means that it short-circuits: i.e., the right expression is evaluated
826 only if the left expression is false.  Due to its precedence, you should
827 probably avoid using this for assignment, only for control flow.
828
829     $a = $b or $c;              # bug: this is wrong
830     ($a = $b) or $c;            # really means this
831     $a = $b || $c;              # better written this way
832
833 However, when it's a list-context assignment and you're trying to use
834 "||" for control flow, you probably need "or" so that the assignment
835 takes higher precedence.
836
837     @info = stat($file) || die;     # oops, scalar sense of stat!
838     @info = stat($file) or die;     # better, now @info gets its due
839
840 Then again, you could always use parentheses.
841
842 Binary "err" is equivalent to C<//>--it's just like binary "or", except it
843 tests its left argument's definedness instead of its truth.  There are two
844 ways to remember "err":  either because many functions return C<undef> on
845 an B<err>or, or as a sort of correction:  C<$a = ($b err 'default')>. This
846 keyword is only available when the 'err' feature is enabled: see
847 L<feature> for more information.
848
849 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
850 It cannot short circuit, of course.
851
852 =head2 C Operators Missing From Perl
853 X<operator, missing from perl> X<&> X<*>
854 X<typecasting> X<(TYPE)>
855
856 Here is what C has that Perl doesn't:
857
858 =over 8
859
860 =item unary &
861
862 Address-of operator.  (But see the "\" operator for taking a reference.)
863
864 =item unary *
865
866 Dereference-address operator. (Perl's prefix dereferencing
867 operators are typed: $, @, %, and &.)
868
869 =item (TYPE)
870
871 Type-casting operator.
872
873 =back
874
875 =head2 Quote and Quote-like Operators
876 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m> 
877 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
878 X<escape sequence> X<escape>
879
880
881 While we usually think of quotes as literal values, in Perl they
882 function as operators, providing various kinds of interpolating and
883 pattern matching capabilities.  Perl provides customary quote characters
884 for these behaviors, but also provides a way for you to choose your
885 quote character for any of them.  In the following table, a C<{}> represents
886 any pair of delimiters you choose.
887
888     Customary  Generic        Meaning        Interpolates
889         ''       q{}          Literal             no
890         ""      qq{}          Literal             yes
891         ``      qx{}          Command             yes*
892                 qw{}         Word list            no
893         //       m{}       Pattern match          yes*
894                 qr{}          Pattern             yes*
895                  s{}{}      Substitution          yes*
896                 tr{}{}    Transliteration         no (but see below)
897         <<EOF                 here-doc            yes*
898
899         * unless the delimiter is ''.
900
901 Non-bracketing delimiters use the same character fore and aft, but the four
902 sorts of brackets (round, angle, square, curly) will all nest, which means
903 that
904
905         q{foo{bar}baz}
906
907 is the same as
908
909         'foo{bar}baz'
910
911 Note, however, that this does not always work for quoting Perl code:
912
913         $s = q{ if($a eq "}") ... }; # WRONG
914
915 is a syntax error. The C<Text::Balanced> module (from CPAN, and
916 starting from Perl 5.8 part of the standard distribution) is able
917 to do this properly.
918
919 There can be whitespace between the operator and the quoting
920 characters, except when C<#> is being used as the quoting character.
921 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
922 operator C<q> followed by a comment.  Its argument will be taken
923 from the next line.  This allows you to write:
924
925     s {foo}  # Replace foo
926       {bar}  # with bar.
927
928 The following escape sequences are available in constructs that interpolate
929 and in transliterations.
930 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N>
931
932     \t          tab             (HT, TAB)
933     \n          newline         (NL)
934     \r          return          (CR)
935     \f          form feed       (FF)
936     \b          backspace       (BS)
937     \a          alarm (bell)    (BEL)
938     \e          escape          (ESC)
939     \033        octal char      (ESC)
940     \x1b        hex char        (ESC)
941     \x{263a}    wide hex char   (SMILEY)
942     \c[         control char    (ESC)
943     \N{name}    named Unicode character
944
945 B<NOTE>: Unlike C and other languages, Perl has no \v escape sequence for
946 the vertical tab (VT - ASCII 11).
947
948 The following escape sequences are available in constructs that interpolate
949 but not in transliterations.
950 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
951
952     \l          lowercase next char
953     \u          uppercase next char
954     \L          lowercase till \E
955     \U          uppercase till \E
956     \E          end case modification
957     \Q          quote non-word characters till \E
958
959 If C<use locale> is in effect, the case map used by C<\l>, C<\L>,
960 C<\u> and C<\U> is taken from the current locale.  See L<perllocale>.
961 If Unicode (for example, C<\N{}> or wide hex characters of 0x100 or
962 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u> and
963 C<\U> is as defined by Unicode.  For documentation of C<\N{name}>,
964 see L<charnames>.
965
966 All systems use the virtual C<"\n"> to represent a line terminator,
967 called a "newline".  There is no such thing as an unvarying, physical
968 newline character.  It is only an illusion that the operating system,
969 device drivers, C libraries, and Perl all conspire to preserve.  Not all
970 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
971 on a Mac, these are reversed, and on systems without line terminator,
972 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
973 you mean a "newline" for your system, but use the literal ASCII when you
974 need an exact character.  For example, most networking protocols expect
975 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
976 and although they often accept just C<"\012">, they seldom tolerate just
977 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
978 you may be burned some day.
979 X<newline> X<line terminator> X<eol> X<end of line>
980 X<\n> X<\r> X<\r\n>
981
982 For constructs that do interpolate, variables beginning with "C<$>"
983 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
984 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
985 But method calls such as C<< $obj->meth >> are not.
986
987 Interpolating an array or slice interpolates the elements in order,
988 separated by the value of C<$">, so is equivalent to interpolating
989 C<join $", @array>.    "Punctuation" arrays such as C<@+> are only
990 interpolated if the name is enclosed in braces C<@{+}>.
991
992 You cannot include a literal C<$> or C<@> within a C<\Q> sequence. 
993 An unescaped C<$> or C<@> interpolates the corresponding variable, 
994 while escaping will cause the literal string C<\$> to be inserted.
995 You'll need to write something like C<m/\Quser\E\@\Qhost/>. 
996
997 Patterns are subject to an additional level of interpretation as a
998 regular expression.  This is done as a second pass, after variables are
999 interpolated, so that regular expressions may be incorporated into the
1000 pattern from the variables.  If this is not what you want, use C<\Q> to
1001 interpolate a variable literally.
1002
1003 Apart from the behavior described above, Perl does not expand
1004 multiple levels of interpolation.  In particular, contrary to the
1005 expectations of shell programmers, back-quotes do I<NOT> interpolate
1006 within double quotes, nor do single quotes impede evaluation of
1007 variables when used within double quotes.
1008
1009 =head2 Regexp Quote-Like Operators
1010 X<operator, regexp>
1011
1012 Here are the quote-like operators that apply to pattern
1013 matching and related activities.
1014
1015 =over 8
1016
1017 =item ?PATTERN?
1018 X<?>
1019
1020 This is just like the C</pattern/> search, except that it matches only
1021 once between calls to the reset() operator.  This is a useful
1022 optimization when you want to see only the first occurrence of
1023 something in each file of a set of files, for instance.  Only C<??>
1024 patterns local to the current package are reset.
1025
1026     while (<>) {
1027         if (?^$?) {
1028                             # blank line between header and body
1029         }
1030     } continue {
1031         reset if eof;       # clear ?? status for next file
1032     }
1033
1034 This usage is vaguely deprecated, which means it just might possibly
1035 be removed in some distant future version of Perl, perhaps somewhere
1036 around the year 2168.
1037
1038 =item m/PATTERN/cgimosx
1039 X<m> X<operator, match> 
1040 X<regexp, options> X<regexp> X<regex, options> X<regex> 
1041 X</c> X</i> X</m> X</o> X</s> X</x>
1042
1043 =item /PATTERN/cgimosx
1044
1045 Searches a string for a pattern match, and in scalar context returns
1046 true if it succeeds, false if it fails.  If no string is specified
1047 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1048 string specified with C<=~> need not be an lvalue--it may be the
1049 result of an expression evaluation, but remember the C<=~> binds
1050 rather tightly.)  See also L<perlre>.  See L<perllocale> for
1051 discussion of additional considerations that apply when C<use locale>
1052 is in effect.
1053
1054 Options are:
1055
1056     c   Do not reset search position on a failed match when /g is in effect.
1057     g   Match globally, i.e., find all occurrences.
1058     i   Do case-insensitive pattern matching.
1059     m   Treat string as multiple lines.
1060     o   Compile pattern only once.
1061     s   Treat string as single line.
1062     x   Use extended regular expressions.
1063
1064 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1065 you can use any pair of non-alphanumeric, non-whitespace characters 
1066 as delimiters.  This is particularly useful for matching path names
1067 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1068 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
1069 If "'" is the delimiter, no interpolation is performed on the PATTERN.
1070
1071 PATTERN may contain variables, which will be interpolated (and the
1072 pattern recompiled) every time the pattern search is evaluated, except
1073 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1074 C<$|> are not interpolated because they look like end-of-string tests.)
1075 If you want such a pattern to be compiled only once, add a C</o> after
1076 the trailing delimiter.  This avoids expensive run-time recompilations,
1077 and is useful when the value you are interpolating won't change over
1078 the life of the script.  However, mentioning C</o> constitutes a promise
1079 that you won't change the variables in the pattern.  If you change them,
1080 Perl won't even notice.  See also L<"qr/STRING/imosx">.
1081
1082 If the PATTERN evaluates to the empty string, the last
1083 I<successfully> matched regular expression is used instead. In this
1084 case, only the C<g> and C<c> flags on the empty pattern is honoured -
1085 the other flags are taken from the original pattern. If no match has
1086 previously succeeded, this will (silently) act instead as a genuine
1087 empty pattern (which will always match).
1088
1089 Note that it's possible to confuse Perl into thinking C<//> (the empty 
1090 regex) is really C<//> (the defined-or operator).  Perl is usually pretty 
1091 good about this, but some pathological cases might trigger this, such as 
1092 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //> 
1093 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl 
1094 will assume you meant defined-or.  If you meant the empty regex, just 
1095 use parentheses or spaces to disambiguate, or even prefix the empty 
1096 regex with an C<m> (so C<//> becomes C<m//>).
1097
1098 If the C</g> option is not used, C<m//> in list context returns a
1099 list consisting of the subexpressions matched by the parentheses in the
1100 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
1101 also set, and that this differs from Perl 4's behavior.)  When there are
1102 no parentheses in the pattern, the return value is the list C<(1)> for
1103 success.  With or without parentheses, an empty list is returned upon
1104 failure.
1105
1106 Examples:
1107
1108     open(TTY, '/dev/tty');
1109     <TTY> =~ /^y/i && foo();    # do foo if desired
1110
1111     if (/Version: *([0-9.]*)/) { $version = $1; }
1112
1113     next if m#^/usr/spool/uucp#;
1114
1115     # poor man's grep
1116     $arg = shift;
1117     while (<>) {
1118         print if /$arg/o;       # compile only once
1119     }
1120
1121     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1122
1123 This last example splits $foo into the first two words and the
1124 remainder of the line, and assigns those three fields to $F1, $F2, and
1125 $Etc.  The conditional is true if any variables were assigned, i.e., if
1126 the pattern matched.
1127
1128 The C</g> modifier specifies global pattern matching--that is,
1129 matching as many times as possible within the string.  How it behaves
1130 depends on the context.  In list context, it returns a list of the
1131 substrings matched by any capturing parentheses in the regular
1132 expression.  If there are no parentheses, it returns a list of all
1133 the matched strings, as if there were parentheses around the whole
1134 pattern.
1135
1136 In scalar context, each execution of C<m//g> finds the next match,
1137 returning true if it matches, and false if there is no further match.
1138 The position after the last match can be read or set using the pos()
1139 function; see L<perlfunc/pos>.   A failed match normally resets the
1140 search position to the beginning of the string, but you can avoid that
1141 by adding the C</c> modifier (e.g. C<m//gc>).  Modifying the target
1142 string also resets the search position.
1143
1144 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1145 zero-width assertion that matches the exact position where the previous
1146 C<m//g>, if any, left off.  Without the C</g> modifier, the C<\G> assertion
1147 still anchors at pos(), but the match is of course only attempted once.
1148 Using C<\G> without C</g> on a target string that has not previously had a
1149 C</g> match applied to it is the same as using the C<\A> assertion to match
1150 the beginning of the string.  Note also that, currently, C<\G> is only
1151 properly supported when anchored at the very beginning of the pattern.
1152
1153 Examples:
1154
1155     # list context
1156     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1157
1158     # scalar context
1159     $/ = "";
1160     while (defined($paragraph = <>)) {
1161         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
1162             $sentences++;
1163         }
1164     }
1165     print "$sentences\n";
1166
1167     # using m//gc with \G
1168     $_ = "ppooqppqq";
1169     while ($i++ < 2) {
1170         print "1: '";
1171         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1172         print "2: '";
1173         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1174         print "3: '";
1175         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1176     }
1177     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1178
1179 The last example should print:
1180
1181     1: 'oo', pos=4
1182     2: 'q', pos=5
1183     3: 'pp', pos=7
1184     1: '', pos=7
1185     2: 'q', pos=8
1186     3: '', pos=8
1187     Final: 'q', pos=8
1188
1189 Notice that the final match matched C<q> instead of C<p>, which a match
1190 without the C<\G> anchor would have done. Also note that the final match
1191 did not update C<pos> -- C<pos> is only updated on a C</g> match. If the
1192 final match did indeed match C<p>, it's a good bet that you're running an
1193 older (pre-5.6.0) Perl.
1194
1195 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1196 combine several regexps like this to process a string part-by-part,
1197 doing different actions depending on which regexp matched.  Each
1198 regexp tries to match where the previous one leaves off.
1199
1200  $_ = <<'EOL';
1201       $url = new URI::URL "http://www/";   die if $url eq "xXx";
1202  EOL
1203  LOOP:
1204     {
1205       print(" digits"),         redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1206       print(" lowercase"),      redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
1207       print(" UPPERCASE"),      redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
1208       print(" Capitalized"),    redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
1209       print(" MiXeD"),          redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
1210       print(" alphanumeric"),   redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
1211       print(" line-noise"),     redo LOOP if /\G[^A-Za-z0-9]+/gc;
1212       print ". That's all!\n";
1213     }
1214
1215 Here is the output (split into several lines):
1216
1217  line-noise lowercase line-noise lowercase UPPERCASE line-noise
1218  UPPERCASE line-noise lowercase line-noise lowercase line-noise
1219  lowercase lowercase line-noise lowercase lowercase line-noise
1220  MiXeD line-noise. That's all!
1221
1222 =item q/STRING/
1223 X<q> X<quote, double> X<'> X<''>
1224
1225 =item C<'STRING'>
1226
1227 A single-quoted, literal string.  A backslash represents a backslash
1228 unless followed by the delimiter or another backslash, in which case
1229 the delimiter or backslash is interpolated.
1230
1231     $foo = q!I said, "You said, 'She said it.'"!;
1232     $bar = q('This is it.');
1233     $baz = '\n';                # a two-character string
1234
1235 =item qq/STRING/
1236 X<qq> X<quote, double> X<"> X<"">
1237
1238 =item "STRING"
1239
1240 A double-quoted, interpolated string.
1241
1242     $_ .= qq
1243      (*** The previous line contains the naughty word "$1".\n)
1244                 if /\b(tcl|java|python)\b/i;      # :-)
1245     $baz = "\n";                # a one-character string
1246
1247 =item qr/STRING/imosx
1248 X<qr> X</i> X</m> X</o> X</s> X</x>
1249
1250 This operator quotes (and possibly compiles) its I<STRING> as a regular
1251 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1252 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1253 is done.  Returns a Perl value which may be used instead of the
1254 corresponding C</STRING/imosx> expression.
1255
1256 For example,
1257
1258     $rex = qr/my.STRING/is;
1259     s/$rex/foo/;
1260
1261 is equivalent to
1262
1263     s/my.STRING/foo/is;
1264
1265 The result may be used as a subpattern in a match:
1266
1267     $re = qr/$pattern/;
1268     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
1269     $string =~ $re;             # or used standalone
1270     $string =~ /$re/;           # or this way
1271
1272 Since Perl may compile the pattern at the moment of execution of qr()
1273 operator, using qr() may have speed advantages in some situations,
1274 notably if the result of qr() is used standalone:
1275
1276     sub match {
1277         my $patterns = shift;
1278         my @compiled = map qr/$_/i, @$patterns;
1279         grep {
1280             my $success = 0;
1281             foreach my $pat (@compiled) {
1282                 $success = 1, last if /$pat/;
1283             }
1284             $success;
1285         } @_;
1286     }
1287
1288 Precompilation of the pattern into an internal representation at
1289 the moment of qr() avoids a need to recompile the pattern every
1290 time a match C</$pat/> is attempted.  (Perl has many other internal
1291 optimizations, but none would be triggered in the above example if
1292 we did not use qr() operator.)
1293
1294 Options are:
1295
1296     i   Do case-insensitive pattern matching.
1297     m   Treat string as multiple lines.
1298     o   Compile pattern only once.
1299     s   Treat string as single line.
1300     x   Use extended regular expressions.
1301
1302 See L<perlre> for additional information on valid syntax for STRING, and
1303 for a detailed look at the semantics of regular expressions.
1304
1305 =item qx/STRING/
1306 X<qx> X<`> X<``> X<backtick>
1307
1308 =item `STRING`
1309
1310 A string which is (possibly) interpolated and then executed as a
1311 system command with C</bin/sh> or its equivalent.  Shell wildcards,
1312 pipes, and redirections will be honored.  The collected standard
1313 output of the command is returned; standard error is unaffected.  In
1314 scalar context, it comes back as a single (potentially multi-line)
1315 string, or undef if the command failed.  In list context, returns a
1316 list of lines (however you've defined lines with $/ or
1317 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
1318
1319 Because backticks do not affect standard error, use shell file descriptor
1320 syntax (assuming the shell supports this) if you care to address this.
1321 To capture a command's STDERR and STDOUT together:
1322
1323     $output = `cmd 2>&1`;
1324
1325 To capture a command's STDOUT but discard its STDERR:
1326
1327     $output = `cmd 2>/dev/null`;
1328
1329 To capture a command's STDERR but discard its STDOUT (ordering is
1330 important here):
1331
1332     $output = `cmd 2>&1 1>/dev/null`;
1333
1334 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1335 but leave its STDOUT to come out the old STDERR:
1336
1337     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1338
1339 To read both a command's STDOUT and its STDERR separately, it's easiest
1340 to redirect them separately to files, and then read from those files
1341 when the program is done:
1342
1343     system("program args 1>program.stdout 2>program.stderr");
1344
1345 The STDIN filehandle used by the command is inherited from Perl's STDIN.
1346 For example:
1347
1348     open BLAM, "blam" || die "Can't open: $!";
1349     open STDIN, "<&BLAM";
1350     print `sort`;
1351
1352 will print the sorted contents of the file "blam".
1353
1354 Using single-quote as a delimiter protects the command from Perl's
1355 double-quote interpolation, passing it on to the shell instead:
1356
1357     $perl_info  = qx(ps $$);            # that's Perl's $$
1358     $shell_info = qx'ps $$';            # that's the new shell's $$
1359
1360 How that string gets evaluated is entirely subject to the command
1361 interpreter on your system.  On most platforms, you will have to protect
1362 shell metacharacters if you want them treated literally.  This is in
1363 practice difficult to do, as it's unclear how to escape which characters.
1364 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1365 to emulate backticks safely.
1366
1367 On some platforms (notably DOS-like ones), the shell may not be
1368 capable of dealing with multiline commands, so putting newlines in
1369 the string may not get you what you want.  You may be able to evaluate
1370 multiple commands in a single line by separating them with the command
1371 separator character, if your shell supports that (e.g. C<;> on many Unix
1372 shells; C<&> on the Windows NT C<cmd> shell).
1373
1374 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1375 output before starting the child process, but this may not be supported
1376 on some platforms (see L<perlport>).  To be safe, you may need to set
1377 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1378 C<IO::Handle> on any open handles.
1379
1380 Beware that some command shells may place restrictions on the length
1381 of the command line.  You must ensure your strings don't exceed this
1382 limit after any necessary interpolations.  See the platform-specific
1383 release notes for more details about your particular environment.
1384
1385 Using this operator can lead to programs that are difficult to port,
1386 because the shell commands called vary between systems, and may in
1387 fact not be present at all.  As one example, the C<type> command under
1388 the POSIX shell is very different from the C<type> command under DOS.
1389 That doesn't mean you should go out of your way to avoid backticks
1390 when they're the right way to get something done.  Perl was made to be
1391 a glue language, and one of the things it glues together is commands.
1392 Just understand what you're getting yourself into.
1393
1394 See L</"I/O Operators"> for more discussion.
1395
1396 =item qw/STRING/
1397 X<qw> X<quote, list> X<quote, words>
1398
1399 Evaluates to a list of the words extracted out of STRING, using embedded
1400 whitespace as the word delimiters.  It can be understood as being roughly
1401 equivalent to:
1402
1403     split(' ', q/STRING/);
1404
1405 the differences being that it generates a real list at compile time, and
1406 in scalar context it returns the last element in the list.  So
1407 this expression:
1408
1409     qw(foo bar baz)
1410
1411 is semantically equivalent to the list:
1412
1413     'foo', 'bar', 'baz'
1414
1415 Some frequently seen examples:
1416
1417     use POSIX qw( setlocale localeconv )
1418     @EXPORT = qw( foo bar baz );
1419
1420 A common mistake is to try to separate the words with comma or to
1421 put comments into a multi-line C<qw>-string.  For this reason, the
1422 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable) 
1423 produces warnings if the STRING contains the "," or the "#" character.
1424
1425 =item s/PATTERN/REPLACEMENT/egimosx
1426 X<substitute> X<substitution> X<replace> X<regexp, replace>
1427 X<regexp, substitute> X</e> X</g> X</i> X</m> X</o> X</s> X</x>
1428
1429 Searches a string for a pattern, and if found, replaces that pattern
1430 with the replacement text and returns the number of substitutions
1431 made.  Otherwise it returns false (specifically, the empty string).
1432
1433 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1434 variable is searched and modified.  (The string specified with C<=~> must
1435 be scalar variable, an array element, a hash element, or an assignment
1436 to one of those, i.e., an lvalue.)
1437
1438 If the delimiter chosen is a single quote, no interpolation is
1439 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1440 PATTERN contains a $ that looks like a variable rather than an
1441 end-of-string test, the variable will be interpolated into the pattern
1442 at run-time.  If you want the pattern compiled only once the first time
1443 the variable is interpolated, use the C</o> option.  If the pattern
1444 evaluates to the empty string, the last successfully executed regular
1445 expression is used instead.  See L<perlre> for further explanation on these.
1446 See L<perllocale> for discussion of additional considerations that apply
1447 when C<use locale> is in effect.
1448
1449 Options are:
1450
1451     e   Evaluate the right side as an expression.
1452     g   Replace globally, i.e., all occurrences.
1453     i   Do case-insensitive pattern matching.
1454     m   Treat string as multiple lines.
1455     o   Compile pattern only once.
1456     s   Treat string as single line.
1457     x   Use extended regular expressions.
1458
1459 Any non-alphanumeric, non-whitespace delimiter may replace the
1460 slashes.  If single quotes are used, no interpretation is done on the
1461 replacement string (the C</e> modifier overrides this, however).  Unlike
1462 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
1463 text is not evaluated as a command.  If the
1464 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
1465 pair of quotes, which may or may not be bracketing quotes, e.g.,
1466 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
1467 replacement portion to be treated as a full-fledged Perl expression
1468 and evaluated right then and there.  It is, however, syntax checked at
1469 compile-time. A second C<e> modifier will cause the replacement portion
1470 to be C<eval>ed before being run as a Perl expression.
1471
1472 Examples:
1473
1474     s/\bgreen\b/mauve/g;                # don't change wintergreen
1475
1476     $path =~ s|/usr/bin|/usr/local/bin|;
1477
1478     s/Login: $foo/Login: $bar/; # run-time pattern
1479
1480     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1481
1482     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1483
1484     $_ = 'abc123xyz';
1485     s/\d+/$&*2/e;               # yields 'abc246xyz'
1486     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1487     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1488
1489     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1490     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1491     s/^=(\w+)/&pod($1)/ge;      # use function call
1492
1493     # expand variables in $_, but dynamics only, using
1494     # symbolic dereferencing
1495     s/\$(\w+)/${$1}/g;
1496
1497     # Add one to the value of any numbers in the string
1498     s/(\d+)/1 + $1/eg;
1499
1500     # This will expand any embedded scalar variable
1501     # (including lexicals) in $_ : First $1 is interpolated
1502     # to the variable name, and then evaluated
1503     s/(\$\w+)/$1/eeg;
1504
1505     # Delete (most) C comments.
1506     $program =~ s {
1507         /\*     # Match the opening delimiter.
1508         .*?     # Match a minimal number of characters.
1509         \*/     # Match the closing delimiter.
1510     } []gsx;
1511
1512     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_, expensively
1513
1514     for ($variable) {           # trim whitespace in $variable, cheap
1515         s/^\s+//;
1516         s/\s+$//;
1517     }
1518
1519     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1520
1521 Note the use of $ instead of \ in the last example.  Unlike
1522 B<sed>, we use the \<I<digit>> form in only the left hand side.
1523 Anywhere else it's $<I<digit>>.
1524
1525 Occasionally, you can't use just a C</g> to get all the changes
1526 to occur that you might want.  Here are two common cases:
1527
1528     # put commas in the right places in an integer
1529     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;  
1530
1531     # expand tabs to 8-column spacing
1532     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1533
1534 =item tr/SEARCHLIST/REPLACEMENTLIST/cds
1535 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
1536
1537 =item y/SEARCHLIST/REPLACEMENTLIST/cds
1538
1539 Transliterates all occurrences of the characters found in the search list
1540 with the corresponding character in the replacement list.  It returns
1541 the number of characters replaced or deleted.  If no string is
1542 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1543 string specified with =~ must be a scalar variable, an array element, a
1544 hash element, or an assignment to one of those, i.e., an lvalue.)
1545
1546 A character range may be specified with a hyphen, so C<tr/A-J/0-9/> 
1547 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1548 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1549 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1550 its own pair of quotes, which may or may not be bracketing quotes,
1551 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1552
1553 Note that C<tr> does B<not> do regular expression character classes
1554 such as C<\d> or C<[:lower:]>.  The <tr> operator is not equivalent to
1555 the tr(1) utility.  If you want to map strings between lower/upper
1556 cases, see L<perlfunc/lc> and L<perlfunc/uc>, and in general consider
1557 using the C<s> operator if you need regular expressions.
1558
1559 Note also that the whole range idea is rather unportable between
1560 character sets--and even within character sets they may cause results
1561 you probably didn't expect.  A sound principle is to use only ranges
1562 that begin from and end at either alphabets of equal case (a-e, A-E),
1563 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1564 character sets in full.
1565
1566 Options:
1567
1568     c   Complement the SEARCHLIST.
1569     d   Delete found but unreplaced characters.
1570     s   Squash duplicate replaced characters.
1571
1572 If the C</c> modifier is specified, the SEARCHLIST character set
1573 is complemented.  If the C</d> modifier is specified, any characters
1574 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1575 (Note that this is slightly more flexible than the behavior of some
1576 B<tr> programs, which delete anything they find in the SEARCHLIST,
1577 period.) If the C</s> modifier is specified, sequences of characters
1578 that were transliterated to the same character are squashed down
1579 to a single instance of the character.
1580
1581 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1582 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1583 than the SEARCHLIST, the final character is replicated till it is long
1584 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1585 This latter is useful for counting characters in a class or for
1586 squashing character sequences in a class.
1587
1588 Examples:
1589
1590     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1591
1592     $cnt = tr/*/*/;             # count the stars in $_
1593
1594     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1595
1596     $cnt = tr/0-9//;            # count the digits in $_
1597
1598     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1599
1600     ($HOST = $host) =~ tr/a-z/A-Z/;
1601
1602     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1603
1604     tr [\200-\377]
1605        [\000-\177];             # delete 8th bit
1606
1607 If multiple transliterations are given for a character, only the
1608 first one is used:
1609
1610     tr/AAA/XYZ/
1611
1612 will transliterate any A to X.
1613
1614 Because the transliteration table is built at compile time, neither
1615 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1616 interpolation.  That means that if you want to use variables, you
1617 must use an eval():
1618
1619     eval "tr/$oldlist/$newlist/";
1620     die $@ if $@;
1621
1622     eval "tr/$oldlist/$newlist/, 1" or die $@;
1623
1624 =item <<EOF
1625 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
1626
1627 A line-oriented form of quoting is based on the shell "here-document"
1628 syntax.  Following a C<< << >> you specify a string to terminate
1629 the quoted material, and all lines following the current line down to
1630 the terminating string are the value of the item.  The terminating
1631 string may be either an identifier (a word), or some quoted text.  If
1632 quoted, the type of quotes you use determines the treatment of the
1633 text, just as in regular quoting.  An unquoted identifier works like
1634 double quotes.  There must be no space between the C<< << >> and
1635 the identifier, unless the identifier is quoted.  (If you put a space it
1636 will be treated as a null identifier, which is valid, and matches the first
1637 empty line.)  The terminating string must appear by itself (unquoted and
1638 with no surrounding whitespace) on the terminating line.
1639
1640        print <<EOF;
1641     The price is $Price.
1642     EOF
1643
1644        print << "EOF"; # same as above
1645     The price is $Price.
1646     EOF
1647
1648        print << `EOC`; # execute commands
1649     echo hi there
1650     echo lo there
1651     EOC
1652
1653        print <<"foo", <<"bar"; # you can stack them
1654     I said foo.
1655     foo
1656     I said bar.
1657     bar
1658
1659        myfunc(<< "THIS", 23, <<'THAT');
1660     Here's a line
1661     or two.
1662     THIS
1663     and here's another.
1664     THAT
1665
1666 Just don't forget that you have to put a semicolon on the end
1667 to finish the statement, as Perl doesn't know you're not going to
1668 try to do this:
1669
1670        print <<ABC
1671     179231
1672     ABC
1673        + 20;
1674
1675 If you want your here-docs to be indented with the 
1676 rest of the code, you'll need to remove leading whitespace
1677 from each line manually:
1678
1679     ($quote = <<'FINIS') =~ s/^\s+//gm;
1680        The Road goes ever on and on, 
1681        down from the door where it began.
1682     FINIS
1683
1684 If you use a here-doc within a delimited construct, such as in C<s///eg>,
1685 the quoted material must come on the lines following the final delimiter.
1686 So instead of
1687
1688     s/this/<<E . 'that'
1689     the other
1690     E
1691      . 'more '/eg;
1692
1693 you have to write
1694
1695     s/this/<<E . 'that' 
1696      . 'more '/eg; 
1697     the other 
1698     E 
1699
1700 If the terminating identifier is on the last line of the program, you
1701 must be sure there is a newline after it; otherwise, Perl will give the
1702 warning B<Can't find string terminator "END" anywhere before EOF...>.
1703
1704 Additionally, the quoting rules for the identifier are not related to
1705 Perl's quoting rules -- C<q()>, C<qq()>, and the like are not supported
1706 in place of C<''> and C<"">, and the only interpolation is for backslashing
1707 the quoting character:
1708
1709     print << "abc\"def";
1710     testing...
1711     abc"def
1712
1713 Finally, quoted strings cannot span multiple lines.  The general rule is
1714 that the identifier must be a string literal.  Stick with that, and you
1715 should be safe.
1716
1717 =back
1718
1719 =head2 Gory details of parsing quoted constructs
1720 X<quote, gory details>
1721
1722 When presented with something that might have several different
1723 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
1724 principle to pick the most probable interpretation.  This strategy
1725 is so successful that Perl programmers often do not suspect the
1726 ambivalence of what they write.  But from time to time, Perl's
1727 notions differ substantially from what the author honestly meant.
1728
1729 This section hopes to clarify how Perl handles quoted constructs.
1730 Although the most common reason to learn this is to unravel labyrinthine
1731 regular expressions, because the initial steps of parsing are the
1732 same for all quoting operators, they are all discussed together.
1733
1734 The most important Perl parsing rule is the first one discussed
1735 below: when processing a quoted construct, Perl first finds the end
1736 of that construct, then interprets its contents.  If you understand
1737 this rule, you may skip the rest of this section on the first
1738 reading.  The other rules are likely to contradict the user's
1739 expectations much less frequently than this first one.
1740
1741 Some passes discussed below are performed concurrently, but because
1742 their results are the same, we consider them individually.  For different
1743 quoting constructs, Perl performs different numbers of passes, from
1744 one to five, but these passes are always performed in the same order.
1745
1746 =over 4
1747
1748 =item Finding the end
1749
1750 The first pass is finding the end of the quoted construct, whether
1751 it be a multicharacter delimiter C<"\nEOF\n"> in the C<<<EOF>
1752 construct, a C</> that terminates a C<qq//> construct, a C<]> which
1753 terminates C<qq[]> construct, or a C<< > >> which terminates a
1754 fileglob started with C<< < >>.
1755
1756 When searching for single-character non-pairing delimiters, such
1757 as C</>, combinations of C<\\> and C<\/> are skipped.  However,
1758 when searching for single-character pairing delimiter like C<[>,
1759 combinations of C<\\>, C<\]>, and C<\[> are all skipped, and nested
1760 C<[>, C<]> are skipped as well.  When searching for multicharacter
1761 delimiters, nothing is skipped.
1762
1763 For constructs with three-part delimiters (C<s///>, C<y///>, and
1764 C<tr///>), the search is repeated once more.
1765
1766 During this search no attention is paid to the semantics of the construct.
1767 Thus:
1768
1769     "$hash{"$foo/$bar"}"
1770
1771 or:
1772
1773     m/ 
1774       bar       # NOT a comment, this slash / terminated m//!
1775      /x
1776
1777 do not form legal quoted expressions.   The quoted part ends on the
1778 first C<"> and C</>, and the rest happens to be a syntax error.
1779 Because the slash that terminated C<m//> was followed by a C<SPACE>,
1780 the example above is not C<m//x>, but rather C<m//> with no C</x>
1781 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
1782
1783 Also no attention is paid to C<\c\> during this search.
1784 Thus the second C<\> in C<qq/\c\/> is interpreted as a part of C<\/>,
1785 and the following C</> is not recognized as a delimiter.
1786 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
1787
1788 =item Removal of backslashes before delimiters
1789
1790 During the second pass, text between the starting and ending
1791 delimiters is copied to a safe location, and the C<\> is removed
1792 from combinations consisting of C<\> and delimiter--or delimiters,
1793 meaning both starting and ending delimiters will should these differ.
1794 This removal does not happen for multi-character delimiters.
1795 Note that the combination C<\\> is left intact, just as it was.
1796
1797 Starting from this step no information about the delimiters is
1798 used in parsing.
1799
1800 =item Interpolation
1801 X<interpolation>
1802
1803 The next step is interpolation in the text obtained, which is now
1804 delimiter-independent.  There are four different cases.
1805
1806 =over 4
1807
1808 =item C<<<'EOF'>, C<m''>, C<s'''>, C<tr///>, C<y///>
1809
1810 No interpolation is performed.
1811
1812 =item C<''>, C<q//>
1813
1814 The only interpolation is removal of C<\> from pairs C<\\>.
1815
1816 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>
1817
1818 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
1819 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
1820 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
1821 The other combinations are replaced with appropriate expansions.
1822
1823 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
1824 is interpolated in the usual way.  Something like C<"\Q\\E"> has
1825 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
1826 result is the same as for C<"\\\\E">.  As a general rule, backslashes
1827 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
1828 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
1829 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
1830
1831   $str = '\t';
1832   return "\Q$str";
1833
1834 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
1835
1836 Interpolated scalars and arrays are converted internally to the C<join> and
1837 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
1838
1839   $foo . " XXX '" . (join $", @arr) . "'";
1840
1841 All operations above are performed simultaneously, left to right.
1842
1843 Because the result of C<"\Q STRING \E"> has all metacharacters
1844 quoted, there is no way to insert a literal C<$> or C<@> inside a
1845 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
1846 C<"\\\$">; if not, it is interpreted as the start of an interpolated
1847 scalar.
1848
1849 Note also that the interpolation code needs to make a decision on
1850 where the interpolated scalar ends.  For instance, whether 
1851 C<< "a $b -> {c}" >> really means:
1852
1853   "a " . $b . " -> {c}";
1854
1855 or:
1856
1857   "a " . $b -> {c};
1858
1859 Most of the time, the longest possible text that does not include
1860 spaces between components and which contains matching braces or
1861 brackets.  because the outcome may be determined by voting based
1862 on heuristic estimators, the result is not strictly predictable.
1863 Fortunately, it's usually correct for ambiguous cases.
1864
1865 =item C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>, 
1866
1867 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
1868 happens (almost) as with C<qq//> constructs, but the substitution
1869 of C<\> followed by RE-special chars (including C<\>) is not
1870 performed.  Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
1871 a C<#>-comment in a C<//x>-regular expression, no processing is
1872 performed whatsoever.  This is the first step at which the presence
1873 of the C<//x> modifier is relevant.
1874
1875 Interpolation has several quirks: C<$|>, C<$(>, and C<$)> are not
1876 interpolated, and constructs C<$var[SOMETHING]> are voted (by several
1877 different estimators) to be either an array element or C<$var>
1878 followed by an RE alternative.  This is where the notation
1879 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
1880 array element C<-9>, not as a regular expression from the variable
1881 C<$arr> followed by a digit, which would be the interpretation of
1882 C</$arr[0-9]/>.  Since voting among different estimators may occur,
1883 the result is not predictable.
1884
1885 It is at this step that C<\1> is begrudgingly converted to C<$1> in
1886 the replacement text of C<s///> to correct the incorrigible
1887 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
1888 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
1889 (that is, the C<$^W> variable) was set.
1890
1891 The lack of processing of C<\\> creates specific restrictions on
1892 the post-processed text.  If the delimiter is C</>, one cannot get
1893 the combination C<\/> into the result of this step.  C</> will
1894 finish the regular expression, C<\/> will be stripped to C</> on
1895 the previous step, and C<\\/> will be left as is.  Because C</> is
1896 equivalent to C<\/> inside a regular expression, this does not
1897 matter unless the delimiter happens to be character special to the
1898 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
1899 alphanumeric char, as in:
1900
1901   m m ^ a \s* b mmx;
1902
1903 In the RE above, which is intentionally obfuscated for illustration, the
1904 delimiter is C<m>, the modifier is C<mx>, and after backslash-removal the
1905 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one 
1906 reason you're encouraged to restrict your delimiters to non-alphanumeric,
1907 non-whitespace choices.
1908
1909 =back
1910
1911 This step is the last one for all constructs except regular expressions,
1912 which are processed further.
1913
1914 =item Interpolation of regular expressions
1915 X<regexp, interpolation>
1916
1917 Previous steps were performed during the compilation of Perl code,
1918 but this one happens at run time--although it may be optimized to
1919 be calculated at compile time if appropriate.  After preprocessing
1920 described above, and possibly after evaluation if catenation,
1921 joining, casing translation, or metaquoting are involved, the
1922 resulting I<string> is passed to the RE engine for compilation.
1923
1924 Whatever happens in the RE engine might be better discussed in L<perlre>,
1925 but for the sake of continuity, we shall do so here.
1926
1927 This is another step where the presence of the C<//x> modifier is
1928 relevant.  The RE engine scans the string from left to right and
1929 converts it to a finite automaton.
1930
1931 Backslashed characters are either replaced with corresponding
1932 literal strings (as with C<\{>), or else they generate special nodes
1933 in the finite automaton (as with C<\b>).  Characters special to the
1934 RE engine (such as C<|>) generate corresponding nodes or groups of
1935 nodes.  C<(?#...)> comments are ignored.  All the rest is either
1936 converted to literal strings to match, or else is ignored (as is
1937 whitespace and C<#>-style comments if C<//x> is present).
1938
1939 Parsing of the bracketed character class construct, C<[...]>, is
1940 rather different than the rule used for the rest of the pattern.
1941 The terminator of this construct is found using the same rules as
1942 for finding the terminator of a C<{}>-delimited construct, the only
1943 exception being that C<]> immediately following C<[> is treated as
1944 though preceded by a backslash.  Similarly, the terminator of
1945 C<(?{...})> is found using the same rules as for finding the
1946 terminator of a C<{}>-delimited construct.
1947
1948 It is possible to inspect both the string given to RE engine and the
1949 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
1950 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
1951 switch documented in L<perlrun/"Command Switches">.
1952
1953 =item Optimization of regular expressions
1954 X<regexp, optimization>
1955
1956 This step is listed for completeness only.  Since it does not change
1957 semantics, details of this step are not documented and are subject
1958 to change without notice.  This step is performed over the finite
1959 automaton that was generated during the previous pass.
1960
1961 It is at this stage that C<split()> silently optimizes C</^/> to
1962 mean C</^/m>.
1963
1964 =back
1965
1966 =head2 I/O Operators
1967 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
1968 X<< <> >> X<@ARGV>
1969
1970 There are several I/O operators you should know about.
1971
1972 A string enclosed by backticks (grave accents) first undergoes
1973 double-quote interpolation.  It is then interpreted as an external
1974 command, and the output of that command is the value of the
1975 backtick string, like in a shell.  In scalar context, a single string
1976 consisting of all output is returned.  In list context, a list of
1977 values is returned, one per line of output.  (You can set C<$/> to use
1978 a different line terminator.)  The command is executed each time the
1979 pseudo-literal is evaluated.  The status value of the command is
1980 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
1981 Unlike in B<csh>, no translation is done on the return data--newlines
1982 remain newlines.  Unlike in any of the shells, single quotes do not
1983 hide variable names in the command from interpretation.  To pass a
1984 literal dollar-sign through to the shell you need to hide it with a
1985 backslash.  The generalized form of backticks is C<qx//>.  (Because
1986 backticks always undergo shell expansion as well, see L<perlsec> for
1987 security concerns.)
1988 X<qx> X<`> X<``> X<backtick> X<glob>
1989
1990 In scalar context, evaluating a filehandle in angle brackets yields
1991 the next line from that file (the newline, if any, included), or
1992 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
1993 (sometimes known as file-slurp mode) and the file is empty, it
1994 returns C<''> the first time, followed by C<undef> subsequently.
1995
1996 Ordinarily you must assign the returned value to a variable, but
1997 there is one situation where an automatic assignment happens.  If
1998 and only if the input symbol is the only thing inside the conditional
1999 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2000 the value is automatically assigned to the global variable $_,
2001 destroying whatever was there previously.  (This may seem like an
2002 odd thing to you, but you'll use the construct in almost every Perl
2003 script you write.)  The $_ variable is not implicitly localized.
2004 You'll have to put a C<local $_;> before the loop if you want that
2005 to happen.
2006
2007 The following lines are equivalent:
2008
2009     while (defined($_ = <STDIN>)) { print; }
2010     while ($_ = <STDIN>) { print; }
2011     while (<STDIN>) { print; }
2012     for (;<STDIN>;) { print; }
2013     print while defined($_ = <STDIN>);
2014     print while ($_ = <STDIN>);
2015     print while <STDIN>;
2016
2017 This also behaves similarly, but avoids $_ :
2018
2019     while (my $line = <STDIN>) { print $line }    
2020
2021 In these loop constructs, the assigned value (whether assignment
2022 is automatic or explicit) is then tested to see whether it is
2023 defined.  The defined test avoids problems where line has a string
2024 value that would be treated as false by Perl, for example a "" or
2025 a "0" with no trailing newline.  If you really mean for such values
2026 to terminate the loop, they should be tested for explicitly:
2027
2028     while (($_ = <STDIN>) ne '0') { ... }
2029     while (<STDIN>) { last unless $_; ... }
2030
2031 In other boolean contexts, C<< <I<filehandle>> >> without an
2032 explicit C<defined> test or comparison elicit a warning if the 
2033 C<use warnings> pragma or the B<-w>
2034 command-line switch (the C<$^W> variable) is in effect.
2035
2036 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2037 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2038 in packages, where they would be interpreted as local identifiers
2039 rather than global.)  Additional filehandles may be created with
2040 the open() function, amongst others.  See L<perlopentut> and
2041 L<perlfunc/open> for details on this.
2042 X<stdin> X<stdout> X<sterr>
2043
2044 If a <FILEHANDLE> is used in a context that is looking for
2045 a list, a list comprising all input lines is returned, one line per
2046 list element.  It's easy to grow to a rather large data space this
2047 way, so use with care.
2048
2049 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2050 See L<perlfunc/readline>.
2051
2052 The null filehandle <> is special: it can be used to emulate the
2053 behavior of B<sed> and B<awk>.  Input from <> comes either from
2054 standard input, or from each file listed on the command line.  Here's
2055 how it works: the first time <> is evaluated, the @ARGV array is
2056 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2057 gives you standard input.  The @ARGV array is then processed as a list
2058 of filenames.  The loop
2059
2060     while (<>) {
2061         ...                     # code for each line
2062     }
2063
2064 is equivalent to the following Perl-like pseudo code:
2065
2066     unshift(@ARGV, '-') unless @ARGV;
2067     while ($ARGV = shift) {
2068         open(ARGV, $ARGV);
2069         while (<ARGV>) {
2070             ...         # code for each line
2071         }
2072     }
2073
2074 except that it isn't so cumbersome to say, and will actually work.
2075 It really does shift the @ARGV array and put the current filename
2076 into the $ARGV variable.  It also uses filehandle I<ARGV>
2077 internally--<> is just a synonym for <ARGV>, which
2078 is magical.  (The pseudo code above doesn't work because it treats
2079 <ARGV> as non-magical.)
2080
2081 You can modify @ARGV before the first <> as long as the array ends up
2082 containing the list of filenames you really want.  Line numbers (C<$.>)
2083 continue as though the input were one big happy file.  See the example
2084 in L<perlfunc/eof> for how to reset line numbers on each file.
2085
2086 If you want to set @ARGV to your own list of files, go right ahead.  
2087 This sets @ARGV to all plain text files if no @ARGV was given:
2088
2089     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2090
2091 You can even set them to pipe commands.  For example, this automatically
2092 filters compressed arguments through B<gzip>:
2093
2094     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2095
2096 If you want to pass switches into your script, you can use one of the
2097 Getopts modules or put a loop on the front like this:
2098
2099     while ($_ = $ARGV[0], /^-/) {
2100         shift;
2101         last if /^--$/;
2102         if (/^-D(.*)/) { $debug = $1 }
2103         if (/^-v/)     { $verbose++  }
2104         # ...           # other switches
2105     }
2106
2107     while (<>) {
2108         # ...           # code for each line
2109     }
2110
2111 The <> symbol will return C<undef> for end-of-file only once.  
2112 If you call it again after this, it will assume you are processing another 
2113 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
2114
2115 If what the angle brackets contain is a simple scalar variable (e.g.,
2116 <$foo>), then that variable contains the name of the
2117 filehandle to input from, or its typeglob, or a reference to the
2118 same.  For example:
2119
2120     $fh = \*STDIN;
2121     $line = <$fh>;
2122
2123 If what's within the angle brackets is neither a filehandle nor a simple
2124 scalar variable containing a filehandle name, typeglob, or typeglob
2125 reference, it is interpreted as a filename pattern to be globbed, and
2126 either a list of filenames or the next filename in the list is returned,
2127 depending on context.  This distinction is determined on syntactic
2128 grounds alone.  That means C<< <$x> >> is always a readline() from
2129 an indirect handle, but C<< <$hash{key}> >> is always a glob().
2130 That's because $x is a simple scalar variable, but C<$hash{key}> is
2131 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
2132 is treated as C<glob("$x ")>, not C<readline($x)>.
2133
2134 One level of double-quote interpretation is done first, but you can't
2135 say C<< <$foo> >> because that's an indirect filehandle as explained
2136 in the previous paragraph.  (In older versions of Perl, programmers
2137 would insert curly brackets to force interpretation as a filename glob:
2138 C<< <${foo}> >>.  These days, it's considered cleaner to call the
2139 internal function directly as C<glob($foo)>, which is probably the right
2140 way to have done it in the first place.)  For example:
2141
2142     while (<*.c>) {
2143         chmod 0644, $_;
2144     }
2145
2146 is roughly equivalent to:
2147
2148     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
2149     while (<FOO>) {
2150         chomp;
2151         chmod 0644, $_;
2152     }
2153
2154 except that the globbing is actually done internally using the standard
2155 C<File::Glob> extension.  Of course, the shortest way to do the above is:
2156
2157     chmod 0644, <*.c>;
2158
2159 A (file)glob evaluates its (embedded) argument only when it is
2160 starting a new list.  All values must be read before it will start
2161 over.  In list context, this isn't important because you automatically
2162 get them all anyway.  However, in scalar context the operator returns
2163 the next value each time it's called, or C<undef> when the list has
2164 run out.  As with filehandle reads, an automatic C<defined> is
2165 generated when the glob occurs in the test part of a C<while>,
2166 because legal glob returns (e.g. a file called F<0>) would otherwise
2167 terminate the loop.  Again, C<undef> is returned only once.  So if
2168 you're expecting a single value from a glob, it is much better to
2169 say
2170
2171     ($file) = <blurch*>;
2172
2173 than
2174
2175     $file = <blurch*>;
2176
2177 because the latter will alternate between returning a filename and
2178 returning false.
2179
2180 If you're trying to do variable interpolation, it's definitely better
2181 to use the glob() function, because the older notation can cause people
2182 to become confused with the indirect filehandle notation.
2183
2184     @files = glob("$dir/*.[ch]");
2185     @files = glob($files[$i]);
2186
2187 =head2 Constant Folding
2188 X<constant folding> X<folding>
2189
2190 Like C, Perl does a certain amount of expression evaluation at
2191 compile time whenever it determines that all arguments to an
2192 operator are static and have no side effects.  In particular, string
2193 concatenation happens at compile time between literals that don't do
2194 variable substitution.  Backslash interpolation also happens at
2195 compile time.  You can say
2196
2197     'Now is the time for all' . "\n" .
2198         'good men to come to.'
2199
2200 and this all reduces to one string internally.  Likewise, if
2201 you say
2202
2203     foreach $file (@filenames) {
2204         if (-s $file > 5 + 100 * 2**16) {  }
2205     }
2206
2207 the compiler will precompute the number which that expression
2208 represents so that the interpreter won't have to.
2209
2210 =head2 No-ops
2211 X<no-op> X<nop>
2212
2213 Perl doesn't officially have a no-op operator, but the bare constants
2214 C<0> and C<1> are special-cased to not produce a warning in a void
2215 context, so you can for example safely do
2216
2217     1 while foo();
2218
2219 =head2 Bitwise String Operators
2220 X<operator, bitwise, string>
2221
2222 Bitstrings of any size may be manipulated by the bitwise operators
2223 (C<~ | & ^>).
2224
2225 If the operands to a binary bitwise op are strings of different
2226 sizes, B<|> and B<^> ops act as though the shorter operand had
2227 additional zero bits on the right, while the B<&> op acts as though
2228 the longer operand were truncated to the length of the shorter.
2229 The granularity for such extension or truncation is one or more
2230 bytes.
2231
2232     # ASCII-based examples 
2233     print "j p \n" ^ " a h";            # prints "JAPH\n"
2234     print "JA" | "  ph\n";              # prints "japh\n"
2235     print "japh\nJunk" & '_____';       # prints "JAPH\n";
2236     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
2237
2238 If you are intending to manipulate bitstrings, be certain that
2239 you're supplying bitstrings: If an operand is a number, that will imply
2240 a B<numeric> bitwise operation.  You may explicitly show which type of
2241 operation you intend by using C<""> or C<0+>, as in the examples below.
2242
2243     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
2244     $foo = '150' |  105;        # yields 255
2245     $foo =  150  | '105';       # yields 255
2246     $foo = '150' | '105';       # yields string '155' (under ASCII)
2247
2248     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
2249     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
2250
2251 See L<perlfunc/vec> for information on how to manipulate individual bits
2252 in a bit vector.
2253
2254 =head2 Integer Arithmetic
2255 X<integer>
2256
2257 By default, Perl assumes that it must do most of its arithmetic in
2258 floating point.  But by saying
2259
2260     use integer;
2261
2262 you may tell the compiler that it's okay to use integer operations
2263 (if it feels like it) from here to the end of the enclosing BLOCK.
2264 An inner BLOCK may countermand this by saying
2265
2266     no integer;
2267
2268 which lasts until the end of that BLOCK.  Note that this doesn't
2269 mean everything is only an integer, merely that Perl may use integer
2270 operations if it is so inclined.  For example, even under C<use
2271 integer>, if you take the C<sqrt(2)>, you'll still get C<1.4142135623731>
2272 or so.
2273
2274 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
2275 and ">>") always produce integral results.  (But see also 
2276 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
2277 them.  By default, their results are interpreted as unsigned integers, but
2278 if C<use integer> is in effect, their results are interpreted
2279 as signed integers.  For example, C<~0> usually evaluates to a large
2280 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
2281 machines.
2282
2283 =head2 Floating-point Arithmetic
2284 X<floating-point> X<floating point> X<float> X<real>
2285
2286 While C<use integer> provides integer-only arithmetic, there is no
2287 analogous mechanism to provide automatic rounding or truncation to a
2288 certain number of decimal places.  For rounding to a certain number
2289 of digits, sprintf() or printf() is usually the easiest route.
2290 See L<perlfaq4>.
2291
2292 Floating-point numbers are only approximations to what a mathematician
2293 would call real numbers.  There are infinitely more reals than floats,
2294 so some corners must be cut.  For example:
2295
2296     printf "%.20g\n", 123456789123456789;
2297     #        produces 123456789123456784
2298
2299 Testing for exact equality of floating-point equality or inequality is
2300 not a good idea.  Here's a (relatively expensive) work-around to compare
2301 whether two floating-point numbers are equal to a particular number of
2302 decimal places.  See Knuth, volume II, for a more robust treatment of
2303 this topic.
2304
2305     sub fp_equal {
2306         my ($X, $Y, $POINTS) = @_;
2307         my ($tX, $tY);
2308         $tX = sprintf("%.${POINTS}g", $X);
2309         $tY = sprintf("%.${POINTS}g", $Y);
2310         return $tX eq $tY;
2311     }
2312
2313 The POSIX module (part of the standard perl distribution) implements
2314 ceil(), floor(), and other mathematical and trigonometric functions.
2315 The Math::Complex module (part of the standard perl distribution)
2316 defines mathematical functions that work on both the reals and the
2317 imaginary numbers.  Math::Complex not as efficient as POSIX, but
2318 POSIX can't work with complex numbers.
2319
2320 Rounding in financial applications can have serious implications, and
2321 the rounding method used should be specified precisely.  In these
2322 cases, it probably pays not to trust whichever system rounding is
2323 being used by Perl, but to instead implement the rounding function you
2324 need yourself.
2325
2326 =head2 Bigger Numbers
2327 X<number, arbitrary precision>
2328
2329 The standard Math::BigInt and Math::BigFloat modules provide
2330 variable-precision arithmetic and overloaded operators, although
2331 they're currently pretty slow. At the cost of some space and
2332 considerable speed, they avoid the normal pitfalls associated with
2333 limited-precision representations.
2334
2335     use Math::BigInt;
2336     $x = Math::BigInt->new('123456789123456789');
2337     print $x * $x;
2338
2339     # prints +15241578780673678515622620750190521
2340
2341 There are several modules that let you calculate with (bound only by
2342 memory and cpu-time) unlimited or fixed precision. There are also
2343 some non-standard modules that provide faster implementations via
2344 external C libraries.
2345
2346 Here is a short, but incomplete summary:
2347
2348         Math::Fraction          big, unlimited fractions like 9973 / 12967
2349         Math::String            treat string sequences like numbers
2350         Math::FixedPrecision    calculate with a fixed precision
2351         Math::Currency          for currency calculations
2352         Bit::Vector             manipulate bit vectors fast (uses C)
2353         Math::BigIntFast        Bit::Vector wrapper for big numbers
2354         Math::Pari              provides access to the Pari C library
2355         Math::BigInteger        uses an external C library
2356         Math::Cephes            uses external Cephes C library (no big numbers)
2357         Math::Cephes::Fraction  fractions via the Cephes library
2358         Math::GMP               another one using an external C library
2359
2360 Choose wisely.
2361
2362 =cut