t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';        # for which_perl() etc
   7 }
   8
   9 use Config;
  10
  11 my ($Null, $Curdir);
  12 if(eval {require File::Spec; 1}) {
  13     $Null = File::Spec->devnull;
  14     $Curdir = File::Spec->curdir;
  15 } else {
  16     die $@ unless is_miniperl();
  17     $Curdir = '.';
  18     diag("miniperl failed to load File::Spec, error is:\n$@");
  19     diag("\ncontinuing, assuming '.' for current directory. Some tests will be skipped.");
  20 }
  21
  22
  23 plan tests => 113;
  24
  25 my $Perl = which_perl();
  26
  27 $ENV{LC_ALL}   = 'C';           # Forge English error messages.
  28 $ENV{LANGUAGE} = 'C';           # Ditto in GNU.
  29
  30 $Is_Amiga   = $^O eq 'amigaos';
  31 $Is_Cygwin  = $^O eq 'cygwin';
  32 $Is_Darwin  = $^O eq 'darwin';
  33 $Is_Dos     = $^O eq 'dos';
  34 $Is_MSWin32 = $^O eq 'MSWin32';
  35 $Is_NetWare = $^O eq 'NetWare';
  36 $Is_OS2     = $^O eq 'os2';
  37 $Is_Solaris = $^O eq 'solaris';
  38 $Is_VMS     = $^O eq 'VMS';
  39 $Is_DGUX    = $^O eq 'dgux';
  40 $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
  41
  42 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare;
  43
  44 $Is_UFS     = $Is_Darwin && (() = `df -t ufs . 2>/dev/null`) == 2;
  45
  46 if ($Is_Cygwin) {
  47   require Win32;
  48   Win32->import;
  49 }
  50
  51 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  52    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  53
  54 my $tmpfile = tempfile();
  55 my $tmpfile_link = tempfile();
  56
  57 chmod 0666, $tmpfile;
  58 unlink_all $tmpfile;
  59 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  60 close FOO;
  61
  62 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  63
  64 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  65
  66 # The clock on a network filesystem might be different from the
  67 # system clock.
  68 my $Filesystem_Time_Offset = abs($mtime - time);
  69
  70 #nlink should if link support configured in Perl.
  71 SKIP: {
  72     skip "No link count - Hard link support not built in.", 1
  73         unless $Config{d_link};
  74
  75     is($nlink, 1, 'nlink on regular file');
  76 }
  77
  78 SKIP: {
  79   skip "mtime and ctime not reliable", 2
  80     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_Darwin;
  81
  82   ok( $mtime,           'mtime' );
  83   is( $mtime, $ctime,   'mtime == ctime' );
  84 }
  85
  86
  87 # Cygwin seems to have a 3 second granularity on its timestamps.
  88 my $funky_FAT_timestamps = $Is_Cygwin;
  89 sleep 3 if $funky_FAT_timestamps;
  90
  91 print FOO "Now is the time for all good men to come to.\n";
  92 close(FOO);
  93
  94 sleep 2;
  95
  96
  97 SKIP: {
  98     unlink $tmpfile_link;
  99     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
 100     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
 101
 102     is( $@, '',         'link() implemented' );
 103     ok( $lnk_result,    'linked tmp testfile' );
 104     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
 105
 106     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
 107
 108     SKIP: {
 109         skip "No link count", 1 if $Config{dont_use_nlink};
 110         skip "Cygwin9X fakes hard links by copying", 1
 111           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
 112
 113         is($nlink, 2,     'Link count on hard linked file' );
 114     }
 115
 116     SKIP: {
 117         skip_if_miniperl("File::Spec not built for minitest", 2);
 118         my $cwd = File::Spec->rel2abs($Curdir);
 119         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
 120                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
 121                                         $mtime && $mtime == $ctime;
 122         skip "AFS has different mtime/ctime link semantics", 2
 123                                      if $cwd =~ m#$Config{'afsroot'}/#;
 124         skip "AmigaOS has different mtime/ctime link semantics", 2
 125                                      if $Is_Amiga;
 126         # Win32 could pass $mtime test but as FAT and NTFS have
 127         # no ctime concept $ctime is ALWAYS == $mtime
 128         # expect netware to be the same ...
 129         skip "No ctime concept on this OS", 2
 130                                      if $Is_MSWin32 ||
 131                                         ($Is_Darwin && $Is_UFS);
 132
 133         if( !ok($mtime, 'hard link mtime') ||
 134             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 135             print STDERR <<DIAG;
 136 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 137 # has this problem.  Building on the ClearCase VOBS filesystem may also
 138 # cause this failure.
 139 #
 140 # Darwin's UFS doesn't have a ctime concept, and thus is expected to fail
 141 # this test.
 142 DIAG
 143         }
 144     }
 145
 146 }
 147
 148 # truncate and touch $tmpfile.
 149 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 150 ok(-z \*F,     '-z on empty filehandle');
 151 ok(! -s \*F,   '   and -s');
 152 close F;
 153
 154 ok(-z $tmpfile,     '-z on empty file');
 155 ok(! -s $tmpfile,   '   and -s');
 156
 157 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 158 print F "hi\n";
 159 close F;
 160
 161 open(F, "<$tmpfile") || DIE("Can't open temp test file: $!");
 162 ok(!-z *F,     '-z on empty filehandle');
 163 ok( -s *F,   '   and -s');
 164 close F;
 165
 166 ok(! -z $tmpfile,   '-z on non-empty file');
 167 ok(-s $tmpfile,     '   and -s');
 168
 169
 170 # Strip all access rights from the file.
 171 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 172
 173 SKIP: {
 174     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 175
 176     SKIP: {
 177         # Going to try to switch away from root.  Might not work.
 178         my $olduid = $>;
 179         eval { $> = 1; };
 180         skip "Can't test -r or -w meaningfully if you're superuser", 2
 181           if ($Is_Cygwin ? Win32::IsAdminUser : $> == 0);
 182
 183         SKIP: {
 184             skip "Can't test -r meaningfully?", 1 if $Is_Dos;
 185             ok(!-r $tmpfile,    "   -r");
 186         }
 187
 188         ok(!-w $tmpfile,    "   -w");
 189
 190         # switch uid back (may not be implemented)
 191         eval { $> = $olduid; };
 192     }
 193
 194     ok(! -x $tmpfile,   '   -x');
 195 }
 196
 197
 198
 199 ok(chmod(0700,$tmpfile),    'chmod 0700');
 200 ok(-r $tmpfile,     '   -r');
 201 ok(-w $tmpfile,     '   -w');
 202
 203 SKIP: {
 204     skip "-x simply determines if a file ends in an executable suffix", 1
 205       if $Is_Dosish;
 206
 207     ok(-x $tmpfile,     '   -x');
 208 }
 209
 210 ok(  -f $tmpfile,   '   -f');
 211 ok(! -d $tmpfile,   '   !-d');
 212
 213 # Is this portable?
 214 ok(  -d '.',          '-d cwd' );
 215 ok(! -f '.',          '!-f cwd' );
 216
 217
 218 SKIP: {
 219     unlink($tmpfile_link);
 220     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 221     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 222
 223     is( $@, '',     'symlink() implemented' );
 224     ok( $symlink_rslt,      'symlink() ok' );
 225     ok(-l $tmpfile_link,    '-l');
 226 }
 227
 228 ok(-o $tmpfile,     '-o');
 229
 230 ok(-e $tmpfile,     '-e');
 231
 232 unlink($tmpfile_link);
 233 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 234
 235 SKIP: {
 236     skip "No character, socket or block special files", 6
 237       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 238     skip "/dev isn't available to test against", 6
 239       unless -d '/dev' && -r '/dev' && -x '/dev';
 240     skip "Skipping: unexpected ls output in MP-RAS", 6
 241       if $Is_MPRAS;
 242
 243     # VMS problem:  If GNV or other UNIX like tool is installed, then
 244     # sometimes Perl will find /bin/ls, and will try to run it.
 245     # But since Perl on VMS does not know to run it under Bash, it will
 246     # try to run the DCL verb LS.  And if the VMS product Language
 247     # Sensitive Editor is installed, or some other LS verb, that will
 248     # be run instead.  So do not do this until we can teach Perl
 249     # when to use BASH on VMS.
 250     skip "ls command not available to Perl in OpenVMS right now.", 6
 251       if $Is_VMS;
 252
 253     delete $ENV{CLICOLOR_FORCE};
 254     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 255     my $CMD = "$LS /dev 2>/dev/null";
 256     my $DEV = qx($CMD);
 257
 258     skip "$CMD failed", 6 if $DEV eq '';
 259
 260     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 261
 262     skip "opendir failed: $!", 6 if @DEV == 0;
 263
 264     # /dev/stdout might be either character special or a named pipe,
 265     # or a symlink, or a socket, depending on which OS and how are
 266     # you running the test, so let's censor that one away.
 267     # Similar remarks hold for stderr.
 268     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 269     @DEV =  grep { $_ ne 'stdout' } @DEV;
 270     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
 271     @DEV =  grep { $_ ne 'stderr' } @DEV;
 272
 273     # /dev/printer is also naughty: in IRIX it shows up as
 274     # Srwx-----, not srwx------.
 275     $DEV =~ s{^.+?\sprinter$}{}m;
 276     @DEV =  grep { $_ ne 'printer' } @DEV;
 277
 278     # If running as root, we will see .files in the ls result,
 279     # and readdir() will see them always.  Potential for conflict,
 280     # so let's weed them out.
 281     $DEV =~ s{^.+?\s\..+?$}{}m;
 282     @DEV =  grep { ! m{^\..+$} } @DEV;
 283
 284     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
 285     if ($^O eq 'irix') {
 286         $DEV =~ s{^S(.+?)}{s$1}mg;
 287     }
 288
 289     my $try = sub {
 290         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 291         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 292         my $c1 = scalar @c1;
 293         my $c2 = scalar @c2;
 294         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 295     };
 296
 297 SKIP: {
 298     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
 299
 300     $try->('b', '-b');
 301     $try->('c', '-c');
 302     $try->('s', '-S');
 303
 304 }
 305
 306 ok(! -b $Curdir,    '!-b cwd');
 307 ok(! -c $Curdir,    '!-c cwd');
 308 ok(! -S $Curdir,    '!-S cwd');
 309
 310 }
 311
 312 SKIP: {
 313     my($cnt, $uid);
 314     $cnt = $uid = 0;
 315
 316     # Find a set of directories that's very likely to have setuid files
 317     # but not likely to be *all* setuid files.
 318     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 319     skip "Can't find a setuid file to test with", 3 unless @bin;
 320
 321     for my $bin (@bin) {
 322         opendir BIN, $bin or die "Can't opendir $bin: $!";
 323         while (defined($_ = readdir BIN)) {
 324             $_ = "$bin/$_";
 325             $cnt++;
 326             $uid++ if -u;
 327             last if $uid && $uid < $cnt;
 328         }
 329     }
 330     closedir BIN;
 331
 332     skip "No setuid programs", 3 if $uid == 0;
 333
 334     isnt($cnt, 0,    'found some programs');
 335     isnt($uid, 0,    '  found some setuid programs');
 336     ok($uid < $cnt,  "    they're not all setuid");
 337 }
 338
 339
 340 # To assist in automated testing when a controlling terminal (/dev/tty)
 341 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 342 # can be set to skip the tests that need a tty.
 343 SKIP: {
 344     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 345
 346     my $TTY = "/dev/tty";
 347
 348     SKIP: {
 349         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 350         skip "No TTY to test -t with", 2 unless -e $TTY;
 351
 352         open(TTY, $TTY) ||
 353           warn "Can't open $TTY--run t/TEST outside of make.\n";
 354         ok(-t TTY,  '-t');
 355         ok(-c TTY,  'tty is -c');
 356         close(TTY);
 357     }
 358     ok(! -t TTY,    '!-t on closed TTY filehandle');
 359
 360     {
 361         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 362         ok(-t,          '-t on STDIN');
 363     }
 364 }
 365
 366 SKIP: {
 367     skip "No null device to test with", 1 unless -e $Null;
 368     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 369
 370     open(NULL, $Null) or DIE("Can't open $Null: $!");
 371     ok(! -t NULL,   'null device is not a TTY');
 372     close(NULL);
 373 }
 374
 375
 376 # These aren't strictly "stat" calls, but so what?
 377 my $statfile = './op/stat.t';
 378 ok(  -T $statfile,    '-T');
 379 ok(! -B $statfile,    '!-B');
 380
 381 SKIP: {
 382      skip("DG/UX", 1) if $Is_DGUX;
 383 ok(-B $Perl,      '-B');
 384 }
 385
 386 ok(! -T $Perl,    '!-T');
 387
 388 open(FOO,$statfile);
 389 SKIP: {
 390     eval { -T FOO; };
 391     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 392
 393     is( $@, '',     '-T on filehandle causes no errors' );
 394
 395     ok(-T FOO,      '   -T');
 396     ok(! -B FOO,    '   !-B');
 397
 398     $_ = <FOO>;
 399     like($_, qr/perl/, 'after readline');
 400     ok(-T FOO,      '   still -T');
 401     ok(! -B FOO,    '   still -B');
 402     close(FOO);
 403
 404     open(FOO,$statfile);
 405     $_ = <FOO>;
 406     like($_, qr/perl/,      'reopened and after readline');
 407     ok(-T FOO,      '   still -T');
 408     ok(! -B FOO,    '   still !-B');
 409
 410     ok(seek(FOO,0,0),   'after seek');
 411     ok(-T FOO,          '   still -T');
 412     ok(! -B FOO,        '   still !-B');
 413
 414     # It's documented this way in perlfunc *shrug*
 415     () = <FOO>;
 416     ok(eof FOO,         'at EOF');
 417     ok(-T FOO,          '   still -T');
 418     ok(-B FOO,          '   now -B');
 419 }
 420 close(FOO);
 421
 422
 423 SKIP: {
 424     skip "No null device to test with", 2 unless -e $Null;
 425
 426     ok(-T $Null,  'null device is -T');
 427     ok(-B $Null,  '    and -B');
 428 }
 429
 430
 431 # and now, a few parsing tests:
 432 $_ = $tmpfile;
 433 ok(-f,      'bare -f   uses $_');
 434 ok(-f(),    '     -f() "');
 435
 436 unlink $tmpfile or print "# unlink failed: $!\n";
 437
 438 # bug id 20011101.069
 439 my @r = \stat($Curdir);
 440 is(scalar @r, 13,   'stat returns full 13 elements');
 441
 442 stat $0;
 443 eval { lstat _ };
 444 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 445     'lstat _ croaks after stat' );
 446 eval { lstat *_ };
 447 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 448     'lstat *_ croaks after stat' );
 449 eval { lstat \*_ };
 450 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 451     'lstat \*_ croaks after stat' );
 452 eval { -l _ };
 453 like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 454     '-l _ croaks after stat' );
 455
 456 lstat $0;
 457 eval { lstat _ };
 458 is( "$@", "", "lstat _ ok after lstat" );
 459 eval { -l _ };
 460 is( "$@", "", "-l _ ok after lstat" );
 461
 462 eval { lstat "test.pl" };
 463 {
 464     open my $fh, "test.pl";
 465     stat *$fh{IO};
 466     eval { lstat _ }
 467 }
 468 like $@, qr/^The stat preceding lstat\(\) wasn't an lstat at /,
 469 'stat $ioref resets stat type';
 470
 471 {
 472     my @statbuf = stat STDOUT;
 473     stat "test.pl";
 474     my @lstatbuf = lstat *STDOUT{IO};
 475     is "@lstatbuf", "@statbuf", 'lstat $ioref reverts to regular fstat';
 476 }
 477
 478 SKIP: {
 479     skip "No lstat", 2 unless $Config{d_lstat};
 480
 481     # bug id 20020124.004
 482     # If we have d_lstat, we should have symlink()
 483     my $linkname = 'stat-' . rand =~ y/.//dr;
 484     my $target = $Perl;
 485     $target =~ s/;\d+\z// if $Is_VMS; # symlinks don't like version numbers
 486     symlink $target, $linkname or die "# Can't symlink $0: $!";
 487     lstat $linkname;
 488     -T _;
 489     eval { lstat _ };
 490     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 491         'lstat croaks after -T _' );
 492     eval { -l _ };
 493     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 494         '-l _ croaks after -T _' );
 495     unlink $linkname or print "# unlink $linkname failed: $!\n";
 496 }
 497
 498 SKIP: {
 499     skip "Too much clock skew between system and filesystem", 5
 500         if ($Filesystem_Time_Offset > 5);
 501     print "# Zzz...\n";
 502     sleep($Filesystem_Time_Offset+1);
 503     my $f = 'tstamp.tmp';
 504     unlink $f;
 505     ok (open(S, "> $f"), 'can create tmp file');
 506     close S or die;
 507     my @a = stat $f;
 508     print "# time=$^T, stat=(@a)\n";
 509     my @b = (-M _, -A _, -C _);
 510     print "# -MAC=(@b)\n";
 511     ok( (-M _) < 0, 'negative -M works');
 512     ok( (-A _) < 0, 'negative -A works');
 513     ok( (-C _) < 0, 'negative -C works');
 514     ok(unlink($f), 'unlink tmp file');
 515 }
 516
 517 # [perl #4253]
 518 {
 519     ok(open(F, ">", $tmpfile), 'can create temp file');
 520     close F;
 521     chmod 0077, $tmpfile;
 522     my @a = stat($tmpfile);
 523     my $s1 = -s _;
 524     -T _;
 525     my $s2 = -s _;
 526     is($s1, $s2, q(-T _ doesn't break the statbuffer));
 527     SKIP: {
 528         skip "No lstat", 1 unless $Config{d_lstat};
 529         skip "uid=0", 1 unless $<&&$>;
 530         skip "Readable by group/other means readable by me", 1 if $^O eq 'VMS';
 531         lstat($tmpfile);
 532         -T _;
 533         ok(eval { lstat _ },
 534            q(-T _ doesn't break lstat for unreadable file));
 535     }
 536     unlink $tmpfile;
 537 }
 538
 539 SKIP: {
 540     skip "No dirfd()", 9 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 541     ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 542     ok(stat(DIR), "stat() on dirhandle works");
 543     ok(-d -r _ , "chained -x's on dirhandle");
 544     ok(-d DIR, "-d on a dirhandle works");
 545
 546     # And now for the ambiguous bareword case
 547     {
 548         no warnings 'deprecated';
 549         ok(open(DIR, "TEST"), 'Can open "TEST" dir')
 550             || diag "Can't open 'TEST':  $!";
 551     }
 552     my $size = (stat(DIR))[7];
 553     ok(defined $size, "stat() on bareword works");
 554     is($size, -s "TEST", "size returned by stat of bareword is for the file");
 555     ok(-f _, "ambiguous bareword uses file handle, not dir handle");
 556     ok(-f DIR);
 557     closedir DIR or die $!;
 558     close DIR or die $!;
 559 }
 560
 561 {
 562     # RT #8244: *FILE{IO} does not behave like *FILE for stat() and -X() operators
 563     ok(open(F, ">", $tmpfile), 'can create temp file');
 564     my @thwap = stat *F{IO};
 565     ok(@thwap, "stat(*F{IO}) works");
 566     ok( -f *F{IO} , "single file tests work with *F{IO}");
 567     close F;
 568     unlink $tmpfile;
 569
 570     #PVIO's hold dirhandle information, so let's test them too.
 571
 572     SKIP: {
 573         skip "No dirfd()", 9 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 574         ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 575         ok(stat(*DIR{IO}), "stat() on *DIR{IO} works");
 576         ok(-d _ , "The special file handle _ is set correctly");
 577         ok(-d -r *DIR{IO} , "chained -x's on *DIR{IO}");
 578
 579         # And now for the ambiguous bareword case
 580         {
 581             no warnings 'deprecated';
 582             ok(open(DIR, "TEST"), 'Can open "TEST" dir')
 583                 || diag "Can't open 'TEST':  $!";
 584         }
 585         my $size = (stat(*DIR{IO}))[7];
 586         ok(defined $size, "stat() on *THINGY{IO} works");
 587         is($size, -s "TEST",
 588            "size returned by stat of *THINGY{IO} is for the file");
 589         ok(-f _, "ambiguous *THINGY{IO} uses file handle, not dir handle");
 590         ok(-f *DIR{IO});
 591         closedir DIR or die $!;
 592         close DIR or die $!;
 593     }
 594 }
 595
 596 # [perl #71002]
 597 {
 598     local $^W = 1;
 599     my $w;
 600     local $SIG{__WARN__} = sub { warn shift; ++$w };
 601     stat 'prepeinamehyparcheiarcheiometoonomaavto';
 602     stat _;
 603     is $w, undef, 'no unopened warning from stat _';
 604 }
 605
 606 END {
 607     chmod 0666, $tmpfile;
 608     unlink_all $tmpfile;
 609 }