This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Document that there are bugs with EBCDIC and regexes
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  See below.
83
84 The C</x> modifier itself needs a little more explanation.  It tells
85 the regular expression parser to ignore most whitespace that is neither
86 backslashed nor within a character class.  You can use this to break up
87 your regular expression into (slightly) more readable parts.  The C<#>
88 character is also treated as a metacharacter introducing a comment,
89 just as in ordinary Perl code.  This also means that if you want real
90 whitespace or C<#> characters in the pattern (outside a character
91 class, where they are unaffected by C</x>), then you'll either have to
92 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
93 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
94 making Perl's regular expressions more readable.  Note that you have to
95 be careful not to include the pattern delimiter in the comment--perl has
96 no way of knowing you did not intend to close the pattern early.  See
97 the C-comment deletion code in L<perlop>.  Also note that anything inside
98 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
99 whether space interpretation within a single multi-character construct.  For
100 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
101 spaces.  Same for a L<quantifier|Quantifiers> such as C<{3}> or
102 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
103 but can between the C<(> and C<?>.  Within any delimiters for such a
104 construct, allowed spaces are not affected by C</x>, and depend on the
105 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
106 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
107 in C<\p{...}>  there can be spaces that follow the Unicode rules, for which see
108 L<perluniprops.pod/Properties accessible through \p{} and \P{}>.
109 X</x>
110
111 =head2 Regular Expressions
112
113 =head3 Metacharacters
114
115 The patterns used in Perl pattern matching evolved from those supplied in
116 the Version 8 regex routines.  (The routines are derived
117 (distantly) from Henry Spencer's freely redistributable reimplementation
118 of the V8 routines.)  See L<Version 8 Regular Expressions> for
119 details.
120
121 In particular the following metacharacters have their standard I<egrep>-ish
122 meanings:
123 X<metacharacter>
124 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
125
126
127     \   Quote the next metacharacter
128     ^   Match the beginning of the line
129     .   Match any character (except newline)
130     $   Match the end of the line (or before newline at the end)
131     |   Alternation
132     ()  Grouping
133     []  Character class
134
135 By default, the "^" character is guaranteed to match only the
136 beginning of the string, the "$" character only the end (or before the
137 newline at the end), and Perl does certain optimizations with the
138 assumption that the string contains only one line.  Embedded newlines
139 will not be matched by "^" or "$".  You may, however, wish to treat a
140 string as a multi-line buffer, such that the "^" will match after any
141 newline within the string (except if the newline is the last character in
142 the string), and "$" will match before any newline.  At the
143 cost of a little more overhead, you can do this by using the /m modifier
144 on the pattern match operator.  (Older programs did this by setting C<$*>,
145 but this practice has been removed in perl 5.9.)
146 X<^> X<$> X</m>
147
148 To simplify multi-line substitutions, the "." character never matches a
149 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
150 the string is a single line--even if it isn't.
151 X<.> X</s>
152
153 =head3 Quantifiers
154
155 The following standard quantifiers are recognized:
156 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
157
158     *      Match 0 or more times
159     +      Match 1 or more times
160     ?      Match 1 or 0 times
161     {n}    Match exactly n times
162     {n,}   Match at least n times
163     {n,m}  Match at least n but not more than m times
164
165 (If a curly bracket occurs in any other context, it is treated
166 as a regular character.  In particular, the lower bound
167 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
168 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
169 to integral values less than a preset limit defined when perl is built.
170 This is usually 32766 on the most common platforms.  The actual limit can
171 be seen in the error message generated by code such as this:
172
173     $_ **= $_ , / {$_} / for 2 .. 42;
174
175 By default, a quantified subpattern is "greedy", that is, it will match as
176 many times as possible (given a particular starting location) while still
177 allowing the rest of the pattern to match.  If you want it to match the
178 minimum number of times possible, follow the quantifier with a "?".  Note
179 that the meanings don't change, just the "greediness":
180 X<metacharacter> X<greedy> X<greediness>
181 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
182
183     *?     Match 0 or more times, not greedily
184     +?     Match 1 or more times, not greedily
185     ??     Match 0 or 1 time, not greedily
186     {n}?   Match exactly n times, not greedily
187     {n,}?  Match at least n times, not greedily
188     {n,m}? Match at least n but not more than m times, not greedily
189
190 By default, when a quantified subpattern does not allow the rest of the
191 overall pattern to match, Perl will backtrack. However, this behaviour is
192 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
193 as well.
194
195     *+     Match 0 or more times and give nothing back
196     ++     Match 1 or more times and give nothing back
197     ?+     Match 0 or 1 time and give nothing back
198     {n}+   Match exactly n times and give nothing back (redundant)
199     {n,}+  Match at least n times and give nothing back
200     {n,m}+ Match at least n but not more than m times and give nothing back
201
202 For instance,
203
204    'aaaa' =~ /a++a/
205
206 will never match, as the C<a++> will gobble up all the C<a>'s in the
207 string and won't leave any for the remaining part of the pattern. This
208 feature can be extremely useful to give perl hints about where it
209 shouldn't backtrack. For instance, the typical "match a double-quoted
210 string" problem can be most efficiently performed when written as:
211
212    /"(?:[^"\\]++|\\.)*+"/
213
214 as we know that if the final quote does not match, backtracking will not
215 help. See the independent subexpression C<< (?>...) >> for more details;
216 possessive quantifiers are just syntactic sugar for that construct. For
217 instance the above example could also be written as follows:
218
219    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
220
221 =head3 Escape sequences
222
223 Because patterns are processed as double quoted strings, the following
224 also work:
225 X<\t> X<\n> X<\r> X<\f> X<\e> X<\a> X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
226 X<\0> X<\c> X<\N> X<\x>
227
228     \t          tab                   (HT, TAB)
229     \n          newline               (LF, NL)
230     \r          return                (CR)
231     \f          form feed             (FF)
232     \a          alarm (bell)          (BEL)
233     \e          escape (think troff)  (ESC)
234     \033        octal char            (example: ESC)
235     \x1B        hex char              (example: ESC)
236     \x{263a}    long hex char         (example: Unicode SMILEY)
237     \cK         control char          (example: VT)
238     \N{name}    named Unicode character
239     \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
240     \l          lowercase next char (think vi)
241     \u          uppercase next char (think vi)
242     \L          lowercase till \E (think vi)
243     \U          uppercase till \E (think vi)
244     \E          end case modification (think vi)
245     \Q          quote (disable) pattern metacharacters till \E
246
247 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
248 and C<\U> is taken from the current locale.  See L<perllocale>.  For
249 documentation of C<\N{name}>, see L<charnames>.
250
251 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
252 An unescaped C<$> or C<@> interpolates the corresponding variable,
253 while escaping will cause the literal string C<\$> to be matched.
254 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
255
256 =head3 Character Classes and other Special Escapes
257
258 In addition, Perl defines the following:
259 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\X> X<\p> X<\P> X<\C>
260 X<\g> X<\k> X<\N> X<\K> X<\v> X<\V> X<\h> X<\H>
261 X<word> X<whitespace> X<character class> X<backreference>
262
263     \w       Match a "word" character (alphanumeric plus "_")
264     \W       Match a non-"word" character
265     \s       Match a whitespace character
266     \S       Match a non-whitespace character
267     \d       Match a digit character
268     \D       Match a non-digit character
269     \pP      Match P, named property.  Use \p{Prop} for longer names.
270     \PP      Match non-P
271     \X       Match Unicode "eXtended grapheme cluster"
272     \C       Match a single C char (octet) even under Unicode.
273              NOTE: breaks up characters into their UTF-8 bytes,
274              so you may end up with malformed pieces of UTF-8.
275              Unsupported in lookbehind.
276     \1       Backreference to a specific group.
277              '1' may actually be any positive integer.
278     \g1      Backreference to a specific or previous group,
279     \g{-1}   number may be negative indicating a previous buffer and may
280              optionally be wrapped in curly brackets for safer parsing.
281     \g{name} Named backreference
282     \k<name> Named backreference
283     \K       Keep the stuff left of the \K, don't include it in $&
284     \N       Any character but \n (experimental)
285     \v       Vertical whitespace
286     \V       Not vertical whitespace
287     \h       Horizontal whitespace
288     \H       Not horizontal whitespace
289     \R       Linebreak
290
291 A C<\w> matches a single alphanumeric character (an alphabetic
292 character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
293 to match a string of Perl-identifier characters (which isn't the same
294 as matching an English word).  If C<use locale> is in effect, the list
295 of alphabetic characters generated by C<\w> is taken from the current
296 locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
297 C<\d>, and C<\D> within character classes, but they aren't usable
298 as either end of a range. If any of them precedes or follows a "-",
299 the "-" is understood literally. If Unicode is in effect, C<\s> matches
300 also "\x{85}", "\x{2028}", and "\x{2029}". See L<perlunicode> for more
301 details about C<\pP>, C<\PP>, C<\X> and the possibility of defining
302 your own C<\p> and C<\P> properties, and L<perluniintro> about Unicode
303 in general.
304 X<\w> X<\W> X<word>
305
306 C<\R> will atomically match a linebreak, including the network line-ending
307 "\x0D\x0A".  Specifically, X<\R> is exactly equivalent to
308
309   (?>\x0D\x0A?|[\x0A-\x0C\x85\x{2028}\x{2029}])
310
311 B<Note:> C<\R> has no special meaning inside of a character class;
312 use C<\v> instead (vertical whitespace).
313 X<\R>
314
315 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
316 character whose name is C<NAME>; and similarly when of the form
317 C<\N{U+I<wide hex char>}>, it matches the character whose Unicode ordinal is
318 I<wide hex char>.  Otherwise it matches any character but C<\n>.
319
320 The POSIX character class syntax
321 X<character class>
322
323     [:class:]
324
325 is also available.  Note that the C<[> and C<]> brackets are I<literal>;
326 they must always be used within a character class expression.
327
328     # this is correct:
329     $string =~ /[[:alpha:]]/;
330
331     # this is not, and will generate a warning:
332     $string =~ /[:alpha:]/;
333
334 The following table shows the mapping of POSIX character class
335 names, common escapes, literal escape sequences and their equivalent
336 Unicode style property names.
337 X<character class> X<\p> X<\p{}>
338 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
339 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
340
341 B<Note:> up to Perl 5.10 the property names used were shared with
342 standard Unicode properties, this was changed in Perl 5.11, see
343 L<perl5110delta> for details.
344
345     POSIX  Esc  Class               Property            Note
346     --------------------------------------------------------
347     alnum       [0-9A-Za-z]         IsPosixAlnum
348     alpha       [A-Za-z]            IsPosixAlpha
349     ascii       [\000-\177]         IsASCII
350     blank       [\011 ]             IsPosixBlank        [1]
351     cntrl       [\0-\37\177]        IsPosixCntrl
352     digit   \d  [0-9]               IsPosixDigit
353     graph       [!-~]               IsPosixGraph
354     lower       [a-z]               IsPosixLower
355     print       [ -~]               IsPosixPrint
356     punct       [!-/:-@[-`{-~]      IsPosixPunct
357     space       [\11-\15 ]          IsPosixSpace        [2]
358             \s  [\11\12\14\15 ]     IsPerlSpace         [2]
359     upper       [A-Z]               IsPosixUpper
360     word    \w  [0-9A-Z_a-z]        IsPerlWord          [3]
361     xdigit      [0-9A-Fa-f]         IsXDigit
362
363 =over
364
365 =item [1]
366
367 A GNU extension equivalent to C<[ \t]>, "all horizontal whitespace".
368
369 =item [2]
370
371 Note that C<\s> and C<[[:space:]]> are B<not> equivalent as C<[[:space:]]>
372 includes also the (very rare) "vertical tabulator", "\cK" or chr(11) in
373 ASCII.
374
375 =item [3]
376
377 A Perl extension, see above.
378
379 =back
380
381 For example use C<[:upper:]> to match all the uppercase characters.
382 Note that the C<[]> are part of the C<[::]> construct, not part of the
383 whole character class.  For example:
384
385     [01[:alpha:]%]
386
387 matches zero, one, any alphabetic character, and the percent sign.
388
389 The other named classes are:
390
391 =over 4
392
393 =item cntrl
394 X<cntrl>
395
396 Any control character.  Usually characters that don't produce output as
397 such but instead control the terminal somehow: for example newline and
398 backspace are control characters.  All characters with ord() less than
399 32 are usually classified as control characters (assuming ASCII,
400 the ISO Latin character sets, and Unicode), as is the character with
401 the ord() value of 127 (C<DEL>).
402
403 =item graph
404 X<graph>
405
406 Any alphanumeric or punctuation (special) character.
407
408 =item print
409 X<print>
410
411 Any alphanumeric or punctuation (special) character or the space character.
412
413 =item punct
414 X<punct>
415
416 Any punctuation (special) character.
417
418 =item xdigit
419 X<xdigit>
420
421 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
422 work just fine) it is included for completeness.
423
424 =back
425
426 You can negate the [::] character classes by prefixing the class name
427 with a '^'. This is a Perl extension.  For example:
428 X<character class, negation>
429
430     POSIX         traditional  Unicode
431
432     [[:^digit:]]    \D         \P{IsPosixDigit}
433     [[:^space:]]    \S         \P{IsPosixSpace}
434     [[:^word:]]     \W         \P{IsPerlWord}
435
436 Perl respects the POSIX standard in that POSIX character classes are
437 only supported within a character class.  The POSIX character classes
438 [.cc.] and [=cc=] are recognized but B<not> supported and trying to
439 use them will cause an error.
440
441 =head3 Assertions
442
443 Perl defines the following zero-width assertions:
444 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
445 X<regexp, zero-width assertion>
446 X<regular expression, zero-width assertion>
447 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
448
449     \b  Match a word boundary
450     \B  Match except at a word boundary
451     \A  Match only at beginning of string
452     \Z  Match only at end of string, or before newline at the end
453     \z  Match only at end of string
454     \G  Match only at pos() (e.g. at the end-of-match position
455         of prior m//g)
456
457 A word boundary (C<\b>) is a spot between two characters
458 that has a C<\w> on one side of it and a C<\W> on the other side
459 of it (in either order), counting the imaginary characters off the
460 beginning and end of the string as matching a C<\W>.  (Within
461 character classes C<\b> represents backspace rather than a word
462 boundary, just as it normally does in any double-quoted string.)
463 The C<\A> and C<\Z> are just like "^" and "$", except that they
464 won't match multiple times when the C</m> modifier is used, while
465 "^" and "$" will match at every internal line boundary.  To match
466 the actual end of the string and not ignore an optional trailing
467 newline, use C<\z>.
468 X<\b> X<\A> X<\Z> X<\z> X</m>
469
470 The C<\G> assertion can be used to chain global matches (using
471 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
472 It is also useful when writing C<lex>-like scanners, when you have
473 several patterns that you want to match against consequent substrings
474 of your string, see the previous reference.  The actual location
475 where C<\G> will match can also be influenced by using C<pos()> as
476 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
477 matches is modified somewhat, in that contents to the left of C<\G> is
478 not counted when determining the length of the match. Thus the following
479 will not match forever:
480 X<\G>
481
482     $str = 'ABC';
483     pos($str) = 1;
484     while (/.\G/g) {
485         print $&;
486     }
487
488 It will print 'A' and then terminate, as it considers the match to
489 be zero-width, and thus will not match at the same position twice in a
490 row.
491
492 It is worth noting that C<\G> improperly used can result in an infinite
493 loop. Take care when using patterns that include C<\G> in an alternation.
494
495 =head3 Capture buffers
496
497 The bracketing construct C<( ... )> creates capture buffers. To refer
498 to the current contents of a buffer later on, within the same pattern,
499 use \1 for the first, \2 for the second, and so on.
500 Outside the match use "$" instead of "\".  (The
501 \<digit> notation works in certain circumstances outside
502 the match.  See the warning below about \1 vs $1 for details.)
503 Referring back to another part of the match is called a
504 I<backreference>.
505 X<regex, capture buffer> X<regexp, capture buffer>
506 X<regular expression, capture buffer> X<backreference>
507
508 There is no limit to the number of captured substrings that you may
509 use.  However Perl also uses \10, \11, etc. as aliases for \010,
510 \011, etc.  (Recall that 0 means octal, so \011 is the character at
511 number 9 in your coded character set; which would be the 10th character,
512 a horizontal tab under ASCII.)  Perl resolves this
513 ambiguity by interpreting \10 as a backreference only if at least 10
514 left parentheses have opened before it.  Likewise \11 is a
515 backreference only if at least 11 left parentheses have opened
516 before it.  And so on.  \1 through \9 are always interpreted as
517 backreferences.
518 If the bracketing group did not match, the associated backreference won't
519 match either. (This can happen if the bracketing group is optional, or
520 in a different branch of an alternation.)
521
522 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
523 In order to provide a safer and easier way to construct patterns using
524 backreferences, Perl provides the C<\g{N}> notation (starting with perl
525 5.10.0). The curly brackets are optional, however omitting them is less
526 safe as the meaning of the pattern can be changed by text (such as digits)
527 following it. When N is a positive integer the C<\g{N}> notation is
528 exactly equivalent to using normal backreferences. When N is a negative
529 integer then it is a relative backreference referring to the previous N'th
530 capturing group. When the bracket form is used and N is not an integer, it
531 is treated as a reference to a named buffer.
532
533 Thus C<\g{-1}> refers to the last buffer, C<\g{-2}> refers to the
534 buffer before that. For example:
535
536         /
537          (Y)            # buffer 1
538          (              # buffer 2
539             (X)         # buffer 3
540             \g{-1}      # backref to buffer 3
541             \g{-3}      # backref to buffer 1
542          )
543         /x
544
545 and would match the same as C</(Y) ( (X) \3 \1 )/x>.
546
547 Additionally, as of Perl 5.10.0 you may use named capture buffers and named
548 backreferences. The notation is C<< (?<name>...) >> to declare and C<< \k<name> >>
549 to reference. You may also use apostrophes instead of angle brackets to delimit the
550 name; and you may use the bracketed C<< \g{name} >> backreference syntax.
551 It's possible to refer to a named capture buffer by absolute and relative number as well.
552 Outside the pattern, a named capture buffer is available via the C<%+> hash.
553 When different buffers within the same pattern have the same name, C<$+{name}>
554 and C<< \k<name> >> refer to the leftmost defined group. (Thus it's possible
555 to do things with named capture buffers that would otherwise require C<(??{})>
556 code to accomplish.)
557 X<named capture buffer> X<regular expression, named capture buffer>
558 X<%+> X<$+{name}> X<< \k<name> >>
559
560 Examples:
561
562     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
563
564     /(.)\1/                         # find first doubled char
565          and print "'$1' is the first doubled character\n";
566
567     /(?<char>.)\k<char>/            # ... a different way
568          and print "'$+{char}' is the first doubled character\n";
569
570     /(?'char'.)\1/                  # ... mix and match
571          and print "'$1' is the first doubled character\n";
572
573     if (/Time: (..):(..):(..)/) {   # parse out values
574         $hours = $1;
575         $minutes = $2;
576         $seconds = $3;
577     }
578
579 Several special variables also refer back to portions of the previous
580 match.  C<$+> returns whatever the last bracket match matched.
581 C<$&> returns the entire matched string.  (At one point C<$0> did
582 also, but now it returns the name of the program.)  C<$`> returns
583 everything before the matched string.  C<$'> returns everything
584 after the matched string. And C<$^N> contains whatever was matched by
585 the most-recently closed group (submatch). C<$^N> can be used in
586 extended patterns (see below), for example to assign a submatch to a
587 variable.
588 X<$+> X<$^N> X<$&> X<$`> X<$'>
589
590 The numbered match variables ($1, $2, $3, etc.) and the related punctuation
591 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
592 until the end of the enclosing block or until the next successful
593 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
594 X<$+> X<$^N> X<$&> X<$`> X<$'>
595 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
596
597
598 B<NOTE>: Failed matches in Perl do not reset the match variables,
599 which makes it easier to write code that tests for a series of more
600 specific cases and remembers the best match.
601
602 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
603 C<$'> anywhere in the program, it has to provide them for every
604 pattern match.  This may substantially slow your program.  Perl
605 uses the same mechanism to produce $1, $2, etc, so you also pay a
606 price for each pattern that contains capturing parentheses.  (To
607 avoid this cost while retaining the grouping behaviour, use the
608 extended regular expression C<(?: ... )> instead.)  But if you never
609 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
610 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
611 if you can, but if you can't (and some algorithms really appreciate
612 them), once you've used them once, use them at will, because you've
613 already paid the price.  As of 5.005, C<$&> is not so costly as the
614 other two.
615 X<$&> X<$`> X<$'>
616
617 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
618 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
619 and C<$'>, B<except> that they are only guaranteed to be defined after a
620 successful match that was executed with the C</p> (preserve) modifier.
621 The use of these variables incurs no global performance penalty, unlike
622 their punctuation char equivalents, however at the trade-off that you
623 have to tell perl when you want to use them.
624 X</p> X<p modifier>
625
626 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
627 C<\w>, C<\n>.  Unlike some other regular expression languages, there
628 are no backslashed symbols that aren't alphanumeric.  So anything
629 that looks like \\, \(, \), \<, \>, \{, or \} is always
630 interpreted as a literal character, not a metacharacter.  This was
631 once used in a common idiom to disable or quote the special meanings
632 of regular expression metacharacters in a string that you want to
633 use for a pattern. Simply quote all non-"word" characters:
634
635     $pattern =~ s/(\W)/\\$1/g;
636
637 (If C<use locale> is set, then this depends on the current locale.)
638 Today it is more common to use the quotemeta() function or the C<\Q>
639 metaquoting escape sequence to disable all metacharacters' special
640 meanings like this:
641
642     /$unquoted\Q$quoted\E$unquoted/
643
644 Beware that if you put literal backslashes (those not inside
645 interpolated variables) between C<\Q> and C<\E>, double-quotish
646 backslash interpolation may lead to confusing results.  If you
647 I<need> to use literal backslashes within C<\Q...\E>,
648 consult L<perlop/"Gory details of parsing quoted constructs">.
649
650 =head2 Extended Patterns
651
652 Perl also defines a consistent extension syntax for features not
653 found in standard tools like B<awk> and B<lex>.  The syntax is a
654 pair of parentheses with a question mark as the first thing within
655 the parentheses.  The character after the question mark indicates
656 the extension.
657
658 The stability of these extensions varies widely.  Some have been
659 part of the core language for many years.  Others are experimental
660 and may change without warning or be completely removed.  Check
661 the documentation on an individual feature to verify its current
662 status.
663
664 A question mark was chosen for this and for the minimal-matching
665 construct because 1) question marks are rare in older regular
666 expressions, and 2) whenever you see one, you should stop and
667 "question" exactly what is going on.  That's psychology...
668
669 =over 10
670
671 =item C<(?#text)>
672 X<(?#)>
673
674 A comment.  The text is ignored.  If the C</x> modifier enables
675 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
676 the comment as soon as it sees a C<)>, so there is no way to put a literal
677 C<)> in the comment.
678
679 =item C<(?pimsx-imsx)>
680 X<(?)>
681
682 One or more embedded pattern-match modifiers, to be turned on (or
683 turned off, if preceded by C<->) for the remainder of the pattern or
684 the remainder of the enclosing pattern group (if any). This is
685 particularly useful for dynamic patterns, such as those read in from a
686 configuration file, taken from an argument, or specified in a table
687 somewhere.  Consider the case where some patterns want to be case
688 sensitive and some do not:  The case insensitive ones merely need to
689 include C<(?i)> at the front of the pattern.  For example:
690
691     $pattern = "foobar";
692     if ( /$pattern/i ) { }
693
694     # more flexible:
695
696     $pattern = "(?i)foobar";
697     if ( /$pattern/ ) { }
698
699 These modifiers are restored at the end of the enclosing group. For example,
700
701     ( (?i) blah ) \s+ \1
702
703 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
704 repetition of the previous word, assuming the C</x> modifier, and no C</i>
705 modifier outside this group.
706
707 These modifiers do not carry over into named subpatterns called in the
708 enclosing group. In other words, a pattern such as C<((?i)(&NAME))> does not
709 change the case-sensitivity of the "NAME" pattern.
710
711 Note that the C<p> modifier is special in that it can only be enabled,
712 not disabled, and that its presence anywhere in a pattern has a global
713 effect. Thus C<(?-p)> and C<(?-p:...)> are meaningless and will warn
714 when executed under C<use warnings>.
715
716 =item C<(?:pattern)>
717 X<(?:)>
718
719 =item C<(?imsx-imsx:pattern)>
720
721 This is for clustering, not capturing; it groups subexpressions like
722 "()", but doesn't make backreferences as "()" does.  So
723
724     @fields = split(/\b(?:a|b|c)\b/)
725
726 is like
727
728     @fields = split(/\b(a|b|c)\b/)
729
730 but doesn't spit out extra fields.  It's also cheaper not to capture
731 characters if you don't need to.
732
733 Any letters between C<?> and C<:> act as flags modifiers as with
734 C<(?imsx-imsx)>.  For example,
735
736     /(?s-i:more.*than).*million/i
737
738 is equivalent to the more verbose
739
740     /(?:(?s-i)more.*than).*million/i
741
742 =item C<(?|pattern)>
743 X<(?|)> X<Branch reset>
744
745 This is the "branch reset" pattern, which has the special property
746 that the capture buffers are numbered from the same starting point
747 in each alternation branch. It is available starting from perl 5.10.0.
748
749 Capture buffers are numbered from left to right, but inside this
750 construct the numbering is restarted for each branch.
751
752 The numbering within each branch will be as normal, and any buffers
753 following this construct will be numbered as though the construct
754 contained only one branch, that being the one with the most capture
755 buffers in it.
756
757 This construct will be useful when you want to capture one of a
758 number of alternative matches.
759
760 Consider the following pattern.  The numbers underneath show in
761 which buffer the captured content will be stored.
762
763
764     # before  ---------------branch-reset----------- after        
765     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
766     # 1            2         2  3        2     3     4  
767
768 Be careful when using the branch reset pattern in combination with 
769 named captures. Named captures are implemented as being aliases to 
770 numbered buffers holding the captures, and that interferes with the
771 implementation of the branch reset pattern. If you are using named
772 captures in a branch reset pattern, it's best to use the same names,
773 in the same order, in each of the alternations:
774
775    /(?|  (?<a> x ) (?<b> y )
776       |  (?<a> z ) (?<b> w )) /x
777
778 Not doing so may lead to surprises:
779
780   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
781   say $+ {a};   # Prints '12'
782   say $+ {b};   # *Also* prints '12'.
783
784 The problem here is that both the buffer named C<< a >> and the buffer
785 named C<< b >> are aliases for the buffer belonging to C<< $1 >>.
786
787 =item Look-Around Assertions
788 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
789
790 Look-around assertions are zero width patterns which match a specific
791 pattern without including it in C<$&>. Positive assertions match when
792 their subpattern matches, negative assertions match when their subpattern
793 fails. Look-behind matches text up to the current match position,
794 look-ahead matches text following the current match position.
795
796 =over 4
797
798 =item C<(?=pattern)>
799 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
800
801 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
802 matches a word followed by a tab, without including the tab in C<$&>.
803
804 =item C<(?!pattern)>
805 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
806
807 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
808 matches any occurrence of "foo" that isn't followed by "bar".  Note
809 however that look-ahead and look-behind are NOT the same thing.  You cannot
810 use this for look-behind.
811
812 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
813 will not do what you want.  That's because the C<(?!foo)> is just saying that
814 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
815 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
816 say "like" because there's the case of your "bar" not having three characters
817 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
818 Sometimes it's still easier just to say:
819
820     if (/bar/ && $` !~ /foo$/)
821
822 For look-behind see below.
823
824 =item C<(?<=pattern)> C<\K>
825 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
826
827 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
828 matches a word that follows a tab, without including the tab in C<$&>.
829 Works only for fixed-width look-behind.
830
831 There is a special form of this construct, called C<\K>, which causes the
832 regex engine to "keep" everything it had matched prior to the C<\K> and
833 not include it in C<$&>. This effectively provides variable length
834 look-behind. The use of C<\K> inside of another look-around assertion
835 is allowed, but the behaviour is currently not well defined.
836
837 For various reasons C<\K> may be significantly more efficient than the
838 equivalent C<< (?<=...) >> construct, and it is especially useful in
839 situations where you want to efficiently remove something following
840 something else in a string. For instance
841
842   s/(foo)bar/$1/g;
843
844 can be rewritten as the much more efficient
845
846   s/foo\Kbar//g;
847
848 =item C<(?<!pattern)>
849 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
850
851 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
852 matches any occurrence of "foo" that does not follow "bar".  Works
853 only for fixed-width look-behind.
854
855 =back
856
857 =item C<(?'NAME'pattern)>
858
859 =item C<< (?<NAME>pattern) >>
860 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
861
862 A named capture buffer. Identical in every respect to normal capturing
863 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
864 used after a successful match to refer to a named buffer. See C<perlvar>
865 for more details on the C<%+> and C<%-> hashes.
866
867 If multiple distinct capture buffers have the same name then the
868 $+{NAME} will refer to the leftmost defined buffer in the match.
869
870 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
871
872 B<NOTE:> While the notation of this construct is the same as the similar
873 function in .NET regexes, the behavior is not. In Perl the buffers are
874 numbered sequentially regardless of being named or not. Thus in the
875 pattern
876
877   /(x)(?<foo>y)(z)/
878
879 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
880 the opposite which is what a .NET regex hacker might expect.
881
882 Currently NAME is restricted to simple identifiers only.
883 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
884 its Unicode extension (see L<utf8>),
885 though it isn't extended by the locale (see L<perllocale>).
886
887 B<NOTE:> In order to make things easier for programmers with experience
888 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
889 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
890 support the use of single quotes as a delimiter for the name.
891
892 =item C<< \k<NAME> >>
893
894 =item C<< \k'NAME' >>
895
896 Named backreference. Similar to numeric backreferences, except that
897 the group is designated by name and not number. If multiple groups
898 have the same name then it refers to the leftmost defined group in
899 the current match.
900
901 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
902 earlier in the pattern.
903
904 Both forms are equivalent.
905
906 B<NOTE:> In order to make things easier for programmers with experience
907 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
908 may be used instead of C<< \k<NAME> >>.
909
910 =item C<(?{ code })>
911 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
912
913 B<WARNING>: This extended regular expression feature is considered
914 experimental, and may be changed without notice. Code executed that
915 has side effects may not perform identically from version to version
916 due to the effect of future optimisations in the regex engine.
917
918 This zero-width assertion evaluates any embedded Perl code.  It
919 always succeeds, and its C<code> is not interpolated.  Currently,
920 the rules to determine where the C<code> ends are somewhat convoluted.
921
922 This feature can be used together with the special variable C<$^N> to
923 capture the results of submatches in variables without having to keep
924 track of the number of nested parentheses. For example:
925
926   $_ = "The brown fox jumps over the lazy dog";
927   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
928   print "color = $color, animal = $animal\n";
929
930 Inside the C<(?{...})> block, C<$_> refers to the string the regular
931 expression is matching against. You can also use C<pos()> to know what is
932 the current position of matching within this string.
933
934 The C<code> is properly scoped in the following sense: If the assertion
935 is backtracked (compare L<"Backtracking">), all changes introduced after
936 C<local>ization are undone, so that
937
938   $_ = 'a' x 8;
939   m<
940      (?{ $cnt = 0 })                    # Initialize $cnt.
941      (
942        a
943        (?{
944            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
945        })
946      )*
947      aaaa
948      (?{ $res = $cnt })                 # On success copy to non-localized
949                                         # location.
950    >x;
951
952 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
953 introduced value, because the scopes that restrict C<local> operators
954 are unwound.
955
956 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
957 switch.  If I<not> used in this way, the result of evaluation of
958 C<code> is put into the special variable C<$^R>.  This happens
959 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
960 inside the same regular expression.
961
962 The assignment to C<$^R> above is properly localized, so the old
963 value of C<$^R> is restored if the assertion is backtracked; compare
964 L<"Backtracking">.
965
966 For reasons of security, this construct is forbidden if the regular
967 expression involves run-time interpolation of variables, unless the
968 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
969 variables contain results of C<qr//> operator (see
970 L<perlop/"qr/STRING/imosx">).
971
972 This restriction is due to the wide-spread and remarkably convenient
973 custom of using run-time determined strings as patterns.  For example:
974
975     $re = <>;
976     chomp $re;
977     $string =~ /$re/;
978
979 Before Perl knew how to execute interpolated code within a pattern,
980 this operation was completely safe from a security point of view,
981 although it could raise an exception from an illegal pattern.  If
982 you turn on the C<use re 'eval'>, though, it is no longer secure,
983 so you should only do so if you are also using taint checking.
984 Better yet, use the carefully constrained evaluation within a Safe
985 compartment.  See L<perlsec> for details about both these mechanisms.
986
987 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
988 broken. The result is unpredictable and will make perl unstable. The
989 workaround is to use global (C<our>) variables.
990
991 B<WARNING>: Because Perl's regex engine is currently not re-entrant,
992 interpolated code may not invoke the regex engine either directly with
993 C<m//> or C<s///>), or indirectly with functions such as
994 C<split>. Invoking the regex engine in these blocks will make perl
995 unstable.
996
997 =item C<(??{ code })>
998 X<(??{})>
999 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1000
1001 B<WARNING>: This extended regular expression feature is considered
1002 experimental, and may be changed without notice. Code executed that
1003 has side effects may not perform identically from version to version
1004 due to the effect of future optimisations in the regex engine.
1005
1006 This is a "postponed" regular subexpression.  The C<code> is evaluated
1007 at run time, at the moment this subexpression may match.  The result
1008 of evaluation is considered as a regular expression and matched as
1009 if it were inserted instead of this construct.  Note that this means
1010 that the contents of capture buffers defined inside an eval'ed pattern
1011 are not available outside of the pattern, and vice versa, there is no
1012 way for the inner pattern to refer to a capture buffer defined outside.
1013 Thus,
1014
1015     ('a' x 100)=~/(??{'(.)' x 100})/
1016
1017 B<will> match, it will B<not> set $1.
1018
1019 The C<code> is not interpolated.  As before, the rules to determine
1020 where the C<code> ends are currently somewhat convoluted.
1021
1022 The following pattern matches a parenthesized group:
1023
1024   $re = qr{
1025              \(
1026              (?:
1027                 (?> [^()]+ )    # Non-parens without backtracking
1028               |
1029                 (??{ $re })     # Group with matching parens
1030              )*
1031              \)
1032           }x;
1033
1034 See also C<(?PARNO)> for a different, more efficient way to accomplish
1035 the same task.
1036
1037 For reasons of security, this construct is forbidden if the regular
1038 expression involves run-time interpolation of variables, unless the
1039 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1040 variables contain results of C<qr//> operator (see
1041 L<perlop/"qr/STRING/imosx">).
1042
1043 Because perl's regex engine is not currently re-entrant, delayed
1044 code may not invoke the regex engine either directly with C<m//> or C<s///>),
1045 or indirectly with functions such as C<split>.
1046
1047 Recursing deeper than 50 times without consuming any input string will
1048 result in a fatal error.  The maximum depth is compiled into perl, so
1049 changing it requires a custom build.
1050
1051 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1052 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1053 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1054 X<regex, relative recursion>
1055
1056 Similar to C<(??{ code })> except it does not involve compiling any code,
1057 instead it treats the contents of a capture buffer as an independent
1058 pattern that must match at the current position.  Capture buffers
1059 contained by the pattern will have the value as determined by the
1060 outermost recursion.
1061
1062 PARNO is a sequence of digits (not starting with 0) whose value reflects
1063 the paren-number of the capture buffer to recurse to. C<(?R)> recurses to
1064 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1065 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1066 to be relative, with negative numbers indicating preceding capture buffers
1067 and positive ones following. Thus C<(?-1)> refers to the most recently
1068 declared buffer, and C<(?+1)> indicates the next buffer to be declared.
1069 Note that the counting for relative recursion differs from that of
1070 relative backreferences, in that with recursion unclosed buffers B<are>
1071 included.
1072
1073 The following pattern matches a function foo() which may contain
1074 balanced parentheses as the argument.
1075
1076   $re = qr{ (                    # paren group 1 (full function)
1077               foo
1078               (                  # paren group 2 (parens)
1079                 \(
1080                   (              # paren group 3 (contents of parens)
1081                   (?:
1082                    (?> [^()]+ )  # Non-parens without backtracking
1083                   |
1084                    (?2)          # Recurse to start of paren group 2
1085                   )*
1086                   )
1087                 \)
1088               )
1089             )
1090           }x;
1091
1092 If the pattern was used as follows
1093
1094     'foo(bar(baz)+baz(bop))'=~/$re/
1095         and print "\$1 = $1\n",
1096                   "\$2 = $2\n",
1097                   "\$3 = $3\n";
1098
1099 the output produced should be the following:
1100
1101     $1 = foo(bar(baz)+baz(bop))
1102     $2 = (bar(baz)+baz(bop))
1103     $3 = bar(baz)+baz(bop)
1104
1105 If there is no corresponding capture buffer defined, then it is a
1106 fatal error.  Recursing deeper than 50 times without consuming any input
1107 string will also result in a fatal error.  The maximum depth is compiled
1108 into perl, so changing it requires a custom build.
1109
1110 The following shows how using negative indexing can make it
1111 easier to embed recursive patterns inside of a C<qr//> construct
1112 for later use:
1113
1114     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1115     if (/foo $parens \s+ + \s+ bar $parens/x) {
1116        # do something here...
1117     }
1118
1119 B<Note> that this pattern does not behave the same way as the equivalent
1120 PCRE or Python construct of the same form. In Perl you can backtrack into
1121 a recursed group, in PCRE and Python the recursed into group is treated
1122 as atomic. Also, modifiers are resolved at compile time, so constructs
1123 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1124 be processed.
1125
1126 =item C<(?&NAME)>
1127 X<(?&NAME)>
1128
1129 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1130 parenthesis to recurse to is determined by name. If multiple parentheses have
1131 the same name, then it recurses to the leftmost.
1132
1133 It is an error to refer to a name that is not declared somewhere in the
1134 pattern.
1135
1136 B<NOTE:> In order to make things easier for programmers with experience
1137 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1138 may be used instead of C<< (?&NAME) >>.
1139
1140 =item C<(?(condition)yes-pattern|no-pattern)>
1141 X<(?()>
1142
1143 =item C<(?(condition)yes-pattern)>
1144
1145 Conditional expression.  C<(condition)> should be either an integer in
1146 parentheses (which is valid if the corresponding pair of parentheses
1147 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1148 name in angle brackets or single quotes (which is valid if a buffer
1149 with the given name matched), or the special symbol (R) (true when
1150 evaluated inside of recursion or eval). Additionally the R may be
1151 followed by a number, (which will be true when evaluated when recursing
1152 inside of the appropriate group), or by C<&NAME>, in which case it will
1153 be true only when evaluated during recursion in the named group.
1154
1155 Here's a summary of the possible predicates:
1156
1157 =over 4
1158
1159 =item (1) (2) ...
1160
1161 Checks if the numbered capturing buffer has matched something.
1162
1163 =item (<NAME>) ('NAME')
1164
1165 Checks if a buffer with the given name has matched something.
1166
1167 =item (?{ CODE })
1168
1169 Treats the code block as the condition.
1170
1171 =item (R)
1172
1173 Checks if the expression has been evaluated inside of recursion.
1174
1175 =item (R1) (R2) ...
1176
1177 Checks if the expression has been evaluated while executing directly
1178 inside of the n-th capture group. This check is the regex equivalent of
1179
1180   if ((caller(0))[3] eq 'subname') { ... }
1181
1182 In other words, it does not check the full recursion stack.
1183
1184 =item (R&NAME)
1185
1186 Similar to C<(R1)>, this predicate checks to see if we're executing
1187 directly inside of the leftmost group with a given name (this is the same
1188 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1189 stack, but only the name of the innermost active recursion.
1190
1191 =item (DEFINE)
1192
1193 In this case, the yes-pattern is never directly executed, and no
1194 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1195 See below for details.
1196
1197 =back
1198
1199 For example:
1200
1201     m{ ( \( )?
1202        [^()]+
1203        (?(1) \) )
1204      }x
1205
1206 matches a chunk of non-parentheses, possibly included in parentheses
1207 themselves.
1208
1209 A special form is the C<(DEFINE)> predicate, which never executes directly
1210 its yes-pattern, and does not allow a no-pattern. This allows to define
1211 subpatterns which will be executed only by using the recursion mechanism.
1212 This way, you can define a set of regular expression rules that can be
1213 bundled into any pattern you choose.
1214
1215 It is recommended that for this usage you put the DEFINE block at the
1216 end of the pattern, and that you name any subpatterns defined within it.
1217
1218 Also, it's worth noting that patterns defined this way probably will
1219 not be as efficient, as the optimiser is not very clever about
1220 handling them.
1221
1222 An example of how this might be used is as follows:
1223
1224   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1225    (?(DEFINE)
1226      (?<NAME_PAT>....)
1227      (?<ADRESS_PAT>....)
1228    )/x
1229
1230 Note that capture buffers matched inside of recursion are not accessible
1231 after the recursion returns, so the extra layer of capturing buffers is
1232 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1233 C<$+{NAME}> would be.
1234
1235 =item C<< (?>pattern) >>
1236 X<backtrack> X<backtracking> X<atomic> X<possessive>
1237
1238 An "independent" subexpression, one which matches the substring
1239 that a I<standalone> C<pattern> would match if anchored at the given
1240 position, and it matches I<nothing other than this substring>.  This
1241 construct is useful for optimizations of what would otherwise be
1242 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1243 It may also be useful in places where the "grab all you can, and do not
1244 give anything back" semantic is desirable.
1245
1246 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1247 (anchored at the beginning of string, as above) will match I<all>
1248 characters C<a> at the beginning of string, leaving no C<a> for
1249 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1250 since the match of the subgroup C<a*> is influenced by the following
1251 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1252 C<a*ab> will match fewer characters than a standalone C<a*>, since
1253 this makes the tail match.
1254
1255 An effect similar to C<< (?>pattern) >> may be achieved by writing
1256 C<(?=(pattern))\1>.  This matches the same substring as a standalone
1257 C<a+>, and the following C<\1> eats the matched string; it therefore
1258 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1259 (The difference between these two constructs is that the second one
1260 uses a capturing group, thus shifting ordinals of backreferences
1261 in the rest of a regular expression.)
1262
1263 Consider this pattern:
1264
1265     m{ \(
1266           (
1267             [^()]+              # x+
1268           |
1269             \( [^()]* \)
1270           )+
1271        \)
1272      }x
1273
1274 That will efficiently match a nonempty group with matching parentheses
1275 two levels deep or less.  However, if there is no such group, it
1276 will take virtually forever on a long string.  That's because there
1277 are so many different ways to split a long string into several
1278 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1279 to a subpattern of the above pattern.  Consider how the pattern
1280 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1281 seconds, but that each extra letter doubles this time.  This
1282 exponential performance will make it appear that your program has
1283 hung.  However, a tiny change to this pattern
1284
1285     m{ \(
1286           (
1287             (?> [^()]+ )        # change x+ above to (?> x+ )
1288           |
1289             \( [^()]* \)
1290           )+
1291        \)
1292      }x
1293
1294 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1295 this yourself would be a productive exercise), but finishes in a fourth
1296 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1297 however, that this pattern currently triggers a warning message under
1298 the C<use warnings> pragma or B<-w> switch saying it
1299 C<"matches null string many times in regex">.
1300
1301 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1302 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1303 This was only 4 times slower on a string with 1000000 C<a>s.
1304
1305 The "grab all you can, and do not give anything back" semantic is desirable
1306 in many situations where on the first sight a simple C<()*> looks like
1307 the correct solution.  Suppose we parse text with comments being delimited
1308 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1309 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1310 the comment delimiter, because it may "give up" some whitespace if
1311 the remainder of the pattern can be made to match that way.  The correct
1312 answer is either one of these:
1313
1314     (?>#[ \t]*)
1315     #[ \t]*(?![ \t])
1316
1317 For example, to grab non-empty comments into $1, one should use either
1318 one of these:
1319
1320     / (?> \# [ \t]* ) (        .+ ) /x;
1321     /     \# [ \t]*   ( [^ \t] .* ) /x;
1322
1323 Which one you pick depends on which of these expressions better reflects
1324 the above specification of comments.
1325
1326 In some literature this construct is called "atomic matching" or
1327 "possessive matching".
1328
1329 Possessive quantifiers are equivalent to putting the item they are applied
1330 to inside of one of these constructs. The following equivalences apply:
1331
1332     Quantifier Form     Bracketing Form
1333     ---------------     ---------------
1334     PAT*+               (?>PAT*)
1335     PAT++               (?>PAT+)
1336     PAT?+               (?>PAT?)
1337     PAT{min,max}+       (?>PAT{min,max})
1338
1339 =back
1340
1341 =head2 Special Backtracking Control Verbs
1342
1343 B<WARNING:> These patterns are experimental and subject to change or
1344 removal in a future version of Perl. Their usage in production code should
1345 be noted to avoid problems during upgrades.
1346
1347 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1348 otherwise stated the ARG argument is optional; in some cases, it is
1349 forbidden.
1350
1351 Any pattern containing a special backtracking verb that allows an argument
1352 has the special behaviour that when executed it sets the current package's
1353 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1354 rules apply:
1355
1356 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1357 verb pattern, if the verb was involved in the failure of the match. If the
1358 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1359 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1360 none. Also, the C<$REGMARK> variable will be set to FALSE.
1361
1362 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1363 the C<$REGMARK> variable will be set to the name of the last
1364 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1365 C<(*MARK:NAME)> verb below for more details.
1366
1367 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1368 and most other regex related variables. They are not local to a scope, nor
1369 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1370 Use C<local> to localize changes to them to a specific scope if necessary.
1371
1372 If a pattern does not contain a special backtracking verb that allows an
1373 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1374
1375 =over 4
1376
1377 =item Verbs that take an argument
1378
1379 =over 4
1380
1381 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1382 X<(*PRUNE)> X<(*PRUNE:NAME)>
1383
1384 This zero-width pattern prunes the backtracking tree at the current point
1385 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1386 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1387 A may backtrack as necessary to match. Once it is reached, matching
1388 continues in B, which may also backtrack as necessary; however, should B
1389 not match, then no further backtracking will take place, and the pattern
1390 will fail outright at the current starting position.
1391
1392 The following example counts all the possible matching strings in a
1393 pattern (without actually matching any of them).
1394
1395     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1396     print "Count=$count\n";
1397
1398 which produces:
1399
1400     aaab
1401     aaa
1402     aa
1403     a
1404     aab
1405     aa
1406     a
1407     ab
1408     a
1409     Count=9
1410
1411 If we add a C<(*PRUNE)> before the count like the following
1412
1413     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1414     print "Count=$count\n";
1415
1416 we prevent backtracking and find the count of the longest matching
1417 at each matching starting point like so:
1418
1419     aaab
1420     aab
1421     ab
1422     Count=3
1423
1424 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1425
1426 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1427 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1428 replaced with a C<< (?>pattern) >> with no functional difference; however,
1429 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1430 C<< (?>pattern) >> alone.
1431
1432
1433 =item C<(*SKIP)> C<(*SKIP:NAME)>
1434 X<(*SKIP)>
1435
1436 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1437 failure it also signifies that whatever text that was matched leading up
1438 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1439 of this pattern. This effectively means that the regex engine "skips" forward
1440 to this position on failure and tries to match again, (assuming that
1441 there is sufficient room to match).
1442
1443 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1444 C<(*MARK:NAME)> was encountered while matching, then it is that position
1445 which is used as the "skip point". If no C<(*MARK)> of that name was
1446 encountered, then the C<(*SKIP)> operator has no effect. When used
1447 without a name the "skip point" is where the match point was when
1448 executing the (*SKIP) pattern.
1449
1450 Compare the following to the examples in C<(*PRUNE)>, note the string
1451 is twice as long:
1452
1453     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1454     print "Count=$count\n";
1455
1456 outputs
1457
1458     aaab
1459     aaab
1460     Count=2
1461
1462 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1463 executed, the next starting point will be where the cursor was when the
1464 C<(*SKIP)> was executed.
1465
1466 =item C<(*MARK:NAME)> C<(*:NAME)>
1467 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1468
1469 This zero-width pattern can be used to mark the point reached in a string
1470 when a certain part of the pattern has been successfully matched. This
1471 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1472 forward to that point if backtracked into on failure. Any number of
1473 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1474
1475 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1476 can be used to "label" a pattern branch, so that after matching, the
1477 program can determine which branches of the pattern were involved in the
1478 match.
1479
1480 When a match is successful, the C<$REGMARK> variable will be set to the
1481 name of the most recently executed C<(*MARK:NAME)> that was involved
1482 in the match.
1483
1484 This can be used to determine which branch of a pattern was matched
1485 without using a separate capture buffer for each branch, which in turn
1486 can result in a performance improvement, as perl cannot optimize
1487 C</(?:(x)|(y)|(z))/> as efficiently as something like
1488 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1489
1490 When a match has failed, and unless another verb has been involved in
1491 failing the match and has provided its own name to use, the C<$REGERROR>
1492 variable will be set to the name of the most recently executed
1493 C<(*MARK:NAME)>.
1494
1495 See C<(*SKIP)> for more details.
1496
1497 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1498
1499 =item C<(*THEN)> C<(*THEN:NAME)>
1500
1501 This is similar to the "cut group" operator C<::> from Perl 6. Like
1502 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1503 failure, it causes the regex engine to try the next alternation in the
1504 innermost enclosing group (capturing or otherwise).
1505
1506 Its name comes from the observation that this operation combined with the
1507 alternation operator (C<|>) can be used to create what is essentially a
1508 pattern-based if/then/else block:
1509
1510   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1511
1512 Note that if this operator is used and NOT inside of an alternation then
1513 it acts exactly like the C<(*PRUNE)> operator.
1514
1515   / A (*PRUNE) B /
1516
1517 is the same as
1518
1519   / A (*THEN) B /
1520
1521 but
1522
1523   / ( A (*THEN) B | C (*THEN) D ) /
1524
1525 is not the same as
1526
1527   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1528
1529 as after matching the A but failing on the B the C<(*THEN)> verb will
1530 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1531
1532 =item C<(*COMMIT)>
1533 X<(*COMMIT)>
1534
1535 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1536 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1537 into on failure it causes the match to fail outright. No further attempts
1538 to find a valid match by advancing the start pointer will occur again.
1539 For example,
1540
1541     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1542     print "Count=$count\n";
1543
1544 outputs
1545
1546     aaab
1547     Count=1
1548
1549 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1550 does not match, the regex engine will not try any further matching on the
1551 rest of the string.
1552
1553 =back
1554
1555 =item Verbs without an argument
1556
1557 =over 4
1558
1559 =item C<(*FAIL)> C<(*F)>
1560 X<(*FAIL)> X<(*F)>
1561
1562 This pattern matches nothing and always fails. It can be used to force the
1563 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1564 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1565
1566 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1567
1568 =item C<(*ACCEPT)>
1569 X<(*ACCEPT)>
1570
1571 B<WARNING:> This feature is highly experimental. It is not recommended
1572 for production code.
1573
1574 This pattern matches nothing and causes the end of successful matching at
1575 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1576 whether there is actually more to match in the string. When inside of a
1577 nested pattern, such as recursion, or in a subpattern dynamically generated
1578 via C<(??{})>, only the innermost pattern is ended immediately.
1579
1580 If the C<(*ACCEPT)> is inside of capturing buffers then the buffers are
1581 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1582 For instance:
1583
1584   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1585
1586 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1587 be set. If another branch in the inner parentheses were matched, such as in the
1588 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1589
1590 =back
1591
1592 =back
1593
1594 =head2 Backtracking
1595 X<backtrack> X<backtracking>
1596
1597 NOTE: This section presents an abstract approximation of regular
1598 expression behavior.  For a more rigorous (and complicated) view of
1599 the rules involved in selecting a match among possible alternatives,
1600 see L<Combining RE Pieces>.
1601
1602 A fundamental feature of regular expression matching involves the
1603 notion called I<backtracking>, which is currently used (when needed)
1604 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1605 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1606 internally, but the general principle outlined here is valid.
1607
1608 For a regular expression to match, the I<entire> regular expression must
1609 match, not just part of it.  So if the beginning of a pattern containing a
1610 quantifier succeeds in a way that causes later parts in the pattern to
1611 fail, the matching engine backs up and recalculates the beginning
1612 part--that's why it's called backtracking.
1613
1614 Here is an example of backtracking:  Let's say you want to find the
1615 word following "foo" in the string "Food is on the foo table.":
1616
1617     $_ = "Food is on the foo table.";
1618     if ( /\b(foo)\s+(\w+)/i ) {
1619         print "$2 follows $1.\n";
1620     }
1621
1622 When the match runs, the first part of the regular expression (C<\b(foo)>)
1623 finds a possible match right at the beginning of the string, and loads up
1624 $1 with "Foo".  However, as soon as the matching engine sees that there's
1625 no whitespace following the "Foo" that it had saved in $1, it realizes its
1626 mistake and starts over again one character after where it had the
1627 tentative match.  This time it goes all the way until the next occurrence
1628 of "foo". The complete regular expression matches this time, and you get
1629 the expected output of "table follows foo."
1630
1631 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1632 everything between "foo" and "bar".  Initially, you write something
1633 like this:
1634
1635     $_ =  "The food is under the bar in the barn.";
1636     if ( /foo(.*)bar/ ) {
1637         print "got <$1>\n";
1638     }
1639
1640 Which perhaps unexpectedly yields:
1641
1642   got <d is under the bar in the >
1643
1644 That's because C<.*> was greedy, so you get everything between the
1645 I<first> "foo" and the I<last> "bar".  Here it's more effective
1646 to use minimal matching to make sure you get the text between a "foo"
1647 and the first "bar" thereafter.
1648
1649     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1650   got <d is under the >
1651
1652 Here's another example. Let's say you'd like to match a number at the end
1653 of a string, and you also want to keep the preceding part of the match.
1654 So you write this:
1655
1656     $_ = "I have 2 numbers: 53147";
1657     if ( /(.*)(\d*)/ ) {                                # Wrong!
1658         print "Beginning is <$1>, number is <$2>.\n";
1659     }
1660
1661 That won't work at all, because C<.*> was greedy and gobbled up the
1662 whole string. As C<\d*> can match on an empty string the complete
1663 regular expression matched successfully.
1664
1665     Beginning is <I have 2 numbers: 53147>, number is <>.
1666
1667 Here are some variants, most of which don't work:
1668
1669     $_ = "I have 2 numbers: 53147";
1670     @pats = qw{
1671         (.*)(\d*)
1672         (.*)(\d+)
1673         (.*?)(\d*)
1674         (.*?)(\d+)
1675         (.*)(\d+)$
1676         (.*?)(\d+)$
1677         (.*)\b(\d+)$
1678         (.*\D)(\d+)$
1679     };
1680
1681     for $pat (@pats) {
1682         printf "%-12s ", $pat;
1683         if ( /$pat/ ) {
1684             print "<$1> <$2>\n";
1685         } else {
1686             print "FAIL\n";
1687         }
1688     }
1689
1690 That will print out:
1691
1692     (.*)(\d*)    <I have 2 numbers: 53147> <>
1693     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1694     (.*?)(\d*)   <> <>
1695     (.*?)(\d+)   <I have > <2>
1696     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1697     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1698     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1699     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1700
1701 As you see, this can be a bit tricky.  It's important to realize that a
1702 regular expression is merely a set of assertions that gives a definition
1703 of success.  There may be 0, 1, or several different ways that the
1704 definition might succeed against a particular string.  And if there are
1705 multiple ways it might succeed, you need to understand backtracking to
1706 know which variety of success you will achieve.
1707
1708 When using look-ahead assertions and negations, this can all get even
1709 trickier.  Imagine you'd like to find a sequence of non-digits not
1710 followed by "123".  You might try to write that as
1711
1712     $_ = "ABC123";
1713     if ( /^\D*(?!123)/ ) {              # Wrong!
1714         print "Yup, no 123 in $_\n";
1715     }
1716
1717 But that isn't going to match; at least, not the way you're hoping.  It
1718 claims that there is no 123 in the string.  Here's a clearer picture of
1719 why that pattern matches, contrary to popular expectations:
1720
1721     $x = 'ABC123';
1722     $y = 'ABC445';
1723
1724     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1725     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1726
1727     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1728     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1729
1730 This prints
1731
1732     2: got ABC
1733     3: got AB
1734     4: got ABC
1735
1736 You might have expected test 3 to fail because it seems to a more
1737 general purpose version of test 1.  The important difference between
1738 them is that test 3 contains a quantifier (C<\D*>) and so can use
1739 backtracking, whereas test 1 will not.  What's happening is
1740 that you've asked "Is it true that at the start of $x, following 0 or more
1741 non-digits, you have something that's not 123?"  If the pattern matcher had
1742 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1743 fail.
1744
1745 The search engine will initially match C<\D*> with "ABC".  Then it will
1746 try to match C<(?!123> with "123", which fails.  But because
1747 a quantifier (C<\D*>) has been used in the regular expression, the
1748 search engine can backtrack and retry the match differently
1749 in the hope of matching the complete regular expression.
1750
1751 The pattern really, I<really> wants to succeed, so it uses the
1752 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1753 time.  Now there's indeed something following "AB" that is not
1754 "123".  It's "C123", which suffices.
1755
1756 We can deal with this by using both an assertion and a negation.
1757 We'll say that the first part in $1 must be followed both by a digit
1758 and by something that's not "123".  Remember that the look-aheads
1759 are zero-width expressions--they only look, but don't consume any
1760 of the string in their match.  So rewriting this way produces what
1761 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1762
1763     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1764     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1765
1766     6: got ABC
1767
1768 In other words, the two zero-width assertions next to each other work as though
1769 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1770 matches only if you're at the beginning of the line AND the end of the
1771 line simultaneously.  The deeper underlying truth is that juxtaposition in
1772 regular expressions always means AND, except when you write an explicit OR
1773 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1774 although the attempted matches are made at different positions because "a"
1775 is not a zero-width assertion, but a one-width assertion.
1776
1777 B<WARNING>: Particularly complicated regular expressions can take
1778 exponential time to solve because of the immense number of possible
1779 ways they can use backtracking to try for a match.  For example, without
1780 internal optimizations done by the regular expression engine, this will
1781 take a painfully long time to run:
1782
1783     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1784
1785 And if you used C<*>'s in the internal groups instead of limiting them
1786 to 0 through 5 matches, then it would take forever--or until you ran
1787 out of stack space.  Moreover, these internal optimizations are not
1788 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1789 on the external group, no current optimization is applicable, and the
1790 match takes a long time to finish.
1791
1792 A powerful tool for optimizing such beasts is what is known as an
1793 "independent group",
1794 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1795 zero-length look-ahead/look-behind assertions will not backtrack to make
1796 the tail match, since they are in "logical" context: only
1797 whether they match is considered relevant.  For an example
1798 where side-effects of look-ahead I<might> have influenced the
1799 following match, see L<C<< (?>pattern) >>>.
1800
1801 =head2 Version 8 Regular Expressions
1802 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1803
1804 In case you're not familiar with the "regular" Version 8 regex
1805 routines, here are the pattern-matching rules not described above.
1806
1807 Any single character matches itself, unless it is a I<metacharacter>
1808 with a special meaning described here or above.  You can cause
1809 characters that normally function as metacharacters to be interpreted
1810 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1811 character; "\\" matches a "\"). This escape mechanism is also required
1812 for the character used as the pattern delimiter.
1813
1814 A series of characters matches that series of characters in the target
1815 string, so the pattern  C<blurfl> would match "blurfl" in the target
1816 string.
1817
1818 You can specify a character class, by enclosing a list of characters
1819 in C<[]>, which will match any character from the list.  If the
1820 first character after the "[" is "^", the class matches any character not
1821 in the list.  Within a list, the "-" character specifies a
1822 range, so that C<a-z> represents all characters between "a" and "z",
1823 inclusive.  If you want either "-" or "]" itself to be a member of a
1824 class, put it at the start of the list (possibly after a "^"), or
1825 escape it with a backslash.  "-" is also taken literally when it is
1826 at the end of the list, just before the closing "]".  (The
1827 following all specify the same class of three characters: C<[-az]>,
1828 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1829 specifies a class containing twenty-six characters, even on EBCDIC-based
1830 character sets.)  Also, if you try to use the character
1831 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1832 a range, the "-" is understood literally.
1833
1834 Note also that the whole range idea is rather unportable between
1835 character sets--and even within character sets they may cause results
1836 you probably didn't expect.  A sound principle is to use only ranges
1837 that begin from and end at either alphabetics of equal case ([a-e],
1838 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1839 spell out the character sets in full.
1840
1841 Characters may be specified using a metacharacter syntax much like that
1842 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1843 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1844 of octal digits, matches the character whose coded character set value
1845 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1846 matches the character whose numeric value is I<nn>. The expression \cI<x>
1847 matches the character control-I<x>.  Finally, the "." metacharacter
1848 matches any character except "\n" (unless you use C</s>).
1849
1850 You can specify a series of alternatives for a pattern using "|" to
1851 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1852 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1853 first alternative includes everything from the last pattern delimiter
1854 ("(", "[", or the beginning of the pattern) up to the first "|", and
1855 the last alternative contains everything from the last "|" to the next
1856 pattern delimiter.  That's why it's common practice to include
1857 alternatives in parentheses: to minimize confusion about where they
1858 start and end.
1859
1860 Alternatives are tried from left to right, so the first
1861 alternative found for which the entire expression matches, is the one that
1862 is chosen. This means that alternatives are not necessarily greedy. For
1863 example: when matching C<foo|foot> against "barefoot", only the "foo"
1864 part will match, as that is the first alternative tried, and it successfully
1865 matches the target string. (This might not seem important, but it is
1866 important when you are capturing matched text using parentheses.)
1867
1868 Also remember that "|" is interpreted as a literal within square brackets,
1869 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1870
1871 Within a pattern, you may designate subpatterns for later reference
1872 by enclosing them in parentheses, and you may refer back to the
1873 I<n>th subpattern later in the pattern using the metacharacter
1874 \I<n>.  Subpatterns are numbered based on the left to right order
1875 of their opening parenthesis.  A backreference matches whatever
1876 actually matched the subpattern in the string being examined, not
1877 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1878 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1879 1 matched "0x", even though the rule C<0|0x> could potentially match
1880 the leading 0 in the second number.
1881
1882 =head2 Warning on \1 Instead of $1
1883
1884 Some people get too used to writing things like:
1885
1886     $pattern =~ s/(\W)/\\\1/g;
1887
1888 This is grandfathered for the RHS of a substitute to avoid shocking the
1889 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1890 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1891 the usual double-quoted string means a control-A.  The customary Unix
1892 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1893 of doing that, you get yourself into trouble if you then add an C</e>
1894 modifier.
1895
1896     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1897
1898 Or if you try to do
1899
1900     s/(\d+)/\1000/;
1901
1902 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1903 C<${1}000>.  The operation of interpolation should not be confused
1904 with the operation of matching a backreference.  Certainly they mean two
1905 different things on the I<left> side of the C<s///>.
1906
1907 =head2 Repeated Patterns Matching a Zero-length Substring
1908
1909 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1910
1911 Regular expressions provide a terse and powerful programming language.  As
1912 with most other power tools, power comes together with the ability
1913 to wreak havoc.
1914
1915 A common abuse of this power stems from the ability to make infinite
1916 loops using regular expressions, with something as innocuous as:
1917
1918     'foo' =~ m{ ( o? )* }x;
1919
1920 The C<o?> matches at the beginning of C<'foo'>, and since the position
1921 in the string is not moved by the match, C<o?> would match again and again
1922 because of the C<*> quantifier.  Another common way to create a similar cycle
1923 is with the looping modifier C<//g>:
1924
1925     @matches = ( 'foo' =~ m{ o? }xg );
1926
1927 or
1928
1929     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1930
1931 or the loop implied by split().
1932
1933 However, long experience has shown that many programming tasks may
1934 be significantly simplified by using repeated subexpressions that
1935 may match zero-length substrings.  Here's a simple example being:
1936
1937     @chars = split //, $string;           # // is not magic in split
1938     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1939
1940 Thus Perl allows such constructs, by I<forcefully breaking
1941 the infinite loop>.  The rules for this are different for lower-level
1942 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1943 ones like the C</g> modifier or split() operator.
1944
1945 The lower-level loops are I<interrupted> (that is, the loop is
1946 broken) when Perl detects that a repeated expression matched a
1947 zero-length substring.   Thus
1948
1949    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1950
1951 is made equivalent to
1952
1953    m{   (?: NON_ZERO_LENGTH )*
1954       |
1955         (?: ZERO_LENGTH )?
1956     }x;
1957
1958 The higher level-loops preserve an additional state between iterations:
1959 whether the last match was zero-length.  To break the loop, the following
1960 match after a zero-length match is prohibited to have a length of zero.
1961 This prohibition interacts with backtracking (see L<"Backtracking">),
1962 and so the I<second best> match is chosen if the I<best> match is of
1963 zero length.
1964
1965 For example:
1966
1967     $_ = 'bar';
1968     s/\w??/<$&>/g;
1969
1970 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1971 match given by non-greedy C<??> is the zero-length match, and the I<second
1972 best> match is what is matched by C<\w>.  Thus zero-length matches
1973 alternate with one-character-long matches.
1974
1975 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1976 position one notch further in the string.
1977
1978 The additional state of being I<matched with zero-length> is associated with
1979 the matched string, and is reset by each assignment to pos().
1980 Zero-length matches at the end of the previous match are ignored
1981 during C<split>.
1982
1983 =head2 Combining RE Pieces
1984
1985 Each of the elementary pieces of regular expressions which were described
1986 before (such as C<ab> or C<\Z>) could match at most one substring
1987 at the given position of the input string.  However, in a typical regular
1988 expression these elementary pieces are combined into more complicated
1989 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1990 (in these examples C<S> and C<T> are regular subexpressions).
1991
1992 Such combinations can include alternatives, leading to a problem of choice:
1993 if we match a regular expression C<a|ab> against C<"abc">, will it match
1994 substring C<"a"> or C<"ab">?  One way to describe which substring is
1995 actually matched is the concept of backtracking (see L<"Backtracking">).
1996 However, this description is too low-level and makes you think
1997 in terms of a particular implementation.
1998
1999 Another description starts with notions of "better"/"worse".  All the
2000 substrings which may be matched by the given regular expression can be
2001 sorted from the "best" match to the "worst" match, and it is the "best"
2002 match which is chosen.  This substitutes the question of "what is chosen?"
2003 by the question of "which matches are better, and which are worse?".
2004
2005 Again, for elementary pieces there is no such question, since at most
2006 one match at a given position is possible.  This section describes the
2007 notion of better/worse for combining operators.  In the description
2008 below C<S> and C<T> are regular subexpressions.
2009
2010 =over 4
2011
2012 =item C<ST>
2013
2014 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2015 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2016 which can be matched by C<T>.
2017
2018 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
2019 match than C<A'B'>.
2020
2021 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2022 C<B> is better match for C<T> than C<B'>.
2023
2024 =item C<S|T>
2025
2026 When C<S> can match, it is a better match than when only C<T> can match.
2027
2028 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2029 two matches for C<T>.
2030
2031 =item C<S{REPEAT_COUNT}>
2032
2033 Matches as C<SSS...S> (repeated as many times as necessary).
2034
2035 =item C<S{min,max}>
2036
2037 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2038
2039 =item C<S{min,max}?>
2040
2041 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2042
2043 =item C<S?>, C<S*>, C<S+>
2044
2045 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2046
2047 =item C<S??>, C<S*?>, C<S+?>
2048
2049 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2050
2051 =item C<< (?>S) >>
2052
2053 Matches the best match for C<S> and only that.
2054
2055 =item C<(?=S)>, C<(?<=S)>
2056
2057 Only the best match for C<S> is considered.  (This is important only if
2058 C<S> has capturing parentheses, and backreferences are used somewhere
2059 else in the whole regular expression.)
2060
2061 =item C<(?!S)>, C<(?<!S)>
2062
2063 For this grouping operator there is no need to describe the ordering, since
2064 only whether or not C<S> can match is important.
2065
2066 =item C<(??{ EXPR })>, C<(?PARNO)>
2067
2068 The ordering is the same as for the regular expression which is
2069 the result of EXPR, or the pattern contained by capture buffer PARNO.
2070
2071 =item C<(?(condition)yes-pattern|no-pattern)>
2072
2073 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2074 already determined.  The ordering of the matches is the same as for the
2075 chosen subexpression.
2076
2077 =back
2078
2079 The above recipes describe the ordering of matches I<at a given position>.
2080 One more rule is needed to understand how a match is determined for the
2081 whole regular expression: a match at an earlier position is always better
2082 than a match at a later position.
2083
2084 =head2 Creating Custom RE Engines
2085
2086 Overloaded constants (see L<overload>) provide a simple way to extend
2087 the functionality of the RE engine.
2088
2089 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2090 matches at a boundary between whitespace characters and non-whitespace
2091 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2092 at these positions, so we want to have each C<\Y|> in the place of the
2093 more complicated version.  We can create a module C<customre> to do
2094 this:
2095
2096     package customre;
2097     use overload;
2098
2099     sub import {
2100       shift;
2101       die "No argument to customre::import allowed" if @_;
2102       overload::constant 'qr' => \&convert;
2103     }
2104
2105     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2106
2107     # We must also take care of not escaping the legitimate \\Y|
2108     # sequence, hence the presence of '\\' in the conversion rules.
2109     my %rules = ( '\\' => '\\\\',
2110                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2111     sub convert {
2112       my $re = shift;
2113       $re =~ s{
2114                 \\ ( \\ | Y . )
2115               }
2116               { $rules{$1} or invalid($re,$1) }sgex;
2117       return $re;
2118     }
2119
2120 Now C<use customre> enables the new escape in constant regular
2121 expressions, i.e., those without any runtime variable interpolations.
2122 As documented in L<overload>, this conversion will work only over
2123 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2124 part of this regular expression needs to be converted explicitly
2125 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2126
2127     use customre;
2128     $re = <>;
2129     chomp $re;
2130     $re = customre::convert $re;
2131     /\Y|$re\Y|/;
2132
2133 =head1 PCRE/Python Support
2134
2135 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2136 to the regex syntax. While Perl programmers are encouraged to use the
2137 Perl specific syntax, the following are also accepted:
2138
2139 =over 4
2140
2141 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2142
2143 Define a named capture buffer. Equivalent to C<< (?<NAME>pattern) >>.
2144
2145 =item C<< (?P=NAME) >>
2146
2147 Backreference to a named capture buffer. Equivalent to C<< \g{NAME} >>.
2148
2149 =item C<< (?P>NAME) >>
2150
2151 Subroutine call to a named capture buffer. Equivalent to C<< (?&NAME) >>.
2152
2153 =back
2154
2155 =head1 BUGS
2156
2157 There are numerous problems with case insensitive matching of characters
2158 outside the ASCII range, especially with those whose folds are multiple
2159 characters, such as ligatures like C<LATIN SMALL LIGATURE FF>.
2160
2161 In a bracketed character class with case insensitive matching, ranges only work
2162 for ASCII characters.  For example,
2163 C<m/[\N{CYRILLIC CAPITAL LETTER A}-\N{CYRILLIC CAPITAL LETTER YA}]/i>
2164 doesn't match all the Russian upper and lower case letters.
2165
2166 Many regular expression constructs don't work on EBCDIC platforms.
2167
2168 This document varies from difficult to understand to completely
2169 and utterly opaque.  The wandering prose riddled with jargon is
2170 hard to fathom in several places.
2171
2172 This document needs a rewrite that separates the tutorial content
2173 from the reference content.
2174
2175 =head1 SEE ALSO
2176
2177 L<perlrequick>.
2178
2179 L<perlretut>.
2180
2181 L<perlop/"Regexp Quote-Like Operators">.
2182
2183 L<perlop/"Gory details of parsing quoted constructs">.
2184
2185 L<perlfaq6>.
2186
2187 L<perlfunc/pos>.
2188
2189 L<perllocale>.
2190
2191 L<perlebcdic>.
2192
2193 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2194 by O'Reilly and Associates.