This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
76f345de35ad87e73f120364db5ae27ed4cc6d33
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2
3 perlre - Perl regular expressions
4
5 =head1 DESCRIPTION
6
7 This page describes the syntax of regular expressions in Perl.  For a
8 description of how to I<use> regular expressions in matching
9 operations, plus various examples of the same, see discussions
10 of C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like Operators">.
11
12 Matching operations can have various modifiers.  Modifiers
13 that relate to the interpretation of the regular expression inside
14 are listed below.  Modifiers that alter the way a regular expression
15 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and 
16 L<perlop/"Gory details of parsing quoted constructs">.
17
18 =over 4
19
20 =item i
21
22 Do case-insensitive pattern matching.
23
24 If C<use locale> is in effect, the case map is taken from the current
25 locale.  See L<perllocale>.
26
27 =item m
28
29 Treat string as multiple lines.  That is, change "^" and "$" from matching
30 the start or end of the string to matching the start or end of any
31 line anywhere within the string.
32
33 =item s
34
35 Treat string as single line.  That is, change "." to match any character
36 whatsoever, even a newline, which normally it would not match.
37
38 The C</s> and C</m> modifiers both override the C<$*> setting.  That
39 is, no matter what C<$*> contains, C</s> without C</m> will force
40 "^" to match only at the beginning of the string and "$" to match
41 only at the end (or just before a newline at the end) of the string.
42 Together, as /ms, they let the "." match any character whatsoever,
43 while yet allowing "^" and "$" to match, respectively, just after
44 and just before newlines within the string.
45
46 =item x
47
48 Extend your pattern's legibility by permitting whitespace and comments.
49
50 =back
51
52 These are usually written as "the C</x> modifier", even though the delimiter
53 in question might not really be a slash.  Any of these
54 modifiers may also be embedded within the regular expression itself using
55 the C<(?...)> construct.  See below.
56
57 The C</x> modifier itself needs a little more explanation.  It tells
58 the regular expression parser to ignore whitespace that is neither
59 backslashed nor within a character class.  You can use this to break up
60 your regular expression into (slightly) more readable parts.  The C<#>
61 character is also treated as a metacharacter introducing a comment,
62 just as in ordinary Perl code.  This also means that if you want real
63 whitespace or C<#> characters in the pattern (outside a character
64 class, where they are unaffected by C</x>), that you'll either have to 
65 escape them or encode them using octal or hex escapes.  Taken together,
66 these features go a long way towards making Perl's regular expressions
67 more readable.  Note that you have to be careful not to include the
68 pattern delimiter in the comment--perl has no way of knowing you did
69 not intend to close the pattern early.  See the C-comment deletion code
70 in L<perlop>.
71
72 =head2 Regular Expressions
73
74 The patterns used in Perl pattern matching derive from supplied in
75 the Version 8 regex routines.  (The routines are derived
76 (distantly) from Henry Spencer's freely redistributable reimplementation
77 of the V8 routines.)  See L<Version 8 Regular Expressions> for
78 details.
79
80 In particular the following metacharacters have their standard I<egrep>-ish
81 meanings:
82
83     \   Quote the next metacharacter
84     ^   Match the beginning of the line
85     .   Match any character (except newline)
86     $   Match the end of the line (or before newline at the end)
87     |   Alternation
88     ()  Grouping
89     []  Character class
90
91 By default, the "^" character is guaranteed to match only the
92 beginning of the string, the "$" character only the end (or before the
93 newline at the end), and Perl does certain optimizations with the
94 assumption that the string contains only one line.  Embedded newlines
95 will not be matched by "^" or "$".  You may, however, wish to treat a
96 string as a multi-line buffer, such that the "^" will match after any
97 newline within the string, and "$" will match before any newline.  At the
98 cost of a little more overhead, you can do this by using the /m modifier
99 on the pattern match operator.  (Older programs did this by setting C<$*>,
100 but this practice is now deprecated.)
101
102 To simplify multi-line substitutions, the "." character never matches a
103 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
104 the string is a single line--even if it isn't.  The C</s> modifier also
105 overrides the setting of C<$*>, in case you have some (badly behaved) older
106 code that sets it in another module.
107
108 The following standard quantifiers are recognized:
109
110     *      Match 0 or more times
111     +      Match 1 or more times
112     ?      Match 1 or 0 times
113     {n}    Match exactly n times
114     {n,}   Match at least n times
115     {n,m}  Match at least n but not more than m times
116
117 (If a curly bracket occurs in any other context, it is treated
118 as a regular character.)  The "*" modifier is equivalent to C<{0,}>, the "+"
119 modifier to C<{1,}>, and the "?" modifier to C<{0,1}>.  n and m are limited
120 to integral values less than a preset limit defined when perl is built.
121 This is usually 32766 on the most common platforms.  The actual limit can
122 be seen in the error message generated by code such as this:
123
124         $_ **= $_ , / {$_} / for 2 .. 42;
125
126 By default, a quantified subpattern is "greedy", that is, it will match as
127 many times as possible (given a particular starting location) while still
128 allowing the rest of the pattern to match.  If you want it to match the
129 minimum number of times possible, follow the quantifier with a "?".  Note
130 that the meanings don't change, just the "greediness":
131
132     *?     Match 0 or more times
133     +?     Match 1 or more times
134     ??     Match 0 or 1 time
135     {n}?   Match exactly n times
136     {n,}?  Match at least n times
137     {n,m}? Match at least n but not more than m times
138
139 Because patterns are processed as double quoted strings, the following
140 also work:
141
142     \t          tab                   (HT, TAB)
143     \n          newline               (LF, NL)
144     \r          return                (CR)
145     \f          form feed             (FF)
146     \a          alarm (bell)          (BEL)
147     \e          escape (think troff)  (ESC)
148     \033        octal char (think of a PDP-11)
149     \x1B        hex char
150     \x{263a}    wide hex char         (Unicode SMILEY)
151     \c[         control char
152     \N{name}    named char
153     \l          lowercase next char (think vi)
154     \u          uppercase next char (think vi)
155     \L          lowercase till \E (think vi)
156     \U          uppercase till \E (think vi)
157     \E          end case modification (think vi)
158     \Q          quote (disable) pattern metacharacters till \E
159
160 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
161 and C<\U> is taken from the current locale.  See L<perllocale>.  For
162 documentation of C<\N{name}>, see L<charnames>.
163
164 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
165 An unescaped C<$> or C<@> interpolates the corresponding variable,
166 while escaping will cause the literal string C<\$> to be matched.
167 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
168
169 In addition, Perl defines the following:
170
171     \w  Match a "word" character (alphanumeric plus "_")
172     \W  Match a non-word character
173     \s  Match a whitespace character
174     \S  Match a non-whitespace character
175     \d  Match a digit character
176     \D  Match a non-digit character
177     \pP Match P, named property.  Use \p{Prop} for longer names.
178     \PP Match non-P
179     \X  Match eXtended Unicode "combining character sequence",
180         equivalent to C<(?:\PM\pM*)>
181     \C  Match a single C char (octet) even under utf8.
182
183 A C<\w> matches a single alphanumeric character, not a whole word.
184 Use C<\w+> to match a string of Perl-identifier characters (which isn't 
185 the same as matching an English word).  If C<use locale> is in effect, the
186 list of alphabetic characters generated by C<\w> is taken from the
187 current locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
188 C<\d>, and C<\D> within character classes (though not as either end of
189 a range).  See L<utf8> for details about C<\pP>, C<\PP>, and C<\X>.
190
191 The POSIX character class syntax
192
193         [:class:]
194
195 is also available.  The available classes and their \-equivalents
196 (if any) are as follows:
197
198     alpha
199     alnum
200     ascii
201     cntrl
202     digit       \d
203     graph
204     lower
205     print
206     punct
207     space       \s
208     upper
209     word        \w
210     xdigit
211
212 Note that the [] are part of the [::] construct, not part of the whole
213 character class.  For example:
214
215         [01[:alpha:]%]
216
217 matches one, zero, any alphabetic character, and the percentage sign.
218
219 The exact meanings of the above classes depend from many things:
220 if the C<utf8> pragma is used, the following equivalences to Unicode
221 \p{} constructs hold:
222
223     alpha       IsAlpha
224     alnum       IsAlnum
225     ascii       IsASCII
226     cntrl       IsCntrl
227     digit       IsDigit
228     graph       IsGraph
229     lower       IsLower
230     print       IsPrint
231     punct       IsPunct
232     space       IsSpace
233     upper       IsUpper
234     word        IsWord
235     xdigit      IsXDigit
236
237 For example, [:lower:] and \p{IsLower} are equivalent.
238
239 If the C<utf8> pragma is not used but the C<locale> pragma is, the
240 classes correlate with the isalpha(3) interface (except for `word',
241 which is a Perl extension, mirroring \w).
242
243 The assumedly non-obviously named classes are:
244
245 =over 4
246
247 =item cntrl
248
249         Any control character.  Usually characters that don't produce
250         output as such but instead control the terminal somehow:
251         for example newline and backspace are control characters.
252         All characters with ord() less than 32 are most often control
253         classified as characters.
254
255 =item graph
256
257         Any alphanumeric or punctuation character.
258
259 =item print
260
261         Any alphanumeric or punctuation character or space.
262
263 =item punct
264
265         Any punctuation character.
266
267 =item xdigit
268
269         Any hexadecimal digit.  Though this may feel silly
270         (/0-9a-f/i would work just fine) it is included
271         for completeness.
272
273 =item 
274
275 =back
276
277 You can negate the [::] character classes by prefixing the class name
278 with a '^'. This is a Perl extension.  For example:
279
280     POSIX       trad. Perl  utf8 Perl
281
282     [:^digit:]      \D      \P{IsDigit}
283     [:^space:]      \S      \P{IsSpace}
284     [:^word:]       \W      \P{IsWord}
285
286 The POSIX character classes [.cc.] and [=cc=] are B<not> supported
287 and trying to use them will cause an error.
288
289 Perl defines the following zero-width assertions:
290
291     \b  Match a word boundary
292     \B  Match a non-(word boundary)
293     \A  Match only at beginning of string
294     \Z  Match only at end of string, or before newline at the end
295     \z  Match only at end of string
296     \G  Match only where previous m//g left off (works only with /g)
297
298 A word boundary (C<\b>) is a spot between two characters
299 that has a C<\w> on one side of it and a C<\W> on the other side
300 of it (in either order), counting the imaginary characters off the
301 beginning and end of the string as matching a C<\W>.  (Within
302 character classes C<\b> represents backspace rather than a word
303 boundary, just as it normally does in any double-quoted string.)
304 The C<\A> and C<\Z> are just like "^" and "$", except that they
305 won't match multiple times when the C</m> modifier is used, while
306 "^" and "$" will match at every internal line boundary.  To match
307 the actual end of the string and not ignore an optional trailing
308 newline, use C<\z>.
309
310 The C<\G> assertion can be used to chain global matches (using
311 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
312 It is also useful when writing C<lex>-like scanners, when you have
313 several patterns that you want to match against consequent substrings
314 of your string, see the previous reference.  The actual location
315 where C<\G> will match can also be influenced by using C<pos()> as
316 an lvalue.  See L<perlfunc/pos>.
317   
318 The bracketing construct C<( ... )> creates capture buffers.  To
319 refer to the digit'th buffer use \E<lt>digitE<gt> within the
320 match.  Outside the match use "$" instead of "\".  (The
321 \E<lt>digitE<gt> notation works in certain circumstances outside 
322 the match.  See the warning below about \1 vs $1 for details.)
323 Referring back to another part of the match is called a
324 I<backreference>.
325
326 There is no limit to the number of captured substrings that you may
327 use.  However Perl also uses \10, \11, etc. as aliases for \010,
328 \011, etc.  (Recall that 0 means octal, so \011 is the 9'th ASCII
329 character, a tab.)  Perl resolves this ambiguity by interpreting
330 \10 as a backreference only if at least 10 left parentheses have
331 opened before it.  Likewise \11 is a backreference only if at least
332 11 left parentheses have opened before it.  And so on.  \1 through
333 \9 are always interpreted as backreferences."
334
335 Examples:
336
337     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
338
339      if (/(.)\1/) {                 # find first doubled char
340          print "'$1' is the first doubled character\n";
341      }
342  
343     if (/Time: (..):(..):(..)/) {   # parse out values
344         $hours = $1;
345         $minutes = $2;
346         $seconds = $3;
347     }
348   
349 Several special variables also refer back to portions of the previous
350 match.  C<$+> returns whatever the last bracket match matched.
351 C<$&> returns the entire matched string.  (At one point C<$0> did
352 also, but now it returns the name of the program.)  C<$`> returns
353 everything before the matched string.  And C<$'> returns everything
354 after the matched string.
355
356 The numbered variables ($1, $2, $3, etc.) and the related punctuation
357 set (C<<$+>, C<$&>, C<$`>, and C<$'>) are all dynamically scoped
358 until the end of the enclosing block or until the next successful
359 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
360
361 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
362 C<$'> anywhere in the program, it has to provide them for every
363 pattern match.  This may substantially slow your program.  Perl
364 uses the same mechanism to produce $1, $2, etc, so you also pay a
365 price for each pattern that contains capturing parentheses.  (To
366 avoid this cost while retaining the grouping behaviour, use the
367 extended regular expression C<(?: ... )> instead.)  But if you never
368 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
369 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
370 if you can, but if you can't (and some algorithms really appreciate
371 them), once you've used them once, use them at will, because you've
372 already paid the price.  As of 5.005, C<$&> is not so costly as the
373 other two.
374
375 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
376 C<\w>, C<\n>.  Unlike some other regular expression languages, there
377 are no backslashed symbols that aren't alphanumeric.  So anything
378 that looks like \\, \(, \), \E<lt>, \E<gt>, \{, or \} is always
379 interpreted as a literal character, not a metacharacter.  This was
380 once used in a common idiom to disable or quote the special meanings
381 of regular expression metacharacters in a string that you want to
382 use for a pattern. Simply quote all non-alphanumeric characters:
383
384     $pattern =~ s/(\W)/\\$1/g;
385
386 Today it is more common to use the quotemeta() function or the C<\Q>
387 metaquoting escape sequence to disable all metacharacters' special
388 meanings like this:
389
390     /$unquoted\Q$quoted\E$unquoted/
391
392 =head2 Extended Patterns
393
394 Perl also defines a consistent extension syntax for features not
395 found in standard tools like B<awk> and B<lex>.  The syntax is a
396 pair of parentheses with a question mark as the first thing within
397 the parentheses.  The character after the question mark indicates
398 the extension.
399
400 The stability of these extensions varies widely.  Some have been
401 part of the core language for many years.  Others are experimental
402 and may change without warning or be completely removed.  Check
403 the documentation on an individual feature to verify its current
404 status.
405
406 A question mark was chosen for this and for the minimal-matching
407 construct because 1) question marks are rare in older regular
408 expressions, and 2) whenever you see one, you should stop and
409 "question" exactly what is going on.  That's psychology...
410
411 =over 10
412
413 =item C<(?#text)>
414
415 A comment.  The text is ignored.  If the C</x> modifier enables
416 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
417 the comment as soon as it sees a C<)>, so there is no way to put a literal
418 C<)> in the comment.
419
420 =item C<(?imsx-imsx)>
421
422 One or more embedded pattern-match modifiers.  This is particularly
423 useful for dynamic patterns, such as those read in from a configuration
424 file, read in as an argument, are specified in a table somewhere,
425 etc.  Consider the case that some of which want to be case sensitive
426 and some do not.  The case insensitive ones need to include merely
427 C<(?i)> at the front of the pattern.  For example:
428
429     $pattern = "foobar";
430     if ( /$pattern/i ) { } 
431
432     # more flexible:
433
434     $pattern = "(?i)foobar";
435     if ( /$pattern/ ) { } 
436
437 Letters after a C<-> turn those modifiers off.  These modifiers are
438 localized inside an enclosing group (if any).  For example,
439
440     ( (?i) blah ) \s+ \1
441
442 will match a repeated (I<including the case>!) word C<blah> in any
443 case, assuming C<x> modifier, and no C<i> modifier outside this
444 group.
445
446 =item C<(?:pattern)>
447
448 =item C<(?imsx-imsx:pattern)>
449
450 This is for clustering, not capturing; it groups subexpressions like
451 "()", but doesn't make backreferences as "()" does.  So
452
453     @fields = split(/\b(?:a|b|c)\b/)
454
455 is like
456
457     @fields = split(/\b(a|b|c)\b/)
458
459 but doesn't spit out extra fields.  It's also cheaper not to capture
460 characters if you don't need to.
461
462 Any letters between C<?> and C<:> act as flags modifiers as with
463 C<(?imsx-imsx)>.  For example, 
464
465     /(?s-i:more.*than).*million/i
466
467 is equivalent to the more verbose
468
469     /(?:(?s-i)more.*than).*million/i
470
471 =item C<(?=pattern)>
472
473 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
474 matches a word followed by a tab, without including the tab in C<$&>.
475
476 =item C<(?!pattern)>
477
478 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
479 matches any occurrence of "foo" that isn't followed by "bar".  Note
480 however that look-ahead and look-behind are NOT the same thing.  You cannot
481 use this for look-behind.
482
483 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
484 will not do what you want.  That's because the C<(?!foo)> is just saying that
485 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
486 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
487 say "like" because there's the case of your "bar" not having three characters
488 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
489 Sometimes it's still easier just to say:
490
491     if (/bar/ && $` !~ /foo$/)
492
493 For look-behind see below.
494
495 =item C<(?E<lt>=pattern)>
496
497 A zero-width positive look-behind assertion.  For example, C</(?E<lt>=\t)\w+/>
498 matches a word that follows a tab, without including the tab in C<$&>.
499 Works only for fixed-width look-behind.
500
501 =item C<(?<!pattern)>
502
503 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
504 matches any occurrence of "foo" that does not follow "bar".  Works
505 only for fixed-width look-behind.
506
507 =item C<(?{ code })>
508
509 B<WARNING>: This extended regular expression feature is considered
510 highly experimental, and may be changed or deleted without notice.
511
512 This zero-width assertion evaluate any embedded Perl code.  It
513 always succeeds, and its C<code> is not interpolated.  Currently,
514 the rules to determine where the C<code> ends are somewhat convoluted.
515
516 The C<code> is properly scoped in the following sense: If the assertion
517 is backtracked (compare L<"Backtracking">), all changes introduced after
518 C<local>ization are undone, so that
519
520   $_ = 'a' x 8;
521   m< 
522      (?{ $cnt = 0 })                    # Initialize $cnt.
523      (
524        a 
525        (?{
526            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
527        })
528      )*  
529      aaaa
530      (?{ $res = $cnt })                 # On success copy to non-localized
531                                         # location.
532    >x;
533
534 will set C<$res = 4>.  Note that after the match, $cnt returns to the globally
535 introduced value, because the scopes that restrict C<local> operators
536 are unwound.
537
538 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
539 switch.  If I<not> used in this way, the result of evaluation of
540 C<code> is put into the special variable C<$^R>.  This happens
541 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
542 inside the same regular expression.
543
544 The assignment to C<$^R> above is properly localized, so the old
545 value of C<$^R> is restored if the assertion is backtracked; compare
546 L<"Backtracking">.
547
548 For reasons of security, this construct is forbidden if the regular
549 expression involves run-time interpolation of variables, unless the
550 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
551 variables contain results of C<qr//> operator (see
552 L<perlop/"qr/STRING/imosx">).  
553
554 This restriction is because of the wide-spread and remarkably convenient
555 custom of using run-time determined strings as patterns.  For example:
556
557     $re = <>;
558     chomp $re;
559     $string =~ /$re/;
560
561 Before Perl knew how to execute interpolated code within a pattern,
562 this operation was completely safe from a security point of view,
563 although it could raise an exception from an illegal pattern.  If
564 you turn on the C<use re 'eval'>, though, it is no longer secure,
565 so you should only do so if you are also using taint checking.
566 Better yet, use the carefully constrained evaluation within a Safe
567 module.  See L<perlsec> for details about both these mechanisms.
568
569 =item C<(?p{ code })>
570
571 B<WARNING>: This extended regular expression feature is considered
572 highly experimental, and may be changed or deleted without notice.
573
574 This is a "postponed" regular subexpression.  The C<code> is evaluated
575 at run time, at the moment this subexpression may match.  The result
576 of evaluation is considered as a regular expression and matched as
577 if it were inserted instead of this construct.
578
579 The C<code> is not interpolated.  As before, the rules to determine
580 where the C<code> ends are currently somewhat convoluted.
581
582 The following pattern matches a parenthesized group:
583
584   $re = qr{
585              \(
586              (?:
587                 (?> [^()]+ )    # Non-parens without backtracking
588               |
589                 (?p{ $re })     # Group with matching parens
590              )*
591              \)
592           }x;
593
594 =item C<(?E<gt>pattern)>
595
596 B<WARNING>: This extended regular expression feature is considered
597 highly experimental, and may be changed or deleted without notice.
598
599 An "independent" subexpression, one which matches the substring
600 that a I<standalone> C<pattern> would match if anchored at the given
601 position--but it matches no more than this substring.  This
602 construct is useful for optimizations of what would otherwise be
603 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
604
605 For example: C<^(?E<gt>a*)ab> will never match, since C<(?E<gt>a*)>
606 (anchored at the beginning of string, as above) will match I<all>
607 characters C<a> at the beginning of string, leaving no C<a> for
608 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
609 since the match of the subgroup C<a*> is influenced by the following
610 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
611 C<a*ab> will match fewer characters than a standalone C<a*>, since
612 this makes the tail match.
613
614 An effect similar to C<(?E<gt>pattern)> may be achieved by writing
615 C<(?=(pattern))\1>.  This matches the same substring as a standalone
616 C<a+>, and the following C<\1> eats the matched string; it therefore
617 makes a zero-length assertion into an analogue of C<(?E<gt>...)>.
618 (The difference between these two constructs is that the second one
619 uses a capturing group, thus shifting ordinals of backreferences
620 in the rest of a regular expression.)
621
622 Consider this pattern:
623
624     m{ \(
625           ( 
626             [^()]+ 
627           | 
628             \( [^()]* \)
629           )+
630        \) 
631      }x
632
633 That will efficiently match a nonempty group with matching parentheses
634 two levels deep or less.  However, if there is no such group, it
635 will take virtually forever on a long string.  That's because there
636 are so many different ways to split a long string into several
637 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
638 to a subpattern of the above pattern.  Consider how the pattern
639 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
640 seconds, but that each extra letter doubles this time.  This
641 exponential performance will make it appear that your program has
642 hung.  However, a tiny change to this pattern
643
644     m{ \( 
645           ( 
646             (?> [^()]+ )
647           | 
648             \( [^()]* \)
649           )+
650        \) 
651      }x
652
653 which uses C<(?E<gt>...)> matches exactly when the one above does (verifying
654 this yourself would be a productive exercise), but finishes in a fourth
655 the time when used on a similar string with 1000000 C<a>s.  Be aware,
656 however, that this pattern currently triggers a warning message under
657 B<-w> saying it C<"matches the null string many times">):
658
659 On simple groups, such as the pattern C<(?E<gt> [^()]+ )>, a comparable
660 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
661 This was only 4 times slower on a string with 1000000 C<a>s.
662
663 =item C<(?(condition)yes-pattern|no-pattern)>
664
665 =item C<(?(condition)yes-pattern)>
666
667 B<WARNING>: This extended regular expression feature is considered
668 highly experimental, and may be changed or deleted without notice.
669
670 Conditional expression.  C<(condition)> should be either an integer in
671 parentheses (which is valid if the corresponding pair of parentheses
672 matched), or look-ahead/look-behind/evaluate zero-width assertion.
673
674 For example:
675
676     m{ ( \( )? 
677        [^()]+ 
678        (?(1) \) ) 
679      }x
680
681 matches a chunk of non-parentheses, possibly included in parentheses
682 themselves.
683
684 =back
685
686 =head2 Backtracking
687
688 A fundamental feature of regular expression matching involves the
689 notion called I<backtracking>, which is currently used (when needed)
690 by all regular expression quantifiers, namely C<*>, C<*?>, C<+>,
691 C<+?>, C<{n,m}>, and C<{n,m}?>.
692
693 For a regular expression to match, the I<entire> regular expression must
694 match, not just part of it.  So if the beginning of a pattern containing a
695 quantifier succeeds in a way that causes later parts in the pattern to
696 fail, the matching engine backs up and recalculates the beginning
697 part--that's why it's called backtracking.
698
699 Here is an example of backtracking:  Let's say you want to find the
700 word following "foo" in the string "Food is on the foo table.":
701
702     $_ = "Food is on the foo table.";
703     if ( /\b(foo)\s+(\w+)/i ) {
704         print "$2 follows $1.\n";
705     }
706
707 When the match runs, the first part of the regular expression (C<\b(foo)>)
708 finds a possible match right at the beginning of the string, and loads up
709 $1 with "Foo".  However, as soon as the matching engine sees that there's
710 no whitespace following the "Foo" that it had saved in $1, it realizes its
711 mistake and starts over again one character after where it had the
712 tentative match.  This time it goes all the way until the next occurrence
713 of "foo". The complete regular expression matches this time, and you get
714 the expected output of "table follows foo."
715
716 Sometimes minimal matching can help a lot.  Imagine you'd like to match
717 everything between "foo" and "bar".  Initially, you write something
718 like this:
719
720     $_ =  "The food is under the bar in the barn.";
721     if ( /foo(.*)bar/ ) {
722         print "got <$1>\n";
723     }
724
725 Which perhaps unexpectedly yields:
726
727   got <d is under the bar in the >
728
729 That's because C<.*> was greedy, so you get everything between the
730 I<first> "foo" and the I<last> "bar".  Here it's more effective
731 to use minimal matching to make sure you get the text between a "foo"
732 and the first "bar" thereafter.
733
734     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
735   got <d is under the >
736
737 Here's another example: let's say you'd like to match a number at the end
738 of a string, and you also want to keep the preceding part the match.
739 So you write this:
740
741     $_ = "I have 2 numbers: 53147";
742     if ( /(.*)(\d*)/ ) {                                # Wrong!
743         print "Beginning is <$1>, number is <$2>.\n";
744     }
745
746 That won't work at all, because C<.*> was greedy and gobbled up the
747 whole string. As C<\d*> can match on an empty string the complete
748 regular expression matched successfully.
749
750     Beginning is <I have 2 numbers: 53147>, number is <>.
751
752 Here are some variants, most of which don't work:
753
754     $_ = "I have 2 numbers: 53147";
755     @pats = qw{
756         (.*)(\d*)
757         (.*)(\d+)
758         (.*?)(\d*)
759         (.*?)(\d+)
760         (.*)(\d+)$
761         (.*?)(\d+)$
762         (.*)\b(\d+)$
763         (.*\D)(\d+)$
764     };
765
766     for $pat (@pats) {
767         printf "%-12s ", $pat;
768         if ( /$pat/ ) {
769             print "<$1> <$2>\n";
770         } else {
771             print "FAIL\n";
772         }
773     }
774
775 That will print out:
776
777     (.*)(\d*)    <I have 2 numbers: 53147> <>
778     (.*)(\d+)    <I have 2 numbers: 5314> <7>
779     (.*?)(\d*)   <> <>
780     (.*?)(\d+)   <I have > <2>
781     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
782     (.*?)(\d+)$  <I have 2 numbers: > <53147>
783     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
784     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
785
786 As you see, this can be a bit tricky.  It's important to realize that a
787 regular expression is merely a set of assertions that gives a definition
788 of success.  There may be 0, 1, or several different ways that the
789 definition might succeed against a particular string.  And if there are
790 multiple ways it might succeed, you need to understand backtracking to
791 know which variety of success you will achieve.
792
793 When using look-ahead assertions and negations, this can all get even
794 tricker.  Imagine you'd like to find a sequence of non-digits not
795 followed by "123".  You might try to write that as
796
797     $_ = "ABC123";
798     if ( /^\D*(?!123)/ ) {              # Wrong!
799         print "Yup, no 123 in $_\n";
800     }
801
802 But that isn't going to match; at least, not the way you're hoping.  It
803 claims that there is no 123 in the string.  Here's a clearer picture of
804 why it that pattern matches, contrary to popular expectations:
805
806     $x = 'ABC123' ;
807     $y = 'ABC445' ;
808
809     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/ ;
810     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/ ;
811
812     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/ ;
813     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/ ;
814
815 This prints
816
817     2: got ABC
818     3: got AB
819     4: got ABC
820
821 You might have expected test 3 to fail because it seems to a more
822 general purpose version of test 1.  The important difference between
823 them is that test 3 contains a quantifier (C<\D*>) and so can use
824 backtracking, whereas test 1 will not.  What's happening is
825 that you've asked "Is it true that at the start of $x, following 0 or more
826 non-digits, you have something that's not 123?"  If the pattern matcher had
827 let C<\D*> expand to "ABC", this would have caused the whole pattern to
828 fail.
829
830 The search engine will initially match C<\D*> with "ABC".  Then it will
831 try to match C<(?!123> with "123", which fails.  But because
832 a quantifier (C<\D*>) has been used in the regular expression, the
833 search engine can backtrack and retry the match differently
834 in the hope of matching the complete regular expression.
835
836 The pattern really, I<really> wants to succeed, so it uses the
837 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
838 time.  Now there's indeed something following "AB" that is not
839 "123".  It's "C123", which suffices.
840
841 We can deal with this by using both an assertion and a negation.
842 We'll say that the first part in $1 must be followed both by a digit
843 and by something that's not "123".  Remember that the look-aheads
844 are zero-width expressions--they only look, but don't consume any
845 of the string in their match.  So rewriting this way produces what
846 you'd expect; that is, case 5 will fail, but case 6 succeeds:
847
848     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/ ;
849     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/ ;
850
851     6: got ABC
852
853 In other words, the two zero-width assertions next to each other work as though
854 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
855 matches only if you're at the beginning of the line AND the end of the
856 line simultaneously.  The deeper underlying truth is that juxtaposition in
857 regular expressions always means AND, except when you write an explicit OR
858 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
859 although the attempted matches are made at different positions because "a"
860 is not a zero-width assertion, but a one-width assertion.
861
862 B<WARNING>: particularly complicated regular expressions can take
863 exponential time to solve because of the immense number of possible
864 ways they can use backtracking to try match.  For example, this will
865 take a painfully long time to run
866
867     /((a{0,5}){0,5}){0,5}/
868
869 And if you used C<*>'s instead of limiting it to 0 through 5 matches,
870 then it would take forever--or until you ran out of stack space.
871
872 A powerful tool for optimizing such beasts is "independent" groups,
873 which do not backtrace (see L<C<(?E<gt>pattern)>>).  Note also that
874 zero-length look-ahead/look-behind assertions will not backtrace to make
875 the tail match, since they are in "logical" context: only 
876 whether they match is considered relevant.  For an example
877 where side-effects of a look-ahead I<might> have influenced the
878 following match, see L<C<(?E<gt>pattern)>>.
879
880 =head2 Version 8 Regular Expressions
881
882 In case you're not familiar with the "regular" Version 8 regex
883 routines, here are the pattern-matching rules not described above.
884
885 Any single character matches itself, unless it is a I<metacharacter>
886 with a special meaning described here or above.  You can cause
887 characters that normally function as metacharacters to be interpreted
888 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
889 character; "\\" matches a "\").  A series of characters matches that
890 series of characters in the target string, so the pattern C<blurfl>
891 would match "blurfl" in the target string.
892
893 You can specify a character class, by enclosing a list of characters
894 in C<[]>, which will match any one character from the list.  If the
895 first character after the "[" is "^", the class matches any character not
896 in the list.  Within a list, the "-" character specifies a
897 range, so that C<a-z> represents all characters between "a" and "z",
898 inclusive.  If you want "-" itself to be a member of a class, put it
899 at the start or end of the list, or escape it with a backslash.  (The
900 following all specify the same class of three characters: C<[-az]>,
901 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
902 specifies a class containing twenty-six characters.)
903
904 Note also that the whole range idea is rather unportable between
905 character sets--and even within character sets they may cause results
906 you probably didn't expect.  A sound principle is to use only ranges
907 that begin from and end at either alphabets of equal case ([a-e],
908 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
909 spell out the character sets in full.
910
911 Characters may be specified using a metacharacter syntax much like that
912 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
913 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
914 of octal digits, matches the character whose ASCII value is I<nnn>.
915 Similarly, \xI<nn>, where I<nn> are hexadecimal digits, matches the
916 character whose ASCII value is I<nn>. The expression \cI<x> matches the
917 ASCII character control-I<x>.  Finally, the "." metacharacter matches any
918 character except "\n" (unless you use C</s>).
919
920 You can specify a series of alternatives for a pattern using "|" to
921 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
922 or "foe" in the target string (as would C<f(e|i|o)e>).  The
923 first alternative includes everything from the last pattern delimiter
924 ("(", "[", or the beginning of the pattern) up to the first "|", and
925 the last alternative contains everything from the last "|" to the next
926 pattern delimiter.  That's why it's common practice to include
927 alternatives in parentheses: to minimize confusion about where they
928 start and end.
929
930 Alternatives are tried from left to right, so the first
931 alternative found for which the entire expression matches, is the one that
932 is chosen. This means that alternatives are not necessarily greedy. For
933 example: when matching C<foo|foot> against "barefoot", only the "foo"
934 part will match, as that is the first alternative tried, and it successfully
935 matches the target string. (This might not seem important, but it is
936 important when you are capturing matched text using parentheses.)
937
938 Also remember that "|" is interpreted as a literal within square brackets,
939 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
940
941 Within a pattern, you may designate subpatterns for later reference
942 by enclosing them in parentheses, and you may refer back to the
943 I<n>th subpattern later in the pattern using the metacharacter
944 \I<n>.  Subpatterns are numbered based on the left to right order
945 of their opening parenthesis.  A backreference matches whatever
946 actually matched the subpattern in the string being examined, not
947 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
948 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
949 1 matched "0x", even though the rule C<0|0x> could potentially match
950 the leading 0 in the second number.
951
952 =head2 Warning on \1 vs $1
953
954 Some people get too used to writing things like:
955
956     $pattern =~ s/(\W)/\\\1/g;
957
958 This is grandfathered for the RHS of a substitute to avoid shocking the
959 B<sed> addicts, but it's a dirty habit to get into.  That's because in
960 PerlThink, the righthand side of a C<s///> is a double-quoted string.  C<\1> in
961 the usual double-quoted string means a control-A.  The customary Unix
962 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
963 of doing that, you get yourself into trouble if you then add an C</e>
964 modifier.
965
966     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
967
968 Or if you try to do
969
970     s/(\d+)/\1000/;
971
972 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
973 C<${1}000>.  The operation of interpolation should not be confused
974 with the operation of matching a backreference.  Certainly they mean two
975 different things on the I<left> side of the C<s///>.
976
977 =head2 Repeated patterns matching zero-length substring
978
979 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
980
981 Regular expressions provide a terse and powerful programming language.  As
982 with most other power tools, power comes together with the ability
983 to wreak havoc.
984
985 A common abuse of this power stems from the ability to make infinite
986 loops using regular expressions, with something as innocuous as:
987
988     'foo' =~ m{ ( o? )* }x;
989
990 The C<o?> can match at the beginning of C<'foo'>, and since the position
991 in the string is not moved by the match, C<o?> would match again and again
992 because of the C<*> modifier.  Another common way to create a similar cycle
993 is with the looping modifier C<//g>:
994
995     @matches = ( 'foo' =~ m{ o? }xg );
996
997 or
998
999     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1000
1001 or the loop implied by split().
1002
1003 However, long experience has shown that many programming tasks may
1004 be significantly simplified by using repeated subexpressions that
1005 may match zero-length substrings.  Here's a simple example being:
1006
1007     @chars = split //, $string;           # // is not magic in split
1008     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1009
1010 Thus Perl allows the C</()/> construct, which I<forcefully breaks
1011 the infinite loop>.  The rules for this are different for lower-level
1012 loops given by the greedy modifiers C<*+{}>, and for higher-level
1013 ones like the C</g> modifier or split() operator.
1014
1015 The lower-level loops are I<interrupted> (that is, the loop is
1016 broken) when Perl detects that a repeated expression matched a
1017 zero-length substring.   Thus
1018
1019    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1020
1021 is made equivalent to 
1022
1023    m{   (?: NON_ZERO_LENGTH )* 
1024       | 
1025         (?: ZERO_LENGTH )? 
1026     }x;
1027
1028 The higher level-loops preserve an additional state between iterations:
1029 whether the last match was zero-length.  To break the loop, the following 
1030 match after a zero-length match is prohibited to have a length of zero.
1031 This prohibition interacts with backtracking (see L<"Backtracking">), 
1032 and so the I<second best> match is chosen if the I<best> match is of
1033 zero length.
1034
1035 For example:
1036
1037     $_ = 'bar';
1038     s/\w??/<$&>/g;
1039
1040 results in C<"<><b><><a><><r><>">.  At each position of the string the best
1041 match given by non-greedy C<??> is the zero-length match, and the I<second 
1042 best> match is what is matched by C<\w>.  Thus zero-length matches
1043 alternate with one-character-long matches.
1044
1045 Similarly, for repeated C<m/()/g> the second-best match is the match at the 
1046 position one notch further in the string.
1047
1048 The additional state of being I<matched with zero-length> is associated with
1049 the matched string, and is reset by each assignment to pos().
1050
1051 =head2 Creating custom RE engines
1052
1053 Overloaded constants (see L<overload>) provide a simple way to extend
1054 the functionality of the RE engine.
1055
1056 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
1057 matches at boundary between white-space characters and non-whitespace
1058 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
1059 at these positions, so we want to have each C<\Y|> in the place of the
1060 more complicated version.  We can create a module C<customre> to do
1061 this:
1062
1063     package customre;
1064     use overload;
1065
1066     sub import {
1067       shift;
1068       die "No argument to customre::import allowed" if @_;
1069       overload::constant 'qr' => \&convert;
1070     }
1071
1072     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
1073
1074     my %rules = ( '\\' => '\\', 
1075                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
1076     sub convert {
1077       my $re = shift;
1078       $re =~ s{ 
1079                 \\ ( \\ | Y . )
1080               }
1081               { $rules{$1} or invalid($re,$1) }sgex; 
1082       return $re;
1083     }
1084
1085 Now C<use customre> enables the new escape in constant regular
1086 expressions, i.e., those without any runtime variable interpolations.
1087 As documented in L<overload>, this conversion will work only over
1088 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
1089 part of this regular expression needs to be converted explicitly
1090 (but only if the special meaning of C<\Y|> should be enabled inside $re):
1091
1092     use customre;
1093     $re = <>;
1094     chomp $re;
1095     $re = customre::convert $re;
1096     /\Y|$re\Y|/;
1097
1098 =head1 BUGS
1099
1100 This manpage is varies from difficult to understand to completely
1101 and utterly opaque.
1102
1103 =head1 SEE ALSO
1104
1105 L<perlop/"Regexp Quote-Like Operators">.
1106
1107 L<perlop/"Gory details of parsing quoted constructs">.
1108
1109 L<perlfaq6>.
1110
1111 L<perlfunc/pos>.
1112
1113 L<perllocale>.
1114
1115 I<Mastering Regular Expressions> by Jeffrey Friedl, published
1116 by O'Reilly and Associates.