ext/DynaLoader/DynaLoader_pm.PL

   1 use Config;
   2
   3 sub to_string {
   4     my ($value) = @_;
   5     $value =~ s/\\/\\\\/g;
   6     $value =~ s/'/\\'/g;
   7     return "'$value'";
   8 }
   9
  10 unlink "DynaLoader.pm" if -f "DynaLoader.pm";
  11 open OUT, ">DynaLoader.pm" or die $!;
  12 print OUT <<'EOT';
  13
  14 # Generated from DynaLoader.pm.PL
  15
  16 package DynaLoader;
  17
  18 #   And Gandalf said: 'Many folk like to know beforehand what is to
  19 #   be set on the table; but those who have laboured to prepare the
  20 #   feast like to keep their secret; for wonder makes the words of
  21 #   praise louder.'
  22
  23 #   (Quote from Tolkien suggested by Anno Siegel.)
  24 #
  25 # See pod text at end of file for documentation.
  26 # See also ext/DynaLoader/README in source tree for other information.
  27 #
  28 # Tim.Bunce@ig.co.uk, August 1994
  29
  30 use vars qw($VERSION *AUTOLOAD);
  31
  32 $VERSION = 1.04;        # avoid typo warning
  33
  34 require AutoLoader;
  35 *AUTOLOAD = \&AutoLoader::AUTOLOAD;
  36
  37 use Config;
  38
  39 # The following require can't be removed during maintenance
  40 # releases, sadly, because of the risk of buggy code that does
  41 # require Carp; Carp::croak "..."; without brackets dying
  42 # if Carp hasn't been loaded in earlier compile time. :-(
  43 # We'll let those bugs get found on the development track.
  44 require Carp if $] < 5.00450;
  45
  46 # enable debug/trace messages from DynaLoader perl code
  47 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  48
  49 #
  50 # Flags to alter dl_load_file behaviour.  Assigned bits:
  51 #   0x01  make symbols available for linking later dl_load_file's.
  52 #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
  53 #         (ignored under VMS; effect is built-in to image linking)
  54 #
  55 # This is called as a class method $module->dl_load_flags.  The
  56 # definition here will be inherited and result on "default" loading
  57 # behaviour unless a sub-class of DynaLoader defines its own version.
  58 #
  59
  60 sub dl_load_flags { 0x00 }
  61
  62 # ($dl_dlext, $dlsrc)
  63 #         = @Config::Config{'dlext', 'dlsrc'};
  64 EOT
  65
  66 print OUT "  (\$dl_dlext, \$dlsrc) = (",
  67           to_string($Config::Config{'dlext'}), ",",
  68           to_string($Config::Config{'dlsrc'}), ")\n;" ;
  69
  70 print OUT <<'EOT';
  71
  72 # Some systems need special handling to expand file specifications
  73 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
  74 # See dl_expandspec() for more details. Should be harmless but
  75 # inefficient to define on systems that don't need it.
  76 $Is_VMS    = $^O eq 'VMS';
  77 $do_expand = $Is_VMS;
  78 $Is_MacOS  = $^O eq 'MacOS';
  79
  80 @dl_require_symbols = ();       # names of symbols we need
  81 @dl_resolve_using   = ();       # names of files to link with
  82 @dl_library_path    = ();       # path to look for files
  83
  84 #XSLoader.pm may have added elements before we were required
  85 #@dl_librefs         = ();       # things we have loaded
  86 #@dl_modules         = ();       # Modules we have loaded
  87
  88 # This is a fix to support DLD's unfortunate desire to relink -lc
  89 @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
  90
  91 EOT
  92
  93 my $cfg_dl_library_path = <<'EOT';
  94 push(@dl_library_path, split(' ', $Config::Config{libpth}));
  95 EOT
  96
  97 sub dquoted_comma_list {
  98     join(", ", map {qq("$_")} @_);
  99 }
 100
 101 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 102     eval $cfg_dl_library_path;
 103     if (!$ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 104         my $dl_library_path = dquoted_comma_list(@dl_library_path);
 105         print OUT <<EOT;
 106 # The below \@dl_library_path has been expanded (%Config) in Perl build time.
 107
 108 \@dl_library_path = ($dl_library_path);
 109
 110 EOT
 111     }
 112 }
 113 else {
 114     print OUT <<EOT;
 115 # Initialise \@dl_library_path with the 'standard' library path
 116 # for this platform as determined by Configure.
 117
 118 $cfg_dl_library_path
 119
 120 EOT
 121 }
 122
 123 my $ldlibpthname;
 124 my $ldlibpthname_defined;
 125 my $pthsep;
 126
 127 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 128     $ldlibpthname         = $Config::Config{ldlibpthname};
 129     $ldlibpthname_defined = defined $Config::Config{ldlibpthname} ? 1 : 0;
 130     $pthsep               = $Config::Config{path_sep};
 131 }
 132 else {
 133     $ldlibpthname         = q($Config::Config{ldlibpthname});
 134     $ldlibpthname_defined = q(defined $Config::Config{ldlibpthname});
 135     $pthsep               = q($Config::Config{path_sep});
 136     print OUT <<EOT;
 137 my \$ldlibpthname         = $ldlibpthname;
 138 my \$ldlibpthname_defined = $ldlibpthname_defined;
 139 my \$pthsep               = $pthsep;
 140
 141 EOT
 142 }
 143
 144 my $env_dl_library_path = <<'EOT';
 145 if ($ldlibpthname_defined &&
 146     exists $ENV{$ldlibpthname}) {
 147     push(@dl_library_path, split(/$pthsep/, $ENV{$ldlibpthname}));
 148 }
 149
 150 # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
 151
 152 if ($ldlibpthname_defined &&
 153     $ldlibpthname ne 'LD_LIBRARY_PATH' &&
 154     exists $ENV{LD_LIBRARY_PATH}) {
 155     push(@dl_library_path, split(/$pthsep/, $ENV{LD_LIBRARY_PATH}));
 156 }
 157 EOT
 158
 159 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 160     eval $env_dl_library_path;
 161 }
 162 else {
 163     print OUT <<EOT;
 164 # Add to \@dl_library_path any extra directories we can gather from environment
 165 # during runtime.
 166
 167 $env_dl_library_path
 168
 169 EOT
 170 }
 171
 172 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 173     my $dl_library_path = dquoted_comma_list(@dl_library_path);
 174     print OUT <<EOT;
 175 # The below \@dl_library_path has been expanded (%Config, %ENV)
 176 # in Perl build time.
 177
 178 \@dl_library_path = ($dl_library_path);
 179
 180 EOT
 181 }
 182
 183 print OUT <<'EOT';
 184 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
 185 # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
 186 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
 187                                 !defined(&dl_error);
 188
 189 if ($dl_debug) {
 190     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
 191     print STDERR "DynaLoader not linked into this perl\n"
 192             unless defined(&boot_DynaLoader);
 193 }
 194
 195 1; # End of main code
 196
 197
 198 sub croak   { require Carp; Carp::croak(@_)   }
 199
 200 sub bootstrap_inherit {
 201     my $module = $_[0];
 202     local *isa = *{"$module\::ISA"};
 203     local @isa = (@isa, 'DynaLoader');
 204     # Cannot goto due to delocalization.  Will report errors on a wrong line?
 205     bootstrap(@_);
 206 }
 207
 208 # The bootstrap function cannot be autoloaded (without complications)
 209 # so we define it here:
 210
 211 sub bootstrap {
 212     # use local vars to enable $module.bs script to edit values
 213     local(@args) = @_;
 214     local($module) = $args[0];
 215     local(@dirs, $file);
 216
 217     unless ($module) {
 218         require Carp;
 219         Carp::confess("Usage: DynaLoader::bootstrap(module)");
 220     }
 221
 222     # A common error on platforms which don't support dynamic loading.
 223     # Since it's fatal and potentially confusing we give a detailed message.
 224     croak("Can't load module $module, dynamic loading not available in this perl.\n".
 225         "  (You may need to build a new perl executable which either supports\n".
 226         "  dynamic loading or has the $module module statically linked into it.)\n")
 227         unless defined(&dl_load_file);
 228
 229     my @modparts = split(/::/,$module);
 230     my $modfname = $modparts[-1];
 231
 232     # Some systems have restrictions on files names for DLL's etc.
 233     # mod2fname returns appropriate file base name (typically truncated)
 234     # It may also edit @modparts if required.
 235     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
 236
 237         if (($^O eq 'NetWare') && (length($modfname) > 8)) {
 238                 $modfname = substr($modfname, 0, 8);
 239         }
 240
 241     my $modpname = join(($Is_MacOS ? ':' : '/'),@modparts);
 242
 243     print STDERR "DynaLoader::bootstrap for $module ",
 244                 ($Is_MacOS
 245                        ? "(:auto:$modpname:$modfname.$dl_dlext)\n" :
 246                        "(auto/$modpname/$modfname.$dl_dlext)\n")
 247         if $dl_debug;
 248
 249     foreach (@INC) {
 250         chop($_ = VMS::Filespec::unixpath($_)) if $Is_VMS;
 251         my $dir;
 252         if ($Is_MacOS) {
 253             my $path = $_;
 254             $path .= ":"  unless /:$/;
 255             $dir = "${path}auto:$modpname";
 256         } else {
 257             $dir = "$_/auto/$modpname";
 258         }
 259         if ($^O ne 'NetWare') {
 260                 next unless -d $dir; # skip over uninteresting directories
 261         }
 262         else {
 263                 next if -f $dir; # skip over uninteresting directories
 264         }
 265
 266         # check for common cases to avoid autoload of dl_findfile
 267         my $try = $Is_MacOS ? "$dir:$modfname.$dl_dlext" : "$dir/$modfname.$dl_dlext";
 268         if ($^O ne 'NetWare') {
 269                 last if $file = ($do_expand) ? dl_expandspec($try) : ((-f $try) && $try);
 270         }
 271         elsif (!(-d $try)) {
 272                 last if $file = ($do_expand) ? dl_expandspec($try) : ($try);
 273         }
 274
 275         # no luck here, save dir for possible later dl_findfile search
 276         push @dirs, $dir;
 277     }
 278     # last resort, let dl_findfile have a go in all known locations
 279     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
 280
 281     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
 282         unless $file;   # wording similar to error from 'require'
 283
 284     $file = uc($file) if $Is_VMS && $Config::Config{d_vms_case_sensitive_symbols};
 285     my $bootname = "boot_$module";
 286     $bootname =~ s/\W/_/g;
 287     @dl_require_symbols = ($bootname);
 288
 289     # Execute optional '.bootstrap' perl script for this module.
 290     # The .bs file can be used to configure @dl_resolve_using etc to
 291     # match the needs of the individual module on this architecture.
 292     my $bs = $file;
 293     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
 294     if (-s $bs) { # only read file if it's not empty
 295         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
 296         eval { do $bs; };
 297         warn "$bs: $@\n" if $@;
 298     }
 299
 300     my $boot_symbol_ref;
 301
 302     if ($^O eq 'darwin') {
 303         if ($boot_symbol_ref = dl_find_symbol(0, $bootname)) {
 304             goto boot; #extension library has already been loaded, e.g. darwin
 305         }
 306     }
 307
 308     # Many dynamic extension loading problems will appear to come from
 309     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
 310     # Often these errors are actually occurring in the initialisation
 311     # C code of the extension XS file. Perl reports the error as being
 312     # in this perl code simply because this was the last perl code
 313     # it executed.
 314
 315     my $libref = dl_load_file($file, $module->dl_load_flags) or
 316         croak("Can't load '$file' for module $module: ".dl_error());
 317
 318     push(@dl_librefs,$libref);  # record loaded object
 319
 320     my @unresolved = dl_undef_symbols();
 321     if (@unresolved) {
 322         require Carp;
 323         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
 324     }
 325
 326     $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
 327          croak("Can't find '$bootname' symbol in $file\n");
 328
 329     push(@dl_modules, $module); # record loaded module
 330
 331   boot:
 332     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
 333
 334     # See comment block above
 335     &$xs(@args);
 336 }
 337
 338
 339 #sub _check_file {   # private utility to handle dl_expandspec vs -f tests
 340 #    my($file) = @_;
 341 #    return $file if (!$do_expand && -f $file); # the common case
 342 #    return $file if ( $do_expand && ($file=dl_expandspec($file)));
 343 #    return undef;
 344 #}
 345
 346
 347 # Let autosplit and the autoloader deal with these functions:
 348 __END__
 349
 350
 351 sub dl_findfile {
 352     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
 353     # This function does not automatically consider the architecture
 354     # or the perl library auto directories.
 355     my (@args) = @_;
 356     my (@dirs,  $dir);   # which directories to search
 357     my (@found);         # full paths to real files we have found
 358 EOT
 359
 360 print OUT '    my $dl_ext= ' . to_string($Config::Config{'dlext'}) .
 361           "; # \$Config::Config{'dlext'} suffix for perl extensions\n";
 362 print OUT '    my $dl_so = ' . to_string($Config::Config{'so'}) .
 363           "; # \$Config::Config{'so'} suffix for shared libraries\n";
 364
 365 print OUT <<'EOT';
 366
 367     print STDERR "dl_findfile(@args)\n" if $dl_debug;
 368
 369     # accumulate directories but process files as they appear
 370     arg: foreach(@args) {
 371         #  Special fast case: full filepath requires no search
 372         if ($Is_VMS && m%[:>/\]]% && -f $_) {
 373             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
 374             last arg unless wantarray;
 375             next;
 376         }
 377         elsif ($Is_MacOS) {
 378             if (m/:/ && -f $_) {
 379                 push(@found,$_);
 380                 last arg unless wantarray;
 381             }
 382         }
 383         elsif (m:/: && -f $_ && !$do_expand) {
 384             push(@found,$_);
 385             last arg unless wantarray;
 386             next;
 387         }
 388
 389         # Deal with directories first:
 390         #  Using a -L prefix is the preferred option (faster and more robust)
 391         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
 392
 393         if ($Is_MacOS) {
 394             #  Otherwise we try to try to spot directories by a heuristic
 395             #  (this is a more complicated issue than it first appears)
 396             if (m/:/ && -d $_) {   push(@dirs, $_); next; }
 397             #  Only files should get this far...
 398             my(@names, $name);    # what filenames to look for
 399             s/^-l//;
 400             push(@names, $_);
 401             foreach $dir (@dirs, @dl_library_path) {
 402                 next unless -d $dir;
 403                 $dir =~ s/^([^:]+)$/:$1/;
 404                 $dir =~ s/:$//;
 405                 foreach $name (@names) {
 406                     my($file) = "$dir:$name";
 407                     print STDERR " checking in $dir for $name\n" if $dl_debug;
 408                     if (-f $file) {
 409                         push(@found, $file);
 410                         next arg; # no need to look any further
 411                     }
 412                 }
 413             }
 414             next;
 415         }
 416
 417         #  Otherwise we try to try to spot directories by a heuristic
 418         #  (this is a more complicated issue than it first appears)
 419         if (m:/: && -d $_) {   push(@dirs, $_); next; }
 420
 421         # VMS: we may be using native VMS directory syntax instead of
 422         # Unix emulation, so check this as well
 423         if ($Is_VMS && /[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
 424
 425         #  Only files should get this far...
 426         my(@names, $name);    # what filenames to look for
 427         if (m:-l: ) {          # convert -lname to appropriate library name
 428             s/-l//;
 429             push(@names,"lib$_.$dl_so");
 430             push(@names,"lib$_.a");
 431         } else {                # Umm, a bare name. Try various alternatives:
 432             # these should be ordered with the most likely first
 433             push(@names,"$_.$dl_ext")    unless m/\.$dl_ext$/o;
 434             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
 435             push(@names,"lib$_.$dl_so")  unless m:/:;
 436             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
 437             push(@names, $_);
 438         }
 439         foreach $dir (@dirs, @dl_library_path) {
 440             next unless -d $dir;
 441             chop($dir = VMS::Filespec::unixpath($dir)) if $Is_VMS;
 442             foreach $name (@names) {
 443                 my($file) = "$dir/$name";
 444                 print STDERR " checking in $dir for $name\n" if $dl_debug;
 445                 $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
 446                 #$file = _check_file($file);
 447                 if ($file) {
 448                     push(@found, $file);
 449                     next arg; # no need to look any further
 450                 }
 451             }
 452         }
 453     }
 454     if ($dl_debug) {
 455         foreach(@dirs) {
 456             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
 457         }
 458         print STDERR "dl_findfile found: @found\n";
 459     }
 460     return $found[0] unless wantarray;
 461     @found;
 462 }
 463
 464
 465 sub dl_expandspec {
 466     my($spec) = @_;
 467     # Optional function invoked if DynaLoader.pm sets $do_expand.
 468     # Most systems do not require or use this function.
 469     # Some systems may implement it in the dl_*.xs file in which case
 470     # this autoload version will not be called but is harmless.
 471
 472     # This function is designed to deal with systems which treat some
 473     # 'filenames' in a special way. For example VMS 'Logical Names'
 474     # (something like unix environment variables - but different).
 475     # This function should recognise such names and expand them into
 476     # full file paths.
 477     # Must return undef if $spec is invalid or file does not exist.
 478
 479     my $file = $spec; # default output to input
 480
 481     if ($Is_VMS) { # dl_expandspec should be defined in dl_vms.xs
 482         require Carp;
 483         Carp::croak("dl_expandspec: should be defined in XS file!\n");
 484     } else {
 485         return undef unless -f $file;
 486     }
 487     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
 488     $file;
 489 }
 490
 491 sub dl_find_symbol_anywhere
 492 {
 493     my $sym = shift;
 494     my $libref;
 495     foreach $libref (@dl_librefs) {
 496         my $symref = dl_find_symbol($libref,$sym);
 497         return $symref if $symref;
 498     }
 499     return undef;
 500 }
 501
 502 =head1 NAME
 503
 504 DynaLoader - Dynamically load C libraries into Perl code
 505
 506 dl_error(), dl_findfile(), dl_expandspec(), dl_load_file(), dl_unload_file(), dl_find_symbol(), dl_find_symbol_anywhere(), dl_undef_symbols(), dl_install_xsub(), dl_load_flags(), bootstrap() - routines used by DynaLoader modules
 507
 508 =head1 SYNOPSIS
 509
 510     package YourPackage;
 511     require DynaLoader;
 512     @ISA = qw(... DynaLoader ...);
 513     bootstrap YourPackage;
 514
 515     # optional method for 'global' loading
 516     sub dl_load_flags { 0x01 }
 517
 518
 519 =head1 DESCRIPTION
 520
 521 This document defines a standard generic interface to the dynamic
 522 linking mechanisms available on many platforms.  Its primary purpose is
 523 to implement automatic dynamic loading of Perl modules.
 524
 525 This document serves as both a specification for anyone wishing to
 526 implement the DynaLoader for a new platform and as a guide for
 527 anyone wishing to use the DynaLoader directly in an application.
 528
 529 The DynaLoader is designed to be a very simple high-level
 530 interface that is sufficiently general to cover the requirements
 531 of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
 532
 533 It is also hoped that the interface will cover the needs of OS/2, NT
 534 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
 535
 536 It must be stressed that the DynaLoader, by itself, is practically
 537 useless for accessing non-Perl libraries because it provides almost no
 538 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
 539 library function or supplying arguments.  A C::DynaLib module
 540 is available from CPAN sites which performs that function for some
 541 common system types.
 542
 543 DynaLoader Interface Summary
 544
 545   @dl_library_path
 546   @dl_resolve_using
 547   @dl_require_symbols
 548   $dl_debug
 549   @dl_librefs
 550   @dl_modules
 551                                                   Implemented in:
 552   bootstrap($modulename)                               Perl
 553   @filepaths = dl_findfile(@names)                     Perl
 554   $flags = $modulename->dl_load_flags                  Perl
 555   $symref  = dl_find_symbol_anywhere($symbol)          Perl
 556
 557   $libref  = dl_load_file($filename, $flags)           C
 558   $status  = dl_unload_file($libref)                   C
 559   $symref  = dl_find_symbol($libref, $symbol)          C
 560   @symbols = dl_undef_symbols()                        C
 561   dl_install_xsub($name, $symref [, $filename])        C
 562   $message = dl_error                                  C
 563
 564 =over 4
 565
 566 =item @dl_library_path
 567
 568 The standard/default list of directories in which dl_findfile() will
 569 search for libraries etc.  Directories are searched in order:
 570 $dl_library_path[0], [1], ... etc
 571
 572 @dl_library_path is initialised to hold the list of 'normal' directories
 573 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
 574 ensure portability across a wide range of platforms.
 575
 576 @dl_library_path should also be initialised with any other directories
 577 that can be determined from the environment at runtime (such as
 578 LD_LIBRARY_PATH for SunOS).
 579
 580 After initialisation @dl_library_path can be manipulated by an
 581 application using push and unshift before calling dl_findfile().
 582 Unshift can be used to add directories to the front of the search order
 583 either to save search time or to override libraries with the same name
 584 in the 'normal' directories.
 585
 586 The load function that dl_load_file() calls may require an absolute
 587 pathname.  The dl_findfile() function and @dl_library_path can be
 588 used to search for and return the absolute pathname for the
 589 library/object that you wish to load.
 590
 591 =item @dl_resolve_using
 592
 593 A list of additional libraries or other shared objects which can be
 594 used to resolve any undefined symbols that might be generated by a
 595 later call to load_file().
 596
 597 This is only required on some platforms which do not handle dependent
 598 libraries automatically.  For example the Socket Perl extension
 599 library (F<auto/Socket/Socket.so>) contains references to many socket
 600 functions which need to be resolved when it's loaded.  Most platforms
 601 will automatically know where to find the 'dependent' library (e.g.,
 602 F</usr/lib/libsocket.so>).  A few platforms need to be told the
 603 location of the dependent library explicitly.  Use @dl_resolve_using
 604 for this.
 605
 606 Example usage:
 607
 608     @dl_resolve_using = dl_findfile('-lsocket');
 609
 610 =item @dl_require_symbols
 611
 612 A list of one or more symbol names that are in the library/object file
 613 to be dynamically loaded.  This is only required on some platforms.
 614
 615 =item @dl_librefs
 616
 617 An array of the handles returned by successful calls to dl_load_file(),
 618 made by bootstrap, in the order in which they were loaded.
 619 Can be used with dl_find_symbol() to look for a symbol in any of
 620 the loaded files.
 621
 622 =item @dl_modules
 623
 624 An array of module (package) names that have been bootstrap'ed.
 625
 626 =item dl_error()
 627
 628 Syntax:
 629
 630     $message = dl_error();
 631
 632 Error message text from the last failed DynaLoader function.  Note
 633 that, similar to errno in unix, a successful function call does not
 634 reset this message.
 635
 636 Implementations should detect the error as soon as it occurs in any of
 637 the other functions and save the corresponding message for later
 638 retrieval.  This will avoid problems on some platforms (such as SunOS)
 639 where the error message is very temporary (e.g., dlerror()).
 640
 641 =item $dl_debug
 642
 643 Internal debugging messages are enabled when $dl_debug is set true.
 644 Currently setting $dl_debug only affects the Perl side of the
 645 DynaLoader.  These messages should help an application developer to
 646 resolve any DynaLoader usage problems.
 647
 648 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
 649
 650 For the DynaLoader developer/porter there is a similar debugging
 651 variable added to the C code (see dlutils.c) and enabled if Perl was
 652 built with the B<-DDEBUGGING> flag.  This can also be set via the
 653 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
 654 higher for more.
 655
 656 =item dl_findfile()
 657
 658 Syntax:
 659
 660     @filepaths = dl_findfile(@names)
 661
 662 Determine the full paths (including file suffix) of one or more
 663 loadable files given their generic names and optionally one or more
 664 directories.  Searches directories in @dl_library_path by default and
 665 returns an empty list if no files were found.
 666
 667 Names can be specified in a variety of platform independent forms.  Any
 668 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
 669 an appropriate suffix for the platform.
 670
 671 If a name does not already have a suitable prefix and/or suffix then
 672 the corresponding file will be searched for by trying combinations of
 673 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
 674 and "$name".
 675
 676 If any directories are included in @names they are searched before
 677 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
 678 names are treated as filenames to be searched for.
 679
 680 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
 681
 682 Example:
 683
 684     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
 685
 686
 687 =item dl_expandspec()
 688
 689 Syntax:
 690
 691     $filepath = dl_expandspec($spec)
 692
 693 Some unusual systems, such as VMS, require special filename handling in
 694 order to deal with symbolic names for files (i.e., VMS's Logical Names).
 695
 696 To support these systems a dl_expandspec() function can be implemented
 697 either in the F<dl_*.xs> file or code can be added to the autoloadable
 698 dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
 699 more information.
 700
 701 =item dl_load_file()
 702
 703 Syntax:
 704
 705     $libref = dl_load_file($filename, $flags)
 706
 707 Dynamically load $filename, which must be the path to a shared object
 708 or library.  An opaque 'library reference' is returned as a handle for
 709 the loaded object.  Returns undef on error.
 710
 711 The $flags argument to alters dl_load_file behaviour.
 712 Assigned bits:
 713
 714  0x01  make symbols available for linking later dl_load_file's.
 715        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
 716        (ignored under VMS; this is a normal part of image linking)
 717
 718 (On systems that provide a handle for the loaded object such as SunOS
 719 and HPUX, $libref will be that handle.  On other systems $libref will
 720 typically be $filename or a pointer to a buffer containing $filename.
 721 The application should not examine or alter $libref in any way.)
 722
 723 This is the function that does the real work.  It should use the
 724 current values of @dl_require_symbols and @dl_resolve_using if required.
 725
 726     SunOS: dlopen($filename)
 727     HP-UX: shl_load($filename)
 728     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
 729     NeXT:  rld_load($filename, @dl_resolve_using)
 730     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
 731
 732 (The dlopen() function is also used by Solaris and some versions of
 733 Linux, and is a common choice when providing a "wrapper" on other
 734 mechanisms as is done in the OS/2 port.)
 735
 736 =item dl_unload_file()
 737
 738 Syntax:
 739
 740     $status = dl_unload_file($libref)
 741
 742 Dynamically unload $libref, which must be an opaque 'library reference' as
 743 returned from dl_load_file.  Returns one on success and zero on failure.
 744
 745 This function is optional and may not necessarily be provided on all platforms.
 746 If it is defined, it is called automatically when the interpreter exits for
 747 every shared object or library loaded by DynaLoader::bootstrap.  All such
 748 library references are stored in @dl_librefs by DynaLoader::Bootstrap as it
 749 loads the libraries.  The files are unloaded in last-in, first-out order.
 750
 751 This unloading is usually necessary when embedding a shared-object perl (e.g.
 752 one configured with -Duseshrplib) within a larger application, and the perl
 753 interpreter is created and destroyed several times within the lifetime of the
 754 application.  In this case it is possible that the system dynamic linker will
 755 unload and then subsequently reload the shared libperl without relocating any
 756 references to it from any files DynaLoaded by the previous incarnation of the
 757 interpreter.  As a result, any shared objects opened by DynaLoader may point to
 758 a now invalid 'ghost' of the libperl shared object, causing apparently random
 759 memory corruption and crashes.  This behaviour is most commonly seen when using
 760 Apache and mod_perl built with the APXS mechanism.
 761
 762     SunOS: dlclose($libref)
 763     HP-UX: ???
 764     Linux: ???
 765     NeXT:  ???
 766     VMS:   ???
 767
 768 (The dlclose() function is also used by Solaris and some versions of
 769 Linux, and is a common choice when providing a "wrapper" on other
 770 mechanisms as is done in the OS/2 port.)
 771
 772 =item dl_loadflags()
 773
 774 Syntax:
 775
 776     $flags = dl_loadflags $modulename;
 777
 778 Designed to be a method call, and to be overridden by a derived class
 779 (i.e. a class which has DynaLoader in its @ISA).  The definition in
 780 DynaLoader itself returns 0, which produces standard behavior from
 781 dl_load_file().
 782
 783 =item dl_find_symbol()
 784
 785 Syntax:
 786
 787     $symref = dl_find_symbol($libref, $symbol)
 788
 789 Return the address of the symbol $symbol or C<undef> if not found.  If the
 790 target system has separate functions to search for symbols of different
 791 types then dl_find_symbol() should search for function symbols first and
 792 then other types.
 793
 794 The exact manner in which the address is returned in $symref is not
 795 currently defined.  The only initial requirement is that $symref can
 796 be passed to, and understood by, dl_install_xsub().
 797
 798     SunOS: dlsym($libref, $symbol)
 799     HP-UX: shl_findsym($libref, $symbol)
 800     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
 801     NeXT:  rld_lookup("_$symbol")
 802     VMS:   lib$find_image_symbol($libref,$symbol)
 803
 804
 805 =item dl_find_symbol_anywhere()
 806
 807 Syntax:
 808
 809     $symref = dl_find_symbol_anywhere($symbol)
 810
 811 Applies dl_find_symbol() to the members of @dl_librefs and returns
 812 the first match found.
 813
 814 =item dl_undef_symbols()
 815
 816 Example
 817
 818     @symbols = dl_undef_symbols()
 819
 820 Return a list of symbol names which remain undefined after load_file().
 821 Returns C<()> if not known.  Don't worry if your platform does not provide
 822 a mechanism for this.  Most do not need it and hence do not provide it,
 823 they just return an empty list.
 824
 825
 826 =item dl_install_xsub()
 827
 828 Syntax:
 829
 830     dl_install_xsub($perl_name, $symref [, $filename])
 831
 832 Create a new Perl external subroutine named $perl_name using $symref as
 833 a pointer to the function which implements the routine.  This is simply
 834 a direct call to newXSUB().  Returns a reference to the installed
 835 function.
 836
 837 The $filename parameter is used by Perl to identify the source file for
 838 the function if required by die(), caller() or the debugger.  If
 839 $filename is not defined then "DynaLoader" will be used.
 840
 841
 842 =item bootstrap()
 843
 844 Syntax:
 845
 846 bootstrap($module)
 847
 848 This is the normal entry point for automatic dynamic loading in Perl.
 849
 850 It performs the following actions:
 851
 852 =over 8
 853
 854 =item *
 855
 856 locates an auto/$module directory by searching @INC
 857
 858 =item *
 859
 860 uses dl_findfile() to determine the filename to load
 861
 862 =item *
 863
 864 sets @dl_require_symbols to C<("boot_$module")>
 865
 866 =item *
 867
 868 executes an F<auto/$module/$module.bs> file if it exists
 869 (typically used to add to @dl_resolve_using any files which
 870 are required to load the module on the current platform)
 871
 872 =item *
 873
 874 calls dl_load_flags() to determine how to load the file.
 875
 876 =item *
 877
 878 calls dl_load_file() to load the file
 879
 880 =item *
 881
 882 calls dl_undef_symbols() and warns if any symbols are undefined
 883
 884 =item *
 885
 886 calls dl_find_symbol() for "boot_$module"
 887
 888 =item *
 889
 890 calls dl_install_xsub() to install it as "${module}::bootstrap"
 891
 892 =item *
 893
 894 calls &{"${module}::bootstrap"} to bootstrap the module (actually
 895 it uses the function reference returned by dl_install_xsub for speed)
 896
 897 =back
 898
 899 =back
 900
 901
 902 =head1 AUTHOR
 903
 904 Tim Bunce, 11 August 1994.
 905
 906 This interface is based on the work and comments of (in no particular
 907 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
 908 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
 909
 910 Larry Wall designed the elegant inherited bootstrap mechanism and
 911 implemented the first Perl 5 dynamic loader using it.
 912
 913 Solaris global loading added by Nick Ing-Simmons with design/coding
 914 assistance from Tim Bunce, January 1996.
 915
 916 =cut
 917 EOT
 918
 919 close OUT or die $!;
 920