This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: [PATCH] Initial attempt at named captures for perls regexp engine
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.  
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19 Matching operations can have various modifiers.  Modifiers
20 that relate to the interpretation of the regular expression inside
21 are listed below.  Modifiers that alter the way a regular expression
22 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and 
23 L<perlop/"Gory details of parsing quoted constructs">.
24
25 =over 4
26
27 =item i
28 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
29 X<regular expression, case-insensitive>
30
31 Do case-insensitive pattern matching.
32
33 If C<use locale> is in effect, the case map is taken from the current
34 locale.  See L<perllocale>.
35
36 =item m
37 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
38
39 Treat string as multiple lines.  That is, change "^" and "$" from matching
40 the start or end of the string to matching the start or end of any
41 line anywhere within the string.
42
43 =item s
44 X</s> X<regex, single-line> X<regexp, single-line>
45 X<regular expression, single-line>
46
47 Treat string as single line.  That is, change "." to match any character
48 whatsoever, even a newline, which normally it would not match.
49
50 Used together, as /ms, they let the "." match any character whatsoever,
51 while still allowing "^" and "$" to match, respectively, just after
52 and just before newlines within the string.
53
54 =item x
55 X</x>
56
57 Extend your pattern's legibility by permitting whitespace and comments.
58
59 =back
60
61 These are usually written as "the C</x> modifier", even though the delimiter
62 in question might not really be a slash.  Any of these
63 modifiers may also be embedded within the regular expression itself using
64 the C<(?...)> construct.  See below.
65
66 The C</x> modifier itself needs a little more explanation.  It tells
67 the regular expression parser to ignore whitespace that is neither
68 backslashed nor within a character class.  You can use this to break up
69 your regular expression into (slightly) more readable parts.  The C<#>
70 character is also treated as a metacharacter introducing a comment,
71 just as in ordinary Perl code.  This also means that if you want real
72 whitespace or C<#> characters in the pattern (outside a character
73 class, where they are unaffected by C</x>), then you'll either have to
74 escape them (using backslashes or C<\Q...\E>) or encode them using octal
75 or hex escapes.  Taken together, these features go a long way towards
76 making Perl's regular expressions more readable.  Note that you have to
77 be careful not to include the pattern delimiter in the comment--perl has
78 no way of knowing you did not intend to close the pattern early.  See
79 the C-comment deletion code in L<perlop>.  Also note that anything inside
80 a C<\Q...\E> stays unaffected by C</x>.
81 X</x>
82
83 =head2 Regular Expressions
84
85 The patterns used in Perl pattern matching derive from supplied in
86 the Version 8 regex routines.  (The routines are derived
87 (distantly) from Henry Spencer's freely redistributable reimplementation
88 of the V8 routines.)  See L<Version 8 Regular Expressions> for
89 details.
90
91 In particular the following metacharacters have their standard I<egrep>-ish
92 meanings:
93 X<metacharacter>
94 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
95
96
97     \   Quote the next metacharacter
98     ^   Match the beginning of the line
99     .   Match any character (except newline)
100     $   Match the end of the line (or before newline at the end)
101     |   Alternation
102     ()  Grouping
103     []  Character class
104
105 By default, the "^" character is guaranteed to match only the
106 beginning of the string, the "$" character only the end (or before the
107 newline at the end), and Perl does certain optimizations with the
108 assumption that the string contains only one line.  Embedded newlines
109 will not be matched by "^" or "$".  You may, however, wish to treat a
110 string as a multi-line buffer, such that the "^" will match after any
111 newline within the string, and "$" will match before any newline.  At the
112 cost of a little more overhead, you can do this by using the /m modifier
113 on the pattern match operator.  (Older programs did this by setting C<$*>,
114 but this practice has been removed in perl 5.9.)
115 X<^> X<$> X</m>
116
117 To simplify multi-line substitutions, the "." character never matches a
118 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
119 the string is a single line--even if it isn't.
120 X<.> X</s>
121
122 The following standard quantifiers are recognized:
123 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
124
125     *      Match 0 or more times
126     +      Match 1 or more times
127     ?      Match 1 or 0 times
128     {n}    Match exactly n times
129     {n,}   Match at least n times
130     {n,m}  Match at least n but not more than m times
131
132 (If a curly bracket occurs in any other context, it is treated
133 as a regular character.  In particular, the lower bound
134 is not optional.)  The "*" modifier is equivalent to C<{0,}>, the "+"
135 modifier to C<{1,}>, and the "?" modifier to C<{0,1}>.  n and m are limited
136 to integral values less than a preset limit defined when perl is built.
137 This is usually 32766 on the most common platforms.  The actual limit can
138 be seen in the error message generated by code such as this:
139
140     $_ **= $_ , / {$_} / for 2 .. 42;
141
142 By default, a quantified subpattern is "greedy", that is, it will match as
143 many times as possible (given a particular starting location) while still
144 allowing the rest of the pattern to match.  If you want it to match the
145 minimum number of times possible, follow the quantifier with a "?".  Note
146 that the meanings don't change, just the "greediness":
147 X<metacharacter> X<greedy> X<greedyness>
148 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
149
150     *?     Match 0 or more times
151     +?     Match 1 or more times
152     ??     Match 0 or 1 time
153     {n}?   Match exactly n times
154     {n,}?  Match at least n times
155     {n,m}? Match at least n but not more than m times
156
157 Because patterns are processed as double quoted strings, the following
158 also work:
159 X<\t> X<\n> X<\r> X<\f> X<\a> X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
160 X<\0> X<\c> X<\N> X<\x>
161
162     \t          tab                   (HT, TAB)
163     \n          newline               (LF, NL)
164     \r          return                (CR)
165     \f          form feed             (FF)
166     \a          alarm (bell)          (BEL)
167     \e          escape (think troff)  (ESC)
168     \033        octal char (think of a PDP-11)
169     \x1B        hex char
170     \x{263a}    wide hex char         (Unicode SMILEY)
171     \c[         control char
172     \N{name}    named char
173     \l          lowercase next char (think vi)
174     \u          uppercase next char (think vi)
175     \L          lowercase till \E (think vi)
176     \U          uppercase till \E (think vi)
177     \E          end case modification (think vi)
178     \Q          quote (disable) pattern metacharacters till \E
179
180 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
181 and C<\U> is taken from the current locale.  See L<perllocale>.  For
182 documentation of C<\N{name}>, see L<charnames>.
183
184 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
185 An unescaped C<$> or C<@> interpolates the corresponding variable,
186 while escaping will cause the literal string C<\$> to be matched.
187 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
188
189 In addition, Perl defines the following:
190 X<metacharacter>
191 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\X> X<\p> X<\P> X<\C>
192 X<word> X<whitespace>
193
194     \w       Match a "word" character (alphanumeric plus "_")
195     \W       Match a non-"word" character
196     \s       Match a whitespace character
197     \S       Match a non-whitespace character
198     \d       Match a digit character
199     \D       Match a non-digit character
200     \pP      Match P, named property.  Use \p{Prop} for longer names.
201     \PP      Match non-P
202     \X       Match eXtended Unicode "combining character sequence",
203              equivalent to (?:\PM\pM*)
204     \C       Match a single C char (octet) even under Unicode.
205              NOTE: breaks up characters into their UTF-8 bytes,
206              so you may end up with malformed pieces of UTF-8.
207              Unsupported in lookbehind.
208     \1       Backreference to a a specific group. 
209              '1' may actually be any positive integer
210     \k<name> Named backreference
211     \N{name} Named unicode character, or unicode escape.
212     \x12     Hexadecimal escape sequence
213     \x{1234} Long hexadecimal escape sequence
214
215 A C<\w> matches a single alphanumeric character (an alphabetic
216 character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
217 to match a string of Perl-identifier characters (which isn't the same
218 as matching an English word).  If C<use locale> is in effect, the list
219 of alphabetic characters generated by C<\w> is taken from the current
220 locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
221 C<\d>, and C<\D> within character classes, but if you try to use them
222 as endpoints of a range, that's not a range, the "-" is understood
223 literally.  If Unicode is in effect, C<\s> matches also "\x{85}",
224 "\x{2028}, and "\x{2029}", see L<perlunicode> for more details about
225 C<\pP>, C<\PP>, and C<\X>, and L<perluniintro> about Unicode in general.
226 You can define your own C<\p> and C<\P> properties, see L<perlunicode>.
227 X<\w> X<\W> X<word>
228
229 The POSIX character class syntax
230 X<character class>
231
232     [:class:]
233
234 is also available.  Note that the C<[> and C<]> braces are I<literal>;
235 they must always be used within a character class expression.
236
237     # this is correct:
238     $string =~ /[[:alpha:]]/;
239
240     # this is not, and will generate a warning:
241     $string =~ /[:alpha:]/;
242
243 The available classes and their backslash equivalents (if available) are
244 as follows:
245 X<character class>
246 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
247 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
248
249     alpha
250     alnum
251     ascii
252     blank               [1]
253     cntrl
254     digit       \d
255     graph
256     lower
257     print
258     punct
259     space       \s      [2]
260     upper
261     word        \w      [3]
262     xdigit
263
264 =over
265
266 =item [1]
267
268 A GNU extension equivalent to C<[ \t]>, "all horizontal whitespace".
269
270 =item [2]
271
272 Not exactly equivalent to C<\s> since the C<[[:space:]]> includes
273 also the (very rare) "vertical tabulator", "\ck", chr(11).
274
275 =item [3]
276
277 A Perl extension, see above.
278
279 =back
280
281 For example use C<[:upper:]> to match all the uppercase characters.
282 Note that the C<[]> are part of the C<[::]> construct, not part of the
283 whole character class.  For example:
284
285     [01[:alpha:]%]
286
287 matches zero, one, any alphabetic character, and the percentage sign.
288
289 The following equivalences to Unicode \p{} constructs and equivalent
290 backslash character classes (if available), will hold:
291 X<character class> X<\p> X<\p{}>
292
293     [[:...:]]   \p{...}         backslash
294
295     alpha       IsAlpha
296     alnum       IsAlnum
297     ascii       IsASCII
298     blank       IsSpace
299     cntrl       IsCntrl
300     digit       IsDigit        \d
301     graph       IsGraph
302     lower       IsLower
303     print       IsPrint
304     punct       IsPunct
305     space       IsSpace
306                 IsSpacePerl    \s
307     upper       IsUpper
308     word        IsWord
309     xdigit      IsXDigit
310
311 For example C<[[:lower:]]> and C<\p{IsLower}> are equivalent.
312
313 If the C<utf8> pragma is not used but the C<locale> pragma is, the
314 classes correlate with the usual isalpha(3) interface (except for
315 "word" and "blank").
316
317 The assumedly non-obviously named classes are:
318
319 =over 4
320
321 =item cntrl
322 X<cntrl>
323
324 Any control character.  Usually characters that don't produce output as
325 such but instead control the terminal somehow: for example newline and
326 backspace are control characters.  All characters with ord() less than
327 32 are most often classified as control characters (assuming ASCII,
328 the ISO Latin character sets, and Unicode), as is the character with
329 the ord() value of 127 (C<DEL>).
330
331 =item graph
332 X<graph>
333
334 Any alphanumeric or punctuation (special) character.
335
336 =item print
337 X<print>
338
339 Any alphanumeric or punctuation (special) character or the space character.
340
341 =item punct
342 X<punct>
343
344 Any punctuation (special) character.
345
346 =item xdigit
347 X<xdigit>
348
349 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
350 work just fine) it is included for completeness.
351
352 =back
353
354 You can negate the [::] character classes by prefixing the class name
355 with a '^'. This is a Perl extension.  For example:
356 X<character class, negation>
357
358     POSIX         traditional  Unicode
359
360     [[:^digit:]]    \D         \P{IsDigit}
361     [[:^space:]]    \S         \P{IsSpace}
362     [[:^word:]]     \W         \P{IsWord}
363
364 Perl respects the POSIX standard in that POSIX character classes are
365 only supported within a character class.  The POSIX character classes
366 [.cc.] and [=cc=] are recognized but B<not> supported and trying to
367 use them will cause an error.
368
369 Perl defines the following zero-width assertions:
370 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
371 X<regexp, zero-width assertion>
372 X<regular expression, zero-width assertion>
373 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
374
375     \b  Match a word boundary
376     \B  Match a non-(word boundary)
377     \A  Match only at beginning of string
378     \Z  Match only at end of string, or before newline at the end
379     \z  Match only at end of string
380     \G  Match only at pos() (e.g. at the end-of-match position
381         of prior m//g)
382
383 A word boundary (C<\b>) is a spot between two characters
384 that has a C<\w> on one side of it and a C<\W> on the other side
385 of it (in either order), counting the imaginary characters off the
386 beginning and end of the string as matching a C<\W>.  (Within
387 character classes C<\b> represents backspace rather than a word
388 boundary, just as it normally does in any double-quoted string.)
389 The C<\A> and C<\Z> are just like "^" and "$", except that they
390 won't match multiple times when the C</m> modifier is used, while
391 "^" and "$" will match at every internal line boundary.  To match
392 the actual end of the string and not ignore an optional trailing
393 newline, use C<\z>.
394 X<\b> X<\A> X<\Z> X<\z> X</m>
395
396 The C<\G> assertion can be used to chain global matches (using
397 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
398 It is also useful when writing C<lex>-like scanners, when you have
399 several patterns that you want to match against consequent substrings
400 of your string, see the previous reference.  The actual location
401 where C<\G> will match can also be influenced by using C<pos()> as
402 an lvalue: see L<perlfunc/pos>. Currently C<\G> is only fully
403 supported when anchored to the start of the pattern; while it
404 is permitted to use it elsewhere, as in C</(?<=\G..)./g>, some
405 such uses (C</.\G/g>, for example) currently cause problems, and
406 it is recommended that you avoid such usage for now.
407 X<\G>
408
409 The bracketing construct C<( ... )> creates capture buffers.  To
410 refer to the digit'th buffer use \<digit> within the
411 match.  Outside the match use "$" instead of "\".  (The
412 \<digit> notation works in certain circumstances outside
413 the match.  See the warning below about \1 vs $1 for details.)
414 Referring back to another part of the match is called a
415 I<backreference>.
416 X<regex, capture buffer> X<regexp, capture buffer>
417 X<regular expression, capture buffer> X<backreference>
418
419 There is no limit to the number of captured substrings that you may
420 use.  However Perl also uses \10, \11, etc. as aliases for \010,
421 \011, etc.  (Recall that 0 means octal, so \011 is the character at
422 number 9 in your coded character set; which would be the 10th character,
423 a horizontal tab under ASCII.)  Perl resolves this
424 ambiguity by interpreting \10 as a backreference only if at least 10
425 left parentheses have opened before it.  Likewise \11 is a
426 backreference only if at least 11 left parentheses have opened
427 before it.  And so on.  \1 through \9 are always interpreted as
428 backreferences.
429
430 Additionally, as of Perl 5.10 you may use named capture buffers and named
431 backreferences. The notation is C<< (?<name>...) >> and C<< \k<name> >>
432 (you may also use single quotes instead of angle brackets to quote the
433 name). The only difference with named capture buffers and unnamed ones is
434 that multiple buffers may have the same name and that the contents of
435 named capture buffers is available via the C<%+> hash. When multiple
436 groups share the same name C<$+{name}> and C<< \k<name> >> refer to the
437 leftmost defined group, thus it's possible to do things with named capture
438 buffers that would otherwise require C<(??{})> code to accomplish. Named
439 capture buffers are numbered just as normal capture buffers are and may be
440 referenced via the magic numeric variables or via numeric backreferences
441 as well as by name.
442
443 Examples:
444
445     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
446
447     /(.)\1/                         # find first doubled char
448          and print "'$1' is the first doubled character\n";
449
450     /(?<char>.)\k<char>/            # ... a different way
451          and print "'$+{char}' is the first doubled character\n";
452
453     /(?<char>.)\1/                  # ... mix and match
454          and print "'$1' is the first doubled character\n";
455
456     if (/Time: (..):(..):(..)/) {   # parse out values
457         $hours = $1;
458         $minutes = $2;
459         $seconds = $3;
460     }
461
462 Several special variables also refer back to portions of the previous
463 match.  C<$+> returns whatever the last bracket match matched.
464 C<$&> returns the entire matched string.  (At one point C<$0> did
465 also, but now it returns the name of the program.)  C<$`> returns
466 everything before the matched string.  C<$'> returns everything
467 after the matched string. And C<$^N> contains whatever was matched by
468 the most-recently closed group (submatch). C<$^N> can be used in
469 extended patterns (see below), for example to assign a submatch to a
470 variable.
471 X<$+> X<$^N> X<$&> X<$`> X<$'>
472
473 The numbered match variables ($1, $2, $3, etc.) and the related punctuation
474 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
475 until the end of the enclosing block or until the next successful
476 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
477 X<$+> X<$^N> X<$&> X<$`> X<$'>
478 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
479
480
481 B<NOTE>: failed matches in Perl do not reset the match variables,
482 which makes it easier to write code that tests for a series of more
483 specific cases and remembers the best match.
484
485 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
486 C<$'> anywhere in the program, it has to provide them for every
487 pattern match.  This may substantially slow your program.  Perl
488 uses the same mechanism to produce $1, $2, etc, so you also pay a
489 price for each pattern that contains capturing parentheses.  (To
490 avoid this cost while retaining the grouping behaviour, use the
491 extended regular expression C<(?: ... )> instead.)  But if you never
492 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
493 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
494 if you can, but if you can't (and some algorithms really appreciate
495 them), once you've used them once, use them at will, because you've
496 already paid the price.  As of 5.005, C<$&> is not so costly as the
497 other two.
498 X<$&> X<$`> X<$'>
499
500 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
501 C<\w>, C<\n>.  Unlike some other regular expression languages, there
502 are no backslashed symbols that aren't alphanumeric.  So anything
503 that looks like \\, \(, \), \<, \>, \{, or \} is always
504 interpreted as a literal character, not a metacharacter.  This was
505 once used in a common idiom to disable or quote the special meanings
506 of regular expression metacharacters in a string that you want to
507 use for a pattern. Simply quote all non-"word" characters:
508
509     $pattern =~ s/(\W)/\\$1/g;
510
511 (If C<use locale> is set, then this depends on the current locale.)
512 Today it is more common to use the quotemeta() function or the C<\Q>
513 metaquoting escape sequence to disable all metacharacters' special
514 meanings like this:
515
516     /$unquoted\Q$quoted\E$unquoted/
517
518 Beware that if you put literal backslashes (those not inside
519 interpolated variables) between C<\Q> and C<\E>, double-quotish
520 backslash interpolation may lead to confusing results.  If you
521 I<need> to use literal backslashes within C<\Q...\E>,
522 consult L<perlop/"Gory details of parsing quoted constructs">.
523
524 =head2 Extended Patterns
525
526 Perl also defines a consistent extension syntax for features not
527 found in standard tools like B<awk> and B<lex>.  The syntax is a
528 pair of parentheses with a question mark as the first thing within
529 the parentheses.  The character after the question mark indicates
530 the extension.
531
532 The stability of these extensions varies widely.  Some have been
533 part of the core language for many years.  Others are experimental
534 and may change without warning or be completely removed.  Check
535 the documentation on an individual feature to verify its current
536 status.
537
538 A question mark was chosen for this and for the minimal-matching
539 construct because 1) question marks are rare in older regular
540 expressions, and 2) whenever you see one, you should stop and
541 "question" exactly what is going on.  That's psychology...
542
543 =over 10
544
545 =item C<(?#text)>
546 X<(?#)>
547
548 A comment.  The text is ignored.  If the C</x> modifier enables
549 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
550 the comment as soon as it sees a C<)>, so there is no way to put a literal
551 C<)> in the comment.
552
553 =item C<(?imsx-imsx)>
554 X<(?)>
555
556 One or more embedded pattern-match modifiers, to be turned on (or
557 turned off, if preceded by C<->) for the remainder of the pattern or
558 the remainder of the enclosing pattern group (if any). This is
559 particularly useful for dynamic patterns, such as those read in from a
560 configuration file, read in as an argument, are specified in a table
561 somewhere, etc.  Consider the case that some of which want to be case
562 sensitive and some do not.  The case insensitive ones need to include
563 merely C<(?i)> at the front of the pattern.  For example:
564
565     $pattern = "foobar";
566     if ( /$pattern/i ) { } 
567
568     # more flexible:
569
570     $pattern = "(?i)foobar";
571     if ( /$pattern/ ) { } 
572
573 These modifiers are restored at the end of the enclosing group. For example,
574
575     ( (?i) blah ) \s+ \1
576
577 will match a repeated (I<including the case>!) word C<blah> in any
578 case, assuming C<x> modifier, and no C<i> modifier outside this
579 group.
580
581 =item C<(?:pattern)>
582 X<(?:)>
583
584 =item C<(?imsx-imsx:pattern)>
585
586 This is for clustering, not capturing; it groups subexpressions like
587 "()", but doesn't make backreferences as "()" does.  So
588
589     @fields = split(/\b(?:a|b|c)\b/)
590
591 is like
592
593     @fields = split(/\b(a|b|c)\b/)
594
595 but doesn't spit out extra fields.  It's also cheaper not to capture
596 characters if you don't need to.
597
598 Any letters between C<?> and C<:> act as flags modifiers as with
599 C<(?imsx-imsx)>.  For example, 
600
601     /(?s-i:more.*than).*million/i
602
603 is equivalent to the more verbose
604
605     /(?:(?s-i)more.*than).*million/i
606
607 =item C<(?=pattern)>
608 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
609
610 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
611 matches a word followed by a tab, without including the tab in C<$&>.
612
613 =item C<(?!pattern)>
614 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
615
616 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
617 matches any occurrence of "foo" that isn't followed by "bar".  Note
618 however that look-ahead and look-behind are NOT the same thing.  You cannot
619 use this for look-behind.
620
621 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
622 will not do what you want.  That's because the C<(?!foo)> is just saying that
623 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
624 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
625 say "like" because there's the case of your "bar" not having three characters
626 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
627 Sometimes it's still easier just to say:
628
629     if (/bar/ && $` !~ /foo$/)
630
631 For look-behind see below.
632
633 =item C<(?<=pattern)>
634 X<(?<=)> X<look-behind, positive> X<lookbehind, positive>
635
636 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
637 matches a word that follows a tab, without including the tab in C<$&>.
638 Works only for fixed-width look-behind.
639
640 =item C<(?<!pattern)>
641 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
642
643 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
644 matches any occurrence of "foo" that does not follow "bar".  Works
645 only for fixed-width look-behind.
646
647 =item C<(?'NAME'pattern)>
648
649 =item C<< (?<NAME>pattern) >>
650 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
651
652 A named capture buffer. Identical in every respect to normal capturing
653 parens C<()> but for the additional fact that C<%+> may be used after
654 a succesful match to refer to a named buffer. See C<perlvar> for more
655 details on the C<%+> hash.
656
657 If multiple distinct capture buffers have the same name then the
658 $+{NAME} will refer to the leftmost defined buffer in the match.
659
660 The forms C<(?'NAME'pattern)> and C<(?<NAME>pattern)> are equivalent.
661
662 B<NOTE:> While the notation of this construct is the same as the similar
663 function in .NET regexes, the behavior is not, in Perl the buffers are
664 numbered sequentially regardless of being named or not. Thus in the
665 pattern
666
667   /(x)(?<foo>y)(z)/
668
669 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
670 the opposite which is what a .NET regex hacker might expect.
671
672 Currently NAME is restricted to word chars only. In other words, it
673 must match C</^\w+$/>.
674
675 =item C<< \k<name> >>
676
677 =item C<< \k'name' >>
678
679 Named backreference. Similar to numeric backreferences, except that
680 the group is designated by name and not number. If multiple groups
681 have the same name then it refers to the leftmost defined group in
682 the current match.
683
684 It is an error to refer to a name not defined by a C<(?<NAME>)>
685 earlier in the pattern.
686
687 Both forms are equivalent.
688
689 =item C<(?{ code })>
690 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
691
692 B<WARNING>: This extended regular expression feature is considered
693 highly experimental, and may be changed or deleted without notice.
694
695 This zero-width assertion evaluates any embedded Perl code.  It
696 always succeeds, and its C<code> is not interpolated.  Currently,
697 the rules to determine where the C<code> ends are somewhat convoluted.
698
699 This feature can be used together with the special variable C<$^N> to
700 capture the results of submatches in variables without having to keep
701 track of the number of nested parentheses. For example:
702
703   $_ = "The brown fox jumps over the lazy dog";
704   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
705   print "color = $color, animal = $animal\n";
706
707 Inside the C<(?{...})> block, C<$_> refers to the string the regular
708 expression is matching against. You can also use C<pos()> to know what is
709 the current position of matching within this string.
710
711 The C<code> is properly scoped in the following sense: If the assertion
712 is backtracked (compare L<"Backtracking">), all changes introduced after
713 C<local>ization are undone, so that
714
715   $_ = 'a' x 8;
716   m< 
717      (?{ $cnt = 0 })                    # Initialize $cnt.
718      (
719        a 
720        (?{
721            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
722        })
723      )*  
724      aaaa
725      (?{ $res = $cnt })                 # On success copy to non-localized
726                                         # location.
727    >x;
728
729 will set C<$res = 4>.  Note that after the match, $cnt returns to the globally
730 introduced value, because the scopes that restrict C<local> operators
731 are unwound.
732
733 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
734 switch.  If I<not> used in this way, the result of evaluation of
735 C<code> is put into the special variable C<$^R>.  This happens
736 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
737 inside the same regular expression.
738
739 The assignment to C<$^R> above is properly localized, so the old
740 value of C<$^R> is restored if the assertion is backtracked; compare
741 L<"Backtracking">.
742
743 Due to an unfortunate implementation issue, the Perl code contained in these
744 blocks is treated as a compile time closure that can have seemingly bizarre
745 consequences when used with lexically scoped variables inside of subroutines
746 or loops.  There are various workarounds for this, including simply using
747 global variables instead.  If you are using this construct and strange results
748 occur then check for the use of lexically scoped variables.
749
750 For reasons of security, this construct is forbidden if the regular
751 expression involves run-time interpolation of variables, unless the
752 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
753 variables contain results of C<qr//> operator (see
754 L<perlop/"qr/STRING/imosx">).  
755
756 This restriction is because of the wide-spread and remarkably convenient
757 custom of using run-time determined strings as patterns.  For example:
758
759     $re = <>;
760     chomp $re;
761     $string =~ /$re/;
762
763 Before Perl knew how to execute interpolated code within a pattern,
764 this operation was completely safe from a security point of view,
765 although it could raise an exception from an illegal pattern.  If
766 you turn on the C<use re 'eval'>, though, it is no longer secure,
767 so you should only do so if you are also using taint checking.
768 Better yet, use the carefully constrained evaluation within a Safe
769 compartment.  See L<perlsec> for details about both these mechanisms.
770
771 Because perl's regex engine is not currently re-entrant, interpolated 
772 code may not invoke the regex engine either directly with C<m//> or C<s///>),
773 or indirectly with functions such as C<split>.
774
775 =item C<(??{ code })>
776 X<(??{})>
777 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
778
779 B<WARNING>: This extended regular expression feature is considered
780 highly experimental, and may be changed or deleted without notice.
781 A simplified version of the syntax may be introduced for commonly
782 used idioms.
783
784 This is a "postponed" regular subexpression.  The C<code> is evaluated
785 at run time, at the moment this subexpression may match.  The result
786 of evaluation is considered as a regular expression and matched as
787 if it were inserted instead of this construct.  Note that this means
788 that the contents of capture buffers defined inside an eval'ed pattern
789 are not available outside of the pattern, and vice versa, there is no
790 way for the inner pattern to refer to a capture buffer defined outside.
791 Thus,
792
793     ('a' x 100)=~/(??{'(.)' x 100})/
794
795 B<will> match, it will B<not> set $1.
796
797 The C<code> is not interpolated.  As before, the rules to determine
798 where the C<code> ends are currently somewhat convoluted.
799
800 The following pattern matches a parenthesized group:
801
802   $re = qr{
803              \(
804              (?:
805                 (?> [^()]+ )    # Non-parens without backtracking
806               |
807                 (??{ $re })     # Group with matching parens
808              )*
809              \)
810           }x;
811
812 See also C<(?PARNO)> for a different, more efficient way to accomplish
813 the same task.
814
815 Because perl's regex engine is not currently re-entrant, delayed 
816 code may not invoke the regex engine either directly with C<m//> or C<s///>),
817 or indirectly with functions such as C<split>.
818
819 Recursing deeper than 50 times without consuming any input string will 
820 result in a fatal error.  The maximum depth is compiled into perl, so 
821 changing it requires a custom build.
822
823 =item C<(?PARNO)> C<(?R)>
824
825 X<(?PARNO)> X<(?1)>
826 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
827
828 B<WARNING>:  This extended regular expression feature is considered
829 highly experimental, and may be changed or deleted without notice.
830
831 Similar to C<(??{ code })> except it does not involve compiling any code,
832 instead it treats the contents of a capture buffer as an independent
833 pattern that must match at the current position.  Capture buffers
834 contained by the pattern will have the value as determined by the
835 outermost recursion.
836
837 PARNO is a sequence of digits not starting with 0 whose value
838 reflects the paren-number of the capture buffer to recurse to.
839 C<(?R)> curses to the beginning of the pattern.
840
841 The following pattern matches a function foo() which may contain
842 balanced parenthesis as the argument.
843
844   $re = qr{ (                    # paren group 1 (full function)
845               foo
846               (                  # paren group 2 (parens)
847                 \(
848                   (              # paren group 3 (contents of parens)
849                   (?:
850                    (?> [^()]+ )  # Non-parens without backtracking
851                   |
852                    (?2)          # Recurse to start of paren group 2
853                   )*
854                   )
855                 \)
856               )
857             )
858           }x;
859
860 If the pattern was used as follows
861
862     'foo(bar(baz)+baz(bop))'=~/$re/
863         and print "\$1 = $1\n",
864                   "\$2 = $2\n",
865                   "\$3 = $3\n";
866
867 the output produced should be the following:
868
869     $1 = foo(bar(baz)+baz(bop))
870     $2 = (bar(baz)+baz(bop))
871     $3 = bar(baz)+baz(bop)
872
873 If there is no corresponding capture buffer defined, then it is a
874 fatal error.  Recursing deeper than 50 times without consuming any input
875 string will also result in a fatal error.  The maximum depth is compiled
876 into perl, so changing it requires a custom build.
877
878 B<Note> that this pattern does not behave the same way as the equivalent
879 PCRE or Python construct of the same form. In perl you can backtrack into
880 a recursed group, in PCRE and Python the recursed into group is treated
881 as atomic. Also, constructs like (?i:(?1)) or (?:(?i)(?1)) do not affect
882 the pattern being recursed into.
883
884 =item C<< (?>pattern) >>
885 X<backtrack> X<backtracking> X<atomic> X<possessive>
886
887 B<WARNING>: This extended regular expression feature is considered
888 highly experimental, and may be changed or deleted without notice.
889
890 An "independent" subexpression, one which matches the substring
891 that a I<standalone> C<pattern> would match if anchored at the given
892 position, and it matches I<nothing other than this substring>.  This
893 construct is useful for optimizations of what would otherwise be
894 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
895 It may also be useful in places where the "grab all you can, and do not
896 give anything back" semantic is desirable.
897
898 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
899 (anchored at the beginning of string, as above) will match I<all>
900 characters C<a> at the beginning of string, leaving no C<a> for
901 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
902 since the match of the subgroup C<a*> is influenced by the following
903 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
904 C<a*ab> will match fewer characters than a standalone C<a*>, since
905 this makes the tail match.
906
907 An effect similar to C<< (?>pattern) >> may be achieved by writing
908 C<(?=(pattern))\1>.  This matches the same substring as a standalone
909 C<a+>, and the following C<\1> eats the matched string; it therefore
910 makes a zero-length assertion into an analogue of C<< (?>...) >>.
911 (The difference between these two constructs is that the second one
912 uses a capturing group, thus shifting ordinals of backreferences
913 in the rest of a regular expression.)
914
915 Consider this pattern:
916
917     m{ \(
918           ( 
919             [^()]+              # x+
920           | 
921             \( [^()]* \)
922           )+
923        \) 
924      }x
925
926 That will efficiently match a nonempty group with matching parentheses
927 two levels deep or less.  However, if there is no such group, it
928 will take virtually forever on a long string.  That's because there
929 are so many different ways to split a long string into several
930 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
931 to a subpattern of the above pattern.  Consider how the pattern
932 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
933 seconds, but that each extra letter doubles this time.  This
934 exponential performance will make it appear that your program has
935 hung.  However, a tiny change to this pattern
936
937     m{ \( 
938           ( 
939             (?> [^()]+ )        # change x+ above to (?> x+ )
940           | 
941             \( [^()]* \)
942           )+
943        \) 
944      }x
945
946 which uses C<< (?>...) >> matches exactly when the one above does (verifying
947 this yourself would be a productive exercise), but finishes in a fourth
948 the time when used on a similar string with 1000000 C<a>s.  Be aware,
949 however, that this pattern currently triggers a warning message under
950 the C<use warnings> pragma or B<-w> switch saying it
951 C<"matches null string many times in regex">.
952
953 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
954 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
955 This was only 4 times slower on a string with 1000000 C<a>s.
956
957 The "grab all you can, and do not give anything back" semantic is desirable
958 in many situations where on the first sight a simple C<()*> looks like
959 the correct solution.  Suppose we parse text with comments being delimited
960 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
961 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
962 the comment delimiter, because it may "give up" some whitespace if
963 the remainder of the pattern can be made to match that way.  The correct
964 answer is either one of these:
965
966     (?>#[ \t]*)
967     #[ \t]*(?![ \t])
968
969 For example, to grab non-empty comments into $1, one should use either
970 one of these:
971
972     / (?> \# [ \t]* ) (        .+ ) /x;
973     /     \# [ \t]*   ( [^ \t] .* ) /x;
974
975 Which one you pick depends on which of these expressions better reflects
976 the above specification of comments.
977
978 In some literature this construct is called "atomic matching" or
979 "possessive matching".
980
981 =item C<(?(condition)yes-pattern|no-pattern)>
982 X<(?()>
983
984 =item C<(?(condition)yes-pattern)>
985
986 B<WARNING>: This extended regular expression feature is considered
987 highly experimental, and may be changed or deleted without notice.
988
989 Conditional expression.  C<(condition)> should be either an integer in
990 parentheses (which is valid if the corresponding pair of parentheses
991 matched), or look-ahead/look-behind/evaluate zero-width assertion.
992
993 For example:
994
995     m{ ( \( )? 
996        [^()]+ 
997        (?(1) \) ) 
998      }x
999
1000 matches a chunk of non-parentheses, possibly included in parentheses
1001 themselves.
1002
1003 =back
1004
1005 =head2 Backtracking
1006 X<backtrack> X<backtracking>
1007
1008 NOTE: This section presents an abstract approximation of regular
1009 expression behavior.  For a more rigorous (and complicated) view of
1010 the rules involved in selecting a match among possible alternatives,
1011 see L<Combining pieces together>.
1012
1013 A fundamental feature of regular expression matching involves the
1014 notion called I<backtracking>, which is currently used (when needed)
1015 by all regular expression quantifiers, namely C<*>, C<*?>, C<+>,
1016 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1017 internally, but the general principle outlined here is valid.
1018
1019 For a regular expression to match, the I<entire> regular expression must
1020 match, not just part of it.  So if the beginning of a pattern containing a
1021 quantifier succeeds in a way that causes later parts in the pattern to
1022 fail, the matching engine backs up and recalculates the beginning
1023 part--that's why it's called backtracking.
1024
1025 Here is an example of backtracking:  Let's say you want to find the
1026 word following "foo" in the string "Food is on the foo table.":
1027
1028     $_ = "Food is on the foo table.";
1029     if ( /\b(foo)\s+(\w+)/i ) {
1030         print "$2 follows $1.\n";
1031     }
1032
1033 When the match runs, the first part of the regular expression (C<\b(foo)>)
1034 finds a possible match right at the beginning of the string, and loads up
1035 $1 with "Foo".  However, as soon as the matching engine sees that there's
1036 no whitespace following the "Foo" that it had saved in $1, it realizes its
1037 mistake and starts over again one character after where it had the
1038 tentative match.  This time it goes all the way until the next occurrence
1039 of "foo". The complete regular expression matches this time, and you get
1040 the expected output of "table follows foo."
1041
1042 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1043 everything between "foo" and "bar".  Initially, you write something
1044 like this:
1045
1046     $_ =  "The food is under the bar in the barn.";
1047     if ( /foo(.*)bar/ ) {
1048         print "got <$1>\n";
1049     }
1050
1051 Which perhaps unexpectedly yields:
1052
1053   got <d is under the bar in the >
1054
1055 That's because C<.*> was greedy, so you get everything between the
1056 I<first> "foo" and the I<last> "bar".  Here it's more effective
1057 to use minimal matching to make sure you get the text between a "foo"
1058 and the first "bar" thereafter.
1059
1060     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1061   got <d is under the >
1062
1063 Here's another example: let's say you'd like to match a number at the end
1064 of a string, and you also want to keep the preceding part of the match.
1065 So you write this:
1066
1067     $_ = "I have 2 numbers: 53147";
1068     if ( /(.*)(\d*)/ ) {                                # Wrong!
1069         print "Beginning is <$1>, number is <$2>.\n";
1070     }
1071
1072 That won't work at all, because C<.*> was greedy and gobbled up the
1073 whole string. As C<\d*> can match on an empty string the complete
1074 regular expression matched successfully.
1075
1076     Beginning is <I have 2 numbers: 53147>, number is <>.
1077
1078 Here are some variants, most of which don't work:
1079
1080     $_ = "I have 2 numbers: 53147";
1081     @pats = qw{
1082         (.*)(\d*)
1083         (.*)(\d+)
1084         (.*?)(\d*)
1085         (.*?)(\d+)
1086         (.*)(\d+)$
1087         (.*?)(\d+)$
1088         (.*)\b(\d+)$
1089         (.*\D)(\d+)$
1090     };
1091
1092     for $pat (@pats) {
1093         printf "%-12s ", $pat;
1094         if ( /$pat/ ) {
1095             print "<$1> <$2>\n";
1096         } else {
1097             print "FAIL\n";
1098         }
1099     }
1100
1101 That will print out:
1102
1103     (.*)(\d*)    <I have 2 numbers: 53147> <>
1104     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1105     (.*?)(\d*)   <> <>
1106     (.*?)(\d+)   <I have > <2>
1107     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1108     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1109     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1110     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1111
1112 As you see, this can be a bit tricky.  It's important to realize that a
1113 regular expression is merely a set of assertions that gives a definition
1114 of success.  There may be 0, 1, or several different ways that the
1115 definition might succeed against a particular string.  And if there are
1116 multiple ways it might succeed, you need to understand backtracking to
1117 know which variety of success you will achieve.
1118
1119 When using look-ahead assertions and negations, this can all get even
1120 trickier.  Imagine you'd like to find a sequence of non-digits not
1121 followed by "123".  You might try to write that as
1122
1123     $_ = "ABC123";
1124     if ( /^\D*(?!123)/ ) {              # Wrong!
1125         print "Yup, no 123 in $_\n";
1126     }
1127
1128 But that isn't going to match; at least, not the way you're hoping.  It
1129 claims that there is no 123 in the string.  Here's a clearer picture of
1130 why that pattern matches, contrary to popular expectations:
1131
1132     $x = 'ABC123';
1133     $y = 'ABC445';
1134
1135     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1136     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1137
1138     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1139     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1140
1141 This prints
1142
1143     2: got ABC
1144     3: got AB
1145     4: got ABC
1146
1147 You might have expected test 3 to fail because it seems to a more
1148 general purpose version of test 1.  The important difference between
1149 them is that test 3 contains a quantifier (C<\D*>) and so can use
1150 backtracking, whereas test 1 will not.  What's happening is
1151 that you've asked "Is it true that at the start of $x, following 0 or more
1152 non-digits, you have something that's not 123?"  If the pattern matcher had
1153 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1154 fail.
1155
1156 The search engine will initially match C<\D*> with "ABC".  Then it will
1157 try to match C<(?!123> with "123", which fails.  But because
1158 a quantifier (C<\D*>) has been used in the regular expression, the
1159 search engine can backtrack and retry the match differently
1160 in the hope of matching the complete regular expression.
1161
1162 The pattern really, I<really> wants to succeed, so it uses the
1163 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1164 time.  Now there's indeed something following "AB" that is not
1165 "123".  It's "C123", which suffices.
1166
1167 We can deal with this by using both an assertion and a negation.
1168 We'll say that the first part in $1 must be followed both by a digit
1169 and by something that's not "123".  Remember that the look-aheads
1170 are zero-width expressions--they only look, but don't consume any
1171 of the string in their match.  So rewriting this way produces what
1172 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1173
1174     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1175     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1176
1177     6: got ABC
1178
1179 In other words, the two zero-width assertions next to each other work as though
1180 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1181 matches only if you're at the beginning of the line AND the end of the
1182 line simultaneously.  The deeper underlying truth is that juxtaposition in
1183 regular expressions always means AND, except when you write an explicit OR
1184 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1185 although the attempted matches are made at different positions because "a"
1186 is not a zero-width assertion, but a one-width assertion.
1187
1188 B<WARNING>: particularly complicated regular expressions can take
1189 exponential time to solve because of the immense number of possible
1190 ways they can use backtracking to try match.  For example, without
1191 internal optimizations done by the regular expression engine, this will
1192 take a painfully long time to run:
1193
1194     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1195
1196 And if you used C<*>'s in the internal groups instead of limiting them
1197 to 0 through 5 matches, then it would take forever--or until you ran
1198 out of stack space.  Moreover, these internal optimizations are not
1199 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1200 on the external group, no current optimization is applicable, and the
1201 match takes a long time to finish.
1202
1203 A powerful tool for optimizing such beasts is what is known as an
1204 "independent group",
1205 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1206 zero-length look-ahead/look-behind assertions will not backtrack to make
1207 the tail match, since they are in "logical" context: only 
1208 whether they match is considered relevant.  For an example
1209 where side-effects of look-ahead I<might> have influenced the
1210 following match, see L<C<< (?>pattern) >>>.
1211
1212 =head2 Version 8 Regular Expressions
1213 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1214
1215 In case you're not familiar with the "regular" Version 8 regex
1216 routines, here are the pattern-matching rules not described above.
1217
1218 Any single character matches itself, unless it is a I<metacharacter>
1219 with a special meaning described here or above.  You can cause
1220 characters that normally function as metacharacters to be interpreted
1221 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1222 character; "\\" matches a "\").  A series of characters matches that
1223 series of characters in the target string, so the pattern C<blurfl>
1224 would match "blurfl" in the target string.
1225
1226 You can specify a character class, by enclosing a list of characters
1227 in C<[]>, which will match any one character from the list.  If the
1228 first character after the "[" is "^", the class matches any character not
1229 in the list.  Within a list, the "-" character specifies a
1230 range, so that C<a-z> represents all characters between "a" and "z",
1231 inclusive.  If you want either "-" or "]" itself to be a member of a
1232 class, put it at the start of the list (possibly after a "^"), or
1233 escape it with a backslash.  "-" is also taken literally when it is
1234 at the end of the list, just before the closing "]".  (The
1235 following all specify the same class of three characters: C<[-az]>,
1236 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1237 specifies a class containing twenty-six characters, even on EBCDIC
1238 based coded character sets.)  Also, if you try to use the character 
1239 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of 
1240 a range, that's not a range, the "-" is understood literally.
1241
1242 Note also that the whole range idea is rather unportable between
1243 character sets--and even within character sets they may cause results
1244 you probably didn't expect.  A sound principle is to use only ranges
1245 that begin from and end at either alphabets of equal case ([a-e],
1246 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1247 spell out the character sets in full.
1248
1249 Characters may be specified using a metacharacter syntax much like that
1250 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1251 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1252 of octal digits, matches the character whose coded character set value 
1253 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits, 
1254 matches the character whose numeric value is I<nn>. The expression \cI<x> 
1255 matches the character control-I<x>.  Finally, the "." metacharacter 
1256 matches any character except "\n" (unless you use C</s>).
1257
1258 You can specify a series of alternatives for a pattern using "|" to
1259 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1260 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1261 first alternative includes everything from the last pattern delimiter
1262 ("(", "[", or the beginning of the pattern) up to the first "|", and
1263 the last alternative contains everything from the last "|" to the next
1264 pattern delimiter.  That's why it's common practice to include
1265 alternatives in parentheses: to minimize confusion about where they
1266 start and end.
1267
1268 Alternatives are tried from left to right, so the first
1269 alternative found for which the entire expression matches, is the one that
1270 is chosen. This means that alternatives are not necessarily greedy. For
1271 example: when matching C<foo|foot> against "barefoot", only the "foo"
1272 part will match, as that is the first alternative tried, and it successfully
1273 matches the target string. (This might not seem important, but it is
1274 important when you are capturing matched text using parentheses.)
1275
1276 Also remember that "|" is interpreted as a literal within square brackets,
1277 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1278
1279 Within a pattern, you may designate subpatterns for later reference
1280 by enclosing them in parentheses, and you may refer back to the
1281 I<n>th subpattern later in the pattern using the metacharacter
1282 \I<n>.  Subpatterns are numbered based on the left to right order
1283 of their opening parenthesis.  A backreference matches whatever
1284 actually matched the subpattern in the string being examined, not
1285 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1286 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1287 1 matched "0x", even though the rule C<0|0x> could potentially match
1288 the leading 0 in the second number.
1289
1290 =head2 Warning on \1 vs $1
1291
1292 Some people get too used to writing things like:
1293
1294     $pattern =~ s/(\W)/\\\1/g;
1295
1296 This is grandfathered for the RHS of a substitute to avoid shocking the
1297 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1298 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1299 the usual double-quoted string means a control-A.  The customary Unix
1300 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1301 of doing that, you get yourself into trouble if you then add an C</e>
1302 modifier.
1303
1304     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1305
1306 Or if you try to do
1307
1308     s/(\d+)/\1000/;
1309
1310 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1311 C<${1}000>.  The operation of interpolation should not be confused
1312 with the operation of matching a backreference.  Certainly they mean two
1313 different things on the I<left> side of the C<s///>.
1314
1315 =head2 Repeated patterns matching zero-length substring
1316
1317 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1318
1319 Regular expressions provide a terse and powerful programming language.  As
1320 with most other power tools, power comes together with the ability
1321 to wreak havoc.
1322
1323 A common abuse of this power stems from the ability to make infinite
1324 loops using regular expressions, with something as innocuous as:
1325
1326     'foo' =~ m{ ( o? )* }x;
1327
1328 The C<o?> can match at the beginning of C<'foo'>, and since the position
1329 in the string is not moved by the match, C<o?> would match again and again
1330 because of the C<*> modifier.  Another common way to create a similar cycle
1331 is with the looping modifier C<//g>:
1332
1333     @matches = ( 'foo' =~ m{ o? }xg );
1334
1335 or
1336
1337     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1338
1339 or the loop implied by split().
1340
1341 However, long experience has shown that many programming tasks may
1342 be significantly simplified by using repeated subexpressions that
1343 may match zero-length substrings.  Here's a simple example being:
1344
1345     @chars = split //, $string;           # // is not magic in split
1346     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1347
1348 Thus Perl allows such constructs, by I<forcefully breaking
1349 the infinite loop>.  The rules for this are different for lower-level
1350 loops given by the greedy modifiers C<*+{}>, and for higher-level
1351 ones like the C</g> modifier or split() operator.
1352
1353 The lower-level loops are I<interrupted> (that is, the loop is
1354 broken) when Perl detects that a repeated expression matched a
1355 zero-length substring.   Thus
1356
1357    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1358
1359 is made equivalent to 
1360
1361    m{   (?: NON_ZERO_LENGTH )* 
1362       | 
1363         (?: ZERO_LENGTH )? 
1364     }x;
1365
1366 The higher level-loops preserve an additional state between iterations:
1367 whether the last match was zero-length.  To break the loop, the following 
1368 match after a zero-length match is prohibited to have a length of zero.
1369 This prohibition interacts with backtracking (see L<"Backtracking">), 
1370 and so the I<second best> match is chosen if the I<best> match is of
1371 zero length.
1372
1373 For example:
1374
1375     $_ = 'bar';
1376     s/\w??/<$&>/g;
1377
1378 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1379 match given by non-greedy C<??> is the zero-length match, and the I<second 
1380 best> match is what is matched by C<\w>.  Thus zero-length matches
1381 alternate with one-character-long matches.
1382
1383 Similarly, for repeated C<m/()/g> the second-best match is the match at the 
1384 position one notch further in the string.
1385
1386 The additional state of being I<matched with zero-length> is associated with
1387 the matched string, and is reset by each assignment to pos().
1388 Zero-length matches at the end of the previous match are ignored
1389 during C<split>.
1390
1391 =head2 Combining pieces together
1392
1393 Each of the elementary pieces of regular expressions which were described
1394 before (such as C<ab> or C<\Z>) could match at most one substring
1395 at the given position of the input string.  However, in a typical regular
1396 expression these elementary pieces are combined into more complicated
1397 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1398 (in these examples C<S> and C<T> are regular subexpressions).
1399
1400 Such combinations can include alternatives, leading to a problem of choice:
1401 if we match a regular expression C<a|ab> against C<"abc">, will it match
1402 substring C<"a"> or C<"ab">?  One way to describe which substring is
1403 actually matched is the concept of backtracking (see L<"Backtracking">).
1404 However, this description is too low-level and makes you think
1405 in terms of a particular implementation.
1406
1407 Another description starts with notions of "better"/"worse".  All the
1408 substrings which may be matched by the given regular expression can be
1409 sorted from the "best" match to the "worst" match, and it is the "best"
1410 match which is chosen.  This substitutes the question of "what is chosen?"
1411 by the question of "which matches are better, and which are worse?".
1412
1413 Again, for elementary pieces there is no such question, since at most
1414 one match at a given position is possible.  This section describes the
1415 notion of better/worse for combining operators.  In the description
1416 below C<S> and C<T> are regular subexpressions.
1417
1418 =over 4
1419
1420 =item C<ST>
1421
1422 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1423 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1424 which can be matched by C<T>. 
1425
1426 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1427 match than C<A'B'>.
1428
1429 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1430 C<B> is better match for C<T> than C<B'>.
1431
1432 =item C<S|T>
1433
1434 When C<S> can match, it is a better match than when only C<T> can match.
1435
1436 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
1437 two matches for C<T>.
1438
1439 =item C<S{REPEAT_COUNT}>
1440
1441 Matches as C<SSS...S> (repeated as many times as necessary).
1442
1443 =item C<S{min,max}>
1444
1445 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
1446
1447 =item C<S{min,max}?>
1448
1449 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
1450
1451 =item C<S?>, C<S*>, C<S+>
1452
1453 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
1454
1455 =item C<S??>, C<S*?>, C<S+?>
1456
1457 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
1458
1459 =item C<< (?>S) >>
1460
1461 Matches the best match for C<S> and only that.
1462
1463 =item C<(?=S)>, C<(?<=S)>
1464
1465 Only the best match for C<S> is considered.  (This is important only if
1466 C<S> has capturing parentheses, and backreferences are used somewhere
1467 else in the whole regular expression.)
1468
1469 =item C<(?!S)>, C<(?<!S)>
1470
1471 For this grouping operator there is no need to describe the ordering, since
1472 only whether or not C<S> can match is important.
1473
1474 =item C<(??{ EXPR })>, C<(?PARNO)>
1475
1476 The ordering is the same as for the regular expression which is
1477 the result of EXPR, or the pattern contained by capture buffer PARNO.
1478
1479 =item C<(?(condition)yes-pattern|no-pattern)>
1480
1481 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
1482 already determined.  The ordering of the matches is the same as for the
1483 chosen subexpression.
1484
1485 =back
1486
1487 The above recipes describe the ordering of matches I<at a given position>.
1488 One more rule is needed to understand how a match is determined for the
1489 whole regular expression: a match at an earlier position is always better
1490 than a match at a later position.
1491
1492 =head2 Creating custom RE engines
1493
1494 Overloaded constants (see L<overload>) provide a simple way to extend
1495 the functionality of the RE engine.
1496
1497 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
1498 matches at boundary between whitespace characters and non-whitespace
1499 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
1500 at these positions, so we want to have each C<\Y|> in the place of the
1501 more complicated version.  We can create a module C<customre> to do
1502 this:
1503
1504     package customre;
1505     use overload;
1506
1507     sub import {
1508       shift;
1509       die "No argument to customre::import allowed" if @_;
1510       overload::constant 'qr' => \&convert;
1511     }
1512
1513     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
1514
1515     # We must also take care of not escaping the legitimate \\Y|
1516     # sequence, hence the presence of '\\' in the conversion rules.
1517     my %rules = ( '\\' => '\\\\', 
1518                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
1519     sub convert {
1520       my $re = shift;
1521       $re =~ s{ 
1522                 \\ ( \\ | Y . )
1523               }
1524               { $rules{$1} or invalid($re,$1) }sgex; 
1525       return $re;
1526     }
1527
1528 Now C<use customre> enables the new escape in constant regular
1529 expressions, i.e., those without any runtime variable interpolations.
1530 As documented in L<overload>, this conversion will work only over
1531 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
1532 part of this regular expression needs to be converted explicitly
1533 (but only if the special meaning of C<\Y|> should be enabled inside $re):
1534
1535     use customre;
1536     $re = <>;
1537     chomp $re;
1538     $re = customre::convert $re;
1539     /\Y|$re\Y|/;
1540
1541 =head1 BUGS
1542
1543 This document varies from difficult to understand to completely
1544 and utterly opaque.  The wandering prose riddled with jargon is
1545 hard to fathom in several places.
1546
1547 This document needs a rewrite that separates the tutorial content
1548 from the reference content.
1549
1550 =head1 SEE ALSO
1551
1552 L<perlrequick>.
1553
1554 L<perlretut>.
1555
1556 L<perlop/"Regexp Quote-Like Operators">.
1557
1558 L<perlop/"Gory details of parsing quoted constructs">.
1559
1560 L<perlfaq6>.
1561
1562 L<perlfunc/pos>.
1563
1564 L<perllocale>.
1565
1566 L<perlebcdic>.
1567
1568 I<Mastering Regular Expressions> by Jeffrey Friedl, published
1569 by O'Reilly and Associates.