This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Adjust documentation for previous change
[perl5.git] / pod / perlsub.pod
1 =head1 NAME
2 X<subroutine> X<function>
3
4 perlsub - Perl subroutines
5
6 =head1 SYNOPSIS
7
8 To declare subroutines:
9 X<subroutine, declaration> X<sub>
10
11     sub NAME;                     # A "forward" declaration.
12     sub NAME(PROTO);              #  ditto, but with prototypes
13     sub NAME : ATTRS;             #  with attributes
14     sub NAME(PROTO) : ATTRS;      #  with attributes and prototypes
15
16     sub NAME BLOCK                # A declaration and a definition.
17     sub NAME(PROTO) BLOCK         #  ditto, but with prototypes
18     sub NAME : ATTRS BLOCK        #  with attributes
19     sub NAME(PROTO) : ATTRS BLOCK #  with prototypes and attributes
20
21 To define an anonymous subroutine at runtime:
22 X<subroutine, anonymous>
23
24     $subref = sub BLOCK;                 # no proto
25     $subref = sub (PROTO) BLOCK;         # with proto
26     $subref = sub : ATTRS BLOCK;         # with attributes
27     $subref = sub (PROTO) : ATTRS BLOCK; # with proto and attributes
28
29 To import subroutines:
30 X<import>
31
32     use MODULE qw(NAME1 NAME2 NAME3);
33
34 To call subroutines:
35 X<subroutine, call> X<call>
36
37     NAME(LIST);    # & is optional with parentheses.
38     NAME LIST;     # Parentheses optional if predeclared/imported.
39     &NAME(LIST);   # Circumvent prototypes.
40     &NAME;         # Makes current @_ visible to called subroutine.
41
42 =head1 DESCRIPTION
43
44 Like many languages, Perl provides for user-defined subroutines.
45 These may be located anywhere in the main program, loaded in from
46 other files via the C<do>, C<require>, or C<use> keywords, or
47 generated on the fly using C<eval> or anonymous subroutines.
48 You can even call a function indirectly using a variable containing
49 its name or a CODE reference.
50
51 The Perl model for function call and return values is simple: all
52 functions are passed as parameters one single flat list of scalars, and
53 all functions likewise return to their caller one single flat list of
54 scalars.  Any arrays or hashes in these call and return lists will
55 collapse, losing their identities--but you may always use
56 pass-by-reference instead to avoid this.  Both call and return lists may
57 contain as many or as few scalar elements as you'd like.  (Often a
58 function without an explicit return statement is called a subroutine, but
59 there's really no difference from Perl's perspective.)
60 X<subroutine, parameter> X<parameter>
61
62 Any arguments passed in show up in the array C<@_>.  Therefore, if
63 you called a function with two arguments, those would be stored in
64 C<$_[0]> and C<$_[1]>.  The array C<@_> is a local array, but its
65 elements are aliases for the actual scalar parameters.  In particular,
66 if an element C<$_[0]> is updated, the corresponding argument is
67 updated (or an error occurs if it is not updatable).  If an argument
68 is an array or hash element which did not exist when the function
69 was called, that element is created only when (and if) it is modified
70 or a reference to it is taken.  (Some earlier versions of Perl
71 created the element whether or not the element was assigned to.)
72 Assigning to the whole array C<@_> removes that aliasing, and does
73 not update any arguments.
74 X<subroutine, argument> X<argument> X<@_>
75
76 A C<return> statement may be used to exit a subroutine, optionally
77 specifying the returned value, which will be evaluated in the
78 appropriate context (list, scalar, or void) depending on the context of
79 the subroutine call.  If you specify no return value, the subroutine
80 returns an empty list in list context, the undefined value in scalar
81 context, or nothing in void context.  If you return one or more
82 aggregates (arrays and hashes), these will be flattened together into
83 one large indistinguishable list.
84
85 If no C<return> is found and if the last statement is an expression, its
86 value is returned. If the last statement is a loop control structure
87 like a C<foreach> or a C<while>, the returned value is unspecified. The
88 empty sub returns the empty list.
89 X<subroutine, return value> X<return value> X<return>
90
91 Perl does not have named formal parameters.  In practice all you
92 do is assign to a C<my()> list of these.  Variables that aren't
93 declared to be private are global variables.  For gory details
94 on creating private variables, see L<"Private Variables via my()">
95 and L<"Temporary Values via local()">.  To create protected
96 environments for a set of functions in a separate package (and
97 probably a separate file), see L<perlmod/"Packages">.
98 X<formal parameter> X<parameter, formal>
99
100 Example:
101
102     sub max {
103         my $max = shift(@_);
104         foreach $foo (@_) {
105             $max = $foo if $max < $foo;
106         }
107         return $max;
108     }
109     $bestday = max($mon,$tue,$wed,$thu,$fri);
110
111 Example:
112
113     # get a line, combining continuation lines
114     #  that start with whitespace
115
116     sub get_line {
117         $thisline = $lookahead;  # global variables!
118         LINE: while (defined($lookahead = <STDIN>)) {
119             if ($lookahead =~ /^[ \t]/) {
120                 $thisline .= $lookahead;
121             }
122             else {
123                 last LINE;
124             }
125         }
126         return $thisline;
127     }
128
129     $lookahead = <STDIN>;       # get first line
130     while (defined($line = get_line())) {
131         ...
132     }
133
134 Assigning to a list of private variables to name your arguments:
135
136     sub maybeset {
137         my($key, $value) = @_;
138         $Foo{$key} = $value unless $Foo{$key};
139     }
140
141 Because the assignment copies the values, this also has the effect
142 of turning call-by-reference into call-by-value.  Otherwise a
143 function is free to do in-place modifications of C<@_> and change
144 its caller's values.
145 X<call-by-reference> X<call-by-value>
146
147     upcase_in($v1, $v2);  # this changes $v1 and $v2
148     sub upcase_in {
149         for (@_) { tr/a-z/A-Z/ }
150     }
151
152 You aren't allowed to modify constants in this way, of course.  If an
153 argument were actually literal and you tried to change it, you'd take a
154 (presumably fatal) exception.   For example, this won't work:
155 X<call-by-reference> X<call-by-value>
156
157     upcase_in("frederick");
158
159 It would be much safer if the C<upcase_in()> function
160 were written to return a copy of its parameters instead
161 of changing them in place:
162
163     ($v3, $v4) = upcase($v1, $v2);  # this doesn't change $v1 and $v2
164     sub upcase {
165         return unless defined wantarray;  # void context, do nothing
166         my @parms = @_;
167         for (@parms) { tr/a-z/A-Z/ }
168         return wantarray ? @parms : $parms[0];
169     }
170
171 Notice how this (unprototyped) function doesn't care whether it was
172 passed real scalars or arrays.  Perl sees all arguments as one big,
173 long, flat parameter list in C<@_>.  This is one area where
174 Perl's simple argument-passing style shines.  The C<upcase()>
175 function would work perfectly well without changing the C<upcase()>
176 definition even if we fed it things like this:
177
178     @newlist   = upcase(@list1, @list2);
179     @newlist   = upcase( split /:/, $var );
180
181 Do not, however, be tempted to do this:
182
183     (@a, @b)   = upcase(@list1, @list2);
184
185 Like the flattened incoming parameter list, the return list is also
186 flattened on return.  So all you have managed to do here is stored
187 everything in C<@a> and made C<@b> empty.  See 
188 L<Pass by Reference> for alternatives.
189
190 A subroutine may be called using an explicit C<&> prefix.  The
191 C<&> is optional in modern Perl, as are parentheses if the
192 subroutine has been predeclared.  The C<&> is I<not> optional
193 when just naming the subroutine, such as when it's used as
194 an argument to defined() or undef().  Nor is it optional when you
195 want to do an indirect subroutine call with a subroutine name or
196 reference using the C<&$subref()> or C<&{$subref}()> constructs,
197 although the C<< $subref->() >> notation solves that problem.
198 See L<perlref> for more about all that.
199 X<&>
200
201 Subroutines may be called recursively.  If a subroutine is called
202 using the C<&> form, the argument list is optional, and if omitted,
203 no C<@_> array is set up for the subroutine: the C<@_> array at the
204 time of the call is visible to subroutine instead.  This is an
205 efficiency mechanism that new users may wish to avoid.
206 X<recursion>
207
208     &foo(1,2,3);        # pass three arguments
209     foo(1,2,3);         # the same
210
211     foo();              # pass a null list
212     &foo();             # the same
213
214     &foo;               # foo() get current args, like foo(@_) !!
215     foo;                # like foo() IFF sub foo predeclared, else "foo"
216
217 Not only does the C<&> form make the argument list optional, it also
218 disables any prototype checking on arguments you do provide.  This
219 is partly for historical reasons, and partly for having a convenient way
220 to cheat if you know what you're doing.  See L<Prototypes> below.
221 X<&>
222
223 Subroutines whose names are in all upper case are reserved to the Perl
224 core, as are modules whose names are in all lower case.  A subroutine in
225 all capitals is a loosely-held convention meaning it will be called
226 indirectly by the run-time system itself, usually due to a triggered event.
227 Subroutines that do special, pre-defined things include C<AUTOLOAD>, C<CLONE>,
228 C<DESTROY> plus all functions mentioned in L<perltie> and L<PerlIO::via>.
229
230 The C<BEGIN>, C<CHECK>, C<INIT> and C<END> subroutines are not so much
231 subroutines as named special code blocks, of which you can have more
232 than one in a package, and which you can B<not> call explicitly.  See
233 L<perlmod/"BEGIN, CHECK, INIT and END">
234
235 =head2 Private Variables via my()
236 X<my> X<variable, lexical> X<lexical> X<lexical variable> X<scope, lexical>
237 X<lexical scope> X<attributes, my>
238
239 Synopsis:
240
241     my $foo;            # declare $foo lexically local
242     my (@wid, %get);    # declare list of variables local
243     my $foo = "flurp";  # declare $foo lexical, and init it
244     my @oof = @bar;     # declare @oof lexical, and init it
245     my $x : Foo = $y;   # similar, with an attribute applied
246
247 B<WARNING>: The use of attribute lists on C<my> declarations is still
248 evolving.  The current semantics and interface are subject to change.
249 See L<attributes> and L<Attribute::Handlers>.
250
251 The C<my> operator declares the listed variables to be lexically
252 confined to the enclosing block, conditional (C<if/unless/elsif/else>),
253 loop (C<for/foreach/while/until/continue>), subroutine, C<eval>,
254 or C<do/require/use>'d file.  If more than one value is listed, the
255 list must be placed in parentheses.  All listed elements must be
256 legal lvalues.  Only alphanumeric identifiers may be lexically
257 scoped--magical built-ins like C<$/> must currently be C<local>ized
258 with C<local> instead.
259
260 Unlike dynamic variables created by the C<local> operator, lexical
261 variables declared with C<my> are totally hidden from the outside
262 world, including any called subroutines.  This is true if it's the
263 same subroutine called from itself or elsewhere--every call gets
264 its own copy.
265 X<local>
266
267 This doesn't mean that a C<my> variable declared in a statically
268 enclosing lexical scope would be invisible.  Only dynamic scopes
269 are cut off.   For example, the C<bumpx()> function below has access
270 to the lexical $x variable because both the C<my> and the C<sub>
271 occurred at the same scope, presumably file scope.
272
273     my $x = 10;
274     sub bumpx { $x++ } 
275
276 An C<eval()>, however, can see lexical variables of the scope it is
277 being evaluated in, so long as the names aren't hidden by declarations within
278 the C<eval()> itself.  See L<perlref>.
279 X<eval, scope of>
280
281 The parameter list to my() may be assigned to if desired, which allows you
282 to initialize your variables.  (If no initializer is given for a
283 particular variable, it is created with the undefined value.)  Commonly
284 this is used to name input parameters to a subroutine.  Examples:
285
286     $arg = "fred";        # "global" variable
287     $n = cube_root(27);
288     print "$arg thinks the root is $n\n";
289  fred thinks the root is 3
290
291     sub cube_root {
292         my $arg = shift;  # name doesn't matter
293         $arg **= 1/3;
294         return $arg;
295     }
296
297 The C<my> is simply a modifier on something you might assign to.  So when
298 you do assign to variables in its argument list, C<my> doesn't
299 change whether those variables are viewed as a scalar or an array.  So
300
301     my ($foo) = <STDIN>;                # WRONG?
302     my @FOO = <STDIN>;
303
304 both supply a list context to the right-hand side, while
305
306     my $foo = <STDIN>;
307
308 supplies a scalar context.  But the following declares only one variable:
309
310     my $foo, $bar = 1;                  # WRONG
311
312 That has the same effect as
313
314     my $foo;
315     $bar = 1;
316
317 The declared variable is not introduced (is not visible) until after
318 the current statement.  Thus,
319
320     my $x = $x;
321
322 can be used to initialize a new $x with the value of the old $x, and
323 the expression
324
325     my $x = 123 and $x == 123
326
327 is false unless the old $x happened to have the value C<123>.
328
329 Lexical scopes of control structures are not bounded precisely by the
330 braces that delimit their controlled blocks; control expressions are
331 part of that scope, too.  Thus in the loop
332
333     while (my $line = <>) {
334         $line = lc $line;
335     } continue {
336         print $line;
337     }
338
339 the scope of $line extends from its declaration throughout the rest of
340 the loop construct (including the C<continue> clause), but not beyond
341 it.  Similarly, in the conditional
342
343     if ((my $answer = <STDIN>) =~ /^yes$/i) {
344         user_agrees();
345     } elsif ($answer =~ /^no$/i) {
346         user_disagrees();
347     } else {
348         chomp $answer;
349         die "'$answer' is neither 'yes' nor 'no'";
350     }
351
352 the scope of $answer extends from its declaration through the rest
353 of that conditional, including any C<elsif> and C<else> clauses, 
354 but not beyond it.  See L<perlsyn/"Simple statements"> for information
355 on the scope of variables in statements with modifiers.
356
357 The C<foreach> loop defaults to scoping its index variable dynamically
358 in the manner of C<local>.  However, if the index variable is
359 prefixed with the keyword C<my>, or if there is already a lexical
360 by that name in scope, then a new lexical is created instead.  Thus
361 in the loop
362 X<foreach> X<for>
363
364     for my $i (1, 2, 3) {
365         some_function();
366     }
367
368 the scope of $i extends to the end of the loop, but not beyond it,
369 rendering the value of $i inaccessible within C<some_function()>.
370 X<foreach> X<for>
371
372 Some users may wish to encourage the use of lexically scoped variables.
373 As an aid to catching implicit uses to package variables,
374 which are always global, if you say
375
376     use strict 'vars';
377
378 then any variable mentioned from there to the end of the enclosing
379 block must either refer to a lexical variable, be predeclared via
380 C<our> or C<use vars>, or else must be fully qualified with the package name.
381 A compilation error results otherwise.  An inner block may countermand
382 this with C<no strict 'vars'>.
383
384 A C<my> has both a compile-time and a run-time effect.  At compile
385 time, the compiler takes notice of it.  The principal usefulness
386 of this is to quiet C<use strict 'vars'>, but it is also essential
387 for generation of closures as detailed in L<perlref>.  Actual
388 initialization is delayed until run time, though, so it gets executed
389 at the appropriate time, such as each time through a loop, for
390 example.
391
392 Variables declared with C<my> are not part of any package and are therefore
393 never fully qualified with the package name.  In particular, you're not
394 allowed to try to make a package variable (or other global) lexical:
395
396     my $pack::var;      # ERROR!  Illegal syntax
397
398 In fact, a dynamic variable (also known as package or global variables)
399 are still accessible using the fully qualified C<::> notation even while a
400 lexical of the same name is also visible:
401
402     package main;
403     local $x = 10;
404     my    $x = 20;
405     print "$x and $::x\n";
406
407 That will print out C<20> and C<10>.
408
409 You may declare C<my> variables at the outermost scope of a file
410 to hide any such identifiers from the world outside that file.  This
411 is similar in spirit to C's static variables when they are used at
412 the file level.  To do this with a subroutine requires the use of
413 a closure (an anonymous function that accesses enclosing lexicals).
414 If you want to create a private subroutine that cannot be called
415 from outside that block, it can declare a lexical variable containing
416 an anonymous sub reference:
417
418     my $secret_version = '1.001-beta';
419     my $secret_sub = sub { print $secret_version };
420     &$secret_sub();
421
422 As long as the reference is never returned by any function within the
423 module, no outside module can see the subroutine, because its name is not in
424 any package's symbol table.  Remember that it's not I<REALLY> called
425 C<$some_pack::secret_version> or anything; it's just $secret_version,
426 unqualified and unqualifiable.
427
428 This does not work with object methods, however; all object methods
429 have to be in the symbol table of some package to be found.  See
430 L<perlref/"Function Templates"> for something of a work-around to
431 this.
432
433 =head2 Persistent Private Variables
434 X<state> X<state variable> X<static> X<variable, persistent> X<variable, static> X<closure>
435
436 There are two ways to build persistent private variables in Perl 5.10.
437 First, you can simply use the C<state> feature. Or, you can use closures,
438 if you want to stay compatible with releases older than 5.10.
439
440 =head3 Persistent variables via state()
441
442 Beginning with perl 5.9.4, you can declare variables with the C<state>
443 keyword in place of C<my>. For that to work, though, you must have
444 enabled that feature beforehand, either by using the C<feature> pragma, or
445 by using C<-E> on one-liners. (see L<feature>)
446
447 For example, the following code maintains a private counter, incremented
448 each time the gimme_another() function is called:
449
450     use feature 'state';
451     sub gimme_another { state $x; return ++$x }
452
453 Also, since C<$x> is lexical, it can't be reached or modified by any Perl
454 code outside.
455
456 You can initialize state variables, and the assigment will be executed
457 only once:
458
459     sub starts_from_42 { state $x = 42; return ++$x }
460
461 You can also, as a syntactic shortcut, initialize more than one if they're
462 all declared within the same state() clause:
463
464     state ($a, $b, $c) = ( 'one', 'two', 'three' );
465
466 However, be warned that state variables declared as part of a list will
467 get assigned each time the statement will be executed, since it will be
468 considered as a regular list assigment, not one to be executed only once:
469
470     (state $x, my $y) = (1, 2); # $x gets reinitialized every time !
471
472 B<Caveat>: the code at the right side of the assignment to a state
473 variable will be executed every time; only the assignment is disabled. So,
474 avoid code that has side-effects, or that is slow to execute. This might
475 be optimized out in a future version of Perl.
476
477 =head3 Persistent variables with closures
478
479 Just because a lexical variable is lexically (also called statically)
480 scoped to its enclosing block, C<eval>, or C<do> FILE, this doesn't mean that
481 within a function it works like a C static.  It normally works more
482 like a C auto, but with implicit garbage collection.  
483
484 Unlike local variables in C or C++, Perl's lexical variables don't
485 necessarily get recycled just because their scope has exited.
486 If something more permanent is still aware of the lexical, it will
487 stick around.  So long as something else references a lexical, that
488 lexical won't be freed--which is as it should be.  You wouldn't want
489 memory being free until you were done using it, or kept around once you
490 were done.  Automatic garbage collection takes care of this for you.
491
492 This means that you can pass back or save away references to lexical
493 variables, whereas to return a pointer to a C auto is a grave error.
494 It also gives us a way to simulate C's function statics.  Here's a
495 mechanism for giving a function private variables with both lexical
496 scoping and a static lifetime.  If you do want to create something like
497 C's static variables, just enclose the whole function in an extra block,
498 and put the static variable outside the function but in the block.
499
500     {
501         my $secret_val = 0;
502         sub gimme_another {
503             return ++$secret_val;
504         }
505     }
506     # $secret_val now becomes unreachable by the outside
507     # world, but retains its value between calls to gimme_another
508
509 If this function is being sourced in from a separate file
510 via C<require> or C<use>, then this is probably just fine.  If it's
511 all in the main program, you'll need to arrange for the C<my>
512 to be executed early, either by putting the whole block above
513 your main program, or more likely, placing merely a C<BEGIN>
514 code block around it to make sure it gets executed before your program
515 starts to run:
516
517     BEGIN {
518         my $secret_val = 0;
519         sub gimme_another {
520             return ++$secret_val;
521         }
522     }
523
524 See L<perlmod/"BEGIN, CHECK, INIT and END"> about the
525 special triggered code blocks, C<BEGIN>, C<CHECK>, C<INIT> and C<END>.
526
527 If declared at the outermost scope (the file scope), then lexicals
528 work somewhat like C's file statics.  They are available to all
529 functions in that same file declared below them, but are inaccessible
530 from outside that file.  This strategy is sometimes used in modules
531 to create private variables that the whole module can see.
532
533 =head2 Temporary Values via local()
534 X<local> X<scope, dynamic> X<dynamic scope> X<variable, local>
535 X<variable, temporary>
536
537 B<WARNING>: In general, you should be using C<my> instead of C<local>, because
538 it's faster and safer.  Exceptions to this include the global punctuation
539 variables, global filehandles and formats, and direct manipulation of the
540 Perl symbol table itself.  C<local> is mostly used when the current value
541 of a variable must be visible to called subroutines.
542
543 Synopsis:
544
545     # localization of values
546
547     local $foo;                 # make $foo dynamically local
548     local (@wid, %get);         # make list of variables local
549     local $foo = "flurp";       # make $foo dynamic, and init it
550     local @oof = @bar;          # make @oof dynamic, and init it
551
552     local $hash{key} = "val";   # sets a local value for this hash entry
553     local ($cond ? $v1 : $v2);  # several types of lvalues support
554                                 # localization
555
556     # localization of symbols
557
558     local *FH;                  # localize $FH, @FH, %FH, &FH  ...
559     local *merlyn = *randal;    # now $merlyn is really $randal, plus
560                                 #     @merlyn is really @randal, etc
561     local *merlyn = 'randal';   # SAME THING: promote 'randal' to *randal
562     local *merlyn = \$randal;   # just alias $merlyn, not @merlyn etc
563
564 A C<local> modifies its listed variables to be "local" to the
565 enclosing block, C<eval>, or C<do FILE>--and to I<any subroutine
566 called from within that block>.  A C<local> just gives temporary
567 values to global (meaning package) variables.  It does I<not> create
568 a local variable.  This is known as dynamic scoping.  Lexical scoping
569 is done with C<my>, which works more like C's auto declarations.
570
571 Some types of lvalues can be localized as well : hash and array elements
572 and slices, conditionals (provided that their result is always
573 localizable), and symbolic references.  As for simple variables, this
574 creates new, dynamically scoped values.
575
576 If more than one variable or expression is given to C<local>, they must be
577 placed in parentheses.  This operator works
578 by saving the current values of those variables in its argument list on a
579 hidden stack and restoring them upon exiting the block, subroutine, or
580 eval.  This means that called subroutines can also reference the local
581 variable, but not the global one.  The argument list may be assigned to if
582 desired, which allows you to initialize your local variables.  (If no
583 initializer is given for a particular variable, it is created with an
584 undefined value.)
585
586 Because C<local> is a run-time operator, it gets executed each time
587 through a loop.  Consequently, it's more efficient to localize your
588 variables outside the loop.
589
590 =head3 Grammatical note on local()
591 X<local, context>
592
593 A C<local> is simply a modifier on an lvalue expression.  When you assign to
594 a C<local>ized variable, the C<local> doesn't change whether its list is viewed
595 as a scalar or an array.  So
596
597     local($foo) = <STDIN>;
598     local @FOO = <STDIN>;
599
600 both supply a list context to the right-hand side, while
601
602     local $foo = <STDIN>;
603
604 supplies a scalar context.
605
606 =head3 Localization of special variables
607 X<local, special variable>
608
609 If you localize a special variable, you'll be giving a new value to it,
610 but its magic won't go away.  That means that all side-effects related
611 to this magic still work with the localized value.
612
613 This feature allows code like this to work :
614
615     # Read the whole contents of FILE in $slurp
616     { local $/ = undef; $slurp = <FILE>; }
617
618 Note, however, that this restricts localization of some values ; for
619 example, the following statement dies, as of perl 5.9.0, with an error
620 I<Modification of a read-only value attempted>, because the $1 variable is
621 magical and read-only :
622
623     local $1 = 2;
624
625 Similarly, but in a way more difficult to spot, the following snippet will
626 die in perl 5.9.0 :
627
628     sub f { local $_ = "foo"; print }
629     for ($1) {
630         # now $_ is aliased to $1, thus is magic and readonly
631         f();
632     }
633
634 See next section for an alternative to this situation.
635
636 B<WARNING>: Localization of tied arrays and hashes does not currently
637 work as described.
638 This will be fixed in a future release of Perl; in the meantime, avoid
639 code that relies on any particular behaviour of localising tied arrays
640 or hashes (localising individual elements is still okay).
641 See L<perl58delta/"Localising Tied Arrays and Hashes Is Broken"> for more
642 details.
643 X<local, tie>
644
645 =head3 Localization of globs
646 X<local, glob> X<glob>
647
648 The construct
649
650     local *name;
651
652 creates a whole new symbol table entry for the glob C<name> in the
653 current package.  That means that all variables in its glob slot ($name,
654 @name, %name, &name, and the C<name> filehandle) are dynamically reset.
655
656 This implies, among other things, that any magic eventually carried by
657 those variables is locally lost.  In other words, saying C<local */>
658 will not have any effect on the internal value of the input record
659 separator.
660
661 Notably, if you want to work with a brand new value of the default scalar
662 $_, and avoid the potential problem listed above about $_ previously
663 carrying a magic value, you should use C<local *_> instead of C<local $_>.
664 As of perl 5.9.1, you can also use the lexical form of C<$_> (declaring it
665 with C<my $_>), which avoids completely this problem.
666
667 =head3 Localization of elements of composite types
668 X<local, composite type element> X<local, array element> X<local, hash element>
669
670 It's also worth taking a moment to explain what happens when you
671 C<local>ize a member of a composite type (i.e. an array or hash element).
672 In this case, the element is C<local>ized I<by name>. This means that
673 when the scope of the C<local()> ends, the saved value will be
674 restored to the hash element whose key was named in the C<local()>, or
675 the array element whose index was named in the C<local()>.  If that
676 element was deleted while the C<local()> was in effect (e.g. by a
677 C<delete()> from a hash or a C<shift()> of an array), it will spring
678 back into existence, possibly extending an array and filling in the
679 skipped elements with C<undef>.  For instance, if you say
680
681     %hash = ( 'This' => 'is', 'a' => 'test' );
682     @ary  = ( 0..5 );
683     {
684          local($ary[5]) = 6;
685          local($hash{'a'}) = 'drill';
686          while (my $e = pop(@ary)) {
687              print "$e . . .\n";
688              last unless $e > 3;
689          }
690          if (@ary) {
691              $hash{'only a'} = 'test';
692              delete $hash{'a'};
693          }
694     }
695     print join(' ', map { "$_ $hash{$_}" } sort keys %hash),".\n";
696     print "The array has ",scalar(@ary)," elements: ",
697           join(', ', map { defined $_ ? $_ : 'undef' } @ary),"\n";
698
699 Perl will print
700
701     6 . . .
702     4 . . .
703     3 . . .
704     This is a test only a test.
705     The array has 6 elements: 0, 1, 2, undef, undef, 5
706
707 The behavior of local() on non-existent members of composite
708 types is subject to change in future.
709
710 =head2 Lvalue subroutines
711 X<lvalue> X<subroutine, lvalue>
712
713 B<WARNING>: Lvalue subroutines are still experimental and the
714 implementation may change in future versions of Perl.
715
716 It is possible to return a modifiable value from a subroutine.
717 To do this, you have to declare the subroutine to return an lvalue.
718
719     my $val;
720     sub canmod : lvalue {
721         # return $val; this doesn't work, don't say "return"
722         $val;
723     }
724     sub nomod {
725         $val;
726     }
727
728     canmod() = 5;   # assigns to $val
729     nomod()  = 5;   # ERROR
730
731 The scalar/list context for the subroutine and for the right-hand
732 side of assignment is determined as if the subroutine call is replaced
733 by a scalar. For example, consider:
734
735     data(2,3) = get_data(3,4);
736
737 Both subroutines here are called in a scalar context, while in:
738
739     (data(2,3)) = get_data(3,4);
740
741 and in:
742
743     (data(2),data(3)) = get_data(3,4);
744
745 all the subroutines are called in a list context.
746
747 =over 4
748
749 =item Lvalue subroutines are EXPERIMENTAL
750
751 They appear to be convenient, but there are several reasons to be
752 circumspect.
753
754 You can't use the return keyword, you must pass out the value before
755 falling out of subroutine scope. (see comment in example above).  This
756 is usually not a problem, but it disallows an explicit return out of a
757 deeply nested loop, which is sometimes a nice way out.
758
759 They violate encapsulation.  A normal mutator can check the supplied
760 argument before setting the attribute it is protecting, an lvalue
761 subroutine never gets that chance.  Consider;
762
763     my $some_array_ref = [];    # protected by mutators ??
764
765     sub set_arr {               # normal mutator
766         my $val = shift;
767         die("expected array, you supplied ", ref $val)
768            unless ref $val eq 'ARRAY';
769         $some_array_ref = $val;
770     }
771     sub set_arr_lv : lvalue {   # lvalue mutator
772         $some_array_ref;
773     }
774
775     # set_arr_lv cannot stop this !
776     set_arr_lv() = { a => 1 };
777
778 =back
779
780 =head2 Passing Symbol Table Entries (typeglobs)
781 X<typeglob> X<*>
782
783 B<WARNING>: The mechanism described in this section was originally
784 the only way to simulate pass-by-reference in older versions of
785 Perl.  While it still works fine in modern versions, the new reference
786 mechanism is generally easier to work with.  See below.
787
788 Sometimes you don't want to pass the value of an array to a subroutine
789 but rather the name of it, so that the subroutine can modify the global
790 copy of it rather than working with a local copy.  In perl you can
791 refer to all objects of a particular name by prefixing the name
792 with a star: C<*foo>.  This is often known as a "typeglob", because the
793 star on the front can be thought of as a wildcard match for all the
794 funny prefix characters on variables and subroutines and such.
795
796 When evaluated, the typeglob produces a scalar value that represents
797 all the objects of that name, including any filehandle, format, or
798 subroutine.  When assigned to, it causes the name mentioned to refer to
799 whatever C<*> value was assigned to it.  Example:
800
801     sub doubleary {
802         local(*someary) = @_;
803         foreach $elem (@someary) {
804             $elem *= 2;
805         }
806     }
807     doubleary(*foo);
808     doubleary(*bar);
809
810 Scalars are already passed by reference, so you can modify
811 scalar arguments without using this mechanism by referring explicitly
812 to C<$_[0]> etc.  You can modify all the elements of an array by passing
813 all the elements as scalars, but you have to use the C<*> mechanism (or
814 the equivalent reference mechanism) to C<push>, C<pop>, or change the size of
815 an array.  It will certainly be faster to pass the typeglob (or reference).
816
817 Even if you don't want to modify an array, this mechanism is useful for
818 passing multiple arrays in a single LIST, because normally the LIST
819 mechanism will merge all the array values so that you can't extract out
820 the individual arrays.  For more on typeglobs, see
821 L<perldata/"Typeglobs and Filehandles">.
822
823 =head2 When to Still Use local()
824 X<local> X<variable, local>
825
826 Despite the existence of C<my>, there are still three places where the
827 C<local> operator still shines.  In fact, in these three places, you
828 I<must> use C<local> instead of C<my>.
829
830 =over 4
831
832 =item 1.
833
834 You need to give a global variable a temporary value, especially $_.
835
836 The global variables, like C<@ARGV> or the punctuation variables, must be 
837 C<local>ized with C<local()>.  This block reads in F</etc/motd>, and splits
838 it up into chunks separated by lines of equal signs, which are placed
839 in C<@Fields>.
840
841     {
842         local @ARGV = ("/etc/motd");
843         local $/ = undef;
844         local $_ = <>;  
845         @Fields = split /^\s*=+\s*$/;
846     } 
847
848 It particular, it's important to C<local>ize $_ in any routine that assigns
849 to it.  Look out for implicit assignments in C<while> conditionals.
850
851 =item 2.
852
853 You need to create a local file or directory handle or a local function.
854
855 A function that needs a filehandle of its own must use
856 C<local()> on a complete typeglob.   This can be used to create new symbol
857 table entries:
858
859     sub ioqueue {
860         local  (*READER, *WRITER);    # not my!
861         pipe    (READER,  WRITER)     or die "pipe: $!";
862         return (*READER, *WRITER);
863     }
864     ($head, $tail) = ioqueue();
865
866 See the Symbol module for a way to create anonymous symbol table
867 entries.
868
869 Because assignment of a reference to a typeglob creates an alias, this
870 can be used to create what is effectively a local function, or at least,
871 a local alias.
872
873     {
874         local *grow = \&shrink; # only until this block exists
875         grow();                 # really calls shrink()
876         move();                 # if move() grow()s, it shrink()s too
877     }
878     grow();                     # get the real grow() again
879
880 See L<perlref/"Function Templates"> for more about manipulating
881 functions by name in this way.
882
883 =item 3.
884
885 You want to temporarily change just one element of an array or hash.
886
887 You can C<local>ize just one element of an aggregate.  Usually this
888 is done on dynamics:
889
890     {
891         local $SIG{INT} = 'IGNORE';
892         funct();                            # uninterruptible
893     } 
894     # interruptibility automatically restored here
895
896 But it also works on lexically declared aggregates.  Prior to 5.005,
897 this operation could on occasion misbehave.
898
899 =back
900
901 =head2 Pass by Reference
902 X<pass by reference> X<pass-by-reference> X<reference>
903
904 If you want to pass more than one array or hash into a function--or
905 return them from it--and have them maintain their integrity, then
906 you're going to have to use an explicit pass-by-reference.  Before you
907 do that, you need to understand references as detailed in L<perlref>.
908 This section may not make much sense to you otherwise.
909
910 Here are a few simple examples.  First, let's pass in several arrays
911 to a function and have it C<pop> all of then, returning a new list
912 of all their former last elements:
913
914     @tailings = popmany ( \@a, \@b, \@c, \@d );
915
916     sub popmany {
917         my $aref;
918         my @retlist = ();
919         foreach $aref ( @_ ) {
920             push @retlist, pop @$aref;
921         }
922         return @retlist;
923     }
924
925 Here's how you might write a function that returns a
926 list of keys occurring in all the hashes passed to it:
927
928     @common = inter( \%foo, \%bar, \%joe );
929     sub inter {
930         my ($k, $href, %seen); # locals
931         foreach $href (@_) {
932             while ( $k = each %$href ) {
933                 $seen{$k}++;
934             }
935         }
936         return grep { $seen{$_} == @_ } keys %seen;
937     }
938
939 So far, we're using just the normal list return mechanism.
940 What happens if you want to pass or return a hash?  Well,
941 if you're using only one of them, or you don't mind them
942 concatenating, then the normal calling convention is ok, although
943 a little expensive.
944
945 Where people get into trouble is here:
946
947     (@a, @b) = func(@c, @d);
948 or
949     (%a, %b) = func(%c, %d);
950
951 That syntax simply won't work.  It sets just C<@a> or C<%a> and
952 clears the C<@b> or C<%b>.  Plus the function didn't get passed
953 into two separate arrays or hashes: it got one long list in C<@_>,
954 as always.
955
956 If you can arrange for everyone to deal with this through references, it's
957 cleaner code, although not so nice to look at.  Here's a function that
958 takes two array references as arguments, returning the two array elements
959 in order of how many elements they have in them:
960
961     ($aref, $bref) = func(\@c, \@d);
962     print "@$aref has more than @$bref\n";
963     sub func {
964         my ($cref, $dref) = @_;
965         if (@$cref > @$dref) {
966             return ($cref, $dref);
967         } else {
968             return ($dref, $cref);
969         }
970     }
971
972 It turns out that you can actually do this also:
973
974     (*a, *b) = func(\@c, \@d);
975     print "@a has more than @b\n";
976     sub func {
977         local (*c, *d) = @_;
978         if (@c > @d) {
979             return (\@c, \@d);
980         } else {
981             return (\@d, \@c);
982         }
983     }
984
985 Here we're using the typeglobs to do symbol table aliasing.  It's
986 a tad subtle, though, and also won't work if you're using C<my>
987 variables, because only globals (even in disguise as C<local>s)
988 are in the symbol table.
989
990 If you're passing around filehandles, you could usually just use the bare
991 typeglob, like C<*STDOUT>, but typeglobs references work, too.
992 For example:
993
994     splutter(\*STDOUT);
995     sub splutter {
996         my $fh = shift;
997         print $fh "her um well a hmmm\n";
998     }
999
1000     $rec = get_rec(\*STDIN);
1001     sub get_rec {
1002         my $fh = shift;
1003         return scalar <$fh>;
1004     }
1005
1006 If you're planning on generating new filehandles, you could do this.
1007 Notice to pass back just the bare *FH, not its reference.
1008
1009     sub openit {
1010         my $path = shift;
1011         local *FH;
1012         return open (FH, $path) ? *FH : undef;
1013     }
1014
1015 =head2 Prototypes
1016 X<prototype> X<subroutine, prototype>
1017
1018 Perl supports a very limited kind of compile-time argument checking
1019 using function prototyping.  If you declare
1020
1021     sub mypush (\@@)
1022
1023 then C<mypush()> takes arguments exactly like C<push()> does.  The
1024 function declaration must be visible at compile time.  The prototype
1025 affects only interpretation of new-style calls to the function,
1026 where new-style is defined as not using the C<&> character.  In
1027 other words, if you call it like a built-in function, then it behaves
1028 like a built-in function.  If you call it like an old-fashioned
1029 subroutine, then it behaves like an old-fashioned subroutine.  It
1030 naturally falls out from this rule that prototypes have no influence
1031 on subroutine references like C<\&foo> or on indirect subroutine
1032 calls like C<&{$subref}> or C<< $subref->() >>.
1033
1034 Method calls are not influenced by prototypes either, because the
1035 function to be called is indeterminate at compile time, since
1036 the exact code called depends on inheritance.
1037
1038 Because the intent of this feature is primarily to let you define
1039 subroutines that work like built-in functions, here are prototypes
1040 for some other functions that parse almost exactly like the
1041 corresponding built-in.
1042
1043     Declared as                 Called as
1044
1045     sub mylink ($$)          mylink $old, $new
1046     sub myvec ($$$)          myvec $var, $offset, 1
1047     sub myindex ($$;$)       myindex &getstring, "substr"
1048     sub mysyswrite ($$$;$)   mysyswrite $buf, 0, length($buf) - $off, $off
1049     sub myreverse (@)        myreverse $a, $b, $c
1050     sub myjoin ($@)          myjoin ":", $a, $b, $c
1051     sub mypop (\@)           mypop @array
1052     sub mysplice (\@$$@)     mysplice @array, @array, 0, @pushme
1053     sub mykeys (\%)          mykeys %{$hashref}
1054     sub myopen (*;$)         myopen HANDLE, $name
1055     sub mypipe (**)          mypipe READHANDLE, WRITEHANDLE
1056     sub mygrep (&@)          mygrep { /foo/ } $a, $b, $c
1057     sub myrand (;$)          myrand 42
1058     sub mytime ()            mytime
1059
1060 Any backslashed prototype character represents an actual argument
1061 that absolutely must start with that character.  The value passed
1062 as part of C<@_> will be a reference to the actual argument given
1063 in the subroutine call, obtained by applying C<\> to that argument.
1064
1065 You can also backslash several argument types simultaneously by using
1066 the C<\[]> notation:
1067
1068     sub myref (\[$@%&*])
1069
1070 will allow calling myref() as
1071
1072     myref $var
1073     myref @array
1074     myref %hash
1075     myref &sub
1076     myref *glob
1077
1078 and the first argument of myref() will be a reference to
1079 a scalar, an array, a hash, a code, or a glob.
1080
1081 Unbackslashed prototype characters have special meanings.  Any
1082 unbackslashed C<@> or C<%> eats all remaining arguments, and forces
1083 list context.  An argument represented by C<$> forces scalar context.  An
1084 C<&> requires an anonymous subroutine, which, if passed as the first
1085 argument, does not require the C<sub> keyword or a subsequent comma.
1086
1087 A C<*> allows the subroutine to accept a bareword, constant, scalar expression,
1088 typeglob, or a reference to a typeglob in that slot.  The value will be
1089 available to the subroutine either as a simple scalar, or (in the latter
1090 two cases) as a reference to the typeglob.  If you wish to always convert
1091 such arguments to a typeglob reference, use Symbol::qualify_to_ref() as
1092 follows:
1093
1094     use Symbol 'qualify_to_ref';
1095
1096     sub foo (*) {
1097         my $fh = qualify_to_ref(shift, caller);
1098         ...
1099     }
1100
1101 A semicolon (C<;>) separates mandatory arguments from optional arguments.
1102 It is redundant before C<@> or C<%>, which gobble up everything else.
1103
1104 As the last character of a prototype, or just before a semicolon, you can
1105 use C<_> in place of C<$>: if this argument is not provided, C<$_> will be
1106 used instead.
1107
1108 Note how the last three examples in the table above are treated
1109 specially by the parser.  C<mygrep()> is parsed as a true list
1110 operator, C<myrand()> is parsed as a true unary operator with unary
1111 precedence the same as C<rand()>, and C<mytime()> is truly without
1112 arguments, just like C<time()>.  That is, if you say
1113
1114     mytime +2;
1115
1116 you'll get C<mytime() + 2>, not C<mytime(2)>, which is how it would be parsed
1117 without a prototype.
1118
1119 The interesting thing about C<&> is that you can generate new syntax with it,
1120 provided it's in the initial position:
1121 X<&>
1122
1123     sub try (&@) {
1124         my($try,$catch) = @_;
1125         eval { &$try };
1126         if ($@) {
1127             local $_ = $@;
1128             &$catch;
1129         }
1130     }
1131     sub catch (&) { $_[0] }
1132
1133     try {
1134         die "phooey";
1135     } catch {
1136         /phooey/ and print "unphooey\n";
1137     };
1138
1139 That prints C<"unphooey">.  (Yes, there are still unresolved
1140 issues having to do with visibility of C<@_>.  I'm ignoring that
1141 question for the moment.  (But note that if we make C<@_> lexically
1142 scoped, those anonymous subroutines can act like closures... (Gee,
1143 is this sounding a little Lispish?  (Never mind.))))
1144
1145 And here's a reimplementation of the Perl C<grep> operator:
1146 X<grep>
1147
1148     sub mygrep (&@) {
1149         my $code = shift;
1150         my @result;
1151         foreach $_ (@_) {
1152             push(@result, $_) if &$code;
1153         }
1154         @result;
1155     }
1156
1157 Some folks would prefer full alphanumeric prototypes.  Alphanumerics have
1158 been intentionally left out of prototypes for the express purpose of
1159 someday in the future adding named, formal parameters.  The current
1160 mechanism's main goal is to let module writers provide better diagnostics
1161 for module users.  Larry feels the notation quite understandable to Perl
1162 programmers, and that it will not intrude greatly upon the meat of the
1163 module, nor make it harder to read.  The line noise is visually
1164 encapsulated into a small pill that's easy to swallow.
1165
1166 If you try to use an alphanumeric sequence in a prototype you will
1167 generate an optional warning - "Illegal character in prototype...".
1168 Unfortunately earlier versions of Perl allowed the prototype to be
1169 used as long as its prefix was a valid prototype.  The warning may be
1170 upgraded to a fatal error in a future version of Perl once the
1171 majority of offending code is fixed.
1172
1173 It's probably best to prototype new functions, not retrofit prototyping
1174 into older ones.  That's because you must be especially careful about
1175 silent impositions of differing list versus scalar contexts.  For example,
1176 if you decide that a function should take just one parameter, like this:
1177
1178     sub func ($) {
1179         my $n = shift;
1180         print "you gave me $n\n";
1181     }
1182
1183 and someone has been calling it with an array or expression
1184 returning a list:
1185
1186     func(@foo);
1187     func( split /:/ );
1188
1189 Then you've just supplied an automatic C<scalar> in front of their
1190 argument, which can be more than a bit surprising.  The old C<@foo>
1191 which used to hold one thing doesn't get passed in.  Instead,
1192 C<func()> now gets passed in a C<1>; that is, the number of elements
1193 in C<@foo>.  And the C<split> gets called in scalar context so it
1194 starts scribbling on your C<@_> parameter list.  Ouch!
1195
1196 This is all very powerful, of course, and should be used only in moderation
1197 to make the world a better place.
1198
1199 =head2 Constant Functions
1200 X<constant>
1201
1202 Functions with a prototype of C<()> are potential candidates for
1203 inlining.  If the result after optimization and constant folding
1204 is either a constant or a lexically-scoped scalar which has no other
1205 references, then it will be used in place of function calls made
1206 without C<&>.  Calls made using C<&> are never inlined.  (See
1207 F<constant.pm> for an easy way to declare most constants.)
1208
1209 The following functions would all be inlined:
1210
1211     sub pi ()           { 3.14159 }             # Not exact, but close.
1212     sub PI ()           { 4 * atan2 1, 1 }      # As good as it gets,
1213                                                 # and it's inlined, too!
1214     sub ST_DEV ()       { 0 }
1215     sub ST_INO ()       { 1 }
1216
1217     sub FLAG_FOO ()     { 1 << 8 }
1218     sub FLAG_BAR ()     { 1 << 9 }
1219     sub FLAG_MASK ()    { FLAG_FOO | FLAG_BAR }
1220
1221     sub OPT_BAZ ()      { not (0x1B58 & FLAG_MASK) }
1222
1223     sub N () { int(OPT_BAZ) / 3 }
1224
1225     sub FOO_SET () { 1 if FLAG_MASK & FLAG_FOO }
1226
1227 Be aware that these will not be inlined; as they contain inner scopes,
1228 the constant folding doesn't reduce them to a single constant:
1229
1230     sub foo_set () { if (FLAG_MASK & FLAG_FOO) { 1 } }
1231
1232     sub baz_val () {
1233         if (OPT_BAZ) {
1234             return 23;
1235         }
1236         else {
1237             return 42;
1238         }
1239     }
1240
1241 If you redefine a subroutine that was eligible for inlining, you'll get
1242 a mandatory warning.  (You can use this warning to tell whether or not a
1243 particular subroutine is considered constant.)  The warning is
1244 considered severe enough not to be optional because previously compiled
1245 invocations of the function will still be using the old value of the
1246 function.  If you need to be able to redefine the subroutine, you need to
1247 ensure that it isn't inlined, either by dropping the C<()> prototype
1248 (which changes calling semantics, so beware) or by thwarting the
1249 inlining mechanism in some other way, such as
1250
1251     sub not_inlined () {
1252         23 if $];
1253     }
1254
1255 =head2 Overriding Built-in Functions
1256 X<built-in> X<override> X<CORE> X<CORE::GLOBAL>
1257
1258 Many built-in functions may be overridden, though this should be tried
1259 only occasionally and for good reason.  Typically this might be
1260 done by a package attempting to emulate missing built-in functionality
1261 on a non-Unix system.
1262
1263 Overriding may be done only by importing the name from a module at
1264 compile time--ordinary predeclaration isn't good enough.  However, the
1265 C<use subs> pragma lets you, in effect, predeclare subs
1266 via the import syntax, and these names may then override built-in ones:
1267
1268     use subs 'chdir', 'chroot', 'chmod', 'chown';
1269     chdir $somewhere;
1270     sub chdir { ... }
1271
1272 To unambiguously refer to the built-in form, precede the
1273 built-in name with the special package qualifier C<CORE::>.  For example,
1274 saying C<CORE::open()> always refers to the built-in C<open()>, even
1275 if the current package has imported some other subroutine called
1276 C<&open()> from elsewhere.  Even though it looks like a regular
1277 function call, it isn't: you can't take a reference to it, such as
1278 the incorrect C<\&CORE::open> might appear to produce.
1279
1280 Library modules should not in general export built-in names like C<open>
1281 or C<chdir> as part of their default C<@EXPORT> list, because these may
1282 sneak into someone else's namespace and change the semantics unexpectedly.
1283 Instead, if the module adds that name to C<@EXPORT_OK>, then it's
1284 possible for a user to import the name explicitly, but not implicitly.
1285 That is, they could say
1286
1287     use Module 'open';
1288
1289 and it would import the C<open> override.  But if they said
1290
1291     use Module;
1292
1293 they would get the default imports without overrides.
1294
1295 The foregoing mechanism for overriding built-in is restricted, quite
1296 deliberately, to the package that requests the import.  There is a second
1297 method that is sometimes applicable when you wish to override a built-in
1298 everywhere, without regard to namespace boundaries.  This is achieved by
1299 importing a sub into the special namespace C<CORE::GLOBAL::>.  Here is an
1300 example that quite brazenly replaces the C<glob> operator with something
1301 that understands regular expressions.
1302
1303     package REGlob;
1304     require Exporter;
1305     @ISA = 'Exporter';
1306     @EXPORT_OK = 'glob';
1307
1308     sub import {
1309         my $pkg = shift;
1310         return unless @_;
1311         my $sym = shift;
1312         my $where = ($sym =~ s/^GLOBAL_// ? 'CORE::GLOBAL' : caller(0));
1313         $pkg->export($where, $sym, @_);
1314     }
1315
1316     sub glob {
1317         my $pat = shift;
1318         my @got;
1319         local *D;
1320         if (opendir D, '.') { 
1321             @got = grep /$pat/, readdir D; 
1322             closedir D;   
1323         }
1324         return @got;
1325     }
1326     1;
1327
1328 And here's how it could be (ab)used:
1329
1330     #use REGlob 'GLOBAL_glob';      # override glob() in ALL namespaces
1331     package Foo;
1332     use REGlob 'glob';              # override glob() in Foo:: only
1333     print for <^[a-z_]+\.pm\$>;     # show all pragmatic modules
1334
1335 The initial comment shows a contrived, even dangerous example.
1336 By overriding C<glob> globally, you would be forcing the new (and
1337 subversive) behavior for the C<glob> operator for I<every> namespace,
1338 without the complete cognizance or cooperation of the modules that own
1339 those namespaces.  Naturally, this should be done with extreme caution--if
1340 it must be done at all.
1341
1342 The C<REGlob> example above does not implement all the support needed to
1343 cleanly override perl's C<glob> operator.  The built-in C<glob> has
1344 different behaviors depending on whether it appears in a scalar or list
1345 context, but our C<REGlob> doesn't.  Indeed, many perl built-in have such
1346 context sensitive behaviors, and these must be adequately supported by
1347 a properly written override.  For a fully functional example of overriding
1348 C<glob>, study the implementation of C<File::DosGlob> in the standard
1349 library.
1350
1351 When you override a built-in, your replacement should be consistent (if
1352 possible) with the built-in native syntax.  You can achieve this by using
1353 a suitable prototype.  To get the prototype of an overridable built-in,
1354 use the C<prototype> function with an argument of C<"CORE::builtin_name">
1355 (see L<perlfunc/prototype>).
1356
1357 Note however that some built-ins can't have their syntax expressed by a
1358 prototype (such as C<system> or C<chomp>).  If you override them you won't
1359 be able to fully mimic their original syntax.
1360
1361 The built-ins C<do>, C<require> and C<glob> can also be overridden, but due
1362 to special magic, their original syntax is preserved, and you don't have
1363 to define a prototype for their replacements.  (You can't override the
1364 C<do BLOCK> syntax, though).
1365
1366 C<require> has special additional dark magic: if you invoke your
1367 C<require> replacement as C<require Foo::Bar>, it will actually receive
1368 the argument C<"Foo/Bar.pm"> in @_.  See L<perlfunc/require>.
1369
1370 And, as you'll have noticed from the previous example, if you override
1371 C<glob>, the C<< <*> >> glob operator is overridden as well.
1372
1373 In a similar fashion, overriding the C<readline> function also overrides
1374 the equivalent I/O operator C<< <FILEHANDLE> >>.
1375
1376 Finally, some built-ins (e.g. C<exists> or C<grep>) can't be overridden.
1377
1378 =head2 Autoloading
1379 X<autoloading> X<AUTOLOAD>
1380
1381 If you call a subroutine that is undefined, you would ordinarily
1382 get an immediate, fatal error complaining that the subroutine doesn't
1383 exist.  (Likewise for subroutines being used as methods, when the
1384 method doesn't exist in any base class of the class's package.)
1385 However, if an C<AUTOLOAD> subroutine is defined in the package or
1386 packages used to locate the original subroutine, then that
1387 C<AUTOLOAD> subroutine is called with the arguments that would have
1388 been passed to the original subroutine.  The fully qualified name
1389 of the original subroutine magically appears in the global $AUTOLOAD
1390 variable of the same package as the C<AUTOLOAD> routine.  The name
1391 is not passed as an ordinary argument because, er, well, just
1392 because, that's why.  (As an exception, a method call to a nonexistent
1393 C<import> or C<unimport> method is just skipped instead.)
1394
1395 Many C<AUTOLOAD> routines load in a definition for the requested
1396 subroutine using eval(), then execute that subroutine using a special
1397 form of goto() that erases the stack frame of the C<AUTOLOAD> routine
1398 without a trace.  (See the source to the standard module documented
1399 in L<AutoLoader>, for example.)  But an C<AUTOLOAD> routine can
1400 also just emulate the routine and never define it.   For example,
1401 let's pretend that a function that wasn't defined should just invoke
1402 C<system> with those arguments.  All you'd do is:
1403
1404     sub AUTOLOAD {
1405         my $program = $AUTOLOAD;
1406         $program =~ s/.*:://;
1407         system($program, @_);
1408     }
1409     date();
1410     who('am', 'i');
1411     ls('-l');
1412
1413 In fact, if you predeclare functions you want to call that way, you don't
1414 even need parentheses:
1415
1416     use subs qw(date who ls);
1417     date;
1418     who "am", "i";
1419     ls '-l';
1420
1421 A more complete example of this is the standard Shell module, which
1422 can treat undefined subroutine calls as calls to external programs.
1423
1424 Mechanisms are available to help modules writers split their modules
1425 into autoloadable files.  See the standard AutoLoader module
1426 described in L<AutoLoader> and in L<AutoSplit>, the standard
1427 SelfLoader modules in L<SelfLoader>, and the document on adding C
1428 functions to Perl code in L<perlxs>.
1429
1430 =head2 Subroutine Attributes
1431 X<attribute> X<subroutine, attribute> X<attrs>
1432
1433 A subroutine declaration or definition may have a list of attributes
1434 associated with it.  If such an attribute list is present, it is
1435 broken up at space or colon boundaries and treated as though a
1436 C<use attributes> had been seen.  See L<attributes> for details
1437 about what attributes are currently supported.
1438 Unlike the limitation with the obsolescent C<use attrs>, the
1439 C<sub : ATTRLIST> syntax works to associate the attributes with
1440 a pre-declaration, and not just with a subroutine definition.
1441
1442 The attributes must be valid as simple identifier names (without any
1443 punctuation other than the '_' character).  They may have a parameter
1444 list appended, which is only checked for whether its parentheses ('(',')')
1445 nest properly.
1446
1447 Examples of valid syntax (even though the attributes are unknown):
1448
1449     sub fnord (&\%) : switch(10,foo(7,3))  :  expensive;
1450     sub plugh () : Ugly('\(") :Bad;
1451     sub xyzzy : _5x5 { ... }
1452
1453 Examples of invalid syntax:
1454
1455     sub fnord : switch(10,foo(); # ()-string not balanced
1456     sub snoid : Ugly('(');        # ()-string not balanced
1457     sub xyzzy : 5x5;              # "5x5" not a valid identifier
1458     sub plugh : Y2::north;        # "Y2::north" not a simple identifier
1459     sub snurt : foo + bar;        # "+" not a colon or space
1460
1461 The attribute list is passed as a list of constant strings to the code
1462 which associates them with the subroutine.  In particular, the second example
1463 of valid syntax above currently looks like this in terms of how it's
1464 parsed and invoked:
1465
1466     use attributes __PACKAGE__, \&plugh, q[Ugly('\(")], 'Bad';
1467
1468 For further details on attribute lists and their manipulation,
1469 see L<attributes> and L<Attribute::Handlers>.
1470
1471 =head1 SEE ALSO
1472
1473 See L<perlref/"Function Templates"> for more about references and closures.
1474 See L<perlxs> if you'd like to learn about calling C subroutines from Perl.  
1475 See L<perlembed> if you'd like to learn about calling Perl subroutines from C.  
1476 See L<perlmod> to learn about bundling up your functions in separate files.
1477 See L<perlmodlib> to learn what library modules come standard on your system.
1478 See L<perltoot> to learn how to make object method calls.