This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
FAQ sync.
[perl5.git] / pod / perlfaq4.pod
1 =head1 NAME
2
3 perlfaq4 - Data Manipulation ($Revision: 1.14 $, $Date: 2002/02/08 22:30:23 $)
4
5 =head1 DESCRIPTION
6
7 This section of the FAQ answers questions related to manipulating
8 numbers, dates, strings, arrays, hashes, and miscellaneous data issues.
9
10 =head1 Data: Numbers
11
12 =head2 Why am I getting long decimals (eg, 19.9499999999999) instead of the numbers I should be getting (eg, 19.95)?
13
14 The infinite set that a mathematician thinks of as the real numbers can
15 only be approximated on a computer, since the computer only has a finite
16 number of bits to store an infinite number of, um, numbers.
17
18 Internally, your computer represents floating-point numbers in binary.
19 Floating-point numbers read in from a file or appearing as literals
20 in your program are converted from their decimal floating-point
21 representation (eg, 19.95) to an internal binary representation.
22
23 However, 19.95 can't be precisely represented as a binary
24 floating-point number, just like 1/3 can't be exactly represented as a
25 decimal floating-point number.  The computer's binary representation
26 of 19.95, therefore, isn't exactly 19.95.
27
28 When a floating-point number gets printed, the binary floating-point
29 representation is converted back to decimal.  These decimal numbers
30 are displayed in either the format you specify with printf(), or the
31 current output format for numbers.  (See L<perlvar/"$#"> if you use
32 print.  C<$#> has a different default value in Perl5 than it did in
33 Perl4.  Changing C<$#> yourself is deprecated.)
34
35 This affects B<all> computer languages that represent decimal
36 floating-point numbers in binary, not just Perl.  Perl provides
37 arbitrary-precision decimal numbers with the Math::BigFloat module
38 (part of the standard Perl distribution), but mathematical operations
39 are consequently slower.
40
41 If precision is important, such as when dealing with money, it's good
42 to work with integers and then divide at the last possible moment.
43 For example, work in pennies (1995) instead of dollars and cents
44 (19.95) and divide by 100 at the end.
45
46 To get rid of the superfluous digits, just use a format (eg,
47 C<printf("%.2f", 19.95)>) to get the required precision.
48 See L<perlop/"Floating-point Arithmetic">.  
49
50 =head2 Why isn't my octal data interpreted correctly?
51
52 Perl only understands octal and hex numbers as such when they occur
53 as literals in your program.  Octal literals in perl must start with 
54 a leading "0" and hexadecimal literals must start with a leading "0x".
55 If they are read in from somewhere and assigned, no automatic 
56 conversion takes place.  You must explicitly use oct() or hex() if you 
57 want the values converted to decimal.  oct() interprets
58 both hex ("0x350") numbers and octal ones ("0350" or even without the
59 leading "0", like "377"), while hex() only converts hexadecimal ones,
60 with or without a leading "0x", like "0x255", "3A", "ff", or "deadbeef".
61 The inverse mapping from decimal to octal can be done with either the
62 "%o" or "%O" sprintf() formats.  To get from decimal to hex try either 
63 the "%x" or the "%X" formats to sprintf().
64
65 This problem shows up most often when people try using chmod(), mkdir(),
66 umask(), or sysopen(), which by widespread tradition typically take 
67 permissions in octal.
68
69     chmod(644,  $file); # WRONG
70     chmod(0644, $file); # right
71
72 Note the mistake in the first line was specifying the decimal literal 
73 644, rather than the intended octal literal 0644.  The problem can
74 be seen with:
75
76     printf("%#o",644); # prints 01204
77
78 Surely you had not intended C<chmod(01204, $file);> - did you?  If you
79 want to use numeric literals as arguments to chmod() et al. then please
80 try to express them as octal constants, that is with a leading zero and 
81 with the following digits restricted to the set 0..7.
82
83 =head2 Does Perl have a round() function?  What about ceil() and floor()?  Trig functions?
84
85 Remember that int() merely truncates toward 0.  For rounding to a
86 certain number of digits, sprintf() or printf() is usually the easiest
87 route.
88
89     printf("%.3f", 3.1415926535);       # prints 3.142
90
91 The POSIX module (part of the standard Perl distribution) implements
92 ceil(), floor(), and a number of other mathematical and trigonometric
93 functions.
94
95     use POSIX;
96     $ceil   = ceil(3.5);                        # 4
97     $floor  = floor(3.5);                       # 3
98
99 In 5.000 to 5.003 perls, trigonometry was done in the Math::Complex
100 module.  With 5.004, the Math::Trig module (part of the standard Perl
101 distribution) implements the trigonometric functions. Internally it
102 uses the Math::Complex module and some functions can break out from
103 the real axis into the complex plane, for example the inverse sine of
104 2.
105
106 Rounding in financial applications can have serious implications, and
107 the rounding method used should be specified precisely.  In these
108 cases, it probably pays not to trust whichever system rounding is
109 being used by Perl, but to instead implement the rounding function you
110 need yourself.
111
112 To see why, notice how you'll still have an issue on half-way-point
113 alternation:
114
115     for ($i = 0; $i < 1.01; $i += 0.05) { printf "%.1f ",$i}
116
117     0.0 0.1 0.1 0.2 0.2 0.2 0.3 0.3 0.4 0.4 0.5 0.5 0.6 0.7 0.7 
118     0.8 0.8 0.9 0.9 1.0 1.0
119
120 Don't blame Perl.  It's the same as in C.  IEEE says we have to do this.
121 Perl numbers whose absolute values are integers under 2**31 (on 32 bit
122 machines) will work pretty much like mathematical integers.  Other numbers
123 are not guaranteed.
124
125 =head2 How do I convert between numeric representations?
126
127 As always with Perl there is more than one way to do it.  Below
128 are a few examples of approaches to making common conversions
129 between number representations.  This is intended to be representational
130 rather than exhaustive.
131
132 Some of the examples below use the Bit::Vector module from CPAN.
133 The reason you might choose Bit::Vector over the perl built in
134 functions is that it works with numbers of ANY size, that it is
135 optimized for speed on some operations, and for at least some
136 programmers the notation might be familiar.
137
138 =item B<How do I convert Hexadecimal into decimal:>
139
140 Using perl's built in conversion of 0x notation:
141
142     $int = 0xDEADBEEF;
143     $dec = sprintf("%d", $int);
144
145 Using the hex function:
146
147     $int = hex("DEADBEEF");
148     $dec = sprintf("%d", $int);
149
150 Using pack:
151
152     $int = unpack("N", pack("H8", substr("0" x 8 . "DEADBEEF", -8)));
153     $dec = sprintf("%d", $int);
154
155 Using the CPAN module Bit::Vector:
156
157     use Bit::Vector;
158     $vec = Bit::Vector->new_Hex(32, "DEADBEEF");
159     $dec = $vec->to_Dec();
160
161 =item B<How do I convert from decimal to hexadecimal:>
162
163 Using sprint:
164
165     $hex = sprintf("%X", 3735928559);
166
167 Using unpack
168
169     $hex = unpack("H*", pack("N", 3735928559));
170
171 Using Bit::Vector
172
173     use Bit::Vector;
174     $vec = Bit::Vector->new_Dec(32, -559038737);
175     $hex = $vec->to_Hex();
176
177 And Bit::Vector supports odd bit counts:
178
179     use Bit::Vector;
180     $vec = Bit::Vector->new_Dec(33, 3735928559);
181     $vec->Resize(32); # suppress leading 0 if unwanted
182     $hex = $vec->to_Hex();
183
184 =item B<How do I convert from octal to decimal:>
185
186 Using Perl's built in conversion of numbers with leading zeros:
187
188     $int = 033653337357; # note the leading 0!
189     $dec = sprintf("%d", $int);
190
191 Using the oct function:
192
193     $int = oct("33653337357");
194     $dec = sprintf("%d", $int);
195
196 Using Bit::Vector:
197
198     use Bit::Vector;
199     $vec = Bit::Vector->new(32);
200     $vec->Chunk_List_Store(3, split(//, reverse "33653337357"));
201     $dec = $vec->to_Dec();
202
203 =item B<How do I convert from decimal to octal:>
204
205 Using sprintf:
206
207     $oct = sprintf("%o", 3735928559);
208
209 Using Bit::Vector
210
211     use Bit::Vector;
212     $vec = Bit::Vector->new_Dec(32, -559038737);
213     $oct = reverse join('', $vec->Chunk_List_Read(3));
214
215 =item B<How do I convert from binary to decimal:>
216
217 Using pack and ord
218
219     $decimal = ord(pack('B8', '10110110'));
220
221 Using pack and unpack for larger strings
222
223     $int = unpack("N", pack("B32",
224         substr("0" x 32 . "11110101011011011111011101111", -32)));
225     $dec = sprintf("%d", $int);
226
227     # substr() is used to left pad a 32 character string with zeros.
228
229 Using Bit::Vector:
230
231     $vec = Bit::Vector->new_Bin(32, "11011110101011011011111011101111");
232     $dec = $vec->to_Dec();
233
234 =item B<How do I convert from decimal to binary:>
235
236 Using unpack;
237
238     $bin = unpack("B*", pack("N", 3735928559));
239
240 Using Bit::Vector:
241
242     use Bit::Vector;
243     $vec = Bit::Vector->new_Dec(32, -559038737);
244     $bin = $vec->to_Bin();
245
246 The remaining transformations (e.g. hex -> oct, bin -> hex, etc.)
247 are left as an exercise to the inclined reader.
248
249
250 =head2 Why doesn't & work the way I want it to?
251
252 The behavior of binary arithmetic operators depends on whether they're
253 used on numbers or strings.  The operators treat a string as a series
254 of bits and work with that (the string C<"3"> is the bit pattern
255 C<00110011>).  The operators work with the binary form of a number
256 (the number C<3> is treated as the bit pattern C<00000011>).
257
258 So, saying C<11 & 3> performs the "and" operation on numbers (yielding
259 C<1>).  Saying C<"11" & "3"> performs the "and" operation on strings
260 (yielding C<"1">).
261
262 Most problems with C<&> and C<|> arise because the programmer thinks
263 they have a number but really it's a string.  The rest arise because
264 the programmer says:
265
266     if ("\020\020" & "\101\101") {
267         # ...
268     }
269
270 but a string consisting of two null bytes (the result of C<"\020\020"
271 & "\101\101">) is not a false value in Perl.  You need:
272
273     if ( ("\020\020" & "\101\101") !~ /[^\000]/) {
274         # ...
275     }
276
277 =head2 How do I multiply matrices?
278
279 Use the Math::Matrix or Math::MatrixReal modules (available from CPAN)
280 or the PDL extension (also available from CPAN).
281
282 =head2 How do I perform an operation on a series of integers?
283
284 To call a function on each element in an array, and collect the
285 results, use:
286
287     @results = map { my_func($_) } @array;
288
289 For example:
290
291     @triple = map { 3 * $_ } @single;
292
293 To call a function on each element of an array, but ignore the
294 results:
295
296     foreach $iterator (@array) {
297         some_func($iterator);
298     }
299
300 To call a function on each integer in a (small) range, you B<can> use:
301
302     @results = map { some_func($_) } (5 .. 25);
303
304 but you should be aware that the C<..> operator creates an array of
305 all integers in the range.  This can take a lot of memory for large
306 ranges.  Instead use:
307
308     @results = ();
309     for ($i=5; $i < 500_005; $i++) {
310         push(@results, some_func($i));
311     }
312
313 This situation has been fixed in Perl5.005. Use of C<..> in a C<for>
314 loop will iterate over the range, without creating the entire range.
315
316     for my $i (5 .. 500_005) {
317         push(@results, some_func($i));
318     }
319
320 will not create a list of 500,000 integers.
321
322 =head2 How can I output Roman numerals?
323
324 Get the http://www.cpan.org/modules/by-module/Roman module.
325
326 =head2 Why aren't my random numbers random?
327
328 If you're using a version of Perl before 5.004, you must call C<srand>
329 once at the start of your program to seed the random number generator.
330 5.004 and later automatically call C<srand> at the beginning.  Don't
331 call C<srand> more than once--you make your numbers less random, rather
332 than more.
333
334 Computers are good at being predictable and bad at being random
335 (despite appearances caused by bugs in your programs :-).  see the
336 F<random> artitcle in the "Far More Than You Ever Wanted To Know"
337 collection in http://www.cpan.org/olddoc/FMTEYEWTK.tgz , courtesy of
338 Tom Phoenix, talks more about this.  John von Neumann said, ``Anyone
339 who attempts to generate random numbers by deterministic means is, of
340 course, living in a state of sin.''
341
342 If you want numbers that are more random than C<rand> with C<srand>
343 provides, you should also check out the Math::TrulyRandom module from
344 CPAN.  It uses the imperfections in your system's timer to generate
345 random numbers, but this takes quite a while.  If you want a better
346 pseudorandom generator than comes with your operating system, look at
347 ``Numerical Recipes in C'' at http://www.nr.com/ .
348
349 =head1 Data: Dates
350
351 =head2 How do I find the week-of-the-year/day-of-the-year?
352
353 The day of the year is in the array returned by localtime() (see
354 L<perlfunc/"localtime">):
355
356     $day_of_year = (localtime(time()))[7];
357
358 =head2 How do I find the current century or millennium?
359
360 Use the following simple functions:
361
362     sub get_century    { 
363         return int((((localtime(shift || time))[5] + 1999))/100);
364     } 
365     sub get_millennium { 
366         return 1+int((((localtime(shift || time))[5] + 1899))/1000);
367     } 
368
369 On some systems, you'll find that the POSIX module's strftime() function
370 has been extended in a non-standard way to use a C<%C> format, which they
371 sometimes claim is the "century".  It isn't, because on most such systems,
372 this is only the first two digits of the four-digit year, and thus cannot
373 be used to reliably determine the current century or millennium.
374
375 =head2 How can I compare two dates and find the difference?
376
377 If you're storing your dates as epoch seconds then simply subtract one
378 from the other.  If you've got a structured date (distinct year, day,
379 month, hour, minute, seconds values), then for reasons of accessibility,
380 simplicity, and efficiency, merely use either timelocal or timegm (from
381 the Time::Local module in the standard distribution) to reduce structured
382 dates to epoch seconds.  However, if you don't know the precise format of
383 your dates, then you should probably use either of the Date::Manip and
384 Date::Calc modules from CPAN before you go hacking up your own parsing
385 routine to handle arbitrary date formats.
386
387 =head2 How can I take a string and turn it into epoch seconds?
388
389 If it's a regular enough string that it always has the same format,
390 you can split it up and pass the parts to C<timelocal> in the standard
391 Time::Local module.  Otherwise, you should look into the Date::Calc
392 and Date::Manip modules from CPAN.
393
394 =head2 How can I find the Julian Day?
395
396 Use the Time::JulianDay module (part of the Time-modules bundle
397 available from CPAN.)
398
399 Before you immerse yourself too deeply in this, be sure to verify that
400 it is the I<Julian> Day you really want.  Are you interested in a way
401 of getting serial days so that you just can tell how many days they
402 are apart or so that you can do also other date arithmetic?  If you
403 are interested in performing date arithmetic, this can be done using
404 modules Date::Manip or Date::Calc.
405
406 There is too many details and much confusion on this issue to cover in
407 this FAQ, but the term is applied (correctly) to a calendar now
408 supplanted by the Gregorian Calendar, with the Julian Calendar failing
409 to adjust properly for leap years on centennial years (among other
410 annoyances).  The term is also used (incorrectly) to mean: [1] days in
411 the Gregorian Calendar; and [2] days since a particular starting time
412 or `epoch', usually 1970 in the Unix world and 1980 in the
413 MS-DOS/Windows world.  If you find that it is not the first meaning
414 that you really want, then check out the Date::Manip and Date::Calc
415 modules.  (Thanks to David Cassell for most of this text.)
416
417 =head2 How do I find yesterday's date?
418
419 The C<time()> function returns the current time in seconds since the
420 epoch.  Take twenty-four hours off that:
421
422     $yesterday = time() - ( 24 * 60 * 60 );
423
424 Then you can pass this to C<localtime()> and get the individual year,
425 month, day, hour, minute, seconds values.
426
427 Note very carefully that the code above assumes that your days are
428 twenty-four hours each.  For most people, there are two days a year
429 when they aren't: the switch to and from summer time throws this off.
430 A solution to this issue is offered by Russ Allbery.
431
432     sub yesterday {
433         my $now  = defined $_[0] ? $_[0] : time;
434         my $then = $now - 60 * 60 * 24;
435         my $ndst = (localtime $now)[8] > 0;
436         my $tdst = (localtime $then)[8] > 0;
437         $then - ($tdst - $ndst) * 60 * 60;
438     }
439     # Should give you "this time yesterday" in seconds since epoch relative to
440     # the first argument or the current time if no argument is given and
441     # suitable for passing to localtime or whatever else you need to do with
442     # it.  $ndst is whether we're currently in daylight savings time; $tdst is
443     # whether the point 24 hours ago was in daylight savings time.  If $tdst
444     # and $ndst are the same, a boundary wasn't crossed, and the correction
445     # will subtract 0.  If $tdst is 1 and $ndst is 0, subtract an hour more
446     # from yesterday's time since we gained an extra hour while going off
447     # daylight savings time.  If $tdst is 0 and $ndst is 1, subtract a
448     # negative hour (add an hour) to yesterday's time since we lost an hour.
449     #
450     # All of this is because during those days when one switches off or onto
451     # DST, a "day" isn't 24 hours long; it's either 23 or 25.
452     #
453     # The explicit settings of $ndst and $tdst are necessary because localtime
454     # only says it returns the system tm struct, and the system tm struct at
455     # least on Solaris doesn't guarantee any particular positive value (like,
456     # say, 1) for isdst, just a positive value.  And that value can
457     # potentially be negative, if DST information isn't available (this sub
458     # just treats those cases like no DST).
459     #
460     # Note that between 2am and 3am on the day after the time zone switches
461     # off daylight savings time, the exact hour of "yesterday" corresponding
462     # to the current hour is not clearly defined.  Note also that if used
463     # between 2am and 3am the day after the change to daylight savings time,
464     # the result will be between 3am and 4am of the previous day; it's
465     # arguable whether this is correct.
466     #
467     # This sub does not attempt to deal with leap seconds (most things don't).
468     #
469     # Copyright relinquished 1999 by Russ Allbery <rra@stanford.edu>
470     # This code is in the public domain
471
472 =head2 Does Perl have a Year 2000 problem?  Is Perl Y2K compliant?
473
474 Short answer: No, Perl does not have a Year 2000 problem.  Yes, Perl is
475 Y2K compliant (whatever that means).  The programmers you've hired to
476 use it, however, probably are not.
477
478 Long answer: The question belies a true understanding of the issue.
479 Perl is just as Y2K compliant as your pencil--no more, and no less.
480 Can you use your pencil to write a non-Y2K-compliant memo?  Of course
481 you can.  Is that the pencil's fault?  Of course it isn't.
482
483 The date and time functions supplied with Perl (gmtime and localtime)
484 supply adequate information to determine the year well beyond 2000
485 (2038 is when trouble strikes for 32-bit machines).  The year returned
486 by these functions when used in a list context is the year minus 1900.
487 For years between 1910 and 1999 this I<happens> to be a 2-digit decimal
488 number. To avoid the year 2000 problem simply do not treat the year as
489 a 2-digit number.  It isn't.
490
491 When gmtime() and localtime() are used in scalar context they return
492 a timestamp string that contains a fully-expanded year.  For example,
493 C<$timestamp = gmtime(1005613200)> sets $timestamp to "Tue Nov 13 01:00:00
494 2001".  There's no year 2000 problem here.
495
496 That doesn't mean that Perl can't be used to create non-Y2K compliant
497 programs.  It can.  But so can your pencil.  It's the fault of the user,
498 not the language.  At the risk of inflaming the NRA: ``Perl doesn't
499 break Y2K, people do.''  See http://language.perl.com/news/y2k.html for
500 a longer exposition.
501
502 =head1 Data: Strings
503
504 =head2 How do I validate input?
505
506 The answer to this question is usually a regular expression, perhaps
507 with auxiliary logic.  See the more specific questions (numbers, mail
508 addresses, etc.) for details.
509
510 =head2 How do I unescape a string?
511
512 It depends just what you mean by ``escape''.  URL escapes are dealt
513 with in L<perlfaq9>.  Shell escapes with the backslash (C<\>)
514 character are removed with
515
516     s/\\(.)/$1/g;
517
518 This won't expand C<"\n"> or C<"\t"> or any other special escapes.
519
520 =head2 How do I remove consecutive pairs of characters?
521
522 To turn C<"abbcccd"> into C<"abccd">:
523
524     s/(.)\1/$1/g;       # add /s to include newlines
525
526 Here's a solution that turns "abbcccd" to "abcd":
527
528     y///cs;     # y == tr, but shorter :-)
529
530 =head2 How do I expand function calls in a string?
531
532 This is documented in L<perlref>.  In general, this is fraught with
533 quoting and readability problems, but it is possible.  To interpolate
534 a subroutine call (in list context) into a string:
535
536     print "My sub returned @{[mysub(1,2,3)]} that time.\n";
537
538 If you prefer scalar context, similar chicanery is also useful for
539 arbitrary expressions:
540
541     print "That yields ${\($n + 5)} widgets\n";
542
543 Version 5.004 of Perl had a bug that gave list context to the
544 expression in C<${...}>, but this is fixed in version 5.005.
545
546 See also ``How can I expand variables in text strings?'' in this
547 section of the FAQ.
548
549 =head2 How do I find matching/nesting anything?
550
551 This isn't something that can be done in one regular expression, no
552 matter how complicated.  To find something between two single
553 characters, a pattern like C</x([^x]*)x/> will get the intervening
554 bits in $1. For multiple ones, then something more like
555 C</alpha(.*?)omega/> would be needed.  But none of these deals with
556 nested patterns, nor can they.  For that you'll have to write a
557 parser.
558
559 If you are serious about writing a parser, there are a number of
560 modules or oddities that will make your life a lot easier.  There are
561 the CPAN modules Parse::RecDescent, Parse::Yapp, and Text::Balanced;
562 and the byacc program.   Starting from perl 5.8 the Text::Balanced
563 is part of the standard distribution.
564
565 One simple destructive, inside-out approach that you might try is to
566 pull out the smallest nesting parts one at a time:
567
568     while (s/BEGIN((?:(?!BEGIN)(?!END).)*)END//gs) {
569         # do something with $1
570     } 
571
572 A more complicated and sneaky approach is to make Perl's regular
573 expression engine do it for you.  This is courtesy Dean Inada, and
574 rather has the nature of an Obfuscated Perl Contest entry, but it
575 really does work:
576
577     # $_ contains the string to parse
578     # BEGIN and END are the opening and closing markers for the
579     # nested text.
580
581     @( = ('(','');
582     @) = (')','');
583     ($re=$_)=~s/((BEGIN)|(END)|.)/$)[!$3]\Q$1\E$([!$2]/gs;
584     @$ = (eval{/$re/},$@!~/unmatched/);
585     print join("\n",@$[0..$#$]) if( $$[-1] );
586
587 =head2 How do I reverse a string?
588
589 Use reverse() in scalar context, as documented in
590 L<perlfunc/reverse>.
591
592     $reversed = reverse $string;
593
594 =head2 How do I expand tabs in a string?
595
596 You can do it yourself:
597
598     1 while $string =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e;
599
600 Or you can just use the Text::Tabs module (part of the standard Perl
601 distribution).
602
603     use Text::Tabs;
604     @expanded_lines = expand(@lines_with_tabs);
605
606 =head2 How do I reformat a paragraph?
607
608 Use Text::Wrap (part of the standard Perl distribution):
609
610     use Text::Wrap;
611     print wrap("\t", '  ', @paragraphs);
612
613 The paragraphs you give to Text::Wrap should not contain embedded
614 newlines.  Text::Wrap doesn't justify the lines (flush-right).
615
616 Or use the CPAN module Text::Autoformat.  Formatting files can be easily
617 done by making a shell alias, like so:
618
619     alias fmt="perl -i -MText::Autoformat -n0777 \
620         -e 'print autoformat $_, {all=>1}' $*"
621
622 See the documentation for Text::Autoformat to appreciate its many
623 capabilities.
624
625 =head2 How can I access/change the first N letters of a string?
626
627 There are many ways.  If you just want to grab a copy, use
628 substr():
629
630     $first_byte = substr($a, 0, 1);
631
632 If you want to modify part of a string, the simplest way is often to
633 use substr() as an lvalue:
634
635     substr($a, 0, 3) = "Tom";
636
637 Although those with a pattern matching kind of thought process will
638 likely prefer
639
640     $a =~ s/^.../Tom/;
641
642 =head2 How do I change the Nth occurrence of something?
643
644 You have to keep track of N yourself.  For example, let's say you want
645 to change the fifth occurrence of C<"whoever"> or C<"whomever"> into
646 C<"whosoever"> or C<"whomsoever">, case insensitively.  These
647 all assume that $_ contains the string to be altered.
648
649     $count = 0;
650     s{((whom?)ever)}{
651         ++$count == 5           # is it the 5th?
652             ? "${2}soever"      # yes, swap
653             : $1                # renege and leave it there
654     }ige;
655
656 In the more general case, you can use the C</g> modifier in a C<while>
657 loop, keeping count of matches.
658
659     $WANT = 3;
660     $count = 0;
661     $_ = "One fish two fish red fish blue fish";
662     while (/(\w+)\s+fish\b/gi) {
663         if (++$count == $WANT) {
664             print "The third fish is a $1 one.\n";
665         }
666     }
667
668 That prints out: C<"The third fish is a red one.">  You can also use a
669 repetition count and repeated pattern like this:
670
671     /(?:\w+\s+fish\s+){2}(\w+)\s+fish/i;
672
673 =head2 How can I count the number of occurrences of a substring within a string?
674
675 There are a number of ways, with varying efficiency.  If you want a
676 count of a certain single character (X) within a string, you can use the
677 C<tr///> function like so:
678
679     $string = "ThisXlineXhasXsomeXx'sXinXit";
680     $count = ($string =~ tr/X//);
681     print "There are $count X characters in the string";
682
683 This is fine if you are just looking for a single character.  However,
684 if you are trying to count multiple character substrings within a
685 larger string, C<tr///> won't work.  What you can do is wrap a while()
686 loop around a global pattern match.  For example, let's count negative
687 integers:
688
689     $string = "-9 55 48 -2 23 -76 4 14 -44";
690     while ($string =~ /-\d+/g) { $count++ }
691     print "There are $count negative numbers in the string";
692
693 =head2 How do I capitalize all the words on one line?
694
695 To make the first letter of each word upper case:
696
697         $line =~ s/\b(\w)/\U$1/g;
698
699 This has the strange effect of turning "C<don't do it>" into "C<Don'T
700 Do It>".  Sometimes you might want this.  Other times you might need a
701 more thorough solution (Suggested by brian d foy):
702
703     $string =~ s/ (
704                  (^\w)    #at the beginning of the line
705                    |      # or
706                  (\s\w)   #preceded by whitespace
707                    )
708                 /\U$1/xg;
709     $string =~ /([\w']+)/\u\L$1/g;
710
711 To make the whole line upper case:
712
713         $line = uc($line);
714
715 To force each word to be lower case, with the first letter upper case:
716
717         $line =~ s/(\w+)/\u\L$1/g;
718
719 You can (and probably should) enable locale awareness of those
720 characters by placing a C<use locale> pragma in your program.
721 See L<perllocale> for endless details on locales.
722
723 This is sometimes referred to as putting something into "title
724 case", but that's not quite accurate.  Consider the proper
725 capitalization of the movie I<Dr. Strangelove or: How I Learned to
726 Stop Worrying and Love the Bomb>, for example.
727
728 =head2 How can I split a [character] delimited string except when inside
729 [character]? (Comma-separated files)
730
731 Take the example case of trying to split a string that is comma-separated
732 into its different fields.  (We'll pretend you said comma-separated, not
733 comma-delimited, which is different and almost never what you mean.) You
734 can't use C<split(/,/)> because you shouldn't split if the comma is inside
735 quotes.  For example, take a data line like this:
736
737     SAR001,"","Cimetrix, Inc","Bob Smith","CAM",N,8,1,0,7,"Error, Core Dumped"
738
739 Due to the restriction of the quotes, this is a fairly complex
740 problem.  Thankfully, we have Jeffrey Friedl, author of a highly
741 recommended book on regular expressions, to handle these for us.  He
742 suggests (assuming your string is contained in $text):
743
744      @new = ();
745      push(@new, $+) while $text =~ m{
746          "([^\"\\]*(?:\\.[^\"\\]*)*)",?  # groups the phrase inside the quotes
747        | ([^,]+),?
748        | ,
749      }gx;
750      push(@new, undef) if substr($text,-1,1) eq ',';
751
752 If you want to represent quotation marks inside a
753 quotation-mark-delimited field, escape them with backslashes (eg,
754 C<"like \"this\"">.  Unescaping them is a task addressed earlier in
755 this section.
756
757 Alternatively, the Text::ParseWords module (part of the standard Perl
758 distribution) lets you say:
759
760     use Text::ParseWords;
761     @new = quotewords(",", 0, $text);
762
763 There's also a Text::CSV (Comma-Separated Values) module on CPAN.
764
765 =head2 How do I strip blank space from the beginning/end of a string?
766
767 Although the simplest approach would seem to be
768
769     $string =~ s/^\s*(.*?)\s*$/$1/;
770
771 not only is this unnecessarily slow and destructive, it also fails with
772 embedded newlines.  It is much faster to do this operation in two steps:
773
774     $string =~ s/^\s+//;
775     $string =~ s/\s+$//;
776
777 Or more nicely written as:
778
779     for ($string) {
780         s/^\s+//;
781         s/\s+$//;
782     }
783
784 This idiom takes advantage of the C<foreach> loop's aliasing
785 behavior to factor out common code.  You can do this
786 on several strings at once, or arrays, or even the 
787 values of a hash if you use a slice:
788
789     # trim whitespace in the scalar, the array, 
790     # and all the values in the hash
791     foreach ($scalar, @array, @hash{keys %hash}) {
792         s/^\s+//;
793         s/\s+$//;
794     }
795
796 =head2 How do I pad a string with blanks or pad a number with zeroes?
797
798 (This answer contributed by Uri Guttman, with kibitzing from
799 Bart Lateur.) 
800
801 In the following examples, C<$pad_len> is the length to which you wish
802 to pad the string, C<$text> or C<$num> contains the string to be padded,
803 and C<$pad_char> contains the padding character. You can use a single
804 character string constant instead of the C<$pad_char> variable if you
805 know what it is in advance. And in the same way you can use an integer in
806 place of C<$pad_len> if you know the pad length in advance.
807
808 The simplest method uses the C<sprintf> function. It can pad on the left
809 or right with blanks and on the left with zeroes and it will not
810 truncate the result. The C<pack> function can only pad strings on the
811 right with blanks and it will truncate the result to a maximum length of
812 C<$pad_len>.
813
814     # Left padding a string with blanks (no truncation):
815     $padded = sprintf("%${pad_len}s", $text);
816
817     # Right padding a string with blanks (no truncation):
818     $padded = sprintf("%-${pad_len}s", $text);
819
820     # Left padding a number with 0 (no truncation): 
821     $padded = sprintf("%0${pad_len}d", $num);
822
823     # Right padding a string with blanks using pack (will truncate):
824     $padded = pack("A$pad_len",$text);
825
826 If you need to pad with a character other than blank or zero you can use
827 one of the following methods.  They all generate a pad string with the
828 C<x> operator and combine that with C<$text>. These methods do
829 not truncate C<$text>.
830
831 Left and right padding with any character, creating a new string:
832
833     $padded = $pad_char x ( $pad_len - length( $text ) ) . $text;
834     $padded = $text . $pad_char x ( $pad_len - length( $text ) );
835
836 Left and right padding with any character, modifying C<$text> directly:
837
838     substr( $text, 0, 0 ) = $pad_char x ( $pad_len - length( $text ) );
839     $text .= $pad_char x ( $pad_len - length( $text ) );
840
841 =head2 How do I extract selected columns from a string?
842
843 Use substr() or unpack(), both documented in L<perlfunc>.
844 If you prefer thinking in terms of columns instead of widths, 
845 you can use this kind of thing:
846
847     # determine the unpack format needed to split Linux ps output
848     # arguments are cut columns
849     my $fmt = cut2fmt(8, 14, 20, 26, 30, 34, 41, 47, 59, 63, 67, 72);
850
851     sub cut2fmt { 
852         my(@positions) = @_;
853         my $template  = '';
854         my $lastpos   = 1;
855         for my $place (@positions) {
856             $template .= "A" . ($place - $lastpos) . " "; 
857             $lastpos   = $place;
858         }
859         $template .= "A*";
860         return $template;
861     }
862
863 =head2 How do I find the soundex value of a string?
864
865 Use the standard Text::Soundex module distributed with Perl.
866 Before you do so, you may want to determine whether `soundex' is in
867 fact what you think it is.  Knuth's soundex algorithm compresses words
868 into a small space, and so it does not necessarily distinguish between
869 two words which you might want to appear separately.  For example, the
870 last names `Knuth' and `Kant' are both mapped to the soundex code K530.
871 If Text::Soundex does not do what you are looking for, you might want
872 to consider the String::Approx module available at CPAN.
873
874 =head2 How can I expand variables in text strings?
875
876 Let's assume that you have a string like:
877
878     $text = 'this has a $foo in it and a $bar';
879
880 If those were both global variables, then this would
881 suffice:
882
883     $text =~ s/\$(\w+)/${$1}/g;  # no /e needed
884
885 But since they are probably lexicals, or at least, they could
886 be, you'd have to do this:
887
888     $text =~ s/(\$\w+)/$1/eeg;
889     die if $@;                  # needed /ee, not /e
890
891 It's probably better in the general case to treat those
892 variables as entries in some special hash.  For example:
893
894     %user_defs = ( 
895         foo  => 23,
896         bar  => 19,
897     );
898     $text =~ s/\$(\w+)/$user_defs{$1}/g;
899
900 See also ``How do I expand function calls in a string?'' in this section
901 of the FAQ.
902
903 =head2 What's wrong with always quoting "$vars"?
904
905 The problem is that those double-quotes force stringification--
906 coercing numbers and references into strings--even when you
907 don't want them to be strings.  Think of it this way: double-quote
908 expansion is used to produce new strings.  If you already 
909 have a string, why do you need more?
910
911 If you get used to writing odd things like these:
912
913     print "$var";       # BAD
914     $new = "$old";      # BAD
915     somefunc("$var");   # BAD
916
917 You'll be in trouble.  Those should (in 99.8% of the cases) be
918 the simpler and more direct:
919
920     print $var;
921     $new = $old;
922     somefunc($var);
923
924 Otherwise, besides slowing you down, you're going to break code when
925 the thing in the scalar is actually neither a string nor a number, but
926 a reference:
927
928     func(\@array);
929     sub func {
930         my $aref = shift;
931         my $oref = "$aref";  # WRONG
932     }
933
934 You can also get into subtle problems on those few operations in Perl
935 that actually do care about the difference between a string and a
936 number, such as the magical C<++> autoincrement operator or the
937 syscall() function.
938
939 Stringification also destroys arrays.  
940
941     @lines = `command`;
942     print "@lines";             # WRONG - extra blanks
943     print @lines;               # right
944
945 =head2 Why don't my <<HERE documents work?
946
947 Check for these three things:
948
949 =over 4
950
951 =item 1. There must be no space after the << part.
952
953 =item 2. There (probably) should be a semicolon at the end.
954
955 =item 3. You can't (easily) have any space in front of the tag.
956
957 =back
958
959 If you want to indent the text in the here document, you 
960 can do this:
961
962     # all in one
963     ($VAR = <<HERE_TARGET) =~ s/^\s+//gm;
964         your text
965         goes here
966     HERE_TARGET
967
968 But the HERE_TARGET must still be flush against the margin.
969 If you want that indented also, you'll have to quote 
970 in the indentation.
971
972     ($quote = <<'    FINIS') =~ s/^\s+//gm;
973             ...we will have peace, when you and all your works have
974             perished--and the works of your dark master to whom you
975             would deliver us. You are a liar, Saruman, and a corrupter
976             of men's hearts.  --Theoden in /usr/src/perl/taint.c
977         FINIS
978     $quote =~ s/\s+--/\n--/;
979
980 A nice general-purpose fixer-upper function for indented here documents
981 follows.  It expects to be called with a here document as its argument.
982 It looks to see whether each line begins with a common substring, and
983 if so, strips that substring off.  Otherwise, it takes the amount of leading
984 whitespace found on the first line and removes that much off each
985 subsequent line.
986
987     sub fix {
988         local $_ = shift;
989         my ($white, $leader);  # common whitespace and common leading string
990         if (/^\s*(?:([^\w\s]+)(\s*).*\n)(?:\s*\1\2?.*\n)+$/) {
991             ($white, $leader) = ($2, quotemeta($1));
992         } else {
993             ($white, $leader) = (/^(\s+)/, '');
994         }
995         s/^\s*?$leader(?:$white)?//gm;
996         return $_;
997     }
998
999 This works with leading special strings, dynamically determined:
1000
1001     $remember_the_main = fix<<'    MAIN_INTERPRETER_LOOP';
1002         @@@ int
1003         @@@ runops() {
1004         @@@     SAVEI32(runlevel);
1005         @@@     runlevel++;
1006         @@@     while ( op = (*op->op_ppaddr)() );
1007         @@@     TAINT_NOT;
1008         @@@     return 0;
1009         @@@ }
1010     MAIN_INTERPRETER_LOOP
1011
1012 Or with a fixed amount of leading whitespace, with remaining
1013 indentation correctly preserved:
1014
1015     $poem = fix<<EVER_ON_AND_ON;
1016        Now far ahead the Road has gone,
1017           And I must follow, if I can,
1018        Pursuing it with eager feet,
1019           Until it joins some larger way
1020        Where many paths and errands meet.
1021           And whither then? I cannot say.
1022                 --Bilbo in /usr/src/perl/pp_ctl.c
1023     EVER_ON_AND_ON
1024
1025 =head1 Data: Arrays
1026
1027 =head2 What is the difference between a list and an array?
1028
1029 An array has a changeable length.  A list does not.  An array is something
1030 you can push or pop, while a list is a set of values.  Some people make
1031 the distinction that a list is a value while an array is a variable.
1032 Subroutines are passed and return lists, you put things into list
1033 context, you initialize arrays with lists, and you foreach() across
1034 a list.  C<@> variables are arrays, anonymous arrays are arrays, arrays
1035 in scalar context behave like the number of elements in them, subroutines
1036 access their arguments through the array C<@_>, and push/pop/shift only work
1037 on arrays.
1038
1039 As a side note, there's no such thing as a list in scalar context.
1040 When you say
1041
1042     $scalar = (2, 5, 7, 9);
1043
1044 you're using the comma operator in scalar context, so it uses the scalar
1045 comma operator.  There never was a list there at all!  This causes the
1046 last value to be returned: 9.
1047
1048 =head2 What is the difference between $array[1] and @array[1]?
1049
1050 The former is a scalar value; the latter an array slice, making
1051 it a list with one (scalar) value.  You should use $ when you want a
1052 scalar value (most of the time) and @ when you want a list with one
1053 scalar value in it (very, very rarely; nearly never, in fact).
1054
1055 Sometimes it doesn't make a difference, but sometimes it does.
1056 For example, compare:
1057
1058     $good[0] = `some program that outputs several lines`;
1059
1060 with
1061
1062     @bad[0]  = `same program that outputs several lines`;
1063
1064 The C<use warnings> pragma and the B<-w> flag will warn you about these 
1065 matters.
1066
1067 =head2 How can I remove duplicate elements from a list or array?
1068
1069 There are several possible ways, depending on whether the array is
1070 ordered and whether you wish to preserve the ordering.
1071
1072 =over 4
1073
1074 =item a)
1075
1076 If @in is sorted, and you want @out to be sorted:
1077 (this assumes all true values in the array)
1078
1079     $prev = "not equal to $in[0]";
1080     @out = grep($_ ne $prev && ($prev = $_, 1), @in);
1081
1082 This is nice in that it doesn't use much extra memory, simulating
1083 uniq(1)'s behavior of removing only adjacent duplicates.  The ", 1"
1084 guarantees that the expression is true (so that grep picks it up)
1085 even if the $_ is 0, "", or undef.
1086
1087 =item b)
1088
1089 If you don't know whether @in is sorted:
1090
1091     undef %saw;
1092     @out = grep(!$saw{$_}++, @in);
1093
1094 =item c)
1095
1096 Like (b), but @in contains only small integers:
1097
1098     @out = grep(!$saw[$_]++, @in);
1099
1100 =item d)
1101
1102 A way to do (b) without any loops or greps:
1103
1104     undef %saw;
1105     @saw{@in} = ();
1106     @out = sort keys %saw;  # remove sort if undesired
1107
1108 =item e)
1109
1110 Like (d), but @in contains only small positive integers:
1111
1112     undef @ary;
1113     @ary[@in] = @in;
1114     @out = grep {defined} @ary;
1115
1116 =back
1117
1118 But perhaps you should have been using a hash all along, eh?
1119
1120 =head2 How can I tell whether a certain element is contained in a list or array?
1121
1122 Hearing the word "in" is an I<in>dication that you probably should have
1123 used a hash, not a list or array, to store your data.  Hashes are
1124 designed to answer this question quickly and efficiently.  Arrays aren't.
1125
1126 That being said, there are several ways to approach this.  If you
1127 are going to make this query many times over arbitrary string values,
1128 the fastest way is probably to invert the original array and keep an
1129 associative array lying about whose keys are the first array's values.
1130
1131     @blues = qw/azure cerulean teal turquoise lapis-lazuli/;
1132     undef %is_blue;
1133     for (@blues) { $is_blue{$_} = 1 }
1134
1135 Now you can check whether $is_blue{$some_color}.  It might have been a
1136 good idea to keep the blues all in a hash in the first place.
1137
1138 If the values are all small integers, you could use a simple indexed
1139 array.  This kind of an array will take up less space:
1140
1141     @primes = (2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31);
1142     undef @is_tiny_prime;
1143     for (@primes) { $is_tiny_prime[$_] = 1 }
1144     # or simply  @istiny_prime[@primes] = (1) x @primes;
1145
1146 Now you check whether $is_tiny_prime[$some_number].
1147
1148 If the values in question are integers instead of strings, you can save
1149 quite a lot of space by using bit strings instead:
1150
1151     @articles = ( 1..10, 150..2000, 2017 );
1152     undef $read;
1153     for (@articles) { vec($read,$_,1) = 1 }
1154
1155 Now check whether C<vec($read,$n,1)> is true for some C<$n>.
1156
1157 Please do not use
1158
1159     ($is_there) = grep $_ eq $whatever, @array;
1160
1161 or worse yet
1162
1163     ($is_there) = grep /$whatever/, @array;
1164
1165 These are slow (checks every element even if the first matches),
1166 inefficient (same reason), and potentially buggy (what if there are
1167 regex characters in $whatever?).  If you're only testing once, then
1168 use:
1169
1170     $is_there = 0;
1171     foreach $elt (@array) {
1172         if ($elt eq $elt_to_find) {
1173             $is_there = 1;
1174             last;
1175         }
1176     }
1177     if ($is_there) { ... }
1178
1179 =head2 How do I compute the difference of two arrays?  How do I compute the intersection of two arrays?
1180
1181 Use a hash.  Here's code to do both and more.  It assumes that
1182 each element is unique in a given array:
1183
1184     @union = @intersection = @difference = ();
1185     %count = ();
1186     foreach $element (@array1, @array2) { $count{$element}++ }
1187     foreach $element (keys %count) {
1188         push @union, $element;
1189         push @{ $count{$element} > 1 ? \@intersection : \@difference }, $element;
1190     }
1191
1192 Note that this is the I<symmetric difference>, that is, all elements in
1193 either A or in B but not in both.  Think of it as an xor operation.
1194
1195 =head2 How do I test whether two arrays or hashes are equal?
1196
1197 The following code works for single-level arrays.  It uses a stringwise
1198 comparison, and does not distinguish defined versus undefined empty
1199 strings.  Modify if you have other needs.
1200
1201     $are_equal = compare_arrays(\@frogs, \@toads);
1202
1203     sub compare_arrays {
1204         my ($first, $second) = @_;
1205         no warnings;  # silence spurious -w undef complaints
1206         return 0 unless @$first == @$second;
1207         for (my $i = 0; $i < @$first; $i++) {
1208             return 0 if $first->[$i] ne $second->[$i];
1209         }
1210         return 1;
1211     }
1212
1213 For multilevel structures, you may wish to use an approach more
1214 like this one.  It uses the CPAN module FreezeThaw:
1215
1216     use FreezeThaw qw(cmpStr);
1217     @a = @b = ( "this", "that", [ "more", "stuff" ] );
1218
1219     printf "a and b contain %s arrays\n",
1220         cmpStr(\@a, \@b) == 0 
1221             ? "the same" 
1222             : "different";
1223
1224 This approach also works for comparing hashes.  Here
1225 we'll demonstrate two different answers:
1226
1227     use FreezeThaw qw(cmpStr cmpStrHard);
1228
1229     %a = %b = ( "this" => "that", "extra" => [ "more", "stuff" ] );
1230     $a{EXTRA} = \%b;
1231     $b{EXTRA} = \%a;                    
1232
1233     printf "a and b contain %s hashes\n",
1234         cmpStr(\%a, \%b) == 0 ? "the same" : "different";
1235
1236     printf "a and b contain %s hashes\n",
1237         cmpStrHard(\%a, \%b) == 0 ? "the same" : "different";
1238
1239
1240 The first reports that both those the hashes contain the same data,
1241 while the second reports that they do not.  Which you prefer is left as
1242 an exercise to the reader.
1243
1244 =head2 How do I find the first array element for which a condition is true?
1245
1246 You can use this if you care about the index:
1247
1248     for ($i= 0; $i < @array; $i++) {
1249         if ($array[$i] eq "Waldo") {
1250             $found_index = $i;
1251             last;
1252         }
1253     }
1254
1255 Now C<$found_index> has what you want.
1256
1257 =head2 How do I handle linked lists?
1258
1259 In general, you usually don't need a linked list in Perl, since with
1260 regular arrays, you can push and pop or shift and unshift at either end,
1261 or you can use splice to add and/or remove arbitrary number of elements at
1262 arbitrary points.  Both pop and shift are both O(1) operations on Perl's
1263 dynamic arrays.  In the absence of shifts and pops, push in general
1264 needs to reallocate on the order every log(N) times, and unshift will
1265 need to copy pointers each time.
1266
1267 If you really, really wanted, you could use structures as described in
1268 L<perldsc> or L<perltoot> and do just what the algorithm book tells you
1269 to do.  For example, imagine a list node like this:
1270
1271     $node = {
1272         VALUE => 42,
1273         LINK  => undef,
1274     };
1275
1276 You could walk the list this way:
1277
1278     print "List: ";
1279     for ($node = $head;  $node; $node = $node->{LINK}) {
1280         print $node->{VALUE}, " ";
1281     }
1282     print "\n";
1283
1284 You could add to the list this way:
1285
1286     my ($head, $tail);
1287     $tail = append($head, 1);       # grow a new head
1288     for $value ( 2 .. 10 ) {
1289         $tail = append($tail, $value);
1290     }
1291
1292     sub append {
1293         my($list, $value) = @_;
1294         my $node = { VALUE => $value };
1295         if ($list) {
1296             $node->{LINK} = $list->{LINK};
1297             $list->{LINK} = $node;
1298         } else {
1299             $_[0] = $node;      # replace caller's version
1300         }
1301         return $node;
1302     }
1303
1304 But again, Perl's built-in are virtually always good enough.
1305
1306 =head2 How do I handle circular lists?
1307
1308 Circular lists could be handled in the traditional fashion with linked
1309 lists, or you could just do something like this with an array:
1310
1311     unshift(@array, pop(@array));  # the last shall be first
1312     push(@array, shift(@array));   # and vice versa
1313
1314 =head2 How do I shuffle an array randomly?
1315
1316 If you either have Perl 5.8.0 or later installed, or if you have
1317 Scalar-List-Utils 1.03 or later installed, you can say:
1318
1319         use List::Util 'shuffle';
1320
1321         @shuffled = shuffle(@list);
1322
1323 If not, you can use this:
1324
1325     # fisher_yates_shuffle
1326     # generate a random permutation of an array in place
1327     # As in shuffling a deck of cards
1328     #
1329     sub fisher_yates_shuffle {
1330         my $deck = shift;  # $deck is a reference to an array
1331         my $i = @$deck;
1332         while (--$i) {
1333             my $j = int rand ($i+1);
1334             @$deck[$i,$j] = @$deck[$j,$i];
1335         }
1336     }
1337
1338 And here is an example of using it:
1339
1340     #
1341     # shuffle my mpeg collection
1342     #
1343     my @mpeg = <audio/*/*.mp3>;
1344     fisher_yates_shuffle( \@mpeg );    # randomize @mpeg in place
1345     print @mpeg;
1346
1347 Note that the above implementation shuffles an array in place,
1348 unlike the List::Util::shuffle() which takes a list and returns
1349 a new shuffled list.
1350
1351 You've probably seen shuffling algorithms that work using splice,
1352 randomly picking another element to swap the current element with
1353
1354     srand;
1355     @new = ();
1356     @old = 1 .. 10;  # just a demo
1357     while (@old) {
1358         push(@new, splice(@old, rand @old, 1));
1359     }
1360
1361 This is bad because splice is already O(N), and since you do it N times,
1362 you just invented a quadratic algorithm; that is, O(N**2).  This does
1363 not scale, although Perl is so efficient that you probably won't notice
1364 this until you have rather largish arrays.
1365
1366 =head2 How do I process/modify each element of an array?
1367
1368 Use C<for>/C<foreach>:
1369
1370     for (@lines) {
1371         s/foo/bar/;     # change that word
1372         y/XZ/ZX/;       # swap those letters
1373     }
1374
1375 Here's another; let's compute spherical volumes:
1376
1377     for (@volumes = @radii) {   # @volumes has changed parts
1378         $_ **= 3;
1379         $_ *= (4/3) * 3.14159;  # this will be constant folded
1380     }
1381
1382 If you want to do the same thing to modify the values of the hash,
1383 you may not use the C<values> function, oddly enough.  You need a slice:
1384
1385     for $orbit ( @orbits{keys %orbits} ) {
1386         ($orbit **= 3) *= (4/3) * 3.14159; 
1387     }
1388
1389 =head2 How do I select a random element from an array?
1390
1391 Use the rand() function (see L<perlfunc/rand>):
1392
1393     # at the top of the program:
1394     srand;                      # not needed for 5.004 and later
1395
1396     # then later on
1397     $index   = rand @array;
1398     $element = $array[$index];
1399
1400 Make sure you I<only call srand once per program, if then>.
1401 If you are calling it more than once (such as before each 
1402 call to rand), you're almost certainly doing something wrong.
1403
1404 =head2 How do I permute N elements of a list?
1405
1406 Here's a little program that generates all permutations
1407 of all the words on each line of input.  The algorithm embodied
1408 in the permute() function should work on any list:
1409
1410     #!/usr/bin/perl -n
1411     # tsc-permute: permute each word of input
1412     permute([split], []);
1413     sub permute {
1414         my @items = @{ $_[0] };
1415         my @perms = @{ $_[1] };
1416         unless (@items) {
1417             print "@perms\n";
1418         } else {
1419             my(@newitems,@newperms,$i);
1420             foreach $i (0 .. $#items) {
1421                 @newitems = @items;
1422                 @newperms = @perms;
1423                 unshift(@newperms, splice(@newitems, $i, 1));
1424                 permute([@newitems], [@newperms]);
1425             }
1426         }
1427     }
1428
1429 Unfortunately, this algorithm is very inefficient. The Algorithm::Permute
1430 module from CPAN runs at least an order of magnitude faster. If you don't
1431 have a C compiler (or a binary distribution of Algorithm::Permute), then
1432 you can use List::Permutor which is written in pure Perl, and is still
1433 several times faster than the algorithm above.
1434
1435 =head2 How do I sort an array by (anything)?
1436
1437 Supply a comparison function to sort() (described in L<perlfunc/sort>):
1438
1439     @list = sort { $a <=> $b } @list;
1440
1441 The default sort function is cmp, string comparison, which would
1442 sort C<(1, 2, 10)> into C<(1, 10, 2)>.  C<< <=> >>, used above, is
1443 the numerical comparison operator.
1444
1445 If you have a complicated function needed to pull out the part you
1446 want to sort on, then don't do it inside the sort function.  Pull it
1447 out first, because the sort BLOCK can be called many times for the
1448 same element.  Here's an example of how to pull out the first word
1449 after the first number on each item, and then sort those words
1450 case-insensitively.
1451
1452     @idx = ();
1453     for (@data) {
1454         ($item) = /\d+\s*(\S+)/;
1455         push @idx, uc($item);
1456     }
1457     @sorted = @data[ sort { $idx[$a] cmp $idx[$b] } 0 .. $#idx ];
1458
1459 which could also be written this way, using a trick
1460 that's come to be known as the Schwartzian Transform:
1461
1462     @sorted = map  { $_->[0] }
1463               sort { $a->[1] cmp $b->[1] }
1464               map  { [ $_, uc( (/\d+\s*(\S+)/)[0]) ] } @data;
1465
1466 If you need to sort on several fields, the following paradigm is useful.
1467
1468     @sorted = sort { field1($a) <=> field1($b) ||
1469                      field2($a) cmp field2($b) ||
1470                      field3($a) cmp field3($b)
1471                    }     @data;
1472
1473 This can be conveniently combined with precalculation of keys as given
1474 above.
1475
1476 See the F<sort> artitcle article in the "Far More Than You Ever Wanted
1477 To Know" collection in http://www.cpan.org/olddoc/FMTEYEWTK.tgz for
1478 more about this approach.
1479
1480 See also the question below on sorting hashes.
1481
1482 =head2 How do I manipulate arrays of bits?
1483
1484 Use pack() and unpack(), or else vec() and the bitwise operations.
1485
1486 For example, this sets $vec to have bit N set if $ints[N] was set:
1487
1488     $vec = '';
1489     foreach(@ints) { vec($vec,$_,1) = 1 }
1490
1491 Here's how, given a vector in $vec, you can
1492 get those bits into your @ints array:
1493
1494     sub bitvec_to_list {
1495         my $vec = shift;
1496         my @ints;
1497         # Find null-byte density then select best algorithm
1498         if ($vec =~ tr/\0// / length $vec > 0.95) {
1499             use integer;
1500             my $i;
1501             # This method is faster with mostly null-bytes
1502             while($vec =~ /[^\0]/g ) {
1503                 $i = -9 + 8 * pos $vec;
1504                 push @ints, $i if vec($vec, ++$i, 1);
1505                 push @ints, $i if vec($vec, ++$i, 1);
1506                 push @ints, $i if vec($vec, ++$i, 1);
1507                 push @ints, $i if vec($vec, ++$i, 1);
1508                 push @ints, $i if vec($vec, ++$i, 1);
1509                 push @ints, $i if vec($vec, ++$i, 1);
1510                 push @ints, $i if vec($vec, ++$i, 1);
1511                 push @ints, $i if vec($vec, ++$i, 1);
1512             }
1513         } else {
1514             # This method is a fast general algorithm
1515             use integer;
1516             my $bits = unpack "b*", $vec;
1517             push @ints, 0 if $bits =~ s/^(\d)// && $1;
1518             push @ints, pos $bits while($bits =~ /1/g);
1519         }
1520         return \@ints;
1521     }
1522
1523 This method gets faster the more sparse the bit vector is.
1524 (Courtesy of Tim Bunce and Winfried Koenig.)
1525
1526 Or use the CPAN module Bit::Vector:
1527
1528     $vector = Bit::Vector->new($num_of_bits);
1529     $vector->Index_List_Store(@ints);
1530     @ints = $vector->Index_List_Read();
1531
1532 Bit::Vector provides efficient methods for bit vector, sets of small integers
1533 and "big int" math. 
1534
1535 Here's a more extensive illustration using vec():
1536
1537     # vec demo
1538     $vector = "\xff\x0f\xef\xfe";
1539     print "Ilya's string \\xff\\x0f\\xef\\xfe represents the number ", 
1540         unpack("N", $vector), "\n";
1541     $is_set = vec($vector, 23, 1);
1542     print "Its 23rd bit is ", $is_set ? "set" : "clear", ".\n";
1543     pvec($vector);
1544
1545     set_vec(1,1,1);
1546     set_vec(3,1,1);
1547     set_vec(23,1,1);
1548
1549     set_vec(3,1,3);
1550     set_vec(3,2,3);
1551     set_vec(3,4,3);
1552     set_vec(3,4,7);
1553     set_vec(3,8,3);
1554     set_vec(3,8,7);
1555
1556     set_vec(0,32,17);
1557     set_vec(1,32,17);
1558
1559     sub set_vec { 
1560         my ($offset, $width, $value) = @_;
1561         my $vector = '';
1562         vec($vector, $offset, $width) = $value;
1563         print "offset=$offset width=$width value=$value\n";
1564         pvec($vector);
1565     }
1566
1567     sub pvec {
1568         my $vector = shift;
1569         my $bits = unpack("b*", $vector);
1570         my $i = 0;
1571         my $BASE = 8;
1572
1573         print "vector length in bytes: ", length($vector), "\n";
1574         @bytes = unpack("A8" x length($vector), $bits);
1575         print "bits are: @bytes\n\n";
1576     } 
1577
1578 =head2 Why does defined() return true on empty arrays and hashes?
1579
1580 The short story is that you should probably only use defined on scalars or
1581 functions, not on aggregates (arrays and hashes).  See L<perlfunc/defined>
1582 in the 5.004 release or later of Perl for more detail.
1583
1584 =head1 Data: Hashes (Associative Arrays)
1585
1586 =head2 How do I process an entire hash?
1587
1588 Use the each() function (see L<perlfunc/each>) if you don't care
1589 whether it's sorted:
1590
1591     while ( ($key, $value) = each %hash) {
1592         print "$key = $value\n";
1593     }
1594
1595 If you want it sorted, you'll have to use foreach() on the result of
1596 sorting the keys as shown in an earlier question.
1597
1598 =head2 What happens if I add or remove keys from a hash while iterating over it?
1599
1600 Don't do that. :-)
1601
1602 [lwall] In Perl 4, you were not allowed to modify a hash at all while
1603 iterating over it.  In Perl 5 you can delete from it, but you still
1604 can't add to it, because that might cause a doubling of the hash table,
1605 in which half the entries get copied up to the new top half of the
1606 table, at which point you've totally bamboozled the iterator code.
1607 Even if the table doesn't double, there's no telling whether your new
1608 entry will be inserted before or after the current iterator position.
1609
1610 Either treasure up your changes and make them after the iterator finishes
1611 or use keys to fetch all the old keys at once, and iterate over the list
1612 of keys.
1613
1614 =head2 How do I look up a hash element by value?
1615
1616 Create a reverse hash:
1617
1618     %by_value = reverse %by_key;
1619     $key = $by_value{$value};
1620
1621 That's not particularly efficient.  It would be more space-efficient
1622 to use:
1623
1624     while (($key, $value) = each %by_key) {
1625         $by_value{$value} = $key;
1626     }
1627
1628 If your hash could have repeated values, the methods above will only find
1629 one of the associated keys.   This may or may not worry you.  If it does
1630 worry you, you can always reverse the hash into a hash of arrays instead:
1631
1632      while (($key, $value) = each %by_key) {
1633          push @{$key_list_by_value{$value}}, $key;
1634      }
1635
1636 =head2 How can I know how many entries are in a hash?
1637
1638 If you mean how many keys, then all you have to do is
1639 use the keys() function in a scalar context:
1640
1641     $num_keys = keys %hash;
1642
1643 The keys() function also resets the iterator, which means that you may 
1644 see strange results if you use this between uses of other hash operators 
1645 such as each().
1646
1647 =head2 How do I sort a hash (optionally by value instead of key)?
1648
1649 Internally, hashes are stored in a way that prevents you from imposing
1650 an order on key-value pairs.  Instead, you have to sort a list of the
1651 keys or values:
1652
1653     @keys = sort keys %hash;    # sorted by key
1654     @keys = sort {
1655                     $hash{$a} cmp $hash{$b}
1656             } keys %hash;       # and by value
1657
1658 Here we'll do a reverse numeric sort by value, and if two keys are
1659 identical, sort by length of key, or if that fails, by straight ASCII
1660 comparison of the keys (well, possibly modified by your locale--see
1661 L<perllocale>).
1662
1663     @keys = sort {
1664                 $hash{$b} <=> $hash{$a}
1665                           ||
1666                 length($b) <=> length($a)
1667                           ||
1668                       $a cmp $b
1669     } keys %hash;
1670
1671 =head2 How can I always keep my hash sorted?
1672
1673 You can look into using the DB_File module and tie() using the
1674 $DB_BTREE hash bindings as documented in L<DB_File/"In Memory Databases">.
1675 The Tie::IxHash module from CPAN might also be instructive.
1676
1677 =head2 What's the difference between "delete" and "undef" with hashes?
1678
1679 Hashes are pairs of scalars: the first is the key, the second is the
1680 value.  The key will be coerced to a string, although the value can be
1681 any kind of scalar: string, number, or reference.  If a key C<$key> is
1682 present in the array, C<exists($key)> will return true.  The value for
1683 a given key can be C<undef>, in which case C<$array{$key}> will be
1684 C<undef> while C<$exists{$key}> will return true.  This corresponds to
1685 (C<$key>, C<undef>) being in the hash.
1686
1687 Pictures help...  here's the C<%ary> table:
1688
1689           keys  values
1690         +------+------+
1691         |  a   |  3   |
1692         |  x   |  7   |
1693         |  d   |  0   |
1694         |  e   |  2   |
1695         +------+------+
1696
1697 And these conditions hold
1698
1699         $ary{'a'}                       is true
1700         $ary{'d'}                       is false
1701         defined $ary{'d'}               is true
1702         defined $ary{'a'}               is true
1703         exists $ary{'a'}                is true (Perl5 only)
1704         grep ($_ eq 'a', keys %ary)     is true
1705
1706 If you now say
1707
1708         undef $ary{'a'}
1709
1710 your table now reads:
1711
1712
1713           keys  values
1714         +------+------+
1715         |  a   | undef|
1716         |  x   |  7   |
1717         |  d   |  0   |
1718         |  e   |  2   |
1719         +------+------+
1720
1721 and these conditions now hold; changes in caps:
1722
1723         $ary{'a'}                       is FALSE
1724         $ary{'d'}                       is false
1725         defined $ary{'d'}               is true
1726         defined $ary{'a'}               is FALSE
1727         exists $ary{'a'}                is true (Perl5 only)
1728         grep ($_ eq 'a', keys %ary)     is true
1729
1730 Notice the last two: you have an undef value, but a defined key!
1731
1732 Now, consider this:
1733
1734         delete $ary{'a'}
1735
1736 your table now reads:
1737
1738           keys  values
1739         +------+------+
1740         |  x   |  7   |
1741         |  d   |  0   |
1742         |  e   |  2   |
1743         +------+------+
1744
1745 and these conditions now hold; changes in caps:
1746
1747         $ary{'a'}                       is false
1748         $ary{'d'}                       is false
1749         defined $ary{'d'}               is true
1750         defined $ary{'a'}               is false
1751         exists $ary{'a'}                is FALSE (Perl5 only)
1752         grep ($_ eq 'a', keys %ary)     is FALSE
1753
1754 See, the whole entry is gone!
1755
1756 =head2 Why don't my tied hashes make the defined/exists distinction?
1757
1758 They may or may not implement the EXISTS() and DEFINED() methods
1759 differently.  For example, there isn't the concept of undef with hashes
1760 that are tied to DBM* files. This means the true/false tables above
1761 will give different results when used on such a hash.  It also means
1762 that exists and defined do the same thing with a DBM* file, and what
1763 they end up doing is not what they do with ordinary hashes.
1764
1765 =head2 How do I reset an each() operation part-way through?
1766
1767 Using C<keys %hash> in scalar context returns the number of keys in
1768 the hash I<and> resets the iterator associated with the hash.  You may
1769 need to do this if you use C<last> to exit a loop early so that when you
1770 re-enter it, the hash iterator has been reset.
1771
1772 =head2 How can I get the unique keys from two hashes?
1773
1774 First you extract the keys from the hashes into lists, then solve
1775 the "removing duplicates" problem described above.  For example:
1776
1777     %seen = ();
1778     for $element (keys(%foo), keys(%bar)) {
1779         $seen{$element}++;
1780     }
1781     @uniq = keys %seen;
1782
1783 Or more succinctly:
1784
1785     @uniq = keys %{{%foo,%bar}};
1786
1787 Or if you really want to save space:
1788
1789     %seen = ();
1790     while (defined ($key = each %foo)) {
1791         $seen{$key}++;
1792     }
1793     while (defined ($key = each %bar)) {
1794         $seen{$key}++;
1795     }
1796     @uniq = keys %seen;
1797
1798 =head2 How can I store a multidimensional array in a DBM file?
1799
1800 Either stringify the structure yourself (no fun), or else
1801 get the MLDBM (which uses Data::Dumper) module from CPAN and layer
1802 it on top of either DB_File or GDBM_File.
1803
1804 =head2 How can I make my hash remember the order I put elements into it?
1805
1806 Use the Tie::IxHash from CPAN.
1807
1808     use Tie::IxHash;
1809     tie(%myhash, Tie::IxHash);
1810     for ($i=0; $i<20; $i++) {
1811         $myhash{$i} = 2*$i;
1812     }
1813     @keys = keys %myhash;
1814     # @keys = (0,1,2,3,...)
1815
1816 =head2 Why does passing a subroutine an undefined element in a hash create it?
1817
1818 If you say something like:
1819
1820     somefunc($hash{"nonesuch key here"});
1821
1822 Then that element "autovivifies"; that is, it springs into existence
1823 whether you store something there or not.  That's because functions
1824 get scalars passed in by reference.  If somefunc() modifies C<$_[0]>,
1825 it has to be ready to write it back into the caller's version.
1826
1827 This has been fixed as of Perl5.004.
1828
1829 Normally, merely accessing a key's value for a nonexistent key does
1830 I<not> cause that key to be forever there.  This is different than
1831 awk's behavior.
1832
1833 =head2 How can I make the Perl equivalent of a C structure/C++ class/hash or array of hashes or arrays?
1834
1835 Usually a hash ref, perhaps like this:
1836
1837     $record = {
1838         NAME   => "Jason",
1839         EMPNO  => 132,
1840         TITLE  => "deputy peon",
1841         AGE    => 23,
1842         SALARY => 37_000,
1843         PALS   => [ "Norbert", "Rhys", "Phineas"],
1844     };
1845
1846 References are documented in L<perlref> and the upcoming L<perlreftut>.
1847 Examples of complex data structures are given in L<perldsc> and
1848 L<perllol>.  Examples of structures and object-oriented classes are
1849 in L<perltoot>.
1850
1851 =head2 How can I use a reference as a hash key?
1852
1853 You can't do this directly, but you could use the standard Tie::RefHash
1854 module distributed with Perl.
1855
1856 =head1 Data: Misc
1857
1858 =head2 How do I handle binary data correctly?
1859
1860 Perl is binary clean, so this shouldn't be a problem.  For example,
1861 this works fine (assuming the files are found):
1862
1863     if (`cat /vmunix` =~ /gzip/) {
1864         print "Your kernel is GNU-zip enabled!\n";
1865     }
1866
1867 On less elegant (read: Byzantine) systems, however, you have
1868 to play tedious games with "text" versus "binary" files.  See
1869 L<perlfunc/"binmode"> or L<perlopentut>.  Most of these ancient-thinking
1870 systems are curses out of Microsoft, who seem to be committed to putting
1871 the backward into backward compatibility.
1872
1873 If you're concerned about 8-bit ASCII data, then see L<perllocale>.
1874
1875 If you want to deal with multibyte characters, however, there are
1876 some gotchas.  See the section on Regular Expressions.
1877
1878 =head2 How do I determine whether a scalar is a number/whole/integer/float?
1879
1880 Assuming that you don't care about IEEE notations like "NaN" or
1881 "Infinity", you probably just want to use a regular expression.
1882
1883    if (/\D/)            { print "has nondigits\n" }
1884    if (/^\d+$/)         { print "is a whole number\n" }
1885    if (/^-?\d+$/)       { print "is an integer\n" }
1886    if (/^[+-]?\d+$/)    { print "is a +/- integer\n" }
1887    if (/^-?\d+\.?\d*$/) { print "is a real number\n" }
1888    if (/^-?(?:\d+(?:\.\d*)?|\.\d+)$/) { print "is a decimal number" }
1889    if (/^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/)
1890                         { print "a C float" }
1891
1892 If you're on a POSIX system, Perl's supports the C<POSIX::strtod>
1893 function.  Its semantics are somewhat cumbersome, so here's a C<getnum>
1894 wrapper function for more convenient access.  This function takes
1895 a string and returns the number it found, or C<undef> for input that
1896 isn't a C float.  The C<is_numeric> function is a front end to C<getnum>
1897 if you just want to say, ``Is this a float?''
1898
1899     sub getnum {
1900         use POSIX qw(strtod);
1901         my $str = shift;
1902         $str =~ s/^\s+//;
1903         $str =~ s/\s+$//;
1904         $! = 0;
1905         my($num, $unparsed) = strtod($str);
1906         if (($str eq '') || ($unparsed != 0) || $!) {
1907             return undef;
1908         } else {
1909             return $num;
1910         } 
1911     } 
1912
1913     sub is_numeric { defined getnum($_[0]) } 
1914
1915 Or you could check out the String::Scanf module on CPAN instead.  The
1916 POSIX module (part of the standard Perl distribution) provides the
1917 C<strtod> and C<strtol> for converting strings to double and longs,
1918 respectively.
1919
1920 =head2 How do I keep persistent data across program calls?
1921
1922 For some specific applications, you can use one of the DBM modules.
1923 See L<AnyDBM_File>.  More generically, you should consult the FreezeThaw
1924 or Storable modules from CPAN.  Starting from Perl 5.8 Storable is part
1925 of the standard distribution.  Here's one example using Storable's C<store>
1926 and C<retrieve> functions:
1927
1928     use Storable; 
1929     store(\%hash, "filename");
1930
1931     # later on...  
1932     $href = retrieve("filename");        # by ref
1933     %hash = %{ retrieve("filename") };   # direct to hash
1934
1935 =head2 How do I print out or copy a recursive data structure?
1936
1937 The Data::Dumper module on CPAN (or the 5.005 release of Perl) is great
1938 for printing out data structures.  The Storable module, found on CPAN,
1939 provides a function called C<dclone> that recursively copies its argument.
1940
1941     use Storable qw(dclone); 
1942     $r2 = dclone($r1);
1943
1944 Where $r1 can be a reference to any kind of data structure you'd like.
1945 It will be deeply copied.  Because C<dclone> takes and returns references,
1946 you'd have to add extra punctuation if you had a hash of arrays that
1947 you wanted to copy.
1948
1949     %newhash = %{ dclone(\%oldhash) };
1950
1951 =head2 How do I define methods for every class/object?
1952
1953 Use the UNIVERSAL class (see L<UNIVERSAL>).
1954
1955 =head2 How do I verify a credit card checksum?
1956
1957 Get the Business::CreditCard module from CPAN.
1958
1959 =head2 How do I pack arrays of doubles or floats for XS code?
1960
1961 The kgbpack.c code in the PGPLOT module on CPAN does just this.
1962 If you're doing a lot of float or double processing, consider using
1963 the PDL module from CPAN instead--it makes number-crunching easy.
1964
1965 =head1 AUTHOR AND COPYRIGHT
1966
1967 Copyright (c) 1997-2002 Tom Christiansen and Nathan Torkington.
1968 All rights reserved.
1969
1970 This documentation is free; you can redistribute it and/or modify it
1971 under the same terms as Perl itself.
1972
1973 Irrespective of its distribution, all code examples in this file
1974 are hereby placed into the public domain.  You are permitted and
1975 encouraged to use this code in your own programs for fun
1976 or for profit as you see fit.  A simple comment in the code giving
1977 credit would be courteous but is not required.