This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
7847678772d376848c9ac3479954415470ef21e9
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compiliation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25
26 require 5.010_001;
27 use strict;
28 use warnings;
29 use Carp;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34
35 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
36
37 ##########################################################################
38 #
39 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
40 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
41 # a pod file and a .t file
42 #
43 # The structure of this file is:
44 #   First these introductory comments; then
45 #   code needed for everywhere, such as debugging stuff; then
46 #   code to handle input parameters; then
47 #   data structures likely to be of external interest (some of which depend on
48 #       the input parameters, so follows them; then
49 #   more data structures and subroutine and package (class) definitions; then
50 #   the small actual loop to process the input files and finish up; then
51 #   a __DATA__ section, for the .t tests
52 #
53 # This program works on all releases of Unicode through at least 5.2.  The
54 # outputs have been scrutinized most intently for release 5.1.  The others
55 # have been checked for somewhat more than just sanity.  It can handle all
56 # existing Unicode character properties in those releases.
57 #
58 # This program is mostly about Unicode character (or code point) properties.
59 # A property describes some attribute or quality of a code point, like if it
60 # is lowercase or not, its name, what version of Unicode it was first defined
61 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
62 # possibilities by making all properties into mappings from each code point
63 # into some corresponding value.  In the case of it being lowercase or not,
64 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
65 # property maps each Unicode code point to a single value, called a "property
66 # value".  (Hence each Unicode property is a true mathematical function with
67 # exactly one value per code point.)
68 #
69 # When using a property in a regular expression, what is desired isn't the
70 # mapping of the code point to its property's value, but the reverse (or the
71 # mathematical "inverse relation"): starting with the property value, "Does a
72 # code point map to it?"  These are written in a "compound" form:
73 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
74 # files containing the lists of code points that map to each such regular
75 # expression property value, one file per list
76 #
77 # There is also a single form shortcut that Perl adds for many of the commonly
78 # used properties.  This happens for all binary properties, plus script,
79 # general_category, and block properties.
80 #
81 # Thus the outputs of this program are files.  There are map files, mostly in
82 # the 'To' directory; and there are list files for use in regular expression
83 # matching, all in subdirectories of the 'lib' directory, with each
84 # subdirectory being named for the property that the lists in it are for.
85 # Bookkeeping, test, and documentation files are also generated.
86
87 my $matches_directory = 'lib';   # Where match (\p{}) files go.
88 my $map_directory = 'To';        # Where map files go.
89
90 # DATA STRUCTURES
91 #
92 # The major data structures of this program are Property, of course, but also
93 # Table.  There are two kinds of tables, very similar to each other.
94 # "Match_Table" is the data structure giving the list of code points that have
95 # a particular property value, mentioned above.  There is also a "Map_Table"
96 # data structure which gives the property's mapping from code point to value.
97 # There are two structures because the match tables need to be combined in
98 # various ways, such as constructing unions, intersections, complements, etc.,
99 # and the map ones don't.  And there would be problems, perhaps subtle, if
100 # a map table were inadvertently operated on in some of those ways.
101 # The use of separate classes with operations defined on one but not the other
102 # prevents accidentally confusing the two.
103 #
104 # At the heart of each table's data structure is a "Range_List", which is just
105 # an ordered list of "Ranges", plus ancillary information, and methods to
106 # operate on them.  A Range is a compact way to store property information.
107 # Each range has a starting code point, an ending code point, and a value that
108 # is meant to apply to all the code points between the two end points,
109 # inclusive.  For a map table, this value is the property value for those
110 # code points.  Two such ranges could be written like this:
111 #   0x41 .. 0x5A, 'Upper',
112 #   0x61 .. 0x7A, 'Lower'
113 #
114 # Each range also has a type used as a convenience to classify the values.
115 # Most ranges in this program will be Type 0, or normal, but there are some
116 # ranges that have a non-zero type.  These are used only in map tables, and
117 # are for mappings that don't fit into the normal scheme of things.  Mappings
118 # that require a hash entry to communicate with utf8.c are one example;
119 # another example is mappings for charnames.pm to use which indicate a name
120 # that is algorithmically determinable from its code point (and vice-versa).
121 # These are used to significantly compact these tables, instead of listing
122 # each one of the tens of thousands individually.
123 #
124 # In a match table, the value of a range is irrelevant (and hence the type as
125 # well, which will always be 0), and arbitrarily set to the null string.
126 # Using the example above, there would be two match tables for those two
127 # entries, one named Upper would contain the 0x41..0x5A range, and the other
128 # named Lower would contain 0x61..0x7A.
129 #
130 # Actually, there are two types of range lists, "Range_Map" is the one
131 # associated with map tables, and "Range_List" with match tables.
132 # Again, this is so that methods can be defined on one and not the other so as
133 # to prevent operating on them in incorrect ways.
134 #
135 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
136 # in the perl core.  All tables could in theory be written, but some are
137 # suppressed because there is no current practical use for them.  It is easy
138 # to change which get written by changing various lists that are near the top
139 # of the actual code in this file.  The table data structures contain enough
140 # ancillary information to allow them to be treated as separate entities for
141 # writing, such as the path to each one's file.  There is a heading in each
142 # map table that gives the format of its entries, and what the map is for all
143 # the code points missing from it.  (This allows tables to be more compact.)
144 #
145 # The Property data structure contains one or more tables.  All properties
146 # contain a map table (except the $perl property which is a
147 # pseudo-property containing only match tables), and any properties that
148 # are usable in regular expression matches also contain various matching
149 # tables, one for each value the property can have.  A binary property can
150 # have two values, True and False (or Y and N, which are preferred by Unicode
151 # terminology).  Thus each of these properties will have a map table that
152 # takes every code point and maps it to Y or N (but having ranges cuts the
153 # number of entries in that table way down), and two match tables, one
154 # which has a list of all the code points that map to Y, and one for all the
155 # code points that map to N.  (For each of these, a third table is also
156 # generated for the pseudo Perl property.  It contains the identical code
157 # points as the Y table, but can be written, not in the compound form, but in
158 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
159 # properties have several possible values, some have many, and properties like
160 # Name have a different value for every named code point.  Those will not,
161 # unless the controlling lists are changed, have their match tables written
162 # out.  But all the ones which can be used in regular expression \p{} and \P{}
163 # constructs will.  Generally a property will have either its map table or its
164 # match tables written but not both.  Again, what gets written is controlled
165 # by lists which can easily be changed.
166 #
167 # For information about the Unicode properties, see Unicode's UAX44 document:
168
169 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
170
171 # As stated earlier, this program will work on any release of Unicode so far.
172 # Most obvious problems in earlier data have NOT been corrected except when
173 # necessary to make Perl or this program work reasonably.  For example, no
174 # folding information was given in early releases, so this program uses the
175 # substitute of lower case, just so that a regular expression with the /i
176 # option will do something that actually gives the right results in many
177 # cases.  There are also a couple other corrections for version 1.1.5,
178 # commented at the point they are made.  As an example of corrections that
179 # weren't made (but could be) is this statement from DerivedAge.txt: "The
180 # supplementary private use code points and the non-character code points were
181 # assigned in version 2.0, but not specifically listed in the UCD until
182 # versions 3.0 and 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0)
183 # More information on Unicode version glitches is further down in these
184 # introductory comments.
185 #
186 # This program works on all properties as of 5.2, though the files for some
187 # are suppressed from apparent lack of demand for them.  You can change which
188 # are output by changing lists in this program.
189 #
190 # The old version of mktables emphasized the term "Fuzzy" to mean Unocde's
191 # loose matchings rules (from Unicode TR18):
192 #
193 #    The recommended names for UCD properties and property values are in
194 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
195 #    [PropValue]. There are both abbreviated names and longer, more
196 #    descriptive names. It is strongly recommended that both names be
197 #    recognized, and that loose matching of property names be used,
198 #    whereby the case distinctions, whitespace, hyphens, and underbar
199 #    are ignored.
200 # The program still allows Fuzzy to override its determination of if loose
201 # matching should be used, but it isn't currently used, as it is no longer
202 # needed; the calculations it makes are good enough.
203 #
204 # SUMMARY OF HOW IT WORKS:
205 #
206 #   Process arguments
207 #
208 #   A list is constructed containing each input file that is to be processed
209 #
210 #   Each file on the list is processed in a loop, using the associated handler
211 #   code for each:
212 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
213 #            first.  These files name the properties and property values.
214 #            Objects are created of all the property and property value names
215 #            that the rest of the input should expect, including all synonyms.
216 #        The other input files give mappings from properties to property
217 #           values.  That is, they list code points and say what the mapping
218 #           is under the given property.  Some files give the mappings for
219 #           just one property; and some for many.  This program goes through
220 #           each file and populates the properties from them.  Some properties
221 #           are listed in more than one file, and Unicode has set up a
222 #           precedence as to which has priority if there is a conflict.  Thus
223 #           the order of processing matters, and this program handles the
224 #           conflict possibility by processing the overriding input files
225 #           last, so that if necessary they replace earlier values.
226 #        After this is all done, the program creates the property mappings not
227 #            furnished by Unicode, but derivable from what it does give.
228 #        The tables of code points that match each property value in each
229 #            property that is accessible by regular expressions are created.
230 #        The Perl-defined properties are created and populated.  Many of these
231 #            require data determined from the earlier steps
232 #        Any Perl-defined synonyms are created, and name clashes between Perl
233 #            and Unicode are reconciled and warned about.
234 #        All the properties are written to files
235 #        Any other files are written, and final warnings issued.
236 #
237 # For clarity, a number of operators have been overloaded to work on tables:
238 #   ~ means invert (take all characters not in the set).  The more
239 #       conventional '!' is not used because of the possibility of confusing
240 #       it with the actual boolean operation.
241 #   + means union
242 #   - means subtraction
243 #   & means intersection
244 # The precedence of these is the order listed.  Parentheses should be
245 # copiously used.  These are not a general scheme.  The operations aren't
246 # defined for a number of things, deliberately, to avoid getting into trouble.
247 # Operations are done on references and affect the underlying structures, so
248 # that the copy constructors for them have been overloaded to not return a new
249 # clone, but the input object itself.
250 #
251 # The bool operator is deliberately not overloaded to avoid confusion with
252 # "should it mean if the object merely exists, or also is non-empty?".
253 #
254 # WHY CERTAIN DESIGN DECISIONS WERE MADE
255 #
256 # This program needs to be able to run under miniperl.  Therefore, it uses a
257 # minimum of other modules, and hence implements some things itself that could
258 # be gotten from CPAN
259 #
260 # This program uses inputs published by the Unicode Consortium.  These can
261 # change incompatibly between releases without the Perl maintainers realizing
262 # it.  Therefore this program is now designed to try to flag these.  It looks
263 # at the directories where the inputs are, and flags any unrecognized files.
264 # It keeps track of all the properties in the files it handles, and flags any
265 # that it doesn't know how to handle.  It also flags any input lines that
266 # don't match the expected syntax, among other checks.
267 #
268 # It is also designed so if a new input file matches one of the known
269 # templates, one hopefully just needs to add it to a list to have it
270 # processed.
271 #
272 # As mentioned earlier, some properties are given in more than one file.  In
273 # particular, the files in the extracted directory are supposedly just
274 # reformattings of the others.  But they contain information not easily
275 # derivable from the other files, including results for Unihan, which this
276 # program doesn't ordinarily look at, and for unassigned code points.  They
277 # also have historically had errors or been incomplete.  In an attempt to
278 # create the best possible data, this program thus processes them first to
279 # glean information missing from the other files; then processes those other
280 # files to override any errors in the extracted ones.  Much of the design was
281 # driven by this need to store things and then possibly override them.
282 #
283 # It tries to keep fatal errors to a minimum, to generate something usable for
284 # testing purposes.  It always looks for files that could be inputs, and will
285 # warn about any that it doesn't know how to handle (the -q option suppresses
286 # the warning).
287 #
288 # Why have files written out for binary 'N' matches?
289 #   For binary properties, if you know the mapping for either Y or N; the
290 #   other is trivial to construct, so could be done at Perl run-time by just
291 #   complementing the result, instead of having a file for it.  That is, if
292 #   someone types in \p{foo: N}, Perl could translate that to \P{foo: Y} and
293 #   not need a file.   The problem is communicating to Perl that a given
294 #   property is binary.  Perl can't figure it out from looking at the N (or
295 #   No), as some non-binary properties have these as property values.  So
296 #   rather than inventing a way to communicate this info back to the core,
297 #   which would have required changes there as well, it was simpler just to
298 #   add the extra tables.
299 #
300 # Why is there more than one type of range?
301 #   This simplified things.  There are some very specialized code points that
302 #   have to be handled specially for output, such as Hangul syllable names.
303 #   By creating a range type (done late in the development process), it
304 #   allowed this to be stored with the range, and overridden by other input.
305 #   Originally these were stored in another data structure, and it became a
306 #   mess trying to decide if a second file that was for the same property was
307 #   overriding the earlier one or not.
308 #
309 # Why are there two kinds of tables, match and map?
310 #   (And there is a base class shared by the two as well.)  As stated above,
311 #   they actually are for different things.  Development proceeded much more
312 #   smoothly when I (khw) realized the distinction.  Map tables are used to
313 #   give the property value for every code point (actually every code point
314 #   that doesn't map to a default value).  Match tables are used for regular
315 #   expression matches, and are essentially the inverse mapping.  Separating
316 #   the two allows more specialized methods, and error checks so that one
317 #   can't just take the intersection of two map tables, for example, as that
318 #   is nonsensical.
319 #
320 # There are no match tables generated for matches of the null string.  These
321 # would look like qr/\p{JSN=}/ currently without modifying the regex code.
322 # Perhaps something like them could be added if necessary.  The JSN does have
323 # a real code point U+110B that maps to the null string, but it is a
324 # contributory property, and therefore not output by default.  And it's easily
325 # handled so far by making the null string the default where it is a
326 # possibility.
327 #
328 # DEBUGGING
329 #
330 # This program is written so it will run under miniperl.  Occasionally changes
331 # will cause an error where the backtrace doesn't work well under miniperl.
332 # To diagnose the problem, you can instead run it under regular perl, if you
333 # have one compiled.
334 #
335 # There is a good trace facility.  To enable it, first sub DEBUG must be set
336 # to return true.  Then a line like
337 #
338 # local $to_trace = 1 if main::DEBUG;
339 #
340 # can be added to enable tracing in its lexical scope or until you insert
341 # another line:
342 #
343 # local $to_trace = 0 if main::DEBUG;
344 #
345 # then use a line like "trace $a, @b, %c, ...;
346 #
347 # Some of the more complex subroutines already have trace statements in them.
348 # Permanent trace statements should be like:
349 #
350 # trace ... if main::DEBUG && $to_trace;
351 #
352 # If there is just one or a few files that you're debugging, you can easily
353 # cause most everything else to be skipped.  Change the line
354 #
355 # my $debug_skip = 0;
356 #
357 # to 1, and every file whose object is in @input_file_objects and doesn't have
358 # a, 'non_skip => 1,' in its constructor will be skipped.
359 #
360 # FUTURE ISSUES
361 #
362 # The program would break if Unicode were to change its names so that
363 # interior white space, underscores, or dashes differences were significant
364 # within property and property value names.
365 #
366 # It might be easier to use the xml versions of the UCD if this program ever
367 # would need heavy revision, and the ability to handle old versions was not
368 # required.
369 #
370 # There is the potential for name collisions, in that Perl has chosen names
371 # that Unicode could decide it also likes.  There have been such collisions in
372 # the past, with mostly Perl deciding to adopt the Unicode definition of the
373 # name.  However in the 5.2 Unicode beta testing, there were a number of such
374 # collisions, which were withdrawn before the final release, because of Perl's
375 # and other's protests.  These all involved new properties which began with
376 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
377 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
378 # Unicode document, so they are unlikely to be used by Unicode for another
379 # purpose.  However, they might try something beginning with 'In', or use any
380 # of the other Perl-defined properties.  This program will warn you of name
381 # collisions, and refuse to generate tables with them, but manual intervention
382 # will be required in this event.  One scheme that could be implemented, if
383 # necessary, would be to have this program generate another file, or add a
384 # field to mktables.lst that gives the date of first definition of a property.
385 # Each new release of Unicode would use that file as a basis for the next
386 # iteration.  And the Perl synonym addition code could sort based on the age
387 # of the property, so older properties get priority, and newer ones that clash
388 # would be refused; hence existing code would not be impacted, and some other
389 # synonym would have to be used for the new property.  This is ugly, and
390 # manual intervention would certainly be easier to do in the short run; lets
391 # hope it never comes to this.
392 #
393 # A NOTE ON UNIHAN
394 #
395 # This program can generate tables from the Unihan database.  But it doesn't
396 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
397 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
398 # database was split into 8 different files, all beginning with the letters
399 # 'Unihan'.  This program will read those file(s) if present, but it needs to
400 # know which of the many properties in the file(s) should have tables created
401 # for them.  It will create tables for any properties listed in
402 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
403 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
404 # property you want is not in those files of the release you are building
405 # against, you must add it to those two arrays.  Starting in 4.0, the
406 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
407 # is present in the directory, a table will be generated for that property.
408 # In 5.2, several more properties were added.  For your convenience, the two
409 # arrays are initialized with all the 5.2 listed properties that are also in
410 # earlier releases.  But these are commented out.  You can just uncomment the
411 # ones you want, or use them as a template for adding entries for other
412 # properties.
413 #
414 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
415 # and filter_unihan_line() are the functions where this is done.  This program
416 # already does some adjusting to make the lines look more like the rest of the
417 # Unicode DB;  You can see what that is in filter_unihan_line()
418 #
419 # There is a bug in the 3.2 data file in which some values for the
420 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
421 # could be added for these; or for a particular installation, the Unihan.txt
422 # file could be edited to fix them.
423 #
424 # HOW TO ADD A FILE TO BE PROCESSED
425 #
426 # A new file from Unicode needs to have an object constructed for it in
427 # @input_file_objects, probably at the end or at the end of the extracted
428 # ones.  The program should warn you if its name will clash with others on
429 # restrictive file systems, like DOS.  If so, figure out a better name, and
430 # add lines to the README.perl file giving that.  If the file is a character
431 # property, it should be in the format that Unicode has by default
432 # standardized for such files for the more recently introduced ones.
433 # If so, the Input_file constructor for @input_file_objects can just be the
434 # file name and release it first appeared in.  If not, then it should be
435 # possible to construct an each_line_handler() to massage the line into the
436 # standardized form.
437 #
438 # For non-character properties, more code will be needed.  You can look at
439 # the existing entries for clues.
440 #
441 # UNICODE VERSIONS NOTES
442 #
443 # The Unicode UCD has had a number of errors in it over the versions.  And
444 # these remain, by policy, in the standard for that version.  Therefore it is
445 # risky to correct them, because code may be expecting the error.  So this
446 # program doesn't generally make changes, unless the error breaks the Perl
447 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
448 # for U+1105, which causes real problems for the algorithms for Jamo
449 # calculations, so it is changed here.
450 #
451 # But it isn't so clear cut as to what to do about concepts that are
452 # introduced in a later release; should they extend back to earlier releases
453 # where the concept just didn't exist?  It was easier to do this than to not,
454 # so that's what was done.  For example, the default value for code points not
455 # in the files for various properties was probably undefined until changed by
456 # some version.  No_Block for blocks is such an example.  This program will
457 # assign No_Block even in Unicode versions that didn't have it.  This has the
458 # benefit that code being written doesn't have to special case earlier
459 # versions; and the detriment that it doesn't match the Standard precisely for
460 # the affected versions.
461 #
462 # Here are some observations about some of the issues in early versions:
463 #
464 # The number of code points in \p{alpha} halve in 2.1.9.  It turns out that
465 # the reason is that the CJK block starting at 4E00 was removed from PropList,
466 # and was not put back in until 3.1.0
467 #
468 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
469 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
470 # reason is that 3.2 introduced U+205F=medium math space, which was not
471 # classed as white space, but Perl figured out that it should have been. 4.0
472 # reclassified it correctly.
473 #
474 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
475 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
476 # was left with no code points, as all the ones that mapped to 202 stayed
477 # mapped to 202.  Thus if your program used the numeric name for the class,
478 # it would not have been affected, but if it used the mnemonic, it would have
479 # been.
480 #
481 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
482 # points which eventually came to have this script property value, instead
483 # mapped to "Unknown".  But in the next release all these code points were
484 # moved to \p{sc=common} instead.
485 #
486 # The default for missing code points for BidiClass is complicated.  Starting
487 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
488 # tries to do the best it can for earlier releases.  It is done in
489 # process_PropertyAliases()
490 #
491 ##############################################################################
492
493 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
494                         # and errors
495 my $MAX_LINE_WIDTH = 78;
496
497 # Debugging aid to skip most files so as to not be distracted by them when
498 # concentrating on the ones being debugged.  Add
499 # non_skip => 1,
500 # to the constructor for those files you want processed when you set this.
501 # Files with a first version number of 0 are special: they are always
502 # processed regardless of the state of this flag.
503 my $debug_skip = 0;
504
505 # Set to 1 to enable tracing.
506 our $to_trace = 0;
507
508 { # Closure for trace: debugging aid
509     my $print_caller = 1;        # ? Include calling subroutine name
510     my $main_with_colon = 'main::';
511     my $main_colon_length = length($main_with_colon);
512
513     sub trace {
514         return unless $to_trace;        # Do nothing if global flag not set
515
516         my @input = @_;
517
518         local $DB::trace = 0;
519         $DB::trace = 0;          # Quiet 'used only once' message
520
521         my $line_number;
522
523         # Loop looking up the stack to get the first non-trace caller
524         my $caller_line;
525         my $caller_name;
526         my $i = 0;
527         do {
528             $line_number = $caller_line;
529             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
530             $caller = $main_with_colon unless defined $caller;
531
532             $caller_name = $caller;
533
534             # get rid of pkg
535             $caller_name =~ s/.*:://;
536             if (substr($caller_name, 0, $main_colon_length)
537                 eq $main_with_colon)
538             {
539                 $caller_name = substr($caller_name, $main_colon_length);
540             }
541
542         } until ($caller_name ne 'trace');
543
544         # If the stack was empty, we were called from the top level
545         $caller_name = 'main' if ($caller_name eq ""
546                                     || $caller_name eq 'trace');
547
548         my $output = "";
549         foreach my $string (@input) {
550             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
551             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
552                 $output .= simple_dumper($string);
553             }
554             else {
555                 $string = "$string" if ref $string;
556                 $string = $UNDEF unless defined $string;
557                 chomp $string;
558                 $string = '""' if $string eq "";
559                 $output .= " " if $output ne ""
560                                 && $string ne ""
561                                 && substr($output, -1, 1) ne " "
562                                 && substr($string, 0, 1) ne " ";
563                 $output .= $string;
564             }
565         }
566
567         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
568         print STDERR "$caller_name: " if $print_caller;
569         print STDERR $output, "\n";
570         return;
571     }
572 }
573
574 # This is for a rarely used development feature that allows you to compare two
575 # versions of the Unicode standard without having to deal with changes caused
576 # by the code points introduced in the later verson.  Change the 0 to a SINGLE
577 # dotted Unicode release number (e.g. 2.1).  Only code points introduced in
578 # that release and earlier will be used; later ones are thrown away.  You use
579 # the version number of the earliest one you want to compare; then run this
580 # program on directory structures containing each release, and compare the
581 # outputs.  These outputs will therefore include only the code points common
582 # to both releases, and you can see the changes caused just by the underlying
583 # release semantic changes.  For versions earlier than 3.2, you must copy a
584 # version of DAge.txt into the directory.
585 my $string_compare_versions = DEBUG && 0; #  e.g., v2.1;
586 my $compare_versions = DEBUG
587                        && $string_compare_versions
588                        && pack "C*", split /\./, $string_compare_versions;
589
590 sub uniques {
591     # Returns non-duplicated input values.  From "Perl Best Practices:
592     # Encapsulated Cleverness".  p. 455 in first edition.
593
594     my %seen;
595     # Arguably this breaks encapsulation, if the goal is to permit multiple
596     # distinct objects to stringify to the same value, and be interchangeable.
597     # However, for this program, no two objects stringify identically, and all
598     # lists passed to this function are either objects or strings. So this
599     # doesn't affect correctness, but it does give a couple of percent speedup.
600     no overloading;
601     return grep { ! $seen{$_}++ } @_;
602 }
603
604 $0 = File::Spec->canonpath($0);
605
606 my $make_test_script = 0;      # ? Should we output a test script
607 my $write_unchanged_files = 0; # ? Should we update the output files even if
608                                #    we don't think they have changed
609 my $use_directory = "";        # ? Should we chdir somewhere.
610 my $pod_directory;             # input directory to store the pod file.
611 my $pod_file = 'perluniprops';
612 my $t_path;                     # Path to the .t test file
613 my $file_list = 'mktables.lst'; # File to store input and output file names.
614                                # This is used to speed up the build, by not
615                                # executing the main body of the program if
616                                # nothing on the list has changed since the
617                                # previous build
618 my $make_list = 1;             # ? Should we write $file_list.  Set to always
619                                # make a list so that when the pumpking is
620                                # preparing a release, s/he won't have to do
621                                # special things
622 my $glob_list = 0;             # ? Should we try to include unknown .txt files
623                                # in the input.
624 my $output_range_counts = 1;   # ? Should we include the number of code points
625                                # in ranges in the output
626 my $output_names = 0;          # ? Should character names be in the output
627 my @viacode;                   # Contains the 1 million character names, if
628                                # $output_names is true
629
630 # Verbosity levels; 0 is quiet
631 my $NORMAL_VERBOSITY = 1;
632 my $PROGRESS = 2;
633 my $VERBOSE = 3;
634
635 my $verbosity = $NORMAL_VERBOSITY;
636
637 # Process arguments
638 while (@ARGV) {
639     my $arg = shift @ARGV;
640     if ($arg eq '-v') {
641         $verbosity = $VERBOSE;
642     }
643     elsif ($arg eq '-p') {
644         $verbosity = $PROGRESS;
645         $| = 1;     # Flush buffers as we go.
646     }
647     elsif ($arg eq '-q') {
648         $verbosity = 0;
649     }
650     elsif ($arg eq '-w') {
651         $write_unchanged_files = 1; # update the files even if havent changed
652     }
653     elsif ($arg eq '-check') {
654         my $this = shift @ARGV;
655         my $ok = shift @ARGV;
656         if ($this ne $ok) {
657             print "Skipping as check params are not the same.\n";
658             exit(0);
659         }
660     }
661     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
662         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
663     }
664     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
665     {
666         $make_test_script = 1;
667     }
668     elsif ($arg eq '-makelist') {
669         $make_list = 1;
670     }
671     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
672         -d $use_directory or croak "Unknown directory '$use_directory'";
673     }
674     elsif ($arg eq '-L') {
675
676         # Existence not tested until have chdir'd
677         $file_list = shift;
678     }
679     elsif ($arg eq '-globlist') {
680         $glob_list = 1;
681     }
682     elsif ($arg eq '-c') {
683         $output_range_counts = ! $output_range_counts
684     }
685     elsif ($arg eq '-output_names') {
686         $output_names = 1;
687     }
688     else {
689         my $with_c = 'with';
690         $with_c .= 'out' if $output_range_counts;   # Complements the state
691         croak <<END;
692 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
693           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
694           [-check A B ]
695   -c          : Output comments $with_c number of code points in ranges
696   -q          : Quiet Mode: Only output serious warnings.
697   -p          : Set verbosity level to normal plus show progress.
698   -v          : Set Verbosity level high:  Show progress and non-serious
699                 warnings
700   -w          : Write files regardless
701   -C dir      : Change to this directory before proceeding. All relative paths
702                 except those specified by the -P and -T options will be done
703                 with respect to this directory.
704   -P dir      : Output $pod_file file to directory 'dir'.
705   -T path     : Create a test script as 'path'; overrides -maketest
706   -L filelist : Use alternate 'filelist' instead of standard one
707   -globlist   : Take as input all non-Test *.txt files in current and sub
708                 directories
709   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
710                 overrides -T
711   -makelist   : Rewrite the file list $file_list based on current setup
712   -output_names : Output each character's name in the table files; useful for
713                 doing what-ifs, looking at diffs; is slow, memory intensive,
714                 resulting tables are usable but very large.
715   -check A B  : Executes $0 only if A and B are the same
716 END
717     }
718 }
719
720 # Stores the most-recently changed file.  If none have changed, can skip the
721 # build
722 my $most_recent = (stat $0)[9];   # Do this before the chdir!
723
724 # Change directories now, because need to read 'version' early.
725 if ($use_directory) {
726     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
727         $pod_directory = File::Spec->rel2abs($pod_directory);
728     }
729     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
730         $t_path = File::Spec->rel2abs($t_path);
731     }
732     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
733     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
734         $pod_directory = File::Spec->abs2rel($pod_directory);
735     }
736     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
737         $t_path = File::Spec->abs2rel($t_path);
738     }
739 }
740
741 # Get Unicode version into regular and v-string.  This is done now because
742 # various tables below get populated based on it.  These tables are populated
743 # here to be near the top of the file, and so easily seeable by those needing
744 # to modify things.
745 open my $VERSION, "<", "version"
746                     or croak "$0: can't open required file 'version': $!\n";
747 my $string_version = <$VERSION>;
748 close $VERSION;
749 chomp $string_version;
750 my $v_version = pack "C*", split /\./, $string_version;        # v string
751
752 # The following are the complete names of properties with property values that
753 # are known to not match any code points in some versions of Unicode, but that
754 # may change in the future so they should be matchable, hence an empty file is
755 # generated for them.
756 my @tables_that_may_be_empty = (
757                                 'Joining_Type=Left_Joining',
758                                 );
759 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
760 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
761 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
762                                                     if $v_version ge v4.1.0;
763
764 # The lists below are hashes, so the key is the item in the list, and the
765 # value is the reason why it is in the list.  This makes generation of
766 # documentation easier.
767
768 my %why_suppressed;  # No file generated for these.
769
770 # Files aren't generated for empty extraneous properties.  This is arguable.
771 # Extraneous properties generally come about because a property is no longer
772 # used in a newer version of Unicode.  If we generated a file without code
773 # points, programs that used to work on that property will still execute
774 # without errors.  It just won't ever match (or will always match, with \P{}).
775 # This means that the logic is now likely wrong.  I (khw) think its better to
776 # find this out by getting an error message.  Just move them to the table
777 # above to change this behavior
778 my %why_suppress_if_empty_warn_if_not = (
779
780    # It is the only property that has ever officially been removed from the
781    # Standard.  The database never contained any code points for it.
782    'Special_Case_Condition' => 'Obsolete',
783
784    # Apparently never official, but there were code points in some versions of
785    # old-style PropList.txt
786    'Non_Break' => 'Obsolete',
787 );
788
789 # These would normally go in the warn table just above, but they were changed
790 # a long time before this program was written, so warnings about them are
791 # moot.
792 if ($v_version gt v3.2.0) {
793     push @tables_that_may_be_empty,
794                                 'Canonical_Combining_Class=Attached_Below_Left'
795 }
796
797 # These are listed in the Property aliases file in 5.2, but Unihan is ignored
798 # unless explicitly added.
799 if ($v_version ge v5.2.0) {
800     my $unihan = 'Unihan; remove from list if using Unihan';
801     foreach my $table (qw (
802                            kAccountingNumeric
803                            kOtherNumeric
804                            kPrimaryNumeric
805                            kCompatibilityVariant
806                            kIICore
807                            kIRG_GSource
808                            kIRG_HSource
809                            kIRG_JSource
810                            kIRG_KPSource
811                            kIRG_MSource
812                            kIRG_KSource
813                            kIRG_TSource
814                            kIRG_USource
815                            kIRG_VSource
816                            kRSUnicode
817                         ))
818     {
819         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
820     }
821 }
822
823 # Properties that this program ignores.
824 my @unimplemented_properties = (
825 'Unicode_Radical_Stroke'    # Remove if changing to handle this one.
826 );
827
828 # There are several types of obsolete properties defined by Unicode.  These
829 # must be hand-edited for every new Unicode release.
830 my %why_deprecated;  # Generates a deprecated warning message if used.
831 my %why_stabilized;  # Documentation only
832 my %why_obsolete;    # Documentation only
833
834 {   # Closure
835     my $simple = 'Perl uses the more complete version of this property';
836     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
837
838     my $other_properties = 'other properties';
839     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
840     my $why_no_expand  = "Easily computed, and yet doesn't cover the common encoding forms (UTF-16/8)",
841
842     %why_deprecated = (
843         'Grapheme_Link' => 'Deprecated by Unicode.  Use ccc=vr (Canonical_Combining_Class=Virama) instead',
844         'Jamo_Short_Name' => $contributory,
845         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
846         'Other_Alphabetic' => $contributory,
847         'Other_Default_Ignorable_Code_Point' => $contributory,
848         'Other_Grapheme_Extend' => $contributory,
849         'Other_ID_Continue' => $contributory,
850         'Other_ID_Start' => $contributory,
851         'Other_Lowercase' => $contributory,
852         'Other_Math' => $contributory,
853         'Other_Uppercase' => $contributory,
854     );
855
856     %why_suppressed = (
857         # There is a lib/unicore/Decomposition.pl (used by normalize.pm) which
858         # contains the same information, but without the algorithmically
859         # determinable Hangul syllables'.  This file is not published, so it's
860         # existence is not noted in the comment.
861         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize',
862
863         'ISO_Comment' => 'Apparently no demand for it, but can access it through Unicode::UCD::charinfo.  Obsoleted, and code points for it removed in Unicode 5.2',
864         'Unicode_1_Name' => "$simple, and no apparent demand for it, but can access it through Unicode::UCD::charinfo.  If there is no later name for a code point, then this one is used instead in charnames",
865
866         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold",
867         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
868         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
869         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
870
871         'Name' => "Accessible via 'use charnames;'",
872         'Name_Alias' => "Accessible via 'use charnames;'",
873
874         # These are sort of jumping the gun; deprecation is proposed for
875         # Unicode version 6.0, but they have never been exposed by Perl, and
876         # likely are soon to be deprecated, so best not to expose them.
877         FC_NFKC_Closure => 'Use NFKC_Casefold instead',
878         Expands_On_NFC => $why_no_expand,
879         Expands_On_NFD => $why_no_expand,
880         Expands_On_NFKC => $why_no_expand,
881         Expands_On_NFKD => $why_no_expand,
882     );
883
884     # The following are suppressed because they were made contributory or
885     # deprecated by Unicode before Perl ever thought about supporting them.
886     foreach my $property ('Jamo_Short_Name', 'Grapheme_Link') {
887         $why_suppressed{$property} = $why_deprecated{$property};
888     }
889
890     # Customize the message for all the 'Other_' properties
891     foreach my $property (keys %why_deprecated) {
892         next if (my $main_property = $property) !~ s/^Other_//;
893         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
894     }
895 }
896
897 if ($v_version ge 4.0.0) {
898     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
899 }
900 if ($v_version ge 5.2.0) {
901     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
902 }
903
904 # Probably obsolete forever
905 if ($v_version ge v4.1.0) {
906     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common"';
907 }
908
909 # This program can create files for enumerated-like properties, such as
910 # 'Numeric_Type'.  This file would be the same format as for a string
911 # property, with a mapping from code point to its value, so you could look up,
912 # for example, the script a code point is in.  But no one so far wants this
913 # mapping, or they have found another way to get it since this is a new
914 # feature.  So no file is generated except if it is in this list.
915 my @output_mapped_properties = split "\n", <<END;
916 END
917
918 # If you are using the Unihan database, you need to add the properties that
919 # you want to extract from it to this table.  For your convenience, the
920 # properties in the 5.2 PropertyAliases.txt file are listed, commented out
921 my @cjk_properties = split "\n", <<'END';
922 #cjkAccountingNumeric; kAccountingNumeric
923 #cjkOtherNumeric; kOtherNumeric
924 #cjkPrimaryNumeric; kPrimaryNumeric
925 #cjkCompatibilityVariant; kCompatibilityVariant
926 #cjkIICore ; kIICore
927 #cjkIRG_GSource; kIRG_GSource
928 #cjkIRG_HSource; kIRG_HSource
929 #cjkIRG_JSource; kIRG_JSource
930 #cjkIRG_KPSource; kIRG_KPSource
931 #cjkIRG_KSource; kIRG_KSource
932 #cjkIRG_TSource; kIRG_TSource
933 #cjkIRG_USource; kIRG_USource
934 #cjkIRG_VSource; kIRG_VSource
935 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
936 END
937
938 # Similarly for the property values.  For your convenience, the lines in the
939 # 5.2 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
940 # '#' marks
941 my @cjk_property_values = split "\n", <<'END';
942 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
943 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
944 ## @missing: 0000..10FFFF; cjkIICore; <none>
945 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
946 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
947 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
948 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
949 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
950 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
951 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
952 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
953 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
954 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
955 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
956 END
957
958 # The input files don't list every code point.  Those not listed are to be
959 # defaulted to some value.  Below are hard-coded what those values are for
960 # non-binary properties as of 5.1.  Starting in 5.0, there are
961 # machine-parsable comment lines in the files the give the defaults; so this
962 # list shouldn't have to be extended.  The claim is that all missing entries
963 # for binary properties will default to 'N'.  Unicode tried to change that in
964 # 5.2, but the beta period produced enough protest that they backed off.
965 #
966 # The defaults for the fields that appear in UnicodeData.txt in this hash must
967 # be in the form that it expects.  The others may be synonyms.
968 my $CODE_POINT = '<code point>';
969 my %default_mapping = (
970     Age => "Unassigned",
971     # Bidi_Class => Complicated; set in code
972     Bidi_Mirroring_Glyph => "",
973     Block => 'No_Block',
974     Canonical_Combining_Class => 0,
975     Case_Folding => $CODE_POINT,
976     Decomposition_Mapping => $CODE_POINT,
977     Decomposition_Type => 'None',
978     East_Asian_Width => "Neutral",
979     FC_NFKC_Closure => $CODE_POINT,
980     General_Category => 'Cn',
981     Grapheme_Cluster_Break => 'Other',
982     Hangul_Syllable_Type => 'NA',
983     ISO_Comment => "",
984     Jamo_Short_Name => "",
985     Joining_Group => "No_Joining_Group",
986     # Joining_Type => Complicated; set in code
987     kIICore => 'N',   #                       Is converted to binary
988     #Line_Break => Complicated; set in code
989     Lowercase_Mapping => $CODE_POINT,
990     Name => "",
991     Name_Alias => "",
992     NFC_QC => 'Yes',
993     NFD_QC => 'Yes',
994     NFKC_QC => 'Yes',
995     NFKD_QC => 'Yes',
996     Numeric_Type => 'None',
997     Numeric_Value => 'NaN',
998     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
999     Sentence_Break => 'Other',
1000     Simple_Case_Folding => $CODE_POINT,
1001     Simple_Lowercase_Mapping => $CODE_POINT,
1002     Simple_Titlecase_Mapping => $CODE_POINT,
1003     Simple_Uppercase_Mapping => $CODE_POINT,
1004     Titlecase_Mapping => $CODE_POINT,
1005     Unicode_1_Name => "",
1006     Unicode_Radical_Stroke => "",
1007     Uppercase_Mapping => $CODE_POINT,
1008     Word_Break => 'Other',
1009 );
1010
1011 # Below are files that Unicode furnishes, but this program ignores, and why
1012 my %ignored_files = (
1013     'CJKRadicals.txt' => 'Unihan data',
1014     'Index.txt' => 'An index, not actual data',
1015     'NamedSqProv.txt' => 'Not officially part of the Unicode standard; Append it to NamedSequences.txt if you want to process the contents.',
1016     'NamesList.txt' => 'Just adds commentary',
1017     'NormalizationCorrections.txt' => 'Data is already in other files.',
1018     'Props.txt' => 'Adds nothing to PropList.txt; only in very early releases',
1019     'ReadMe.txt' => 'Just comments',
1020     'README.TXT' => 'Just comments',
1021     'StandardizedVariants.txt' => 'Only for glyph changes, not a Unicode character property.  Does not fit into current scheme where one code point is mapped',
1022 );
1023
1024 ### End of externally interesting definitions, except for @input_file_objects
1025
1026 my $HEADER=<<"EOF";
1027 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1028 # This file is machine-generated by $0 from the Unicode
1029 # database, Version $string_version.  Any changes made here will be lost!
1030 EOF
1031
1032 my $INTERNAL_ONLY=<<"EOF";
1033
1034 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1035 # This file is for internal use by the Perl program only.  The format and even
1036 # the name or existence of this file are subject to change without notice.
1037 # Don't use it directly.
1038 EOF
1039
1040 my $DEVELOPMENT_ONLY=<<"EOF";
1041 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1042 # This file contains information artificially constrained to code points
1043 # present in Unicode release $string_compare_versions.
1044 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1045 # not be used for production.
1046
1047 EOF
1048
1049 my $LAST_UNICODE_CODEPOINT_STRING = "10FFFF";
1050 my $LAST_UNICODE_CODEPOINT = hex $LAST_UNICODE_CODEPOINT_STRING;
1051 my $MAX_UNICODE_CODEPOINTS = $LAST_UNICODE_CODEPOINT + 1;
1052
1053 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1054 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1055 # to decrease backtracking
1056 my $code_point_re =
1057         qr/ \b (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1058
1059 # This matches the beginning of the line in the Unicode db files that give the
1060 # defaults for code points not listed (i.e., missing) in the file.  The code
1061 # depends on this ending with a semi-colon, so it can assume it is a valid
1062 # field when the line is split() by semi-colons
1063 my $missing_defaults_prefix =
1064             qr/^#\s+\@missing:\s+0000\.\.$LAST_UNICODE_CODEPOINT_STRING\s*;/;
1065
1066 # Property types.  Unicode has more types, but these are sufficient for our
1067 # purposes.
1068 my $UNKNOWN = -1;   # initialized to illegal value
1069 my $NON_STRING = 1; # Either binary or enum
1070 my $BINARY = 2;
1071 my $ENUM = 3;       # Include catalog
1072 my $STRING = 4;     # Anything else: string or misc
1073
1074 # Some input files have lines that give default values for code points not
1075 # contained in the file.  Sometimes these should be ignored.
1076 my $NO_DEFAULTS = 0;        # Must evaluate to false
1077 my $NOT_IGNORED = 1;
1078 my $IGNORED = 2;
1079
1080 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1081 # and will appear in the main body of the tables in the output files, but
1082 # there are other types of ranges as well, listed below, that are specially
1083 # handled.   There are pseudo-types as well that will never be stored as a
1084 # type, but will affect the calculation of the type.
1085
1086 # 0 is for normal, non-specials
1087 my $MULTI_CP = 1;           # Sequence of more than code point
1088 my $HANGUL_SYLLABLE = 2;
1089 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1090 my $NULL = 4;               # The map is to the null string; utf8.c can't
1091                             # handle these, nor is there an accepted syntax
1092                             # for them in \p{} constructs
1093 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1094                              # otherwise be $MULTI_CP type are instead type 0
1095
1096 # process_generic_property_file() can accept certain overrides in its input.
1097 # Each of these must begin AND end with $CMD_DELIM.
1098 my $CMD_DELIM = "\a";
1099 my $REPLACE_CMD = 'replace';    # Override the Replace
1100 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1101
1102 my $NO = 0;
1103 my $YES = 1;
1104
1105 # Values for the Replace argument to add_range.
1106 # $NO                      # Don't replace; add only the code points not
1107                            # already present.
1108 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1109                            # the comments at the subroutine definition.
1110 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1111 my $MULTIPLE = 4;          # Don't replace, but add a duplicate record if
1112                            # already there
1113
1114 # Flags to give property statuses.  The phrases are to remind maintainers that
1115 # if the flag is changed, the indefinite article referring to it in the
1116 # documentation may need to be as well.
1117 my $NORMAL = "";
1118 my $SUPPRESSED = 'z';   # The character should never actually be seen, since
1119                         # it is suppressed
1120 my $PLACEHOLDER = 'P';  # Implies no pod entry generated
1121 my $DEPRECATED = 'D';
1122 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1123 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1124 my $DISCOURAGED = 'X';
1125 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1126 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1127 my $STRICTER = 'T';
1128 my $a_bold_stricter = "a 'B<$STRICTER>'";
1129 my $A_bold_stricter = "A 'B<$STRICTER>'";
1130 my $STABILIZED = 'S';
1131 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1132 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1133 my $OBSOLETE = 'O';
1134 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1135 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1136
1137 my %status_past_participles = (
1138     $DISCOURAGED => 'discouraged',
1139     $SUPPRESSED => 'should never be generated',
1140     $STABILIZED => 'stabilized',
1141     $OBSOLETE => 'obsolete',
1142     $DEPRECATED => 'deprecated',
1143 );
1144
1145 # The format of the values of the map tables:
1146 my $BINARY_FORMAT = 'b';
1147 my $DECIMAL_FORMAT = 'd';
1148 my $FLOAT_FORMAT = 'f';
1149 my $INTEGER_FORMAT = 'i';
1150 my $HEX_FORMAT = 'x';
1151 my $RATIONAL_FORMAT = 'r';
1152 my $STRING_FORMAT = 's';
1153 my $DECOMP_STRING_FORMAT = 'c';
1154
1155 my %map_table_formats = (
1156     $BINARY_FORMAT => 'binary',
1157     $DECIMAL_FORMAT => 'single decimal digit',
1158     $FLOAT_FORMAT => 'floating point number',
1159     $INTEGER_FORMAT => 'integer',
1160     $HEX_FORMAT => 'positive hex whole number; a code point',
1161     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1162     $STRING_FORMAT => 'string',
1163     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decompostion mapping',
1164 );
1165
1166 # Unicode didn't put such derived files in a separate directory at first.
1167 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1168 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1169 my $AUXILIARY = 'auxiliary';
1170
1171 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1172 my %loose_to_file_of;       # loosely maps table names to their respective
1173                             # files
1174 my %stricter_to_file_of;    # same; but for stricter mapping.
1175 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1176                              # their rational equivalent
1177 my %loose_property_name_of; # Loosely maps property names to standard form
1178
1179 # These constants names and values were taken from the Unicode standard,
1180 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1181 # syllables.  The '_string' versions are so generated tables can retain the
1182 # hex format, which is the more familiar value
1183 my $SBase_string = "0xAC00";
1184 my $SBase = CORE::hex $SBase_string;
1185 my $LBase_string = "0x1100";
1186 my $LBase = CORE::hex $LBase_string;
1187 my $VBase_string = "0x1161";
1188 my $VBase = CORE::hex $VBase_string;
1189 my $TBase_string = "0x11A7";
1190 my $TBase = CORE::hex $TBase_string;
1191 my $SCount = 11172;
1192 my $LCount = 19;
1193 my $VCount = 21;
1194 my $TCount = 28;
1195 my $NCount = $VCount * $TCount;
1196
1197 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1198 # with the above published constants.
1199 my %Jamo;
1200 my %Jamo_L;     # Leading consonants
1201 my %Jamo_V;     # Vowels
1202 my %Jamo_T;     # Trailing consonants
1203
1204 my @backslash_X_tests;     # List of tests read in for testing \X
1205 my @unhandled_properties;  # Will contain a list of properties found in
1206                            # the input that we didn't process.
1207 my @match_properties;      # Properties that have match tables, to be
1208                            # listed in the pod
1209 my @map_properties;        # Properties that get map files written
1210 my @named_sequences;       # NamedSequences.txt contents.
1211 my %potential_files;       # Generated list of all .txt files in the directory
1212                            # structure so we can warn if something is being
1213                            # ignored.
1214 my @files_actually_output; # List of files we generated.
1215 my @more_Names;            # Some code point names are compound; this is used
1216                            # to store the extra components of them.
1217 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1218                            # the minimum before we consider it equivalent to a
1219                            # candidate rational
1220 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1221
1222 # These store references to certain commonly used property objects
1223 my $gc;
1224 my $perl;
1225 my $block;
1226 my $perl_charname;
1227 my $print;
1228
1229 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1230 my $has_In_conflicts = 0;
1231 my $has_Is_conflicts = 0;
1232
1233 sub internal_file_to_platform ($) {
1234     # Convert our file paths which have '/' separators to those of the
1235     # platform.
1236
1237     my $file = shift;
1238     return undef unless defined $file;
1239
1240     return File::Spec->join(split '/', $file);
1241 }
1242
1243 sub file_exists ($) {   # platform independent '-e'.  This program internally
1244                         # uses slash as a path separator.
1245     my $file = shift;
1246     return 0 if ! defined $file;
1247     return -e internal_file_to_platform($file);
1248 }
1249
1250 sub objaddr($) {
1251     # Returns the address of the blessed input object.
1252     # It doesn't check for blessedness because that would do a string eval
1253     # every call, and the program is structured so that this is never called
1254     # for a non-blessed object.
1255
1256     no overloading; # If overloaded, numifying below won't work.
1257
1258     # Numifying a ref gives its address.
1259     return pack 'J', $_[0];
1260 }
1261
1262 # Commented code below should work on Perl 5.8.
1263 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1264 ## the native perl version of it (which is what would operate under miniperl)
1265 ## is extremely slow, as it does a string eval every call.
1266 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1267 #                            && defined eval "require Scalar::Util";
1268 #
1269 #sub objaddr($) {
1270 #    # Returns the address of the blessed input object.  Uses the XS version if
1271 #    # available.  It doesn't check for blessedness because that would do a
1272 #    # string eval every call, and the program is structured so that this is
1273 #    # never called for a non-blessed object.
1274 #
1275 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1276 #
1277 #    # Check at least that is a ref.
1278 #    my $pkg = ref($_[0]) or return undef;
1279 #
1280 #    # Change to a fake package to defeat any overloaded stringify
1281 #    bless $_[0], 'main::Fake';
1282 #
1283 #    # Numifying a ref gives its address.
1284 #    my $addr = pack 'J', $_[0];
1285 #
1286 #    # Return to original class
1287 #    bless $_[0], $pkg;
1288 #    return $addr;
1289 #}
1290
1291 sub max ($$) {
1292     my $a = shift;
1293     my $b = shift;
1294     return $a if $a >= $b;
1295     return $b;
1296 }
1297
1298 sub min ($$) {
1299     my $a = shift;
1300     my $b = shift;
1301     return $a if $a <= $b;
1302     return $b;
1303 }
1304
1305 sub clarify_number ($) {
1306     # This returns the input number with underscores inserted every 3 digits
1307     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1308     # checked.
1309
1310     my $number = shift;
1311     my $pos = length($number) - 3;
1312     return $number if $pos <= 1;
1313     while ($pos > 0) {
1314         substr($number, $pos, 0) = '_';
1315         $pos -= 3;
1316     }
1317     return $number;
1318 }
1319
1320
1321 package Carp;
1322
1323 # These routines give a uniform treatment of messages in this program.  They
1324 # are placed in the Carp package to cause the stack trace to not include them,
1325 # although an alternative would be to use another package and set @CARP_NOT
1326 # for it.
1327
1328 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1329
1330 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1331 # and overload trying to load Scalar:Util under miniperl.  See
1332 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1333 undef $overload::VERSION;
1334
1335 sub my_carp {
1336     my $message = shift || "";
1337     my $nofold = shift || 0;
1338
1339     if ($message) {
1340         $message = main::join_lines($message);
1341         $message =~ s/^$0: *//;     # Remove initial program name
1342         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1343         $message = "\n$0: $message;";
1344
1345         # Fold the message with program name, semi-colon end punctuation
1346         # (which looks good with the message that carp appends to it), and a
1347         # hanging indent for continuation lines.
1348         $message = main::simple_fold($message, "", 4) unless $nofold;
1349         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1350                                     # appends is to the same line
1351     }
1352
1353     return $message if defined wantarray;   # If a caller just wants the msg
1354
1355     carp $message;
1356     return;
1357 }
1358
1359 sub my_carp_bug {
1360     # This is called when it is clear that the problem is caused by a bug in
1361     # this program.
1362
1363     my $message = shift;
1364     $message =~ s/^$0: *//;
1365     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1366     carp $message;
1367     return;
1368 }
1369
1370 sub carp_too_few_args {
1371     if (@_ != 2) {
1372         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1373         return;
1374     }
1375
1376     my $args_ref = shift;
1377     my $count = shift;
1378
1379     my_carp_bug("Need at least $count arguments to "
1380         . (caller 1)[3]
1381         . ".  Instead got: '"
1382         . join ', ', @$args_ref
1383         . "'.  No action taken.");
1384     return;
1385 }
1386
1387 sub carp_extra_args {
1388     my $args_ref = shift;
1389     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1390
1391     unless (ref $args_ref) {
1392         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1393         return;
1394     }
1395     my ($package, $file, $line) = caller;
1396     my $subroutine = (caller 1)[3];
1397
1398     my $list;
1399     if (ref $args_ref eq 'HASH') {
1400         foreach my $key (keys %$args_ref) {
1401             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1402         }
1403         $list = join ', ', each %{$args_ref};
1404     }
1405     elsif (ref $args_ref eq 'ARRAY') {
1406         foreach my $arg (@$args_ref) {
1407             $arg = $UNDEF unless defined $arg;
1408         }
1409         $list = join ', ', @$args_ref;
1410     }
1411     else {
1412         my_carp_bug("Can't cope with ref "
1413                 . ref($args_ref)
1414                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1415         return;
1416     }
1417
1418     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1419     return;
1420 }
1421
1422 package main;
1423
1424 { # Closure
1425
1426     # This program uses the inside-out method for objects, as recommended in
1427     # "Perl Best Practices".  This closure aids in generating those.  There
1428     # are two routines.  setup_package() is called once per package to set
1429     # things up, and then set_access() is called for each hash representing a
1430     # field in the object.  These routines arrange for the object to be
1431     # properly destroyed when no longer used, and for standard accessor
1432     # functions to be generated.  If you need more complex accessors, just
1433     # write your own and leave those accesses out of the call to set_access().
1434     # More details below.
1435
1436     my %constructor_fields; # fields that are to be used in constructors; see
1437                             # below
1438
1439     # The values of this hash will be the package names as keys to other
1440     # hashes containing the name of each field in the package as keys, and
1441     # references to their respective hashes as values.
1442     my %package_fields;
1443
1444     sub setup_package {
1445         # Sets up the package, creating standard DESTROY and dump methods
1446         # (unless already defined).  The dump method is used in debugging by
1447         # simple_dumper().
1448         # The optional parameters are:
1449         #   a)  a reference to a hash, that gets populated by later
1450         #       set_access() calls with one of the accesses being
1451         #       'constructor'.  The caller can then refer to this, but it is
1452         #       not otherwise used by these two routines.
1453         #   b)  a reference to a callback routine to call during destruction
1454         #       of the object, before any fields are actually destroyed
1455
1456         my %args = @_;
1457         my $constructor_ref = delete $args{'Constructor_Fields'};
1458         my $destroy_callback = delete $args{'Destroy_Callback'};
1459         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1460
1461         my %fields;
1462         my $package = (caller)[0];
1463
1464         $package_fields{$package} = \%fields;
1465         $constructor_fields{$package} = $constructor_ref;
1466
1467         unless ($package->can('DESTROY')) {
1468             my $destroy_name = "${package}::DESTROY";
1469             no strict "refs";
1470
1471             # Use typeglob to give the anonymous subroutine the name we want
1472             *$destroy_name = sub {
1473                 my $self = shift;
1474                 my $addr = do { no overloading; pack 'J', $self; };
1475
1476                 $self->$destroy_callback if $destroy_callback;
1477                 foreach my $field (keys %{$package_fields{$package}}) {
1478                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1479                     delete $package_fields{$package}{$field}{$addr};
1480                 }
1481                 return;
1482             }
1483         }
1484
1485         unless ($package->can('dump')) {
1486             my $dump_name = "${package}::dump";
1487             no strict "refs";
1488             *$dump_name = sub {
1489                 my $self = shift;
1490                 return dump_inside_out($self, $package_fields{$package}, @_);
1491             }
1492         }
1493         return;
1494     }
1495
1496     sub set_access {
1497         # Arrange for the input field to be garbage collected when no longer
1498         # needed.  Also, creates standard accessor functions for the field
1499         # based on the optional parameters-- none if none of these parameters:
1500         #   'addable'    creates an 'add_NAME()' accessor function.
1501         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1502         #                function.
1503         #   'settable'   creates a 'set_NAME()' accessor function.
1504         #   'constructor' doesn't create an accessor function, but adds the
1505         #                field to the hash that was previously passed to
1506         #                setup_package();
1507         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1508         # 'add' etc. all mean 'addable'.
1509         # The read accessor function will work on both array and scalar
1510         # values.  If another accessor in the parameter list is 'a', the read
1511         # access assumes an array.  You can also force it to be array access
1512         # by specifying 'readable_array' instead of 'readable'
1513         #
1514         # A sort-of 'protected' access can be set-up by preceding the addable,
1515         # readable or settable with some initial portion of 'protected_' (but,
1516         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1517         # "protection" is only by convention.  All that happens is that the
1518         # accessor functions' names begin with an underscore.  So instead of
1519         # calling set_foo, the call is _set_foo.  (Real protection could be
1520         # accomplished by having a new subroutine, end_package, called at the
1521         # end of each package, and then storing the __LINE__ ranges and
1522         # checking them on every accessor.  But that is way overkill.)
1523
1524         # We create anonymous subroutines as the accessors and then use
1525         # typeglobs to assign them to the proper package and name
1526
1527         my $name = shift;   # Name of the field
1528         my $field = shift;  # Reference to the inside-out hash containing the
1529                             # field
1530
1531         my $package = (caller)[0];
1532
1533         if (! exists $package_fields{$package}) {
1534             croak "$0: Must call 'setup_package' before 'set_access'";
1535         }
1536
1537         # Stash the field so DESTROY can get it.
1538         $package_fields{$package}{$name} = $field;
1539
1540         # Remaining arguments are the accessors.  For each...
1541         foreach my $access (@_) {
1542             my $access = lc $access;
1543
1544             my $protected = "";
1545
1546             # Match the input as far as it goes.
1547             if ($access =~ /^(p[^_]*)_/) {
1548                 $protected = $1;
1549                 if (substr('protected_', 0, length $protected)
1550                     eq $protected)
1551                 {
1552
1553                     # Add 1 for the underscore not included in $protected
1554                     $access = substr($access, length($protected) + 1);
1555                     $protected = '_';
1556                 }
1557                 else {
1558                     $protected = "";
1559                 }
1560             }
1561
1562             if (substr('addable', 0, length $access) eq $access) {
1563                 my $subname = "${package}::${protected}add_$name";
1564                 no strict "refs";
1565
1566                 # add_ accessor.  Don't add if already there, which we
1567                 # determine using 'eq' for scalars and '==' otherwise.
1568                 *$subname = sub {
1569                     use strict "refs";
1570                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1571                     my $self = shift;
1572                     my $value = shift;
1573                     my $addr = do { no overloading; pack 'J', $self; };
1574                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1575                     if (ref $value) {
1576                         return if grep { $value == $_ } @{$field->{$addr}};
1577                     }
1578                     else {
1579                         return if grep { $value eq $_ } @{$field->{$addr}};
1580                     }
1581                     push @{$field->{$addr}}, $value;
1582                     return;
1583                 }
1584             }
1585             elsif (substr('constructor', 0, length $access) eq $access) {
1586                 if ($protected) {
1587                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1588                 }
1589                 else {
1590                     $constructor_fields{$package}{$name} = $field;
1591                 }
1592             }
1593             elsif (substr('readable_array', 0, length $access) eq $access) {
1594
1595                 # Here has read access.  If one of the other parameters for
1596                 # access is array, or this one specifies array (by being more
1597                 # than just 'readable_'), then create a subroutine that
1598                 # assumes the data is an array.  Otherwise just a scalar
1599                 my $subname = "${package}::${protected}$name";
1600                 if (grep { /^a/i } @_
1601                     or length($access) > length('readable_'))
1602                 {
1603                     no strict "refs";
1604                     *$subname = sub {
1605                         use strict "refs";
1606                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1607                         my $addr = do { no overloading; pack 'J', $_[0]; };
1608                         if (ref $field->{$addr} ne 'ARRAY') {
1609                             my $type = ref $field->{$addr};
1610                             $type = 'scalar' unless $type;
1611                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1612                             return;
1613                         }
1614                         return scalar @{$field->{$addr}} unless wantarray;
1615
1616                         # Make a copy; had problems with caller modifying the
1617                         # original otherwise
1618                         my @return = @{$field->{$addr}};
1619                         return @return;
1620                     }
1621                 }
1622                 else {
1623
1624                     # Here not an array value, a simpler function.
1625                     no strict "refs";
1626                     *$subname = sub {
1627                         use strict "refs";
1628                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1629                         no overloading;
1630                         return $field->{pack 'J', $_[0]};
1631                     }
1632                 }
1633             }
1634             elsif (substr('settable', 0, length $access) eq $access) {
1635                 my $subname = "${package}::${protected}set_$name";
1636                 no strict "refs";
1637                 *$subname = sub {
1638                     use strict "refs";
1639                     if (main::DEBUG) {
1640                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1641                         Carp::carp_extra_args(\@_) if @_ > 2;
1642                     }
1643                     # $self is $_[0]; $value is $_[1]
1644                     no overloading;
1645                     $field->{pack 'J', $_[0]} = $_[1];
1646                     return;
1647                 }
1648             }
1649             else {
1650                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1651             }
1652         }
1653         return;
1654     }
1655 }
1656
1657 package Input_file;
1658
1659 # All input files use this object, which stores various attributes about them,
1660 # and provides for convenient, uniform handling.  The run method wraps the
1661 # processing.  It handles all the bookkeeping of opening, reading, and closing
1662 # the file, returning only significant input lines.
1663 #
1664 # Each object gets a handler which processes the body of the file, and is
1665 # called by run().  Most should use the generic, default handler, which has
1666 # code scrubbed to handle things you might not expect.  A handler should
1667 # basically be a while(next_line()) {...} loop.
1668 #
1669 # You can also set up handlers to
1670 #   1) call before the first line is read for pre processing
1671 #   2) call to adjust each line of the input before the main handler gets them
1672 #   3) call upon EOF before the main handler exits its loop
1673 #   4) call at the end for post processing
1674 #
1675 # $_ is used to store the input line, and is to be filtered by the
1676 # each_line_handler()s.  So, if the format of the line is not in the desired
1677 # format for the main handler, these are used to do that adjusting.  They can
1678 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1679 # so the $_ output of one is used as the input to the next.  None of the other
1680 # handlers are stackable, but could easily be changed to be so.
1681 #
1682 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1683 # which insert the parameters as lines to be processed before the next input
1684 # file line is read.  This allows the EOF handler to flush buffers, for
1685 # example.  The difference between the two routines is that the lines inserted
1686 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1687 # called it from such a handler, you would get infinite recursion.)  Lines
1688 # inserted by insert_adjusted_lines() go directly to the main handler without
1689 # any adjustments.  If the  post-processing handler calls any of these, there
1690 # will be no effect.  Some error checking for these conditions could be added,
1691 # but it hasn't been done.
1692 #
1693 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1694 # to prevent further processing of the line.  This routine will output the
1695 # message as a warning once, and then keep a count of the lines that have the
1696 # same message, and output that count at the end of the file's processing.
1697 # This keeps the number of messages down to a manageable amount.
1698 #
1699 # get_missings() should be called to retrieve any @missing input lines.
1700 # Messages will be raised if this isn't done if the options aren't to ignore
1701 # missings.
1702
1703 sub trace { return main::trace(@_); }
1704
1705 { # Closure
1706     # Keep track of fields that are to be put into the constructor.
1707     my %constructor_fields;
1708
1709     main::setup_package(Constructor_Fields => \%constructor_fields);
1710
1711     my %file; # Input file name, required
1712     main::set_access('file', \%file, qw{ c r });
1713
1714     my %first_released; # Unicode version file was first released in, required
1715     main::set_access('first_released', \%first_released, qw{ c r });
1716
1717     my %handler;    # Subroutine to process the input file, defaults to
1718                     # 'process_generic_property_file'
1719     main::set_access('handler', \%handler, qw{ c });
1720
1721     my %property;
1722     # name of property this file is for.  defaults to none, meaning not
1723     # applicable, or is otherwise determinable, for example, from each line.
1724     main::set_access('property', \%property, qw{ c });
1725
1726     my %optional;
1727     # If this is true, the file is optional.  If not present, no warning is
1728     # output.  If it is present, the string given by this parameter is
1729     # evaluated, and if false the file is not processed.
1730     main::set_access('optional', \%optional, 'c', 'r');
1731
1732     my %non_skip;
1733     # This is used for debugging, to skip processing of all but a few input
1734     # files.  Add 'non_skip => 1' to the constructor for those files you want
1735     # processed when you set the $debug_skip global.
1736     main::set_access('non_skip', \%non_skip, 'c');
1737
1738     my %skip;
1739     # This is used to skip processing of this input file semi-permanently.
1740     # It is used for files that we aren't planning to process anytime soon,
1741     # but want to allow to be in the directory and not raise a message that we
1742     # are not handling.  Mostly for test files.  This is in contrast to the
1743     # non_skip element, which is supposed to be used very temporarily for
1744     # debugging.  Sets 'optional' to 1
1745     main::set_access('skip', \%skip, 'c');
1746
1747     my %each_line_handler;
1748     # list of subroutines to look at and filter each non-comment line in the
1749     # file.  defaults to none.  The subroutines are called in order, each is
1750     # to adjust $_ for the next one, and the final one adjusts it for
1751     # 'handler'
1752     main::set_access('each_line_handler', \%each_line_handler, 'c');
1753
1754     my %has_missings_defaults;
1755     # ? Are there lines in the file giving default values for code points
1756     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
1757     # the norm, but IGNORED means it has such lines, but the handler doesn't
1758     # use them.  Having these three states allows us to catch changes to the
1759     # UCD that this program should track
1760     main::set_access('has_missings_defaults',
1761                                         \%has_missings_defaults, qw{ c r });
1762
1763     my %pre_handler;
1764     # Subroutine to call before doing anything else in the file.  If undef, no
1765     # such handler is called.
1766     main::set_access('pre_handler', \%pre_handler, qw{ c });
1767
1768     my %eof_handler;
1769     # Subroutine to call upon getting an EOF on the input file, but before
1770     # that is returned to the main handler.  This is to allow buffers to be
1771     # flushed.  The handler is expected to call insert_lines() or
1772     # insert_adjusted() with the buffered material
1773     main::set_access('eof_handler', \%eof_handler, qw{ c r });
1774
1775     my %post_handler;
1776     # Subroutine to call after all the lines of the file are read in and
1777     # processed.  If undef, no such handler is called.
1778     main::set_access('post_handler', \%post_handler, qw{ c });
1779
1780     my %progress_message;
1781     # Message to print to display progress in lieu of the standard one
1782     main::set_access('progress_message', \%progress_message, qw{ c });
1783
1784     my %handle;
1785     # cache open file handle, internal.  Is undef if file hasn't been
1786     # processed at all, empty if has;
1787     main::set_access('handle', \%handle);
1788
1789     my %added_lines;
1790     # cache of lines added virtually to the file, internal
1791     main::set_access('added_lines', \%added_lines);
1792
1793     my %errors;
1794     # cache of errors found, internal
1795     main::set_access('errors', \%errors);
1796
1797     my %missings;
1798     # storage of '@missing' defaults lines
1799     main::set_access('missings', \%missings);
1800
1801     sub new {
1802         my $class = shift;
1803
1804         my $self = bless \do{ my $anonymous_scalar }, $class;
1805         my $addr = do { no overloading; pack 'J', $self; };
1806
1807         # Set defaults
1808         $handler{$addr} = \&main::process_generic_property_file;
1809         $non_skip{$addr} = 0;
1810         $skip{$addr} = 0;
1811         $has_missings_defaults{$addr} = $NO_DEFAULTS;
1812         $handle{$addr} = undef;
1813         $added_lines{$addr} = [ ];
1814         $each_line_handler{$addr} = [ ];
1815         $errors{$addr} = { };
1816         $missings{$addr} = [ ];
1817
1818         # Two positional parameters.
1819         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1820         $file{$addr} = main::internal_file_to_platform(shift);
1821         $first_released{$addr} = shift;
1822
1823         # The rest of the arguments are key => value pairs
1824         # %constructor_fields has been set up earlier to list all possible
1825         # ones.  Either set or push, depending on how the default has been set
1826         # up just above.
1827         my %args = @_;
1828         foreach my $key (keys %args) {
1829             my $argument = $args{$key};
1830
1831             # Note that the fields are the lower case of the constructor keys
1832             my $hash = $constructor_fields{lc $key};
1833             if (! defined $hash) {
1834                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
1835                 next;
1836             }
1837             if (ref $hash->{$addr} eq 'ARRAY') {
1838                 if (ref $argument eq 'ARRAY') {
1839                     foreach my $argument (@{$argument}) {
1840                         next if ! defined $argument;
1841                         push @{$hash->{$addr}}, $argument;
1842                     }
1843                 }
1844                 else {
1845                     push @{$hash->{$addr}}, $argument if defined $argument;
1846                 }
1847             }
1848             else {
1849                 $hash->{$addr} = $argument;
1850             }
1851             delete $args{$key};
1852         };
1853
1854         # If the file has a property for it, it means that the property is not
1855         # listed in the file's entries.  So add a handler to the list of line
1856         # handlers to insert the property name into the lines, to provide a
1857         # uniform interface to the final processing subroutine.
1858         # the final code doesn't have to worry about that.
1859         if ($property{$addr}) {
1860             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
1861         }
1862
1863         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
1864             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
1865         }
1866
1867         $optional{$addr} = 1 if $skip{$addr};
1868
1869         return $self;
1870     }
1871
1872
1873     use overload
1874         fallback => 0,
1875         qw("") => "_operator_stringify",
1876         "." => \&main::_operator_dot,
1877     ;
1878
1879     sub _operator_stringify {
1880         my $self = shift;
1881
1882         return __PACKAGE__ . " object for " . $self->file;
1883     }
1884
1885     # flag to make sure extracted files are processed early
1886     my $seen_non_extracted_non_age = 0;
1887
1888     sub run {
1889         # Process the input object $self.  This opens and closes the file and
1890         # calls all the handlers for it.  Currently,  this can only be called
1891         # once per file, as it destroy's the EOF handler
1892
1893         my $self = shift;
1894         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1895
1896         my $addr = do { no overloading; pack 'J', $self; };
1897
1898         my $file = $file{$addr};
1899
1900         # Don't process if not expecting this file (because released later
1901         # than this Unicode version), and isn't there.  This means if someone
1902         # copies it into an earlier version's directory, we will go ahead and
1903         # process it.
1904         return if $first_released{$addr} gt $v_version && ! -e $file;
1905
1906         # If in debugging mode and this file doesn't have the non-skip
1907         # flag set, and isn't one of the critical files, skip it.
1908         if ($debug_skip
1909             && $first_released{$addr} ne v0
1910             && ! $non_skip{$addr})
1911         {
1912             print "Skipping $file in debugging\n" if $verbosity;
1913             return;
1914         }
1915
1916         # File could be optional
1917         if ($optional{$addr}) {
1918             return unless -e $file;
1919             my $result = eval $optional{$addr};
1920             if (! defined $result) {
1921                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
1922                 return;
1923             }
1924             if (! $result) {
1925                 if ($verbosity) {
1926                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
1927                 }
1928                 return;
1929             }
1930         }
1931
1932         if (! defined $file || ! -e $file) {
1933
1934             # If the file doesn't exist, see if have internal data for it
1935             # (based on first_released being 0).
1936             if ($first_released{$addr} eq v0) {
1937                 $handle{$addr} = 'pretend_is_open';
1938             }
1939             else {
1940                 if (! $optional{$addr}  # File could be optional
1941                     && $v_version ge $first_released{$addr})
1942                 {
1943                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
1944                 }
1945                 return;
1946             }
1947         }
1948         else {
1949
1950             # Here, the file exists.  Some platforms may change the case of
1951             # its name
1952             if ($seen_non_extracted_non_age) {
1953                 if ($file =~ /$EXTRACTED/i) {
1954                     Carp::my_carp_bug(join_lines(<<END
1955 $file should be processed just after the 'Prop...Alias' files, and before
1956 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
1957 have subtle problems
1958 END
1959                     ));
1960                 }
1961             }
1962             elsif ($EXTRACTED_DIR
1963                     && $first_released{$addr} ne v0
1964                     && $file !~ /$EXTRACTED/i
1965                     && lc($file) ne 'dage.txt')
1966             {
1967                 # We don't set this (by the 'if' above) if we have no
1968                 # extracted directory, so if running on an early version,
1969                 # this test won't work.  Not worth worrying about.
1970                 $seen_non_extracted_non_age = 1;
1971             }
1972
1973             # And mark the file as having being processed, and warn if it
1974             # isn't a file we are expecting.  As we process the files,
1975             # they are deleted from the hash, so any that remain at the
1976             # end of the program are files that we didn't process.
1977             my $fkey = File::Spec->rel2abs($file);
1978             my $expecting = delete $potential_files{$fkey};
1979             $expecting = delete $potential_files{lc($fkey)} unless defined $expecting;
1980             Carp::my_carp("Was not expecting '$file'.") if
1981                     ! $expecting
1982                     && ! defined $handle{$addr};
1983
1984             # Having deleted from expected files, we can quit if not to do
1985             # anything.  Don't print progress unless really want verbosity
1986             if ($skip{$addr}) {
1987                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
1988                 return;
1989             }
1990
1991             # Open the file, converting the slashes used in this program
1992             # into the proper form for the OS
1993             my $file_handle;
1994             if (not open $file_handle, "<", $file) {
1995                 Carp::my_carp("Can't open $file.  Skipping: $!");
1996                 return 0;
1997             }
1998             $handle{$addr} = $file_handle; # Cache the open file handle
1999         }
2000
2001         if ($verbosity >= $PROGRESS) {
2002             if ($progress_message{$addr}) {
2003                 print "$progress_message{$addr}\n";
2004             }
2005             else {
2006                 # If using a virtual file, say so.
2007                 print "Processing ", (-e $file)
2008                                        ? $file
2009                                        : "substitute $file",
2010                                      "\n";
2011             }
2012         }
2013
2014
2015         # Call any special handler for before the file.
2016         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2017
2018         # Then the main handler
2019         &{$handler{$addr}}($self);
2020
2021         # Then any special post-file handler.
2022         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2023
2024         # If any errors have been accumulated, output the counts (as the first
2025         # error message in each class was output when it was encountered).
2026         if ($errors{$addr}) {
2027             my $total = 0;
2028             my $types = 0;
2029             foreach my $error (keys %{$errors{$addr}}) {
2030                 $total += $errors{$addr}->{$error};
2031                 delete $errors{$addr}->{$error};
2032                 $types++;
2033             }
2034             if ($total > 1) {
2035                 my $message
2036                         = "A total of $total lines had errors in $file.  ";
2037
2038                 $message .= ($types == 1)
2039                             ? '(Only the first one was displayed.)'
2040                             : '(Only the first of each type was displayed.)';
2041                 Carp::my_carp($message);
2042             }
2043         }
2044
2045         if (@{$missings{$addr}}) {
2046             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2047         }
2048
2049         # If a real file handle, close it.
2050         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2051                                                         ref $handle{$addr};
2052         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2053                                # the file, as opposed to undef
2054         return;
2055     }
2056
2057     sub next_line {
2058         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2059         # if such a line exists.  'logical' means that any lines that have
2060         # been added via insert_lines() will be returned in $_ before the file
2061         # is read again.
2062
2063         my $self = shift;
2064         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2065
2066         my $addr = do { no overloading; pack 'J', $self; };
2067
2068         # Here the file is open (or if the handle is not a ref, is an open
2069         # 'virtual' file).  Get the next line; any inserted lines get priority
2070         # over the file itself.
2071         my $adjusted;
2072
2073         LINE:
2074         while (1) { # Loop until find non-comment, non-empty line
2075             #local $to_trace = 1 if main::DEBUG;
2076             my $inserted_ref = shift @{$added_lines{$addr}};
2077             if (defined $inserted_ref) {
2078                 ($adjusted, $_) = @{$inserted_ref};
2079                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2080                 return 1 if $adjusted;
2081             }
2082             else {
2083                 last if ! ref $handle{$addr}; # Don't read unless is real file
2084                 last if ! defined ($_ = readline $handle{$addr});
2085             }
2086             chomp;
2087             trace $_ if main::DEBUG && $to_trace;
2088
2089             # See if this line is the comment line that defines what property
2090             # value that code points that are not listed in the file should
2091             # have.  The format or existence of these lines is not guaranteed
2092             # by Unicode since they are comments, but the documentation says
2093             # that this was added for machine-readability, so probably won't
2094             # change.  This works starting in Unicode Version 5.0.  They look
2095             # like:
2096             #
2097             # @missing: 0000..10FFFF; Not_Reordered
2098             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2099             # @missing: 0000..10FFFF; ; NaN
2100             #
2101             # Save the line for a later get_missings() call.
2102             if (/$missing_defaults_prefix/) {
2103                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2104                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2105                 }
2106                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2107                     my @defaults = split /\s* ; \s*/x, $_;
2108
2109                     # The first field is the @missing, which ends in a
2110                     # semi-colon, so can safely shift.
2111                     shift @defaults;
2112
2113                     # Some of these lines may have empty field placeholders
2114                     # which get in the way.  An example is:
2115                     # @missing: 0000..10FFFF; ; NaN
2116                     # Remove them.  Process starting from the top so the
2117                     # splice doesn't affect things still to be looked at.
2118                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2119                         next if $defaults[$i] ne "";
2120                         splice @defaults, $i, 1;
2121                     }
2122
2123                     # What's left should be just the property (maybe) and the
2124                     # default.  Having only one element means it doesn't have
2125                     # the property.
2126                     my $default;
2127                     my $property;
2128                     if (@defaults >= 1) {
2129                         if (@defaults == 1) {
2130                             $default = $defaults[0];
2131                         }
2132                         else {
2133                             $property = $defaults[0];
2134                             $default = $defaults[1];
2135                         }
2136                     }
2137
2138                     if (@defaults < 1
2139                         || @defaults > 2
2140                         || ($default =~ /^</
2141                             && $default !~ /^<code *point>$/i
2142                             && $default !~ /^<none>$/i))
2143                     {
2144                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2145                     }
2146                     else {
2147
2148                         # If the property is missing from the line, it should
2149                         # be the one for the whole file
2150                         $property = $property{$addr} if ! defined $property;
2151
2152                         # Change <none> to the null string, which is what it
2153                         # really means.  If the default is the code point
2154                         # itself, set it to <code point>, which is what
2155                         # Unicode uses (but sometimes they've forgotten the
2156                         # space)
2157                         if ($default =~ /^<none>$/i) {
2158                             $default = "";
2159                         }
2160                         elsif ($default =~ /^<code *point>$/i) {
2161                             $default = $CODE_POINT;
2162                         }
2163
2164                         # Store them as a sub-arrays with both components.
2165                         push @{$missings{$addr}}, [ $default, $property ];
2166                     }
2167                 }
2168
2169                 # There is nothing for the caller to process on this comment
2170                 # line.
2171                 next;
2172             }
2173
2174             # Remove comments and trailing space, and skip this line if the
2175             # result is empty
2176             s/#.*//;
2177             s/\s+$//;
2178             next if /^$/;
2179
2180             # Call any handlers for this line, and skip further processing of
2181             # the line if the handler sets the line to null.
2182             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2183                 &{$sub_ref}($self);
2184                 next LINE if /^$/;
2185             }
2186
2187             # Here the line is ok.  return success.
2188             return 1;
2189         } # End of looping through lines.
2190
2191         # If there is an EOF handler, call it (only once) and if it generates
2192         # more lines to process go back in the loop to handle them.
2193         if ($eof_handler{$addr}) {
2194             &{$eof_handler{$addr}}($self);
2195             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2196             goto LINE if $added_lines{$addr};
2197         }
2198
2199         # Return failure -- no more lines.
2200         return 0;
2201
2202     }
2203
2204 #   Not currently used, not fully tested.
2205 #    sub peek {
2206 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2207 #        # record.  Not callable from an each_line_handler(), nor does it call
2208 #        # an each_line_handler() on the line.
2209 #
2210 #        my $self = shift;
2211 #        my $addr = do { no overloading; pack 'J', $self; };
2212 #
2213 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2214 #            my ($adjusted, $line) = @{$inserted_ref};
2215 #            next if $adjusted;
2216 #
2217 #            # Remove comments and trailing space, and return a non-empty
2218 #            # resulting line
2219 #            $line =~ s/#.*//;
2220 #            $line =~ s/\s+$//;
2221 #            return $line if $line ne "";
2222 #        }
2223 #
2224 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2225 #        while (1) { # Loop until find non-comment, non-empty line
2226 #            local $to_trace = 1 if main::DEBUG;
2227 #            trace $_ if main::DEBUG && $to_trace;
2228 #            return if ! defined (my $line = readline $handle{$addr});
2229 #            chomp $line;
2230 #            push @{$added_lines{$addr}}, [ 0, $line ];
2231 #
2232 #            $line =~ s/#.*//;
2233 #            $line =~ s/\s+$//;
2234 #            return $line if $line ne "";
2235 #        }
2236 #
2237 #        return;
2238 #    }
2239
2240
2241     sub insert_lines {
2242         # Lines can be inserted so that it looks like they were in the input
2243         # file at the place it was when this routine is called.  See also
2244         # insert_adjusted_lines().  Lines inserted via this routine go through
2245         # any each_line_handler()
2246
2247         my $self = shift;
2248
2249         # Each inserted line is an array, with the first element being 0 to
2250         # indicate that this line hasn't been adjusted, and needs to be
2251         # processed.
2252         no overloading;
2253         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2254         return;
2255     }
2256
2257     sub insert_adjusted_lines {
2258         # Lines can be inserted so that it looks like they were in the input
2259         # file at the place it was when this routine is called.  See also
2260         # insert_lines().  Lines inserted via this routine are already fully
2261         # adjusted, ready to be processed; each_line_handler()s handlers will
2262         # not be called.  This means this is not a completely general
2263         # facility, as only the last each_line_handler on the stack should
2264         # call this.  It could be made more general, by passing to each of the
2265         # line_handlers their position on the stack, which they would pass on
2266         # to this routine, and that would replace the boolean first element in
2267         # the anonymous array pushed here, so that the next_line routine could
2268         # use that to call only those handlers whose index is after it on the
2269         # stack.  But this is overkill for what is needed now.
2270
2271         my $self = shift;
2272         trace $_[0] if main::DEBUG && $to_trace;
2273
2274         # Each inserted line is an array, with the first element being 1 to
2275         # indicate that this line has been adjusted
2276         no overloading;
2277         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2278         return;
2279     }
2280
2281     sub get_missings {
2282         # Returns the stored up @missings lines' values, and clears the list.
2283         # The values are in an array, consisting of the default in the first
2284         # element, and the property in the 2nd.  However, since these lines
2285         # can be stacked up, the return is an array of all these arrays.
2286
2287         my $self = shift;
2288         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2289
2290         my $addr = do { no overloading; pack 'J', $self; };
2291
2292         # If not accepting a list return, just return the first one.
2293         return shift @{$missings{$addr}} unless wantarray;
2294
2295         my @return = @{$missings{$addr}};
2296         undef @{$missings{$addr}};
2297         return @return;
2298     }
2299
2300     sub _insert_property_into_line {
2301         # Add a property field to $_, if this file requires it.
2302
2303         my $self = shift;
2304         my $addr = do { no overloading; pack 'J', $self; };
2305         my $property = $property{$addr};
2306         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2307
2308         $_ =~ s/(;|$)/; $property$1/;
2309         return;
2310     }
2311
2312     sub carp_bad_line {
2313         # Output consistent error messages, using either a generic one, or the
2314         # one given by the optional parameter.  To avoid gazillions of the
2315         # same message in case the syntax of a  file is way off, this routine
2316         # only outputs the first instance of each message, incrementing a
2317         # count so the totals can be output at the end of the file.
2318
2319         my $self = shift;
2320         my $message = shift;
2321         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2322
2323         my $addr = do { no overloading; pack 'J', $self; };
2324
2325         $message = 'Unexpected line' unless $message;
2326
2327         # No trailing punctuation so as to fit with our addenda.
2328         $message =~ s/[.:;,]$//;
2329
2330         # If haven't seen this exact message before, output it now.  Otherwise
2331         # increment the count of how many times it has occurred
2332         unless ($errors{$addr}->{$message}) {
2333             Carp::my_carp("$message in '$_' in "
2334                             . $file{$addr}
2335                             . " at line $..  Skipping this line;");
2336             $errors{$addr}->{$message} = 1;
2337         }
2338         else {
2339             $errors{$addr}->{$message}++;
2340         }
2341
2342         # Clear the line to prevent any further (meaningful) processing of it.
2343         $_ = "";
2344
2345         return;
2346     }
2347 } # End closure
2348
2349 package Multi_Default;
2350
2351 # Certain properties in early versions of Unicode had more than one possible
2352 # default for code points missing from the files.  In these cases, one
2353 # default applies to everything left over after all the others are applied,
2354 # and for each of the others, there is a description of which class of code
2355 # points applies to it.  This object helps implement this by storing the
2356 # defaults, and for all but that final default, an eval string that generates
2357 # the class that it applies to.
2358
2359
2360 {   # Closure
2361
2362     main::setup_package();
2363
2364     my %class_defaults;
2365     # The defaults structure for the classes
2366     main::set_access('class_defaults', \%class_defaults);
2367
2368     my %other_default;
2369     # The default that applies to everything left over.
2370     main::set_access('other_default', \%other_default, 'r');
2371
2372
2373     sub new {
2374         # The constructor is called with default => eval pairs, terminated by
2375         # the left-over default. e.g.
2376         # Multi_Default->new(
2377         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2378         #               -  0x200D',
2379         #        'R' => 'some other expression that evaluates to code points',
2380         #        .
2381         #        .
2382         #        .
2383         #        'U'));
2384
2385         my $class = shift;
2386
2387         my $self = bless \do{my $anonymous_scalar}, $class;
2388         my $addr = do { no overloading; pack 'J', $self; };
2389
2390         while (@_ > 1) {
2391             my $default = shift;
2392             my $eval = shift;
2393             $class_defaults{$addr}->{$default} = $eval;
2394         }
2395
2396         $other_default{$addr} = shift;
2397
2398         return $self;
2399     }
2400
2401     sub get_next_defaults {
2402         # Iterates and returns the next class of defaults.
2403         my $self = shift;
2404         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2405
2406         my $addr = do { no overloading; pack 'J', $self; };
2407
2408         return each %{$class_defaults{$addr}};
2409     }
2410 }
2411
2412 package Alias;
2413
2414 # An alias is one of the names that a table goes by.  This class defines them
2415 # including some attributes.  Everything is currently setup in the
2416 # constructor.
2417
2418
2419 {   # Closure
2420
2421     main::setup_package();
2422
2423     my %name;
2424     main::set_access('name', \%name, 'r');
2425
2426     my %loose_match;
2427     # Determined by the constructor code if this name should match loosely or
2428     # not.  The constructor parameters can override this, but it isn't fully
2429     # implemented, as should have ability to override Unicode one's via
2430     # something like a set_loose_match()
2431     main::set_access('loose_match', \%loose_match, 'r');
2432
2433     my %make_pod_entry;
2434     # Some aliases should not get their own entries because they are covered
2435     # by a wild-card, and some we want to discourage use of.  Binary
2436     main::set_access('make_pod_entry', \%make_pod_entry, 'r');
2437
2438     my %status;
2439     # Aliases have a status, like deprecated, or even suppressed (which means
2440     # they don't appear in documentation).  Enum
2441     main::set_access('status', \%status, 'r');
2442
2443     my %externally_ok;
2444     # Similarly, some aliases should not be considered as usable ones for
2445     # external use, such as file names, or we don't want documentation to
2446     # recommend them.  Boolean
2447     main::set_access('externally_ok', \%externally_ok, 'r');
2448
2449     sub new {
2450         my $class = shift;
2451
2452         my $self = bless \do { my $anonymous_scalar }, $class;
2453         my $addr = do { no overloading; pack 'J', $self; };
2454
2455         $name{$addr} = shift;
2456         $loose_match{$addr} = shift;
2457         $make_pod_entry{$addr} = shift;
2458         $externally_ok{$addr} = shift;
2459         $status{$addr} = shift;
2460
2461         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2462
2463         # Null names are never ok externally
2464         $externally_ok{$addr} = 0 if $name{$addr} eq "";
2465
2466         return $self;
2467     }
2468 }
2469
2470 package Range;
2471
2472 # A range is the basic unit for storing code points, and is described in the
2473 # comments at the beginning of the program.  Each range has a starting code
2474 # point; an ending code point (not less than the starting one); a value
2475 # that applies to every code point in between the two end-points, inclusive;
2476 # and an enum type that applies to the value.  The type is for the user's
2477 # convenience, and has no meaning here, except that a non-zero type is
2478 # considered to not obey the normal Unicode rules for having standard forms.
2479 #
2480 # The same structure is used for both map and match tables, even though in the
2481 # latter, the value (and hence type) is irrelevant and could be used as a
2482 # comment.  In map tables, the value is what all the code points in the range
2483 # map to.  Type 0 values have the standardized version of the value stored as
2484 # well, so as to not have to recalculate it a lot.
2485
2486 sub trace { return main::trace(@_); }
2487
2488 {   # Closure
2489
2490     main::setup_package();
2491
2492     my %start;
2493     main::set_access('start', \%start, 'r', 's');
2494
2495     my %end;
2496     main::set_access('end', \%end, 'r', 's');
2497
2498     my %value;
2499     main::set_access('value', \%value, 'r');
2500
2501     my %type;
2502     main::set_access('type', \%type, 'r');
2503
2504     my %standard_form;
2505     # The value in internal standard form.  Defined only if the type is 0.
2506     main::set_access('standard_form', \%standard_form);
2507
2508     # Note that if these fields change, the dump() method should as well
2509
2510     sub new {
2511         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2512         my $class = shift;
2513
2514         my $self = bless \do { my $anonymous_scalar }, $class;
2515         my $addr = do { no overloading; pack 'J', $self; };
2516
2517         $start{$addr} = shift;
2518         $end{$addr} = shift;
2519
2520         my %args = @_;
2521
2522         my $value = delete $args{'Value'};  # Can be 0
2523         $value = "" unless defined $value;
2524         $value{$addr} = $value;
2525
2526         $type{$addr} = delete $args{'Type'} || 0;
2527
2528         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2529
2530         if (! $type{$addr}) {
2531             $standard_form{$addr} = main::standardize($value);
2532         }
2533
2534         return $self;
2535     }
2536
2537     use overload
2538         fallback => 0,
2539         qw("") => "_operator_stringify",
2540         "." => \&main::_operator_dot,
2541     ;
2542
2543     sub _operator_stringify {
2544         my $self = shift;
2545         my $addr = do { no overloading; pack 'J', $self; };
2546
2547         # Output it like '0041..0065 (value)'
2548         my $return = sprintf("%04X", $start{$addr})
2549                         .  '..'
2550                         . sprintf("%04X", $end{$addr});
2551         my $value = $value{$addr};
2552         my $type = $type{$addr};
2553         $return .= ' (';
2554         $return .= "$value";
2555         $return .= ", Type=$type" if $type != 0;
2556         $return .= ')';
2557
2558         return $return;
2559     }
2560
2561     sub standard_form {
2562         # The standard form is the value itself if the standard form is
2563         # undefined (that is if the value is special)
2564
2565         my $self = shift;
2566         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2567
2568         my $addr = do { no overloading; pack 'J', $self; };
2569
2570         return $standard_form{$addr} if defined $standard_form{$addr};
2571         return $value{$addr};
2572     }
2573
2574     sub dump {
2575         # Human, not machine readable.  For machine readable, comment out this
2576         # entire routine and let the standard one take effect.
2577         my $self = shift;
2578         my $indent = shift;
2579         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2580
2581         my $addr = do { no overloading; pack 'J', $self; };
2582
2583         my $return = $indent
2584                     . sprintf("%04X", $start{$addr})
2585                     . '..'
2586                     . sprintf("%04X", $end{$addr})
2587                     . " '$value{$addr}';";
2588         if (! defined $standard_form{$addr}) {
2589             $return .= "(type=$type{$addr})";
2590         }
2591         elsif ($standard_form{$addr} ne $value{$addr}) {
2592             $return .= "(standard '$standard_form{$addr}')";
2593         }
2594         return $return;
2595     }
2596 } # End closure
2597
2598 package _Range_List_Base;
2599
2600 # Base class for range lists.  A range list is simply an ordered list of
2601 # ranges, so that the ranges with the lowest starting numbers are first in it.
2602 #
2603 # When a new range is added that is adjacent to an existing range that has the
2604 # same value and type, it merges with it to form a larger range.
2605 #
2606 # Ranges generally do not overlap, except that there can be multiple entries
2607 # of single code point ranges.  This is because of NameAliases.txt.
2608 #
2609 # In this program, there is a standard value such that if two different
2610 # values, have the same standard value, they are considered equivalent.  This
2611 # value was chosen so that it gives correct results on Unicode data
2612
2613 # There are a number of methods to manipulate range lists, and some operators
2614 # are overloaded to handle them.
2615
2616 sub trace { return main::trace(@_); }
2617
2618 { # Closure
2619
2620     our $addr;
2621
2622     main::setup_package();
2623
2624     my %ranges;
2625     # The list of ranges
2626     main::set_access('ranges', \%ranges, 'readable_array');
2627
2628     my %max;
2629     # The highest code point in the list.  This was originally a method, but
2630     # actual measurements said it was used a lot.
2631     main::set_access('max', \%max, 'r');
2632
2633     my %each_range_iterator;
2634     # Iterator position for each_range()
2635     main::set_access('each_range_iterator', \%each_range_iterator);
2636
2637     my %owner_name_of;
2638     # Name of parent this is attached to, if any.  Solely for better error
2639     # messages.
2640     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2641
2642     my %_search_ranges_cache;
2643     # A cache of the previous result from _search_ranges(), for better
2644     # performance
2645     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2646
2647     sub new {
2648         my $class = shift;
2649         my %args = @_;
2650
2651         # Optional initialization data for the range list.
2652         my $initialize = delete $args{'Initialize'};
2653
2654         my $self;
2655
2656         # Use _union() to initialize.  _union() returns an object of this
2657         # class, which means that it will call this constructor recursively.
2658         # But it won't have this $initialize parameter so that it won't
2659         # infinitely loop on this.
2660         return _union($class, $initialize, %args) if defined $initialize;
2661
2662         $self = bless \do { my $anonymous_scalar }, $class;
2663         my $addr = do { no overloading; pack 'J', $self; };
2664
2665         # Optional parent object, only for debug info.
2666         $owner_name_of{$addr} = delete $args{'Owner'};
2667         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2668
2669         # Stringify, in case it is an object.
2670         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2671
2672         # This is used only for error messages, and so a colon is added
2673         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2674
2675         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2676
2677         # Max is initialized to a negative value that isn't adjacent to 0,
2678         # for simpler tests
2679         $max{$addr} = -2;
2680
2681         $_search_ranges_cache{$addr} = 0;
2682         $ranges{$addr} = [];
2683
2684         return $self;
2685     }
2686
2687     use overload
2688         fallback => 0,
2689         qw("") => "_operator_stringify",
2690         "." => \&main::_operator_dot,
2691     ;
2692
2693     sub _operator_stringify {
2694         my $self = shift;
2695         my $addr = do { no overloading; pack 'J', $self; };
2696
2697         return "Range_List attached to '$owner_name_of{$addr}'"
2698                                                 if $owner_name_of{$addr};
2699         return "anonymous Range_List " . \$self;
2700     }
2701
2702     sub _union {
2703         # Returns the union of the input code points.  It can be called as
2704         # either a constructor or a method.  If called as a method, the result
2705         # will be a new() instance of the calling object, containing the union
2706         # of that object with the other parameter's code points;  if called as
2707         # a constructor, the first parameter gives the class the new object
2708         # should be, and the second parameter gives the code points to go into
2709         # it.
2710         # In either case, there are two parameters looked at by this routine;
2711         # any additional parameters are passed to the new() constructor.
2712         #
2713         # The code points can come in the form of some object that contains
2714         # ranges, and has a conventionally named method to access them; or
2715         # they can be an array of individual code points (as integers); or
2716         # just a single code point.
2717         #
2718         # If they are ranges, this routine doesn't make any effort to preserve
2719         # the range values of one input over the other.  Therefore this base
2720         # class should not allow _union to be called from other than
2721         # initialization code, so as to prevent two tables from being added
2722         # together where the range values matter.  The general form of this
2723         # routine therefore belongs in a derived class, but it was moved here
2724         # to avoid duplication of code.  The failure to overload this in this
2725         # class keeps it safe.
2726         #
2727
2728         my $self;
2729         my @args;   # Arguments to pass to the constructor
2730
2731         my $class = shift;
2732
2733         # If a method call, will start the union with the object itself, and
2734         # the class of the new object will be the same as self.
2735         if (ref $class) {
2736             $self = $class;
2737             $class = ref $self;
2738             push @args, $self;
2739         }
2740
2741         # Add the other required parameter.
2742         push @args, shift;
2743         # Rest of parameters are passed on to the constructor
2744
2745         # Accumulate all records from both lists.
2746         my @records;
2747         for my $arg (@args) {
2748             #local $to_trace = 0 if main::DEBUG;
2749             trace "argument = $arg" if main::DEBUG && $to_trace;
2750             if (! defined $arg) {
2751                 my $message = "";
2752                 if (defined $self) {
2753                     no overloading;
2754                     $message .= $owner_name_of{pack 'J', $self};
2755                 }
2756                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
2757                 return;
2758             }
2759             $arg = [ $arg ] if ! ref $arg;
2760             my $type = ref $arg;
2761             if ($type eq 'ARRAY') {
2762                 foreach my $element (@$arg) {
2763                     push @records, Range->new($element, $element);
2764                 }
2765             }
2766             elsif ($arg->isa('Range')) {
2767                 push @records, $arg;
2768             }
2769             elsif ($arg->can('ranges')) {
2770                 push @records, $arg->ranges;
2771             }
2772             else {
2773                 my $message = "";
2774                 if (defined $self) {
2775                     no overloading;
2776                     $message .= $owner_name_of{pack 'J', $self};
2777                 }
2778                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
2779                 return;
2780             }
2781         }
2782
2783         # Sort with the range containing the lowest ordinal first, but if
2784         # two ranges start at the same code point, sort with the bigger range
2785         # of the two first, because it takes fewer cycles.
2786         @records = sort { ($a->start <=> $b->start)
2787                                       or
2788                                     # if b is shorter than a, b->end will be
2789                                     # less than a->end, and we want to select
2790                                     # a, so want to return -1
2791                                     ($b->end <=> $a->end)
2792                                    } @records;
2793
2794         my $new = $class->new(@_);
2795
2796         # Fold in records so long as they add new information.
2797         for my $set (@records) {
2798             my $start = $set->start;
2799             my $end   = $set->end;
2800             my $value   = $set->value;
2801             if ($start > $new->max) {
2802                 $new->_add_delete('+', $start, $end, $value);
2803             }
2804             elsif ($end > $new->max) {
2805                 $new->_add_delete('+', $new->max +1, $end, $value);
2806             }
2807         }
2808
2809         return $new;
2810     }
2811
2812     sub range_count {        # Return the number of ranges in the range list
2813         my $self = shift;
2814         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2815
2816         no overloading;
2817         return scalar @{$ranges{pack 'J', $self}};
2818     }
2819
2820     sub min {
2821         # Returns the minimum code point currently in the range list, or if
2822         # the range list is empty, 2 beyond the max possible.  This is a
2823         # method because used so rarely, that not worth saving between calls,
2824         # and having to worry about changing it as ranges are added and
2825         # deleted.
2826
2827         my $self = shift;
2828         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2829
2830         my $addr = do { no overloading; pack 'J', $self; };
2831
2832         # If the range list is empty, return a large value that isn't adjacent
2833         # to any that could be in the range list, for simpler tests
2834         return $LAST_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
2835         return $ranges{$addr}->[0]->start;
2836     }
2837
2838     sub contains {
2839         # Boolean: Is argument in the range list?  If so returns $i such that:
2840         #   range[$i]->end < $codepoint <= range[$i+1]->end
2841         # which is one beyond what you want; this is so that the 0th range
2842         # doesn't return false
2843         my $self = shift;
2844         my $codepoint = shift;
2845         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2846
2847         my $i = $self->_search_ranges($codepoint);
2848         return 0 unless defined $i;
2849
2850         # The search returns $i, such that
2851         #   range[$i-1]->end < $codepoint <= range[$i]->end
2852         # So is in the table if and only iff it is at least the start position
2853         # of range $i.
2854         no overloading;
2855         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
2856         return $i + 1;
2857     }
2858
2859     sub containing_range {
2860         # Returns the range object that contains the code point, undef if none
2861
2862         my $self = shift;
2863         my $codepoint = shift;
2864         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2865
2866         my $i = $self->contains($codepoint);
2867         return unless $i;
2868
2869         # contains() returns 1 beyond where we should look
2870         no overloading;
2871         return $ranges{pack 'J', $self}->[$i-1];
2872     }
2873
2874     sub value_of {
2875         # Returns the value associated with the code point, undef if none
2876
2877         my $self = shift;
2878         my $codepoint = shift;
2879         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2880
2881         my $range = $self->containing_range($codepoint);
2882         return unless defined $range;
2883
2884         return $range->value;
2885     }
2886
2887     sub type_of {
2888         # Returns the type of the range containing the code point, undef if
2889         # the code point is not in the table
2890
2891         my $self = shift;
2892         my $codepoint = shift;
2893         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2894
2895         my $range = $self->containing_range($codepoint);
2896         return unless defined $range;
2897
2898         return $range->type;
2899     }
2900
2901     sub _search_ranges {
2902         # Find the range in the list which contains a code point, or where it
2903         # should go if were to add it.  That is, it returns $i, such that:
2904         #   range[$i-1]->end < $codepoint <= range[$i]->end
2905         # Returns undef if no such $i is possible (e.g. at end of table), or
2906         # if there is an error.
2907
2908         my $self = shift;
2909         my $code_point = shift;
2910         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2911
2912         my $addr = do { no overloading; pack 'J', $self; };
2913
2914         return if $code_point > $max{$addr};
2915         my $r = $ranges{$addr};                # The current list of ranges
2916         my $range_list_size = scalar @$r;
2917         my $i;
2918
2919         use integer;        # want integer division
2920
2921         # Use the cached result as the starting guess for this one, because,
2922         # an experiment on 5.1 showed that 90% of the time the cache was the
2923         # same as the result on the next call (and 7% it was one less).
2924         $i = $_search_ranges_cache{$addr};
2925         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
2926                                             # from an intervening deletion
2927         #local $to_trace = 1 if main::DEBUG;
2928         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
2929         return $i if $code_point <= $r->[$i]->end
2930                      && ($i == 0 || $r->[$i-1]->end < $code_point);
2931
2932         # Here the cache doesn't yield the correct $i.  Try adding 1.
2933         if ($i < $range_list_size - 1
2934             && $r->[$i]->end < $code_point &&
2935             $code_point <= $r->[$i+1]->end)
2936         {
2937             $i++;
2938             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
2939             $_search_ranges_cache{$addr} = $i;
2940             return $i;
2941         }
2942
2943         # Here, adding 1 also didn't work.  We do a binary search to
2944         # find the correct position, starting with current $i
2945         my $lower = 0;
2946         my $upper = $range_list_size - 1;
2947         while (1) {
2948             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
2949
2950             if ($code_point <= $r->[$i]->end) {
2951
2952                 # Here we have met the upper constraint.  We can quit if we
2953                 # also meet the lower one.
2954                 last if $i == 0 || $r->[$i-1]->end < $code_point;
2955
2956                 $upper = $i;        # Still too high.
2957
2958             }
2959             else {
2960
2961                 # Here, $r[$i]->end < $code_point, so look higher up.
2962                 $lower = $i;
2963             }
2964
2965             # Split search domain in half to try again.
2966             my $temp = ($upper + $lower) / 2;
2967
2968             # No point in continuing unless $i changes for next time
2969             # in the loop.
2970             if ($temp == $i) {
2971
2972                 # We can't reach the highest element because of the averaging.
2973                 # So if one below the upper edge, force it there and try one
2974                 # more time.
2975                 if ($i == $range_list_size - 2) {
2976
2977                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
2978                     $i = $range_list_size - 1;
2979
2980                     # Change $lower as well so if fails next time through,
2981                     # taking the average will yield the same $i, and we will
2982                     # quit with the error message just below.
2983                     $lower = $i;
2984                     next;
2985                 }
2986                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
2987                 return;
2988             }
2989             $i = $temp;
2990         } # End of while loop
2991
2992         if (main::DEBUG && $to_trace) {
2993             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
2994             trace "i=  [ $i ]", $r->[$i];
2995             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
2996         }
2997
2998         # Here we have found the offset.  Cache it as a starting point for the
2999         # next call.
3000         $_search_ranges_cache{$addr} = $i;
3001         return $i;
3002     }
3003
3004     sub _add_delete {
3005         # Add, replace or delete ranges to or from a list.  The $type
3006         # parameter gives which:
3007         #   '+' => insert or replace a range, returning a list of any changed
3008         #          ranges.
3009         #   '-' => delete a range, returning a list of any deleted ranges.
3010         #
3011         # The next three parameters give respectively the start, end, and
3012         # value associated with the range.  'value' should be null unless the
3013         # operation is '+';
3014         #
3015         # The range list is kept sorted so that the range with the lowest
3016         # starting position is first in the list, and generally, adjacent
3017         # ranges with the same values are merged into a single larger one (see
3018         # exceptions below).
3019         #
3020         # There are more parameters; all are key => value pairs:
3021         #   Type    gives the type of the value.  It is only valid for '+'.
3022         #           All ranges have types; if this parameter is omitted, 0 is
3023         #           assumed.  Ranges with type 0 are assumed to obey the
3024         #           Unicode rules for casing, etc; ranges with other types are
3025         #           not.  Otherwise, the type is arbitrary, for the caller's
3026         #           convenience, and looked at only by this routine to keep
3027         #           adjacent ranges of different types from being merged into
3028         #           a single larger range, and when Replace =>
3029         #           $IF_NOT_EQUIVALENT is specified (see just below).
3030         #   Replace  determines what to do if the range list already contains
3031         #            ranges which coincide with all or portions of the input
3032         #            range.  It is only valid for '+':
3033         #       => $NO            means that the new value is not to replace
3034         #                         any existing ones, but any empty gaps of the
3035         #                         range list coinciding with the input range
3036         #                         will be filled in with the new value.
3037         #       => $UNCONDITIONALLY  means to replace the existing values with
3038         #                         this one unconditionally.  However, if the
3039         #                         new and old values are identical, the
3040         #                         replacement is skipped to save cycles
3041         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3042         #                         with this one if they are not equivalent.
3043         #                         Ranges are equivalent if their types are the
3044         #                         same, and they are the same string; or if
3045         #                         both are type 0 ranges, if their Unicode
3046         #                         standard forms are identical.  In this last
3047         #                         case, the routine chooses the more "modern"
3048         #                         one to use.  This is because some of the
3049         #                         older files are formatted with values that
3050         #                         are, for example, ALL CAPs, whereas the
3051         #                         derived files have a more modern style,
3052         #                         which looks better.  By looking for this
3053         #                         style when the pre-existing and replacement
3054         #                         standard forms are the same, we can move to
3055         #                         the modern style
3056         #       => $MULTIPLE      means that if this range duplicates an
3057         #                         existing one, but has a different value,
3058         #                         don't replace the existing one, but insert
3059         #                         this, one so that the same range can occur
3060         #                         multiple times.
3061         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3062         #
3063         # "same value" means identical for non-type-0 ranges, and it means
3064         # having the same standard forms for type-0 ranges.
3065
3066         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3067
3068         my $self = shift;
3069         my $operation = shift;   # '+' for add/replace; '-' for delete;
3070         my $start = shift;
3071         my $end   = shift;
3072         my $value = shift;
3073
3074         my %args = @_;
3075
3076         $value = "" if not defined $value;        # warning: $value can be "0"
3077
3078         my $replace = delete $args{'Replace'};
3079         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3080
3081         my $type = delete $args{'Type'};
3082         $type = 0 unless defined $type;
3083
3084         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3085
3086         my $addr = do { no overloading; pack 'J', $self; };
3087
3088         if ($operation ne '+' && $operation ne '-') {
3089             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3090             return;
3091         }
3092         unless (defined $start && defined $end) {
3093             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3094             return;
3095         }
3096         unless ($end >= $start) {
3097             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3098             return;
3099         }
3100         #local $to_trace = 1 if main::DEBUG;
3101
3102         if ($operation eq '-') {
3103             if ($replace != $IF_NOT_EQUIVALENT) {
3104                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3105                 $replace = $IF_NOT_EQUIVALENT;
3106             }
3107             if ($type) {
3108                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3109                 $type = 0;
3110             }
3111             if ($value ne "") {
3112                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3113                 $value = "";
3114             }
3115         }
3116
3117         my $r = $ranges{$addr};               # The current list of ranges
3118         my $range_list_size = scalar @$r;     # And its size
3119         my $max = $max{$addr};                # The current high code point in
3120                                               # the list of ranges
3121
3122         # Do a special case requiring fewer machine cycles when the new range
3123         # starts after the current highest point.  The Unicode input data is
3124         # structured so this is common.
3125         if ($start > $max) {
3126
3127             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3128             return if $operation eq '-'; # Deleting a non-existing range is a
3129                                          # no-op
3130
3131             # If the new range doesn't logically extend the current final one
3132             # in the range list, create a new range at the end of the range
3133             # list.  (max cleverly is initialized to a negative number not
3134             # adjacent to 0 if the range list is empty, so even adding a range
3135             # to an empty range list starting at 0 will have this 'if'
3136             # succeed.)
3137             if ($start > $max + 1        # non-adjacent means can't extend.
3138                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3139                 || @{$r}[-1]->type != $type # types differ, can't extend.
3140             ) {
3141                 push @$r, Range->new($start, $end,
3142                                      Value => $value,
3143                                      Type => $type);
3144             }
3145             else {
3146
3147                 # Here, the new range starts just after the current highest in
3148                 # the range list, and they have the same type and value.
3149                 # Extend the current range to incorporate the new one.
3150                 @{$r}[-1]->set_end($end);
3151             }
3152
3153             # This becomes the new maximum.
3154             $max{$addr} = $end;
3155
3156             return;
3157         }
3158         #local $to_trace = 0 if main::DEBUG;
3159
3160         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3161
3162         # Here, the input range isn't after the whole rest of the range list.
3163         # Most likely 'splice' will be needed.  The rest of the routine finds
3164         # the needed splice parameters, and if necessary, does the splice.
3165         # First, find the offset parameter needed by the splice function for
3166         # the input range.  Note that the input range may span multiple
3167         # existing ones, but we'll worry about that later.  For now, just find
3168         # the beginning.  If the input range is to be inserted starting in a
3169         # position not currently in the range list, it must (obviously) come
3170         # just after the range below it, and just before the range above it.
3171         # Slightly less obviously, it will occupy the position currently
3172         # occupied by the range that is to come after it.  More formally, we
3173         # are looking for the position, $i, in the array of ranges, such that:
3174         #
3175         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3176         #
3177         # (The ordered relationships within existing ranges are also shown in
3178         # the equation above).  However, if the start of the input range is
3179         # within an existing range, the splice offset should point to that
3180         # existing range's position in the list; that is $i satisfies a
3181         # somewhat different equation, namely:
3182         #
3183         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3184         #
3185         # More briefly, $start can come before or after r[$i]->start, and at
3186         # this point, we don't know which it will be.  However, these
3187         # two equations share these constraints:
3188         #
3189         #   r[$i-1]->end < $start <= r[$i]->end
3190         #
3191         # And that is good enough to find $i.
3192
3193         my $i = $self->_search_ranges($start);
3194         if (! defined $i) {
3195             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3196             return;
3197         }
3198
3199         # The search function returns $i such that:
3200         #
3201         # r[$i-1]->end < $start <= r[$i]->end
3202         #
3203         # That means that $i points to the first range in the range list
3204         # that could possibly be affected by this operation.  We still don't
3205         # know if the start of the input range is within r[$i], or if it
3206         # points to empty space between r[$i-1] and r[$i].
3207         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3208
3209         # Special case the insertion of data that is not to replace any
3210         # existing data.
3211         if ($replace == $NO) {  # If $NO, has to be operation '+'
3212             #local $to_trace = 1 if main::DEBUG;
3213             trace "Doesn't replace" if main::DEBUG && $to_trace;
3214
3215             # Here, the new range is to take effect only on those code points
3216             # that aren't already in an existing range.  This can be done by
3217             # looking through the existing range list and finding the gaps in
3218             # the ranges that this new range affects, and then calling this
3219             # function recursively on each of those gaps, leaving untouched
3220             # anything already in the list.  Gather up a list of the changed
3221             # gaps first so that changes to the internal state as new ranges
3222             # are added won't be a problem.
3223             my @gap_list;
3224
3225             # First, if the starting point of the input range is outside an
3226             # existing one, there is a gap from there to the beginning of the
3227             # existing range -- add a span to fill the part that this new
3228             # range occupies
3229             if ($start < $r->[$i]->start) {
3230                 push @gap_list, Range->new($start,
3231                                            main::min($end,
3232                                                      $r->[$i]->start - 1),
3233                                            Type => $type);
3234                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3235             }
3236
3237             # Then look through the range list for other gaps until we reach
3238             # the highest range affected by the input one.
3239             my $j;
3240             for ($j = $i+1; $j < $range_list_size; $j++) {
3241                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3242                 last if $end < $r->[$j]->start;
3243
3244                 # If there is a gap between when this range starts and the
3245                 # previous one ends, add a span to fill it.  Note that just
3246                 # because there are two ranges doesn't mean there is a
3247                 # non-zero gap between them.  It could be that they have
3248                 # different values or types
3249                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3250                     push @gap_list,
3251                         Range->new($r->[$j-1]->end + 1,
3252                                    $r->[$j]->start - 1,
3253                                    Type => $type);
3254                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3255                 }
3256             }
3257
3258             # Here, we have either found an existing range in the range list,
3259             # beyond the area affected by the input one, or we fell off the
3260             # end of the loop because the input range affects the whole rest
3261             # of the range list.  In either case, $j is 1 higher than the
3262             # highest affected range.  If $j == $i, it means that there are no
3263             # affected ranges, that the entire insertion is in the gap between
3264             # r[$i-1], and r[$i], which we already have taken care of before
3265             # the loop.
3266             # On the other hand, if there are affected ranges, it might be
3267             # that there is a gap that needs filling after the final such
3268             # range to the end of the input range
3269             if ($r->[$j-1]->end < $end) {
3270                     push @gap_list, Range->new(main::max($start,
3271                                                          $r->[$j-1]->end + 1),
3272                                                $end,
3273                                                Type => $type);
3274                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3275             }
3276
3277             # Call recursively to fill in all the gaps.
3278             foreach my $gap (@gap_list) {
3279                 $self->_add_delete($operation,
3280                                    $gap->start,
3281                                    $gap->end,
3282                                    $value,
3283                                    Type => $type);
3284             }
3285
3286             return;
3287         }
3288
3289         # Here, we have taken care of the case where $replace is $NO, which
3290         # means that whatever action we now take is done unconditionally.  It
3291         # still could be that this call will result in a no-op, if duplicates
3292         # aren't allowed, and we are inserting a range that merely duplicates
3293         # data already in the range list; or also if deleting a non-existent
3294         # range.
3295         # $i still points to the first potential affected range.  Now find the
3296         # highest range affected, which will determine the length parameter to
3297         # splice.  (The input range can span multiple existing ones.)  While
3298         # we are looking through the range list, see also if this is an
3299         # insertion that will change the values of at least one of the
3300         # affected ranges.  We don't need to do this check unless this is an
3301         # insertion of non-multiples, and also since this is a boolean, we
3302         # don't need to do it if have already determined that it will make a
3303         # change; just unconditionally change them.  $cdm is created to be 1
3304         # if either of these is true. (The 'c' in the name comes from below)
3305         my $cdm = ($operation eq '-' || $replace == $MULTIPLE);
3306         my $j;        # This will point to the highest affected range
3307
3308         # For non-zero types, the standard form is the value itself;
3309         my $standard_form = ($type) ? $value : main::standardize($value);
3310
3311         for ($j = $i; $j < $range_list_size; $j++) {
3312             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3313
3314             # If find a range that it doesn't overlap into, we can stop
3315             # searching
3316             last if $end < $r->[$j]->start;
3317
3318             # Here, overlaps the range at $j.  If the value's don't match,
3319             # and this is supposedly an insertion, it becomes a change
3320             # instead.  This is what the 'c' stands for in $cdm.
3321             if (! $cdm) {
3322                 if ($r->[$j]->standard_form ne $standard_form) {
3323                     $cdm = 1;
3324                 }
3325                 else {
3326
3327                     # Here, the two values are essentially the same.  If the
3328                     # two are actually identical, replacing wouldn't change
3329                     # anything so skip it.
3330                     my $pre_existing = $r->[$j]->value;
3331                     if ($pre_existing ne $value) {
3332
3333                         # Here the new and old standardized values are the
3334                         # same, but the non-standardized values aren't.  If
3335                         # replacing unconditionally, then replace
3336                         if( $replace == $UNCONDITIONALLY) {
3337                             $cdm = 1;
3338                         }
3339                         else {
3340
3341                             # Here, are replacing conditionally.  Decide to
3342                             # replace or not based on which appears to look
3343                             # the "nicest".  If one is mixed case and the
3344                             # other isn't, choose the mixed case one.
3345                             my $new_mixed = $value =~ /[A-Z]/
3346                                             && $value =~ /[a-z]/;
3347                             my $old_mixed = $pre_existing =~ /[A-Z]/
3348                                             && $pre_existing =~ /[a-z]/;
3349
3350                             if ($old_mixed != $new_mixed) {
3351                                 $cdm = 1 if $new_mixed;
3352                                 if (main::DEBUG && $to_trace) {
3353                                     if ($cdm) {
3354                                         trace "Replacing $pre_existing with $value";
3355                                     }
3356                                     else {
3357                                         trace "Retaining $pre_existing over $value";
3358                                     }
3359                                 }
3360                             }
3361                             else {
3362
3363                                 # Here casing wasn't different between the two.
3364                                 # If one has hyphens or underscores and the
3365                                 # other doesn't, choose the one with the
3366                                 # punctuation.
3367                                 my $new_punct = $value =~ /[-_]/;
3368                                 my $old_punct = $pre_existing =~ /[-_]/;
3369
3370                                 if ($old_punct != $new_punct) {
3371                                     $cdm = 1 if $new_punct;
3372                                     if (main::DEBUG && $to_trace) {
3373                                         if ($cdm) {
3374                                             trace "Replacing $pre_existing with $value";
3375                                         }
3376                                         else {
3377                                             trace "Retaining $pre_existing over $value";
3378                                         }
3379                                     }
3380                                 }   # else existing one is just as "good";
3381                                     # retain it to save cycles.
3382                             }
3383                         }
3384                     }
3385                 }
3386             }
3387         } # End of loop looking for highest affected range.
3388
3389         # Here, $j points to one beyond the highest range that this insertion
3390         # affects (hence to beyond the range list if that range is the final
3391         # one in the range list).
3392
3393         # The splice length is all the affected ranges.  Get it before
3394         # subtracting, for efficiency, so we don't have to later add 1.
3395         my $length = $j - $i;
3396
3397         $j--;        # $j now points to the highest affected range.
3398         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3399
3400         # If inserting a multiple record, this is where it goes, after all the
3401         # existing ones for this range.  This implies an insertion, and no
3402         # change to any existing ranges.  Note that $j can be -1 if this new
3403         # range doesn't actually duplicate any existing, and comes at the
3404         # beginning of the list, in which case we can handle it like any other
3405         # insertion, and is easier to do so.
3406         if ($replace == $MULTIPLE && $j >= 0) {
3407
3408             # This restriction could be remedied with a little extra work, but
3409             # it won't hopefully ever be necessary
3410             if ($r->[$j]->start != $r->[$j]->end) {
3411                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple when the other range ($r->[$j]) contains more than one code point.  No action taken.");
3412                 return;
3413             }
3414
3415             # Don't add an exact duplicate, as it isn't really a multiple
3416             return if $value eq $r->[$j]->value && $type eq $r->[$j]->type;
3417
3418             trace "Adding multiple record at $j+1 with $start..$end, $value" if main::DEBUG && $to_trace;
3419             my @return = splice @$r,
3420                                 $j+1,
3421                                 0,
3422                                 Range->new($start,
3423                                            $end,
3424                                            Value => $value,
3425                                            Type => $type);
3426             if (main::DEBUG && $to_trace) {
3427                 trace "After splice:";
3428                 trace 'j-2=[', $j-2, ']', $r->[$j-2] if $j >= 2;
3429                 trace 'j-1=[', $j-1, ']', $r->[$j-1] if $j >= 1;
3430                 trace "j  =[", $j, "]", $r->[$j] if $j >= 0;
3431                 trace 'j+1=[', $j+1, ']', $r->[$j+1] if $j < @$r - 1;
3432                 trace 'j+2=[', $j+2, ']', $r->[$j+2] if $j < @$r - 2;
3433                 trace 'j+3=[', $j+3, ']', $r->[$j+3] if $j < @$r - 3;
3434             }
3435             return @return;
3436         }
3437
3438         # Here, have taken care of $NO and $MULTIPLE replaces.
3439         # $j points to the highest affected range.  But it can be < $i or even
3440         # -1.  These happen only if the insertion is entirely in the gap
3441         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3442         # above exited first time through with $end < $r->[$i]->start.  (And
3443         # then we subtracted one from j)  This implies also that $start <
3444         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3445         # $start, so the entire input range is in the gap.
3446         if ($j < $i) {
3447
3448             # Here the entire input range is in the gap before $i.
3449
3450             if (main::DEBUG && $to_trace) {
3451                 if ($i) {
3452                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3453                 }
3454                 else {
3455                     trace "Entire range is before $r->[$i]";
3456                 }
3457             }
3458             return if $operation ne '+'; # Deletion of a non-existent range is
3459                                          # a no-op
3460         }
3461         else {
3462
3463             # Here the entire input range is not in the gap before $i.  There
3464             # is an affected one, and $j points to the highest such one.
3465
3466             # At this point, here is the situation:
3467             # This is not an insertion of a multiple, nor of tentative ($NO)
3468             # data.
3469             #   $i  points to the first element in the current range list that
3470             #            may be affected by this operation.  In fact, we know
3471             #            that the range at $i is affected because we are in
3472             #            the else branch of this 'if'
3473             #   $j  points to the highest affected range.
3474             # In other words,
3475             #   r[$i-1]->end < $start <= r[$i]->end
3476             # And:
3477             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3478             #
3479             # Also:
3480             #   $cdm is a boolean which is set true if and only if this is a
3481             #        change or deletion (multiple was handled above).  In
3482             #        other words, it could be renamed to be just $cd.
3483
3484             # We now have enough information to decide if this call is a no-op
3485             # or not.  It is a no-op if it is a deletion of a non-existent
3486             # range, or an insertion of already existing data.
3487
3488             if (main::DEBUG && $to_trace && ! $cdm
3489                                          && $i == $j
3490                                          && $start >= $r->[$i]->start)
3491             {
3492                     trace "no-op";
3493             }
3494             return if ! $cdm      # change or delete => not no-op
3495                       && $i == $j # more than one affected range => not no-op
3496
3497                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3498                       # Further, $start and/or $end is >= r[$i]->start
3499                       # The test below hence guarantees that
3500                       #     r[$i]->start < $start <= $end <= r[$i]->end
3501                       # This means the input range is contained entirely in
3502                       # the one at $i, so is a no-op
3503                       && $start >= $r->[$i]->start;
3504         }
3505
3506         # Here, we know that some action will have to be taken.  We have
3507         # calculated the offset and length (though adjustments may be needed)
3508         # for the splice.  Now start constructing the replacement list.
3509         my @replacement;
3510         my $splice_start = $i;
3511
3512         my $extends_below;
3513         my $extends_above;
3514
3515         # See if should extend any adjacent ranges.
3516         if ($operation eq '-') { # Don't extend deletions
3517             $extends_below = $extends_above = 0;
3518         }
3519         else {  # Here, should extend any adjacent ranges.  See if there are
3520                 # any.
3521             $extends_below = ($i > 0
3522                             # can't extend unless adjacent
3523                             && $r->[$i-1]->end == $start -1
3524                             # can't extend unless are same standard value
3525                             && $r->[$i-1]->standard_form eq $standard_form
3526                             # can't extend unless share type
3527                             && $r->[$i-1]->type == $type);
3528             $extends_above = ($j+1 < $range_list_size
3529                             && $r->[$j+1]->start == $end +1
3530                             && $r->[$j+1]->standard_form eq $standard_form
3531                             && $r->[$j-1]->type == $type);
3532         }
3533         if ($extends_below && $extends_above) { # Adds to both
3534             $splice_start--;     # start replace at element below
3535             $length += 2;        # will replace on both sides
3536             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3537
3538             # The result will fill in any gap, replacing both sides, and
3539             # create one large range.
3540             @replacement = Range->new($r->[$i-1]->start,
3541                                       $r->[$j+1]->end,
3542                                       Value => $value,
3543                                       Type => $type);
3544         }
3545         else {
3546
3547             # Here we know that the result won't just be the conglomeration of
3548             # a new range with both its adjacent neighbors.  But it could
3549             # extend one of them.
3550
3551             if ($extends_below) {
3552
3553                 # Here the new element adds to the one below, but not to the
3554                 # one above.  If inserting, and only to that one range,  can
3555                 # just change its ending to include the new one.
3556                 if ($length == 0 && ! $cdm) {
3557                     $r->[$i-1]->set_end($end);
3558                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3559                     return;
3560                 }
3561                 else {
3562                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3563                     $splice_start--;        # start replace at element below
3564                     $length++;              # will replace the element below
3565                     $start = $r->[$i-1]->start;
3566                 }
3567             }
3568             elsif ($extends_above) {
3569
3570                 # Here the new element adds to the one above, but not below.
3571                 # Mirror the code above
3572                 if ($length == 0 && ! $cdm) {
3573                     $r->[$j+1]->set_start($start);
3574                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3575                     return;
3576                 }
3577                 else {
3578                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3579                     $length++;        # will replace the element above
3580                     $end = $r->[$j+1]->end;
3581                 }
3582             }
3583
3584             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3585
3586             # Finally, here we know there will have to be a splice.
3587             # If the change or delete affects only the highest portion of the
3588             # first affected range, the range will have to be split.  The
3589             # splice will remove the whole range, but will replace it by a new
3590             # range containing just the unaffected part.  So, in this case,
3591             # add to the replacement list just this unaffected portion.
3592             if (! $extends_below
3593                 && $start > $r->[$i]->start && $start <= $r->[$i]->end)
3594             {
3595                 push @replacement,
3596                     Range->new($r->[$i]->start,
3597                                $start - 1,
3598                                Value => $r->[$i]->value,
3599                                Type => $r->[$i]->type);
3600             }
3601
3602             # In the case of an insert or change, but not a delete, we have to
3603             # put in the new stuff;  this comes next.
3604             if ($operation eq '+') {
3605                 push @replacement, Range->new($start,
3606                                               $end,
3607                                               Value => $value,
3608                                               Type => $type);
3609             }
3610
3611             trace "Range at $j is $r->[$j]" if main::DEBUG && $to_trace && $j != $i;
3612             #trace "$end >=", $r->[$j]->start, " && $end <", $r->[$j]->end if main::DEBUG && $to_trace;
3613
3614             # And finally, if we're changing or deleting only a portion of the
3615             # highest affected range, it must be split, as the lowest one was.
3616             if (! $extends_above
3617                 && $j >= 0  # Remember that j can be -1 if before first
3618                             # current element
3619                 && $end >= $r->[$j]->start
3620                 && $end < $r->[$j]->end)
3621             {
3622                 push @replacement,
3623                     Range->new($end + 1,
3624                                $r->[$j]->end,
3625                                Value => $r->[$j]->value,
3626                                Type => $r->[$j]->type);
3627             }
3628         }
3629
3630         # And do the splice, as calculated above
3631         if (main::DEBUG && $to_trace) {
3632             trace "replacing $length element(s) at $i with ";
3633             foreach my $replacement (@replacement) {
3634                 trace "    $replacement";
3635             }
3636             trace "Before splice:";
3637             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3638             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3639             trace "i  =[", $i, "]", $r->[$i];
3640             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3641             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3642         }
3643
3644         my @return = splice @$r, $splice_start, $length, @replacement;
3645
3646         if (main::DEBUG && $to_trace) {
3647             trace "After splice:";
3648             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3649             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3650             trace "i  =[", $i, "]", $r->[$i];
3651             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3652             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3653             trace "removed @return";
3654         }
3655
3656         # An actual deletion could have changed the maximum in the list.
3657         # There was no deletion if the splice didn't return something, but
3658         # otherwise recalculate it.  This is done too rarely to worry about
3659         # performance.
3660         if ($operation eq '-' && @return) {
3661             $max{$addr} = $r->[-1]->end;
3662         }
3663         return @return;
3664     }
3665
3666     sub reset_each_range {  # reset the iterator for each_range();
3667         my $self = shift;
3668         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3669
3670         no overloading;
3671         undef $each_range_iterator{pack 'J', $self};
3672         return;
3673     }
3674
3675     sub each_range {
3676         # Iterate over each range in a range list.  Results are undefined if
3677         # the range list is changed during the iteration.
3678
3679         my $self = shift;
3680         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3681
3682         my $addr = do { no overloading; pack 'J', $self; };
3683
3684         return if $self->is_empty;
3685
3686         $each_range_iterator{$addr} = -1
3687                                 if ! defined $each_range_iterator{$addr};
3688         $each_range_iterator{$addr}++;
3689         return $ranges{$addr}->[$each_range_iterator{$addr}]
3690                         if $each_range_iterator{$addr} < @{$ranges{$addr}};
3691         undef $each_range_iterator{$addr};
3692         return;
3693     }
3694
3695     sub count {        # Returns count of code points in range list
3696         my $self = shift;
3697         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3698
3699         my $addr = do { no overloading; pack 'J', $self; };
3700
3701         my $count = 0;
3702         foreach my $range (@{$ranges{$addr}}) {
3703             $count += $range->end - $range->start + 1;
3704         }
3705         return $count;
3706     }
3707
3708     sub delete_range {    # Delete a range
3709         my $self = shift;
3710         my $start = shift;
3711         my $end = shift;
3712
3713         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3714
3715         return $self->_add_delete('-', $start, $end, "");
3716     }
3717
3718     sub is_empty { # Returns boolean as to if a range list is empty
3719         my $self = shift;
3720         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3721
3722         no overloading;
3723         return scalar @{$ranges{pack 'J', $self}} == 0;
3724     }
3725
3726     sub hash {
3727         # Quickly returns a scalar suitable for separating tables into
3728         # buckets, i.e. it is a hash function of the contents of a table, so
3729         # there are relatively few conflicts.
3730
3731         my $self = shift;
3732         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3733
3734         my $addr = do { no overloading; pack 'J', $self; };
3735
3736         # These are quickly computable.  Return looks like 'min..max;count'
3737         return $self->min . "..$max{$addr};" . scalar @{$ranges{$addr}};
3738     }
3739 } # End closure for _Range_List_Base
3740
3741 package Range_List;
3742 use base '_Range_List_Base';
3743
3744 # A Range_List is a range list for match tables; i.e. the range values are
3745 # not significant.  Thus a number of operations can be safely added to it,
3746 # such as inversion, intersection.  Note that union is also an unsafe
3747 # operation when range values are cared about, and that method is in the base
3748 # class, not here.  But things are set up so that that method is callable only
3749 # during initialization.  Only in this derived class, is there an operation
3750 # that combines two tables.  A Range_Map can thus be used to initialize a
3751 # Range_List, and its mappings will be in the list, but are not significant to
3752 # this class.
3753
3754 sub trace { return main::trace(@_); }
3755
3756 { # Closure
3757
3758     use overload
3759         fallback => 0,
3760         '+' => sub { my $self = shift;
3761                     my $other = shift;
3762
3763                     return $self->_union($other)
3764                 },
3765         '&' => sub { my $self = shift;
3766                     my $other = shift;
3767
3768                     return $self->_intersect($other, 0);
3769                 },
3770         '~' => "_invert",
3771         '-' => "_subtract",
3772     ;
3773
3774     sub _invert {
3775         # Returns a new Range_List that gives all code points not in $self.
3776
3777         my $self = shift;
3778
3779         my $new = Range_List->new;
3780
3781         # Go through each range in the table, finding the gaps between them
3782         my $max = -1;   # Set so no gap before range beginning at 0
3783         for my $range ($self->ranges) {
3784             my $start = $range->start;
3785             my $end   = $range->end;
3786
3787             # If there is a gap before this range, the inverse will contain
3788             # that gap.
3789             if ($start > $max + 1) {
3790                 $new->add_range($max + 1, $start - 1);
3791             }
3792             $max = $end;
3793         }
3794
3795         # And finally, add the gap from the end of the table to the max
3796         # possible code point
3797         if ($max < $LAST_UNICODE_CODEPOINT) {
3798             $new->add_range($max + 1, $LAST_UNICODE_CODEPOINT);
3799         }
3800         return $new;
3801     }
3802
3803     sub _subtract {
3804         # Returns a new Range_List with the argument deleted from it.  The
3805         # argument can be a single code point, a range, or something that has
3806         # a range, with the _range_list() method on it returning them
3807
3808         my $self = shift;
3809         my $other = shift;
3810         my $reversed = shift;
3811         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3812
3813         if ($reversed) {
3814             Carp::my_carp_bug("Can't cope with a "
3815              .  __PACKAGE__
3816              . " being the second parameter in a '-'.  Subtraction ignored.");
3817             return $self;
3818         }
3819
3820         my $new = Range_List->new(Initialize => $self);
3821
3822         if (! ref $other) { # Single code point
3823             $new->delete_range($other, $other);
3824         }
3825         elsif ($other->isa('Range')) {
3826             $new->delete_range($other->start, $other->end);
3827         }
3828         elsif ($other->can('_range_list')) {
3829             foreach my $range ($other->_range_list->ranges) {
3830                 $new->delete_range($range->start, $range->end);
3831             }
3832         }
3833         else {
3834             Carp::my_carp_bug("Can't cope with a "
3835                         . ref($other)
3836                         . " argument to '-'.  Subtraction ignored."
3837                         );
3838             return $self;
3839         }
3840
3841         return $new;
3842     }
3843
3844     sub _intersect {
3845         # Returns either a boolean giving whether the two inputs' range lists
3846         # intersect (overlap), or a new Range_List containing the intersection
3847         # of the two lists.  The optional final parameter being true indicates
3848         # to do the check instead of the intersection.
3849
3850         my $a_object = shift;
3851         my $b_object = shift;
3852         my $check_if_overlapping = shift;
3853         $check_if_overlapping = 0 unless defined $check_if_overlapping;
3854         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3855
3856         if (! defined $b_object) {
3857             my $message = "";
3858             $message .= $a_object->_owner_name_of if defined $a_object;
3859             Carp::my_carp_bug($message .= "Called with undefined value.  Intersection not done.");
3860             return;
3861         }
3862
3863         # a & b = !(!a | !b), or in our terminology = ~ ( ~a + -b )
3864         # Thus the intersection could be much more simply be written:
3865         #   return ~(~$a_object + ~$b_object);
3866         # But, this is slower, and when taking the inverse of a large
3867         # range_size_1 table, back when such tables were always stored that
3868         # way, it became prohibitively slow, hence the code was changed to the
3869         # below
3870
3871         if ($b_object->isa('Range')) {
3872             $b_object = Range_List->new(Initialize => $b_object,
3873                                         Owner => $a_object->_owner_name_of);
3874         }
3875         $b_object = $b_object->_range_list if $b_object->can('_range_list');
3876
3877         my @a_ranges = $a_object->ranges;
3878         my @b_ranges = $b_object->ranges;
3879
3880         #local $to_trace = 1 if main::DEBUG;
3881         trace "intersecting $a_object with ", scalar @a_ranges, "ranges and $b_object with", scalar @b_ranges, " ranges" if main::DEBUG && $to_trace;
3882
3883         # Start with the first range in each list
3884         my $a_i = 0;
3885         my $range_a = $a_ranges[$a_i];
3886         my $b_i = 0;
3887         my $range_b = $b_ranges[$b_i];
3888
3889         my $new = __PACKAGE__->new(Owner => $a_object->_owner_name_of)
3890                                                 if ! $check_if_overlapping;
3891
3892         # If either list is empty, there is no intersection and no overlap
3893         if (! defined $range_a || ! defined $range_b) {
3894             return $check_if_overlapping ? 0 : $new;
3895         }
3896         trace "range_a[$a_i]=$range_a; range_b[$b_i]=$range_b" if main::DEBUG && $to_trace;
3897
3898         # Otherwise, must calculate the intersection/overlap.  Start with the
3899         # very first code point in each list
3900         my $a = $range_a->start;
3901         my $b = $range_b->start;
3902
3903         # Loop through all the ranges of each list; in each iteration, $a and
3904         # $b are the current code points in their respective lists
3905         while (1) {
3906
3907             # If $a and $b are the same code point, ...
3908             if ($a == $b) {
3909
3910                 # it means the lists overlap.  If just checking for overlap
3911                 # know the answer now,
3912                 return 1 if $check_if_overlapping;
3913
3914                 # The intersection includes this code point plus anything else
3915                 # common to both current ranges.
3916                 my $start = $a;
3917                 my $end = main::min($range_a->end, $range_b->end);
3918                 if (! $check_if_overlapping) {
3919                     trace "adding intersection range ", sprintf("%04X", $start) . ".." . sprintf("%04X", $end) if main::DEBUG && $to_trace;
3920                     $new->add_range($start, $end);
3921                 }
3922
3923                 # Skip ahead to the end of the current intersect
3924                 $a = $b = $end;
3925
3926                 # If the current intersect ends at the end of either range (as
3927                 # it must for at least one of them), the next possible one
3928                 # will be the beginning code point in it's list's next range.
3929                 if ($a == $range_a->end) {
3930                     $range_a = $a_ranges[++$a_i];
3931                     last unless defined $range_a;
3932                     $a = $range_a->start;
3933                 }
3934                 if ($b == $range_b->end) {
3935                     $range_b = $b_ranges[++$b_i];
3936                     last unless defined $range_b;
3937                     $b = $range_b->start;
3938                 }
3939
3940                 trace "range_a[$a_i]=$range_a; range_b[$b_i]=$range_b" if main::DEBUG && $to_trace;
3941             }
3942             elsif ($a < $b) {
3943
3944                 # Not equal, but if the range containing $a encompasses $b,
3945                 # change $a to be the middle of the range where it does equal
3946                 # $b, so the next iteration will get the intersection
3947                 if ($range_a->end >= $b) {
3948                     $a = $b;
3949                 }
3950                 else {
3951
3952                     # Here, the current range containing $a is entirely below
3953                     # $b.  Go try to find a range that could contain $b.
3954                     $a_i = $a_object->_search_ranges($b);
3955
3956                     # If no range found, quit.
3957                     last unless defined $a_i;
3958
3959                     # The search returns $a_i, such that
3960                     #   range_a[$a_i-1]->end < $b <= range_a[$a_i]->end
3961                     # Set $a to the beginning of this new range, and repeat.
3962                     $range_a = $a_ranges[$a_i];
3963                     $a = $range_a->start;
3964                 }
3965             }
3966             else { # Here, $b < $a.
3967
3968                 # Mirror image code to the leg just above
3969                 if ($range_b->end >= $a) {
3970                     $b = $a;
3971                 }
3972                 else {
3973                     $b_i = $b_object->_search_ranges($a);
3974                     last unless defined $b_i;
3975                     $range_b = $b_ranges[$b_i];
3976                     $b = $range_b->start;
3977                 }
3978             }
3979         } # End of looping through ranges.
3980
3981         # Intersection fully computed, or now know that there is no overlap
3982         return $check_if_overlapping ? 0 : $new;
3983     }
3984
3985     sub overlaps {
3986         # Returns boolean giving whether the two arguments overlap somewhere
3987
3988        &