This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
86ba9140973686b8f52b9289e2a67c856ef622fa
[perl5.git] / pod / perlipc.pod
1 =head1 NAME
2
3 perlipc - Perl interprocess communication (signals, fifos, pipes, safe subprocesses, sockets, and semaphores)
4
5 =head1 DESCRIPTION
6
7 The basic IPC facilities of Perl are built out of the good old Unix
8 signals, named pipes, pipe opens, the Berkeley socket routines, and SysV
9 IPC calls.  Each is used in slightly different situations.
10
11 =head1 Signals
12
13 Perl uses a simple signal handling model: the %SIG hash contains names
14 or references of user-installed signal handlers.  These handlers will
15 be called with an argument which is the name of the signal that
16 triggered it.  A signal may be generated intentionally from a
17 particular keyboard sequence like control-C or control-Z, sent to you
18 from another process, or triggered automatically by the kernel when
19 special events transpire, like a child process exiting, your own process
20 running out of stack space, or hitting a process file-size limit.
21
22 For example, to trap an interrupt signal, set up a handler like this:
23
24     our $shucks;
25
26     sub catch_zap {
27         my $signame = shift;
28         $shucks++;
29         die "Somebody sent me a SIG$signame";
30     }
31     $SIG{INT} = __PACKAGE__ . "::catch_zap";
32     $SIG{INT} = \&catch_zap;  # best strategy
33
34 Prior to Perl 5.8.0 it was necessary to do as little as you possibly
35 could in your handler; notice how all we do is set a global variable
36 and then raise an exception.  That's because on most systems,
37 libraries are not re-entrant; particularly, memory allocation and I/O
38 routines are not.  That meant that doing nearly I<anything> in your
39 handler could in theory trigger a memory fault and subsequent core
40 dump - see L</Deferred Signals (Safe Signals)> below.
41
42 The names of the signals are the ones listed out by C<kill -l> on your
43 system, or you can retrieve them using the CPAN module L<IPC::Signal>.
44
45 You may also choose to assign the strings C<"IGNORE"> or C<"DEFAULT"> as
46 the handler, in which case Perl will try to discard the signal or do the
47 default thing.
48
49 On most Unix platforms, the C<CHLD> (sometimes also known as C<CLD>) signal
50 has special behavior with respect to a value of C<"IGNORE">.
51 Setting C<$SIG{CHLD}> to C<"IGNORE"> on such a platform has the effect of
52 not creating zombie processes when the parent process fails to C<wait()>
53 on its child processes (i.e., child processes are automatically reaped).
54 Calling C<wait()> with C<$SIG{CHLD}> set to C<"IGNORE"> usually returns
55 C<-1> on such platforms.
56
57 Some signals can be neither trapped nor ignored, such as the KILL and STOP
58 (but not the TSTP) signals. Note that ignoring signals makes them disappear.
59 If you only want them blocked temporarily without them getting lost you'll
60 have to use POSIX' sigprocmask.
61
62 Sending a signal to a negative process ID means that you send the signal
63 to the entire Unix process group.  This code sends a hang-up signal to all
64 processes in the current process group, and also sets $SIG{HUP} to C<"IGNORE">
65 so it doesn't kill itself:
66
67     # block scope for local
68     {
69         local $SIG{HUP} = "IGNORE";
70         kill HUP => -getpgrp();
71         # snazzy writing of: kill("HUP", -getpgrp())
72     }
73
74 Another interesting signal to send is signal number zero.  This doesn't
75 actually affect a child process, but instead checks whether it's alive
76 or has changed its UIDs.
77
78     unless (kill 0 => $kid_pid) {
79         warn "something wicked happened to $kid_pid";
80     }
81
82 Signal number zero may fail because you lack permission to send the
83 signal when directed at a process whose real or saved UID is not
84 identical to the real or effective UID of the sending process, even
85 though the process is alive.  You may be able to determine the cause of
86 failure using C<$!> or C<%!>.
87
88     unless (kill(0 => $pid) || $!{EPERM}) {
89         warn "$pid looks dead";
90     }
91
92 You might also want to employ anonymous functions for simple signal
93 handlers:
94
95     $SIG{INT} = sub { die "\nOutta here!\n" };
96
97 SIGCHLD handlers require some special care.  If a second child dies
98 while in the signal handler caused by the first death, we won't get
99 another signal. So must loop here else we will leave the unreaped child
100 as a zombie. And the next time two children die we get another zombie.
101 And so on.
102
103     use POSIX ":sys_wait_h";
104     $SIG{CHLD} = sub {
105         while ((my $child = waitpid(-1, WNOHANG)) > 0) {
106             $Kid_Status{$child} = $?;
107         }
108     };
109     # do something that forks...
110
111 Be careful: qx(), system(), and some modules for calling external commands
112 do a fork(), then wait() for the result. Thus, your signal handler
113 will be called. Because wait() was already called by system() or qx(),
114 the wait() in the signal handler will see no more zombies and will
115 therefore block.
116
117 The best way to prevent this issue is to use waitpid(), as in the following
118 example:
119
120     use POSIX ":sys_wait_h"; # for nonblocking read
121
122     my %children;
123
124     $SIG{CHLD} = sub {
125         # don't change $! and $? outside handler
126         local ($!, $?);
127         while ( (my $pid = waitpid(-1, WNOHANG)) > 0 ) {
128             delete $children{$pid};
129             cleanup_child($pid, $?);
130         }
131     };
132
133     while (1) {
134         my $pid = fork();
135         die "cannot fork" unless defined $pid;
136         if ($pid == 0) {
137             # ...
138             exit 0;
139         } else {
140             $children{$pid}=1;
141             # ...
142             system($command);
143             # ...
144        }
145     }
146
147 Signal handling is also used for timeouts in Unix.  While safely
148 protected within an C<eval{}> block, you set a signal handler to trap
149 alarm signals and then schedule to have one delivered to you in some
150 number of seconds.  Then try your blocking operation, clearing the alarm
151 when it's done but not before you've exited your C<eval{}> block.  If it
152 goes off, you'll use die() to jump out of the block.
153
154 Here's an example:
155
156     my $ALARM_EXCEPTION = "alarm clock restart";
157     eval {
158         local $SIG{ALRM} = sub { die $ALARM_EXCEPTION };
159         alarm 10;
160         flock($fh, 2)    # blocking write lock
161                         || die "cannot flock: $!";
162         alarm 0;
163     };
164     if ($@ && $@ !~ quotemeta($ALARM_EXCEPTION)) { die }
165
166 If the operation being timed out is system() or qx(), this technique
167 is liable to generate zombies.    If this matters to you, you'll
168 need to do your own fork() and exec(), and kill the errant child process.
169
170 For more complex signal handling, you might see the standard POSIX
171 module.  Lamentably, this is almost entirely undocumented, but the
172 F<ext/POSIX/t/sigaction.t> file from the Perl source distribution has
173 some examples in it.
174
175 =head2 Handling the SIGHUP Signal in Daemons
176
177 A process that usually starts when the system boots and shuts down
178 when the system is shut down is called a daemon (Disk And Execution
179 MONitor). If a daemon process has a configuration file which is
180 modified after the process has been started, there should be a way to
181 tell that process to reread its configuration file without stopping
182 the process. Many daemons provide this mechanism using a C<SIGHUP>
183 signal handler. When you want to tell the daemon to reread the file,
184 simply send it the C<SIGHUP> signal.
185
186 The following example implements a simple daemon, which restarts
187 itself every time the C<SIGHUP> signal is received. The actual code is
188 located in the subroutine C<code()>, which just prints some debugging
189 info to show that it works; it should be replaced with the real code.
190
191   #!/usr/bin/perl
192
193   use strict;
194   use warnings;
195
196   use POSIX ();
197   use FindBin ();
198   use File::Basename ();
199   use File::Spec::Functions qw(catfile);
200
201   $| = 1;
202
203   # make the daemon cross-platform, so exec always calls the script
204   # itself with the right path, no matter how the script was invoked.
205   my $script = File::Basename::basename($0);
206   my $SELF  = catfile($FindBin::Bin, $script);
207
208   # POSIX unmasks the sigprocmask properly
209   $SIG{HUP} = sub {
210       print "got SIGHUP\n";
211       exec($SELF, @ARGV)        || die "$0: couldn't restart: $!";
212   };
213
214   code();
215
216   sub code {
217       print "PID: $$\n";
218       print "ARGV: @ARGV\n";
219       my $count = 0;
220       while (1) {
221           sleep 2;
222           print ++$count, "\n";
223       }
224   }
225
226
227 =head2 Deferred Signals (Safe Signals)
228
229 Before Perl 5.8.0, installing Perl code to deal with signals exposed you to
230 danger from two things.  First, few system library functions are
231 re-entrant.  If the signal interrupts while Perl is executing one function
232 (like malloc(3) or printf(3)), and your signal handler then calls the same
233 function again, you could get unpredictable behavior--often, a core dump.
234 Second, Perl isn't itself re-entrant at the lowest levels.  If the signal
235 interrupts Perl while Perl is changing its own internal data structures,
236 similarly unpredictable behavior may result.
237
238 There were two things you could do, knowing this: be paranoid or be
239 pragmatic.  The paranoid approach was to do as little as possible in your
240 signal handler.  Set an existing integer variable that already has a
241 value, and return.  This doesn't help you if you're in a slow system call,
242 which will just restart.  That means you have to C<die> to longjmp(3) out
243 of the handler.  Even this is a little cavalier for the true paranoiac,
244 who avoids C<die> in a handler because the system I<is> out to get you.
245 The pragmatic approach was to say "I know the risks, but prefer the
246 convenience", and to do anything you wanted in your signal handler,
247 and be prepared to clean up core dumps now and again.
248
249 Perl 5.8.0 and later avoid these problems by "deferring" signals.  That is,
250 when the signal is delivered to the process by the system (to the C code
251 that implements Perl) a flag is set, and the handler returns immediately.
252 Then at strategic "safe" points in the Perl interpreter (e.g. when it is
253 about to execute a new opcode) the flags are checked and the Perl level
254 handler from %SIG is executed. The "deferred" scheme allows much more
255 flexibility in the coding of signal handlers as we know the Perl
256 interpreter is in a safe state, and that we are not in a system library
257 function when the handler is called.  However the implementation does
258 differ from previous Perls in the following ways:
259
260 =over 4
261
262 =item Long-running opcodes
263
264 As the Perl interpreter looks at signal flags only when it is about
265 to execute a new opcode, a signal that arrives during a long-running
266 opcode (e.g. a regular expression operation on a very large string) will
267 not be seen until the current opcode completes.
268
269 If a signal of any given type fires multiple times during an opcode
270 (such as from a fine-grained timer), the handler for that signal will
271 be called only once, after the opcode completes; all other
272 instances will be discarded.  Furthermore, if your system's signal queue
273 gets flooded to the point that there are signals that have been raised
274 but not yet caught (and thus not deferred) at the time an opcode
275 completes, those signals may well be caught and deferred during
276 subsequent opcodes, with sometimes surprising results.  For example, you
277 may see alarms delivered even after calling C<alarm(0)> as the latter
278 stops the raising of alarms but does not cancel the delivery of alarms
279 raised but not yet caught.  Do not depend on the behaviors described in
280 this paragraph as they are side effects of the current implementation and
281 may change in future versions of Perl.
282
283 =item Interrupting IO
284
285 When a signal is delivered (e.g., SIGINT from a control-C) the operating
286 system breaks into IO operations like I<read>(2), which is used to
287 implement Perl's readline() function, the C<< <> >> operator. On older
288 Perls the handler was called immediately (and as C<read> is not "unsafe",
289 this worked well). With the "deferred" scheme the handler is I<not> called
290 immediately, and if Perl is using the system's C<stdio> library that
291 library may restart the C<read> without returning to Perl to give it a
292 chance to call the %SIG handler. If this happens on your system the
293 solution is to use the C<:perlio> layer to do IO--at least on those handles
294 that you want to be able to break into with signals. (The C<:perlio> layer
295 checks the signal flags and calls %SIG handlers before resuming IO
296 operation.)
297
298 The default in Perl 5.8.0 and later is to automatically use
299 the C<:perlio> layer.
300
301 Note that it is not advisable to access a file handle within a signal
302 handler where that signal has interrupted an I/O operation on that same
303 handle. While perl will at least try hard not to crash, there are no
304 guarantees of data integrity; for example, some data might get dropped or
305 written twice.
306
307 Some networking library functions like gethostbyname() are known to have
308 their own implementations of timeouts which may conflict with your
309 timeouts.  If you have problems with such functions, try using the POSIX
310 sigaction() function, which bypasses Perl safe signals.  Be warned that
311 this does subject you to possible memory corruption, as described above.
312
313 Instead of setting C<$SIG{ALRM}>:
314
315    local $SIG{ALRM} = sub { die "alarm" };
316
317 try something like the following:
318
319  use POSIX qw(SIGALRM);
320  POSIX::sigaction(SIGALRM,
321                   POSIX::SigAction->new(sub { die "alarm" }))
322           || die "Error setting SIGALRM handler: $!\n";
323
324 Another way to disable the safe signal behavior locally is to use
325 the C<Perl::Unsafe::Signals> module from CPAN, which affects
326 all signals.
327
328 =item Restartable system calls
329
330 On systems that supported it, older versions of Perl used the
331 SA_RESTART flag when installing %SIG handlers.  This meant that
332 restartable system calls would continue rather than returning when
333 a signal arrived.  In order to deliver deferred signals promptly,
334 Perl 5.8.0 and later do I<not> use SA_RESTART.  Consequently,
335 restartable system calls can fail (with $! set to C<EINTR>) in places
336 where they previously would have succeeded.
337
338 The default C<:perlio> layer retries C<read>, C<write>
339 and C<close> as described above; interrupted C<wait> and
340 C<waitpid> calls will always be retried.
341
342 =item Signals as "faults"
343
344 Certain signals like SEGV, ILL, and BUS are generated by virtual memory
345 addressing errors and similar "faults". These are normally fatal: there is
346 little a Perl-level handler can do with them.  So Perl delivers them
347 immediately rather than attempting to defer them.
348
349 =item Signals triggered by operating system state
350
351 On some operating systems certain signal handlers are supposed to "do
352 something" before returning. One example can be CHLD or CLD, which
353 indicates a child process has completed. On some operating systems the
354 signal handler is expected to C<wait> for the completed child
355 process. On such systems the deferred signal scheme will not work for
356 those signals: it does not do the C<wait>. Again the failure will
357 look like a loop as the operating system will reissue the signal because
358 there are completed child processes that have not yet been C<wait>ed for.
359
360 =back
361
362 If you want the old signal behavior back despite possible
363 memory corruption, set the environment variable C<PERL_SIGNALS> to
364 C<"unsafe">.  This feature first appeared in Perl 5.8.1.
365
366 =head1 Named Pipes
367
368 A named pipe (often referred to as a FIFO) is an old Unix IPC
369 mechanism for processes communicating on the same machine.  It works
370 just like regular anonymous pipes, except that the
371 processes rendezvous using a filename and need not be related.
372
373 To create a named pipe, use the C<POSIX::mkfifo()> function.
374
375     use POSIX qw(mkfifo);
376     mkfifo($path, 0700)     ||  die "mkfifo $path failed: $!";
377
378 You can also use the Unix command mknod(1), or on some
379 systems, mkfifo(1).  These may not be in your normal path, though.
380
381     # system return val is backwards, so && not ||
382     #
383     $ENV{PATH} .= ":/etc:/usr/etc";
384     if  (      system("mknod",  $path, "p")
385             && system("mkfifo", $path) )
386     {
387         die "mk{nod,fifo} $path failed";
388     }
389
390
391 A fifo is convenient when you want to connect a process to an unrelated
392 one.  When you open a fifo, the program will block until there's something
393 on the other end.
394
395 For example, let's say you'd like to have your F<.signature> file be a
396 named pipe that has a Perl program on the other end.  Now every time any
397 program (like a mailer, news reader, finger program, etc.) tries to read
398 from that file, the reading program will read the new signature from your
399 program.  We'll use the pipe-checking file-test operator, B<-p>, to find
400 out whether anyone (or anything) has accidentally removed our fifo.
401
402     chdir();    # go home
403     my $FIFO = ".signature";
404
405     while (1) {
406         unless (-p $FIFO) {
407             unlink $FIFO;   # discard any failure, will catch later
408             require POSIX;  # delayed loading of heavy module
409             POSIX::mkfifo($FIFO, 0700)
410                                   || die "can't mkfifo $FIFO: $!";
411         }
412
413         # next line blocks till there's a reader
414         open (my $fh, ">", $FIFO) || die "can't open $FIFO: $!";
415         print $fh "John Smith (smith\@host.org)\n", `fortune -s`;
416         close($fh)                || die "can't close $FIFO: $!";
417         sleep 2;                # to avoid dup signals
418     }
419
420 =head1 Using open() for IPC
421
422 Perl's basic open() statement can also be used for unidirectional
423 interprocess communication by specifying the open mode as C<|-> or C<-|>.
424 Here's how to start
425 something up in a child process you intend to write to:
426
427     open(my $spooler, "|-", "cat -v | lpr -h 2>/dev/null")
428                         || die "can't fork: $!";
429     local $SIG{PIPE} = sub { die "spooler pipe broke" };
430     print $spooler "stuff\n";
431     close $spooler      || die "bad spool: $! $?";
432
433 And here's how to start up a child process you intend to read from:
434
435     open(my $status, "-|", "netstat -an 2>&1")
436                         || die "can't fork: $!";
437     while (<$status>) {
438         next if /^(tcp|udp)/;
439         print;
440     }
441     close $status       || die "bad netstat: $! $?";
442
443 Be aware that these operations are full Unix forks, which means they may
444 not be correctly implemented on all alien systems.  See L<perlport/open>
445 for portability details.
446
447 In the two-argument form of open(), a pipe open can be achieved by
448 either appending or prepending a pipe symbol to the second argument:
449
450     open(my $spooler, "| cat -v | lpr -h 2>/dev/null")
451                         || die "can't fork: $!";
452     open(my $status, "netstat -an 2>&1 |")
453                         || die "can't fork: $!";
454
455 This can be used even on systems that do not support forking, but this
456 possibly allows code intended to read files to unexpectedly execute
457 programs.  If one can be sure that a particular program is a Perl script
458 expecting filenames in @ARGV using the two-argument form of open() or the
459 C<< <> >> operator, the clever programmer can write something like this:
460
461     % program f1 "cmd1|" - f2 "cmd2|" f3 < tmpfile
462
463 and no matter which sort of shell it's called from, the Perl program will
464 read from the file F<f1>, the process F<cmd1>, standard input (F<tmpfile>
465 in this case), the F<f2> file, the F<cmd2> command, and finally the F<f3>
466 file.  Pretty nifty, eh?
467
468 You might notice that you could use backticks for much the
469 same effect as opening a pipe for reading:
470
471     print grep { !/^(tcp|udp)/ } `netstat -an 2>&1`;
472     die "bad netstatus ($?)" if $?;
473
474 While this is true on the surface, it's much more efficient to process the
475 file one line or record at a time because then you don't have to read the
476 whole thing into memory at once.  It also gives you finer control of the
477 whole process, letting you kill off the child process early if you'd like.
478
479 Be careful to check the return values from both open() and close().  If
480 you're I<writing> to a pipe, you should also trap SIGPIPE.  Otherwise,
481 think of what happens when you start up a pipe to a command that doesn't
482 exist: the open() will in all likelihood succeed (it only reflects the
483 fork()'s success), but then your output will fail--spectacularly.  Perl
484 can't know whether the command worked, because your command is actually
485 running in a separate process whose exec() might have failed.  Therefore,
486 while readers of bogus commands return just a quick EOF, writers
487 to bogus commands will get hit with a signal, which they'd best be prepared
488 to handle.  Consider:
489
490     open(my $fh, "|-", "bogus") || die "can't fork: $!";
491     print $fh "bang\n";         #  neither necessary nor sufficient
492                                 #  to check print retval!
493     close($fh)                  || die "can't close: $!";
494
495 The reason for not checking the return value from print() is because of
496 pipe buffering; physical writes are delayed.  That won't blow up until the
497 close, and it will blow up with a SIGPIPE.  To catch it, you could use
498 this:
499
500     $SIG{PIPE} = "IGNORE";
501     open(my $fh, "|-", "bogus") || die "can't fork: $!";
502     print $fh "bang\n";
503     close($fh)                  || die "can't close: status=$?";
504
505 =head2 Filehandles
506
507 Both the main process and any child processes it forks share the same
508 STDIN, STDOUT, and STDERR filehandles.  If both processes try to access
509 them at once, strange things can happen.  You may also want to close
510 or reopen the filehandles for the child.  You can get around this by
511 opening your pipe with open(), but on some systems this means that the
512 child process cannot outlive the parent.
513
514 =head2 Background Processes
515
516 You can run a command in the background with:
517
518     system("cmd &");
519
520 The command's STDOUT and STDERR (and possibly STDIN, depending on your
521 shell) will be the same as the parent's.  You won't need to catch
522 SIGCHLD because of the double-fork taking place; see below for details.
523
524 =head2 Complete Dissociation of Child from Parent
525
526 In some cases (starting server processes, for instance) you'll want to
527 completely dissociate the child process from the parent.  This is
528 often called daemonization.  A well-behaved daemon will also chdir()
529 to the root directory so it doesn't prevent unmounting the filesystem
530 containing the directory from which it was launched, and redirect its
531 standard file descriptors from and to F</dev/null> so that random
532 output doesn't wind up on the user's terminal.
533
534  use POSIX "setsid";
535
536  sub daemonize {
537      chdir("/")                     || die "can't chdir to /: $!";
538      open(STDIN,  "<", "/dev/null") || die "can't read /dev/null: $!";
539      open(STDOUT, ">", "/dev/null") || die "can't write /dev/null: $!";
540      defined(my $pid = fork())      || die "can't fork: $!";
541      exit if $pid;              # non-zero now means I am the parent
542      (setsid() != -1)           || die "Can't start a new session: $!";
543      open(STDERR, ">&", STDOUT) || die "can't dup stdout: $!";
544  }
545
546 The fork() has to come before the setsid() to ensure you aren't a
547 process group leader; the setsid() will fail if you are.  If your
548 system doesn't have the setsid() function, open F</dev/tty> and use the
549 C<TIOCNOTTY> ioctl() on it instead.  See tty(4) for details.
550
551 Non-Unix users should check their C<< I<Your_OS>::Process >> module for
552 other possible solutions.
553
554 =head2 Safe Pipe Opens
555
556 Another interesting approach to IPC is making your single program go
557 multiprocess and communicate between--or even amongst--yourselves.  The
558 two-argument form of the
559 open() function will accept a file argument of either C<"-|"> or C<"|-">
560 to do a very interesting thing: it forks a child connected to the
561 filehandle you've opened.  The child is running the same program as the
562 parent.  This is useful for safely opening a file when running under an
563 assumed UID or GID, for example.  If you open a pipe I<to> minus, you can
564 write to the filehandle you opened and your kid will find it in I<his>
565 STDIN.  If you open a pipe I<from> minus, you can read from the filehandle
566 you opened whatever your kid writes to I<his> STDOUT.
567
568     use English;
569     my $PRECIOUS = "/path/to/some/safe/file";
570     my $sleep_count;
571     my $pid;
572     my $kid_to_write;
573
574     do {
575         $pid = open($kid_to_write, "|-");
576         unless (defined $pid) {
577             warn "cannot fork: $!";
578             die "bailing out" if $sleep_count++ > 6;
579             sleep 10;
580         }
581     } until defined $pid;
582
583     if ($pid) {                 # I am the parent
584         print $kid_to_write @some_data;
585         close($kid_to_write)    || warn "kid exited $?";
586     } else {                    # I am the child
587         # drop permissions in setuid and/or setgid programs:
588         ($EUID, $EGID) = ($UID, $GID);
589         open (my $outfile, ">", $PRECIOUS)
590                                 || die "can't open $PRECIOUS: $!";
591         while (<STDIN>) {
592             print $outfile;     # child STDIN is parent $kid_to_write
593         }
594         close($outfile)         || die "can't close $PRECIOUS: $!";
595         exit(0);                # don't forget this!!
596     }
597
598 Another common use for this construct is when you need to execute
599 something without the shell's interference.  With system(), it's
600 straightforward, but you can't use a pipe open or backticks safely.
601 That's because there's no way to stop the shell from getting its hands on
602 your arguments.   Instead, use lower-level control to call exec() directly.
603
604 Here's a safe backtick or pipe open for read:
605
606     my $pid = open(my $kid_to_read, "-|");
607     defined($pid)            || die "can't fork: $!";
608
609     if ($pid) {             # parent
610         while (<$kid_to_read>) {
611                             # do something interesting
612         }
613         close($kid_to_read)  || warn "kid exited $?";
614
615     } else {                # child
616         ($EUID, $EGID) = ($UID, $GID); # suid only
617         exec($program, @options, @args)
618                              || die "can't exec program: $!";
619         # NOTREACHED
620     }
621
622 And here's a safe pipe open for writing:
623
624     my $pid = open(my $kid_to_write, "|-");
625     defined($pid)            || die "can't fork: $!";
626
627     $SIG{PIPE} = sub { die "whoops, $program pipe broke" };
628
629     if ($pid) {             # parent
630         print $kid_to_write @data;
631         close($kid_to_write) || warn "kid exited $?";
632
633     } else {                # child
634         ($EUID, $EGID) = ($UID, $GID);
635         exec($program, @options, @args)
636                              || die "can't exec program: $!";
637         # NOTREACHED
638     }
639
640 It is very easy to dead-lock a process using this form of open(), or
641 indeed with any use of pipe() with multiple subprocesses.  The
642 example above is "safe" because it is simple and calls exec().  See
643 L</"Avoiding Pipe Deadlocks"> for general safety principles, but there
644 are extra gotchas with Safe Pipe Opens.
645
646 In particular, if you opened the pipe using C<open $fh, "|-">, then you
647 cannot simply use close() in the parent process to close an unwanted
648 writer.  Consider this code:
649
650     my $pid = open(my $writer, "|-");        # fork open a kid
651     defined($pid)               || die "first fork failed: $!";
652     if ($pid) {
653         if (my $sub_pid = fork()) {
654             defined($sub_pid)   || die "second fork failed: $!";
655             close($writer)      || die "couldn't close writer: $!";
656             # now do something else...
657         }
658         else {
659             # first write to $writer
660             # ...
661             # then when finished
662             close($writer)      || die "couldn't close writer: $!";
663             exit(0);
664         }
665     }
666     else {
667         # first do something with STDIN, then
668         exit(0);
669     }
670
671 In the example above, the true parent does not want to write to the $writer
672 filehandle, so it closes it.  However, because $writer was opened using
673 C<open $fh, "|-">, it has a special behavior: closing it calls
674 waitpid() (see L<perlfunc/waitpid>), which waits for the subprocess
675 to exit.  If the child process ends up waiting for something happening
676 in the section marked "do something else", you have deadlock.
677
678 This can also be a problem with intermediate subprocesses in more
679 complicated code, which will call waitpid() on all open filehandles
680 during global destruction--in no predictable order.
681
682 To solve this, you must manually use pipe(), fork(), and the form of
683 open() which sets one file descriptor to another, as shown below:
684
685     pipe(my $reader, my $writer)   || die "pipe failed: $!";
686     $pid = fork();
687     defined($pid)                  || die "first fork failed: $!";
688     if ($pid) {
689         close $reader;
690         if (my $sub_pid = fork()) {
691             defined($sub_pid)      || die "first fork failed: $!";
692             close($writer)         || die "can't close writer: $!";
693         }
694         else {
695             # write to $writer...
696             # ...
697             # then  when finished
698             close($writer)         || die "can't close writer: $!";
699             exit(0);
700         }
701         # write to $writer...
702     }
703     else {
704         open(STDIN, "<&", $reader) || die "can't reopen STDIN: $!";
705         close($writer)             || die "can't close writer: $!";
706         # do something...
707         exit(0);
708     }
709
710 Since Perl 5.8.0, you can also use the list form of C<open> for pipes.
711 This is preferred when you wish to avoid having the shell interpret
712 metacharacters that may be in your command string.
713
714 So for example, instead of using:
715
716     open(my $ps_pipe, "-|", "ps aux") || die "can't open ps pipe: $!";
717
718 One would use either of these:
719
720     open(my $ps_pipe, "-|", "ps", "aux")
721                                       || die "can't open ps pipe: $!";
722
723     @ps_args = qw[ ps aux ];
724     open(my $ps_pipe, "-|", @ps_args)
725                                       || die "can't open @ps_args|: $!";
726
727 Because there are more than three arguments to open(), it forks the ps(1)
728 command I<without> spawning a shell, and reads its standard output via the
729 C<$ps_pipe> filehandle.  The corresponding syntax to I<write> to command
730 pipes is to use C<"|-"> in place of C<"-|">.
731
732 This was admittedly a rather silly example, because you're using string
733 literals whose content is perfectly safe.  There is therefore no cause to
734 resort to the harder-to-read, multi-argument form of pipe open().  However,
735 whenever you cannot be assured that the program arguments are free of shell
736 metacharacters, the fancier form of open() should be used.  For example:
737
738     @grep_args = ("egrep", "-i", $some_pattern, @many_files);
739     open(my $grep_pipe, "-|", @grep_args)
740                         || die "can't open @grep_args|: $!";
741
742 Here the multi-argument form of pipe open() is preferred because the
743 pattern and indeed even the filenames themselves might hold metacharacters.
744
745 =head2 Avoiding Pipe Deadlocks
746
747 Whenever you have more than one subprocess, you must be careful that each
748 closes whichever half of any pipes created for interprocess communication
749 it is not using.  This is because any child process reading from the pipe
750 and expecting an EOF will never receive it, and therefore never exit. A
751 single process closing a pipe is not enough to close it; the last process
752 with the pipe open must close it for it to read EOF.
753
754 Certain built-in Unix features help prevent this most of the time.  For
755 instance, filehandles have a "close on exec" flag, which is set I<en masse>
756 under control of the C<$^F> variable.  This is so any filehandles you
757 didn't explicitly route to the STDIN, STDOUT or STDERR of a child
758 I<program> will be automatically closed.
759
760 Always explicitly and immediately call close() on the writable end of any
761 pipe, unless that process is actually writing to it.  Even if you don't
762 explicitly call close(), Perl will still close() all filehandles during
763 global destruction.  As previously discussed, if those filehandles have
764 been opened with Safe Pipe Open, this will result in calling waitpid(),
765 which may again deadlock.
766
767 =head2 Bidirectional Communication with Another Process
768
769 While this works reasonably well for unidirectional communication, what
770 about bidirectional communication?  The most obvious approach doesn't work:
771
772     # THIS DOES NOT WORK!!
773     open(my $prog_for_reading_and_writing, "| some program |")
774
775 If you forget to C<use warnings>, you'll miss out entirely on the
776 helpful diagnostic message:
777
778     Can't do bidirectional pipe at -e line 1.
779
780 If you really want to, you can use the standard open2() from the
781 C<IPC::Open2> module to catch both ends.  There's also an open3() in
782 C<IPC::Open3> for tridirectional I/O so you can also catch your child's
783 STDERR, but doing so would then require an awkward select() loop and
784 wouldn't allow you to use normal Perl input operations.
785
786 If you look at its source, you'll see that open2() uses low-level
787 primitives like the pipe() and exec() syscalls to create all the
788 connections.  Although it might have been more efficient by using
789 socketpair(), this would have been even less portable than it already
790 is. The open2() and open3() functions are unlikely to work anywhere
791 except on a Unix system, or at least one purporting POSIX compliance.
792
793 =for TODO
794 Hold on, is this even true?  First it says that socketpair() is avoided
795 for portability, but then it says it probably won't work except on
796 Unixy systems anyway.  Which one of those is true?
797
798 Here's an example of using open2():
799
800     use FileHandle;
801     use IPC::Open2;
802     $pid = open2(my $reader, my $writer, "cat -un");
803     print $writer "stuff\n";
804     $got = <$reader>;
805
806 The problem with this is that buffering is really going to ruin your
807 day.  Even though your C<$writer> filehandle is auto-flushed so the process
808 on the other end gets your data in a timely manner, you can't usually do
809 anything to force that process to give its data to you in a similarly quick
810 fashion.  In this special case, we could actually so, because we gave
811 I<cat> a B<-u> flag to make it unbuffered.  But very few commands are
812 designed to operate over pipes, so this seldom works unless you yourself
813 wrote the program on the other end of the double-ended pipe.
814
815 A solution to this is to use a library which uses pseudottys to make your
816 program behave more reasonably.  This way you don't have to have control
817 over the source code of the program you're using.  The C<Expect> module
818 from CPAN also addresses this kind of thing.  This module requires two
819 other modules from CPAN, C<IO::Pty> and C<IO::Stty>.  It sets up a pseudo
820 terminal to interact with programs that insist on talking to the terminal
821 device driver.  If your system is supported, this may be your best bet.
822
823 =head2 Bidirectional Communication with Yourself
824
825 If you want, you may make low-level pipe() and fork() syscalls to stitch
826 this together by hand.  This example only talks to itself, but you could
827 reopen the appropriate handles to STDIN and STDOUT and call other processes.
828 (The following example lacks proper error checking.)
829
830  #!/usr/bin/perl -w
831  # pipe1 - bidirectional communication using two pipe pairs
832  #         designed for the socketpair-challenged
833  use IO::Handle;             # thousands of lines just for autoflush :-(
834  pipe(my $parent_rdr, my $child_wtr);  # XXX: check failure?
835  pipe(my $child_rdr,  my $parent_wtr); # XXX: check failure?
836  $child_wtr->autoflush(1);
837  $parent_wtr->autoflush(1);
838
839  if ($pid = fork()) {
840      close $parent_rdr;
841      close $parent_wtr;
842      print $child_wtr "Parent Pid $$ is sending this\n";
843      chomp($line = <$child_rdr>);
844      print "Parent Pid $$ just read this: '$line'\n";
845      close $child_rdr; close $child_wtr;
846      waitpid($pid, 0);
847  } else {
848      die "cannot fork: $!" unless defined $pid;
849      close $child_rdr;
850      close $child_wtr;
851      chomp($line = <$parent_rdr>);
852      print "Child Pid $$ just read this: '$line'\n";
853      print $parent_wtr "Child Pid $$ is sending this\n";
854      close $parent_rdr;
855      close $parent_wtr;
856      exit(0);
857  }
858
859 But you don't actually have to make two pipe calls.  If you
860 have the socketpair() system call, it will do this all for you.
861
862  #!/usr/bin/perl -w
863  # pipe2 - bidirectional communication using socketpair
864  #   "the best ones always go both ways"
865
866  use Socket;
867  use IO::Handle;  # thousands of lines just for autoflush :-(
868
869  # We say AF_UNIX because although *_LOCAL is the
870  # POSIX 1003.1g form of the constant, many machines
871  # still don't have it.
872  socketpair(my $child, my $parent, AF_UNIX, SOCK_STREAM, PF_UNSPEC)
873                              ||  die "socketpair: $!";
874
875  $child->autoflush(1);
876  $parent->autoflush(1);
877
878  if ($pid = fork()) {
879      close $parent;
880      print $child "Parent Pid $$ is sending this\n";
881      chomp($line = <$child>);
882      print "Parent Pid $$ just read this: '$line'\n";
883      close $child;
884      waitpid($pid, 0);
885  } else {
886      die "cannot fork: $!" unless defined $pid;
887      close $child;
888      chomp($line = <$parent>);
889      print "Child Pid $$ just read this: '$line'\n";
890      print $parent "Child Pid $$ is sending this\n";
891      close $parent;
892      exit(0);
893  }
894
895 =head1 Sockets: Client/Server Communication
896
897 While not entirely limited to Unix-derived operating systems (e.g., WinSock
898 on PCs provides socket support, as do some VMS libraries), you might not have
899 sockets on your system, in which case this section probably isn't going to
900 do you much good.  With sockets, you can do both virtual circuits like TCP
901 streams and datagrams like UDP packets.  You may be able to do even more
902 depending on your system.
903
904 The Perl functions for dealing with sockets have the same names as
905 the corresponding system calls in C, but their arguments tend to differ
906 for two reasons.  First, Perl filehandles work differently than C file
907 descriptors.  Second, Perl already knows the length of its strings, so you
908 don't need to pass that information.
909
910 One of the major problems with ancient, antemillennial socket code in Perl
911 was that it used hard-coded values for some of the constants, which
912 severely hurt portability.  If you ever see code that does anything like
913 explicitly setting C<$AF_INET = 2>, you know you're in for big trouble.
914 An immeasurably superior approach is to use the C<Socket> module, which more
915 reliably grants access to the various constants and functions you'll need.
916
917 If you're not writing a server/client for an existing protocol like
918 NNTP or SMTP, you should give some thought to how your server will
919 know when the client has finished talking, and vice-versa.  Most
920 protocols are based on one-line messages and responses (so one party
921 knows the other has finished when a "\n" is received) or multi-line
922 messages and responses that end with a period on an empty line
923 ("\n.\n" terminates a message/response).
924
925 =head2 Internet Line Terminators
926
927 The Internet line terminator is "\015\012".  Under ASCII variants of
928 Unix, that could usually be written as "\r\n", but under other systems,
929 "\r\n" might at times be "\015\015\012", "\012\012\015", or something
930 completely different.  The standards specify writing "\015\012" to be
931 conformant (be strict in what you provide), but they also recommend
932 accepting a lone "\012" on input (be lenient in what you require).
933 We haven't always been very good about that in the code in this manpage,
934 but unless you're on a Mac from way back in its pre-Unix dark ages, you'll
935 probably be ok.
936
937 =head2 Internet TCP Clients and Servers
938
939 Use Internet-domain sockets when you want to do client-server
940 communication that might extend to machines outside of your own system.
941
942 Here's a sample TCP client using Internet-domain sockets:
943
944     #!/usr/bin/perl -w
945     use strict;
946     use Socket;
947     my ($remote, $port, $iaddr, $paddr, $proto, $line);
948
949     $remote  = shift || "localhost";
950     $port    = shift || 2345;  # random port
951     if ($port =~ /\D/) { $port = getservbyname($port, "tcp") }
952     die "No port" unless $port;
953     $iaddr   = inet_aton($remote)       || die "no host: $remote";
954     $paddr   = sockaddr_in($port, $iaddr);
955
956     $proto   = getprotobyname("tcp");
957     socket(my $sock, PF_INET, SOCK_STREAM, $proto)  || die "socket: $!";
958     connect($sock, $paddr)              || die "connect: $!";
959     while ($line = <$sock>) {
960         print $line;
961     }
962
963     close ($sock)                        || die "close: $!";
964     exit(0);
965
966 And here's a corresponding server to go along with it.  We'll
967 leave the address as C<INADDR_ANY> so that the kernel can choose
968 the appropriate interface on multihomed hosts.  If you want sit
969 on a particular interface (like the external side of a gateway
970 or firewall machine), fill this in with your real address instead.
971
972  #!/usr/bin/perl -Tw
973  use strict;
974  BEGIN { $ENV{PATH} = "/usr/bin:/bin" }
975  use Socket;
976  use Carp;
977  my $EOL = "\015\012";
978
979  sub logmsg { print "$0 $$: @_ at ", scalar localtime(), "\n" }
980
981  my $port  = shift || 2345;
982  die "invalid port" unless $port =~ /^ \d+ $/x;
983
984  my $proto = getprotobyname("tcp");
985
986  socket(my $server, PF_INET, SOCK_STREAM, $proto) || die "socket: $!";
987  setsockopt($server, SOL_SOCKET, SO_REUSEADDR, pack("l", 1))
988                                                || die "setsockopt: $!";
989  bind($server, sockaddr_in($port, INADDR_ANY)) || die "bind: $!";
990  listen($server, SOMAXCONN)                    || die "listen: $!";
991
992  logmsg "server started on port $port";
993
994  my $paddr;
995
996  for ( ; $paddr = accept(my $client, $server); close $client) {
997      my($port, $iaddr) = sockaddr_in($paddr);
998      my $name = gethostbyaddr($iaddr, AF_INET);
999
1000      logmsg "connection from $name [",
1001              inet_ntoa($iaddr), "]
1002              at port $port";
1003
1004      print $client "Hello there, $name, it's now ",
1005                      scalar localtime(), $EOL;
1006  }
1007
1008 And here's a multitasking version.  It's multitasked in that
1009 like most typical servers, it spawns (fork()s) a slave server to
1010 handle the client request so that the master server can quickly
1011 go back to service a new client.
1012
1013  #!/usr/bin/perl -Tw
1014  use strict;
1015  BEGIN { $ENV{PATH} = "/usr/bin:/bin" }
1016  use Socket;
1017  use Carp;
1018  my $EOL = "\015\012";
1019
1020  sub spawn;  # forward declaration
1021  sub logmsg { print "$0 $$: @_ at ", scalar localtime(), "\n" }
1022
1023  my $port  = shift || 2345;
1024  die "invalid port" unless $port =~ /^ \d+ $/x;
1025
1026  my $proto = getprotobyname("tcp");
1027
1028  socket(my $server, PF_INET, SOCK_STREAM, $proto) || die "socket: $!";
1029  setsockopt($server, SOL_SOCKET, SO_REUSEADDR, pack("l", 1))
1030                                                || die "setsockopt: $!";
1031  bind($server, sockaddr_in($port, INADDR_ANY)) || die "bind: $!";
1032  listen($server, SOMAXCONN)                    || die "listen: $!";
1033
1034  logmsg "server started on port $port";
1035
1036  my $waitedpid = 0;
1037  my $paddr;
1038
1039  use POSIX ":sys_wait_h";
1040  use Errno;
1041
1042  sub REAPER {
1043      local $!;   # don't let waitpid() overwrite current error
1044      while ((my $pid = waitpid(-1, WNOHANG)) > 0 && WIFEXITED($?)) {
1045          logmsg "reaped $waitedpid" . ($? ? " with exit $?" : "");
1046      }
1047      $SIG{CHLD} = \&REAPER;  # loathe SysV
1048  }
1049
1050  $SIG{CHLD} = \&REAPER;
1051
1052  while (1) {
1053      $paddr = accept(my $client, $server) || do {
1054          # try again if accept() returned because got a signal
1055          next if $!{EINTR};
1056          die "accept: $!";
1057      };
1058      my ($port, $iaddr) = sockaddr_in($paddr);
1059      my $name = gethostbyaddr($iaddr, AF_INET);
1060
1061      logmsg "connection from $name [",
1062             inet_ntoa($iaddr),
1063             "] at port $port";
1064
1065      spawn $client, sub {
1066          $| = 1;
1067          print "Hello there, $name, it's now ",
1068                scalar localtime(),
1069                $EOL;
1070          exec "/usr/games/fortune"       # XXX: "wrong" line terminators
1071              or confess "can't exec fortune: $!";
1072      };
1073      close $client;
1074  }
1075
1076  sub spawn {
1077      my $client = shift;
1078      my $coderef = shift;
1079
1080      unless (@_ == 0 && $coderef && ref($coderef) eq "CODE") {
1081          confess "usage: spawn CLIENT CODEREF";
1082      }
1083
1084      my $pid;
1085      unless (defined($pid = fork())) {
1086          logmsg "cannot fork: $!";
1087          return;
1088      }
1089      elsif ($pid) {
1090          logmsg "begat $pid";
1091          return; # I'm the parent
1092      }
1093      # else I'm the child -- go spawn
1094
1095      open(STDIN,  "<&", $client)   || die "can't dup client to stdin";
1096      open(STDOUT, ">&", $client)   || die "can't dup client to stdout";
1097      ## open(STDERR, ">&", STDOUT) || die "can't dup stdout to stderr";
1098      exit($coderef->());
1099  }
1100
1101 This server takes the trouble to clone off a child version via fork()
1102 for each incoming request.  That way it can handle many requests at
1103 once, which you might not always want.  Even if you don't fork(), the
1104 listen() will allow that many pending connections.  Forking servers
1105 have to be particularly careful about cleaning up their dead children
1106 (called "zombies" in Unix parlance), because otherwise you'll quickly
1107 fill up your process table.  The REAPER subroutine is used here to
1108 call waitpid() for any child processes that have finished, thereby
1109 ensuring that they terminate cleanly and don't join the ranks of the
1110 living dead.
1111
1112 Within the while loop we call accept() and check to see if it returns
1113 a false value.  This would normally indicate a system error needs
1114 to be reported.  However, the introduction of safe signals (see
1115 L</Deferred Signals (Safe Signals)> above) in Perl 5.8.0 means that
1116 accept() might also be interrupted when the process receives a signal.
1117 This typically happens when one of the forked subprocesses exits and
1118 notifies the parent process with a CHLD signal.
1119
1120 If accept() is interrupted by a signal, $! will be set to EINTR.
1121 If this happens, we can safely continue to the next iteration of
1122 the loop and another call to accept().  It is important that your
1123 signal handling code not modify the value of $!, or else this test
1124 will likely fail.  In the REAPER subroutine we create a local version
1125 of $! before calling waitpid().  When waitpid() sets $! to ECHILD as
1126 it inevitably does when it has no more children waiting, it
1127 updates the local copy and leaves the original unchanged.
1128
1129 You should use the B<-T> flag to enable taint checking (see L<perlsec>)
1130 even if we aren't running setuid or setgid.  This is always a good idea
1131 for servers or any program run on behalf of someone else (like CGI
1132 scripts), because it lessens the chances that people from the outside will
1133 be able to compromise your system.
1134
1135 Let's look at another TCP client.  This one connects to the TCP "time"
1136 service on a number of different machines and shows how far their clocks
1137 differ from the system on which it's being run:
1138
1139     #!/usr/bin/perl  -w
1140     use strict;
1141     use Socket;
1142
1143     my $SECS_OF_70_YEARS = 2208988800;
1144     sub ctime { scalar localtime(shift() || time()) }
1145
1146     my $iaddr = gethostbyname("localhost");
1147     my $proto = getprotobyname("tcp");
1148     my $port = getservbyname("time", "tcp");
1149     my $paddr = sockaddr_in(0, $iaddr);
1150     my($host);
1151
1152     $| = 1;
1153     printf "%-24s %8s %s\n", "localhost", 0, ctime();
1154
1155     foreach $host (@ARGV) {
1156         printf "%-24s ", $host;
1157         my $hisiaddr = inet_aton($host)     || die "unknown host";
1158         my $hispaddr = sockaddr_in($port, $hisiaddr);
1159         socket(my $socket, PF_INET, SOCK_STREAM, $proto)
1160                                             || die "socket: $!";
1161         connect($socket, $hispaddr)         || die "connect: $!";
1162         my $rtime = pack("C4", ());
1163         read($socket, $rtime, 4);
1164         close($socket);
1165         my $histime = unpack("N", $rtime) - $SECS_OF_70_YEARS;
1166         printf "%8d %s\n", $histime - time(), ctime($histime);
1167     }
1168
1169 =head2 Unix-Domain TCP Clients and Servers
1170
1171 That's fine for Internet-domain clients and servers, but what about local
1172 communications?  While you can use the same setup, sometimes you don't
1173 want to.  Unix-domain sockets are local to the current host, and are often
1174 used internally to implement pipes.  Unlike Internet domain sockets, Unix
1175 domain sockets can show up in the file system with an ls(1) listing.
1176
1177     % ls -l /dev/log
1178     srw-rw-rw-  1 root            0 Oct 31 07:23 /dev/log
1179
1180 You can test for these with Perl's B<-S> file test:
1181
1182     unless (-S "/dev/log") {
1183         die "something's wicked with the log system";
1184     }
1185
1186 Here's a sample Unix-domain client:
1187
1188     #!/usr/bin/perl -w
1189     use Socket;
1190     use strict;
1191     my ($rendezvous, $line);
1192
1193     $rendezvous = shift || "catsock";
1194     socket(my $sock, PF_UNIX, SOCK_STREAM, 0) || die "socket: $!";
1195     connect($sock, sockaddr_un($rendezvous))  || die "connect: $!";
1196     while (defined($line = <$sock>)) {
1197         print $line;
1198     }
1199     exit(0);
1200
1201 And here's a corresponding server.  You don't have to worry about silly
1202 network terminators here because Unix domain sockets are guaranteed
1203 to be on the localhost, and thus everything works right.
1204
1205     #!/usr/bin/perl -Tw
1206     use strict;
1207     use Socket;
1208     use Carp;
1209
1210     BEGIN { $ENV{PATH} = "/usr/bin:/bin" }
1211     sub spawn;  # forward declaration
1212     sub logmsg { print "$0 $$: @_ at ", scalar localtime(), "\n" }
1213
1214     my $NAME = "catsock";
1215     my $uaddr = sockaddr_un($NAME);
1216     my $proto = getprotobyname("tcp");
1217
1218     socket(my $server, PF_UNIX, SOCK_STREAM, 0) || die "socket: $!";
1219     unlink($NAME);
1220     bind  ($server, $uaddr)                     || die "bind: $!";
1221     listen($server, SOMAXCONN)                  || die "listen: $!";
1222
1223     logmsg "server started on $NAME";
1224
1225     my $waitedpid;
1226
1227     use POSIX ":sys_wait_h";
1228     sub REAPER {
1229         my $child;
1230         while (($waitedpid = waitpid(-1, WNOHANG)) > 0) {
1231             logmsg "reaped $waitedpid" . ($? ? " with exit $?" : "");
1232         }
1233         $SIG{CHLD} = \&REAPER;  # loathe SysV
1234     }
1235
1236     $SIG{CHLD} = \&REAPER;
1237
1238
1239     for ( $waitedpid = 0;
1240           accept(my $client, $server) || $waitedpid;
1241           $waitedpid = 0, close $client)
1242     {
1243         next if $waitedpid;
1244         logmsg "connection on $NAME";
1245         spawn $client, sub {
1246             print "Hello there, it's now ", scalar localtime(), "\n";
1247             exec("/usr/games/fortune")  || die "can't exec fortune: $!";
1248         };
1249     }
1250
1251     sub spawn {
1252         my $client = shift();
1253         my $coderef = shift();
1254
1255         unless (@_ == 0 && $coderef && ref($coderef) eq "CODE") {
1256             confess "usage: spawn CLIENT CODEREF";
1257         }
1258
1259         my $pid;
1260         unless (defined($pid = fork())) {
1261             logmsg "cannot fork: $!";
1262             return;
1263         }
1264         elsif ($pid) {
1265             logmsg "begat $pid";
1266             return; # I'm the parent
1267         }
1268         else {
1269             # I'm the child -- go spawn
1270         }
1271
1272         open(STDIN,  "<&", $client)
1273             || die "can't dup client to stdin";
1274         open(STDOUT, ">&", $client)
1275             || die "can't dup client to stdout";
1276         ## open(STDERR, ">&", STDOUT)
1277         ##  || die "can't dup stdout to stderr";
1278         exit($coderef->());
1279     }
1280
1281 As you see, it's remarkably similar to the Internet domain TCP server, so
1282 much so, in fact, that we've omitted several duplicate functions--spawn(),
1283 logmsg(), ctime(), and REAPER()--which are the same as in the other server.
1284
1285 So why would you ever want to use a Unix domain socket instead of a
1286 simpler named pipe?  Because a named pipe doesn't give you sessions.  You
1287 can't tell one process's data from another's.  With socket programming,
1288 you get a separate session for each client; that's why accept() takes two
1289 arguments.
1290
1291 For example, let's say that you have a long-running database server daemon
1292 that you want folks to be able to access from the Web, but only
1293 if they go through a CGI interface.  You'd have a small, simple CGI
1294 program that does whatever checks and logging you feel like, and then acts
1295 as a Unix-domain client and connects to your private server.
1296
1297 =head1 TCP Clients with IO::Socket
1298
1299 For those preferring a higher-level interface to socket programming, the
1300 IO::Socket module provides an object-oriented approach.  If for some reason
1301 you lack this module, you can just fetch IO::Socket from CPAN, where you'll also
1302 find modules providing easy interfaces to the following systems: DNS, FTP,
1303 Ident (RFC 931), NIS and NISPlus, NNTP, Ping, POP3, SMTP, SNMP, SSLeay,
1304 Telnet, and Time--to name just a few.
1305
1306 =head2 A Simple Client
1307
1308 Here's a client that creates a TCP connection to the "daytime"
1309 service at port 13 of the host name "localhost" and prints out everything
1310 that the server there cares to provide.
1311
1312     #!/usr/bin/perl -w
1313     use IO::Socket;
1314     $remote = IO::Socket::INET->new(
1315                         Proto    => "tcp",
1316                         PeerAddr => "localhost",
1317                         PeerPort => "daytime(13)",
1318                     )
1319                  || die "can't connect to daytime service on localhost";
1320     while (<$remote>) { print }
1321
1322 When you run this program, you should get something back that
1323 looks like this:
1324
1325     Wed May 14 08:40:46 MDT 1997
1326
1327 Here are what those parameters to the new() constructor mean:
1328
1329 =over 4
1330
1331 =item C<Proto>
1332
1333 This is which protocol to use.  In this case, the socket handle returned
1334 will be connected to a TCP socket, because we want a stream-oriented
1335 connection, that is, one that acts pretty much like a plain old file.
1336 Not all sockets are this of this type.  For example, the UDP protocol
1337 can be used to make a datagram socket, used for message-passing.
1338
1339 =item C<PeerAddr>
1340
1341 This is the name or Internet address of the remote host the server is
1342 running on.  We could have specified a longer name like C<"www.perl.com">,
1343 or an address like C<"207.171.7.72">.  For demonstration purposes, we've
1344 used the special hostname C<"localhost">, which should always mean the
1345 current machine you're running on.  The corresponding Internet address
1346 for localhost is C<"127.0.0.1">, if you'd rather use that.
1347
1348 =item C<PeerPort>
1349
1350 This is the service name or port number we'd like to connect to.
1351 We could have gotten away with using just C<"daytime"> on systems with a
1352 well-configured system services file,[FOOTNOTE: The system services file
1353 is found in I</etc/services> under Unixy systems.] but here we've specified the
1354 port number (13) in parentheses.  Using just the number would have also
1355 worked, but numeric literals make careful programmers nervous.
1356
1357 =back
1358
1359 =head2 A Webget Client
1360
1361 Here's a simple client that takes a remote host to fetch a document
1362 from, and then a list of files to get from that host.  This is a
1363 more interesting client than the previous one because it first sends
1364 something to the server before fetching the server's response.
1365
1366     #!/usr/bin/perl -w
1367     use IO::Socket;
1368     unless (@ARGV > 1) { die "usage: $0 host url ..." }
1369     $host = shift(@ARGV);
1370     $EOL = "\015\012";
1371     $BLANK = $EOL x 2;
1372     for my $document (@ARGV) {
1373         $remote = IO::Socket::INET->new( Proto     => "tcp",
1374                                          PeerAddr  => $host,
1375                                          PeerPort  => "http(80)",
1376                   )     || die "cannot connect to httpd on $host";
1377         $remote->autoflush(1);
1378         print $remote "GET $document HTTP/1.0" . $BLANK;
1379         while ( <$remote> ) { print }
1380         close $remote;
1381     }
1382
1383 The web server handling the HTTP service is assumed to be at
1384 its standard port, number 80.  If the server you're trying to
1385 connect to is at a different port, like 1080 or 8080, you should specify it
1386 as the named-parameter pair, C<< PeerPort => 8080 >>.  The C<autoflush>
1387 method is used on the socket because otherwise the system would buffer
1388 up the output we sent it.  (If you're on a prehistoric Mac, you'll also
1389 need to change every C<"\n"> in your code that sends data over the network
1390 to be a C<"\015\012"> instead.)
1391
1392 Connecting to the server is only the first part of the process: once you
1393 have the connection, you have to use the server's language.  Each server
1394 on the network has its own little command language that it expects as
1395 input.  The string that we send to the server starting with "GET" is in
1396 HTTP syntax.  In this case, we simply request each specified document.
1397 Yes, we really are making a new connection for each document, even though
1398 it's the same host.  That's the way you always used to have to speak HTTP.
1399 Recent versions of web browsers may request that the remote server leave
1400 the connection open a little while, but the server doesn't have to honor
1401 such a request.
1402
1403 Here's an example of running that program, which we'll call I<webget>:
1404
1405     % webget www.perl.com /guanaco.html
1406     HTTP/1.1 404 File Not Found
1407     Date: Thu, 08 May 1997 18:02:32 GMT
1408     Server: Apache/1.2b6
1409     Connection: close
1410     Content-type: text/html
1411
1412     <HEAD><TITLE>404 File Not Found</TITLE></HEAD>
1413     <BODY><H1>File Not Found</H1>
1414     The requested URL /guanaco.html was not found on this server.<P>
1415     </BODY>
1416
1417 Ok, so that's not very interesting, because it didn't find that
1418 particular document.  But a long response wouldn't have fit on this page.
1419
1420 For a more featureful version of this program, you should look to
1421 the I<lwp-request> program included with the LWP modules from CPAN.
1422
1423 =head2 Interactive Client with IO::Socket
1424
1425 Well, that's all fine if you want to send one command and get one answer,
1426 but what about setting up something fully interactive, somewhat like
1427 the way I<telnet> works?  That way you can type a line, get the answer,
1428 type a line, get the answer, etc.
1429
1430 This client is more complicated than the two we've done so far, but if
1431 you're on a system that supports the powerful C<fork> call, the solution
1432 isn't that rough.  Once you've made the connection to whatever service
1433 you'd like to chat with, call C<fork> to clone your process.  Each of
1434 these two identical process has a very simple job to do: the parent
1435 copies everything from the socket to standard output, while the child
1436 simultaneously copies everything from standard input to the socket.
1437 To accomplish the same thing using just one process would be I<much>
1438 harder, because it's easier to code two processes to do one thing than it
1439 is to code one process to do two things.  (This keep-it-simple principle
1440 a cornerstones of the Unix philosophy, and good software engineering as
1441 well, which is probably why it's spread to other systems.)
1442
1443 Here's the code:
1444
1445     #!/usr/bin/perl -w
1446     use strict;
1447     use IO::Socket;
1448     my ($host, $port, $kidpid, $handle, $line);
1449
1450     unless (@ARGV == 2) { die "usage: $0 host port" }
1451     ($host, $port) = @ARGV;
1452
1453     # create a tcp connection to the specified host and port
1454     $handle = IO::Socket::INET->new(Proto     => "tcp",
1455                                     PeerAddr  => $host,
1456                                     PeerPort  => $port)
1457                || die "can't connect to port $port on $host: $!";
1458
1459     $handle->autoflush(1);       # so output gets there right away
1460     print STDERR "[Connected to $host:$port]\n";
1461
1462     # split the program into two processes, identical twins
1463     die "can't fork: $!" unless defined($kidpid = fork());
1464
1465     # the if{} block runs only in the parent process
1466     if ($kidpid) {
1467         # copy the socket to standard output
1468         while (defined ($line = <$handle>)) {
1469             print STDOUT $line;
1470         }
1471         kill("TERM", $kidpid);   # send SIGTERM to child
1472     }
1473     # the else{} block runs only in the child process
1474     else {
1475         # copy standard input to the socket
1476         while (defined ($line = <STDIN>)) {
1477             print $handle $line;
1478         }
1479         exit(0);                # just in case
1480     }
1481
1482 The C<kill> function in the parent's C<if> block is there to send a
1483 signal to our child process, currently running in the C<else> block,
1484 as soon as the remote server has closed its end of the connection.
1485
1486 If the remote server sends data a byte at time, and you need that
1487 data immediately without waiting for a newline (which might not happen),
1488 you may wish to replace the C<while> loop in the parent with the
1489 following:
1490
1491     my $byte;
1492     while (sysread($handle, $byte, 1) == 1) {
1493         print STDOUT $byte;
1494     }
1495
1496 Making a system call for each byte you want to read is not very efficient
1497 (to put it mildly) but is the simplest to explain and works reasonably
1498 well.
1499
1500 =head1 TCP Servers with IO::Socket
1501
1502 As always, setting up a server is little bit more involved than running a client.
1503 The model is that the server creates a special kind of socket that
1504 does nothing but listen on a particular port for incoming connections.
1505 It does this by calling the C<< IO::Socket::INET->new() >> method with
1506 slightly different arguments than the client did.
1507
1508 =over 4
1509
1510 =item Proto
1511
1512 This is which protocol to use.  Like our clients, we'll
1513 still specify C<"tcp"> here.
1514
1515 =item LocalPort
1516
1517 We specify a local
1518 port in the C<LocalPort> argument, which we didn't do for the client.
1519 This is service name or port number for which you want to be the
1520 server. (Under Unix, ports under 1024 are restricted to the
1521 superuser.)  In our sample, we'll use port 9000, but you can use
1522 any port that's not currently in use on your system.  If you try
1523 to use one already in used, you'll get an "Address already in use"
1524 message.  Under Unix, the C<netstat -a> command will show
1525 which services current have servers.
1526
1527 =item Listen
1528
1529 The C<Listen> parameter is set to the maximum number of
1530 pending connections we can accept until we turn away incoming clients.
1531 Think of it as a call-waiting queue for your telephone.
1532 The low-level Socket module has a special symbol for the system maximum, which
1533 is SOMAXCONN.
1534
1535 =item Reuse
1536
1537 The C<Reuse> parameter is needed so that we restart our server
1538 manually without waiting a few minutes to allow system buffers to
1539 clear out.
1540
1541 =back
1542
1543 Once the generic server socket has been created using the parameters
1544 listed above, the server then waits for a new client to connect
1545 to it.  The server blocks in the C<accept> method, which eventually accepts a
1546 bidirectional connection from the remote client.  (Make sure to autoflush
1547 this handle to circumvent buffering.)
1548
1549 To add to user-friendliness, our server prompts the user for commands.
1550 Most servers don't do this.  Because of the prompt without a newline,
1551 you'll have to use the C<sysread> variant of the interactive client above.
1552
1553 This server accepts one of five different commands, sending output back to
1554 the client.  Unlike most network servers, this one handles only one
1555 incoming client at a time.  Multitasking servers are covered in
1556 Chapter 16 of the Camel.
1557
1558 Here's the code.  We'll
1559
1560  #!/usr/bin/perl -w
1561  use IO::Socket;
1562  use Net::hostent;      # for OOish version of gethostbyaddr
1563
1564  $PORT = 9000;          # pick something not in use
1565
1566  $server = IO::Socket::INET->new( Proto     => "tcp",
1567                                   LocalPort => $PORT,
1568                                   Listen    => SOMAXCONN,
1569                                   Reuse     => 1);
1570
1571  die "can't setup server" unless $server;
1572  print "[Server $0 accepting clients]\n";
1573
1574  while ($client = $server->accept()) {
1575    $client->autoflush(1);
1576    print $client "Welcome to $0; type help for command list.\n";
1577    $hostinfo = gethostbyaddr($client->peeraddr);
1578    printf "[Connect from %s]\n",
1579           $hostinfo ? $hostinfo->name : $client->peerhost;
1580    print $client "Command? ";
1581    while ( <$client>) {
1582      next unless /\S/;     # blank line
1583      if    (/quit|exit/i)  { last                                      }
1584      elsif (/date|time/i)  { printf $client "%s\n", scalar localtime() }
1585      elsif (/who/i )       { print  $client `who 2>&1`                 }
1586      elsif (/cookie/i )    { print  $client `/usr/games/fortune 2>&1`  }
1587      elsif (/motd/i )      { print  $client `cat /etc/motd 2>&1`       }
1588      else {
1589        print $client "Commands: quit date who cookie motd\n";
1590      }
1591    } continue {
1592       print $client "Command? ";
1593    }
1594    close $client;
1595  }
1596
1597 =head1 UDP: Message Passing
1598
1599 Another kind of client-server setup is one that uses not connections, but
1600 messages.  UDP communications involve much lower overhead but also provide
1601 less reliability, as there are no promises that messages will arrive at
1602 all, let alone in order and unmangled.  Still, UDP offers some advantages
1603 over TCP, including being able to "broadcast" or "multicast" to a whole
1604 bunch of destination hosts at once (usually on your local subnet).  If you
1605 find yourself overly concerned about reliability and start building checks
1606 into your message system, then you probably should use just TCP to start
1607 with.
1608
1609 UDP datagrams are I<not> a bytestream and should not be treated as such.
1610 This makes using I/O mechanisms with internal buffering like stdio (i.e.
1611 print() and friends) especially cumbersome. Use syswrite(), or better
1612 send(), like in the example below.
1613
1614 Here's a UDP program similar to the sample Internet TCP client given
1615 earlier.  However, instead of checking one host at a time, the UDP version
1616 will check many of them asynchronously by simulating a multicast and then
1617 using select() to do a timed-out wait for I/O.  To do something similar
1618 with TCP, you'd have to use a different socket handle for each host.
1619
1620  #!/usr/bin/perl -w
1621  use strict;
1622  use Socket;
1623  use Sys::Hostname;
1624
1625  my ( $count, $hisiaddr, $hispaddr, $histime,
1626       $host, $iaddr, $paddr, $port, $proto,
1627       $rin, $rout, $rtime, $SECS_OF_70_YEARS);
1628
1629  $SECS_OF_70_YEARS = 2_208_988_800;
1630
1631  $iaddr = gethostbyname(hostname());
1632  $proto = getprotobyname("udp");
1633  $port = getservbyname("time", "udp");
1634  $paddr = sockaddr_in(0, $iaddr); # 0 means let kernel pick
1635
1636  socket(my $socket, PF_INET, SOCK_DGRAM, $proto) || die "socket: $!";
1637  bind($socket, $paddr)                           || die "bind: $!";
1638
1639  $| = 1;
1640  printf "%-12s %8s %s\n",  "localhost", 0, scalar localtime();
1641  $count = 0;
1642  for $host (@ARGV) {
1643      $count++;
1644      $hisiaddr = inet_aton($host)            || die "unknown host";
1645      $hispaddr = sockaddr_in($port, $hisiaddr);
1646      defined(send($socket, 0, 0, $hispaddr)) || die "send $host: $!";
1647  }
1648
1649  $rin = "";
1650  vec($rin, fileno($socket), 1) = 1;
1651
1652  # timeout after 10.0 seconds
1653  while ($count && select($rout = $rin, undef, undef, 10.0)) {
1654      $rtime = "";
1655      $hispaddr = recv($socket, $rtime, 4, 0) || die "recv: $!";
1656      ($port, $hisiaddr) = sockaddr_in($hispaddr);
1657      $host = gethostbyaddr($hisiaddr, AF_INET);
1658      $histime = unpack("N", $rtime) - $SECS_OF_70_YEARS;
1659      printf "%-12s ", $host;
1660      printf "%8d %s\n", $histime - time(), scalar localtime($histime);
1661      $count--;
1662  }
1663
1664 This example does not include any retries and may consequently fail to
1665 contact a reachable host. The most prominent reason for this is congestion
1666 of the queues on the sending host if the number of hosts to contact is
1667 sufficiently large.
1668
1669 =head1 SysV IPC
1670
1671 While System V IPC isn't so widely used as sockets, it still has some
1672 interesting uses.  However, you cannot use SysV IPC or Berkeley mmap() to
1673 have a variable shared amongst several processes.  That's because Perl
1674 would reallocate your string when you weren't wanting it to.  You might
1675 look into the C<IPC::Shareable> or C<threads::shared> modules for that.
1676
1677 Here's a small example showing shared memory usage.
1678
1679     use IPC::SysV qw(IPC_PRIVATE IPC_RMID S_IRUSR S_IWUSR);
1680
1681     $size = 2000;
1682     $id = shmget(IPC_PRIVATE, $size, S_IRUSR | S_IWUSR);
1683     defined($id)                    || die "shmget: $!";
1684     print "shm key $id\n";
1685
1686     $message = "Message #1";
1687     shmwrite($id, $message, 0, 60)  || die "shmwrite: $!";
1688     print "wrote: '$message'\n";
1689     shmread($id, $buff, 0, 60)      || die "shmread: $!";
1690     print "read : '$buff'\n";
1691
1692     # the buffer of shmread is zero-character end-padded.
1693     substr($buff, index($buff, "\0")) = "";
1694     print "un" unless $buff eq $message;
1695     print "swell\n";
1696
1697     print "deleting shm $id\n";
1698     shmctl($id, IPC_RMID, 0)        || die "shmctl: $!";
1699
1700 Here's an example of a semaphore:
1701
1702     use IPC::SysV qw(IPC_CREAT);
1703
1704     $IPC_KEY = 1234;
1705     $id = semget($IPC_KEY, 10, 0666 | IPC_CREAT);
1706     defined($id)                    || die "semget: $!";
1707     print "sem id $id\n";
1708
1709 Put this code in a separate file to be run in more than one process.
1710 Call the file F<take>:
1711
1712     # create a semaphore
1713
1714     $IPC_KEY = 1234;
1715     $id = semget($IPC_KEY, 0, 0);
1716     defined($id)                    || die "semget: $!";
1717
1718     $semnum  = 0;
1719     $semflag = 0;
1720
1721     # "take" semaphore
1722     # wait for semaphore to be zero
1723     $semop = 0;
1724     $opstring1 = pack("s!s!s!", $semnum, $semop, $semflag);
1725
1726     # Increment the semaphore count
1727     $semop = 1;
1728     $opstring2 = pack("s!s!s!", $semnum, $semop,  $semflag);
1729     $opstring  = $opstring1 . $opstring2;
1730
1731     semop($id, $opstring)   || die "semop: $!";
1732
1733 Put this code in a separate file to be run in more than one process.
1734 Call this file F<give>:
1735
1736     # "give" the semaphore
1737     # run this in the original process and you will see
1738     # that the second process continues
1739
1740     $IPC_KEY = 1234;
1741     $id = semget($IPC_KEY, 0, 0);
1742     die unless defined($id);
1743
1744     $semnum  = 0;
1745     $semflag = 0;
1746
1747     # Decrement the semaphore count
1748     $semop = -1;
1749     $opstring = pack("s!s!s!", $semnum, $semop, $semflag);
1750
1751     semop($id, $opstring)   || die "semop: $!";
1752
1753 The SysV IPC code above was written long ago, and it's definitely
1754 clunky looking.  For a more modern look, see the IPC::SysV module.
1755
1756 A small example demonstrating SysV message queues:
1757
1758     use IPC::SysV qw(IPC_PRIVATE IPC_RMID IPC_CREAT S_IRUSR S_IWUSR);
1759
1760     my $id = msgget(IPC_PRIVATE, IPC_CREAT | S_IRUSR | S_IWUSR);
1761     defined($id)                || die "msgget failed: $!";
1762
1763     my $sent      = "message";
1764     my $type_sent = 1234;
1765
1766     msgsnd($id, pack("l! a*", $type_sent, $sent), 0)
1767                                 || die "msgsnd failed: $!";
1768
1769     msgrcv($id, my $rcvd_buf, 60, 0, 0)
1770                                 || die "msgrcv failed: $!";
1771
1772     my($type_rcvd, $rcvd) = unpack("l! a*", $rcvd_buf);
1773
1774     if ($rcvd eq $sent) {
1775         print "okay\n";
1776     } else {
1777         print "not okay\n";
1778     }
1779
1780     msgctl($id, IPC_RMID, 0)    || die "msgctl failed: $!\n";
1781
1782 =head1 NOTES
1783
1784 Most of these routines quietly but politely return C<undef> when they
1785 fail instead of causing your program to die right then and there due to
1786 an uncaught exception.  (Actually, some of the new I<Socket> conversion
1787 functions do croak() on bad arguments.)  It is therefore essential to
1788 check return values from these functions.  Always begin your socket
1789 programs this way for optimal success, and don't forget to add the B<-T>
1790 taint-checking flag to the C<#!> line for servers:
1791
1792     #!/usr/bin/perl -Tw
1793     use strict;
1794     use sigtrap;
1795     use Socket;
1796
1797 =head1 BUGS
1798
1799 These routines all create system-specific portability problems.  As noted
1800 elsewhere, Perl is at the mercy of your C libraries for much of its system
1801 behavior.  It's probably safest to assume broken SysV semantics for
1802 signals and to stick with simple TCP and UDP socket operations; e.g., don't
1803 try to pass open file descriptors over a local UDP datagram socket if you
1804 want your code to stand a chance of being portable.
1805
1806 =head1 AUTHOR
1807
1808 Tom Christiansen, with occasional vestiges of Larry Wall's original
1809 version and suggestions from the Perl Porters.
1810
1811 =head1 SEE ALSO
1812
1813 There's a lot more to networking than this, but this should get you
1814 started.
1815
1816 For intrepid programmers, the indispensable textbook is I<Unix Network
1817 Programming, 2nd Edition, Volume 1> by W. Richard Stevens (published by
1818 Prentice-Hall).  Most books on networking address the subject from the
1819 perspective of a C programmer; translation to Perl is left as an exercise
1820 for the reader.
1821
1822 The IO::Socket(3) manpage describes the object library, and the Socket(3)
1823 manpage describes the low-level interface to sockets.  Besides the obvious
1824 functions in L<perlfunc>, you should also check out the F<modules> file at
1825 your nearest CPAN site, especially
1826 L<http://www.cpan.org/modules/00modlist.long.html#ID5_Networking_>.
1827 See L<perlmodlib> or best yet, the F<Perl FAQ> for a description
1828 of what CPAN is and where to get it if the previous link doesn't work
1829 for you.
1830
1831 Section 5 of CPAN's F<modules> file is devoted to "Networking, Device
1832 Control (modems), and Interprocess Communication", and contains numerous
1833 unbundled modules numerous networking modules, Chat and Expect operations,
1834 CGI programming, DCE, FTP, IPC, NNTP, Proxy, Ptty, RPC, SNMP, SMTP, Telnet,
1835 Threads, and ToolTalk--to name just a few.