This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
7a5b81ea46464fd341ec834fe1439254c374b957
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_05';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     @cmdfhs
631     $CommandSet
632     $CreateTTY
633     $DBGR
634     @dbline
635     $dbline
636     %dbline
637     $dieLevel
638     $evalarg
639     $filename
640     $frame
641     $hist
642     $histfile
643     $histsize
644     $ImmediateStop
645     $IN
646     $inhibit_exit
647     @ini_INC
648     $ini_warn
649     $line
650     $maxtrace
651     $od
652     $onetimeDump
653     $onetimedumpDepth
654     %option
655     @options
656     $osingle
657     $otrace
658     $OUT
659     $packname
660     $pager
661     $post
662     %postponed
663     $prc
664     $pre
665     $pretype
666     $psh
667     @RememberOnROptions
668     $remoteport
669     @res
670     $rl
671     @saved
672     $signal
673     $signalLevel
674     $single
675     $start
676     $sub
677     %sub
678     $subname
679     $term
680     $trace
681     $usercontext
682     $warnLevel
683     $window
684 );
685
686 # Used to save @ARGV and extract any debugger-related flags.
687 use vars qw(@ARGS);
688
689 # Used to prevent multiple entries to diesignal()
690 # (if for instance diesignal() itself dies)
691 use vars qw($panic);
692
693 # Used to prevent the debugger from running nonstop
694 # after a restart
695 use vars qw($second_time);
696
697 sub _calc_usercontext {
698     my ($package) = @_;
699
700     # Cancel strict completely for the evaluated code, so the code
701     # the user evaluates won't be affected by it. (Shlomi Fish)
702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
703     . "package $package;";    # this won't let them modify, alas
704 }
705
706 sub eval {
707
708     # 'my' would make it visible from user code
709     #    but so does local! --tchrist
710     # Remember: this localizes @DB::res, not @main::res.
711     local @res;
712     {
713
714         # Try to keep the user code from messing  with us. Save these so that
715         # even if the eval'ed code changes them, we can put them back again.
716         # Needed because the user could refer directly to the debugger's
717         # package globals (and any 'my' variables in this containing scope)
718         # inside the eval(), and we want to try to stay safe.
719         local $otrace  = $trace;
720         local $osingle = $single;
721         local $od      = $^D;
722
723         # Untaint the incoming eval() argument.
724         { ($evalarg) = $evalarg =~ /(.*)/s; }
725
726         # $usercontext built in DB::DB near the comment
727         # "set up the context for DB::eval ..."
728         # Evaluate and save any results.
729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
730
731         # Restore those old values.
732         $trace  = $otrace;
733         $single = $osingle;
734         $^D     = $od;
735     }
736
737     # Save the current value of $@, and preserve it in the debugger's copy
738     # of the saved precious globals.
739     my $at = $@;
740
741     # Since we're only saving $@, we only have to localize the array element
742     # that it will be stored in.
743     local $saved[0];    # Preserve the old value of $@
744     eval { DB::save() };
745
746     # Now see whether we need to report an error back to the user.
747     if ($at) {
748         local $\ = '';
749         print $OUT $at;
750     }
751
752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
753     # are package globals.
754     elsif ($onetimeDump) {
755         if ( $onetimeDump eq 'dump' ) {
756             local $option{dumpDepth} = $onetimedumpDepth
757               if defined $onetimedumpDepth;
758             dumpit( $OUT, \@res );
759         }
760         elsif ( $onetimeDump eq 'methods' ) {
761             methods( $res[0] );
762         }
763     } ## end elsif ($onetimeDump)
764     @res;
765 } ## end sub eval
766
767 ############################################## End lexical danger zone
768
769 # After this point it is safe to introduce lexicals.
770 # The code being debugged will be executing in its own context, and
771 # can't see the inside of the debugger.
772 #
773 # However, one should not overdo it: leave as much control from outside as
774 # possible. If you make something a lexical, it's not going to be addressable
775 # from outside the debugger even if you know its name.
776
777 # This file is automatically included if you do perl -d.
778 # It's probably not useful to include this yourself.
779 #
780 # Before venturing further into these twisty passages, it is
781 # wise to read the perldebguts man page or risk the ire of dragons.
782 #
783 # (It should be noted that perldebguts will tell you a lot about
784 # the underlying mechanics of how the debugger interfaces into the
785 # Perl interpreter, but not a lot about the debugger itself. The new
786 # comments in this code try to address this problem.)
787
788 # Note that no subroutine call is possible until &DB::sub is defined
789 # (for subroutines defined outside of the package DB). In fact the same is
790 # true if $deep is not defined.
791
792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
793
794 # modified Perl debugger, to be run from Emacs in perldb-mode
795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
796 # Johan Vromans -- upgrade to 4.0 pl 10
797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
798 ########################################################################
799
800 =head1 DEBUGGER INITIALIZATION
801
802 The debugger starts up in phases.
803
804 =head2 BASIC SETUP
805
806 First, it initializes the environment it wants to run in: turning off
807 warnings during its own compilation, defining variables which it will need
808 to avoid warnings later, setting itself up to not exit when the program
809 terminates, and defaulting to printing return values for the C<r> command.
810
811 =cut
812
813 # Needed for the statement after exec():
814 #
815 # This BEGIN block is simply used to switch off warnings during debugger
816 # compilation. Probably it would be better practice to fix the warnings,
817 # but this is how it's done at the moment.
818
819 BEGIN {
820     $ini_warn = $^W;
821     $^W       = 0;
822 }    # Switch compilation warnings off until another BEGIN.
823
824 local ($^W) = 0;    # Switch run-time warnings off during init.
825
826 =head2 THREADS SUPPORT
827
828 If we are running under a threaded Perl, we require threads and threads::shared
829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
830 threaded debugger control.  C<-dt> can also be used to set this.
831
832 Each new thread will be announced and the debugger prompt will always inform
833 you of each new thread created.  It will also indicate the thread id in which
834 we are currently running within the prompt like this:
835
836         [tid] DB<$i>
837
838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
839 command prompt.  The prompt will show: C<[0]> when running under threads, but
840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
841
842 While running under threads, when you set or delete a breakpoint (etc.), this
843 will apply to all threads, not just the currently running one.  When you are
844 in a currently executing thread, you will stay there until it completes.  With
845 the current implementation it is not currently possible to hop from one thread
846 to another.
847
848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
849
850 Note that threading support was built into the debugger as of Perl version
851 C<5.8.6> and debugger version C<1.2.8>.
852
853 =cut
854
855 BEGIN {
856   # ensure we can share our non-threaded variables or no-op
857   if ($ENV{PERL5DB_THREADED}) {
858         require threads;
859         require threads::shared;
860         import threads::shared qw(share);
861         $DBGR;
862         share(\$DBGR);
863         lock($DBGR);
864         print "Threads support enabled\n";
865   } else {
866         *lock  = sub(*) {};
867         *share = sub(*) {};
868   }
869 }
870
871 # These variables control the execution of 'dumpvar.pl'.
872 {
873     package dumpvar;
874     use vars qw(
875     $hashDepth
876     $arrayDepth
877     $dumpDBFiles
878     $dumpPackages
879     $quoteHighBit
880     $printUndef
881     $globPrint
882     $usageOnly
883     );
884 }
885
886 # used to control die() reporting in diesignal()
887 {
888     package Carp;
889     use vars qw($CarpLevel);
890 }
891
892 # without threads, $filename is not defined until DB::DB is called
893 foreach my $k (keys (%INC)) {
894         share(\$main::{'_<'.$filename}) if defined $filename;
895 };
896
897 # Command-line + PERLLIB:
898 # Save the contents of @INC before they are modified elsewhere.
899 @ini_INC = @INC;
900
901 # This was an attempt to clear out the previous values of various
902 # trapped errors. Apparently it didn't help. XXX More info needed!
903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
904
905 # We set these variables to safe values. We don't want to blindly turn
906 # off warnings, because other packages may still want them.
907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
908                                    # (local $^W cannot help - other packages!).
909
910 # Default to not exiting when program finishes; print the return
911 # value when the 'r' command is used to return from a subroutine.
912 $inhibit_exit = $option{PrintRet} = 1;
913
914 use vars qw($trace_to_depth);
915
916 # Default to 1E9 so it won't be limited to a certain recursion depth.
917 $trace_to_depth = 1E9;
918
919 =head1 OPTION PROCESSING
920
921 The debugger's options are actually spread out over the debugger itself and
922 C<dumpvar.pl>; some of these are variables to be set, while others are
923 subs to be called with a value. To try to make this a little easier to
924 manage, the debugger uses a few data structures to define what options
925 are legal and how they are to be processed.
926
927 First, the C<@options> array defines the I<names> of all the options that
928 are to be accepted.
929
930 =cut
931
932 @options = qw(
933   CommandSet   HistFile      HistSize
934   hashDepth    arrayDepth    dumpDepth
935   DumpDBFiles  DumpPackages  DumpReused
936   compactDump  veryCompact   quote
937   HighBit      undefPrint    globPrint
938   PrintRet     UsageOnly     frame
939   AutoTrace    TTY           noTTY
940   ReadLine     NonStop       LineInfo
941   maxTraceLen  recallCommand ShellBang
942   pager        tkRunning     ornaments
943   signalLevel  warnLevel     dieLevel
944   inhibit_exit ImmediateStop bareStringify
945   CreateTTY    RemotePort    windowSize
946   DollarCaretP
947 );
948
949 @RememberOnROptions = qw(DollarCaretP);
950
951 =pod
952
953 Second, C<optionVars> lists the variables that each option uses to save its
954 state.
955
956 =cut
957
958 use vars qw(%optionVars);
959
960 %optionVars = (
961     hashDepth     => \$dumpvar::hashDepth,
962     arrayDepth    => \$dumpvar::arrayDepth,
963     CommandSet    => \$CommandSet,
964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
965     DumpPackages  => \$dumpvar::dumpPackages,
966     DumpReused    => \$dumpvar::dumpReused,
967     HighBit       => \$dumpvar::quoteHighBit,
968     undefPrint    => \$dumpvar::printUndef,
969     globPrint     => \$dumpvar::globPrint,
970     UsageOnly     => \$dumpvar::usageOnly,
971     CreateTTY     => \$CreateTTY,
972     bareStringify => \$dumpvar::bareStringify,
973     frame         => \$frame,
974     AutoTrace     => \$trace,
975     inhibit_exit  => \$inhibit_exit,
976     maxTraceLen   => \$maxtrace,
977     ImmediateStop => \$ImmediateStop,
978     RemotePort    => \$remoteport,
979     windowSize    => \$window,
980     HistFile      => \$histfile,
981     HistSize      => \$histsize,
982 );
983
984 =pod
985
986 Third, C<%optionAction> defines the subroutine to be called to process each
987 option.
988
989 =cut
990
991 use vars qw(%optionAction);
992
993 %optionAction = (
994     compactDump   => \&dumpvar::compactDump,
995     veryCompact   => \&dumpvar::veryCompact,
996     quote         => \&dumpvar::quote,
997     TTY           => \&TTY,
998     noTTY         => \&noTTY,
999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 use vars qw($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(@hist @truehist %postponed_file @typeahead);
1381
1382 sub _restore_shared_globals_after_restart
1383 {
1384     @hist          = get_list('PERLDB_HIST');
1385     %break_on_load = get_list("PERLDB_ON_LOAD");
1386     %postponed     = get_list("PERLDB_POSTPONE");
1387
1388     share(@hist);
1389     share(@truehist);
1390     share(%break_on_load);
1391     share(%postponed);
1392 }
1393
1394 sub _restore_breakpoints_and_actions {
1395
1396     my @had_breakpoints = get_list("PERLDB_VISITED");
1397
1398     for my $file_idx ( 0 .. $#had_breakpoints ) {
1399         my $filename = $had_breakpoints[$file_idx];
1400         my %pf = get_list("PERLDB_FILE_$file_idx");
1401         $postponed_file{ $filename } = \%pf if %pf;
1402         my @lines = sort {$a <=> $b} keys(%pf);
1403         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1404         for my $line_idx (0 .. $#lines) {
1405             _set_breakpoint_enabled_status(
1406                 $filename,
1407                 $lines[$line_idx],
1408                 ($enabled_statuses[$line_idx] ? 1 : ''),
1409             );
1410         }
1411     }
1412
1413     return;
1414 }
1415
1416 sub _restore_options_after_restart
1417 {
1418     my %options_map = get_list("PERLDB_OPT");
1419
1420     while ( my ( $opt, $val ) = each %options_map ) {
1421         $val =~ s/[\\\']/\\$1/g;
1422         parse_options("$opt'$val'");
1423     }
1424
1425     return;
1426 }
1427
1428 sub _restore_globals_after_restart
1429 {
1430     # restore original @INC
1431     @INC     = get_list("PERLDB_INC");
1432     @ini_INC = @INC;
1433
1434     # return pre/postprompt actions and typeahead buffer
1435     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1436     $pre       = [ get_list("PERLDB_PRE") ];
1437     $post      = [ get_list("PERLDB_POST") ];
1438     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1439
1440     return;
1441 }
1442
1443
1444 if ( exists $ENV{PERLDB_RESTART} ) {
1445
1446     # We're restarting, so we don't need the flag that says to restart anymore.
1447     delete $ENV{PERLDB_RESTART};
1448
1449     # $restart = 1;
1450     _restore_shared_globals_after_restart();
1451
1452     _restore_breakpoints_and_actions();
1453
1454     # restore options
1455     _restore_options_after_restart();
1456
1457     _restore_globals_after_restart();
1458 } ## end if (exists $ENV{PERLDB_RESTART...
1459
1460 =head2 SETTING UP THE TERMINAL
1461
1462 Now, we'll decide how the debugger is going to interact with the user.
1463 If there's no TTY, we set the debugger to run non-stop; there's not going
1464 to be anyone there to enter commands.
1465
1466 =cut
1467
1468 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1469 use vars qw($lineinfo $doccmd);
1470
1471 if ($notty) {
1472     $runnonstop = 1;
1473         share($runnonstop);
1474 }
1475
1476 =pod
1477
1478 If there is a TTY, we have to determine who it belongs to before we can
1479 proceed. If this is a slave editor or graphical debugger (denoted by
1480 the first command-line switch being '-emacs'), we shift this off and
1481 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1482
1483 =cut
1484
1485 else {
1486
1487     # Is Perl being run from a slave editor or graphical debugger?
1488     # If so, don't use readline, and set $slave_editor = 1.
1489     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1490         $rl = 0;
1491         shift(@main::ARGV);
1492     }
1493
1494     #require Term::ReadLine;
1495
1496 =pod
1497
1498 We then determine what the console should be on various systems:
1499
1500 =over 4
1501
1502 =item * Cygwin - We use C<stdin> instead of a separate device.
1503
1504 =cut
1505
1506     if ( $^O eq 'cygwin' ) {
1507
1508         # /dev/tty is binary. use stdin for textmode
1509         undef $console;
1510     }
1511
1512 =item * Unix - use C</dev/tty>.
1513
1514 =cut
1515
1516     elsif ( -e "/dev/tty" ) {
1517         $console = "/dev/tty";
1518     }
1519
1520 =item * Windows or MSDOS - use C<con>.
1521
1522 =cut
1523
1524     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1525         $console = "con";
1526     }
1527
1528 =item * VMS - use C<sys$command>.
1529
1530 =cut
1531
1532     else {
1533
1534         # everything else is ...
1535         $console = "sys\$command";
1536     }
1537
1538 =pod
1539
1540 =back
1541
1542 Several other systems don't use a specific console. We C<undef $console>
1543 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1544 with a slave editor, Epoc).
1545
1546 =cut
1547
1548     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1549
1550         # /dev/tty is binary. use stdin for textmode
1551         $console = undef;
1552     }
1553
1554     if ( $^O eq 'NetWare' ) {
1555
1556         # /dev/tty is binary. use stdin for textmode
1557         $console = undef;
1558     }
1559
1560     # In OS/2, we need to use STDIN to get textmode too, even though
1561     # it pretty much looks like Unix otherwise.
1562     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1563     {    # In OS/2
1564         $console = undef;
1565     }
1566
1567     # EPOC also falls into the 'got to use STDIN' camp.
1568     if ( $^O eq 'epoc' ) {
1569         $console = undef;
1570     }
1571
1572 =pod
1573
1574 If there is a TTY hanging around from a parent, we use that as the console.
1575
1576 =cut
1577
1578     $console = $tty if defined $tty;
1579
1580 =head2 SOCKET HANDLING
1581
1582 The debugger is capable of opening a socket and carrying out a debugging
1583 session over the socket.
1584
1585 If C<RemotePort> was defined in the options, the debugger assumes that it
1586 should try to start a debugging session on that port. It builds the socket
1587 and then tries to connect the input and output filehandles to it.
1588
1589 =cut
1590
1591     # Handle socket stuff.
1592
1593     if ( defined $remoteport ) {
1594
1595         # If RemotePort was defined in the options, connect input and output
1596         # to the socket.
1597         $IN = $OUT = connect_remoteport();
1598     } ## end if (defined $remoteport)
1599
1600 =pod
1601
1602 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1603 this is probably a situation where multiple debuggers are running (for example,
1604 a backticked command that starts up another debugger). We create a new IN and
1605 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1606 and if we can.
1607
1608 =cut
1609
1610     # Non-socket.
1611     else {
1612
1613         # Two debuggers running (probably a system or a backtick that invokes
1614         # the debugger itself under the running one). create a new IN and OUT
1615         # filehandle, and do the necessary mojo to create a new tty if we
1616         # know how, and we can.
1617         create_IN_OUT(4) if $CreateTTY & 4;
1618         if ($console) {
1619
1620             # If we have a console, check to see if there are separate ins and
1621             # outs to open. (They are assumed identical if not.)
1622
1623             my ( $i, $o ) = split /,/, $console;
1624             $o = $i unless defined $o;
1625
1626             # read/write on in, or just read, or read on STDIN.
1627             open( IN,      "+<$i" )
1628               || open( IN, "<$i" )
1629               || open( IN, "<&STDIN" );
1630
1631             # read/write/create/clobber out, or write/create/clobber out,
1632             # or merge with STDERR, or merge with STDOUT.
1633                  open( OUT, "+>$o" )
1634               || open( OUT, ">$o" )
1635               || open( OUT, ">&STDERR" )
1636               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1637
1638         } ## end if ($console)
1639         elsif ( not defined $console ) {
1640
1641             # No console. Open STDIN.
1642             open( IN, "<&STDIN" );
1643
1644             # merge with STDERR, or with STDOUT.
1645             open( OUT,      ">&STDERR" )
1646               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1647             $console = 'STDIN/OUT';
1648         } ## end elsif (not defined $console)
1649
1650         # Keep copies of the filehandles so that when the pager runs, it
1651         # can close standard input without clobbering ours.
1652         if ($console or (not defined($console))) {
1653             $IN = \*IN;
1654             $OUT = \*OUT;
1655         }
1656     } ## end elsif (from if(defined $remoteport))
1657
1658     # Unbuffer DB::OUT. We need to see responses right away.
1659     $OUT->autoflush(1);
1660
1661     # Line info goes to debugger output unless pointed elsewhere.
1662     # Pointing elsewhere makes it possible for slave editors to
1663     # keep track of file and position. We have both a filehandle
1664     # and a I/O description to keep track of.
1665     $LINEINFO = $OUT     unless defined $LINEINFO;
1666     $lineinfo = $console unless defined $lineinfo;
1667         # share($LINEINFO); # <- unable to share globs
1668         share($lineinfo);   #
1669
1670 =pod
1671
1672 To finish initialization, we show the debugger greeting,
1673 and then call the C<afterinit()> subroutine if there is one.
1674
1675 =cut
1676
1677     # Show the debugger greeting.
1678     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1679     unless ($runnonstop) {
1680         local $\ = '';
1681         local $, = '';
1682         if ( $term_pid eq '-1' ) {
1683             print $OUT "\nDaughter DB session started...\n";
1684         }
1685         else {
1686             print $OUT "\nLoading DB routines from $header\n";
1687             print $OUT (
1688                 "Editor support ",
1689                 $slave_editor ? "enabled" : "available", ".\n"
1690             );
1691             print $OUT
1692 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1693         } ## end else [ if ($term_pid eq '-1')
1694     } ## end unless ($runnonstop)
1695 } ## end else [ if ($notty)
1696
1697 # XXX This looks like a bug to me.
1698 # Why copy to @ARGS and then futz with @args?
1699 @ARGS = @ARGV;
1700 # for (@args) {
1701     # Make sure backslashes before single quotes are stripped out, and
1702     # keep args unless they are numeric (XXX why?)
1703     # s/\'/\\\'/g;                      # removed while not justified understandably
1704     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1705 # }
1706
1707 # If there was an afterinit() sub defined, call it. It will get
1708 # executed in our scope, so it can fiddle with debugger globals.
1709 if ( defined &afterinit ) {    # May be defined in $rcfile
1710     afterinit();
1711 }
1712
1713 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1714 use vars qw($I_m_init);
1715
1716 $I_m_init = 1;
1717
1718 ############################################################ Subroutines
1719
1720 =head1 SUBROUTINES
1721
1722 =head2 DB
1723
1724 This gigantic subroutine is the heart of the debugger. Called before every
1725 statement, its job is to determine if a breakpoint has been reached, and
1726 stop if so; read commands from the user, parse them, and execute
1727 them, and then send execution off to the next statement.
1728
1729 Note that the order in which the commands are processed is very important;
1730 some commands earlier in the loop will actually alter the C<$cmd> variable
1731 to create other commands to be executed later. This is all highly I<optimized>
1732 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1733 see what's happening in any given command.
1734
1735 =cut
1736
1737 use vars qw(
1738     $action
1739     %alias
1740     $cmd
1741     $doret
1742     $fall_off_end
1743     $file
1744     $filename_ini
1745     $finished
1746     %had_breakpoints
1747     $incr
1748     $laststep
1749     $level
1750     $max
1751     @old_watch
1752     $package
1753     $rc
1754     $sh
1755     @stack
1756     $stack_depth
1757     @to_watch
1758     $try
1759     $end
1760 );
1761
1762 sub _DB__determine_if_we_should_break
1763 {
1764     # if we have something here, see if we should break.
1765     # $stop is lexical and local to this block - $action on the other hand
1766     # is global.
1767     my $stop;
1768
1769     if ( $dbline{$line}
1770         && _is_breakpoint_enabled($filename, $line)
1771         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1772     {
1773
1774         # Stop if the stop criterion says to just stop.
1775         if ( $stop eq '1' ) {
1776             $signal |= 1;
1777         }
1778
1779         # It's a conditional stop; eval it in the user's context and
1780         # see if we should stop. If so, remove the one-time sigil.
1781         elsif ($stop) {
1782             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1783             &eval;
1784             # If the breakpoint is temporary, then delete its enabled status.
1785             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1786                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1787             }
1788         }
1789     } ## end if ($dbline{$line} && ...
1790 }
1791
1792 sub _DB__is_finished {
1793     if ($finished and $level <= 1) {
1794         end_report();
1795         return 1;
1796     }
1797     else {
1798         return;
1799     }
1800 }
1801
1802 sub _DB__read_next_cmd
1803 {
1804     my ($tid) = @_;
1805
1806     # We have a terminal, or can get one ...
1807     if (!$term) {
1808         setterm();
1809     }
1810
1811     # ... and it belogs to this PID or we get one for this PID ...
1812     if ($term_pid != $$) {
1813         resetterm(1);
1814     }
1815
1816     # ... and we got a line of command input ...
1817     $cmd = DB::readline(
1818         "$pidprompt $tid DB"
1819         . ( '<' x $level )
1820         . ( $#hist + 1 )
1821         . ( '>' x $level ) . " "
1822     );
1823
1824     return defined($cmd);
1825 }
1826
1827 sub DB {
1828
1829     # lock the debugger and get the thread id for the prompt
1830     lock($DBGR);
1831     my $tid;
1832     my $position;
1833     my ($prefix, $after, $infix);
1834     my $pat;
1835     my $explicit_stop;
1836
1837     if ($ENV{PERL5DB_THREADED}) {
1838         $tid = eval { "[".threads->tid."]" };
1839     }
1840
1841     my $obj = DB::Obj->new(
1842         {
1843             position => \$position,
1844             prefix => \$prefix,
1845             after => \$after,
1846             explicit_stop => \$explicit_stop,
1847             infix => \$infix,
1848         },
1849     );
1850
1851     $obj->_DB_on_init__initialize_globals(@_);
1852
1853     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1854     # The code being debugged may have altered them.
1855     &save;
1856
1857     # Since DB::DB gets called after every line, we can use caller() to
1858     # figure out where we last were executing. Sneaky, eh? This works because
1859     # caller is returning all the extra information when called from the
1860     # debugger.
1861     local ( $package, $filename, $line ) = caller;
1862     $filename_ini = $filename;
1863
1864     # set up the context for DB::eval, so it can properly execute
1865     # code on behalf of the user. We add the package in so that the
1866     # code is eval'ed in the proper package (not in the debugger!).
1867     local $usercontext = _calc_usercontext($package);
1868
1869     # Create an alias to the active file magical array to simplify
1870     # the code here.
1871     local (*dbline) = $main::{ '_<' . $filename };
1872
1873     # Last line in the program.
1874     $max = $#dbline;
1875
1876     _DB__determine_if_we_should_break(@_);
1877
1878     # Preserve the current stop-or-not, and see if any of the W
1879     # (watch expressions) has changed.
1880     my $was_signal = $signal;
1881
1882     # If we have any watch expressions ...
1883     $obj->_DB__handle_watch_expressions(@_);
1884
1885 =head2 C<watchfunction()>
1886
1887 C<watchfunction()> is a function that can be defined by the user; it is a
1888 function which will be run on each entry to C<DB::DB>; it gets the
1889 current package, filename, and line as its parameters.
1890
1891 The watchfunction can do anything it likes; it is executing in the
1892 debugger's context, so it has access to all of the debugger's internal
1893 data structures and functions.
1894
1895 C<watchfunction()> can control the debugger's actions. Any of the following
1896 will cause the debugger to return control to the user's program after
1897 C<watchfunction()> executes:
1898
1899 =over 4
1900
1901 =item *
1902
1903 Returning a false value from the C<watchfunction()> itself.
1904
1905 =item *
1906
1907 Altering C<$single> to a false value.
1908
1909 =item *
1910
1911 Altering C<$signal> to a false value.
1912
1913 =item *
1914
1915 Turning off the C<4> bit in C<$trace> (this also disables the
1916 check for C<watchfunction()>. This can be done with
1917
1918     $trace &= ~4;
1919
1920 =back
1921
1922 =cut
1923
1924     # If there's a user-defined DB::watchfunction, call it with the
1925     # current package, filename, and line. The function executes in
1926     # the DB:: package.
1927     if ( $trace & 4 ) {    # User-installed watch
1928         return
1929           if watchfunction( $package, $filename, $line )
1930           and not $single
1931           and not $was_signal
1932           and not( $trace & ~4 );
1933     } ## end if ($trace & 4)
1934
1935     # Pick up any alteration to $signal in the watchfunction, and
1936     # turn off the signal now.
1937     $was_signal = $signal;
1938     $signal     = 0;
1939
1940 =head2 GETTING READY TO EXECUTE COMMANDS
1941
1942 The debugger decides to take control if single-step mode is on, the
1943 C<t> command was entered, or the user generated a signal. If the program
1944 has fallen off the end, we set things up so that entering further commands
1945 won't cause trouble, and we say that the program is over.
1946
1947 =cut
1948
1949     # Make sure that we always print if asked for explicitly regardless
1950     # of $trace_to_depth .
1951     $explicit_stop = ($single || $was_signal);
1952
1953     # Check to see if we should grab control ($single true,
1954     # trace set appropriately, or we got a signal).
1955     if ( $explicit_stop || ( $trace & 1 ) ) {
1956         $obj->_DB__grab_control(@_);
1957     } ## end if ($single || ($trace...
1958
1959 =pod
1960
1961 If there's an action to be executed for the line we stopped at, execute it.
1962 If there are any preprompt actions, execute those as well.
1963
1964 =cut
1965
1966     # If there's an action, do it now.
1967     if ($action) {
1968         $evalarg = $action;
1969         DB::eval();
1970     }
1971
1972     # Are we nested another level (e.g., did we evaluate a function
1973     # that had a breakpoint in it at the debugger prompt)?
1974     if ( $single || $was_signal ) {
1975
1976         # Yes, go down a level.
1977         local $level = $level + 1;
1978
1979         # Do any pre-prompt actions.
1980         foreach $evalarg (@$pre) {
1981             DB::eval();
1982         }
1983
1984         # Complain about too much recursion if we passed the limit.
1985         if ($single & 4) {
1986             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
1987         }
1988
1989         # The line we're currently on. Set $incr to -1 to stay here
1990         # until we get a command that tells us to advance.
1991         $start = $line;
1992         $incr  = -1;      # for backward motion.
1993
1994         # Tack preprompt debugger actions ahead of any actual input.
1995         @typeahead = ( @$pretype, @typeahead );
1996
1997 =head2 WHERE ARE WE?
1998
1999 XXX Relocate this section?
2000
2001 The debugger normally shows the line corresponding to the current line of
2002 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2003 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2004
2005 C<$incr> controls by how many lines the I<current> line should move forward
2006 after a command is executed. If set to -1, this indicates that the I<current>
2007 line shouldn't change.
2008
2009 C<$start> is the I<current> line. It is used for things like knowing where to
2010 move forwards or backwards from when doing an C<L> or C<-> command.
2011
2012 C<$max> tells the debugger where the last line of the current file is. It's
2013 used to terminate loops most often.
2014
2015 =head2 THE COMMAND LOOP
2016
2017 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2018 in two parts:
2019
2020 =over 4
2021
2022 =item *
2023
2024 The outer part of the loop, starting at the C<CMD> label. This loop
2025 reads a command and then executes it.
2026
2027 =item *
2028
2029 The inner part of the loop, starting at the C<PIPE> label. This part
2030 is wholly contained inside the C<CMD> block and only executes a command.
2031 Used to handle commands running inside a pager.
2032
2033 =back
2034
2035 So why have two labels to restart the loop? Because sometimes, it's easier to
2036 have a command I<generate> another command and then re-execute the loop to do
2037 the new command. This is faster, but perhaps a bit more convoluted.
2038
2039 =cut
2040
2041         # The big command dispatch loop. It keeps running until the
2042         # user yields up control again.
2043         #
2044         # If we have a terminal for input, and we get something back
2045         # from readline(), keep on processing.
2046         my $piped;
2047         my $selected;
2048
2049       CMD:
2050         while (_DB__read_next_cmd($tid))
2051         {
2052
2053             share($cmd);
2054             # ... try to execute the input as debugger commands.
2055
2056             # Don't stop running.
2057             $single = 0;
2058
2059             # No signal is active.
2060             $signal = 0;
2061
2062             # Handle continued commands (ending with \):
2063             if ($cmd =~ s/\\\z/\n/) {
2064                 $cmd .= &readline("  cont: ");
2065                 redo CMD;
2066             }
2067
2068 =head4 The null command
2069
2070 A newline entered by itself means I<re-execute the last command>. We grab the
2071 command out of C<$laststep> (where it was recorded previously), and copy it
2072 back into C<$cmd> to be executed below. If there wasn't any previous command,
2073 we'll do nothing below (no command will match). If there was, we also save it
2074 in the command history and fall through to allow the command parsing to pick
2075 it up.
2076
2077 =cut
2078
2079             # Empty input means repeat the last command.
2080             $cmd =~ /^$/ && ( $cmd = $laststep );
2081             chomp($cmd);    # get rid of the annoying extra newline
2082             push( @hist, $cmd ) if length($cmd) > 1;
2083             push( @truehist, $cmd );
2084                         share(@hist);
2085                         share(@truehist);
2086
2087             # This is a restart point for commands that didn't arrive
2088             # via direct user input. It allows us to 'redo PIPE' to
2089             # re-execute command processing without reading a new command.
2090           PIPE: {
2091                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2092                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2093                 my ($i) = split( /\s+/, $cmd );
2094
2095 =head3 COMMAND ALIASES
2096
2097 The debugger can create aliases for commands (these are stored in the
2098 C<%alias> hash). Before a command is executed, the command loop looks it up
2099 in the alias hash and substitutes the contents of the alias for the command,
2100 completely replacing it.
2101
2102 =cut
2103
2104                 # See if there's an alias for the command, and set it up if so.
2105                 if ( $alias{$i} ) {
2106
2107                     # Squelch signal handling; we want to keep control here
2108                     # if something goes loco during the alias eval.
2109                     local $SIG{__DIE__};
2110                     local $SIG{__WARN__};
2111
2112                     # This is a command, so we eval it in the DEBUGGER's
2113                     # scope! Otherwise, we can't see the special debugger
2114                     # variables, or get to the debugger's subs. (Well, we
2115                     # _could_, but why make it even more complicated?)
2116                     eval "\$cmd =~ $alias{$i}";
2117                     if ($@) {
2118                         local $\ = '';
2119                         print $OUT "Couldn't evaluate '$i' alias: $@";
2120                         next CMD;
2121                     }
2122                 } ## end if ($alias{$i})
2123
2124 =head3 MAIN-LINE COMMANDS
2125
2126 All of these commands work up to and after the program being debugged has
2127 terminated.
2128
2129 =head4 C<q> - quit
2130
2131 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2132 try to execute further, cleaning any restart-related stuff out of the
2133 environment, and executing with the last value of C<$?>.
2134
2135 =cut
2136
2137                 if ($cmd eq 'q') {
2138                     $fall_off_end = 1;
2139                     clean_ENV();
2140                     exit $?;
2141                 }
2142
2143 =head4 C<t> - trace [n]
2144
2145 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2146 If level is specified, set C<$trace_to_depth>.
2147
2148 =cut
2149
2150                 if (my ($levels) = $cmd =~ /\At(?:\s+(\d+))?\z/) {
2151                     $trace ^= 1;
2152                     local $\ = '';
2153                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2154                     print $OUT "Trace = "
2155                       . ( ( $trace & 1 )
2156                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2157                       : "off" ) . "\n";
2158                     next CMD;
2159                 }
2160
2161 =head4 C<S> - list subroutines matching/not matching a pattern
2162
2163 Walks through C<%sub>, checking to see whether or not to print the name.
2164
2165 =cut
2166
2167                 if (my ($print_all_subs, $should_reverse, $Spatt)
2168                     = $cmd =~ /\AS(\s+(!)?(.+))?\z/) {
2169                     # $Spatt is the pattern (if any) to use.
2170                     # Reverse scan?
2171                     my $Srev     = defined $should_reverse;
2172                     # No args - print all subs.
2173                     my $Snocheck = !defined $print_all_subs;
2174
2175                     # Need to make these sane here.
2176                     local $\ = '';
2177                     local $, = '';
2178
2179                     # Search through the debugger's magical hash of subs.
2180                     # If $nocheck is true, just print the sub name.
2181                     # Otherwise, check it against the pattern. We then use
2182                     # the XOR trick to reverse the condition as required.
2183                     foreach $subname ( sort( keys %sub ) ) {
2184                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2185                             print $OUT $subname, "\n";
2186                         }
2187                     }
2188                     next CMD;
2189                 }
2190
2191 =head4 C<X> - list variables in current package
2192
2193 Since the C<V> command actually processes this, just change this to the
2194 appropriate C<V> command and fall through.
2195
2196 =cut
2197
2198                 $cmd =~ s/^X\b/V $package/;
2199
2200 =head4 C<V> - list variables
2201
2202 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2203
2204 =cut
2205
2206                 # Bare V commands get the currently-being-debugged package
2207                 # added.
2208                 if ($cmd eq "V") {
2209                     $cmd = "V $package";
2210                 }
2211
2212                 # V - show variables in package.
2213                 if (my ($new_packname, $new_vars_str) =
2214                     $cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
2215
2216                     # Save the currently selected filehandle and
2217                     # force output to debugger's filehandle (dumpvar
2218                     # just does "print" for output).
2219                     my $savout = select($OUT);
2220
2221                     # Grab package name and variables to dump.
2222                     $packname = $new_packname;
2223                     my @vars     = split( ' ', $new_vars_str );
2224
2225                     # If main::dumpvar isn't here, get it.
2226                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2227                     if ( defined &main::dumpvar ) {
2228
2229                         # We got it. Turn off subroutine entry/exit messages
2230                         # for the moment, along with return values.
2231                         local $frame = 0;
2232                         local $doret = -2;
2233
2234                         # must detect sigpipe failures  - not catching
2235                         # then will cause the debugger to die.
2236                         eval {
2237                             &main::dumpvar(
2238                                 $packname,
2239                                 defined $option{dumpDepth}
2240                                 ? $option{dumpDepth}
2241                                 : -1,    # assume -1 unless specified
2242                                 @vars
2243                             );
2244                         };
2245
2246                         # The die doesn't need to include the $@, because
2247                         # it will automatically get propagated for us.
2248                         if ($@) {
2249                             die unless $@ =~ /dumpvar print failed/;
2250                         }
2251                     } ## end if (defined &main::dumpvar)
2252                     else {
2253
2254                         # Couldn't load dumpvar.
2255                         print $OUT "dumpvar.pl not available.\n";
2256                     }
2257
2258                     # Restore the output filehandle, and go round again.
2259                     select($savout);
2260                     next CMD;
2261                 }
2262
2263 =head4 C<x> - evaluate and print an expression
2264
2265 Hands the expression off to C<DB::eval>, setting it up to print the value
2266 via C<dumpvar.pl> instead of just printing it directly.
2267
2268 =cut
2269
2270                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2271                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2272
2273                     # handle special  "x 3 blah" syntax XXX propagate
2274                     # doc back to special variables.
2275                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2276                         $onetimedumpDepth = $1;
2277                     }
2278                 }
2279
2280 =head4 C<m> - print methods
2281
2282 Just uses C<DB::methods> to determine what methods are available.
2283
2284 =cut
2285
2286                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2287                     methods($1);
2288                     next CMD;
2289                 }
2290
2291                 # m expr - set up DB::eval to do the work
2292                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2293                     $onetimeDump = 'methods';   #  method output gets used there
2294                 }
2295
2296 =head4 C<f> - switch files
2297
2298 =cut
2299
2300                 if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
2301                     $file =~ s/\s+$//;
2302
2303                     # help for no arguments (old-style was return from sub).
2304                     if ( !$file ) {
2305                         print $OUT
2306                           "The old f command is now the r command.\n";    # hint
2307                         print $OUT "The new f command switches filenames.\n";
2308                         next CMD;
2309                     } ## end if (!$file)
2310
2311                     # if not in magic file list, try a close match.
2312                     if ( !defined $main::{ '_<' . $file } ) {
2313                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2314                             {
2315                                 $try = substr( $try, 2 );
2316                                 print $OUT "Choosing $try matching '$file':\n";
2317                                 $file = $try;
2318                             }
2319                         } ## end if (($try) = grep(m#^_<.*$file#...
2320                     } ## end if (!defined $main::{ ...
2321
2322                     # If not successfully switched now, we failed.
2323                     if ( !defined $main::{ '_<' . $file } ) {
2324                         print $OUT "No file matching '$file' is loaded.\n";
2325                         next CMD;
2326                     }
2327
2328                     # We switched, so switch the debugger internals around.
2329                     elsif ( $file ne $filename ) {
2330                         *dbline   = $main::{ '_<' . $file };
2331                         $max      = $#dbline;
2332                         $filename = $file;
2333                         $start    = 1;
2334                         $cmd      = "l";
2335                     } ## end elsif ($file ne $filename)
2336
2337                     # We didn't switch; say we didn't.
2338                     else {
2339                         print $OUT "Already in $file.\n";
2340                         next CMD;
2341                     }
2342                 }
2343
2344 =head4 C<.> - return to last-executed line.
2345
2346 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2347 and then we look up the line in the magical C<%dbline> hash.
2348
2349 =cut
2350
2351                 # . command.
2352                 if ($cmd eq '.') {
2353                     $incr = -1;    # stay at current line
2354
2355                     # Reset everything to the old location.
2356                     $start    = $line;
2357                     $filename = $filename_ini;
2358                     *dbline   = $main::{ '_<' . $filename };
2359                     $max      = $#dbline;
2360
2361                     # Now where are we?
2362                     print_lineinfo($position);
2363                     next CMD;
2364                 }
2365
2366 =head4 C<-> - back one window
2367
2368 We change C<$start> to be one window back; if we go back past the first line,
2369 we set it to be the first line. We ser C<$incr> to put us back at the
2370 currently-executing line, and then put a C<l $start +> (list one window from
2371 C<$start>) in C<$cmd> to be executed later.
2372
2373 =cut
2374
2375                 # - - back a window.
2376                 if ($cmd eq '-') {
2377
2378                     # back up by a window; go to 1 if back too far.
2379                     $start -= $incr + $window + 1;
2380                     $start = 1 if $start <= 0;
2381                     $incr  = $window - 1;
2382
2383                     # Generate and execute a "l +" command (handled below).
2384                     $cmd = 'l ' . ($start) . '+';
2385                 }
2386
2387 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2388
2389 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2390 problems, most notably that the default case of several commands destroying
2391 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2392 retain the old commands for those who were used to using them or who preferred
2393 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2394 deal with them instead of processing them in-line.
2395
2396 =cut
2397
2398                 # All of these commands were remapped in perl 5.8.0;
2399                 # we send them off to the secondary dispatcher (see below).
2400                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2401                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2402                     next CMD;
2403                 }
2404
2405 =head4 C<y> - List lexicals in higher scope
2406
2407 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2408 above the current one and then displays then using C<dumpvar.pl>.
2409
2410 =cut
2411
2412                 if (my ($match_level, $match_vars)
2413                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2414
2415                     # See if we've got the necessary support.
2416                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2417                       or &warn(
2418                         $@ =~ /locate/
2419                         ? "PadWalker module not found - please install\n"
2420                         : $@
2421                       )
2422                       and next CMD;
2423
2424                     # Load up dumpvar if we don't have it. If we can, that is.
2425                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2426                     defined &main::dumpvar
2427                       or print $OUT "dumpvar.pl not available.\n"
2428                       and next CMD;
2429
2430                     # Got all the modules we need. Find them and print them.
2431                     my @vars = split( ' ', $match_vars || '' );
2432
2433                     # Find the pad.
2434                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2435
2436                     # Oops. Can't find it.
2437                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2438
2439                     # Show the desired vars with dumplex().
2440                     my $savout = select($OUT);
2441
2442                     # Have dumplex dump the lexicals.
2443                     dumpvar::dumplex( $_, $h->{$_},
2444                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2445                         @vars )
2446                       for sort keys %$h;
2447                     select($savout);
2448                     next CMD;
2449                 }
2450
2451 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2452
2453 All of the commands below this point don't work after the program being
2454 debugged has ended. All of them check to see if the program has ended; this
2455 allows the commands to be relocated without worrying about a 'line of
2456 demarcation' above which commands can be entered anytime, and below which
2457 they can't.
2458
2459 =head4 C<n> - single step, but don't trace down into subs
2460
2461 Done by setting C<$single> to 2, which forces subs to execute straight through
2462 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2463 so a null command knows what to re-execute.
2464
2465 =cut
2466
2467                 # n - next
2468                 if ($cmd eq 'n') {
2469                     next CMD if _DB__is_finished();
2470
2471                     # Single step, but don't enter subs.
2472                     $single = 2;
2473
2474                     # Save for empty command (repeat last).
2475                     $laststep = $cmd;
2476                     last CMD;
2477                 }
2478
2479 =head4 C<s> - single-step, entering subs
2480
2481 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2482 subs. Also saves C<s> as C<$lastcmd>.
2483
2484 =cut
2485
2486                 # s - single step.
2487                 if ($cmd eq 's') {
2488
2489                     # Get out and restart the command loop if program
2490                     # has finished.
2491                     next CMD if _DB__is_finished();
2492
2493                     # Single step should enter subs.
2494                     $single = 1;
2495
2496                     # Save for empty command (repeat last).
2497                     $laststep = $cmd;
2498                     last CMD;
2499                 }
2500
2501 =head4 C<c> - run continuously, setting an optional breakpoint
2502
2503 Most of the code for this command is taken up with locating the optional
2504 breakpoint, which is either a subroutine name or a line number. We set
2505 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2506 in this and all call levels above this one.
2507
2508 =cut
2509
2510                 # c - start continuous execution.
2511                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2512
2513                     # Hey, show's over. The debugged program finished
2514                     # executing already.
2515                     next CMD if _DB__is_finished();
2516
2517                     # Capture the place to put a one-time break.
2518                     $subname = $i;
2519
2520                     #  Probably not needed, since we finish an interactive
2521                     #  sub-session anyway...
2522                     # local $filename = $filename;
2523                     # local *dbline = *dbline; # XXX Would this work?!
2524                     #
2525                     # The above question wonders if localizing the alias
2526                     # to the magic array works or not. Since it's commented
2527                     # out, we'll just leave that to speculation for now.
2528
2529                     # If the "subname" isn't all digits, we'll assume it
2530                     # is a subroutine name, and try to find it.
2531                     if ( $subname =~ /\D/ ) {    # subroutine name
2532                             # Qualify it to the current package unless it's
2533                             # already qualified.
2534                         $subname = $package . "::" . $subname
2535                           unless $subname =~ /::/;
2536
2537                         # find_sub will return "file:line_number" corresponding
2538                         # to where the subroutine is defined; we call find_sub,
2539                         # break up the return value, and assign it in one
2540                         # operation.
2541                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2542
2543                         # Force the line number to be numeric.
2544                         $i += 0;
2545
2546                         # If we got a line number, we found the sub.
2547                         if ($i) {
2548
2549                             # Switch all the debugger's internals around so
2550                             # we're actually working with that file.
2551                             $filename = $file;
2552                             *dbline   = $main::{ '_<' . $filename };
2553
2554                             # Mark that there's a breakpoint in this file.
2555                             $had_breakpoints{$filename} |= 1;
2556
2557                             # Scan forward to the first executable line
2558                             # after the 'sub whatever' line.
2559                             $max = $#dbline;
2560                             ++$i while $dbline[$i] == 0 && $i < $max;
2561                         } ## end if ($i)
2562
2563                         # We didn't find a sub by that name.
2564                         else {
2565                             print $OUT "Subroutine $subname not found.\n";
2566                             next CMD;
2567                         }
2568                     } ## end if ($subname =~ /\D/)
2569
2570                     # At this point, either the subname was all digits (an
2571                     # absolute line-break request) or we've scanned through
2572                     # the code following the definition of the sub, looking
2573                     # for an executable, which we may or may not have found.
2574                     #
2575                     # If $i (which we set $subname from) is non-zero, we
2576                     # got a request to break at some line somewhere. On
2577                     # one hand, if there wasn't any real subroutine name
2578                     # involved, this will be a request to break in the current
2579                     # file at the specified line, so we have to check to make
2580                     # sure that the line specified really is breakable.
2581                     #
2582                     # On the other hand, if there was a subname supplied, the
2583                     # preceding block has moved us to the proper file and
2584                     # location within that file, and then scanned forward
2585                     # looking for the next executable line. We have to make
2586                     # sure that one was found.
2587                     #
2588                     # On the gripping hand, we can't do anything unless the
2589                     # current value of $i points to a valid breakable line.
2590                     # Check that.
2591                     if ($i) {
2592
2593                         # Breakable?
2594                         if ( $dbline[$i] == 0 ) {
2595                             print $OUT "Line $i not breakable.\n";
2596                             next CMD;
2597                         }
2598
2599                         # Yes. Set up the one-time-break sigil.
2600                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2601                         _enable_breakpoint_temp_enabled_status($filename, $i);
2602                     } ## end if ($i)
2603
2604                     # Turn off stack tracing from here up.
2605                     for my $i (0 .. $stack_depth) {
2606                         $stack[ $i ] &= ~1;
2607                     }
2608                     last CMD;
2609                 }
2610
2611 =head4 C<r> - return from a subroutine
2612
2613 For C<r> to work properly, the debugger has to stop execution again
2614 immediately after the return is executed. This is done by forcing
2615 single-stepping to be on in the call level above the current one. If
2616 we are printing return values when a C<r> is executed, set C<$doret>
2617 appropriately, and force us out of the command loop.
2618
2619 =cut
2620
2621                 # r - return from the current subroutine.
2622                 if ($cmd eq 'r') {
2623
2624                     # Can't do anything if the program's over.
2625                     next CMD if _DB__is_finished();
2626
2627                     # Turn on stack trace.
2628                     $stack[$stack_depth] |= 1;
2629
2630                     # Print return value unless the stack is empty.
2631                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2632                     last CMD;
2633                 }
2634
2635 =head4 C<T> - stack trace
2636
2637 Just calls C<DB::print_trace>.
2638
2639 =cut
2640
2641                 if ($cmd eq 'T') {
2642                     print_trace( $OUT, 1 );    # skip DB
2643                     next CMD;
2644                 }
2645
2646 =head4 C<w> - List window around current line.
2647
2648 Just calls C<DB::cmd_w>.
2649
2650 =cut
2651
2652                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2653                     &cmd_w( 'w', $arg );
2654                     next CMD;
2655                 }
2656
2657 =head4 C<W> - watch-expression processing.
2658
2659 Just calls C<DB::cmd_W>.
2660
2661 =cut
2662
2663                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2664                     &cmd_W( 'W', $arg );
2665                     next CMD;
2666                 }
2667
2668 =head4 C</> - search forward for a string in the source
2669
2670 We take the argument and treat it as a pattern. If it turns out to be a
2671 bad one, we return the error we got from trying to C<eval> it and exit.
2672 If not, we create some code to do the search and C<eval> it so it can't
2673 mess us up.
2674
2675 =cut
2676
2677                 # The pattern as a string.
2678                 use vars qw($inpat);
2679
2680                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2681
2682                     # Remove the final slash.
2683                     $inpat =~ s:([^\\])/$:$1:;
2684
2685                     # If the pattern isn't null ...
2686                     if ( $inpat ne "" ) {
2687
2688                         # Turn of warn and die procesing for a bit.
2689                         local $SIG{__DIE__};
2690                         local $SIG{__WARN__};
2691
2692                         # Create the pattern.
2693                         eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2694                         if ( $@ ne "" ) {
2695
2696                             # Oops. Bad pattern. No biscuit.
2697                             # Print the eval error and go back for more
2698                             # commands.
2699                             print $OUT "$@";
2700                             next CMD;
2701                         }
2702                         $pat = $inpat;
2703                     } ## end if ($inpat ne "")
2704
2705                     # Set up to stop on wrap-around.
2706                     $end = $start;
2707
2708                     # Don't move off the current line.
2709                     $incr = -1;
2710
2711                     # Done in eval so nothing breaks if the pattern
2712                     # does something weird.
2713                     eval '
2714                         no strict q/vars/;
2715                         for (;;) {
2716                             # Move ahead one line.
2717                             ++$start;
2718
2719                             # Wrap if we pass the last line.
2720                             $start = 1 if ($start > $max);
2721
2722                             # Stop if we have gotten back to this line again,
2723                             last if ($start == $end);
2724
2725                             # A hit! (Note, though, that we are doing
2726                             # case-insensitive matching. Maybe a qr//
2727                             # expression would be better, so the user could
2728                             # do case-sensitive matching if desired.
2729                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2730                                 if ($slave_editor) {
2731                                     # Handle proper escaping in the slave.
2732                                     print $OUT "\032\032$filename:$start:0\n";
2733                                 }
2734                                 else {
2735                                     # Just print the line normally.
2736                                     print $OUT "$start:\t",$dbline[$start],"\n";
2737                                 }
2738                                 # And quit since we found something.
2739                                 last;
2740                             }
2741                          } ';
2742
2743                     # If we wrapped, there never was a match.
2744                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2745                     next CMD;
2746                 }
2747
2748 =head4 C<?> - search backward for a string in the source
2749
2750 Same as for C</>, except the loop runs backwards.
2751
2752 =cut
2753
2754                 # ? - backward pattern search.
2755                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2756
2757                     # Get the pattern, remove trailing question mark.
2758                     $inpat =~ s:([^\\])\?$:$1:;
2759
2760                     # If we've got one ...
2761                     if ( $inpat ne "" ) {
2762
2763                         # Turn off die & warn handlers.
2764                         local $SIG{__DIE__};
2765                         local $SIG{__WARN__};
2766                         eval '$inpat =~ m' . "\a$inpat\a";
2767
2768                         if ( $@ ne "" ) {
2769
2770                             # Ouch. Not good. Print the error.
2771                             print $OUT $@;
2772                             next CMD;
2773                         }
2774                         $pat = $inpat;
2775                     } ## end if ($inpat ne "")
2776
2777                     # Where we are now is where to stop after wraparound.
2778                     $end = $start;
2779
2780                     # Don't move away from this line.
2781                     $incr = -1;
2782
2783                     # Search inside the eval to prevent pattern badness
2784                     # from killing us.
2785                     eval '
2786                         no strict q/vars/;
2787                         for (;;) {
2788                             # Back up a line.
2789                             --$start;
2790
2791                             # Wrap if we pass the first line.
2792
2793                             $start = $max if ($start <= 0);
2794
2795                             # Quit if we get back where we started,
2796                             last if ($start == $end);
2797
2798                             # Match?
2799                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2800                                 if ($slave_editor) {
2801                                     # Yep, follow slave editor requirements.
2802                                     print $OUT "\032\032$filename:$start:0\n";
2803                                 }
2804                                 else {
2805                                     # Yep, just print normally.
2806                                     print $OUT "$start:\t",$dbline[$start],"\n";
2807                                 }
2808
2809                                 # Found, so done.
2810                                 last;
2811                             }
2812                         } ';
2813
2814                     # Say we failed if the loop never found anything,
2815                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2816                     next CMD;
2817                 }
2818
2819 =head4 C<$rc> - Recall command
2820
2821 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2822 that the terminal supports history). It find the the command required, puts it
2823 into C<$cmd>, and redoes the loop to execute it.
2824
2825 =cut
2826
2827                 # $rc - recall command.
2828                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2829
2830                     # No arguments, take one thing off history.
2831                     pop(@hist) if length($cmd) > 1;
2832
2833                     # Relative (- found)?
2834                     #  Y - index back from most recent (by 1 if bare minus)
2835                     #  N - go to that particular command slot or the last
2836                     #      thing if nothing following.
2837                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2838
2839                     # Pick out the command desired.
2840                     $cmd = $hist[$i];
2841
2842                     # Print the command to be executed and restart the loop
2843                     # with that command in the buffer.
2844                     print $OUT $cmd, "\n";
2845                     redo CMD;
2846                 }
2847
2848 =head4 C<$sh$sh> - C<system()> command
2849
2850 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2851 C<STDOUT> from getting messed up.
2852
2853 =cut
2854
2855                 # $sh$sh - run a shell command (if it's all ASCII).
2856                 # Can't run shell commands with Unicode in the debugger, hmm.
2857                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2858
2859                     # System it.
2860                     &system($arg);
2861                     next CMD;
2862                 }
2863
2864 =head4 C<$rc I<pattern> $rc> - Search command history
2865
2866 Another command to manipulate C<@hist>: this one searches it with a pattern.
2867 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2868
2869 =cut
2870
2871                 # $rc pattern $rc - find a command in the history.
2872                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2873
2874                     # Create the pattern to use.
2875                     $pat = "^$arg";
2876
2877                     # Toss off last entry if length is >1 (and it always is).
2878                     pop(@hist) if length($cmd) > 1;
2879
2880                     # Look backward through the history.
2881                     for ( $i = $#hist ; $i ; --$i ) {
2882                         # Stop if we find it.
2883                         last if $hist[$i] =~ /$pat/;
2884                     }
2885
2886                     if ( !$i ) {
2887
2888                         # Never found it.
2889                         print $OUT "No such command!\n\n";
2890                         next CMD;
2891                     }
2892
2893                     # Found it. Put it in the buffer, print it, and process it.
2894                     $cmd = $hist[$i];
2895                     print $OUT $cmd, "\n";
2896                     redo CMD;
2897                 }
2898
2899 =head4 C<$sh> - Invoke a shell
2900
2901 Uses C<DB::system> to invoke a shell.
2902
2903 =cut
2904
2905                 # $sh - start a shell.
2906                 if ($cmd =~ /\A$sh\z/) {
2907
2908                     # Run the user's shell. If none defined, run Bourne.
2909                     # We resume execution when the shell terminates.
2910                     &system( $ENV{SHELL} || "/bin/sh" );
2911                     next CMD;
2912                 }
2913
2914 =head4 C<$sh I<command>> - Force execution of a command in a shell
2915
2916 Like the above, but the command is passed to the shell. Again, we use
2917 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2918
2919 =cut
2920
2921                 # $sh command - start a shell and run a command in it.
2922                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
2923
2924                     # XXX: using csh or tcsh destroys sigint retvals!
2925                     #&system($1);  # use this instead
2926
2927                     # use the user's shell, or Bourne if none defined.
2928                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
2929                     next CMD;
2930                 }
2931
2932 =head4 C<H> - display commands in history
2933
2934 Prints the contents of C<@hist> (if any).
2935
2936 =cut
2937
2938                 if ($cmd =~ /\AH\b\s*\*/) {
2939                     @hist = @truehist = ();
2940                     print $OUT "History cleansed\n";
2941                     next CMD;
2942                 }
2943
2944                 if (my ($num)
2945                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
2946
2947                     # Anything other than negative numbers is ignored by
2948                     # the (incorrect) pattern, so this test does nothing.
2949                     $end = $num ? ( $#hist - $num ) : 0;
2950
2951                     # Set to the minimum if less than zero.
2952                     $hist = 0 if $hist < 0;
2953
2954                     # Start at the end of the array.
2955                     # Stay in while we're still above the ending value.
2956                     # Tick back by one each time around the loop.
2957                     for ( $i = $#hist ; $i > $end ; $i-- ) {
2958
2959                         # Print the command  unless it has no arguments.
2960                         print $OUT "$i: ", $hist[$i], "\n"
2961                           unless $hist[$i] =~ /^.?$/;
2962                     }
2963                     next CMD;
2964                 }
2965
2966 =head4 C<man, doc, perldoc> - look up documentation
2967
2968 Just calls C<runman()> to print the appropriate document.
2969
2970 =cut
2971
2972                 # man, perldoc, doc - show manual pages.
2973                 if (my ($man_page)
2974                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
2975                     runman($man_page);
2976                     next CMD;
2977                 }
2978
2979 =head4 C<p> - print
2980
2981 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2982 the bottom of the loop.
2983
2984 =cut
2985
2986                 my $print_cmd = 'print {$DB::OUT} ';
2987                 # p - print (no args): print $_.
2988                 if ($cmd eq 'p') {
2989                     $cmd = $print_cmd . '$_';
2990                 }
2991
2992                 # p - print the given expression.
2993                 $cmd =~ s/\Ap\b/$print_cmd /;
2994
2995 =head4 C<=> - define command alias
2996
2997 Manipulates C<%alias> to add or list command aliases.
2998
2999 =cut
3000
3001                 # = - set up a command alias.
3002                 if ($cmd =~ s/\A=\s*//) {
3003                     my @keys;
3004                     if ( length $cmd == 0 ) {
3005
3006                         # No args, get current aliases.
3007                         @keys = sort keys %alias;
3008                     }
3009                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3010
3011                         # Creating a new alias. $k is alias name, $v is
3012                         # alias value.
3013
3014                         # can't use $_ or kill //g state
3015                         for my $x ( $k, $v ) {
3016
3017                             # Escape "alarm" characters.
3018                             $x =~ s/\a/\\a/g;
3019                         }
3020
3021                         # Substitute key for value, using alarm chars
3022                         # as separators (which is why we escaped them in
3023                         # the command).
3024                         $alias{$k} = "s\a$k\a$v\a";
3025
3026                         # Turn off standard warn and die behavior.
3027                         local $SIG{__DIE__};
3028                         local $SIG{__WARN__};
3029
3030                         # Is it valid Perl?
3031                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3032
3033                             # Nope. Bad alias. Say so and get out.
3034                             print $OUT "Can't alias $k to $v: $@\n";
3035                             delete $alias{$k};
3036                             next CMD;
3037                         }
3038
3039                         # We'll only list the new one.
3040                         @keys = ($k);
3041                     } ## end elsif (my ($k, $v) = ($cmd...
3042
3043                     # The argument is the alias to list.
3044                     else {
3045                         @keys = ($cmd);
3046                     }
3047
3048                     # List aliases.
3049                     for my $k (@keys) {
3050
3051                         # Messy metaquoting: Trim the substitution code off.
3052                         # We use control-G as the delimiter because it's not
3053                         # likely to appear in the alias.
3054                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3055
3056                             # Print the alias.
3057                             print $OUT "$k\t= $1\n";
3058                         }
3059                         elsif ( defined $alias{$k} ) {
3060
3061                             # Couldn't trim it off; just print the alias code.
3062                             print $OUT "$k\t$alias{$k}\n";
3063                         }
3064                         else {
3065
3066                             # No such, dude.
3067                             print "No alias for $k\n";
3068                         }
3069                     } ## end for my $k (@keys)
3070                     next CMD;
3071                 }
3072
3073 =head4 C<source> - read commands from a file.
3074
3075 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3076 pick it up.
3077
3078 =cut
3079
3080                 # source - read commands from a file (or pipe!) and execute.
3081                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3082                     if ( open my $fh, $sourced_fn ) {
3083
3084                         # Opened OK; stick it in the list of file handles.
3085                         push @cmdfhs, $fh;
3086                     }
3087                     else {
3088
3089                         # Couldn't open it.
3090                         &warn("Can't execute '$sourced_fn': $!\n");
3091                     }
3092                     next CMD;
3093                 }
3094
3095                 if (my ($which_cmd, $position)
3096                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3097
3098                     my ($fn, $line_num);
3099                     if ($position =~ m{\A\d+\z})
3100                     {
3101                         $fn = $filename;
3102                         $line_num = $position;
3103                     }
3104                     elsif (my ($new_fn, $new_line_num)
3105                         = $position =~ m{\A(.*):(\d+)\z}) {
3106                         ($fn, $line_num) = ($new_fn, $new_line_num);
3107                     }
3108                     else
3109                     {
3110                         &warn("Wrong spec for enable/disable argument.\n");
3111                     }
3112
3113                     if (defined($fn)) {
3114                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3115                             _set_breakpoint_enabled_status($fn, $line_num,
3116                                 ($which_cmd eq 'enable' ? 1 : '')
3117                             );
3118                         }
3119                         else {
3120                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3121                         }
3122                     }
3123
3124                     next CMD;
3125                 }
3126
3127 =head4 C<save> - send current history to a file
3128
3129 Takes the complete history, (not the shrunken version you see with C<H>),
3130 and saves it to the given filename, so it can be replayed using C<source>.
3131
3132 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3133
3134 =cut
3135
3136                 # save source - write commands to a file for later use
3137                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3138                     my $filename = $new_fn || '.perl5dbrc';    # default?
3139                     if ( open my $fh, '>', $filename ) {
3140
3141                        # chomp to remove extraneous newlines from source'd files
3142                         chomp( my @truelist =
3143                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3144                               @truehist );
3145                         print $fh join( "\n", @truelist );
3146                         print "commands saved in $file\n";
3147                     }
3148                     else {
3149                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3150                     }
3151                     next CMD;
3152                 }
3153
3154 =head4 C<R> - restart
3155
3156 Restart the debugger session.
3157
3158 =head4 C<rerun> - rerun the current session
3159
3160 Return to any given position in the B<true>-history list
3161
3162 =cut
3163
3164                 # R - restart execution.
3165                 # rerun - controlled restart execution.
3166                 if (my ($cmd_cmd, $cmd_params) =
3167                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3168                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3169
3170                     # Close all non-system fds for a clean restart.  A more
3171                     # correct method would be to close all fds that were not
3172                     # open when the process started, but this seems to be
3173                     # hard.  See "debugger 'R'estart and open database
3174                     # connections" on p5p.
3175
3176                     my $max_fd = 1024; # default if POSIX can't be loaded
3177                     if (eval { require POSIX }) {
3178                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3179                     }
3180
3181                     if (defined $max_fd) {
3182                         foreach ($^F+1 .. $max_fd-1) {
3183                             next unless open FD_TO_CLOSE, "<&=$_";
3184                             close(FD_TO_CLOSE);
3185                         }
3186                     }
3187
3188                     # And run Perl again.  We use exec() to keep the
3189                     # PID stable (and that way $ini_pids is still valid).
3190                     exec(@args) || print $OUT "exec failed: $!\n";
3191
3192                     last CMD;
3193                 }
3194
3195 =head4 C<|, ||> - pipe output through the pager.
3196
3197 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3198 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3199 pipe to the pager (restoring the output filehandles if this fails). If this
3200 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3201 set C<$signal>, sending us back into the debugger.
3202
3203 We then trim off the pipe symbols and C<redo> the command loop at the
3204 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3205 reading another.
3206
3207 =cut
3208
3209                 # || - run command in the pager, with output to DB::OUT.
3210                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3211                     if ( $pager =~ /^\|/ ) {
3212
3213                         # Default pager is into a pipe. Redirect I/O.
3214                         open( SAVEOUT, ">&STDOUT" )
3215                           || &warn("Can't save STDOUT");
3216                         open( STDOUT, ">&OUT" )
3217                           || &warn("Can't redirect STDOUT");
3218                     } ## end if ($pager =~ /^\|/)
3219                     else {
3220
3221                         # Not into a pipe. STDOUT is safe.
3222                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3223                     }
3224
3225                     # Fix up environment to record we have less if so.
3226                     fix_less();
3227
3228                     unless ( $piped = open( OUT, $pager ) ) {
3229
3230                         # Couldn't open pipe to pager.
3231                         &warn("Can't pipe output to '$pager'");
3232                         if ( $pager =~ /^\|/ ) {
3233
3234                             # Redirect I/O back again.
3235                             open( OUT, ">&STDOUT" )    # XXX: lost message
3236                               || &warn("Can't restore DB::OUT");
3237                             open( STDOUT, ">&SAVEOUT" )
3238                               || &warn("Can't restore STDOUT");
3239                             close(SAVEOUT);
3240                         } ## end if ($pager =~ /^\|/)
3241                         else {
3242
3243                             # Redirect I/O. STDOUT already safe.
3244                             open( OUT, ">&STDOUT" )    # XXX: lost message
3245                               || &warn("Can't restore DB::OUT");
3246                         }
3247                         next CMD;
3248                     } ## end unless ($piped = open(OUT,...
3249
3250                     # Set up broken-pipe handler if necessary.
3251                     $SIG{PIPE} = \&DB::catch
3252                       if $pager =~ /^\|/
3253                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3254
3255                     OUT->autoflush(1);
3256                     # Save current filehandle, and put it back.
3257                     $selected = select(OUT);
3258                     # Don't put it back if pager was a pipe.
3259                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3260
3261                     # Trim off the pipe symbols and run the command now.
3262                     $cmd =~ s#\A\|+\s*##;
3263                     redo PIPE;
3264                 }
3265
3266 =head3 END OF COMMAND PARSING
3267
3268 Anything left in C<$cmd> at this point is a Perl expression that we want to
3269 evaluate. We'll always evaluate in the user's context, and fully qualify
3270 any variables we might want to address in the C<DB> package.
3271
3272 =cut
3273
3274                 # t - turn trace on.
3275                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3276                     my $trace_arg = $1;
3277                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3278                 }
3279
3280                 # s - single-step. Remember the last command was 's'.
3281                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3282                     $laststep = 's';
3283                 }
3284
3285                 # n - single-step, but not into subs. Remember last command
3286                 # was 'n'.
3287                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3288                     $laststep = 'n';
3289                 }
3290
3291             }    # PIPE:
3292
3293             # Make sure the flag that says "the debugger's running" is
3294             # still on, to make sure we get control again.
3295             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3296
3297             # Run *our* eval that executes in the caller's context.
3298             DB::eval();
3299
3300             # Turn off the one-time-dump stuff now.
3301             if ($onetimeDump) {
3302                 $onetimeDump      = undef;
3303                 $onetimedumpDepth = undef;
3304             }
3305             elsif ( $term_pid == $$ ) {
3306                 eval { # May run under miniperl, when not available...
3307                     STDOUT->flush();
3308                     STDERR->flush();
3309                 };
3310
3311                 # XXX If this is the master pid, print a newline.
3312                 print {$OUT} "\n";
3313             }
3314         } ## end while (($term || &setterm...
3315
3316 =head3 POST-COMMAND PROCESSING
3317
3318 After each command, we check to see if the command output was piped anywhere.
3319 If so, we go through the necessary code to unhook the pipe and go back to
3320 our standard filehandles for input and output.
3321
3322 =cut
3323
3324         continue {    # CMD:
3325
3326             # At the end of every command:
3327             if ($piped) {
3328
3329                 # Unhook the pipe mechanism now.
3330                 if ( $pager =~ /^\|/ ) {
3331
3332                     # No error from the child.
3333                     $? = 0;
3334
3335                     # we cannot warn here: the handle is missing --tchrist
3336                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3337
3338                     # most of the $? crud was coping with broken cshisms
3339                     # $? is explicitly set to 0, so this never runs.
3340                     if ($?) {
3341                         print SAVEOUT "Pager '$pager' failed: ";
3342                         if ( $? == -1 ) {
3343                             print SAVEOUT "shell returned -1\n";
3344                         }
3345                         elsif ( $? >> 8 ) {
3346                             print SAVEOUT ( $? & 127 )
3347                               ? " (SIG#" . ( $? & 127 ) . ")"
3348                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3349                         }
3350                         else {
3351                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3352                         }
3353                     } ## end if ($?)
3354
3355                     # Reopen filehandle for our output (if we can) and
3356                     # restore STDOUT (if we can).
3357                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3358                     open( STDOUT, ">&SAVEOUT" )
3359                       || &warn("Can't restore STDOUT");
3360
3361                     # Turn off pipe exception handler if necessary.
3362                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3363
3364                     # Will stop ignoring SIGPIPE if done like nohup(1)
3365                     # does SIGINT but Perl doesn't give us a choice.
3366                 } ## end if ($pager =~ /^\|/)
3367                 else {
3368
3369                     # Non-piped "pager". Just restore STDOUT.
3370                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3371                 }
3372
3373                 # Close filehandle pager was using, restore the normal one
3374                 # if necessary,
3375                 close(SAVEOUT);
3376                 select($selected), $selected = "" unless $selected eq "";
3377
3378                 # No pipes now.
3379                 $piped = "";
3380             } ## end if ($piped)
3381         }    # CMD:
3382
3383 =head3 COMMAND LOOP TERMINATION
3384
3385 When commands have finished executing, we come here. If the user closed the
3386 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3387 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3388 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3389 The interpreter will then execute the next line and then return control to us
3390 again.
3391
3392 =cut
3393
3394         # No more commands? Quit.
3395         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3396
3397         # Evaluate post-prompt commands.
3398         foreach $evalarg (@$post) {
3399             DB::eval();
3400         }
3401     }    # if ($single || $signal)
3402
3403     # Put the user's globals back where you found them.
3404     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3405     ();
3406 } ## end sub DB
3407
3408 package DB::Obj;
3409
3410 sub new {
3411     my $class = shift;
3412
3413     my $self = bless {}, $class;
3414
3415     $self->_init(@_);
3416
3417     return $self;
3418 }
3419
3420 sub _init {
3421     my ($self, $args) = @_;
3422
3423     %{$self} = (%$self, %$args);
3424
3425     return;
3426 }
3427
3428 {
3429     no strict 'refs';
3430     foreach my $slot_name (qw(after explicit_stop infix position prefix)) {
3431         my $slot = $slot_name;
3432         *{$slot} = sub {
3433             my $self = shift;
3434
3435             if (@_) {
3436                 ${ $self->{$slot} } = shift;
3437             }
3438
3439             return ${ $self->{$slot} };
3440         };
3441
3442         *{"append_to_$slot"} = sub {
3443             my $self = shift;
3444             my $s = shift;
3445
3446             return $self->$slot($self->$slot . $s);
3447         };
3448     }
3449 }
3450
3451 sub _DB_on_init__initialize_globals
3452 {
3453     my $self = shift;
3454
3455     # Check for whether we should be running continuously or not.
3456     # _After_ the perl program is compiled, $single is set to 1:
3457     if ( $DB::single and not $DB::second_time++ ) {
3458
3459         # Options say run non-stop. Run until we get an interrupt.
3460         if ($DB::runnonstop) {    # Disable until signal
3461                 # If there's any call stack in place, turn off single
3462                 # stepping into subs throughout the stack.
3463             for my $i (0 .. $DB::stack_depth) {
3464                 $DB::stack[ $i ] &= ~1;
3465             }
3466
3467             # And we are now no longer in single-step mode.
3468             $DB::single = 0;
3469
3470             # If we simply returned at this point, we wouldn't get
3471             # the trace info. Fall on through.
3472             # return;
3473         } ## end if ($runnonstop)
3474
3475         elsif ($DB::ImmediateStop) {
3476
3477             # We are supposed to stop here; XXX probably a break.
3478             $DB::ImmediateStop = 0;    # We've processed it; turn it off
3479             $DB::signal        = 1;    # Simulate an interrupt to force
3480                                    # us into the command loop
3481         }
3482     } ## end if ($single and not $second_time...
3483
3484     # If we're in single-step mode, or an interrupt (real or fake)
3485     # has occurred, turn off non-stop mode.
3486     $DB::runnonstop = 0 if $DB::single or $DB::signal;
3487
3488     return;
3489 }
3490
3491 sub _DB__handle_watch_expressions
3492 {
3493     my $self = shift;
3494
3495     if ( $DB::trace & 2 ) {
3496         for my $n (0 .. $#DB::to_watch) {
3497             $DB::evalarg = $DB::to_watch[$n];
3498             local $DB::onetimeDump;    # Tell DB::eval() to not output results
3499
3500             # Fix context DB::eval() wants to return an array, but
3501             # we need a scalar here.
3502             my ($val) = join( "', '", DB::eval() );
3503             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3504
3505             # Did it change?
3506             if ( $val ne $DB::old_watch[$n] ) {
3507
3508                 # Yep! Show the difference, and fake an interrupt.
3509                 $DB::signal = 1;
3510                 print {$DB::OUT} <<EOP;
3511 Watchpoint $n:\t$DB::to_watch[$n] changed:
3512     old value:\t$DB::old_watch[$n]
3513     new value:\t$val
3514 EOP
3515                 $DB::old_watch[$n] = $val;
3516             } ## end if ($val ne $old_watch...
3517         } ## end for my $n (0 ..
3518     } ## end if ($trace & 2)
3519
3520     return;
3521 }
3522
3523 sub _my_print_lineinfo
3524 {
3525     my ($self, $i, $incr_pos) = @_;
3526
3527     if ($DB::frame) {
3528         # Print it indented if tracing is on.
3529         DB::print_lineinfo( ' ' x $DB::stack_depth,
3530             "$i:\t$DB::dbline[$i]" . $self->after );
3531     }
3532     else {
3533         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3534     }
3535 }
3536
3537 sub _curr_line {
3538     return $DB::dbline[$DB::line];
3539 }
3540
3541 sub _DB__grab_control
3542 {
3543     my $self = shift;
3544
3545     # Yes, grab control.
3546     if ($DB::slave_editor) {
3547
3548         # Tell the editor to update its position.
3549         $self->position("\032\032${DB::filename}:${DB::line}:0\n");
3550         DB::print_lineinfo($self->position());
3551     }
3552
3553 =pod
3554
3555 Special check: if we're in package C<DB::fake>, we've gone through the
3556 C<END> block at least once. We set up everything so that we can continue
3557 to enter commands and have a valid context to be in.
3558
3559 =cut
3560
3561     elsif ( $DB::package eq 'DB::fake' ) {
3562
3563         # Fallen off the end already.
3564         if (!$DB::term) {
3565             DB::setterm();
3566         }
3567
3568         DB::print_help(<<EOP);
3569 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3570 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3571 B<h q>, B<h R> or B<h o> to get additional info.
3572 EOP
3573
3574         # Set the DB::eval context appropriately.
3575         $DB::package     = 'main';
3576         $DB::usercontext = DB::_calc_usercontext($DB::package);
3577     } ## end elsif ($package eq 'DB::fake')
3578
3579 =pod
3580
3581 If the program hasn't finished executing, we scan forward to the
3582 next executable line, print that out, build the prompt from the file and line
3583 number information, and print that.
3584
3585 =cut
3586
3587     else {
3588
3589
3590         # Still somewhere in the midst of execution. Set up the
3591         #  debugger prompt.
3592         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3593                              # Perl 5 ones (sorry, we don't print Klingon
3594                              #module names)
3595
3596         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3597         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3598         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3599
3600         # Break up the prompt if it's really long.
3601         if ( length($self->prefix()) > 30 ) {
3602             $self->position($self->prefix . "$DB::line):\n$DB::line:\t" . $self->_curr_line . $self->after);
3603             $self->prefix("");
3604             $self->infix(":\t");
3605         }
3606         else {
3607             $self->infix("):\t");
3608             $self->position(
3609                 $self->prefix . $DB::line. $self->infix
3610                 . $self->_curr_line . $self->after
3611             );
3612         }
3613
3614         # Print current line info, indenting if necessary.
3615         $self->_my_print_lineinfo($DB::line, $self->position);
3616
3617         my $i;
3618         my $line_i = sub { return $DB::dbline[$i]; };
3619
3620         # Scan forward, stopping at either the end or the next
3621         # unbreakable line.
3622         for ( $i = $DB::line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3623         {    #{ vi
3624
3625             # Drop out on null statements, block closers, and comments.
3626             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3627
3628             # Drop out if the user interrupted us.
3629             last if $DB::signal;
3630
3631             # Append a newline if the line doesn't have one. Can happen
3632             # in eval'ed text, for instance.
3633             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3634
3635             # Next executable line.
3636             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3637                 . $self->after;
3638             $self->append_to_position($incr_pos);
3639             $self->_my_print_lineinfo($i, $incr_pos);
3640         } ## end for ($i = $line + 1 ; $i...
3641     } ## end else [ if ($slave_editor)
3642
3643     return;
3644 }
3645
3646 package DB;
3647
3648 # The following code may be executed now:
3649 # BEGIN {warn 4}
3650
3651 =head2 sub
3652
3653 C<sub> is called whenever a subroutine call happens in the program being
3654 debugged. The variable C<$DB::sub> contains the name of the subroutine
3655 being called.
3656
3657 The core function of this subroutine is to actually call the sub in the proper
3658 context, capturing its output. This of course causes C<DB::DB> to get called
3659 again, repeating until the subroutine ends and returns control to C<DB::sub>
3660 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3661 return value, and returns its captured copy of the return value as its own
3662 return value. The value then feeds back into the program being debugged as if
3663 C<DB::sub> hadn't been there at all.
3664
3665 C<sub> does all the work of printing the subroutine entry and exit messages
3666 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3667 and also prints the return value if needed (for the C<r> command and if
3668 the 16 bit is set in C<$frame>).
3669
3670 It also tracks the subroutine call depth by saving the current setting of
3671 C<$single> in the C<@stack> package global; if this exceeds the value in
3672 C<$deep>, C<sub> automatically turns on printing of the current depth by
3673 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3674 of stop/don't stop on entry to subs set as it currently is set.
3675
3676 =head3 C<caller()> support
3677
3678 If C<caller()> is called from the package C<DB>, it provides some
3679 additional data, in the following order:
3680
3681 =over 4
3682
3683 =item * C<$package>
3684
3685 The package name the sub was in
3686
3687 =item * C<$filename>
3688
3689 The filename it was defined in
3690
3691 =item * C<$line>
3692
3693 The line number it was defined on
3694
3695 =item * C<$subroutine>
3696
3697 The subroutine name; C<(eval)> if an C<eval>().
3698
3699 =item * C<$hasargs>
3700
3701 1 if it has arguments, 0 if not
3702
3703 =item * C<$wantarray>
3704
3705 1 if array context, 0 if scalar context
3706
3707 =item * C<$evaltext>
3708
3709 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3710
3711 =item * C<$is_require>
3712
3713 frame was created by a C<use> or C<require> statement
3714
3715 =item * C<$hints>
3716
3717 pragma information; subject to change between versions
3718
3719 =item * C<$bitmask>
3720
3721 pragma information; subject to change between versions
3722
3723 =item * C<@DB::args>
3724
3725 arguments with which the subroutine was invoked
3726
3727 =back
3728
3729 =cut
3730
3731 use vars qw($deep);
3732
3733 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3734 # happy. -- Shlomi Fish
3735 sub DB::sub {
3736         # Do not use a regex in this subroutine -> results in corrupted memory
3737         # See: [perl #66110]
3738
3739         # lock ourselves under threads
3740         lock($DBGR);
3741
3742     # Whether or not the autoloader was running, a scalar to put the
3743     # sub's return value in (if needed), and an array to put the sub's
3744     # return value in (if needed).
3745     my ( $al, $ret, @ret ) = "";
3746         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3747                 print "creating new thread\n";
3748         }
3749
3750     # If the last ten characters are '::AUTOLOAD', note we've traced
3751     # into AUTOLOAD for $sub.
3752     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3753         no strict 'refs';
3754         $al = " for $$sub" if defined $$sub;
3755     }
3756
3757     # We stack the stack pointer and then increment it to protect us
3758     # from a situation that might unwind a whole bunch of call frames
3759     # at once. Localizing the stack pointer means that it will automatically
3760     # unwind the same amount when multiple stack frames are unwound.
3761     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3762
3763     # Expand @stack.
3764     $#stack = $stack_depth;
3765
3766     # Save current single-step setting.
3767     $stack[-1] = $single;
3768
3769     # Turn off all flags except single-stepping.
3770     $single &= 1;
3771
3772     # If we've gotten really deeply recursed, turn on the flag that will
3773     # make us stop with the 'deep recursion' message.
3774     $single |= 4 if $stack_depth == $deep;
3775
3776     # If frame messages are on ...
3777     (
3778         $frame & 4    # Extended frame entry message
3779         ? (
3780             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3781
3782             # Why -1? But it works! :-(
3783             # Because print_trace will call add 1 to it and then call
3784             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3785             # in dump_trace.
3786             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3787           )
3788         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3789
3790           # standard frame entry message
3791       )
3792       if $frame;
3793
3794     # Determine the sub's return type, and capture appropriately.
3795     if (wantarray) {
3796
3797         # Called in array context. call sub and capture output.
3798         # DB::DB will recursively get control again if appropriate; we'll come
3799         # back here when the sub is finished.
3800         {
3801             no strict 'refs';
3802             @ret = &$sub;
3803         }
3804
3805         # Pop the single-step value back off the stack.
3806         $single |= $stack[ $stack_depth-- ];
3807
3808         # Check for exit trace messages...
3809         (
3810             $frame & 4    # Extended exit message
3811             ? (
3812                 print_lineinfo( ' ' x $stack_depth, "out " ),
3813                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3814               )
3815             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3816
3817               # Standard exit message
3818           )
3819           if $frame & 2;
3820
3821         # Print the return info if we need to.
3822         if ( $doret eq $stack_depth or $frame & 16 ) {
3823
3824             # Turn off output record separator.
3825             local $\ = '';
3826             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3827
3828             # Indent if we're printing because of $frame tracing.
3829             print $fh ' ' x $stack_depth if $frame & 16;
3830
3831             # Print the return value.
3832             print $fh "list context return from $sub:\n";
3833             dumpit( $fh, \@ret );
3834
3835             # And don't print it again.
3836             $doret = -2;
3837         } ## end if ($doret eq $stack_depth...
3838             # And we have to return the return value now.
3839         @ret;
3840     } ## end if (wantarray)
3841
3842     # Scalar context.
3843     else {
3844         if ( defined wantarray ) {
3845         no strict 'refs';
3846             # Save the value if it's wanted at all.
3847             $ret = &$sub;
3848         }
3849         else {
3850         no strict 'refs';
3851             # Void return, explicitly.
3852             &$sub;
3853             undef $ret;
3854         }
3855
3856         # Pop the single-step value off the stack.
3857         $single |= $stack[ $stack_depth-- ];
3858
3859         # If we're doing exit messages...
3860         (
3861             $frame & 4    # Extended messages
3862             ? (
3863                 print_lineinfo( ' ' x $stack_depth, "out " ),
3864                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3865               )
3866             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3867
3868               # Standard messages
3869           )
3870           if $frame & 2;
3871
3872         # If we are supposed to show the return value... same as before.
3873         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3874             local $\ = '';
3875             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3876             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3877             print $fh (
3878                 defined wantarray
3879                 ? "scalar context return from $sub: "
3880                 : "void context return from $sub\n"
3881             );
3882             dumpit( $fh, $ret ) if defined wantarray;
3883             $doret = -2;
3884         } ## end if ($doret eq $stack_depth...
3885
3886         # Return the appropriate scalar value.
3887         $ret;
3888     } ## end else [ if (wantarray)
3889 } ## end sub _sub
3890
3891 sub lsub : lvalue {
3892
3893     no strict 'refs';
3894
3895         # lock ourselves under threads
3896         lock($DBGR);
3897
3898     # Whether or not the autoloader was running, a scalar to put the
3899     # sub's return value in (if needed), and an array to put the sub's
3900     # return value in (if needed).
3901     my ( $al, $ret, @ret ) = "";
3902         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3903                 print "creating new thread\n";
3904         }
3905
3906     # If the last ten characters are C'::AUTOLOAD', note we've traced
3907     # into AUTOLOAD for $sub.
3908     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3909         $al = " for $$sub";
3910     }
3911
3912     # We stack the stack pointer and then increment it to protect us
3913     # from a situation that might unwind a whole bunch of call frames
3914     # at once. Localizing the stack pointer means that it will automatically
3915     # unwind the same amount when multiple stack frames are unwound.
3916     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3917
3918     # Expand @stack.
3919     $#stack = $stack_depth;
3920
3921     # Save current single-step setting.
3922     $stack[-1] = $single;
3923
3924     # Turn off all flags except single-stepping.
3925     $single &= 1;
3926
3927     # If we've gotten really deeply recursed, turn on the flag that will
3928     # make us stop with the 'deep recursion' message.
3929     $single |= 4 if $stack_depth == $deep;
3930
3931     # If frame messages are on ...
3932     (
3933         $frame & 4    # Extended frame entry message
3934         ? (
3935             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3936
3937             # Why -1? But it works! :-(
3938             # Because print_trace will call add 1 to it and then call
3939             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3940             # in dump_trace.
3941             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3942           )
3943         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3944
3945           # standard frame entry message
3946       )
3947       if $frame;
3948
3949     # Pop the single-step value back off the stack.
3950     $single |= $stack[ $stack_depth-- ];
3951
3952     # call the original lvalue sub.
3953     &$sub;
3954 }
3955
3956 # Abstracting common code from multiple places elsewhere:
3957 sub depth_print_lineinfo {
3958     my $always_print = shift;
3959
3960     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3961 }
3962
3963 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3964
3965 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3966 Most of the changes were to systematize the command structure and to eliminate
3967 commands that threw away user input without checking.
3968
3969 The following sections describe the code added to make it easy to support
3970 multiple command sets with conflicting command names. This section is a start
3971 at unifying all command processing to make it simpler to develop commands.
3972
3973 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3974 number, and C<$dbline> (the current line) as arguments.
3975
3976 Support functions in this section which have multiple modes of failure C<die>
3977 on error; the rest simply return a false value.
3978
3979 The user-interface functions (all of the C<cmd_*> functions) just output
3980 error messages.
3981
3982 =head2 C<%set>
3983
3984 The C<%set> hash defines the mapping from command letter to subroutine
3985 name suffix.
3986
3987 C<%set> is a two-level hash, indexed by set name and then by command name.
3988 Note that trying to set the CommandSet to C<foobar> simply results in the
3989 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3990
3991 =cut
3992
3993 ### The API section
3994
3995 my %set = (    #
3996     'pre580' => {
3997         'a' => 'pre580_a',
3998         'A' => 'pre580_null',
3999         'b' => 'pre580_b',
4000         'B' => 'pre580_null',
4001         'd' => 'pre580_null',
4002         'D' => 'pre580_D',
4003         'h' => 'pre580_h',
4004         'M' => 'pre580_null',
4005         'O' => 'o',
4006         'o' => 'pre580_null',
4007         'v' => 'M',
4008         'w' => 'v',
4009         'W' => 'pre580_W',
4010     },
4011     'pre590' => {
4012         '<'  => 'pre590_prepost',
4013         '<<' => 'pre590_prepost',
4014         '>'  => 'pre590_prepost',
4015         '>>' => 'pre590_prepost',
4016         '{'  => 'pre590_prepost',
4017         '{{' => 'pre590_prepost',
4018     },
4019 );
4020
4021 my %breakpoints_data;
4022
4023 sub _has_breakpoint_data_ref {
4024     my ($filename, $line) = @_;
4025
4026     return (
4027         exists( $breakpoints_data{$filename} )
4028             and
4029         exists( $breakpoints_data{$filename}{$line} )
4030     );
4031 }
4032
4033 sub _get_breakpoint_data_ref {
4034     my ($filename, $line) = @_;
4035
4036     return ($breakpoints_data{$filename}{$line} ||= +{});
4037 }
4038
4039 sub _delete_breakpoint_data_ref {
4040     my ($filename, $line) = @_;
4041
4042     delete($breakpoints_data{$filename}{$line});
4043     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4044         delete($breakpoints_data{$filename});
4045     }
4046
4047     return;
4048 }
4049
4050 sub _set_breakpoint_enabled_status {
4051     my ($filename, $line, $status) = @_;
4052
4053     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4054         ($status ? 1 : '')
4055         ;
4056
4057     return;
4058 }
4059
4060 sub _enable_breakpoint_temp_enabled_status {
4061     my ($filename, $line) = @_;
4062
4063     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4064
4065     return;
4066 }
4067
4068 sub _cancel_breakpoint_temp_enabled_status {
4069     my ($filename, $line) = @_;
4070
4071     my $ref = _get_breakpoint_data_ref($filename, $line);
4072
4073     delete ($ref->{'temp_enabled'});
4074
4075     if (! %$ref) {
4076         _delete_breakpoint_data_ref($filename, $line);
4077     }
4078
4079     return;
4080 }
4081
4082 sub _is_breakpoint_enabled {
4083     my ($filename, $line) = @_;
4084
4085     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4086     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4087 }
4088
4089 =head2 C<cmd_wrapper()> (API)
4090
4091 C<cmd_wrapper()> allows the debugger to switch command sets
4092 depending on the value of the C<CommandSet> option.
4093
4094 It tries to look up the command in the C<%set> package-level I<lexical>
4095 (which means external entities can't fiddle with it) and create the name of
4096 the sub to call based on the value found in the hash (if it's there). I<All>
4097 of the commands to be handled in a set have to be added to C<%set>; if they
4098 aren't found, the 5.8.0 equivalent is called (if there is one).
4099
4100 This code uses symbolic references.
4101
4102 =cut
4103
4104 sub cmd_wrapper {
4105     my $cmd      = shift;
4106     my $line     = shift;
4107     my $dblineno = shift;
4108
4109     # Assemble the command subroutine's name by looking up the
4110     # command set and command name in %set. If we can't find it,
4111     # default to the older version of the command.
4112     my $call = 'cmd_'
4113       . ( $set{$CommandSet}{$cmd}
4114           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4115
4116     # Call the command subroutine, call it by name.
4117     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4118 } ## end sub cmd_wrapper
4119
4120 =head3 C<cmd_a> (command)
4121
4122 The C<a> command handles pre-execution actions. These are associated with a
4123 particular line, so they're stored in C<%dbline>. We default to the current
4124 line if none is specified.
4125
4126 =cut
4127
4128 sub cmd_a {
4129     my $cmd    = shift;
4130     my $line   = shift || '';    # [.|line] expr
4131     my $dbline = shift;
4132
4133     # If it's dot (here), or not all digits,  use the current line.
4134     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
4135
4136     # Should be a line number followed by an expression.
4137     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4138         my ( $lineno, $expr ) = ( $1, $2 );
4139
4140         # If we have an expression ...
4141         if ( length $expr ) {
4142
4143             # ... but the line isn't breakable, complain.
4144             if ( $dbline[$lineno] == 0 ) {
4145                 print $OUT
4146                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4147             }
4148             else {
4149
4150                 # It's executable. Record that the line has an action.
4151                 $had_breakpoints{$filename} |= 2;
4152
4153                 # Remove any action, temp breakpoint, etc.
4154                 $dbline{$lineno} =~ s/\0[^\0]*//;
4155
4156                 # Add the action to the line.
4157                 $dbline{$lineno} .= "\0" . action($expr);
4158
4159                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4160             }
4161         } ## end if (length $expr)
4162     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4163     else {
4164
4165         # Syntax wrong.
4166         print $OUT
4167           "Adding an action requires an optional lineno and an expression\n"
4168           ;    # hint
4169     }
4170 } ## end sub cmd_a
4171
4172 =head3 C<cmd_A> (command)
4173
4174 Delete actions. Similar to above, except the delete code is in a separate
4175 subroutine, C<delete_action>.
4176
4177 =cut
4178
4179 sub cmd_A {
4180     my $cmd    = shift;
4181     my $line   = shift || '';
4182     my $dbline = shift;
4183
4184     # Dot is this line.
4185     $line =~ s/^\./$dbline/;
4186
4187     # Call delete_action with a null param to delete them all.
4188     # The '1' forces the eval to be true. It'll be false only
4189     # if delete_action blows up for some reason, in which case
4190     # we print $@ and get out.
4191     if ( $line eq '*' ) {
4192         if (! eval { _delete_all_actions(); 1 }) {
4193             print {$OUT} $@;
4194             return;
4195         }
4196     }
4197
4198     # There's a real line  number. Pass it to delete_action.
4199     # Error trapping is as above.
4200     elsif ( $line =~ /^(\S.*)/ ) {
4201         if (! eval { delete_action($1); 1 }) {
4202             print {$OUT} $@;
4203             return;
4204         }
4205     }
4206
4207     # Swing and a miss. Bad syntax.
4208     else {
4209         print $OUT
4210           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4211     }
4212 } ## end sub cmd_A
4213
4214 =head3 C<delete_action> (API)
4215
4216 C<delete_action> accepts either a line number or C<undef>. If a line number
4217 is specified, we check for the line being executable (if it's not, it
4218 couldn't have had an  action). If it is, we just take the action off (this
4219 will get any kind of an action, including breakpoints).
4220
4221 =cut
4222
4223 sub _remove_action_from_dbline {
4224     my $i = shift;
4225
4226     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4227     delete $dbline{$i} if $dbline{$i} eq '';
4228
4229     return;
4230 }
4231
4232 sub _delete_all_actions {
4233     print {$OUT} "Deleting all actions...\n";
4234
4235     for my $file ( keys %had_breakpoints ) {
4236         local *dbline = $main::{ '_<' . $file };
4237         $max = $#dbline;
4238         my $was;
4239         for my $i (1 .. $max) {
4240             if ( defined $dbline{$i} ) {
4241                 _remove_action_from_dbline($i);
4242             }
4243         }
4244
4245         unless ( $had_breakpoints{$file} &= ~2 ) {
4246             delete $had_breakpoints{$file};
4247         }
4248     }
4249
4250     return;
4251 }
4252
4253 sub delete_action {
4254     my $i = shift;
4255
4256     if ( defined($i) ) {
4257         # Can there be one?
4258         die "Line $i has no action .\n" if $dbline[$i] == 0;
4259
4260         # Nuke whatever's there.
4261         _remove_action_from_dbline($i);
4262     }
4263     else {
4264         _delete_all_actions();
4265     }
4266 }
4267
4268 =head3 C<cmd_b> (command)
4269
4270 Set breakpoints. Since breakpoints can be set in so many places, in so many
4271 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4272 we try to parse the command type, and then shuttle it off to an appropriate
4273 subroutine to actually do the work of setting the breakpoint in the right
4274 place.
4275
4276 =cut
4277
4278 sub cmd_b {
4279     my $cmd    = shift;
4280     my $line   = shift;    # [.|line] [cond]
4281     my $dbline = shift;
4282
4283     my $default_cond = sub {
4284         my $cond = shift;
4285         return length($cond) ? $cond : '1';
4286     };
4287
4288     # Make . the current line number if it's there..
4289     $line =~ s/^\.(\s|\z)/$dbline$1/;
4290
4291     # No line number, no condition. Simple break on current line.
4292     if ( $line =~ /^\s*$/ ) {
4293         cmd_b_line( $dbline, 1 );
4294     }
4295
4296     # Break on load for a file.
4297     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4298         $file =~ s/\s+\z//;
4299         cmd_b_load($file);
4300     }
4301
4302     # b compile|postpone <some sub> [<condition>]
4303     # The interpreter actually traps this one for us; we just put the
4304     # necessary condition in the %postponed hash.
4305     elsif ( my ($action, $subname, $cond)
4306         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4307
4308         # De-Perl4-ify the name - ' separators to ::.
4309         $subname =~ s/'/::/g;
4310
4311         # Qualify it into the current package unless it's already qualified.
4312         $subname = "${package}::" . $subname unless $subname =~ /::/;
4313
4314         # Add main if it starts with ::.
4315         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4316
4317         # Save the break type for this sub.
4318         $postponed{$subname} = (($action eq 'postpone')
4319             ? ( "break +0 if " . $default_cond->($cond) )
4320             : "compile");
4321     } ## end elsif ($line =~ ...
4322     # b <filename>:<line> [<condition>]
4323     elsif (my ($filename, $line_num, $cond)
4324         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4325         cmd_b_filename_line(
4326             $filename,
4327             $line_num,
4328             (length($cond) ? $cond : '1'),
4329         );
4330     }
4331     # b <sub name> [<condition>]
4332     elsif ( my ($new_subname, $new_cond) =
4333         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4334
4335         #
4336         $subname = $new_subname;
4337         cmd_b_sub( $subname, $default_cond->($new_cond) );
4338     }
4339
4340     # b <line> [<condition>].
4341     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4342
4343         # Capture the line. If none, it's the current line.
4344         $line = $line_n || $dbline;
4345
4346         # Break on line.
4347         cmd_b_line( $line, $default_cond->($cond) );
4348     }
4349
4350     # Line didn't make sense.
4351     else {
4352         print "confused by line($line)?\n";
4353     }
4354
4355     return;
4356 } ## end sub cmd_b
4357
4358 =head3 C<break_on_load> (API)
4359
4360 We want to break when this file is loaded. Mark this file in the
4361 C<%break_on_load> hash, and note that it has a breakpoint in
4362 C<%had_breakpoints>.
4363
4364 =cut
4365
4366 sub break_on_load {
4367     my $file = shift;
4368     $break_on_load{$file} = 1;
4369     $had_breakpoints{$file} |= 1;
4370 }
4371
4372 =head3 C<report_break_on_load> (API)
4373
4374 Gives us an array of filenames that are set to break on load. Note that
4375 only files with break-on-load are in here, so simply showing the keys
4376 suffices.
4377
4378 =cut
4379
4380 sub report_break_on_load {
4381     sort keys %break_on_load;
4382 }
4383
4384 =head3 C<cmd_b_load> (command)
4385
4386 We take the file passed in and try to find it in C<%INC> (which maps modules
4387 to files they came from). We mark those files for break-on-load via
4388 C<break_on_load> and then report that it was done.
4389
4390 =cut
4391
4392 sub cmd_b_load {
4393     my $file = shift;
4394     my @files;
4395
4396     # This is a block because that way we can use a redo inside it
4397     # even without there being any looping structure at all outside it.
4398     {
4399
4400         # Save short name and full path if found.
4401         push @files, $file;
4402         push @files, $::INC{$file} if $::INC{$file};
4403
4404         # Tack on .pm and do it again unless there was a '.' in the name
4405         # already.
4406         $file .= '.pm', redo unless $file =~ /\./;
4407     }
4408
4409     # Do the real work here.
4410     break_on_load($_) for @files;
4411
4412     # All the files that have break-on-load breakpoints.
4413     @files = report_break_on_load;
4414
4415     # Normalize for the purposes of our printing this.
4416     local $\ = '';
4417     local $" = ' ';
4418     print $OUT "Will stop on load of '@files'.\n";
4419 } ## end sub cmd_b_load
4420
4421 =head3 C<$filename_error> (API package global)
4422
4423 Several of the functions we need to implement in the API need to work both
4424 on the current file and on other files. We don't want to duplicate code, so
4425 C<$filename_error> is used to contain the name of the file that's being
4426 worked on (if it's not the current one).
4427
4428 We can now build functions in pairs: the basic function works on the current
4429 file, and uses C<$filename_error> as part of its error message. Since this is
4430 initialized to C<"">, no filename will appear when we are working on the
4431 current file.
4432
4433 The second function is a wrapper which does the following:
4434
4435 =over 4
4436
4437 =item *
4438
4439 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4440
4441 =item *
4442
4443 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4444
4445 =item *
4446
4447 Calls the first function.
4448
4449 The first function works on the I<current> file (i.e., the one we changed to),
4450 and prints C<$filename_error> in the error message (the name of the other file)
4451 if it needs to. When the functions return, C<*dbline> is restored to point
4452 to the actual current file (the one we're executing in) and
4453 C<$filename_error> is restored to C<"">. This restores everything to
4454 the way it was before the second function was called at all.
4455
4456 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4457 details.
4458
4459 =back
4460
4461 =cut
4462
4463 use vars qw($filename_error);
4464 $filename_error = '';
4465
4466 =head3 breakable_line(from, to) (API)
4467
4468 The subroutine decides whether or not a line in the current file is breakable.
4469 It walks through C<@dbline> within the range of lines specified, looking for
4470 the first line that is breakable.
4471
4472 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4473 first line I<after> C<$to> that's breakable, if there is one.
4474
4475 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4476 first line I<before> C<$to> that's breakable, if there is one.
4477
4478 =cut
4479
4480 sub breakable_line {
4481
4482     my ( $from, $to ) = @_;
4483
4484     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4485     my $i = $from;
4486
4487     # If there are at least 2 arguments, we're trying to search a range.
4488     if ( @_ >= 2 ) {
4489
4490         # $delta is positive for a forward search, negative for a backward one.
4491         my $delta = $from < $to ? +1 : -1;
4492
4493         # Keep us from running off the ends of the file.
4494         my $limit = $delta > 0 ? $#dbline : 1;
4495
4496         # Clever test. If you're a mathematician, it's obvious why this
4497         # test works. If not:
4498         # If $delta is positive (going forward), $limit will be $#dbline.
4499         #    If $to is less than $limit, ($limit - $to) will be positive, times
4500         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4501         #    as the stopping point.
4502         #
4503         #    If $to is greater than $limit, ($limit - $to) is negative,
4504         #    times $delta of 1 (positive), so the result is < 0 and we should
4505         #    use $limit ($#dbline) as the stopping point.
4506         #
4507         # If $delta is negative (going backward), $limit will be 1.
4508         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4509         #    (negative) so the result is > 0, and we use $to as the stopping
4510         #    point.
4511         #
4512         #    If $to is less than zero, ($limit - $to) will be positive,
4513         #    times $delta of -1 (negative), so the result is not > 0, and
4514         #    we use $limit (1) as the stopping point.
4515         #
4516         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4517         #    (negative), still giving zero; the result is not > 0, and
4518         #    we use $limit (1) as the stopping point.
4519         #
4520         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4521         #    (negative), giving a positive (>0) value, so we'll set $limit to
4522         #    $to.
4523
4524         $limit = $to if ( $limit - $to ) * $delta > 0;
4525
4526         # The real search loop.
4527         # $i starts at $from (the point we want to start searching from).
4528         # We move through @dbline in the appropriate direction (determined
4529         # by $delta: either -1 (back) or +1 (ahead).
4530         # We stay in as long as we haven't hit an executable line
4531         # ($dbline[$i] == 0 means not executable) and we haven't reached
4532         # the limit yet (test similar to the above).
4533         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4534
4535     } ## end if (@_ >= 2)
4536
4537     # If $i points to a line that is executable, return that.
4538     return $i unless $dbline[$i] == 0;
4539
4540     # Format the message and print it: no breakable lines in range.
4541     my ( $pl, $upto ) = ( '', '' );
4542     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4543
4544     # If there's a filename in filename_error, we'll see it.
4545     # If not, not.
4546     die "Line$pl $from$upto$filename_error not breakable\n";
4547 } ## end sub breakable_line
4548
4549 =head3 breakable_line_in_filename(file, from, to) (API)
4550
4551 Like C<breakable_line>, but look in another file.
4552
4553 =cut