lib/charnames.pm

   1 package charnames;
   2 use strict;
   3 use warnings;
   4 use File::Spec;
   5 our $VERSION = '1.08';
   6
   7 use bytes ();           # for $bytes::hint_bits
   8
   9 my %alias1 = (
  10                 # Icky 3.2 names with parentheses.
  11                 'LINE FEED'             => 'LINE FEED (LF)',
  12                 'FORM FEED'             => 'FORM FEED (FF)',
  13                 'CARRIAGE RETURN'       => 'CARRIAGE RETURN (CR)',
  14                 'NEXT LINE'             => 'NEXT LINE (NEL)',
  15                 # Convenience.
  16                 'LF'                    => 'LINE FEED (LF)',
  17                 'FF'                    => 'FORM FEED (FF)',
  18                 'CR'                    => 'CARRIAGE RETURN (CR)',
  19                 'NEL'                   => 'NEXT LINE (NEL)',
  20                 # More convenience.  For futher convencience,
  21                 # it is suggested some way using using the NamesList
  22                 # aliases is implemented.
  23                 'ZWNJ'                  => 'ZERO WIDTH NON-JOINER',
  24                 'ZWJ'                   => 'ZERO WIDTH JOINER',
  25                 'BOM'                   => 'BYTE ORDER MARK',
  26             );
  27
  28 my %alias2 = (
  29                 # Pre-3.2 compatibility (only for the first 256 characters).
  30                 'HORIZONTAL TABULATION' => 'CHARACTER TABULATION',
  31                 'VERTICAL TABULATION'   => 'LINE TABULATION',
  32                 'FILE SEPARATOR'        => 'INFORMATION SEPARATOR FOUR',
  33                 'GROUP SEPARATOR'       => 'INFORMATION SEPARATOR THREE',
  34                 'RECORD SEPARATOR'      => 'INFORMATION SEPARATOR TWO',
  35                 'UNIT SEPARATOR'        => 'INFORMATION SEPARATOR ONE',
  36                 'PARTIAL LINE DOWN'     => 'PARTIAL LINE FORWARD',
  37                 'PARTIAL LINE UP'       => 'PARTIAL LINE BACKWARD',
  38             );
  39
  40 my %alias3 = (
  41                 # User defined aliasses. Even more convenient :)
  42             );
  43 my $txt;
  44
  45 sub croak
  46 {
  47   require Carp; goto &Carp::croak;
  48 } # croak
  49
  50 sub carp
  51 {
  52   require Carp; goto &Carp::carp;
  53 } # carp
  54
  55 sub alias (@)
  56 {
  57   @_ or return %alias3;
  58   my $alias = ref $_[0] ? $_[0] : { @_ };
  59   @alias3{keys %$alias} = values %$alias;
  60 } # alias
  61
  62 sub alias_file ($)
  63 {
  64   my ($arg, $file) = @_;
  65   if (-f $arg && File::Spec->file_name_is_absolute ($arg)) {
  66     $file = $arg;
  67   }
  68   elsif ($arg =~ m/^\w+$/) {
  69     $file = "unicore/${arg}_alias.pl";
  70   }
  71   else {
  72     croak "Charnames alias files can only have identifier characters";
  73   }
  74   if (my @alias = do $file) {
  75     @alias == 1 && !defined $alias[0] and
  76       croak "$file cannot be used as alias file for charnames";
  77     @alias % 2 and
  78       croak "$file did not return a (valid) list of alias pairs";
  79     alias (@alias);
  80     return (1);
  81   }
  82   0;
  83 } # alias_file
  84
  85 # This is not optimized in any way yet
  86 sub charnames
  87 {
  88   my $name = shift;
  89
  90   if (exists $alias1{$name}) {
  91     $name = $alias1{$name};
  92   }
  93   elsif (exists $alias2{$name}) {
  94     require warnings;
  95     warnings::warnif('deprecated', qq{Unicode character name "$name" is deprecated, use "$alias2{$name}" instead});
  96     $name = $alias2{$name};
  97   }
  98   elsif (exists $alias3{$name}) {
  99     $name = $alias3{$name};
 100   }
 101
 102   my $ord;
 103   my @off;
 104   my $fname;
 105
 106   if ($name eq "BYTE ORDER MARK") {
 107     $fname = $name;
 108     $ord = 0xFEFF;
 109   } else {
 110     ## Suck in the code/name list as a big string.
 111     ## Lines look like:
 112     ##     "0052\t\tLATIN CAPITAL LETTER R\n"
 113     $txt = do "unicore/Name.pl" unless $txt;
 114
 115     ## @off will hold the index into the code/name string of the start and
 116     ## end of the name as we find it.
 117
 118     ## If :full, look for the name exactly
 119     if ($^H{charnames_full} and $txt =~ /\t\t\Q$name\E$/m) {
 120       @off = ($-[0], $+[0]);
 121     }
 122
 123     ## If we didn't get above, and :short allowed, look for the short name.
 124     ## The short name is like "greek:Sigma"
 125     unless (@off) {
 126       if ($^H{charnames_short} and $name =~ /^(.+?):(.+)/s) {
 127         my ($script, $cname) = ($1, $2);
 128         my $case = $cname =~ /[[:upper:]]/ ? "CAPITAL" : "SMALL";
 129         if ($txt =~ m/\t\t\U$script\E (?:$case )?LETTER \U\Q$cname\E$/m) {
 130           @off = ($-[0], $+[0]);
 131         }
 132       }
 133     }
 134
 135     ## If we still don't have it, check for the name among the loaded
 136     ## scripts.
 137     if (not @off) {
 138       my $case = $name =~ /[[:upper:]]/ ? "CAPITAL" : "SMALL";
 139       for my $script (@{$^H{charnames_scripts}}) {
 140         if ($txt =~ m/\t\t$script (?:$case )?LETTER \U\Q$name\E$/m) {
 141           @off = ($-[0], $+[0]);
 142           last;
 143         }
 144       }
 145     }
 146
 147     ## If we don't have it by now, give up.
 148     unless (@off) {
 149       carp "Unknown charname '$name'";
 150       return "\x{FFFD}";
 151     }
 152
 153     ##
 154     ## Now know where in the string the name starts.
 155     ## The code, in hex, is before that.
 156     ##
 157     ## The code can be 4-6 characters long, so we've got to sort of
 158     ## go look for it, just after the newline that comes before $off[0].
 159     ##
 160     ## This would be much easier if unicore/Name.pl had info in
 161     ## a name/code order, instead of code/name order.
 162     ##
 163     ## The +1 after the rindex() is to skip past the newline we're finding,
 164     ## or, if the rindex() fails, to put us to an offset of zero.
 165     ##
 166     my $hexstart = rindex($txt, "\n", $off[0]) + 1;
 167
 168     ## we know where it starts, so turn into number -
 169     ## the ordinal for the char.
 170     $ord = CORE::hex substr($txt, $hexstart, $off[0] - $hexstart);
 171   }
 172
 173   if ($^H & $bytes::hint_bits) {        # "use bytes" in effect?
 174     use bytes;
 175     return chr $ord if $ord <= 255;
 176     my $hex = sprintf "%04x", $ord;
 177     if (not defined $fname) {
 178       $fname = substr $txt, $off[0] + 2, $off[1] - $off[0] - 2;
 179     }
 180     croak "Character 0x$hex with name '$fname' is above 0xFF";
 181   }
 182
 183   no warnings 'utf8'; # allow even illegal characters
 184   return pack "U", $ord;
 185 } # charnames
 186
 187 sub import
 188 {
 189   shift; ## ignore class name
 190
 191   if (not @_) {
 192     carp("`use charnames' needs explicit imports list");
 193   }
 194   $^H{charnames} = \&charnames ;
 195
 196   ##
 197   ## fill %h keys with our @_ args.
 198   ##
 199   my ($promote, %h, @args) = (0);
 200   while (my $arg = shift) {
 201     if ($arg eq ":alias") {
 202       @_ or
 203         croak ":alias needs an argument in charnames";
 204       my $alias = shift;
 205       if (ref $alias) {
 206         ref $alias eq "HASH" or
 207           croak "Only HASH reference supported as argument to :alias";
 208         alias ($alias);
 209         next;
 210       }
 211       if ($alias =~ m{:(\w+)$}) {
 212         $1 eq "full" || $1 eq "short" and
 213           croak ":alias cannot use existing pragma :$1 (reversed order?)";
 214         alias_file ($1) and $promote = 1;
 215         next;
 216       }
 217       alias_file ($alias);
 218       next;
 219     }
 220     if (substr($arg, 0, 1) eq ':' and ! ($arg eq ":full" || $arg eq ":short")) {
 221       warn "unsupported special '$arg' in charnames";
 222       next;
 223     }
 224     push @args, $arg;
 225   }
 226   @args == 0 && $promote and @args = (":full");
 227   @h{@args} = (1) x @args;
 228
 229   $^H{charnames_full} = delete $h{':full'};
 230   $^H{charnames_short} = delete $h{':short'};
 231   $^H{charnames_scripts} = [map uc, keys %h];
 232
 233   ##
 234   ## If utf8? warnings are enabled, and some scripts were given,
 235   ## see if at least we can find one letter of each script.
 236   ##
 237   if (warnings::enabled('utf8') && @{$^H{charnames_scripts}}) {
 238     $txt = do "unicore/Name.pl" unless $txt;
 239
 240     for my $script (@{$^H{charnames_scripts}}) {
 241       if (not $txt =~ m/\t\t$script (?:CAPITAL |SMALL )?LETTER /) {
 242         warnings::warn('utf8',  "No such script: '$script'");
 243       }
 244     }
 245   }
 246 } # import
 247
 248 my %viacode;
 249
 250 sub viacode
 251 {
 252   if (@_ != 1) {
 253     carp "charnames::viacode() expects one argument";
 254     return;
 255   }
 256
 257   my $arg = shift;
 258
 259   # this is derived from Unicode::UCD, where it is nearly the same as the
 260   # function _getcode(), but it makes sure that even a hex argument has the
 261   # proper number of leading zeros, which is critical in matching against $txt
 262   # below
 263   my $hex;
 264   if ($arg =~ /^[1-9]\d*$/) {
 265     $hex = sprintf "%04X", $arg;
 266   } elsif ($arg =~ /^(?:[Uu]\+|0[xX])?([[:xdigit:]]+)$/) {
 267     # Below is the line that differs from the _getcode() source
 268     $hex = sprintf "%04X", hex $arg;
 269   } else {
 270     carp("unexpected arg \"$arg\" to charnames::viacode()");
 271     return;
 272   }
 273
 274   # checking the length first is slightly faster
 275   if (length($hex) > 5 && hex($hex) > 0x10FFFF) {
 276     carp "Unicode characters only allocated up to U+10FFFF (you asked for U+$hex)";
 277     return;
 278   }
 279
 280   return $viacode{$hex} if exists $viacode{$hex};
 281
 282   $txt = do "unicore/Name.pl" unless $txt;
 283
 284   return unless $txt =~ m/^$hex\t\t(.+)/m;
 285
 286   $viacode{$hex} = $1;
 287 } # viacode
 288
 289 my %vianame;
 290
 291 sub vianame
 292 {
 293   if (@_ != 1) {
 294     carp "charnames::vianame() expects one name argument";
 295     return ()
 296   }
 297
 298   my $arg = shift;
 299
 300   return chr CORE::hex $1 if $arg =~ /^U\+([0-9a-fA-F]+)$/;
 301
 302   return $vianame{$arg} if exists $vianame{$arg};
 303
 304   $txt = do "unicore/Name.pl" unless $txt;
 305
 306   my $pos = index $txt, "\t\t$arg\n";
 307   if (0 <= $pos) {
 308     my $posLF = rindex $txt, "\n", $pos;
 309     (my $code = substr $txt, $posLF + 1, 6) =~ tr/\t//d;
 310     return $vianame{$arg} = CORE::hex $code;
 311
 312     # If $pos is at the 1st line, $posLF must be -1 (not found);
 313     # then $posLF + 1 equals to 0 (at the beginning of $txt).
 314     # Otherwise $posLF is the position of "\n";
 315     # then $posLF + 1 must be the position of the next to "\n"
 316     # (the beginning of the line).
 317     # substr($txt, $posLF + 1, 6) may be "0000\t\t", "00A1\t\t",
 318     # "10300\t", "100000", etc. So we can get the code via removing TAB.
 319   } else {
 320     return;
 321   }
 322 } # vianame
 323
 324
 325 1;
 326 __END__
 327
 328 =head1 NAME
 329
 330 charnames - define character names for C<\N{named}> string literal escapes
 331
 332 =head1 SYNOPSIS
 333
 334   use charnames ':full';
 335   print "\N{GREEK SMALL LETTER SIGMA} is called sigma.\n";
 336
 337   use charnames ':short';
 338   print "\N{greek:Sigma} is an upper-case sigma.\n";
 339
 340   use charnames qw(cyrillic greek);
 341   print "\N{sigma} is Greek sigma, and \N{be} is Cyrillic b.\n";
 342
 343   use charnames ":full", ":alias" => {
 344     e_ACUTE => "LATIN SMALL LETTER E WITH ACUTE",
 345   };
 346   print "\N{e_ACUTE} is a small letter e with an acute.\n";
 347
 348   use charnames ();
 349   print charnames::viacode(0x1234); # prints "ETHIOPIC SYLLABLE SEE"
 350   printf "%04X", charnames::vianame("GOTHIC LETTER AHSA"); # prints "10330"
 351
 352 =head1 DESCRIPTION
 353
 354 Pragma C<use charnames> supports arguments C<:full>, C<:short>, script
 355 names and customized aliases.  If C<:full> is present, for expansion of
 356 C<\N{CHARNAME}>, the string C<CHARNAME> is first looked up in the list of
 357 standard Unicode character names.  If C<:short> is present, and
 358 C<CHARNAME> has the form C<SCRIPT:CNAME>, then C<CNAME> is looked up
 359 as a letter in script C<SCRIPT>.  If pragma C<use charnames> is used
 360 with script name arguments, then for C<\N{CHARNAME}> the name
 361 C<CHARNAME> is looked up as a letter in the given scripts (in the
 362 specified order). Customized aliases are explained in L</CUSTOM ALIASES>.
 363
 364 For lookup of C<CHARNAME> inside a given script C<SCRIPTNAME>
 365 this pragma looks for the names
 366
 367   SCRIPTNAME CAPITAL LETTER CHARNAME
 368   SCRIPTNAME SMALL LETTER CHARNAME
 369   SCRIPTNAME LETTER CHARNAME
 370
 371 in the table of standard Unicode names.  If C<CHARNAME> is lowercase,
 372 then the C<CAPITAL> variant is ignored, otherwise the C<SMALL> variant
 373 is ignored.
 374
 375 Note that C<\N{...}> is compile-time, it's a special form of string
 376 constant used inside double-quoted strings: in other words, you cannot
 377 use variables inside the C<\N{...}>.  If you want similar run-time
 378 functionality, use charnames::vianame().
 379
 380 For the C0 and C1 control characters (U+0000..U+001F, U+0080..U+009F)
 381 as of Unicode 3.1, there are no official Unicode names but you can use
 382 instead the ISO 6429 names (LINE FEED, ESCAPE, and so forth).  In
 383 Unicode 3.2 (as of Perl 5.8) some naming changes take place ISO 6429
 384 has been updated, see L</ALIASES>.  Also note that the U+UU80, U+0081,
 385 U+0084, and U+0099 do not have names even in ISO 6429.
 386
 387 Since the Unicode standard uses "U+HHHH", so can you: "\N{U+263a}"
 388 is the Unicode smiley face, or "\N{WHITE SMILING FACE}".
 389
 390 =head1 ALIASES
 391
 392 A few aliases have been defined for convenience: instead of having
 393 to use the official names
 394
 395     LINE FEED (LF)
 396     FORM FEED (FF)
 397     CARRIAGE RETURN (CR)
 398     NEXT LINE (NEL)
 399
 400 (yes, with parentheses) one can use
 401
 402     LINE FEED
 403     FORM FEED
 404     CARRIAGE RETURN
 405     NEXT LINE
 406     LF
 407     FF
 408     CR
 409     NEL
 410
 411 One can also use
 412
 413     BYTE ORDER MARK
 414     BOM
 415
 416 and
 417
 418     ZWNJ
 419     ZWJ
 420
 421 for ZERO WIDTH NON-JOINER and ZERO WIDTH JOINER.
 422
 423 For backward compatibility one can use the old names for
 424 certain C0 and C1 controls
 425
 426     old                         new
 427
 428     HORIZONTAL TABULATION       CHARACTER TABULATION
 429     VERTICAL TABULATION         LINE TABULATION
 430     FILE SEPARATOR              INFORMATION SEPARATOR FOUR
 431     GROUP SEPARATOR             INFORMATION SEPARATOR THREE
 432     RECORD SEPARATOR            INFORMATION SEPARATOR TWO
 433     UNIT SEPARATOR              INFORMATION SEPARATOR ONE
 434     PARTIAL LINE DOWN           PARTIAL LINE FORWARD
 435     PARTIAL LINE UP             PARTIAL LINE BACKWARD
 436
 437 but the old names in addition to giving the character
 438 will also give a warning about being deprecated.
 439
 440 =head1 CUSTOM ALIASES
 441
 442 This version of charnames supports three mechanisms of adding local
 443 or customized aliases to standard Unicode naming conventions (:full).
 444
 445 Note that an alias should not be something that is a legal curly
 446 brace-enclosed quantifier (see L<perlreref/QUANTIFIERS>).  For example
 447 C<\N{123}> means to match 123 non-newline characters, and is not treated as an
 448 alias.  Aliases are discouraged from beginning with anything other than an
 449 alphabetic character and from containing anything other than alphanumerics,
 450 spaces, dashes, colons, parentheses, and underscores.  Currently they must be
 451 ASCII.
 452
 453 =head2 Anonymous hashes
 454
 455     use charnames ":full", ":alias" => {
 456         e_ACUTE => "LATIN SMALL LETTER E WITH ACUTE",
 457         };
 458     my $str = "\N{e_ACUTE}";
 459
 460 =head2 Alias file
 461
 462     use charnames ":full", ":alias" => "pro";
 463
 464     will try to read "unicore/pro_alias.pl" from the @INC path. This
 465     file should return a list in plain perl:
 466
 467     (
 468     A_GRAVE         => "LATIN CAPITAL LETTER A WITH GRAVE",
 469     A_CIRCUM        => "LATIN CAPITAL LETTER A WITH CIRCUMFLEX",
 470     A_DIAERES       => "LATIN CAPITAL LETTER A WITH DIAERESIS",
 471     A_TILDE         => "LATIN CAPITAL LETTER A WITH TILDE",
 472     A_BREVE         => "LATIN CAPITAL LETTER A WITH BREVE",
 473     A_RING          => "LATIN CAPITAL LETTER A WITH RING ABOVE",
 474     A_MACRON        => "LATIN CAPITAL LETTER A WITH MACRON",
 475     );
 476
 477 =head2 Alias shortcut
 478
 479     use charnames ":alias" => ":pro";
 480
 481     works exactly the same as the alias pairs, only this time,
 482     ":full" is inserted automatically as first argument (if no
 483     other argument is given).
 484
 485 =head1 charnames::viacode(code)
 486
 487 Returns the full name of the character indicated by the numeric code.
 488 The example
 489
 490     print charnames::viacode(0x2722);
 491
 492 prints "FOUR TEARDROP-SPOKED ASTERISK".
 493
 494 Returns undef if no name is known for the code.
 495
 496 This works only for the standard names, and does not yet apply
 497 to custom translators.
 498
 499 Notice that the name returned for of U+FEFF is "ZERO WIDTH NO-BREAK
 500 SPACE", not "BYTE ORDER MARK".
 501
 502 =head1 charnames::vianame(name)
 503
 504 Returns the code point indicated by the name.
 505 The example
 506
 507     printf "%04X", charnames::vianame("FOUR TEARDROP-SPOKED ASTERISK");
 508
 509 prints "2722".
 510
 511 Returns undef if the name is unknown.
 512
 513 This works only for the standard names, and does not yet apply
 514 to custom translators.
 515
 516 =head1 CUSTOM TRANSLATORS
 517
 518 The mechanism of translation of C<\N{...}> escapes is general and not
 519 hardwired into F<charnames.pm>.  A module can install custom
 520 translations (inside the scope which C<use>s the module) with the
 521 following magic incantation:
 522
 523     sub import {
 524         shift;
 525         $^H{charnames} = \&translator;
 526     }
 527
 528 Here translator() is a subroutine which takes C<CHARNAME> as an
 529 argument, and returns text to insert into the string instead of the
 530 C<\N{CHARNAME}> escape.  Since the text to insert should be different
 531 in C<bytes> mode and out of it, the function should check the current
 532 state of C<bytes>-flag as in:
 533
 534     use bytes ();                       # for $bytes::hint_bits
 535     sub translator {
 536         if ($^H & $bytes::hint_bits) {
 537             return bytes_translator(@_);
 538         }
 539         else {
 540             return utf8_translator(@_);
 541         }
 542     }
 543
 544 See L</CUSTOM ALIASES> above for restrictions on C<CHARNAME>.
 545
 546 =head1 ILLEGAL CHARACTERS
 547
 548 If you ask by name for a character that does not exist, a warning is given and
 549 the Unicode I<replacement character> "\x{FFFD}" is returned.
 550
 551 If you ask by code for a character that is unassigned, no warning is
 552 given and C<undef> is returned.  (Though if you ask for a code point
 553 past U+10FFFF you do get a warning.)  See L</BUGS> below.
 554
 555 =head1 BUGS
 556
 557 viacode should return an empty string for unassigned in-range Unicode code
 558 points, as that is their correct current name.
 559
 560 viacode(0) doesn't return C<NULL>, but C<undef>
 561
 562 vianame returns a chr if the input name is of the form C<U+...>, and an ord
 563 otherwise.  It is planned to change this to always return an ord.
 564
 565 None of the functions work on almost all the Hangul syllable and CJK Unicode
 566 characters that have their code points as part of their names.
 567
 568 Names must be ASCII characters only.
 569
 570 Unicode standard named sequences are not recognized, such as
 571 C<LATIN CAPITAL LETTER A WITH MACRON AND GRAVE>
 572 (which should mean C<LATIN CAPITAL LETTER A WITH MACRON> with an additional
 573 C<COMBINING GRAVE ACCENT>).
 574
 575 Since evaluation of the translation function happens in the middle of
 576 compilation (of a string literal), the translation function should not
 577 do any C<eval>s or C<require>s.  This restriction should be lifted in
 578 a future version of Perl.
 579
 580 =cut