This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
mktables: Add comment
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25 require 5.010_001;
26 use strict;
27 use warnings;
28 use Carp;
29 use Config;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34 use re "/aa";
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 sub NON_ASCII_PLATFORM { ord("A") != 65 }
40
41 ##########################################################################
42 #
43 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
44 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
45 # a pod file and .t files, depending on option parameters.
46 #
47 # The structure of this file is:
48 #   First these introductory comments; then
49 #   code needed for everywhere, such as debugging stuff; then
50 #   code to handle input parameters; then
51 #   data structures likely to be of external interest (some of which depend on
52 #       the input parameters, so follows them; then
53 #   more data structures and subroutine and package (class) definitions; then
54 #   the small actual loop to process the input files and finish up; then
55 #   a __DATA__ section, for the .t tests
56 #
57 # This program works on all releases of Unicode so far.  The outputs have been
58 # scrutinized most intently for release 5.1.  The others have been checked for
59 # somewhat more than just sanity.  It can handle all non-provisional Unicode
60 # character properties in those releases.
61 #
62 # This program is mostly about Unicode character (or code point) properties.
63 # A property describes some attribute or quality of a code point, like if it
64 # is lowercase or not, its name, what version of Unicode it was first defined
65 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
66 # possibilities by making all properties into mappings from each code point
67 # into some corresponding value.  In the case of it being lowercase or not,
68 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
69 # property maps each Unicode code point to a single value, called a "property
70 # value".  (Some more recently defined properties, map a code point to a set
71 # of values.)
72 #
73 # When using a property in a regular expression, what is desired isn't the
74 # mapping of the code point to its property's value, but the reverse (or the
75 # mathematical "inverse relation"): starting with the property value, "Does a
76 # code point map to it?"  These are written in a "compound" form:
77 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
78 # files containing the lists of code points that map to each such regular
79 # expression property value, one file per list
80 #
81 # There is also a single form shortcut that Perl adds for many of the commonly
82 # used properties.  This happens for all binary properties, plus script,
83 # general_category, and block properties.
84 #
85 # Thus the outputs of this program are files.  There are map files, mostly in
86 # the 'To' directory; and there are list files for use in regular expression
87 # matching, all in subdirectories of the 'lib' directory, with each
88 # subdirectory being named for the property that the lists in it are for.
89 # Bookkeeping, test, and documentation files are also generated.
90
91 my $matches_directory = 'lib';   # Where match (\p{}) files go.
92 my $map_directory = 'To';        # Where map files go.
93
94 # DATA STRUCTURES
95 #
96 # The major data structures of this program are Property, of course, but also
97 # Table.  There are two kinds of tables, very similar to each other.
98 # "Match_Table" is the data structure giving the list of code points that have
99 # a particular property value, mentioned above.  There is also a "Map_Table"
100 # data structure which gives the property's mapping from code point to value.
101 # There are two structures because the match tables need to be combined in
102 # various ways, such as constructing unions, intersections, complements, etc.,
103 # and the map ones don't.  And there would be problems, perhaps subtle, if
104 # a map table were inadvertently operated on in some of those ways.
105 # The use of separate classes with operations defined on one but not the other
106 # prevents accidentally confusing the two.
107 #
108 # At the heart of each table's data structure is a "Range_List", which is just
109 # an ordered list of "Ranges", plus ancillary information, and methods to
110 # operate on them.  A Range is a compact way to store property information.
111 # Each range has a starting code point, an ending code point, and a value that
112 # is meant to apply to all the code points between the two end points,
113 # inclusive.  For a map table, this value is the property value for those
114 # code points.  Two such ranges could be written like this:
115 #   0x41 .. 0x5A, 'Upper',
116 #   0x61 .. 0x7A, 'Lower'
117 #
118 # Each range also has a type used as a convenience to classify the values.
119 # Most ranges in this program will be Type 0, or normal, but there are some
120 # ranges that have a non-zero type.  These are used only in map tables, and
121 # are for mappings that don't fit into the normal scheme of things.  Mappings
122 # that require a hash entry to communicate with utf8.c are one example;
123 # another example is mappings for charnames.pm to use which indicate a name
124 # that is algorithmically determinable from its code point (and the reverse).
125 # These are used to significantly compact these tables, instead of listing
126 # each one of the tens of thousands individually.
127 #
128 # In a match table, the value of a range is irrelevant (and hence the type as
129 # well, which will always be 0), and arbitrarily set to the null string.
130 # Using the example above, there would be two match tables for those two
131 # entries, one named Upper would contain the 0x41..0x5A range, and the other
132 # named Lower would contain 0x61..0x7A.
133 #
134 # Actually, there are two types of range lists, "Range_Map" is the one
135 # associated with map tables, and "Range_List" with match tables.
136 # Again, this is so that methods can be defined on one and not the others so
137 # as to prevent operating on them in incorrect ways.
138 #
139 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
140 # in the perl core.  All tables could in theory be written, but some are
141 # suppressed because there is no current practical use for them.  It is easy
142 # to change which get written by changing various lists that are near the top
143 # of the actual code in this file.  The table data structures contain enough
144 # ancillary information to allow them to be treated as separate entities for
145 # writing, such as the path to each one's file.  There is a heading in each
146 # map table that gives the format of its entries, and what the map is for all
147 # the code points missing from it.  (This allows tables to be more compact.)
148 #
149 # The Property data structure contains one or more tables.  All properties
150 # contain a map table (except the $perl property which is a
151 # pseudo-property containing only match tables), and any properties that
152 # are usable in regular expression matches also contain various matching
153 # tables, one for each value the property can have.  A binary property can
154 # have two values, True and False (or Y and N, which are preferred by Unicode
155 # terminology).  Thus each of these properties will have a map table that
156 # takes every code point and maps it to Y or N (but having ranges cuts the
157 # number of entries in that table way down), and two match tables, one
158 # which has a list of all the code points that map to Y, and one for all the
159 # code points that map to N.  (For each binary property, a third table is also
160 # generated for the pseudo Perl property.  It contains the identical code
161 # points as the Y table, but can be written in regular expressions, not in the
162 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
163 # properties are binary, but some properties have several possible values,
164 # some have many, and properties like Name have a different value for every
165 # named code point.  Those will not, unless the controlling lists are changed,
166 # have their match tables written out.  But all the ones which can be used in
167 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
168 # a property would have either its map table or its match tables written but
169 # not both.  Again, what gets written is controlled by lists which can easily
170 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
171 # tables needed to reconstruct the Unicode db are now written out, while
172 # suppressing the Unicode .txt files that contain the data.  Our tables are
173 # much more compact than the .txt files, so a significant space savings was
174 # achieved.  Also, tables are not written out that are trivially derivable
175 # from tables that do get written.  So, there typically is no file containing
176 # the code points not matched by a binary property (the table for \P{} versus
177 # lowercase \p{}), since you just need to invert the True table to get the
178 # False table.
179
180 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
181 # how many match tables there are and the content of the maps.  This 'Type' is
182 # different than a range 'Type', so don't get confused by the two concepts
183 # having the same name.
184 #
185 # For information about the Unicode properties, see Unicode's UAX44 document:
186
187 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
188
189 # As stated earlier, this program will work on any release of Unicode so far.
190 # Most obvious problems in earlier data have NOT been corrected except when
191 # necessary to make Perl or this program work reasonably, and to keep out
192 # potential security issues.  For example, no folding information was given in
193 # early releases, so this program substitutes lower case instead, just so that
194 # a regular expression with the /i option will do something that actually
195 # gives the right results in many cases.  There are also a couple other
196 # corrections for version 1.1.5, commented at the point they are made.  As an
197 # example of corrections that weren't made (but could be) is this statement
198 # from DerivedAge.txt: "The supplementary private use code points and the
199 # non-character code points were assigned in version 2.0, but not specifically
200 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
201 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
202 # further down in these introductory comments.
203 #
204 # This program works on all non-provisional properties as of the current
205 # Unicode release, though the files for some are suppressed for various
206 # reasons.  You can change which are output by changing lists in this program.
207 #
208 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
209 # loose matchings rules (from Unicode TR18):
210 #
211 #    The recommended names for UCD properties and property values are in
212 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
213 #    [PropValue]. There are both abbreviated names and longer, more
214 #    descriptive names. It is strongly recommended that both names be
215 #    recognized, and that loose matching of property names be used,
216 #    whereby the case distinctions, whitespace, hyphens, and underbar
217 #    are ignored.
218 #
219 # The program still allows Fuzzy to override its determination of if loose
220 # matching should be used, but it isn't currently used, as it is no longer
221 # needed; the calculations it makes are good enough.
222 #
223 # SUMMARY OF HOW IT WORKS:
224 #
225 #   Process arguments
226 #
227 #   A list is constructed containing each input file that is to be processed
228 #
229 #   Each file on the list is processed in a loop, using the associated handler
230 #   code for each:
231 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
232 #            first.  These files name the properties and property values.
233 #            Objects are created of all the property and property value names
234 #            that the rest of the input should expect, including all synonyms.
235 #        The other input files give mappings from properties to property
236 #           values.  That is, they list code points and say what the mapping
237 #           is under the given property.  Some files give the mappings for
238 #           just one property; and some for many.  This program goes through
239 #           each file and populates the properties and their map tables from
240 #           them.  Some properties are listed in more than one file, and
241 #           Unicode has set up a precedence as to which has priority if there
242 #           is a conflict.  Thus the order of processing matters, and this
243 #           program handles the conflict possibility by processing the
244 #           overriding input files last, so that if necessary they replace
245 #           earlier values.
246 #        After this is all done, the program creates the property mappings not
247 #            furnished by Unicode, but derivable from what it does give.
248 #        The tables of code points that match each property value in each
249 #            property that is accessible by regular expressions are created.
250 #        The Perl-defined properties are created and populated.  Many of these
251 #            require data determined from the earlier steps
252 #        Any Perl-defined synonyms are created, and name clashes between Perl
253 #            and Unicode are reconciled and warned about.
254 #        All the properties are written to files
255 #        Any other files are written, and final warnings issued.
256 #
257 # For clarity, a number of operators have been overloaded to work on tables:
258 #   ~ means invert (take all characters not in the set).  The more
259 #       conventional '!' is not used because of the possibility of confusing
260 #       it with the actual boolean operation.
261 #   + means union
262 #   - means subtraction
263 #   & means intersection
264 # The precedence of these is the order listed.  Parentheses should be
265 # copiously used.  These are not a general scheme.  The operations aren't
266 # defined for a number of things, deliberately, to avoid getting into trouble.
267 # Operations are done on references and affect the underlying structures, so
268 # that the copy constructors for them have been overloaded to not return a new
269 # clone, but the input object itself.
270 #
271 # The bool operator is deliberately not overloaded to avoid confusion with
272 # "should it mean if the object merely exists, or also is non-empty?".
273 #
274 # WHY CERTAIN DESIGN DECISIONS WERE MADE
275 #
276 # This program needs to be able to run under miniperl.  Therefore, it uses a
277 # minimum of other modules, and hence implements some things itself that could
278 # be gotten from CPAN
279 #
280 # This program uses inputs published by the Unicode Consortium.  These can
281 # change incompatibly between releases without the Perl maintainers realizing
282 # it.  Therefore this program is now designed to try to flag these.  It looks
283 # at the directories where the inputs are, and flags any unrecognized files.
284 # It keeps track of all the properties in the files it handles, and flags any
285 # that it doesn't know how to handle.  It also flags any input lines that
286 # don't match the expected syntax, among other checks.
287 #
288 # It is also designed so if a new input file matches one of the known
289 # templates, one hopefully just needs to add it to a list to have it
290 # processed.
291 #
292 # As mentioned earlier, some properties are given in more than one file.  In
293 # particular, the files in the extracted directory are supposedly just
294 # reformattings of the others.  But they contain information not easily
295 # derivable from the other files, including results for Unihan, which this
296 # program doesn't ordinarily look at, and for unassigned code points.  They
297 # also have historically had errors or been incomplete.  In an attempt to
298 # create the best possible data, this program thus processes them first to
299 # glean information missing from the other files; then processes those other
300 # files to override any errors in the extracted ones.  Much of the design was
301 # driven by this need to store things and then possibly override them.
302 #
303 # It tries to keep fatal errors to a minimum, to generate something usable for
304 # testing purposes.  It always looks for files that could be inputs, and will
305 # warn about any that it doesn't know how to handle (the -q option suppresses
306 # the warning).
307 #
308 # Why is there more than one type of range?
309 #   This simplified things.  There are some very specialized code points that
310 #   have to be handled specially for output, such as Hangul syllable names.
311 #   By creating a range type (done late in the development process), it
312 #   allowed this to be stored with the range, and overridden by other input.
313 #   Originally these were stored in another data structure, and it became a
314 #   mess trying to decide if a second file that was for the same property was
315 #   overriding the earlier one or not.
316 #
317 # Why are there two kinds of tables, match and map?
318 #   (And there is a base class shared by the two as well.)  As stated above,
319 #   they actually are for different things.  Development proceeded much more
320 #   smoothly when I (khw) realized the distinction.  Map tables are used to
321 #   give the property value for every code point (actually every code point
322 #   that doesn't map to a default value).  Match tables are used for regular
323 #   expression matches, and are essentially the inverse mapping.  Separating
324 #   the two allows more specialized methods, and error checks so that one
325 #   can't just take the intersection of two map tables, for example, as that
326 #   is nonsensical.
327 #
328 # What about 'fate' and 'status'.  The concept of a table's fate was created
329 #   late when it became clear that something more was needed.  The difference
330 #   between this and 'status' is unclean, and could be improved if someone
331 #   wanted to spend the effort.
332 #
333 # DEBUGGING
334 #
335 # This program is written so it will run under miniperl.  Occasionally changes
336 # will cause an error where the backtrace doesn't work well under miniperl.
337 # To diagnose the problem, you can instead run it under regular perl, if you
338 # have one compiled.
339 #
340 # There is a good trace facility.  To enable it, first sub DEBUG must be set
341 # to return true.  Then a line like
342 #
343 # local $to_trace = 1 if main::DEBUG;
344 #
345 # can be added to enable tracing in its lexical scope (plus dynamic) or until
346 # you insert another line:
347 #
348 # local $to_trace = 0 if main::DEBUG;
349 #
350 # To actually trace, use a line like "trace $a, @b, %c, ...;
351 #
352 # Some of the more complex subroutines already have trace statements in them.
353 # Permanent trace statements should be like:
354 #
355 # trace ... if main::DEBUG && $to_trace;
356 #
357 # If there is just one or a few files that you're debugging, you can easily
358 # cause most everything else to be skipped.  Change the line
359 #
360 # my $debug_skip = 0;
361 #
362 # to 1, and every file whose object is in @input_file_objects and doesn't have
363 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
364 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
365 #
366 # To compare the output tables, it may be useful to specify the -annotate
367 # flag.  (As of this writing, this can't be done on a clean workspace, due to
368 # requirements in Text::Tabs used in this option; so first run mktables
369 # without this option.)  This option adds comment lines to each table, one for
370 # each non-algorithmically named character giving, currently its code point,
371 # name, and graphic representation if printable (and you have a font that
372 # knows about it).  This makes it easier to see what the particular code
373 # points are in each output table.  Non-named code points are annotated with a
374 # description of their status, and contiguous ones with the same description
375 # will be output as a range rather than individually.  Algorithmically named
376 # characters are also output as ranges, except when there are just a few
377 # contiguous ones.
378 #
379 # FUTURE ISSUES
380 #
381 # The program would break if Unicode were to change its names so that
382 # interior white space, underscores, or dashes differences were significant
383 # within property and property value names.
384 #
385 # It might be easier to use the xml versions of the UCD if this program ever
386 # would need heavy revision, and the ability to handle old versions was not
387 # required.
388 #
389 # There is the potential for name collisions, in that Perl has chosen names
390 # that Unicode could decide it also likes.  There have been such collisions in
391 # the past, with mostly Perl deciding to adopt the Unicode definition of the
392 # name.  However in the 5.2 Unicode beta testing, there were a number of such
393 # collisions, which were withdrawn before the final release, because of Perl's
394 # and other's protests.  These all involved new properties which began with
395 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
396 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
397 # Unicode document, so they are unlikely to be used by Unicode for another
398 # purpose.  However, they might try something beginning with 'In', or use any
399 # of the other Perl-defined properties.  This program will warn you of name
400 # collisions, and refuse to generate tables with them, but manual intervention
401 # will be required in this event.  One scheme that could be implemented, if
402 # necessary, would be to have this program generate another file, or add a
403 # field to mktables.lst that gives the date of first definition of a property.
404 # Each new release of Unicode would use that file as a basis for the next
405 # iteration.  And the Perl synonym addition code could sort based on the age
406 # of the property, so older properties get priority, and newer ones that clash
407 # would be refused; hence existing code would not be impacted, and some other
408 # synonym would have to be used for the new property.  This is ugly, and
409 # manual intervention would certainly be easier to do in the short run; lets
410 # hope it never comes to this.
411 #
412 # A NOTE ON UNIHAN
413 #
414 # This program can generate tables from the Unihan database.  But it doesn't
415 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
416 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
417 # database was split into 8 different files, all beginning with the letters
418 # 'Unihan'.  This program will read those file(s) if present, but it needs to
419 # know which of the many properties in the file(s) should have tables created
420 # for them.  It will create tables for any properties listed in
421 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
422 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
423 # property you want is not in those files of the release you are building
424 # against, you must add it to those two arrays.  Starting in 4.0, the
425 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
426 # is present in the directory, a table will be generated for that property.
427 # In 5.2, several more properties were added.  For your convenience, the two
428 # arrays are initialized with all the 6.0 listed properties that are also in
429 # earlier releases.  But these are commented out.  You can just uncomment the
430 # ones you want, or use them as a template for adding entries for other
431 # properties.
432 #
433 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
434 # and filter_unihan_line() are the functions where this is done.  This program
435 # already does some adjusting to make the lines look more like the rest of the
436 # Unicode DB;  You can see what that is in filter_unihan_line()
437 #
438 # There is a bug in the 3.2 data file in which some values for the
439 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
440 # could be added for these; or for a particular installation, the Unihan.txt
441 # file could be edited to fix them.
442 #
443 # HOW TO ADD A FILE TO BE PROCESSED
444 #
445 # A new file from Unicode needs to have an object constructed for it in
446 # @input_file_objects, probably at the end or at the end of the extracted
447 # ones.  The program should warn you if its name will clash with others on
448 # restrictive file systems, like DOS.  If so, figure out a better name, and
449 # add lines to the README.perl file giving that.  If the file is a character
450 # property, it should be in the format that Unicode has implicitly
451 # standardized for such files for the more recently introduced ones.
452 # If so, the Input_file constructor for @input_file_objects can just be the
453 # file name and release it first appeared in.  If not, then it should be
454 # possible to construct an each_line_handler() to massage the line into the
455 # standardized form.
456 #
457 # For non-character properties, more code will be needed.  You can look at
458 # the existing entries for clues.
459 #
460 # UNICODE VERSIONS NOTES
461 #
462 # The Unicode UCD has had a number of errors in it over the versions.  And
463 # these remain, by policy, in the standard for that version.  Therefore it is
464 # risky to correct them, because code may be expecting the error.  So this
465 # program doesn't generally make changes, unless the error breaks the Perl
466 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
467 # for U+1105, which causes real problems for the algorithms for Jamo
468 # calculations, so it is changed here.
469 #
470 # But it isn't so clear cut as to what to do about concepts that are
471 # introduced in a later release; should they extend back to earlier releases
472 # where the concept just didn't exist?  It was easier to do this than to not,
473 # so that's what was done.  For example, the default value for code points not
474 # in the files for various properties was probably undefined until changed by
475 # some version.  No_Block for blocks is such an example.  This program will
476 # assign No_Block even in Unicode versions that didn't have it.  This has the
477 # benefit that code being written doesn't have to special case earlier
478 # versions; and the detriment that it doesn't match the Standard precisely for
479 # the affected versions.
480 #
481 # Here are some observations about some of the issues in early versions:
482 #
483 # Prior to version 3.0, there were 3 character decompositions.  These are not
484 # handled by Unicode::Normalize, nor will it compile when presented a version
485 # that has them.  However, you can trivially get it to compile by simply
486 # ignoring those decompositions, by changing the croak to a carp.  At the time
487 # of this writing, the line (in cpan/Unicode-Normalize/mkheader) reads
488 #
489 #   croak("Weird Canonical Decomposition of U+$h");
490 #
491 # Simply change to a carp.  It will compile, but will not know about any three
492 # character decomposition.
493
494 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
495 # that the reason is that the CJK block starting at 4E00 was removed from
496 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
497 # single property name \p{alpha}) has the correct values.  But the compound
498 # form is simply not generated until 3.1, as it can be argued that prior to
499 # this release, this was not an official property.  The comments for
500 # filter_old_style_proplist() give more details.
501 #
502 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
503 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
504 # reason is that 3.2 introduced U+205F=medium math space, which was not
505 # classed as white space, but Perl figured out that it should have been. 4.0
506 # reclassified it correctly.
507 #
508 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
509 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
510 # became 202, and ATBL was left with no code points, as all the ones that
511 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
512 # name for the class, it would not have been affected, but if it used the
513 # mnemonic, it would have been.
514 #
515 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
516 # points which eventually came to have this script property value, instead
517 # mapped to "Unknown".  But in the next release all these code points were
518 # moved to \p{sc=common} instead.
519 #
520 # The default for missing code points for BidiClass is complicated.  Starting
521 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
522 # tries to do the best it can for earlier releases.  It is done in
523 # process_PropertyAliases()
524 #
525 # In version 2.1.2, the entry in UnicodeData.txt:
526 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
527 # should instead be
528 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
529 # Without this change, there are casing problems for this character.
530 #
531 # Search for $string_compare_versions to see how to compare changes to
532 # properties between Unicode versions
533 #
534 ##############################################################################
535
536 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
537                         # and errors
538 my $MAX_LINE_WIDTH = 78;
539
540 # Debugging aid to skip most files so as to not be distracted by them when
541 # concentrating on the ones being debugged.  Add
542 # non_skip => 1,
543 # to the constructor for those files you want processed when you set this.
544 # Files with a first version number of 0 are special: they are always
545 # processed regardless of the state of this flag.  Generally, Jamo.txt and
546 # UnicodeData.txt must not be skipped if you want this program to not die
547 # before normal completion.
548 my $debug_skip = 0;
549
550
551 # Normally these are suppressed.
552 my $write_Unicode_deprecated_tables = 0;
553
554 # Set to 1 to enable tracing.
555 our $to_trace = 0;
556
557 { # Closure for trace: debugging aid
558     my $print_caller = 1;        # ? Include calling subroutine name
559     my $main_with_colon = 'main::';
560     my $main_colon_length = length($main_with_colon);
561
562     sub trace {
563         return unless $to_trace;        # Do nothing if global flag not set
564
565         my @input = @_;
566
567         local $DB::trace = 0;
568         $DB::trace = 0;          # Quiet 'used only once' message
569
570         my $line_number;
571
572         # Loop looking up the stack to get the first non-trace caller
573         my $caller_line;
574         my $caller_name;
575         my $i = 0;
576         do {
577             $line_number = $caller_line;
578             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
579             $caller = $main_with_colon unless defined $caller;
580
581             $caller_name = $caller;
582
583             # get rid of pkg
584             $caller_name =~ s/.*:://;
585             if (substr($caller_name, 0, $main_colon_length)
586                 eq $main_with_colon)
587             {
588                 $caller_name = substr($caller_name, $main_colon_length);
589             }
590
591         } until ($caller_name ne 'trace');
592
593         # If the stack was empty, we were called from the top level
594         $caller_name = 'main' if ($caller_name eq ""
595                                     || $caller_name eq 'trace');
596
597         my $output = "";
598         foreach my $string (@input) {
599             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
600             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
601                 $output .= simple_dumper($string);
602             }
603             else {
604                 $string = "$string" if ref $string;
605                 $string = $UNDEF unless defined $string;
606                 chomp $string;
607                 $string = '""' if $string eq "";
608                 $output .= " " if $output ne ""
609                                 && $string ne ""
610                                 && substr($output, -1, 1) ne " "
611                                 && substr($string, 0, 1) ne " ";
612                 $output .= $string;
613             }
614         }
615
616         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
617         print STDERR "$caller_name: " if $print_caller;
618         print STDERR $output, "\n";
619         return;
620     }
621 }
622
623 # This is for a rarely used development feature that allows you to compare two
624 # versions of the Unicode standard without having to deal with changes caused
625 # by the code points introduced in the later version.  Change the 0 to a
626 # string containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only
627 # code points introduced in that release and earlier will be used; later ones
628 # are thrown away.  You use the version number of the earliest one you want to
629 # compare; then run this program on directory structures containing each
630 # release, and compare the outputs.  These outputs will therefore include only
631 # the code points common to both releases, and you can see the changes caused
632 # just by the underlying release semantic changes.  For versions earlier than
633 # 3.2, you must copy a version of DAge.txt into the directory.
634 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
635 my $compare_versions = DEBUG
636                        && $string_compare_versions
637                        && pack "C*", split /\./, $string_compare_versions;
638
639 sub uniques {
640     # Returns non-duplicated input values.  From "Perl Best Practices:
641     # Encapsulated Cleverness".  p. 455 in first edition.
642
643     my %seen;
644     # Arguably this breaks encapsulation, if the goal is to permit multiple
645     # distinct objects to stringify to the same value, and be interchangeable.
646     # However, for this program, no two objects stringify identically, and all
647     # lists passed to this function are either objects or strings. So this
648     # doesn't affect correctness, but it does give a couple of percent speedup.
649     no overloading;
650     return grep { ! $seen{$_}++ } @_;
651 }
652
653 $0 = File::Spec->canonpath($0);
654
655 my $make_test_script = 0;      # ? Should we output a test script
656 my $make_norm_test_script = 0; # ? Should we output a normalization test script
657 my $write_unchanged_files = 0; # ? Should we update the output files even if
658                                #    we don't think they have changed
659 my $use_directory = "";        # ? Should we chdir somewhere.
660 my $pod_directory;             # input directory to store the pod file.
661 my $pod_file = 'perluniprops';
662 my $t_path;                     # Path to the .t test file
663 my $file_list = 'mktables.lst'; # File to store input and output file names.
664                                # This is used to speed up the build, by not
665                                # executing the main body of the program if
666                                # nothing on the list has changed since the
667                                # previous build
668 my $make_list = 1;             # ? Should we write $file_list.  Set to always
669                                # make a list so that when the pumpking is
670                                # preparing a release, s/he won't have to do
671                                # special things
672 my $glob_list = 0;             # ? Should we try to include unknown .txt files
673                                # in the input.
674 my $output_range_counts = $debugging_build;   # ? Should we include the number
675                                               # of code points in ranges in
676                                               # the output
677 my $annotate = 0;              # ? Should character names be in the output
678
679 # Verbosity levels; 0 is quiet
680 my $NORMAL_VERBOSITY = 1;
681 my $PROGRESS = 2;
682 my $VERBOSE = 3;
683
684 my $verbosity = $NORMAL_VERBOSITY;
685
686 # Stored in mktables.lst so that if this program is called with different
687 # options, will regenerate even if the files otherwise look like they're
688 # up-to-date.
689 my $command_line_arguments = join " ", @ARGV;
690
691 # Process arguments
692 while (@ARGV) {
693     my $arg = shift @ARGV;
694     if ($arg eq '-v') {
695         $verbosity = $VERBOSE;
696     }
697     elsif ($arg eq '-p') {
698         $verbosity = $PROGRESS;
699         $| = 1;     # Flush buffers as we go.
700     }
701     elsif ($arg eq '-q') {
702         $verbosity = 0;
703     }
704     elsif ($arg eq '-w') {
705         $write_unchanged_files = 1; # update the files even if havent changed
706     }
707     elsif ($arg eq '-check') {
708         my $this = shift @ARGV;
709         my $ok = shift @ARGV;
710         if ($this ne $ok) {
711             print "Skipping as check params are not the same.\n";
712             exit(0);
713         }
714     }
715     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
716         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
717     }
718     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
719     {
720         $make_test_script = 1;
721     }
722     elsif ($arg eq '-makenormtest')
723     {
724         $make_norm_test_script = 1;
725     }
726     elsif ($arg eq '-makelist') {
727         $make_list = 1;
728     }
729     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
730         -d $use_directory or croak "Unknown directory '$use_directory'";
731     }
732     elsif ($arg eq '-L') {
733
734         # Existence not tested until have chdir'd
735         $file_list = shift;
736     }
737     elsif ($arg eq '-globlist') {
738         $glob_list = 1;
739     }
740     elsif ($arg eq '-c') {
741         $output_range_counts = ! $output_range_counts
742     }
743     elsif ($arg eq '-annotate') {
744         $annotate = 1;
745         $debugging_build = 1;
746         $output_range_counts = 1;
747     }
748     else {
749         my $with_c = 'with';
750         $with_c .= 'out' if $output_range_counts;   # Complements the state
751         croak <<END;
752 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
753           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
754           [-check A B ]
755   -c          : Output comments $with_c number of code points in ranges
756   -q          : Quiet Mode: Only output serious warnings.
757   -p          : Set verbosity level to normal plus show progress.
758   -v          : Set Verbosity level high:  Show progress and non-serious
759                 warnings
760   -w          : Write files regardless
761   -C dir      : Change to this directory before proceeding. All relative paths
762                 except those specified by the -P and -T options will be done
763                 with respect to this directory.
764   -P dir      : Output $pod_file file to directory 'dir'.
765   -T path     : Create a test script as 'path'; overrides -maketest
766   -L filelist : Use alternate 'filelist' instead of standard one
767   -globlist   : Take as input all non-Test *.txt files in current and sub
768                 directories
769   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
770                 overrides -T
771   -makelist   : Rewrite the file list $file_list based on current setup
772   -annotate   : Output an annotation for each character in the table files;
773                 useful for debugging mktables, looking at diffs; but is slow
774                 and memory intensive
775   -check A B  : Executes $0 only if A and B are the same
776 END
777     }
778 }
779
780 # Stores the most-recently changed file.  If none have changed, can skip the
781 # build
782 my $most_recent = (stat $0)[9];   # Do this before the chdir!
783
784 # Change directories now, because need to read 'version' early.
785 if ($use_directory) {
786     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
787         $pod_directory = File::Spec->rel2abs($pod_directory);
788     }
789     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
790         $t_path = File::Spec->rel2abs($t_path);
791     }
792     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
793     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
794         $pod_directory = File::Spec->abs2rel($pod_directory);
795     }
796     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
797         $t_path = File::Spec->abs2rel($t_path);
798     }
799 }
800
801 # Get Unicode version into regular and v-string.  This is done now because
802 # various tables below get populated based on it.  These tables are populated
803 # here to be near the top of the file, and so easily seeable by those needing
804 # to modify things.
805 open my $VERSION, "<", "version"
806                     or croak "$0: can't open required file 'version': $!\n";
807 my $string_version = <$VERSION>;
808 close $VERSION;
809 chomp $string_version;
810 my $v_version = pack "C*", split /\./, $string_version;        # v string
811
812 # The following are the complete names of properties with property values that
813 # are known to not match any code points in some versions of Unicode, but that
814 # may change in the future so they should be matchable, hence an empty file is
815 # generated for them.
816 my @tables_that_may_be_empty;
817 push @tables_that_may_be_empty, 'Joining_Type=Left_Joining'
818                                                     if $v_version lt v6.3.0;
819 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
820 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
821 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
822                                                     if $v_version ge v4.1.0;
823 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
824                                                     if $v_version ge v6.0.0;
825 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
826                                                     if $v_version ge v6.1.0;
827 push @tables_that_may_be_empty, 'Canonical_Combining_Class=CCC133'
828                                                     if $v_version ge v6.2.0;
829
830 # The lists below are hashes, so the key is the item in the list, and the
831 # value is the reason why it is in the list.  This makes generation of
832 # documentation easier.
833
834 my %why_suppressed;  # No file generated for these.
835
836 # Files aren't generated for empty extraneous properties.  This is arguable.
837 # Extraneous properties generally come about because a property is no longer
838 # used in a newer version of Unicode.  If we generated a file without code
839 # points, programs that used to work on that property will still execute
840 # without errors.  It just won't ever match (or will always match, with \P{}).
841 # This means that the logic is now likely wrong.  I (khw) think its better to
842 # find this out by getting an error message.  Just move them to the table
843 # above to change this behavior
844 my %why_suppress_if_empty_warn_if_not = (
845
846    # It is the only property that has ever officially been removed from the
847    # Standard.  The database never contained any code points for it.
848    'Special_Case_Condition' => 'Obsolete',
849
850    # Apparently never official, but there were code points in some versions of
851    # old-style PropList.txt
852    'Non_Break' => 'Obsolete',
853 );
854
855 # These would normally go in the warn table just above, but they were changed
856 # a long time before this program was written, so warnings about them are
857 # moot.
858 if ($v_version gt v3.2.0) {
859     push @tables_that_may_be_empty,
860                                 'Canonical_Combining_Class=Attached_Below_Left'
861 }
862
863 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
864 # unless explicitly added.
865 if ($v_version ge v5.2.0) {
866     my $unihan = 'Unihan; remove from list if using Unihan';
867     foreach my $table (qw (
868                            kAccountingNumeric
869                            kOtherNumeric
870                            kPrimaryNumeric
871                            kCompatibilityVariant
872                            kIICore
873                            kIRG_GSource
874                            kIRG_HSource
875                            kIRG_JSource
876                            kIRG_KPSource
877                            kIRG_MSource
878                            kIRG_KSource
879                            kIRG_TSource
880                            kIRG_USource
881                            kIRG_VSource
882                            kRSUnicode
883                         ))
884     {
885         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
886     }
887 }
888
889 # Enum values for to_output_map() method in the Map_Table package.
890 my $EXTERNAL_MAP = 1;
891 my $INTERNAL_MAP = 2;
892 my $OUTPUT_ADJUSTED = 3;
893
894 # To override computed values for writing the map tables for these properties.
895 # The default for enum map tables is to write them out, so that the Unicode
896 # .txt files can be removed, but all the data to compute any property value
897 # for any code point is available in a more compact form.
898 my %global_to_output_map = (
899     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
900     # get stuck supporting it if things change.  Since it is a STRING
901     # property, it normally would be listed in the pod, but INTERNAL_MAP
902     # suppresses that.
903     Unicode_1_Name => $INTERNAL_MAP,
904
905     Present_In => 0,                # Suppress, as easily computed from Age
906     Block => (NON_ASCII_PLATFORM) ? 1 : 0,  # Suppress, as Blocks.txt is
907                                             # retained, but needed for
908                                             # non-ASCII
909
910     # Suppress, as mapping can be found instead from the
911     # Perl_Decomposition_Mapping file
912     Decomposition_Type => 0,
913 );
914
915 # Properties that this program ignores.
916 my @unimplemented_properties;
917
918 # With this release, it is automatically handled if the Unihan db is
919 # downloaded
920 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version le v5.2.0;
921
922 # There are several types of obsolete properties defined by Unicode.  These
923 # must be hand-edited for every new Unicode release.
924 my %why_deprecated;  # Generates a deprecated warning message if used.
925 my %why_stabilized;  # Documentation only
926 my %why_obsolete;    # Documentation only
927
928 {   # Closure
929     my $simple = 'Perl uses the more complete version';
930     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
931
932     my $other_properties = 'other properties';
933     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
934     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
935
936     %why_deprecated = (
937         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
938         'Jamo_Short_Name' => $contributory,
939         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
940         'Other_Alphabetic' => $contributory,
941         'Other_Default_Ignorable_Code_Point' => $contributory,
942         'Other_Grapheme_Extend' => $contributory,
943         'Other_ID_Continue' => $contributory,
944         'Other_ID_Start' => $contributory,
945         'Other_Lowercase' => $contributory,
946         'Other_Math' => $contributory,
947         'Other_Uppercase' => $contributory,
948         'Expands_On_NFC' => $why_no_expand,
949         'Expands_On_NFD' => $why_no_expand,
950         'Expands_On_NFKC' => $why_no_expand,
951         'Expands_On_NFKD' => $why_no_expand,
952     );
953
954     %why_suppressed = (
955         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
956         # contains the same information, but without the algorithmically
957         # determinable Hangul syllables'.  This file is not published, so it's
958         # existence is not noted in the comment.
959         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or Unicode::UCD::prop_invmap()',
960
961         'Indic_Matra_Category' => "Provisional",
962         'Indic_Syllabic_Category' => "Provisional",
963
964         # Don't suppress ISO_Comment, as otherwise special handling is needed
965         # to differentiate between it and gc=c, which can be written as 'isc',
966         # which is the same characters as ISO_Comment's short name.
967
968         'Name' => "Accessible via \\N{...} or 'use charnames;' or Unicode::UCD::prop_invmap()",
969
970         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold or Unicode::UCD::prop_invmap()",
971         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
972         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
973         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
974
975         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
976     );
977
978     foreach my $property (
979
980             # The following are suppressed because they were made contributory
981             # or deprecated by Unicode before Perl ever thought about
982             # supporting them.
983             'Jamo_Short_Name',
984             'Grapheme_Link',
985             'Expands_On_NFC',
986             'Expands_On_NFD',
987             'Expands_On_NFKC',
988             'Expands_On_NFKD',
989
990             # The following are suppressed because they have been marked
991             # as deprecated for a sufficient amount of time
992             'Other_Alphabetic',
993             'Other_Default_Ignorable_Code_Point',
994             'Other_Grapheme_Extend',
995             'Other_ID_Continue',
996             'Other_ID_Start',
997             'Other_Lowercase',
998             'Other_Math',
999             'Other_Uppercase',
1000     ) {
1001         $why_suppressed{$property} = $why_deprecated{$property};
1002     }
1003
1004     # Customize the message for all the 'Other_' properties
1005     foreach my $property (keys %why_deprecated) {
1006         next if (my $main_property = $property) !~ s/^Other_//;
1007         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
1008     }
1009 }
1010
1011 if ($write_Unicode_deprecated_tables) {
1012     foreach my $property (keys %why_suppressed) {
1013         delete $why_suppressed{$property} if $property =~
1014                                                     / ^ Other | Grapheme /x;
1015     }
1016 }
1017
1018 if ($v_version ge 4.0.0) {
1019     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
1020     if ($v_version ge 6.0.0) {
1021         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
1022     }
1023 }
1024 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
1025     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
1026     if ($v_version ge 6.0.0) {
1027         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
1028     }
1029 }
1030
1031 # Probably obsolete forever
1032 if ($v_version ge v4.1.0) {
1033     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
1034 }
1035 if ($v_version ge v6.0.0) {
1036     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana" (or both)';
1037     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
1038 }
1039
1040 # This program can create files for enumerated-like properties, such as
1041 # 'Numeric_Type'.  This file would be the same format as for a string
1042 # property, with a mapping from code point to its value, so you could look up,
1043 # for example, the script a code point is in.  But no one so far wants this
1044 # mapping, or they have found another way to get it since this is a new
1045 # feature.  So no file is generated except if it is in this list.
1046 my @output_mapped_properties = split "\n", <<END;
1047 END
1048
1049 # If you are using the Unihan database in a Unicode version before 5.2, you
1050 # need to add the properties that you want to extract from it to this table.
1051 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
1052 # listed, commented out
1053 my @cjk_properties = split "\n", <<'END';
1054 #cjkAccountingNumeric; kAccountingNumeric
1055 #cjkOtherNumeric; kOtherNumeric
1056 #cjkPrimaryNumeric; kPrimaryNumeric
1057 #cjkCompatibilityVariant; kCompatibilityVariant
1058 #cjkIICore ; kIICore
1059 #cjkIRG_GSource; kIRG_GSource
1060 #cjkIRG_HSource; kIRG_HSource
1061 #cjkIRG_JSource; kIRG_JSource
1062 #cjkIRG_KPSource; kIRG_KPSource
1063 #cjkIRG_KSource; kIRG_KSource
1064 #cjkIRG_TSource; kIRG_TSource
1065 #cjkIRG_USource; kIRG_USource
1066 #cjkIRG_VSource; kIRG_VSource
1067 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
1068 END
1069
1070 # Similarly for the property values.  For your convenience, the lines in the
1071 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
1072 # '#' marks (for Unicode versions before 5.2)
1073 my @cjk_property_values = split "\n", <<'END';
1074 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1075 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
1076 ## @missing: 0000..10FFFF; cjkIICore; <none>
1077 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
1078 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
1079 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
1080 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
1081 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
1082 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
1083 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
1084 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
1085 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
1086 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1087 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1088 END
1089
1090 # The input files don't list every code point.  Those not listed are to be
1091 # defaulted to some value.  Below are hard-coded what those values are for
1092 # non-binary properties as of 5.1.  Starting in 5.0, there are
1093 # machine-parsable comment lines in the files that give the defaults; so this
1094 # list shouldn't have to be extended.  The claim is that all missing entries
1095 # for binary properties will default to 'N'.  Unicode tried to change that in
1096 # 5.2, but the beta period produced enough protest that they backed off.
1097 #
1098 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1099 # be in the form that it expects.  The others may be synonyms.
1100 my $CODE_POINT = '<code point>';
1101 my %default_mapping = (
1102     Age => "Unassigned",
1103     # Bidi_Class => Complicated; set in code
1104     Bidi_Mirroring_Glyph => "",
1105     Block => 'No_Block',
1106     Canonical_Combining_Class => 0,
1107     Case_Folding => $CODE_POINT,
1108     Decomposition_Mapping => $CODE_POINT,
1109     Decomposition_Type => 'None',
1110     East_Asian_Width => "Neutral",
1111     FC_NFKC_Closure => $CODE_POINT,
1112     General_Category => 'Cn',
1113     Grapheme_Cluster_Break => 'Other',
1114     Hangul_Syllable_Type => 'NA',
1115     ISO_Comment => "",
1116     Jamo_Short_Name => "",
1117     Joining_Group => "No_Joining_Group",
1118     # Joining_Type => Complicated; set in code
1119     kIICore => 'N',   #                       Is converted to binary
1120     #Line_Break => Complicated; set in code
1121     Lowercase_Mapping => $CODE_POINT,
1122     Name => "",
1123     Name_Alias => "",
1124     NFC_QC => 'Yes',
1125     NFD_QC => 'Yes',
1126     NFKC_QC => 'Yes',
1127     NFKD_QC => 'Yes',
1128     Numeric_Type => 'None',
1129     Numeric_Value => 'NaN',
1130     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1131     Sentence_Break => 'Other',
1132     Simple_Case_Folding => $CODE_POINT,
1133     Simple_Lowercase_Mapping => $CODE_POINT,
1134     Simple_Titlecase_Mapping => $CODE_POINT,
1135     Simple_Uppercase_Mapping => $CODE_POINT,
1136     Titlecase_Mapping => $CODE_POINT,
1137     Unicode_1_Name => "",
1138     Unicode_Radical_Stroke => "",
1139     Uppercase_Mapping => $CODE_POINT,
1140     Word_Break => 'Other',
1141 );
1142
1143 # Below are files that Unicode furnishes, but this program ignores, and why.
1144 # NormalizationCorrections.txt requires some more explanation.  It documents
1145 # the cumulative fixes to erroneous normalizations in earlier Unicode
1146 # versions.  Its main purpose is so that someone running on an earlier version
1147 # can use this file to override what got published in that earlier release.
1148 # It would be easy for mktables to read and handle this file.  But all the
1149 # corrections in it should already be in the other files for the release it
1150 # is.  To get it to actually mean something useful, someone would have to be
1151 # using an earlier Unicode release, and copy it to the files for that release
1152 # and recomplile.  So far there has been no demand to do that, so this hasn't
1153 # been implemented.
1154 my %ignored_files = (
1155     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1156     'Index.txt' => 'Alphabetical index of Unicode characters',
1157     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1158     'NamesList.txt' => 'Annotated list of characters',
1159     'NamesList.html' => 'Describes the format and contents of F<NamesList.txt>',
1160     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1161     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1162     'ReadMe.txt' => 'Documentation',
1163     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1164     'StandardizedVariants.html' => 'Provides a visual display of the standard variant sequences derived from F<StandardizedVariants.txt>.',
1165     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1166     'USourceData.txt' => 'Documentation of status and cross reference of proposals for encoding by Unicode of Unihan characters',
1167     'USourceGlyphs.pdf' => 'Pictures of the characters in F<USourceData.txt>',
1168     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1169     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1170     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1171     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1172 );
1173
1174 my %skipped_files;  # List of files that we skip
1175
1176 ### End of externally interesting definitions, except for @input_file_objects
1177
1178 my $HEADER=<<"EOF";
1179 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1180 # This file is machine-generated by $0 from the Unicode
1181 # database, Version $string_version.  Any changes made here will be lost!
1182 EOF
1183
1184 my $INTERNAL_ONLY_HEADER = <<"EOF";
1185
1186 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1187 # This file is for internal use by core Perl only.  The format and even the
1188 # name or existence of this file are subject to change without notice.  Don't
1189 # use it directly.  Use Unicode::UCD to access the Unicode character data
1190 # base.
1191 EOF
1192
1193 my $DEVELOPMENT_ONLY=<<"EOF";
1194 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1195 # This file contains information artificially constrained to code points
1196 # present in Unicode release $string_compare_versions.
1197 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1198 # not be used for production.
1199
1200 EOF
1201
1202 my $MAX_UNICODE_CODEPOINT_STRING = "10FFFF";
1203 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1204 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1205
1206 # We work with above-Unicode code points, up to UV_MAX.   But when you get
1207 # that high, above IV_MAX, some operations don't work, and you can easily get
1208 # overflow.  Therefore for internal use, we use a much smaller number,
1209 # translating it to UV_MAX only for output.  The exact number is immaterial
1210 # (all Unicode code points are treated exactly the same), but the algorithm
1211 # requires it to be at least 2 * $MAX_UNICODE_CODEPOINTS + 1;
1212 my $MAX_WORKING_CODEPOINTS= $MAX_UNICODE_CODEPOINT * 8;
1213 my $MAX_WORKING_CODEPOINT = $MAX_WORKING_CODEPOINTS - 1;
1214 my $MAX_WORKING_CODEPOINT_STRING = sprintf("%X", $MAX_WORKING_CODEPOINT);
1215
1216 my $MAX_PLATFORM_CODEPOINT = ~0;
1217
1218 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1219 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1220 # to decrease backtracking.  The first regex allows the code point to be at
1221 # the end of a word, but to work properly, the word shouldn't end with a valid
1222 # hex character.  The second one won't match a code point at the end of a
1223 # word, and doesn't have the run-on issue
1224 my $run_on_code_point_re =
1225             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1226 my $code_point_re = qr/\b$run_on_code_point_re/;
1227
1228 # This matches the beginning of the line in the Unicode db files that give the
1229 # defaults for code points not listed (i.e., missing) in the file.  The code
1230 # depends on this ending with a semi-colon, so it can assume it is a valid
1231 # field when the line is split() by semi-colons
1232 my $missing_defaults_prefix =
1233             qr/^#\s+\@missing:\s+0000\.\.$MAX_UNICODE_CODEPOINT_STRING\s*;/;
1234
1235 # Property types.  Unicode has more types, but these are sufficient for our
1236 # purposes.
1237 my $UNKNOWN = -1;   # initialized to illegal value
1238 my $NON_STRING = 1; # Either binary or enum
1239 my $BINARY = 2;
1240 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1241                        # tables, additional true and false tables are
1242                        # generated so that false is anything matching the
1243                        # default value, and true is everything else.
1244 my $ENUM = 4;       # Include catalog
1245 my $STRING = 5;     # Anything else: string or misc
1246
1247 # Some input files have lines that give default values for code points not
1248 # contained in the file.  Sometimes these should be ignored.
1249 my $NO_DEFAULTS = 0;        # Must evaluate to false
1250 my $NOT_IGNORED = 1;
1251 my $IGNORED = 2;
1252
1253 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1254 # and will appear in the main body of the tables in the output files, but
1255 # there are other types of ranges as well, listed below, that are specially
1256 # handled.   There are pseudo-types as well that will never be stored as a
1257 # type, but will affect the calculation of the type.
1258
1259 # 0 is for normal, non-specials
1260 my $MULTI_CP = 1;           # Sequence of more than code point
1261 my $HANGUL_SYLLABLE = 2;
1262 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1263 my $NULL = 4;               # The map is to the null string; utf8.c can't
1264                             # handle these, nor is there an accepted syntax
1265                             # for them in \p{} constructs
1266 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1267                              # otherwise be $MULTI_CP type are instead type 0
1268
1269 # process_generic_property_file() can accept certain overrides in its input.
1270 # Each of these must begin AND end with $CMD_DELIM.
1271 my $CMD_DELIM = "\a";
1272 my $REPLACE_CMD = 'replace';    # Override the Replace
1273 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1274
1275 my $NO = 0;
1276 my $YES = 1;
1277
1278 # Values for the Replace argument to add_range.
1279 # $NO                      # Don't replace; add only the code points not
1280                            # already present.
1281 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1282                            # the comments at the subroutine definition.
1283 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1284 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1285                            # already there
1286 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1287                            # already there
1288 my $CROAK = 6;             # Die with an error if is already there
1289
1290 # Flags to give property statuses.  The phrases are to remind maintainers that
1291 # if the flag is changed, the indefinite article referring to it in the
1292 # documentation may need to be as well.
1293 my $NORMAL = "";
1294 my $DEPRECATED = 'D';
1295 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1296 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1297 my $DISCOURAGED = 'X';
1298 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1299 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1300 my $STRICTER = 'T';
1301 my $a_bold_stricter = "a 'B<$STRICTER>'";
1302 my $A_bold_stricter = "A 'B<$STRICTER>'";
1303 my $STABILIZED = 'S';
1304 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1305 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1306 my $OBSOLETE = 'O';
1307 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1308 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1309
1310 my %status_past_participles = (
1311     $DISCOURAGED => 'discouraged',
1312     $STABILIZED => 'stabilized',
1313     $OBSOLETE => 'obsolete',
1314     $DEPRECATED => 'deprecated',
1315 );
1316
1317 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1318 # externally documented.
1319 my $ORDINARY = 0;       # The normal fate.
1320 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1321                         # but there is a file written that can be used to
1322                         # reconstruct this table
1323 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1324                         # for Perl's internal use only
1325 my $LEGACY_ONLY = 3;    # Like $INTERNAL_ONLY, but not actually used by Perl.
1326                         # Is for backwards compatibility for applications that
1327                         # read the file directly, so it's format is
1328                         # unchangeable.
1329 my $SUPPRESSED = 4;     # The file for this table is not written out, and as a
1330                         # result, we don't bother to do many computations on
1331                         # it.
1332 my $PLACEHOLDER = 5;    # Like $SUPPRESSED, but we go through all the
1333                         # computations anyway, as the values are needed for
1334                         # things to work.  This happens when we have Perl
1335                         # extensions that depend on Unicode tables that
1336                         # wouldn't normally be in a given Unicode version.
1337
1338 # The format of the values of the tables:
1339 my $EMPTY_FORMAT = "";
1340 my $BINARY_FORMAT = 'b';
1341 my $DECIMAL_FORMAT = 'd';
1342 my $FLOAT_FORMAT = 'f';
1343 my $INTEGER_FORMAT = 'i';
1344 my $HEX_FORMAT = 'x';
1345 my $RATIONAL_FORMAT = 'r';
1346 my $STRING_FORMAT = 's';
1347 my $ADJUST_FORMAT = 'a';
1348 my $HEX_ADJUST_FORMAT = 'ax';
1349 my $DECOMP_STRING_FORMAT = 'c';
1350 my $STRING_WHITE_SPACE_LIST = 'sw';
1351
1352 my %map_table_formats = (
1353     $BINARY_FORMAT => 'binary',
1354     $DECIMAL_FORMAT => 'single decimal digit',
1355     $FLOAT_FORMAT => 'floating point number',
1356     $INTEGER_FORMAT => 'integer',
1357     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1358     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1359     $STRING_FORMAT => 'string',
1360     $ADJUST_FORMAT => 'some entries need adjustment',
1361     $HEX_ADJUST_FORMAT => 'mapped value in hex; some entries need adjustment',
1362     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1363     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1364 );
1365
1366 # Unicode didn't put such derived files in a separate directory at first.
1367 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1368 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1369 my $AUXILIARY = 'auxiliary';
1370
1371 # Hashes and arrays that will eventually go into Heavy.pl for the use of
1372 # utf8_heavy.pl and into UCD.pl for the use of UCD.pm
1373 my %loose_to_file_of;       # loosely maps table names to their respective
1374                             # files
1375 my %stricter_to_file_of;    # same; but for stricter mapping.
1376 my %loose_property_to_file_of; # Maps a loose property name to its map file
1377 my @inline_definitions = "V0"; # Each element gives a definition of a unique
1378                             # inversion list.  When a definition is inlined,
1379                             # its value in the hash it's in (one of the two
1380                             # defined just above) will include an index into
1381                             # this array.  The 0th element is initialized to
1382                             # the definition for a zero length invwersion list
1383 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1384                             # in the hash %utf8::SwashInfo
1385 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1386                              # their rational equivalent
1387 my %loose_property_name_of; # Loosely maps (non_string) property names to
1388                             # standard form
1389 my %string_property_loose_to_name; # Same, for string properties.
1390 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1391                             # the property name in standard loose form, and
1392                             # 'value' is the default value for that property,
1393                             # also in standard loose form.
1394 my %loose_to_standard_value; # loosely maps table names to the canonical
1395                             # alias for them
1396 my %ambiguous_names;        # keys are alias names (in standard form) that
1397                             # have more than one possible meaning.
1398 my %prop_aliases;           # Keys are standard property name; values are each
1399                             # one's aliases
1400 my %prop_value_aliases;     # Keys of top level are standard property name;
1401                             # values are keys to another hash,  Each one is
1402                             # one of the property's values, in standard form.
1403                             # The values are that prop-val's aliases.
1404 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1405
1406 # Most properties are immune to caseless matching, otherwise you would get
1407 # nonsensical results, as properties are a function of a code point, not
1408 # everything that is caselessly equivalent to that code point.  For example,
1409 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1410 # be true because 's' and 'S' are equivalent caselessly.  However,
1411 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1412 # extend that concept to those very few properties that are like this.  Each
1413 # such property will match the full range caselessly.  They are hard-coded in
1414 # the program; it's not worth trying to make it general as it's extremely
1415 # unlikely that they will ever change.
1416 my %caseless_equivalent_to;
1417
1418 # These constants names and values were taken from the Unicode standard,
1419 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1420 # syllables.  The '_string' versions are so generated tables can retain the
1421 # hex format, which is the more familiar value
1422 my $SBase_string = "0xAC00";
1423 my $SBase = CORE::hex $SBase_string;
1424 my $LBase_string = "0x1100";
1425 my $LBase = CORE::hex $LBase_string;
1426 my $VBase_string = "0x1161";
1427 my $VBase = CORE::hex $VBase_string;
1428 my $TBase_string = "0x11A7";
1429 my $TBase = CORE::hex $TBase_string;
1430 my $SCount = 11172;
1431 my $LCount = 19;
1432 my $VCount = 21;
1433 my $TCount = 28;
1434 my $NCount = $VCount * $TCount;
1435
1436 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1437 # with the above published constants.
1438 my %Jamo;
1439 my %Jamo_L;     # Leading consonants
1440 my %Jamo_V;     # Vowels
1441 my %Jamo_T;     # Trailing consonants
1442
1443 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1444 # The key is the base name of the code point, and the value is an
1445 # array giving all the ranges that use this base name.  Each range
1446 # is actually a hash giving the 'low' and 'high' values of it.
1447 my %names_ending_in_code_point;
1448 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1449                                         # removed from the names
1450 # Inverse mapping.  The list of ranges that have these kinds of
1451 # names.  Each element contains the low, high, and base names in an
1452 # anonymous hash.
1453 my @code_points_ending_in_code_point;
1454
1455 # To hold Unicode's normalization test suite
1456 my @normalization_tests;
1457
1458 # Boolean: does this Unicode version have the hangul syllables, and are we
1459 # writing out a table for them?
1460 my $has_hangul_syllables = 0;
1461
1462 # Does this Unicode version have code points whose names end in their
1463 # respective code points, and are we writing out a table for them?  0 for no;
1464 # otherwise points to first property that a table is needed for them, so that
1465 # if multiple tables are needed, we don't create duplicates
1466 my $needing_code_points_ending_in_code_point = 0;
1467
1468 my @backslash_X_tests;     # List of tests read in for testing \X
1469 my @unhandled_properties;  # Will contain a list of properties found in
1470                            # the input that we didn't process.
1471 my @match_properties;      # Properties that have match tables, to be
1472                            # listed in the pod
1473 my @map_properties;        # Properties that get map files written
1474 my @named_sequences;       # NamedSequences.txt contents.
1475 my %potential_files;       # Generated list of all .txt files in the directory
1476                            # structure so we can warn if something is being
1477                            # ignored.
1478 my @files_actually_output; # List of files we generated.
1479 my @more_Names;            # Some code point names are compound; this is used
1480                            # to store the extra components of them.
1481 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1482                            # the minimum before we consider it equivalent to a
1483                            # candidate rational
1484 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1485
1486 # These store references to certain commonly used property objects
1487 my $ccc;
1488 my $gc;
1489 my $perl;
1490 my $block;
1491 my $perl_charname;
1492 my $print;
1493 my $All;
1494 my $script;
1495
1496 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1497 my $has_In_conflicts = 0;
1498 my $has_Is_conflicts = 0;
1499
1500 sub internal_file_to_platform ($) {
1501     # Convert our file paths which have '/' separators to those of the
1502     # platform.
1503
1504     my $file = shift;
1505     return undef unless defined $file;
1506
1507     return File::Spec->join(split '/', $file);
1508 }
1509
1510 sub file_exists ($) {   # platform independent '-e'.  This program internally
1511                         # uses slash as a path separator.
1512     my $file = shift;
1513     return 0 if ! defined $file;
1514     return -e internal_file_to_platform($file);
1515 }
1516
1517 sub objaddr($) {
1518     # Returns the address of the blessed input object.
1519     # It doesn't check for blessedness because that would do a string eval
1520     # every call, and the program is structured so that this is never called
1521     # for a non-blessed object.
1522
1523     no overloading; # If overloaded, numifying below won't work.
1524
1525     # Numifying a ref gives its address.
1526     return pack 'J', $_[0];
1527 }
1528
1529 # These are used only if $annotate is true.
1530 # The entire range of Unicode characters is examined to populate these
1531 # after all the input has been processed.  But most can be skipped, as they
1532 # have the same descriptive phrases, such as being unassigned
1533 my @viacode;            # Contains the 1 million character names
1534 my @printable;          # boolean: And are those characters printable?
1535 my @annotate_char_type; # Contains a type of those characters, specifically
1536                         # for the purposes of annotation.
1537 my $annotate_ranges;    # A map of ranges of code points that have the same
1538                         # name for the purposes of annotation.  They map to the
1539                         # upper edge of the range, so that the end point can
1540                         # be immediately found.  This is used to skip ahead to
1541                         # the end of a range, and avoid processing each
1542                         # individual code point in it.
1543 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1544                                    # characters, but excluding those which are
1545                                    # also noncharacter code points
1546
1547 # The annotation types are an extension of the regular range types, though
1548 # some of the latter are folded into one.  Make the new types negative to
1549 # avoid conflicting with the regular types
1550 my $SURROGATE_TYPE = -1;
1551 my $UNASSIGNED_TYPE = -2;
1552 my $PRIVATE_USE_TYPE = -3;
1553 my $NONCHARACTER_TYPE = -4;
1554 my $CONTROL_TYPE = -5;
1555 my $ABOVE_UNICODE_TYPE = -6;
1556 my $UNKNOWN_TYPE = -7;  # Used only if there is a bug in this program
1557
1558 sub populate_char_info ($) {
1559     # Used only with the $annotate option.  Populates the arrays with the
1560     # input code point's info that are needed for outputting more detailed
1561     # comments.  If calling context wants a return, it is the end point of
1562     # any contiguous range of characters that share essentially the same info
1563
1564     my $i = shift;
1565     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1566
1567     $viacode[$i] = $perl_charname->value_of($i) || "";
1568
1569     # A character is generally printable if Unicode says it is,
1570     # but below we make sure that most Unicode general category 'C' types
1571     # aren't.
1572     $printable[$i] = $print->contains($i);
1573
1574     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1575
1576     # Only these two regular types are treated specially for annotations
1577     # purposes
1578     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1579                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1580
1581     # Give a generic name to all code points that don't have a real name.
1582     # We output ranges, if applicable, for these.  Also calculate the end
1583     # point of the range.
1584     my $end;
1585     if (! $viacode[$i]) {
1586         my $nonchar;
1587         if ($i > $MAX_UNICODE_CODEPOINT) {
1588             $viacode[$i] = 'Above-Unicode';
1589             $annotate_char_type[$i] = $ABOVE_UNICODE_TYPE;
1590             $printable[$i] = 0;
1591             $end = $MAX_WORKING_CODEPOINT;
1592         }
1593         elsif ($gc-> table('Private_use')->contains($i)) {
1594             $viacode[$i] = 'Private Use';
1595             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1596             $printable[$i] = 0;
1597             $end = $gc->table('Private_Use')->containing_range($i)->end;
1598         }
1599         elsif ((defined ($nonchar =
1600                             Property::property_ref('Noncharacter_Code_Point'))
1601                && $nonchar->table('Y')->contains($i)))
1602         {
1603             $viacode[$i] = 'Noncharacter';
1604             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1605             $printable[$i] = 0;
1606             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1607                                                     containing_range($i)->end;
1608         }
1609         elsif ($gc-> table('Control')->contains($i)) {
1610             $viacode[$i] = property_ref('Name_Alias')->value_of($i) || 'Control';
1611             $annotate_char_type[$i] = $CONTROL_TYPE;
1612             $printable[$i] = 0;
1613         }
1614         elsif ($gc-> table('Unassigned')->contains($i)) {
1615             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1616             $printable[$i] = 0;
1617             if ($v_version lt v2.0.0) { # No blocks in earliest releases
1618                 $viacode[$i] = 'Unassigned';
1619                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1620             }
1621             else {
1622                 $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1623
1624                 # Because we name the unassigned by the blocks they are in, it
1625                 # can't go past the end of that block, and it also can't go
1626                 # past the unassigned range it is in.  The special table makes
1627                 # sure that the non-characters, which are unassigned, are
1628                 # separated out.
1629                 $end = min($block->containing_range($i)->end,
1630                            $unassigned_sans_noncharacters->
1631                                                     containing_range($i)->end);
1632             }
1633         }
1634         elsif ($v_version lt v2.0.0) {  # No surrogates in earliest releases
1635             $viacode[$i] = $gc->value_of($i);
1636             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1637             $printable[$i] = 0;
1638         }
1639         elsif ($gc-> table('Surrogate')->contains($i)) {
1640             $viacode[$i] = 'Surrogate';
1641             $annotate_char_type[$i] = $SURROGATE_TYPE;
1642             $printable[$i] = 0;
1643             $end = $gc->table('Surrogate')->containing_range($i)->end;
1644         }
1645         else {
1646             Carp::my_carp_bug("Can't figure out how to annotate "
1647                               . sprintf("U+%04X", $i)
1648                               . ".  Proceeding anyway.");
1649             $viacode[$i] = 'UNKNOWN';
1650             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1651             $printable[$i] = 0;
1652         }
1653     }
1654
1655     # Here, has a name, but if it's one in which the code point number is
1656     # appended to the name, do that.
1657     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1658         $viacode[$i] .= sprintf("-%04X", $i);
1659         $end = $perl_charname->containing_range($i)->end;
1660     }
1661
1662     # And here, has a name, but if it's a hangul syllable one, replace it with
1663     # the correct name from the Unicode algorithm
1664     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1665         use integer;
1666         my $SIndex = $i - $SBase;
1667         my $L = $LBase + $SIndex / $NCount;
1668         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1669         my $T = $TBase + $SIndex % $TCount;
1670         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1671         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1672         $end = $perl_charname->containing_range($i)->end;
1673     }
1674
1675     return if ! defined wantarray;
1676     return $i if ! defined $end;    # If not a range, return the input
1677
1678     # Save this whole range so can find the end point quickly
1679     $annotate_ranges->add_map($i, $end, $end);
1680
1681     return $end;
1682 }
1683
1684 # Commented code below should work on Perl 5.8.
1685 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1686 ## the native perl version of it (which is what would operate under miniperl)
1687 ## is extremely slow, as it does a string eval every call.
1688 #my $has_fast_scalar_util = $^X !~ /miniperl/
1689 #                            && defined eval "require Scalar::Util";
1690 #
1691 #sub objaddr($) {
1692 #    # Returns the address of the blessed input object.  Uses the XS version if
1693 #    # available.  It doesn't check for blessedness because that would do a
1694 #    # string eval every call, and the program is structured so that this is
1695 #    # never called for a non-blessed object.
1696 #
1697 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1698 #
1699 #    # Check at least that is a ref.
1700 #    my $pkg = ref($_[0]) or return undef;
1701 #
1702 #    # Change to a fake package to defeat any overloaded stringify
1703 #    bless $_[0], 'main::Fake';
1704 #
1705 #    # Numifying a ref gives its address.
1706 #    my $addr = pack 'J', $_[0];
1707 #
1708 #    # Return to original class
1709 #    bless $_[0], $pkg;
1710 #    return $addr;
1711 #}
1712
1713 sub max ($$) {
1714     my $a = shift;
1715     my $b = shift;
1716     return $a if $a >= $b;
1717     return $b;
1718 }
1719
1720 sub min ($$) {
1721     my $a = shift;
1722     my $b = shift;
1723     return $a if $a <= $b;
1724     return $b;
1725 }
1726
1727 sub clarify_number ($) {
1728     # This returns the input number with underscores inserted every 3 digits
1729     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1730     # checked.
1731
1732     my $number = shift;
1733     my $pos = length($number) - 3;
1734     return $number if $pos <= 1;
1735     while ($pos > 0) {
1736         substr($number, $pos, 0) = '_';
1737         $pos -= 3;
1738     }
1739     return $number;
1740 }
1741
1742 sub clarify_code_point_count ($) {
1743     # This is like clarify_number(), but the input is assumed to be a count of
1744     # code points, rather than a generic number.
1745
1746     my $append = "";
1747
1748     my $number = shift;
1749     if ($number > $MAX_UNICODE_CODEPOINTS) {
1750         $number -= ($MAX_WORKING_CODEPOINTS - $MAX_UNICODE_CODEPOINTS);
1751         return "All above-Unicode code points" if $number == 0;
1752         $append = " + all above-Unicode code points";
1753     }
1754     return clarify_number($number) . $append;
1755 }
1756
1757 package Carp;
1758
1759 # These routines give a uniform treatment of messages in this program.  They
1760 # are placed in the Carp package to cause the stack trace to not include them,
1761 # although an alternative would be to use another package and set @CARP_NOT
1762 # for it.
1763
1764 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1765
1766 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1767 # and overload trying to load Scalar:Util under miniperl.  See
1768 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1769 undef $overload::VERSION;
1770
1771 sub my_carp {
1772     my $message = shift || "";
1773     my $nofold = shift || 0;
1774
1775     if ($message) {
1776         $message = main::join_lines($message);
1777         $message =~ s/^$0: *//;     # Remove initial program name
1778         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1779         $message = "\n$0: $message;";
1780
1781         # Fold the message with program name, semi-colon end punctuation
1782         # (which looks good with the message that carp appends to it), and a
1783         # hanging indent for continuation lines.
1784         $message = main::simple_fold($message, "", 4) unless $nofold;
1785         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1786                                     # appends is to the same line
1787     }
1788
1789     return $message if defined wantarray;   # If a caller just wants the msg
1790
1791     carp $message;
1792     return;
1793 }
1794
1795 sub my_carp_bug {
1796     # This is called when it is clear that the problem is caused by a bug in
1797     # this program.
1798
1799     my $message = shift;
1800     $message =~ s/^$0: *//;
1801     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1802     carp $message;
1803     return;
1804 }
1805
1806 sub carp_too_few_args {
1807     if (@_ != 2) {
1808         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1809         return;
1810     }
1811
1812     my $args_ref = shift;
1813     my $count = shift;
1814
1815     my_carp_bug("Need at least $count arguments to "
1816         . (caller 1)[3]
1817         . ".  Instead got: '"
1818         . join ', ', @$args_ref
1819         . "'.  No action taken.");
1820     return;
1821 }
1822
1823 sub carp_extra_args {
1824     my $args_ref = shift;
1825     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1826
1827     unless (ref $args_ref) {
1828         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1829         return;
1830     }
1831     my ($package, $file, $line) = caller;
1832     my $subroutine = (caller 1)[3];
1833
1834     my $list;
1835     if (ref $args_ref eq 'HASH') {
1836         foreach my $key (keys %$args_ref) {
1837             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1838         }
1839         $list = join ', ', each %{$args_ref};
1840     }
1841     elsif (ref $args_ref eq 'ARRAY') {
1842         foreach my $arg (@$args_ref) {
1843             $arg = $UNDEF unless defined $arg;
1844         }
1845         $list = join ', ', @$args_ref;
1846     }
1847     else {
1848         my_carp_bug("Can't cope with ref "
1849                 . ref($args_ref)
1850                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1851         return;
1852     }
1853
1854     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1855     return;
1856 }
1857
1858 package main;
1859
1860 { # Closure
1861
1862     # This program uses the inside-out method for objects, as recommended in
1863     # "Perl Best Practices".  (This is the best solution still, since this has
1864     # to run under miniperl.)  This closure aids in generating those.  There
1865     # are two routines.  setup_package() is called once per package to set
1866     # things up, and then set_access() is called for each hash representing a
1867     # field in the object.  These routines arrange for the object to be
1868     # properly destroyed when no longer used, and for standard accessor
1869     # functions to be generated.  If you need more complex accessors, just
1870     # write your own and leave those accesses out of the call to set_access().
1871     # More details below.
1872
1873     my %constructor_fields; # fields that are to be used in constructors; see
1874                             # below
1875
1876     # The values of this hash will be the package names as keys to other
1877     # hashes containing the name of each field in the package as keys, and
1878     # references to their respective hashes as values.
1879     my %package_fields;
1880
1881     sub setup_package {
1882         # Sets up the package, creating standard DESTROY and dump methods
1883         # (unless already defined).  The dump method is used in debugging by
1884         # simple_dumper().
1885         # The optional parameters are:
1886         #   a)  a reference to a hash, that gets populated by later
1887         #       set_access() calls with one of the accesses being
1888         #       'constructor'.  The caller can then refer to this, but it is
1889         #       not otherwise used by these two routines.
1890         #   b)  a reference to a callback routine to call during destruction
1891         #       of the object, before any fields are actually destroyed
1892
1893         my %args = @_;
1894         my $constructor_ref = delete $args{'Constructor_Fields'};
1895         my $destroy_callback = delete $args{'Destroy_Callback'};
1896         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1897
1898         my %fields;
1899         my $package = (caller)[0];
1900
1901         $package_fields{$package} = \%fields;
1902         $constructor_fields{$package} = $constructor_ref;
1903
1904         unless ($package->can('DESTROY')) {
1905             my $destroy_name = "${package}::DESTROY";
1906             no strict "refs";
1907
1908             # Use typeglob to give the anonymous subroutine the name we want
1909             *$destroy_name = sub {
1910                 my $self = shift;
1911                 my $addr = do { no overloading; pack 'J', $self; };
1912
1913                 $self->$destroy_callback if $destroy_callback;
1914                 foreach my $field (keys %{$package_fields{$package}}) {
1915                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1916                     delete $package_fields{$package}{$field}{$addr};
1917                 }
1918                 return;
1919             }
1920         }
1921
1922         unless ($package->can('dump')) {
1923             my $dump_name = "${package}::dump";
1924             no strict "refs";
1925             *$dump_name = sub {
1926                 my $self = shift;
1927                 return dump_inside_out($self, $package_fields{$package}, @_);
1928             }
1929         }
1930         return;
1931     }
1932
1933     sub set_access {
1934         # Arrange for the input field to be garbage collected when no longer
1935         # needed.  Also, creates standard accessor functions for the field
1936         # based on the optional parameters-- none if none of these parameters:
1937         #   'addable'    creates an 'add_NAME()' accessor function.
1938         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1939         #                function.
1940         #   'settable'   creates a 'set_NAME()' accessor function.
1941         #   'constructor' doesn't create an accessor function, but adds the
1942         #                field to the hash that was previously passed to
1943         #                setup_package();
1944         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1945         # 'add' etc. all mean 'addable'.
1946         # The read accessor function will work on both array and scalar
1947         # values.  If another accessor in the parameter list is 'a', the read
1948         # access assumes an array.  You can also force it to be array access
1949         # by specifying 'readable_array' instead of 'readable'
1950         #
1951         # A sort-of 'protected' access can be set-up by preceding the addable,
1952         # readable or settable with some initial portion of 'protected_' (but,
1953         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1954         # "protection" is only by convention.  All that happens is that the
1955         # accessor functions' names begin with an underscore.  So instead of
1956         # calling set_foo, the call is _set_foo.  (Real protection could be
1957         # accomplished by having a new subroutine, end_package, called at the
1958         # end of each package, and then storing the __LINE__ ranges and
1959         # checking them on every accessor.  But that is way overkill.)
1960
1961         # We create anonymous subroutines as the accessors and then use
1962         # typeglobs to assign them to the proper package and name
1963
1964         my $name = shift;   # Name of the field
1965         my $field = shift;  # Reference to the inside-out hash containing the
1966                             # field
1967
1968         my $package = (caller)[0];
1969
1970         if (! exists $package_fields{$package}) {
1971             croak "$0: Must call 'setup_package' before 'set_access'";
1972         }
1973
1974         # Stash the field so DESTROY can get it.
1975         $package_fields{$package}{$name} = $field;
1976
1977         # Remaining arguments are the accessors.  For each...
1978         foreach my $access (@_) {
1979             my $access = lc $access;
1980
1981             my $protected = "";
1982
1983             # Match the input as far as it goes.
1984             if ($access =~ /^(p[^_]*)_/) {
1985                 $protected = $1;
1986                 if (substr('protected_', 0, length $protected)
1987                     eq $protected)
1988                 {
1989
1990                     # Add 1 for the underscore not included in $protected
1991                     $access = substr($access, length($protected) + 1);
1992                     $protected = '_';
1993                 }
1994                 else {
1995                     $protected = "";
1996                 }
1997             }
1998
1999             if (substr('addable', 0, length $access) eq $access) {
2000                 my $subname = "${package}::${protected}add_$name";
2001                 no strict "refs";
2002
2003                 # add_ accessor.  Don't add if already there, which we
2004                 # determine using 'eq' for scalars and '==' otherwise.
2005                 *$subname = sub {
2006                     use strict "refs";
2007                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2008                     my $self = shift;
2009                     my $value = shift;
2010                     my $addr = do { no overloading; pack 'J', $self; };
2011                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2012                     if (ref $value) {
2013                         return if grep { $value == $_ } @{$field->{$addr}};
2014                     }
2015                     else {
2016                         return if grep { $value eq $_ } @{$field->{$addr}};
2017                     }
2018                     push @{$field->{$addr}}, $value;
2019                     return;
2020                 }
2021             }
2022             elsif (substr('constructor', 0, length $access) eq $access) {
2023                 if ($protected) {
2024                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
2025                 }
2026                 else {
2027                     $constructor_fields{$package}{$name} = $field;
2028                 }
2029             }
2030             elsif (substr('readable_array', 0, length $access) eq $access) {
2031
2032                 # Here has read access.  If one of the other parameters for
2033                 # access is array, or this one specifies array (by being more
2034                 # than just 'readable_'), then create a subroutine that
2035                 # assumes the data is an array.  Otherwise just a scalar
2036                 my $subname = "${package}::${protected}$name";
2037                 if (grep { /^a/i } @_
2038                     or length($access) > length('readable_'))
2039                 {
2040                     no strict "refs";
2041                     *$subname = sub {
2042                         use strict "refs";
2043                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2044                         my $addr = do { no overloading; pack 'J', $_[0]; };
2045                         if (ref $field->{$addr} ne 'ARRAY') {
2046                             my $type = ref $field->{$addr};
2047                             $type = 'scalar' unless $type;
2048                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
2049                             return;
2050                         }
2051                         return scalar @{$field->{$addr}} unless wantarray;
2052
2053                         # Make a copy; had problems with caller modifying the
2054                         # original otherwise
2055                         my @return = @{$field->{$addr}};
2056                         return @return;
2057                     }
2058                 }
2059                 else {
2060
2061                     # Here not an array value, a simpler function.
2062                     no strict "refs";
2063                     *$subname = sub {
2064                         use strict "refs";
2065                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2066                         no overloading;
2067                         return $field->{pack 'J', $_[0]};
2068                     }
2069                 }
2070             }
2071             elsif (substr('settable', 0, length $access) eq $access) {
2072                 my $subname = "${package}::${protected}set_$name";
2073                 no strict "refs";
2074                 *$subname = sub {
2075                     use strict "refs";
2076                     if (main::DEBUG) {
2077                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
2078                         Carp::carp_extra_args(\@_) if @_ > 2;
2079                     }
2080                     # $self is $_[0]; $value is $_[1]
2081                     no overloading;
2082                     $field->{pack 'J', $_[0]} = $_[1];
2083                     return;
2084                 }
2085             }
2086             else {
2087                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
2088             }
2089         }
2090         return;
2091     }
2092 }
2093
2094 package Input_file;
2095
2096 # All input files use this object, which stores various attributes about them,
2097 # and provides for convenient, uniform handling.  The run method wraps the
2098 # processing.  It handles all the bookkeeping of opening, reading, and closing
2099 # the file, returning only significant input lines.
2100 #
2101 # Each object gets a handler which processes the body of the file, and is
2102 # called by run().  All character property files must use the generic,
2103 # default handler, which has code scrubbed to handle things you might not
2104 # expect, including automatic EBCDIC handling.  For files that don't deal with
2105 # mapping code points to a property value, such as test files,
2106 # PropertyAliases, PropValueAliases, and named sequences, you can override the
2107 # handler to be a custom one.  Such a handler should basically be a
2108 # while(next_line()) {...} loop.
2109 #
2110 # You can also set up handlers to
2111 #   1) call before the first line is read, for pre processing
2112 #   2) call to adjust each line of the input before the main handler gets
2113 #      them.  This can be automatically generated, if appropriately simple
2114 #      enough, by specifiying a Properties parameter in the constructor.
2115 #   3) call upon EOF before the main handler exits its loop
2116 #   4) call at the end, for post processing
2117 #
2118 # $_ is used to store the input line, and is to be filtered by the
2119 # each_line_handler()s.  So, if the format of the line is not in the desired
2120 # format for the main handler, these are used to do that adjusting.  They can
2121 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2122 # so the $_ output of one is used as the input to the next.  None of the other
2123 # handlers are stackable, but could easily be changed to be so.
2124 #
2125 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2126 # which insert the parameters as lines to be processed before the next input
2127 # file line is read.  This allows the EOF handler to flush buffers, for
2128 # example.  The difference between the two routines is that the lines inserted
2129 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2130 # called it from such a handler, you would get infinite recursion.)  Lines
2131 # inserted by insert_adjusted_lines() go directly to the main handler without
2132 # any adjustments.  If the  post-processing handler calls any of these, there
2133 # will be no effect.  Some error checking for these conditions could be added,
2134 # but it hasn't been done.
2135 #
2136 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2137 # to prevent further processing of the line.  This routine will output the
2138 # message as a warning once, and then keep a count of the lines that have the
2139 # same message, and output that count at the end of the file's processing.
2140 # This keeps the number of messages down to a manageable amount.
2141 #
2142 # get_missings() should be called to retrieve any @missing input lines.
2143 # Messages will be raised if this isn't done if the options aren't to ignore
2144 # missings.
2145
2146 sub trace { return main::trace(@_); }
2147
2148 { # Closure
2149     # Keep track of fields that are to be put into the constructor.
2150     my %constructor_fields;
2151
2152     main::setup_package(Constructor_Fields => \%constructor_fields);
2153
2154     my %file; # Input file name, required
2155     main::set_access('file', \%file, qw{ c r });
2156
2157     my %first_released; # Unicode version file was first released in, required
2158     main::set_access('first_released', \%first_released, qw{ c r });
2159
2160     my %handler;    # Subroutine to process the input file, defaults to
2161                     # 'process_generic_property_file'
2162     main::set_access('handler', \%handler, qw{ c });
2163
2164     my %property;
2165     # name of property this file is for.  defaults to none, meaning not
2166     # applicable, or is otherwise determinable, for example, from each line.
2167     main::set_access('property', \%property, qw{ c r });
2168
2169     my %optional;
2170     # If this is true, the file is optional.  If not present, no warning is
2171     # output.  If it is present, the string given by this parameter is
2172     # evaluated, and if false the file is not processed.
2173     main::set_access('optional', \%optional, 'c', 'r');
2174
2175     my %non_skip;
2176     # This is used for debugging, to skip processing of all but a few input
2177     # files.  Add 'non_skip => 1' to the constructor for those files you want
2178     # processed when you set the $debug_skip global.
2179     main::set_access('non_skip', \%non_skip, 'c');
2180
2181     my %skip;
2182     # This is used to skip processing of this input file semi-permanently,
2183     # when it evaluates to true.  The value should be the reason the file is
2184     # being skipped.  It is used for files that we aren't planning to process
2185     # anytime soon, but want to allow to be in the directory and not raise a
2186     # message that we are not handling.  Mostly for test files.  This is in
2187     # contrast to the non_skip element, which is supposed to be used very
2188     # temporarily for debugging.  Sets 'optional' to 1.  Also, files that we
2189     # pretty much will never look at can be placed in the global
2190     # %ignored_files instead.  Ones used here will be added to %skipped files
2191     main::set_access('skip', \%skip, 'c');
2192
2193     my %each_line_handler;
2194     # list of subroutines to look at and filter each non-comment line in the
2195     # file.  defaults to none.  The subroutines are called in order, each is
2196     # to adjust $_ for the next one, and the final one adjusts it for
2197     # 'handler'
2198     main::set_access('each_line_handler', \%each_line_handler, 'c');
2199
2200     my %properties; # Optional ordered list of the properties that occur in each
2201     # meaningful line of the input file.  If present, an appropriate
2202     # each_line_handler() is automatically generated and pushed onto the stack
2203     # of such handlers.  This is useful when a file contains multiple
2204     # proerties per line, but no other special considerations are necessary.
2205     # The special value "<ignored>" means to discard the corresponding input
2206     # field.
2207     # Any @missing lines in the file should also match this syntax; no such
2208     # files exist as of 6.3.  But if it happens in a future release, the code
2209     # could be expanded to properly parse them.
2210     main::set_access('properties', \%properties, qw{ c r });
2211
2212     my %has_missings_defaults;
2213     # ? Are there lines in the file giving default values for code points
2214     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2215     # the norm, but IGNORED means it has such lines, but the handler doesn't
2216     # use them.  Having these three states allows us to catch changes to the
2217     # UCD that this program should track.  XXX This could be expanded to
2218     # specify the syntax for such lines, like %properties above.
2219     main::set_access('has_missings_defaults',
2220                                         \%has_missings_defaults, qw{ c r });
2221
2222     my %pre_handler;
2223     # Subroutine to call before doing anything else in the file.  If undef, no
2224     # such handler is called.
2225     main::set_access('pre_handler', \%pre_handler, qw{ c });
2226
2227     my %eof_handler;
2228     # Subroutine to call upon getting an EOF on the input file, but before
2229     # that is returned to the main handler.  This is to allow buffers to be
2230     # flushed.  The handler is expected to call insert_lines() or
2231     # insert_adjusted() with the buffered material
2232     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2233
2234     my %post_handler;
2235     # Subroutine to call after all the lines of the file are read in and
2236     # processed.  If undef, no such handler is called.
2237     main::set_access('post_handler', \%post_handler, qw{ c });
2238
2239     my %progress_message;
2240     # Message to print to display progress in lieu of the standard one
2241     main::set_access('progress_message', \%progress_message, qw{ c });
2242
2243     my %handle;
2244     # cache open file handle, internal.  Is undef if file hasn't been
2245     # processed at all, empty if has;
2246     main::set_access('handle', \%handle);
2247
2248     my %added_lines;
2249     # cache of lines added virtually to the file, internal
2250     main::set_access('added_lines', \%added_lines);
2251
2252     my %remapped_lines;
2253     # cache of lines added virtually to the file, internal
2254     main::set_access('remapped_lines', \%remapped_lines);
2255
2256     my %errors;
2257     # cache of errors found, internal
2258     main::set_access('errors', \%errors);
2259
2260     my %missings;
2261     # storage of '@missing' defaults lines
2262     main::set_access('missings', \%missings);
2263
2264     sub _next_line;
2265     sub _next_line_with_remapped_range;
2266
2267     sub new {
2268         my $class = shift;
2269
2270         my $self = bless \do{ my $anonymous_scalar }, $class;
2271         my $addr = do { no overloading; pack 'J', $self; };
2272
2273         # Set defaults
2274         $handler{$addr} = \&main::process_generic_property_file;
2275         $non_skip{$addr} = 0;
2276         $skip{$addr} = 0;
2277         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2278         $handle{$addr} = undef;
2279         $added_lines{$addr} = [ ];
2280         $remapped_lines{$addr} = [ ];
2281         $each_line_handler{$addr} = [ ];
2282         $errors{$addr} = { };
2283         $missings{$addr} = [ ];
2284
2285         # Two positional parameters.
2286         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2287         $file{$addr} = main::internal_file_to_platform(shift);
2288         $first_released{$addr} = shift;
2289
2290         # The rest of the arguments are key => value pairs
2291         # %constructor_fields has been set up earlier to list all possible
2292         # ones.  Either set or push, depending on how the default has been set
2293         # up just above.
2294         my %args = @_;
2295         foreach my $key (keys %args) {
2296             my $argument = $args{$key};
2297
2298             # Note that the fields are the lower case of the constructor keys
2299             my $hash = $constructor_fields{lc $key};
2300             if (! defined $hash) {
2301                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2302                 next;
2303             }
2304             if (ref $hash->{$addr} eq 'ARRAY') {
2305                 if (ref $argument eq 'ARRAY') {
2306                     foreach my $argument (@{$argument}) {
2307                         next if ! defined $argument;
2308                         push @{$hash->{$addr}}, $argument;
2309                     }
2310                 }
2311                 else {
2312                     push @{$hash->{$addr}}, $argument if defined $argument;
2313                 }
2314             }
2315             else {
2316                 $hash->{$addr} = $argument;
2317             }
2318             delete $args{$key};
2319         };
2320
2321         # If the file has a property for it, it means that the property is not
2322         # listed in the file's entries.  So add a handler to the list of line
2323         # handlers to insert the property name into the lines, to provide a
2324         # uniform interface to the final processing subroutine.
2325         # the final code doesn't have to worry about that.
2326         if ($property{$addr}) {
2327             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2328         }
2329
2330         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2331             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2332         }
2333
2334         # If skipping, set to optional, and add to list of ignored files,
2335         # including its reason
2336         if ($skip{$addr}) {
2337             $optional{$addr} = 1;
2338             $skipped_files{$file{$addr}} = $skip{$addr}
2339         }
2340         elsif ($properties{$addr}) {
2341
2342             # Add a handler for each line in the input so that it creates a
2343             # separate input line for each property in those input lines, thus
2344             # making them suitable for process_generic_property_file().
2345
2346             push @{$each_line_handler{$addr}},
2347                  sub {
2348                     my $file = shift;
2349                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2350
2351                     my @fields = split /\s*;\s*/, $_, -1;
2352
2353                     if (@fields - 1 > @{$properties{$addr}}) {
2354                         $file->carp_bad_line('Extra fields');
2355                         $_ = "";
2356                         return;
2357                     }
2358                     my $range = shift @fields;  # 0th element is always the
2359                                                 # range
2360
2361                     # The next fields in the input line correspond
2362                     # respectively to the stored properties.
2363                     for my $i (0 ..  @{$properties{$addr}} - 1) {
2364                         my $property_name = $properties{$addr}[$i];
2365                         next if $property_name eq '<ignored>';
2366                         $file->insert_adjusted_lines(
2367                               "$range; $property_name; $fields[$i]");
2368                     }
2369                     $_ = "";
2370
2371                     return;
2372                 };
2373         }
2374
2375         {   # On non-ascii platforms, we use a special handler
2376             no strict;
2377             no warnings 'once';
2378             *next_line = (main::NON_ASCII_PLATFORM)
2379                          ? *_next_line_with_remapped_range
2380                          : *_next_line;
2381         }
2382
2383         return $self;
2384     }
2385
2386
2387     use overload
2388         fallback => 0,
2389         qw("") => "_operator_stringify",
2390         "." => \&main::_operator_dot,
2391         ".=" => \&main::_operator_dot_equal,
2392     ;
2393
2394     sub _operator_stringify {
2395         my $self = shift;
2396
2397         return __PACKAGE__ . " object for " . $self->file;
2398     }
2399
2400     # flag to make sure extracted files are processed early
2401     my $seen_non_extracted_non_age = 0;
2402
2403     sub run {
2404         # Process the input object $self.  This opens and closes the file and
2405         # calls all the handlers for it.  Currently,  this can only be called
2406         # once per file, as it destroy's the EOF handler
2407
2408         my $self = shift;
2409         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2410
2411         my $addr = do { no overloading; pack 'J', $self; };
2412
2413         my $file = $file{$addr};
2414
2415         # Don't process if not expecting this file (because released later
2416         # than this Unicode version), and isn't there.  This means if someone
2417         # copies it into an earlier version's directory, we will go ahead and
2418         # process it.
2419         return if $first_released{$addr} gt $v_version && ! -e $file;
2420
2421         # If in debugging mode and this file doesn't have the non-skip
2422         # flag set, and isn't one of the critical files, skip it.
2423         if ($debug_skip
2424             && $first_released{$addr} ne v0
2425             && ! $non_skip{$addr})
2426         {
2427             print "Skipping $file in debugging\n" if $verbosity;
2428             return;
2429         }
2430
2431         # File could be optional
2432         if ($optional{$addr}) {
2433             return unless -e $file;
2434             my $result = eval $optional{$addr};
2435             if (! defined $result) {
2436                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2437                 return;
2438             }
2439             if (! $result) {
2440                 if ($verbosity) {
2441                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2442                 }
2443                 return;
2444             }
2445         }
2446
2447         if (! defined $file || ! -e $file) {
2448
2449             # If the file doesn't exist, see if have internal data for it
2450             # (based on first_released being 0).
2451             if ($first_released{$addr} eq v0) {
2452                 $handle{$addr} = 'pretend_is_open';
2453             }
2454             else {
2455                 if (! $optional{$addr}  # File could be optional
2456                     && $v_version ge $first_released{$addr})
2457                 {
2458                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2459                 }
2460                 return;
2461             }
2462         }
2463         else {
2464
2465             # Here, the file exists.  Some platforms may change the case of
2466             # its name
2467             if ($seen_non_extracted_non_age) {
2468                 if ($file =~ /$EXTRACTED/i) {
2469                     Carp::my_carp_bug(main::join_lines(<<END
2470 $file should be processed just after the 'Prop...Alias' files, and before
2471 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2472 have subtle problems
2473 END
2474                     ));
2475                 }
2476             }
2477             elsif ($EXTRACTED_DIR
2478                     && $first_released{$addr} ne v0
2479                     && $file !~ /$EXTRACTED/i
2480                     && lc($file) ne 'dage.txt')
2481             {
2482                 # We don't set this (by the 'if' above) if we have no
2483                 # extracted directory, so if running on an early version,
2484                 # this test won't work.  Not worth worrying about.
2485                 $seen_non_extracted_non_age = 1;
2486             }
2487
2488             # And mark the file as having being processed, and warn if it
2489             # isn't a file we are expecting.  As we process the files,
2490             # they are deleted from the hash, so any that remain at the
2491             # end of the program are files that we didn't process.
2492             my $fkey = File::Spec->rel2abs($file);
2493             my $expecting = delete $potential_files{lc($fkey)};
2494
2495             Carp::my_carp("Was not expecting '$file'.") if
2496                     ! $expecting
2497                     && ! defined $handle{$addr};
2498
2499             # Having deleted from expected files, we can quit if not to do
2500             # anything.  Don't print progress unless really want verbosity
2501             if ($skip{$addr}) {
2502                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2503                 return;
2504             }
2505
2506             # Open the file, converting the slashes used in this program
2507             # into the proper form for the OS
2508             my $file_handle;
2509             if (not open $file_handle, "<", $file) {
2510                 Carp::my_carp("Can't open $file.  Skipping: $!");
2511                 return 0;
2512             }
2513             $handle{$addr} = $file_handle; # Cache the open file handle
2514
2515             if ($v_version ge v3.2.0
2516                 && lc($file) ne 'unicodedata.txt'
2517
2518                     # Unihan files used another format until v7
2519                 && ($v_version ge v7.0.0 || $file !~ /^Unihan/i))
2520             {
2521                 $_ = <$file_handle>;
2522                 if ($_ !~ / - $string_version \. /x) {
2523                     chomp;
2524                     $_ =~ s/^#\s*//;
2525                     die Carp::my_carp("File '$file' is version '$_'.  It should be version $string_version");
2526                 }
2527             }
2528         }
2529
2530         if ($verbosity >= $PROGRESS) {
2531             if ($progress_message{$addr}) {
2532                 print "$progress_message{$addr}\n";
2533             }
2534             else {
2535                 # If using a virtual file, say so.
2536                 print "Processing ", (-e $file)
2537                                        ? $file
2538                                        : "substitute $file",
2539                                      "\n";
2540             }
2541         }
2542
2543
2544         # Call any special handler for before the file.
2545         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2546
2547         # Then the main handler
2548         &{$handler{$addr}}($self);
2549
2550         # Then any special post-file handler.
2551         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2552
2553         # If any errors have been accumulated, output the counts (as the first
2554         # error message in each class was output when it was encountered).
2555         if ($errors{$addr}) {
2556             my $total = 0;
2557             my $types = 0;
2558             foreach my $error (keys %{$errors{$addr}}) {
2559                 $total += $errors{$addr}->{$error};
2560                 delete $errors{$addr}->{$error};
2561                 $types++;
2562             }
2563             if ($total > 1) {
2564                 my $message
2565                         = "A total of $total lines had errors in $file.  ";
2566
2567                 $message .= ($types == 1)
2568                             ? '(Only the first one was displayed.)'
2569                             : '(Only the first of each type was displayed.)';
2570                 Carp::my_carp($message);
2571             }
2572         }
2573
2574         if (@{$missings{$addr}}) {
2575             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2576         }
2577
2578         # If a real file handle, close it.
2579         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2580                                                         ref $handle{$addr};
2581         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2582                                # the file, as opposed to undef
2583         return;
2584     }
2585
2586     sub _next_line {
2587         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2588         # if such a line exists.  'logical' means that any lines that have
2589         # been added via insert_lines() will be returned in $_ before the file
2590         # is read again.
2591
2592         my $self = shift;
2593         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2594
2595         my $addr = do { no overloading; pack 'J', $self; };
2596
2597         # Here the file is open (or if the handle is not a ref, is an open
2598         # 'virtual' file).  Get the next line; any inserted lines get priority
2599         # over the file itself.
2600         my $adjusted;
2601
2602         LINE:
2603         while (1) { # Loop until find non-comment, non-empty line
2604             #local $to_trace = 1 if main::DEBUG;
2605             my $inserted_ref = shift @{$added_lines{$addr}};
2606             if (defined $inserted_ref) {
2607                 ($adjusted, $_) = @{$inserted_ref};
2608                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2609                 return 1 if $adjusted;
2610             }
2611             else {
2612                 last if ! ref $handle{$addr}; # Don't read unless is real file
2613                 last if ! defined ($_ = readline $handle{$addr});
2614             }
2615             chomp;
2616             trace $_ if main::DEBUG && $to_trace;
2617
2618             # See if this line is the comment line that defines what property
2619             # value that code points that are not listed in the file should
2620             # have.  The format or existence of these lines is not guaranteed
2621             # by Unicode since they are comments, but the documentation says
2622             # that this was added for machine-readability, so probably won't
2623             # change.  This works starting in Unicode Version 5.0.  They look
2624             # like:
2625             #
2626             # @missing: 0000..10FFFF; Not_Reordered
2627             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2628             # @missing: 0000..10FFFF; ; NaN
2629             #
2630             # Save the line for a later get_missings() call.
2631             if (/$missing_defaults_prefix/) {
2632                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2633                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2634                 }
2635                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2636                     my @defaults = split /\s* ; \s*/x, $_;
2637
2638                     # The first field is the @missing, which ends in a
2639                     # semi-colon, so can safely shift.
2640                     shift @defaults;
2641
2642                     # Some of these lines may have empty field placeholders
2643                     # which get in the way.  An example is:
2644                     # @missing: 0000..10FFFF; ; NaN
2645                     # Remove them.  Process starting from the top so the
2646                     # splice doesn't affect things still to be looked at.
2647                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2648                         next if $defaults[$i] ne "";
2649                         splice @defaults, $i, 1;
2650                     }
2651
2652                     # What's left should be just the property (maybe) and the
2653                     # default.  Having only one element means it doesn't have
2654                     # the property.
2655                     my $default;
2656                     my $property;
2657                     if (@defaults >= 1) {
2658                         if (@defaults == 1) {
2659                             $default = $defaults[0];
2660                         }
2661                         else {
2662                             $property = $defaults[0];
2663                             $default = $defaults[1];
2664                         }
2665                     }
2666
2667                     if (@defaults < 1
2668                         || @defaults > 2
2669                         || ($default =~ /^</
2670                             && $default !~ /^<code *point>$/i
2671                             && $default !~ /^<none>$/i
2672                             && $default !~ /^<script>$/i))
2673                     {
2674                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2675                     }
2676                     else {
2677
2678                         # If the property is missing from the line, it should
2679                         # be the one for the whole file
2680                         $property = $property{$addr} if ! defined $property;
2681
2682                         # Change <none> to the null string, which is what it
2683                         # really means.  If the default is the code point
2684                         # itself, set it to <code point>, which is what
2685                         # Unicode uses (but sometimes they've forgotten the
2686                         # space)
2687                         if ($default =~ /^<none>$/i) {
2688                             $default = "";
2689                         }
2690                         elsif ($default =~ /^<code *point>$/i) {
2691                             $default = $CODE_POINT;
2692                         }
2693                         elsif ($default =~ /^<script>$/i) {
2694
2695                             # Special case this one.  Currently is from
2696                             # ScriptExtensions.txt, and means for all unlisted
2697                             # code points, use their Script property values.
2698                             # For the code points not listed in that file, the
2699                             # default value is 'Unknown'.
2700                             $default = "Unknown";
2701                         }
2702
2703                         # Store them as a sub-arrays with both components.
2704                         push @{$missings{$addr}}, [ $default, $property ];
2705                     }
2706                 }
2707
2708                 # There is nothing for the caller to process on this comment
2709                 # line.
2710                 next;
2711             }
2712
2713             # Remove comments and trailing space, and skip this line if the
2714             # result is empty
2715             s/#.*//;
2716             s/\s+$//;
2717             next if /^$/;
2718
2719             # Call any handlers for this line, and skip further processing of
2720             # the line if the handler sets the line to null.
2721             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2722                 &{$sub_ref}($self);
2723                 next LINE if /^$/;
2724             }
2725
2726             # Here the line is ok.  return success.
2727             return 1;
2728         } # End of looping through lines.
2729
2730         # If there is an EOF handler, call it (only once) and if it generates
2731         # more lines to process go back in the loop to handle them.
2732         if ($eof_handler{$addr}) {
2733             &{$eof_handler{$addr}}($self);
2734             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2735             goto LINE if $added_lines{$addr};
2736         }
2737
2738         # Return failure -- no more lines.
2739         return 0;
2740
2741     }
2742
2743     sub _next_line_with_remapped_range {
2744         my $self = shift;
2745         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2746
2747         # like _next_line(), but for use on non-ASCII platforms.  It sets $_
2748         # to be the next logical input line, if any.  Returns non-zero if such
2749         # a line exists.  'logical' means that any lines that have been added
2750         # via insert_lines() will be returned in $_ before the file is read
2751         # again.
2752         #
2753         # The difference from _next_line() is that this remaps the Unicode
2754         # code points in the input to those of the native platform.  Each
2755         # input line contains a single code point, or a single contiguous
2756         # range of them  This routine splits each range into its individual
2757         # code points and caches them.  It returns the cached values,
2758         # translated into their native equivalents, one at a time, for each
2759         # call, before reading the next line.  Since native values can only be
2760         # a single byte wide, no translation is needed for code points above
2761         # 0xFF, and ranges that are entirely above that number are not split.
2762         # If an input line contains the range 254-1000, it would be split into
2763         # three elements: 254, 255, and 256-1000.  (The downstream table
2764         # insertion code will sort and coalesce the individual code points
2765         # into appropriate ranges.)
2766
2767         my $addr = do { no overloading; pack 'J', $self; };
2768
2769         while (1) {
2770
2771             # Look in cache before reading the next line.  Return any cached
2772             # value, translated
2773             my $inserted = shift @{$remapped_lines{$addr}};
2774             if (defined $inserted) {
2775                 trace $inserted if main::DEBUG && $to_trace;
2776                 $_ = $inserted =~ s/^ ( \d+ ) /sprintf("%04X", utf8::unicode_to_native($1))/xer;
2777                 trace $_ if main::DEBUG && $to_trace;
2778                 return 1;
2779             }
2780
2781             # Get the next line.
2782             return 0 unless _next_line($self);
2783
2784             # If there is a special handler for it, return the line,
2785             # untranslated.  This should happen only for files that are
2786             # special, not being code-point related, such as property names.
2787             return 1 if $handler{$addr}
2788                                     != \&main::process_generic_property_file;
2789
2790             my ($range, $property_name, $map, @remainder)
2791                 = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
2792
2793             if (@remainder
2794                 || ! defined $property_name
2795                 || $range !~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
2796             {
2797                 Carp::my_carp_bug("Unrecognized input line '$_'.  Ignored");
2798             }
2799
2800             my $low = hex $1;
2801             my $high = (defined $2) ? hex $2 : $low;
2802
2803             # If the input maps the range to another code point, remap the
2804             # target if it is between 0 and 255.
2805             my $tail;
2806             if (defined $map) {
2807                 $map =~ s/\b 00 ( [0-9A-F]{2} ) \b/sprintf("%04X", utf8::unicode_to_native(hex $1))/gxe;
2808                 $tail = "$property_name; $map";
2809                 $_ = "$range; $tail";
2810             }
2811             else {
2812                 $tail = $property_name;
2813             }
2814
2815             # If entire range is above 255, just return it, unchanged (except
2816             # any mapped-to code point, already changed above)
2817             return 1 if $low > 255;
2818
2819             # Cache an entry for every code point < 255.  For those in the
2820             # range above 255, return a dummy entry for just that portion of
2821             # the range.  Note that this will be out-of-order, but that is not
2822             # a problem.
2823             foreach my $code_point ($low .. $high) {
2824                 if ($code_point > 255) {
2825                     $_ = sprintf "%04X..%04X; $tail", $code_point, $high;
2826                     return 1;
2827                 }
2828                 push @{$remapped_lines{$addr}}, "$code_point; $tail";
2829             }
2830         } # End of looping through lines.
2831
2832         # NOTREACHED
2833     }
2834
2835 #   Not currently used, not fully tested.
2836 #    sub peek {
2837 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2838 #        # record.  Not callable from an each_line_handler(), nor does it call
2839 #        # an each_line_handler() on the line.
2840 #
2841 #        my $self = shift;
2842 #        my $addr = do { no overloading; pack 'J', $self; };
2843 #
2844 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2845 #            my ($adjusted, $line) = @{$inserted_ref};
2846 #            next if $adjusted;
2847 #
2848 #            # Remove comments and trailing space, and return a non-empty
2849 #            # resulting line
2850 #            $line =~ s/#.*//;
2851 #            $line =~ s/\s+$//;
2852 #            return $line if $line ne "";
2853 #        }
2854 #
2855 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2856 #        while (1) { # Loop until find non-comment, non-empty line
2857 #            local $to_trace = 1 if main::DEBUG;
2858 #            trace $_ if main::DEBUG && $to_trace;
2859 #            return if ! defined (my $line = readline $handle{$addr});
2860 #            chomp $line;
2861 #            push @{$added_lines{$addr}}, [ 0, $line ];
2862 #
2863 #            $line =~ s/#.*//;
2864 #            $line =~ s/\s+$//;
2865 #            return $line if $line ne "";
2866 #        }
2867 #
2868 #        return;
2869 #    }
2870
2871
2872     sub insert_lines {
2873         # Lines can be inserted so that it looks like they were in the input
2874         # file at the place it was when this routine is called.  See also
2875         # insert_adjusted_lines().  Lines inserted via this routine go through
2876         # any each_line_handler()
2877
2878         my $self = shift;
2879
2880         # Each inserted line is an array, with the first element being 0 to
2881         # indicate that this line hasn't been adjusted, and needs to be
2882         # processed.
2883         no overloading;
2884         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2885         return;
2886     }
2887
2888     sub insert_adjusted_lines {
2889         # Lines can be inserted so that it looks like they were in the input
2890         # file at the place it was when this routine is called.  See also
2891         # insert_lines().  Lines inserted via this routine are already fully
2892         # adjusted, ready to be processed; each_line_handler()s handlers will
2893         # not be called.  This means this is not a completely general
2894         # facility, as only the last each_line_handler on the stack should
2895         # call this.  It could be made more general, by passing to each of the
2896         # line_handlers their position on the stack, which they would pass on
2897         # to this routine, and that would replace the boolean first element in
2898         # the anonymous array pushed here, so that the next_line routine could
2899         # use that to call only those handlers whose index is after it on the
2900         # stack.  But this is overkill for what is needed now.
2901
2902         my $self = shift;
2903         trace $_[0] if main::DEBUG && $to_trace;
2904
2905         # Each inserted line is an array, with the first element being 1 to
2906         # indicate that this line has been adjusted
2907         no overloading;
2908         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2909         return;
2910     }
2911
2912     sub get_missings {
2913         # Returns the stored up @missings lines' values, and clears the list.
2914         # The values are in an array, consisting of the default in the first
2915         # element, and the property in the 2nd.  However, since these lines
2916         # can be stacked up, the return is an array of all these arrays.
2917
2918         my $self = shift;
2919         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2920
2921         my $addr = do { no overloading; pack 'J', $self; };
2922
2923         # If not accepting a list return, just return the first one.
2924         return shift @{$missings{$addr}} unless wantarray;
2925
2926         my @return = @{$missings{$addr}};
2927         undef @{$missings{$addr}};
2928         return @return;
2929     }
2930
2931     sub _insert_property_into_line {
2932         # Add a property field to $_, if this file requires it.
2933
2934         my $self = shift;
2935         my $addr = do { no overloading; pack 'J', $self; };
2936         my $property = $property{$addr};
2937         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2938
2939         $_ =~ s/(;|$)/; $property$1/;
2940         return;
2941     }
2942
2943     sub carp_bad_line {
2944         # Output consistent error messages, using either a generic one, or the
2945         # one given by the optional parameter.  To avoid gazillions of the
2946         # same message in case the syntax of a  file is way off, this routine
2947         # only outputs the first instance of each message, incrementing a
2948         # count so the totals can be output at the end of the file.
2949
2950         my $self = shift;
2951         my $message = shift;
2952         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2953
2954         my $addr = do { no overloading; pack 'J', $self; };
2955
2956         $message = 'Unexpected line' unless $message;
2957
2958         # No trailing punctuation so as to fit with our addenda.
2959         $message =~ s/[.:;,]$//;
2960
2961         # If haven't seen this exact message before, output it now.  Otherwise
2962         # increment the count of how many times it has occurred
2963         unless ($errors{$addr}->{$message}) {
2964             Carp::my_carp("$message in '$_' in "
2965                             . $file{$addr}
2966                             . " at line $..  Skipping this line;");
2967             $errors{$addr}->{$message} = 1;
2968         }
2969         else {
2970             $errors{$addr}->{$message}++;
2971         }
2972
2973         # Clear the line to prevent any further (meaningful) processing of it.
2974         $_ = "";
2975
2976         return;
2977     }
2978 } # End closure
2979
2980 package Multi_Default;
2981
2982 # Certain properties in early versions of Unicode had more than one possible
2983 # default for code points missing from the files.  In these cases, one
2984 # default applies to everything left over after all the others are applied,
2985 # and for each of the others, there is a description of which class of code
2986 # points applies to it.  This object helps implement this by storing the
2987 # defaults, and for all but that final default, an eval string that generates
2988 # the class that it applies to.
2989
2990
2991 {   # Closure
2992
2993     main::setup_package();
2994
2995     my %class_defaults;
2996     # The defaults structure for the classes
2997     main::set_access('class_defaults', \%class_defaults);
2998
2999     my %other_default;
3000     # The default that applies to everything left over.
3001     main::set_access('other_default', \%other_default, 'r');
3002
3003
3004     sub new {
3005         # The constructor is called with default => eval pairs, terminated by
3006         # the left-over default. e.g.
3007         # Multi_Default->new(
3008         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
3009         #               -  0x200D',
3010         #        'R' => 'some other expression that evaluates to code points',
3011         #        .
3012         #        .
3013         #        .
3014         #        'U'));
3015
3016         my $class = shift;
3017
3018         my $self = bless \do{my $anonymous_scalar}, $class;
3019         my $addr = do { no overloading; pack 'J', $self; };
3020
3021         while (@_ > 1) {
3022             my $default = shift;
3023             my $eval = shift;
3024             $class_defaults{$addr}->{$default} = $eval;
3025         }
3026
3027         $other_default{$addr} = shift;
3028
3029         return $self;
3030     }
3031
3032     sub get_next_defaults {
3033         # Iterates and returns the next class of defaults.
3034         my $self = shift;
3035         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3036
3037         my $addr = do { no overloading; pack 'J', $self; };
3038
3039         return each %{$class_defaults{$addr}};
3040     }
3041 }
3042
3043 package Alias;
3044
3045 # An alias is one of the names that a table goes by.  This class defines them
3046 # including some attributes.  Everything is currently setup in the
3047 # constructor.
3048
3049
3050 {   # Closure
3051
3052     main::setup_package();
3053
3054     my %name;
3055     main::set_access('name', \%name, 'r');
3056
3057     my %loose_match;
3058     # Should this name match loosely or not.
3059     main::set_access('loose_match', \%loose_match, 'r');
3060
3061     my %make_re_pod_entry;
3062     # Some aliases should not get their own entries in the re section of the
3063     # pod, because they are covered by a wild-card, and some we want to
3064     # discourage use of.  Binary
3065     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
3066
3067     my %ucd;
3068     # Is this documented to be accessible via Unicode::UCD
3069     main::set_access('ucd', \%ucd, 'r', 's');
3070
3071     my %status;
3072     # Aliases have a status, like deprecated, or even suppressed (which means
3073     # they don't appear in documentation).  Enum
3074     main::set_access('status', \%status, 'r');
3075
3076     my %ok_as_filename;
3077     # Similarly, some aliases should not be considered as usable ones for
3078     # external use, such as file names, or we don't want documentation to
3079     # recommend them.  Boolean
3080     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
3081
3082     sub new {
3083         my $class = shift;
3084
3085         my $self = bless \do { my $anonymous_scalar }, $class;
3086         my $addr = do { no overloading; pack 'J', $self; };
3087
3088         $name{$addr} = shift;
3089         $loose_match{$addr} = shift;
3090         $make_re_pod_entry{$addr} = shift;
3091         $ok_as_filename{$addr} = shift;
3092         $status{$addr} = shift;
3093         $ucd{$addr} = shift;
3094
3095         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3096
3097         # Null names are never ok externally
3098         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
3099
3100         return $self;
3101     }
3102 }
3103
3104 package Range;
3105
3106 # A range is the basic unit for storing code points, and is described in the
3107 # comments at the beginning of the program.  Each range has a starting code
3108 # point; an ending code point (not less than the starting one); a value
3109 # that applies to every code point in between the two end-points, inclusive;
3110 # and an enum type that applies to the value.  The type is for the user's
3111 # convenience, and has no meaning here, except that a non-zero type is
3112 # considered to not obey the normal Unicode rules for having standard forms.
3113 #
3114 # The same structure is used for both map and match tables, even though in the
3115 # latter, the value (and hence type) is irrelevant and could be used as a
3116 # comment.  In map tables, the value is what all the code points in the range
3117 # map to.  Type 0 values have the standardized version of the value stored as
3118 # well, so as to not have to recalculate it a lot.
3119
3120 sub trace { return main::trace(@_); }
3121
3122 {   # Closure
3123
3124     main::setup_package();
3125
3126     my %start;
3127     main::set_access('start', \%start, 'r', 's');
3128
3129     my %end;
3130     main::set_access('end', \%end, 'r', 's');
3131
3132     my %value;
3133     main::set_access('value', \%value, 'r');
3134
3135     my %type;
3136     main::set_access('type', \%type, 'r');
3137
3138     my %standard_form;
3139     # The value in internal standard form.  Defined only if the type is 0.
3140     main::set_access('standard_form', \%standard_form);
3141
3142     # Note that if these fields change, the dump() method should as well
3143
3144     sub new {
3145         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
3146         my $class = shift;
3147
3148         my $self = bless \do { my $anonymous_scalar }, $class;
3149         my $addr = do { no overloading; pack 'J', $self; };
3150
3151         $start{$addr} = shift;
3152         $end{$addr} = shift;
3153
3154         my %args = @_;
3155
3156         my $value = delete $args{'Value'};  # Can be 0
3157         $value = "" unless defined $value;
3158         $value{$addr} = $value;
3159
3160         $type{$addr} = delete $args{'Type'} || 0;
3161
3162         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3163
3164         return $self;
3165     }
3166
3167     use overload
3168         fallback => 0,
3169         qw("") => "_operator_stringify",
3170         "." => \&main::_operator_dot,
3171         ".=" => \&main::_operator_dot_equal,
3172     ;
3173
3174     sub _operator_stringify {
3175         my $self = shift;
3176         my $addr = do { no overloading; pack 'J', $self; };
3177
3178         # Output it like '0041..0065 (value)'
3179         my $return = sprintf("%04X", $start{$addr})
3180                         .  '..'
3181                         . sprintf("%04X", $end{$addr});
3182         my $value = $value{$addr};
3183         my $type = $type{$addr};
3184         $return .= ' (';
3185         $return .= "$value";
3186         $return .= ", Type=$type" if $type != 0;
3187         $return .= ')';
3188
3189         return $return;
3190     }
3191
3192     sub standard_form {
3193         # Calculate the standard form only if needed, and cache the result.
3194         # The standard form is the value itself if the type is special.
3195         # This represents a considerable CPU and memory saving - at the time
3196         # of writing there are 368676 non-special objects, but the standard
3197         # form is only requested for 22047 of them - ie about 6%.
3198
3199         my $self = shift;
3200         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3201
3202         my $addr = do { no overloading; pack 'J', $self; };
3203
3204         return $standard_form{$addr} if defined $standard_form{$addr};
3205
3206         my $value = $value{$addr};
3207         return $value if $type{$addr};
3208         return $standard_form{$addr} = main::standardize($value);
3209     }
3210
3211     sub dump {
3212         # Human, not machine readable.  For machine readable, comment out this
3213         # entire routine and let the standard one take effect.
3214         my $self = shift;
3215         my $indent = shift;
3216         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3217
3218         my $addr = do { no overloading; pack 'J', $self; };
3219
3220         my $return = $indent
3221                     . sprintf("%04X", $start{$addr})
3222                     . '..'
3223                     . sprintf("%04X", $end{$addr})
3224                     . " '$value{$addr}';";
3225         if (! defined $standard_form{$addr}) {
3226             $return .= "(type=$type{$addr})";
3227         }
3228         elsif ($standard_form{$addr} ne $value{$addr}) {
3229             $return .= "(standard '$standard_form{$addr}')";
3230         }
3231         return $return;
3232     }
3233 } # End closure
3234
3235 package _Range_List_Base;
3236
3237 # Base class for range lists.  A range list is simply an ordered list of
3238 # ranges, so that the ranges with the lowest starting numbers are first in it.
3239 #
3240 # When a new range is added that is adjacent to an existing range that has the
3241 # same value and type, it merges with it to form a larger range.
3242 #
3243 # Ranges generally do not overlap, except that there can be multiple entries
3244 # of single code point ranges.  This is because of NameAliases.txt.
3245 #
3246 # In this program, there is a standard value such that if two different
3247 # values, have the same standard value, they are considered equivalent.  This
3248 # value was chosen so that it gives correct results on Unicode data
3249
3250 # There are a number of methods to manipulate range lists, and some operators
3251 # are overloaded to handle them.
3252
3253 sub trace { return main::trace(@_); }
3254
3255 { # Closure
3256
3257     our $addr;
3258
3259     # Max is initialized to a negative value that isn't adjacent to 0, for
3260     # simpler tests
3261     my $max_init = -2;
3262
3263     main::setup_package();
3264
3265     my %ranges;
3266     # The list of ranges
3267     main::set_access('ranges', \%ranges, 'readable_array');
3268
3269     my %max;
3270     # The highest code point in the list.  This was originally a method, but
3271     # actual measurements said it was used a lot.
3272     main::set_access('max', \%max, 'r');
3273
3274     my %each_range_iterator;
3275     # Iterator position for each_range()
3276     main::set_access('each_range_iterator', \%each_range_iterator);
3277
3278     my %owner_name_of;
3279     # Name of parent this is attached to, if any.  Solely for better error
3280     # messages.
3281     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3282
3283     my %_search_ranges_cache;
3284     # A cache of the previous result from _search_ranges(), for better
3285     # performance
3286     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3287
3288     sub new {
3289         my $class = shift;
3290         my %args = @_;
3291
3292         # Optional initialization data for the range list.
3293         my $initialize = delete $args{'Initialize'};
3294
3295         my $self;
3296
3297         # Use _union() to initialize.  _union() returns an object of this
3298         # class, which means that it will call this constructor recursively.
3299         # But it won't have this $initialize parameter so that it won't
3300         # infinitely loop on this.
3301         return _union($class, $initialize, %args) if defined $initialize;
3302
3303         $self = bless \do { my $anonymous_scalar }, $class;
3304         my $addr = do { no overloading; pack 'J', $self; };
3305
3306         # Optional parent object, only for debug info.
3307         $owner_name_of{$addr} = delete $args{'Owner'};
3308         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3309
3310         # Stringify, in case it is an object.
3311         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3312
3313         # This is used only for error messages, and so a colon is added
3314         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3315
3316         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3317
3318         $max{$addr} = $max_init;
3319
3320         $_search_ranges_cache{$addr} = 0;
3321         $ranges{$addr} = [];
3322
3323         return $self;
3324     }
3325
3326     use overload
3327         fallback => 0,
3328         qw("") => "_operator_stringify",
3329         "." => \&main::_operator_dot,
3330         ".=" => \&main::_operator_dot_equal,
3331     ;
3332
3333     sub _operator_stringify {
3334         my $self = shift;
3335         my $addr = do { no overloading; pack 'J', $self; };
3336
3337         return "Range_List attached to '$owner_name_of{$addr}'"
3338                                                 if $owner_name_of{$addr};
3339         return "anonymous Range_List " . \$self;
3340     }
3341
3342     sub _union {
3343         # Returns the union of the input code points.  It can be called as
3344         # either a constructor or a method.  If called as a method, the result
3345         # will be a new() instance of the calling object, containing the union
3346         # of that object with the other parameter's code points;  if called as
3347         # a constructor, the first parameter gives the class that the new object
3348         # should be, and the second parameter gives the code points to go into
3349         # it.
3350         # In either case, there are two parameters looked at by this routine;
3351         # any additional parameters are passed to the new() constructor.
3352         #
3353         # The code points can come in the form of some object that contains
3354         # ranges, and has a conventionally named method to access them; or
3355         # they can be an array of individual code points (as integers); or
3356         # just a single code point.
3357         #
3358         # If they are ranges, this routine doesn't make any effort to preserve
3359         # the range values and types of one input over the other.  Therefore
3360         # this base class should not allow _union to be called from other than
3361         # initialization code, so as to prevent two tables from being added
3362         # together where the range values matter.  The general form of this
3363         # routine therefore belongs in a derived class, but it was moved here
3364         # to avoid duplication of code.  The failure to overload this in this
3365         # class keeps it safe.
3366         #
3367         # It does make the effort during initialization to accept tables with
3368         # multiple values for the same code point, and to preserve the order
3369         # of these.  If there is only one input range or range set, it doesn't
3370         # sort (as it should already be sorted to the desired order), and will
3371         # accept multiple values per code point.  Otherwise it will merge
3372         # multiple values into a single one.
3373
3374         my $self;
3375         my @args;   # Arguments to pass to the constructor
3376
3377         my $class = shift;
3378
3379         # If a method call, will start the union with the object itself, and
3380         # the class of the new object will be the same as self.
3381         if (ref $class) {
3382             $self = $class;
3383             $class = ref $self;
3384             push @args, $self;
3385         }
3386
3387         # Add the other required parameter.
3388         push @args, shift;
3389         # Rest of parameters are passed on to the constructor
3390
3391         # Accumulate all records from both lists.
3392         my @records;
3393         my $input_count = 0;
3394         for my $arg (@args) {
3395             #local $to_trace = 0 if main::DEBUG;
3396             trace "argument = $arg" if main::DEBUG && $to_trace;
3397             if (! defined $arg) {
3398                 my $message = "";
3399                 if (defined $self) {
3400                     no overloading;
3401                     $message .= $owner_name_of{pack 'J', $self};
3402                 }
3403                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3404                 return;
3405             }
3406
3407             $arg = [ $arg ] if ! ref $arg;
3408             my $type = ref $arg;
3409             if ($type eq 'ARRAY') {
3410                 foreach my $element (@$arg) {
3411                     push @records, Range->new($element, $element);
3412                     $input_count++;
3413                 }
3414             }
3415             elsif ($arg->isa('Range')) {
3416                 push @records, $arg;
3417                 $input_count++;
3418             }
3419             elsif ($arg->can('ranges')) {
3420                 push @records, $arg->ranges;
3421                 $input_count++;
3422             }
3423             else {
3424                 my $message = "";
3425                 if (defined $self) {
3426                     no overloading;
3427                     $message .= $owner_name_of{pack 'J', $self};
3428                 }
3429                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3430                 return;
3431             }
3432         }
3433
3434         # Sort with the range containing the lowest ordinal first, but if
3435         # two ranges start at the same code point, sort with the bigger range
3436         # of the two first, because it takes fewer cycles.
3437         if ($input_count > 1) {
3438             @records = sort { ($a->start <=> $b->start)
3439                                       or
3440                                     # if b is shorter than a, b->end will be
3441                                     # less than a->end, and we want to select
3442                                     # a, so want to return -1
3443                                     ($b->end <=> $a->end)
3444                                    } @records;
3445         }
3446
3447         my $new = $class->new(@_);
3448
3449         # Fold in records so long as they add new information.
3450         for my $set (@records) {
3451             my $start = $set->start;
3452             my $end   = $set->end;
3453             my $value = $set->value;
3454             my $type  = $set->type;
3455             if ($start > $new->max) {
3456                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3457             }
3458             elsif ($end > $new->max) {
3459                 $new->_add_delete('+', $new->max +1, $end, $value,
3460                                                                 Type => $type);
3461             }
3462             elsif ($input_count == 1) {
3463                 # Here, overlaps existing range, but is from a single input,
3464                 # so preserve the multiple values from that input.
3465                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3466                                                 Replace => $MULTIPLE_AFTER);
3467             }
3468         }
3469
3470         return $new;
3471     }
3472
3473     sub range_count {        # Return the number of ranges in the range list
3474         my $self = shift;
3475         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3476
3477         no overloading;
3478         return scalar @{$ranges{pack 'J', $self}};
3479     }
3480
3481     sub min {
3482         # Returns the minimum code point currently in the range list, or if
3483         # the range list is empty, 2 beyond the max possible.  This is a
3484         # method because used so rarely, that not worth saving between calls,
3485         # and having to worry about changing it as ranges are added and
3486         # deleted.
3487
3488         my $self = shift;
3489         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3490
3491         my $addr = do { no overloading; pack 'J', $self; };
3492
3493         # If the range list is empty, return a large value that isn't adjacent
3494         # to any that could be in the range list, for simpler tests
3495         return $MAX_WORKING_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3496         return $ranges{$addr}->[0]->start;
3497     }
3498
3499     sub contains {
3500         # Boolean: Is argument in the range list?  If so returns $i such that:
3501         #   range[$i]->end < $codepoint <= range[$i+1]->end
3502         # which is one beyond what you want; this is so that the 0th range
3503         # doesn't return false
3504         my $self = shift;
3505         my $codepoint = shift;
3506         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3507
3508         my $i = $self->_search_ranges($codepoint);
3509         return 0 unless defined $i;
3510
3511         # The search returns $i, such that
3512         #   range[$i-1]->end < $codepoint <= range[$i]->end
3513         # So is in the table if and only iff it is at least the start position
3514         # of range $i.
3515         no overloading;
3516         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3517         return $i + 1;
3518     }
3519
3520     sub containing_range {
3521         # Returns the range object that contains the code point, undef if none
3522
3523         my $self = shift;
3524         my $codepoint = shift;
3525         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3526
3527         my $i = $self->contains($codepoint);
3528         return unless $i;
3529
3530         # contains() returns 1 beyond where we should look
3531         no overloading;
3532         return $ranges{pack 'J', $self}->[$i-1];
3533     }
3534
3535     sub value_of {
3536         # Returns the value associated with the code point, undef if none
3537
3538         my $self = shift;
3539         my $codepoint = shift;
3540         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3541
3542         my $range = $self->containing_range($codepoint);
3543         return unless defined $range;
3544
3545         return $range->value;
3546     }
3547
3548     sub type_of {
3549         # Returns the type of the range containing the code point, undef if
3550         # the code point is not in the table
3551
3552         my $self = shift;
3553         my $codepoint = shift;
3554         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3555
3556         my $range = $self->containing_range($codepoint);
3557         return unless defined $range;
3558
3559         return $range->type;
3560     }
3561
3562     sub _search_ranges {
3563         # Find the range in the list which contains a code point, or where it
3564         # should go if were to add it.  That is, it returns $i, such that:
3565         #   range[$i-1]->end < $codepoint <= range[$i]->end
3566         # Returns undef if no such $i is possible (e.g. at end of table), or
3567         # if there is an error.
3568
3569         my $self = shift;
3570         my $code_point = shift;
3571         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3572
3573         my $addr = do { no overloading; pack 'J', $self; };
3574
3575         return if $code_point > $max{$addr};
3576         my $r = $ranges{$addr};                # The current list of ranges
3577         my $range_list_size = scalar @$r;
3578         my $i;
3579
3580         use integer;        # want integer division
3581
3582         # Use the cached result as the starting guess for this one, because,
3583         # an experiment on 5.1 showed that 90% of the time the cache was the
3584         # same as the result on the next call (and 7% it was one less).
3585         $i = $_search_ranges_cache{$addr};
3586         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3587                                             # from an intervening deletion
3588         #local $to_trace = 1 if main::DEBUG;
3589         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3590         return $i if $code_point <= $r->[$i]->end
3591                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3592
3593         # Here the cache doesn't yield the correct $i.  Try adding 1.
3594         if ($i < $range_list_size - 1
3595             && $r->[$i]->end < $code_point &&
3596             $code_point <= $r->[$i+1]->end)
3597         {
3598             $i++;
3599             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3600             $_search_ranges_cache{$addr} = $i;
3601             return $i;
3602         }
3603
3604         # Here, adding 1 also didn't work.  We do a binary search to
3605         # find the correct position, starting with current $i
3606         my $lower = 0;
3607         my $upper = $range_list_size - 1;
3608         while (1) {
3609             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3610
3611             if ($code_point <= $r->[$i]->end) {
3612
3613                 # Here we have met the upper constraint.  We can quit if we
3614                 # also meet the lower one.
3615                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3616
3617                 $upper = $i;        # Still too high.
3618
3619             }
3620             else {
3621
3622                 # Here, $r[$i]->end < $code_point, so look higher up.
3623                 $lower = $i;
3624             }
3625
3626             # Split search domain in half to try again.
3627             my $temp = ($upper + $lower) / 2;
3628
3629             # No point in continuing unless $i changes for next time
3630             # in the loop.
3631             if ($temp == $i) {
3632
3633                 # We can't reach the highest element because of the averaging.
3634                 # So if one below the upper edge, force it there and try one
3635                 # more time.
3636                 if ($i == $range_list_size - 2) {
3637
3638                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3639                     $i = $range_list_size - 1;
3640
3641                     # Change $lower as well so if fails next time through,
3642                     # taking the average will yield the same $i, and we will
3643                     # quit with the error message just below.
3644                     $lower = $i;
3645                     next;
3646                 }
3647                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3648                 return;
3649             }
3650             $i = $temp;
3651         } # End of while loop
3652
3653         if (main::DEBUG && $to_trace) {
3654             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3655             trace "i=  [ $i ]", $r->[$i];
3656             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3657         }
3658
3659         # Here we have found the offset.  Cache it as a starting point for the
3660         # next call.
3661         $_search_ranges_cache{$addr} = $i;
3662         return $i;
3663     }
3664
3665     sub _add_delete {
3666         # Add, replace or delete ranges to or from a list.  The $type
3667         # parameter gives which:
3668         #   '+' => insert or replace a range, returning a list of any changed
3669         #          ranges.
3670         #   '-' => delete a range, returning a list of any deleted ranges.
3671         #
3672         # The next three parameters give respectively the start, end, and
3673         # value associated with the range.  'value' should be null unless the
3674         # operation is '+';
3675         #
3676         # The range list is kept sorted so that the range with the lowest
3677         # starting position is first in the list, and generally, adjacent
3678         # ranges with the same values are merged into a single larger one (see
3679         # exceptions below).
3680         #
3681         # There are more parameters; all are key => value pairs:
3682         #   Type    gives the type of the value.  It is only valid for '+'.
3683         #           All ranges have types; if this parameter is omitted, 0 is
3684         #           assumed.  Ranges with type 0 are assumed to obey the
3685         #           Unicode rules for casing, etc; ranges with other types are
3686         #           not.  Otherwise, the type is arbitrary, for the caller's
3687         #           convenience, and looked at only by this routine to keep
3688         #           adjacent ranges of different types from being merged into
3689         #           a single larger range, and when Replace =>
3690         #           $IF_NOT_EQUIVALENT is specified (see just below).
3691         #   Replace  determines what to do if the range list already contains
3692         #            ranges which coincide with all or portions of the input
3693         #            range.  It is only valid for '+':
3694         #       => $NO            means that the new value is not to replace
3695         #                         any existing ones, but any empty gaps of the
3696         #                         range list coinciding with the input range
3697         #                         will be filled in with the new value.
3698         #       => $UNCONDITIONALLY  means to replace the existing values with
3699         #                         this one unconditionally.  However, if the
3700         #                         new and old values are identical, the
3701         #                         replacement is skipped to save cycles
3702         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3703         #          (the default)  with this one if they are not equivalent.
3704         #                         Ranges are equivalent if their types are the
3705         #                         same, and they are the same string; or if
3706         #                         both are type 0 ranges, if their Unicode
3707         #                         standard forms are identical.  In this last
3708         #                         case, the routine chooses the more "modern"
3709         #                         one to use.  This is because some of the
3710         #                         older files are formatted with values that
3711         #                         are, for example, ALL CAPs, whereas the
3712         #                         derived files have a more modern style,
3713         #                         which looks better.  By looking for this
3714         #                         style when the pre-existing and replacement
3715         #                         standard forms are the same, we can move to
3716         #                         the modern style
3717         #       => $MULTIPLE_BEFORE means that if this range duplicates an
3718         #                         existing one, but has a different value,
3719         #                         don't replace the existing one, but insert
3720         #                         this, one so that the same range can occur
3721         #                         multiple times.  They are stored LIFO, so
3722         #                         that the final one inserted is the first one
3723         #                         returned in an ordered search of the table.
3724         #                         If this is an exact duplicate, including the
3725         #                         value, the original will be moved to be
3726         #                         first, before any other duplicate ranges
3727         #                         with different values.
3728         #       => $MULTIPLE_AFTER is like $MULTIPLE_BEFORE, but is stored
3729         #                         FIFO, so that this one is inserted after all
3730         #                         others that currently exist.  If this is an
3731         #                         exact duplicate, including value, of an
3732         #                         existing range, this one is discarded
3733         #                         (leaving the existing one in its original,
3734         #                         higher priority position
3735         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3736         #
3737         # "same value" means identical for non-type-0 ranges, and it means
3738         # having the same standard forms for type-0 ranges.
3739
3740         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3741
3742         my $self = shift;
3743         my $operation = shift;   # '+' for add/replace; '-' for delete;
3744         my $start = shift;
3745         my $end   = shift;
3746         my $value = shift;
3747
3748         my %args = @_;
3749
3750         $value = "" if not defined $value;        # warning: $value can be "0"
3751
3752         my $replace = delete $args{'Replace'};
3753         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3754
3755         my $type = delete $args{'Type'};
3756         $type = 0 unless defined $type;
3757
3758         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3759
3760         my $addr = do { no overloading; pack 'J', $self; };
3761
3762         if ($operation ne '+' && $operation ne '-') {
3763             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3764             return;
3765         }
3766         unless (defined $start && defined $end) {
3767             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3768             return;
3769         }
3770         unless ($end >= $start) {
3771             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3772             return;
3773         }
3774         #local $to_trace = 1 if main::DEBUG;
3775
3776         if ($operation eq '-') {
3777             if ($replace != $IF_NOT_EQUIVALENT) {
3778                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3779                 $replace = $IF_NOT_EQUIVALENT;
3780             }
3781             if ($type) {
3782                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3783                 $type = 0;
3784             }
3785             if ($value ne "") {
3786                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3787                 $value = "";
3788             }
3789         }
3790
3791         my $r = $ranges{$addr};               # The current list of ranges
3792         my $range_list_size = scalar @$r;     # And its size
3793         my $max = $max{$addr};                # The current high code point in
3794                                               # the list of ranges
3795
3796         # Do a special case requiring fewer machine cycles when the new range
3797         # starts after the current highest point.  The Unicode input data is
3798         # structured so this is common.
3799         if ($start > $max) {
3800
3801             trace "$owner_name_of{$addr} $operation", sprintf("%04X..%04X (%s) type=%d; prev max=%04X", $start, $end, $value, $type, $max) if main::DEBUG && $to_trace;
3802             return if $operation eq '-'; # Deleting a non-existing range is a
3803                                          # no-op
3804
3805             # If the new range doesn't logically extend the current final one
3806             # in the range list, create a new range at the end of the range
3807             # list.  (max cleverly is initialized to a negative number not
3808             # adjacent to 0 if the range list is empty, so even adding a range
3809             # to an empty range list starting at 0 will have this 'if'
3810             # succeed.)
3811             if ($start > $max + 1        # non-adjacent means can't extend.
3812                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3813                 || @{$r}[-1]->type != $type # types differ, can't extend.
3814             ) {
3815                 push @$r, Range->new($start, $end,
3816                                      Value => $value,
3817                                      Type => $type);
3818             }
3819             else {
3820
3821                 # Here, the new range starts just after the current highest in
3822                 # the range list, and they have the same type and value.
3823                 # Extend the current range to incorporate the new one.
3824                 @{$r}[-1]->set_end($end);
3825             }
3826
3827             # This becomes the new maximum.
3828             $max{$addr} = $end;
3829
3830             return;
3831         }
3832         #local $to_trace = 0 if main::DEBUG;
3833
3834         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3835
3836         # Here, the input range isn't after the whole rest of the range list.
3837         # Most likely 'splice' will be needed.  The rest of the routine finds
3838         # the needed splice parameters, and if necessary, does the splice.
3839         # First, find the offset parameter needed by the splice function for
3840         # the input range.  Note that the input range may span multiple
3841         # existing ones, but we'll worry about that later.  For now, just find
3842         # the beginning.  If the input range is to be inserted starting in a
3843         # position not currently in the range list, it must (obviously) come
3844         # just after the range below it, and just before the range above it.
3845         # Slightly less obviously, it will occupy the position currently
3846         # occupied by the range that is to come after it.  More formally, we
3847         # are looking for the position, $i, in the array of ranges, such that:
3848         #
3849         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3850         #
3851         # (The ordered relationships within existing ranges are also shown in
3852         # the equation above).  However, if the start of the input range is
3853         # within an existing range, the splice offset should point to that
3854         # existing range's position in the list; that is $i satisfies a
3855         # somewhat different equation, namely:
3856         #
3857         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3858         #
3859         # More briefly, $start can come before or after r[$i]->start, and at
3860         # this point, we don't know which it will be.  However, these
3861         # two equations share these constraints:
3862         #
3863         #   r[$i-1]->end < $start <= r[$i]->end
3864         #
3865         # And that is good enough to find $i.
3866
3867         my $i = $self->_search_ranges($start);
3868         if (! defined $i) {
3869             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3870             return;
3871         }
3872
3873         # The search function returns $i such that:
3874         #
3875         # r[$i-1]->end < $start <= r[$i]->end
3876         #
3877         # That means that $i points to the first range in the range list
3878         # that could possibly be affected by this operation.  We still don't
3879         # know if the start of the input range is within r[$i], or if it
3880         # points to empty space between r[$i-1] and r[$i].
3881         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3882
3883         # Special case the insertion of data that is not to replace any
3884         # existing data.
3885         if ($replace == $NO) {  # If $NO, has to be operation '+'
3886             #local $to_trace = 1 if main::DEBUG;
3887             trace "Doesn't replace" if main::DEBUG && $to_trace;
3888
3889             # Here, the new range is to take effect only on those code points
3890             # that aren't already in an existing range.  This can be done by
3891             # looking through the existing range list and finding the gaps in
3892             # the ranges that this new range affects, and then calling this
3893             # function recursively on each of those gaps, leaving untouched
3894             # anything already in the list.  Gather up a list of the changed
3895             # gaps first so that changes to the internal state as new ranges
3896             # are added won't be a problem.
3897             my @gap_list;
3898
3899             # First, if the starting point of the input range is outside an
3900             # existing one, there is a gap from there to the beginning of the
3901             # existing range -- add a span to fill the part that this new
3902             # range occupies
3903             if ($start < $r->[$i]->start) {
3904                 push @gap_list, Range->new($start,
3905                                            main::min($end,
3906                                                      $r->[$i]->start - 1),
3907                                            Type => $type);
3908                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3909             }
3910
3911             # Then look through the range list for other gaps until we reach
3912             # the highest range affected by the input one.
3913             my $j;
3914             for ($j = $i+1; $j < $range_list_size; $j++) {
3915                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3916                 last if $end < $r->[$j]->start;
3917
3918                 # If there is a gap between when this range starts and the
3919                 # previous one ends, add a span to fill it.  Note that just
3920                 # because there are two ranges doesn't mean there is a
3921                 # non-zero gap between them.  It could be that they have
3922                 # different values or types
3923                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3924                     push @gap_list,
3925                         Range->new($r->[$j-1]->end + 1,
3926                                    $r->[$j]->start - 1,
3927                                    Type => $type);
3928                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3929                 }
3930             }
3931
3932             # Here, we have either found an existing range in the range list,
3933             # beyond the area affected by the input one, or we fell off the
3934             # end of the loop because the input range affects the whole rest
3935             # of the range list.  In either case, $j is 1 higher than the
3936             # highest affected range.  If $j == $i, it means that there are no
3937             # affected ranges, that the entire insertion is in the gap between
3938             # r[$i-1], and r[$i], which we already have taken care of before
3939             # the loop.
3940             # On the other hand, if there are affected ranges, it might be
3941             # that there is a gap that needs filling after the final such
3942             # range to the end of the input range
3943             if ($r->[$j-1]->end < $end) {
3944                     push @gap_list, Range->new(main::max($start,
3945                                                          $r->[$j-1]->end + 1),
3946                                                $end,
3947                                                Type => $type);
3948                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3949             }
3950
3951             # Call recursively to fill in all the gaps.
3952             foreach my $gap (@gap_list) {
3953                 $self->_add_delete($operation,
3954                                    $gap->start,
3955                                    $gap->end,
3956                                    $value,
3957                                    Type => $type);
3958             }
3959
3960             return;
3961         }
3962
3963         # Here, we have taken care of the case where $replace is $NO.
3964         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3965         # If inserting a multiple record, this is where it goes, before the
3966         # first (if any) existing one if inserting LIFO.  (If this is to go
3967         # afterwards, FIFO, we below move the pointer to there.)  These imply
3968         # an insertion, and no change to any existing ranges.  Note that $i
3969         # can be -1 if this new range doesn't actually duplicate any existing,
3970         # and comes at the beginning of the list.
3971         if ($replace == $MULTIPLE_BEFORE || $replace == $MULTIPLE_AFTER) {
3972
3973             if ($start != $end) {
3974                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3975                 return;
3976             }
3977
3978             # If the new code point is within a current range ...
3979             if ($end >= $r->[$i]->start) {
3980
3981                 # Don't add an exact duplicate, as it isn't really a multiple
3982                 my $existing_value = $r->[$i]->value;
3983                 my $existing_type = $r->[$i]->type;
3984                 return if $value eq $existing_value && $type eq $existing_type;
3985
3986                 # If the multiple value is part of an existing range, we want
3987                 # to split up that range, so that only the single code point
3988                 # is affected.  To do this, we first call ourselves
3989                 # recursively to delete that code point from the table, having
3990                 # preserved its current data above.  Then we call ourselves
3991                 # recursively again to add the new multiple, which we know by
3992                 # the test just above is different than the current code
3993                 # point's value, so it will become a range containing a single
3994                 # code point: just itself.  Finally, we add back in the
3995                 # pre-existing code point, which will again be a single code
3996                 # point range.  Because 'i' likely will have changed as a
3997                 # result of these operations, we can't just continue on, but
3998                 # do this operation recursively as well.  If we are inserting
3999                 # LIFO, the pre-existing code point needs to go after the new
4000                 # one, so use MULTIPLE_AFTER; and vice versa.
4001                 if ($r->[$i]->start != $r->[$i]->end) {
4002                     $self->_add_delete('-', $start, $end, "");
4003                     $self->_add_delete('+', $start, $end, $value, Type => $type);
4004                     return $self->_add_delete('+',
4005                             $start, $end,
4006                             $existing_value,
4007                             Type => $existing_type,
4008                             Replace => ($replace == $MULTIPLE_BEFORE)
4009                           &