This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Bump the $VERSION of File::stat (documentation changed).
[perl5.git] / lib / ExtUtils / MM.pm
1 package ExtUtils::MM;
2
3 use strict;
4 use ExtUtils::MakeMaker::Config;
5
6 our $VERSION = '6.47_02';
7
8 require ExtUtils::Liblist;
9 require ExtUtils::MakeMaker;
10 our @ISA = qw(ExtUtils::Liblist ExtUtils::MakeMaker);
11
12 =head1 NAME
13
14 ExtUtils::MM - OS adjusted ExtUtils::MakeMaker subclass
15
16 =head1 SYNOPSIS
17
18   require ExtUtils::MM;
19   my $mm = MM->new(...);
20
21 =head1 DESCRIPTION
22
23 B<FOR INTERNAL USE ONLY>
24
25 ExtUtils::MM is a subclass of ExtUtils::MakeMaker which automatically
26 chooses the appropriate OS specific subclass for you
27 (ie. ExtUils::MM_Unix, etc...).
28
29 It also provides a convenient alias via the MM class (I didn't want
30 MakeMaker modules outside of ExtUtils/).
31
32 This class might turn out to be a temporary solution, but MM won't go
33 away.
34
35 =cut
36
37 {
38     # Convenient alias.
39     package MM;
40     our @ISA = qw(ExtUtils::MM);
41     sub DESTROY {}
42 }
43
44 sub _is_win95 {
45     # miniperl might not have the Win32 functions available and we need
46     # to run in miniperl.
47     return defined &Win32::IsWin95 ? Win32::IsWin95() 
48                                    : ! defined $ENV{SYSTEMROOT}; 
49 }
50
51 my %Is = ();
52 $Is{VMS}    = $^O eq 'VMS';
53 $Is{OS2}    = $^O eq 'os2';
54 $Is{MacOS}  = $^O eq 'MacOS';
55 if( $^O eq 'MSWin32' ) {
56     _is_win95() ? $Is{Win95} = 1 : $Is{Win32} = 1;
57 }
58 $Is{UWIN}   = $^O =~ /^uwin(-nt)?$/;
59 $Is{Cygwin} = $^O eq 'cygwin';
60 $Is{NW5}    = $Config{osname} eq 'NetWare';  # intentional
61 $Is{BeOS}   = $^O =~ /beos/i;    # XXX should this be that loose?
62 $Is{DOS}    = $^O eq 'dos';
63 if( $Is{NW5} ) {
64     $^O = 'NetWare';
65     delete $Is{Win32};
66 }
67 $Is{VOS}    = $^O eq 'vos';
68 $Is{QNX}    = $^O eq 'qnx';
69 $Is{AIX}    = $^O eq 'aix';
70 $Is{Darwin} = $^O eq 'darwin';
71
72 $Is{Unix}   = !grep { $_ } values %Is;
73
74 map { delete $Is{$_} unless $Is{$_} } keys %Is;
75 _assert( keys %Is == 1 );
76 my($OS) = keys %Is;
77
78
79 my $class = "ExtUtils::MM_$OS";
80 eval "require $class" unless $INC{"ExtUtils/MM_$OS.pm"}; ## no critic
81 die $@ if $@;
82 unshift @ISA, $class;
83
84
85 sub _assert {
86     my $sanity = shift;
87     die sprintf "Assert failed at %s line %d\n", (caller)[1,2] unless $sanity;
88     return;
89 }