This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: [perl #40262] kill( 0, ... ) does not return alive status of child process
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, the scalar arguments will
18 be first, and the list argument will follow.  (Note that there can ever
19 be only one such list argument.)  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for the elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use the parentheses, the simple (but occasionally
34 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  And whitespace
37 between the function and left parenthesis doesn't count--so you need to
38 be careful sometimes:
39
40     print 1+2+4;        # Prints 7.
41     print(1+2) + 4;     # Prints 3.
42     print (1+2)+4;      # Also prints 3!
43     print +(1+2)+4;     # Prints 7.
44     print ((1+2)+4);    # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in a scalar context by
59 returning the undefined value, and in a list context by returning the
60 null list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value it would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls
82 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 =head2 Perl Functions by Category
90 X<function>
91
92 Here are Perl's functions (including things that look like
93 functions, like some keywords and named operators)
94 arranged by category.  Some functions appear in more
95 than one place.
96
97 =over 4
98
99 =item Functions for SCALARs or strings
100 X<scalar> X<string> X<character>
101
102 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
103 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
104 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
105
106 =item Regular expressions and pattern matching
107 X<regular expression> X<regex> X<regexp>
108
109 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
110
111 =item Numeric functions
112 X<numeric> X<number> X<trigonometric> X<trigonometry>
113
114 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
115 C<sin>, C<sqrt>, C<srand>
116
117 =item Functions for real @ARRAYs
118 X<array>
119
120 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
121
122 =item Functions for list data
123 X<list>
124
125 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
126
127 =item Functions for real %HASHes
128 X<hash>
129
130 C<delete>, C<each>, C<exists>, C<keys>, C<values>
131
132 =item Input and output functions
133 X<I/O> X<input> X<output> X<dbm>
134
135 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
136 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
137 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
138 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
139 C<warn>, C<write>
140
141 =item Functions for fixed length data or records
142
143 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
144
145 =item Functions for filehandles, files, or directories
146 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
147
148 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
149 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
150 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
151 C<umask>, C<unlink>, C<utime>
152
153 =item Keywords related to the control flow of your Perl program
154 X<control flow>
155
156 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
157 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
158
159 =item Keywords related to switch
160
161 C<break>, C<continue>, C<given>, C<when>, C<default>
162
163 (These are only available if you enable the "switch" feature.
164 See L<feature> and L<perlsyn/"Switch statements">.)
165
166 =item Keywords related to scoping
167
168 C<caller>, C<import>, C<local>, C<my>, C<our>, C<state>, C<package>,
169 C<use>
170
171 (C<state> is only available if the "state" feature is enabled. See
172 L<feature>.)
173
174 =item Miscellaneous functions
175
176 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
177 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
178
179 =item Functions for processes and process groups
180 X<process> X<pid> X<process id>
181
182 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
183 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
184 C<times>, C<wait>, C<waitpid>
185
186 =item Keywords related to perl modules
187 X<module>
188
189 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
190
191 =item Keywords related to classes and object-orientedness
192 X<object> X<class> X<package>
193
194 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
195 C<untie>, C<use>
196
197 =item Low-level socket functions
198 X<socket> X<sock>
199
200 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
201 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
202 C<socket>, C<socketpair>
203
204 =item System V interprocess communication functions
205 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
206
207 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
208 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
209
210 =item Fetching user and group info
211 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
212
213 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
214 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
215 C<getpwuid>, C<setgrent>, C<setpwent>
216
217 =item Fetching network info
218 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
219
220 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
221 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
222 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
223 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
224 C<setnetent>, C<setprotoent>, C<setservent>
225
226 =item Time-related functions
227 X<time> X<date>
228
229 C<gmtime>, C<localtime>, C<time>, C<times>
230
231 =item Functions new in perl5
232 X<perl5>
233
234 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
235 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
236 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr>, C<qw>, C<qx>,
237 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
238 C<ucfirst>, C<untie>, C<use>, C<when>
239
240 * - C<sub> was a keyword in perl4, but in perl5 it is an
241 operator, which can be used in expressions.
242
243 =item Functions obsoleted in perl5
244
245 C<dbmclose>, C<dbmopen>
246
247 =back
248
249 =head2 Portability
250 X<portability> X<Unix> X<portable>
251
252 Perl was born in Unix and can therefore access all common Unix
253 system calls.  In non-Unix environments, the functionality of some
254 Unix system calls may not be available, or details of the available
255 functionality may differ slightly.  The Perl functions affected
256 by this are:
257
258 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
259 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
260 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
261 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
262 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
263 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
264 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
265 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
266 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
267 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
268 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
269 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
270 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
271 C<shmwrite>, C<socket>, C<socketpair>,
272 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
273 C<times>, C<truncate>, C<umask>, C<unlink>,
274 C<utime>, C<wait>, C<waitpid>
275
276 For more information about the portability of these functions, see
277 L<perlport> and other available platform-specific documentation.
278
279 =head2 Alphabetical Listing of Perl Functions
280
281 =over 8
282
283 =item -X FILEHANDLE
284 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
285 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
286
287 =item -X EXPR
288
289 =item -X DIRHANDLE
290
291 =item -X
292
293 A file test, where X is one of the letters listed below.  This unary
294 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
295 and tests the associated file to see if something is true about it.  If the
296 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
297 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
298 the undefined value if the file doesn't exist.  Despite the funny
299 names, precedence is the same as any other named unary operator, and
300 the argument may be parenthesized like any other unary operator.  The
301 operator may be any of:
302
303     -r  File is readable by effective uid/gid.
304     -w  File is writable by effective uid/gid.
305     -x  File is executable by effective uid/gid.
306     -o  File is owned by effective uid.
307
308     -R  File is readable by real uid/gid.
309     -W  File is writable by real uid/gid.
310     -X  File is executable by real uid/gid.
311     -O  File is owned by real uid.
312
313     -e  File exists.
314     -z  File has zero size (is empty).
315     -s  File has nonzero size (returns size in bytes).
316
317     -f  File is a plain file.
318     -d  File is a directory.
319     -l  File is a symbolic link.
320     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
321     -S  File is a socket.
322     -b  File is a block special file.
323     -c  File is a character special file.
324     -t  Filehandle is opened to a tty.
325
326     -u  File has setuid bit set.
327     -g  File has setgid bit set.
328     -k  File has sticky bit set.
329
330     -T  File is an ASCII text file (heuristic guess).
331     -B  File is a "binary" file (opposite of -T).
332
333     -M  Script start time minus file modification time, in days.
334     -A  Same for access time.
335     -C  Same for inode change time (Unix, may differ for other platforms)
336
337 Example:
338
339     while (<>) {
340         chomp;
341         next unless -f $_;      # ignore specials
342         #...
343     }
344
345 The interpretation of the file permission operators C<-r>, C<-R>,
346 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
347 of the file and the uids and gids of the user.  There may be other
348 reasons you can't actually read, write, or execute the file.  Such
349 reasons may be for example network filesystem access controls, ACLs
350 (access control lists), read-only filesystems, and unrecognized
351 executable formats.
352
353 Also note that, for the superuser on the local filesystems, the C<-r>,
354 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
355 if any execute bit is set in the mode.  Scripts run by the superuser
356 may thus need to do a stat() to determine the actual mode of the file,
357 or temporarily set their effective uid to something else.
358
359 If you are using ACLs, there is a pragma called C<filetest> that may
360 produce more accurate results than the bare stat() mode bits.
361 When under the C<use filetest 'access'> the above-mentioned filetests
362 will test whether the permission can (not) be granted using the
363 access() family of system calls.  Also note that the C<-x> and C<-X> may
364 under this pragma return true even if there are no execute permission
365 bits set (nor any extra execute permission ACLs).  This strangeness is
366 due to the underlying system calls' definitions.  Read the
367 documentation for the C<filetest> pragma for more information.
368
369 Note that C<-s/a/b/> does not do a negated substitution.  Saying
370 C<-exp($foo)> still works as expected, however--only single letters
371 following a minus are interpreted as file tests.
372
373 The C<-T> and C<-B> switches work as follows.  The first block or so of the
374 file is examined for odd characters such as strange control codes or
375 characters with the high bit set.  If too many strange characters (>30%)
376 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
377 containing null in the first block is considered a binary file.  If C<-T>
378 or C<-B> is used on a filehandle, the current IO buffer is examined
379 rather than the first block.  Both C<-T> and C<-B> return true on a null
380 file, or a file at EOF when testing a filehandle.  Because you have to
381 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
382 against the file first, as in C<next unless -f $file && -T $file>.
383
384 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
385 the special filehandle consisting of a solitary underline, then the stat
386 structure of the previous file test (or stat operator) is used, saving
387 a system call.  (This doesn't work with C<-t>, and you need to remember
388 that lstat() and C<-l> will leave values in the stat structure for the
389 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
390 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
391 Example:
392
393     print "Can do.\n" if -r $a || -w _ || -x _;
394
395     stat($filename);
396     print "Readable\n" if -r _;
397     print "Writable\n" if -w _;
398     print "Executable\n" if -x _;
399     print "Setuid\n" if -u _;
400     print "Setgid\n" if -g _;
401     print "Sticky\n" if -k _;
402     print "Text\n" if -T _;
403     print "Binary\n" if -B _;
404
405 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
406 test operators, in a way that C<-f -w -x $file> is equivalent to
407 C<-x $file && -w _ && -f _>. (This is only syntax fancy: if you use
408 the return value of C<-f $file> as an argument to another filetest
409 operator, no special magic will happen.)
410
411 =item abs VALUE
412 X<abs> X<absolute>
413
414 =item abs
415
416 Returns the absolute value of its argument.
417 If VALUE is omitted, uses C<$_>.
418
419 =item accept NEWSOCKET,GENERICSOCKET
420 X<accept>
421
422 Accepts an incoming socket connect, just as the accept(2) system call
423 does.  Returns the packed address if it succeeded, false otherwise.
424 See the example in L<perlipc/"Sockets: Client/Server Communication">.
425
426 On systems that support a close-on-exec flag on files, the flag will
427 be set for the newly opened file descriptor, as determined by the
428 value of $^F.  See L<perlvar/$^F>.
429
430 =item alarm SECONDS
431 X<alarm>
432 X<SIGALRM>
433 X<timer>
434
435 =item alarm
436
437 Arranges to have a SIGALRM delivered to this process after the
438 specified number of wallclock seconds has elapsed.  If SECONDS is not
439 specified, the value stored in C<$_> is used. (On some machines,
440 unfortunately, the elapsed time may be up to one second less or more
441 than you specified because of how seconds are counted, and process
442 scheduling may delay the delivery of the signal even further.)
443
444 Only one timer may be counting at once.  Each call disables the
445 previous timer, and an argument of C<0> may be supplied to cancel the
446 previous timer without starting a new one.  The returned value is the
447 amount of time remaining on the previous timer.
448
449 For delays of finer granularity than one second, you may use Perl's
450 four-argument version of select() leaving the first three arguments
451 undefined, or you might be able to use the C<syscall> interface to
452 access setitimer(2) if your system supports it.  The Time::HiRes
453 module (from CPAN, and starting from Perl 5.8 part of the standard
454 distribution) may also prove useful.
455
456 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
457 (C<sleep> may be internally implemented in your system with C<alarm>)
458
459 If you want to use C<alarm> to time out a system call you need to use an
460 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
461 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
462 restart system calls on some systems.  Using C<eval>/C<die> always works,
463 modulo the caveats given in L<perlipc/"Signals">.
464
465     eval {
466         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
467         alarm $timeout;
468         $nread = sysread SOCKET, $buffer, $size;
469         alarm 0;
470     };
471     if ($@) {
472         die unless $@ eq "alarm\n";   # propagate unexpected errors
473         # timed out
474     }
475     else {
476         # didn't
477     }
478
479 For more information see L<perlipc>.
480
481 =item atan2 Y,X
482 X<atan2> X<arctangent> X<tan> X<tangent>
483
484 Returns the arctangent of Y/X in the range -PI to PI.
485
486 For the tangent operation, you may use the C<Math::Trig::tan>
487 function, or use the familiar relation:
488
489     sub tan { sin($_[0]) / cos($_[0])  }
490
491 Note that atan2(0, 0) is not well-defined.
492
493 =item bind SOCKET,NAME
494 X<bind>
495
496 Binds a network address to a socket, just as the bind system call
497 does.  Returns true if it succeeded, false otherwise.  NAME should be a
498 packed address of the appropriate type for the socket.  See the examples in
499 L<perlipc/"Sockets: Client/Server Communication">.
500
501 =item binmode FILEHANDLE, LAYER
502 X<binmode> X<binary> X<text> X<DOS> X<Windows>
503
504 =item binmode FILEHANDLE
505
506 Arranges for FILEHANDLE to be read or written in "binary" or "text"
507 mode on systems where the run-time libraries distinguish between
508 binary and text files.  If FILEHANDLE is an expression, the value is
509 taken as the name of the filehandle.  Returns true on success,
510 otherwise it returns C<undef> and sets C<$!> (errno).
511
512 On some systems (in general, DOS and Windows-based systems) binmode()
513 is necessary when you're not working with a text file.  For the sake
514 of portability it is a good idea to always use it when appropriate,
515 and to never use it when it isn't appropriate.  Also, people can
516 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
517
518 In other words: regardless of platform, use binmode() on binary data,
519 like for example images.
520
521 If LAYER is present it is a single string, but may contain multiple
522 directives. The directives alter the behaviour of the file handle.
523 When LAYER is present using binmode on text file makes sense.
524
525 If LAYER is omitted or specified as C<:raw> the filehandle is made
526 suitable for passing binary data. This includes turning off possible CRLF
527 translation and marking it as bytes (as opposed to Unicode characters).
528 Note that, despite what may be implied in I<"Programming Perl"> (the
529 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
530 -- other layers which would affect binary nature of the stream are
531 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
532 PERLIO environment variable.
533
534 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
535 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
536 establish default I/O layers.  See L<open>.
537
538 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
539 in "Programming Perl, 3rd Edition".  However, since the publishing of this
540 book, by many known as "Camel III", the consensus of the naming of this
541 functionality has moved from "discipline" to "layer".  All documentation
542 of this version of Perl therefore refers to "layers" rather than to
543 "disciplines".  Now back to the regularly scheduled documentation...>
544
545 To mark FILEHANDLE as UTF-8, use C<:utf8>.
546
547 In general, binmode() should be called after open() but before any I/O
548 is done on the filehandle.  Calling binmode() will normally flush any
549 pending buffered output data (and perhaps pending input data) on the
550 handle.  An exception to this is the C<:encoding> layer that
551 changes the default character encoding of the handle, see L<open>.
552 The C<:encoding> layer sometimes needs to be called in
553 mid-stream, and it doesn't flush the stream.  The C<:encoding>
554 also implicitly pushes on top of itself the C<:utf8> layer because
555 internally Perl will operate on UTF-8 encoded Unicode characters.
556
557 The operating system, device drivers, C libraries, and Perl run-time
558 system all work together to let the programmer treat a single
559 character (C<\n>) as the line terminator, irrespective of the external
560 representation.  On many operating systems, the native text file
561 representation matches the internal representation, but on some
562 platforms the external representation of C<\n> is made up of more than
563 one character.
564
565 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
566 character to end each line in the external representation of text (even
567 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
568 on Unix and most VMS files). In other systems like OS/2, DOS and the
569 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
570 but what's stored in text files are the two characters C<\cM\cJ>.  That
571 means that, if you don't use binmode() on these systems, C<\cM\cJ>
572 sequences on disk will be converted to C<\n> on input, and any C<\n> in
573 your program will be converted back to C<\cM\cJ> on output.  This is what
574 you want for text files, but it can be disastrous for binary files.
575
576 Another consequence of using binmode() (on some systems) is that
577 special end-of-file markers will be seen as part of the data stream.
578 For systems from the Microsoft family this means that if your binary
579 data contains C<\cZ>, the I/O subsystem will regard it as the end of
580 the file, unless you use binmode().
581
582 binmode() is not only important for readline() and print() operations,
583 but also when using read(), seek(), sysread(), syswrite() and tell()
584 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
585 in L<perlvar> for how to manually set your input and output
586 line-termination sequences.
587
588 =item bless REF,CLASSNAME
589 X<bless>
590
591 =item bless REF
592
593 This function tells the thingy referenced by REF that it is now an object
594 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
595 is used.  Because a C<bless> is often the last thing in a constructor,
596 it returns the reference for convenience.  Always use the two-argument
597 version if a derived class might inherit the function doing the blessing.
598 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
599 of objects.
600
601 Consider always blessing objects in CLASSNAMEs that are mixed case.
602 Namespaces with all lowercase names are considered reserved for
603 Perl pragmata.  Builtin types have all uppercase names. To prevent
604 confusion, you may wish to avoid such package names as well.  Make sure
605 that CLASSNAME is a true value.
606
607 See L<perlmod/"Perl Modules">.
608
609 =item break
610
611 Break out of a C<given()> block.
612
613 This keyword is enabled by the "switch" feature: see L<feature>
614 for more information.
615
616 =item caller EXPR
617 X<caller> X<call stack> X<stack> X<stack trace>
618
619 =item caller
620
621 Returns the context of the current subroutine call.  In scalar context,
622 returns the caller's package name if there is a caller, that is, if
623 we're in a subroutine or C<eval> or C<require>, and the undefined value
624 otherwise.  In list context, returns
625
626     # 0         1          2
627     ($package, $filename, $line) = caller;
628
629 With EXPR, it returns some extra information that the debugger uses to
630 print a stack trace.  The value of EXPR indicates how many call frames
631 to go back before the current one.
632
633     #  0         1          2      3            4
634     ($package, $filename, $line, $subroutine, $hasargs,
635
636     #  5          6          7            8       9         10
637     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
638      = caller($i);
639
640 Here $subroutine may be C<(eval)> if the frame is not a subroutine
641 call, but an C<eval>.  In such a case additional elements $evaltext and
642 C<$is_require> are set: C<$is_require> is true if the frame is created by a
643 C<require> or C<use> statement, $evaltext contains the text of the
644 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
645 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
646 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
647 frame.)  $subroutine may also be C<(unknown)> if this particular
648 subroutine happens to have been deleted from the symbol table.
649 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
650 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
651 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
652 between versions of Perl, and are not meant for external use.
653
654 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
655 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
656 of this hash, as they are the actual values stored in the optree.
657
658 Furthermore, when called from within the DB package, caller returns more
659 detailed information: it sets the list variable C<@DB::args> to be the
660 arguments with which the subroutine was invoked.
661
662 Be aware that the optimizer might have optimized call frames away before
663 C<caller> had a chance to get the information.  That means that C<caller(N)>
664 might not return information about the call frame you expect it do, for
665 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
666 previous time C<caller> was called.
667
668 =item chdir EXPR
669 X<chdir>
670 X<cd>
671 X<directory, change>
672
673 =item chdir FILEHANDLE
674
675 =item chdir DIRHANDLE
676
677 =item chdir
678
679 Changes the working directory to EXPR, if possible. If EXPR is omitted,
680 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
681 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
682 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
683 neither is set, C<chdir> does nothing. It returns true upon success,
684 false otherwise. See the example under C<die>.
685
686 On systems that support fchdir, you might pass a file handle or
687 directory handle as argument.  On systems that don't support fchdir,
688 passing handles produces a fatal error at run time.
689
690 =item chmod LIST
691 X<chmod> X<permission> X<mode>
692
693 Changes the permissions of a list of files.  The first element of the
694 list must be the numerical mode, which should probably be an octal
695 number, and which definitely should I<not> be a string of octal digits:
696 C<0644> is okay, C<'0644'> is not.  Returns the number of files
697 successfully changed.  See also L</oct>, if all you have is a string.
698
699     $cnt = chmod 0755, 'foo', 'bar';
700     chmod 0755, @executables;
701     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
702                                              # --w----r-T
703     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
704     $mode = 0644;   chmod $mode, 'foo';      # this is best
705
706 On systems that support fchmod, you might pass file handles among the
707 files.  On systems that don't support fchmod, passing file handles
708 produces a fatal error at run time.   The file handles must be passed
709 as globs or references to be recognized.  Barewords are considered
710 file names.
711
712     open(my $fh, "<", "foo");
713     my $perm = (stat $fh)[2] & 07777;
714     chmod($perm | 0600, $fh);
715
716 You can also import the symbolic C<S_I*> constants from the Fcntl
717 module:
718
719     use Fcntl ':mode';
720
721     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
722     # This is identical to the chmod 0755 of the above example.
723
724 =item chomp VARIABLE
725 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
726
727 =item chomp( LIST )
728
729 =item chomp
730
731 This safer version of L</chop> removes any trailing string
732 that corresponds to the current value of C<$/> (also known as
733 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
734 number of characters removed from all its arguments.  It's often used to
735 remove the newline from the end of an input record when you're worried
736 that the final record may be missing its newline.  When in paragraph
737 mode (C<$/ = "">), it removes all trailing newlines from the string.
738 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
739 a reference to an integer or the like, see L<perlvar>) chomp() won't
740 remove anything.
741 If VARIABLE is omitted, it chomps C<$_>.  Example:
742
743     while (<>) {
744         chomp;  # avoid \n on last field
745         @array = split(/:/);
746         # ...
747     }
748
749 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
750
751 You can actually chomp anything that's an lvalue, including an assignment:
752
753     chomp($cwd = `pwd`);
754     chomp($answer = <STDIN>);
755
756 If you chomp a list, each element is chomped, and the total number of
757 characters removed is returned.
758
759 If the C<encoding> pragma is in scope then the lengths returned are
760 calculated from the length of C<$/> in Unicode characters, which is not
761 always the same as the length of C<$/> in the native encoding.
762
763 Note that parentheses are necessary when you're chomping anything
764 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
765 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
766 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
767 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
768 as C<chomp($a, $b)>.
769
770 =item chop VARIABLE
771 X<chop>
772
773 =item chop( LIST )
774
775 =item chop
776
777 Chops off the last character of a string and returns the character
778 chopped.  It is much more efficient than C<s/.$//s> because it neither
779 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
780 If VARIABLE is a hash, it chops the hash's values, but not its keys.
781
782 You can actually chop anything that's an lvalue, including an assignment.
783
784 If you chop a list, each element is chopped.  Only the value of the
785 last C<chop> is returned.
786
787 Note that C<chop> returns the last character.  To return all but the last
788 character, use C<substr($string, 0, -1)>.
789
790 See also L</chomp>.
791
792 =item chown LIST
793 X<chown> X<owner> X<user> X<group>
794
795 Changes the owner (and group) of a list of files.  The first two
796 elements of the list must be the I<numeric> uid and gid, in that
797 order.  A value of -1 in either position is interpreted by most
798 systems to leave that value unchanged.  Returns the number of files
799 successfully changed.
800
801     $cnt = chown $uid, $gid, 'foo', 'bar';
802     chown $uid, $gid, @filenames;
803
804 On systems that support fchown, you might pass file handles among the
805 files.  On systems that don't support fchown, passing file handles
806 produces a fatal error at run time.  The file handles must be passed
807 as globs or references to be recognized.  Barewords are considered
808 file names.
809
810 Here's an example that looks up nonnumeric uids in the passwd file:
811
812     print "User: ";
813     chomp($user = <STDIN>);
814     print "Files: ";
815     chomp($pattern = <STDIN>);
816
817     ($login,$pass,$uid,$gid) = getpwnam($user)
818         or die "$user not in passwd file";
819
820     @ary = glob($pattern);      # expand filenames
821     chown $uid, $gid, @ary;
822
823 On most systems, you are not allowed to change the ownership of the
824 file unless you're the superuser, although you should be able to change
825 the group to any of your secondary groups.  On insecure systems, these
826 restrictions may be relaxed, but this is not a portable assumption.
827 On POSIX systems, you can detect this condition this way:
828
829     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
830     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
831
832 =item chr NUMBER
833 X<chr> X<character> X<ASCII> X<Unicode>
834
835 =item chr
836
837 Returns the character represented by that NUMBER in the character set.
838 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
839 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
840 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
841 backward compatibility reasons (but see L<encoding>).
842
843 Negative values give the Unicode replacement character (chr(0xfffd)),
844 except under the L<bytes> pragma, where low eight bits of the value
845 (truncated to an integer) are used.
846
847 If NUMBER is omitted, uses C<$_>.
848
849 For the reverse, use L</ord>.
850
851 Note that under the C<bytes> pragma the NUMBER is masked to
852 the low eight bits.
853
854 See L<perlunicode> and L<encoding> for more about Unicode.
855
856 =item chroot FILENAME
857 X<chroot> X<root>
858
859 =item chroot
860
861 This function works like the system call by the same name: it makes the
862 named directory the new root directory for all further pathnames that
863 begin with a C</> by your process and all its children.  (It doesn't
864 change your current working directory, which is unaffected.)  For security
865 reasons, this call is restricted to the superuser.  If FILENAME is
866 omitted, does a C<chroot> to C<$_>.
867
868 =item close FILEHANDLE
869 X<close>
870
871 =item close
872
873 Closes the file or pipe associated with the file handle, returning
874 true only if IO buffers are successfully flushed and closes the system
875 file descriptor.  Closes the currently selected filehandle if the
876 argument is omitted.
877
878 You don't have to close FILEHANDLE if you are immediately going to do
879 another C<open> on it, because C<open> will close it for you.  (See
880 C<open>.)  However, an explicit C<close> on an input file resets the line
881 counter (C<$.>), while the implicit close done by C<open> does not.
882
883 If the file handle came from a piped open, C<close> will additionally
884 return false if one of the other system calls involved fails, or if the
885 program exits with non-zero status.  (If the only problem was that the
886 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
887 also waits for the process executing on the pipe to complete, in case you
888 want to look at the output of the pipe afterwards, and
889 implicitly puts the exit status value of that command into C<$?> and
890 C<${^CHILD_ERROR_NATIVE}>.
891
892 Prematurely closing the read end of a pipe (i.e. before the process
893 writing to it at the other end has closed it) will result in a
894 SIGPIPE being delivered to the writer.  If the other end can't
895 handle that, be sure to read all the data before closing the pipe.
896
897 Example:
898
899     open(OUTPUT, '|sort >foo')  # pipe to sort
900         or die "Can't start sort: $!";
901     #...                        # print stuff to output
902     close OUTPUT                # wait for sort to finish
903         or warn $! ? "Error closing sort pipe: $!"
904                    : "Exit status $? from sort";
905     open(INPUT, 'foo')          # get sort's results
906         or die "Can't open 'foo' for input: $!";
907
908 FILEHANDLE may be an expression whose value can be used as an indirect
909 filehandle, usually the real filehandle name.
910
911 =item closedir DIRHANDLE
912 X<closedir>
913
914 Closes a directory opened by C<opendir> and returns the success of that
915 system call.
916
917 =item connect SOCKET,NAME
918 X<connect>
919
920 Attempts to connect to a remote socket, just as the connect system call
921 does.  Returns true if it succeeded, false otherwise.  NAME should be a
922 packed address of the appropriate type for the socket.  See the examples in
923 L<perlipc/"Sockets: Client/Server Communication">.
924
925 =item continue BLOCK
926 X<continue>
927
928 =item continue
929
930 C<continue> is actually a flow control statement rather than a function.  If
931 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
932 C<foreach>), it is always executed just before the conditional is about to
933 be evaluated again, just like the third part of a C<for> loop in C.  Thus
934 it can be used to increment a loop variable, even when the loop has been
935 continued via the C<next> statement (which is similar to the C C<continue>
936 statement).
937
938 C<last>, C<next>, or C<redo> may appear within a C<continue>
939 block.  C<last> and C<redo> will behave as if they had been executed within
940 the main block.  So will C<next>, but since it will execute a C<continue>
941 block, it may be more entertaining.
942
943     while (EXPR) {
944         ### redo always comes here
945         do_something;
946     } continue {
947         ### next always comes here
948         do_something_else;
949         # then back the top to re-check EXPR
950     }
951     ### last always comes here
952
953 Omitting the C<continue> section is semantically equivalent to using an
954 empty one, logically enough.  In that case, C<next> goes directly back
955 to check the condition at the top of the loop.
956
957 If the "switch" feature is enabled, C<continue> is also a
958 function that will break out of the current C<when> or C<default>
959 block, and fall through to the next case. See L<feature> and
960 L<perlsyn/"Switch statements"> for more information.
961
962
963 =item cos EXPR
964 X<cos> X<cosine> X<acos> X<arccosine>
965
966 =item cos
967
968 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
969 takes cosine of C<$_>.
970
971 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
972 function, or use this relation:
973
974     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
975
976 =item crypt PLAINTEXT,SALT
977 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
978 X<decrypt> X<cryptography> X<passwd> X<encrypt>
979
980 Creates a digest string exactly like the crypt(3) function in the C
981 library (assuming that you actually have a version there that has not
982 been extirpated as a potential munitions).
983
984 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
985 into a short string, called a digest, which is returned.  The same
986 PLAINTEXT and SALT will always return the same string, but there is no
987 (known) way to get the original PLAINTEXT from the hash.  Small
988 changes in the PLAINTEXT or SALT will result in large changes in the
989 digest.
990
991 There is no decrypt function.  This function isn't all that useful for
992 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
993 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
994 primarily used to check if two pieces of text are the same without
995 having to transmit or store the text itself.  An example is checking
996 if a correct password is given.  The digest of the password is stored,
997 not the password itself.  The user types in a password that is
998 crypt()'d with the same salt as the stored digest.  If the two digests
999 match the password is correct.
1000
1001 When verifying an existing digest string you should use the digest as
1002 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1003 to create the digest is visible as part of the digest.  This ensures
1004 crypt() will hash the new string with the same salt as the digest.
1005 This allows your code to work with the standard L<crypt|/crypt> and
1006 with more exotic implementations.  In other words, do not assume
1007 anything about the returned string itself, or how many bytes in the
1008 digest matter.
1009
1010 Traditionally the result is a string of 13 bytes: two first bytes of
1011 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1012 the first eight bytes of the digest string mattered, but alternative
1013 hashing schemes (like MD5), higher level security schemes (like C2),
1014 and implementations on non-UNIX platforms may produce different
1015 strings.
1016
1017 When choosing a new salt create a random two character string whose
1018 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1019 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1020 characters is just a recommendation; the characters allowed in
1021 the salt depend solely on your system's crypt library, and Perl can't
1022 restrict what salts C<crypt()> accepts.
1023
1024 Here's an example that makes sure that whoever runs this program knows
1025 their password:
1026
1027     $pwd = (getpwuid($<))[1];
1028
1029     system "stty -echo";
1030     print "Password: ";
1031     chomp($word = <STDIN>);
1032     print "\n";
1033     system "stty echo";
1034
1035     if (crypt($word, $pwd) ne $pwd) {
1036         die "Sorry...\n";
1037     } else {
1038         print "ok\n";
1039     }
1040
1041 Of course, typing in your own password to whoever asks you
1042 for it is unwise.
1043
1044 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1045 of data, not least of all because you can't get the information
1046 back.  Look at the L<Digest> module for more robust algorithms.
1047
1048 If using crypt() on a Unicode string (which I<potentially> has
1049 characters with codepoints above 255), Perl tries to make sense
1050 of the situation by trying to downgrade (a copy of the string)
1051 the string back to an eight-bit byte string before calling crypt()
1052 (on that copy).  If that works, good.  If not, crypt() dies with
1053 C<Wide character in crypt>.
1054
1055 =item dbmclose HASH
1056 X<dbmclose>
1057
1058 [This function has been largely superseded by the C<untie> function.]
1059
1060 Breaks the binding between a DBM file and a hash.
1061
1062 =item dbmopen HASH,DBNAME,MASK
1063 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1064
1065 [This function has been largely superseded by the C<tie> function.]
1066
1067 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1068 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1069 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1070 is the name of the database (without the F<.dir> or F<.pag> extension if
1071 any).  If the database does not exist, it is created with protection
1072 specified by MASK (as modified by the C<umask>).  If your system supports
1073 only the older DBM functions, you may perform only one C<dbmopen> in your
1074 program.  In older versions of Perl, if your system had neither DBM nor
1075 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1076 sdbm(3).
1077
1078 If you don't have write access to the DBM file, you can only read hash
1079 variables, not set them.  If you want to test whether you can write,
1080 either use file tests or try setting a dummy hash entry inside an C<eval>,
1081 which will trap the error.
1082
1083 Note that functions such as C<keys> and C<values> may return huge lists
1084 when used on large DBM files.  You may prefer to use the C<each>
1085 function to iterate over large DBM files.  Example:
1086
1087     # print out history file offsets
1088     dbmopen(%HIST,'/usr/lib/news/history',0666);
1089     while (($key,$val) = each %HIST) {
1090         print $key, ' = ', unpack('L',$val), "\n";
1091     }
1092     dbmclose(%HIST);
1093
1094 See also L<AnyDBM_File> for a more general description of the pros and
1095 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1096 rich implementation.
1097
1098 You can control which DBM library you use by loading that library
1099 before you call dbmopen():
1100
1101     use DB_File;
1102     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1103         or die "Can't open netscape history file: $!";
1104
1105 =item defined EXPR
1106 X<defined> X<undef> X<undefined>
1107
1108 =item defined
1109
1110 Returns a Boolean value telling whether EXPR has a value other than
1111 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
1112 checked.
1113
1114 Many operations return C<undef> to indicate failure, end of file,
1115 system error, uninitialized variable, and other exceptional
1116 conditions.  This function allows you to distinguish C<undef> from
1117 other values.  (A simple Boolean test will not distinguish among
1118 C<undef>, zero, the empty string, and C<"0">, which are all equally
1119 false.)  Note that since C<undef> is a valid scalar, its presence
1120 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1121 returns C<undef> when its argument is an empty array, I<or> when the
1122 element to return happens to be C<undef>.
1123
1124 You may also use C<defined(&func)> to check whether subroutine C<&func>
1125 has ever been defined.  The return value is unaffected by any forward
1126 declarations of C<&func>.  Note that a subroutine which is not defined
1127 may still be callable: its package may have an C<AUTOLOAD> method that
1128 makes it spring into existence the first time that it is called -- see
1129 L<perlsub>.
1130
1131 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1132 used to report whether memory for that aggregate has ever been
1133 allocated.  This behavior may disappear in future versions of Perl.
1134 You should instead use a simple test for size:
1135
1136     if (@an_array) { print "has array elements\n" }
1137     if (%a_hash)   { print "has hash members\n"   }
1138
1139 When used on a hash element, it tells you whether the value is defined,
1140 not whether the key exists in the hash.  Use L</exists> for the latter
1141 purpose.
1142
1143 Examples:
1144
1145     print if defined $switch{'D'};
1146     print "$val\n" while defined($val = pop(@ary));
1147     die "Can't readlink $sym: $!"
1148         unless defined($value = readlink $sym);
1149     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1150     $debugging = 0 unless defined $debugging;
1151
1152 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1153 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1154 defined values.  For example, if you say
1155
1156     "ab" =~ /a(.*)b/;
1157
1158 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1159 matched "nothing".  It didn't really fail to match anything.  Rather, it
1160 matched something that happened to be zero characters long.  This is all
1161 very above-board and honest.  When a function returns an undefined value,
1162 it's an admission that it couldn't give you an honest answer.  So you
1163 should use C<defined> only when you're questioning the integrity of what
1164 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1165 what you want.
1166
1167 See also L</undef>, L</exists>, L</ref>.
1168
1169 =item delete EXPR
1170 X<delete>
1171
1172 Given an expression that specifies a hash element, array element, hash slice,
1173 or array slice, deletes the specified element(s) from the hash or array.
1174 In the case of an array, if the array elements happen to be at the end,
1175 the size of the array will shrink to the highest element that tests
1176 true for exists() (or 0 if no such element exists).
1177
1178 Returns a list with the same number of elements as the number of elements
1179 for which deletion was attempted.  Each element of that list consists of
1180 either the value of the element deleted, or the undefined value.  In scalar
1181 context, this means that you get the value of the last element deleted (or
1182 the undefined value if that element did not exist).
1183
1184     %hash = (foo => 11, bar => 22, baz => 33);
1185     $scalar = delete $hash{foo};             # $scalar is 11
1186     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1187     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1188
1189 Deleting from C<%ENV> modifies the environment.  Deleting from
1190 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1191 from a C<tie>d hash or array may not necessarily return anything.
1192
1193 Deleting an array element effectively returns that position of the array
1194 to its initial, uninitialized state.  Subsequently testing for the same
1195 element with exists() will return false.  Also, deleting array elements
1196 in the middle of an array will not shift the index of the elements
1197 after them down.  Use splice() for that.  See L</exists>.
1198
1199 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1200
1201     foreach $key (keys %HASH) {
1202         delete $HASH{$key};
1203     }
1204
1205     foreach $index (0 .. $#ARRAY) {
1206         delete $ARRAY[$index];
1207     }
1208
1209 And so do these:
1210
1211     delete @HASH{keys %HASH};
1212
1213     delete @ARRAY[0 .. $#ARRAY];
1214
1215 But both of these are slower than just assigning the empty list
1216 or undefining %HASH or @ARRAY:
1217
1218     %HASH = ();         # completely empty %HASH
1219     undef %HASH;        # forget %HASH ever existed
1220
1221     @ARRAY = ();        # completely empty @ARRAY
1222     undef @ARRAY;       # forget @ARRAY ever existed
1223
1224 Note that the EXPR can be arbitrarily complicated as long as the final
1225 operation is a hash element, array element,  hash slice, or array slice
1226 lookup:
1227
1228     delete $ref->[$x][$y]{$key};
1229     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1230
1231     delete $ref->[$x][$y][$index];
1232     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1233
1234 =item die LIST
1235 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1236
1237 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1238 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1239 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1240 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1241 an C<eval(),> the error message is stuffed into C<$@> and the
1242 C<eval> is terminated with the undefined value.  This makes
1243 C<die> the way to raise an exception.
1244
1245 Equivalent examples:
1246
1247     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1248     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1249
1250 If the last element of LIST does not end in a newline, the current
1251 script line number and input line number (if any) are also printed,
1252 and a newline is supplied.  Note that the "input line number" (also
1253 known as "chunk") is subject to whatever notion of "line" happens to
1254 be currently in effect, and is also available as the special variable
1255 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1256
1257 Hint: sometimes appending C<", stopped"> to your message will cause it
1258 to make better sense when the string C<"at foo line 123"> is appended.
1259 Suppose you are running script "canasta".
1260
1261     die "/etc/games is no good";
1262     die "/etc/games is no good, stopped";
1263
1264 produce, respectively
1265
1266     /etc/games is no good at canasta line 123.
1267     /etc/games is no good, stopped at canasta line 123.
1268
1269 See also exit(), warn(), and the Carp module.
1270
1271 If LIST is empty and C<$@> already contains a value (typically from a
1272 previous eval) that value is reused after appending C<"\t...propagated">.
1273 This is useful for propagating exceptions:
1274
1275     eval { ... };
1276     die unless $@ =~ /Expected exception/;
1277
1278 If LIST is empty and C<$@> contains an object reference that has a
1279 C<PROPAGATE> method, that method will be called with additional file
1280 and line number parameters.  The return value replaces the value in
1281 C<$@>.  i.e. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1282 were called.
1283
1284 If C<$@> is empty then the string C<"Died"> is used.
1285
1286 die() can also be called with a reference argument.  If this happens to be
1287 trapped within an eval(), $@ contains the reference.  This behavior permits
1288 a more elaborate exception handling implementation using objects that
1289 maintain arbitrary state about the nature of the exception.  Such a scheme
1290 is sometimes preferable to matching particular string values of $@ using
1291 regular expressions.  Here's an example:
1292
1293     use Scalar::Util 'blessed';
1294
1295     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1296     if ($@) {
1297         if (blessed($@) && $@->isa("Some::Module::Exception")) {
1298             # handle Some::Module::Exception
1299         }
1300         else {
1301             # handle all other possible exceptions
1302         }
1303     }
1304
1305 Because perl will stringify uncaught exception messages before displaying
1306 them, you may want to overload stringification operations on such custom
1307 exception objects.  See L<overload> for details about that.
1308
1309 You can arrange for a callback to be run just before the C<die>
1310 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1311 handler will be called with the error text and can change the error
1312 message, if it sees fit, by calling C<die> again.  See
1313 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1314 L<"eval BLOCK"> for some examples.  Although this feature was 
1315 to be run only right before your program was to exit, this is not
1316 currently the case--the C<$SIG{__DIE__}> hook is currently called
1317 even inside eval()ed blocks/strings!  If one wants the hook to do
1318 nothing in such situations, put
1319
1320         die @_ if $^S;
1321
1322 as the first line of the handler (see L<perlvar/$^S>).  Because
1323 this promotes strange action at a distance, this counterintuitive
1324 behavior may be fixed in a future release.
1325
1326 =item do BLOCK
1327 X<do> X<block>
1328
1329 Not really a function.  Returns the value of the last command in the
1330 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1331 C<until> loop modifier, executes the BLOCK once before testing the loop
1332 condition. (On other statements the loop modifiers test the conditional
1333 first.)
1334
1335 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1336 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1337 See L<perlsyn> for alternative strategies.
1338
1339 =item do SUBROUTINE(LIST)
1340 X<do>
1341
1342 This form of subroutine call is deprecated.  See L<perlsub>.
1343
1344 =item do EXPR
1345 X<do>
1346
1347 Uses the value of EXPR as a filename and executes the contents of the
1348 file as a Perl script.
1349
1350     do 'stat.pl';
1351
1352 is just like
1353
1354     eval `cat stat.pl`;
1355
1356 except that it's more efficient and concise, keeps track of the current
1357 filename for error messages, searches the @INC directories, and updates
1358 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1359 variables.  It also differs in that code evaluated with C<do FILENAME>
1360 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1361 same, however, in that it does reparse the file every time you call it,
1362 so you probably don't want to do this inside a loop.
1363
1364 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1365 error.  If C<do> can read the file but cannot compile it, it
1366 returns undef and sets an error message in C<$@>.   If the file is
1367 successfully compiled, C<do> returns the value of the last expression
1368 evaluated.
1369
1370 Note that inclusion of library modules is better done with the
1371 C<use> and C<require> operators, which also do automatic error checking
1372 and raise an exception if there's a problem.
1373
1374 You might like to use C<do> to read in a program configuration
1375 file.  Manual error checking can be done this way:
1376
1377     # read in config files: system first, then user
1378     for $file ("/share/prog/defaults.rc",
1379                "$ENV{HOME}/.someprogrc")
1380    {
1381         unless ($return = do $file) {
1382             warn "couldn't parse $file: $@" if $@;
1383             warn "couldn't do $file: $!"    unless defined $return;
1384             warn "couldn't run $file"       unless $return;
1385         }
1386     }
1387
1388 =item dump LABEL
1389 X<dump> X<core> X<undump>
1390
1391 =item dump
1392
1393 This function causes an immediate core dump.  See also the B<-u>
1394 command-line switch in L<perlrun>, which does the same thing.
1395 Primarily this is so that you can use the B<undump> program (not
1396 supplied) to turn your core dump into an executable binary after
1397 having initialized all your variables at the beginning of the
1398 program.  When the new binary is executed it will begin by executing
1399 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1400 Think of it as a goto with an intervening core dump and reincarnation.
1401 If C<LABEL> is omitted, restarts the program from the top.
1402
1403 B<WARNING>: Any files opened at the time of the dump will I<not>
1404 be open any more when the program is reincarnated, with possible
1405 resulting confusion on the part of Perl.
1406
1407 This function is now largely obsolete, partly because it's very
1408 hard to convert a core file into an executable, and because the
1409 real compiler backends for generating portable bytecode and compilable
1410 C code have superseded it.  That's why you should now invoke it as
1411 C<CORE::dump()>, if you don't want to be warned against a possible
1412 typo.
1413
1414 If you're looking to use L<dump> to speed up your program, consider
1415 generating bytecode or native C code as described in L<perlcc>.  If
1416 you're just trying to accelerate a CGI script, consider using the
1417 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1418 You might also consider autoloading or selfloading, which at least
1419 make your program I<appear> to run faster.
1420
1421 =item each HASH
1422 X<each> X<hash, iterator>
1423
1424 When called in list context, returns a 2-element list consisting of the
1425 key and value for the next element of a hash, so that you can iterate over
1426 it.  When called in scalar context, returns only the key for the next
1427 element in the hash.
1428
1429 Entries are returned in an apparently random order.  The actual random
1430 order is subject to change in future versions of perl, but it is
1431 guaranteed to be in the same order as either the C<keys> or C<values>
1432 function would produce on the same (unmodified) hash.  Since Perl
1433 5.8.1 the ordering is different even between different runs of Perl
1434 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1435
1436 When the hash is entirely read, a null array is returned in list context
1437 (which when assigned produces a false (C<0>) value), and C<undef> in
1438 scalar context.  The next call to C<each> after that will start iterating
1439 again.  There is a single iterator for each hash, shared by all C<each>,
1440 C<keys>, and C<values> function calls in the program; it can be reset by
1441 reading all the elements from the hash, or by evaluating C<keys HASH> or
1442 C<values HASH>.  If you add or delete elements of a hash while you're
1443 iterating over it, you may get entries skipped or duplicated, so
1444 don't.  Exception: It is always safe to delete the item most recently
1445 returned by C<each()>, which means that the following code will work:
1446
1447         while (($key, $value) = each %hash) {
1448           print $key, "\n";
1449           delete $hash{$key};   # This is safe
1450         }
1451
1452 The following prints out your environment like the printenv(1) program,
1453 only in a different order:
1454
1455     while (($key,$value) = each %ENV) {
1456         print "$key=$value\n";
1457     }
1458
1459 See also C<keys>, C<values> and C<sort>.
1460
1461 =item eof FILEHANDLE
1462 X<eof>
1463 X<end of file>
1464 X<end-of-file>
1465
1466 =item eof ()
1467
1468 =item eof
1469
1470 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1471 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1472 gives the real filehandle.  (Note that this function actually
1473 reads a character and then C<ungetc>s it, so isn't very useful in an
1474 interactive context.)  Do not read from a terminal file (or call
1475 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1476 as terminals may lose the end-of-file condition if you do.
1477
1478 An C<eof> without an argument uses the last file read.  Using C<eof()>
1479 with empty parentheses is very different.  It refers to the pseudo file
1480 formed from the files listed on the command line and accessed via the
1481 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1482 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1483 used will cause C<@ARGV> to be examined to determine if input is
1484 available.   Similarly, an C<eof()> after C<< <> >> has returned
1485 end-of-file will assume you are processing another C<@ARGV> list,
1486 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1487 see L<perlop/"I/O Operators">.
1488
1489 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1490 detect the end of each file, C<eof()> will only detect the end of the
1491 last file.  Examples:
1492
1493     # reset line numbering on each input file
1494     while (<>) {
1495         next if /^\s*#/;        # skip comments
1496         print "$.\t$_";
1497     } continue {
1498         close ARGV  if eof;     # Not eof()!
1499     }
1500
1501     # insert dashes just before last line of last file
1502     while (<>) {
1503         if (eof()) {            # check for end of last file
1504             print "--------------\n";
1505         }
1506         print;
1507         last if eof();          # needed if we're reading from a terminal
1508     }
1509
1510 Practical hint: you almost never need to use C<eof> in Perl, because the
1511 input operators typically return C<undef> when they run out of data, or if
1512 there was an error.
1513
1514 =item eval EXPR
1515 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1516 X<error, handling> X<exception, handling>
1517
1518 =item eval BLOCK
1519
1520 =item eval
1521
1522 In the first form, the return value of EXPR is parsed and executed as if it
1523 were a little Perl program.  The value of the expression (which is itself
1524 determined within scalar context) is first parsed, and if there weren't any
1525 errors, executed in the lexical context of the current Perl program, so
1526 that any variable settings or subroutine and format definitions remain
1527 afterwards.  Note that the value is parsed every time the C<eval> executes.
1528 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1529 delay parsing and subsequent execution of the text of EXPR until run time.
1530
1531 In the second form, the code within the BLOCK is parsed only once--at the
1532 same time the code surrounding the C<eval> itself was parsed--and executed
1533 within the context of the current Perl program.  This form is typically
1534 used to trap exceptions more efficiently than the first (see below), while
1535 also providing the benefit of checking the code within BLOCK at compile
1536 time.
1537
1538 The final semicolon, if any, may be omitted from the value of EXPR or within
1539 the BLOCK.
1540
1541 In both forms, the value returned is the value of the last expression
1542 evaluated inside the mini-program; a return statement may be also used, just
1543 as with subroutines.  The expression providing the return value is evaluated
1544 in void, scalar, or list context, depending on the context of the C<eval> 
1545 itself.  See L</wantarray> for more on how the evaluation context can be 
1546 determined.
1547
1548 If there is a syntax error or runtime error, or a C<die> statement is
1549 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1550 error message.  If there was no error, C<$@> is guaranteed to be a null
1551 string.  Beware that using C<eval> neither silences perl from printing
1552 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1553 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1554 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1555 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1556
1557 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1558 determining whether a particular feature (such as C<socket> or C<symlink>)
1559 is implemented.  It is also Perl's exception trapping mechanism, where
1560 the die operator is used to raise exceptions.
1561
1562 If the code to be executed doesn't vary, you may use the eval-BLOCK
1563 form to trap run-time errors without incurring the penalty of
1564 recompiling each time.  The error, if any, is still returned in C<$@>.
1565 Examples:
1566
1567     # make divide-by-zero nonfatal
1568     eval { $answer = $a / $b; }; warn $@ if $@;
1569
1570     # same thing, but less efficient
1571     eval '$answer = $a / $b'; warn $@ if $@;
1572
1573     # a compile-time error
1574     eval { $answer = };                 # WRONG
1575
1576     # a run-time error
1577     eval '$answer =';   # sets $@
1578
1579 Using the C<eval{}> form as an exception trap in libraries does have some
1580 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1581 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1582 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1583 as shown in this example:
1584
1585     # a very private exception trap for divide-by-zero
1586     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1587     warn $@ if $@;
1588
1589 This is especially significant, given that C<__DIE__> hooks can call
1590 C<die> again, which has the effect of changing their error messages:
1591
1592     # __DIE__ hooks may modify error messages
1593     {
1594        local $SIG{'__DIE__'} =
1595               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1596        eval { die "foo lives here" };
1597        print $@ if $@;                # prints "bar lives here"
1598     }
1599
1600 Because this promotes action at a distance, this counterintuitive behavior
1601 may be fixed in a future release.
1602
1603 With an C<eval>, you should be especially careful to remember what's
1604 being looked at when:
1605
1606     eval $x;            # CASE 1
1607     eval "$x";          # CASE 2
1608
1609     eval '$x';          # CASE 3
1610     eval { $x };        # CASE 4
1611
1612     eval "\$$x++";      # CASE 5
1613     $$x++;              # CASE 6
1614
1615 Cases 1 and 2 above behave identically: they run the code contained in
1616 the variable $x.  (Although case 2 has misleading double quotes making
1617 the reader wonder what else might be happening (nothing is).)  Cases 3
1618 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1619 does nothing but return the value of $x.  (Case 4 is preferred for
1620 purely visual reasons, but it also has the advantage of compiling at
1621 compile-time instead of at run-time.)  Case 5 is a place where
1622 normally you I<would> like to use double quotes, except that in this
1623 particular situation, you can just use symbolic references instead, as
1624 in case 6.
1625
1626 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1627 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1628
1629 Note that as a very special case, an C<eval ''> executed within the C<DB>
1630 package doesn't see the usual surrounding lexical scope, but rather the
1631 scope of the first non-DB piece of code that called it. You don't normally
1632 need to worry about this unless you are writing a Perl debugger.
1633
1634 =item exec LIST
1635 X<exec> X<execute>
1636
1637 =item exec PROGRAM LIST
1638
1639 The C<exec> function executes a system command I<and never returns>--
1640 use C<system> instead of C<exec> if you want it to return.  It fails and
1641 returns false only if the command does not exist I<and> it is executed
1642 directly instead of via your system's command shell (see below).
1643
1644 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1645 warns you if there is a following statement which isn't C<die>, C<warn>,
1646 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1647 I<really> want to follow an C<exec> with some other statement, you
1648 can use one of these styles to avoid the warning:
1649
1650     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1651     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1652
1653 If there is more than one argument in LIST, or if LIST is an array
1654 with more than one value, calls execvp(3) with the arguments in LIST.
1655 If there is only one scalar argument or an array with one element in it,
1656 the argument is checked for shell metacharacters, and if there are any,
1657 the entire argument is passed to the system's command shell for parsing
1658 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1659 If there are no shell metacharacters in the argument, it is split into
1660 words and passed directly to C<execvp>, which is more efficient.
1661 Examples:
1662
1663     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1664     exec "sort $outfile | uniq";
1665
1666 If you don't really want to execute the first argument, but want to lie
1667 to the program you are executing about its own name, you can specify
1668 the program you actually want to run as an "indirect object" (without a
1669 comma) in front of the LIST.  (This always forces interpretation of the
1670 LIST as a multivalued list, even if there is only a single scalar in
1671 the list.)  Example:
1672
1673     $shell = '/bin/csh';
1674     exec $shell '-sh';          # pretend it's a login shell
1675
1676 or, more directly,
1677
1678     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1679
1680 When the arguments get executed via the system shell, results will
1681 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1682 for details.
1683
1684 Using an indirect object with C<exec> or C<system> is also more
1685 secure.  This usage (which also works fine with system()) forces
1686 interpretation of the arguments as a multivalued list, even if the
1687 list had just one argument.  That way you're safe from the shell
1688 expanding wildcards or splitting up words with whitespace in them.
1689
1690     @args = ( "echo surprise" );
1691
1692     exec @args;               # subject to shell escapes
1693                                 # if @args == 1
1694     exec { $args[0] } @args;  # safe even with one-arg list
1695
1696 The first version, the one without the indirect object, ran the I<echo>
1697 program, passing it C<"surprise"> an argument.  The second version
1698 didn't--it tried to run a program literally called I<"echo surprise">,
1699 didn't find it, and set C<$?> to a non-zero value indicating failure.
1700
1701 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1702 output before the exec, but this may not be supported on some platforms
1703 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1704 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1705 open handles in order to avoid lost output.
1706
1707 Note that C<exec> will not call your C<END> blocks, nor will it call
1708 any C<DESTROY> methods in your objects.
1709
1710 =item exists EXPR
1711 X<exists> X<autovivification>
1712
1713 Given an expression that specifies a hash element or array element,
1714 returns true if the specified element in the hash or array has ever
1715 been initialized, even if the corresponding value is undefined.  The
1716 element is not autovivified if it doesn't exist.
1717
1718     print "Exists\n"    if exists $hash{$key};
1719     print "Defined\n"   if defined $hash{$key};
1720     print "True\n"      if $hash{$key};
1721
1722     print "Exists\n"    if exists $array[$index];
1723     print "Defined\n"   if defined $array[$index];
1724     print "True\n"      if $array[$index];
1725
1726 A hash or array element can be true only if it's defined, and defined if
1727 it exists, but the reverse doesn't necessarily hold true.
1728
1729 Given an expression that specifies the name of a subroutine,
1730 returns true if the specified subroutine has ever been declared, even
1731 if it is undefined.  Mentioning a subroutine name for exists or defined
1732 does not count as declaring it.  Note that a subroutine which does not
1733 exist may still be callable: its package may have an C<AUTOLOAD>
1734 method that makes it spring into existence the first time that it is
1735 called -- see L<perlsub>.
1736
1737     print "Exists\n"    if exists &subroutine;
1738     print "Defined\n"   if defined &subroutine;
1739
1740 Note that the EXPR can be arbitrarily complicated as long as the final
1741 operation is a hash or array key lookup or subroutine name:
1742
1743     if (exists $ref->{A}->{B}->{$key})  { }
1744     if (exists $hash{A}{B}{$key})       { }
1745
1746     if (exists $ref->{A}->{B}->[$ix])   { }
1747     if (exists $hash{A}{B}[$ix])        { }
1748
1749     if (exists &{$ref->{A}{B}{$key}})   { }
1750
1751 Although the deepest nested array or hash will not spring into existence
1752 just because its existence was tested, any intervening ones will.
1753 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1754 into existence due to the existence test for the $key element above.
1755 This happens anywhere the arrow operator is used, including even:
1756
1757     undef $ref;
1758     if (exists $ref->{"Some key"})      { }
1759     print $ref;             # prints HASH(0x80d3d5c)
1760
1761 This surprising autovivification in what does not at first--or even
1762 second--glance appear to be an lvalue context may be fixed in a future
1763 release.
1764
1765 Use of a subroutine call, rather than a subroutine name, as an argument
1766 to exists() is an error.
1767
1768     exists &sub;        # OK
1769     exists &sub();      # Error
1770
1771 =item exit EXPR
1772 X<exit> X<terminate> X<abort>
1773
1774 =item exit
1775
1776 Evaluates EXPR and exits immediately with that value.    Example:
1777
1778     $ans = <STDIN>;
1779     exit 0 if $ans =~ /^[Xx]/;
1780
1781 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1782 universally recognized values for EXPR are C<0> for success and C<1>
1783 for error; other values are subject to interpretation depending on the
1784 environment in which the Perl program is running.  For example, exiting
1785 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1786 the mailer to return the item undelivered, but that's not true everywhere.
1787
1788 Don't use C<exit> to abort a subroutine if there's any chance that
1789 someone might want to trap whatever error happened.  Use C<die> instead,
1790 which can be trapped by an C<eval>.
1791
1792 The exit() function does not always exit immediately.  It calls any
1793 defined C<END> routines first, but these C<END> routines may not
1794 themselves abort the exit.  Likewise any object destructors that need to
1795 be called are called before the real exit.  If this is a problem, you
1796 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1797 See L<perlmod> for details.
1798
1799 =item exp EXPR
1800 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1801
1802 =item exp
1803
1804 Returns I<e> (the natural logarithm base) to the power of EXPR.
1805 If EXPR is omitted, gives C<exp($_)>.
1806
1807 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1808 X<fcntl>
1809
1810 Implements the fcntl(2) function.  You'll probably have to say
1811
1812     use Fcntl;
1813
1814 first to get the correct constant definitions.  Argument processing and
1815 value return works just like C<ioctl> below.
1816 For example:
1817
1818     use Fcntl;
1819     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1820         or die "can't fcntl F_GETFL: $!";
1821
1822 You don't have to check for C<defined> on the return from C<fcntl>.
1823 Like C<ioctl>, it maps a C<0> return from the system call into
1824 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1825 in numeric context.  It is also exempt from the normal B<-w> warnings
1826 on improper numeric conversions.
1827
1828 Note that C<fcntl> will produce a fatal error if used on a machine that
1829 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1830 manpage to learn what functions are available on your system.
1831
1832 Here's an example of setting a filehandle named C<REMOTE> to be
1833 non-blocking at the system level.  You'll have to negotiate C<$|>
1834 on your own, though.
1835
1836     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1837
1838     $flags = fcntl(REMOTE, F_GETFL, 0)
1839                 or die "Can't get flags for the socket: $!\n";
1840
1841     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1842                 or die "Can't set flags for the socket: $!\n";
1843
1844 =item fileno FILEHANDLE
1845 X<fileno>
1846
1847 Returns the file descriptor for a filehandle, or undefined if the
1848 filehandle is not open.  This is mainly useful for constructing
1849 bitmaps for C<select> and low-level POSIX tty-handling operations.
1850 If FILEHANDLE is an expression, the value is taken as an indirect
1851 filehandle, generally its name.
1852
1853 You can use this to find out whether two handles refer to the
1854 same underlying descriptor:
1855
1856     if (fileno(THIS) == fileno(THAT)) {
1857         print "THIS and THAT are dups\n";
1858     }
1859
1860 (Filehandles connected to memory objects via new features of C<open> may
1861 return undefined even though they are open.)
1862
1863
1864 =item flock FILEHANDLE,OPERATION
1865 X<flock> X<lock> X<locking>
1866
1867 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1868 for success, false on failure.  Produces a fatal error if used on a
1869 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1870 C<flock> is Perl's portable file locking interface, although it locks
1871 only entire files, not records.
1872
1873 Two potentially non-obvious but traditional C<flock> semantics are
1874 that it waits indefinitely until the lock is granted, and that its locks
1875 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1876 fewer guarantees.  This means that programs that do not also use C<flock>
1877 may modify files locked with C<flock>.  See L<perlport>, 
1878 your port's specific documentation, or your system-specific local manpages
1879 for details.  It's best to assume traditional behavior if you're writing
1880 portable programs.  (But if you're not, you should as always feel perfectly
1881 free to write for your own system's idiosyncrasies (sometimes called
1882 "features").  Slavish adherence to portability concerns shouldn't get
1883 in the way of your getting your job done.)
1884
1885 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1886 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1887 you can use the symbolic names if you import them from the Fcntl module,
1888 either individually, or as a group using the ':flock' tag.  LOCK_SH
1889 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1890 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1891 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1892 waiting for the lock (check the return status to see if you got it).
1893
1894 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1895 before locking or unlocking it.
1896
1897 Note that the emulation built with lockf(3) doesn't provide shared
1898 locks, and it requires that FILEHANDLE be open with write intent.  These
1899 are the semantics that lockf(3) implements.  Most if not all systems
1900 implement lockf(3) in terms of fcntl(2) locking, though, so the
1901 differing semantics shouldn't bite too many people.
1902
1903 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1904 be open with read intent to use LOCK_SH and requires that it be open
1905 with write intent to use LOCK_EX.
1906
1907 Note also that some versions of C<flock> cannot lock things over the
1908 network; you would need to use the more system-specific C<fcntl> for
1909 that.  If you like you can force Perl to ignore your system's flock(2)
1910 function, and so provide its own fcntl(2)-based emulation, by passing
1911 the switch C<-Ud_flock> to the F<Configure> program when you configure
1912 perl.
1913
1914 Here's a mailbox appender for BSD systems.
1915
1916     use Fcntl ':flock'; # import LOCK_* constants
1917
1918     sub lock {
1919         flock(MBOX,LOCK_EX);
1920         # and, in case someone appended
1921         # while we were waiting...
1922         seek(MBOX, 0, 2);
1923     }
1924
1925     sub unlock {
1926         flock(MBOX,LOCK_UN);
1927     }
1928
1929     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1930             or die "Can't open mailbox: $!";
1931
1932     lock();
1933     print MBOX $msg,"\n\n";
1934     unlock();
1935
1936 On systems that support a real flock(), locks are inherited across fork()
1937 calls, whereas those that must resort to the more capricious fcntl()
1938 function lose the locks, making it harder to write servers.
1939
1940 See also L<DB_File> for other flock() examples.
1941
1942 =item fork
1943 X<fork> X<child> X<parent>
1944
1945 Does a fork(2) system call to create a new process running the
1946 same program at the same point.  It returns the child pid to the
1947 parent process, C<0> to the child process, or C<undef> if the fork is
1948 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1949 are shared, while everything else is copied.  On most systems supporting
1950 fork(), great care has gone into making it extremely efficient (for
1951 example, using copy-on-write technology on data pages), making it the
1952 dominant paradigm for multitasking over the last few decades.
1953
1954 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1955 output before forking the child process, but this may not be supported
1956 on some platforms (see L<perlport>).  To be safe, you may need to set
1957 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1958 C<IO::Handle> on any open handles in order to avoid duplicate output.
1959
1960 If you C<fork> without ever waiting on your children, you will
1961 accumulate zombies.  On some systems, you can avoid this by setting
1962 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1963 forking and reaping moribund children.
1964
1965 Note that if your forked child inherits system file descriptors like
1966 STDIN and STDOUT that are actually connected by a pipe or socket, even
1967 if you exit, then the remote server (such as, say, a CGI script or a
1968 backgrounded job launched from a remote shell) won't think you're done.
1969 You should reopen those to F</dev/null> if it's any issue.
1970
1971 =item format
1972 X<format>
1973
1974 Declare a picture format for use by the C<write> function.  For
1975 example:
1976
1977     format Something =
1978         Test: @<<<<<<<< @||||| @>>>>>
1979               $str,     $%,    '$' . int($num)
1980     .
1981
1982     $str = "widget";
1983     $num = $cost/$quantity;
1984     $~ = 'Something';
1985     write;
1986
1987 See L<perlform> for many details and examples.
1988
1989 =item formline PICTURE,LIST
1990 X<formline>
1991
1992 This is an internal function used by C<format>s, though you may call it,
1993 too.  It formats (see L<perlform>) a list of values according to the
1994 contents of PICTURE, placing the output into the format output
1995 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1996 Eventually, when a C<write> is done, the contents of
1997 C<$^A> are written to some filehandle.  You could also read C<$^A>
1998 and then set C<$^A> back to C<"">.  Note that a format typically
1999 does one C<formline> per line of form, but the C<formline> function itself
2000 doesn't care how many newlines are embedded in the PICTURE.  This means
2001 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
2002 You may therefore need to use multiple formlines to implement a single
2003 record format, just like the format compiler.
2004
2005 Be careful if you put double quotes around the picture, because an C<@>
2006 character may be taken to mean the beginning of an array name.
2007 C<formline> always returns true.  See L<perlform> for other examples.
2008
2009 =item getc FILEHANDLE
2010 X<getc> X<getchar> X<character> X<file, read>
2011
2012 =item getc
2013
2014 Returns the next character from the input file attached to FILEHANDLE,
2015 or the undefined value at end of file, or if there was an error (in
2016 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2017 STDIN.  This is not particularly efficient.  However, it cannot be
2018 used by itself to fetch single characters without waiting for the user
2019 to hit enter.  For that, try something more like:
2020
2021     if ($BSD_STYLE) {
2022         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2023     }
2024     else {
2025         system "stty", '-icanon', 'eol', "\001";
2026     }
2027
2028     $key = getc(STDIN);
2029
2030     if ($BSD_STYLE) {
2031         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2032     }
2033     else {
2034         system "stty", 'icanon', 'eol', '^@'; # ASCII null
2035     }
2036     print "\n";
2037
2038 Determination of whether $BSD_STYLE should be set
2039 is left as an exercise to the reader.
2040
2041 The C<POSIX::getattr> function can do this more portably on
2042 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2043 module from your nearest CPAN site; details on CPAN can be found on
2044 L<perlmodlib/CPAN>.
2045
2046 =item getlogin
2047 X<getlogin> X<login>
2048
2049 This implements the C library function of the same name, which on most
2050 systems returns the current login from F</etc/utmp>, if any.  If null,
2051 use C<getpwuid>.
2052
2053     $login = getlogin || getpwuid($<) || "Kilroy";
2054
2055 Do not consider C<getlogin> for authentication: it is not as
2056 secure as C<getpwuid>.
2057
2058 =item getpeername SOCKET
2059 X<getpeername> X<peer>
2060
2061 Returns the packed sockaddr address of other end of the SOCKET connection.
2062
2063     use Socket;
2064     $hersockaddr    = getpeername(SOCK);
2065     ($port, $iaddr) = sockaddr_in($hersockaddr);
2066     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2067     $herstraddr     = inet_ntoa($iaddr);
2068
2069 =item getpgrp PID
2070 X<getpgrp> X<group>
2071
2072 Returns the current process group for the specified PID.  Use
2073 a PID of C<0> to get the current process group for the
2074 current process.  Will raise an exception if used on a machine that
2075 doesn't implement getpgrp(2).  If PID is omitted, returns process
2076 group of current process.  Note that the POSIX version of C<getpgrp>
2077 does not accept a PID argument, so only C<PID==0> is truly portable.
2078
2079 =item getppid
2080 X<getppid> X<parent> X<pid>
2081
2082 Returns the process id of the parent process.
2083
2084 Note for Linux users: on Linux, the C functions C<getpid()> and
2085 C<getppid()> return different values from different threads. In order to
2086 be portable, this behavior is not reflected by the perl-level function
2087 C<getppid()>, that returns a consistent value across threads. If you want
2088 to call the underlying C<getppid()>, you may use the CPAN module
2089 C<Linux::Pid>.
2090
2091 =item getpriority WHICH,WHO
2092 X<getpriority> X<priority> X<nice>
2093
2094 Returns the current priority for a process, a process group, or a user.
2095 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2096 machine that doesn't implement getpriority(2).
2097
2098 =item getpwnam NAME
2099 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2100 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2101 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2102 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2103 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2104 X<endnetent> X<endprotoent> X<endservent> 
2105
2106 =item getgrnam NAME
2107
2108 =item gethostbyname NAME
2109
2110 =item getnetbyname NAME
2111
2112 =item getprotobyname NAME
2113
2114 =item getpwuid UID
2115
2116 =item getgrgid GID
2117
2118 =item getservbyname NAME,PROTO
2119
2120 =item gethostbyaddr ADDR,ADDRTYPE
2121
2122 =item getnetbyaddr ADDR,ADDRTYPE
2123
2124 =item getprotobynumber NUMBER
2125
2126 =item getservbyport PORT,PROTO
2127
2128 =item getpwent
2129
2130 =item getgrent
2131
2132 =item gethostent
2133
2134 =item getnetent
2135
2136 =item getprotoent
2137
2138 =item getservent
2139
2140 =item setpwent
2141
2142 =item setgrent
2143
2144 =item sethostent STAYOPEN
2145
2146 =item setnetent STAYOPEN
2147
2148 =item setprotoent STAYOPEN
2149
2150 =item setservent STAYOPEN
2151
2152 =item endpwent
2153
2154 =item endgrent
2155
2156 =item endhostent
2157
2158 =item endnetent
2159
2160 =item endprotoent
2161
2162 =item endservent
2163
2164 These routines perform the same functions as their counterparts in the
2165 system library.  In list context, the return values from the
2166 various get routines are as follows:
2167
2168     ($name,$passwd,$uid,$gid,
2169        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2170     ($name,$passwd,$gid,$members) = getgr*
2171     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2172     ($name,$aliases,$addrtype,$net) = getnet*
2173     ($name,$aliases,$proto) = getproto*
2174     ($name,$aliases,$port,$proto) = getserv*
2175
2176 (If the entry doesn't exist you get a null list.)
2177
2178 The exact meaning of the $gcos field varies but it usually contains
2179 the real name of the user (as opposed to the login name) and other
2180 information pertaining to the user.  Beware, however, that in many
2181 system users are able to change this information and therefore it
2182 cannot be trusted and therefore the $gcos is tainted (see
2183 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2184 login shell, are also tainted, because of the same reason.
2185
2186 In scalar context, you get the name, unless the function was a
2187 lookup by name, in which case you get the other thing, whatever it is.
2188 (If the entry doesn't exist you get the undefined value.)  For example:
2189
2190     $uid   = getpwnam($name);
2191     $name  = getpwuid($num);
2192     $name  = getpwent();
2193     $gid   = getgrnam($name);
2194     $name  = getgrgid($num);
2195     $name  = getgrent();
2196     #etc.
2197
2198 In I<getpw*()> the fields $quota, $comment, and $expire are special
2199 cases in the sense that in many systems they are unsupported.  If the
2200 $quota is unsupported, it is an empty scalar.  If it is supported, it
2201 usually encodes the disk quota.  If the $comment field is unsupported,
2202 it is an empty scalar.  If it is supported it usually encodes some
2203 administrative comment about the user.  In some systems the $quota
2204 field may be $change or $age, fields that have to do with password
2205 aging.  In some systems the $comment field may be $class.  The $expire
2206 field, if present, encodes the expiration period of the account or the
2207 password.  For the availability and the exact meaning of these fields
2208 in your system, please consult your getpwnam(3) documentation and your
2209 F<pwd.h> file.  You can also find out from within Perl what your
2210 $quota and $comment fields mean and whether you have the $expire field
2211 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2212 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2213 files are only supported if your vendor has implemented them in the
2214 intuitive fashion that calling the regular C library routines gets the
2215 shadow versions if you're running under privilege or if there exists
2216 the shadow(3) functions as found in System V (this includes Solaris
2217 and Linux.)  Those systems that implement a proprietary shadow password
2218 facility are unlikely to be supported.
2219
2220 The $members value returned by I<getgr*()> is a space separated list of
2221 the login names of the members of the group.
2222
2223 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2224 C, it will be returned to you via C<$?> if the function call fails.  The
2225 C<@addrs> value returned by a successful call is a list of the raw
2226 addresses returned by the corresponding system library call.  In the
2227 Internet domain, each address is four bytes long and you can unpack it
2228 by saying something like:
2229
2230     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2231
2232 The Socket library makes this slightly easier:
2233
2234     use Socket;
2235     $iaddr = inet_aton("127.1"); # or whatever address
2236     $name  = gethostbyaddr($iaddr, AF_INET);
2237
2238     # or going the other way
2239     $straddr = inet_ntoa($iaddr);
2240
2241 If you get tired of remembering which element of the return list
2242 contains which return value, by-name interfaces are provided
2243 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2244 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2245 and C<User::grent>.  These override the normal built-ins, supplying
2246 versions that return objects with the appropriate names
2247 for each field.  For example:
2248
2249    use File::stat;
2250    use User::pwent;
2251    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2252
2253 Even though it looks like they're the same method calls (uid),
2254 they aren't, because a C<File::stat> object is different from
2255 a C<User::pwent> object.
2256
2257 =item getsockname SOCKET
2258 X<getsockname>
2259
2260 Returns the packed sockaddr address of this end of the SOCKET connection,
2261 in case you don't know the address because you have several different
2262 IPs that the connection might have come in on.
2263
2264     use Socket;
2265     $mysockaddr = getsockname(SOCK);
2266     ($port, $myaddr) = sockaddr_in($mysockaddr);
2267     printf "Connect to %s [%s]\n",
2268        scalar gethostbyaddr($myaddr, AF_INET),
2269        inet_ntoa($myaddr);
2270
2271 =item getsockopt SOCKET,LEVEL,OPTNAME
2272 X<getsockopt>
2273
2274 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2275 Options may exist at multiple protocol levels depending on the socket
2276 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2277 C<Socket> module) will exist. To query options at another level the
2278 protocol number of the appropriate protocol controlling the option
2279 should be supplied. For example, to indicate that an option is to be
2280 interpreted by the TCP protocol, LEVEL should be set to the protocol
2281 number of TCP, which you can get using getprotobyname.
2282
2283 The call returns a packed string representing the requested socket option,
2284 or C<undef> if there is an error (the error reason will be in $!). What
2285 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2286 your system documentation for details. A very common case however is that
2287 the option is an integer, in which case the result will be a packed
2288 integer which you can decode using unpack with the C<i> (or C<I>) format.
2289
2290 An example testing if Nagle's algorithm is turned on on a socket:
2291
2292     use Socket qw(:all);
2293
2294     defined(my $tcp = getprotobyname("tcp"))
2295         or die "Could not determine the protocol number for tcp";
2296     # my $tcp = IPPROTO_TCP; # Alternative
2297     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2298         or die "Could not query TCP_NODELAY socket option: $!";
2299     my $nodelay = unpack("I", $packed);
2300     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2301
2302
2303 =item glob EXPR
2304 X<glob> X<wildcard> X<filename, expansion> X<expand>
2305
2306 =item glob
2307
2308 In list context, returns a (possibly empty) list of filename expansions on
2309 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2310 scalar context, glob iterates through such filename expansions, returning
2311 undef when the list is exhausted. This is the internal function
2312 implementing the C<< <*.c> >> operator, but you can use it directly. If
2313 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2314 more detail in L<perlop/"I/O Operators">.
2315
2316 Beginning with v5.6.0, this operator is implemented using the standard
2317 C<File::Glob> extension.  See L<File::Glob> for details.
2318
2319 =item gmtime EXPR
2320 X<gmtime> X<UTC> X<Greenwich>
2321
2322 =item gmtime
2323
2324 Works just like L<localtime> but the returned values are
2325 localized for the standard Greenwich time zone.
2326
2327 Note: when called in list context, $isdst, the last value
2328 returned by gmtime is always C<0>.  There is no
2329 Daylight Saving Time in GMT.
2330
2331 See L<perlport/gmtime> for portability concerns.
2332
2333 =item goto LABEL
2334 X<goto> X<jump> X<jmp>
2335
2336 =item goto EXPR
2337
2338 =item goto &NAME
2339
2340 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2341 execution there.  It may not be used to go into any construct that
2342 requires initialization, such as a subroutine or a C<foreach> loop.  It
2343 also can't be used to go into a construct that is optimized away,
2344 or to get out of a block or subroutine given to C<sort>.
2345 It can be used to go almost anywhere else within the dynamic scope,
2346 including out of subroutines, but it's usually better to use some other
2347 construct such as C<last> or C<die>.  The author of Perl has never felt the
2348 need to use this form of C<goto> (in Perl, that is--C is another matter).
2349 (The difference being that C does not offer named loops combined with
2350 loop control.  Perl does, and this replaces most structured uses of C<goto>
2351 in other languages.)
2352
2353 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2354 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2355 necessarily recommended if you're optimizing for maintainability:
2356
2357     goto ("FOO", "BAR", "GLARCH")[$i];
2358
2359 The C<goto-&NAME> form is quite different from the other forms of
2360 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2361 doesn't have the stigma associated with other gotos.  Instead, it
2362 exits the current subroutine (losing any changes set by local()) and
2363 immediately calls in its place the named subroutine using the current
2364 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2365 load another subroutine and then pretend that the other subroutine had
2366 been called in the first place (except that any modifications to C<@_>
2367 in the current subroutine are propagated to the other subroutine.)
2368 After the C<goto>, not even C<caller> will be able to tell that this
2369 routine was called first.
2370
2371 NAME needn't be the name of a subroutine; it can be a scalar variable
2372 containing a code reference, or a block that evaluates to a code
2373 reference.
2374
2375 =item grep BLOCK LIST
2376 X<grep>
2377
2378 =item grep EXPR,LIST
2379
2380 This is similar in spirit to, but not the same as, grep(1) and its
2381 relatives.  In particular, it is not limited to using regular expressions.
2382
2383 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2384 C<$_> to each element) and returns the list value consisting of those
2385 elements for which the expression evaluated to true.  In scalar
2386 context, returns the number of times the expression was true.
2387
2388     @foo = grep(!/^#/, @bar);    # weed out comments
2389
2390 or equivalently,
2391
2392     @foo = grep {!/^#/} @bar;    # weed out comments
2393
2394 Note that C<$_> is an alias to the list value, so it can be used to
2395 modify the elements of the LIST.  While this is useful and supported,
2396 it can cause bizarre results if the elements of LIST are not variables.
2397 Similarly, grep returns aliases into the original list, much as a for
2398 loop's index variable aliases the list elements.  That is, modifying an
2399 element of a list returned by grep (for example, in a C<foreach>, C<map>
2400 or another C<grep>) actually modifies the element in the original list.
2401 This is usually something to be avoided when writing clear code.
2402
2403 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2404 been declared with C<my $_>) then, in addition to being locally aliased to
2405 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2406 can't be seen from the outside, avoiding any potential side-effects.
2407
2408 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2409
2410 =item hex EXPR
2411 X<hex> X<hexadecimal>
2412
2413 =item hex
2414
2415 Interprets EXPR as a hex string and returns the corresponding value.
2416 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2417 L</oct>.)  If EXPR is omitted, uses C<$_>.
2418
2419     print hex '0xAf'; # prints '175'
2420     print hex 'aF';   # same
2421
2422 Hex strings may only represent integers.  Strings that would cause
2423 integer overflow trigger a warning.  Leading whitespace is not stripped,
2424 unlike oct(). To present something as hex, look into L</printf>,
2425 L</sprintf>, or L</unpack>.
2426
2427 =item import LIST
2428 X<import>
2429
2430 There is no builtin C<import> function.  It is just an ordinary
2431 method (subroutine) defined (or inherited) by modules that wish to export
2432 names to another module.  The C<use> function calls the C<import> method
2433 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2434
2435 =item index STR,SUBSTR,POSITION
2436 X<index> X<indexOf> X<InStr>
2437
2438 =item index STR,SUBSTR
2439
2440 The index function searches for one string within another, but without
2441 the wildcard-like behavior of a full regular-expression pattern match.
2442 It returns the position of the first occurrence of SUBSTR in STR at
2443 or after POSITION.  If POSITION is omitted, starts searching from the
2444 beginning of the string.  POSITION before the beginning of the string
2445 or after its end is treated as if it were the beginning or the end,
2446 respectively.  POSITION and the return value are based at C<0> (or whatever
2447 you've set the C<$[> variable to--but don't do that).  If the substring
2448 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2449
2450 =item int EXPR
2451 X<int> X<integer> X<truncate> X<trunc> X<floor>
2452
2453 =item int
2454
2455 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2456 You should not use this function for rounding: one because it truncates
2457 towards C<0>, and two because machine representations of floating point
2458 numbers can sometimes produce counterintuitive results.  For example,
2459 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2460 because it's really more like -268.99999999999994315658 instead.  Usually,
2461 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2462 functions will serve you better than will int().
2463
2464 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2465 X<ioctl>
2466
2467 Implements the ioctl(2) function.  You'll probably first have to say
2468
2469     require "sys/ioctl.ph";     # probably in $Config{archlib}/sys/ioctl.ph
2470
2471 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2472 exist or doesn't have the correct definitions you'll have to roll your
2473 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2474 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2475 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2476 written depending on the FUNCTION--a pointer to the string value of SCALAR
2477 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2478 has no string value but does have a numeric value, that value will be
2479 passed rather than a pointer to the string value.  To guarantee this to be
2480 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2481 functions may be needed to manipulate the values of structures used by
2482 C<ioctl>.
2483
2484 The return value of C<ioctl> (and C<fcntl>) is as follows:
2485
2486         if OS returns:          then Perl returns:
2487             -1                    undefined value
2488              0                  string "0 but true"
2489         anything else               that number
2490
2491 Thus Perl returns true on success and false on failure, yet you can
2492 still easily determine the actual value returned by the operating
2493 system:
2494
2495     $retval = ioctl(...) || -1;
2496     printf "System returned %d\n", $retval;
2497
2498 The special string C<"0 but true"> is exempt from B<-w> complaints
2499 about improper numeric conversions.
2500
2501 =item join EXPR,LIST
2502 X<join>
2503
2504 Joins the separate strings of LIST into a single string with fields
2505 separated by the value of EXPR, and returns that new string.  Example:
2506
2507     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2508
2509 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2510 first argument.  Compare L</split>.
2511
2512 =item keys HASH
2513 X<keys> X<key>
2514
2515 Returns a list consisting of all the keys of the named hash.
2516 (In scalar context, returns the number of keys.)
2517
2518 The keys are returned in an apparently random order.  The actual
2519 random order is subject to change in future versions of perl, but it
2520 is guaranteed to be the same order as either the C<values> or C<each>
2521 function produces (given that the hash has not been modified).  Since
2522 Perl 5.8.1 the ordering is different even between different runs of
2523 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2524 Attacks">).
2525
2526 As a side effect, calling keys() resets the HASH's internal iterator
2527 (see L</each>).  In particular, calling keys() in void context resets
2528 the iterator with no other overhead.
2529
2530 Here is yet another way to print your environment:
2531
2532     @keys = keys %ENV;
2533     @values = values %ENV;
2534     while (@keys) {
2535         print pop(@keys), '=', pop(@values), "\n";
2536     }
2537
2538 or how about sorted by key:
2539
2540     foreach $key (sort(keys %ENV)) {
2541         print $key, '=', $ENV{$key}, "\n";
2542     }
2543
2544 The returned values are copies of the original keys in the hash, so
2545 modifying them will not affect the original hash.  Compare L</values>.
2546
2547 To sort a hash by value, you'll need to use a C<sort> function.
2548 Here's a descending numeric sort of a hash by its values:
2549
2550     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2551         printf "%4d %s\n", $hash{$key}, $key;
2552     }
2553
2554 As an lvalue C<keys> allows you to increase the number of hash buckets
2555 allocated for the given hash.  This can gain you a measure of efficiency if
2556 you know the hash is going to get big.  (This is similar to pre-extending
2557 an array by assigning a larger number to $#array.)  If you say
2558
2559     keys %hash = 200;
2560
2561 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2562 in fact, since it rounds up to the next power of two.  These
2563 buckets will be retained even if you do C<%hash = ()>, use C<undef
2564 %hash> if you want to free the storage while C<%hash> is still in scope.
2565 You can't shrink the number of buckets allocated for the hash using
2566 C<keys> in this way (but you needn't worry about doing this by accident,
2567 as trying has no effect).
2568
2569 See also C<each>, C<values> and C<sort>.
2570
2571 =item kill SIGNAL, LIST
2572 X<kill> X<signal>
2573
2574 Sends a signal to a list of processes.  Returns the number of
2575 processes successfully signaled (which is not necessarily the
2576 same as the number actually killed).
2577
2578     $cnt = kill 1, $child1, $child2;
2579     kill 9, @goners;
2580
2581 If SIGNAL is zero, no signal is sent to the process, but the kill(2)
2582 system call will check whether it's possible to send a signal to it (that
2583 means, to be brief, that the process is owned by the same user, or we are
2584 the super-user).  This is a useful way to check that a child process is
2585 alive (even if only as a zombie) and hasn't changed its UID.  See
2586 L<perlport> for notes on the portability of this construct.
2587
2588 Unlike in the shell, if SIGNAL is negative, it kills
2589 process groups instead of processes.  (On System V, a negative I<PROCESS>
2590 number will also kill process groups, but that's not portable.)  That
2591 means you usually want to use positive not negative signals.  You may also
2592 use a signal name in quotes.
2593
2594 See L<perlipc/"Signals"> for more details.
2595
2596 =item last LABEL
2597 X<last> X<break>
2598
2599 =item last
2600
2601 The C<last> command is like the C<break> statement in C (as used in
2602 loops); it immediately exits the loop in question.  If the LABEL is
2603 omitted, the command refers to the innermost enclosing loop.  The
2604 C<continue> block, if any, is not executed:
2605
2606     LINE: while (<STDIN>) {
2607         last LINE if /^$/;      # exit when done with header
2608         #...
2609     }
2610
2611 C<last> cannot be used to exit a block which returns a value such as
2612 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2613 a grep() or map() operation.
2614
2615 Note that a block by itself is semantically identical to a loop
2616 that executes once.  Thus C<last> can be used to effect an early
2617 exit out of such a block.
2618
2619 See also L</continue> for an illustration of how C<last>, C<next>, and
2620 C<redo> work.
2621
2622 =item lc EXPR
2623 X<lc> X<lowercase>
2624
2625 =item lc
2626
2627 Returns a lowercased version of EXPR.  This is the internal function
2628 implementing the C<\L> escape in double-quoted strings.  Respects
2629 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2630 and L<perlunicode> for more details about locale and Unicode support.
2631
2632 If EXPR is omitted, uses C<$_>.
2633
2634 =item lcfirst EXPR
2635 X<lcfirst> X<lowercase>
2636
2637 =item lcfirst
2638
2639 Returns the value of EXPR with the first character lowercased.  This
2640 is the internal function implementing the C<\l> escape in
2641 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2642 locale> in force.  See L<perllocale> and L<perlunicode> for more
2643 details about locale and Unicode support.
2644
2645 If EXPR is omitted, uses C<$_>.
2646
2647 =item length EXPR
2648 X<length> X<size>
2649
2650 =item length
2651
2652 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2653 omitted, returns length of C<$_>.  Note that this cannot be used on
2654 an entire array or hash to find out how many elements these have.
2655 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2656
2657 Note the I<characters>: if the EXPR is in Unicode, you will get the
2658 number of characters, not the number of bytes.  To get the length
2659 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2660
2661 =item link OLDFILE,NEWFILE
2662 X<link>
2663
2664 Creates a new filename linked to the old filename.  Returns true for
2665 success, false otherwise.
2666
2667 =item listen SOCKET,QUEUESIZE
2668 X<listen>
2669
2670 Does the same thing that the listen system call does.  Returns true if
2671 it succeeded, false otherwise.  See the example in
2672 L<perlipc/"Sockets: Client/Server Communication">.
2673
2674 =item local EXPR
2675 X<local>
2676
2677 You really probably want to be using C<my> instead, because C<local> isn't
2678 what most people think of as "local".  See
2679 L<perlsub/"Private Variables via my()"> for details.
2680
2681 A local modifies the listed variables to be local to the enclosing
2682 block, file, or eval.  If more than one value is listed, the list must
2683 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2684 for details, including issues with tied arrays and hashes.
2685
2686 =item localtime EXPR
2687 X<localtime> X<ctime>
2688
2689 =item localtime
2690
2691 Converts a time as returned by the time function to a 9-element list
2692 with the time analyzed for the local time zone.  Typically used as
2693 follows:
2694
2695     #  0    1    2     3     4    5     6     7     8
2696     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2697                                                 localtime(time);
2698
2699 All list elements are numeric, and come straight out of the C `struct
2700 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2701 of the specified time.
2702
2703 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2704 the range C<0..11> with 0 indicating January and 11 indicating December.
2705 This makes it easy to get a month name from a list:
2706
2707     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2708     print "$abbr[$mon] $mday";
2709     # $mon=9, $mday=18 gives "Oct 18"
2710
2711 C<$year> is the number of years since 1900, not just the last two digits
2712 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2713 to get a complete 4-digit year is simply:
2714
2715     $year += 1900;
2716
2717 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
2718 to do that, would you?
2719
2720 To get the last two digits of the year (e.g., '01' in 2001) do:
2721
2722     $year = sprintf("%02d", $year % 100);
2723
2724 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2725 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2726 (or C<0..365> in leap years.)
2727
2728 C<$isdst> is true if the specified time occurs during Daylight Saving
2729 Time, false otherwise.
2730
2731 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2732
2733 In scalar context, C<localtime()> returns the ctime(3) value:
2734
2735     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2736
2737 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2738 instead of local time use the L</gmtime> builtin. See also the
2739 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2740 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2741 and mktime(3) functions.
2742
2743 To get somewhat similar but locale dependent date strings, set up your
2744 locale environment variables appropriately (please see L<perllocale>) and
2745 try for example:
2746
2747     use POSIX qw(strftime);
2748     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2749     # or for GMT formatted appropriately for your locale:
2750     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2751
2752 Note that the C<%a> and C<%b>, the short forms of the day of the week
2753 and the month of the year, may not necessarily be three characters wide.
2754
2755 See L<perlport/localtime> for portability concerns.
2756
2757 The L<Time::gmtime> and L<Time::localtime> modules provides a convenient,
2758 by-name access mechanism to the gmtime() and localtime() functions,
2759 respectively.
2760
2761 For a comprehensive date and time representation look at the
2762 L<DateTime> module on CPAN.
2763
2764 =item lock THING
2765 X<lock>
2766
2767 This function places an advisory lock on a shared variable, or referenced
2768 object contained in I<THING> until the lock goes out of scope.
2769
2770 lock() is a "weak keyword" : this means that if you've defined a function
2771 by this name (before any calls to it), that function will be called
2772 instead. (However, if you've said C<use threads>, lock() is always a
2773 keyword.) See L<threads>.
2774
2775 =item log EXPR
2776 X<log> X<logarithm> X<e> X<ln> X<base>
2777
2778 =item log
2779
2780 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2781 returns log of C<$_>.  To get the log of another base, use basic algebra:
2782 The base-N log of a number is equal to the natural log of that number
2783 divided by the natural log of N.  For example:
2784
2785     sub log10 {
2786         my $n = shift;
2787         return log($n)/log(10);
2788     }
2789
2790 See also L</exp> for the inverse operation.
2791
2792 =item lstat EXPR
2793 X<lstat>
2794
2795 =item lstat
2796
2797 Does the same thing as the C<stat> function (including setting the
2798 special C<_> filehandle) but stats a symbolic link instead of the file
2799 the symbolic link points to.  If symbolic links are unimplemented on
2800 your system, a normal C<stat> is done.  For much more detailed
2801 information, please see the documentation for C<stat>.
2802
2803 If EXPR is omitted, stats C<$_>.
2804
2805 =item m//
2806
2807 The match operator.  See L<perlop>.
2808
2809 =item map BLOCK LIST
2810 X<map>
2811
2812 =item map EXPR,LIST
2813
2814 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2815 C<$_> to each element) and returns the list value composed of the
2816 results of each such evaluation.  In scalar context, returns the
2817 total number of elements so generated.  Evaluates BLOCK or EXPR in
2818 list context, so each element of LIST may produce zero, one, or
2819 more elements in the returned value.
2820
2821     @chars = map(chr, @nums);
2822
2823 translates a list of numbers to the corresponding characters.  And
2824
2825     %hash = map { getkey($_) => $_ } @array;
2826
2827 is just a funny way to write
2828
2829     %hash = ();
2830     foreach $_ (@array) {
2831         $hash{getkey($_)} = $_;
2832     }
2833
2834 Note that C<$_> is an alias to the list value, so it can be used to
2835 modify the elements of the LIST.  While this is useful and supported,
2836 it can cause bizarre results if the elements of LIST are not variables.
2837 Using a regular C<foreach> loop for this purpose would be clearer in
2838 most cases.  See also L</grep> for an array composed of those items of
2839 the original list for which the BLOCK or EXPR evaluates to true.
2840
2841 If C<$_> is lexical in the scope where the C<map> appears (because it has
2842 been declared with C<my $_>) then, in addition to being locally aliased to
2843 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2844 can't be seen from the outside, avoiding any potential side-effects.
2845
2846 C<{> starts both hash references and blocks, so C<map { ...> could be either
2847 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2848 ahead for the closing C<}> it has to take a guess at which its dealing with
2849 based what it finds just after the C<{>. Usually it gets it right, but if it
2850 doesn't it won't realize something is wrong until it gets to the C<}> and
2851 encounters the missing (or unexpected) comma. The syntax error will be
2852 reported close to the C<}> but you'll need to change something near the C<{>
2853 such as using a unary C<+> to give perl some help:
2854
2855     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2856     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2857     %hash = map { ("\L$_", 1) } @array  # this also works
2858     %hash = map {  lc($_), 1  } @array  # as does this.
2859     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2860
2861     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2862
2863 or to force an anon hash constructor use C<+{>
2864
2865    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2866
2867 and you get list of anonymous hashes each with only 1 entry.
2868
2869 =item mkdir FILENAME,MASK
2870 X<mkdir> X<md> X<directory, create>
2871
2872 =item mkdir FILENAME
2873
2874 =item mkdir
2875
2876 Creates the directory specified by FILENAME, with permissions
2877 specified by MASK (as modified by C<umask>).  If it succeeds it
2878 returns true, otherwise it returns false and sets C<$!> (errno).
2879 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2880 to C<$_>.
2881
2882 In general, it is better to create directories with permissive MASK,
2883 and let the user modify that with their C<umask>, than it is to supply
2884 a restrictive MASK and give the user no way to be more permissive.
2885 The exceptions to this rule are when the file or directory should be
2886 kept private (mail files, for instance).  The perlfunc(1) entry on
2887 C<umask> discusses the choice of MASK in more detail.
2888
2889 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2890 number of trailing slashes.  Some operating and filesystems do not get
2891 this right, so Perl automatically removes all trailing slashes to keep
2892 everyone happy.
2893
2894 In order to recursively create a directory structure look at
2895 the C<mkpath> function of the L<File::Path> module.
2896
2897 =item msgctl ID,CMD,ARG
2898 X<msgctl>
2899
2900 Calls the System V IPC function msgctl(2).  You'll probably have to say
2901
2902     use IPC::SysV;
2903
2904 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2905 then ARG must be a variable that will hold the returned C<msqid_ds>
2906 structure.  Returns like C<ioctl>: the undefined value for error,
2907 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2908 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2909
2910 =item msgget KEY,FLAGS
2911 X<msgget>
2912
2913 Calls the System V IPC function msgget(2).  Returns the message queue
2914 id, or the undefined value if there is an error.  See also
2915 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2916
2917 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2918 X<msgrcv>
2919
2920 Calls the System V IPC function msgrcv to receive a message from
2921 message queue ID into variable VAR with a maximum message size of
2922 SIZE.  Note that when a message is received, the message type as a
2923 native long integer will be the first thing in VAR, followed by the
2924 actual message.  This packing may be opened with C<unpack("l! a*")>.
2925 Taints the variable.  Returns true if successful, or false if there is
2926 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2927 C<IPC::SysV::Msg> documentation.
2928
2929 =item msgsnd ID,MSG,FLAGS
2930 X<msgsnd>
2931
2932 Calls the System V IPC function msgsnd to send the message MSG to the
2933 message queue ID.  MSG must begin with the native long integer message
2934 type, and be followed by the length of the actual message, and finally
2935 the message itself.  This kind of packing can be achieved with
2936 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2937 or false if there is an error.  See also C<IPC::SysV>
2938 and C<IPC::SysV::Msg> documentation.
2939
2940 =item my EXPR
2941 X<my>
2942
2943 =item my TYPE EXPR
2944
2945 =item my EXPR : ATTRS
2946
2947 =item my TYPE EXPR : ATTRS
2948
2949 A C<my> declares the listed variables to be local (lexically) to the
2950 enclosing block, file, or C<eval>.  If more than one value is listed,
2951 the list must be placed in parentheses.
2952
2953 The exact semantics and interface of TYPE and ATTRS are still
2954 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2955 and attributes are handled using the C<attributes> pragma, or starting
2956 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2957 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2958 L<attributes>, and L<Attribute::Handlers>.
2959
2960 =item next LABEL
2961 X<next> X<continue>
2962
2963 =item next
2964
2965 The C<next> command is like the C<continue> statement in C; it starts
2966 the next iteration of the loop:
2967
2968     LINE: while (<STDIN>) {
2969         next LINE if /^#/;      # discard comments
2970         #...
2971     }
2972
2973 Note that if there were a C<continue> block on the above, it would get
2974 executed even on discarded lines.  If the LABEL is omitted, the command
2975 refers to the innermost enclosing loop.
2976
2977 C<next> cannot be used to exit a block which returns a value such as
2978 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2979 a grep() or map() operation.
2980
2981 Note that a block by itself is semantically identical to a loop
2982 that executes once.  Thus C<next> will exit such a block early.
2983
2984 See also L</continue> for an illustration of how C<last>, C<next>, and
2985 C<redo> work.
2986
2987 =item no Module VERSION LIST
2988 X<no>
2989
2990 =item no Module VERSION
2991
2992 =item no Module LIST
2993
2994 =item no Module
2995
2996 See the C<use> function, of which C<no> is the opposite.
2997
2998 =item oct EXPR
2999 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3000
3001 =item oct
3002
3003 Interprets EXPR as an octal string and returns the corresponding
3004 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3005 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3006 binary string.  Leading whitespace is ignored in all three cases.)
3007 The following will handle decimal, binary, octal, and hex in the standard
3008 Perl or C notation:
3009
3010     $val = oct($val) if $val =~ /^0/;
3011
3012 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3013 in octal), use sprintf() or printf():
3014
3015     $perms = (stat("filename"))[2] & 07777;
3016     $oct_perms = sprintf "%lo", $perms;
3017
3018 The oct() function is commonly used when a string such as C<644> needs
3019 to be converted into a file mode, for example. (Although perl will
3020 automatically convert strings into numbers as needed, this automatic
3021 conversion assumes base 10.)
3022
3023 =item open FILEHANDLE,EXPR
3024 X<open> X<pipe> X<file, open> X<fopen>
3025
3026 =item open FILEHANDLE,MODE,EXPR
3027
3028 =item open FILEHANDLE,MODE,EXPR,LIST
3029
3030 =item open FILEHANDLE,MODE,REFERENCE
3031
3032 =item open FILEHANDLE
3033
3034 Opens the file whose filename is given by EXPR, and associates it with
3035 FILEHANDLE.
3036
3037 (The following is a comprehensive reference to open(): for a gentler
3038 introduction you may consider L<perlopentut>.)
3039
3040 If FILEHANDLE is an undefined scalar variable (or array or hash element)
3041 the variable is assigned a reference to a new anonymous filehandle,
3042 otherwise if FILEHANDLE is an expression, its value is used as the name of
3043 the real filehandle wanted.  (This is considered a symbolic reference, so
3044 C<use strict 'refs'> should I<not> be in effect.)
3045
3046 If EXPR is omitted, the scalar variable of the same name as the
3047 FILEHANDLE contains the filename.  (Note that lexical variables--those
3048 declared with C<my>--will not work for this purpose; so if you're
3049 using C<my>, specify EXPR in your call to open.)
3050
3051 If three or more arguments are specified then the mode of opening and
3052 the file name are separate. If MODE is C<< '<' >> or nothing, the file
3053 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
3054 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
3055 the file is opened for appending, again being created if necessary.
3056
3057 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
3058 indicate that you want both read and write access to the file; thus
3059 C<< '+<' >> is almost always preferred for read/write updates--the C<<
3060 '+>' >> mode would clobber the file first.  You can't usually use
3061 either read-write mode for updating textfiles, since they have
3062 variable length records.  See the B<-i> switch in L<perlrun> for a
3063 better approach.  The file is created with permissions of C<0666>
3064 modified by the process' C<umask> value.
3065
3066 These various prefixes correspond to the fopen(3) modes of C<'r'>,
3067 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
3068
3069 In the 2-arguments (and 1-argument) form of the call the mode and
3070 filename should be concatenated (in this order), possibly separated by
3071 spaces.  It is possible to omit the mode in these forms if the mode is
3072 C<< '<' >>.
3073
3074 If the filename begins with C<'|'>, the filename is interpreted as a
3075 command to which output is to be piped, and if the filename ends with a
3076 C<'|'>, the filename is interpreted as a command which pipes output to
3077 us.  See L<perlipc/"Using open() for IPC">
3078 for more examples of this.  (You are not allowed to C<open> to a command
3079 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
3080 and L<perlipc/"Bidirectional Communication with Another Process">
3081 for alternatives.)
3082
3083 For three or more arguments if MODE is C<'|-'>, the filename is
3084 interpreted as a command to which output is to be piped, and if MODE
3085 is C<'-|'>, the filename is interpreted as a command which pipes
3086 output to us.  In the 2-arguments (and 1-argument) form one should
3087 replace dash (C<'-'>) with the command.
3088 See L<perlipc/"Using open() for IPC"> for more examples of this.
3089 (You are not allowed to C<open> to a command that pipes both in I<and>
3090 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3091 L<perlipc/"Bidirectional Communication"> for alternatives.)
3092
3093 In the three-or-more argument form of pipe opens, if LIST is specified
3094 (extra arguments after the command name) then LIST becomes arguments
3095 to the command invoked if the platform supports it.  The meaning of
3096 C<open> with more than three arguments for non-pipe modes is not yet
3097 specified. Experimental "layers" may give extra LIST arguments
3098 meaning.
3099
3100 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
3101 and opening C<< '>-' >> opens STDOUT.
3102
3103 You may use the three-argument form of open to specify IO "layers"
3104 (sometimes also referred to as "disciplines") to be applied to the handle
3105 that affect how the input and output are processed (see L<open> and
3106 L<PerlIO> for more details). For example
3107
3108   open(FH, "<:utf8", "file")
3109
3110 will open the UTF-8 encoded file containing Unicode characters,
3111 see L<perluniintro>. Note that if layers are specified in the
3112 three-arg form then default layers stored in ${^OPEN} (see L<perlvar>;
3113 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3114
3115 Open returns nonzero upon success, the undefined value otherwise.  If
3116 the C<open> involved a pipe, the return value happens to be the pid of
3117 the subprocess.
3118
3119 If you're running Perl on a system that distinguishes between text
3120 files and binary files, then you should check out L</binmode> for tips
3121 for dealing with this.  The key distinction between systems that need
3122 C<binmode> and those that don't is their text file formats.  Systems
3123 like Unix, Mac OS, and Plan 9, which delimit lines with a single
3124 character, and which encode that character in C as C<"\n">, do not
3125 need C<binmode>.  The rest need it.
3126
3127 When opening a file, it's usually a bad idea to continue normal execution
3128 if the request failed, so C<open> is frequently used in connection with
3129 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3130 where you want to make a nicely formatted error message (but there are
3131 modules that can help with that problem)) you should always check
3132 the return value from opening a file.  The infrequent exception is when
3133 working with an unopened filehandle is actually what you want to do.
3134
3135 As a special case the 3-arg form with a read/write mode and the third
3136 argument being C<undef>:
3137
3138     open(TMP, "+>", undef) or die ...
3139
3140 opens a filehandle to an anonymous temporary file.  Also using "+<"
3141 works for symmetry, but you really should consider writing something
3142 to the temporary file first.  You will need to seek() to do the
3143 reading.
3144
3145 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
3146 changed this (i.e. Configure -Uuseperlio), you can open file handles to
3147 "in memory" files held in Perl scalars via:
3148
3149     open($fh, '>', \$variable) || ..
3150
3151 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
3152 file, you have to close it first:
3153
3154     close STDOUT;
3155     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3156
3157 Examples:
3158
3159     $ARTICLE = 100;
3160     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3161     while (<ARTICLE>) {...
3162
3163     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
3164     # if the open fails, output is discarded
3165
3166     open(DBASE, '+<', 'dbase.mine')             # open for update
3167         or die "Can't open 'dbase.mine' for update: $!";
3168
3169     open(DBASE, '+<dbase.mine')                 # ditto
3170         or die "Can't open 'dbase.mine' for update: $!";
3171
3172     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
3173         or die "Can't start caesar: $!";
3174
3175     open(ARTICLE, "caesar <$article |")         # ditto
3176         or die "Can't start caesar: $!";
3177
3178     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
3179         or die "Can't start sort: $!";
3180
3181     # in memory files
3182     open(MEMORY,'>', \$var)
3183         or die "Can't open memory file: $!";
3184     print MEMORY "foo!\n";                      # output will end up in $var
3185
3186     # process argument list of files along with any includes
3187
3188     foreach $file (@ARGV) {
3189         process($file, 'fh00');
3190     }
3191
3192     sub process {
3193         my($filename, $input) = @_;
3194         $input++;               # this is a string increment
3195         unless (open($input, $filename)) {
3196             print STDERR "Can't open $filename: $!\n";
3197             return;
3198         }
3199
3200         local $_;
3201         while (<$input>) {              # note use of indirection
3202             if (/^#include "(.*)"/) {
3203                 process($1, $input);
3204                 next;
3205             }
3206             #...                # whatever
3207         }
3208     }
3209
3210 See L<perliol> for detailed info on PerlIO.
3211
3212 You may also, in the Bourne shell tradition, specify an EXPR beginning
3213 with C<< '>&' >>, in which case the rest of the string is interpreted
3214 as the name of a filehandle (or file descriptor, if numeric) to be
3215 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3216 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3217 The mode you specify should match the mode of the original filehandle.
3218 (Duping a filehandle does not take into account any existing contents
3219 of IO buffers.) If you use the 3-arg form then you can pass either a
3220 number, the name of a filehandle or the normal "reference to a glob".
3221
3222 Here is a script that saves, redirects, and restores C<STDOUT> and
3223 C<STDERR> using various methods:
3224
3225     #!/usr/bin/perl
3226     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3227     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3228
3229     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3230     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3231
3232     select STDERR; $| = 1;      # make unbuffered
3233     select STDOUT; $| = 1;      # make unbuffered
3234
3235     print STDOUT "stdout 1\n";  # this works for
3236     print STDERR "stderr 1\n";  # subprocesses too
3237
3238     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3239     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3240
3241     print STDOUT "stdout 2\n";
3242     print STDERR "stderr 2\n";
3243
3244 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3245 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3246 that file descriptor (and not call L<dup(2)>); this is more
3247 parsimonious of file descriptors.  For example:
3248
3249     # open for input, reusing the fileno of $fd
3250     open(FILEHANDLE, "<&=$fd")
3251
3252 or
3253
3254     open(FILEHANDLE, "<&=", $fd)
3255
3256 or
3257
3258     # open for append, using the fileno of OLDFH
3259     open(FH, ">>&=", OLDFH)
3260
3261 or
3262
3263     open(FH, ">>&=OLDFH")
3264
3265 Being parsimonious on filehandles is also useful (besides being
3266 parsimonious) for example when something is dependent on file
3267 descriptors, like for example locking using flock().  If you do just
3268 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3269 descriptor as B, and therefore flock(A) will not flock(B), and vice
3270 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3271 the same file descriptor.
3272
3273 Note that if you are using Perls older than 5.8.0, Perl will be using
3274 the standard C libraries' fdopen() to implement the "=" functionality.
3275 On many UNIX systems fdopen() fails when file descriptors exceed a
3276 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3277 most often the default.
3278
3279 You can see whether Perl has been compiled with PerlIO or not by
3280 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3281 is C<define>, you have PerlIO, otherwise you don't.
3282
3283 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3284 with 2-arguments (or 1-argument) form of open(), then
3285 there is an implicit fork done, and the return value of open is the pid
3286 of the child within the parent process, and C<0> within the child
3287 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3288 The filehandle behaves normally for the parent, but i/o to that
3289 filehandle is piped from/to the STDOUT/STDIN of the child process.
3290 In the child process the filehandle isn't opened--i/o happens from/to
3291 the new STDOUT or STDIN.  Typically this is used like the normal
3292 piped open when you want to exercise more control over just how the
3293 pipe command gets executed, such as when you are running setuid, and
3294 don't want to have to scan shell commands for metacharacters.
3295 The following triples are more or less equivalent:
3296
3297     open(FOO, "|tr '[a-z]' '[A-Z]'");
3298     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3299     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3300     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3301
3302     open(FOO, "cat -n '$file'|");
3303     open(FOO, '-|', "cat -n '$file'");
3304     open(FOO, '-|') || exec 'cat', '-n', $file;
3305     open(FOO, '-|', "cat", '-n', $file);
3306
3307 The last example in each block shows the pipe as "list form", which is
3308 not yet supported on all platforms.  A good rule of thumb is that if
3309 your platform has true C<fork()> (in other words, if your platform is
3310 UNIX) you can use the list form.
3311
3312 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3313
3314 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3315 output before any operation that may do a fork, but this may not be
3316 supported on some platforms (see L<perlport>).  To be safe, you may need
3317 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3318 of C<IO::Handle> on any open handles.
3319
3320 On systems that support a close-on-exec flag on files, the flag will
3321 be set for the newly opened file descriptor as determined by the value
3322 of $^F.  See L<perlvar/$^F>.
3323
3324 Closing any piped filehandle causes the parent process to wait for the
3325 child to finish, and returns the status value in C<$?> and
3326 C<${^CHILD_ERROR_NATIVE}>.
3327
3328 The filename passed to 2-argument (or 1-argument) form of open() will
3329 have leading and trailing whitespace deleted, and the normal
3330 redirection characters honored.  This property, known as "magic open",
3331 can often be used to good effect.  A user could specify a filename of
3332 F<"rsh cat file |">, or you could change certain filenames as needed:
3333
3334     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3335     open(FH, $filename) or die "Can't open $filename: $!";
3336
3337 Use 3-argument form to open a file with arbitrary weird characters in it,
3338
3339     open(FOO, '<', $file);
3340
3341 otherwise it's necessary to protect any leading and trailing whitespace:
3342
3343     $file =~ s#^(\s)#./$1#;
3344     open(FOO, "< $file\0");
3345
3346 (this may not work on some bizarre filesystems).  One should
3347 conscientiously choose between the I<magic> and 3-arguments form
3348 of open():
3349
3350     open IN, $ARGV[0];
3351
3352 will allow the user to specify an argument of the form C<"rsh cat file |">,
3353 but will not work on a filename which happens to have a trailing space, while
3354
3355     open IN, '<', $ARGV[0];
3356
3357 will have exactly the opposite restrictions.
3358
3359 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3360 should use the C<sysopen> function, which involves no such magic (but
3361 may use subtly different filemodes than Perl open(), which is mapped
3362 to C fopen()).  This is
3363 another way to protect your filenames from interpretation.  For example:
3364
3365     use IO::Handle;
3366     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3367         or die "sysopen $path: $!";
3368     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3369     print HANDLE "stuff $$\n";
3370     seek(HANDLE, 0, 0);
3371     print "File contains: ", <HANDLE>;
3372
3373 Using the constructor from the C<IO::Handle> package (or one of its
3374 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3375 filehandles that have the scope of whatever variables hold references to
3376 them, and automatically close whenever and however you leave that scope:
3377
3378     use IO::File;
3379     #...
3380     sub read_myfile_munged {
3381         my $ALL = shift;
3382         my $handle = new IO::File;
3383         open($handle, "myfile") or die "myfile: $!";
3384         $first = <$handle>
3385             or return ();     # Automatically closed here.
3386         mung $first or die "mung failed";       # Or here.
3387         return $first, <$handle> if $ALL;       # Or here.
3388         $first;                                 # Or here.
3389     }
3390
3391 See L</seek> for some details about mixing reading and writing.
3392
3393 =item opendir DIRHANDLE,EXPR
3394 X<opendir>
3395
3396 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3397 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3398 DIRHANDLE may be an expression whose value can be used as an indirect
3399 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3400 scalar variable (or array or hash element), the variable is assigned a
3401 reference to a new anonymous dirhandle.
3402 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3403
3404 =item ord EXPR
3405 X<ord> X<encoding>
3406
3407 =item ord
3408
3409 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3410 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3411 uses C<$_>.
3412
3413 For the reverse, see L</chr>.
3414 See L<perlunicode> and L<encoding> for more about Unicode.
3415
3416 =item our EXPR
3417 X<our> X<global>
3418
3419 =item our TYPE EXPR
3420
3421 =item our EXPR : ATTRS
3422
3423 =item our TYPE EXPR : ATTRS
3424
3425 C<our> associates a simple name with a package variable in the current
3426 package for use within the current scope.  When C<use strict 'vars'> is in
3427 effect, C<our> lets you use declared global variables without qualifying
3428 them with package names, within the lexical scope of the C<our> declaration.
3429 In this way C<our> differs from C<use vars>, which is package scoped.
3430
3431 Unlike C<my>, which both allocates storage for a variable and associates
3432 a simple name with that storage for use within the current scope, C<our>
3433 associates a simple name with a package variable in the current package,
3434 for use within the current scope.  In other words, C<our> has the same
3435 scoping rules as C<my>, but does not necessarily create a
3436 variable.
3437
3438 If more than one value is listed, the list must be placed
3439 in parentheses.
3440
3441     our $foo;
3442     our($bar, $baz);
3443
3444 An C<our> declaration declares a global variable that will be visible
3445 across its entire lexical scope, even across package boundaries.  The
3446 package in which the variable is entered is determined at the point
3447 of the declaration, not at the point of use.  This means the following
3448 behavior holds:
3449
3450     package Foo;
3451     our $bar;           # declares $Foo::bar for rest of lexical scope
3452     $bar = 20;
3453
3454     package Bar;
3455     print $bar;         # prints 20, as it refers to $Foo::bar
3456
3457 Multiple C<our> declarations with the same name in the same lexical
3458 scope are allowed if they are in different packages.  If they happen
3459 to be in the same package, Perl will emit warnings if you have asked
3460 for them, just like multiple C<my> declarations.  Unlike a second
3461 C<my> declaration, which will bind the name to a fresh variable, a
3462 second C<our> declaration in the same package, in the same scope, is
3463 merely redundant.
3464
3465     use warnings;
3466     package Foo;
3467     our $bar;           # declares $Foo::bar for rest of lexical scope
3468     $bar = 20;
3469
3470     package Bar;
3471     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3472     print $bar;         # prints 30
3473
3474     our $bar;           # emits warning but has no other effect
3475     print $bar;         # still prints 30
3476
3477 An C<our> declaration may also have a list of attributes associated
3478 with it.
3479
3480 The exact semantics and interface of TYPE and ATTRS are still
3481 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3482 and attributes are handled using the C<attributes> pragma, or starting
3483 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3484 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3485 L<attributes>, and L<Attribute::Handlers>.
3486
3487 =item pack TEMPLATE,LIST
3488 X<pack>
3489
3490 Takes a LIST of values and converts it into a string using the rules
3491 given by the TEMPLATE.  The resulting string is the concatenation of
3492 the converted values.  Typically, each converted value looks
3493 like its machine-level representation.  For example, on 32-bit machines
3494 an integer may be represented by a sequence of 4 bytes that will be 
3495 converted to a sequence of 4 characters.
3496
3497 The TEMPLATE is a sequence of characters that give the order and type
3498 of values, as follows:
3499
3500     a   A string with arbitrary binary data, will be null padded.
3501     A   A text (ASCII) string, will be space padded.
3502     Z   A null terminated (ASCIZ) string, will be null padded.
3503
3504     b   A bit string (ascending bit order inside each byte, like vec()).
3505     B   A bit string (descending bit order inside each byte).
3506     h   A hex string (low nybble first).
3507     H   A hex string (high nybble first).
3508
3509     c   A signed char (8-bit) value.
3510     C   An unsigned C char (octet) even under Unicode. Should normally not
3511         be used. See U and W instead.
3512     W   An unsigned char value (can be greater than 255).
3513
3514     s   A signed short (16-bit) value.
3515     S   An unsigned short value.
3516
3517     l   A signed long (32-bit) value.
3518     L   An unsigned long value.
3519
3520     q   A signed quad (64-bit) value.
3521     Q   An unsigned quad value.
3522           (Quads are available only if your system supports 64-bit
3523            integer values _and_ if Perl has been compiled to support those.
3524            Causes a fatal error otherwise.)
3525
3526     i   A signed integer value.
3527     I   A unsigned integer value.
3528           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3529            size depends on what a local C compiler calls 'int'.)
3530
3531     n   An unsigned short (16-bit) in "network" (big-endian) order.
3532     N   An unsigned long (32-bit) in "network" (big-endian) order.
3533     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3534     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3535
3536     j   A Perl internal signed integer value (IV).
3537     J   A Perl internal unsigned integer value (UV).
3538
3539     f   A single-precision float in the native format.
3540     d   A double-precision float in the native format.
3541
3542     F   A Perl internal floating point value (NV) in the native format
3543     D   A long double-precision float in the native format.
3544           (Long doubles are available only if your system supports long
3545            double values _and_ if Perl has been compiled to support those.
3546            Causes a fatal error otherwise.)
3547
3548     p   A pointer to a null-terminated string.
3549     P   A pointer to a structure (fixed-length string).
3550
3551     u   A uuencoded string.
3552     U   A Unicode character number.  Encodes to UTF-8 internally
3553         (or UTF-EBCDIC in EBCDIC platforms).
3554
3555     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3556         details).  Its bytes represent an unsigned integer in base 128,
3557         most significant digit first, with as few digits as possible.  Bit
3558         eight (the high bit) is set on each byte except the last.
3559
3560     x   A null byte.
3561     X   Back up a byte.
3562     @   Null fill or truncate to absolute position, counted from the
3563         start of the innermost ()-group.
3564     .   Null fill or truncate to absolute position specified by value.
3565     (   Start of a ()-group.
3566
3567 One or more of the modifiers below may optionally follow some letters in the
3568 TEMPLATE (the second column lists the letters for which the modifier is
3569 valid):
3570
3571     !   sSlLiI     Forces native (short, long, int) sizes instead
3572                    of fixed (16-/32-bit) sizes.
3573
3574         xX         Make x and X act as alignment commands.
3575
3576         nNvV       Treat integers as signed instead of unsigned.
3577
3578         @.         Specify position as byte offset in the internal
3579                    representation of the packed string. Efficient but
3580                    dangerous.
3581
3582     >   sSiIlLqQ   Force big-endian byte-order on the type.
3583         jJfFdDpP   (The "big end" touches the construct.)
3584
3585     <   sSiIlLqQ   Force little-endian byte-order on the type.
3586         jJfFdDpP   (The "little end" touches the construct.)
3587
3588 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3589 in which case they force a certain byte-order on all components of
3590 that group, including subgroups.
3591
3592 The following rules apply:
3593
3594 =over 8
3595
3596 =item *
3597
3598 Each letter may optionally be followed by a number giving a repeat
3599 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3600 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3601 that many values from the LIST.  A C<*> for the repeat count means to
3602 use however many items are left, except for C<@>, C<x>, C<X>, where it
3603 is equivalent to C<0>, for <.> where it means relative to string start
3604 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3605 A numeric repeat count may optionally be enclosed in brackets, as in
3606 C<pack 'C[80]', @arr>.
3607
3608 One can replace the numeric repeat count by a template enclosed in brackets;
3609 then the packed length of this template in bytes is used as a count.
3610 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3611 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3612 If the template in brackets contains alignment commands (such as C<x![d]>),
3613 its packed length is calculated as if the start of the template has the maximal
3614 possible alignment.
3615
3616 When used with C<Z>, C<*> results in the addition of a trailing null
3617 byte (so the packed result will be one longer than the byte C<length>
3618 of the item).
3619
3620 When used with C<@>, the repeat count represents an offset from the start
3621 of the innermost () group.
3622
3623 When used with C<.>, the repeat count is used to determine the starting
3624 position from where the value offset is calculated. If the repeat count
3625 is 0, it's relative to the current position. If the repeat count is C<*>,
3626 the offset is relative to the start of the packed string. And if its an
3627 integer C<n> the offset is relative to the start of the n-th innermost
3628 () group (or the start of the string if C<n> is bigger then the group
3629 level).
3630
3631 The repeat count for C<u> is interpreted as the maximal number of bytes
3632 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3633 count should not be more than 65.
3634
3635 =item *
3636
3637 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3638 string of length count, padding with nulls or spaces as necessary.  When
3639 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3640 after the first null, and C<a> returns data verbatim.
3641
3642 If the value-to-pack is too long, it is truncated.  If too long and an
3643 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3644 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3645 count is 0).
3646
3647 =item *
3648
3649 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3650 Each character of the input field of pack() generates 1 bit of the result.
3651 Each result bit is based on the least-significant bit of the corresponding
3652 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3653 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3654
3655 Starting from the beginning of the input string of pack(), each 8-tuple
3656 of characters is converted to 1 character of output.  With format C<b>
3657 the first character of the 8-tuple determines the least-significant bit of a
3658 character, and with format C<B> it determines the most-significant bit of
3659 a character.
3660
3661 If the length of the input string is not exactly divisible by 8, the
3662 remainder is packed as if the input string were padded by null characters
3663 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3664
3665 If the input string of pack() is longer than needed, extra characters are 
3666 ignored. A C<*> for the repeat count of pack() means to use all the 
3667 characters of the input field.  On unpack()ing the bits are converted to a 
3668 string of C<"0">s and C<"1">s.
3669
3670 =item *
3671
3672 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3673 representable as hexadecimal digits, 0-9a-f) long.
3674
3675 Each character of the input field of pack() generates 4 bits of the result.
3676 For non-alphabetical characters the result is based on the 4 least-significant
3677 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3678 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3679 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3680 is compatible with the usual hexadecimal digits, so that C<"a"> and
3681 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3682 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3683
3684 Starting from the beginning of the input string of pack(), each pair
3685 of characters is converted to 1 character of output.  With format C<h> the
3686 first character of the pair determines the least-significant nybble of the
3687 output character, and with format C<H> it determines the most-significant
3688 nybble.
3689
3690 If the length of the input string is not even, it behaves as if padded
3691 by a null character at the end.  Similarly, during unpack()ing the "extra"
3692 nybbles are ignored.
3693
3694 If the input string of pack() is longer than needed, extra characters are
3695 ignored.
3696 A C<*> for the repeat count of pack() means to use all the characters of
3697 the input field.  On unpack()ing the nybbles are converted to a string
3698 of hexadecimal digits.
3699
3700 =item *
3701
3702 The C<p> type packs a pointer to a null-terminated string.  You are
3703 responsible for ensuring the string is not a temporary value (which can
3704 potentially get deallocated before you get around to using the packed result).
3705 The C<P> type packs a pointer to a structure of the size indicated by the
3706 length.  A NULL pointer is created if the corresponding value for C<p> or
3707 C<P> is C<undef>, similarly for unpack().
3708
3709 If your system has a strange pointer size (i.e. a pointer is neither as
3710 big as an int nor as big as a long), it may not be possible to pack or
3711 unpack pointers in big- or little-endian byte order.  Attempting to do
3712 so will result in a fatal error.
3713
3714 =item *
3715
3716 The C</> template character allows packing and unpacking of a sequence of
3717 items where the packed structure contains a packed item count followed by 
3718 the packed items themselves.
3719
3720 For C<pack> you write I<length-item>C</>I<sequence-item> and the
3721 I<length-item> describes how the length value is packed. The ones likely
3722 to be of most use are integer-packing ones like C<n> (for Java strings),
3723 C<w> (for ASN.1 or SNMP) and C<N> (for Sun XDR).
3724
3725 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3726 the minimum of that and the number of available items is used as argument
3727 for the I<length-item>. If it has no repeat count or uses a '*', the number
3728 of available items is used.
3729
3730 For C<unpack> an internal stack of integer arguments unpacked so far is
3731 used. You write C</>I<sequence-item> and the repeat count is obtained by
3732 popping off the last element from the stack. The I<sequence-item> must not
3733 have a repeat count.
3734
3735 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3736 the I<length-item> is a string length, not a number of strings. If there is
3737 an explicit repeat count for pack, the packed string will be adjusted to that
3738 given length.
3739
3740     unpack 'W/a', "\04Gurusamy";            gives ('Guru')
3741     unpack 'a3/A A*', '007 Bond  J ';       gives (' Bond', 'J')
3742     unpack 'a3 x2 /A A*', '007: Bond, J.';  gives ('Bond, J', '.')
3743     pack 'n/a* w/a','hello,','world';       gives "\000\006hello,\005world"
3744     pack 'a/W2', ord('a') .. ord('z');      gives '2ab'
3745
3746 The I<length-item> is not returned explicitly from C<unpack>.
3747
3748 Adding a count to the I<length-item> letter is unlikely to do anything
3749 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3750 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3751 which Perl does not regard as legal in numeric strings.
3752
3753 =item *
3754
3755 The integer types C<s>, C<S>, C<l>, and C<L> may be
3756 followed by a C<!> modifier to signify native shorts or
3757 longs--as you can see from above for example a bare C<l> does mean
3758 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3759 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3760 see whether using C<!> makes any difference by
3761
3762         print length(pack("s")), " ", length(pack("s!")), "\n";
3763         print length(pack("l")), " ", length(pack("l!")), "\n";
3764
3765 C<i!> and C<I!> also work but only because of completeness;
3766 they are identical to C<i> and C<I>.
3767
3768 The actual sizes (in bytes) of native shorts, ints, longs, and long
3769 longs on the platform where Perl was built are also available via
3770 L<Config>:
3771
3772        use Config;
3773        print $Config{shortsize},    "\n";
3774        print $Config{intsize},      "\n";
3775        print $Config{longsize},     "\n";
3776        print $Config{longlongsize}, "\n";
3777
3778 (The C<$Config{longlongsize}> will be undefined if your system does
3779 not support long longs.)
3780
3781 =item *
3782
3783 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3784 are inherently non-portable between processors and operating systems
3785 because they obey the native byteorder and endianness.  For example a
3786 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3787 (arranged in and handled by the CPU registers) into bytes as
3788
3789         0x12 0x34 0x56 0x78     # big-endian
3790         0x78 0x56 0x34 0x12     # little-endian
3791
3792 Basically, the Intel and VAX CPUs are little-endian, while everybody
3793 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3794 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3795 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3796 mode.
3797
3798 The names `big-endian' and `little-endian' are comic references to
3799 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3800 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3801 the egg-eating habits of the Lilliputians.
3802
3803 Some systems may have even weirder byte orders such as
3804
3805         0x56 0x78 0x12 0x34
3806         0x34 0x12 0x78 0x56
3807
3808 You can see your system's preference with
3809
3810         print join(" ", map { sprintf "%#02x", $_ }
3811                             unpack("W*",pack("L",0x12345678))), "\n";
3812
3813 The byteorder on the platform where Perl was built is also available
3814 via L<Config>:
3815
3816         use Config;
3817         print $Config{byteorder}, "\n";
3818
3819 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3820 and C<'87654321'> are big-endian.
3821
3822 If you want portable packed integers you can either use the formats
3823 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3824 modifiers.  These modifiers are only available as of perl 5.9.2.
3825 See also L<perlport>.
3826
3827 =item *
3828
3829 All integer and floating point formats as well as C<p> and C<P> and
3830 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3831 to force big- or little- endian byte-order, respectively.
3832 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3833 signed integers, 64-bit integers and floating point values.  However,
3834 there are some things to keep in mind.
3835
3836 Exchanging signed integers between different platforms only works
3837 if all platforms store them in the same format.  Most platforms store
3838 signed integers in two's complement, so usually this is not an issue.
3839
3840 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3841 formats on big- or little-endian machines.  Otherwise, attempting to
3842 do so will result in a fatal error.
3843
3844 Forcing big- or little-endian byte-order on floating point values for
3845 data exchange can only work if all platforms are using the same
3846 binary representation (e.g. IEEE floating point format).  Even if all
3847 platforms are using IEEE, there may be subtle differences.  Being able
3848 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3849 but also very dangerous if you don't know exactly what you're doing.
3850 It is definitely not a general way to portably store floating point
3851 values.
3852
3853 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3854 all types inside the group that accept the byte-order modifiers,
3855 including all subgroups.  It will silently be ignored for all other
3856 types.  You are not allowed to override the byte-order within a group
3857 that already has a byte-order modifier suffix.
3858
3859 =item *
3860
3861 Real numbers (floats and doubles) are in the native machine format only;
3862 due to the multiplicity of floating formats around, and the lack of a
3863 standard "network" representation, no facility for interchange has been
3864 made.  This means that packed floating point data written on one machine
3865 may not be readable on another - even if both use IEEE floating point
3866 arithmetic (as the endian-ness of the memory representation is not part
3867 of the IEEE spec).  See also L<perlport>.
3868
3869 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3870 modifiers to force big- or little-endian byte-order on floating point values.
3871
3872 Note that Perl uses doubles (or long doubles, if configured) internally for
3873 all numeric calculation, and converting from double into float and thence back
3874 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3875 will not in general equal $foo).
3876
3877 =item *
3878
3879 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3880 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3881 where the packed string is processed in its UTF-8-encoded Unicode form on
3882 a byte by byte basis. Character mode is the default unless the format string 
3883 starts with an C<U>. You can switch mode at any moment with an explicit 
3884 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3885 or until the end of the ()-group in which it was entered.
3886
3887 =item *
3888
3889 You must yourself do any alignment or padding by inserting for example
3890 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3891 could know where the characters are going to or coming from.  Therefore
3892 C<pack> (and C<unpack>) handle their output and input as flat
3893 sequences of characters.
3894
3895 =item *
3896
3897 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3898 take a repeat count, both as postfix, and for unpack() also via the C</>
3899 template character. Within each repetition of a group, positioning with
3900 C<@> starts again at 0. Therefore, the result of
3901
3902     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3903
3904 is the string "\0a\0\0bc".
3905
3906 =item *
3907
3908 C<x> and C<X> accept C<!> modifier.  In this case they act as
3909 alignment commands: they jump forward/back to the closest position
3910 aligned at a multiple of C<count> characters. For example, to pack() or
3911 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3912 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3913 aligned on the double's size.
3914
3915 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3916 both result in no-ops.
3917
3918 =item *
3919
3920 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3921 will represent signed 16-/32-bit integers in big-/little-endian order.
3922 This is only portable if all platforms sharing the packed data use the
3923 same binary representation for signed integers (e.g. all platforms are
3924 using two's complement representation).
3925
3926 =item *
3927
3928 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3929 White space may be used to separate pack codes from each other, but
3930 modifiers and a repeat count must follow immediately.
3931
3932 =item *
3933
3934 If TEMPLATE requires more arguments to pack() than actually given, pack()
3935 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
3936 to pack() than actually given, extra arguments are ignored.
3937
3938 =back
3939
3940 Examples:
3941
3942     $foo = pack("WWWW",65,66,67,68);
3943     # foo eq "ABCD"
3944     $foo = pack("W4",65,66,67,68);
3945     # same thing
3946     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
3947     # same thing with Unicode circled letters.
3948     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3949     # same thing with Unicode circled letters. You don't get the UTF-8
3950     # bytes because the U at the start of the format caused a switch to
3951     # U0-mode, so the UTF-8 bytes get joined into characters
3952     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
3953     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
3954     # This is the UTF-8 encoding of the string in the previous example
3955
3956     $foo = pack("ccxxcc",65,66,67,68);
3957     # foo eq "AB\0\0CD"
3958
3959     # note: the above examples featuring "W" and "c" are true
3960     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3961     # and UTF-8.  In EBCDIC the first example would be
3962     # $foo = pack("WWWW",193,194,195,196);
3963
3964     $foo = pack("s2",1,2);
3965     # "\1\0\2\0" on little-endian
3966     # "\0\1\0\2" on big-endian
3967
3968     $foo = pack("a4","abcd","x","y","z");
3969     # "abcd"
3970
3971     $foo = pack("aaaa","abcd","x","y","z");
3972     # "axyz"
3973
3974     $foo = pack("a14","abcdefg");
3975     # "abcdefg\0\0\0\0\0\0\0"
3976
3977     $foo = pack("i9pl", gmtime);
3978     # a real struct tm (on my system anyway)
3979
3980     $utmp_template = "Z8 Z8 Z16 L";
3981     $utmp = pack($utmp_template, @utmp1);
3982     # a struct utmp (BSDish)
3983
3984     @utmp2 = unpack($utmp_template, $utmp);
3985     # "@utmp1" eq "@utmp2"
3986
3987     sub bintodec {
3988         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3989     }
3990
3991     $foo = pack('sx2l', 12, 34);
3992     # short 12, two zero bytes padding, long 34
3993     $bar = pack('s@4l', 12, 34);
3994     # short 12, zero fill to position 4, long 34
3995     # $foo eq $bar
3996     $baz = pack('s.l', 12, 4, 34);
3997     # short 12, zero fill to position 4, long 34
3998
3999     $foo = pack('nN', 42, 4711);
4000     # pack big-endian 16- and 32-bit unsigned integers
4001     $foo = pack('S>L>', 42, 4711);
4002     # exactly the same
4003     $foo = pack('s<l<', -42, 4711);
4004     # pack little-endian 16- and 32-bit signed integers
4005     $foo = pack('(sl)<', -42, 4711);
4006     # exactly the same
4007
4008 The same template may generally also be used in unpack().
4009
4010 =item package NAMESPACE
4011 X<package> X<module> X<namespace>
4012
4013 =item package
4014
4015 Declares the compilation unit as being in the given namespace.  The scope
4016 of the package declaration is from the declaration itself through the end
4017 of the enclosing block, file, or eval (the same as the C<my> operator).
4018 All further unqualified dynamic identifiers will be in this namespace.
4019 A package statement affects only dynamic variables--including those
4020 you've used C<local> on--but I<not> lexical variables, which are created
4021 with C<my>.  Typically it would be the first declaration in a file to
4022 be included by the C<require> or C<use> operator.  You can switch into a
4023 package in more than one place; it merely influences which symbol table
4024 is used by the compiler for the rest of that block.  You can refer to
4025 variables and filehandles in other packages by prefixing the identifier
4026 with the package name and a double colon:  C<$Package::Variable>.
4027 If the package name is null, the C<main> package as assumed.  That is,
4028 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
4029 still seen in older code).
4030
4031 If NAMESPACE is omitted, then there is no current package, and all
4032 identifiers must be fully qualified or lexicals.  However, you are
4033 strongly advised not to make use of this feature. Its use can cause
4034 unexpected behaviour, even crashing some versions of Perl. It is
4035 deprecated, and will be removed from a future release.
4036
4037 See L<perlmod/"Packages"> for more information about packages, modules,
4038 and classes.  See L<perlsub> for other scoping issues.
4039
4040 =item pipe READHANDLE,WRITEHANDLE
4041 X<pipe>
4042
4043 Opens a pair of connected pipes like the corresponding system call.
4044 Note that if you set up a loop of piped processes, deadlock can occur
4045 unless you are very careful.  In addition, note that Perl's pipes use
4046 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4047 after each command, depending on the application.
4048
4049 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
4050 for examples of such things.
4051
4052 On systems that support a close-on-exec flag on files, the flag will be set
4053 for the newly opened file descriptors as determined by the value of $^F.
4054 See L<perlvar/$^F>.
4055
4056 =item pop ARRAY
4057 X<pop> X<stack>
4058
4059 =item pop
4060
4061 Pops and returns the last value of the array, shortening the array by
4062 one element.  Has an effect similar to
4063
4064     $ARRAY[$#ARRAY--]
4065
4066 If there are no elements in the array, returns the undefined value
4067 (although this may happen at other times as well).  If ARRAY is
4068 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
4069 array in subroutines, just like C<shift>.
4070
4071 =item pos SCALAR
4072 X<pos> X<match, position>
4073
4074 =item pos
4075
4076 Returns the offset of where the last C<m//g> search left off for the variable
4077 in question (C<$_> is used when the variable is not specified).  Note that
4078 0 is a valid match offset.  C<undef> indicates that the search position
4079 is reset (usually due to match failure, but can also be because no match has
4080 yet been performed on the scalar). C<pos> directly accesses the location used
4081 by the regexp engine to store the offset, so assigning to C<pos> will change
4082 that offset, and so will also influence the C<\G> zero-width assertion in
4083 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
4084 the return from C<pos> won't change either in this case.  See L<perlre> and
4085 L<perlop>.
4086
4087 =item print FILEHANDLE LIST
4088 X<print>
4089
4090 =item print LIST
4091
4092 =item print
4093
4094 Prints a string or a list of strings.  Returns true if successful.
4095 FILEHANDLE may be a scalar variable name, in which case the variable
4096 contains the name of or a reference to the filehandle, thus introducing
4097 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
4098 the next token is a term, it may be misinterpreted as an operator
4099 unless you interpose a C<+> or put parentheses around the arguments.)
4100 If FILEHANDLE is omitted, prints by default to standard output (or
4101 to the last selected output channel--see L</select>).  If LIST is
4102 also omitted, prints C<$_> to the currently selected output channel.
4103 To set the default output channel to something other than STDOUT
4104 use the select operation.  The current value of C<$,> (if any) is
4105 printed between each LIST item.  The current value of C<$\> (if
4106 any) is printed after the entire LIST has been printed.  Because
4107 print takes a LIST, anything in the LIST is evaluated in list
4108 context, and any subroutine that you call will have one or more of
4109 its expressions evaluated in list context.  Also be careful not to
4110 follow the print keyword with a left parenthesis unless you want
4111 the corresponding right parenthesis to terminate the arguments to
4112 the print--interpose a C<+> or put parentheses around all the
4113 arguments.
4114
4115 Note that if you're storing FILEHANDLEs in an array, or if you're using
4116 any other expression more complex than a scalar variable to retrieve it,
4117 you will have to use a block returning the filehandle value instead:
4118
4119     print { $files[$i] } "stuff\n";
4120     print { $OK ? STDOUT : STDERR } "stuff\n";
4121
4122 =item printf FILEHANDLE FORMAT, LIST
4123 X<printf>
4124
4125 =item printf FORMAT, LIST
4126
4127 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4128 (the output record separator) is not appended.  The first argument
4129 of the list will be interpreted as the C<printf> format. See C<sprintf>
4130 for an explanation of the format argument. If C<use locale> is in effect,
4131 the character used for the decimal point in formatted real numbers is
4132 affected by the LC_NUMERIC locale.  See L<perllocale>.
4133
4134 Don't fall into the trap of using a C<printf> when a simple
4135 C<print> would do.  The C<print> is more efficient and less
4136 error prone.
4137
4138 =item prototype FUNCTION
4139 X<prototype>
4140
4141 Returns the prototype of a function as a string (or C<undef> if the
4142 function has no prototype).  FUNCTION is a reference to, or the name of,
4143 the function whose prototype you want to retrieve.
4144
4145 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4146 name for Perl builtin.  If the builtin is not I<overridable> (such as
4147 C<qw//>) or its arguments cannot be expressed by a prototype (such as
4148 C<system>) returns C<undef> because the builtin does not really behave
4149 like a Perl function.  Otherwise, the string describing the equivalent
4150 prototype is returned.
4151
4152 =item push ARRAY,LIST
4153 X<push>, X<stack>
4154
4155 Treats ARRAY as a stack, and pushes the values of LIST
4156 onto the end of ARRAY.  The length of ARRAY increases by the length of
4157 LIST.  Has the same effect as
4158
4159     for $value (LIST) {
4160         $ARRAY[++$#ARRAY] = $value;
4161     }
4162
4163 but is more efficient.  Returns the number of elements in the array following
4164 the completed C<push>.
4165
4166 =item q/STRING/
4167
4168 =item qq/STRING/
4169
4170 =item qr/STRING/
4171
4172 =item qx/STRING/
4173
4174 =item qw/STRING/
4175
4176 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
4177
4178 =item quotemeta EXPR
4179 X<quotemeta> X<metacharacter>
4180
4181 =item quotemeta
4182
4183 Returns the value of EXPR with all non-"word"
4184 characters backslashed.  (That is, all characters not matching
4185 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4186 returned string, regardless of any locale settings.)
4187 This is the internal function implementing
4188 the C<\Q> escape in double-quoted strings.
4189
4190 If EXPR is omitted, uses C<$_>.
4191
4192 =item rand EXPR
4193 X<rand> X<random>
4194
4195 =item rand
4196
4197 Returns a random fractional number greater than or equal to C<0> and less
4198 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4199 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4200 also special-cased as C<1> - this has not been documented before perl 5.8.0
4201 and is subject to change in future versions of perl.  Automatically calls
4202 C<srand> unless C<srand> has already been called.  See also C<srand>.
4203
4204 Apply C<int()> to the value returned by C<rand()> if you want random
4205 integers instead of random fractional numbers.  For example,
4206
4207     int(rand(10))
4208
4209 returns a random integer between C<0> and C<9>, inclusive.
4210
4211 (Note: If your rand function consistently returns numbers that are too
4212 large or too small, then your version of Perl was probably compiled
4213 with the wrong number of RANDBITS.)
4214
4215 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4216 X<read> X<file, read>
4217
4218 =item read FILEHANDLE,SCALAR,LENGTH
4219
4220 Attempts to read LENGTH I<characters> of data into variable SCALAR
4221 from the specified FILEHANDLE.  Returns the number of characters
4222 actually read, C<0> at end of file, or undef if there was an error (in
4223 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4224 so that the last character actually read is the last character of the
4225 scalar after the read.
4226
4227 An OFFSET may be specified to place the read data at some place in the
4228 string other than the beginning.  A negative OFFSET specifies
4229 placement at that many characters counting backwards from the end of
4230 the string.  A positive OFFSET greater than the length of SCALAR
4231 results in the string being padded to the required size with C<"\0">
4232 bytes before the result of the read is appended.
4233
4234 The call is actually implemented in terms of either Perl's or system's
4235 fread() call.  To get a true read(2) system call, see C<sysread>.
4236
4237 Note the I<characters>: depending on the status of the filehandle,
4238 either (8-bit) bytes or characters are read.  By default all
4239 filehandles operate on bytes, but for example if the filehandle has
4240 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4241 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4242 characters, not bytes.  Similarly for the C<:encoding> pragma:
4243 in that case pretty much any characters can be read.
4244
4245 =item readdir DIRHANDLE
4246 X<readdir>
4247
4248 Returns the next directory entry for a directory opened by C<opendir>.
4249 If used in list context, returns all the rest of the entries in the
4250 directory.  If there are no more entries, returns an undefined value in
4251 scalar context or a null list in list context.
4252
4253 If you're planning to filetest the return values out of a C<readdir>, you'd
4254 better prepend the directory in question.  Otherwise, because we didn't
4255 C<chdir> there, it would have been testing the wrong file.
4256
4257     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4258     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4259     closedir DIR;
4260
4261 =item readline EXPR
4262 X<readline> X<gets> X<fgets>
4263
4264 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
4265 context, each call reads and returns the next line, until end-of-file is
4266 reached, whereupon the subsequent call returns undef.  In list context,
4267 reads until end-of-file is reached and returns a list of lines.  Note that
4268 the notion of "line" used here is however you may have defined it
4269 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4270
4271 When C<$/> is set to C<undef>, when readline() is in scalar
4272 context (i.e. file slurp mode), and when an empty file is read, it
4273 returns C<''> the first time, followed by C<undef> subsequently.
4274
4275 This is the internal function implementing the C<< <EXPR> >>
4276 operator, but you can use it directly.  The C<< <EXPR> >>
4277 operator is discussed in more detail in L<perlop/"I/O Operators">.
4278
4279     $line = <STDIN>;
4280     $line = readline(*STDIN);           # same thing
4281
4282 If readline encounters an operating system error, C<$!> will be set with the
4283 corresponding error message.  It can be helpful to check C<$!> when you are
4284 reading from filehandles you don't trust, such as a tty or a socket.  The
4285 following example uses the operator form of C<readline>, and takes the necessary
4286 steps to ensure that C<readline> was successful.
4287
4288     for (;;) {
4289         undef $!;
4290         unless (defined( $line = <> )) {
4291             die $! if $!;
4292             last; # reached EOF
4293         }
4294         # ...
4295     }
4296
4297 =item readlink EXPR
4298 X<readlink>
4299
4300 =item readlink
4301
4302 Returns the value of a symbolic link, if symbolic links are
4303 implemented.  If not, gives a fatal error.  If there is some system
4304 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4305 omitted, uses C<$_>.
4306
4307 =item readpipe EXPR
4308 X<readpipe>
4309
4310 EXPR is executed as a system command.
4311 The collected standard output of the command is returned.
4312 In scalar context, it comes back as a single (potentially
4313 multi-line) string.  In list context, returns a list of lines
4314 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4315 This is the internal function implementing the C<qx/EXPR/>
4316 operator, but you can use it directly.  The C<qx/EXPR/>
4317 operator is discussed in more detail in L<perlop/"I/O Operators">.
4318
4319 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4320 X<recv>
4321
4322 Receives a message on a socket.  Attempts to receive LENGTH characters
4323 of data into variable SCALAR from the specified SOCKET filehandle.
4324 SCALAR will be grown or shrunk to the length actually read.  Takes the
4325 same flags as the system call of the same name.  Returns the address
4326 of the sender if SOCKET's protocol supports this; returns an empty
4327 string otherwise.  If there's an error, returns the undefined value.
4328 This call is actually implemented in terms of recvfrom(2) system call.
4329 See L<perlipc/"UDP: Message Passing"> for examples.
4330
4331 Note the I<characters>: depending on the status of the socket, either
4332 (8-bit) bytes or characters are received.  By default all sockets
4333 operate on bytes, but for example if the socket has been changed using
4334 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4335 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4336 characters, not bytes.  Similarly for the C<:encoding> pragma:
4337 in that case pretty much any characters can be read.
4338
4339 =item redo LABEL
4340 X<redo>
4341
4342 =item redo
4343
4344 The C<redo> command restarts the loop block without evaluating the
4345 conditional again.  The C<continue> block, if any, is not executed.  If
4346 the LABEL is omitted, the command refers to the innermost enclosing
4347 loop.  Programs that want to lie to themselves about what was just input 
4348 normally use this command:
4349
4350     # a simpleminded Pascal comment stripper
4351     # (warning: assumes no { or } in strings)
4352     LINE: while (<STDIN>) {
4353         while (s|({.*}.*){.*}|$1 |) {}
4354         s|{.*}| |;
4355         if (s|{.*| |) {
4356             $front = $_;
4357             while (<STDIN>) {
4358                 if (/}/) {      # end of comment?
4359                     s|^|$front\{|;
4360                     redo LINE;
4361                 }
4362             }
4363         }
4364         print;
4365     }
4366
4367 C<redo> cannot be used to retry a block which returns a value such as
4368 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4369 a grep() or map() operation.
4370
4371 Note that a block by itself is semantically identical to a loop
4372 that executes once.  Thus C<redo> inside such a block will effectively
4373 turn it into a looping construct.
4374
4375 See also L</continue> for an illustration of how C<last>, C<next>, and
4376 C<redo> work.
4377
4378 =item ref EXPR
4379 X<ref> X<reference>
4380
4381 =item ref
4382
4383 Returns a non-empty string if EXPR is a reference, the empty
4384 string otherwise. If EXPR
4385 is not specified, C<$_> will be used.  The value returned depends on the
4386 type of thing the reference is a reference to.
4387 Builtin types include:
4388
4389     SCALAR
4390     ARRAY
4391     HASH
4392     CODE
4393     REF
4394     GLOB
4395     LVALUE
4396     FORMAT
4397     IO
4398     VSTRING
4399     Regexp
4400
4401 If the referenced object has been blessed into a package, then that package
4402 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4403
4404     if (ref($r) eq "HASH") {
4405         print "r is a reference to a hash.\n";
4406     }
4407     unless (ref($r)) {
4408         print "r is not a reference at all.\n";
4409     }
4410
4411 See also L<perlref>.
4412
4413 =item rename OLDNAME,NEWNAME
4414 X<rename> X<move> X<mv> X<ren>
4415
4416 Changes the name of a file; an existing file NEWNAME will be
4417 clobbered.  Returns true for success, false otherwise.
4418
4419 Behavior of this function varies wildly depending on your system
4420 implementation.  For example, it will usually not work across file system
4421 boundaries, even though the system I<mv> command sometimes compensates
4422 for this.  Other restrictions include whether it works on directories,
4423 open files, or pre-existing files.  Check L<perlport> and either the
4424 rename(2) manpage or equivalent system documentation for details.
4425
4426 For a platform independent C<move> function look at the L<File::Copy>
4427 module.
4428
4429 =item require VERSION
4430 X<require>
4431
4432 =item require EXPR
4433
4434 =item require
4435
4436 Demands a version of Perl specified by VERSION, or demands some semantics
4437 specified by EXPR or by C<$_> if EXPR is not supplied.
4438
4439 VERSION may be either a numeric argument such as 5.006, which will be
4440 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4441 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4442 VERSION is greater than the version of the current Perl interpreter.
4443 Compare with L</use>, which can do a similar check at compile time.
4444
4445 Specifying VERSION as a literal of the form v5.6.1 should generally be
4446 avoided, because it leads to misleading error messages under earlier
4447 versions of Perl that do not support this syntax.  The equivalent numeric
4448 version should be used instead.
4449
4450     require v5.6.1;     # run time version check
4451     require 5.6.1;      # ditto
4452     require 5.006_001;  # ditto; preferred for backwards compatibility
4453
4454 Otherwise, C<require> demands that a library file be included if it
4455 hasn't already been included.  The file is included via the do-FILE
4456 mechanism, which is essentially just a variety of C<eval>.  Has
4457 semantics similar to the following subroutine:
4458
4459     sub require {
4460        my ($filename) = @_;
4461        if (exists $INC{$filename}) {
4462            return 1 if $INC{$filename};
4463            die "Compilation failed in require";
4464        }
4465        my ($realfilename,$result);
4466        ITER: {
4467            foreach $prefix (@INC) {
4468                $realfilename = "$prefix/$filename";
4469                if (-f $realfilename) {
4470                    $INC{$filename} = $realfilename;
4471                    $result = do $realfilename;
4472                    last ITER;
4473                }
4474            }
4475            die "Can't find $filename in \@INC";
4476        }
4477        if ($@) {
4478            $INC{$filename} = undef;
4479            die $@;
4480        } elsif (!$result) {
4481            delete $INC{$filename};
4482            die "$filename did not return true value";
4483        } else {
4484            return $result;
4485        }
4486     }
4487
4488 Note that the file will not be included twice under the same specified
4489 name.
4490
4491 The file must return true as the last statement to indicate
4492 successful execution of any initialization code, so it's customary to
4493 end such a file with C<1;> unless you're sure it'll return true
4494 otherwise.  But it's better just to put the C<1;>, in case you add more
4495 statements.
4496
4497 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4498 replaces "F<::>" with "F</>" in the filename for you,
4499 to make it easy to load standard modules.  This form of loading of
4500 modules does not risk altering your namespace.
4501
4502 In other words, if you try this:
4503
4504         require Foo::Bar;    # a splendid bareword
4505
4506 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4507 directories specified in the C<@INC> array.
4508
4509 But if you try this:
4510
4511         $class = 'Foo::Bar';
4512         require $class;      # $class is not a bareword
4513     #or
4514         require "Foo::Bar";  # not a bareword because of the ""
4515
4516 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4517 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4518
4519         eval "require $class";
4520
4521 Now that you understand how C<require> looks for files in the case of a
4522 bareword argument, there is a little extra functionality going on behind
4523 the scenes.  Before C<require> looks for a "F<.pm>" extension, it will
4524 first look for a similar filename with a "F<.pmc>" extension. If this file
4525 is found, it will be loaded in place of any file ending in a "F<.pm>"
4526 extension.
4527
4528 You can also insert hooks into the import facility, by putting directly
4529 Perl code into the @INC array.  There are three forms of hooks: subroutine
4530 references, array references and blessed objects.
4531
4532 Subroutine references are the simplest case.  When the inclusion system
4533 walks through @INC and encounters a subroutine, this subroutine gets
4534 called with two parameters, the first being a reference to itself, and the
4535 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4536 subroutine should return nothing, or a list of up to 4 values in the
4537 following order:
4538
4539 =over
4540
4541 =item 1
4542
4543 A reference to a scalar, containing any initial source code to prepend to
4544 the file or generator output.
4545
4546
4547 =item 2
4548
4549 A filehandle, from which the file will be read.  
4550
4551 =item 3
4552
4553 A reference to a subroutine. If there is no filehandle (previous item),
4554 then this subroutine is expected to generate one line of source code per
4555 call, writing the line into C<$_> and returning 1, then returning 0 at
4556 "end of file". If there is a filehandle, then the subroutine will be
4557 called to act a simple source filter, with the line as read in C<$_>.
4558 Again, return 1 for each valid line, and 0 after all lines have been
4559 returned.
4560
4561 =item 4
4562
4563 Optional state for the subroutine. The state is passed in as C<$_[1]>. A
4564 reference to the subroutine itself is passed in as C<$_[0]>.
4565
4566 =back
4567
4568 If an empty list, C<undef>, or nothing that matches the first 3 values above
4569 is returned then C<require> will look at the remaining elements of @INC.
4570 Note that this file handle must be a real file handle (strictly a typeglob,
4571 or reference to a typeglob, blessed or unblessed) - tied file handles will be
4572 ignored and return value processing will stop there.
4573
4574 If the hook is an array reference, its first element must be a subroutine
4575 reference.  This subroutine is called as above, but the first parameter is
4576 the array reference.  This enables to pass indirectly some arguments to
4577 the subroutine.
4578
4579 In other words, you can write:
4580
4581     push @INC, \&my_sub;
4582     sub my_sub {
4583         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4584         ...
4585     }
4586
4587 or:
4588
4589     push @INC, [ \&my_sub, $x, $y, ... ];
4590     sub my_sub {
4591         my ($arrayref, $filename) = @_;
4592         # Retrieve $x, $y, ...
4593         my @parameters = @$arrayref[1..$#$arrayref];
4594         ...
4595     }
4596
4597 If the hook is an object, it must provide an INC method that will be
4598 called as above, the first parameter being the object itself.  (Note that
4599 you must fully qualify the sub's name, as unqualified C<INC> is always forced
4600 into package C<main>.)  Here is a typical code layout:
4601
4602     # In Foo.pm
4603     package Foo;
4604     sub new { ... }
4605     sub Foo::INC {
4606         my ($self, $filename) = @_;
4607         ...
4608     }
4609
4610     # In the main program
4611     push @INC, new Foo(...);
4612
4613 Note that these hooks are also permitted to set the %INC entry
4614 corresponding to the files they have loaded. See L<perlvar/%INC>.
4615
4616 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4617
4618 =item reset EXPR
4619 X<reset>
4620
4621 =item reset
4622
4623 Generally used in a C<continue> block at the end of a loop to clear
4624 variables and reset C<??> searches so that they work again.  The
4625 expression is interpreted as a list of single characters (hyphens
4626 allowed for ranges).  All variables and arrays beginning with one of
4627 those letters are reset to their pristine state.  If the expression is
4628 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4629 only variables or searches in the current package.  Always returns
4630 1.  Examples:
4631
4632     reset 'X';          # reset all X variables
4633     reset 'a-z';        # reset lower case variables
4634     reset;              # just reset ?one-time? searches
4635
4636 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4637 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4638 variables--lexical variables are unaffected, but they clean themselves
4639 up on scope exit anyway, so you'll probably want to use them instead.
4640 See L</my>.