Porting/corelist.pl

   1 #!perl
   2 # Generates info for Module::CoreList from this perl tree
   3 # run this from the root of a perl tree
   4 #
   5 # Data is on STDOUT.
   6 #
   7 # With an optional arg specifying the root of a CPAN mirror, outputs the
   8 # %upstream and %bug_tracker hashes too.
   9
  10 use autodie;
  11 use strict;
  12 use warnings;
  13 no  warnings 'experimental::autoderef';
  14 use File::Find;
  15 use ExtUtils::MM_Unix;
  16 use version;
  17 use lib "Porting";
  18 use Maintainers qw(%Modules files_to_modules);
  19 use File::Spec;
  20 use Parse::CPAN::Meta;
  21 use IPC::Cmd 'can_run';
  22 use HTTP::Tiny;
  23 use IO::Uncompress::Gunzip;
  24
  25 my $corelist_file = 'dist/Module-CoreList/lib/Module/CoreList.pm';
  26 my $utils_file = 'dist/Module-CoreList/lib/Module/CoreList/Utils.pm';
  27
  28 my %lines;
  29 my %module_to_file;
  30 my %modlist;
  31
  32 die "usage: $0 [ cpan-mirror/ ] [ 5.x.y] \n" unless @ARGV <= 2;
  33 my $cpan         = shift;
  34 my $raw_version  = shift || $];
  35 my $perl_version = version->parse("$raw_version");
  36 my $perl_vnum    = $perl_version->numify;
  37 my $perl_vstring = $perl_version->normal; # how do we get version.pm to not give us leading v?
  38 $perl_vstring =~ s/^v//;
  39
  40 if ( !-f 'MANIFEST' ) {
  41     die "Must be run from the root of a clean perl tree\n";
  42 }
  43
  44 open( my $corelist_fh, '<', $corelist_file );
  45 my $corelist = join( '', <$corelist_fh> );
  46 close $corelist_fh;
  47
  48 unless (
  49     $corelist =~ /^%released \s* = \s* \(
  50         .*?
  51         $perl_vnum \s* => \s* .*?
  52         \);/ismx
  53     )
  54 {
  55     warn "Adding $perl_vnum to the list of released perl versions. Please consider adding a release date.\n";
  56     $corelist =~ s/^(%released \s* = \s* .*?) ( \) )
  57                 /$1  $perl_vnum => '????-??-??',\n  $2/ismx;
  58 }
  59
  60 if ($cpan) {
  61     my $modlistfile = File::Spec->catfile( $cpan, 'modules', '02packages.details.txt' );
  62     my $content;
  63
  64     my $fh;
  65     if ( -e $modlistfile ) {
  66         warn "Reading the module list from $modlistfile";
  67         open $fh, '<', $modlistfile;
  68     } elsif ( -e $modlistfile . ".gz" ) {
  69         my $zcat = can_run('gzcat') || can_run('zcat') or die "Can't find gzcat or zcat";
  70         warn "Reading the module list from $modlistfile.gz";
  71         open $fh, '-|', "$zcat $modlistfile.gz";
  72     } else {
  73         warn "About to fetch 02packages from ftp.funet.fi. This may take a few minutes\n";
  74         my $gzipped_content = fetch_url('http://ftp.funet.fi/pub/CPAN/modules/02packages.details.txt.gz');
  75         unless ($gzipped_content) {
  76             die "Unable to read 02packages.details.txt from either your CPAN mirror or ftp.funet.fi";
  77         }
  78         IO::Uncompress::Gunzip::gunzip(\$gzipped_content, \$content, Transparent => 0)
  79             or die "Can't gunzip content: $IO::Uncompress::Gunzip::GunzipError";
  80     }
  81
  82     if ( $fh and !$content ) {
  83         local $/ = "\n";
  84         $content = join( '', <$fh> );
  85     }
  86
  87     die "Incompatible modlist format"
  88         unless $content =~ /^Columns: +package name, version, path/m;
  89
  90     # Converting the file to a hash is about 5 times faster than a regexp flat
  91     # lookup.
  92     for ( split( qr/\n/, $content ) ) {
  93         next unless /^([A-Za-z_:0-9]+) +[-0-9.undefHASHVERSIONvsetwhenloadingbogus]+ +(\S+)/;
  94         $modlist{$1} = $2;
  95     }
  96 }
  97
  98 find(
  99     sub {
 100         /(\.pm|_pm\.PL)$/ or return;
 101         /PPPort\.pm$/ and return;
 102         my $module = $File::Find::name;
 103         $module =~ /\b(demo|t|private)\b/ and return;    # demo or test modules
 104         my $version = MM->parse_version($_);
 105         defined $version or $version = 'undef';
 106         $version =~ /\d/ and $version = "'$version'";
 107
 108         # some heuristics to figure out the module name from the file name
 109         $module =~ s{^(lib|cpan|dist|(?:symbian/)?ext|os2/OS2)/}{}
 110                         and $1 ne 'lib'
 111             and (
 112             $module =~ s{\b(\w+)/\1\b}{$1},
 113             $module =~ s{^B/O}{O},
 114             $module =~ s{^Devel-PPPort}{Devel},
 115             $module =~ s{^libnet/}{},
 116             $module =~ s{^PathTools/}{},
 117             $module =~ s{REXX/DLL}{DLL},
 118             $module =~ s{^Encode/encoding}{encoding},
 119             $module =~ s{^IPC-SysV/}{IPC/},
 120             $module =~ s{^MIME-Base64/QuotedPrint}{MIME/QuotedPrint},
 121             $module =~ s{^(?:DynaLoader|Errno|Opcode|XSLoader)/}{},
 122             $module =~ s{^Sys-Syslog/win32}{Sys-Syslog},
 123             $module =~ s{^Time-Piece/Seconds}{Time/Seconds},
 124             );
 125                 $module =~ s{^lib/}{}g;
 126         $module =~ s{/}{::}g;
 127         $module =~ s{-}{::}g;
 128                 $module =~ s{^.*::lib::}{}; # turns Foo/lib/Foo.pm into Foo.pm
 129         $module =~ s/(\.pm|_pm\.PL)$//;
 130         $lines{$module}          = $version;
 131         $module_to_file{$module} = $File::Find::name;
 132     },
 133     'os2/OS2',
 134     'symbian/ext',
 135     'lib',
 136     'ext',
 137         'cpan',
 138         'dist'
 139 );
 140
 141 -e 'configpm' and $lines{Config} = "$]";
 142
 143 if ( open my $ucdv, "<", "lib/unicore/version" ) {
 144     chomp( my $ucd = <$ucdv> );
 145     $lines{Unicode} = "'$ucd'";
 146     close $ucdv;
 147 }
 148
 149 my $delta_data = make_corelist_delta(
 150   $perl_vnum,
 151   \%lines,
 152   \%Module::CoreList::version
 153 );
 154
 155 my $versions_in_release = "    " . $perl_vnum . " => {\n";
 156 $versions_in_release .= "        delta_from => $delta_data->{delta_from},\n";
 157 $versions_in_release .= "        changed => {\n";
 158 foreach my $key (sort keys $delta_data->{changed}) {
 159   $versions_in_release .= sprintf "            %-24s=> %s,\n", "'$key'",
 160       defined $delta_data->{changed}{$key} ? "'"
 161         . $delta_data->{changed}{$key} . "'" : "undef";
 162 }
 163 $versions_in_release .= "        },\n";
 164 $versions_in_release .= "        removed => {\n";
 165 for my $key (sort keys($delta_data->{removed} || {})) {
 166   $versions_in_release .= sprintf "            %-24s=> %s,\n", "'$key'", 1;
 167 }
 168 $versions_in_release .= "        }\n";
 169 $versions_in_release .= "    },\n";
 170
 171 $corelist =~ s/^(%delta\s*=\s*.*?)^\s*$perl_vnum\s*=>\s*{.*?},\s*(^\);)$/$1$2/ism;
 172 $corelist =~ s/^(%delta\s*=\s*.*?)(^\);)$/$1$versions_in_release$2/ism;
 173
 174 exit unless %modlist;
 175
 176 # We have to go through this two stage lookup, given how Maintainers.pl keys its
 177 # data by "Module", which is really a dist.
 178 my $file_to_M = files_to_modules( values %module_to_file );
 179
 180 sub slurp_utf8($) {
 181     open my $fh, "<:utf8", "$_[0]"
 182         or die "can't open $_[0] for reading: $!";
 183     return do { local $/; <$fh> };
 184 }
 185
 186 sub parse_cpan_meta($) {
 187     return Parse::CPAN::Meta->${
 188         $_[0] =~ /\A\x7b/ ? \"load_json_string" : \"load_yaml_string"
 189     }($_[0]);
 190 }
 191
 192 my %module_to_upstream;
 193 my %module_to_dist;
 194 my %dist_to_meta_YAML;
 195 my %module_to_deprecated;
 196 while ( my ( $module, $file ) = each %module_to_file ) {
 197     my $M = $file_to_M->{$file};
 198     next unless $M;
 199     next if $Modules{$M}{MAINTAINER} && $Modules{$M}{MAINTAINER} eq 'P5P';
 200     $module_to_upstream{$module} = $Modules{$M}{UPSTREAM};
 201     $module_to_deprecated{$module} = 1 if $Modules{$M}{DEPRECATED};
 202     next
 203         if defined $module_to_upstream{$module}
 204             && $module_to_upstream{$module} eq 'blead';
 205     my $dist = $modlist{$module};
 206     unless ($dist) {
 207         warn "Can't find a distribution for $module\n";
 208         next;
 209     }
 210     $module_to_dist{$module} = $dist;
 211
 212     next if exists $dist_to_meta_YAML{$dist};
 213
 214     $dist_to_meta_YAML{$dist} = undef;
 215
 216     # Like it or lump it, this has to be Unix format.
 217     my $meta_YAML_path = "authors/id/$dist";
 218     $meta_YAML_path =~ s/(?:tar\.gz|tar\.bz2|zip|tgz)$/meta/
 219         or die "ERROR: bad meta YAML path: '$meta_YAML_path'";
 220     my $meta_YAML_url = 'http://ftp.funet.fi/pub/CPAN/' . $meta_YAML_path;
 221
 222     if ( -e "$cpan/$meta_YAML_path" ) {
 223         $dist_to_meta_YAML{$dist} = parse_cpan_meta(slurp_utf8( $cpan . "/" . $meta_YAML_path ));
 224     } elsif ( my $content = fetch_url($meta_YAML_url) ) {
 225         unless ($content) {
 226             warn "Failed to fetch $meta_YAML_url\n";
 227             next;
 228         }
 229         eval { $dist_to_meta_YAML{$dist} = parse_cpan_meta($content); };
 230         if ( my $err = $@ ) {
 231             warn "$meta_YAML_path: ".$err;
 232             next;
 233         }
 234     } else {
 235         warn "$meta_YAML_path does not exist for $module\n";
 236
 237         # I tried code to open the tarballs with Archive::Tar to find and
 238         # extract META.yml, but only Text-Tabs+Wrap-2006.1117.tar.gz had one,
 239         # so it's not worth including.
 240         next;
 241     }
 242 }
 243
 244 my $upstream_stanza = "%upstream = (\n";
 245 foreach my $module ( sort keys %module_to_upstream ) {
 246     my $upstream = defined $module_to_upstream{$module} ? "'$module_to_upstream{$module}'" : 'undef';
 247     $upstream_stanza .= sprintf "    %-24s=> %s,\n", "'$module'", $upstream;
 248 }
 249 $upstream_stanza .= ");";
 250
 251 $corelist =~ s/^%upstream .*? ;$/$upstream_stanza/ismx;
 252
 253 # Deprecation generation
 254 {
 255   my $delta_data = make_corelist_delta(
 256     $perl_vnum,
 257     \%module_to_deprecated,
 258     do { no warnings 'once'; \%Module::CoreList::deprecated },
 259   );
 260
 261   my $deprecated_stanza = "    " . $perl_vnum . " => {\n";
 262   $deprecated_stanza .= "        delta_from => $delta_data->{delta_from},\n";
 263   $deprecated_stanza .= "        changed => {\n";
 264   foreach my $key (sort keys $delta_data->{changed}) {
 265     $deprecated_stanza .= sprintf "            %-24s=> %s,\n", "'$key'",
 266         defined $delta_data->{changed}{$key} ? "'"
 267           . $delta_data->{changed}{$key} . "'" : "undef";
 268   }
 269   $deprecated_stanza .= "        },\n";
 270   $deprecated_stanza .= "        removed => {\n";
 271   for my $key (sort keys($delta_data->{removed} || {})) {
 272     $deprecated_stanza .= sprintf "           %-24s=> %s,\n", "'$key'", 1;
 273   }
 274   $deprecated_stanza .= "        }\n";
 275   $deprecated_stanza .= "    },\n";
 276
 277   $corelist =~ s/^(%deprecated\s*=\s*.*?)^\s*$perl_vnum\s*=>\s*{.*?},\s*(^\);)$/$1$2/ism;
 278   $corelist =~ s/^(%deprecated\s*=\s*.*?)(^\);)$/$1$deprecated_stanza$2/xism;
 279 }
 280
 281 my $tracker = "%bug_tracker = (\n";
 282 foreach my $module ( sort keys %module_to_upstream ) {
 283     my $upstream = defined $module_to_upstream{$module};
 284     next
 285         if defined $upstream and $upstream eq 'blead';
 286
 287     my $bug_tracker;
 288
 289     my $dist = $module_to_dist{$module};
 290     $bug_tracker = $dist_to_meta_YAML{$dist}->{resources}{bugtracker}
 291         if $dist;
 292     $bug_tracker = $bug_tracker->{web} if ref($bug_tracker) eq "HASH";
 293
 294     $bug_tracker = defined $bug_tracker ? quote($bug_tracker) : 'undef';
 295         next if $bug_tracker eq "'http://rt.perl.org/perlbug/'";
 296     $tracker .= sprintf "    %-24s=> %s,\n", "'$module'", $bug_tracker;
 297 }
 298 $tracker .= ");";
 299
 300 $corelist =~ s/^%bug_tracker .*? ;/$tracker/eismx;
 301
 302 write_corelist($corelist,$corelist_file);
 303
 304 open( my $utils_fh, '<', $utils_file );
 305 my $utils = join( '', <$utils_fh> );
 306 close $utils_fh;
 307
 308 my %utils = map { ( $_ => 1 ) } parse_utils_lst();
 309
 310 my $delta_utils = make_coreutils_delta($perl_vnum, \%utils);
 311
 312 my $utilities_in_release = "    " . $perl_vnum . " => {\n";
 313 $utilities_in_release .= "        delta_from => $delta_utils->{delta_from},\n";
 314 $utilities_in_release .= "        changed => {\n";
 315 foreach my $key (sort keys $delta_utils->{changed}) {
 316   $utilities_in_release .= sprintf "            %-24s=> %s,\n", "'$key'",
 317       defined $delta_utils->{changed}{$key} ? "'"
 318         . $delta_utils->{changed}{$key} . "'" : "undef";
 319 }
 320 $utilities_in_release .= "        },\n";
 321 $utilities_in_release .= "        removed => {\n";
 322 for my $key (sort keys($delta_utils->{removed} || {})) {
 323   $utilities_in_release .= sprintf "            %-24s=> %s,\n", "'$key'", 1;
 324 }
 325 $utilities_in_release .= "        }\n";
 326 $utilities_in_release .= "    },\n";
 327
 328 $utils =~ s/^(my %delta\s*=\s*.*?)^\s*$perl_vnum\s*=>\s*{.*?},\s*(^\);)$/$1$2/ism;
 329 $utils =~ s/^(my %delta\s*=\s*.*?)(^\);)$/$1$utilities_in_release$2/ism;
 330
 331 write_corelist($utils,$utils_file);
 332
 333 warn "All done. Please check over the following files carefully before committing.\nThanks!\n";
 334 warn "$corelist_file\n$utils_file\n";
 335
 336 sub write_corelist {
 337     my $content = shift;
 338     my $filename = shift;
 339     open (my $clfh, ">", $filename);
 340     binmode $clfh;
 341     print $clfh $content;
 342     close($clfh);
 343 }
 344
 345 sub fetch_url {
 346     my $url = shift;
 347     my $http = HTTP::Tiny->new;
 348     my $response = $http->get($url);
 349     if ($response->{success}) {
 350         return $response->{content};
 351     } else {
 352         warn "Error fetching $url: $response->{status} $response->{reason}\n";
 353         return;
 354     }
 355 }
 356
 357 sub make_corelist_delta {
 358   my($version, $lines, $existing) = @_;
 359   # Trust core perl, if someone does use a weird version number the worst that
 360   # can happen is an extra delta entry for a module.
 361   my %versions = map { $_ => eval $lines->{$_} } keys %$lines;
 362
 363   # Ensure we have the corelist data loaded from this perl checkout, not the system one.
 364   require $corelist_file;
 365
 366   my %deltas;
 367   # Search for the release with the least amount of changes (this avoids having
 368   # to ask for where this perl was branched from).
 369   for my $previous (reverse sort { $a <=> $b } keys %$existing) {
 370     # Shouldn't happen, but ensure we don't load weird data...
 371     next if $previous > $version || $previous == $version;
 372     my $delta = $deltas{$previous} = {};
 373     ($delta->{changed}, $delta->{removed}) = calculate_delta(
 374       $existing->{$previous}, \%versions);
 375   }
 376
 377   my $smallest = (sort {
 378       ((keys($deltas{$a}->{changed}) + keys($deltas{$a}->{removed})) <=>
 379        (keys($deltas{$b}->{changed}) + keys($deltas{$b}->{removed}))) ||
 380       $b <=> $a
 381     } keys %deltas)[0];
 382
 383   return {
 384     delta_from => $smallest,
 385     changed => $deltas{$smallest}{changed},
 386     removed => $deltas{$smallest}{removed},
 387   }
 388 }
 389
 390 sub make_coreutils_delta {
 391   my($version, $lines) = @_;
 392   # Trust core perl, if someone does use a weird version number the worst that
 393   # can happen is an extra delta entry for a module.
 394   my %utilities = map { $_ => eval $lines->{$_} } keys %$lines;
 395
 396   # Ensure we have the corelist data loaded from this perl checkout, not the system one.
 397   require $utils_file;
 398
 399   my %deltas;
 400   # Search for the release with the least amount of changes (this avoids having
 401   # to ask for where this perl was branched from).
 402   for my $previous (reverse sort { $a <=> $b } keys %Module::CoreList::Utils::utilities) {
 403     # Shouldn't happen, but ensure we don't load weird data...
 404     next if $previous > $version || $previous == $version;
 405
 406     my $delta = $deltas{$previous} = {};
 407     ($delta->{changed}, $delta->{removed}) = calculate_delta(
 408       $Module::CoreList::Utils::utilities{$previous}, \%utilities);
 409   }
 410
 411   my $smallest = (sort {
 412       ((keys($deltas{$a}->{changed}) + keys($deltas{$a}->{removed})) <=>
 413        (keys($deltas{$b}->{changed}) + keys($deltas{$b}->{removed}))) ||
 414       $b <=> $a
 415     } keys %deltas)[0];
 416
 417   return {
 418     delta_from => $smallest,
 419     changed => $deltas{$smallest}{changed},
 420     removed => $deltas{$smallest}{removed},
 421   }
 422 }
 423
 424 # Calculate (changed, removed) modules between two versions.
 425 sub calculate_delta {
 426   my($from, $to) = @_;
 427   my(%changed, %removed);
 428
 429   for my $package(keys $from) {
 430     if(not exists $to->{$package}) {
 431       $removed{$package} = 1;
 432     }
 433   }
 434
 435   for my $package(keys $to) {
 436     if(!exists $from->{$package}
 437         || (defined $from->{$package} && !defined $to->{$package})
 438         || (!defined $from->{$package} && defined $to->{$package})
 439         || (defined $from->{$package} && defined $to->{$package}
 440             && $from->{$package} ne $to->{$package})) {
 441       $changed{$package} = $to->{$package};
 442     }
 443   }
 444
 445   return \%changed, \%removed;
 446 }
 447
 448 sub quote {
 449     my ($str) = @_;
 450     # There's gotta be something already doing this properly that we could just
 451     # reuse, but I can't quite thing of where to look for it, so I'm gonna do
 452     # the simplest possible thing that'll allow me to release 5.17.7.  --rafl
 453     $str =~ s/'/\\'/g;
 454     "'${str}'";
 455 }
 456
 457 sub parse_utils_lst {
 458   require File::Spec::Unix;
 459   my @scripts;
 460   open my $fh, '<', 'utils.lst' or die "$!\n";
 461   while (<$fh>) {
 462     chomp;
 463     my ($file,$extra) = split m!#!;
 464     $file =~ s!\s+!!g;
 465     push @scripts, $file;
 466     $extra =~ s!\s+!!g if $extra;
 467     if ( $extra and my ($link) = $extra =~ m!^link=(.+?)$! ) {
 468       push @scripts, $link;
 469     }
 470   }
 471   return map { +( File::Spec::Unix->splitpath( $_ ) )[-1] } @scripts;
 472 }