This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Add support for Unicode's Script_Extension property
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25
26 require 5.010_001;
27 use strict;
28 use warnings;
29 use Carp;
30 use Config;
31 use File::Find;
32 use File::Path;
33 use File::Spec;
34 use Text::Tabs;
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 ##########################################################################
40 #
41 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
42 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
43 # a pod file and a .t file
44 #
45 # The structure of this file is:
46 #   First these introductory comments; then
47 #   code needed for everywhere, such as debugging stuff; then
48 #   code to handle input parameters; then
49 #   data structures likely to be of external interest (some of which depend on
50 #       the input parameters, so follows them; then
51 #   more data structures and subroutine and package (class) definitions; then
52 #   the small actual loop to process the input files and finish up; then
53 #   a __DATA__ section, for the .t tests
54 #
55 # This program works on all releases of Unicode through at least 6.0.  The
56 # outputs have been scrutinized most intently for release 5.1.  The others
57 # have been checked for somewhat more than just sanity.  It can handle all
58 # existing Unicode character properties in those releases.
59 #
60 # This program is mostly about Unicode character (or code point) properties.
61 # A property describes some attribute or quality of a code point, like if it
62 # is lowercase or not, its name, what version of Unicode it was first defined
63 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
64 # possibilities by making all properties into mappings from each code point
65 # into some corresponding value.  In the case of it being lowercase or not,
66 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
67 # property maps each Unicode code point to a single value, called a "property
68 # value".  (Hence each Unicode property is a true mathematical function with
69 # exactly one value per code point.)
70 #
71 # When using a property in a regular expression, what is desired isn't the
72 # mapping of the code point to its property's value, but the reverse (or the
73 # mathematical "inverse relation"): starting with the property value, "Does a
74 # code point map to it?"  These are written in a "compound" form:
75 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
76 # files containing the lists of code points that map to each such regular
77 # expression property value, one file per list
78 #
79 # There is also a single form shortcut that Perl adds for many of the commonly
80 # used properties.  This happens for all binary properties, plus script,
81 # general_category, and block properties.
82 #
83 # Thus the outputs of this program are files.  There are map files, mostly in
84 # the 'To' directory; and there are list files for use in regular expression
85 # matching, all in subdirectories of the 'lib' directory, with each
86 # subdirectory being named for the property that the lists in it are for.
87 # Bookkeeping, test, and documentation files are also generated.
88
89 my $matches_directory = 'lib';   # Where match (\p{}) files go.
90 my $map_directory = 'To';        # Where map files go.
91
92 # DATA STRUCTURES
93 #
94 # The major data structures of this program are Property, of course, but also
95 # Table.  There are two kinds of tables, very similar to each other.
96 # "Match_Table" is the data structure giving the list of code points that have
97 # a particular property value, mentioned above.  There is also a "Map_Table"
98 # data structure which gives the property's mapping from code point to value.
99 # There are two structures because the match tables need to be combined in
100 # various ways, such as constructing unions, intersections, complements, etc.,
101 # and the map ones don't.  And there would be problems, perhaps subtle, if
102 # a map table were inadvertently operated on in some of those ways.
103 # The use of separate classes with operations defined on one but not the other
104 # prevents accidentally confusing the two.
105 #
106 # At the heart of each table's data structure is a "Range_List", which is just
107 # an ordered list of "Ranges", plus ancillary information, and methods to
108 # operate on them.  A Range is a compact way to store property information.
109 # Each range has a starting code point, an ending code point, and a value that
110 # is meant to apply to all the code points between the two end points,
111 # inclusive.  For a map table, this value is the property value for those
112 # code points.  Two such ranges could be written like this:
113 #   0x41 .. 0x5A, 'Upper',
114 #   0x61 .. 0x7A, 'Lower'
115 #
116 # Each range also has a type used as a convenience to classify the values.
117 # Most ranges in this program will be Type 0, or normal, but there are some
118 # ranges that have a non-zero type.  These are used only in map tables, and
119 # are for mappings that don't fit into the normal scheme of things.  Mappings
120 # that require a hash entry to communicate with utf8.c are one example;
121 # another example is mappings for charnames.pm to use which indicate a name
122 # that is algorithmically determinable from its code point (and vice-versa).
123 # These are used to significantly compact these tables, instead of listing
124 # each one of the tens of thousands individually.
125 #
126 # In a match table, the value of a range is irrelevant (and hence the type as
127 # well, which will always be 0), and arbitrarily set to the null string.
128 # Using the example above, there would be two match tables for those two
129 # entries, one named Upper would contain the 0x41..0x5A range, and the other
130 # named Lower would contain 0x61..0x7A.
131 #
132 # Actually, there are two types of range lists, "Range_Map" is the one
133 # associated with map tables, and "Range_List" with match tables.
134 # Again, this is so that methods can be defined on one and not the other so as
135 # to prevent operating on them in incorrect ways.
136 #
137 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
138 # in the perl core.  All tables could in theory be written, but some are
139 # suppressed because there is no current practical use for them.  It is easy
140 # to change which get written by changing various lists that are near the top
141 # of the actual code in this file.  The table data structures contain enough
142 # ancillary information to allow them to be treated as separate entities for
143 # writing, such as the path to each one's file.  There is a heading in each
144 # map table that gives the format of its entries, and what the map is for all
145 # the code points missing from it.  (This allows tables to be more compact.)
146 #
147 # The Property data structure contains one or more tables.  All properties
148 # contain a map table (except the $perl property which is a
149 # pseudo-property containing only match tables), and any properties that
150 # are usable in regular expression matches also contain various matching
151 # tables, one for each value the property can have.  A binary property can
152 # have two values, True and False (or Y and N, which are preferred by Unicode
153 # terminology).  Thus each of these properties will have a map table that
154 # takes every code point and maps it to Y or N (but having ranges cuts the
155 # number of entries in that table way down), and two match tables, one
156 # which has a list of all the code points that map to Y, and one for all the
157 # code points that map to N.  (For each of these, a third table is also
158 # generated for the pseudo Perl property.  It contains the identical code
159 # points as the Y table, but can be written, not in the compound form, but in
160 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
161 # properties have several possible values, some have many, and properties like
162 # Name have a different value for every named code point.  Those will not,
163 # unless the controlling lists are changed, have their match tables written
164 # out.  But all the ones which can be used in regular expression \p{} and \P{}
165 # constructs will.  Generally a property will have either its map table or its
166 # match tables written but not both.  Again, what gets written is controlled
167 # by lists which can easily be changed.  Properties have a 'Type', like
168 # binary, or string, or enum depending on how many match tables there are and
169 # the content of the maps.  This 'Type' is different than a range 'Type', so
170 # don't get confused by the two concepts having the same name.
171 #
172 # For information about the Unicode properties, see Unicode's UAX44 document:
173
174 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
175
176 # As stated earlier, this program will work on any release of Unicode so far.
177 # Most obvious problems in earlier data have NOT been corrected except when
178 # necessary to make Perl or this program work reasonably.  For example, no
179 # folding information was given in early releases, so this program uses the
180 # substitute of lower case, just so that a regular expression with the /i
181 # option will do something that actually gives the right results in many
182 # cases.  There are also a couple other corrections for version 1.1.5,
183 # commented at the point they are made.  As an example of corrections that
184 # weren't made (but could be) is this statement from DerivedAge.txt: "The
185 # supplementary private use code points and the non-character code points were
186 # assigned in version 2.0, but not specifically listed in the UCD until
187 # versions 3.0 and 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0)
188 # More information on Unicode version glitches is further down in these
189 # introductory comments.
190 #
191 # This program works on all non-provisional properties as of 6.0, though the
192 # files for some are suppressed from apparent lack of demand for them.  You
193 # can change which are output by changing lists in this program.
194 #
195 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
196 # loose matchings rules (from Unicode TR18):
197 #
198 #    The recommended names for UCD properties and property values are in
199 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
200 #    [PropValue]. There are both abbreviated names and longer, more
201 #    descriptive names. It is strongly recommended that both names be
202 #    recognized, and that loose matching of property names be used,
203 #    whereby the case distinctions, whitespace, hyphens, and underbar
204 #    are ignored.
205 # The program still allows Fuzzy to override its determination of if loose
206 # matching should be used, but it isn't currently used, as it is no longer
207 # needed; the calculations it makes are good enough.
208 #
209 # SUMMARY OF HOW IT WORKS:
210 #
211 #   Process arguments
212 #
213 #   A list is constructed containing each input file that is to be processed
214 #
215 #   Each file on the list is processed in a loop, using the associated handler
216 #   code for each:
217 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
218 #            first.  These files name the properties and property values.
219 #            Objects are created of all the property and property value names
220 #            that the rest of the input should expect, including all synonyms.
221 #        The other input files give mappings from properties to property
222 #           values.  That is, they list code points and say what the mapping
223 #           is under the given property.  Some files give the mappings for
224 #           just one property; and some for many.  This program goes through
225 #           each file and populates the properties from them.  Some properties
226 #           are listed in more than one file, and Unicode has set up a
227 #           precedence as to which has priority if there is a conflict.  Thus
228 #           the order of processing matters, and this program handles the
229 #           conflict possibility by processing the overriding input files
230 #           last, so that if necessary they replace earlier values.
231 #        After this is all done, the program creates the property mappings not
232 #            furnished by Unicode, but derivable from what it does give.
233 #        The tables of code points that match each property value in each
234 #            property that is accessible by regular expressions are created.
235 #        The Perl-defined properties are created and populated.  Many of these
236 #            require data determined from the earlier steps
237 #        Any Perl-defined synonyms are created, and name clashes between Perl
238 #            and Unicode are reconciled and warned about.
239 #        All the properties are written to files
240 #        Any other files are written, and final warnings issued.
241 #
242 # For clarity, a number of operators have been overloaded to work on tables:
243 #   ~ means invert (take all characters not in the set).  The more
244 #       conventional '!' is not used because of the possibility of confusing
245 #       it with the actual boolean operation.
246 #   + means union
247 #   - means subtraction
248 #   & means intersection
249 # The precedence of these is the order listed.  Parentheses should be
250 # copiously used.  These are not a general scheme.  The operations aren't
251 # defined for a number of things, deliberately, to avoid getting into trouble.
252 # Operations are done on references and affect the underlying structures, so
253 # that the copy constructors for them have been overloaded to not return a new
254 # clone, but the input object itself.
255 #
256 # The bool operator is deliberately not overloaded to avoid confusion with
257 # "should it mean if the object merely exists, or also is non-empty?".
258 #
259 # WHY CERTAIN DESIGN DECISIONS WERE MADE
260 #
261 # This program needs to be able to run under miniperl.  Therefore, it uses a
262 # minimum of other modules, and hence implements some things itself that could
263 # be gotten from CPAN
264 #
265 # This program uses inputs published by the Unicode Consortium.  These can
266 # change incompatibly between releases without the Perl maintainers realizing
267 # it.  Therefore this program is now designed to try to flag these.  It looks
268 # at the directories where the inputs are, and flags any unrecognized files.
269 # It keeps track of all the properties in the files it handles, and flags any
270 # that it doesn't know how to handle.  It also flags any input lines that
271 # don't match the expected syntax, among other checks.
272 #
273 # It is also designed so if a new input file matches one of the known
274 # templates, one hopefully just needs to add it to a list to have it
275 # processed.
276 #
277 # As mentioned earlier, some properties are given in more than one file.  In
278 # particular, the files in the extracted directory are supposedly just
279 # reformattings of the others.  But they contain information not easily
280 # derivable from the other files, including results for Unihan, which this
281 # program doesn't ordinarily look at, and for unassigned code points.  They
282 # also have historically had errors or been incomplete.  In an attempt to
283 # create the best possible data, this program thus processes them first to
284 # glean information missing from the other files; then processes those other
285 # files to override any errors in the extracted ones.  Much of the design was
286 # driven by this need to store things and then possibly override them.
287 #
288 # It tries to keep fatal errors to a minimum, to generate something usable for
289 # testing purposes.  It always looks for files that could be inputs, and will
290 # warn about any that it doesn't know how to handle (the -q option suppresses
291 # the warning).
292 #
293 # Why have files written out for binary 'N' matches?
294 #   For binary properties, if you know the mapping for either Y or N; the
295 #   other is trivial to construct, so could be done at Perl run-time by just
296 #   complementing the result, instead of having a file for it.  That is, if
297 #   someone types in \p{foo: N}, Perl could translate that to \P{foo: Y} and
298 #   not need a file.   The problem is communicating to Perl that a given
299 #   property is binary.  Perl can't figure it out from looking at the N (or
300 #   No), as some non-binary properties have these as property values.  So
301 #   rather than inventing a way to communicate this info back to the core,
302 #   which would have required changes there as well, it was simpler just to
303 #   add the extra tables.
304 #
305 # Why is there more than one type of range?
306 #   This simplified things.  There are some very specialized code points that
307 #   have to be handled specially for output, such as Hangul syllable names.
308 #   By creating a range type (done late in the development process), it
309 #   allowed this to be stored with the range, and overridden by other input.
310 #   Originally these were stored in another data structure, and it became a
311 #   mess trying to decide if a second file that was for the same property was
312 #   overriding the earlier one or not.
313 #
314 # Why are there two kinds of tables, match and map?
315 #   (And there is a base class shared by the two as well.)  As stated above,
316 #   they actually are for different things.  Development proceeded much more
317 #   smoothly when I (khw) realized the distinction.  Map tables are used to
318 #   give the property value for every code point (actually every code point
319 #   that doesn't map to a default value).  Match tables are used for regular
320 #   expression matches, and are essentially the inverse mapping.  Separating
321 #   the two allows more specialized methods, and error checks so that one
322 #   can't just take the intersection of two map tables, for example, as that
323 #   is nonsensical.
324 #
325 # There are no match tables generated for matches of the null string.  These
326 # would look like qr/\p{JSN=}/ currently without modifying the regex code.
327 # Perhaps something like them could be added if necessary.  The JSN does have
328 # a real code point U+110B that maps to the null string, but it is a
329 # contributory property, and therefore not output by default.  And it's easily
330 # handled so far by making the null string the default where it is a
331 # possibility.
332 #
333 # DEBUGGING
334 #
335 # This program is written so it will run under miniperl.  Occasionally changes
336 # will cause an error where the backtrace doesn't work well under miniperl.
337 # To diagnose the problem, you can instead run it under regular perl, if you
338 # have one compiled.
339 #
340 # There is a good trace facility.  To enable it, first sub DEBUG must be set
341 # to return true.  Then a line like
342 #
343 # local $to_trace = 1 if main::DEBUG;
344 #
345 # can be added to enable tracing in its lexical scope or until you insert
346 # another line:
347 #
348 # local $to_trace = 0 if main::DEBUG;
349 #
350 # then use a line like "trace $a, @b, %c, ...;
351 #
352 # Some of the more complex subroutines already have trace statements in them.
353 # Permanent trace statements should be like:
354 #
355 # trace ... if main::DEBUG && $to_trace;
356 #
357 # If there is just one or a few files that you're debugging, you can easily
358 # cause most everything else to be skipped.  Change the line
359 #
360 # my $debug_skip = 0;
361 #
362 # to 1, and every file whose object is in @input_file_objects and doesn't have
363 # a, 'non_skip => 1,' in its constructor will be skipped.
364 #
365 # To compare the output tables, it may be useful to specify the -annotate
366 # flag.  This causes the tables to expand so there is one entry for each
367 # non-algorithmically named code point giving, currently its name, and its
368 # graphic representation if printable (and you have a font that knows about
369 # it).  This makes it easier to see what the particular code points are in
370 # each output table.  The tables are usable, but because they don't have
371 # ranges (for the most part), a Perl using them will run slower.  Non-named
372 # code points are annotated with a description of their status, and contiguous
373 # ones with the same description will be output as a range rather than
374 # individually.  Algorithmically named characters are also output as ranges,
375 # except when there are just a few contiguous ones.
376 #
377 # FUTURE ISSUES
378 #
379 # The program would break if Unicode were to change its names so that
380 # interior white space, underscores, or dashes differences were significant
381 # within property and property value names.
382 #
383 # It might be easier to use the xml versions of the UCD if this program ever
384 # would need heavy revision, and the ability to handle old versions was not
385 # required.
386 #
387 # There is the potential for name collisions, in that Perl has chosen names
388 # that Unicode could decide it also likes.  There have been such collisions in
389 # the past, with mostly Perl deciding to adopt the Unicode definition of the
390 # name.  However in the 5.2 Unicode beta testing, there were a number of such
391 # collisions, which were withdrawn before the final release, because of Perl's
392 # and other's protests.  These all involved new properties which began with
393 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
394 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
395 # Unicode document, so they are unlikely to be used by Unicode for another
396 # purpose.  However, they might try something beginning with 'In', or use any
397 # of the other Perl-defined properties.  This program will warn you of name
398 # collisions, and refuse to generate tables with them, but manual intervention
399 # will be required in this event.  One scheme that could be implemented, if
400 # necessary, would be to have this program generate another file, or add a
401 # field to mktables.lst that gives the date of first definition of a property.
402 # Each new release of Unicode would use that file as a basis for the next
403 # iteration.  And the Perl synonym addition code could sort based on the age
404 # of the property, so older properties get priority, and newer ones that clash
405 # would be refused; hence existing code would not be impacted, and some other
406 # synonym would have to be used for the new property.  This is ugly, and
407 # manual intervention would certainly be easier to do in the short run; lets
408 # hope it never comes to this.
409 #
410 # A NOTE ON UNIHAN
411 #
412 # This program can generate tables from the Unihan database.  But it doesn't
413 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
414 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
415 # database was split into 8 different files, all beginning with the letters
416 # 'Unihan'.  This program will read those file(s) if present, but it needs to
417 # know which of the many properties in the file(s) should have tables created
418 # for them.  It will create tables for any properties listed in
419 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
420 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
421 # property you want is not in those files of the release you are building
422 # against, you must add it to those two arrays.  Starting in 4.0, the
423 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
424 # is present in the directory, a table will be generated for that property.
425 # In 5.2, several more properties were added.  For your convenience, the two
426 # arrays are initialized with all the 6.0 listed properties that are also in
427 # earlier releases.  But these are commented out.  You can just uncomment the
428 # ones you want, or use them as a template for adding entries for other
429 # properties.
430 #
431 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
432 # and filter_unihan_line() are the functions where this is done.  This program
433 # already does some adjusting to make the lines look more like the rest of the
434 # Unicode DB;  You can see what that is in filter_unihan_line()
435 #
436 # There is a bug in the 3.2 data file in which some values for the
437 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
438 # could be added for these; or for a particular installation, the Unihan.txt
439 # file could be edited to fix them.
440 #
441 # HOW TO ADD A FILE TO BE PROCESSED
442 #
443 # A new file from Unicode needs to have an object constructed for it in
444 # @input_file_objects, probably at the end or at the end of the extracted
445 # ones.  The program should warn you if its name will clash with others on
446 # restrictive file systems, like DOS.  If so, figure out a better name, and
447 # add lines to the README.perl file giving that.  If the file is a character
448 # property, it should be in the format that Unicode has by default
449 # standardized for such files for the more recently introduced ones.
450 # If so, the Input_file constructor for @input_file_objects can just be the
451 # file name and release it first appeared in.  If not, then it should be
452 # possible to construct an each_line_handler() to massage the line into the
453 # standardized form.
454 #
455 # For non-character properties, more code will be needed.  You can look at
456 # the existing entries for clues.
457 #
458 # UNICODE VERSIONS NOTES
459 #
460 # The Unicode UCD has had a number of errors in it over the versions.  And
461 # these remain, by policy, in the standard for that version.  Therefore it is
462 # risky to correct them, because code may be expecting the error.  So this
463 # program doesn't generally make changes, unless the error breaks the Perl
464 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
465 # for U+1105, which causes real problems for the algorithms for Jamo
466 # calculations, so it is changed here.
467 #
468 # But it isn't so clear cut as to what to do about concepts that are
469 # introduced in a later release; should they extend back to earlier releases
470 # where the concept just didn't exist?  It was easier to do this than to not,
471 # so that's what was done.  For example, the default value for code points not
472 # in the files for various properties was probably undefined until changed by
473 # some version.  No_Block for blocks is such an example.  This program will
474 # assign No_Block even in Unicode versions that didn't have it.  This has the
475 # benefit that code being written doesn't have to special case earlier
476 # versions; and the detriment that it doesn't match the Standard precisely for
477 # the affected versions.
478 #
479 # Here are some observations about some of the issues in early versions:
480 #
481 # The number of code points in \p{alpha} halved in 2.1.9.  It turns out that
482 # the reason is that the CJK block starting at 4E00 was removed from PropList,
483 # and was not put back in until 3.1.0
484 #
485 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
486 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
487 # reason is that 3.2 introduced U+205F=medium math space, which was not
488 # classed as white space, but Perl figured out that it should have been. 4.0
489 # reclassified it correctly.
490 #
491 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
492 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
493 # was left with no code points, as all the ones that mapped to 202 stayed
494 # mapped to 202.  Thus if your program used the numeric name for the class,
495 # it would not have been affected, but if it used the mnemonic, it would have
496 # been.
497 #
498 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
499 # points which eventually came to have this script property value, instead
500 # mapped to "Unknown".  But in the next release all these code points were
501 # moved to \p{sc=common} instead.
502 #
503 # The default for missing code points for BidiClass is complicated.  Starting
504 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
505 # tries to do the best it can for earlier releases.  It is done in
506 # process_PropertyAliases()
507 #
508 ##############################################################################
509
510 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
511                         # and errors
512 my $MAX_LINE_WIDTH = 78;
513
514 # Debugging aid to skip most files so as to not be distracted by them when
515 # concentrating on the ones being debugged.  Add
516 # non_skip => 1,
517 # to the constructor for those files you want processed when you set this.
518 # Files with a first version number of 0 are special: they are always
519 # processed regardless of the state of this flag.
520 my $debug_skip = 0;
521
522 # Set to 1 to enable tracing.
523 our $to_trace = 0;
524
525 { # Closure for trace: debugging aid
526     my $print_caller = 1;        # ? Include calling subroutine name
527     my $main_with_colon = 'main::';
528     my $main_colon_length = length($main_with_colon);
529
530     sub trace {
531         return unless $to_trace;        # Do nothing if global flag not set
532
533         my @input = @_;
534
535         local $DB::trace = 0;
536         $DB::trace = 0;          # Quiet 'used only once' message
537
538         my $line_number;
539
540         # Loop looking up the stack to get the first non-trace caller
541         my $caller_line;
542         my $caller_name;
543         my $i = 0;
544         do {
545             $line_number = $caller_line;
546             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
547             $caller = $main_with_colon unless defined $caller;
548
549             $caller_name = $caller;
550
551             # get rid of pkg
552             $caller_name =~ s/.*:://;
553             if (substr($caller_name, 0, $main_colon_length)
554                 eq $main_with_colon)
555             {
556                 $caller_name = substr($caller_name, $main_colon_length);
557             }
558
559         } until ($caller_name ne 'trace');
560
561         # If the stack was empty, we were called from the top level
562         $caller_name = 'main' if ($caller_name eq ""
563                                     || $caller_name eq 'trace');
564
565         my $output = "";
566         foreach my $string (@input) {
567             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
568             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
569                 $output .= simple_dumper($string);
570             }
571             else {
572                 $string = "$string" if ref $string;
573                 $string = $UNDEF unless defined $string;
574                 chomp $string;
575                 $string = '""' if $string eq "";
576                 $output .= " " if $output ne ""
577                                 && $string ne ""
578                                 && substr($output, -1, 1) ne " "
579                                 && substr($string, 0, 1) ne " ";
580                 $output .= $string;
581             }
582         }
583
584         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
585         print STDERR "$caller_name: " if $print_caller;
586         print STDERR $output, "\n";
587         return;
588     }
589 }
590
591 # This is for a rarely used development feature that allows you to compare two
592 # versions of the Unicode standard without having to deal with changes caused
593 # by the code points introduced in the later version.  Change the 0 to a SINGLE
594 # dotted Unicode release number (e.g. 2.1).  Only code points introduced in
595 # that release and earlier will be used; later ones are thrown away.  You use
596 # the version number of the earliest one you want to compare; then run this
597 # program on directory structures containing each release, and compare the
598 # outputs.  These outputs will therefore include only the code points common
599 # to both releases, and you can see the changes caused just by the underlying
600 # release semantic changes.  For versions earlier than 3.2, you must copy a
601 # version of DAge.txt into the directory.
602 my $string_compare_versions = DEBUG && 0; #  e.g., v2.1;
603 my $compare_versions = DEBUG
604                        && $string_compare_versions
605                        && pack "C*", split /\./, $string_compare_versions;
606
607 sub uniques {
608     # Returns non-duplicated input values.  From "Perl Best Practices:
609     # Encapsulated Cleverness".  p. 455 in first edition.
610
611     my %seen;
612     # Arguably this breaks encapsulation, if the goal is to permit multiple
613     # distinct objects to stringify to the same value, and be interchangeable.
614     # However, for this program, no two objects stringify identically, and all
615     # lists passed to this function are either objects or strings. So this
616     # doesn't affect correctness, but it does give a couple of percent speedup.
617     no overloading;
618     return grep { ! $seen{$_}++ } @_;
619 }
620
621 $0 = File::Spec->canonpath($0);
622
623 my $make_test_script = 0;      # ? Should we output a test script
624 my $write_unchanged_files = 0; # ? Should we update the output files even if
625                                #    we don't think they have changed
626 my $use_directory = "";        # ? Should we chdir somewhere.
627 my $pod_directory;             # input directory to store the pod file.
628 my $pod_file = 'perluniprops';
629 my $t_path;                     # Path to the .t test file
630 my $file_list = 'mktables.lst'; # File to store input and output file names.
631                                # This is used to speed up the build, by not
632                                # executing the main body of the program if
633                                # nothing on the list has changed since the
634                                # previous build
635 my $make_list = 1;             # ? Should we write $file_list.  Set to always
636                                # make a list so that when the pumpking is
637                                # preparing a release, s/he won't have to do
638                                # special things
639 my $glob_list = 0;             # ? Should we try to include unknown .txt files
640                                # in the input.
641 my $output_range_counts = $debugging_build;   # ? Should we include the number
642                                               # of code points in ranges in
643                                               # the output
644 my $annotate = 0;              # ? Should character names be in the output
645
646 # Verbosity levels; 0 is quiet
647 my $NORMAL_VERBOSITY = 1;
648 my $PROGRESS = 2;
649 my $VERBOSE = 3;
650
651 my $verbosity = $NORMAL_VERBOSITY;
652
653 # Process arguments
654 while (@ARGV) {
655     my $arg = shift @ARGV;
656     if ($arg eq '-v') {
657         $verbosity = $VERBOSE;
658     }
659     elsif ($arg eq '-p') {
660         $verbosity = $PROGRESS;
661         $| = 1;     # Flush buffers as we go.
662     }
663     elsif ($arg eq '-q') {
664         $verbosity = 0;
665     }
666     elsif ($arg eq '-w') {
667         $write_unchanged_files = 1; # update the files even if havent changed
668     }
669     elsif ($arg eq '-check') {
670         my $this = shift @ARGV;
671         my $ok = shift @ARGV;
672         if ($this ne $ok) {
673             print "Skipping as check params are not the same.\n";
674             exit(0);
675         }
676     }
677     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
678         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
679     }
680     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
681     {
682         $make_test_script = 1;
683     }
684     elsif ($arg eq '-makelist') {
685         $make_list = 1;
686     }
687     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
688         -d $use_directory or croak "Unknown directory '$use_directory'";
689     }
690     elsif ($arg eq '-L') {
691
692         # Existence not tested until have chdir'd
693         $file_list = shift;
694     }
695     elsif ($arg eq '-globlist') {
696         $glob_list = 1;
697     }
698     elsif ($arg eq '-c') {
699         $output_range_counts = ! $output_range_counts
700     }
701     elsif ($arg eq '-annotate') {
702         $annotate = 1;
703         $debugging_build = 1;
704         $output_range_counts = 1;
705     }
706     else {
707         my $with_c = 'with';
708         $with_c .= 'out' if $output_range_counts;   # Complements the state
709         croak <<END;
710 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
711           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
712           [-check A B ]
713   -c          : Output comments $with_c number of code points in ranges
714   -q          : Quiet Mode: Only output serious warnings.
715   -p          : Set verbosity level to normal plus show progress.
716   -v          : Set Verbosity level high:  Show progress and non-serious
717                 warnings
718   -w          : Write files regardless
719   -C dir      : Change to this directory before proceeding. All relative paths
720                 except those specified by the -P and -T options will be done
721                 with respect to this directory.
722   -P dir      : Output $pod_file file to directory 'dir'.
723   -T path     : Create a test script as 'path'; overrides -maketest
724   -L filelist : Use alternate 'filelist' instead of standard one
725   -globlist   : Take as input all non-Test *.txt files in current and sub
726                 directories
727   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
728                 overrides -T
729   -makelist   : Rewrite the file list $file_list based on current setup
730   -annotate   : Output an annotation for each character in the table files;
731                 useful for debugging mktables, looking at diffs; but is slow,
732                 memory intensive; resulting tables are usable but slow and
733                 very large.
734   -check A B  : Executes $0 only if A and B are the same
735 END
736     }
737 }
738
739 # Stores the most-recently changed file.  If none have changed, can skip the
740 # build
741 my $most_recent = (stat $0)[9];   # Do this before the chdir!
742
743 # Change directories now, because need to read 'version' early.
744 if ($use_directory) {
745     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
746         $pod_directory = File::Spec->rel2abs($pod_directory);
747     }
748     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
749         $t_path = File::Spec->rel2abs($t_path);
750     }
751     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
752     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
753         $pod_directory = File::Spec->abs2rel($pod_directory);
754     }
755     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
756         $t_path = File::Spec->abs2rel($t_path);
757     }
758 }
759
760 # Get Unicode version into regular and v-string.  This is done now because
761 # various tables below get populated based on it.  These tables are populated
762 # here to be near the top of the file, and so easily seeable by those needing
763 # to modify things.
764 open my $VERSION, "<", "version"
765                     or croak "$0: can't open required file 'version': $!\n";
766 my $string_version = <$VERSION>;
767 close $VERSION;
768 chomp $string_version;
769 my $v_version = pack "C*", split /\./, $string_version;        # v string
770
771 # The following are the complete names of properties with property values that
772 # are known to not match any code points in some versions of Unicode, but that
773 # may change in the future so they should be matchable, hence an empty file is
774 # generated for them.
775 my @tables_that_may_be_empty = (
776                                 'Joining_Type=Left_Joining',
777                                 );
778 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
779 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
780 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
781                                                     if $v_version ge v4.1.0;
782 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
783                                                     if $v_version ge v6.0.0;
784
785 # The lists below are hashes, so the key is the item in the list, and the
786 # value is the reason why it is in the list.  This makes generation of
787 # documentation easier.
788
789 my %why_suppressed;  # No file generated for these.
790
791 # Files aren't generated for empty extraneous properties.  This is arguable.
792 # Extraneous properties generally come about because a property is no longer
793 # used in a newer version of Unicode.  If we generated a file without code
794 # points, programs that used to work on that property will still execute
795 # without errors.  It just won't ever match (or will always match, with \P{}).
796 # This means that the logic is now likely wrong.  I (khw) think its better to
797 # find this out by getting an error message.  Just move them to the table
798 # above to change this behavior
799 my %why_suppress_if_empty_warn_if_not = (
800
801    # It is the only property that has ever officially been removed from the
802    # Standard.  The database never contained any code points for it.
803    'Special_Case_Condition' => 'Obsolete',
804
805    # Apparently never official, but there were code points in some versions of
806    # old-style PropList.txt
807    'Non_Break' => 'Obsolete',
808 );
809
810 # These would normally go in the warn table just above, but they were changed
811 # a long time before this program was written, so warnings about them are
812 # moot.
813 if ($v_version gt v3.2.0) {
814     push @tables_that_may_be_empty,
815                                 'Canonical_Combining_Class=Attached_Below_Left'
816 }
817
818 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
819 # unless explicitly added.
820 if ($v_version ge v5.2.0) {
821     my $unihan = 'Unihan; remove from list if using Unihan';
822     foreach my $table (qw (
823                            kAccountingNumeric
824                            kOtherNumeric
825                            kPrimaryNumeric
826                            kCompatibilityVariant
827                            kIICore
828                            kIRG_GSource
829                            kIRG_HSource
830                            kIRG_JSource
831                            kIRG_KPSource
832                            kIRG_MSource
833                            kIRG_KSource
834                            kIRG_TSource
835                            kIRG_USource
836                            kIRG_VSource
837                            kRSUnicode
838                         ))
839     {
840         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
841     }
842 }
843
844 # Enum values for to_output_map() method in the Map_Table package.
845 my $EXTERNAL_MAP = 1;
846 my $INTERNAL_MAP = 2;
847
848 # To override computed values for writing the map tables for these properties.
849 # The default for enum map tables is to write them out, so that the Unicode
850 # .txt files can be removed, but all the data to compute any property value
851 # for any code point is available in a more compact form.
852 my %global_to_output_map = (
853     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
854     # get stuck supporting it if things change.  Sinc it is a STRING property,
855     # it normally would be listed in the pod, but INTERNAL_MAP suppresses
856     # that.
857     Unicode_1_Name => $INTERNAL_MAP,
858
859     Present_In => 0,                # Suppress, as easily computed from Age
860     Canonical_Combining_Class => 0, # Duplicate of CombiningClass.pl
861     Block => 0,                     # Suppress, as Blocks.txt is retained.
862 );
863
864 # Properties that this program ignores.
865 my @unimplemented_properties = (
866 'Unicode_Radical_Stroke'    # Remove if changing to handle this one.
867 );
868
869 # There are several types of obsolete properties defined by Unicode.  These
870 # must be hand-edited for every new Unicode release.
871 my %why_deprecated;  # Generates a deprecated warning message if used.
872 my %why_stabilized;  # Documentation only
873 my %why_obsolete;    # Documentation only
874
875 {   # Closure
876     my $simple = 'Perl uses the more complete version of this property';
877     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
878
879     my $other_properties = 'other properties';
880     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
881     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
882
883     %why_deprecated = (
884         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
885         'Jamo_Short_Name' => $contributory,
886         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
887         'Other_Alphabetic' => $contributory,
888         'Other_Default_Ignorable_Code_Point' => $contributory,
889         'Other_Grapheme_Extend' => $contributory,
890         'Other_ID_Continue' => $contributory,
891         'Other_ID_Start' => $contributory,
892         'Other_Lowercase' => $contributory,
893         'Other_Math' => $contributory,
894         'Other_Uppercase' => $contributory,
895     );
896
897     %why_suppressed = (
898         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
899         # contains the same information, but without the algorithmically
900         # determinable Hangul syllables'.  This file is not published, so it's
901         # existence is not noted in the comment.
902         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize',
903
904         'ISO_Comment' => 'Apparently no demand for it, but can access it through Unicode::UCD::charinfo.  Obsoleted, and code points for it removed in Unicode 5.2',
905
906         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold",
907         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
908         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
909         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
910
911         'Name' => "Accessible via 'use charnames;'",
912         'Name_Alias' => "Accessible via 'use charnames;'",
913
914         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
915         Expands_On_NFC => $why_no_expand,
916         Expands_On_NFD => $why_no_expand,
917         Expands_On_NFKC => $why_no_expand,
918         Expands_On_NFKD => $why_no_expand,
919     );
920
921     # The following are suppressed because they were made contributory or
922     # deprecated by Unicode before Perl ever thought about supporting them.
923     foreach my $property ('Jamo_Short_Name', 'Grapheme_Link') {
924         $why_suppressed{$property} = $why_deprecated{$property};
925     }
926
927     # Customize the message for all the 'Other_' properties
928     foreach my $property (keys %why_deprecated) {
929         next if (my $main_property = $property) !~ s/^Other_//;
930         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
931     }
932 }
933
934 if ($v_version ge 4.0.0) {
935     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
936     if ($v_version ge 6.0.0) {
937         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
938     }
939 }
940 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
941     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
942     if ($v_version ge 6.0.0) {
943         $why_deprecated{'ISO_Comment'} = 'No longer needed for chart generation; otherwise not useful, and code points for it have been removed';
944     }
945 }
946
947 # Probably obsolete forever
948 if ($v_version ge v4.1.0) {
949     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
950 }
951 if ($v_version ge v6.0.0) {
952     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using Script_Extensions=Katakana or Script_Extensions=Hiragana (or both)"';
953     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either Script_Extensions=Katakana or Script_Extensions=Hiragana"';
954 }
955
956 # This program can create files for enumerated-like properties, such as
957 # 'Numeric_Type'.  This file would be the same format as for a string
958 # property, with a mapping from code point to its value, so you could look up,
959 # for example, the script a code point is in.  But no one so far wants this
960 # mapping, or they have found another way to get it since this is a new
961 # feature.  So no file is generated except if it is in this list.
962 my @output_mapped_properties = split "\n", <<END;
963 END
964
965 # If you are using the Unihan database, you need to add the properties that
966 # you want to extract from it to this table.  For your convenience, the
967 # properties in the 6.0 PropertyAliases.txt file are listed, commented out
968 my @cjk_properties = split "\n", <<'END';
969 #cjkAccountingNumeric; kAccountingNumeric
970 #cjkOtherNumeric; kOtherNumeric
971 #cjkPrimaryNumeric; kPrimaryNumeric
972 #cjkCompatibilityVariant; kCompatibilityVariant
973 #cjkIICore ; kIICore
974 #cjkIRG_GSource; kIRG_GSource
975 #cjkIRG_HSource; kIRG_HSource
976 #cjkIRG_JSource; kIRG_JSource
977 #cjkIRG_KPSource; kIRG_KPSource
978 #cjkIRG_KSource; kIRG_KSource
979 #cjkIRG_TSource; kIRG_TSource
980 #cjkIRG_USource; kIRG_USource
981 #cjkIRG_VSource; kIRG_VSource
982 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
983 END
984
985 # Similarly for the property values.  For your convenience, the lines in the
986 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
987 # '#' marks
988 my @cjk_property_values = split "\n", <<'END';
989 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
990 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
991 ## @missing: 0000..10FFFF; cjkIICore; <none>
992 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
993 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
994 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
995 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
996 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
997 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
998 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
999 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
1000 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
1001 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1002 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1003 END
1004
1005 # The input files don't list every code point.  Those not listed are to be
1006 # defaulted to some value.  Below are hard-coded what those values are for
1007 # non-binary properties as of 5.1.  Starting in 5.0, there are
1008 # machine-parsable comment lines in the files the give the defaults; so this
1009 # list shouldn't have to be extended.  The claim is that all missing entries
1010 # for binary properties will default to 'N'.  Unicode tried to change that in
1011 # 5.2, but the beta period produced enough protest that they backed off.
1012 #
1013 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1014 # be in the form that it expects.  The others may be synonyms.
1015 my $CODE_POINT = '<code point>';
1016 my %default_mapping = (
1017     Age => "Unassigned",
1018     # Bidi_Class => Complicated; set in code
1019     Bidi_Mirroring_Glyph => "",
1020     Block => 'No_Block',
1021     Canonical_Combining_Class => 0,
1022     Case_Folding => $CODE_POINT,
1023     Decomposition_Mapping => $CODE_POINT,
1024     Decomposition_Type => 'None',
1025     East_Asian_Width => "Neutral",
1026     FC_NFKC_Closure => $CODE_POINT,
1027     General_Category => 'Cn',
1028     Grapheme_Cluster_Break => 'Other',
1029     Hangul_Syllable_Type => 'NA',
1030     ISO_Comment => "",
1031     Jamo_Short_Name => "",
1032     Joining_Group => "No_Joining_Group",
1033     # Joining_Type => Complicated; set in code
1034     kIICore => 'N',   #                       Is converted to binary
1035     #Line_Break => Complicated; set in code
1036     Lowercase_Mapping => $CODE_POINT,
1037     Name => "",
1038     Name_Alias => "",
1039     NFC_QC => 'Yes',
1040     NFD_QC => 'Yes',
1041     NFKC_QC => 'Yes',
1042     NFKD_QC => 'Yes',
1043     Numeric_Type => 'None',
1044     Numeric_Value => 'NaN',
1045     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1046     Sentence_Break => 'Other',
1047     Simple_Case_Folding => $CODE_POINT,
1048     Simple_Lowercase_Mapping => $CODE_POINT,
1049     Simple_Titlecase_Mapping => $CODE_POINT,
1050     Simple_Uppercase_Mapping => $CODE_POINT,
1051     Titlecase_Mapping => $CODE_POINT,
1052     Unicode_1_Name => "",
1053     Unicode_Radical_Stroke => "",
1054     Uppercase_Mapping => $CODE_POINT,
1055     Word_Break => 'Other',
1056 );
1057
1058 # Below are files that Unicode furnishes, but this program ignores, and why
1059 my %ignored_files = (
1060     'CJKRadicals.txt' => 'Unihan data',
1061     'Index.txt' => 'An index, not actual data',
1062     'NamedSqProv.txt' => 'Not officially part of the Unicode standard; Append it to NamedSequences.txt if you want to process the contents.',
1063     'NamesList.txt' => 'Just adds commentary',
1064     'NormalizationCorrections.txt' => 'Data is already in other files.',
1065     'Props.txt' => 'Adds nothing to PropList.txt; only in very early releases',
1066     'ReadMe.txt' => 'Just comments',
1067     'README.TXT' => 'Just comments',
1068     'StandardizedVariants.txt' => 'Only for glyph changes, not a Unicode character property.  Does not fit into current scheme where one code point is mapped',
1069     'EmojiSources.txt' => 'Not of general utility: for Japanese legacy cell-phone applications',
1070     'IndicMatraCategory.txt' => 'Provisional',
1071     'IndicSyllabicCategory.txt' => 'Provisional',
1072 );
1073
1074 ### End of externally interesting definitions, except for @input_file_objects
1075
1076 my $HEADER=<<"EOF";
1077 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1078 # This file is machine-generated by $0 from the Unicode
1079 # database, Version $string_version.  Any changes made here will be lost!
1080 EOF
1081
1082 my $INTERNAL_ONLY=<<"EOF";
1083
1084 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1085 # This file is for internal use by the Perl program only.  The format and even
1086 # the name or existence of this file are subject to change without notice.
1087 # Don't use it directly.
1088 EOF
1089
1090 my $DEVELOPMENT_ONLY=<<"EOF";
1091 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1092 # This file contains information artificially constrained to code points
1093 # present in Unicode release $string_compare_versions.
1094 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1095 # not be used for production.
1096
1097 EOF
1098
1099 my $LAST_UNICODE_CODEPOINT_STRING = "10FFFF";
1100 my $LAST_UNICODE_CODEPOINT = hex $LAST_UNICODE_CODEPOINT_STRING;
1101 my $MAX_UNICODE_CODEPOINTS = $LAST_UNICODE_CODEPOINT + 1;
1102
1103 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1104 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1105 # to decrease backtracking.  The first one allows the code point to be at the
1106 # end of a word, but to work properly, the word shouldn't end with a valid hex
1107 # character.  The second one won't match a code point at the end of a word,
1108 # and doesn't have the run-on issue
1109 my $run_on_code_point_re =
1110             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1111 my $code_point_re = qr/\b$run_on_code_point_re/;
1112
1113 # This matches the beginning of the line in the Unicode db files that give the
1114 # defaults for code points not listed (i.e., missing) in the file.  The code
1115 # depends on this ending with a semi-colon, so it can assume it is a valid
1116 # field when the line is split() by semi-colons
1117 my $missing_defaults_prefix =
1118             qr/^#\s+\@missing:\s+0000\.\.$LAST_UNICODE_CODEPOINT_STRING\s*;/;
1119
1120 # Property types.  Unicode has more types, but these are sufficient for our
1121 # purposes.
1122 my $UNKNOWN = -1;   # initialized to illegal value
1123 my $NON_STRING = 1; # Either binary or enum
1124 my $BINARY = 2;
1125 my $ENUM = 3;       # Include catalog
1126 my $STRING = 4;     # Anything else: string or misc
1127
1128 # Some input files have lines that give default values for code points not
1129 # contained in the file.  Sometimes these should be ignored.
1130 my $NO_DEFAULTS = 0;        # Must evaluate to false
1131 my $NOT_IGNORED = 1;
1132 my $IGNORED = 2;
1133
1134 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1135 # and will appear in the main body of the tables in the output files, but
1136 # there are other types of ranges as well, listed below, that are specially
1137 # handled.   There are pseudo-types as well that will never be stored as a
1138 # type, but will affect the calculation of the type.
1139
1140 # 0 is for normal, non-specials
1141 my $MULTI_CP = 1;           # Sequence of more than code point
1142 my $HANGUL_SYLLABLE = 2;
1143 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1144 my $NULL = 4;               # The map is to the null string; utf8.c can't
1145                             # handle these, nor is there an accepted syntax
1146                             # for them in \p{} constructs
1147 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1148                              # otherwise be $MULTI_CP type are instead type 0
1149
1150 # process_generic_property_file() can accept certain overrides in its input.
1151 # Each of these must begin AND end with $CMD_DELIM.
1152 my $CMD_DELIM = "\a";
1153 my $REPLACE_CMD = 'replace';    # Override the Replace
1154 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1155
1156 my $NO = 0;
1157 my $YES = 1;
1158
1159 # Values for the Replace argument to add_range.
1160 # $NO                      # Don't replace; add only the code points not
1161                            # already present.
1162 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1163                            # the comments at the subroutine definition.
1164 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1165 my $MULTIPLE = 4;          # Don't replace, but add a duplicate record if
1166                            # already there
1167 my $CROAK = 5;             # Die with an error if is already there
1168
1169 # Flags to give property statuses.  The phrases are to remind maintainers that
1170 # if the flag is changed, the indefinite article referring to it in the
1171 # documentation may need to be as well.
1172 my $NORMAL = "";
1173 my $SUPPRESSED = 'z';   # The character should never actually be seen, since
1174                         # it is suppressed
1175 my $PLACEHOLDER = 'P';  # Implies no pod entry generated
1176 my $DEPRECATED = 'D';
1177 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1178 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1179 my $DISCOURAGED = 'X';
1180 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1181 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1182 my $STRICTER = 'T';
1183 my $a_bold_stricter = "a 'B<$STRICTER>'";
1184 my $A_bold_stricter = "A 'B<$STRICTER>'";
1185 my $STABILIZED = 'S';
1186 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1187 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1188 my $OBSOLETE = 'O';
1189 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1190 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1191
1192 my %status_past_participles = (
1193     $DISCOURAGED => 'discouraged',
1194     $SUPPRESSED => 'should never be generated',
1195     $STABILIZED => 'stabilized',
1196     $OBSOLETE => 'obsolete',
1197     $DEPRECATED => 'deprecated',
1198 );
1199
1200 # The format of the values of the tables:
1201 my $EMPTY_FORMAT = "";
1202 my $BINARY_FORMAT = 'b';
1203 my $DECIMAL_FORMAT = 'd';
1204 my $FLOAT_FORMAT = 'f';
1205 my $INTEGER_FORMAT = 'i';
1206 my $HEX_FORMAT = 'x';
1207 my $RATIONAL_FORMAT = 'r';
1208 my $STRING_FORMAT = 's';
1209 my $DECOMP_STRING_FORMAT = 'c';
1210
1211 my %map_table_formats = (
1212     $BINARY_FORMAT => 'binary',
1213     $DECIMAL_FORMAT => 'single decimal digit',
1214     $FLOAT_FORMAT => 'floating point number',
1215     $INTEGER_FORMAT => 'integer',
1216     $HEX_FORMAT => 'positive hex whole number; a code point',
1217     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1218     $STRING_FORMAT => 'string',
1219     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1220 );
1221
1222 # Unicode didn't put such derived files in a separate directory at first.
1223 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1224 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1225 my $AUXILIARY = 'auxiliary';
1226
1227 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1228 my %loose_to_file_of;       # loosely maps table names to their respective
1229                             # files
1230 my %stricter_to_file_of;    # same; but for stricter mapping.
1231 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1232                              # their rational equivalent
1233 my %loose_property_name_of; # Loosely maps property names to standard form
1234
1235 # Most properties are immune to caseless matching, otherwise you would get
1236 # nonsensical results, as properties are a function of a code point, not
1237 # everything that is caselessly equivalent to that code point.  For example,
1238 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1239 # be true because 's' and 'S' are equivalent caselessly.  However,
1240 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1241 # extend that concept to those very few properties that are like this.  Each
1242 # such property will match the full range caselessly.  They are hard-coded in
1243 # the program; it's not worth trying to make it general as it's extremely
1244 # unlikely that they will ever change.
1245 my %caseless_equivalent_to;
1246
1247 # These constants names and values were taken from the Unicode standard,
1248 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1249 # syllables.  The '_string' versions are so generated tables can retain the
1250 # hex format, which is the more familiar value
1251 my $SBase_string = "0xAC00";
1252 my $SBase = CORE::hex $SBase_string;
1253 my $LBase_string = "0x1100";
1254 my $LBase = CORE::hex $LBase_string;
1255 my $VBase_string = "0x1161";
1256 my $VBase = CORE::hex $VBase_string;
1257 my $TBase_string = "0x11A7";
1258 my $TBase = CORE::hex $TBase_string;
1259 my $SCount = 11172;
1260 my $LCount = 19;
1261 my $VCount = 21;
1262 my $TCount = 28;
1263 my $NCount = $VCount * $TCount;
1264
1265 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1266 # with the above published constants.
1267 my %Jamo;
1268 my %Jamo_L;     # Leading consonants
1269 my %Jamo_V;     # Vowels
1270 my %Jamo_T;     # Trailing consonants
1271
1272 my @backslash_X_tests;     # List of tests read in for testing \X
1273 my @unhandled_properties;  # Will contain a list of properties found in
1274                            # the input that we didn't process.
1275 my @match_properties;      # Properties that have match tables, to be
1276                            # listed in the pod
1277 my @map_properties;        # Properties that get map files written
1278 my @named_sequences;       # NamedSequences.txt contents.
1279 my %potential_files;       # Generated list of all .txt files in the directory
1280                            # structure so we can warn if something is being
1281                            # ignored.
1282 my @files_actually_output; # List of files we generated.
1283 my @more_Names;            # Some code point names are compound; this is used
1284                            # to store the extra components of them.
1285 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1286                            # the minimum before we consider it equivalent to a
1287                            # candidate rational
1288 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1289
1290 # These store references to certain commonly used property objects
1291 my $gc;
1292 my $perl;
1293 my $block;
1294 my $perl_charname;
1295 my $print;
1296 my $Any;
1297
1298 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1299 my $has_In_conflicts = 0;
1300 my $has_Is_conflicts = 0;
1301
1302 sub internal_file_to_platform ($) {
1303     # Convert our file paths which have '/' separators to those of the
1304     # platform.
1305
1306     my $file = shift;
1307     return undef unless defined $file;
1308
1309     return File::Spec->join(split '/', $file);
1310 }
1311
1312 sub file_exists ($) {   # platform independent '-e'.  This program internally
1313                         # uses slash as a path separator.
1314     my $file = shift;
1315     return 0 if ! defined $file;
1316     return -e internal_file_to_platform($file);
1317 }
1318
1319 sub objaddr($) {
1320     # Returns the address of the blessed input object.
1321     # It doesn't check for blessedness because that would do a string eval
1322     # every call, and the program is structured so that this is never called
1323     # for a non-blessed object.
1324
1325     no overloading; # If overloaded, numifying below won't work.
1326
1327     # Numifying a ref gives its address.
1328     return pack 'J', $_[0];
1329 }
1330
1331 # These are used only if $annotate is true.
1332 # The entire range of Unicode characters is examined to populate these
1333 # after all the input has been processed.  But most can be skipped, as they
1334 # have the same descriptive phrases, such as being unassigned
1335 my @viacode;            # Contains the 1 million character names
1336 my @printable;          # boolean: And are those characters printable?
1337 my @annotate_char_type; # Contains a type of those characters, specifically
1338                         # for the purposes of annotation.
1339 my $annotate_ranges;    # A map of ranges of code points that have the same
1340                         # name for the purposes of annotation.  They map to the
1341                         # upper edge of the range, so that the end point can
1342                         # be immediately found.  This is used to skip ahead to
1343                         # the end of a range, and avoid processing each
1344                         # individual code point in it.
1345 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1346                                    # characters, but excluding those which are
1347                                    # also noncharacter code points
1348
1349 # The annotation types are an extension of the regular range types, though
1350 # some of the latter are folded into one.  Make the new types negative to
1351 # avoid conflicting with the regular types
1352 my $SURROGATE_TYPE = -1;
1353 my $UNASSIGNED_TYPE = -2;
1354 my $PRIVATE_USE_TYPE = -3;
1355 my $NONCHARACTER_TYPE = -4;
1356 my $CONTROL_TYPE = -5;
1357 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1358
1359 sub populate_char_info ($) {
1360     # Used only with the $annotate option.  Populates the arrays with the
1361     # input code point's info that are needed for outputting more detailed
1362     # comments.  If calling context wants a return, it is the end point of
1363     # any contiguous range of characters that share essentially the same info
1364
1365     my $i = shift;
1366     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1367
1368     $viacode[$i] = $perl_charname->value_of($i) || "";
1369
1370     # A character is generally printable if Unicode says it is,
1371     # but below we make sure that most Unicode general category 'C' types
1372     # aren't.
1373     $printable[$i] = $print->contains($i);
1374
1375     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1376
1377     # Only these two regular types are treated specially for annotations
1378     # purposes
1379     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1380                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1381
1382     # Give a generic name to all code points that don't have a real name.
1383     # We output ranges, if applicable, for these.  Also calculate the end
1384     # point of the range.
1385     my $end;
1386     if (! $viacode[$i]) {
1387         if ($gc-> table('Surrogate')->contains($i)) {
1388             $viacode[$i] = 'Surrogate';
1389             $annotate_char_type[$i] = $SURROGATE_TYPE;
1390             $printable[$i] = 0;
1391             $end = $gc->table('Surrogate')->containing_range($i)->end;
1392         }
1393         elsif ($gc-> table('Private_use')->contains($i)) {
1394             $viacode[$i] = 'Private Use';
1395             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1396             $printable[$i] = 0;
1397             $end = $gc->table('Private_Use')->containing_range($i)->end;
1398         }
1399         elsif (Property::property_ref('Noncharacter_Code_Point')-> table('Y')->
1400                                                                 contains($i))
1401         {
1402             $viacode[$i] = 'Noncharacter';
1403             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1404             $printable[$i] = 0;
1405             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1406                                                     containing_range($i)->end;
1407         }
1408         elsif ($gc-> table('Control')->contains($i)) {
1409             $viacode[$i] = 'Control';
1410             $annotate_char_type[$i] = $CONTROL_TYPE;
1411             $printable[$i] = 0;
1412             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1413         }
1414         elsif ($gc-> table('Unassigned')->contains($i)) {
1415             $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1416             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1417             $printable[$i] = 0;
1418
1419             # Because we name the unassigned by the blocks they are in, it
1420             # can't go past the end of that block, and it also can't go past
1421             # the unassigned range it is in.  The special table makes sure
1422             # that the non-characters, which are unassigned, are separated
1423             # out.
1424             $end = min($block->containing_range($i)->end,
1425                        $unassigned_sans_noncharacters-> containing_range($i)->
1426                                                                          end);
1427         }
1428         else {
1429             Carp::my_carp_bug("Can't figure out how to annotate "
1430                               . sprintf("U+%04X", $i)
1431                               . ".  Proceeding anyway.");
1432             $viacode[$i] = 'UNKNOWN';
1433             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1434             $printable[$i] = 0;
1435         }
1436     }
1437
1438     # Here, has a name, but if it's one in which the code point number is
1439     # appended to the name, do that.
1440     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1441         $viacode[$i] .= sprintf("-%04X", $i);
1442         $end = $perl_charname->containing_range($i)->end;
1443     }
1444
1445     # And here, has a name, but if it's a hangul syllable one, replace it with
1446     # the correct name from the Unicode algorithm
1447     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1448         use integer;
1449         my $SIndex = $i - $SBase;
1450         my $L = $LBase + $SIndex / $NCount;
1451         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1452         my $T = $TBase + $SIndex % $TCount;
1453         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1454         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1455         $end = $perl_charname->containing_range($i)->end;
1456     }
1457
1458     return if ! defined wantarray;
1459     return $i if ! defined $end;    # If not a range, return the input
1460
1461     # Save this whole range so can find the end point quickly
1462     $annotate_ranges->add_map($i, $end, $end);
1463
1464     return $end;
1465 }
1466
1467 # Commented code below should work on Perl 5.8.
1468 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1469 ## the native perl version of it (which is what would operate under miniperl)
1470 ## is extremely slow, as it does a string eval every call.
1471 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1472 #                            && defined eval "require Scalar::Util";
1473 #
1474 #sub objaddr($) {
1475 #    # Returns the address of the blessed input object.  Uses the XS version if
1476 #    # available.  It doesn't check for blessedness because that would do a
1477 #    # string eval every call, and the program is structured so that this is
1478 #    # never called for a non-blessed object.
1479 #
1480 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1481 #
1482 #    # Check at least that is a ref.
1483 #    my $pkg = ref($_[0]) or return undef;
1484 #
1485 #    # Change to a fake package to defeat any overloaded stringify
1486 #    bless $_[0], 'main::Fake';
1487 #
1488 #    # Numifying a ref gives its address.
1489 #    my $addr = pack 'J', $_[0];
1490 #
1491 #    # Return to original class
1492 #    bless $_[0], $pkg;
1493 #    return $addr;
1494 #}
1495
1496 sub max ($$) {
1497     my $a = shift;
1498     my $b = shift;
1499     return $a if $a >= $b;
1500     return $b;
1501 }
1502
1503 sub min ($$) {
1504     my $a = shift;
1505     my $b = shift;
1506     return $a if $a <= $b;
1507     return $b;
1508 }
1509
1510 sub clarify_number ($) {
1511     # This returns the input number with underscores inserted every 3 digits
1512     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1513     # checked.
1514
1515     my $number = shift;
1516     my $pos = length($number) - 3;
1517     return $number if $pos <= 1;
1518     while ($pos > 0) {
1519         substr($number, $pos, 0) = '_';
1520         $pos -= 3;
1521     }
1522     return $number;
1523 }
1524
1525
1526 package Carp;
1527
1528 # These routines give a uniform treatment of messages in this program.  They
1529 # are placed in the Carp package to cause the stack trace to not include them,
1530 # although an alternative would be to use another package and set @CARP_NOT
1531 # for it.
1532
1533 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1534
1535 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1536 # and overload trying to load Scalar:Util under miniperl.  See
1537 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1538 undef $overload::VERSION;
1539
1540 sub my_carp {
1541     my $message = shift || "";
1542     my $nofold = shift || 0;
1543
1544     if ($message) {
1545         $message = main::join_lines($message);
1546         $message =~ s/^$0: *//;     # Remove initial program name
1547         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1548         $message = "\n$0: $message;";
1549
1550         # Fold the message with program name, semi-colon end punctuation
1551         # (which looks good with the message that carp appends to it), and a
1552         # hanging indent for continuation lines.
1553         $message = main::simple_fold($message, "", 4) unless $nofold;
1554         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1555                                     # appends is to the same line
1556     }
1557
1558     return $message if defined wantarray;   # If a caller just wants the msg
1559
1560     carp $message;
1561     return;
1562 }
1563
1564 sub my_carp_bug {
1565     # This is called when it is clear that the problem is caused by a bug in
1566     # this program.
1567
1568     my $message = shift;
1569     $message =~ s/^$0: *//;
1570     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1571     carp $message;
1572     return;
1573 }
1574
1575 sub carp_too_few_args {
1576     if (@_ != 2) {
1577         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1578         return;
1579     }
1580
1581     my $args_ref = shift;
1582     my $count = shift;
1583
1584     my_carp_bug("Need at least $count arguments to "
1585         . (caller 1)[3]
1586         . ".  Instead got: '"
1587         . join ', ', @$args_ref
1588         . "'.  No action taken.");
1589     return;
1590 }
1591
1592 sub carp_extra_args {
1593     my $args_ref = shift;
1594     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1595
1596     unless (ref $args_ref) {
1597         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1598         return;
1599     }
1600     my ($package, $file, $line) = caller;
1601     my $subroutine = (caller 1)[3];
1602
1603     my $list;
1604     if (ref $args_ref eq 'HASH') {
1605         foreach my $key (keys %$args_ref) {
1606             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1607         }
1608         $list = join ', ', each %{$args_ref};
1609     }
1610     elsif (ref $args_ref eq 'ARRAY') {
1611         foreach my $arg (@$args_ref) {
1612             $arg = $UNDEF unless defined $arg;
1613         }
1614         $list = join ', ', @$args_ref;
1615     }
1616     else {
1617         my_carp_bug("Can't cope with ref "
1618                 . ref($args_ref)
1619                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1620         return;
1621     }
1622
1623     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1624     return;
1625 }
1626
1627 package main;
1628
1629 { # Closure
1630
1631     # This program uses the inside-out method for objects, as recommended in
1632     # "Perl Best Practices".  This closure aids in generating those.  There
1633     # are two routines.  setup_package() is called once per package to set
1634     # things up, and then set_access() is called for each hash representing a
1635     # field in the object.  These routines arrange for the object to be
1636     # properly destroyed when no longer used, and for standard accessor
1637     # functions to be generated.  If you need more complex accessors, just
1638     # write your own and leave those accesses out of the call to set_access().
1639     # More details below.
1640
1641     my %constructor_fields; # fields that are to be used in constructors; see
1642                             # below
1643
1644     # The values of this hash will be the package names as keys to other
1645     # hashes containing the name of each field in the package as keys, and
1646     # references to their respective hashes as values.
1647     my %package_fields;
1648
1649     sub setup_package {
1650         # Sets up the package, creating standard DESTROY and dump methods
1651         # (unless already defined).  The dump method is used in debugging by
1652         # simple_dumper().
1653         # The optional parameters are:
1654         #   a)  a reference to a hash, that gets populated by later
1655         #       set_access() calls with one of the accesses being
1656         #       'constructor'.  The caller can then refer to this, but it is
1657         #       not otherwise used by these two routines.
1658         #   b)  a reference to a callback routine to call during destruction
1659         #       of the object, before any fields are actually destroyed
1660
1661         my %args = @_;
1662         my $constructor_ref = delete $args{'Constructor_Fields'};
1663         my $destroy_callback = delete $args{'Destroy_Callback'};
1664         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1665
1666         my %fields;
1667         my $package = (caller)[0];
1668
1669         $package_fields{$package} = \%fields;
1670         $constructor_fields{$package} = $constructor_ref;
1671
1672         unless ($package->can('DESTROY')) {
1673             my $destroy_name = "${package}::DESTROY";
1674             no strict "refs";
1675
1676             # Use typeglob to give the anonymous subroutine the name we want
1677             *$destroy_name = sub {
1678                 my $self = shift;
1679                 my $addr = do { no overloading; pack 'J', $self; };
1680
1681                 $self->$destroy_callback if $destroy_callback;
1682                 foreach my $field (keys %{$package_fields{$package}}) {
1683                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1684                     delete $package_fields{$package}{$field}{$addr};
1685                 }
1686                 return;
1687             }
1688         }
1689
1690         unless ($package->can('dump')) {
1691             my $dump_name = "${package}::dump";
1692             no strict "refs";
1693             *$dump_name = sub {
1694                 my $self = shift;
1695                 return dump_inside_out($self, $package_fields{$package}, @_);
1696             }
1697         }
1698         return;
1699     }
1700
1701     sub set_access {
1702         # Arrange for the input field to be garbage collected when no longer
1703         # needed.  Also, creates standard accessor functions for the field
1704         # based on the optional parameters-- none if none of these parameters:
1705         #   'addable'    creates an 'add_NAME()' accessor function.
1706         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1707         #                function.
1708         #   'settable'   creates a 'set_NAME()' accessor function.
1709         #   'constructor' doesn't create an accessor function, but adds the
1710         #                field to the hash that was previously passed to
1711         #                setup_package();
1712         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1713         # 'add' etc. all mean 'addable'.
1714         # The read accessor function will work on both array and scalar
1715         # values.  If another accessor in the parameter list is 'a', the read
1716         # access assumes an array.  You can also force it to be array access
1717         # by specifying 'readable_array' instead of 'readable'
1718         #
1719         # A sort-of 'protected' access can be set-up by preceding the addable,
1720         # readable or settable with some initial portion of 'protected_' (but,
1721         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1722         # "protection" is only by convention.  All that happens is that the
1723         # accessor functions' names begin with an underscore.  So instead of
1724         # calling set_foo, the call is _set_foo.  (Real protection could be
1725         # accomplished by having a new subroutine, end_package, called at the
1726         # end of each package, and then storing the __LINE__ ranges and
1727         # checking them on every accessor.  But that is way overkill.)
1728
1729         # We create anonymous subroutines as the accessors and then use
1730         # typeglobs to assign them to the proper package and name
1731
1732         my $name = shift;   # Name of the field
1733         my $field = shift;  # Reference to the inside-out hash containing the
1734                             # field
1735
1736         my $package = (caller)[0];
1737
1738         if (! exists $package_fields{$package}) {
1739             croak "$0: Must call 'setup_package' before 'set_access'";
1740         }
1741
1742         # Stash the field so DESTROY can get it.
1743         $package_fields{$package}{$name} = $field;
1744
1745         # Remaining arguments are the accessors.  For each...
1746         foreach my $access (@_) {
1747             my $access = lc $access;
1748
1749             my $protected = "";
1750
1751             # Match the input as far as it goes.
1752             if ($access =~ /^(p[^_]*)_/) {
1753                 $protected = $1;
1754                 if (substr('protected_', 0, length $protected)
1755                     eq $protected)
1756                 {
1757
1758                     # Add 1 for the underscore not included in $protected
1759                     $access = substr($access, length($protected) + 1);
1760                     $protected = '_';
1761                 }
1762                 else {
1763                     $protected = "";
1764                 }
1765             }
1766
1767             if (substr('addable', 0, length $access) eq $access) {
1768                 my $subname = "${package}::${protected}add_$name";
1769                 no strict "refs";
1770
1771                 # add_ accessor.  Don't add if already there, which we
1772                 # determine using 'eq' for scalars and '==' otherwise.
1773                 *$subname = sub {
1774                     use strict "refs";
1775                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1776                     my $self = shift;
1777                     my $value = shift;
1778                     my $addr = do { no overloading; pack 'J', $self; };
1779                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1780                     if (ref $value) {
1781                         return if grep { $value == $_ } @{$field->{$addr}};
1782                     }
1783                     else {
1784                         return if grep { $value eq $_ } @{$field->{$addr}};
1785                     }
1786                     push @{$field->{$addr}}, $value;
1787                     return;
1788                 }
1789             }
1790             elsif (substr('constructor', 0, length $access) eq $access) {
1791                 if ($protected) {
1792                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1793                 }
1794                 else {
1795                     $constructor_fields{$package}{$name} = $field;
1796                 }
1797             }
1798             elsif (substr('readable_array', 0, length $access) eq $access) {
1799
1800                 # Here has read access.  If one of the other parameters for
1801                 # access is array, or this one specifies array (by being more
1802                 # than just 'readable_'), then create a subroutine that
1803                 # assumes the data is an array.  Otherwise just a scalar
1804                 my $subname = "${package}::${protected}$name";
1805                 if (grep { /^a/i } @_
1806                     or length($access) > length('readable_'))
1807                 {
1808                     no strict "refs";
1809                     *$subname = sub {
1810                         use strict "refs";
1811                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1812                         my $addr = do { no overloading; pack 'J', $_[0]; };
1813                         if (ref $field->{$addr} ne 'ARRAY') {
1814                             my $type = ref $field->{$addr};
1815                             $type = 'scalar' unless $type;
1816                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1817                             return;
1818                         }
1819                         return scalar @{$field->{$addr}} unless wantarray;
1820
1821                         # Make a copy; had problems with caller modifying the
1822                         # original otherwise
1823                         my @return = @{$field->{$addr}};
1824                         return @return;
1825                     }
1826                 }
1827                 else {
1828
1829                     # Here not an array value, a simpler function.
1830                     no strict "refs";
1831                     *$subname = sub {
1832                         use strict "refs";
1833                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1834                         no overloading;
1835                         return $field->{pack 'J', $_[0]};
1836                     }
1837                 }
1838             }
1839             elsif (substr('settable', 0, length $access) eq $access) {
1840                 my $subname = "${package}::${protected}set_$name";
1841                 no strict "refs";
1842                 *$subname = sub {
1843                     use strict "refs";
1844                     if (main::DEBUG) {
1845                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1846                         Carp::carp_extra_args(\@_) if @_ > 2;
1847                     }
1848                     # $self is $_[0]; $value is $_[1]
1849                     no overloading;
1850                     $field->{pack 'J', $_[0]} = $_[1];
1851                     return;
1852                 }
1853             }
1854             else {
1855                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1856             }
1857         }
1858         return;
1859     }
1860 }
1861
1862 package Input_file;
1863
1864 # All input files use this object, which stores various attributes about them,
1865 # and provides for convenient, uniform handling.  The run method wraps the
1866 # processing.  It handles all the bookkeeping of opening, reading, and closing
1867 # the file, returning only significant input lines.
1868 #
1869 # Each object gets a handler which processes the body of the file, and is
1870 # called by run().  Most should use the generic, default handler, which has
1871 # code scrubbed to handle things you might not expect.  A handler should
1872 # basically be a while(next_line()) {...} loop.
1873 #
1874 # You can also set up handlers to
1875 #   1) call before the first line is read for pre processing
1876 #   2) call to adjust each line of the input before the main handler gets them
1877 #   3) call upon EOF before the main handler exits its loop
1878 #   4) call at the end for post processing
1879 #
1880 # $_ is used to store the input line, and is to be filtered by the
1881 # each_line_handler()s.  So, if the format of the line is not in the desired
1882 # format for the main handler, these are used to do that adjusting.  They can
1883 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1884 # so the $_ output of one is used as the input to the next.  None of the other
1885 # handlers are stackable, but could easily be changed to be so.
1886 #
1887 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1888 # which insert the parameters as lines to be processed before the next input
1889 # file line is read.  This allows the EOF handler to flush buffers, for
1890 # example.  The difference between the two routines is that the lines inserted
1891 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1892 # called it from such a handler, you would get infinite recursion.)  Lines
1893 # inserted by insert_adjusted_lines() go directly to the main handler without
1894 # any adjustments.  If the  post-processing handler calls any of these, there
1895 # will be no effect.  Some error checking for these conditions could be added,
1896 # but it hasn't been done.
1897 #
1898 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1899 # to prevent further processing of the line.  This routine will output the
1900 # message as a warning once, and then keep a count of the lines that have the
1901 # same message, and output that count at the end of the file's processing.
1902 # This keeps the number of messages down to a manageable amount.
1903 #
1904 # get_missings() should be called to retrieve any @missing input lines.
1905 # Messages will be raised if this isn't done if the options aren't to ignore
1906 # missings.
1907
1908 sub trace { return main::trace(@_); }
1909
1910 { # Closure
1911     # Keep track of fields that are to be put into the constructor.
1912     my %constructor_fields;
1913
1914     main::setup_package(Constructor_Fields => \%constructor_fields);
1915
1916     my %file; # Input file name, required
1917     main::set_access('file', \%file, qw{ c r });
1918
1919     my %first_released; # Unicode version file was first released in, required
1920     main::set_access('first_released', \%first_released, qw{ c r });
1921
1922     my %handler;    # Subroutine to process the input file, defaults to
1923                     # 'process_generic_property_file'
1924     main::set_access('handler', \%handler, qw{ c });
1925
1926     my %property;
1927     # name of property this file is for.  defaults to none, meaning not
1928     # applicable, or is otherwise determinable, for example, from each line.
1929     main::set_access('property', \%property, qw{ c });
1930
1931     my %optional;
1932     # If this is true, the file is optional.  If not present, no warning is
1933     # output.  If it is present, the string given by this parameter is
1934     # evaluated, and if false the file is not processed.
1935     main::set_access('optional', \%optional, 'c', 'r');
1936
1937     my %non_skip;
1938     # This is used for debugging, to skip processing of all but a few input
1939     # files.  Add 'non_skip => 1' to the constructor for those files you want
1940     # processed when you set the $debug_skip global.
1941     main::set_access('non_skip', \%non_skip, 'c');
1942
1943     my %skip;
1944     # This is used to skip processing of this input file semi-permanently.
1945     # It is used for files that we aren't planning to process anytime soon,
1946     # but want to allow to be in the directory and not raise a message that we
1947     # are not handling.  Mostly for test files.  This is in contrast to the
1948     # non_skip element, which is supposed to be used very temporarily for
1949     # debugging.  Sets 'optional' to 1
1950     main::set_access('skip', \%skip, 'c');
1951
1952     my %each_line_handler;
1953     # list of subroutines to look at and filter each non-comment line in the
1954     # file.  defaults to none.  The subroutines are called in order, each is
1955     # to adjust $_ for the next one, and the final one adjusts it for
1956     # 'handler'
1957     main::set_access('each_line_handler', \%each_line_handler, 'c');
1958
1959     my %has_missings_defaults;
1960     # ? Are there lines in the file giving default values for code points
1961     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
1962     # the norm, but IGNORED means it has such lines, but the handler doesn't
1963     # use them.  Having these three states allows us to catch changes to the
1964     # UCD that this program should track
1965     main::set_access('has_missings_defaults',
1966                                         \%has_missings_defaults, qw{ c r });
1967
1968     my %pre_handler;
1969     # Subroutine to call before doing anything else in the file.  If undef, no
1970     # such handler is called.
1971     main::set_access('pre_handler', \%pre_handler, qw{ c });
1972
1973     my %eof_handler;
1974     # Subroutine to call upon getting an EOF on the input file, but before
1975     # that is returned to the main handler.  This is to allow buffers to be
1976     # flushed.  The handler is expected to call insert_lines() or
1977     # insert_adjusted() with the buffered material
1978     main::set_access('eof_handler', \%eof_handler, qw{ c r });
1979
1980     my %post_handler;
1981     # Subroutine to call after all the lines of the file are read in and
1982     # processed.  If undef, no such handler is called.
1983     main::set_access('post_handler', \%post_handler, qw{ c });
1984
1985     my %progress_message;
1986     # Message to print to display progress in lieu of the standard one
1987     main::set_access('progress_message', \%progress_message, qw{ c });
1988
1989     my %handle;
1990     # cache open file handle, internal.  Is undef if file hasn't been
1991     # processed at all, empty if has;
1992     main::set_access('handle', \%handle);
1993
1994     my %added_lines;
1995     # cache of lines added virtually to the file, internal
1996     main::set_access('added_lines', \%added_lines);
1997
1998     my %errors;
1999     # cache of errors found, internal
2000     main::set_access('errors', \%errors);
2001
2002     my %missings;
2003     # storage of '@missing' defaults lines
2004     main::set_access('missings', \%missings);
2005
2006     sub new {
2007         my $class = shift;
2008
2009         my $self = bless \do{ my $anonymous_scalar }, $class;
2010         my $addr = do { no overloading; pack 'J', $self; };
2011
2012         # Set defaults
2013         $handler{$addr} = \&main::process_generic_property_file;
2014         $non_skip{$addr} = 0;
2015         $skip{$addr} = 0;
2016         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2017         $handle{$addr} = undef;
2018         $added_lines{$addr} = [ ];
2019         $each_line_handler{$addr} = [ ];
2020         $errors{$addr} = { };
2021         $missings{$addr} = [ ];
2022
2023         # Two positional parameters.
2024         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2025         $file{$addr} = main::internal_file_to_platform(shift);
2026         $first_released{$addr} = shift;
2027
2028         # The rest of the arguments are key => value pairs
2029         # %constructor_fields has been set up earlier to list all possible
2030         # ones.  Either set or push, depending on how the default has been set
2031         # up just above.
2032         my %args = @_;
2033         foreach my $key (keys %args) {
2034             my $argument = $args{$key};
2035
2036             # Note that the fields are the lower case of the constructor keys
2037             my $hash = $constructor_fields{lc $key};
2038             if (! defined $hash) {
2039                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2040                 next;
2041             }
2042             if (ref $hash->{$addr} eq 'ARRAY') {
2043                 if (ref $argument eq 'ARRAY') {
2044                     foreach my $argument (@{$argument}) {
2045                         next if ! defined $argument;
2046                         push @{$hash->{$addr}}, $argument;
2047                     }
2048                 }
2049                 else {
2050                     push @{$hash->{$addr}}, $argument if defined $argument;
2051                 }
2052             }
2053             else {
2054                 $hash->{$addr} = $argument;
2055             }
2056             delete $args{$key};
2057         };
2058
2059         # If the file has a property for it, it means that the property is not
2060         # listed in the file's entries.  So add a handler to the list of line
2061         # handlers to insert the property name into the lines, to provide a
2062         # uniform interface to the final processing subroutine.
2063         # the final code doesn't have to worry about that.
2064         if ($property{$addr}) {
2065             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2066         }
2067
2068         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2069             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2070         }
2071
2072         $optional{$addr} = 1 if $skip{$addr};
2073
2074         return $self;
2075     }
2076
2077
2078     use overload
2079         fallback => 0,
2080         qw("") => "_operator_stringify",
2081         "." => \&main::_operator_dot,
2082     ;
2083
2084     sub _operator_stringify {
2085         my $self = shift;
2086
2087         return __PACKAGE__ . " object for " . $self->file;
2088     }
2089
2090     # flag to make sure extracted files are processed early
2091     my $seen_non_extracted_non_age = 0;
2092
2093     sub run {
2094         # Process the input object $self.  This opens and closes the file and
2095         # calls all the handlers for it.  Currently,  this can only be called
2096         # once per file, as it destroy's the EOF handler
2097
2098         my $self = shift;
2099         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2100
2101         my $addr = do { no overloading; pack 'J', $self; };
2102
2103         my $file = $file{$addr};
2104
2105         # Don't process if not expecting this file (because released later
2106         # than this Unicode version), and isn't there.  This means if someone
2107         # copies it into an earlier version's directory, we will go ahead and
2108         # process it.
2109         return if $first_released{$addr} gt $v_version && ! -e $file;
2110
2111         # If in debugging mode and this file doesn't have the non-skip
2112         # flag set, and isn't one of the critical files, skip it.
2113         if ($debug_skip
2114             && $first_released{$addr} ne v0
2115             && ! $non_skip{$addr})
2116         {
2117             print "Skipping $file in debugging\n" if $verbosity;
2118             return;
2119         }
2120
2121         # File could be optional
2122         if ($optional{$addr}) {
2123             return unless -e $file;
2124             my $result = eval $optional{$addr};
2125             if (! defined $result) {
2126                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2127                 return;
2128             }
2129             if (! $result) {
2130                 if ($verbosity) {
2131                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2132                 }
2133                 return;
2134             }
2135         }
2136
2137         if (! defined $file || ! -e $file) {
2138
2139             # If the file doesn't exist, see if have internal data for it
2140             # (based on first_released being 0).
2141             if ($first_released{$addr} eq v0) {
2142                 $handle{$addr} = 'pretend_is_open';
2143             }
2144             else {
2145                 if (! $optional{$addr}  # File could be optional
2146                     && $v_version ge $first_released{$addr})
2147                 {
2148                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2149                 }
2150                 return;
2151             }
2152         }
2153         else {
2154
2155             # Here, the file exists.  Some platforms may change the case of
2156             # its name
2157             if ($seen_non_extracted_non_age) {
2158                 if ($file =~ /$EXTRACTED/i) {
2159                     Carp::my_carp_bug(join_lines(<<END
2160 $file should be processed just after the 'Prop...Alias' files, and before
2161 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2162 have subtle problems
2163 END
2164                     ));
2165                 }
2166             }
2167             elsif ($EXTRACTED_DIR
2168                     && $first_released{$addr} ne v0
2169                     && $file !~ /$EXTRACTED/i
2170                     && lc($file) ne 'dage.txt')
2171             {
2172                 # We don't set this (by the 'if' above) if we have no
2173                 # extracted directory, so if running on an early version,
2174                 # this test won't work.  Not worth worrying about.
2175                 $seen_non_extracted_non_age = 1;
2176             }
2177
2178             # And mark the file as having being processed, and warn if it
2179             # isn't a file we are expecting.  As we process the files,
2180             # they are deleted from the hash, so any that remain at the
2181             # end of the program are files that we didn't process.
2182             my $fkey = File::Spec->rel2abs($file);
2183             my $expecting = delete $potential_files{$fkey};
2184             $expecting = delete $potential_files{lc($fkey)} unless defined $expecting;
2185             Carp::my_carp("Was not expecting '$file'.") if
2186                     ! $expecting
2187                     && ! defined $handle{$addr};
2188
2189             # Having deleted from expected files, we can quit if not to do
2190             # anything.  Don't print progress unless really want verbosity
2191             if ($skip{$addr}) {
2192                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2193                 return;
2194             }
2195
2196             # Open the file, converting the slashes used in this program
2197             # into the proper form for the OS
2198             my $file_handle;
2199             if (not open $file_handle, "<", $file) {
2200                 Carp::my_carp("Can't open $file.  Skipping: $!");
2201                 return 0;
2202             }
2203             $handle{$addr} = $file_handle; # Cache the open file handle
2204         }
2205
2206         if ($verbosity >= $PROGRESS) {
2207             if ($progress_message{$addr}) {
2208                 print "$progress_message{$addr}\n";
2209             }
2210             else {
2211                 # If using a virtual file, say so.
2212                 print "Processing ", (-e $file)
2213                                        ? $file
2214                                        : "substitute $file",
2215                                      "\n";
2216             }
2217         }
2218
2219
2220         # Call any special handler for before the file.
2221         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2222
2223         # Then the main handler
2224         &{$handler{$addr}}($self);
2225
2226         # Then any special post-file handler.
2227         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2228
2229         # If any errors have been accumulated, output the counts (as the first
2230         # error message in each class was output when it was encountered).
2231         if ($errors{$addr}) {
2232             my $total = 0;
2233             my $types = 0;
2234             foreach my $error (keys %{$errors{$addr}}) {
2235                 $total += $errors{$addr}->{$error};
2236                 delete $errors{$addr}->{$error};
2237                 $types++;
2238             }
2239             if ($total > 1) {
2240                 my $message
2241                         = "A total of $total lines had errors in $file.  ";
2242
2243                 $message .= ($types == 1)
2244                             ? '(Only the first one was displayed.)'
2245                             : '(Only the first of each type was displayed.)';
2246                 Carp::my_carp($message);
2247             }
2248         }
2249
2250         if (@{$missings{$addr}}) {
2251             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2252         }
2253
2254         # If a real file handle, close it.
2255         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2256                                                         ref $handle{$addr};
2257         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2258                                # the file, as opposed to undef
2259         return;
2260     }
2261
2262     sub next_line {
2263         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2264         # if such a line exists.  'logical' means that any lines that have
2265         # been added via insert_lines() will be returned in $_ before the file
2266         # is read again.
2267
2268         my $self = shift;
2269         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2270
2271         my $addr = do { no overloading; pack 'J', $self; };
2272
2273         # Here the file is open (or if the handle is not a ref, is an open
2274         # 'virtual' file).  Get the next line; any inserted lines get priority
2275         # over the file itself.
2276         my $adjusted;
2277
2278         LINE:
2279         while (1) { # Loop until find non-comment, non-empty line
2280             #local $to_trace = 1 if main::DEBUG;
2281             my $inserted_ref = shift @{$added_lines{$addr}};
2282             if (defined $inserted_ref) {
2283                 ($adjusted, $_) = @{$inserted_ref};
2284                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2285                 return 1 if $adjusted;
2286             }
2287             else {
2288                 last if ! ref $handle{$addr}; # Don't read unless is real file
2289                 last if ! defined ($_ = readline $handle{$addr});
2290             }
2291             chomp;
2292             trace $_ if main::DEBUG && $to_trace;
2293
2294             # See if this line is the comment line that defines what property
2295             # value that code points that are not listed in the file should
2296             # have.  The format or existence of these lines is not guaranteed
2297             # by Unicode since they are comments, but the documentation says
2298             # that this was added for machine-readability, so probably won't
2299             # change.  This works starting in Unicode Version 5.0.  They look
2300             # like:
2301             #
2302             # @missing: 0000..10FFFF; Not_Reordered
2303             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2304             # @missing: 0000..10FFFF; ; NaN
2305             #
2306             # Save the line for a later get_missings() call.
2307             if (/$missing_defaults_prefix/) {
2308                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2309                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2310                 }
2311                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2312                     my @defaults = split /\s* ; \s*/x, $_;
2313
2314                     # The first field is the @missing, which ends in a
2315                     # semi-colon, so can safely shift.
2316                     shift @defaults;
2317
2318                     # Some of these lines may have empty field placeholders
2319                     # which get in the way.  An example is:
2320                     # @missing: 0000..10FFFF; ; NaN
2321                     # Remove them.  Process starting from the top so the
2322                     # splice doesn't affect things still to be looked at.
2323                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2324                         next if $defaults[$i] ne "";
2325                         splice @defaults, $i, 1;
2326                     }
2327
2328                     # What's left should be just the property (maybe) and the
2329                     # default.  Having only one element means it doesn't have
2330                     # the property.
2331                     my $default;
2332                     my $property;
2333                     if (@defaults >= 1) {
2334                         if (@defaults == 1) {
2335                             $default = $defaults[0];
2336                         }
2337                         else {
2338                             $property = $defaults[0];
2339                             $default = $defaults[1];
2340                         }
2341                     }
2342
2343                     if (@defaults < 1
2344                         || @defaults > 2
2345                         || ($default =~ /^</
2346                             && $default !~ /^<code *point>$/i
2347                             && $default !~ /^<none>$/i))
2348                     {
2349                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2350                     }
2351                     else {
2352
2353                         # If the property is missing from the line, it should
2354                         # be the one for the whole file
2355                         $property = $property{$addr} if ! defined $property;
2356
2357                         # Change <none> to the null string, which is what it
2358                         # really means.  If the default is the code point
2359                         # itself, set it to <code point>, which is what
2360                         # Unicode uses (but sometimes they've forgotten the
2361                         # space)
2362                         if ($default =~ /^<none>$/i) {
2363                             $default = "";
2364                         }
2365                         elsif ($default =~ /^<code *point>$/i) {
2366                             $default = $CODE_POINT;
2367                         }
2368
2369                         # Store them as a sub-arrays with both components.
2370                         push @{$missings{$addr}}, [ $default, $property ];
2371                     }
2372                 }
2373
2374                 # There is nothing for the caller to process on this comment
2375                 # line.
2376                 next;
2377             }
2378
2379             # Remove comments and trailing space, and skip this line if the
2380             # result is empty
2381             s/#.*//;
2382             s/\s+$//;
2383             next if /^$/;
2384
2385             # Call any handlers for this line, and skip further processing of
2386             # the line if the handler sets the line to null.
2387             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2388                 &{$sub_ref}($self);
2389                 next LINE if /^$/;
2390             }
2391
2392             # Here the line is ok.  return success.
2393             return 1;
2394         } # End of looping through lines.
2395
2396         # If there is an EOF handler, call it (only once) and if it generates
2397         # more lines to process go back in the loop to handle them.
2398         if ($eof_handler{$addr}) {
2399             &{$eof_handler{$addr}}($self);
2400             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2401             goto LINE if $added_lines{$addr};
2402         }
2403
2404         # Return failure -- no more lines.
2405         return 0;
2406
2407     }
2408
2409 #   Not currently used, not fully tested.
2410 #    sub peek {
2411 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2412 #        # record.  Not callable from an each_line_handler(), nor does it call
2413 #        # an each_line_handler() on the line.
2414 #
2415 #        my $self = shift;
2416 #        my $addr = do { no overloading; pack 'J', $self; };
2417 #
2418 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2419 #            my ($adjusted, $line) = @{$inserted_ref};
2420 #            next if $adjusted;
2421 #
2422 #            # Remove comments and trailing space, and return a non-empty
2423 #            # resulting line
2424 #            $line =~ s/#.*//;
2425 #            $line =~ s/\s+$//;
2426 #            return $line if $line ne "";
2427 #        }
2428 #
2429 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2430 #        while (1) { # Loop until find non-comment, non-empty line
2431 #            local $to_trace = 1 if main::DEBUG;
2432 #            trace $_ if main::DEBUG && $to_trace;
2433 #            return if ! defined (my $line = readline $handle{$addr});
2434 #            chomp $line;
2435 #            push @{$added_lines{$addr}}, [ 0, $line ];
2436 #
2437 #            $line =~ s/#.*//;
2438 #            $line =~ s/\s+$//;
2439 #            return $line if $line ne "";
2440 #        }
2441 #
2442 #        return;
2443 #    }
2444
2445
2446     sub insert_lines {
2447         # Lines can be inserted so that it looks like they were in the input
2448         # file at the place it was when this routine is called.  See also
2449         # insert_adjusted_lines().  Lines inserted via this routine go through
2450         # any each_line_handler()
2451
2452         my $self = shift;
2453
2454         # Each inserted line is an array, with the first element being 0 to
2455         # indicate that this line hasn't been adjusted, and needs to be
2456         # processed.
2457         no overloading;
2458         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2459         return;
2460     }
2461
2462     sub insert_adjusted_lines {
2463         # Lines can be inserted so that it looks like they were in the input
2464         # file at the place it was when this routine is called.  See also
2465         # insert_lines().  Lines inserted via this routine are already fully
2466         # adjusted, ready to be processed; each_line_handler()s handlers will
2467         # not be called.  This means this is not a completely general
2468         # facility, as only the last each_line_handler on the stack should
2469         # call this.  It could be made more general, by passing to each of the
2470         # line_handlers their position on the stack, which they would pass on
2471         # to this routine, and that would replace the boolean first element in
2472         # the anonymous array pushed here, so that the next_line routine could
2473         # use that to call only those handlers whose index is after it on the
2474         # stack.  But this is overkill for what is needed now.
2475
2476         my $self = shift;
2477         trace $_[0] if main::DEBUG && $to_trace;
2478
2479         # Each inserted line is an array, with the first element being 1 to
2480         # indicate that this line has been adjusted
2481         no overloading;
2482         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2483         return;
2484     }
2485
2486     sub get_missings {
2487         # Returns the stored up @missings lines' values, and clears the list.
2488         # The values are in an array, consisting of the default in the first
2489         # element, and the property in the 2nd.  However, since these lines
2490         # can be stacked up, the return is an array of all these arrays.
2491
2492         my $self = shift;
2493         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2494
2495         my $addr = do { no overloading; pack 'J', $self; };
2496
2497         # If not accepting a list return, just return the first one.
2498         return shift @{$missings{$addr}} unless wantarray;
2499
2500         my @return = @{$missings{$addr}};
2501         undef @{$missings{$addr}};
2502         return @return;
2503     }
2504
2505     sub _insert_property_into_line {
2506         # Add a property field to $_, if this file requires it.
2507
2508         my $self = shift;
2509         my $addr = do { no overloading; pack 'J', $self; };
2510         my $property = $property{$addr};
2511         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2512
2513         $_ =~ s/(;|$)/; $property$1/;
2514         return;
2515     }
2516
2517     sub carp_bad_line {
2518         # Output consistent error messages, using either a generic one, or the
2519         # one given by the optional parameter.  To avoid gazillions of the
2520         # same message in case the syntax of a  file is way off, this routine
2521         # only outputs the first instance of each message, incrementing a
2522         # count so the totals can be output at the end of the file.
2523
2524         my $self = shift;
2525         my $message = shift;
2526         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2527
2528         my $addr = do { no overloading; pack 'J', $self; };
2529
2530         $message = 'Unexpected line' unless $message;
2531
2532         # No trailing punctuation so as to fit with our addenda.
2533         $message =~ s/[.:;,]$//;
2534
2535         # If haven't seen this exact message before, output it now.  Otherwise
2536         # increment the count of how many times it has occurred
2537         unless ($errors{$addr}->{$message}) {
2538             Carp::my_carp("$message in '$_' in "
2539                             . $file{$addr}
2540                             . " at line $..  Skipping this line;");
2541             $errors{$addr}->{$message} = 1;
2542         }
2543         else {
2544             $errors{$addr}->{$message}++;
2545         }
2546
2547         # Clear the line to prevent any further (meaningful) processing of it.
2548         $_ = "";
2549
2550         return;
2551     }
2552 } # End closure
2553
2554 package Multi_Default;
2555
2556 # Certain properties in early versions of Unicode had more than one possible
2557 # default for code points missing from the files.  In these cases, one
2558 # default applies to everything left over after all the others are applied,
2559 # and for each of the others, there is a description of which class of code
2560 # points applies to it.  This object helps implement this by storing the
2561 # defaults, and for all but that final default, an eval string that generates
2562 # the class that it applies to.
2563
2564
2565 {   # Closure
2566
2567     main::setup_package();
2568
2569     my %class_defaults;
2570     # The defaults structure for the classes
2571     main::set_access('class_defaults', \%class_defaults);
2572
2573     my %other_default;
2574     # The default that applies to everything left over.
2575     main::set_access('other_default', \%other_default, 'r');
2576
2577
2578     sub new {
2579         # The constructor is called with default => eval pairs, terminated by
2580         # the left-over default. e.g.
2581         # Multi_Default->new(
2582         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2583         #               -  0x200D',
2584         #        'R' => 'some other expression that evaluates to code points',
2585         #        .
2586         #        .
2587         #        .
2588         #        'U'));
2589
2590         my $class = shift;
2591
2592         my $self = bless \do{my $anonymous_scalar}, $class;
2593         my $addr = do { no overloading; pack 'J', $self; };
2594
2595         while (@_ > 1) {
2596             my $default = shift;
2597             my $eval = shift;
2598             $class_defaults{$addr}->{$default} = $eval;
2599         }
2600
2601         $other_default{$addr} = shift;
2602
2603         return $self;
2604     }
2605
2606     sub get_next_defaults {
2607         # Iterates and returns the next class of defaults.
2608         my $self = shift;
2609         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2610
2611         my $addr = do { no overloading; pack 'J', $self; };
2612
2613         return each %{$class_defaults{$addr}};
2614     }
2615 }
2616
2617 package Alias;
2618
2619 # An alias is one of the names that a table goes by.  This class defines them
2620 # including some attributes.  Everything is currently setup in the
2621 # constructor.
2622
2623
2624 {   # Closure
2625
2626     main::setup_package();
2627
2628     my %name;
2629     main::set_access('name', \%name, 'r');
2630
2631     my %loose_match;
2632     # Determined by the constructor code if this name should match loosely or
2633     # not.  The constructor parameters can override this, but it isn't fully
2634     # implemented, as should have ability to override Unicode one's via
2635     # something like a set_loose_match()
2636     main::set_access('loose_match', \%loose_match, 'r');
2637
2638     my %make_pod_entry;
2639     # Some aliases should not get their own entries because they are covered
2640     # by a wild-card, and some we want to discourage use of.  Binary
2641     main::set_access('make_pod_entry', \%make_pod_entry, 'r');
2642
2643     my %status;
2644     # Aliases have a status, like deprecated, or even suppressed (which means
2645     # they don't appear in documentation).  Enum
2646     main::set_access('status', \%status, 'r');
2647
2648     my %externally_ok;
2649     # Similarly, some aliases should not be considered as usable ones for
2650     # external use, such as file names, or we don't want documentation to
2651     # recommend them.  Boolean
2652     main::set_access('externally_ok', \%externally_ok, 'r');
2653
2654     sub new {
2655         my $class = shift;
2656
2657         my $self = bless \do { my $anonymous_scalar }, $class;
2658         my $addr = do { no overloading; pack 'J', $self; };
2659
2660         $name{$addr} = shift;
2661         $loose_match{$addr} = shift;
2662         $make_pod_entry{$addr} = shift;
2663         $externally_ok{$addr} = shift;
2664         $status{$addr} = shift;
2665
2666         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2667
2668         # Null names are never ok externally
2669         $externally_ok{$addr} = 0 if $name{$addr} eq "";
2670
2671         return $self;
2672     }
2673 }
2674
2675 package Range;
2676
2677 # A range is the basic unit for storing code points, and is described in the
2678 # comments at the beginning of the program.  Each range has a starting code
2679 # point; an ending code point (not less than the starting one); a value
2680 # that applies to every code point in between the two end-points, inclusive;
2681 # and an enum type that applies to the value.  The type is for the user's
2682 # convenience, and has no meaning here, except that a non-zero type is
2683 # considered to not obey the normal Unicode rules for having standard forms.
2684 #
2685 # The same structure is used for both map and match tables, even though in the
2686 # latter, the value (and hence type) is irrelevant and could be used as a
2687 # comment.  In map tables, the value is what all the code points in the range
2688 # map to.  Type 0 values have the standardized version of the value stored as
2689 # well, so as to not have to recalculate it a lot.
2690
2691 sub trace { return main::trace(@_); }
2692
2693 {   # Closure
2694
2695     main::setup_package();
2696
2697     my %start;
2698     main::set_access('start', \%start, 'r', 's');
2699
2700     my %end;
2701     main::set_access('end', \%end, 'r', 's');
2702
2703     my %value;
2704     main::set_access('value', \%value, 'r');
2705
2706     my %type;
2707     main::set_access('type', \%type, 'r');
2708
2709     my %standard_form;
2710     # The value in internal standard form.  Defined only if the type is 0.
2711     main::set_access('standard_form', \%standard_form);
2712
2713     # Note that if these fields change, the dump() method should as well
2714
2715     sub new {
2716         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2717         my $class = shift;
2718
2719         my $self = bless \do { my $anonymous_scalar }, $class;
2720         my $addr = do { no overloading; pack 'J', $self; };
2721
2722         $start{$addr} = shift;
2723         $end{$addr} = shift;
2724
2725         my %args = @_;
2726
2727         my $value = delete $args{'Value'};  # Can be 0
2728         $value = "" unless defined $value;
2729         $value{$addr} = $value;
2730
2731         $type{$addr} = delete $args{'Type'} || 0;
2732
2733         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2734
2735         if (! $type{$addr}) {
2736             $standard_form{$addr} = main::standardize($value);
2737         }
2738
2739         return $self;
2740     }
2741
2742     use overload
2743         fallback => 0,
2744         qw("") => "_operator_stringify",
2745         "." => \&main::_operator_dot,
2746     ;
2747
2748     sub _operator_stringify {
2749         my $self = shift;
2750         my $addr = do { no overloading; pack 'J', $self; };
2751
2752         # Output it like '0041..0065 (value)'
2753         my $return = sprintf("%04X", $start{$addr})
2754                         .  '..'
2755                         . sprintf("%04X", $end{$addr});
2756         my $value = $value{$addr};
2757         my $type = $type{$addr};
2758         $return .= ' (';
2759         $return .= "$value";
2760         $return .= ", Type=$type" if $type != 0;
2761         $return .= ')';
2762
2763         return $return;
2764     }
2765
2766     sub standard_form {
2767         # The standard form is the value itself if the standard form is
2768         # undefined (that is if the value is special)
2769
2770         my $self = shift;
2771         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2772
2773         my $addr = do { no overloading; pack 'J', $self; };
2774
2775         return $standard_form{$addr} if defined $standard_form{$addr};
2776         return $value{$addr};
2777     }
2778
2779     sub dump {
2780         # Human, not machine readable.  For machine readable, comment out this
2781         # entire routine and let the standard one take effect.
2782         my $self = shift;
2783         my $indent = shift;
2784         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2785
2786         my $addr = do { no overloading; pack 'J', $self; };
2787
2788         my $return = $indent
2789                     . sprintf("%04X", $start{$addr})
2790                     . '..'
2791                     . sprintf("%04X", $end{$addr})
2792                     . " '$value{$addr}';";
2793         if (! defined $standard_form{$addr}) {
2794             $return .= "(type=$type{$addr})";
2795         }
2796         elsif ($standard_form{$addr} ne $value{$addr}) {
2797             $return .= "(standard '$standard_form{$addr}')";
2798         }
2799         return $return;
2800     }
2801 } # End closure
2802
2803 package _Range_List_Base;
2804
2805 # Base class for range lists.  A range list is simply an ordered list of
2806 # ranges, so that the ranges with the lowest starting numbers are first in it.
2807 #
2808 # When a new range is added that is adjacent to an existing range that has the
2809 # same value and type, it merges with it to form a larger range.
2810 #
2811 # Ranges generally do not overlap, except that there can be multiple entries
2812 # of single code point ranges.  This is because of NameAliases.txt.
2813 #
2814 # In this program, there is a standard value such that if two different
2815 # values, have the same standard value, they are considered equivalent.  This
2816 # value was chosen so that it gives correct results on Unicode data
2817
2818 # There are a number of methods to manipulate range lists, and some operators
2819 # are overloaded to handle them.
2820
2821 sub trace { return main::trace(@_); }
2822
2823 { # Closure
2824
2825     our $addr;
2826
2827     main::setup_package();
2828
2829     my %ranges;
2830     # The list of ranges
2831     main::set_access('ranges', \%ranges, 'readable_array');
2832
2833     my %max;
2834     # The highest code point in the list.  This was originally a method, but
2835     # actual measurements said it was used a lot.
2836     main::set_access('max', \%max, 'r');
2837
2838     my %each_range_iterator;
2839     # Iterator position for each_range()
2840     main::set_access('each_range_iterator', \%each_range_iterator);
2841
2842     my %owner_name_of;
2843     # Name of parent this is attached to, if any.  Solely for better error
2844     # messages.
2845     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2846
2847     my %_search_ranges_cache;
2848     # A cache of the previous result from _search_ranges(), for better
2849     # performance
2850     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2851
2852     sub new {
2853         my $class = shift;
2854         my %args = @_;
2855
2856         # Optional initialization data for the range list.
2857         my $initialize = delete $args{'Initialize'};
2858
2859         my $self;
2860
2861         # Use _union() to initialize.  _union() returns an object of this
2862         # class, which means that it will call this constructor recursively.
2863         # But it won't have this $initialize parameter so that it won't
2864         # infinitely loop on this.
2865         return _union($class, $initialize, %args) if defined $initialize;
2866
2867         $self = bless \do { my $anonymous_scalar }, $class;
2868         my $addr = do { no overloading; pack 'J', $self; };
2869
2870         # Optional parent object, only for debug info.
2871         $owner_name_of{$addr} = delete $args{'Owner'};
2872         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2873
2874         # Stringify, in case it is an object.
2875         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2876
2877         # This is used only for error messages, and so a colon is added
2878         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2879
2880         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2881
2882         # Max is initialized to a negative value that isn't adjacent to 0,
2883         # for simpler tests
2884         $max{$addr} = -2;
2885
2886         $_search_ranges_cache{$addr} = 0;
2887         $ranges{$addr} = [];
2888
2889         return $self;
2890     }
2891
2892     use overload
2893         fallback => 0,
2894         qw("") => "_operator_stringify",
2895         "." => \&main::_operator_dot,
2896     ;
2897
2898     sub _operator_stringify {
2899         my $self = shift;
2900         my $addr = do { no overloading; pack 'J', $self; };
2901
2902         return "Range_List attached to '$owner_name_of{$addr}'"
2903                                                 if $owner_name_of{$addr};
2904         return "anonymous Range_List " . \$self;
2905     }
2906
2907     sub _union {
2908         # Returns the union of the input code points.  It can be called as
2909         # either a constructor or a method.  If called as a method, the result
2910         # will be a new() instance of the calling object, containing the union
2911         # of that object with the other parameter's code points;  if called as
2912         # a constructor, the first parameter gives the class the new object
2913         # should be, and the second parameter gives the code points to go into
2914         # it.
2915         # In either case, there are two parameters looked at by this routine;
2916         # any additional parameters are passed to the new() constructor.
2917         #
2918         # The code points can come in the form of some object that contains
2919         # ranges, and has a conventionally named method to access them; or
2920         # they can be an array of individual code points (as integers); or
2921         # just a single code point.
2922         #
2923         # If they are ranges, this routine doesn't make any effort to preserve
2924         # the range values of one input over the other.  Therefore this base
2925         # class should not allow _union to be called from other than
2926         # initialization code, so as to prevent two tables from being added
2927         # together where the range values matter.  The general form of this
2928         # routine therefore belongs in a derived class, but it was moved here
2929         # to avoid duplication of code.  The failure to overload this in this
2930         # class keeps it safe.
2931         #
2932
2933         my $self;
2934         my @args;   # Arguments to pass to the constructor
2935
2936         my $class = shift;
2937
2938         # If a method call, will start the union with the object itself, and
2939         # the class of the new object will be the same as self.
2940         if (ref $class) {
2941             $self = $class;
2942             $class = ref $self;
2943             push @args, $self;
2944         }
2945
2946         # Add the other required parameter.
2947         push @args, shift;
2948         # Rest of parameters are passed on to the constructor
2949
2950         # Accumulate all records from both lists.
2951         my @records;
2952         for my $arg (@args) {
2953             #local $to_trace = 0 if main::DEBUG;
2954             trace "argument = $arg" if main::DEBUG && $to_trace;
2955             if (! defined $arg) {
2956                 my $message = "";
2957                 if (defined $self) {
2958                     no overloading;
2959                     $message .= $owner_name_of{pack 'J', $self};
2960                 }
2961                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
2962                 return;
2963             }
2964             $arg = [ $arg ] if ! ref $arg;
2965             my $type = ref $arg;
2966             if ($type eq 'ARRAY') {
2967                 foreach my $element (@$arg) {
2968                     push @records, Range->new($element, $element);
2969                 }
2970             }
2971             elsif ($arg->isa('Range')) {
2972                 push @records, $arg;
2973             }
2974             elsif ($arg->can('ranges')) {
2975                 push @records, $arg->ranges;
2976             }
2977             else {
2978                 my $message = "";
2979                 if (defined $self) {
2980                     no overloading;
2981                     $message .= $owner_name_of{pack 'J', $self};
2982                 }
2983                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
2984                 return;
2985             }
2986         }
2987
2988         # Sort with the range containing the lowest ordinal first, but if
2989         # two ranges start at the same code point, sort with the bigger range
2990         # of the two first, because it takes fewer cycles.
2991         @records = sort { ($a->start <=> $b->start)
2992                                       or
2993                                     # if b is shorter than a, b->end will be
2994                                     # less than a->end, and we want to select
2995                                     # a, so want to return -1
2996                                     ($b->end <=> $a->end)
2997                                    } @records;
2998
2999         my $new = $class->new(@_);
3000
3001         # Fold in records so long as they add new information.
3002         for my $set (@records) {
3003             my $start = $set->start;
3004             my $end   = $set->end;
3005             my $value   = $set->value;
3006             if ($start > $new->max) {
3007                 $new->_add_delete('+', $start, $end, $value);
3008             }
3009             elsif ($end > $new->max) {
3010                 $new->_add_delete('+', $new->max +1, $end, $value);
3011             }
3012         }
3013
3014         return $new;
3015     }
3016
3017     sub range_count {        # Return the number of ranges in the range list
3018         my $self = shift;
3019         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3020
3021         no overloading;
3022         return scalar @{$ranges{pack 'J', $self}};
3023     }
3024
3025     sub min {
3026         # Returns the minimum code point currently in the range list, or if
3027         # the range list is empty, 2 beyond the max possible.  This is a
3028         # method because used so rarely, that not worth saving between calls,
3029         # and having to worry about changing it as ranges are added and
3030         # deleted.
3031
3032         my $self = shift;
3033         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3034
3035         my $addr = do { no overloading; pack 'J', $self; };
3036
3037         # If the range list is empty, return a large value that isn't adjacent
3038         # to any that could be in the range list, for simpler tests
3039         return $LAST_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3040         return $ranges{$addr}->[0]->start;
3041     }
3042
3043     sub contains {
3044         # Boolean: Is argument in the range list?  If so returns $i such that:
3045         #   range[$i]->end < $codepoint <= range[$i+1]->end
3046         # which is one beyond what you want; this is so that the 0th range
3047         # doesn't return false
3048         my $self = shift;
3049         my $codepoint = shift;
3050         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3051
3052         my $i = $self->_search_ranges($codepoint);
3053         return 0 unless defined $i;
3054
3055         # The search returns $i, such that
3056         #   range[$i-1]->end < $codepoint <= range[$i]->end
3057         # So is in the table if and only iff it is at least the start position
3058         # of range $i.
3059         no overloading;
3060         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3061         return $i + 1;
3062     }
3063
3064     sub containing_range {
3065         # Returns the range object that contains the code point, undef if none
3066
3067         my $self = shift;
3068         my $codepoint = shift;
3069         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3070
3071         my $i = $self->contains($codepoint);
3072         return unless $i;
3073
3074         # contains() returns 1 beyond where we should look
3075         no overloading;
3076         return $ranges{pack 'J', $self}->[$i-1];
3077     }
3078
3079     sub value_of {
3080         # Returns the value associated with the code point, undef if none
3081
3082         my $self = shift;
3083         my $codepoint = shift;
3084         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3085
3086         my $range = $self->containing_range($codepoint);
3087         return unless defined $range;
3088
3089         return $range->value;
3090     }
3091
3092     sub type_of {
3093         # Returns the type of the range containing the code point, undef if
3094         # the code point is not in the table
3095
3096         my $self = shift;
3097         my $codepoint = shift;
3098         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3099
3100         my $range = $self->containing_range($codepoint);
3101         return unless defined $range;
3102
3103         return $range->type;
3104     }
3105
3106     sub _search_ranges {
3107         # Find the range in the list which contains a code point, or where it
3108         # should go if were to add it.  That is, it returns $i, such that:
3109         #   range[$i-1]->end < $codepoint <= range[$i]->end
3110         # Returns undef if no such $i is possible (e.g. at end of table), or
3111         # if there is an error.
3112
3113         my $self = shift;
3114         my $code_point = shift;
3115         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3116
3117         my $addr = do { no overloading; pack 'J', $self; };
3118
3119         return if $code_point > $max{$addr};
3120         my $r = $ranges{$addr};                # The current list of ranges
3121         my $range_list_size = scalar @$r;
3122         my $i;
3123
3124         use integer;        # want integer division
3125
3126         # Use the cached result as the starting guess for this one, because,
3127         # an experiment on 5.1 showed that 90% of the time the cache was the
3128         # same as the result on the next call (and 7% it was one less).
3129         $i = $_search_ranges_cache{$addr};
3130         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3131                                             # from an intervening deletion
3132         #local $to_trace = 1 if main::DEBUG;
3133         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3134         return $i if $code_point <= $r->[$i]->end
3135                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3136
3137         # Here the cache doesn't yield the correct $i.  Try adding 1.
3138         if ($i < $range_list_size - 1
3139             && $r->[$i]->end < $code_point &&
3140             $code_point <= $r->[$i+1]->end)
3141         {
3142             $i++;
3143             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3144             $_search_ranges_cache{$addr} = $i;
3145             return $i;
3146         }
3147
3148         # Here, adding 1 also didn't work.  We do a binary search to
3149         # find the correct position, starting with current $i
3150         my $lower = 0;
3151         my $upper = $range_list_size - 1;
3152         while (1) {
3153             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3154
3155             if ($code_point <= $r->[$i]->end) {
3156
3157                 # Here we have met the upper constraint.  We can quit if we
3158                 # also meet the lower one.
3159                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3160
3161                 $upper = $i;        # Still too high.
3162
3163             }
3164             else {
3165
3166                 # Here, $r[$i]->end < $code_point, so look higher up.
3167                 $lower = $i;
3168             }
3169
3170             # Split search domain in half to try again.
3171             my $temp = ($upper + $lower) / 2;
3172
3173             # No point in continuing unless $i changes for next time
3174             # in the loop.
3175             if ($temp == $i) {
3176
3177                 # We can't reach the highest element because of the averaging.
3178                 # So if one below the upper edge, force it there and try one
3179                 # more time.
3180                 if ($i == $range_list_size - 2) {
3181
3182                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3183                     $i = $range_list_size - 1;
3184
3185                     # Change $lower as well so if fails next time through,
3186                     # taking the average will yield the same $i, and we will
3187                     # quit with the error message just below.
3188                     $lower = $i;
3189                     next;
3190                 }
3191                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3192                 return;
3193             }
3194             $i = $temp;
3195         } # End of while loop
3196
3197         if (main::DEBUG && $to_trace) {
3198             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3199             trace "i=  [ $i ]", $r->[$i];
3200             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3201         }
3202
3203         # Here we have found the offset.  Cache it as a starting point for the
3204         # next call.
3205         $_search_ranges_cache{$addr} = $i;
3206         return $i;
3207     }
3208
3209     sub _add_delete {
3210         # Add, replace or delete ranges to or from a list.  The $type
3211         # parameter gives which:
3212         #   '+' => insert or replace a range, returning a list of any changed
3213         #          ranges.
3214         #   '-' => delete a range, returning a list of any deleted ranges.
3215         #
3216         # The next three parameters give respectively the start, end, and
3217         # value associated with the range.  'value' should be null unless the
3218         # operation is '+';
3219         #
3220         # The range list is kept sorted so that the range with the lowest
3221         # starting position is first in the list, and generally, adjacent
3222         # ranges with the same values are merged into a single larger one (see
3223         # exceptions below).
3224         #
3225         # There are more parameters; all are key => value pairs:
3226         #   Type    gives the type of the value.  It is only valid for '+'.
3227         #           All ranges have types; if this parameter is omitted, 0 is
3228         #           assumed.  Ranges with type 0 are assumed to obey the
3229         #           Unicode rules for casing, etc; ranges with other types are
3230         #           not.  Otherwise, the type is arbitrary, for the caller's
3231         #           convenience, and looked at only by this routine to keep
3232         #           adjacent ranges of different types from being merged into
3233         #           a single larger range, and when Replace =>
3234         #           $IF_NOT_EQUIVALENT is specified (see just below).
3235         #   Replace  determines what to do if the range list already contains
3236         #            ranges which coincide with all or portions of the input
3237         #            range.  It is only valid for '+':
3238         #       => $NO            means that the new value is not to replace
3239         #                         any existing ones, but any empty gaps of the
3240         #                         range list coinciding with the input range
3241         #                         will be filled in with the new value.
3242         #       => $UNCONDITIONALLY  means to replace the existing values with
3243         #                         this one unconditionally.  However, if the
3244         #                         new and old values are identical, the
3245         #                         replacement is skipped to save cycles
3246         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3247         #                         with this one if they are not equivalent.
3248         #                         Ranges are equivalent if their types are the
3249         #                         same, and they are the same string; or if
3250         #                         both are type 0 ranges, if their Unicode
3251         #                         standard forms are identical.  In this last
3252         #                         case, the routine chooses the more "modern"
3253         #                         one to use.  This is because some of the
3254         #                         older files are formatted with values that
3255         #                         are, for example, ALL CAPs, whereas the
3256         #                         derived files have a more modern style,
3257         #                         which looks better.  By looking for this
3258         #                         style when the pre-existing and replacement
3259         #                         standard forms are the same, we can move to
3260         #                         the modern style
3261         #       => $MULTIPLE      means that if this range duplicates an
3262         #                         existing one, but has a different value,
3263         #                         don't replace the existing one, but insert
3264         #                         this, one so that the same range can occur
3265         #                         multiple times.  They are stored LIFO, so
3266         #                         that the final one inserted is the first one
3267         #                         returned in an ordered search of the table.
3268         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3269         #
3270         # "same value" means identical for non-type-0 ranges, and it means
3271         # having the same standard forms for type-0 ranges.
3272
3273         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3274
3275         my $self = shift;
3276         my $operation = shift;   # '+' for add/replace; '-' for delete;
3277         my $start = shift;
3278         my $end   = shift;
3279         my $value = shift;
3280
3281         my %args = @_;
3282
3283         $value = "" if not defined $value;        # warning: $value can be "0"
3284
3285         my $replace = delete $args{'Replace'};
3286         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3287
3288         my $type = delete $args{'Type'};
3289         $type = 0 unless defined $type;
3290
3291         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3292
3293         my $addr = do { no overloading; pack 'J', $self; };
3294
3295         if ($operation ne '+' && $operation ne '-') {
3296             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3297             return;
3298         }
3299         unless (defined $start && defined $end) {
3300             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3301             return;
3302         }
3303         unless ($end >= $start) {
3304             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3305             return;
3306         }
3307         #local $to_trace = 1 if main::DEBUG;
3308
3309         if ($operation eq '-') {
3310             if ($replace != $IF_NOT_EQUIVALENT) {
3311                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3312                 $replace = $IF_NOT_EQUIVALENT;
3313             }
3314             if ($type) {
3315                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3316                 $type = 0;
3317             }
3318             if ($value ne "") {
3319                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3320                 $value = "";
3321             }
3322         }
3323
3324         my $r = $ranges{$addr};               # The current list of ranges
3325         my $range_list_size = scalar @$r;     # And its size
3326         my $max = $max{$addr};                # The current high code point in
3327                                               # the list of ranges
3328
3329         # Do a special case requiring fewer machine cycles when the new range
3330         # starts after the current highest point.  The Unicode input data is
3331         # structured so this is common.
3332         if ($start > $max) {
3333
3334             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3335             return if $operation eq '-'; # Deleting a non-existing range is a
3336                                          # no-op
3337
3338             # If the new range doesn't logically extend the current final one
3339             # in the range list, create a new range at the end of the range
3340             # list.  (max cleverly is initialized to a negative number not
3341             # adjacent to 0 if the range list is empty, so even adding a range
3342             # to an empty range list starting at 0 will have this 'if'
3343             # succeed.)
3344             if ($start > $max + 1        # non-adjacent means can't extend.
3345                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3346                 || @{$r}[-1]->type != $type # types differ, can't extend.
3347             ) {
3348                 push @$r, Range->new($start, $end,
3349                                      Value => $value,
3350                                      Type => $type);
3351             }
3352             else {
3353
3354                 # Here, the new range starts just after the current highest in
3355                 # the range list, and they have the same type and value.
3356                 # Extend the current range to incorporate the new one.
3357                 @{$r}[-1]->set_end($end);
3358             }
3359
3360             # This becomes the new maximum.
3361             $max{$addr} = $end;
3362
3363             return;
3364         }
3365         #local $to_trace = 0 if main::DEBUG;
3366
3367         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3368
3369         # Here, the input range isn't after the whole rest of the range list.
3370         # Most likely 'splice' will be needed.  The rest of the routine finds
3371         # the needed splice parameters, and if necessary, does the splice.
3372         # First, find the offset parameter needed by the splice function for
3373         # the input range.  Note that the input range may span multiple
3374         # existing ones, but we'll worry about that later.  For now, just find
3375         # the beginning.  If the input range is to be inserted starting in a
3376         # position not currently in the range list, it must (obviously) come
3377         # just after the range below it, and just before the range above it.
3378         # Slightly less obviously, it will occupy the position currently
3379         # occupied by the range that is to come after it.  More formally, we
3380         # are looking for the position, $i, in the array of ranges, such that:
3381         #
3382         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3383         #
3384         # (The ordered relationships within existing ranges are also shown in
3385         # the equation above).  However, if the start of the input range is
3386         # within an existing range, the splice offset should point to that
3387         # existing range's position in the list; that is $i satisfies a
3388         # somewhat different equation, namely:
3389         #
3390         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3391         #
3392         # More briefly, $start can come before or after r[$i]->start, and at
3393         # this point, we don't know which it will be.  However, these
3394         # two equations share these constraints:
3395         #
3396         #   r[$i-1]->end < $start <= r[$i]->end
3397         #
3398         # And that is good enough to find $i.
3399
3400         my $i = $self->_search_ranges($start);
3401         if (! defined $i) {
3402             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3403             return;
3404         }
3405
3406         # The search function returns $i such that:
3407         #
3408         # r[$i-1]->end < $start <= r[$i]->end
3409         #
3410         # That means that $i points to the first range in the range list
3411         # that could possibly be affected by this operation.  We still don't
3412         # know if the start of the input range is within r[$i], or if it
3413         # points to empty space between r[$i-1] and r[$i].
3414         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3415
3416         # Special case the insertion of data that is not to replace any
3417         # existing data.
3418         if ($replace == $NO) {  # If $NO, has to be operation '+'
3419             #local $to_trace = 1 if main::DEBUG;
3420             trace "Doesn't replace" if main::DEBUG && $to_trace;
3421
3422             # Here, the new range is to take effect only on those code points
3423             # that aren't already in an existing range.  This can be done by
3424             # looking through the existing range list and finding the gaps in
3425             # the ranges that this new range affects, and then calling this
3426             # function recursively on each of those gaps, leaving untouched
3427             # anything already in the list.  Gather up a list of the changed
3428             # gaps first so that changes to the internal state as new ranges
3429             # are added won't be a problem.
3430             my @gap_list;
3431
3432             # First, if the starting point of the input range is outside an
3433             # existing one, there is a gap from there to the beginning of the
3434             # existing range -- add a span to fill the part that this new
3435             # range occupies
3436             if ($start < $r->[$i]->start) {
3437                 push @gap_list, Range->new($start,
3438                                            main::min($end,
3439                                                      $r->[$i]->start - 1),
3440                                            Type => $type);
3441                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3442             }
3443
3444             # Then look through the range list for other gaps until we reach
3445             # the highest range affected by the input one.
3446             my $j;
3447             for ($j = $i+1; $j < $range_list_size; $j++) {
3448                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3449                 last if $end < $r->[$j]->start;
3450
3451                 # If there is a gap between when this range starts and the
3452                 # previous one ends, add a span to fill it.  Note that just
3453                 # because there are two ranges doesn't mean there is a
3454                 # non-zero gap between them.  It could be that they have
3455                 # different values or types
3456                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3457                     push @gap_list,
3458                         Range->new($r->[$j-1]->end + 1,
3459                                    $r->[$j]->start - 1,
3460                                    Type => $type);
3461                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3462                 }
3463             }
3464
3465             # Here, we have either found an existing range in the range list,
3466             # beyond the area affected by the input one, or we fell off the
3467             # end of the loop because the input range affects the whole rest
3468             # of the range list.  In either case, $j is 1 higher than the
3469             # highest affected range.  If $j == $i, it means that there are no
3470             # affected ranges, that the entire insertion is in the gap between
3471             # r[$i-1], and r[$i], which we already have taken care of before
3472             # the loop.
3473             # On the other hand, if there are affected ranges, it might be
3474             # that there is a gap that needs filling after the final such
3475             # range to the end of the input range
3476             if ($r->[$j-1]->end < $end) {
3477                     push @gap_list, Range->new(main::max($start,
3478                                                          $r->[$j-1]->end + 1),
3479                                                $end,
3480                                                Type => $type);
3481                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3482             }
3483
3484             # Call recursively to fill in all the gaps.
3485             foreach my $gap (@gap_list) {
3486                 $self->_add_delete($operation,
3487                                    $gap->start,
3488                                    $gap->end,
3489                                    $value,
3490                                    Type => $type);
3491             }
3492
3493             return;
3494         }
3495
3496         # Here, we have taken care of the case where $replace is $NO.
3497         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3498         # If inserting a multiple record, this is where it goes, before the
3499         # first (if any) existing one.  This implies an insertion, and no
3500         # change to any existing ranges.  Note that $i can be -1 if this new
3501         # range doesn't actually duplicate any existing, and comes at the
3502         # beginning of the list.
3503         if ($replace == $MULTIPLE) {
3504
3505             if ($start != $end) {
3506                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3507                 return;
3508             }
3509
3510             # Don't add an exact duplicate, as it isn't really a multiple
3511             if ($end >= $r->[$i]->start) {
3512                 if ($r->[$i]->start != $r->[$i]->end) {
3513                     Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the other range ($r->[$i]) contains more than one code point.  No action taken.");
3514                     return;
3515                 }
3516                 return if $value eq $r->[$i]->value && $type eq $r->[$i]->type;
3517             }
3518
3519             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3520             my @return = splice @$r,
3521                                 $i,
3522                                 0,
3523                                 Range->new($start,
3524                                            $end,
3525                                            Value => $value,
3526                                            Type => $type);
3527             if (main::DEBUG && $to_trace) {
3528                 trace "After splice:";
3529                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3530                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3531                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3532                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3533                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3534                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3535             }
3536             return @return;
3537         }
3538
3539         # Here, we have taken care of $NO and $MULTIPLE replaces.  This leaves
3540         # delete, insert, and replace either unconditionally or if not
3541         # equivalent.  $i still points to the first potential affected range.
3542         # Now find the highest range affected, which will determine the length
3543         # parameter to splice.  (The input range can span multiple existing
3544         # ones.)  If this isn't a deletion, while we are looking through the
3545         # range list, see also if this is a replacement rather than a clean
3546         # insertion; that is if it will change the values of at least one
3547         # existing range.  Start off assuming it is an insert, until find it
3548         # isn't.
3549         my $clean_insert = $operation eq '+';
3550         my $j;        # This will point to the highest affected range
3551
3552         # For non-zero types, the standard form is the value itself;
3553         my $standard_form = ($type) ? $value : main::standardize($value);
3554
3555         for ($j = $i; $j < $range_list_size; $j++) {
3556             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3557
3558             # If find a range that it doesn't overlap into, we can stop
3559             # searching
3560             last if $end < $r->[$j]->start;
3561
3562             # Here, overlaps the range at $j.  If the values don't match,
3563             # and so far we think this is a clean insertion, it becomes a
3564             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3565             if ($clean_insert) {
3566                 if ($r->[$j]->standard_form ne $standard_form) {
3567                     $clean_insert = 0;
3568                     if ($replace == $CROAK) {
3569                         main::croak("The range to add "
3570                         . sprintf("%04X", $start)
3571                         . '-'
3572                         . sprintf("%04X", $end)
3573                         . " with value '$value' overlaps an existing range $r->[$j]");
3574                     }
3575                 }
3576                 else {
3577
3578                     # Here, the two values are essentially the same.  If the
3579                     # two are actually identical, replacing wouldn't change
3580                     # anything so skip it.
3581                     my $pre_existing = $r->[$j]->value;
3582                     if ($pre_existing ne $value) {
3583
3584                         # Here the new and old standardized values are the
3585                         # same, but the non-standardized values aren't.  If
3586                         # replacing unconditionally, then replace
3587                         if( $replace == $UNCONDITIONALLY) {
3588                             $clean_insert = 0;
3589                         }
3590                         else {
3591
3592                             # Here, are replacing conditionally.  Decide to
3593                             # replace or not based on which appears to look
3594                             # the "nicest".  If one is mixed case and the
3595                             # other isn't, choose the mixed case one.
3596                             my $new_mixed = $value =~ /[A-Z]/
3597                                             && $value =~ /[a-z]/;
3598                             my $old_mixed = $pre_existing =~ /[A-Z]/
3599                                             && $pre_existing =~ /[a-z]/;
3600
3601                             if ($old_mixed != $new_mixed) {
3602                                 $clean_insert = 0 if $new_mixed;
3603                                 if (main::DEBUG && $to_trace) {
3604                                     if ($clean_insert) {
3605                                         trace "Retaining $pre_existing over $value";
3606                                     }
3607                                     else {
3608                                         trace "Replacing $pre_existing with $value";
3609                                     }
3610                                 }
3611                             }
3612                             else {
3613
3614                                 # Here casing wasn't different between the two.
3615                                 # If one has hyphens or underscores and the
3616                                 # other doesn't, choose the one with the
3617                                 # punctuation.
3618                                 my $new_punct = $value =~ /[-_]/;
3619                                 my $old_punct = $pre_existing =~ /[-_]/;
3620
3621                                 if ($old_punct != $new_punct) {
3622                                     $clean_insert = 0 if $new_punct;
3623                                     if (main::DEBUG && $to_trace) {
3624                                         if ($clean_insert) {
3625                                             trace "Retaining $pre_existing over $value";
3626                                         }
3627                                         else {
3628                                             trace "Replacing $pre_existing with $value";
3629                                         }
3630                                     }
3631                                 }   # else existing one is just as "good";
3632                                     # retain it to save cycles.
3633                             }
3634                         }
3635                     }
3636                 }
3637             }
3638         } # End of loop looking for highest affected range.
3639
3640         # Here, $j points to one beyond the highest range that this insertion
3641         # affects (hence to beyond the range list if that range is the final
3642         # one in the range list).
3643
3644         # The splice length is all the affected ranges.  Get it before
3645         # subtracting, for efficiency, so we don't have to later add 1.
3646         my $length = $j - $i;
3647
3648         $j--;        # $j now points to the highest affected range.
3649         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3650
3651         # Here, have taken care of $NO and $MULTIPLE replaces.
3652         # $j points to the highest affected range.  But it can be < $i or even
3653         # -1.  These happen only if the insertion is entirely in the gap
3654         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3655         # above exited first time through with $end < $r->[$i]->start.  (And
3656         # then we subtracted one from j)  This implies also that $start <
3657         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3658         # $start, so the entire input range is in the gap.
3659         if ($j < $i) {
3660
3661             # Here the entire input range is in the gap before $i.
3662
3663             if (main::DEBUG && $to_trace) {
3664                 if ($i) {
3665                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3666                 }
3667                 else {
3668                     trace "Entire range is before $r->[$i]";
3669                 }
3670             }
3671             return if $operation ne '+'; # Deletion of a non-existent range is
3672                                          # a no-op
3673         }
3674         else {
3675
3676             # Here part of the input range is not in the gap before $i.  Thus,
3677             # there is at least one affected one, and $j points to the highest
3678             # such one.
3679
3680             # At this point, here is the situation:
3681             # This is not an insertion of a multiple, nor of tentative ($NO)
3682             # data.
3683             #   $i  points to the first element in the current range list that
3684             #            may be affected by this operation.  In fact, we know
3685             #            that the range at $i is affected because we are in
3686             #            the else branch of this 'if'
3687             #   $j  points to the highest affected range.
3688             # In other words,
3689             #   r[$i-1]->end < $start <= r[$i]->end
3690             # And:
3691             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3692             #
3693             # Also:
3694             #   $clean_insert is a boolean which is set true if and only if
3695             #        this is a "clean insertion", i.e., not a change nor a
3696             #        deletion (multiple was handled above).
3697
3698             # We now have enough information to decide if this call is a no-op
3699             # or not.  It is a no-op if this is an insertion of already
3700             # existing data.
3701
3702             if (main::DEBUG && $to_trace && $clean_insert
3703                                          && $i == $j
3704                                          && $start >= $r->[$i]->start)
3705             {
3706                     trace "no-op";
3707             }
3708             return if $clean_insert
3709                       && $i == $j # more than one affected range => not no-op
3710
3711                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3712                       # Further, $start and/or $end is >= r[$i]->start
3713                       # The test below hence guarantees that
3714                       #     r[$i]->start < $start <= $end <= r[$i]->end
3715                       # This means the input range is contained entirely in
3716                       # the one at $i, so is a no-op
3717                       && $start >= $r->[$i]->start;
3718         }
3719
3720         # Here, we know that some action will have to be taken.  We have
3721         # calculated the offset and length (though adjustments may be needed)
3722         # for the splice.  Now start constructing the replacement list.
3723         my @replacement;
3724         my $splice_start = $i;
3725
3726         my $extends_below;
3727         my $extends_above;
3728
3729         # See if should extend any adjacent ranges.
3730         if ($operation eq '-') { # Don't extend deletions
3731             $extends_below = $extends_above = 0;
3732         }
3733         else {  # Here, should extend any adjacent ranges.  See if there are
3734                 # any.
3735             $extends_below = ($i > 0
3736                             # can't extend unless adjacent
3737                             && $r->[$i-1]->end == $start -1
3738                             # can't extend unless are same standard value
3739                             && $r->[$i-1]->standard_form eq $standard_form
3740                             # can't extend unless share type
3741                             && $r->[$i-1]->type == $type);
3742             $extends_above = ($j+1 < $range_list_size
3743                             && $r->[$j+1]->start == $end +1
3744                             && $r->[$j+1]->standard_form eq $standard_form
3745                             && $r->[$j+1]->type == $type);
3746         }
3747         if ($extends_below && $extends_above) { # Adds to both
3748             $splice_start--;     # start replace at element below
3749             $length += 2;        # will replace on both sides
3750             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3751
3752             # The result will fill in any gap, replacing both sides, and
3753             # create one large range.
3754             @replacement = Range->new($r->[$i-1]->start,
3755                                       $r->[$j+1]->end,
3756                                       Value => $value,
3757                                       Type => $type);
3758         }
3759         else {
3760
3761             # Here we know that the result won't just be the conglomeration of
3762             # a new range with both its adjacent neighbors.  But it could
3763             # extend one of them.
3764
3765             if ($extends_below) {
3766
3767                 # Here the new element adds to the one below, but not to the
3768                 # one above.  If inserting, and only to that one range,  can
3769                 # just change its ending to include the new one.
3770                 if ($length == 0 && $clean_insert) {
3771                     $r->[$i-1]->set_end($end);
3772                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3773                     return;
3774                 }
3775                 else {
3776                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3777                     $splice_start--;        # start replace at element below
3778                     $length++;              # will replace the element below
3779                     $start = $r->[$i-1]->start;
3780                 }
3781             }
3782             elsif ($extends_above) {
3783
3784                 # Here the new element adds to the one above, but not below.
3785                 # Mirror the code above
3786                 if ($length == 0 && $clean_insert) {
3787                     $r->[$j+1]->set_start($start);
3788                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3789                     return;
3790                 }
3791                 else {
3792                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3793                     $length++;        # will replace the element above
3794                     $end = $r->[$j+1]->end;
3795                 }
3796             }
3797
3798             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3799
3800             # Finally, here we know there will have to be a splice.
3801             # If the change or delete affects only the highest portion of the
3802             # first affected range, the range will have to be split.  The
3803             # splice will remove the whole range, but will replace it by a new
3804             # range containing just the unaffected part.  So, in this case,
3805             # add to the replacement list just this unaffected portion.
3806             if (! $extends_below
3807                 && $start > $r->[$i]->start && $start <= $r->[$i]->end)
3808             {
3809                 push @replacement,
3810                     Range->new($r->[$i]->start,
3811                                $start - 1,
3812                                Value => $r->[$i]->value,
3813                                Type => $r->[$i]->type);
3814             }
3815
3816             # In the case of an insert or change, but not a delete, we have to
3817             # put in the new stuff;  this comes next.
3818             if ($operation eq '+') {
3819                 push @replacement, Range->new($start,
3820                                               $end,
3821                                               Value => $value,
3822                                               Type => $type);
3823             }
3824
3825             trace "Range at $j is $r->[$j]" if main::DEBUG && $to_trace && $j != $i;
3826             #trace "$end >=", $r->[$j]->start, " && $end <", $r->[$j]->end if main::DEBUG && $to_trace;
3827
3828             # And finally, if we're changing or deleting only a portion of the
3829             # highest affected range, it must be split, as the lowest one was.
3830             if (! $extends_above
3831                 && $j >= 0  # Remember that j can be -1 if before first
3832                             # current element
3833                 && $end >= $r->[$j]->start
3834                 && $end < $r->[$j]->end)
3835             {
3836                 push @replacement,
3837                     Range->new($end + 1,
3838                                $r->[$j]->end,
3839                                Value => $r->[$j]->value,
3840                                Type => $r->[$j]->type);
3841             }
3842         }
3843
3844         # And do the splice, as calculated above
3845         if (main::DEBUG && $to_trace) {
3846             trace "replacing $length element(s) at $i with ";
3847             foreach my $replacement (@replacement) {
3848                 trace "    $replacement";
3849             }
3850             trace "Before splice:";
3851             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3852             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3853             trace "i  =[", $i, "]", $r->[$i];
3854             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3855             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3856         }
3857
3858         my @return = splice @$r, $splice_start, $length, @replacement;
3859
3860         if (main::DEBUG && $to_trace) {
3861             trace "After splice:";
3862             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3863             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3864             trace "i  =[", $i, "]", $r->[$i];
3865             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3866             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3867             trace "removed ", @return if @return;
3868         }
3869
3870         # An actual deletion could have changed the maximum in the list.
3871         # There was no deletion if the splice didn't return something, but
3872         # otherwise recalculate it.  This is done too rarely to worry about
3873         # performance.
3874         if ($operation eq '-' && @return) {
3875             $max{$addr} = $r->[-1]->end;
3876         }
3877         return @return;
3878     }
3879
3880     sub reset_each_range {  # reset the iterator for each_range();
3881         my $self = shift;
3882         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3883
3884         no overloading;
3885         undef $each_range_iterator{pack 'J', $self};
3886         return;
3887     }
3888
3889     sub each_range {
3890         # Iterate over each range in a range list.  Results are undefined if
3891         # the range list is changed during the iteration.
3892
3893         my $self = shift;
3894         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3895
3896         my $addr = do { no overloading; pack 'J', $self; };
3897
3898         return if $self->is_empty;
3899
3900         $each_range_iterator{$addr} = -1
3901                                 if ! defined $each_range_iterator{$addr};
3902         $each_range_iterator{$addr}++;
3903         return $ranges{$addr}->[$each_range_iterator{$addr}]
3904                         if $each_range_iterator{$addr} < @{$ranges{$addr}};
3905         undef $each_range_iterator{$addr};
3906         return;
3907     }
3908
3909     sub count {        # Returns count of code points in range list
3910         my $self = shift;
3911         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3912
3913         my $addr = do { no overloading; pack 'J', $self; };
3914
3915         my $count = 0;
3916         foreach my $range (@{$ranges{$addr}}) {
3917             $count += $range->end - $range->start + 1;
3918         }
3919         return $count;
3920     }
3921
3922     sub delete_range {    # Delete a range
3923         my $self = shift;
3924         my $start = shift;
3925         my $end = shift;
3926
3927         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3928
3929         return $self->_add_delete('-', $start, $end, "");
3930     }
3931
3932     sub is_empty { # Returns boolean as to if a range list is empty
3933         my $self = shift;
3934         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3935
3936         no overloading;
3937         return scalar @{$ranges{pack 'J', $self}} == 0;
3938     }
3939
3940     sub hash {
3941         # Quickly returns a scalar suitable for separating tables into
3942         # buckets, i.e. it is a hash function of the contents of a table, so
3943         # there are relatively few conflicts.
3944
3945         my $self = shift;
3946         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3947
3948         my $addr = do { no overloading; pack 'J', $self; };
3949
3950         # These are quickly computable.  Return looks like 'min..max;count'
3951         return $self->min . "..$max{$addr};" . scalar @{$ranges{$addr}};
3952     }
3953 } # End closure for _Range_List_Base
3954
3955 package Range_List;
3956 use base '_Range_List_Base';
3957
3958 # A Range_List is a range list for match tables; i.e. the range values are
3959 # not significant.  Thus a number of operations can be safely added to it,
3960 # such as inversion, intersection.  Note that union is also an unsafe
3961 # operation when range values are cared about, and that method is in the base
3962 # class, not here.  But things are set up so that that method is callable only
3963 # during initialization.  Only in this derived class, is there an operation
3964 # that combines two tables.  A Range_Map can thus be used to initialize a
3965 # Range_List, and its mappings will be in the list, but are not significant to
3966 # this class.
3967
3968 sub trace { return main::trace(@_); }
3969
3970 { # Closure
3971
3972     use overload
3973         fallback => 0,
3974         '+' => sub { my $self = shift;
3975                     my $other = shift;
3976
3977                     return $self->_union($other)
3978                 },
3979         '&' => sub { my $self = shift;
3980                     my $other = shift;
3981
3982                     return $self->_intersect($other, 0);
3983                 },
3984         '~' => "_invert",
3985         '-' => "_subtract",
3986     ;
3987
3988     sub _invert {
3989         # Returns a new Range_List that gives all code points not in $self.
3990
3991         my $self = shift;
3992
3993         my $new = Range_List->new;
3994
3995         # Go through each range in the table, finding the gaps between them