This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Minor cleanup of RE tests and docs
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2
3 perlre - Perl regular expressions
4
5 =head1 DESCRIPTION
6
7 This page describes the syntax of regular expressions in Perl.  For a
8 description of how to I<use> regular expressions in matching
9 operations, plus various examples of the same, see discussion
10 of C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like Operators">.
11
12 The matching operations can have various modifiers.  The modifiers
13 that relate to the interpretation of the regular expression inside
14 are listed below.  For the modifiers that alter the way a regular expression
15 is used by Perl, see L<perlop/"Regexp Quote-Like Operators"> and 
16 L<perlop/"Gory details of parsing quoted constructs">.
17
18 =over 4
19
20 =item i
21
22 Do case-insensitive pattern matching.
23
24 If C<use locale> is in effect, the case map is taken from the current
25 locale.  See L<perllocale>.
26
27 =item m
28
29 Treat string as multiple lines.  That is, change "^" and "$" from matching
30 at only the very start or end of the string to the start or end of any
31 line anywhere within the string,
32
33 =item s
34
35 Treat string as single line.  That is, change "." to match any character
36 whatsoever, even a newline, which it normally would not match.
37
38 The C</s> and C</m> modifiers both override the C<$*> setting.  That is, no matter
39 what C<$*> contains, C</s> without C</m> will force "^" to match only at the
40 beginning of the string and "$" to match only at the end (or just before a
41 newline at the end) of the string.  Together, as /ms, they let the "." match
42 any character whatsoever, while yet allowing "^" and "$" to match,
43 respectively, just after and just before newlines within the string.
44
45 =item x
46
47 Extend your pattern's legibility by permitting whitespace and comments.
48
49 =back
50
51 These are usually written as "the C</x> modifier", even though the delimiter
52 in question might not actually be a slash.  In fact, any of these
53 modifiers may also be embedded within the regular expression itself using
54 the new C<(?...)> construct.  See below.
55
56 The C</x> modifier itself needs a little more explanation.  It tells
57 the regular expression parser to ignore whitespace that is neither
58 backslashed nor within a character class.  You can use this to break up
59 your regular expression into (slightly) more readable parts.  The C<#>
60 character is also treated as a metacharacter introducing a comment,
61 just as in ordinary Perl code.  This also means that if you want real
62 whitespace or C<#> characters in the pattern (outside of a character
63 class, where they are unaffected by C</x>), that you'll either have to 
64 escape them or encode them using octal or hex escapes.  Taken together,
65 these features go a long way towards making Perl's regular expressions
66 more readable.  Note that you have to be careful not to include the
67 pattern delimiter in the comment--perl has no way of knowing you did
68 not intend to close the pattern early.  See the C-comment deletion code
69 in L<perlop>.
70
71 =head2 Regular Expressions
72
73 The patterns used in pattern matching are regular expressions such as
74 those supplied in the Version 8 regex routines.  (In fact, the
75 routines are derived (distantly) from Henry Spencer's freely
76 redistributable reimplementation of the V8 routines.)
77 See L<Version 8 Regular Expressions> for details.
78
79 In particular the following metacharacters have their standard I<egrep>-ish
80 meanings:
81
82     \   Quote the next metacharacter
83     ^   Match the beginning of the line
84     .   Match any character (except newline)
85     $   Match the end of the line (or before newline at the end)
86     |   Alternation
87     ()  Grouping
88     []  Character class
89
90 By default, the "^" character is guaranteed to match at only the
91 beginning of the string, the "$" character at only the end (or before the
92 newline at the end) and Perl does certain optimizations with the
93 assumption that the string contains only one line.  Embedded newlines
94 will not be matched by "^" or "$".  You may, however, wish to treat a
95 string as a multi-line buffer, such that the "^" will match after any
96 newline within the string, and "$" will match before any newline.  At the
97 cost of a little more overhead, you can do this by using the /m modifier
98 on the pattern match operator.  (Older programs did this by setting C<$*>,
99 but this practice is now deprecated.)
100
101 To facilitate multi-line substitutions, the "." character never matches a
102 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
103 the string is a single line--even if it isn't.  The C</s> modifier also
104 overrides the setting of C<$*>, in case you have some (badly behaved) older
105 code that sets it in another module.
106
107 The following standard quantifiers are recognized:
108
109     *      Match 0 or more times
110     +      Match 1 or more times
111     ?      Match 1 or 0 times
112     {n}    Match exactly n times
113     {n,}   Match at least n times
114     {n,m}  Match at least n but not more than m times
115
116 (If a curly bracket occurs in any other context, it is treated
117 as a regular character.)  The "*" modifier is equivalent to C<{0,}>, the "+"
118 modifier to C<{1,}>, and the "?" modifier to C<{0,1}>.  n and m are limited
119 to integral values less than 65536.
120
121 By default, a quantified subpattern is "greedy", that is, it will match as
122 many times as possible (given a particular starting location) while still
123 allowing the rest of the pattern to match.  If you want it to match the
124 minimum number of times possible, follow the quantifier with a "?".  Note
125 that the meanings don't change, just the "greediness":
126
127     *?     Match 0 or more times
128     +?     Match 1 or more times
129     ??     Match 0 or 1 time
130     {n}?   Match exactly n times
131     {n,}?  Match at least n times
132     {n,m}? Match at least n but not more than m times
133
134 Because patterns are processed as double quoted strings, the following
135 also work:
136
137     \t          tab                   (HT, TAB)
138     \n          newline               (LF, NL)
139     \r          return                (CR)
140     \f          form feed             (FF)
141     \a          alarm (bell)          (BEL)
142     \e          escape (think troff)  (ESC)
143     \033        octal char (think of a PDP-11)
144     \x1B        hex char
145     \c[         control char
146     \l          lowercase next char (think vi)
147     \u          uppercase next char (think vi)
148     \L          lowercase till \E (think vi)
149     \U          uppercase till \E (think vi)
150     \E          end case modification (think vi)
151     \Q          quote (disable) pattern metacharacters till \E
152
153 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
154 and C<\U> is taken from the current locale.  See L<perllocale>.
155
156 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
157 An unescaped C<$> or C<@> interpolates the corresponding variable,
158 while escaping will cause the literal string C<\$> to be matched.
159 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
160
161 In addition, Perl defines the following:
162
163     \w  Match a "word" character (alphanumeric plus "_")
164     \W  Match a non-word character
165     \s  Match a whitespace character
166     \S  Match a non-whitespace character
167     \d  Match a digit character
168     \D  Match a non-digit character
169
170 A C<\w> matches a single alphanumeric character, not a whole
171 word.  To match a word you'd need to say C<\w+>.  If C<use locale> is in
172 effect, the list of alphabetic characters generated by C<\w> is taken
173 from the current locale.  See L<perllocale>. You may use C<\w>, C<\W>,
174 C<\s>, C<\S>, C<\d>, and C<\D> within character classes (though not as
175 either end of a range).
176
177 Perl defines the following zero-width assertions:
178
179     \b  Match a word boundary
180     \B  Match a non-(word boundary)
181     \A  Match only at beginning of string
182     \Z  Match only at end of string, or before newline at the end
183     \z  Match only at end of string
184     \G  Match only where previous m//g left off (works only with /g)
185
186 A word boundary (C<\b>) is defined as a spot between two characters that
187 has a C<\w> on one side of it and a C<\W> on the other side of it (in
188 either order), counting the imaginary characters off the beginning and
189 end of the string as matching a C<\W>.  (Within character classes C<\b>
190 represents backspace rather than a word boundary.)  The C<\A> and C<\Z> are
191 just like "^" and "$", except that they won't match multiple times when the
192 C</m> modifier is used, while "^" and "$" will match at every internal line
193 boundary.  To match the actual end of the string, not ignoring newline,
194 you can use C<\z>.  The C<\G> assertion can be used to chain global
195 matches (using C<m//g>), as described in
196 L<perlop/"Regexp Quote-Like Operators">.
197
198 It is also useful when writing C<lex>-like scanners, when you have several
199 patterns that you want to match against consequent substrings of your
200 string, see the previous reference.
201 The actual location where C<\G> will match can also be influenced
202 by using C<pos()> as an lvalue.  See L<perlfunc/pos>.
203
204 When the bracketing construct C<( ... )> is used, \E<lt>digitE<gt> matches the
205 digit'th substring.  Outside of the pattern, always use "$" instead of "\"
206 in front of the digit.  (While the \E<lt>digitE<gt> notation can on rare occasion work
207 outside the current pattern, this should not be relied upon.  See the
208 WARNING below.) The scope of $E<lt>digitE<gt> (and C<$`>, C<$&>, and C<$'>)
209 extends to the end of the enclosing BLOCK or eval string, or to the next
210 successful pattern match, whichever comes first.  If you want to use
211 parentheses to delimit a subpattern (e.g., a set of alternatives) without
212 saving it as a subpattern, follow the ( with a ?:.
213
214 You may have as many parentheses as you wish.  If you have more
215 than 9 substrings, the variables $10, $11, ... refer to the
216 corresponding substring.  Within the pattern, \10, \11, etc. refer back
217 to substrings if there have been at least that many left parentheses before
218 the backreference.  Otherwise (for backward compatibility) \10 is the
219 same as \010, a backspace, and \11 the same as \011, a tab.  And so
220 on.  (\1 through \9 are always backreferences.)
221
222 C<$+> returns whatever the last bracket match matched.  C<$&> returns the
223 entire matched string.  (C<$0> used to return the same thing, but not any
224 more.)  C<$`> returns everything before the matched string.  C<$'> returns
225 everything after the matched string.  Examples:
226
227     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
228
229     if (/Time: (..):(..):(..)/) {
230         $hours = $1;
231         $minutes = $2;
232         $seconds = $3;
233     }
234
235 Once perl sees that you need one of C<$&>, C<$`> or C<$'> anywhere in
236 the program, it has to provide them on each and every pattern match.
237 This can slow your program down.  The same mechanism that handles
238 these provides for the use of $1, $2, etc., so you pay the same price
239 for each pattern that contains capturing parentheses. But if you never
240 use $&, etc., in your script, then patterns I<without> capturing
241 parentheses won't be penalized. So avoid $&, $', and $` if you can,
242 but if you can't (and some algorithms really appreciate them), once
243 you've used them once, use them at will, because you've already paid
244 the price.  As of 5.005, $& is not so costly as the other two.
245
246 Backslashed metacharacters in Perl are
247 alphanumeric, such as C<\b>, C<\w>, C<\n>.  Unlike some other regular
248 expression languages, there are no backslashed symbols that aren't
249 alphanumeric.  So anything that looks like \\, \(, \), \E<lt>, \E<gt>,
250 \{, or \} is always interpreted as a literal character, not a
251 metacharacter.  This was once used in a common idiom to disable or
252 quote the special meanings of regular expression metacharacters in a
253 string that you want to use for a pattern. Simply quote all
254 non-alphanumeric characters:
255
256     $pattern =~ s/(\W)/\\$1/g;
257
258 Now it is much more common to see either the quotemeta() function or
259 the C<\Q> escape sequence used to disable all metacharacters' special
260 meanings like this:
261
262     /$unquoted\Q$quoted\E$unquoted/
263
264 Perl defines a consistent extension syntax for regular expressions.
265 The syntax is a pair of parentheses with a question mark as the first
266 thing within the parentheses (this was a syntax error in older
267 versions of Perl).  The character after the question mark gives the
268 function of the extension.  Several extensions are already supported:
269
270 =over 10
271
272 =item C<(?#text)>
273
274 A comment.  The text is ignored.  If the C</x> switch is used to enable
275 whitespace formatting, a simple C<#> will suffice.  Note that perl closes
276 the comment as soon as it sees a C<)>, so there is no way to put a literal
277 C<)> in the comment.
278
279 =item C<(?:pattern)>
280
281 =item C<(?imsx-imsx:pattern)>
282
283 This is for clustering, not capturing; it groups subexpressions like
284 "()", but doesn't make backreferences as "()" does.  So
285
286     @fields = split(/\b(?:a|b|c)\b/)
287
288 is like
289
290     @fields = split(/\b(a|b|c)\b/)
291
292 but doesn't spit out extra fields.
293
294 The letters between C<?> and C<:> act as flags modifiers, see
295 L<C<(?imsx-imsx)>>.  In particular,
296
297     /(?s-i:more.*than).*million/i
298
299 is equivalent to more verbose
300
301     /(?:(?s-i)more.*than).*million/i
302
303 =item C<(?=pattern)>
304
305 A zero-width positive lookahead assertion.  For example, C</\w+(?=\t)/>
306 matches a word followed by a tab, without including the tab in C<$&>.
307
308 =item C<(?!pattern)>
309
310 A zero-width negative lookahead assertion.  For example C</foo(?!bar)/>
311 matches any occurrence of "foo" that isn't followed by "bar".  Note
312 however that lookahead and lookbehind are NOT the same thing.  You cannot
313 use this for lookbehind.
314
315 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
316 will not do what you want.  That's because the C<(?!foo)> is just saying that
317 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
318 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
319 say "like" because there's the case of your "bar" not having three characters
320 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
321 Sometimes it's still easier just to say:
322
323     if (/bar/ && $` !~ /foo$/)
324
325 For lookbehind see below.
326
327 =item C<(?E<lt>=pattern)>
328
329 A zero-width positive lookbehind assertion.  For example, C</(?E<lt>=\t)\w+/>
330 matches a word following a tab, without including the tab in C<$&>.
331 Works only for fixed-width lookbehind.
332
333 =item C<(?<!pattern)>
334
335 A zero-width negative lookbehind assertion.  For example C</(?<!bar)foo/>
336 matches any occurrence of "foo" that isn't following "bar".  
337 Works only for fixed-width lookbehind.
338
339 =item C<(?{ code })>
340
341 Experimental "evaluate any Perl code" zero-width assertion.  Always
342 succeeds.  C<code> is not interpolated.  Currently the rules to
343 determine where the C<code> ends are somewhat convoluted.
344
345 The C<code> is properly scoped in the following sense: if the assertion
346 is backtracked (compare L<"Backtracking">), all the changes introduced after
347 C<local>isation are undone, so
348
349   $_ = 'a' x 8;
350   m< 
351      (?{ $cnt = 0 })                    # Initialize $cnt.
352      (
353        a 
354        (?{
355            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
356        })
357      )*  
358      aaaa
359      (?{ $res = $cnt })                 # On success copy to non-localized
360                                         # location.
361    >x;
362
363 will set C<$res = 4>.  Note that after the match $cnt returns to the globally
364 introduced value 0, since the scopes which restrict C<local> statements
365 are unwound.
366
367 This assertion may be used as L<C<(?(condition)yes-pattern|no-pattern)>>
368 switch.  If I<not> used in this way, the result of evaluation of C<code>
369 is put into variable $^R.  This happens immediately, so $^R can be used from
370 other C<(?{ code })> assertions inside the same regular expression.
371
372 The above assignment to $^R is properly localized, thus the old value of $^R
373 is restored if the assertion is backtracked (compare L<"Backtracking">).
374
375 Due to security concerns, this construction is not allowed if the regular
376 expression involves run-time interpolation of variables, unless 
377 C<use re 'eval'> pragma is used (see L<re>), or the variables contain
378 results of qr() operator (see L<perlop/"qr/STRING/imosx">).
379
380 This restriction is due to the wide-spread (questionable) practice of 
381 using the construct
382
383     $re = <>;
384     chomp $re;
385     $string =~ /$re/;
386
387 without tainting.  While this code is frowned upon from security point
388 of view, when C<(?{})> was introduced, it was considered bad to add 
389 I<new> security holes to existing scripts.
390
391 B<NOTE:>  Use of the above insecure snippet without also enabling taint mode
392 is to be severely frowned upon.  C<use re 'eval'> does not disable tainting
393 checks, thus to allow $re in the above snippet to contain C<(?{})>
394 I<with tainting enabled>, one needs both C<use re 'eval'> and untaint
395 the $re.
396
397 =item C<(?E<gt>pattern)>
398
399 An "independent" subexpression.  Matches the substring that a
400 I<standalone> C<pattern> would match if anchored at the given position,
401 B<and only this substring>.
402
403 Say, C<^(?E<gt>a*)ab> will never match, since C<(?E<gt>a*)> (anchored
404 at the beginning of string, as above) will match I<all> characters
405 C<a> at the beginning of string, leaving no C<a> for C<ab> to match.
406 In contrast, C<a*ab> will match the same as C<a+b>, since the match of
407 the subgroup C<a*> is influenced by the following group C<ab> (see
408 L<"Backtracking">).  In particular, C<a*> inside C<a*ab> will match
409 fewer characters than a standalone C<a*>, since this makes the tail match.
410
411 An effect similar to C<(?E<gt>pattern)> may be achieved by
412
413    (?=(pattern))\1
414
415 since the lookahead is in I<"logical"> context, thus matches the same
416 substring as a standalone C<a+>.  The following C<\1> eats the matched
417 string, thus making a zero-length assertion into an analogue of
418 C<(?E<gt>...)>.  (The difference between these two constructs is that the
419 second one uses a catching group, thus shifting ordinals of
420 backreferences in the rest of a regular expression.)
421
422 This construct is useful for optimizations of "eternal"
423 matches, because it will not backtrack (see L<"Backtracking">).  
424
425     m{ \(
426           ( 
427             [^()]+ 
428           | 
429             \( [^()]* \)
430           )+
431        \) 
432      }x
433
434 That will efficiently match a nonempty group with matching
435 two-or-less-level-deep parentheses.  However, if there is no such group,
436 it will take virtually forever on a long string.  That's because there are
437 so many different ways to split a long string into several substrings.
438 This is what C<(.+)+> is doing, and C<(.+)+> is similar to a subpattern
439 of the above pattern.  Consider that the above pattern detects no-match
440 on C<((()aaaaaaaaaaaaaaaaaa> in several seconds, but that  each extra
441 letter doubles this time.  This exponential performance will make it
442 appear that your program has hung.
443
444 However, a tiny modification of this pattern 
445
446     m{ \( 
447           ( 
448             (?> [^()]+ )
449           | 
450             \( [^()]* \)
451           )+
452        \) 
453      }x
454
455 which uses C<(?E<gt>...)> matches exactly when the one above does (verifying
456 this yourself would be a productive exercise), but finishes in a fourth
457 the time when used on a similar string with 1000000 C<a>s.  Be aware,
458 however, that this pattern currently triggers a warning message under
459 B<-w> saying it C<"matches the null string many times">):
460
461 On simple groups, such as the pattern C<(?> [^()]+ )>, a comparable
462 effect may be achieved by negative lookahead, as in C<[^()]+ (?! [^()] )>.
463 This was only 4 times slower on a string with 1000000 C<a>s.
464
465 =item C<(?(condition)yes-pattern|no-pattern)>
466
467 =item C<(?(condition)yes-pattern)>
468
469 Conditional expression.  C<(condition)> should be either an integer in
470 parentheses (which is valid if the corresponding pair of parentheses
471 matched), or lookahead/lookbehind/evaluate zero-width assertion.
472
473 Say,
474
475     m{ ( \( )? 
476        [^()]+ 
477        (?(1) \) ) 
478      }x
479
480 matches a chunk of non-parentheses, possibly included in parentheses
481 themselves.
482
483 =item C<(?imsx-imsx)>
484
485 One or more embedded pattern-match modifiers.  This is particularly
486 useful for patterns that are specified in a table somewhere, some of
487 which want to be case sensitive, and some of which don't.  The case
488 insensitive ones need to include merely C<(?i)> at the front of the
489 pattern.  For example:
490
491     $pattern = "foobar";
492     if ( /$pattern/i ) { } 
493
494     # more flexible:
495
496     $pattern = "(?i)foobar";
497     if ( /$pattern/ ) { } 
498
499 Letters after C<-> switch modifiers off.
500
501 These modifiers are localized inside an enclosing group (if any).  Say,
502
503     ( (?i) blah ) \s+ \1
504
505 (assuming C<x> modifier, and no C<i> modifier outside of this group)
506 will match a repeated (I<including the case>!) word C<blah> in any
507 case.
508
509 =back
510
511 A question mark was chosen for this and for the new minimal-matching
512 construct because 1) question mark is pretty rare in older regular
513 expressions, and 2) whenever you see one, you should stop and "question"
514 exactly what is going on.  That's psychology...
515
516 =head2 Backtracking
517
518 A fundamental feature of regular expression matching involves the
519 notion called I<backtracking>, which is currently used (when needed)
520 by all regular expression quantifiers, namely C<*>, C<*?>, C<+>,
521 C<+?>, C<{n,m}>, and C<{n,m}?>.
522
523 For a regular expression to match, the I<entire> regular expression must
524 match, not just part of it.  So if the beginning of a pattern containing a
525 quantifier succeeds in a way that causes later parts in the pattern to
526 fail, the matching engine backs up and recalculates the beginning
527 part--that's why it's called backtracking.
528
529 Here is an example of backtracking:  Let's say you want to find the
530 word following "foo" in the string "Food is on the foo table.":
531
532     $_ = "Food is on the foo table.";
533     if ( /\b(foo)\s+(\w+)/i ) {
534         print "$2 follows $1.\n";
535     }
536
537 When the match runs, the first part of the regular expression (C<\b(foo)>)
538 finds a possible match right at the beginning of the string, and loads up
539 $1 with "Foo".  However, as soon as the matching engine sees that there's
540 no whitespace following the "Foo" that it had saved in $1, it realizes its
541 mistake and starts over again one character after where it had the
542 tentative match.  This time it goes all the way until the next occurrence
543 of "foo". The complete regular expression matches this time, and you get
544 the expected output of "table follows foo."
545
546 Sometimes minimal matching can help a lot.  Imagine you'd like to match
547 everything between "foo" and "bar".  Initially, you write something
548 like this:
549
550     $_ =  "The food is under the bar in the barn.";
551     if ( /foo(.*)bar/ ) {
552         print "got <$1>\n";
553     }
554
555 Which perhaps unexpectedly yields:
556
557   got <d is under the bar in the >
558
559 That's because C<.*> was greedy, so you get everything between the
560 I<first> "foo" and the I<last> "bar".  In this case, it's more effective
561 to use minimal matching to make sure you get the text between a "foo"
562 and the first "bar" thereafter.
563
564     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
565   got <d is under the >
566
567 Here's another example: let's say you'd like to match a number at the end
568 of a string, and you also want to keep the preceding part the match.
569 So you write this:
570
571     $_ = "I have 2 numbers: 53147";
572     if ( /(.*)(\d*)/ ) {                                # Wrong!
573         print "Beginning is <$1>, number is <$2>.\n";
574     }
575
576 That won't work at all, because C<.*> was greedy and gobbled up the
577 whole string. As C<\d*> can match on an empty string the complete
578 regular expression matched successfully.
579
580     Beginning is <I have 2 numbers: 53147>, number is <>.
581
582 Here are some variants, most of which don't work:
583
584     $_ = "I have 2 numbers: 53147";
585     @pats = qw{
586         (.*)(\d*)
587         (.*)(\d+)
588         (.*?)(\d*)
589         (.*?)(\d+)
590         (.*)(\d+)$
591         (.*?)(\d+)$
592         (.*)\b(\d+)$
593         (.*\D)(\d+)$
594     };
595
596     for $pat (@pats) {
597         printf "%-12s ", $pat;
598         if ( /$pat/ ) {
599             print "<$1> <$2>\n";
600         } else {
601             print "FAIL\n";
602         }
603     }
604
605 That will print out:
606
607     (.*)(\d*)    <I have 2 numbers: 53147> <>
608     (.*)(\d+)    <I have 2 numbers: 5314> <7>
609     (.*?)(\d*)   <> <>
610     (.*?)(\d+)   <I have > <2>
611     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
612     (.*?)(\d+)$  <I have 2 numbers: > <53147>
613     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
614     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
615
616 As you see, this can be a bit tricky.  It's important to realize that a
617 regular expression is merely a set of assertions that gives a definition
618 of success.  There may be 0, 1, or several different ways that the
619 definition might succeed against a particular string.  And if there are
620 multiple ways it might succeed, you need to understand backtracking to
621 know which variety of success you will achieve.
622
623 When using lookahead assertions and negations, this can all get even
624 tricker.  Imagine you'd like to find a sequence of non-digits not
625 followed by "123".  You might try to write that as
626
627     $_ = "ABC123";
628     if ( /^\D*(?!123)/ ) {              # Wrong!
629         print "Yup, no 123 in $_\n";
630     }
631
632 But that isn't going to match; at least, not the way you're hoping.  It
633 claims that there is no 123 in the string.  Here's a clearer picture of
634 why it that pattern matches, contrary to popular expectations:
635
636     $x = 'ABC123' ;
637     $y = 'ABC445' ;
638
639     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/ ;
640     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/ ;
641
642     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/ ;
643     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/ ;
644
645 This prints
646
647     2: got ABC
648     3: got AB
649     4: got ABC
650
651 You might have expected test 3 to fail because it seems to a more
652 general purpose version of test 1.  The important difference between
653 them is that test 3 contains a quantifier (C<\D*>) and so can use
654 backtracking, whereas test 1 will not.  What's happening is
655 that you've asked "Is it true that at the start of $x, following 0 or more
656 non-digits, you have something that's not 123?"  If the pattern matcher had
657 let C<\D*> expand to "ABC", this would have caused the whole pattern to
658 fail.
659 The search engine will initially match C<\D*> with "ABC".  Then it will
660 try to match C<(?!123> with "123", which of course fails.  But because
661 a quantifier (C<\D*>) has been used in the regular expression, the
662 search engine can backtrack and retry the match differently
663 in the hope of matching the complete regular expression.
664
665 The pattern really, I<really> wants to succeed, so it uses the
666 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
667 time.  Now there's indeed something following "AB" that is not
668 "123".  It's in fact "C123", which suffices.
669
670 We can deal with this by using both an assertion and a negation.  We'll
671 say that the first part in $1 must be followed by a digit, and in fact, it
672 must also be followed by something that's not "123".  Remember that the
673 lookaheads are zero-width expressions--they only look, but don't consume
674 any of the string in their match.  So rewriting this way produces what
675 you'd expect; that is, case 5 will fail, but case 6 succeeds:
676
677     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/ ;
678     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/ ;
679
680     6: got ABC
681
682 In other words, the two zero-width assertions next to each other work as though
683 they're ANDed together, just as you'd use any builtin assertions:  C</^$/>
684 matches only if you're at the beginning of the line AND the end of the
685 line simultaneously.  The deeper underlying truth is that juxtaposition in
686 regular expressions always means AND, except when you write an explicit OR
687 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
688 although the attempted matches are made at different positions because "a"
689 is not a zero-width assertion, but a one-width assertion.
690
691 One warning: particularly complicated regular expressions can take
692 exponential time to solve due to the immense number of possible ways they
693 can use backtracking to try match.  For example this will take a very long
694 time to run
695
696     /((a{0,5}){0,5}){0,5}/
697
698 And if you used C<*>'s instead of limiting it to 0 through 5 matches, then
699 it would take literally forever--or until you ran out of stack space.
700
701 A powerful tool for optimizing such beasts is "independent" groups,
702 which do not backtrace (see L<C<(?E<gt>pattern)>>).  Note also that
703 zero-length lookahead/lookbehind assertions will not backtrace to make
704 the tail match, since they are in "logical" context: only the fact
705 whether they match or not is considered relevant.  For an example
706 where side-effects of a lookahead I<might> have influenced the
707 following match, see L<C<(?E<gt>pattern)>>.
708
709 =head2 Version 8 Regular Expressions
710
711 In case you're not familiar with the "regular" Version 8 regex
712 routines, here are the pattern-matching rules not described above.
713
714 Any single character matches itself, unless it is a I<metacharacter>
715 with a special meaning described here or above.  You can cause
716 characters that normally function as metacharacters to be interpreted
717 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
718 character; "\\" matches a "\").  A series of characters matches that
719 series of characters in the target string, so the pattern C<blurfl>
720 would match "blurfl" in the target string.
721
722 You can specify a character class, by enclosing a list of characters
723 in C<[]>, which will match any one character from the list.  If the
724 first character after the "[" is "^", the class matches any character not
725 in the list.  Within a list, the "-" character is used to specify a
726 range, so that C<a-z> represents all characters between "a" and "z",
727 inclusive.  If you want "-" itself to be a member of a class, put it
728 at the start or end of the list, or escape it with a backslash.  (The
729 following all specify the same class of three characters: C<[-az]>,
730 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
731 specifies a class containing twenty-six characters.)
732
733 Characters may be specified using a metacharacter syntax much like that
734 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
735 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
736 of octal digits, matches the character whose ASCII value is I<nnn>.
737 Similarly, \xI<nn>, where I<nn> are hexadecimal digits, matches the
738 character whose ASCII value is I<nn>. The expression \cI<x> matches the
739 ASCII character control-I<x>.  Finally, the "." metacharacter matches any
740 character except "\n" (unless you use C</s>).
741
742 You can specify a series of alternatives for a pattern using "|" to
743 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
744 or "foe" in the target string (as would C<f(e|i|o)e>).  The
745 first alternative includes everything from the last pattern delimiter
746 ("(", "[", or the beginning of the pattern) up to the first "|", and
747 the last alternative contains everything from the last "|" to the next
748 pattern delimiter.  For this reason, it's common practice to include
749 alternatives in parentheses, to minimize confusion about where they
750 start and end.
751
752 Alternatives are tried from left to right, so the first
753 alternative found for which the entire expression matches, is the one that
754 is chosen. This means that alternatives are not necessarily greedy. For
755 example: when mathing C<foo|foot> against "barefoot", only the "foo"
756 part will match, as that is the first alternative tried, and it successfully
757 matches the target string. (This might not seem important, but it is
758 important when you are capturing matched text using parentheses.)
759
760 Also remember that "|" is interpreted as a literal within square brackets,
761 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
762
763 Within a pattern, you may designate subpatterns for later reference by
764 enclosing them in parentheses, and you may refer back to the I<n>th
765 subpattern later in the pattern using the metacharacter \I<n>.
766 Subpatterns are numbered based on the left to right order of their
767 opening parenthesis.  A backreference matches whatever
768 actually matched the subpattern in the string being examined, not the
769 rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
770 match "0x1234 0x4321", but not "0x1234 01234", because subpattern 1
771 actually matched "0x", even though the rule C<0|0x> could
772 potentially match the leading 0 in the second number.
773
774 =head2 WARNING on \1 vs $1
775
776 Some people get too used to writing things like:
777
778     $pattern =~ s/(\W)/\\\1/g;
779
780 This is grandfathered for the RHS of a substitute to avoid shocking the
781 B<sed> addicts, but it's a dirty habit to get into.  That's because in
782 PerlThink, the righthand side of a C<s///> is a double-quoted string.  C<\1> in
783 the usual double-quoted string means a control-A.  The customary Unix
784 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
785 of doing that, you get yourself into trouble if you then add an C</e>
786 modifier.
787
788     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
789
790 Or if you try to do
791
792     s/(\d+)/\1000/;
793
794 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
795 C<${1}000>.  Basically, the operation of interpolation should not be confused
796 with the operation of matching a backreference.  Certainly they mean two
797 different things on the I<left> side of the C<s///>.
798
799 =head2 Repeated patterns matching zero-length substring
800
801 WARNING: Difficult material (and prose) ahead.  This section needs a rewrite.
802
803 Regular expressions provide a terse and powerful programming language.  As
804 with most other power tools, power comes together with the ability
805 to wreak havoc.
806
807 A common abuse of this power stems from the ability to make infinite
808 loops using regular expressions, with something as innocous as:
809
810     'foo' =~ m{ ( o? )* }x;
811
812 The C<o?> can match at the beginning of C<'foo'>, and since the position
813 in the string is not moved by the match, C<o?> would match again and again
814 due to the C<*> modifier.  Another common way to create a similar cycle
815 is with the looping modifier C<//g>:
816
817     @matches = ( 'foo' =~ m{ o? }xg );
818
819 or
820
821     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
822
823 or the loop implied by split().
824
825 However, long experience has shown that many programming tasks may
826 be significantly simplified by using repeated subexpressions which
827 may match zero-length substrings, with a simple example being:
828
829     @chars = split //, $string;           # // is not magic in split
830     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
831
832 Thus Perl allows the C</()/> construct, which I<forcefully breaks
833 the infinite loop>.  The rules for this are different for lower-level
834 loops given by the greedy modifiers C<*+{}>, and for higher-level
835 ones like the C</g> modifier or split() operator.
836
837 The lower-level loops are I<interrupted> when it is detected that a 
838 repeated expression did match a zero-length substring, thus
839
840    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
841
842 is made equivalent to 
843
844    m{   (?: NON_ZERO_LENGTH )* 
845       | 
846         (?: ZERO_LENGTH )? 
847     }x;
848
849 The higher level-loops preserve an additional state between iterations:
850 whether the last match was zero-length.  To break the loop, the following 
851 match after a zero-length match is prohibited to have a length of zero.
852 This prohibition interacts with backtracking (see L<"Backtracking">), 
853 and so the I<second best> match is chosen if the I<best> match is of
854 zero length.
855
856 Say,
857
858     $_ = 'bar';
859     s/\w??/<$&>/g;
860
861 results in C<"<><b><><a><><r><>">.  At each position of the string the best
862 match given by non-greedy C<??> is the zero-length match, and the I<second 
863 best> match is what is matched by C<\w>.  Thus zero-length matches
864 alternate with one-character-long matches.
865
866 Similarly, for repeated C<m/()/g> the second-best match is the match at the 
867 position one notch further in the string.
868
869 The additional state of being I<matched with zero-length> is associated to
870 the matched string, and is reset by each assignment to pos().
871
872 =head2 Creating custom RE engines
873
874 Overloaded constants (see L<overload>) provide a simple way to extend
875 the functionality of the RE engine.
876
877 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
878 matches at boundary between white-space characters and non-whitespace
879 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
880 at these positions, so we want to have each C<\Y|> in the place of the
881 more complicated version.  We can create a module C<customre> to do
882 this:
883
884     package customre;
885     use overload;
886
887     sub import {
888       shift;
889       die "No argument to customre::import allowed" if @_;
890       overload::constant 'qr' => \&convert;
891     }
892
893     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
894
895     my %rules = ( '\\' => '\\', 
896                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
897     sub convert {
898       my $re = shift;
899       $re =~ s{ 
900                 \\ ( \\ | Y . )
901               }
902               { $rules{$1} or invalid($re,$1) }sgex; 
903       return $re;
904     }
905
906 Now C<use customre> enables the new escape in constant regular
907 expressions, i.e., those without any runtime variable interpolations.
908 As documented in L<overload>, this conversion will work only over
909 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
910 part of this regular expression needs to be converted explicitly
911 (but only if the special meaning of C<\Y|> should be enabled inside $re):
912
913     use customre;
914     $re = <>;
915     chomp $re;
916     $re = customre::convert $re;
917     /\Y|$re\Y|/;
918
919 =head2 SEE ALSO
920
921 L<perlop/"Regexp Quote-Like Operators">.
922
923 L<perlop/"Gory details of parsing quoted constructs">.
924
925 L<perlfunc/pos>.
926
927 L<perllocale>.
928
929 I<Mastering Regular Expressions> (see L<perlbook>) by Jeffrey Friedl.