This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Move all the generated file header printing into read_only_top()
[perl5.git] / regen / regen_lib.pl
1 #!/usr/bin/perl -w
2 use strict;
3 use vars qw($Needs_Write $Verbose @Changed $TAP);
4 use File::Compare;
5 use Symbol;
6 use Text::Wrap;
7
8 # Common functions needed by the regen scripts
9
10 $Needs_Write = $^O eq 'cygwin' || $^O eq 'os2' || $^O eq 'MSWin32';
11
12 $Verbose = 0;
13 @ARGV = grep { not($_ eq '-q' and $Verbose = -1) }
14   grep { not($_ eq '--tap' and $TAP = 1) }
15   grep { not($_ eq '-v' and $Verbose = 1) } @ARGV;
16
17 END {
18   print STDOUT "Changed: @Changed\n" if @Changed;
19 }
20
21 sub safer_unlink {
22   my @names = @_;
23   my $cnt = 0;
24
25   my $name;
26   foreach $name (@names) {
27     next unless -e $name;
28     chmod 0777, $name if $Needs_Write;
29     ( CORE::unlink($name) and ++$cnt
30       or warn "Couldn't unlink $name: $!\n" );
31   }
32   return $cnt;
33 }
34
35 sub safer_rename_silent {
36   my ($from, $to) = @_;
37
38   # Some dosish systems can't rename over an existing file:
39   safer_unlink $to;
40   chmod 0600, $from if $Needs_Write;
41   rename $from, $to;
42 }
43
44 sub rename_if_different {
45   my ($from, $to) = @_;
46
47   if ($TAP) {
48       my $not = compare($from, $to) ? 'not ' : '';
49       print STDOUT $not . "ok - $0 $to\n";
50       safer_unlink($from);
51       return;
52   }
53   if (compare($from, $to) == 0) {
54       warn "no changes between '$from' & '$to'\n" if $Verbose > 0;
55       safer_unlink($from);
56       return;
57   }
58   warn "changed '$from' to '$to'\n" if $Verbose > 0;
59   push @Changed, $to unless $Verbose < 0;
60   safer_rename_silent($from, $to) or die "renaming $from to $to: $!";
61 }
62
63 # Saf*er*, but not totally safe. And assumes always open for output.
64 sub safer_open {
65     my $name = shift;
66     my $fh = gensym;
67     open $fh, ">$name" or die "Can't create $name: $!";
68     *{$fh}->{SCALAR} = $name;
69     binmode $fh;
70     $fh;
71 }
72
73 sub safer_close {
74     my $fh = shift;
75     close $fh or die 'Error closing ' . *{$fh}->{SCALAR} . ": $!";
76 }
77
78 sub read_only_top {
79     my %args = @_;
80     die "Missing language argument" unless defined $args{lang};
81     die "Unknown language argument '$args{lang}'"
82         unless $args{lang} eq 'Perl' or $args{lang} eq 'C';
83     my $style = $args{style} ? " $args{style} " : '   ';
84
85     my $raw = "-*- buffer-read-only: t -*-\n";
86
87     if ($args{file}) {
88         $raw .= "\n   $args{file}\n";
89     }
90     if ($args{copyright}) {
91         local $" = ', ';
92         local $Text::Wrap::columns = 75;
93         $raw .= wrap('   ', '   ', <<"EOM") . "\n";
94
95 Copyright (C) @{$args{copyright}} by\0Larry\0Wall\0and\0others
96
97 You may distribute under the terms of either the GNU General Public
98 License or the Artistic License, as specified in the README file.
99 EOM
100     }
101
102     $raw .= "!!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!\n";
103
104     if ($args{by}) {
105         $raw .= "This file is built by $args{by}";
106         if ($args{from}) {
107             my @from = ref $args{from} eq 'ARRAY' ? @{$args{from}} : $args{from};
108             my $last = pop @from;
109             if (@from) {
110                 $raw .= ' from ' . join (', ', @from) . " and $last";
111             } else {
112                 $raw .= " from $last";
113             }
114         }
115         $raw .= ".\n";
116     }
117     $raw .= "Any changes made here will be lost!\n";
118     $raw .= $args{final} if $args{final};
119
120     local $Text::Wrap::columns = 78;
121     my $cooked = $args{lang} eq 'Perl'
122         ? wrap('# ', '# ', $raw) . "\n" : wrap('/* ', $style, $raw) . " */\n\n";
123     $cooked =~ tr/\0/ /; # Don't break Larry's name etc
124     $cooked =~ s/ +$//mg; # Remove all trailing spaces
125     return $cooked;
126 }
127
128 1;