This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
7d1a90bb9f5010881f41f3518a6fa2bddd01db1e
[perl5.git] / t / test.pl
1 #
2 # t/test.pl - most of Test::More functionality without the fuss
3
4
5 # NOTE:
6 #
7 # Increment ($x++) has a certain amount of cleverness for things like
8 #
9 #   $x = 'zz';
10 #   $x++; # $x eq 'aaa';
11 #
12 # stands more chance of breaking than just a simple
13 #
14 #   $x = $x + 1
15 #
16 # In this file, we use the latter "Baby Perl" approach, and increment
17 # will be worked over by t/op/inc.t
18
19 $Level = 1;
20 my $test = 1;
21 my $planned;
22 my $noplan;
23 my $Perl;       # Safer version of $^X set by which_perl()
24
25 $TODO = 0;
26 $NO_ENDING = 0;
27
28 # Use this instead of print to avoid interference while testing globals.
29 sub _print {
30     local($\, $", $,) = (undef, ' ', '');
31     print STDOUT @_;
32 }
33
34 sub _print_stderr {
35     local($\, $", $,) = (undef, ' ', '');
36     print STDERR @_;
37 }
38
39 sub plan {
40     my $n;
41     if (@_ == 1) {
42         $n = shift;
43         if ($n eq 'no_plan') {
44           undef $n;
45           $noplan = 1;
46         }
47     } else {
48         my %plan = @_;
49         $n = $plan{tests};
50     }
51     _print "1..$n\n" unless $noplan;
52     $planned = $n;
53 }
54
55 END {
56     my $ran = $test - 1;
57     if (!$NO_ENDING) {
58         if (defined $planned && $planned != $ran) {
59             _print_stderr
60                 "# Looks like you planned $planned tests but ran $ran.\n";
61         } elsif ($noplan) {
62             _print "1..$ran\n";
63         }
64     }
65 }
66
67 # Use this instead of "print STDERR" when outputing failure diagnostic
68 # messages
69 sub _diag {
70     return unless @_;
71     my @mess = map { /^#/ ? "$_\n" : "# $_\n" }
72                map { split /\n/ } @_;
73     $TODO ? _print(@mess) : _print_stderr(@mess);
74 }
75
76 sub diag {
77     _diag(@_);
78 }
79
80 sub skip_all {
81     if (@_) {
82         _print "1..0 # Skip @_\n";
83     } else {
84         _print "1..0\n";
85     }
86     exit(0);
87 }
88
89 sub _ok {
90     my ($pass, $where, $name, @mess) = @_;
91     # Do not try to microoptimize by factoring out the "not ".
92     # VMS will avenge.
93     my $out;
94     if ($name) {
95         # escape out '#' or it will interfere with '# skip' and such
96         $name =~ s/#/\\#/g;
97         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
98     } else {
99         $out = $pass ? "ok $test" : "not ok $test";
100     }
101
102     $out = $out . " # TODO $TODO" if $TODO;
103     _print "$out\n";
104
105     unless ($pass) {
106         _diag "# Failed $where\n";
107     }
108
109     # Ensure that the message is properly escaped.
110     _diag @mess;
111
112     $test = $test + 1; # don't use ++
113
114     return $pass;
115 }
116
117 sub _where {
118     my @caller = caller($Level);
119     return "at $caller[1] line $caller[2]";
120 }
121
122 # DON'T use this for matches. Use like() instead.
123 sub ok ($@) {
124     my ($pass, $name, @mess) = @_;
125     _ok($pass, _where(), $name, @mess);
126 }
127
128 sub _q {
129     my $x = shift;
130     return 'undef' unless defined $x;
131     my $q = $x;
132     $q =~ s/\\/\\\\/g;
133     $q =~ s/'/\\'/g;
134     return "'$q'";
135 }
136
137 sub _qq {
138     my $x = shift;
139     return defined $x ? '"' . display ($x) . '"' : 'undef';
140 };
141
142 # keys are the codes \n etc map to, values are 2 char strings such as \n
143 my %backslash_escape;
144 foreach my $x (split //, 'nrtfa\\\'"') {
145     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
146 }
147 # A way to display scalars containing control characters and Unicode.
148 # Trying to avoid setting $_, or relying on local $_ to work.
149 sub display {
150     my @result;
151     foreach my $x (@_) {
152         if (defined $x and not ref $x) {
153             my $y = '';
154             foreach my $c (unpack("U*", $x)) {
155                 if ($c > 255) {
156                     $y = $y . sprintf "\\x{%x}", $c;
157                 } elsif ($backslash_escape{$c}) {
158                     $y = $y . $backslash_escape{$c};
159                 } else {
160                     my $z = chr $c; # Maybe we can get away with a literal...
161                     $z = sprintf "\\%03o", $c if $z =~ /[[:^print:]]/;
162                     $y = $y . $z;
163                 }
164             }
165             $x = $y;
166         }
167         return $x unless wantarray;
168         push @result, $x;
169     }
170     return @result;
171 }
172
173 sub is ($$@) {
174     my ($got, $expected, $name, @mess) = @_;
175
176     my $pass;
177     if( !defined $got || !defined $expected ) {
178         # undef only matches undef
179         $pass = !defined $got && !defined $expected;
180     }
181     else {
182         $pass = $got eq $expected;
183     }
184
185     unless ($pass) {
186         unshift(@mess, "#      got "._qq($got)."\n",
187                        "# expected "._qq($expected)."\n");
188     }
189     _ok($pass, _where(), $name, @mess);
190 }
191
192 sub isnt ($$@) {
193     my ($got, $isnt, $name, @mess) = @_;
194
195     my $pass;
196     if( !defined $got || !defined $isnt ) {
197         # undef only matches undef
198         $pass = defined $got || defined $isnt;
199     }
200     else {
201         $pass = $got ne $isnt;
202     }
203
204     unless( $pass ) {
205         unshift(@mess, "# it should not be "._qq($got)."\n",
206                        "# but it is.\n");
207     }
208     _ok($pass, _where(), $name, @mess);
209 }
210
211 sub cmp_ok ($$$@) {
212     my($got, $type, $expected, $name, @mess) = @_;
213
214     my $pass;
215     {
216         local $^W = 0;
217         local($@,$!);   # don't interfere with $@
218                         # eval() sometimes resets $!
219         $pass = eval "\$got $type \$expected";
220     }
221     unless ($pass) {
222         # It seems Irix long doubles can have 2147483648 and 2147483648
223         # that stringify to the same thing but are acutally numerically
224         # different. Display the numbers if $type isn't a string operator,
225         # and the numbers are stringwise the same.
226         # (all string operators have alphabetic names, so tr/a-z// is true)
227         # This will also show numbers for some uneeded cases, but will
228         # definately be helpful for things such as == and <= that fail
229         if ($got eq $expected and $type !~ tr/a-z//) {
230             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
231         }
232         unshift(@mess, "#      got "._qq($got)."\n",
233                        "# expected $type "._qq($expected)."\n");
234     }
235     _ok($pass, _where(), $name, @mess);
236 }
237
238 # Check that $got is within $range of $expected
239 # if $range is 0, then check it's exact
240 # else if $expected is 0, then $range is an absolute value
241 # otherwise $range is a fractional error.
242 # Here $range must be numeric, >= 0
243 # Non numeric ranges might be a useful future extension. (eg %)
244 sub within ($$$@) {
245     my ($got, $expected, $range, $name, @mess) = @_;
246     my $pass;
247     if (!defined $got or !defined $expected or !defined $range) {
248         # This is a fail, but doesn't need extra diagnostics
249     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
250         # This is a fail
251         unshift @mess, "# got, expected and range must be numeric\n";
252     } elsif ($range < 0) {
253         # This is also a fail
254         unshift @mess, "# range must not be negative\n";
255     } elsif ($range == 0) {
256         # Within 0 is ==
257         $pass = $got == $expected;
258     } elsif ($expected == 0) {
259         # If expected is 0, treat range as absolute
260         $pass = ($got <= $range) && ($got >= - $range);
261     } else {
262         my $diff = $got - $expected;
263         $pass = abs ($diff / $expected) < $range;
264     }
265     unless ($pass) {
266         if ($got eq $expected) {
267             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
268         }
269         unshift@mess, "#      got "._qq($got)."\n",
270                       "# expected "._qq($expected)." (within "._qq($range).")\n";
271     }
272     _ok($pass, _where(), $name, @mess);
273 }
274
275 # Note: this isn't quite as fancy as Test::More::like().
276
277 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
278 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
279
280 sub like_yn ($$$@) {
281     my ($flip, $got, $expected, $name, @mess) = @_;
282     my $pass;
283     $pass = $got =~ /$expected/ if !$flip;
284     $pass = $got !~ /$expected/ if $flip;
285     unless ($pass) {
286         unshift(@mess, "#      got '$got'\n",
287                 $flip
288                 ? "# expected !~ /$expected/\n" : "# expected /$expected/\n");
289     }
290     local $Level = $Level + 1;
291     _ok($pass, _where(), $name, @mess);
292 }
293
294 sub pass {
295     _ok(1, '', @_);
296 }
297
298 sub fail {
299     _ok(0, _where(), @_);
300 }
301
302 sub curr_test {
303     $test = shift if @_;
304     return $test;
305 }
306
307 sub next_test {
308   my $retval = $test;
309   $test = $test + 1; # don't use ++
310   $retval;
311 }
312
313 # Note: can't pass multipart messages since we try to
314 # be compatible with Test::More::skip().
315 sub skip {
316     my $why = shift;
317     my $n    = @_ ? shift : 1;
318     for (1..$n) {
319         _print "ok $test # skip $why\n";
320         $test = $test + 1;
321     }
322     local $^W = 0;
323     last SKIP;
324 }
325
326 sub todo_skip {
327     my $why = shift;
328     my $n   = @_ ? shift : 1;
329
330     for (1..$n) {
331         _print "not ok $test # TODO & SKIP $why\n";
332         $test = $test + 1;
333     }
334     local $^W = 0;
335     last TODO;
336 }
337
338 sub eq_array {
339     my ($ra, $rb) = @_;
340     return 0 unless $#$ra == $#$rb;
341     for my $i (0..$#$ra) {
342         next     if !defined $ra->[$i] && !defined $rb->[$i];
343         return 0 if !defined $ra->[$i];
344         return 0 if !defined $rb->[$i];
345         return 0 unless $ra->[$i] eq $rb->[$i];
346     }
347     return 1;
348 }
349
350 sub eq_hash {
351   my ($orig, $suspect) = @_;
352   my $fail;
353   while (my ($key, $value) = each %$suspect) {
354     # Force a hash recompute if this perl's internals can cache the hash key.
355     $key = "" . $key;
356     if (exists $orig->{$key}) {
357       if ($orig->{$key} ne $value) {
358         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
359                      " now ", _qq($value), "\n";
360         $fail = 1;
361       }
362     } else {
363       _print "# key ", _qq($key), " is ", _qq($value),
364                    ", not in original.\n";
365       $fail = 1;
366     }
367   }
368   foreach (keys %$orig) {
369     # Force a hash recompute if this perl's internals can cache the hash key.
370     $_ = "" . $_;
371     next if (exists $suspect->{$_});
372     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
373     $fail = 1;
374   }
375   !$fail;
376 }
377
378 sub require_ok ($) {
379     my ($require) = @_;
380     eval <<REQUIRE_OK;
381 require $require;
382 REQUIRE_OK
383     _ok(!$@, _where(), "require $require");
384 }
385
386 sub use_ok ($) {
387     my ($use) = @_;
388     eval <<USE_OK;
389 use $use;
390 USE_OK
391     _ok(!$@, _where(), "use $use");
392 }
393
394 # runperl - Runs a separate perl interpreter.
395 # Arguments :
396 #   switches => [ command-line switches ]
397 #   nolib    => 1 # don't use -I../lib (included by default)
398 #   prog     => one-liner (avoid quotes)
399 #   progs    => [ multi-liner (avoid quotes) ]
400 #   progfile => perl script
401 #   stdin    => string to feed the stdin
402 #   stderr   => redirect stderr to stdout
403 #   args     => [ command-line arguments to the perl program ]
404 #   verbose  => print the command line
405
406 my $is_mswin    = $^O eq 'MSWin32';
407 my $is_netware  = $^O eq 'NetWare';
408 my $is_vms      = $^O eq 'VMS';
409 my $is_cygwin   = $^O eq 'cygwin';
410
411 sub _quote_args {
412     my ($runperl, $args) = @_;
413
414     foreach (@$args) {
415         # In VMS protect with doublequotes because otherwise
416         # DCL will lowercase -- unless already doublequoted.
417        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
418        $runperl = $runperl . ' ' . $_;
419     }
420     return $runperl;
421 }
422
423 sub _create_runperl { # Create the string to qx in runperl().
424     my %args = @_;
425     my $runperl = which_perl();
426     if ($runperl =~ m/\s/) {
427         $runperl = qq{"$runperl"};
428     }
429     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
430     if ($ENV{PERL_RUNPERL_DEBUG}) {
431         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
432     }
433     unless ($args{nolib}) {
434         $runperl = $runperl . ' "-I../lib"'; # doublequotes because of VMS
435     }
436     if ($args{switches}) {
437         local $Level = 2;
438         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
439             unless ref $args{switches} eq "ARRAY";
440         $runperl = _quote_args($runperl, $args{switches});
441     }
442     if (defined $args{prog}) {
443         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
444             if defined $args{progs};
445         $args{progs} = [$args{prog}]
446     }
447     if (defined $args{progs}) {
448         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
449             unless ref $args{progs} eq "ARRAY";
450         foreach my $prog (@{$args{progs}}) {
451             if ($is_mswin || $is_netware || $is_vms) {
452                 $runperl = $runperl . qq ( -e "$prog" );
453             }
454             else {
455                 $runperl = $runperl . qq ( -e '$prog' );
456             }
457         }
458     } elsif (defined $args{progfile}) {
459         $runperl = $runperl . qq( "$args{progfile}");
460     } else {
461         # You probaby didn't want to be sucking in from the upstream stdin
462         die "test.pl:runperl(): none of prog, progs, progfile, args, "
463             . " switches or stdin specified"
464             unless defined $args{args} or defined $args{switches}
465                 or defined $args{stdin};
466     }
467     if (defined $args{stdin}) {
468         # so we don't try to put literal newlines and crs onto the
469         # command line.
470         $args{stdin} =~ s/\n/\\n/g;
471         $args{stdin} =~ s/\r/\\r/g;
472
473         if ($is_mswin || $is_netware || $is_vms) {
474             $runperl = qq{$Perl -e "print qq(} .
475                 $args{stdin} . q{)" | } . $runperl;
476         }
477         else {
478             $runperl = qq{$Perl -e 'print qq(} .
479                 $args{stdin} . q{)' | } . $runperl;
480         }
481     }
482     if (defined $args{args}) {
483         $runperl = _quote_args($runperl, $args{args});
484     }
485     $runperl = $runperl . ' 2>&1' if $args{stderr};
486     if ($args{verbose}) {
487         my $runperldisplay = $runperl;
488         $runperldisplay =~ s/\n/\n\#/g;
489         _print_stderr "# $runperldisplay\n";
490     }
491     return $runperl;
492 }
493
494 sub runperl {
495     die "test.pl:runperl() does not take a hashref"
496         if ref $_[0] and ref $_[0] eq 'HASH';
497     my $runperl = &_create_runperl;
498     my $result;
499
500     my $tainted = ${^TAINT};
501     my %args = @_;
502     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
503
504     if ($tainted) {
505         # We will assume that if you're running under -T, you really mean to
506         # run a fresh perl, so we'll brute force launder everything for you
507         my $sep;
508
509         if (! eval 'require Config; 1') {
510             warn "test.pl had problems loading Config: $@";
511             $sep = ':';
512         } else {
513             $sep = $Config::Config{path_sep};
514         }
515
516         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
517         local @ENV{@keys} = ();
518         # Untaint, plus take out . and empty string:
519         local $ENV{'DCL$PATH'} = $1 if $is_vms && ($ENV{'DCL$PATH'} =~ /(.*)/s);
520         $ENV{PATH} =~ /(.*)/s;
521         local $ENV{PATH} =
522             join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
523                 ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
524                     split quotemeta ($sep), $1;
525         $ENV{PATH} = $ENV{PATH} . "$sep/bin" if $is_cygwin;  # Must have /bin under Cygwin
526
527         $runperl =~ /(.*)/s;
528         $runperl = $1;
529
530         $result = `$runperl`;
531     } else {
532         $result = `$runperl`;
533     }
534     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
535     return $result;
536 }
537
538 *run_perl = \&runperl; # Nice alias.
539
540 sub DIE {
541     _print_stderr "# @_\n";
542     exit 1;
543 }
544
545 # A somewhat safer version of the sometimes wrong $^X.
546 sub which_perl {
547     unless (defined $Perl) {
548         $Perl = $^X;
549
550         # VMS should have 'perl' aliased properly
551         return $Perl if $^O eq 'VMS';
552
553         my $exe;
554         if (! eval 'require Config; 1') {
555             warn "test.pl had problems loading Config: $@";
556             $exe = '';
557         } else {
558             $exe = $Config::Config{_exe};
559         }
560        $exe = '' unless defined $exe;
561
562         # This doesn't absolutize the path: beware of future chdirs().
563         # We could do File::Spec->abs2rel() but that does getcwd()s,
564         # which is a bit heavyweight to do here.
565
566         if ($Perl =~ /^perl\Q$exe\E$/i) {
567             my $perl = "perl$exe";
568             if (! eval 'require File::Spec; 1') {
569                 warn "test.pl had problems loading File::Spec: $@";
570                 $Perl = "./$perl";
571             } else {
572                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
573             }
574         }
575
576         # Build up the name of the executable file from the name of
577         # the command.
578
579         if ($Perl !~ /\Q$exe\E$/i) {
580             $Perl = $Perl . $exe;
581         }
582
583         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
584
585         # For subcommands to use.
586         $ENV{PERLEXE} = $Perl;
587     }
588     return $Perl;
589 }
590
591 sub unlink_all {
592     foreach my $file (@_) {
593         1 while unlink $file;
594         _print_stderr "# Couldn't unlink '$file': $!\n" if -f $file;
595     }
596 }
597
598 my %tmpfiles;
599 END { unlink_all keys %tmpfiles }
600
601 # A regexp that matches the tempfile names
602 $::tempfile_regexp = 'tmp\d+[A-Z][A-Z]?';
603
604 # Avoid ++, avoid ranges, avoid split //
605 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
606 sub tempfile {
607     my $count = 0;
608     do {
609         my $temp = $count;
610         my $try = "tmp$$";
611         do {
612             $try = $try . $letters[$temp % 26];
613             $temp = int ($temp / 26);
614         } while $temp;
615         # Need to note all the file names we allocated, as a second request may
616         # come before the first is created.
617         if (!-e $try && !$tmpfiles{$try}) {
618             # We have a winner
619             $tmpfiles{$try} = 1;
620             return $try;
621         }
622         $count = $count + 1;
623     } while $count < 26 * 26;
624     die "Can't find temporary file name starting 'tmp$$'";
625 }
626
627 # This is the temporary file for _fresh_perl
628 my $tmpfile = tempfile();
629
630 #
631 # _fresh_perl
632 #
633 # The $resolve must be a subref that tests the first argument
634 # for success, or returns the definition of success (e.g. the
635 # expected scalar) if given no arguments.
636 #
637
638 sub _fresh_perl {
639     my($prog, $resolve, $runperl_args, $name) = @_;
640
641     # Given the choice of the mis-parsable {}
642     # (we want an anon hash, but a borked lexer might think that it's a block)
643     # or relying on taking a reference to a lexical
644     # (\ might be mis-parsed, and the reference counting on the pad may go
645     #  awry)
646     # it feels like the least-worse thing is to assume that auto-vivification
647     # works. At least, this is only going to be a run-time failure, so won't
648     # affect tests using this file but not this function.
649     $runperl_args->{progfile} = $tmpfile;
650     $runperl_args->{stderr} = 1;
651
652     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
653
654     # VMS adjustments
655     if( $^O eq 'VMS' ) {
656         $prog =~ s#/dev/null#NL:#;
657
658         # VMS file locking
659         $prog =~ s{if \(-e _ and -f _ and -r _\)}
660                   {if (-e _ and -f _)}
661     }
662
663     print TEST $prog;
664     close TEST or die "Cannot close $tmpfile: $!";
665
666     my $results = runperl(%$runperl_args);
667     my $status = $?;
668
669     # Clean up the results into something a bit more predictable.
670     $results  =~ s/\n+$//;
671     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
672     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
673
674     # bison says 'parse error' instead of 'syntax error',
675     # various yaccs may or may not capitalize 'syntax'.
676     $results =~ s/^(syntax|parse) error/syntax error/mig;
677
678     if ($^O eq 'VMS') {
679         # some tests will trigger VMS messages that won't be expected
680         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
681
682         # pipes double these sometimes
683         $results =~ s/\n\n/\n/g;
684     }
685
686     my $pass = $resolve->($results);
687     unless ($pass) {
688         _diag "# PROG: \n$prog\n";
689         _diag "# EXPECTED:\n", $resolve->(), "\n";
690         _diag "# GOT:\n$results\n";
691         _diag "# STATUS: $status\n";
692     }
693
694     # Use the first line of the program as a name if none was given
695     unless( $name ) {
696         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
697         $name = $name . '...' if length $first_line > length $name;
698     }
699
700     _ok($pass, _where(), "fresh_perl - $name");
701 }
702
703 #
704 # fresh_perl_is
705 #
706 # Combination of run_perl() and is().
707 #
708
709 sub fresh_perl_is {
710     my($prog, $expected, $runperl_args, $name) = @_;
711
712     # _fresh_perl() is going to clip the trailing newlines off the result.
713     # This will make it so the test author doesn't have to know that.
714     $expected =~ s/\n+$//;
715
716     local $Level = 2;
717     _fresh_perl($prog,
718                 sub { @_ ? $_[0] eq $expected : $expected },
719                 $runperl_args, $name);
720 }
721
722 #
723 # fresh_perl_like
724 #
725 # Combination of run_perl() and like().
726 #
727
728 sub fresh_perl_like {
729     my($prog, $expected, $runperl_args, $name) = @_;
730     local $Level = 2;
731     _fresh_perl($prog,
732                 sub { @_ ?
733                           $_[0] =~ (ref $expected ? $expected : /$expected/) :
734                           $expected },
735                 $runperl_args, $name);
736 }
737
738 sub can_ok ($@) {
739     my($proto, @methods) = @_;
740     my $class = ref $proto || $proto;
741
742     unless( @methods ) {
743         return _ok( 0, _where(), "$class->can(...)" );
744     }
745
746     my @nok = ();
747     foreach my $method (@methods) {
748         local($!, $@);  # don't interfere with caller's $@
749                         # eval sometimes resets $!
750         eval { $proto->can($method) } || push @nok, $method;
751     }
752
753     my $name;
754     $name = @methods == 1 ? "$class->can('$methods[0]')"
755                           : "$class->can(...)";
756
757     _ok( !@nok, _where(), $name );
758 }
759
760 sub isa_ok ($$;$) {
761     my($object, $class, $obj_name) = @_;
762
763     my $diag;
764     $obj_name = 'The object' unless defined $obj_name;
765     my $name = "$obj_name isa $class";
766     if( !defined $object ) {
767         $diag = "$obj_name isn't defined";
768     }
769     elsif( !ref $object ) {
770         $diag = "$obj_name isn't a reference";
771     }
772     else {
773         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
774         local($@, $!);  # eval sometimes resets $!
775         my $rslt = eval { $object->isa($class) };
776         if( $@ ) {
777             if( $@ =~ /^Can't call method "isa" on unblessed reference/ ) {
778                 if( !UNIVERSAL::isa($object, $class) ) {
779                     my $ref = ref $object;
780                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
781                 }
782             } else {
783                 die <<WHOA;
784 WHOA! I tried to call ->isa on your object and got some weird error.
785 This should never happen.  Please contact the author immediately.
786 Here's the error.
787 $@
788 WHOA
789             }
790         }
791         elsif( !$rslt ) {
792             my $ref = ref $object;
793             $diag = "$obj_name isn't a '$class' it's a '$ref'";
794         }
795     }
796
797     _ok( !$diag, _where(), $name );
798 }
799
800 # Set a watchdog to timeout the entire test file
801 # NOTE:  If the test file uses 'threads', then call the watchdog() function
802 #        _AFTER_ the 'threads' module is loaded.
803 sub watchdog ($)
804 {
805     my $timeout = shift;
806     my $timeout_msg = 'Test process timed out - terminating';
807
808     my $pid_to_kill = $$;   # PID for this process
809
810     # Don't use a watchdog process if 'threads' is loaded -
811     #   use a watchdog thread instead
812     if (! $threads::threads) {
813
814         # On Windows and VMS, try launching a watchdog process
815         #   using system(1, ...) (see perlport.pod)
816         if (($^O eq 'MSWin32') || ($^O eq 'VMS')) {
817             # On Windows, try to get the 'real' PID
818             if ($^O eq 'MSWin32') {
819                 eval { require Win32; };
820                 if (defined(&Win32::GetCurrentProcessId)) {
821                     $pid_to_kill = Win32::GetCurrentProcessId();
822                 }
823             }
824
825             # If we still have a fake PID, we can't use this method at all
826             return if ($pid_to_kill <= 0);
827
828             # Launch watchdog process
829             my $watchdog;
830             eval {
831                 local $SIG{'__WARN__'} = sub {
832                     _diag("Watchdog warning: $_[0]");
833                 };
834                 my $sig = $^O eq 'VMS' ? 'TERM' : 'KILL';
835                 my $cmd = _create_runperl( prog =>  "sleep($timeout);" .
836                                                     "warn qq/# $timeout_msg" . '\n/;' .
837                                                     "kill($sig, $pid_to_kill);");
838                 $watchdog = system(1, $cmd);
839             };
840             if ($@ || ($watchdog <= 0)) {
841                 _diag('Failed to start watchdog');
842                 _diag($@) if $@;
843                 undef($watchdog);
844                 return;
845             }
846
847             # Add END block to parent to terminate and
848             #   clean up watchdog process
849             eval "END { local \$! = 0; local \$? = 0;
850                         wait() if kill('KILL', $watchdog); };";
851             return;
852         }
853
854         # Try using fork() to generate a watchdog process
855         my $watchdog;
856         eval { $watchdog = fork() };
857         if (defined($watchdog)) {
858             if ($watchdog) {   # Parent process
859                 # Add END block to parent to terminate and
860                 #   clean up watchdog process
861                 eval "END { local \$! = 0; local \$? = 0;
862                             wait() if kill('KILL', $watchdog); };";
863                 return;
864             }
865
866             ### Watchdog process code
867
868             # Load POSIX if available
869             eval { require POSIX; };
870
871             # Execute the timeout
872             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
873             sleep(2);
874
875             # Kill test process if still running
876             if (kill(0, $pid_to_kill)) {
877                 _diag($timeout_msg);
878                 kill('KILL', $pid_to_kill);
879             }
880
881             # Don't execute END block (added at beginning of this file)
882             $NO_ENDING = 1;
883
884             # Terminate ourself (i.e., the watchdog)
885             POSIX::_exit(1) if (defined(&POSIX::_exit));
886             exit(1);
887         }
888
889         # fork() failed - fall through and try using a thread
890     }
891
892     # Use a watchdog thread because either 'threads' is loaded,
893     #   or fork() failed
894     if (eval 'require threads; 1') {
895         threads->create(sub {
896                 # Load POSIX if available
897                 eval { require POSIX; };
898
899                 # Execute the timeout
900                 my $time_left = $timeout;
901                 do {
902                     $time_left = $time_left - sleep($time_left);
903                 } while ($time_left > 0);
904
905                 # Kill the parent (and ourself)
906                 select(STDERR); $| = 1;
907                 _diag($timeout_msg);
908                 POSIX::_exit(1) if (defined(&POSIX::_exit));
909                 my $sig = $^O eq 'VMS' ? 'TERM' : 'KILL';
910                 kill($sig, $pid_to_kill);
911             })->detach();
912         return;
913     }
914
915     # If everything above fails, then just use an alarm timeout
916     if (eval { alarm($timeout); 1; }) {
917         # Load POSIX if available
918         eval { require POSIX; };
919
920         # Alarm handler will do the actual 'killing'
921         $SIG{'ALRM'} = sub {
922             select(STDERR); $| = 1;
923             _diag($timeout_msg);
924             POSIX::_exit(1) if (defined(&POSIX::_exit));
925             my $sig = $^O eq 'VMS' ? 'TERM' : 'KILL';
926             kill($sig, $pid_to_kill);
927         };
928     }
929 }
930
931 1;