This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
PATCH: perlfunc cleanup, part 1
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, the scalar arguments will
18 be first, and the list argument will follow.  (Note that there can ever
19 be only one such list argument.)  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for the elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use the parentheses, the simple (but occasionally
34 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  And whitespace
37 between the function and left parenthesis doesn't count--so you need to
38 be careful sometimes:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in a scalar context by
59 returning the undefined value, and in a list context by returning the
60 null list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls
82 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
111 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 =item Regular expressions and pattern matching
115 X<regular expression> X<regex> X<regexp>
116
117 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
118
119 =item Numeric functions
120 X<numeric> X<number> X<trigonometric> X<trigonometry>
121
122 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
123 C<sin>, C<sqrt>, C<srand>
124
125 =item Functions for real @ARRAYs
126 X<array>
127
128 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
129
130 =item Functions for list data
131 X<list>
132
133 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
134
135 =item Functions for real %HASHes
136 X<hash>
137
138 C<delete>, C<each>, C<exists>, C<keys>, C<values>
139
140 =item Input and output functions
141 X<I/O> X<input> X<output> X<dbm>
142
143 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
144 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
145 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
146 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
147 C<warn>, C<write>
148
149 =item Functions for fixed length data or records
150
151 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
152
153 =item Functions for filehandles, files, or directories
154 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
155
156 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
157 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
158 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
159 C<umask>, C<unlink>, C<utime>
160
161 =item Keywords related to the control flow of your Perl program
162 X<control flow>
163
164 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
165 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
166
167 =item Keywords related to switch
168
169 C<break>, C<continue>, C<given>, C<when>, C<default>
170
171 (These are only available if you enable the "switch" feature.
172 See L<feature> and L<perlsyn/"Switch statements">.)
173
174 =item Keywords related to scoping
175
176 C<caller>, C<import>, C<local>, C<my>, C<our>, C<state>, C<package>,
177 C<use>
178
179 (C<state> is only available if the "state" feature is enabled. See
180 L<feature>.)
181
182 =item Miscellaneous functions
183
184 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
185 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
186
187 =item Functions for processes and process groups
188 X<process> X<pid> X<process id>
189
190 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
191 C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
192 C<times>, C<wait>, C<waitpid>
193
194 =item Keywords related to perl modules
195 X<module>
196
197 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
198
199 =item Keywords related to classes and object-orientation
200 X<object> X<class> X<package>
201
202 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
203 C<untie>, C<use>
204
205 =item Low-level socket functions
206 X<socket> X<sock>
207
208 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
209 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
210 C<socket>, C<socketpair>
211
212 =item System V interprocess communication functions
213 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
214
215 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
216 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
217
218 =item Fetching user and group info
219 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
220
221 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
222 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
223 C<getpwuid>, C<setgrent>, C<setpwent>
224
225 =item Fetching network info
226 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
227
228 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
229 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
230 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
231 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
232 C<setnetent>, C<setprotoent>, C<setservent>
233
234 =item Time-related functions
235 X<time> X<date>
236
237 C<gmtime>, C<localtime>, C<time>, C<times>
238
239 =item Functions new in perl5
240 X<perl5>
241
242 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
243 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
244 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
245 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
246 C<ucfirst>, C<untie>, C<use>, C<when>
247
248 * - C<sub> was a keyword in perl4, but in perl5 it is an
249 operator, which can be used in expressions.
250
251 =item Functions obsoleted in perl5
252
253 C<dbmclose>, C<dbmopen>
254
255 =back
256
257 =head2 Portability
258 X<portability> X<Unix> X<portable>
259
260 Perl was born in Unix and can therefore access all common Unix
261 system calls.  In non-Unix environments, the functionality of some
262 Unix system calls may not be available, or details of the available
263 functionality may differ slightly.  The Perl functions affected
264 by this are:
265
266 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
267 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
268 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
269 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
270 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
271 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
272 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
273 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
274 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
275 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
276 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
277 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
278 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
279 C<shmwrite>, C<socket>, C<socketpair>,
280 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
281 C<times>, C<truncate>, C<umask>, C<unlink>,
282 C<utime>, C<wait>, C<waitpid>
283
284 For more information about the portability of these functions, see
285 L<perlport> and other available platform-specific documentation.
286
287 =head2 Alphabetical Listing of Perl Functions
288
289 =over 8
290
291 =item -X FILEHANDLE
292 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
293 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
294
295 =item -X EXPR
296
297 =item -X DIRHANDLE
298
299 =item -X
300
301 A file test, where X is one of the letters listed below.  This unary
302 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
303 and tests the associated file to see if something is true about it.  If the
304 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
305 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
306 the undefined value if the file doesn't exist.  Despite the funny
307 names, precedence is the same as any other named unary operator.  The
308 operator may be any of:
309
310     -r  File is readable by effective uid/gid.
311     -w  File is writable by effective uid/gid.
312     -x  File is executable by effective uid/gid.
313     -o  File is owned by effective uid.
314
315     -R  File is readable by real uid/gid.
316     -W  File is writable by real uid/gid.
317     -X  File is executable by real uid/gid.
318     -O  File is owned by real uid.
319
320     -e  File exists.
321     -z  File has zero size (is empty).
322     -s  File has nonzero size (returns size in bytes).
323
324     -f  File is a plain file.
325     -d  File is a directory.
326     -l  File is a symbolic link.
327     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
328     -S  File is a socket.
329     -b  File is a block special file.
330     -c  File is a character special file.
331     -t  Filehandle is opened to a tty.
332
333     -u  File has setuid bit set.
334     -g  File has setgid bit set.
335     -k  File has sticky bit set.
336
337     -T  File is an ASCII text file (heuristic guess).
338     -B  File is a "binary" file (opposite of -T).
339
340     -M  Script start time minus file modification time, in days.
341     -A  Same for access time.
342     -C  Same for inode change time (Unix, may differ for other platforms)
343
344 Example:
345
346     while (<>) {
347         chomp;
348         next unless -f $_;  # ignore specials
349         #...
350     }
351
352 The interpretation of the file permission operators C<-r>, C<-R>,
353 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
354 of the file and the uids and gids of the user.  There may be other
355 reasons you can't actually read, write, or execute the file: for
356 example network filesystem access controls, ACLs (access control lists),
357 read-only filesystems, and unrecognized executable formats.  Note
358 that the use of these six specific operators to verify if some operation
359 is possible is usually a mistake, because it may be open to race
360 conditions.
361
362 Also note that, for the superuser on the local filesystems, the C<-r>,
363 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
364 if any execute bit is set in the mode.  Scripts run by the superuser
365 may thus need to do a stat() to determine the actual mode of the file,
366 or temporarily set their effective uid to something else.
367
368 If you are using ACLs, there is a pragma called C<filetest> that may
369 produce more accurate results than the bare stat() mode bits.
370 When under the C<use filetest 'access'> the above-mentioned filetests
371 will test whether the permission can (not) be granted using the
372 access() family of system calls.  Also note that the C<-x> and C<-X> may
373 under this pragma return true even if there are no execute permission
374 bits set (nor any extra execute permission ACLs).  This strangeness is
375 due to the underlying system calls' definitions. Note also that, due to
376 the implementation of C<use filetest 'access'>, the C<_> special
377 filehandle won't cache the results of the file tests when this pragma is
378 in effect.  Read the documentation for the C<filetest> pragma for more
379 information.
380
381 Note that C<-s/a/b/> does not do a negated substitution.  Saying
382 C<-exp($foo)> still works as expected, however--only single letters
383 following a minus are interpreted as file tests.
384
385 The C<-T> and C<-B> switches work as follows.  The first block or so of the
386 file is examined for odd characters such as strange control codes or
387 characters with the high bit set.  If too many strange characters (>30%)
388 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
389 containing null in the first block is considered a binary file.  If C<-T>
390 or C<-B> is used on a filehandle, the current IO buffer is examined
391 rather than the first block.  Both C<-T> and C<-B> return true on a null
392 file, or a file at EOF when testing a filehandle.  Because you have to
393 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
394 against the file first, as in C<next unless -f $file && -T $file>.
395
396 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
397 the special filehandle consisting of a solitary underline, then the stat
398 structure of the previous file test (or stat operator) is used, saving
399 a system call.  (This doesn't work with C<-t>, and you need to remember
400 that lstat() and C<-l> will leave values in the stat structure for the
401 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
402 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
403 Example:
404
405     print "Can do.\n" if -r $a || -w _ || -x _;
406
407     stat($filename);
408     print "Readable\n" if -r _;
409     print "Writable\n" if -w _;
410     print "Executable\n" if -x _;
411     print "Setuid\n" if -u _;
412     print "Setgid\n" if -g _;
413     print "Sticky\n" if -k _;
414     print "Text\n" if -T _;
415     print "Binary\n" if -B _;
416
417 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
418 test operators, in a way that C<-f -w -x $file> is equivalent to
419 C<-x $file && -w _ && -f _>. (This is only syntax fancy: if you use
420 the return value of C<-f $file> as an argument to another filetest
421 operator, no special magic will happen.)
422
423 =item abs VALUE
424 X<abs> X<absolute>
425
426 =item abs
427
428 Returns the absolute value of its argument.
429 If VALUE is omitted, uses C<$_>.
430
431 =item accept NEWSOCKET,GENERICSOCKET
432 X<accept>
433
434 Accepts an incoming socket connect, just as the accept(2) system call
435 does.  Returns the packed address if it succeeded, false otherwise.
436 See the example in L<perlipc/"Sockets: Client/Server Communication">.
437
438 On systems that support a close-on-exec flag on files, the flag will
439 be set for the newly opened file descriptor, as determined by the
440 value of $^F.  See L<perlvar/$^F>.
441
442 =item alarm SECONDS
443 X<alarm>
444 X<SIGALRM>
445 X<timer>
446
447 =item alarm
448
449 Arranges to have a SIGALRM delivered to this process after the
450 specified number of wallclock seconds has elapsed.  If SECONDS is not
451 specified, the value stored in C<$_> is used. (On some machines,
452 unfortunately, the elapsed time may be up to one second less or more
453 than you specified because of how seconds are counted, and process
454 scheduling may delay the delivery of the signal even further.)
455
456 Only one timer may be counting at once.  Each call disables the
457 previous timer, and an argument of C<0> may be supplied to cancel the
458 previous timer without starting a new one.  The returned value is the
459 amount of time remaining on the previous timer.
460
461 For delays of finer granularity than one second, the Time::HiRes module
462 (from CPAN, and starting from Perl 5.8 part of the standard
463 distribution) provides ualarm().  You may also use Perl's four-argument
464 version of select() leaving the first three arguments undefined, or you
465 might be able to use the C<syscall> interface to access setitimer(2) if
466 your system supports it. See L<perlfaq8> for details.
467
468 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
469 C<sleep> may be internally implemented on your system with C<alarm>.
470
471 If you want to use C<alarm> to time out a system call you need to use an
472 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
473 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
474 restart system calls on some systems.  Using C<eval>/C<die> always works,
475 modulo the caveats given in L<perlipc/"Signals">.
476
477     eval {
478         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
479         alarm $timeout;
480         $nread = sysread SOCKET, $buffer, $size;
481         alarm 0;
482     };
483     if ($@) {
484         die unless $@ eq "alarm\n";   # propagate unexpected errors
485         # timed out
486     }
487     else {
488         # didn't
489     }
490
491 For more information see L<perlipc>.
492
493 =item atan2 Y,X
494 X<atan2> X<arctangent> X<tan> X<tangent>
495
496 Returns the arctangent of Y/X in the range -PI to PI.
497
498 For the tangent operation, you may use the C<Math::Trig::tan>
499 function, or use the familiar relation:
500
501     sub tan { sin($_[0]) / cos($_[0])  }
502
503 The return value for C<atan2(0,0)> is implementation-defined; consult
504 your atan2(3) manpage for more information.
505
506 =item bind SOCKET,NAME
507 X<bind>
508
509 Binds a network address to a socket, just as the bind system call
510 does.  Returns true if it succeeded, false otherwise.  NAME should be a
511 packed address of the appropriate type for the socket.  See the examples in
512 L<perlipc/"Sockets: Client/Server Communication">.
513
514 =item binmode FILEHANDLE, LAYER
515 X<binmode> X<binary> X<text> X<DOS> X<Windows>
516
517 =item binmode FILEHANDLE
518
519 Arranges for FILEHANDLE to be read or written in "binary" or "text"
520 mode on systems where the run-time libraries distinguish between
521 binary and text files.  If FILEHANDLE is an expression, the value is
522 taken as the name of the filehandle.  Returns true on success,
523 otherwise it returns C<undef> and sets C<$!> (errno).
524
525 On some systems (in general, DOS and Windows-based systems) binmode()
526 is necessary when you're not working with a text file.  For the sake
527 of portability it is a good idea to always use it when appropriate,
528 and to never use it when it isn't appropriate.  Also, people can
529 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
530
531 In other words: regardless of platform, use binmode() on binary data,
532 like for example images.
533
534 If LAYER is present it is a single string, but may contain multiple
535 directives. The directives alter the behaviour of the file handle.
536 When LAYER is present using binmode on a text file makes sense.
537
538 If LAYER is omitted or specified as C<:raw> the filehandle is made
539 suitable for passing binary data. This includes turning off possible CRLF
540 translation and marking it as bytes (as opposed to Unicode characters).
541 Note that, despite what may be implied in I<"Programming Perl"> (the
542 Camel) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>
543 --other layers that would affect the binary nature of the stream are
544 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
545 PERLIO environment variable.
546
547 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
548 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
549 establish default I/O layers.  See L<open>.
550
551 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
552 in "Programming Perl, 3rd Edition".  However, since the publishing of this
553 book, by many known as "Camel III", the consensus of the naming of this
554 functionality has moved from "discipline" to "layer".  All documentation
555 of this version of Perl therefore refers to "layers" rather than to
556 "disciplines".  Now back to the regularly scheduled documentation...>
557
558 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(utf8)>.
559 C<:utf8> just marks the data as UTF-8 without further checking,
560 while C<:encoding(utf8)> checks the data for actually being valid
561 UTF-8. More details can be found in L<PerlIO::encoding>.
562
563 In general, binmode() should be called after open() but before any I/O
564 is done on the filehandle.  Calling binmode() will normally flush any
565 pending buffered output data (and perhaps pending input data) on the
566 handle.  An exception to this is the C<:encoding> layer that
567 changes the default character encoding of the handle, see L<open>.
568 The C<:encoding> layer sometimes needs to be called in
569 mid-stream, and it doesn't flush the stream.  The C<:encoding>
570 also implicitly pushes on top of itself the C<:utf8> layer because
571 internally Perl will operate on UTF-8 encoded Unicode characters.
572
573 The operating system, device drivers, C libraries, and Perl run-time
574 system all work together to let the programmer treat a single
575 character (C<\n>) as the line terminator, irrespective of the external
576 representation.  On many operating systems, the native text file
577 representation matches the internal representation, but on some
578 platforms the external representation of C<\n> is made up of more than
579 one character.
580
581 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
582 character to end each line in the external representation of text (even
583 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
584 on Unix and most VMS files). In other systems like OS/2, DOS and the
585 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
586 but what's stored in text files are the two characters C<\cM\cJ>.  That
587 means that, if you don't use binmode() on these systems, C<\cM\cJ>
588 sequences on disk will be converted to C<\n> on input, and any C<\n> in
589 your program will be converted back to C<\cM\cJ> on output.  This is what
590 you want for text files, but it can be disastrous for binary files.
591
592 Another consequence of using binmode() (on some systems) is that
593 special end-of-file markers will be seen as part of the data stream.
594 For systems from the Microsoft family this means that if your binary
595 data contains C<\cZ>, the I/O subsystem will regard it as the end of
596 the file, unless you use binmode().
597
598 binmode() is not only important for readline() and print() operations,
599 but also when using read(), seek(), sysread(), syswrite() and tell()
600 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
601 in L<perlvar> for how to manually set your input and output
602 line-termination sequences.
603
604 =item bless REF,CLASSNAME
605 X<bless>
606
607 =item bless REF
608
609 This function tells the thingy referenced by REF that it is now an object
610 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
611 is used.  Because a C<bless> is often the last thing in a constructor,
612 it returns the reference for convenience.  Always use the two-argument
613 version if a derived class might inherit the function doing the blessing.
614 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
615 of objects.
616
617 Consider always blessing objects in CLASSNAMEs that are mixed case.
618 Namespaces with all lowercase names are considered reserved for
619 Perl pragmata.  Builtin types have all uppercase names. To prevent
620 confusion, you may wish to avoid such package names as well.  Make sure
621 that CLASSNAME is a true value.
622
623 See L<perlmod/"Perl Modules">.
624
625 =item break
626
627 Break out of a C<given()> block.
628
629 This keyword is enabled by the "switch" feature: see L<feature>
630 for more information.
631
632 =item caller EXPR
633 X<caller> X<call stack> X<stack> X<stack trace>
634
635 =item caller
636
637 Returns the context of the current subroutine call.  In scalar context,
638 returns the caller's package name if there I<is> a caller (that is, if
639 we're in a subroutine or C<eval> or C<require>) and the undefined value
640 otherwise.  In list context, returns
641
642     # 0         1          2
643     ($package, $filename, $line) = caller;
644
645 With EXPR, it returns some extra information that the debugger uses to
646 print a stack trace.  The value of EXPR indicates how many call frames
647 to go back before the current one.
648
649     #  0         1          2      3            4
650     ($package, $filename, $line, $subroutine, $hasargs,
651
652     #  5          6          7            8       9         10
653     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
654      = caller($i);
655
656 Here $subroutine may be C<(eval)> if the frame is not a subroutine
657 call, but an C<eval>.  In such a case additional elements $evaltext and
658 C<$is_require> are set: C<$is_require> is true if the frame is created by a
659 C<require> or C<use> statement, $evaltext contains the text of the
660 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
661 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
662 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
663 frame.)  $subroutine may also be C<(unknown)> if this particular
664 subroutine happens to have been deleted from the symbol table.
665 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
666 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
667 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
668 between versions of Perl, and are not meant for external use.
669
670 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
671 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
672 of this hash, as they are the actual values stored in the optree.
673
674 Furthermore, when called from within the DB package, caller returns more
675 detailed information: it sets the list variable C<@DB::args> to be the
676 arguments with which the subroutine was invoked.
677
678 Be aware that the optimizer might have optimized call frames away before
679 C<caller> had a chance to get the information.  That means that C<caller(N)>
680 might not return information about the call frame you expect it to, for
681 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
682 previous time C<caller> was called.
683
684 =item chdir EXPR
685 X<chdir>
686 X<cd>
687 X<directory, change>
688
689 =item chdir FILEHANDLE
690
691 =item chdir DIRHANDLE
692
693 =item chdir
694
695 Changes the working directory to EXPR, if possible. If EXPR is omitted,
696 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
697 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
698 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
699 neither is set, C<chdir> does nothing. It returns true on success,
700 false otherwise. See the example under C<die>.
701
702 On systems that support fchdir, you may pass a file handle or
703 directory handle as argument.  On systems that don't support fchdir,
704 passing handles produces a fatal error at run time.
705
706 =item chmod LIST
707 X<chmod> X<permission> X<mode>
708
709 Changes the permissions of a list of files.  The first element of the
710 list must be the numerical mode, which should probably be an octal
711 number, and which definitely should I<not> be a string of octal digits:
712 C<0644> is okay, C<'0644'> is not.  Returns the number of files
713 successfully changed.  See also L</oct>, if all you have is a string.
714
715     $cnt = chmod 0755, 'foo', 'bar';
716     chmod 0755, @executables;
717     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
718                                              # --w----r-T
719     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
720     $mode = 0644;   chmod $mode, 'foo';      # this is best
721
722 On systems that support fchmod, you may pass file handles among the
723 files.  On systems that don't support fchmod, passing file handles
724 produces a fatal error at run time.   The file handles must be passed
725 as globs or references to be recognized.  Barewords are considered
726 file names.
727
728     open(my $fh, "<", "foo");
729     my $perm = (stat $fh)[2] & 07777;
730     chmod($perm | 0600, $fh);
731
732 You can also import the symbolic C<S_I*> constants from the Fcntl
733 module:
734
735     use Fcntl ':mode';
736
737     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
738     # This is identical to the chmod 0755 of the above example.
739
740 =item chomp VARIABLE
741 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
742
743 =item chomp( LIST )
744
745 =item chomp
746
747 This safer version of L</chop> removes any trailing string
748 that corresponds to the current value of C<$/> (also known as
749 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
750 number of characters removed from all its arguments.  It's often used to
751 remove the newline from the end of an input record when you're worried
752 that the final record may be missing its newline.  When in paragraph
753 mode (C<$/ = "">), it removes all trailing newlines from the string.
754 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
755 a reference to an integer or the like, see L<perlvar>) chomp() won't
756 remove anything.
757 If VARIABLE is omitted, it chomps C<$_>.  Example:
758
759     while (<>) {
760         chomp;  # avoid \n on last field
761         @array = split(/:/);
762         # ...
763     }
764
765 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
766
767 You can actually chomp anything that's an lvalue, including an assignment:
768
769     chomp($cwd = `pwd`);
770     chomp($answer = <STDIN>);
771
772 If you chomp a list, each element is chomped, and the total number of
773 characters removed is returned.
774
775 Note that parentheses are necessary when you're chomping anything
776 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
777 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
778 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
779 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
780 as C<chomp($a, $b)>.
781
782 =item chop VARIABLE
783 X<chop>
784
785 =item chop( LIST )
786
787 =item chop
788
789 Chops off the last character of a string and returns the character
790 chopped.  It is much more efficient than C<s/.$//s> because it neither
791 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
792 If VARIABLE is a hash, it chops the hash's values, but not its keys.
793
794 You can actually chop anything that's an lvalue, including an assignment.
795
796 If you chop a list, each element is chopped.  Only the value of the
797 last C<chop> is returned.
798
799 Note that C<chop> returns the last character.  To return all but the last
800 character, use C<substr($string, 0, -1)>.
801
802 See also L</chomp>.
803
804 =item chown LIST
805 X<chown> X<owner> X<user> X<group>
806
807 Changes the owner (and group) of a list of files.  The first two
808 elements of the list must be the I<numeric> uid and gid, in that
809 order.  A value of -1 in either position is interpreted by most
810 systems to leave that value unchanged.  Returns the number of files
811 successfully changed.
812
813     $cnt = chown $uid, $gid, 'foo', 'bar';
814     chown $uid, $gid, @filenames;
815
816 On systems that support fchown, you may pass file handles among the
817 files.  On systems that don't support fchown, passing file handles
818 produces a fatal error at run time.  The file handles must be passed
819 as globs or references to be recognized.  Barewords are considered
820 file names.
821
822 Here's an example that looks up nonnumeric uids in the passwd file:
823
824     print "User: ";
825     chomp($user = <STDIN>);
826     print "Files: ";
827     chomp($pattern = <STDIN>);
828
829     ($login,$pass,$uid,$gid) = getpwnam($user)
830         or die "$user not in passwd file";
831
832     @ary = glob($pattern);  # expand filenames
833     chown $uid, $gid, @ary;
834
835 On most systems, you are not allowed to change the ownership of the
836 file unless you're the superuser, although you should be able to change
837 the group to any of your secondary groups.  On insecure systems, these
838 restrictions may be relaxed, but this is not a portable assumption.
839 On POSIX systems, you can detect this condition this way:
840
841     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
842     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
843
844 =item chr NUMBER
845 X<chr> X<character> X<ASCII> X<Unicode>
846
847 =item chr
848
849 Returns the character represented by that NUMBER in the character set.
850 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
851 chr(0x263a) is a Unicode smiley face.  
852
853 Negative values give the Unicode replacement character (chr(0xfffd)),
854 except under the L<bytes> pragma, where the low eight bits of the value
855 (truncated to an integer) are used.
856
857 If NUMBER is omitted, uses C<$_>.
858
859 For the reverse, use L</ord>.
860
861 Note that characters from 128 to 255 (inclusive) are by default
862 internally not encoded as UTF-8 for backward compatibility reasons.
863
864 See L<perlunicode> for more about Unicode.
865
866 =item chroot FILENAME
867 X<chroot> X<root>
868
869 =item chroot
870
871 This function works like the system call by the same name: it makes the
872 named directory the new root directory for all further pathnames that
873 begin with a C</> by your process and all its children.  (It doesn't
874 change your current working directory, which is unaffected.)  For security
875 reasons, this call is restricted to the superuser.  If FILENAME is
876 omitted, does a C<chroot> to C<$_>.
877
878 =item close FILEHANDLE
879 X<close>
880
881 =item close
882
883 Closes the file or pipe associated with the file handle, flushes the IO
884 buffers, and closes the system file descriptor.  Returns true if those
885 operations have succeeded and if no error was reported by any PerlIO
886 layer.  Closes the currently selected filehandle if the argument is
887 omitted.
888
889 You don't have to close FILEHANDLE if you are immediately going to do
890 another C<open> on it, because C<open> will close it for you.  (See
891 C<open>.)  However, an explicit C<close> on an input file resets the line
892 counter (C<$.>), while the implicit close done by C<open> does not.
893
894 If the file handle came from a piped open, C<close> will additionally
895 return false if one of the other system calls involved fails, or if the
896 program exits with non-zero status.  (If the only problem was that the
897 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
898 also waits for the process executing on the pipe to exit, in case you
899 wish to look at the output of the pipe afterwards, and
900 implicitly puts the exit status value of that command into C<$?> and
901 C<${^CHILD_ERROR_NATIVE}>.
902
903 Closing the read end of a pipe before the process writing to it at the
904 other end is done writing results in the writer receiving a SIGPIPE.  If
905 the other end can't handle that, be sure to read all the data before
906 closing the pipe.
907
908 Example:
909
910     open(OUTPUT, '|sort >foo')  # pipe to sort
911         or die "Can't start sort: $!";
912     #...                        # print stuff to output
913     close OUTPUT                # wait for sort to finish
914         or warn $! ? "Error closing sort pipe: $!"
915                    : "Exit status $? from sort";
916     open(INPUT, 'foo')          # get sort's results
917         or die "Can't open 'foo' for input: $!";
918
919 FILEHANDLE may be an expression whose value can be used as an indirect
920 filehandle, usually the real filehandle name.
921
922 =item closedir DIRHANDLE
923 X<closedir>
924
925 Closes a directory opened by C<opendir> and returns the success of that
926 system call.
927
928 =item connect SOCKET,NAME
929 X<connect>
930
931 Attempts to connect to a remote socket, just like connect(2).
932 Returns true if it succeeded, false otherwise.  NAME should be a
933 packed address of the appropriate type for the socket.  See the examples in
934 L<perlipc/"Sockets: Client/Server Communication">.
935
936 =item continue BLOCK
937 X<continue>
938
939 =item continue
940
941 C<continue> is actually a flow control statement rather than a function.  If
942 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
943 C<foreach>), it is always executed just before the conditional is about to
944 be evaluated again, just like the third part of a C<for> loop in C.  Thus
945 it can be used to increment a loop variable, even when the loop has been
946 continued via the C<next> statement (which is similar to the C C<continue>
947 statement).
948
949 C<last>, C<next>, or C<redo> may appear within a C<continue>
950 block.  C<last> and C<redo> will behave as if they had been executed within
951 the main block.  So will C<next>, but since it will execute a C<continue>
952 block, it may be more entertaining.
953
954     while (EXPR) {
955         ### redo always comes here
956         do_something;
957     } continue {
958         ### next always comes here
959         do_something_else;
960         # then back the top to re-check EXPR
961     }
962     ### last always comes here
963
964 Omitting the C<continue> section is semantically equivalent to using an
965 empty one, logically enough.  In that case, C<next> goes directly back
966 to check the condition at the top of the loop.
967
968 If the "switch" feature is enabled, C<continue> is also a
969 function that will break out of the current C<when> or C<default>
970 block, and fall through to the next case. See L<feature> and
971 L<perlsyn/"Switch statements"> for more information.
972
973
974 =item cos EXPR
975 X<cos> X<cosine> X<acos> X<arccosine>
976
977 =item cos
978
979 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
980 takes cosine of C<$_>.
981
982 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
983 function, or use this relation:
984
985     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
986
987 =item crypt PLAINTEXT,SALT
988 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
989 X<decrypt> X<cryptography> X<passwd> X<encrypt>
990
991 Creates a digest string exactly like the crypt(3) function in the C
992 library (assuming that you actually have a version there that has not
993 been extirpated as a potential munition).
994
995 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
996 into a short string, called a digest, which is returned.  The same
997 PLAINTEXT and SALT will always return the same string, but there is no
998 (known) way to get the original PLAINTEXT from the hash.  Small
999 changes in the PLAINTEXT or SALT will result in large changes in the
1000 digest.
1001
1002 There is no decrypt function.  This function isn't all that useful for
1003 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1004 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1005 primarily used to check if two pieces of text are the same without
1006 having to transmit or store the text itself.  An example is checking
1007 if a correct password is given.  The digest of the password is stored,
1008 not the password itself.  The user types in a password that is
1009 crypt()'d with the same salt as the stored digest.  If the two digests
1010 match the password is correct.
1011
1012 When verifying an existing digest string you should use the digest as
1013 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1014 to create the digest is visible as part of the digest.  This ensures
1015 crypt() will hash the new string with the same salt as the digest.
1016 This allows your code to work with the standard L<crypt|/crypt> and
1017 with more exotic implementations.  In other words, do not assume
1018 anything about the returned string itself, or how many bytes in the
1019 digest matter.
1020
1021 Traditionally the result is a string of 13 bytes: two first bytes of
1022 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1023 the first eight bytes of PLAINTEXT mattered. But alternative
1024 hashing schemes (like MD5), higher level security schemes (like C2),
1025 and implementations on non-Unix platforms may produce different
1026 strings.
1027
1028 When choosing a new salt create a random two character string whose
1029 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1030 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1031 characters is just a recommendation; the characters allowed in
1032 the salt depend solely on your system's crypt library, and Perl can't
1033 restrict what salts C<crypt()> accepts.
1034
1035 Here's an example that makes sure that whoever runs this program knows
1036 their password:
1037
1038     $pwd = (getpwuid($<))[1];
1039
1040     system "stty -echo";
1041     print "Password: ";
1042     chomp($word = <STDIN>);
1043     print "\n";
1044     system "stty echo";
1045
1046     if (crypt($word, $pwd) ne $pwd) {
1047         die "Sorry...\n";
1048     } else {
1049         print "ok\n";
1050     }
1051
1052 Of course, typing in your own password to whoever asks you
1053 for it is unwise.
1054
1055 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1056 of data, not least of all because you can't get the information
1057 back.  Look at the L<Digest> module for more robust algorithms.
1058
1059 If using crypt() on a Unicode string (which I<potentially> has
1060 characters with codepoints above 255), Perl tries to make sense
1061 of the situation by trying to downgrade (a copy of the string)
1062 the string back to an eight-bit byte string before calling crypt()
1063 (on that copy).  If that works, good.  If not, crypt() dies with
1064 C<Wide character in crypt>.
1065
1066 =item dbmclose HASH
1067 X<dbmclose>
1068
1069 [This function has been largely superseded by the C<untie> function.]
1070
1071 Breaks the binding between a DBM file and a hash.
1072
1073 =item dbmopen HASH,DBNAME,MASK
1074 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1075
1076 [This function has been largely superseded by the C<tie> function.]
1077
1078 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1079 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1080 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1081 is the name of the database (without the F<.dir> or F<.pag> extension if
1082 any).  If the database does not exist, it is created with protection
1083 specified by MASK (as modified by the C<umask>).  If your system supports
1084 only the older DBM functions, you may make only one C<dbmopen> call in your
1085 program.  In older versions of Perl, if your system had neither DBM nor
1086 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1087 sdbm(3).
1088
1089 If you don't have write access to the DBM file, you can only read hash
1090 variables, not set them.  If you want to test whether you can write,
1091 either use file tests or try setting a dummy hash entry inside an C<eval>,
1092 which will trap the error.
1093
1094 Note that functions such as C<keys> and C<values> may return huge lists
1095 when used on large DBM files.  You may prefer to use the C<each>
1096 function to iterate over large DBM files.  Example:
1097
1098     # print out history file offsets
1099     dbmopen(%HIST,'/usr/lib/news/history',0666);
1100     while (($key,$val) = each %HIST) {
1101         print $key, ' = ', unpack('L',$val), "\n";
1102     }
1103     dbmclose(%HIST);
1104
1105 See also L<AnyDBM_File> for a more general description of the pros and
1106 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1107 rich implementation.
1108
1109 You can control which DBM library you use by loading that library
1110 before you call dbmopen():
1111
1112     use DB_File;
1113     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1114         or die "Can't open netscape history file: $!";
1115
1116 =item defined EXPR
1117 X<defined> X<undef> X<undefined>
1118
1119 =item defined
1120
1121 Returns a Boolean value telling whether EXPR has a value other than
1122 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
1123 checked.
1124
1125 Many operations return C<undef> to indicate failure, end of file,
1126 system error, uninitialized variable, and other exceptional
1127 conditions.  This function allows you to distinguish C<undef> from
1128 other values.  (A simple Boolean test will not distinguish among
1129 C<undef>, zero, the empty string, and C<"0">, which are all equally
1130 false.)  Note that since C<undef> is a valid scalar, its presence
1131 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1132 returns C<undef> when its argument is an empty array, I<or> when the
1133 element to return happens to be C<undef>.
1134
1135 You may also use C<defined(&func)> to check whether subroutine C<&func>
1136 has ever been defined.  The return value is unaffected by any forward
1137 declarations of C<&func>.  A subroutine that is not defined
1138 may still be callable: its package may have an C<AUTOLOAD> method that
1139 makes it spring into existence the first time that it is called--see
1140 L<perlsub>.
1141
1142 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1143 used to report whether memory for that aggregate has ever been
1144 allocated.  This behavior may disappear in future versions of Perl.
1145 You should instead use a simple test for size:
1146
1147     if (@an_array) { print "has array elements\n" }
1148     if (%a_hash)   { print "has hash members\n"   }
1149
1150 When used on a hash element, it tells you whether the value is defined,
1151 not whether the key exists in the hash.  Use L</exists> for the latter
1152 purpose.
1153
1154 Examples:
1155
1156     print if defined $switch{'D'};
1157     print "$val\n" while defined($val = pop(@ary));
1158     die "Can't readlink $sym: $!"
1159         unless defined($value = readlink $sym);
1160     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1161     $debugging = 0 unless defined $debugging;
1162
1163 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1164 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1165 defined values.  For example, if you say
1166
1167     "ab" =~ /a(.*)b/;
1168
1169 The pattern match succeeds and C<$1> is defined, although it
1170 matched "nothing".  It didn't really fail to match anything.  Rather, it
1171 matched something that happened to be zero characters long.  This is all
1172 very above-board and honest.  When a function returns an undefined value,
1173 it's an admission that it couldn't give you an honest answer.  So you
1174 should use C<defined> only when you're questioning the integrity of what
1175 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1176 what you want.
1177
1178 See also L</undef>, L</exists>, L</ref>.
1179
1180 =item delete EXPR
1181 X<delete>
1182
1183 Given an expression that specifies an element or slice of an aggregate (a
1184 hash or an array), deletes the specified elements from that aggregate so
1185 that exists() on that element no longer returns true.  Setting an aggregate
1186 element to the undefined value does not remove its key, but deleting it
1187 does; see L</exists>.
1188
1189 Returns the value or values deleted in list context, or the last such
1190 element in scalar context.  The return list's length always matches that of
1191 the argument list: deleting non-existent elements returns the undefined
1192 value in their corresponding positions.
1193
1194 Deleting array elements never changes indices of existing values; use
1195 shift() or splice() for that.  However, if all deleted elements fall at
1196 the end of an array, the array's size shrinks to the position of the
1197 highest element that still tests true for exists(), or to 0 if none do.
1198
1199 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1200 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1201 or array may not necessarily return anything; it depends on the implementation
1202 of the C<tied> package's DELETE method, which may do whatever it pleases.
1203
1204 The C<delete local EXPR> construct localizes the deletion to the current
1205 block at run time.  Until the block exits, elements locally deleted
1206 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1207 of composite types">.
1208
1209     %hash = (foo => 11, bar => 22, baz => 33);
1210     $scalar = delete $hash{foo};             # $scalar is 11
1211     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1212     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1213
1214 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1215
1216     foreach $key (keys %HASH) {
1217         delete $HASH{$key};
1218     }
1219
1220     foreach $index (0 .. $#ARRAY) {
1221         delete $ARRAY[$index];
1222     }
1223
1224 And so do these:
1225
1226     delete @HASH{keys %HASH};
1227
1228     delete @ARRAY[0 .. $#ARRAY];
1229
1230 But both are slower than assigning the empty list
1231 or undefining %HASH or @ARRAY, which is the customary 
1232 way to empty out an aggregate:
1233
1234     %HASH = ();     # completely empty %HASH
1235     undef %HASH;    # forget %HASH ever existed
1236
1237     @ARRAY = ();    # completely empty @ARRAY
1238     undef @ARRAY;   # forget @ARRAY ever existed
1239
1240 The EXPR can be arbitrarily complicated provided its
1241 final operation is an element or slice of an aggregate:
1242
1243     delete $ref->[$x][$y]{$key};
1244     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1245
1246     delete $ref->[$x][$y][$index];
1247     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1248
1249 =item die LIST
1250 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1251
1252 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1253 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1254 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1255 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1256 an C<eval(),> the error message is stuffed into C<$@> and the
1257 C<eval> is terminated with the undefined value.  This makes
1258 C<die> the way to raise an exception.
1259
1260 Equivalent examples:
1261
1262     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1263     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1264
1265 If the last element of LIST does not end in a newline, the current
1266 script line number and input line number (if any) are also printed,
1267 and a newline is supplied.  Note that the "input line number" (also
1268 known as "chunk") is subject to whatever notion of "line" happens to
1269 be currently in effect, and is also available as the special variable
1270 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1271
1272 Hint: sometimes appending C<", stopped"> to your message will cause it
1273 to make better sense when the string C<"at foo line 123"> is appended.
1274 Suppose you are running script "canasta".
1275
1276     die "/etc/games is no good";
1277     die "/etc/games is no good, stopped";
1278
1279 produce, respectively
1280
1281     /etc/games is no good at canasta line 123.
1282     /etc/games is no good, stopped at canasta line 123.
1283
1284 See also exit(), warn(), and the Carp module.
1285
1286 If the output is empty and C<$@> already contains a value (typically from a
1287 previous eval) that value is reused after appending C<"\t...propagated">.
1288 This is useful for propagating exceptions:
1289
1290     eval { ... };
1291     die unless $@ =~ /Expected exception/;
1292
1293 If the output is empty and C<$@> contains an object reference that has a
1294 C<PROPAGATE> method, that method will be called with additional file
1295 and line number parameters.  The return value replaces the value in
1296 C<$@>.  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1297 were called.
1298
1299 If C<$@> is empty then the string C<"Died"> is used.
1300
1301 You can also call C<die> with a reference argument, and if this is trapped
1302 within an C<eval>, C<$@> contains that reference.  This permits more
1303 elaborate exception handling using objects that maintain arbitrary state
1304 about the exception.  Such a scheme is sometimes preferable to matching
1305 particular string values of C<$@> with regular expressions.  Because C<$@> 
1306 is a global variable and C<eval> may be used within object implementations,
1307 be careful that analyzing the error object doesn't replace the reference in
1308 the global variable.  It's easiest to make a local copy of the reference
1309 before any manipulations.  Here's an example:
1310
1311     use Scalar::Util "blessed";
1312
1313     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1314     if (my $ev_err = $@) {
1315         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1316             # handle Some::Module::Exception
1317         }
1318         else {
1319             # handle all other possible exceptions
1320         }
1321     }
1322
1323 Because perl stringifies uncaught exception messages before display,
1324 you'll probably want to overload stringification operations on
1325 exception objects.  See L<overload> for details about that.
1326
1327 You can arrange for a callback to be run just before the C<die>
1328 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1329 handler will be called with the error text and can change the error
1330 message, if it sees fit, by calling C<die> again.  See
1331 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1332 L<"eval BLOCK"> for some examples.  Although this feature was 
1333 to be run only right before your program was to exit, this is not
1334 currently the case--the C<$SIG{__DIE__}> hook is currently called
1335 even inside eval()ed blocks/strings!  If one wants the hook to do
1336 nothing in such situations, put
1337
1338     die @_ if $^S;
1339
1340 as the first line of the handler (see L<perlvar/$^S>).  Because
1341 this promotes strange action at a distance, this counterintuitive
1342 behavior may be fixed in a future release.
1343
1344 =item do BLOCK
1345 X<do> X<block>
1346
1347 Not really a function.  Returns the value of the last command in the
1348 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1349 C<until> loop modifier, executes the BLOCK once before testing the loop
1350 condition. (On other statements the loop modifiers test the conditional
1351 first.)
1352
1353 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1354 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1355 See L<perlsyn> for alternative strategies.
1356
1357 =item do SUBROUTINE(LIST)
1358 X<do>
1359
1360 This form of subroutine call is deprecated.  See L<perlsub>.
1361
1362 =item do EXPR
1363 X<do>
1364
1365 Uses the value of EXPR as a filename and executes the contents of the
1366 file as a Perl script.
1367
1368     do 'stat.pl';
1369
1370 is just like
1371
1372     eval `cat stat.pl`;
1373
1374 except that it's more efficient and concise, keeps track of the current
1375 filename for error messages, searches the @INC directories, and updates
1376 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1377 variables.  It also differs in that code evaluated with C<do FILENAME>
1378 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1379 same, however, in that it does reparse the file every time you call it,
1380 so you probably don't want to do this inside a loop.
1381
1382 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1383 error.  If C<do> can read the file but cannot compile it, it
1384 returns undef and sets an error message in C<$@>.   If the file is
1385 successfully compiled, C<do> returns the value of the last expression
1386 evaluated.
1387
1388 Inclusion of library modules is better done with the
1389 C<use> and C<require> operators, which also do automatic error checking
1390 and raise an exception if there's a problem.
1391
1392 You might like to use C<do> to read in a program configuration
1393 file.  Manual error checking can be done this way:
1394
1395     # read in config files: system first, then user
1396     for $file ("/share/prog/defaults.rc",
1397                "$ENV{HOME}/.someprogrc")
1398     {
1399         unless ($return = do $file) {
1400             warn "couldn't parse $file: $@" if $@;
1401             warn "couldn't do $file: $!"    unless defined $return;
1402             warn "couldn't run $file"       unless $return;
1403         }
1404     }
1405
1406 =item dump LABEL
1407 X<dump> X<core> X<undump>
1408
1409 =item dump
1410
1411 This function causes an immediate core dump.  See also the B<-u>
1412 command-line switch in L<perlrun>, which does the same thing.
1413 Primarily this is so that you can use the B<undump> program (not
1414 supplied) to turn your core dump into an executable binary after
1415 having initialized all your variables at the beginning of the
1416 program.  When the new binary is executed it will begin by executing
1417 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1418 Think of it as a goto with an intervening core dump and reincarnation.
1419 If C<LABEL> is omitted, restarts the program from the top.
1420
1421 B<WARNING>: Any files opened at the time of the dump will I<not>
1422 be open any more when the program is reincarnated, with possible
1423 resulting confusion by Perl.
1424
1425 This function is now largely obsolete, mostly because it's very hard to
1426 convert a core file into an executable. That's why you should now invoke
1427 it as C<CORE::dump()>, if you don't want to be warned against a possible
1428 typo.
1429
1430 =item each HASH
1431 X<each> X<hash, iterator>
1432
1433 =item each ARRAY
1434 X<array, iterator>
1435
1436 When called in list context, returns a 2-element list consisting of the key
1437 and value for the next element of a hash, or the index and value for the
1438 next element of an array, so that you can iterate over it.  When called in
1439 scalar context, returns only the key (not the value) in a hash, or the index
1440 in an array.
1441
1442 Hash entries are returned in an apparently random order.  The actual random
1443 order is subject to change in future versions of perl, but it is
1444 guaranteed to be in the same order as either the C<keys> or C<values>
1445 function would produce on the same (unmodified) hash.  Since Perl
1446 5.8.2 the ordering can be different even between different runs of Perl
1447 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1448
1449 After C<each> has returned all entries from the hash or array, the next
1450 call to C<each> returns the empty list in list context and C<undef> in
1451 scalar context.  The next call following that one restarts iteration.  Each
1452 hash or array has its own internal iterator, accessed by C<each>, C<keys>,
1453 and C<values>.  The iterator is implicitly reset when C<each> has reached
1454 the end as just described; it can be explicitly reset by calling C<keys> or
1455 C<values> on the hash or array.  If you add or delete a hash's elements
1456 while iterating over it, entries may be skipped or duplicated--so don't do
1457 that.  Exception: It is always safe to delete the item most recently
1458 returned by C<each()>, so the following code will work properly:
1459
1460         while (($key, $value) = each %hash) {
1461           print $key, "\n";
1462           delete $hash{$key};   # This is safe
1463         }
1464
1465 This prints out your environment like the printenv(1) program,
1466 only in a different order:
1467
1468     while (($key,$value) = each %ENV) {
1469         print "$key=$value\n";
1470     }
1471
1472 See also C<keys>, C<values> and C<sort>.
1473
1474 =item eof FILEHANDLE
1475 X<eof>
1476 X<end of file>
1477 X<end-of-file>
1478
1479 =item eof ()
1480
1481 =item eof
1482
1483 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1484 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1485 gives the real filehandle.  (Note that this function actually
1486 reads a character and then C<ungetc>s it, so isn't useful in an
1487 interactive context.)  Do not read from a terminal file (or call
1488 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1489 as terminals may lose the end-of-file condition if you do.
1490
1491 An C<eof> without an argument uses the last file read.  Using C<eof()>
1492 with empty parentheses is different.  It refers to the pseudo file
1493 formed from the files listed on the command line and accessed via the
1494 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1495 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1496 used will cause C<@ARGV> to be examined to determine if input is
1497 available.   Similarly, an C<eof()> after C<< <> >> has returned
1498 end-of-file will assume you are processing another C<@ARGV> list,
1499 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1500 see L<perlop/"I/O Operators">.
1501
1502 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1503 detect the end of each file, C<eof()> will only detect the end of the
1504 last file.  Examples:
1505
1506     # reset line numbering on each input file
1507     while (<>) {
1508         next if /^\s*#/;  # skip comments
1509         print "$.\t$_";
1510     } continue {
1511         close ARGV if eof;  # Not eof()!
1512     }
1513
1514     # insert dashes just before last line of last file
1515     while (<>) {
1516         if (eof()) {  # check for end of last file
1517             print "--------------\n";
1518         }
1519         print;
1520         last if eof();          # needed if we're reading from a terminal
1521     }
1522
1523 Practical hint: you almost never need to use C<eof> in Perl, because the
1524 input operators typically return C<undef> when they run out of data, or if
1525 there was an error.
1526
1527 =item eval EXPR
1528 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1529 X<error, handling> X<exception, handling>
1530
1531 =item eval BLOCK
1532
1533 =item eval
1534
1535 In the first form, the return value of EXPR is parsed and executed as if it
1536 were a little Perl program.  The value of the expression (which is itself
1537 determined within scalar context) is first parsed, and if there weren't any
1538 errors, executed in the lexical context of the current Perl program, so
1539 that any variable settings or subroutine and format definitions remain
1540 afterwards.  Note that the value is parsed every time the C<eval> executes.
1541 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1542 delay parsing and subsequent execution of the text of EXPR until run time.
1543
1544 In the second form, the code within the BLOCK is parsed only once--at the
1545 same time the code surrounding the C<eval> itself was parsed--and executed
1546 within the context of the current Perl program.  This form is typically
1547 used to trap exceptions more efficiently than the first (see below), while
1548 also providing the benefit of checking the code within BLOCK at compile
1549 time.
1550
1551 The final semicolon, if any, may be omitted from the value of EXPR or within
1552 the BLOCK.
1553
1554 In both forms, the value returned is the value of the last expression
1555 evaluated inside the mini-program; a return statement may be also used, just
1556 as with subroutines.  The expression providing the return value is evaluated
1557 in void, scalar, or list context, depending on the context of the C<eval> 
1558 itself.  See L</wantarray> for more on how the evaluation context can be 
1559 determined.
1560
1561 If there is a syntax error or runtime error, or a C<die> statement is
1562 executed, C<eval> returns an undefined value in scalar context
1563 or an empty list in list context, and C<$@> is set to the
1564 error message.  If there was no error, C<$@> is guaranteed to be a null
1565 string.  Beware that using C<eval> neither silences perl from printing
1566 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1567 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1568 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1569 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1570
1571 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1572 determining whether a particular feature (such as C<socket> or C<symlink>)
1573 is implemented.  It is also Perl's exception trapping mechanism, where
1574 the die operator is used to raise exceptions.
1575
1576 If you want to trap errors when loading an XS module, some problems with
1577 the binary interface (such as Perl version skew) may be fatal even with
1578 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set. See L<perlrun>.
1579
1580 If the code to be executed doesn't vary, you may use the eval-BLOCK
1581 form to trap run-time errors without incurring the penalty of
1582 recompiling each time.  The error, if any, is still returned in C<$@>.
1583 Examples:
1584
1585     # make divide-by-zero nonfatal
1586     eval { $answer = $a / $b; }; warn $@ if $@;
1587
1588     # same thing, but less efficient
1589     eval '$answer = $a / $b'; warn $@ if $@;
1590
1591     # a compile-time error
1592     eval { $answer = }; # WRONG
1593
1594     # a run-time error
1595     eval '$answer =';   # sets $@
1596
1597 Using the C<eval{}> form as an exception trap in libraries does have some
1598 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1599 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1600 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1601 as this example shows:
1602
1603     # a private exception trap for divide-by-zero
1604     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1605     warn $@ if $@;
1606
1607 This is especially significant, given that C<__DIE__> hooks can call
1608 C<die> again, which has the effect of changing their error messages:
1609
1610     # __DIE__ hooks may modify error messages
1611     {
1612        local $SIG{'__DIE__'} =
1613               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1614        eval { die "foo lives here" };
1615        print $@ if $@;                # prints "bar lives here"
1616     }
1617
1618 Because this promotes action at a distance, this counterintuitive behavior
1619 may be fixed in a future release.
1620
1621 With an C<eval>, you should be especially careful to remember what's
1622 being looked at when:
1623
1624     eval $x;        # CASE 1
1625     eval "$x";      # CASE 2
1626
1627     eval '$x';      # CASE 3
1628     eval { $x };    # CASE 4
1629
1630     eval "\$$x++";  # CASE 5
1631     $$x++;          # CASE 6
1632
1633 Cases 1 and 2 above behave identically: they run the code contained in
1634 the variable $x.  (Although case 2 has misleading double quotes making
1635 the reader wonder what else might be happening (nothing is).)  Cases 3
1636 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1637 does nothing but return the value of $x.  (Case 4 is preferred for
1638 purely visual reasons, but it also has the advantage of compiling at
1639 compile-time instead of at run-time.)  Case 5 is a place where
1640 normally you I<would> like to use double quotes, except that in this
1641 particular situation, you can just use symbolic references instead, as
1642 in case 6.
1643
1644 The assignment to C<$@> occurs before restoration of localised variables,
1645 which means a temporary is required if you want to mask some but not all
1646 errors:
1647
1648     # alter $@ on nefarious repugnancy only
1649     {
1650        my $e;
1651        {
1652           local $@; # protect existing $@
1653           eval { test_repugnancy() };
1654           # $@ =~ /nefarious/ and die $@; # DOES NOT WORK
1655           $@ =~ /nefarious/ and $e = $@;
1656        }
1657        die $e if defined $e
1658     }
1659
1660 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1661 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1662
1663 Note that as a special case, an C<eval ''> executed within the C<DB>
1664 package doesn't see the usual surrounding lexical scope, but rather the
1665 scope of the first non-DB piece of code that called it. You don't normally
1666 need to worry about this unless you are writing a Perl debugger.
1667
1668 =item exec LIST
1669 X<exec> X<execute>
1670
1671 =item exec PROGRAM LIST
1672
1673 The C<exec> function executes a system command I<and never returns>--
1674 use C<system> instead of C<exec> if you want it to return.  It fails and
1675 returns false only if the command does not exist I<and> it is executed
1676 directly instead of via your system's command shell (see below).
1677
1678 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1679 warns you if there is a following statement that isn't C<die>, C<warn>,
1680 or C<exit> (if C<-w> is set --but you always do that).   If you
1681 I<really> want to follow an C<exec> with some other statement, you
1682 can use one of these styles to avoid the warning:
1683
1684     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1685     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1686
1687 If there is more than one argument in LIST, or if LIST is an array
1688 with more than one value, calls execvp(3) with the arguments in LIST.
1689 If there is only one scalar argument or an array with one element in it,
1690 the argument is checked for shell metacharacters, and if there are any,
1691 the entire argument is passed to the system's command shell for parsing
1692 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1693 If there are no shell metacharacters in the argument, it is split into
1694 words and passed directly to C<execvp>, which is more efficient.
1695 Examples:
1696
1697     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1698     exec "sort $outfile | uniq";
1699
1700 If you don't really want to execute the first argument, but want to lie
1701 to the program you are executing about its own name, you can specify
1702 the program you actually want to run as an "indirect object" (without a
1703 comma) in front of the LIST.  (This always forces interpretation of the
1704 LIST as a multivalued list, even if there is only a single scalar in
1705 the list.)  Example:
1706
1707     $shell = '/bin/csh';
1708     exec $shell '-sh';    # pretend it's a login shell
1709
1710 or, more directly,
1711
1712     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1713
1714 When the arguments get executed via the system shell, results will
1715 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1716 for details.
1717
1718 Using an indirect object with C<exec> or C<system> is also more
1719 secure.  This usage (which also works fine with system()) forces
1720 interpretation of the arguments as a multivalued list, even if the
1721 list had just one argument.  That way you're safe from the shell
1722 expanding wildcards or splitting up words with whitespace in them.
1723
1724     @args = ( "echo surprise" );
1725
1726     exec @args;               # subject to shell escapes
1727                                 # if @args == 1
1728     exec { $args[0] } @args;  # safe even with one-arg list
1729
1730 The first version, the one without the indirect object, ran the I<echo>
1731 program, passing it C<"surprise"> an argument.  The second version didn't;
1732 it tried to run a program named I<"echo surprise">, didn't find it, and set
1733 C<$?> to a non-zero value indicating failure.
1734
1735 Beginning with v5.6.0, Perl attempts to flush all files opened for
1736 output before the exec, but this may not be supported on some platforms
1737 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1738 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1739 open handles to avoid lost output.
1740
1741 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1742 C<DESTROY> methods on your objects.
1743
1744 =item exists EXPR
1745 X<exists> X<autovivification>
1746
1747 Given an expression that specifies a hash element or array element,
1748 returns true if the specified element in the hash or array has ever
1749 been initialized, even if the corresponding value is undefined.
1750
1751     print "Exists\n"    if exists $hash{$key};
1752     print "Defined\n"   if defined $hash{$key};
1753     print "True\n"      if $hash{$key};
1754
1755     print "Exists\n"    if exists $array[$index];
1756     print "Defined\n"   if defined $array[$index];
1757     print "True\n"      if $array[$index];
1758
1759 A hash or array element can be true only if it's defined, and defined if
1760 it exists, but the reverse doesn't necessarily hold true.
1761
1762 Given an expression that specifies the name of a subroutine,
1763 returns true if the specified subroutine has ever been declared, even
1764 if it is undefined.  Mentioning a subroutine name for exists or defined
1765 does not count as declaring it.  Note that a subroutine that does not
1766 exist may still be callable: its package may have an C<AUTOLOAD>
1767 method that makes it spring into existence the first time that it is
1768 called--see L<perlsub>.
1769
1770     print "Exists\n"  if exists &subroutine;
1771     print "Defined\n" if defined &subroutine;
1772
1773 Note that the EXPR can be arbitrarily complicated as long as the final
1774 operation is a hash or array key lookup or subroutine name:
1775
1776     if (exists $ref->{A}->{B}->{$key})  { }
1777     if (exists $hash{A}{B}{$key})       { }
1778
1779     if (exists $ref->{A}->{B}->[$ix])   { }
1780     if (exists $hash{A}{B}[$ix])        { }
1781
1782     if (exists &{$ref->{A}{B}{$key}})   { }
1783
1784 Although the deepest nested array or hash will not spring into existence
1785 just because its existence was tested, any intervening ones will.
1786 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1787 into existence due to the existence test for the $key element above.
1788 This happens anywhere the arrow operator is used, including even:
1789
1790     undef $ref;
1791     if (exists $ref->{"Some key"})    { }
1792     print $ref;  # prints HASH(0x80d3d5c)
1793
1794 This surprising autovivification in what does not at first--or even
1795 second--glance appear to be an lvalue context may be fixed in a future
1796 release.
1797
1798 Use of a subroutine call, rather than a subroutine name, as an argument
1799 to exists() is an error.
1800
1801     exists &sub;    # OK
1802     exists &sub();  # Error
1803
1804 =item exit EXPR
1805 X<exit> X<terminate> X<abort>
1806
1807 =item exit
1808
1809 Evaluates EXPR and exits immediately with that value.    Example:
1810
1811     $ans = <STDIN>;
1812     exit 0 if $ans =~ /^[Xx]/;
1813
1814 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1815 universally recognized values for EXPR are C<0> for success and C<1>
1816 for error; other values are subject to interpretation depending on the
1817 environment in which the Perl program is running.  For example, exiting
1818 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1819 the mailer to return the item undelivered, but that's not true everywhere.
1820
1821 Don't use C<exit> to abort a subroutine if there's any chance that
1822 someone might want to trap whatever error happened.  Use C<die> instead,
1823 which can be trapped by an C<eval>.
1824
1825 The exit() function does not always exit immediately.  It calls any
1826 defined C<END> routines first, but these C<END> routines may not
1827 themselves abort the exit.  Likewise any object destructors that need to
1828 be called are called before the real exit.  If this is a problem, you
1829 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1830 See L<perlmod> for details.
1831
1832 =item exp EXPR
1833 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1834
1835 =item exp
1836
1837 Returns I<e> (the natural logarithm base) to the power of EXPR.
1838 If EXPR is omitted, gives C<exp($_)>.
1839
1840 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1841 X<fcntl>
1842
1843 Implements the fcntl(2) function.  You'll probably have to say
1844
1845     use Fcntl;
1846
1847 first to get the correct constant definitions.  Argument processing and
1848 value return works just like C<ioctl> below.
1849 For example:
1850
1851     use Fcntl;
1852     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1853         or die "can't fcntl F_GETFL: $!";
1854
1855 You don't have to check for C<defined> on the return from C<fcntl>.
1856 Like C<ioctl>, it maps a C<0> return from the system call into
1857 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1858 in numeric context.  It is also exempt from the normal B<-w> warnings
1859 on improper numeric conversions.
1860
1861 Note that C<fcntl> will produce a fatal error if used on a machine that
1862 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1863 manpage to learn what functions are available on your system.
1864
1865 Here's an example of setting a filehandle named C<REMOTE> to be
1866 non-blocking at the system level.  You'll have to negotiate C<$|>
1867 on your own, though.
1868
1869     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1870
1871     $flags = fcntl(REMOTE, F_GETFL, 0)
1872                 or die "Can't get flags for the socket: $!\n";
1873
1874     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1875                 or die "Can't set flags for the socket: $!\n";
1876
1877 =item fileno FILEHANDLE
1878 X<fileno>
1879
1880 Returns the file descriptor for a filehandle, or undefined if the
1881 filehandle is not open.  This is mainly useful for constructing
1882 bitmaps for C<select> and low-level POSIX tty-handling operations.
1883 If FILEHANDLE is an expression, the value is taken as an indirect
1884 filehandle, generally its name.
1885
1886 You can use this to find out whether two handles refer to the
1887 same underlying descriptor:
1888
1889     if (fileno(THIS) == fileno(THAT)) {
1890         print "THIS and THAT are dups\n";
1891     }
1892
1893 (Filehandles connected to memory objects via new features of C<open> may
1894 return undefined even though they are open.)
1895
1896
1897 =item flock FILEHANDLE,OPERATION
1898 X<flock> X<lock> X<locking>
1899
1900 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1901 for success, false on failure.  Produces a fatal error if used on a
1902 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1903 C<flock> is Perl's portable file locking interface, although it locks
1904 only entire files, not records.
1905
1906 Two potentially non-obvious but traditional C<flock> semantics are
1907 that it waits indefinitely until the lock is granted, and that its locks
1908 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1909 fewer guarantees.  This means that programs that do not also use C<flock>
1910 may modify files locked with C<flock>.  See L<perlport>, 
1911 your port's specific documentation, or your system-specific local manpages
1912 for details.  It's best to assume traditional behavior if you're writing
1913 portable programs.  (But if you're not, you should as always feel perfectly
1914 free to write for your own system's idiosyncrasies (sometimes called
1915 "features").  Slavish adherence to portability concerns shouldn't get
1916 in the way of your getting your job done.)
1917
1918 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1919 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1920 you can use the symbolic names if you import them from the Fcntl module,
1921 either individually, or as a group using the ':flock' tag.  LOCK_SH
1922 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1923 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1924 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1925 waiting for the lock (check the return status to see if you got it).
1926
1927 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1928 before locking or unlocking it.
1929
1930 Note that the emulation built with lockf(3) doesn't provide shared
1931 locks, and it requires that FILEHANDLE be open with write intent.  These
1932 are the semantics that lockf(3) implements.  Most if not all systems
1933 implement lockf(3) in terms of fcntl(2) locking, though, so the
1934 differing semantics shouldn't bite too many people.
1935
1936 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1937 be open with read intent to use LOCK_SH and requires that it be open
1938 with write intent to use LOCK_EX.
1939
1940 Note also that some versions of C<flock> cannot lock things over the
1941 network; you would need to use the more system-specific C<fcntl> for
1942 that.  If you like you can force Perl to ignore your system's flock(2)
1943 function, and so provide its own fcntl(2)-based emulation, by passing
1944 the switch C<-Ud_flock> to the F<Configure> program when you configure
1945 perl.
1946
1947 Here's a mailbox appender for BSD systems.
1948
1949     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
1950
1951     sub lock {
1952         my ($fh) = @_;
1953         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
1954
1955         # and, in case someone appended while we were waiting...
1956         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
1957     }
1958
1959     sub unlock {
1960         my ($fh) = @_;
1961         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
1962     }
1963
1964     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
1965         or die "Can't open mailbox: $!";
1966
1967     lock($mbox);
1968     print $mbox $msg,"\n\n";
1969     unlock($mbox);
1970
1971 On systems that support a real flock(), locks are inherited across fork()
1972 calls, whereas those that must resort to the more capricious fcntl()
1973 function lose the locks, making it harder to write servers.
1974
1975 See also L<DB_File> for other flock() examples.
1976
1977 =item fork
1978 X<fork> X<child> X<parent>
1979
1980 Does a fork(2) system call to create a new process running the
1981 same program at the same point.  It returns the child pid to the
1982 parent process, C<0> to the child process, or C<undef> if the fork is
1983 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1984 are shared, while everything else is copied.  On most systems supporting
1985 fork(), great care has gone into making it extremely efficient (for
1986 example, using copy-on-write technology on data pages), making it the
1987 dominant paradigm for multitasking over the last few decades.
1988
1989 Beginning with v5.6.0, Perl attempts to flush all files opened for
1990 output before forking the child process, but this may not be supported
1991 on some platforms (see L<perlport>).  To be safe, you may need to set
1992 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1993 C<IO::Handle> on any open handles to avoid duplicate output.
1994
1995 If you C<fork> without ever waiting on your children, you will
1996 accumulate zombies.  On some systems, you can avoid this by setting
1997 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1998 forking and reaping moribund children.
1999
2000 Note that if your forked child inherits system file descriptors like
2001 STDIN and STDOUT that are actually connected by a pipe or socket, even
2002 if you exit, then the remote server (such as, say, a CGI script or a
2003 backgrounded job launched from a remote shell) won't think you're done.
2004 You should reopen those to F</dev/null> if it's any issue.
2005
2006 =item format
2007 X<format>
2008
2009 Declare a picture format for use by the C<write> function.  For
2010 example:
2011
2012     format Something =
2013         Test: @<<<<<<<< @||||| @>>>>>
2014               $str,     $%,    '$' . int($num)
2015     .
2016
2017     $str = "widget";
2018     $num = $cost/$quantity;
2019     $~ = 'Something';
2020     write;
2021
2022 See L<perlform> for many details and examples.
2023
2024 =item formline PICTURE,LIST
2025 X<formline>
2026
2027 This is an internal function used by C<format>s, though you may call it,
2028 too.  It formats (see L<perlform>) a list of values according to the
2029 contents of PICTURE, placing the output into the format output
2030 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2031 Eventually, when a C<write> is done, the contents of
2032 C<$^A> are written to some filehandle.  You could also read C<$^A>
2033 and then set C<$^A> back to C<"">.  Note that a format typically
2034 does one C<formline> per line of form, but the C<formline> function itself
2035 doesn't care how many newlines are embedded in the PICTURE.  This means
2036 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
2037 You may therefore need to use multiple formlines to implement a single
2038 record format, just like the format compiler.
2039
2040 Be careful if you put double quotes around the picture, because an C<@>
2041 character may be taken to mean the beginning of an array name.
2042 C<formline> always returns true.  See L<perlform> for other examples.
2043
2044 =item getc FILEHANDLE
2045 X<getc> X<getchar> X<character> X<file, read>
2046
2047 =item getc
2048
2049 Returns the next character from the input file attached to FILEHANDLE,
2050 or the undefined value at end of file, or if there was an error (in
2051 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2052 STDIN.  This is not particularly efficient.  However, it cannot be
2053 used by itself to fetch single characters without waiting for the user
2054 to hit enter.  For that, try something more like:
2055
2056     if ($BSD_STYLE) {
2057         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2058     }
2059     else {
2060         system "stty", '-icanon', 'eol', "\001";
2061     }
2062
2063     $key = getc(STDIN);
2064
2065     if ($BSD_STYLE) {
2066         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2067     }
2068     else {
2069         system "stty", 'icanon', 'eol', '^@'; # ASCII null
2070     }
2071     print "\n";
2072
2073 Determination of whether $BSD_STYLE should be set
2074 is left as an exercise to the reader.
2075
2076 The C<POSIX::getattr> function can do this more portably on
2077 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2078 module from your nearest CPAN site; details on CPAN can be found on
2079 L<perlmodlib/CPAN>.
2080
2081 =item getlogin
2082 X<getlogin> X<login>
2083
2084 This implements the C library function of the same name, which on most
2085 systems returns the current login from F</etc/utmp>, if any.  If null,
2086 use C<getpwuid>.
2087
2088     $login = getlogin || getpwuid($<) || "Kilroy";
2089
2090 Do not consider C<getlogin> for authentication: it is not as
2091 secure as C<getpwuid>.
2092
2093 =item getpeername SOCKET
2094 X<getpeername> X<peer>
2095
2096 Returns the packed sockaddr address of other end of the SOCKET connection.
2097
2098     use Socket;
2099     $hersockaddr    = getpeername(SOCK);
2100     ($port, $iaddr) = sockaddr_in($hersockaddr);
2101     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2102     $herstraddr     = inet_ntoa($iaddr);
2103
2104 =item getpgrp PID
2105 X<getpgrp> X<group>
2106
2107 Returns the current process group for the specified PID.  Use
2108 a PID of C<0> to get the current process group for the
2109 current process.  Will raise an exception if used on a machine that
2110 doesn't implement getpgrp(2).  If PID is omitted, returns process
2111 group of current process.  Note that the POSIX version of C<getpgrp>
2112 does not accept a PID argument, so only C<PID==0> is truly portable.
2113
2114 =item getppid
2115 X<getppid> X<parent> X<pid>
2116
2117 Returns the process id of the parent process.
2118
2119 Note for Linux users: on Linux, the C functions C<getpid()> and
2120 C<getppid()> return different values from different threads. In order to
2121 be portable, this behavior is not reflected by the perl-level function
2122 C<getppid()>, that returns a consistent value across threads. If you want
2123 to call the underlying C<getppid()>, you may use the CPAN module
2124 C<Linux::Pid>.
2125
2126 =item getpriority WHICH,WHO
2127 X<getpriority> X<priority> X<nice>
2128
2129 Returns the current priority for a process, a process group, or a user.
2130 (See C<getpriority(2)>.)  Will raise a fatal exception if used on a
2131 machine that doesn't implement getpriority(2).
2132
2133 =item getpwnam NAME
2134 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2135 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2136 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2137 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2138 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2139 X<endnetent> X<endprotoent> X<endservent> 
2140
2141 =item getgrnam NAME
2142
2143 =item gethostbyname NAME
2144
2145 =item getnetbyname NAME
2146
2147 =item getprotobyname NAME
2148
2149 =item getpwuid UID
2150
2151 =item getgrgid GID
2152
2153 =item getservbyname NAME,PROTO
2154
2155 =item gethostbyaddr ADDR,ADDRTYPE
2156
2157 =item getnetbyaddr ADDR,ADDRTYPE
2158
2159 =item getprotobynumber NUMBER
2160
2161 =item getservbyport PORT,PROTO
2162
2163 =item getpwent
2164
2165 =item getgrent
2166
2167 =item gethostent
2168
2169 =item getnetent
2170
2171 =item getprotoent
2172
2173 =item getservent
2174
2175 =item setpwent
2176
2177 =item setgrent
2178
2179 =item sethostent STAYOPEN
2180
2181 =item setnetent STAYOPEN
2182
2183 =item setprotoent STAYOPEN
2184
2185 =item setservent STAYOPEN
2186
2187 =item endpwent
2188
2189 =item endgrent
2190
2191 =item endhostent
2192
2193 =item endnetent
2194
2195 =item endprotoent
2196
2197 =item endservent
2198
2199 These routines are the same as their counterparts in the
2200 system C library.  In list context, the return values from the
2201 various get routines are as follows:
2202
2203     ($name,$passwd,$uid,$gid,
2204        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2205     ($name,$passwd,$gid,$members) = getgr*
2206     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2207     ($name,$aliases,$addrtype,$net) = getnet*
2208     ($name,$aliases,$proto) = getproto*
2209     ($name,$aliases,$port,$proto) = getserv*
2210
2211 (If the entry doesn't exist you get a null list.)
2212
2213 The exact meaning of the $gcos field varies but it usually contains
2214 the real name of the user (as opposed to the login name) and other
2215 information pertaining to the user.  Beware, however, that in many
2216 system users are able to change this information and therefore it
2217 cannot be trusted and therefore the $gcos is tainted (see
2218 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2219 login shell, are also tainted, because of the same reason.
2220
2221 In scalar context, you get the name, unless the function was a
2222 lookup by name, in which case you get the other thing, whatever it is.
2223 (If the entry doesn't exist you get the undefined value.)  For example:
2224
2225     $uid   = getpwnam($name);
2226     $name  = getpwuid($num);
2227     $name  = getpwent();
2228     $gid   = getgrnam($name);
2229     $name  = getgrgid($num);
2230     $name  = getgrent();
2231     #etc.
2232
2233 In I<getpw*()> the fields $quota, $comment, and $expire are special
2234 in that they are unsupported on many systems.  If the
2235 $quota is unsupported, it is an empty scalar.  If it is supported, it
2236 usually encodes the disk quota.  If the $comment field is unsupported,
2237 it is an empty scalar.  If it is supported it usually encodes some
2238 administrative comment about the user.  In some systems the $quota
2239 field may be $change or $age, fields that have to do with password
2240 aging.  In some systems the $comment field may be $class.  The $expire
2241 field, if present, encodes the expiration period of the account or the
2242 password.  For the availability and the exact meaning of these fields
2243 in your system, please consult your getpwnam(3) documentation and your
2244 F<pwd.h> file.  You can also find out from within Perl what your
2245 $quota and $comment fields mean and whether you have the $expire field
2246 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2247 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2248 files are only supported if your vendor has implemented them in the
2249 intuitive fashion that calling the regular C library routines gets the
2250 shadow versions if you're running under privilege or if there exists
2251 the shadow(3) functions as found in System V (this includes Solaris
2252 and Linux.)  Those systems that implement a proprietary shadow password
2253 facility are unlikely to be supported.
2254
2255 The $members value returned by I<getgr*()> is a space separated list of
2256 the login names of the members of the group.
2257
2258 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2259 C, it will be returned to you via C<$?> if the function call fails.  The
2260 C<@addrs> value returned by a successful call is a list of the raw
2261 addresses returned by the corresponding system library call.  In the
2262 Internet domain, each address is four bytes long and you can unpack it
2263 by saying something like:
2264
2265     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2266
2267 The Socket library makes this slightly easier:
2268
2269     use Socket;
2270     $iaddr = inet_aton("127.1"); # or whatever address
2271     $name  = gethostbyaddr($iaddr, AF_INET);
2272
2273     # or going the other way
2274     $straddr = inet_ntoa($iaddr);
2275
2276 In the opposite way, to resolve a hostname to the IP address
2277 you can write this:
2278
2279     use Socket;
2280     $packed_ip = gethostbyname("www.perl.org");
2281     if (defined $packed_ip) {
2282         $ip_address = inet_ntoa($packed_ip);
2283     }
2284
2285 Make sure <gethostbyname()> is called in SCALAR context and that
2286 its return value is checked for definedness.
2287
2288 If you get tired of remembering which element of the return list
2289 contains which return value, by-name interfaces are provided
2290 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2291 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2292 and C<User::grent>.  These override the normal built-ins, supplying
2293 versions that return objects with the appropriate names
2294 for each field.  For example:
2295
2296    use File::stat;
2297    use User::pwent;
2298    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2299
2300 Even though it looks like they're the same method calls (uid),
2301 they aren't, because a C<File::stat> object is different from
2302 a C<User::pwent> object.
2303
2304 =item getsockname SOCKET
2305 X<getsockname>
2306
2307 Returns the packed sockaddr address of this end of the SOCKET connection,
2308 in case you don't know the address because you have several different
2309 IPs that the connection might have come in on.
2310
2311     use Socket;
2312     $mysockaddr = getsockname(SOCK);
2313     ($port, $myaddr) = sockaddr_in($mysockaddr);
2314     printf "Connect to %s [%s]\n",
2315        scalar gethostbyaddr($myaddr, AF_INET),
2316        inet_ntoa($myaddr);
2317
2318 =item getsockopt SOCKET,LEVEL,OPTNAME
2319 X<getsockopt>
2320
2321 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2322 Options may exist at multiple protocol levels depending on the socket
2323 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2324 C<Socket> module) will exist. To query options at another level the
2325 protocol number of the appropriate protocol controlling the option
2326 should be supplied. For example, to indicate that an option is to be
2327 interpreted by the TCP protocol, LEVEL should be set to the protocol
2328 number of TCP, which you can get using C<getprotobyname>.
2329
2330 The function returns a packed string representing the requested socket
2331 option, or C<undef> if there is an error (the error reason will be in
2332 C<$!>). What exactly is in the packed string depends on LEVEL and OPTNAME;
2333 consult getsockopt(2) for details.  A common case is that the option is an
2334 integer, in which case the result is a packed integer, which you can decode
2335 using C<unpack> with the C<i> (or C<I>) format.
2336
2337 An example to test whether Nagle's algorithm is turned on on a socket:
2338
2339     use Socket qw(:all);
2340
2341     defined(my $tcp = getprotobyname("tcp"))
2342         or die "Could not determine the protocol number for tcp";
2343     # my $tcp = IPPROTO_TCP; # Alternative
2344     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2345         or die "getsockopt TCP_NODELAY: $!";
2346     my $nodelay = unpack("I", $packed);
2347     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2348
2349
2350 =item glob EXPR
2351 X<glob> X<wildcard> X<filename, expansion> X<expand>
2352
2353 =item glob
2354
2355 In list context, returns a (possibly empty) list of filename expansions on
2356 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2357 scalar context, glob iterates through such filename expansions, returning
2358 undef when the list is exhausted. This is the internal function
2359 implementing the C<< <*.c> >> operator, but you can use it directly. If
2360 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2361 more detail in L<perlop/"I/O Operators">.
2362
2363 Note that C<glob> splits its arguments on whitespace and treats
2364 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2365 matches all files with a F<.c> or F<.h> extension.  The expression
2366 C<glob(".* *")> matchs all files in the current working directory.
2367
2368 If non-empty braces are the only wildcard characters used in the
2369 C<glob>, no filenames are matched, but potentially many strings
2370 are returned.  For example, this produces nine strings, one for
2371 each pairing of fruits and colors:
2372
2373     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2374
2375 Beginning with v5.6.0, this operator is implemented using the standard
2376 C<File::Glob> extension.  See L<File::Glob> for details, including
2377 C<bsd_glob> which does not treat whitespace as a pattern separator.
2378
2379 =item gmtime EXPR
2380 X<gmtime> X<UTC> X<Greenwich>
2381
2382 =item gmtime
2383
2384 Works just like L<localtime> but the returned values are
2385 localized for the standard Greenwich time zone.
2386
2387 Note: when called in list context, $isdst, the last value
2388 returned by gmtime is always C<0>.  There is no
2389 Daylight Saving Time in GMT.
2390
2391 See L<perlport/gmtime> for portability concerns.
2392
2393 =item goto LABEL
2394 X<goto> X<jump> X<jmp>
2395
2396 =item goto EXPR
2397
2398 =item goto &NAME
2399
2400 The C<goto-LABEL> form finds the statement labeled with LABEL and
2401 resumes execution there. It can't be used to get out of a block or
2402 subroutine given to C<sort>.  It can be used to go almost anywhere
2403 else within the dynamic scope, including out of subroutines, but it's
2404 usually better to use some other construct such as C<last> or C<die>.
2405 The author of Perl has never felt the need to use this form of C<goto>
2406 (in Perl, that is--C is another matter).  (The difference is that C
2407 does not offer named loops combined with loop control.  Perl does, and
2408 this replaces most structured uses of C<goto> in other languages.)
2409
2410 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2411 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2412 necessarily recommended if you're optimizing for maintainability:
2413
2414     goto ("FOO", "BAR", "GLARCH")[$i];
2415
2416 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2417 deprecated and will issue a warning.  Even then, it may not be used to
2418 go into any construct that requires initialization, such as a
2419 subroutine or a C<foreach> loop.  It also can't be used to go into a
2420 construct that is optimized away.
2421
2422 The C<goto-&NAME> form is quite different from the other forms of
2423 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2424 doesn't have the stigma associated with other gotos.  Instead, it
2425 exits the current subroutine (losing any changes set by local()) and
2426 immediately calls in its place the named subroutine using the current
2427 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2428 load another subroutine and then pretend that the other subroutine had
2429 been called in the first place (except that any modifications to C<@_>
2430 in the current subroutine are propagated to the other subroutine.)
2431 After the C<goto>, not even C<caller> will be able to tell that this
2432 routine was called first.
2433
2434 NAME needn't be the name of a subroutine; it can be a scalar variable
2435 containing a code reference, or a block that evaluates to a code
2436 reference.
2437
2438 =item grep BLOCK LIST
2439 X<grep>
2440
2441 =item grep EXPR,LIST
2442
2443 This is similar in spirit to, but not the same as, grep(1) and its
2444 relatives.  In particular, it is not limited to using regular expressions.
2445
2446 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2447 C<$_> to each element) and returns the list value consisting of those
2448 elements for which the expression evaluated to true.  In scalar
2449 context, returns the number of times the expression was true.
2450
2451     @foo = grep(!/^#/, @bar);    # weed out comments
2452
2453 or equivalently,
2454
2455     @foo = grep {!/^#/} @bar;    # weed out comments
2456
2457 Note that C<$_> is an alias to the list value, so it can be used to
2458 modify the elements of the LIST.  While this is useful and supported,
2459 it can cause bizarre results if the elements of LIST are not variables.
2460 Similarly, grep returns aliases into the original list, much as a for
2461 loop's index variable aliases the list elements.  That is, modifying an
2462 element of a list returned by grep (for example, in a C<foreach>, C<map>
2463 or another C<grep>) actually modifies the element in the original list.
2464 This is usually something to be avoided when writing clear code.
2465
2466 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2467 been declared with C<my $_>) then, in addition to being locally aliased to
2468 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2469 can't be seen from the outside, avoiding any potential side-effects.
2470
2471 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2472
2473 =item hex EXPR
2474 X<hex> X<hexadecimal>
2475
2476 =item hex
2477
2478 Interprets EXPR as a hex string and returns the corresponding value.
2479 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2480 L</oct>.)  If EXPR is omitted, uses C<$_>.
2481
2482     print hex '0xAf'; # prints '175'
2483     print hex 'aF';   # same
2484
2485 Hex strings may only represent integers.  Strings that would cause
2486 integer overflow trigger a warning.  Leading whitespace is not stripped,
2487 unlike oct(). To present something as hex, look into L</printf>,
2488 L</sprintf>, or L</unpack>.
2489
2490 =item import LIST
2491 X<import>
2492
2493 There is no builtin C<import> function.  It is just an ordinary
2494 method (subroutine) defined (or inherited) by modules that wish to export
2495 names to another module.  The C<use> function calls the C<import> method
2496 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2497
2498 =item index STR,SUBSTR,POSITION
2499 X<index> X<indexOf> X<InStr>
2500
2501 =item index STR,SUBSTR
2502
2503 The index function searches for one string within another, but without
2504 the wildcard-like behavior of a full regular-expression pattern match.
2505 It returns the position of the first occurrence of SUBSTR in STR at
2506 or after POSITION.  If POSITION is omitted, starts searching from the
2507 beginning of the string.  POSITION before the beginning of the string
2508 or after its end is treated as if it were the beginning or the end,
2509 respectively.  POSITION and the return value are based at C<0> (or whatever
2510 you've set the C<$[> variable to--but don't do that).  If the substring
2511 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2512
2513 =item int EXPR
2514 X<int> X<integer> X<truncate> X<trunc> X<floor>
2515
2516 =item int
2517
2518 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2519 You should not use this function for rounding: one because it truncates
2520 towards C<0>, and two because machine representations of floating point
2521 numbers can sometimes produce counterintuitive results.  For example,
2522 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2523 because it's really more like -268.99999999999994315658 instead.  Usually,
2524 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2525 functions will serve you better than will int().
2526
2527 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2528 X<ioctl>
2529
2530 Implements the ioctl(2) function.  You'll probably first have to say
2531
2532     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2533
2534 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2535 exist or doesn't have the correct definitions you'll have to roll your
2536 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2537 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2538 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2539 written depending on the FUNCTION--a pointer to the string value of SCALAR
2540 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2541 has no string value but does have a numeric value, that value will be
2542 passed rather than a pointer to the string value.  To guarantee this to be
2543 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2544 functions may be needed to manipulate the values of structures used by
2545 C<ioctl>.
2546
2547 The return value of C<ioctl> (and C<fcntl>) is as follows:
2548
2549     if OS returns:      then Perl returns:
2550         -1               undefined value
2551          0              string "0 but true"
2552     anything else           that number
2553
2554 Thus Perl returns true on success and false on failure, yet you can
2555 still easily determine the actual value returned by the operating
2556 system:
2557
2558     $retval = ioctl(...) || -1;
2559     printf "System returned %d\n", $retval;
2560
2561 The special string C<"0 but true"> is exempt from B<-w> complaints
2562 about improper numeric conversions.
2563
2564 =item join EXPR,LIST
2565 X<join>
2566
2567 Joins the separate strings of LIST into a single string with fields
2568 separated by the value of EXPR, and returns that new string.  Example:
2569
2570     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2571
2572 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2573 first argument.  Compare L</split>.
2574
2575 =item keys HASH
2576 X<keys> X<key>
2577
2578 =item keys ARRAY
2579
2580 Returns a list consisting of all the keys of the named hash, or the indices
2581 of an array. (In scalar context, returns the number of keys or indices.)
2582
2583 The keys of a hash are returned in an apparently random order.  The actual
2584 random order is subject to change in future versions of perl, but it
2585 is guaranteed to be the same order as either the C<values> or C<each>
2586 function produces (given that the hash has not been modified).  Since
2587 Perl 5.8.1 the ordering is different even between different runs of
2588 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2589 Attacks">).
2590
2591 As a side effect, calling keys() resets the HASH or ARRAY's internal iterator
2592 (see L</each>).  In particular, calling keys() in void context resets
2593 the iterator with no other overhead.
2594
2595 Here is yet another way to print your environment:
2596
2597     @keys = keys %ENV;
2598     @values = values %ENV;
2599     while (@keys) {
2600         print pop(@keys), '=', pop(@values), "\n";
2601     }
2602
2603 or how about sorted by key:
2604
2605     foreach $key (sort(keys %ENV)) {
2606         print $key, '=', $ENV{$key}, "\n";
2607     }
2608
2609 The returned values are copies of the original keys in the hash, so
2610 modifying them will not affect the original hash.  Compare L</values>.
2611
2612 To sort a hash by value, you'll need to use a C<sort> function.
2613 Here's a descending numeric sort of a hash by its values:
2614
2615     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2616         printf "%4d %s\n", $hash{$key}, $key;
2617     }
2618
2619 As an lvalue C<keys> allows you to increase the number of hash buckets
2620 allocated for the given hash.  This can gain you a measure of efficiency if
2621 you know the hash is going to get big.  (This is similar to pre-extending
2622 an array by assigning a larger number to $#array.)  If you say
2623
2624     keys %hash = 200;
2625
2626 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2627 in fact, since it rounds up to the next power of two.  These
2628 buckets will be retained even if you do C<%hash = ()>, use C<undef
2629 %hash> if you want to free the storage while C<%hash> is still in scope.
2630 You can't shrink the number of buckets allocated for the hash using
2631 C<keys> in this way (but you needn't worry about doing this by accident,
2632 as trying has no effect). C<keys @array> in an lvalue context is a syntax
2633 error.
2634
2635 See also C<each>, C<values> and C<sort>.
2636
2637 =item kill SIGNAL, LIST
2638 X<kill> X<signal>
2639
2640 Sends a signal to a list of processes.  Returns the number of
2641 processes successfully signaled (which is not necessarily the
2642 same as the number actually killed).
2643
2644     $cnt = kill 1, $child1, $child2;
2645     kill 9, @goners;
2646
2647 If SIGNAL is zero, no signal is sent to the process, but the kill(2)
2648 system call will check whether it's possible to send a signal to it (that
2649 means, to be brief, that the process is owned by the same user, or we are
2650 the super-user).  This is a useful way to check that a child process is
2651 alive (even if only as a zombie) and hasn't changed its UID.  See
2652 L<perlport> for notes on the portability of this construct.
2653
2654 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2655 of processes. That means you usually want to use positive not negative signals.
2656 You may also use a signal name in quotes.
2657
2658 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2659 the operating system.  For example, on POSIX-conforming systems, zero will
2660 signal the current process group and -1 will signal all processes.
2661
2662 See L<perlipc/"Signals"> for more details.
2663
2664 =item last LABEL
2665 X<last> X<break>
2666
2667 =item last
2668
2669 The C<last> command is like the C<break> statement in C (as used in
2670 loops); it immediately exits the loop in question.  If the LABEL is
2671 omitted, the command refers to the innermost enclosing loop.  The
2672 C<continue> block, if any, is not executed:
2673
2674     LINE: while (<STDIN>) {
2675         last LINE if /^$/;  # exit when done with header
2676         #...
2677     }
2678
2679 C<last> cannot be used to exit a block that returns a value such as
2680 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2681 a grep() or map() operation.
2682
2683 Note that a block by itself is semantically identical to a loop
2684 that executes once.  Thus C<last> can be used to effect an early
2685 exit out of such a block.
2686
2687 See also L</continue> for an illustration of how C<last>, C<next>, and
2688 C<redo> work.
2689
2690 =item lc EXPR
2691 X<lc> X<lowercase>
2692
2693 =item lc
2694
2695 Returns a lowercased version of EXPR.  This is the internal function
2696 implementing the C<\L> escape in double-quoted strings.
2697
2698 If EXPR is omitted, uses C<$_>.
2699
2700 What gets returned depends on several factors:
2701
2702 =over
2703
2704 =item If C<use bytes> is in effect:
2705
2706 =over
2707
2708 =item On EBCDIC platforms
2709
2710 The results are what the C language system call C<tolower()> returns.
2711
2712 =item On ASCII platforms
2713
2714 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
2715 respectively.
2716
2717 =back
2718
2719 =item Otherwise, If EXPR has the UTF8 flag set
2720
2721 If the current package has a subroutine named C<ToLower>, it will be used to
2722 change the case (See L<perlunicode/User-Defined Case Mappings>.)
2723 Otherwise Unicode semantics are used for the case change.
2724
2725 =item Otherwise, if C<use locale> is in effect
2726
2727 Respects current LC_CTYPE locale.  See L<perllocale>.
2728
2729 =item Otherwise, if C<use feature 'unicode_strings'> is in effect:
2730
2731 Unicode semantics are used for the case change.  Any subroutine named
2732 C<ToLower> will not be used.
2733
2734 =item Otherwise:
2735
2736 =over
2737
2738 =item On EBCDIC platforms
2739
2740 The results are what the C language system call C<tolower()> returns.
2741
2742 =item On ASCII platforms
2743
2744 ASCII semantics are used for the case change.  The lowercase of any character
2745 outside the ASCII range is the character itself.
2746
2747 =back
2748
2749 =back
2750
2751 =item lcfirst EXPR
2752 X<lcfirst> X<lowercase>
2753
2754 =item lcfirst
2755
2756 Returns the value of EXPR with the first character lowercased.  This
2757 is the internal function implementing the C<\l> escape in
2758 double-quoted strings.
2759
2760 If EXPR is omitted, uses C<$_>.
2761
2762 This function behaves the same way under various pragma, such as in a locale,
2763 as L</lc> does.
2764
2765 =item length EXPR
2766 X<length> X<size>
2767
2768 =item length
2769
2770 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2771 omitted, returns length of C<$_>.  If EXPR is undefined, returns C<undef>.
2772 Note that this cannot be used on an entire array or hash to find out how
2773 many elements these have. For that, use C<scalar @array> and C<scalar keys
2774 %hash> respectively.
2775
2776 Note the I<characters>: if the EXPR is in Unicode, you will get the
2777 number of characters, not the number of bytes.  To get the length
2778 of the internal string in bytes, use C<bytes::length(EXPR)>, see
2779 L<bytes>.  Note that the internal encoding is variable, and the number
2780 of bytes usually meaningless.  To get the number of bytes that the
2781 string would have when encoded as UTF-8, use
2782 C<length(Encoding::encode_utf8(EXPR))>.
2783
2784 =item link OLDFILE,NEWFILE
2785 X<link>
2786
2787 Creates a new filename linked to the old filename.  Returns true for
2788 success, false otherwise.
2789
2790 =item listen SOCKET,QUEUESIZE
2791 X<listen>
2792
2793 Does the same thing that the listen system call does.  Returns true if
2794 it succeeded, false otherwise.  See the example in
2795 L<perlipc/"Sockets: Client/Server Communication">.
2796
2797 =item local EXPR
2798 X<local>
2799
2800 You really probably want to be using C<my> instead, because C<local> isn't
2801 what most people think of as "local".  See
2802 L<perlsub/"Private Variables via my()"> for details.
2803
2804 A local modifies the listed variables to be local to the enclosing
2805 block, file, or eval.  If more than one value is listed, the list must
2806 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2807 for details, including issues with tied arrays and hashes.
2808
2809 The C<delete local EXPR> construct can also be used to localize the deletion
2810 of array/hash elements to the current block.
2811 See L<perlsub/"Localized deletion of elements of composite types">.
2812
2813 =item localtime EXPR
2814 X<localtime> X<ctime>
2815
2816 =item localtime
2817
2818 Converts a time as returned by the time function to a 9-element list
2819 with the time analyzed for the local time zone.  Typically used as
2820 follows:
2821
2822     #  0    1    2     3     4    5     6     7     8
2823     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2824                                                 localtime(time);
2825
2826 All list elements are numeric, and come straight out of the C `struct
2827 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2828 of the specified time.
2829
2830 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2831 the range C<0..11> with 0 indicating January and 11 indicating December.
2832 This makes it easy to get a month name from a list:
2833
2834     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2835     print "$abbr[$mon] $mday";
2836     # $mon=9, $mday=18 gives "Oct 18"
2837
2838 C<$year> is the number of years since 1900, not just the last two digits
2839 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2840 to get a 4-digit year is simply:
2841
2842     $year += 1900;
2843
2844 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
2845 to do that, would you?
2846
2847 To get the last two digits of the year (e.g., '01' in 2001) do:
2848
2849     $year = sprintf("%02d", $year % 100);
2850
2851 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2852 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2853 (or C<0..365> in leap years.)
2854
2855 C<$isdst> is true if the specified time occurs during Daylight Saving
2856 Time, false otherwise.
2857
2858 If EXPR is omitted, C<localtime()> uses the current time (as returned
2859 by time(3)).
2860
2861 In scalar context, C<localtime()> returns the ctime(3) value:
2862
2863     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2864
2865 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2866 instead of local time use the L</gmtime> builtin. See also the
2867 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2868 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2869 and mktime(3) functions.
2870
2871 To get somewhat similar but locale dependent date strings, set up your
2872 locale environment variables appropriately (please see L<perllocale>) and
2873 try for example:
2874
2875     use POSIX qw(strftime);
2876     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2877     # or for GMT formatted appropriately for your locale:
2878     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2879
2880 Note that the C<%a> and C<%b>, the short forms of the day of the week
2881 and the month of the year, may not necessarily be three characters wide.
2882
2883 See L<perlport/localtime> for portability concerns.
2884
2885 The L<Time::gmtime> and L<Time::localtime> modules provides a convenient,
2886 by-name access mechanism to the gmtime() and localtime() functions,
2887 respectively.
2888
2889 For a comprehensive date and time representation look at the
2890 L<DateTime> module on CPAN.
2891
2892 =item lock THING
2893 X<lock>
2894
2895 This function places an advisory lock on a shared variable, or referenced
2896 object contained in I<THING> until the lock goes out of scope.
2897
2898 lock() is a "weak keyword" : this means that if you've defined a function
2899 by this name (before any calls to it), that function will be called
2900 instead. (However, if you've said C<use threads>, lock() is always a
2901 keyword.) See L<threads>.
2902
2903 =item log EXPR
2904 X<log> X<logarithm> X<e> X<ln> X<base>
2905
2906 =item log
2907
2908 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2909 returns log of C<$_>.  To get the log of another base, use basic algebra:
2910 The base-N log of a number is equal to the natural log of that number
2911 divided by the natural log of N.  For example:
2912
2913     sub log10 {
2914         my $n = shift;
2915         return log($n)/log(10);
2916     }
2917
2918 See also L</exp> for the inverse operation.
2919
2920 =item lstat EXPR
2921 X<lstat>
2922
2923 =item lstat
2924
2925 Does the same thing as the C<stat> function (including setting the
2926 special C<_> filehandle) but stats a symbolic link instead of the file
2927 the symbolic link points to.  If symbolic links are unimplemented on
2928 your system, a normal C<stat> is done.  For much more detailed
2929 information, please see the documentation for C<stat>.
2930
2931 If EXPR is omitted, stats C<$_>.
2932
2933 =item m//
2934
2935 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
2936
2937 =item map BLOCK LIST
2938 X<map>
2939
2940 =item map EXPR,LIST
2941
2942 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2943 C<$_> to each element) and returns the list value composed of the
2944 results of each such evaluation.  In scalar context, returns the
2945 total number of elements so generated.  Evaluates BLOCK or EXPR in
2946 list context, so each element of LIST may produce zero, one, or
2947 more elements in the returned value.
2948
2949     @chars = map(chr, @nums);
2950
2951 translates a list of numbers to the corresponding characters.  And
2952
2953     %hash = map { get_a_key_for($_) => $_ } @array;
2954
2955 is just a funny way to write
2956
2957     %hash = ();
2958     foreach (@array) {
2959         $hash{get_a_key_for($_)} = $_;
2960     }
2961
2962 Note that C<$_> is an alias to the list value, so it can be used to
2963 modify the elements of the LIST.  While this is useful and supported,
2964 it can cause bizarre results if the elements of LIST are not variables.
2965 Using a regular C<foreach> loop for this purpose would be clearer in
2966 most cases.  See also L</grep> for an array composed of those items of
2967 the original list for which the BLOCK or EXPR evaluates to true.
2968
2969 If C<$_> is lexical in the scope where the C<map> appears (because it has
2970 been declared with C<my $_>), then, in addition to being locally aliased to
2971 the list elements, C<$_> keeps being lexical inside the block; that is, it
2972 can't be seen from the outside, avoiding any potential side-effects.
2973
2974 C<{> starts both hash references and blocks, so C<map { ...> could be either
2975 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2976 ahead for the closing C<}> it has to take a guess at which it's dealing with
2977 based on what it finds just after the C<{>. Usually it gets it right, but if it
2978 doesn't it won't realize something is wrong until it gets to the C<}> and
2979 encounters the missing (or unexpected) comma. The syntax error will be
2980 reported close to the C<}>, but you'll need to change something near the C<{>
2981 such as using a unary C<+> to give perl some help:
2982
2983     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2984     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2985     %hash = map { ("\L$_", 1) } @array  # this also works
2986     %hash = map {  lc($_), 1  } @array  # as does this.
2987     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2988
2989     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2990
2991 or to force an anon hash constructor use C<+{>:
2992
2993    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2994
2995 and you get list of anonymous hashes each with only 1 entry.
2996
2997 =item mkdir FILENAME,MASK
2998 X<mkdir> X<md> X<directory, create>
2999
3000 =item mkdir FILENAME
3001
3002 =item mkdir
3003
3004 Creates the directory specified by FILENAME, with permissions
3005 specified by MASK (as modified by C<umask>).  If it succeeds it
3006 returns true, otherwise it returns false and sets C<$!> (errno).
3007 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
3008 to C<$_>.
3009
3010 In general, it is better to create directories with permissive MASK,
3011 and let the user modify that with their C<umask>, than it is to supply
3012 a restrictive MASK and give the user no way to be more permissive.
3013 The exceptions to this rule are when the file or directory should be
3014 kept private (mail files, for instance).  The perlfunc(1) entry on
3015 C<umask> discusses the choice of MASK in more detail.
3016
3017 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3018 number of trailing slashes.  Some operating and filesystems do not get
3019 this right, so Perl automatically removes all trailing slashes to keep
3020 everyone happy.
3021
3022 To recursively create a directory structure, look at
3023 the C<mkpath> function of the L<File::Path> module.
3024
3025 =item msgctl ID,CMD,ARG
3026 X<msgctl>
3027
3028 Calls the System V IPC function msgctl(2).  You'll probably have to say
3029
3030     use IPC::SysV;
3031
3032 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3033 then ARG must be a variable that will hold the returned C<msqid_ds>
3034 structure.  Returns like C<ioctl>: the undefined value for error,
3035 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3036 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
3037
3038 =item msgget KEY,FLAGS
3039 X<msgget>
3040
3041 Calls the System V IPC function msgget(2).  Returns the message queue
3042 id, or the undefined value if there is an error.  See also
3043 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
3044
3045 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3046 X<msgrcv>
3047
3048 Calls the System V IPC function msgrcv to receive a message from
3049 message queue ID into variable VAR with a maximum message size of
3050 SIZE.  Note that when a message is received, the message type as a
3051 native long integer will be the first thing in VAR, followed by the
3052 actual message.  This packing may be opened with C<unpack("l! a*")>.
3053 Taints the variable.  Returns true if successful, or false if there is
3054 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
3055 C<IPC::SysV::Msg> documentation.
3056
3057 =item msgsnd ID,MSG,FLAGS
3058 X<msgsnd>
3059
3060 Calls the System V IPC function msgsnd to send the message MSG to the
3061 message queue ID.  MSG must begin with the native long integer message
3062 type, and be followed by the length of the actual message, and finally
3063 the message itself.  This kind of packing can be achieved with
3064 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3065 or false if there is an error.  See also C<IPC::SysV>
3066 and C<IPC::SysV::Msg> documentation.
3067
3068 =item my EXPR
3069 X<my>
3070
3071 =item my TYPE EXPR
3072
3073 =item my EXPR : ATTRS
3074
3075 =item my TYPE EXPR : ATTRS
3076
3077 A C<my> declares the listed variables to be local (lexically) to the
3078 enclosing block, file, or C<eval>.  If more than one value is listed,
3079 the list must be placed in parentheses.
3080
3081 The exact semantics and interface of TYPE and ATTRS are still
3082 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3083 and attributes are handled using the C<attributes> pragma, or starting
3084 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3085 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3086 L<attributes>, and L<Attribute::Handlers>.
3087
3088 =item next LABEL
3089 X<next> X<continue>
3090
3091 =item next
3092
3093 The C<next> command is like the C<continue> statement in C; it starts
3094 the next iteration of the loop:
3095
3096     LINE: while (<STDIN>) {
3097         next LINE if /^#/;  # discard comments
3098         #...
3099     }
3100
3101 Note that if there were a C<continue> block on the above, it would get
3102 executed even on discarded lines.  If the LABEL is omitted, the command
3103 refers to the innermost enclosing loop.
3104
3105 C<next> cannot be used to exit a block which returns a value such as
3106 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3107 a grep() or map() operation.
3108
3109 Note that a block by itself is semantically identical to a loop
3110 that executes once.  Thus C<next> will exit such a block early.
3111
3112 See also L</continue> for an illustration of how C<last>, C<next>, and
3113 C<redo> work.
3114
3115 =item no Module VERSION LIST
3116 X<no>
3117
3118 =item no Module VERSION
3119
3120 =item no Module LIST
3121
3122 =item no Module
3123
3124 =item no VERSION
3125
3126 See the C<use> function, of which C<no> is the opposite.
3127
3128 =item oct EXPR
3129 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3130
3131 =item oct
3132
3133 Interprets EXPR as an octal string and returns the corresponding
3134 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3135 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3136 binary string.  Leading whitespace is ignored in all three cases.)
3137 The following will handle decimal, binary, octal, and hex in the standard
3138 Perl or C notation:
3139
3140     $val = oct($val) if $val =~ /^0/;
3141
3142 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3143 in octal), use sprintf() or printf():
3144
3145     $perms = (stat("filename"))[2] & 07777;
3146     $oct_perms = sprintf "%lo", $perms;
3147
3148 The oct() function is commonly used when a string such as C<644> needs
3149 to be converted into a file mode, for example. (Although perl will
3150 automatically convert strings into numbers as needed, this automatic
3151 conversion assumes base 10.)
3152
3153 =item open FILEHANDLE,EXPR
3154 X<open> X<pipe> X<file, open> X<fopen>
3155
3156 =item open FILEHANDLE,MODE,EXPR
3157
3158 =item open FILEHANDLE,MODE,EXPR,LIST
3159
3160 =item open FILEHANDLE,MODE,REFERENCE
3161
3162 =item open FILEHANDLE
3163
3164 Opens the file whose filename is given by EXPR, and associates it with
3165 FILEHANDLE.
3166
3167 Simple examples to open a file for reading:
3168
3169     open(my $fh, '<', "input.txt") or die $!;
3170
3171 and for writing:
3172
3173     open(my $fh, '>', "output.txt") or die $!;
3174
3175 (The following is a comprehensive reference to open(): for a gentler
3176 introduction you may consider L<perlopentut>.)
3177
3178 If FILEHANDLE is an undefined scalar variable (or array or hash element)
3179 the variable is assigned a reference to a new anonymous filehandle,
3180 otherwise if FILEHANDLE is an expression, its value is used as the name of
3181 the real filehandle wanted.  (This is considered a symbolic reference, so
3182 C<use strict 'refs'> should I<not> be in effect.)
3183
3184 If EXPR is omitted, the scalar variable of the same name as the
3185 FILEHANDLE contains the filename.  (Note that lexical variables--those
3186 declared with C<my>--will not work for this purpose; so if you're
3187 using C<my>, specify EXPR in your call to open.)
3188
3189 If three or more arguments are specified then the mode of opening and
3190 the file name are separate. If MODE is C<< '<' >> or nothing, the file
3191 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
3192 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
3193 the file is opened for appending, again being created if necessary.
3194
3195 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
3196 indicate that you want both read and write access to the file; thus
3197 C<< '+<' >> is almost always preferred for read/write updates--the C<<
3198 '+>' >> mode would clobber the file first.  You can't usually use
3199 either read-write mode for updating textfiles, since they have
3200 variable length records.  See the B<-i> switch in L<perlrun> for a
3201 better approach.  The file is created with permissions of C<0666>
3202 modified by the process's C<umask> value.
3203
3204 These various prefixes correspond to the fopen(3) modes of C<'r'>,
3205 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
3206
3207 In the 2-arguments (and 1-argument) form of the call the mode and
3208 filename should be concatenated (in this order), possibly separated by
3209 spaces.  It is possible to omit the mode in these forms if the mode is
3210 C<< '<' >>.
3211
3212 If the filename begins with C<'|'>, the filename is interpreted as a
3213 command to which output is to be piped, and if the filename ends with a
3214 C<'|'>, the filename is interpreted as a command that pipes output to
3215 us.  See L<perlipc/"Using open() for IPC">
3216 for more examples of this.  (You are not allowed to C<open> to a command
3217 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
3218 and L<perlipc/"Bidirectional Communication with Another Process">
3219 for alternatives.)
3220
3221 For three or more arguments if MODE is C<'|-'>, the filename is
3222 interpreted as a command to which output is to be piped, and if MODE
3223 is C<'-|'>, the filename is interpreted as a command that pipes
3224 output to us.  In the 2-arguments (and 1-argument) form one should
3225 replace dash (C<'-'>) with the command.
3226 See L<perlipc/"Using open() for IPC"> for more examples of this.
3227 (You are not allowed to C<open> to a command that pipes both in I<and>
3228 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3229 L<perlipc/"Bidirectional Communication"> for alternatives.)
3230
3231 In the three-or-more argument form of pipe opens, if LIST is specified
3232 (extra arguments after the command name) then LIST becomes arguments
3233 to the command invoked if the platform supports it.  The meaning of
3234 C<open> with more than three arguments for non-pipe modes is not yet
3235 specified. Experimental "layers" may give extra LIST arguments
3236 meaning.
3237
3238 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
3239 and opening C<< '>-' >> opens STDOUT.
3240
3241 You may use the three-argument form of open to specify IO "layers"
3242 (sometimes also referred to as "disciplines") to be applied to the handle
3243 that affect how the input and output are processed (see L<open> and
3244 L<PerlIO> for more details). For example
3245
3246   open(my $fh, "<:encoding(UTF-8)", "file")
3247
3248 will open the UTF-8 encoded file containing Unicode characters,
3249 see L<perluniintro>. Note that if layers are specified in the
3250 three-arg form then default layers stored in ${^OPEN} (see L<perlvar>;
3251 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3252
3253 Open returns nonzero on success, the undefined value otherwise.  If
3254 the C<open> involved a pipe, the return value happens to be the pid of
3255 the subprocess.
3256
3257 If you're running Perl on a system that distinguishes between text
3258 files and binary files, then you should check out L</binmode> for tips
3259 for dealing with this.  The key distinction between systems that need
3260 C<binmode> and those that don't is their text file formats.  Systems
3261 like Unix, Mac OS, and Plan 9, that end lines with a single
3262 character and encode that character in C as C<"\n"> do not
3263 need C<binmode>.  The rest need it.
3264
3265 When opening a file, it's seldom a good idea to continue 
3266 if the request failed, so C<open> is frequently used with
3267 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3268 where you want to format a suitable error message (but there are
3269 modules that can help with that problem)) always check
3270 the return value from opening a file.  
3271
3272 As a special case the 3-arg form with a read/write mode and the third
3273 argument being C<undef>:
3274
3275     open(my $tmp, "+>", undef) or die ...
3276
3277 opens a filehandle to an anonymous temporary file.  Also using "+<"
3278 works for symmetry, but you really should consider writing something
3279 to the temporary file first.  You will need to seek() to do the
3280 reading.
3281
3282 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
3283 changed this (i.e., Configure -Uuseperlio), you can open file handles to
3284 "in memory" files held in Perl scalars via:
3285
3286     open($fh, '>', \$variable) || ..
3287
3288 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
3289 file, you have to close it first:
3290
3291     close STDOUT;
3292     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3293
3294 Examples:
3295
3296     $ARTICLE = 100;
3297     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3298     while (<ARTICLE>) {...
3299
3300     open(LOG, '>>/usr/spool/news/twitlog');  # (log is reserved)
3301     # if the open fails, output is discarded
3302
3303     open(my $dbase, '+<', 'dbase.mine')      # open for update
3304         or die "Can't open 'dbase.mine' for update: $!";
3305
3306     open(my $dbase, '+<dbase.mine')          # ditto
3307         or die "Can't open 'dbase.mine' for update: $!";
3308
3309     open(ARTICLE, '-|', "caesar <$article")  # decrypt article
3310         or die "Can't start caesar: $!";
3311
3312     open(ARTICLE, "caesar <$article |")      # ditto
3313         or die "Can't start caesar: $!";
3314
3315     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3316         or die "Can't start sort: $!";
3317
3318     # in memory files
3319     open(MEMORY,'>', \$var)
3320         or die "Can't open memory file: $!";
3321     print MEMORY "foo!\n";                   # output will appear in $var
3322
3323     # process argument list of files along with any includes
3324
3325     foreach $file (@ARGV) {
3326         process($file, 'fh00');
3327     }
3328
3329     sub process {
3330         my($filename, $input) = @_;
3331         $input++;    # this is a string increment
3332         unless (open($input, $filename)) {
3333             print STDERR "Can't open $filename: $!\n";
3334             return;
3335         }
3336
3337         local $_;
3338         while (<$input>) {    # note use of indirection
3339             if (/^#include "(.*)"/) {
3340                 process($1, $input);
3341                 next;
3342             }
3343             #...          # whatever
3344         }
3345     }
3346
3347 See L<perliol> for detailed info on PerlIO.
3348
3349 You may also, in the Bourne shell tradition, specify an EXPR beginning
3350 with C<< '>&' >>, in which case the rest of the string is interpreted
3351 as the name of a filehandle (or file descriptor, if numeric) to be
3352 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3353 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3354 The mode you specify should match the mode of the original filehandle.
3355 (Duping a filehandle does not take into account any existing contents
3356 of IO buffers.) If you use the 3-arg form then you can pass either a
3357 number, the name of a filehandle or the normal "reference to a glob".
3358
3359 Here is a script that saves, redirects, and restores C<STDOUT> and
3360 C<STDERR> using various methods:
3361
3362     #!/usr/bin/perl
3363     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3364     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3365
3366     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3367     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3368
3369     select STDERR; $| = 1;  # make unbuffered
3370     select STDOUT; $| = 1;  # make unbuffered
3371
3372     print STDOUT "stdout 1\n";  # this works for
3373     print STDERR "stderr 1\n";  # subprocesses too
3374
3375     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3376     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3377
3378     print STDOUT "stdout 2\n";
3379     print STDERR "stderr 2\n";
3380
3381 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3382 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3383 that file descriptor (and not call C<dup(2)>); this is more
3384 parsimonious of file descriptors.  For example:
3385
3386     # open for input, reusing the fileno of $fd
3387     open(FILEHANDLE, "<&=$fd")
3388
3389 or
3390
3391     open(FILEHANDLE, "<&=", $fd)
3392
3393 or
3394
3395     # open for append, using the fileno of OLDFH
3396     open(FH, ">>&=", OLDFH)
3397
3398 or
3399
3400     open(FH, ">>&=OLDFH")
3401
3402 Being parsimonious on filehandles is also useful (besides being
3403 parsimonious) for example when something is dependent on file
3404 descriptors, like for example locking using flock().  If you do just
3405 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3406 descriptor as B, and therefore flock(A) will not flock(B), and vice
3407 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3408 the same file descriptor.
3409
3410 Note that if you are using Perls older than 5.8.0, Perl will be using
3411 the standard C libraries' fdopen() to implement the "=" functionality.
3412 On many Unix systems fdopen() fails when file descriptors exceed a
3413 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3414 most often the default.
3415
3416 You can see whether Perl has been compiled with PerlIO or not by
3417 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3418 is C<define>, you have PerlIO, otherwise you don't.
3419
3420 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3421 with 2-arguments (or 1-argument) form of open(), then
3422 there is an implicit fork done, and the return value of open is the pid
3423 of the child within the parent process, and C<0> within the child
3424 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3425 The filehandle behaves normally for the parent, but i/o to that
3426 filehandle is piped from/to the STDOUT/STDIN of the child process.
3427 In the child process the filehandle isn't opened--i/o happens from/to
3428 the new STDOUT or STDIN.  Typically this is used like the normal
3429 piped open when you want to exercise more control over just how the
3430 pipe command gets executed, such as when you are running setuid, and
3431 don't want to have to scan shell commands for metacharacters.
3432 The following triples are more or less equivalent:
3433
3434     open(FOO, "|tr '[a-z]' '[A-Z]'");
3435     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3436     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3437     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3438
3439     open(FOO, "cat -n '$file'|");
3440     open(FOO, '-|', "cat -n '$file'");
3441     open(FOO, '-|') || exec 'cat', '-n', $file;
3442     open(FOO, '-|', "cat", '-n', $file);
3443
3444 The last example in each block shows the pipe as "list form", which is
3445 not yet supported on all platforms.  A good rule of thumb is that if
3446 your platform has true C<fork()> (in other words, if your platform is
3447 Unix) you can use the list form.
3448
3449 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3450
3451 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3452 output before any operation that may do a fork, but this may not be
3453 supported on some platforms (see L<perlport>).  To be safe, you may need
3454 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3455 of C<IO::Handle> on any open handles.
3456
3457 On systems that support a close-on-exec flag on files, the flag will
3458 be set for the newly opened file descriptor as determined by the value
3459 of $^F.  See L<perlvar/$^F>.
3460
3461 Closing any piped filehandle causes the parent process to wait for the
3462 child to finish, and returns the status value in C<$?> and
3463 C<${^CHILD_ERROR_NATIVE}>.
3464
3465 The filename passed to 2-argument (or 1-argument) form of open() will
3466 have leading and trailing whitespace deleted, and the normal
3467 redirection characters honored.  This property, known as "magic open",
3468 can often be used to good effect.  A user could specify a filename of
3469 F<"rsh cat file |">, or you could change certain filenames as needed:
3470
3471     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3472     open(FH, $filename) or die "Can't open $filename: $!";
3473
3474 Use 3-argument form to open a file with arbitrary weird characters in it,
3475
3476     open(FOO, '<', $file);
3477
3478 otherwise it's necessary to protect any leading and trailing whitespace:
3479
3480     $file =~ s#^(\s)#./$1#;
3481     open(FOO, "< $file\0");
3482
3483 (this may not work on some bizarre filesystems).  One should
3484 conscientiously choose between the I<magic> and 3-arguments form
3485 of open():
3486
3487     open IN, $ARGV[0];
3488
3489 will allow the user to specify an argument of the form C<"rsh cat file |">,
3490 but will not work on a filename that happens to have a trailing space, while
3491
3492     open IN, '<', $ARGV[0];
3493
3494 will have exactly the opposite restrictions.
3495
3496 If you want a "real" C C<open> (see C<open(2)> on your system), then you
3497 should use the C<sysopen> function, which involves no such magic (but
3498 may use subtly different filemodes than Perl open(), which is mapped
3499 to C fopen()).  This is
3500 another way to protect your filenames from interpretation.  For example:
3501
3502     use IO::Handle;
3503     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3504         or die "sysopen $path: $!";
3505     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3506     print HANDLE "stuff $$\n";
3507     seek(HANDLE, 0, 0);
3508     print "File contains: ", <HANDLE>;
3509
3510 Using the constructor from the C<IO::Handle> package (or one of its
3511 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3512 filehandles that have the scope of whatever variables hold references to
3513 them, and automatically close whenever and however you leave that scope:
3514
3515     use IO::File;
3516     #...
3517     sub read_myfile_munged {
3518         my $ALL = shift;
3519         my $handle = IO::File->new;
3520         open($handle, "myfile") or die "myfile: $!";
3521         $first = <$handle>
3522             or return ();     # Automatically closed here.
3523         mung $first or die "mung failed";  # Or here.
3524         return $first, <$handle> if $ALL;  # Or here.
3525         $first;          # Or here.
3526     }
3527
3528 See L</seek> for some details about mixing reading and writing.
3529
3530 =item opendir DIRHANDLE,EXPR
3531 X<opendir>
3532
3533 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3534 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3535 DIRHANDLE may be an expression whose value can be used as an indirect
3536 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3537 scalar variable (or array or hash element), the variable is assigned a
3538 reference to a new anonymous dirhandle.
3539 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3540
3541 See example at C<readdir>.
3542
3543 =item ord EXPR
3544 X<ord> X<encoding>
3545
3546 =item ord
3547
3548 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3549 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3550 uses C<$_>.
3551
3552 For the reverse, see L</chr>.
3553 See L<perlunicode> for more about Unicode.
3554
3555 =item our EXPR
3556 X<our> X<global>
3557
3558 =item our TYPE EXPR
3559
3560 =item our EXPR : ATTRS
3561
3562 =item our TYPE EXPR : ATTRS
3563
3564 C<our> associates a simple name with a package variable in the current
3565 package for use within the current scope.  When C<use strict 'vars'> is in
3566 effect, C<our> lets you use declared global variables without qualifying
3567 them with package names, within the lexical scope of the C<our> declaration.
3568 In this way C<our> differs from C<use vars>, which is package scoped.
3569
3570 Unlike C<my>, which both allocates storage for a variable and associates
3571 a simple name with that storage for use within the current scope, C<our>
3572 associates a simple name with a package variable in the current package,
3573 for use within the current scope.  In other words, C<our> has the same
3574 scoping rules as C<my>, but does not necessarily create a
3575 variable.
3576
3577 If more than one value is listed, the list must be placed
3578 in parentheses.
3579
3580     our $foo;
3581     our($bar, $baz);
3582
3583 An C<our> declaration declares a global variable that will be visible
3584 across its entire lexical scope, even across package boundaries.  The
3585 package in which the variable is entered is determined at the point
3586 of the declaration, not at the point of use.  This means the following
3587 behavior holds:
3588
3589     package Foo;
3590     our $bar;      # declares $Foo::bar for rest of lexical scope
3591     $bar = 20;
3592
3593     package Bar;
3594     print $bar;    # prints 20, as it refers to $Foo::bar
3595
3596 Multiple C<our> declarations with the same name in the same lexical
3597 scope are allowed if they are in different packages.  If they happen
3598 to be in the same package, Perl will emit warnings if you have asked
3599 for them, just like multiple C<my> declarations.  Unlike a second
3600 C<my> declaration, which will bind the name to a fresh variable, a
3601 second C<our> declaration in the same package, in the same scope, is
3602 merely redundant.
3603
3604     use warnings;
3605     package Foo;
3606     our $bar;      # declares $Foo::bar for rest of lexical scope
3607     $bar = 20;
3608
3609     package Bar;
3610     our $bar = 30; # declares $Bar::bar for rest of lexical scope
3611     print $bar;    # prints 30
3612
3613     our $bar;      # emits warning but has no other effect
3614     print $bar;    # still prints 30
3615
3616 An C<our> declaration may also have a list of attributes associated
3617 with it.
3618
3619 The exact semantics and interface of TYPE and ATTRS are still
3620 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3621 and attributes are handled using the C<attributes> pragma, or starting
3622 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3623 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3624 L<attributes>, and L<Attribute::Handlers>.
3625
3626 =item pack TEMPLATE,LIST
3627 X<pack>
3628
3629 Takes a LIST of values and converts it into a string using the rules
3630 given by the TEMPLATE.  The resulting string is the concatenation of
3631 the converted values.  Typically, each converted value looks
3632 like its machine-level representation.  For example, on 32-bit machines
3633 an integer may be represented by a sequence of 4 bytes that will be 
3634 converted to a sequence of 4 characters.
3635
3636 See L<perlpacktut> for an introduction to this function.
3637
3638 The TEMPLATE is a sequence of characters that give the order and type
3639 of values, as follows:
3640
3641     a  A string with arbitrary binary data, will be null padded.
3642     A  A text (ASCII) string, will be space padded.
3643     Z  A null terminated (ASCIZ) string, will be null padded.
3644
3645     b  A bit string (ascending bit order inside each byte, like vec()).
3646     B  A bit string (descending bit order inside each byte).
3647     h  A hex string (low nybble first).
3648     H  A hex string (high nybble first).
3649
3650     c  A signed char (8-bit) value.
3651     C  An unsigned char (octet) value.
3652     W   An unsigned char value (can be greater than 255).
3653
3654     s  A signed short (16-bit) value.
3655     S  An unsigned short value.
3656
3657     l  A signed long (32-bit) value.
3658     L  An unsigned long value.
3659
3660     q  A signed quad (64-bit) value.
3661     Q  An unsigned quad value.
3662       (Quads are available only if your system supports 64-bit
3663        integer values _and_ if Perl has been compiled to support those.
3664            Causes a fatal error otherwise.)
3665
3666     i  A signed integer value.
3667     I  A unsigned integer value.
3668       (This 'integer' is _at_least_ 32 bits wide.  Its exact
3669            size depends on what a local C compiler calls 'int'.)
3670
3671     n  An unsigned short (16-bit) in "network" (big-endian) order.
3672     N  An unsigned long (32-bit) in "network" (big-endian) order.
3673     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
3674     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
3675
3676     j   A Perl internal signed integer value (IV).
3677     J   A Perl internal unsigned integer value (UV).
3678
3679     f  A single-precision float in the native format.
3680     d  A double-precision float in the native format.
3681
3682     F  A Perl internal floating point value (NV) in the native format
3683     D  A long double-precision float in the native format.
3684       (Long doubles are available only if your system supports long
3685        double values _and_ if Perl has been compiled to support those.
3686            Causes a fatal error otherwise.)
3687
3688     p  A pointer to a null-terminated string.
3689     P  A pointer to a structure (fixed-length string).
3690
3691     u  A uuencoded string.
3692     U  A Unicode character number.  Encodes to a character in character mode
3693         and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in byte mode.
3694
3695     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3696     details).  Its bytes represent an unsigned integer in base 128,
3697     most significant digit first, with as few digits as possible.  Bit
3698     eight (the high bit) is set on each byte except the last.
3699
3700     x  A null byte.
3701     X  Back up a byte.
3702     @  Null fill or truncate to absolute position, counted from the
3703         start of the innermost ()-group.
3704     .   Null fill or truncate to absolute position specified by value.
3705     (  Start of a ()-group.
3706
3707 One or more of the modifiers below may optionally follow some letters in the
3708 TEMPLATE (the second column lists the letters for which the modifier is
3709 valid):
3710
3711     !   sSlLiI     Forces native (short, long, int) sizes instead
3712                    of fixed (16-/32-bit) sizes.
3713
3714         xX         Make x and X act as alignment commands.
3715
3716         nNvV       Treat integers as signed instead of unsigned.
3717
3718         @.         Specify position as byte offset in the internal
3719                    representation of the packed string. Efficient but
3720                    dangerous.
3721
3722     >   sSiIlLqQ   Force big-endian byte-order on the type.
3723         jJfFdDpP   (The "big end" touches the construct.)
3724
3725     <   sSiIlLqQ   Force little-endian byte-order on the type.
3726         jJfFdDpP   (The "little end" touches the construct.)
3727
3728 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3729 in which case they force a certain byte-order on all components of
3730 that group, including subgroups.
3731
3732 The following rules apply:
3733
3734 =over 8
3735
3736 =item *
3737
3738 Each letter may optionally be followed by a number giving a repeat
3739 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3740 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3741 that many values from the LIST.  A C<*> for the repeat count means to
3742 use however many items are left, except for C<@>, C<x>, C<X>, where it
3743 is equivalent to C<0>, for <.> where it means relative to string start
3744 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3745 A numeric repeat count may optionally be enclosed in brackets, as in
3746 C<pack 'C[80]', @arr>.
3747
3748 One can replace the numeric repeat count by a template enclosed in brackets;
3749 then the packed length of this template in bytes is used as a count.
3750 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3751 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3752 If the template in brackets contains alignment commands (such as C<x![d]>),
3753 its packed length is calculated as if the start of the template has the maximal
3754 possible alignment.
3755
3756 When used with C<Z>, C<*> results in the addition of a trailing null
3757 byte (so the packed result will be one longer than the byte C<length>
3758 of the item).
3759
3760 When used with C<@>, the repeat count represents an offset from the start
3761 of the innermost () group.
3762
3763 When used with C<.>, the repeat count is used to determine the starting
3764 position from where the value offset is calculated. If the repeat count
3765 is 0, it's relative to the current position. If the repeat count is C<*>,
3766 the offset is relative to the start of the packed string. And if its an
3767 integer C<n> the offset is relative to the start of the n-th innermost
3768 () group (or the start of the string if C<n> is bigger then the group
3769 level).
3770
3771 The repeat count for C<u> is interpreted as the maximal number of bytes
3772 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3773 count should not be more than 65.
3774
3775 =item *
3776
3777 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3778 string of length count, padding with nulls or spaces as necessary.  When
3779 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3780 after the first null, and C<a> returns data verbatim.
3781
3782 If the value-to-pack is too long, it is truncated.  If too long and an
3783 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3784 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3785 count is 0).
3786
3787 =item *
3788
3789 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3790 Each character of the input field of pack() generates 1 bit of the result.
3791 Each result bit is based on the least-significant bit of the corresponding
3792 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3793 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3794
3795 Starting from the beginning of the input string of pack(), each 8-tuple
3796 of characters is converted to 1 character of output.  With format C<b>
3797 the first character of the 8-tuple determines the least-significant bit of a
3798 character, and with format C<B> it determines the most-significant bit of
3799 a character.
3800
3801 If the length of the input string is not exactly divisible by 8, the
3802 remainder is packed as if the input string were padded by null characters
3803 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3804
3805 If the input string of pack() is longer than needed, extra characters are 
3806 ignored. A C<*> for the repeat count of pack() means to use all the 
3807 characters of the input field.  On unpack()ing the bits are converted to a 
3808 string of C<"0">s and C<"1">s.
3809
3810 =item *
3811
3812 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3813 representable as hexadecimal digits, 0-9a-f) long.
3814
3815 Each character of the input field of pack() generates 4 bits of the result.
3816 For non-alphabetical characters the result is based on the 4 least-significant
3817 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3818 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3819 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3820 is compatible with the usual hexadecimal digits, so that C<"a"> and
3821 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3822 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3823
3824 Starting from the beginning of the input string of pack(), each pair
3825 of characters is converted to 1 character of output.  With format C<h> the
3826 first character of the pair determines the least-significant nybble of the
3827 output character, and with format C<H> it determines the most-significant
3828 nybble.
3829
3830 If the length of the input string is not even, it behaves as if padded
3831 by a null character at the end.  Similarly, during unpack()ing the "extra"
3832 nybbles are ignored.
3833
3834 If the input string of pack() is longer than needed, extra characters are
3835 ignored.
3836 A C<*> for the repeat count of pack() means to use all the characters of
3837 the input field.  On unpack()ing the nybbles are converted to a string
3838 of hexadecimal digits.
3839
3840 =item *
3841
3842 The C<p> type packs a pointer to a null-terminated string.  You are
3843 responsible for ensuring the string is not a temporary value (which can
3844 potentially get deallocated before you get around to using the packed result).
3845 The C<P> type packs a pointer to a structure of the size indicated by the
3846 length.  A NULL pointer is created if the corresponding value for C<p> or
3847 C<P> is C<undef>, similarly for unpack().
3848
3849 If your system has a strange pointer size (i.e., a pointer is neither as
3850 big as an int nor as big as a long), it may not be possible to pack or
3851 unpack pointers in big- or little-endian byte order.  Attempting to do
3852 so will result in a fatal error.
3853
3854 =item *
3855
3856 The C</> template character allows packing and unpacking of a sequence of
3857 items where the packed structure contains a packed item count followed by 
3858 the packed items themselves.
3859
3860 For C<pack> you write I<length-item>C</>I<sequence-item> and the
3861 I<length-item> describes how the length value is packed. The ones likely
3862 to be of most use are integer-packing ones like C<n> (for Java strings),
3863 C<w> (for ASN.1 or SNMP) and C<N> (for Sun XDR).
3864
3865 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3866 the minimum of that and the number of available items is used as argument
3867 for the I<length-item>. If it has no repeat count or uses a '*', the number
3868 of available items is used.
3869
3870 For C<unpack> an internal stack of integer arguments unpacked so far is
3871 used. You write C</>I<sequence-item> and the repeat count is obtained by
3872 popping off the last element from the stack. The I<sequence-item> must not
3873 have a repeat count.
3874
3875 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3876 the I<length-item> is the string length, not the number of strings. If there is
3877 an explicit repeat count for pack, the packed string will be adjusted to that length.
3878
3879     unpack 'W/a', "\04Gurusamy";            gives ('Guru')
3880     unpack 'a3/A A*', '007 Bond  J ';       gives (' Bond', 'J')
3881     unpack 'a3 x2 /A A*', '007: Bond, J.';  gives ('Bond, J', '.')
3882     pack 'n/a* w/a','hello,','world';       gives "\000\006hello,\005world"
3883     pack 'a/W2', ord('a') .. ord('z');      gives '2ab'
3884
3885 The I<length-item> is not returned explicitly from C<unpack>.
3886
3887 Adding a count to the I<length-item> letter is unlikely to do anything
3888 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3889 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3890 which Perl does not regard as legal in numeric strings.
3891
3892 =item *
3893
3894 The integer types C<s>, C<S>, C<l>, and C<L> may be
3895 followed by a C<!> modifier to signify native shorts or
3896 longs--as you can see from above for example a bare C<l> does mean
3897 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3898 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3899 see whether using C<!> makes any difference by
3900
3901     print length(pack("s")), " ", length(pack("s!")), "\n";
3902     print length(pack("l")), " ", length(pack("l!")), "\n";
3903
3904 C<i!> and C<I!> also work but only because of completeness;
3905 they are identical to C<i> and C<I>.
3906
3907 The actual sizes (in bytes) of native shorts, ints, longs, and long
3908 longs on the platform where Perl was built are also available via
3909 L<Config>:
3910
3911        use Config;
3912        print $Config{shortsize},    "\n";
3913        print $Config{intsize},      "\n";
3914        print $Config{longsize},     "\n";
3915        print $Config{longlongsize}, "\n";
3916
3917 (The C<$Config{longlongsize}> will be undefined if your system does
3918 not support long longs.)
3919
3920 =item *
3921
3922 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3923 are inherently non-portable between processors and operating systems
3924 because they obey the native byteorder and endianness.  For example a
3925 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3926 (arranged in and handled by the CPU registers) into bytes as
3927
3928     0x12 0x34 0x56 0x78  # big-endian
3929     0x78 0x56 0x34 0x12  # little-endian
3930
3931 Basically, the Intel and VAX CPUs are little-endian, while everybody
3932 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3933 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3934 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3935 mode.
3936
3937 The names `big-endian' and `little-endian' are comic references to
3938 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3939 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3940 the egg-eating habits of the Lilliputians.
3941
3942 Some systems may have even weirder byte orders such as
3943
3944    0x56 0x78 0x12 0x34
3945    0x34 0x12 0x78 0x56
3946
3947 You can see your system's preference with
3948
3949    print join(" ", map { sprintf "%#02x", $_ }
3950                             unpack("W*",pack("L",0x12345678))), "\n";
3951
3952 The byteorder on the platform where Perl was built is also available
3953 via L<Config>:
3954
3955     use Config;
3956     print $Config{byteorder}, "\n";
3957
3958 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3959 and C<'87654321'> are big-endian.
3960
3961 If you want portable packed integers you can either use the formats
3962 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3963 modifiers.  These modifiers are only available as of perl 5.9.2.
3964 See also L<perlport>.
3965
3966 =item *
3967
3968 All integer and floating point formats as well as C<p> and C<P> and
3969 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3970 to force big- or little- endian byte-order, respectively.
3971 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3972 signed integers, 64-bit integers and floating point values.  However,
3973 there are some things to keep in mind.
3974
3975 Exchanging signed integers between different platforms only works
3976 if all platforms store them in the same format.  Most platforms store
3977 signed integers in two's complement, so usually this is not an issue.
3978
3979 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3980 formats on big- or little-endian machines.  Otherwise, attempting to
3981 do so will result in a fatal error.
3982
3983 Forcing big- or little-endian byte-order on floating point values for
3984 data exchange can only work if all platforms are using the same
3985 binary representation (e.g. IEEE floating point format).  Even if all
3986 platforms are using IEEE, there may be subtle differences.  Being able
3987 to use C<E<gt>> or C<E<lt>> on floating point values can be useful,
3988 but also dangerous if you don't know exactly what you're doing.
3989 It is not a general way to portably store floating point values.
3990
3991 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3992 all types inside the group that accept the byte-order modifiers,
3993 including all subgroups.  It will silently be ignored for all other
3994 types.  You are not allowed to override the byte-order within a group
3995 that already has a byte-order modifier suffix.
3996
3997 =item *
3998
3999 Real numbers (floats and doubles) are in the native machine format only;
4000 due to the multiplicity of floating formats around, and the lack of a
4001 standard "network" representation, no facility for interchange has been
4002 made.  This means that packed floating point data written on one machine
4003 may not be readable on another - even if both use IEEE floating point
4004 arithmetic (as the endian-ness of the memory representation is not part
4005 of the IEEE spec).  See also L<perlport>.
4006
4007 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
4008 modifiers to force big- or little-endian byte-order on floating point values.
4009
4010 Note that Perl uses doubles (or long doubles, if configured) internally for
4011 all numeric calculation, and converting from double into float and thence back
4012 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
4013 will not in general equal $foo).
4014
4015 =item *
4016
4017 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
4018 the packed string is processed per character and UTF-8 mode (C<U0> mode)
4019 where the packed string is processed in its UTF-8-encoded Unicode form on
4020 a byte by byte basis. Character mode is the default unless the format string 
4021 starts with an C<U>. You can switch mode at any moment with an explicit 
4022 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
4023 or until the end of the ()-group in which it was entered.
4024
4025 =item *
4026
4027 You must yourself do any alignment or padding by inserting for example
4028 enough C<'x'>es while packing.  There is no way to pack() and unpack()
4029 could know where the characters are going to or coming from.  Therefore
4030 C<pack> (and C<unpack>) handle their output and input as flat
4031 sequences of characters.
4032
4033 =item *
4034
4035 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
4036 take a repeat count, both as postfix, and for unpack() also via the C</>
4037 template character. Within each repetition of a group, positioning with
4038 C<@> starts again at 0. Therefore, the result of
4039
4040     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
4041
4042 is the string "\0a\0\0bc".
4043
4044 =item *
4045
4046 C<x> and C<X> accept C<!> modifier.  In this case they act as
4047 alignment commands: they jump forward/back to the closest position
4048 aligned at a multiple of C<count> characters. For example, to pack() or
4049 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
4050 use the template C<W x![d] d W[2]>; this assumes that doubles must be
4051 aligned on the double's size.
4052
4053 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
4054 both result in no-ops.
4055
4056 =item *
4057
4058 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
4059 will represent signed 16-/32-bit integers in big-/little-endian order.
4060 This is only portable if all platforms sharing the packed data use the
4061 same binary representation for signed integers (e.g. all platforms are
4062 using two's complement representation).
4063
4064 =item *
4065
4066 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
4067 White space may be used to separate pack codes from each other, but
4068 modifiers and a repeat count must follow immediately.
4069
4070 =item *
4071
4072 If TEMPLATE requires more arguments to pack() than actually given, pack()
4073 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4074 to pack() than actually given, extra arguments are ignored.
4075
4076 =back
4077
4078 Examples:
4079
4080     $foo = pack("WWWW",65,66,67,68);
4081     # foo eq "ABCD"
4082     $foo = pack("W4",65,66,67,68);
4083     # same thing
4084     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4085     # same thing with Unicode circled letters.
4086     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4087     # same thing with Unicode circled letters. You don't get the UTF-8
4088     # bytes because the U at the start of the format caused a switch to
4089     # U0-mode, so the UTF-8 bytes get joined into characters
4090     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4091     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4092     # This is the UTF-8 encoding of the string in the previous example
4093
4094     $foo = pack("ccxxcc",65,66,67,68);
4095     # foo eq "AB\0\0CD"
4096
4097     # note: the above examples featuring "W" and "c" are true
4098     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4099     # and UTF-8.  In EBCDIC the first example would be
4100     # $foo = pack("WWWW",193,194,195,196);
4101
4102     $foo = pack("s2",1,2);
4103     # "\1\0\2\0" on little-endian
4104     # "\0\1\0\2" on big-endian
4105
4106     $foo = pack("a4","abcd","x","y","z");
4107     # "abcd"
4108
4109     $foo = pack("aaaa","abcd","x","y","z");
4110     # "axyz"
4111
4112     $foo = pack("a14","abcdefg");
4113     # "abcdefg\0\0\0\0\0\0\0"
4114
4115     $foo = pack("i9pl", gmtime);
4116     # a real struct tm (on my system anyway)
4117
4118     $utmp_template = "Z8 Z8 Z16 L";
4119     $utmp = pack($utmp_template, @utmp1);
4120     # a struct utmp (BSDish)
4121
4122     @utmp2 = unpack($utmp_template, $utmp);
4123     # "@utmp1" eq "@utmp2"
4124
4125     sub bintodec {
4126         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4127     }
4128
4129     $foo = pack('sx2l', 12, 34);
4130     # short 12, two zero bytes padding, long 34
4131     $bar = pack('s@4l', 12, 34);
4132     # short 12, zero fill to position 4, long 34
4133     # $foo eq $bar
4134     $baz = pack('s.l', 12, 4, 34);
4135     # short 12, zero fill to position 4, long 34
4136
4137     $foo = pack('nN', 42, 4711);
4138     # pack big-endian 16- and 32-bit unsigned integers
4139     $foo = pack('S>L>', 42, 4711);
4140     # exactly the same
4141     $foo = pack('s<l<', -42, 4711);
4142     # pack little-endian 16- and 32-bit signed integers
4143     $foo = pack('(sl)<', -42, 4711);
4144     # exactly the same
4145
4146 The same template may generally also be used in unpack().
4147
4148 =item package NAMESPACE VERSION
4149 X<package> X<module> X<namespace> X<version>
4150
4151 =item package NAMESPACE
4152
4153 Declares the compilation unit as being in the given namespace.  The scope
4154 of the package declaration is from the declaration itself through the end
4155 of the enclosing block, file, or eval (the same as the C<my> operator).
4156 All further unqualified dynamic identifiers will be in this namespace.
4157 A package statement affects only dynamic variables--including those
4158 you've used C<local> on--but I<not> lexical variables, which are created
4159 with C<my>.  Typically it would be the first declaration in a file to
4160 be included by the C<require> or C<use> operator.  You can switch into a
4161 package in more than one place; it merely influences which symbol table
4162 is used by the compiler for the rest of that block.  You can refer to
4163 variables and filehandles in other packages by prefixing the identifier
4164 with the package name and a double colon:  C<$Package::Variable>.
4165 If the package name is null, the C<main> package as assumed.  That is,
4166 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
4167 still seen in older code).
4168
4169 If VERSION is provided, C<package> also sets the C<$VERSION> variable in the
4170 given namespace.  VERSION must be a numeric literal or v-string; it is
4171 parsed exactly the same way as a VERSION argument to C<use MODULE VERSION>.
4172 C<$VERSION> should only be set once per package.
4173
4174 See L<perlmod/"Packages"> for more information about packages, modules,
4175 and classes.  See L<perlsub> for other scoping issues.
4176
4177 =item pipe READHANDLE,WRITEHANDLE
4178 X<pipe>
4179
4180 Opens a pair of connected pipes like the corresponding system call.
4181 Note that if you set up a loop of piped processes, deadlock can occur
4182 unless you are very careful.  In addition, note that Perl's pipes use
4183 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4184 after each command, depending on the application.
4185
4186 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
4187 for examples of such things.
4188
4189 On systems that support a close-on-exec flag on files, the flag will be set
4190 for the newly opened file descriptors as determined by the value of $^F.
4191 See L<perlvar/$^F>.
4192
4193 =item pop ARRAY
4194 X<pop> X<stack>
4195
4196 =item pop
4197
4198 Pops and returns the last value of the array, shortening the array by
4199 one element.
4200
4201 If there are no elements in the array, returns the undefined value
4202 (although this may happen at other times as well).  If ARRAY is
4203 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
4204 array in subroutines, just like C<shift>.
4205
4206 =item pos SCALAR
4207 X<pos> X<match, position>
4208
4209 =item pos
4210
4211 Returns the offset of where the last C<m//g> search left off for the variable
4212 in question (C<$_> is used when the variable is not specified).  Note that
4213 0 is a valid match offset.  C<undef> indicates that the search position
4214 is reset (usually due to match failure, but can also be because no match has
4215 yet been run on the scalar). C<pos> directly accesses the location used
4216 by the regexp engine to store the offset, so assigning to C<pos> will change
4217 that offset, and so will also influence the C<\G> zero-width assertion in
4218 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
4219 the return from C<pos> won't change either in this case.  See L<perlre> and
4220 L<perlop>.
4221
4222 =item print FILEHANDLE LIST
4223 X<print>
4224
4225 =item print LIST
4226
4227 =item print
4228
4229 Prints a string or a list of strings.  Returns true if successful.
4230 FILEHANDLE may be a scalar variable name, in which case the variable
4231 contains the name of or a reference to the filehandle, thus introducing
4232 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
4233 the next token is a term, it may be misinterpreted as an operator
4234 unless you interpose a C<+> or put parentheses around the arguments.)
4235 If FILEHANDLE is omitted, prints by default to standard output (or
4236 to the last selected output channel--see L</select>).  If LIST is
4237 also omitted, prints C<$_> to the currently selected output channel.
4238 To set the default output channel to something other than STDOUT
4239 use the select operation.  The current value of C<$,> (if any) is
4240 printed between each LIST item.  The current value of C<$\> (if
4241 any) is printed after the entire LIST has been printed.  Because
4242 print takes a LIST, anything in the LIST is evaluated in list
4243 context, and any subroutine that you call will have one or more of
4244 its expressions evaluated in list context.  Also be careful not to
4245 follow the print keyword with a left parenthesis unless you want
4246 the corresponding right parenthesis to terminate the arguments to
4247 the print--interpose a C<+> or put parentheses around all the
4248 arguments.
4249
4250 Note that if you're storing FILEHANDLEs in an array, or if you're using
4251 any other expression more complex than a scalar variable to retrieve it,
4252 you will have to use a block returning the filehandle value instead:
4253
4254     print { $files[$i] } "stuff\n";
4255     print { $OK ? STDOUT : STDERR } "stuff\n";
4256
4257 Printing to a closed pipe or socket will generate a SIGPIPE signal.  See
4258 L<perlipc> for more on signal handling.
4259
4260 =item printf FILEHANDLE FORMAT, LIST
4261 X<printf>
4262
4263 =item printf FORMAT, LIST
4264
4265 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4266 (the output record separator) is not appended.  The first argument
4267 of the list will be interpreted as the C<printf> format. See C<sprintf>
4268 for an explanation of the format argument.  If C<use locale> is in effect,
4269 and POSIX::setlocale() has been called, the character used for the decimal
4270 separator in formatted floating point numbers is affected by the LC_NUMERIC
4271 locale.  See L<perllocale> and L<POSIX>.
4272
4273 Don't fall into the trap of using a C<printf> when a simple
4274 C<print> would do.  The C<print> is more efficient and less
4275 error prone.
4276
4277 =item prototype FUNCTION
4278 X<prototype>
4279
4280 Returns the prototype of a function as a string (or C<undef> if the
4281 function has no prototype).  FUNCTION is a reference to, or the name of,
4282 the function whose prototype you want to retrieve.
4283
4284 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4285 name for a Perl builtin.  If the builtin is not I<overridable> (such as
4286 C<qw//>) or if its arguments cannot be adequately expressed by a prototype
4287 (such as C<system>), prototype() returns C<undef>, because the builtin
4288 does not really behave like a Perl function.  Otherwise, the string
4289 describing the equivalent prototype is returned.
4290
4291 =item push ARRAY,LIST
4292 X<push> X<stack>
4293
4294 Treats ARRAY as a stack, and pushes the values of LIST
4295 onto the end of ARRAY.  The length of ARRAY increases by the length of
4296 LIST.  Has the same effect as
4297
4298     for $value (LIST) {
4299         $ARRAY[++$#ARRAY] = $value;
4300     }
4301
4302 but is more efficient.  Returns the number of elements in the array following
4303 the completed C<push>.
4304
4305 =item q/STRING/
4306
4307 =item qq/STRING/
4308
4309 =item qx/STRING/
4310
4311 =item qw/STRING/
4312
4313 Generalized quotes.  See L<perlop/"Quote-Like Operators">.
4314
4315 =item qr/STRING/
4316
4317 Regexp-like quote.  See L<perlop/"Regexp Quote-Like Operators">.
4318
4319 =item quotemeta EXPR
4320 X<quotemeta> X<metacharacter>
4321
4322 =item quotemeta
4323
4324 Returns the value of EXPR with all non-"word"
4325 characters backslashed.  (That is, all characters not matching
4326 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4327 returned string, regardless of any locale settings.)
4328 This is the internal function implementing
4329 the C<\Q> escape in double-quoted strings.
4330
4331 If EXPR is omitted, uses C<$_>.
4332
4333 quotemeta (and C<\Q> ... C<\E>) are useful when interpolating strings into
4334 regular expressions, because by default an interpolated variable will be
4335 considered a mini-regular expression. For example:
4336
4337     my $sentence = 'The quick brown fox jumped over the lazy dog';
4338     my $substring = 'quick.*?fox';
4339     $sentence =~ s{$substring}{big bad wolf};
4340
4341 Will cause C<$sentence> to become C<'The big bad wolf jumped over...'>.
4342
4343 On the other hand:
4344
4345     my $sentence = 'The quick brown fox jumped over the lazy dog';
4346     my $substring = 'quick.*?fox';
4347     $sentence =~ s{\Q$substring\E}{big bad wolf};
4348
4349 Or:
4350
4351     my $sentence = 'The quick brown fox jumped over the lazy dog';
4352     my $substring = 'quick.*?fox';
4353     my $quoted_substring = quotemeta($substring);
4354     $sentence =~ s{$quoted_substring}{big bad wolf};
4355
4356 Will both leave the sentence as is. Normally, when accepting string input from
4357 the user, quotemeta() or C<\Q> must be used.
4358
4359 =item rand EXPR
4360 X<rand> X<random>
4361
4362 =item rand
4363
4364 Returns a random fractional number greater than or equal to C<0> and less
4365 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4366 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4367 also special-cased as C<1> - this has not been documented before perl 5.8.0
4368 and is subject to change in future versions of perl.  Automatically calls
4369 C<srand> unless C<srand> has already been called.  See also C<srand>.
4370
4371 Apply C<int()> to the value returned by C<rand()> if you want random
4372 integers instead of random fractional numbers.  For example,
4373
4374     int(rand(10))
4375
4376 returns a random integer between C<0> and C<9>, inclusive.
4377
4378 (Note: If your rand function consistently returns numbers that are too
4379 large or too small, then your version of Perl was probably compiled
4380 with the wrong number of RANDBITS.)
4381
4382 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4383 X<read> X<file, read>
4384
4385 =item read FILEHANDLE,SCALAR,LENGTH
4386
4387 Attempts to read LENGTH I<characters> of data into variable SCALAR
4388 from the specified FILEHANDLE.  Returns the number of characters
4389 actually read, C<0> at end of file, or undef if there was an error (in
4390 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4391 so that the last character actually read is the last character of the
4392 scalar after the read.
4393
4394 An OFFSET may be specified to place the read data at some place in the
4395 string other than the beginning.  A negative OFFSET specifies
4396 placement at that many characters counting backwards from the end of
4397 the string.  A positive OFFSET greater than the length of SCALAR
4398 results in the string being padded to the required size with C<"\0">
4399 bytes before the result of the read is appended.
4400
4401 The call is implemented in terms of either Perl's or your system's native
4402 fread(3) library function.  To get a true read(2) system call, see C<sysread>.
4403
4404 Note the I<characters>: depending on the status of the filehandle,
4405 either (8-bit) bytes or characters are read.  By default all
4406 filehandles operate on bytes, but for example if the filehandle has
4407 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4408 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4409 characters, not bytes.  Similarly for the C<:encoding> pragma:
4410 in that case pretty much any characters can be read.
4411
4412 =item readdir DIRHANDLE
4413 X<readdir>
4414
4415 Returns the next directory entry for a directory opened by C<opendir>.
4416 If used in list context, returns all the rest of the entries in the
4417 directory.  If there are no more entries, returns an undefined value in
4418 scalar context or a null list in list context.
4419
4420 If you're planning to filetest the return values out of a C<readdir>, you'd
4421 better prepend the directory in question.  Otherwise, because we didn't
4422 C<chdir> there, it would have been testing the wrong file.
4423
4424     opendir(my $dh, $some_dir) || die "can't opendir $some_dir: $!";
4425     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir($dh);
4426     closedir $dh;
4427
4428 As of Perl 5.11.2 you can use a bare C<readdir> in a C<while> loop,
4429 which will set C<$_> on every iteration.
4430
4431     opendir(my $dh, $some_dir) || die;
4432     while(readdir $dh) {
4433         print "$some_dir/$_\n";
4434     }
4435     closedir $dh;
4436
4437 =item readline EXPR
4438
4439 =item readline
4440 X<readline> X<gets> X<fgets>
4441
4442 Reads from the filehandle whose typeglob is contained in EXPR (or from
4443 *ARGV if EXPR is not provided).  In scalar context, each call reads and
4444 returns the next line until end-of-file is reached, whereupon the
4445 subsequent call returns C<undef>.  In list context, reads until end-of-file
4446 is reached and returns a list of lines.  Note that the notion of "line"
4447 used here is whatever you may have defined with C<$/> or
4448 C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4449
4450 When C<$/> is set to C<undef>, when C<readline> is in scalar
4451 context (i.e., file slurp mode), and when an empty file is read, it
4452 returns C<''> the first time, followed by C<undef> subsequently.
4453
4454 This is the internal function implementing the C<< <EXPR> >>
4455 operator, but you can use it directly.  The C<< <EXPR> >>
4456 operator is discussed in more detail in L<perlop/"I/O Operators">.
4457
4458     $line = <STDIN>;
4459     $line = readline(*STDIN);    # same thing
4460
4461 If C<readline> encounters an operating system error, C<$!> will be set
4462 with the corresponding error message.  It can be helpful to check
4463 C<$!> when you are reading from filehandles you don't trust, such as a
4464 tty or a socket.  The following example uses the operator form of
4465 C<readline> and dies if the result is not defined.
4466
4467     while ( ! eof($fh) ) {
4468         defined( $_ = <$fh> ) or die "readline failed: $!";
4469         ...
4470     }
4471
4472 Note that you have can't handle C<readline> errors that way with the
4473 C<ARGV> filehandle. In that case, you have to open each element of
4474 C<@ARGV> yourself since C<eof> handles C<ARGV> differently.
4475
4476     foreach my $arg (@ARGV) {
4477         open(my $fh, $arg) or warn "Can't open $arg: $!";
4478
4479         while ( ! eof($fh) ) {
4480             defined( $_ = <$fh> )
4481                 or die "readline failed for $arg: $!";
4482             ...
4483         }
4484     }
4485
4486 =item readlink EXPR
4487 X<readlink>
4488
4489 =item readlink
4490
4491 Returns the value of a symbolic link, if symbolic links are
4492 implemented.  If not, gives a fatal error.  If there is some system
4493 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4494 omitted, uses C<$_>.
4495
4496 =item readpipe EXPR
4497
4498 =item readpipe
4499 X<readpipe>
4500
4501 EXPR is executed as a system command.
4502 The collected standard output of the command is returned.
4503 In scalar context, it comes back as a single (potentially
4504 multi-line) string.  In list context, returns a list of lines
4505 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4506 This is the internal function implementing the C<qx/EXPR/>
4507 operator, but you can use it directly.  The C<qx/EXPR/>
4508 operator is discussed in more detail in L<perlop/"I/O Operators">.
4509 If EXPR is omitted, uses C<$_>.
4510
4511 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4512 X<recv>
4513
4514 Receives a message on a socket.  Attempts to receive LENGTH characters
4515 of data into variable SCALAR from the specified SOCKET filehandle.
4516 SCALAR will be grown or shrunk to the length actually read.  Takes the
4517 same flags as the system call of the same name.  Returns the address
4518 of the sender if SOCKET's protocol supports this; returns an empty
4519 string otherwise.  If there's an error, returns the undefined value.
4520 This call is actually implemented in terms of recvfrom(2) system call.
4521 See L<perlipc/"UDP: Message Passing"> for examples.
4522
4523 Note the I<characters>: depending on the status of the socket, either
4524 (8-bit) bytes or characters are received.  By default all sockets
4525 operate on bytes, but for example if the socket has been changed using
4526 binmode() to operate with the C<:encoding(utf8)> I/O layer (see the
4527 C<open> pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4528 characters, not bytes.  Similarly for the C<:encoding> pragma: in that
4529 case pretty much any characters can be read.
4530
4531 =item redo LABEL
4532 X<redo>
4533
4534 =item redo
4535
4536 The C<redo> command restarts the loop block without evaluating the
4537 conditional again.  The C<continue> block, if any, is not executed.  If
4538 the LABEL is omitted, the command refers to the innermost enclosing
4539 loop.  Programs that want to lie to themselves about what was just input 
4540 normally use this command:
4541
4542     # a simpleminded Pascal comment stripper
4543     # (warning: assumes no { or } in strings)
4544     LINE: while (<STDIN>) {
4545         while (s|({.*}.*){.*}|$1 |) {}
4546         s|{.*}| |;
4547         if (s|{.*| |) {
4548             $front = $_;
4549             while (<STDIN>) {
4550                 if (/}/) {  # end of comment?
4551                     s|^|$front\{|;
4552                     redo LINE;
4553                 }
4554             }
4555         }
4556         print;
4557     }
4558
4559 C<redo> cannot be used to retry a block that returns a value such as
4560 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4561 a grep() or map() operation.
4562
4563 Note that a block by itself is semantically identical to a loop
4564 that executes once.  Thus C<redo> inside such a block will effectively
4565 turn it into a looping construct.
4566
4567 See also L</continue> for an illustration of how C<last>, C<next>, and
4568 C<redo> work.
4569
4570 =item ref EXPR
4571 X<ref> X<reference>
4572
4573 =item ref
4574
4575 Returns a non-empty string if EXPR is a reference, the empty
4576 string otherwise. If EXPR
4577 is not specified, C<$_> will be used.  The value returned depends on the
4578 type of thing the reference is a reference to.
4579 Builtin types include:
4580
4581     SCALAR
4582     ARRAY
4583     HASH
4584     CODE
4585     REF
4586     GLOB
4587     LVALUE
4588     FORMAT
4589     IO
4590     VSTRING
4591     Regexp
4592
4593 If the referenced object has been blessed into a package, then that package
4594 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4595
4596     if (ref($r) eq "HASH") {
4597         print "r is a reference to a hash.\n";
4598     }
4599     unless (ref($r)) {
4600         print "r is not a reference at all.\n";
4601     }
4602
4603 The return value C<LVALUE> indicates a reference to an lvalue that is not
4604 a variable. You get this from taking the reference of function calls like
4605 C<pos()> or C<substr()>. C<VSTRING> is returned if the reference points
4606 to a L<version string|perldata/"Version Strings">.
4607
4608 The result C<Regexp> indicates that the argument is a regular expression
4609 resulting from C<qr//>.
4610
4611 See also L<perlref>.
4612
4613 =item rename OLDNAME,NEWNAME
4614 X<rename> X<move> X<mv> X<ren>
4615
4616 Changes the name of a file; an existing file NEWNAME will be
4617 clobbered.  Returns true for success, false otherwise.
4618
4619 Behavior of this function varies wildly depending on your system
4620 implementation.  For example, it will usually not work across file system
4621 boundaries, even though the system I<mv> command sometimes compensates
4622 for this.  Other restrictions include whether it works on directories,
4623 open files, or pre-existing files.  Check L<perlport> and either the
4624 rename(2) manpage or equivalent system documentation for details.
4625
4626 For a platform independent C<move> function look at the L<File::Copy>
4627 module.
4628
4629 =item require VERSION
4630 X<require>
4631
4632 =item require EXPR
4633
4634 =item require
4635
4636 Demands a version of Perl specified by VERSION, or demands some semantics
4637 specified by EXPR or by C<$_> if EXPR is not supplied.
4638
4639 VERSION may be either a numeric argument such as 5.006, which will be
4640 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4641 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4642 VERSION is greater than the version of the current Perl interpreter.
4643 Compare with L</use>, which can do a similar check at compile time.
4644
4645 Specifying VERSION as a literal of the form v5.6.1 should generally be
4646 avoided, because it leads to misleading error messages under earlier
4647 versions of Perl that do not support this syntax.  The equivalent numeric
4648 version should be used instead.
4649
4650     require v5.6.1;     # run time version check
4651     require 5.6.1;      # ditto
4652     require 5.006_001;  # ditto; preferred for backwards compatibility
4653
4654 Otherwise, C<require> demands that a library file be included if it
4655 hasn't already been included.  The file is included via the do-FILE
4656 mechanism, which is essentially just a variety of C<eval> with the
4657 caveat that lexical variables in the invoking script will be invisible
4658 to the included code.  Has semantics similar to the following subroutine:
4659
4660     sub require {
4661        my ($filename) = @_;
4662        if (exists $INC{$filename}) {
4663            return 1 if $INC{$filename};
4664