This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Remove all references to old OO tutorial docs, and add refs to perlootut where approp...
[perl5.git] / cpan / perlfaq / lib / perlfaq7.pod
1 =head1 NAME
2
3 perlfaq7 - General Perl Language Issues
4
5 =head1 DESCRIPTION
6
7 This section deals with general Perl language issues that don't
8 clearly fit into any of the other sections.
9
10 =head2 Can I get a BNF/yacc/RE for the Perl language?
11
12 There is no BNF, but you can paw your way through the yacc grammar in
13 perly.y in the source distribution if you're particularly brave.  The
14 grammar relies on very smart tokenizing code, so be prepared to
15 venture into toke.c as well.
16
17 In the words of Chaim Frenkel: "Perl's grammar can not be reduced to BNF.
18 The work of parsing perl is distributed between yacc, the lexer, smoke
19 and mirrors."
20
21 =head2 What are all these $@%&* punctuation signs, and how do I know when to use them?
22
23 They are type specifiers, as detailed in L<perldata>:
24
25     $ for scalar values (number, string or reference)
26     @ for arrays
27     % for hashes (associative arrays)
28     & for subroutines (aka functions, procedures, methods)
29     * for all types of that symbol name.  In version 4 you used them like
30       pointers, but in modern perls you can just use references.
31
32 There are a couple of other symbols that
33 you're likely to encounter that aren't
34 really type specifiers:
35
36     <> are used for inputting a record from a filehandle.
37     \  takes a reference to something.
38
39 Note that <FILE> is I<neither> the type specifier for files
40 nor the name of the handle.  It is the C<< <> >> operator applied
41 to the handle FILE.  It reads one line (well, record--see
42 L<perlvar/$E<sol>>) from the handle FILE in scalar context, or I<all> lines
43 in list context.  When performing open, close, or any other operation
44 besides C<< <> >> on files, or even when talking about the handle, do
45 I<not> use the brackets.  These are correct: C<eof(FH)>, C<seek(FH, 0,
46 2)> and "copying from STDIN to FILE".
47
48 =head2 Do I always/never have to quote my strings or use semicolons and commas?
49
50 Normally, a bareword doesn't need to be quoted, but in most cases
51 probably should be (and must be under C<use strict>).  But a hash key
52 consisting of a simple word and the left-hand
53 operand to the C<< => >> operator both
54 count as though they were quoted:
55
56     This                    is like this
57     ------------            ---------------
58     $foo{line}              $foo{'line'}
59     bar => stuff            'bar' => stuff
60
61 The final semicolon in a block is optional, as is the final comma in a
62 list.  Good style (see L<perlstyle>) says to put them in except for
63 one-liners:
64
65     if ($whoops) { exit 1 }
66     @nums = (1, 2, 3);
67
68     if ($whoops) {
69         exit 1;
70     }
71
72     @lines = (
73         "There Beren came from mountains cold",
74         "And lost he wandered under leaves",
75     );
76
77 =head2 How do I skip some return values?
78
79 One way is to treat the return values as a list and index into it:
80
81     $dir = (getpwnam($user))[7];
82
83 Another way is to use undef as an element on the left-hand-side:
84
85     ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
86
87 You can also use a list slice to select only the elements that
88 you need:
89
90     ($dev, $ino, $uid, $gid) = ( stat($file) )[0,1,4,5];
91
92 =head2 How do I temporarily block warnings?
93
94 If you are running Perl 5.6.0 or better, the C<use warnings> pragma
95 allows fine control of what warning are produced.
96 See L<perllexwarn> for more details.
97
98     {
99         no warnings;          # temporarily turn off warnings
100         $a = $b + $c;         # I know these might be undef
101     }
102
103 Additionally, you can enable and disable categories of warnings.
104 You turn off the categories you want to ignore and you can still
105 get other categories of warnings.  See L<perllexwarn> for the
106 complete details, including the category names and hierarchy.
107
108     {
109         no warnings 'uninitialized';
110         $a = $b + $c;
111     }
112
113 If you have an older version of Perl, the C<$^W> variable (documented
114 in L<perlvar>) controls runtime warnings for a block:
115
116     {
117         local $^W = 0;        # temporarily turn off warnings
118         $a = $b + $c;         # I know these might be undef
119     }
120
121 Note that like all the punctuation variables, you cannot currently
122 use my() on C<$^W>, only local().
123
124 =head2 What's an extension?
125
126 An extension is a way of calling compiled C code from Perl.  Reading
127 L<perlxstut> is a good place to learn more about extensions.
128
129 =head2 Why do Perl operators have different precedence than C operators?
130
131 Actually, they don't.  All C operators that Perl copies have the same
132 precedence in Perl as they do in C.  The problem is with operators that C
133 doesn't have, especially functions that give a list context to everything
134 on their right, eg. print, chmod, exec, and so on.  Such functions are
135 called "list operators" and appear as such in the precedence table in
136 L<perlop>.
137
138 A common mistake is to write:
139
140     unlink $file || die "snafu";
141
142 This gets interpreted as:
143
144     unlink ($file || die "snafu");
145
146 To avoid this problem, either put in extra parentheses or use the
147 super low precedence C<or> operator:
148
149     (unlink $file) || die "snafu";
150     unlink $file or die "snafu";
151
152 The "English" operators (C<and>, C<or>, C<xor>, and C<not>)
153 deliberately have precedence lower than that of list operators for
154 just such situations as the one above.
155
156 Another operator with surprising precedence is exponentiation.  It
157 binds more tightly even than unary minus, making C<-2**2> produce a
158 negative not a positive four.  It is also right-associating, meaning
159 that C<2**3**2> is two raised to the ninth power, not eight squared.
160
161 Although it has the same precedence as in C, Perl's C<?:> operator
162 produces an lvalue.  This assigns $x to either $a or $b, depending
163 on the trueness of $maybe:
164
165     ($maybe ? $a : $b) = $x;
166
167 =head2 How do I declare/create a structure?
168
169 In general, you don't "declare" a structure.  Just use a (probably
170 anonymous) hash reference.  See L<perlref> and L<perldsc> for details.
171 Here's an example:
172
173     $person = {};                   # new anonymous hash
174     $person->{AGE}  = 24;           # set field AGE to 24
175     $person->{NAME} = "Nat";        # set field NAME to "Nat"
176
177 If you're looking for something a bit more rigorous, try L<perlootut>.
178
179 =head2 How do I create a module?
180
181 (contributed by brian d foy)
182
183 L<perlmod>, L<perlmodlib>, L<perlmodstyle> explain modules
184 in all the gory details. L<perlnewmod> gives a brief
185 overview of the process along with a couple of suggestions
186 about style.
187
188 If you need to include C code or C library interfaces in
189 your module, you'll need h2xs.  h2xs will create the module
190 distribution structure and the initial interface files
191 you'll need.  L<perlxs> and L<perlxstut> explain the details.
192
193 If you don't need to use C code, other tools such as
194 ExtUtils::ModuleMaker and Module::Starter, can help you
195 create a skeleton module distribution.
196
197 You may also want to see Sam Tregar's "Writing Perl Modules
198 for CPAN" ( http://apress.com/book/bookDisplay.html?bID=14 )
199 which is the best hands-on guide to creating module
200 distributions.
201
202 =head2 How do I adopt or take over a module already on CPAN?
203
204 (contributed by brian d foy)
205
206 The easiest way to take over a module is to have the current
207 module maintainer either make you a co-maintainer or transfer
208 the module to you.
209
210 If you can't reach the author for some reason (e.g. email bounces),
211 the PAUSE admins at modules@perl.org can help. The PAUSE admins
212 treat each case individually.
213
214 =over 4
215
216 =item *
217
218 Get a login for the Perl Authors Upload Server (PAUSE) if you don't
219 already have one: http://pause.perl.org
220
221 =item *
222
223 Write to modules@perl.org explaining what you did to contact the
224 current maintainer. The PAUSE admins will also try to reach the
225 maintainer.
226
227 =item *
228
229 Post a public message in a heavily trafficked site announcing your
230 intention to take over the module.
231
232 =item *
233
234 Wait a bit. The PAUSE admins don't want to act too quickly in case
235 the current maintainer is on holiday. If there's no response to
236 private communication or the public post, a PAUSE admin can transfer
237 it to you.
238
239 =back
240
241 =head2 How do I create a class?
242 X<class, creation> X<package>
243
244 (contributed by brian d foy)
245
246 In Perl, a class is just a package, and methods are just subroutines.
247 Perl doesn't get more formal than that and lets you set up the package
248 just the way that you like it (that is, it doesn't set up anything for
249 you).
250
251 The Perl documentation has a tutorial on object oriented programming in
252 L<perlootut>. Also see the perl objects reference docs in L<perlobj>.
253
254 =head2 How can I tell if a variable is tainted?
255
256 You can use the tainted() function of the Scalar::Util module, available
257 from CPAN (or included with Perl since release 5.8.0).
258 See also L<perlsec/"Laundering and Detecting Tainted Data">.
259
260 =head2 What's a closure?
261
262 Closures are documented in L<perlref>.
263
264 I<Closure> is a computer science term with a precise but
265 hard-to-explain meaning. Usually, closures are implemented in Perl as
266 anonymous subroutines with lasting references to lexical variables
267 outside their own scopes. These lexicals magically refer to the
268 variables that were around when the subroutine was defined (deep
269 binding).
270
271 Closures are most often used in programming languages where you can
272 have the return value of a function be itself a function, as you can
273 in Perl. Note that some languages provide anonymous functions but are
274 not capable of providing proper closures: the Python language, for
275 example.  For more information on closures, check out any textbook on
276 functional programming.  Scheme is a language that not only supports
277 but encourages closures.
278
279 Here's a classic non-closure function-generating function:
280
281     sub add_function_generator {
282         return sub { shift() + shift() };
283     }
284
285     $add_sub = add_function_generator();
286     $sum = $add_sub->(4,5);                # $sum is 9 now.
287
288 The anonymous subroutine returned by add_function_generator() isn't
289 technically a closure because it refers to no lexicals outside its own
290 scope.  Using a closure gives you a I<function template> with some
291 customization slots left out to be filled later.
292
293 Contrast this with the following make_adder() function, in which the
294 returned anonymous function contains a reference to a lexical variable
295 outside the scope of that function itself.  Such a reference requires
296 that Perl return a proper closure, thus locking in for all time the
297 value that the lexical had when the function was created.
298
299     sub make_adder {
300         my $addpiece = shift;
301         return sub { shift() + $addpiece };
302     }
303
304     $f1 = make_adder(20);
305     $f2 = make_adder(555);
306
307 Now C<&$f1($n)> is always 20 plus whatever $n you pass in, whereas
308 C<&$f2($n)> is always 555 plus whatever $n you pass in.  The $addpiece
309 in the closure sticks around.
310
311 Closures are often used for less esoteric purposes.  For example, when
312 you want to pass in a bit of code into a function:
313
314     my $line;
315     timeout( 30, sub { $line = <STDIN> } );
316
317 If the code to execute had been passed in as a string,
318 C<< '$line = <STDIN>' >>, there would have been no way for the
319 hypothetical timeout() function to access the lexical variable
320 $line back in its caller's scope.
321
322 Another use for a closure is to make a variable I<private> to a
323 named subroutine, e.g. a counter that gets initialized at creation
324 time of the sub and can only be modified from within the sub.
325 This is sometimes used with a BEGIN block in package files to make
326 sure a variable doesn't get meddled with during the lifetime of the
327 package:
328
329     BEGIN {
330         my $id = 0;
331         sub next_id { ++$id }
332     }
333
334 This is discussed in more detail in L<perlsub>; see the entry on
335 I<Persistent Private Variables>.
336
337 =head2 What is variable suicide and how can I prevent it?
338
339 This problem was fixed in perl 5.004_05, so preventing it means upgrading
340 your version of perl. ;)
341
342 Variable suicide is when you (temporarily or permanently) lose the value
343 of a variable.  It is caused by scoping through my() and local()
344 interacting with either closures or aliased foreach() iterator variables
345 and subroutine arguments.  It used to be easy to inadvertently lose a
346 variable's value this way, but now it's much harder.  Take this code:
347
348     my $f = 'foo';
349     sub T {
350         while ($i++ < 3) { my $f = $f; $f .= "bar"; print $f, "\n" }
351     }
352
353     T;
354     print "Finally $f\n";
355
356 If you are experiencing variable suicide, that C<my $f> in the subroutine
357 doesn't pick up a fresh copy of the C<$f> whose value is <foo>. The output
358 shows that inside the subroutine the value of C<$f> leaks through when it
359 shouldn't, as in this output:
360
361     foobar
362     foobarbar
363     foobarbarbar
364     Finally foo
365
366 The $f that has "bar" added to it three times should be a new C<$f>
367 C<my $f> should create a new lexical variable each time through the loop.
368 The expected output is:
369
370     foobar
371     foobar
372     foobar
373     Finally foo
374
375 =head2 How can I pass/return a {Function, FileHandle, Array, Hash, Method, Regex}?
376
377 You need to pass references to these objects.  See L<perlsub/"Pass by
378 Reference"> for this particular question, and L<perlref> for
379 information on references.
380
381 =over 4
382
383 =item Passing Variables and Functions
384
385 Regular variables and functions are quite easy to pass: just pass in a
386 reference to an existing or anonymous variable or function:
387
388     func( \$some_scalar );
389
390     func( \@some_array  );
391     func( [ 1 .. 10 ]   );
392
393     func( \%some_hash   );
394     func( { this => 10, that => 20 }   );
395
396     func( \&some_func   );
397     func( sub { $_[0] ** $_[1] }   );
398
399 =item Passing Filehandles
400
401 As of Perl 5.6, you can represent filehandles with scalar variables
402 which you treat as any other scalar.
403
404     open my $fh, $filename or die "Cannot open $filename! $!";
405     func( $fh );
406
407     sub func {
408         my $passed_fh = shift;
409
410         my $line = <$passed_fh>;
411     }
412
413 Before Perl 5.6, you had to use the C<*FH> or C<\*FH> notations.
414 These are "typeglobs"--see L<perldata/"Typeglobs and Filehandles">
415 and especially L<perlsub/"Pass by Reference"> for more information.
416
417 =item Passing Regexes
418
419 Here's an example of how to pass in a string and a regular expression
420 for it to match against. You construct the pattern with the C<qr//>
421 operator:
422
423     sub compare($$) {
424         my ($val1, $regex) = @_;
425         my $retval = $val1 =~ /$regex/;
426     return $retval;
427     }
428     $match = compare("old McDonald", qr/d.*D/i);
429
430 =item Passing Methods
431
432 To pass an object method into a subroutine, you can do this:
433
434     call_a_lot(10, $some_obj, "methname")
435     sub call_a_lot {
436         my ($count, $widget, $trick) = @_;
437         for (my $i = 0; $i < $count; $i++) {
438             $widget->$trick();
439         }
440     }
441
442 Or, you can use a closure to bundle up the object, its
443 method call, and arguments:
444
445     my $whatnot =  sub { $some_obj->obfuscate(@args) };
446     func($whatnot);
447     sub func {
448         my $code = shift;
449         &$code();
450     }
451
452 You could also investigate the can() method in the UNIVERSAL class
453 (part of the standard perl distribution).
454
455 =back
456
457 =head2 How do I create a static variable?
458
459 (contributed by brian d foy)
460
461 In Perl 5.10, declare the variable with C<state>. The C<state>
462 declaration creates the lexical variable that persists between calls
463 to the subroutine:
464
465     sub counter { state $count = 1; $counter++ }
466
467 You can fake a static variable by using a lexical variable which goes
468 out of scope. In this example, you define the subroutine C<counter>, and
469 it uses the lexical variable C<$count>. Since you wrap this in a BEGIN
470 block, C<$count> is defined at compile-time, but also goes out of
471 scope at the end of the BEGIN block. The BEGIN block also ensures that
472 the subroutine and the value it uses is defined at compile-time so the
473 subroutine is ready to use just like any other subroutine, and you can
474 put this code in the same place as other subroutines in the program
475 text (i.e. at the end of the code, typically). The subroutine
476 C<counter> still has a reference to the data, and is the only way you
477 can access the value (and each time you do, you increment the value).
478 The data in chunk of memory defined by C<$count> is private to
479 C<counter>.
480
481     BEGIN {
482         my $count = 1;
483         sub counter { $count++ }
484     }
485
486     my $start = counter();
487
488     .... # code that calls counter();
489
490     my $end = counter();
491
492 In the previous example, you created a function-private variable
493 because only one function remembered its reference. You could define
494 multiple functions while the variable is in scope, and each function
495 can share the "private" variable. It's not really "static" because you
496 can access it outside the function while the lexical variable is in
497 scope, and even create references to it. In this example,
498 C<increment_count> and C<return_count> share the variable. One
499 function adds to the value and the other simply returns the value.
500 They can both access C<$count>, and since it has gone out of scope,
501 there is no other way to access it.
502
503     BEGIN {
504         my $count = 1;
505         sub increment_count { $count++ }
506         sub return_count    { $count }
507     }
508
509 To declare a file-private variable, you still use a lexical variable.
510 A file is also a scope, so a lexical variable defined in the file
511 cannot be seen from any other file.
512
513 See L<perlsub/"Persistent Private Variables"> for more information.
514 The discussion of closures in L<perlref> may help you even though we
515 did not use anonymous subroutines in this answer. See
516 L<perlsub/"Persistent Private Variables"> for details.
517
518 =head2 What's the difference between dynamic and lexical (static) scoping?  Between local() and my()?
519
520 C<local($x)> saves away the old value of the global variable C<$x>
521 and assigns a new value for the duration of the subroutine I<which is
522 visible in other functions called from that subroutine>.  This is done
523 at run-time, so is called dynamic scoping.  local() always affects global
524 variables, also called package variables or dynamic variables.
525
526 C<my($x)> creates a new variable that is only visible in the current
527 subroutine.  This is done at compile-time, so it is called lexical or
528 static scoping.  my() always affects private variables, also called
529 lexical variables or (improperly) static(ly scoped) variables.
530
531 For instance:
532
533     sub visible {
534         print "var has value $var\n";
535     }
536
537     sub dynamic {
538         local $var = 'local';    # new temporary value for the still-global
539         visible();              #   variable called $var
540     }
541
542     sub lexical {
543         my $var = 'private';    # new private variable, $var
544         visible();              # (invisible outside of sub scope)
545     }
546
547     $var = 'global';
548
549     visible();              # prints global
550     dynamic();              # prints local
551     lexical();              # prints global
552
553 Notice how at no point does the value "private" get printed.  That's
554 because $var only has that value within the block of the lexical()
555 function, and it is hidden from the called subroutine.
556
557 In summary, local() doesn't make what you think of as private, local
558 variables.  It gives a global variable a temporary value.  my() is
559 what you're looking for if you want private variables.
560
561 See L<perlsub/"Private Variables via my()"> and
562 L<perlsub/"Temporary Values via local()"> for excruciating details.
563
564 =head2 How can I access a dynamic variable while a similarly named lexical is in scope?
565
566 If you know your package, you can just mention it explicitly, as in
567 $Some_Pack::var. Note that the notation $::var is B<not> the dynamic $var
568 in the current package, but rather the one in the "main" package, as
569 though you had written $main::var.
570
571     use vars '$var';
572     local $var = "global";
573     my    $var = "lexical";
574
575     print "lexical is $var\n";
576     print "global  is $main::var\n";
577
578 Alternatively you can use the compiler directive our() to bring a
579 dynamic variable into the current lexical scope.
580
581     require 5.006; # our() did not exist before 5.6
582     use vars '$var';
583
584     local $var = "global";
585     my $var    = "lexical";
586
587     print "lexical is $var\n";
588
589     {
590         our $var;
591         print "global  is $var\n";
592     }
593
594 =head2 What's the difference between deep and shallow binding?
595
596 In deep binding, lexical variables mentioned in anonymous subroutines
597 are the same ones that were in scope when the subroutine was created.
598 In shallow binding, they are whichever variables with the same names
599 happen to be in scope when the subroutine is called.  Perl always uses
600 deep binding of lexical variables (i.e., those created with my()).
601 However, dynamic variables (aka global, local, or package variables)
602 are effectively shallowly bound.  Consider this just one more reason
603 not to use them.  See the answer to L<"What's a closure?">.
604
605 =head2 Why doesn't "my($foo) = E<lt>FILEE<gt>;" work right?
606
607 C<my()> and C<local()> give list context to the right hand side
608 of C<=>.  The <FH> read operation, like so many of Perl's
609 functions and operators, can tell which context it was called in and
610 behaves appropriately.  In general, the scalar() function can help.
611 This function does nothing to the data itself (contrary to popular myth)
612 but rather tells its argument to behave in whatever its scalar fashion is.
613 If that function doesn't have a defined scalar behavior, this of course
614 doesn't help you (such as with sort()).
615
616 To enforce scalar context in this particular case, however, you need
617 merely omit the parentheses:
618
619     local($foo) = <FILE>;        # WRONG
620     local($foo) = scalar(<FILE>);   # ok
621     local $foo  = <FILE>;        # right
622
623 You should probably be using lexical variables anyway, although the
624 issue is the same here:
625
626     my($foo) = <FILE>;    # WRONG
627     my $foo  = <FILE>;    # right
628
629 =head2 How do I redefine a builtin function, operator, or method?
630
631 Why do you want to do that? :-)
632
633 If you want to override a predefined function, such as open(),
634 then you'll have to import the new definition from a different
635 module.  See L<perlsub/"Overriding Built-in Functions">.
636
637 If you want to overload a Perl operator, such as C<+> or C<**>,
638 then you'll want to use the C<use overload> pragma, documented
639 in L<overload>.
640
641 If you're talking about obscuring method calls in parent classes,
642 see L<perlobj/"Inheritance">.
643
644 =head2 What's the difference between calling a function as &foo and foo()?
645
646 (contributed by brian d foy)
647
648 Calling a subroutine as C<&foo> with no trailing parentheses ignores
649 the prototype of C<foo> and passes it the current value of the argument
650 list, C<@_>. Here's an example; the C<bar> subroutine calls C<&foo>,
651 which prints its arguments list:
652
653     sub bar { &foo }
654
655     sub foo { print "Args in foo are: @_\n" }
656
657     bar( qw( a b c ) );
658
659 When you call C<bar> with arguments, you see that C<foo> got the same C<@_>:
660
661     Args in foo are: a b c
662
663 Calling the subroutine with trailing parentheses, with or without arguments,
664 does not use the current C<@_> and respects the subroutine prototype. Changing
665 the example to put parentheses after the call to C<foo> changes the program:
666
667     sub bar { &foo() }
668
669     sub foo { print "Args in foo are: @_\n" }
670
671     bar( qw( a b c ) );
672
673 Now the output shows that C<foo> doesn't get the C<@_> from its caller.
674
675     Args in foo are:
676
677 The main use of the C<@_> pass-through feature is to write subroutines
678 whose main job it is to call other subroutines for you. For further
679 details, see L<perlsub>.
680
681 =head2 How do I create a switch or case statement?
682
683 In Perl 5.10, use the C<given-when> construct described in L<perlsyn>:
684
685     use 5.010;
686
687     given ( $string ) {
688         when( 'Fred' )        { say "I found Fred!" }
689         when( 'Barney' )      { say "I found Barney!" }
690         when( /Bamm-?Bamm/ )  { say "I found Bamm-Bamm!" }
691         default               { say "I don't recognize the name!" }
692     };
693
694 If one wants to use pure Perl and to be compatible with Perl versions
695 prior to 5.10, the general answer is to use C<if-elsif-else>:
696
697     for ($variable_to_test) {
698         if    (/pat1/)  { }     # do something
699         elsif (/pat2/)  { }     # do something else
700         elsif (/pat3/)  { }     # do something else
701         else            { }     # default
702     }
703
704 Here's a simple example of a switch based on pattern matching,
705 lined up in a way to make it look more like a switch statement.
706 We'll do a multiway conditional based on the type of reference stored
707 in $whatchamacallit:
708
709     SWITCH: for (ref $whatchamacallit) {
710
711         /^$/           && die "not a reference";
712
713         /SCALAR/       && do {
714                         print_scalar($$ref);
715                         last SWITCH;
716                       };
717
718         /ARRAY/        && do {
719                         print_array(@$ref);
720                         last SWITCH;
721                       };
722
723         /HASH/        && do {
724                         print_hash(%$ref);
725                         last SWITCH;
726                       };
727
728         /CODE/        && do {
729                         warn "can't print function ref";
730                         last SWITCH;
731                       };
732
733         # DEFAULT
734
735         warn "User defined type skipped";
736
737     }
738
739 See L<perlsyn> for other examples in this style.
740
741 Sometimes you should change the positions of the constant and the variable.
742 For example, let's say you wanted to test which of many answers you were
743 given, but in a case-insensitive way that also allows abbreviations.
744 You can use the following technique if the strings all start with
745 different characters or if you want to arrange the matches so that
746 one takes precedence over another, as C<"SEND"> has precedence over
747 C<"STOP"> here:
748
749     chomp($answer = <>);
750     if    ("SEND"  =~ /^\Q$answer/i) { print "Action is send\n"  }
751     elsif ("STOP"  =~ /^\Q$answer/i) { print "Action is stop\n"  }
752     elsif ("ABORT" =~ /^\Q$answer/i) { print "Action is abort\n" }
753     elsif ("LIST"  =~ /^\Q$answer/i) { print "Action is list\n"  }
754     elsif ("EDIT"  =~ /^\Q$answer/i) { print "Action is edit\n"  }
755
756 A totally different approach is to create a hash of function references.
757
758     my %commands = (
759         "happy" => \&joy,
760         "sad",  => \&sullen,
761         "done"  => sub { die "See ya!" },
762         "mad"   => \&angry,
763     );
764
765     print "How are you? ";
766     chomp($string = <STDIN>);
767     if ($commands{$string}) {
768         $commands{$string}->();
769     } else {
770         print "No such command: $string\n";
771     }
772
773 Starting from Perl 5.8, a source filter module, C<Switch>, can also be
774 used to get switch and case. Its use is now discouraged, because it's
775 not fully compatible with the native switch of Perl 5.10, and because,
776 as it's implemented as a source filter, it doesn't always work as intended
777 when complex syntax is involved.
778
779 =head2 How can I catch accesses to undefined variables, functions, or methods?
780
781 The AUTOLOAD method, discussed in L<perlsub/"Autoloading"> and
782 L<perlobj/"AUTOLOAD">, lets you capture calls to
783 undefined functions and methods.
784
785 When it comes to undefined variables that would trigger a warning
786 under C<use warnings>, you can promote the warning to an error.
787
788     use warnings FATAL => qw(uninitialized);
789
790 =head2 Why can't a method included in this same file be found?
791
792 Some possible reasons: your inheritance is getting confused, you've
793 misspelled the method name, or the object is of the wrong type.  Check
794 out L<perlobj> for details about any of the above cases.  You may
795 also use C<print ref($object)> to find out the class C<$object> was
796 blessed into.
797
798 Another possible reason for problems is that you've used the
799 indirect object syntax (eg, C<find Guru "Samy">) on a class name
800 before Perl has seen that such a package exists.  It's wisest to make
801 sure your packages are all defined before you start using them, which
802 will be taken care of if you use the C<use> statement instead of
803 C<require>.  If not, make sure to use arrow notation (eg.,
804 C<< Guru->find("Samy") >>) instead.  Object notation is explained in
805 L<perlobj>.
806
807 Make sure to read about creating modules in L<perlmod> and
808 the perils of indirect objects in L<perlobj/"Method Invocation">.
809
810 =head2 How can I find out my current or calling package?
811
812 (contributed by brian d foy)
813
814 To find the package you are currently in, use the special literal
815 C<__PACKAGE__>, as documented in L<perldata>. You can only use the
816 special literals as separate tokens, so you can't interpolate them
817 into strings like you can with variables:
818
819     my $current_package = __PACKAGE__;
820     print "I am in package $current_package\n";
821
822 If you want to find the package calling your code, perhaps to give better
823 diagnostics as L<Carp> does, use the C<caller> built-in:
824
825     sub foo {
826         my @args = ...;
827         my( $package, $filename, $line ) = caller;
828
829         print "I was called from package $package\n";
830         );
831
832 By default, your program starts in package C<main>, so you will
833 always be in some package.
834
835 This is different from finding out the package an object is blessed
836 into, which might not be the current package. For that, use C<blessed>
837 from L<Scalar::Util>, part of the Standard Library since Perl 5.8:
838
839     use Scalar::Util qw(blessed);
840     my $object_package = blessed( $object );
841
842 Most of the time, you shouldn't care what package an object is blessed
843 into, however, as long as it claims to inherit from that class:
844
845     my $is_right_class = eval { $object->isa( $package ) }; # true or false
846
847 And, with Perl 5.10 and later, you don't have to check for an
848 inheritance to see if the object can handle a role. For that, you can
849 use C<DOES>, which comes from C<UNIVERSAL>:
850
851     my $class_does_it = eval { $object->DOES( $role ) }; # true or false
852
853 You can safely replace C<isa> with C<DOES> (although the converse is not true).
854
855 =head2 How can I comment out a large block of Perl code?
856
857 (contributed by brian d foy)
858
859 The quick-and-dirty way to comment out more than one line of Perl is
860 to surround those lines with Pod directives. You have to put these
861 directives at the beginning of the line and somewhere where Perl
862 expects a new statement (so not in the middle of statements like the #
863 comments). You end the comment with C<=cut>, ending the Pod section:
864
865     =pod
866
867     my $object = NotGonnaHappen->new();
868
869     ignored_sub();
870
871     $wont_be_assigned = 37;
872
873     =cut
874
875 The quick-and-dirty method only works well when you don't plan to
876 leave the commented code in the source. If a Pod parser comes along,
877 you're multiline comment is going to show up in the Pod translation.
878 A better way hides it from Pod parsers as well.
879
880 The C<=begin> directive can mark a section for a particular purpose.
881 If the Pod parser doesn't want to handle it, it just ignores it. Label
882 the comments with C<comment>. End the comment using C<=end> with the
883 same label. You still need the C<=cut> to go back to Perl code from
884 the Pod comment:
885
886     =begin comment
887
888     my $object = NotGonnaHappen->new();
889
890     ignored_sub();
891
892     $wont_be_assigned = 37;
893
894     =end comment
895
896     =cut
897
898 For more information on Pod, check out L<perlpod> and L<perlpodspec>.
899
900 =head2 How do I clear a package?
901
902 Use this code, provided by Mark-Jason Dominus:
903
904     sub scrub_package {
905         no strict 'refs';
906         my $pack = shift;
907         die "Shouldn't delete main package"
908             if $pack eq "" || $pack eq "main";
909         my $stash = *{$pack . '::'}{HASH};
910         my $name;
911         foreach $name (keys %$stash) {
912             my $fullname = $pack . '::' . $name;
913             # Get rid of everything with that name.
914             undef $$fullname;
915             undef @$fullname;
916             undef %$fullname;
917             undef &$fullname;
918             undef *$fullname;
919         }
920     }
921
922 Or, if you're using a recent release of Perl, you can
923 just use the Symbol::delete_package() function instead.
924
925 =head2 How can I use a variable as a variable name?
926
927 Beginners often think they want to have a variable contain the name
928 of a variable.
929
930     $fred    = 23;
931     $varname = "fred";
932     ++$$varname;         # $fred now 24
933
934 This works I<sometimes>, but it is a very bad idea for two reasons.
935
936 The first reason is that this technique I<only works on global
937 variables>.  That means that if $fred is a lexical variable created
938 with my() in the above example, the code wouldn't work at all: you'd
939 accidentally access the global and skip right over the private lexical
940 altogether.  Global variables are bad because they can easily collide
941 accidentally and in general make for non-scalable and confusing code.
942
943 Symbolic references are forbidden under the C<use strict> pragma.
944 They are not true references and consequently are not reference-counted
945 or garbage-collected.
946
947 The other reason why using a variable to hold the name of another
948 variable is a bad idea is that the question often stems from a lack of
949 understanding of Perl data structures, particularly hashes.  By using
950 symbolic references, you are just using the package's symbol-table hash
951 (like C<%main::>) instead of a user-defined hash.  The solution is to
952 use your own hash or a real reference instead.
953
954     $USER_VARS{"fred"} = 23;
955     $varname = "fred";
956     $USER_VARS{$varname}++;  # not $$varname++
957
958 There we're using the %USER_VARS hash instead of symbolic references.
959 Sometimes this comes up in reading strings from the user with variable
960 references and wanting to expand them to the values of your perl
961 program's variables.  This is also a bad idea because it conflates the
962 program-addressable namespace and the user-addressable one.  Instead of
963 reading a string and expanding it to the actual contents of your program's
964 own variables:
965
966     $str = 'this has a $fred and $barney in it';
967     $str =~ s/(\$\w+)/$1/eeg;          # need double eval
968
969 it would be better to keep a hash around like %USER_VARS and have
970 variable references actually refer to entries in that hash:
971
972     $str =~ s/\$(\w+)/$USER_VARS{$1}/g;   # no /e here at all
973
974 That's faster, cleaner, and safer than the previous approach.  Of course,
975 you don't need to use a dollar sign.  You could use your own scheme to
976 make it less confusing, like bracketed percent symbols, etc.
977
978     $str = 'this has a %fred% and %barney% in it';
979     $str =~ s/%(\w+)%/$USER_VARS{$1}/g;   # no /e here at all
980
981 Another reason that folks sometimes think they want a variable to
982 contain the name of a variable is that they don't know how to build
983 proper data structures using hashes.  For example, let's say they
984 wanted two hashes in their program: %fred and %barney, and that they
985 wanted to use another scalar variable to refer to those by name.
986
987     $name = "fred";
988     $$name{WIFE} = "wilma";     # set %fred
989
990     $name = "barney";
991     $$name{WIFE} = "betty";    # set %barney
992
993 This is still a symbolic reference, and is still saddled with the
994 problems enumerated above.  It would be far better to write:
995
996     $folks{"fred"}{WIFE}   = "wilma";
997     $folks{"barney"}{WIFE} = "betty";
998
999 And just use a multilevel hash to start with.
1000
1001 The only times that you absolutely I<must> use symbolic references are
1002 when you really must refer to the symbol table.  This may be because it's
1003 something that one can't take a real reference to, such as a format name.
1004 Doing so may also be important for method calls, since these always go
1005 through the symbol table for resolution.
1006
1007 In those cases, you would turn off C<strict 'refs'> temporarily so you
1008 can play around with the symbol table.  For example:
1009
1010     @colors = qw(red blue green yellow orange purple violet);
1011     for my $name (@colors) {
1012         no strict 'refs';  # renege for the block
1013         *$name = sub { "<FONT COLOR='$name'>@_</FONT>" };
1014     }
1015
1016 All those functions (red(), blue(), green(), etc.) appear to be separate,
1017 but the real code in the closure actually was compiled only once.
1018
1019 So, sometimes you might want to use symbolic references to manipulate
1020 the symbol table directly.  This doesn't matter for formats, handles, and
1021 subroutines, because they are always global--you can't use my() on them.
1022 For scalars, arrays, and hashes, though--and usually for subroutines--
1023 you probably only want to use hard references.
1024
1025 =head2 What does "bad interpreter" mean?
1026
1027 (contributed by brian d foy)
1028
1029 The "bad interpreter" message comes from the shell, not perl.  The
1030 actual message may vary depending on your platform, shell, and locale
1031 settings.
1032
1033 If you see "bad interpreter - no such file or directory", the first
1034 line in your perl script (the "shebang" line) does not contain the
1035 right path to perl (or any other program capable of running scripts).
1036 Sometimes this happens when you move the script from one machine to
1037 another and each machine has a different path to perl--/usr/bin/perl
1038 versus /usr/local/bin/perl for instance. It may also indicate
1039 that the source machine has CRLF line terminators and the
1040 destination machine has LF only: the shell tries to find
1041 /usr/bin/perl<CR>, but can't.
1042
1043 If you see "bad interpreter: Permission denied", you need to make your
1044 script executable.
1045
1046 In either case, you should still be able to run the scripts with perl
1047 explicitly:
1048
1049     % perl script.pl
1050
1051 If you get a message like "perl: command not found", perl is not in
1052 your PATH, which might also mean that the location of perl is not
1053 where you expect it so you need to adjust your shebang line.
1054
1055 =head1 AUTHOR AND COPYRIGHT
1056
1057 Copyright (c) 1997-2010 Tom Christiansen, Nathan Torkington, and
1058 other authors as noted. All rights reserved.
1059
1060 This documentation is free; you can redistribute it and/or modify it
1061 under the same terms as Perl itself.
1062
1063 Irrespective of its distribution, all code examples in this file
1064 are hereby placed into the public domain.  You are permitted and
1065 encouraged to use this code in your own programs for fun
1066 or for profit as you see fit.  A simple comment in the code giving
1067 credit would be courteous but is not required.