This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: [PATCH] Initial attempt at named captures for perls regexp engine
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 Predefined Names
8
9 The following names have special meaning to Perl.  Most 
10 punctuation names have reasonable mnemonics, or analogs in the
11 shells.  Nevertheless, if you wish to use long variable names,
12 you need only say
13
14     use English;
15
16 at the top of your program. This aliases all the short names to the long
17 names in the current package. Some even have medium names, generally
18 borrowed from B<awk>. In general, it's best to use the
19
20     use English '-no_match_vars';
21
22 invocation if you don't need $PREMATCH, $MATCH, or $POSTMATCH, as it avoids
23 a certain performance hit with the use of regular expressions. See
24 L<English>.
25
26 Variables that depend on the currently selected filehandle may be set by
27 calling an appropriate object method on the IO::Handle object, although
28 this is less efficient than using the regular built-in variables. (Summary
29 lines below for this contain the word HANDLE.) First you must say
30
31     use IO::Handle;
32
33 after which you may use either
34
35     method HANDLE EXPR
36
37 or more safely,
38
39     HANDLE->method(EXPR)
40
41 Each method returns the old value of the IO::Handle attribute.
42 The methods each take an optional EXPR, which, if supplied, specifies the
43 new value for the IO::Handle attribute in question.  If not supplied,
44 most methods do nothing to the current value--except for
45 autoflush(), which will assume a 1 for you, just to be different.
46
47 Because loading in the IO::Handle class is an expensive operation, you should
48 learn how to use the regular built-in variables.
49
50 A few of these variables are considered "read-only".  This means that if
51 you try to assign to this variable, either directly or indirectly through
52 a reference, you'll raise a run-time exception.
53
54 You should be very careful when modifying the default values of most
55 special variables described in this document. In most cases you want
56 to localize these variables before changing them, since if you don't,
57 the change may affect other modules which rely on the default values
58 of the special variables that you have changed. This is one of the
59 correct ways to read the whole file at once:
60
61     open my $fh, "foo" or die $!;
62     local $/; # enable localized slurp mode
63     my $content = <$fh>;
64     close $fh;
65
66 But the following code is quite bad:
67
68     open my $fh, "foo" or die $!;
69     undef $/; # enable slurp mode
70     my $content = <$fh>;
71     close $fh;
72
73 since some other module, may want to read data from some file in the
74 default "line mode", so if the code we have just presented has been
75 executed, the global value of C<$/> is now changed for any other code
76 running inside the same Perl interpreter.
77
78 Usually when a variable is localized you want to make sure that this
79 change affects the shortest scope possible. So unless you are already
80 inside some short C<{}> block, you should create one yourself. For
81 example:
82
83     my $content = '';
84     open my $fh, "foo" or die $!;
85     {
86         local $/;
87         $content = <$fh>;
88     }
89     close $fh;
90
91 Here is an example of how your own code can go broken:
92
93     for (1..5){
94         nasty_break();
95         print "$_ ";
96     }
97     sub nasty_break {
98         $_ = 5;
99         # do something with $_
100     }
101
102 You probably expect this code to print:
103
104     1 2 3 4 5
105
106 but instead you get:
107
108     5 5 5 5 5
109
110 Why? Because nasty_break() modifies C<$_> without localizing it
111 first. The fix is to add local():
112
113         local $_ = 5;
114
115 It's easy to notice the problem in such a short example, but in more
116 complicated code you are looking for trouble if you don't localize
117 changes to the special variables.
118
119 The following list is ordered by scalar variables first, then the
120 arrays, then the hashes.
121
122 =over 8
123
124 =item $ARG
125
126 =item $_
127 X<$_> X<$ARG>
128
129 The default input and pattern-searching space.  The following pairs are
130 equivalent:
131
132     while (<>) {...}    # equivalent only in while!
133     while (defined($_ = <>)) {...}
134
135     /^Subject:/
136     $_ =~ /^Subject:/
137
138     tr/a-z/A-Z/
139     $_ =~ tr/a-z/A-Z/
140
141     chomp
142     chomp($_)
143
144 Here are the places where Perl will assume $_ even if you
145 don't use it:
146
147 =over 3
148
149 =item *
150
151 Various unary functions, including functions like ord() and int(), as well
152 as the all file tests (C<-f>, C<-d>) except for C<-t>, which defaults to
153 STDIN.
154
155 =item *
156
157 Various list functions like print() and unlink().
158
159 =item *
160
161 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
162 without an C<=~> operator.
163
164 =item *
165
166 The default iterator variable in a C<foreach> loop if no other
167 variable is supplied.
168
169 =item *
170
171 The implicit iterator variable in the grep() and map() functions.
172
173 =item *
174
175 The default place to put an input record when a C<< <FH> >>
176 operation's result is tested by itself as the sole criterion of a C<while>
177 test.  Outside a C<while> test, this will not happen.
178
179 =back
180
181 As C<$_> is a global variable, this may lead in some cases to unwanted
182 side-effects.  As of perl 5.9.1, you can now use a lexical version of
183 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
184 declaring C<our $> restores the global C<$_> in the current scope.
185
186 (Mnemonic: underline is understood in certain operations.)
187
188 =back
189
190 =over 8
191
192 =item $a
193
194 =item $b
195 X<$a> X<$b>
196
197 Special package variables when using sort(), see L<perlfunc/sort>.
198 Because of this specialness $a and $b don't need to be declared
199 (using use vars, or our()) even when using the C<strict 'vars'> pragma.
200 Don't lexicalize them with C<my $a> or C<my $b> if you want to be
201 able to use them in the sort() comparison block or function.
202
203 =back
204
205 =over 8
206
207 =item $<I<digits>>
208 X<$1> X<$2> X<$3>
209
210 Contains the subpattern from the corresponding set of capturing
211 parentheses from the last pattern match, not counting patterns
212 matched in nested blocks that have been exited already.  (Mnemonic:
213 like \digits.)  These variables are all read-only and dynamically
214 scoped to the current BLOCK.
215
216 =item $MATCH
217
218 =item $&
219 X<$&> X<$MATCH>
220
221 The string matched by the last successful pattern match (not counting
222 any matches hidden within a BLOCK or eval() enclosed by the current
223 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only
224 and dynamically scoped to the current BLOCK.
225
226 The use of this variable anywhere in a program imposes a considerable
227 performance penalty on all regular expression matches.  See L</BUGS>.
228
229 See L</@-> for a replacement.
230
231 =item $PREMATCH
232
233 =item $`
234 X<$`> X<$PREMATCH>
235
236 The string preceding whatever was matched by the last successful
237 pattern match (not counting any matches hidden within a BLOCK or eval
238 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
239 string.)  This variable is read-only.
240
241 The use of this variable anywhere in a program imposes a considerable
242 performance penalty on all regular expression matches.  See L</BUGS>.
243
244 See L</@-> for a replacement.
245
246 =item $POSTMATCH
247
248 =item $'
249 X<$'> X<$POSTMATCH>
250
251 The string following whatever was matched by the last successful
252 pattern match (not counting any matches hidden within a BLOCK or eval()
253 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
254 string.)  Example:
255
256     local $_ = 'abcdefghi';
257     /def/;
258     print "$`:$&:$'\n";         # prints abc:def:ghi
259
260 This variable is read-only and dynamically scoped to the current BLOCK.
261
262 The use of this variable anywhere in a program imposes a considerable
263 performance penalty on all regular expression matches.  See L</BUGS>.
264
265 See L</@-> for a replacement.
266
267 =item $LAST_PAREN_MATCH
268
269 =item $+
270 X<$+> X<$LAST_PAREN_MATCH>
271
272 The text matched by the last bracket of the last successful search pattern.
273 This is useful if you don't know which one of a set of alternative patterns
274 matched. For example:
275
276     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
277
278 (Mnemonic: be positive and forward looking.)
279 This variable is read-only and dynamically scoped to the current BLOCK.
280
281 =item $^N
282 X<$^N>
283
284 The text matched by the used group most-recently closed (i.e. the group
285 with the rightmost closing parenthesis) of the last successful search
286 pattern.  (Mnemonic: the (possibly) Nested parenthesis that most
287 recently closed.)
288
289 This is primarily used inside C<(?{...})> blocks for examining text
290 recently matched. For example, to effectively capture text to a variable
291 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
292
293      (?:(...)(?{ $var = $^N }))
294
295 By setting and then using C<$var> in this way relieves you from having to
296 worry about exactly which numbered set of parentheses they are.
297
298 This variable is dynamically scoped to the current BLOCK.
299
300 =item @LAST_MATCH_END
301
302 =item @+
303 X<@+> X<@LAST_MATCH_END>
304
305 This array holds the offsets of the ends of the last successful
306 submatches in the currently active dynamic scope.  C<$+[0]> is
307 the offset into the string of the end of the entire match.  This
308 is the same value as what the C<pos> function returns when called
309 on the variable that was matched against.  The I<n>th element
310 of this array holds the offset of the I<n>th submatch, so
311 C<$+[1]> is the offset past where $1 ends, C<$+[2]> the offset
312 past where $2 ends, and so on.  You can use C<$#+> to determine
313 how many subgroups were in the last successful match.  See the
314 examples given for the C<@-> variable.
315
316 =item %+
317 X<%+>
318
319 Similar to C<@+>, the C<%+> hash allows access to the named capture
320 buffers, should they exist, in the last successful match in the
321 currently active dynamic scope.
322
323 C<$+{foo}> is equivalent to C<$1> after the following match:
324
325   'foo'=~/(?<foo>foo)/;
326
327 =item HANDLE->input_line_number(EXPR)
328
329 =item $INPUT_LINE_NUMBER
330
331 =item $NR
332
333 =item $.
334 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
335
336 Current line number for the last filehandle accessed.
337
338 Each filehandle in Perl counts the number of lines that have been read
339 from it.  (Depending on the value of C<$/>, Perl's idea of what
340 constitutes a line may not match yours.)  When a line is read from a
341 filehandle (via readline() or C<< <> >>), or when tell() or seek() is
342 called on it, C<$.> becomes an alias to the line counter for that
343 filehandle.
344
345 You can adjust the counter by assigning to C<$.>, but this will not
346 actually move the seek pointer.  I<Localizing C<$.> will not localize
347 the filehandle's line count>.  Instead, it will localize perl's notion
348 of which filehandle C<$.> is currently aliased to.
349
350 C<$.> is reset when the filehandle is closed, but B<not> when an open
351 filehandle is reopened without an intervening close().  For more
352 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
353 an explicit close, line numbers increase across ARGV files (but see
354 examples in L<perlfunc/eof>).
355
356 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
357 line counter for a given filehandle without having to worry about
358 which handle you last accessed.
359
360 (Mnemonic: many programs use "." to mean the current line number.)
361
362 =item IO::Handle->input_record_separator(EXPR)
363
364 =item $INPUT_RECORD_SEPARATOR
365
366 =item $RS
367
368 =item $/
369 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
370
371 The input record separator, newline by default.  This 
372 influences Perl's idea of what a "line" is.  Works like B<awk>'s RS
373 variable, including treating empty lines as a terminator if set to
374 the null string.  (An empty line cannot contain any spaces
375 or tabs.)  You may set it to a multi-character string to match a
376 multi-character terminator, or to C<undef> to read through the end
377 of file.  Setting it to C<"\n\n"> means something slightly
378 different than setting to C<"">, if the file contains consecutive
379 empty lines.  Setting to C<""> will treat two or more consecutive
380 empty lines as a single empty line.  Setting to C<"\n\n"> will
381 blindly assume that the next input character belongs to the next
382 paragraph, even if it's a newline.  (Mnemonic: / delimits
383 line boundaries when quoting poetry.)
384
385     local $/;           # enable "slurp" mode
386     local $_ = <FH>;    # whole file now here
387     s/\n[ \t]+/ /g;
388
389 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to be
390 better for something. :-)
391
392 Setting C<$/> to a reference to an integer, scalar containing an integer, or
393 scalar that's convertible to an integer will attempt to read records
394 instead of lines, with the maximum record size being the referenced
395 integer.  So this:
396
397     local $/ = \32768; # or \"32768", or \$var_containing_32768
398     open my $fh, $myfile or die $!;
399     local $_ = <$fh>;
400
401 will read a record of no more than 32768 bytes from FILE.  If you're
402 not reading from a record-oriented file (or your OS doesn't have
403 record-oriented files), then you'll likely get a full chunk of data
404 with every read.  If a record is larger than the record size you've
405 set, you'll get the record back in pieces.  Trying to set the record
406 size to zero or less will cause reading in the (rest of the) whole file.
407
408 On VMS, record reads are done with the equivalent of C<sysread>,
409 so it's best not to mix record and non-record reads on the same
410 file.  (This is unlikely to be a problem, because any file you'd
411 want to read in record mode is probably unusable in line mode.)
412 Non-VMS systems do normal I/O, so it's safe to mix record and
413 non-record reads of a file.
414
415 See also L<perlport/"Newlines">.  Also see C<$.>.
416
417 =item HANDLE->autoflush(EXPR)
418
419 =item $OUTPUT_AUTOFLUSH
420
421 =item $|
422 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
423
424 If set to nonzero, forces a flush right away and after every write
425 or print on the currently selected output channel.  Default is 0
426 (regardless of whether the channel is really buffered by the
427 system or not; C<$|> tells you only whether you've asked Perl
428 explicitly to flush after each write).  STDOUT will
429 typically be line buffered if output is to the terminal and block
430 buffered otherwise.  Setting this variable is useful primarily when
431 you are outputting to a pipe or socket, such as when you are running
432 a Perl program under B<rsh> and want to see the output as it's
433 happening.  This has no effect on input buffering.  See L<perlfunc/getc>
434 for that.  (Mnemonic: when you want your pipes to be piping hot.)
435
436 =item IO::Handle->output_field_separator EXPR
437
438 =item $OUTPUT_FIELD_SEPARATOR
439
440 =item $OFS
441
442 =item $,
443 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
444
445 The output field separator for the print operator.  If defined, this
446 value is printed between each of print's arguments.  Default is C<undef>.
447 (Mnemonic: what is printed when there is a "," in your print statement.)
448
449 =item IO::Handle->output_record_separator EXPR
450
451 =item $OUTPUT_RECORD_SEPARATOR
452
453 =item $ORS
454
455 =item $\
456 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
457
458 The output record separator for the print operator.  If defined, this
459 value is printed after the last of print's arguments.  Default is C<undef>.
460 (Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
461 Also, it's just like C<$/>, but it's what you get "back" from Perl.)
462
463 =item $LIST_SEPARATOR
464
465 =item $"
466 X<$"> X<$LIST_SEPARATOR>
467
468 This is like C<$,> except that it applies to array and slice values
469 interpolated into a double-quoted string (or similar interpreted
470 string).  Default is a space.  (Mnemonic: obvious, I think.)
471
472 =item $SUBSCRIPT_SEPARATOR
473
474 =item $SUBSEP
475
476 =item $;
477 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
478
479 The subscript separator for multidimensional array emulation.  If you
480 refer to a hash element as
481
482     $foo{$a,$b,$c}
483
484 it really means
485
486     $foo{join($;, $a, $b, $c)}
487
488 But don't put
489
490     @foo{$a,$b,$c}      # a slice--note the @
491
492 which means
493
494     ($foo{$a},$foo{$b},$foo{$c})
495
496 Default is "\034", the same as SUBSEP in B<awk>.  If your
497 keys contain binary data there might not be any safe value for C<$;>.
498 (Mnemonic: comma (the syntactic subscript separator) is a
499 semi-semicolon.  Yeah, I know, it's pretty lame, but C<$,> is already
500 taken for something more important.)
501
502 Consider using "real" multidimensional arrays as described
503 in L<perllol>.
504
505 =item HANDLE->format_page_number(EXPR)
506
507 =item $FORMAT_PAGE_NUMBER
508
509 =item $%
510 X<$%> X<$FORMAT_PAGE_NUMBER>
511
512 The current page number of the currently selected output channel.
513 Used with formats.
514 (Mnemonic: % is page number in B<nroff>.)
515
516 =item HANDLE->format_lines_per_page(EXPR)
517
518 =item $FORMAT_LINES_PER_PAGE
519
520 =item $=
521 X<$=> X<$FORMAT_LINES_PER_PAGE>
522
523 The current page length (printable lines) of the currently selected
524 output channel.  Default is 60.  
525 Used with formats.
526 (Mnemonic: = has horizontal lines.)
527
528 =item HANDLE->format_lines_left(EXPR)
529
530 =item $FORMAT_LINES_LEFT
531
532 =item $-
533 X<$-> X<$FORMAT_LINES_LEFT>
534
535 The number of lines left on the page of the currently selected output
536 channel.  
537 Used with formats.
538 (Mnemonic: lines_on_page - lines_printed.)
539
540 =item @LAST_MATCH_START
541
542 =item @-
543 X<@-> X<@LAST_MATCH_START>
544
545 $-[0] is the offset of the start of the last successful match.
546 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
547 I<n>-th subpattern, or undef if the subpattern did not match.
548
549 Thus after a match against $_, $& coincides with C<substr $_, $-[0],
550 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
551 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
552 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the last
553 matched subgroup in the last successful match.  Contrast with
554 C<$#+>, the number of subgroups in the regular expression.  Compare
555 with C<@+>.
556
557 This array holds the offsets of the beginnings of the last
558 successful submatches in the currently active dynamic scope.
559 C<$-[0]> is the offset into the string of the beginning of the
560 entire match.  The I<n>th element of this array holds the offset
561 of the I<n>th submatch, so C<$-[1]> is the offset where $1
562 begins, C<$-[2]> the offset where $2 begins, and so on.
563
564 After a match against some variable $var:
565
566 =over 5
567
568 =item C<$`> is the same as C<substr($var, 0, $-[0])>
569
570 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
571
572 =item C<$'> is the same as C<substr($var, $+[0])>
573
574 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>  
575
576 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
577
578 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
579
580 =back
581
582 =item HANDLE->format_name(EXPR)
583
584 =item $FORMAT_NAME
585
586 =item $~
587 X<$~> X<$FORMAT_NAME>
588
589 The name of the current report format for the currently selected output
590 channel.  Default is the name of the filehandle.  (Mnemonic: brother to
591 C<$^>.)
592
593 =item HANDLE->format_top_name(EXPR)
594
595 =item $FORMAT_TOP_NAME
596
597 =item $^
598 X<$^> X<$FORMAT_TOP_NAME>
599
600 The name of the current top-of-page format for the currently selected
601 output channel.  Default is the name of the filehandle with _TOP
602 appended.  (Mnemonic: points to top of page.)
603
604 =item IO::Handle->format_line_break_characters EXPR
605
606 =item $FORMAT_LINE_BREAK_CHARACTERS
607
608 =item $:
609 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
610
611 The current set of characters after which a string may be broken to
612 fill continuation fields (starting with ^) in a format.  Default is
613 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
614 poetry is a part of a line.)
615
616 =item IO::Handle->format_formfeed EXPR
617
618 =item $FORMAT_FORMFEED
619
620 =item $^L
621 X<$^L> X<$FORMAT_FORMFEED>
622
623 What formats output as a form feed.  Default is \f.
624
625 =item $ACCUMULATOR
626
627 =item $^A
628 X<$^A> X<$ACCUMULATOR>
629
630 The current value of the write() accumulator for format() lines.  A format
631 contains formline() calls that put their result into C<$^A>.  After
632 calling its format, write() prints out the contents of C<$^A> and empties.
633 So you never really see the contents of C<$^A> unless you call
634 formline() yourself and then look at it.  See L<perlform> and
635 L<perlfunc/formline()>.
636
637 =item $CHILD_ERROR
638
639 =item $?
640 X<$?> X<$CHILD_ERROR>
641
642 The status returned by the last pipe close, backtick (C<``>) command,
643 successful call to wait() or waitpid(), or from the system()
644 operator.  This is just the 16-bit status word returned by the
645 traditional Unix wait() system call (or else is made up to look like it).  Thus, the
646 exit value of the subprocess is really (C<<< $? >> 8 >>>), and
647 C<$? & 127> gives which signal, if any, the process died from, and
648 C<$? & 128> reports whether there was a core dump.  (Mnemonic:
649 similar to B<sh> and B<ksh>.)
650
651 Additionally, if the C<h_errno> variable is supported in C, its value
652 is returned via $? if any C<gethost*()> function fails.
653
654 If you have installed a signal handler for C<SIGCHLD>, the
655 value of C<$?> will usually be wrong outside that handler.
656
657 Inside an C<END> subroutine C<$?> contains the value that is going to be
658 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
659 change the exit status of your program.  For example:
660
661     END {
662         $? = 1 if $? == 255;  # die would make it 255
663     } 
664
665 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
666 actual VMS exit status, instead of the default emulation of POSIX
667 status; see L<perlvms/$?> for details.
668
669 Also see L<Error Indicators>.
670
671 =item ${^CHILD_ERROR_NATIVE}
672 X<$^CHILD_ERROR_NATIVE>
673
674 The native status returned by the last pipe close, backtick (C<``>)
675 command, successful call to wait() or waitpid(), or from the system()
676 operator.  On POSIX-like systems this value can be decoded with the
677 WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED, WSTOPSIG
678 and WIFCONTINUED functions provided by the L<POSIX> module.
679
680 Under VMS this reflects the actual VMS exit status; i.e. it is the same
681 as $? when the pragma C<use vmsish 'status'> is in effect.
682
683 =item ${^ENCODING}
684 X<$^ENCODING>
685
686 The I<object reference> to the Encode object that is used to convert
687 the source code to Unicode.  Thanks to this variable your perl script
688 does not have to be written in UTF-8.  Default is I<undef>.  The direct
689 manipulation of this variable is highly discouraged.  See L<encoding>
690 for more details.
691
692 =item $OS_ERROR
693
694 =item $ERRNO
695
696 =item $!
697 X<$!> X<$ERRNO> X<$OS_ERROR>
698
699 If used numerically, yields the current value of the C C<errno>
700 variable, or in other words, if a system or library call fails, it
701 sets this variable.  This means that the value of C<$!> is meaningful
702 only I<immediately> after a B<failure>:
703
704     if (open(FH, $filename)) {
705         # Here $! is meaningless.
706         ...
707     } else {
708         # ONLY here is $! meaningful.
709         ...
710         # Already here $! might be meaningless.
711     }
712     # Since here we might have either success or failure,
713     # here $! is meaningless.
714
715 In the above I<meaningless> stands for anything: zero, non-zero,
716 C<undef>.  A successful system or library call does B<not> set
717 the variable to zero.
718
719 If used as a string, yields the corresponding system error string.
720 You can assign a number to C<$!> to set I<errno> if, for instance,
721 you want C<"$!"> to return the string for error I<n>, or you want
722 to set the exit value for the die() operator.  (Mnemonic: What just
723 went bang?)
724
725 Also see L<Error Indicators>.
726
727 =item %!
728 X<%!>
729
730 Each element of C<%!> has a true value only if C<$!> is set to that
731 value.  For example, C<$!{ENOENT}> is true if and only if the current
732 value of C<$!> is C<ENOENT>; that is, if the most recent error was
733 "No such file or directory" (or its moral equivalent: not all operating
734 systems give that exact error, and certainly not all languages).
735 To check if a particular key is meaningful on your system, use
736 C<exists $!{the_key}>; for a list of legal keys, use C<keys %!>.
737 See L<Errno> for more information, and also see above for the
738 validity of C<$!>.
739
740 =item $EXTENDED_OS_ERROR
741
742 =item $^E
743 X<$^E> X<$EXTENDED_OS_ERROR>
744
745 Error information specific to the current operating system.  At
746 the moment, this differs from C<$!> under only VMS, OS/2, and Win32
747 (and for MacPerl).  On all other platforms, C<$^E> is always just
748 the same as C<$!>.
749
750 Under VMS, C<$^E> provides the VMS status value from the last
751 system error.  This is more specific information about the last
752 system error than that provided by C<$!>.  This is particularly
753 important when C<$!> is set to B<EVMSERR>.
754
755 Under OS/2, C<$^E> is set to the error code of the last call to
756 OS/2 API either via CRT, or directly from perl.
757
758 Under Win32, C<$^E> always returns the last error information
759 reported by the Win32 call C<GetLastError()> which describes
760 the last error from within the Win32 API.  Most Win32-specific
761 code will report errors via C<$^E>.  ANSI C and Unix-like calls
762 set C<errno> and so most portable Perl code will report errors
763 via C<$!>. 
764
765 Caveats mentioned in the description of C<$!> generally apply to
766 C<$^E>, also.  (Mnemonic: Extra error explanation.)
767
768 Also see L<Error Indicators>.
769
770 =item $EVAL_ERROR
771
772 =item $@
773 X<$@> X<$EVAL_ERROR>
774
775 The Perl syntax error message from the last eval() operator.
776 If $@ is the null string, the last eval() parsed and executed
777 correctly (although the operations you invoked may have failed in the
778 normal fashion).  (Mnemonic: Where was the syntax error "at"?)
779
780 Warning messages are not collected in this variable.  You can,
781 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
782 as described below.
783
784 Also see L<Error Indicators>.
785
786 =item $PROCESS_ID
787
788 =item $PID
789
790 =item $$
791 X<$$> X<$PID> X<$PROCESS_ID>
792
793 The process number of the Perl running this script.  You should
794 consider this variable read-only, although it will be altered
795 across fork() calls.  (Mnemonic: same as shells.)
796
797 Note for Linux users: on Linux, the C functions C<getpid()> and
798 C<getppid()> return different values from different threads. In order to
799 be portable, this behavior is not reflected by C<$$>, whose value remains
800 consistent across threads. If you want to call the underlying C<getpid()>,
801 you may use the CPAN module C<Linux::Pid>.
802
803 =item $REAL_USER_ID
804
805 =item $UID
806
807 =item $<
808 X<< $< >> X<$UID> X<$REAL_USER_ID>
809
810 The real uid of this process.  (Mnemonic: it's the uid you came I<from>,
811 if you're running setuid.)  You can change both the real uid and
812 the effective uid at the same time by using POSIX::setuid().  Since
813 changes to $< require a system call, check $! after a change attempt to 
814 detect any possible errors.
815
816 =item $EFFECTIVE_USER_ID
817
818 =item $EUID
819
820 =item $>
821 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
822
823 The effective uid of this process.  Example:
824
825     $< = $>;            # set real to effective uid
826     ($<,$>) = ($>,$<);  # swap real and effective uid
827
828 You can change both the effective uid and the real uid at the same
829 time by using POSIX::setuid().  Changes to $> require a check to $!
830 to detect any possible errors after an attempted change. 
831
832 (Mnemonic: it's the uid you went I<to>, if you're running setuid.)
833 C<< $< >> and C<< $> >> can be swapped only on machines
834 supporting setreuid().
835
836 =item $REAL_GROUP_ID
837
838 =item $GID
839
840 =item $(
841 X<$(> X<$GID> X<$REAL_GROUP_ID>
842
843 The real gid of this process.  If you are on a machine that supports
844 membership in multiple groups simultaneously, gives a space separated
845 list of groups you are in.  The first number is the one returned by
846 getgid(), and the subsequent ones by getgroups(), one of which may be
847 the same as the first number.
848
849 However, a value assigned to C<$(> must be a single number used to
850 set the real gid.  So the value given by C<$(> should I<not> be assigned
851 back to C<$(> without being forced numeric, such as by adding zero.
852
853 You can change both the real gid and the effective gid at the same
854 time by using POSIX::setgid().  Changes to $( require a check to $!
855 to detect any possible errors after an attempted change.
856
857 (Mnemonic: parentheses are used to I<group> things.  The real gid is the
858 group you I<left>, if you're running setgid.)
859
860 =item $EFFECTIVE_GROUP_ID
861
862 =item $EGID
863
864 =item $)
865 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
866
867 The effective gid of this process.  If you are on a machine that
868 supports membership in multiple groups simultaneously, gives a space
869 separated list of groups you are in.  The first number is the one
870 returned by getegid(), and the subsequent ones by getgroups(), one of
871 which may be the same as the first number.
872
873 Similarly, a value assigned to C<$)> must also be a space-separated
874 list of numbers.  The first number sets the effective gid, and
875 the rest (if any) are passed to setgroups().  To get the effect of an
876 empty list for setgroups(), just repeat the new effective gid; that is,
877 to force an effective gid of 5 and an effectively empty setgroups()
878 list, say C< $) = "5 5" >.
879
880 You can change both the effective gid and the real gid at the same
881 time by using POSIX::setgid() (use only a single numeric argument).
882 Changes to $) require a check to $! to detect any possible errors
883 after an attempted change.
884
885 (Mnemonic: parentheses are used to I<group> things.  The effective gid
886 is the group that's I<right> for you, if you're running setgid.)
887
888 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
889 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
890 and C<$)> can be swapped only on machines supporting setregid().
891
892 =item $PROGRAM_NAME
893
894 =item $0
895 X<$0> X<$PROGRAM_NAME>
896
897 Contains the name of the program being executed.
898
899 On some (read: not all) operating systems assigning to C<$0> modifies
900 the argument area that the C<ps> program sees.  On some platforms you
901 may have to use special C<ps> options or a different C<ps> to see the
902 changes.  Modifying the $0 is more useful as a way of indicating the
903 current program state than it is for hiding the program you're
904 running.  (Mnemonic: same as B<sh> and B<ksh>.)
905
906 Note that there are platform specific limitations on the maximum
907 length of C<$0>.  In the most extreme case it may be limited to the
908 space occupied by the original C<$0>.
909
910 In some platforms there may be arbitrary amount of padding, for
911 example space characters, after the modified name as shown by C<ps>.
912 In some platforms this padding may extend all the way to the original
913 length of the argument area, no matter what you do (this is the case
914 for example with Linux 2.2).
915
916 Note for BSD users: setting C<$0> does not completely remove "perl"
917 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
918 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
919 and the " (perl)" suffix are shown depends on your exact BSD variant
920 and version).  This is an operating system feature, Perl cannot help it.
921
922 In multithreaded scripts Perl coordinates the threads so that any
923 thread may modify its copy of the C<$0> and the change becomes visible
924 to ps(1) (assuming the operating system plays along).  Note that
925 the view of C<$0> the other threads have will not change since they
926 have their own copies of it.
927
928 =item $[
929 X<$[>
930
931 The index of the first element in an array, and of the first character
932 in a substring.  Default is 0, but you could theoretically set it
933 to 1 to make Perl behave more like B<awk> (or Fortran) when
934 subscripting and when evaluating the index() and substr() functions.
935 (Mnemonic: [ begins subscripts.)
936
937 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
938 directive, and cannot influence the behavior of any other file.
939 (That's why you can only assign compile-time constants to it.)
940 Its use is highly discouraged.
941
942 Note that, unlike other compile-time directives (such as L<strict>),
943 assignment to C<$[> can be seen from outer lexical scopes in the same file.
944 However, you can use local() on it to strictly bind its value to a
945 lexical block.
946
947 =item $]
948 X<$]>
949
950 The version + patchlevel / 1000 of the Perl interpreter.  This variable
951 can be used to determine whether the Perl interpreter executing a
952 script is in the right range of versions.  (Mnemonic: Is this version
953 of perl in the right bracket?)  Example:
954
955     warn "No checksumming!\n" if $] < 3.019;
956
957 See also the documentation of C<use VERSION> and C<require VERSION>
958 for a convenient way to fail if the running Perl interpreter is too old.
959
960 The floating point representation can sometimes lead to inaccurate
961 numeric comparisons.  See C<$^V> for a more modern representation of
962 the Perl version that allows accurate string comparisons.
963
964 =item $COMPILING
965
966 =item $^C
967 X<$^C> X<$COMPILING>
968
969 The current value of the flag associated with the B<-c> switch.
970 Mainly of use with B<-MO=...> to allow code to alter its behavior
971 when being compiled, such as for example to AUTOLOAD at compile
972 time rather than normal, deferred loading.  See L<perlcc>.  Setting
973 C<$^C = 1> is similar to calling C<B::minus_c>.
974
975 =item $DEBUGGING
976
977 =item $^D
978 X<$^D> X<$DEBUGGING>
979
980 The current value of the debugging flags.  (Mnemonic: value of B<-D>
981 switch.) May be read or set. Like its command-line equivalent, you can use
982 numeric or symbolic values, eg C<$^D = 10> or C<$^D = "st">.
983
984 =item ${^RE_DEBUG_FLAGS}
985
986 The current value of the regex debugging flags. Set to 0 for no debug output
987 even when the re 'debug' module is loaded. See L<re> for details.
988
989 =item ${^RE_TRIE_MAXBUF}
990
991 Controls how certain regex optimisations are applied and how much memory they
992 utilize. This value by default is 65536 which corresponds to a 512kB temporary
993 cache. Set this to a higher value to trade memory for speed when matching
994 large alternations. Set it to a lower value if you want the optimisations to
995 be as conservative of memory as possible but still occur, and set it to a
996 negative value to prevent the optimisation and conserve the most memory.
997 Under normal situations this variable should be of no interest to you.
998
999 =item $SYSTEM_FD_MAX
1000
1001 =item $^F
1002 X<$^F> X<$SYSTEM_FD_MAX>
1003
1004 The maximum system file descriptor, ordinarily 2.  System file
1005 descriptors are passed to exec()ed processes, while higher file
1006 descriptors are not.  Also, during an open(), system file descriptors are
1007 preserved even if the open() fails.  (Ordinary file descriptors are
1008 closed before the open() is attempted.)  The close-on-exec
1009 status of a file descriptor will be decided according to the value of
1010 C<$^F> when the corresponding file, pipe, or socket was opened, not the
1011 time of the exec().
1012
1013 =item $^H
1014
1015 WARNING: This variable is strictly for internal use only.  Its availability,
1016 behavior, and contents are subject to change without notice.
1017
1018 This variable contains compile-time hints for the Perl interpreter.  At the
1019 end of compilation of a BLOCK the value of this variable is restored to the
1020 value when the interpreter started to compile the BLOCK.
1021
1022 When perl begins to parse any block construct that provides a lexical scope
1023 (e.g., eval body, required file, subroutine body, loop body, or conditional
1024 block), the existing value of $^H is saved, but its value is left unchanged.
1025 When the compilation of the block is completed, it regains the saved value.
1026 Between the points where its value is saved and restored, code that
1027 executes within BEGIN blocks is free to change the value of $^H.
1028
1029 This behavior provides the semantic of lexical scoping, and is used in,
1030 for instance, the C<use strict> pragma.
1031
1032 The contents should be an integer; different bits of it are used for
1033 different pragmatic flags.  Here's an example:
1034
1035     sub add_100 { $^H |= 0x100 }
1036
1037     sub foo {
1038         BEGIN { add_100() }
1039         bar->baz($boon);
1040     }
1041
1042 Consider what happens during execution of the BEGIN block.  At this point
1043 the BEGIN block has already been compiled, but the body of foo() is still
1044 being compiled.  The new value of $^H will therefore be visible only while
1045 the body of foo() is being compiled.
1046
1047 Substitution of the above BEGIN block with:
1048
1049     BEGIN { require strict; strict->import('vars') }
1050
1051 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
1052 version of the same lexical pragma:
1053
1054     BEGIN { require strict; strict->import('vars') if $condition }
1055
1056 =item %^H
1057
1058 The %^H hash provides the same scoping semantic as $^H.  This makes it
1059 useful for implementation of lexically scoped pragmas. See L<perlpragma>.
1060
1061 =item $INPLACE_EDIT
1062
1063 =item $^I
1064 X<$^I> X<$INPLACE_EDIT>
1065
1066 The current value of the inplace-edit extension.  Use C<undef> to disable
1067 inplace editing.  (Mnemonic: value of B<-i> switch.)
1068
1069 =item $^M
1070 X<$^M>
1071
1072 By default, running out of memory is an untrappable, fatal error.
1073 However, if suitably built, Perl can use the contents of C<$^M>
1074 as an emergency memory pool after die()ing.  Suppose that your Perl
1075 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
1076 Then
1077
1078     $^M = 'a' x (1 << 16);
1079
1080 would allocate a 64K buffer for use in an emergency.  See the
1081 F<INSTALL> file in the Perl distribution for information on how to
1082 add custom C compilation flags when compiling perl.  To discourage casual
1083 use of this advanced feature, there is no L<English|English> long name for
1084 this variable.
1085
1086 =item $OSNAME
1087
1088 =item $^O
1089 X<$^O> X<$OSNAME>
1090
1091 The name of the operating system under which this copy of Perl was
1092 built, as determined during the configuration process.  The value
1093 is identical to C<$Config{'osname'}>.  See also L<Config> and the 
1094 B<-V> command-line switch documented in L<perlrun>.
1095
1096 In Windows platforms, $^O is not very helpful: since it is always
1097 C<MSWin32>, it doesn't tell the difference between
1098 95/98/ME/NT/2000/XP/CE/.NET.  Use Win32::GetOSName() or
1099 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
1100 between the variants.
1101
1102 =item ${^OPEN}
1103
1104 An internal variable used by PerlIO.  A string in two parts, separated
1105 by a C<\0> byte, the first part describes the input layers, the second
1106 part describes the output layers.
1107
1108 =item $PERLDB
1109
1110 =item $^P
1111 X<$^P> X<$PERLDB>
1112
1113 The internal variable for debugging support.  The meanings of the
1114 various bits are subject to change, but currently indicate:
1115
1116 =over 6
1117
1118 =item 0x01
1119
1120 Debug subroutine enter/exit.
1121
1122 =item 0x02
1123
1124 Line-by-line debugging.
1125
1126 =item 0x04
1127
1128 Switch off optimizations.
1129
1130 =item 0x08
1131
1132 Preserve more data for future interactive inspections.
1133
1134 =item 0x10
1135
1136 Keep info about source lines on which a subroutine is defined.
1137
1138 =item 0x20
1139
1140 Start with single-step on.
1141
1142 =item 0x40
1143
1144 Use subroutine address instead of name when reporting.
1145
1146 =item 0x80
1147
1148 Report C<goto &subroutine> as well.
1149
1150 =item 0x100
1151
1152 Provide informative "file" names for evals based on the place they were compiled.
1153
1154 =item 0x200
1155
1156 Provide informative names to anonymous subroutines based on the place they
1157 were compiled.
1158
1159 =item 0x400
1160
1161 Debug assertion subroutines enter/exit.
1162
1163 =back
1164
1165 Some bits may be relevant at compile-time only, some at
1166 run-time only.  This is a new mechanism and the details may change.
1167
1168 =item $LAST_REGEXP_CODE_RESULT
1169
1170 =item $^R
1171 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1172
1173 The result of evaluation of the last successful C<(?{ code })>
1174 regular expression assertion (see L<perlre>).  May be written to.
1175
1176 =item $EXCEPTIONS_BEING_CAUGHT
1177
1178 =item $^S
1179 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1180
1181 Current state of the interpreter.
1182
1183     $^S         State
1184     ---------   -------------------
1185     undef       Parsing module/eval
1186     true (1)    Executing an eval
1187     false (0)   Otherwise
1188
1189 The first state may happen in $SIG{__DIE__} and $SIG{__WARN__} handlers.
1190
1191 =item $BASETIME
1192
1193 =item $^T
1194 X<$^T> X<$BASETIME>
1195
1196 The time at which the program began running, in seconds since the
1197 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
1198 and B<-C> filetests are based on this value.
1199
1200 =item ${^TAINT}
1201
1202 Reflects if taint mode is on or off.  1 for on (the program was run with
1203 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
1204 B<-t> or B<-TU>).  This variable is read-only.
1205
1206 =item ${^UNICODE}
1207
1208 Reflects certain Unicode settings of Perl.  See L<perlrun>
1209 documentation for the C<-C> switch for more information about
1210 the possible values. This variable is set during Perl startup
1211 and is thereafter read-only.
1212
1213 =item ${^UTF8CACHE}
1214
1215 This variable controls the state of the internal UTF-8 offset caching code.
1216 1 for on (the default), 0 for off, -1 to debug the caching code by checking
1217 all its results against linear scans, and panicking on any discrepancy.
1218
1219 =item ${^UTF8LOCALE}
1220
1221 This variable indicates whether an UTF-8 locale was detected by perl at
1222 startup. This information is used by perl when it's in
1223 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
1224 switch); see L<perlrun> for more info on this.
1225
1226 =item $PERL_VERSION
1227
1228 =item $^V
1229 X<$^V> X<$PERL_VERSION>
1230
1231 The revision, version, and subversion of the Perl interpreter, represented
1232 as a string composed of characters with those ordinals.  Thus in Perl v5.6.0
1233 it equals C<chr(5) . chr(6) . chr(0)> and will return true for
1234 C<$^V eq v5.6.0>.  Note that the characters in this string value can
1235 potentially be in Unicode range.
1236
1237 This variable first appeared in perl 5.6.0; earlier versions of perl will
1238 see an undefined value.
1239
1240 This can be used to determine whether the Perl interpreter executing a
1241 script is in the right range of versions.  (Mnemonic: use ^V for Version
1242 Control.)  Example:
1243
1244     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
1245
1246 To convert C<$^V> into its string representation use sprintf()'s
1247 C<"%vd"> conversion:
1248
1249     printf "version is v%vd\n", $^V;  # Perl's version
1250
1251 See the documentation of C<use VERSION> and C<require VERSION>
1252 for a convenient way to fail if the running Perl interpreter is too old.
1253
1254 See also C<$]> for an older representation of the Perl version.
1255
1256 =item $WARNING
1257
1258 =item $^W
1259 X<$^W> X<$WARNING>
1260
1261 The current value of the warning switch, initially true if B<-w>
1262 was used, false otherwise, but directly modifiable.  (Mnemonic:
1263 related to the B<-w> switch.)  See also L<warnings>.
1264
1265 =item ${^WARNING_BITS}
1266
1267 The current set of warning checks enabled by the C<use warnings> pragma.
1268 See the documentation of C<warnings> for more details.
1269
1270 =item ${^WIN32_SLOPPY_STAT}
1271
1272 If this variable is set to a true value, then stat() on Windows will
1273 not try to open the file. This means that the link count cannot be
1274 determined and file attributes may be out of date if additional
1275 hardlinks to the file exist. On the other hand, not opening the file
1276 is considerably faster, especially for files on network drives.
1277
1278 This variable could be set in the F<sitecustomize.pl> file to
1279 configure the local Perl installation to use "sloppy" stat() by
1280 default.  See L<perlrun> for more information about site
1281 customization.
1282
1283 =item $EXECUTABLE_NAME
1284
1285 =item $^X
1286 X<$^X> X<$EXECUTABLE_NAME>
1287
1288 The name used to execute the current copy of Perl, from C's
1289 C<argv[0]> or (where supported) F</proc/self/exe>.
1290
1291 Depending on the host operating system, the value of $^X may be
1292 a relative or absolute pathname of the perl program file, or may
1293 be the string used to invoke perl but not the pathname of the
1294 perl program file.  Also, most operating systems permit invoking
1295 programs that are not in the PATH environment variable, so there
1296 is no guarantee that the value of $^X is in PATH.  For VMS, the
1297 value may or may not include a version number.
1298
1299 You usually can use the value of $^X to re-invoke an independent
1300 copy of the same perl that is currently running, e.g.,
1301
1302   @first_run = `$^X -le "print int rand 100 for 1..100"`;
1303
1304 But recall that not all operating systems support forking or
1305 capturing of the output of commands, so this complex statement
1306 may not be portable.
1307
1308 It is not safe to use the value of $^X as a path name of a file,
1309 as some operating systems that have a mandatory suffix on
1310 executable files do not require use of the suffix when invoking
1311 a command.  To convert the value of $^X to a path name, use the
1312 following statements:
1313
1314   # Build up a set of file names (not command names).
1315   use Config;
1316   $this_perl = $^X;
1317   if ($^O ne 'VMS')
1318      {$this_perl .= $Config{_exe}
1319           unless $this_perl =~ m/$Config{_exe}$/i;}
1320
1321 Because many operating systems permit anyone with read access to
1322 the Perl program file to make a copy of it, patch the copy, and
1323 then execute the copy, the security-conscious Perl programmer
1324 should take care to invoke the installed copy of perl, not the
1325 copy referenced by $^X.  The following statements accomplish
1326 this goal, and produce a pathname that can be invoked as a
1327 command or referenced as a file.
1328
1329   use Config;
1330   $secure_perl_path = $Config{perlpath};
1331   if ($^O ne 'VMS')
1332      {$secure_perl_path .= $Config{_exe}
1333           unless $secure_perl_path =~ m/$Config{_exe}$/i;}
1334
1335 =item ARGV
1336 X<ARGV>
1337
1338 The special filehandle that iterates over command-line filenames in
1339 C<@ARGV>. Usually written as the null filehandle in the angle operator
1340 C<< <> >>. Note that currently C<ARGV> only has its magical effect
1341 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1342 corresponding to the last file opened by C<< <> >>. In particular,
1343 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1344 may not cause your function to automatically read the contents of all the
1345 files in C<@ARGV>.
1346
1347 =item $ARGV
1348 X<$ARGV>
1349
1350 contains the name of the current file when reading from <>.
1351
1352 =item @ARGV
1353 X<@ARGV>
1354
1355 The array @ARGV contains the command-line arguments intended for
1356 the script.  C<$#ARGV> is generally the number of arguments minus
1357 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1358 command name itself.  See C<$0> for the command name.
1359
1360 =item ARGVOUT
1361 X<ARGVOUT>
1362
1363 The special filehandle that points to the currently open output file
1364 when doing edit-in-place processing with B<-i>.  Useful when you have
1365 to do a lot of inserting and don't want to keep modifying $_.  See
1366 L<perlrun> for the B<-i> switch.
1367
1368 =item @F
1369 X<@F>
1370
1371 The array @F contains the fields of each line read in when autosplit
1372 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
1373 is package-specific, and must be declared or given a full package name
1374 if not in package main when running under C<strict 'vars'>.
1375
1376 =item @INC
1377 X<@INC>
1378
1379 The array @INC contains the list of places that the C<do EXPR>,
1380 C<require>, or C<use> constructs look for their library files.  It
1381 initially consists of the arguments to any B<-I> command-line
1382 switches, followed by the default Perl library, probably
1383 F</usr/local/lib/perl>, followed by ".", to represent the current
1384 directory.  ("." will not be appended if taint checks are enabled, either by
1385 C<-T> or by C<-t>.)  If you need to modify this at runtime, you should use
1386 the C<use lib> pragma to get the machine-dependent library properly
1387 loaded also:
1388
1389     use lib '/mypath/libdir/';
1390     use SomeMod;
1391
1392 You can also insert hooks into the file inclusion system by putting Perl
1393 code directly into @INC.  Those hooks may be subroutine references, array
1394 references or blessed objects.  See L<perlfunc/require> for details.
1395
1396 =item @ARG
1397
1398 =item @_
1399 X<@_> X<@ARG>
1400
1401 Within a subroutine the array @_ contains the parameters passed to that
1402 subroutine.  See L<perlsub>.
1403
1404 =item %INC
1405 X<%INC>
1406
1407 The hash %INC contains entries for each filename included via the
1408 C<do>, C<require>, or C<use> operators.  The key is the filename
1409 you specified (with module names converted to pathnames), and the
1410 value is the location of the file found.  The C<require>
1411 operator uses this hash to determine whether a particular file has
1412 already been included.
1413
1414 If the file was loaded via a hook (e.g. a subroutine reference, see
1415 L<perlfunc/require> for a description of these hooks), this hook is
1416 by default inserted into %INC in place of a filename.  Note, however,
1417 that the hook may have set the %INC entry by itself to provide some more
1418 specific info.
1419
1420 =item %ENV
1421
1422 =item $ENV{expr}
1423 X<%ENV>
1424
1425 The hash %ENV contains your current environment.  Setting a
1426 value in C<ENV> changes the environment for any child processes
1427 you subsequently fork() off.
1428
1429 =item %SIG
1430
1431 =item $SIG{expr}
1432 X<%SIG>
1433
1434 The hash C<%SIG> contains signal handlers for signals.  For example:
1435
1436     sub handler {       # 1st argument is signal name
1437         my($sig) = @_;
1438         print "Caught a SIG$sig--shutting down\n";
1439         close(LOG);
1440         exit(0);
1441     }
1442
1443     $SIG{'INT'}  = \&handler;
1444     $SIG{'QUIT'} = \&handler;
1445     ...
1446     $SIG{'INT'}  = 'DEFAULT';   # restore default action
1447     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
1448
1449 Using a value of C<'IGNORE'> usually has the effect of ignoring the
1450 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
1451 this special case.
1452
1453 Here are some other examples:
1454
1455     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
1456     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
1457     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
1458     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
1459
1460 Be sure not to use a bareword as the name of a signal handler,
1461 lest you inadvertently call it. 
1462
1463 If your system has the sigaction() function then signal handlers are
1464 installed using it.  This means you get reliable signal handling.
1465
1466 The default delivery policy of signals changed in Perl 5.8.0 from 
1467 immediate (also known as "unsafe") to deferred, also known as 
1468 "safe signals".  See L<perlipc> for more information.
1469
1470 Certain internal hooks can be also set using the %SIG hash.  The
1471 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
1472 about to be printed.  The warning message is passed as the first
1473 argument.  The presence of a C<__WARN__> hook causes the ordinary printing
1474 of warnings to C<STDERR> to be suppressed.  You can use this to save warnings
1475 in a variable, or turn warnings into fatal errors, like this:
1476
1477     local $SIG{__WARN__} = sub { die $_[0] };
1478     eval $proggie;
1479
1480 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
1481 disable warnings using the empty subroutine:
1482
1483     local $SIG{__WARN__} = sub {};
1484
1485 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
1486 is about to be thrown.  The error message is passed as the first
1487 argument.  When a C<__DIE__> hook routine returns, the exception
1488 processing continues as it would have in the absence of the hook,
1489 unless the hook routine itself exits via a C<goto>, a loop exit, or a C<die()>.
1490 The C<__DIE__> handler is explicitly disabled during the call, so that you
1491 can die from a C<__DIE__> handler.  Similarly for C<__WARN__>.
1492
1493 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
1494 even inside an eval().  Do not use this to rewrite a pending exception
1495 in C<$@>, or as a bizarre substitute for overriding C<CORE::GLOBAL::die()>.
1496 This strange action at a distance may be fixed in a future release
1497 so that C<$SIG{__DIE__}> is only called if your program is about
1498 to exit, as was the original intent.  Any other use is deprecated.
1499
1500 C<__DIE__>/C<__WARN__> handlers are very special in one respect:
1501 they may be called to report (probable) errors found by the parser.
1502 In such a case the parser may be in inconsistent state, so any
1503 attempt to evaluate Perl code from such a handler will probably
1504 result in a segfault.  This means that warnings or errors that
1505 result from parsing Perl should be used with extreme caution, like
1506 this:
1507
1508     require Carp if defined $^S;
1509     Carp::confess("Something wrong") if defined &Carp::confess;
1510     die "Something wrong, but could not load Carp to give backtrace...
1511          To see backtrace try starting Perl with -MCarp switch";
1512
1513 Here the first line will load Carp I<unless> it is the parser who
1514 called the handler.  The second line will print backtrace and die if
1515 Carp was available.  The third line will be executed only if Carp was
1516 not available.
1517
1518 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
1519 L<warnings> for additional information.
1520
1521 =back
1522
1523 =head2 Error Indicators
1524 X<error> X<exception>
1525
1526 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1527 about different types of error conditions that may appear during
1528 execution of a Perl program.  The variables are shown ordered by
1529 the "distance" between the subsystem which reported the error and
1530 the Perl process.  They correspond to errors detected by the Perl
1531 interpreter, C library, operating system, or an external program,
1532 respectively.
1533
1534 To illustrate the differences between these variables, consider the 
1535 following Perl expression, which uses a single-quoted string:
1536
1537     eval q{
1538         open my $pipe, "/cdrom/install |" or die $!;
1539         my @res = <$pipe>;
1540         close $pipe or die "bad pipe: $?, $!";
1541     };
1542
1543 After execution of this statement all 4 variables may have been set.  
1544
1545 C<$@> is set if the string to be C<eval>-ed did not compile (this
1546 may happen if C<open> or C<close> were imported with bad prototypes),
1547 or if Perl code executed during evaluation die()d .  In these cases
1548 the value of $@ is the compile error, or the argument to C<die>
1549 (which will interpolate C<$!> and C<$?>).  (See also L<Fatal>,
1550 though.)
1551
1552 When the eval() expression above is executed, open(), C<< <PIPE> >>,
1553 and C<close> are translated to calls in the C run-time library and
1554 thence to the operating system kernel.  C<$!> is set to the C library's
1555 C<errno> if one of these calls fails. 
1556
1557 Under a few operating systems, C<$^E> may contain a more verbose
1558 error indicator, such as in this case, "CDROM tray not closed."
1559 Systems that do not support extended error messages leave C<$^E>
1560 the same as C<$!>.
1561
1562 Finally, C<$?> may be set to non-0 value if the external program
1563 F</cdrom/install> fails.  The upper eight bits reflect specific
1564 error conditions encountered by the program (the program's exit()
1565 value).   The lower eight bits reflect mode of failure, like signal
1566 death and core dump information  See wait(2) for details.  In
1567 contrast to C<$!> and C<$^E>, which are set only if error condition
1568 is detected, the variable C<$?> is set on each C<wait> or pipe
1569 C<close>, overwriting the old value.  This is more like C<$@>, which
1570 on every eval() is always set on failure and cleared on success.
1571
1572 For more details, see the individual descriptions at C<$@>, C<$!>, C<$^E>,
1573 and C<$?>.
1574
1575 =head2 Technical Note on the Syntax of Variable Names
1576
1577 Variable names in Perl can have several formats.  Usually, they
1578 must begin with a letter or underscore, in which case they can be
1579 arbitrarily long (up to an internal limit of 251 characters) and
1580 may contain letters, digits, underscores, or the special sequence
1581 C<::> or C<'>.  In this case, the part before the last C<::> or
1582 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
1583
1584 Perl variable names may also be a sequence of digits or a single
1585 punctuation or control character.  These names are all reserved for
1586 special uses by Perl; for example, the all-digits names are used
1587 to hold data captured by backreferences after a regular expression
1588 match.  Perl has a special syntax for the single-control-character
1589 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
1590 character.  For example, the notation C<$^W> (dollar-sign caret
1591 C<W>) is the scalar variable whose name is the single character
1592 control-C<W>.  This is better than typing a literal control-C<W>
1593 into your program.
1594
1595 Finally, new in Perl 5.6, Perl variable names may be alphanumeric
1596 strings that begin with control characters (or better yet, a caret).
1597 These variables must be written in the form C<${^Foo}>; the braces
1598 are not optional.  C<${^Foo}> denotes the scalar variable whose
1599 name is a control-C<F> followed by two C<o>'s.  These variables are
1600 reserved for future special uses by Perl, except for the ones that
1601 begin with C<^_> (control-underscore or caret-underscore).  No
1602 control-character name that begins with C<^_> will acquire a special
1603 meaning in any future version of Perl; such names may therefore be
1604 used safely in programs.  C<$^_> itself, however, I<is> reserved.
1605
1606 Perl identifiers that begin with digits, control characters, or
1607 punctuation characters are exempt from the effects of the C<package>
1608 declaration and are always forced to be in package C<main>; they are
1609 also exempt from C<strict 'vars'> errors.  A few other names are also
1610 exempt in these ways:
1611
1612         ENV             STDIN
1613         INC             STDOUT
1614         ARGV            STDERR
1615         ARGVOUT         _
1616         SIG
1617
1618 In particular, the new special C<${^_XYZ}> variables are always taken
1619 to be in package C<main>, regardless of any C<package> declarations
1620 presently in scope.  
1621
1622 =head1 BUGS
1623
1624 Due to an unfortunate accident of Perl's implementation, C<use
1625 English> imposes a considerable performance penalty on all regular
1626 expression matches in a program, regardless of whether they occur
1627 in the scope of C<use English>.  For that reason, saying C<use
1628 English> in libraries is strongly discouraged.  See the
1629 Devel::SawAmpersand module documentation from CPAN
1630 ( http://www.cpan.org/modules/by-module/Devel/ )
1631 for more information. Writing C<use English '-no_match_vars';>
1632 avoids the performance penalty.
1633
1634 Having to even think about the C<$^S> variable in your exception
1635 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
1636 invites grievous and difficult to track down errors.  Avoid it
1637 and use an C<END{}> or CORE::GLOBAL::die override instead.