This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: [PATCH] Document that m//k works
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 Predefined Names
8
9 The following names have special meaning to Perl.  Most 
10 punctuation names have reasonable mnemonics, or analogs in the
11 shells.  Nevertheless, if you wish to use long variable names,
12 you need only say
13
14     use English;
15
16 at the top of your program. This aliases all the short names to the long
17 names in the current package. Some even have medium names, generally
18 borrowed from B<awk>. In general, it's best to use the
19
20     use English '-no_match_vars';
21
22 invocation if you don't need $PREMATCH, $MATCH, or $POSTMATCH, as it avoids
23 a certain performance hit with the use of regular expressions. See
24 L<English>.
25
26 Variables that depend on the currently selected filehandle may be set by
27 calling an appropriate object method on the IO::Handle object, although
28 this is less efficient than using the regular built-in variables. (Summary
29 lines below for this contain the word HANDLE.) First you must say
30
31     use IO::Handle;
32
33 after which you may use either
34
35     method HANDLE EXPR
36
37 or more safely,
38
39     HANDLE->method(EXPR)
40
41 Each method returns the old value of the IO::Handle attribute.
42 The methods each take an optional EXPR, which, if supplied, specifies the
43 new value for the IO::Handle attribute in question.  If not supplied,
44 most methods do nothing to the current value--except for
45 autoflush(), which will assume a 1 for you, just to be different.
46
47 Because loading in the IO::Handle class is an expensive operation, you should
48 learn how to use the regular built-in variables.
49
50 A few of these variables are considered "read-only".  This means that if
51 you try to assign to this variable, either directly or indirectly through
52 a reference, you'll raise a run-time exception.
53
54 You should be very careful when modifying the default values of most
55 special variables described in this document. In most cases you want
56 to localize these variables before changing them, since if you don't,
57 the change may affect other modules which rely on the default values
58 of the special variables that you have changed. This is one of the
59 correct ways to read the whole file at once:
60
61     open my $fh, "foo" or die $!;
62     local $/; # enable localized slurp mode
63     my $content = <$fh>;
64     close $fh;
65
66 But the following code is quite bad:
67
68     open my $fh, "foo" or die $!;
69     undef $/; # enable slurp mode
70     my $content = <$fh>;
71     close $fh;
72
73 since some other module, may want to read data from some file in the
74 default "line mode", so if the code we have just presented has been
75 executed, the global value of C<$/> is now changed for any other code
76 running inside the same Perl interpreter.
77
78 Usually when a variable is localized you want to make sure that this
79 change affects the shortest scope possible. So unless you are already
80 inside some short C<{}> block, you should create one yourself. For
81 example:
82
83     my $content = '';
84     open my $fh, "foo" or die $!;
85     {
86         local $/;
87         $content = <$fh>;
88     }
89     close $fh;
90
91 Here is an example of how your own code can go broken:
92
93     for (1..5){
94         nasty_break();
95         print "$_ ";
96     }
97     sub nasty_break {
98         $_ = 5;
99         # do something with $_
100     }
101
102 You probably expect this code to print:
103
104     1 2 3 4 5
105
106 but instead you get:
107
108     5 5 5 5 5
109
110 Why? Because nasty_break() modifies C<$_> without localizing it
111 first. The fix is to add local():
112
113         local $_ = 5;
114
115 It's easy to notice the problem in such a short example, but in more
116 complicated code you are looking for trouble if you don't localize
117 changes to the special variables.
118
119 The following list is ordered by scalar variables first, then the
120 arrays, then the hashes.
121
122 =over 8
123
124 =item $ARG
125
126 =item $_
127 X<$_> X<$ARG>
128
129 The default input and pattern-searching space.  The following pairs are
130 equivalent:
131
132     while (<>) {...}    # equivalent only in while!
133     while (defined($_ = <>)) {...}
134
135     /^Subject:/
136     $_ =~ /^Subject:/
137
138     tr/a-z/A-Z/
139     $_ =~ tr/a-z/A-Z/
140
141     chomp
142     chomp($_)
143
144 Here are the places where Perl will assume $_ even if you
145 don't use it:
146
147 =over 3
148
149 =item *
150
151 Various unary functions, including functions like ord() and int(), as well
152 as the all file tests (C<-f>, C<-d>) except for C<-t>, which defaults to
153 STDIN.
154
155 =item *
156
157 Various list functions like print() and unlink().
158
159 =item *
160
161 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
162 without an C<=~> operator.
163
164 =item *
165
166 The default iterator variable in a C<foreach> loop if no other
167 variable is supplied.
168
169 =item *
170
171 The implicit iterator variable in the grep() and map() functions.
172
173 =item *
174
175 The default place to put an input record when a C<< <FH> >>
176 operation's result is tested by itself as the sole criterion of a C<while>
177 test.  Outside a C<while> test, this will not happen.
178
179 =back
180
181 As C<$_> is a global variable, this may lead in some cases to unwanted
182 side-effects.  As of perl 5.9.1, you can now use a lexical version of
183 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
184 declaring C<our $> restores the global C<$_> in the current scope.
185
186 (Mnemonic: underline is understood in certain operations.)
187
188 =back
189
190 =over 8
191
192 =item $a
193
194 =item $b
195 X<$a> X<$b>
196
197 Special package variables when using sort(), see L<perlfunc/sort>.
198 Because of this specialness $a and $b don't need to be declared
199 (using use vars, or our()) even when using the C<strict 'vars'> pragma.
200 Don't lexicalize them with C<my $a> or C<my $b> if you want to be
201 able to use them in the sort() comparison block or function.
202
203 =back
204
205 =over 8
206
207 =item $<I<digits>>
208 X<$1> X<$2> X<$3>
209
210 Contains the subpattern from the corresponding set of capturing
211 parentheses from the last pattern match, not counting patterns
212 matched in nested blocks that have been exited already.  (Mnemonic:
213 like \digits.)  These variables are all read-only and dynamically
214 scoped to the current BLOCK.
215
216 =item $MATCH
217
218 =item $&
219 X<$&> X<$MATCH>
220
221 The string matched by the last successful pattern match (not counting
222 any matches hidden within a BLOCK or eval() enclosed by the current
223 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only
224 and dynamically scoped to the current BLOCK.
225
226 The use of this variable anywhere in a program imposes a considerable
227 performance penalty on all regular expression matches.  See L</BUGS>.
228
229 See L</@-> for a replacement.
230
231 =item ${^MATCH}
232 X<${^MATCH}>
233
234 This is similar to C<$&> (C<$POSTMATCH>) except that it does not incur the
235 performance penalty associated with that variable, and is only guaranteed
236 to return a defined value when the pattern was compiled or executed with
237 the C</p> modifier.
238
239 =item $PREMATCH
240
241 =item $`
242 X<$`> X<$PREMATCH>
243
244 The string preceding whatever was matched by the last successful
245 pattern match (not counting any matches hidden within a BLOCK or eval
246 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
247 string.)  This variable is read-only.
248
249 The use of this variable anywhere in a program imposes a considerable
250 performance penalty on all regular expression matches.  See L</BUGS>.
251
252 See L</@-> for a replacement.
253
254 =item ${^PREMATCH}
255 X<${^PREMATCH}>
256
257 This is similar to C<$`> ($PREMATCH) except that it does not incur the
258 performance penalty associated with that variable, and is only guaranteed
259 to return a defined value when the pattern was compiled or executed with
260 the C</p> modifier.
261
262 =item $POSTMATCH
263
264 =item $'
265 X<$'> X<$POSTMATCH>
266
267 The string following whatever was matched by the last successful
268 pattern match (not counting any matches hidden within a BLOCK or eval()
269 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
270 string.)  Example:
271
272     local $_ = 'abcdefghi';
273     /def/;
274     print "$`:$&:$'\n";         # prints abc:def:ghi
275
276 This variable is read-only and dynamically scoped to the current BLOCK.
277
278 The use of this variable anywhere in a program imposes a considerable
279 performance penalty on all regular expression matches.  See L</BUGS>.
280
281 See L</@-> for a replacement.
282
283 =item ${^POSTMATCH}
284 X<${^POSTMATCH}>
285
286 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
287 performance penalty associated with that variable, and is only guaranteed
288 to return a defined value when the pattern was compiled or executed with
289 the C</p> modifier.
290
291 =item $LAST_PAREN_MATCH
292
293 =item $+
294 X<$+> X<$LAST_PAREN_MATCH>
295
296 The text matched by the last bracket of the last successful search pattern.
297 This is useful if you don't know which one of a set of alternative patterns
298 matched. For example:
299
300     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
301
302 (Mnemonic: be positive and forward looking.)
303 This variable is read-only and dynamically scoped to the current BLOCK.
304
305 =item $^N
306 X<$^N>
307
308 The text matched by the used group most-recently closed (i.e. the group
309 with the rightmost closing parenthesis) of the last successful search
310 pattern.  (Mnemonic: the (possibly) Nested parenthesis that most
311 recently closed.)
312
313 This is primarily used inside C<(?{...})> blocks for examining text
314 recently matched. For example, to effectively capture text to a variable
315 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
316
317      (?:(...)(?{ $var = $^N }))
318
319 By setting and then using C<$var> in this way relieves you from having to
320 worry about exactly which numbered set of parentheses they are.
321
322 This variable is dynamically scoped to the current BLOCK.
323
324 =item @LAST_MATCH_END
325
326 =item @+
327 X<@+> X<@LAST_MATCH_END>
328
329 This array holds the offsets of the ends of the last successful
330 submatches in the currently active dynamic scope.  C<$+[0]> is
331 the offset into the string of the end of the entire match.  This
332 is the same value as what the C<pos> function returns when called
333 on the variable that was matched against.  The I<n>th element
334 of this array holds the offset of the I<n>th submatch, so
335 C<$+[1]> is the offset past where $1 ends, C<$+[2]> the offset
336 past where $2 ends, and so on.  You can use C<$#+> to determine
337 how many subgroups were in the last successful match.  See the
338 examples given for the C<@-> variable.
339
340 =item %+
341 X<%+>
342
343 Similar to C<@+>, the C<%+> hash allows access to the named capture
344 buffers, should they exist, in the last successful match in the
345 currently active dynamic scope.
346
347 C<$+{foo}> is equivalent to C<$1> after the following match:
348
349   'foo'=~/(?<foo>foo)/;
350
351 The underlying behaviour of %+ is provided by the L<re::Tie::Hash::NamedCapture>
352 module.
353
354 B<Note:> As C<%-> and C<%+> are tied views into a common internal hash
355 associated with the last successful regular expression. Therefore mixing
356 iterative access to them via C<each> may have unpredictable results.
357 Likewise, if the last successful match changes then the results may be
358 surprising.
359
360 =item HANDLE->input_line_number(EXPR)
361
362 =item $INPUT_LINE_NUMBER
363
364 =item $NR
365
366 =item $.
367 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
368
369 Current line number for the last filehandle accessed.
370
371 Each filehandle in Perl counts the number of lines that have been read
372 from it.  (Depending on the value of C<$/>, Perl's idea of what
373 constitutes a line may not match yours.)  When a line is read from a
374 filehandle (via readline() or C<< <> >>), or when tell() or seek() is
375 called on it, C<$.> becomes an alias to the line counter for that
376 filehandle.
377
378 You can adjust the counter by assigning to C<$.>, but this will not
379 actually move the seek pointer.  I<Localizing C<$.> will not localize
380 the filehandle's line count>.  Instead, it will localize perl's notion
381 of which filehandle C<$.> is currently aliased to.
382
383 C<$.> is reset when the filehandle is closed, but B<not> when an open
384 filehandle is reopened without an intervening close().  For more
385 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
386 an explicit close, line numbers increase across ARGV files (but see
387 examples in L<perlfunc/eof>).
388
389 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
390 line counter for a given filehandle without having to worry about
391 which handle you last accessed.
392
393 (Mnemonic: many programs use "." to mean the current line number.)
394
395 =item IO::Handle->input_record_separator(EXPR)
396
397 =item $INPUT_RECORD_SEPARATOR
398
399 =item $RS
400
401 =item $/
402 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
403
404 The input record separator, newline by default.  This 
405 influences Perl's idea of what a "line" is.  Works like B<awk>'s RS
406 variable, including treating empty lines as a terminator if set to
407 the null string.  (An empty line cannot contain any spaces
408 or tabs.)  You may set it to a multi-character string to match a
409 multi-character terminator, or to C<undef> to read through the end
410 of file.  Setting it to C<"\n\n"> means something slightly
411 different than setting to C<"">, if the file contains consecutive
412 empty lines.  Setting to C<""> will treat two or more consecutive
413 empty lines as a single empty line.  Setting to C<"\n\n"> will
414 blindly assume that the next input character belongs to the next
415 paragraph, even if it's a newline.  (Mnemonic: / delimits
416 line boundaries when quoting poetry.)
417
418     local $/;           # enable "slurp" mode
419     local $_ = <FH>;    # whole file now here
420     s/\n[ \t]+/ /g;
421
422 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to be
423 better for something. :-)
424
425 Setting C<$/> to a reference to an integer, scalar containing an integer, or
426 scalar that's convertible to an integer will attempt to read records
427 instead of lines, with the maximum record size being the referenced
428 integer.  So this:
429
430     local $/ = \32768; # or \"32768", or \$var_containing_32768
431     open my $fh, $myfile or die $!;
432     local $_ = <$fh>;
433
434 will read a record of no more than 32768 bytes from FILE.  If you're
435 not reading from a record-oriented file (or your OS doesn't have
436 record-oriented files), then you'll likely get a full chunk of data
437 with every read.  If a record is larger than the record size you've
438 set, you'll get the record back in pieces.  Trying to set the record
439 size to zero or less will cause reading in the (rest of the) whole file.
440
441 On VMS, record reads are done with the equivalent of C<sysread>,
442 so it's best not to mix record and non-record reads on the same
443 file.  (This is unlikely to be a problem, because any file you'd
444 want to read in record mode is probably unusable in line mode.)
445 Non-VMS systems do normal I/O, so it's safe to mix record and
446 non-record reads of a file.
447
448 See also L<perlport/"Newlines">.  Also see C<$.>.
449
450 =item HANDLE->autoflush(EXPR)
451
452 =item $OUTPUT_AUTOFLUSH
453
454 =item $|
455 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
456
457 If set to nonzero, forces a flush right away and after every write
458 or print on the currently selected output channel.  Default is 0
459 (regardless of whether the channel is really buffered by the
460 system or not; C<$|> tells you only whether you've asked Perl
461 explicitly to flush after each write).  STDOUT will
462 typically be line buffered if output is to the terminal and block
463 buffered otherwise.  Setting this variable is useful primarily when
464 you are outputting to a pipe or socket, such as when you are running
465 a Perl program under B<rsh> and want to see the output as it's
466 happening.  This has no effect on input buffering.  See L<perlfunc/getc>
467 for that.  (Mnemonic: when you want your pipes to be piping hot.)
468
469 =item IO::Handle->output_field_separator EXPR
470
471 =item $OUTPUT_FIELD_SEPARATOR
472
473 =item $OFS
474
475 =item $,
476 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
477
478 The output field separator for the print operator.  If defined, this
479 value is printed between each of print's arguments.  Default is C<undef>.
480 (Mnemonic: what is printed when there is a "," in your print statement.)
481
482 =item IO::Handle->output_record_separator EXPR
483
484 =item $OUTPUT_RECORD_SEPARATOR
485
486 =item $ORS
487
488 =item $\
489 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
490
491 The output record separator for the print operator.  If defined, this
492 value is printed after the last of print's arguments.  Default is C<undef>.
493 (Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
494 Also, it's just like C<$/>, but it's what you get "back" from Perl.)
495
496 =item $LIST_SEPARATOR
497
498 =item $"
499 X<$"> X<$LIST_SEPARATOR>
500
501 This is like C<$,> except that it applies to array and slice values
502 interpolated into a double-quoted string (or similar interpreted
503 string).  Default is a space.  (Mnemonic: obvious, I think.)
504
505 =item $SUBSCRIPT_SEPARATOR
506
507 =item $SUBSEP
508
509 =item $;
510 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
511
512 The subscript separator for multidimensional array emulation.  If you
513 refer to a hash element as
514
515     $foo{$a,$b,$c}
516
517 it really means
518
519     $foo{join($;, $a, $b, $c)}
520
521 But don't put
522
523     @foo{$a,$b,$c}      # a slice--note the @
524
525 which means
526
527     ($foo{$a},$foo{$b},$foo{$c})
528
529 Default is "\034", the same as SUBSEP in B<awk>.  If your
530 keys contain binary data there might not be any safe value for C<$;>.
531 (Mnemonic: comma (the syntactic subscript separator) is a
532 semi-semicolon.  Yeah, I know, it's pretty lame, but C<$,> is already
533 taken for something more important.)
534
535 Consider using "real" multidimensional arrays as described
536 in L<perllol>.
537
538 =item HANDLE->format_page_number(EXPR)
539
540 =item $FORMAT_PAGE_NUMBER
541
542 =item $%
543 X<$%> X<$FORMAT_PAGE_NUMBER>
544
545 The current page number of the currently selected output channel.
546 Used with formats.
547 (Mnemonic: % is page number in B<nroff>.)
548
549 =item HANDLE->format_lines_per_page(EXPR)
550
551 =item $FORMAT_LINES_PER_PAGE
552
553 =item $=
554 X<$=> X<$FORMAT_LINES_PER_PAGE>
555
556 The current page length (printable lines) of the currently selected
557 output channel.  Default is 60.  
558 Used with formats.
559 (Mnemonic: = has horizontal lines.)
560
561 =item HANDLE->format_lines_left(EXPR)
562
563 =item $FORMAT_LINES_LEFT
564
565 =item $-
566 X<$-> X<$FORMAT_LINES_LEFT>
567
568 The number of lines left on the page of the currently selected output
569 channel.  
570 Used with formats.
571 (Mnemonic: lines_on_page - lines_printed.)
572
573 =item @LAST_MATCH_START
574
575 =item @-
576 X<@-> X<@LAST_MATCH_START>
577
578 $-[0] is the offset of the start of the last successful match.
579 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
580 I<n>-th subpattern, or undef if the subpattern did not match.
581
582 Thus after a match against $_, $& coincides with C<substr $_, $-[0],
583 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
584 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
585 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the last
586 matched subgroup in the last successful match.  Contrast with
587 C<$#+>, the number of subgroups in the regular expression.  Compare
588 with C<@+>.
589
590 This array holds the offsets of the beginnings of the last
591 successful submatches in the currently active dynamic scope.
592 C<$-[0]> is the offset into the string of the beginning of the
593 entire match.  The I<n>th element of this array holds the offset
594 of the I<n>th submatch, so C<$-[1]> is the offset where $1
595 begins, C<$-[2]> the offset where $2 begins, and so on.
596
597 After a match against some variable $var:
598
599 =over 5
600
601 =item C<$`> is the same as C<substr($var, 0, $-[0])>
602
603 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
604
605 =item C<$'> is the same as C<substr($var, $+[0])>
606
607 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>  
608
609 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
610
611 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
612
613 =back
614
615 =item %-
616 X<%->
617
618 Similar to %+, this variable allows access to the named capture
619 buffers that were defined in the last successful match. It returns
620 a reference to an array containing one value per buffer of a given
621 name in the pattern.
622
623     if ('1234'=~/(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
624         foreach my $name (sort keys(%-)) {
625             my $ary = $-{$name};
626             foreach my $idx (0..$#$ary) {
627                 print "\$-{$name}[$idx] : ",
628                       (defined($ary->[$idx]) ? "'$ary->[$idx]'" : "undef"),
629                       "\n";
630             }
631         }
632     }
633
634 would print out:
635
636     $-{A}[0] : '1'
637     $-{A}[1] : '3'
638     $-{B}[0] : '2'
639     $-{B}[1] : '4'
640
641 The behaviour of %- is implemented via the L<re::Tie::Hash::NamedCapture> module.
642
643 Note that C<%-> and C<%+> are tied views into a common internal hash
644 associated with the last successful regular expression. Therefore mixing
645 iterative access to them via C<each> may have unpredictable results.
646 Likewise, if the last successful match changes then the results may be
647 surprising.
648
649 =item HANDLE->format_name(EXPR)
650
651 =item $FORMAT_NAME
652
653 =item $~
654 X<$~> X<$FORMAT_NAME>
655
656 The name of the current report format for the currently selected output
657 channel.  Default is the name of the filehandle.  (Mnemonic: brother to
658 C<$^>.)
659
660 =item HANDLE->format_top_name(EXPR)
661
662 =item $FORMAT_TOP_NAME
663
664 =item $^
665 X<$^> X<$FORMAT_TOP_NAME>
666
667 The name of the current top-of-page format for the currently selected
668 output channel.  Default is the name of the filehandle with _TOP
669 appended.  (Mnemonic: points to top of page.)
670
671 =item IO::Handle->format_line_break_characters EXPR
672
673 =item $FORMAT_LINE_BREAK_CHARACTERS
674
675 =item $:
676 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
677
678 The current set of characters after which a string may be broken to
679 fill continuation fields (starting with ^) in a format.  Default is
680 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
681 poetry is a part of a line.)
682
683 =item IO::Handle->format_formfeed EXPR
684
685 =item $FORMAT_FORMFEED
686
687 =item $^L
688 X<$^L> X<$FORMAT_FORMFEED>
689
690 What formats output as a form feed.  Default is \f.
691
692 =item $ACCUMULATOR
693
694 =item $^A
695 X<$^A> X<$ACCUMULATOR>
696
697 The current value of the write() accumulator for format() lines.  A format
698 contains formline() calls that put their result into C<$^A>.  After
699 calling its format, write() prints out the contents of C<$^A> and empties.
700 So you never really see the contents of C<$^A> unless you call
701 formline() yourself and then look at it.  See L<perlform> and
702 L<perlfunc/formline()>.
703
704 =item $CHILD_ERROR
705
706 =item $?
707 X<$?> X<$CHILD_ERROR>
708
709 The status returned by the last pipe close, backtick (C<``>) command,
710 successful call to wait() or waitpid(), or from the system()
711 operator.  This is just the 16-bit status word returned by the
712 traditional Unix wait() system call (or else is made up to look like it).  Thus, the
713 exit value of the subprocess is really (C<<< $? >> 8 >>>), and
714 C<$? & 127> gives which signal, if any, the process died from, and
715 C<$? & 128> reports whether there was a core dump.  (Mnemonic:
716 similar to B<sh> and B<ksh>.)
717
718 Additionally, if the C<h_errno> variable is supported in C, its value
719 is returned via $? if any C<gethost*()> function fails.
720
721 If you have installed a signal handler for C<SIGCHLD>, the
722 value of C<$?> will usually be wrong outside that handler.
723
724 Inside an C<END> subroutine C<$?> contains the value that is going to be
725 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
726 change the exit status of your program.  For example:
727
728     END {
729         $? = 1 if $? == 255;  # die would make it 255
730     } 
731
732 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
733 actual VMS exit status, instead of the default emulation of POSIX
734 status; see L<perlvms/$?> for details.
735
736 Also see L<Error Indicators>.
737
738 =item ${^CHILD_ERROR_NATIVE}
739 X<$^CHILD_ERROR_NATIVE>
740
741 The native status returned by the last pipe close, backtick (C<``>)
742 command, successful call to wait() or waitpid(), or from the system()
743 operator.  On POSIX-like systems this value can be decoded with the
744 WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED, WSTOPSIG
745 and WIFCONTINUED functions provided by the L<POSIX> module.
746
747 Under VMS this reflects the actual VMS exit status; i.e. it is the same
748 as $? when the pragma C<use vmsish 'status'> is in effect.
749
750 =item ${^ENCODING}
751 X<$^ENCODING>
752
753 The I<object reference> to the Encode object that is used to convert
754 the source code to Unicode.  Thanks to this variable your perl script
755 does not have to be written in UTF-8.  Default is I<undef>.  The direct
756 manipulation of this variable is highly discouraged.  See L<encoding>
757 for more details.
758
759 =item $OS_ERROR
760
761 =item $ERRNO
762
763 =item $!
764 X<$!> X<$ERRNO> X<$OS_ERROR>
765
766 If used numerically, yields the current value of the C C<errno>
767 variable, or in other words, if a system or library call fails, it
768 sets this variable.  This means that the value of C<$!> is meaningful
769 only I<immediately> after a B<failure>:
770
771     if (open(FH, $filename)) {
772         # Here $! is meaningless.
773         ...
774     } else {
775         # ONLY here is $! meaningful.
776         ...
777         # Already here $! might be meaningless.
778     }
779     # Since here we might have either success or failure,
780     # here $! is meaningless.
781
782 In the above I<meaningless> stands for anything: zero, non-zero,
783 C<undef>.  A successful system or library call does B<not> set
784 the variable to zero.
785
786 If used as a string, yields the corresponding system error string.
787 You can assign a number to C<$!> to set I<errno> if, for instance,
788 you want C<"$!"> to return the string for error I<n>, or you want
789 to set the exit value for the die() operator.  (Mnemonic: What just
790 went bang?)
791
792 Also see L<Error Indicators>.
793
794 =item %!
795 X<%!>
796
797 Each element of C<%!> has a true value only if C<$!> is set to that
798 value.  For example, C<$!{ENOENT}> is true if and only if the current
799 value of C<$!> is C<ENOENT>; that is, if the most recent error was
800 "No such file or directory" (or its moral equivalent: not all operating
801 systems give that exact error, and certainly not all languages).
802 To check if a particular key is meaningful on your system, use
803 C<exists $!{the_key}>; for a list of legal keys, use C<keys %!>.
804 See L<Errno> for more information, and also see above for the
805 validity of C<$!>.
806
807 =item $EXTENDED_OS_ERROR
808
809 =item $^E
810 X<$^E> X<$EXTENDED_OS_ERROR>
811
812 Error information specific to the current operating system.  At
813 the moment, this differs from C<$!> under only VMS, OS/2, and Win32
814 (and for MacPerl).  On all other platforms, C<$^E> is always just
815 the same as C<$!>.
816
817 Under VMS, C<$^E> provides the VMS status value from the last
818 system error.  This is more specific information about the last
819 system error than that provided by C<$!>.  This is particularly
820 important when C<$!> is set to B<EVMSERR>.
821
822 Under OS/2, C<$^E> is set to the error code of the last call to
823 OS/2 API either via CRT, or directly from perl.
824
825 Under Win32, C<$^E> always returns the last error information
826 reported by the Win32 call C<GetLastError()> which describes
827 the last error from within the Win32 API.  Most Win32-specific
828 code will report errors via C<$^E>.  ANSI C and Unix-like calls
829 set C<errno> and so most portable Perl code will report errors
830 via C<$!>. 
831
832 Caveats mentioned in the description of C<$!> generally apply to
833 C<$^E>, also.  (Mnemonic: Extra error explanation.)
834
835 Also see L<Error Indicators>.
836
837 =item $EVAL_ERROR
838
839 =item $@
840 X<$@> X<$EVAL_ERROR>
841
842 The Perl syntax error message from the last eval() operator.
843 If $@ is the null string, the last eval() parsed and executed
844 correctly (although the operations you invoked may have failed in the
845 normal fashion).  (Mnemonic: Where was the syntax error "at"?)
846
847 Warning messages are not collected in this variable.  You can,
848 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
849 as described below.
850
851 Also see L<Error Indicators>.
852
853 =item $PROCESS_ID
854
855 =item $PID
856
857 =item $$
858 X<$$> X<$PID> X<$PROCESS_ID>
859
860 The process number of the Perl running this script.  You should
861 consider this variable read-only, although it will be altered
862 across fork() calls.  (Mnemonic: same as shells.)
863
864 Note for Linux users: on Linux, the C functions C<getpid()> and
865 C<getppid()> return different values from different threads. In order to
866 be portable, this behavior is not reflected by C<$$>, whose value remains
867 consistent across threads. If you want to call the underlying C<getpid()>,
868 you may use the CPAN module C<Linux::Pid>.
869
870 =item $REAL_USER_ID
871
872 =item $UID
873
874 =item $<
875 X<< $< >> X<$UID> X<$REAL_USER_ID>
876
877 The real uid of this process.  (Mnemonic: it's the uid you came I<from>,
878 if you're running setuid.)  You can change both the real uid and
879 the effective uid at the same time by using POSIX::setuid().  Since
880 changes to $< require a system call, check $! after a change attempt to 
881 detect any possible errors.
882
883 =item $EFFECTIVE_USER_ID
884
885 =item $EUID
886
887 =item $>
888 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
889
890 The effective uid of this process.  Example:
891
892     $< = $>;            # set real to effective uid
893     ($<,$>) = ($>,$<);  # swap real and effective uid
894
895 You can change both the effective uid and the real uid at the same
896 time by using POSIX::setuid().  Changes to $> require a check to $!
897 to detect any possible errors after an attempted change. 
898
899 (Mnemonic: it's the uid you went I<to>, if you're running setuid.)
900 C<< $< >> and C<< $> >> can be swapped only on machines
901 supporting setreuid().
902
903 =item $REAL_GROUP_ID
904
905 =item $GID
906
907 =item $(
908 X<$(> X<$GID> X<$REAL_GROUP_ID>
909
910 The real gid of this process.  If you are on a machine that supports
911 membership in multiple groups simultaneously, gives a space separated
912 list of groups you are in.  The first number is the one returned by
913 getgid(), and the subsequent ones by getgroups(), one of which may be
914 the same as the first number.
915
916 However, a value assigned to C<$(> must be a single number used to
917 set the real gid.  So the value given by C<$(> should I<not> be assigned
918 back to C<$(> without being forced numeric, such as by adding zero.
919
920 You can change both the real gid and the effective gid at the same
921 time by using POSIX::setgid().  Changes to $( require a check to $!
922 to detect any possible errors after an attempted change.
923
924 (Mnemonic: parentheses are used to I<group> things.  The real gid is the
925 group you I<left>, if you're running setgid.)
926
927 =item $EFFECTIVE_GROUP_ID
928
929 =item $EGID
930
931 =item $)
932 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
933
934 The effective gid of this process.  If you are on a machine that
935 supports membership in multiple groups simultaneously, gives a space
936 separated list of groups you are in.  The first number is the one
937 returned by getegid(), and the subsequent ones by getgroups(), one of
938 which may be the same as the first number.
939
940 Similarly, a value assigned to C<$)> must also be a space-separated
941 list of numbers.  The first number sets the effective gid, and
942 the rest (if any) are passed to setgroups().  To get the effect of an
943 empty list for setgroups(), just repeat the new effective gid; that is,
944 to force an effective gid of 5 and an effectively empty setgroups()
945 list, say C< $) = "5 5" >.
946
947 You can change both the effective gid and the real gid at the same
948 time by using POSIX::setgid() (use only a single numeric argument).
949 Changes to $) require a check to $! to detect any possible errors
950 after an attempted change.
951
952 (Mnemonic: parentheses are used to I<group> things.  The effective gid
953 is the group that's I<right> for you, if you're running setgid.)
954
955 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
956 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
957 and C<$)> can be swapped only on machines supporting setregid().
958
959 =item $PROGRAM_NAME
960
961 =item $0
962 X<$0> X<$PROGRAM_NAME>
963
964 Contains the name of the program being executed.
965
966 On some (read: not all) operating systems assigning to C<$0> modifies
967 the argument area that the C<ps> program sees.  On some platforms you
968 may have to use special C<ps> options or a different C<ps> to see the
969 changes.  Modifying the $0 is more useful as a way of indicating the
970 current program state than it is for hiding the program you're
971 running.  (Mnemonic: same as B<sh> and B<ksh>.)
972
973 Note that there are platform specific limitations on the maximum
974 length of C<$0>.  In the most extreme case it may be limited to the
975 space occupied by the original C<$0>.
976
977 In some platforms there may be arbitrary amount of padding, for
978 example space characters, after the modified name as shown by C<ps>.
979 In some platforms this padding may extend all the way to the original
980 length of the argument area, no matter what you do (this is the case
981 for example with Linux 2.2).
982
983 Note for BSD users: setting C<$0> does not completely remove "perl"
984 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
985 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
986 and the " (perl)" suffix are shown depends on your exact BSD variant
987 and version).  This is an operating system feature, Perl cannot help it.
988
989 In multithreaded scripts Perl coordinates the threads so that any
990 thread may modify its copy of the C<$0> and the change becomes visible
991 to ps(1) (assuming the operating system plays along).  Note that
992 the view of C<$0> the other threads have will not change since they
993 have their own copies of it.
994
995 =item $[
996 X<$[>
997
998 The index of the first element in an array, and of the first character
999 in a substring.  Default is 0, but you could theoretically set it
1000 to 1 to make Perl behave more like B<awk> (or Fortran) when
1001 subscripting and when evaluating the index() and substr() functions.
1002 (Mnemonic: [ begins subscripts.)
1003
1004 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
1005 directive, and cannot influence the behavior of any other file.
1006 (That's why you can only assign compile-time constants to it.)
1007 Its use is highly discouraged.
1008
1009 Note that, unlike other compile-time directives (such as L<strict>),
1010 assignment to C<$[> can be seen from outer lexical scopes in the same file.
1011 However, you can use local() on it to strictly bind its value to a
1012 lexical block.
1013
1014 =item $]
1015 X<$]>
1016
1017 The version + patchlevel / 1000 of the Perl interpreter.  This variable
1018 can be used to determine whether the Perl interpreter executing a
1019 script is in the right range of versions.  (Mnemonic: Is this version
1020 of perl in the right bracket?)  Example:
1021
1022     warn "No checksumming!\n" if $] < 3.019;
1023
1024 See also the documentation of C<use VERSION> and C<require VERSION>
1025 for a convenient way to fail if the running Perl interpreter is too old.
1026
1027 The floating point representation can sometimes lead to inaccurate
1028 numeric comparisons.  See C<$^V> for a more modern representation of
1029 the Perl version that allows accurate string comparisons.
1030
1031 =item $COMPILING
1032
1033 =item $^C
1034 X<$^C> X<$COMPILING>
1035
1036 The current value of the flag associated with the B<-c> switch.
1037 Mainly of use with B<-MO=...> to allow code to alter its behavior
1038 when being compiled, such as for example to AUTOLOAD at compile
1039 time rather than normal, deferred loading.  See L<perlcc>.  Setting
1040 C<$^C = 1> is similar to calling C<B::minus_c>.
1041
1042 =item $DEBUGGING
1043
1044 =item $^D
1045 X<$^D> X<$DEBUGGING>
1046
1047 The current value of the debugging flags.  (Mnemonic: value of B<-D>
1048 switch.) May be read or set. Like its command-line equivalent, you can use
1049 numeric or symbolic values, eg C<$^D = 10> or C<$^D = "st">.
1050
1051 =item ${^RE_DEBUG_FLAGS}
1052
1053 The current value of the regex debugging flags. Set to 0 for no debug output
1054 even when the re 'debug' module is loaded. See L<re> for details.
1055
1056 =item ${^RE_TRIE_MAXBUF}
1057
1058 Controls how certain regex optimisations are applied and how much memory they
1059 utilize. This value by default is 65536 which corresponds to a 512kB temporary
1060 cache. Set this to a higher value to trade memory for speed when matching
1061 large alternations. Set it to a lower value if you want the optimisations to
1062 be as conservative of memory as possible but still occur, and set it to a
1063 negative value to prevent the optimisation and conserve the most memory.
1064 Under normal situations this variable should be of no interest to you.
1065
1066 =item $SYSTEM_FD_MAX
1067
1068 =item $^F
1069 X<$^F> X<$SYSTEM_FD_MAX>
1070
1071 The maximum system file descriptor, ordinarily 2.  System file
1072 descriptors are passed to exec()ed processes, while higher file
1073 descriptors are not.  Also, during an open(), system file descriptors are
1074 preserved even if the open() fails.  (Ordinary file descriptors are
1075 closed before the open() is attempted.)  The close-on-exec
1076 status of a file descriptor will be decided according to the value of
1077 C<$^F> when the corresponding file, pipe, or socket was opened, not the
1078 time of the exec().
1079
1080 =item $^H
1081
1082 WARNING: This variable is strictly for internal use only.  Its availability,
1083 behavior, and contents are subject to change without notice.
1084
1085 This variable contains compile-time hints for the Perl interpreter.  At the
1086 end of compilation of a BLOCK the value of this variable is restored to the
1087 value when the interpreter started to compile the BLOCK.
1088
1089 When perl begins to parse any block construct that provides a lexical scope
1090 (e.g., eval body, required file, subroutine body, loop body, or conditional
1091 block), the existing value of $^H is saved, but its value is left unchanged.
1092 When the compilation of the block is completed, it regains the saved value.
1093 Between the points where its value is saved and restored, code that
1094 executes within BEGIN blocks is free to change the value of $^H.
1095
1096 This behavior provides the semantic of lexical scoping, and is used in,
1097 for instance, the C<use strict> pragma.
1098
1099 The contents should be an integer; different bits of it are used for
1100 different pragmatic flags.  Here's an example:
1101
1102     sub add_100 { $^H |= 0x100 }
1103
1104     sub foo {
1105         BEGIN { add_100() }
1106         bar->baz($boon);
1107     }
1108
1109 Consider what happens during execution of the BEGIN block.  At this point
1110 the BEGIN block has already been compiled, but the body of foo() is still
1111 being compiled.  The new value of $^H will therefore be visible only while
1112 the body of foo() is being compiled.
1113
1114 Substitution of the above BEGIN block with:
1115
1116     BEGIN { require strict; strict->import('vars') }
1117
1118 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
1119 version of the same lexical pragma:
1120
1121     BEGIN { require strict; strict->import('vars') if $condition }
1122
1123 =item %^H
1124
1125 The %^H hash provides the same scoping semantic as $^H.  This makes it
1126 useful for implementation of lexically scoped pragmas. See L<perlpragma>.
1127
1128 =item $INPLACE_EDIT
1129
1130 =item $^I
1131 X<$^I> X<$INPLACE_EDIT>
1132
1133 The current value of the inplace-edit extension.  Use C<undef> to disable
1134 inplace editing.  (Mnemonic: value of B<-i> switch.)
1135
1136 =item $^M
1137 X<$^M>
1138
1139 By default, running out of memory is an untrappable, fatal error.
1140 However, if suitably built, Perl can use the contents of C<$^M>
1141 as an emergency memory pool after die()ing.  Suppose that your Perl
1142 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
1143 Then
1144
1145     $^M = 'a' x (1 << 16);
1146
1147 would allocate a 64K buffer for use in an emergency.  See the
1148 F<INSTALL> file in the Perl distribution for information on how to
1149 add custom C compilation flags when compiling perl.  To discourage casual
1150 use of this advanced feature, there is no L<English|English> long name for
1151 this variable.
1152
1153 =item $OSNAME
1154
1155 =item $^O
1156 X<$^O> X<$OSNAME>
1157
1158 The name of the operating system under which this copy of Perl was
1159 built, as determined during the configuration process.  The value
1160 is identical to C<$Config{'osname'}>.  See also L<Config> and the 
1161 B<-V> command-line switch documented in L<perlrun>.
1162
1163 In Windows platforms, $^O is not very helpful: since it is always
1164 C<MSWin32>, it doesn't tell the difference between
1165 95/98/ME/NT/2000/XP/CE/.NET.  Use Win32::GetOSName() or
1166 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
1167 between the variants.
1168
1169 =item ${^OPEN}
1170
1171 An internal variable used by PerlIO.  A string in two parts, separated
1172 by a C<\0> byte, the first part describes the input layers, the second
1173 part describes the output layers.
1174
1175 =item $PERLDB
1176
1177 =item $^P
1178 X<$^P> X<$PERLDB>
1179
1180 The internal variable for debugging support.  The meanings of the
1181 various bits are subject to change, but currently indicate:
1182
1183 =over 6
1184
1185 =item 0x01
1186
1187 Debug subroutine enter/exit.
1188
1189 =item 0x02
1190
1191 Line-by-line debugging.
1192
1193 =item 0x04
1194
1195 Switch off optimizations.
1196
1197 =item 0x08
1198
1199 Preserve more data for future interactive inspections.
1200
1201 =item 0x10
1202
1203 Keep info about source lines on which a subroutine is defined.
1204
1205 =item 0x20
1206
1207 Start with single-step on.
1208
1209 =item 0x40
1210
1211 Use subroutine address instead of name when reporting.
1212
1213 =item 0x80
1214
1215 Report C<goto &subroutine> as well.
1216
1217 =item 0x100
1218
1219 Provide informative "file" names for evals based on the place they were compiled.
1220
1221 =item 0x200
1222
1223 Provide informative names to anonymous subroutines based on the place they
1224 were compiled.
1225
1226 =item 0x400
1227
1228 Debug assertion subroutines enter/exit.
1229
1230 =back
1231
1232 Some bits may be relevant at compile-time only, some at
1233 run-time only.  This is a new mechanism and the details may change.
1234
1235 =item $LAST_REGEXP_CODE_RESULT
1236
1237 =item $^R
1238 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1239
1240 The result of evaluation of the last successful C<(?{ code })>
1241 regular expression assertion (see L<perlre>).  May be written to.
1242
1243 =item $EXCEPTIONS_BEING_CAUGHT
1244
1245 =item $^S
1246 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1247
1248 Current state of the interpreter.
1249
1250     $^S         State
1251     ---------   -------------------
1252     undef       Parsing module/eval
1253     true (1)    Executing an eval
1254     false (0)   Otherwise
1255
1256 The first state may happen in $SIG{__DIE__} and $SIG{__WARN__} handlers.
1257
1258 =item $BASETIME
1259
1260 =item $^T
1261 X<$^T> X<$BASETIME>
1262
1263 The time at which the program began running, in seconds since the
1264 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
1265 and B<-C> filetests are based on this value.
1266
1267 =item ${^TAINT}
1268
1269 Reflects if taint mode is on or off.  1 for on (the program was run with
1270 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
1271 B<-t> or B<-TU>).  This variable is read-only.
1272
1273 =item ${^UNICODE}
1274
1275 Reflects certain Unicode settings of Perl.  See L<perlrun>
1276 documentation for the C<-C> switch for more information about
1277 the possible values. This variable is set during Perl startup
1278 and is thereafter read-only.
1279
1280 =item ${^UTF8CACHE}
1281
1282 This variable controls the state of the internal UTF-8 offset caching code.
1283 1 for on (the default), 0 for off, -1 to debug the caching code by checking
1284 all its results against linear scans, and panicking on any discrepancy.
1285
1286 =item ${^UTF8LOCALE}
1287
1288 This variable indicates whether an UTF-8 locale was detected by perl at
1289 startup. This information is used by perl when it's in
1290 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
1291 switch); see L<perlrun> for more info on this.
1292
1293 =item $PERL_VERSION
1294
1295 =item $^V
1296 X<$^V> X<$PERL_VERSION>
1297
1298 The revision, version, and subversion of the Perl interpreter, represented
1299 as a string composed of characters with those ordinals.  Thus in Perl v5.6.0
1300 it equals C<chr(5) . chr(6) . chr(0)> and will return true for
1301 C<$^V eq v5.6.0>.  Note that the characters in this string value can
1302 potentially be in Unicode range.
1303
1304 This variable first appeared in perl 5.6.0; earlier versions of perl will
1305 see an undefined value.
1306
1307 This can be used to determine whether the Perl interpreter executing a
1308 script is in the right range of versions.  (Mnemonic: use ^V for Version
1309 Control.)  Example:
1310
1311     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
1312
1313 To convert C<$^V> into its string representation use sprintf()'s
1314 C<"%vd"> conversion:
1315
1316     printf "version is v%vd\n", $^V;  # Perl's version
1317
1318 See the documentation of C<use VERSION> and C<require VERSION>
1319 for a convenient way to fail if the running Perl interpreter is too old.
1320
1321 See also C<$]> for an older representation of the Perl version.
1322
1323 =item $WARNING
1324
1325 =item $^W
1326 X<$^W> X<$WARNING>
1327
1328 The current value of the warning switch, initially true if B<-w>
1329 was used, false otherwise, but directly modifiable.  (Mnemonic:
1330 related to the B<-w> switch.)  See also L<warnings>.
1331
1332 =item ${^WARNING_BITS}
1333
1334 The current set of warning checks enabled by the C<use warnings> pragma.
1335 See the documentation of C<warnings> for more details.
1336
1337 =item ${^WIN32_SLOPPY_STAT}
1338
1339 If this variable is set to a true value, then stat() on Windows will
1340 not try to open the file. This means that the link count cannot be
1341 determined and file attributes may be out of date if additional
1342 hardlinks to the file exist. On the other hand, not opening the file
1343 is considerably faster, especially for files on network drives.
1344
1345 This variable could be set in the F<sitecustomize.pl> file to
1346 configure the local Perl installation to use "sloppy" stat() by
1347 default.  See L<perlrun> for more information about site
1348 customization.
1349
1350 =item $EXECUTABLE_NAME
1351
1352 =item $^X
1353 X<$^X> X<$EXECUTABLE_NAME>
1354
1355 The name used to execute the current copy of Perl, from C's
1356 C<argv[0]> or (where supported) F</proc/self/exe>.
1357
1358 Depending on the host operating system, the value of $^X may be
1359 a relative or absolute pathname of the perl program file, or may
1360 be the string used to invoke perl but not the pathname of the
1361 perl program file.  Also, most operating systems permit invoking
1362 programs that are not in the PATH environment variable, so there
1363 is no guarantee that the value of $^X is in PATH.  For VMS, the
1364 value may or may not include a version number.
1365
1366 You usually can use the value of $^X to re-invoke an independent
1367 copy of the same perl that is currently running, e.g.,
1368
1369   @first_run = `$^X -le "print int rand 100 for 1..100"`;
1370
1371 But recall that not all operating systems support forking or
1372 capturing of the output of commands, so this complex statement
1373 may not be portable.
1374
1375 It is not safe to use the value of $^X as a path name of a file,
1376 as some operating systems that have a mandatory suffix on
1377 executable files do not require use of the suffix when invoking
1378 a command.  To convert the value of $^X to a path name, use the
1379 following statements:
1380
1381   # Build up a set of file names (not command names).
1382   use Config;
1383   $this_perl = $^X;
1384   if ($^O ne 'VMS')
1385      {$this_perl .= $Config{_exe}
1386           unless $this_perl =~ m/$Config{_exe}$/i;}
1387
1388 Because many operating systems permit anyone with read access to
1389 the Perl program file to make a copy of it, patch the copy, and
1390 then execute the copy, the security-conscious Perl programmer
1391 should take care to invoke the installed copy of perl, not the
1392 copy referenced by $^X.  The following statements accomplish
1393 this goal, and produce a pathname that can be invoked as a
1394 command or referenced as a file.
1395
1396   use Config;
1397   $secure_perl_path = $Config{perlpath};
1398   if ($^O ne 'VMS')
1399      {$secure_perl_path .= $Config{_exe}
1400           unless $secure_perl_path =~ m/$Config{_exe}$/i;}
1401
1402 =item ARGV
1403 X<ARGV>
1404
1405 The special filehandle that iterates over command-line filenames in
1406 C<@ARGV>. Usually written as the null filehandle in the angle operator
1407 C<< <> >>. Note that currently C<ARGV> only has its magical effect
1408 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1409 corresponding to the last file opened by C<< <> >>. In particular,
1410 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1411 may not cause your function to automatically read the contents of all the
1412 files in C<@ARGV>.
1413
1414 =item $ARGV
1415 X<$ARGV>
1416
1417 contains the name of the current file when reading from <>.
1418
1419 =item @ARGV
1420 X<@ARGV>
1421
1422 The array @ARGV contains the command-line arguments intended for
1423 the script.  C<$#ARGV> is generally the number of arguments minus
1424 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1425 command name itself.  See C<$0> for the command name.
1426
1427 =item ARGVOUT
1428 X<ARGVOUT>
1429
1430 The special filehandle that points to the currently open output file
1431 when doing edit-in-place processing with B<-i>.  Useful when you have
1432 to do a lot of inserting and don't want to keep modifying $_.  See
1433 L<perlrun> for the B<-i> switch.
1434
1435 =item @F
1436 X<@F>
1437
1438 The array @F contains the fields of each line read in when autosplit
1439 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
1440 is package-specific, and must be declared or given a full package name
1441 if not in package main when running under C<strict 'vars'>.
1442
1443 =item @INC
1444 X<@INC>
1445
1446 The array @INC contains the list of places that the C<do EXPR>,
1447 C<require>, or C<use> constructs look for their library files.  It
1448 initially consists of the arguments to any B<-I> command-line
1449 switches, followed by the default Perl library, probably
1450 F</usr/local/lib/perl>, followed by ".", to represent the current
1451 directory.  ("." will not be appended if taint checks are enabled, either by
1452 C<-T> or by C<-t>.)  If you need to modify this at runtime, you should use
1453 the C<use lib> pragma to get the machine-dependent library properly
1454 loaded also:
1455
1456     use lib '/mypath/libdir/';
1457     use SomeMod;
1458
1459 You can also insert hooks into the file inclusion system by putting Perl
1460 code directly into @INC.  Those hooks may be subroutine references, array
1461 references or blessed objects.  See L<perlfunc/require> for details.
1462
1463 =item @ARG
1464
1465 =item @_
1466 X<@_> X<@ARG>
1467
1468 Within a subroutine the array @_ contains the parameters passed to that
1469 subroutine.  See L<perlsub>.
1470
1471 =item %INC
1472 X<%INC>
1473
1474 The hash %INC contains entries for each filename included via the
1475 C<do>, C<require>, or C<use> operators.  The key is the filename
1476 you specified (with module names converted to pathnames), and the
1477 value is the location of the file found.  The C<require>
1478 operator uses this hash to determine whether a particular file has
1479 already been included.
1480
1481 If the file was loaded via a hook (e.g. a subroutine reference, see
1482 L<perlfunc/require> for a description of these hooks), this hook is
1483 by default inserted into %INC in place of a filename.  Note, however,
1484 that the hook may have set the %INC entry by itself to provide some more
1485 specific info.
1486
1487 =item %ENV
1488
1489 =item $ENV{expr}
1490 X<%ENV>
1491
1492 The hash %ENV contains your current environment.  Setting a
1493 value in C<ENV> changes the environment for any child processes
1494 you subsequently fork() off.
1495
1496 =item %SIG
1497
1498 =item $SIG{expr}
1499 X<%SIG>
1500
1501 The hash C<%SIG> contains signal handlers for signals.  For example:
1502
1503     sub handler {       # 1st argument is signal name
1504         my($sig) = @_;
1505         print "Caught a SIG$sig--shutting down\n";
1506         close(LOG);
1507         exit(0);
1508     }
1509
1510     $SIG{'INT'}  = \&handler;
1511     $SIG{'QUIT'} = \&handler;
1512     ...
1513     $SIG{'INT'}  = 'DEFAULT';   # restore default action
1514     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
1515
1516 Using a value of C<'IGNORE'> usually has the effect of ignoring the
1517 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
1518 this special case.
1519
1520 Here are some other examples:
1521
1522     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
1523     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
1524     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
1525     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
1526
1527 Be sure not to use a bareword as the name of a signal handler,
1528 lest you inadvertently call it. 
1529
1530 If your system has the sigaction() function then signal handlers are
1531 installed using it.  This means you get reliable signal handling.
1532
1533 The default delivery policy of signals changed in Perl 5.8.0 from 
1534 immediate (also known as "unsafe") to deferred, also known as 
1535 "safe signals".  See L<perlipc> for more information.
1536
1537 Certain internal hooks can be also set using the %SIG hash.  The
1538 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
1539 about to be printed.  The warning message is passed as the first
1540 argument.  The presence of a C<__WARN__> hook causes the ordinary printing
1541 of warnings to C<STDERR> to be suppressed.  You can use this to save warnings
1542 in a variable, or turn warnings into fatal errors, like this:
1543
1544     local $SIG{__WARN__} = sub { die $_[0] };
1545     eval $proggie;
1546
1547 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
1548 disable warnings using the empty subroutine:
1549
1550     local $SIG{__WARN__} = sub {};
1551
1552 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
1553 is about to be thrown.  The error message is passed as the first
1554 argument.  When a C<__DIE__> hook routine returns, the exception
1555 processing continues as it would have in the absence of the hook,
1556 unless the hook routine itself exits via a C<goto>, a loop exit, or a C<die()>.
1557 The C<__DIE__> handler is explicitly disabled during the call, so that you
1558 can die from a C<__DIE__> handler.  Similarly for C<__WARN__>.
1559
1560 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
1561 even inside an eval().  Do not use this to rewrite a pending exception
1562 in C<$@>, or as a bizarre substitute for overriding C<CORE::GLOBAL::die()>.
1563 This strange action at a distance may be fixed in a future release
1564 so that C<$SIG{__DIE__}> is only called if your program is about
1565 to exit, as was the original intent.  Any other use is deprecated.
1566
1567 C<__DIE__>/C<__WARN__> handlers are very special in one respect:
1568 they may be called to report (probable) errors found by the parser.
1569 In such a case the parser may be in inconsistent state, so any
1570 attempt to evaluate Perl code from such a handler will probably
1571 result in a segfault.  This means that warnings or errors that
1572 result from parsing Perl should be used with extreme caution, like
1573 this:
1574
1575     require Carp if defined $^S;
1576     Carp::confess("Something wrong") if defined &Carp::confess;
1577     die "Something wrong, but could not load Carp to give backtrace...
1578          To see backtrace try starting Perl with -MCarp switch";
1579
1580 Here the first line will load Carp I<unless> it is the parser who
1581 called the handler.  The second line will print backtrace and die if
1582 Carp was available.  The third line will be executed only if Carp was
1583 not available.
1584
1585 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
1586 L<warnings> for additional information.
1587
1588 =back
1589
1590 =head2 Error Indicators
1591 X<error> X<exception>
1592
1593 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1594 about different types of error conditions that may appear during
1595 execution of a Perl program.  The variables are shown ordered by
1596 the "distance" between the subsystem which reported the error and
1597 the Perl process.  They correspond to errors detected by the Perl
1598 interpreter, C library, operating system, or an external program,
1599 respectively.
1600
1601 To illustrate the differences between these variables, consider the 
1602 following Perl expression, which uses a single-quoted string:
1603
1604     eval q{
1605         open my $pipe, "/cdrom/install |" or die $!;
1606         my @res = <$pipe>;
1607         close $pipe or die "bad pipe: $?, $!";
1608     };
1609
1610 After execution of this statement all 4 variables may have been set.  
1611
1612 C<$@> is set if the string to be C<eval>-ed did not compile (this
1613 may happen if C<open> or C<close> were imported with bad prototypes),
1614 or if Perl code executed during evaluation die()d .  In these cases
1615 the value of $@ is the compile error, or the argument to C<die>
1616 (which will interpolate C<$!> and C<$?>).  (See also L<Fatal>,
1617 though.)
1618
1619 When the eval() expression above is executed, open(), C<< <PIPE> >>,
1620 and C<close> are translated to calls in the C run-time library and
1621 thence to the operating system kernel.  C<$!> is set to the C library's
1622 C<errno> if one of these calls fails. 
1623
1624 Under a few operating systems, C<$^E> may contain a more verbose
1625 error indicator, such as in this case, "CDROM tray not closed."
1626 Systems that do not support extended error messages leave C<$^E>
1627 the same as C<$!>.
1628
1629 Finally, C<$?> may be set to non-0 value if the external program
1630 F</cdrom/install> fails.  The upper eight bits reflect specific
1631 error conditions encountered by the program (the program's exit()
1632 value).   The lower eight bits reflect mode of failure, like signal
1633 death and core dump information  See wait(2) for details.  In
1634 contrast to C<$!> and C<$^E>, which are set only if error condition
1635 is detected, the variable C<$?> is set on each C<wait> or pipe
1636 C<close>, overwriting the old value.  This is more like C<$@>, which
1637 on every eval() is always set on failure and cleared on success.
1638
1639 For more details, see the individual descriptions at C<$@>, C<$!>, C<$^E>,
1640 and C<$?>.
1641
1642 =head2 Technical Note on the Syntax of Variable Names
1643
1644 Variable names in Perl can have several formats.  Usually, they
1645 must begin with a letter or underscore, in which case they can be
1646 arbitrarily long (up to an internal limit of 251 characters) and
1647 may contain letters, digits, underscores, or the special sequence
1648 C<::> or C<'>.  In this case, the part before the last C<::> or
1649 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
1650
1651 Perl variable names may also be a sequence of digits or a single
1652 punctuation or control character.  These names are all reserved for
1653 special uses by Perl; for example, the all-digits names are used
1654 to hold data captured by backreferences after a regular expression
1655 match.  Perl has a special syntax for the single-control-character
1656 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
1657 character.  For example, the notation C<$^W> (dollar-sign caret
1658 C<W>) is the scalar variable whose name is the single character
1659 control-C<W>.  This is better than typing a literal control-C<W>
1660 into your program.
1661
1662 Finally, new in Perl 5.6, Perl variable names may be alphanumeric
1663 strings that begin with control characters (or better yet, a caret).
1664 These variables must be written in the form C<${^Foo}>; the braces
1665 are not optional.  C<${^Foo}> denotes the scalar variable whose
1666 name is a control-C<F> followed by two C<o>'s.  These variables are
1667 reserved for future special uses by Perl, except for the ones that
1668 begin with C<^_> (control-underscore or caret-underscore).  No
1669 control-character name that begins with C<^_> will acquire a special
1670 meaning in any future version of Perl; such names may therefore be
1671 used safely in programs.  C<$^_> itself, however, I<is> reserved.
1672
1673 Perl identifiers that begin with digits, control characters, or
1674 punctuation characters are exempt from the effects of the C<package>
1675 declaration and are always forced to be in package C<main>; they are
1676 also exempt from C<strict 'vars'> errors.  A few other names are also
1677 exempt in these ways:
1678
1679         ENV             STDIN
1680         INC             STDOUT
1681         ARGV            STDERR
1682         ARGVOUT         _
1683         SIG
1684
1685 In particular, the new special C<${^_XYZ}> variables are always taken
1686 to be in package C<main>, regardless of any C<package> declarations
1687 presently in scope.  
1688
1689 =head1 BUGS
1690
1691 Due to an unfortunate accident of Perl's implementation, C<use
1692 English> imposes a considerable performance penalty on all regular
1693 expression matches in a program, regardless of whether they occur
1694 in the scope of C<use English>.  For that reason, saying C<use
1695 English> in libraries is strongly discouraged.  See the
1696 Devel::SawAmpersand module documentation from CPAN
1697 ( http://www.cpan.org/modules/by-module/Devel/ )
1698 for more information. Writing C<use English '-no_match_vars';>
1699 avoids the performance penalty.
1700
1701 Having to even think about the C<$^S> variable in your exception
1702 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
1703 invites grievous and difficult to track down errors.  Avoid it
1704 and use an C<END{}> or CORE::GLOBAL::die override instead.