This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[inseparable changes from patch from perl5.003_12 to perl5.003_13]
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar and list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one list argument.)  For instance, splice() has three scalar
19 arguments followed by a list.
20
21 In the syntax descriptions that follow, list operators that expect a
22 list (and provide list context for the elements of the list) are shown
23 with LIST as an argument.  Such a list may consist of any combination
24 of scalar arguments or list values; the list values will be included
25 in the list as if each individual element were interpolated at that
26 point in the list, forming a longer single-dimensional list value.
27 Elements of the LIST should be separated by commas.
28
29 Any function in the list below may be used either with or without
30 parentheses around its arguments.  (The syntax descriptions omit the
31 parentheses.)  If you use the parentheses, the simple (but occasionally
32 surprising) rule is this: It I<LOOKS> like a function, therefore it I<IS> a
33 function, and precedence doesn't matter.  Otherwise it's a list
34 operator or unary operator, and precedence does matter.  And whitespace
35 between the function and left parenthesis doesn't count--so you need to
36 be careful sometimes:
37
38     print 1+2+3;        # Prints 6.
39     print(1+2) + 3;     # Prints 3.
40     print (1+2)+3;      # Also prints 3!
41     print +(1+2)+3;     # Prints 6.
42     print ((1+2)+3);    # Prints 6.
43
44 If you run Perl with the B<-w> switch it can warn you about this.  For
45 example, the third line above produces:
46
47     print (...) interpreted as function at - line 1.
48     Useless use of integer addition in void context at - line 1.
49
50 For functions that can be used in either a scalar or list context,
51 non-abortive failure is generally indicated in a scalar context by
52 returning the undefined value, and in a list context by returning the
53 null list.
54
55 Remember the following rule:
56
57 =over 8
58
59 =item  
60
61 I<THERE IS NO GENERAL RULE FOR CONVERTING A LIST INTO A SCALAR!>
62
63 =back
64
65 Each operator and function decides which sort of value it would be most
66 appropriate to return in a scalar context.  Some operators return the
67 length of the list that would have been returned in a list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72
73 =head2 Perl Functions by Category
74
75 Here are Perl's functions (including things that look like
76 functions, like some of the keywords and named operators)
77 arranged by category.  Some functions appear in more
78 than one place.
79
80 =over
81
82 =item Functions for SCALARs or strings
83
84 chomp, chop, chr, crypt, hex, index, lc, lcfirst, length,
85 oct, ord, pack, q/STRING/, qq/STRING/, reverse, rindex,
86 sprintf, substr, tr///, uc, ucfirst, y///
87
88 =item Regular expressions and pattern matching
89
90 m//, pos, quotemeta, s///, split, study
91
92 =item Numeric functions
93
94 abs, atan2, cos, exp, hex, int, log, oct, rand, sin, sqrt,
95 srand
96
97 =item Functions for real @ARRAYs
98
99 pop, push, shift, splice, unshift
100
101 =item Functions for list data
102
103 grep, join, map, qw/STRING/, reverse, sort, unpack
104
105 =item Functions for real %HASHes
106
107 delete, each, exists, keys, values
108
109 =item Input and output functions
110
111 binmode, close, closedir, dbmclose, dbmopen, die, eof,
112 fileno, flock, format, getc, print, printf, read, readdir,
113 rewinddir, seek, seekdir, select, syscall, sysread,
114 syswrite, tell, telldir, truncate, warn, write
115
116 =item Functions for fixed length data or records
117
118 pack, read, syscall, sysread, syswrite, unpack, vec
119
120 =item Functions for filehandles, files, or directories
121
122 I<-X>, chdir, chmod, chown, chroot, fcntl, glob, ioctl, link,
123 lstat, mkdir, open, opendir, readlink, rename, rmdir,
124 stat, symlink, umask, unlink, utime
125
126 =item Keywords related to the control flow of your perl program
127
128 caller, continue, die, do, dump, eval, exit, goto, last,
129 next, redo, return, sub, wantarray
130
131 =item Keywords related to scoping 
132
133 caller, import, local, my, package, use
134
135 =item Miscellaneous functions
136
137 defined, dump, eval, formline, local, my, reset, scalar,
138 undef, wantarray
139
140 =item Functions for processes and process groups
141
142 alarm, exec, fork, getpgrp, getppid, getpriority, kill,
143 pipe, qx/STRING/, setpgrp, setpriority, sleep, system,
144 times, wait, waitpid
145
146 =item Keywords related to perl modules
147
148 do, import, no, package, require, use
149
150 =item Keywords related to classes and object-orientedness
151
152 bless, dbmclose, dbmopen, package, ref, tie, tied, untie, use
153
154 =item Low-level socket functions
155
156 accept, bind, connect, getpeername, getsockname,
157 getsockopt, listen, recv, send, setsockopt, shutdown,
158 socket, socketpair
159
160 =item System V interprocess communication functions
161
162 msgctl, msgget, msgrcv, msgsnd, semctl, semget, semop,
163 shmctl, shmget, shmread, shmwrite
164
165 =item Fetching user and group info
166
167 endgrent, endhostent, endnetent, endpwent, getgrent,
168 getgrgid, getgrnam, getlogin, getpwent, getpwnam,
169 getpwuid, setgrent, setpwent
170
171 =item Fetching network info
172
173 endprotoent, endservent, gethostbyaddr, gethostbyname,
174 gethostent, getnetbyaddr, getnetbyname, getnetent,
175 getprotobyname, getprotobynumber, getprotoent,
176 getservbyname, getservbyport, getservent, sethostent,
177 setnetent, setprotoent, setservent
178
179 =item Time-related functions
180
181 gmtime, localtime, time, times
182
183 =item Functions new in perl5
184
185 abs, bless, chomp, chr, exists, formline, glob, import, lc,
186 lcfirst, map, my, no, prototype, qx, qw, readline, readpipe,
187 ref, sub*, sysopen, tie, tied, uc, ucfirst, untie, use
188
189 * - C<sub> was a keyword in perl4, but in perl5 it is an
190 operator which can be used in expressions.
191
192 =item Functions obsoleted in perl5
193
194 dbmclose, dbmopen
195
196
197 =back
198
199 =head2 Alphabetical Listing of Perl Functions
200
201
202 =over 8
203
204 =item -X FILEHANDLE
205
206 =item -X EXPR
207
208 =item -X
209
210 A file test, where X is one of the letters listed below.  This unary
211 operator takes one argument, either a filename or a filehandle, and
212 tests the associated file to see if something is true about it.  If the
213 argument is omitted, tests $_, except for C<-t>, which tests STDIN.
214 Unless otherwise documented, it returns C<1> for TRUE and C<''> for FALSE, or
215 the undefined value if the file doesn't exist.  Despite the funny
216 names, precedence is the same as any other named unary operator, and
217 the argument may be parenthesized like any other unary operator.  The
218 operator may be any of:
219
220     -r  File is readable by effective uid/gid.
221     -w  File is writable by effective uid/gid.
222     -x  File is executable by effective uid/gid.
223     -o  File is owned by effective uid.
224
225     -R  File is readable by real uid/gid.
226     -W  File is writable by real uid/gid.
227     -X  File is executable by real uid/gid.
228     -O  File is owned by real uid.
229
230     -e  File exists.
231     -z  File has zero size.
232     -s  File has non-zero size (returns size).
233
234     -f  File is a plain file.
235     -d  File is a directory.
236     -l  File is a symbolic link.
237     -p  File is a named pipe (FIFO).
238     -S  File is a socket.
239     -b  File is a block special file.
240     -c  File is a character special file.
241     -t  Filehandle is opened to a tty.
242
243     -u  File has setuid bit set.
244     -g  File has setgid bit set.
245     -k  File has sticky bit set.
246
247     -T  File is a text file.
248     -B  File is a binary file (opposite of -T).
249
250     -M  Age of file in days when script started.
251     -A  Same for access time.
252     -C  Same for inode change time.
253
254 The interpretation of the file permission operators C<-r>, C<-R>, C<-w>,
255 C<-W>, C<-x>, and C<-X> is based solely on the mode of the file and the
256 uids and gids of the user.  There may be other reasons you can't actually
257 read, write or execute the file.  Also note that, for the superuser,
258 C<-r>, C<-R>, C<-w>, and C<-W> always return 1, and C<-x> and C<-X> return
259 1 if any execute bit is set in the mode.  Scripts run by the superuser may
260 thus need to do a stat() to determine the actual mode of the
261 file, or temporarily set the uid to something else.
262
263 Example:
264
265     while (<>) {
266         chop;
267         next unless -f $_;      # ignore specials
268         ...
269     }
270
271 Note that C<-s/a/b/> does not do a negated substitution.  Saying
272 C<-exp($foo)> still works as expected, however--only single letters
273 following a minus are interpreted as file tests.
274
275 The C<-T> and C<-B> switches work as follows.  The first block or so of the
276 file is examined for odd characters such as strange control codes or
277 characters with the high bit set.  If too many odd characters (E<gt>30%)
278 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
279 containing null in the first block is considered a binary file.  If C<-T>
280 or C<-B> is used on a filehandle, the current stdio buffer is examined
281 rather than the first block.  Both C<-T> and C<-B> return TRUE on a null
282 file, or a file at EOF when testing a filehandle.  Because you have to 
283 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
284 against the file first, as in C<next unless -f $file && -T $file>.
285
286 If any of the file tests (or either the stat() or lstat() operators) are given the
287 special filehandle consisting of a solitary underline, then the stat
288 structure of the previous file test (or stat operator) is used, saving
289 a system call.  (This doesn't work with C<-t>, and you need to remember
290 that lstat() and C<-l> will leave values in the stat structure for the
291 symbolic link, not the real file.)  Example:
292
293     print "Can do.\n" if -r $a || -w _ || -x _;
294
295     stat($filename);
296     print "Readable\n" if -r _;
297     print "Writable\n" if -w _;
298     print "Executable\n" if -x _;
299     print "Setuid\n" if -u _;
300     print "Setgid\n" if -g _;
301     print "Sticky\n" if -k _;
302     print "Text\n" if -T _;
303     print "Binary\n" if -B _;
304
305 =item abs VALUE
306
307 =item abs 
308
309 Returns the absolute value of its argument.
310 If VALUE is omitted, uses $_.
311
312 =item accept NEWSOCKET,GENERICSOCKET
313
314 Accepts an incoming socket connect, just as the accept(2) system call
315 does.  Returns the packed address if it succeeded, FALSE otherwise.
316 See example in L<perlipc/"Sockets: Client/Server Communication">.
317
318 =item alarm SECONDS
319
320 =item alarm 
321
322 Arranges to have a SIGALRM delivered to this process after the
323 specified number of seconds have elapsed.  If SECONDS is not specified,
324 the value stored in $_ is used. (On some machines,
325 unfortunately, the elapsed time may be up to one second less than you
326 specified because of how seconds are counted.)  Only one timer may be
327 counting at once.  Each call disables the previous timer, and an
328 argument of 0 may be supplied to cancel the previous timer without
329 starting a new one.  The returned value is the amount of time remaining
330 on the previous timer.
331
332 For delays of finer granularity than one second, you may use Perl's
333 syscall() interface to access setitimer(2) if your system supports it, 
334 or else see L</select()> below.  It is not advised to intermix alarm() 
335 and sleep() calls.
336
337 If you want to use alarm() to time out a system call you need to use an
338 eval/die pair. You can't rely on the alarm causing the system call to
339 fail with $! set to EINTR because Perl sets up signal handlers to
340 restart system calls on some systems.  Using eval/die always works.
341
342     eval {
343         local $SIG{ALRM} = sub { die "alarm\n" };       # NB \n required
344         alarm $timeout;
345         $nread = sysread SOCKET, $buffer, $size;
346         alarm 0;
347     };
348     die if $@ && $@ ne "alarm\n";       # propagate errors
349     if ($@) {
350         # timed out
351     }
352     else {
353         # didn't
354     }
355
356 =item atan2 Y,X
357
358 Returns the arctangent of Y/X in the range -PI to PI.
359
360 =item bind SOCKET,NAME
361
362 Binds a network address to a socket, just as the bind system call
363 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
364 packed address of the appropriate type for the socket.  See the examples in
365 L<perlipc/"Sockets: Client/Server Communication">.
366
367 =item binmode FILEHANDLE
368
369 Arranges for the file to be read or written in "binary" mode in operating
370 systems that distinguish between binary and text files.  Files that are
371 not in binary mode have CR LF sequences translated to LF on input and LF
372 translated to CR LF on output.  Binmode has no effect under Unix; in DOS
373 and similarly archaic systems, it may be imperative--otherwise your
374 DOS-damaged C library may mangle your file.  The key distinction between
375 systems that need binmode and those that don't is their text file
376 formats.  Systems like Unix and Plan9 that delimit lines with a single
377 character, and that encode that character in C as '\n', do not need
378 C<binmode>.  The rest need it.  If FILEHANDLE is an expression, the value
379 is taken as the name of the filehandle.
380
381 =item bless REF,CLASSNAME
382
383 =item bless REF
384
385 This function tells the referenced object (passed as REF) that it is now
386 an object in the CLASSNAME package--or the current package if no CLASSNAME
387 is specified, which is often the case.  It returns the reference for
388 convenience, because a bless() is often the last thing in a constructor.
389 Always use the two-argument version if the function doing the blessing
390 might be inherited by a derived class.  See L<perlobj> for more about the
391 blessing (and blessings) of objects.
392
393 =item caller EXPR
394
395 =item caller
396
397 Returns the context of the current subroutine call.  In a scalar context,
398 returns TRUE if there is a caller, that is, if we're in a subroutine or
399 eval() or require(), and FALSE otherwise.  In a list context, returns
400
401     ($package, $filename, $line) = caller;
402
403 With EXPR, it returns some extra information that the debugger uses to
404 print a stack trace.  The value of EXPR indicates how many call frames
405 to go back before the current one.
406
407     ($package, $filename, $line,
408      $subroutine, $hasargs, $wantargs) = caller($i);
409
410 Furthermore, when called from within the DB package, caller returns more
411 detailed information: it sets the list variable @DB::args to be the
412 arguments with which that subroutine was invoked.
413
414 =item chdir EXPR
415
416 Changes the working directory to EXPR, if possible.  If EXPR is
417 omitted, changes to home directory.  Returns TRUE upon success, FALSE
418 otherwise.  See example under die().
419
420 =item chmod LIST
421
422 Changes the permissions of a list of files.  The first element of the
423 list must be the numerical mode, which should probably be an octal
424 number.  Returns the number of files successfully changed.
425
426     $cnt = chmod 0755, 'foo', 'bar';
427     chmod 0755, @executables;
428
429 =item chomp VARIABLE
430
431 =item chomp LIST
432
433 =item chomp
434
435 This is a slightly safer version of chop (see below).  It removes any
436 line ending that corresponds to the current value of C<$/> (also known as
437 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the number
438 of characters removed.  It's often used to remove the newline from the
439 end of an input record when you're worried that the final record may be
440 missing its newline.  When in paragraph mode (C<$/ = "">), it removes all
441 trailing newlines from the string.  If VARIABLE is omitted, it chomps
442 $_.  Example:
443
444     while (<>) {
445         chomp;  # avoid \n on last field
446         @array = split(/:/);
447         ...
448     }
449
450 You can actually chomp anything that's an lvalue, including an assignment:
451
452     chomp($cwd = `pwd`);
453     chomp($answer = <STDIN>);
454
455 If you chomp a list, each element is chomped, and the total number of
456 characters removed is returned.
457
458 =item chop VARIABLE
459
460 =item chop LIST
461
462 =item chop
463
464 Chops off the last character of a string and returns the character
465 chopped.  It's used primarily to remove the newline from the end of an
466 input record, but is much more efficient than C<s/\n//> because it neither
467 scans nor copies the string.  If VARIABLE is omitted, chops $_.
468 Example:
469
470     while (<>) {
471         chop;   # avoid \n on last field
472         @array = split(/:/);
473         ...
474     }
475
476 You can actually chop anything that's an lvalue, including an assignment:
477
478     chop($cwd = `pwd`);
479     chop($answer = <STDIN>);
480
481 If you chop a list, each element is chopped.  Only the value of the
482 last chop is returned.
483
484 Note that chop returns the last character.  To return all but the last
485 character, use C<substr($string, 0, -1)>.
486
487 =item chown LIST
488
489 Changes the owner (and group) of a list of files.  The first two
490 elements of the list must be the I<NUMERICAL> uid and gid, in that order.
491 Returns the number of files successfully changed.
492
493     $cnt = chown $uid, $gid, 'foo', 'bar';
494     chown $uid, $gid, @filenames;
495
496 Here's an example that looks up non-numeric uids in the passwd file:
497
498     print "User: ";
499     chop($user = <STDIN>);
500     print "Files: "
501     chop($pattern = <STDIN>);
502
503     ($login,$pass,$uid,$gid) = getpwnam($user)
504         or die "$user not in passwd file";
505
506     @ary = <${pattern}>;        # expand filenames
507     chown $uid, $gid, @ary;
508
509 On most systems, you are not allowed to change the ownership of the 
510 file unless you're the superuser, although you should be able to change
511 the group to any of your secondary groups.  On insecure systems, these
512 restrictions may be relaxed, but this is not a portable assumption.
513
514 =item chr NUMBER
515
516 =item chr 
517
518 Returns the character represented by that NUMBER in the character set.
519 For example, C<chr(65)> is "A" in ASCII.
520
521 If NUMBER is omitted, uses $_.
522
523 =item chroot FILENAME
524
525 =item chroot 
526
527 This function works as the system call by the same name: it makes the
528 named directory the new root directory for all further pathnames that
529 begin with a "/" by your process and all of its children.  (It doesn't
530 change your current working directory is unaffected.)  For security
531 reasons, this call is restricted to the superuser.  If FILENAME is
532 omitted, does chroot to $_.
533
534 =item close FILEHANDLE
535
536 Closes the file or pipe associated with the file handle, returning TRUE
537 only if stdio successfully flushes buffers and closes the system file
538 descriptor.  You don't have to close FILEHANDLE if you are immediately
539 going to do another open() on it, because open() will close it for you.  (See
540 open().)  However, an explicit close on an input file resets the line
541 counter ($.), while the implicit close done by open() does not.  Also,
542 closing a pipe will wait for the process executing on the pipe to
543 complete, in case you want to look at the output of the pipe
544 afterwards.  Closing a pipe explicitly also puts the status value of
545 the command into C<$?>.  Example:
546
547     open(OUTPUT, '|sort >foo'); # pipe to sort
548     ...                         # print stuff to output
549     close OUTPUT;               # wait for sort to finish
550     open(INPUT, 'foo');         # get sort's results
551
552 FILEHANDLE may be an expression whose value gives the real filehandle name.
553
554 =item closedir DIRHANDLE
555
556 Closes a directory opened by opendir().
557
558 =item connect SOCKET,NAME
559
560 Attempts to connect to a remote socket, just as the connect system call
561 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
562 packed address of the appropriate type for the socket.  See the examples in
563 L<perlipc/"Sockets: Client/Server Communication">.
564
565 =item continue BLOCK
566
567 Actually a flow control statement rather than a function.  If there is a
568 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
569 C<foreach>), it is always executed just before the conditional is about to
570 be evaluated again, just like the third part of a C<for> loop in C.  Thus
571 it can be used to increment a loop variable, even when the loop has been
572 continued via the C<next> statement (which is similar to the C C<continue>
573 statement).
574
575 =item cos EXPR
576
577 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted
578 takes cosine of $_.
579
580 =item crypt PLAINTEXT,SALT
581
582 Encrypts a string exactly like the crypt(3) function in the C library
583 (assuming that you actually have a version there that has not been
584 extirpated as a potential munition).  This can prove useful for checking
585 the password file for lousy passwords, amongst other things.  Only the
586 guys wearing white hats should do this.
587
588 Here's an example that makes sure that whoever runs this program knows
589 their own password:
590
591     $pwd = (getpwuid($<))[1];
592     $salt = substr($pwd, 0, 2);
593
594     system "stty -echo";
595     print "Password: ";
596     chop($word = <STDIN>);
597     print "\n";
598     system "stty echo";
599
600     if (crypt($word, $salt) ne $pwd) {
601         die "Sorry...\n";
602     } else {
603         print "ok\n";
604     } 
605
606 Of course, typing in your own password to whomever asks you 
607 for it is unwise.
608
609 =item dbmclose ASSOC_ARRAY
610
611 [This function has been superseded by the untie() function.]
612
613 Breaks the binding between a DBM file and an associative array.
614
615 =item dbmopen ASSOC,DBNAME,MODE
616
617 [This function has been superseded by the tie() function.]
618
619 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(), or Berkeley DB file to an
620 associative array.  ASSOC is the name of the associative array.  (Unlike
621 normal open, the first argument is I<NOT> a filehandle, even though it
622 looks like one).  DBNAME is the name of the database (without the F<.dir>
623 or F<.pag> extension if any).  If the database does not exist, it is
624 created with protection specified by MODE (as modified by the umask()).
625 If your system supports only the older DBM functions, you may perform only
626 one dbmopen() in your program.  In older versions of Perl, if your system
627 had neither DBM nor ndbm, calling dbmopen() produced a fatal error; it now
628 falls back to sdbm(3).
629
630 If you don't have write access to the DBM file, you can only read
631 associative array variables, not set them.  If you want to test whether
632 you can write, either use file tests or try setting a dummy array entry
633 inside an eval(), which will trap the error.
634
635 Note that functions such as keys() and values() may return huge array
636 values when used on large DBM files.  You may prefer to use the each()
637 function to iterate over large DBM files.  Example:
638
639     # print out history file offsets
640     dbmopen(%HIST,'/usr/lib/news/history',0666);
641     while (($key,$val) = each %HIST) {
642         print $key, ' = ', unpack('L',$val), "\n";
643     }
644     dbmclose(%HIST);
645
646 See also L<AnyDBM_File> for a more general description of the pros and
647 cons of the various dbm approaches, as well as L<DB_File> for a particularly
648 rich implementation.
649
650 =item defined EXPR
651
652 =item defined 
653
654 Returns a boolean value saying whether EXPR has a real value
655 or not. If EXPR is not present, $_ will be checked. Many operations
656 return the undefined value under exceptional conditions, such as end of
657 file, uninitialized variable, system error and such.  This function
658 allows you to distinguish between an undefined
659 null scalar and a defined null scalar with operations that might return
660 a real null string, such as referencing elements of an array.  You may
661 also check to see if arrays or subroutines exist.  Use of defined on
662 predefined variables is not guaranteed to produce intuitive results.
663
664 When used on a hash array element, it tells you whether the value
665 is defined, not whether the key exists in the hash.  Use exists() for that.
666
667 Examples:
668
669     print if defined $switch{'D'};
670     print "$val\n" while defined($val = pop(@ary));
671     die "Can't readlink $sym: $!"
672         unless defined($value = readlink $sym);
673     eval '@foo = ()' if defined(@foo);
674     die "No XYZ package defined" unless defined %_XYZ;
675     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
676
677 See also undef().
678
679 Note: many folks tend to overuse defined(), and then are surprised to
680 discover that the number 0 and the null string are, in fact, defined
681 concepts.  For example, if you say
682
683     "ab" =~ /a(.*)b/;
684
685 the pattern match succeeds, and $1 is defined, despite the fact that it
686 matched "nothing".  But it didn't really match nothing--rather, it
687 matched something that happened to be 0 characters long.  This is all
688 very above-board and honest.  When a function returns an undefined value,
689 it's an admission that it couldn't give you an honest answer.  So
690 you should use defined() only when you're questioning the integrity
691 of what you're trying to do.  At other times, a simple comparison to
692 0 or "" is what you want.
693
694 =item delete EXPR
695
696 Deletes the specified key(s) and their associated values from a hash
697 array.  For each key, returns the deleted value associated with that key,
698 or the undefined value if there was no such key.  Deleting from C<$ENV{}>
699 modifies the environment.  Deleting from an array tied to a DBM file
700 deletes the entry from the DBM file.  (But deleting from a tie()d hash
701 doesn't necessarily return anything.)
702
703 The following deletes all the values of an associative array:
704
705     foreach $key (keys %HASH) {
706         delete $HASH{$key};
707     }
708
709 And so does this:
710
711     delete @HASH{keys %HASH}
712
713 (But both of these are slower than the undef() command.)  Note that the
714 EXPR can be arbitrarily complicated as long as the final operation is a
715 hash element lookup or hash slice:
716
717     delete $ref->[$x][$y]{$key};
718     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
719
720 =item die LIST
721
722 Outside of an eval(), prints the value of LIST to C<STDERR> and exits with
723 the current value of C<$!> (errno).  If C<$!> is 0, exits with the value of
724 C<($? E<gt>E<gt> 8)> (back-tick `command` status).  If C<($? E<gt>E<gt> 8)> is 0,
725 exits with 255.  Inside an eval(), the error message is stuffed into C<$@>,
726 and the eval() is terminated with the undefined value; this makes die()
727 the way to raise an exception.
728
729 Equivalent examples:
730
731     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
732     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n" 
733
734 If the value of EXPR does not end in a newline, the current script line
735 number and input line number (if any) are also printed, and a newline
736 is supplied.  Hint: sometimes appending ", stopped" to your message
737 will cause it to make better sense when the string "at foo line 123" is
738 appended.  Suppose you are running script "canasta".
739
740     die "/etc/games is no good";
741     die "/etc/games is no good, stopped";
742
743 produce, respectively
744
745     /etc/games is no good at canasta line 123.
746     /etc/games is no good, stopped at canasta line 123.
747
748 See also exit() and warn().
749
750 =item do BLOCK
751
752 Not really a function.  Returns the value of the last command in the
753 sequence of commands indicated by BLOCK.  When modified by a loop
754 modifier, executes the BLOCK once before testing the loop condition.
755 (On other statements the loop modifiers test the conditional first.)
756
757 =item do SUBROUTINE(LIST)
758
759 A deprecated form of subroutine call.  See L<perlsub>.
760
761 =item do EXPR
762
763 Uses the value of EXPR as a filename and executes the contents of the
764 file as a Perl script.  Its primary use is to include subroutines
765 from a Perl subroutine library.
766
767     do 'stat.pl';
768
769 is just like
770
771     eval `cat stat.pl`;
772
773 except that it's more efficient, more concise, keeps track of the
774 current filename for error messages, and searches all the B<-I>
775 libraries if the file isn't in the current directory (see also the @INC
776 array in L<perlvar/Predefined Names>).  It's the same, however, in that it does
777 re-parse the file every time you call it, so you probably don't want to
778 do this inside a loop.
779
780 Note that inclusion of library modules is better done with the
781 use() and require() operators, which also do error checking
782 and raise an exception if there's a problem.
783
784 =item dump LABEL
785
786 This causes an immediate core dump.  Primarily this is so that you can
787 use the B<undump> program to turn your core dump into an executable binary
788 after having initialized all your variables at the beginning of the
789 program.  When the new binary is executed it will begin by executing a
790 C<goto LABEL> (with all the restrictions that C<goto> suffers).  Think of
791 it as a goto with an intervening core dump and reincarnation.  If LABEL
792 is omitted, restarts the program from the top.  WARNING: any files
793 opened at the time of the dump will NOT be open any more when the
794 program is reincarnated, with possible resulting confusion on the part
795 of Perl.  See also B<-u> option in L<perlrun>.
796
797 Example:
798
799     #!/usr/bin/perl
800     require 'getopt.pl';
801     require 'stat.pl';
802     %days = (
803         'Sun' => 1,
804         'Mon' => 2,
805         'Tue' => 3,
806         'Wed' => 4,
807         'Thu' => 5,
808         'Fri' => 6,
809         'Sat' => 7,
810     );
811
812     dump QUICKSTART if $ARGV[0] eq '-d';
813
814     QUICKSTART:
815     Getopt('f');
816
817 =item each ASSOC_ARRAY
818
819 When called in a list context, returns a 2-element array consisting
820 of the key and value for the next element of an associative array,
821 so that you can iterate over it.  When called in a scalar context,
822 returns the key for only the next element in the associative array.
823 Entries are returned in an apparently random order.  When the array is
824 entirely read, a null array is returned in list context (which when
825 assigned produces a FALSE (0) value), and C<undef> is returned in a
826 scalar context.  The next call to each() after that will start
827 iterating again.  The iterator can be reset only by reading all the
828 elements from the array.  You should not add elements to an array while
829 you're iterating over it.  There is a single iterator for each
830 associative array, shared by all each(), keys(), and values() function
831 calls in the program.  The following prints out your environment like
832 the printenv(1) program, only in a different order:
833
834     while (($key,$value) = each %ENV) {
835         print "$key=$value\n";
836     }
837
838 See also keys() and values().
839
840 =item eof FILEHANDLE
841
842 =item eof ()
843
844 =item eof
845
846 Returns 1 if the next read on FILEHANDLE will return end of file, or if
847 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
848 gives the real filehandle name.  (Note that this function actually
849 reads a character and then ungetc()s it, so it is not very useful in an
850 interactive context.)  Do not read from a terminal file (or call
851 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  Filetypes such
852 as terminals may lose the end-of-file condition if you do.
853
854 An C<eof> without an argument uses the last file read as argument.
855 Empty parentheses () may be used to indicate
856 the pseudo file formed of the files listed on the command line, i.e.,
857 C<eof()> is reasonable to use inside a while (E<lt>E<gt>) loop to detect the end
858 of only the last file.  Use C<eof(ARGV)> or eof without the parentheses to
859 test I<EACH> file in a while (E<lt>E<gt>) loop.  Examples:
860
861     # reset line numbering on each input file
862     while (<>) {
863         print "$.\t$_";
864         close(ARGV) if (eof);   # Not eof().
865     }
866
867     # insert dashes just before last line of last file
868     while (<>) {
869         if (eof()) {
870             print "--------------\n";
871             close(ARGV);        # close or break; is needed if we
872                                 # are reading from the terminal
873         }
874         print;
875     }
876
877 Practical hint: you almost never need to use C<eof> in Perl, because the
878 input operators return undef when they run out of data.  
879
880 =item eval EXPR
881
882 =item eval BLOCK
883
884 EXPR is parsed and executed as if it were a little Perl program.  It
885 is executed in the context of the current Perl program, so that any
886 variable settings or subroutine and format definitions remain afterwards.
887 The value returned is the value of the last expression evaluated, or a
888 return statement may be used, just as with subroutines.  The last
889 expression is evaluated in scalar or array context, depending on the
890 context of the eval.
891
892 If there is a syntax error or runtime error, or a die() statement is
893 executed, an undefined value is returned by eval(), and C<$@> is set to the
894 error message.  If there was no error, C<$@> is guaranteed to be a null
895 string.  If EXPR is omitted, evaluates $_.  The final semicolon, if
896 any, may be omitted from the expression.
897
898 Note that, because eval() traps otherwise-fatal errors, it is useful for
899 determining whether a particular feature (such as socket() or symlink())
900 is implemented.  It is also Perl's exception trapping mechanism, where
901 the die operator is used to raise exceptions.
902
903 If the code to be executed doesn't vary, you may use the eval-BLOCK
904 form to trap run-time errors without incurring the penalty of
905 recompiling each time.  The error, if any, is still returned in C<$@>.
906 Examples:
907
908     # make divide-by-zero non-fatal
909     eval { $answer = $a / $b; }; warn $@ if $@;
910
911     # same thing, but less efficient
912     eval '$answer = $a / $b'; warn $@ if $@;
913
914     # a compile-time error
915     eval { $answer = };
916
917     # a run-time error
918     eval '$answer =';   # sets $@
919
920 With an eval(), you should be especially careful to remember what's 
921 being looked at when:
922
923     eval $x;            # CASE 1
924     eval "$x";          # CASE 2
925
926     eval '$x';          # CASE 3
927     eval { $x };        # CASE 4
928
929     eval "\$$x++"       # CASE 5
930     $$x++;              # CASE 6
931
932 Cases 1 and 2 above behave identically: they run the code contained in the
933 variable $x.  (Although case 2 has misleading double quotes making the
934 reader wonder what else might be happening (nothing is).) Cases 3 and 4
935 likewise behave in the same way: they run the code E<lt>$xE<gt>, which does
936 nothing at all.  (Case 4 is preferred for purely visual reasons.) Case 5
937 is a place where normally you I<WOULD> like to use double quotes, except
938 that in that particular situation, you can just use symbolic references
939 instead, as in case 6.
940
941 =item exec LIST
942
943 The exec() function executes a system command I<AND NEVER RETURNS>,
944 unless the command does not exist and is executed directly instead of
945 via C</bin/sh -c> (see below).  Use system() instead of exec() if you
946 want it to return.
947
948 If there is more than one argument in LIST, or if LIST is an array with
949 more than one value, calls execvp(3) with the arguments in LIST.  If
950 there is only one scalar argument, the argument is checked for shell
951 metacharacters.  If there are any, the entire argument is passed to
952 C</bin/sh -c> for parsing.  If there are none, the argument is split
953 into words and passed directly to execvp(), which is more efficient.
954 Note: exec() and system() do not flush your output buffer, so you may
955 need to set C<$|> to avoid lost output.  Examples:
956
957     exec '/bin/echo', 'Your arguments are: ', @ARGV;
958     exec "sort $outfile | uniq";
959
960 If you don't really want to execute the first argument, but want to lie
961 to the program you are executing about its own name, you can specify
962 the program you actually want to run as an "indirect object" (without a
963 comma) in front of the LIST.  (This always forces interpretation of the
964 LIST as a multi-valued list, even if there is only a single scalar in
965 the list.)  Example:
966
967     $shell = '/bin/csh';
968     exec $shell '-sh';          # pretend it's a login shell
969
970 or, more directly,
971
972     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
973
974 =item exists EXPR
975
976 Returns TRUE if the specified hash key exists in its hash array, even
977 if the corresponding value is undefined.
978
979     print "Exists\n" if exists $array{$key};
980     print "Defined\n" if defined $array{$key};
981     print "True\n" if $array{$key};
982
983 A hash element can be TRUE only if it's defined, and defined if
984 it exists, but the reverse doesn't necessarily hold true.
985
986 Note that the EXPR can be arbitrarily complicated as long as the final
987 operation is a hash key lookup:
988
989     if (exists $ref->[$x][$y]{$key}) { ... }
990
991 =item exit EXPR
992
993 Evaluates EXPR and exits immediately with that value.  (Actually, it
994 calls any defined C<END> routines first, but the C<END> routines may not
995 abort the exit.  Likewise any object destructors that need to be called
996 are called before exit.)  Example:
997
998     $ans = <STDIN>;
999     exit 0 if $ans =~ /^[Xx]/;
1000
1001 See also die().  If EXPR is omitted, exits with 0 status.
1002
1003 =item exp EXPR
1004
1005 =item exp 
1006
1007 Returns I<e> (the natural logarithm base) to the power of EXPR.  
1008 If EXPR is omitted, gives C<exp($_)>.
1009
1010 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1011
1012 Implements the fcntl(2) function.  You'll probably have to say
1013
1014     use Fcntl;
1015
1016 first to get the correct function definitions.  Argument processing and
1017 value return works just like ioctl() below.  Note that fcntl() will produce
1018 a fatal error if used on a machine that doesn't implement fcntl(2).
1019 For example:
1020
1021     use Fcntl;
1022     fcntl($filehandle, F_GETLK, $packed_return_buffer);
1023
1024 =item fileno FILEHANDLE
1025
1026 Returns the file descriptor for a filehandle.  This is useful for
1027 constructing bitmaps for select().  If FILEHANDLE is an expression, the
1028 value is taken as the name of the filehandle.
1029
1030 =item flock FILEHANDLE,OPERATION
1031
1032 Calls flock(2) on FILEHANDLE.  See L<flock(2)> for definition of
1033 OPERATION.  Returns TRUE for success, FALSE on failure.  Will produce a
1034 fatal error if used on a machine that doesn't implement either flock(2) or
1035 fcntl(2). The fcntl(2) system call will be automatically used if flock(2)
1036 is missing from your system.  This makes flock() the portable file locking
1037 strategy, although it will lock only entire files, not records.  Note also
1038 that some versions of flock() cannot lock things over the network; you
1039 would need to use the more system-specific fcntl() for that.
1040
1041 Here's a mailbox appender for BSD systems.
1042
1043     use Fcntl ':flock'; # import LOCK_* constants
1044
1045     sub lock {
1046         flock(MBOX,LOCK_EX);
1047         # and, in case someone appended
1048         # while we were waiting...
1049         seek(MBOX, 0, 2);
1050     }
1051
1052     sub unlock {
1053         flock(MBOX,LOCK_UN);
1054     }
1055
1056     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1057             or die "Can't open mailbox: $!";
1058
1059     lock();
1060     print MBOX $msg,"\n\n";
1061     unlock();
1062
1063 See also L<DB_File> for other flock() examples.
1064
1065 =item fork
1066
1067 Does a fork(2) system call.  Returns the child pid to the parent process
1068 and 0 to the child process, or C<undef> if the fork is unsuccessful.
1069 Note: unflushed buffers remain unflushed in both processes, which means
1070 you may need to set C<$|> ($AUTOFLUSH in English) or call the 
1071 autoflush() FileHandle method to avoid duplicate output.
1072
1073 If you fork() without ever waiting on your children, you will accumulate
1074 zombies:
1075
1076     $SIG{CHLD} = sub { wait };
1077
1078 There's also the double-fork trick (error checking on 
1079 fork() returns omitted);
1080
1081     unless ($pid = fork) {
1082         unless (fork) {
1083             exec "what you really wanna do";
1084             die "no exec";
1085             # ... or ...
1086             ## (some_perl_code_here)
1087             exit 0;
1088         }
1089         exit 0;
1090     }
1091     waitpid($pid,0);
1092
1093 See also L<perlipc> for more examples of forking and reaping
1094 moribund children.
1095
1096 =item format
1097
1098 Declare a picture format with use by the write() function.  For
1099 example:
1100
1101     format Something = 
1102         Test: @<<<<<<<< @||||| @>>>>>
1103               $str,     $%,    '$' . int($num)
1104     .
1105
1106     $str = "widget";
1107     $num = $cost/$quantity;
1108     $~ = 'Something';
1109     write;
1110
1111 See L<perlform> for many details and examples.
1112
1113
1114 =item formline PICTURE, LIST
1115
1116 This is an internal function used by C<format>s, though you may call it
1117 too.  It formats (see L<perlform>) a list of values according to the
1118 contents of PICTURE, placing the output into the format output
1119 accumulator, C<$^A> (or $ACCUMULATOR in English).
1120 Eventually, when a write() is done, the contents of
1121 C<$^A> are written to some filehandle, but you could also read C<$^A>
1122 yourself and then set C<$^A> back to "".  Note that a format typically
1123 does one formline() per line of form, but the formline() function itself
1124 doesn't care how many newlines are embedded in the PICTURE.  This means
1125 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1126 You may therefore need to use multiple formlines to implement a single
1127 record format, just like the format compiler.
1128
1129 Be careful if you put double quotes around the picture, because an "C<@>"
1130 character may be taken to mean the beginning of an array name.
1131 formline() always returns TRUE.  See L<perlform> for other examples.
1132
1133 =item getc FILEHANDLE
1134
1135 =item getc
1136
1137 Returns the next character from the input file attached to FILEHANDLE,
1138 or a null string at end of file.  If FILEHANDLE is omitted, reads from STDIN.
1139 This is not particularly efficient.  It cannot be used to get unbuffered
1140 single-characters, however.  For that, try something more like:
1141
1142     if ($BSD_STYLE) {
1143         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1144     }
1145     else {
1146         system "stty", '-icanon', 'eol', "\001"; 
1147     }
1148
1149     $key = getc(STDIN);
1150
1151     if ($BSD_STYLE) {
1152         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1153     }
1154     else {
1155         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1156     }
1157     print "\n";
1158
1159 Determination of whether to whether $BSD_STYLE should be set 
1160 is left as an exercise to the reader.  
1161
1162 See also the C<Term::ReadKey> module from your nearest CPAN site;
1163 details on CPAN can be found on L<perlmod/CPAN> 
1164
1165 =item getlogin
1166
1167 Returns the current login from F</etc/utmp>, if any.  If null, use
1168 getpwuid().  
1169
1170     $login = getlogin || (getpwuid($<))[0] || "Kilroy";
1171
1172 Do not consider getlogin() for authentication: it is not as
1173 secure as getpwuid().
1174
1175 =item getpeername SOCKET
1176
1177 Returns the packed sockaddr address of other end of the SOCKET connection.
1178
1179     use Socket;
1180     $hersockaddr    = getpeername(SOCK);
1181     ($port, $iaddr) = unpack_sockaddr_in($hersockaddr);
1182     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1183     $herstraddr     = inet_ntoa($iaddr);
1184
1185 =item getpgrp PID
1186
1187 Returns the current process group for the specified PID.  Use
1188 a PID of 0 to get the current process group for the
1189 current process.  Will raise an exception if used on a machine that
1190 doesn't implement getpgrp(2).  If PID is omitted, returns process
1191 group of current process.  Note that the POSIX version of getpgrp()
1192 does not accept a PID argument, so only PID==0 is truly portable.
1193
1194 =item getppid
1195
1196 Returns the process id of the parent process.
1197
1198 =item getpriority WHICH,WHO
1199
1200 Returns the current priority for a process, a process group, or a user.
1201 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1202 machine that doesn't implement getpriority(2).
1203
1204 =item getpwnam NAME
1205
1206 =item getgrnam NAME
1207
1208 =item gethostbyname NAME
1209
1210 =item getnetbyname NAME
1211
1212 =item getprotobyname NAME
1213
1214 =item getpwuid UID
1215
1216 =item getgrgid GID
1217
1218 =item getservbyname NAME,PROTO
1219
1220 =item gethostbyaddr ADDR,ADDRTYPE
1221
1222 =item getnetbyaddr ADDR,ADDRTYPE
1223
1224 =item getprotobynumber NUMBER
1225
1226 =item getservbyport PORT,PROTO
1227
1228 =item getpwent
1229
1230 =item getgrent
1231
1232 =item gethostent
1233
1234 =item getnetent
1235
1236 =item getprotoent
1237
1238 =item getservent
1239
1240 =item setpwent
1241
1242 =item setgrent
1243
1244 =item sethostent STAYOPEN
1245
1246 =item setnetent STAYOPEN
1247
1248 =item setprotoent STAYOPEN
1249
1250 =item setservent STAYOPEN
1251
1252 =item endpwent
1253
1254 =item endgrent
1255
1256 =item endhostent
1257
1258 =item endnetent
1259
1260 =item endprotoent
1261
1262 =item endservent
1263
1264 These routines perform the same functions as their counterparts in the
1265 system library.  Within a list context, the return values from the
1266 various get routines are as follows:
1267
1268     ($name,$passwd,$uid,$gid,
1269        $quota,$comment,$gcos,$dir,$shell) = getpw*
1270     ($name,$passwd,$gid,$members) = getgr*
1271     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1272     ($name,$aliases,$addrtype,$net) = getnet*
1273     ($name,$aliases,$proto) = getproto*
1274     ($name,$aliases,$port,$proto) = getserv*
1275
1276 (If the entry doesn't exist you get a null list.)
1277
1278 Within a scalar context, you get the name, unless the function was a
1279 lookup by name, in which case you get the other thing, whatever it is.
1280 (If the entry doesn't exist you get the undefined value.)  For example:
1281
1282     $uid = getpwnam
1283     $name = getpwuid
1284     $name = getpwent
1285     $gid = getgrnam
1286     $name = getgrgid
1287     $name = getgrent
1288     etc.
1289
1290 The $members value returned by I<getgr*()> is a space separated list of
1291 the login names of the members of the group.
1292
1293 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1294 C, it will be returned to you via C<$?> if the function call fails.  The
1295 @addrs value returned by a successful call is a list of the raw
1296 addresses returned by the corresponding system library call.  In the
1297 Internet domain, each address is four bytes long and you can unpack it
1298 by saying something like:
1299
1300     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1301
1302 =item getsockname SOCKET
1303
1304 Returns the packed sockaddr address of this end of the SOCKET connection.
1305
1306     use Socket;
1307     $mysockaddr = getsockname(SOCK);
1308     ($port, $myaddr) = unpack_sockaddr_in($mysockaddr);
1309
1310 =item getsockopt SOCKET,LEVEL,OPTNAME
1311
1312 Returns the socket option requested, or undefined if there is an error.
1313
1314 =item glob EXPR
1315
1316 Returns the value of EXPR with filename expansions such as a shell
1317 would do.  This is the internal function implementing the E<lt>*.*E<gt>
1318 operator, except it's easier to use.
1319
1320 =item gmtime EXPR
1321
1322 Converts a time as returned by the time function to a 9-element array
1323 with the time localized for the standard Greenwich time zone.  
1324 Typically used as follows:
1325
1326
1327     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1328                                             gmtime(time);
1329
1330 All array elements are numeric, and come straight out of a struct tm.
1331 In particular this means that $mon has the range 0..11 and $wday has
1332 the range 0..6.  If EXPR is omitted, does C<gmtime(time())>.
1333
1334 =item goto LABEL
1335
1336 =item goto EXPR
1337
1338 =item goto &NAME
1339
1340 The goto-LABEL form finds the statement labeled with LABEL and resumes
1341 execution there.  It may not be used to go into any construct that
1342 requires initialization, such as a subroutine or a foreach loop.  It
1343 also can't be used to go into a construct that is optimized away.  It
1344 can be used to go almost anywhere else within the dynamic scope,
1345 including out of subroutines, but it's usually better to use some other
1346 construct such as last or die.  The author of Perl has never felt the
1347 need to use this form of goto (in Perl, that is--C is another matter).
1348
1349 The goto-EXPR form expects a label name, whose scope will be resolved
1350 dynamically.  This allows for computed gotos per FORTRAN, but isn't
1351 necessarily recommended if you're optimizing for maintainability:
1352
1353     goto ("FOO", "BAR", "GLARCH")[$i];
1354
1355 The goto-&NAME form is highly magical, and substitutes a call to the
1356 named subroutine for the currently running subroutine.  This is used by
1357 AUTOLOAD subroutines that wish to load another subroutine and then
1358 pretend that the other subroutine had been called in the first place
1359 (except that any modifications to @_ in the current subroutine are
1360 propagated to the other subroutine.)  After the goto, not even caller()
1361 will be able to tell that this routine was called first.
1362
1363 =item grep BLOCK LIST
1364
1365 =item grep EXPR,LIST
1366
1367 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1368 $_ to each element) and returns the list value consisting of those
1369 elements for which the expression evaluated to TRUE.  In a scalar
1370 context, returns the number of times the expression was TRUE.
1371
1372     @foo = grep(!/^#/, @bar);    # weed out comments
1373
1374 or equivalently,
1375
1376     @foo = grep {!/^#/} @bar;    # weed out comments
1377
1378 Note that, because $_ is a reference into the list value, it can be used
1379 to modify the elements of the array.  While this is useful and
1380 supported, it can cause bizarre results if the LIST is not a named
1381 array.
1382
1383 =item hex EXPR
1384
1385 =item hex 
1386
1387 Interprets EXPR as a hex string and returns the corresponding decimal
1388 value.  (To convert strings that might start with 0 or 0x see
1389 oct().)  If EXPR is omitted, uses $_.
1390
1391 =item import
1392
1393 There is no built-in import() function.  It is merely an ordinary
1394 method (subroutine) defined (or inherited) by modules that wish to export
1395 names to another module.  The use() function calls the import() method
1396 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
1397
1398 =item index STR,SUBSTR,POSITION
1399
1400 =item index STR,SUBSTR
1401
1402 Returns the position of the first occurrence of SUBSTR in STR at or after
1403 POSITION.  If POSITION is omitted, starts searching from the beginning of
1404 the string.  The return value is based at 0 (or whatever you've set the C<$[>
1405 variable to--but don't do that).  If the substring is not found, returns
1406 one less than the base, ordinarily -1.
1407
1408 =item int EXPR
1409
1410 =item int 
1411
1412 Returns the integer portion of EXPR.  If EXPR is omitted, uses $_.
1413
1414 =item ioctl FILEHANDLE,FUNCTION,SCALAR
1415
1416 Implements the ioctl(2) function.  You'll probably have to say
1417
1418     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
1419
1420 first to get the correct function definitions.  If F<ioctl.ph> doesn't
1421 exist or doesn't have the correct definitions you'll have to roll your
1422 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
1423 (There is a Perl script called B<h2ph> that comes with the Perl kit which
1424 may help you in this, but it's non-trivial.)  SCALAR will be read and/or
1425 written depending on the FUNCTION--a pointer to the string value of SCALAR
1426 will be passed as the third argument of the actual ioctl call.  (If SCALAR
1427 has no string value but does have a numeric value, that value will be
1428 passed rather than a pointer to the string value.  To guarantee this to be
1429 TRUE, add a 0 to the scalar before using it.)  The pack() and unpack()
1430 functions are useful for manipulating the values of structures used by
1431 ioctl().  The following example sets the erase character to DEL.
1432
1433     require 'ioctl.ph';
1434     $getp = &TIOCGETP;
1435     die "NO TIOCGETP" if $@ || !$getp;
1436     $sgttyb_t = "ccccs";                # 4 chars and a short
1437     if (ioctl(STDIN,$getp,$sgttyb)) {
1438         @ary = unpack($sgttyb_t,$sgttyb);
1439         $ary[2] = 127;
1440         $sgttyb = pack($sgttyb_t,@ary);
1441         ioctl(STDIN,&TIOCSETP,$sgttyb)
1442             || die "Can't ioctl: $!";
1443     }
1444
1445 The return value of ioctl (and fcntl) is as follows:
1446
1447         if OS returns:          then Perl returns:
1448             -1                    undefined value
1449              0                  string "0 but true"
1450         anything else               that number
1451
1452 Thus Perl returns TRUE on success and FALSE on failure, yet you can
1453 still easily determine the actual value returned by the operating
1454 system:
1455
1456     ($retval = ioctl(...)) || ($retval = -1);
1457     printf "System returned %d\n", $retval;
1458
1459 =item join EXPR,LIST
1460
1461 Joins the separate strings of LIST or ARRAY into a single string with
1462 fields separated by the value of EXPR, and returns the string.
1463 Example:
1464
1465     $_ = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
1466
1467 See L<perlfunc/split>.
1468
1469 =item keys ASSOC_ARRAY
1470
1471 Returns a normal array consisting of all the keys of the named
1472 associative array.  (In a scalar context, returns the number of keys.)
1473 The keys are returned in an apparently random order, but it is the same
1474 order as either the values() or each() function produces (given that
1475 the associative array has not been modified).  Here is yet another way
1476 to print your environment:
1477
1478     @keys = keys %ENV;
1479     @values = values %ENV;
1480     while ($#keys >= 0) {
1481         print pop(@keys), '=', pop(@values), "\n";
1482     }
1483
1484 or how about sorted by key:
1485
1486     foreach $key (sort(keys %ENV)) {
1487         print $key, '=', $ENV{$key}, "\n";
1488     }
1489
1490 To sort an array by value, you'll need to use a C<sort{}>
1491 function.  Here's a descending numeric sort of a hash by its values:
1492
1493     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash)) {
1494         printf "%4d %s\n", $hash{$key}, $key;
1495     }
1496
1497 As an lvalue C<keys> allows you to increase the number of hash buckets
1498 allocated for the given associative array.  This can gain you a measure
1499 of efficiency if you know the hash is going to get big.  (This is
1500 similar to pre-extending an array by assigning a larger number to
1501 $#array.)  If you say
1502
1503     keys %hash = 200;
1504
1505 then C<%hash> will have at least 200 buckets allocated for it.  These
1506 buckets will be retained even if you do C<%hash = ()>, use C<undef
1507 %hash> if you want to free the storage while C<%hash> is still in scope.
1508 You can't shrink the number of buckets allocated for the hash using
1509 C<keys> in this way (but you needn't worry about doing this by accident,
1510 as trying has no effect).
1511
1512 =item kill LIST
1513
1514 Sends a signal to a list of processes.  The first element of 
1515 the list must be the signal to send.  Returns the number of 
1516 processes successfully signaled.
1517
1518     $cnt = kill 1, $child1, $child2;
1519     kill 9, @goners;
1520
1521 Unlike in the shell, in Perl if the I<SIGNAL> is negative, it kills
1522 process groups instead of processes.  (On System V, a negative I<PROCESS>
1523 number will also kill process groups, but that's not portable.)  That
1524 means you usually want to use positive not negative signals.  You may also
1525 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
1526
1527 =item last LABEL
1528
1529 =item last
1530
1531 The C<last> command is like the C<break> statement in C (as used in
1532 loops); it immediately exits the loop in question.  If the LABEL is
1533 omitted, the command refers to the innermost enclosing loop.  The
1534 C<continue> block, if any, is not executed:
1535
1536     LINE: while (<STDIN>) {
1537         last LINE if /^$/;      # exit when done with header
1538         ...
1539     }
1540
1541 =item lc EXPR
1542
1543 =item lc 
1544
1545 Returns an lowercased version of EXPR.  This is the internal function
1546 implementing the \L escape in double-quoted strings.  
1547 Should respect any POSIX setlocale() settings.
1548
1549 If EXPR is omitted, uses $_.
1550
1551 =item lcfirst EXPR
1552
1553 =item lcfirst 
1554
1555 Returns the value of EXPR with the first character lowercased.  This is
1556 the internal function implementing the \l escape in double-quoted strings.
1557 Should respect any POSIX setlocale() settings.
1558
1559 If EXPR is omitted, uses $_.
1560
1561 =item length EXPR
1562
1563 =item length 
1564
1565 Returns the length in characters of the value of EXPR.  If EXPR is
1566 omitted, returns length of $_.
1567
1568 =item link OLDFILE,NEWFILE
1569
1570 Creates a new filename linked to the old filename.  Returns 1 for
1571 success, 0 otherwise.
1572
1573 =item listen SOCKET,QUEUESIZE
1574
1575 Does the same thing that the listen system call does.  Returns TRUE if
1576 it succeeded, FALSE otherwise.  See example in L<perlipc/"Sockets: Client/Server Communication">.
1577
1578 =item local EXPR
1579
1580 A local modifies the listed variables to be local to the enclosing block,
1581 subroutine, C<eval{}>, or C<do>.  If more than one value is listed, the
1582 list must be placed in parentheses.  See L<perlsub/"Temporary Values via
1583 local()"> for details.
1584
1585 But you really probably want to be using my() instead, because local() isn't
1586 what most people think of as "local").  See L<perlsub/"Private Variables
1587 via my()"> for details.
1588
1589 =item localtime EXPR
1590
1591 Converts a time as returned by the time function to a 9-element array
1592 with the time analyzed for the local time zone.  Typically used as
1593 follows:
1594
1595     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1596                                                 localtime(time);
1597
1598 All array elements are numeric, and come straight out of a struct tm.
1599 In particular this means that $mon has the range 0..11 and $wday has
1600 the range 0..6.  If EXPR is omitted, does localtime(time).
1601
1602 In a scalar context, prints out the ctime(3) value:
1603
1604     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1605
1606 Also see the F<timelocal.pl> library, and the strftime(3) function available
1607 via the POSIX module.
1608
1609 =item log EXPR
1610
1611 =item log 
1612
1613 Returns logarithm (base I<e>) of EXPR.  If EXPR is omitted, returns log
1614 of $_.
1615
1616 =item lstat FILEHANDLE
1617
1618 =item lstat EXPR
1619
1620 =item lstat 
1621
1622 Does the same thing as the stat() function, but stats a symbolic link
1623 instead of the file the symbolic link points to.  If symbolic links are
1624 unimplemented on your system, a normal stat() is done.
1625
1626 If EXPR is omitted, stats $_.
1627
1628 =item m//
1629
1630 The match operator.  See L<perlop>.
1631
1632 =item map BLOCK LIST
1633
1634 =item map EXPR,LIST
1635
1636 Evaluates the BLOCK or EXPR for each element of LIST (locally setting $_ to each
1637 element) and returns the list value composed of the results of each such
1638 evaluation.  Evaluates BLOCK or EXPR in a list context, so each element of LIST
1639 may produce zero, one, or more elements in the returned value.
1640
1641     @chars = map(chr, @nums);
1642
1643 translates a list of numbers to the corresponding characters.  And
1644
1645     %hash = map { getkey($_) => $_ } @array;
1646
1647 is just a funny way to write
1648
1649     %hash = ();
1650     foreach $_ (@array) {
1651         $hash{getkey($_)} = $_;
1652     }
1653
1654 =item mkdir FILENAME,MODE
1655
1656 Creates the directory specified by FILENAME, with permissions specified
1657 by MODE (as modified by umask).  If it succeeds it returns 1, otherwise
1658 it returns 0 and sets C<$!> (errno).
1659
1660 =item msgctl ID,CMD,ARG
1661
1662 Calls the System V IPC function msgctl(2).  If CMD is &IPC_STAT, then ARG
1663 must be a variable which will hold the returned msqid_ds structure.
1664 Returns like ioctl: the undefined value for error, "0 but true" for
1665 zero, or the actual return value otherwise.
1666
1667 =item msgget KEY,FLAGS
1668
1669 Calls the System V IPC function msgget(2).  Returns the message queue id,
1670 or the undefined value if there is an error.
1671
1672 =item msgsnd ID,MSG,FLAGS
1673
1674 Calls the System V IPC function msgsnd to send the message MSG to the
1675 message queue ID.  MSG must begin with the long integer message type,
1676 which may be created with C<pack("l", $type)>.  Returns TRUE if
1677 successful, or FALSE if there is an error.
1678
1679 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
1680
1681 Calls the System V IPC function msgrcv to receive a message from
1682 message queue ID into variable VAR with a maximum message size of
1683 SIZE.  Note that if a message is received, the message type will be the
1684 first thing in VAR, and the maximum length of VAR is SIZE plus the size
1685 of the message type.  Returns TRUE if successful, or FALSE if there is
1686 an error.
1687
1688 =item my EXPR
1689
1690 A "my" declares the listed variables to be local (lexically) to the
1691 enclosing block, subroutine, C<eval>, or C<do/require/use>'d file.  If
1692 more than one value is listed, the list must be placed in parentheses.  See
1693 L<perlsub/"Private Variables via my()"> for details.
1694
1695 =item next LABEL
1696
1697 =item next
1698
1699 The C<next> command is like the C<continue> statement in C; it starts
1700 the next iteration of the loop:
1701
1702     LINE: while (<STDIN>) {
1703         next LINE if /^#/;      # discard comments
1704         ...
1705     }
1706
1707 Note that if there were a C<continue> block on the above, it would get
1708 executed even on discarded lines.  If the LABEL is omitted, the command
1709 refers to the innermost enclosing loop.
1710
1711 =item no Module LIST
1712
1713 See the "use" function, which "no" is the opposite of.
1714
1715 =item oct EXPR
1716
1717 =item oct 
1718
1719 Interprets EXPR as an octal string and returns the corresponding
1720 decimal value.  (If EXPR happens to start off with 0x, interprets it as
1721 a hex string instead.)  The following will handle decimal, octal, and
1722 hex in the standard Perl or C notation:
1723
1724     $val = oct($val) if $val =~ /^0/;
1725
1726 If EXPR is omitted, uses $_.
1727
1728 =item open FILEHANDLE,EXPR
1729
1730 =item open FILEHANDLE
1731
1732 Opens the file whose filename is given by EXPR, and associates it with
1733 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
1734 name of the real filehandle wanted.  If EXPR is omitted, the scalar
1735 variable of the same name as the FILEHANDLE contains the filename.
1736 (Note that lexical variables--those declared with C<my>--will not work
1737 for this purpose; so if you're using C<my>, specify EXPR in your call
1738 to open.)
1739
1740 If the filename begins with '<' or nothing, the file is opened for input.
1741 If the filename begins with '>', the file is truncated and opened for
1742 output.  If the filename begins with '>>', the file is opened for
1743 appending.  You can put a '+' in front of the '>' or '<' to indicate that
1744 you want both read and write access to the file; thus '+<' is almost
1745 always preferred for read/write updates--the '+>' mode would clobber the
1746 file first.  The prefix and the filename may be separated with spaces.
1747 These various prefixes correspond to the fopen(3) modes of 'r', 'r+', 'w',
1748 'w+', 'a', and 'a+'.
1749
1750 If the filename begins with "|", the filename is interpreted as a command
1751 to which output is to be piped, and if the filename ends with a "|", the
1752 filename is interpreted See L<perlipc/"Using open() for IPC"> for more
1753 examples of this.  as command which pipes input to us.  (You may not have
1754 a raw open() to a command that pipes both in I<and> out, but see
1755 L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
1756 for alternatives.)
1757
1758 Opening '-' opens STDIN and opening 'E<gt>-' opens STDOUT.  Open returns
1759 non-zero upon success, the undefined value otherwise.  If the open
1760 involved a pipe, the return value happens to be the pid of the
1761 subprocess.  
1762
1763 If you're unfortunate enough to be running Perl on a system that
1764 distinguishes between text files and binary files (modern operating
1765 systems don't care), then you should check out L</binmode> for tips for
1766 dealing with this.  The key distinction between systems that need binmode
1767 and those that don't is their text file formats.  Systems like Unix and
1768 Plan9 that delimit lines with a single character, and that encode that
1769 character in C as '\n', do not need C<binmode>.  The rest need it.
1770
1771 Examples:
1772
1773     $ARTICLE = 100;
1774     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
1775     while (<ARTICLE>) {...
1776
1777     open(LOG, '>>/usr/spool/news/twitlog'); # (log is reserved)
1778
1779     open(DBASE, '+<dbase.mine');            # open for update
1780
1781     open(ARTICLE, "caesar <$article |");    # decrypt article
1782
1783     open(EXTRACT, "|sort >/tmp/Tmp$$");     # $$ is our process id
1784
1785     # process argument list of files along with any includes
1786
1787     foreach $file (@ARGV) {
1788         process($file, 'fh00');
1789     }
1790
1791     sub process {
1792         local($filename, $input) = @_;
1793         $input++;               # this is a string increment
1794         unless (open($input, $filename)) {
1795             print STDERR "Can't open $filename: $!\n";
1796             return;
1797         }
1798
1799         while (<$input>) {              # note use of indirection
1800             if (/^#include "(.*)"/) {
1801                 process($1, $input);
1802                 next;
1803             }
1804             ...         # whatever
1805         }
1806     }
1807
1808 You may also, in the Bourne shell tradition, specify an EXPR beginning
1809 with "E<gt>&", in which case the rest of the string is interpreted as the
1810 name of a filehandle (or file descriptor, if numeric) which is to be
1811 duped and opened.  You may use & after E<gt>, E<gt>E<gt>, E<lt>, +E<gt>,
1812 +E<gt>E<gt>, and +E<lt>.  The
1813 mode you specify should match the mode of the original filehandle.
1814 (Duping a filehandle does not take into account any existing contents of
1815 stdio buffers.)
1816 Here is a script that saves, redirects, and restores STDOUT and
1817 STDERR:
1818
1819     #!/usr/bin/perl
1820     open(SAVEOUT, ">&STDOUT");
1821     open(SAVEERR, ">&STDERR");
1822
1823     open(STDOUT, ">foo.out") || die "Can't redirect stdout";
1824     open(STDERR, ">&STDOUT") || die "Can't dup stdout";
1825
1826     select(STDERR); $| = 1;     # make unbuffered
1827     select(STDOUT); $| = 1;     # make unbuffered
1828
1829     print STDOUT "stdout 1\n";  # this works for
1830     print STDERR "stderr 1\n";  # subprocesses too
1831
1832     close(STDOUT);
1833     close(STDERR);
1834
1835     open(STDOUT, ">&SAVEOUT");
1836     open(STDERR, ">&SAVEERR");
1837
1838     print STDOUT "stdout 2\n";
1839     print STDERR "stderr 2\n";
1840
1841
1842 If you specify "E<lt>&=N", where N is a number, then Perl will do an
1843 equivalent of C's fdopen() of that file descriptor; this is more
1844 parsimonious of file descriptors.  For example:
1845
1846     open(FILEHANDLE, "<&=$fd")
1847
1848 If you open a pipe on the command "-", i.e., either "|-" or "-|", then
1849 there is an implicit fork done, and the return value of open is the pid
1850 of the child within the parent process, and 0 within the child
1851 process.  (Use C<defined($pid)> to determine whether the open was successful.)
1852 The filehandle behaves normally for the parent, but i/o to that
1853 filehandle is piped from/to the STDOUT/STDIN of the child process.
1854 In the child process the filehandle isn't opened--i/o happens from/to
1855 the new STDOUT or STDIN.  Typically this is used like the normal
1856 piped open when you want to exercise more control over just how the
1857 pipe command gets executed, such as when you are running setuid, and
1858 don't want to have to scan shell commands for metacharacters.  
1859 The following pairs are more or less equivalent:
1860
1861     open(FOO, "|tr '[a-z]' '[A-Z]'");
1862     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
1863
1864     open(FOO, "cat -n '$file'|");
1865     open(FOO, "-|") || exec 'cat', '-n', $file;
1866
1867 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
1868
1869 Explicitly closing any piped filehandle causes the parent process to
1870 wait for the child to finish, and returns the status value in C<$?>.
1871 Note: on any operation which may do a fork, unflushed buffers remain
1872 unflushed in both processes, which means you may need to set C<$|> to
1873 avoid duplicate output.
1874
1875 Using the constructor from the IO::Handle package (or one of its
1876 subclasses, such as IO::File or IO::Socket),
1877 you can generate anonymous filehandles which have the scope of whatever
1878 variables hold references to them, and automatically close whenever
1879 and however you leave that scope:
1880
1881     use IO::File;
1882     ...
1883     sub read_myfile_munged {
1884         my $ALL = shift;
1885         my $handle = new IO::File;
1886         open($handle, "myfile") or die "myfile: $!";
1887         $first = <$handle>
1888             or return ();     # Automatically closed here.
1889         mung $first or die "mung failed";       # Or here.
1890         return $first, <$handle> if $ALL;       # Or here.
1891         $first;                                 # Or here.
1892     }
1893
1894 The filename that is passed to open will have leading and trailing
1895 whitespace deleted.  To open a file with arbitrary weird
1896 characters in it, it's necessary to protect any leading and trailing
1897 whitespace thusly:
1898
1899     $file =~ s#^(\s)#./$1#;
1900     open(FOO, "< $file\0");
1901
1902 If you want a "real" C open() (see L<open(2)> on your system), then
1903 you should use the sysopen() function.  This is another way to
1904 protect your filenames from interpretation.  For example:
1905
1906     use FileHandle;
1907     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL, 0700)
1908         or die "sysopen $path: $!";
1909     HANDLE->autoflush(1);
1910     HANDLE->print("stuff $$\n");
1911     seek(HANDLE, 0, 0);
1912     print "File contains: ", <HANDLE>;
1913
1914 See L</seek()> for some details about mixing reading and writing.
1915
1916 =item opendir DIRHANDLE,EXPR
1917
1918 Opens a directory named EXPR for processing by readdir(), telldir(),
1919 seekdir(), rewinddir(), and closedir().  Returns TRUE if successful.
1920 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
1921
1922 =item ord EXPR
1923
1924 =item ord 
1925
1926 Returns the numeric ascii value of the first character of EXPR.  If
1927 EXPR is omitted, uses $_.
1928
1929 =item pack TEMPLATE,LIST
1930
1931 Takes an array or list of values and packs it into a binary structure,
1932 returning the string containing the structure.  The TEMPLATE is a
1933 sequence of characters that give the order and type of values, as
1934 follows:
1935
1936     A   An ascii string, will be space padded.
1937     a   An ascii string, will be null padded.
1938     b   A bit string (ascending bit order, like vec()).
1939     B   A bit string (descending bit order).
1940     h   A hex string (low nybble first).
1941     H   A hex string (high nybble first).
1942
1943     c   A signed char value.
1944     C   An unsigned char value.
1945     s   A signed short value.
1946     S   An unsigned short value.
1947     i   A signed integer value.
1948     I   An unsigned integer value.
1949     l   A signed long value.
1950     L   An unsigned long value.
1951
1952     n   A short in "network" order.
1953     N   A long in "network" order.
1954     v   A short in "VAX" (little-endian) order.
1955     V   A long in "VAX" (little-endian) order.
1956
1957     f   A single-precision float in the native format.
1958     d   A double-precision float in the native format.
1959
1960     p   A pointer to a null-terminated string.
1961     P   A pointer to a structure (fixed-length string).
1962
1963     u   A uuencoded string.
1964
1965     w A BER compressed integer. Bytes give an unsigned integer base
1966       128, most significant digit first, with as few digits as
1967       possible, and with the bit 8 of each byte except the last set
1968       to "1."
1969
1970     x   A null byte.
1971     X   Back up a byte.
1972     @   Null fill to absolute position.
1973
1974 Each letter may optionally be followed by a number which gives a repeat
1975 count.  With all types except "a", "A", "b", "B", "h", "H", and "P" the
1976 pack function will gobble up that many values from the LIST.  A * for the
1977 repeat count means to use however many items are left.  The "a" and "A"
1978 types gobble just one value, but pack it as a string of length count,
1979 padding with nulls or spaces as necessary.  (When unpacking, "A" strips
1980 trailing spaces and nulls, but "a" does not.)  Likewise, the "b" and "B"
1981 fields pack a string that many bits long.  The "h" and "H" fields pack a
1982 string that many nybbles long.  The "P" packs a pointer to a structure of
1983 the size indicated by the length.  Real numbers (floats and doubles) are
1984 in the native machine format only; due to the multiplicity of floating
1985 formats around, and the lack of a standard "network" representation, no
1986 facility for interchange has been made.  This means that packed floating
1987 point data written on one machine may not be readable on another - even if
1988 both use IEEE floating point arithmetic (as the endian-ness of the memory
1989 representation is not part of the IEEE spec).  Note that Perl uses doubles
1990 internally for all numeric calculation, and converting from double into
1991 float and thence back to double again will lose precision (i.e.,
1992 C<unpack("f", pack("f", $foo)>) will not in general equal $foo).
1993
1994 Examples:
1995
1996     $foo = pack("cccc",65,66,67,68);
1997     # foo eq "ABCD"
1998     $foo = pack("c4",65,66,67,68);
1999     # same thing
2000
2001     $foo = pack("ccxxcc",65,66,67,68);
2002     # foo eq "AB\0\0CD"
2003
2004     $foo = pack("s2",1,2);
2005     # "\1\0\2\0" on little-endian
2006     # "\0\1\0\2" on big-endian
2007
2008     $foo = pack("a4","abcd","x","y","z");
2009     # "abcd"
2010
2011     $foo = pack("aaaa","abcd","x","y","z");
2012     # "axyz"
2013
2014     $foo = pack("a14","abcdefg");
2015     # "abcdefg\0\0\0\0\0\0\0"
2016
2017     $foo = pack("i9pl", gmtime);
2018     # a real struct tm (on my system anyway)
2019
2020     sub bintodec {
2021         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
2022     }
2023
2024 The same template may generally also be used in the unpack function.
2025
2026 =item package NAMESPACE
2027
2028 Declares the compilation unit as being in the given namespace.  The scope
2029 of the package declaration is from the declaration itself through the end of
2030 the enclosing block (the same scope as the local() operator).  All further
2031 unqualified dynamic identifiers will be in this namespace.  A package
2032 statement affects only dynamic variables--including those you've used
2033 local() on--but I<not> lexical variables created with my().  Typically it
2034 would be the first declaration in a file to be included by the C<require>
2035 or C<use> operator.  You can switch into a package in more than one place;
2036 it influences merely which symbol table is used by the compiler for the
2037 rest of that block.  You can refer to variables and filehandles in other
2038 packages by prefixing the identifier with the package name and a double
2039 colon:  C<$Package::Variable>.  If the package name is null, the C<main>
2040 package as assumed.  That is, C<$::sail> is equivalent to C<$main::sail>.
2041
2042 See L<perlmod/"Packages"> for more information about packages, modules,
2043 and classes.  See L<perlsub> for other scoping issues.
2044
2045 =item pipe READHANDLE,WRITEHANDLE
2046
2047 Opens a pair of connected pipes like the corresponding system call.
2048 Note that if you set up a loop of piped processes, deadlock can occur
2049 unless you are very careful.  In addition, note that Perl's pipes use
2050 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
2051 after each command, depending on the application.
2052
2053 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
2054 for examples of such things.
2055
2056 =item pop ARRAY
2057
2058 Pops and returns the last value of the array, shortening the array by
2059 1.  Has a similar effect to
2060
2061     $tmp = $ARRAY[$#ARRAY--];
2062
2063 If there are no elements in the array, returns the undefined value.
2064 If ARRAY is omitted, pops the
2065 @ARGV array in the main program, and the @_ array in subroutines, just
2066 like shift().
2067
2068 =item pos SCALAR
2069
2070 =item pos 
2071
2072 Returns the offset of where the last C<m//g> search left off for the variable
2073 is in question ($_ is used when the variable is not specified). May be
2074 modified to change that offset.
2075
2076 =item print FILEHANDLE LIST
2077
2078 =item print LIST
2079
2080 =item print
2081
2082 Prints a string or a comma-separated list of strings.  Returns TRUE
2083 if successful.  FILEHANDLE may be a scalar variable name, in which case
2084 the variable contains the name of or a reference to the filehandle, thus introducing one
2085 level of indirection.  (NOTE: If FILEHANDLE is a variable and the next
2086 token is a term, it may be misinterpreted as an operator unless you
2087 interpose a + or put parentheses around the arguments.)  If FILEHANDLE is
2088 omitted, prints by default to standard output (or to the last selected
2089 output channel--see L</select>).  If LIST is also omitted, prints $_ to
2090 STDOUT.  To set the default output channel to something other than
2091 STDOUT use the select operation.  Note that, because print takes a
2092 LIST, anything in the LIST is evaluated in a list context, and any
2093 subroutine that you call will have one or more of its expressions
2094 evaluated in a list context.  Also be careful not to follow the print
2095 keyword with a left parenthesis unless you want the corresponding right
2096 parenthesis to terminate the arguments to the print--interpose a + or
2097 put parentheses around all the arguments.
2098
2099 Note that if you're storing FILEHANDLES in an array or other expression,
2100 you will have to use a block returning its value instead:
2101
2102     print { $files[$i] } "stuff\n";
2103     print { $OK ? STDOUT : STDERR } "stuff\n";
2104
2105 =item printf FILEHANDLE FORMAT, LIST
2106
2107 =item printf FORMAT, LIST
2108
2109 Equivalent to a "print FILEHANDLE sprintf(FORMAT, LIST)".  The first argument
2110 of the list will be interpreted as the printf format.
2111
2112 =item prototype FUNCTION
2113
2114 Returns the prototype of a function as a string (or C<undef> if the
2115 function has no prototype).  FUNCTION is a reference to, or the name of,
2116 the function whose prototype you want to retrieve.
2117
2118 =item push ARRAY,LIST
2119
2120 Treats ARRAY as a stack, and pushes the values of LIST
2121 onto the end of ARRAY.  The length of ARRAY increases by the length of
2122 LIST.  Has the same effect as
2123
2124     for $value (LIST) {
2125         $ARRAY[++$#ARRAY] = $value;
2126     }
2127
2128 but is more efficient.  Returns the new number of elements in the array.
2129
2130 =item q/STRING/
2131
2132 =item qq/STRING/
2133
2134 =item qx/STRING/
2135
2136 =item qw/STRING/
2137
2138 Generalized quotes.  See L<perlop>.
2139
2140 =item quotemeta EXPR
2141
2142 =item quotemeta 
2143
2144 Returns the value of EXPR with with all regular expression
2145 metacharacters backslashed.  This is the internal function implementing
2146 the \Q escape in double-quoted strings.
2147
2148 If EXPR is omitted, uses $_.
2149
2150 =item rand EXPR
2151
2152 =item rand
2153
2154 Returns a random fractional number between 0 and the value of EXPR.
2155 (EXPR should be positive.)  If EXPR is omitted, returns a value between 
2156 0 and 1.  This function produces repeatable sequences unless srand() 
2157 is invoked.  See also srand().
2158
2159 (Note: if your rand function consistently returns numbers that are too
2160 large or too small, then your version of Perl was probably compiled
2161 with the wrong number of RANDBITS.  As a workaround, you can usually
2162 multiply EXPR by the correct power of 2 to get the range you want.
2163 This will make your script unportable, however.  It's better to recompile
2164 if you can.)
2165
2166 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
2167
2168 =item read FILEHANDLE,SCALAR,LENGTH
2169
2170 Attempts to read LENGTH bytes of data into variable SCALAR from the
2171 specified FILEHANDLE.  Returns the number of bytes actually read, or
2172 undef if there was an error.  SCALAR will be grown or shrunk to the
2173 length actually read.  An OFFSET may be specified to place the read
2174 data at some other place than the beginning of the string.  This call
2175 is actually implemented in terms of stdio's fread call.  To get a true
2176 read system call, see sysread().
2177
2178 =item readdir DIRHANDLE
2179
2180 Returns the next directory entry for a directory opened by opendir().
2181 If used in a list context, returns all the rest of the entries in the
2182 directory.  If there are no more entries, returns an undefined value in
2183 a scalar context or a null list in a list context.
2184
2185 If you're planning to filetest the return values out of a readdir(), you'd
2186 better prepend the directory in question.  Otherwise, because we didn't
2187 chdir() there, it would have been testing the wrong file.
2188
2189     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
2190     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
2191     closedir DIR;
2192
2193 =item readlink EXPR
2194
2195 =item readlink 
2196
2197 Returns the value of a symbolic link, if symbolic links are
2198 implemented.  If not, gives a fatal error.  If there is some system
2199 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
2200 omitted, uses $_.
2201
2202 =item recv SOCKET,SCALAR,LEN,FLAGS
2203
2204 Receives a message on a socket.  Attempts to receive LENGTH bytes of
2205 data into variable SCALAR from the specified SOCKET filehandle.
2206 Actually does a C recvfrom(), so that it can returns the address of the
2207 sender.  Returns the undefined value if there's an error.  SCALAR will
2208 be grown or shrunk to the length actually read.  Takes the same flags
2209 as the system call of the same name.  
2210 See L<perlipc/"UDP: Message Passing"> for examples.
2211
2212 =item redo LABEL
2213
2214 =item redo
2215
2216 The C<redo> command restarts the loop block without evaluating the
2217 conditional again.  The C<continue> block, if any, is not executed.  If
2218 the LABEL is omitted, the command refers to the innermost enclosing
2219 loop.  This command is normally used by programs that want to lie to
2220 themselves about what was just input:
2221
2222     # a simpleminded Pascal comment stripper
2223     # (warning: assumes no { or } in strings)
2224     LINE: while (<STDIN>) {
2225         while (s|({.*}.*){.*}|$1 |) {}
2226         s|{.*}| |;
2227         if (s|{.*| |) {
2228             $front = $_;
2229             while (<STDIN>) {
2230                 if (/}/) {      # end of comment?
2231                     s|^|$front{|;
2232                     redo LINE;
2233                 }
2234             }
2235         }
2236         print;
2237     }
2238
2239 =item ref EXPR
2240
2241 =item ref 
2242
2243 Returns a TRUE value if EXPR is a reference, FALSE otherwise. If EXPR
2244 is not specified, $_ will be used. The value returned depends on the
2245 type of thing the reference is a reference to.
2246 Builtin types include:
2247
2248     REF
2249     SCALAR
2250     ARRAY
2251     HASH
2252     CODE
2253     GLOB
2254
2255 If the referenced object has been blessed into a package, then that package 
2256 name is returned instead.  You can think of ref() as a typeof() operator.
2257
2258     if (ref($r) eq "HASH") {
2259         print "r is a reference to an associative array.\n";
2260     } 
2261     if (!ref ($r) {
2262         print "r is not a reference at all.\n";
2263     } 
2264
2265 See also L<perlref>.
2266
2267 =item rename OLDNAME,NEWNAME
2268
2269 Changes the name of a file.  Returns 1 for success, 0 otherwise.  Will
2270 not work across file system boundaries.
2271
2272 =item require EXPR
2273
2274 =item require
2275
2276 Demands some semantics specified by EXPR, or by $_ if EXPR is not
2277 supplied.  If EXPR is numeric, demands that the current version of Perl
2278 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
2279
2280 Otherwise, demands that a library file be included if it hasn't already
2281 been included.  The file is included via the do-FILE mechanism, which is
2282 essentially just a variety of eval().  Has semantics similar to the following
2283 subroutine:
2284
2285     sub require {
2286         local($filename) = @_;
2287         return 1 if $INC{$filename};
2288         local($realfilename,$result);
2289         ITER: {
2290             foreach $prefix (@INC) {
2291                 $realfilename = "$prefix/$filename";
2292                 if (-f $realfilename) {
2293                     $result = do $realfilename;
2294                     last ITER;
2295                 }
2296             }
2297             die "Can't find $filename in \@INC";
2298         }
2299         die $@ if $@;
2300         die "$filename did not return true value" unless $result;
2301         $INC{$filename} = $realfilename;
2302         $result;
2303     }
2304
2305 Note that the file will not be included twice under the same specified
2306 name.  The file must return TRUE as the last statement to indicate
2307 successful execution of any initialization code, so it's customary to
2308 end such a file with "1;" unless you're sure it'll return TRUE
2309 otherwise.  But it's better just to put the "C<1;>", in case you add more
2310 statements.
2311
2312 If EXPR is a bare word, the require assumes a "F<.pm>" extension and
2313 replaces "F<::>" with "F</>" in the filename for you,
2314 to make it easy to load standard modules.  This form of loading of 
2315 modules does not risk altering your namespace.
2316
2317 For a yet-more-powerful import facility, see L</use> and 
2318 L<perlmod>.
2319
2320 =item reset EXPR
2321
2322 =item reset
2323
2324 Generally used in a C<continue> block at the end of a loop to clear
2325 variables and reset ?? searches so that they work again.  The
2326 expression is interpreted as a list of single characters (hyphens
2327 allowed for ranges).  All variables and arrays beginning with one of
2328 those letters are reset to their pristine state.  If the expression is
2329 omitted, one-match searches (?pattern?) are reset to match again.  Resets
2330 only variables or searches in the current package.  Always returns
2331 1.  Examples:
2332
2333     reset 'X';          # reset all X variables
2334     reset 'a-z';        # reset lower case variables
2335     reset;              # just reset ?? searches
2336
2337 Resetting "A-Z" is not recommended because you'll wipe out your
2338 ARGV and ENV arrays.  Resets only package variables--lexical variables
2339 are unaffected, but they clean themselves up on scope exit anyway,
2340 so you'll probably want to use them instead.  See L</my>.
2341
2342 =item return LIST
2343
2344 Returns from a subroutine or eval with the value specified.  (Note that
2345 in the absence of a return a subroutine or eval() will automatically
2346 return the value of the last expression evaluated.)
2347
2348 =item reverse LIST
2349
2350 In a list context, returns a list value consisting of the elements
2351 of LIST in the opposite order.  In a scalar context, returns a string
2352 value consisting of the bytes of the first element of LIST in the
2353 opposite order.   
2354
2355     print reverse <>;                   # line tac 
2356
2357     undef $/;
2358     print scalar reverse scalar <>;     # byte tac
2359
2360 =item rewinddir DIRHANDLE
2361
2362 Sets the current position to the beginning of the directory for the
2363 readdir() routine on DIRHANDLE.
2364
2365 =item rindex STR,SUBSTR,POSITION
2366
2367 =item rindex STR,SUBSTR
2368
2369 Works just like index except that it returns the position of the LAST
2370 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
2371 last occurrence at or before that position.
2372
2373 =item rmdir FILENAME
2374
2375 =item rmdir 
2376
2377 Deletes the directory specified by FILENAME if it is empty.  If it
2378 succeeds it returns 1, otherwise it returns 0 and sets C<$!> (errno).  If
2379 FILENAME is omitted, uses $_.
2380
2381 =item s///
2382
2383 The substitution operator.  See L<perlop>.
2384
2385 =item scalar EXPR
2386
2387 Forces EXPR to be interpreted in a scalar context and returns the value
2388 of EXPR.  
2389
2390     @counts = ( scalar @a, scalar @b, scalar @c );
2391
2392 There is no equivalent operator to force an expression to 
2393 be interpolated in a list context because it's in practice never
2394 needed.  If you really wanted to do so, however, you could use
2395 the construction C<@{[ (some expression) ]}>, but usually a simple
2396 C<(some expression)> suffices.
2397
2398 =item seek FILEHANDLE,POSITION,WHENCE
2399
2400 Randomly positions the file pointer for FILEHANDLE, just like the fseek()
2401 call of stdio.  FILEHANDLE may be an expression whose value gives the name
2402 of the filehandle.  The values for WHENCE are 0 to set the file pointer to
2403 POSITION, 1 to set the it to current plus POSITION, and 2 to set it to EOF
2404 plus offset.  You may use the values SEEK_SET, SEEK_CUR, and SEEK_END for
2405 this from POSIX module.  Returns 1 upon success, 0 otherwise.
2406
2407 On some systems you have to do a seek whenever you switch between reading
2408 and writing.  Amongst other things, this may have the effect of calling
2409 stdio's clearerr(3).  A "whence" of 1 (SEEK_CUR) is useful for not moving
2410 the file pointer:
2411
2412     seek(TEST,0,1);
2413
2414 This is also useful for applications emulating C<tail -f>.  Once you hit
2415 EOF on your read, and then sleep for a while, you might have to stick in a
2416 seek() to reset things.  First the simple trick listed above to clear the
2417 filepointer.  The seek() doesn't change the current position, but it
2418 I<does> clear the end-of-file condition on the handle, so that the next
2419 C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
2420
2421 If that doesn't work (some stdios are particularly cantankerous), then
2422 you may need something more like this:
2423
2424     for (;;) {
2425         for ($curpos = tell(FILE); $_ = <FILE>; $curpos = tell(FILE)) {
2426             # search for some stuff and put it into files
2427         }
2428         sleep($for_a_while);
2429         seek(FILE, $curpos, 0);
2430     }
2431
2432 =item seekdir DIRHANDLE,POS
2433
2434 Sets the current position for the readdir() routine on DIRHANDLE.  POS
2435 must be a value returned by telldir().  Has the same caveats about
2436 possible directory compaction as the corresponding system library
2437 routine.
2438
2439 =item select FILEHANDLE
2440
2441 =item select
2442
2443 Returns the currently selected filehandle.  Sets the current default
2444 filehandle for output, if FILEHANDLE is supplied.  This has two
2445 effects: first, a C<write> or a C<print> without a filehandle will
2446 default to this FILEHANDLE.  Second, references to variables related to
2447 output will refer to this output channel.  For example, if you have to
2448 set the top of form format for more than one output channel, you might
2449 do the following:
2450
2451     select(REPORT1);
2452     $^ = 'report1_top';
2453     select(REPORT2);
2454     $^ = 'report2_top';
2455
2456 FILEHANDLE may be an expression whose value gives the name of the
2457 actual filehandle.  Thus:
2458
2459     $oldfh = select(STDERR); $| = 1; select($oldfh);
2460
2461 Some programmers may prefer to think of filehandles as objects with
2462 methods, preferring to write the last example as:
2463
2464     use FileHandle;
2465     STDERR->autoflush(1);
2466
2467 =item select RBITS,WBITS,EBITS,TIMEOUT
2468
2469 This calls the select(2) system call with the bit masks specified, which
2470 can be constructed using fileno() and vec(), along these lines:
2471
2472     $rin = $win = $ein = '';
2473     vec($rin,fileno(STDIN),1) = 1;
2474     vec($win,fileno(STDOUT),1) = 1;
2475     $ein = $rin | $win;
2476
2477 If you want to select on many filehandles you might wish to write a
2478 subroutine:
2479
2480     sub fhbits {
2481         local(@fhlist) = split(' ',$_[0]);
2482         local($bits);
2483         for (@fhlist) {
2484             vec($bits,fileno($_),1) = 1;
2485         }
2486         $bits;
2487     }
2488     $rin = fhbits('STDIN TTY SOCK');
2489
2490 The usual idiom is:
2491
2492     ($nfound,$timeleft) =
2493       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
2494
2495 or to block until something becomes ready just do this 
2496
2497     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
2498
2499 Most systems do not bother to return anything useful in $timeleft, so
2500 calling select() in a scalar context just returns $nfound.
2501
2502 Any of the bit masks can also be undef.  The timeout, if specified, is
2503 in seconds, which may be fractional.  Note: not all implementations are
2504 capable of returning the $timeleft.  If not, they always return
2505 $timeleft equal to the supplied $timeout.
2506
2507 You can effect a sleep of 250 milliseconds this way:
2508
2509     select(undef, undef, undef, 0.25);
2510
2511 B<WARNING>: Do not attempt to mix buffered I/O (like read() or E<lt>FHE<gt>)
2512 with select().  You have to use sysread() instead.
2513
2514 =item semctl ID,SEMNUM,CMD,ARG
2515
2516 Calls the System V IPC function semctl.  If CMD is &IPC_STAT or
2517 &GETALL, then ARG must be a variable which will hold the returned
2518 semid_ds structure or semaphore value array.  Returns like ioctl: the
2519 undefined value for error, "0 but true" for zero, or the actual return
2520 value otherwise.
2521
2522 =item semget KEY,NSEMS,FLAGS
2523
2524 Calls the System V IPC function semget.  Returns the semaphore id, or
2525 the undefined value if there is an error.
2526
2527 =item semop KEY,OPSTRING
2528
2529 Calls the System V IPC function semop to perform semaphore operations
2530 such as signaling and waiting.  OPSTRING must be a packed array of
2531 semop structures.  Each semop structure can be generated with
2532 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
2533 operations is implied by the length of OPSTRING.  Returns TRUE if
2534 successful, or FALSE if there is an error.  As an example, the
2535 following code waits on semaphore $semnum of semaphore id $semid:
2536
2537     $semop = pack("sss", $semnum, -1, 0);
2538     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
2539
2540 To signal the semaphore, replace "-1" with "1".
2541
2542 =item send SOCKET,MSG,FLAGS,TO
2543
2544 =item send SOCKET,MSG,FLAGS
2545
2546 Sends a message on a socket.  Takes the same flags as the system call
2547 of the same name.  On unconnected sockets you must specify a
2548 destination to send TO, in which case it does a C sendto().  Returns
2549 the number of characters sent, or the undefined value if there is an
2550 error.
2551 See L<perlipc/"UDP: Message Passing"> for examples.
2552
2553 =item setpgrp PID,PGRP
2554
2555 Sets the current process group for the specified PID, 0 for the current
2556 process.  Will produce a fatal error if used on a machine that doesn't
2557 implement setpgrp(2).  If the arguments are omitted, it defaults to
2558 0,0.  Note that the POSIX version of setpgrp() does not accept any
2559 arguments, so only setpgrp 0,0 is portable.
2560
2561 =item setpriority WHICH,WHO,PRIORITY
2562
2563 Sets the current priority for a process, a process group, or a user.
2564 (See setpriority(2).)  Will produce a fatal error if used on a machine
2565 that doesn't implement setpriority(2).
2566
2567 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
2568
2569 Sets the socket option requested.  Returns undefined if there is an
2570 error.  OPTVAL may be specified as undef if you don't want to pass an
2571 argument.
2572
2573 =item shift ARRAY
2574
2575 =item shift
2576
2577 Shifts the first value of the array off and returns it, shortening the
2578 array by 1 and moving everything down.  If there are no elements in the
2579 array, returns the undefined value.  If ARRAY is omitted, shifts the
2580 @ARGV array in the main program, and the @_ array in subroutines.
2581 (This is determined lexically.)  See also unshift(), push(), and pop().
2582 Shift() and unshift() do the same thing to the left end of an array
2583 that push() and pop() do to the right end.
2584
2585 =item shmctl ID,CMD,ARG
2586
2587 Calls the System V IPC function shmctl.  If CMD is &IPC_STAT, then ARG
2588 must be a variable which will hold the returned shmid_ds structure.
2589 Returns like ioctl: the undefined value for error, "0 but true" for
2590 zero, or the actual return value otherwise.
2591
2592 =item shmget KEY,SIZE,FLAGS
2593
2594 Calls the System V IPC function shmget.  Returns the shared memory
2595 segment id, or the undefined value if there is an error.
2596
2597 =item shmread ID,VAR,POS,SIZE
2598
2599 =item shmwrite ID,STRING,POS,SIZE
2600
2601 Reads or writes the System V shared memory segment ID starting at
2602 position POS for size SIZE by attaching to it, copying in/out, and
2603 detaching from it.  When reading, VAR must be a variable which will
2604 hold the data read.  When writing, if STRING is too long, only SIZE
2605 bytes are used; if STRING is too short, nulls are written to fill out
2606 SIZE bytes.  Return TRUE if successful, or FALSE if there is an error.
2607
2608 =item shutdown SOCKET,HOW
2609
2610 Shuts down a socket connection in the manner indicated by HOW, which
2611 has the same interpretation as in the system call of the same name.
2612
2613 =item sin EXPR
2614
2615 =item sin 
2616
2617 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
2618 returns sine of $_.
2619
2620 =item sleep EXPR
2621
2622 =item sleep
2623
2624 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
2625 May be interrupted by sending the process a SIGALRM.  Returns the
2626 number of seconds actually slept.  You probably cannot mix alarm() and
2627 sleep() calls, because sleep() is often implemented using alarm().
2628
2629 On some older systems, it may sleep up to a full second less than what
2630 you requested, depending on how it counts seconds.  Most modern systems
2631 always sleep the full amount.
2632
2633 For delays of finer granularity than one second, you may use Perl's
2634 syscall() interface to access setitimer(2) if your system supports it, 
2635 or else see L</select()> below.  
2636
2637 See also the POSIX module's sigpause() function.
2638
2639 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
2640
2641 Opens a socket of the specified kind and attaches it to filehandle
2642 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for the
2643 system call of the same name.  You should "use Socket;" first to get
2644 the proper definitions imported.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
2645
2646 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
2647
2648 Creates an unnamed pair of sockets in the specified domain, of the
2649 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
2650 for the system call of the same name.  If unimplemented, yields a fatal
2651 error.  Returns TRUE if successful.
2652
2653 =item sort SUBNAME LIST
2654
2655 =item sort BLOCK LIST
2656
2657 =item sort LIST
2658
2659 Sorts the LIST and returns the sorted list value.  Nonexistent values
2660 of arrays are stripped out.  If SUBNAME or BLOCK is omitted, sorts
2661 in standard string comparison order.  If SUBNAME is specified, it
2662 gives the name of a subroutine that returns an integer less than, equal
2663 to, or greater than 0, depending on how the elements of the array are
2664 to be ordered.  (The E<lt>=E<gt> and cmp operators are extremely useful in such
2665 routines.)  SUBNAME may be a scalar variable name, in which case the
2666 value provides the name of the subroutine to use.  In place of a
2667 SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
2668 subroutine.
2669
2670 In the interests of efficiency the normal calling code for subroutines is
2671 bypassed, with the following effects: the subroutine may not be a
2672 recursive subroutine, and the two elements to be compared are passed into
2673 the subroutine not via @_ but as the package global variables $a and
2674 $b (see example below).  They are passed by reference, so don't
2675 modify $a and $b.  And don't try to declare them as lexicals either.
2676
2677 Examples:
2678
2679     # sort lexically
2680     @articles = sort @files;
2681
2682     # same thing, but with explicit sort routine
2683     @articles = sort {$a cmp $b} @files;
2684
2685     # now case-insensitively
2686     @articles = sort { uc($a) cmp uc($b)} @files;
2687
2688     # same thing in reversed order
2689     @articles = sort {$b cmp $a} @files;
2690
2691     # sort numerically ascending
2692     @articles = sort {$a <=> $b} @files;
2693
2694     # sort numerically descending
2695     @articles = sort {$b <=> $a} @files;
2696
2697     # sort using explicit subroutine name
2698     sub byage {
2699         $age{$a} <=> $age{$b};  # presuming integers
2700     }
2701     @sortedclass = sort byage @class;
2702
2703     # this sorts the %age associative arrays by value 
2704     # instead of key using an in-line function
2705     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
2706
2707     sub backwards { $b cmp $a; }
2708     @harry = ('dog','cat','x','Cain','Abel');
2709     @george = ('gone','chased','yz','Punished','Axed');
2710     print sort @harry;
2711             # prints AbelCaincatdogx
2712     print sort backwards @harry;
2713             # prints xdogcatCainAbel
2714     print sort @george, 'to', @harry;
2715             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
2716
2717     # inefficiently sort by descending numeric compare using 
2718     # the first integer after the first = sign, or the 
2719     # whole record case-insensitively otherwise
2720
2721     @new = sort {
2722         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
2723                             ||
2724                     uc($a)  cmp  uc($b)
2725     } @old;
2726
2727     # same thing, but much more efficiently;
2728     # we'll build auxiliary indices instead
2729     # for speed
2730     @nums = @caps = ();
2731     for (@old) { 
2732         push @nums, /=(\d+)/;
2733         push @caps, uc($_);
2734     } 
2735
2736     @new = @old[ sort {
2737                         $nums[$b] <=> $nums[$a]
2738                                  ||
2739                         $caps[$a] cmp $caps[$b]
2740                        } 0..$#old
2741                ];
2742
2743     # same thing using a Schwartzian Transform (no temps)
2744     @new = map { $_->[0] }
2745         sort { $b->[1] <=> $a->[1]
2746                         ||
2747                $a->[2] cmp $b->[2]
2748         } map { [$_, /=(\d+)/, uc($_)] } @old;
2749
2750 If you're using strict, you I<MUST NOT> declare $a
2751 and $b as lexicals.  They are package globals.  That means
2752 if you're in the C<main> package, it's
2753
2754     @articles = sort {$main::b <=> $main::a} @files;
2755
2756 or just
2757
2758     @articles = sort {$::b <=> $::a} @files;
2759
2760 but if you're in the C<FooPack> package, it's
2761
2762     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
2763
2764 The comparison function is required to behave.  If it returns
2765 inconsistent results (sometimes saying $x[1] is less than $x[2] and
2766 sometimes saying the opposite, for example) the Perl interpreter will
2767 probably crash and dump core.  This is entirely due to and dependent
2768 upon your system's qsort(3) library routine; this routine often avoids
2769 sanity checks in the interest of speed.
2770
2771 =item splice ARRAY,OFFSET,LENGTH,LIST
2772
2773 =item splice ARRAY,OFFSET,LENGTH
2774
2775 =item splice ARRAY,OFFSET
2776
2777 Removes the elements designated by OFFSET and LENGTH from an array, and
2778 replaces them with the elements of LIST, if any.  Returns the elements
2779 removed from the array.  The array grows or shrinks as necessary.  If
2780 LENGTH is omitted, removes everything from OFFSET onward.  The
2781 following equivalences hold (assuming C<$[ == 0>):
2782
2783     push(@a,$x,$y)      splice(@a,$#a+1,0,$x,$y)
2784     pop(@a)             splice(@a,-1)
2785     shift(@a)           splice(@a,0,1)
2786     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
2787     $a[$x] = $y         splice(@a,$x,1,$y);
2788
2789 Example, assuming array lengths are passed before arrays:
2790
2791     sub aeq {   # compare two list values
2792         local(@a) = splice(@_,0,shift);
2793         local(@b) = splice(@_,0,shift);
2794         return 0 unless @a == @b;       # same len?
2795         while (@a) {
2796             return 0 if pop(@a) ne pop(@b);
2797         }
2798         return 1;
2799     }
2800     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
2801
2802 =item split /PATTERN/,EXPR,LIMIT
2803
2804 =item split /PATTERN/,EXPR
2805
2806 =item split /PATTERN/
2807
2808 =item split
2809
2810 Splits a string into an array of strings, and returns it.
2811
2812 If not in a list context, returns the number of fields found and splits into
2813 the @_ array.  (In a list context, you can force the split into @_ by
2814 using C<??> as the pattern delimiters, but it still returns the array
2815 value.)  The use of implicit split to @_ is deprecated, however.
2816
2817 If EXPR is omitted, splits the $_ string.  If PATTERN is also omitted,
2818 splits on whitespace (after skipping any leading whitespace).  Anything
2819 matching PATTERN is taken to be a delimiter separating the fields.  (Note
2820 that the delimiter may be longer than one character.)  If LIMIT is
2821 specified and is not negative, splits into no more than that many fields
2822 (though it may split into fewer).  If LIMIT is unspecified, trailing null
2823 fields are stripped (which potential users of pop() would do well to
2824 remember).  If LIMIT is negative, it is treated as if an arbitrarily large
2825 LIMIT had been specified.
2826
2827 A pattern matching the null string (not to be confused with
2828 a null pattern C<//>, which is just one member of the set of patterns
2829 matching a null string) will split the value of EXPR into separate
2830 characters at each point it matches that way.  For example:
2831
2832     print join(':', split(/ */, 'hi there'));
2833
2834 produces the output 'h:i:t:h:e:r:e'.
2835
2836 The LIMIT parameter can be used to split a line partially
2837
2838     ($login, $passwd, $remainder) = split(/:/, $_, 3);
2839
2840 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
2841 one larger than the number of variables in the list, to avoid
2842 unnecessary work.  For the list above LIMIT would have been 4 by
2843 default.  In time critical applications it behooves you not to split
2844 into more fields than you really need.
2845
2846 If the PATTERN contains parentheses, additional array elements are
2847 created from each matching substring in the delimiter.
2848
2849     split(/([,-])/, "1-10,20", 3);
2850
2851 produces the list value
2852
2853     (1, '-', 10, ',', 20)
2854
2855 If you had the entire header of a normal Unix email message in $header, 
2856 you could split it up into fields and their values this way:
2857
2858     $header =~ s/\n\s+/ /g;  # fix continuation lines
2859     %hdrs   =  (UNIX_FROM => split /^(.*?):\s*/m, $header);
2860
2861 The pattern C</PATTERN/> may be replaced with an expression to specify
2862 patterns that vary at runtime.  (To do runtime compilation only once,
2863 use C</$variable/o>.)
2864
2865 As a special case, specifying a PATTERN of space (C<' '>) will split on
2866 white space just as split with no arguments does.  Thus, split(' ') can
2867 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
2868 will give you as many null initial fields as there are leading spaces.
2869 A split on /\s+/ is like a split(' ') except that any leading
2870 whitespace produces a null first field.  A split with no arguments
2871 really does a C<split(' ', $_)> internally.
2872
2873 Example:
2874
2875     open(passwd, '/etc/passwd');
2876     while (<passwd>) {
2877         ($login, $passwd, $uid, $gid, $gcos, 
2878             $home, $shell) = split(/:/);
2879         ...
2880     }
2881
2882 (Note that $shell above will still have a newline on it.  See L</chop>, 
2883 L</chomp>, and L</join>.)
2884
2885 =item sprintf FORMAT, LIST
2886
2887 Returns a string formatted by the usual printf conventions of the C
2888 language.  See L<sprintf(3)> or L<printf(3)> on your system for details.
2889 (The * character for an indirectly specified length is not
2890 supported, but you can get the same effect by interpolating a variable
2891 into the pattern.)  Some C libraries' implementations of sprintf() can
2892 dump core when fed ludicrous arguments.
2893
2894 =item sqrt EXPR
2895
2896 =item sqrt 
2897
2898 Return the square root of EXPR.  If EXPR is omitted, returns square
2899 root of $_.
2900
2901 =item srand EXPR
2902
2903 Sets the random number seed for the C<rand> operator.  If EXPR is omitted,
2904 uses a semi-random value based on the current time and process ID, among
2905 other things.  Of course, you'd need something much more random than that for
2906 cryptographic purposes, because it's easy to guess the current time.
2907 Checksumming the compressed output of rapidly changing operating system
2908 status programs is the usual method.  Examples are posted regularly to
2909 the comp.security.unix newsgroup.
2910
2911 =item stat FILEHANDLE
2912
2913 =item stat EXPR
2914
2915 =item stat 
2916
2917 Returns a 13-element array giving the status info for a file, either the
2918 file opened via FILEHANDLE, or named by EXPR. If EXPR is omitted, it
2919 stats $_.  Returns a null list if the stat fails.  Typically used as
2920 follows:
2921
2922
2923     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
2924        $atime,$mtime,$ctime,$blksize,$blocks)
2925            = stat($filename);
2926
2927 Not all fields are supported on all filesystem types.  Here are the 
2928 meaning of the fields:
2929
2930   dev       device number of filesystem 
2931   ino       inode number 
2932   mode      file mode  (type and permissions)
2933   nlink     number of (hard) links to the file 
2934   uid       numeric user ID of file's owner 
2935   gid       numeric group ID of file's owner 
2936   rdev      the device identifier (special files only)
2937   size      total size of file, in bytes 
2938   atime     last access time since the epoch
2939   mtime     last modify time since the epoch
2940   ctime     inode change time (NOT creation type!) since the epoch
2941   blksize   preferred block size for file system I/O
2942   blocks    actual number of blocks allocated
2943
2944 (The epoch was at 00:00 January 1, 1970 GMT.)
2945
2946 If stat is passed the special filehandle consisting of an underline, no
2947 stat is done, but the current contents of the stat structure from the
2948 last stat or filetest are returned.  Example:
2949
2950     if (-x $file && (($d) = stat(_)) && $d < 0) {
2951         print "$file is executable NFS file\n";
2952     }
2953
2954 (This works on machines only for which the device number is negative under NFS.)
2955
2956 =item study SCALAR
2957
2958 =item study
2959
2960 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
2961 doing many pattern matches on the string before it is next modified.
2962 This may or may not save time, depending on the nature and number of
2963 patterns you are searching on, and on the distribution of character
2964 frequencies in the string to be searched--you probably want to compare
2965 run times with and without it to see which runs faster.  Those loops
2966 which scan for many short constant strings (including the constant
2967 parts of more complex patterns) will benefit most.  You may have only
2968 one study active at a time--if you study a different scalar the first
2969 is "unstudied".  (The way study works is this: a linked list of every
2970 character in the string to be searched is made, so we know, for
2971 example, where all the 'k' characters are.  From each search string,
2972 the rarest character is selected, based on some static frequency tables
2973 constructed from some C programs and English text.  Only those places
2974 that contain this "rarest" character are examined.)
2975
2976 For example, here is a loop which inserts index producing entries
2977 before any line containing a certain pattern:
2978
2979     while (<>) {
2980         study;
2981         print ".IX foo\n" if /\bfoo\b/;
2982         print ".IX bar\n" if /\bbar\b/;
2983         print ".IX blurfl\n" if /\bblurfl\b/;
2984         ...
2985         print;
2986     }
2987
2988 In searching for /\bfoo\b/, only those locations in $_ that contain "f"
2989 will be looked at, because "f" is rarer than "o".  In general, this is
2990 a big win except in pathological cases.  The only question is whether
2991 it saves you more time than it took to build the linked list in the
2992 first place.
2993
2994 Note that if you have to look for strings that you don't know till
2995 runtime, you can build an entire loop as a string and eval that to
2996 avoid recompiling all your patterns all the time.  Together with
2997 undefining $/ to input entire files as one record, this can be very
2998 fast, often faster than specialized programs like fgrep(1).  The following
2999 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
3000 out the names of those files that contain a match:
3001
3002     $search = 'while (<>) { study;';
3003     foreach $word (@words) {
3004         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
3005     }
3006     $search .= "}";
3007     @ARGV = @files;
3008     undef $/;
3009     eval $search;               # this screams
3010     $/ = "\n";          # put back to normal input delimiter
3011     foreach $file (sort keys(%seen)) {
3012         print $file, "\n";
3013     }
3014
3015 =item sub BLOCK
3016
3017 =item sub NAME
3018
3019 =item sub NAME BLOCK
3020
3021 This is subroutine definition, not a real function I<per se>.  With just a
3022 NAME (and possibly prototypes), it's just a forward declaration.  Without
3023 a NAME, it's an anonymous function declaration, and does actually return a
3024 value: the CODE ref of the closure you just created. See L<perlsub> and
3025 L<perlref> for details.
3026
3027 =item substr EXPR,OFFSET,LEN
3028
3029 =item substr EXPR,OFFSET
3030
3031 Extracts a substring out of EXPR and returns it.  First character is at
3032 offset 0, or whatever you've set $[ to.  If OFFSET is negative, starts
3033 that far from the end of the string.  If LEN is omitted, returns
3034 everything to the end of the string.  If LEN is negative, leaves that
3035 many characters off the end of the string.
3036
3037 You can use the substr() function
3038 as an lvalue, in which case EXPR must be an lvalue.  If you assign
3039 something shorter than LEN, the string will shrink, and if you assign
3040 something longer than LEN, the string will grow to accommodate it.  To
3041 keep the string the same length you may need to pad or chop your value
3042 using sprintf().
3043
3044 =item symlink OLDFILE,NEWFILE
3045
3046 Creates a new filename symbolically linked to the old filename.
3047 Returns 1 for success, 0 otherwise.  On systems that don't support
3048 symbolic links, produces a fatal error at run time.  To check for that,
3049 use eval:
3050
3051     $symlink_exists = (eval 'symlink("","");', $@ eq '');
3052
3053 =item syscall LIST
3054
3055 Calls the system call specified as the first element of the list,
3056 passing the remaining elements as arguments to the system call.  If
3057 unimplemented, produces a fatal error.  The arguments are interpreted
3058 as follows: if a given argument is numeric, the argument is passed as
3059 an int.  If not, the pointer to the string value is passed.  You are
3060 responsible to make sure a string is pre-extended long enough to
3061 receive any result that might be written into a string.  If your
3062 integer arguments are not literals and have never been interpreted in a
3063 numeric context, you may need to add 0 to them to force them to look
3064 like numbers.
3065
3066     require 'syscall.ph';               # may need to run h2ph
3067     syscall(&SYS_write, fileno(STDOUT), "hi there\n", 9);
3068
3069 Note that Perl supports passing of up to only 14 arguments to your system call,
3070 which in practice should usually suffice.
3071
3072 =item sysopen FILEHANDLE,FILENAME,MODE
3073
3074 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
3075
3076 Opens the file whose filename is given by FILENAME, and associates it
3077 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
3078 the name of the real filehandle wanted.  This function calls the
3079 underlying operating system's C<open> function with the parameters
3080 FILENAME, MODE, PERMS.
3081
3082 The possible values and flag bits of the MODE parameter are
3083 system-dependent; they are available via the standard module C<Fcntl>.
3084 However, for historical reasons, some values are universal: zero means
3085 read-only, one means write-only, and two means read/write.
3086
3087 If the file named by FILENAME does not exist and the C<open> call
3088 creates it (typically because MODE includes the O_CREAT flag), then
3089 the value of PERMS specifies the permissions of the newly created
3090 file.  If PERMS is omitted, the default value is 0666, which allows
3091 read and write for all.  This default is reasonable: see C<umask>.
3092
3093 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
3094
3095 =item sysread FILEHANDLE,SCALAR,LENGTH
3096
3097 Attempts to read LENGTH bytes of data into variable SCALAR from the
3098 specified FILEHANDLE, using the system call read(2).  It bypasses
3099 stdio, so mixing this with other kinds of reads may cause confusion.
3100 Returns the number of bytes actually read, or undef if there was an
3101 error.  SCALAR will be grown or shrunk so that the last byte actually
3102 read is the last byte of the scalar after the read.
3103
3104 An OFFSET may be specified to place the read data at some place in the
3105 string other than the beginning.  A negative OFFSET specifies
3106 placement at that many bytes counting backwards from the end of the
3107 string.  A positive OFFSET greater than the length of SCALAR results
3108 in the string being padded to the required size with "\0" bytes before
3109 the result of the read is appended.
3110
3111 =item system LIST
3112
3113 Does exactly the same thing as "exec LIST" except that a fork is done
3114 first, and the parent process waits for the child process to complete.
3115 Note that argument processing varies depending on the number of
3116 arguments.  The return value is the exit status of the program as
3117 returned by the wait() call.  To get the actual exit value divide by
3118 256.  See also L</exec>.  This is I<NOT> what you want to use to capture 
3119 the output from a command, for that you should use merely back-ticks, as
3120 described in L<perlop/"`STRING`">.
3121
3122 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
3123
3124 =item syswrite FILEHANDLE,SCALAR,LENGTH
3125
3126 Attempts to write LENGTH bytes of data from variable SCALAR to the
3127 specified FILEHANDLE, using the system call write(2).  It bypasses
3128 stdio, so mixing this with prints may cause confusion.  Returns the
3129 number of bytes actually written, or undef if there was an error.
3130 If the length is greater than the available data, only as much data as
3131 is available will be written.
3132
3133 An OFFSET may be specified to write the data from some part of the
3134 string other than the beginning.  A negative OFFSET specifies writing
3135 from that many bytes counting backwards from the end of the string.
3136
3137 =item tell FILEHANDLE
3138
3139 =item tell
3140
3141 Returns the current file position for FILEHANDLE.  FILEHANDLE may be an
3142 expression whose value gives the name of the actual filehandle.  If
3143 FILEHANDLE is omitted, assumes the file last read.
3144
3145 =item telldir DIRHANDLE
3146
3147 Returns the current position of the readdir() routines on DIRHANDLE.
3148 Value may be given to seekdir() to access a particular location in a
3149 directory.  Has the same caveats about possible directory compaction as
3150 the corresponding system library routine.
3151
3152 =item tie VARIABLE,CLASSNAME,LIST
3153
3154 This function binds a variable to a package class that will provide the
3155 implementation for the variable.  VARIABLE is the name of the variable
3156 to be enchanted.  CLASSNAME is the name of a class implementing objects
3157 of correct type.  Any additional arguments are passed to the "new"
3158 method of the class (meaning TIESCALAR, TIEARRAY, or TIEHASH).
3159 Typically these are arguments such as might be passed to the dbm_open()
3160 function of C.  The object returned by the "new" method is also
3161 returned by the tie() function, which would be useful if you want to
3162 access other methods in CLASSNAME.
3163
3164 Note that functions such as keys() and values() may return huge array
3165 values when used on large objects, like DBM files.  You may prefer to
3166 use the each() function to iterate over such.  Example:
3167
3168     # print out history file offsets
3169     use NDBM_File;
3170     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
3171     while (($key,$val) = each %HIST) {
3172         print $key, ' = ', unpack('L',$val), "\n";
3173     }
3174     untie(%HIST);
3175
3176 A class implementing an associative array should have the following
3177 methods:
3178
3179     TIEHASH classname, LIST
3180     DESTROY this
3181     FETCH this, key
3182     STORE this, key, value
3183     DELETE this, key
3184     EXISTS this, key
3185     FIRSTKEY this
3186     NEXTKEY this, lastkey
3187
3188 A class implementing an ordinary array should have the following methods:
3189
3190     TIEARRAY classname, LIST
3191     DESTROY this
3192     FETCH this, key
3193     STORE this, key, value
3194     [others TBD]
3195
3196 A class implementing a scalar should have the following methods:
3197
3198     TIESCALAR classname, LIST
3199     DESTROY this
3200     FETCH this, 
3201     STORE this, value
3202
3203 Unlike dbmopen(), the tie() function will not use or require a module
3204 for you--you need to do that explicitly yourself.  See L<DB_File>
3205 or the F<Config> module for interesting tie() implementations.
3206
3207 =item tied VARIABLE
3208
3209 Returns a reference to the object underlying VARIABLE (the same value
3210 that was originally returned by the tie() call which bound the variable
3211 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
3212 package.
3213
3214 =item time
3215
3216 Returns the number of non-leap seconds since whatever time the system
3217 considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS,
3218 and 00:00:00 UTC, January 1, 1970 for most other systems).
3219 Suitable for feeding to gmtime() and localtime().
3220
3221 =item times
3222
3223 Returns a four-element array giving the user and system times, in
3224 seconds, for this process and the children of this process.
3225
3226     ($user,$system,$cuser,$csystem) = times;
3227
3228 =item tr///
3229
3230 The translation operator.  See L<perlop>.
3231
3232 =item truncate FILEHANDLE,LENGTH
3233
3234 =item truncate EXPR,LENGTH
3235
3236 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
3237 specified length.  Produces a fatal error if truncate isn't implemented
3238 on your system.
3239
3240 =item uc EXPR
3241
3242 =item uc 
3243
3244 Returns an uppercased version of EXPR.  This is the internal function
3245 implementing the \U escape in double-quoted strings.
3246 Should respect any POSIX setlocale() settings.
3247
3248 If EXPR is omitted, uses $_.
3249
3250 =item ucfirst EXPR
3251
3252 =item ucfirst 
3253
3254 Returns the value of EXPR with the first character uppercased.  This is
3255 the internal function implementing the \u escape in double-quoted strings.
3256 Should respect any POSIX setlocale() settings.
3257
3258 If EXPR is omitted, uses $_.
3259
3260 =item umask EXPR
3261
3262 =item umask
3263
3264 Sets the umask for the process and returns the old one.  If EXPR is
3265 omitted, returns merely the current umask.
3266
3267 =item undef EXPR
3268
3269 =item undef
3270
3271 Undefines the value of EXPR, which must be an lvalue.  Use on only a
3272 scalar value, an entire array, or a subroutine name (using "&").  (Using undef()
3273 will probably not do what you expect on most predefined variables or
3274 DBM list values, so don't do that.)  Always returns the undefined value.  You can omit
3275 the EXPR, in which case nothing is undefined, but you still get an
3276 undefined value that you could, for instance, return from a
3277 subroutine.  Examples:
3278
3279     undef $foo;
3280     undef $bar{'blurfl'};
3281     undef @ary;
3282     undef %assoc;
3283     undef &mysub;
3284     return (wantarray ? () : undef) if $they_blew_it;
3285
3286 =item unlink LIST
3287
3288 =item unlink 
3289
3290 Deletes a list of files.  Returns the number of files successfully
3291 deleted.
3292
3293     $cnt = unlink 'a', 'b', 'c';
3294     unlink @goners;
3295     unlink <*.bak>;
3296
3297 Note: unlink will not delete directories unless you are superuser and
3298 the B<-U> flag is supplied to Perl.  Even if these conditions are
3299 met, be warned that unlinking a directory can inflict damage on your
3300 filesystem.  Use rmdir instead.
3301
3302 If LIST is omitted, uses $_.
3303
3304 =item unpack TEMPLATE,EXPR
3305
3306 Unpack does the reverse of pack: it takes a string representing a
3307 structure and expands it out into a list value, returning the array
3308 value.  (In a scalar context, it returns merely the first value
3309 produced.)  The TEMPLATE has the same format as in the pack function.
3310 Here's a subroutine that does substring:
3311
3312     sub substr {
3313         local($what,$where,$howmuch) = @_;
3314         unpack("x$where a$howmuch", $what);
3315     }
3316
3317 and then there's
3318
3319     sub ordinal { unpack("c",$_[0]); } # same as ord()
3320
3321 In addition, you may prefix a field with a %E<lt>numberE<gt> to indicate that
3322 you want a E<lt>numberE<gt>-bit checksum of the items instead of the items
3323 themselves.  Default is a 16-bit checksum.  For example, the following
3324 computes the same number as the System V sum program:
3325
3326     while (<>) {
3327         $checksum += unpack("%16C*", $_);
3328     }
3329     $checksum %= 65536;
3330
3331 The following efficiently counts the number of set bits in a bit vector:
3332
3333     $setbits = unpack("%32b*", $selectmask);
3334
3335 =item untie VARIABLE
3336
3337 Breaks the binding between a variable and a package.  (See tie().)
3338
3339 =item unshift ARRAY,LIST
3340
3341 Does the opposite of a C<shift>.  Or the opposite of a C<push>,
3342 depending on how you look at it.  Prepends list to the front of the
3343 array, and returns the new number of elements in the array.
3344
3345     unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/;
3346
3347 Note the LIST is prepended whole, not one element at a time, so the
3348 prepended elements stay in the same order.  Use reverse to do the
3349 reverse.
3350
3351 =item use Module LIST
3352
3353 =item use Module
3354
3355 =item use Module VERSION LIST
3356
3357 =item use VERSION
3358
3359 Imports some semantics into the current package from the named module,
3360 generally by aliasing certain subroutine or variable names into your
3361 package.  It is exactly equivalent to
3362
3363     BEGIN { require Module; import Module LIST; }
3364
3365 except that Module I<must> be a bare word.
3366
3367 If the first argument to C<use> is a number, it is treated as a version
3368 number instead of a module name.  If the version of the Perl interpreter
3369 is less than VERSION, then an error message is printed and Perl exits
3370 immediately.  This is often useful if you need to check the current
3371 Perl version before C<use>ing library modules which have changed in
3372 incompatible ways from older versions of Perl.  (We try not to do
3373 this more than we have to.)
3374
3375 The BEGIN forces the require and import to happen at compile time.  The
3376 require makes sure the module is loaded into memory if it hasn't been
3377 yet.  The import is not a builtin--it's just an ordinary static method
3378 call into the "Module" package to tell the module to import the list of
3379 features back into the current package.  The module can implement its
3380 import method any way it likes, though most modules just choose to
3381 derive their import method via inheritance from the Exporter class that
3382 is defined in the Exporter module. See L<Exporter>.  If no import
3383 method can be found then the error is currently silently ignored. This
3384 may change to a fatal error in a future version.
3385
3386 If you don't want your namespace altered, explicitly supply an empty list:
3387
3388     use Module ();
3389
3390 That is exactly equivalent to
3391
3392     BEGIN { require Module; }
3393
3394 If the VERSION argument is present between Module and LIST, then the
3395 C<use> will fail if the C<$VERSION> variable in package Module is
3396 less than VERSION.
3397
3398 Because this is a wide-open interface, pragmas (compiler directives)
3399 are also implemented this way.  Currently implemented pragmas are:
3400
3401     use integer;
3402     use diagnostics;
3403     use sigtrap qw(SEGV BUS);
3404     use strict  qw(subs vars refs);
3405     use subs    qw(afunc blurfl);
3406
3407 These pseudo-modules import semantics into the current block scope, unlike
3408 ordinary modules, which import symbols into the current package (which are
3409 effective through the end of the file).
3410
3411 There's a corresponding "no" command that unimports meanings imported
3412 by use, i.e., it calls C<unimport Module LIST> instead of C<import>.
3413
3414     no integer;
3415     no strict 'refs';
3416
3417 If no unimport method can be found the call fails with a fatal error.
3418
3419 See L<perlmod> for a list of standard modules and pragmas.
3420
3421 =item utime LIST
3422
3423 Changes the access and modification times on each file of a list of
3424 files.  The first two elements of the list must be the NUMERICAL access
3425 and modification times, in that order.  Returns the number of files
3426 successfully changed.  The inode modification time of each file is set
3427 to the current time.  Example of a "touch" command:
3428
3429     #!/usr/bin/perl
3430     $now = time;
3431     utime $now, $now, @ARGV;
3432
3433 =item values ASSOC_ARRAY
3434
3435 Returns a normal array consisting of all the values of the named
3436 associative array.  (In a scalar context, returns the number of
3437 values.)  The values are returned in an apparently random order, but it
3438 is the same order as either the keys() or each() function would produce
3439 on the same array.  See also keys(), each(), and sort().
3440
3441 =item vec EXPR,OFFSET,BITS
3442
3443 Treats the string in EXPR as a vector of unsigned integers, and
3444 returns the value of the bit field specified by OFFSET.  BITS specifies
3445 the number of bits that are reserved for each entry in the bit
3446 vector. This must be a power of two from 1 to 32. vec() may also be
3447 assigned to, in which case parentheses are needed to give the expression
3448 the correct precedence as in
3449
3450     vec($image, $max_x * $x + $y, 8) = 3;
3451
3452 Vectors created with vec() can also be manipulated with the logical
3453 operators |, &, and ^, which will assume a bit vector operation is
3454 desired when both operands are strings.
3455
3456 To transform a bit vector into a string or array of 0's and 1's, use these:
3457
3458     $bits = unpack("b*", $vector);
3459     @bits = split(//, unpack("b*", $vector));
3460
3461 If you know the exact length in bits, it can be used in place of the *.
3462
3463 =item wait
3464
3465 Waits for a child process to terminate and returns the pid of the
3466 deceased process, or -1 if there are no child processes.  The status is
3467 returned in C<$?>.
3468
3469 =item waitpid PID,FLAGS
3470
3471 Waits for a particular child process to terminate and returns the pid
3472 of the deceased process, or -1 if there is no such child process.  The
3473 status is returned in C<$?>.  If you say
3474
3475     use POSIX ":sys_wait_h";
3476     ...
3477     waitpid(-1,&WNOHANG);
3478
3479 then you can do a non-blocking wait for any process.  Non-blocking wait
3480 is available on machines supporting either the waitpid(2) or
3481 wait4(2) system calls.  However, waiting for a particular pid with
3482 FLAGS of 0 is implemented everywhere.  (Perl emulates the system call
3483 by remembering the status values of processes that have exited but have
3484 not been harvested by the Perl script yet.)
3485
3486 =item wantarray
3487
3488 Returns TRUE if the context of the currently executing subroutine is
3489 looking for a list value.  Returns FALSE if the context is looking
3490 for a scalar.
3491
3492     return wantarray ? () : undef;
3493
3494 =item warn LIST
3495
3496 Produces a message on STDERR just like die(), but doesn't exit or
3497 on an exception.
3498
3499 =item write FILEHANDLE
3500
3501 =item write EXPR
3502
3503 =item write
3504
3505 Writes a formatted record (possibly multi-line) to the specified file,
3506 using the format associated with that file.  By default the format for
3507 a file is the one having the same name is the filehandle, but the
3508 format for the current output channel (see the select() function) may be set
3509 explicitly by assigning the name of the format to the C<$~> variable.
3510
3511 Top of form processing is handled automatically:  if there is
3512 insufficient room on the current page for the formatted record, the
3513 page is advanced by writing a form feed, a special top-of-page format
3514 is used to format the new page header, and then the record is written.
3515 By default the top-of-page format is the name of the filehandle with
3516 "_TOP" appended, but it may be dynamically set to the format of your
3517 choice by assigning the name to the C<$^> variable while the filehandle is
3518 selected.  The number of lines remaining on the current page is in
3519 variable C<$->, which can be set to 0 to force a new page.
3520
3521 If FILEHANDLE is unspecified, output goes to the current default output
3522 channel, which starts out as STDOUT but may be changed by the
3523 C<select> operator.  If the FILEHANDLE is an EXPR, then the expression
3524 is evaluated and the resulting string is used to look up the name of
3525 the FILEHANDLE at run time.  For more on formats, see L<perlform>.
3526
3527 Note that write is I<NOT> the opposite of read.  Unfortunately.
3528
3529 =item y///
3530
3531 The translation operator.  See L<perlop>.
3532
3533 =back