This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
mktables: Refactor if-else series
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25 require 5.010_001;
26 use strict;
27 use warnings;
28 use Carp;
29 use Config;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34 use re "/aa";
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 ##########################################################################
40 #
41 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
42 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
43 # a pod file and a .t file
44 #
45 # The structure of this file is:
46 #   First these introductory comments; then
47 #   code needed for everywhere, such as debugging stuff; then
48 #   code to handle input parameters; then
49 #   data structures likely to be of external interest (some of which depend on
50 #       the input parameters, so follows them; then
51 #   more data structures and subroutine and package (class) definitions; then
52 #   the small actual loop to process the input files and finish up; then
53 #   a __DATA__ section, for the .t tests
54 #
55 # This program works on all releases of Unicode through at least 6.0.  The
56 # outputs have been scrutinized most intently for release 5.1.  The others
57 # have been checked for somewhat more than just sanity.  It can handle all
58 # existing Unicode character properties in those releases.
59 #
60 # This program is mostly about Unicode character (or code point) properties.
61 # A property describes some attribute or quality of a code point, like if it
62 # is lowercase or not, its name, what version of Unicode it was first defined
63 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
64 # possibilities by making all properties into mappings from each code point
65 # into some corresponding value.  In the case of it being lowercase or not,
66 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
67 # property maps each Unicode code point to a single value, called a "property
68 # value".  (Hence each Unicode property is a true mathematical function with
69 # exactly one value per code point.)
70 #
71 # When using a property in a regular expression, what is desired isn't the
72 # mapping of the code point to its property's value, but the reverse (or the
73 # mathematical "inverse relation"): starting with the property value, "Does a
74 # code point map to it?"  These are written in a "compound" form:
75 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
76 # files containing the lists of code points that map to each such regular
77 # expression property value, one file per list
78 #
79 # There is also a single form shortcut that Perl adds for many of the commonly
80 # used properties.  This happens for all binary properties, plus script,
81 # general_category, and block properties.
82 #
83 # Thus the outputs of this program are files.  There are map files, mostly in
84 # the 'To' directory; and there are list files for use in regular expression
85 # matching, all in subdirectories of the 'lib' directory, with each
86 # subdirectory being named for the property that the lists in it are for.
87 # Bookkeeping, test, and documentation files are also generated.
88
89 my $matches_directory = 'lib';   # Where match (\p{}) files go.
90 my $map_directory = 'To';        # Where map files go.
91
92 # DATA STRUCTURES
93 #
94 # The major data structures of this program are Property, of course, but also
95 # Table.  There are two kinds of tables, very similar to each other.
96 # "Match_Table" is the data structure giving the list of code points that have
97 # a particular property value, mentioned above.  There is also a "Map_Table"
98 # data structure which gives the property's mapping from code point to value.
99 # There are two structures because the match tables need to be combined in
100 # various ways, such as constructing unions, intersections, complements, etc.,
101 # and the map ones don't.  And there would be problems, perhaps subtle, if
102 # a map table were inadvertently operated on in some of those ways.
103 # The use of separate classes with operations defined on one but not the other
104 # prevents accidentally confusing the two.
105 #
106 # At the heart of each table's data structure is a "Range_List", which is just
107 # an ordered list of "Ranges", plus ancillary information, and methods to
108 # operate on them.  A Range is a compact way to store property information.
109 # Each range has a starting code point, an ending code point, and a value that
110 # is meant to apply to all the code points between the two end points,
111 # inclusive.  For a map table, this value is the property value for those
112 # code points.  Two such ranges could be written like this:
113 #   0x41 .. 0x5A, 'Upper',
114 #   0x61 .. 0x7A, 'Lower'
115 #
116 # Each range also has a type used as a convenience to classify the values.
117 # Most ranges in this program will be Type 0, or normal, but there are some
118 # ranges that have a non-zero type.  These are used only in map tables, and
119 # are for mappings that don't fit into the normal scheme of things.  Mappings
120 # that require a hash entry to communicate with utf8.c are one example;
121 # another example is mappings for charnames.pm to use which indicate a name
122 # that is algorithmically determinable from its code point (and vice-versa).
123 # These are used to significantly compact these tables, instead of listing
124 # each one of the tens of thousands individually.
125 #
126 # In a match table, the value of a range is irrelevant (and hence the type as
127 # well, which will always be 0), and arbitrarily set to the null string.
128 # Using the example above, there would be two match tables for those two
129 # entries, one named Upper would contain the 0x41..0x5A range, and the other
130 # named Lower would contain 0x61..0x7A.
131 #
132 # Actually, there are two types of range lists, "Range_Map" is the one
133 # associated with map tables, and "Range_List" with match tables.
134 # Again, this is so that methods can be defined on one and not the other so as
135 # to prevent operating on them in incorrect ways.
136 #
137 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
138 # in the perl core.  All tables could in theory be written, but some are
139 # suppressed because there is no current practical use for them.  It is easy
140 # to change which get written by changing various lists that are near the top
141 # of the actual code in this file.  The table data structures contain enough
142 # ancillary information to allow them to be treated as separate entities for
143 # writing, such as the path to each one's file.  There is a heading in each
144 # map table that gives the format of its entries, and what the map is for all
145 # the code points missing from it.  (This allows tables to be more compact.)
146 #
147 # The Property data structure contains one or more tables.  All properties
148 # contain a map table (except the $perl property which is a
149 # pseudo-property containing only match tables), and any properties that
150 # are usable in regular expression matches also contain various matching
151 # tables, one for each value the property can have.  A binary property can
152 # have two values, True and False (or Y and N, which are preferred by Unicode
153 # terminology).  Thus each of these properties will have a map table that
154 # takes every code point and maps it to Y or N (but having ranges cuts the
155 # number of entries in that table way down), and two match tables, one
156 # which has a list of all the code points that map to Y, and one for all the
157 # code points that map to N.  (For each of these, a third table is also
158 # generated for the pseudo Perl property.  It contains the identical code
159 # points as the Y table, but can be written, not in the compound form, but in
160 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
161 # properties have several possible values, some have many, and properties like
162 # Name have a different value for every named code point.  Those will not,
163 # unless the controlling lists are changed, have their match tables written
164 # out.  But all the ones which can be used in regular expression \p{} and \P{}
165 # constructs will.  Prior to 5.14, generally a property would have either its
166 # map table or its match tables written but not both.  Again, what gets
167 # written is controlled by lists which can easily be changed.  Starting in
168 # 5.14, advantage was taken of this, and all the map tables needed to
169 # reconstruct the Unicode db are now written out, while suppressing the
170 # Unicode .txt files that contain the data.  Our tables are much more compact
171 # than the .txt files, so a significant space savings was achieved.
172
173 # Properties have a 'Type', like binary, or string, or enum depending on how
174 # many match tables there are and the content of the maps.  This 'Type' is
175 # different than a range 'Type', so don't get confused by the two concepts
176 # having the same name.
177 #
178 # For information about the Unicode properties, see Unicode's UAX44 document:
179
180 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
181
182 # As stated earlier, this program will work on any release of Unicode so far.
183 # Most obvious problems in earlier data have NOT been corrected except when
184 # necessary to make Perl or this program work reasonably.  For example, no
185 # folding information was given in early releases, so this program substitutes
186 # lower case instead, just so that a regular expression with the /i option
187 # will do something that actually gives the right results in many cases.
188 # There are also a couple other corrections for version 1.1.5, commented at
189 # the point they are made.  As an example of corrections that weren't made
190 # (but could be) is this statement from DerivedAge.txt: "The supplementary
191 # private use code points and the non-character code points were assigned in
192 # version 2.0, but not specifically listed in the UCD until versions 3.0 and
193 # 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0) More information
194 # on Unicode version glitches is further down in these introductory comments.
195 #
196 # This program works on all non-provisional properties as of 6.0, though the
197 # files for some are suppressed from apparent lack of demand for them.  You
198 # can change which are output by changing lists in this program.
199 #
200 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
201 # loose matchings rules (from Unicode TR18):
202 #
203 #    The recommended names for UCD properties and property values are in
204 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
205 #    [PropValue]. There are both abbreviated names and longer, more
206 #    descriptive names. It is strongly recommended that both names be
207 #    recognized, and that loose matching of property names be used,
208 #    whereby the case distinctions, whitespace, hyphens, and underbar
209 #    are ignored.
210 # The program still allows Fuzzy to override its determination of if loose
211 # matching should be used, but it isn't currently used, as it is no longer
212 # needed; the calculations it makes are good enough.
213 #
214 # SUMMARY OF HOW IT WORKS:
215 #
216 #   Process arguments
217 #
218 #   A list is constructed containing each input file that is to be processed
219 #
220 #   Each file on the list is processed in a loop, using the associated handler
221 #   code for each:
222 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
223 #            first.  These files name the properties and property values.
224 #            Objects are created of all the property and property value names
225 #            that the rest of the input should expect, including all synonyms.
226 #        The other input files give mappings from properties to property
227 #           values.  That is, they list code points and say what the mapping
228 #           is under the given property.  Some files give the mappings for
229 #           just one property; and some for many.  This program goes through
230 #           each file and populates the properties from them.  Some properties
231 #           are listed in more than one file, and Unicode has set up a
232 #           precedence as to which has priority if there is a conflict.  Thus
233 #           the order of processing matters, and this program handles the
234 #           conflict possibility by processing the overriding input files
235 #           last, so that if necessary they replace earlier values.
236 #        After this is all done, the program creates the property mappings not
237 #            furnished by Unicode, but derivable from what it does give.
238 #        The tables of code points that match each property value in each
239 #            property that is accessible by regular expressions are created.
240 #        The Perl-defined properties are created and populated.  Many of these
241 #            require data determined from the earlier steps
242 #        Any Perl-defined synonyms are created, and name clashes between Perl
243 #            and Unicode are reconciled and warned about.
244 #        All the properties are written to files
245 #        Any other files are written, and final warnings issued.
246 #
247 # For clarity, a number of operators have been overloaded to work on tables:
248 #   ~ means invert (take all characters not in the set).  The more
249 #       conventional '!' is not used because of the possibility of confusing
250 #       it with the actual boolean operation.
251 #   + means union
252 #   - means subtraction
253 #   & means intersection
254 # The precedence of these is the order listed.  Parentheses should be
255 # copiously used.  These are not a general scheme.  The operations aren't
256 # defined for a number of things, deliberately, to avoid getting into trouble.
257 # Operations are done on references and affect the underlying structures, so
258 # that the copy constructors for them have been overloaded to not return a new
259 # clone, but the input object itself.
260 #
261 # The bool operator is deliberately not overloaded to avoid confusion with
262 # "should it mean if the object merely exists, or also is non-empty?".
263 #
264 # WHY CERTAIN DESIGN DECISIONS WERE MADE
265 #
266 # This program needs to be able to run under miniperl.  Therefore, it uses a
267 # minimum of other modules, and hence implements some things itself that could
268 # be gotten from CPAN
269 #
270 # This program uses inputs published by the Unicode Consortium.  These can
271 # change incompatibly between releases without the Perl maintainers realizing
272 # it.  Therefore this program is now designed to try to flag these.  It looks
273 # at the directories where the inputs are, and flags any unrecognized files.
274 # It keeps track of all the properties in the files it handles, and flags any
275 # that it doesn't know how to handle.  It also flags any input lines that
276 # don't match the expected syntax, among other checks.
277 #
278 # It is also designed so if a new input file matches one of the known
279 # templates, one hopefully just needs to add it to a list to have it
280 # processed.
281 #
282 # As mentioned earlier, some properties are given in more than one file.  In
283 # particular, the files in the extracted directory are supposedly just
284 # reformattings of the others.  But they contain information not easily
285 # derivable from the other files, including results for Unihan, which this
286 # program doesn't ordinarily look at, and for unassigned code points.  They
287 # also have historically had errors or been incomplete.  In an attempt to
288 # create the best possible data, this program thus processes them first to
289 # glean information missing from the other files; then processes those other
290 # files to override any errors in the extracted ones.  Much of the design was
291 # driven by this need to store things and then possibly override them.
292 #
293 # It tries to keep fatal errors to a minimum, to generate something usable for
294 # testing purposes.  It always looks for files that could be inputs, and will
295 # warn about any that it doesn't know how to handle (the -q option suppresses
296 # the warning).
297 #
298 # Why is there more than one type of range?
299 #   This simplified things.  There are some very specialized code points that
300 #   have to be handled specially for output, such as Hangul syllable names.
301 #   By creating a range type (done late in the development process), it
302 #   allowed this to be stored with the range, and overridden by other input.
303 #   Originally these were stored in another data structure, and it became a
304 #   mess trying to decide if a second file that was for the same property was
305 #   overriding the earlier one or not.
306 #
307 # Why are there two kinds of tables, match and map?
308 #   (And there is a base class shared by the two as well.)  As stated above,
309 #   they actually are for different things.  Development proceeded much more
310 #   smoothly when I (khw) realized the distinction.  Map tables are used to
311 #   give the property value for every code point (actually every code point
312 #   that doesn't map to a default value).  Match tables are used for regular
313 #   expression matches, and are essentially the inverse mapping.  Separating
314 #   the two allows more specialized methods, and error checks so that one
315 #   can't just take the intersection of two map tables, for example, as that
316 #   is nonsensical.
317 #
318 # DEBUGGING
319 #
320 # This program is written so it will run under miniperl.  Occasionally changes
321 # will cause an error where the backtrace doesn't work well under miniperl.
322 # To diagnose the problem, you can instead run it under regular perl, if you
323 # have one compiled.
324 #
325 # There is a good trace facility.  To enable it, first sub DEBUG must be set
326 # to return true.  Then a line like
327 #
328 # local $to_trace = 1 if main::DEBUG;
329 #
330 # can be added to enable tracing in its lexical scope or until you insert
331 # another line:
332 #
333 # local $to_trace = 0 if main::DEBUG;
334 #
335 # then use a line like "trace $a, @b, %c, ...;
336 #
337 # Some of the more complex subroutines already have trace statements in them.
338 # Permanent trace statements should be like:
339 #
340 # trace ... if main::DEBUG && $to_trace;
341 #
342 # If there is just one or a few files that you're debugging, you can easily
343 # cause most everything else to be skipped.  Change the line
344 #
345 # my $debug_skip = 0;
346 #
347 # to 1, and every file whose object is in @input_file_objects and doesn't have
348 # a, 'non_skip => 1,' in its constructor will be skipped.
349 #
350 # To compare the output tables, it may be useful to specify the -annotate
351 # flag.  This causes the tables to expand so there is one entry for each
352 # non-algorithmically named code point giving, currently its name, and its
353 # graphic representation if printable (and you have a font that knows about
354 # it).  This makes it easier to see what the particular code points are in
355 # each output table.  The tables are usable, but because they don't have
356 # ranges (for the most part), a Perl using them will run slower.  Non-named
357 # code points are annotated with a description of their status, and contiguous
358 # ones with the same description will be output as a range rather than
359 # individually.  Algorithmically named characters are also output as ranges,
360 # except when there are just a few contiguous ones.
361 #
362 # FUTURE ISSUES
363 #
364 # The program would break if Unicode were to change its names so that
365 # interior white space, underscores, or dashes differences were significant
366 # within property and property value names.
367 #
368 # It might be easier to use the xml versions of the UCD if this program ever
369 # would need heavy revision, and the ability to handle old versions was not
370 # required.
371 #
372 # There is the potential for name collisions, in that Perl has chosen names
373 # that Unicode could decide it also likes.  There have been such collisions in
374 # the past, with mostly Perl deciding to adopt the Unicode definition of the
375 # name.  However in the 5.2 Unicode beta testing, there were a number of such
376 # collisions, which were withdrawn before the final release, because of Perl's
377 # and other's protests.  These all involved new properties which began with
378 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
379 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
380 # Unicode document, so they are unlikely to be used by Unicode for another
381 # purpose.  However, they might try something beginning with 'In', or use any
382 # of the other Perl-defined properties.  This program will warn you of name
383 # collisions, and refuse to generate tables with them, but manual intervention
384 # will be required in this event.  One scheme that could be implemented, if
385 # necessary, would be to have this program generate another file, or add a
386 # field to mktables.lst that gives the date of first definition of a property.
387 # Each new release of Unicode would use that file as a basis for the next
388 # iteration.  And the Perl synonym addition code could sort based on the age
389 # of the property, so older properties get priority, and newer ones that clash
390 # would be refused; hence existing code would not be impacted, and some other
391 # synonym would have to be used for the new property.  This is ugly, and
392 # manual intervention would certainly be easier to do in the short run; lets
393 # hope it never comes to this.
394 #
395 # A NOTE ON UNIHAN
396 #
397 # This program can generate tables from the Unihan database.  But it doesn't
398 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
399 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
400 # database was split into 8 different files, all beginning with the letters
401 # 'Unihan'.  This program will read those file(s) if present, but it needs to
402 # know which of the many properties in the file(s) should have tables created
403 # for them.  It will create tables for any properties listed in
404 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
405 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
406 # property you want is not in those files of the release you are building
407 # against, you must add it to those two arrays.  Starting in 4.0, the
408 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
409 # is present in the directory, a table will be generated for that property.
410 # In 5.2, several more properties were added.  For your convenience, the two
411 # arrays are initialized with all the 6.0 listed properties that are also in
412 # earlier releases.  But these are commented out.  You can just uncomment the
413 # ones you want, or use them as a template for adding entries for other
414 # properties.
415 #
416 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
417 # and filter_unihan_line() are the functions where this is done.  This program
418 # already does some adjusting to make the lines look more like the rest of the
419 # Unicode DB;  You can see what that is in filter_unihan_line()
420 #
421 # There is a bug in the 3.2 data file in which some values for the
422 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
423 # could be added for these; or for a particular installation, the Unihan.txt
424 # file could be edited to fix them.
425 #
426 # HOW TO ADD A FILE TO BE PROCESSED
427 #
428 # A new file from Unicode needs to have an object constructed for it in
429 # @input_file_objects, probably at the end or at the end of the extracted
430 # ones.  The program should warn you if its name will clash with others on
431 # restrictive file systems, like DOS.  If so, figure out a better name, and
432 # add lines to the README.perl file giving that.  If the file is a character
433 # property, it should be in the format that Unicode has by default
434 # standardized for such files for the more recently introduced ones.
435 # If so, the Input_file constructor for @input_file_objects can just be the
436 # file name and release it first appeared in.  If not, then it should be
437 # possible to construct an each_line_handler() to massage the line into the
438 # standardized form.
439 #
440 # For non-character properties, more code will be needed.  You can look at
441 # the existing entries for clues.
442 #
443 # UNICODE VERSIONS NOTES
444 #
445 # The Unicode UCD has had a number of errors in it over the versions.  And
446 # these remain, by policy, in the standard for that version.  Therefore it is
447 # risky to correct them, because code may be expecting the error.  So this
448 # program doesn't generally make changes, unless the error breaks the Perl
449 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
450 # for U+1105, which causes real problems for the algorithms for Jamo
451 # calculations, so it is changed here.
452 #
453 # But it isn't so clear cut as to what to do about concepts that are
454 # introduced in a later release; should they extend back to earlier releases
455 # where the concept just didn't exist?  It was easier to do this than to not,
456 # so that's what was done.  For example, the default value for code points not
457 # in the files for various properties was probably undefined until changed by
458 # some version.  No_Block for blocks is such an example.  This program will
459 # assign No_Block even in Unicode versions that didn't have it.  This has the
460 # benefit that code being written doesn't have to special case earlier
461 # versions; and the detriment that it doesn't match the Standard precisely for
462 # the affected versions.
463 #
464 # Here are some observations about some of the issues in early versions:
465 #
466 # The number of code points in \p{alpha} halved in 2.1.9.  It turns out that
467 # the reason is that the CJK block starting at 4E00 was removed from PropList,
468 # and was not put back in until 3.1.0
469 #
470 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
471 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
472 # reason is that 3.2 introduced U+205F=medium math space, which was not
473 # classed as white space, but Perl figured out that it should have been. 4.0
474 # reclassified it correctly.
475 #
476 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
477 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
478 # was left with no code points, as all the ones that mapped to 202 stayed
479 # mapped to 202.  Thus if your program used the numeric name for the class,
480 # it would not have been affected, but if it used the mnemonic, it would have
481 # been.
482 #
483 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
484 # points which eventually came to have this script property value, instead
485 # mapped to "Unknown".  But in the next release all these code points were
486 # moved to \p{sc=common} instead.
487 #
488 # The default for missing code points for BidiClass is complicated.  Starting
489 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
490 # tries to do the best it can for earlier releases.  It is done in
491 # process_PropertyAliases()
492 #
493 ##############################################################################
494
495 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
496                         # and errors
497 my $MAX_LINE_WIDTH = 78;
498
499 # Debugging aid to skip most files so as to not be distracted by them when
500 # concentrating on the ones being debugged.  Add
501 # non_skip => 1,
502 # to the constructor for those files you want processed when you set this.
503 # Files with a first version number of 0 are special: they are always
504 # processed regardless of the state of this flag.  Generally, Jamo.txt and
505 # UnicodeData.txt must not be skipped if you want this program to not die
506 # before normal completion.
507 my $debug_skip = 0;
508
509 # Set to 1 to enable tracing.
510 our $to_trace = 0;
511
512 { # Closure for trace: debugging aid
513     my $print_caller = 1;        # ? Include calling subroutine name
514     my $main_with_colon = 'main::';
515     my $main_colon_length = length($main_with_colon);
516
517     sub trace {
518         return unless $to_trace;        # Do nothing if global flag not set
519
520         my @input = @_;
521
522         local $DB::trace = 0;
523         $DB::trace = 0;          # Quiet 'used only once' message
524
525         my $line_number;
526
527         # Loop looking up the stack to get the first non-trace caller
528         my $caller_line;
529         my $caller_name;
530         my $i = 0;
531         do {
532             $line_number = $caller_line;
533             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
534             $caller = $main_with_colon unless defined $caller;
535
536             $caller_name = $caller;
537
538             # get rid of pkg
539             $caller_name =~ s/.*:://;
540             if (substr($caller_name, 0, $main_colon_length)
541                 eq $main_with_colon)
542             {
543                 $caller_name = substr($caller_name, $main_colon_length);
544             }
545
546         } until ($caller_name ne 'trace');
547
548         # If the stack was empty, we were called from the top level
549         $caller_name = 'main' if ($caller_name eq ""
550                                     || $caller_name eq 'trace');
551
552         my $output = "";
553         foreach my $string (@input) {
554             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
555             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
556                 $output .= simple_dumper($string);
557             }
558             else {
559                 $string = "$string" if ref $string;
560                 $string = $UNDEF unless defined $string;
561                 chomp $string;
562                 $string = '""' if $string eq "";
563                 $output .= " " if $output ne ""
564                                 && $string ne ""
565                                 && substr($output, -1, 1) ne " "
566                                 && substr($string, 0, 1) ne " ";
567                 $output .= $string;
568             }
569         }
570
571         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
572         print STDERR "$caller_name: " if $print_caller;
573         print STDERR $output, "\n";
574         return;
575     }
576 }
577
578 # This is for a rarely used development feature that allows you to compare two
579 # versions of the Unicode standard without having to deal with changes caused
580 # by the code points introduced in the later version.  Change the 0 to a
581 # string containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only
582 # code points introduced in that release and earlier will be used; later ones
583 # are thrown away.  You use the version number of the earliest one you want to
584 # compare; then run this program on directory structures containing each
585 # release, and compare the outputs.  These outputs will therefore include only
586 # the code points common to both releases, and you can see the changes caused
587 # just by the underlying release semantic changes.  For versions earlier than
588 # 3.2, you must copy a version of DAge.txt into the directory.
589 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
590 my $compare_versions = DEBUG
591                        && $string_compare_versions
592                        && pack "C*", split /\./, $string_compare_versions;
593
594 sub uniques {
595     # Returns non-duplicated input values.  From "Perl Best Practices:
596     # Encapsulated Cleverness".  p. 455 in first edition.
597
598     my %seen;
599     # Arguably this breaks encapsulation, if the goal is to permit multiple
600     # distinct objects to stringify to the same value, and be interchangeable.
601     # However, for this program, no two objects stringify identically, and all
602     # lists passed to this function are either objects or strings. So this
603     # doesn't affect correctness, but it does give a couple of percent speedup.
604     no overloading;
605     return grep { ! $seen{$_}++ } @_;
606 }
607
608 $0 = File::Spec->canonpath($0);
609
610 my $make_test_script = 0;      # ? Should we output a test script
611 my $write_unchanged_files = 0; # ? Should we update the output files even if
612                                #    we don't think they have changed
613 my $use_directory = "";        # ? Should we chdir somewhere.
614 my $pod_directory;             # input directory to store the pod file.
615 my $pod_file = 'perluniprops';
616 my $t_path;                     # Path to the .t test file
617 my $file_list = 'mktables.lst'; # File to store input and output file names.
618                                # This is used to speed up the build, by not
619                                # executing the main body of the program if
620                                # nothing on the list has changed since the
621                                # previous build
622 my $make_list = 1;             # ? Should we write $file_list.  Set to always
623                                # make a list so that when the pumpking is
624                                # preparing a release, s/he won't have to do
625                                # special things
626 my $glob_list = 0;             # ? Should we try to include unknown .txt files
627                                # in the input.
628 my $output_range_counts = $debugging_build;   # ? Should we include the number
629                                               # of code points in ranges in
630                                               # the output
631 my $annotate = 0;              # ? Should character names be in the output
632
633 # Verbosity levels; 0 is quiet
634 my $NORMAL_VERBOSITY = 1;
635 my $PROGRESS = 2;
636 my $VERBOSE = 3;
637
638 my $verbosity = $NORMAL_VERBOSITY;
639
640 # Process arguments
641 while (@ARGV) {
642     my $arg = shift @ARGV;
643     if ($arg eq '-v') {
644         $verbosity = $VERBOSE;
645     }
646     elsif ($arg eq '-p') {
647         $verbosity = $PROGRESS;
648         $| = 1;     # Flush buffers as we go.
649     }
650     elsif ($arg eq '-q') {
651         $verbosity = 0;
652     }
653     elsif ($arg eq '-w') {
654         $write_unchanged_files = 1; # update the files even if havent changed
655     }
656     elsif ($arg eq '-check') {
657         my $this = shift @ARGV;
658         my $ok = shift @ARGV;
659         if ($this ne $ok) {
660             print "Skipping as check params are not the same.\n";
661             exit(0);
662         }
663     }
664     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
665         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
666     }
667     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
668     {
669         $make_test_script = 1;
670     }
671     elsif ($arg eq '-makelist') {
672         $make_list = 1;
673     }
674     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
675         -d $use_directory or croak "Unknown directory '$use_directory'";
676     }
677     elsif ($arg eq '-L') {
678
679         # Existence not tested until have chdir'd
680         $file_list = shift;
681     }
682     elsif ($arg eq '-globlist') {
683         $glob_list = 1;
684     }
685     elsif ($arg eq '-c') {
686         $output_range_counts = ! $output_range_counts
687     }
688     elsif ($arg eq '-annotate') {
689         $annotate = 1;
690         $debugging_build = 1;
691         $output_range_counts = 1;
692     }
693     else {
694         my $with_c = 'with';
695         $with_c .= 'out' if $output_range_counts;   # Complements the state
696         croak <<END;
697 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
698           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
699           [-check A B ]
700   -c          : Output comments $with_c number of code points in ranges
701   -q          : Quiet Mode: Only output serious warnings.
702   -p          : Set verbosity level to normal plus show progress.
703   -v          : Set Verbosity level high:  Show progress and non-serious
704                 warnings
705   -w          : Write files regardless
706   -C dir      : Change to this directory before proceeding. All relative paths
707                 except those specified by the -P and -T options will be done
708                 with respect to this directory.
709   -P dir      : Output $pod_file file to directory 'dir'.
710   -T path     : Create a test script as 'path'; overrides -maketest
711   -L filelist : Use alternate 'filelist' instead of standard one
712   -globlist   : Take as input all non-Test *.txt files in current and sub
713                 directories
714   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
715                 overrides -T
716   -makelist   : Rewrite the file list $file_list based on current setup
717   -annotate   : Output an annotation for each character in the table files;
718                 useful for debugging mktables, looking at diffs; but is slow,
719                 memory intensive; resulting tables are usable but are slow and
720                 very large (and currently fail the Unicode::UCD.t tests).
721   -check A B  : Executes $0 only if A and B are the same
722 END
723     }
724 }
725
726 # Stores the most-recently changed file.  If none have changed, can skip the
727 # build
728 my $most_recent = (stat $0)[9];   # Do this before the chdir!
729
730 # Change directories now, because need to read 'version' early.
731 if ($use_directory) {
732     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
733         $pod_directory = File::Spec->rel2abs($pod_directory);
734     }
735     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
736         $t_path = File::Spec->rel2abs($t_path);
737     }
738     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
739     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
740         $pod_directory = File::Spec->abs2rel($pod_directory);
741     }
742     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
743         $t_path = File::Spec->abs2rel($t_path);
744     }
745 }
746
747 # Get Unicode version into regular and v-string.  This is done now because
748 # various tables below get populated based on it.  These tables are populated
749 # here to be near the top of the file, and so easily seeable by those needing
750 # to modify things.
751 open my $VERSION, "<", "version"
752                     or croak "$0: can't open required file 'version': $!\n";
753 my $string_version = <$VERSION>;
754 close $VERSION;
755 chomp $string_version;
756 my $v_version = pack "C*", split /\./, $string_version;        # v string
757
758 # The following are the complete names of properties with property values that
759 # are known to not match any code points in some versions of Unicode, but that
760 # may change in the future so they should be matchable, hence an empty file is
761 # generated for them.
762 my @tables_that_may_be_empty = (
763                                 'Joining_Type=Left_Joining',
764                                 );
765 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
766 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
767 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
768                                                     if $v_version ge v4.1.0;
769 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
770                                                     if $v_version ge v6.0.0;
771 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
772                                                     if $v_version ge v6.1.0;
773
774 # The lists below are hashes, so the key is the item in the list, and the
775 # value is the reason why it is in the list.  This makes generation of
776 # documentation easier.
777
778 my %why_suppressed;  # No file generated for these.
779
780 # Files aren't generated for empty extraneous properties.  This is arguable.
781 # Extraneous properties generally come about because a property is no longer
782 # used in a newer version of Unicode.  If we generated a file without code
783 # points, programs that used to work on that property will still execute
784 # without errors.  It just won't ever match (or will always match, with \P{}).
785 # This means that the logic is now likely wrong.  I (khw) think its better to
786 # find this out by getting an error message.  Just move them to the table
787 # above to change this behavior
788 my %why_suppress_if_empty_warn_if_not = (
789
790    # It is the only property that has ever officially been removed from the
791    # Standard.  The database never contained any code points for it.
792    'Special_Case_Condition' => 'Obsolete',
793
794    # Apparently never official, but there were code points in some versions of
795    # old-style PropList.txt
796    'Non_Break' => 'Obsolete',
797 );
798
799 # These would normally go in the warn table just above, but they were changed
800 # a long time before this program was written, so warnings about them are
801 # moot.
802 if ($v_version gt v3.2.0) {
803     push @tables_that_may_be_empty,
804                                 'Canonical_Combining_Class=Attached_Below_Left'
805 }
806
807 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
808 # unless explicitly added.
809 if ($v_version ge v5.2.0) {
810     my $unihan = 'Unihan; remove from list if using Unihan';
811     foreach my $table (qw (
812                            kAccountingNumeric
813                            kOtherNumeric
814                            kPrimaryNumeric
815                            kCompatibilityVariant
816                            kIICore
817                            kIRG_GSource
818                            kIRG_HSource
819                            kIRG_JSource
820                            kIRG_KPSource
821                            kIRG_MSource
822                            kIRG_KSource
823                            kIRG_TSource
824                            kIRG_USource
825                            kIRG_VSource
826                            kRSUnicode
827                         ))
828     {
829         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
830     }
831 }
832
833 # Enum values for to_output_map() method in the Map_Table package.
834 my $EXTERNAL_MAP = 1;
835 my $INTERNAL_MAP = 2;
836
837 # To override computed values for writing the map tables for these properties.
838 # The default for enum map tables is to write them out, so that the Unicode
839 # .txt files can be removed, but all the data to compute any property value
840 # for any code point is available in a more compact form.
841 my %global_to_output_map = (
842     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
843     # get stuck supporting it if things change.  Since it is a STRING
844     # property, it normally would be listed in the pod, but INTERNAL_MAP
845     # suppresses that.
846     Unicode_1_Name => $INTERNAL_MAP,
847
848     Present_In => 0,                # Suppress, as easily computed from Age
849     Block => 0,                     # Suppress, as Blocks.txt is retained.
850
851     # Suppress, as mapping can be found instead from the
852     # Perl_Decomposition_Mapping file
853     Decomposition_Type => 0,
854 );
855
856 # Properties that this program ignores.
857 my @unimplemented_properties;
858
859 # With this release, it is automatically handled if the Unihan db is
860 # downloaded
861 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version le v5.2.0;
862
863 # There are several types of obsolete properties defined by Unicode.  These
864 # must be hand-edited for every new Unicode release.
865 my %why_deprecated;  # Generates a deprecated warning message if used.
866 my %why_stabilized;  # Documentation only
867 my %why_obsolete;    # Documentation only
868
869 {   # Closure
870     my $simple = 'Perl uses the more complete version of this property';
871     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
872
873     my $other_properties = 'other properties';
874     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
875     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
876
877     %why_deprecated = (
878         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
879         'Jamo_Short_Name' => $contributory,
880         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
881         'Other_Alphabetic' => $contributory,
882         'Other_Default_Ignorable_Code_Point' => $contributory,
883         'Other_Grapheme_Extend' => $contributory,
884         'Other_ID_Continue' => $contributory,
885         'Other_ID_Start' => $contributory,
886         'Other_Lowercase' => $contributory,
887         'Other_Math' => $contributory,
888         'Other_Uppercase' => $contributory,
889         'Expands_On_NFC' => $why_no_expand,
890         'Expands_On_NFD' => $why_no_expand,
891         'Expands_On_NFKC' => $why_no_expand,
892         'Expands_On_NFKD' => $why_no_expand,
893     );
894
895     %why_suppressed = (
896         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
897         # contains the same information, but without the algorithmically
898         # determinable Hangul syllables'.  This file is not published, so it's
899         # existence is not noted in the comment.
900         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or Unicode::UCD::prop_invmap()',
901
902         'Indic_Matra_Category' => "Provisional",
903         'Indic_Syllabic_Category' => "Provisional",
904
905         # Don't suppress ISO_Comment, as otherwise special handling is needed
906         # to differentiate between it and gc=c, which can be written as 'isc',
907         # which is the same characters as ISO_Comment's short name.
908
909         'Name' => "Accessible via \\N{...} or 'use charnames;' or Unicode::UCD::prop_invmap()",
910
911         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold or Unicode::UCD::prop_invmap()",
912         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
913         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
914         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
915
916         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
917     );
918
919     foreach my $property (
920
921             # The following are suppressed because they were made contributory
922             # or deprecated by Unicode before Perl ever thought about
923             # supporting them.
924             'Jamo_Short_Name',
925             'Grapheme_Link',
926             'Expands_On_NFC',
927             'Expands_On_NFD',
928             'Expands_On_NFKC',
929             'Expands_On_NFKD',
930
931             # The following are suppressed because they have been marked
932             # as deprecated for a sufficient amount of time
933             'Other_Alphabetic',
934             'Other_Default_Ignorable_Code_Point',
935             'Other_Grapheme_Extend',
936             'Other_ID_Continue',
937             'Other_ID_Start',
938             'Other_Lowercase',
939             'Other_Math',
940             'Other_Uppercase',
941     ) {
942         $why_suppressed{$property} = $why_deprecated{$property};
943     }
944
945     # Customize the message for all the 'Other_' properties
946     foreach my $property (keys %why_deprecated) {
947         next if (my $main_property = $property) !~ s/^Other_//;
948         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
949     }
950 }
951
952 if ($v_version ge 4.0.0) {
953     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
954     if ($v_version ge 6.0.0) {
955         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
956     }
957 }
958 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
959     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
960     if ($v_version ge 6.0.0) {
961         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
962     }
963 }
964
965 # Probably obsolete forever
966 if ($v_version ge v4.1.0) {
967     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
968 }
969 if ($v_version ge v6.0.0) {
970     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana (or both)"';
971     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
972 }
973
974 # This program can create files for enumerated-like properties, such as
975 # 'Numeric_Type'.  This file would be the same format as for a string
976 # property, with a mapping from code point to its value, so you could look up,
977 # for example, the script a code point is in.  But no one so far wants this
978 # mapping, or they have found another way to get it since this is a new
979 # feature.  So no file is generated except if it is in this list.
980 my @output_mapped_properties = split "\n", <<END;
981 END
982
983 # If you are using the Unihan database in a Unicode version before 5.2, you
984 # need to add the properties that you want to extract from it to this table.
985 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
986 # listed, commented out
987 my @cjk_properties = split "\n", <<'END';
988 #cjkAccountingNumeric; kAccountingNumeric
989 #cjkOtherNumeric; kOtherNumeric
990 #cjkPrimaryNumeric; kPrimaryNumeric
991 #cjkCompatibilityVariant; kCompatibilityVariant
992 #cjkIICore ; kIICore
993 #cjkIRG_GSource; kIRG_GSource
994 #cjkIRG_HSource; kIRG_HSource
995 #cjkIRG_JSource; kIRG_JSource
996 #cjkIRG_KPSource; kIRG_KPSource
997 #cjkIRG_KSource; kIRG_KSource
998 #cjkIRG_TSource; kIRG_TSource
999 #cjkIRG_USource; kIRG_USource
1000 #cjkIRG_VSource; kIRG_VSource
1001 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
1002 END
1003
1004 # Similarly for the property values.  For your convenience, the lines in the
1005 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
1006 # '#' marks (for Unicode versions before 5.2)
1007 my @cjk_property_values = split "\n", <<'END';
1008 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1009 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
1010 ## @missing: 0000..10FFFF; cjkIICore; <none>
1011 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
1012 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
1013 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
1014 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
1015 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
1016 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
1017 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
1018 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
1019 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
1020 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1021 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1022 END
1023
1024 # The input files don't list every code point.  Those not listed are to be
1025 # defaulted to some value.  Below are hard-coded what those values are for
1026 # non-binary properties as of 5.1.  Starting in 5.0, there are
1027 # machine-parsable comment lines in the files the give the defaults; so this
1028 # list shouldn't have to be extended.  The claim is that all missing entries
1029 # for binary properties will default to 'N'.  Unicode tried to change that in
1030 # 5.2, but the beta period produced enough protest that they backed off.
1031 #
1032 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1033 # be in the form that it expects.  The others may be synonyms.
1034 my $CODE_POINT = '<code point>';
1035 my %default_mapping = (
1036     Age => "Unassigned",
1037     # Bidi_Class => Complicated; set in code
1038     Bidi_Mirroring_Glyph => "",
1039     Block => 'No_Block',
1040     Canonical_Combining_Class => 0,
1041     Case_Folding => $CODE_POINT,
1042     Decomposition_Mapping => $CODE_POINT,
1043     Decomposition_Type => 'None',
1044     East_Asian_Width => "Neutral",
1045     FC_NFKC_Closure => $CODE_POINT,
1046     General_Category => 'Cn',
1047     Grapheme_Cluster_Break => 'Other',
1048     Hangul_Syllable_Type => 'NA',
1049     ISO_Comment => "",
1050     Jamo_Short_Name => "",
1051     Joining_Group => "No_Joining_Group",
1052     # Joining_Type => Complicated; set in code
1053     kIICore => 'N',   #                       Is converted to binary
1054     #Line_Break => Complicated; set in code
1055     Lowercase_Mapping => $CODE_POINT,
1056     Name => "",
1057     Name_Alias => "",
1058     NFC_QC => 'Yes',
1059     NFD_QC => 'Yes',
1060     NFKC_QC => 'Yes',
1061     NFKD_QC => 'Yes',
1062     Numeric_Type => 'None',
1063     Numeric_Value => 'NaN',
1064     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1065     Sentence_Break => 'Other',
1066     Simple_Case_Folding => $CODE_POINT,
1067     Simple_Lowercase_Mapping => $CODE_POINT,
1068     Simple_Titlecase_Mapping => $CODE_POINT,
1069     Simple_Uppercase_Mapping => $CODE_POINT,
1070     Titlecase_Mapping => $CODE_POINT,
1071     Unicode_1_Name => "",
1072     Unicode_Radical_Stroke => "",
1073     Uppercase_Mapping => $CODE_POINT,
1074     Word_Break => 'Other',
1075 );
1076
1077 # Below are files that Unicode furnishes, but this program ignores, and why
1078 my %ignored_files = (
1079     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1080     'Index.txt' => 'Alphabetical index of Unicode characters',
1081     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1082     'NamesList.txt' => 'Annotated list of characters',
1083     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1084     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1085     'ReadMe.txt' => 'Documentation',
1086     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1087     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1088     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1089     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1090     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1091     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1092 );
1093
1094 my %skipped_files;  # List of files that we skip
1095
1096 ### End of externally interesting definitions, except for @input_file_objects
1097
1098 my $HEADER=<<"EOF";
1099 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1100 # This file is machine-generated by $0 from the Unicode
1101 # database, Version $string_version.  Any changes made here will be lost!
1102 EOF
1103
1104 my $INTERNAL_ONLY_HEADER = <<"EOF";
1105
1106 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1107 # This file is for internal use by core Perl only.  The format and even the
1108 # name or existence of this file are subject to change without notice.  Don't
1109 # use it directly.
1110 EOF
1111
1112 my $DEVELOPMENT_ONLY=<<"EOF";
1113 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1114 # This file contains information artificially constrained to code points
1115 # present in Unicode release $string_compare_versions.
1116 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1117 # not be used for production.
1118
1119 EOF
1120
1121 my $MAX_UNICODE_CODEPOINT_STRING = "10FFFF";
1122 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1123 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1124
1125 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1126 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1127 # to decrease backtracking.  The first regex allows the code point to be at
1128 # the end of a word, but to work properly, the word shouldn't end with a valid
1129 # hex character.  The second one won't match a code point at the end of a
1130 # word, and doesn't have the run-on issue
1131 my $run_on_code_point_re =
1132             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1133 my $code_point_re = qr/\b$run_on_code_point_re/;
1134
1135 # This matches the beginning of the line in the Unicode db files that give the
1136 # defaults for code points not listed (i.e., missing) in the file.  The code
1137 # depends on this ending with a semi-colon, so it can assume it is a valid
1138 # field when the line is split() by semi-colons
1139 my $missing_defaults_prefix =
1140             qr/^#\s+\@missing:\s+0000\.\.$MAX_UNICODE_CODEPOINT_STRING\s*;/;
1141
1142 # Property types.  Unicode has more types, but these are sufficient for our
1143 # purposes.
1144 my $UNKNOWN = -1;   # initialized to illegal value
1145 my $NON_STRING = 1; # Either binary or enum
1146 my $BINARY = 2;
1147 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1148                        # tables, additional true and false tables are
1149                        # generated so that false is anything matching the
1150                        # default value, and true is everything else.
1151 my $ENUM = 4;       # Include catalog
1152 my $STRING = 5;     # Anything else: string or misc
1153
1154 # Some input files have lines that give default values for code points not
1155 # contained in the file.  Sometimes these should be ignored.
1156 my $NO_DEFAULTS = 0;        # Must evaluate to false
1157 my $NOT_IGNORED = 1;
1158 my $IGNORED = 2;
1159
1160 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1161 # and will appear in the main body of the tables in the output files, but
1162 # there are other types of ranges as well, listed below, that are specially
1163 # handled.   There are pseudo-types as well that will never be stored as a
1164 # type, but will affect the calculation of the type.
1165
1166 # 0 is for normal, non-specials
1167 my $MULTI_CP = 1;           # Sequence of more than code point
1168 my $HANGUL_SYLLABLE = 2;
1169 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1170 my $NULL = 4;               # The map is to the null string; utf8.c can't
1171                             # handle these, nor is there an accepted syntax
1172                             # for them in \p{} constructs
1173 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1174                              # otherwise be $MULTI_CP type are instead type 0
1175
1176 # process_generic_property_file() can accept certain overrides in its input.
1177 # Each of these must begin AND end with $CMD_DELIM.
1178 my $CMD_DELIM = "\a";
1179 my $REPLACE_CMD = 'replace';    # Override the Replace
1180 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1181
1182 my $NO = 0;
1183 my $YES = 1;
1184
1185 # Values for the Replace argument to add_range.
1186 # $NO                      # Don't replace; add only the code points not
1187                            # already present.
1188 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1189                            # the comments at the subroutine definition.
1190 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1191 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1192                            # already there
1193 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1194                            # already there
1195 my $CROAK = 6;             # Die with an error if is already there
1196
1197 # Flags to give property statuses.  The phrases are to remind maintainers that
1198 # if the flag is changed, the indefinite article referring to it in the
1199 # documentation may need to be as well.
1200 my $NORMAL = "";
1201 my $DEPRECATED = 'D';
1202 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1203 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1204 my $DISCOURAGED = 'X';
1205 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1206 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1207 my $STRICTER = 'T';
1208 my $a_bold_stricter = "a 'B<$STRICTER>'";
1209 my $A_bold_stricter = "A 'B<$STRICTER>'";
1210 my $STABILIZED = 'S';
1211 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1212 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1213 my $OBSOLETE = 'O';
1214 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1215 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1216
1217 my %status_past_participles = (
1218     $DISCOURAGED => 'discouraged',
1219     $STABILIZED => 'stabilized',
1220     $OBSOLETE => 'obsolete',
1221     $DEPRECATED => 'deprecated',
1222 );
1223
1224 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1225 # externally documented.
1226 my $ORDINARY = 0;       # The normal fate.
1227 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1228                         # but there is a file written that can be used to
1229                         # reconstruct this table
1230 my $SUPPRESSED = 3;     # The file for this table is not written out.
1231 my $INTERNAL_ONLY = 4;  # The file for this table is written out, but it is
1232                         # for Perl's internal use only
1233 my $PLACEHOLDER = 5;    # A property that is defined as a placeholder in a
1234                         # Unicode version that doesn't have it, but we need it
1235                         # to be defined, if empty, to have things work.
1236                         # Implies no pod entry generated
1237
1238 # The format of the values of the tables:
1239 my $EMPTY_FORMAT = "";
1240 my $BINARY_FORMAT = 'b';
1241 my $DECIMAL_FORMAT = 'd';
1242 my $FLOAT_FORMAT = 'f';
1243 my $INTEGER_FORMAT = 'i';
1244 my $HEX_FORMAT = 'x';
1245 my $RATIONAL_FORMAT = 'r';
1246 my $STRING_FORMAT = 's';
1247 my $DECOMP_STRING_FORMAT = 'c';
1248 my $STRING_WHITE_SPACE_LIST = 'sw';
1249
1250 my %map_table_formats = (
1251     $BINARY_FORMAT => 'binary',
1252     $DECIMAL_FORMAT => 'single decimal digit',
1253     $FLOAT_FORMAT => 'floating point number',
1254     $INTEGER_FORMAT => 'integer',
1255     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1256     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1257     $STRING_FORMAT => 'string',
1258     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1259     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1260 );
1261
1262 # Unicode didn't put such derived files in a separate directory at first.
1263 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1264 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1265 my $AUXILIARY = 'auxiliary';
1266
1267 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1268 # and into UCD.pl for the use of UCD.pm
1269 my %loose_to_file_of;       # loosely maps table names to their respective
1270                             # files
1271 my %stricter_to_file_of;    # same; but for stricter mapping.
1272 my %loose_property_to_file_of; # Maps a loose property name to its map file
1273 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1274                             # in the hash %utf8::SwashInfo
1275 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1276                              # their rational equivalent
1277 my %loose_property_name_of; # Loosely maps (non_string) property names to
1278                             # standard form
1279 my %string_property_loose_to_name; # Same, for string properties.
1280 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1281                             # the property name in standard loose form, and
1282                             # 'value' is the default value for that property,
1283                             # also in standard loose form.
1284 my %loose_to_standard_value; # loosely maps table names to the canonical
1285                             # alias for them
1286 my %ambiguous_names;        # keys are alias names (in standard form) that
1287                             # have more than one possible meaning.
1288 my %prop_aliases;           # Keys are standard property name; values are each
1289                             # one's aliases
1290 my %prop_value_aliases;     # Keys of top level are standard property name;
1291                             # values are keys to another hash,  Each one is
1292                             # one of the property's values, in standard form.
1293                             # The values are that prop-val's aliases.
1294 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1295
1296 # Most properties are immune to caseless matching, otherwise you would get
1297 # nonsensical results, as properties are a function of a code point, not
1298 # everything that is caselessly equivalent to that code point.  For example,
1299 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1300 # be true because 's' and 'S' are equivalent caselessly.  However,
1301 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1302 # extend that concept to those very few properties that are like this.  Each
1303 # such property will match the full range caselessly.  They are hard-coded in
1304 # the program; it's not worth trying to make it general as it's extremely
1305 # unlikely that they will ever change.
1306 my %caseless_equivalent_to;
1307
1308 # These constants names and values were taken from the Unicode standard,
1309 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1310 # syllables.  The '_string' versions are so generated tables can retain the
1311 # hex format, which is the more familiar value
1312 my $SBase_string = "0xAC00";
1313 my $SBase = CORE::hex $SBase_string;
1314 my $LBase_string = "0x1100";
1315 my $LBase = CORE::hex $LBase_string;
1316 my $VBase_string = "0x1161";
1317 my $VBase = CORE::hex $VBase_string;
1318 my $TBase_string = "0x11A7";
1319 my $TBase = CORE::hex $TBase_string;
1320 my $SCount = 11172;
1321 my $LCount = 19;
1322 my $VCount = 21;
1323 my $TCount = 28;
1324 my $NCount = $VCount * $TCount;
1325
1326 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1327 # with the above published constants.
1328 my %Jamo;
1329 my %Jamo_L;     # Leading consonants
1330 my %Jamo_V;     # Vowels
1331 my %Jamo_T;     # Trailing consonants
1332
1333 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1334 # The key is the base name of the code point, and the value is an
1335 # array giving all the ranges that use this base name.  Each range
1336 # is actually a hash giving the 'low' and 'high' values of it.
1337 my %names_ending_in_code_point;
1338 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1339                                         # removed from the names
1340 # Inverse mapping.  The list of ranges that have these kinds of
1341 # names.  Each element contains the low, high, and base names in an
1342 # anonymous hash.
1343 my @code_points_ending_in_code_point;
1344
1345 # Boolean: does this Unicode version have the hangul syllables, and are we
1346 # writing out a table for them?
1347 my $has_hangul_syllables = 0;
1348
1349 # Does this Unicode version have code points whose names end in their
1350 # respective code points, and are we writing out a table for them?  0 for no;
1351 # otherwise points to first property that a table is needed for them, so that
1352 # if multiple tables are needed, we don't create duplicates
1353 my $needing_code_points_ending_in_code_point = 0;
1354
1355 my @backslash_X_tests;     # List of tests read in for testing \X
1356 my @unhandled_properties;  # Will contain a list of properties found in
1357                            # the input that we didn't process.
1358 my @match_properties;      # Properties that have match tables, to be
1359                            # listed in the pod
1360 my @map_properties;        # Properties that get map files written
1361 my @named_sequences;       # NamedSequences.txt contents.
1362 my %potential_files;       # Generated list of all .txt files in the directory
1363                            # structure so we can warn if something is being
1364                            # ignored.
1365 my @files_actually_output; # List of files we generated.
1366 my @more_Names;            # Some code point names are compound; this is used
1367                            # to store the extra components of them.
1368 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1369                            # the minimum before we consider it equivalent to a
1370                            # candidate rational
1371 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1372
1373 # These store references to certain commonly used property objects
1374 my $gc;
1375 my $perl;
1376 my $block;
1377 my $perl_charname;
1378 my $print;
1379 my $Any;
1380 my $script;
1381
1382 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1383 my $has_In_conflicts = 0;
1384 my $has_Is_conflicts = 0;
1385
1386 sub internal_file_to_platform ($) {
1387     # Convert our file paths which have '/' separators to those of the
1388     # platform.
1389
1390     my $file = shift;
1391     return undef unless defined $file;
1392
1393     return File::Spec->join(split '/', $file);
1394 }
1395
1396 sub file_exists ($) {   # platform independent '-e'.  This program internally
1397                         # uses slash as a path separator.
1398     my $file = shift;
1399     return 0 if ! defined $file;
1400     return -e internal_file_to_platform($file);
1401 }
1402
1403 sub objaddr($) {
1404     # Returns the address of the blessed input object.
1405     # It doesn't check for blessedness because that would do a string eval
1406     # every call, and the program is structured so that this is never called
1407     # for a non-blessed object.
1408
1409     no overloading; # If overloaded, numifying below won't work.
1410
1411     # Numifying a ref gives its address.
1412     return pack 'J', $_[0];
1413 }
1414
1415 # These are used only if $annotate is true.
1416 # The entire range of Unicode characters is examined to populate these
1417 # after all the input has been processed.  But most can be skipped, as they
1418 # have the same descriptive phrases, such as being unassigned
1419 my @viacode;            # Contains the 1 million character names
1420 my @printable;          # boolean: And are those characters printable?
1421 my @annotate_char_type; # Contains a type of those characters, specifically
1422                         # for the purposes of annotation.
1423 my $annotate_ranges;    # A map of ranges of code points that have the same
1424                         # name for the purposes of annotation.  They map to the
1425                         # upper edge of the range, so that the end point can
1426                         # be immediately found.  This is used to skip ahead to
1427                         # the end of a range, and avoid processing each
1428                         # individual code point in it.
1429 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1430                                    # characters, but excluding those which are
1431                                    # also noncharacter code points
1432
1433 # The annotation types are an extension of the regular range types, though
1434 # some of the latter are folded into one.  Make the new types negative to
1435 # avoid conflicting with the regular types
1436 my $SURROGATE_TYPE = -1;
1437 my $UNASSIGNED_TYPE = -2;
1438 my $PRIVATE_USE_TYPE = -3;
1439 my $NONCHARACTER_TYPE = -4;
1440 my $CONTROL_TYPE = -5;
1441 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1442
1443 sub populate_char_info ($) {
1444     # Used only with the $annotate option.  Populates the arrays with the
1445     # input code point's info that are needed for outputting more detailed
1446     # comments.  If calling context wants a return, it is the end point of
1447     # any contiguous range of characters that share essentially the same info
1448
1449     my $i = shift;
1450     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1451
1452     $viacode[$i] = $perl_charname->value_of($i) || "";
1453
1454     # A character is generally printable if Unicode says it is,
1455     # but below we make sure that most Unicode general category 'C' types
1456     # aren't.
1457     $printable[$i] = $print->contains($i);
1458
1459     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1460
1461     # Only these two regular types are treated specially for annotations
1462     # purposes
1463     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1464                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1465
1466     # Give a generic name to all code points that don't have a real name.
1467     # We output ranges, if applicable, for these.  Also calculate the end
1468     # point of the range.
1469     my $end;
1470     if (! $viacode[$i]) {
1471         if ($gc-> table('Surrogate')->contains($i)) {
1472             $viacode[$i] = 'Surrogate';
1473             $annotate_char_type[$i] = $SURROGATE_TYPE;
1474             $printable[$i] = 0;
1475             $end = $gc->table('Surrogate')->containing_range($i)->end;
1476         }
1477         elsif ($gc-> table('Private_use')->contains($i)) {
1478             $viacode[$i] = 'Private Use';
1479             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1480             $printable[$i] = 0;
1481             $end = $gc->table('Private_Use')->containing_range($i)->end;
1482         }
1483         elsif (Property::property_ref('Noncharacter_Code_Point')-> table('Y')->
1484                                                                 contains($i))
1485         {
1486             $viacode[$i] = 'Noncharacter';
1487             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1488             $printable[$i] = 0;
1489             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1490                                                     containing_range($i)->end;
1491         }
1492         elsif ($gc-> table('Control')->contains($i)) {
1493             $viacode[$i] = 'Control';
1494             $annotate_char_type[$i] = $CONTROL_TYPE;
1495             $printable[$i] = 0;
1496             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1497         }
1498         elsif ($gc-> table('Unassigned')->contains($i)) {
1499             $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1500             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1501             $printable[$i] = 0;
1502
1503             # Because we name the unassigned by the blocks they are in, it
1504             # can't go past the end of that block, and it also can't go past
1505             # the unassigned range it is in.  The special table makes sure
1506             # that the non-characters, which are unassigned, are separated
1507             # out.
1508             $end = min($block->containing_range($i)->end,
1509                        $unassigned_sans_noncharacters-> containing_range($i)->
1510                                                                          end);
1511         }
1512         else {
1513             Carp::my_carp_bug("Can't figure out how to annotate "
1514                               . sprintf("U+%04X", $i)
1515                               . ".  Proceeding anyway.");
1516             $viacode[$i] = 'UNKNOWN';
1517             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1518             $printable[$i] = 0;
1519         }
1520     }
1521
1522     # Here, has a name, but if it's one in which the code point number is
1523     # appended to the name, do that.
1524     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1525         $viacode[$i] .= sprintf("-%04X", $i);
1526         $end = $perl_charname->containing_range($i)->end;
1527     }
1528
1529     # And here, has a name, but if it's a hangul syllable one, replace it with
1530     # the correct name from the Unicode algorithm
1531     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1532         use integer;
1533         my $SIndex = $i - $SBase;
1534         my $L = $LBase + $SIndex / $NCount;
1535         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1536         my $T = $TBase + $SIndex % $TCount;
1537         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1538         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1539         $end = $perl_charname->containing_range($i)->end;
1540     }
1541
1542     return if ! defined wantarray;
1543     return $i if ! defined $end;    # If not a range, return the input
1544
1545     # Save this whole range so can find the end point quickly
1546     $annotate_ranges->add_map($i, $end, $end);
1547
1548     return $end;
1549 }
1550
1551 # Commented code below should work on Perl 5.8.
1552 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1553 ## the native perl version of it (which is what would operate under miniperl)
1554 ## is extremely slow, as it does a string eval every call.
1555 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1556 #                            && defined eval "require Scalar::Util";
1557 #
1558 #sub objaddr($) {
1559 #    # Returns the address of the blessed input object.  Uses the XS version if
1560 #    # available.  It doesn't check for blessedness because that would do a
1561 #    # string eval every call, and the program is structured so that this is
1562 #    # never called for a non-blessed object.
1563 #
1564 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1565 #
1566 #    # Check at least that is a ref.
1567 #    my $pkg = ref($_[0]) or return undef;
1568 #
1569 #    # Change to a fake package to defeat any overloaded stringify
1570 #    bless $_[0], 'main::Fake';
1571 #
1572 #    # Numifying a ref gives its address.
1573 #    my $addr = pack 'J', $_[0];
1574 #
1575 #    # Return to original class
1576 #    bless $_[0], $pkg;
1577 #    return $addr;
1578 #}
1579
1580 sub max ($$) {
1581     my $a = shift;
1582     my $b = shift;
1583     return $a if $a >= $b;
1584     return $b;
1585 }
1586
1587 sub min ($$) {
1588     my $a = shift;
1589     my $b = shift;
1590     return $a if $a <= $b;
1591     return $b;
1592 }
1593
1594 sub clarify_number ($) {
1595     # This returns the input number with underscores inserted every 3 digits
1596     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1597     # checked.
1598
1599     my $number = shift;
1600     my $pos = length($number) - 3;
1601     return $number if $pos <= 1;
1602     while ($pos > 0) {
1603         substr($number, $pos, 0) = '_';
1604         $pos -= 3;
1605     }
1606     return $number;
1607 }
1608
1609
1610 package Carp;
1611
1612 # These routines give a uniform treatment of messages in this program.  They
1613 # are placed in the Carp package to cause the stack trace to not include them,
1614 # although an alternative would be to use another package and set @CARP_NOT
1615 # for it.
1616
1617 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1618
1619 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1620 # and overload trying to load Scalar:Util under miniperl.  See
1621 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1622 undef $overload::VERSION;
1623
1624 sub my_carp {
1625     my $message = shift || "";
1626     my $nofold = shift || 0;
1627
1628     if ($message) {
1629         $message = main::join_lines($message);
1630         $message =~ s/^$0: *//;     # Remove initial program name
1631         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1632         $message = "\n$0: $message;";
1633
1634         # Fold the message with program name, semi-colon end punctuation
1635         # (which looks good with the message that carp appends to it), and a
1636         # hanging indent for continuation lines.
1637         $message = main::simple_fold($message, "", 4) unless $nofold;
1638         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1639                                     # appends is to the same line
1640     }
1641
1642     return $message if defined wantarray;   # If a caller just wants the msg
1643
1644     carp $message;
1645     return;
1646 }
1647
1648 sub my_carp_bug {
1649     # This is called when it is clear that the problem is caused by a bug in
1650     # this program.
1651
1652     my $message = shift;
1653     $message =~ s/^$0: *//;
1654     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1655     carp $message;
1656     return;
1657 }
1658
1659 sub carp_too_few_args {
1660     if (@_ != 2) {
1661         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1662         return;
1663     }
1664
1665     my $args_ref = shift;
1666     my $count = shift;
1667
1668     my_carp_bug("Need at least $count arguments to "
1669         . (caller 1)[3]
1670         . ".  Instead got: '"
1671         . join ', ', @$args_ref
1672         . "'.  No action taken.");
1673     return;
1674 }
1675
1676 sub carp_extra_args {
1677     my $args_ref = shift;
1678     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1679
1680     unless (ref $args_ref) {
1681         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1682         return;
1683     }
1684     my ($package, $file, $line) = caller;
1685     my $subroutine = (caller 1)[3];
1686
1687     my $list;
1688     if (ref $args_ref eq 'HASH') {
1689         foreach my $key (keys %$args_ref) {
1690             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1691         }
1692         $list = join ', ', each %{$args_ref};
1693     }
1694     elsif (ref $args_ref eq 'ARRAY') {
1695         foreach my $arg (@$args_ref) {
1696             $arg = $UNDEF unless defined $arg;
1697         }
1698         $list = join ', ', @$args_ref;
1699     }
1700     else {
1701         my_carp_bug("Can't cope with ref "
1702                 . ref($args_ref)
1703                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1704         return;
1705     }
1706
1707     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1708     return;
1709 }
1710
1711 package main;
1712
1713 { # Closure
1714
1715     # This program uses the inside-out method for objects, as recommended in
1716     # "Perl Best Practices".  This closure aids in generating those.  There
1717     # are two routines.  setup_package() is called once per package to set
1718     # things up, and then set_access() is called for each hash representing a
1719     # field in the object.  These routines arrange for the object to be
1720     # properly destroyed when no longer used, and for standard accessor
1721     # functions to be generated.  If you need more complex accessors, just
1722     # write your own and leave those accesses out of the call to set_access().
1723     # More details below.
1724
1725     my %constructor_fields; # fields that are to be used in constructors; see
1726                             # below
1727
1728     # The values of this hash will be the package names as keys to other
1729     # hashes containing the name of each field in the package as keys, and
1730     # references to their respective hashes as values.
1731     my %package_fields;
1732
1733     sub setup_package {
1734         # Sets up the package, creating standard DESTROY and dump methods
1735         # (unless already defined).  The dump method is used in debugging by
1736         # simple_dumper().
1737         # The optional parameters are:
1738         #   a)  a reference to a hash, that gets populated by later
1739         #       set_access() calls with one of the accesses being
1740         #       'constructor'.  The caller can then refer to this, but it is
1741         #       not otherwise used by these two routines.
1742         #   b)  a reference to a callback routine to call during destruction
1743         #       of the object, before any fields are actually destroyed
1744
1745         my %args = @_;
1746         my $constructor_ref = delete $args{'Constructor_Fields'};
1747         my $destroy_callback = delete $args{'Destroy_Callback'};
1748         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1749
1750         my %fields;
1751         my $package = (caller)[0];
1752
1753         $package_fields{$package} = \%fields;
1754         $constructor_fields{$package} = $constructor_ref;
1755
1756         unless ($package->can('DESTROY')) {
1757             my $destroy_name = "${package}::DESTROY";
1758             no strict "refs";
1759
1760             # Use typeglob to give the anonymous subroutine the name we want
1761             *$destroy_name = sub {
1762                 my $self = shift;
1763                 my $addr = do { no overloading; pack 'J', $self; };
1764
1765                 $self->$destroy_callback if $destroy_callback;
1766                 foreach my $field (keys %{$package_fields{$package}}) {
1767                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1768                     delete $package_fields{$package}{$field}{$addr};
1769                 }
1770                 return;
1771             }
1772         }
1773
1774         unless ($package->can('dump')) {
1775             my $dump_name = "${package}::dump";
1776             no strict "refs";
1777             *$dump_name = sub {
1778                 my $self = shift;
1779                 return dump_inside_out($self, $package_fields{$package}, @_);
1780             }
1781         }
1782         return;
1783     }
1784
1785     sub set_access {
1786         # Arrange for the input field to be garbage collected when no longer
1787         # needed.  Also, creates standard accessor functions for the field
1788         # based on the optional parameters-- none if none of these parameters:
1789         #   'addable'    creates an 'add_NAME()' accessor function.
1790         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1791         #                function.
1792         #   'settable'   creates a 'set_NAME()' accessor function.
1793         #   'constructor' doesn't create an accessor function, but adds the
1794         #                field to the hash that was previously passed to
1795         #                setup_package();
1796         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1797         # 'add' etc. all mean 'addable'.
1798         # The read accessor function will work on both array and scalar
1799         # values.  If another accessor in the parameter list is 'a', the read
1800         # access assumes an array.  You can also force it to be array access
1801         # by specifying 'readable_array' instead of 'readable'
1802         #
1803         # A sort-of 'protected' access can be set-up by preceding the addable,
1804         # readable or settable with some initial portion of 'protected_' (but,
1805         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1806         # "protection" is only by convention.  All that happens is that the
1807         # accessor functions' names begin with an underscore.  So instead of
1808         # calling set_foo, the call is _set_foo.  (Real protection could be
1809         # accomplished by having a new subroutine, end_package, called at the
1810         # end of each package, and then storing the __LINE__ ranges and
1811         # checking them on every accessor.  But that is way overkill.)
1812
1813         # We create anonymous subroutines as the accessors and then use
1814         # typeglobs to assign them to the proper package and name
1815
1816         my $name = shift;   # Name of the field
1817         my $field = shift;  # Reference to the inside-out hash containing the
1818                             # field
1819
1820         my $package = (caller)[0];
1821
1822         if (! exists $package_fields{$package}) {
1823             croak "$0: Must call 'setup_package' before 'set_access'";
1824         }
1825
1826         # Stash the field so DESTROY can get it.
1827         $package_fields{$package}{$name} = $field;
1828
1829         # Remaining arguments are the accessors.  For each...
1830         foreach my $access (@_) {
1831             my $access = lc $access;
1832
1833             my $protected = "";
1834
1835             # Match the input as far as it goes.
1836             if ($access =~ /^(p[^_]*)_/) {
1837                 $protected = $1;
1838                 if (substr('protected_', 0, length $protected)
1839                     eq $protected)
1840                 {
1841
1842                     # Add 1 for the underscore not included in $protected
1843                     $access = substr($access, length($protected) + 1);
1844                     $protected = '_';
1845                 }
1846                 else {
1847                     $protected = "";
1848                 }
1849             }
1850
1851             if (substr('addable', 0, length $access) eq $access) {
1852                 my $subname = "${package}::${protected}add_$name";
1853                 no strict "refs";
1854
1855                 # add_ accessor.  Don't add if already there, which we
1856                 # determine using 'eq' for scalars and '==' otherwise.
1857                 *$subname = sub {
1858                     use strict "refs";
1859                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1860                     my $self = shift;
1861                     my $value = shift;
1862                     my $addr = do { no overloading; pack 'J', $self; };
1863                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1864                     if (ref $value) {
1865                         return if grep { $value == $_ } @{$field->{$addr}};
1866                     }
1867                     else {
1868                         return if grep { $value eq $_ } @{$field->{$addr}};
1869                     }
1870                     push @{$field->{$addr}}, $value;
1871                     return;
1872                 }
1873             }
1874             elsif (substr('constructor', 0, length $access) eq $access) {
1875                 if ($protected) {
1876                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1877                 }
1878                 else {
1879                     $constructor_fields{$package}{$name} = $field;
1880                 }
1881             }
1882             elsif (substr('readable_array', 0, length $access) eq $access) {
1883
1884                 # Here has read access.  If one of the other parameters for
1885                 # access is array, or this one specifies array (by being more
1886                 # than just 'readable_'), then create a subroutine that
1887                 # assumes the data is an array.  Otherwise just a scalar
1888                 my $subname = "${package}::${protected}$name";
1889                 if (grep { /^a/i } @_
1890                     or length($access) > length('readable_'))
1891                 {
1892                     no strict "refs";
1893                     *$subname = sub {
1894                         use strict "refs";
1895                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1896                         my $addr = do { no overloading; pack 'J', $_[0]; };
1897                         if (ref $field->{$addr} ne 'ARRAY') {
1898                             my $type = ref $field->{$addr};
1899                             $type = 'scalar' unless $type;
1900                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1901                             return;
1902                         }
1903                         return scalar @{$field->{$addr}} unless wantarray;
1904
1905                         # Make a copy; had problems with caller modifying the
1906                         # original otherwise
1907                         my @return = @{$field->{$addr}};
1908                         return @return;
1909                     }
1910                 }
1911                 else {
1912
1913                     # Here not an array value, a simpler function.
1914                     no strict "refs";
1915                     *$subname = sub {
1916                         use strict "refs";
1917                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1918                         no overloading;
1919                         return $field->{pack 'J', $_[0]};
1920                     }
1921                 }
1922             }
1923             elsif (substr('settable', 0, length $access) eq $access) {
1924                 my $subname = "${package}::${protected}set_$name";
1925                 no strict "refs";
1926                 *$subname = sub {
1927                     use strict "refs";
1928                     if (main::DEBUG) {
1929                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1930                         Carp::carp_extra_args(\@_) if @_ > 2;
1931                     }
1932                     # $self is $_[0]; $value is $_[1]
1933                     no overloading;
1934                     $field->{pack 'J', $_[0]} = $_[1];
1935                     return;
1936                 }
1937             }
1938             else {
1939                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1940             }
1941         }
1942         return;
1943     }
1944 }
1945
1946 package Input_file;
1947
1948 # All input files use this object, which stores various attributes about them,
1949 # and provides for convenient, uniform handling.  The run method wraps the
1950 # processing.  It handles all the bookkeeping of opening, reading, and closing
1951 # the file, returning only significant input lines.
1952 #
1953 # Each object gets a handler which processes the body of the file, and is
1954 # called by run().  Most should use the generic, default handler, which has
1955 # code scrubbed to handle things you might not expect.  A handler should
1956 # basically be a while(next_line()) {...} loop.
1957 #
1958 # You can also set up handlers to
1959 #   1) call before the first line is read for pre processing
1960 #   2) call to adjust each line of the input before the main handler gets them
1961 #   3) call upon EOF before the main handler exits its loop
1962 #   4) call at the end for post processing
1963 #
1964 # $_ is used to store the input line, and is to be filtered by the
1965 # each_line_handler()s.  So, if the format of the line is not in the desired
1966 # format for the main handler, these are used to do that adjusting.  They can
1967 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1968 # so the $_ output of one is used as the input to the next.  None of the other
1969 # handlers are stackable, but could easily be changed to be so.
1970 #
1971 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1972 # which insert the parameters as lines to be processed before the next input
1973 # file line is read.  This allows the EOF handler to flush buffers, for
1974 # example.  The difference between the two routines is that the lines inserted
1975 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1976 # called it from such a handler, you would get infinite recursion.)  Lines
1977 # inserted by insert_adjusted_lines() go directly to the main handler without
1978 # any adjustments.  If the  post-processing handler calls any of these, there
1979 # will be no effect.  Some error checking for these conditions could be added,
1980 # but it hasn't been done.
1981 #
1982 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1983 # to prevent further processing of the line.  This routine will output the
1984 # message as a warning once, and then keep a count of the lines that have the
1985 # same message, and output that count at the end of the file's processing.
1986 # This keeps the number of messages down to a manageable amount.
1987 #
1988 # get_missings() should be called to retrieve any @missing input lines.
1989 # Messages will be raised if this isn't done if the options aren't to ignore
1990 # missings.
1991
1992 sub trace { return main::trace(@_); }
1993
1994 { # Closure
1995     # Keep track of fields that are to be put into the constructor.
1996     my %constructor_fields;
1997
1998     main::setup_package(Constructor_Fields => \%constructor_fields);
1999
2000     my %file; # Input file name, required
2001     main::set_access('file', \%file, qw{ c r });
2002
2003     my %first_released; # Unicode version file was first released in, required
2004     main::set_access('first_released', \%first_released, qw{ c r });
2005
2006     my %handler;    # Subroutine to process the input file, defaults to
2007                     # 'process_generic_property_file'
2008     main::set_access('handler', \%handler, qw{ c });
2009
2010     my %property;
2011     # name of property this file is for.  defaults to none, meaning not
2012     # applicable, or is otherwise determinable, for example, from each line.
2013     main::set_access('property', \%property, qw{ c });
2014
2015     my %optional;
2016     # If this is true, the file is optional.  If not present, no warning is
2017     # output.  If it is present, the string given by this parameter is
2018     # evaluated, and if false the file is not processed.
2019     main::set_access('optional', \%optional, 'c', 'r');
2020
2021     my %non_skip;
2022     # This is used for debugging, to skip processing of all but a few input
2023     # files.  Add 'non_skip => 1' to the constructor for those files you want
2024     # processed when you set the $debug_skip global.
2025     main::set_access('non_skip', \%non_skip, 'c');
2026
2027     my %skip;
2028     # This is used to skip processing of this input file semi-permanently,
2029     # when it evaluates to true.  The value should be the reason the file is
2030     # being skipped.  It is used for files that we aren't planning to process
2031     # anytime soon, but want to allow to be in the directory and not raise a
2032     # message that we are not handling.  Mostly for test files.  This is in
2033     # contrast to the non_skip element, which is supposed to be used very
2034     # temporarily for debugging.  Sets 'optional' to 1.  Also, files that we
2035     # pretty much will never look at can be placed in the global
2036     # %ignored_files instead.  Ones used here will be added to %skipped files
2037     main::set_access('skip', \%skip, 'c');
2038
2039     my %each_line_handler;
2040     # list of subroutines to look at and filter each non-comment line in the
2041     # file.  defaults to none.  The subroutines are called in order, each is
2042     # to adjust $_ for the next one, and the final one adjusts it for
2043     # 'handler'
2044     main::set_access('each_line_handler', \%each_line_handler, 'c');
2045
2046     my %has_missings_defaults;
2047     # ? Are there lines in the file giving default values for code points
2048     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2049     # the norm, but IGNORED means it has such lines, but the handler doesn't
2050     # use them.  Having these three states allows us to catch changes to the
2051     # UCD that this program should track
2052     main::set_access('has_missings_defaults',
2053                                         \%has_missings_defaults, qw{ c r });
2054
2055     my %pre_handler;
2056     # Subroutine to call before doing anything else in the file.  If undef, no
2057     # such handler is called.
2058     main::set_access('pre_handler', \%pre_handler, qw{ c });
2059
2060     my %eof_handler;
2061     # Subroutine to call upon getting an EOF on the input file, but before
2062     # that is returned to the main handler.  This is to allow buffers to be
2063     # flushed.  The handler is expected to call insert_lines() or
2064     # insert_adjusted() with the buffered material
2065     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2066
2067     my %post_handler;
2068     # Subroutine to call after all the lines of the file are read in and
2069     # processed.  If undef, no such handler is called.
2070     main::set_access('post_handler', \%post_handler, qw{ c });
2071
2072     my %progress_message;
2073     # Message to print to display progress in lieu of the standard one
2074     main::set_access('progress_message', \%progress_message, qw{ c });
2075
2076     my %handle;
2077     # cache open file handle, internal.  Is undef if file hasn't been
2078     # processed at all, empty if has;
2079     main::set_access('handle', \%handle);
2080
2081     my %added_lines;
2082     # cache of lines added virtually to the file, internal
2083     main::set_access('added_lines', \%added_lines);
2084
2085     my %errors;
2086     # cache of errors found, internal
2087     main::set_access('errors', \%errors);
2088
2089     my %missings;
2090     # storage of '@missing' defaults lines
2091     main::set_access('missings', \%missings);
2092
2093     sub new {
2094         my $class = shift;
2095
2096         my $self = bless \do{ my $anonymous_scalar }, $class;
2097         my $addr = do { no overloading; pack 'J', $self; };
2098
2099         # Set defaults
2100         $handler{$addr} = \&main::process_generic_property_file;
2101         $non_skip{$addr} = 0;
2102         $skip{$addr} = 0;
2103         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2104         $handle{$addr} = undef;
2105         $added_lines{$addr} = [ ];
2106         $each_line_handler{$addr} = [ ];
2107         $errors{$addr} = { };
2108         $missings{$addr} = [ ];
2109
2110         # Two positional parameters.
2111         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2112         $file{$addr} = main::internal_file_to_platform(shift);
2113         $first_released{$addr} = shift;
2114
2115         # The rest of the arguments are key => value pairs
2116         # %constructor_fields has been set up earlier to list all possible
2117         # ones.  Either set or push, depending on how the default has been set
2118         # up just above.
2119         my %args = @_;
2120         foreach my $key (keys %args) {
2121             my $argument = $args{$key};
2122
2123             # Note that the fields are the lower case of the constructor keys
2124             my $hash = $constructor_fields{lc $key};
2125             if (! defined $hash) {
2126                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2127                 next;
2128             }
2129             if (ref $hash->{$addr} eq 'ARRAY') {
2130                 if (ref $argument eq 'ARRAY') {
2131                     foreach my $argument (@{$argument}) {
2132                         next if ! defined $argument;
2133                         push @{$hash->{$addr}}, $argument;
2134                     }
2135                 }
2136                 else {
2137                     push @{$hash->{$addr}}, $argument if defined $argument;
2138                 }
2139             }
2140             else {
2141                 $hash->{$addr} = $argument;
2142             }
2143             delete $args{$key};
2144         };
2145
2146         # If the file has a property for it, it means that the property is not
2147         # listed in the file's entries.  So add a handler to the list of line
2148         # handlers to insert the property name into the lines, to provide a
2149         # uniform interface to the final processing subroutine.
2150         # the final code doesn't have to worry about that.
2151         if ($property{$addr}) {
2152             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2153         }
2154
2155         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2156             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2157         }
2158
2159         # If skipping, set to optional, and add to list of ignored files,
2160         # including its reason
2161         if ($skip{$addr}) {
2162             $optional{$addr} = 1;
2163             $skipped_files{$file{$addr}} = $skip{$addr}
2164         }
2165
2166         return $self;
2167     }
2168
2169
2170     use overload
2171         fallback => 0,
2172         qw("") => "_operator_stringify",
2173         "." => \&main::_operator_dot,
2174     ;
2175
2176     sub _operator_stringify {
2177         my $self = shift;
2178
2179         return __PACKAGE__ . " object for " . $self->file;
2180     }
2181
2182     # flag to make sure extracted files are processed early
2183     my $seen_non_extracted_non_age = 0;
2184
2185     sub run {
2186         # Process the input object $self.  This opens and closes the file and
2187         # calls all the handlers for it.  Currently,  this can only be called
2188         # once per file, as it destroy's the EOF handler
2189
2190         my $self = shift;
2191         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2192
2193         my $addr = do { no overloading; pack 'J', $self; };
2194
2195         my $file = $file{$addr};
2196
2197         # Don't process if not expecting this file (because released later
2198         # than this Unicode version), and isn't there.  This means if someone
2199         # copies it into an earlier version's directory, we will go ahead and
2200         # process it.
2201         return if $first_released{$addr} gt $v_version && ! -e $file;
2202
2203         # If in debugging mode and this file doesn't have the non-skip
2204         # flag set, and isn't one of the critical files, skip it.
2205         if ($debug_skip
2206             && $first_released{$addr} ne v0
2207             && ! $non_skip{$addr})
2208         {
2209             print "Skipping $file in debugging\n" if $verbosity;
2210             return;
2211         }
2212
2213         # File could be optional
2214         if ($optional{$addr}) {
2215             return unless -e $file;
2216             my $result = eval $optional{$addr};
2217             if (! defined $result) {
2218                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2219                 return;
2220             }
2221             if (! $result) {
2222                 if ($verbosity) {
2223                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2224                 }
2225                 return;
2226             }
2227         }
2228
2229         if (! defined $file || ! -e $file) {
2230
2231             # If the file doesn't exist, see if have internal data for it
2232             # (based on first_released being 0).
2233             if ($first_released{$addr} eq v0) {
2234                 $handle{$addr} = 'pretend_is_open';
2235             }
2236             else {
2237                 if (! $optional{$addr}  # File could be optional
2238                     && $v_version ge $first_released{$addr})
2239                 {
2240                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2241                 }
2242                 return;
2243             }
2244         }
2245         else {
2246
2247             # Here, the file exists.  Some platforms may change the case of
2248             # its name
2249             if ($seen_non_extracted_non_age) {
2250                 if ($file =~ /$EXTRACTED/i) {
2251                     Carp::my_carp_bug(main::join_lines(<<END
2252 $file should be processed just after the 'Prop...Alias' files, and before
2253 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2254 have subtle problems
2255 END
2256                     ));
2257                 }
2258             }
2259             elsif ($EXTRACTED_DIR
2260                     && $first_released{$addr} ne v0
2261                     && $file !~ /$EXTRACTED/i
2262                     && lc($file) ne 'dage.txt')
2263             {
2264                 # We don't set this (by the 'if' above) if we have no
2265                 # extracted directory, so if running on an early version,
2266                 # this test won't work.  Not worth worrying about.
2267                 $seen_non_extracted_non_age = 1;
2268             }
2269
2270             # And mark the file as having being processed, and warn if it
2271             # isn't a file we are expecting.  As we process the files,
2272             # they are deleted from the hash, so any that remain at the
2273             # end of the program are files that we didn't process.
2274             my $fkey = File::Spec->rel2abs($file);
2275             my $expecting = delete $potential_files{lc($fkey)};
2276
2277             Carp::my_carp("Was not expecting '$file'.") if
2278                     ! $expecting
2279                     && ! defined $handle{$addr};
2280
2281             # Having deleted from expected files, we can quit if not to do
2282             # anything.  Don't print progress unless really want verbosity
2283             if ($skip{$addr}) {
2284                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2285                 return;
2286             }
2287
2288             # Open the file, converting the slashes used in this program
2289             # into the proper form for the OS
2290             my $file_handle;
2291             if (not open $file_handle, "<", $file) {
2292                 Carp::my_carp("Can't open $file.  Skipping: $!");
2293                 return 0;
2294             }
2295             $handle{$addr} = $file_handle; # Cache the open file handle
2296         }
2297
2298         if ($verbosity >= $PROGRESS) {
2299             if ($progress_message{$addr}) {
2300                 print "$progress_message{$addr}\n";
2301             }
2302             else {
2303                 # If using a virtual file, say so.
2304                 print "Processing ", (-e $file)
2305                                        ? $file
2306                                        : "substitute $file",
2307                                      "\n";
2308             }
2309         }
2310
2311
2312         # Call any special handler for before the file.
2313         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2314
2315         # Then the main handler
2316         &{$handler{$addr}}($self);
2317
2318         # Then any special post-file handler.
2319         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2320
2321         # If any errors have been accumulated, output the counts (as the first
2322         # error message in each class was output when it was encountered).
2323         if ($errors{$addr}) {
2324             my $total = 0;
2325             my $types = 0;
2326             foreach my $error (keys %{$errors{$addr}}) {
2327                 $total += $errors{$addr}->{$error};
2328                 delete $errors{$addr}->{$error};
2329                 $types++;
2330             }
2331             if ($total > 1) {
2332                 my $message
2333                         = "A total of $total lines had errors in $file.  ";
2334
2335                 $message .= ($types == 1)
2336                             ? '(Only the first one was displayed.)'
2337                             : '(Only the first of each type was displayed.)';
2338                 Carp::my_carp($message);
2339             }
2340         }
2341
2342         if (@{$missings{$addr}}) {
2343             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2344         }
2345
2346         # If a real file handle, close it.
2347         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2348                                                         ref $handle{$addr};
2349         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2350                                # the file, as opposed to undef
2351         return;
2352     }
2353
2354     sub next_line {
2355         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2356         # if such a line exists.  'logical' means that any lines that have
2357         # been added via insert_lines() will be returned in $_ before the file
2358         # is read again.
2359
2360         my $self = shift;
2361         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2362
2363         my $addr = do { no overloading; pack 'J', $self; };
2364
2365         # Here the file is open (or if the handle is not a ref, is an open
2366         # 'virtual' file).  Get the next line; any inserted lines get priority
2367         # over the file itself.
2368         my $adjusted;
2369
2370         LINE:
2371         while (1) { # Loop until find non-comment, non-empty line
2372             #local $to_trace = 1 if main::DEBUG;
2373             my $inserted_ref = shift @{$added_lines{$addr}};
2374             if (defined $inserted_ref) {
2375                 ($adjusted, $_) = @{$inserted_ref};
2376                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2377                 return 1 if $adjusted;
2378             }
2379             else {
2380                 last if ! ref $handle{$addr}; # Don't read unless is real file
2381                 last if ! defined ($_ = readline $handle{$addr});
2382             }
2383             chomp;
2384             trace $_ if main::DEBUG && $to_trace;
2385
2386             # See if this line is the comment line that defines what property
2387             # value that code points that are not listed in the file should
2388             # have.  The format or existence of these lines is not guaranteed
2389             # by Unicode since they are comments, but the documentation says
2390             # that this was added for machine-readability, so probably won't
2391             # change.  This works starting in Unicode Version 5.0.  They look
2392             # like:
2393             #
2394             # @missing: 0000..10FFFF; Not_Reordered
2395             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2396             # @missing: 0000..10FFFF; ; NaN
2397             #
2398             # Save the line for a later get_missings() call.
2399             if (/$missing_defaults_prefix/) {
2400                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2401                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2402                 }
2403                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2404                     my @defaults = split /\s* ; \s*/x, $_;
2405
2406                     # The first field is the @missing, which ends in a
2407                     # semi-colon, so can safely shift.
2408                     shift @defaults;
2409
2410                     # Some of these lines may have empty field placeholders
2411                     # which get in the way.  An example is:
2412                     # @missing: 0000..10FFFF; ; NaN
2413                     # Remove them.  Process starting from the top so the
2414                     # splice doesn't affect things still to be looked at.
2415                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2416                         next if $defaults[$i] ne "";
2417                         splice @defaults, $i, 1;
2418                     }
2419
2420                     # What's left should be just the property (maybe) and the
2421                     # default.  Having only one element means it doesn't have
2422                     # the property.
2423                     my $default;
2424                     my $property;
2425                     if (@defaults >= 1) {
2426                         if (@defaults == 1) {
2427                             $default = $defaults[0];
2428                         }
2429                         else {
2430                             $property = $defaults[0];
2431                             $default = $defaults[1];
2432                         }
2433                     }
2434
2435                     if (@defaults < 1
2436                         || @defaults > 2
2437                         || ($default =~ /^</
2438                             && $default !~ /^<code *point>$/i
2439                             && $default !~ /^<none>$/i
2440                             && $default !~ /^<script>$/i))
2441                     {
2442                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2443                     }
2444                     else {
2445
2446                         # If the property is missing from the line, it should
2447                         # be the one for the whole file
2448                         $property = $property{$addr} if ! defined $property;
2449
2450                         # Change <none> to the null string, which is what it
2451                         # really means.  If the default is the code point
2452                         # itself, set it to <code point>, which is what
2453                         # Unicode uses (but sometimes they've forgotten the
2454                         # space)
2455                         if ($default =~ /^<none>$/i) {
2456                             $default = "";
2457                         }
2458                         elsif ($default =~ /^<code *point>$/i) {
2459                             $default = $CODE_POINT;
2460                         }
2461                         elsif ($default =~ /^<script>$/i) {
2462
2463                             # Special case this one.  Currently is from
2464                             # ScriptExtensions.txt, and means for all unlisted
2465                             # code points, use their Script property values.
2466                             # For the code points not listed in that file, the
2467                             # default value is 'Unknown'.
2468                             $default = "Unknown";
2469                         }
2470
2471                         # Store them as a sub-arrays with both components.
2472                         push @{$missings{$addr}}, [ $default, $property ];
2473                     }
2474                 }
2475
2476                 # There is nothing for the caller to process on this comment
2477                 # line.
2478                 next;
2479             }
2480
2481             # Remove comments and trailing space, and skip this line if the
2482             # result is empty
2483             s/#.*//;
2484             s/\s+$//;
2485             next if /^$/;
2486
2487             # Call any handlers for this line, and skip further processing of
2488             # the line if the handler sets the line to null.
2489             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2490                 &{$sub_ref}($self);
2491                 next LINE if /^$/;
2492             }
2493
2494             # Here the line is ok.  return success.
2495             return 1;
2496         } # End of looping through lines.
2497
2498         # If there is an EOF handler, call it (only once) and if it generates
2499         # more lines to process go back in the loop to handle them.
2500         if ($eof_handler{$addr}) {
2501             &{$eof_handler{$addr}}($self);
2502             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2503             goto LINE if $added_lines{$addr};
2504         }
2505
2506         # Return failure -- no more lines.
2507         return 0;
2508
2509     }
2510
2511 #   Not currently used, not fully tested.
2512 #    sub peek {
2513 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2514 #        # record.  Not callable from an each_line_handler(), nor does it call
2515 #        # an each_line_handler() on the line.
2516 #
2517 #        my $self = shift;
2518 #        my $addr = do { no overloading; pack 'J', $self; };
2519 #
2520 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2521 #            my ($adjusted, $line) = @{$inserted_ref};
2522 #            next if $adjusted;
2523 #
2524 #            # Remove comments and trailing space, and return a non-empty
2525 #            # resulting line
2526 #            $line =~ s/#.*//;
2527 #            $line =~ s/\s+$//;
2528 #            return $line if $line ne "";
2529 #        }
2530 #
2531 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2532 #        while (1) { # Loop until find non-comment, non-empty line
2533 #            local $to_trace = 1 if main::DEBUG;
2534 #            trace $_ if main::DEBUG && $to_trace;
2535 #            return if ! defined (my $line = readline $handle{$addr});
2536 #            chomp $line;
2537 #            push @{$added_lines{$addr}}, [ 0, $line ];
2538 #
2539 #            $line =~ s/#.*//;
2540 #            $line =~ s/\s+$//;
2541 #            return $line if $line ne "";
2542 #        }
2543 #
2544 #        return;
2545 #    }
2546
2547
2548     sub insert_lines {
2549         # Lines can be inserted so that it looks like they were in the input
2550         # file at the place it was when this routine is called.  See also
2551         # insert_adjusted_lines().  Lines inserted via this routine go through
2552         # any each_line_handler()
2553
2554         my $self = shift;
2555
2556         # Each inserted line is an array, with the first element being 0 to
2557         # indicate that this line hasn't been adjusted, and needs to be
2558         # processed.
2559         no overloading;
2560         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2561         return;
2562     }
2563
2564     sub insert_adjusted_lines {
2565         # Lines can be inserted so that it looks like they were in the input
2566         # file at the place it was when this routine is called.  See also
2567         # insert_lines().  Lines inserted via this routine are already fully
2568         # adjusted, ready to be processed; each_line_handler()s handlers will
2569         # not be called.  This means this is not a completely general
2570         # facility, as only the last each_line_handler on the stack should
2571         # call this.  It could be made more general, by passing to each of the
2572         # line_handlers their position on the stack, which they would pass on
2573         # to this routine, and that would replace the boolean first element in
2574         # the anonymous array pushed here, so that the next_line routine could
2575         # use that to call only those handlers whose index is after it on the
2576         # stack.  But this is overkill for what is needed now.
2577
2578         my $self = shift;
2579         trace $_[0] if main::DEBUG && $to_trace;
2580
2581         # Each inserted line is an array, with the first element being 1 to
2582         # indicate that this line has been adjusted
2583         no overloading;
2584         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2585         return;
2586     }
2587
2588     sub get_missings {
2589         # Returns the stored up @missings lines' values, and clears the list.
2590         # The values are in an array, consisting of the default in the first
2591         # element, and the property in the 2nd.  However, since these lines
2592         # can be stacked up, the return is an array of all these arrays.
2593
2594         my $self = shift;
2595         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2596
2597         my $addr = do { no overloading; pack 'J', $self; };
2598
2599         # If not accepting a list return, just return the first one.
2600         return shift @{$missings{$addr}} unless wantarray;
2601
2602         my @return = @{$missings{$addr}};
2603         undef @{$missings{$addr}};
2604         return @return;
2605     }
2606
2607     sub _insert_property_into_line {
2608         # Add a property field to $_, if this file requires it.
2609
2610         my $self = shift;
2611         my $addr = do { no overloading; pack 'J', $self; };
2612         my $property = $property{$addr};
2613         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2614
2615         $_ =~ s/(;|$)/; $property$1/;
2616         return;
2617     }
2618
2619     sub carp_bad_line {
2620         # Output consistent error messages, using either a generic one, or the
2621         # one given by the optional parameter.  To avoid gazillions of the
2622         # same message in case the syntax of a  file is way off, this routine
2623         # only outputs the first instance of each message, incrementing a
2624         # count so the totals can be output at the end of the file.
2625
2626         my $self = shift;
2627         my $message = shift;
2628         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2629
2630         my $addr = do { no overloading; pack 'J', $self; };
2631
2632         $message = 'Unexpected line' unless $message;
2633
2634         # No trailing punctuation so as to fit with our addenda.
2635         $message =~ s/[.:;,]$//;
2636
2637         # If haven't seen this exact message before, output it now.  Otherwise
2638         # increment the count of how many times it has occurred
2639         unless ($errors{$addr}->{$message}) {
2640             Carp::my_carp("$message in '$_' in "
2641                             . $file{$addr}
2642                             . " at line $..  Skipping this line;");
2643             $errors{$addr}->{$message} = 1;
2644         }
2645         else {
2646             $errors{$addr}->{$message}++;
2647         }
2648
2649         # Clear the line to prevent any further (meaningful) processing of it.
2650         $_ = "";
2651
2652         return;
2653     }
2654 } # End closure
2655
2656 package Multi_Default;
2657
2658 # Certain properties in early versions of Unicode had more than one possible
2659 # default for code points missing from the files.  In these cases, one
2660 # default applies to everything left over after all the others are applied,
2661 # and for each of the others, there is a description of which class of code
2662 # points applies to it.  This object helps implement this by storing the
2663 # defaults, and for all but that final default, an eval string that generates
2664 # the class that it applies to.
2665
2666
2667 {   # Closure
2668
2669     main::setup_package();
2670
2671     my %class_defaults;
2672     # The defaults structure for the classes
2673     main::set_access('class_defaults', \%class_defaults);
2674
2675     my %other_default;
2676     # The default that applies to everything left over.
2677     main::set_access('other_default', \%other_default, 'r');
2678
2679
2680     sub new {
2681         # The constructor is called with default => eval pairs, terminated by
2682         # the left-over default. e.g.
2683         # Multi_Default->new(
2684         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2685         #               -  0x200D',
2686         #        'R' => 'some other expression that evaluates to code points',
2687         #        .
2688         #        .
2689         #        .
2690         #        'U'));
2691
2692         my $class = shift;
2693
2694         my $self = bless \do{my $anonymous_scalar}, $class;
2695         my $addr = do { no overloading; pack 'J', $self; };
2696
2697         while (@_ > 1) {
2698             my $default = shift;
2699             my $eval = shift;
2700             $class_defaults{$addr}->{$default} = $eval;
2701         }
2702
2703         $other_default{$addr} = shift;
2704
2705         return $self;
2706     }
2707
2708     sub get_next_defaults {
2709         # Iterates and returns the next class of defaults.
2710         my $self = shift;
2711         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2712
2713         my $addr = do { no overloading; pack 'J', $self; };
2714
2715         return each %{$class_defaults{$addr}};
2716     }
2717 }
2718
2719 package Alias;
2720
2721 # An alias is one of the names that a table goes by.  This class defines them
2722 # including some attributes.  Everything is currently setup in the
2723 # constructor.
2724
2725
2726 {   # Closure
2727
2728     main::setup_package();
2729
2730     my %name;
2731     main::set_access('name', \%name, 'r');
2732
2733     my %loose_match;
2734     # Should this name match loosely or not.
2735     main::set_access('loose_match', \%loose_match, 'r');
2736
2737     my %make_re_pod_entry;
2738     # Some aliases should not get their own entries in the re section of the
2739     # pod, because they are covered by a wild-card, and some we want to
2740     # discourage use of.  Binary
2741     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
2742
2743     my %ucd;
2744     # Is this documented to be accessible via Unicode::UCD
2745     main::set_access('ucd', \%ucd, 'r', 's');
2746
2747     my %status;
2748     # Aliases have a status, like deprecated, or even suppressed (which means
2749     # they don't appear in documentation).  Enum
2750     main::set_access('status', \%status, 'r');
2751
2752     my %ok_as_filename;
2753     # Similarly, some aliases should not be considered as usable ones for
2754     # external use, such as file names, or we don't want documentation to
2755     # recommend them.  Boolean
2756     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
2757
2758     sub new {
2759         my $class = shift;
2760
2761         my $self = bless \do { my $anonymous_scalar }, $class;
2762         my $addr = do { no overloading; pack 'J', $self; };
2763
2764         $name{$addr} = shift;
2765         $loose_match{$addr} = shift;
2766         $make_re_pod_entry{$addr} = shift;
2767         $ok_as_filename{$addr} = shift;
2768         $status{$addr} = shift;
2769         $ucd{$addr} = shift;
2770
2771         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2772
2773         # Null names are never ok externally
2774         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
2775
2776         return $self;
2777     }
2778 }
2779
2780 package Range;
2781
2782 # A range is the basic unit for storing code points, and is described in the
2783 # comments at the beginning of the program.  Each range has a starting code
2784 # point; an ending code point (not less than the starting one); a value
2785 # that applies to every code point in between the two end-points, inclusive;
2786 # and an enum type that applies to the value.  The type is for the user's
2787 # convenience, and has no meaning here, except that a non-zero type is
2788 # considered to not obey the normal Unicode rules for having standard forms.
2789 #
2790 # The same structure is used for both map and match tables, even though in the
2791 # latter, the value (and hence type) is irrelevant and could be used as a
2792 # comment.  In map tables, the value is what all the code points in the range
2793 # map to.  Type 0 values have the standardized version of the value stored as
2794 # well, so as to not have to recalculate it a lot.
2795
2796 sub trace { return main::trace(@_); }
2797
2798 {   # Closure
2799
2800     main::setup_package();
2801
2802     my %start;
2803     main::set_access('start', \%start, 'r', 's');
2804
2805     my %end;
2806     main::set_access('end', \%end, 'r', 's');
2807
2808     my %value;
2809     main::set_access('value', \%value, 'r');
2810
2811     my %type;
2812     main::set_access('type', \%type, 'r');
2813
2814     my %standard_form;
2815     # The value in internal standard form.  Defined only if the type is 0.
2816     main::set_access('standard_form', \%standard_form);
2817
2818     # Note that if these fields change, the dump() method should as well
2819
2820     sub new {
2821         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2822         my $class = shift;
2823
2824         my $self = bless \do { my $anonymous_scalar }, $class;
2825         my $addr = do { no overloading; pack 'J', $self; };
2826
2827         $start{$addr} = shift;
2828         $end{$addr} = shift;
2829
2830         my %args = @_;
2831
2832         my $value = delete $args{'Value'};  # Can be 0
2833         $value = "" unless defined $value;
2834         $value{$addr} = $value;
2835
2836         $type{$addr} = delete $args{'Type'} || 0;
2837
2838         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2839
2840         if (! $type{$addr}) {
2841             $standard_form{$addr} = main::standardize($value);
2842         }
2843
2844         return $self;
2845     }
2846
2847     use overload
2848         fallback => 0,
2849         qw("") => "_operator_stringify",
2850         "." => \&main::_operator_dot,
2851     ;
2852
2853     sub _operator_stringify {
2854         my $self = shift;
2855         my $addr = do { no overloading; pack 'J', $self; };
2856
2857         # Output it like '0041..0065 (value)'
2858         my $return = sprintf("%04X", $start{$addr})
2859                         .  '..'
2860                         . sprintf("%04X", $end{$addr});
2861         my $value = $value{$addr};
2862         my $type = $type{$addr};
2863         $return .= ' (';
2864         $return .= "$value";
2865         $return .= ", Type=$type" if $type != 0;
2866         $return .= ')';
2867
2868         return $return;
2869     }
2870
2871     sub standard_form {
2872         # The standard form is the value itself if the standard form is
2873         # undefined (that is if the value is special)
2874
2875         my $self = shift;
2876         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2877
2878         my $addr = do { no overloading; pack 'J', $self; };
2879
2880         return $standard_form{$addr} if defined $standard_form{$addr};
2881         return $value{$addr};
2882     }
2883
2884     sub dump {
2885         # Human, not machine readable.  For machine readable, comment out this
2886         # entire routine and let the standard one take effect.
2887         my $self = shift;
2888         my $indent = shift;
2889         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2890
2891         my $addr = do { no overloading; pack 'J', $self; };
2892
2893         my $return = $indent
2894                     . sprintf("%04X", $start{$addr})
2895                     . '..'
2896                     . sprintf("%04X", $end{$addr})
2897                     . " '$value{$addr}';";
2898         if (! defined $standard_form{$addr}) {
2899             $return .= "(type=$type{$addr})";
2900         }
2901         elsif ($standard_form{$addr} ne $value{$addr}) {
2902             $return .= "(standard '$standard_form{$addr}')";
2903         }
2904         return $return;
2905     }
2906 } # End closure
2907
2908 package _Range_List_Base;
2909
2910 # Base class for range lists.  A range list is simply an ordered list of
2911 # ranges, so that the ranges with the lowest starting numbers are first in it.
2912 #
2913 # When a new range is added that is adjacent to an existing range that has the
2914 # same value and type, it merges with it to form a larger range.
2915 #
2916 # Ranges generally do not overlap, except that there can be multiple entries
2917 # of single code point ranges.  This is because of NameAliases.txt.
2918 #
2919 # In this program, there is a standard value such that if two different
2920 # values, have the same standard value, they are considered equivalent.  This
2921 # value was chosen so that it gives correct results on Unicode data
2922
2923 # There are a number of methods to manipulate range lists, and some operators
2924 # are overloaded to handle them.
2925
2926 sub trace { return main::trace(@_); }
2927
2928 { # Closure
2929
2930     our $addr;
2931
2932     main::setup_package();
2933
2934     my %ranges;
2935     # The list of ranges
2936     main::set_access('ranges', \%ranges, 'readable_array');
2937
2938     my %max;
2939     # The highest code point in the list.  This was originally a method, but
2940     # actual measurements said it was used a lot.
2941     main::set_access('max', \%max, 'r');
2942
2943     my %each_range_iterator;
2944     # Iterator position for each_range()
2945     main::set_access('each_range_iterator', \%each_range_iterator);
2946
2947     my %owner_name_of;
2948     # Name of parent this is attached to, if any.  Solely for better error
2949     # messages.
2950     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2951
2952     my %_search_ranges_cache;
2953     # A cache of the previous result from _search_ranges(), for better
2954     # performance
2955     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2956
2957     sub new {
2958         my $class = shift;
2959         my %args = @_;
2960
2961         # Optional initialization data for the range list.
2962         my $initialize = delete $args{'Initialize'};
2963
2964         my $self;
2965
2966         # Use _union() to initialize.  _union() returns an object of this
2967         # class, which means that it will call this constructor recursively.
2968         # But it won't have this $initialize parameter so that it won't
2969         # infinitely loop on this.
2970         return _union($class, $initialize, %args) if defined $initialize;
2971
2972         $self = bless \do { my $anonymous_scalar }, $class;
2973         my $addr = do { no overloading; pack 'J', $self; };
2974
2975         # Optional parent object, only for debug info.
2976         $owner_name_of{$addr} = delete $args{'Owner'};
2977         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2978
2979         # Stringify, in case it is an object.
2980         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2981
2982         # This is used only for error messages, and so a colon is added
2983         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2984
2985         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2986
2987         # Max is initialized to a negative value that isn't adjacent to 0,
2988         # for simpler tests
2989         $max{$addr} = -2;
2990
2991         $_search_ranges_cache{$addr} = 0;
2992         $ranges{$addr} = [];
2993
2994         return $self;
2995     }
2996
2997     use overload
2998         fallback => 0,
2999         qw("") => "_operator_stringify",
3000         "." => \&main::_operator_dot,
3001     ;
3002
3003     sub _operator_stringify {
3004         my $self = shift;
3005         my $addr = do { no overloading; pack 'J', $self; };
3006
3007         return "Range_List attached to '$owner_name_of{$addr}'"
3008                                                 if $owner_name_of{$addr};
3009         return "anonymous Range_List " . \$self;
3010     }
3011
3012     sub _union {
3013         # Returns the union of the input code points.  It can be called as
3014         # either a constructor or a method.  If called as a method, the result
3015         # will be a new() instance of the calling object, containing the union
3016         # of that object with the other parameter's code points;  if called as
3017         # a constructor, the first parameter gives the class that the new object
3018         # should be, and the second parameter gives the code points to go into
3019         # it.
3020         # In either case, there are two parameters looked at by this routine;
3021         # any additional parameters are passed to the new() constructor.
3022         #
3023         # The code points can come in the form of some object that contains
3024         # ranges, and has a conventionally named method to access them; or
3025         # they can be an array of individual code points (as integers); or
3026         # just a single code point.
3027         #
3028         # If they are ranges, this routine doesn't make any effort to preserve
3029         # the range values and types of one input over the other.  Therefore
3030         # this base class should not allow _union to be called from other than
3031         # initialization code, so as to prevent two tables from being added
3032         # together where the range values matter.  The general form of this
3033         # routine therefore belongs in a derived class, but it was moved here
3034         # to avoid duplication of code.  The failure to overload this in this
3035         # class keeps it safe.
3036         #
3037         # It does make the effort during initialization to accept tables with
3038         # multiple values for the same code point, and to preserve the order
3039         # of these.  If there is only one input range or range set, it doesn't
3040         # sort (as it should already be sorted to the desired order), and will
3041         # accept multiple values per code point.  Otherwise it will merge
3042         # multiple values into a single one.
3043
3044         my $self;
3045         my @args;   # Arguments to pass to the constructor
3046
3047         my $class = shift;
3048
3049         # If a method call, will start the union with the object itself, and
3050         # the class of the new object will be the same as self.
3051         if (ref $class) {
3052             $self = $class;
3053             $class = ref $self;
3054             push @args, $self;
3055         }
3056
3057         # Add the other required parameter.
3058         push @args, shift;
3059         # Rest of parameters are passed on to the constructor
3060
3061         # Accumulate all records from both lists.
3062         my @records;
3063         my $input_count = 0;
3064         for my $arg (@args) {
3065             #local $to_trace = 0 if main::DEBUG;
3066             trace "argument = $arg" if main::DEBUG && $to_trace;
3067             if (! defined $arg) {
3068                 my $message = "";
3069                 if (defined $self) {
3070                     no overloading;
3071                     $message .= $owner_name_of{pack 'J', $self};
3072                 }
3073                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
3074                 return;
3075             }
3076
3077             $arg = [ $arg ] if ! ref $arg;
3078             my $type = ref $arg;
3079             if ($type eq 'ARRAY') {
3080                 foreach my $element (@$arg) {
3081                     push @records, Range->new($element, $element);
3082                     $input_count++;
3083                 }
3084             }
3085             elsif ($arg->isa('Range')) {
3086                 push @records, $arg;
3087                 $input_count++;
3088             }
3089             elsif ($arg->can('ranges')) {
3090                 push @records, $arg->ranges;
3091                 $input_count++;
3092             }
3093             else {
3094                 my $message = "";
3095                 if (defined $self) {
3096                     no overloading;
3097                     $message .= $owner_name_of{pack 'J', $self};
3098                 }
3099                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3100                 return;
3101             }
3102         }
3103
3104         # Sort with the range containing the lowest ordinal first, but if
3105         # two ranges start at the same code point, sort with the bigger range
3106         # of the two first, because it takes fewer cycles.
3107         if ($input_count > 1) {
3108             @records = sort { ($a->start <=> $b->start)
3109                                       or
3110                                     # if b is shorter than a, b->end will be
3111                                     # less than a->end, and we want to select
3112                                     # a, so want to return -1
3113                                     ($b->end <=> $a->end)
3114                                    } @records;
3115         }
3116
3117         my $new = $class->new(@_);
3118
3119         # Fold in records so long as they add new information.
3120         for my $set (@records) {
3121             my $start = $set->start;
3122             my $end   = $set->end;
3123             my $value = $set->value;
3124             my $type  = $set->type;
3125             if ($start > $new->max) {
3126                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3127             }
3128             elsif ($end > $new->max) {
3129                 $new->_add_delete('+', $new->max +1, $end, $value,
3130                                                                 Type => $type);
3131             }
3132             elsif ($input_count == 1) {
3133                 # Here, overlaps existing range, but is from a single input,
3134                 # so preserve the multiple values from that input.
3135                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3136                                                 Replace => $MULTIPLE_AFTER);
3137             }
3138         }
3139
3140         return $new;
3141     }
3142
3143     sub range_count {        # Return the number of ranges in the range list
3144         my $self = shift;
3145         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3146
3147         no overloading;
3148         return scalar @{$ranges{pack 'J', $self}};
3149     }
3150
3151     sub min {
3152         # Returns the minimum code point currently in the range list, or if
3153         # the range list is empty, 2 beyond the max possible.  This is a
3154         # method because used so rarely, that not worth saving between calls,
3155         # and having to worry about changing it as ranges are added and
3156         # deleted.
3157
3158         my $self = shift;
3159         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3160
3161         my $addr = do { no overloading; pack 'J', $self; };
3162
3163         # If the range list is empty, return a large value that isn't adjacent
3164         # to any that could be in the range list, for simpler tests
3165         return $MAX_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3166         return $ranges{$addr}->[0]->start;
3167     }
3168
3169     sub contains {
3170         # Boolean: Is argument in the range list?  If so returns $i such that:
3171         #   range[$i]->end < $codepoint <= range[$i+1]->end
3172         # which is one beyond what you want; this is so that the 0th range
3173         # doesn't return false
3174         my $self = shift;
3175         my $codepoint = shift;
3176         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3177
3178         my $i = $self->_search_ranges($codepoint);
3179         return 0 unless defined $i;
3180
3181         # The search returns $i, such that
3182         #   range[$i-1]->end < $codepoint <= range[$i]->end
3183         # So is in the table if and only iff it is at least the start position
3184         # of range $i.
3185         no overloading;
3186         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3187         return $i + 1;
3188     }
3189
3190     sub containing_range {
3191         # Returns the range object that contains the code point, undef if none
3192
3193         my $self = shift;
3194         my $codepoint = shift;
3195         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3196
3197         my $i = $self->contains($codepoint);
3198         return unless $i;
3199
3200         # contains() returns 1 beyond where we should look
3201         no overloading;
3202         return $ranges{pack 'J', $self}->[$i-1];
3203     }
3204
3205     sub value_of {
3206         # Returns the value associated with the code point, undef if none
3207
3208         my $self = shift;
3209         my $codepoint = shift;
3210         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3211
3212         my $range = $self->containing_range($codepoint);
3213         return unless defined $range;
3214
3215         return $range->value;
3216     }
3217
3218     sub type_of {
3219         # Returns the type of the range containing the code point, undef if
3220         # the code point is not in the table
3221
3222         my $self = shift;
3223         my $codepoint = shift;
3224         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3225
3226         my $range = $self->containing_range($codepoint);
3227         return unless defined $range;
3228
3229         return $range->type;
3230     }
3231
3232     sub _search_ranges {
3233         # Find the range in the list which contains a code point, or where it
3234         # should go if were to add it.  That is, it returns $i, such that:
3235         #   range[$i-1]->end < $codepoint <= range[$i]->end
3236         # Returns undef if no such $i is possible (e.g. at end of table), or
3237         # if there is an error.
3238
3239         my $self = shift;
3240         my $code_point = shift;
3241         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3242
3243         my $addr = do { no overloading; pack 'J', $self; };
3244
3245         return if $code_point > $max{$addr};
3246         my $r = $ranges{$addr};                # The current list of ranges
3247         my $range_list_size = scalar @$r;
3248         my $i;
3249
3250         use integer;        # want integer division
3251
3252         # Use the cached result as the starting guess for this one, because,
3253         # an experiment on 5.1 showed that 90% of the time the cache was the
3254         # same as the result on the next call (and 7% it was one less).
3255         $i = $_search_ranges_cache{$addr};
3256         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3257                                             # from an intervening deletion
3258         #local $to_trace = 1 if main::DEBUG;
3259         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3260         return $i if $code_point <= $r->[$i]->end
3261                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3262
3263         # Here the cache doesn't yield the correct $i.  Try adding 1.
3264         if ($i < $range_list_size - 1
3265             && $r->[$i]->end < $code_point &&
3266             $code_point <= $r->[$i+1]->end)
3267         {
3268             $i++;
3269             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3270             $_search_ranges_cache{$addr} = $i;
3271             return $i;
3272         }
3273
3274         # Here, adding 1 also didn't work.  We do a binary search to
3275         # find the correct position, starting with current $i
3276         my $lower = 0;
3277         my $upper = $range_list_size - 1;
3278         while (1) {
3279             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3280
3281             if ($code_point <= $r->[$i]->end) {
3282
3283                 # Here we have met the upper constraint.  We can quit if we
3284                 # also meet the lower one.
3285                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3286
3287                 $upper = $i;        # Still too high.
3288
3289             }
3290             else {
3291
3292                 # Here, $r[$i]->end < $code_point, so look higher up.
3293                 $lower = $i;
3294             }
3295
3296             # Split search domain in half to try again.
3297             my $temp = ($upper + $lower) / 2;
3298
3299             # No point in continuing unless $i changes for next time
3300             # in the loop.
3301             if ($temp == $i) {
3302
3303                 # We can't reach the highest element because of the averaging.
3304                 # So if one below the upper edge, force it there and try one
3305                 # more time.
3306                 if ($i == $range_list_size - 2) {
3307
3308                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3309                     $i = $range_list_size - 1;
3310
3311                     # Change $lower as well so if fails next time through,
3312                     # taking the average will yield the same $i, and we will
3313                     # quit with the error message just below.
3314                     $lower = $i;
3315                     next;
3316                 }
3317                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3318                 return;
3319             }
3320             $i = $temp;
3321         } # End of while loop
3322
3323         if (main::DEBUG && $to_trace) {
3324             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3325             trace "i=  [ $i ]", $r->[$i];
3326             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3327         }
3328
3329         # Here we have found the offset.  Cache it as a starting point for the
3330         # next call.
3331         $_search_ranges_cache{$addr} = $i;
3332         return $i;
3333     }
3334
3335     sub _add_delete {
3336         # Add, replace or delete ranges to or from a list.  The $type
3337         # parameter gives which:
3338         #   '+' => insert or replace a range, returning a list of any changed
3339         #          ranges.
3340         #   '-' => delete a range, returning a list of any deleted ranges.
3341         #
3342         # The next three parameters give respectively the start, end, and
3343         # value associated with the range.  'value' should be null unless the
3344         # operation is '+';
3345         #
3346         # The range list is kept sorted so that the range with the lowest
3347         # starting position is first in the list, and generally, adjacent
3348         # ranges with the same values are merged into a single larger one (see
3349         # exceptions below).
3350         #
3351         # There are more parameters; all are key => value pairs:
3352         #   Type    gives the type of the value.  It is only valid for '+'.
3353         #           All ranges have types; if this parameter is omitted, 0 is
3354         #           assumed.  Ranges with type 0 are assumed to obey the
3355         #           Unicode rules for casing, etc; ranges with other types are
3356         #           not.  Otherwise, the type is arbitrary, for the caller's
3357         #           convenience, and looked at only by this routine to keep
3358         #           adjacent ranges of different types from being merged into
3359         #           a single larger range, and when Replace =>
3360         #           $IF_NOT_EQUIVALENT is specified (see just below).
3361         #   Replace  determines what to do if the range list already contains
3362         #            ranges which coincide with all or portions of the input
3363         #            range.  It is only valid for '+':
3364         #       => $NO            means that the new value is not to replace
3365         #                         any existing ones, but any empty gaps of the
3366         #                         range list coinciding with the input range
3367         #                         will be filled in with the new value.
3368         #       => $UNCONDITIONALLY  means to replace the existing values with
3369         #                         this one unconditionally.  However, if the
3370         #                         new and old values are identical, the
3371         #                         replacement is skipped to save cycles
3372         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3373         #          (the default)  with this one if they are not equivalent.
3374         #                         Ranges are equivalent if their types are the
3375         #                         same, and they are the same string; or if
3376         #                         both are type 0 ranges, if their Unicode
3377         #                         standard forms are identical.  In this last
3378         #                         case, the routine chooses the more "modern"
3379         #                         one to use.  This is because some of the
3380         #                         older files are formatted with values that
3381         #                         are, for example, ALL CAPs, whereas the
3382         #                         derived files have a more modern style,
3383         #                         which looks better.  By looking for this
3384         #                         style when the pre-existing and replacement
3385         #                         standard forms are the same, we can move to
3386         #                         the modern style
3387         #       => $MULTIPLE_BEFORE means that if this range duplicates an
3388         #                         existing one, but has a different value,
3389         #                         don't replace the existing one, but insert
3390         #                         this, one so that the same range can occur
3391         #                         multiple times.  They are stored LIFO, so
3392         #                         that the final one inserted is the first one
3393         #                         returned in an ordered search of the table.
3394         #       => $MULTIPLE_AFTER is like $MULTIPLE_BEFORE, but is stored
3395         #                         FIFO, so that this one is inserted after all
3396         #                         others that currently exist.
3397         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3398         #
3399         # "same value" means identical for non-type-0 ranges, and it means
3400         # having the same standard forms for type-0 ranges.
3401
3402         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3403
3404         my $self = shift;
3405         my $operation = shift;   # '+' for add/replace; '-' for delete;
3406         my $start = shift;
3407         my $end   = shift;
3408         my $value = shift;
3409
3410         my %args = @_;
3411
3412         $value = "" if not defined $value;        # warning: $value can be "0"
3413
3414         my $replace = delete $args{'Replace'};
3415         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3416
3417         my $type = delete $args{'Type'};
3418         $type = 0 unless defined $type;
3419
3420         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3421
3422         my $addr = do { no overloading; pack 'J', $self; };
3423
3424         if ($operation ne '+' && $operation ne '-') {
3425             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3426             return;
3427         }
3428         unless (defined $start && defined $end) {
3429             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3430             return;
3431         }
3432         unless ($end >= $start) {
3433             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3434             return;
3435         }
3436         #local $to_trace = 1 if main::DEBUG;
3437
3438         if ($operation eq '-') {
3439             if ($replace != $IF_NOT_EQUIVALENT) {
3440                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3441                 $replace = $IF_NOT_EQUIVALENT;
3442             }
3443             if ($type) {
3444                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3445                 $type = 0;
3446             }
3447             if ($value ne "") {
3448                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3449                 $value = "";
3450             }
3451         }
3452
3453         my $r = $ranges{$addr};               # The current list of ranges
3454         my $range_list_size = scalar @$r;     # And its size
3455         my $max = $max{$addr};                # The current high code point in
3456                                               # the list of ranges
3457
3458         # Do a special case requiring fewer machine cycles when the new range
3459         # starts after the current highest point.  The Unicode input data is
3460         # structured so this is common.
3461         if ($start > $max) {
3462
3463             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3464             return if $operation eq '-'; # Deleting a non-existing range is a
3465                                          # no-op
3466
3467             # If the new range doesn't logically extend the current final one
3468             # in the range list, create a new range at the end of the range
3469             # list.  (max cleverly is initialized to a negative number not
3470             # adjacent to 0 if the range list is empty, so even adding a range
3471             # to an empty range list starting at 0 will have this 'if'
3472             # succeed.)
3473             if ($start > $max + 1        # non-adjacent means can't extend.
3474                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3475                 || @{$r}[-1]->type != $type # types differ, can't extend.
3476             ) {
3477                 push @$r, Range->new($start, $end,
3478                                      Value => $value,
3479                                      Type => $type);
3480             }
3481             else {
3482
3483                 # Here, the new range starts just after the current highest in
3484                 # the range list, and they have the same type and value.
3485                 # Extend the current range to incorporate the new one.
3486                 @{$r}[-1]->set_end($end);
3487             }
3488
3489             # This becomes the new maximum.
3490             $max{$addr} = $end;
3491
3492             return;
3493         }
3494         #local $to_trace = 0 if main::DEBUG;
3495
3496         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3497
3498         # Here, the input range isn't after the whole rest of the range list.
3499         # Most likely 'splice' will be needed.  The rest of the routine finds
3500         # the needed splice parameters, and if necessary, does the splice.
3501         # First, find the offset parameter needed by the splice function for
3502         # the input range.  Note that the input range may span multiple
3503         # existing ones, but we'll worry about that later.  For now, just find
3504         # the beginning.  If the input range is to be inserted starting in a
3505         # position not currently in the range list, it must (obviously) come
3506         # just after the range below it, and just before the range above it.
3507         # Slightly less obviously, it will occupy the position currently
3508         # occupied by the range that is to come after it.  More formally, we
3509         # are looking for the position, $i, in the array of ranges, such that:
3510         #
3511         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3512         #
3513         # (The ordered relationships within existing ranges are also shown in
3514         # the equation above).  However, if the start of the input range is
3515         # within an existing range, the splice offset should point to that
3516         # existing range's position in the list; that is $i satisfies a
3517         # somewhat different equation, namely:
3518         #
3519         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3520         #
3521         # More briefly, $start can come before or after r[$i]->start, and at
3522         # this point, we don't know which it will be.  However, these
3523         # two equations share these constraints:
3524         #
3525         #   r[$i-1]->end < $start <= r[$i]->end
3526         #
3527         # And that is good enough to find $i.
3528
3529         my $i = $self->_search_ranges($start);
3530         if (! defined $i) {
3531             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3532             return;
3533         }
3534
3535         # The search function returns $i such that:
3536         #
3537         # r[$i-1]->end < $start <= r[$i]->end
3538         #
3539         # That means that $i points to the first range in the range list
3540         # that could possibly be affected by this operation.  We still don't
3541         # know if the start of the input range is within r[$i], or if it
3542         # points to empty space between r[$i-1] and r[$i].
3543         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3544
3545         # Special case the insertion of data that is not to replace any
3546         # existing data.
3547         if ($replace == $NO) {  # If $NO, has to be operation '+'
3548             #local $to_trace = 1 if main::DEBUG;
3549             trace "Doesn't replace" if main::DEBUG && $to_trace;
3550
3551             # Here, the new range is to take effect only on those code points
3552             # that aren't already in an existing range.  This can be done by
3553             # looking through the existing range list and finding the gaps in
3554             # the ranges that this new range affects, and then calling this
3555             # function recursively on each of those gaps, leaving untouched
3556             # anything already in the list.  Gather up a list of the changed
3557             # gaps first so that changes to the internal state as new ranges
3558             # are added won't be a problem.
3559             my @gap_list;
3560
3561             # First, if the starting point of the input range is outside an
3562             # existing one, there is a gap from there to the beginning of the
3563             # existing range -- add a span to fill the part that this new
3564             # range occupies
3565             if ($start < $r->[$i]->start) {
3566                 push @gap_list, Range->new($start,
3567                                            main::min($end,
3568                                                      $r->[$i]->start - 1),
3569                                            Type => $type);
3570                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3571             }
3572
3573             # Then look through the range list for other gaps until we reach
3574             # the highest range affected by the input one.
3575             my $j;
3576             for ($j = $i+1; $j < $range_list_size; $j++) {
3577                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3578                 last if $end < $r->[$j]->start;
3579
3580                 # If there is a gap between when this range starts and the
3581                 # previous one ends, add a span to fill it.  Note that just
3582                 # because there are two ranges doesn't mean there is a
3583                 # non-zero gap between them.  It could be that they have
3584                 # different values or types
3585                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3586                     push @gap_list,
3587                         Range->new($r->[$j-1]->end + 1,
3588                                    $r->[$j]->start - 1,
3589                                    Type => $type);
3590                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3591                 }
3592             }
3593
3594             # Here, we have either found an existing range in the range list,
3595             # beyond the area affected by the input one, or we fell off the
3596             # end of the loop because the input range affects the whole rest
3597             # of the range list.  In either case, $j is 1 higher than the
3598             # highest affected range.  If $j == $i, it means that there are no
3599             # affected ranges, that the entire insertion is in the gap between
3600             # r[$i-1], and r[$i], which we already have taken care of before
3601             # the loop.
3602             # On the other hand, if there are affected ranges, it might be
3603             # that there is a gap that needs filling after the final such
3604             # range to the end of the input range
3605             if ($r->[$j-1]->end < $end) {
3606                     push @gap_list, Range->new(main::max($start,
3607                                                          $r->[$j-1]->end + 1),
3608                                                $end,
3609                                                Type => $type);
3610                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3611             }
3612
3613             # Call recursively to fill in all the gaps.
3614             foreach my $gap (@gap_list) {
3615                 $self->_add_delete($operation,
3616                                    $gap->start,
3617                                    $gap->end,
3618                                    $value,
3619                                    Type => $type);
3620             }
3621
3622             return;
3623         }
3624
3625         # Here, we have taken care of the case where $replace is $NO.
3626         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3627         # If inserting a multiple record, this is where it goes, before the
3628         # first (if any) existing one if inserting LIFO.  (If this is to go
3629         # afterwards, FIFO, we below move the pointer to there.)  These imply
3630         # an insertion, and no change to any existing ranges.  Note that $i
3631         # can be -1 if this new range doesn't actually duplicate any existing,
3632         # and comes at the beginning of the list.
3633         if ($replace == $MULTIPLE_BEFORE || $replace == $MULTIPLE_AFTER) {
3634
3635             if ($start != $end) {
3636                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3637                 return;
3638             }
3639
3640             # If the new code point is within a current range ...
3641             if ($end >= $r->[$i]->start) {
3642
3643                 # Don't add an exact duplicate, as it isn't really a multiple
3644                 my $existing_value = $r->[$i]->value;
3645                 my $existing_type = $r->[$i]->type;
3646                 return if $value eq $existing_value && $type eq $existing_type;
3647
3648                 # If the multiple value is part of an existing range, we want
3649                 # to split up that range, so that only the single code point
3650                 # is affected.  To do this, we first call ourselves
3651                 # recursively to delete that code point from the table, having
3652                 # preserved its current data above.  Then we call ourselves
3653                 # recursively again to add the new multiple, which we know by
3654                 # the test just above is different than the current code
3655                 # point's value, so it will become a range containing a single
3656                 # code point: just itself.  Finally, we add back in the
3657                 # pre-existing code point, which will again be a single code
3658                 # point range.  Because 'i' likely will have changed as a
3659                 # result of these operations, we can't just continue on, but
3660                 # do this operation recursively as well.  If we are inserting
3661                 # LIFO, the pre-existing code point needs to go after the new
3662                 # one, so use MULTIPLE_AFTER; and vice versa.
3663                 if ($r->[$i]->start != $r->[$i]->end) {
3664                     $self->_add_delete('-', $start, $end, "");
3665                     $self->_add_delete('+', $start, $end, $value, Type => $type);
3666                     return $self->_add_delete('+',
3667                             $start, $end,
3668                             $existing_value,
3669                             Type => $existing_type,
3670                             Replace => ($replace == $MULTIPLE_BEFORE)
3671                                        ? $MULTIPLE_AFTER
3672                                        : $MULTIPLE_BEFORE);
3673                 }
3674             }
3675
3676             # If to place this new record after, move to beyond all existing
3677             # ones.
3678             if ($replace == $MULTIPLE_AFTER) {
3679                 while ($i < @$r && $r->[$i]->start == $start) {
3680                     $i++;
3681                 }
3682             }
3683
3684             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3685             my @return = splice @$r,
3686                                 $i,
3687                                 0,
3688                                 Range->new($start,
3689                                            $end,
3690                                            Value => $value,
3691                                            Type => $type);
3692             if (main::DEBUG && $to_trace) {
3693                 trace "After splice:";
3694                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3695                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3696                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3697                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3698                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3699                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3700             }
3701             return @return;
3702         }
3703
3704         # Here, we have taken care of $NO and $MULTIPLE_foo replaces.  This
3705         # leaves delete, insert, and replace either unconditionally or if not
3706         # equivalent.  $i still points to the first potential affected range.
3707         # Now find the highest range affected, which will determine the length
3708         # parameter to splice.  (The input range can span multiple existing
3709         # ones.)  If this isn't a deletion, while we are looking through the
3710         # range list, see also if this is a replacement rather than a clean
3711         # insertion; that is if it will change the values of at least one
3712         # existing range.  Start off assuming it is an insert, until find it
3713         # isn't.
3714         my $clean_insert = $operation eq '+';
3715         my $j;        # This will point to the highest affected range
3716
3717         # For non-zero types, the standard form is the value itself;
3718         my $standard_form = ($type) ? $value : main::standardize($value);
3719
3720         for ($j = $i; $j < $range_list_size; $j++) {
3721             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3722
3723             # If find a range that it doesn't overlap into, we can stop
3724             # searching
3725             last if $end < $r->[$j]->start;
3726
3727             # Here, overlaps the range at $j.  If the values don't match,
3728             # and so far we think this is a clean insertion, it becomes a
3729             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3730             if ($clean_insert) {
3731                 if ($r->[$j]->standard_form ne $standard_form) {
3732                     $clean_insert = 0;
3733                     if ($replace == $CROAK) {
3734                         main::croak("The range to add "
3735                         . sprintf("%04X", $start)
3736                         . '-'
3737                         . sprintf("%04X", $end)
3738                         . " with value '$value' overlaps an existing range $r->[$j]");
3739                     }
3740                 }
3741                 else {
3742
3743                     # Here, the two values are essentially the same.  If the
3744                     # two are actually identical, replacing wouldn't change
3745                     # anything so skip it.
3746                     my $pre_existing = $r->[$j]->value;
3747                     if ($pre_existing ne $value) {
3748
3749                         # Here the new and old standardized values are the
3750                         # same, but the non-standardized values aren't.  If
3751                         # replacing unconditionally, then replace
3752                         if( $replace == $UNCONDITIONALLY) {
3753                             $clean_insert = 0;
3754                         }
3755                         else {
3756
3757                             # Here, are replacing conditionally.  Decide to
3758                             # replace or not based on which appears to look
3759                             # the "nicest".  If one is mixed case and the
3760                             # other isn't, choose the mixed case one.
3761                             my $new_mixed = $value =~ /[A-Z]/
3762                                             && $value =~ /[a-z]/;
3763                             my $old_mixed = $pre_existing =~ /[A-Z]/
3764                                             && $pre_existing =~ /[a-z]/;
3765
3766                             if ($old_mixed != $new_mixed) {
3767                                 $clean_insert = 0 if $new_mixed;
3768                                 if (main::DEBUG && $to_trace) {
3769                                     if ($clean_insert) {
3770                                         trace "Retaining $pre_existing over $value";
3771                                     }
3772                                     else {
3773                                         trace "Replacing $pre_existing with $value";
3774                                     }
3775                                 }
3776                             }
3777                             else {
3778
3779                                 # Here casing wasn't different between the two.
3780                                 # If one has hyphens or underscores and the
3781                                 # other doesn't, choose the one with the
3782                                 # punctuation.
3783                                 my $new_punct = $value =~ /[-_]/;
3784                                 my $old_punct = $pre_existing =~ /[-_]/;
3785
3786                                 if ($old_punct != $new_punct) {
3787                                     $clean_insert = 0 if $new_punct;
3788                                     if (main::DEBUG && $to_trace) {
3789                                         if ($clean_insert) {
3790                                             trace "Retaining $pre_existing over $value";
3791                                         }
3792                                         else {
3793                                             trace "Replacing $pre_existing with $value";
3794                                         }
3795                                     }
3796                                 }   # else existing one is just as "good";
3797                                     # retain it to save cycles.
3798                             }
3799                         }
3800                     }
3801                 }
3802             }
3803         } # End of loop looking for highest affected range.
3804
3805         # Here, $j points to one beyond the highest range that this insertion
3806         # affects (hence to beyond the range list if that range is the final
3807         # one in the range list).
3808
3809         # The splice length is all the affected ranges.  Get it before
3810         # subtracting, for efficiency, so we don't have to later add 1.
3811         my $length = $j - $i;
3812
3813         $j--;        # $j now points to the highest affected range.
3814         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3815
3816         # Here, have taken care of $NO and $MULTIPLE_foo replaces.
3817         # $j points to the highest affected range.  But it can be < $i or even
3818         # -1.  These happen only if the insertion is entirely in the gap
3819         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3820         # above exited first time through with $end < $r->[$i]->start.  (And
3821         # then we subtracted one from j)  This implies also that $start <
3822         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3823         # $start, so the entire input range is in the gap.
3824         if ($j < $i) {
3825
3826             # Here the entire input range is in the gap before $i.
3827
3828             if (main::DEBUG && $to_trace) {
3829                 if ($i) {
3830                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3831                 }
3832                 else {
3833                     trace "Entire range is before $r->[$i]";
3834                 }
3835             }
3836             return if $operation ne '+'; # Deletion of a non-existent range is
3837                                          # a no-op
3838         }
3839         else {
3840
3841             # Here part of the input range is not in the gap before $i.  Thus,
3842             # there is at least one affected one, and $j points to the highest
3843             # such one.
3844
3845             # At this point, here is the situation:
3846             # This is not an insertion of a multiple, nor of tentative ($NO)
3847             # data.
3848             #   $i  points to the first element in the current range list that
3849             #            may be affected by this operation.  In fact, we know
3850             #            that the range at $i is affected because we are in
3851             #            the else branch of this 'if'
3852             #   $j  points to the highest affected range.
3853             # In other words,
3854             #   r[$i-1]->end < $start <= r[$i]->end
3855             # And:
3856             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3857             #
3858             # Also:
3859             #   $clean_insert is a boolean which is set true if and only if
3860             #        this is a "clean insertion", i.e., not a change nor a
3861             #        deletion (multiple was handled above).
3862
3863             # We now have enough information to decide if this call is a no-op
3864             # or not.  It is a no-op if this is an insertion of already
3865             # existing data.
3866
3867             if (main::DEBUG && $to_trace && $clean_insert
3868                                          && $i == $j
3869                                          && $start >= $r->[$i]->start)
3870             {
3871                     trace "no-op";
3872             }
3873             return if $clean_insert
3874                       && $i == $j # more than one affected range => not no-op
3875
3876                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3877                       # Further, $start and/or $end is >= r[$i]->start
3878                       # The test below hence guarantees that
3879                       #     r[$i]->start < $start <= $end <= r[$i]->end
3880                       # This means the input range is contained entirely in
3881                       # the one at $i, so is a no-op
3882                       && $start >= $r->[$i]->start;
3883         }
3884
3885         # Here, we know that some action will have to be taken.  We have
3886         # calculated the offset and length (though adjustments may be needed)
3887         # for the splice.  Now start constructing the replacement list.
3888         my @replacement;
3889         my $splice_start = $i;
3890
3891         my $extends_below;
3892         my $extends_above;
3893
3894         # See if should extend any adjacent ranges.
3895         if ($operation eq '-') { # Don't extend deletions
3896             $extends_below = $extends_above = 0;
3897         }
3898         else {  # Here, should extend any adjacent ranges.  See if there are
3899                 # any.
3900             $extends_below = ($i > 0
3901                             # can't extend unless adjacent
3902                             && $r->[$i-1]->end == $start -1
3903                             # can't extend unless are same standard value
3904                             && $r->[$i-1]->standard_form eq $standard_form
3905                             # can't extend unless share type
3906                             && $r->[$i-1]->type == $type);
3907             $extends_above = ($j+1 < $range_list_size
3908                             && $r->[$j+1]->start == $end +1
3909                             && $r->[$j+1]->standard_form eq $standard_form
3910                             && $r->[$j+1]->type == $type);
3911         }
3912         if ($extends_below && $extends_above) { # Adds to both
3913             $splice_start--;     # start replace at element below
3914             $length += 2;        # will replace on both sides
3915             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3916
3917             # The result will fill in any gap, replacing both sides, and
3918             # create one large range.
3919             @replacement = Range->new($r->[$i-1]->start,
3920                                       $r->[$j+1]->end,
3921                                       Value => $value,
3922                                       Type => $type);
3923         }
3924         else {
3925
3926             # Here we know that the result won't just be the conglomeration of
3927             # a new range with both its adjacent neighbors.  But it could
3928             # extend one of them.
3929
3930             if ($extends_below) {
3931
3932                 # Here the new element adds to the one below, but not to the
3933                 # one above.  If inserting, and only to that one range,  can
3934                 # just change its ending to include the new one.
3935                 if ($length == 0 && $clean_insert) {
3936                     $r->[$i-1]->set_end($end);
3937                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3938                     return;
3939                 }
3940                 else {
3941                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3942                     $splice_start--;        # start replace at element below
3943                     $length++;              # will replace the element below
3944                     $start = $r->[$i-1]->start;
3945                 }
3946             }
3947             elsif ($extends_above) {
3948
3949                 # Here the new element adds to the one above, but not below.
3950                 # Mirror the code above
3951                 if ($length == 0 && $clean_insert) {
3952                     $r->[$j+1]->set_start($start);
3953                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3954                     return;
3955                 }
3956                 else {
3957                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3958                     $length++;        # will replace the element above
3959                     $end = $r->[$j+1]->end;
3960                 }
3961             }
3962
3963             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3964
3965           &n