This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
8140ded50533feca15bcf2f11702463a445f4961
[perl5.git] / t / op / svleak.t
1 #!./perl
2
3 # A place to put some simple leak tests. Uses XS::APItest to make
4 # PL_sv_count available, allowing us to run a bit of code multiple times and
5 # see if the count increases.
6
7 BEGIN {
8     chdir 't';
9     @INC = '../lib';
10     require './test.pl';
11
12     eval { require XS::APItest; XS::APItest->import('sv_count'); 1 }
13         or skip_all("XS::APItest not available");
14 }
15
16 use Config;
17
18 plan tests => 115;
19
20 # run some code N times. If the number of SVs at the end of loop N is
21 # greater than (N-1)*delta at the end of loop 1, we've got a leak
22 #
23 sub leak {
24     my ($n, $delta, $code, @rest) = @_;
25     my $sv0 = 0;
26     my $sv1 = 0;
27     for my $i (1..$n) {
28         &$code();
29         $sv1 = sv_count();
30         $sv0 = $sv1 if $i == 1;
31     }
32     cmp_ok($sv1-$sv0, '<=', ($n-1)*$delta, @rest);
33 }
34
35 # Like leak, but run a string eval instead.
36 # The code is used instead of the test name
37 # if the name is absent.
38 sub eleak {
39     my ($n,$delta,$code,@rest) = @_;
40     leak $n, $delta, sub { eval $code },
41          @rest ? @rest : $code
42 }
43
44 # run some expression N times. The expr is concatenated N times and then
45 # evaled, ensuring that that there are no scope exits between executions.
46 # If the number of SVs at the end of expr N is greater than (N-1)*delta at
47 # the end of expr 1, we've got a leak
48 #
49 sub leak_expr {
50     my ($n, $delta, $expr, @rest) = @_;
51     my $sv0 = 0;
52     my $sv1 = 0;
53     my $true = 1; # avoid stuff being optimised away
54     my $code1 = "($expr || \$true)";
55     my $code = "$code1 && (\$sv0 = sv_count())" . ("&& $code1" x 4)
56                 . " && (\$sv1 = sv_count())";
57     if (eval $code) {
58         cmp_ok($sv1-$sv0, '<=', ($n-1)*$delta, @rest);
59     }
60     else {
61         fail("eval @rest: $@");
62     }
63 }
64
65
66 my @a;
67
68 leak(5, 0, sub {},                 "basic check 1 of leak test infrastructure");
69 leak(5, 0, sub {push @a,1;pop @a}, "basic check 2 of leak test infrastructure");
70 leak(5, 1, sub {push @a,1;},       "basic check 3 of leak test infrastructure");
71
72 # Fatal warnings
73 my $f = "use warnings FATAL =>";
74 my $all = "$f 'all';";
75 eleak(2, 0, "$f 'deprecated'; qq|\\c\{|", 'qq|\c{| with fatal warnings');
76 eleak(2, 0, "$f 'syntax'; qq|\\c`|", 'qq|\c`| with fatal warnings');
77 eleak(2, 0, "$all /\$\\ /", '/$\ / with fatal warnings');
78 eleak(2, 0, "$all s//\\1/", 's//\1/ with fatal warnings');
79 eleak(2, 0, "$all qq|\\i|", 'qq|\i| with fatal warnings');
80 eleak(2, 0, "$f 'digit'; qq|\\o{9}|", 'qq|\o{9}| with fatal warnings');
81 eleak(2, 0, "$f 'misc'; sub foo{} sub foo:lvalue",
82      'ignored :lvalue with fatal warnings');
83 eleak(2, 0, "no warnings; use feature ':all'; $f 'misc';
84              my sub foo{} sub foo:lvalue",
85      'ignored mysub :lvalue with fatal warnings');
86 eleak(2, 0, "no warnings; use feature ':all'; $all
87              my sub foo{} sub foo:lvalue{}",
88      'fatal mysub redef warning');
89 eleak(2, 0, "$all sub foo{} sub foo{}", 'fatal sub redef warning');
90 eleak(2, 0, "$all *x=sub {}",
91      'fatal sub redef warning with sub-to-glob assignment');
92 eleak(2, 0, "$all *x=sub() {1}",
93      'fatal const sub redef warning with sub-to-glob assignment');
94 eleak(2, 0, "$all XS::APItest::newCONSTSUB(\\%main::=>name=>0=>1)",
95      'newCONSTSUB sub redefinition with fatal warnings');
96 eleak(2, 0, "$f 'misc'; my\$a,my\$a", 'double my with fatal warnings');
97 eleak(2, 0, "$f 'misc'; our\$a,our\$a", 'double our with fatal warnings');
98 eleak(2, 0, "$f 'closure';
99              sub foo { my \$x; format=\n\@\n\$x\n.\n} write; ",
100      'format closing over unavailable var with fatal warnings');
101 eleak(2, 0, "$all /(?{})?/ ", '(?{})? with fatal warnings');
102 eleak(2, 0, "$all /(?{})+/ ", '(?{})+ with fatal warnings');
103 eleak(2, 0, "$all /[\\i]/ ", 'invalid charclass escape with fatal warns');
104 eleak(2, 0, "$all /[:foo:]/ ", '/[:foo:]/ with fatal warnings');
105 eleak(2, 0, "$all /[a-\\d]/ ", '[a-\d] char class with fatal warnings');
106 eleak(2, 0, "$all v111111111111111111111111111111111111111111111111",
107      'vstring num overflow with fatal warnings');
108
109 eleak(2, 0, 'sub{<*>}');
110 # Use a random number of ops, so that the glob op does not reuse the same
111 # address each time, giving us false passes.
112 leak(2, 0, sub { eval '$x+'x(1 + rand() * 100) . '<*>'; },
113     'freeing partly iterated glob');
114
115 eleak(2, 0, 'goto sub {}', 'goto &sub in eval');
116 eleak(2, 0, '() = sort { goto sub {} } 1,2', 'goto &sub in sort');
117 eleak(2, 0, '/(?{ goto sub {} })/', 'goto &sub in regexp');
118
119 sub TIEARRAY    { bless [], $_[0] }
120 sub FETCH       { $_[0]->[$_[1]] }
121 sub STORE       { $_[0]->[$_[1]] = $_[2] }
122
123 # local $tied_elem[..] leaks <20020502143736.N16831@dansat.data-plan.com>"
124 {
125     tie my @a, 'main';
126     leak(5, 0, sub {local $a[0]}, "local \$tied[0]");
127 }
128
129 # Overloading
130 require overload;
131 eleak(2, 0, "BEGIN{overload::constant integer=>sub{}} 1,1,1,1,1,1,1,1,1,1",
132      '"too many errors" from constant overloading returning undef');
133 # getting this one to leak was complicated; we have to unset LOCALIZE_HH:
134 eleak(2, 0, 'BEGIN{overload::constant integer=>sub{}; $^H &= ~ 0x00020000}
135              1,1,1,1,1,1,1,1,1,1',
136      '"too many errors" from constant overloading with $^H sabotaged');
137 eleak(2, 0, "BEGIN{overload::constant integer=>sub{}; undef %^H}
138              1,1,1,1,1,1,1,1,1,1",
139      '"too many errors" from constant overloading with %^H undefined');
140
141
142 # [perl #74484]  repeated tries leaked SVs on the tmps stack
143
144 leak_expr(5, 0, q{"YYYYYa" =~ /.+?(a(.+?)|b)/ }, "trie leak");
145
146 # [perl #48004] map/grep didn't free tmps till the end
147
148 {
149     # qr/1/ just creates tmps that are hopefully freed per iteration
150
151     my $s;
152     my @a;
153     my @count = (0) x 4; # pre-allocate
154
155     grep qr/1/ && ($count[$_] = sv_count()) && 99,  0..3;
156     is(@count[3] - @count[0], 0, "void   grep expr:  no new tmps per iter");
157     grep { qr/1/ && ($count[$_] = sv_count()) && 99 }  0..3;
158     is(@count[3] - @count[0], 0, "void   grep block: no new tmps per iter");
159
160     $s = grep qr/1/ && ($count[$_] = sv_count()) && 99,  0..3;
161     is(@count[3] - @count[0], 0, "scalar grep expr:  no new tmps per iter");
162     $s = grep { qr/1/ && ($count[$_] = sv_count()) && 99 }  0..3;
163     is(@count[3] - @count[0], 0, "scalar grep block: no new tmps per iter");
164
165     @a = grep qr/1/ && ($count[$_] = sv_count()) && 99,  0..3;
166     is(@count[3] - @count[0], 0, "list   grep expr:  no new tmps per iter");
167     @a = grep { qr/1/ && ($count[$_] = sv_count()) && 99 }  0..3;
168     is(@count[3] - @count[0], 0, "list   grep block: no new tmps per iter");
169
170
171     map qr/1/ && ($count[$_] = sv_count()) && 99,  0..3;
172     is(@count[3] - @count[0], 0, "void   map expr:  no new tmps per iter");
173     map { qr/1/ && ($count[$_] = sv_count()) && 99 }  0..3;
174     is(@count[3] - @count[0], 0, "void   map block: no new tmps per iter");
175
176     $s = map qr/1/ && ($count[$_] = sv_count()) && 99,  0..3;
177     is(@count[3] - @count[0], 0, "scalar map expr:  no new tmps per iter");
178     $s = map { qr/1/ && ($count[$_] = sv_count()) && 99 }  0..3;
179     is(@count[3] - @count[0], 0, "scalar map block: no new tmps per iter");
180
181     @a = map qr/1/ && ($count[$_] = sv_count()) && 99,  0..3;
182     is(@count[3] - @count[0], 3, "list   map expr:  one new tmp per iter");
183     @a = map { qr/1/ && ($count[$_] = sv_count()) && 99 }  0..3;
184     is(@count[3] - @count[0], 3, "list   map block: one new tmp per iter");
185
186 }
187
188 SKIP:
189 { # broken by 304474c3, fixed by cefd5c7c, but didn't seem to cause
190   # any other test failures
191   # base test case from ribasushi (Peter Rabbitson)
192   eval { require Scalar::Util; Scalar::Util->import("weaken"); 1; }
193     or skip "no weaken", 1;
194   my $weak;
195   {
196     $weak = my $in = {};
197     weaken($weak);
198     my $out = { in => $in, in => undef }
199   }
200   ok(!$weak, "hash referenced weakened SV released");
201 }
202
203 # prototype() errors
204 leak(2,0, sub { eval { prototype "CORE::fu" } }, 'prototype errors');
205
206 # RT #72246: rcatline memory leak on bad $/
207
208 leak(2, 0,
209     sub {
210         my $f;
211         open CATLINE, '<', \$f;
212         local $/ = "\x{262E}";
213         my $str = "\x{2622}";
214         eval { $str .= <CATLINE> };
215     },
216     "rcatline leak"
217 );
218
219 {
220     my $RE = qr/
221       (?:
222         <(?<tag>
223           \s*
224           [^>\s]+
225         )>
226       )??
227     /xis;
228
229     "<html><body></body></html>" =~ m/$RE/gcs;
230
231     leak(5, 0, sub {
232         my $tag = $+{tag};
233     }, "named regexp captures");
234 }
235
236 eleak(2,0,'/[:]/');
237 eleak(2,0,'/[\xdf]/i');
238 eleak(2,0,'s![^/]!!');
239 eleak(2,0,'/[pp]/');
240 eleak(2,0,'/[[:ascii:]]/');
241 eleak(2,0,'/[[.zog.]]/');
242 eleak(2,0,'/[.zog.]/');
243 eleak(2,0,'no warnings; /(?[])/');
244
245 # These can generate one ref count, but just  once.
246 eleak(4,1,'chr(0x100) =~ /[[:punct:]]/');
247 eleak(4,1,'chr(0x100) =~ /[[:^punct:]]/');
248 eleak(4,1,'chr(0x100) =~ /[[:word:]]/');
249 eleak(4,1,'chr(0x100) =~ /[[:^word:]]/');
250
251 eleak(2,0,'chr(0x100) =~ /\P{Assigned}/');
252 leak(2,0,sub { /(??{})/ }, '/(??{})/');
253
254 leak(2,0,sub { !$^V }, '[perl #109762] version object in boolean context');
255
256
257 # [perl #114356] run-time rexexp with unchanging pattern got
258 # inflated refcounts
259 eleak(2, 0, q{ my $x = "x"; "abc" =~ /$x/ for 1..5 }, '#114356');
260
261 eleak(2, 0, 'sub', '"sub" with nothing following');
262 eleak(2, 0, '+sub:a{}', 'anon subs with invalid attributes');
263 eleak(2, 0, 'no warnings; sub a{1 1}', 'sub with syntax error');
264 eleak(2, 0, 'no warnings; sub {1 1}', 'anon sub with syntax error');
265 eleak(2, 0, 'no warnings; use feature ":all"; my sub a{1 1}',
266      'my sub with syntax error');
267
268 # Reification (or lack thereof)
269 leak(2, 0, sub { sub { local $_[0]; shift }->(1) },
270     'local $_[0] on surreal @_, followed by shift');
271 leak(2, 0, sub { sub { local $_[0]; \@_ }->(1) },
272     'local $_[0] on surreal @_, followed by reification');
273
274 # Syntax errors
275 eleak(2, 0, '"${<<END}"
276                  ', 'unterminated here-doc in quotes in multiline eval');
277 eleak(2, 0, '"${<<END
278                }"', 'unterminated here-doc in multiline quotes in eval');
279 leak(2, 0, sub { eval { do './op/svleak.pl' } },
280         'unterminated here-doc in file');
281 eleak(2, 0, 'tr/9-0//');
282 eleak(2, 0, 'tr/a-z-0//');
283 eleak(2, 0, 'no warnings; nonexistent_function 33838',
284         'bareword followed by number');
285 eleak(2, 0, '//dd;'x20, '"too many errors" when parsing m// flags');
286 eleak(2, 0, 's///dd;'x20, '"too many errors" when parsing s/// flags');
287 eleak(2, 0, 'no warnings; 2 2;BEGIN{}',
288       'BEGIN block after syntax error');
289 {
290     local %INC; # in case Errno is already loaded
291     eleak(2, 0, 'no warnings; 2@!{',
292                 'implicit "use Errno" after syntax error');
293 }
294 eleak(2, 0, "\"\$\0\356\"", 'qq containing $ <null> something');
295 eleak(2, 0, 'END OF TERMS AND CONDITIONS', 'END followed by words');
296 eleak(2, 0, "+ + +;qq|\\N{a}|"x10,'qq"\N{a}" after errors');
297 eleak(2, 0, "qq|\\N{%}|",      'qq"\N{%}" (invalid charname)');
298 eleak(2, 0, "qq|\\N{au}|;",    'qq"\N{invalid}"');
299 eleak(2, 0, "qq|\\c|;"x10,     '"too many errors" from qq"\c"');
300 eleak(2, 0, "qq|\\o|;"x10,     '"too many errors" from qq"\o"');
301 eleak(2, 0, "qq|\\x{|;"x10,    '"too many errors" from qq"\x{"');
302 eleak(2, 0, "qq|\\N|;"x10,     '"too many errors" from qq"\N"');
303 eleak(2, 0, "qq|\\N{|;"x10,    '"too many errors" from qq"\N{"');
304 eleak(2, 0, "qq|\\N{U+GETG}|;"x10,'"too many errors" from qq"\N{U+JUNK}"');
305
306
307 # [perl #114764] Attributes leak scalars
308 leak(2, 0, sub { eval 'my $x : shared' }, 'my $x :shared used to leak');
309
310 eleak(2, 0, 'ref: 1', 'labels');
311
312 # Tied hash iteration was leaking if the hash was freed before itera-
313 # tion was over.
314 package t {
315     sub TIEHASH { bless [] }
316     sub FIRSTKEY { 0 }
317 }
318 leak(2, 0, sub {
319     my $h = {};
320     tie %$h, t;
321     each %$h;
322     undef $h;
323 }, 'tied hash iteration does not leak');
324
325 package explosive_scalar {
326     sub TIESCALAR { my $self = shift; bless [undef, {@_}], $self  }
327     sub FETCH     { die 'FETCH' if $_[0][1]{FETCH}; $_[0][0] }
328     sub STORE     { die 'STORE' if $_[0][1]{STORE}; $_[0][0] = $_[1] }
329 }
330 tie my $die_on_fetch, 'explosive_scalar', FETCH => 1;
331
332 # List assignment was leaking when assigning explosive scalars to
333 # aggregates.
334 leak(2, 0, sub {
335     eval {%a = ($die_on_fetch, 0)}; # key
336     eval {%a = (0, $die_on_fetch)}; # value
337     eval {%a = ($die_on_fetch, $die_on_fetch)}; # both
338     eval {%a = ($die_on_fetch)}; # key, odd elements
339 }, 'hash assignment does not leak');
340 leak(2, 0, sub {
341     eval {@a = ($die_on_fetch)};
342     eval {($die_on_fetch, $b) = ($b, $die_on_fetch)};
343     # restore
344     tie $die_on_fetch, 'explosive_scalar', FETCH => 1;
345 }, 'array assignment does not leak');
346
347 # [perl #107000]
348 package hhtie {
349     sub TIEHASH { bless [] }
350     sub STORE    { $_[0][0]{$_[1]} = $_[2] }
351     sub FETCH    { die if $explosive; $_[0][0]{$_[1]} }
352     sub FIRSTKEY { keys %{$_[0][0]}; each %{$_[0][0]} }
353     sub NEXTKEY  { each %{$_[0][0]} }
354 }
355 leak(2, 0, sub {
356     eval q`
357         BEGIN {
358             $hhtie::explosive = 0;
359             tie %^H, hhtie;
360             $^H{foo} = bar;
361             $hhtie::explosive = 1;
362         }
363         { 1; }
364     `;
365 }, 'hint-hash copying does not leak');
366
367 package explosive_array {
368     sub TIEARRAY  { bless [[], {}], $_[0]  }
369     sub FETCH     { die if $_[0]->[1]{FETCH}; $_[0]->[0][$_[1]]  }
370     sub FETCHSIZE { die if $_[0]->[1]{FETCHSIZE}; scalar @{ $_[0]->[0]  }  }
371     sub STORE     { die if $_[0]->[1]{STORE}; $_[0]->[0][$_[1]] = $_[2]  }
372     sub CLEAR     { die if $_[0]->[1]{CLEAR}; @{$_[0]->[0]} = ()  }
373     sub EXTEND    { die if $_[0]->[1]{EXTEND}; return  }
374     sub explode   { my $self = shift; $self->[1] = {@_} }
375 }
376
377 leak(2, 0, sub {
378     tie my @a, 'explosive_array';
379     tied(@a)->explode( STORE => 1 );
380     my $x = 0;
381     eval { @a = ($x)  };
382 }, 'explosive array assignment does not leak');
383
384 leak(2, 0, sub {
385     my ($a, $b);
386     eval { warn $die_on_fetch };
387 }, 'explosive warn argument');
388
389 leak(2, 0, sub {
390     my $foo = sub { return $die_on_fetch };
391     my $res = eval { $foo->() };
392     my @res = eval { $foo->() };
393 }, 'function returning explosive does not leak');
394
395 leak(2, 0, sub {
396     my $res = eval { {$die_on_fetch, 0} };
397     $res = eval { {0, $die_on_fetch} };
398 }, 'building anon hash with explosives does not leak');
399
400 leak(2, 0, sub {
401     my $res = eval { [$die_on_fetch] };
402 }, 'building anon array with explosives does not leak');
403
404 leak(2, 0, sub {
405     my @a;
406     eval { push @a, $die_on_fetch };
407 }, 'pushing exploding scalar does not leak');
408
409 leak(2, 0, sub {
410     eval { push @-, '' };
411 }, 'pushing onto read-only array does not leak');
412
413
414 # Run-time regexp code blocks
415 {
416     use re 'eval';
417     my @tests = ('[(?{})]','(?{})');
418     for my $t (@tests) {
419         leak(2, 0, sub {
420             / $t/;
421         }, "/ \$x/ where \$x is $t does not leak");
422         leak(2, 0, sub {
423             /(?{})$t/;
424         }, "/(?{})\$x/ where \$x is $t does not leak");
425     }
426 }
427
428
429 {
430     use warnings FATAL => 'all';
431     leak(2, 0, sub {
432         no warnings 'once';
433         eval { printf uNopened 42 };
434     }, 'printfing to bad handle under fatal warnings does not leak');
435     open my $fh, ">", \my $buf;
436     leak(2, 0, sub {
437         eval { printf $fh chr 2455 };
438     }, 'wide fatal warning does not make printf leak');
439     close $fh or die $!;
440 }
441
442
443 leak(2,0,sub{eval{require untohunothu}}, 'requiring nonexistent module');