This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Handle darwin ppc nm output, reenable test.
[perl5.git] / t / porting / libperl.t
1 #!/usr/bin/perl -w
2
3 # Try opening libperl.a with nm, and verifying it has the kind of symbols
4 # we expected.  Fail softly, expect things only on known platforms.
5 #
6 # Also, if the rarely-used builds options -DPERL_GLOBAL_STRUCT or
7 # -DPERL_GLOBAL_STRUCT_PRIVATE are used, verify that they did what
8 # they were meant to do, hide the global variables (see perlguts for
9 # the details).
10 #
11 # Debugging tip: nm output (this script's input) can be faked by
12 # giving one command line argument for this script: it should be
13 # either the filename to read, or "-" for STDIN.
14
15 BEGIN {
16     chdir 't' if -d 't';
17     @INC = '../lib';
18     require "./test.pl";
19 }
20
21 use strict;
22
23 use Config;
24
25 if ($Config{cc} =~ /g\+\+/) {
26     # XXX Could use c++filt, maybe.
27     skip_all "on g++";
28 }
29
30 my $libperl_a;
31
32 for my $f (qw(../libperl.a libperl.a)) {
33   if (-f $f) {
34     $libperl_a = $f;
35     last;
36   }
37 }
38
39 unless (defined $libperl_a) {
40   skip_all "no libperl.a";
41 }
42
43 print "# libperl = $libperl_a\n";
44
45 my $nm;
46 my $nm_opt = '';
47 my $nm_style;
48
49 if ($^O eq 'linux') {
50     $nm = '/usr/bin/nm';
51     $nm_style = 'gnu';
52 } elsif ($^O eq 'darwin') {
53     $nm = '/usr/bin/nm';
54     $nm_style = 'darwin';
55     # With the -m option we get better information than the BSD-like
56     # default: with the default, a lot of symbols get dumped into 'S'
57     # or 's', for example one cannot tell the difference between const
58     # and non-const symbols.
59     $nm_opt = '-m';
60 }
61
62 unless (defined $nm) {
63   skip_all "no nm";
64 }
65
66 unless (defined $nm_style) {
67   skip_all "no nm style";
68 }
69
70 print "# nm = $nm\n";
71 print "# nm_style = $nm_style\n";
72 print "# nm_opt = $nm_opt\n";
73
74 unless (-x $nm) {
75     skip_all "no executable nm $nm";
76 }
77
78 if ($nm_style eq 'gnu') {
79     open(my $nm_fh, "$nm --version|") or
80         skip_all "nm failed: $!";
81     my $gnu_verified;
82     while (<$nm_fh>) {
83         if (/^GNU nm/) {
84             $gnu_verified = 1;
85             last;
86         }
87     }
88     unless ($gnu_verified) {
89         skip_all "no GNU nm";
90     }
91 }
92
93 my $nm_err_tmp = "libperl$$";
94
95 END {
96     # this is still executed when we skip_all above, avoid a warning
97     unlink $nm_err_tmp if $nm_err_tmp;
98 }
99
100 my $nm_fh;
101
102 if (@ARGV == 1) {
103     my $fake = shift @ARGV;
104     print "# Faking nm output from $fake\n";
105     if ($fake eq '-') {
106         open($nm_fh, "<&STDIN") or
107             skip_all "Duping STDIN failed: $!";
108     } else {
109         open($nm_fh, "<", $fake) or
110             skip_all "Opening '$fake' failed: $!";
111     }
112     undef $nm_err_tmp; # In this case there will be no nm errors.
113 } else {
114     open($nm_fh, "$nm $nm_opt $libperl_a 2>$nm_err_tmp |") or
115         skip_all "$nm $nm_opt $libperl_a failed: $!";
116 }
117  
118 sub nm_parse_gnu {
119     my $symbols = shift;
120     my $line = $_;
121     if (m{^(\w+\.o):$}) {
122         $symbols->{obj}{$1}++;
123         $symbols->{o} = $1;
124         return;
125     } else {
126         die "$0: undefined current object: $line"
127             unless defined $symbols->{o};
128         if (s/^[0-9a-f]{8}(?:[0-9a-f]{8})? //) {
129             if (/^[Rr] (\w+)$/) {
130                 $symbols->{data}{const}{$1}{$symbols->{o}}++;
131             } elsif (/^r .+$/) {
132                 # Skip local const.
133             } elsif (/^[Tti] (\w+)(\..+)?$/) {
134                 $symbols->{text}{$1}{$symbols->{o}}++;
135             } elsif (/^C (\w+)$/) {
136                 $symbols->{data}{common}{$1}{$symbols->{o}}++;
137             } elsif (/^[BbSs] (\w+)(\.\d+)?$/) {
138                 $symbols->{data}{bss}{$1}{$symbols->{o}}++;
139             } elsif (/^0{16} D _LIB_VERSION$/) {
140                 # Skip the _LIB_VERSION (not ours).
141             } elsif (/^[DdGg] (\w+)$/) {
142                 $symbols->{data}{data}{$1}{$symbols->{o}}++;
143             } elsif (/^. \.?(\w+)$/) {
144                 # Skip the unknown types.
145                 print "# Unknown type: $line ($symbols->{o})\n";
146             }
147             return;
148         } elsif (/^ {8}(?: {8})? U (\w+)$/) {
149             # Skip the undefined.
150             return;
151         }
152     }
153     print "# Unexpected nm output '$line' ($symbols->{o})\n";
154 }
155
156 sub nm_parse_darwin {
157     my $symbols = shift;
158     my $line = $_;
159     if (m{^(?:\.\./)?libperl\.a\((\w+\.o)\):$}) {
160         $symbols->{obj}{$1}++;
161         $symbols->{o} = $1;
162         return;
163     } else {
164         die "$0: undefined current object: $line" unless defined $symbols->{o};
165         if (s/^[0-9a-f]{8}(?:[0-9a-f]{8})? //) {
166             if (/^\(__TEXT,__(?:eh_frame|cstring)\) /) {
167                 # Skip the eh_frame and cstring.
168             } elsif (/^\(__TEXT,__(?:const|literal\d+)\) (?:non-)?external _?(\w+)(\.\w+)?$/) {
169                 my ($symbol, $suffix) = ($1, $2);
170                 # Ignore function-local constants like
171                 # _Perl_av_extend_guts.oom_array_extend
172                 return if defined $suffix && /__TEXT,__const/;
173                 $symbols->{data}{const}{$symbol}{$symbols->{o}}++;
174             } elsif (/^\(__TEXT,__text\) (?:non-)?external _(\w+)$/) {
175                 $symbols->{text}{$1}{$symbols->{o}}++;
176             } elsif (/^\(__DATA,__(const|data|bss|common)\) (?:non-)?external _(\w+)(\.\w+)?$/) {
177                 my ($dtype, $symbol, $suffix) = ($1, $2, $3);
178                 # Ignore function-local constants like
179                 # _Perl_pp_gmtime.dayname
180                 return if defined $suffix;
181                 $symbols->{data}{$dtype}{$symbol}{$symbols->{o}}++;
182             } elsif (/^\(__DATA,__const\) non-external _\.memset_pattern\d*$/) {
183                 # Skip this, whatever it is (some inlined leakage from
184                 # darwin libc?)
185             } elsif (/^\(__\w+,__\w+\) /) {
186                 # Skip the unknown types.
187                 print "# Unknown type: $line ($symbols->{o})\n";
188             }
189             return;
190         } elsif (/^ {8}(?: {8})? \(undefined\) /) {
191             # Skip the undefined.
192             return;
193         }
194     }
195     print "# Unexpected nm output '$line' ($symbols->{o})\n";
196 }
197
198 my $nm_parse;
199
200 if ($nm_style eq 'gnu') {
201     $nm_parse = \&nm_parse_gnu;
202 } elsif ($nm_style eq 'darwin') {
203     $nm_parse = \&nm_parse_darwin;
204 }
205
206 unless (defined $nm_parse) {
207     skip_all "no nm parser";
208 }
209
210 my %symbols;
211
212 while (<$nm_fh>) {
213     next if /^$/;
214     chomp;
215     $nm_parse->(\%symbols);
216 }
217
218 # use Data::Dumper; print Dumper(\%symbols);
219
220 if (keys %symbols == 0) {
221     skip_all "no symbols\n";
222 }
223
224 # These should always be true for everyone.
225
226 ok($symbols{obj}{'pp.o'}, "has object pp.o");
227 ok($symbols{text}{'Perl_peep'}, "has text Perl_peep");
228 ok($symbols{text}{'Perl_pp_uc'}{'pp.o'}, "has text Perl_pp_uc in pp.o");
229 ok(exists $symbols{data}{const}, "has data const symbols");
230 ok($symbols{data}{const}{PL_no_mem}{'globals.o'}, "has PL_no_mem");
231
232 my $DEBUGGING = $Config{ccflags} =~ /-DDEBUGGING/ ? 1 : 0;
233
234 my $GS  = $Config{ccflags} =~ /-DPERL_GLOBAL_STRUCT\b/ ? 1 : 0;
235 my $GSP = $Config{ccflags} =~ /-DPERL_GLOBAL_STRUCT_PRIVATE/ ? 1 : 0;
236
237 print "# GS  = $GS\n";
238 print "# GSP = $GSP\n";
239
240 my %data_symbols;
241
242 for my $dtype (sort keys %{$symbols{data}}) {
243     for my $symbol (sort keys %{$symbols{data}{$dtype}}) {
244         $data_symbols{$symbol}++;
245     }
246 }
247
248 # Since we are deprived of Test::More.
249 sub is_deeply {
250     my ($a, $b) = @_;
251     if (ref $a eq 'ARRAY' && ref $b eq 'ARRAY') {
252         if (@$a == @$b) {
253             for my $i (0..$#$a) {
254                 unless ($a->[$i] eq $b->[$i]) {
255                     printf("# LHS elem #%d '%s' ne RHS elem #%d '%s'\n",
256                            $a->[$i], $b->[$i]);
257                     return 0;
258                 }
259             }
260             return 1;
261         } else {
262             printf("# LHS length %d, RHS length %d\n",
263                    @$a, @$b);
264             return 0;
265         }
266     } else {
267         die "$0: Unexpcted: is_deeply $a $b\n";
268     }
269 }
270
271 # The following tests differ between vanilla vs $GSP or $GS.
272 #
273 # Some terminology:
274 # - "text" symbols are code
275 # - "data" symbols are data (duh), with subdivisions:
276 #   - "bss": (Block-Started-by-Symbol: originally from IBM assembler...),
277 #     uninitialized data, which often even doesn't exist in the object
278 #     file as such, only its size does, which is then created on demand
279 #     by the loader
280 #  - "const": initialized read-only data, like string literals
281 #  - "common": uninitialized data unless initialized...
282 #    (the full story is too long for here, see "man nm")
283 #  - "data": initialized read-write data
284 #    (somewhat confusingly below: "data data", but it makes code simpler)
285
286 if ($GSP) {
287     print "# -DPERL_GLOBAL_STRUCT_PRIVATE\n";
288     ok(!exists $data_symbols{PL_hash_seed}, "has no PL_hash_seed");
289     ok(!exists $data_symbols{PL_ppaddr}, "has no PL_ppaddr");
290
291     ok(! exists $symbols{data}{bss}, "has no data bss symbols");
292     ok(! exists $symbols{data}{data} ||
293             # clang with ASAN seems to add this symbol to every object file:
294             !grep($_ ne '__unnamed_1', keys %{$symbols{data}{data}}),
295         "has no data data symbols");
296     ok(! exists $symbols{data}{common}, "has no data common symbols");
297
298     # -DPERL_GLOBAL_STRUCT_PRIVATE should NOT have
299     # the extra text symbol for accessing the vars
300     # (as opposed to "just" -DPERL_GLOBAL_STRUCT)
301     ok(! exists $symbols{text}{Perl_GetVars}, "has no Perl_GetVars");
302 } elsif ($GS) {
303     print "# -DPERL_GLOBAL_STRUCT\n";
304     ok(!exists $data_symbols{PL_hash_seed}, "has no PL_hash_seed");
305     ok(!exists $data_symbols{PL_ppaddr}, "has no PL_ppaddr");
306
307     ok(! exists $symbols{data}{bss}, "has no data bss symbols");
308
309     # These PerlIO data symbols are left visible with
310     # -DPERL_GLOBAL_STRUCT (as opposed to -DPERL_GLOBAL_STRUCT_PRIVATE)
311     my @PerlIO =
312         qw(
313            PerlIO_byte
314            PerlIO_crlf
315            PerlIO_pending
316            PerlIO_perlio
317            PerlIO_raw
318            PerlIO_remove
319            PerlIO_stdio
320            PerlIO_unix
321            PerlIO_utf8
322           );
323
324     # PL_magic_vtables is const with -DPERL_GLOBAL_STRUCT_PRIVATE but
325     # otherwise not const -- because of SWIG which wants to modify
326     # the table.  Evil SWIG, eeevil.
327
328     # my_cxt_index is used with PERL_IMPLICIT_CONTEXT, which
329     # -DPERL_GLOBAL_STRUCT has turned on.
330     is_deeply([sort keys %{$symbols{data}{data}}],
331               [sort('PL_VarsPtr',
332                     @PerlIO,
333                     'PL_magic_vtables',
334                     'my_cxt_index')],
335               "data data symbols");
336
337     # Only one data common symbol, our "supervariable".
338     is_deeply([sort keys %{$symbols{data}{common}}],
339               ['PL_Vars'],
340               "data common symbols");
341
342     ok($symbols{data}{data}{PL_VarsPtr}{'globals.o'}, "has PL_VarsPtr");
343     ok($symbols{data}{common}{PL_Vars}{'globals.o'}, "has PL_Vars");
344
345     # -DPERL_GLOBAL_STRUCT has extra text symbol for accessing the vars.
346     ok($symbols{text}{Perl_GetVars}{'util.o'}, "has Perl_GetVars");
347 } else {
348     print "# neither -DPERL_GLOBAL_STRUCT nor -DPERL_GLOBAL_STRUCT_PRIVATE\n";
349
350     if ( !$symbols{data}{common} ) {
351         # This is likely because Perl was compiled with 
352         # -Accflags="-fno-common"
353         $symbols{data}{common} = $symbols{data}{bss};
354     }
355     
356     ok($symbols{data}{common}{PL_hash_seed}{'globals.o'}, "has PL_hash_seed");
357     ok($symbols{data}{data}{PL_ppaddr}{'globals.o'}, "has PL_ppaddr");
358
359     # None of the GLOBAL_STRUCT* business here.
360     ok(! exists $symbols{data}{data}{PL_VarsPtr}, "has no PL_VarsPtr");
361     ok(! exists $symbols{data}{common}{PL_Vars}, "has no PL_Vars");
362     ok(! exists $symbols{text}{Perl_GetVars}, "has no Perl_GetVars");
363 }
364
365 if (defined $nm_err_tmp) {
366     if (open(my $nm_err_fh, $nm_err_tmp)) {
367         my $error;
368         while (<$nm_err_fh>) {
369             # OS X has weird error where nm warns about
370             # "no name list" but then outputs fine.
371             if (/nm: no name list/ && $^O eq 'darwin') {
372                 print "# $^O ignoring $nm output: $_";
373                 next;
374             }
375             warn "$0: Unexpected $nm error: $_";
376             $error++;
377         }
378         die "$0: Unexpected $nm errors\n" if $error;
379     } else {
380         warn "Failed to open '$nm_err_tmp': $!\n";
381     }
382 }
383
384 done_testing();