This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
rip out CPAN-release cruft from B::Deparse
[perl5.git] / lib / B / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD OPf_PARENS
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpKVSLICE
16          OPpCONST_BARE
17          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
18          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER OPpREPEAT_DOLIST
19          OPpSORT_REVERSE OPpMULTIDEREF_EXISTS OPpMULTIDEREF_DELETE
20          OPpSPLIT_ASSIGN OPpSPLIT_LEX
21          OPpPADHV_ISKEYS OPpRV2HV_ISKEYS
22          OPpMULTICONCAT_APPEND OPpMULTICONCAT_STRINGIFY OPpMULTICONCAT_FAKE
23          OPpTRUEBOOL OPpINDEX_BOOLNEG
24          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
25          SVs_PADTMP SVpad_TYPED
26          CVf_METHOD CVf_LVALUE
27          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
28          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED PMf_EXTENDED_MORE
29          PADNAMEt_OUTER
30         MDEREF_reload
31         MDEREF_AV_pop_rv2av_aelem
32         MDEREF_AV_gvsv_vivify_rv2av_aelem
33         MDEREF_AV_padsv_vivify_rv2av_aelem
34         MDEREF_AV_vivify_rv2av_aelem
35         MDEREF_AV_padav_aelem
36         MDEREF_AV_gvav_aelem
37         MDEREF_HV_pop_rv2hv_helem
38         MDEREF_HV_gvsv_vivify_rv2hv_helem
39         MDEREF_HV_padsv_vivify_rv2hv_helem
40         MDEREF_HV_vivify_rv2hv_helem
41         MDEREF_HV_padhv_helem
42         MDEREF_HV_gvhv_helem
43         MDEREF_ACTION_MASK
44         MDEREF_INDEX_none
45         MDEREF_INDEX_const
46         MDEREF_INDEX_padsv
47         MDEREF_INDEX_gvsv
48         MDEREF_INDEX_MASK
49         MDEREF_FLAG_last
50         MDEREF_MASK
51         MDEREF_SHIFT
52     );
53
54 $VERSION = '1.45';
55 use strict;
56 our $AUTOLOAD;
57 use warnings ();
58 require feature;
59
60 BEGIN {
61     # List version-specific constants here.
62     # Easiest way to keep this code portable between version looks to
63     # be to fake up a dummy constant that will never actually be true.
64     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
65                 OPpPAD_STATE PMf_SKIPWHITE RXf_SKIPWHITE
66                 PMf_CHARSET PMf_KEEPCOPY PMf_NOCAPTURE CVf_ANONCONST
67                 CVf_LOCKED OPpREVERSE_INPLACE OPpSUBSTR_REPL_FIRST
68                 PMf_NONDESTRUCT OPpCONST_ARYBASE OPpEVAL_BYTES
69                 OPpLVREF_TYPE OPpLVREF_SV OPpLVREF_AV OPpLVREF_HV
70                 OPpLVREF_CV OPpLVREF_ELEM SVpad_STATE)) {
71         eval { B->import($_) };
72         no strict 'refs';
73         *{$_} = sub () {0} unless *{$_}{CODE};
74     }
75 }
76
77 # Todo:
78 #  (See also BUGS section at the end of this file)
79 #
80 # - finish tr/// changes
81 # - add option for even more parens (generalize \&foo change)
82 # - left/right context
83 # - copy comments (look at real text with $^P?)
84 # - avoid semis in one-statement blocks
85 # - associativity of &&=, ||=, ?:
86 # - ',' => '=>' (auto-unquote?)
87 # - break long lines ("\r" as discretionary break?)
88 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
89 # - more style options: brace style, hex vs. octal, quotes, ...
90 # - print big ints as hex/octal instead of decimal (heuristic?)
91 # - handle 'my $x if 0'?
92 # - version using op_next instead of op_first/sibling?
93 # - avoid string copies (pass arrays, one big join?)
94 # - here-docs?
95
96 # Current test.deparse failures
97 # comp/hints 6 - location of BEGIN blocks wrt. block openings
98 # run/switchI 1 - missing -I switches entirely
99 #    perl -Ifoo -e 'print @INC'
100 # op/caller 2 - warning mask propagates backwards before warnings::register
101 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
102 # op/getpid 2 - can't assign to shared my() declaration (threads only)
103 #    'my $x : shared = 5'
104 # op/override 7 - parens on overridden require change v-string interpretation
105 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
106 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
107 # op/pat 774 - losing Unicode-ness of Latin1-only strings
108 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
109 # op/recurse 12 - missing parens on recursive call makes it look like method
110 #    'sub f { f($x) }'
111 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
112 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
113 # op/tiehandle compile - "use strict" deparsed in the wrong place
114 # uni/tr_ several
115 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
116 # ext/Data/Dumper/t/dumper compile
117 # ext/DB_file/several
118 # ext/Encode/several
119 # ext/Ernno/Errno warnings
120 # ext/IO/lib/IO/t/io_sel 23
121 # ext/PerlIO/t/encoding compile
122 # ext/POSIX/t/posix 6
123 # ext/Socket/Socket 8
124 # ext/Storable/t/croak compile
125 # lib/Attribute/Handlers/t/multi compile
126 # lib/bignum/ several
127 # lib/charnames 35
128 # lib/constant 32
129 # lib/English 40
130 # lib/ExtUtils/t/bytes 4
131 # lib/File/DosGlob compile
132 # lib/Filter/Simple/t/data 1
133 # lib/Math/BigInt/t/constant 1
134 # lib/Net/t/config Deparse-warning
135 # lib/overload compile
136 # lib/Switch/ several
137 # lib/Symbol 4
138 # lib/Test/Simple several
139 # lib/Term/Complete
140 # lib/Tie/File/t/29_downcopy 5
141 # lib/vars 22
142
143 # Object fields:
144 #
145 # in_coderef2text:
146 # True when deparsing via $deparse->coderef2text; false when deparsing the
147 # main program.
148 #
149 # avoid_local:
150 # (local($a), local($b)) and local($a, $b) have the same internal
151 # representation but the short form looks better. We notice we can
152 # use a large-scale local when checking the list, but need to prevent
153 # individual locals too. This hash holds the addresses of OPs that
154 # have already had their local-ness accounted for. The same thing
155 # is done with my().
156 #
157 # curcv:
158 # CV for current sub (or main program) being deparsed
159 #
160 # curcvlex:
161 # Cached hash of lexical variables for curcv: keys are
162 # names prefixed with "m" or "o" (representing my/our), and
163 # each value is an array with two elements indicating the cop_seq
164 # of scopes in which a var of that name is valid and a third ele-
165 # ment referencing the pad name.
166 #
167 # curcop:
168 # COP for statement being deparsed
169 #
170 # curstash:
171 # name of the current package for deparsed code
172 #
173 # subs_todo:
174 # array of [cop_seq, CV, is_format?, name] for subs and formats we still
175 # want to deparse.  The fourth element is a pad name thingy for lexical
176 # subs or a string for special blocks.  For other subs, it is undef.  For
177 # lexical subs, CV may be undef, indicating a stub declaration.
178 #
179 # protos_todo:
180 # as above, but [name, prototype] for subs that never got a GV
181 #
182 # subs_done, forms_done:
183 # keys are addresses of GVs for subs and formats we've already
184 # deparsed (or at least put into subs_todo)
185 #
186 # subs_declared
187 # keys are names of subs for which we've printed declarations.
188 # That means we can omit parentheses from the arguments. It also means we
189 # need to put CORE:: on core functions of the same name.
190 #
191 # in_subst_repl
192 # True when deparsing the replacement part of a substitution.
193 #
194 # in_refgen
195 # True when deparsing the argument to \.
196 #
197 # parens: -p
198 # linenums: -l
199 # unquote: -q
200 # cuddle: ' ' or '\n', depending on -sC
201 # indent_size: -si
202 # use_tabs: -sT
203 # ex_const: -sv
204
205 # A little explanation of how precedence contexts and associativity
206 # work:
207 #
208 # deparse() calls each per-op subroutine with an argument $cx (short
209 # for context, but not the same as the cx* in the perl core), which is
210 # a number describing the op's parents in terms of precedence, whether
211 # they're inside an expression or at statement level, etc.  (see
212 # chart below). When ops with children call deparse on them, they pass
213 # along their precedence. Fractional values are used to implement
214 # associativity ('($x + $y) + $z' => '$x + $y + $y') and related
215 # parentheses hacks. The major disadvantage of this scheme is that
216 # it doesn't know about right sides and left sides, so say if you
217 # assign a listop to a variable, it can't tell it's allowed to leave
218 # the parens off the listop.
219
220 # Precedences:
221 # 26             [TODO] inside interpolation context ("")
222 # 25 left        terms and list operators (leftward)
223 # 24 left        ->
224 # 23 nonassoc    ++ --
225 # 22 right       **
226 # 21 right       ! ~ \ and unary + and -
227 # 20 left        =~ !~
228 # 19 left        * / % x
229 # 18 left        + - .
230 # 17 left        << >>
231 # 16 nonassoc    named unary operators
232 # 15 nonassoc    < > <= >= lt gt le ge
233 # 14 nonassoc    == != <=> eq ne cmp
234 # 13 left        &
235 # 12 left        | ^
236 # 11 left        &&
237 # 10 left        ||
238 #  9 nonassoc    ..  ...
239 #  8 right       ?:
240 #  7 right       = += -= *= etc.
241 #  6 left        , =>
242 #  5 nonassoc    list operators (rightward)
243 #  4 right       not
244 #  3 left        and
245 #  2 left        or xor
246 #  1             statement modifiers
247 #  0.5           statements, but still print scopes as do { ... }
248 #  0             statement level
249 # -1             format body
250
251 # Nonprinting characters with special meaning:
252 # \cS - steal parens (see maybe_parens_unop)
253 # \n - newline and indent
254 # \t - increase indent
255 # \b - decrease indent ('outdent')
256 # \f - flush left (no indent)
257 # \cK - kill following semicolon, if any
258
259 # Semicolon handling:
260 #  - Individual statements are not deparsed with trailing semicolons.
261 #    (If necessary, \cK is tacked on to the end.)
262 #  - Whatever code joins statements together or emits them (lineseq,
263 #    scopeop, deparse_root) is responsible for adding semicolons where
264 #    necessary.
265 #  - use statements are deparsed with trailing semicolons because they are
266 #    immediately concatenated with the following statement.
267 #  - indent() removes semicolons wherever it sees \cK.
268
269
270 BEGIN { for (qw[ const stringify rv2sv list glob pushmark null aelem
271                  kvaslice kvhslice padsv
272                  nextstate dbstate rv2av rv2hv helem custom ]) {
273     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
274 }}
275
276 # _pessimise_walk(): recursively walk the optree of a sub,
277 # possibly undoing optimisations along the way.
278
279 sub _pessimise_walk {
280     my ($self, $startop) = @_;
281
282     return unless $$startop;
283     my ($op, $prevop);
284     for ($op = $startop; $$op; $prevop = $op, $op = $op->sibling) {
285         my $ppname = $op->name;
286
287         # pessimisations start here
288
289         if ($ppname eq "padrange") {
290             # remove PADRANGE:
291             # the original optimisation either (1) changed this:
292             #    pushmark -> (various pad and list and null ops) -> the_rest
293             # or (2), for the = @_ case, changed this:
294             #    pushmark -> gv[_] -> rv2av -> (pad stuff)       -> the_rest
295             # into this:
296             #    padrange ----------------------------------------> the_rest
297             # so we just need to convert the padrange back into a
298             # pushmark, and in case (1), set its op_next to op_sibling,
299             # which is the head of the original chain of optimised-away
300             # pad ops, or for (2), set it to sibling->first, which is
301             # the original gv[_].
302
303             $B::overlay->{$$op} = {
304                     type => OP_PUSHMARK,
305                     name => 'pushmark',
306                     private => ($op->private & OPpLVAL_INTRO),
307             };
308         }
309
310         # pessimisations end here
311
312         if (class($op) eq 'PMOP') {
313             if (ref($op->pmreplroot)
314                 && ${$op->pmreplroot}
315                 && $op->pmreplroot->isa( 'B::OP' ))
316             {
317                 $self-> _pessimise_walk($op->pmreplroot);
318             }
319
320             # pessimise any /(?{...})/ code blocks
321             my ($re, $cv);
322             my $code_list = $op->code_list;
323             if ($$code_list) {
324                 $self->_pessimise_walk($code_list);
325             }
326             elsif (${$re = $op->pmregexp} && ${$cv = $re->qr_anoncv}) {
327                 $code_list = $cv->ROOT      # leavesub
328                                ->first      #   qr
329                                ->code_list; #     list
330                 $self->_pessimise_walk($code_list);
331             }
332         }
333
334         if ($op->flags & OPf_KIDS) {
335             $self-> _pessimise_walk($op->first);
336         }
337
338     }
339 }
340
341
342 # _pessimise_walk_exe(): recursively walk the op_next chain of a sub,
343 # possibly undoing optimisations along the way.
344
345 sub _pessimise_walk_exe {
346     my ($self, $startop, $visited) = @_;
347
348     no warnings 'recursion';
349
350     return unless $$startop;
351     return if $visited->{$$startop};
352     my ($op, $prevop);
353     for ($op = $startop; $$op; $prevop = $op, $op = $op->next) {
354         last if $visited->{$$op};
355         $visited->{$$op} = 1;
356         my $ppname = $op->name;
357         if ($ppname =~
358             /^((and|d?or)(assign)?|(map|grep)while|range|cond_expr|once)$/
359             # entertry is also a logop, but its op_other invariably points
360             # into the same chain as the main execution path, so we skip it
361         ) {
362             $self->_pessimise_walk_exe($op->other, $visited);
363         }
364         elsif ($ppname eq "subst") {
365             $self->_pessimise_walk_exe($op->pmreplstart, $visited);
366         }
367         elsif ($ppname =~ /^(enter(loop|iter))$/) {
368             # redoop and nextop will already be covered by the main block
369             # of the loop
370             $self->_pessimise_walk_exe($op->lastop, $visited);
371         }
372
373         # pessimisations start here
374     }
375 }
376
377 # Go through an optree and "remove" some optimisations by using an
378 # overlay to selectively modify or un-null some ops. Deparsing in the
379 # absence of those optimisations is then easier.
380 #
381 # Note that older optimisations are not removed, as Deparse was already
382 # written to recognise them before the pessimise/overlay system was added.
383
384 sub pessimise {
385     my ($self, $root, $start) = @_;
386
387     no warnings 'recursion';
388     # walk tree in root-to-branch order
389     $self->_pessimise_walk($root);
390
391     my %visited;
392     # walk tree in execution order
393     $self->_pessimise_walk_exe($start, \%visited);
394 }
395
396
397 sub null {
398     my $op = shift;
399     return class($op) eq "NULL";
400 }
401
402
403 # Add a CV to the list of subs that still need deparsing.
404
405 sub todo {
406     my $self = shift;
407     my($cv, $is_form, $name) = @_;
408     my $cvfile = $cv->FILE//'';
409     return unless ($cvfile eq $0 || exists $self->{files}{$cvfile});
410     my $seq;
411     if ($cv->OUTSIDE_SEQ) {
412         $seq = $cv->OUTSIDE_SEQ;
413     } elsif (!null($cv->START) and is_state($cv->START)) {
414         $seq = $cv->START->cop_seq;
415     } else {
416         $seq = 0;
417     }
418     my $stash = $cv->STASH;
419     if (class($stash) eq 'HV') {
420         $self->{packs}{$stash->NAME}++;
421     }
422     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form, $name];
423 }
424
425
426 # Pop the next sub from the todo list and deparse it
427
428 sub next_todo {
429     my $self = shift;
430     my $ent = shift @{$self->{'subs_todo'}};
431     my ($seq, $cv, $is_form, $name) = @$ent;
432
433     # any 'use strict; package foo' that should come before the sub
434     # declaration to sync with the first COP of the sub
435     my $pragmata = '';
436     if ($cv and !null($cv->START) and is_state($cv->START))  {
437         $pragmata = $self->pragmata($cv->START);
438     }
439
440     if (ref $name) { # lexical sub
441         # emit the sub.
442         my @text;
443         my $flags = $name->FLAGS;
444         push @text,
445             !$cv || $seq <= $name->COP_SEQ_RANGE_LOW
446                 ? $self->keyword($flags & SVpad_OUR
447                                     ? "our"
448                                     : $flags & SVpad_STATE
449                                         ? "state"
450                                         : "my") . " "
451                 : "";
452         # XXX We would do $self->keyword("sub"), but ‘my CORE::sub’
453         #     doesn’t work and ‘my sub’ ignores a &sub in scope.  I.e.,
454         #     we have a core bug here.
455         push @text, "sub " . substr $name->PVX, 1;
456         if ($cv) {
457             # my sub foo { }
458             push @text,  " " . $self->deparse_sub($cv);
459             $text[-1] =~ s/ ;$/;/;
460         }
461         else {
462             # my sub foo;
463             push @text, ";\n";
464         }
465         return $pragmata . join "", @text;
466     }
467
468     my $gv = $cv->GV;
469     $name //= $self->gv_name($gv);
470     if ($is_form) {
471         return $pragmata . $self->keyword("format") . " $name =\n"
472             . $self->deparse_format($cv). "\n";
473     } else {
474         my $use_dec;
475         if ($name eq "BEGIN") {
476             $use_dec = $self->begin_is_use($cv);
477             if (defined ($use_dec) and $self->{'expand'} < 5) {
478                 return $pragmata if 0 == length($use_dec);
479
480                 #  XXX bit of a hack: Test::More's use_ok() method
481                 #  builds a fake use statement which deparses as, e.g.
482                 #      use Net::Ping (@{$args[0];});
483                 #  As well as being superfluous (the use_ok() is deparsed
484                 #  too) and ugly, it fails under use strict and otherwise
485                 #  makes use of a lexical var that's not in scope.
486                 #  So strip it out.
487                 return $pragmata
488                         if $use_dec =~
489                             m/
490                                 \A
491                                 use \s \S+ \s \(\@\{
492                                 (
493                                     \s*\#line\ \d+\ \".*"\s*
494                                 )?
495                                 \$args\[0\];\}\);
496                                 \n
497                                 \Z
498                             /x;
499
500                 $use_dec =~ s/^(use|no)\b/$self->keyword($1)/e;
501             }
502         }
503         my $l = '';
504         if ($self->{'linenums'}) {
505             my $line = $gv->LINE;
506             my $file = $gv->FILE;
507             $l = "\n\f#line $line \"$file\"\n";
508         }
509         my $p = '';
510         my $stash;
511         if (class($cv->STASH) ne "SPECIAL") {
512             $stash = $cv->STASH->NAME;
513             if ($stash ne $self->{'curstash'}) {
514                 $p = $self->keyword("package") . " $stash;\n";
515                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
516                 $self->{'curstash'} = $stash;
517             }
518         }
519         if ($use_dec) {
520             return "$pragmata$p$l$use_dec";
521         }
522         if ( $name !~ /::/ and $self->lex_in_scope("&$name")
523                             || $self->lex_in_scope("&$name", 1) )
524         {
525             $name = "$self->{'curstash'}::$name";
526         } elsif (defined $stash) {
527             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
528         }
529         my $ret = "$pragmata${p}${l}" . $self->keyword("sub") . " $name "
530               . $self->deparse_sub($cv);
531         $self->{'subs_declared'}{$name} = 1;
532         return $ret;
533     }
534 }
535
536
537 # Return a "use" declaration for this BEGIN block, if appropriate
538 sub begin_is_use {
539     my ($self, $cv) = @_;
540     my $root = $cv->ROOT;
541     local @$self{qw'curcv curcvlex'} = ($cv);
542     local $B::overlay = {};
543     $self->pessimise($root, $cv->START);
544 #require B::Debug;
545 #B::walkoptree($cv->ROOT, "debug");
546     my $lineseq = $root->first;
547     return if $lineseq->name ne "lineseq";
548
549     my $req_op = $lineseq->first->sibling;
550     return if $req_op->name ne "require";
551
552     # maybe it's C<require expr> rather than C<require 'foo'>
553     return if ($req_op->first->name ne 'const');
554
555     my $module;
556     if ($req_op->first->private & OPpCONST_BARE) {
557         # Actually it should always be a bareword
558         $module = $self->const_sv($req_op->first)->PV;
559         $module =~ s[/][::]g;
560         $module =~ s/.pm$//;
561     }
562     else {
563         $module = $self->const($self->const_sv($req_op->first), 6);
564     }
565
566     my $version;
567     my $version_op = $req_op->sibling;
568     return if class($version_op) eq "NULL";
569     if ($version_op->name eq "lineseq") {
570         # We have a version parameter; skip nextstate & pushmark
571         my $constop = $version_op->first->next->next;
572
573         return unless $self->const_sv($constop)->PV eq $module;
574         $constop = $constop->sibling;
575         $version = $self->const_sv($constop);
576         if (class($version) eq "IV") {
577             $version = $version->int_value;
578         } elsif (class($version) eq "NV") {
579             $version = $version->NV;
580         } elsif (class($version) ne "PVMG") {
581             # Includes PVIV and PVNV
582             $version = $version->PV;
583         } else {
584             # version specified as a v-string
585             $version = 'v'.join '.', map ord, split //, $version->PV;
586         }
587         $constop = $constop->sibling;
588         return if $constop->name ne "method_named";
589         return if $self->meth_sv($constop)->PV ne "VERSION";
590     }
591
592     $lineseq = $version_op->sibling;
593     return if $lineseq->name ne "lineseq";
594     my $entersub = $lineseq->first->sibling;
595     if ($entersub->name eq "stub") {
596         return "use $module $version ();\n" if defined $version;
597         return "use $module ();\n";
598     }
599     return if $entersub->name ne "entersub";
600
601     # See if there are import arguments
602     my $args = '';
603
604     my $svop = $entersub->first->sibling; # Skip over pushmark
605     return unless $self->const_sv($svop)->PV eq $module;
606
607     # Pull out the arguments
608     for ($svop=$svop->sibling; index($svop->name, "method_") != 0;
609                 $svop = $svop->sibling) {
610         $args .= ", " if length($args);
611         $args .= $self->deparse($svop, 6);
612     }
613
614     my $use = 'use';
615     my $method_named = $svop;
616     return if $method_named->name ne "method_named";
617     my $method_name = $self->meth_sv($method_named)->PV;
618
619     if ($method_name eq "unimport") {
620         $use = 'no';
621     }
622
623     # Certain pragmas are dealt with using hint bits,
624     # so we ignore them here
625     if ($module eq 'strict' || $module eq 'integer'
626         || $module eq 'bytes' || $module eq 'warnings'
627         || $module eq 'feature') {
628         return "";
629     }
630
631     if (defined $version && length $args) {
632         return "$use $module $version ($args);\n";
633     } elsif (defined $version) {
634         return "$use $module $version;\n";
635     } elsif (length $args) {
636         return "$use $module ($args);\n";
637     } else {
638         return "$use $module;\n";
639     }
640 }
641
642 sub stash_subs {
643     my ($self, $pack, $seen) = @_;
644     my (@ret, $stash);
645     if (!defined $pack) {
646         $pack = '';
647         $stash = \%::;
648     }
649     else {
650         $pack =~ s/(::)?$/::/;
651         no strict 'refs';
652         $stash = \%{"main::$pack"};
653     }
654     return
655         if ($seen ||= {})->{
656             $INC{"overload.pm"} ? overload::StrVal($stash) : $stash
657            }++;
658     my %stash = svref_2object($stash)->ARRAY;
659     while (my ($key, $val) = each %stash) {
660         my $flags = $val->FLAGS;
661         if ($flags & SVf_ROK) {
662             # A reference.  Dump this if it is a reference to a CV.  If it
663             # is a constant acting as a proxy for a full subroutine, then
664             # we may or may not have to dump it.  If some form of perl-
665             # space visible code must have created it, be it a use
666             # statement, or some direct symbol-table manipulation code that
667             # we will deparse, then we don’t want to dump it.  If it is the
668             # result of a declaration like sub f () { 42 } then we *do*
669             # want to dump it.  The only way to distinguish these seems
670             # to be the SVs_PADTMP flag on the constant, which is admit-
671             # tedly a hack.
672             my $class = class(my $referent = $val->RV);
673             if ($class eq "CV") {
674                 $self->todo($referent, 0);
675             } elsif (
676                 $class !~ /^(AV|HV|CV|FM|IO|SPECIAL)\z/
677                 # A more robust way to write that would be this, but B does
678                 # not provide the SVt_ constants:
679                 # ($referent->FLAGS & B::SVTYPEMASK) < B::SVt_PVAV
680                 and $referent->FLAGS & SVs_PADTMP
681             ) {
682                 push @{$self->{'protos_todo'}}, [$pack . $key, $val];
683             }
684         } elsif ($flags & (SVf_POK|SVf_IOK)) {
685             # Just a prototype. As an ugly but fairly effective way
686             # to find out if it belongs here is to see if the AUTOLOAD
687             # (if any) for the stash was defined in one of our files.
688             my $A = $stash{"AUTOLOAD"};
689             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
690                 && class($A->CV) eq "CV") {
691                 my $AF = $A->FILE;
692                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
693             }
694             push @{$self->{'protos_todo'}},
695                  [$pack . $key, $flags & SVf_POK ? $val->PV: undef];
696         } elsif (class($val) eq "GV") {
697             if (class(my $cv = $val->CV) ne "SPECIAL") {
698                 next if $self->{'subs_done'}{$$val}++;
699                 next if $$val != ${$cv->GV};   # Ignore imposters
700                 $self->todo($cv, 0);
701             }
702             if (class(my $cv = $val->FORM) ne "SPECIAL") {
703                 next if $self->{'forms_done'}{$$val}++;
704                 next if $$val != ${$cv->GV};   # Ignore imposters
705                 $self->todo($cv, 1);
706             }
707             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
708                 $self->stash_subs($pack . $key, $seen);
709             }
710         }
711     }
712 }
713
714 sub print_protos {
715     my $self = shift;
716     my $ar;
717     my @ret;
718     foreach $ar (@{$self->{'protos_todo'}}) {
719         if (ref $ar->[1]) {
720             # Only print a constant if it occurs in the same package as a
721             # dumped sub.  This is not perfect, but a heuristic that will
722             # hopefully work most of the time.  Ideally we would use
723             # CvFILE, but a constant stub has no CvFILE.
724             my $pack = ($ar->[0] =~ /(.*)::/)[0];
725             next if $pack and !$self->{packs}{$pack}
726         }
727         my $body = defined $ar->[1]
728                 ? ref $ar->[1]
729                     ? " () {\n    " . $self->const($ar->[1]->RV,0) . ";\n}"
730                     : " (". $ar->[1] . ");"
731                 : ";";
732         push @ret, "sub " . $ar->[0] .  "$body\n";
733     }
734     delete $self->{'protos_todo'};
735     return @ret;
736 }
737
738 sub style_opts {
739     my $self = shift;
740     my $opts = shift;
741     my $opt;
742     while (length($opt = substr($opts, 0, 1))) {
743         if ($opt eq "C") {
744             $self->{'cuddle'} = " ";
745             $opts = substr($opts, 1);
746         } elsif ($opt eq "i") {
747             $opts =~ s/^i(\d+)//;
748             $self->{'indent_size'} = $1;
749         } elsif ($opt eq "T") {
750             $self->{'use_tabs'} = 1;
751             $opts = substr($opts, 1);
752         } elsif ($opt eq "v") {
753             $opts =~ s/^v([^.]*)(.|$)//;
754             $self->{'ex_const'} = $1;
755         }
756     }
757 }
758
759 sub new {
760     my $class = shift;
761     my $self = bless {}, $class;
762     $self->{'cuddle'} = "\n";
763     $self->{'curcop'} = undef;
764     $self->{'curstash'} = "main";
765     $self->{'ex_const'} = "'???'";
766     $self->{'expand'} = 0;
767     $self->{'files'} = {};
768     $self->{'packs'} = {};
769     $self->{'indent_size'} = 4;
770     $self->{'linenums'} = 0;
771     $self->{'parens'} = 0;
772     $self->{'subs_todo'} = [];
773     $self->{'unquote'} = 0;
774     $self->{'use_dumper'} = 0;
775     $self->{'use_tabs'} = 0;
776
777     $self->{'ambient_arybase'} = 0;
778     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
779     $self->{'ambient_hints'} = 0;
780     $self->{'ambient_hinthash'} = undef;
781     $self->init();
782
783     while (my $arg = shift @_) {
784         if ($arg eq "-d") {
785             $self->{'use_dumper'} = 1;
786             require Data::Dumper;
787         } elsif ($arg =~ /^-f(.*)/) {
788             $self->{'files'}{$1} = 1;
789         } elsif ($arg eq "-l") {
790             $self->{'linenums'} = 1;
791         } elsif ($arg eq "-p") {
792             $self->{'parens'} = 1;
793         } elsif ($arg eq "-P") {
794             $self->{'noproto'} = 1;
795         } elsif ($arg eq "-q") {
796             $self->{'unquote'} = 1;
797         } elsif (substr($arg, 0, 2) eq "-s") {
798             $self->style_opts(substr $arg, 2);
799         } elsif ($arg =~ /^-x(\d)$/) {
800             $self->{'expand'} = $1;
801         }
802     }
803     return $self;
804 }
805
806 {
807     # Mask out the bits that L<warnings::register> uses
808     my $WARN_MASK;
809     BEGIN {
810         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
811     }
812     sub WARN_MASK () {
813         return $WARN_MASK;
814     }
815 }
816
817 # Initialise the contextual information, either from
818 # defaults provided with the ambient_pragmas method,
819 # or from perl's own defaults otherwise.
820 sub init {
821     my $self = shift;
822
823     $self->{'arybase'}  = $self->{'ambient_arybase'};
824     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
825                                 ? $self->{'ambient_warnings'} & WARN_MASK
826                                 : undef;
827     $self->{'hints'}    = $self->{'ambient_hints'};
828     $self->{'hinthash'} = $self->{'ambient_hinthash'};
829
830     # also a convenient place to clear out subs_declared
831     delete $self->{'subs_declared'};
832 }
833
834 sub compile {
835     my(@args) = @_;
836     return sub {
837         my $self = B::Deparse->new(@args);
838         # First deparse command-line args
839         if (defined $^I) { # deparse -i
840             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
841         }
842         if ($^W) { # deparse -w
843             print qq(BEGIN { \$^W = $^W; }\n);
844         }
845         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
846             my $fs = perlstring($/) || 'undef';
847             my $bs = perlstring($O::savebackslash) || 'undef';
848             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
849         }
850         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
851         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
852             ? B::unitcheck_av->ARRAY
853             : ();
854         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
855         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
856         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
857         my @names = qw(BEGIN UNITCHECK CHECK INIT END);
858         my @blocks = \(@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs);
859         while (@names) {
860             my ($name, $blocks) = (shift @names, shift @blocks);
861             for my $block (@$blocks) {
862                 $self->todo($block, 0, $name);
863             }
864         }
865         $self->stash_subs();
866         local($SIG{"__DIE__"}) =
867           sub {
868               if ($self->{'curcop'}) {
869                   my $cop = $self->{'curcop'};
870                   my($line, $file) = ($cop->line, $cop->file);
871                   print STDERR "While deparsing $file near line $line,\n";
872               }
873             };
874         $self->{'curcv'} = main_cv;
875         $self->{'curcvlex'} = undef;
876         print $self->print_protos;
877         @{$self->{'subs_todo'}} =
878           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
879         my $root = main_root;
880         local $B::overlay = {};
881         unless (null $root) {
882             $self->pad_subs($self->{'curcv'});
883             # Check for a stub-followed-by-ex-cop, resulting from a program
884             # consisting solely of sub declarations.  For backward-compati-
885             # bility (and sane output) we don’t want to emit the stub.
886             #   leave
887             #     enter
888             #     stub
889             #     ex-nextstate (or ex-dbstate)
890             my $kid;
891             if ( $root->name eq 'leave'
892              and ($kid = $root->first)->name eq 'enter'
893              and !null($kid = $kid->sibling) and $kid->name eq 'stub'
894              and !null($kid = $kid->sibling) and $kid->name eq 'null'
895              and class($kid) eq 'COP' and null $kid->sibling )
896             {
897                 # ignore
898             } else {
899                 $self->pessimise($root, main_start);
900                 print $self->indent($self->deparse_root($root)), "\n";
901             }
902         }
903         my @text;
904         while (scalar(@{$self->{'subs_todo'}})) {
905             push @text, $self->next_todo;
906         }
907         print $self->indent(join("", @text)), "\n" if @text;
908
909         # Print __DATA__ section, if necessary
910         no strict 'refs';
911         my $laststash = defined $self->{'curcop'}
912             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
913         if (defined *{$laststash."::DATA"}{IO}) {
914             print $self->keyword("package") . " $laststash;\n"
915                 unless $laststash eq $self->{'curstash'};
916             print $self->keyword("__DATA__") . "\n";
917             print readline(*{$laststash."::DATA"});
918         }
919     }
920 }
921
922 sub coderef2text {
923     my $self = shift;
924     my $sub = shift;
925     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
926
927     $self->init();
928     local $self->{in_coderef2text} = 1;
929     return $self->indent($self->deparse_sub(svref_2object($sub)));
930 }
931
932 my %strict_bits = do {
933     local $^H;
934     map +($_ => strict::bits($_)), qw/refs subs vars/
935 };
936
937 sub ambient_pragmas {
938     my $self = shift;
939     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
940
941     while (@_ > 1) {
942         my $name = shift();
943         my $val  = shift();
944
945         if ($name eq 'strict') {
946             require strict;
947
948             if ($val eq 'none') {
949                 $hint_bits &= $strict_bits{$_} for qw/refs subs vars/;
950                 next();
951             }
952
953             my @names;
954             if ($val eq "all") {
955                 @names = qw/refs subs vars/;
956             }
957             elsif (ref $val) {
958                 @names = @$val;
959             }
960             else {
961                 @names = split' ', $val;
962             }
963             $hint_bits |= $strict_bits{$_} for @names;
964         }
965
966         elsif ($name eq '$[') {
967             if (OPpCONST_ARYBASE) {
968                 $arybase = $val;
969             } else {
970                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
971             }
972         }
973
974         elsif ($name eq 'integer'
975             || $name eq 'bytes'
976             || $name eq 'utf8') {
977             require "$name.pm";
978             if ($val) {
979                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
980             }
981             else {
982                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
983             }
984         }
985
986         elsif ($name eq 're') {
987             require re;
988             if ($val eq 'none') {
989                 $hint_bits &= ~re::bits(qw/taint eval/);
990                 next();
991             }
992
993             my @names;
994             if ($val eq 'all') {
995                 @names = qw/taint eval/;
996             }
997             elsif (ref $val) {
998                 @names = @$val;
999             }
1000             else {
1001                 @names = split' ',$val;
1002             }
1003             $hint_bits |= re::bits(@names);
1004         }
1005
1006         elsif ($name eq 'warnings') {
1007             if ($val eq 'none') {
1008                 $warning_bits = $warnings::NONE;
1009                 next();
1010             }
1011
1012             my @names;
1013             if (ref $val) {
1014                 @names = @$val;
1015             }
1016             else {
1017                 @names = split/\s+/, $val;
1018             }
1019
1020             $warning_bits = $warnings::NONE if !defined ($warning_bits);
1021             $warning_bits |= warnings::bits(@names);
1022         }
1023
1024         elsif ($name eq 'warning_bits') {
1025             $warning_bits = $val;
1026         }
1027
1028         elsif ($name eq 'hint_bits') {
1029             $hint_bits = $val;
1030         }
1031
1032         elsif ($name eq '%^H') {
1033             $hinthash = $val;
1034         }
1035
1036         else {
1037             croak "Unknown pragma type: $name";
1038         }
1039     }
1040     if (@_) {
1041         croak "The ambient_pragmas method expects an even number of args";
1042     }
1043
1044     $self->{'ambient_arybase'} = $arybase;
1045     $self->{'ambient_warnings'} = $warning_bits;
1046     $self->{'ambient_hints'} = $hint_bits;
1047     $self->{'ambient_hinthash'} = $hinthash;
1048 }
1049
1050 # This method is the inner loop, so try to keep it simple
1051 sub deparse {
1052     my $self = shift;
1053     my($op, $cx) = @_;
1054
1055     Carp::confess("Null op in deparse") if !defined($op)
1056                                         || class($op) eq "NULL";
1057     my $meth = "pp_" . $op->name;
1058     return $self->$meth($op, $cx);
1059 }
1060
1061 sub indent {
1062     my $self = shift;
1063     my $txt = shift;
1064     # \cK also swallows a preceding line break when followed by a
1065     # semicolon.
1066     $txt =~ s/\n\cK;//g;
1067     my @lines = split(/\n/, $txt);
1068     my $leader = "";
1069     my $level = 0;
1070     my $line;
1071     for $line (@lines) {
1072         my $cmd = substr($line, 0, 1);
1073         if ($cmd eq "\t" or $cmd eq "\b") {
1074             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
1075             if ($self->{'use_tabs'}) {
1076                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
1077             } else {
1078                 $leader = " " x $level;
1079             }
1080             $line = substr($line, 1);
1081         }
1082         if (index($line, "\f") > 0) {
1083                 $line =~ s/\f/\n/;
1084         }
1085         if (substr($line, 0, 1) eq "\f") {
1086             $line = substr($line, 1); # no indent
1087         } else {
1088             $line = $leader . $line;
1089         }
1090         $line =~ s/\cK;?//g;
1091     }
1092     return join("\n", @lines);
1093 }
1094
1095 sub pad_subs {
1096     my ($self, $cv) = @_;
1097     my $padlist = $cv->PADLIST;
1098     my @names = $padlist->ARRAYelt(0)->ARRAY;
1099     my @values = $padlist->ARRAYelt(1)->ARRAY;
1100     my @todo;
1101   PADENTRY:
1102     for my $ix (0.. $#names) { for $_ ($names[$ix]) {
1103         next if class($_) eq "SPECIAL";
1104         my $name = $_->PVX;
1105         if (defined $name && $name =~ /^&./) {
1106             my $low = $_->COP_SEQ_RANGE_LOW;
1107             my $flags = $_->FLAGS;
1108             my $outer = $flags & PADNAMEt_OUTER;
1109             if ($flags & SVpad_OUR) {
1110                 push @todo, [$low, undef, 0, $_]
1111                           # [seq, no cv, not format, padname]
1112                     unless $outer;
1113                 next;
1114             }
1115             my $protocv = $flags & SVpad_STATE
1116                 ? $values[$ix]
1117                 : $_->PROTOCV;
1118             if (class ($protocv) ne 'CV') {
1119                 my $flags = $flags;
1120                 my $cv = $cv;
1121                 my $name = $_;
1122                 while ($flags & PADNAMEt_OUTER && class ($protocv) ne 'CV')
1123                 {
1124                     $cv = $cv->OUTSIDE;
1125                     next PADENTRY if class($cv) eq 'SPECIAL'; # XXX freed?
1126                     my $padlist = $cv->PADLIST;
1127                     my $ix = $name->PARENT_PAD_INDEX;
1128                     $name = $padlist->NAMES->ARRAYelt($ix);
1129                     $flags = $name->FLAGS;
1130                     $protocv = $flags & SVpad_STATE
1131                         ? $padlist->ARRAYelt(1)->ARRAYelt($ix)
1132                         : $name->PROTOCV;
1133                 }
1134             }
1135             my $defined_in_this_sub = ${$protocv->OUTSIDE} == $$cv || do {
1136                 my $other = $protocv->PADLIST;
1137                 $$other && $other->outid == $padlist->id;
1138             };
1139             if ($flags & PADNAMEt_OUTER) {
1140                 next unless $defined_in_this_sub;
1141                 push @todo, [$protocv->OUTSIDE_SEQ, $protocv, 0, $_];
1142                 next;
1143             }
1144             my $outseq = $protocv->OUTSIDE_SEQ;
1145             if ($outseq <= $low) {
1146                 # defined before its name is visible, so it’s gotta be
1147                 # declared and defined at once: my sub foo { ... }
1148                 push @todo, [$low, $protocv, 0, $_];
1149             }
1150             else {
1151                 # declared and defined separately: my sub f; sub f { ... }
1152                 push @todo, [$low, undef, 0, $_];
1153                 push @todo, [$outseq, $protocv, 0, $_]
1154                     if $defined_in_this_sub;
1155             }
1156         }
1157     }}
1158     @{$self->{'subs_todo'}} =
1159         sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}}, @todo
1160 }
1161
1162
1163 # deparse_argops(): deparse, if possible, a sequence of argcheck + argelem
1164 # ops into a subroutine signature. If successful, return the first op
1165 # following the signature ops plus the signature string; else return the
1166 # empty list.
1167 #
1168 # Normally a bunch of argelem ops will have been generated by the
1169 # signature parsing, but it's possible that ops have been added manually
1170 # or altered. In this case we "return ()" and fall back to general
1171 # deparsing of the individual sigelems as 'my $x = $_[N]' etc.
1172 #
1173 # We're only called if the first two ops are nextstate and argcheck.
1174
1175 sub deparse_argops {
1176     my ($self, $firstop, $cv) = @_;
1177
1178     my @sig;
1179     my $o = $firstop;
1180     return if $o->label; #first nextstate;
1181
1182     # OP_ARGCHECK
1183
1184     $o = $o->sibling;
1185     my ($params, $opt_params, $slurpy) = $o->aux_list($cv);
1186     my $mandatory = $params - $opt_params;
1187     my $seen_slurpy = 0;
1188     my $last_ix = -1;
1189
1190     # keep looking for valid nextstate + argelem pairs
1191
1192     while (1) {
1193         # OP_NEXTSTATE
1194         $o = $o->sibling;
1195         last unless $$o;
1196         last unless $o->name =~ /^(next|db)state$/;
1197         last if $o->label;
1198
1199         # OP_ARGELEM
1200         my $o2 = $o->sibling;
1201         last unless $$o2;
1202
1203         if ($o2->name eq 'argelem') {
1204             my $ix  = $o2->string($cv);
1205             while (++$last_ix < $ix) {
1206                 push @sig, $last_ix <  $mandatory ? '$' : '$=';
1207             }
1208             my $var = $self->padname($o2->targ);
1209             if ($var =~ /^[@%]/) {
1210                 return if $seen_slurpy;
1211                 $seen_slurpy = 1;
1212                 return if $ix != $params or !$slurpy
1213                             or substr($var,0,1) ne $slurpy;
1214             }
1215             else {
1216                 return if $ix >= $params;
1217             }
1218             if ($o2->flags & OPf_KIDS) {
1219                 my $kid = $o2->first;
1220                 return unless $$kid and $kid->name eq 'argdefelem';
1221                 my $def = $self->deparse($kid->first, 7);
1222                 $def = "($def)" if $kid->first->flags & OPf_PARENS;
1223                 $var .= " = $def";
1224             }
1225             push @sig, $var;
1226         }
1227         elsif ($o2->name eq 'null'
1228                and ($o2->flags & OPf_KIDS)
1229                and $o2->first->name eq 'argdefelem')
1230         {
1231             # special case - a void context default expression: $ = expr
1232
1233             my $defop = $o2->first;
1234             my $ix = $defop->targ;
1235             while (++$last_ix < $ix) {
1236                 push @sig, $last_ix <  $mandatory ? '$' : '$=';
1237             }
1238             return if $last_ix >= $params
1239                     or $last_ix < $mandatory;
1240             my $def = $self->deparse($defop->first, 7);
1241             $def = "($def)" if $defop->first->flags & OPf_PARENS;
1242             push @sig, '$ = ' . $def;
1243         }
1244         else {
1245             last;
1246         }
1247
1248         $o = $o2;
1249     }
1250
1251     while (++$last_ix < $params) {
1252         push @sig, $last_ix <  $mandatory ? '$' : '$=';
1253     }
1254     push @sig, $slurpy if $slurpy and !$seen_slurpy;
1255
1256     return ($o, join(', ', @sig));
1257 }
1258
1259 # Deparse a sub. Returns everything except the 'sub foo',
1260 # e.g.  ($$) : method { ...; }
1261 # or    ($a, $b) : prototype($$) lvalue;
1262
1263 sub deparse_sub {
1264     my $self = shift;
1265     my $cv = shift;
1266     my @attrs;
1267     my $protosig; # prototype or signature (what goes in the (....))
1268
1269 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
1270 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
1271     local $self->{'curcop'} = $self->{'curcop'};
1272
1273     my $has_sig = $self->{hinthash}{feature_signatures};
1274     if ($cv->FLAGS & SVf_POK) {
1275         my $proto = $cv->PV;
1276         if ($has_sig) {
1277             push @attrs, "prototype($proto)";
1278         }
1279         else {
1280             $protosig = $proto;
1281         }
1282     }
1283     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE|CVf_ANONCONST)) {
1284         push @attrs, "lvalue" if $cv->CvFLAGS & CVf_LVALUE;
1285         push @attrs, "method" if $cv->CvFLAGS & CVf_METHOD;
1286         push @attrs, "const"  if $cv->CvFLAGS & CVf_ANONCONST;
1287     }
1288
1289     local($self->{'curcv'}) = $cv;
1290     local($self->{'curcvlex'});
1291     local(@$self{qw'curstash warnings hints hinthash'})
1292                 = @$self{qw'curstash warnings hints hinthash'};
1293     my $body;
1294     my $root = $cv->ROOT;
1295     local $B::overlay = {};
1296     if (not null $root) {
1297         $self->pad_subs($cv);
1298         $self->pessimise($root, $cv->START);
1299         my $lineseq = $root->first;
1300         if ($lineseq->name eq "lineseq") {
1301             my $firstop = $lineseq->first;
1302
1303             if ($has_sig) {
1304                 my $o2;
1305                 # try to deparse first few ops as a signature if possible
1306                 if (     $$firstop
1307                      and $firstop->name =~  /^(next|db)state$/
1308                      and (($o2 = $firstop->sibling))
1309                      and $$o2)
1310                 {
1311                     if ($o2->name eq 'argcheck') {
1312                         my ($nexto, $sig) = $self->deparse_argops($firstop, $cv);
1313                         if (defined $nexto) {
1314                             $firstop = $nexto;
1315                             $protosig = $sig;
1316                         }
1317                     }
1318                 }
1319             }
1320
1321             my @ops;
1322             for (my $o = $firstop; $$o; $o=$o->sibling) {
1323                 push @ops, $o;
1324             }
1325             $body = $self->lineseq(undef, 0, @ops).";";
1326             if (!$has_sig and $ops[-1]->name =~ /^(next|db)state$/) {
1327                 # this handles void context in
1328                 #   use feature signatures; sub ($=1) {}
1329                 $body .= "\n()";
1330             }
1331             my $scope_en = $self->find_scope_en($lineseq);
1332             if (defined $scope_en) {
1333                 my $subs = join"", $self->seq_subs($scope_en);
1334                 $body .= ";\n$subs" if length($subs);
1335             }
1336         }
1337         else {
1338             $body = $self->deparse($root->first, 0);
1339         }
1340         $body = "{\n\t$body\n\b}";
1341     }
1342     else {
1343         my $sv = $cv->const_sv;
1344         if ($$sv) {
1345             # uh-oh. inlinable sub... format it differently
1346             $body = "{ " . $self->const($sv, 0) . " }\n";
1347         } else { # XSUB? (or just a declaration)
1348             $body = ';'
1349         }
1350     }
1351     $protosig = defined $protosig ? "($protosig) " : "";
1352     my $attrs = '';
1353     $attrs = ': ' . join('', map "$_ ", @attrs) if @attrs;
1354     return "$protosig$attrs$body\n";
1355 }
1356
1357 sub deparse_format {
1358     my $self = shift;
1359     my $form = shift;
1360     my @text;
1361     local($self->{'curcv'}) = $form;
1362     local($self->{'curcvlex'});
1363     local($self->{'in_format'}) = 1;
1364     local(@$self{qw'curstash warnings hints hinthash'})
1365                 = @$self{qw'curstash warnings hints hinthash'};
1366     my $op = $form->ROOT;
1367     local $B::overlay = {};
1368     $self->pessimise($op, $form->START);
1369     my $kid;
1370     return "\f." if $op->first->name eq 'stub'
1371                 || $op->first->name eq 'nextstate';
1372     $op = $op->first->first; # skip leavewrite, lineseq
1373     while (not null $op) {
1374         $op = $op->sibling; # skip nextstate
1375         my @exprs;
1376         $kid = $op->first->sibling; # skip pushmark
1377         push @text, "\f".$self->const_sv($kid)->PV;
1378         $kid = $kid->sibling;
1379         for (; not null $kid; $kid = $kid->sibling) {
1380             push @exprs, $self->deparse($kid, -1);
1381             $exprs[-1] =~ s/;\z//;
1382         }
1383         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
1384         $op = $op->sibling;
1385     }
1386     return join("", @text) . "\f.";
1387 }
1388
1389 sub is_scope {
1390     my $op = shift;
1391     return $op->name eq "leave" || $op->name eq "scope"
1392       || $op->name eq "lineseq"
1393         || ($op->name eq "null" && class($op) eq "UNOP"
1394             && (is_scope($op->first) || $op->first->name eq "enter"));
1395 }
1396
1397 sub is_state {
1398     my $name = $_[0]->name;
1399     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
1400 }
1401
1402 sub is_miniwhile { # check for one-line loop ('foo() while $y--')
1403     my $op = shift;
1404     return (!null($op) and null($op->sibling)
1405             and $op->name eq "null" and class($op) eq "UNOP"
1406             and (($op->first->name =~ /^(and|or)$/
1407                   and $op->first->first->sibling->name eq "lineseq")
1408                  or ($op->first->name eq "lineseq"
1409                      and not null $op->first->first->sibling
1410                      and $op->first->first->sibling->name eq "unstack")
1411                  ));
1412 }
1413
1414 # Check if the op and its sibling are the initialization and the rest of a
1415 # for (..;..;..) { ... } loop
1416 sub is_for_loop {
1417     my $op = shift;
1418     # This OP might be almost anything, though it won't be a
1419     # nextstate. (It's the initialization, so in the canonical case it
1420     # will be an sassign.) The sibling is (old style) a lineseq whose
1421     # first child is a nextstate and whose second is a leaveloop, or
1422     # (new style) an unstack whose sibling is a leaveloop.
1423     my $lseq = $op->sibling;
1424     return 0 unless !is_state($op) and !null($lseq);
1425     if ($lseq->name eq "lineseq") {
1426         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
1427             && (my $sib = $lseq->first->sibling)) {
1428             return (!null($sib) && $sib->name eq "leaveloop");
1429         }
1430     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
1431         my $sib = $lseq->sibling;
1432         return $sib && !null($sib) && $sib->name eq "leaveloop";
1433     }
1434     return 0;
1435 }
1436
1437 sub is_scalar {
1438     my $op = shift;
1439     return ($op->name eq "rv2sv" or
1440             $op->name eq "padsv" or
1441             $op->name eq "gv" or # only in array/hash constructs
1442             $op->flags & OPf_KIDS && !null($op->first)
1443               && $op->first->name eq "gvsv");
1444 }
1445
1446 sub maybe_parens {
1447     my $self = shift;
1448     my($text, $cx, $prec) = @_;
1449     if ($prec < $cx              # unary ops nest just fine
1450         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1451         or $self->{'parens'})
1452     {
1453         $text = "($text)";
1454         # In a unop, let parent reuse our parens; see maybe_parens_unop
1455         $text = "\cS" . $text if $cx == 16;
1456         return $text;
1457     } else {
1458         return $text;
1459     }
1460 }
1461
1462 # same as above, but get around the 'if it looks like a function' rule
1463 sub maybe_parens_unop {
1464     my $self = shift;
1465     my($name, $kid, $cx) = @_;
1466     if ($cx > 16 or $self->{'parens'}) {
1467         $kid =  $self->deparse($kid, 1);
1468         if ($name eq "umask" && $kid =~ /^\d+$/) {
1469             $kid = sprintf("%#o", $kid);
1470         }
1471         return $self->keyword($name) . "($kid)";
1472     } else {
1473         $kid = $self->deparse($kid, 16);
1474         if ($name eq "umask" && $kid =~ /^\d+$/) {
1475             $kid = sprintf("%#o", $kid);
1476         }
1477         $name = $self->keyword($name);
1478         if (substr($kid, 0, 1) eq "\cS") {
1479             # use kid's parens
1480             return $name . substr($kid, 1);
1481         } elsif (substr($kid, 0, 1) eq "(") {
1482             # avoid looks-like-a-function trap with extra parens
1483             # ('+' can lead to ambiguities)
1484             return "$name(" . $kid  . ")";
1485         } else {
1486             return "$name $kid";
1487         }
1488     }
1489 }
1490
1491 sub maybe_parens_func {
1492     my $self = shift;
1493     my($func, $text, $cx, $prec) = @_;
1494     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1495         return "$func($text)";
1496     } else {
1497         return "$func $text";
1498     }
1499 }
1500
1501 sub find_our_type {
1502     my ($self, $name) = @_;
1503     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1504     my $seq = $self->{'curcop'} ? $self->{'curcop'}->cop_seq : 0;
1505     for my $a (@{$self->{'curcvlex'}{"o$name"}}) {
1506         my ($st, undef, $padname) = @$a;
1507         if ($st >= $seq && $padname->FLAGS & SVpad_TYPED) {
1508             return $padname->SvSTASH->NAME;
1509         }
1510     }
1511     return '';
1512 }
1513
1514 sub maybe_local {
1515     my $self = shift;
1516     my($op, $cx, $text) = @_;
1517     my $name = $op->name;
1518     my $our_intro = ($name =~ /^(?:(?:gv|rv2)[ash]v|split|refassign
1519                                   |lv(?:av)?ref)$/x)
1520                         ? OPpOUR_INTRO
1521                         : 0;
1522     my $lval_intro = $name eq 'split' ? 0 : OPpLVAL_INTRO;
1523     # The @a in \(@a) isn't in ref context, but only when the
1524     # parens are there.
1525     my $need_parens = $self->{'in_refgen'} && $name =~ /[ah]v\z/
1526                    && ($op->flags & (OPf_PARENS|OPf_REF)) == OPf_PARENS;
1527     if ((my $priv = $op->private) & ($lval_intro|$our_intro)) {
1528         my @our_local;
1529         push @our_local, "local" if $priv & $lval_intro;
1530         push @our_local, "our"   if $priv & $our_intro;
1531         my $our_local = join " ", map $self->keyword($_), @our_local;
1532         if( $our_local[-1] eq 'our' ) {
1533             if ( $text !~ /^\W(\w+::)*\w+\z/
1534              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1535             ) {
1536                 die "Unexpected our($text)\n";
1537             }
1538             $text =~ s/(\w+::)+//;
1539
1540             if (my $type = $self->find_our_type($text)) {
1541                 $our_local .= ' ' . $type;
1542             }
1543         }
1544         return $need_parens ? "($text)" : $text
1545             if $self->{'avoid_local'}{$$op};
1546         if ($need_parens) {
1547             return "$our_local($text)";
1548         } elsif (want_scalar($op)) {
1549             return "$our_local $text";
1550         } else {
1551             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1552         }
1553     } else {
1554         return $need_parens ? "($text)" : $text;
1555     }
1556 }
1557
1558 sub maybe_targmy {
1559     my $self = shift;
1560     my($op, $cx, $func, @args) = @_;
1561     if ($op->private & OPpTARGET_MY) {
1562         my $var = $self->padname($op->targ);
1563         my $val = $func->($self, $op, 7, @args);
1564         return $self->maybe_parens("$var = $val", $cx, 7);
1565     } else {
1566         return $func->($self, $op, $cx, @args);
1567     }
1568 }
1569
1570 sub padname_sv {
1571     my $self = shift;
1572     my $targ = shift;
1573     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1574 }
1575
1576 sub maybe_my {
1577     my $self = shift;
1578     my($op, $cx, $text, $padname, $forbid_parens) = @_;
1579     # The @a in \(@a) isn't in ref context, but only when the
1580     # parens are there.
1581     my $need_parens = !$forbid_parens && $self->{'in_refgen'}
1582                    && $op->name =~ /[ah]v\z/
1583                    && ($op->flags & (OPf_PARENS|OPf_REF)) == OPf_PARENS;
1584     # The @a in \my @a must not have parens.
1585     if (!$need_parens && $self->{'in_refgen'}) {
1586         $forbid_parens = 1;
1587     }
1588     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1589         # Check $padname->FLAGS for statehood, rather than $op->private,
1590         # because enteriter ops do not carry the flag.
1591         my $my =
1592             $self->keyword($padname->FLAGS & SVpad_STATE ? "state" : "my");
1593         if ($padname->FLAGS & SVpad_TYPED) {
1594             $my .= ' ' . $padname->SvSTASH->NAME;
1595         }
1596         if ($need_parens) {
1597             return "$my($text)";
1598         } elsif ($forbid_parens || want_scalar($op)) {
1599             return "$my $text";
1600         } else {
1601             return $self->maybe_parens_func($my, $text, $cx, 16);
1602         }
1603     } else {
1604         return $need_parens ? "($text)" : $text;
1605     }
1606 }
1607
1608 # The following OPs don't have functions:
1609
1610 # pp_padany -- does not exist after parsing
1611
1612 sub AUTOLOAD {
1613     if ($AUTOLOAD =~ s/^.*::pp_//) {
1614         warn "unexpected OP_".
1615           ($_[1]->type == OP_CUSTOM ? "CUSTOM ($AUTOLOAD)" : uc $AUTOLOAD);
1616         return "XXX";
1617     } else {
1618         die "Undefined subroutine $AUTOLOAD called";
1619     }
1620 }
1621
1622 sub DESTROY {}  #       Do not AUTOLOAD
1623
1624 # $root should be the op which represents the root of whatever
1625 # we're sequencing here. If it's undefined, then we don't append
1626 # any subroutine declarations to the deparsed ops, otherwise we
1627 # append appropriate declarations.
1628 sub lineseq {
1629     my($self, $root, $cx, @ops) = @_;
1630     my($expr, @exprs);
1631
1632     my $out_cop = $self->{'curcop'};
1633     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1634     my $limit_seq;
1635     if (defined $root) {
1636         $limit_seq = $out_seq;
1637         my $nseq;
1638         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1639         $limit_seq = $nseq if !defined($limit_seq)
1640                            or defined($nseq) && $nseq < $limit_seq;
1641     }
1642     $limit_seq = $self->{'limit_seq'}
1643         if defined($self->{'limit_seq'})
1644         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1645     local $self->{'limit_seq'} = $limit_seq;
1646
1647     $self->walk_lineseq($root, \@ops,
1648                        sub { push @exprs, $_[0]} );
1649
1650     my $sep = $cx ? '; ' : ";\n";
1651     my $body = join($sep, grep {length} @exprs);
1652     my $subs = "";
1653     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1654         $subs = join "\n", $self->seq_subs($limit_seq);
1655     }
1656     return join($sep, grep {length} $body, $subs);
1657 }
1658
1659 sub scopeop {
1660     my($real_block, $self, $op, $cx) = @_;
1661     my $kid;
1662     my @kids;
1663
1664     local(@$self{qw'curstash warnings hints hinthash'})
1665                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1666     if ($real_block) {
1667         $kid = $op->first->sibling; # skip enter
1668         if (is_miniwhile($kid)) {
1669             my $top = $kid->first;
1670             my $name = $top->name;
1671             if ($name eq "and") {
1672                 $name = $self->keyword("while");
1673             } elsif ($name eq "or") {
1674                 $name = $self->keyword("until");
1675             } else { # no conditional -> while 1 or until 0
1676                 return $self->deparse($top->first, 1) . " "
1677                      . $self->keyword("while") . " 1";
1678             }
1679             my $cond = $top->first;
1680             my $body = $cond->sibling->first; # skip lineseq
1681             $cond = $self->deparse($cond, 1);
1682             $body = $self->deparse($body, 1);
1683             return "$body $name $cond";
1684         }
1685     } else {
1686         $kid = $op->first;
1687     }
1688     for (; !null($kid); $kid = $kid->sibling) {
1689         push @kids, $kid;
1690     }
1691     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1692         my $body = $self->lineseq($op, 0, @kids);
1693         return is_lexical_subs(@kids)
1694                 ? $body
1695                 : ($self->lex_in_scope("&do") ? "CORE::do" : "do")
1696                  . " {\n\t$body\n\b}";
1697     } else {
1698         my $lineseq = $self->lineseq($op, $cx, @kids);
1699         return (length ($lineseq) ? "$lineseq;" : "");
1700     }
1701 }
1702
1703 sub pp_scope { scopeop(0, @_); }
1704 sub pp_lineseq { scopeop(0, @_); }
1705 sub pp_leave { scopeop(1, @_); }
1706
1707 # This is a special case of scopeop and lineseq, for the case of the
1708 # main_root. The difference is that we print the output statements as
1709 # soon as we get them, for the sake of impatient users.
1710 sub deparse_root {
1711     my $self = shift;
1712     my($op) = @_;
1713     local(@$self{qw'curstash warnings hints hinthash'})
1714       = @$self{qw'curstash warnings hints hinthash'};
1715     my @kids;
1716     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1717     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1718         push @kids, $kid;
1719     }
1720     $self->walk_lineseq($op, \@kids,
1721                         sub { return unless length $_[0];
1722                               print $self->indent($_[0].';');
1723                               print "\n"
1724                                 unless $_[1] == $#kids;
1725                           });
1726 }
1727
1728 sub walk_lineseq {
1729     my ($self, $op, $kids, $callback) = @_;
1730     my @kids = @$kids;
1731     for (my $i = 0; $i < @kids; $i++) {
1732         my $expr = "";
1733         if (is_state $kids[$i]) {
1734             $expr = $self->deparse($kids[$i++], 0);
1735             if ($i > $#kids) {
1736                 $callback->($expr, $i);
1737                 last;
1738             }
1739         }
1740         if (is_for_loop($kids[$i])) {
1741             $callback->($expr . $self->for_loop($kids[$i], 0),
1742                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1743             next;
1744         }
1745         my $expr2 = $self->deparse($kids[$i], (@kids != 1)/2);
1746         $expr2 =~ s/^sub :(?!:)/+sub :/; # statement label otherwise
1747         $expr .= $expr2;
1748         $callback->($expr, $i);
1749     }
1750 }
1751
1752 # The BEGIN {} is used here because otherwise this code isn't executed
1753 # when you run B::Deparse on itself.
1754 my %globalnames;
1755 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1756             "ENV", "ARGV", "ARGVOUT", "_"); }
1757
1758 sub gv_name {
1759     my $self = shift;
1760     my $gv = shift;
1761     my $raw = shift;
1762 #Carp::confess() unless ref($gv) eq "B::GV";
1763     my $cv = $gv->FLAGS & SVf_ROK ? $gv->RV : 0;
1764     my $stash = ($cv || $gv)->STASH->NAME;
1765     my $name = $raw
1766         ? $cv ? $cv->NAME_HEK || $cv->GV->NAME : $gv->NAME
1767         : $cv
1768             ? B::safename($cv->NAME_HEK || $cv->GV->NAME)
1769             : $gv->SAFENAME;
1770     if ($stash eq 'main' && $name =~ /^::/) {
1771         $stash = '::';
1772     }
1773     elsif (($stash eq 'main'
1774             && ($globalnames{$name} || $name =~ /^[^A-Za-z_:]/))
1775         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1776             && ($stash eq 'main' || $name !~ /::/))
1777           )
1778     {
1779         $stash = "";
1780     } else {
1781         $stash = $stash . "::";
1782     }
1783     if (!$raw and $name =~ /^(\^..|{)/) {
1784         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1785     }
1786     return $stash . $name;
1787 }
1788
1789 # Return the name to use for a stash variable.
1790 # If a lexical with the same name is in scope, or
1791 # if strictures are enabled, it may need to be
1792 # fully-qualified.
1793 sub stash_variable {
1794     my ($self, $prefix, $name, $cx) = @_;
1795
1796     return "$prefix$name" if $name =~ /::/;
1797
1798     unless ($prefix eq '$' || $prefix eq '@' || $prefix eq '&' || #'
1799             $prefix eq '%' || $prefix eq '$#') {
1800         return "$prefix$name";
1801     }
1802
1803     if ($name =~ /^[^[:alpha:]_+-]$/) {
1804       if (defined $cx && $cx == 26) {
1805         if ($prefix eq '@') {
1806             return "$prefix\{$name}";
1807         }
1808         elsif ($name eq '#') { return '${#}' } #  "${#}a" vs "$#a"
1809       }
1810       if ($prefix eq '$#') {
1811         return "\$#{$name}";
1812       }
1813     }
1814
1815     return $prefix . $self->maybe_qualify($prefix, $name);
1816 }
1817
1818 my %unctrl = # portable to EBCDIC
1819     (
1820      "\c@" => '@',      # unused
1821      "\cA" => 'A',
1822      "\cB" => 'B',
1823      "\cC" => 'C',
1824      "\cD" => 'D',
1825      "\cE" => 'E',
1826      "\cF" => 'F',
1827      "\cG" => 'G',
1828      "\cH" => 'H',
1829      "\cI" => 'I',
1830      "\cJ" => 'J',
1831      "\cK" => 'K',
1832      "\cL" => 'L',
1833      "\cM" => 'M',
1834      "\cN" => 'N',
1835      "\cO" => 'O',
1836      "\cP" => 'P',
1837      "\cQ" => 'Q',
1838      "\cR" => 'R',
1839      "\cS" => 'S',
1840      "\cT" => 'T',
1841      "\cU" => 'U',
1842      "\cV" => 'V',
1843      "\cW" => 'W',
1844      "\cX" => 'X',
1845      "\cY" => 'Y',
1846      "\cZ" => 'Z',
1847      "\c[" => '[',      # unused
1848      "\c\\" => '\\',    # unused
1849      "\c]" => ']',      # unused
1850      "\c_" => '_',      # unused
1851     );
1852
1853 # Return just the name, without the prefix.  It may be returned as a quoted
1854 # string.  The second return value is a boolean indicating that.
1855 sub stash_variable_name {
1856     my($self, $prefix, $gv) = @_;
1857     my $name = $self->gv_name($gv, 1);
1858     $name = $self->maybe_qualify($prefix,$name);
1859     if ($name =~ /^(?:\S|(?!\d)[\ca-\cz]?(?:\w|::)*|\d+)\z/) {
1860         $name =~ s/^([\ca-\cz])/'^' . $unctrl{$1}/e;
1861         $name =~ /^(\^..|{)/ and $name = "{$name}";
1862         return $name, 0; # not quoted
1863     }
1864     else {
1865         single_delim("q", "'", $name, $self), 1;
1866     }
1867 }
1868
1869 sub maybe_qualify {
1870     my ($self,$prefix,$name) = @_;
1871     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1872     return $name if !$prefix || $name =~ /::/;
1873     return $self->{'curstash'}.'::'. $name
1874         if
1875             $name =~ /^(?!\d)\w/         # alphabetic
1876          && $v    !~ /^\$[ab]\z/         # not $a or $b
1877          && !$globalnames{$name}         # not a global name
1878          && $self->{hints} & $strict_bits{vars}  # strict vars
1879          && !$self->lex_in_scope($v,1)   # no "our"
1880       or $self->lex_in_scope($v);        # conflicts with "my" variable
1881     return $name;
1882 }
1883
1884 sub lex_in_scope {
1885     my ($self, $name, $our) = @_;
1886     substr $name, 0, 0, = $our ? 'o' : 'm'; # our/my
1887     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1888
1889     return 0 if !defined($self->{'curcop'});
1890     my $seq = $self->{'curcop'}->cop_seq;
1891     return 0 if !exists $self->{'curcvlex'}{$name};
1892     for my $a (@{$self->{'curcvlex'}{$name}}) {
1893         my ($st, $en) = @$a;
1894         return 1 if $seq > $st && $seq <= $en;
1895     }
1896     return 0;
1897 }
1898
1899 sub populate_curcvlex {
1900     my $self = shift;
1901     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1902         my $padlist = $cv->PADLIST;
1903         # an undef CV still in lexical chain
1904         next if class($padlist) eq "SPECIAL";
1905         my @padlist = $padlist->ARRAY;
1906         my @ns = $padlist[0]->ARRAY;
1907
1908         for (my $i=0; $i<@ns; ++$i) {
1909             next if class($ns[$i]) eq "SPECIAL";
1910             if (class($ns[$i]) eq "PV") {
1911                 # Probably that pesky lexical @_
1912                 next;
1913             }
1914             my $name = $ns[$i]->PVX;
1915             next unless defined $name;
1916             my ($seq_st, $seq_en) =
1917                 ($ns[$i]->FLAGS & SVf_FAKE)
1918                     ? (0, 999999)
1919                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1920
1921             push @{$self->{'curcvlex'}{
1922                         ($ns[$i]->FLAGS & SVpad_OUR ? 'o' : 'm') . $name
1923                   }}, [$seq_st, $seq_en, $ns[$i]];
1924         }
1925     }
1926 }
1927
1928 sub find_scope_st { ((find_scope(@_))[0]); }
1929 sub find_scope_en { ((find_scope(@_))[1]); }
1930
1931 # Recurses down the tree, looking for pad variable introductions and COPs
1932 sub find_scope {
1933     my ($self, $op, $scope_st, $scope_en) = @_;
1934     carp("Undefined op in find_scope") if !defined $op;
1935     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1936
1937     my @queue = ($op);
1938     while(my $op = shift @queue ) {
1939         for (my $o=$op->first; $$o; $o=$o->sibling) {
1940             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1941                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1942                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1943                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1944                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1945                 return ($scope_st, $scope_en);
1946             }
1947             elsif (is_state($o)) {
1948                 my $c = $o->cop_seq;
1949                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1950                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1951                 return ($scope_st, $scope_en);
1952             }
1953             elsif ($o->flags & OPf_KIDS) {
1954                 unshift (@queue, $o);
1955             }
1956         }
1957     }
1958
1959     return ($scope_st, $scope_en);
1960 }
1961
1962 # Returns a list of subs which should be inserted before the COP
1963 sub cop_subs {
1964     my ($self, $op, $out_seq) = @_;
1965     my $seq = $op->cop_seq;
1966     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1967     return $self->seq_subs($seq);
1968 }
1969
1970 sub seq_subs {
1971     my ($self, $seq) = @_;
1972     my @text;
1973 #push @text, "# ($seq)\n";
1974
1975     return "" if !defined $seq;
1976     my @pending;
1977     while (scalar(@{$self->{'subs_todo'}})
1978            and $seq > $self->{'subs_todo'}[0][0]) {
1979         my $cv = $self->{'subs_todo'}[0][1];
1980         # Skip the OUTSIDE check for lexical subs.  We may be deparsing a
1981         # cloned anon sub with lexical subs declared in it, in which case
1982         # the OUTSIDE pointer points to the anon protosub.
1983         my $lexical = ref $self->{'subs_todo'}[0][3];
1984         my $outside = !$lexical && $cv && $cv->OUTSIDE;
1985         if (!$lexical and $cv
1986          and ${$cv->OUTSIDE || \0} != ${$self->{'curcv'}})
1987         {
1988             push @pending, shift @{$self->{'subs_todo'}};
1989             next;
1990         }
1991         push @text, $self->next_todo;
1992     }
1993     unshift @{$self->{'subs_todo'}}, @pending;
1994     return @text;
1995 }
1996
1997 sub _features_from_bundle {
1998     my ($hints, $hh) = @_;
1999     foreach (@{$feature::feature_bundle{@feature::hint_bundles[$hints >> $feature::hint_shift]}}) {
2000         $hh->{$feature::feature{$_}} = 1;
2001     }
2002     return $hh;
2003 }
2004
2005 # generate any pragmas, 'package foo' etc needed to synchronise
2006 # with the given cop
2007
2008 sub pragmata {
2009     my $self = shift;
2010     my($op) = @_;
2011
2012     my @text;
2013
2014     my $stash = $op->stashpv;
2015     if ($stash ne $self->{'curstash'}) {
2016         push @text, $self->keyword("package") . " $stash;\n";
2017         $self->{'curstash'} = $stash;
2018     }
2019
2020     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
2021         push @text, '$[ = '. $op->arybase .";\n";
2022         $self->{'arybase'} = $op->arybase;
2023     }
2024
2025     my $warnings = $op->warnings;
2026     my $warning_bits;
2027     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
2028         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
2029     }
2030     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
2031         $warning_bits = $warnings::NONE;
2032     }
2033     elsif ($warnings->isa("B::SPECIAL")) {
2034         $warning_bits = undef;
2035     }
2036     else {
2037         $warning_bits = $warnings->PV & WARN_MASK;
2038     }
2039
2040     if (defined ($warning_bits) and
2041        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
2042         push @text,
2043             $self->declare_warnings($self->{'warnings'}, $warning_bits);
2044         $self->{'warnings'} = $warning_bits;
2045     }
2046
2047     my $hints = $op->hints;
2048     my $old_hints = $self->{'hints'};
2049     if ($self->{'hints'} != $hints) {
2050         push @text, $self->declare_hints($self->{'hints'}, $hints);
2051         $self->{'hints'} = $hints;
2052     }
2053
2054     my $newhh;
2055     $newhh = $op->hints_hash->HASH;
2056
2057     {
2058         # feature bundle hints
2059         my $from = $old_hints & $feature::hint_mask;
2060         my $to   = $    hints & $feature::hint_mask;
2061         if ($from != $to) {
2062             if ($to == $feature::hint_mask) {
2063                 if ($self->{'hinthash'}) {
2064                     delete $self->{'hinthash'}{$_}
2065                         for grep /^feature_/, keys %{$self->{'hinthash'}};
2066                 }
2067                 else { $self->{'hinthash'} = {} }
2068                 $self->{'hinthash'}
2069                     = _features_from_bundle($from, $self->{'hinthash'});
2070             }
2071             else {
2072                 my $bundle =
2073                     $feature::hint_bundles[$to >> $feature::hint_shift];
2074                 $bundle =~ s/(\d[13579])\z/$1+1/e; # 5.11 => 5.12
2075                 push @text,
2076                     $self->keyword("no") . " feature ':all';\n",
2077                     $self->keyword("use") . " feature ':$bundle';\n";
2078             }
2079         }
2080     }
2081
2082     {
2083         push @text, $self->declare_hinthash(
2084             $self->{'hinthash'}, $newhh,
2085             $self->{indent_size}, $self->{hints},
2086         );
2087         $self->{'hinthash'} = $newhh;
2088     }
2089
2090     return join("", @text);
2091 }
2092
2093
2094 # Notice how subs and formats are inserted between statements here;
2095 # also $[ assignments and pragmas.
2096 sub pp_nextstate {
2097     my $self = shift;
2098     my($op, $cx) = @_;
2099     $self->{'curcop'} = $op;
2100
2101     my @text;
2102
2103     my @subs = $self->cop_subs($op);
2104     if (@subs) {
2105         # Special marker to swallow up the semicolon
2106         push @subs, "\cK";
2107     }
2108     push @text, @subs;
2109
2110     push @text, $self->pragmata($op);
2111
2112
2113     # This should go after of any branches that add statements, to
2114     # increase the chances that it refers to the same line it did in
2115     # the original program.
2116     if ($self->{'linenums'} && $cx != .5) { # $cx == .5 means in a format
2117         push @text, "\f#line " . $op->line .
2118           ' "' . $op->file, qq'"\n';
2119     }
2120
2121     push @text, $op->label . ": " if $op->label;
2122
2123     return join("", @text);
2124 }
2125
2126 sub declare_warnings {
2127     my ($self, $from, $to) = @_;
2128     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
2129         return $self->keyword("use") . " warnings;\n";
2130     }
2131     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
2132         return $self->keyword("no") . " warnings;\n";
2133     }
2134     return "BEGIN {\${^WARNING_BITS} = \""
2135            . join("", map { sprintf("\\x%02x", ord $_) } split "", $to)
2136            . "\"}\n\cK";
2137 }
2138
2139 sub declare_hints {
2140     my ($self, $from, $to) = @_;
2141     my $use = $to   & ~$from;
2142     my $no  = $from & ~$to;
2143     my $decls = "";
2144     for my $pragma (hint_pragmas($use)) {
2145         $decls .= $self->keyword("use") . " $pragma;\n";
2146     }
2147     for my $pragma (hint_pragmas($no)) {
2148         $decls .= $self->keyword("no") . " $pragma;\n";
2149     }
2150     return $decls;
2151 }
2152
2153 # Internal implementation hints that the core sets automatically, so don't need
2154 # (or want) to be passed back to the user
2155 my %ignored_hints = (
2156     'open<' => 1,
2157     'open>' => 1,
2158     ':'     => 1,
2159     'strict/refs' => 1,
2160     'strict/subs' => 1,
2161     'strict/vars' => 1,
2162 );
2163
2164 my %rev_feature;
2165
2166 sub declare_hinthash {
2167     my ($self, $from, $to, $indent, $hints) = @_;
2168     my $doing_features =
2169         ($hints & $feature::hint_mask) == $feature::hint_mask;
2170     my @decls;
2171     my @features;
2172     my @unfeatures; # bugs?
2173     for my $key (sort keys %$to) {
2174         next if $ignored_hints{$key};
2175         my $is_feature = $key =~ /^feature_/;
2176         next if $is_feature and not $doing_features;
2177         if (!exists $from->{$key} or $from->{$key} ne $to->{$key}) {
2178             push(@features, $key), next if $is_feature;
2179             push @decls,
2180                 qq(\$^H{) . single_delim("q", "'", $key, $self) . qq(} = )
2181               . (
2182                    defined $to->{$key}
2183                         ? single_delim("q", "'", $to->{$key}, $self)
2184                         : 'undef'
2185                 )
2186               . qq(;);
2187         }
2188     }
2189     for my $key (sort keys %$from) {
2190         next if $ignored_hints{$key};
2191         my $is_feature = $key =~ /^feature_/;
2192         next if $is_feature and not $doing_features;
2193         if (!exists $to->{$key}) {
2194             push(@unfeatures, $key), next if $is_feature;
2195             push @decls, qq(delete \$^H{'$key'};);
2196         }
2197     }
2198     my @ret;
2199     if (@features || @unfeatures) {
2200         if (!%rev_feature) { %rev_feature = reverse %feature::feature }
2201     }
2202     if (@features) {
2203         push @ret, $self->keyword("use") . " feature "
2204                  . join(", ", map "'$rev_feature{$_}'", @features) . ";\n";
2205     }
2206     if (@unfeatures) {
2207         push @ret, $self->keyword("no") . " feature "
2208                  . join(", ", map "'$rev_feature{$_}'", @unfeatures)
2209                  . ";\n";
2210     }
2211     @decls and
2212         push @ret,
2213              join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n\cK";
2214     return @ret;
2215 }
2216
2217 sub hint_pragmas {
2218     my ($bits) = @_;
2219     my (@pragmas, @strict);
2220     push @pragmas, "integer" if $bits & 0x1;
2221     for (sort keys %strict_bits) {
2222         push @strict, "'$_'" if $bits & $strict_bits{$_};
2223     }
2224     if (@strict == keys %strict_bits) {
2225         push @pragmas, "strict";
2226     }
2227     elsif (@strict) {
2228         push @pragmas, "strict " . join ', ', @strict;
2229     }
2230     push @pragmas, "bytes" if $bits & 0x8;
2231     return @pragmas;
2232 }
2233
2234 sub pp_dbstate { pp_nextstate(@_) }
2235 sub pp_setstate { pp_nextstate(@_) }
2236
2237 sub pp_unstack { return "" } # see also leaveloop
2238
2239 my %feature_keywords = (
2240   # keyword => 'feature',
2241     state   => 'state',
2242     say     => 'say',
2243     given   => 'switch',
2244     when    => 'switch',
2245     default => 'switch',
2246     break   => 'switch',
2247     evalbytes=>'evalbytes',
2248     __SUB__ => '__SUB__',
2249    fc       => 'fc',
2250 );
2251
2252 # keywords that are strong and also have a prototype
2253 #
2254 my %strong_proto_keywords = map { $_ => 1 } qw(
2255     pos
2256     prototype
2257     scalar
2258     study
2259     undef
2260 );
2261
2262 sub feature_enabled {
2263         my($self,$name) = @_;
2264         my $hh;
2265         my $hints = $self->{hints} & $feature::hint_mask;
2266         if ($hints && $hints != $feature::hint_mask) {
2267             $hh = _features_from_bundle($hints);
2268         }
2269         elsif ($hints) { $hh = $self->{'hinthash'} }
2270         return $hh && $hh->{"feature_$feature_keywords{$name}"}
2271 }
2272
2273 sub keyword {
2274     my $self = shift;
2275     my $name = shift;
2276     return $name if $name =~ /^CORE::/; # just in case
2277     if (exists $feature_keywords{$name}) {
2278         return "CORE::$name" if not $self->feature_enabled($name);
2279     }
2280     # This sub may be called for a program that has no nextstate ops.  In
2281     # that case we may have a lexical sub named no/use/sub in scope but
2282     # but $self->lex_in_scope will return false because it depends on the
2283     # current nextstate op.  So we need this alternate method if there is
2284     # no current cop.
2285     if (!$self->{'curcop'}) {
2286         $self->populate_curcvlex() if !defined $self->{'curcvlex'};
2287         return "CORE::$name" if exists $self->{'curcvlex'}{"m&$name"}
2288                              || exists $self->{'curcvlex'}{"o&$name"};
2289     } elsif ($self->lex_in_scope("&$name")
2290           || $self->lex_in_scope("&$name", 1)) {
2291         return "CORE::$name";
2292     }
2293     if ($strong_proto_keywords{$name}
2294         || ($name !~ /^(?:chom?p|do|exec|glob|s(?:elect|ystem))\z/
2295             && !defined eval{prototype "CORE::$name"})
2296     ) { return $name }
2297     if (
2298         exists $self->{subs_declared}{$name}
2299          or
2300         exists &{"$self->{curstash}::$name"}
2301     ) {
2302         return "CORE::$name"
2303     }
2304     return $name;
2305 }
2306
2307 sub baseop {
2308     my $self = shift;
2309     my($op, $cx, $name) = @_;
2310     return $self->keyword($name);
2311 }
2312
2313 sub pp_stub { "()" }
2314 sub pp_wantarray { baseop(@_, "wantarray") }
2315 sub pp_fork { baseop(@_, "fork") }
2316 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
2317 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
2318 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
2319 sub pp_tms { baseop(@_, "times") }
2320 sub pp_ghostent { baseop(@_, "gethostent") }
2321 sub pp_gnetent { baseop(@_, "getnetent") }
2322 sub pp_gprotoent { baseop(@_, "getprotoent") }
2323 sub pp_gservent { baseop(@_, "getservent") }
2324 sub pp_ehostent { baseop(@_, "endhostent") }
2325 sub pp_enetent { baseop(@_, "endnetent") }
2326 sub pp_eprotoent { baseop(@_, "endprotoent") }
2327 sub pp_eservent { baseop(@_, "endservent") }
2328 sub pp_gpwent { baseop(@_, "getpwent") }
2329 sub pp_spwent { baseop(@_, "setpwent") }
2330 sub pp_epwent { baseop(@_, "endpwent") }
2331 sub pp_ggrent { baseop(@_, "getgrent") }
2332 sub pp_sgrent { baseop(@_, "setgrent") }
2333 sub pp_egrent { baseop(@_, "endgrent") }
2334 sub pp_getlogin { baseop(@_, "getlogin") }
2335
2336 sub POSTFIX () { 1 }
2337
2338 # I couldn't think of a good short name, but this is the category of
2339 # symbolic unary operators with interesting precedence
2340
2341 sub pfixop {
2342     my $self = shift;
2343     my($op, $cx, $name, $prec, $flags) = (@_, 0);
2344     my $kid = $op->first;
2345     $kid = $self->deparse($kid, $prec);
2346     return $self->maybe_parens(($flags & POSTFIX)
2347                                  ? "$kid$name"
2348                                    # avoid confusion with filetests
2349                                  : $name eq '-'
2350                                    && $kid =~ /^[a-zA-Z](?!\w)/
2351                                         ? "$name($kid)"
2352                                         : "$name$kid",
2353                                $cx, $prec);
2354 }
2355
2356 sub pp_preinc { pfixop(@_, "++", 23) }
2357 sub pp_predec { pfixop(@_, "--", 23) }
2358 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
2359 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
2360 sub pp_i_preinc { pfixop(@_, "++", 23) }
2361 sub pp_i_predec { pfixop(@_, "--", 23) }
2362 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
2363 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
2364 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
2365 *pp_ncomplement = *pp_complement;
2366 sub pp_scomplement { maybe_targmy(@_, \&pfixop, "~.", 21) }
2367
2368 sub pp_negate { maybe_targmy(@_, \&real_negate) }
2369 sub real_negate {
2370     my $self = shift;
2371     my($op, $cx) = @_;
2372     if ($op->first->name =~ /^(i_)?negate$/) {
2373         # avoid --$x
2374         $self->pfixop($op, $cx, "-", 21.5);
2375     } else {
2376         $self->pfixop($op, $cx, "-", 21);       
2377     }
2378 }
2379 sub pp_i_negate { pp_negate(@_) }
2380
2381 sub pp_not {
2382     my $self = shift;
2383     my($op, $cx) = @_;
2384     if ($cx <= 4) {
2385         $self->listop($op, $cx, "not", $op->first);
2386     } else {
2387         $self->pfixop($op, $cx, "!", 21);       
2388     }
2389 }
2390
2391 sub unop {
2392     my $self = shift;
2393     my($op, $cx, $name, $nollafr) = @_;
2394     my $kid;
2395     if ($op->flags & OPf_KIDS) {
2396         $kid = $op->first;
2397         if (not $name) {
2398             # this deals with 'boolkeys' right now
2399             return $self->deparse($kid,$cx);
2400         }
2401         my $builtinname = $name;
2402         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
2403         if (defined prototype($builtinname)
2404            && $builtinname ne 'CORE::readline'
2405            && prototype($builtinname) =~ /^;?\*/
2406            && $kid->name eq "rv2gv") {
2407             $kid = $kid->first;
2408         }
2409
2410         if ($nollafr) {
2411             if (($kid = $self->deparse($kid, 16)) !~ s/^\cS//) {
2412                 # require foo() is a syntax error.
2413                 $kid =~ /^(?!\d)\w/ and $kid = "($kid)";
2414             }
2415             return $self->maybe_parens(
2416                         $self->keyword($name) . " $kid", $cx, 16
2417                    );
2418         }   
2419         return $self->maybe_parens_unop($name, $kid, $cx);
2420     } else {
2421         return $self->maybe_parens(
2422             $self->keyword($name) . ($op->flags & OPf_SPECIAL ? "()" : ""),
2423             $cx, 16,
2424         );
2425     }
2426 }
2427
2428 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
2429 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
2430 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
2431 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
2432 sub pp_defined { unop(@_, "defined") }
2433 sub pp_undef { unop(@_, "undef") }
2434 sub pp_study { unop(@_, "study") }
2435 sub pp_ref { unop(@_, "ref") }
2436 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
2437
2438 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
2439 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
2440 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
2441 sub pp_srand { unop(@_, "srand") }
2442 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
2443 sub pp_log { maybe_targmy(@_, \&unop, "log") }
2444 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
2445 sub pp_int { maybe_targmy(@_, \&unop, "int") }
2446 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
2447 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
2448 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
2449
2450 sub pp_length { maybe_targmy(@_, \&unop, "length") }
2451 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
2452 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
2453
2454 sub pp_each { unop(@_, "each") }
2455 sub pp_values { unop(@_, "values") }
2456 sub pp_keys { unop(@_, "keys") }
2457 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
2458 sub pp_boolkeys { 
2459     # no name because its an optimisation op that has no keyword
2460     unop(@_,"");
2461 }
2462 sub pp_aeach { unop(@_, "each") }
2463 sub pp_avalues { unop(@_, "values") }
2464 sub pp_akeys { unop(@_, "keys") }
2465 sub pp_pop { unop(@_, "pop") }
2466 sub pp_shift { unop(@_, "shift") }
2467
2468 sub pp_caller { unop(@_, "caller") }
2469 sub pp_reset { unop(@_, "reset") }
2470 sub pp_exit { unop(@_, "exit") }
2471 sub pp_prototype { unop(@_, "prototype") }
2472
2473 sub pp_close { unop(@_, "close") }
2474 sub pp_fileno { unop(@_, "fileno") }
2475 sub pp_umask { unop(@_, "umask") }
2476 sub pp_untie { unop(@_, "untie") }
2477 sub pp_tied { unop(@_, "tied") }
2478 sub pp_dbmclose { unop(@_, "dbmclose") }
2479 sub pp_getc { unop(@_, "getc") }
2480 sub pp_eof { unop(@_, "eof") }
2481 sub pp_tell { unop(@_, "tell") }
2482 sub pp_getsockname { unop(@_, "getsockname") }
2483 sub pp_getpeername { unop(@_, "getpeername") }
2484
2485 sub pp_chdir {
2486     my ($self, $op, $cx) = @_;
2487     if (($op->flags & (OPf_SPECIAL|OPf_KIDS)) == (OPf_SPECIAL|OPf_KIDS)) {
2488         my $kw = $self->keyword("chdir");
2489         my $kid = $self->const_sv($op->first)->PV;
2490         my $code = $kw
2491                  . ($cx >= 16 || $self->{'parens'} ? "($kid)" : " $kid");
2492         maybe_targmy(@_, sub { $_[3] }, $code);
2493     } else {
2494         maybe_targmy(@_, \&unop, "chdir")
2495     }
2496 }
2497
2498 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
2499 sub pp_readlink { unop(@_, "readlink") }
2500 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
2501 sub pp_readdir { unop(@_, "readdir") }
2502 sub pp_telldir { unop(@_, "telldir") }
2503 sub pp_rewinddir { unop(@_, "rewinddir") }
2504 sub pp_closedir { unop(@_, "closedir") }
2505 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
2506 sub pp_localtime { unop(@_, "localtime") }
2507 sub pp_gmtime { unop(@_, "gmtime") }
2508 sub pp_alarm { unop(@_, "alarm") }
2509 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
2510
2511 sub pp_dofile {
2512     my $code = unop(@_, "do", 1); # llafr does not apply
2513     if ($code =~ s/^((?:CORE::)?do) \{/$1({/) { $code .= ')' }
2514     $code;
2515 }
2516 sub pp_entereval {
2517     unop(
2518       @_,
2519       $_[1]->private & OPpEVAL_BYTES ? 'evalbytes' : "eval"
2520     )
2521 }
2522
2523 sub pp_ghbyname { unop(@_, "gethostbyname") }
2524 sub pp_gnbyname { unop(@_, "getnetbyname") }
2525 sub pp_gpbyname { unop(@_, "getprotobyname") }
2526 sub pp_shostent { unop(@_, "sethostent") }
2527 sub pp_snetent { unop(@_, "setnetent") }
2528 sub pp_sprotoent { unop(@_, "setprotoent") }
2529 sub pp_sservent { unop(@_, "setservent") }
2530 sub pp_gpwnam { unop(@_, "getpwnam") }
2531 sub pp_gpwuid { unop(@_, "getpwuid") }
2532 sub pp_ggrnam { unop(@_, "getgrnam") }
2533 sub pp_ggrgid { unop(@_, "getgrgid") }
2534
2535 sub pp_lock { unop(@_, "lock") }
2536
2537 sub pp_continue { unop(@_, "continue"); }
2538 sub pp_break { unop(@_, "break"); }
2539
2540 sub givwhen {
2541     my $self = shift;
2542     my($op, $cx, $givwhen) = @_;
2543
2544     my $enterop = $op->first;
2545     my ($head, $block);
2546     if ($enterop->flags & OPf_SPECIAL) {
2547         $head = $self->keyword("default");
2548         $block = $self->deparse($enterop->first, 0);
2549     }
2550     else {
2551         my $cond = $enterop->first;
2552         my $cond_str = $self->deparse($cond, 1);
2553         $head = "$givwhen ($cond_str)";
2554         $block = $self->deparse($cond->sibling, 0);
2555     }
2556
2557     return "$head {\n".
2558         "\t$block\n".
2559         "\b}\cK";
2560 }
2561
2562 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
2563 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
2564
2565 sub pp_exists {
2566     my $self = shift;
2567     my($op, $cx) = @_;
2568     my $arg;
2569     my $name = $self->keyword("exists");
2570     if ($op->private & OPpEXISTS_SUB) {
2571         # Checking for the existence of a subroutine
2572         return $self->maybe_parens_func($name,
2573                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
2574     }
2575     if ($op->flags & OPf_SPECIAL) {
2576         # Array element, not hash element
2577         return $self->maybe_parens_func($name,
2578                                 $self->pp_aelem($op->first, 16), $cx, 16);
2579     }
2580     return $self->maybe_parens_func($name, $self->pp_helem($op->first, 16),
2581                                     $cx, 16);
2582 }
2583
2584 sub pp_delete {
2585     my $self = shift;
2586     my($op, $cx) = @_;
2587     my $arg;
2588     my $name = $self->keyword("delete");
2589     if ($op->private & (OPpSLICE|OPpKVSLICE)) {
2590         if ($op->flags & OPf_SPECIAL) {
2591             # Deleting from an array, not a hash
2592             return $self->maybe_parens_func($name,
2593                                         $self->pp_aslice($op->first, 16),
2594                                         $cx, 16);
2595         }
2596         return $self->maybe_parens_func($name,
2597                                         $self->pp_hslice($op->first, 16),
2598                                         $cx, 16);
2599     } else {
2600         if ($op->flags & OPf_SPECIAL) {
2601             # Deleting from an array, not a hash
2602             return $self->maybe_parens_func($name,
2603                                         $self->pp_aelem($op->first, 16),
2604                                         $cx, 16);
2605         }
2606         return $self->maybe_parens_func($name,
2607                                         $self->pp_helem($op->first, 16),
2608                                         $cx, 16);
2609     }
2610 }
2611
2612 sub pp_require {
2613     my $self = shift;
2614     my($op, $cx) = @_;
2615     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
2616     my $kid = $op->first;
2617     if ($kid->name eq 'const') {
2618         my $priv = $kid->private;
2619         my $sv = $self->const_sv($kid);
2620         my $arg;
2621         if ($priv & OPpCONST_BARE) {
2622             $arg = $sv->PV;
2623             $arg =~ s[/][::]g;
2624             $arg =~ s/\.pm//g;
2625         } elsif ($priv & OPpCONST_NOVER) {
2626             $opname = $self->keyword('no');
2627             $arg = $self->const($sv, 16);
2628         } elsif ((my $tmp = $self->const($sv, 16)) =~ /^v/) {
2629             $arg = $tmp;
2630         }
2631         if ($arg) {
2632             return $self->maybe_parens("$opname $arg", $cx, 16);
2633         }
2634     }
2635     $self->unop(
2636             $op, $cx,
2637             $opname,
2638             1, # llafr does not apply
2639     );
2640 }
2641
2642 sub pp_scalar {
2643     my $self = shift;
2644     my($op, $cx) = @_;
2645     my $kid = $op->first;
2646     if (not null $kid->sibling) {
2647         # XXX Was a here-doc
2648         return $self->dquote($op);
2649     }
2650     $self->unop(@_, "scalar");
2651 }
2652
2653
2654 sub padval {
2655     my $self = shift;
2656     my $targ = shift;
2657     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
2658 }
2659
2660 sub anon_hash_or_list {
2661     my $self = shift;
2662     my($op, $cx) = @_;
2663
2664     my($pre, $post) = @{{"anonlist" => ["[","]"],
2665                          "anonhash" => ["{","}"]}->{$op->name}};
2666     my($expr, @exprs);
2667     $op = $op->first->sibling; # skip pushmark
2668     for (; !null($op); $op = $op->sibling) {
2669         $expr = $self->deparse($op, 6);
2670         push @exprs, $expr;
2671     }
2672     if ($pre eq "{" and $cx < 1) {
2673         # Disambiguate that it's not a block
2674         $pre = "+{";
2675     }
2676     return $pre . join(", ", @exprs) . $post;
2677 }
2678
2679 sub pp_anonlist {
2680     my $self = shift;
2681     my ($op, $cx) = @_;
2682     if ($op->flags & OPf_SPECIAL) {
2683         return $self->anon_hash_or_list($op, $cx);
2684     }
2685     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
2686     return 'XXX';
2687 }
2688
2689 *pp_anonhash = \&pp_anonlist;
2690
2691 sub pp_refgen {
2692     my $self = shift;   
2693     my($op, $cx) = @_;
2694     my $kid = $op->first;
2695     if ($kid->name eq "null") {
2696         my $anoncode = $kid = $kid->first;
2697         if ($anoncode->name eq "anonconst") {
2698             $anoncode = $anoncode->first->first->sibling;
2699         }
2700         if ($anoncode->name eq "anoncode"
2701          or !null($anoncode = $kid->sibling) and
2702                  $anoncode->name eq "anoncode") {
2703             return $self->e_anoncode({ code => $self->padval($anoncode->targ) });
2704         } elsif ($kid->name eq "pushmark") {
2705             my $sib_name = $kid->sibling->name;
2706             if ($sib_name eq 'entersub') {
2707                 my $text = $self->deparse($kid->sibling, 1);
2708                 # Always show parens for \(&func()), but only with -p otherwise
2709                 $text = "($text)" if $self->{'parens'}
2710                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
2711                 return "\\$text";
2712             }
2713         }
2714     }
2715     local $self->{'in_refgen'} = 1;
2716     $self->pfixop($op, $cx, "\\", 20);
2717 }
2718
2719 sub e_anoncode {
2720     my ($self, $info) = @_;
2721     my $text = $self->deparse_sub($info->{code});
2722     return $self->keyword("sub") . " $text";
2723 }
2724
2725 sub pp_srefgen { pp_refgen(@_) }
2726
2727 sub pp_readline {
2728     my $self = shift;
2729     my($op, $cx) = @_;
2730     my $kid = $op->first;
2731     if (is_scalar($kid)
2732         and $op->flags & OPf_SPECIAL
2733         and $self->deparse($kid, 1) eq 'ARGV')
2734     {
2735         return '<<>>';
2736     }
2737     return $self->unop($op, $cx, "readline");
2738 }
2739
2740 sub pp_rcatline {
2741     my $self = shift;
2742     my($op) = @_;
2743     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
2744 }
2745
2746 # Unary operators that can occur as pseudo-listops inside double quotes
2747 sub dq_unop {
2748     my $self = shift;
2749     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
2750     my $kid;
2751     if ($op->flags & OPf_KIDS) {
2752        $kid = $op->first;
2753        # If there's more than one kid, the first is an ex-pushmark.
2754        $kid = $kid->sibling if not null $kid->sibling;
2755        return $self->maybe_parens_unop($name, $kid, $cx);
2756     } else {
2757        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
2758     }
2759 }
2760
2761 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
2762 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
2763 sub pp_uc { dq_unop(@_, "uc") }
2764 sub pp_lc { dq_unop(@_, "lc") }
2765 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
2766 sub pp_fc { dq_unop(@_, "fc") }
2767
2768 sub loopex {
2769     my $self = shift;
2770     my ($op, $cx, $name) = @_;
2771     if (class($op) eq "PVOP") {
2772         $name .= " " . $op->pv;
2773     } elsif (class($op) eq "OP") {
2774         # no-op
2775     } elsif (class($op) eq "UNOP") {
2776         (my $kid = $self->deparse($op->first, 7)) =~ s/^\cS//;
2777         # last foo() is a syntax error.
2778         $kid =~ /^(?!\d)\w/ and $kid = "($kid)";
2779         $name .= " $kid";
2780     }
2781     return $self->maybe_parens($name, $cx, 7);
2782 }
2783
2784 sub pp_last { loopex(@_, "last") }
2785 sub pp_next { loopex(@_, "next") }
2786 sub pp_redo { loopex(@_, "redo") }
2787 sub pp_goto { loopex(@_, "goto") }
2788 sub pp_dump { loopex(@_, "CORE::dump") }
2789
2790 sub ftst {
2791     my $self = shift;
2792     my($op, $cx, $name) = @_;
2793     if (class($op) eq "UNOP") {
2794         # Genuine '-X' filetests are exempt from the LLAFR, but not
2795         # l?stat()
2796         if ($name =~ /^-/) {
2797             (my $kid = $self->deparse($op->first, 16)) =~ s/^\cS//;
2798             return $self->maybe_parens("$name $kid", $cx, 16);
2799         }
2800         return $self->maybe_parens_unop($name, $op->first, $cx);
2801     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2802         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2803     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2804         return $name;
2805     }
2806 }
2807
2808 sub pp_lstat    { ftst(@_, "lstat") }
2809 sub pp_stat     { ftst(@_, "stat") }
2810 sub pp_ftrread  { ftst(@_, "-R") }
2811 sub pp_ftrwrite { ftst(@_, "-W") }
2812 sub pp_ftrexec  { ftst(@_, "-X") }
2813 sub pp_fteread  { ftst(@_, "-r") }
2814 sub pp_ftewrite { ftst(@_, "-w") }
2815 sub pp_fteexec  { ftst(@_, "-x") }
2816 sub pp_ftis     { ftst(@_, "-e") }
2817 sub pp_fteowned { ftst(@_, "-O") }
2818 sub pp_ftrowned { ftst(@_, "-o") }
2819 sub pp_ftzero   { ftst(@_, "-z") }
2820 sub pp_ftsize   { ftst(@_, "-s") }
2821 sub pp_ftmtime  { ftst(@_, "-M") }
2822 sub pp_ftatime  { ftst(@_, "-A") }
2823 sub pp_ftctime  { ftst(@_, "-C") }
2824 sub pp_ftsock   { ftst(@_, "-S") }
2825 sub pp_ftchr    { ftst(@_, "-c") }
2826 sub pp_ftblk    { ftst(@_, "-b") }
2827 sub pp_ftfile   { ftst(@_, "-f") }
2828 sub pp_ftdir    { ftst(@_, "-d") }
2829 sub pp_ftpipe   { ftst(@_, "-p") }
2830 sub pp_ftlink   { ftst(@_, "-l") }
2831 sub pp_ftsuid   { ftst(@_, "-u") }
2832 sub pp_ftsgid   { ftst(@_, "-g") }
2833 sub pp_ftsvtx   { ftst(@_, "-k") }
2834 sub pp_fttty    { ftst(@_, "-t") }
2835 sub pp_fttext   { ftst(@_, "-T") }
2836 sub pp_ftbinary { ftst(@_, "-B") }
2837
2838 sub SWAP_CHILDREN () { 1 }
2839 sub ASSIGN () { 2 } # has OP= variant
2840 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2841
2842 my(%left, %right);
2843
2844 sub assoc_class {
2845     my $op = shift;
2846     my $name = $op->name;
2847     if ($name eq "concat" and $op->first->name eq "concat") {
2848         # avoid spurious '=' -- see comment in pp_concat
2849         return "concat";
2850     }
2851     if ($name eq "null" and class($op) eq "UNOP"
2852         and $op->first->name =~ /^(and|x?or)$/
2853         and null $op->first->sibling)
2854     {
2855         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2856         # with a null that's used as the common end point of the two
2857         # flows of control. For precedence purposes, ignore it.
2858         # (COND_EXPRs have these too, but we don't bother with
2859         # their associativity).
2860         return assoc_class($op->first);
2861     }
2862     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2863 }
2864
2865 # Left associative operators, like '+', for which
2866 # $a + $b + $c is equivalent to ($a + $b) + $c
2867
2868 BEGIN {
2869     %left = ('multiply' => 19, 'i_multiply' => 19,
2870              'divide' => 19, 'i_divide' => 19,
2871              'modulo' => 19, 'i_modulo' => 19,
2872              'repeat' => 19,
2873              'add' => 18, 'i_add' => 18,
2874              'subtract' => 18, 'i_subtract' => 18,
2875              'concat' => 18,
2876              'left_shift' => 17, 'right_shift' => 17,
2877              'bit_and' => 13, 'nbit_and' => 13, 'sbit_and' => 13,
2878              'bit_or' => 12, 'bit_xor' => 12,
2879              'sbit_or' => 12, 'sbit_xor' => 12,
2880              'nbit_or' => 12, 'nbit_xor' => 12,
2881              'and' => 3,
2882              'or' => 2, 'xor' => 2,
2883             );
2884 }
2885
2886 sub deparse_binop_left {
2887     my $self = shift;
2888     my($op, $left, $prec) = @_;
2889     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2890         and $left{assoc_class($op)} == $left{assoc_class($left)})
2891     {
2892         return $self->deparse($left, $prec - .00001);
2893     } else {
2894         return $self->deparse($left, $prec);    
2895     }
2896 }
2897
2898 # Right associative operators, like '=', for which
2899 # $a = $b = $c is equivalent to $a = ($b = $c)
2900
2901 BEGIN {
2902     %right = ('pow' => 22,
2903               'sassign=' => 7, 'aassign=' => 7,
2904               'multiply=' => 7, 'i_multiply=' => 7,
2905               'divide=' => 7, 'i_divide=' => 7,
2906               'modulo=' => 7, 'i_modulo=' => 7,
2907               'repeat=' => 7, 'refassign' => 7, 'refassign=' => 7,
2908               'add=' => 7, 'i_add=' => 7,
2909               'subtract=' => 7, 'i_subtract=' => 7,
2910               'concat=' => 7,
2911               'left_shift=' => 7, 'right_shift=' => 7,
2912               'bit_and=' => 7, 'sbit_and=' => 7, 'nbit_and=' => 7,
2913               'nbit_or=' => 7, 'nbit_xor=' => 7,
2914               'sbit_or=' => 7, 'sbit_xor=' => 7,
2915               'andassign' => 7,
2916               'orassign' => 7,
2917              );
2918 }
2919
2920 sub deparse_binop_right {
2921     my $self = shift;
2922     my($op, $right, $prec) = @_;
2923     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2924         and $right{assoc_class($op)} == $right{assoc_class($right)})
2925     {
2926         return $self->deparse($right, $prec - .00001);
2927     } else {
2928         return $self->deparse($right, $prec);   
2929     }
2930 }
2931
2932 sub binop {
2933     my $self = shift;
2934     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2935     my $left = $op->first;
2936     my $right = $op->last;
2937     my $eq = "";
2938     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2939         $eq = "=";
2940         $prec = 7;
2941     }
2942     if ($flags & SWAP_CHILDREN) {
2943         ($left, $right) = ($right, $left);
2944     }
2945     my $leftop = $left;
2946     $left = $self->deparse_binop_left($op, $left, $prec);
2947     $left = "($left)" if $flags & LIST_CONTEXT
2948                      and    $left !~ /^(my|our|local|)[\@\(]/
2949                          || do {
2950                                 # Parenthesize if the left argument is a
2951                                 # lone repeat op.
2952                                 my $left = $leftop->first->sibling;
2953                                 $left->name eq 'repeat'
2954                                     && null($left->sibling);
2955                             };
2956     $right = $self->deparse_binop_right($op, $right, $prec);
2957     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2958 }
2959
2960 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2961 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2962 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2963 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2964 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2965 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2966 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2967 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2968 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2969 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2970 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2971
2972 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2973 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2974 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2975 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2976 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2977 *pp_nbit_and = *pp_bit_and;
2978 *pp_nbit_or  = *pp_bit_or;
2979 *pp_nbit_xor = *pp_bit_xor;
2980 sub pp_sbit_and { maybe_targmy(@_, \&binop, "&.", 13, ASSIGN) }
2981 sub pp_sbit_or { maybe_targmy(@_, \&binop, "|.", 12, ASSIGN) }
2982 sub pp_sbit_xor { maybe_targmy(@_, \&binop, "^.", 12, ASSIGN) }
2983
2984 sub pp_eq { binop(@_, "==", 14) }
2985 sub pp_ne { binop(@_, "!=", 14) }
2986 sub pp_lt { binop(@_, "<", 15) }
2987 sub pp_gt { binop(@_, ">", 15) }
2988 sub pp_ge { binop(@_, ">=", 15) }
2989 sub pp_le { binop(@_, "<=", 15) }
2990 sub pp_ncmp { binop(@_, "<=>", 14) }
2991 sub pp_i_eq { binop(@_, "==", 14) }
2992 sub pp_i_ne { binop(@_, "!=", 14) }
2993 sub pp_i_lt { binop(@_, "<", 15) }
2994 sub pp_i_gt { binop(@_, ">", 15) }
2995 sub pp_i_ge { binop(@_, ">=", 15) }
2996 sub pp_i_le { binop(@_, "<=", 15) }
2997 sub pp_i_ncmp { maybe_targmy(@_, \&binop, "<=>", 14) }
2998
2999 sub pp_seq { binop(@_, "eq", 14) }
3000 sub pp_sne { binop(@_, "ne", 14) }
3001 sub pp_slt { binop(@_, "lt", 15) }
3002 sub pp_sgt { binop(@_, "gt", 15) }
3003 sub pp_sge { binop(@_, "ge", 15) }
3004 sub pp_sle { binop(@_, "le", 15) }
3005 sub pp_scmp { maybe_targmy(@_, \&binop, "cmp", 14) }
3006
3007 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
3008 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
3009
3010 sub pp_smartmatch {
3011     my ($self, $op, $cx) = @_;
3012     if (($op->flags & OPf_SPECIAL) && $self->{expand} < 2) {
3013         return $self->deparse($op->last, $cx);
3014     }
3015     else {
3016         binop(@_, "~~", 14);
3017     }
3018 }
3019
3020 # '.' is special because concats-of-concats are optimized to save copying
3021 # by making all but the first concat stacked. The effect is as if the
3022 # programmer had written '($a . $b) .= $c', except legal.
3023 sub pp_concat { maybe_targmy(@_, \&real_concat) }
3024 sub real_concat {
3025     my $self = shift;
3026     my($op, $cx) = @_;
3027     my $left = $op->first;
3028     my $right = $op->last;
3029     my $eq = "";
3030     my $prec = 18;
3031     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
3032         $eq = "=";
3033         $prec = 7;
3034     }
3035     $left = $self->deparse_binop_left($op, $left, $prec);
3036     $right = $self->deparse_binop_right($op, $right, $prec);
3037     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
3038 }
3039
3040 sub pp_repeat { maybe_targmy(@_, \&repeat) }
3041
3042 # 'x' is weird when the left arg is a list
3043 sub repeat {
3044     my $self = shift;
3045     my($op, $cx) = @_;
3046     my $left = $op->first;
3047     my $right = $op->last;
3048     my $eq = "";
3049     my $prec = 19;
3050     if ($op->flags & OPf_STACKED) {
3051         $eq = "=";
3052         $prec = 7;
3053     }
3054     if (null($right)) { # list repeat; count is inside left-side ex-list
3055                         # in 5.21.5 and earlier
3056         my $kid = $left->first->sibling; # skip pushmark
3057         my @exprs;
3058         for (; !null($kid->sibling); $kid = $kid->sibling) {
3059             push @exprs, $self->deparse($kid, 6);
3060         }
3061         $right = $kid;
3062         $left = "(" . join(", ", @exprs). ")";
3063     } else {
3064         my $dolist = $op->private & OPpREPEAT_DOLIST;
3065         $left = $self->deparse_binop_left($op, $left, $dolist ? 1 : $prec);
3066         if ($dolist) {
3067             $left = "($left)";
3068         }
3069     }
3070     $right = $self->deparse_binop_right($op, $right, $prec);
3071     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
3072 }
3073
3074 sub range {
3075     my $self = shift;
3076     my ($op, $cx, $type) = @_;
3077     my $left = $op->first;
3078     my $right = $left->sibling;
3079     $left = $self->deparse($left, 9);
3080     $right = $self->deparse($right, 9);
3081     return $self->maybe_parens("$left $type $right", $cx, 9);
3082 }
3083
3084 sub pp_flop {
3085     my $self = shift;
3086     my($op, $cx) = @_;
3087     my $flip = $op->first;
3088     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
3089     return $self->range($flip->first, $cx, $type);
3090 }
3091
3092 # one-line while/until is handled in pp_leave
3093
3094 sub logop {
3095     my $self = shift;
3096     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
3097     my $left = $op->first;
3098     my $right = $op->first->sibling;
3099     $blockname &&= $self->keyword($blockname);
3100     if ($cx < 1 and is_scope($right) and $blockname
3101         and $self->{'expand'} < 7)
3102     { # if ($a) {$b}
3103         $left = $self->deparse($left, 1);
3104         $right = $self->deparse($right, 0);
3105         return "$blockname ($left) {\n\t$right\n\b}\cK";
3106     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
3107              and $self->{'expand'} < 7) { # $b if $a
3108         $right = $self->deparse($right, 1);
3109         $left = $self->deparse($left, 1);
3110         return "$right $blockname $left";
3111     } elsif ($cx > $lowprec and $highop) { # $a && $b
3112         $left = $self->deparse_binop_left($op, $left, $highprec);
3113         $right = $self->deparse_binop_right($op, $right, $highprec);
3114         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
3115     } else { # $a and $b
3116         $left = $self->deparse_binop_left($op, $left, $lowprec);
3117         $right = $self->deparse_binop_right($op, $right, $lowprec);
3118         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
3119     }
3120 }
3121
3122 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
3123 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
3124 sub pp_dor { logop(@_, "//", 10) }
3125
3126 # xor is syntactically a logop, but it's really a binop (contrary to
3127 # old versions of opcode.pl). Syntax is what matters here.
3128 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
3129
3130 sub logassignop {
3131     my $self = shift;
3132     my ($op, $cx, $opname) = @_;
3133     my $left = $op->first;
3134     my $right = $op->first->sibling->first; # skip sassign
3135     $left = $self->deparse($left, 7);
3136     $right = $self->deparse($right, 7);
3137     return $self->maybe_parens("$left $opname $right", $cx, 7);
3138 }
3139
3140 sub pp_andassign { logassignop(@_, "&&=") }
3141 sub pp_orassign  { logassignop(@_, "||=") }
3142 sub pp_dorassign { logassignop(@_, "//=") }
3143
3144 sub rv2gv_or_string {
3145     my($self,$op) = @_;
3146     if ($op->name eq "gv") { # could be open("open") or open("###")
3147         my($name,$quoted) =
3148             $self->stash_variable_name("", $self->gv_or_padgv($op));
3149         $quoted ? $name : "*$name";
3150     }
3151     else {
3152         $self->deparse($op, 6);
3153     }
3154 }
3155
3156 sub listop {
3157     my $self = shift;
3158     my($op, $cx, $name, $kid, $nollafr) = @_;
3159     my(@exprs);
3160     my $parens = ($cx >= 5) || $self->{'parens'};
3161     $kid ||= $op->first->sibling;
3162     # If there are no arguments, add final parentheses (or parenthesize the
3163     # whole thing if the llafr does not apply) to account for cases like
3164     # (return)+1 or setpgrp()+1.  When the llafr does not apply, we use a
3165     # precedence of 6 (< comma), as "return, 1" does not need parentheses.
3166     if (null $kid) {
3167         return $nollafr
3168                 ? $self->maybe_parens($self->keyword($name), $cx, 7)
3169                 : $self->keyword($name) . '()' x (7 < $cx);
3170     }
3171     my $first;
3172     my $fullname = $self->keyword($name);
3173     my $proto = prototype("CORE::$name");
3174     if (
3175          (     (defined $proto && $proto =~ /^;?\*/)
3176             || $name eq 'select' # select(F) doesn't have a proto
3177          )
3178          && $kid->name eq "rv2gv"
3179          && !($kid->private & OPpLVAL_INTRO)
3180     ) {
3181         $first = $self->rv2gv_or_string($kid->first);
3182     }
3183     else {
3184         $first = $self->deparse($kid, 6);
3185     }
3186     if ($name eq "chmod" && $first =~ /^\d+$/) {
3187         $first = sprintf("%#o", $first);
3188     }
3189     $first = "+$first"
3190         if not $parens and not $nollafr and substr($first, 0, 1) eq "(";
3191     push @exprs, $first;
3192     $kid = $kid->sibling;
3193     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv"
3194          && !($kid->private & OPpLVAL_INTRO)) {
3195         push @exprs, $first = $self->rv2gv_or_string($kid->first);
3196         $kid = $kid->sibling;
3197     }
3198     for (; !null($kid); $kid = $kid->sibling) {
3199         push @exprs, $self->deparse($kid, 6);
3200     }
3201     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
3202         return "$exprs[0] = $fullname"
3203                  . ($parens ? "($exprs[0])" : " $exprs[0]");
3204     }
3205
3206     if ($parens && $nollafr) {
3207         return "($fullname " . join(", ", @exprs) . ")";
3208     } elsif ($parens) {
3209         return "$fullname(" . join(", ", @exprs) . ")";
3210     } else {
3211         return "$fullname " . join(", ", @exprs);
3212     }
3213 }
3214
3215 sub pp_bless { listop(@_, "bless") }
3216 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
3217 sub pp_substr {
3218     my ($self,$op,$cx) = @_;
3219     if ($op->private & OPpSUBSTR_REPL_FIRST) {
3220         return
3221            listop($self, $op, 7, "substr", $op->first->sibling->sibling)
3222          . " = "
3223          . $self->deparse($op->first->sibling, 7);
3224     }
3225     maybe_local(@_, listop(@_, "substr"))
3226 }
3227
3228 sub pp_index {
3229     # Also handles pp_rindex.
3230     #
3231     # The body of this function includes an unrolled maybe_targmy(),
3232     # since the two parts of that sub's actions need to have have the
3233     # '== -1' bit in between
3234
3235     my($self, $op, $cx) = @_;
3236
3237     my $lex  = ($op->private & OPpTARGET_MY);
3238     my $bool = ($op->private & OPpTRUEBOOL);
3239
3240     my $val = $self->listop($op, ($bool ? 14 : $lex ? 7 : $cx), $op->name);
3241
3242     # (index() == -1) has op_eq and op_const optimised away
3243     if ($bool) {
3244         $val .= ($op->private & OPpINDEX_BOOLNEG) ? " == -1" : " != -1";
3245         $val = "($val)" if ($op->flags & OPf_PARENS);
3246     }
3247     if ($lex) {
3248         my $var = $self->padname($op->targ);
3249         $val = $self->maybe_parens("$var = $val", $cx, 7);
3250     }
3251     $val;
3252 }
3253
3254 sub pp_rindex { pp_index(@_); }
3255 sub pp_vec { maybe_targmy(@_, \&maybe_local, listop(@_, "vec")) }
3256 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
3257 sub pp_formline { listop(@_, "formline") } # see also deparse_format
3258 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
3259 sub pp_unpack { listop(@_, "unpack") }
3260 sub pp_pack { listop(@_, "pack") }
3261 sub pp_join { maybe_targmy(@_, \&listop, "join") }
3262 sub pp_splice { listop(@_, "splice") }
3263 sub pp_push { maybe_targmy(@_, \&listop, "push") }
3264 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
3265 sub pp_reverse { listop(@_, "reverse") }
3266 sub pp_warn { listop(@_, "warn") }
3267 sub pp_die { listop(@_, "die") }
3268 sub pp_return { listop(@_, "return", undef, 1) } # llafr does not apply
3269 sub pp_open { listop(@_, "open") }
3270 sub pp_pipe_op { listop(@_, "pipe") }
3271 sub pp_tie { listop(@_, "tie") }
3272 sub pp_binmode { listop(@_, "binmode") }
3273 sub pp_dbmopen { listop(@_, "dbmopen") }
3274 sub pp_sselect { listop(@_, "select") }
3275 sub pp_select { listop(@_, "select") }
3276 sub pp_read { listop(@_, "read") }
3277 sub pp_sysopen { listop(@_, "sysopen") }
3278 sub pp_sysseek { listop(@_, "sysseek") }
3279 sub pp_sysread { listop(@_, "sysread") }
3280 sub pp_syswrite { listop(@_, "syswrite") }
3281 sub pp_send { listop(@_, "send") }
3282 sub pp_recv { listop(@_, "recv") }
3283 sub pp_seek { listop(@_, "seek") }
3284 sub pp_fcntl { listop(@_, "fcntl") }
3285 sub pp_ioctl { listop(@_, "ioctl") }
3286 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
3287 sub pp_socket { listop(@_, "socket") }
3288 sub pp_sockpair { listop(@_, "socketpair") }
3289 sub pp_bind { listop(@_, "bind") }
3290 sub pp_connect { listop(@_, "connect") }
3291 sub pp_listen { listop(@_, "listen") }
3292 sub pp_accept { listop(@_, "accept") }
3293 sub pp_shutdown { listop(@_, "shutdown") }
3294 sub pp_gsockopt { listop(@_, "getsockopt") }
3295 sub pp_ssockopt { listop(@_, "setsockopt") }
3296 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
3297 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
3298 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
3299 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
3300 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
3301 sub pp_link { maybe_targmy(@_, \&listop, "link") }
3302 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
3303 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
3304 sub pp_open_dir { listop(@_, "opendir") }
3305 sub pp_seekdir { listop(@_, "seekdir") }
3306 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
3307 sub pp_system { maybe_targmy(@_, \&indirop, "system") }
3308 sub pp_exec { maybe_targmy(@_, \&indirop, "exec") }
3309 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
3310 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
3311 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
3312 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
3313 sub pp_shmget { listop(@_, "shmget") }
3314 sub pp_shmctl { listop(@_, "shmctl") }
3315 sub pp_shmread { listop(@_, "shmread") }
3316 sub pp_shmwrite { listop(@_, "shmwrite") }
3317 sub pp_msgget { listop(@_, "msgget") }
3318 sub pp_msgctl { listop(@_, "msgctl") }
3319 sub pp_msgsnd { listop(@_, "msgsnd") }
3320 sub pp_msgrcv { listop(@_, "msgrcv") }
3321 sub pp_semget { listop(@_, "semget") }
3322 sub pp_semctl { listop(@_, "semctl") }
3323 sub pp_semop { listop(@_, "semop") }
3324 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
3325 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
3326 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
3327 sub pp_gsbyname { listop(@_, "getservbyname") }
3328 sub pp_gsbyport { listop(@_, "getservbyport") }
3329 sub pp_syscall { listop(@_, "syscall") }
3330
3331 sub pp_glob {
3332     my $self = shift;
3333     my($op, $cx) = @_;
3334     my $kid = $op->first->sibling;  # skip pushmark
3335     my $keyword =
3336         $op->flags & OPf_SPECIAL ? 'glob' : $self->keyword('glob');
3337     my $text = $self->deparse($kid);
3338     return $cx >= 5 || $self->{'parens'}
3339         ? "$keyword($text)"
3340         : "$keyword $text";
3341 }
3342
3343 # Truncate is special because OPf_SPECIAL makes a bareword first arg
3344 # be a filehandle. This could probably be better fixed in the core
3345 # by moving the GV lookup into ck_truc.
3346
3347 sub pp_truncate {
3348     my $self = shift;
3349     my($op, $cx) = @_;
3350     my(@exprs);
3351     my $parens = ($cx >= 5) || $self->{'parens'};
3352     my $kid = $op->first->sibling;
3353     my $fh;
3354     if ($op->flags & OPf_SPECIAL) {
3355         # $kid is an OP_CONST
3356         $fh = $self->const_sv($kid)->PV;
3357     } else {
3358         $fh = $self->deparse($kid, 6);
3359         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
3360     }
3361     my $len = $self->deparse($kid->sibling, 6);
3362     my $name = $self->keyword('truncate');
3363     if ($parens) {
3364         return "$name($fh, $len)";
3365     } else {
3366         return "$name $fh, $len";
3367     }
3368 }
3369
3370 sub indirop {
3371     my $self = shift;
3372     my($op, $cx, $name) = @_;
3373     my($expr, @exprs);
3374     my $firstkid = my $kid = $op->first->sibling;
3375     my $indir = "";
3376     if ($op->flags & OPf_STACKED) {
3377         $indir = $kid;
3378         $indir = $indir->first; # skip rv2gv
3379         if (is_scope($indir)) {
3380             $indir = "{" . $self->deparse($indir, 0) . "}";
3381             $indir = "{;}" if $indir eq "{}";
3382         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
3383             $indir = $self->const_sv($indir)->PV;
3384         } else {
3385             $indir = $self->deparse($indir, 24);
3386         }
3387         $indir = $indir . " ";
3388         $kid = $kid->sibling;
3389     }
3390     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
3391         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
3392                                                   : '{$a <=> $b} ';
3393     }
3394     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
3395         $indir = '{$b cmp $a} ';
3396     }
3397     for (; !null($kid); $kid = $kid->sibling) {
3398         $expr = $self->deparse($kid, !$indir && $kid == $firstkid && $name eq "sort" && $firstkid->name eq "entersub" ? 16 : 6);
3399         push @exprs, $expr;
3400     }
3401     my $name2;
3402     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
3403         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
3404     }
3405     else { $name2 = $self->keyword($name) }
3406     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
3407         return "$exprs[0] = $name2 $indir $exprs[0]";
3408     }
3409
3410     my $args = $indir . join(", ", @exprs);
3411     if ($indir ne "" && $name eq "sort") {
3412         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
3413         # give bareword warnings in that case. Therefore if context
3414         # requires, we'll put parens around the outside "(sort f 1, 2,
3415         # 3)". Unfortunately, we'll currently think the parens are
3416         # necessary more often that they really are, because we don't
3417         # distinguish which side of an assignment we're on.
3418         if ($cx >= 5) {
3419             return "($name2 $args)";
3420         } else {
3421             return "$name2 $args";
3422         }
3423     } elsif (
3424         !$indir && $name eq "sort"
3425       && !null($op->first->sibling)
3426       && $op->first->sibling->name eq 'entersub'
3427     ) {
3428         # We cannot say sort foo(bar), as foo will be interpreted as a
3429         # comparison routine.  We have to say sort(...) in that case.
3430         return "$name2($args)";
3431     } else {
3432         return length $args
3433                 ? $self->maybe_parens_func($name2, $args, $cx, 5)
3434                 : $name2 . '()' x (7 < $cx);
3435     }
3436
3437 }
3438
3439 sub pp_prtf { indirop(@_, "printf") }
3440 sub pp_print { indirop(@_, "print") }
3441 sub pp_say  { indirop(@_, "say") }
3442 sub pp_sort { indirop(@_, "sort") }
3443
3444 sub mapop {
3445     my $self = shift;
3446     my($op, $cx, $name) = @_;
3447     my($expr, @exprs);
3448     my $kid = $op->first; # this is the (map|grep)start
3449     $kid = $kid->first->sibling; # skip a pushmark
3450     my $code = $kid->first; # skip a null
3451     if (is_scope $code) {
3452         $code = "{" . $self->deparse($code, 0) . "} ";
3453     } else {
3454         $code = $self->deparse($code, 24);
3455         $code .= ", " if !null($kid->sibling);
3456     }
3457     $kid = $kid->sibling;
3458     for (; !null($kid); $kid = $kid->sibling) {
3459         $expr = $self->deparse($kid, 6);
3460         push @exprs, $expr if defined $expr;
3461     }
3462     return $self->maybe_parens_func($self->keyword($name),
3463                                     $code . join(", ", @exprs), $cx, 5);
3464 }
3465
3466 sub pp_mapwhile { mapop(@_, "map") }
3467 sub pp_grepwhile { mapop(@_, "grep") }
3468 sub pp_mapstart { baseop(@_, "map") }
3469 sub pp_grepstart { baseop(@_, "grep") }
3470
3471 my %uses_intro;
3472 BEGIN {
3473     @uses_intro{
3474         eval { require B::Op_private }
3475           ? @{$B::Op_private::ops_using{OPpLVAL_INTRO}}
3476           : qw(gvsv rv2sv rv2hv rv2gv rv2av aelem helem aslice
3477                hslice delete padsv padav padhv enteriter entersub padrange
3478                pushmark cond_expr refassign list)
3479     } = ();
3480     delete @uses_intro{qw( lvref lvrefslice lvavref entersub )};
3481 }
3482
3483
3484 # Look for a my attribute declaration in a list or ex-list. Returns undef
3485 # if not found, 'my($x, @a) :Foo(bar)' etc otherwise.
3486 #
3487 # There are three basic tree structs that are expected:
3488 #
3489 # my $x :foo;
3490 #      <1> ex-list vK/LVINTRO ->c
3491 #         <0> ex-pushmark v ->3
3492 #         <1> entersub[t2] vKRS*/TARG ->b
3493 #                ....
3494 #         <0> padsv[$x:64,65] vM/LVINTRO ->c
3495 #
3496 # my @a :foo;
3497 # my %h :foo;
3498 #
3499 #      <1> ex-list vK ->c
3500 #         <0> ex-pushmark v ->3
3501 #         <0> padav[@a:64,65] vM/LVINTRO ->4
3502 #         <1> entersub[t2] vKRS*/TARG ->c
3503 #            ....
3504 #
3505 # my ($x,@a,%h) :foo;
3506 #
3507 #      <;> nextstate(main 64 -e:1) v:{ ->3
3508 #      <@> list vKP ->w
3509 #         <0> pushmark vM/LVINTRO ->4
3510 #         <0> padsv[$x:64,65] vM/LVINTRO ->5
3511 #         <0> padav[@a:64,65] vM/LVINTRO ->6
3512 #         <0> padhv[%h:64,65] vM/LVINTRO ->7
3513 #         <1> entersub[t4] vKRS*/TARG ->f
3514 #            ....
3515 #         <1> entersub[t5] vKRS*/TARG ->n
3516 #            ....
3517 #         <1> entersub[t6] vKRS*/TARG ->v
3518 #           ....
3519 # where the entersub in all cases looks like
3520 #        <1> entersub[t2] vKRS*/TARG ->c
3521 #           <0> pushmark s ->5
3522 #           <$> const[PV "attributes"] sM ->6
3523 #           <$> const[PV "main"] sM ->7
3524 #           <1> srefgen sKM/1 ->9
3525 #              <1> ex-list lKRM ->8
3526 #                 <0> padsv[@a:64,65] sRM ->8
3527 #           <$> const[PV "foo"] sM ->a
3528 #           <.> method_named[PV "import"] ->b
3529
3530 sub maybe_my_attr {
3531     my ($self, $op, $cx) = @_;
3532
3533     my $kid = $op->first->sibling; # skip pushmark
3534     return if class($kid) eq 'NULL';
3535
3536     my $lop;
3537     my $type;
3538
3539     # Extract out all the pad ops and entersub ops into
3540     # @padops and @entersubops. Return if anything else seen.
3541     # Also determine what class (if any) all the pad vars belong to
3542     my $class;
3543     my (@padops, @entersubops);
3544     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
3545         my $lopname = $lop->name;
3546         my $loppriv = $lop->private;
3547         if ($lopname =~ /^pad[sah]v$/) {
3548             return unless $loppriv & OPpLVAL_INTRO;
3549             return if     $loppriv & OPpPAD_STATE;
3550
3551             my $padname = $self->padname_sv($lop->targ);
3552             my $thisclass = ($padname->FLAGS & SVpad_TYPED)
3553                                 ? $padname->SvSTASH->NAME : 'main';
3554
3555             # all pad vars must be in the same class
3556             $class //= $thisclass;
3557             return unless $thisclass eq $class;
3558
3559             push @padops, $lop;
3560         }
3561         elsif ($lopname eq 'entersub') {
3562             push @entersubops, $lop;
3563         }
3564         else {
3565             return;
3566         }
3567     }
3568
3569     return unless @padops && @padops == @entersubops;
3570
3571     # there should be a balance: each padop has a corresponding
3572     # 'attributes'->import() method call, in the same order.
3573
3574     my @varnames;
3575     my $attr_text;
3576
3577     for my $i (0..$#padops) {
3578         my $padop = $padops[$i];
3579         my $esop  = $entersubops[$i];
3580
3581         push @varnames, $self->padname($padop->targ);
3582
3583         return unless ($esop->flags & OPf_KIDS);
3584
3585         my $kid = $esop->first;
3586         return unless $kid->type == OP_PUSHMARK;
3587
3588         $kid = $kid->sibling;
3589         return unless $$kid && $kid->type == OP_CONST;
3590         return unless $self->const_sv($kid)->PV eq 'attributes';
3591
3592         $kid = $kid->sibling;
3593         return unless $$kid && $kid->type == OP_CONST; # __PACKAGE__
3594
3595         $kid = $kid->sibling;
3596         return unless  $$kid
3597                     && $kid->name eq "srefgen"
3598                     && ($kid->flags & OPf_KIDS)
3599                     && ($kid->first->flags & OPf_KIDS)
3600                     && $kid->first->first->name =~ /^pad[sah]v$/
3601                     && $kid->first->first->targ == $padop->targ;
3602
3603         $kid = $kid->sibling;
3604         my @attr;
3605         while ($$kid) {
3606             last if ($kid->type != OP_CONST);
3607             push @attr, $self->const_sv($kid)->PV;
3608             $kid = $kid->sibling;
3609         }
3610         return unless @attr;
3611         my $thisattr = ":" . join(' ', @attr);
3612         $attr_text //= $thisattr;
3613         # all import calls must have the same list of attributes
3614         return unless $attr_text eq $thisattr;
3615
3616         return unless $kid->name eq 'method_named';
3617         return unless $self->meth_sv($kid)->PV eq 'import';
3618
3619         $kid = $kid->sibling;
3620         return if $$kid;
3621     }
3622
3623     my $res = 'my';
3624     $res .= " $class " if $class ne 'main';
3625     $res .=
3626             (@varnames > 1)
3627             ? "(" . join(', ', @varnames) . ')'
3628             : " $varnames[0]";
3629
3630     return "$res $attr_text";
3631 }
3632
3633
3634 sub pp_list {
3635     my $self = shift;
3636     my($op, $cx) = @_;
3637
3638     {
3639         # might be my ($s,@a,%h) :Foo(bar);
3640         my $my_attr = maybe_my_attr($self, $op, $cx);
3641         return $my_attr if defined $my_attr;
3642     }
3643
3644     my($expr, @exprs);
3645     my $kid = $op->first->sibling; # skip pushmark
3646     return '' if class($kid) eq 'NULL';
3647     my $lop;
3648     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
3649     my $type;
3650     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
3651         my $lopname = $lop->name;
3652         my $loppriv = $lop->private;
3653         my $newtype;
3654         if ($lopname =~ /^pad[ash]v$/ && $loppriv & OPpLVAL_INTRO) {
3655             if ($loppriv & OPpPAD_STATE) { # state()
3656                 ($local = "", last) if $local !~ /^(?:either|state)$/;
3657                 $local = "state";
3658             } else { # my()
3659                 ($local = "", last) if $local !~ /^(?:either|my)$/;
3660                 $local = "my";
3661             }
3662             my $padname = $self->padname_sv($lop->targ);
3663             if ($padname->FLAGS & SVpad_TYPED) {
3664                 $newtype = $padname->SvSTASH->NAME;
3665             }
3666         } elsif ($lopname =~ /^(?:gv|rv2)([ash])v$/
3667                         && $loppriv & OPpOUR_INTRO
3668                 or $lopname eq "null" && class($lop) eq 'UNOP'
3669                         && $lop->first->name eq "gvsv"
3670                         && $lop->first->private & OPpOUR_INTRO) { # our()
3671             my $newlocal = "local " x !!($loppriv & OPpLVAL_INTRO) . "our";
3672             ($local = "", last)
3673                 if $local ne 'either' && $local ne $newlocal;
3674             $local = $newlocal;
3675             my $funny = !$1 || $1 eq 's' ? '$' : $1 eq 'a' ? '@' : '%';
3676             if (my $t = $self->find_our_type(
3677                     $funny . $self->gv_or_padgv($lop->first)->NAME
3678                )) {
3679                 $newtype = $t;
3680             }
3681         } elsif ($lopname ne 'undef'
3682            and    !($loppriv & OPpLVAL_INTRO)
3683                || !exists $uses_intro{$lopname eq 'null'
3684                                         ? substr B::ppname($lop->targ), 3
3685                                         : $lopname})
3686         {
3687             $local = ""; # or not
3688             last;
3689         } elsif ($lopname ne "undef")
3690         {
3691             # local()
3692             ($local = "", last) if $local !~ /^(?:either|local)$/;
3693             $local = "local";
3694         }
3695         if (defined $type && defined $newtype && $newtype ne $type) {
3696             $local = '';
3697             last;
3698         }
3699         $type = $newtype;
3700     }
3701     $local = "" if $local eq "either"; # no point if it's all undefs
3702     $local &&= join ' ', map $self->keyword($_), split / /, $local;
3703     $local .= " $type " if $local && length $type;
3704     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
3705     for (; !null($kid); $kid = $kid->sibling) {
3706         if ($local) {
3707             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
3708                 $lop = $kid->first;
3709             } else {
3710                 $lop = $kid;
3711             }
3712             $self->{'avoid_local'}{$$lop}++;
3713             $expr = $self->deparse($kid, 6);
3714             delete $self->{'avoid_local'}{$$lop};
3715         } else {
3716             $expr = $self->deparse($kid, 6);
3717         }
3718         push @exprs, $expr;
3719     }
3720     if ($local) {
3721         return "$local(" . join(", ", @exprs) . ")";
3722     } else {
3723         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
3724     }
3725 }
3726
3727 sub is_ifelse_cont {
3728     my $op = shift;
3729     return ($op->name eq "null" and class($op) eq "UNOP"
3730             and $op->first->name =~ /^(and|cond_expr)$/
3731             and is_scope($op->first->first->sibling));
3732 }
3733
3734 sub pp_cond_expr {
3735     my $self = shift;
3736     my($op, $cx) = @_;
3737     my $cond = $op->first;
3738     my $true = $cond->sibling;
3739     my $false = $true->sibling;
3740     my $cuddle = $self->{'cuddle'};
3741     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
3742             (is_scope($false) || is_ifelse_cont($false))
3743             and $self->{'expand'} < 7) {
3744         $cond = $self->deparse($cond, 8);
3745         $true = $self->deparse($true, 6);
3746         $false = $self->deparse($false, 8);
3747         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
3748     }
3749
3750     $cond = $self->deparse($cond, 1);
3751     $true = $self->deparse($true, 0);
3752     my $head = $self->keyword("if") . " ($cond) {\n\t$true\n\b}";
3753     my @elsifs;
3754     my $elsif;
3755     while (!null($false) and is_ifelse_cont($false)) {
3756         my $newop = $false->first;
3757         my $newcond = $newop->first;
3758         my $newtrue = $newcond->sibling;
3759         $false = $newtrue->sibling; # last in chain is OP_AND => no else
3760         if ($newcond->name eq "lineseq")
3761         {
3762             # lineseq to ensure correct line numbers in elsif()
3763             # Bug #37302 fixed by change #33710.
3764             $newcond = $newcond->first->sibling;
3765         }
3766         $newcond = $self->deparse($newcond, 1);
3767         $newtrue = $self->deparse($newtrue, 0);
3768         $elsif ||= $self->keyword("elsif");
3769         push @elsifs, "$elsif ($newcond) {\n\t$newtrue\n\b}";
3770     }
3771     if (!null($false)) {
3772         $false = $cuddle . $self->keyword("else") . " {\n\t" .
3773           $self->deparse($false, 0) . "\n\b}\cK";
3774     } else {
3775         $false = "\cK";
3776     }
3777     return $head . join($cuddle, "", @elsifs) . $false;
3778 }
3779
3780 sub pp_once {
3781     my ($self, $op, $cx) = @_;
3782     my $cond = $op->first;
3783     my $true = $cond->sibling;
3784
3785     my $ret = $self->deparse($true, $cx);
3786     $ret =~ s/^(\(?)\$/$1 . $self->keyword("state") . ' $'/e;
3787     $ret;
3788 }
3789
3790 sub loop_common {
3791     my $self = shift;
3792     my($op, $cx, $init) = @_;
3793     my $enter = $op->first;
3794     my $kid = $enter->sibling;
3795     local(@$self{qw'curstash warnings hints hinthash'})
3796                 = @$self{qw'curstash warnings hints hinthash'};
3797     my $head = "";
3798     my $bare = 0;
3799     my $body;
3800     my $cond = undef;
3801     my $name;
3802     if ($kid->name eq "lineseq") { # bare or infinite loop
3803         if ($kid->last->name eq "unstack") { # infinite
3804             $head = "while (1) "; # Can't use for(;;) if there's a continue
3805             $cond = "";
3806         } else {
3807             $bare = 1;
3808         }
3809         $body = $kid;
3810     } elsif ($enter->name eq "enteriter") { # foreach
3811         my $ary = $enter->first->sibling; # first was pushmark
3812         my $var = $ary->sibling;
3813         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
3814             # "reverse" was optimised away
3815             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
3816         } elsif ($enter->flags & OPf_STACKED
3817             and not null $ary->first->sibling->sibling)
3818         {
3819             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
3820               $self->deparse($ary->first->sibling->sibling, 9);
3821         } else {
3822             $ary = $self->deparse($ary, 1);
3823         }
3824         if (null $var) {
3825             $var = $self->pp_padsv($enter, 1, 1);
3826         } elsif ($var->name eq "rv2gv") {
3827             $var = $self->pp_rv2sv($var, 1);
3828             if ($enter->private & OPpOUR_INTRO) {
3829                 # our declarations don't have package names
3830                 $var =~ s/^(.).*::/$1/;
3831                 $var = "our $var";
3832             }
3833         } elsif ($var->name eq "gv") {
3834             $var = "\$" . $self->deparse($var, 1);
3835         } else {
3836             $var = $self->deparse($var, 1);
3837         }
3838         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
3839         if (!is_state $body->first and $body->first->name !~ /^(?:stub|leave|scope)$/) {
3840             confess unless $var eq '$_';
3841             $body = $body->first;
3842             return $self->deparse($body, 2) . " "
3843                  . $self->keyword("foreach") . " ($ary)";
3844         }
3845         $head = "foreach $var ($ary) ";
3846     } elsif ($kid->name eq "null") { # while/until
3847         $kid = $kid->first;
3848         $name = {"and" => "while", "or" => "until"}->{$kid->name};
3849         $cond = $kid->first;
3850         $body = $kid->first->sibling;
3851     } elsif ($kid->name eq "stub") { # bare and empty
3852         return "{;}"; # {} could be a hashref
3853     }
3854     # If there isn't a continue block, then the next pointer for the loop
3855     # will point to the unstack, which is kid's last child, except
3856     # in a bare loop, when it will point to the leaveloop. When neither of
3857     # these conditions hold, then the second-to-last child is the continue
3858     # block (or the last in a bare loop).
3859     my $cont_start = $enter->nextop;
3860     my $cont;
3861     my $precond;
3862     my $postcond;
3863     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
3864         if ($bare) {
3865             $cont = $body->last;
3866         } else {
3867             $cont = $body->first;
3868             while (!null($cont->sibling->sibling)) {
3869                 $cont = $cont->sibling;
3870             }
3871         }
3872         my $state = $body->first;
3873         my $cuddle = $self->{'cuddle'};
3874         my @states;
3875         for (; $$state != $$cont; $state = $state->sibling) {
3876             push @states, $state;
3877         }
3878         $body = $self->lineseq(undef, 0, @states);
3879         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
3880             $precond = "for ($init; ";
3881             $postcond = "; " . $self->deparse($cont, 1) .") ";
3882             $cont = "\cK";
3883         } else {
3884             $cont = $cuddle . "continue {\n\t" .
3885               $self->deparse($cont, 0) . "\n\b}\cK";
3886         }
3887     } else {
3888         return "" if !defined $body;
3889         if (length $init) {
3890             $precond = "for ($init; ";
3891             $postcond = ";) ";
3892         }
3893         $cont = "\cK";
3894         $body = $self->deparse($body, 0);
3895     }
3896     if ($precond) { # for(;;)
3897         $cond &&= $name eq 'until'
3898                     ? listop($self, undef, 1, "not", $cond->first)
3899                     : $self->deparse($cond, 1);
3900         $head = "$precond$cond$postcond";
3901     }
3902     if ($name && !$head) {
3903         ref $cond and $cond = $self->deparse($cond, 1);
3904         $head = "$name ($cond) ";
3905     }
3906     $head =~ s/^(for(?:each)?|while|until)/$self->keyword($1)/e;
3907     $body =~ s/;?$/;\n/;
3908
3909     return $head . "{\n\t" . $body . "\b}" . $cont;
3910 }
3911
3912 sub pp_leaveloop { shift->loop_common(@_, "") }
3913
3914 sub for_loop {
3915     my $self = shift;
3916     my($op, $cx) = @_;
3917     my $init = $self->deparse($op, 1);
3918     my $s = $op->sibling;
3919     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
3920     return $self->loop_common($ll, $cx, $init);
3921 }
3922
3923 sub pp_leavetry {
3924     my $self = shift;
3925     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
3926 }
3927
3928 sub _op_is_or_was {
3929   my ($op, $expect_type) = @_;
3930   my $type = $op->type;
3931   return($type == $expect_type
3932          || ($type == OP_NULL && $op->targ == $expect_type));
3933 }
3934
3935 sub pp_null {
3936     my($self, $op, $cx) = @_;
3937
3938     # might be 'my $s :Foo(bar);'
3939     if ($op->targ == OP_LIST) {
3940         my $my_attr = maybe_my_attr($self, $op, $cx);
3941         return $my_attr if defined $my_attr;
3942     }
3943
3944     if (class($op) eq "OP") {
3945         # old value is lost
3946         return $self->{'ex_const'} if $op->targ == OP_CONST;
3947     } elsif (class ($op) eq "COP") {
3948             return &pp_nextstate;
3949     } elsif ($op->first->name eq 'pushmark'
3950              or $op->first->name eq 'null'
3951                 && $op->first->targ == OP_PUSHMARK
3952                 && _op_is_or_was($op, OP_LIST)) {
3953         return $self->pp_list($op, $cx);
3954     } elsif ($op->first->name eq "enter") {
3955         return $self->pp_leave($op, $cx);
3956     } elsif ($op->first->name eq "leave") {
3957         return $self->pp_leave($op->first, $cx);
3958     } elsif ($op->first->name eq "scope") {
3959         return $self->pp_scope($op->first, $cx);
3960     } elsif ($op->targ == OP_STRINGIFY) {
3961         return $self->dquote($op, $cx);
3962     } elsif ($op->targ == OP_GLOB) {
3963         return $self->pp_glob(
3964                  $op->first    # entersub
3965                     ->first    # ex-list
3966                     ->first    # pushmark
3967                     ->sibling, # glob
3968                  $cx
3969                );
3970     } elsif (!null($op->first->sibling) and
3971              $op->first->sibling->name eq "readline" and
3972              $op->first->sibling->flags & OPf_STACKED) {
3973         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
3974                                    . $self->deparse($op->first->sibling, 7),
3975                                    $cx, 7);
3976     } elsif (!null($op->first->sibling) and
3977              $op->first->sibling->name =~ /^transr?\z/ and
3978              $op->first->sibling->flags & OPf_STACKED) {
3979         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
3980                                    . $self->deparse($op->first->sibling, 20),
3981                                    $cx, 20);
3982     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
3983         return ($self->lex_in_scope("&do") ? "CORE::do" : "do")
3984              . " {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
3985     } elsif (!null($op->first->sibling) and
3986              $op->first->sibling->name eq "null" and
3987              class($op->first->sibling) eq "UNOP" and
3988              $op->first->sibling->first->flags & OPf_STACKED and
3989              $op->first->sibling->first->name eq "rcatline") {
3990         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
3991                                    . $self->deparse($op->first->sibling, 18),
3992                                    $cx, 18);
3993     } else {
3994         return $self->deparse($op->first, $cx);
3995     }
3996 }
3997
3998 sub padname {
3999     my $self = shift;
4000     my $targ = shift;
4001     return $self->padname_sv($targ)->PVX;
4002 }
4003
4004 sub padany {
4005     my $self = shift;
4006     my $op = shift;
4007     return substr($self->padname($op->targ), 1); # skip $/@/%
4008 }
4009
4010 sub pp_padsv {
4011     my $self = shift;
4012     my($op, $cx, $forbid_parens) = @_;
4013     my $targ = $op->targ;
4014     return $self->maybe_my($op, $cx, $self->padname($targ),
4015                            $self->padname_sv($targ),
4016                            $forbid_parens);
4017 }
4018
4019 sub pp_padav { pp_padsv(@_) }
4020
4021 sub pp_padhv {
4022     my $op = $_[1];
4023     my $keys = '';
4024     # with OPpPADHV_ISKEYS the keys op is optimised away, except
4025     # in scalar context the old op is kept (but not executed) so its targ
4026     # can be used.
4027     $keys = 'keys ' if (     ($op->private & OPpPADHV_ISKEYS)
4028                             && !(($op->flags & OPf_WANT) == OPf_WANT_SCALAR));
4029     $keys . pp_padsv(@_);
4030 }
4031
4032 sub gv_or_padgv {
4033     my $self = shift;
4034     my $op = shift;
4035     if (class($op) eq "PADOP") {
4036         return $self->padval($op->padix);
4037     } else { # class($op) eq "SVOP"
4038         return $op->gv;
4039     }
4040 }
4041
4042 sub pp_gvsv {
4043     my $self = shift;
4044     my($op, $cx) = @_;
4045     my $gv = $self->gv_or_padgv($op);
4046     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
4047                                  $self->gv_name($gv), $cx));
4048 }
4049
4050 sub pp_gv {
4051     my $self = shift;
4052     my($op, $cx) = @_;
4053     my $gv = $self->gv_or_padgv($op);
4054     return $self->gv_name($gv);
4055 }
4056
4057 sub pp_aelemfast_lex {
4058     my $self = shift;
4059     my($op, $cx) = @_;
4060     my $name = $self->padname($op->targ);
4061     $name =~ s/^@/\$/;
4062     my $i = $op->private;
4063     $i -= 256 if $i > 127;
4064     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
4065 }
4066
4067 sub pp_aelemfast {
4068     my $self = shift;
4069     my($op, $cx) = @_;
4070     # optimised PADAV, pre 5.15
4071     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
4072
4073     my $gv = $self->gv_or_padgv($op);
4074     my($name,$quoted) = $self->stash_variable_name('@',$gv);
4075     $name = $quoted ? "$name->" : '$' . $name;
4076     my $i = $op->private;
4077     $i -= 256 if $i > 127;
4078     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
4079 }
4080
4081 sub rv2x {
4082     my $self = shift;
4083     my($op, $cx, $type) = @_;
4084
4085     if (class($op) eq 'NULL' || !$op->can("first")) {
4086         carp("Unexpected op in pp_rv2x");
4087         return 'XXX';
4088     }
4089     my $kid = $op->first;
4090     if ($kid->name eq "gv") {
4091         return $self->stash_variable($type, $self->deparse($kid, 0), $cx);
4092     } elsif (is_scalar $kid) {
4093         my $str = $self->deparse($kid, 0);
4094         if ($str =~ /^\$([^\w\d])\z/) {
4095             # "$$+" isn't a legal way to write the scalar dereference
4096             # of $+, since the lexer can't tell you aren't trying to
4097             # do something like "$$ + 1" to get one more than your
4098             # PID. Either "${$+}" or "$${+}" are workable
4099             # disambiguations, but if the programmer did the former,
4100             # they'd be in the "else" clause below rather than here.
4101             # It's not clear if this should somehow be unified with
4102             # the code in dq and re_dq that also adds lexer
4103             # disambiguation braces.
4104             $str = '$' . "{$1}"; #'
4105         }
4106         return $type . $str;
4107     } else {
4108         return $type . "{" . $self->deparse($kid, 0) . "}";
4109     }
4110 }
4111
4112 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
4113 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
4114
4115 sub pp_rv2hv {
4116     my $op = $_[1];
4117     (($op->private & OPpRV2HV_ISKEYS) ? 'keys ' : '')
4118         . maybe_local(@_, rv2x(@_, "%"))
4119 }
4120
4121 # skip rv2av
4122 sub pp_av2arylen {
4123     my $self = shift;
4124     my($op, $cx) = @_;
4125     if ($op->first->name eq "padav") {
4126         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
4127     } else {
4128         return $self->maybe_local($op, $cx,
4129                                   $self->rv2x($op->first, $cx, '$#'));
4130     }
4131 }
4132
4133 # skip down to the old, ex-rv2cv
4134 sub pp_rv2cv {
4135     my ($self, $op, $cx) = @_;
4136     if (!null($op->first) && $op->first->name eq 'null' &&
4137         $op->first->targ == OP_LIST)
4138     {
4139         return $self->rv2x($op->first->first->sibling, $cx, "&")
4140     }
4141     else {
4142         return $self->rv2x($op, $cx, "")
4143     }
4144 }
4145
4146 sub list_const {
4147     my $self = shift;
4148     my($cx, @list) = @_;
4149     my @a = map $self->const($_, 6), @list;
4150     if (@a == 0) {
4151         return "()";
4152     } elsif (@a == 1) {
4153         return $a[0];
4154     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
4155         # collapse (-1,0,1,2) into (-1..2)
4156         my ($s, $e) = @a[0,-1];
4157         my $i = $s;
4158         return $self->maybe_parens("$s..$e", $cx, 9)
4159           unless grep $i++ != $_, @a;
4160     }
4161     return $self->maybe_parens(join(", ", @a), $cx, 6);
4162 }
4163
4164 sub pp_rv2av {
4165     my $self = shift;
4166     my($op, $cx) = @_;
4167     my $kid = $op->first;
4168     if ($kid->name eq "const") { # constant list
4169         my $av = $self->const_sv($kid);
4170         return $self->list_const($cx, $av->ARRAY);
4171     } else {
4172         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
4173     }
4174  }
4175
4176 sub is_subscriptable {
4177     my $op = shift;
4178     if ($op->name =~ /^([ahg]elem|multideref$)/) {
4179         return 1;
4180     } elsif ($op->name eq "entersub") {
4181         my $kid = $op->first;
4182         return 0 unless null $kid->sibling;
4183         $kid = $kid->first;
4184         $kid = $kid->sibling until null $kid->sibling;
4185         return 0 if is_scope($kid);
4186         $kid = $kid->first;
4187         return 0 if $kid->name eq "gv" || $kid->name eq "padcv";
4188         return 0 if is_scalar($kid);
4189         return is_subscriptable($kid);  
4190     } else {
4191         return 0;
4192     }
4193 }
4194
4195 sub elem_or_slice_array_name
4196 {
4197     my $self = shift;
4198     my ($array, $left, $padname, $allow_arrow) = @_;
4199
4200     if ($array->name eq $padname) {
4201         return $self->padany($array);
4202     } elsif (is_scope($array)) { # ${expr}[0]
4203         return "{" . $self->deparse($array, 0) . "}";
4204     } elsif ($array->name eq "gv") {
4205         ($array, my $quoted) =
4206             $self->stash_variable_name(
4207                 $left eq '[' ? '@' : '%', $self->gv_or_padgv($array)
4208             );
4209         if (!$allow_arrow && $quoted) {
4210             # This cannot happen.
4211             die "Invalid variable name $array for slice";
4212         }
4213         return $quoted ? "$array->" : $array;
4214     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
4215         return $self->deparse($array, 24);
4216     } else {
4217         return undef;
4218     }
4219 }
4220
4221 sub elem_or_slice_single_index
4222 {
4223     my $self = shift;
4224     my ($idx) = @_;
4225
4226     $idx = $self->deparse($idx, 1);
4227
4228     # Outer parens in an array index will confuse perl
4229     # if we're interpolating in a regular expression, i.e.
4230     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
4231     #
4232     # If $self->{parens}, then an initial '(' will
4233     # definitely be paired with a final ')'. If
4234     # !$self->{parens}, the misleading parens won't
4235     # have been added in the first place.
4236     #
4237     # [You might think that we could get "(...)...(...)"
4238     # where the initial and final parens do not match
4239     # each other. But we can't, because the above would
4240     # only happen if there's an infix binop between the
4241     # two pairs of parens, and *that* means that the whole
4242     # expression would be parenthesized as well.]
4243     #
4244     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
4245
4246     # Hash-element braces will autoquote a bareword inside themselves.
4247     # We need to make sure that C<$hash{warn()}> doesn't come out as
4248     # C<$hash{warn}>, which has a quite different meaning. Currently
4249     # B::Deparse will always quote strings, even if the string was a
4250     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
4251     # for constant strings.) So we can cheat slightly here - if we see
4252     # a bareword, we know that it is supposed to be a function call.
4253     #
4254     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
4255
4256     return $idx;
4257 }
4258
4259 sub elem {
4260     my $self = shift;
4261     my ($op, $cx, $left, $right, $padname) = @_;
4262     my($array, $idx) = ($op->first, $op->first->sibling);
4263
4264     $idx = $self->elem_or_slice_single_index($idx);
4265
4266     unless ($array->name eq $padname) { # Maybe this has been fixed     
4267         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
4268     }
4269     if (my $array_name=$self->elem_or_slice_array_name
4270             ($array, $left, $padname, 1)) {
4271         return ($array_name =~ /->\z/
4272                     ? $array_name
4273                     : $array_name eq '#' ? '${#}' : "\$" . $array_name)
4274               . $left . $idx . $right;
4275     } else {
4276         # $x[20][3]{hi} or expr->[20]
4277         my $arrow = is_subscriptable($array) ? "" : "->";
4278         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
4279     }
4280
4281 }
4282
4283 # a simplified version of elem_or_slice_array_name()
4284 # for the use of pp_multideref
4285
4286 sub multideref_var_name {
4287     my $self = shift;
4288     my ($gv, $is_hash) = @_;
4289
4290     my ($name, $quoted) =
4291         $self->stash_variable_name( $is_hash  ? '%' : '@', $gv);
4292     return $quoted ? "$name->"
4293                    : $name eq '#'
4294                         ? '${#}'       # avoid ${#}[1] => $#[1]
4295                         : '$' . $name;
4296 }
4297
4298
4299 # deparse an OP_MULTICONCAT. If $in_dq is 1, we're within
4300 # a double-quoted string, so for example.
4301 #     "abc\Qdef$x\Ebar"
4302 # might get compiled as
4303 #    multiconcat("abc", metaquote(multiconcat("def", $x)), "bar")
4304 # and the inner multiconcat should be deparsed as C<def$x> rather than
4305 # the normal C<def . $x>
4306 # Ditto if  $in_dq is 2, handle qr/...\Qdef$x\E.../.
4307
4308 sub do_multiconcat {
4309     my $self = shift;
4310     my($op, $cx, $in_dq) = @_;
4311
4312     my $kid;
4313     my @kids;
4314     my $assign;
4315     my $append;
4316     my $lhs = "";
4317
4318     for ($kid = $op->first; !null $kid; $kid = $kid->sibling) {
4319         # skip the consts and/or padsv we've optimised away
4320         push @kids, $kid
4321             unless $kid->type == OP_NULL
4322               && (   $kid->targ == OP_PADSV
4323                   || $kid->targ == OP_CONST
4324                   || $kid->targ == OP_PUSHMARK);
4325     }
4326
4327     $append = ($op->private & OPpMULTICONCAT_APPEND);
4328
4329     if ($op->private & OPpTARGET_MY) {
4330         # '$lex  = ...' or '$lex .= ....' or 'my $lex = '
4331         $lhs = $self->padname($op->targ);
4332         $lhs = "my $lhs" if ($op->private & OPpLVAL_INTRO);
4333         $assign = 1;
4334     }
4335     elsif ($op->flags & OPf_STACKED) {
4336         # 'expr  = ...' or 'expr .= ....'
4337         my $expr = $append ? shift(@kids) : pop(@kids);
4338         $lhs = $self->deparse($expr, 7);
4339         $assign = 1;
4340     }
4341
4342     if ($assign) {
4343         $lhs .=  $append ? ' .= ' : ' = ';
4344     }
4345
4346     my ($nargs, $const_str, @const_lens) = $op->aux_list($self->{curcv});
4347
4348     my @consts;
4349     my $i = 0;
4350     for (@const_lens) {
4351         if ($_ == -1) {
4352             push @consts, undef;
4353         }
4354         else {
4355             push @consts, substr($const_str, $i, $_);
4356         my @args;
4357             $i += $_;
4358         }
4359     }
4360
4361     my $rhs = "";
4362
4363     if (   $in_dq
4364         || (($op->private & OPpMULTICONCAT_STRINGIFY) && !$self->{'unquote'}))
4365     {
4366         # "foo=$foo bar=$bar "
4367         my $not_first;
4368         while (@consts) {
4369             $rhs = dq_disambiguate($rhs, $self->dq(shift(@kids), 18))
4370                 if $not_first;
4371             $not_first = 1;
4372             my $c = shift @consts;
4373             if (defined $c) {
4374                 if ($in_dq == 2) {
4375                     # in pattern: don't convert newline to '\n' etc etc
4376                     my $s = re_uninterp(escape_re(re_unback($c)));
4377                     $rhs = re_dq_disambiguate($rhs, $s)
4378                 }
4379                 else {
4380                     my $s = uninterp(escape_str(unback($c)));
4381                     $rhs = dq_disambiguate($rhs, $s)
4382                 }
4383             }
4384         }
4385         return $rhs if $in_dq;
4386         $rhs = single_delim("qq", '"', $rhs, $self);
4387     }
4388     elsif ($op->private & OPpMULTICONCAT_FAKE) {
4389         # sprintf("foo=%s bar=%s ", $foo, $bar)
4390
4391         my @all;
4392         @consts = map { $_ //= ''; s/%/%%/g; $_ } @consts;
4393         my $fmt = join '%s', @consts;
4394         push @all, $self->quoted_const_str($fmt);
4395
4396         # the following is a stripped down copy of sub listop {}
4397         my $parens = $assign || ($cx >= 5) || $self->{'parens'};
4398         my $fullname = $self->keyword('sprintf');
4399         push @all, map $self->deparse($_, 6), @kids;
4400
4401         $rhs = $parens
4402                 ? "$fullname(" . join(", ", @all) . ")"
4403                 : "$fullname " . join(", ", @all);
4404     }
4405     else {
4406         # "foo=" . $foo . " bar=" . $bar
4407         my @all;
4408         my $not_first;
4409         while (@consts) {
4410             push @all, $self->deparse(shift(@kids), 18) if $not_first;
4411             $not_first = 1;
4412             my $c = shift @consts;
4413             if (defined $c) {
4414                 push @all, $self->quoted_const_str($c);
4415             }
4416         }
4417         $rhs .= join ' . ', @all;
4418     }
4419
4420     my $text = $lhs . $rhs;
4421
4422     $text = "($text)" if     ($cx >= (($assign) ? 7 : 18+1))
4423                           || $self->{'parens'};
4424
4425     return $text;
4426 }
4427
4428
4429 sub pp_multiconcat {
4430     my $self = shift;
4431     $self->do_multiconcat(@_, 0);
4432 }
4433
4434
4435 sub pp_multideref {
4436     my $self = shift;
4437     my($op, $cx) = @_;
4438     my $text = "";
4439
4440     if ($op->private & OPpMULTIDEREF_EXISTS) {
4441         $text = $self->keyword("exists"). " ";
4442     }
4443     elsif ($op->private & OPpMULTIDEREF_DELETE) {
4444         $text = $self->keyword("delete"). " ";
4445     }
4446     elsif ($op->private & OPpLVAL_INTRO) {
4447         $text = $self->keyword("local"). " ";
4448     }
4449
4450     if ($op->first && ($op->first->flags & OPf_KIDS)) {
4451         # arbitrary initial expression, e.g. f(1,2,3)->[...]
4452         my $expr = $self->deparse($op->first, 24);
4453         # stop "exists (expr)->{...}" being interpreted as
4454         #"(exists (expr))->{...}"
4455         $expr = "+$expr" if $expr =~ /^\(/;
4456         $text .=  $expr;
4457     }
4458
4459     my @items = $op->aux_list($self->{curcv});
4460     my $actions = shift @items;
4461
4462     my $is_hash;
4463     my $derefs = 0;
4464
4465     while (1) {
4466         if (($actions & MDEREF_ACTION_MASK) == MDEREF_reload) {
4467             $actions = shift @items;
4468             next;
4469         }
4470
4471         $is_hash = (
4472            ($actions & MDEREF_ACTION_MASK) == MDEREF_HV_pop_rv2hv_helem
4473         || ($actions & MDEREF_ACTION_MASK) == MDEREF_HV_gvsv_vivify_rv2hv_helem
4474         || ($actions & MDEREF_ACTION_MASK) == MDEREF_HV_padsv_vivify_rv2hv_helem
4475         || ($actions & MDEREF_ACTION_MASK) == MDEREF_HV_vivify_rv2hv_helem
4476         || ($actions & MDEREF_ACTION_MASK) == MDEREF_HV_padhv_helem
4477         || ($actions & MDEREF_ACTION_MASK) == MDEREF_HV_gvhv_helem
4478         );
4479
4480         if (   ($actions & MDEREF_ACTION_MASK) == MDEREF_AV_padav_aelem
4481             || ($actions & MDEREF_ACTION_MASK) == MDEREF_HV_padhv_helem)
4482         {
4483             $derefs = 1;
4484         &nbs