pod/perlrebackslash.pod

   1 =head1 NAME
   2
   3 perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes
   4
   5 =head1 DESCRIPTION
   6
   7 The top level documentation about Perl regular expressions
   8 is found in L<perlre>.
   9
  10 This document describes all backslash and escape sequences. After
  11 explaining the role of the backslash, it lists all the sequences that have
  12 a special meaning in Perl regular expressions (in alphabetical order),
  13 then describes each of them.
  14
  15 Most sequences are described in detail in different documents; the primary
  16 purpose of this document is to have a quick reference guide describing all
  17 backslash and escape sequences.
  18
  19 =head2 The backslash
  20
  21 In a regular expression, the backslash can perform one of two tasks:
  22 it either takes away the special meaning of the character following it
  23 (for instance, C<\|> matches a vertical bar, it's not an alternation),
  24 or it is the start of a backslash or escape sequence.
  25
  26 The rules determining what it is are quite simple: if the character
  27 following the backslash is an ASCII punctuation (non-word) character (that is,
  28 anything that is not a letter, digit, or underscore), then the backslash just
  29 takes away any special meaning of the character following it.
  30
  31 If the character following the backslash is an ASCII letter or an ASCII digit,
  32 then the sequence may be special; if so, it's listed below. A few letters have
  33 not been used yet, so escaping them with a backslash doesn't change them to be
  34 special.  A future version of Perl may assign a special meaning to them, so if
  35 you have warnings turned on, Perl issues a warning if you use such a
  36 sequence.  [1].
  37
  38 It is however guaranteed that backslash or escape sequences never have a
  39 punctuation character following the backslash, not now, and not in a future
  40 version of Perl 5. So it is safe to put a backslash in front of a non-word
  41 character.
  42
  43 Note that the backslash itself is special; if you want to match a backslash,
  44 you have to escape the backslash with a backslash: C</\\/> matches a single
  45 backslash.
  46
  47 =over 4
  48
  49 =item [1]
  50
  51 There is one exception. If you use an alphanumeric character as the
  52 delimiter of your pattern (which you probably shouldn't do for readability
  53 reasons), you have to escape the delimiter if you want to match
  54 it. Perl won't warn then. See also L<perlop/Gory details of parsing
  55 quoted constructs>.
  56
  57 =back
  58
  59
  60 =head2 All the sequences and escapes
  61
  62 Those not usable within a bracketed character class (like C<[\da-z]>) are marked
  63 as C<Not in [].>
  64
  65  \000              Octal escape sequence.  See also \o{}.
  66  \1                Absolute backreference.  Not in [].
  67  \a                Alarm or bell.
  68  \A                Beginning of string.  Not in [].
  69  \b                Word/non-word boundary. (Backspace in []).
  70  \B                Not a word/non-word boundary.  Not in [].
  71  \cX               Control-X.
  72  \C                Single octet, even under UTF-8.  Not in [].
  73  \d                Character class for digits.
  74  \D                Character class for non-digits.
  75  \e                Escape character.
  76  \E                Turn off \Q, \L and \U processing.  Not in [].
  77  \f                Form feed.
  78  \F                Foldcase till \E.  Not in [].
  79  \g{}, \g1         Named, absolute or relative backreference.
  80                    Not in [].
  81  \G                Pos assertion.  Not in [].
  82  \h                Character class for horizontal whitespace.
  83  \H                Character class for non horizontal whitespace.
  84  \k{}, \k<>, \k''  Named backreference.  Not in [].
  85  \K                Keep the stuff left of \K.  Not in [].
  86  \l                Lowercase next character.  Not in [].
  87  \L                Lowercase till \E.  Not in [].
  88  \n                (Logical) newline character.
  89  \N                Any character but newline.  Not in [].
  90  \N{}              Named or numbered (Unicode) character or sequence.
  91  \o{}              Octal escape sequence.
  92  \p{}, \pP         Character with the given Unicode property.
  93  \P{}, \PP         Character without the given Unicode property.
  94  \Q                Quote (disable) pattern metacharacters till \E.  Not
  95                    in [].
  96  \r                Return character.
  97  \R                Generic new line.  Not in [].
  98  \s                Character class for whitespace.
  99  \S                Character class for non whitespace.
 100  \t                Tab character.
 101  \u                Titlecase next character.  Not in [].
 102  \U                Uppercase till \E.  Not in [].
 103  \v                Character class for vertical whitespace.
 104  \V                Character class for non vertical whitespace.
 105  \w                Character class for word characters.
 106  \W                Character class for non-word characters.
 107  \x{}, \x00        Hexadecimal escape sequence.
 108  \X                Unicode "extended grapheme cluster".  Not in [].
 109  \z                End of string.  Not in [].
 110  \Z                End of string.  Not in [].
 111
 112 =head2 Character Escapes
 113
 114 =head3  Fixed characters
 115
 116 A handful of characters have a dedicated I<character escape>. The following
 117 table shows them, along with their ASCII code points (in decimal and hex),
 118 their ASCII name, the control escape on ASCII platforms and a short
 119 description.  (For EBCDIC platforms, see L<perlebcdic/OPERATOR DIFFERENCES>.)
 120
 121  Seq.  Code Point  ASCII   Cntrl   Description.
 122        Dec    Hex
 123   \a     7     07    BEL    \cG    alarm or bell
 124   \b     8     08     BS    \cH    backspace [1]
 125   \e    27     1B    ESC    \c[    escape character
 126   \f    12     0C     FF    \cL    form feed
 127   \n    10     0A     LF    \cJ    line feed [2]
 128   \r    13     0D     CR    \cM    carriage return
 129   \t     9     09    TAB    \cI    tab
 130
 131 =over 4
 132
 133 =item [1]
 134
 135 C<\b> is the backspace character only inside a character class. Outside a
 136 character class, C<\b> is a word/non-word boundary.
 137
 138 =item [2]
 139
 140 C<\n> matches a logical newline. Perl converts between C<\n> and your
 141 OS's native newline character when reading from or writing to text files.
 142
 143 =back
 144
 145 =head4 Example
 146
 147  $str =~ /\t/;   # Matches if $str contains a (horizontal) tab.
 148
 149 =head3 Control characters
 150
 151 C<\c> is used to denote a control character; the character following C<\c>
 152 determines the value of the construct.  For example the value of C<\cA> is
 153 C<chr(1)>, and the value of C<\cb> is C<chr(2)>, etc.
 154 The gory details are in L<perlop/"Regexp Quote-Like Operators">.  A complete
 155 list of what C<chr(1)>, etc. means for ASCII and EBCDIC platforms is in
 156 L<perlebcdic/OPERATOR DIFFERENCES>.
 157
 158 Note that C<\c\> alone at the end of a regular expression (or doubled-quoted
 159 string) is not valid.  The backslash must be followed by another character.
 160 That is, C<\c\I<X>> means C<chr(28) . 'I<X>'> for all characters I<X>.
 161
 162 To write platform-independent code, you must use C<\N{I<NAME>}> instead, like
 163 C<\N{ESCAPE}> or C<\N{U+001B}>, see L<charnames>.
 164
 165 Mnemonic: I<c>ontrol character.
 166
 167 =head4 Example
 168
 169  $str =~ /\cK/;  # Matches if $str contains a vertical tab (control-K).
 170
 171 =head3 Named or numbered characters and character sequences
 172
 173 Unicode characters have a Unicode name and numeric code point (ordinal)
 174 value.  Use the
 175 C<\N{}> construct to specify a character by either of these values.
 176 Certain sequences of characters also have names.
 177
 178 To specify by name, the name of the character or character sequence goes
 179 between the curly braces.
 180
 181 To specify a character by Unicode code point, use the form C<\N{U+I<code
 182 point>}>, where I<code point> is a number in hexadecimal that gives the
 183 code point that Unicode has assigned to the desired character.  It is
 184 customary but not required to use leading zeros to pad the number to 4
 185 digits.  Thus C<\N{U+0041}> means C<LATIN CAPITAL LETTER A>, and you will
 186 rarely see it written without the two leading zeros.  C<\N{U+0041}> means
 187 "A" even on EBCDIC machines (where the ordinal value of "A" is not 0x41).
 188
 189 It is even possible to give your own names to characters and character
 190 sequences.  For details, see L<charnames>.
 191
 192 (There is an expanded internal form that you may see in debug output:
 193 C<\N{U+I<code point>.I<code point>...}>.
 194 The C<...> means any number of these I<code point>s separated by dots.
 195 This represents the sequence formed by the characters.  This is an internal
 196 form only, subject to change, and you should not try to use it yourself.)
 197
 198 Mnemonic: I<N>amed character.
 199
 200 Note that a character or character sequence expressed as a named
 201 or numbered character is considered a character without special
 202 meaning by the regex engine, and will match "as is".
 203
 204 =head4 Example
 205
 206  $str =~ /\N{THAI CHARACTER SO SO}/;  # Matches the Thai SO SO character
 207
 208  use charnames 'Cyrillic';            # Loads Cyrillic names.
 209  $str =~ /\N{ZHE}\N{KA}/;             # Match "ZHE" followed by "KA".
 210
 211 =head3 Octal escapes
 212
 213 There are two forms of octal escapes.  Each is used to specify a character by
 214 its code point specified in octal notation.
 215
 216 One form, available starting in Perl 5.14 looks like C<\o{...}>, where the dots
 217 represent one or more octal digits.  It can be used for any Unicode character.
 218
 219 It was introduced to avoid the potential problems with the other form,
 220 available in all Perls.  That form consists of a backslash followed by three
 221 octal digits.  One problem with this form is that it can look exactly like an
 222 old-style backreference (see
 223 L</Disambiguation rules between old-style octal escapes and backreferences>
 224 below.)  You can avoid this by making the first of the three digits always a
 225 zero, but that makes \077 the largest code point specifiable.
 226
 227 In some contexts, a backslash followed by two or even one octal digits may be
 228 interpreted as an octal escape, sometimes with a warning, and because of some
 229 bugs, sometimes with surprising results.  Also, if you are creating a regex
 230 out of smaller snippets concatenated together, and you use fewer than three
 231 digits, the beginning of one snippet may be interpreted as adding digits to the
 232 ending of the snippet before it.  See L</Absolute referencing> for more
 233 discussion and examples of the snippet problem.
 234
 235 Note that a character expressed as an octal escape is considered
 236 a character without special meaning by the regex engine, and will match
 237 "as is".
 238
 239 To summarize, the C<\o{}> form is always safe to use, and the other form is
 240 safe to use for code points through \077 when you use exactly three digits to
 241 specify them.
 242
 243 Mnemonic: I<0>ctal or I<o>ctal.
 244
 245 =head4 Examples (assuming an ASCII platform)
 246
 247  $str = "Perl";
 248  $str =~ /\o{120}/;  # Match, "\120" is "P".
 249  $str =~ /\120/;     # Same.
 250  $str =~ /\o{120}+/; # Match, "\120" is "P",
 251                      # it's repeated at least once.
 252  $str =~ /\120+/;    # Same.
 253  $str =~ /P\053/;    # No match, "\053" is "+" and taken literally.
 254  /\o{23073}/         # Black foreground, white background smiling face.
 255  /\o{4801234567}/    # Raises a warning, and yields chr(4).
 256
 257 =head4 Disambiguation rules between old-style octal escapes and backreferences
 258
 259 Octal escapes of the C<\000> form outside of bracketed character classes
 260 potentially clash with old-style backreferences (see L</Absolute referencing>
 261 below).  They both consist of a backslash followed by numbers.  So Perl has to
 262 use heuristics to determine whether it is a backreference or an octal escape.
 263 Perl uses the following rules to disambiguate:
 264
 265 =over 4
 266
 267 =item 1
 268
 269 If the backslash is followed by a single digit, it's a backreference.
 270
 271 =item 2
 272
 273 If the first digit following the backslash is a 0, it's an octal escape.
 274
 275 =item 3
 276
 277 If the number following the backslash is N (in decimal), and Perl already
 278 has seen N capture groups, Perl considers this a backreference.  Otherwise,
 279 it considers it an octal escape. If N has more than three digits, Perl
 280 takes only the first three for the octal escape; the rest are matched as is.
 281
 282  my $pat  = "(" x 999;
 283     $pat .= "a";
 284     $pat .= ")" x 999;
 285  /^($pat)\1000$/;   #  Matches 'aa'; there are 1000 capture groups.
 286  /^$pat\1000$/;     #  Matches 'a@0'; there are 999 capture groups
 287                     #  and \1000 is seen as \100 (a '@') and a '0'.
 288
 289 =back
 290
 291 You can force a backreference interpretation always by using the C<\g{...}>
 292 form.  You can the force an octal interpretation always by using the C<\o{...}>
 293 form, or for numbers up through \077 (= 63 decimal), by using three digits,
 294 beginning with a "0".
 295
 296 =head3 Hexadecimal escapes
 297
 298 Like octal escapes, there are two forms of hexadecimal escapes, but both start
 299 with the same thing, C<\x>.  This is followed by either exactly two hexadecimal
 300 digits forming a number, or a hexadecimal number of arbitrary length surrounded
 301 by curly braces. The hexadecimal number is the code point of the character you
 302 want to express.
 303
 304 Note that a character expressed as one of these escapes is considered a
 305 character without special meaning by the regex engine, and will match
 306 "as is".
 307
 308 Mnemonic: heI<x>adecimal.
 309
 310 =head4 Examples (assuming an ASCII platform)
 311
 312  $str = "Perl";
 313  $str =~ /\x50/;    # Match, "\x50" is "P".
 314  $str =~ /\x50+/;   # Match, "\x50" is "P", it is repeated at least once
 315  $str =~ /P\x2B/;   # No match, "\x2B" is "+" and taken literally.
 316
 317  /\x{2603}\x{2602}/ # Snowman with an umbrella.
 318                     # The Unicode character 2603 is a snowman,
 319                     # the Unicode character 2602 is an umbrella.
 320  /\x{263B}/         # Black smiling face.
 321  /\x{263b}/         # Same, the hex digits A - F are case insensitive.
 322
 323 =head2 Modifiers
 324
 325 A number of backslash sequences have to do with changing the character,
 326 or characters following them. C<\l> will lowercase the character following
 327 it, while C<\u> will uppercase (or, more accurately, titlecase) the
 328 character following it. They provide functionality similar to the
 329 functions C<lcfirst> and C<ucfirst>.
 330
 331 To uppercase or lowercase several characters, one might want to use
 332 C<\L> or C<\U>, which will lowercase/uppercase all characters following
 333 them, until either the end of the pattern or the next occurrence of
 334 C<\E>, whichever comes first. They provide functionality similar to what
 335 the functions C<lc> and C<uc> provide.
 336
 337 C<\Q> is used to quote (disable) pattern metacharacters, up to the next
 338 C<\E> or the end of the pattern. C<\Q> adds a backslash to any character
 339 that could have special meaning to Perl.  In the ASCII range, it quotes
 340 every character that isn't a letter, digit, or underscore.  See
 341 L<perlfunc/quotemeta> for details on what gets quoted for non-ASCII
 342 code points.  Using this ensures that any character between C<\Q> and
 343 C<\E> will be matched literally, not interpreted as a metacharacter by
 344 the regex engine.
 345
 346 C<\F> can be used to casefold all characters following, up to the next C<\E>
 347 or the end of the pattern. It provides the functionality similar to
 348 the C<fc> function.
 349
 350 Mnemonic: I<L>owercase, I<U>ppercase, I<F>old-case, I<Q>uotemeta, I<E>nd.
 351
 352 =head4 Examples
 353
 354  $sid     = "sid";
 355  $greg    = "GrEg";
 356  $miranda = "(Miranda)";
 357  $str     =~ /\u$sid/;        # Matches 'Sid'
 358  $str     =~ /\L$greg/;       # Matches 'greg'
 359  $str     =~ /\Q$miranda\E/;  # Matches '(Miranda)', as if the pattern
 360                               #   had been written as /\(Miranda\)/
 361
 362 =head2 Character classes
 363
 364 Perl regular expressions have a large range of character classes. Some of
 365 the character classes are written as a backslash sequence. We will briefly
 366 discuss those here; full details of character classes can be found in
 367 L<perlrecharclass>.
 368
 369 C<\w> is a character class that matches any single I<word> character
 370 (letters, digits, Unicode marks, and connector punctuation (like the
 371 underscore)).  C<\d> is a character class that matches any decimal
 372 digit, while the character class C<\s> matches any whitespace character.
 373 New in perl 5.10.0 are the classes C<\h> and C<\v> which match horizontal
 374 and vertical whitespace characters.
 375
 376 The exact set of characters matched by C<\d>, C<\s>, and C<\w> varies
 377 depending on various pragma and regular expression modifiers.  It is
 378 possible to restrict the match to the ASCII range by using the C</a>
 379 regular expression modifier.  See L<perlrecharclass>.
 380
 381 The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are
 382 character classes that match, respectively, any character that isn't a
 383 word character, digit, whitespace, horizontal whitespace, or vertical
 384 whitespace.
 385
 386 Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical.
 387
 388 =head3 Unicode classes
 389
 390 C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to
 391 match a character that matches the given Unicode property; properties
 392 include things like "letter", or "thai character". Capitalizing the
 393 sequence to C<\PP> and C<\P{Property}> make the sequence match a character
 394 that doesn't match the given Unicode property. For more details, see
 395 L<perlrecharclass/Backslash sequences> and
 396 L<perlunicode/Unicode Character Properties>.
 397
 398 Mnemonic: I<p>roperty.
 399
 400 =head2 Referencing
 401
 402 If capturing parenthesis are used in a regular expression, we can refer
 403 to the part of the source string that was matched, and match exactly the
 404 same thing. There are three ways of referring to such I<backreference>:
 405 absolutely, relatively, and by name.
 406
 407 =for later add link to perlrecapture
 408
 409 =head3 Absolute referencing
 410
 411 Either C<\gI<N>> (starting in Perl 5.10.0), or C<\I<N>> (old-style) where I<N>
 412 is a positive (unsigned) decimal number of any length is an absolute reference
 413 to a capturing group.
 414
 415 I<N> refers to the Nth set of parentheses, so C<\gI<N>> refers to whatever has
 416 been matched by that set of parentheses.  Thus C<\g1> refers to the first
 417 capture group in the regex.
 418
 419 The C<\gI<N>> form can be equivalently written as C<\g{I<N>}>
 420 which avoids ambiguity when building a regex by concatenating shorter
 421 strings.  Otherwise if you had a regex C<qr/$a$b/>, and C<$a> contained
 422 C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which is
 423 probably not what you intended.
 424
 425 In the C<\I<N>> form, I<N> must not begin with a "0", and there must be at
 426 least I<N> capturing groups, or else I<N> is considered an octal escape
 427 (but something like C<\18> is the same as C<\0018>; that is, the octal escape
 428 C<"\001"> followed by a literal digit C<"8">).
 429
 430 Mnemonic: I<g>roup.
 431
 432 =head4 Examples
 433
 434  /(\w+) \g1/;    # Finds a duplicated word, (e.g. "cat cat").
 435  /(\w+) \1/;     # Same thing; written old-style.
 436  /(.)(.)\g2\g1/;  # Match a four letter palindrome (e.g. "ABBA").
 437
 438
 439 =head3 Relative referencing
 440
 441 C<\g-I<N>> (starting in Perl 5.10.0) is used for relative addressing.  (It can
 442 be written as C<\g{-I<N>>.)  It refers to the I<N>th group before the
 443 C<\g{-I<N>}>.
 444
 445 The big advantage of this form is that it makes it much easier to write
 446 patterns with references that can be interpolated in larger patterns,
 447 even if the larger pattern also contains capture groups.
 448
 449 =head4 Examples
 450
 451  /(A)        # Group 1
 452   (          # Group 2
 453     (B)      # Group 3
 454     \g{-1}   # Refers to group 3 (B)
 455     \g{-3}   # Refers to group 1 (A)
 456   )
 457  /x;         # Matches "ABBA".
 458
 459  my $qr = qr /(.)(.)\g{-2}\g{-1}/;  # Matches 'abab', 'cdcd', etc.
 460  /$qr$qr/                           # Matches 'ababcdcd'.
 461
 462 =head3 Named referencing
 463
 464 C<\g{I<name>}> (starting in Perl 5.10.0) can be used to back refer to a
 465 named capture group, dispensing completely with having to think about capture
 466 buffer positions.
 467
 468 To be compatible with .Net regular expressions, C<\g{name}> may also be
 469 written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>.
 470
 471 To prevent any ambiguity, I<name> must not start with a digit nor contain a
 472 hyphen.
 473
 474 =head4 Examples
 475
 476  /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat")
 477  /(?<word>\w+) \k{word}/ # Same.
 478  /(?<word>\w+) \k<word>/ # Same.
 479  /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/
 480                          # Match a four letter palindrome (e.g. "ABBA")
 481
 482 =head2 Assertions
 483
 484 Assertions are conditions that have to be true; they don't actually
 485 match parts of the substring. There are six assertions that are written as
 486 backslash sequences.
 487
 488 =over 4
 489
 490 =item \A
 491
 492 C<\A> only matches at the beginning of the string. If the C</m> modifier
 493 isn't used, then C</\A/> is equivalent to C</^/>. However, if the C</m>
 494 modifier is used, then C</^/> matches internal newlines, but the meaning
 495 of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning
 496 of the string regardless whether the C</m> modifier is used.
 497
 498 =item \z, \Z
 499
 500 C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't
 501 used, then C</\Z/> is equivalent to C</$/>; that is, it matches at the
 502 end of the string, or one before the newline at the end of the string. If the
 503 C</m> modifier is used, then C</$/> matches at internal newlines, but the
 504 meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at
 505 the end of the string (or just before a trailing newline) regardless whether
 506 the C</m> modifier is used.
 507
 508 C<\z> is just like C<\Z>, except that it does not match before a trailing
 509 newline. C<\z> matches at the end of the string only, regardless of the
 510 modifiers used, and not just before a newline.  It is how to anchor the
 511 match to the true end of the string under all conditions.
 512
 513 =item \G
 514
 515 C<\G> is usually used only in combination with the C</g> modifier. If the
 516 C</g> modifier is used and the match is done in scalar context, Perl
 517 remembers where in the source string the last match ended, and the next time,
 518 it will start the match from where it ended the previous time.
 519
 520 C<\G> matches the point where the previous match on that string ended,
 521 or the beginning of that string if there was no previous match.
 522
 523 =for later add link to perlremodifiers
 524
 525 Mnemonic: I<G>lobal.
 526
 527 =item \b, \B
 528
 529 C<\b> matches at any place between a word and a non-word character; C<\B>
 530 matches at any place between characters where C<\b> doesn't match. C<\b>
 531 and C<\B> assume there's a non-word character before the beginning and after
 532 the end of the source string; so C<\b> will match at the beginning (or end)
 533 of the source string if the source string begins (or ends) with a word
 534 character. Otherwise, C<\B> will match.
 535
 536 Do not use something like C<\b=head\d\b> and expect it to match the
 537 beginning of a line.  It can't, because for there to be a boundary before
 538 the non-word "=", there must be a word character immediately previous.
 539 All boundary determinations look for word characters alone, not for
 540 non-words characters nor for string ends.  It may help to understand how
 541 <\b> and <\B> work by equating them as follows:
 542
 543     \b  really means    (?:(?<=\w)(?!\w)|(?<!\w)(?=\w))
 544     \B  really means    (?:(?<=\w)(?=\w)|(?<!\w)(?!\w))
 545
 546 Mnemonic: I<b>oundary.
 547
 548 =back
 549
 550 =head4 Examples
 551
 552   "cat"   =~ /\Acat/;     # Match.
 553   "cat"   =~ /cat\Z/;     # Match.
 554   "cat\n" =~ /cat\Z/;     # Match.
 555   "cat\n" =~ /cat\z/;     # No match.
 556
 557   "cat"   =~ /\bcat\b/;   # Matches.
 558   "cats"  =~ /\bcat\b/;   # No match.
 559   "cat"   =~ /\bcat\B/;   # No match.
 560   "cats"  =~ /\bcat\B/;   # Match.
 561
 562   while ("cat dog" =~ /(\w+)/g) {
 563       print $1;           # Prints 'catdog'
 564   }
 565   while ("cat dog" =~ /\G(\w+)/g) {
 566       print $1;           # Prints 'cat'
 567   }
 568
 569 =head2 Misc
 570
 571 Here we document the backslash sequences that don't fall in one of the
 572 categories above. These are:
 573
 574 =over 4
 575
 576 =item \C
 577
 578 C<\C> always matches a single octet, even if the source string is encoded
 579 in UTF-8 format, and the character to be matched is a multi-octet character.
 580 This is very dangerous, because it violates
 581 the logical character abstraction and can cause UTF-8 sequences to become malformed.
 582
 583 Mnemonic: oI<C>tet.
 584
 585 =item \K
 586
 587 This appeared in perl 5.10.0. Anything matched left of C<\K> is
 588 not included in C<$&>, and will not be replaced if the pattern is
 589 used in a substitution. This lets you write C<s/PAT1 \K PAT2/REPL/x>
 590 instead of C<s/(PAT1) PAT2/${1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>.
 591
 592 Mnemonic: I<K>eep.
 593
 594 =item \N
 595
 596 This feature, available starting in v5.12,  matches any character
 597 that is B<not> a newline.  It is a short-hand for writing C<[^\n]>, and is
 598 identical to the C<.> metasymbol, except under the C</s> flag, which changes
 599 the meaning of C<.>, but not C<\N>.
 600
 601 Note that C<\N{...}> can mean a
 602 L<named or numbered character
 603 |/Named or numbered characters and character sequences>.
 604
 605 Mnemonic: Complement of I<\n>.
 606
 607 =item \R
 608 X<\R>
 609
 610 C<\R> matches a I<generic newline>; that is, anything considered a
 611 linebreak sequence by Unicode. This includes all characters matched by
 612 C<\v> (vertical whitespace), and the multi character sequence C<"\x0D\x0A">
 613 (carriage return followed by a line feed, sometimes called the network
 614 newline; it's the end of line sequence used in Microsoft text files opened
 615 in binary mode). C<\R> is equivalent to C<< (?>\x0D\x0A|\v) >>.  (The
 616 reason it doesn't backtrack is that the sequence is considered
 617 inseparable.  That means that
 618
 619  "\x0D\x0A" =~ /^\R\x0A$/   # No match
 620
 621 fails, because the C<\R> matches the entire string, and won't backtrack
 622 to match just the C<"\x0D">.)  Since
 623 C<\R> can match a sequence of more than one character, it cannot be put
 624 inside a bracketed character class; C</[\R]/> is an error; use C<\v>
 625 instead.  C<\R> was introduced in perl 5.10.0.
 626
 627 Note that this does not respect any locale that might be in effect; it
 628 matches according to the platform's native character set.
 629
 630 Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>,
 631 and more importantly because Unicode recommends such a regular expression
 632 metacharacter, and suggests C<\R> as its notation.
 633
 634 =item \X
 635 X<\X>
 636
 637 This matches a Unicode I<extended grapheme cluster>.
 638
 639 C<\X> matches quite well what normal (non-Unicode-programmer) usage
 640 would consider a single character.  As an example, consider a G with some sort
 641 of diacritic mark, such as an arrow.  There is no such single character in
 642 Unicode, but one can be composed by using a G followed by a Unicode "COMBINING
 643 UPWARDS ARROW BELOW", and would be displayed by Unicode-aware software as if it
 644 were a single character.
 645
 646 Mnemonic: eI<X>tended Unicode character.
 647
 648 =back
 649
 650 =head4 Examples
 651
 652  "\x{256}" =~ /^\C\C$/;    # Match as chr (0x256) takes
 653                            # 2 octets in UTF-8.
 654
 655  $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz'
 656  $str =~ s/(.)\K\g1//g;    # Delete duplicated characters.
 657
 658  "\n"   =~ /^\R$/;         # Match, \n   is a generic newline.
 659  "\r"   =~ /^\R$/;         # Match, \r   is a generic newline.
 660  "\r\n" =~ /^\R$/;         # Match, \r\n is a generic newline.
 661
 662  "P\x{307}" =~ /^\X$/     # \X matches a P with a dot above.
 663
 664 =cut