This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[PATCH] Re: chomp/chop prototype changed?
[perl5.git] / pod / perlsub.pod
1 =head1 NAME
2
3 perlsub - Perl subroutines
4
5 =head1 SYNOPSIS
6
7 To declare subroutines:
8
9     sub NAME;                     # A "forward" declaration.
10     sub NAME(PROTO);              #  ditto, but with prototypes
11     sub NAME : ATTRS;             #  with attributes
12     sub NAME(PROTO) : ATTRS;      #  with attributes and prototypes
13
14     sub NAME BLOCK                # A declaration and a definition.
15     sub NAME(PROTO) BLOCK         #  ditto, but with prototypes
16     sub NAME : ATTRS BLOCK        #  with attributes
17     sub NAME(PROTO) : ATTRS BLOCK #  with prototypes and attributes
18
19 To define an anonymous subroutine at runtime:
20
21     $subref = sub BLOCK;                 # no proto
22     $subref = sub (PROTO) BLOCK;         # with proto
23     $subref = sub : ATTRS BLOCK;         # with attributes
24     $subref = sub (PROTO) : ATTRS BLOCK; # with proto and attributes
25
26 To import subroutines:
27
28     use MODULE qw(NAME1 NAME2 NAME3);
29
30 To call subroutines:
31
32     NAME(LIST);    # & is optional with parentheses.
33     NAME LIST;     # Parentheses optional if predeclared/imported.
34     &NAME(LIST);   # Circumvent prototypes.
35     &NAME;         # Makes current @_ visible to called subroutine.
36
37 =head1 DESCRIPTION
38
39 Like many languages, Perl provides for user-defined subroutines.
40 These may be located anywhere in the main program, loaded in from
41 other files via the C<do>, C<require>, or C<use> keywords, or
42 generated on the fly using C<eval> or anonymous subroutines.
43 You can even call a function indirectly using a variable containing
44 its name or a CODE reference.
45
46 The Perl model for function call and return values is simple: all
47 functions are passed as parameters one single flat list of scalars, and
48 all functions likewise return to their caller one single flat list of
49 scalars.  Any arrays or hashes in these call and return lists will
50 collapse, losing their identities--but you may always use
51 pass-by-reference instead to avoid this.  Both call and return lists may
52 contain as many or as few scalar elements as you'd like.  (Often a
53 function without an explicit return statement is called a subroutine, but
54 there's really no difference from Perl's perspective.)
55
56 Any arguments passed in show up in the array C<@_>.  Therefore, if
57 you called a function with two arguments, those would be stored in
58 C<$_[0]> and C<$_[1]>.  The array C<@_> is a local array, but its
59 elements are aliases for the actual scalar parameters.  In particular,
60 if an element C<$_[0]> is updated, the corresponding argument is
61 updated (or an error occurs if it is not updatable).  If an argument
62 is an array or hash element which did not exist when the function
63 was called, that element is created only when (and if) it is modified
64 or a reference to it is taken.  (Some earlier versions of Perl
65 created the element whether or not the element was assigned to.)
66 Assigning to the whole array C<@_> removes that aliasing, and does
67 not update any arguments.
68
69 The return value of a subroutine is the value of the last expression
70 evaluated.  More explicitly, a C<return> statement may be used to exit the
71 subroutine, optionally specifying the returned value, which will be
72 evaluated in the appropriate context (list, scalar, or void) depending
73 on the context of the subroutine call.  If you specify no return value,
74 the subroutine returns an empty list in list context, the undefined
75 value in scalar context, or nothing in void context.  If you return
76 one or more aggregates (arrays and hashes), these will be flattened
77 together into one large indistinguishable list.
78
79 Perl does not have named formal parameters.  In practice all you
80 do is assign to a C<my()> list of these.  Variables that aren't
81 declared to be private are global variables.  For gory details
82 on creating private variables, see L<"Private Variables via my()">
83 and L<"Temporary Values via local()">.  To create protected
84 environments for a set of functions in a separate package (and
85 probably a separate file), see L<perlmod/"Packages">.
86
87 Example:
88
89     sub max {
90         my $max = shift(@_);
91         foreach $foo (@_) {
92             $max = $foo if $max < $foo;
93         }
94         return $max;
95     }
96     $bestday = max($mon,$tue,$wed,$thu,$fri);
97
98 Example:
99
100     # get a line, combining continuation lines
101     #  that start with whitespace
102
103     sub get_line {
104         $thisline = $lookahead;  # global variables!
105         LINE: while (defined($lookahead = <STDIN>)) {
106             if ($lookahead =~ /^[ \t]/) {
107                 $thisline .= $lookahead;
108             }
109             else {
110                 last LINE;
111             }
112         }
113         return $thisline;
114     }
115
116     $lookahead = <STDIN>;       # get first line
117     while (defined($line = get_line())) {
118         ...
119     }
120
121 Assigning to a list of private variables to name your arguments:
122
123     sub maybeset {
124         my($key, $value) = @_;
125         $Foo{$key} = $value unless $Foo{$key};
126     }
127
128 Because the assignment copies the values, this also has the effect
129 of turning call-by-reference into call-by-value.  Otherwise a
130 function is free to do in-place modifications of C<@_> and change
131 its caller's values.
132
133     upcase_in($v1, $v2);  # this changes $v1 and $v2
134     sub upcase_in {
135         for (@_) { tr/a-z/A-Z/ }
136     }
137
138 You aren't allowed to modify constants in this way, of course.  If an
139 argument were actually literal and you tried to change it, you'd take a
140 (presumably fatal) exception.   For example, this won't work:
141
142     upcase_in("frederick");
143
144 It would be much safer if the C<upcase_in()> function
145 were written to return a copy of its parameters instead
146 of changing them in place:
147
148     ($v3, $v4) = upcase($v1, $v2);  # this doesn't change $v1 and $v2
149     sub upcase {
150         return unless defined wantarray;  # void context, do nothing
151         my @parms = @_;
152         for (@parms) { tr/a-z/A-Z/ }
153         return wantarray ? @parms : $parms[0];
154     }
155
156 Notice how this (unprototyped) function doesn't care whether it was
157 passed real scalars or arrays.  Perl sees all arguments as one big,
158 long, flat parameter list in C<@_>.  This is one area where
159 Perl's simple argument-passing style shines.  The C<upcase()>
160 function would work perfectly well without changing the C<upcase()>
161 definition even if we fed it things like this:
162
163     @newlist   = upcase(@list1, @list2);
164     @newlist   = upcase( split /:/, $var );
165
166 Do not, however, be tempted to do this:
167
168     (@a, @b)   = upcase(@list1, @list2);
169
170 Like the flattened incoming parameter list, the return list is also
171 flattened on return.  So all you have managed to do here is stored
172 everything in C<@a> and made C<@b> an empty list.  See 
173 L<Pass by Reference> for alternatives.
174
175 A subroutine may be called using an explicit C<&> prefix.  The
176 C<&> is optional in modern Perl, as are parentheses if the
177 subroutine has been predeclared.  The C<&> is I<not> optional
178 when just naming the subroutine, such as when it's used as
179 an argument to defined() or undef().  Nor is it optional when you
180 want to do an indirect subroutine call with a subroutine name or
181 reference using the C<&$subref()> or C<&{$subref}()> constructs,
182 although the C<< $subref->() >> notation solves that problem.
183 See L<perlref> for more about all that.
184
185 Subroutines may be called recursively.  If a subroutine is called
186 using the C<&> form, the argument list is optional, and if omitted,
187 no C<@_> array is set up for the subroutine: the C<@_> array at the
188 time of the call is visible to subroutine instead.  This is an
189 efficiency mechanism that new users may wish to avoid.
190
191     &foo(1,2,3);        # pass three arguments
192     foo(1,2,3);         # the same
193
194     foo();              # pass a null list
195     &foo();             # the same
196
197     &foo;               # foo() get current args, like foo(@_) !!
198     foo;                # like foo() IFF sub foo predeclared, else "foo"
199
200 Not only does the C<&> form make the argument list optional, it also
201 disables any prototype checking on arguments you do provide.  This
202 is partly for historical reasons, and partly for having a convenient way
203 to cheat if you know what you're doing.  See L<Prototypes> below.
204
205 Functions whose names are in all upper case are reserved to the Perl
206 core, as are modules whose names are in all lower case.  A
207 function in all capitals is a loosely-held convention meaning it
208 will be called indirectly by the run-time system itself, usually
209 due to a triggered event.  Functions that do special, pre-defined
210 things include C<BEGIN>, C<CHECK>, C<INIT>, C<END>, C<AUTOLOAD>,
211 C<CLONE> and C<DESTROY>--plus all functions mentioned in L<perltie>.
212
213 =head2 Private Variables via my()
214
215 Synopsis:
216
217     my $foo;            # declare $foo lexically local
218     my (@wid, %get);    # declare list of variables local
219     my $foo = "flurp";  # declare $foo lexical, and init it
220     my @oof = @bar;     # declare @oof lexical, and init it
221     my $x : Foo = $y;   # similar, with an attribute applied
222
223 B<WARNING>: The use of attribute lists on C<my> declarations is
224 experimental.  This feature should not be relied upon.  It may
225 change or disappear in future releases of Perl.  See L<attributes>.
226
227 The C<my> operator declares the listed variables to be lexically
228 confined to the enclosing block, conditional (C<if/unless/elsif/else>),
229 loop (C<for/foreach/while/until/continue>), subroutine, C<eval>,
230 or C<do/require/use>'d file.  If more than one value is listed, the
231 list must be placed in parentheses.  All listed elements must be
232 legal lvalues.  Only alphanumeric identifiers may be lexically
233 scoped--magical built-ins like C<$/> must currently be C<local>ize
234 with C<local> instead.
235
236 Unlike dynamic variables created by the C<local> operator, lexical
237 variables declared with C<my> are totally hidden from the outside
238 world, including any called subroutines.  This is true if it's the
239 same subroutine called from itself or elsewhere--every call gets
240 its own copy.
241
242 This doesn't mean that a C<my> variable declared in a statically
243 enclosing lexical scope would be invisible.  Only dynamic scopes
244 are cut off.   For example, the C<bumpx()> function below has access
245 to the lexical $x variable because both the C<my> and the C<sub>
246 occurred at the same scope, presumably file scope.
247
248     my $x = 10;
249     sub bumpx { $x++ } 
250
251 An C<eval()>, however, can see lexical variables of the scope it is
252 being evaluated in, so long as the names aren't hidden by declarations within
253 the C<eval()> itself.  See L<perlref>.
254
255 The parameter list to my() may be assigned to if desired, which allows you
256 to initialize your variables.  (If no initializer is given for a
257 particular variable, it is created with the undefined value.)  Commonly
258 this is used to name input parameters to a subroutine.  Examples:
259
260     $arg = "fred";        # "global" variable
261     $n = cube_root(27);
262     print "$arg thinks the root is $n\n";
263  fred thinks the root is 3
264
265     sub cube_root {
266         my $arg = shift;  # name doesn't matter
267         $arg **= 1/3;
268         return $arg;
269     }
270
271 The C<my> is simply a modifier on something you might assign to.  So when
272 you do assign to variables in its argument list, C<my> doesn't
273 change whether those variables are viewed as a scalar or an array.  So
274
275     my ($foo) = <STDIN>;                # WRONG?
276     my @FOO = <STDIN>;
277
278 both supply a list context to the right-hand side, while
279
280     my $foo = <STDIN>;
281
282 supplies a scalar context.  But the following declares only one variable:
283
284     my $foo, $bar = 1;                  # WRONG
285
286 That has the same effect as
287
288     my $foo;
289     $bar = 1;
290
291 The declared variable is not introduced (is not visible) until after
292 the current statement.  Thus,
293
294     my $x = $x;
295
296 can be used to initialize a new $x with the value of the old $x, and
297 the expression
298
299     my $x = 123 and $x == 123
300
301 is false unless the old $x happened to have the value C<123>.
302
303 Lexical scopes of control structures are not bounded precisely by the
304 braces that delimit their controlled blocks; control expressions are
305 part of that scope, too.  Thus in the loop
306
307     while (my $line = <>) {
308         $line = lc $line;
309     } continue {
310         print $line;
311     }
312
313 the scope of $line extends from its declaration throughout the rest of
314 the loop construct (including the C<continue> clause), but not beyond
315 it.  Similarly, in the conditional
316
317     if ((my $answer = <STDIN>) =~ /^yes$/i) {
318         user_agrees();
319     } elsif ($answer =~ /^no$/i) {
320         user_disagrees();
321     } else {
322         chomp $answer;
323         die "'$answer' is neither 'yes' nor 'no'";
324     }
325
326 the scope of $answer extends from its declaration through the rest
327 of that conditional, including any C<elsif> and C<else> clauses, 
328 but not beyond it.
329
330 None of the foregoing text applies to C<if/unless> or C<while/until>
331 modifiers appended to simple statements.  Such modifiers are not
332 control structures and have no effect on scoping.
333
334 The C<foreach> loop defaults to scoping its index variable dynamically
335 in the manner of C<local>.  However, if the index variable is
336 prefixed with the keyword C<my>, or if there is already a lexical
337 by that name in scope, then a new lexical is created instead.  Thus
338 in the loop
339
340     for my $i (1, 2, 3) {
341         some_function();
342     }
343
344 the scope of $i extends to the end of the loop, but not beyond it,
345 rendering the value of $i inaccessible within C<some_function()>.
346
347 Some users may wish to encourage the use of lexically scoped variables.
348 As an aid to catching implicit uses to package variables,
349 which are always global, if you say
350
351     use strict 'vars';
352
353 then any variable mentioned from there to the end of the enclosing
354 block must either refer to a lexical variable, be predeclared via
355 C<our> or C<use vars>, or else must be fully qualified with the package name.
356 A compilation error results otherwise.  An inner block may countermand
357 this with C<no strict 'vars'>.
358
359 A C<my> has both a compile-time and a run-time effect.  At compile
360 time, the compiler takes notice of it.  The principal usefulness
361 of this is to quiet C<use strict 'vars'>, but it is also essential
362 for generation of closures as detailed in L<perlref>.  Actual
363 initialization is delayed until run time, though, so it gets executed
364 at the appropriate time, such as each time through a loop, for
365 example.
366
367 Variables declared with C<my> are not part of any package and are therefore
368 never fully qualified with the package name.  In particular, you're not
369 allowed to try to make a package variable (or other global) lexical:
370
371     my $pack::var;      # ERROR!  Illegal syntax
372     my $_;              # also illegal (currently)
373
374 In fact, a dynamic variable (also known as package or global variables)
375 are still accessible using the fully qualified C<::> notation even while a
376 lexical of the same name is also visible:
377
378     package main;
379     local $x = 10;
380     my    $x = 20;
381     print "$x and $::x\n";
382
383 That will print out C<20> and C<10>.
384
385 You may declare C<my> variables at the outermost scope of a file
386 to hide any such identifiers from the world outside that file.  This
387 is similar in spirit to C's static variables when they are used at
388 the file level.  To do this with a subroutine requires the use of
389 a closure (an anonymous function that accesses enclosing lexicals).
390 If you want to create a private subroutine that cannot be called
391 from outside that block, it can declare a lexical variable containing
392 an anonymous sub reference:
393
394     my $secret_version = '1.001-beta';
395     my $secret_sub = sub { print $secret_version };
396     &$secret_sub();
397
398 As long as the reference is never returned by any function within the
399 module, no outside module can see the subroutine, because its name is not in
400 any package's symbol table.  Remember that it's not I<REALLY> called
401 C<$some_pack::secret_version> or anything; it's just $secret_version,
402 unqualified and unqualifiable.
403
404 This does not work with object methods, however; all object methods
405 have to be in the symbol table of some package to be found.  See
406 L<perlref/"Function Templates"> for something of a work-around to
407 this.
408
409 =head2 Persistent Private Variables
410
411 Just because a lexical variable is lexically (also called statically)
412 scoped to its enclosing block, C<eval>, or C<do> FILE, this doesn't mean that
413 within a function it works like a C static.  It normally works more
414 like a C auto, but with implicit garbage collection.  
415
416 Unlike local variables in C or C++, Perl's lexical variables don't
417 necessarily get recycled just because their scope has exited.
418 If something more permanent is still aware of the lexical, it will
419 stick around.  So long as something else references a lexical, that
420 lexical won't be freed--which is as it should be.  You wouldn't want
421 memory being free until you were done using it, or kept around once you
422 were done.  Automatic garbage collection takes care of this for you.
423
424 This means that you can pass back or save away references to lexical
425 variables, whereas to return a pointer to a C auto is a grave error.
426 It also gives us a way to simulate C's function statics.  Here's a
427 mechanism for giving a function private variables with both lexical
428 scoping and a static lifetime.  If you do want to create something like
429 C's static variables, just enclose the whole function in an extra block,
430 and put the static variable outside the function but in the block.
431
432     {
433         my $secret_val = 0;
434         sub gimme_another {
435             return ++$secret_val;
436         }
437     }
438     # $secret_val now becomes unreachable by the outside
439     # world, but retains its value between calls to gimme_another
440
441 If this function is being sourced in from a separate file
442 via C<require> or C<use>, then this is probably just fine.  If it's
443 all in the main program, you'll need to arrange for the C<my>
444 to be executed early, either by putting the whole block above
445 your main program, or more likely, placing merely a C<BEGIN>
446 sub around it to make sure it gets executed before your program
447 starts to run:
448
449     sub BEGIN {
450         my $secret_val = 0;
451         sub gimme_another {
452             return ++$secret_val;
453         }
454     }
455
456 See L<perlmod/"Package Constructors and Destructors"> about the
457 special triggered functions, C<BEGIN>, C<CHECK>, C<INIT> and C<END>.
458
459 If declared at the outermost scope (the file scope), then lexicals
460 work somewhat like C's file statics.  They are available to all
461 functions in that same file declared below them, but are inaccessible
462 from outside that file.  This strategy is sometimes used in modules
463 to create private variables that the whole module can see.
464
465 =head2 Temporary Values via local()
466
467 B<WARNING>: In general, you should be using C<my> instead of C<local>, because
468 it's faster and safer.  Exceptions to this include the global punctuation
469 variables, filehandles and formats, and direct manipulation of the Perl
470 symbol table itself.  Format variables often use C<local> though, as do
471 other variables whose current value must be visible to called
472 subroutines.
473
474 Synopsis:
475
476     local $foo;                 # declare $foo dynamically local
477     local (@wid, %get);         # declare list of variables local
478     local $foo = "flurp";       # declare $foo dynamic, and init it
479     local @oof = @bar;          # declare @oof dynamic, and init it
480
481     local *FH;                  # localize $FH, @FH, %FH, &FH  ...
482     local *merlyn = *randal;    # now $merlyn is really $randal, plus
483                                 #     @merlyn is really @randal, etc
484     local *merlyn = 'randal';   # SAME THING: promote 'randal' to *randal
485     local *merlyn = \$randal;   # just alias $merlyn, not @merlyn etc
486
487 A C<local> modifies its listed variables to be "local" to the
488 enclosing block, C<eval>, or C<do FILE>--and to I<any subroutine
489 called from within that block>.  A C<local> just gives temporary
490 values to global (meaning package) variables.  It does I<not> create
491 a local variable.  This is known as dynamic scoping.  Lexical scoping
492 is done with C<my>, which works more like C's auto declarations.
493
494 If more than one variable is given to C<local>, they must be placed in
495 parentheses.  All listed elements must be legal lvalues.  This operator works
496 by saving the current values of those variables in its argument list on a
497 hidden stack and restoring them upon exiting the block, subroutine, or
498 eval.  This means that called subroutines can also reference the local
499 variable, but not the global one.  The argument list may be assigned to if
500 desired, which allows you to initialize your local variables.  (If no
501 initializer is given for a particular variable, it is created with an
502 undefined value.)  Commonly this is used to name the parameters to a
503 subroutine.  Examples:
504
505     for $i ( 0 .. 9 ) {
506         $digits{$i} = $i;
507     }
508     # assume this function uses global %digits hash
509     parse_num();
510
511     # now temporarily add to %digits hash
512     if ($base12) {
513         # (NOTE: not claiming this is efficient!)
514         local %digits  = (%digits, 't' => 10, 'e' => 11);
515         parse_num();  # parse_num gets this new %digits!
516     }
517     # old %digits restored here
518
519 Because C<local> is a run-time operator, it gets executed each time
520 through a loop.  In releases of Perl previous to 5.0, this used more stack
521 storage each time until the loop was exited.  Perl now reclaims the space
522 each time through, but it's still more efficient to declare your variables
523 outside the loop.
524
525 A C<local> is simply a modifier on an lvalue expression.  When you assign to
526 a C<local>ized variable, the C<local> doesn't change whether its list is viewed
527 as a scalar or an array.  So
528
529     local($foo) = <STDIN>;
530     local @FOO = <STDIN>;
531
532 both supply a list context to the right-hand side, while
533
534     local $foo = <STDIN>;
535
536 supplies a scalar context.
537
538 A note about C<local()> and composite types is in order.  Something
539 like C<local(%foo)> works by temporarily placing a brand new hash in
540 the symbol table.  The old hash is left alone, but is hidden "behind"
541 the new one.
542
543 This means the old variable is completely invisible via the symbol
544 table (i.e. the hash entry in the C<*foo> typeglob) for the duration
545 of the dynamic scope within which the C<local()> was seen.  This
546 has the effect of allowing one to temporarily occlude any magic on
547 composite types.  For instance, this will briefly alter a tied
548 hash to some other implementation:
549
550     tie %ahash, 'APackage';
551     [...]
552     {
553        local %ahash;
554        tie %ahash, 'BPackage';
555        [..called code will see %ahash tied to 'BPackage'..]
556        {
557           local %ahash;
558           [..%ahash is a normal (untied) hash here..]
559        }
560     }
561     [..%ahash back to its initial tied self again..]
562
563 As another example, a custom implementation of C<%ENV> might look
564 like this:
565
566     {
567         local %ENV;
568         tie %ENV, 'MyOwnEnv';
569         [..do your own fancy %ENV manipulation here..]
570     }
571     [..normal %ENV behavior here..]
572
573 It's also worth taking a moment to explain what happens when you
574 C<local>ize a member of a composite type (i.e. an array or hash element).
575 In this case, the element is C<local>ized I<by name>. This means that
576 when the scope of the C<local()> ends, the saved value will be
577 restored to the hash element whose key was named in the C<local()>, or
578 the array element whose index was named in the C<local()>.  If that
579 element was deleted while the C<local()> was in effect (e.g. by a
580 C<delete()> from a hash or a C<shift()> of an array), it will spring
581 back into existence, possibly extending an array and filling in the
582 skipped elements with C<undef>.  For instance, if you say
583
584     %hash = ( 'This' => 'is', 'a' => 'test' );
585     @ary  = ( 0..5 );
586     {
587          local($ary[5]) = 6;
588          local($hash{'a'}) = 'drill';
589          while (my $e = pop(@ary)) {
590              print "$e . . .\n";
591              last unless $e > 3;
592          }
593          if (@ary) {
594              $hash{'only a'} = 'test';
595              delete $hash{'a'};
596          }
597     }
598     print join(' ', map { "$_ $hash{$_}" } sort keys %hash),".\n";
599     print "The array has ",scalar(@ary)," elements: ",
600           join(', ', map { defined $_ ? $_ : 'undef' } @ary),"\n";
601
602 Perl will print
603
604     6 . . .
605     4 . . .
606     3 . . .
607     This is a test only a test.
608     The array has 6 elements: 0, 1, 2, undef, undef, 5
609
610 The behavior of local() on non-existent members of composite
611 types is subject to change in future.
612
613 =head2 Lvalue subroutines
614
615 B<WARNING>: Lvalue subroutines are still experimental and the implementation
616 may change in future versions of Perl.
617
618 It is possible to return a modifiable value from a subroutine.
619 To do this, you have to declare the subroutine to return an lvalue.
620
621     my $val;
622     sub canmod : lvalue {
623         $val;
624     }
625     sub nomod {
626         $val;
627     }
628
629     canmod() = 5;   # assigns to $val
630     nomod()  = 5;   # ERROR
631
632 The scalar/list context for the subroutine and for the right-hand
633 side of assignment is determined as if the subroutine call is replaced
634 by a scalar. For example, consider:
635
636     data(2,3) = get_data(3,4);
637
638 Both subroutines here are called in a scalar context, while in:
639
640     (data(2,3)) = get_data(3,4);
641
642 and in:
643
644     (data(2),data(3)) = get_data(3,4);
645
646 all the subroutines are called in a list context.
647
648 =head2 Passing Symbol Table Entries (typeglobs)
649
650 B<WARNING>: The mechanism described in this section was originally
651 the only way to simulate pass-by-reference in older versions of
652 Perl.  While it still works fine in modern versions, the new reference
653 mechanism is generally easier to work with.  See below.
654
655 Sometimes you don't want to pass the value of an array to a subroutine
656 but rather the name of it, so that the subroutine can modify the global
657 copy of it rather than working with a local copy.  In perl you can
658 refer to all objects of a particular name by prefixing the name
659 with a star: C<*foo>.  This is often known as a "typeglob", because the
660 star on the front can be thought of as a wildcard match for all the
661 funny prefix characters on variables and subroutines and such.
662
663 When evaluated, the typeglob produces a scalar value that represents
664 all the objects of that name, including any filehandle, format, or
665 subroutine.  When assigned to, it causes the name mentioned to refer to
666 whatever C<*> value was assigned to it.  Example:
667
668     sub doubleary {
669         local(*someary) = @_;
670         foreach $elem (@someary) {
671             $elem *= 2;
672         }
673     }
674     doubleary(*foo);
675     doubleary(*bar);
676
677 Scalars are already passed by reference, so you can modify
678 scalar arguments without using this mechanism by referring explicitly
679 to C<$_[0]> etc.  You can modify all the elements of an array by passing
680 all the elements as scalars, but you have to use the C<*> mechanism (or
681 the equivalent reference mechanism) to C<push>, C<pop>, or change the size of
682 an array.  It will certainly be faster to pass the typeglob (or reference).
683
684 Even if you don't want to modify an array, this mechanism is useful for
685 passing multiple arrays in a single LIST, because normally the LIST
686 mechanism will merge all the array values so that you can't extract out
687 the individual arrays.  For more on typeglobs, see
688 L<perldata/"Typeglobs and Filehandles">.
689
690 =head2 When to Still Use local()
691
692 Despite the existence of C<my>, there are still three places where the
693 C<local> operator still shines.  In fact, in these three places, you
694 I<must> use C<local> instead of C<my>.
695
696 =over 4
697
698 =item 1.
699
700 You need to give a global variable a temporary value, especially $_.
701
702 The global variables, like C<@ARGV> or the punctuation variables, must be 
703 C<local>ized with C<local()>.  This block reads in F</etc/motd>, and splits
704 it up into chunks separated by lines of equal signs, which are placed
705 in C<@Fields>.
706
707     {
708         local @ARGV = ("/etc/motd");
709         local $/ = undef;
710         local $_ = <>;  
711         @Fields = split /^\s*=+\s*$/;
712     } 
713
714 It particular, it's important to C<local>ize $_ in any routine that assigns
715 to it.  Look out for implicit assignments in C<while> conditionals.
716
717 =item 2.
718
719 You need to create a local file or directory handle or a local function.
720
721 A function that needs a filehandle of its own must use
722 C<local()> on a complete typeglob.   This can be used to create new symbol
723 table entries:
724
725     sub ioqueue {
726         local  (*READER, *WRITER);    # not my!
727         pipe    (READER,  WRITER);    or die "pipe: $!";
728         return (*READER, *WRITER);
729     }
730     ($head, $tail) = ioqueue();
731
732 See the Symbol module for a way to create anonymous symbol table
733 entries.
734
735 Because assignment of a reference to a typeglob creates an alias, this
736 can be used to create what is effectively a local function, or at least,
737 a local alias.
738
739     {
740         local *grow = \&shrink; # only until this block exists
741         grow();                 # really calls shrink()
742         move();                 # if move() grow()s, it shrink()s too
743     }
744     grow();                     # get the real grow() again
745
746 See L<perlref/"Function Templates"> for more about manipulating
747 functions by name in this way.
748
749 =item 3.
750
751 You want to temporarily change just one element of an array or hash.
752
753 You can C<local>ize just one element of an aggregate.  Usually this
754 is done on dynamics:
755
756     {
757         local $SIG{INT} = 'IGNORE';
758         funct();                            # uninterruptible
759     } 
760     # interruptibility automatically restored here
761
762 But it also works on lexically declared aggregates.  Prior to 5.005,
763 this operation could on occasion misbehave.
764
765 =back
766
767 =head2 Pass by Reference
768
769 If you want to pass more than one array or hash into a function--or
770 return them from it--and have them maintain their integrity, then
771 you're going to have to use an explicit pass-by-reference.  Before you
772 do that, you need to understand references as detailed in L<perlref>.
773 This section may not make much sense to you otherwise.
774
775 Here are a few simple examples.  First, let's pass in several arrays
776 to a function and have it C<pop> all of then, returning a new list
777 of all their former last elements:
778
779     @tailings = popmany ( \@a, \@b, \@c, \@d );
780
781     sub popmany {
782         my $aref;
783         my @retlist = ();
784         foreach $aref ( @_ ) {
785             push @retlist, pop @$aref;
786         }
787         return @retlist;
788     }
789
790 Here's how you might write a function that returns a
791 list of keys occurring in all the hashes passed to it:
792
793     @common = inter( \%foo, \%bar, \%joe );
794     sub inter {
795         my ($k, $href, %seen); # locals
796         foreach $href (@_) {
797             while ( $k = each %$href ) {
798                 $seen{$k}++;
799             }
800         }
801         return grep { $seen{$_} == @_ } keys %seen;
802     }
803
804 So far, we're using just the normal list return mechanism.
805 What happens if you want to pass or return a hash?  Well,
806 if you're using only one of them, or you don't mind them
807 concatenating, then the normal calling convention is ok, although
808 a little expensive.
809
810 Where people get into trouble is here:
811
812     (@a, @b) = func(@c, @d);
813 or
814     (%a, %b) = func(%c, %d);
815
816 That syntax simply won't work.  It sets just C<@a> or C<%a> and
817 clears the C<@b> or C<%b>.  Plus the function didn't get passed
818 into two separate arrays or hashes: it got one long list in C<@_>,
819 as always.
820
821 If you can arrange for everyone to deal with this through references, it's
822 cleaner code, although not so nice to look at.  Here's a function that
823 takes two array references as arguments, returning the two array elements
824 in order of how many elements they have in them:
825
826     ($aref, $bref) = func(\@c, \@d);
827     print "@$aref has more than @$bref\n";
828     sub func {
829         my ($cref, $dref) = @_;
830         if (@$cref > @$dref) {
831             return ($cref, $dref);
832         } else {
833             return ($dref, $cref);
834         }
835     }
836
837 It turns out that you can actually do this also:
838
839     (*a, *b) = func(\@c, \@d);
840     print "@a has more than @b\n";
841     sub func {
842         local (*c, *d) = @_;
843         if (@c > @d) {
844             return (\@c, \@d);
845         } else {
846             return (\@d, \@c);
847         }
848     }
849
850 Here we're using the typeglobs to do symbol table aliasing.  It's
851 a tad subtle, though, and also won't work if you're using C<my>
852 variables, because only globals (even in disguise as C<local>s)
853 are in the symbol table.
854
855 If you're passing around filehandles, you could usually just use the bare
856 typeglob, like C<*STDOUT>, but typeglobs references work, too.
857 For example:
858
859     splutter(\*STDOUT);
860     sub splutter {
861         my $fh = shift;
862         print $fh "her um well a hmmm\n";
863     }
864
865     $rec = get_rec(\*STDIN);
866     sub get_rec {
867         my $fh = shift;
868         return scalar <$fh>;
869     }
870
871 If you're planning on generating new filehandles, you could do this.
872 Notice to pass back just the bare *FH, not its reference.
873
874     sub openit {
875         my $path = shift;
876         local *FH;
877         return open (FH, $path) ? *FH : undef;
878     }
879
880 =head2 Prototypes
881
882 Perl supports a very limited kind of compile-time argument checking
883 using function prototyping.  If you declare
884
885     sub mypush (\@@)
886
887 then C<mypush()> takes arguments exactly like C<push()> does.  The
888 function declaration must be visible at compile time.  The prototype
889 affects only interpretation of new-style calls to the function,
890 where new-style is defined as not using the C<&> character.  In
891 other words, if you call it like a built-in function, then it behaves
892 like a built-in function.  If you call it like an old-fashioned
893 subroutine, then it behaves like an old-fashioned subroutine.  It
894 naturally falls out from this rule that prototypes have no influence
895 on subroutine references like C<\&foo> or on indirect subroutine
896 calls like C<&{$subref}> or C<< $subref->() >>.
897
898 Method calls are not influenced by prototypes either, because the
899 function to be called is indeterminate at compile time, since
900 the exact code called depends on inheritance.
901
902 Because the intent of this feature is primarily to let you define
903 subroutines that work like built-in functions, here are prototypes
904 for some other functions that parse almost exactly like the
905 corresponding built-in.
906
907     Declared as                 Called as
908
909     sub mylink ($$)          mylink $old, $new
910     sub myvec ($$$)          myvec $var, $offset, 1
911     sub myindex ($$;$)       myindex &getstring, "substr"
912     sub mysyswrite ($$$;$)   mysyswrite $buf, 0, length($buf) - $off, $off
913     sub myreverse (@)        myreverse $a, $b, $c
914     sub myjoin ($@)          myjoin ":", $a, $b, $c
915     sub mypop (\@)           mypop @array
916     sub mysplice (\@$$@)     mysplice @array, @array, 0, @pushme
917     sub mykeys (\%)          mykeys %{$hashref}
918     sub myopen (*;$)         myopen HANDLE, $name
919     sub mypipe (**)          mypipe READHANDLE, WRITEHANDLE
920     sub mygrep (&@)          mygrep { /foo/ } $a, $b, $c
921     sub myrand ($)           myrand 42
922     sub mytime ()            mytime
923
924 Any backslashed prototype character represents an actual argument
925 that absolutely must start with that character.  The value passed
926 as part of C<@_> will be a reference to the actual argument given
927 in the subroutine call, obtained by applying C<\> to that argument.
928
929 You can also backslash several argument types simultaneously by using
930 the C<\[]> notation:
931
932     sub myref (\[$@%&*])
933
934 will allow calling myref() as
935
936     myref $var
937     myref @array
938     myref %hash
939     myref &sub
940     myref *glob
941
942 and the first argument of myref() will be a reference to
943 a scalar, an array, a hash, a code, or a glob.
944
945 Unbackslashed prototype characters have special meanings.  Any
946 unbackslashed C<@> or C<%> eats all remaining arguments, and forces
947 list context.  An argument represented by C<$> forces scalar context.  An
948 C<&> requires an anonymous subroutine, which, if passed as the first
949 argument, does not require the C<sub> keyword or a subsequent comma.
950
951 A C<*> allows the subroutine to accept a bareword, constant, scalar expression,
952 typeglob, or a reference to a typeglob in that slot.  The value will be
953 available to the subroutine either as a simple scalar, or (in the latter
954 two cases) as a reference to the typeglob.  If you wish to always convert
955 such arguments to a typeglob reference, use Symbol::qualify_to_ref() as
956 follows:
957
958     use Symbol 'qualify_to_ref';
959
960     sub foo (*) {
961         my $fh = qualify_to_ref(shift, caller);
962         ...
963     }
964
965 A semicolon separates mandatory arguments from optional arguments.
966 It is redundant before C<@> or C<%>, which gobble up everything else.
967
968 Note how the last three examples in the table above are treated
969 specially by the parser.  C<mygrep()> is parsed as a true list
970 operator, C<myrand()> is parsed as a true unary operator with unary
971 precedence the same as C<rand()>, and C<mytime()> is truly without
972 arguments, just like C<time()>.  That is, if you say
973
974     mytime +2;
975
976 you'll get C<mytime() + 2>, not C<mytime(2)>, which is how it would be parsed
977 without a prototype.
978
979 The interesting thing about C<&> is that you can generate new syntax with it,
980 provided it's in the initial position:
981
982     sub try (&@) {
983         my($try,$catch) = @_;
984         eval { &$try };
985         if ($@) {
986             local $_ = $@;
987             &$catch;
988         }
989     }
990     sub catch (&) { $_[0] }
991
992     try {
993         die "phooey";
994     } catch {
995         /phooey/ and print "unphooey\n";
996     };
997
998 That prints C<"unphooey">.  (Yes, there are still unresolved
999 issues having to do with visibility of C<@_>.  I'm ignoring that
1000 question for the moment.  (But note that if we make C<@_> lexically
1001 scoped, those anonymous subroutines can act like closures... (Gee,
1002 is this sounding a little Lispish?  (Never mind.))))
1003
1004 And here's a reimplementation of the Perl C<grep> operator:
1005
1006     sub mygrep (&@) {
1007         my $code = shift;
1008         my @result;
1009         foreach $_ (@_) {
1010             push(@result, $_) if &$code;
1011         }
1012         @result;
1013     }
1014
1015 Some folks would prefer full alphanumeric prototypes.  Alphanumerics have
1016 been intentionally left out of prototypes for the express purpose of
1017 someday in the future adding named, formal parameters.  The current
1018 mechanism's main goal is to let module writers provide better diagnostics
1019 for module users.  Larry feels the notation quite understandable to Perl
1020 programmers, and that it will not intrude greatly upon the meat of the
1021 module, nor make it harder to read.  The line noise is visually
1022 encapsulated into a small pill that's easy to swallow.
1023
1024 It's probably best to prototype new functions, not retrofit prototyping
1025 into older ones.  That's because you must be especially careful about
1026 silent impositions of differing list versus scalar contexts.  For example,
1027 if you decide that a function should take just one parameter, like this:
1028
1029     sub func ($) {
1030         my $n = shift;
1031         print "you gave me $n\n";
1032     }
1033
1034 and someone has been calling it with an array or expression
1035 returning a list:
1036
1037     func(@foo);
1038     func( split /:/ );
1039
1040 Then you've just supplied an automatic C<scalar> in front of their
1041 argument, which can be more than a bit surprising.  The old C<@foo>
1042 which used to hold one thing doesn't get passed in.  Instead,
1043 C<func()> now gets passed in a C<1>; that is, the number of elements
1044 in C<@foo>.  And the C<split> gets called in scalar context so it
1045 starts scribbling on your C<@_> parameter list.  Ouch!
1046
1047 This is all very powerful, of course, and should be used only in moderation
1048 to make the world a better place.
1049
1050 =head2 Constant Functions
1051
1052 Functions with a prototype of C<()> are potential candidates for
1053 inlining.  If the result after optimization and constant folding
1054 is either a constant or a lexically-scoped scalar which has no other
1055 references, then it will be used in place of function calls made
1056 without C<&>.  Calls made using C<&> are never inlined.  (See
1057 F<constant.pm> for an easy way to declare most constants.)
1058
1059 The following functions would all be inlined:
1060
1061     sub pi ()           { 3.14159 }             # Not exact, but close.
1062     sub PI ()           { 4 * atan2 1, 1 }      # As good as it gets,
1063                                                 # and it's inlined, too!
1064     sub ST_DEV ()       { 0 }
1065     sub ST_INO ()       { 1 }
1066
1067     sub FLAG_FOO ()     { 1 << 8 }
1068     sub FLAG_BAR ()     { 1 << 9 }
1069     sub FLAG_MASK ()    { FLAG_FOO | FLAG_BAR }
1070
1071     sub OPT_BAZ ()      { not (0x1B58 & FLAG_MASK) }
1072     sub BAZ_VAL () {
1073         if (OPT_BAZ) {
1074             return 23;
1075         }
1076         else {
1077             return 42;
1078         }
1079     }
1080
1081     sub N () { int(BAZ_VAL) / 3 }
1082     BEGIN {
1083         my $prod = 1;
1084         for (1..N) { $prod *= $_ }
1085         sub N_FACTORIAL () { $prod }
1086     }
1087
1088 If you redefine a subroutine that was eligible for inlining, you'll get
1089 a mandatory warning.  (You can use this warning to tell whether or not a
1090 particular subroutine is considered constant.)  The warning is
1091 considered severe enough not to be optional because previously compiled
1092 invocations of the function will still be using the old value of the
1093 function.  If you need to be able to redefine the subroutine, you need to
1094 ensure that it isn't inlined, either by dropping the C<()> prototype
1095 (which changes calling semantics, so beware) or by thwarting the
1096 inlining mechanism in some other way, such as
1097
1098     sub not_inlined () {
1099         23 if $];
1100     }
1101
1102 =head2 Overriding Built-in Functions
1103
1104 Many built-in functions may be overridden, though this should be tried
1105 only occasionally and for good reason.  Typically this might be
1106 done by a package attempting to emulate missing built-in functionality
1107 on a non-Unix system.
1108
1109 Overriding may be done only by importing the name from a
1110 module--ordinary predeclaration isn't good enough.  However, the
1111 C<use subs> pragma lets you, in effect, predeclare subs
1112 via the import syntax, and these names may then override built-in ones:
1113
1114     use subs 'chdir', 'chroot', 'chmod', 'chown';
1115     chdir $somewhere;
1116     sub chdir { ... }
1117
1118 To unambiguously refer to the built-in form, precede the
1119 built-in name with the special package qualifier C<CORE::>.  For example,
1120 saying C<CORE::open()> always refers to the built-in C<open()>, even
1121 if the current package has imported some other subroutine called
1122 C<&open()> from elsewhere.  Even though it looks like a regular
1123 function call, it isn't: you can't take a reference to it, such as
1124 the incorrect C<\&CORE::open> might appear to produce.
1125
1126 Library modules should not in general export built-in names like C<open>
1127 or C<chdir> as part of their default C<@EXPORT> list, because these may
1128 sneak into someone else's namespace and change the semantics unexpectedly.
1129 Instead, if the module adds that name to C<@EXPORT_OK>, then it's
1130 possible for a user to import the name explicitly, but not implicitly.
1131 That is, they could say
1132
1133     use Module 'open';
1134
1135 and it would import the C<open> override.  But if they said
1136
1137     use Module;
1138
1139 they would get the default imports without overrides.
1140
1141 The foregoing mechanism for overriding built-in is restricted, quite
1142 deliberately, to the package that requests the import.  There is a second
1143 method that is sometimes applicable when you wish to override a built-in
1144 everywhere, without regard to namespace boundaries.  This is achieved by
1145 importing a sub into the special namespace C<CORE::GLOBAL::>.  Here is an
1146 example that quite brazenly replaces the C<glob> operator with something
1147 that understands regular expressions.
1148
1149     package REGlob;
1150     require Exporter;
1151     @ISA = 'Exporter';
1152     @EXPORT_OK = 'glob';
1153
1154     sub import {
1155         my $pkg = shift;
1156         return unless @_;
1157         my $sym = shift;
1158         my $where = ($sym =~ s/^GLOBAL_// ? 'CORE::GLOBAL' : caller(0));
1159         $pkg->export($where, $sym, @_);
1160     }
1161
1162     sub glob {
1163         my $pat = shift;
1164         my @got;
1165         local *D;
1166         if (opendir D, '.') { 
1167             @got = grep /$pat/, readdir D; 
1168             closedir D;   
1169         }
1170         return @got;
1171     }
1172     1;
1173
1174 And here's how it could be (ab)used:
1175
1176     #use REGlob 'GLOBAL_glob';      # override glob() in ALL namespaces
1177     package Foo;
1178     use REGlob 'glob';              # override glob() in Foo:: only
1179     print for <^[a-z_]+\.pm\$>;     # show all pragmatic modules
1180
1181 The initial comment shows a contrived, even dangerous example.
1182 By overriding C<glob> globally, you would be forcing the new (and
1183 subversive) behavior for the C<glob> operator for I<every> namespace,
1184 without the complete cognizance or cooperation of the modules that own
1185 those namespaces.  Naturally, this should be done with extreme caution--if
1186 it must be done at all.
1187
1188 The C<REGlob> example above does not implement all the support needed to
1189 cleanly override perl's C<glob> operator.  The built-in C<glob> has
1190 different behaviors depending on whether it appears in a scalar or list
1191 context, but our C<REGlob> doesn't.  Indeed, many perl built-in have such
1192 context sensitive behaviors, and these must be adequately supported by
1193 a properly written override.  For a fully functional example of overriding
1194 C<glob>, study the implementation of C<File::DosGlob> in the standard
1195 library.
1196
1197 When you override a built-in, your replacement should be consistent (if
1198 possible) with the built-in native syntax.  You can achieve this by using
1199 a suitable prototype.  To get the prototype of an overridable built-in,
1200 use the C<prototype> function with an argument of C<"CORE::builtin_name">
1201 (see L<perlfunc/prototype>).
1202
1203 Note however that some built-ins can't have their syntax expressed by a
1204 prototype (such as C<system> or C<chomp>).  If you override them you won't
1205 be able to fully mimic their original syntax.
1206
1207 The built-ins C<do>, C<require> and C<glob> can also be overriden, but due
1208 to special magic, their original syntax is preserved, and you don't have
1209 to define a prototype for their replacements.  (You can't override the
1210 C<do BLOCK> syntax, though).
1211
1212 C<require> has special additional dark magic: if you invoke your
1213 C<require> replacement as C<require Foo::Bar>, it will actually receive
1214 the argument C<"Foo/Bar.pm"> in @_.  See L<perlfunc/require>.
1215
1216 And, as you'll have noticed from the previous example, if you override
1217 C<glob>, the C<E<lt>*E<gt>> glob operator is overriden as well.
1218
1219 Finally, some built-ins (e.g. C<exists> or C<grep>) can't be overriden.
1220
1221 =head2 Autoloading
1222
1223 If you call a subroutine that is undefined, you would ordinarily
1224 get an immediate, fatal error complaining that the subroutine doesn't
1225 exist.  (Likewise for subroutines being used as methods, when the
1226 method doesn't exist in any base class of the class's package.)
1227 However, if an C<AUTOLOAD> subroutine is defined in the package or
1228 packages used to locate the original subroutine, then that
1229 C<AUTOLOAD> subroutine is called with the arguments that would have
1230 been passed to the original subroutine.  The fully qualified name
1231 of the original subroutine magically appears in the global $AUTOLOAD
1232 variable of the same package as the C<AUTOLOAD> routine.  The name
1233 is not passed as an ordinary argument because, er, well, just
1234 because, that's why...
1235
1236 Many C<AUTOLOAD> routines load in a definition for the requested
1237 subroutine using eval(), then execute that subroutine using a special
1238 form of goto() that erases the stack frame of the C<AUTOLOAD> routine
1239 without a trace.  (See the source to the standard module documented
1240 in L<AutoLoader>, for example.)  But an C<AUTOLOAD> routine can
1241 also just emulate the routine and never define it.   For example,
1242 let's pretend that a function that wasn't defined should just invoke
1243 C<system> with those arguments.  All you'd do is:
1244
1245     sub AUTOLOAD {
1246         my $program = $AUTOLOAD;
1247         $program =~ s/.*:://;
1248         system($program, @_);
1249     }
1250     date();
1251     who('am', 'i');
1252     ls('-l');
1253
1254 In fact, if you predeclare functions you want to call that way, you don't
1255 even need parentheses:
1256
1257     use subs qw(date who ls);
1258     date;
1259     who "am", "i";
1260     ls -l;
1261
1262 A more complete example of this is the standard Shell module, which
1263 can treat undefined subroutine calls as calls to external programs.
1264
1265 Mechanisms are available to help modules writers split their modules
1266 into autoloadable files.  See the standard AutoLoader module
1267 described in L<AutoLoader> and in L<AutoSplit>, the standard
1268 SelfLoader modules in L<SelfLoader>, and the document on adding C
1269 functions to Perl code in L<perlxs>.
1270
1271 =head2 Subroutine Attributes
1272
1273 A subroutine declaration or definition may have a list of attributes
1274 associated with it.  If such an attribute list is present, it is
1275 broken up at space or colon boundaries and treated as though a
1276 C<use attributes> had been seen.  See L<attributes> for details
1277 about what attributes are currently supported.
1278 Unlike the limitation with the obsolescent C<use attrs>, the
1279 C<sub : ATTRLIST> syntax works to associate the attributes with
1280 a pre-declaration, and not just with a subroutine definition.
1281
1282 The attributes must be valid as simple identifier names (without any
1283 punctuation other than the '_' character).  They may have a parameter
1284 list appended, which is only checked for whether its parentheses ('(',')')
1285 nest properly.
1286
1287 Examples of valid syntax (even though the attributes are unknown):
1288
1289     sub fnord (&\%) : switch(10,foo(7,3))  :  expensive ;
1290     sub plugh () : Ugly('\(") :Bad ;
1291     sub xyzzy : _5x5 { ... }
1292
1293 Examples of invalid syntax:
1294
1295     sub fnord : switch(10,foo() ; # ()-string not balanced
1296     sub snoid : Ugly('(') ;       # ()-string not balanced
1297     sub xyzzy : 5x5 ;             # "5x5" not a valid identifier
1298     sub plugh : Y2::north ;       # "Y2::north" not a simple identifier
1299     sub snurt : foo + bar ;       # "+" not a colon or space
1300
1301 The attribute list is passed as a list of constant strings to the code
1302 which associates them with the subroutine.  In particular, the second example
1303 of valid syntax above currently looks like this in terms of how it's
1304 parsed and invoked:
1305
1306     use attributes __PACKAGE__, \&plugh, q[Ugly('\(")], 'Bad';
1307
1308 For further details on attribute lists and their manipulation,
1309 see L<attributes>.
1310
1311 =head1 SEE ALSO
1312
1313 See L<perlref/"Function Templates"> for more about references and closures.
1314 See L<perlxs> if you'd like to learn about calling C subroutines from Perl.  
1315 See L<perlembed> if you'd like to learn about calling Perl subroutines from C.  
1316 See L<perlmod> to learn about bundling up your functions in separate files.
1317 See L<perlmodlib> to learn what library modules come standard on your system.
1318 See L<perltoot> to learn how to make object method calls.