This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
7f2e5f76c3169e10c6a50346a0c6e34ac1db7770
[perl5.git] / lib / _charnames.pm
1 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
2 # This helper module is for internal use by core Perl only.  This module is
3 # subject to change or removal at any time without notice.  Don't use it
4 # directly.  Use the public <charnames> module instead.
5
6 package _charnames;
7 use strict;
8 use warnings;
9 use File::Spec;
10 our $VERSION = '1.35';
11 use unicore::Name;    # mktables-generated algorithmically-defined names
12
13 use bytes ();          # for $bytes::hint_bits
14 use re "/aa";          # Everything in here should be ASCII
15
16 $Carp::Internal{ (__PACKAGE__) } = 1;
17
18 # Translate between Unicode character names and their code points.  This is a
19 # submodule of package <charnames>, used to allow \N{...} to be autoloaded,
20 # but it was decided not to autoload the various functions in charnames; the
21 # splitting allows this behavior.
22 #
23 # The official names with their code points are stored in a table in
24 # lib/unicore/Name.pl which is read in as a large string (almost 3/4 Mb in
25 # Unicode 6.0).  Each code point/name combination is separated by a \n in the
26 # string.  (Some of the CJK and the Hangul syllable names are determined
27 # instead algorithmically via subroutines stored instead in
28 # lib/unicore/Name.pm).  Because of the large size of this table, it isn't
29 # converted into hashes for faster lookup.
30 #
31 # But, user defined aliases are stored in their own hashes, as are Perl
32 # extensions to the official names.  These are checked first before looking at
33 # the official table.
34 #
35 # Basically, the table is grepped for the input code point (viacode()) or
36 # name (the other functions), and the corresponding value on the same line is
37 # returned.  The grepping is done by turning the input into a regular
38 # expression.  Thus, the same table does double duty, used by both name and
39 # code point lookup.  (If we were to have hashes, we would need two, one for
40 # each lookup direction.)
41 #
42 # For loose name matching, the logical thing would be to have a table
43 # with all the ignorable characters squeezed out, and then grep it with the
44 # similiarly-squeezed input name.  (And this is in fact how the lookups are
45 # done with the small Perl extension hashes.)  But since we need to be able to
46 # go from code point to official name, the original table would still need to
47 # exist.  Due to the large size of the table, it was decided to not read
48 # another very large string into memory for a second table.  Instead, the
49 # regular expression of the input name is modified to have optional spaces and
50 # dashes between characters.  For example, in strict matching, the regular
51 # expression would be:
52 #   qr/\tDIGIT ONE$/m
53 # Under loose matching, the blank would be squeezed out, and the re would be:
54 #   qr/\tD[- ]?I[- ]?G[- ]?I[- ]?T[- ]?O[- ]?N[- ]?E$/m
55 # which matches a blank or dash between any characters in the official table.
56 #
57 # This is also how script lookup is done.  Basically the re looks like
58 #   qr/ (?:LATIN|GREEK|CYRILLIC) (?:SMALL )?LETTER $name/
59 # where $name is the loose or strict regex for the remainder of the name.
60
61 # The hashes are stored as utf8 strings.  This makes it easier to deal with
62 # sequences.  I (khw) also tried making Name.pl utf8, but it slowed things
63 # down by a factor of 7.  I then tried making Name.pl store the ut8
64 # equivalents but not calling them utf8.  That led to similar speed as leaving
65 # it alone, but since that is harder for a human to parse, I left it as-is.
66
67 my %system_aliases = (
68
69     'SINGLE-SHIFT 2'                => pack("U", 0x8E),
70     'SINGLE-SHIFT 3'                => pack("U", 0x8F),
71     'PRIVATE USE 1'                 => pack("U", 0x91),
72     'PRIVATE USE 2'                 => pack("U", 0x92),
73 );
74
75 # These are the aliases above that differ under :loose and :full matching
76 # because the :full versions have blanks or hyphens in them.
77 #my %loose_system_aliases = (
78 #);
79
80 #my %deprecated_aliases;
81 #$deprecated_aliases{'BELL'} = pack("U", 0x07) if $^V lt v5.17.0;
82
83 #my %loose_deprecated_aliases = (
84 #);
85
86 # These are special cased in :loose matching, differing only in a medial
87 # hyphen
88 my $HANGUL_JUNGSEONG_O_E_utf8 = pack("U", 0x1180);
89 my $HANGUL_JUNGSEONG_OE_utf8 = pack("U", 0x116C);
90
91
92 my $txt;  # The table of official character names
93
94 my %full_names_cache; # Holds already-looked-up names, so don't have to
95 # re-look them up again.  The previous versions of charnames had scoping
96 # bugs.  For example if we use script A in one scope and find and cache
97 # what Z resolves to, we can't use that cache in a different scope that
98 # uses script B instead of A, as Z might be an entirely different letter
99 # there; or there might be different aliases in effect in different
100 # scopes, or :short may be in effect or not effect in different scopes,
101 # or various combinations thereof.  This was solved in this version
102 # mostly by moving things to %^H.  But some things couldn't be moved
103 # there.  One of them was the cache of runtime looked-up names, in part
104 # because %^H is read-only at runtime.  I (khw) don't know why the cache
105 # was run-time only in the previous versions: perhaps oversight; perhaps
106 # that compile time looking doesn't happen in a loop so didn't think it
107 # was worthwhile; perhaps not wanting to make the cache too large.  But
108 # I decided to make it compile time as well; this could easily be
109 # changed.
110 # Anyway, this hash is not scoped, and is added to at runtime.  It
111 # doesn't have scoping problems because the data in it is restricted to
112 # official names, which are always invariant, and we only set it and
113 # look at it at during :full lookups, so is unaffected by any other
114 # scoped options.  I put this in to maintain parity with the older
115 # version.  If desired, a %short_names cache could also be made, as well
116 # as one for each script, say in %script_names_cache, with each key
117 # being a hash for a script named in a 'use charnames' statement.  I
118 # decided not to do that for now, just because it's added complication,
119 # and because I'm just trying to maintain parity, not extend it.
120
121 # Like %full_names_cache, but for use when :loose is in effect.  There needs
122 # to be two caches because :loose may not be in effect for a scope, and a
123 # loose name could inappropriately be returned when only exact matching is
124 # called for.
125 my %loose_names_cache;
126
127 # Designed so that test decimal first, and then hex.  Leading zeros
128 # imply non-decimal, as do non-[0-9]
129 my $decimal_qr = qr/^[1-9]\d*$/;
130
131 # Returns the hex number in $1.
132 my $hex_qr = qr/^(?:[Uu]\+|0[xX])?([[:xdigit:]]+)$/;
133
134 sub croak
135 {
136   require Carp; goto &Carp::croak;
137 } # croak
138
139 sub carp
140 {
141   require Carp; goto &Carp::carp;
142 } # carp
143
144 sub alias (@) # Set up a single alias
145 {
146   my @errors;
147
148   my $alias = ref $_[0] ? $_[0] : { @_ };
149   foreach my $name (sort keys %$alias) {  # Sort only because it helps having
150                                           # deterministic output for
151                                           # t/lib/charnames/alias
152     my $value = $alias->{$name};
153     next unless defined $value;          # Omit if screwed up.
154
155     # Is slightly slower to just after this statement see if it is
156     # decimal, since we already know it is after having converted from
157     # hex, but makes the code easier to maintain, and is called
158     # infrequently, only at compile-time
159     if ($value !~ $decimal_qr && $value =~ $hex_qr) {
160       $value = CORE::hex $1;
161     }
162     if ($value =~ $decimal_qr) {
163         no warnings qw(non_unicode surrogate nonchar); # Allow any of these
164         $^H{charnames_ord_aliases}{$name} = pack("U", $value);
165
166         # Use a canonical form.
167         $^H{charnames_inverse_ords}{sprintf("%05X", $value)} = $name;
168     }
169     else {
170         # This regex needs to be sync'd with the code in toke.c that checks
171         # for the same thing
172         if ($name !~ / ^
173                        \p{_Perl_Charname_Begin}
174                        \p{_Perl_Charname_Continue}*
175                        $ /x) {
176           push @errors, $name;
177         }
178         else {
179           $^H{charnames_name_aliases}{$name} = $value;
180         }
181     }
182   }
183
184   # We find and output all errors from this :alias definition, rather than
185   # failing on the first one, so fewer runs are needed to get it to compile
186   if (@errors) {
187     foreach my $name (@errors) {
188       my $ok = "";
189       $ok = $1 if $name =~ / ^ ( \p{Alpha} [-\p{XPosixWord} ():\xa0]* ) /x;
190       my $first_bad = substr($name, length($ok), 1);
191       $name = "Invalid character in charnames alias definition; marked by <-- HERE in '$ok$first_bad<-- HERE " . substr($name, length($ok) + 1) . "'";
192     }
193     croak join "\n", @errors;
194   }
195
196   return;
197 } # alias
198
199 sub not_legal_use_bytes_msg {
200   my ($name, $utf8) = @_;
201   my $return;
202
203   if (length($utf8) == 1) {
204     $return = sprintf("Character 0x%04x with name '%s' is", ord $utf8, $name);
205   } else {
206     $return = sprintf("String with name '%s' (and ordinals %s) contains character(s)", $name, join(" ", map { sprintf "0x%04X", ord $_ } split(//, $utf8)));
207   }
208   return $return . " above 0xFF with 'use bytes' in effect";
209 }
210
211 sub alias_file ($)  # Reads a file containing alias definitions
212 {
213   my ($arg, $file) = @_;
214   if (-f $arg && File::Spec->file_name_is_absolute ($arg)) {
215     $file = $arg;
216   }
217   elsif ($arg =~ m/^\w+$/) {
218     $file = "unicore/${arg}_alias.pl";
219   }
220   else {
221     croak "Charnames alias file names can only have identifier characters";
222   }
223   if (my @alias = do $file) {
224     @alias == 1 && !defined $alias[0] and
225       croak "$file cannot be used as alias file for charnames";
226     @alias % 2 and
227       croak "$file did not return a (valid) list of alias pairs";
228     alias (@alias);
229     return (1);
230   }
231   0;
232 } # alias_file
233
234 # For use when don't import anything.  This structure must be kept in
235 # sync with the one that import() fills up.
236 my %dummy_H = (
237                 charnames_stringified_names => "",
238                 charnames_stringified_ords => "",
239                 charnames_scripts => "",
240                 charnames_full => 1,
241                 charnames_loose => 0,
242                 charnames_short => 0,
243               );
244
245
246 sub lookup_name ($$$) {
247   my ($name, $wants_ord, $runtime) = @_;
248
249   # Lookup the name or sequence $name in the tables.  If $wants_ord is false,
250   # returns the string equivalent of $name; if true, returns the ordinal value
251   # instead, but in this case $name must not be a sequence; otherwise undef is
252   # returned and a warning raised.  $runtime is 0 if compiletime, otherwise
253   # gives the number of stack frames to go back to get the application caller
254   # info.
255   # If $name is not found, returns undef in runtime with no warning; and in
256   # compiletime, the Unicode replacement character, with a warning.
257
258   # It looks first in the aliases, then in the large table of official Unicode
259   # names.
260
261   my $utf8;       # The string result
262   my $save_input;
263
264   if ($runtime) {
265
266     my $hints_ref = (caller($runtime))[10];
267
268     # If we didn't import anything (which happens with 'use charnames ()',
269     # substitute a dummy structure.
270     $hints_ref = \%dummy_H if ! defined $hints_ref
271                               || (! defined $hints_ref->{charnames_full}
272                                   && ! defined $hints_ref->{charnames_loose});
273
274     # At runtime, but currently not at compile time, $^H gets
275     # stringified, so un-stringify back to the original data structures.
276     # These get thrown away by perl before the next invocation
277     # Also fill in the hash with the non-stringified data.
278     # N.B.  New fields must be also added to %dummy_H
279
280     %{$^H{charnames_name_aliases}} = split ',',
281                                       $hints_ref->{charnames_stringified_names};
282     %{$^H{charnames_ord_aliases}} = split ',',
283                                       $hints_ref->{charnames_stringified_ords};
284     $^H{charnames_scripts} = $hints_ref->{charnames_scripts};
285     $^H{charnames_full} = $hints_ref->{charnames_full};
286     $^H{charnames_loose} = $hints_ref->{charnames_loose};
287     $^H{charnames_short} = $hints_ref->{charnames_short};
288   }
289
290   my $loose = $^H{charnames_loose};
291   my $lookup_name;  # Input name suitably modified for grepping for in the
292                     # table
293
294   # User alias should be checked first or else can't override ours, and if we
295   # were to add any, could conflict with theirs.
296   if (exists $^H{charnames_ord_aliases}{$name}) {
297     $utf8 = $^H{charnames_ord_aliases}{$name};
298   }
299   elsif (exists $^H{charnames_name_aliases}{$name}) {
300     $name = $^H{charnames_name_aliases}{$name};
301     $save_input = $lookup_name = $name;  # Cache the result for any error
302                                          # message
303     # The aliases are documented to not match loosely, so change loose match
304     # into full.
305     if ($loose) {
306       $loose = 0;
307       $^H{charnames_full} = 1;
308     }
309   }
310   else {
311
312     # Here, not a user alias.  That means that loose matching may be in
313     # effect; will have to modify the input name.
314     $lookup_name = $name;
315     if ($loose) {
316       $lookup_name = uc $lookup_name;
317
318       # Squeeze out all underscores
319       $lookup_name =~ s/_//g;
320
321       # Remove all medial hyphens
322       $lookup_name =~ s/ (?<= \S  ) - (?= \S  )//gx;
323
324       # Squeeze out all spaces
325       $lookup_name =~ s/\s//g;
326     }
327
328     # Here, $lookup_name has been modified as necessary for looking in the
329     # hashes.  Check the system alias files next.  Most of these aliases are
330     # the same for both strict and loose matching.  To save space, the ones
331     # which differ are in their own separate hash, which is checked if loose
332     # matching is selected and the regular match fails.  To save time, the
333     # loose hashes could be expanded to include all aliases, and there would
334     # only have to be one check.  But if someone specifies :loose, they are
335     # interested in convenience over speed, and the time for this second check
336     # is miniscule compared to the rest of the routine.
337     if (exists $system_aliases{$lookup_name}) {
338       $utf8 = $system_aliases{$lookup_name};
339     }
340     # There are currently no entries in this hash, so don't waste time looking
341     # for them.  But the code is retained for the unlikely possibility that
342     # some will be added in the future.
343 #    elsif ($loose && exists $loose_system_aliases{$lookup_name}) {
344 #      $utf8 = $loose_system_aliases{$lookup_name};
345 #    }
346 #    if (exists $deprecated_aliases{$lookup_name}) {
347 #      require warnings;
348 #      warnings::warnif('deprecated',
349 #                       "Unicode character name \"$name\" is deprecated, use \""
350 #                       . viacode(ord $deprecated_aliases{$lookup_name})
351 #                       . "\" instead");
352 #      $utf8 = $deprecated_aliases{$lookup_name};
353 #    }
354     # There are currently no entries in this hash, so don't waste time looking
355     # for them.  But the code is retained for the unlikely possibility that
356     # some will be added in the future.
357 #    elsif ($loose && exists $loose_deprecated_aliases{$lookup_name}) {
358 #      require warnings;
359 #      warnings::warnif('deprecated',
360 #                       "Unicode character name \"$name\" is deprecated, use \""
361 #                       . viacode(ord $loose_deprecated_aliases{$lookup_name})
362 #                       . "\" instead");
363 #      $utf8 = $loose_deprecated_aliases{$lookup_name};
364 #    }
365   }
366
367   my @off;  # Offsets into table of pattern match begin and end
368
369   # If haven't found it yet...
370   if (! defined $utf8) {
371
372     # See if has looked this input up earlier.
373     if (! $loose && $^H{charnames_full} && exists $full_names_cache{$name}) {
374       $utf8 = $full_names_cache{$name};
375     }
376     elsif ($loose && exists $loose_names_cache{$name}) {
377       $utf8 = $loose_names_cache{$name};
378     }
379     else { # Here, must do a look-up
380
381       # If full or loose matching succeeded, points to where to cache the
382       # result
383       my $cache_ref;
384
385       ## Suck in the code/name list as a big string.
386       ## Lines look like:
387       ##     "00052\tLATIN CAPITAL LETTER R\n"
388       # or
389       #      "0052 0303\tLATIN CAPITAL LETTER R WITH TILDE\n"
390       $txt = do "unicore/Name.pl" unless $txt;
391
392       ## @off will hold the index into the code/name string of the start and
393       ## end of the name as we find it.
394
395       ## If :loose, look for a loose match; if :full, look for the name
396       ## exactly
397       # First, see if the name is one which is algorithmically determinable.
398       # The subroutine is included in Name.pl.  The table contained in
399       # $txt doesn't contain these.  Experiments show that checking
400       # for these before checking for the regular names has no
401       # noticeable impact on performance for the regular names, but
402       # the other way around slows down finding these immensely.
403       # Algorithmically determinables are not placed in the cache because
404       # that uses up memory, and finding these again is fast.
405       if (($loose || $^H{charnames_full})
406           && (defined (my $ord = charnames::name_to_code_point_special($lookup_name, $loose))))
407       {
408         $utf8 = pack("U", $ord);
409       }
410       else {
411
412         # Not algorithmically determinable; look up in the table.  The name
413         # will be turned into a regex, so quote any meta characters.
414         $lookup_name = quotemeta $lookup_name;
415
416         if ($loose) {
417
418           # For loose matches, $lookup_name has already squeezed out the
419           # non-essential characters.  We have to add in code to make the
420           # squeezed version match the non-squeezed equivalent in the table.
421           # The only remaining hyphens are ones that start or end a word in
422           # the original.  They have been quoted in $lookup_name so they look
423           # like "\-".  Change all other characters except the backslash
424           # quotes for any metacharacters, and the final character, so that
425           # e.g., COLON gets transformed into: /C[- ]?O[- ]?L[- ]?O[- ]?N/
426           $lookup_name =~ s/ (?! \\ -)    # Don't do this to the \- sequence
427                              ( [^-\\] )   # Nor the "-" within that sequence,
428                                           # nor the "\" that quotes metachars,
429                                           # but otherwise put the char into $1
430                              (?=.)        # And don't do it for the final char
431                            /$1\[- \]?/gx; # And add an optional blank or
432                                           # '-' after each $1 char
433
434           # Those remaining hyphens were originally at the beginning or end of
435           # a word, so they can match either a blank before or after, but not
436           # both.  (Keep in mind that they have been quoted, so are a '\-'
437           # sequence)
438           $lookup_name =~ s/\\ -/(?:- | -)/xg;
439         }
440
441         # Do the lookup in the full table if asked for, and if succeeds
442         # save the offsets and set where to cache the result.
443         if (($loose || $^H{charnames_full}) && $txt =~ /\t$lookup_name$/m) {
444           @off = ($-[0] + 1, $+[0]);    # The 1 is for the tab
445           $cache_ref = ($loose) ? \%loose_names_cache : \%full_names_cache;
446         }
447         else {
448
449           # Here, didn't look for, or didn't find the name.
450           # If :short is allowed, see if input is like "greek:Sigma".
451           # Keep in mind that $lookup_name has had the metas quoted.
452           my $scripts_trie = "";
453           my $name_has_uppercase;
454           if (($^H{charnames_short})
455               && $lookup_name =~ /^ (?: \\ \s)*   # Quoted space
456                                     (.+?)         # $1 = the script
457                                     (?: \\ \s)*
458                                     \\ :          # Quoted colon
459                                     (?: \\ \s)*
460                                     (.+?)         # $2 = the name
461                                     (?: \\ \s)* $
462                                   /xs)
463           {
464               # Even in non-loose matching, the script traditionally has been
465               # case insensitve
466               $scripts_trie = "\U$1";
467               $lookup_name = $2;
468
469               # Use original name to find its input casing, but ignore the
470               # script part of that to make the determination.
471               $save_input = $name if ! defined $save_input;
472               $name =~ s/.*?://;
473               $name_has_uppercase = $name =~ /[[:upper:]]/;
474           }
475           else { # Otherwise look in allowed scripts
476               $scripts_trie = $^H{charnames_scripts};
477
478               # Use original name to find its input casing
479               $name_has_uppercase = $name =~ /[[:upper:]]/;
480           }
481
482           my $case = $name_has_uppercase ? "CAPITAL" : "SMALL";
483           return if (! $scripts_trie || $txt !~
484              /\t (?: $scripts_trie ) \ (?:$case\ )? LETTER \ \U$lookup_name $/xm);
485
486           # Here have found the input name in the table.
487           @off = ($-[0] + 1, $+[0]);  # The 1 is for the tab
488         }
489
490         # Here, the input name has been found; we haven't set up the output,
491         # but we know where in the string
492         # the name starts.  The string is set up so that for single characters
493         # (and not named sequences), the name is preceded immediately by a
494         # tab and 5 hex digits for its code, with a \n before those.  Named
495         # sequences won't have the 7th preceding character be a \n.
496         # (Actually, for the very first entry in the table this isn't strictly
497         # true: subtracting 7 will yield -1, and the substr below will
498         # therefore yield the very last character in the table, which should
499         # also be a \n, so the statement works anyway.)
500         if (substr($txt, $off[0] - 7, 1) eq "\n") {
501           $utf8 = pack("U", CORE::hex substr($txt, $off[0] - 6, 5));
502
503           # Handle the single loose matching special case, in which two names
504           # differ only by a single medial hyphen.  If the original had a
505           # hyphen (or more) in the right place, then it is that one.
506           $utf8 = $HANGUL_JUNGSEONG_O_E_utf8
507                   if $loose
508                      && $utf8 eq $HANGUL_JUNGSEONG_OE_utf8
509                      && $name =~ m/O \s* - [-\s]* E/ix;
510                      # Note that this wouldn't work if there were a 2nd
511                      # OE in the name
512         }
513         else {
514
515           # Here, is a named sequence.  Need to go looking for the beginning,
516           # which is just after the \n from the previous entry in the table.
517           # The +1 skips past that newline, or, if the rindex() fails, to put
518           # us to an offset of zero.
519           my $charstart = rindex($txt, "\n", $off[0] - 7) + 1;
520           $utf8 = pack("U*", map { CORE::hex }
521               split " ", substr($txt, $charstart, $off[0] - $charstart - 1));
522         }
523       }
524
525       # Cache the input so as to not have to search the large table
526       # again, but only if it came from the one search that we cache.
527       # (Haven't bothered with the pain of sorting out scoping issues for the
528       # scripts searches.)
529       $cache_ref->{$name} = $utf8 if defined $cache_ref;
530     }
531   }
532
533
534   # Here, have the utf8.  If the return is to be an ord, must be any single
535   # character.
536   if ($wants_ord) {
537     return ord($utf8) if length $utf8 == 1;
538   }
539   else {
540
541     # Here, wants string output.  If utf8 is acceptable, just return what
542     # we've got; otherwise attempt to convert it to non-utf8 and return that.
543     my $in_bytes = ($runtime)
544                    ? (caller $runtime)[8] & $bytes::hint_bits
545                    : $^H & $bytes::hint_bits;
546     return $utf8 if (! $in_bytes || utf8::downgrade($utf8, 1)) # The 1 arg
547                                                   # means don't die on failure
548   }
549
550   # Here, there is an error:  either there are too many characters, or the
551   # result string needs to be non-utf8, and at least one character requires
552   # utf8.  Prefer any official name over the input one for the error message.
553   if (@off) {
554     $name = substr($txt, $off[0], $off[1] - $off[0]) if @off;
555   }
556   else {
557     $name = (defined $save_input) ? $save_input : $_[0];
558   }
559
560   if ($wants_ord) {
561     # Only way to get here in this case is if result too long.  Message
562     # assumes that our only caller that requires single char result is
563     # vianame.
564     carp "charnames::vianame() doesn't handle named sequences ($name).  Use charnames::string_vianame() instead";
565     return;
566   }
567
568   # Only other possible failure here is from use bytes.
569   if ($runtime) {
570     carp not_legal_use_bytes_msg($name, $utf8);
571     return;
572   } else {
573     croak not_legal_use_bytes_msg($name, $utf8);
574   }
575
576 } # lookup_name
577
578 sub charnames {
579
580   # For \N{...}.  Looks up the character name and returns the string
581   # representation of it.
582
583   # The first 0 arg means wants a string returned; the second that we are in
584   # compile time
585   return lookup_name($_[0], 0, 0);
586 }
587
588 sub import
589 {
590   shift; ## ignore class name
591
592   if (not @_) {
593     carp("'use charnames' needs explicit imports list");
594   }
595   $^H{charnames} = \&charnames ;
596   $^H{charnames_ord_aliases} = {};
597   $^H{charnames_name_aliases} = {};
598   $^H{charnames_inverse_ords} = {};
599   # New fields must be added to %dummy_H, and the code in lookup_name()
600   # that copies fields from the runtime structure
601
602   ##
603   ## fill %h keys with our @_ args.
604   ##
605   my ($promote, %h, @args) = (0);
606   while (my $arg = shift) {
607     if ($arg eq ":alias") {
608       @_ or
609         croak ":alias needs an argument in charnames";
610       my $alias = shift;
611       if (ref $alias) {
612         ref $alias eq "HASH" or
613           croak "Only HASH reference supported as argument to :alias";
614         alias ($alias);
615         next;
616       }
617       if ($alias =~ m{:(\w+)$}) {
618         $1 eq "full" || $1 eq "loose" || $1 eq "short" and
619           croak ":alias cannot use existing pragma :$1 (reversed order?)";
620         alias_file ($1) and $promote = 1;
621         next;
622       }
623       alias_file ($alias);
624       next;
625     }
626     if (substr($arg, 0, 1) eq ':'
627       and ! ($arg eq ":full" || $arg eq ":short" || $arg eq ":loose"))
628     {
629       warn "unsupported special '$arg' in charnames";
630       next;
631     }
632     push @args, $arg;
633   }
634
635   @args == 0 && $promote and @args = (":full");
636   @h{@args} = (1) x @args;
637
638   # Don't leave these undefined as are tested for in lookup_names
639   $^H{charnames_full} = delete $h{':full'} || 0;
640   $^H{charnames_loose} = delete $h{':loose'} || 0;
641   $^H{charnames_short} = delete $h{':short'} || 0;
642   my @scripts = map { uc quotemeta } keys %h;
643
644   ##
645   ## If utf8? warnings are enabled, and some scripts were given,
646   ## see if at least we can find one letter from each script.
647   ##
648   if (warnings::enabled('utf8') && @scripts) {
649     $txt = do "unicore/Name.pl" unless $txt;
650
651     for my $script (@scripts) {
652       if (not $txt =~ m/\t$script (?:CAPITAL |SMALL )?LETTER /) {
653         warnings::warn('utf8',  "No such script: '$script'");
654         $script = quotemeta $script;  # Escape it, for use in the re.
655       }
656     }
657   }
658
659   # %^H gets stringified, so serialize it ourselves so can extract the
660   # real data back later.
661   $^H{charnames_stringified_ords} = join ",", %{$^H{charnames_ord_aliases}};
662   $^H{charnames_stringified_names} = join ",", %{$^H{charnames_name_aliases}};
663   $^H{charnames_stringified_inverse_ords} = join ",", %{$^H{charnames_inverse_ords}};
664
665   # Modify the input script names for loose name matching if that is also
666   # specified, similar to the way the base character name is prepared.  They
667   # don't (currently, and hopefully never will) have dashes.  These go into a
668   # regex, and have already been uppercased and quotemeta'd.  Squeeze out all
669   # input underscores, blanks, and dashes.  Then convert so will match a blank
670   # between any characters.
671   if ($^H{charnames_loose}) {
672     for (my $i = 0; $i < @scripts; $i++) {
673       $scripts[$i] =~ s/[_ -]//g;
674       $scripts[$i] =~ s/ ( [^\\] ) (?= . ) /$1\\ ?/gx;
675     }
676   }
677
678   $^H{charnames_scripts} = join "|", @scripts;  # Stringifiy them as a trie
679 } # import
680
681 # Cache of already looked-up values.  This is set to only contain
682 # official values, and user aliases can't override them, so scoping is
683 # not an issue.
684 my %viacode;
685
686 sub viacode {
687
688   # Returns the name of the code point argument
689
690   if (@_ != 1) {
691     carp "charnames::viacode() expects one argument";
692     return;
693   }
694
695   my $arg = shift;
696
697   # This is derived from Unicode::UCD, where it is nearly the same as the
698   # function _getcode(), but here it makes sure that even a hex argument
699   # has the proper number of leading zeros, which is critical in
700   # matching against $txt below
701   # Must check if decimal first; see comments at that definition
702   my $hex;
703   if ($arg =~ $decimal_qr) {
704     $hex = sprintf "%05X", $arg;
705   } elsif ($arg =~ $hex_qr) {
706     # Below is the line that differs from the _getcode() source
707     $hex = sprintf "%05X", hex $1;
708   } else {
709     carp("unexpected arg \"$arg\" to charnames::viacode()");
710     return;
711   }
712
713   return $viacode{$hex} if exists $viacode{$hex};
714
715   my $return;
716
717   # If the code point is above the max in the table, there's no point
718   # looking through it.  Checking the length first is slightly faster
719   if (length($hex) <= 5 || CORE::hex($hex) <= 0x10FFFF) {
720     $txt = do "unicore/Name.pl" unless $txt;
721
722     # See if the name is algorithmically determinable.
723     my $algorithmic = charnames::code_point_to_name_special(CORE::hex $hex);
724     if (defined $algorithmic) {
725       $viacode{$hex} = $algorithmic;
726       return $algorithmic;
727     }
728
729     # Return the official name, if exists.  It's unclear to me (khw) at
730     # this juncture if it is better to return a user-defined override, so
731     # leaving it as is for now.
732     if ($txt =~ m/^$hex\t/m) {
733
734         # The name starts with the next character and goes up to the
735         # next new-line.  Using capturing parentheses above instead of
736         # @+ more than doubles the execution time in Perl 5.13
737         $return = substr($txt, $+[0], index($txt, "\n", $+[0]) - $+[0]);
738
739         # If not one of these 4 code points, return what we've found.
740         if ($hex !~ / ^ 000 (?: 8[014] | 99 ) $ /x) {
741           $viacode{$hex} = $return;
742           return $return;
743         }
744
745         # For backwards compatibility, we don't return the official name of
746         # the 4 code points if there are user-defined aliases for them -- so
747         # continue looking.
748     }
749   }
750
751   # See if there is a user name for it, before giving up completely.
752   # First get the scoped aliases, give up if have none.
753   my $H_ref = (caller(1))[10];
754   return if ! defined $return
755               && (! defined $H_ref
756                   || ! exists $H_ref->{charnames_stringified_inverse_ords});
757
758   my %code_point_aliases;
759   if (defined $H_ref->{charnames_stringified_inverse_ords}) {
760     %code_point_aliases = split ',',
761                           $H_ref->{charnames_stringified_inverse_ords};
762     return $code_point_aliases{$hex} if exists $code_point_aliases{$hex};
763   }
764
765   # Here there is no user-defined alias, return any official one.
766   return $return if defined $return;
767
768   if (CORE::hex($hex) > 0x10FFFF
769       && warnings::enabled('non_unicode'))
770   {
771       carp "Unicode characters only allocated up to U+10FFFF (you asked for U+$hex)";
772   }
773   return;
774
775 } # _viacode
776
777 1;
778
779 # ex: set ts=8 sts=2 sw=2 et: