This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
828400553947cd99401fca19443dc57d560658dc
[perl5.git] / Porting / bisect.pl
1 #!/usr/bin/perl -w
2 use strict;
3
4 my $start_time = time;
5
6 # The default, auto_abbrev will treat -e as an abbreviation of --end
7 # Which isn't what we want.
8 use Getopt::Long qw(:config pass_through no_auto_abbrev);
9
10 my ($start, $end, $validate);
11 unshift @ARGV, '--help' unless GetOptions('start=s' => \$start,
12                                           'end=s' => \$end,
13                                           validate => \$validate);
14
15 @ARGV = ('--', 'sh', '-c', 'cd t && ./perl TEST base/*.t')
16     if $validate && !@ARGV;
17
18 my $runner = $0;
19 $runner =~ s/bisect\.pl/bisect-runner.pl/;
20
21 die "Can't find bisect runner $runner" unless -f $runner;
22
23 {
24     my ($dev0, $ino0) = stat $0;
25     die "Can't stat $0: $!" unless defined $ino0;
26     my ($dev1, $ino1) = stat 'Porting/bisect.pl';
27     die "Can't run a bisect using the directory containing $runner"
28       if defined $dev1 && $dev0 == $dev1 && $ino0 == $ino1;
29 }
30
31 system $^X, $runner, '--check-args', @ARGV and exit 255;
32
33 # We try these in this order for the start revision if none is specified.
34 my @stable = qw(perl-5.002 perl-5.003 perl-5.004 perl-5.005 perl-5.6.0
35                 perl-5.8.0 v5.10.0 v5.12.0 v5.14.0);
36
37 $end = 'blead' unless defined $end;
38
39 # Canonicalising branches to revisions before moving the checkout permits one
40 # to use revisions such as 'HEAD' for --start or --end
41 foreach ($start, $end) {
42     next unless $_;
43     $_ = `git rev-parse $_`;
44     die unless defined $_;
45     chomp;
46 }
47
48 my $modified = () = `git ls-files --modified --deleted --others`;
49
50 die "This checkout is not clean - $modified modified or untracked file(s)"
51     if $modified;
52
53 sub validate {
54     my $commit = shift;
55     if (defined $start && `git rev-list -n1 $commit ^$start^` eq "") {
56         print "Skipping $commit, as it is earlier than $start\n";
57         return;
58     }
59     if (defined $end && `git rev-list -n1 $end ^$commit^` eq "") {
60         print "Skipping $commit, as it is more recent than $end\n";
61         return;
62     }
63     print "Testing $commit...\n";
64     system "git checkout $commit </dev/null" and die;
65     my $ret = system $^X, $runner, '--no-clean', @ARGV;
66     die "Runner returned $ret, not 0 for revision $commit" if $ret;
67     system 'git clean -dxf </dev/null' and die;
68     system 'git reset --hard HEAD </dev/null' and die;
69     return $commit;
70 }
71
72 if ($validate) {
73     require Text::Wrap;
74     my @built = map {validate $_} 'blead', reverse @stable;
75     if (@built) {
76         print Text::Wrap::wrap("", "", "Successfully validated @built\n");
77         exit 0;
78     }
79     print "Did not validate anything\n";
80     exit 1;
81 }
82
83 my $git_version = `git --version`;
84 if (defined $git_version
85     && $git_version =~ /\Agit version (\d+\.\d+\.\d+)(.*)/) {
86     $git_version = eval "v$1";
87 } else {
88     $git_version = v0.0.0;
89 }
90
91 if ($git_version ge v1.6.6) {
92     system "git bisect reset HEAD" and die;
93 } else {
94     system "git bisect reset" and die;
95 }
96
97 # Sanity check the first and last revisions:
98 system "git checkout $end" and die;
99 my $ret = system $^X, $runner, @ARGV;
100 die "Runner returned $ret for end revision" unless $ret;
101
102 if (defined $start) {
103     system "git checkout $start" and die;
104     my $ret = system $^X, $runner, @ARGV;
105     die "Runner returned $ret, not 0 for start revision" if $ret;
106 } else {
107     # Try to find the earliest version for which the test works
108     foreach my $try (@stable) {
109         system "git checkout $try" and die;
110         my $ret = system $^X, $runner, @ARGV;
111         if (!$ret) {
112             $start = $try;
113             last;
114         }
115     }
116     die "Can't find a suitable start revision to default to. Tried @stable"
117         unless defined $start;
118 }
119
120 system "git bisect start" and die;
121 system "git bisect good $start" and die;
122 system "git bisect bad $end" and die;
123
124 # And now get git bisect to do the hard work:
125 system 'git', 'bisect', 'run', $^X, $runner, @ARGV and die;
126
127 END {
128     my $end_time = time;
129
130     printf "That took %d seconds\n", $end_time - $start_time
131         if defined $start_time;
132 }
133
134 # Local variables:
135 # cperl-indent-level: 4
136 # indent-tabs-mode: nil
137 # End:
138 #
139 # ex: set ts=8 sts=4 sw=4 et: