This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Deparse: avoid upgrading RV to GV in stash entries
[perl5.git] / lib / B / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD OPf_PARENS
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpKVSLICE
16          OPpCONST_BARE
17          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
18          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER OPpREPEAT_DOLIST
19          OPpSORT_REVERSE OPpMULTIDEREF_EXISTS OPpMULTIDEREF_DELETE
20          OPpSPLIT_ASSIGN OPpSPLIT_LEX
21          OPpPADHV_ISKEYS OPpRV2HV_ISKEYS
22          OPpCONCAT_NESTED
23          OPpMULTICONCAT_APPEND OPpMULTICONCAT_STRINGIFY OPpMULTICONCAT_FAKE
24          OPpTRUEBOOL OPpINDEX_BOOLNEG
25          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
26          SVs_PADTMP SVpad_TYPED
27          CVf_METHOD CVf_LVALUE
28          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
29          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED PMf_EXTENDED_MORE
30          PADNAMEt_OUTER
31         MDEREF_reload
32         MDEREF_AV_pop_rv2av_aelem
33         MDEREF_AV_gvsv_vivify_rv2av_aelem
34         MDEREF_AV_padsv_vivify_rv2av_aelem
35         MDEREF_AV_vivify_rv2av_aelem
36         MDEREF_AV_padav_aelem
37         MDEREF_AV_gvav_aelem
38         MDEREF_HV_pop_rv2hv_helem
39         MDEREF_HV_gvsv_vivify_rv2hv_helem
40         MDEREF_HV_padsv_vivify_rv2hv_helem
41         MDEREF_HV_vivify_rv2hv_helem
42         MDEREF_HV_padhv_helem
43         MDEREF_HV_gvhv_helem
44         MDEREF_ACTION_MASK
45         MDEREF_INDEX_none
46         MDEREF_INDEX_const
47         MDEREF_INDEX_padsv
48         MDEREF_INDEX_gvsv
49         MDEREF_INDEX_MASK
50         MDEREF_FLAG_last
51         MDEREF_MASK
52         MDEREF_SHIFT
53     );
54
55 $VERSION = '1.46';
56 use strict;
57 our $AUTOLOAD;
58 use warnings ();
59 require feature;
60
61 BEGIN {
62     # List version-specific constants here.
63     # Easiest way to keep this code portable between version looks to
64     # be to fake up a dummy constant that will never actually be true.
65     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
66                 OPpPAD_STATE PMf_SKIPWHITE RXf_SKIPWHITE
67                 PMf_CHARSET PMf_KEEPCOPY PMf_NOCAPTURE CVf_ANONCONST
68                 CVf_LOCKED OPpREVERSE_INPLACE OPpSUBSTR_REPL_FIRST
69                 PMf_NONDESTRUCT OPpCONST_ARYBASE OPpEVAL_BYTES
70                 OPpLVREF_TYPE OPpLVREF_SV OPpLVREF_AV OPpLVREF_HV
71                 OPpLVREF_CV OPpLVREF_ELEM SVpad_STATE)) {
72         eval { B->import($_) };
73         no strict 'refs';
74         *{$_} = sub () {0} unless *{$_}{CODE};
75     }
76 }
77
78 # Todo:
79 #  (See also BUGS section at the end of this file)
80 #
81 # - finish tr/// changes
82 # - add option for even more parens (generalize \&foo change)
83 # - left/right context
84 # - copy comments (look at real text with $^P?)
85 # - avoid semis in one-statement blocks
86 # - associativity of &&=, ||=, ?:
87 # - ',' => '=>' (auto-unquote?)
88 # - break long lines ("\r" as discretionary break?)
89 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
90 # - more style options: brace style, hex vs. octal, quotes, ...
91 # - print big ints as hex/octal instead of decimal (heuristic?)
92 # - handle 'my $x if 0'?
93 # - version using op_next instead of op_first/sibling?
94 # - avoid string copies (pass arrays, one big join?)
95 # - here-docs?
96
97 # Current test.deparse failures
98 # comp/hints 6 - location of BEGIN blocks wrt. block openings
99 # run/switchI 1 - missing -I switches entirely
100 #    perl -Ifoo -e 'print @INC'
101 # op/caller 2 - warning mask propagates backwards before warnings::register
102 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
103 # op/getpid 2 - can't assign to shared my() declaration (threads only)
104 #    'my $x : shared = 5'
105 # op/override 7 - parens on overridden require change v-string interpretation
106 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
107 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
108 # op/pat 774 - losing Unicode-ness of Latin1-only strings
109 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
110 # op/recurse 12 - missing parens on recursive call makes it look like method
111 #    'sub f { f($x) }'
112 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
113 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
114 # op/tiehandle compile - "use strict" deparsed in the wrong place
115 # uni/tr_ several
116 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
117 # ext/Data/Dumper/t/dumper compile
118 # ext/DB_file/several
119 # ext/Encode/several
120 # ext/Ernno/Errno warnings
121 # ext/IO/lib/IO/t/io_sel 23
122 # ext/PerlIO/t/encoding compile
123 # ext/POSIX/t/posix 6
124 # ext/Socket/Socket 8
125 # ext/Storable/t/croak compile
126 # lib/Attribute/Handlers/t/multi compile
127 # lib/bignum/ several
128 # lib/charnames 35
129 # lib/constant 32
130 # lib/English 40
131 # lib/ExtUtils/t/bytes 4
132 # lib/File/DosGlob compile
133 # lib/Filter/Simple/t/data 1
134 # lib/Math/BigInt/t/constant 1
135 # lib/Net/t/config Deparse-warning
136 # lib/overload compile
137 # lib/Switch/ several
138 # lib/Symbol 4
139 # lib/Test/Simple several
140 # lib/Term/Complete
141 # lib/Tie/File/t/29_downcopy 5
142 # lib/vars 22
143
144 # Object fields:
145 #
146 # in_coderef2text:
147 # True when deparsing via $deparse->coderef2text; false when deparsing the
148 # main program.
149 #
150 # avoid_local:
151 # (local($a), local($b)) and local($a, $b) have the same internal
152 # representation but the short form looks better. We notice we can
153 # use a large-scale local when checking the list, but need to prevent
154 # individual locals too. This hash holds the addresses of OPs that
155 # have already had their local-ness accounted for. The same thing
156 # is done with my().
157 #
158 # curcv:
159 # CV for current sub (or main program) being deparsed
160 #
161 # curcvlex:
162 # Cached hash of lexical variables for curcv: keys are
163 # names prefixed with "m" or "o" (representing my/our), and
164 # each value is an array with two elements indicating the cop_seq
165 # of scopes in which a var of that name is valid and a third ele-
166 # ment referencing the pad name.
167 #
168 # curcop:
169 # COP for statement being deparsed
170 #
171 # curstash:
172 # name of the current package for deparsed code
173 #
174 # subs_todo:
175 # array of [cop_seq, CV, is_format?, name] for subs and formats we still
176 # want to deparse.  The fourth element is a pad name thingy for lexical
177 # subs or a string for special blocks.  For other subs, it is undef.  For
178 # lexical subs, CV may be undef, indicating a stub declaration.
179 #
180 # protos_todo:
181 # as above, but [name, prototype] for subs that never got a GV
182 #
183 # subs_done, forms_done:
184 # keys are addresses of GVs for subs and formats we've already
185 # deparsed (or at least put into subs_todo)
186 #
187 # subs_declared
188 # keys are names of subs for which we've printed declarations.
189 # That means we can omit parentheses from the arguments. It also means we
190 # need to put CORE:: on core functions of the same name.
191 #
192 # in_subst_repl
193 # True when deparsing the replacement part of a substitution.
194 #
195 # in_refgen
196 # True when deparsing the argument to \.
197 #
198 # parens: -p
199 # linenums: -l
200 # unquote: -q
201 # cuddle: ' ' or '\n', depending on -sC
202 # indent_size: -si
203 # use_tabs: -sT
204 # ex_const: -sv
205
206 # A little explanation of how precedence contexts and associativity
207 # work:
208 #
209 # deparse() calls each per-op subroutine with an argument $cx (short
210 # for context, but not the same as the cx* in the perl core), which is
211 # a number describing the op's parents in terms of precedence, whether
212 # they're inside an expression or at statement level, etc.  (see
213 # chart below). When ops with children call deparse on them, they pass
214 # along their precedence. Fractional values are used to implement
215 # associativity ('($x + $y) + $z' => '$x + $y + $y') and related
216 # parentheses hacks. The major disadvantage of this scheme is that
217 # it doesn't know about right sides and left sides, so say if you
218 # assign a listop to a variable, it can't tell it's allowed to leave
219 # the parens off the listop.
220
221 # Precedences:
222 # 26             [TODO] inside interpolation context ("")
223 # 25 left        terms and list operators (leftward)
224 # 24 left        ->
225 # 23 nonassoc    ++ --
226 # 22 right       **
227 # 21 right       ! ~ \ and unary + and -
228 # 20 left        =~ !~
229 # 19 left        * / % x
230 # 18 left        + - .
231 # 17 left        << >>
232 # 16 nonassoc    named unary operators
233 # 15 nonassoc    < > <= >= lt gt le ge
234 # 14 nonassoc    == != <=> eq ne cmp
235 # 13 left        &
236 # 12 left        | ^
237 # 11 left        &&
238 # 10 left        ||
239 #  9 nonassoc    ..  ...
240 #  8 right       ?:
241 #  7 right       = += -= *= etc.
242 #  6 left        , =>
243 #  5 nonassoc    list operators (rightward)
244 #  4 right       not
245 #  3 left        and
246 #  2 left        or xor
247 #  1             statement modifiers
248 #  0.5           statements, but still print scopes as do { ... }
249 #  0             statement level
250 # -1             format body
251
252 # Nonprinting characters with special meaning:
253 # \cS - steal parens (see maybe_parens_unop)
254 # \n - newline and indent
255 # \t - increase indent
256 # \b - decrease indent ('outdent')
257 # \f - flush left (no indent)
258 # \cK - kill following semicolon, if any
259
260 # Semicolon handling:
261 #  - Individual statements are not deparsed with trailing semicolons.
262 #    (If necessary, \cK is tacked on to the end.)
263 #  - Whatever code joins statements together or emits them (lineseq,
264 #    scopeop, deparse_root) is responsible for adding semicolons where
265 #    necessary.
266 #  - use statements are deparsed with trailing semicolons because they are
267 #    immediately concatenated with the following statement.
268 #  - indent() removes semicolons wherever it sees \cK.
269
270
271 BEGIN { for (qw[ const stringify rv2sv list glob pushmark null aelem
272                  kvaslice kvhslice padsv
273                  nextstate dbstate rv2av rv2hv helem custom ]) {
274     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
275 }}
276
277 # _pessimise_walk(): recursively walk the optree of a sub,
278 # possibly undoing optimisations along the way.
279
280 sub _pessimise_walk {
281     my ($self, $startop) = @_;
282
283     return unless $$startop;
284     my ($op, $prevop);
285     for ($op = $startop; $$op; $prevop = $op, $op = $op->sibling) {
286         my $ppname = $op->name;
287
288         # pessimisations start here
289
290         if ($ppname eq "padrange") {
291             # remove PADRANGE:
292             # the original optimisation either (1) changed this:
293             #    pushmark -> (various pad and list and null ops) -> the_rest
294             # or (2), for the = @_ case, changed this:
295             #    pushmark -> gv[_] -> rv2av -> (pad stuff)       -> the_rest
296             # into this:
297             #    padrange ----------------------------------------> the_rest
298             # so we just need to convert the padrange back into a
299             # pushmark, and in case (1), set its op_next to op_sibling,
300             # which is the head of the original chain of optimised-away
301             # pad ops, or for (2), set it to sibling->first, which is
302             # the original gv[_].
303
304             $B::overlay->{$$op} = {
305                     type => OP_PUSHMARK,
306                     name => 'pushmark',
307                     private => ($op->private & OPpLVAL_INTRO),
308             };
309         }
310
311         # pessimisations end here
312
313         if (class($op) eq 'PMOP') {
314             if (ref($op->pmreplroot)
315                 && ${$op->pmreplroot}
316                 && $op->pmreplroot->isa( 'B::OP' ))
317             {
318                 $self-> _pessimise_walk($op->pmreplroot);
319             }
320
321             # pessimise any /(?{...})/ code blocks
322             my ($re, $cv);
323             my $code_list = $op->code_list;
324             if ($$code_list) {
325                 $self->_pessimise_walk($code_list);
326             }
327             elsif (${$re = $op->pmregexp} && ${$cv = $re->qr_anoncv}) {
328                 $code_list = $cv->ROOT      # leavesub
329                                ->first      #   qr
330                                ->code_list; #     list
331                 $self->_pessimise_walk($code_list);
332             }
333         }
334
335         if ($op->flags & OPf_KIDS) {
336             $self-> _pessimise_walk($op->first);
337         }
338
339     }
340 }
341
342
343 # _pessimise_walk_exe(): recursively walk the op_next chain of a sub,
344 # possibly undoing optimisations along the way.
345
346 sub _pessimise_walk_exe {
347     my ($self, $startop, $visited) = @_;
348
349     no warnings 'recursion';
350
351     return unless $$startop;
352     return if $visited->{$$startop};
353     my ($op, $prevop);
354     for ($op = $startop; $$op; $prevop = $op, $op = $op->next) {
355         last if $visited->{$$op};
356         $visited->{$$op} = 1;
357         my $ppname = $op->name;
358         if ($ppname =~
359             /^((and|d?or)(assign)?|(map|grep)while|range|cond_expr|once)$/
360             # entertry is also a logop, but its op_other invariably points
361             # into the same chain as the main execution path, so we skip it
362         ) {
363             $self->_pessimise_walk_exe($op->other, $visited);
364         }
365         elsif ($ppname eq "subst") {
366             $self->_pessimise_walk_exe($op->pmreplstart, $visited);
367         }
368         elsif ($ppname =~ /^(enter(loop|iter))$/) {
369             # redoop and nextop will already be covered by the main block
370             # of the loop
371             $self->_pessimise_walk_exe($op->lastop, $visited);
372         }
373
374         # pessimisations start here
375     }
376 }
377
378 # Go through an optree and "remove" some optimisations by using an
379 # overlay to selectively modify or un-null some ops. Deparsing in the
380 # absence of those optimisations is then easier.
381 #
382 # Note that older optimisations are not removed, as Deparse was already
383 # written to recognise them before the pessimise/overlay system was added.
384
385 sub pessimise {
386     my ($self, $root, $start) = @_;
387
388     no warnings 'recursion';
389     # walk tree in root-to-branch order
390     $self->_pessimise_walk($root);
391
392     my %visited;
393     # walk tree in execution order
394     $self->_pessimise_walk_exe($start, \%visited);
395 }
396
397
398 sub null {
399     my $op = shift;
400     return class($op) eq "NULL";
401 }
402
403
404 # Add a CV to the list of subs that still need deparsing.
405
406 sub todo {
407     my $self = shift;
408     my($cv, $is_form, $name) = @_;
409     my $cvfile = $cv->FILE//'';
410     return unless ($cvfile eq $0 || exists $self->{files}{$cvfile});
411     my $seq;
412     if ($cv->OUTSIDE_SEQ) {
413         $seq = $cv->OUTSIDE_SEQ;
414     } elsif (!null($cv->START) and is_state($cv->START)) {
415         $seq = $cv->START->cop_seq;
416     } else {
417         $seq = 0;
418     }
419     my $stash = $cv->STASH;
420     if (class($stash) eq 'HV') {
421         $self->{packs}{$stash->NAME}++;
422     }
423     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form, $name];
424 }
425
426
427 # Pop the next sub from the todo list and deparse it
428
429 sub next_todo {
430     my $self = shift;
431     my $ent = shift @{$self->{'subs_todo'}};
432     my ($seq, $cv, $is_form, $name) = @$ent;
433
434     # any 'use strict; package foo' that should come before the sub
435     # declaration to sync with the first COP of the sub
436     my $pragmata = '';
437     if ($cv and !null($cv->START) and is_state($cv->START))  {
438         $pragmata = $self->pragmata($cv->START);
439     }
440
441     if (ref $name) { # lexical sub
442         # emit the sub.
443         my @text;
444         my $flags = $name->FLAGS;
445         push @text,
446             !$cv || $seq <= $name->COP_SEQ_RANGE_LOW
447                 ? $self->keyword($flags & SVpad_OUR
448                                     ? "our"
449                                     : $flags & SVpad_STATE
450                                         ? "state"
451                                         : "my") . " "
452                 : "";
453         # XXX We would do $self->keyword("sub"), but ‘my CORE::sub’
454         #     doesn’t work and ‘my sub’ ignores a &sub in scope.  I.e.,
455         #     we have a core bug here.
456         push @text, "sub " . substr $name->PVX, 1;
457         if ($cv) {
458             # my sub foo { }
459             push @text,  " " . $self->deparse_sub($cv);
460             $text[-1] =~ s/ ;$/;/;
461         }
462         else {
463             # my sub foo;
464             push @text, ";\n";
465         }
466         return $pragmata . join "", @text;
467     }
468
469     my $gv = $cv->GV;
470     $name //= $self->gv_name($gv);
471     if ($is_form) {
472         return $pragmata . $self->keyword("format") . " $name =\n"
473             . $self->deparse_format($cv). "\n";
474     } else {
475         my $use_dec;
476         if ($name eq "BEGIN") {
477             $use_dec = $self->begin_is_use($cv);
478             if (defined ($use_dec) and $self->{'expand'} < 5) {
479                 return $pragmata if 0 == length($use_dec);
480
481                 #  XXX bit of a hack: Test::More's use_ok() method
482                 #  builds a fake use statement which deparses as, e.g.
483                 #      use Net::Ping (@{$args[0];});
484                 #  As well as being superfluous (the use_ok() is deparsed
485                 #  too) and ugly, it fails under use strict and otherwise
486                 #  makes use of a lexical var that's not in scope.
487                 #  So strip it out.
488                 return $pragmata
489                         if $use_dec =~
490                             m/
491                                 \A
492                                 use \s \S+ \s \(\@\{
493                                 (
494                                     \s*\#line\ \d+\ \".*"\s*
495                                 )?
496                                 \$args\[0\];\}\);
497                                 \n
498                                 \Z
499                             /x;
500
501                 $use_dec =~ s/^(use|no)\b/$self->keyword($1)/e;
502             }
503         }
504         my $l = '';
505         if ($self->{'linenums'}) {
506             my $line = $gv->LINE;
507             my $file = $gv->FILE;
508             $l = "\n\f#line $line \"$file\"\n";
509         }
510         my $p = '';
511         my $stash;
512         if (class($cv->STASH) ne "SPECIAL") {
513             $stash = $cv->STASH->NAME;
514             if ($stash ne $self->{'curstash'}) {
515                 $p = $self->keyword("package") . " $stash;\n";
516                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
517                 $self->{'curstash'} = $stash;
518             }
519         }
520         if ($use_dec) {
521             return "$pragmata$p$l$use_dec";
522         }
523         if ( $name !~ /::/ and $self->lex_in_scope("&$name")
524                             || $self->lex_in_scope("&$name", 1) )
525         {
526             $name = "$self->{'curstash'}::$name";
527         } elsif (defined $stash) {
528             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
529         }
530         my $ret = "$pragmata${p}${l}" . $self->keyword("sub") . " $name "
531               . $self->deparse_sub($cv);
532         $self->{'subs_declared'}{$name} = 1;
533         return $ret;
534     }
535 }
536
537
538 # Return a "use" declaration for this BEGIN block, if appropriate
539 sub begin_is_use {
540     my ($self, $cv) = @_;
541     my $root = $cv->ROOT;
542     local @$self{qw'curcv curcvlex'} = ($cv);
543     local $B::overlay = {};
544     $self->pessimise($root, $cv->START);
545 #require B::Debug;
546 #B::walkoptree($cv->ROOT, "debug");
547     my $lineseq = $root->first;
548     return if $lineseq->name ne "lineseq";
549
550     my $req_op = $lineseq->first->sibling;
551     return if $req_op->name ne "require";
552
553     # maybe it's C<require expr> rather than C<require 'foo'>
554     return if ($req_op->first->name ne 'const');
555
556     my $module;
557     if ($req_op->first->private & OPpCONST_BARE) {
558         # Actually it should always be a bareword
559         $module = $self->const_sv($req_op->first)->PV;
560         $module =~ s[/][::]g;
561         $module =~ s/.pm$//;
562     }
563     else {
564         $module = $self->const($self->const_sv($req_op->first), 6);
565     }
566
567     my $version;
568     my $version_op = $req_op->sibling;
569     return if class($version_op) eq "NULL";
570     if ($version_op->name eq "lineseq") {
571         # We have a version parameter; skip nextstate & pushmark
572         my $constop = $version_op->first->next->next;
573
574         return unless $self->const_sv($constop)->PV eq $module;
575         $constop = $constop->sibling;
576         $version = $self->const_sv($constop);
577         if (class($version) eq "IV") {
578             $version = $version->int_value;
579         } elsif (class($version) eq "NV") {
580             $version = $version->NV;
581         } elsif (class($version) ne "PVMG") {
582             # Includes PVIV and PVNV
583             $version = $version->PV;
584         } else {
585             # version specified as a v-string
586             $version = 'v'.join '.', map ord, split //, $version->PV;
587         }
588         $constop = $constop->sibling;
589         return if $constop->name ne "method_named";
590         return if $self->meth_sv($constop)->PV ne "VERSION";
591     }
592
593     $lineseq = $version_op->sibling;
594     return if $lineseq->name ne "lineseq";
595     my $entersub = $lineseq->first->sibling;
596     if ($entersub->name eq "stub") {
597         return "use $module $version ();\n" if defined $version;
598         return "use $module ();\n";
599     }
600     return if $entersub->name ne "entersub";
601
602     # See if there are import arguments
603     my $args = '';
604
605     my $svop = $entersub->first->sibling; # Skip over pushmark
606     return unless $self->const_sv($svop)->PV eq $module;
607
608     # Pull out the arguments
609     for ($svop=$svop->sibling; index($svop->name, "method_") != 0;
610                 $svop = $svop->sibling) {
611         $args .= ", " if length($args);
612         $args .= $self->deparse($svop, 6);
613     }
614
615     my $use = 'use';
616     my $method_named = $svop;
617     return if $method_named->name ne "method_named";
618     my $method_name = $self->meth_sv($method_named)->PV;
619
620     if ($method_name eq "unimport") {
621         $use = 'no';
622     }
623
624     # Certain pragmas are dealt with using hint bits,
625     # so we ignore them here
626     if ($module eq 'strict' || $module eq 'integer'
627         || $module eq 'bytes' || $module eq 'warnings'
628         || $module eq 'feature') {
629         return "";
630     }
631
632     if (defined $version && length $args) {
633         return "$use $module $version ($args);\n";
634     } elsif (defined $version) {
635         return "$use $module $version;\n";
636     } elsif (length $args) {
637         return "$use $module ($args);\n";
638     } else {
639         return "$use $module;\n";
640     }
641 }
642
643 sub stash_subs {
644     my ($self, $pack, $seen) = @_;
645     my (@ret, $stash);
646     if (!defined $pack) {
647         $pack = '';
648         $stash = \%::;
649     }
650     else {
651         $pack =~ s/(::)?$/::/;
652         no strict 'refs';
653         $stash = \%{"main::$pack"};
654     }
655     return
656         if ($seen ||= {})->{
657             $INC{"overload.pm"} ? overload::StrVal($stash) : $stash
658            }++;
659     my $stashobj = svref_2object($stash);
660     my %stash = $stashobj->ARRAY;
661     while (my ($key, $val) = each %stash) {
662         my $flags = $val->FLAGS;
663         if ($flags & SVf_ROK) {
664             # A reference.  Dump this if it is a reference to a CV.  If it
665             # is a constant acting as a proxy for a full subroutine, then
666             # we may or may not have to dump it.  If some form of perl-
667             # space visible code must have created it, be it a use
668             # statement, or some direct symbol-table manipulation code that
669             # we will deparse, then we don’t want to dump it.  If it is the
670             # result of a declaration like sub f () { 42 } then we *do*
671             # want to dump it.  The only way to distinguish these seems
672             # to be the SVs_PADTMP flag on the constant, which is admit-
673             # tedly a hack.
674             my $class = class(my $referent = $val->RV);
675             if ($class eq "CV") {
676                 $self->todo($referent, 0);
677             } elsif (
678                 $class !~ /^(AV|HV|CV|FM|IO|SPECIAL)\z/
679                 # A more robust way to write that would be this, but B does
680                 # not provide the SVt_ constants:
681                 # ($referent->FLAGS & B::SVTYPEMASK) < B::SVt_PVAV
682                 and $referent->FLAGS & SVs_PADTMP
683             ) {
684                 push @{$self->{'protos_todo'}}, [$pack . $key, $val];
685             }
686         } elsif ($flags & (SVf_POK|SVf_IOK)) {
687             # Just a prototype. As an ugly but fairly effective way
688             # to find out if it belongs here is to see if the AUTOLOAD
689             # (if any) for the stash was defined in one of our files.
690             my $A = $stash{"AUTOLOAD"};
691             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
692                 && class($A->CV) eq "CV") {
693                 my $AF = $A->FILE;
694                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
695             }
696             push @{$self->{'protos_todo'}},
697                  [$pack . $key, $flags & SVf_POK ? $val->PV: undef];
698         } elsif (class($val) eq "GV") {
699             if (class(my $cv = $val->CV) ne "SPECIAL") {
700                 next if $self->{'subs_done'}{$$val}++;
701
702                 # Ignore imposters (aliases etc)
703                 my $name = $cv->NAME_HEK;
704                 if(defined $name) {
705                     # avoid using $cv->GV here because if the $val GV is
706                     # an alias, CvGV() could upgrade the real stash entry
707                     # from an RV to a GV
708                     next unless $name eq $key;
709                     next unless $$stashobj == ${$cv->STASH};
710                 }
711                 else {
712                    next if $$val != ${$cv->GV};
713                 }
714
715                 $self->todo($cv, 0);
716             }
717             if (class(my $cv = $val->FORM) ne "SPECIAL") {
718                 next if $self->{'forms_done'}{$$val}++;
719                 next if $$val != ${$cv->GV};   # Ignore imposters
720                 $self->todo($cv, 1);
721             }
722             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
723                 $self->stash_subs($pack . $key, $seen);
724             }
725         }
726     }
727 }
728
729 sub print_protos {
730     my $self = shift;
731     my $ar;
732     my @ret;
733     foreach $ar (@{$self->{'protos_todo'}}) {
734         if (ref $ar->[1]) {
735             # Only print a constant if it occurs in the same package as a
736             # dumped sub.  This is not perfect, but a heuristic that will
737             # hopefully work most of the time.  Ideally we would use
738             # CvFILE, but a constant stub has no CvFILE.
739             my $pack = ($ar->[0] =~ /(.*)::/)[0];
740             next if $pack and !$self->{packs}{$pack}
741         }
742         my $body = defined $ar->[1]
743                 ? ref $ar->[1]
744                     ? " () {\n    " . $self->const($ar->[1]->RV,0) . ";\n}"
745                     : " (". $ar->[1] . ");"
746                 : ";";
747         push @ret, "sub " . $ar->[0] .  "$body\n";
748     }
749     delete $self->{'protos_todo'};
750     return @ret;
751 }
752
753 sub style_opts {
754     my $self = shift;
755     my $opts = shift;
756     my $opt;
757     while (length($opt = substr($opts, 0, 1))) {
758         if ($opt eq "C") {
759             $self->{'cuddle'} = " ";
760             $opts = substr($opts, 1);
761         } elsif ($opt eq "i") {
762             $opts =~ s/^i(\d+)//;
763             $self->{'indent_size'} = $1;
764         } elsif ($opt eq "T") {
765             $self->{'use_tabs'} = 1;
766             $opts = substr($opts, 1);
767         } elsif ($opt eq "v") {
768             $opts =~ s/^v([^.]*)(.|$)//;
769             $self->{'ex_const'} = $1;
770         }
771     }
772 }
773
774 sub new {
775     my $class = shift;
776     my $self = bless {}, $class;
777     $self->{'cuddle'} = "\n";
778     $self->{'curcop'} = undef;
779     $self->{'curstash'} = "main";
780     $self->{'ex_const'} = "'???'";
781     $self->{'expand'} = 0;
782     $self->{'files'} = {};
783     $self->{'packs'} = {};
784     $self->{'indent_size'} = 4;
785     $self->{'linenums'} = 0;
786     $self->{'parens'} = 0;
787     $self->{'subs_todo'} = [];
788     $self->{'unquote'} = 0;
789     $self->{'use_dumper'} = 0;
790     $self->{'use_tabs'} = 0;
791
792     $self->{'ambient_arybase'} = 0;
793     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
794     $self->{'ambient_hints'} = 0;
795     $self->{'ambient_hinthash'} = undef;
796     $self->init();
797
798     while (my $arg = shift @_) {
799         if ($arg eq "-d") {
800             $self->{'use_dumper'} = 1;
801             require Data::Dumper;
802         } elsif ($arg =~ /^-f(.*)/) {
803             $self->{'files'}{$1} = 1;
804         } elsif ($arg eq "-l") {
805             $self->{'linenums'} = 1;
806         } elsif ($arg eq "-p") {
807             $self->{'parens'} = 1;
808         } elsif ($arg eq "-P") {
809             $self->{'noproto'} = 1;
810         } elsif ($arg eq "-q") {
811             $self->{'unquote'} = 1;
812         } elsif (substr($arg, 0, 2) eq "-s") {
813             $self->style_opts(substr $arg, 2);
814         } elsif ($arg =~ /^-x(\d)$/) {
815             $self->{'expand'} = $1;
816         }
817     }
818     return $self;
819 }
820
821 {
822     # Mask out the bits that L<warnings::register> uses
823     my $WARN_MASK;
824     BEGIN {
825         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
826     }
827     sub WARN_MASK () {
828         return $WARN_MASK;
829     }
830 }
831
832 # Initialise the contextual information, either from
833 # defaults provided with the ambient_pragmas method,
834 # or from perl's own defaults otherwise.
835 sub init {
836     my $self = shift;
837
838     $self->{'arybase'}  = $self->{'ambient_arybase'};
839     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
840                                 ? $self->{'ambient_warnings'} & WARN_MASK
841                                 : undef;
842     $self->{'hints'}    = $self->{'ambient_hints'};
843     $self->{'hinthash'} = $self->{'ambient_hinthash'};
844
845     # also a convenient place to clear out subs_declared
846     delete $self->{'subs_declared'};
847 }
848
849 sub compile {
850     my(@args) = @_;
851     return sub {
852         my $self = B::Deparse->new(@args);
853         # First deparse command-line args
854         if (defined $^I) { # deparse -i
855             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
856         }
857         if ($^W) { # deparse -w
858             print qq(BEGIN { \$^W = $^W; }\n);
859         }
860         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
861             my $fs = perlstring($/) || 'undef';
862             my $bs = perlstring($O::savebackslash) || 'undef';
863             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
864         }
865         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
866         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
867             ? B::unitcheck_av->ARRAY
868             : ();
869         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
870         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
871         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
872         my @names = qw(BEGIN UNITCHECK CHECK INIT END);
873         my @blocks = \(@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs);
874         while (@names) {
875             my ($name, $blocks) = (shift @names, shift @blocks);
876             for my $block (@$blocks) {
877                 $self->todo($block, 0, $name);
878             }
879         }
880         $self->stash_subs();
881         local($SIG{"__DIE__"}) =
882           sub {
883               if ($self->{'curcop'}) {
884                   my $cop = $self->{'curcop'};
885                   my($line, $file) = ($cop->line, $cop->file);
886                   print STDERR "While deparsing $file near line $line,\n";
887               }
888             };
889         $self->{'curcv'} = main_cv;
890         $self->{'curcvlex'} = undef;
891         print $self->print_protos;
892         @{$self->{'subs_todo'}} =
893           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
894         my $root = main_root;
895         local $B::overlay = {};
896         unless (null $root) {
897             $self->pad_subs($self->{'curcv'});
898             # Check for a stub-followed-by-ex-cop, resulting from a program
899             # consisting solely of sub declarations.  For backward-compati-
900             # bility (and sane output) we don’t want to emit the stub.
901             #   leave
902             #     enter
903             #     stub
904             #     ex-nextstate (or ex-dbstate)
905             my $kid;
906             if ( $root->name eq 'leave'
907              and ($kid = $root->first)->name eq 'enter'
908              and !null($kid = $kid->sibling) and $kid->name eq 'stub'
909              and !null($kid = $kid->sibling) and $kid->name eq 'null'
910              and class($kid) eq 'COP' and null $kid->sibling )
911             {
912                 # ignore
913             } else {
914                 $self->pessimise($root, main_start);
915                 print $self->indent($self->deparse_root($root)), "\n";
916             }
917         }
918         my @text;
919         while (scalar(@{$self->{'subs_todo'}})) {
920             push @text, $self->next_todo;
921         }
922         print $self->indent(join("", @text)), "\n" if @text;
923
924         # Print __DATA__ section, if necessary
925         no strict 'refs';
926         my $laststash = defined $self->{'curcop'}
927             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
928         if (defined *{$laststash."::DATA"}{IO}) {
929             print $self->keyword("package") . " $laststash;\n"
930                 unless $laststash eq $self->{'curstash'};
931             print $self->keyword("__DATA__") . "\n";
932             print readline(*{$laststash."::DATA"});
933         }
934     }
935 }
936
937 sub coderef2text {
938     my $self = shift;
939     my $sub = shift;
940     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
941
942     $self->init();
943     local $self->{in_coderef2text} = 1;
944     return $self->indent($self->deparse_sub(svref_2object($sub)));
945 }
946
947 my %strict_bits = do {
948     local $^H;
949     map +($_ => strict::bits($_)), qw/refs subs vars/
950 };
951
952 sub ambient_pragmas {
953     my $self = shift;
954     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
955
956     while (@_ > 1) {
957         my $name = shift();
958         my $val  = shift();
959
960         if ($name eq 'strict') {
961             require strict;
962
963             if ($val eq 'none') {
964                 $hint_bits &= $strict_bits{$_} for qw/refs subs vars/;
965                 next();
966             }
967
968             my @names;
969             if ($val eq "all") {
970                 @names = qw/refs subs vars/;
971             }
972             elsif (ref $val) {
973                 @names = @$val;
974             }
975             else {
976                 @names = split' ', $val;
977             }
978             $hint_bits |= $strict_bits{$_} for @names;
979         }
980
981         elsif ($name eq '$[') {
982             if (OPpCONST_ARYBASE) {
983                 $arybase = $val;
984             } else {
985                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
986             }
987         }
988
989         elsif ($name eq 'integer'
990             || $name eq 'bytes'
991             || $name eq 'utf8') {
992             require "$name.pm";
993             if ($val) {
994                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
995             }
996             else {
997                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
998             }
999         }
1000
1001         elsif ($name eq 're') {
1002             require re;
1003             if ($val eq 'none') {
1004                 $hint_bits &= ~re::bits(qw/taint eval/);
1005                 next();
1006             }
1007
1008             my @names;
1009             if ($val eq 'all') {
1010                 @names = qw/taint eval/;
1011             }
1012             elsif (ref $val) {
1013                 @names = @$val;
1014             }
1015             else {
1016                 @names = split' ',$val;
1017             }
1018             $hint_bits |= re::bits(@names);
1019         }
1020
1021         elsif ($name eq 'warnings') {
1022             if ($val eq 'none') {
1023                 $warning_bits = $warnings::NONE;
1024                 next();
1025             }
1026
1027             my @names;
1028             if (ref $val) {
1029                 @names = @$val;
1030             }
1031             else {
1032                 @names = split/\s+/, $val;
1033             }
1034
1035             $warning_bits = $warnings::NONE if !defined ($warning_bits);
1036             $warning_bits |= warnings::bits(@names);
1037         }
1038
1039         elsif ($name eq 'warning_bits') {
1040             $warning_bits = $val;
1041         }
1042
1043         elsif ($name eq 'hint_bits') {
1044             $hint_bits = $val;
1045         }
1046
1047         elsif ($name eq '%^H') {
1048             $hinthash = $val;
1049         }
1050
1051         else {
1052             croak "Unknown pragma type: $name";
1053         }
1054     }
1055     if (@_) {
1056         croak "The ambient_pragmas method expects an even number of args";
1057     }
1058
1059     $self->{'ambient_arybase'} = $arybase;
1060     $self->{'ambient_warnings'} = $warning_bits;
1061     $self->{'ambient_hints'} = $hint_bits;
1062     $self->{'ambient_hinthash'} = $hinthash;
1063 }
1064
1065 # This method is the inner loop, so try to keep it simple
1066 sub deparse {
1067     my $self = shift;
1068     my($op, $cx) = @_;
1069
1070     Carp::confess("Null op in deparse") if !defined($op)
1071                                         || class($op) eq "NULL";
1072     my $meth = "pp_" . $op->name;
1073     return $self->$meth($op, $cx);
1074 }
1075
1076 sub indent {
1077     my $self = shift;
1078     my $txt = shift;
1079     # \cK also swallows a preceding line break when followed by a
1080     # semicolon.
1081     $txt =~ s/\n\cK;//g;
1082     my @lines = split(/\n/, $txt);
1083     my $leader = "";
1084     my $level = 0;
1085     my $line;
1086     for $line (@lines) {
1087         my $cmd = substr($line, 0, 1);
1088         if ($cmd eq "\t" or $cmd eq "\b") {
1089             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
1090             if ($self->{'use_tabs'}) {
1091                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
1092             } else {
1093                 $leader = " " x $level;
1094             }
1095             $line = substr($line, 1);
1096         }
1097         if (index($line, "\f") > 0) {
1098                 $line =~ s/\f/\n/;
1099         }
1100         if (substr($line, 0, 1) eq "\f") {
1101             $line = substr($line, 1); # no indent
1102         } else {
1103             $line = $leader . $line;
1104         }
1105         $line =~ s/\cK;?//g;
1106     }
1107     return join("\n", @lines);
1108 }
1109
1110 sub pad_subs {
1111     my ($self, $cv) = @_;
1112     my $padlist = $cv->PADLIST;
1113     my @names = $padlist->ARRAYelt(0)->ARRAY;
1114     my @values = $padlist->ARRAYelt(1)->ARRAY;
1115     my @todo;
1116   PADENTRY:
1117     for my $ix (0.. $#names) { for $_ ($names[$ix]) {
1118         next if class($_) eq "SPECIAL";
1119         my $name = $_->PVX;
1120         if (defined $name && $name =~ /^&./) {
1121             my $low = $_->COP_SEQ_RANGE_LOW;
1122             my $flags = $_->FLAGS;
1123             my $outer = $flags & PADNAMEt_OUTER;
1124             if ($flags & SVpad_OUR) {
1125                 push @todo, [$low, undef, 0, $_]
1126                           # [seq, no cv, not format, padname]
1127                     unless $outer;
1128                 next;
1129             }
1130             my $protocv = $flags & SVpad_STATE
1131                 ? $values[$ix]
1132                 : $_->PROTOCV;
1133             if (class ($protocv) ne 'CV') {
1134                 my $flags = $flags;
1135                 my $cv = $cv;
1136                 my $name = $_;
1137                 while ($flags & PADNAMEt_OUTER && class ($protocv) ne 'CV')
1138                 {
1139                     $cv = $cv->OUTSIDE;
1140                     next PADENTRY if class($cv) eq 'SPECIAL'; # XXX freed?
1141                     my $padlist = $cv->PADLIST;
1142                     my $ix = $name->PARENT_PAD_INDEX;
1143                     $name = $padlist->NAMES->ARRAYelt($ix);
1144                     $flags = $name->FLAGS;
1145                     $protocv = $flags & SVpad_STATE
1146                         ? $padlist->ARRAYelt(1)->ARRAYelt($ix)
1147                         : $name->PROTOCV;
1148                 }
1149             }
1150             my $defined_in_this_sub = ${$protocv->OUTSIDE} == $$cv || do {
1151                 my $other = $protocv->PADLIST;
1152                 $$other && $other->outid == $padlist->id;
1153             };
1154             if ($flags & PADNAMEt_OUTER) {
1155                 next unless $defined_in_this_sub;
1156                 push @todo, [$protocv->OUTSIDE_SEQ, $protocv, 0, $_];
1157                 next;
1158             }
1159             my $outseq = $protocv->OUTSIDE_SEQ;
1160             if ($outseq <= $low) {
1161                 # defined before its name is visible, so it’s gotta be
1162                 # declared and defined at once: my sub foo { ... }
1163                 push @todo, [$low, $protocv, 0, $_];
1164             }
1165             else {
1166                 # declared and defined separately: my sub f; sub f { ... }
1167                 push @todo, [$low, undef, 0, $_];
1168                 push @todo, [$outseq, $protocv, 0, $_]
1169                     if $defined_in_this_sub;
1170             }
1171         }
1172     }}
1173     @{$self->{'subs_todo'}} =
1174         sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}}, @todo
1175 }
1176
1177
1178 # deparse_argops(): deparse, if possible, a sequence of argcheck + argelem
1179 # ops into a subroutine signature. If successful, return the first op
1180 # following the signature ops plus the signature string; else return the
1181 # empty list.
1182 #
1183 # Normally a bunch of argelem ops will have been generated by the
1184 # signature parsing, but it's possible that ops have been added manually
1185 # or altered. In this case we "return ()" and fall back to general
1186 # deparsing of the individual sigelems as 'my $x = $_[N]' etc.
1187 #
1188 # We're only called if the first two ops are nextstate and argcheck.
1189
1190 sub deparse_argops {
1191     my ($self, $firstop, $cv) = @_;
1192
1193     my @sig;
1194     my $o = $firstop;
1195     return if $o->label; #first nextstate;
1196
1197     # OP_ARGCHECK
1198
1199     $o = $o->sibling;
1200     my ($params, $opt_params, $slurpy) = $o->aux_list($cv);
1201     my $mandatory = $params - $opt_params;
1202     my $seen_slurpy = 0;
1203     my $last_ix = -1;
1204
1205     # keep looking for valid nextstate + argelem pairs
1206
1207     while (1) {
1208         # OP_NEXTSTATE
1209         $o = $o->sibling;
1210         last unless $$o;
1211         last unless $o->name =~ /^(next|db)state$/;
1212         last if $o->label;
1213
1214         # OP_ARGELEM
1215         my $o2 = $o->sibling;
1216         last unless $$o2;
1217
1218         if ($o2->name eq 'argelem') {
1219             my $ix  = $o2->string($cv);
1220             while (++$last_ix < $ix) {
1221                 push @sig, $last_ix <  $mandatory ? '$' : '$=';
1222             }
1223             my $var = $self->padname($o2->targ);
1224             if ($var =~ /^[@%]/) {
1225                 return if $seen_slurpy;
1226                 $seen_slurpy = 1;
1227                 return if $ix != $params or !$slurpy
1228                             or substr($var,0,1) ne $slurpy;
1229             }
1230             else {
1231                 return if $ix >= $params;
1232             }
1233             if ($o2->flags & OPf_KIDS) {
1234                 my $kid = $o2->first;
1235                 return unless $$kid and $kid->name eq 'argdefelem';
1236                 my $def = $self->deparse($kid->first, 7);
1237                 $def = "($def)" if $kid->first->flags & OPf_PARENS;
1238                 $var .= " = $def";
1239             }
1240             push @sig, $var;
1241         }
1242         elsif ($o2->name eq 'null'
1243                and ($o2->flags & OPf_KIDS)
1244                and $o2->first->name eq 'argdefelem')
1245         {
1246             # special case - a void context default expression: $ = expr
1247
1248             my $defop = $o2->first;
1249             my $ix = $defop->targ;
1250             while (++$last_ix < $ix) {
1251                 push @sig, $last_ix <  $mandatory ? '$' : '$=';
1252             }
1253             return if $last_ix >= $params
1254                     or $last_ix < $mandatory;
1255             my $def = $self->deparse($defop->first, 7);
1256             $def = "($def)" if $defop->first->flags & OPf_PARENS;
1257             push @sig, '$ = ' . $def;
1258         }
1259         else {
1260             last;
1261         }
1262
1263         $o = $o2;
1264     }
1265
1266     while (++$last_ix < $params) {
1267         push @sig, $last_ix <  $mandatory ? '$' : '$=';
1268     }
1269     push @sig, $slurpy if $slurpy and !$seen_slurpy;
1270
1271     return ($o, join(', ', @sig));
1272 }
1273
1274 # Deparse a sub. Returns everything except the 'sub foo',
1275 # e.g.  ($$) : method { ...; }
1276 # or    ($a, $b) : prototype($$) lvalue;
1277
1278 sub deparse_sub {
1279     my $self = shift;
1280     my $cv = shift;
1281     my @attrs;
1282     my $protosig; # prototype or signature (what goes in the (....))
1283
1284 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
1285 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
1286     local $self->{'curcop'} = $self->{'curcop'};
1287
1288     my $has_sig = $self->{hinthash}{feature_signatures};
1289     if ($cv->FLAGS & SVf_POK) {
1290         my $proto = $cv->PV;
1291         if ($has_sig) {
1292             push @attrs, "prototype($proto)";
1293         }
1294         else {
1295             $protosig = $proto;
1296         }
1297     }
1298     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE|CVf_ANONCONST)) {
1299         push @attrs, "lvalue" if $cv->CvFLAGS & CVf_LVALUE;
1300         push @attrs, "method" if $cv->CvFLAGS & CVf_METHOD;
1301         push @attrs, "const"  if $cv->CvFLAGS & CVf_ANONCONST;
1302     }
1303
1304     local($self->{'curcv'}) = $cv;
1305     local($self->{'curcvlex'});
1306     local(@$self{qw'curstash warnings hints hinthash'})
1307                 = @$self{qw'curstash warnings hints hinthash'};
1308     my $body;
1309     my $root = $cv->ROOT;
1310     local $B::overlay = {};
1311     if (not null $root) {
1312         $self->pad_subs($cv);
1313         $self->pessimise($root, $cv->START);
1314         my $lineseq = $root->first;
1315         if ($lineseq->name eq "lineseq") {
1316             my $firstop = $lineseq->first;
1317
1318             if ($has_sig) {
1319                 my $o2;
1320                 # try to deparse first few ops as a signature if possible
1321                 if (     $$firstop
1322                      and $firstop->name =~  /^(next|db)state$/
1323                      and (($o2 = $firstop->sibling))
1324                      and $$o2)
1325                 {
1326                     if ($o2->name eq 'argcheck') {
1327                         my ($nexto, $sig) = $self->deparse_argops($firstop, $cv);
1328                         if (defined $nexto) {
1329                             $firstop = $nexto;
1330                             $protosig = $sig;
1331                         }
1332                     }
1333                 }
1334             }
1335
1336             my @ops;
1337             for (my $o = $firstop; $$o; $o=$o->sibling) {
1338                 push @ops, $o;
1339             }
1340             $body = $self->lineseq(undef, 0, @ops).";";
1341             if (!$has_sig and $ops[-1]->name =~ /^(next|db)state$/) {
1342                 # this handles void context in
1343                 #   use feature signatures; sub ($=1) {}
1344                 $body .= "\n()";
1345             }
1346             my $scope_en = $self->find_scope_en($lineseq);
1347             if (defined $scope_en) {
1348                 my $subs = join"", $self->seq_subs($scope_en);
1349                 $body .= ";\n$subs" if length($subs);
1350             }
1351         }
1352         else {
1353             $body = $self->deparse($root->first, 0);
1354         }
1355         $body = "{\n\t$body\n\b}";
1356     }
1357     else {
1358         my $sv = $cv->const_sv;
1359         if ($$sv) {
1360             # uh-oh. inlinable sub... format it differently
1361             $body = "{ " . $self->const($sv, 0) . " }\n";
1362         } else { # XSUB? (or just a declaration)
1363             $body = ';'
1364         }
1365     }
1366     $protosig = defined $protosig ? "($protosig) " : "";
1367     my $attrs = '';
1368     $attrs = ': ' . join('', map "$_ ", @attrs) if @attrs;
1369     return "$protosig$attrs$body\n";
1370 }
1371
1372 sub deparse_format {
1373     my $self = shift;
1374     my $form = shift;
1375     my @text;
1376     local($self->{'curcv'}) = $form;
1377     local($self->{'curcvlex'});
1378     local($self->{'in_format'}) = 1;
1379     local(@$self{qw'curstash warnings hints hinthash'})
1380                 = @$self{qw'curstash warnings hints hinthash'};
1381     my $op = $form->ROOT;
1382     local $B::overlay = {};
1383     $self->pessimise($op, $form->START);
1384     my $kid;
1385     return "\f." if $op->first->name eq 'stub'
1386                 || $op->first->name eq 'nextstate';
1387     $op = $op->first->first; # skip leavewrite, lineseq
1388     while (not null $op) {
1389         $op = $op->sibling; # skip nextstate
1390         my @exprs;
1391         $kid = $op->first->sibling; # skip pushmark
1392         push @text, "\f".$self->const_sv($kid)->PV;
1393         $kid = $kid->sibling;
1394         for (; not null $kid; $kid = $kid->sibling) {
1395             push @exprs, $self->deparse($kid, -1);
1396             $exprs[-1] =~ s/;\z//;
1397         }
1398         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
1399         $op = $op->sibling;
1400     }
1401     return join("", @text) . "\f.";
1402 }
1403
1404 sub is_scope {
1405     my $op = shift;
1406     return $op->name eq "leave" || $op->name eq "scope"
1407       || $op->name eq "lineseq"
1408         || ($op->name eq "null" && class($op) eq "UNOP"
1409             && (is_scope($op->first) || $op->first->name eq "enter"));
1410 }
1411
1412 sub is_state {
1413     my $name = $_[0]->name;
1414     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
1415 }
1416
1417 sub is_miniwhile { # check for one-line loop ('foo() while $y--')
1418     my $op = shift;
1419     return (!null($op) and null($op->sibling)
1420             and $op->name eq "null" and class($op) eq "UNOP"
1421             and (($op->first->name =~ /^(and|or)$/
1422                   and $op->first->first->sibling->name eq "lineseq")
1423                  or ($op->first->name eq "lineseq"
1424                      and not null $op->first->first->sibling
1425                      and $op->first->first->sibling->name eq "unstack")
1426                  ));
1427 }
1428
1429 # Check if the op and its sibling are the initialization and the rest of a
1430 # for (..;..;..) { ... } loop
1431 sub is_for_loop {
1432     my $op = shift;
1433     # This OP might be almost anything, though it won't be a
1434     # nextstate. (It's the initialization, so in the canonical case it
1435     # will be an sassign.) The sibling is (old style) a lineseq whose
1436     # first child is a nextstate and whose second is a leaveloop, or
1437     # (new style) an unstack whose sibling is a leaveloop.
1438     my $lseq = $op->sibling;
1439     return 0 unless !is_state($op) and !null($lseq);
1440     if ($lseq->name eq "lineseq") {
1441         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
1442             && (my $sib = $lseq->first->sibling)) {
1443             return (!null($sib) && $sib->name eq "leaveloop");
1444         }
1445     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
1446         my $sib = $lseq->sibling;
1447         return $sib && !null($sib) && $sib->name eq "leaveloop";
1448     }
1449     return 0;
1450 }
1451
1452 sub is_scalar {
1453     my $op = shift;
1454     return ($op->name eq "rv2sv" or
1455             $op->name eq "padsv" or
1456             $op->name eq "gv" or # only in array/hash constructs
1457             $op->flags & OPf_KIDS && !null($op->first)
1458               && $op->first->name eq "gvsv");
1459 }
1460
1461 sub maybe_parens {
1462     my $self = shift;
1463     my($text, $cx, $prec) = @_;
1464     if ($prec < $cx              # unary ops nest just fine
1465         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1466         or $self->{'parens'})
1467     {
1468         $text = "($text)";
1469         # In a unop, let parent reuse our parens; see maybe_parens_unop
1470         $text = "\cS" . $text if $cx == 16;
1471         return $text;
1472     } else {
1473         return $text;
1474     }
1475 }
1476
1477 # same as above, but get around the 'if it looks like a function' rule
1478 sub maybe_parens_unop {
1479     my $self = shift;
1480     my($name, $kid, $cx) = @_;
1481     if ($cx > 16 or $self->{'parens'}) {
1482         $kid =  $self->deparse($kid, 1);
1483         if ($name eq "umask" && $kid =~ /^\d+$/) {
1484             $kid = sprintf("%#o", $kid);
1485         }
1486         return $self->keyword($name) . "($kid)";
1487     } else {
1488         $kid = $self->deparse($kid, 16);
1489         if ($name eq "umask" && $kid =~ /^\d+$/) {
1490             $kid = sprintf("%#o", $kid);
1491         }
1492         $name = $self->keyword($name);
1493         if (substr($kid, 0, 1) eq "\cS") {
1494             # use kid's parens
1495             return $name . substr($kid, 1);
1496         } elsif (substr($kid, 0, 1) eq "(") {
1497             # avoid looks-like-a-function trap with extra parens
1498             # ('+' can lead to ambiguities)
1499             return "$name(" . $kid  . ")";
1500         } else {
1501             return "$name $kid";
1502         }
1503     }
1504 }
1505
1506 sub maybe_parens_func {
1507     my $self = shift;
1508     my($func, $text, $cx, $prec) = @_;
1509     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1510         return "$func($text)";
1511     } else {
1512         return "$func $text";
1513     }
1514 }
1515
1516 sub find_our_type {
1517     my ($self, $name) = @_;
1518     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1519     my $seq = $self->{'curcop'} ? $self->{'curcop'}->cop_seq : 0;
1520     for my $a (@{$self->{'curcvlex'}{"o$name"}}) {
1521         my ($st, undef, $padname) = @$a;
1522         if ($st >= $seq && $padname->FLAGS & SVpad_TYPED) {
1523             return $padname->SvSTASH->NAME;
1524         }
1525     }
1526     return '';
1527 }
1528
1529 sub maybe_local {
1530     my $self = shift;
1531     my($op, $cx, $text) = @_;
1532     my $name = $op->name;
1533     my $our_intro = ($name =~ /^(?:(?:gv|rv2)[ash]v|split|refassign
1534                                   |lv(?:av)?ref)$/x)
1535                         ? OPpOUR_INTRO
1536                         : 0;
1537     my $lval_intro = $name eq 'split' ? 0 : OPpLVAL_INTRO;
1538     # The @a in \(@a) isn't in ref context, but only when the
1539     # parens are there.
1540     my $need_parens = $self->{'in_refgen'} && $name =~ /[ah]v\z/
1541                    && ($op->flags & (OPf_PARENS|OPf_REF)) == OPf_PARENS;
1542     if ((my $priv = $op->private) & ($lval_intro|$our_intro)) {
1543         my @our_local;
1544         push @our_local, "local" if $priv & $lval_intro;
1545         push @our_local, "our"   if $priv & $our_intro;
1546         my $our_local = join " ", map $self->keyword($_), @our_local;
1547         if( $our_local[-1] eq 'our' ) {
1548             if ( $text !~ /^\W(\w+::)*\w+\z/
1549              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1550             ) {
1551                 die "Unexpected our($text)\n";
1552             }
1553             $text =~ s/(\w+::)+//;
1554
1555             if (my $type = $self->find_our_type($text)) {
1556                 $our_local .= ' ' . $type;
1557             }
1558         }
1559         return $need_parens ? "($text)" : $text
1560             if $self->{'avoid_local'}{$$op};
1561         if ($need_parens) {
1562             return "$our_local($text)";
1563         } elsif (want_scalar($op)) {
1564             return "$our_local $text";
1565         } else {
1566             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1567         }
1568     } else {
1569         return $need_parens ? "($text)" : $text;
1570     }
1571 }
1572
1573 sub maybe_targmy {
1574     my $self = shift;
1575     my($op, $cx, $func, @args) = @_;
1576     if ($op->private & OPpTARGET_MY) {
1577         my $var = $self->padname($op->targ);
1578         my $val = $func->($self, $op, 7, @args);
1579         return $self->maybe_parens("$var = $val", $cx, 7);
1580     } else {
1581         return $func->($self, $op, $cx, @args);
1582     }
1583 }
1584
1585 sub padname_sv {
1586     my $self = shift;
1587     my $targ = shift;
1588     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1589 }
1590
1591 sub maybe_my {
1592     my $self = shift;
1593     my($op, $cx, $text, $padname, $forbid_parens) = @_;
1594     # The @a in \(@a) isn't in ref context, but only when the
1595     # parens are there.
1596     my $need_parens = !$forbid_parens && $self->{'in_refgen'}
1597                    && $op->name =~ /[ah]v\z/
1598                    && ($op->flags & (OPf_PARENS|OPf_REF)) == OPf_PARENS;
1599     # The @a in \my @a must not have parens.
1600     if (!$need_parens && $self->{'in_refgen'}) {
1601         $forbid_parens = 1;
1602     }
1603     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1604         # Check $padname->FLAGS for statehood, rather than $op->private,
1605         # because enteriter ops do not carry the flag.
1606         my $my =
1607             $self->keyword($padname->FLAGS & SVpad_STATE ? "state" : "my");
1608         if ($padname->FLAGS & SVpad_TYPED) {
1609             $my .= ' ' . $padname->SvSTASH->NAME;
1610         }
1611         if ($need_parens) {
1612             return "$my($text)";
1613         } elsif ($forbid_parens || want_scalar($op)) {
1614             return "$my $text";
1615         } else {
1616             return $self->maybe_parens_func($my, $text, $cx, 16);
1617         }
1618     } else {
1619         return $need_parens ? "($text)" : $text;
1620     }
1621 }
1622
1623 # The following OPs don't have functions:
1624
1625 # pp_padany -- does not exist after parsing
1626
1627 sub AUTOLOAD {
1628     if ($AUTOLOAD =~ s/^.*::pp_//) {
1629         warn "unexpected OP_".
1630           ($_[1]->type == OP_CUSTOM ? "CUSTOM ($AUTOLOAD)" : uc $AUTOLOAD);
1631         return "XXX";
1632     } else {
1633         die "Undefined subroutine $AUTOLOAD called";
1634     }
1635 }
1636
1637 sub DESTROY {}  #       Do not AUTOLOAD
1638
1639 # $root should be the op which represents the root of whatever
1640 # we're sequencing here. If it's undefined, then we don't append
1641 # any subroutine declarations to the deparsed ops, otherwise we
1642 # append appropriate declarations.
1643 sub lineseq {
1644     my($self, $root, $cx, @ops) = @_;
1645     my($expr, @exprs);
1646
1647     my $out_cop = $self->{'curcop'};
1648     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1649     my $limit_seq;
1650     if (defined $root) {
1651         $limit_seq = $out_seq;
1652         my $nseq;
1653         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1654         $limit_seq = $nseq if !defined($limit_seq)
1655                            or defined($nseq) && $nseq < $limit_seq;
1656     }
1657     $limit_seq = $self->{'limit_seq'}
1658         if defined($self->{'limit_seq'})
1659         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1660     local $self->{'limit_seq'} = $limit_seq;
1661
1662     $self->walk_lineseq($root, \@ops,
1663                        sub { push @exprs, $_[0]} );
1664
1665     my $sep = $cx ? '; ' : ";\n";
1666     my $body = join($sep, grep {length} @exprs);
1667     my $subs = "";
1668     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1669         $subs = join "\n", $self->seq_subs($limit_seq);
1670     }
1671     return join($sep, grep {length} $body, $subs);
1672 }
1673
1674 sub scopeop {
1675     my($real_block, $self, $op, $cx) = @_;
1676     my $kid;
1677     my @kids;
1678
1679     local(@$self{qw'curstash warnings hints hinthash'})
1680                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1681     if ($real_block) {
1682         $kid = $op->first->sibling; # skip enter
1683         if (is_miniwhile($kid)) {
1684             my $top = $kid->first;
1685             my $name = $top->name;
1686             if ($name eq "and") {
1687                 $name = $self->keyword("while");
1688             } elsif ($name eq "or") {
1689                 $name = $self->keyword("until");
1690             } else { # no conditional -> while 1 or until 0
1691                 return $self->deparse($top->first, 1) . " "
1692                      . $self->keyword("while") . " 1";
1693             }
1694             my $cond = $top->first;
1695             my $body = $cond->sibling->first; # skip lineseq
1696             $cond = $self->deparse($cond, 1);
1697             $body = $self->deparse($body, 1);
1698             return "$body $name $cond";
1699         }
1700     } else {
1701         $kid = $op->first;
1702     }
1703     for (; !null($kid); $kid = $kid->sibling) {
1704         push @kids, $kid;
1705     }
1706     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1707         my $body = $self->lineseq($op, 0, @kids);
1708         return is_lexical_subs(@kids)
1709                 ? $body
1710                 : ($self->lex_in_scope("&do") ? "CORE::do" : "do")
1711                  . " {\n\t$body\n\b}";
1712     } else {
1713         my $lineseq = $self->lineseq($op, $cx, @kids);
1714         return (length ($lineseq) ? "$lineseq;" : "");
1715     }
1716 }
1717
1718 sub pp_scope { scopeop(0, @_); }
1719 sub pp_lineseq { scopeop(0, @_); }
1720 sub pp_leave { scopeop(1, @_); }
1721
1722 # This is a special case of scopeop and lineseq, for the case of the
1723 # main_root. The difference is that we print the output statements as
1724 # soon as we get them, for the sake of impatient users.
1725 sub deparse_root {
1726     my $self = shift;
1727     my($op) = @_;
1728     local(@$self{qw'curstash warnings hints hinthash'})
1729       = @$self{qw'curstash warnings hints hinthash'};
1730     my @kids;
1731     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1732     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1733         push @kids, $kid;
1734     }
1735     $self->walk_lineseq($op, \@kids,
1736                         sub { return unless length $_[0];
1737                               print $self->indent($_[0].';');
1738                               print "\n"
1739                                 unless $_[1] == $#kids;
1740                           });
1741 }
1742
1743 sub walk_lineseq {
1744     my ($self, $op, $kids, $callback) = @_;
1745     my @kids = @$kids;
1746     for (my $i = 0; $i < @kids; $i++) {
1747         my $expr = "";
1748         if (is_state $kids[$i]) {
1749             $expr = $self->deparse($kids[$i++], 0);
1750             if ($i > $#kids) {
1751                 $callback->($expr, $i);
1752                 last;
1753             }
1754         }
1755         if (is_for_loop($kids[$i])) {
1756             $callback->($expr . $self->for_loop($kids[$i], 0),
1757                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1758             next;
1759         }
1760         my $expr2 = $self->deparse($kids[$i], (@kids != 1)/2);
1761         $expr2 =~ s/^sub :(?!:)/+sub :/; # statement label otherwise
1762         $expr .= $expr2;
1763         $callback->($expr, $i);
1764     }
1765 }
1766
1767 # The BEGIN {} is used here because otherwise this code isn't executed
1768 # when you run B::Deparse on itself.
1769 my %globalnames;
1770 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1771             "ENV", "ARGV", "ARGVOUT", "_"); }
1772
1773 sub gv_name {
1774     my $self = shift;
1775     my $gv = shift;
1776     my $raw = shift;
1777 #Carp::confess() unless ref($gv) eq "B::GV";
1778     my $cv = $gv->FLAGS & SVf_ROK ? $gv->RV : 0;
1779     my $stash = ($cv || $gv)->STASH->NAME;
1780     my $name = $raw
1781         ? $cv ? $cv->NAME_HEK || $cv->GV->NAME : $gv->NAME
1782         : $cv
1783             ? B::safename($cv->NAME_HEK || $cv->GV->NAME)
1784             : $gv->SAFENAME;
1785     if ($stash eq 'main' && $name =~ /^::/) {
1786         $stash = '::';
1787     }
1788     elsif (($stash eq 'main'
1789             && ($globalnames{$name} || $name =~ /^[^A-Za-z_:]/))
1790         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1791             && ($stash eq 'main' || $name !~ /::/))
1792           )
1793     {
1794         $stash = "";
1795     } else {
1796         $stash = $stash . "::";
1797     }
1798     if (!$raw and $name =~ /^(\^..|{)/) {
1799         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1800     }
1801     return $stash . $name;
1802 }
1803
1804 # Return the name to use for a stash variable.
1805 # If a lexical with the same name is in scope, or
1806 # if strictures are enabled, it may need to be
1807 # fully-qualified.
1808 sub stash_variable {
1809     my ($self, $prefix, $name, $cx) = @_;
1810
1811     return $prefix.$self->maybe_qualify($prefix, $name) if $name =~ /::/;
1812
1813     unless ($prefix eq '$' || $prefix eq '@' || $prefix eq '&' || #'
1814             $prefix eq '%' || $prefix eq '$#') {
1815         return "$prefix$name";
1816     }
1817
1818     if ($name =~ /^[^[:alpha:]_+-]$/) {
1819       if (defined $cx && $cx == 26) {
1820         if ($prefix eq '@') {
1821             return "$prefix\{$name}";
1822         }
1823         elsif ($name eq '#') { return '${#}' } #  "${#}a" vs "$#a"
1824       }
1825       if ($prefix eq '$#') {
1826         return "\$#{$name}";
1827       }
1828     }
1829
1830     return $prefix . $self->maybe_qualify($prefix, $name);
1831 }
1832
1833 my %unctrl = # portable to EBCDIC
1834     (
1835      "\c@" => '@',      # unused
1836      "\cA" => 'A',
1837      "\cB" => 'B',
1838      "\cC" => 'C',
1839      "\cD" => 'D',
1840      "\cE" => 'E',
1841      "\cF" => 'F',
1842      "\cG" => 'G',
1843      "\cH" => 'H',
1844      "\cI" => 'I',
1845      "\cJ" => 'J',
1846      "\cK" => 'K',
1847      "\cL" => 'L',
1848      "\cM" => 'M',
1849      "\cN" => 'N',
1850      "\cO" => 'O',
1851      "\cP" => 'P',
1852      "\cQ" => 'Q',
1853      "\cR" => 'R',
1854      "\cS" => 'S',
1855      "\cT" => 'T',
1856      "\cU" => 'U',
1857      "\cV" => 'V',
1858      "\cW" => 'W',
1859      "\cX" => 'X',
1860      "\cY" => 'Y',
1861      "\cZ" => 'Z',
1862      "\c[" => '[',      # unused
1863      "\c\\" => '\\',    # unused
1864      "\c]" => ']',      # unused
1865      "\c_" => '_',      # unused
1866     );
1867
1868 # Return just the name, without the prefix.  It may be returned as a quoted
1869 # string.  The second return value is a boolean indicating that.
1870 sub stash_variable_name {
1871     my($self, $prefix, $gv) = @_;
1872     my $name = $self->gv_name($gv, 1);
1873     $name = $self->maybe_qualify($prefix,$name);
1874     if ($name =~ /^(?:\S|(?!\d)[\ca-\cz]?(?:\w|::)*|\d+)\z/) {
1875         $name =~ s/^([\ca-\cz])/'^' . $unctrl{$1}/e;
1876         $name =~ /^(\^..|{)/ and $name = "{$name}";
1877         return $name, 0; # not quoted
1878     }
1879     else {
1880         single_delim("q", "'", $name, $self), 1;
1881     }
1882 }
1883
1884 sub maybe_qualify {
1885     my ($self,$prefix,$name) = @_;
1886     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1887     if ($prefix eq "") {
1888         $name .= "::" if $name =~ /(?:\ACORE::[^:]*|::)\z/;
1889         return $name;
1890     }
1891     return $name if $name =~ /::/;
1892     return $self->{'curstash'}.'::'. $name
1893         if
1894             $name =~ /^(?!\d)\w/         # alphabetic
1895          && $v    !~ /^\$[ab]\z/         # not $a or $b
1896          && $v =~ /\A[\$\@\%\&]/         # scalar, array, hash, or sub
1897          && !$globalnames{$name}         # not a global name
1898          && $self->{hints} & $strict_bits{vars}  # strict vars
1899          && !$self->lex_in_scope($v,1)   # no "our"
1900       or $self->lex_in_scope($v);        # conflicts with "my" variable
1901     return $name;
1902 }
1903
1904 sub lex_in_scope {
1905     my ($self, $name, $our) = @_;
1906     substr $name, 0, 0, = $our ? 'o' : 'm'; # our/my
1907     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1908
1909     return 0 if !defined($self->{'curcop'});
1910     my $seq = $self->{'curcop'}->cop_seq;
1911     return 0 if !exists $self->{'curcvlex'}{$name};
1912     for my $a (@{$self->{'curcvlex'}{$name}}) {
1913         my ($st, $en) = @$a;
1914         return 1 if $seq > $st && $seq <= $en;
1915     }
1916     return 0;
1917 }
1918
1919 sub populate_curcvlex {
1920     my $self = shift;
1921     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1922         my $padlist = $cv->PADLIST;
1923         # an undef CV still in lexical chain
1924         next if class($padlist) eq "SPECIAL";
1925         my @padlist = $padlist->ARRAY;
1926         my @ns = $padlist[0]->ARRAY;
1927
1928         for (my $i=0; $i<@ns; ++$i) {
1929             next if class($ns[$i]) eq "SPECIAL";
1930             if (class($ns[$i]) eq "PV") {
1931                 # Probably that pesky lexical @_
1932                 next;
1933             }
1934             my $name = $ns[$i]->PVX;
1935             next unless defined $name;
1936             my ($seq_st, $seq_en) =
1937                 ($ns[$i]->FLAGS & SVf_FAKE)
1938                     ? (0, 999999)
1939                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1940
1941             push @{$self->{'curcvlex'}{
1942                         ($ns[$i]->FLAGS & SVpad_OUR ? 'o' : 'm') . $name
1943                   }}, [$seq_st, $seq_en, $ns[$i]];
1944         }
1945     }
1946 }
1947
1948 sub find_scope_st { ((find_scope(@_))[0]); }
1949 sub find_scope_en { ((find_scope(@_))[1]); }
1950
1951 # Recurses down the tree, looking for pad variable introductions and COPs
1952 sub find_scope {
1953     my ($self, $op, $scope_st, $scope_en) = @_;
1954     carp("Undefined op in find_scope") if !defined $op;
1955     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1956
1957     my @queue = ($op);
1958     while(my $op = shift @queue ) {
1959         for (my $o=$op->first; $$o; $o=$o->sibling) {
1960             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1961                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1962                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1963                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1964                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1965                 return ($scope_st, $scope_en);
1966             }
1967             elsif (is_state($o)) {
1968                 my $c = $o->cop_seq;
1969                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1970                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1971                 return ($scope_st, $scope_en);
1972             }
1973             elsif ($o->flags & OPf_KIDS) {
1974                 unshift (@queue, $o);
1975             }
1976         }
1977     }
1978
1979     return ($scope_st, $scope_en);
1980 }
1981
1982 # Returns a list of subs which should be inserted before the COP
1983 sub cop_subs {
1984     my ($self, $op, $out_seq) = @_;
1985     my $seq = $op->cop_seq;
1986     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1987     return $self->seq_subs($seq);
1988 }
1989
1990 sub seq_subs {
1991     my ($self, $seq) = @_;
1992     my @text;
1993 #push @text, "# ($seq)\n";
1994
1995     return "" if !defined $seq;
1996     my @pending;
1997     while (scalar(@{$self->{'subs_todo'}})
1998            and $seq > $self->{'subs_todo'}[0][0]) {
1999         my $cv = $self->{'subs_todo'}[0][1];
2000         # Skip the OUTSIDE check for lexical subs.  We may be deparsing a
2001         # cloned anon sub with lexical subs declared in it, in which case
2002         # the OUTSIDE pointer points to the anon protosub.
2003         my $lexical = ref $self->{'subs_todo'}[0][3];
2004         my $outside = !$lexical && $cv && $cv->OUTSIDE;
2005         if (!$lexical and $cv
2006          and ${$cv->OUTSIDE || \0} != ${$self->{'curcv'}})
2007         {
2008             push @pending, shift @{$self->{'subs_todo'}};
2009             next;
2010         }
2011         push @text, $self->next_todo;
2012     }
2013     unshift @{$self->{'subs_todo'}}, @pending;
2014     return @text;
2015 }
2016
2017 sub _features_from_bundle {
2018     my ($hints, $hh) = @_;
2019     foreach (@{$feature::feature_bundle{@feature::hint_bundles[$hints >> $feature::hint_shift]}}) {
2020         $hh->{$feature::feature{$_}} = 1;
2021     }
2022     return $hh;
2023 }
2024
2025 # generate any pragmas, 'package foo' etc needed to synchronise
2026 # with the given cop
2027
2028 sub pragmata {
2029     my $self = shift;
2030     my($op) = @_;
2031
2032     my @text;
2033
2034     my $stash = $op->stashpv;
2035     if ($stash ne $self->{'curstash'}) {
2036         push @text, $self->keyword("package") . " $stash;\n";
2037         $self->{'curstash'} = $stash;
2038     }
2039
2040     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
2041         push @text, '$[ = '. $op->arybase .";\n";
2042         $self->{'arybase'} = $op->arybase;
2043     }
2044
2045     my $warnings = $op->warnings;
2046     my $warning_bits;
2047     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
2048         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
2049     }
2050     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
2051         $warning_bits = $warnings::NONE;
2052     }
2053     elsif ($warnings->isa("B::SPECIAL")) {
2054         $warning_bits = undef;
2055     }
2056     else {
2057         $warning_bits = $warnings->PV & WARN_MASK;
2058     }
2059
2060     if (defined ($warning_bits) and
2061        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
2062         push @text,
2063             $self->declare_warnings($self->{'warnings'}, $warning_bits);
2064         $self->{'warnings'} = $warning_bits;
2065     }
2066
2067     my $hints = $op->hints;
2068     my $old_hints = $self->{'hints'};
2069     if ($self->{'hints'} != $hints) {
2070         push @text, $self->declare_hints($self->{'hints'}, $hints);
2071         $self->{'hints'} = $hints;
2072     }
2073
2074     my $newhh;
2075     $newhh = $op->hints_hash->HASH;
2076
2077     {
2078         # feature bundle hints
2079         my $from = $old_hints & $feature::hint_mask;
2080         my $to   = $    hints & $feature::hint_mask;
2081         if ($from != $to) {
2082             if ($to == $feature::hint_mask) {
2083                 if ($self->{'hinthash'}) {
2084                     delete $self->{'hinthash'}{$_}
2085                         for grep /^feature_/, keys %{$self->{'hinthash'}};
2086                 }
2087                 else { $self->{'hinthash'} = {} }
2088                 $self->{'hinthash'}
2089                     = _features_from_bundle($from, $self->{'hinthash'});
2090             }
2091             else {
2092                 my $bundle =
2093                     $feature::hint_bundles[$to >> $feature::hint_shift];
2094                 $bundle =~ s/(\d[13579])\z/$1+1/e; # 5.11 => 5.12
2095                 push @text,
2096                     $self->keyword("no") . " feature ':all';\n",
2097                     $self->keyword("use") . " feature ':$bundle';\n";
2098             }
2099         }
2100     }
2101
2102     {
2103         push @text, $self->declare_hinthash(
2104             $self->{'hinthash'}, $newhh,
2105             $self->{indent_size}, $self->{hints},
2106         );
2107         $self->{'hinthash'} = $newhh;
2108     }
2109
2110     return join("", @text);
2111 }
2112
2113
2114 # Notice how subs and formats are inserted between statements here;
2115 # also $[ assignments and pragmas.
2116 sub pp_nextstate {
2117     my $self = shift;
2118     my($op, $cx) = @_;
2119     $self->{'curcop'} = $op;
2120
2121     my @text;
2122
2123     my @subs = $self->cop_subs($op);
2124     if (@subs) {
2125         # Special marker to swallow up the semicolon
2126         push @subs, "\cK";
2127     }
2128     push @text, @subs;
2129
2130     push @text, $self->pragmata($op);
2131
2132
2133     # This should go after of any branches that add statements, to
2134     # increase the chances that it refers to the same line it did in
2135     # the original program.
2136     if ($self->{'linenums'} && $cx != .5) { # $cx == .5 means in a format
2137         push @text, "\f#line " . $op->line .
2138           ' "' . $op->file, qq'"\n';
2139     }
2140
2141     push @text, $op->label . ": " if $op->label;
2142
2143     return join("", @text);
2144 }
2145
2146 sub declare_warnings {
2147     my ($self, $from, $to) = @_;
2148     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
2149         return $self->keyword("use") . " warnings;\n";
2150     }
2151     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
2152         return $self->keyword("no") . " warnings;\n";
2153     }
2154     return "BEGIN {\${^WARNING_BITS} = \""
2155            . join("", map { sprintf("\\x%02x", ord $_) } split "", $to)
2156            . "\"}\n\cK";
2157 }
2158
2159 sub declare_hints {
2160     my ($self, $from, $to) = @_;
2161     my $use = $to   & ~$from;
2162     my $no  = $from & ~$to;
2163     my $decls = "";
2164     for my $pragma (hint_pragmas($use)) {
2165         $decls .= $self->keyword("use") . " $pragma;\n";
2166     }
2167     for my $pragma (hint_pragmas($no)) {
2168         $decls .= $self->keyword("no") . " $pragma;\n";
2169     }
2170     return $decls;
2171 }
2172
2173 # Internal implementation hints that the core sets automatically, so don't need
2174 # (or want) to be passed back to the user
2175 my %ignored_hints = (
2176     'open<' => 1,
2177     'open>' => 1,
2178     ':'     => 1,
2179     'strict/refs' => 1,
2180     'strict/subs' => 1,
2181     'strict/vars' => 1,
2182 );
2183
2184 my %rev_feature;
2185
2186 sub declare_hinthash {
2187     my ($self, $from, $to, $indent, $hints) = @_;
2188     my $doing_features =
2189         ($hints & $feature::hint_mask) == $feature::hint_mask;
2190     my @decls;
2191     my @features;
2192     my @unfeatures; # bugs?
2193     for my $key (sort keys %$to) {
2194         next if $ignored_hints{$key};
2195         my $is_feature = $key =~ /^feature_/;
2196         next if $is_feature and not $doing_features;
2197         if (!exists $from->{$key} or $from->{$key} ne $to->{$key}) {
2198             push(@features, $key), next if $is_feature;
2199             push @decls,
2200                 qq(\$^H{) . single_delim("q", "'", $key, $self) . qq(} = )
2201               . (
2202                    defined $to->{$key}
2203                         ? single_delim("q", "'", $to->{$key}, $self)
2204                         : 'undef'
2205                 )
2206               . qq(;);
2207         }
2208     }
2209     for my $key (sort keys %$from) {
2210         next if $ignored_hints{$key};
2211         my $is_feature = $key =~ /^feature_/;
2212         next if $is_feature and not $doing_features;
2213         if (!exists $to->{$key}) {
2214             push(@unfeatures, $key), next if $is_feature;
2215             push @decls, qq(delete \$^H{'$key'};);
2216         }
2217     }
2218     my @ret;
2219     if (@features || @unfeatures) {
2220         if (!%rev_feature) { %rev_feature = reverse %feature::feature }
2221     }
2222     if (@features) {
2223         push @ret, $self->keyword("use") . " feature "
2224                  . join(", ", map "'$rev_feature{$_}'", @features) . ";\n";
2225     }
2226     if (@unfeatures) {
2227         push @ret, $self->keyword("no") . " feature "
2228                  . join(", ", map "'$rev_feature{$_}'", @unfeatures)
2229                  . ";\n";
2230     }
2231     @decls and
2232         push @ret,
2233              join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n\cK";
2234     return @ret;
2235 }
2236
2237 sub hint_pragmas {
2238     my ($bits) = @_;
2239     my (@pragmas, @strict);
2240     push @pragmas, "integer" if $bits & 0x1;
2241     for (sort keys %strict_bits) {
2242         push @strict, "'$_'" if $bits & $strict_bits{$_};
2243     }
2244     if (@strict == keys %strict_bits) {
2245         push @pragmas, "strict";
2246     }
2247     elsif (@strict) {
2248         push @pragmas, "strict " . join ', ', @strict;
2249     }
2250     push @pragmas, "bytes" if $bits & 0x8;
2251     return @pragmas;
2252 }
2253
2254 sub pp_dbstate { pp_nextstate(@_) }
2255 sub pp_setstate { pp_nextstate(@_) }
2256
2257 sub pp_unstack { return "" } # see also leaveloop
2258
2259 my %feature_keywords = (
2260   # keyword => 'feature',
2261     state   => 'state',
2262     say     => 'say',
2263     given   => 'switch',
2264     when    => 'switch',
2265     default => 'switch',
2266     break   => 'switch',
2267     evalbytes=>'evalbytes',
2268     __SUB__ => '__SUB__',
2269    fc       => 'fc',
2270 );
2271
2272 # keywords that are strong and also have a prototype
2273 #
2274 my %strong_proto_keywords = map { $_ => 1 } qw(
2275     pos
2276     prototype
2277     scalar
2278     study
2279     undef
2280 );
2281
2282 sub feature_enabled {
2283         my($self,$name) = @_;
2284         my $hh;
2285         my $hints = $self->{hints} & $feature::hint_mask;
2286         if ($hints && $hints != $feature::hint_mask) {
2287             $hh = _features_from_bundle($hints);
2288         }
2289         elsif ($hints) { $hh = $self->{'hinthash'} }
2290         return $hh && $hh->{"feature_$feature_keywords{$name}"}
2291 }
2292
2293 sub keyword {
2294     my $self = shift;
2295     my $name = shift;
2296     return $name if $name =~ /^CORE::/; # just in case
2297     if (exists $feature_keywords{$name}) {
2298         return "CORE::$name" if not $self->feature_enabled($name);
2299     }
2300     # This sub may be called for a program that has no nextstate ops.  In
2301     # that case we may have a lexical sub named no/use/sub in scope but
2302     # but $self->lex_in_scope will return false because it depends on the
2303     # current nextstate op.  So we need this alternate method if there is
2304     # no current cop.
2305     if (!$self->{'curcop'}) {
2306         $self->populate_curcvlex() if !defined $self->{'curcvlex'};
2307         return "CORE::$name" if exists $self->{'curcvlex'}{"m&$name"}
2308                              || exists $self->{'curcvlex'}{"o&$name"};
2309     } elsif ($self->lex_in_scope("&$name")
2310           || $self->lex_in_scope("&$name", 1)) {
2311         return "CORE::$name";
2312     }
2313     if ($strong_proto_keywords{$name}
2314         || ($name !~ /^(?:chom?p|do|exec|glob|s(?:elect|ystem))\z/
2315             && !defined eval{prototype "CORE::$name"})
2316     ) { return $name }
2317     if (
2318         exists $self->{subs_declared}{$name}
2319          or
2320         exists &{"$self->{curstash}::$name"}
2321     ) {
2322         return "CORE::$name"
2323     }
2324     return $name;
2325 }
2326
2327 sub baseop {
2328     my $self = shift;
2329     my($op, $cx, $name) = @_;
2330     return $self->keyword($name);
2331 }
2332
2333 sub pp_stub { "()" }
2334 sub pp_wantarray { baseop(@_, "wantarray") }
2335 sub pp_fork { baseop(@_, "fork") }
2336 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
2337 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
2338 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
2339 sub pp_tms { baseop(@_, "times") }
2340 sub pp_ghostent { baseop(@_, "gethostent") }
2341 sub pp_gnetent { baseop(@_, "getnetent") }
2342 sub pp_gprotoent { baseop(@_, "getprotoent") }
2343 sub pp_gservent { baseop(@_, "getservent") }
2344 sub pp_ehostent { baseop(@_, "endhostent") }
2345 sub pp_enetent { baseop(@_, "endnetent") }
2346 sub pp_eprotoent { baseop(@_, "endprotoent") }
2347 sub pp_eservent { baseop(@_, "endservent") }
2348 sub pp_gpwent { baseop(@_, "getpwent") }
2349 sub pp_spwent { baseop(@_, "setpwent") }
2350 sub pp_epwent { baseop(@_, "endpwent") }
2351 sub pp_ggrent { baseop(@_, "getgrent") }
2352 sub pp_sgrent { baseop(@_, "setgrent") }
2353 sub pp_egrent { baseop(@_, "endgrent") }
2354 sub pp_getlogin { baseop(@_, "getlogin") }
2355
2356 sub POSTFIX () { 1 }
2357
2358 # I couldn't think of a good short name, but this is the category of
2359 # symbolic unary operators with interesting precedence
2360
2361 sub pfixop {
2362     my $self = shift;
2363     my($op, $cx, $name, $prec, $flags) = (@_, 0);
2364     my $kid = $op->first;
2365     $kid = $self->deparse($kid, $prec);
2366     return $self->maybe_parens(($flags & POSTFIX)
2367                                  ? "$kid$name"
2368                                    # avoid confusion with filetests
2369                                  : $name eq '-'
2370                                    && $kid =~ /^[a-zA-Z](?!\w)/
2371                                         ? "$name($kid)"
2372                                         : "$name$kid",
2373                                $cx, $prec);
2374 }
2375
2376 sub pp_preinc { pfixop(@_, "++", 23) }
2377 sub pp_predec { pfixop(@_, "--", 23) }
2378 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
2379 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
2380 sub pp_i_preinc { pfixop(@_, "++", 23) }
2381 sub pp_i_predec { pfixop(@_, "--", 23) }
2382 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
2383 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
2384 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
2385 *pp_ncomplement = *pp_complement;
2386 sub pp_scomplement { maybe_targmy(@_, \&pfixop, "~.", 21) }
2387
2388 sub pp_negate { maybe_targmy(@_, \&real_negate) }
2389 sub real_negate {
2390     my $self = shift;
2391     my($op, $cx) = @_;
2392     if ($op->first->name =~ /^(i_)?negate$/) {
2393         # avoid --$x
2394         $self->pfixop($op, $cx, "-", 21.5);
2395     } else {
2396         $self->pfixop($op, $cx, "-", 21);       
2397     }
2398 }
2399 sub pp_i_negate { pp_negate(@_) }
2400
2401 sub pp_not {
2402     my $self = shift;
2403     my($op, $cx) = @_;
2404     if ($cx <= 4) {
2405         $self->listop($op, $cx, "not", $op->first);
2406     } else {
2407         $self->pfixop($op, $cx, "!", 21);       
2408     }
2409 }
2410
2411 sub unop {
2412     my $self = shift;
2413     my($op, $cx, $name, $nollafr) = @_;
2414     my $kid;
2415     if ($op->flags & OPf_KIDS) {
2416         $kid = $op->first;
2417         if (not $name) {
2418             # this deals with 'boolkeys' right now
2419             return $self->deparse($kid,$cx);
2420         }
2421         my $builtinname = $name;
2422         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
2423         if (defined prototype($builtinname)
2424            && $builtinname ne 'CORE::readline'
2425            && prototype($builtinname) =~ /^;?\*/
2426            && $kid->name eq "rv2gv") {
2427             $kid = $kid->first;
2428         }
2429
2430         if ($nollafr) {
2431             if (($kid = $self->deparse($kid, 16)) !~ s/^\cS//) {
2432                 # require foo() is a syntax error.
2433                 $kid =~ /^(?!\d)\w/ and $kid = "($kid)";
2434             }
2435             return $self->maybe_parens(
2436                         $self->keyword($name) . " $kid", $cx, 16
2437                    );
2438         }   
2439         return $self->maybe_parens_unop($name, $kid, $cx);
2440     } else {
2441         return $self->maybe_parens(
2442             $self->keyword($name) . ($op->flags & OPf_SPECIAL ? "()" : ""),
2443             $cx, 16,
2444         );
2445     }
2446 }
2447
2448 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
2449 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
2450 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
2451 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
2452 sub pp_defined { unop(@_, "defined") }
2453 sub pp_undef { unop(@_, "undef") }
2454 sub pp_study { unop(@_, "study") }
2455 sub pp_ref { unop(@_, "ref") }
2456 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
2457
2458 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
2459 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
2460 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
2461 sub pp_srand { unop(@_, "srand") }
2462 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
2463 sub pp_log { maybe_targmy(@_, \&unop, "log") }
2464 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
2465 sub pp_int { maybe_targmy(@_, \&unop, "int") }
2466 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
2467 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
2468 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
2469
2470 sub pp_length { maybe_targmy(@_, \&unop, "length") }
2471 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
2472 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
2473
2474 sub pp_each { unop(@_, "each") }
2475 sub pp_values { unop(@_, "values") }
2476 sub pp_keys { unop(@_, "keys") }
2477 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
2478 sub pp_boolkeys { 
2479     # no name because its an optimisation op that has no keyword
2480     unop(@_,"");
2481 }
2482 sub pp_aeach { unop(@_, "each") }
2483 sub pp_avalues { unop(@_, "values") }
2484 sub pp_akeys { unop(@_, "keys") }
2485 sub pp_pop { unop(@_, "pop") }
2486 sub pp_shift { unop(@_, "shift") }
2487
2488 sub pp_caller { unop(@_, "caller") }
2489 sub pp_reset { unop(@_, "reset") }
2490 sub pp_exit { unop(@_, "exit") }
2491 sub pp_prototype { unop(@_, "prototype") }
2492
2493 sub pp_close { unop(@_, "close") }
2494 sub pp_fileno { unop(@_, "fileno") }
2495 sub pp_umask { unop(@_, "umask") }
2496 sub pp_untie { unop(@_, "untie") }
2497 sub pp_tied { unop(@_, "tied") }
2498 sub pp_dbmclose { unop(@_, "dbmclose") }
2499 sub pp_getc { unop(@_, "getc") }
2500 sub pp_eof { unop(@_, "eof") }
2501 sub pp_tell { unop(@_, "tell") }
2502 sub pp_getsockname { unop(@_, "getsockname") }
2503 sub pp_getpeername { unop(@_, "getpeername") }
2504
2505 sub pp_chdir {
2506     my ($self, $op, $cx) = @_;
2507     if (($op->flags & (OPf_SPECIAL|OPf_KIDS)) == (OPf_SPECIAL|OPf_KIDS)) {
2508         my $kw = $self->keyword("chdir");
2509         my $kid = $self->const_sv($op->first)->PV;
2510         my $code = $kw
2511                  . ($cx >= 16 || $self->{'parens'} ? "($kid)" : " $kid");
2512         maybe_targmy(@_, sub { $_[3] }, $code);
2513     } else {
2514         maybe_targmy(@_, \&unop, "chdir")
2515     }
2516 }
2517
2518 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
2519 sub pp_readlink { unop(@_, "readlink") }
2520 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
2521 sub pp_readdir { unop(@_, "readdir") }
2522 sub pp_telldir { unop(@_, "telldir") }
2523 sub pp_rewinddir { unop(@_, "rewinddir") }
2524 sub pp_closedir { unop(@_, "closedir") }
2525 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
2526 sub pp_localtime { unop(@_, "localtime") }
2527 sub pp_gmtime { unop(@_, "gmtime") }
2528 sub pp_alarm { unop(@_, "alarm") }
2529 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
2530
2531 sub pp_dofile {
2532     my $code = unop(@_, "do", 1); # llafr does not apply
2533     if ($code =~ s/^((?:CORE::)?do) \{/$1({/) { $code .= ')' }
2534     $code;
2535 }
2536 sub pp_entereval {
2537     unop(
2538       @_,
2539       $_[1]->private & OPpEVAL_BYTES ? 'evalbytes' : "eval"
2540     )
2541 }
2542
2543 sub pp_ghbyname { unop(@_, "gethostbyname") }
2544 sub pp_gnbyname { unop(@_, "getnetbyname") }
2545 sub pp_gpbyname { unop(@_, "getprotobyname") }
2546 sub pp_shostent { unop(@_, "sethostent") }
2547 sub pp_snetent { unop(@_, "setnetent") }
2548 sub pp_sprotoent { unop(@_, "setprotoent") }
2549 sub pp_sservent { unop(@_, "setservent") }
2550 sub pp_gpwnam { unop(@_, "getpwnam") }
2551 sub pp_gpwuid { unop(@_, "getpwuid") }
2552 sub pp_ggrnam { unop(@_, "getgrnam") }
2553 sub pp_ggrgid { unop(@_, "getgrgid") }
2554
2555 sub pp_lock { unop(@_, "lock") }
2556
2557 sub pp_continue { unop(@_, "continue"); }
2558 sub pp_break { unop(@_, "break"); }
2559
2560 sub givwhen {
2561     my $self = shift;
2562     my($op, $cx, $givwhen) = @_;
2563
2564     my $enterop = $op->first;
2565     my ($head, $block);
2566     if ($enterop->flags & OPf_SPECIAL) {
2567         $head = $self->keyword("default");
2568         $block = $self->deparse($enterop->first, 0);
2569     }
2570     else {
2571         my $cond = $enterop->first;
2572         my $cond_str = $self->deparse($cond, 1);
2573         $head = "$givwhen ($cond_str)";
2574         $block = $self->deparse($cond->sibling, 0);
2575     }
2576
2577     return "$head {\n".
2578         "\t$block\n".
2579         "\b}\cK";
2580 }
2581
2582 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
2583 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
2584
2585 sub pp_exists {
2586     my $self = shift;
2587     my($op, $cx) = @_;
2588     my $arg;
2589     my $name = $self->keyword("exists");
2590     if ($op->private & OPpEXISTS_SUB) {
2591         # Checking for the existence of a subroutine
2592         return $self->maybe_parens_func($name,
2593                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
2594     }
2595     if ($op->flags & OPf_SPECIAL) {
2596         # Array element, not hash element
2597         return $self->maybe_parens_func($name,
2598                                 $self->pp_aelem($op->first, 16), $cx, 16);
2599     }
2600     return $self->maybe_parens_func($name, $self->pp_helem($op->first, 16),
2601                                     $cx, 16);
2602 }
2603
2604 sub pp_delete {
2605     my $self = shift;
2606     my($op, $cx) = @_;
2607     my $arg;
2608     my $name = $self->keyword("delete");
2609     if ($op->private & (OPpSLICE|OPpKVSLICE)) {
2610         if ($op->flags & OPf_SPECIAL) {
2611             # Deleting from an array, not a hash
2612             return $self->maybe_parens_func($name,
2613                                         $self->pp_aslice($op->first, 16),
2614                                         $cx, 16);
2615         }
2616         return $self->maybe_parens_func($name,
2617                                         $self->pp_hslice($op->first, 16),
2618                                         $cx, 16);
2619     } else {
2620         if ($op->flags & OPf_SPECIAL) {
2621             # Deleting from an array, not a hash
2622             return $self->maybe_parens_func($name,
2623                                         $self->pp_aelem($op->first, 16),
2624                                         $cx, 16);
2625         }
2626         return $self->maybe_parens_func($name,
2627                                         $self->pp_helem($op->first, 16),
2628                                         $cx, 16);
2629     }
2630 }
2631
2632 sub pp_require {
2633     my $self = shift;
2634     my($op, $cx) = @_;
2635     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
2636     my $kid = $op->first;
2637     if ($kid->name eq 'const') {
2638         my $priv = $kid->private;
2639         my $sv = $self->const_sv($kid);
2640         my $arg;
2641         if ($priv & OPpCONST_BARE) {
2642             $arg = $sv->PV;
2643             $arg =~ s[/][::]g;
2644             $arg =~ s/\.pm//g;
2645         } elsif ($priv & OPpCONST_NOVER) {
2646             $opname = $self->keyword('no');
2647             $arg = $self->const($sv, 16);
2648         } elsif ((my $tmp = $self->const($sv, 16)) =~ /^v/) {
2649             $arg = $tmp;
2650         }
2651         if ($arg) {
2652             return $self->maybe_parens("$opname $arg", $cx, 16);
2653         }
2654     }
2655     $self->unop(
2656             $op, $cx,
2657             $opname,
2658             1, # llafr does not apply
2659     );
2660 }
2661
2662 sub pp_scalar {
2663     my $self = shift;
2664     my($op, $cx) = @_;
2665     my $kid = $op->first;
2666     if (not null $kid->sibling) {
2667         # XXX Was a here-doc
2668         return $self->dquote($op);
2669     }
2670     $self->unop(@_, "scalar");
2671 }
2672
2673
2674 sub padval {
2675     my $self = shift;
2676     my $targ = shift;
2677     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
2678 }
2679
2680 sub anon_hash_or_list {
2681     my $self = shift;
2682     my($op, $cx) = @_;
2683
2684     my($pre, $post) = @{{"anonlist" => ["[","]"],
2685                          "anonhash" => ["{","}"]}->{$op->name}};
2686     my($expr, @exprs);
2687     $op = $op->first->sibling; # skip pushmark
2688     for (; !null($op); $op = $op->sibling) {
2689         $expr = $self->deparse($op, 6);
2690         push @exprs, $expr;
2691     }
2692     if ($pre eq "{" and $cx < 1) {
2693         # Disambiguate that it's not a block
2694         $pre = "+{";
2695     }
2696     return $pre . join(", ", @exprs) . $post;
2697 }
2698
2699 sub pp_anonlist {
2700     my $self = shift;
2701     my ($op, $cx) = @_;
2702     if ($op->flags & OPf_SPECIAL) {
2703         return $self->anon_hash_or_list($op, $cx);
2704     }
2705     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
2706     return 'XXX';
2707 }
2708
2709 *pp_anonhash = \&pp_anonlist;
2710
2711 sub pp_refgen {
2712     my $self = shift;   
2713     my($op, $cx) = @_;
2714     my $kid = $op->first;
2715     if ($kid->name eq "null") {
2716         my $anoncode = $kid = $kid->first;
2717         if ($anoncode->name eq "anonconst") {
2718             $anoncode = $anoncode->first->first->sibling;
2719         }
2720         if ($anoncode->name eq "anoncode"
2721          or !null($anoncode = $kid->sibling) and
2722                  $anoncode->name eq "anoncode") {
2723             return $self->e_anoncode({ code => $self->padval($anoncode->targ) });
2724         } elsif ($kid->name eq "pushmark") {
2725             my $sib_name = $kid->sibling->name;
2726             if ($sib_name eq 'entersub') {
2727                 my $text = $self->deparse($kid->sibling, 1);
2728                 # Always show parens for \(&func()), but only with -p otherwise
2729                 $text = "($text)" if $self->{'parens'}
2730                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
2731                 return "\\$text";
2732             }
2733         }
2734     }
2735     local $self->{'in_refgen'} = 1;
2736     $self->pfixop($op, $cx, "\\", 20);
2737 }
2738
2739 sub e_anoncode {
2740     my ($self, $info) = @_;
2741     my $text = $self->deparse_sub($info->{code});
2742     return $self->keyword("sub") . " $text";
2743 }
2744
2745 sub pp_srefgen { pp_refgen(@_) }
2746
2747 sub pp_readline {
2748     my $self = shift;
2749     my($op, $cx) = @_;
2750     my $kid = $op->first;
2751     if (is_scalar($kid)
2752         and $op->flags & OPf_SPECIAL
2753         and $self->deparse($kid, 1) eq 'ARGV')
2754     {
2755         return '<<>>';
2756     }
2757     return $self->unop($op, $cx, "readline");
2758 }
2759
2760 sub pp_rcatline {
2761     my $self = shift;
2762     my($op) = @_;
2763     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
2764 }
2765
2766 # Unary operators that can occur as pseudo-listops inside double quotes
2767 sub dq_unop {
2768     my $self = shift;
2769     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
2770     my $kid;
2771     if ($op->flags & OPf_KIDS) {
2772        $kid = $op->first;
2773        # If there's more than one kid, the first is an ex-pushmark.
2774        $kid = $kid->sibling if not null $kid->sibling;
2775        return $self->maybe_parens_unop($name, $kid, $cx);
2776     } else {
2777        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
2778     }
2779 }
2780
2781 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
2782 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
2783 sub pp_uc { dq_unop(@_, "uc") }
2784 sub pp_lc { dq_unop(@_, "lc") }
2785 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
2786 sub pp_fc { dq_unop(@_, "fc") }
2787
2788 sub loopex {
2789     my $self = shift;
2790     my ($op, $cx, $name) = @_;
2791     if (class($op) eq "PVOP") {
2792         $name .= " " . $op->pv;
2793     } elsif (class($op) eq "OP") {
2794         # no-op
2795     } elsif (class($op) eq "UNOP") {
2796         (my $kid = $self->deparse($op->first, 7)) =~ s/^\cS//;
2797         # last foo() is a syntax error.
2798         $kid =~ /^(?!\d)\w/ and $kid = "($kid)";
2799         $name .= " $kid";
2800     }
2801     return $self->maybe_parens($name, $cx, 7);
2802 }
2803
2804 sub pp_last { loopex(@_, "last") }
2805 sub pp_next { loopex(@_, "next") }
2806 sub pp_redo { loopex(@_, "redo") }
2807 sub pp_goto { loopex(@_, "goto") }
2808 sub pp_dump { loopex(@_, "CORE::dump") }
2809
2810 sub ftst {
2811     my $self = shift;
2812     my($op, $cx, $name) = @_;
2813     if (class($op) eq "UNOP") {
2814         # Genuine '-X' filetests are exempt from the LLAFR, but not
2815         # l?stat()
2816         if ($name =~ /^-/) {
2817             (my $kid = $self->deparse($op->first, 16)) =~ s/^\cS//;
2818             return $self->maybe_parens("$name $kid", $cx, 16);
2819         }
2820         return $self->maybe_parens_unop($name, $op->first, $cx);
2821     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2822         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2823     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2824         return $name;
2825     }
2826 }
2827
2828 sub pp_lstat    { ftst(@_, "lstat") }
2829 sub pp_stat     { ftst(@_, "stat") }
2830 sub pp_ftrread  { ftst(@_, "-R") }
2831 sub pp_ftrwrite { ftst(@_, "-W") }
2832 sub pp_ftrexec  { ftst(@_, "-X") }
2833 sub pp_fteread  { ftst(@_, "-r") }
2834 sub pp_ftewrite { ftst(@_, "-w") }
2835 sub pp_fteexec  { ftst(@_, "-x") }
2836 sub pp_ftis     { ftst(@_, "-e") }
2837 sub pp_fteowned { ftst(@_, "-O") }
2838 sub pp_ftrowned { ftst(@_, "-o") }
2839 sub pp_ftzero   { ftst(@_, "-z") }
2840 sub pp_ftsize   { ftst(@_, "-s") }
2841 sub pp_ftmtime  { ftst(@_, "-M") }
2842 sub pp_ftatime  { ftst(@_, "-A") }
2843 sub pp_ftctime  { ftst(@_, "-C") }
2844 sub pp_ftsock   { ftst(@_, "-S") }
2845 sub pp_ftchr    { ftst(@_, "-c") }
2846 sub pp_ftblk    { ftst(@_, "-b") }
2847 sub pp_ftfile   { ftst(@_, "-f") }
2848 sub pp_ftdir    { ftst(@_, "-d") }
2849 sub pp_ftpipe   { ftst(@_, "-p") }
2850 sub pp_ftlink   { ftst(@_, "-l") }
2851 sub pp_ftsuid   { ftst(@_, "-u") }
2852 sub pp_ftsgid   { ftst(@_, "-g") }
2853 sub pp_ftsvtx   { ftst(@_, "-k") }
2854 sub pp_fttty    { ftst(@_, "-t") }
2855 sub pp_fttext   { ftst(@_, "-T") }
2856 sub pp_ftbinary { ftst(@_, "-B") }
2857
2858 sub SWAP_CHILDREN () { 1 }
2859 sub ASSIGN () { 2 } # has OP= variant
2860 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2861
2862 my(%left, %right);
2863
2864 sub assoc_class {
2865     my $op = shift;
2866     my $name = $op->name;
2867     if ($name eq "concat" and $op->first->name eq "concat") {
2868         # avoid spurious '=' -- see comment in pp_concat
2869         return "concat";
2870     }
2871     if ($name eq "null" and class($op) eq "UNOP"
2872         and $op->first->name =~ /^(and|x?or)$/
2873         and null $op->first->sibling)
2874     {
2875         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2876         # with a null that's used as the common end point of the two
2877         # flows of control. For precedence purposes, ignore it.
2878         # (COND_EXPRs have these too, but we don't bother with
2879         # their associativity).
2880         return assoc_class($op->first);
2881     }
2882     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2883 }
2884
2885 # Left associative operators, like '+', for which
2886 # $a + $b + $c is equivalent to ($a + $b) + $c
2887
2888 BEGIN {
2889     %left = ('multiply' => 19, 'i_multiply' => 19,
2890              'divide' => 19, 'i_divide' => 19,
2891              'modulo' => 19, 'i_modulo' => 19,
2892              'repeat' => 19,
2893              'add' => 18, 'i_add' => 18,
2894              'subtract' => 18, 'i_subtract' => 18,
2895              'concat' => 18,
2896              'left_shift' => 17, 'right_shift' => 17,
2897              'bit_and' => 13, 'nbit_and' => 13, 'sbit_and' => 13,
2898              'bit_or' => 12, 'bit_xor' => 12,
2899              'sbit_or' => 12, 'sbit_xor' => 12,
2900              'nbit_or' => 12, 'nbit_xor' => 12,
2901              'and' => 3,
2902              'or' => 2, 'xor' => 2,
2903             );
2904 }
2905
2906 sub deparse_binop_left {
2907     my $self = shift;
2908     my($op, $left, $prec) = @_;
2909     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2910         and $left{assoc_class($op)} == $left{assoc_class($left)})
2911     {
2912         return $self->deparse($left, $prec - .00001);
2913     } else {
2914         return $self->deparse($left, $prec);    
2915     }
2916 }
2917
2918 # Right associative operators, like '=', for which
2919 # $a = $b = $c is equivalent to $a = ($b = $c)
2920
2921 BEGIN {
2922     %right = ('pow' => 22,
2923               'sassign=' => 7, 'aassign=' => 7,
2924               'multiply=' => 7, 'i_multiply=' => 7,
2925               'divide=' => 7, 'i_divide=' => 7,
2926               'modulo=' => 7, 'i_modulo=' => 7,
2927               'repeat=' => 7, 'refassign' => 7, 'refassign=' => 7,
2928               'add=' => 7, 'i_add=' => 7,
2929               'subtract=' => 7, 'i_subtract=' => 7,
2930               'concat=' => 7,
2931               'left_shift=' => 7, 'right_shift=' => 7,
2932               'bit_and=' => 7, 'sbit_and=' => 7, 'nbit_and=' => 7,
2933               'nbit_or=' => 7, 'nbit_xor=' => 7,
2934               'sbit_or=' => 7, 'sbit_xor=' => 7,
2935               'andassign' => 7,
2936               'orassign' => 7,
2937              );
2938 }
2939
2940 sub deparse_binop_right {
2941     my $self = shift;
2942     my($op, $right, $prec) = @_;
2943     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2944         and $right{assoc_class($op)} == $right{assoc_class($right)})
2945     {
2946         return $self->deparse($right, $prec - .00001);
2947     } else {
2948         return $self->deparse($right, $prec);   
2949     }
2950 }
2951
2952 sub binop {
2953     my $self = shift;
2954     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2955     my $left = $op->first;
2956     my $right = $op->last;
2957     my $eq = "";
2958     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2959         $eq = "=";
2960         $prec = 7;
2961     }
2962     if ($flags & SWAP_CHILDREN) {
2963         ($left, $right) = ($right, $left);
2964     }
2965     my $leftop = $left;
2966     $left = $self->deparse_binop_left($op, $left, $prec);
2967     $left = "($left)" if $flags & LIST_CONTEXT
2968                      and    $left !~ /^(my|our|local|)[\@\(]/
2969                          || do {
2970                                 # Parenthesize if the left argument is a
2971                                 # lone repeat op.
2972                                 my $left = $leftop->first->sibling;
2973                                 $left->name eq 'repeat'
2974                                     && null($left->sibling);
2975                             };
2976     $right = $self->deparse_binop_right($op, $right, $prec);
2977     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2978 }
2979
2980 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2981 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2982 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2983 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2984 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2985 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2986 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2987 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2988 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2989 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2990 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2991
2992 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2993 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2994 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2995 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2996 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2997 *pp_nbit_and = *pp_bit_and;
2998 *pp_nbit_or  = *pp_bit_or;
2999 *pp_nbit_xor = *pp_bit_xor;
3000 sub pp_sbit_and { maybe_targmy(@_, \&binop, "&.", 13, ASSIGN) }
3001 sub pp_sbit_or { maybe_targmy(@_, \&binop, "|.", 12, ASSIGN) }
3002 sub pp_sbit_xor { maybe_targmy(@_, \&binop, "^.", 12, ASSIGN) }
3003
3004 sub pp_eq { binop(@_, "==", 14) }
3005 sub pp_ne { binop(@_, "!=", 14) }
3006 sub pp_lt { binop(@_, "<", 15) }
3007 sub pp_gt { binop(@_, ">", 15) }
3008 sub pp_ge { binop(@_, ">=", 15) }
3009 sub pp_le { binop(@_, "<=", 15) }
3010 sub pp_ncmp { binop(@_, "<=>", 14) }
3011 sub pp_i_eq { binop(@_, "==", 14) }
3012 sub pp_i_ne { binop(@_, "!=", 14) }
3013 sub pp_i_lt { binop(@_, "<", 15) }
3014 sub pp_i_gt { binop(@_, ">", 15) }
3015 sub pp_i_ge { binop(@_, ">=", 15) }
3016 sub pp_i_le { binop(@_, "<=", 15) }
3017 sub pp_i_ncmp { maybe_targmy(@_, \&binop, "<=>", 14) }
3018
3019 sub pp_seq { binop(@_, "eq", 14) }
3020 sub pp_sne { binop(@_, "ne", 14) }
3021 sub pp_slt { binop(@_, "lt", 15) }
3022 sub pp_sgt { binop(@_, "gt", 15) }
3023 sub pp_sge { binop(@_, "ge", 15) }
3024 sub pp_sle { binop(@_, "le", 15) }
3025 sub pp_scmp { maybe_targmy(@_, \&binop, "cmp", 14) }
3026
3027 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
3028 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
3029
3030 sub pp_smartmatch {
3031     my ($self, $op, $cx) = @_;
3032     if (($op->flags & OPf_SPECIAL) && $self->{expand} < 2) {
3033         return $self->deparse($op->last, $cx);
3034     }
3035     else {
3036         binop(@_, "~~", 14);
3037     }
3038 }
3039
3040 # '.' is special because concats-of-concats are optimized to save copying
3041 # by making all but the first concat stacked. The effect is as if the
3042 # programmer had written '($a . $b) .= $c', except legal.
3043 sub pp_concat { maybe_targmy(@_, \&real_concat) }
3044 sub real_concat {
3045     my $self = shift;
3046     my($op, $cx) = @_;
3047     my $left = $op->first;
3048     my $right = $op->last;
3049     my $eq = "";
3050     my $prec = 18;
3051     if (($op->flags & OPf_STACKED) and !($op->private & OPpCONCAT_NESTED)) {
3052         # '.=' rather than optimised '.'
3053         $eq = "=";
3054         $prec = 7;
3055     }
3056     $left = $self->deparse_binop_left($op, $left, $prec);
3057     $right = $self->deparse_binop_right($op, $right, $prec);
3058     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
3059 }
3060
3061 sub pp_repeat { maybe_targmy(@_, \&repeat) }
3062
3063 # 'x' is weird when the left arg is a list
3064 sub repeat {
3065     my $self = shift;
3066     my($op, $cx) = @_;
3067     my $left = $op->first;
3068     my $right = $op->last;
3069     my $eq = "";
3070     my $prec = 19;
3071     if ($op->flags & OPf_STACKED) {
3072         $eq = "=";
3073         $prec = 7;
3074     }
3075     if (null($right)) { # list repeat; count is inside left-side ex-list
3076                         # in 5.21.5 and earlier
3077         my $kid = $left->first->sibling; # skip pushmark
3078         my @exprs;
3079         for (; !null($kid->sibling); $kid = $kid->sibling) {
3080             push @exprs, $self->deparse($kid, 6);
3081         }
3082         $right = $kid;
3083         $left = "(" . join(", ", @exprs). ")";
3084     } else {
3085         my $dolist = $op->private & OPpREPEAT_DOLIST;
3086         $left = $self->deparse_binop_left($op, $left, $dolist ? 1 : $prec);
3087         if ($dolist) {
3088             $left = "($left)";
3089         }
3090     }
3091     $right = $self->deparse_binop_right($op, $right, $prec);
3092     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
3093 }
3094
3095 sub range {
3096     my $self = shift;
3097     my ($op, $cx, $type) = @_;
3098     my $left = $op->first;
3099     my $right = $left->sibling;
3100     $left = $self->deparse($left, 9);
3101     $right = $self->deparse($right, 9);
3102     return $self->maybe_parens("$left $type $right", $cx, 9);
3103 }
3104
3105 sub pp_flop {
3106     my $self = shift;
3107     my($op, $cx) = @_;
3108     my $flip = $op->first;
3109     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
3110     return $self->range($flip->first, $cx, $type);
3111 }
3112
3113 # one-line while/until is handled in pp_leave
3114
3115 sub logop {
3116     my $self = shift;
3117     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
3118     my $left = $op->first;
3119     my $right = $op->first->sibling;
3120     $blockname &&= $self->keyword($blockname);
3121     if ($cx < 1 and is_scope($right) and $blockname
3122         and $self->{'expand'} < 7)
3123     { # if ($a) {$b}
3124         $left = $self->deparse($left, 1);
3125         $right = $self->deparse($right, 0);
3126         return "$blockname ($left) {\n\t$right\n\b}\cK";
3127     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
3128              and $self->{'expand'} < 7) { # $b if $a
3129         $right = $self->deparse($right, 1);
3130         $left = $self->deparse($left, 1);
3131         return "$right $blockname $left";
3132     } elsif ($cx > $lowprec and $highop) { # $a && $b
3133         $left = $self->deparse_binop_left($op, $left, $highprec);
3134         $right = $self->deparse_binop_right($op, $right, $highprec);
3135         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
3136     } else { # $a and $b
3137         $left = $self->deparse_binop_left($op, $left, $lowprec);
3138         $right = $self->deparse_binop_right($op, $right, $lowprec);
3139         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
3140     }
3141 }
3142
3143 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
3144 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
3145 sub pp_dor { logop(@_, "//", 10) }
3146
3147 # xor is syntactically a logop, but it's really a binop (contrary to
3148 # old versions of opcode.pl). Syntax is what matters here.
3149 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
3150
3151 sub logassignop {
3152     my $self = shift;
3153     my ($op, $cx, $opname) = @_;
3154     my $left = $op->first;
3155     my $right = $op->first->sibling->first; # skip sassign
3156     $left = $self->deparse($left, 7);
3157     $right = $self->deparse($right, 7);
3158     return $self->maybe_parens("$left $opname $right", $cx, 7);
3159 }
3160
3161 sub pp_andassign { logassignop(@_, "&&=") }
3162 sub pp_orassign  { logassignop(@_, "||=") }
3163 sub pp_dorassign { logassignop(@_, "//=") }
3164
3165 sub rv2gv_or_string {
3166     my($self,$op) = @_;
3167     if ($op->name eq "gv") { # could be open("open") or open("###")
3168         my($name,$quoted) =
3169             $self->stash_variable_name("", $self->gv_or_padgv($op));
3170         $quoted ? $name : "*$name";
3171     }
3172     else {
3173         $self->deparse($op, 6);
3174     }
3175 }
3176
3177 sub listop {
3178     my $self = shift;
3179     my($op, $cx, $name, $kid, $nollafr) = @_;
3180     my(@exprs);
3181     my $parens = ($cx >= 5) || $self->{'parens'};
3182     $kid ||= $op->first->sibling;
3183     # If there are no arguments, add final parentheses (or parenthesize the
3184     # whole thing if the llafr does not apply) to account for cases like
3185     # (return)+1 or setpgrp()+1.  When the llafr does not apply, we use a
3186     # precedence of 6 (< comma), as "return, 1" does not need parentheses.
3187     if (null $kid) {
3188         return $nollafr
3189                 ? $self->maybe_parens($self->keyword($name), $cx, 7)
3190                 : $self->keyword($name) . '()' x (7 < $cx);
3191     }
3192     my $first;
3193     my $fullname = $self->keyword($name);
3194     my $proto = prototype("CORE::$name");
3195     if (
3196          (     (defined $proto && $proto =~ /^;?\*/)
3197             || $name eq 'select' # select(F) doesn't have a proto
3198          )
3199          && $kid->name eq "rv2gv"
3200          && !($kid->private & OPpLVAL_INTRO)
3201     ) {
3202         $first = $self->rv2gv_or_string($kid->first);
3203     }
3204     else {
3205         $first = $self->deparse($kid, 6);
3206     }
3207     if ($name eq "chmod" && $first =~ /^\d+$/) {
3208         $first = sprintf("%#o", $first);
3209     }
3210     $first = "+$first"
3211         if not $parens and not $nollafr and substr($first, 0, 1) eq "(";
3212     push @exprs, $first;
3213     $kid = $kid->sibling;
3214     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv"
3215          && !($kid->private & OPpLVAL_INTRO)) {
3216         push @exprs, $first = $self->rv2gv_or_string($kid->first);
3217         $kid = $kid->sibling;
3218     }
3219     for (; !null($kid); $kid = $kid->sibling) {
3220         push @exprs, $self->deparse($kid, 6);
3221     }
3222     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
3223         return "$exprs[0] = $fullname"
3224                  . ($parens ? "($exprs[0])" : " $exprs[0]");
3225     }
3226
3227     if ($parens && $nollafr) {
3228         return "($fullname " . join(", ", @exprs) . ")";
3229     } elsif ($parens) {
3230         return "$fullname(" . join(", ", @exprs) . ")";
3231     } else {
3232         return "$fullname " . join(", ", @exprs);
3233     }
3234 }
3235
3236 sub pp_bless { listop(@_, "bless") }
3237 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
3238 sub pp_substr {
3239     my ($self,$op,$cx) = @_;
3240     if ($op->private & OPpSUBSTR_REPL_FIRST) {
3241         return
3242            listop($self, $op, 7, "substr", $op->first->sibling->sibling)
3243          . " = "
3244          . $self->deparse($op->first->sibling, 7);
3245     }
3246     maybe_local(@_, listop(@_, "substr"))
3247 }
3248
3249 sub pp_index {
3250     # Also handles pp_rindex.
3251     #
3252     # The body of this function includes an unrolled maybe_targmy(),
3253     # since the two parts of that sub's actions need to have have the
3254     # '== -1' bit in between
3255
3256     my($self, $op, $cx) = @_;
3257
3258     my $lex  = ($op->private & OPpTARGET_MY);
3259     my $bool = ($op->private & OPpTRUEBOOL);
3260
3261     my $val = $self->listop($op, ($bool ? 14 : $lex ? 7 : $cx), $op->name);
3262
3263     # (index() == -1) has op_eq and op_const optimised away
3264     if ($bool) {
3265         $val .= ($op->private & OPpINDEX_BOOLNEG) ? " == -1" : " != -1";
3266         $val = "($val)" if ($op->flags & OPf_PARENS);
3267     }
3268     if ($lex) {
3269         my $var = $self->padname($op->targ);
3270         $val = $self->maybe_parens("$var = $val", $cx, 7);
3271     }
3272     $val;
3273 }
3274
3275 sub pp_rindex { pp_index(@_); }
3276 sub pp_vec { maybe_targmy(@_, \&maybe_local, listop(@_, "vec")) }
3277 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
3278 sub pp_formline { listop(@_, "formline") } # see also deparse_format
3279 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
3280 sub pp_unpack { listop(@_, "unpack") }
3281 sub pp_pack { listop(@_, "pack") }
3282 sub pp_join { maybe_targmy(@_, \&listop, "join") }
3283 sub pp_splice { listop(@_, "splice") }
3284 sub pp_push { maybe_targmy(@_, \&listop, "push") }
3285 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
3286 sub pp_reverse { listop(@_, "reverse") }
3287 sub pp_warn { listop(@_, "warn") }
3288 sub pp_die { listop(@_, "die") }
3289 sub pp_return { listop(@_, "return", undef, 1) } # llafr does not apply
3290 sub pp_open { listop(@_, "open") }
3291 sub pp_pipe_op { listop(@_, "pipe") }
3292 sub pp_tie { listop(@_, "tie") }
3293 sub pp_binmode { listop(@_, "binmode") }
3294 sub pp_dbmopen { listop(@_, "dbmopen") }
3295 sub pp_sselect { listop(@_, "select") }
3296 sub pp_select { listop(@_, "select") }
3297 sub pp_read { listop(@_, "read") }
3298 sub pp_sysopen { listop(@_, "sysopen") }
3299 sub pp_sysseek { listop(@_, "sysseek") }
3300 sub pp_sysread { listop(@_, "sysread") }
3301 sub pp_syswrite { listop(@_, "syswrite") }
3302 sub pp_send { listop(@_, "send") }
3303 sub pp_recv { listop(@_, "recv") }
3304 sub pp_seek { listop(@_, "seek") }
3305 sub pp_fcntl { listop(@_, "fcntl") }
3306 sub pp_ioctl { listop(@_, "ioctl") }
3307 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
3308 sub pp_socket { listop(@_, "socket") }
3309 sub pp_sockpair { listop(@_, "socketpair") }
3310 sub pp_bind { listop(@_, "bind") }
3311 sub pp_connect { listop(@_, "connect") }
3312 sub pp_listen { listop(@_, "listen") }
3313 sub pp_accept { listop(@_, "accept") }
3314 sub pp_shutdown { listop(@_, "shutdown") }
3315 sub pp_gsockopt { listop(@_, "getsockopt") }
3316 sub pp_ssockopt { listop(@_, "setsockopt") }
3317 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
3318 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
3319 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
3320 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
3321 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
3322 sub pp_link { maybe_targmy(@_, \&listop, "link") }
3323 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
3324 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
3325 sub pp_open_dir { listop(@_, "opendir") }
3326 sub pp_seekdir { listop(@_, "seekdir") }
3327 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
3328 sub pp_system { maybe_targmy(@_, \&indirop, "system") }
3329 sub pp_exec { maybe_targmy(@_, \&indirop, "exec") }
3330 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
3331 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
3332 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
3333 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
3334 sub pp_shmget { listop(@_, "shmget") }
3335 sub pp_shmctl { listop(@_, "shmctl") }
3336 sub pp_shmread { listop(@_, "shmread") }
3337 sub pp_shmwrite { listop(@_, "shmwrite") }
3338 sub pp_msgget { listop(@_, "msgget") }
3339 sub pp_msgctl { listop(@_, "msgctl") }
3340 sub pp_msgsnd { listop(@_, "msgsnd") }
3341 sub pp_msgrcv { listop(@_, "msgrcv") }
3342 sub pp_semget { listop(@_, "semget") }
3343 sub pp_semctl { listop(@_, "semctl") }
3344 sub pp_semop { listop(@_, "semop") }
3345 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
3346 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
3347 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
3348 sub pp_gsbyname { listop(@_, "getservbyname") }
3349 sub pp_gsbyport { listop(@_, "getservbyport") }
3350 sub pp_syscall { listop(@_, "syscall") }
3351
3352 sub pp_glob {
3353     my $self = shift;
3354     my($op, $cx) = @_;
3355     my $kid = $op->first->sibling;  # skip pushmark
3356     my $keyword =
3357         $op->flags & OPf_SPECIAL ? 'glob' : $self->keyword('glob');
3358     my $text = $self->deparse($kid);
3359     return $cx >= 5 || $self->{'parens'}
3360         ? "$keyword($text)"
3361         : "$keyword $text";
3362 }
3363
3364 # Truncate is special because OPf_SPECIAL makes a bareword first arg
3365 # be a filehandle. This could probably be better fixed in the core
3366 # by moving the GV lookup into ck_truc.
3367
3368 sub pp_truncate {
3369     my $self = shift;
3370     my($op, $cx) = @_;
3371     my(@exprs);
3372     my $parens = ($cx >= 5) || $self->{'parens'};
3373     my $kid = $op->first->sibling;
3374     my $fh;
3375     if ($op->flags & OPf_SPECIAL) {
3376         # $kid is an OP_CONST
3377         $fh = $self->const_sv($kid)->PV;
3378     } else {
3379         $fh = $self->deparse($kid, 6);
3380         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
3381     }
3382     my $len = $self->deparse($kid->sibling, 6);
3383     my $name = $self->keyword('truncate');
3384     if ($parens) {
3385         return "$name($fh, $len)";
3386     } else {
3387         return "$name $fh, $len";
3388     }
3389 }
3390
3391 sub indirop {
3392     my $self = shift;
3393     my($op, $cx, $name) = @_;
3394     my($expr, @exprs);
3395     my $firstkid = my $kid = $op->first->sibling;
3396     my $indir = "";
3397     if ($op->flags & OPf_STACKED) {
3398         $indir = $kid;
3399         $indir = $indir->first; # skip rv2gv
3400         if (is_scope($indir)) {
3401             $indir = "{" . $self->deparse($indir, 0) . "}";
3402             $indir = "{;}" if $indir eq "{}";
3403         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
3404             $indir = $self->const_sv($indir)->PV;
3405         } else {
3406             $indir = $self->deparse($indir, 24);
3407         }
3408         $indir = $indir . " ";
3409         $kid = $kid->sibling;
3410     }
3411     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
3412         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
3413                                                   : '{$a <=> $b} ';
3414     }
3415     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
3416         $indir = '{$b cmp $a} ';
3417     }
3418     for (; !null($kid); $kid = $kid->sibling) {
3419         $expr = $self->deparse($kid, !$indir && $kid == $firstkid && $name eq "sort" && $firstkid->name eq "entersub" ? 16 : 6);
3420         push @exprs, $expr;
3421     }
3422     my $name2;
3423     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
3424         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
3425     }
3426     else { $name2 = $self->keyword($name) }
3427     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
3428         return "$exprs[0] = $name2 $indir $exprs[0]";
3429     }
3430
3431     my $args = $indir . join(", ", @exprs);
3432     if ($indir ne "" && $name eq "sort") {
3433         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
3434         # give bareword warnings in that case. Therefore if context
3435         # requires, we'll put parens around the outside "(sort f 1, 2,
3436         # 3)". Unfortunately, we'll currently think the parens are
3437         # necessary more often that they really are, because we don't
3438         # distinguish which side of an assignment we're on.
3439         if ($cx >= 5) {
3440             return "($name2 $args)";
3441         } else {
3442             return "$name2 $args";
3443         }
3444     } elsif (
3445         !$indir && $name eq "sort"
3446       && !null($op->first->sibling)
3447       && $op->first->sibling->name eq 'entersub'
3448     ) {
3449         # We cannot say sort foo(bar), as foo will be interpreted as a
3450         # comparison routine.  We have to say sort(...) in that case.
3451         return "$name2($args)";
3452     } else {
3453         return length $args
3454                 ? $self->maybe_parens_func($name2, $args, $cx, 5)
3455                 : $name2 . '()' x (7 < $cx);
3456     }
3457
3458 }
3459
3460 sub pp_prtf { indirop(@_, "printf") }
3461 sub pp_print { indirop(@_, "print") }
3462 sub pp_say  { indirop(@_, "say") }
3463 sub pp_sort { indirop(@_, "sort") }
3464
3465 sub mapop {
3466     my $self = shift;
3467     my($op, $cx, $name) = @_;
3468     my($expr, @exprs);
3469     my $kid = $op->first; # this is the (map|grep)start
3470     $kid = $kid->first->sibling; # skip a pushmark
3471     my $code = $kid->first; # skip a null
3472     if (is_scope $code) {
3473         $code = "{" . $self->deparse($code, 0) . "} ";
3474     } else {
3475         $code = $self->deparse($code, 24);
3476         $code .= ", " if !null($kid->sibling);
3477     }
3478     $kid = $kid->sibling;
3479     for (; !null($kid); $kid = $kid->sibling) {
3480         $expr = $self->deparse($kid, 6);
3481         push @exprs, $expr if defined $expr;
3482     }
3483     return $self->maybe_parens_func($self->keyword($name),
3484                                     $code . join(", ", @exprs), $cx, 5);
3485 }
3486
3487 sub pp_mapwhile { mapop(@_, "map") }
3488 sub pp_grepwhile { mapop(@_, "grep") }
3489 sub pp_mapstart { baseop(@_, "map") }
3490 sub pp_grepstart { baseop(@_, "grep") }
3491
3492 my %uses_intro;
3493 BEGIN {
3494     @uses_intro{
3495         eval { require B::Op_private }
3496           ? @{$B::Op_private::ops_using{OPpLVAL_INTRO}}
3497           : qw(gvsv rv2sv rv2hv rv2gv rv2av aelem helem aslice
3498                hslice delete padsv padav padhv enteriter entersub padrange
3499                pushmark cond_expr refassign list)
3500     } = ();
3501     delete @uses_intro{qw( lvref lvrefslice lvavref entersub )};
3502 }
3503
3504
3505 # Look for a my attribute declaration in a list or ex-list. Returns undef
3506 # if not found, 'my($x, @a) :Foo(bar)' etc otherwise.
3507 #
3508 # There are three basic tree structs that are expected:
3509 #
3510 # my $x :foo;
3511 #      <1> ex-list vK/LVINTRO ->c
3512 #         <0> ex-pushmark v ->3
3513 #         <1> entersub[t2] vKRS*/TARG ->b
3514 #                ....
3515 #         <0> padsv[$x:64,65] vM/LVINTRO ->c
3516 #
3517 # my @a :foo;
3518 # my %h :foo;
3519 #
3520 #      <1> ex-list vK ->c
3521 #         <0> ex-pushmark v ->3
3522 #         <0> padav[@a:64,65] vM/LVINTRO ->4
3523 #         <1> entersub[t2] vKRS*/TARG ->c
3524 #            ....
3525 #
3526 # my ($x,@a,%h) :foo;
3527 #
3528 #      <;> nextstate(main 64 -e:1) v:{ ->3
3529 #      <@> list vKP ->w
3530 #         <0> pushmark vM/LVINTRO ->4
3531 #         <0> padsv[$x:64,65] vM/LVINTRO ->5
3532 #         <0> padav[@a:64,65] vM/LVINTRO ->6
3533 #         <0> padhv[%h:64,65] vM/LVINTRO ->7
3534 #         <1> entersub[t4] vKRS*/TARG ->f
3535 #            ....
3536 #         <1> entersub[t5] vKRS*/TARG ->n
3537 #            ....
3538 #         <1> entersub[t6] vKRS*/TARG ->v
3539 #           ....
3540 # where the entersub in all cases looks like
3541 #        <1> entersub[t2] vKRS*/TARG ->c
3542 #           <0> pushmark s ->5
3543 #           <$> const[PV "attributes"] sM ->6
3544 #           <$> const[PV "main"] sM ->7
3545 #           <1> srefgen sKM/1 ->9
3546 #              <1> ex-list lKRM ->8
3547 #                 <0> padsv[@a:64,65] sRM ->8
3548 #           <$> const[PV "foo"] sM ->a
3549 #           <.> method_named[PV "import"] ->b
3550
3551 sub maybe_my_attr {
3552     my ($self, $op, $cx) = @_;
3553
3554     my $kid = $op->first->sibling; # skip pushmark
3555     return if class($kid) eq 'NULL';
3556
3557     my $lop;
3558     my $type;
3559
3560     # Extract out all the pad ops and entersub ops into
3561     # @padops and @entersubops. Return if anything else seen.
3562     # Also determine what class (if any) all the pad vars belong to
3563     my $class;
3564     my (@padops, @entersubops);
3565     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
3566         my $lopname = $lop->name;
3567         my $loppriv = $lop->private;
3568         if ($lopname =~ /^pad[sah]v$/) {
3569             return unless $loppriv & OPpLVAL_INTRO;
3570             return if     $loppriv & OPpPAD_STATE;
3571
3572             my $padname = $self->padname_sv($lop->targ);
3573             my $thisclass = ($padname->FLAGS & SVpad_TYPED)
3574                                 ? $padname->SvSTASH->NAME : 'main';
3575
3576             # all pad vars must be in the same class
3577             $class //= $thisclass;
3578             return unless $thisclass eq $class;
3579
3580             push @padops, $lop;
3581         }
3582         elsif ($lopname eq 'entersub') {
3583             push @entersubops, $lop;
3584         }
3585         else {
3586             return;
3587         }
3588     }
3589
3590     return unless @padops && @padops == @entersubops;
3591
3592     # there should be a balance: each padop has a corresponding
3593     # 'attributes'->import() method call, in the same order.
3594
3595     my @varnames;
3596     my $attr_text;
3597
3598     for my $i (0..$#padops) {
3599         my $padop = $padops[$i];
3600         my $esop  = $entersubops[$i];
3601
3602         push @varnames, $self->padname($padop->targ);
3603
3604         return unless ($esop->flags & OPf_KIDS);
3605
3606         my $kid = $esop->first;
3607         return unless $kid->type == OP_PUSHMARK;
3608
3609         $kid = $kid->sibling;
3610         return unless $$kid && $kid->type == OP_CONST;
3611         return unless $self->const_sv($kid)->PV eq 'attributes';
3612
3613         $kid = $kid->sibling;
3614         return unless $$kid && $kid->type == OP_CONST; # __PACKAGE__
3615
3616         $kid = $kid->sibling;
3617         return unless  $$kid
3618                     && $kid->name eq "srefgen"
3619                     && ($kid->flags & OPf_KIDS)
3620                     && ($kid->first->flags & OPf_KIDS)
3621                     && $kid->first->first->name =~ /^pad[sah]v$/
3622                     && $kid->first->first->targ == $padop->targ;
3623
3624         $kid = $kid->sibling;
3625         my @attr;
3626         while ($$kid) {
3627             last if ($kid->type != OP_CONST);
3628             push @attr, $self->const_sv($kid)->PV;
3629             $kid = $kid->sibling;
3630         }
3631         return unless @attr;
3632         my $thisattr = ":" . join(' ', @attr);
3633         $attr_text //= $thisattr;
3634         # all import calls must have the same list of attributes
3635         return unless $attr_text eq $thisattr;
3636
3637         return unless $kid->name eq 'method_named';
3638         return unless $self->meth_sv($kid)->PV eq 'import';
3639
3640         $kid = $kid->sibling;
3641         return if $$kid;
3642     }
3643
3644     my $res = 'my';
3645     $res .= " $class " if $class ne 'main';
3646     $res .=
3647             (@varnames > 1)
3648             ? "(" . join(', ', @varnames) . ')'
3649             : " $varnames[0]";
3650
3651     return "$res $attr_text";
3652 }
3653
3654
3655 sub pp_list {
3656     my $self = shift;
3657     my($op, $cx) = @_;
3658
3659     {
3660         # might be my ($s,@a,%h) :Foo(bar);
3661         my $my_attr = maybe_my_attr($self, $op, $cx);
3662         return $my_attr if defined $my_attr;
3663     }
3664
3665     my($expr, @exprs);
3666     my $kid = $op->first->sibling; # skip pushmark
3667     return '' if class($kid) eq 'NULL';
3668     my $lop;
3669     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
3670     my $type;
3671     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
3672         my $lopname = $lop->name;
3673         my $loppriv = $lop->private;
3674         my $newtype;
3675         if ($lopname =~ /^pad[ash]v$/ && $loppriv & OPpLVAL_INTRO) {
3676             if ($loppriv & OPpPAD_STATE) { # state()
3677                 ($local = "", last) if $local !~ /^(?:either|state)$/;
3678                 $local = "state";
3679             } else { # my()
3680                 ($local = "", last) if $local !~ /^(?:either|my)$/;
3681                 $local = "my";
3682             }
3683             my $padname = $self->padname_sv($lop->targ);
3684             if ($padname->FLAGS & SVpad_TYPED) {
3685                 $newtype = $padname->SvSTASH->NAME;
3686             }
3687         } elsif ($lopname =~ /^(?:gv|rv2)([ash])v$/
3688                         && $loppriv & OPpOUR_INTRO
3689                 or $lopname eq "null" && class($lop) eq 'UNOP'
3690                         && $lop->first->name eq "gvsv"
3691                         && $lop->first->private & OPpOUR_INTRO) { # our()
3692             my $newlocal = "local " x !!($loppriv & OPpLVAL_INTRO) . "our";
3693             ($local = "", last)
3694                 if $local ne 'either' && $local ne $newlocal;
3695             $local = $newlocal;
3696             my $funny = !$1 || $1 eq 's' ? '$' : $1 eq 'a' ? '@' : '%';
3697             if (my $t = $self->find_our_type(
3698                     $funny . $self->gv_or_padgv($lop->first)->NAME
3699                )) {
3700                 $newtype = $t;
3701             }
3702         } elsif ($lopname ne 'undef'
3703            and    !($loppriv & OPpLVAL_INTRO)
3704                || !exists $uses_intro{$lopname eq 'null'
3705                                         ? substr B::ppname($lop->targ), 3
3706                                         : $lopname})
3707         {
3708             $local = ""; # or not
3709             last;
3710         } elsif ($lopname ne "undef")
3711         {
3712             # local()
3713             ($local = "", last) if $local !~ /^(?:either|local)$/;
3714             $local = "local";
3715         }
3716         if (defined $type && defined $newtype && $newtype ne $type) {
3717             $local = '';
3718             last;
3719         }
3720         $type = $newtype;
3721     }
3722     $local = "" if $local eq "either"; # no point if it's all undefs
3723     $local &&= join ' ', map $self->keyword($_), split / /, $local;
3724     $local .= " $type " if $local && length $type;
3725     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
3726     for (; !null($kid); $kid = $kid->sibling) {
3727         if ($local) {
3728             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
3729                 $lop = $kid->first;
3730             } else {
3731                 $lop = $kid;
3732             }
3733             $self->{'avoid_local'}{$$lop}++;
3734             $expr = $self->deparse($kid, 6);
3735             delete $self->{'avoid_local'}{$$lop};
3736         } else {
3737             $expr = $self->deparse($kid, 6);
3738         }
3739         push @exprs, $expr;
3740     }
3741     if ($local) {
3742         return "$local(" . join(", ", @exprs) . ")";
3743     } else {
3744         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
3745     }
3746 }
3747
3748 sub is_ifelse_cont {
3749     my $op = shift;
3750     return ($op->name eq "null" and class($op) eq "UNOP"
3751             and $op->first->name =~ /^(and|cond_expr)$/
3752             and is_scope($op->first->first->sibling));
3753 }
3754
3755 sub pp_cond_expr {
3756     my $self = shift;
3757     my($op, $cx) = @_;
3758     my $cond = $op->first;
3759     my $true = $cond->sibling;
3760     my $false = $true->sibling;
3761     my $cuddle = $self->{'cuddle'};
3762     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
3763             (is_scope($false) || is_ifelse_cont($false))
3764             and $self->{'expand'} < 7) {
3765         $cond = $self->deparse($cond, 8);
3766         $true = $self->deparse($true, 6);
3767         $false = $self->deparse($false, 8);
3768         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
3769     }
3770
3771     $cond = $self->deparse($cond, 1);
3772     $true = $self->deparse($true, 0);
3773     my $head = $self->keyword("if") . " ($cond) {\n\t$true\n\b}";
3774     my @elsifs;
3775     my $elsif;
3776     while (!null($false) and is_ifelse_cont($false)) {
3777         my $newop = $false->first;
3778         my $newcond = $newop->first;
3779         my $newtrue = $newcond->sibling;
3780         $false = $newtrue->sibling; # last in chain is OP_AND => no else
3781         if ($newcond->name eq "lineseq")
3782         {
3783             # lineseq to ensure correct line numbers in elsif()
3784             # Bug #37302 fixed by change #33710.
3785             $newcond = $newcond->first->sibling;
3786         }
3787         $newcond = $self->deparse($newcond, 1);
3788         $newtrue = $self->deparse($newtrue, 0);
3789         $elsif ||= $self->keyword("elsif");
3790         push @elsifs, "$elsif ($newcond) {\n\t$newtrue\n\b}";
3791     }
3792     if (!null($false)) {
3793         $false = $cuddle . $self->keyword("else") . " {\n\t" .
3794           $self->deparse($false, 0) . "\n\b}\cK";
3795     } else {
3796         $false = "\cK";
3797     }
3798     return $head . join($cuddle, "", @elsifs) . $false;
3799 }
3800
3801 sub pp_once {
3802     my ($self, $op, $cx) = @_;
3803     my $cond = $op->first;
3804     my $true = $cond->sibling;
3805
3806     my $ret = $self->deparse($true, $cx);
3807     $ret =~ s/^(\(?)\$/$1 . $self->keyword("state") . ' $'/e;
3808     $ret;
3809 }
3810
3811 sub loop_common {
3812     my $self = shift;
3813     my($op, $cx, $init) = @_;
3814     my $enter = $op->first;
3815     my $kid = $enter->sibling;
3816     local(@$self{qw'curstash warnings hints hinthash'})
3817                 = @$self{qw'curstash warnings hints hinthash'};
3818     my $head = "";
3819     my $bare = 0;
3820     my $body;
3821     my $cond = undef;
3822     my $name;
3823     if ($kid->name eq "lineseq") { # bare or infinite loop
3824         if ($kid->last->name eq "unstack") { # infinite
3825             $head = "while (1) "; # Can't use for(;;) if there's a continue
3826             $cond = "";
3827         } else {
3828             $bare = 1;
3829         }
3830         $body = $kid;
3831     } elsif ($enter->name eq "enteriter") { # foreach
3832         my $ary = $enter->first->sibling; # first was pushmark
3833         my $var = $ary->sibling;
3834         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
3835             # "reverse" was optimised away
3836             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
3837         } elsif ($enter->flags & OPf_STACKED
3838             and not null $ary->first->sibling->sibling)
3839         {
3840             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
3841               $self->deparse($ary->first->sibling->sibling, 9);
3842         } else {
3843             $ary = $self->deparse($ary, 1);
3844         }
3845         if (null $var) {
3846             $var = $self->pp_padsv($enter, 1, 1);
3847         } elsif ($var->name eq "rv2gv") {
3848             $var = $self->pp_rv2sv($var, 1);
3849             if ($enter->private & OPpOUR_INTRO) {
3850                 # our declarations don't have package names
3851                 $var =~ s/^(.).*::/$1/;
3852                 $var = "our $var";
3853             }
3854         } elsif ($var->name eq "gv") {
3855             $var = "\$" . $self->deparse($var, 1);
3856         } else {
3857             $var = $self->deparse($var, 1);
3858         }
3859         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
3860         if (!is_state $body->first and $body->first->name !~ /^(?:stub|leave|scope)$/) {
3861             confess unless $var eq '$_';
3862             $body = $body->first;
3863             return $self->deparse($body, 2) . " "
3864                  . $self->keyword("foreach") . " ($ary)";
3865         }
3866         $head = "foreach $var ($ary) ";
3867     } elsif ($kid->name eq "null") { # while/until
3868         $kid = $kid->first;
3869         $name = {"and" => "while", "or" => "until"}->{$kid->name};
3870         $cond = $kid->first;
3871         $body = $kid->first->sibling;
3872     } elsif ($kid->name eq "stub") { # bare and empty
3873         return "{;}"; # {} could be a hashref
3874     }
3875     # If there isn't a continue block, then the next pointer for the loop
3876     # will point to the unstack, which is kid's last child, except
3877     # in a bare loop, when it will point to the leaveloop. When neither of
3878     # these conditions hold, then the second-to-last child is the continue
3879     # block (or the last in a bare loop).
3880     my $cont_start = $enter->nextop;
3881     my $cont;
3882     my $precond;
3883     my $postcond;
3884     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
3885         if ($bare) {
3886             $cont = $body->last;
3887         } else {
3888             $cont = $body->first;
3889             while (!null($cont->sibling->sibling)) {
3890                 $cont = $cont->sibling;
3891             }
3892         }
3893         my $state = $body->first;
3894         my $cuddle = $self->{'cuddle'};
3895         my @states;
3896         for (; $$state != $$cont; $state = $state->sibling) {
3897             push @states, $state;
3898         }
3899         $body = $self->lineseq(undef, 0, @states);
3900         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
3901             $precond = "for ($init; ";
3902             $postcond = "; " . $self->deparse($cont, 1) .") ";
3903             $cont = "\cK";
3904         } else {
3905             $cont = $cuddle . "continue {\n\t" .
3906               $self->deparse($cont, 0) . "\n\b}\cK";
3907         }
3908     } else {
3909         return "" if !defined $body;
3910         if (length $init) {
3911             $precond = "for ($init; ";
3912             $postcond = ";) ";
3913         }
3914         $cont = "\cK";
3915         $body = $self->deparse($body, 0);
3916     }
3917     if ($precond) { # for(;;)
3918         $cond &&= $name eq 'until'
3919                     ? listop($self, undef, 1, "not", $cond->first)
3920                     : $self->deparse($cond, 1);
3921         $head = "$precond$cond$postcond";
3922     }
3923     if ($name && !$head) {
3924         ref $cond and $cond = $self->deparse($cond, 1);
3925         $head = "$name ($cond) ";
3926     }
3927     $head =~ s/^(for(?:each)?|while|until)/$self->keyword($1)/e;
3928     $body =~ s/;?$/;\n/;
3929
3930     return $head . "{\n\t" . $body . "\b}" . $cont;
3931 }
3932
3933 sub pp_leaveloop { shift->loop_common(@_, "") }
3934
3935 sub for_loop {
3936     my $self = shift;
3937     my($op, $cx) = @_;
3938     my $init = $self->deparse($op, 1);
3939     my $s = $op->sibling;
3940     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
3941     return $self->loop_common($ll, $cx, $init);
3942 }
3943
3944 sub pp_leavetry {
3945     my $self = shift;
3946     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
3947 }
3948
3949 sub _op_is_or_was {
3950   my ($op, $expect_type) = @_;
3951   my $type = $op->type;
3952   return($type == $expect_type
3953          || ($type == OP_NULL && $op->targ == $expect_type));
3954 }
3955
3956 sub pp_null {
3957     my($self, $op, $cx) = @_;
3958
3959     # might be 'my $s :Foo(bar);'
3960     if ($op->targ == OP_LIST) {
3961         my $my_attr = maybe_my_attr($self, $op, $cx);
3962         return $my_attr if defined $my_attr;
3963     }
3964
3965     if (class($op) eq "OP") {
3966         # old value is lost
3967         return $self->{'ex_const'} if $op->targ == OP_CONST;
3968     } elsif (class ($op) eq "COP") {
3969             return &pp_nextstate;
3970     } elsif ($op->first->name eq 'pushmark'
3971              or $op->first->name eq 'null'
3972                 && $op->first->targ == OP_PUSHMARK
3973                 && _op_is_or_was($op, OP_LIST)) {
3974         return $self->pp_list($op, $cx);
3975     } elsif ($op->first->name eq "enter") {
3976         return $self->pp_leave($op, $cx);
3977     } elsif ($op->first->name eq "leave") {
3978         return $self->pp_leave($op->first, $cx);
3979     } elsif ($op->first->name eq "scope") {
3980         return $self->pp_scope($op->first, $cx);
3981     } elsif ($op->targ == OP_STRINGIFY) {
3982         return $self->dquote($op, $cx);
3983     } elsif ($op->targ == OP_GLOB) {
3984         return $self->pp_glob(
3985                  $op->first    # entersub
3986                     ->first    # ex-list
3987                     ->first    # pushmark
3988                     ->sibling, # glob
3989                  $cx
3990                );
3991     } elsif (!null($op->first->sibling) and
3992              $op->first->sibling->name eq "readline" and
3993              $op->first->sibling->flags & OPf_STACKED) {
3994         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
3995                                    . $self->deparse($op->first->sibling, 7),
3996                                    $cx, 7);
3997     } elsif (!null($op->first->sibling) and
3998              $op->first->sibling->name =~ /^transr?\z/ and
3999              $op->first->sibling->flags & OPf_STACKED) {
4000         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
4001                                    . $self->deparse($op->first->sibling, 20),
4002                                    $cx, 20);
4003     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
4004         return ($self->lex_in_scope("&do") ? "CORE::do" : "do")
4005              . " {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
4006     } elsif (!null($op->first->sibling) and
4007              $op->first->sibling->name eq "null" and
4008              class($op->first->sibling) eq "UNOP" and
4009              $op->first->sibling->first->flags & OPf_STACKED and
4010              $op->first->sibling->first->name eq "rcatline") {
4011         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
4012                                    . $self->deparse($op->first->sibling, 18),
4013                                    $cx, 18);
4014     } else {
4015         return $self->deparse($op->first, $cx);
4016     }
4017 }
4018
4019 sub padname {
4020     my $self = shift;
4021     my $targ = shift;
4022     return $self->padname_sv($targ)->PVX;
4023 }
4024
4025 sub padany {
4026     my $self = shift;
4027     my $op = shift;
4028     return substr($self->padname($op->targ), 1); # skip $/@/%
4029 }
4030
4031 sub pp_padsv {
4032     my $self = shift;
4033     my($op, $cx, $forbid_parens) = @_;
4034     my $targ = $op->targ;
4035     return $self->maybe_my($op, $cx, $self->padname($targ),
4036                            $self->padname_sv($targ),
4037                            $forbid_parens);
4038 }
4039
4040 sub pp_padav { pp_padsv(@_) }
4041
4042 # prepend 'keys' where its been optimised away, with suitable handling
4043 # of CORE:: and parens
4044
4045 sub add_keys_keyword {
4046     my ($self, $str, $cx) = @_;
4047     $str = $self->maybe_parens($str, $cx, 16);
4048     # 'keys %h' versus 'keys(%h)'
4049     $str = " $str" unless $str =~ /^\(/;
4050     return $self->keyword("keys") . $str;
4051 }
4052
4053 sub pp_padhv {
4054     my ($self, $op, $cx) = @_;
4055     my $str =  pp_padsv(@_);
4056     # with OPpPADHV_ISKEYS the keys op is optimised away, except
4057     # in scalar context the old op is kept (but not executed) so its targ
4058     # can be used.
4059     if (     ($op->private & OPpPADHV_ISKEYS)
4060         && !(($op->flags & OPf_WANT) == OPf_WANT_SCALAR))
4061     {
4062         $str = $self->add_keys_keyword($str, $cx);
4063     }
4064     $str;
4065 }
4066
4067 sub gv_or_padgv {
4068     my $self = shift;
4069     my $op = shift;
4070     if (class($op) eq "PADOP") {
4071         return $self->padval($op->padix);
4072     } else { # class($op) eq "SVOP"
4073         return $op->gv;
4074     }
4075 }
4076
4077 sub pp_gvsv {
4078     my $self = shift;
4079     my($op, $cx) = @_;
4080     my $gv = $self->gv_or_padgv($op);
4081     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
4082                                  $self->gv_name($gv), $cx));
4083 }
4084
4085 sub pp_gv {
4086     my $self = shift;
4087     my($op, $cx) = @_;
4088     my $gv = $self->gv_or_padgv($op);
4089     return $self->maybe_qualify("", $self->gv_name($gv));
4090 }
4091
4092 sub pp_aelemfast_lex {
4093     my $self = shift;
4094     my($op, $cx) = @_;
4095     my $name = $self->padname($op->targ);
4096     $name =~ s/^@/\$/;
4097     my $i = $op->private;
4098     $i -= 256 if $i > 127;
4099     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
4100 }
4101
4102 sub pp_aelemfast {
4103     my $self = shift;
4104     my($op, $cx) = @_;
4105     # optimised PADAV, pre 5.15
4106     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
4107
4108     my $gv = $self->gv_or_padgv($op);
4109     my($name,$quoted) = $self->stash_variable_name('@',$gv);
4110     $name = $quoted ? "$name->" : '$' . $name;
4111     my $i = $op->private;
4112     $i -= 256 if $i > 127;
4113     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
4114 }
4115
4116 sub rv2x {
4117     my $self = shift;
4118     my($op, $cx, $type) = @_;
4119
4120     if (class($op) eq 'NULL' || !$op->can("first")) {
4121         carp("Unexpected op in pp_rv2x");
4122         return 'XXX';
4123     }
4124     my $kid = $op->first;
4125     if ($kid->name eq "gv") {
4126         return $self->stash_variable($type,
4127                     $self->gv_name($self->gv_or_padgv($kid)), $cx);
4128     } elsif (is_scalar $kid) {
4129         my $str = $self->deparse($kid, 0);
4130         if ($str =~ /^\$([^\w\d])\z/) {
4131             # "$$+" isn't a legal way to write the scalar dereference
4132             # of $+, since the lexer can't tell you aren't trying to
4133             # do something like "$$ + 1" to get one more than your
4134             # PID. Either "${$+}" or "$${+}" are workable
4135             # disambiguations, but if the programmer did the former,
4136             # they'd be in the "else" clause below rather than here.
4137             # It's not clear if this should somehow be unified with
4138             # the code in dq and re_dq that also adds lexer
4139             # disambiguation braces.
4140             $str = '$' . "{$1}"; #'
4141         }
4142         return $type . $str;
4143     } else {
4144         return $type . "{" . $self->deparse($kid, 0) . "}";
4145     }
4146 }
4147
4148 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
4149 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
4150
4151 sub pp_rv2hv {
4152     my ($self, $op, $cx) = @_;
4153     my $str = rv2x(@_, "%");
4154     if ($op->private & OPpRV2HV_ISKEYS) {
4155         $str = $self->add_keys_keyword($str, $cx);
4156     }
4157     return maybe_local(@_, $str);
4158 }
4159
4160 # skip rv2av
4161 sub pp_av2arylen {
4162     my $self = shift;
4163     my($op, $cx) = @_;
4164     if ($op->first->name eq "padav") {
4165         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
4166     } else {
4167         return $self->maybe_local($op, $cx,
4168                                   $self->rv2x($op->first, $cx, '$#'));
4169     }
4170 }
4171
4172 # skip down to the old, ex-rv2cv
4173 sub pp_rv2cv {
4174     my ($self, $op, $cx) = @_;
4175     if (!null($op->first) && $op->first->name eq 'null' &&
4176         $op->first->targ == OP_LIST)
4177     {
4178         return $self->rv2x($op->first->first->sibling, $cx, "&")
4179     }
4180     else {
4181         return $self->rv2x($op, $cx, "")
4182     }
4183 }
4184
4185 sub list_const {
4186     my $self = shift;
4187     my($cx, @list) = @_;
4188     my @a = map $self->const($_, 6), @list;
4189     if (@a == 0) {
4190         return "()";
4191     } elsif (@a == 1) {
4192         return $a[0];
4193     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
4194         # collapse (-1,0,1,2) into (-1..2)
4195         my ($s, $e) = @a[0,-1];
4196         my $i = $s;
4197         return $self->maybe_parens("$s..$e", $cx, 9)
4198           unless grep $i++ != $_, @a;
4199     }
4200     return $self->maybe_parens(join(", ", @a), $cx, 6);
4201 }
4202
4203 sub pp_rv2av {
4204     my $self = shift;
4205     my($op, $cx) = @_;
4206     my $kid = $op->first;
4207     if ($kid->name eq "const") { # constant list
4208         my $av = $self->const_sv($kid);
4209         return $self->list_const($cx, $av->ARRAY);
4210     } else {
4211         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
4212     }
4213  }
4214
4215 sub is_subscriptable {
4216     my $op = shift;
4217     if ($op->name =~ /^([ahg]elem|multideref$)/) {
4218         return 1;
4219     } elsif ($op->name eq "entersub") {
4220         my $kid = $op->first;
4221         return 0 unless null $kid->sibling;
4222         $kid = $kid->first;
4223         $kid = $kid->sibling until null $kid->sibling;
4224         return 0 if is_scope($kid);
4225         $kid = $kid->first;
4226         return 0 if $kid->name eq "gv" || $kid->name eq "padcv";
4227         return 0 if is_scalar($kid);
4228         return is_subscriptable($kid);  
4229     } else {
4230         return 0;
4231     }
4232 }
4233
4234 sub elem_or_slice_array_name
4235 {
4236     my $self = shift;
4237     my ($array, $left, $padname, $allow_arrow) = @_;
4238
4239     if ($array->name eq $padname) {
4240         return $self->padany($array);
4241     } elsif (is_scope($array)) { # ${expr}[0]
4242         return "{" . $self->deparse($array, 0) . "}";
4243     } elsif ($array->name eq "gv") {
4244         ($array, my $quoted) =
4245             $self->stash_variable_name(
4246                 $left eq '[' ? '@' : '%', $self->gv_or_padgv($array)
4247             );
4248         if (!$allow_arrow && $quoted) {
4249             # This cannot happen.
4250             die "Invalid variable name $array for slice";
4251         }
4252         return $quoted ? "$array->" : $array;
4253     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
4254         return $self->deparse($array, 24);
4255     } else {
4256         return undef;
4257     }
4258 }
4259
4260 sub elem_or_slice_single_index
4261 {
4262     my $self = shift;
4263     my ($idx) = @_;
4264
4265     $idx = $self->deparse($idx, 1);
4266
4267     # Outer parens in an array index will confuse perl
4268     # if we're interpolating in a regular expression, i.e.
4269     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
4270     #
4271     # If $self->{parens}, then an initial '(' will
4272     # definitely be paired with a final ')'. If
4273     # !$self->{parens}, the misleading parens won't
4274     # have been added in the first place.
4275     #
4276     # [You might think that we could get "(...)...(...)"
4277     # where the initial and final parens do not match
4278     # each other. But we can't, because the above would
4279     # only happen if there's an infix binop between the
4280     # two pairs of parens, and *that* means that the whole
4281     # expression would be parenthesized as well.]
4282     #
4283     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
4284
4285     # Hash-element braces will autoquote a bareword inside themselves.
4286     # We need to make sure that C<$hash{warn()}> doesn't come out as
4287     # C<$hash{warn}>, which has a quite different meaning. Currently
4288     # B::Deparse will always quote strings, even if the string was a
4289     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
4290     # for constant strings.) So we can cheat slightly here - if we see
4291     # a bareword, we know that it is supposed to be a function call.
4292     #
4293     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
4294
4295     return $idx;
4296 }
4297
4298 sub elem {
4299     my $self = shift;
4300     my ($op, $cx, $left, $right, $padname) = @_;
4301     my($array, $idx) = ($op->first, $op->first->sibling);
4302
4303     $idx = $self->elem_or_slice_single_index($idx);
4304
4305     unless ($array->name eq $padname) { # Maybe this has been fixed     
4306         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
4307     }
4308     if (my $array_name=$self->elem_or_slice_array_name
4309             ($array, $left, $padname, 1)) {
4310         return ($array_name =~ /->\z/
4311                     ? $array_name
4312                     : $array_name eq '#' ? '${#}' : "\$" . $array_name)
4313               . $left . $idx . $right;
4314     } else {
4315         # $x[20][3]{hi} or expr->[20]
4316         my $arrow = is_subscriptable($array) ? "" : "->";
4317         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
4318     }
4319
4320 }
4321
4322 # a simplified version of elem_or_slice_array_name()
4323 # for the use of pp_multideref
4324
4325 sub multideref_var_name {
4326     my $self = shift;
4327     my ($gv, $is_hash) = @_;
4328
4329     my ($name, $quoted) =
4330         $self->stash_variable_name( $is_hash  ? '%' : '@', $gv);
4331     return $quoted ? "$name->"
4332                    : $name eq '#'
4333                         ? '${#}'       # avoid ${#}[1] => $#[1]
4334                         : '$' . $name;
4335 }
4336
4337
4338 # deparse an OP_MULTICONCAT. If $in_dq is 1, we're within
4339 # a double-quoted string, so for example.
4340 #     "abc\Qdef$x\Ebar"
4341 # might get compiled as
4342 #    multiconcat("abc", metaquote(multiconcat("def", $x)), "bar")
4343 # and the inner multiconcat should be deparsed as C<def$x> rather than
4344 # the normal C<def . $x>
4345 # Ditto if  $in_dq is 2, handle qr/...\Qdef$x\E.../.
4346
4347 sub do_multiconcat {
4348     my $self = shift;
4349     my($op, $cx, $in_dq) = @_;
4350
4351     my $kid;
4352     my @kids;
4353     my $assign;
4354     my $append;
4355     my $lhs = "";
4356
4357     for ($kid = $op->first; !null $kid; $kid = $kid->sibling) {
4358         # skip the consts and/or padsv we've optimised away
4359         push @kids, $kid
4360             unless $kid->type == OP_NULL
4361               && (   $kid->targ == OP_PADSV
4362                   || $kid->targ == OP_CONST
4363                   || $kid->targ == OP_PUSHMARK);
4364     }
4365
4366     $append = ($op->private & OPpMULTICONCAT_APPEND);
4367
4368     if ($op->private & OPpTARGET_MY) {
4369         # '$lex  = ...' or '$lex .= ....' or 'my $lex = '
4370         $lhs = $self->padname($op->targ);
4371         $lhs = "my $lhs" if ($op->private & OPpLVAL_INTRO);
4372         $assign = 1;
4373     }
4374     elsif ($op->flags & OPf_STACKED) {
4375         # 'expr  = ...' or 'expr .= ....'
4376         my $expr = $append ? shift(@kids) : pop(@kids);
4377         $lhs = $self->deparse($expr, 7);
4378         $assign = 1;
4379     }
4380
4381     if ($assign) {
4382         $lhs .=  $append ? ' .= ' : ' = ';
4383     }
4384
4385     my ($nargs, $const_str, @const_lens) = $op->aux_list($self->{curcv});
4386
4387     my @consts;
4388     my $i = 0;
4389     for (@const_lens) {
4390         if ($_ == -1) {
4391             push @consts, undef;
4392         }
4393         else {
4394             push @consts, substr($const_str, $i, $_);
4395         my @args;
4396             $i += $_;
4397         }
4398     }
4399
4400     my $rhs = "";
4401
4402     if (   $in_dq
4403         || (($op->private & OPpMULTICONCAT_STRINGIFY) && !$self->{'unquote'}))
4404     {
4405         # "foo=$foo bar=$bar "
4406         my $not_first;
4407         while (@consts) {
4408             $rhs = dq_disambiguate($rhs, $self->dq(shift(@kids), 18))
4409                 if $not_first;
4410             $not_first = 1;
4411             my $c = shift @consts;
4412             if (defined $c) {
4413                 if ($in_dq == 2) {
4414                     # in pattern: don't convert newline to '\n' etc etc
4415                     my $s = re_uninterp(escape_re(re_unback($c)));
4416                     $rhs = re_dq_disambiguate($rhs, $s)
4417                 }
4418                 else {
4419                     my $s = uninterp(escape_str(unback($c)));
4420                     $rhs = dq_disambiguate($rhs, $s)
4421                 }
4422             }
4423         }
4424         return $rhs if $in_dq;
4425         $rhs = single_delim("qq", '"', $rhs, $self);
4426     }
4427     elsif ($op->private & OPpMULTICONCAT_FAKE) {
4428         # sprintf("foo=%s bar=%s ", $foo, $bar)
4429
4430         my @all;
4431         @consts = map { $_ //= ''; s/%/%%/g; $_ } @consts;
4432         my $fmt = join '%s', @consts;
4433         push @all, $self->quoted_const_str($fmt);
4434
4435         # the following is a stripped down copy of sub listop {}
4436         my $parens = $assign || ($cx >= 5) || $self->{'parens'};
4437         my $fullname = $self->keyword('sprintf');
4438         push @all, map $self->deparse($_, 6), @kids;
4439
4440         $rhs = $parens
4441                 ? "$fullname(" . join(", ", @all) . ")"
4442                 : "$fullname " . join(", ", @all);
4443     }
4444     else {
4445         # "foo=" . $foo . " bar=" . $bar
4446         my @all;
4447         my $not_first;
4448         while (@consts) {
4449             push @all, $self->deparse(shift(@kids), 18) if $not_first;
4450             $not_first = 1;
4451             my $c = shift @consts;
4452             if (defined $c) {
4453                 push @all, $self->quoted_const_str($c);
4454             }
4455         }
4456         $rhs .= join ' . ', @all;
4457     }
4458
4459     my $text = $lhs . $rhs;
4460
4461     $text = "($text)" if     ($cx >= (($assign) ? 7 : 18+1))
4462                           || $self->{'parens'};
4463
4464     return $text;
4465 }
4466
4467
4468 sub pp_multiconcat {
4469     my $self = shift;
4470     $self->do_multiconcat(@_, 0);
4471 }
4472
4473
4474 sub pp_multideref {
4475     my $self = shift;
4476     my($op, $cx) = @_;
4477     my $text = "";
4478
4479     if ($op->private & OPpMULTIDEREF_EXISTS) {
4480         $text = $self->keyword("exists"). " ";
4481     }
4482     elsif ($op->private & OPpMULTIDEREF_DELETE) {
4483         $text = $self->keyword("delete"). " ";